*comment é

*image chap2.png center CHAPTER TWO: BRUNT

*image chap2_quote.png center "Thus I became Queen Ashe's shadow. Where she went, so did I, covering the darkness where her light does not shine." —MamaNa

*page_break

The competing gleams of the golden surfaces should be enough to tell you that you're in Lady Venuma's quarters, but it's made all the more obvious by the many portraits of her hung throughout the expansive halls. These portraits are spaced between dozens of dynamic V-shaped sculptures, which someone else might mistake for homages to the Versus Verses—you know better, of course. Especially since you also note the lipstick V now painted on Lady Venuma's lips, which you've never seen before. You wonder if she only wears this shade in her private quarters….

Here in Lady Venuma's lush wing, you also wonder if the temperature and dry climate you've experienced so far on Versus might be semipermanent. After all, Lady Venuma's quarters feel like a tropical villa, all open air and exotic palms and water features. Every room seems to have a sweeping balcony, which you confirm as you pass a room filled with design sketches. Is it possible Lady Venuma designs all of her own dresses? If that's the case, you're sure she has an army of Aye Ayeseamstresses to sew them for her….

You thought your own guest suite was big, but you now realize it could easily fit into just Lady Venuma's entrance foyer. You suppose there's room enough in this Castle for all thirteen Elites to have this much space, but something tells you the grandest accommodations must be saved for Wone like Lady Venuma, Ord Ambassador or not. You can only imagine what Queen Ashe's master quarters must look like….

*page_break

"I would ask how you are enjoying your time in The Elite Castle, but that seems a rather rhetorical question," Lady Venuma says as she floats beside you, her caftan brushing the marble floor underneath.
*if (rlshp_venuma < 40) or (breezedie)
	You can tell she is trying to be polite, but you can also detect the hints of detestation underneath Lady Venuma's voice—she clearly isn't over what happened between you in the last few days.
	*goto alaswe
*else
	If Lady Venuma is pleased to see you, she isn't showing it—you can detect that she feels the need to play her cards close to her chest, for some reason.
	*goto alaswe
 	
*label alaswe

"Alas, we do not have time for small talk, as the other brunch guests await our arrival."

Obviously Lady Venuma is trying to usher you to the brunch as neutrally as possible, but now that you realize you might only have this quick moment alone with Lady Venuma, do you say anything to rouse the demigoddess? You certainly don't need Rosae to remind you how everything you say is loaded, especially when it comes to Lady Venuma.

*choice
	#"I'd much prefer a moment alone with you, my lady."
		*set outspoken %+18
		*if lvfinalromance
			"I plan for us to have many moments alone once today's work is done, little lost one," Lady Venuma says, hitting you with a look of pure lust that sends goosebumps rippling across your skin. "Trust in me and remain patient."

			*goto alonetimeoutcomes
		*else
			"I am glad to hear it, as we have much to discuss," Lady Venuma says. "Once my work for the day is done, we shall have our moment alone."

			*label alonetimeoutcomes
			*if (coupspy) or (coupbond)
				*set rlshp_venuma %+15
				*set status +2
				*if coupbond
					*set calculating %-9
				*if coupspy
					*set calculating %+9

				*label muchtosay
				Lady Venuma then turns to you with a knowing look gleaming in her eyes, as if she doesn't yet want to speak freely but still has much to say.
				*goto brunchery
			*elseif (doubleagent)
				*set rlshp_venuma %+15
				*set status +2
				*set calculating %+9
				*goto muchtosay
			*elseif (calculating > 60)
				*set rlshp_venuma %+5
				*set status +1
				*set abolishstatus +2

				Lady Venuma then turns to you, and you can tell that you were calculating enough to make her believe this statement, whether it's true or not.
				*goto brunchery
			*else
				*set rlshp_venuma %-15
				*set abolishstatus +2

				Lady Venuma then turns a remarkably cold shoulder to you despite her words, perhaps sensing some insincerity behind your own, given that you are a bit out of practice being calculating.
				*goto brunchery
	#"I'm very much enjoying my time here and look forward to brunch."
		*set outspoken %-18
		*if lvfinalromance
			"I hope you do not enjoy it so much that you forget about me, little lost one," Lady Venuma says, her eyes traveling over you. "Though worry not, for we shall have moments alone together to remind you of such matters.
			*goto enjoytimeoutcomes
		*else
			"Excellent," Lady Venuma says. "Though I do hope we might have an additional moment alone later, as we have much to discuss."

			*label enjoytimeoutcomes
			Lady Venuma then turns to you, and from the look she gives you,
			*if winjoin
				*set rlshp_venuma %+10
				*set status +2
				*set calculating %-9
				you can tell she doesn't detect the truth under your words: that you're truly here for the Elite, not for her.
				*goto brunchery
			*elseif coupspy
				*set rlshp_venuma %+10
				*set status +2
				*set calculating %+9
				you can tell she is pleased you are claiming to enjoy the Elite experience, given your aspirations to join as a secretive coup spy.
				*goto brunchery
			*elseif eliteinfo
				*set rlshp_venuma %+10
				*set status +2
				you can tell that she believes your words to be truthful, given your current lack of a political stance.
				*goto brunchery
			*elseif (calculating < 40)
				*set rlshp_venuma %+5
				*set status +1
				*set abolishstatus +2
				you can tell she believes your words to be truthful, given how trustworthy you naturally seem.
				*goto brunchery
			*else
				*set rlshp_venuma %-15
				*set abolishstatus +2
				you can tell she doubts whether your words were fully truthful, given your general disposition—which doesn't exactly prioritize seeming trustworthy.
				*goto brunchery
	#"This is all a bit much for me, to be honest."
		*set outspoken %+18
		*if lvfinalromance
			"Still, you must not lose your nerve now, little lost one," Lady Venuma says, her eyes traveling over you. "Worry not, we shall have moments alone later to bolster your confidence."
			*goto bitmuchoutcomes
		*else
			"Nonetheless, you must seem as if you belong, if you are to continue to do well," Lady Venuma says, remaining tight-lipped. "Worry not, we shall have moments alone later to bolster your confidence. There is much to discuss."

			*label bitmuchoutcomes
			Lady Venuma then turns to you, and from the look she gives you,
			*if coupbond
				*set rlshp_venuma %+10
				*set status +2
				*set calculating %-9
				you can tell she does at least seem to sense your hidden desire to remain strong with her coup.
				*goto brunchery
			*elseif doubleagent
				*set rlshp_venuma %+10
				*set status +2
				*set calculating %+9
				you can tell she does not detect that these words are meant only to cement your future status as a double agent inside her coup.
				*goto brunchery
			*elseif eliteinfo
				*set rlshp_venuma %+10
				*set status +2
				*set calculating %-9
				she believes your words to be truthful, given your current lack of a political stance.
				*goto brunchery
			*elseif (calculating < 40)
				*set rlshp_venuma %+5
				*set status +1
				*set abolishstatus +2
				she believes your words to be truthful, given how trustworthy you naturally seem.
				*goto brunchery
			*else
				*set rlshp_venuma %-15
				*set abolishstatus +2
				she doubts your words were truthful, given your general disposition—which doesn't exactly prioritize seeming trustworthy.
				*goto brunchery
	#Just let Lady Venuma do the talking.
		*set outspoken %-18
		*if lvfinalromance
			"What, no words for your great lady, little lost one?" Lady Venuma says, her eyes traveling over you. "Worry not, we shall have moments alone later to bolster your confidence."
			*goto saynothingoutcomes
		*else
			"Good, save your words for later," Lady Venuma says. "I plan for us to have a private moment alone when all my work is complete. There is much yet to discuss."

			*label saynothingoutcomes
			Lady Venuma then turns to you, and from the look she gives you,
			*if eliteinfo
				*set rlshp_venuma %+10
				*set status +2
				*if (calculating > 50)
					*set calculating %-9
				*if (calculating < 51)
					*set calculating %+9
				you can tell she still means to recruit you to her cause and senses your current lack of political affiliation.
				*goto brunchery
			*elseif winjoin
				*set rlshp_venuma %+10
				*set status +2
				*set calculating %-9
				you can tell she still believes she can convert you; obviously, she doesn't sense your desire to win the Trials solely to join the Elite.
				*goto brunchery
			*elseif (calculating > 60) or (calculating < 40)
				*set rlshp_venuma %+5
				*set status +1
				*set abolishstatus +2
				she believes your silence to truly be golden, at least at this moment.
				*goto brunchery
			*else
				*set rlshp_venuma %-15
				*set abolishstatus +2
				she finds doubt in your silence.
				*goto brunchery

*label brunchery

"At any rate, today will hold many luxuries and surprises for you," Lady Venuma says as she suddenly lowers herself to the ground and turns into another open corridor. "The first of which awaits us in the banquet hall."

As you follow Lady Venuma around the corner, you immediately see what she means. You thought you might have already experienced the best of Lady Venuma's villa wing, but it turns out you haven't seen anything yet.

*page_break

The banquet hall, as Lady Venuma calls it, sits on a stone ledge extended over the castle cliffside, covered by an awning overgrown with flower vines. The ledge, which is surrounded by a serene infinity pool, also holds a golden table laid with every kind of food you can imagine—and some you never even thought to imagine.

As you approach the table, you find that you are actually more interested in its occupants than the spread or the incredible views. At the end of the table Imperva sits bolt straight, with her sword arm drawn behind her back and a plate of assorted meats piled in front of her.

"You have already met Imperva in the Trials," Lady Venuma says as you approach. You move to greet Imperva, but all you feel from her is an ambient burst of 
*if lvfinalromance
	jealousy, sour and sharp.
	*if concubineclue
		This resonates with the feeling you received from Imperva during the Trial earlier and only serves as further proof she may be involved with Lady Venuma too. As your own wave of jealousy mounts, you decide you must get to the bottom of this during brunch.
		*goto focusambiet
	*else
		You wonder why she would be jealous…unless she is also involved with Lady Venuma too, somehow?
		*goto focusambiet
*else
	impatience, pulsing and suffocating—it doesn't seem like Imperva is necessarily a fan of fancy brunches.
	*if (rlshp_imperva > 50)
		Still, she nods at you and gives you some kind of salutation gesture, one you can ambiently sense is an offering of respect to a fellow warrior.
	*if (rlshp_imperva <= 50)
		Or of you, since you can ambiently sense that she doesn't deem your presence worthy of a warrior's welcome, given your Trial performance.
	*goto focusambiet

*label focusambiet

You'd pay far more attention to Imperva's ambient emotion if it weren't for the woman sitting across from her—though you're not sure you'd even call her that.
*if (winjoin) or (doubleagent)
	She looks more like a branch than a woman, with a long flat torso and even longer limbs. There's something incredibly delicate and dignified about her, but also flexible—she appears to have a body somewhat like taffy stretched across a board. Her skin is an iridescent sea-green and she has blunt-banged, pin-straight seafoam hair down to her waist. Perhaps most fascinating of all, her long face is covered with slate-blue pearls, studding her features in intricate patterns.
	*goto metheralready
*else
	She looks more like a puff than a woman, with a round, soft body and stubby limbs. There's something incredibly soft and adorable about her, but also strong—she appears to have a body somewhat like an overripe watermelon. Her skin is an iridescent sea-green, and she has a mop of curly seafoam hair down to her shoulders. Perhaps most fascinating of all, her round face is covered with slate-blue pearls, studding her features in intricate patterns.
	*goto metheralready

*label metheralready
*page_break
*set meetmamana true

"Allow me to introduce you to MamaNa," Lady Venuma says, striding toward the shimmering, sea-colored woman-shape. "MamaNa is a founding member of The Elite Courte and remains Queen Ashe's most trusted advisor."

MamaNa stands and bows deeply as you approach, a difficult act for her body to achieve. "It is an absolute pleasure to make your acquaintance, ${name} Thomil," MamaNa says, sending you a bright wave of ambient joy and respect.

As Lady Venuma sits at the head of the table, you take your own seat beside MamaNa, who you notice has selected a plate of rainbow chard and marmalade. Your stomach rumbles as you look at your own empty plate—the exertion of the first Trial has left you ravenous. 

"Please, indulge in the bounty my Aye Ayechef has prepared," Lady Venuma says, clearly picking up on your hunger. "You have earned it after your performance this morning."

*if extraworning
	"I don't mean to sound like a broken record," Rosae quietly chirps in your ear as you settle in. "So this will be my last reminder to focus on building
	*if energyapprentice
		Strength or Command, with a hearty meal or fine delicacies."
		*goto foodchotime
	*elseif strengthapprentice
		Energy or Command, with exotic foods or fine delicacies."
		*goto foodchotime
	*else
		Energy or Strength, with exotic foods or a hearty meal."
		*goto foodchotime

*label foodchotime

Eying the beautiful spread, what do you choose to eat?

*choice
	#A combination of fine food that demonstrates a refined palate, including royal delicacies like spacefish caviar and Wone truffles.
		*set calculating %+5
		*set command +12
		*goto oncefull
	#I can't pass up the opportunity to eat many of the hearty Priscan homestyle dishes prepared in my honor, even though they include rather messy items served family style.
		*set calculating %-5
		*set strength +12
		*goto oncefull
	#I want to eat exotic foods that I've never tried before, like vibrating ectoplasm and luminescent shelling.
		*set security %-5
		*set energy +12
		*goto oncefull
	#I will only eat what is served to me, which is currently a side salad of nimble lettuce.
		*set security %+5
		*set agile +12
		*goto oncefull

*label oncefull

Once you begin filling your stomach, you turn your attention to the next-most-pressing matter: why has Lady Venuma chosen Imperva and MamaNa to join your private victory brunch, out of all the Elites?
*if concubineclue
	You figure Imperva must be here because of her potential romantic connection to Lady Venuma—though if that's true, bringing you two together wouldn't necessarily be the smartest move on Lady Venuma's part. 

	Unless Imperva is also secretly a member of the coup, which would stand to reason if she is indeed involved with Lady Venuma. And if that's the case, then could MamaNa be a member of this coup as well?
	*goto newret 
*elseif impervacoupclue
	You figure Imperva must be here as a secret member of the coup, given what you sensed during the Trial earlier. If that's the case, then could MamaNa be a member of the coup as well?
	*goto newret
*else
	Could either or both of them be secret members of Lady Venuma's Coup? 
	*goto newret

*label newret
Or is MamaNa's presence here simply mandated, as she is Queen Ashe's "most trusted advisor?"

"What a divine food selection," MamaNa says, noting your plate. "Almost as divine as that ${mirrorshape} mirror patch of yours. It is rather darling, isn't it? You simply must tell me all about it."

"Well, everyone on my home planet has them," you answer between bites. "But every Priscan mirror tattoo is uniquely customized, shaped to mean something personal."

"How positively fascinating!" MamaNa coos between bites of her own rainbow chard. "We are ever so excited to get to know you better, but also for you to get to know us better. I ask about your patch because it reminds me of my own body pearls, which my people arrange aesthetically for personal expression. And much like your mirror patch, my pearls serve a purpose as well. Would you like to know what?"

You look over at MamaNa, wondering why she is asking when you know she's obviously going to tell you anyway. Still, you nod as you continue chewing.

*page_break

"My pearls aren't merely decorative; they actually block any and all potential surveillance frequencies," MamaNa explains. "You mustn't fret, though: there isn't any actual surveillance to be had in this Castle, or on Versus at all, for that matter—such undisclosed eavesdropping is expressly forbidden. Still, I wanted you to know without a doubt that we four speak here in complete confidence. That will prove important for the next part of our conversation."

MamaNa is clearly gearing up to speak about something controversial, so you glance at Lady Venuma—but she just keeps her eyes settled silently on MamaNa. For whatever reason, it seems MamaNa will be the one leading this brunch, which is a…different experience, when it comes to Lady Venuma.

"So, my dearest one, you must be wondering why Lady Venuma has invited Imperva and me here to join you today," MamaNa asks, not giving you an actual opportunity to respond. "On the surface, to our fellow distinguished Elite, this gathering is rather innocuous. Imperva and Lady Venuma are known to be close friends, and I am Queen Ashe's most trusted advisor, expected to report faithfully back to her.

"However, as usual, underneath the surface is entirely another matter," MamaNa says, a smile spreading across her bright lips. "We three are the core of the coup, which is now been formally named The Versus Subversive Front. And we have gathered here today to earn your trust and extend an earnest invitation to The VS Front."

*page_break

You nearly drop your cutlery hearing this, taken aback by MamaNa's directness—especially given the usual need for subtlety and subterfuge you've experienced on Versus so far. You're not sure if you find it refreshing or intimidating, yet.

"We know you are already aware of The VS Front
*if todrickdie
	from your interactions with Lady Venuma and Breeze, and perhaps even some of our other Ord recruits. Regardless, we'd like to take this opportunity to start fresh. Here at this table, we are able to be unusually frank with you.
*if breezedie
	despite the…unpleasantness with Breeze, but we'd like to take this opportunity to start fresh.
We want you to join us, so we desire to show that we are open books to you. What might you want to know about us?"

As MamaNa finishes her speech, all you can think is:
*if (coupbond) or (coupspy)
	[i]this is perfect.[/i] You're being pulled into the inner circle of the coup—or rather, The VS Front. 
*if doubleagent
	[i]this is perfect.[/i] You're being pulled into the inner circle of the coup—or rather, The VS Front. Which you hope will only further your appeal as a potential Elite double agent.
*if winjoin
	this makes you uncomfortable, since it isn't your intention to join the coup—or rather, The VS Front. Still, you can't leave or argue just yet, since you don't know how close MamaNa really is to Queen Ashe. For all you know, perhaps MamaNa still remains loyal to the true Queen and is acting as a spy for her here. Your best bet is to play it as nice and straightforward as possible until you can be sure.
*if eliteinfo
	you're not sure you're interested in joining the coup—or rather, The VS Front. You still hope to remain disengaged from the politics here, at least until you know more about The Elite Courte.
*comment endif

Looking back at MamaNa, you know that no matter what, this is an opportunity to learn some crucial information. Taking advantage of the opportunity, you decide to:

*label brunchlearnchoos
*choice
	#Learn about the setup of the first Trial, hoping I might learn what kind of ability profile to full absorb for the remaining Trials.
		*set weapons %-15
		*label thetrialleabu
		*achieve brunchlearnfirsttrial
		*comment Zach Internal Note: brunchords = false means reader selected this option

		"I can cover this topic," Lady Venuma says after you ask your question, though she proceeds only after receiving a gracious nod from MamaNa. "Each Wone Elite here on Versus is charged with organizing one of the three Trials. Queen Ashe made me responsible for the first Trial, which was meant to be a test of combat ability, both physically and strategically. Beyond these mandates, Queen Ashe left the particulars of the first Trial up to my personal discretion."

		You nod at Lady Venuma, processing the knowledge that there are more Elite Wone deities present on Versus—at least one more, it seems.

		"While we're being honest," Lady Venuma says, a devilish smile creeping its way across her face, "it would seem our dear Baron Airon was correct in crying foul, for I was sure to devise the Trial to cause him in particular to fail. It was no accident choosing the three Delegates as I did. For example, Imperva here was selected because I knew she would be sure to follow my command to guarantee Baron Airon's failure. 

		"I also knew Imperva's efforts would be more than enough to keep Baron Airon from excelling, but to be doubly sure, I cast Lockdown next, knowing of the profound hate that runs deeply between Blarfngardian Warlocks and Sallytrans. Casting Cadet Gadget as a third choice was obvious, for he follows his compatriot Lockdown around like a lost puppy."

		*page_break

		"Now I'm sure you must be wondering: Why did I want Baron Airon to lose this first Trial?" Lady Venuma poses rhetorically. "I already know that our fair Pinkuju will remain loyal to The VS Front, for she has formed a close bond with The Unpronounceable One who, for all his considerable shortcomings, has still stood resolutely against The Elite Courte from his first day on Versus. I also know that sweet, simple Groggy, the most pliable of the Entrants, will do anything for the one who frees it from Baron Airon's tyranny—and that person so far has been me. 

		"Whereas Baron Airon, who can't help his obsession with royalty and luxury, would most likely to be increasingly tempted to join The Elite Courte the longer he remains at this fine Castle," Lady Venuma explains. "However, if Baron Airon were to be unceremoniously eliminated from The Elite Trials first, especially in place of a Groggian slave, his soaring hatred of The Elite would know no bounds.

		"And of course, once I use my Ambassador access later today to 'inform' Baron Airon that it was Queen Ashe who ordered me to stack the odds against him, and I offer him a place of prominence in our resistance, Baron Airon's ego will make him ours entirely," Lady Venuma finishes, looking rather pleased with herself.

		You listen to Lady Venuma's words and realize this is an entirely sound plan, assuming Baron Airon believes Lady Venuma's lie about Queen Ashe. And since Lady Venuma is the only Elite capable of direct contact with the Ords, why would Baron Airon ever have a reason not to? This plan is rather cunning and devious…and makes you wonder where you fall on Lady Venuma's life-sized chess board.

		"Clearly, we need the Entrant who wins The Elite Trials to be one of our own. We cannot afford to add another number to Queen Ashe's loyal ranks, given how slim our majority margins remain," Lady Venuma says, now turning her shining eyes directly on you. "Which means, of course, that shows of loyalty will remain crucial in determining the outcomes of the Trials yet to come."

		*page_break

		Unlike MamaNa, Lady Venuma prefers her meaning to be delivered in veiled niceties, but her message is still clear: if Lady Venuma doesn't believe you to be loyal to The VS Front, she'll ensure that you lose the Trials in any way she can.

		*if (coupbond) or (coupspy)
			"Then I guess it's a good thing I am loyal to The VS Front," you say, resolute in your honest devotion. "That was an incredibly smart play with Baron Airon; thank you for trusting me with this information."

			"You are most welcome," Lady Venuma says, smiling at you while raising her goblet. "And most deserving."
			*goto infover
		*elseif doubleagent
			"Then I guess it's a good thing I am loyal to The VS Front," you say, clearly getting very good at this double-agent game. "That was an incredibly smart play with Baron Airon; thank you for trusting me with this information."

			You wish you could just say what you really think of The VS Front, but you know that would get you nowhere at this particular moment. But you do think to yourself: whether she is threatening you or not, Lady Venuma is potentially making herself vulnerable by telling you this information, especially if you decide to use this against her. Then again, that's assuming you'd even be able to use the information—would Baron Airon or anyone else believe you if you told them this truth, since it would be your word against Lady Venuma's? 

			Regardless, you're sure that possessing this information will certainly help you in your quest to become Elite, one way or another.

			"You are most welcome," Lady Venuma says, smiling at you while raising her goblet. "And most deserving."
			*goto infover
		*elseif winjoin
			"Thank you for trusting me with this information," you say, not wanting to indicate any loyalty to The VS Front, but also not wanting to indicate any clear disloyalty. You wish you could just say what you really think of The VS Front, but you know that would get you nowhere at this particular moment. Instead, you know that this version of the truth is much more preferable.

			But you do think to yourself: whether she is threatening you or not, Lady Venuma is potentially making herself vulnerable by telling you this information, especially if you decide to use this against her. Then again, that's assuming you'd even be able to use the information—would Baron Airon or anyone else believe you if you told them this truth, since it would be your word against Lady Venuma's? 

			Regardless, you're sure that possessing this information will certainly help you in your quest to become Elite, one way or another.

			"You are most welcome," Lady Venuma says, smiling at you while raising her goblet. "And most deserving. Or at least, I hope you prove to be."
			*goto infover
		*else
			"That was a smart play with Baron Airon; thank you for trusting me with this information," you say, not wanting to indicate any loyalty to The VS Front, but also not wanting to indicate any clear disloyalty. 

			If you do decide to pick a side, possessing this information as a member of the inner circle of The VS Front could be as useful as having it as a tool to use against The VS Front to bring them down later—assuming you ever intend to make such a political move. So far, you've been just fine rising above the fray and staying as uninvolved as possible.

			"You are most welcome," Lady Venuma says, smiling at you while raising her goblet. "And most deserving. Or at least, I hope you prove to be."
			*goto infover
	#Learn about the setup of the first Trial, hoping I might find out how to best equip myself for the Trials to come.
		*set weapons %+15
		*goto thetrialleabu
	#Learn the status of the other Ord members officially in The VS Front because I miss them already, being away from them in The Elite Castle.
		*set calculating %-15
		*goto learnordsbru
	#Learn the status of the other Ord members officially in The VS Front—and maybe even the identity of any other secret members currently embedded within the Elite.
		*set calculating %+15
		*label learnordsbru
		*set brunchords true
		*achieve brunchlearnordcoup

		"I can cover this topic," Lady Venuma says after you ask your question, though she proceeds only after receiving a gracious nod from MamaNa. "I'd be happy to tell you how our fine Front began to form. Last cycle, after Breeze's…scandal, shall we call it, I was able to convince Queen Ashe of the need for an Elite Ambassador to soothe relations with the Ords."

		You listen, hoping Lady Venuma might elaborate on whatever Breeze's scandal might be, but she just moves on quickly.

		"Of course, Queen Ashe, in her infinite wisdom, assumed I might have intentions to inflame these relations, but our dear MamaNa convinced Queen Ashe that giving me a small realm to rule would keep any lofty ambitions at bay—not to mention that I could never possibly have the numbers to truly rise against The Elite Courte with the often-rapid Ord casualties in the Versus Matches and the bedrock of Elite support Queen Ashe has, present company included," Lady Venuma nearly cackles, the pleasure in her voice unhidden.

		"Anyway, my first act as Ord Ambassador was to recruit Breeze to our cause, which was quite easy given ${brehis} imposed isolation. I thought Todrick would also fall in line easily, but I found his loyalty to the Wone begins and ends with Queen Ashe, his Blarfngardian goddess of choice. And we all know what ended up happening with those two, don't we, ${name}?"

		Indeed you do, given how the first Versus Vote and Match went and your role in affecting both. Still, knowing this backstory makes Lady Venuma's political maneuvering to save Breeze a bit more clear, you suppose.

		*page_break		

		"On the first three days after your arrival, I was able to meet with quite a few of the Ords as part of my duties as Ord Ambassador," Lady Venuma continues. "Baron Airon and his subservient Grog were relatively easy to recruit, given Baron Airon's born-and-bred desire for superiority. 

		"The Unpronounceable One, for all his considerable shortcomings, has stood resolutely against The Elite Courte from his first day here on Versus and was also easy to recruit. It turns out he had already formed a close bond with Pinkuju, who seemed quite prone naturally to the idea of rebellion anyway. Of course you know this already, in part, since these four were all at our first gathering, Breeze's farewell party."

		You also know that Lady Venuma made attempts to recruit you those first three days as well—though only you know whether these attempts have proven successful, thus far.

		"On the fourth day of this new cycle, while you were here in the Castle Entrant sequester, I was also able to meet with OtherBoard in her UniForest home, as well as Cel and Trig in their hidden camp. Obviously Cel and Trig were eager to join anything resembling a rebellion, while OtherBoard was quite roused by the call for a movement to establish equality. I fear it will prove rather difficult getting these three to work together in the future, but they have all been recruited nonetheless."

		*page_break

		You're not surprised to hear any of this, given your own experiences with OtherBoard, Cel, and Trig. By your count, Lady Venuma has just covered all of the current Ords, excluding Empress Vaccus and the mysterious eleventh Ord still unaccounted for. So you do some quick mental math: there are currently twelve Elites, three of whom are the secret VS Front members sitting before you. That means the Elite still have nine votes, assuming Lady Venuma doesn't have any more traitors secretly stowed on her side. 

		The VS Front needs nine votes for a chance to tie or ten votes to take the majority…so it would seem that, even without you, Lady Venuma has recruited enough members to make that majority happen. Of course, this is assuming that everyone she has enlisted is actually as loyal to The VS Front as they say they are.
	
		*if (coupbond) or (coupspy)
			"Then I guess it's a good thing I am loyal to The VS Front," you say, resolute in your honest devotion—and hoping everyone else claiming loyalty is as well. "Thank you for trusting me with this information."

			"You are most welcome," Lady Venuma says, smiling at you while raising her goblet. "And most deserving."
			*goto infover
		*elseif doubleagent
			"Then I guess it's a good thing I am loyal to The VS Front. Thank you for trusting me with this information," you say, clearly getting very good at this double agent game—and hoping, given these numbers, that you aren't the only one.

			You wish you could just say what you really think of The VS Front, but you know that would get you nowhere at this particular moment. But you do think to yourself: Lady Venuma is potentially making herself rather vulnerable by telling you this information, especially if you decide to use it against her. Then again, that's assuming you'd even be able to use the information, since it would be your word against Lady Venuma's…. 

			And then you think: has Lady Venuma told you this information because she trusts you, or because she knows there's nothing you can do to stop her? Or is it possible she is potentially inflating her numbers, or trying to intimidate you to join? Does it change how you feel at all about your goal? You figure you'll have to decide sooner than later, though not right here, and certainly not vocally.

			"You are most welcome," Lady Venuma says, smiling at you while raising her goblet. "And most deserving."
			*goto infover
		*elseif winjoin
			"Thank you for trusting me with this information," you say, wishing you could say what you really think of The VS Front, but you know that would get you nowhere at this particular moment. This version of the truth is much more preferable, for now.

			But you do think to yourself: Lady Venuma is potentially making herself vulnerable by telling you this information, especially if you decide to use it against her. Then again, that's assuming you'd even be able to use the information, since it would be your word against Lady Venuma's…. 

			And then you think: has Lady Venuma told you this information because she trusts you, or because she knows there's nothing you can do to stop her?  Or is it possible she is potentially inflating her numbers, or trying to intimidate you to join? Does it change how you feel at all about your goal? You figure you'll have to decide sooner than later, though not right here, and certainly not vocally.

			"You are most welcome," Lady Venuma says, smiling at you while raising her goblet. "And most deserving. Or at least, I hope you prove to be."
			*goto infover
		*else
			"That was a smart play with Baron Airon; thank you for trusting me with this information," you say, not wanting to indicate any loyalty to The VS Front, but also not wanting to indicate any clear disloyalty. 

			If you do decide to pick a side, possessing this information as a member of the inner circle of The VS Front could be useful. Or it could be equally useful having it as a tool to to use against The VS Front to bring them down later—assuming you ever intend to make such a political move. So far, you've been just fine rising above the fray and staying as uninvolved as possible.

			"You are most welcome," Lady Venuma says, smiling at you while raising her goblet. "And most deserving. Or at least, I hope you prove to be so."
			*goto infover

*label infover
*page_break

These three ladies who lunch are certainly trusting you with a lot of information—you hope that's a good thing, but you can't help but worry about the potential strings attached…or the hidden price to pay for their generosity. 

As you consider this, it suddenly occurs to you to ask a question that seemed potentially off-limits in the days before. "Lady Venuma, I have to ask," you begin, "why do you want to overthrow The Elite Courte in the first place?"

Lady Venuma matches your gaze, her eyes crackling with golden intensity. She does not hesitate to answer your question.

"There is rather a straightforward explanation," Lady Venuma responds. "My entire life, I have always played on the side of the underdog. Though truly, I believe The Elite Courte must fall because opposing it is simply the right thing to do."

Staring back at Lady Venuma, you nod and guard your own reaction closely from her probing intuition—because only you know whether Lady Venuma's explanation proves satisfactory or faulty by your standards.

*page_break

As the conversation finally reaches a lull, along with your thoughts, you look down to find that you've already eaten the majority of your food already.

"I am quite pleased you enjoyed your food so much, ${name}," Lady Venuma says, eying your empty plate with amusement. 

The plate almost shatters, however, as Imperva suddenly slams three of her fists down on the table and jumps to her feet. Before she storms away from the table, you swear you hear the words "boring" and "useless" muttered in her guttural voice. 

*page_break

As Imperva stomps toward the interior of the villa wing, Lady Venuma rises to her feet. "I must apologize for Imperva's rudeness, but I am afraid table manners are not precisely prized where she is from. Nonetheless, we have two more Entrant victory brunches to host, and her presence, however temperamental, is required. Will you both please excuse me?"

"Of course, my lady," MamaNa says, rising to her feet to answer for the both of you.

"My thanks, MamaNa," Lady Venuma returns. "Might you be so kind as to escort ${name} back to ${youhis} quarters? I will be sure to visit later myself, to conclude our affairs."

*choice
	#"I can escort myself, thank you," I say, quite tired of being spoken for.
		*set outspoken %+10
		*set rlshp_venuma %-5

		"Naturally," MamaNa says, speaking up before Lady Venuma can respond. "Nonetheless, might you escort me instead, ${name} Thomil? I'd rather enjoy the company."

		"Sure," you answer, giving Lady Venuma the excuse she needs to turn on her heels.
		*goto lvglides
	#"I look forward to it, Lady Venuma," I say.
		*set outspoken %+10
		*set rlshp_venuma %+5

		Lady Venuma gives you a knowing nod before turning on her heels.
		*goto lvglides
	#"Perhaps MamaNa can tell me about Imperva on our way, so that I might understand her reaction," I say.
		*set outspoken %-10
		*set rlshp_venuma %+5

		Lady Venuma gives you both a knowing nod before turning on her heels. As Lady Venuma glides after Imperva, you turn to MamaNa.

		"You mustn't judge Imperva too harshly," MamaNa begins. "I'm afraid that not only is she unaccustomed to the particulars of diplomacy, but the very idea of The VS Front is difficult for her to swallow.

		"You see, Imperva is a warrior woman from Versarione, a planet that idolizes Versus as the ultimate call of worthiness. As such, Versarione's entire culture revolves around constantly training in survival death games in order to be prepared should the call for Selection ever come. Being called to Versus for Imperva is the ultimate blessing, but also the ultimate responsibility. 

		"As if that weight weren't great enough, Imperva comes from a rather royal family—a family that owes its royalty entirely to the eldest daughter, Withstandia. She was Selected for Versus and returned Reborn a few years ago, after serving as an original member of Queen Ashe's Elite Courte," MamamNa sighs, finally taking a breath. "Lovely girl, that Withstandia, but Imperva has grown up rather in the shadow of her older sister's legend, never expecting to be Selected herself."

		*page_break

		"So when she was Selected, Imperva's sole mission was to join The Elite Courte and remain fiercely loyal to Queen Ashe, since Versarione also worships the Wone as creation gods. Imperva succeeded in those goals rather quickly, given her sister's legacy," MamaNa continues.

		"But all that began to change when Imperva met Lady Venuma, who slowly convinced Imperva that she must begin to forge her own path independent of her sister if she is ever to earn the same kind of respect. And who better for Imperva to forge that path behind than a bold new Wone goddess, one who embraces the new way of things, as opposed to the old Enlightened Wone order? But I'm afraid we don't have time to cover the infamous Wone FourPath Splinter at this particular moment."

		"You must understand that a life of endless combat is all Imperva wants and knows. She thrives on competition and glory, so fancy brunches aren't exactly her forte," MamaNa concludes. "Being on Versus is every one of Imperva's lifelong dreams come true, so how could she not take it too seriously? The girl might have a one-track mind, but what she lacks in patience and calmness, she makes up for in unparalleled loyalty. She will serve The VS Front well, now that her loyalty lies with Lady Venuma. What's more, Queen Ashe will never see Imperva's betrayal coming."

		*page_break
		*goto commimperva

*label lvglides

As Lady Venuma glides after Imperva, you turn to MamaNa, who rather expectedly has something to say on the matter of Imperva's exit. "You mustn't judge Imperva too harshly. I'm afraid she is rather unaccustomed to the particulars of diplomacy, given her upbringing.

*label commimperva
"While Imperva has committed herself to The VS Front, she a still is having rather a hard time with the guilt of this betrayal, it seems," MamaNa sighs. "But I'm certain Lady Venuma has it handled—to say she has a special way with Imperva would be an understatement. Now, let us be off; I have a rather scenic route planned for us."

As MamaNa makes her own way away from the table, you still feel a bit unnerved by her honesty—and you can't help but wonder what further honesty MamaNa might have in store for you, now that you will have some moments alone.

Feeling a bit sleepy from the brunch you just inhaled, you force yourself to stay as awake and alert as possible, because you know that you have quite the afternoon ahead of you.

*page_break Under The Surface

It turns out MamaNa's scenic route includes a tour of her favorite place in the Castle, the underground aquarium. The iridescent halls match the tone of MamaNa's skin, and it seems as if she belongs here amidst the cool blue tanks. 

You suppose there isn't much exotic alien wildlife to be found on Versus, given the Selection process, but the aquarium still holds all kinds of aquatic wildlife indigenous to the Versus ecosystem. Most of the underground windows face into the Love Lake, exposing its murky depths with tracks of outward-facing lights. 

You have to admit, though, your attention has been more occupied by the bright lava tanks on the opposite side of the hall, where magma creatures from the Volcano Rapids are held. So far you've seen a scaly, lizard-like creature with a stone beak and, rather impossibly, a school of icefish slicing their way through the thick magma like daggers. You have to wonder: Who spends their time on Versus catching these creatures? Or is that task simply left to a team of dedicated Aye Ayezookeepers, the silent custodians of Versus? 

*page_break

Refocusing your attention, you now walk beside MamaNa, who you are surprised to find has somehow shifted her shape to seem more humanoid and readjusted her stature to match your height. Her skin has turned almost scaly, and pale green, while a new pearl configuration studs her face—at least, you think the pearls are arranged differently, from what little you can see underneath the massively oversized sunglasses MamaNa now wears. This seems a strange accessory choice for these dark blue halls, but that's clearly not the first question you have lined up for MamaNa, given her transformation.

"Apologies, I forget how my transitions can be unexpected at first," MamaNa says, no doubt catching the look of surprise on your face. "I come from a planet where our physiology has evolved to become adaptable to different environments. I can control the transitions if I want, but mostly it's an automatic process."

Hearing this, you have to wonder if this is an ability you'd like to absorb—would shape-shifting be exciting and different, or would it mess too much with your sense of self? This thought also makes you wonder if you'll have much of a choice in the matter, given that your potential options for full absorbs today seem to be shrinking, with the victory brunch cut unexpectedly short.

*page_break

"Our adaptable physiology is only one part of my people's culture," MamaNa continues, turning her attention to a deep red storm cloud floating through the Love Lake, one that shoots tiny bolts of orange lightning despite being submerged. "Where I come from, the entire planet follows one set of governing principles, a philosophy and religion that has ingrained itself into our very biology: self-preservation as our most sacred natural order. My people respect all universal orders as a rule, but the survival of our species is prized above all else. It's a large part of why my physiology adapts to the environment. Oh, I hope you couldn't tell, but I'm several hundred years old."

"I couldn't," you say honestly, trying to process MamaNa's cultural explanation—for it immediately reminds you of Prisca. "My own people have a similar global obsession with sharing and reflection, grown out of our natural absorption abilities. But this has also led to a global doctrine of isolation, to keep our culture from being drowned out by the absorption of foreign entities."

"My people struggle with a similar balance, given our constant adaptations," MamaNa muses. "When you can look like anyone or anything, how do you know who the real you is? I assume the same must apply when absorbing the abilities and memories of others."

MamaNa certainly poses a question Priscans have struggled with for generations: Do you maintain your isolation and therefore your cultural purity, keeping Prisca safe and protected, but potentially risking stagnation by preserving antiquated ways of life? Or do you open your borders and join the galactic community to continue evolving and learning, but potentially at the cost of cultural dilution and the loss of a distinctly Priscan identity?

*choice
	#"That's precisely why I support the Reflectionist doctrine and the Purity Laws preserving Priscan isolation," I say.
		*achieve believethereflection
		*set security %+15
		*set purity %+20

		"In fact, since coming to Versus, I understand that more than ever," you finish, hoping to add further weight to your point.

		"Yes, my people felt much the same way for quite some time," MamaNa says with a sigh. "Until we realized that to run from that ability, to preserve it selfishly, means stagnation and ultimately death. Sometimes the only way to survive is to evolve, to remain open to change."

		*if (purity > 50)
			It seems everything about Versus has been trying to push you to believe what MamaNa is saying, but your faith is not abandoned so easily. If Versus has taught you anything, it's the importance of believing in something and keeping your faith.
			*goto taknk
		*else
			You once thought the same way as MamaNa, but if Versus has taught you anything, it's the importance of believing in something and keeping your faith.
			*goto taknk
	#"It just seems wrong to hide from the rest of the galaxy and to waste our talents when we could be using our gifts to help spread knowledge and culture," I say.
		*achieve againstthereflection
		*set security %-15
		*set purity %-20

		"My eyes have been opened to so much since coming to Versus, yet I still know who I am," you finish, hoping to add further weight to your point.

		"Tell me if you feel the same after a hundred years and a hundred faces, my dear child," MamaNa answers, a sad smile on her face.
	
		While MamaNa may have a point, you can feel below the surface of her words that she'd never dampen her abilities with monotony, not for a moment.
		*if (purity < 25)
			And deep down, you've always felt the same way.
			*goto taknk
		*elseif (purity < 50)
			You used to feel truly conflicted about Prisca's isolation, but after all that has happened on Versus, how can you still believe in that Reflectionist anachronism?
			*goto taknk
		*else 
			You used to feel differently about Prisca's isolation, but after all that has happened on Versus, how can you still believe in that Reflectionist anachronism?
			*goto taknk
	#"I can't be sure that either way is right just yet. I'm still waiting until I see proof of something real before I make up my mind, but likely the answer lies somewhere in the middle," I say.
		*set enlighten %+15
		*goto notsureroute
	#"Versus has taught me to remain open to new ways of thinking. So I'm going to do just that before I pass any judgment on ancient, global traditions," I say.
		*set enlighten %-15
		*if eone
			*set etwo true

		*label notsureroute
		*achieve notsureofthereflection

		"I'd be foolish to believe I have the answers to anything after realizing how big the galaxy is, and how little I truly know of it," you finish.

		"Yes, I understand that," MamaNa says with a sly smile on her face. "But you'd be surprised how sometimes universal truths, however grand, can be found on the smallest, most personal of scales. Don't count yourself out of the running just yet, my child."

		*if (purity = 75)
			*set purity %-10

			You used to feel differently about Prisca's isolation, but after all that has happened on Versus, how can you still believe in that Reflectionist anachronism so blindly?
			*goto taknk
		*elseif (purity = 25)
			*set purity %+10
			You never used to believe in the Priscan Reflectionist tradition, but the further away from home you feel, the more you feel the need to connect to it somehow. You're not sure you believe in it just yet, but you're also not as sure it should be summarily discounted either.
			*goto taknk
		*else
			You've been nothing but conflicted, open, and critical since coming to Versus and you've always thought of that as a good thing. However, could it be time to start believing in something more concretely?
			*goto taknk

*label taknk
*if newreader
	*set growth +10
*if loadedreader
	*set growth +5

*page_break

*if etwo
	*achieve echelontwo

MamaNa pauses to watch as you come across a massive tank full of long, slithering eelwhales who swim away from a fireshark trailing them. A contemplative look settles on MamaNa's face as the blue tank lights up her own iridescent skin.

"Self-preservation, our most basic instinct. See?" MamaNa continues. "I tell you this about my culture so that you might understand what I have to say next, about why I helped establish Queen Ashe's Elite Courte all those cycles ago. When Queen Ashe first proposed establishing order on Versus with her ruling Elite, I believed it a brilliant solution. Not only was it a way to keep myself protected—I'm not any great warrior, if you hadn't noticed—it was also a way to propagate the natural order of the Versus Verses.

"My people also believe that self-preservation is most elegant when it is in consonance with natural order, so we are inclined to have a deep respect for Versus as a universal constant," MamaNa continues. "Queen Ashe's Courte seemed to represent all this: revealing the worthy, separating the strong from the weak, imposing lawful order on the lawless chaos of the Versus voting process. 

"Ever since Queen Ashe chose her first Courte and built this castle with her very own creative essence, I have served her loyally. My people do not worship the Wone, but we do respect power—and we are drawn to it. Here was a literal goddess Queen, one who built a castle with her mind, who sought to rule this system of preservation with strength and order, asking me to help enhance all that she believed was noble about Versus. How could I possibly say no?"

MamaNa finally takes a breath after posing this question—and that's when you realize she doesn't seem to need to breathe for long stretches of time, which clearly contributes to her ability to speak at such great lengths without pause.

*page_break

"For five cycles I have served Queen Ashe, becoming her eyes and ears. Goddess Queens have many talents, but grasping the social nuances of mortals is not among them. Thus I became Queen Ashe's shadow. Where she went, so did I, covering the darkness where her light does not shine. I am not too humble to say that I have saved Queen Ashe's Courte from ruin more than once, and Queen Ashe knows this to be true."

You wonder why MamaNa is telling you all this, but just like before, you know it must be leading to something important—or at least, something MamaNa feels is important. You figure you had better hear her out and learn all you can before saying anything too revealing, yourself.

"But then a strange thing started happening. I thought for sure I'd be Reborn for my service, just as surely as Queen Ashe would someday be Reborn herself. But here we still remained on Versus, while more and more of the surviving Ords were Reborn instead of the so-called great Elites. I started to wonder: Could we be missing the point somehow? I began to study those who were Reborn, to examine what these honored few had in common. They had all persevered, of course, not succumbing to the Versus Matches. But that wasn't it; there was a more important key: they weren't just surviving; they were thriving. Each and every Reborn Versian seemed different in some way, forever changed from when they had arrived.

"Queen Ashe and I had stayed the course, had both doubled down on who we were and what we believed, on what we thought made us worthy of Selection in the first place. And many Elite Versians had followed in our footsteps, becoming some of Queen Ashe's most loyal agents. However, a fatal flaw emerged that I could not ignore: if the system Queen Ashe imposed, the one I helped put into place, hadn't led us to being Reborn, it must not remain consistent with the natural order of Versus. 

"And if that were true, The Elite Courte must not be a path to true self-preservation, in the larger scheme."

*page_break

"And so you've now decided The Elite Courte must fall?" you say, putting together the pieces MamaNa has laid out before you.

"Smart cookie," MamaNa says. "You must also be wondering why I am telling you all this, but the answer is always the same: self-preservation. Of course, Lady Venuma has told me all about her experiences with you, Breeze, and Todrick," MamaNa says. "I believe you acted most admirably, though I have to say, I almost expected you to step in in ${deathone}'s place and volunteer yourself."

You consider these words, which strike you as odd—and also strike a nerve. As MamaNa lapses into her very first silence, you realize she expects you to have an opinion on this matter. And you certainly do.

*choice 
	#"I have much to accomplish for the people of my home planet while on Versus. If I were to sacrifice myself, I would be sacrificing all of them, too."
		You know your Dhanthik search is far too important to jeopardize by volunteering yourself in the line of fire in such a blatant way. You are here on Versus for a purpose: to find Dhanthik, defeat Empress Vaccus, and save Prisca. That must remain your priority, no matter what.

		MamaNa takes in your words,
		*if (calculating < 40) or (security > 50)
			*set mastery +2
			*set growth +5
			seeming to accept them.
			*goto mncallzout
		*else
			seeming to doubt them somehow.
			*goto mncallzout
	#"After all of your talk of self-preservation, you must know that no one in their right mind would do something like that."
		Volunteering nobly may be a nice ideal to ponder, but it has nothing to do with the pragmatic reality of your situation here on Versus—and you bet MamaNa knows that.
		
		MamaNa takes in your words,
		*if (calculating > 60) or (security > 50)
			*set mastery +2
			*set growth +5
			seeming to accept them.
			*goto mncallzout
		*else
			seeming to doubt them somehow.
			*goto mncallzout
	#"I wish I could have volunteered myself. My time here only matters if I make it matter."
		You wish that had been an option available to you at the time, but it just wasn't. Besides, you wonder if you'd even be here having this conversation if you had volunteered and faced the unkillable Bominate. Something tells you the answer would be no.
		
		MamaNa takes in your words,
		*if (calculating < 40) or (security <= 50)
			*set mastery +2
			*set growth +5
			seeming to accept them.
			*goto mncallzout
		*else
			seeming to doubt them somehow.
			*goto mncallzout
	#"Honestly, volunteering myself didn't even occur to me."
		You suppose it would have been a noble gesture, but it has nothing to do with the pragmatic reality of your situation here on Versus. Besides, you already know that you wouldn't be here having this conversation if you had volunteered and faced the unkillable Bominate.
		
		MamaNa takes in your words,
		*if (calculating > 60) or (security <= 50)
			*set mastery +2
			*set growth +5
			seeming to accept them.
			*goto mncallzout
		*else
			seeming to doubt them somehow.
			*goto mncallzout
		
*label mncallzout
Then MamaNa eyes you from head to toe, sprouting a peculiar, thin-lipped smile that shifts the slate pearls on her face ever so slightly.

"Always thinking, this one is," MamaNa says. "Really,
*if breezedie
	I know you saved Todrick because you thought it was the right thing to do. Just like I know you
	*goto calledoutmam 
*elseif ruthlessrebellion
	I know you stepped in and convinced Todrick to volunteer in order to show Lady Venuma your support. Just like I know you
	*goto calledoutmam
*else
	You wanted to show Lady Venuma support, or perhaps to keep your options open, so you didn't step in during the Todrick situation. But I know the real reason—it's probably because you
	*goto calledoutmam

*label calledoutmam
*if (winjoin) or (doubleagent)
	*if winjoin
		plan to win The Elite Trials on your own and tell Queen Ashe about our little rebellion so that you can join her esteemed ranks.
	*if doubleagent
		plan to double-cross our little rebellion in the hopes of becoming a good little spy for the almighty Queen Ashe.
	But I'm afraid I'll have something to say about that, for things aren't always exactly what they seem, are they?"

	*page_break

	You freeze where you stand, because you did not expect MamaNa to be so direct. Nor did you expect her to know your true intentions, when not even Lady Venuma herself seems to have been able to. How can MamaNa intuit such things? Or is she just baiting you, calling your bluff to see how you'll react?

	"Don't fret my pet, there's miles left to discuss," MamaNa says. "I understand why you'd want to join The Elite Courte. Queen Ashe's power and influence can seem quite alluring—take it from someone who has fallen under her spell before. I also understand why you wouldn't necessarily trust Lady Venuma, seeing as she can be quite a bully. The great Lady has probably made you feel this choice is binary: in or out, with us or against us. However, I wanted to have this little chat to tell you that it isn't all that simple. The Wone may live permanently in the black and the white and the gold, but the rest of us are often left to occupy the grey. 

	"I'll clue you in on a little secret," MamaNa then says, leaning in to whisper to you, smelling distinctly of metal and brine. "The third and final Trial will be something we call a SoulTest, a rigorous intention-revealing audience with Queen Ashe and only Queen Ashe. All Elite Courte members have been through this test, and let me tell you: if I can read your true intentions this easily, Queen Ashe will be able to do so in a heartbeat. Which is actually rather good news for you, if you choose stay this current Elite course.

	"However, the news would not be quite as good for me, given my own goals. The truth of The VS Front would no doubt be revealed in your Elite ascension, an outcome that Lady Venuma and I both clearly cannot allow. Should you choose to stay this course, you must know that we would do everything in our power to ensure that you fail the second Trial and never get such an audience with Queen Ashe."

	*page_break

	"Now I know what you must be thinking right now, because trust me, I have thought this through quite thoroughly," MamaNa says before you can even process her threat. You may have to take breaths and beats, but MamaNa doesn't seem to suffer the same need, carrying on as calmly as if you're talking about the weather. "Sure, you could cry foul and expose The VS Front before the next Trial, but who would you trust with such information, who could you know to be truly loyal to Queen Ashe and not to us? And even if you could find another Elite who would listen, or perhaps if you simply shouted your knowledge from the rooftops to any and all who would listen, who would believe your word over mine?

	"You, who have attended both of Lady Venuma's clandestine Ord meetings, first at Todrick's cottage and then at Breeze's farewell gathering? Over me, Queen Ashe's most trusted advisor for years, who is also able to use her transformative nature to pass Queen Ashe's rigorous SoulTests on a regular basis? At best, you may be able to take down Lady Venuma with such a bold play, but surely you'd go down on her sinking ship—while I would simply persevere to begin again, as I always do.

	"Yes, I fear you'd find out rather the hard way that I am incredibly well protected. I've had months and months to prepare and insulate myself, to think this through. Self-preservation, see? So you must ask yourself: Do you want someone like me as an enemy, when I could just as easily be your ally?" MamaNa asks, smiling at you as if she has not a care in the world.  "It is not too late to join The VS Front, ${name} Thomil. Besides, you haven't even met Queen Ashe for yourself. Who knows, it might be best to go with the devilish goddess you already know, no?"

	Your mind races and reels with questions and considerations now that MamaNa has finally stopped speaking. Can you really trust MamaNa when she seems so willing to betray Queen Ashe and sell out Lady Venuma? On the other hand, could you afford to not have someone as seemingly adept at deception as MamaNa on your side? She is lobbying you pretty hard, which perhaps means The VS Front truly needs your vote—or that MamaNa is afraid of what damage you could do if left in the Trials.
	*goto statusabsorub
*elseif (coupspy) or (coupbond)
	*if coupspy
		plan to offer to spy on The Elite Courte for our brewing VS Front."
	*if coupbond
		plan to remain loyal to The VS Front through and through."
	*comment endif

	You nod at MamaNa, a bit wary that she seems to be able to intuit your true intentions—then again, you've attempted to make these intentions pretty clear to Lady Venuma, so it makes sense.

	*page_break

	"I am pleased you are loyal to our cause, for The VS Front surely will prevail," MamaNa continues before you can even process her words. You may have to take breaths and beats, but MamaNa doesn't seem to suffer the same need. "Queen Ashe certainly knows that Lady Venuma is vicious, but our Queen doesn't believe that Lady Venuma actually has the means to overthrow the Elite—I have been sure to convince Queen Ashe of that. After all, I'm her most trusted advisor, the one who recommended we placate Lady Venuma with the Ord Ambassador position in the first place so as to keep her occupied with a realm and a duty of her own. Sure, Queen Ashe knew that exposing Lady Venuma to the Ords might be a risk, but who do you think volunteered to keep her ever-watchful eye on our golden demigoddess?

	*label wontseecoming
	"Queen Ashe is many things, but she isn't omniscient and she doesn't believe I would ever betray her," MamaNa almost sighs. "The Queen believes my loyalty runs as deep as my desire for self-preservation. So you can be sure that when The VS Front finally makes our move, Queen Ashe will not see it coming. 

	"All that said, our majority margins are still more dangerously thin than I'd prefer. So The VS Front needs you, ${name} Thomil—not just to vote with us when the time comes, but to rise as the champion of The Elite Trials," MamaNa says, leaning in to whisper to you, smelling of metal and brine. "Which is why I aim to fill you in on a little secret.

	"The third and final Trial will be something we call a SoulTest, a rigorous intention-revealing audience with Queen Ashe and only Queen Ashe. All Elite Courte members have been through it, and let me tell you: if I can read your true intentions this easily, Queen Ashe will be able to in a heartbeat. Which means I must help you train to deceive Queen Ashe, a skill I have honed over the years with my own natural malleability."
	*goto statusabsorub
*else
	hope to avoid engaging in such politics altogether. But I'm afraid I'll have something to say about that, for things aren't always exactly what they seem, are they?"

	You nod at MamaNa, a bit wary she seems to be able to intuit your true intentions—then again, you've made these apolitical intentions fairly clear, so it makes sense. You're more worried what MamaNa might mean about things not being what they seem.

	*page_break

	"You have left your options open; that's an admirable and adept thing," MamaNa says. "However, I do believe you will have to choose a side if you are to survive. And here is why you should join our side, my dear.

	*goto wontseecoming

*label statusabsorub
*page_break
*set meetashe true

"At the heart of it all, I suppose I'm trying to say that you don't have to stay locked into one goal, my mirrored friend," MamaNa continues. "If Versus has taught me anything, it's that we mustn't have tunnel vision, that we must learn to balance being reliable and adaptable, political and loyal. I tell you all this because I believe you must decide your own agenda for yourself—it's the only way you'll actually be of use to either side. 

"When that SoulTest comes, you will have to choose to project your deepest intention, and you will have to be prepared to be convincing down to your very core. I encourage you to explore and practice building these intentions over the coming days, for I can teach you how to remain malleable and, with enough practice, to pass Queen Ashe's SoulTest however you choose, truthfully or otherwise.

"But don't just take my word for it," MamaNa says, suddenly reaching out her greenish and scaly hand to you. "Flash absorb a part of what I know. See how grand your plans can be for yourself."

MamaNa then touches your hand and suddenly a flash absorb begins, one you're not sure you even initiate. You are suddenly flooded with images of an exotic-yet-uniform population, all changing and evolving to the same end. Immediately you feel more fluid, more malleable—like you could do anything you want in the moment and become anything you need to accomplish your goals.

"I'd give you more," MamaNa says, stepping back from you. "But alas, Lady Venuma will have something to say about that, as you shall learn later."

*page_break
*set mamanaopeneyes true
*set mamanaabolish true
*set abolishbothstatus abolishstatus

*if winjoin
	*set winjoinstatus status
*if doubleagent
	*set doubleagentstatus status
*if coupspy
	*set coupspystatus status
*if coupbond
	*set coupbondstatus status
*if eliteinfo
	*set eliteinfostatus status

*if winjoin
	*set coupspystatus +5
	*set doubleagentstatus +5
	*set eliteinfostatus +5
	*comment Zach Internal Note: You've been ideally cozying up to Elite, which is good if you're becoming a Coup spy or want to be a Double Agent for Elite.
*if doubleagent
	*set winjoinstatus +5
	*set coupspystatus +5
	*comment Zach Internal Note: You've been falsely cozying up to Coup while trying to make secret Elite bonds, so it's good if you want to join Elite more straightforwardly or transfer your calculating skills to spying for Coup.
*if coupspy
	*set winjoinstatus +5
	*set doubleagentstatus +5
	*comment Zach Internal Note: You've been falsely cozying up to Elite while trying to make quiet Coup bonds, so it's good if you want to join Coup more straightforwardly or transfer your calculating skills to spying for Elite.
*if coupbond
	*set coupspystatus +5
	*set doubleagentstatus +5
	*comment Zach Internal Note: You've been ideally cozying up to Coup, which is good if you're becoming a Coup spy or want to be a secret Double Agent for Elite.
*if eliteinfo
	*set winjoinstatus +5
	*set coupbondstatus +5
	*comment Zach Internal Note: You've been trying to remain above politics, so you have a better shot at the less political status goals of joining either straightforwardly.

As the flash absorb settles, you can sense with your Tech Apprentice skill that something has changed in your Stats Screen….

Before, you were locked into one political goal, marching toward one inevitable conclusion and hoping to prove yourself worthy enough of that goal—but now MamaNa has shown you a new way. Thanks to MamaNa's ability to transform herself, you can pursue several goals at once to keep your options open if need be. Or you could still stay your original course if you wanted, tracking the progress of one chosen goal and ignoring MamaNa's advice. 

You notice one last option flickering at the bottom of the Status goals progress bars. Secret Abolitionist? What does that mean?

"As you can see, you can operate differently than you have been previously," MamaNa says, interrupting your thoughts. "These Status meters will help you keep track of all of your goals before the SoulTest with Queen Ashe in your third Trial—assuming you make it there, of course. Using these meters, you'll know what goals you can prove to Queen Ashe, by using this little trick my people developed to project an intention earnestly or deceptively. 

"When the time comes, Queen Ashe will read your single chosen intention and deem you worthy or unworthy based on your levels—and you can be sure any level lower than half full will be sure to fail. After all, Queen Ashe will not be reading your mind, but rather your heart—which is far more difficult to conceal. 

"Now that you've been fully enlightened, I'm afraid we must begin our own work."

*page_break

"Know this, ${name} Thomil. Over the next few days, this simmering conflict will come to a boil and one side will prevail. Either The VS Front will fail and The Elite Courte will keep its ruling majority intact for the remainder of this Versus cycle, or The VS Front will indeed succeed and wrestle the majority from the fallen Elite. Now, if this latter outcome were to come to fruition, I invite you to think carefully…

"While Lady Venuma claims to be fighting for justice and equality, I expect that if The VS Front prevails, we shall just see the rise of a new Elite majority, one that simply has a different set of former-Ord members led by Lady Venuma. She claims to prize the underdog, and that may indeed be true, but it is obviously equally true that Lady Venuma seeks power and control for herself, whether she wants to admit this or not.

"I must ask: With all the reasons I have given for wanting The Elite Courte to fall, is that outcome what we want? Or is there some loftier goal to be reached, one that establishes true equality on Versus?"

MamaNa breathes in deeply after posing this last question, finally indicating that the moment for your response has arrived. Whether or not you know what MamaNa is getting at with this last bit of her speech, you do know that however you answer will be the very first test of your new Status goal system….

*page_break

"Oh dear, MamaNa certainly has changed things around in your Stats Screen once again!" Rosae chirps in a tizzy, hoping to warn you before you make this clearly important decision. "With so many changes, I can't advise you properly so quickly, but I can tell you this much: make sure to start building toward the Status goal, or goals, you might want to fulfill in this upcoming SoulTest. Since many of these Status goals can be pursued alongside one another, I have provided a hastily constructed table, one that also lists the desired traits to help achieve each potential goal!"

Before you answer MamaNa, you make sure to access the table of Status goals Rosae has drawn for you in the Stats Screen, which you know will remain there for reference thanks to the permanent Tech Apprentice skill you acquired from OtherBoard. 

Once you have referenced this table, you turn to MamaNa, trying to decide what words will best represent yourself and your potential agenda.

*choice
	#"I want to join The VS Front, because I want to see its oppressed members rise to power," I say, truly meaning it.
		*gosub trial_end
		*set coupbondstatus +15
		*set coupspystatus +10
		*set doubleagentstatus +5
		*set calculating %-15
		
		You don't say this next part out loud to MamaNa, but you know the reason you now feel this way is because:

		*choice
			#I actually think this is a better path to eventual equality—I bet most Ords will want equality too, despite Lady Venuma's probable ambitions to create a new ruling majority.
				*set security %-10
				*goto abolishunlock
			#I think this is just my own best shot at surviving and staying in the majority.
				*set security %+10
				*goto mamanaassuaged
			#I truly want the Elite to fall and the so-called meek to inherit Versus, because I've come to know and love the Ords.
				*set rlshp_ob %+5
				*set rlshp_breeze %+5
				*set rlshp_grog %+5
				*set rlshp_pj %+5
				*set rlshp_airon %+5
				*goto mamanaassuaged
	#"I want to join The VS Front, because I want to see its members rise to power," I say, but I'm lying through my teeth to disarm and placate MamaNa.
		*gosub trial_end
		*set doubleagentstatus +15
		*set winjoinstatus +10
		*set coupspystatus +5
		*set calculating %+15

		You don't say this next part out loud to MamaNa, but you know the reason you now feel this way is because:

		*choice
			#I actually believe in the structure of the Elite system, unlike MamaNa. Plus, I think this is my own best shot at surviving and staying in the majority.
				*set security %+10
				*goto mamanaassuaged
			#I truly want the Elite to stay in power, because I've come to know and love the Elites I've met.
				*set rlshp_oli %+5
				*set rlshp_cadet %+5
				*set rlshp_lockdown %+5
				*set rlshp_imperva %+5
				*goto mamanaassuaged
			#I don't believe in the Elite system, or any majority system for that matter, but I just cannot trust MamaNa or Lady Venuma.
				*set security %-10
				*goto mamanaassuaged
	#"I plan to remain loyal to the Elite no matter what you threaten me with, MamaNa," I say defiantly.
		*gosub trial_end
		*set winjoinstatus +15
		*set doubleagentstatus +15
		*set outspoken %+15
	
		You don't say this next part out loud to MamaNa, but you know the reason you now feel this way is because:

		*choice
			#I actually believe in the structure of the Elite system, unlike MamaNa. Plus, I think this is my own best shot at surviving and staying in the majority.
				*set security %+10
				*goto mamanathreat
			#I truly want the Elite to stay in power, because I've come to know and love the Elites I've met.
				*set rlshp_oli %+5
				*set rlshp_cadet %+5
				*set rlshp_lockdown %+5
				*set rlshp_imperva %+5
				*goto mamanathreat
			#I don't believe in the Elite system, or any majority system for that matter, but I just cannot trust MamaNa or Lady Venuma.
				*set security %-10
				*goto mamanathreat
	#"I will follow your advice to learn as much as I can and keep my options open," I say without formally committing to a side—because I don't think that's actually what MamaNa wants me to do, at least not yet.
		*gosub trial_end
		*set eliteinfostatus +15
		*set coupspystatus +10
		*set doubleagentstatus +5
		*set outspoken %-15

		You don't say this next part out loud to MamaNa, but you know the reason you now feel this way is because:

		*choice
			#I really do still need to gather more information before I make a decision—though I do hope I can avoid choosing sides altogether.
				*set outspoken %-5
				*set enlighten %-5
				*goto mamanaassuaged
			#Truly, I hope I can hold out just long enough to join the winning side once the chips have fallen. Obviously I think remaining a free agent is my best shot at surviving and being Reborn.
				*set security %+10
				*goto mamanaassuaged
			#Actually, if I had my way, I'd abolish both movements and make everyone on Versus equal.
				*set security %-10
				*goto abolishunlock
	#"I trust you more than anyone I've met so far on Versus, MamaNa," I say, feeling there's more MamaNa wants to tell me if she can truly trust me. "I want to work with you no matter what."
		*gosub trial_end
		*set coupspystatus +15
		*set coupbondstatus +10
		*set doubleagentstatus +5
		*set calculating %+15

		You don't say this next part out loud to MamaNa, but you know the reason you now feel this way is because:

		*choice
			#I don't trust Lady Venuma—and I don't think MamaNa actually trusts her either.
				*set rlshp_venuma %-10
				*goto abolishunlock
			#I am genuinely impressed by MamaNa and trust her with my life now. I think sticking with her is my best bet to survive.
				*set security %+10
				*goto abolishunlock
			#Actually, if I had my way, I'd abolish both movements and make everyone on Versus equal.
				*set security %-10
				*goto abolishunlock

*label mamanathreat
*achieve mamaoffyourside
*set rlshp_mamana 28
*set mamanaabolish false

MamaNa is visibly displeased with you, but tries to hold her emotions in check. 

"Well, mirrored one, I hope you can lie in the bed you've begun to make," MamaNa seethes, her voice suddenly growing gritty. "Because I can assure you that you've just made a very powerful enemy."

"So have you," you say, meeting MamaNa's gaze. You certainly won't be intimidated by anyone and you're always going to stand up for what you believe in, no matter what.

However, unlike before, you won't now be judged and evaluated based on just one goal. So despite the line you just drew in the sand, you can still work toward whatever final intention you choose. Still, now you have to do so knowing that MamaNa will be gunning for you behind the scenes. 

*page_break

"You will return to your quarters now," MamaNa states as you finally approach the end of the aquarium hall, clearly still trying to keep her disdain disguised. "Before you return, I have one final item to offer you, seeing as we still seem to have some…trust left to build. As a gesture of my willingness to work with you, I'm going to make Empress Vaccus the target of the next majority Versus Vote instead of 
*if todrickdie
	Breeze.
*if breezedie
	the Elite's intended target.
How does that sound to you, my bold companion?"

Your first thought is that targeting Empress Vaccus must be a move that furthers MamaNa's own agenda somehow—the fact that it pleases you must just be convenient to her, an additional tool she can use to try to win you over. Whether this gesture is genuine or not, it's one you're more than willing to accept if it keeps you safe in this upcoming Vote and puts the target on Empress Vaccus. Besides, it's yet another bit of information you can potentially use as leverage against MamaNa later if need be. This will also serve as a perfect opportunity to see if MamaNa truly possesses the influence she so often claims to. 

So you nod kindly to thank MamaNa for this gesture, but you don't say anything—all that needs to has been said already.
*goto mustfeelhtesame

*label mamanaassuaged
*achieve mamaonyourside
*set rlshp_mamana 72
*set mamanaabolish false

MamaNa smiles at you, revealing a row of perfect white teeth and practically radiating with happiness and acceptance.

"Well, ${name} Thomil, I am pleased to count you as a potential ally," MamaNa says. "Welcome to the right side of Versian history."

You smile back at MamaNa, because it seems you have successfully assuaged her concerns. However, unlike before, you won't be judged and evaluated based on one goal. Now you can work toward whatever final intention you choose, no matter what you just said or did. 

You can also do so with the freedom of knowing that MamaNa trusts you and won't be gunning for you behind the scenes.
*goto backtolyfe

*label abolishunlock
*set abolishbothstatus +15
*set rlshp_mamana 88

MamaNa then eyes you very carefully, as if trying to study your insides. She takes another long, deep breath and takes off her sunglasses, setting her dull jade eyes on you.

"I think I can trust you, ${name} Thomil, and may Evo preserve me if I am wrong," MamaNa sighs. "Which means it's time to let you in on my true endgame. Ultimately, I want there to be no ruling majority on Versus. Instead, I want to return to a system that is open, one that is free and equal and undivided. A system without undue security for anyone and that represents Versus as it is supposed to be: a system that encourages the instinct for self-preservation in us all. As both you and I have already guessed, Lady Venuma doesn't aim to establish such a free system with her coup—she simply wants to replace Queen Ashe as supreme and form her own version of The Elite Courte. 

"Lady Venuma's coup will only flip power structures, but I mean to abolish both. So why then am I working with Lady Venuma, you must ask?" Once again, MamaNa answers the question without pause. "Aligning with Lady Venuma is a necessary first step, for there is no way to oppose Queen Ashe otherwise—the Queen is as powerful as she is beloved among The Elite Courte. To overthrow her rule would require an Ord majority, which is why I was sure to position Lady Venuma as Ord Ambassador: to give her access to the untapped potential of the Ords. And given Lady Venuma's considerable talent at coercion, I'd say she was the perfect woman for the job. Plus, she is also the perfect woman to take the fall should our plans go south, given Queen Ashe's wariness of the unabashedly devious demigoddess.

"Now, if The VS Front does indeed prevail and become the new majority, whereas Queen Ashe was once revered, Lady Venuma will most certainly not be. Once we have used Lady Venuma as a necessary tool to depose Queen Ashe, it will then be much easier for us to depose Lady Venuma in turn and thus create a free system. That is, assuming you also desire such an outcome?"

*page_break
*achieve mamahiddenagenda

You nod at MamaNa, because you're going to take her advice—you're going to leave your options open until you've had time to decide whether you truly agree with her motive and methods.

"Excellent," MamaNa says, taking your nod as a gesture of full acceptance. "Though of course, no one in their wildest dreams, from Queen Ashe to Lady Venuma, would believe you if you were to ever repeat any of my secret plan. As you might expect by now, I've covered my tracks quite carefully. But I suspect there will be no need for such precautions with you."

MamaNa smiles at you, revealing a row of perfect white teeth and practically radiating with happiness and acceptance. "There are many more layers to this plan, but I'm afraid you'll have to do a bit more to prove yourself to learn the particulars. Don't fret, I've put everyone else in my secret little cabal through the same paces. For now, I'm simply thrilled that we see things the same way."

*page_break
*achieve echelonthree
*if etwo
	*set ethree true

You smile back at MamaNa, projecting as much trust and calmness as you can on the surface. However, underneath, your mind races and churns—given that MamaNa has just told you about successfully deceiving her two closest allies, can you really trust her? Could this entire thing be a lie? Or do you really believe you've found MamaNa's true intentions under all of her versions, which means you can trust in working toward the same goal together—assuming this is even a goal you believe in?

You suppose you'll have to keep your eyes and ears open to find out…just like you'll have to decide whether MamaNa's agenda truly coincides with your own, despite your initial inclination to abolish the ruling majorities. 
*if lvfinalromance
	And especially given your connection to Lady Venuma, who would certainly not benefit from this agenda.
Unlike before, though, you won't be judged and evaluated based on just one goal. Now you can work toward whatever final intention you choose, no matter what you've just said or done. 

So as tempting as this pathway might seem, you must remember that it's just another option laid before you—albeit a very secretive and rarefied pathway.
*goto backtolyfe

*label backtolyfe
*page_break

"Well, I must be returning you to your quarters now, lest we rouse undue suspicion," MamaNa says as you finally approach the end of the aquarium hall. "Though before you go, I have something to offer you. As a token of my trust, whatever you decide, I'm going to make Empress Vaccus the target of the next majority Versus Vote instead of 
*if todrickdie
	Breeze.
*if breezedie
	the Elite's next intended target.
*comment endif
How does that sound?"

Your first thought is that MamaNa is obviously trying to win you over, and you have to wonder if this is simply a move that furthers her agenda and conveniently happens to please you at the same time. Whatever the truth may be, this is still a gesture you're more than willing to accept if it keeps you safe in the upcoming vote and puts the target on Empress Vaccus. Plus, this will serve as a perfect opportunity to see if MamaNa truly possesses the influence she so often claims to. 

So you nod kindly to thank MamaNa for this gesture, but you don't say anything—all that needs to has already been said.
*label mustfeelhtesame
Now all that remains to be seen is the truth behind MamaNa's words—as she has so astutely pointed out, MamaNa could really be anything, from a true VS Front loyalist to an embedded Elite spy for Queen Ashe…a thought that is too complicated and loaded for you to unpack at this moment.

MamaNa must feel the same way about the need for more words, for as you exit aquarium hall, she simply says: "I trust you can find your own way from here?" 

You nod once again, knowing that MamaNa means this in more ways than one. 

*page_break Finding Your Way

You enter your own suite feeling thoroughly exhausted, looking forward to a good scrub and a long nap. Just when you thought you had the lay of the Versus land figured out, MamaNa has shaken up the game board entirely. You're going to have to take some time to reorient yourself in this new political landscape, to be sure. 

But you soon realize these things will have to wait as you find Lady Venuma standing on your balcony, her caftan flowing dramatically in the wind. Your first thought is whether Ayeleen let Lady Venuma in or she can just come and go as she pleases, though that thought is eclipsed by a far more important realization: whether you're ready or not, this will be your first opportunity to test your new malleable MamaNa Status goal system, given the fact you know firmly that Lady Venuma stands with The VS Front as their self-appointed leader.

"I trust you had a productive discussion with MamaNa?" Lady Venuma says, turning to face you as you enter. You can already feel her goddess eyes probing through you, trying to intuit your emotions for some clue. Thankfully you're able to project whatever emotion—or lack of emotion—you want, given your Priscan absorb experience.

"It was definitely eye-opening," you say, stepping into the room and knowing that much is absolutely true.

"Well, I hope you are prepared to have your eyes further opened," Lady Venuma answers, now approaching you inside the room. "Because I am here for a reason. I have decided to grant you permission to fully absorb a fraction of my power."

*page_break

It's not lost on you that Lady Venuma doesn't seem interested in whether you actually want to absorb from her or not—but you have to admit, the prospect is immediately tempting. What would it feel like to command the kind of power that Lady Venuma possesses? And what would it be like to MemoryTravel to a world full of gods and goddesses for two whole nights? You wouldn't mind learning the answer to both questions….

Besides, you haven't had the opportunity to full absorb anyone else today, and given the way you keep getting sequestered here in your quarters, this very well may be your last chance to do so before nightfall. You'd hate to waste a night without MemoryTraveling. Plus, having Lady Venuma's power and intuition will no doubt be helpful in the Trials to come—after all, engaging in this full absorb might also offer you insight into the Wone's inner nature and culture that could help you connect to Queen Ashe later on.

Then again, having this power will also connect you inextricably to Lady Venuma, both internally and externally. And Lady Venuma can't be offering this absorb freely—you must ask yourself why she is really doing so. What price might you have to pay in return? 

It seems that, whatever your potential goal may be, there are benefits and drawbacks to engaging in this full absorb.

*page_break

"I can see your wheels—they're spinning," Lady Venuma says, stopping just in front of you like a towering statue of golden beauty. Being this close, you can't help but wonder: What would it be like to walk a mile in her mighty, high-heeled shoes? 

"Tell me, do you know why I offer this absorb?" Lady Venuma asks, posing the very question you've been trying to answer.

*if lvfinalromance
	*goto sexualabsorb

Thinking it over, you know that no matter how innocuous this question may seem, it's a politically loaded one. So your answer should be as well, given your newly updated Status goal matrix.

*choice
	#"So that I may get to know you better, my great Lady."
		*set rlshp_venuma %+15
		*set outspoken %-10
		*set coupbondstatus +15
		*set coupspystatus +10
		*set doubleagentstatus +10
		*set eliteinfostatus +10
	
		"Among other reasons," Lady Venuma says, an intractable look on her golden face.
		*goto lvabsorbing
	#"So that I might have the power and influence to win the Trials and occupy an Elite position, which would benefit The VS Front." 
		*set rlshp_venuma %+15
		*set calculating %+10
		*set coupspystatus +15
		*set doubleagentstatus +10
		*set coupbondstatus +10
		*set abolishbothstatus +5

		"How clever," Lady Venuma says, with just the hint of a smile on her golden face. "Clever will serve you well in this setting."
		*goto lvabsorbing
	*if (breezedie) #"As a gesture of peace, to mend fences and show what your VS Front has to offer."
		*set rlshp_venuma %+10
		*set calculating %-10
		*set abolishbothstatus +15
		*set coupbondstatus +10
		*set eliteinfostatus +10
		*set winjoin status +5

		"How perceptive," Lady Venuma says, with just the hint of a smile on her golden face. "Yes, to forget the past ugliness with Breeze and begin a bright future anew."
		*goto lvabsorbing
	#"So that I might feel indebted to you and appear loyal to you from the outside, I presume."
		*set rlshp_venuma %-5
		*set outspoken %+10
		*set eliteinfostatus +15
		*set doubleagentstatus +15
		*set abolishbothstatus +10
		*set coupspystatus +5

		"How clever," Lady Venuma says, with just the hint of a smile on her golden face. "Let us hope you are not too clever for your own good."
		*goto lvabsorbing
	#"I haven't accepted your offer yet."
		*set rlshp_venuma %-15
		*set outspoken %-10
		*set winjoin status +15
		*set eliteinfostatus +15
		*set doubleagentstatus +10

		"Careful, little lost one," Lady Venuma says, a dangerous light now beginning to glow in her golden eyes. "You would not want to seem ungrateful, especially not to the one who is responsible for placing you in this very position—or the one who is responsible for your continued success here at the Trials."
		*goto lvabsorbing

*label lvabsorbing

You match Lady Venuma's gaze, content in the satisfaction that only you know the true meaning behind your words. Ultimately, it doesn't really matter why Lady Venuma offers this full absorb, given all you have to gain by accepting. No matter what, you're going to use this borrowed power to your advantage, whether your goals align with Lady Venuma's or not.

"Let us not waste any more time then, shall we?" Lady Venuma asks, obviously sensing that you have made up your mind. She steps closer still, ready to begin the absorb process.

*page_break
*goto theabsorbhappens

*label sexualabsorb

However, it becomes immediately clear that Lady Venuma isn't interested in your words as a response. After so long apart, Lady Venuma is interested in something else….

She kisses you fiercely and you kiss her back, allowing your ambient absorb and her goddess intuition to blend into one.
*if (rlshp_mamana = 88)
	Which is fine by you, since you have decided to keep your knowledge of MamaNa's hidden agenda a complete secret until you know whether it's real or not.
*comment endif

You and Lady Venuma are suddenly both naked in the next instant, stripped bare in every way. You can feel Lady Venuma's golden, warm skin against your own, probing, entering, pulsing, combining.

Lady Venuma will have her answer. Now.

*choice
	#"I am yours, Lady Venuma, and you are mine," I say.
		*set rlshp_venuma %+15
		*set calculating %-10
		*set coupbondstatus +15
		*set coupspystatus +10
		*set doubleagentstatus +10
		*set eliteinfostatus +5
		*goto lvbonever
	#"I am here to please you, my great Lady. To serve you," I say.
		*set rlshp_venuma %+15
		*set outspoken %+10
		*set coupspystatus +15
		*set doubleagentstatus +10
		*set coupbondstatus +10
		*set abolishbothstatus +5
		*goto lvbonever
	#I am not Lady Venuma's to own, but neither is she fully mine. She will know this intuitively.
		*set rlshp_venuma %-5
		*set outspoken %-10
		*set eliteinfostatus +15
		*set doubleagentstatus +15
		*set abolishbothstatus +10
		*set coupspystatus +5
		*goto lvbonever
	#I do not belong to Lady Venuma in any way, but I don't dare let her feel that.
		*set rlshp_venuma %-15
		*set calculating %+10
		*set winjoin status +15
		*set eliteinfostatus +15
		*set doubleagentstatus +10
		*goto lvbonever

*label lvbonever

Time passes, but it all feels the same to you: perpetual bliss. You can't be sure how long it is before Lady Venuma finally speaks, but when she does, it's not at all the words you expect to hear.

"Now that we are connected, you must know something: you are not to engage in romantics with any other," Lady Venuma declares. "I wanted to be sure that was clear before we progressed any further."

You open your mouth to respond, but Lady Venuma speaks again, cutting you off. 

"This is not a matter open for discussion. It is an ancient, divine compact between Wone and mortal. My only obligation is to inform you who else I consort with. So you must know that I am involved with you. I am involved with Imperva.
*if thruple
	And I am also involved with Breeze." 

	*page_break

	Lady Venuma must catch the look on your face, because she then says: "I thought this last thrupling pleased you?"

	"It does, but—"

	"Then there is no 'but' to speak of," Lady Venuma interrupts once again. "You can be with Imperva and Breeze and me, all together if you wish, once our VS Front wins the day. However, this may occur only when I am present. And certainly with no one else. I am goddess and you are mortal, so you are to respect these wishes. Besides, even if you were to attempt otherwise, all of the other Versians already know you are mine and mine alone."
	*goto doyouresp
*else
	And I am involved with Breeze." 

	Lady Venuma says this casually, as if it is the most commonplace thing in the world. You listen as best you can, trying to process Lady Venuma's blunt admissions.

	*page_break

	"Of course, you are free to be with Imperva and Breeze and me, all together if you wish, once our VS Front wins the day," Lady Venuma continues. "However, this may occur only when I am present. And certainly with no one else. 

	"I am goddess and you are mortal, so you are to respect these wishes. Besides, even if you were to attempt otherwise, all of the other Versians already know you are mine and mine alone."  
	*goto doyouresp

*label doyouresp

You try to absorb the weight of Lady Venuma's words, but find that it is an incredibly difficult task. All you can do in response is:

*choice
	#Tell Lady Venuma I am fine with these mandates. She is a goddess and I am mortal, after all.
		*label lvexcle
		"Excellent," Lady Venuma says, climbing on top of you again. "Now it is time to reward you for your undying loyalty. Prepare yourself."
		*goto theabsorbhappens
	*if (thruple) #Tell Lady Venuma that I will be more than happy to spread the love between her, Imperva, and Breeze.
		*goto lvexcle
	#Accept these mandates. I suppose this is what I should have expected when I chose to get in bed with a literal goddess.	
		*goto lvexcle
	#Stay silent. I have to take some time to process whether I am okay with any of this before accepting or declining.
		"I can sense your doubt," Lady Venuma says, seeming annoyed. "Perhaps once you understand how my mind works, you will be more amenable to my divine terms. So, shall we begin? My time runs short." 
		*goto theabsorbhappens
	#Make it very clear that I am not Lady Venuma's pet. No one tells me what I can and cannot do, goddess or otherwise.
		*set lvnotokay true
		"The wilder your thoughts run, the more they call out to me," Lady Venuma says, the chill in her voice dropping to subzero levels. "You grow bold. And you forget your place. Perhaps once you understand how my mind works, you will be more amenable to my divine terms. So, shall we begin? My time runs short." 

		You have some more "wild thoughts" to share with Lady Venuma, but you also know that right now, you really do need Lady Venuma's full absorb. Besides, once she gets a taste of your own mind in this absorb, perhaps the great Lady will reconsider her deplorable mandates.

		After all, you're sure that Lady Venuma will only love you more if you show her you are one who is not to be trifled with either.

		*page_break
		*goto theabsorbhappens

*label theabsorbhappens

Lady Venuma then reaches out her hand to take yours, grasping it tightly. Within an instant, the full absorb initiates, lighting the entire room up in a golden haze. And you cannot hide your satisfaction when, despite her forwardness, Lady Venuma obviously does not expect what happens next.

Golden yellow energy begins to radiate off of Lady Venuma and into you, making you feel stronger and smarter, longer and leaner. As the energy crackles and ripples across your newly defined muscles, you feel dignified, superior, and entitled by birthright—even your skin takes on a slightly golden sheen, as if anointed by the heavens somehow. 

You can also tell that your senses are heightened, that you can see and hear and taste and smell things you never did before. You even feel a familiar sixth sense, one that allows you not just to read the emotions of others, but perhaps to even influence them. This new sense feels something like your absorb abilities, but amplified by a great factor and eminently more effortless….

*page_break

As the absorb begins to seep in, you can also feel the newfound ability to allocate its areas to your specializations. It becomes immediately clear that Lady Venuma's ability profile favors Strength, Energy, and Command—whereas your OtherBoard full absorb prioritized her proficiency for Technology, as well as her natural Energy and Strength talents. 

You see now that, for the duration of each full absorb, you are best suited to focus on the unique specialization combinations of the absorbee. So it seems Tech and Agility will have to take a backseat in the next few days as you focus on the other three—which also happen to coincide with the absorb areas Rosae has already indicated you should strengthen. 

Taking all of this into account, you decide to prioritize:

*choice
	#The incredible strength to command lesser beings to do as I wish.
		*set command +18
		*set strength +18
		*set enlighten %+10
		*set security %+10
		*goto alloverness
	#The energy of creation: the graceful ability to guide and shape.
		*set energy +18
		*set command +18
		*set enlighten %-10
		*set security %+10
		*goto alloverness
	#The raw power in my fingertips, to do whatever I choose with.
		*set strength +18
		*set energy +18
		*set enlighten %-10
		*set security %-10
		*goto alloverness
	#The intuition to understand others and effect global progress.
		*set command +18
		*set tech +18
		*set enlighten %+10
		*set security %-10
		*goto alloverness
	#Pure, destructive energy force.
		*set energy +18
		*set command +18
		*set security %+20
		*goto alloverness		
	#Mighty, invincible strength.
		*set strength +18
		*set agile +18
		*set security %-20
		*goto alloverness

*label alloverness

When the absorb finally settles, you feel an amplified connection to Lady Venuma—a connection you can tell that the demigoddess herself did not at all anticipate. She obviously had little understanding of how different this divine sharing process would be with a Priscan—and you have to admit, you can't help but be just slightly pleased at how overwhelmed Lady Venuma seems. You can tell that she is not used to feeling so exposed—and getting a taste of her own medicine seems a rather bitter pill for her to swallow. 

*if lvfinalromance
	"That will be all, love," Lady Venuma manages to stammer before turning and walking abruptly toward the door, reclothing herself automatically as she goes. "I have one last brunch to host and I must be returning. We shall reconvene soon."

	Seeing Lady Venuma so rattled, you experience an aloof satisfaction flow through you like a cooling wind—especially given the monogamy mandates she just laid out before you. Perhaps Lady Venuma will reconsider her position, now that she seems to have met her match. 

	But honestly, if anything, this full absorb has helped you begin to understand the superiority complex that seems to drive Lady Venuma. If you're being truly honest with yourself, now that you've had the slightest taste of what it feels like to be Lady Venuma, you're not sure you'd act all that differently.

	*page_break

	However you feel, you know that you can sort things out with Lady Venuma once you've both had a chance to process this deeply probing encounter.

	Besides, no matter how much Lady Venuma may want to distance herself from you at the moment, she won't get very far.
	*goto mornqu
*else
	"That will be all," Lady Venuma manages to stammer before turning and walking abruptly toward the door. "I have one last brunch to host and I must be returning. We shall…reconvene."

	As Lady Venuma exits, you experience an aloof satisfaction flow through you like a cooling wind. And whether you like it or not, now that you've had the slightest taste of what it feels like to be Lady Venuma, you can begin to understand where her superiority complex comes from…and perhaps use it to your advantage in the physical and political Trials to come.

	*page_break

	Whether you and Lady Venuma want to be near each other after this encounter, though, is fairly irrelevant.

	*goto mornqu

*label mornqu
You'll be spending the coming night with her in MemoryTravel, exploring an entire world filled with the allegedly divine. You're quite curious to see if these Wone deities live up to their legend, or if they fall flat in your eyes…

For if you feel entitled to anything after this particular full absorb, it's the privilege to pass judgment on others.

*if masteryfortybonus
	*goto endoftwo
*elseif (mastery >= 40)
	*set lifemax +1
	*set masteryfortybonus true
	*achieve masteryfortybonusac
	*goto endoftwo
*else
	*goto endoftwo

*label endoftwo
*finish PART TWO: JUDGE OR JURY

*label trial_end
*label end_trial
*check_purchase adfree
*if choice_purchased_adfree or not(choice_purchase_supported)
	*label purchased
	*return
Remember earlier how we told you that the first two chapters are available for free? This is the end of the free content.

[i]To find out what happens next, please purchase the remaining chapters.[/i]

*purchase_discount adfree 2022-07-21 $4.99 $2.99 purchased
*abort
