*comment é

*image cover.png center 

*image title.png center VERSUS: THE ELITE TRIALS

*page_break

*image zslogo.png center Zachary Sergi
*line_break
By
*line_break
Zachary 
*line_break
Sergi

*page_break

*label menu

*image banner.png center VERSUS: THE ELITE TRIALS

[b]VERSUS[/b]: THE ELITE TRIALS is the sequel to [b]VERSUS[/b]: THE LOST ONES. Haven't read the first book? No worries, we'll catch you up with an interactive recap below!

*if not(choice_is_steam)
	In the meantime, check out all of the Choice of Games titles by
	*link http://zacharysergi.tumblr.com/ Zachary Sergi:

	[b]THE VERSUS SERIES[/b]:
	*line_break
	*link https://www.choiceofgames.com/versus-the-lost-ones/redirect.php?src=v2 Versus: The Lost Ones (Book One)
	*line_break
	*link https://www.choiceofgames.com/versus-elite-trials/redirect.php?src=v2 Versus: The Elite Trials (Book Two)

	[b]THE HEROES RISE TRILOGY[/b]:
	*line_break
	*link https://www.choiceofgames.com/heroes-rise/redirect.php?src=v2 Heroes Rise: The Prodigy (Book One)
	*line_break
	*link https://www.choiceofgames.com/heroes-rise-2-hero-project/redirect.php?src=v2 Heroes Rise: The Hero Project (Book Two)
	*line_break
	*link https://www.choiceofgames.com/heroes-rise-3-herofall/redirect.php?src=ve Heroes Rise: HeroFall (Book Three)

	[i]Heroes Rise Presents:[/i]
	*line_break
	[b]THE HERO PROJECT TRILOGY[/b]
	*line_break
	*link https://www.choiceofgames.com/hero-project-redemption-season/redirect.php?src=v2 The Hero Project: Redemption Season (Book One)
	*line_break
	[i]The Hero Project: Book Two[/i] (Expected Release: 2017)

*choice
	#I am a new reader.
		*set newreader true
		
		[i]Enjoy this brief recap of [b]VERSUS[/b]: THE LOST ONES, which will also help define your main character.[/i]

		*goto newreaderrecap
	#I want to load my game from [b]VERSUS[/b]: THE LOST ONES.
		*restore_game cancel=menu
		*label loadedreader
		*set loadedreader true

		Would you like to read a recap of your loaded playthrough of [b]VERSUS[/b]: THE LOST ONES?

		Note that this recap will review and reflect the choices you have already made. If you would like to read a recap that allows you to remake these choices, start over and choose to be a "new reader."

		There are certain statistic and narrative advantages to reading with a loaded game, however, so be sure to do so for one of your read-throughs, if possible! 

		*choice
			#Yes, I'd like to read a recap.
				*goto newreaderrecap
			#No, I'd like to begin [b]VERSUS[/b]: THE ELITE TRIALS.
				*goto timetobegin

*label newreaderrecap

*image lostones.png center VERSUS: THE LOST ONES

You were born on a remote planet named Prisca, where everyone possesses the ability to absorb the talents and memories of others. As a result, Priscan culture values sharing above all else, so Prisca is a planet made of mirrors—a powerful reminder to see yourself in everything, so that you may reflect everything in yourself. The metaphor is so potent, in fact, that all Priscans are branded with mirror patches on their left cheeks upon birth.

You always wondered what it might be like on other planets in the galaxy, whether other cultures valued sharing the way that Priscans do. However, you've always been unable to leave Prisca, for no one is allowed on or off the planet. Not just that—no "culturally impure" alien knowledge is allowed to enter Prisca's borders, in order to protect the purity of the planetary Collective Consciousness.

Whatever else you believed, you always found it difficult to understand the point of having the ability to share everything when everyone is the same and there's nothing new to learn. 

Prisca's Impure Black Market tried its best to keep you supplied with galactic textbooks and foreign fiction, but you knew the truth: there was an entire galaxy beyond Prisca filled with bold and exciting planets brimming with strange and wonderful cultures, and you hardly knew anything about them.

*if loadedreader
	*page_break
	*goto genderchoice

Your Priscan name is:

*choice
	#Caprica.
		*set name "Caprica"
		*goto genderchoice
	#Nilo.
		*set name "Nilo"
		*goto genderchoice
	#Godessa.
		*set name "Godessa"
		*goto genderchoice
	#Bludgeono.
		*set name "Bludgeono"
		*goto genderchoice
	#Gailford.
		*set name "Gailford"
		*goto genderchoice
	#Bohari.
		*set name "Bohari"
		*goto genderchoice
	#Kgoins.
		*set name "Kgoins"
		*goto genderchoice
	#Hillsaint.
		*set name "Hillsaint"
		*goto genderchoice
	#Phershorn.
		*set name "Phershorn"
		*goto genderchoice
	#Select my own name.
		Your first name is:
		*input_text name
		*goto genderchoice 

*label genderchoice

You always dreamed of more in life, perhaps even a life of galactic exploration, but it wasn't just the Purity Laws that kept you trapped on Prisca: you were drafted as a soldier to fight in a global war. Your enemy? A deadly invading threat named the Blots—mindless and vampiric slug creatures that convert every living being and terraform every kind of terrain in their path. The Blot hordes had been trying to conquer Prisca for years, and every Priscan was called to serve in this inescapable Black Blot War.

You were particularly involved in the war, since your mother is the greatest Priscan general who ever lived. You always held on to the hope that you might lead a different life when the war was won, which actually seemed possible as you prepared to enter Prisca's most pivotal battle against the Blots ever. 

However, these hopes were shattered when, right before the great battle, Mother asked you to inherit her command position should she fall—a title that was supposed to go to your older sister Gilo, the perfect soldier, who lives for war.

With this great request hanging in your mind, you did your best to focus as you went into battle against the Blots, often
*if loadedreader
	*if (weapons > 50)
		utilizing your standard Priscan Anti-Blot Battlesuite weapons skill instead of your natural Priscan mental abilities.
		*page_break
		*goto teeporout
	*else
		favoring your natural Priscan mental abilities over your Anti-Blot Battlesuite.
		*page_break
		*goto teeporout
*if newreader
	relying on your:

*choice
	#Forceful weapons skill.
		*label weaponized
		*set weapons 60

		Utilizing your standard Priscan Anti-Blot Battlesuite, you fought bravely in this major battle.
		*goto teeporout
	#Cunning weapons skill.
		*goto weaponized
	#Forceful natural abilities.
		*label naturalized
		*set weapons 40

		Favoring your Priscan mental abilities over your Anti-Blot Battlesuite, you fought bravely in this major battle.
		*goto teeporout
	#Cunning natural abilities.
		*goto naturalized

*label teeporout

All your efforts seemed in vain, though, when you saw several Blot generals converging on Mother's command post.

You and Gilo rushed to her rescue, but before you could arrive, you were bathed in strange red energy…

And found yourself instantly transported to planet Versus. 

*page_break

Of course, at the time you didn't know what that meant, having been isolated from the larger galaxy for your entire life. All you did know was that you were immediately confronted with several diverse alien beings—though there was one in particular that startled you to your core… 

Empress Vaccus, the intelligent ruler of the Blot hive mind, wearing its crown of jagged spikes and sporting a bloody V painted across its slick, black chest.

After a quick and dirty fight with the all-powerful Empress Vaccus, you boldly chased it into an overgrown forest as it rather uncharacteristically fled. While Empress Vaccus managed to escape, you—quite literally—ran into a wild sentient android named OtherBoard.

*if newreader
	*page_break

You soon learned that OtherBoard also lived in isolation in this UniForest from the rest of her fellow Versians, but she was still able to teach you much about Versus—thanks largely to your Priscan ability to full absorb OtherBoard's memories and abilities. This process dulled your general absorb abilities for two days, but equipped you with new technological skills downloaded from OtherBoard—who was also unexpectedly shut down to reboot for the length of the full absorb.

These new technological abilities gave you access to informational readouts, many of which still appear in your "Show Stats" screen to be reviewed at any time. With information explaining Versus saved there permanently, especially in "The Verses" section, you focused on other more personal readouts…

*if loadedreader
	*page_break
	*if mtf
		*goto mtfreadout
	*if ftm
		*goto ftmreadout
	*if genderneutral
		*goto genderloaded
	*if male
		*goto malereadout
	*if female
		*goto femalereadout

[b]NAME:[/b] ${name} Thomil
*line_break
[b]SPECIES:[/b] Enhanced Human / Priscan Humanoid
*line_break
[b]HOME PLANET:[/b] Prisca
*line_break
[b]GENDER:[/b]

*set tech +6
*set energy +3
*set strength +3

*choice
	#I'm male.
		*label malereadout
		[b]NAME:[/b] ${name} Thomil
		*line_break
		[b]SPECIES:[/b] Enhanced Human / Priscan Humanoid
		*line_break
		[b]HOME PLANET:[/b] Prisca
		*line_break
		[b]GENDER:[/b] Male
		*goto boardingtime
	#I'm female.
		*set male false
		*set female true
		*set youze "she"
		*set youhir "her"
		*set youhis "her"

		*label femalereadout
		[b]NAME:[/b] ${name} Thomil
		*line_break
		[b]SPECIES:[/b] Enhanced Human / Priscan Humanoid
		*line_break
		[b]HOME PLANET:[/b] Prisca
		*line_break
		[b]GENDER:[/b] Female
		*goto boardingtime
	#I was assigned as male at birth, but am female.
		*set male false
		*set female true
		*set mtf true
		*set youze "she"
		*set youhir "her"
		*set youhis "her"

		*label mtfreadout
		As for your gender, you underwent all the procedures you desired to become the woman you were always meant to be. You had come across Impure Black Market texts about other cultures where such gender confirmations are considered taboo or even sacrilegious, but in Priscan society, where everyone can quite literally share their thoughts and experiences, it's fairly impossible not to accept others once you understand who they truly are.

		Besides, about one in two hundred Priscan children are born with mismatched sexes and genders, so confirmation techniques were perfected long ago. 
		
		*goto femalereadout
	#I was assigned as female at birth, but am male.
		*set ftm true

		*label ftmreadout
		As for your gender, you underwent all the procedures you desired to become the man you were always meant to be. You had come across Impure Black Market texts about other cultures where such gender confirmations are considered taboo or even sacrilegious, but in Priscan society, where everyone can quite literally share their thoughts and experiences, it's fairly impossible not to accept others once you understand who they truly are.

		Besides, about one in two hundred Priscan children are born with mismatched sexes and genders, so confirmation techniques were perfected long ago. 
		
		*goto malereadout
	#I was born with intersex characteristics.
		*set intersex true

		You had come across Impure Black Market texts about other cultures where the broad spectrum of intersex identities is considered taboo or even sacrilegious, but in Priscan society, where everyone can quite literally share their thoughts and experiences, it's fairly impossible not to accept others once you understand who they truly are.

		Besides, about one in fifty Priscan children are born with intersex characteristics, so Priscans are comfortable with all kinds of identities. 

		Personally, you consider your identity to be:

		*choice
			#Male.
				*goto malereadout
			#Female.
				*set male false
				*set female true
				*set youze "she"
				*set youhir "her"
				*set youhis "her"
				*goto femalereadout
			#I don't subscribe to any gender categories.
				*set male false
				*set genderneutral true
				*goto genderneutralreadout
	#I don't subscribe to any gender categories.
		*set male false
		*set genderneutral true

		*label genderloaded
		When it comes to your own gender, you are all genders, but you are also no gender. You believe gender defies categorization, operating on a kind of sliding scale—one that can change every day. 

		You had come across Impure Black Market texts about other cultures where such thinking is considered taboo or even sacrilegious, but in Priscan society, where everyone can quite literally share their thoughts and experiences, it's fairly impossible not to accept others once you understand who they truly are.

		Besides, even the most staunchly "male" or "female" cisgenders admit that sometimes they feel more "masculine" or "feminine" at different times. You just take that kind of thinking to a whole new level.  

		*label genderneutralreadout

		You've also chosen to identify with the pronouns:

		*choice
			#Ze and hir.
				*set youze "ze"
				*set youhir "hir"
				*set youhis "hir"
				*goto genderneutralreadoutreal
			#They, them, and their.
				*set youze "they"
				*set youhir "them"
				*set youhis "their"
				*goto genderneutralreadoutreal
			#Zhe, zhim, and zhir.
				*set youze "zhe"
				*set youhir "zhim"
				*set youhis "zhir"
				*goto genderneutralreadoutreal
			#I'd like to input my own pronouns.
				Instead of he, she, or they, you prefer:

				*input_text youze

				Instead of him, her, or them, you prefer:

				*input_text youhir

				Instead of his, her, or their, you prefer:

				*input_text youhis
				*goto genderneutralreadoutreal
		
*label genderneutralreadoutreal

[b]NAME:[/b] ${name} Thomil
*line_break
[b]SPECIES:[/b] Enhanced Human / Priscan Humanoid
*line_break
[b]HOME PLANET:[/b] Prisca
*line_break
[b]GENDER:[/b] Not Applicable
*goto boardingtime 

*label boardingtime
*line_break
[b]ABILITIES:[/b] Absorption of Memories and Abilities 
*line_break
[b]ABILITY LEVEL:[/b] Low
*line_break
[b]ADDENDUM:[/b]
*line_break
[i]Energy Absorption:[/i] ${energy}
*line_break
[i]Strength Absorption:[/i] ${strength}
*line_break
[i]Technical Skill Absorption:[/i] ${tech}
*line_break
[i]Command Absorption:[/i] ${command}
*line_break
[i]Agility Absorption:[/i] ${agile}

You had never realized that your absorption powers could be broken down into categories like this before your full absorb, which also seemed to boost your Technical Skill most, along with Energy and Strength, thanks to OtherBoard's own talent profile. You continued to hone these absorb abilities, especially that first night on Versus when you discovered a lost Priscan skill: DreamScape MemoryTravel.

Once you fell asleep, you found yourself mentally time-traveling to OtherBoard's home planet. Your guide for this MemoryTravel experience was Rosae, your Priscan WorningBird and lifelong blue-furred pet, who lives in a pouch on your Battlesuite ${beltcolor} belt.

*page_break

Rosae, who was now suddenly able to speak full sentences in MemoryTravel, explained that when any Priscan performs a full absorb on any non-Priscan being, they are automatically granted access to the absorbee's memories once they go to sleep. Rosae told you to think of it almost like a time-travel dream, where you were reliving your absorbee's memories—in this case, OtherBoard's. Except you were not limited to OtherBoard's specific memories: you were able to draw on her planet's Collective Consciousness to move about the memoryworld as if it were the real world.

Rosae also made it clear that while you can change events in MemoryTravel history temporarily, this only lasts as long as you are asleep. Once you wake up, the experience collapses entirely like a dream, leaving history and the future unaltered. However, your own brain is wired to think this experience is real and registers any bodily harm as actual, so you learned that you could very truly die while MemoryTraveling.

This kind of inherent danger was one of the factors that prompted the Purity Laws all those years ago. Rosae was incredibly excited to be the first WorningBird able to engage in her primary purpose in many years, so you got right to MemoryTraveling with Rosae as your official guide.

*page_break

*if newreader
	*set fighthumm false
	*set helpob false
	*set betrayob false
	*set skipthree true
	
As you and Rosae explored OtherBoard's home planet, Binaria, you discovered a startling truth: the legendary warrior and supposed lost savior of Prisca had once visited Binaria. The Legend of The Lost One goes as such:

In the early days of the Black Blot War, there was a pivotal battle where Priscan troops were being overwhelmed by the Blot hordes—until, seemingly out of nowhere, a shape-shifting warrior appeared to burn the Blots cleanly from the inside out and turn them to ash instead of their signature Blotbogs. Once the legion of Blots had been thoroughly crisped, this warrior hung in the air, swathed head-to-toe in white energy armor, obviously much mightier than the average Priscan—though still sporting a mirror patch.

Before the few surviving troops could learn any more about this strange savior, there was a bright streak of white light and the figure disappeared. Since that epic showing, there have been many competing theories on who this godlike warrior might have been and where Ze might be now. Despite these questions, hope endured that this revered warrior would return someday to end the Black Blot War. This figure was thus given the honor of a rarefied Olde Priscanian name: Dhan Thik, meaning literally "the great one, lost to be found." 

And so the Legend of Dhanthik, The Lost One, was born.

*page_break

Given the pervasiveness of the Black Blot War, Dhanthik has been elevated to a kind of deity in Priscan culture, a figure of hope to be respected and emulated above all else. So it was totally surreal for you to encounter Dhanthik, albeit briefly, during your time MemoryTraveling on OtherBoard's home planet. And once you woke up from this MemoryTravel dream back on planet Versus, you realized you obviously had to MemoryTravel again the next night to discover more about Dhanthik's travels.

In the meantime, you had a full day of gaining your bearings and meeting some of the other inhabitants on Versus ahead of you. 

That's when you got to know Lady Venuma, the self-proclaimed goddess, Breeze, the scatterbrained wind-manipulator, and Todrick, the fatherly farmer. In a secret meeting, these three explained to you the political realities of Versus, including Queen Ashe's ruling Elite Courte. Thankfully, all of this information was stored in your Stats Screen for review, especially in the "Verses" and "Versus Inhabitants" sections.

*page_break

This is also when you learned that Lady Venuma and Breeze were attempting to convince Todrick to volunteer for the next Versus Vote in Breeze's place. Apparently this Elite Courte, which controls the vote, was targeting Breeze for some mysterious misdeed from the previous cycle. Lady Venuma was attempting to use her influence as Elite Courte Ord Ambassador to protect Breeze…

Because it turns out Lady Venuma and Breeze were secretly planning a rebellion to overthrow The Elite Courte. 

Knowing the seemingly innocent and gullible Todrick dreamed of joining The Elite Courte, Lady Venuma told Todrick he'd need to volunteer in Breeze's place to be worthy of Queen Ashe's attention. In reality, Lady Venuma secretly knew that Todrick would probably face his death in the Versus Match against a being known only as the "Un-Thing."

*if loadedreader
	In reaction to this, you had to weigh your political goals and personality strengths. Ultimately, you decided to 
	*if ruthlessrebellion
		ruthlessly support the rebellion by helping convince Todrick to volunteer.
		*page_break
		*goto consqeunce
	*if genuinerebellion
		genuinely support the rebellion by supporting Lady Venuma and Breeze.
		*page_break
		*goto consqeunce
	*if ruthlessregime
		ruthlessly attempt to join The Elite Courte by placating Lady Venuma until you could use your insider knowledge to sell her out later.
		*page_break
		*goto consqeunce
	*if genuineregime
		genuinely attempt to join The Elite Courte and protect Todrick by warning him of Lady Venuma's political game.
		*page_break
		*goto consqeunce
	*if officiallyneutral
		hold off on the politics to see what side, if any, to join later.
		*page_break
		*goto consqeunce

Lady Venuma then tested your own intentions in this situation, so you had to weigh your political goals and personality strengths before you ultimately decided to:

*choice
	#Ruthlessly join the rebellion by helping convince Todrick to volunteer.
		*set ruthlessrebellion true
		*set todrickdie true
		*set deathone "Todrick"
		*set liveone "Breeze"
		*set ruthless 60
		*set regime 40
		*goto consqeunce
	#Genuinely join the rebellion by gently supporting Lady Venuma and Breeze.
		*set genuinerebellion true
		*set todrickdie true
		*set deathone "Todrick"
		*set liveone "Breeze"
		*set ruthless 40
		*set regime 40
		*goto consqeunce
	#Ruthlessly attempt to join The Elite Courte by placating Lady Venuma in the moment, so that I could later use my insider knowledge to sell her out.
		*set ruthlessregime true
		*set todrickdie true
		*set deathone "Todrick"
		*set liveone "Breeze"
		*set ruthless 60
		*set regime 60
		*goto consqeunce
	#Genuinely attempt to join The Elite Courte and protect Todrick by warning him of Lady Venuma's political game.
		*set genuineregime true
		*set todrickdie false
		*set deathone "Breeze"
		*set liveone "Todrick"
		*set ruthless 40
		*set regime 60
		*goto consqeunce
	#Hold off on the politics for now to see which side, if any, I want to join later.
		*set officiallyneutral true
		*set todrickdie true
		*set deathone "Todrick"
		*set liveone "Breeze"
		*set ruthless 50
		*set regime 50
		*goto consqeunce

*label consqeunce

You saw the consequences of your actions play out later at the official Voting Ceremony, where 
*if todrickdie
	Todrick indeed volunteered in Breeze's place and was voted into the first Versus Match.
*if (todrickdie = false)
	Todrick did not volunteer. Instead, he blindsided Breeze by implementing a majority vote that placed the wind-manipulator into the first Versus Match.
*comment endif

During this first Voting Ceremony, you also met several of the other Ord Versians—listed in the ever-handy Stats Screen for later viewing—and glimpsed the opaque Elite Courte skybox looming over the ceremony from above.

Then, as night fell once again and OtherBoard continued to reboot, you refocused on your second overnight MemoryTravel dream-trip to learn more about Dhanthik. 

*page_break

It turned out that Dhanthik was in Binarian space to try to unite the warring humans and androids there in order to create a master race—one that Dhanthik claimed was needed to stop an unspecified impending galactic threat. You immediately wondered whether Dhanthik was talking about the Blots, and you questioned why Ze wasn't back on Prisca fighting them, but all of your questions were put on hold as a monstrous creature appeared: 

The Bominate, a twisted version of Dhanthik's vision that combined human and android attributes to make an unkillable assassin. You'll never forget the sight of this Bominate, with its rusted metal joints pieced together under globs of putrid flesh and its blue robotic lights shining through a sliced-off human face stretched over its metal skull.

In the ensuing battle, OtherBoard's partner was brutally murdered right in front of her and you were just barely able to save Dhanthik's own life by relying on your strongest absorb ability area;
*if loadedreader
	once you did so,
	*if (tech > 19)
		you ended up achieving the status of absorption Tech Novice.
		*goto tempfend
	*elseif (energy > 9)
		you ended up achieving the status of absorption Energy Apprentice.
		*goto tempfend
	*elseif (strength > 9)
		you ended up achieving the status of absorption Strength Apprentice.
		*goto tempfend
	*else
		your Tech absorption skill approached the Apprentice level.
		*goto tempfend
*if newreader
	you favored your technological skills in order to approach the Tech Apprentice level.
	*goto tempfend

*label tempfend

Temporarily fending off the Bominate, you were then able to learn that some unknown foreign race had purposefully created this monstrosity to keep Binaria embroiled in civil war. It turned out the only thing capable of killing the Bominate, utilizing a gene-specific nerve touch, was the secret race that had created it.
*if (loadedreader) and (bomsteal)
	*goto horiblwound
*if newreader
	*set bominatetruth true
	*set bomsteal false
You also learned that this race was from a neighbor planet of Binaria named Cuttara—information that would prove very useful later.

*label horiblwound
*page_break

During this MemoryTravel battle, Dhanthik was horribly wounded by the Bominate and subsequently lost control of Hir shape-shifting abilities. Right before the Bominate could finish Dhanthik, you were stunned to see Dhanthik bathed in red energy…

The same red energy that had teleported you to Versus.

This potential game-changing revelation was then confirmed when you woke up back on Versus, as you were pulled away for a psychic conversation with the mysterious Elite Courte member known only as Oli.

You found Oli intriguing for many reasons, not least of which because 
*if loadedreader
	*if androgsexual
		you're attracted to androgyny or uncategorizable gender identities, and Oli falls under that umbrella.
		*page_break
		*goto venumatalk
	*if pansexual
		you're attracted to many types, and Oli seemed to be exactly your type.
		*page_break
		*goto venumatalk
	*if attractedtowomen 
		you're attracted to women, and Oli was a particularly appealing one.
		*page_break
		*goto venumatalk
	*if attractedtomen
		you're attracted to men, and Oli was a particularly appealing one.
		*page_break
		*goto venumatalk
*if newreader
	*set rlshp_oli 60
	Oli falls into the group you happen to be attracted to:

*choice
	#I am only attracted to men.
		*set attractedtomen true
		*set olimale true
		*set bremale true
		*goto venumatalk
	#I am only attracted to women.
		*set attractedtowomen true
		*set olifemale true
		*set olize "she"
		*set olihis "her"
		*set olihir "her"
		*set brefemale true
		*set breze "she"
		*set brehis "her"
		*set brehir "her"
		*goto venumatalk
	#I don't see gender, I see people. Gender, or lack thereof, doesn't concern me.
		*set attractedtomen true
		*set attractedtowomen true
		*set pansexual true
		*set breandrog true
		*set breze "ze"
		*set brehis "hir"
		*set brehir "hir"

		You don't rely on categories to decide who you're attracted to. However, you were potentially attracted to Oli in this case because Oli is:

		*choice
			#Male.
				*set olimale true
				*goto venumatalk
			#Female.
				*set olifemale true
				*set olize "she"
				*set olihis "her"
				*set olihir "her"
				*goto venumatalk
			#Androgenous.
				*set oliandrog true
				*set olize "ze"
				*set olihis "hir"
				*set olihir "hir"
				*goto venumatalk
	#I'm most attracted to androgyny and uncategorizable identities, but I don't necessarily discriminate.
		*set attractedtomen true
		*set attractedtowomen true
		*set androgsexual true
		*set oliandrog true
		*set olize "ze"
		*set olihis "hir"
		*set olihir "hir"
		*set breandrog true
		*set breze "ze"
		*set brehis "hir"
		*set brehir "hir"
		*goto venumatalk

*label venumatalk

Oli pulled away your consciousness for a secret mental conversation on what ${olize} called the brainplane, since Elite members aren't technically allowed to speak to Ords like you. Oli also sported a mysterious Priscan-looking mirror patch on ${olihis} wrist and somehow knew about the legend of Dhanthik, but ${olize} didn't have time to answer any of your many questions about these things. Oli only had time to deliver an important message about the search for Dhanthik.

Oli explained that Dhanthik was indeed Selected by Versus and still residing here, on the Constructive side among you. Dhanthik arrived badly injured, and to protect Hirself Ze entered a transformative healing state, assuming the form of a new being. As a result, Dhanthik does not remember who Ze really is. 

Oli didn't know exactly why or how, but ${olize} confirmed that Dhanthik was operating as an anomaly in the Verses System—even if Dhanthik's assumed identity is killed or Reborn, Dhanthik simply returns to Versus in a completely new assumed persona. Dhanthik's false identities are so comprehensive that Ze can evade all kinds of psychic detection, and each successive false identity believes itself to be real on every level. Therefore nothing so far has been able to detect who Dhanthik is hiding as, but Oli believed that Priscan MemoryTravel was the only way to identify Dhanthik and awaken Hir from this cosmic coma.

Oli then proclaimed that since you were the first Priscan to enter Versus since Dhanthik's disguised arrival, The Great One was Lost to be Found by you, ${name} Thomil—and the fate of the entire galaxy might depend upon your success.

*page_break

Once this too-brief conversation ended, you couldn't help but reflect upon your potential purpose for being Selected by Versus. Could this be why, to use your unique absorb ability to wake up Dhanthik by MemoryTraveling everyone here? Whatever you believed about your purpose, you knew you had to complete this task to save everyone you loved back on Prisca—and perhaps even beyond. 

In order to organize this task, you started an official Dhanthik checklist in the Stats Screen. You then realized the only way to narrow down this list would be to MemoryTravel each of the remaining unknown Versus inhabitants—a process that would take you MemoryTraveling to nearly two dozen new worlds. You'd get to visit countless cultures and borrow a wide array of new abilities, a prospect that was simultaneously exhilarating and terrifying. 

No matter what else this experience ends up being, you realized it would truly prove to be the adventure of a lifetime—the adventure you'd always secretly wanted.

*page_break

*if loadedreader
	When you returned from the brainplane to find a now-awakened OtherBoard at odds with Cel and Trig, two human Rutonian soldiers newly transported to Versus, you intervened to stop the conflict by revealing the truth about the Bominate's origins.

	As the conflict fizzled in the face of this revelation and the Rutonians departed, you learned OtherBoard had been living in isolation in order to mourn the loss of her love, Multiplicity—which OtherBoard did by injecting Multiplicity's old personality matrix disks, dubbed "Solgrams."

	You then helped to remind OtherBoard of her Multinarian mission for peaceful unification and tried to kickstart the healing process for this android, who was clearly new to experiencing emotions.

	*if obnsr
		You ended things with OtherBoard by hoping to enter into a mutual nonsexual romance.
		*goto thepartyloaded
	*elseif (rlshp_ob > 70)
		You ended things with OtherBoard as potentially good friends.
		*goto thepartyloaded
	*elseif (rlshp_ob > 30)
		You ended things with OtherBoard as a potential ally, given your political aspirations.
		*goto thepartyloaded
	*else
		You ended things with OtherBoard as a potential enemy, given your political aspirations.
		*goto thepartyloaded

*set bomob true
*set bompeace false
*set bomwar false
*set bomceltrig false
*set rlshp_celtrig 50
*set rlshp_ob 71
*set secretcoupmeeting true
*set rlshp_newbies 50
*set rlshp_airon 50
*set rlshp_pj 50
*set rlshp_grog 50
*set rlshp_brawl 50

When you returned from the brainplane, you realized that you needed to narrow down your Dhanthik list in one important way: by full absorbing ${deathone} before the potentially deadly Versus match that night. Luckily you were invited to an Ord party thrown by Breeze, where you hoped to be able to accomplish this task. 

You met many of the other Ords at this party and managed to full absorb 
*if todrickdie
	Todrick as hoped. This process left you feeling very connected to Todrick—and somewhat guilty, given your role in his decision to volunteer. 

	Thankfully you also grew closer to Breeze, who ended up revealing to you that this party was the first unofficial meeting of ${brehis} and Lady Venuma's coup. As Lady Venuma herself then appeared,
	*if officiallyneutral
		*set rlshp_venuma 51
		*set rlshp_breeze 51
		you resolved to end things with Breeze and Lady Venuma as potential allies, wanting to keep your distance before you picked a political side.
		*goto brelvromance
	*elseif ruthlessregime
		*set rlshp_venuma 51
		*set rlshp_breeze 51
		you ended things with Breeze and Lady Venuma as potential allies, wanting to keep your enemies closer, given your Elite Courte aspirations.
		*goto brelvromance
	*else
		*set rlshp_venuma 71
		*set rlshp_breeze 71
		you ended things with Breeze and Lady Venuma as potential friends, wanting to keep them as close as possible.
		*goto brelvromance
*else
	Breeze as hoped, despite ${brehir} hating you. This process left you feeling very connected to Breeze, not to mention somewhat guilty. 

	Thankfully you also grew closer to Todrick, who ended up telling you that he thought this party was actually the first unofficial meeting of Lady Venuma's coup.

	As Lady Venuma herself then appeared, you thought you might have to make a move, since she clearly now saw you as a potential enemy, given what you had done to thwart her plans for Todrick.

	*set rlshp_todrick 71
	*set rlshp_venuma 20
	*set lvfinalromance false
	*set thruple false
	*set brefinalromance false
	*set brefinalnohookup false
	*set bretimeprocess false
	*page_break
	*goto evbattle

*label brelvromance

Though you did have the chance to get much closer to Breeze and Lady Venuma, if you wanted:

*choice
	*selectable_if (attractedtowomen) #I entered into romances with both Lady Venuma and Breeze.
		*set thruple true
		*set lvfinalromance true
		*set rlshp_venuma 80
		*set rlshp_breeze 80
		*set brefinalromance true
		*set brefinalnohookup false
		*set bretimeprocess false

		You were even able to consummate this divine relationship with Lady Venuma, who revealed she was also involved with Breeze. Now you wonder if you'll get to do the same with Breeze, either privately or with Lady Venuma as an official thruple.
		*goto evbattle
	*selectable_if (attractedtowomen) #I entered into a romance with Lady Venuma.
		*set thruple false
		*set lvfinalromance true
		*set rlshp_venuma 80
		*set brefinalromance false
		*set brefinalnohookup false
		*set bretimeprocess false

		You were even able to consummate this divine relationship with Lady Venuma, and you hope to do so again.
		*goto evbattle
	#I entered into a romance with Breeze.
		*set thruple false
		*set lvfinalromance false
		*set rlshp_breeze 80
		*set brefinalromance true
		*set brefinalnohookup false
		*set bretimeprocess false

		You didn't make this relationship with Breeze physical at the party, but you hope to take any next steps sometime soon.
		*goto evbattle
	#I didn't want a romance with either.
		*set thruple false
		*set lvfinalromance false
		*set brefinalromance false
		*set brefinalnohookup false
		*set bretimeprocess false
		*goto evbattle

*label thepartyloaded
*page_break

After that, you realized you needed to narrow down your Dhanthik list in one important way: by full absorbing ${deathone} before the potentially deadly Versus match that night. Luckily you were invited to an Ord party thrown by Breeze, where you hoped to be able to accomplish this task. 

You met many of the other Ords at this party and managed to full absorb 
*if todrickdie
	Todrick as hoped. This process left you feeling very connected to Todrick—and somewhat guilty, given your role in his decision to volunteer.

	*if secretcoupmeeting
		Thankfully you also grew closer to Breeze, who ended up revealing to you that this party was the first unofficial meeting of ${brehis} and Lady Venuma's coup. His reveal took on new meaning as Lady Venuma then arrived, making a grand entrance as usual.
		*goto breezeloaded
	*else 
		You also spent time with Breeze and Lady Venuma, once she made her grand entrance.
		*goto breezeloaded
*else
	Breeze as hoped, despite ${brehir} hating you.

	*if secretcoupmeeting
		Thankfully you instead grew closer to Todrick, who ended up telling you that he thought this was the first unofficial meeting of Lady Venuma's coup.
		*goto lvarrivedloaded
	*else
		You also got to spend more time with your new friend and ally, Todrick.
		
		*label lvarrivedloaded

		As Lady Venuma herself then appeared, you thought you might have to make a move, since she clearly now saw you as an enemy.
		*page_break
		*goto evbattle

*label breezeloaded

*if thruple
	Ultimately, you entered into romances with both Breeze and Lady Venuma, as a potential thruple. You later consummated your relationship with Lady Venuma in a rather divine experience.
	*goto breoptions
*elseif lvfinalromance
	Ultimately, you entered into a romance with Lady Venuma, one you later consummated in rather divine terms.
	*page_break
	*goto evbattle
*elseif brefinalromance
	You actually entered into a romance with Breeze at this party. 
	*label breoptions
	*if brefinalnohookup
		You didn't make this relationship with Breeze physical at the party, but you hope to take any next steps sometime soon.
		*page_break
		*goto evbattle
	*else
		You also started to hook up with Breeze at the party,
		*if bretimeprocess
			but needed time to process the fact that ${breze} is intersex.
			*page_break
			*goto evbattle
		*else
			feeling totally fine when ${breze} revealed that ${breze} is secretly intersex—an identity Breeze was ashamed of because of stigma from ${brehis} home planet.
			*page_break
			*goto evbattle
*else
	*goto evbattle

*label evbattle
*if newreader 
	*set life 10
	*set lifemax 10

Things took a dark turn when Empress Vaccus unexpectedly crashed the party. You had almost forgotten about Empress Vaccus' presence on Versus, given everything else you had been dealing with, but its arrival was a rather potent and deadly reminder.

In the knock-down, drag-out fight that ensued between you and the sluglike Blot Empress, you managed to hold your own using all of your wits and resources—yet another feat no other Priscan had ever even come close to achieving. 

The epic fight left both you and Empress Vaccus injured, and while Empress Vaccus ultimately fled, you ended up passing out…

*page_break

Only to awaken later and find ${deathone} facing the dreaded Un-Thing—which turned out to be another updated version of the half-human, half-android Bominate you had encountered in MemoryTravel.

*if loadedreader
	*if multiplicitytruth
		In the ensuing battle, ${deathone} managed to knock off this new Bominate's faceplate to reveal that its face was marked with a unique tattoo—one that once belonged to OtherBoard's partner, Multiplicity. The revelation that this Bominate was made from Multiplicity's dead body filled you with horror and sadness for OtherBoard.
		*goto ultdie
	*else
		*goto ultdie
*else
	*set multiplicitytruth false
	*goto ultdie

*label ultdie

${deathone} fought valiantly and bravely against this Destructive Bominate, but it wasn't enough.

You watched helplessly as ${deathone} fell prey to the Bominate's acidic fury and become one of its many Versian victims.

*page_break

Later, at ${deathone}'s funeral, almost all of the other Constructive Versians gathered, including the once-reclusive OtherBoard. You were still unable to see The Elite Courte in their hovering skybox, but you did hear Queen Ashe's super-bright voice as she delivered a eulogy in ${deathone}'s honor.

Feeling the familiar Priscan urge to reflect at this ceremony, you thought about how every aspect of what you believed had already been tried and tested during your short time on Versus so far. You quickly realized that you would continue to be tested too, as Queen Ashe went on to announce… 

That you were among the five Ord Versians invited to participate in The Elite Trials, the competition to win the vacant thirteenth spot in The Elite Courte. Hearing this, you immediately knew what your goal had to be, based on all you had already done on Versus:

*if loadedreader
	*if coupspy
		You had to attempt to win The Elite Trials and join The Elite Courte, but only to become a spy for Lady Venuma's brewing coup.
		*goto funeralends
	*elseif coupbond
		You had to use your time in The Elite Trials to bond with any hidden coup members Lady Venuma might connect you to.
		*goto funeralends
	*elseif doubleagent
		You had to attempt to become an Elite Courte member by offering to be a double agent for Queen Ashe, spying on the brewing coup.
		*goto funeralends
	*elseif winjoin
		You had to try to win The Elite Trials earnestly, to become a member of The Elite Courte.
		*goto funeralends
	*else
		You had to use your time in The Elite Trials to gather more information and focus on finding Dhanthik.
		*goto funeralends
*else
	*if ruthlessrebellion
		*set coupspy true
		You had to attempt to win The Elite Trials and join The Elite Courte, but only to become a spy for Lady Venuma's brewing coup.
		*goto funeralends
	*elseif genuinerebellion
		*set coupbond true
		You had to use your time in The Elite Trials to bond with any hidden coup members Lady Venuma might connect you to.
		*goto funeralends
	*elseif ruthlessregime
		*set doubleagent true
		You had to attempt to become an Elite Courte member by offering to be a double agent for Queen Ashe, spying on the brewing coup.
		*goto funeralends
	*elseif genuineregime
		*set winjoin true
		You had to try to win The Elite Trials earnestly, to become a member of The Elite Courte.
		*goto funeralends
	*else
		*set eliteinfo true
		You had to use your time in The Elite Trials to gather more information and focus on finding Dhanthik.
		*goto funeralends

*label funeralends
*page_break

As silence stretched over the funeral gathering and your own thoughts alike, you experienced a rare moment of peace. 

Still, there were so many questions you needed to answer: Who is Dhanthik hiding as? Why have you been Selected by Versus? Will you survive long enough to be Reborn? Will you be able to save your planet and family? How will you choose to answer Mother's inheritance request? Will you be able to defeat Empress Vaccus? How will you fare in The Elite Trials? Will Lady Venuma be able to pull off her coup? Will you be able to kill the Bominate using the secrets you've learned? Will you ever be voted into the Versus Match? And if you are, will you survive it? 

Or will you fall, just like ${deathone}?

As you stood among the bright and diverse Versians with your own goals set, the answers to these burning questions didn't seem to matter as much. After all, you'd been given the chance to live out the adventure you'd always dreamed of having…

…and perhaps you'd simply begun to write the Verses of your own story.
*goto timetobegin

*label timetobegin
*finish VERSUS: The Elite Trials
