*comment é

*set mastery 35
*if (growth < 0)
	*set growth 0
*if (status < 5)
	*set status 5

*if priscantruebeliever
	*set purity 75
*if priscannonbeliever
	*set purity 25
*if priscanconflicted
	*set purity 40

*if (weapons > 75)
	*set weapons 75
*if (weapons < 75) and (weapons > 49)
	*set weapons 60
*if (weapons < 50) and (weapons > 25)
	*set weapons 40
*if (weapons < 25)
	*set weapons 25

*if (regime > 50)
	*set security 60
	*goto ruthtesty
*else
	*set security 40
	*goto ruthtesty

*label ruthtesty
*if (ruthless > 50)
	*set calculating 60
	*goto ruthtestover
*else
	*set calculating 40
	*goto ruthtestover

*label ruthtestover
*if (todrickdie = false) 
	*set breezedie true

*image banner.png center VERSUS: THE ELITE TRIALS

*page_break

*image prologue.png center PROLOGUE: HAUNT

*image prologue_quote.png center "That was rather jarring, was it not?" —Rosae Thomil

*page_break

${deathone} is dead. 

There's no arguing that, and yet, there ${deathone} stands before you. No, not standing, and definitely not before you. It's just a reflection, a shadow of who
*if todrickdie
	he
*if breezedie
	${breze}
used to be.

This is MemoryTravel, you remind yourself as Rosae flutters beside you. Unanchored MemoryTravel, at that. Which means that for the last two nights, you and Rosae have fumbled from one jumbled memory fragment to another, wandering with no living absorption guide.

You're not sure if these fragmented MemoryTravel nightmares are your punishment or your consolation, but you do know this much: 

Tonight is your last chance to make them count.

*page_break

Rosae suddenly lets out a high-pitched chirp beside you, and that's when you see it…

*if todrickdie
	The earthen thing, mud-green and dripping with blackish paint. It raises its long, rake-like fingers in your direction, letting out a guttural moan laced with malice and anguish you can feel.
*if breezedie
	The airy thing, night-black and punctured. It raises its hollow, disintegrating fingers in your direction, letting out a whining moan laced with terror and anguish you can feel.
*comment endif

It wants you to pay. It wants to consume you. It wants to ravage your mind.

So will you let it?

*choice
	*if (todrickdie) #Use the farming tools stored in my belt against this monster.
		*set tech +6

		You unlatch the retractable scythe from your weapons belt and swing it at the monster, screaming furiously. The muddy monster easily dodges the blow, however, creeping closer to you with its sodden darkness.

		So you focus harder, trying to access your absorption skills and heighten them past your usual fail-safes so the monster cannot predict your next move.

		Spinning quickly, you spike the tip of the scythe into the ground and pivot your body around the posted shaft, launching into a kick that knocks the monster back.  
		*goto absorbstream
	*if (breezedie) #Use my residual Binarian rationality to banish this monster.
		*set tech +6

		You know what you see is nothing but a nightmare, one without an absorbee anchor to tether it to historical reality. So you focus on banishing the monster with a pure stream of rationality…but the monster easily overcomes any trace of the rational, creeping closer to you with its icy ethereality.

		So you focus harder, trying to access your absorption skills and heighten them past your usual fail-safes so that the monster cannot predict your next thought.

		Standing your ground, you curl your thoughts into a mental fist and batter the monster with a blunt punch of rationality.
		*goto absorbstream
	*if (todrickdie) #Use my inner golden glow to repel this monster's darkness.
		*set energy +6

		You unleash a blast of pure golden energy from your hands, screaming as its force pours through you. The monster just seems to absorb the blast in its dark folds, however, creeping ever closer to you.

		So you focus harder, trying to access your absorption skills and heighten them past your usual fail-safes so the monster cannot predict your next move.

		Standing your ground, you curl your fingers into fists and double down on the energy, releasing an immensely powerful blast that knocks the monster back.
		*goto absorbstream
	*if (breezedie) #Use my borrowed wind energy to repel this monster.
		*set energy +6

		You unleash a blast of pure wind from your hands, screaming as its force pours through you. The monster seems just seems to absorb the blast in its dark folds, however, creeping ever closer to you.

		You focus harder, trying to access your absorption skills and heighten them past your usual fail-safes so the monster cannot predict your next move.

		Standing your ground, you curl your fingers into fists and double down on the wind strength, releasing a gale-force blast that knocks the monster back.
		*goto absorbstream
	#Use my borrowed divine strength against this monster.
		*set strength +6

		You stand your ground and try to grasp the monster, so that you can toss it far away with your bare hands. The monster easily evades your grip with it slinky maneuvers, however, dodging and returning to consume you.

		You focus harder, trying to access your absorption skills and heighten them past your usual fail-safes so the monster cannot predict your next move.

		Standing your ground once again, you curl your fingers into fists and batter the monster with a blunt punch that knocks it backwards with bone-shattering force.
		*goto absorbstream

*label absorbstream
*page_break

*if (tech > 19)
	*set technovice true
	*achieve technoviceachieve
*if (energy > 9)
	*set energyapprentice true
	*achieve energyappachieve
*if (strength > 9)
	*set strengthapprentice true
	*achieve strengthappachieve

*set techapprentice true
*achieve techappachieve

*set agile 0
*set command 0
*set energy 0
*set strength 0
*set tech 0

The monster is sent reeling away—but so are you and Rosae, in turn. You fall and fall and fall, until you land…

*if todrickdie
	At a dinner table? 

	Seated across from you is Todrick, gathered with a group of people who must be his family, since they all look just like him. Taking in the cozy dining room, you find that there are paintings everywhere done by Todrick, just like in his Versus cottage.
*if breezedie
	On a rooftop shining underneath the setting sun? 

	There's no one else here, save for someone crouched in the corner and crying—someone who turns out to be Breeze. $!{Breze} is curled in a ball while boldly costumed people fly by across the sky above ${brehir}, ${brehis} tears drowned out as these champions soar to the sounds of cheers and explosions.
*comment endif

Seeing this, you feel your heart break a little—though you can't tell if it's your heart or ${deathone}'s that really does the breaking. 

Before you can say anything, a red light begins to creep around ${deathone}. As it builds into a bright shine, you realize immediately that you've fallen into the perfect moment—because that's the teleportation signature unique to Versus, the one that Selects inhabitants.

*page_break

As you feel yourself pulled out of MemoryTravel and back to Versus, a wave of relief hits you. Not just because you'll finally escape these nightmarish fragments, but because seeing ${deathone} teleported like this confirms what you already felt in your gut when you first full absorbed 
*if todrickdie
	him
*if breezedie
	${brehir}
at the farewell party…

"Mission accomplished, and not a moment too soon if you ask me! That was rather jarring, was it not?" Rosae says as she fades away beside you. "This confirms that ${deathone} is not Dhanthik. Which means it's time for me to sign off until our next—oh dear, your Absorb statistics!" 

Hearing Rosae's cry, you use your newly achieved Tech Apprentice skill to check your Stats Screen. Once you do, you see why Rosae seems to be so concerned: your absorb areas have been rebooted and reconfigured. 

What the blerg?

*page_break

"How odd. I must investigate this further," Rosae says, already sounding lost in thought. "I will report back when I have some answers!"

As you wave goodbye to Rosae, you find it easy to remain calm about this absorption change, knowing that Rosae is on the case. This causes you to experience another pang of emotion, because while you're comforted to know that you'll get to see Rosae again, you realize that this is probably the last time you'll get to see ${deathone}.

Ever. 

As ${deathone}'s image now shrinks further and further away, you feel yourself slipping away too, slipping back…

To the morning that will change everything you've come to know about Versus.

*page_break PART ONE: TRIAL AND ERROR

*image part1.png center PART ONE: TRIAL AND ERROR

*image chap1.png center CHAPTER ONE: TOKEN

*image chap1_quote.png center "I was an Ord just like you not too long ago, so I know how the Elite system seems from the outside—but I promise it's not really what you must think." —Cadet Gadget 

*page_break

You open your eyes to find a bucktoothed and twitching Aye Aye settling a tray of breakfast beside your bed. Not just any Aye Aye—it wears a black blazer, shirt, and tie over its thick fur and attempts a bow as it retreats. That's Ayeleen, the Elite Courte Aye Ayemaid assigned to you.

As Ayeleen begins the long journey across your palatial suite to its own adjacent quarters, you inevitably feel the weight of your MemoryTravel nightmare tug on your mind. Trying to shake it off, you take a deep breath and stretch out your limbs. As awful as it has been to be haunted by ${deathone} these two long nights, at least you know it will be over today, when your full absorb finally fades.

As a matter of fact, you can already feel 
*if todrickdie
	Todrick's buoyancy and speediness 
*if breezedie
	Breeze's airiness and lightness 
receding, leaving you with a distinctly heavy, leaden feeling. Trying to ignore the weight of ${deathone}'s loss, you instead focus on the fact that this means you can now initiate a brand-new full absorb.

Which officially becomes the second-most exciting and nerve-inducing adventure you'll probably embark upon today.

*page_break

Stepping out of your sovereign-sized bed, you leave behind the comforts of your high-thread-count sheets for the equally luxurious plushness of your robe. You then walk across the cool marble floors with a cup of coffee, your new favorite addiction, in your hands.

Ayeleen has already pulled back the curtains, revealing the expansive view stretching as far as the eye can see. Your suite sits atop one of the highest floors of The Elite Castle, which in turn sits atop the bluffs overlooking the Love Lake. The lake shimmers beneath you now, untouched except for the gilded voting amphitheater hovering in its alcove, gleaming in the morning sun.

Beyond the lake, you settle your eyes on what has quickly become your favorite sight:

*choice
	#The Verses Village beyond the lake, where you can see the Inn clearly.
		*if todrickdie
			*set rlshp_breeze %+5
			You picture Breeze in ${brehis} beachy room inside, sleeping soundly.
			*goto viewcred
		*else
			You picture Breeze's beachy room inside, now left empty.
			*goto viewcred
	#The colorful squares showing in patches between the farmland cottages and woods.
		*if todrickdie
			You picture the inside of Todrick's cozy cottage, now left empty.
			*goto viewcred
		*else
			*set rlshp_todrick %+5
			You picture Todrick in his own cozy cottage, sleeping soundly.
			*goto viewcred
	#The Icecap Mountains looming in the distance.
		Massive clouds hover above the Icecaps, almost as large as the mountains themselves.
		*goto viewcred
	#The treetops of the Uniforest on the horizon.
		*set rlshp_ob %+5
		You picture OtherBoard in her camp there, sleeping soundly—until you remember that she doesn't actually need to sleep.
		*goto viewcred
	#The fiery breath of the Volcano Rapids emerging every so often over the horizon.
		You can't help but wonder what lies in those distant "Deathscapes," where Empress Vaccus and the final unrevealed Ord might dwell.
		*goto viewcred

*label viewcred

Moving on, you decide to access your Dhanthik checklist and mentally cross ${deathone} off—along with OtherBoard, that makes two Versians down and twenty-one left to go.

As you already know, today brings another opportunity to full absorb someone new—which should prove particularly interesting, given that today will also be the official start of The Elite Trials. You had no idea what to expect yesterday when Ayeleen came to fetch you from the Village Inn, where you had spent your third night on Versus. Ayeleen led you up to the Castle, taking you through a discreet service entrance and directly to this suite, where you spent the day pampered with massages, steam baths, and all the food you could stomach.

You then spent the rest of yesterday in isolation, told only that you'd be allowed to leave your room when the first Trial began today. Given the fact that today will also see the second Versus Vote take place, you were thankful for the opportunity to rest—you have a very full day ahead of you.

You turn and look across your deluxe suite. You found it a bit strange to be treated so secretively upon entering the Castle and you're dying to see the rest of it, but it's also hard to care too much about being stuck in your rather luxurious suite—which comes complete with its own kitchen, dining room, mini spa, and servant quarters.

*page_break

You stand in the grand bedroom, taking in the twenty-foot ceilings; the gold, purple, and green drapery; the canopy bed; and the marble floor with its intersecting V pattern. There are paintings on the wall that you think might depict former Elite Versians, potentially even those who have been Reborn. These paintings hang on opposite sides of a massive banner that bears some kind of insignia: a white flame placed in the center of a red letter A. You can only assume that this must be the royal seal of Queen Ashe or The Elite Courte, or perhaps even both. 

The most noteworthy feature of your suite, however, is the library's worth of bookshelves filled from floor to ceiling with intergalactic fiction—you could spend months exploring just these shelves, let alone what wonders the rest of the Castle must offer.

You can certainly see how someone could get used to life as an Elite—so you have to remind yourself that your goal, at least for now, 
*if winjoin
	is indeed to earn a spot in this Castle by winning The Elite Trials. Thankfully, your experience here so far has only helped to reinforce that desire.
*if doubleagent
	is indeed to earn a spot in The Elite Courte. You're not necessarily relying on winning the Trials to make that happen, but you'll still need to do well enough to earn an audience with Queen Ashe somehow—she is the only one you know you can trust not to be in Lady Venuma's coup. 
*if coupspy
	is to spy on The Elite Courte to help the coup take them down. You shouldn't get too used to these accomodations—or maybe you should, since part of this goal does actually require winning a spot via The Elite Trials so you can continue to spy and further diminish the Elite majority numbers from within.
*if coupbond
	is to overthrow the Elite—the spoils of this Castle should belong to everyone. You know, however, that in order to meet the other potential coup members and bond with Lady Venuma further, not to mention have access to an Elite full absorb, you'll need do well in The Elite Trials, at least at first.
*if eliteinfo
	is to use your time in The Elite Trials to gather information and generally avoid the politics. You may only care about having access to The Elite Courte to broaden your search, but you do at least have to do well enough in The Elite Trials to access as many Elite absorbs as you can.
*comment endif
	
Which, in turn, means that you had better start preparing for these Elite Trials…

*page_break

You walk toward the large wooden armoire set against one of the walls and open it to find your Priscan Battlesuite laundered, cleaned, and polished to perfection. You can see other piles of clothing in the clear drawers below, but they're all locked behind panes of glass—obviously you're supposed to wear your native Priscan clothes for the beginning of the Trials, for whatever reason.

Which is just as well, since something tells you that you'll need your Battlesuite today, given that you'll have no absorbed abilities to rely on as you enter the Trials.

Taking a deep breath, you catch a glimpse of yourself in the armoire's mirrored interior. The reflective surface make you think of Prisca, and you get a pang of homesickness despite yourself. You still don't know if your homeworld has been shattered to pieces by the Blots in your absence, but instead you force yourself to picture Mother, Father, and Gilo in your house right now, in the mirrored contemplation room, reciting the Dhanthik reflection. If only you could share with them all that you've learned since being on Versus and tell them that you actually got to meet Dhanthik…well, sort of.

Breathing out, you focus on the mirror patch on your left cheek, channeling it as a source of strength. You take in its unique shape, which is meant to represent the essence of who you are. When teenagers come of age on Prisca, they are able to have the honor of reshaping their plain rectangular mirror-patch tattoos individually. When your day came, you chose:

*choice
	#A star, to represent my desire to explore the galaxy.
		*set mirrorshape "star"
		*set growth +1
		*goto readynowsteady
	#A healing medical cross.
		*set mirrorshape "cross"
		*set mastery +1
		*goto readynowsteady
	#The symbol of the Reflectionist elders, a circular mirror.
		*set mirrorshape "circle"
		*set enlighten %+5
		*goto readynowsteady
	#The two lines of an equality sign.
		*set mirrorshape "equality sign"
		*set security %-5
		*goto readynowsteady
	#A dagger.
		*set mirrorshape "dagger"
		*set weapons %+5
		*goto readynowsteady
	#An abstract shape, to represent free thought.
		*set mirrorshape "abstract shape"
		*Set enlighten %-5
		*goto readynowsteady
	#My family crest, the seal of the Priscan General authority.
		*set mirrorshape "crest"
		*set security %+5
		*goto readynowsteady
	#A wildflower, to represent the untamed potential of the Priscan mind.
		*set mirrorshape "flower"
		*set weapons %-5
		*goto readynowsteady
	#A different shape…
		*set enlighten %-5
		*input_text mirrorshape
		*goto readynowsteady 

*label readynowsteady

Touching your mirrored ${mirrorshape} patch, you try to draw from it the motivation you need to face all that will inevitably come today.

Only then, after this moment of reflection, do you reach forward and begin armoring up in your Priscan Battlesuite.

Luckily you now have Ayeleen to assist you in this task, albeit silently—and somewhat begrudgingly, if you had to guess.

*page_break Not Long After

You find yourself in the backyard of the Castle, though "back-grounds" would probably be a more appropriate term. You stand on a flat patch of patio before a stretch of grass that goes on for half an acre, disturbed only by a lush greenhouse off to the right. The grass then gives way to a rolling hill, where you can just barely glimpse more elaborate gardens below and beyond. Looming behind all of the greenery, several miles in the distance, is another massive wall—but you can't quite tell from here whether it's another Versus barrier or something Versian-made.

As breathtaking and awesome as the sight may be, there's much more to currently occupy your attention. For example, Lady Venuma is now floating before you in all her golden glory, hovering perfectly in place against the lush background. She wears knee-high patent-leather boots, and her flowing black caftan is held in place by a golden body-necklace studded with canary diamonds. These match the chain-link headpiece that hangs elegantly across her forehead and contains a single golden-yellow gemstone. Lady Venuma's look is completed with a high, tight ponytail that pulls her already-sharp features tighter, making her seem even more impeccable and impenetrable than usual.

"First, I would like to officially welcome our Ord Entrants into The Elite Trials," Lady Venuma begins, her voice as high and clear as ever. She addresses you all as one group, not pausing to acknowledge anyone individually—not even you. "While The Unpronounceable One has once again declined our invitation, the four of you have graciously accepted and attended."

*page_break

You look to your right and see the other three Entrants, all of whom seem relatively unsurprised to hear this news. They also all wear the clothes they arrived in, freshly cleaned just like yours. Pinkuju stands beside you in her black-and-pink-striped racing jumpsuit and matching helmet, with her blackmetal wings already unfurled—she clearly means business. 

Beside Pinkuju floats Baron Airon, his arms crossed against his bare chest and his bronzed skin reflecting the sunlight. You can see Grog towering tall behind both of the others, noticing that its usually filthy pale yellow skin looks washed clean and its enormous fingernails appear painted with a new design: the intersecting V's of the Versus Verses.

Seeing all of these now-familiar faces, you can't help but think of your third night on Versus, after ${deathone}'s funeral and before your first MemoryTravel nightmare…

*if thruple
	You stayed at the Inn and hoped Lady Venuma would be able to visit, but you knew that she'd probably remain confined to The Elite Castle. Instead, you walked down the hallway to see if you could spend some time with Breeze.
	*goto breezeroutes
*elseif lvfinalromance
	You stayed at the Inn and hoped Lady Venuma would be able to visit, but you knew that she'd probably remain confined to The Elite Castle. Instead, you had to make do with a fantasy of your own making…and seeing Lady Venuma now brings back the memory.
	*goto lvchoice
*elseif brefinalromance
	You immediately walked down the hallway to see if you could spend some more time with Breeze.
	*goto breezeroutes
*else
	*goto generalchoice

*label lvchoice
*choice
	#I dreamed of getting to know Lady Venuma, inside and out. Again.
		*set rlshp_venuma %+10
		You and Lady Venuma got so very much inside each other earlier, given your ambient absorb ability and her emotional intuition skill. You also got very well acquainted with Lady Venuma's outside in the process…
		*goto lvcontspee
	#I remembered the feeling of Lady Venuma's lips.
		*set rlshp_venuma %+10
		Not just the taste of her lips as they touched your own, but the feeling of them traveling all over your body…
		*goto lvcontspee
	#I remembered the feeling of Lady Venuma's power coursing through me.
		*set rlshp_venuma %+10
		You and Lady Venuma got so very much inside each other earlier, given your ambient absorb ability and her emotional intuition skill. The feeling of her immense power filling you up was as enticing as it was overwhelming…
		*goto lvcontspee
	#Actually, I tabled the fantasy to reflect upon ${deathone} respectfully.
		*set calculating %-10
		*goto lvcontspee
	#Actually, I tabled the fantasy to review the Versus political landscape and ponder potential moves.
		*set calculating %+10
		*goto lvcontspee

*label breezeroutes

*choice
	*if ((thruple) or (breezeinsult)) #I wanted to address that Breeze lied to me about being involved with Lady Venuma—unless, of course, it turns out Lady Venuma was the one lying to me.
		*label butbreeze
		However, Breeze ignored your knocks, if ${breze} was even inside ${brehis} room to hear them in the first place. 

		You rationalized this lack of a response by assuming: 

		*choice
			#Breeze must have just been upset about Todrick's death, or perhaps the fact ${breze} wasn't chosen for The Elite Trials.
				*set rlshp_breeze %+10
				*label breeokay

				Breeze probably just needed some space. Still, now you're not sure you'll get to see Breeze until after The Elite Trials, which makes you quite sad. Hopefully you get the chance to have an honest conversation with Breeze once this is all over.
				*goto lvcontspee
			#Breeze must not have been in ${brehis} room; otherwise ${breze} would have answered.
				*set rlshp_breeze %+10
				*goto breeokay
			#Actually, I think Breeze was in there and avoiding me, which makes me angry.
				*set rlshp_breeze %-10

				Now you're not sure you'll get to see Breeze until after The Elite Trials, which makes you even angrier. Hopefully you get the chance to have an honest conversation with Breeze once this is all over. Or rather, not hopefully—you're going to make sure you do, no matter what.
				*goto lvcontspee
			*if (bretimeprocess) #Perhaps Breeeze is avoiding me because of what happened.
				*goto breeokay
	*if (bretimeprocess) #I hoped to talk about what Breeze revealed to me at the party and my response.
		*goto butbreeze
	*if (brefinalnohookup) #I hoped to hook up with Breeze for the first time, now that we would have proper time and privacy.
		*label breintimat
		*set rlshp_breeze %+10

		However, Breeze ignored your knocks, if ${breze} was even inside ${brehis} room to hear them. You wanted to tell yourself there was no answer because Breeze was upset about Todrick's death, or perhaps because ${breze} wasn't chosen for The Elite Trials. You didn't want to consider the possibility that ${breze} ignored you for some other reason….

		Now you're not sure you'll get to see Breeze until after The Elite Trials, which makes you quite sad. Hopefully you get the chance to finally be intimate with Breeze once this is all over.
		*goto lvcontspee
	*if (brefinalnohookup = false) #I hoped to hook up with Breeze again, especially now that we would have proper time and privacy.
		*goto breintimat
	#I hoped to spend more time with Breeze and get to know ${brehir} better.
		*goto breintimat
	#Actually, I wanted to reflect upon Todrick's death respectfully.
		*set calculating %-10
		*goto lvcontspee
	#Actually, I wanted to review the Versus political landscape and ponder potential moves.
		*set calculating %+10
		*goto lvcontspee

*label generalchoice

You decided to spend that time:

*choice
	#Thinking about Oli.
		*set rlshp_oli %+10
		You wished you could see Oli that night, but you knew you'd have to wait until the next time ${olize} would be able to pull your consciousness away to the brainplane. Or at least until the start of The Elite Trials, where you might get the chance to see Oli again.
		*goto lvcontspee
	*if (obnsr) #Thinking about OtherBoard.
		*set rlshp_ob %+10
		You almost thought about trekking out into the UniForest to visit her, but your aching body didn't allow it. Hopefully now that OtherBoard has begun to break her isolation, she'll be more comfortable meeting you in the middle, too.
		*goto lvcontspee
	*if (attractedtomen) #Visiting Baron Airon.
		*set aironhookup true
		*set rlshp_airon %+15

		You snuck out to go to Baron Airon's cottage, after the lustful looks he had been giving you. You found Grog sleeping in the dirt outside, but were very unprepared for what you found inside….
		*goto lvcontspee
	#Going over questions about Versus and my situation.
		*set calculating %+10
		These questions seem to plague your mind whenever you have a moment of downtime, and sometimes even when you don't. Who is Dhanthik? Why were you selected for Versus? What must you do to be Reborn? What will become of Mother’s Priscan General inheritance mandate if you ever do return? What was the outcome of the Blot battle before you were selected? What is Breeze’s secret? Who is Oli, really? How can you defeat the Bominate, if you ever need to? What is the galactic threat Dhanthik seems to be preparing for? These questions, related or random, always seem to occupy your ever-turning mind.
		*goto lvcontspee
	#Thinking of home and wondering what has happened there.
		*set calculating %-10
		These questions seem to plague your mind whenever you have a moment of downtime, and sometimes even when you don't. What was the outcome of the Blot battle before you were selected? What must you do to be Reborn and return to Prisca? What will become of Mother’s General Priscan inheritance mandate if you ever do return?
		*goto lvcontspee
	#Reflecting upon ${deathone} respectfully.
		*set calculating %-5
		*goto lvcontspee
	#Contemplating the Versus political landscape and pondering potential moves.
		*set calculating %+5
		*goto lvcontspee

*label lvcontspee

Lady Venuma's voice pulls you away from this memory, however, as she continues her introductory speech.

"The Elite Trials will unfold over three days and include three separate events. At the conclusion of each event, one Entrant will be dismissed from the Trials and asked to leave the Castle. The last Entrant remaining after all three Trials will become the official thirteenth member of The Elite Courte."

Hearing this announcement sends a jolt through your body—because it means if you don't perform well today, this experience could be over before it has even had the chance to begin. You can tell the news has the same effect on the other three Entrants beside you. You can't imagine any of them has more at stake than you, given your Dhanthik mission—though you remind yourself that you don't really know all that much about Pinkuju, Baron Airon, or Grog just yet, so who knows what they each have to lose.

"Each Trial will be overseen by a Wone guardian and run by a select portion of Elite members, but all other nonparticipating Elites will review the Trials from roving skyboxes."

As Lady Venuma says this, you notice three Elite skyboxes suddenly moving into position above her, each a different royal metal: gold, silver, and bronze. You suppose these hidden Elites—Queen Ashe, Oli, Royal A-08 and all those still yet to reveal themselves—will be following you through the Trial, passing judgment from on high.

*page_break

"This first Trial, which I have been given stewardship over, is meant to test your skill, strength, and natural ability," Lady Venuma continues. "I have selected three of our newest Elite members to help run this Trial as Delegates, all of whom are currently stationed throughout the Elite gardens. 

"Each Elite Delegate has been given four tokens, one designated for each of you, and your task is simple: acquire one token from each of the three Delegates, by any means necessary. Whether you feel this requires force or finesse is entirely left to your individual discretion. The first three Entrants to return here with three tokens each will advance to the second Trial and be rewarded with a special Elite victory brunch."

[i]So this is a flat-out race,[/i] you think—which is something Pinkuju looks quite well-equipped to excel at, not to mention Baron Airon, with his avian flight abilities. And then there's Grog, who might seem big and slow, but still remains astoundingly strong and durable. However, you quickly remind yourself this race is about much more than just speed or strength—it's about combat, or perhaps even finding diplomatic ways around combat. Whoever these unknown Elite Delegates will be, it sounds like you'll have to assess them individually, to see what qualities they respond to most….

Which, thankfully, is your Priscan specialty.

*page_break

"I wish you the best of luck," Lady Venuma says as she floats down to the ground, apparently having explained all she needs to. "Now, may the worthy Entrants rise to the occasion. You may begin."

The instant Lady Venuma's heels touch the ground, Pinkuju bursts forward in a blur, invisible contrail waving from her blackmetal wings. As she rockets away over the grassy hill, Baron Airon turns to Grog and says: "Slave, stay here and do not move."

Baron Airon then takes flight himself, heading over the grassy hill in the opposite direction of Pinkuju. You figure that means you'd better head toward the greenhouse too, though you can't help but feel for Grog, who stays put after Baron Airon's command. Thankfully, as you sprint forward you manage to hear Lady Venuma speaking behind you:

"I give you permission to move," Lady Venuma states. "Remember what we discussed, Groggy? Baron Airon will have to learn that there is only one master here."

As you run out of earshot, you have to wonder: is Lady Venuma referring to herself or to Queen Ashe?

*page_break Across The Field

Sprinting toward the greenhouse, you already think it's a shame you have to rush through this experience. This isn't the first beautiful garden you've graced on Versus, but it certainly might be the most breathtaking—and you've barely even begun to enter its depths. 

You're currently running through a long trellis tunnel overgrown with leaves, hanging vines, and great clusters of purple-pink flowers. The trellis is one of four that lead to the freestanding greenhouse, and you can't even begin to imagine what exotic foliage you'll find inside that space.

Crunching over mulchy grass, you approach the front entrance of the greenhouse and find its glass-paned walls are tinted so that you cannot see inside. You can see another figure approaching from an adjacent trellis, though—and the lumbering steps shaking the ground with every bound tell you that this must be Grog. Not only did Grog clearly decide to listen to Lady Venuma after all, but it would seem that it is way faster than you would have expected, too.

You and Grog both reach the front entrance at the same time, but instead of looking anxious or agitated, Grog simply waves at you with a glum smile.

*page_break

"One at a time, please."

You can't be sure where this voice comes from, though you think you see a light shine from one of the windows behind Grog as the voice speaks. It sounds lovely, almost like an electric organ harmonizing with itself on multiple high and low frequencies. 

Whatever or wherever this voice is coming from, its message is clear. You look at Grog, wondering if you'll have to fight for your entrance spot and what you could possibly do to overcome its brute strength. The best you could hope to do is distract Grog, probably….

"Priscy, I'm operating outside of my typical warning protocols for the moment, because I have an urgent update regarding your absorb areas," Rosae suddenly chirps in your ear, in a voice you know that only you can hear. "With each full absorb, the nature of your absorb abilities seems to shift slightly, which is perfectly normal. However, it seems that the combination of ${deathone} dying during your full absorb and your unprecedented lateral MemoryTravel experience has served to reconfigure your absorb ability. 

"The mechanized point system that was associated with OtherBoard appears to have completely rebooted and to have evolved into a more organic system. I have compiled a quick tutorial on how best to take advantage of this new absorb system, so bear with me. Your absorb areas are now broken into percentage categories, so you can strengthen and affect them at all times.
*if energyapprentice
	Now that you are an Energy and Tech Apprentice, the next time you max out each of these percentage bars it will upgrade you to Novice and unlock a new skill. However, I must recommend focusing on a secondary stat to enrich before then, perhaps bringing Strength or Command."
	*goto radvice
*elseif strengthapprentice
	Now that you are a Strength and Tech Apprentice, the next time you max out each of these percentage bars it will upgrade you to Novice and unlock a new skill. However, I must recommend focusing on a secondary stat to enrich before then, perhaps Energy or Command."
	*goto radvice
*elseif technovice
	Now that you are a Tech Novice, the next time you max out this percentage bar it will upgrade you to Expert and unlock a new skill. However, I must recommend focusing on a secondary stat to enrich before then, perhaps Energy, Command, or Strength."
	*goto radvice
*else
	Now that you are a Tech Apprentice, the next time you max out this percentage bar it will upgrade you to Novice and unlock a new skill. However, I must recommend focusing on a secondary stat to enrich before then, perhaps Energy, Command, or Strength."
	*goto radvice

*label radvice
*page_break

As Rosae's advice on your new absorb system rings in your ears, you see Grog take a step…backward? It appears Grog is stepping aside so that you may be the one to enter first, but the question now becomes: Do you trust Grog to let you pass? 

Just as soon as you think this, Rosae's voice once again chirps in your ear.

"One last warning before I leave you be, Priscy. I have yet to sort out the precise consequences of this momentous absorb shift, but until I do, you should probably wait until the victory brunch to full absorb anyone," Rosae concludes. 
*if extraworning
	*label yonote
	"Now operating on my Extra WorningBird function, I must advise you
	*if energyapprentice
		to utilize your Strength or Command skill, choosing perhaps the grav-glider or a Mindbolt.
		*goto infavorof
	*elseif strengthapprentice
		to utilize your Energy or Command skill, choosing perhaps a Mindbolt or the grav-gun.
		*goto infavorof
	*else
		to utilize your Strength or Energy skill, choosing perhaps the grav-gun or grav-glider.
		*label infavorof
		Unless you'd rather prioritize being more diplomatic, of course."

		You've noticed Rosae has stopped giving you general simplistic warnings in favor of these more sophisticated warnings, which seems to reflect her more complex true nature. This is fine by you, since the warnings tend to come when you have to make crucial choices…like now.
		*goto cdgchoose
*else
	"If you would like to continue receiving warnings like this, please activate my official Extra WorningBird function."

	Would you like to activate Rosae's more sophisticated function option? 

	*check_purchase extraworning
	*if choice_purchased_extraworning
		[i]You've paid to unlock the Extra WorningBird function with an in-app purchase.[/i]

		*choice
			#Unlock Rosae's Extra WorningBird function again, at no additional charge.
				*label purchasedextraworning
				*set extraworning true
				*goto yonote
			#No, I won't need this bonus feature.
				*label noextraworning
				You've noticed that Rosae has stopped giving you general simplistic warnings in favor of these more sophisticated warnings, which seems to reflect her more complex true nature. You can't help but wonder what she'd tell you now if she were properly enabled.
				*goto cdgchoose
	*else
		*purchase extraworning $0.99 purchasedextraworning
		*page_break No, Thanks
		*goto noextraworning

*label cdgchoose

*choice
	#Stun Grog with a gravity blast from my grav-gun because I don't trust Grog to let me pass.
		*set weapons %+20
		*set energy +7 
		*set tech +7
		*set rlshp_grog 30
		*set calculating %+15

		You quickly draw your grav-gun and fire off a gravity blast that knocks Grog in the side of the head. It doesn't seem to totally put Grog down, but it does give you enough cover to rush into the greenhouse uninterrupted.

		*label grogsad
		You've guaranteed yourself entrance, but you had also better beware a potentially angry Grog the next time you run into it. Still, you remind yourself that if Grog is willing to let everyone else step ahead of it, it probably stands little chance of winning this first Trial anyway.  

		So you enter the greenhouse with as little guilt as possible, as Grog takes a seat glumly against the nearest wall.
		*goto grogmove
	#Accept Grog's invitation, activating my grav-glider to make it to the door swiftly just in case.
		*set weapons %+20
		*set strength +7
		*set agile +7
		*set rlshp_grog 70
		*set calculating %-15

		You burst forward in a blur of grav-powered speed, waving to a still-smiling Grog as you pass. 

		You feel an immediate pang of emotion at seeing this. You can't be sure whether it's a sign of kindness or submission, but you can be sure of one thing: if Grog is willing to let everyone else step ahead of it, it probably stands little chance of winning this first Trial.  

		You nod a quick thank you, then enter the greenhouse as Grog takes a seat beside the door with a heavy thud.
		*goto grogmove
	#Disorient Grog with a Priscan shareburst mindbolt because I don't trust Grog to let me pass.
		*set weapons %-20
		*set command +7
		*set energy +7
		*set rlshp_grog 30
		*set calculating %+15

		You fire off a quickly generated shareburst mindbolt that knocks Grog in the side of the head. It doesn't seem to totally put Grog down, but it does give you enough cover to rush into the greenhouse uninterrupted, as Grog seems totally confused.

		*goto grogsad

*label grogmove
*page_break Into The Greenhouse

Once inside the greenhouse, you stop dead in your tracks as your senses are completely overwhelmed: you are blinded by intense reflections of sunlight, your skin immediately moistens from the dense humidity, and your nostrils clog with thick, burnt pollen.

Activating your Battlesuite visor sunshade mode, you wait a few moments for the flashes to stop spotting your vision. Unfortunately, in those moments you also begin to sneeze uncontrollably into your visor, which you then have to retract with your eyes pressed shut.

"Terribly sorry, I always forget how the shinevines affect unenlightened humans," the voice sounds again, its harmonized tones reverberating across the greenhouse. "Ah, and I mean unen-light-ened quite literally; I wouldn't want to sound like some kind of Elitist snob. Though I suppose that must seem rather oxymoronic, given the situation."

Thankfully this mini-speech gives you enough time to stop sneezing, reengage your sunshade visor, and adjust to the light in the greenhouse…which you now realize is coming from rows and rows of crystal plants, all of which sprout several flowers made of sunlight. The sight is stunning and it instantly reminds you of the Priscan mirrorwoods gleaming in the midday sun. These plants are actually quite different than the mirrortrees, though, with their clear stalks and glowing petals.

*page_break

"You must be ${name}," the harmonized voice echoes. As it does, you notice a corresponding beam of light pulsing through the greenhouse to match the tone. You're not sure how you're able to distinguish the voice-beam from the sunlight and lightflowers pouring through the greenhouse, but somehow you can. "I have a rather prodigious list of questions about Prisca for you, two hundred and sixty-three to be exact! You'd be surprised how little is written or recorded about Prisca, or then again, maybe you wouldn't.

"But I'm afraid that's neither here nor there at the moment, unfortunately," the harmonized voice continues as the beam dances through the greenhouse. "I suppose it's time we cut to the heart of the matter, if only for your sake."

The darting beam suddenly shines in front of you like a spotlight, and you almost look away it's so bright. Still, you force your eyes to stay fixed as the light begins to solidify and twist into the shape of a humanoid man. He wears a uniform of sorts, a white bodysuit of microfiber armor with neon-yellow light accents. There are matching glowing yellow letters on his chest that read "GCC CG1," and a utility belt fitted across his waist that holds some kind of light-ray gun on one side and a medical kit on the other. Something about his pale complexion and oblong eyes actually reminds you of Pinkuju, except this uniformed man's eyes, teeth, and short hair are all translucently clear like the stalks for the lightplants.

"I take it you've never met an officer of the Galactic Council Corps before?" the officer says, his voice now sounding less harmonized in humanoid form. "I'm Cadet-Level Officer Guozhi Ta, but everyone calls me Cadet Gadget for short. Something about the linguistic patterns of most local languages, but I don't have to get into the minutiae."

Cadet Gadget reaches out his hand to shake and you return the gesture, surprised by how dense his grip feels.

*page_break
*set meetcadet true

"Just so you know, we're not going to have to fight or anything. I assume you'll get much more of that sort of thing later, rest assured," Cadet Gadget says. "I'd much rather handle things diplomatically than resort to violence, but then again, any good GCC officer should feel that way."

Cadet Gadget beams with a look of pride as you take in his uniform. You had always known there was a Galactic Council out there that Prisca obviously wasn't a part of, a confederation of representatives from many planets meant to govern intergalactic relations and maintain peace. It makes sense that they'd have some kind of policing task force—you wonder if Cadet Gadget's light-based physiology is patented GCC officer technology or part of his own natural biology. You immediately find yourself missing OtherBoard's auto-readouts to tell you such things.

"You must have as many questions for me as I have for you," Cadet Gadget goes on. "Lady Venuma tells us you're a bit of a budding explorer. Well, I'm quite the galactic culture cataloguer myself. That's actually why I joined the GCC originally, as an interpreter."

You try to keep listening to Cadet Gadget, but your mind instantly races with the idea that Lady Venuma has been talking about you. You wonder what that could mean, for better or worse.

"I really do hope we get to spend some real time together, there's just so much to discuss," Cadet Gadget says, causing you to sense the ambient sincerity and eagerness radiating off of him, feeling much like warm light itself.

*page_break

"I think I'd like that," you answer, trying not to be hypnotized by all the light. "I have to admit, you're not exactly what I expected from The Elite Courte, not that I really have much to go on."

"Well, if your only points of reference are Lady Venuma and Royal A-08, as I believe they are, I can see why you'd paint a certain portrait of us," Cadet Gadget laughs. "Trust me, we're not all royalty. In fact, The Elite Courte is actually a rather diverse group, galactically speaking. I'm quite proud to be a part of it. Being Selected for Versus was honor enough, but then to be counted among this group Queen Ashe has gathered…for a peon like me, it's quite the thrill."

"When did you join?" you ask, feeling slightly less anxious about the length of this conversation knowing that you at least are ahead of Grog in this race if it comes down to it.

"This is my second cycle here on Versus—Queen Ashe invited me and my best friend Lockdown at the end of last cycle as auto-Entrants, as she is sometimes known to do. I was an Ord just like you not too long ago, so I know how the Elite system seems from the outside—but I promise it's not really what you must think. Queen Ashe has revolutionized the Versus system, perhaps even improved upon the process's natural strengths, though I suppose that's what creation goddesses are meant to do. 

"Anyway, Versus is all about testing worthiness, and Queen Ashe has simply applied order and peace to a once-chaotic system, to serve the same purpose. For an amateur historian such as I, to be part of such a cultural revolution is really quite something. For even if no one can ever know about it in the galaxy beyond, Versus sets the tone for us all. I understand that much now."

*page_break

Cadet Gadget looks momentarily wistful speaking these words, until he takes a breath and refocuses himself. "Listen to me going on. I'm supposed to be hearing about your beliefs, not my own. So what do you think about this Elite system, ${name}? You can be honest with me; I'd much rather hear what you really think than what you think I want to hear."

You're not sure if you can believe that fully, but Cadet Gadget has certainly gone out of his way to make you comfortable. You suppose it's up to you whether to be truly disarmed or not.

*if extraworning
	"Priscy, if I may interrupt a moment?" Rosae suddenly chirps in your ear. "I'd venture that Cadet Gadget is truly an Elite loyalist, but that's up for you to decide. I must simply caution you to be careful what you say, because as easygoing as our Cadet may seem, your answer here will carry great political weight."
*comment endif

You quickly glance up, but even if an Elite skybox were positioned there, you're not sure that you'd be able to see it through all the light and the tinted windows of the greenhouse. You can't be sure if anyone, including Lady Venuma, is currently eavesdropping. No matter what, you have to remember that the most important thing is deciding who to build relationships with, according to your current Status goal.

*choice
	#"I couldn't be more honored or excited to be here. I want to join The Elite Courte very badly."
		*if (winjoin) or (doubleagent)
			*set status +2
			*set rlshp_cadet %+15
			*set security %+5
			*set trialonespeed +2

			*if winjoin
				*set calculating %-5
				You say this knowing that you really mean it. Your goal, at least at this moment, is to join The Elite Courte however possible.
				*goto cgsmile
			*else
				*set calculating %+5
				You say this like you really mean it. After all, your goal at this moment is to join The Elite Courte however possible, even if it means losing the Trials and returning to the coup as a secretive double agent.
				*goto cgsmile
		*elseif coupspy
			*set status +2
			*set rlshp_cadet %+15
			*set trialonespeed +2
			*set calculating %+5

			Right now you'll say anything to get in the Elite Courte's good graces—at least as long as your goal remains to become an embedded spy for the coup.
			*goto cgsmile
		*else
			*set rlshp_cadet %+5
			*set trialonespeed +1

			You say this just hoping to build a bond with Cadet Gadget for now, not necessarily to further your current agenda.
			*goto cgpause
	#"I really respect Lady Venuma as Ord Ambassador and trust her judgment in having me here."
		*if coupbond
			*set status +2
			*set rlshp_cadet %+5
			*set security %-5
			*set calculating %-5
			*set trialonespeed +2
			
			You say this hoping to test the waters with Cadet Gadget, to see how he might feel about Lady Venuma—and whether he shares your sense of loyalty.
			*goto cgsmile
		*elseif coupspy
			*set status +2
			*set trialonespeed +1
			*set calculating %+5

			You forgo this opportuniy to gush about The Elite Courte and instead say this, hoping to test the waters with Cadet Gadget. You want to see how he might feel about Lady Venuma and whether he shares your sense of loyalty.

			*goto cgsmile
		*else
			*set rlshp_cadet %-5
			*set trialonespeed +1

			You say this just to see how Cadet Gadget will react, even though it doesn't necessarily further your current agenda.
			*goto cgpause
	#"I just want to learn and soak up as much of this experience as possible."
		*set abolishstatus +1
		
		*if eliteinfo
			*set status +2
			*set rlshp_cadet %+15
			*set trialonespeed +2

			You say this because it's absolutely true and you don't want to lie to Cadet Gadget if you don't have to.

			*if (calculating > 50)
				*set calculating %+5
				*goto cgsmile
			*else
				*set calculating %-5
				*goto cgsmile
		*elseif (coupbond) or (winjoin)
			*set status +2
			*set rlshp_cadet %+10
			*set trialonespeed +1
			*set calculating %-5

			You say this in an attempt to connect with Cadet Gadget genuinely, hoping it doesn't seem like you're evading the question—which you are.
			*goto cgpause
		*else
			*set rlshp_cadet %+5
			*set trialonespeed +1
			*set calculating %+5

			You say this in an attempt to connect with Cadet Gadget, hoping it doesn't seem like you're evading the question—which you are.
			*goto cgpause
	#"To be honest, I don't really agree with the whole Elite thing yet."
		*set abolishstatus +1

		*if (coupbond) or (eliteinfo)
			*set status +2
			*set rlshp_cadet %+15
			*set trialonespeed +2
			*set security %-5
			*set calculating %-5

			You say this because it's absolutely true and you don't want to lie to Cadet Gadget if you don't have to.
			*goto cgsmile
		*else
			*set rlshp_cadet %-5
			*set trialonespeed +1

			You say this purely to see how Cadet Gadget will respond, even though it doesn't necessarily further your current agenda.
			*goto cgpause

*label cgsmile

You hope to elicit some reaction from Cadet Gadget, but instead he just smiles a row of now-glowing teeth. 
*goto onequest

*label cgpause

You hope to elicit some reaction from Cadet Gadget, but instead he just pauses, considering your response for much longer than you'd expect—or would want, given the racing circumstances.
*goto onequest

*label onequest

Cadet Gadget considers your answer a moment further, then holds out his hand—where a small golden coin suddenly materializes, made entirely of light. Fathers Below, that must be one of his Trial Delegate tokens!

"Congratulations, ${name}," Cadet Gadget says, his translucent hair and eyes now glowing yellow too. "Like I said earlier, I do someday hope to spend more time together. Best of luck with your remaining challenges in this first Trial!"

Reaching forward without hesitation, you take the light token from Cadet Gadget's hand and…

*choice
	#Shake Cadet Gadget's hand, waiting a few excruciating seconds, to be courteous, before turning to run out of the greenhouse.
		*if (calculating > 50)
			*set rlshp_cadet %+10
			Cadet Gadget clearly appreciates this gesture, understanding the rush you are in.
			*goto takeoffcadeg
		*else
			*set rlshp_cadet %-10
			However, Cadet Gadget obviously senses how forced this gesture is, since you are visibly in a rush.
			*goto takeoffcadeg
	#Run straight out of the greenhouse, not wanting to waste one more second, even if it appears rude.
		*if (calculating > 50)
			*set rlshp_cadet %-5
			While clearly a bit miffed, you can tell Cadet Gadget at least respects the fact that you're in a rush.
			*goto takeoffcadeg
		*else
			*set rlshp_cadet %-10
			A move that does not go over terribly well with the Cadet.
			*goto takeoffcadeg
	#Pull Cadet Gadget into a hug to thank him.
		*if (calculating < 50)
			*set rlshp_cadet %+10
			Cadet Gadget hugs back, clearly thankful for the time you take to offer this gesture. You then send Cadet Gadget a smile before turning to go.
			*goto takeoffcadeg
		*else
			*set rlshp_cadet %-10
			But you can immediately tell this gesture of physical affection feels forced and makes Cadet Gadget feel unexpectedly uncomfortable.
			*goto takeoffcadeg
	*if (attractedtomen) #Smile warmly at Cadet Gadget, because he is completely adorable.
		Cadet Gadget just smiles warmly back at you, seeming completely oblivious to the signal you are sending. So you give Cadet Gadget a quick nod of thanks before turning to go.
		
		*if (calculating < 50)
			*set rlshp_cadet %+10
			*goto takeoffcadeg
		*else
			*set rlshp_cadet %+5
			*goto takeoffcadeg

*label takeoffcadeg

As you take off and Cadet Gadget reverts back into lightform, you can't help but wonder what you said that tipped the scales for him enough to offer his token. 

Whatever it was, you realize that some of The Elite Courte obviously heard what you said as well, since you spot the silver skybox hovering just above the greenhouse as you exit. You don't have the time to consider what that means at the moment—
*if (rlshp_grog = 70)
	all you have time for is a quick wave at Grog
*if (rlshp_grog = 30)
	you only have time to rush past Grog
as it enters the greenhouse you now sprint away from.

*page_break In Another Garden

You breathe heavily as you run up to the edge of a long, winding set of stairs. These stairs lead down to the rolling valley below, where you spot a pond in the distance—a pond Pinkuju is currently flying away from like a human missile on her blackmetal wings. In the blink of an eye she is gone to the left, disappearing into a vast hedge maze. Which means you know exactly what you have to do next.

Activating your own Battlesuite grav-glider, you jump off the edge of the hillside and fly down beside the stairs. The bright colors of flowers lining the stairs swish into a blur as you pick up speed and set your sights on the pond beyond.

You swoop lower to the grass as you approach, taking in the sight of the sturdy, orange-leaved trees that line the pond. These trees stand between bushes of every shade of green imaginable and swaths of vibrant violet, red, and blue flowers.

The scenery is quite vivid and tranquil, but you focus your attention on the center of the pond, where a stony footbridge extends across the water. That's where Pinkuju took off from, so you figure that's where the next Elite Delegate must be waiting—especially since the bronze Elite skybox suddenly emerges from the hedge maze, floating toward this bridge as well.

*page_break

When you land on the footbridge underneath the newly arrived skybox, you don't see anything except for small swarms of insects buzzing among lily pads on the pond's placid surface. Scanning the bright colors along the waterfront, you search for any sign of a person—then, remembering Cadet Gadget's entrance, you wonder if you're even looking for a humanoid in the first place.

Still scanning the pond's shoreline, you catch a flash behind one of the orange trees. You think it looks like the sun reflecting off something metal, like a…crown?

A wave of adrenaline suddenly pulses from your head to your toes and your stomach turns over. Could that possibly be the crown that belongs to Empress Vaccus? And if so, what the blerg is it doing here, lurking behind the trees? Your mind begins to race with images of Empress Vaccus—its rotten, decaying black flesh and limbs studded with blacknamel tusks….

You suppress these images and step forward to get a better look, but whatever metallic gleam you saw now seems to be gone. You're about to activate your grav-glider to investigate when suddenly the water beside the bridge begins to ripple, occupying your attention. Something improbably large begins to break through the surface of the pond.

*page_break

The adrenaline already buzzing in your system now begins to burst through your limbs, and your breath escapes you as the enormous thing rises out of the pond.

Above the footbridge now floats what you can only describe as a storybook dragon, four stories tall and half as wide. Water falls from its scaly pink skin in great cascades and splashes up into the air as the dragon spreads its massive magenta wings.

Its long face is punctured by mountainous sharp teeth, and pink smoke trails from its flared nostrils. It wears a small pouch on a leather strap over its raw chest, and its spiky tail waves above its head, tipped with a swordlike claw.

The dragon fixes its glowing green eyes on you and seems to…wink? Whatever this gesture means, you waste no time equipping yourself for potential defense.

*if extraworning
	*if energyapprentice
		"Priscy, remember you want to build Strength or Command," Rosae chirps hurriedly, sounding rather spooked. "So the defense-panels or standing your ground are your best bets!"
		*goto thelddragcho
	*elseif strengthapprentice
		"Priscy, remember you want to build Energy or Command," Rosae chirps hurriedly, sounding rather spooked. "So the mindbolt is your best bet. Though really, all other options should help build at least one of those areas, too."
		*goto thelddragcho
	*else
		"Priscy, remember you want to build Strength or Energy," Rosae chirps hurriedly, sounding rather spooked. "So finding cover is your best bet. Though really, all available options should help build at least one of those areas, too."
		*goto thelddragcho

*label thelddragcho
*temp techresponse ""
*choice
	#Go on the offensive by preparing to stun the dragon with a Priscan shareburst mindbolt.
		*set command +5
		*set energy +5
		*set weapons %-15
		*set techresponse "power down your mindbolt"
		*goto unequpp
	#Raise the defense-panels on my Battlesuite forearms in front of my face.
		*set strength +5
		*set command +5
		*set weapons %+15
		*set techresponse "lower your defense-panels"
		*goto unequpp
	#Tumble off the bridge to get out of the open and find better cover behind the trees, while also buying time to better assess the situation before reacting.
		*set strength +5
		*set energy +5
		*set calculating %+15
		*set techresponse "return to the footbridge"
		*goto unequpp
	#Stand my ground and remain calm, because I don't want to judge a dragon by its cover—perhaps it's actually friendly and just wants to talk.
		*set command +5
		*set strength +5
		*set calculating %-15
		*set techresponse "exhale"
		*goto unequpp

*label unequpp
As you do so, the dragon suddenly begins to glow with pink energy and shrink before your eyes. You watch in awe as the giant dragon slowly disappears and transforms into the shape of…

A very handsome man, who lands with a soft thud on the footbridge. He stands just over six feet tall, with wavy brown hair that falls to his shoulders and pale beige skin tanned thoroughly by the sun. He has the same round, bright green eyes as the dragon, which now stare at you playfully behind a smiling, scruff-lined jaw seemingly chiseled from stone. Instinctively, you ${techresponse}, no longer feeling the direct threat of being eaten alive.

That's also when you realize this dragon-man stands completely naked, save for the leather strap strung across his muscular chest and flat stomach. The pouch now rests slightly below his belly button, at the bottom of the V his abdominal muscles make. Staring at this dragon-man, you're actually not sure which was more intimidating, the dragon or this statuesque man.
*if (attractedtomen = false)
	You don't even need to be attracted to men to see how beautiful this one is.
*comment endif

"'Ello, sport," the man says, still smiling at you. "Didn't mean to give ya a fright; ya sounded like that wang Sallytran buzzard fly'n by."

*page_break

"Guess'n ah oughta put on some frocks, less you prefer the buff?" the dragon-man says, shifting his weight so that every one of his tanned muscles flexes.

"You're the one in charge here," you say, immediately feeling silly. This dragon-man has thrown you quite off—so off that you were distracted from your potential Empress Vaccus sighting. Seeing nothing now as you quickly scan the pond's shoreline, you chalk it up to a trick of the light, maybe even from the bronze skybox still presiding above you.

But "trick of the light" takes on a totally new meaning as the dragon-man snaps his fingers, causing more pink energy to swirl around his rugged body and magically form clothes. He now wears leather boots and a belt that holds up tight black pants. A leather vest sits over a pink button-down shirt, which remains open down to the top row of his ab muscles. He finally slides the leather pouch to his back, completing the look.

"Ah'm Lockdown the Rage'n Drag'n, infamous Warlock Pirate of Blarfngard," Lockdown says, now looking you over. "Lemme query, ya're the queer Priscan, ${name}?"

*page_break
*set meetlockdown true

"Yes, though I'm not sure being Priscan is considered queer," you answer, trying to adjust to the cadence of Lockdown's unique speech patterns.

"Ah, where ah'm from, queer means someth'n else, someth'n good," Lockdown explains. "But tell me, are all Priscans look'n like ya do?"

You shake your head, suddenly feeling a rush of attraction ambiently sliding off of Lockdown. It smells like musk and sea salt and feels like a wave cresting, rather appropriately. 

"Shame," Lockdown says, shooting you a seductive smile. "Though ah query lucky as piss'n for me, eh?"

*if extraworning
	"Warning, Priscy," Rosae alerts you. "I sense shameless flirting. Don't let all the hormones cloud your judgment here! Never forget your status goals, especially with those skyboxes around!"

*choice
	*if (attractedtomen) #I'm attracted to Lockdown, so I will hit on him just as shamelessly.
		*set rlshp_lockdown %+20
		*set outspoken %+5
		*set crushlockdown true
		*label hitonld

		"The real shame is that you decided to put clothes on," you say, trying to match Lockdown's smile.

		"Issit so?" Lockdown says, looking totally unfazed—but pleased. "Ah could just'a easily blink off your frock too, ya know?"

		"Unfortunately, I don't have much time for magic tricks at the moment," you respond, trying to keep your cheeks from blushing at the thought.

		"Oh, and what'f ah said you had to make time for my tricks?" Lockdown asks, crossing his thick arms.

		"I guess I'd say that I'd like a token of your appreciation in return," you try.

		"Cle'er," Lockdown laughs. "Ah fancy cle'er."

		*label reactionsldpol
		*if (lvfinalromance)
			*set rlshp_venuma %-10
			As Lockdown's gaze blazes a hole in you, you wonder how Lady Venuma will feel about this shameless flirting and whether she is watching up in that bronze skybox.
			*goto magictrick
		*elseif ((winjoin) or (doubleagent)) or (coupspy)
			*set status +2

			As Lockdown's gaze blazes a hole in you, you figure that it's smart for you to keep cozying up to the Elite members like this—the fact that Lockdown is so charming is just a perk.
			*goto magictrick
		*elseif coupbond
			*set abolishstatus +1
			As Lockdown's gaze blazes a hole in you, you just have to hope that he might secretly be in on Lady Venuma's coup as well.
			*goto magictrick
		*else
			*set abolishstatus +1
			As pleasant as this interaction might be, you have to remind yourself that it's just a distraction from your other goals here.
			*goto magictrick
	*if (attractedtomen) #I'm attracted to Lockdown, but don't want to be obvious. I should play hard to get.
		*set rlshp_lockdown %+15
		*set outspoken %-5
		*set crushlockdown true

		*label subtleld
		"The real question is: What do I have to do to earn a token of your affection?" you ask, trying to match Lockdown's smile.

		"Cle'er," Lockdown laughs, looking totally unfazed—but pleased. "Ah fancy cle'er."

		*if (lvfinalromance) 
			*set status +2
		*goto reactionsldpol
	#I'm not interested in Lockdown romantically, but I will hit on him to get on his good side, since that seems to be his game here.
		*set rlshp_lockdown %+15
		*set outspoken %+5
		*goto hitonld
	#I don't know enough about Lockdown to feel anything yet, so I just want to be nice to get to know him better.
		*set rlshp_lockdown %+10
		*set outspoken %-5
		
		"The real question is: What do I have to do to earn a token of your affection?" you ask, trying to match Lockdown's smile.

		"Cle'er," Lockdown laughs, looking totally unfazed—but pleased. "Ah fancy cle'er."

		*if ((winjoin) or (doubleagent)) or (coupspy)
			*set status +2
			*set abolishstatus +1

			As Lockdown's gaze blazes a hole in you, you figure that it's smart for you to keep cozying up to the Elite members—the fact that Lockdown is so handsome is just a perk.
			*goto magictrick
		*elseif coupbond
			As Lockdown's gaze blazes a hole in you, you just have to hope that Lockdown might secretly be in on Lady Venuma's coup as well.
			*goto magictrick
		*else
			*set abolishstatus +1
			As pleasant as this interaction might be, you have to remind yourself that it's just a distraction from your other goals here.
			*if eliteinfo
				*set status +2
				*goto magictrick
			*else
				*goto magictrick
	#I don't trust Lockdown at all.
		*set rlshp_lockdown %-10
		*set outspoken %-5

		"You know what I'm here for, so let's just cut to the chase, shall we?" you ask directly.

		"But why, when foreplay is so much fun?" Lockdown teases, crossing his arms.

		You cross your arms in return, not willing to play into Lockdown's supposed charms.
		*if (coupbond) or (eliteinfo)
			*set status +2

			You don't have any interest in Lockdown—the only interest you might have is finding out whether he is loyal to the Elite or secretly a member of Lady Venuma's coup.
			*goto magictrick
		*else
			*set abolishstatus +1

			You try to force a smile, knowing you'll probably have to win Lockdown over at some point to get further into The Elite Courte's good graces, if you can stomach it.
			*goto magictrick

*label magictrick
*page_break

"Well Ah'm fond'a ya already, so we can be gett'n right down to my token test," Lockdown finally says. "Hope ya fare better'n that Baron Air-head did."

It suddenly clicks for you that Lockdown said he was from Blarfngard, the same planet as Baron Airon, Grog, and Todrick. Lockdown clearly harbors some animosity towards Baron Airon, but you wonder whether the same applies to Grog—and whether that will give you another potential advantage in this Trial. You also wonder why there seem to be so many Versians pulled from Blarfngard and whether that's normal, but that's a question for another time….

"I'm pos my buddy Gadget's test was some strategic mind puzzle, know'n him," Lockdown continues. "But mine's gonna be way simpler, if that's a'right with ya."

Lockdown locks eyes with you once again, smiling more mischievously this time. Pink energy courses around his hands and you have to wonder: Just what else is he capable of, being a Warlock?

*page_break

"Here's mah test," Lockdown says, narrowing his eyes at you. "Impress me."

Hearing Lockdown's words, your gut immediately tells you that he probably isn't going to be impressed with more clever words or your Battlesuite technology. Lockdown is going to want a bit of a show—which means you're probably best suited to relying on your absorb powers, one way or another.

*if extraworning
	*if energyapprentice
		"Priscy, unless you've been building your Strength or Agile absorb stat areas, I'd highly recommend using your Energy Apprentice skill in this instance!" Rosae chirps in your ear.
		*goto ldimpchotime
	*elseif strengthapprentice	
		"Priscy, unless you've been building your Energy or Agile absorb stat areas, I'd highly recommend using your Strength Apprentice skill in this instance!" Rosae chirps in your ear.
		*goto ldimpchotime
	*else
		"Priscy, make sure to use one of the new absorb areas you've been building, of course!" Rosae chirps in your ear.
		*goto ldimpchotime

*label ldimpchotime

You decide to go with:

*temp absorboneenergy false
*temp absorbonestrength false
*temp absorboneagile false
*choice
	#A display of my Energy absorption abilities.
		*set absorboneenergy true
		*if energyapprentice
			Since you're now an Energy Apprentice, you figure you should utilize your new skill by generating a static shock, courtesy of OtherBoard's embedded skill.

			You reach out your hand and generate a pop of static electricity that ripples menacingly across your forearm. 

			You can't believe you're doing this without the aid of your Battlesuite or an actual absorb—this is an ability you'll hang on to for the rest of your life. That's blerging incredible.
			*goto tokenldgood 
		*else
			Thinking fast, you decide to flash absorb some of Lockdown's pink energy. 

			Reaching out your hand, you initiate a flash absorb, immediately giving you that familiar weightless feeling as your eyes shine like liquid mirrors and your entire body seizes. You are flooded with images of a life lived on the sea, one filled with conquests and adventure and affairs.

			Once the absorb settles, you generate the same pink energy around your outstretched hand that Lockdown just did.
			*if (energy > 0)
				*goto tokenldgood 
			*else
				*goto tokenldbad
	#A display of my Strength absorption abilities.
		*set absorbonestrength true
		*if strengthapprentice
			Since you're now a Strength Apprentice, you figure you should utilize your new skill by punching a hole straight through the footbridge, courtesy of OtherBoard's embedded skill.

			You take a step back and then smash your closed fist down directly through the footbridge bottom as you feel temporary mechanical strength coursing through your forearm. 

			You can't believe you're doing this without the aid of your Battlesuite or an actual absorb—this is an ability you'll hang on to for the rest of your life. That's blerging incredible.
			*goto tokenldgood 
		*else
			Thinking fast, you decide to flash absorb some of Lockdown's dragon strength. 

			Reaching out your hand, you initiate a flash absorb, immediately giving you that familiar weightless feeling as your eyes shine like liquid mirrors and your entire body seizes. You are flooded with images of a life lived on the sea, one filled with conquests and adventure and affairs.

			Once your mind has settled, you take a step back and smash your closed fist down directly through the footbridge bottom as you feel temporary dragon strength coursing through your forearm.
			*if (strength > 0)
				*goto tokenldgood 
			*else
				*goto tokenldbad
	#A display of my Agile absorption abilities.
		*set absorboneagile true

		Thinking fast, you decide to flash absorb some of Lockdown's natural agility. 

		Reaching out your hand, you initiate a flash absorb, immediately giving you that familiar weightless feeling as your eyes shine like liquid mirrors and your entire body seizes. You are flooded with images of a life lived on the sea, one filled with conquests and adventure and affairs.

		Once your mind has settled, you take a step back and execute a series of acrobatic backflips across the bridge as you feel temporary agility course through your limbs.
		*if (agile > 0)
			*goto tokenldgood 
		*else
			*goto tokenldbad

*label tokenldgood
*page_break
*set trialonespeed +3
*set mastery +2
*set rlshp_lockdown %+10

"Impressi'e indeed," Lockdown says, offering you a few claps. "Now Ah'm just die'n to see what else you're capable of, sport." 

Lockdown says this with lust practically dripping off his words. However it makes you feel, you wonder if this is just how he speaks to everyone, or if he really thinks you are special.

"Which means Ah'd best be gi'in you this, huh?" Lockdown then says, holding out a shiny, dragon-shaped token in his hand. "Now scurry along so we can do this again sometime soon, ya heard?"

Taking the Delegate token from Lockdown, you smile and do just that, because there is no time to waste. Besides, a much better way to ensure spending more time with Lockdown is to win this Trial race, anyway. 
*goto cutimperv

*label tokenldbad
*set trialonespeed +1
*set rlshp_lockdown %-15

"Meh," Lockdown says, shaking his head at you. "Ah reckon you're gonna be have to try'n harder than that, sport."

Lockdown holds out a dragon coin in his palm—which he then throws over his shoulder and into the pond.

"Ah'm mighty sorry, but rules are rules," Lockdown sighs. "Ya best get to div'n, ah really do want to get to spend more time with ya."

As you dive into the pond to collect the discarded token, you're not sure you really care what Lockdown wants, at this particular moment.
*goto cutimperv

*label cutimperv
*page_break Over The Hedges

"I thought it was bad enough there was no welcome reception, but then to be herded like cattle through the servant entrances of the Castle? I suppose the accommodations are grand enough, but we'd never even think of treating guests this way in the soaring cities."

Baron Airon has decided to grace you with his presence as you glide over the sprawling hedge maze in search of the third Elite Delegate hidden within its leafy walls. You were surprised Baron Airon didn't try to get ahead of you, but from the look of the cuts and scrapes on his olive skin and his tousled feathery hair, you'd guess Baron Airon has had a rough go of it so far.

"I thought I would respect these Elites, but they seem to have no sense of proper decorum. For Feather's sake, they have a filthy Warlock in their ranks! Not to mention that common petty officer—who made me wait while he interviewed a slave! As if those brutes have anything remotely intelligent to share."

*if aironhookup
	*page_break

	Hearing Baron Airon now, going on and on, you really just can't believe he has said nothing about the night you shared together.

	Your mind flashes back there, to the bedroom of Baron Airon's cottage. You didn't spend any time in the actual bed, though, instead spending most of the night on the floor, where your hands traveled over Baron Airon's bare skin and across his hairy chest, which was matted down with sweat. From the first instant your lips touched, it was very clear that Baron Airon knew what he was doing, pushing you to the brink and then receding, over and over again for hours. His energy seemed as endless as his stamina that night….

	Flying beside him now, you eye the ridges of his stomach muscles and the stubble on his jaw, the curve of his full lips…and you want to touch him all over again. You also try your best to process Baron Airon's current rant—however excellent that night was, you realize now that it didn't involve much speaking.
	*goto bachoose
*else
	As Baron Airon rants, all you can think is: 
	*goto bachoose

*label bachoose

*choice
	*if (aironhookup) #I definitely want to hook up with Baron Airon again, no matter what.
		*set rlshp_airon %+20
		*set outspoken %+15
		*set calculating %-10
		*set security %-5
		*set crushairon true

		"Do you have nothing to say about the other night?" you ask, trying to make eye contact with Baron Airon.

		"What of it?" Baron Airon asks, looking genuinely confused. "What does that have to do with this Trial?"

		You stare back at Baron Airon, not at all sure how to respond to that sentiment, or rather, the lack thereof. You look away for a moment to gather your thoughts, but when you turn back to Baron Airon…

		He is gone.

		*page_break
		*label niceairon
		*set abolishstatus +1
		*if ((coupbond) or (coupspy)) or (doubleagent)
			*set status +2
		*goto zagaway
	*if (aironhookup) #I have zero interest in hooking up with Baron Airon again, but I will remain friendly nonetheless.
		*set rlshp_airon %+15
		*set outspoken %-15
		*set calculating %+10
		*set security %+5

		So you smile and nod at Baron Airon, sensing that he doesn't desire dialogue so much as an empty vessel to project his monologues onto.

		Or at least you try to, until you find that Baron Airon is no longer flying beside you.
		*goto niceairon
	#Baron Airon is harmless, so I'll just let him rant. 
		*set rlshp_airon %+10
		*set outspoken %-15
		*set calculating %+10
		*set security %+5

		You smile and nod at Baron Airon, sensing that he doesn't desire dialogue so much as an empty vessel to project his monologues onto. Or at least you try to, until you find that Baron Airon is no longer flying beside you.

		*set abolishstatus +1
		*if (eliteinfo) or (coupspy)
			*set status +2
		*goto zagaway
	#I can't stand Baron Airon, but he doesn't need to know it.
		*set rlshp_airon %-5
		*set outspoken %-15
		*set calculating %+10
		*set security %+5
		*set abolishstatus +1

		You stay silent for now, allowing Baron Airon to monologue while you tune him out. Or at least you try to, until you find that Baron Airon is no longer flying beside you.

		*if ((winjoin) or (doubleagent)) or (coupbond)
			*set status +2
		*goto zagaway
	#I can't stand Baron Airon. Someone needs to put him in his place.
		*set rlshp_airon %-20
		*set outspoken %+15
		*set calculating %-10
		*set security %-5

		"Do you have any idea how ridiculous you sound?" you ask. "Honestly, there are much more important things we both should be focusing on."

		You wait for Baron Airon's indignant response, but you don't receive one. That's because when you turn to look at him, you realize that Baron Airon is gone.
		
		*if (winjoin) or (eliteinfo)
			*set status +2
		*goto zagaway

*label zagaway

You're not sure how he could have done so in the blink of an eye, but Baron Airon has somehow lost you. Could it be that he found the Elite Delegate and took off without you? Or did he just not want to continue this conversation?

Whatever the reason, you decide you need to focus on the race, anyway—which becomes decidedly more difficult as the hedges below start to shift. They spin and shuffle with increasing speed, so much so that you struggle to keep your own equilibrium. Once the crazed shifting settles, you find yourself totally disoriented within the airspace of the hedge maze.

Could this shifting explain why Baron Airon disappeared suddenly? Whatever else it means, you know one thing: you need to find this Elite Delegate before the hedges shift again, given how dizzy you currently feel.

*page_break Searching… Searching…

*if coupspy
	*set eone true
	*achieve echelonone

Blerg knows how long later, you finally spot a figure standing in the center of an internal courtyard down in the hedge maze below. As you make your way toward her, you realize that none of the Elite skyboxes seem to have followed you here. You don't know if it's because of the shifting hedge airspace or because they're all just otherwise occupied, but this might be your first unwatched Delegate interaction—so it's up to you to decide whether that affects your behavior or not.

You land in front of a woman who must be eight feet tall—you might even consider her a mini-giantess. She has long red hair that is wrapped tightly around her chest as a sort of top, though that's not as surprising as the fact that she has four arms, one of which has a small sword permanently burned into its palm. Her light brown skin is covered with intricate henna scrawlings in the parts left exposed between plates of silver and red armor, which also appear to be seared into her skin in places. Her face is as brutish as her stature, with a bulbous nose, full lips, and beady eyes that currently sport an incredibly intense look. She appears generally fleshy and big-boned, but somehow strong and toned at the same time.

Baron Airon lies unconscious at this warrior giantess's feet, a welt now swelling over his left eye.

"He hit on me, so I hit him," the warrior giantess says in a voice that sounds like gravel grinding underfoot. "I'm Imperva. Do you want to try hitting on me too?"

*page_break
*set meetimperva true

You shake your head, deciding immediately that it's probably best for you to let Imperva take the lead here, given Baron Airon's current state.

"There will be more hitting: that is what I exist for," Imperva says, seeming oddly calm. "I will test your battle mettle, as requested."

"Was that requested by Queen Ashe or Lady Venuma?" you ask, treading carefully. You want to learn more about Imperva, but the last thing you want to do is anger her—which it seems you might be doing, as you get a blast of indistinct, intense emotion at the mention of the Wone goddesses. The ambient vibe feels quite like a blunt punch to the face.

"It is requested by the Verses." Imperva states this in an even tone, but her body seems to grow even larger before you as she speaks, causing the metal plates of her red and silver armor to slip and scrape. "But I have only respect and reverence for the mighty Wone."

You have a feeling you're not going to be able to avoid a fight here, but you figure you might as well try—besides, this might be your only opportunity to learn which Wone goddess elicits such an intense response from Imperva, given the rare lack of a presiding Elite Courte skybox.

*choice
	#"I too have nothing but respect for Lady Venuma."
		*if (lvfinalromance)
			*set rlshp_imperva %-10
			*set status +2
			*if (calculating > 50)
				*set calculating %+5
			*if (calculating <= 50)
				*set calculating %-5
			*set concubineclue true
			*achieve concubineimperva

			You instantly feel an ambient blast of jealousy explode from Imperva. It has the distinct flavor of someone who has been romantically involved with the demigoddess, as you can recall all too well. You don't have much time to absorb this realization or unpack its implications, however, as Imperva suddenly steps forward.
			
			*label smalltalk
			
			"I hate small talk," Imperva grunts. "Let's get to the hitting."
			*goto battletime
		*elseif (coupbond) or (coupspy)
			*set rlshp_imperva %+15
			*set status +2
			*set impervacoupclue true
			*achieve coupimperva
			
			"Then we have that in common," Imperva says, making sure to look you directly in the eye. Your ambient absorb senses inform you she is trying to tell you something else—something about her involvement with Lady Venuma's plans.

			Not wanting to verbalize this realization, you simply nod at Imperva. It looks like you just found a new coup ally—though it also looks like Imperva doesn't want to make this obvious as she steps forward.

			*if coupbond
				*set calculating %-5
				*goto smalltalk
			*else
				*set calculating %+5
				*goto smalltalk
		*else
			*set rlshp_imperva %+5
			*set abolishstatus +1
			"Then we have that in common," Imperva says simply. You hope for more, or to at least ambient absorb some telling emotion from Imperva, but instead she begins to step forward.
			*goto smalltalk
	#"I too have nothing but respect for Queen Ashe and her Elite Courte."
		*if (winjoin) or (doubleagent)
			*set rlshp_imperva %-5
			*set status +2
			*if (calculating > 50)
				*set calculating %+5
			*if (calculating <= 50)
				*set calculating %-5
			*set impervacoupclue true
			*achieve coupimperva

			"Then we have that in common," Imperva says, making sure to look you directly in the eye. However, your ambient absorb senses tell you something different than Imperva's words—that her true respect lies with Lady Venuma. Could it be possible that you have just found another one of the coup's secret agents?

			Imperva stares back at you silently, as if deciding whether you have bought what she is selling. Unfortunately, as she cracks her knuckles and steps toward you, it seems Imperva has no interest in giving you any further hints about her affiliations.
			*goto smalltalk
		*else
			*set rlshp_imperva %-15
			*set abolishstatus +1
			You're not sure you really mean this, given your goal, but you want to see Imperva's potential reaction. Unfortunately, as she cracks her knuckles and steps toward you, it seems Imperva has no interest in giving you any hints.
			*goto smalltalk
	#"If a fight is inevitable, should we just get to it?"
		*set rlshp_imperva %+10
		*if (calculating > 50)
			*set calculating %+5
		*if (calculating <= 50)
			*set calculating %-5
		*set abolishstatus +1
		*set status +2

		"No small talk, straight to battle?" Imperva says, actually cracking a smile. "I like you."

		She steps forward, cracking her knuckles menacingly as she does.
		*goto battletime
	
*label battletime

Then, without further comment, Imperva charges at you, waving her sword-hand in the air and calling out some shrill war cry.

*if extraworning
	"Priscy, this new absorb system is trickier, since it is now organically connected to all of your battle systems!" Rosae suddenly shouts, hoping to warn you before Imperva can strike. "It seems you can no longer simply rely on the same absorb area again and again, so I suggest you fall back on your second-strongest area in conjunction with the use of your weapons or natural abilities!
	*if energyapprentice
		*if absorboneenergy 
			Since you already used your Energy Apprentice skill, focus on any other area you have been building!"
			*goto impervafallout
		*else
			As such, now would be an opportune time to use your Energy Apprentice skill!"
			*goto impervafallout
	*elseif strengthapprentice	
		*if absorbonestrength
			Since you already used your Strength Apprentice skill, focus on any other area you have been building!"
			*goto impervafallout
		*else
			As such, now would be an opportune time to use your Strength Apprentice skill!"
			*goto impervafallout
	*else
		*if technovice
			As such, now would be an opportune time to use your Tech Novice skill!"
			*goto impervafallout
		*else
			*goto impervafallout
*else
	"Priscy, this will be my final unsolicited outburst, I promise!" Rosae suddenly shouts, hoping to warn you before Imperva can strike. "This new absorb system is trickier, since it is now organically connected to all of your battle systems. It seems you can no longer simply rely on the same absorb area again and again, so I suggest you fall back on your second-strongest area in conjunction with the use of your weapons or natural abilities!"
	*goto impervafallout

*label impervafallout
*choice
	*selectable_if (absorbonestrength = false) #Fight back with a grav-punch.
		*set weapons %+25

		You activate the grav-converters on your wrist units and swing a punch powered by redirected gravity at Imperva.

		*if (strength > 0) or (strengthapprentice)
			*goto impressimp
		*else
			*goto koimp
	*selectable_if (absorboneenergy = false) #Overwhelm Imperva with a shareburst mindbolt.
		*set weapons %-25

		You focus your absorb abilities and fire a bolt of shared mental matter from your forehead, which fires in a visible burst directly at Imperva.

		*if (energy > 0) or (energyapprentice)
			*goto impressimp
		*else
			*goto koimp
	*selectable_if (absorboneagile = false) #Avoid Imperva's blow with a flip and strike her from behind.
		*set weapons %-25

		Trusting your training and instincts, you leap into the air and flip around, landing behind Imperva. Then you swing your momentum into a jumping kick.

		*if (agile > 0)
			*goto impressimp
		*else
			*goto koimp
	#Connect to my Battlesuite to engage in tech-assisted hand-to-hand combat.
		*set weapons %+25

		*if (technovice)
			You're a Tech Novice now, which means you can connect to your Battlesuite directly and activate its systems to blend with your biological systems.

			Trusting your training and instincts, you spin forward and throw a jab at Imperva, feeling the joints of your Battlesuite move in perfect consonance with your own limbs.
			*goto impressimp
		*else
			Trusting your training and instincts, you spin forward and throw a jab at Imperva.

			*if (tech > 0)
				*goto impressimp
			*else
				*goto koimp

*label impressimp
*set mastery +2
*set trialonespeed +3
*set life -1
*set rlshp_imperva %+20

However, Imperva dodges your blow with a speed that belies her considerable girth. Then she slams one of her fists into the back of your head. 

You find your body knocked forward, and the next thing you know, you're facedown on the floor…

*page_break

…with a warrior token lying on the ground beside you.

"You never had any hope of hitting me," Imperva states. "But your best attempt was passable. Now begone."

Not needing to stick around for any more of Imperva's charming compliments, you ignore the throbbing in your head and pull yourself to your feet—because you've got a race to finish.
*goto rushback

*label koimp
*set trialonespeed +1
*set life -3
*set rlshp_imperva %-20

However, Imperva dodges your blow with a speed that belies her considerable girth. Then she slams one of her fists into the back of your head. 

You find your body knocked forward, and the next thing you know, you're facedown on the floor…

*page_break

…with a warrior token lying on the ground beside you. 

When you finally pull yourself back to your feet, however, you find that both Imperva and Baron Airon aren't in this courtyard anymore. How long could you have been out? It only felt like seconds, but it obviously must have been longer.

Clutching your third and final token and ignoring the throbbing in your head, you activate your grav-glider once again, because you've got a race to complete—one you hope hasn't finished already.
*goto rushback

*label rushback
*page_break Over The Finish Line

Your pulse still races, and your breath escapes your lungs in sharp, short bursts—but you've made it. You now stand atop a newly erected winner's circle podium that holds three elevated places, each one designated for the Entrants who have survived this first Trial. 

Thankfully, you've raced fast enough to qualify as one of those surviving Entrants. 

Feeling relieved, you look around to fully assess the outcome of your efforts…

*page_break

*if (trialonespeed = 8)
	*set status +2
	*set abolishstatus +2
	*achieve wonfirsttrial

	Pinkuju currently stands in second place above Grog, who is in third place—which leaves the highest, first-place spot occupied by you. You can feel the relief and pride pumping into your body, knowing you have survived this first Trial with high marks by standing out in first place.
	*goto endoftrial
*elseif (trialonespeed > 5)
	*set status +1
	*set abolishstatus +1
	Pinkuju currently stands in first place above Grog, who is in third place—which leaves the second-place spot occupied by you. You can feel the relief and pride pumping into your body, knowing you have survived this first Trial safely in the middle.
	*goto endoftrial
*else
	Pinkuju currently stands in first place above Grog, who is in second place—which leaves the third-place spot occupied by you. You can feel the mixture of relief and nerves swirling in your gut, knowing that you have survived this first Trial—but just barely.
	*goto endoftrial

*label endoftrial

This means that Baron Airon will be the first Entrant eliminated, though he isn't currently anywhere to be seen. Does that mean Baron Airon has already been asked to leave, without even reaching the finish line? If that's the case, you know he won't be fond of that kind of treatment at all….

"I would like to extend my highest congratulations to you three for winning this first Trial and advancing to the next event," Lady Venuma announces, now hovering directly in front of the podium. She is flanked by her Trial Delegates—Imperva, Lockdown, and Cadet Gadget—while the three tinted Elite skyboxes float above her.

"On behalf of my Trial Delegates and the remainder of The Elite Courte, I now invite each of you to a private victory brunch in the Ord Ambassador wing, where you shall dine individually with a select gathering of…ah, there he is."

*page_break

Lady Venuma turns her attention towards the hedge maze hill, which Baron Airon now comes flying over, looking both bitter and bruised.

"This Trial was a farce!" Baron Airon screams as he approaches. "It was unfairly arranged against me; I know this to be true! I demand this be declared a mistrial!"

As Baron Airon nears, Lady Venuma turns to Lockdown and nods at him. Smiling widely, Lockdown then waves his hand to generate a shower of pink light that forms an energy cage around Baron Airon. This magical pink cage certainly succeeds in slowing Baron Airon down, but it fails to silence him.

"Command this filthy Warlock to release me!" Baron Airon shrieks. "To cage a Sallytran noble is tantamount to treason! It is an offense punishable by death!"

"Come'n at me, birdbrain," Lockdown says with a look of hate on his face—one that is rivaled in intensity by the rage twisting on Baron Airon's face, rage that allows Baron Airon to somehow break through the bars of pink energy and push through the broken cage. Once freed, Baron Airon zooms at Lockdown with outstretched hands, screaming at the top of his lungs.

*page_break

Within the blink of an eye, Cadet Gadget beams at Baron Airon like a human bolt of lightning. Before Baron Airon even knows what has happened, he is bound and gagged by light shackles and pinned to the ground by Cadet Gadget. Baron Airon wriggles and screams muffled threats, but to no avail. 

"Say'n thanks, Gadget," Lockdown smiles. "Though ah could'a handled that fowl fool all on m' own."

"I know, but this was faster," Cadet Gadget says. "Besides, no one messes with my friends."

"Aw shucks, ah query you want'n me to blush," Lockdown says, patting Cadet Gadget on the back. Smiling back at Lockdown, Cadet Gadget seems to glow—both literally and figuratively.

*page_break

"On that rousing note, thus concludes the first Trial," Lady Venuma proclaims. "Now, let us feast."

As everyone stirs, you have to wonder whether Baron Airon was completely full of wind, or if this first Trial could really have been rigged for him to fail, as he claims. You figure that can be a question you hope to answer at this victory brunch, which begs a few other questions: Who will be at this victory brunch? Who, in turn, will you be able to full absorb? What planet will you get to MemoryTravel to next?

As you step off the winner's podium, you know you're about to find out.

*if (mastery >= 40)
	*set lifemax +1
	*set masteryfortybonus true
	*achieve masteryfortybonusac

*finish CHAPTER TWO: BRUNT
