*label display

*if meetimperva
	*set impervastatname "Imperva"

*if meetlockdown
	*set lockdownstatname "Lockdown"

*if meetcadet
	*set cadetstatname "Cadet Gadget"

*if meetmamana
	*set mamanastatname "MamaNa"

*if meeteverly
	*set everlystatname "Prince Everly"

*if meetashe
	*set ashestatname "Queen Ashe"

*label officialstatchart

*image battlestats.png center BATTLE STATS
*stat_chart
	text life Current Life
	text lifemax Maximum Life
	opposed_pair Weapons	
		Abilities
	percent agile Agility
	percent command Command
	percent energy Energy
	percent strength Strength
	percent tech Tech
*if techapprentice
	[b]Tech Apprentice[/b]: Level Cleared [i](Able to Access Readouts Remotely)[/i]
*if technovice
	*line_break
	[b]Tech Novice[/b]: Level Cleared [i](Able to Redirect Weapons Systems)[/i]
*if energyapprentice
	*line_break
	[b]Energy Apprentice[/b]: Level Cleared [i](Able to Generate Bio-Shock Blast)[/i]
*if energynovicebool
	*line_break
	[b]Energy Novice[/b]: Level Cleared [i]Able To Unleash Golden Essence[/i]
*if strengthapprentice
	*line_break
	[b]Strength Apprentice[/b]: Level Cleared [i](Able to Access Bio-Enhanced Punches)[/i]
*if strengthnovicebool
	*line_break
	[b]Strength Novice[/b]: Level Cleared [i](Acquired Demi-Divine Durability)[/i]
*if commandappbool
	*line_break
	[b]Command Apprentice[/b]: Level Cleared [i](Able To Access Divine Coercion Skill)[/i]
*comment endif

*image socialstats.png center SOCIAL STATS
*stat_chart
	opposed_pair Calculating
		Trustworthy
	opposed_pair Outspoken
		Contemplative
	opposed_pair Enlighten
		Educate
	opposed_pair Security
		Freedom
	opposed_pair Purity 
		Diversity
*comment endif

*if mamanaabolish
	*goto statusprogresschartabolish
*elseif mamanaopeneyes
	*goto statusprogresschart
*else
	*goto normalprogresschart

*label normalprogresschart

*image progressstats.png center PROGRESS STATS
*stat_chart
	text Mastery
	text Growth
*comment endif
*goto relationshipcharts

*label statusprogresschartabolish

*image progressstats.png center PROGRESS STATS
*stat_chart
	text Mastery
	text Growth
	percent winjoinstatus Win Trials To Join The Elite Courte
	percent doubleagentstatus Elite Double Agent Within Coup
	percent coupbondstatus Establish Ties Within Coup
	percent coupspystatus Coup Spy Within Elite
	percent eliteinfostatus Remain As Neutral As Possible
	percent abolishbothstatus Secret Abolitionist
*comment endif
*goto relationshipcharts

*label statusprogresschart

*image progressstats.png center PROGRESS STATS
*stat_chart
	text Mastery
	text Growth
	percent winjoinstatus Win Trials To Join The Elite Courte
	percent doubleagentstatus Elite Double Agent Within Coup
	percent coupbondstatus Establish Ties Within Coup
	percent coupspystatus Coup Spy Within Elite
	percent eliteinfostatus Remain As Neutral As Possible
*comment endif
*goto relationshipcharts

*label relationshipcharts

*image relationships.png center RELATIONSHIPS
*if todrickdie
	*goto showbreezechart
*else
	*goto showtodrickchart

*label showbreezechart
*stat_chart
	percent rlshp_ob OtherBoard
	percent rlshp_venuma Lady Venuma
	percent rlshp_breeze Breeze
	percent rlshp_oli Oli
	percent rlshp_airon Baron Airon
	percent rlshp_grog Grog
	percent rlshp_pj Pinkuju
	percent rlshp_imperva ${impervastatname}
	percent rlshp_lockdown ${lockdownstatname}
	percent rlshp_cadet ${cadetstatname}
	percent rlshp_mamana ${mamanastatname}
	percent rlshp_everly ${everlystatname}
	percent rlshp_ashe ${ashestatname}
*comment endif
*goto collectedvinfo

*label showtodrickchart
*stat_chart
	percent rlshp_ob OtherBoard
	percent rlshp_venuma Lady Venuma
	percent rlshp_todrick Todrick
	percent rlshp_oli Oli
	percent rlshp_airon Baron Airon
	percent rlshp_grog Grog
	percent rlshp_pj Pinkuju
	percent rlshp_imperva ${impervastatname}
	percent rlshp_lockdown ${lockdownstatname}
	percent rlshp_cadet ${cadetstatname}
	percent rlshp_mamana ${mamanastatname}
	percent rlshp_everly ${everlystatname}
	percent rlshp_ashe ${ashestatname}
*comment endif
*goto collectedvinfo

*label collectedvinfo

*image collected_info.png center Collected Versus Information

*choice
	#The Verses.
		*goto versesrundown
	#Versus Inhabitants.
		*goto characterrundown
	#Dhanthik MemoryTravel Checklist.
		*goto checklistrundown
	#Achievement Structure.
		Once you have unlocked every Achievement, you have fully experienced every variation of [b]VERSUS[/b]: THE ELITE TRIALS. 

		[i]Tip:[/i] this will require multiple readthroughs.

		*page_break
		*goto officialstatchart
	#Stat Explanations.
		[b]Trustworthy vs. Calculating[/b]: Are you more honest and genuine, but less able to pull of political maneuvers? Or are you more political and shrewd, but generally harder to trust?
		
		[b]Outspoken vs. Contemplative[/b]: Are you committed to speaking out and stepping up as a leader, even if it places a bigger target on your back? Or are you inclined to keep your thoughts to yourself and survey situations, even if it means you have potentially less influence over others?

		[b]Freedom vs. Security[/b]: To live in a completely free society means that there can no promise of safety, because there are no rules to enforce security. Conversely, to live in a completely secure society means that there must be many rules restricting freedom. Which is more important?

		[b]Enlighten vs. Educate[/b]: Is it important to teach others what to think by passing along wisdom and knowledge you know to be true, whether they embrace this imposition or not? Or is it more important to teach others how to think for themselves, even if it means they might disagree with you?

		[b]Purity vs. Diversity[/b]: Is it important for a culture to remain separate in order to maintain its purity and identity, even if this risks potential cultural stagnation? Or is it more important to integrate and interact with other diverse communities, even if it risks cultural dilution and change?

		[b]Mastery[/b]: Gain Mastery points by making decisions consistent with your existing Stat Levels. These Levels will be continuously tested and rewarded with Mastery points.

		[b]Growth[/b]: This Stat measures your character evolution. How successfully do you navigate new cultures? How do you respond to belief systems that potentially conflict with your own? Does your own perspective evolve or remain unchanged?

		*page_break
		*goto officialstatchart
	*if (mamanaopeneyes) #Status Goals.
		As you access this page, Rosae's voice chirps in your ear with a clarification: "While the following traits will not necessarily be required to carry out each potential Status goal, possessing the correct combination of traits will only help you achieve each respective goal. Then, when the time finally comes, your Status levels for each goal will determine whether you can pass Queen Ashe's SoulTest or not, so be sure to keep an eye on which status levels you are building most!"

		[b]Win Trials To Join The Elite Courte[/b]: Trustworthy. Outspoken. Security.
		*line_break
		[b]Elite Double Agent Within Coup[/b]: Calculating. Contemplative. Security. 
		*line_break
		[b]Establish Ties Within Coup[/b]: Trustworthy. Contemplative. High Security OR High Freedom. 
		*line_break
		[b]Coup Spy Within Elite[/b]: Calculating. Outspoken. High Security OR High Freedom.
		*line_break
		[b]Remain As Neutral As Possible[/b]: High Trustworthy OR High Calculating. Contemplative. High Security OR High Freedom.
		*if mamanaabolish
			*line_break
			[b]Secret Abolishionist[/b]: High Trustworthy OR High Calculating. Outspoken. Freedom.
		*comment endif

		"As an additional note, be advised that your relationships will matter a great deal in allocating final Status for each goal, as well," Rosae then adds. "Obviously, you want strong relationships with all those aligned with your ultimate goal, or if you plan to become a spy of some sort, you want to please both sides. Conversely, you want to distance yourself from those on the potential opposing side you plan to end up against. Keeping track of who falls on which side of the Elite/Coup split, however, will be up to your own knowledge and intuition, as the politics evolve and update!

		"You likely will not always be able to build all the desired personality, political, and relationship stats all the time, having to sometimes sacrifice one for another as you make choices. However, you must always remember to focus on what you feel is most important in the moment, Priscy!"

		*page_break
		*goto officialstatchart
	*if (fourpathslinterreveal) #The Wone FourPath Splinter.

		[b]AUTHORIUS[/b]
		*line_break
		[i]Path of the Pastor[/i]
		*line_break
		[b]Crest:[/b] The White & Fiery A.
		*line_break
		The Authorius Path represents the original school of Wone thought, following the ancient texts of Enlightenment and benevolent Security. The Authorius thus believe in imposing the most important universal truths upon the unenlightened by implementing clearly defined rules. 
		*line_break
		[i]Stern. Devout. Righteous. Loyal.[/i]
		*line_break
		[b]Wone Contact:[/b] Queen Ashe

		[b]BOLDURE[/b]
		*line_break
		[i]Path of the Pioneer[/i]
		*line_break
		[b]Crest:[/b] The Gold & Bold B.
		*line_break
		The Boldure Path represents the newest emerging school of NuGuard Wone thought, following the revolutionary texts of Education and Freedom. The Boldure thus believe in teaching the unenlightened to think for themselves, a process they also believe demands total freedom.
		*line_break
		[i]Adventurous. Curious. Rebellious. Bold.[/i]
		*line_break
		[b]Wone Contact:[/b] Lady Venuma

		[b]COMMAITH[/b]
		*line_break
		[i]Path of the Parent[/i]
		*line_break
		[b]Crest:[/b] The Black & Flexible C.
		*line_break
		The Commaith Path represents the more conservative combination of new and old, merging the ancient text of Enlightenment with the concept of intellectual Freedom. The Commaith thus believe in imposing the most important universal truths upon the unenlightened, but also in balancing this imposition with freedom from strict rule, to allow the unenlightened to learn from their own mistakes.
		*line_break
		[i]Nurturing. Punishing. Wise. Protective.[/i]
		*line_break
		[b]Wone Contact:[/b] Lord Grahl

		[b]DEMLECT[/b]
		*line_break
		[i]Path of the Prefect[/i]
		*line_break
		[b]Crest:[/b] The Rose & Circular D.
		*line_break
		The Demlect Path represents the more progressive combination of new and old, merging the revolutionary text of Education with the adherence to rules of Security. The Demlect thus believe in teaching the unenlightened to think for themselves, but also in balancing this potentially destructive process with rules and guidelines to protect the unenlightened.
		*line_break
		[i]Studious. Ambitious. Political. Lawful.[/i]
		*line_break
		[b]Wone Contact:[/b] Prince Everly

		*page_break
		*goto officialstatchart

*label versesrundown

*image v_map.png

[b]Planet Versus[/b]
*line_break
Versus is a mysterious and infamous planet, governed by the laws of the ancient Verses Scriptures. Planet Versus remains a sacred space where those Selected are called to face the ultimate test. It is said to be a place of great spiritual awakening, rehabilitation, and rebirth, but it is also a place of great danger.

The only way to access planet Versus is to be Selected by the planet itself. In some cultures, Selection is seen as the greatest honor, a sign of extreme wells of untapped potential. In other cultures, Selection is a sign of being one of the most hopeless and ruthless of souls. 

Once Selected, you must survive long enough for Planet Versus to deem you worthy of returning home, an honor known as being Reborn. The Reborn return to their homeworlds to become planetary legends and forces for monumental change, constructively or destructively.

Inhabitants of Versus live in complete isolation—there is no way to communicate with or escape to the rest of the galaxy. Versus is still a place of universal mystery—no one knows why they are Selected or how Versus truly works, not even The Wone.

[b]Versus Rules[/b]
*line_break
-- Planet Versus is split in two by the Versus Barrier, with twenty-four inhabitants on each side. 
*line_break
-- You're on the Constructive side, meant to challenge the Destructive side.  
*line_break
-- The Versus Vote occurs every three days. The Constructive and Destructive inhabitants with the most peer votes go into the Versus Match against each other.
*line_break
-- After twenty-four Votes and Matches, those deemed worthy among the twenty-four remaining survivors are Reborn.
*line_break
-- The Holdovers break for a few months until Newcomers arrive to restore each side to twenty-four inhabitants, and the Versus cycle begins again.

[b]The Elite Courte[/b]
*line_break
The Constructive half of Versus is currently ruled by a system imposed by Queen Ashe Solares of the Wone Haus of Element, Order of Fire. Every cycle, Queen Ashe selects a worthy ruling majority of thirteen to control the Versus Vote. The eleven remaining "Ords" rotate through the twenty-four Versus Matches. Whoever survives at the end of the cycle may be selected for the Elite Trials, along with any Newcomers that catch Queen Ashe's eye.

*page_break
*goto officialstatchart


*label characterrundown

[b]NAME:[/b] Royal A-08
*line_break
[b]SPECIES:[/b] Binarian Android, Royal Classification
*line_break
[b]HOME PLANET:[/b] Binaria
*line_break
[b]STANDARD BINARIAN ABILITIES:[/b] Durability, Strength, Computing, Interfacing 
*line_break
[b]ROYAL CLASS BINARIAN ABILITIES:[/b] Flight Generators, Energy Emissions, Musical Manipulation, PowerGram Catalogue 

[b]NAME:[/b] Lady Venuma Grecca
*line_break
[b]SPECIES:[/b] Demigoddess
*line_break
[b]HOME PLANET:[/b] Wone
*line_break
[b]ABILITIES:[/b] Flight, Durability, Strength, Enhanced Senses, Energy Redirection, Knowledgeability, Charms, Intuition

[b]NAME:[/b] Electrician C-5184 / "OtherBoard"
*line_break
[b]SPECIES:[/b] Binarian Android, Municipal Working Classification
*line_break
[b]HOME PLANET:[/b] Binaria
*line_break
[b]ABILITIES:[/b] Durability, Strength, Computing, Interfacing 
*line_break
[b]ELECTRICIAN SPECIAL ABILITIES:[/b] Wire Tensity, Electrical Generation, Electrical Manipulation

*if todrickdie
	*goto breezecharacter
*else
	*goto todrickcharacter

*label breezecharacter

[b]NAME:[/b] Jess Damon / "Breeze"
*line_break
[b]SPECIES:[/b] Enhanced Human / Millennithian Humanoid
*line_break
[b]HOME PLANET:[/b] Millennith
*line_break
[b]ABILITIES:[/b] Wind Generation, Wind Manipulation, Wind-Supported Flight, Flight Altered Anatomy 
*goto pinkujucharacter

*label todrickcharacter

[b]NAME:[/b] Todrick Tumpkin
*line_break
[b]SPECIES:[/b] Human
*line_break
[b]HOME PLANET:[/b] Blarfngard
*line_break
[b]ABILITIES:[/b] Farming Expertise, Nimbleness
*goto pinkujucharacter

*label pinkujucharacter

[b]NAME:[/b] Shiro Demon / "Pinkuju"
*line_break
[b]SPECIES:[/b] Human
*line_break
[b]HOME PLANET:[/b] Resu
*line_break
[b]ABILITIES:[/b] Weapons Expertise, Racing Expertise, Martial Arts Expertise

[b]NAME:[/b] Baron Airon VI
*line_break
[b]SPECIES:[/b] Humanoid-Avian Crossgenetics
*line_break
[b]HOME PLANET:[/b] Blarfngard
*line_break
[b]ABILITIES:[/b] Flight, Speed, Avian Qualities

[b]NAME:[/b] Slave #29 / "Grog"
*line_break
[b]SPECIES:[/b] Groogian
*line_break
[b]HOME PLANET:[/b] Blarfngard
*line_break
[b]ABILITIES:[/b] Durability, Strength, Resilience, Retractable Shellback

[b]NAME:[/b] Oli
*line_break
[b]SPECIES:[/b] Humanoid
*line_break
[b]HOME PLANET:[/b] Unknown
*line_break
[b]ABILITIES:[/b] Pyschic Projections, Wide Assortment of Applications

*page_break
*goto officialstatchart


*label checklistrundown
[b]VERSUS CONSTRUCTIVE INHABITANTS[/b]

[b]Ords:[/b] Twelve Inhabitants
*line_break
*if (olidtclue = false)
	1.) [b]${name} Thomil:[/b] Not Dhanthik
*if olidtclue
	1.) [b]${name} Thomil:[/b] Status Unknown
*line_break 
2.) [b]OtherBoard:[/b] Not Dhanthik, MemoryTraveled
*line_break 
*if (olidtclue = false)
	3.) [b]Empress Vaccus:[/b] Status Unknown, MemoryTravel Priority Normal
*if olidtclue
	3.) [b]Empress Vaccus:[/b] Known Beyond Versus, MemoryTravel Priority Low
*line_break 
*if todrickdie
	4.) [b]Breeze:[/b] Status Unknown, MemoryTravel Priority Normal
	*line_break
	5.) [b]Todrick:[/b] Not Dhanthik, MemoryTraveled [i]Deceased[/i]
*if (todrickdie = false)
	4.) [b]Todrick:[/b] Status Unknown, MemoryTravel Priority Normal
	*line_break
	5.) [b]Breeze:[/b] Not Dhanthik, MemoryTraveled [i]Deceased[/i]
*line_break
6.) [b]Pinkuju:[/b] Status Unknown, MemoryTravel Priority Normal
*line_break
7.) [b]Baron Airon:[/b] Status Unknown, MemoryTravel Priority Normal
*line_break
8.) [b]Grog:[/b] Status Unknown, MemoryTravel Priority Normal
*line_break
*if fighthumm
	*if (olidtclue = false)
		9.) [b]Cel:[/b] Encountered in MemoryTarvel, MemoryTravel Priority Low
		*line_break
		10.) [b]Trig:[/b] Encountered in MemoryTarvel, MemoryTravel Priority Low
	*if olidtclue
		9.) [b]Cel:[/b] Not Dhanthik, Encountered in MemoryTarvel
		*line_break
		10.) [b]Trig:[/b] Not Dhanthik, Encountered in MemoryTarvel
*if (fighthumm = false)
	9.) [b]Cel:[/b] Status Unknown, MemoryTravel Priority Normal
	*line_break
	10.) [b]Trig:[/b] Status Unknown, MemoryTravel Priority Normal
*line_break
11.) [b]The Unpronounceable One:[/b] Status Unknown, MemoryTravel Priority Normal
*line_break
12.) [b]Unknown Ord Inhabitant [i](Possibly Burnbone?)[/i]:[/b] Status Unknown, MemoryTravel Priority Normal

[b]The Elite Courte:[/b] Twelve Inhabitants
*line_break
*if (olidtclue = false)
	1.) [b]Queen Ashe:[/b] Versus Timeline Possibly Incompatible, MemoryTravel Priority Low
*if olidtclue
	*if (ashenotdt = false)
		1.) [b]Queen Ashe:[/b] Known Beyond Versus, MemoryTravel Priority Low
	*if ashenotdt
		1.) [b]Queen Ashe:[/b] Not Dhanthik, Encountered in MemoryTarvel
*line_break
*if (olidtclue = false)
	2.) [b]Lady Venuma:[/b] Status Unknown, MemoryTravel Priority Normal
*if olidtclue
	*if (lvfound = false)
		2.) [b]Lady Venuma:[/b] Status Unknown, MemoryTravel Priority HIGH
	*if lvfound
		2.) [b]Lady Venuma:[/b] Not Dhanthik, Encountered in MemoryTarvel
*line_break
3.) [b]Royal A-08:[/b] Status Unknown, MemoryTravel Priority Normal
*line_break
4.) [b]Oli:[/b] Status Unknown, MemoryTravel Priority Normal
*if meetcadet
	*line_break
	5.) [b]Cadet Gadget:[/b] Status Unknown, MemoryTravel Priority Normal
*if meetlockdown
	*line_break
	6.) [b]Lockdown:[/b] Status Unknown, MemoryTravel Priority Normal
*if meetimperva
	*line_break
	7.) [b]Imperva:[/b] Status Unknown, MemoryTravel Priority Normal
*if meetmamana
	*line_break
	8.) [b]MamaNa:[/b] Status Unknown, MemoryTravel Priority Normal
*if meeteverly
	*line_break
	*if (olidtclue = false)
		9.) [b]Prince Everly:[/b] Status Unknown, MemoryTravel Priority Normal
	*if olidtclue
		9.) [b]Prince Everly:[/b] Not Dhanthik, Encountered in MemoryTarvel
*if meetbeyhalo
	*line_break
	10.) [b]Beyhalo:[/b] Status Unknown, MemoryTravel Priority Normal
*if meetglorya
	*line_break
	11.) [b]Glorya:[/b] Status Unknown, MemoryTravel Priority Normal
*line_break
[i]Remaining Elite Courte Unidentified[/i]

*page_break
*goto officialstatchart
