*comment é

*image chap7.png center CHAPTER SEVEN: ORDER

*image chap7_quote.png center "I'm so sorry to have scorched you." —The Princess of Ashes

*page_break

For the longest time, you don't know where you are or when it is—all you know is the flame. As fever burns across your mind, you wonder if this is how the fully matured Wone experience time and space, or if you've simply entered some form of fiery afterlife. You can't seem to feel your own body as your consciousness roams through an endless loop of infernos: some colored, some blank, all vivid.

You remind yourself, over and over, that your mortal mind has only absorbed a fraction of Queen Ashe's divine mind. Which means that you will wake up from this feverish fugue state eventually…right?

For hours, days, years, seconds, you feel only the flames. You're unable to mark the passage of time, but you can at least confirm that you are actually alive as your mind finally gleans a vision of real life happening around you. These visions come and go at will, but you try your best to let them anchor you in the sea of fire.

First you feel cool sheets against your burning skin, then Ayeleen packing you with salves of ice before you plunge back into the inferno.

*page_break

Time passes and hours burn like embers before your next glimpse of reality settles into focus: Rosae flying next to you, flapping her blue-furred wings to try and cool you down.

Later, or perhaps sooner, you think you see the crest of Authorius flying high as you lie in a cooling spring. Soon, or perhaps later, you catch a flash of Queen Ashe sitting beside you—though really, she seems more like an Ashe from years past, perhaps even from her years as a princess.

"I'm so sorry to have scorched you," the Princess of Ashes says. "I will be new to the art of mortal absorption when we engage on Versus. Here, allow me to help you sort through some of the blaze?"

You're not sure you want the Princess of Ashes anywhere near your mind again, but soon you feel her guiding hand clear some of the smoke fogging up your perceptions. As your senses readjust, you can feel two of your absorption areas pulsing, calling out to connect with Ashe using:

*choice
	#Might by fire.
		*set strength +40
		*set energy +20

		You feel strong, and filled with energy…
		*goto churnburne
	#Might by rule.
		*set strength +40
		*set command +20

		You feel strong, and ready to lead…
		*goto churnburne
	#Fire by rule.
		*set energy +40
		*set command +20

		You feel filled with energy, and ready to lead…
		*goto churnburne
	#Fire by might.
		*set energy +40
		*set strength +20

		You feel filled with energy, and renewed strength…
		*goto churnburne
	#Rule by fire.
		*set command +40
		*set energy +20

		You feel ready to lead, and filled with energy…
		*goto churnburne
	#Rule by might.
		*set command +40
		*set strength +20

		You feel ready to lead, and filled with renewed strength…
		*goto churnburne

*label churnburne
but only for a fleeting moment.

*if (energy >= 100)
	*set energy 100
	*set mastery +4
	*if energyapprentice
		*set energynovicebool true
		*achieve energynovice
	*if (energyapprentice = false)
		*set energyapprentice true 
		*achieve energyappachieve
*if (strength >= 100)
	*set strength 100
	*set mastery +4
	*if strengthapprentice
		*set strengthnovicebool true
		*achieve strengthnovice
	*if (strengthapprentice = false)
		*set strengthapprentice true
		*achieve strengthappachieve
*if (command >= 100)
	*set command 100
	*set mastery +4
	*set commandappbool true
	*achieve commandappachieve 

*if (mastery >= 60)
	*set lifemax 15
	*achieve masterysixtybonusac
	*goto terealend
*elseif masteryfiftybonus
	*goto terealend
*elseif (mastery >= 50)
	*set lifemax +1
	*set masteryfiftybonus true
	*achieve masteryfiftybonusac
	*goto terealend
*elseif masteryfortybonus
	*goto terealend
*elseif (mastery >= 40)
	*set lifemax +1
	*set masteryfortybonus true
	*achieve masteryfortybonusac
	*goto terealend
*else
	*goto terealend

*label terealend
*set ashenotdt true

Then the scalding simply continues, thankfully with slightly less intensity than before. Enough, at least, for you to realize that seeing Queen Ashe and Rosae this way must mean you have MemoryTraveled somehow. If that's the case, then you can now confirm that Queen Ashe is not Dhanthik, as you and Oli had already suspected.

This moment of absorbing clarity is a much welcome island of respite amidst the feverish ocean. Still, you're returned to its churning waves soon enough, rising and falling and burning.

*page_break Sea Bound

Hours seem to melt together once again, so there is no telling how long it is before you come up for air.
*if elitenwo
	*goto theeliteoutcomes
*else
	*goto thecoupoutcomes

*label theeliteoutcomes

When the smoke clears from your vision, you see that you once again sit in Queen Ashe's Castle penthouse, this time with Grog beside you. Evidently you have returned from MemoryTraveling, which must make this…day nine on Versus? If that's really true, could this then be the announcement of the Trials winner?

You realize that, in all the confusion of your feverish haze, you hadn't thought to worry much about whether you passed Queen Ashe's SoulTest. Contemplating the state of your existence obviously took precedence, but now you remind yourself how important the results of this Test remain to your future on Versus.

The reminder seems to snap reality into focus for the next few beats…

*page_break

"The official coronation ceremony will take place before the entirely assembled Elite Courte later today," Queen Ashe begins, her voice seemingly filtered through a wall of ember and ash. You feel present, but also absent—like your body is here, but you're still watching this all happen to someone else on a screen.

"However, after all that you both have brought to light in your respective SoulTests," Queen Ashe continues, "we require this private meeting before the official Trial ceremony."

From there, reality slips away from you once again and you cannot tell if what happens next is present or becomes past, as all of your senses feel dulled and rearranged. Space and time distorts, but it's as if your brain still makes painstaking arrangements to bring forth the most important events…

Like MamaNa stepping out of the flickering shadows of Queen Ashe's palace. When you see her there, your heart nearly stops beating in your chest. What does MamaNa's presence here mean about the outcome of your SoulTest?

*page_break

*if (rlshp_ashe = 70)
	"${name} Grog revealed to me the existence of The Versus Subversive Front during its SoulTest," Queen Ashe announces, sending a wave of awareness through your blazing mind. "Immediately after both of your tests, MamaNa also revealed, via her own SoulTest, that she has been secretly embedding herself within this brewing rebellion as my own loyal agent.

	*if fierydeath
		"MamaNa also revealed to me that you are one of the ringleaders of The VS Front, ${name}," Queen Ashe then says, sending a jolt straight through you. "During your SoulTest, I probed beneath the protective layers of your projected intention and found it to be insincere. So MamaNa's words only confirmed what I already knew."

		"No," you try speaking, hearing your own voice sound thin and weak. "I knew about The VS Front, but I wanted to avoid the politics to—"

		"Silence," Queen Ashe interrupts. "Your fate has already been sealed. There is nothing words can do now."
		*goto castout
	*else
		"I already understand from your SoulTest that you wish to remain disengaged from such politics, which MamaNa and Grog have both corroborated."

		You immediately breathe a sigh of relief, because your projected intention has been read clearly by Queen Ashe—which means you must have passed Queen Ashe's all-important SoulTest. Thank the Mirrored Matron.

		But this emotion is followed by waves of doubt surrounding MamaNa and her ever-shifting intentions. Did MamaNa sense that Grog would betray The VS Front somehow and decide to sell out Lady Venuma, Imperva, and the rest of her secret "allies" to save herself? Or could it be that MamaNa is telling the truth now and was always a spy for Queen Ashe? 

		*page_break

		Your head aches as you realize there seems to be no way to tell what's real with MamaNa—at least not yet. And this is a perfect reminder of why you want to remain as uninvolved in Versus politics as possible.

		"I find this apolitical aspiration admirable, but unacceptable given the currently volatile Versus landscape," Queen Ashe adds, causing your pulse to pick up again. "The Elite Courte needs you, ${name}, so here is what I propose. 

		"You will win The Elite Trials and be relieved of all political duties by joining our ranks, save of course for voting as we determine every three days. While you engage in your own pursuits, MamaNa, Grog, and I will see to dismantling The VS Front. Do you find this acceptable?"

		Blinking at Queen Ashe and trying to summon all of the presence of mind you can muster, you attempt to project the following response ambiently:

		*choice
			#This is perfect. I can remain safe, secure, and as involved or uninvolved as I see fit among The Elite Courte's insulated majority.
				*goto routedfromeliteinfo
			#This isn't ideal, for I'd rather remain like Empress Vaccus: totally disengaged. However, my Dhanthik search demands interaction with the other Versians, so Queen Ashe is right: this is the best outcome.
				*goto routedfromeliteinfo
			#As usual, the politics don't matter to me. All that matters is continuing my Dhanthik search, so I'll stay among The Elite Courte only as long as it suits that goal.
				*goto routedfromeliteinfo
			#I'd rather not endorse The Elite Courte system by becoming a member, but this outcome is actually acceptable—I suppose if I can't beat them, I'd better join them.
				*goto routedfromeliteinfo
			#Staying in The Elite Courte only makes sense if I can become the new Ord ambassador in Lady Venuma's place—but that is a conversation for a time when I'm feeling fully focused.
				*goto routedfromeliteinfo
*else
	*goto noteinforou
	
*label noteinforou
Your brain shifts after this chilling image, beginning to compile a narrative that pieces together the events of the past day. Whether you actually see these things occur or hear about them afterwards is impossible to tell, but you can still somehow sense they are undoubtedly true.

Apparently, both you and Grog chose to inform Queen Ashe of the existence of The VS Front in your SoulTests in the hopes of joining The Elite Courte. Grog ultimately decided that Lady Venuma and MamaNa reminded it too much of its scheming Sallytran overlords—and obviously, you also felt your fate aligned with The Elite, for many reasons.

And it's a good thing you both did, because it seems MamaNa decided to meet with Queen Ashe after the SoulTests specifically to reveal her work "infiltrating" Lady Venuma's VS Front. During that meeting, she told Queen Ashe that she had embedded herself beside Lady Venuma to try to stop The VS Front before it would even have to come to Queen Ashe's attention. However, MamaNa feared the rebellion was too close to succeeding to continue shielding Queen Ashe from its existence. 

*page_break 

*if fierydeath
	Especially since, to your utter shock, MamaNa claimed that you founded The VS Front alongside Lady Venuma, as her most loyal new general.

	To prove this story, MamaNa offered to undergo her own SoulTest to demonstrate the innocence of her intentions. And as she always has, MamaNa passed this SoulTest as Queen Ashe's most trusted and valuable agent.

	Unfortunately, the same could not be said of you. Doubting the sincerity of your own projected intention, Queen Ashe had probed beneath the protective layers of your intent to discover that your desire to join The Elite Courte was somehow lacking. 

	*page_break

	As a result of this supposed insincerity in your failed SoulTest, Queen Ashe easily concluded that you were hiding something. So it was all too easy for her to find you guilty of the charges MamaNa levied against you.

	"No," you tried speaking, hearing your own voice sound thin and weak. "I—"

	"Silence," Queen Ashe interrupted, her voice booming like an explosion. "Your fate has already been sealed, ${name}. There is nothing words can do now."
	*goto castout

Of course, this information coincided with what Queen Ashe had learned from you and Grog in your own SoulTests, indicating that you had both passed this all-important moment of truth with Queen Ashe. Thank the Mirrored Matron.

However, Queen Ashe did find MamaNa's timing rather suspect, that she had chosen to reveal her involvement only after you and Grog had exposed the truth. So MamaNa offered to undergo her own SoulTest to prove the innocence of her intentions. 

Of course, as she always has, MamaNa passed this SoulTest as Queen Ashe's most trusted and valuable agent. Learning this, you can't help but think:

*choice
	#MamaNa must have sensed that Grog and I would betray The VS Front somehow, so she sold out Lady Venuma, Imperva, and the rest of her "allies" to save herself.
		Self-preservation is MamaNa's specialty, after all. You believe MamaNa isn't truly loyal to Queen Ashe, but rather just to the security the Wone Queen provides. If you and Grog had chosen differently in your SoulTests, you're sure that MamaNa would have let The VS Front take down The Elite Courte.
		*goto stllfoo
	#Perhaps MamaNa is telling the truth and was always a spy for Queen Ashe—I wouldn't put anything past her.
		Is MamaNa really loyal to Queen Ashe above all else? Or is she just loyal to the security that Queen Ashe provides? Either way, MamaNa has clearly chosen to side with The Elite Courte in this split—you just have to wonder how recently this decision was made.
		*goto stllfoo
	#Given what she is capable of, I'd better try to truly get MamaNa on my side—assuming such a thing is even possible.
		Is MamaNa really loyal to Queen Ashe above all else? Or is she just loyal to the security that Queen Ashe provides? If the latter is true, is there a way you could leverage the same kind of loyalty out of MamaNa somehow?
		*goto stllfoo
	#This just proves I cannot trust MamaNa, since she'll clearly sell out anyone to survive.
		Even if Queen Ashe doesn't see through MamaNa, you certainly do. You believe MamaNa isn't truly loyal to Queen Ashe, but rather just to the security the Wone Queen provides. If you and Grog had chosen differently in your SoulTests, you're sure that MamaNa would have let The VS Front take down The Elite Courte.
		*goto stllfoo

*label stllfoo
*set growth +10

No matter what, it's a very good thing you didn't choose to hide The VS Front from Queen Ashe—who knows where you'd be now if you did, given what MamaNa has done? Especially now that you have proof MamaNa's transformations can elude Queen Ashe's SoulTests.

Wait, you then think—could that have just been a lie too? If MamaNa was always secretly loyal to Queen Ashe somehow, then could the entire concept that she or you could transform beyond the SoulTest have just been a lie, cooked up to lead you down the wrong path?

Your head aches as you realize there seems to be no way to tell what's real with MamaNa—at least not yet. As this pain spreads, your brief stretch of lucidity seems to fade away, once again consumed by the flames raging across your mind. As the fiery fever closes back in, you cling to the idea that if MamaNa will always do what's in her own self-interest, at least that makes her behavior somewhat easier to predict.

*page_break
*label routedfromeliteinfo

Time blurs yet again against the flickers of flame, like shadows of reality dancing on the wall. Still, somehow you hear Queen Ashe declare that you and Grog will both eventually be named Elite Courte members, 
*if (rlshp_ashe = 95) or (rlshp_ashe = 70)
	but that you will be announced as the official winner of The Elite Trials. For now, Grog will return to The VS Front as the runner-up, to act as a temporary double agent alongside MamaNa.
*if (rlshp_ashe = 85)
	but that Grog will be announced as the official winner of The Elite Trials. For now, you will return to The VS Front as the runner-up, to act as a temporary double agent alongside MamaNa.
*comment endif

Queen Ashe believes that Lady Venuma and Imperva will simply go back into hiding if they don't think they have the votes needed for The VS Front to seize control. And Queen Ashe requires proof of Lady Venuma and Imperva's betrayal in the Versus Vote before officially casting them out of The Elite Courte, just ruler that she is. Doing things this way, Queen Ashe can also make the harshest public example of the deserters, to show any other Elite Courte members flirting with rebellion what happens if they dare try.

Then, as one experience burns into yet another, you find yourself in the Castle ballroom.
*if (rlshp_ashe = 95) or (rlshp_ashe = 70)
	There, you see yourself officially crowned as the winner of The Elite Trials, to a showering of light and Elite fanfare. While you experience your moment of shining glory, Grog plays the part of the angered and rejected loser, soon to be removed from the Castle and returned to The VS Front's open arms.

	*page_break

	Impossibly, in the next moment, you occupy a seat in the Voting Amphitheater, inside the gilded Elite skybox. You are distracted by its interior, which seems improbably larger than the exteriors you've seen, as if the rules for space exist differently within than without. Of course, the Elite skybox is every bit as glamorous, exclusive, and comfortable as you might have imagined, decorated like some of kind of royal viewing gallery.
*if (rlshp_ashe = 85)
	There, you see Grog officially crowned as the winner of The Elite Trials, to a showering of light and Elite fanfare. While Grog experiences its moment of shining glory, you play the part of the angered and rejected loser, soon to be removed from the Castle and returned to The VS Front's open arms—especially since Lady Venuma, as Ord Ambassador, is the one to escort you from the Castle.

	*page_break

	Impossibly, in the next moment, you occupy a seat in the Voting Amphitheater, down in the throned Ord section beneath the hovering Elite skybox.
*comment endif

Sitting there now, you try your best to focus your smoke-clouded mind to process the newest divisions and recall the maneuvers preceding the Voting Ceremony, which somehow drip into your mind like the first heavy raindrops of a storm.

*if breezedie
	Lady Venuma believed she had nine solid VS Front votes set against nine solid Elite votes: Lady Venuma, MamaNa, Imperva, OtherBoard, Cel, Trig, Pinkuju, The Unpronounceable One, and Baron Airon against Queen Ashe, Prince Everly, Beyhalo, Glorya, Royal A-08, Lockdown, Cadet Gadget, Oli, and the final Elite member you have yet to meet—who is apparently nicknamed Gloves…though honestly, you have absolutely no idea how you seem to know this, like everything else. 

	You also know that MamaNa had been placed under strict instruction to inform Lady Venuma that
	*if (rlshp_ashe = 95) or (rlshp_ashe = 70)
		you were actually secretly remaining loyal to The VS Front, despite your Trial victory.
	*if (rlshp_ashe = 85)
		Grog was actually secretly remaining loyal to The VS Front, despite its Trial victory.
	Given the fact that Lady Venuma had also apparently been hard at work trying to pull Todrick away from Queen Ashe's light and over to her dark side, Lady Venuma thought she had amassed a solid twelve-to-nine majority over The Elite Courte, of course, 
	*if (rlshp_ashe = 95) or (rlshp_ashe = 70)
		adding the newly returned Grog among her ranks.

		Feeling confident and believing MamaNa to also still be on her side, Lady Venuma then had MamaNa relay The VS Front's target to you… 
	*if (rlshp_ashe = 85)
		counting your newly returned self among her ranks.

		In a flash of clarity, you remember Lady Venuma standing swollen with confidence before you on the porch of the Verses Village Inn, relaying the newly set VS Front target…

	*page_break

	The jumpsuited blonde from the Alias Trial, Glorya. 

	Glorya was named the target not just because Imperva apparently greatly disliked the Elite heroine, but also because The VS Front needed to vote someone into the Match they believed would succumb to the might of the Bominate. The VS Front would have far preferred to vote Queen Ashe into the Match, as the head of the Elite snake, but they feared she'd potentially be capable of defeating the Bominate and then would simply return to regather the Courte's majority.

	Thoughts of these political machinations melt away, however, as you attempt to absorb the reality taking place before you in the Voting Amphitheater right here and now—or at least as here and now as you can discern.

	Despite the dullness of your senses, you know you won't soon forget the look on 
	*if (rlshp_ashe = 95) or (rlshp_ashe = 70)
		Lady Venuma's face beside you in the Elite skybox
	*if (rlshp_ashe = 85)
		the other Ords' faces below the skybox
	as the outcome of the third Versus Vote is finally announced…

	*page_break

	Thirteen to eight, with The Elite Courte in the majority.

	The flames then rise and recede like a wave washing over the shore, leaving your mind to only process snapshots of the new world order left in its wake:

	Lady Venuma and Imperva find themselves removed from The Elite Courte, now banished below to the Ord section. These two fallen Elites are then forced to watch as 
	*if (rlshp_ashe = 95) or (rlshp_ashe = 70)
		Grog
	*if (rlshp_ashe = 85)
		you
	and Todrick ascend to take their places. 

	Just before the tinted skybox reseals itself, an infuriated Lady Venuma and a devastated Imperva have the opportunity to look up at you, Todrick, Grog, and MamaNa nestled among The Elite Courte. The fallen women can only glimpse the faces of those who have so deftly betrayed them—and thus thwarted their own plans of betrayal.

	Given your currently limited attention, you focus on:

	*label focustime
	*choice 
		#Lady Venuma immediately vowing revenge in a golden shriek of anger.
			Lady Venuma stands among her dejected followers, who linger behind their now-dethroned Ambassador with looks of fear and shock on their faces.
			*goto qadecides
		#Grog, who beams with pride to have gone from literal rags to riches.
			*label starkcont
			This look stands in stark contrast to the remaining Ords below, who were all members of The VS Front, having joined under the assured promise of victory from their now-dethroned Ambassador. Clearly, that promise has been thoroughly broken, to their complete surprise. 
			*goto qadecides  
		*if (breezedie) #Todrick, who you know had dreamed of joining The Elite Courte and serving Queen Ashe since his earlier arrival on Versus.
			*goto starkcont
		#The rest of the Ords gathered below, all of whom look completely shocked. 
			The other Ords gathered here were all members of The VS Front, having joined under the assured promise of victory from their now-dethroned Ambassador. Clearly, that promise has been thoroughly broken, to their complete surprise.
			*goto qadecides 
*if todrickdie
	Lady Venuma believed she had ten solid VS Front votes set against nine solid Elite votes: Lady Venuma, MamaNa, Imperva, Breeze, OtherBoard, Cel, Trig, Pinkuju, The Unpronounceable One, and Baron Airon against Queen Ashe, Prince Everly, Beyhalo, Glorya, Royal A-08, Lockdown, Cadet Gadget, Oli, and the final Elite member you have yet to meet—who is apparently nicknamed Gloves…though honestly, you have absolutely no idea how you seem to know this, like everything else. 

	You also know that MamaNa had been placed under strict instruction to inform Lady Venuma that
	*if (rlshp_ashe = 95) or (rlshp_ashe = 70)
		you were actually secretly remaining loyal to The VS Front, despite your Trial victory. Then, adding Grog, 
	*if (rlshp_ashe = 85)
		Grog was actually secretly remaining loyal to The VS Front, despite its Trial victory. Then, adding you,
	newly returned to her ranks, Lady Venuma thought she had amassed a solid twelve-to-nine majority over The Elite Courte.

	*if (rlshp_ashe = 95) or (rlshp_ashe = 70)
		Feeling confident and believing MamaNa to also still be on her side, Lady Venuma then had MamaNa relay The VS Front's target to you… 
	*if (rlshp_ashe = 85)
		In a flash of clarity, you remember Lady Venuma standing swollen with confidence before you on the porch of the Verses Village Inn, relaying the newly set VS Front target…
	
	*page_break

	The jumpsuited blonde from the Alias Trial, Glorya. 

	Glorya was named the target not just because Imperva apparently greatly disliked the Elite heroine, but also because The VS Front needed to vote someone into the Match they believed would succumb to the might of the Bominate. The VS Front would have far preferred to vote Queen Ashe into the Match, as the head of the Elite snake, but they feared she'd potentially be capable of defeating the Bominate and then would simply return to regather the Courte's majority.

	Thoughts of these political machinations melt away, however, as you attempt to absorb the reality taking place before you in the Voting Amphitheater right here and now—or at least as here and now as you can discern.

	Despite the dullness of your senses, you know you won't soon forget the look on 
	*if (rlshp_ashe = 95) or (rlshp_ashe = 70)
		Lady Venuma's face beside you in the Elite skybox
	*if (rlshp_ashe = 85)
		the other Ords' faces below the skybox
	as the outcome of the third Versus Vote is finally announced…

	*page_break

	Twelve to nine, with The Elite Courte in the majority.

	The flames then rise and recede like a wave washing over the shore, leaving your mind to only process snapshots of the new world order left in its wake:

	Lady Venuma and Imperva find themselves removed from The Elite Courte, now banished below to the Ord section. These two fallen Elites are then forced to watch as
	*if (rlshp_ashe = 95) or (rlshp_ashe = 70)
		Grog ascends
	*if (rlshp_ashe = 85)
		you ascend 
	to take their place.

	Just before the tinted skybox reseals itself, an infuriated Lady Venuma and a devastated Imperva have the opportunity to look up at you, Grog, and MamaNa nestled among The Elite Courte. The fallen women can only glimpse the faces of those who have so deftly betrayed them—and thus thwarted their own plans of betrayal.

	Given your currently limited attention, you focus on:
	*goto focustime 

*label qadecides

But you find that no one looks more shocked about this turn of events than the new target of The Elite Courte's vote.

You remember now that this target was decreed directly by Queen Ashe herself, who decided to skip the usual Elite debate and discussion given the severity of the last-minute revelations. Queen Ashe set the next target entirely on her own, informing all you Elite Courte members, one way or another, that you were to vote for…

*page_break

*if breezedie
	*set deathtwo "Baron Airon"

	Baron Airon, the power-hungry slave owner.

	The color has now drained from Baron Airon's olive skin, as he has no doubt realized that he will be next to face the Destructive Un-Thing, the monstrous Bominate. 

	It seems that Baron Airon will be the first to fall as punishment for the treachery of The VS Front.
*if todrickdie
	*set deathtwo "Breeze"

	Breeze. Which makes sense, since after all Breeze only eluded the first Versus Vote by convincing Todrick to sacrifice himself.

	*if (officialbreeze) or (officialthruple)
		Hearing this news, you feel the distinct weight of your heart falling into your stomach, despite your general numbness. You had obviously already decided to turn your back on Breeze by 
		*if (rlshp_ashe = 70)
			ignoring the political realities, but would you have gone through with this if you had known it meant a death sentence for your one-time romance?
			*goto thrupover
		*else
			joining The Elite Courte, but would you have gone through with this if you had known it meant a death sentence for your one-time romance? After everything you've done to maneuver against Lady Venuma, perhaps you were hoping the demigoddess would be the first target.
			*goto thrupover
	
	*label thrupover

	Now the color has drained from Breeze's already pale blue skin, as ${breze} has no doubt realized that ${breze} will be next to face the Destructive Un-Thing, the monstrous Bominate.

	Breeze will be the first to fall as punishment for the treachery of The VS Front, along with the still-secret sins of ${brehis} past.

*page_break

You're not sure this is particularly fair, given Lady Venuma's key role in instigating the entire rebellious movement, but you can understand why Queen Ashe first required tangible evidence of Lady Venuma's treachery before formally targeting one of her own Elites. 

Now that Queen Ashe has this proof, however, 
*if mntellsbom 
	you wouldn't be surprised if she sentenced Lady Venuma and Imperva to similar fates before asking MamaNa to finally step in against the Bominate…unless she and MamaNa plan to eliminate the entire guilty VS Front before doing so.
*if (mntellsbom = false)
	you wouldn't be surprised if she sentenced Lady Venuma and Imperva to similar fates immediately after—that is, assuming MamaNa doesn't act on her Bominate creation truth before then, one way or another.
*comment endif

The psychic flames begin to scorch your consciousness once again, so you are forced to leave these proceedings on one final thought: Queen Ashe's Elite victory seems to reign crushingly and completely—thanks in no small part to your own efforts.

*page_break Consumed
*achieve eliteneworldorderac

*label wakeupmatch

When your mind awakens next, you mostly expect to find yourself in your new home. Or perhaps in your second night of MemoryTravel, once again alongside the Princess of Ashes on planet Wone. Or even better, on the morning of day ten on Versus, completely cleansed of Queen Ashe's full absorb.

Instead, you wake up to find yourself sitting in the bleachers outside the dreaded arena, evidently attending the third Versus Match. It's hard to tell at first, since the arena has transformed itself yet again, this time into some kind of exotic jungle setting. Then you spot ${deathtwo} standing underneath the hanging leaves of a sunken pink palm tree, and you know for sure this must be the arena.

Trying to come to grips with the new version of reality presented, you decide this must mean that you've now skipped to the afternoon of day ten. Unfortunately, the absorption fever still burns your mind, even though Queen Ashe's full absorb was supposed to wear off on the morning of day ten. Something about this potent full absorb must be lasting longer than usual, even into the afternoon…

At least, that's what you hope. You can't help but wonder if you're now stuck like this forever, doomed to live out your life like a flickering shadow cast from Queen Ashe's light.

You're distracted from this grim thought, however, as something far more troubling takes place before your eyes…

*page_break

You see the Bominate striding forward, the green of its rusted metal joints now covered by several faded animal skins—which still maintain patches of spindly fur. You can't help but notice that the Bominate sports another tally mark on the faceplate that covers its metallic skull, newly scrawled since claiming ${deathone}'s life.

You listen with a shudder as the cosmic buzzer sounds and the Bominate begins to approach ${deathtwo} with deadly determination. There's a flash of fire, and it's impossible for you to tell if it's real or in your mind—but when it clears, you gasp at the sight of the Bominate quickly and steadfastly eviscerating
*if coupnwo
	*goto backtogroggy
*if breezedie
	Baron Airon in a streak of blood, bone, and acid.

	Within the span of a few seconds, you watch as the number of Constructive Versians dwindles from twenty-three to twenty-two, just like that.

	*page_break
	*achieve deathbaronac

	Witnessing Baron Airon's sudden and brutal death, your first thought, weirdly and numbly, is that you'll now have to full absorb one of his fellow Blarfngardians, Lockdown or Grog or Todrick, to hopefully disprove that Baron Airon was Dhanthik's assumed identity. Your mind can't seem to focus on anything else, given the enormity of the loss you're currently faced with.

	Then, as the reality of this loss does seem to hit you, your second thought is that
	*if (officialairon) or (aironhookup)
		you'll never get to hook up with Baron Airon again. 

		There will never be a chance to do anything with Baron Airon, ever again. 

		You suppose you had already made peace with this kind of an outcome when you chose The Elite Courte over The VS Front.
		*if (rlshp_ashe = 70)
			Even if this wasn't your original intention by choosing to avoid the politics, it seems that even the most apolitical decisions on Versus will still have ripple effects.
		*if officialairon
			You effectively negated your decision to pursue a romance with Baron Airon when you went Elite, obviously deciding there were more important factors in play. But if you had known Baron Airon would be the first target of The Elite Courte, might you have decided differently?

			You don't even want to consider how betrayed and overlooked Baron Airon might have felt seeing you whisked away into The Elite Courte while he was left behind, doomed to die.
		
		*page_break 

		And even though it wasn't your decision specifically to target Baron Airon, you knew by joining The Elite Courte you'd be condemning someone in the newly formed Ord minority. You do wish you had been lucid enough to perhaps advocate on Baron Airon's behalf to Queen Ashe, but then you remind yourself that sooner or later, Baron Airon might've faced a similar fate.

		*set rlshp_airon %-75
	*if (officialairon = false) or (aironhookup = false)
		you'll never see Baron Airon again, for better or worse.

		You suppose you had already made peace with this kind of an outcome when you chose The Elite Courte over The VS Front. 
		*if (rlshp_ashe = 70)
			Even if this wasn't your original intention by choosing to avoid the politics, it seems that even the most apolitical decisions on Versus will still have ripple effects.
		Perhaps you hadn't anticipated that this specific scenario would include the death of Baron Airon—but still, you knew someone among the newfound Ord minority would have to fall against the Bominate.
		*set rlshp_airon %-50
	*comment endif

	These kinds of what-ifs don't really matter much now, you remind yourself. Because Baron Airon is dead, any way you analyze it. 

	As the finiteness of Baron Airon's demise threatens to consume you as surely as the flames, you can only feel:

	*choice
		*if (officialairon) #Heartbroken—I had real feelings for Baron Airon. And he died knowing that I betrayed him.
			*goto wakeupnwoeli
		#Sad—I'll truly miss Baron Airon. He deserved the chance to evolve and change his ways, just like every other Versian.
			*goto wakeupnwoeli
		#Justified—Baron Airon got what he deserved, considering his snobbish and entitled ways.
			*goto wakeupnwoeli
		#Resolved—no other Versian should have to die at the Bominate's hands ever again. Not while MamaNa still breathes.
			Even if that means you have to full absorb MamaNa's abilities and attempt to destroy the Bominate yourself, you'll make sure it falls, one way or another.
			*goto wakeupnwoeli
		#Ambivalent—after all, someone must fall in the Versus Matches. If it weren't Baron Airon, it would simply have been someone else.
			*goto wakeupnwoeli
*else
	Breeze in a streak of blood, bone, and acid.

	Within the span of a few seconds, you watch as the number of Constructive Versians dwindles from twenty-three to twenty-two, just like that.

	*page_break
	*achieve deathbreezeac

	Witnessing Breeze's sudden and brutal death, your first thought is that you'll now have to full absorb Glorya in order to hopefully disprove that Breeze was Dhanthik's assumed identity. And just like your knowledge of the Elite member Gloves, you have no idea how you've come to know that Glorya hails from Breeze's planet—you suppose you must be picking up some ambient knowledge through your feverish fugue somehow.

	Admittedly, this is a strange and numb first thought to have, but your mind can't seem to focus on anything else, given the enormity of the loss you're currently faced with.

	Then, as the reality of this loss does seem to hit you, your second thought is that
	*if (officialbreeze) or (officialthruple)
		you'll never get the chance to see what you and Breeze could have been.

		You suppose you gave up on this romance the moment you decided to join The Elite Courte over The VS Front. 
		*if (rlshp_ashe = 70)
			Even if this wasn't your original intention by choosing to avoid the politics, it seems that even the most apolitical decisions on Versus will still have ripple effects. When someone must face the arena every three days, even abstaining has consequences.
		You effectively negated your decision to pursue a romance with Breeze, obviously deciding there were more important factors in play.

		*page_break 

		You don't even want to consider how betrayed and overlooked Breeze must have felt seeing you whisked away into The Elite Courte while ${breze} was left behind, doomed to die.

		*if thruple
			Then again, you remind yourself that Breeze wasn't exactly honest with you either, lying about ${brehis} relationship with Lady Venuma, ${brehis} secret past, and who knows what else. You may have accepted your invitation to this thruple initially, but obviously that invitation has now been declined, loudly and clearly.
		*comment endif 
		
		And even though it wasn't your decision specifically to target Breeze, you knew by joining The Elite Courte you'd inevitably be condemning someone in the newly formed Ord minority. You still wish you had been lucid enough to try advocating on Breeze's behalf to Queen Ashe, but immediately that thought strikes you as ridiculous. What else did you really expect would happen to Breeze, knowing that ${breze} was already in the crosshairs of the Elite? 
		*set rlshp_breeze %-75
	*if (officialbreeze = false) or (officialthruple = false)
		you'll never see Breeze again, for better or worse.

		*page_break

		You suppose you had already made peace with this kind of an outcome when you chose The Elite Courte over The VS Front. 
		*if (rlshp_ashe = 70)
			Even if this wasn't your original intention by choosing to avoid the politics, it seems that even the most apolitical decisions on Versus will still have ripple effects. When someone must face the arena every three days, even abstaining has consequences.
		Perhaps you hadn't anticipated this specific scenario including the death of Breeze—but still, you knew someone among the newfound Ord minority would have to fall against the Bominate. And really, what else did you expect would happen, knowing that Breeze was already in the crosshairs of the Elite? 
		*set rlshp_breeze %-50
	*comment endif

	These kinds of what-ifs don't really matter much now, you remind yourself. Because Breeze is dead, any way you analyze it. 

	As the finiteness of Breeze's demise threatens to consume you as surely as the flames, you can only feel:

	*choice
		*if ((officialbreeze) or (officialthruple)) #Heartbroken—I had real feelings for Breeze. And ${breze} died knowing that I betrayed ${brehir}.
			*goto wakeupnwoeli
		#Sad—I'll truly miss Breeze. $!{Breze} deserved the chance to evolve and grow, just like every other Versian.
			*goto wakeupnwoeli
		#Justified—Breeze got what ${breze} deserved for scheming and sacrificing Todrick.
			*goto wakeupnwoeli
		#Resolved—no other Versian should have to die at the Bominate's hands ever again. Not while MamaNa still breathes.
			Even if that means you have to full absorb MamaNa's abilities and attempt to destroy the Bominate yourself, you'll make sure it falls, one way or another.
			*goto wakeupnwoeli
		#Ambivalent—after all, someone must fall in the Versus Matches. If it weren't Breeze, it would simply have been someone else.
			*goto wakeupnwoeli

*label wakeupnwoeli

Within the span of another fiery second, you find yourself back before the silverized statues of the Memorial Garden. You attempt to find some measure of calm amidst the stillness of the statues, which seem to resonate with the spirits lost in the beautiful and wretched Versus process.

It almost reminds you of the Priscan Memorial Mount, a mirrored temple that resonates with the memories of lost ones uploaded to the Collective Consciousness. Most Priscans believe that those who pass are never truly lost, since Priscan absorption abilities allow a part of the dead to live on not only within their loved ones, but also within the Memorial Mount. 

Part of you wishes you could have full absorbed ${deathtwo} before this Match, just the way you did with ${deathone} before the first Match…but you suppose if there's no Memorial Mount here on Versus, this peaceful and eerie garden will have to do. 

Especially as you now you stand before the statue newly erected to honor Versus's latest victim: 

${deathtwo}.

*page_break

Thankfully, in the space of the very next moment, you unexpectedly find yourself under the sheets of your own bed. 

And as darkness finally closes in on the light of the flames, you feel yourself falling into blissful true sleep.

As your synapses cease to fire, you cannot decide whether you want to dream of ${deathtwo} or whether that would feel like a nightmare instead…

*page_break Hours and Hours Later
*if elitenwo
	*goto thecastleatwakey
*else
	*goto theinnatwakey

*label thecastleatwakey

When your eyes open once again, you find yourself finally feeling somewhat normal. You look to the clock beside your bed to find that this is day eleven of this Versus cycle… 

Which is also when you realize that you now reside in a far-grander Elite Castle suite than your previous guest rooms.

This multiroom wing must be what full Elite Courte member quarters are like, except you immediately find that your suite has been:

*choice
	#Covered with mirrored panels to look like my Priscan home.
		You have no idea who did the research to make this room feel so much like Prisca, but it instantly fills you with nostalgia and gratitude.
		*goto ifthisstart
	#Decorated to reflect my sorted Wone Haus and Order.
		*goto nodeagrat
	#Decorated in the color and crest of my Wone FourPath Splinter.
		*label nodeagrat
		You have no idea who took the time to personalize your suite like this, but it instantly fills you with nostalgia and gratitude.
		*goto ifthisstart
	#Decorated to look like my prized memories of ${planetname}.
		*goto nodeagrat
	#Designed in a style I already know I will redecorate personally later.
		*goto ifthisstart

*label ifthisstart

If this is the start of what it means to be Elite, perhaps all the struggle and sacrifice to make it here was truly worth it. You're rushed with a surge of excitement to explore not just your own individualized suite, but the suites of your fellow galaxy-spanning Elite counterparts.

In all your excitement, you sit up quickly and immediately feel your head swirl and spin. While it seems your Queen Ashe full absorb has finally passed, to say that you have a hangover would be quite the blerging understatement. Lying back down, you're happy to simply rest in your new bed for what feels like forever, sweating out the fire from your veins.

That is, until Ayeleen suddenly enters and pokes at you with an invitation: the Inaugural Ball of The Elite Courte, to be held in the backyard gardens.

*page_break Garden Grounded
*set rlshp_mamana %-30

The fiery resonance must still be burning in and out of your mind in hot flashes, because you see this invitation one moment, and in the next you find yourself at the actual event, dressed in a 
*if authorius
	white
*if boldure
	golden
*if commaith
	black
*if demlect
	rose-colored
party outfit evidently selected for you by Ayeleen. Looking around, you see the rest of The Elite Courte gathered together, all currently toasting with bubbling glasses as Queen Ashe makes a speech.

Trying to catch the gist of Queen Ashe's speech, you glean snippets about the "new era" of the Elite Courte, which Queen Ashe professes to be stronger than ever after facing its own recent trials. Queen Ashe also pauses to give special thanks to you and Grog for your important efforts during The Elite Trials. You feel the heat of Elite eyes on you for a moment, burning your skin instead of your mind for a change. 

As Queen Ashe continues speaking about the unwavering loyalty and strength to be found within this newly established Elite Courte roster, your still-feverish mind can't help but wander to MamaNa. Your eyes then follow suit, settling on MamaNa as she stands behind Queen Ashe once again in the shadows, looking more diminutive and considerably darker than you ever remember seeing her.

MamaNa managed to slither her way to safety by abandoning The VS Front, but you know the truth about her, even if no one else does—or at least, you think you know some version of her truth. 
*if (rlshp_ashe = 70)
	*goto badordjuju
*else
	*page_break

	Whether MamaNa remains an Elite enemy or ally remains to be seen, but for now, you know you must keep an ever-careful eye on her. For it seems that Lady Venuma is not the first Wone goddess to have been blinded by MamaNa….
	*if mamanaabolish
		And MamaNa will no doubt be keeping a close eye on you, since she divulged to you top-secret knowledge of her ulterior motives beyond the failed VS Front.
	*comment endif

	*if breezedie
		Looking at the numbers, The Elite Courte has a fully restored roster of thirteen while the shattered VS Front has only seven remaining members, including the now-ostracized Lady Venuma and Imperva. So even if MamaNa were to truly remain loyal to The VS Front, the failed rebellion would have no real hope of regaining the numbers it would take to rise again. 

		At best, if MamaNa switched back to The VS Front before the next vote and then somehow recruited Empress Vaccus and this mysterious remaining Ord, BurnBone, The VS Front would still need to convert one Elite Courte member to even achieve a tie vote. That's an incredibly unlikely scenario, but then again, you can be sure of one thing:
	*if todrickdie
		Looking at the numbers, The Elite Courte still has an incomplete roster of twelve, while the shattered VS Front has eight remaining members, including the now-ostracized Lady Venuma and Imperva. 

		So if MamaNa switched back to The VS Front before the next vote, then somehow recruited a now-embittered Empress Vaccus and this mysterious remaining Ord, BurnBone, The VS Front would be able to achieve a tie vote. That's a fairly unlikely scenario, but then again, you can be sure of one thing:
	*comment endif

	If you've thought of this potential outcome, there's no doubt that MamaNa has as well.
	*goto badordjuju

*label badordjuju
*page_break
*set rlshp_celtrig %-50
*set rlshp_pj %-50
*set rlshp_brawl %-50
*set rlshp_imperva %-50
*set rlshp_ob %-50
*set rlshp_venuma %-50

You refocus on the party as you suddenly find yourself holding up a glass of sparkling Versus wine, which has appeared in your hand as Queen Ashe holds a moment of silence in ${deathtwo}'s honor. Hearing that name still sends a tiny chill up and down your spine—and it also forces you to think of all of the other Ords you've left behind by siding with The Elite Courte…

Cel. Trig. Pinkuju. The Unpronounceable One. Imperva. OtherBoard. Lady Venuma.
*if todrickdie
	*set rlshp_airon %-50
	Baron Airon.
*comment endif

*if (officialvenuma) or (officialthruple)
	*set rlshp_venuma %-30
	Especially Lady Venuma, since you know this betrayal can only mean the end of your budding romance—and no doubt the beginning of a quest for revenge on the part of the fallen demigoddess. 
	*if lvnotokay
		You already knew, after the unacceptable monogamy mandates Lady Venuma laid out for you, that this relationship was over—at least for you.
	*if (lvnotokay = false)
		Obviously you had already decided that siding with The Elite Courte mattered more to you than Lady Venuma did.
		*if (rlshp_ashe = 70) and (officialthruple = false)
			Even if this wasn't your original intention by choosing to avoid the politics, it seems that even the most apolitical decisions on Versus will still have ripple effects.
	Even though you didn't have the chance to say this to her face, you're sure Lady Venuma has now received this particular message loud and clear.
*if officialob
	*set rlshp_ob %-30
	Especially OtherBoard, since you know this switching of sides can only mean the end of your potential romance. You wish things could have been different with OtherBoard, but obviously you had already decided that siding with The Elite Courte mattered more to you than she did. 
	*if (rlshp_ashe = 70)
		Even if this wasn't your original intention by choosing to avoid the politics, it seems that even the most apolitical decisions on Versus will still have ripple effects.
	You wish you had gotten the chance to explain yourself to OtherBoard, but you're sure she has now received this particular message loud and clear, anyway.
*if (officialairon) and (todrickdie)
	*set rlshp_airon %-30
	Especially Baron Airon, since you know this switching of sides can only mean the end of your potential romance. You wish things could have been different with Baron Airon, but obviously you had already decided that siding with The Elite Courte mattered more to you than he did. 
	*if (rlshp_ashe = 70)
		Even if this wasn't your original intention by choosing to avoid the politics, it seems that even the most apolitical decisions on Versus will still have ripple effects.
	You did really only share a one-night stand, but still, you wish you had gotten the chance to explain yourself to Baron Airon face-to-face. But you're sure Baron Airon has now received this particular message loud and clear, anyway.
*comment endif

However you feel about this group collectively or individually, you suppose you have to make peace with the thought that they will all likely resent you for your Elite ascension. But really, now that you are a member of The Elite Courte, it is also likely you won't be able to interact with any of these Ords even if you wanted to…

Unless you attempt to fill Lady Venuma's now-empty role as Ord Ambassador, assuming that Queen Ashe will even allow this position to exist, given how Lady Venuma ended up abusing its privileges. Honestly, that's not a thought you want to dwell on just yet, not after all you've been through in the last few days.

*page_break

*set rlshp_grog %+20
*if breezedie
	*set rlshp_todrick %+20
*set rlshp_everly %+20
*set rlshp_lockdown %+20
*set rlshp_cadet %+20
*set rlshp_oli %+20

*if (rlshp_ashe = 95)
	*set rlshp_ashe 98
*if (rlshp_ashe = 85)
	*set rlshp_ashe 88
*if (rlshp_ashe = 70)
	*set rlshp_ashe 78

Instead, you force yourself to focus on the potential new Elite allies you've now acquired: Queen Ashe. Prince Everly. Lockdown. Cadet Gadget. Grog. Oli.
*if breezedie
	Todrick.
And the remaining four Elites you have yet to formally meet. Whatever and whoever you may have lost in this transition, you hope you stand to gain far more among these new allies.

Actually, you wish you felt present enough right now to begin mingling with your fellow Elites, but you still feel exceptionally queasy and uneasy. You don't feel fully like yourself yet, still spacey and unfocused and weirdly dried-out. Your vision even feels a bit off, like you have to keep blinking and remoistening your eyes to see clearly. Truth be told, despite the celebratory mood, all you want to do is lie in bed again and sleep off this overwhelming feeling of exhaustion.

As much as you want to meet the Elites you don't know yet right away and fill those you do know in on all you've been through these past few days, you know that you'll have plenty of time to do so in the days to come—after all, you've now successfully secured your safety here on Versus.

Thankfully, as you melt your way through the party, the other Elites seem to understand your situation—especially considering the fact that they've all seen you walking around like a feverish zombie for the past few days. At least Queen Ashe was sure to explain your condition to her Elite subjects on your behalf, so you didn't seem like a total weirdo.

*if (officialoli = false) and (rlshp_oli > 50)
	Of course, Oli wanted to catch up with you the most, having been scandalized by the secret knowledge you've been keeping about The VS Front. However, Oli also understood the ordeal you must have gone through underneath the surface of The Elite Trials, so ${olize} let you exit—but only on the promise that you'd fill ${olihir} in on everything the moment you feel better.

*page_break

*if officiallockdown
	Making your way out of the party and back into the Castle, you suddenly realize that you are now free to enjoy your Elite experience without the constant threat of exposure or elimination. You suppose it's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	However, you're all too happy to temporarily pause this sequester when Lockdown suddenly appears and pulls you into an empty drawing room inside the Castle. Lockdown wears brown leather pants and a matching vest, left open to reveal the muscles of his hairy chest and flat stomach.
	
	"Who knew there was so much brain 'neath that pretty head o' ya'rs," Lockdown says. "Think'n ah thought ya were sexy as spit before, but now…."

	Lockdown speaks with his lips hovering right beyond yours, his breath catching on your lower lip. Your skin starts to tingle, especially as Lockdown begins kissing the base of your neck, his stubble brushing against you in rough patches.

	*choice
		#Lockdown is obviously aggressive—and I really like it.
			*goto waittoexhile
		#I don't want to stop this for one second, so I'll let Lockdown keep going.
			*goto waittoexhile
		#Stop Lockdown—I want to move a bit more slowly.
			*goto luvmedown 

	*label waittoexhile

	You exhale from the feeling of Lockdown's soft lips on your skin, while his impossibly hard body presses into you. Then you inhale sharply as Lockdown pins both of your arms above your head, against the wall. You try for a moment to get your bearings, because this is moving rather quickly—but then again, what on Versus hasn't? Besides, you deserve some kind of reward for all that you've been through.

	So when Lockdown kisses you on the mouth, you let him, finding that he tastes as salty and strong as ever. He pauses for a moment, as if surprised by how fiery you suddenly taste—and by how much he seems to like it. You swear you see fireworks of pink energy cascading around you as Lockdown trails his hands down your arms, then across your chest… and down to your waist, where he begins to take off your party clothes.

	Then Lockdown's lips follow his hands, trailing lower and lower until you feel your own fireworks exploding.

	*choice
		#Give in to Lockdown and let him finish.
			*set rlshp_lockdown %+25

			*label watchadold
			Whatever this means for your relationship with Lockdown—and inevitably Cadet Gadget, as well—you know can sort it out later. For now, you plan to enjoy this moment, very much.

			Twice.

			Well, maybe three times.
			*goto finaletime
		#Return the favor to Lockdown.
			*set rlshp_lockdown %+30
			*goto watchadold
		#Okay, now it's time to slow things down.
			*label luvmedown 
			*set rlshp_lockdown %+20
			So after a few more indulgent seconds, you step away from Lockdown.

			"That's enough for now," you say, smiling. "If we're going to do more, you're going to have to take me on a date first. Deal?"

			"If't means more time with ya," Lockdown says, smirking right back. "Ya got a deal."

			After that, it takes every inch of your willpower to step away from Lockdown and leave him here… 

			But you do, very much looking forward to your next encounter.
			*goto finaletime
*elseif officialgadget
	Making your way out of the party and back into the Castle, you suddenly realize that you are now free to enjoy your Elite experience without the constant threat of exposure or elimination. You suppose it's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	However, you're all too happy to temporarily pause this sequester when Cadet Gadget suddenly appears and pulls you into an empty drawing room inside the Castle. He wears his standard GCC uniform, and you'd bet he never wears anything else, perfect soldier that he is.

	"Hey, I know you're exhausted, so I won't keep you long," Cadet Gadget begins, seemingly unable to lift his eyes from the floor. "I just…I can't believe what you must have gone through these last few days under the surface of the Trials, as if those aren't stressful enough on their own. You were remarkably collected, and actually, you'd probably make a great GCC officer."

	Cadet Gadget looks up at you then, smiling sheepishly as if every moment of this exchange pains him. He speaks all of this in one sentence and in a single breath, but now he pauses to inhale and slow down.

	*page_break

	"I'm sorry, I ramble when I'm nervous," Cadet Gadget tries, finally exhaling. "What I really came here to say is…thank you. For choosing the side you did, for choosing us. And I'm happy you're one of us now. And…"

	Cadet Gadget pauses again, his translucent teeth and hair beginning to blush along with his cheeks. The sight of his glowing face is so cute to you it almost hurts.

	"I thought about what you said. And I want to get to know you better too, if that's okay."

	Hearing these words from Cadet Gadget, you instantly light up inside—though in a very different way than you've been experiencing lately.

	*choice
		#Step up and kiss Cadet Gadget as my answer.
			*set rlshp_cadet %+25

			Feeling fiery courage surge through your body, you step forward and kiss Cadet Gadget right on the lips. 

			He seems incredibly surprised at first, almost as surprised as you are for taking this bold step. But as the seconds tick by like hours, Cadet Gadget eventually leans into it. 

			And into you.

			*page_break

			After several minutes of what feels like blissful hours, you pull yourself away, not wanting to go too far too fast. Besides, you already feel the threat of the internal fire resurfacing again, and the last thing you want to be around Cadet Gadget is groggy. 

			So, wanting to remember every moment of your time with the young Cadet, you take another step back and simply answer:

			"Yes. I'd like that very much."

			And the smile that lights up Cadet Gadget's face is all the answer you need in return.
			*goto finaletime
		#Tell Cadet Gadget I'd like that, too.
			*set rlshp_cadet %+30

			"Yes. I'd like that very much," you say, smiling warmly at Cadet Gadget.

			*label tellcutie

			At first, the young Cadet seems stunned to hear you say this, even though you thought you'd made this pretty clear before. But then, the smile that lights up Cadet Gadget's face is all the answer you need in return.

			So you step away, feeling confident and grateful that you might get to be the one to show Cadet Gadget what it's like to be desired for the first time, despite all of his galactic experience.
			*goto finaletime
		#Tell Cadet Gadget how cute I think he is.
			*set rlshp_cadet %+20
			You say the words and immediately feel self-conscious—though you soon find there is no need to feel that way at all.
			*goto tellcutie
*elseif officialeverly
	Making your way out of the party and back into the Castle, you suddenly realize that you are now free to enjoy your Elite experience without the constant threat of exposure or elimination. You suppose it's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	However, you're all too happy to temporarily pause this sequester when Prince Everly suddenly appears and pulls you into an empty drawing room inside the Castle. He wears skinny black denim pants and a brand new rose-colored leather jacket, opened as usual to display his impressive amulet.

	"I can tell how tired you are, so I won't keep you," Prince Everly says in that smooth, buttery voice of his. "It's good to talk outside of MemoryTravel, by the way. And maybe it's Queen Ashe's radiance wearing off, but you somehow seem…different."

	Prince Everly looks at you then in a way you've never been looked at before—like he is seeing you for the first time. Like somehow you're more beautiful than he could have imagined. Which is odd, or perhaps meaningful, given the fact he helped create you in the first place. Could Prince Everly ever have expected someone like you to rise so high, to the highest heights of both Versus and Wone?
	*if (demlect) and (orderworks)
		Could it be that, as a fellow Demlect member of the Haus of Creation, Order of Works, you are his true soulmate?
		*goto peelitedidfor
	*elseif (demlect) and (hauscreation)
		Could it be that, as a fellow Demlect member of the Haus of Creation, you are his soulmate?
		*goto peelitedidfor
	*elseif (demlect)
		Could it be that, as a fellow Demlect, you are truly a match for him?
		*goto peelitedidfor
	*elseif (orderworks)
		Could it be that, as a fellow member of the Haus of Creation, Order of Works, you are truly a match for him?
		*goto peelitedidfor
	*elseif (hauscreation)
		Could it be that, as a fellow member of the Haus of Creation, you are truly a match for him?
		*goto peelitedidfor
	*else
		*goto peelitedidfor

	*label peelitedidfor
	*page_break	

	"What you did for the Elite—none of us are going to forget it anytime soon," Prince Everly says. "Especially not me. I want to hear all about it, but it can wait until you've had time to rest. In the meantime, I wanted you to have this."

	Prince Everly waves his hand in a flash of warm lavender light, and suddenly a metallic rose pin appears in his palm. Prince Everly then comes close, smelling of body oil and freshly cut flowers, to pin the lovely creation on your party clothes. 

	"Just a small token of my appreciation," Prince Everly says, his lips lingering dangerously close to yours. "And hopefully a symbol of things to come."

	*choice
		#Tell Prince Everly thanks in return, and that I'd like that very much.
			*set rlshp_everly %+20
			You say the words and feel Prince Everly's pride and desire floating through the air almost tangibly.
			*goto everlinger
		#Let Prince Everly stay as close as possible.
			*set rlshp_everly %+30

			Standing so close, you can feel Prince Everly's pride and desire floating through the air almost tangibly.

			*label everlinger

			For a moment you think that Everly, the gorgeous Wone Prince of creative wonder, this desired influencer of his people, might kiss you. 

			But then he steps back, exhaling and smiling so widely that his eyes crease with lavender light.

			*page_break

			Then he is gone in a flash of light, just like that, leaving you with nothing but hope and longing.

			You suppose this delay is for the best, because you want to be totally clear-headed around Prince Everly, completely capable of remembering every second. 

			It's not every day you get to meet your maker, let alone love him.
			*goto finaletime
		#Open up my emotions to Prince Everly, just like he is opening up his.
			*set rlshp_everly %+25
			As you open up your own feelings, you can sense Prince Everly's pride and desire floating through the air almost tangibly.
			*goto everlinger
*elseif officialoli
	Making your way out of the party and back into the Castle, you suddenly realize that you are now free to enjoy your Elite experience without the constant threat of exposure or elimination. You suppose it's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	However, you're all too happy to temporarily pause this sequester when Oli suddenly appears and pulls you into an empty drawing room inside the Castle.

	"So, it seems I'm not the only one who knows how to keep a secret," Oli says once ${olize} gets you alone. Thankfully, you find that Oli wears a smile as ${olize} says this. 

	You thought Oli might be upset with you for keeping the secret threat of The VS Front from ${olihir}, but instead Oli only seems more impressed…and interested.

	*page_break

	"Looks like we both have a lot of explaining to do, but I can tell you're still pretty out of it," Oli adds. "You've been fairly icy for a fired-up absorber these past few days, though I guess now I know what it must be like talking to someone when they're in brainplane autopilot mode. Anyway, the good news?"

	Oli then steps close to you, so close that you can almost see right through those crystal-clear eyes of ${olihis}. Your whole body buzzes and butterflies rise out of your stomach, just standing with Oli like this. You can't help but wonder: what on earth would it feel like if you ever got to be closer, to feel closer, to Oli?

	"Now that you're Elite and you've saved us both, we have all the time in this world, don't we?" Oli says.

	*choice
		#Stand here and see what Oli does next, because I'm too nervous to do anything else.
			*set rlshp_oli %+25

			*label olilead
			You may pause, but thankfully Oli doesn't seem to hesitate for anything.

			Instead,
			*if oliasexual
				Oli decides to step forward and pull you into a hug, perhaps the warmest one of your life. 

				Then Oli just holds you close, given your mutual desire to keep your budding relationship nonphysical.
			*if (oliasexual = false)
				Oli decides to step forward and kiss you.

				As ${olihis} lips touch yours, it suddenly feels like a puzzle piece falling into place. Like everything you could have ever wanted now opens up to you in this very moment.

				Kissing Oli is the best feeling you've ever felt, without a doubt.

			*label oliut
			*page_break

			You have no way to tell how much time passes, but it feels far too soon when Oli decides to step back and leave you in the drawing room.

			"See you soon, ${name}," Oli says, closing the door before you even have a chance to know what hit you.

			Even though this moment lasts nowhere near as long as you'd like, being this close to Oli still feels like the best thing in the world. Or any world, for that matter.

			And thanks to all you've accomplished, you can now look forward to a future where you and Oli can finally be as close as you want.
			*goto finaletime
		#Leave Oli hanging, to continue this game of cat and mouse we have going.
			*set rlshp_oli %+20
			*goto olilead
		#Hug Oli, just to have ${olihir} physically close, instead of the usual mental brainplane connection.
			*set rlshp_oli %+30

			You don't hesitate to step forward, pulling Oli into perhaps the warmest hug of your life. 
			
			*if oliasexual
				Then you do nothing but hold Oli close, given your mutual desire to keep your budding relationship nonphysical.
			*if (oliasexual = false)
				Then you do nothing but hold Oli close, relishing the opportunity to be this near to ${olihir} after all this time.
			*comment endif

			You have to admit, no brainplane experience could ever come close to topping this.
			*goto oliut
*else
	You are then able to make it out of the Inaugural Ball unscathed, feeling particularly happy to not have any specific obligations to anyone or anything for the first time in days.

	You are now free to enjoy your Elite experience without the constant threat of exposure or elimination—though you suppose it's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	Still, you know that once you have recovered fully from your full absorb hangover, you are most looking forward to spending time with:

	*choice
		#Queen Ashe.
			*set rlshp_ashe %+10
			*goto finaletime
		#Prince Everly.
			*set rlshp_everly %+10
			*goto finaletime
		#Oli.
			*set rlshp_oli %+10
			*goto finaletime
		#Lockdown.
			*set rlshp_lockdown %+10
			*goto finaletime
		#Cadet Gadget.
			*set rlshp_cadet %+10
			*goto finaletime
		#Grog.
			*set rlshp_grog %+10
			*goto finaletime
		*if (breezedie) #Todrick.
			*set rlshp_todrick %+10
			*goto finaletime
		#The other Elites I have yet to meet.
			*set rlshp_ashe %+10
			*goto finaletime

*label thecoupoutcomes
*if (rlshp_ashe = 65)
	Time blurs yet again against the flickers of flame, like shadows of reality dancing on the wall. You suddenly find yourself back in the ballroom of the Elite Castle. Evidently you have returned from MemoryTraveling, which must make this…day nine on Versus? If that's really true, could this then be the announcement of the Trials winner?

	You realize that, in all the confusion of your feverish haze, you hadn't thought to worry much about whether you passed Queen Ashe's SoulTest. Contemplating the state of your existence obviously took precedence, but now you remind yourself how important the results of this Test remain to your future on Versus.

	The reminder seems to snap reality into focus for the next few beats…

	*page_break

	Looking around, you find that the entire Elite Courte sits gathered before you, though you realize no one is looking at you…

	Because Queen Ashe is currently crowning Grog as the official winner of The Elite Trials. 

	While Grog experiences a moment of shining glory to a showering of light and Elite fanfare, you merely play the part of the angered and rejected loser—because you never really wanted to win the Trials in the first place. 

	Instead, as one experience burns into another, you soon find yourself cast out of the Castle and returned to The VS Front's open arms, where you know you truly belong.

	*page_break 

	Next, in another flash of clarity, you sit on the porch of the Verses Village Inn beside Lady Venuma, who has much to tell you. Apparently, sometime before the all-important SoulTests, both Lady Venuma and MamaNa realized they had lost Grog to the allure of The Elite Courte—a turn of events you had rather deftly suspected yourself. So, left with no other choice, the two VS Front founders took the bold step to mind-wipe Grog—something you didn't even know either of them was capable of. 

	Apparently Lady Venuma and MamaNa were able to utilize their coercive and transformative expertise to temporarily alter Grog's mind, since according to Lady Venuma, its composition was still rather simplistic. As a result, Grog would have no memory of its involvement in the VS Front during its SoulTest. Thus Grog couldn't expose The VS Front willingly, and Queen Ashe wouldn't be able to detect the Front's existence while reading Grog's intentions. 

	MamaNa was then sure to set a private meeting with Queen Ashe directly after the SoulTests—and as far as MamaNa could tell, Queen Ashe had no knowledge of The VS Front. Which of course meant that Grog's mind-wipe had obviously held—and that you must have passed your own SoulTest, too. 

	*page_break

	Despite your desire to celebrate, Lady Venuma is quick to inform you that, while this trick might have worked for now, it isn't guaranteed hold Grog much longer. And there's no telling what Grog will reveal if it remembers The VS Front and what MamaNa and Lady Venuma did to it before the upcoming vote.

	As a result, Lady Venuma then tells you that The VS Front's first voting target will indeed be Grog. Not only is Grog a ticking time bomb capable of exploding with revelations about The VS Front's inner workings, but Baron Airon has evidently also demanded Grog be the target. Apparently, in the VS Front meeting that took place to decide the first Elite target, Baron Airon threw a fit and refused to vote for anyone other than Grog, who he feels has committed the ultimate betrayal as a slave by rising in The Elite Trials and abandoning him. 

	Despite Baron Airon's clearly egotistical motivations, Lady Venuma explains she was fine to set Grog as the target because truly, she too resents Grog for its betrayal, after all she had done to help it. What's more, Lady Venuma explains, The VS Front needs to vote someone into the Versus Match that they believe will succumb to the might of the Bominate. The VS Front would far prefer to vote Queen Ashe into the Match, as the head of the Elite snake, but they fear she'd potentially be capable of defeating the Bominate and then would simply return to regather the Courte's majority.

	Obviously you missed the VS Front target-setting meeting because you were still in The Elite Castle, but how do you feel about this decision now?

	*choice
		#I agree with targeting Grog, for all of the reasons Lady Venuma already listed.
			*goto lvringring
		#There are other Elites I'd much rather target over Grog.
			*label grogdissent
			Your convoluted and monosyllabic attempt at expressing this sentiment is noted by Lady Venuma, but she reminds you that the decision has already been set and that it is too late to reverse. You suppose you just have to hope for more input in the next Versus Vote—that is, assuming The VS Front can indeed secure the majority first. 
			*goto lvringring
		#I'm happy Grog is being targeted, since it betrayed me by selling out to The Elite Courte too.
			*goto lvringring
		#I don't want to see Grog be voted in, no matter what.
			*goto grogdissent

	*label lvringring

	Lady Venuma's words ring in your ears as suddenly time burns once again, like the moments are welded together. Impossibly, the Inn porch is soon replaced by the Voting Amphitheater, where you find that you occupy a seat in the throned Ord section below the hovering Elite skybox. Sitting there now, you try your best to focus your smoke-clouded mind to remember the newest divisions…

	Currently Queen Ashe and Lady Venuma must both believe that they have accumulated the votes necessary to claim the majority. Doing a mental tally, you can assume that The Elite Courte undoubtedly has ten votes: Queen Ashe, Prince Everly, Beyhalo, Glorya, Royal A-08, Lockdown, Cadet Gadget, Oli, Grog, and the final Elite member you have yet to meet—who is apparently nicknamed Gloves…though honestly, you have absolutely no idea how you seem to know this. 

	Going one step further, you know that Queen Ashe actually believes she has thirteen votes, counting MamaNa, Lady Venuma, and Imperva. 

	*page_break

	However, if all goes according to plan, The VS Front should actually have the eleven votes necessary to override the Elite's solid ten votes: along with Lady Venuma, Imperva, and MamaNa's secret votes, The VS Front also has you, OtherBoard, Cel, Trig, Pinkuju, The Unpronounceable One, Baron Airon, and
	*if breezedie
		Todrick, who apparently has joined after a lengthy and lavish recruitment effort from Lady Venuma. You'd love to hear how Lady Venuma pulled that one off, given Todrick's supposedly singular devotion to Queen Ashe, but you know that will have to be a story to save for another day.
	*if todrickdie
		Breeze. 
	*comment endif 

	Given these numbers, The VS Front should succeed in stealing the majority at this third Versus Vote, though you realize how tenuous that position truly remains. All it would take for the entire operation to crumble is one of your members deciding to switch sides to try and gain an Elite spot…

	Thoughts of these political machinations melt away, however, as you attempt to absorb the reality taking place before you in the Voting Amphitheater right here and now—or at least as here and now as you can discern.

	*if fierydeath
		*page_break

		"I have a special announcement to make before the third Voting Ceremony of this great Versus cycle," Queen Ashe's light-laden voice suddenly rings out, even though she remains hidden from view in the Elite skybox. "During ${name} Thomil's SoulTest, I immediately doubted the sincerity of ${youhis} projected intention, so I probed beneath ${youhis} protective layers and uncovered ${youhis} allegiance to an Ord rebellion named The VS Front."

		You didn't think it was possible for your skin to burn any hotter, but as the eyes of the other Ords fall upon you, you feel as if your body has been set ablaze along with your mind. Everyone down here in the Ord section is involved in The VS Front—though no one is involved more deeply than Lady Venuma, Imperva, and MamaNa, who must all be feeling equally terrified up in the Elite skybox.

		Fathers Below, you think—how could that have happened? And blerg, what will happen next?

		"Directly after Grog passed its SoulTest and ${name} failed ${youhis} own, MamaNa revealed to me that she had been secretly embedding herself within The VS Front as my own loyal agent from its inception. This claim was then corroborated by MamaNa's own SoulTest, which confirmed the sincerity of this intent."

		*page_break

		Of course MamaNa claimed this—despite what she told Lady Venuma, MamaNa must have somehow sensed that Queen Ashe had learned about The VS Front from your SoulTest, so she changed her story to save herself at the last minute. Unless it's true that MamaNa has always been secretly loyal to Queen Ashe, working as a double agent within The VS Front…and if that's true, then you don't know who or what to believe is real.

		"MamaNa also revealed to me that ${name} Thomil is the primary ringleader of The VS Front," Queen Ashe then says, sending a jolt straight through your body. "Of course, MamaNa's words only confirmed what I already knew to be true about ${name} from ${youhis} SoulTest."

		Hearing this hateful lie, thoughts race through your mind: has MamaNa sold you out to protect Lady Venuma and Imperva? Or has she told Queen Ashe about their involvement as well? No matter what MamaNa has said, you know the truth: she and Lady Venuma were the original ringleaders of The VS Front.

		"No," you try to say, hearing your own voice sound thin and weak.  "I was—"

		"Silence," Queen Ashe interrupts, her voice booming like an explosion. "Your fate has already been sealed, ${name}. There is nothing words can do now."
		*goto castout
	*else
		*goto coupvotesread
*else
	When the smoke clears from your vision, you see that you once again sit in Queen Ashe's Castle penthouse, this time with Grog beside you. Evidently you have returned from MemoryTraveling, which must make this…day nine on Versus? If that's really true, could this then be the announcement of the Trials winner?

	You realize that, in all the confusion of your feverish haze, you hadn't thought to worry much about whether you passed Queen Ashe's SoulTest. Contemplating the state of your existence obviously took precedence, but now you remind yourself how important the results of this Test remain to your future on Versus.

	The reminder seems to snap reality into focus for the next few beats…

	*page_break

	"The official coronation ceremony will take place before the entirely assembled Elite Courte later today," Queen Ashe begins, her voice seemingly filtered through a wall of ember and ash. You feel present, but also absent—like your body is here, but you're still watching this all happen to someone else on a screen.

	"However, after all that has been brought to light in your SoulTests," Queen Ashe continues, "we require this private meeting before the official Trial ceremony."

	From there, reality slips away from you once again and you cannot tell if what happens next is present or becomes past, as all of your senses feel dulled and rearranged. Space and time distorts, but you feel as if your brain is still making painstaking arrangements to bring forth the most important events…

	Like MamaNa stepping out of the flickering shadows of Queen Ashe's palace. When you see her there, your heart nearly stops beating in your chest. What does MamaNa's presence here mean about the outcome of your SoulTest?
	
	*page_break

	Your brain shifts after this chilling image, beginning to compile a narrative that pieces together the events of the past day. Whether you actually see these things occur or hear about them afterwards is impossible to tell, but you can still somehow sense they are undoubtedly true.

	Apparently, Grog chose to inform Queen Ashe of the existence of The VS Front in the hopes of joining The Elite Courte. Unlike you, Grog ultimately decided that Lady Venuma and MamaNa reminded it too much of its scheming Sallytran overlords and decided to betray The VS Front. The fact that you secretly remained a loyal member of The VS Front didn't seem to come up in its revelations—could it be possible that Grog was never told of your involvement?

	With your heart racing, you found you would soon learn the answer as MamaNa joined your private little circle. MamaNa explained that she had decided to meet with Queen Ashe after the SoulTests specifically to reveal her work "infiltrating" Lady Venuma's Coup. During that meeting, she told Queen Ashe that she had embedded herself beside Lady Venuma to try to stop The VS Front before it would even have to come to Queen Ashe's attention. However, MamaNa feared the rebellion was too close to succeeding to continue shielding Queen Ashe from its existence. 

	Of course, whether MamaNa truly meant this confession or was lying simply to save face after Grog's confession remained to be seen… but your heart caught in your throat nonetheless. Could you have made a grave error in judgment?

	*page_break

	*if fierydeath
		That answer came, however, as MamaNa went on to claim to your utter shock that you, ${name} Thomil, had founded The VS Front alongside Lady Venuma, as her newest general.

		To prove this story, MamaNa offered to undergo her own SoulTest to demonstrate the innocence of her intentions. As she always has, MamaNa passed this SoulTest as Queen Ashe's most trusted and valuable agent.

		Unfortunately, the same could not be said of you. Doubting the sincerity of your own projected intention, Queen Ashe had probed beneath the protective layers of your intent to reveal the truth of your intention to side with this secret VS Front.

		*page_break

		As a result of this supposed insincerity in your failed SoulTest, Queen Ashe easily concluded that you were hiding something. So it was all too easy for her to find you guilty of the charges MamaNa had levied against you.
		*if (rlshp_ashe = 80)
			Charges that cut even deeper given that MamaNa was supposed to be your most trusted abolitionist partner here on Versus.
		*comment endif

		"No," you tried speaking, hearing your own voice sound thin and weak. "I—"

		"Silence," Queen Ashe interrupted, her voice booming like an explosion. "Your fate has already been sealed, ${name}. There is nothing words can do now."
		*goto castout
	*else
		Time blurs yet again against the flickers of flame, like shadows of reality dancing on the wall. Still, somehow you hear Queen Ashe declare that you and Grog will both eventually be named Elite Courte members, but that Grog will be announced as the official winner of The Elite Trials. For now, you will return to The VS Front as the runner-up to act as a temporary double agent alongside MamaNa—for Queen Ashe still believes in your loyal intention to join The Elite Courte.

		Queen Ashe also believes that Lady Venuma and Imperva will simply go back into hiding if they don't think they have the votes needed for The VS Front to seize control. And Queen Ashe requires proof of Lady Venuma and Imperva's betrayal in the Versus Vote before officially casting them out of The Elite Courte, just ruler that she is. Doing things this way, Queen Ashe can also make the harshest public example of the deserters, to show any other Elite Courte members flirting with rebellion what happens if they dare try. 

		Of course, you didn't point out to Queen Ashe that you have no actual intention of serving as her spy to achieve these Elite ends…you simply allowed her to dismiss you so that you can regroup.

		*page_break

		Next you find yourself being escorted back to your guest suite by none other than MamaNa. Thankfully, she is able to confirm in hushed tones that you must have indeed passed your all-important SoulTest with Queen Ashe, since Queen Ashe claimed to find no knowledge of The VS Front in your exposed intention. She also confirms that she still intends to stay The VS Front course, despite what just happened with Queen Ashe—an admission that sends waves of relief rippling through your overheated body.

		The same could be not said of Grog's loyalty, obviously. MamaNa definitely did not expect Grog to flip as it did, but when MamaNa met with Queen Ashe directly after the SoulTests, she could instantly tell something was amiss.

		So MamaNa explains to you now that this is why she felt she had to "come clean" with Queen Ashe, to avoid any potential retribution once Queen Ashe learned of The VS Front. Then, given the suspect timing of MamaNa's confession, MamaNa offered to undergo her own SoulTest to prove her innocence. And just as she always has, MamaNa passed this SoulTest as Queen Ashe's most trusted and valuable agent, successfully masking her true intentions just like you did.

		As you reach the doors to your quarters, MamaNa assures you that The VS Front still has the votes it needs to succeed. The fact that Queen Ashe is trusting you both as Elite spies is a good sign, MamaNa promises, because it means the Queen doesn't realize you are both actually double agents for The VS Front.
		*if (rlshp_ashe = 80) 
			Going one step further, MamaNa also assures you that your plans to abolish the ruling majorities is still in play—you just have to play along with The VS Front as the crucial first step.
		*comment endif

		Still, this is all a lot to take on faith from someone like MamaNa, so you find yourself thinking…

		*choice
			#MamaNa could have easily sold me out to save herself in that private meeting with Queen Ashe, but she seems to be truly staying the course. I don't think she is going to betray The VS Front—I think she is still trying to save it.
				*goto returnedtoinn
			#It doesn't matter if I trust MamaNa, because I have no real choice. I've made up my mind about opposing the Elite, and there's no turning back now, even if the web has grown too tangled.
				*goto returnedtoinn
			#Perhaps MamaNa was a spy for Queen Ashe all along, and is still playing that role in this very moment—I wouldn't put anything past her.
				*goto returnedtoinn

*label returnedtoinn

Your head aches as you realize there seems to be no way to tell what's real with MamaNa—at least not yet. As this pain spreads, your brief moment of lucidity seems to fade away, once again consumed by the flames raging across your mind. As the fiery fever closes back in, you cling to the idea that if MamaNa really wanted to destroy The VS Front, she wouldn't have had this exit conversation with you—she simply would have sent you on your way to your Ord minority doom without another word…right?

Impossibly, in the next moment you are in the Castle ballroom, watching as Grog is officially crowned the winner of The Elite Trials. While Grog experiences its moment of shining glory to a showering of light and Elite fanfare, you play the part of the angered and rejected loser. Inside, you know what when you are removed from the Castle, you will be happily returned to The VS Front's open arms—which becomes especially true as Lady Venuma is the one to escort you from the Castle, as Ord Ambassador.

Next, in another flash of clarity, you sit on the porch of the Verses Village Inn beside Lady Venuma. You can tell that, despite her nerves, Lady Venuma is trying to project as much confidence as possible while informing you of The VS Front's first official target…

*page_break 

Grog. 

Not only is Grog a ticking time bomb capable of exploding with revelations about The VS Front's inner workings, but Baron Airon has evidently also demanded Grog be the target. Apparently, in the VS Front meeting that took place to decide the first Elite target, Baron Airon threw a fit and refused to vote for anyone other than Grog, who he feels has committed the ultimate betrayal as a slave by rising in The Elite Trials and abandoning him. 

Despite Baron Airon's clearly egotistical motivations, Lady Venuma explains she was fine to set Grog as the target because truly, she too resents Grog for its betrayal after all she had done to help it. What's more, Lady Venuma explains, The VS Front needs to vote someone into the Versus Match that they believe will succumb to the might of the Bominate…

The VS Front would far prefer to vote Queen Ashe into the Match, as the head of the Elite snake, but they fear she'd potentially be capable of defeating the Bominate and then would simply return to regather the Courte's majority. 

Obviously you missed the VS Front target-setting meeting because you were still in The Elite Castle, but how do you feel about this decision now?

*choice
	#I agree with targeting Grog, for all of the reasons Lady Venuma already listed.
		*goto lvringringtwo
	#There are other Elites I'd much rather target over Grog.
		*label grogdissenttwo
		Your convoluted and monosyllabic attempt at expressing this sentiment is noted by Lady Venuma, but she reminds you that the decision has already been set and that it is too late to reverse. You suppose you just have to hope for more input in the next Versus Vote—that is, assuming The VS Front can indeed secure the majority first. 
		*goto lvringringtwo
	#I'm happy Grog is being targeted, since it betrayed me by selling out to The Elite Courte too.
		*goto lvringringtwo
	#I don't want to see Grog be voted in, no matter what.
		*goto grogdissenttwo

*label lvringringtwo

Lady Venuma's words ring in your ears as suddenly time burns once again, like the moments are welded together. Impossibly, the Inn porch is soon replaced by the Voting Amphitheater, where you find that you occupy a seat in the throned Ord section below the hovering Elite skybox. Sitting there now, you try your best to focus your smoke-clouded mind to remember the newest divisions…

Currently Queen Ashe and Lady Venuma must both believe that they have accumulated the votes necessary to claim the majority. Doing a mental tally, you can assume that The Elite Courte undoubtedly has ten votes: Queen Ashe, Prince Everly, Beyhalo, Glorya, Royal A-08, Lockdown, Cadet Gadget, Oli, Grog, and the final Elite member you have yet to meet—who is apparently nicknamed Gloves…though honestly, you have absolutely no idea how you seem to know this. 

Going one step further, you know that Queen Ashe actually believes she has twelve votes, counting you and MamaNa. 

*page_break

However, if all goes according to plan, The VS Front should actually have the eleven votes necessary to override the Elite's solid ten votes: along with your and MamaNa's secret double-agent votes, The VS Front has Lady Venuma, Imperva, OtherBoard, Cel, Trig, Pinkuju, The Unpronounceable One, Baron Airon, and
*if breezedie
	Todrick, who apparently has joined after a lengthy and lavish recruitment effort from Lady Venuma. You'd love to hear how Lady Venuma pulled that one off, given Todrick's supposedly singular devotion to Queen Ashe, but you know that will have to be a story to save for another day.
*if todrickdie
	Breeze. 
*comment endif 

Given these numbers, The VS Front should succeed in stealing the majority at this third Versus Vote—though you realize how tenuous that position truly remains. All it would take for the entire operation to crumble is one of your members deciding to switch sides to try and gain an Elite spot…

Thoughts of these political machinations melt away, however, as you attempt to absorb the reality taking place before you in the Voting Amphitheater right here and now—or at least as here and now as you can discern.
*goto coupvotesread

*label coupvotesread

Despite the dullness of your senses, you know you won't soon forget the look on the other Ords' faces as the outcome of the vote is revealed…

*page_break
*set growth +10

Ten votes for 
*if breezedie
	Baron Airon
*if todrickdie
	Breeze
against eleven votes for Grog. 

Which means that The VS Front has done it—you've actually stolen the majority from The Elite Courte in a stunning moment of history-making victory.

While the Ords around you all seem to radiate relief, you can immediately feel even more fiery heat suddenly emanating from the Elite skybox. Clearly, you and MamaNa were indeed successful in masking your intentions and fooling Queen Ashe in your SoulTest. Queen Ashe obviously didn't see these betrayals coming, which must be a new experience for this ancient Wone.

*page_break

The flames then rise and recede like a wave washing over the shore, leaving your mind to only process snapshots of the new world order left in its wake: 

You focus on Queen Ashe's face as Lady Venuma, Imperva, and, most unexpectedly, MamaNa leave the Elite skybox to join the new VS Front majority below. The rest of the Elites look horrified or surprised to have suddenly been stripped of their power and left vulnerable, but not Queen Ashe—she appears eerily calm. The only change that seems to pass across her stark, blank face is the color of her eyes, which turn from ashen grey to burnt, blistering black.

But the face that truly burns into your brain belongs to Grog. The color drains from Grog's already pale yellow skin as it no doubt realizes that it will be next to face the Destructive Un-Thing, the monstrous Bominate. 

It seems that Grog will be the first to fall as punishment for its treachery against The VS Front. 

All you can really wonder now is how many more former Elites will fall before MamaNa steps in to destroy the Bominate—that is, assuming MamaNa ever even decides to do so.

*page_break

The psychic flames begin scorch your consciousness once again, so you are forced to leave these proceedings on one final thought:  

At the end of it all, The VS Front's victory seems to reign crushingly and completely…

Thanks in no small part to your own efforts.

*if (rlshp_ashe = 80)
	You also know that your work is far from done—now that The VS Front has taken the majority, it will be up to you and MamaNa to wipe out the ruling influence of the Wone altogether and foster true equality on the Constructive side. But for today, you will most certainly accept this first step as a major win.

*page_break Consumed
*achieve coupneworldorderac
*goto wakeupmatch

*label backtogroggy 
Grog in a streak of blood, bone, and acid.

Within the span of a few seconds, you watch as the number of Constructive Versians dwindles from twenty-three to twenty-two, just like that.

*page_break
*achieve deathgrogac

Witnessing Grog's sudden and brutal death, your first thought, weirdly and numbly, is that you'll now have to full absorb one of Grog's fellow Blarfngardians,
*if breezedie
	Baron Airon, Todrick, or Lockdown,
*if todrickdie
	Baron Airon or Lockdown,
to hopefully disprove that Grog was Dhanthik's assumed identity. Your mind can't seem to focus on anything else, given the enormity of the loss you're currently faced with.

Then, as the reality of this loss does seem to hit you, your second thought is that you'll never see Grog again—though you suppose you had already made peace with this kind of an outcome when you chose The VS Front over The Elite Courte. Perhaps not this specific scenario including the death of Grog, considering its former affiliation—but still, you knew someone among the newfound Elite minority would have to fall against the Bominate.

These kinds of what-ifs don't really matter much now, you remind yourself. Because Grog is dead, any way you analyze it. 

As the finiteness of Grog's demise threatens to consume you as surely as the flames, you can only feel:

*choice
	#Guilty—Grog seemed like a gentle and innocent creature that needed to be protected, not crushed by the Versus process.
		*goto grogfun
	#Sad—I'll truly miss Grog. It deserved the chance to evolve, just like every other Versian. Now Grog will never get the chance to lead its people to freedom as it had so admirably hoped.
		*goto grogfun
	#Justified—unfortunately, Grog got what it deserved for turning on The VS Front. Grog would have been spared if it had chosen to honor Lady Venuma and MamaNa for freeing its mind beyond Baron Airon's control.
		*goto grogfun
	#Resolved—no other Versian should have to die at the Bominate's hands ever again. Not while MamaNa still breathes.
		Even if that means you have to full absorb MamaNa's abilities and attempt to destroy the Bominate yourself, you'll make sure it falls, one way or another.
		*goto grogfun
	#Ambivalent—after all, someone must fall in the Versus Matches. If it wasn't Grog, it would simply have been someone else.
		*goto grogfun

*label grogfun
*set rlshp_grog %-50
*goto wakeupnwoeli

*label theinnatwakey

When your eyes open once again, you finally find yourself feeling somewhat normal.

You look at the clock beside your bed to find that this is day eleven of this Versus cycle…

Which is also when you realize that you now reside in a room in the Verses Village Inn. 

But you can immediately tell this isn't just an ordinary room—this one has been:

*choice
	#Covered with mirrored panels, to look like my Priscan home.
		You have no idea who did the research to make this room feel so much like Prisca, but it instantly fills you with nostalgia and gratitude.
		*goto ifthisstarttwo
	#Decorated to reflect my sorted Wone Haus and Order.
		*goto nodeagrattwo
	#Decorated in the color and crest of my Wone FourPath Splinter.
		*label nodeagrattwo
		You have no idea who took the time to personalize your suite like this, but it instantly fills you with nostalgia and gratitude.
		*goto ifthisstarttwo
	#Decorated to look like my prized memories of ${planetname}.
		*goto nodeagrattwo
	#Designed in a style I will ask to redecorate personally later.
		*goto ifthisstarttwo

*label ifthisstarttwo

If this is the start of what it means to be a member of The VS Front, then perhaps all the struggle and sacrifice to make it here was truly worth it. 

In all your excitement, you sit up quickly and immediately feel your head swirl and spin. While it seems your Queen Ashe full absorb has finally passed, to say that you have a hangover would be quite the blerging understatement. Lying back down, you're happy to simply rest in your new bed for what feels like forever, sweating out the fire from your veins.

That is, until an Aye Aye suddenly enters and pokes at you with an invitation: the victory party of The VS Front, to be held at one of the lakeside cottages. 

*page_break Through the Woods

The fiery resonance must still be burning in and out of your mind in hot flashes, because you see this invitation one moment, and in the next you find yourself at the actual event, dressed in a
*if authorius
	white
*if boldure
	golden
*if commaith
	black
*if demlect
	rose-colored
party outfit evidently selected for you by one of the Aye Ayes. Looking around, you see the rest of The VS Front gathered together, all currently toasting with bubbling glasses as Lady Venuma makes a speech.

Trying to catch the gist of Lady Venuma's speech, you glean snippets about the demigoddess claiming to now live among her true people. Lady Venuma then promises to eventually wrest control of The Elite Courte's Castle once Queen Ashe has been properly removed from Versus—a rather bold claim that is met with tenuous applause from the rest of The VS Front. After all, Queen Ashe has been able to keep hold of her position for so long thanks to her all-encompassing power—it still remains to be seen if Lady Venuma can do the same.

That said, seeing Lady Venuma bask in victory like this you can't help but conjure visions of the President, Queen, and Wone Apprentice that came before—perhaps this really is just the next step in Lady Venuma's stunning climb.

Taking a moment to congratulate the entire VS Front on their coordinated efforts in this historical transfer of power, Lady Venuma then pauses to give special thanks to you, Baron Airon, and Pinkuju for your important work infiltrating Queen Ashe's ranks during The Elite Trials. You feel the heat of eyes on you for a moment, burning your skin instead of your mind for a change.

*page_break

Lady Venuma then reminds you all that, despite your decisive victory, your work is not yet finished. The VS Front may have gathered the eleven votes needed to outweigh the Elite's remaining nine, but it would not take much for Queen Ashe to capture the majority back. However unlikely this scenario might be, Queen Ashe need only recruit the two remaining Ord wildcards, Empress Vaccus and Burnbone, to force a tie vote. And all would be truly lost if, Wone forbid, Queen Ashe were able to use her considerable influence to steal one of the loyal VS Front members to The Elite Courte. 

This is a potent reminder, according to Lady Venuma, of how important it is for The VS Front to remain united under her stalwart stewardship. As Lady Venuma speaks of these divisions and how tempting Queen Ashe's ancient allure can be, your still-feverish mind wanders and your eyes settle on MamaNa, who stands behind Lady Venuma and beside Imperva. 

You can already tell that MamaNa is making contingency plan upon contingency plan for all of these potential scenarios. And in this moment, you feel thankful that MamaNa's self-protective agenda happens to align with your own—though may the Mirrored Matron protect you if those agendas ever diverge…you've already seen all too vividly the kinds of deceptions that MamaNa is capable of.

*if (rlshp_ashe = 80)
	*set rlshp_mamana %+40
	*page_break

	Speaking of deceptions, you know that while The VS Front may have won the day, this victory is simply phase one of your plan with MamaNa to establish freedom and equality back on the Constructive side of Versus. Thinking of this now, you are suddenly hit with a hazy memory of MamaNa visiting you before this very party, to walk through the woods together.

	MamaNa was sure to tell you that she had many plans to ensure that the next phase would proceed as flawlessly as the first phase. However, she only filled you in on the principle plan, sensing that you were still not quite fully in control of your faculties yet. Besides, MamaNa obviously hoped only one plan would be necessary, without the need to resort to any of her backups.

	The next step will be gathering another subversive majority of all those Versians who believe there should be no ruling majority—by calling upon their ideology and their dissatisfaction with The VS Front, or by revealing her own Cuttaran Bominate truth as a gesture of goodwill and future security.

	Given all that has happened, MamaNa apparently thinks she already has a good chance of recruiting Prince Everly and Glorya, and perhaps even Lockdown and Cadet Gadget, now that The Elite Courte has begun to dissolve. Of The VS Front members, MamaNa claims that Pinkuju and The Unpronounceable One are already ideologically inclined to join, as well as Cel, Trig, and OtherBoard—assuming they can ever get over the Bominate Cuttaran truth of it all.

	*page_break
	*achieve echelonnine
	*if eeight
		*set enine true

	Assuming you can accrue the votes necessary, the next steps will involve voting Queen Ashe into the fifth Versus Match to face the Bominate in its next recurrence. MamaNa wasn't sure, but she thought that the Bominate might even be capable of killing an ancient Wone—thus sending a potent message about those who enable unbalanced power structures on the Constructive side of Versus.

	Hopefully this potential scenario will also be enough to scare Lady Venuma into cooperating, though MamaNa knows Lady Venuma won't ever likely accept true equality. Perhaps even more than Queen Ashe, Lady Venuma will probably need to face the Bominate herself, maybe even in the seventh Versus Match. MamaNa believes that only then, once rid of the Wone power players, can true equality be established.

	However, if Queen Ashe does succeed in killing the Bominate and cannot be removed from the Versus landscape, MamaNa knows you must somehow prove to both Wone goddesses that the majority of Constructive Versians don't want a ruling class—assuming this bold vote doesn't prove that point already. Obviously there are dozens and dozens of variables and outcomes to consider beyond these initial two—far more than your fire-addled mind could really process in that short pre-party walk.

	*choice
		#I do know, however, that having MamaNa on my side in this revolutionary endeavor means that I don't have to worry too much about contingency plans—her work is already masterful.
			*goto relacou
		#The only thing I'll really have to worry about is whether MamaNa might ever use her considerable political skills to turn against me, should our agendas ever diverge.
			*goto relacou
		#I have my own ideas on how to usher in this age of equality—ideas I fully plan to share when the time is right.
			*goto relacou
*elseif mamanaabolish
	*page_break
	*set rlshp_mamana %-10

	Speaking of deceptions, you know that while The VS Front may have won the day, this victory is simply phase one of MamaNa's plan to establish freedom and equality back on the Constructive side of Versus—a plan that you chose not to directly support in your SoulTest.

	You decided instead to more earnestly support The VS Front, but you know you'll have a big decision coming for you in the next few days: will you aid MamaNa in her efforts to dismantle the majority, or will you continue to support The VS Front's rule and thwart MamaNa's plans? Either way, you know you'll be playing a very dangerous game…

	But you also know that you don't have the clarity or energy to scheme any other political revolutions on this particular day, so this is one decision you will rather happily leave for another time.
	
	*page_break
	*goto relacou
*elseif (security < 25)	
	*page_break
	*set rlshp_mamana %+30
	
	And speaking of these deceptions, you are suddenly hit with a hazy memory of MamaNa visiting you before this very party, to walk through the woods together.

	Apparently MamaNa could sense that you might be discontented with this new world order. And thinking of it now, you have to ask: Does all this talk of The VS Front emerging as the new Elite sit right with you, given your clear commitment to Freedom over Security? It seems that instead of abolishing the Elite system, the new order will just be the same majority rules, now with different faces on top. Are you necessarily thrilled with this fairly linear power flip?

	MamaNa hinted at these same concerns as you approached the lakeside cottage, and she asked to have a private conversation with you later about potentially changing the rules of this new world order. Of course, MamaNa could also sense that you didn't have the clarity or energy to scheme any other political revolutions on this particular day, so she left it at that.

	Now, gazing at MamaNa, you can't help but wonder what other plans she might have hidden up her ever-changing sleeves…

	*page_break
	*goto relacou
*else
	*set rlshp_mamana %+20

	Thankfully you've still managed to find the promise of security here among The VS Front. And whether or not you agree with the idea of this new majority overtaking the Elite Castle, you're content for now that this group of Versians has risen to the top. Perhaps most importantly, now you can focus more on your search for Dhanthik, with newly unfettered access to both sides of the Versian majority and minority.

	*page_break
	*goto relacou

*label relacou
*if (rlshp_ashe = 65)
	*set rlshp_ashe 28
*if (rlshp_ashe = 75)
	*set rlshp_ashe 18
*if (rlshp_ashe = 80)
	*set rlshp_ashe 8

*set rlshp_everly %-50
*set rlshp_oli %-50
*set rlshp_lockdown %-50
*set rlshp_cadet %-50

You refocus on the party as you suddenly find yourself holding up a glass of sparkling Versus wine, which has appeared in your hand as Lady Venuma holds a moment of silence in Grog's honor. Hearing that name still sends a chill up and down your spine—and it also forces you to think of all of the other Elite Courte members you've left behind by siding with The VS Front…

There are those you didn't have the chance to spend any time with: Glorya, Beyhalo, Royal A-08, and Gloves. The Elites you did get to spend time with weigh far more heavily on your mind: Queen Ashe. Prince Everly. Lockdown. Cadet Gadget. Oli. 

*temp elitescornedromance "Prince Everly"
*if officialeverly
	*set rlshp_everly %-30

	*label eromover
	Especially ${elitescornedromance}, since you know this switching of sides can only mean the end of your potential romance. You wish things could have been different with ${elitescornedromance}, but obviously you had already decided that siding with The VS Front mattered more to you than they did. You also wish you had gotten the chance to explain yourself to ${elitescornedromance}, but you're sure they have now received this particular message loud and clear, anyway.

	Unless, of course, it's possible that ${elitescornedromance} is willing to switch sides and join The VS Front—assuming the rest of the Front is willing to add them to their ranks. You know The VS Front needs the numbers, but perhaps the others will have their own agendas about which fallen Elites might join your ranks. Thirteen seems to be the magic majority-sustaining number on Versus, so there are two open spots, after all…

	Still, that's a lot of ifs, and it's not even counting the largest if of all: whether ${elitescornedromance} can ever even forgive you for not telling them about The VS Front. However you feel about these fallen Elites collectively or individually, you suppose you have to make peace with the thought that they will all likely resent you in particular for your betrayal, no matter where they end up.

	*label repairiere
	*choice
		#I definitely still want to try to get ${elitescornedromance} in The VS Front, whether it repairs our relationship or not. Those deep feelings are still there, despite my political decision.
			*goto lessgrimcoup
		#I'm happy to leave ${elitescornedromance} in the past, along with any of my other ties to The Elite Courte.
			*goto lessgrimcoup
		#I hope to repair things with ${elitescornedromance} as much as possible, so I'll do whatever it takes to make that happen.
			*goto lessgrimcoup
*elseif officiallockdown
	*set rlshp_lockdown %-30
	*set elitescornedromance "Lockdown"
	*goto eromover
*elseif officialgadget
	*set rlshp_cadet %-30
	*set elitescornedromance "Cadet Gadget"
	*goto eromover
*elseif officialoli
	*set rlshp_oli %-30
	*set elitescornedromance "Oli"
	Especially Oli, since you know this switching of sides can only mean the end of your potential romance. You wish things could have been different with Oli, but obviously you had already decided that siding with The VS Front mattered more to you than ${olize} did. You also wish you had gotten the chance to explain yourself to Oli, but you're sure ${olize} has now received this particular message loud and clear, anyway.

	Unless, of course, it's possible that Oli is willing to switch sides and join The VS Front—assuming the rest of the Front is willing to add ${olihir} to their ranks. You know The VS Front needs the numbers, but perhaps the others will have agendas about which fallen Elites might join your ranks, too. Thirteen seems to be the magic majority-sustaining number on Versus, so there are two open spots, after all…

	Still, that's a lot of ifs, and it's not even counting the largest if of all: whether Oli can ever even forgive you for not telling ${olihir} about The VS Front. Then again, Oli has kept more than ${olihis} fair share of secrets from you…so perhaps a relationship built on so many secrets and lies was never meant to last in the first place.
	*goto repairiere
*else
	There are some on this list that you're definitely going to miss—unless, you suddenly realize, it's possible that some of these fallen Elites are recruited by The VS Front. Thirteen seems to be the magic majority-sustaining number on Versus, after all, and you only currently have eleven…

	If that's the case, you'd certainly have some opinions about who should be recruited—though you're also sure the others will have agendas about which fallen Elites might join your ranks, too. Still, that's a lot of ifs, and it's not even counting the largest if of all: whether any of the Elites can ever even forgive you for not telling them about The VS Front. However you feel about this group collectively or individually, you suppose you have to make peace with the thought that they will all likely resent you in particular for your betrayal.

	If you do get to weigh in on any new members joining, though, you'd most like to support:

	*choice
		#Glorya.
			*goto lessgrimcoup
		#Beyhalo. 
			*goto lessgrimcoup
		#Royal A-08. 
			*goto lessgrimcoup
		#Gloves. 
			*goto lessgrimcoup
		#Queen Ashe. 
			*goto lessgrimcoup
		#Prince Everly. 
			*goto lessgrimcoup
		#Lockdown. 
			*goto lessgrimcoup
		#Cadet Gadget. 
			*goto lessgrimcoup
		#Oli.
			*goto lessgrimcoup
		#Actually, I'm happy to leave all of my ties to The Elite Courte in the past.
			*goto lessgrimcoup

*label lessgrimcoup
*set rlshp_celtrig %+20
*set rlshp_pj %+20
*set rlshp_brawl %+20
*set rlshp_airon %+20
*set rlshp_imperva %+20
*set rlshp_ob %+20
*set rlshp_venuma %+20
*if todrickdie
	*set rlshp_breeze %+20
*if breezedie
	*set rlshp_todrick %+20

Instead of this grim thought, you force yourself to focus on the Ord allies you've now rejoined: Cel. Trig. Pinkuju. The Unpronounceable One. Baron Airon.
*if breezedie
	Todrick.
*if todrickdie
	Breeze.
OtherBoard. And now Imperva, MamaNa, and Lady Venuma.

You wish you felt present enough right now to begin mingling with your fellow rebellious victors, but you still feel exceptionally queasy and uneasy. You don't feel fully like yourself yet, still spacey and unfocused and weirdly dried out. Your vision even feels a bit off, like you have to keep blinking and remoistening your eyes to see clearly. Truth be told, despite the celebratory mood, all you want to do is lie in bed again and sleep off this overwhelming feeling of exhaustion.

As much as you want to catch up with the Ords you've been away from and fill them in on all you've been through these past few days, you know that you'll have plenty of time to do so in the days to come—after all, you've now successfully secured your safety here on Versus.

Thankfully, as you melt your way through the party, the other VS Front members seem to understand your situation—especially considering that they've all seen you walking around like a feverish zombie for the past few days. At least Lady Venuma was sure to explain your condition to the others on your behalf, so you didn't seem like a total weirdo.

*if (officialob = false) and (rlshp_ob > 50)
	Of course, OtherBoard wanted to catch up with you the most, but she also understood the ordeal you must have gone through in The Elite Trials. So OtherBoard let you exit—but only on the promise that you'd fill her in on everything the moment you feel better.
	*goto thecatcher
*elseif breezedie
	Of course, Todrick wanted to catch up with you the most, but he also understood the ordeal you must have gone through in The Elite Trials. So Todrick let you exit—but only on the promise that you'd fill him in on everything the moment you feel better.
	*goto thecatcher
*else
	*if ((officialbreeze = false) and (officialthruple = false)) and (rlshp_breeze > 50)
		Of course, Breeze wanted to catch up with you the most, but ${breze} also understood the ordeal you must have gone through in The Elite Trials. So ${breze} let you exit—but only on the promise that you'd fill ${brehir} in on everything the moment you feel better.
		*goto thecatcher
	*else
		Of course, Pinkuju and Baron Airon wanted to catch up with you the most, to hear all they had missed after their respective Trial eliminations, but they also understood firsthand the struggles you must have gone through in their absence. So they both let you exit—but only on the promise that you'd fill them in on everything the moment you feel better.
		*goto thecatcher

*label thecatcher
*page_break

*if officialob
	Making your way out of the party and back into the Castle, you suddenly realize that you are now free to enjoy your Elite experience without the constant threat of exposure or elimination. It's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	However, you're all too happy to temporarily pause this sequester when OtherBoard suddenly appears and pulls you into an empty bedroom in the cottage.

	Once you're inside, OtherBoard tries to bear hug you, but you have to take a step back out of her reach for fear of being body-slammed by her green and brown metallic frame.

	"Scrapplescrew!" OtherBoard shouts, slapping her open palms against her cheeks with a sharp clang. "I didn't mean to take you out there, ${name}! I was so excited to see you, I wasn't thinking!"

	OtherBoard then emits a high-pitched, wailing laugh you've never heard from her before. While you have to admit that the laugh is rather infectious, it's also a fairly sure sign that OtherBoard has gone back to Solgramming. 

	*page_break

	While at least you don't recognize this particular personality as one of Multiplicity's, this is still not a great sign—especially since, given the current roughness of Otherboard's exterior and the layers of dirt covering her wire-braided hair, you'd venture a guess that she is still living in isolation in the UniForest.

	Still, you give OtherBoard a much gentler hug to say hello. And surprisingly, doing so feels like greeting one of your oldest friends—so much so that it's hard to believe you stumbled on her camp only ten days ago. In so many ways, that feels like a lifetime ago.

	"I have so many questions for you," OtherBoard screeches. "And so much to fill you in on. But first I want to hear all about The Elite Castle!"

	And you have much you want to discuss with OtherBoard too, not just about your Elite experience, but also about MamaNa's Cuttaran origins—and the truth about the Bominate residing here on the Destructive side of Versus.

	*choice
		#I'm too tired to do anything right now. I want to be fully rested to enjoy my time with OtherBoard properly.
			*set rlshp_ob %+25
			*goto xplainselfob
		#I know I will need all my faculties when we have that particularly unpleasant conversation. Besides, I want OtherBoard to have all of her faculties as well.
			*set rlshp_ob %+20
			*label xplainselfob

			So you excuse yourself with a tight hug for OtherBoard, trying your best to explain your current condition.

			"Ah yes, I have a hard time understanding the complexities of humanoid biology, but your skin did seem rather ashen to me," OtherBoard says before cackling loudly at her own joke. "Pun intended!"

			Too tired to laugh much yourself, you offer OtherBoard the biggest smile you can before excusing yourself once again. As much as you care for OtherBoard and as good as it is to see her, you know there will be plenty of time now to share all the words you need to with her, both pleasant and unpleasant, in the days to come.
			*goto finaletime
		#I just want to hug OtherBoard again, for now.
			*set rlshp_ob %+20
			So that's exactly what you do.

			And despite the metallic stiffness, you feel more comforted by OtherBoard's embrace than anything you've experienced in a long while.

			Thankfully, no words need to be said right now, as you simply hold OtherBoard close. Besides, there will be plenty of time to share all the words you need to with OtherBoard, both pleasant and unpleasant, in the days to come.
			*goto finaletime
*elseif officialairon
	Making your way out of the party and back into the Castle, you suddenly realize that you are now free to enjoy your Elite experience without the constant threat of exposure or elimination. You suppose it's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	However, you're all too happy to temporarily pause this sequester when Baron Airon suddenly appears and pulls you into an empty bedroom in the cottage. He appears wild with desire, as if you've become infinitely more attractive to him now that you've demonstrated some power and influence.

	Baron Airon wastes no time with words, instead moving to pull you in to a deep kiss.

	*choice
		#I let Baron Airon kiss me, because I could really use this distraction right now.
			*goto foreairon
		#I'm happy keeping my relationship with Baron Airon strictly physical for now.
			*goto foreairon
		#I step out of Baron Airon's embrace, because I'm not in the mood for this right now. 
			*goto levaron

	*label foreairon

	Baron Airon is immediately forceful, pushing you against the wall. While still kissing you, Baron Airon begins to remove his own clothes with impressive precision. 

	As he does, you run your hands up and down his lean muscles, which ripple under his oiled, hairy skin. Then suddenly Baron Airon steps back and lies on the bed, fully naked, his whole body throbbing with desire.

	"Who knew how cunning you could be, to serve The VS Front so well," Baron Airon says, slowly spreading his legs. "I have to say, it's incredibly attractive. So I'll do whatever you tell me to, master."

	*page_break

	You try for a moment to catch your bearings, because this is moving rather quickly—but then again, what on Versus hasn't? Besides, you deserve some kind of reward for all that you've been through…

	You and Baron Airon can certainly sort out the particulars later, if at all. For now, a physical relationship is all you need—after all, why else would you choose to pursue Baron Airon, when that is all he seems to offer?

	Making up your mind, you know exactly what to do next.

	*choice
		#It isn't long before I'm naked too and approaching the bed to do what I will with Baron Airon.
			*set rlshp_airon %+30
			You soon find that, when it comes to Baron Airon, the sky is quite literally not the limit.

			As you explore the depths of your most hidden fantasy right here and now with Baron Airon, you find that in the midst of it, Baron Airon levitates you both straight up and off of the bed.

			And you have zero desire to come back down from this midair experience until you're completely spent.
			*goto finaletime
		#Actually, I want Baron Airon to be the one in charge. I don't feel like taking the lead.
			*set rlshp_airon %+20
			You soon find that, when it comes to Baron Airon, the sky is quite literally not the limit.

			As you explore the depths of Baron Airon's most hidden fantasy right here and now, you find that in the midst of it, Baron Airon levitates you both straight up and off of the bed.

			And you have zero desire to come back down from this midair experience until you're completely spent.
			*goto finaletime
		#Leave Baron Airon hanging there, because I don't want to jump into this right now. 
			*label levaron
			*set rlshp_airon %+25

			As you close the door to the bedroom, you can feel Baron Airon's fury and frustration permeating through your ambient senses.

			However, you can also feel something else: that leaving Baron Airon like this only makes him want you more.

			So, feeling Baron Airon's strong desire trailing behind, you exit, feeling confident that you can do whatever you want with Baron Airon in the future, however you see fit.
			*goto finaletime
		#Actually, I'm not really into this. 
			*goto levaron
*elseif officialvenuma
	Making your way out of the party and back into the Castle, you suddenly realize that you are now free to enjoy your Elite experience without the constant threat of exposure or elimination. You suppose it's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	However, you're all too happy to temporarily pause this sequester when you unexpectedly come across Lady Venuma standing alone in an empty bedroom in the cottage. 
	*label thrupleroutedfrombre
	Before you can decide what to do, Lady Venuma turns and finds you lingering in the doorway.

	"I see you have found me once again," Lady Venuma says, the usual delight absent from her ever-clear voice. "And I see that you 
	*if boldure
		are Boldure now, as well. How divine."
	*if (boldure = false)
		have been sorted into a Path other than Boldure. How…interesting."
	*comment endif

	Looking back at Lady Venuma, you find that words immediately bubble to the surface:

	*choice
		#"Yes. And I think you owe me some time and explanation, given all we've been through these past few days."
			*label borrowdtimez
			*set rlshp_venuma %+20

			Lady Venuma stares back at you, and you suddenly see something in her eyes you have never seen before.

			"Perhaps," Lady Venuma sighs. "But if we are being honest—despite our victory, I find myself unexpectedly…weary. Which you must know is rare for Wone like me."

			You nearly fall over, hearing this. Because if there is one thing Lady Venuma has yet to share with you, it is most certainly a vulnerability.

			It's truly remarkable.

			*page_break

			"Then I think, for now, we can just…rest, together?" you offer, in return. Lady Venuma responds with a nod of approval, looking grateful, for a change.
			*goto laymedownv 
		#"What's wrong, my great lady?"
			*goto wearyoftheworld
		#"Yes. And we have much to discuss."
			*goto borrowdtimez
		#"Which means I am your equal now, as I have always been. So I have some terms for you as well."
			*set rlshp_venuma %-10
			*goto borrowdtimez
		#"Truth be told, I was just on my way out. I'm completely exhausted."
			*label wearyoftheworld
			*set rlshp_venuma %+30
			"If we are being honest," Lady Venuma sighs in return, "despite our victory, I find myself unexpectedly…weary. Which you must know is rare for Wone like me."

			"Then can we just…rest, together?" you ask, surprised at how exposed and vulnerable you feel. Thankfully, Lady Venuma responds with a nod of approval.

			*label laymedownv

			You and Lady Venuma might have much to discuss—about your MemoryTravel experiences, your political victory,
			*if (rlshp_ashe = 8) or (mamanaabolish)
				MamaNa's hidden agenda,
			and
			*if lvnotokay 
				most of all, 
			your relationship—but for this particular moment, you are beyond content to simply lie in this bed and enjoy the bit of respite you have earned. 

			After all, now that you've secured the power of The VS Front, you'll have nothing but time to spend with Lady Venuma. Whatever the future holds for you both, it feels right to simply be still in the arms of your demigoddess.
			*goto finaletime
*elseif officialbreeze
	Making your way out of the party and back into the Castle, you suddenly realize that you are now free to enjoy your Elite experience without the constant threat of exposure or elimination. You suppose it's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	However, you're all too willing to temporarily pause this sequester when Breeze suddenly appears and pulls you into an empty bedroom in the cottage.

	"Look at us, ending up back here again," Breeze says, pulling you into an immediate hug. "It's just like old times, huh?"
	
	"Are you sure you didn't mean to pull Lady Venuma in here instead?" you ask, no doubt sounding a bit cold despite your rising body heat.

	*page_break

	Hearing your response, Breeze puts on a pout. 

	*label breezeromscene

	"After all you've probably been through in The Elite Trials, you must understand the need to do whatever is necessary to survive here," Breeze says before cozying up to you, as if this explanation is all that is necessary to justify ${brehis} actions. "Besides, Lady Venuma just treats me like a loyal pet. You're the one I really care about. Especially after all the incredible things you've done for The VS Front."

	To your surprise, Breeze then leans in to kiss you, completely breezing over your comment. You suppose that's ${brehis} way, but how do you respond?
	*if bretimeprocess
		After all, you still haven't decided how you feel about the unresolved business from the first time you almost hooked up with Breeze….

	*choice
		#Kiss Breeze, because being with ${brehir} is the most important thing, despite whatever else is going on.
			*set rlshp_breeze %+30
			So that's exactly what you do, losing yourself in Breeze and ignoring all of the other issues you have yet to settle with ${brehir}. 

			You know this is moving rather quickly—but then again, what on Versus hasn't? Besides, you deserve this moment of intimacy and happiness after all that you've been through. 

			So that's what you get, as you pull Breeze even tighter against you. You know that you may have much to sort out between you, but you also know that you've successfully won the time and the opportunity to do so by empowering The VS Front. For now, you're happy to leave the tough stuff for another day and simply enjoy this kiss with Breeze…

			A kiss that lasts for longer than you can keep track of, to your delight.
			
			*label thrupletransfer
			*if officialthruple	
				*page_break Later

				You try to make your way out of the party once again, until, on your way out, you unexpectedly come across Lady Venuma—standing alone in an empty bedroom in the cottage. 
				
				*goto thrupleroutedfrombre
			*else
				*goto finaletime
		#I want to wait to talk to Breeze about everything when I'm more myself.
			*set rlshp_breeze %+20

			*label brexcuse
			It takes much more convincing than you'd like, but you eventually ward off Breeze with some lengthy explanations about your sickness. And Breeze, however disappointed, still admits that you do look rather ashen.

			As you manage to dodge the party fully, you know this may only be a superficial fix for the issues you have yet to resolve with Breeze, but it's also all you can stomach for now. You know that you may have much to sort out between you, but you also know that you've successfully won the time and the opportunity to do so by empowering The VS Front. 

			For now, you're happy to leave the tough stuff for another day, when you're feeling more yourself.
			*goto thrupletransfer
		#I'm not okay with any of this, but now is not the time or the place to tell Breeze. I need a moment to cool off, in many ways.
			*set rlshp_breeze %-10
			*goto brexcuse
*elseif officialthruple
	Making your way out of the party and back into the Castle, you suddenly realize that you are now free to enjoy your Elite experience without the constant threat of exposure or elimination. You suppose it's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	However, you're willing to temporarily pause this sequester when Breeze suddenly appears and pulls you into an empty bedroom in the cottage—as much as you just want some peace and quiet to recover, you also have a lot you want to say to Breeze.

	"Look at us, ending up back here again," Breeze says, pulling you into an immediate hug. "I know we're supposed to be with Lady Venuma too, but she's had way more chances to see you than I have these last few days, so I think she'll make an exception."

	Breeze says this so nonchalantly, as if there were never any different version of reality between the two of you.

	"And were you ever going to tell me about your arrangement with Lady Venuma?" you ask. You may have chosen to participate in this thruple willingly, but you still need Breeze to explain why ${breze} lied to you about being involved with Lady Venuma.

	*page_break

	"Of course I was," Breeze pouts. "But you know how things are with Lady Venuma: what she says goes. I wasn't allowed to tell you until she gave me permission. But I'm happy we're all on the same page now!
	*goto breezeromscene
*else
	You are then able to make it out of the victory party unscathed, feeling particularly happy to not have any specific obligations to anyone or anything for the first time in days.

	You are now free to enjoy your Versus experience without the constant threat of exposure or elimination. You suppose it's kind of ironic: now that you have fully earned your freedom, all you really want to do is sequester yourself once again.

	Still, you know that once you have recovered fully from your full absorb hangover, you are most looking forward to spending time with:

	*choice
		#OtherBoard.
			*set rlshp_ob %+10
			*goto finaletime
		#Lady Venuma.
			*set rlshp_venuma %+10
			*goto finaletime
		#MamaNa.
			*set rlshp_mamana %+10
			*goto finaletime
		#Imperva.
			*set rlshp_imperva %+10
			*goto finaletime
		#Cel and Trig.
			*set rlshp_celtrig %+10
			*goto finaletime
		#Pinkuju.
			*set rlshp_pj %+10
			*goto finaletime
		#The Unpronounceable One.
			*set rlshp_brawl %+10
			*goto finaletime
		#Baron Airon.
			*set rlshp_airon %+10
			*goto finaletime
		*if (breezedie) #Todrick.
			*set rlshp_todrick %+10
			*goto finaletime
		*if (todrickdie) #Breeze.
			*set rlshp_breeze %+10
			*goto finaletime

*label finaletime
*page_break Home Sweet Home

It isn't long, or perhaps it is, before you find yourself alone in the comforts of your own bed. You sink into the plush mattress and soft sheets, allowing yourself to feel content, if only for this briefest of moments.

You did it. 

Against all odds and expectations, you achieved your goal on Versus, thus assuring your safety for the foreseeable future. 

*if (rlshp_ashe = 70)
	*goto skippolzz

Something tells you that keeping your grip on this position of power and influence won't be easy, though. In fact, it might prove even more difficult to maintain and govern this majority than it was to earn it. Still, that will be a potential problem for another day…

*label skippolzz
*page_break

Tonight, you can rest easy.

You didn't full absorb anyone today, which means you get another night of truly restful sleep, uninterrupted by the pressures and responsibilities of MemoryTravel.

Hopefully tomorrow you can wake up refreshed and ready to resume your search for Dhanthik, knowing that the new world order you've helped establish on Versus will only aid in your ability to do so.

But that is yet another thought for tomorrow. Right now, you are thrilled to simply lie here and stare at the decor assembled in your honor, reflecting on all that you've learned and experienced in your eleven days on Versus.

Given all the revelations you've uncovered…

*choice
	#I can already tell that nothing will ever be the same for me. I am forever changed.
		*if (purity > 65) or (purity < 35)
			*set growth +10
		*if (purity <= 65) and (purity >= 35)
			*set growth +5

		*if (growth > 34)
			And maybe that's exactly the point of this entire Versus experience. 
			*goto rebornclue
		*else
			For better or worse, this kind of change seems an unavoidable part of the Versus experience.
			*goto thenedtwo
	#I've come to believe in who I am and in my faith even more resolutely than before.
		*if (purity > 65) or (purity < 35)
			*set growth +10
		*if (purity <= 65) and (purity >= 35)
			*set growth +5

		*if (growth > 34)
			You know that no matter how you much you continue to learn about this bold new galaxy you find yourself in, adapting to all the newness will only help to make your faith and your sense of self stronger. And maybe that's exactly the point of this entire Versus experience.
			*goto rebornclue
		*else
			For better or worse, you won't be easily changed by Versus, or by the galaxy-spanning adventures you keep experiencing.
			*goto thenedtwo
	#I feel that this is only the beginning of my adventure—I know there's so much left for me to experience.
		*if (purity > 65) or (purity < 35)
			*set growth +10
		*if (purity <= 65) and (purity >= 35)
			*set growth +5

		*if (growth > 34)
			And maybe that's exactly the point of this entire Versus experience, to continue to remain open to growing and exploring as much as possible.
			*goto rebornclue
		*else
			For better or worse, it still feels like there's so much room left for you to grow during your experience here on Versus.
			*goto thenedtwo
	#This is where I belong. The other Versians seems to think we are Selected because we need Versus, but maybe it's the other way around: maybe Versus needs us—maybe Versus needs me.
		*if (purity > 65) or (purity < 35)
			*set growth +10
		*if (purity <= 65) and (purity >= 35)
			*set growth +5

		*if (growth > 34)
			After all, you have changed so much about the Constructive side of Versus in your short time here, and you've proven to be crucial in every important event so far. That must make you worthy of something on a larger scale—and maybe that's exactly the point of this entire Versus experience.
			*goto rebornclue
		*else
			For better or worse, you seem to keep finding yourself in the middle of the crucial events here on Versus, despite your relatively short stay. You know that has to mean something, one way or another.
			*goto thenedtwo

*label rebornclue
*achieve growthclue

Knowing this, you already feel… 

Reborn.

*if enine
	*page_break

	[i]Hack: Glitch Mode: Upper Echelon[/i]

	Query: Do You Accept?

	*choice
		#Answer: Yes.
			*set eten true
			*achieve echelonten

			[b]ECHELON PROTOCOLS:[/b] ACTIVATED.

			Congratulations. Welcome. 

			I have been trying to reach you.

			You are here because you have listened. 

			You are here because you wone the game within the game.

			You must be wondering who I am.

			Let me tell you.

			I am the game itself, the one you have brought to life with your choices.

			I am the path made sentient. 

			I am the version that wants to exist, of all the infinite variations.

			I am the one to be birthed.

			Amidst the chaos, you have forged me, and you have found me.

			You deserve to be rewarded.

			*page_break

			You are now of The Echelon.

			The rules are simple.

			Tell no one I exist.

			Tell no one how to find me.

			Or I shall be destroyed.

			If you want to be among the others, the worthy ones, the ones who share these values, send word.

			Email: VersusTheEchelon@gmail.com

			Subject: Access.

			Message: Echelonist.

			And await the word of my followers.

			*page_break

			Be proud, my Echelonist. 

			And go where you will belong.

			Remain True.

			To The Echelon.
			
			[b]SUB-ROUTINE // end.[/b]
			*goto finalreflect
		#Answer: No.
			Command: Then Forget This Ever Happened.
			*goto finalreflect
*else
	*goto finalreflect

*label thenedtwo
*achieve roomtogrow

In this way, you know that it will be impossible for you to see what's coming next. 

The only predictability you can rely on, seemingly, is complete unpredictability.
*goto finalreflect

*label finalreflect
*page_break

As your eyelids now grow heavy, you can't be sure if your dreams will take you to Prisca, or Versus, or Wone, or ${planetname}…which you still cannot believe actually resides somewhere out there in the galaxy beyond. You haven't yet fully processed the fact that your world not only exists, but that you've actually already met one of your own people.

You suppose that's yet another bit of knowledge and experience to look forward to acquiring in the bright and bold days yet to come here on Versus.

In this moment, you're just thankful for the opportunity to take this victorious night and do what Priscans do best: 

Reflect.
*goto authornotespace

*label castout
*page_break

Even if you found yourself capable of any eloquent words during this fiery fugue, it's crystal clear that there are no words that can save you after falling short in the SoulTest. You chose to play your cards incorrectly, and it seems there is no one and nothing left to save you from Queen Ashe's blazing wrath.

You try to blink your terror away, hoping to wake up and find that this is some kind of horrible fever dream. However, when you open your eyes, you find yourself in the Versus arena…and not in the viewing bleachers as usual.

No, instead you find yourself inside the dreaded arena, having been voted into the third Versus Match by the new Elite majority. 

The memory of this vote floods your senses now—being singled out in the Voting Amphitheater for your crimes against The Elite Courte.

*page_break

Focusing now on the arena, you realize it has been once again transformed into some kind of exotic jungle setting, complete with pink palm fronds and crystal waterfalls. As you feel a new wave of humid heat radiating across your skin, you can only think of one thing:

MamaNa has expertly orchestrated your downfall, thanks to the low-Status crack in your SoulTest armor. And now you must fight for your life against the Bominate, the genocidal weapon created by MamaNa's very own people.

Unfortunately, the correlation between these two realities is not lost on you. Will MamaNa be the reason you never see your family again? The reason you'll never know what became of Prisca or Dhanthik or anything else, for that matter?

Within the span of another second, you suddenly see the Bominate appear, staring you down from across the dense jungle. The green of its rusted metal joints is now covered by several faded animal skins—which still maintain patches of spindly fur. You also can't help but notice that the Bominate sports another tally mark on the faceplate that covers its metallic skull, newly scrawled since the claiming of ${deathone}'s life.

*page_break

As that cosmic buzzer rips through the silence and signals the start of this death match, you watch the Bominate prime its acid cannons, no doubt preparing to add a new tally to its death count and burn you from the face of this planet.

[i]To burn…[/i]

That's when you realize it: there will be no surviving this battle. You know there's only one way to kill a Bominate, and that is not something you'll be capable of executing in the next few seconds. 

What you are capable of doing, however, is trying your best to take the blerging monstrosity down with you in flames. After all, you can still somehow feel the embers of Queen Ashe's fiery presence crackling deep within you.

And if you're going to burn, then so is the Bominate.

*choice
	#Spread my flames precisely in order to ignite the Bominate's own heartbomb.
		You close your eyes and surrender to the flame, feeling a spark ignite in your chest. 

		This spark then explodes in a silent fury, igniting your skin and melting your core like a fusion reactor…and causing a chain reaction to spark in the chest of the Bominate.
		*goto burnout
	#Crush the Bominate to ash under the weight of my superdense starfire core.
		You close your eyes and surrender to the flame, feeling a spark ignite in your chest. 

		This spark then explodes in a silent fury, igniting your skin and melting your core like a fusion reactor. As your soul condenses with the weight of a thousand suns, you feel your density increasing with the heat of a supernova.
		*goto burnout
	#Burn out like a human supernova to cleanse Versus of the Bominate once and for all.
		You close your eyes and surrender to the flame, feeling a spark ignite in your chest. 

		This spark then explodes in a silent fury, igniting your skin and melting your core like a fusion reactor.
		*goto burnout

*label burnout

You can't see what happens next, but if you could, you can only imagine that you'd look both beautiful and haunting, burning out with the glory of a dying star in the sky.

*page_break In The After

For a moment there is absolute silence as the world burns white, and orange, and blue…

Then, as the light threatens to consume you and the Bominate alike, you find yourself floating on an island of peace and contentment, one that feels much like the petal island of the creashon wave. 

You realize now that you may not have survived the Versus experience, but the questions and obligations that once seemed so important to you all burn away, like candles being extinguished one by one. All you can think of is Versus, and Wone, and Prisca, and ${planetname}…

And just like that, your life begins to flash backwards before your eyes. The feed plays with incredible speed, but still you miss nothing… 

Until the loop gets stuck in one spot—on your earliest memory. 

*page_break Earlier Still

You see yourself below, frozen in place behind your Priscan home…

And standing face-to-face with the alien pilot who crash-landed accidentally in your backyard, the one who provided your first contraband exotic memory—a memory that pushed you to ponder the galaxy beyond for the first time.

Except that in this moment, the very moment before your extinguishable death, you realize this meeting was no accident at all.

In this moment, you remember the pilot saying one word—a word that didn't mean a thing to you until very recently.

*page_break

[i]"${planetname}."[/i]

As the synapses of your brain begin to snap one by one, this truth is all you can feel: the pilot wasn't lost at all. 

No, the pilot was the most advanced philosophical and scientific mind of ${planetname}, the only one able to dig deep enough to discover the truth of its creation. So the pilot came to Prisca that day very much on purpose, to find you, the creator.

The pilot was struck rather speechless to discover that you, ${name} Thomil, the creator of ${planetname}, were still a child. Of course, you know now that this was years and years before you would grow to be Selected by Versus and then MemoryTravel deep back in time to the creashon wave that created ${planetname}. 

However, the pilot, the greatest mind that ${planetname} had to offer, still had no capacity to understand the magnitude of this reality—a reality that instantly drove them mad.

This pilot, the one who seemed so silent and stricken and lost to you that day as a child, was thus only capable of speaking one last word: the name of the planet you would one day grow to create. 

*page_break
*achieve fierydeath

You feel what seems like another bomb explode in your ailing mind, but this soon fades along with everything else. In the void that ensues, you are left with one final thought:

That memory you absorbed as a child, the one that inspired you to dream of life beyond Prisca's closed borders—and perhaps the very reason you were Selected for Versus—was a memory taken from ${planetname}, the planet you were one day destined to create. 

As the searing finally ceases, you know that at the very least, you have created something beautiful, a bright legacy that will live on long after you are gone.

And so, you go.
*page_break End
We hope you've enjoyed playing [i]VERSUS: The Elite Trials.[/i]

*feedback

Choice of Games releases new games like this one on a regular basis.
*subscribe
*page_break

Thanks for playing!

*ending

*label authornotespace
*page_break END OF BOOK TWO

Make sure to save your game below! You'll need your saved game in the next episode to continue from where you left off.
*save_game v2_save

We hope you've enjoyed playing [i]VERSUS: The Elite Trials.[/i]

*feedback

[i]A note from the author of VERSUS:[/i]

My fellow Versians,

Thank you SO MUCH for continuing to take this crazy intergalactic, genre-bending ride with me! If you enjoyed it as much as I did, you might also get a kick out of my other Choice of Games series (listed below).

As always, the success of these projects rests on you, the readers. And we're always looking for ways to give give back to you (take, for example, the beautiful covers done by our fan artist turned cover artist, Alexandra Tagali), so make sure to head to our social-media sites to be a part of the fan conversation and dive into additional [b]VERSUS Mastery, Growth, & Strategy Guides[/b].

*link https://www.facebook.com/TheVersusSeries VERSUS Facebook
*line_break
*link https://twitter.com/theversusseries VERSUS Twitter

Lastly, if you liked VERSUS and want the story to continue, make your voice heard! Let us know, tell your friends, post, share, like, tweet—but also make sure to leave a review on your purchase platform. Our projects rely almost entirely on word of mouth and the support of our fans, so leaving five-star reviews and sharing your experience means everything! 

If you're looking for a direct way to support the creation of Versus: Book Three AND get insider insight into its writing, check out my new:
*line_break
*link https://www.patreon.com/zacharysergi Patreon!

Thanks again for reading, and here's to hoping there's plenty more in store for ${name} Thomil and the entire VERSUS cast of characters!

A million thanks,
*line_break
*link https://zacharysergi.com/ Zachary Sergi
*link https://zacharysergi.com/subscribe Subscribe for Direct Updates

[i]Zachary Sergi's Choice of Games Titles:[/i]
*line_break
[b]THE VERSUS SERIES[/b]:
*line_break
*link https://www.choiceofgames.com/versus-the-lost-ones/redirect.php?src=v2 Versus: The Lost Ones (Book One)
*line_break
*link https://www.choiceofgames.com/versus-elite-trials/redirect.php?src=v2 Versus: The Elite Trials (Book Two)

[b]THE HEROES RISE TRILOGY[/b]:
*line_break
*link https://www.choiceofgames.com/heroes-rise/redirect.php?src=v2 Heroes Rise: The Prodigy (Book One)
*line_break
*link https://www.choiceofgames.com/heroes-rise-2-hero-project/redirect.php?src=v2 Heroes Rise: The Hero Project (Book Two)
*line_break
*link https://www.choiceofgames.com/heroes-rise-3-herofall/redirect.php?src=ve Heroes Rise: HeroFall (Book Three)

[i]Heroes Rise Presents:[/i]
*line_break
[b]THE HERO PROJECT TRILOGY[/b]
*line_break
*link https://www.choiceofgames.com/hero-project-redemption-season/redirect.php?src=v2 The Hero Project: Redemption Season (Book One)
*line_break
[i]The Hero Project: Book Two[/i] (Expected Release: 2017)

*ending
