*comment é

*image part3.png center PART THREE: TRIAL BY FIRE

*image chap6.png center CHAPTER SIX: ASHES

*image chap6_quote.png center "Welcome, ${name} Thomil. I have been looking forward to meeting you for quite some time. Truly." —Queen Ashe Solares

*page_break
*set life lifemax

You've done it—you've survived your first full week on Versus. This morning marks day eight, which you can hardly believe. It feels more like you've lived a lifetime here, or multiple lifetimes, given your MemoryTravel experiences. 

In fact, after how intense this last trip proved to be, you were thrilled to learn yesterday that every seventh day on Versus is reserved as a day of solitary rest and reflection. After spending several sleepless hours yesterday night trying to process everything you had experienced with Prince Everly, ${planetname}, Lord Grahl, and Apprentice Grecca, you still felt you had gotten nowhere—so when Ayeleen entered with the rising sun to inform you of your earned day of rest, you were incredibly relieved.

Especially as it turned out that you actually needed the rest part desperately—you had intended to spend most of the time reflecting, but when Lady Venuma's full absorb finally wore off, you passed out back in your bed for several blissful, uninterrupted hours. 

Once you woke up from this deep sleep, you also found out that every seventh day is meant to heal every Versian's physical wounds, in order to level the Versus playing field. This healing felt particularly wonderful, as you were still rather sore from the shadowy wounds inflicted by Lord Grahl.

Today, on the morning of day eight, you find yourself feeling refreshed. Which is particularly good timing, considering the fact that you now find yourself waiting…

*page_break

In the grand foyer of Queen Ashe's penthouse wing. You sit beside Grog, trying not to shake in your Priscan Battlesuite boots in anticipation of the SoulTest soon to come. 

You thought you might have time for visits—wanted or unwanted—from MamaNa, Lady Venuma, or any other number of interested Elite Courte members. However, first thing upon being woken up by Ayeleen, you were put into your BattleSuite and brought to Queen Ashe's quarters.

You tried your best to prepare yourself on the way here, but as you did, you came to a rather reassuring realization: 

You already feel prepared. 

*page_break

You've had so much time to choose where you stand, and now the time has come to make your final political Status goal decision. The fates of your allies and enemies now rest squarely in your hands—or rather, this decision will likely determine who will remain your ally and who will become your enemy. 

After all, whatever side you do or don't choose will determine who might rise to power and who might fall into a minority—and those among that minority will be the first to face the threat of death in future Versus Matches.

Not that your decision needed any more weight added to it, but yesterday you forced yourself to consider who might be voted into the next Versus Match to face the Bominate based on who maintains power—especially since Empress Vaccus cannot be voted into back-to-back Matches.

*fake_choice
	*if (todrickdie) #If The Elite Courte maintains the majority, I'm sure the target will fall on Breeze, since ${breze} was only spared in the first vote by Todrick volunteering.
	#If The Elite Courte maintains the majority and Lady Venuma, MamaNa, and Imperva are exposed as traitors, the vote will likely fall on one of them.
	#If The Elite Courte maintains its majority, I suppose the target could really fall on any of the remaining Ords, including OtherBoard, Cel, Trig, Pinkuju, The Unpronounceable One, or Baron Airon.
	#If I don't pass this final SoulTest, I suppose the target could fall onto me—or Grog, for that matter, if it fails.
	#If The VS Front seizes control of the vote, I think Queen Ashe will likely be targeted, as The Elite's leader.
	#If The VS Front seizes control of the vote, I suppose the target could really fall on any of the remaining Elites: Oli, Prince Everly, Lockdown, Cadet Gadget, Beyhalo, Glorya, or Royal A-08.
	#Honestly, there is no way to predict who will be the next to face the vote, so I just have to follow my instincts—and hope it isn't me.
	
Whatever you decide, you know that you'll be indirectly sealing someone's fate in the short term—and the fate of many others in the long term. You also hope you'll be setting yourself up to have some say in the deciding of these majority votes, but you can't really be sure.

You can be sure, however, that no relationship is likely to survive this inevitable divide once you choose your path. No matter how strong—or romantic—your relationship with someone might be, it will no doubt crumble under the weight of a conflicting decision.

So you already know that when the time comes to make your final decision, you had better consider who matters most to you and weigh them against your potential principles.

*page_break

As if this weren't enough to get your nerves churning, you also know you're about to meet the legendary Queen Ashe face-to-face for the first time. And that she stands ready to judge your intentions, in all of her supposedly divine and ancient glory. 

To try to distract yourself as you wait for this all-important private meeting, you study the Queen's grand entrance foyer. You'd think somehow that all this opulence you've experienced would become less magnificent after your time in this Castle, but nothing you've seen so far could hold a candle to Queen Ashe's grand foyer—and you mean that quite literally. 

Ever-lit candles flicker in immense candelabras hung throughout the foyer, burning in flames of every color imaginable. The rest of the space is painted stark white, a rather simple and sleek design in comparison to the gold and rose tones of the rest of the Castle. Despite this crispness, however, the foyer still somehow feels equally warm and romantic. 

That sense of warmth is probably thanks to the red, orange, and yellow tapestries draped throughout the space, each seemingly woven from vibrant, glowing thread. The penthouse foyer is also perched on a ledge overlooking the shimmering Love Lake, which refracts through the various flames to cast fluid patterns on the white walls.

Reflecting on the beauty of this grand room, you know you won't let this be a deciding factor, but…

*choice
	#I love it here at the Elite Castle. This is where I belong.
		*set doubleagentstatus +4
		*set winjoinstatus +4
		*set eliteinfostatus +4
		*goto besideyougrog
	#None of this fancy stuff matters to me as much as my independence and my growth.
		*set eliteinfostatus +4
		*set abolishbothstatus +4
		*goto besideyougrog
	#It's nice to have experienced and enjoyed the Castle, but I'm not sure this is where I really belong.
		*set coupbondstatus +4
		*set coupspystatus +4
		*set eliteinfostatus +4
		*goto besideyougrog
	#This beautiful castle should belong to everyone, not just a select few.
		*set abolishbothstatus +4
		*set coupbondstatus +4
		*set coupspystatus +4
		*goto besideyougrog

*label besideyougrog

Beside you, Grog seems even more entranced by the decor in Queen Ashe's grand foyer. You can practically see the stars in its eyes—you know Lady Venuma and MamaNa think Grog is aligning with The VS Front thanks to their self-described generosity, but from its current awestruck look, you have to wonder if Grog has actually been won over by the Elite experience. You try to reach out with your demigoddess intuition to confirm this suspicion, but you realize that it's gone, having faded with the rest of Lady Venuma's full absorb.

You instinctively switch to your ambient absorb sense, but you're surprised to find that it feels foggy and hollow in comparison—like your vision has been blurred significantly. It seems you'll have to take some time to readjust from Lady Venuma's precisely honed intuition back to the fuzzier and more general ambient absorb.

"No one I know has ever seen anything like this," Grog suddenly says, still looking around the foyer. "Well, we have built palaces like this, I suppose. We've just never been guests."

As Grog speaks, you realize that you haven't really ever heard its voice—it's distinctly sweet and low, but simultaneously papery and delicate. You'd have expected something far deeper and simpler to come from someone of Grog's size and stature, but you suppose you should know by now not to judge a mirror by its reflection.

*page_break

"Same for me," you answer, looking up at Grog. "I'm in the military where I'm from. So there aren't many castle visits on the docket."

"Is that what your mirror patch stands for?" Grog asks, now turning and craning its neck down to look directly at you.

"Not specifically," you say. "Everyone on my planet gets one when we're old enough."

"Oh. Have you been in the military long?" 

"Long enough," you answer, letting out a long sigh at the thought.

"Well, if we ever have the time, could you maybe teach me some things about strategy and fighting?" Grog asks. "My people don't receive any education, at least not since we were stolen into slavery. Those of us born into it, like me, are barely even taught to read—and that's only because the Sallytrans need us to follow construction instructions."

*page_break

"Oh, of course," you say, feeling for Grog, "though the kind of warfare I'm used to is different than these Versus Matches seem to be."

"Oh yes, I'm sure," Grog says. "But this would be for being Reborn to Blarfngard. If that happens, I'm going to use all I've learned to help me free my people."

You try not to seem too surprised to hear this—the Grog you've encountered so far has been so meek and mild-mannered. Where did this budding revolutionary suddenly come from?

"At least, I'm going to try," Grog then adds, perhaps reading your reaction. "The idea still scares me half to death, but after all I've seen and learned here, and after the way the Wone have treated me, how could I not? You know, the Sallytrans who enslaved us always told us that the Wone couldn't hear the prayers of us Groggians—and that our enslavement was decreed to the Sallytrans by the Wone themselves. I'm very happy to have learned what boldfaced lies those are from both Lady Venuma and Prince Everly."

Knowing that this will likely be one of your last opportunities to affect your Status goals before the SoulTest, you respond to Grog by saying:

*choice
	#"I think we probably both stand to learn a great deal from Queen Ashe, as well."
		*set winjoinstatus +7
		*set coupspystatus +7
		*set rlshp_grog %+20
		*set calculating %+20

		Grog seems to agree with you heartily, given the vigorous head nod it meets your statement with. 
		*goto hapyorsad
	#"Lady Venuma has taught me more than I ever could have imagined in my short time here."
		*set coupbondstatus +7
		*set doubleagentstatus +7
		*set rlshp_grog %-20
		*set calculating %+20

		Grog nods at you after this, but it doesn't offer any words of agreement. Instead, Grog seems far more politely interested than earnestly enthused by this notion.
		*goto hapyorsad
	#"Well, Prince Everly has changed my whole worldview. Literally."
		*set winjoinstatus +7
		*set eliteinfostatus +7
		*set rlshp_grog %+10
		*set calculating %-20

		Grog seems to agree with you heartily, given the vigorous head nod it meets your statement with. 
		*goto hapyorsad
	#"Actually, I've learned more from the other non-Wone Versians here, like MamaNa."
		*set abolishbothstatus +7
		*set coupspystatus +7
		*set rlshp_grog %-15
		*set calculating %+20

		Grog nods at you after this, but it doesn't offer any words of agreement. Instead, Grog seems far more politely interested than earnestly enthused by this notion. In fact, from what you can tell, Grog seems almost afraid of MamaNa—or at least afraid of talking about her.
		*goto hapyorsad
	#"I'd be happy to help you in any way I can, Grog."
		*set abolishbothstatus +7
		*set eliteinfostatus +7
		*set rlshp_grog %+20
		*set calculating %-20

		Grog seems rather genuinely touched by this offer, though this emotion seems to be immediately overtaken by a wave of doubt—as if Grog knows you both probably won't be able to do this, given your current Trial rivalry. 
		*goto hapyorsad

*label hapyorsad
*gosub statuscheckend

You then have to ask yourself: could this possibly mean that Grog is leaning toward actually joining The Elite Courte instead of The VS Front? If that is indeed its truest intention, you have to consider what Grog might reveal to Queen Ashe in its SoulTest…but you suppose it's also possible Grog is just a good spy for The VS Front—a far better one than Pinkuju turned out to be, if that's the case. Either way, should Grog's response now give you any reason to change how you handle your own SoulTest?

Grog opens its mouth to respond again, but before it can, the double doors to Queen Ashe's suite suddenly open. An Aye Aye appears from within—one whose finely combed red fur glows like a living ember. This elegant Aye Ayember stands before the double doors and points one fiery finger… 

Directly at you.

*page_break

Feeling a jolt of adrenaline strike your system, you take the deepest breath you can. You then stand to meet your fate, trying to shake off any lingering doubts. 

Whatever Grog does or doesn't plan to do, you know that ultimately you have to make the best decision for yourself. At the end of it all, Grog is just one factor among dozens you must consider.

"Good luck in there, friend," Grog says, giving you a toothy grin as you walk by.

"Good luck to you, too," you say, knowing that right now, you and Grog may appear as rivals—but whether that's really true or not, like so many other things, depends upon your decision in this SoulTest.

*page_break

Thinking about these competing factors as you approach the double doors, you can almost feel your Status goal progressions locking into place. Before they settle, you are able to use your Tech Apprentice skill to sense one final shift—a shift that takes place based on your accumulated behavior patterns since that fateful meeting with MamaNa in the halls of the aquarium.

*if (calculating < 50) and (outspoken < 50)
	You have ultimately been Trustworthy and Contemplative, and have valued 
	*if (security > 75)
		*set coupbondstatus +15
		*set eliteinfostatus +15
		Security,
		*goto cbmoveon
	*elseif (security > 50)
		*set coupbondstatus +7
		*set eliteinfostatus +7
		Security, 
		*goto cbmoveon
	*elseif (security < 25)
		*set coupbondstatus +15
		*set eliteinfostatus +15
		Freedom,
		*goto cbmoveon
	*else 
		*set coupbondstatus +7
		*set eliteinfostatus +7
		Freedom,
		*label cbmoveon
		so your Status has been additionally boosted to [i]Establish Ties Within Coup[/i] and [i]Remain As Neutral As Possible,[/i] since these are the most statistically ideal goals for you.
		*goto donthaveto
*elseif (calculating < 50) and (outspoken >= 50)
	*if (security > 50)
		*set winjoinstatus +15

		You have ultimately been Trustworthy and Outspoken, and have valued Security, so your Status has been additionally boosted to [i]Win Trials To Join The Elite Courte[/i], since that is the most statistically ideal goal for you.
		*goto donthaveto
	*elseif mamanaabolish
		*set abolishbothstatus +15

		You have ultimately been Trustworthy and Outspoken, and have valued Freedom, so your Status has been additionally boosted to become a [i]Secret Abolitionist,[/i] since that is the most statistically ideal goal for you.
		*goto donthaveto
	*else
		*set winjoinstatus +7
		You have ultimately been Trustworthy and Outspoken, so your Status has been additionally boosted to [i]Win Trials To Join The Elite Courte,[/i] since that is the most statistically ideal goal for you.
		*goto donthaveto
*elseif (calculating >= 50) and (outspoken < 50)
	*if (security > 75)
		*set doubleagentstatus +15
		*set eliteinfostatus +15

		*label dasecure
		You have ultimately been Calculating and Contemplative, and have valued Security, so your Status has been additionally boosted to [i]Become Elite Double Agent Within Coup[/i] and [i]Remain As Neutral As Possible,[/i] since these are the most statistically ideal goals for you.
		*goto donthaveto
	*elseif (security > 50)
		*set doubleagentstatus +15
		*set eliteinfostatus +7
		*goto dasecure
	*elseif (security < 25)
		*set doubleagentstatus +7
		*set eliteinfostatus +15

		*label dafreedom
		You have ultimately been Calculating and Contemplative, and have valued Freedom, so your Status has been additionally boosted to [i]Become Elite Double Agent Within Coup[/i] and [i]Remain As Neutral As Possible[/i], since these are the most statistically ideal goals for you.
		*goto donthaveto
	*else
		*set doubleagentstatus +7
		*set eliteinfostatus +7
		*goto dafreedom
*else
	You have ultimately been Calculating and Outspoken, and have valued 
	*if (security > 75)
		*set coupspystatus +15
		*label cssec
		Security, so your Status has been additionally boosted to [i]Become Coup Spy Within Elite,[/i] since this is the most statistically ideal goal for you.
		*goto donthaveto
	*elseif (security > 50)
		*set coupspystatus +7
		*goto cssec
	*elseif mamanaabolish
		*if (security < 25)
			*set coupspystatus +15
			*set abolishbothstatus +15
			*label csfree
			Freedom, so your Status has been additionally boosted to [i]Become Coup Spy Within Elite[/i] and to become a [i]Secret Abolitionist[/i], since these are the most statistically ideal goals for you.
			*goto donthaveto
		*else 
			*set coupspystatus +7
			*set abolishbothstatus +15
			*goto csfree
	*elseif (security < 25)
		*set coupspystatus +15
		*label csfreesolo
		Freedom, so your Status has been additionally boosted to [i]Become Coup Spy Within Elite,[/i] since this is the most statistically ideal goal for you.
		*goto donthaveto
	*else 
		*set coupspystatus +7
		*goto csfreesolo

*label donthaveto
*gosub statuscheckend

*if (calculating > 75)
	*achieve calchigh
*if (calculating < 25)
	*achieve trusthigh
*if (outspoken > 75)
	*achieve outspokenhigh
*if (outspoken < 25)
	*achieve conthigh

You know that this statistical trending doesn't at all mean that you have to choose this as your designated intention—nor does it necessarily mean you even should, based on your Status goal levels. Still, it's intriguing to know the goals that suit you best based on your decision-making patterns. It's also fascinating to see how this compares to your FourPath Splinter corner: 
*if authorius 
	Authorius, the Path of the Pastor, which theoretically values Security and Enlightenment and includes The Elite Courte's ruler, Queen Ashe.
*if boldure
	Boldure, the Path of the Pioneer, which theoretically values Freedom and Education and includes The VS Front ringleader, Lady Venuma.
	*if mamanaabolish
		Or perhaps instead leads towards MamaNa's hidden equality agenda, as you already know.
*if commaith
	Commaith, the Path of the Parent, which values Freedom and Enlightenment and includes the likes of an enforcer like Lord Grahl—and which also straddles the ideological line between the current regime and rebellion.
*if demlect 
	Demlect, the Path of the Prefect, which theoretically values Security—but also the groundbreaking, countercultural movement of Education—and includes Elite Courte member Prince Everly.
*comment endif

Ultimately, you are a complicated and unique individual whose personality and motivations cannot be quantified by such simple statistics. However, it is always interesting to see how your behavior is perceived by a source outside yourself, however much you may agree or disagree.

*page_break

Last but certainly not least, it appears the final influence on your Status is tallied based on your relationships with everyone you've encountered since entering The Elite Trials. Obviously, being closer to Elite members like Lockdown, Cadet Gadget, Prince Everly, and Oli is better for certain Elite aspirations or VS Front spy goals, while the opposite is true of connections to Lady Venuma, MamaNa, Imperva, Pinkuju, and Baron Airon: those relationships are better for The VS Front or Elite double agent goals. And of course, having good relationships in general with as many Versians as possible, regardless of their affiliations, is best for any nonpolitical or more…hidden agendas.

*if (rlshp_lockdown > 60)
	*set winjoinstatus +1
	*set doubleagentstatus +1
	*set coupspystatus +1
	*set abolishbothstatus +1
	*set eliteinfostatus +1
*if (rlshp_lockdown < 40)
	*set coupbondstatus +1
*if (rlshp_cadet > 60)
	*set winjoinstatus +1
	*set doubleagentstatus +1
	*set coupspystatus +1
	*set abolishbothstatus +1
	*set eliteinfostatus +1
*if (rlshp_cadet < 40)
	*set coupbondstatus +1
*if (rlshp_everly > 60)
	*set winjoinstatus +1
	*set abolishbothstatus +1
	*set coupspystatus +1
	*set doubleagentstatus +1
	*set eliteinfostatus +1
*if (rlshp_everly < 40)
	*set coupbondstatus +1
*if (rlshp_oli > 70)
	*set winjoinstatus +1
	*set coupspystatus +1
	*set eliteinfostatus +1
	*set doubleagentstatus +1
	*set abolishbothstatus +1
*if (rlshp_oli < 30)
	*set coupbondstatus +1
*if (rlshp_venuma > 70)
	*set coupbondstatus +1
	*set doubleagentstatus +1
	*set coupspystatus +1
*if (rlshp_venuma < 30)
	*set winjoinstatus +1
	*set eliteinfostatus +1
	*set abolishbothstatus +1
*if (rlshp_imperva > 55)
	*set coupbondstatus +1
	*set doubleagentstatus +1
	*set coupspystatus +1
*if (rlshp_imperva < 45)
	*set winjoinstatus +1
	*set eliteinfostatus +1
	*set abolishbothstatus +1
*if (rlshp_airon > 55)
	*set coupbondstatus +1
	*set doubleagentstatus +1
	*set coupspystatus +1
*if (rlshp_airon < 45)
	*set winjoinstatus +1
	*set eliteinfostatus +1
	*set abolishbothstatus +1
*if (rlshp_mamana > 65)
	*set coupbondstatus +1
	*set abolishbothstatus +1
	*set coupspystatus +1
	*set doubleagentstatus +1
*if (rlshp_imperva < 35)
	*set winjoinstatus +1
	*set eliteinfostatus +1
*comment endif

*gosub statuscheckend

*if extraworning
	"Priscy, something tells me I won't be able to interfere during this SoulTest, so let me warn you now, while I have the chance," Rosae begins, chirping hurriedly as you approach Queen Ashe's inner sanctum. "Obviously you should only go with a Status goal that has been progressed and practiced up to at least fifty percent; otherwise, Queen Ashe will likely be able to see through your intentions. Now, I know how important this decision will be, so I will let you focus. Best of luck, ${name}!"

	Giving Rosae a quick mental thanks, you
	*goto entertest
*else
	You bet that right about now, if Rosae could, she'd be warning you to examine these Status levels very closely before committing to a decision. After all, based on MamaNa's advice, during the SoulTest Queen Ashe will no doubt be able to see through any Status paths whose levels are less than half full.

	You
	*goto entertest

*label entertest
then take another long, deep breath to try and soothe your nerves. [i]You've got this,[/i] you remind yourself, trying to recall that feeling of preparedness from earlier.

*page_break Through The Double Doors

You walk through what feels like an endless hallway of closed doors, stretching on either side of you in perfect whitewashed symmetry. The only feature breaking up the monotony is the fire that burns on the front of each door, where the knob would ordinarily be. Some of these flames are hot, some are cold. Some are bright, and some are dark. You have to ask yourself: what secrets and wonders could possibly be held behind these identical yet diverse doors? The flickering of their many flames is so mesmerizing that you barely recognize you've reached the end of the corridor and arrived at your destination.

Once you do enter Queen Ashe's master suite, your eye has no idea where to settle first. The round room is set underneath a vaulted dome that glows with warm white light. Out to the right is another balcony that overlooks the Love Lake and holds a massive pitted bonfire. You wonder why you haven't seen this epic flame burning from the Verses Village and decide that it must be masked from view somehow, unless it is actually newly lit in honor of The Trials.

Back inside the round room, a sparse setting of sleek chairs and chaise lounges is set around a table. Two sweeping staircases flank the dome and rise to meet at another balcony on the second floor. You're wondering where Queen Ashe herself is when the glowing Aye Ayember shuts the door behind you with a thud. Then you nearly scream… 

At the startling sight of a singular bolt of fire, which strikes the floor like lightning from a yellow storm cloud. This storm cloud then begins to shower droplets of molten lava that collect in pools on the floor, streaking forth like the tears of a volcano.

As the magma drizzle builds into a downpour before you, another firebolt of flame strikes…and suddenly Queen Ashe appears.

*page_break

Your first thought is that Queen Ashe is much taller and thinner than both Lady Venuma and Prince Everly, almost like a ray of light made flesh. The bits of flesh that do show through Queen Ashe's clothes glow white hot—which makes sense, since her skin is as stark white as the walls of her palace. This contrasts with her vibrant orange hair, which is flecked with streaks of yellow, glowing like fire itself.

Queen Ashe wears an intricately corseted ruby top that is encrusted with blue gems the color of flame. Attached to the corset are several flowing layers of white chiffon skirts, all embroidered with delicate patterns sewn in red thread and beads. On her head, Queen Ashe wears a crown of blazing firejewels that drip across her forehead elegantly.

Queen Ashe seems quite like a rainbow personified, since the colors of her royal garb shine almost as brightly as a sun. As a result, the singular feature that seems to stand out most is Queen Ashe's deep grey eyes, which match the color of ash and send shadowy accents streaking down her white cheeks.

"Welcome, ${name} Thomil," Queen Ashe says, her voice, full of purity and poise, bursting forth like a beam of light. "I have been looking forward to meeting you for quite some time. Truly."

Hearing Queen Ashe say your name and address you directly, you can instantly feel how it's impossible not to believe her inherent goodness. You are filled with such hope and awe just to be in her presence—it's beyond anything you've ever experienced, even after visiting Wone.

*choice
	#I can see why so many seem to follow Queen Ashe so blindly.
		*set rlshp_ashe %+20
		*goto tiltahea
	#I can see how Queen Ashe could be blinded to any mortals who don't immediately fall under her spell, if this is usual effect she must have.
		*set rlshp_ashe %-10
		*goto tiltahea
	#I'm reserving any judgment until I spend more time with Queen Ashe.
		*set rlshp_ashe %+10
		*goto tiltahea
	#Despite—or perhaps because of—this instantaneous feeling, I don't trust Queen Ashe at all.
		*set rlshp_ashe %-20
		*goto tiltahea

*label tiltahea

Queen Ashe tilts her adorned head, seeming to read your reaction clearly—you have to remember that, as an ancient Wone, she is perhaps even more capable of doing so than Prince Everly or Lady Venuma. 

Unlike your experiences with Lady Venuma, though, you suddenly feel Queen Ashe offer you something ambiently in return for what she has taken. She inexplicably shares with you the duality of her existence, the finely tuned balance she has represented for eons: the purity, cleansing, rebirth, and life-giving nature of the flame, balanced against the death, charring, scarring, and rotting that is left behind with the ash. 

This balance also feels different even than the kind Prince Everly shared with you…while Prince Everly's duality felt fresh and new and inherited, with Queen Ashe it feels like you are standing in the presence of history itself—as if she was somehow forged in the galaxy's first fire. Or perhaps even as if she was the one to spark the very first flame….

*page_break 

*if (rlshp_mamana > 60)
	"You should know that MamaNa speaks highly of you. Quite highly," Queen Ashe offers. "You must also know that to me, there are few greater forms of praise."

	Hearing MamaNa's name reminds you instantly of your last conversation with her in the VIP lounge—and gives you an idea. As Queen Ashe speaks, you try to get a sense of what she might or might not know about the Bominate, by peeking into her mind with your ambient abilities. 

	However, you quickly learn that there will be no ambiently absorbing Queen Ashe—all you feel when you try is a burning wall of fire that threatens to consume you.

	"I'd say the same of her," you answer instead, totally unsure of whether Queen Ashe has detected your failed probe. Would that even be a blip on her radar, or do you simply register for her with all the force of a gnat flying into a hurricane? 

	"Actually, I'd say the same of all the Elites I've met, for that matter," you add, feeling the need to match Queen Ashe's cool and diplomatic tone.
	*goto alsosen
*else
	*set mntellsbom true

	"MamaNa has told me of you," Queen Ashe says gently, giving no indication of whether this message was positive, negative, or something in between. 

	Hearing MamaNa's name reminds you instantly of your last conversation with her in the VIP lounge—and gives you an idea. As Queen Ashe speaks, you try to get a sense of what she might or might not know about the Bominate by peeking into her mind with your ambient abilities. However, you quickly learn that there will be no ambiently absorbing Queen Ashe—all you feel when you try is a burning wall of fire that threatens to consume you.

	You're totally unsure of whether Queen Ashe has even detected your failed probe—would that even be a blip on her radar, or do you simply register for her with all the force of a gnat flying into a hurricane? 

	*page_break

	"MamaNa also told me that you…inspired her to reconsider the secrecy surrounding her Cuttaran heritage and the Bominate," Queen Ashe then says, an expressionless look on her face.

	Once again, you receive zero indication of whether Queen Ashe already knew this truth before your VIP conversation with MamaNa at the second Trial, or if she learned this secret more recently. If the latter is true, MamaNa must have felt the need to protect herself by coming clean with Queen Ashe before you could potentially expose her. 

	Whether Queen Ashe is upset or ambivalent about this Bominate truth, you also cannot tell. Either way, MamaNa has successfully removed your leverage, at least when it comes to Queen Ashe and this Bominate secret. But you can sense that is a thought for a later time, as there are far more pressing considerations coming in this all-important meeting.

	"I hope MamaNa's truth saves many future Constructive Versian lives," you respond, feeling the need to match Queen Ashe's cool and diplomatic tone.
	*goto alsosen

*label alsosen
*page_break

"I can also sense you have visited Wone," Queen Ashe lilts, moving on as her ashen eyes seem to burn through you. 
*if authorius 
	"Authorius. Lovely."
*if boldure
	"Boldure. Fascinating."
*if commaith
	"Commaith. Interesting."
*if demlect 
	"Demlect. Fitting."
*comment endif

Queen Ashe's eyes then grow cloudy and turn deep black for a moment before returning to normal. "And you still draw breath, which means you must have escaped Lord Grahl's clutches, as well. Impressive."

"I actually—"

"You needn't speak further," Queen Ashe interrupts with a wave of her white hand. "I can intuit all that I need. I speak aloud only for your mortal benefit, because I want you to feel at ease, ${name}, to feel at home here in my Castle. After all, advancing this deeply into The Elite Trials is no small feat. I am proud of you, to see how far you have come on such little experience."

Despite being silenced and potentially belittled, somehow you are only filled with joy and love and pride to hear Queen Ashe's words—as if she could never possibly mean an inch of harm.

*page_break

"Though now I see…" Queen Ashe trails off, her eyes flickering dark once more. "Apologies. I have never met a Priscan before. Clever. Prince Everly's creations always do tend to stand out, don't they?"

You're about to answer when you remember that Queen Ashe can probably already register your feelings on the rather loaded subject of Prisca's creation.  

"I can see now that you don't require words either, given your natural absorb abilities," Queen Ashe continues. "All it will take is a connection your people call…"

Queen Ashe then pauses, looking out into the distance before turning back to make blazing eye contact with you. "Full absorption."

*page_break

You hear these words, and instantly they make perfect sense. A full absorb would not only share Queen Ashe's benevolence with you as usual—given her immortal senses, it would also surely reveal your deepest and truest intention to her as well. Or, as MamaNa has hopefully taught you, it would reveal the intention you're best able to project, honestly or otherwise.

Which means the moment is finally upon you, even sooner than you could have expected: the SoulTest that will reveal or conceal your ultimate goal. The choice that this entire Versus experience has been leading up to, the one that will decide the fate of virtually every one of your fellow Versians.

Knowing what will come next, your thoughts seem to crystallize into the most important considerations…

*page_break

Do you make your decision based on ideology, to follow what you believe is right? Do you decide based on your best chances for survival, to ensure you can continue the important work of your Dhanthik search? Do you decide based on the opportunity to accrue power, to continue the evolution you've experienced since arriving on Versus? Do you decide based on your relationships, to protect those you've come to care for most? Or do you simply decide based on necessity, given the potential restrictions of your Status levels accrued by the decisions that have led you to this point?

Ideology, survival, power, relationships, necessity—which of these competing foundational motivations will you favor? You know you will most likely have to sacrifice at least one for another in the difficult decision you now face.

Before you know it, Queen Ashe has moved just an inch away from you, her presence burning warm and bright across every inch of your skin. When she reaches out to touch your cheek, it is as if you have been touched by the sun itself. Everything turns white and red and blue and orange as you feel yourself cleansed from the inside out, swallowed up by flames stronger than imagination. 

And in that moment, you focus on only one intention. No, not focus—you cling. You cling to the only intention that you hope will matter.

*choice
	#I expose myself honestly, in the hopes of revealing the existence of The VS Front and demonstrating my absolute loyalty to Queen Ashe and her Elite Courte.
		*set elitenwo true
		*set rlshp_ashe 95
		*achieve winjoinfinal
		*if (winjoinstatus > 50)
			*goto burnburnburn
		*else
			*set fierydeath true
			*goto burnburnburn
	#I pledge my allegiance to The Elite Courte by revealing the existence of The VS Front—and by offering to embed myself within their traitorous ranks as a double agent.
		*set elitenwo true
		*set rlshp_ashe 85
		*achieve doubleagentfinal
		*if (doubleagentstatus > 50)
			*goto burnburnburn
		*else
			*set fierydeath true
			*goto burnburnburn
	#I conceal the existence of The VS Front from Queen Ashe by focusing fully on my true desire to build bonds with my fellow Ord Versians.
		*set coupnwo true
		*set rlshp_ashe 65
		*achieve coupbondfinal
		*if (coupbondstatus > 50)
			*goto burnburnburn
		*else
			*set fierydeath true
			*goto burnburnburn
	#I pledge my allegiance to Queen Ashe and The Elite Courte—all the while deeply disguising my true intention to spy on The Elite Courte for the still-secret VS Front.
		*set coupnwo true
		*set rlshp_ashe 75
		*achieve coupspyfinal
		*if (coupspystatus > 50)
			*goto burnburnburn
		*else
			*set fierydeath true
			*goto burnburnburn
	#I radiate the desire to rise above all of the ever-transient Versian politics, in the hopes of continuing to learn and grow independently.
		*set elitenwo true
		*set rlshp_ashe 70
		*achieve eliteinfofinal
		*if (eliteinfostatus > 50)
			*goto burnburnburn
		*else
			*set fierydeath true
			*goto burnburnburn
	*if (mamanaabolish) #I project my intense loyalty to MamaNa, knowing that Queen Ashe will interpret this as loyalty to The Elite Courte. Underneath the surface, however, I deftly conceal our joint intentions to join The VS Front and later abolish all ruling majority systems.
		*set coupnwo true
		*set rlshp_ashe 80
		*achieve abolishbothfinal
		*if (abolishbothstatus > 50)
			*goto burnburnburn
		*else
			*set fierydeath true
			*goto burnburnburn

*label burnburnburn

All that remains of you is this singular projected intention, which you repeat over and over like a life-giving mantra. 

But it isn't long before this mantra is set ablaze with the rest of your mind.

You find yourself entering some kind of fiery fugue, overwhelmed by Queen Ashe's divine consciousness.

Soon space and time fall away abruptly, changing the fabric of everything and cutting this experience unexpectedly short.

Soon, all you can feel is the flame, burning you into ash.

*finish Chapter Seven: Order

*label statuscheckend
*if (winjoinstatus > 100)
	*set winjoinstatus 100
*if (doubleagentstatus > 100)
	*set doubleagentstatus 100
*if (coupspystatus > 100)
	*set coupspystatus 100
*if (coupbondstatus > 100)
	*set coupbondstatus 100
*if (eliteinfostatus > 100)
	*set eliteinfostatus 100
*if (abolishbothstatus > 100)
	*set abolishbothstatus 100
*return
