*comment Copyright 2015 by Mike Walter
*comment The Lost Heir 2:  Forging a Kingdom
*comment Scene #5: warprep.txt
*comment 61422 Words - 383 subroutines = 61.0 k
*hide_reuse
*gosub ResetAdventure
*temp warprep_teleport 0
*temp warprep_dwarves false
*temp warprep_elves false
*temp warprep_gnomes false
*temp warprep_halflings false
*temp warprep_halforcs false
*temp warprep_uddodead false
*temp gonna_date_b false
*temp teardrop_used false
*temp teardrop_used_on_self false
*temp warprep_firstbreak_done false
*temp warprep_secondbreak_done false
*temp warprep_thirdbreak_done false
*temp warprep_fourthbreak_done false
*temp warprep_seewhatbthinks false
*temp charity_event false
*temp mentioned_same_sex_magic false
*temp banter_name "None"
*label Random_Banter_loop
*rand coinflip 1 5
*if ((coinflip=1) and (gillgale_inparty))
	*set banter_name gillgale_name
	*goto After_Pick_Banter
*if ((coinflip=2) and (karlkarla_inparty))
	*set banter_name karlkarla_name
	*goto After_Pick_Banter
*if ((coinflip=3) and (peterpetra_inparty))
	*set banter_name peterpetra_name
	*goto After_Pick_Banter
*if ((coinflip=4) and (theothea_inparty))
	*set banter_name theothea_name
	*goto After_Pick_Banter
*if ((coinflip=5) and (jacejess_inparty))
	*set banter_name jacejess_name
	*goto After_Pick_Banter
*goto Random_Banter_loop

*label After_Pick_Banter

The temperature drops even further and soon the snow begins to fall lightly.  The sages are already saying that this will be a very cold and storm-filled winter.  The priests and priestesses who are supportive of your cause say that this is a good omen from the Gods and Goddesses, since it assures that you will have an uninterrupted winter of preparation before war begins in the spring.
*label Warprep_loop
*if (health<100)
	
	Between the passing of time and the priests of the temples, your body is healed of injuries.
	*if (showstats)
		*line_break
		(Health 100 / 100)
	*set health 100
	*set currentfriend_injured false
	*set companion_injured false
	*set demonstone_kgirr_used false
	*set demonstone_xiatta_used false
	*set demonstone_zonch_used false
	*set demonstone_brahl_used false
	*set demonstone_tyborr_used false
	*set demonstone_daanda_used false
	*goto Warprep_Check_AllDone
*else
	*goto Warprep_Check_AllDone

*label Warprep_Check_AllDone
*if ((((warprep_dwarves) and (warprep_elves)) and ((warprep_gnomes) and (warprep_halflings))) and ((warprep_halforcs) and (warprep_spies!="None")))
	*goto Warprep_AlliesGathered
*else
	*goto Warprep_Check_FirstBreak

*label Warprep_Check_FirstBreak
*if ((warprep_teleport=1) and (warprep_firstbreak_done=false))
	*set warprep_firstbreak_done true
	*if (prisonchild_exists)
		
		${prisonchild_name}, the ${prisonchild_boygirl} you rescued from Bunta, is having a lot of trouble adapting to ${prisonchild_hisher} new freedom and to palace life.  Despite everyone's attempts to find out who ${prisonchild_heshe} really is or who ${prisonchild_hisher} parents are, nobody can learn anything.  To make matters worse, ${prisonchild_heshe} still won't speak.
		
		"$!{prisonchild_heshe} bit the maid," Samuel, the Head Steward, complains to you.  "It was bad enough when ${prisonchild_heshe} was growling at my staff when they cleaned ${prisonchild_hisher} room, but after this, everyone refuses to go anywhere near ${prisonchild_himher} and I have to clean the room myself…with a pair of guards at my side!  You have to do something."
		*choice
			#Make ${prisonchild_name} a royal page under Samuel's care.
				Samuel practically chokes at your decision.  As a page, ${prisonchild_name} will be expected to run errands for Samuel.  Since ${prisonchild_name} won't speak and has a tendency to bite or growl when nervous, you have given the poor Head Steward a monumental task.
				*choice
					*selectable_if (gold>=50) #Give Samuel a small gift.  (Needs 50 Gold)
						You give your Head Steward some coin as a token of your appreciation.  He seems a little more accepting of the situation after this.
						*if (showstats)
							*line_break
							(Good +3, Gold -50 and Charm +2)
						*set good +3
						*set gold -50
						*set charm +2
						
						*goto After_Samuel_Gift
					#Offer no extra remuneration.
						*goto After_Samuel_Gift
				*label After_Samuel_Gift
				Over the next couple of days, you see that Samuel has gotten ${prisonchild_name} some nice new clothes and is keeping ${prisonchild_himher} busy.  Your list of complaints from the nobles seems endless as ${prisonchild_name} snarls at them when ${prisonchild_heshe} is frustrated or angry.  As winter wears on, the number of complaints lessens as ${prisonchild_name} learns some basic social skills and the nobles get used to ${prisonchild_hisher} odd ways.
				*set prisonchild_job "page"
				*goto Warprep_BreakChecks_Done
			#Ask Samuel to find ${prisonchild_name} some work in the kitchens.
				Samuel nods at your orders and takes ${prisonchild_name} to the kitchens.  There are always pots that need to be scrubbed or potatoes that need to be peeled.  The work is difficult, but it is honest and time consuming.  As winter wears on, you see ${prisonchild_name} silently going about ${prisonchild_hisher} tasks.
				*set prisonchild_job "kitchen"
				*goto Warprep_BreakChecks_Done
			#Tell Samuel to leave ${prisonchild_name} alone.
				Samuel has no choice but to obey.
				*label Leave_Alone
				Living in the royal suites is an enormous adjustment and only time will help ${prisonchild_name} cope with the changes.  The feral look in ${prisonchild_hisher} eyes never seems to go away and ${prisonchild_hisher} room looks more like an animal's den than a child's bedroom.
				*set prisonchild_job "alone"
				*goto Warprep_BreakChecks_Done
			#Say, "Well don't clean ${prisonchild_hisher} room any more."
				"As you wish, Your Highness," Samuel says with a nod.
				
				*goto Leave_Alone
			#Send ${prisonchild_name} to the Academy of Wizards for a formal education.
				The chances of ${prisonchild_name} having the skills needed to be a wizard are slim, but the great education of the fabled community would be very beneficial to ${prisonchild_himher}.  You send a private letter to Archmage Cumari, telling him about ${prisonchild_name} as well.  ${prisonchild_name} scowls at you the day that ${prisonchild_heshe} is taken away from Brightwater and sent to the Academy.
				*if (showstats)
					*line_break
					(${prisonchild_name} Relationship -20)
				*set prisonchild_relationship -20
				*set prisonchild_job "academy"
				*set prisonchild_inparty false
				*goto Warprep_BreakChecks_Done
			#Send ${prisonchild_name} to the temple orphanage and out of your life forever.
				"It's probably the best thing for the child," Samuel says with a consoling nod.
				
				The priests come and take ${prisonchild_name} to the temple orphanage where they will nurture ${prisonchild_himher} with more time and caring than you are able to give.
				*set prisonchild_exists false
				*set prisonchild_inparty false
				*goto Warprep_BreakChecks_Done
	*else
		*goto Warprep_BreakChecks_Done
*else
	*goto Warprep_Check_SecondBreak

*label Warprep_Check_SecondBreak
*if ((warprep_teleport=2) and (warprep_secondbreak_done=false))
	*set warprep_secondbreak_done true
	*if ((((branbrinn_heshe="he") and (likesboys)) or ((branbrinn_heshe="she") and (likesgirls))) or (lover_exists))
		*comment Must like BranBrinn, or have a lover, or both.
		
		One evening, at dinnertime, three powerful council members gather at your table.  General Vale, Lord Tovor and Archmage Cumari wait until the room is empty before speaking to you.  You suspect that they have something important, personal and private to tell you.
		
		"I drew the short straw," General Vale says gruffly.  "So I have to tell you what we're all thinking.
		*if (lover_exists)
			*if (lover_name=theothea_name)
				The mountain-${theothea_manwoman}
			*if (lover_name=karlkarla_name)
				The peasant
				*if (karlkarla_hisher="his")
					boy
				*if (karlkarla_hisher="her")
					girl
			*if (lover_name=jacejess_name)
				The Soulburner
			*if (lover_name=peterpetra_name)
				The disgraced nobleman's
				*if (peterpetra_hisher="his")
					boy
				*if (peterpetra_hisher="her")
					girl
			*if (lover_name=gillgale_name)
				The thief
				*if (gillgale_hisher="his")
					boy
				*if (gillgale_hisher="her")
					girl
			you've been fooling around with isn't marriage material."
		*if (lover_exists=false)
			You have to get married."
		
		Lord Tovor looks shocked and giggles nervously at General Vale's blunt words.
		
		Archmage Cumari rolls his eyes before speaking, "What our socially inept general is trying to say is, you need a suitable Royal Consort.  The people need to see stability in their future.  By declaring that you are officially
		*if (gender="male")
			courting
		*if (gender="female")
			being courted by
		someone, it shows that you may someday get married and have a child.  With war looming on the horizon, the citizens are afraid that you will be killed without a royal heir to succeed you.
		*if (lover_exists)
			And yes, I'm afraid that General Vale is correct.  ${lover_name} is not a good choice."
		
		"We think you should
		*if ((branbrinn_heshe="he") and (likesboys)) or ((branbrinn_heshe="she") and (likesgirls))
			*set warprep_b_suggested true
			*if (gender="male")
				court Captain ${branbrinn_name},"
			*if (gender="female")
				allow Captain ${branbrinn_name} to court you,"
			Lord Tovor says in a rush.  "$!{branbrinn_heshe} has noble blood, we trust ${branbrinn_himher} and ${branbrinn_heshe} has ties to the old regime."
			*if ((mc_hisher="his") and (branbrinn_hisher="his"))
				
				"Yes, we know that you like men,"
				*label SameSex_Courting
				*set mentioned_same_sex_magic true
				Archmage Cumari says.  "And yes, we believe that the people will be okay with this union.  As for a biological heir, I have the magic to make such a thing possible, should you decide to someday marry ${branbrinn_himher}."
				*goto Choose_Consort_loop
			*if ((mc_hisher="her") and (branbrinn_hisher="her"))
				
				"Yes, we know that you like women,"
				*goto SameSex_Courting
			*goto Choose_Consort_loop
		*else
			*comment Doesn't like BranBrinn, so must have a lover
			end your relationship with ${lover_name} and begin looking for a more suitable match."
			*goto Choose_Consort_loop

		*label Choose_Consort_loop
		*choice
			*if (lover_exists) #Speak to ${lover_name} about it.
				That night, you tell ${lover_name} about the meeting.
				
				*if (lover_name=theothea_name)
					"Well, what's the problem?" ${theothea_name} says.  "Just make me your damn Royal Consort and those old men will shut up."
				*if (lover_name=karlkarla_name)
					"I understand," ${karlkarla_name} says softly. "I'm a commoner, after all.  I'd try not to embarrass you too much, if you were to name me Royal Consort."
				*if (lover_name=peterpetra_name)
					"Very well," ${peterpetra_name} says.  "Name me Royal Consort so we can live honestly."
				*if (lover_name=gillgale_name)
					"Really?" ${gillgale_name} says.  "I guess now that you're no longer in hiding, you have all those responsibilities again.  So, you going to do it or not?"
				*if (lover_name=jacejess_name)
					"Then that's the end of it," ${jacejess_name} says with a sour expression on ${jacejess_hisher} face.  "You can't very well name me to be Royal Consort, now can you."
				*label Name_Or_Not_loop
				*choice
					#Ask, "Do you want to be named Royal Consort?"
						*if (lover_name=theothea_name)
							"Sure, why not?" ${theothea_name} says with a grin.  "Might be fun to watch those puffed up dandies bow to me."
						*if (lover_name=karlkarla_name)
							"Yes, that would be nice," ${karlkarla_name} says shyly.
						*if (lover_name=peterpetra_name)
							"I wish to remain with you," ${peterpetra_name} says.  "So yes.  I will take this title."
						*if (lover_name=gillgale_name)
							"Sure, why not?" ${gillgale_name} says with a grin.
						*if (lover_name=jacejess_name)
							"That's ludicrous," ${jacejess_name} says.  "I'm a Soulburner.  I can't be Royal Consort."
						*goto Name_Or_Not_loop
					#Make ${lover_name} your Royal Consort.
						*goto Happily_Accept_Role
					#Choose not to make ${lover_name} your Royal Consort.
						*if (lover_name=theothea_name)
							"Good enough to romp around with but not good enough to be official?" ${theothea_name} says.  "No thank you.  If your duties as ${princeprincess} come first, then count me out."
						*if (lover_name=karlkarla_name)
							"Your duties as ${princeprincess} come first," ${karlkarla_name} says.  "We need to break up so you can find someone suitable."
						*if (lover_name=peterpetra_name)
							"I will not live a lie," ${peterpetra_name} says.  "If you won't name me Royal Consort, then we must part ways."
						*if (lover_name=gillgale_name)
							"You have a duty as the ${princeprincess}," ${gillgale_name} says.  "I don't think we can be together without it being official."
						*if (lover_name=jacejess_name)
							"It was an interesting distraction while it lasted." ${jacejess_name} says.  "But I don't want to be your dirty little secret."
						*choice
							#Refuse to leave ${lover_name} and name ${lover_himher} to be your Royal Consort after all.
								*label Happily_Accept_Role
								*if (lover_name=jacejess_name)
									"Really?"  ${jacejess_name} says in a surprised voice.  "Officially?  Well, okay, I accept."
									
								*if (lover_name!=jacejess_name)
									${lover_name} accepts the role and you spend the night discussing your future together.
								In the morning, you find your councillors and deliver the news to them.
								
								*goto Warprep_NameLoverConsort
							#End your relationship with ${lover_name}.
								*goto End_Relationship
			*if (lover_exists) #Say, "I will ask ${lover_name} to be my Royal Consort."
				*label Warprep_NameLoverConsort
				*if (mentioned_same_sex_magic)
					"I can use the same spell that I had offered before," Archmage Cumari says tentatively.  "So, a child is possible between the two of you."
					*goto Warprep_ChoseLoverConsort_AfterBabytalk
				"The public may accept this," Archmage Cumari says after a short pause to think.
				*if ((mentioned_same_sex_magic=false) and (mc_hisher=lover_hisher))
					"And I have the magic needed to allow the two of you to have a child.  Unorthodox, but it would provide the stability we are looking for."
				*label Warprep_ChoseLoverConsort_AfterBabytalk
				
				"This isn't a complete disaster," General Vale says grudgingly, clearly accepting the idea because he has no other choice.
				
				"Yes, ${lover_name} could be made to work," Lord Tovor says for the same reason.
				*if (warprep_b_suggested)
					"Although the captain would have been better."
				*if (showstats)
					*line_break
					(Archmage Cumari Relationship +2, General Vale Relationship +2, Lord Tovor Relationship +2, Army Morale +3 and Citizen Reputation +3)
				*set cumari_relationship +2
				*set vale_relationship +2
				*set tovor_relationship +2
				*set army_morale +3
				*set citizen_reputation +3
				*goto Warprep_BreakChecks_Done
			*if ((lover_exists) and ((gender="male") and (warprep_b_suggested))) #Say, "Okay, I shall break up with ${lover_name} and court ${branbrinn_name}."
				*label Break_And_Date_B
				*set lover_name "None"
				*set lover_exists false
				*set gonna_date_b true
				Your three advisers
				*if (warprep_seewhatbthinks)
					are content
				*if (warprep_seewhatbthinks=false)
					couldn't be happier
				to hear that you are taking their words seriously.  You still have a few demi-human allies to talk with, so you decide to
				*if (warprep_seewhatbthinks)
					speak to
				*if (warprep_seewhatbthinks=false)
					tell
				${branbrinn_name} after you have finished.  Once that task is done, you will have time to think about such things.
				*if (showstats)
					*line_break
					(Archmage Cumari Relationship +5, General Vale Relationship +5, Lord Tovor Relationship +5, Army Morale +5 and Citizen Reputation +10)
				*set cumari_relationship +5
				*set vale_relationship +5
				*set tovor_relationship +5
				*set army_morale +5
				*set citizen_reputation +10
				*if (lover_exists=false)
					*goto Warprep_BreakChecks_Done
				
				That night, you break the news to ${lover_name}.  It is a sad and difficult conversation, but eventually, ${lover_heshe} understands why you must put the needs of the kingdom over your own.  You decide to not tell ${branbrinn_name} your decision just yet, wanting to put a little time between your relationships.
				*gosub Warprep_BreakUp
				*goto Warprep_BreakChecks_Done
				
				*label Warprep_BreakUp
				*if (lover_name=theothea_name)
					Thankfully, the big mountain-${theothea_manwoman} says that ${theothea_heshe} will continue to help you reunite Daria, although you can see the sadness in ${lover_hisher} eyes.
					*if (showstats)
						*line_break
						(${theothea_name} Relationship -10)
					*set theothea_relationship -10
				*if (lover_name=peterpetra_name)
					Thankfully, the cleric says that ${lover_heshe} will continue to help you reunite Daria, although you can see the sadness in ${lover_hisher} eyes.
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship -10)
					*set peterpetra_relationship -10
				*if (lover_name=gillgale_name)
					Thankfully, the rogue says that ${lover_heshe} will continue to help you reunite Daria, although you can see the sadness in ${lover_hisher} eyes.
					*if (showstats)
						*line_break
						(${gillgale_name} Relationship -10)
					*set gillgale_relationship -10
				*if (lover_name=karlkarla_name)
					Thankfully, the archer says that ${lover_heshe} will continue to help you reunite Daria, although you can see the sadness in ${lover_hisher} eyes.
					*if (showstats)
						*line_break
						(${karlkarla_name} Relationship -10)
					*set karlkarla_relationship -10
				*if (lover_name=jacejess_name)
					Thankfully, the Soulburner says that ${lover_heshe} will continue to help you reunite Daria, although you can see the sadness in ${lover_hisher} eyes.
					*if (showstats)
						*line_break
						(${jacejess_name} Relationship -10)
					*set jacejess_relationship -10
				*set theothea_lover false
				*set jacejess_lover false
				*set karlkarla_lover false
				*set peterpetra_lover false
				*set gillgale_lover false
				*set lover_exists false
				*set lover_name "None"
				*set friend1_lover false
				*set friend2_lover false
				*set friend3_lover false
				*set friend4_lover false
				*return
			*if ((lover_exists) and ((gender="female") and (warprep_b_suggested))) #Say, "Okay, I shall break up with ${lover_name} and allow ${branbrinn_name} to court me."
				*goto Break_And_Date_B
			*if ((lover_exists=false) and ((gender="male") and (warprep_b_suggested))) #Say, "Okay, I shall court ${branbrinn_name}."
				*goto Break_And_Date_B
			*if ((lover_exists=false) and (warprep_b_suggested)) #Say, "I'll see what ${branbrinn_name} thinks, but no promises."
				*set warprep_seewhatbthinks true
				*goto Break_And_Date_B
			*if ((lover_exists=false) and ((gender="female") and (warprep_b_suggested))) #Say, "Okay, I shall allow ${branbrinn_name} to court me."
				*goto Break_And_Date_B
			*if (warprep_b_suggested=false) #Ask, "If it's so important to you three, then maybe you should choose my consort?"
				The three men look away from you and don't answer your question.  Besides making it clear that they would like you to find someone other than ${lover_name}, they offer you no other suggestions.
				*goto Choose_Consort_loop
			#Say, "These are great matters of state, and of personal import to me.  Please, let me take a while to think about it."
				*goto More_Important_Than_Dating
			#Say, "Go away.  I shall not name anyone to be my Royal Consort."
				The three men seem nervous about your decision.
				*label More_Important_Than_Dating
				Your word is supreme, so they drop the issue and leave you to your dinner.
				*if (lover_exists)
					The next day, ${lover_name} brings up the subject at breakfast.  You aren't sure which of the three men spoke to ${lover_himher}, but ${lover_heshe} is not happy about the matter.
					
					"Your duty to your kingdom must come first," ${lover_name} says.  "We must part ways."
					*label Not_Name_Royal_Consort
					*if (lover_name=theothea_name)
						*if (showstats)
							*line_break
							(${theothea_name} Relationship -3)
						*set theothea_relationship -3
					*if (lover_name=peterpetra_name)
						*if (showstats)
							*line_break
							(${peterpetra_name} Relationship -3)
						*set peterpetra_relationship -3
					*if (lover_name=gillgale_name)
						*if (showstats)
							*line_break
							(${gillgale_name} Relationship -3)
						*set gillgale_relationship -3
					*if (lover_name=karlkarla_name)
						*if (showstats)
							*line_break
							(${karlkarla_name} Relationship -3)
						*set karlkarla_relationship -3
					*if (lover_name=jacejess_name)
						*if (showstats)
							*line_break
							(${jacejess_name} Relationship -3)
						*set jacejess_relationship -3
					*choice
						#Refuse to leave ${lover_name} and name ${lover_himher} to be your Royal Consort after all.
							${lover_name} seems reluctant at first, but after some thought, ${lover_heshe} agrees.  After breakfast, you find your councillors and deliver the news to them.
							
							*goto Warprep_NameLoverConsort
						#Say, "As you wish."
							*label End_Relationship
							*gosub Warprep_BreakUp
							*if (warprep_b_suggested)
								*choice
									#Now that you are single, tell the lords that you have changed your mind about Captain ${branbrinn_name}.
										*goto Break_And_Date_B
									#Refuse to name anyone your Royal Consort.
										You refuse to be forced into the decision, despite how angry it makes your advisers.
										*goto Warprep_ChoseNone
							*else 
								*goto Warprep_BreakChecks_Done
				*else
					*comment Single and chose no consort, but could have
					*label Warprep_ChoseNone
					*if (showstats)
						*line_break
						(Archmage Cumari Relationship -3, General Vale Relationship -3, Lord Tovor Relationship -3, Army Morale -3 and Citizen Reputation -5)
					*set cumari_relationship -3
					*set vale_relationship -3
					*set tovor_relationship -3
					*set army_morale -3
					*set citizen_reputation -5
					*gosub Check_Army_Stats
					*goto Warprep_BreakChecks_Done
	*else
		*comment No lover and doesn't like BranBrinn
		*goto Warprep_BreakChecks_Done
*else
	*goto Warprep_Check_ThirdBreak

*label Warprep_Check_ThirdBreak
*if ((warprep_teleport=3) and (warprep_thirdbreak_done=false))
	*set warprep_thirdbreak_done true
	*if (class_assassin>0)
		
		"Do you know of a garden in need of weeding?" a girl you haven't seen before asks you as you walk back from the army camps one day.
		
		The codewords from the Guild of Assassins haven't been spoken to you in some time.  It appears that they have made the connection to who you are now and who you were before.  The girl who speaks the words looks like a common street person.  She would go unnoticed just about anywhere.  Lady Emaline would have thoroughly approved of her disguise.
		*choice
			#Reply, "The garden is overgrown with weeds."
				"You have risen high," the girl says softly.  "The contract is for a sea captain.  The price is being paid by his crew.  I suppose this is a mutiny or something.  His name is Tyson Wells and he owns a ship called the Epiphany.  It's in the dockyard for the winter and his crew wants a new captain elected by spring, which means removing the current one.  Good luck, my ${princeprincess}.  The entire Guild is proud of you."
				*choice
					#Take the contract.
						*goto Assassin_Accept
					#Turn down the contract.
						You tell the girl that you won't be taking the contract.  She shrugs her shoulders at your decision.  She is just a messenger and the Guild will find someone else to kill the mark.
						*goto After_Warprep_ClassQuest
				*label Assassin_Accept
				That night, you go to the bars by the docks.  It's easy to find Captain Wells.  He has a room in one of the nicer dockside inns.  You put on a disguise and enter the common room.  The captain is very drunk and has a woman on each knee.  He sings loudly and sloshes a half-filled tankard of ale to-and-fro as he bounces the girls on his knees.  The girls don't seem to mind as they sing along just as loudly.
				*label Captain_loop
				*choice
					#Go outside and wait until the Epiphany's captain goes to bed.
						*label Wait_For_Bed
						The hours pass as you wait for the noises in the bar to quiet down.  Eventually, they do.  You wait a few more hours until you are certain that everyone is asleep.  You then go back into the bar and quietly stalk up the stairs.  You listen carefully at each door until you find one that is filled with the great rumbling snores that belong to the captain.
						*label Outside_Captain_loop
						*choice
							#Pick the lock and sneak in.
								*if (lockpickset=false)
									Unfortunately, you have no lockpicks.  The lock doesn't look particularly difficult, but without the correct tools, you have no chance of getting in.
									*if (showstats)
										(Needed Lockpick Set)
									*goto Outside_Captain_loop
								You take out your lockpicks and apply them to the door.
								*if ((devices>=50) and (stealth>=40))
									You have no trouble silently lifting the latch and opening the door.
									*if (showstats)
										*line_break
										(Devices +2 and Stealth +2)
									*set devices +2
									*set stealth +2
									
									The large captain is sound asleep in his bed and all alone.
									*label Fight_Sleeping_Cap
									*choice
										*if (dagger) #Cut the captain's throat with your dagger.
											*label Blade_Kill_Sleep_Cap
											The man never wakes up as his life's blood stains his pillow.  You silently leave the inn and nobody sees you go.
											*if (showstats)
												*line_break
												(Blades +2)
											*set blades +2
											*goto Captain_Dead
										*if (sword) #Cut the captain's throat with your sword.
											*goto Blade_Kill_Sleep_Cap
										#Strangle the captain to death.
											*if ((strength>=50) or (unarmed>=60))
												The captain startles awake at your touch, but you are already on top of him with your hands closed tightly around his throat.  You squeeze until he stops breathing and then squeeze a little more to be sure.
												*if (showstats)
													*line_break
													(Strength +1 and Unarmed +1)
												*set strength +1
												*set unarmed +1
												*goto Captain_Dead
											*else
												The captain startles awake at your touch and is much too strong to allow you to strangle him.  He grabs you by both hands and throws you off the bed.  Instead of fighting you further, he
												*gosub Failed_Assassination_blurb
												*if (showstats)
													(Needed 50 Strength or 60 Unarmed)
												*goto Warprep_loop
										#Make a noise so the captain wakes up.
											The captain startles awake at your deliberate noise.
											*goto Fight_Awake_Cap 
								*else
									*if (devices<50)
										You use every tool you own, but none of them manage to open the locked door.
										*if (showstats)
											(Needed 50 Devices)
										*goto Captain_loop
									You manage to lift the latch and open the door, but your actions are loud enough to wake the captain.  You see him sit up in his bed and look at you in surprise.  He is alone and very shocked to see you.
									*if (showstats)
										(Needed 40 Stealth)
										*line_break
										(Devices +2)
									*set devices +2
									*goto Fight_Awake_Cap
							#Knock down the door.
								*if (strength>=60)
									The door comes off its hinges as you put your weight behind it.  You see the captain sit up in his bed and look at you in surprise.  He is alone and very shocked to see you.
									*if (showstats)
										*line_break
										(Strength +2)
									*set strength +2
									*label Fight_Awake_Cap
									*choice
										*if (dagger) #Throw your dagger at the captain.
											*if (blades>=40)
												The dagger embeds itself in the captain's throat and the big man falls back into the bed.  You quickly retrieve your dagger and leave the inn before anyone sees you.
												*if (showstats)
													*line_break
													(Blades +2)
												*set blades +2
												*goto Captain_Dead
											*else
												The dagger embeds itself into the wall beside the captain.  The big man gets to his feet and jumps out the window!  He
												*gosub Failed_Assassination_blurb
												*if (showstats)
													(Needed 40 Blades)
												*goto Warprep_loop
										*if (sword) #Step forward and drive your sword into the captain's chest.
											*if (blades>=50)
												The long blade slides deeply into his body and the big man falls back into the bed.  You leave the inn before anyone sees you.
												*if (showstats)
													*line_break
													(Blades +2)
												*set blades +2
												*goto Captain_Dead
											*else
												The big man moves much quicker than you anticipate as your sword drives into the mattress where he had been lying.  He
												*gosub Failed_Assassination_blurb
												*if (showstats)
													(Needed 50 Blades)
												*goto Warprep_loop
										*if (bow) #Shoot the captain with an arrow.
											*if (archery>=60)
												The arrow punches right through his throat and the big man falls back into the bed.  You leave the inn before anyone sees you.
												*if (showstats)
													*line_break
													(Archery +2)
												*set archery +2
												*goto Captain_Dead
											*else
												The big man moves much quicker than you anticipate as your arrow sticks into the mattress where he had been lying.  He
												*gosub Failed_Assassination_blurb
												*if (showstats)
													(Needed 60 Archery)
												*goto Warprep_loop
										#Cast a lightning bolt at the captain.
											The big man wastes no time as he gets to his feet and rushes to the window.  Your incantation
											*if (magic>=85)
												almost doesn't finish in time.  The lightning strikes him in the back and throws him out the window face first, killing him twice as well as you needed to.  You leave the inn before anyone sees you.
												*if (showstats)
													*line_break
													(Magic +2)
												*set magic +2
												*goto Captain_Dead
											*else
												is a second too slow as he jumps to the street below.  Your lightning shoots harmlessly out the window into the night air, missing him entirely.  You realize belatedly that you needed something faster than magic to deal with this mark.  Captain Wells takes the failed assassination attempt seriously and leaves Brightwater for the winter to visit an old friend.  Unfortunately, you are unable to fulfill the contract.
												*if (showstats)
													(Needed 85 Magic)
												*goto Warprep_loop
										#Jump onto the captain and strangle him.
											*if (unarmed>=80)
												It is not an easy task to strangle such a large man.  He tries to fight back, but you manage to hold his throat closed until he stops breathing.  After the deed is done, you leave the inn before anyone sees you.
												*if (showstats)
													*line_break
													(Unarmed +2)
												*set unarmed +2
												*goto Captain_Dead
											*else
												The captain is much too strong to allow you to strangle him.  He grabs you by both hands and throws you off the bed.  Instead of fighting you further, he
												*gosub Failed_Assassination_blurb
												*if (showstats)
													(Needed 80 Unarmed)
												*goto Warprep_loop
										#Say, "Your crew is trying to murder you.  You better get out of town."
											Captain Wells looks at you, but due to your disguise, he can't tell who you are.  He wastes no time in deciding whether you are telling the truth or not.  Instead, he jumps out the window and disappears into the night.  He takes your words seriously and 
											*label Told_Captain
											leaves Brightwater for the winter to visit an old friend.  You know that if the Guild finds out what you have done, you will be killed.  Needless to say, you don't get paid for the supposedly botched contract.
											*if (showstats)
												(Good +15)
												*set good +15
											*goto Warprep_loop
								*else
									You smash into the door a few times, but it holds solid.  You hear many doors open at once and barely get out of the inn in time.  You learn that the captain got scared by the intrusion and left Brightwater for the winter to visit an old friend.  Unfortunately, you are unable to fulfill the contract by spring.
									*if (showstats)
										(Needed 60 Strength)
									*goto Warprep_loop
							#Change your mind and let the captain live.
								You leave the inn and return to your room at the keep.
								*goto Give_Up_Captain
						*label Failed_Assassination_blurb
						gets to his feet and jumps out the window!  Captain Wells takes the failed assassination attempt seriously and leaves Brightwater for the winter to visit an old friend.  Unfortunately, you are unable to fulfill the contract.
						*return
					*if (gender="female") #Push one of the girls off the captain's knee and take her place.
						The girl falls to the wooden floor and the captain turns to look at you.
						*if (charm>=50)
							He smiles at you and gives you a bounce to show that he likes your spirit.
							*if (showstats)
								*line_break
								(Charm +3)
							*set charm +3
							*choice
								#Slip a pinch of poison into the captain's drink.
									You manage to slip the powder into his drink while he is touching the other girl's bottom.
									*goto Poison_Cap
								#Try to convince the captain to take you to his room.
									It doesn't take very much convincing when he learns that a woman is willing to go to bed with him for free.  He loudly announces to everyone that he is tired, takes you by the hand and drags you upstairs.  Captain Wells gets into the bed and pats the space beside him.
									*choice
										#Sleep with the captain and wait for him to fall asleep.
											The captain is a bold and brash lover.  It takes only a few minutes and then he is sound asleep next to you.
											*set virgin false
											*goto Fight_Sleeping_Cap
										#Attack the captain.
											*goto Fight_Awake_Cap
								#Change your mind and leave the bar.
									The captain raises his hands in confusion as you leave him with the other girl.  He laughs and reaches for the girl you pushed off his lap, but she slaps his hand away.  You leave the inn and return to your room at the keep.
									*goto Give_Up_Captain
						*else
							He laughs at your spunk and then sets you down on your feet as he reaches for the girl who fell down.  The bouncers escort you outside as the girl whom you knocked over gives you a smug look.
							*if (showstats)
								(Needed 50 Charm)
							*goto Outside_Bar
					#Push the captain off his chair and shout, "Stay away from my girl!"
						The captain falls to the ground and the two girls on his lap fall with him.  He quickly gets to his feet and puffs out his chest.  You see his large fist coming for your face
						*if ((unarmed>=40) and (agility>=40))
							and easily duck under the powerful haymaker.  The captain is a brawler and is used to such surprises.  He raises his fists to cover his face and grins at you through missing teeth.
							*if (showstats)
								*line_break
								(Agility +2 and Unarmed +2)
							*set agility +2
							*set unarmed +2
							*choice
								*if (dagger) #Draw your dagger.
									*goto Brawl_weapon
								*if (sword) #Draw your sword.
									*goto Brawl_weapon
								*if (bow) #Draw your bow.
									*label Brawl_weapon
									"No weapons!" the bouncers shout as you feel a heavy club over the back of your head.
									*if (showstats)
										*line_break
										(Health -10 to ${health} / 100)
									*set health -10
									
									You are thrown out into the street to nurse your wounds and the bouncers won't let you back in.
									*goto Outside_Bar
								#Cast a spell to make your hands as hard as iron.
									"No magic!" the bouncers shout as you feel a heavy club over the back of your head.
									
									You are thrown out into the street to nurse your wounds and the bouncers won't let you back in.
									*goto Outside_Bar
								#Attempt to kill the captain and make it look like an accident.
									*if (unarmed<40)
										The captain laughs at your attempts to fight him, but he is clearly more talented than you.  You feel his fists strike you more than once and soon you fall to the ground.  The bouncers throw you out of the tavern and refuse to let you back in.
										*set health -30
										*if (showstats)
											(Needed 70 Unarmed)
											*line_break
											(Health -30 to ${health} / 100)
										*goto Outside_Bar
									*if (unarmed<70)
										You manage to keep the captain's fists away from your face and deliver a few good punches yourself.  Unfortunately, once you have beaten the captain to the floor, the bouncers pull you off before you can kill him.  They throw you out for taking the fight too far and refuse to let you back in.
										*if (showstats)
											(Needed 70 Unarmed)
										*goto Outside_Bar
									You dance away from the captain's fists, and when you have a clear opening, you strike him solidly in the throat.  He grabs his neck as he unsuccessfully tries to soothe his crushed windpipe.  The tavern keeper tells one of the bouncers to fetch a cleric, but you know that they won't get there in time.  You slip away in the chaos and the captain's death is attributed to a bar fight accident.
									*if (showstats)
										*line_break
										(Unarmed +2)
									*set unarmed +2
									*goto Captain_Dead
						*else
							and then nothing but black.  The captain is clearly a bar-room brawler and followed the two key rules for such fights:  Strike first and strike hard.  You wake up outside the bar with a bloody nose.  The two bouncers now standing by the door make it clear that they will not allow you to come back in.
							*set health -20
							*if (showstats)
								(Needed 40 Agility and 40 Unarmed)
								*line_break
								(Health -20 to ${health} / 100)
							*label Outside_Bar
							
							You don't have any other options except to wait for the captain to go to bed.
							*goto Wait_For_Bed
					#Silently watch from a dark corner of the bar.
						*if (stealth>=40)
							It's easy to remain unnoticed in the bar as the captain continues to make a grand fool of himself.  You watch as he drinks and banters with the ladies.  After about an hour, he announces that he must "empty some bilge water".  He lets the two girls off his knees and goes through a small door at the back of the tavern which leads to the privy.
							*if (showstats)
								*line_break
								(Stealth +3)
							*set stealth +3
							*choice
								#Place a pinch of poison into his unwatched drink.
									You slip the powder into his drink and return to your seat without being seen.
									*label Poison_Cap
									The poison magnifies the effects of the alcohol he has consumed and after a few minutes, he falls to the ground unconscious.  He then begins to vomit and choke.  The bartender is quick to roll him over and try to save him, thinking that it is simply another night of work.
									*if (nature>=50)
										Instead, Captain Wells dies on the dirty floor and everyone thinks that it is alcohol poisoning.  You leave the bar and nobody remembers you were even there.
										*if (showstats)
											*line_break
											(Nature +3)
										*set nature +3
										*goto Captain_Dead
									*else
										The captain must have vomited up enough of your poison, because to your dismay, he doesn't die.  He must also have become suspicious because he leaves Brightwater that night and spends the rest of the winter with a friend.  Unfortunately, you are unable to fulfill the contract in the allotted time.
										*if (showstats)
											(Needed 50 Nature)
										*goto Warprep_loop
								#Follow the captain into the privy.
									You step into the small smelly room after Captain Wells.  The big man doesn't even bother to turn around as he unties his trousers and begins to urinate into the hole in the floor while whistling a sea shanty.
									*choice
										*if ((dagger) or (sword)) #Stab the captain in the back.
											Your blade easily finds its mark and the captain falls to the ground dead.  You clean your blade on his clothes and leave the tavern before anyone knows that it is you.
											*if (showstats)
												*line_break
												(Blades +2)
											*set blades +2
											*goto Captain_Dead
										#Grab the captain by the back of the head and smash his face into the brick wall.
											*if ((unarmed>=40) or (strength>=40))
												It only takes one good smack to crack the captain's head open.  He falls to the ground and you see the grey jelly of his brains oozing out of his split skull.  You silently leave the tavern before anyone knows that it is you.
												*if (showstats)
													*line_break
													(Unarmed +2)
												*set unarmed +2
												*goto Captain_Dead
											*else
												You hit the captain's head off the wall, but instead of going unconscious, he turns around and pushes you to the floor.  He then runs over your body and out the front door of the tavern while holding his trousers up with one hand.  When you come out, the bouncers escort you out of the tavern, thinking that you are simply another drunk and started a fight for no reason.						
												*if (showstats)
													(Needed 40 Unarmed or 40 Strength)
												*goto Outside_Bar
										#Say, "Your crew has hired me to kill you."
											The captain turns around and gives you a solid push as he runs past you.  He doesn't stop to hear anything more that you may have to say as he rushes out of the bar.  He must have believed you, because he
											*goto Told_Captain
						*else
							You try to remain unnoticed in the corner of the bar, but it isn't as easy as you think.  Many of the servers continuously call out to you, asking if you would like a drink or a dance.  You realize that they think you are shy or sad as they try to "bring you out of your shell."  Captain Wells notices you and keeps a close eye on you, spoiling your immediate plans.
							*if (showstats)
								(Needed 40 Stealth)
							*goto Captain_loop
					#Change your mind and don't kill the captain.
						*label Give_Up_Captain
						You don't know if the Guild eventually gives the contract out to another operator or not, but you don't collect the bounty.  The Guild doesn't speak to you about it, assuming that you just never found an opportune moment to do the deed.
						*goto Warprep_loop
			#Reply, "I don't do that any more."
				"The weeds never stop growing," the girl replies quietly.  "Once a gardener, always a gardener."
				*label Assassin_GivesUp
				
				She slips away as quickly as she appeared…just another face in the crowd.  She is right, of course.  Membership in the Guild of Assassins is a lifetime commitment.  Just because you don't want to take a contract today doesn't mean that they won't offer you one tomorrow.  You continue on to your rooms in the keep, pulling your clothes tighter around you to ward off the cold weather.
				*goto Warprep_loop
			#Reply, "I'm too busy right now."
				"The weeds never stop growing," the girl replies quietly.
				*goto Assassin_GivesUp
		*label Captain_Dead
		*set assassin_killed_captain true
		
		An older man with grey hair drops by the keep a few days later with your reward for killing Captain Wells.
		*if (showstats)
			(Gold +350)
		*set gold +350
		*set assassin_kills +1
		*goto Warprep_loop
	*if (class_bard>0)
		
		It isn't long before your fans ask you to start performing for them on a regular basis.  Unfortunately, you just don't have the time.  Braydon Summers, a well-known businessman, comes to you with an idea.
		
		"Let me organize an enormous show during the Midwinter Festival for you," he suggests.  "I have access to many merchants and I'd be happy to put together the entire event for a share of the proceeds."
		*temp patron "None"
		*choice
			#Accept Braydon's proposal.
				*label Find_Merchant_Concert
				*set patron "merchant"
				Braydon really does know his business.  He rents a very large warehouse and hires several taverns' worth of servers.  The amount of ale and food brought in for the event is staggering.  The advertisements are posted all over Brightwater and many heralds are hired to spread the word.
				*goto The_Show
			#Organize the event yourself.
				Braydon wishes you luck as you forego his expertise.  You start by using your own keep, which is much larger than any tavern.  You ask Samuel, your Head Steward, to staff the event, but he says no, because it isn't official business.  He then says that he could pass the word to the servants in case any of them would like to make some extra money.  You realize that you will need to invest your own money and that you have no guarantee that you will make any of it back.
				*choice
					*selectable_if (gold>=350) #Pay 350 gold to pay for the servants and buy some refreshments to sell.  (Needs 350 Gold)
						*set patron "self"
						You also hire some heralds to spread the word of your event.  Many kegs of drink and tables of food are brought into the keep and managed by the servants you have hired.
						*if (showstats)
							*line_break
							(Gold -350)
						*set gold -350
						*goto The_Show
					#Change your mind and find the merchant.
						*goto Find_Merchant_Concert
					#Change your mind and cancel the concert.
						Samuel nods in understanding, content that you are focusing your attention on your duties and not your "hobbies" as he says.  
						*goto No_Concert
			#Decide to not have a concert.
				*label No_Concert
				Your fans are saddened by the news, but you tell them that your kingdom comes first.
				*if (showstats)
					*line_break
					(Citizen Reputation +5)
				*set citizen_reputation +5
				*goto After_Warprep_ClassQuest
		*label The_Show
		
		When news of the event spreads, you hear some citizens discussing the concert in the street.  They are sad that they can't afford to go.  It gives you an idea.
		*choice
			#Declare that the event will be non-profit and that everyone may attend for free.
				*set charity_event true
				*if (patron="merchant")
					"What is this?" Braydon says the moment he hears.  "This is not what we agreed to.  This is my livelihood and I need to be paid.  Besides, you signed a contract."
					*choice
						*selectable_if (gold>=350) #Pay Braydon for the breach of contract.  (Needs 350 Gold)
							Braydon seems content with the money and continues to work for you.  In a way, he is even happier since he will make his profit regardless of whether the event is successful or not.
							*if (showstats)
								*line_break
								(Gold -350)
							*set gold -350
							*goto The_Show_2
						#Change your mind about making the event free.
							Braydon is happy that things are back to normal.
							*set charity_event false
							*goto The_Show_2
				When word spreads that the event will be free, the citizens of Brightwater become very excited.
				*goto The_Show_2
			#Give out a few free tickets and proceed as normal.
				*if (patron="merchant")
					Braydon doesn't mind that you have given out a few complimentary tickets and also invites some of his friends to attend without having to pay.
				The people whom you give the tickets to are very happy with your generosity.
				*if (showstats)
					*line_break
					(Citizen Reputation +3)
				*set citizen_reputation +3
				*goto The_Show_2
			#Don't change anything.
				*goto The_Show_2_ns

		*label The_Show_2
		
		*label The_Show_2_ns
		*if (charity_event=false)
			The ticket sales go very well.
		*if (charity_event)
			The excitement surrounding the event is very high.
		You know that part of this is due to your standing as ${princeprincess}, but you also know that people want to see the famous bard perform.
		*if (charity_event)
			The fact that it's free doesn't hurt either.
		You soon realize that this will easily be the largest show you have ever been a part of!
		
		On the day of the big event you stand behind the curtain, listening as the crowd enters.  You know that many of your friends will be in the audience.  You mount the stage
		*if (lute)
			with your lute in your hand.
		*if (lute=false)
			realizing that you don't have a lute!  This nearly ends the night early except that
			*if (patron="self")
				one of the servants rushes to her room and brings you a battered old instrument.  It doesn't look pretty, but it has a nice sound.
			*if (patron="merchant")
				Braydon had already purchased a backup lute in case yours broke.  He didn't know that you didn't even have one, but he happily gives it to you so you can play.
			*if (showstats)
				*line_break
				(Gained a Lute)
			*set lute true
		
		You watch the curtains draw back and feel the hush fall over your audience.  You see ${friend1_name},
		*if (friend2_exists)
			${friend2_name},
		${friend3_name} and Captain ${branbrinn_name} in the crowd.  It is every bit as large as you had suspected.  Amos, your foster father, would be immensely proud of you today.
		*choice
			#Play a slow emotional song to begin.
				The crowd is silent as you play and sing.  The song is full of feelings and quickly captures the audience's attention.
				*goto The_Show_3
			#Introduce your show with some words.
				You say a few words about yourself and about the places you've played.  This warms up the audience and makes them very receptive to what you will do next.
				*goto The_Show_3
			#Play a well-known fast song to begin.
				The fast song immediately pumps up your audience and gets their attention.
				*goto The_Show_3
		
		*label The_Show_3
		You see that the staff is serving a lot of drinks and food as the crowd hangs off of your every word.  You go through the song selection you have prepared.  They listen intently and eagerly applaud at the end of each piece.  You know that it's a good show and that you are making a real name for yourself.  You also know that if you only play other people's songs, you will never find a place in bardic history.  Clearing your throat, you begin to play some of your own music.
		*choice
			#Your songs are mostly light-hearted and fun.
				The crowd laughs along as you play.
				*goto The_Show_4
			#Your songs are mostly sad and depressing.
				The crowd weeps openly as you play.
				*goto The_Show_4
			#Your songs are mostly great epic ballads, filled with history and battles.
				The crowd listens in awe as you play.
				*goto The_Show_4
			#Your songs are mostly about romance and love.
				The crowd has sappy smiles on their faces as you play.
				*goto The_Show_4
		
		*label The_Show_4
		The night goes very well as you become more relaxed and comfortable.
		*if (lover_exists)
			At the end of your last song, ${lover_name} throws a bouquet of flowers onto the stage.
			*if (lover_name=theothea_name)
				You see your large mountain-${theothea_manwoman} blushing as ${theothea_heshe} does it.
			*if (lover_name=gillgale_name)
				$!{gillgale_heshe} gives a flourishing bow of ${gillgale_hisher} own as ${gillgale_heshe} leaves the stage.
			*if ((lover_name=peterpetra_name) or (lover_name=branbrinn_name))
				$!{lover_heshe} gives you a nod of respect before returning to ${lover_hisher} seat.
			*if (lover_name=karlkarla_name)
				You can see your shy archer blushing as ${lover_heshe} does it.
			*if (lover_name=jacejess_name)
				You see the Soulburner glaring at the audience members as ${lover_heshe} returns to ${lover_hisher} seat.
		When it's over, the crowd
		*temp concert_take 0
		*if (class_bard=1)
			leaves with content expressions on their faces, but it's unlikely that your songs will be sung across the continent as you had hoped.  They are happy with your performance and nobody asks for their money back.
			*if (charity_event)
				*if (showstats)
					(Needed More Bardic Training for Greater Bonus)
					*line_break
					(Citizen Reputation +10)
				*set citizen_reputation +10
				*goto After_Warprep_ClassQuest
			*if (patron="self")
				At least you get to keep all of the proceeds for yourself, although you can't help but notice that you have lost money on the event.
				*set concert_take 300
			*if (patron="merchant")
				Your merchant patron takes his cut and thanks you for your time, happily giving you your share.
				*set concert_take 50
		*if (class_bard=2)
			leaves singing your songs.  They are very happy with your performance and you can tell that your songs will be sung across the continent as you achieve true fame.
			*if (charity_event)
				*if (showstats)
					(Needed More Bardic Training for Greater Bonus)
					*line_break
					(Citizen Reputation +15)
				*set citizen_reputation +15
				*goto After_Warprep_ClassQuest
			*if (patron="self")
				Your servants send the proceeds from the concert to your room.
				*set concert_take 450
			*if (patron="merchant")
				Your merchant patron takes his cut and thanks you for your time, happily giving you your share.
				*set concert_take 100
		*if (class_bard=3)
			is almost rioting from excitement.  They are screaming and yelling after your epic performance and you know that many of the songs you sang tonight will be sung for the rest of history.
			*if (charity_event)
				*if (showstats)
					*line_break
					(Citizen Reputation +25)
				*set citizen_reputation +25
				*goto After_Warprep_ClassQuest
			*if (patron="self")
				Your servants send the proceeds from the concert to your room.
				*set concert_take 550
			*if (patron="merchant")
				Your merchant patron takes his cut and thanks you for your time, happily giving you your share.
				*set concert_take 150
			*if (showstats)
				*line_break
				(Gold +${concert_take})
			*set gold +concert_take
			*goto After_Warprep_ClassQuest
		*if (showstats)
			(Needed More Bardic Training for Greater Bonus)
			*line_break
			(Gold +${concert_take})
		*set gold +concert_take
		*goto After_Warprep_ClassQuest
	*if (class_knight>0)
		
		You are training with the soldiers when a group of people start yelling.  To your surprise, they are all calling for you.  After you finally calm them down enough to hear what they have to say, you learn that they all wish to become your personal squire.  As a knight of the realm, and the ${princeprincess} too, you have a large group of candidates to choose from.  The successful candidate will be responsible for grooming your horse, sharpening your sword and helping you into your armour.  In return, you are expected to vouch for them in their own pursuit to become a knight, if they prove worthy.  After some discussion and research, you have narrowed the group to four choices.
		*label Consider_Squire_loop
		*choice
			*allow_reuse #Consider a young peasant boy named Remus.
				*comment honest, needs equip
				Remus is in good physical condition and is of excellent moral character.  Unfortunately, he is not the smartest of lads, but he is earnest.  As a peasant, he also doesn't have very much money, so his equipment is shabby and in need of repair.
				*set squire_name "Remus"
				*set squire_hisher "his"
				*set squire_heshe "he"
				*set squire_himher "him"
				*set squire_equipped false
				*label Choose_Squire
				*choice
					#Choose ${squire_name} to be your squire.
						*goto Chose_Squire
					*allow_reuse #Consider someone else.
						${squire_name} remains with the others, hoping you will choose ${squire_himher}.
						*goto Consider_Squire_loop
			*allow_reuse #Consider a noble girl named Marla.
				*comment dishonest, has equip
				Marla comes from a good family and her equipment is in excellent condition.  When you speak to her, you quickly see that she wishes to become a knight in order to gain further prestige and power over others.  Her skills are lacking and her attitude is terrible.
				*set squire_name "Marla"
				*set squire_hisher "her"
				*set squire_heshe "she"
				*set squire_himher "her"
				*set squire_equipped true
				*goto Choose_Squire
			*allow_reuse #Consider an old ex-priest named Gordon.
				*comment dishonest, has equip
				Gordon is long past his prime, but his life's ambition is to become a knight before he dies.  He is an ex-priest of Lucien, having left the order due to several indiscretions and poor decisions.  His morals are uncertain, but his equipment is functional and serviceable. You do wonder though if he'll ever have the strength to swing a sword properly.
				*set squire_name "Gordon"
				*set squire_hisher "his"
				*set squire_heshe "he"
				*set squire_himher "him"
				*set squire_equipped true
				*goto Choose_Squire
			*allow_reuse #Consider a merchant's daughter named Raquel.
				*comment honest, needs equip
				Raquel has old second-hand equipment that she likely found in a scrap heap because her parents don't want her to become a knight.  She seems like a nice girl, although she appears timid and shy at times.  She has no skills in battle, but understands the concepts of weaponry and armoury from selling them in her parents' store.
				*set squire_name "Raquel"
				*set squire_hisher "her"
				*set squire_heshe "she"
				*set squire_himher "her"
				*set squire_equipped false
				*goto Choose_Squire
			#Choose nobody.
				Taking on a squire is a lot of work.  You decide to not bother with the task since you have so much to do as it is.
				*set squire_name "None"
				*set squire_hisher "None"
				*set squire_heshe "None"
				*set squire_himher "None"
				*goto After_Warprep_ClassQuest
		
		*label Chose_Squire
		${squire_name} is very excited that you have chosen ${squire_himher}.
		*if (squire_equipped=false)
			You look over ${squire_hisher} equipment and realize that it needs some work.
			*choice
				*selectable_if (gold>=200) #Buy ${squire_name} new armour, a shield, a sword and a horse.  (Needs 200 gold)
					${squire_name}'s equipment was in sore need of replacement.  With better equipment, you feel more secure in taking ${squire_himher} to war with you.
					*if (showstats)
						*line_break
						(Gold -200)
					*set gold -200
					*set squire_equipped true
					
					*goto Chose_Squire_2
				#Let your squire find ${squire_hisher} own equipment.
					Sir Maxson, your own patron knight, never gave you all of the equipment you needed.  It's true that Sir Grady helped you out, but that was more because he was your foster father than out of his duties as a knight.
					*goto Chose_Squire_2
		*else
			*goto Chose_Squire_2
		
		*label Chose_Squire_2
		You watch ${squire_name} swing ${squire_hisher} sword as ${squire_heshe} works with the other squires.  You can see a lot of room for improvement, but helping ${squire_himher} yourself would cut into your own training time.
		*choice
			#Train your squire.
				You teach ${squire_name} the proper forms of swordplay as well as how to sit correctly on a horse.  You sometimes wonder if a squad commander in your army would be just as good, but you know that your squire is your duty, so you train ${squire_himher} the best you can, even though you know that you should be working on your own skills.
				*set squire_trained true
				*goto After_Warprep_ClassQuest
			#Let your squire train with the others and concentrate on your own skills.
				You have a war to win and you know that your skills must be in top shape.  You don't have time to play nursemaid to a lowly squire.  You concentrate on your weaponry every day as you become the best knight you can be.
				*if (showstats)
					*line_break
					(Strength +2, Endurance +2, Agility +2, Blades +2 and Archery +2)
				*set strength +2
				*set endurance +2
				*set agility +2
				*set blades +2
				*set archery +2
				*set squire_trained false
				*goto After_Warprep_ClassQuest
	*if (class_monk>0)
		
		Life as a monk is often contradictory and odd.  You are expected to shun worldly possessions to focus on self-improvement, but as the ${princeprincess} of the realm, you are expected to have the finest equipment in order to fulfill your duties.  Sister Geri had spoken often of these paradoxes.  You sit upon a frozen tower that overlooks the wintry landscape.  Your breath is slow and your heart beats even slower as you meditate upon your life.
		
		*if (good>=50)
			Suddenly, a large clump of snow dislodges itself from the tower's flag and falls beside you.  In the middle of the fluffy whiteness, you see an old raven's nest and in the raven's nest, you see the glitter of gold.  The bird had likely picked up the shiny pieces and stored them and now, through a remarkable coincidence, the money has fallen at your feet.
			*if (showstats)
				*line_break
				(Gold +40)
			*set gold +40
			*goto Karma_1
		*else
			Suddenly, a large clump of snow dislodges itself from the tower's flag and falls down upon you.  Through a remarkable coincidence, it strikes your money pouch
			*if (gold>=30)
				and a few gold coins are lost into the snow far below.
				*if (showstats)
					*line_break
					(Gold -30)
				*set gold -30
				*goto Karma_1
			*if (gold>0)
				and your last remaining coins are lost into the snow far below.
				*if (showstats)
					*line_break
					(Gold -${gold})
				*set gold 0
				*goto Karma_1
			and tears the empty bag open.  You will need to mend it tonight.
			*goto Karma_1
		*label Karma_1
		
		You stand up from your meditation and make your way down the tower.  The icy stairs are very dangerous and before you know it, your feet have slid out from under you!
		*if (good>=50)
			Amazingly, you do a complete flip in midair and land unharmed on your bottom.  You shake your head in amazement and get back to your feet.  You didn't move a muscle—the lucky fall had happened all on its own.
			*goto Karma_2
		*else
			You grab for the railing, but find it missing.  You tumble down the stairs, gathering dozens of bruises and scrapes.  You get back to your feet and look behind you.  The railing is in good repair through the entire tower, but one section is missing…right where you needed it.  It is more bad luck.
			*goto Karma_2
		
		*label Karma_2
		You had a meeting with Lord Tovor concerning a new wheat vendor.
		*choice
			#Continue to the meeting.
				You arrive at the clerk's office and see that he has several bags of sample product in front of him as he judges the quality of each grain compared to its price.
				
				"Good morning," he says.  "This one isn't quite as fresh and plump as the others, but the price is very good and the quality's not so bad…."
				
				He holds up a bag of grain for you to inspect.
				*if (good>=50)
					As the food settles, you see the glint of another gold coin.  You pull it out and look up at Tovor.
					*if (showstats)
						*line_break
						(Gold +1)
					*set gold +1
					
					"Looks like it's your lucky day," he says with a smile.  "Must have fallen out of the farmer's pocket when he was gathering the grain."
					*goto Karma_3
				*else
					As the food settles, you see a glint of yellow which suddenly flies upward and stings you on the tip of your nose!
					
					"I am so sorry," Lord Tovor says.  "It's a bee-weevil.  Harmless, but painful.  Looks like it's your unlucky day."
					*goto Karma_3
			#Cancel the meeting and go to your room.
				You open the door to your room and
				*if (good>=50)
					see a brass chandelier fall to the ground just inches from your toes!  Two servants are replacing the candles and nearly dropped it on your head.
					
					"I am so sorry, Your Highness," one of the servants says.  "That almost landed on you.  Looks like today is your lucky day!"
					*goto Karma_3
				*else
					place your foot directly into a bucket of dirty water that a servant had left out.
					
					"I am so sorry, Your Highness!" the servant says from the other side of the room where he is mopping the floor.  "Looks like it's your unlucky day."
					*goto Karma_3
		
		*label Karma_3
		
		You are more attuned to the universe than most people and you know that luck is merely a symptom of your karmic alignment.  The fact that so many strange things are occurring at once tells you that these are no mere accidents.
		*choice
			#Go to a monastery in the city to ask for help.
				You leave without another word, wishing that Sister Geri was still alive to consult with.  The most enlightened monk in the monastery agrees that something special is happening to you.  He tells you that you are experiencing a Harmonic Wave.  He says that these rare events occur when the universe makes a course correction and that most people merely attribute the coincidences to good or bad luck.  He tells you to be careful, but offers you no solid advice.
				*if (showstats)
					*line_break
					(Religion +3)
				*set religion +3
				*goto Karma_4
			#Go to the library and look up help.
				You leave without another word, wishing that Sister Geri was still alive to consult with.  You consult many books until you find something that tells you what is happening.  The tome refers to something called a Harmonic Wave.  It says that these rare events occur when the universe makes a course correction and that most people merely attribute the coincidences to good or bad luck.
				*if (showstats)
					*line_break
					(Arcana +3)
				*set arcana +3
				*goto Karma_4
		
		*label Karma_4
		*choice
			#Meditate upon your situation.
				*if (class_monk=3)
					The answer seems to float up from nothingness.
					*goto Karma_5
				*else
					You consider the implications of what a Harmonic Wave could do and what the proper response to it would be.  Unfortunately, you come up with no clear ideas.
					*if (showstats)
						(Needed Level 3 Monk)
					*goto Karma_4
			#Analyze your day so far.
				*if (perception>=75)
					*if (good>=50)
						The money, the safe fall…it's clear that good things have been happening to you, so the answer is self evident.
						*goto Karma_5
					*else
						The loss of money, the missing rail…it's clear that evil things have been happening to you, so the answer is self evident.
						*goto Karma_5
				*else
					So many odd coincidences with no particular pattern.  You don't see it yet.
					*if (showstats)
						(Needed 75 Perception)
					*goto Karma_4
			#Consider what you know from history.
				*if (history>=75)
					You recall that quite often historical figures rose to greatness after a selfless act while others fell to disgrace after doing something inherently evil.  The answer suddenly seems clear.
					*goto Karma_5
				*else
					You can't think of any stories about tripping down stairs or snow falling from towers.  Perhaps the answer isn't in a history book after all.
					*if (showstats)
						(Needed 75 History)
					*goto Karma_4
			#Consider what is happening from a magical perspective.
				*if (arcana>=75)
					It is simply a mathematical equation.  If the universe needs to balance itself, and you have acted in a particular way, then the universe will have to react accordingly.  The answer suddenly seems clear.
					*goto Karma_5
				*else
					The amount of energy that the universe itself could apply to correct the Harmonic Balance would be enormous and impossible to harness, using conventional spells.  There must be another way.
					*goto Karma_4
			#Give up trying to figure out what is happening.
				Sometimes the universe is simply too complex and enormous to understand.
				*if (good>=50)
					You have a very lucky day as you find coins all over the place, the cooks prepare your favourite meal and your warm beverages stay warm until you finish drinking them.  The next day, things are back to normal.  Your great day makes you happy and easy to be around which makes everyone else happy as well.
					*if (showstats)
						*line_break
						(Gold +87, Charm +3, Citizen Reputation +3 and Army Morale +3)
					*set gold +87
					*set charm +3
					*set citizen_reputation +3
					*set army_morale +3
					*goto After_Warprep_ClassQuest
				*else
					You have a very unlucky day as a chair breaks under you, your bed gets lice, your dinner is accidentally burned and countless other small mishaps befall you.  You are miserable by the end of it and everyone is walking on eggshells around you.  The next day, things are back to normal.  Your terrible day makes everyone work extra hard so they escape your attention and bad mood.
					*if (showstats)
						*line_break
						(Army Power +3)
					*set army_power +3
					*goto After_Warprep_ClassQuest
					
		*label Karma_5
		*if (good>=50)
			You have done some good in the world, so the balance would be for something good to now happen to you.
			*goto Karma_6
		*else
			You have done some evil in the world, so the balance would be for something evil to now happen to you.
		
		*label Karma_6
		This may be a once in a lifetime opportunity to amplify this surge of essence to your own benefit.  But, it could also be dangerous, to try to harness such energies.
		*choice
			#You try to focus the Harmonic Wave into your inner being.
				You cancel all of your appointments for the remainder of the day.  You can feel the universe pushing at you as it attempts to correct the unbalance.  Random acts of
				*if (good>=50)
					goodness
				*if (good<50)
					evil
				radiate toward you, but instead of allowing them to unfold in small coincidental ways, you hold on to them.  You push all of the feelings they bring into the void as you hold yourself apart from the very universe itself.  Like a single rock in the ocean, the waves batter you.  You lose all sense of time as an insurmountable force cascades over you.  You awake the next morning and things are back to normal.  The Harmonic Wave is over and you feel stronger than ever.
				*if (showstats)
					*line_break
					(Lost all Good and Evil, Strength +7, Agility +7 and Endurance +7)
				*set good 50
				*set strength +7
				*set agility +7
				*set endurance +7
				*goto After_Warprep_ClassQuest
			#You decide to let the universe balance itself and be at peace with what fate brings you.
				Perhaps this is one of the Great Problems that the oldest monks are faced with?  To allow the power to wash over you, knowing you could change it, instead of trying to force things to happen the way they wish.  You cancel the rest of your appointments for the day and meditate upon the changes that the Wave may bring.  It lasts for a single day and afterwards, things are back to normal.
				*if (showstats)
					*line_break
					(Perception +10, Arcana +5, History +5 and Magic +5)
				*set perception +10
				*set arcana +5
				*set history +5
				*set magic +5
				*goto After_Warprep_ClassQuest
	*else
		*goto After_Warprep_ClassQuest

	*label After_Warprep_ClassQuest
	*set warprep_uddodead true
	
	Travelling across Daria and the other duchies is nearly impossible due to the heavy winter storms that are common at this time of year.  Despite this,
	*if (warprep_spies="Tornassa")
		your spies in Tornassa bring back vital information
	*if (warprep_spies!="Tornassa")
		news from Tornassa reaches Brightwater
	anyway.  Duke Uddo is dead.  Rumour claims that you sent an assassin to kill Duke Uddo and Duchess Selina in
	*if (warprep_spies="Tornassa")
		their castle.
	*if (warprep_spies!="Tornassa")
		Tornassa.
	The gossip says that Selina's new bodyguard
	*if (prisoner1_name=karlkarla_name)
		put an arrow into the assassin's heart
	*if (prisoner1_name=theothea_name)
		crushed in the assassin's head
	*if (prisoner1_name=jacejess_name)
		set the assassin on fire
	*if (prisoner1_name=peterpetra_name)
		struck down the assassin
	*if (prisoner1_name=gillgale_name)
		stabbed the assassin in the back
	just before he could kill the duchess too.  The fact that the castle had been fully repaired since the fire on the night of your parents' murder, and that the defences were back to normal, hadn't slowed the killer at all.  The Uddo duchy grieved the loss of their ruler and promptly proclaimed Duchess Selina to be their new leader.  Selina quickly mandated a draft, forming a large army to stop your alleged treason.
	
	"This changes nothing," General Vale says.  "We must still march on Ludd in the spring and then north into Tornassa."
	*goto Warprep_BreakChecks_Done
*else
	*goto Warprep_Check_FourthBreak
	
*label Warprep_Check_FourthBreak
*if ((warprep_teleport=4) and (warprep_fourthbreak_done=false))
	*set warprep_fourthbreak_done true
	
	The effects of your economic decisions begin to make themselves known.
	*if (army_budget="increase")
		The gold from the treasury continues to flow toward the war effort.  Soldiers are paid well; new tents, extra food and equipment all arrive promptly.  Resentment toward you and the army builds as people struggle to make their tax payments on time.
		*if (showstats)
			(Army Power +5, Army Food +5, Army Morale +10, Army Size +10 and Citizen Reputation -20)
		*set army_power +5
		*set army_food +5
		*set army_morale +10
		*set army_size +10
		*set citizen_reputation -20
		*goto Warprep_BreakChecks_Done
	*if (army_budget="decrease")
		The gold from the nearly empty treasury is stretched even thinner as the army grows.  The citizens are happy that you have lowered taxes, but the army finds that there is no money to replace or repair torn tents, worn-out sleeping blankets, broken armour, chipped swords, dented pots and a thousand other things. 
		*if (showstats)
			(Army Power -5, Army Food -5, Army Morale -10, Army Size -5 and Citizen Reputation +20)
		*set army_power -5
		*set army_food -5
		*set army_morale -10
		*set army_size -5
		*set citizen_reputation +20
		*gosub Check_Army_Stats
		*goto Warprep_BreakChecks_Done
	*comment (army_budget="same")
	The treasury was nearly empty before you came and the tax rate was very high.  The army continues to use the taxes to pay the soldiers a fair wage, repair torn tents, replace worn-out sleeping bags, repair broken armour and handle a thousand other needs.  The citizens are still unhappy, since the tax rate, which you left the same, makes their lives very difficult.
	*if (showstats)
		(Army Morale -2 and Citizen Reputation -5)
	*set army_morale -2
	*set citizen_reputation -5
	*gosub Check_Army_Stats
	*goto Warprep_BreakChecks_Done
*else
	*goto Warprep_BreakChecks_Done

*label Warprep_BreakChecks_Done
*choice
	#Ask General Vale and Captain ${branbrinn_name} about any existing spy networks.
		*label Warprep_GetSpies
		"The spy network was the first thing Selina bolstered when she began ruling," General Vale says.  "The spy master went missing the day of the vote that restored your rule.  You can be sure that Selina knows exactly what we are doing here.  It's hard to be certain of the loyalty of any of the spies that remained behind."
		
		"I could make a list of those that I think are most likely to be trustworthy," Captain ${branbrinn_name} says.  "What would you like for them to be doing this winter?"
		*label Choose_Spy_Location
		*choice
			#Say, "We need to learn what Selina is up to.  Send them to Tornassa."
				"A wise move, Your Highness," General Vale says in agreement.  "That is where the bulk of the army will be.  Any information from Tornassa will be of great importance to our campaign."
				*if (showstats)
					*line_break
					(General Vale Relationship +2)
				*set vale_relationship +2
				*set warprep_spies "Tornassa"
				*goto Warprep_loop
			#Say, "Our first target is Ludd.  Send them to Duke Eddan."
				"A wise move, Your Highness," General Vale says in agreement.  "If we don't get past Ludd, nothing else matters.  Any information we get will be of great importance to our campaign."
				*if (showstats)
					*line_break
					(General Vale Relationship +2)
				*set vale_relationship +2
				*set warprep_spies "Ludd"
				*goto Warprep_loop
			#Say, "My biggest worry is here in Brightwater.  Have them ferret out Selina's spies."
				"This is smart," ${branbrinn_name} says in agreement.  "We may not be able to stop the information from reaching Selina, but perhaps we could foil any possible sabotage plans before they occur."
				*if (showstats)
					*line_break
					(${branbrinn_name} Relationship +2)
				*set branbrinn_relationship +2
				*set warprep_spies "Brightwater"
				*goto Warprep_loop
			*allow_reuse #Say, "The true threat is Zusak.  Send them to the Consortium in Vernex."
				"We would do better with information about the armies we will be facing in Ludd and Tornassa," General Vale says.
				
				"Selina's spies here in Brightwater will be causing problems," ${branbrinn_name} says.  "But, it shall be as you wish, Your Highness."
				*choice
					#Say, "I still wish to send them to Vernex."
						"As you wish, Your Highness," Captain ${branbrinn_name} and General Vale both say.
						*if (showstats)
							*line_break
							(${branbrinn_name} Relationship -2 and General Vale Relationship -2)
						*set branbrinn_relationship -2
						*set vale_relationship -2
						*set warprep_spies "Vernex"
						*goto Warprep_loop
					*allow_reuse #Say, "Perhaps you are right."
						Captain ${branbrinn_name} and General Vale wait to hear where you will send your spies.
						*goto Choose_Spy_Location
	#Go to the dwarf king in the Grey Mountains.
		*set warprep_dwarves true
		*gosub Teleport
		It was cold when you left, but now it is even colder.  You pull your winter clothing closer to yourself and look around.  The Grey Mountains tower over you in all directions, but the enormous mountain you are standing on the side of is even bigger.  The Academy wizards who sent you claim that this is the home of the dwarves, but you see no buildings and no structures.
		*if (currentfriend_name!="None")
			
			"I sure hope they put us on the right mountain," ${currentfriend_name} says.
		
		The ledge you are standing on has a narrow path leading down the mountain.  You are just about to begin the long descent when you hear a grating noise.  A section of the mountain wall swings open to reveal a short stocky man with an impressive beard.  He is holding a large crossbow aimed toward you.
		
		"Are ye lost,
		*if (gender="male")
			laddie?"
		*if (gender="female")
			lassie?"
		the dwarf asks in a gruff voice.
		*if (currentfriend_name!="None")
			
			*comment endif
		*if (currentfriend_name=theothea_name)
			"Holy blazing hells!!" ${theothea_name} exclaims as the dwarf seems to step out of nothing.  "Ya startled the rocks outta me!"
		*if (currentfriend_name=karlkarla_name)
			"Eeeep!" ${karlkarla_name} yelps as the dwarf seems to step out of nothing.
		*if (currentfriend_name=jacejess_name)
			${jacejess_name}'s eyes blaze white for a moment as the dwarf seems to step out of nothing.  They return to normal immediately after, but you can't help but think how close the dwarf had been to being incinerated.
		*if (currentfriend_name=peterpetra_name)
			"Merciful Lucien!" ${peterpetra_name} exclaims as the dwarf seems to step out of nothing.  The devout holy warrior immediately kisses ${peterpetra_hisher} holy symbol as an apology for ${peterpetra_hisher} misuse of the deity's name.
		*if (currentfriend_name=branbrinn_name)
			${branbrinn_name} has half the blade of ${branbrinn_hisher} longsword bared as the voice seems to erupt out of nothing.  The captain immediately slides the blade back into its sheath as ${branbrinn_heshe} sees that it is a dwarf.
		*if (currentfriend_name=gillgale_name)
			${gillgale_name} dives to the side and into a roll, drawing both of ${gillgale_hisher} swords as the voice seems to erupt out of nothing.  When the thief sees that it's one of the dwarfs you came to see, ${gillgale_heshe} blushes and returns ${gillgale_hisher} swords to their sheaths.
		*choice
			#Say, "I am here to speak to your king."
				"Are ye now?" the bearded warrior says as he arches a bushy eyebrow.
				*goto Dwarf_MoreDwarfs
			#Ask, "Pardon me, but are you a dwarf?"
				"Was it the beard that gave it away?" the short warrior says as he lowers the crossbow.  "I'd make a tiny ogre, now wouldn't I?"
				*goto Dwarf_MoreDwarfs
			#Say, "Put that weapon away before I take it from you."
				"Ye have some spunk!" the bearded warrior exclaims hardily as he lowers the crossbow.
				*goto Dwarf_MoreDwarfs
			#Say nothing.
				"I must have said that wrong," the bearded warrior offers.  "I'm not very good at speaking Human."
				*goto Dwarf_MoreDwarfs
				
		*label Dwarf_MoreDwarfs
		
		The dwarf opens the rest of the door, showing a large entrance into the side of the mountain.  The stonework craftsmanship is remarkable.  While the door had been closed, you hadn't even seen a seam.  The thuds of more dwarf-feet tell you that similar doors have opened behind you.  Before you can do anything, you are surrounded by more warriors with crossbows.
		
		"Come along now," the first one says.  "It isn't every day that we find a human on our doorstep.  King Grolsch will want to speak to you."
		
		You are led into the mountain.  The marble floor and enormous pillars show that the dwarf home has been here a long time.  You see many more warriors, several of whom holding worn battle axes which seem too large for their small statures.  After a few minutes, you find yourself standing in a large room with many long wooden tables.  Seated at the tables are many more dwarves with pewter mugs of ale and plates filled with food.  A large stone throne sits empty in the corner.  A dwarf with a bright red beard and a battered crown stands up from one of the tables.
		
		"I am King Grolsch," he says as he puffs out his chest.  "And who might you be?"
		*fake_choice
			#Say, "I am $!{princeprincess} ${name}."
			#Say, "I am the heir to the Kingdom of Daria."
			#Say, "I am the ruler of the duchy formerly known as Dumain."
		"The $!{kingqueen} of the humans," King Grolsch says as he arches a bushy red eyebrow.
		
		You begin by explaining that you are the ${princeprincess} of a portion of the humans.  You spend the next hour telling King Grolsch about your situation and how you would like to make an alliance with him and his people.  You explain that you would like his dwarven smithies to supply your army and his dwarven warriors to join you in your campaign once the snow melts.
		
		"We have always let you humans do as you like, as long as you leave us alone under our mountains.  But I agree, there is much to gain from trading with you.  We do not shy from battle and your cause seems just.  Unfortunately, we have our own troubles."
		*choice
			#Say, "Perhaps there is something I can do to help?"
				*goto Dwarf_GetMission
			#Say, "I'm sorry.  The threat of the demon summoners is too great.  I'm afraid we have no time to help you."
				"I understand," King Grolsch says.  "Then I am afraid we can't help you."
				
				*goto Kicked_Out_Of_Dwarf_Land
			#Say, "Very well, we don't need any stinking dwarves to help us anyway."
				Instead of getting upset, King Grolsch laughs at your words.
				*label Kicked_Out_Of_Dwarf_Land
				You are escorted down a new hallway, and before long you find yourself outside again.  Once the door to the dwarven kingdom is closed, you are unable to find it again.  Two weeks pass as you camp in the mountains, after which, the wizards back in Brightwater activate the artifact and the magical lights envelop you once again.  In a heartbeat, you find yourself back home.  The dwarves will not be aiding you in your upcoming campaign.
				*set dwarf_help 0
				*goto Warprep_loop
		*label Dwarf_GetMission
		"Oh?" King Grolsch says with a smile on his ruddy face.  "Is the $!{kingqueen} of the humans also a great warrior?  Very well, come with me."
		
		You don't bother to correct him a second time.  He leads you through a hall as a group of dwarven warriors join you.  After nearly an hour of walking, a door is opened and you find yourself outside once again.  He points across a mountain valley which looks to have been trampled with small hoofprints.
		
		"This is where our sheep graze when the snows go away.  About a mile in that direction, a giant has made himself a home.  The pesky creature is enormous and he's eating our sheep.  He's also killed several of our best warriors.  If you can remove him, you'll have proved your worth to us and we will help you in your upcoming war."
		*temp dwarfs_broughtdwarfs
		*set dwarfs_broughtdwarfs false
		*label Dwarf_GiantApproach_loop
		*choice
			#Stealthily attempt to get closer to the giant camp.
				*if (dwarfs_broughtdwarfs)
					King Grolsch watches as you and his warriors slink between the snow covered rock outcroppings and approach the giant's camp.  After an hour of walking, you see a large blazing fire.  Several trees have been knocked over to fuel the inferno.  The stomping of your dwarven companions is more than loud enough to wake the giant.  He gets to his feet as you approach.  The creature is easily eleven feet tall and wears only rags, despite the cold weather.  You can see grease stains across his chest from the many sheep he has feasted upon.  In his hand, he holds an enormous wooden club that is as tall as you are.
					*goto Dwarf_Giant_Alert
				The dwarves watch as you slink between the snow covered rock outcroppings and approach the giant's camp.  After an hour of walking, you see a large blazing fire.  Several trees have been knocked over to fuel the inferno.
				*if (stealth<40)
					The giant sitting in front of the fire opens his eyes as your foot crunches in the snow.  He gets to his feet as you approach.  The creature is easily eleven feet tall and wears only rags, despite the cold weather.  You can see grease stains across his chest from the many sheep he has feasted upon.  In his hand, he holds an enormous wooden club that is as tall as you are.
					*if (showstats)
						(Needed 40 Stealth)
					*goto Dwarf_Giant_Alert
				The giant sitting in front of the fire is snoring loudly.  The creature is easily eleven feet tall and wears only rags, despite the cold weather.  You can see grease stains across his chest from the many sheep he has feasted upon.  At his feet sits an enormous wooden club that is as tall as you are.
				*comment No dwarves with MC
				*label Giant_Asleep_Choices
				*choice
					#Sneak up to the giant and slit his throat before he awakes.
						*if (stealth<70)
							You approach the giant as quietly as you can, but just as you get close, the fire pops and the creature opens his eyes.  He gets quickly to his feet as he grabs his club.
							*if (showstats)
								(Needed 70 Stealth)
							*goto Dwarf_Giant_Alert
						*else
							*if ((sword) or (dagger))
								Your blade slices cleanly through the giant's exposed throat.  You are forced to scramble backward as he awakens!  He lumbers to his feet and puts his hands to the wound.  The blood pours through his fingers, and within moments, the enormous monster crashes to the ground at your feet.
								*if (showstats)
									*line_break
									(Stealth +2)
								*set stealth +2
								*goto Dwarf_Giant_Dead
							*else
								You are nearly upon the giant when you realize your folly.  You don't have a sword or a dagger to do the deed!  You consider using magic, or some other method, but it's too late.  The giant's eyes open and he scrambles backward away from you, getting to his feet and grabbing his club.
								*if (showstats)
									(Needed a Sword or a Dagger)
								*goto Dwarf_Giant_Alert
					*if (sword) #Attack the sleeping giant with your sword.
						*if (blades>=40)
							You manage to hit the monster twice before he even opens his eyes.  By the time he tries to pick up his club, you have driven your sword into his heart.  The giant gurgles as he falls dead beside his campfire.
							*if (showstats)
								*line_break
								(Blades +2)
							*set blades +2
							*goto Dwarf_Giant_Dead
						*else
							You strike the monster once, but he shrugs off your attack and picks up his club.
							*if (showstats)
								(Needed 40 Blades)
							*goto Dwarf_GettingHit
					*if (dagger) #Attack the sleeping giant with your dagger.
						*if (blades>=65)
							You manage to hit the monster twice before he even opens his eyes.  By the time he tries to pick up his club, you have driven your sword into his heart.  The giant gurgles as he falls dead beside his campfire.
							*if (showstats)
								*line_break
								(Blades +2)
							*set blades +2
							*goto Dwarf_Giant_Dead
						*else
							You strike the monster once with your tiny blade, but he shrugs off your attack and picks up his club.  A sword's longer reach would have made things much easier.
							*if (showstats)
								(Needed 65 Blades)
							*goto Dwarf_GettingHit
					*if (bow) #Attack the sleeping giant with your bow.
						*if (archery>=40)
							The fact that the giant wasn't moving makes shooting him much easier.  You manage to put two feathered arrows into his throat before he wakes up.  He almost makes it to his feet, but doesn't quite do so.  He falls onto his back and dies as he tries to draw breath through his punctured throat.
							*if (showstats)
								*line_break
								(Archery +2)
							*set archery +2
							*goto Dwarf_Giant_Dead
						*else
							Your arrow strikes the giant in the shoulder instead of the throat.  He gets to his feet and grabs his club, hardly seeming to care that he has been hit.
							*if (showstats)
								(Needed 40 Archery)
							*goto Dwarf_Giant_Alert
					#Try to strangle the sleeping giant.
						You jump onto the enormous monster and wrap your arms around his throat in a bear hug.  You struggle to keep your grip as you squeeze.  
						*if (unarmed>=70)
							He wakes up and stands, but you continue to hang on.  After a few moments, he staggers and falls onto his knees.  You have a moment of fright when he begins to sway forward, but in the end, he falls onto his back and dies.
							*if (showstats)
								*line_break
								(Unarmed +2)
							*set unarmed +2
							*goto Dwarf_Giant_Dead
						*else
							He grabs you with both hands and pulls you free, dropping you to the ground at his feet.
							*if (showstats)
								(Needed 70 Unarmed)
							*goto Dwarf_Giant_Alert
					*if (demonsummoner)
						*allow_reuse #Consider using a Demonstone.
							You open your runebag and consider your options.
							*label Giant_Sleeping_DemonSummon
							*choice
								*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and ((demonstone_xiatta_used=false) and (demonsummoner))) #Summon Xi'atta and tell it to attack the giant.
									*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
									Xi'atta appears in front of you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
									
									*if (willpower>=40)
										"Yes, ${mastermistress}," Xi'atta says.
										
										The small frosty demon clearly does not like what it has been summoned to do, but since you dominated its will, it has no choice but to obey.  Xi'atta causes a small patch of the giant's large cheek to freeze, but this merely wakes the monster.  The giant grabs his club, and with one swing, drives the demon back into its own plane of existence.  It will take some time before Xi'atta can be called again.
										*set demonstone_xiatta_used true
										*goto Dwarf_Giant_Alert
									*else
										"No, that thing would kill me," it says. The contest of wills is rejoined and the icy demon pops out of existence.
										*if (showstats)
											(Needed 40 Willpower)
										*goto Giant_Sleeping_DemonSummon
								*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl and tell it to attack the giant.
									*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
									Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
									
									*if (willpower>=70)
										"Yes, ${mastermistress}," Brahl says reluctantly.
										
										Brahl manages to slice a few chunks of flesh from the giant before awakening him.  The enormous monster grabs his club and is about to smash Brahl into a sticky pulp when suddenly the brawny demon rushes in close and tears into the giant's stomach some more.  When the battle is over, the giant lies dead on the ground with his gut torn open.  Unfortunately, Brahl has also taken enough injury to force it back to its own plane of existence.  It will be some time before Brahl can be summoned again.
										*set demonstone_brahl_used true
										*goto Dwarf_Giant_Dead
									*else
										"I like a good fight, but that thing is huge," Brahl says before beginning a contest of wills.  A moment later and the brawny demon pops out of existence.
										*if (showstats)
											(Needed 70 Willpower)
									*goto Giant_Sleeping_DemonSummon
								*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and ((demonstone_zonch_used=false) and (demonsummoner))) #Summon Zon'ch and tell it to attack the giant.
									*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
									Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one foot tall form.
									
									*if (willpower>=50)
										"Yes, ${mastermistress}," Zon'ch says unhappily.
										
										The dusty demon walks over to the giant and summons a cloud of dirt.  Whatever Zon'ch had intended to do with it fails miserably as the giant awakens with a sneeze.  The huge creature grabs Zon'ch in one big hand and squeezes the small demon into a goo, causing it to disappear back to its own plane of existence.  It will take some time before Zon'ch can be called again.
										*set demonstone_zonch_used true
										*goto Dwarf_Giant_Alert
									*else
										"No, that thing would kill me," it says. The contest of wills is rejoined and the dusty demon pops out of existence.
										*if (showstats)
											(Needed 50 Willpower)
										*goto Giant_Sleeping_DemonSummon
								*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and ((demonstone_daanda_used=false) and (demonsummoner))) #Summon Daan'da and tell it to attack the giant.
									*comment Will of 0, but very stupid and weak.
									Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
									*set demonstone_daanda_used true
									
									"Okay, ${mastermistress}," Daan'da says.
									
									The thin demon walks over and flails ineffectually at the giant.  It takes several hits before the big monster even wakes up, but when he does, he strikes Daan'da with one large fist and sends the demon back to its own plane of existence.
									*goto Dwarf_Giant_Alert
								*allow_reuse #Close your runebag.
									*goto Giant_Asleep_Choices
					*if ((currentfriend_name=karlkarla_name) and (infinity_arrow)) #Tell ${karlkarla_name} to shoot the giant with the Infinity Arrow.
						*set infinity_arrow false
						The magical arrow flies true, striking the giant in the eye.  It buries itself so deep into the giant's skull that only a small red hole is left behind.  The giant's other eye never even opens as he dies on the spot.
						*goto Dwarf_Giant_Dead
					#Cast a spell to cause the giant's campfire to explode on the slumbering monster.
						*if (magic>=40)
							You are able to take your time and finish the spell to completion.  The fire explodes outward, enveloping the sleeping giant in its fiery embrace.  He roars in pain for a moment before falling to the ground dead and smoking.
							*if (showstats)
								*line_break
								(Magic +2)
							*set magic +2
							*goto Dwarf_Giant_Dead
						*else
							Your carefully uttered magical incantation wakes the giant.  He gets to his feet and grabs his club.  He steps aside as the fire from the campfire burns where he had been standing.
							*if (showstats)
								(Needed 40 Magic)
							*goto Dwarf_Giant_Alert
					#Shout, "Wake up, foul beast!"
						The giant opens his eyes, gets to his feet and grabs his club.
						*goto Dwarf_Giant_Alert
					#Shout, "Wake up.  I wish to speak to you!"
						The giant opens his eyes, gets to his feet and grabs his club.
						*goto Dwarf_Giant_Alert
					#Give up and leave the dwarves to deal with the giant themselves.
						*label Dwarf_Gave_Up
						King Grolsch is disappointed.  You are escorted back through the mountain keep and down a new hallway, and before long you find yourself outside again.  Once the door to the dwarven kingdom is closed, you are unable to find it again.  Two weeks pass as you camp in the mountains.  With very little gear, it isn't a pleasant stay.  You are thankful when the wizards back in Brightwater activate the artifact and the magical lights envelop you once again.  In a heartbeat, you find yourself back home.  The dwarves will not be aiding you in your upcoming campaign.
						*set dwarf_help 0
						*goto Warprep_loop
			#Boldly walk to the camp.
				The dwarves grin at your bravado as you march across the snowy field.  After an hour of walking, you see a large blazing fire.  Several trees have been knocked over to fuel the inferno.  The giant sitting in front of the fire gets to his feet as you approach.  The creature is easily eleven feet tall and wears only rags, despite the cold weather.  You can see grease stains across his chest from the many sheep he has feasted upon.  In his hand, he holds an enormous wooden club that is as tall as you are.
				*label Dwarf_Giant_Alert
				*choice
					*if (sword) #Attack the giant with your sword.
						*if (blades>=60)
							You step inside of the giant's reach as he takes a clumsy swing at you.  You then slash him across the stomach.  By the time he tries to strike you with his club, you have driven your sword into his heart.  The giant gurgles as he falls dead beside his campfire.
							*if (showstats)
								*line_break
								(Blades +2)
							*set blades +2
							*goto Dwarf_Giant_Dead
						*else
							You strike the monster once, but he shrugs off your attack and picks up his club.
							*if (showstats)
								(Needed 60 Blades)
							*goto Dwarf_GettingHit
					#Attempt to trip the giant.
						*if (unarmed>=70)
							You step inside of the giant's reach as he takes a clumsy swing at you.  You then push the creature when he is off-balance.  The giant crashes to the ground, striking his head against the stony ground, killing him instantly.
							*if (showstats)
								*line_break
								(Unarmed +2)
							*set unarmed +2
							*goto Dwarf_Giant_Dead
						*else
							You try to topple the giant over, but he is much too large to move.
							*if (showstats)
								(Needed 70 Unarmed)
							*goto Dwarf_GettingHit
					*if (dagger) #Attack the giant with your dagger.
						*if (blades>=85)
							You step inside of the giant's reach as he takes a clumsy swing at you.  You then stab his enormous chest multiple times with your dagger.  By the time he tries to strike you with his club, his heart has been punctured multiple times.  He gurgles as he falls dead beside his campfire.
							*if (showstats)
								*line_break
								(Blades +2)
							*set blades +2
							*goto Dwarf_Giant_Dead
						*else
							You strike the monster once with your tiny blade, but he shrugs off your attack and picks up his club.  A sword's longer reach would have made things much easier.
							*if (showstats)
								(Needed 85 Blades)
							*goto Dwarf_GettingHit
					*if (bow) #Attack the giant with your bow.
						*if (archery>=70)
							The giant tries to swat the arrows from the air, but you place two long shafts through his throat anyway.  He gurgles loudly as he falls to the ground beside his campfire.  After a few more minutes, he stops breathing.
							*if (showstats)
								*line_break
								(Archery +2)
							*set archery +2
							*goto Dwarf_Giant_Dead
						*else
							The giant raises his enormous arm just in time, causing the shafts to miss his throat as they drive into his wrist instead.
							*if (showstats)
								(Needed 70 Archery)
							*goto Dwarf_Giant_Alert
					#Cast a lightning bolt at the giant.
						*if (magic>=80)
							The giant roars a challenge at you as he rushes forward, but the lightning strikes him solidly in the chest, throwing him backward.  He crashes to the ground dead as the smoke wafts from his charred body.
							*if (showstats)
								*line_break
								(Magic +2)
							*set magic +2
							*goto Dwarf_Giant_Dead
						*else
							The lightning bolt is slow in manifesting, which allows the giant to step aside, causing the electricity to miss the monster.
							*if (showstats)
								(Needed 80 Magic)
							*goto Dwarf_Giant_Alert
					*if ((currentfriend_name=karlkarla_name) and (infinity_arrow)) #Tell ${karlkarla_name} to shoot the giant with the Infinity Arrow.
						*set infinity_arrow false
						The magical arrow flies true, striking the giant in the eye.  It buries itself so deep into the giant's skull that only a small red hole is left behind.  The giant falls forward and lands on his face, with a thundering thump, dead as can be.
						*goto Dwarf_Giant_Dead
					#Say, "I mean you no harm."
						The giant cocks his enormous head to the side as he struggles to comprehend what you said.  You aren't sure if he is going to answer, but then, words form on his big mouth.
						
						"Yummy sheep.  Kratog
						*if (charm<50)
							eat.  Yummy human.  Kratog eat you too."
							*if (showstats)
								(Needed 50 Charm)
							*goto Dwarf_Giant_Alert
						eat."
						*if (showstats)
							*line_break
							(Charm +2)
						*set charm +2
						*choice
							#Say, "Kratog, this is dwarf land.  These sheep belong to them."
								The giant pauses once more before answering.
								
								"Dwarves yummy too."
								*choice
									#Say, "Perhaps if you take a few sheep with you, you can then find some wild goats on another mountaintop?"
										*if (dwarfs_broughtdwarfs)
											The dwarfs grumble a bit, but they follow your lead.
										The giant takes several minutes to think about your offer before finally nodding acceptance.  He proceeds to stomp toward the grazing fields to gather his sheep.
										*choice
											#Let the giant gather the sheep.
												The giant's long legs allow him to catch the fleeing sheep with little trouble.  You watch as he gathers three fuzzy white sheep under each arm.  He then grins back at you before lumbering away.
												*set kratog_gavesheep true
												*goto Dwarf_Giant_Dead
											*if ((sword) or (dagger)) #Attack the giant, with your blade, the moment he turns his back on you.
												The big brute doesn't expect your treachery as you launch your attack upon his exposed back.  A few slices later and you've hamstrung the monstrosity.  The moment he falls to the ground, you are able to cut his throat as well.
												*if (showstats)
													*line_break
													(Blades +3 and Evil +7)
												*set blades +3
												*set good -7
												*goto Dwarf_Giant_Dead
											#Attack the giant, with a spell, the moment he turns his back on you.
												The big brute doesn't try to stop you, giving you ample time to finish your spell.
												*if (magic<30)
													Unfortunately, even with this advantage, the spell of choking that you cast is too weak to kill the giant.  Angered, he turns toward you as he coughs from the magical effects.
													*if (showstats)
														(Needed 30 Magic)
													*goto Dwarf_GettingHit
												A cloud of poisonous gas erupts around his face.  He immediately gasps and coughs as he attempts to wave away the fumes with his massive hands.  Unfortunately for him, the spell is well-cast and the poison remains.  Within seconds, the giant falls to the ground dead.
												*if (showstats)
													*line_break
													(Magic +3 and Evil +7)
												*set magic +3
												*set good -7
												*goto Dwarf_Giant_Dead
									#Say, "Time to die, giant."
										*goto Giant_Smile
							#Say, "Get the hells off this mountain, or I'll be forced to kill you."
								*label Giant_Smile
								The giant grins at you, either not understanding your words or not caring.
								*goto Dwarf_Giant_Alert								
					*if (demonsummoner)
						*allow_reuse #Consider using a Demonstone.
							You open your runebag and consider your options.
							*label Giant_Alert_DemonSummon
							*choice
								*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and ((demonstone_xiatta_used=false) and (demonsummoner))) #Summon Xi'atta and tell it to attack the giant.
									*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
									Xi'atta appears in front of you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
									
									*if (willpower>=40)
										"Yes, ${mastermistress}," Xi'atta says.
										
										The small frosty demon clearly does not like what it has been summoned to do, but since you dominated its will, it has no choice but to obey. Xi'atta causes a small patch of the giant's large cheek to freeze, but this merely irritates the monster.  The giant swings his club and drives the demon back into its own plane of existence.  It will take some time before Xi'atta can be called again.
										*set demonstone_xiatta_used true
										*goto Dwarf_Giant_Alert
									*else
										"No, that thing would kill me," it says. The contest of wills is rejoined and the icy demon pops out of existence.
										*if (showstats)
											(Needed 40 Willpower)
										*goto Giant_Alert_DemonSummon
								*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl and tell it to attack the giant.
									*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
									Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
									
									*if (willpower>=70)
										"Yes, ${mastermistress}," Brahl says reluctantly.
										
										The enormous monster grabs his club and is about to smash Brahl into a sticky pulp when suddenly the brawny demon rushes in close and tears into the giant's stomach.  When the battle is over, the giant lies dead on the ground with his gut torn open.  Unfortunately, Brahl has also taken enough injury to force it back to its own plane of existence.  It will be some time before Brahl can be summoned again.
										*set demonstone_brahl_used true
										*goto Dwarf_Giant_Dead
									*else
										"I like a good fight, but that thing is huge," Brahl says before beginning a contest of wills.  A moment later and the brawny demon pops out of existence.
										*if (showstats)
											(Needed 70 Willpower)
									*goto Giant_Alert_DemonSummon
								*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and ((demonstone_zonch_used=false) and (demonsummoner))) #Summon Zon'ch and tell it to attack the giant.
									*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
									Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
									
									*if (willpower>=50)
										"Yes, ${mastermistress}," Zon'ch says unhappily.
										
										The dusty demon walks over to the giant and summons a cloud of dirt.  Whatever Zon'ch had intended to do with it fails miserably as the giant grabs Zon'ch in one big hand and squeezes the small demon into a goo, causing it to disappear back to its own plane of existence.  It will take some time before Zon'ch can be called again.
										*set demonstone_zonch_used true
										*goto Dwarf_Giant_Alert
									*else
										"No, that thing would kill me," it says. The contest of wills is rejoined and the dusty demon pops out of existence.
										*if (showstats)
											(Needed 50 Willpower)
										*goto Giant_Alert_DemonSummon
								*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and ((demonstone_daanda_used=false) and (demonsummoner))) #Summon Daan'da and tell it to attack the giant.
									*comment Will of 0, but very stupid and weak.
									Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
									*set demonstone_daanda_used true
									
									"Okay, ${mastermistress}," Daan'da says.
									
									The thin demon walks over and flails ineffectually at the giant.  The big monster strikes Daan'da with one large fist and sends the demon back to its own plane of existence.
									*goto Dwarf_Giant_Alert
								*allow_reuse #Close your runebag.
									*goto Dwarf_Giant_Alert
					#Give up and leave the dwarves to deal with the giant themselves.
						*goto Dwarf_Gave_Up	
			#Ask, "Will some of your warriors come with me?"
				*if (charm<50)
					*if (currentfriend_name!=theothea_name)
						*label Dwarf_NoMoreHelp
						"We've lost enough warriors trying to stop this monster," King Grolsch says.  "We'll let him eat the rest of the sheep that we haven't herded to another meadow and then hope he moves on in the spring.  Unless you can remove him, that is."
						*if (showstats)
							(Needed 50 Charm)
						*goto Dwarf_GiantApproach_loop
					*else
						"I was going to say no," King Grolsch says.  "But I recognize you, ${theothea_name}.  You're of the Norgan Mountain clans.  Tell me, mountain-${theothea_manwoman}: Can I trust your companion with the lives of my warriors?"
						
						*if (theothea_relationship>=80)
							
							"Absolutely," ${theothea_name} says without hesitation.  "$!{mc_heshe} is a good friend and will try to keep your warriors safe."
							*if (showstats)
								*line_break
								(${theothea_name} Relationship +3)
							*set theothea_relationship +3
							*label Dwarf_MoreDwarves
							
							"Very well," King Grolsch says, and he tells a group of six dwarves to accompany you.
							*set dwarfs_broughtdwarfs true
							*goto Dwarf_GiantApproach_loop
						${theothea_name} pauses for a moment before nodding.  "Yes, your warriors will be safe."
						*if (showstats)
							(Needed 80 ${theothea_name} Relationship)
						
						*goto Dwarf_NoMoreHelp
				*else
					"Yes, I will send six of my warriors with you," King Grolsch says after a moment's consideration.
					*if (showstats)
						*line_break
						(Charm +2)
					*set charm +2
					*set dwarfs_broughtdwarfs true
					*goto Dwarf_GiantApproach_loop
			*if (currentfriend_name!="None") #Let ${currentfriend_name} attack the giant.
				As ${currentfriend_name} gets into position, the giant swings his club at you!
				*goto Friend_Help_Giant
			#Say, "I'm afraid that I can't help you."
				"Yes, it's quite a problem," King Grolsch agrees.  "I'll get you a place to stay while you wait for the snows to clear so you can return to your own cities."
				
				*if (dwarfs_broughtdwarfs)
					The dwarves who were to accompany you seem upset that they won't be going into battle.
				You spend two weeks among the dwarves, eating their food and listening to their songs, after which, the wizards back in Brightwater activate the artifact and the magical lights envelop you once again.  In a heartbeat, you find yourself back home.  The dwarves will not be aiding you in your upcoming campaign.
				*set dwarf_help 0
				*goto Warprep_loop
		
		*label Dwarf_GettingHit
		
		The giant swings his enormous club toward you!
		*label Friend_Help_Giant
		*if (currentfriend_name!="None")
			At the last moment,
			*if (currentfriend_name=theothea_name)
				${theothea_name}'s large hammer intercepts the blow.  The giant drives one of his knees upward, catching the mountain-${theothea_manwoman} in the chin and dropping ${theothea_himher} to the ground in a heap.
				*set theothea_injured true
			*if (currentfriend_name=branbrinn_name)
				${branbrinn_name}'s longsword intercepts the blow.  The giant drives one of his knees upward, catching the captain in the chin and dropping ${branbrinn_himher} to the ground in a heap.
				*set branbrinn_injured true
			*if (currentfriend_name=peterpetra_name)
				${peterpetra_name}'s morningstar intercepts the blow.  The giant drives one of his knees upward, catching the holy warrior in the chin and dropping ${peterpetra_himher} to the ground in a heap.
				*set peterpetra_injured true
			*if (currentfriend_name=gillgale_name)
				${gillgale_name} suddenly leaps onto the creature's back, forcing the giant to stop his attack on you.  The monster reaches back, grabs the thief and throws ${gillgale_himher} away like a toy!  ${gillgale_name} bounces across the field in a tumbled heap.
				*set gillgale_injured true
			*if (currentfriend_name=karlkarla_name)
				${karlkarla_name}'s arrow strikes the giant in the arm, causing him to abort his attack on you.  The monster drives one of his knees upward, catching the archer in the chin and dropping ${karlkarla_himher} to the ground in a heap.
				*set karlkarla_injured true
			*if (currentfriend_name=jacejess_name)
				${jacejess_name}'s magical energy beam strikes the giant in the arm, causing him to abort his attack on you.  The monster drives one of his knees upward, catching the Soulburner in the chin and dropping ${jacejess_himher} to the ground in a heap.
				*set jacejess_injured true
			*label Giant_Distraction
			*choice
				*if (sword) #Attack the giant with your sword.
					*label Giant_Distraction_Blades
					You use the distraction to grab the giant's clothing and climb him like a ladder.  Before he can throw you off, you drive your blade into the giant's neck.  Blood sprays from the wound as he falls to the ground, dead.
					*if (showstats)
						*line_break
						(Blades +2)
					*set blades +2
					*goto Dwarf_GettingHit_2
				*if (dagger) #Attack the giant with your dagger.
					*goto Giant_Distraction_Blades
				#Push the giant off the mountain.
					You use the distraction to push the giant over.  He tries to grab at anything to stop him from falling, but fails.  You watch as the enormous creature rolls down the mountainside to his death.
					*if (showstats)
						*line_break
						(Strength +2)
					*set strength +2
					*goto Dwarf_GettingHit_2
				*if (bow) #Attack the giant with your bow and arrow.
					*if (archery<30)
						The first arrow misses, as does the second.  Luckily for you, the distraction proves long enough for you to eventually strike the giant.
					*if (archery>=30)
						The arrow flies true.
					The feathered shaft lodges itself deeply into the giant's eye.  The massive monster falls backward, crashing onto his back and breathing no more.
					*if (showstats)
						*line_break
						(Archery +3)
					*set archery +3
					*goto Dwarf_GettingHit_2
				#Summon an ice spike to strike the giant.
					The distraction allows you to finish your spell.
					*if (magic<30)
						The icy bolt moves very slowly and you know that it is very fragile.  Luckily, the giant is too busy to see it and it lodges itself deeply into the monster's exposed throat!
					*if (magic>=30)
						The icy bolt strikes the giant in the throat!
					Blood pours around the ice as he attempts to pull the object out, but it is too slippery to get a hold of.  The giant falls to the ground dead.
					*if (showstats)
						*line_break
						(Magic +3)
					*set magic +3
					*goto Dwarf_GettingHit_2
			*label Dwarf_GettingHit_2
			
			${currentfriend_name} will be okay, but the injuries ${currentfriend_heshe} received will take a long time to heal.
			*set currentfriend_injured true
			*goto Dwarf_Giant_Dead
		*else
			*if (dwarfs_broughtdwarfs)
				At the last moment, the dwarfs who accompanied you rush forward to intercept the blow!  One dwarf is hit in the stomach and another in the face as the battle is joined.
				*goto Giant_Distraction
			You don't remember the club actually hitting you, as you wake up back in the dwarven stronghold a few days later.  The dwarves slowly nurse you back to health.  They are impressed that you tried to stop the giant, but they refuse to help you with your war effort.  Two weeks after your arrival in the dwarven lands, the wizards back in Brightwater activate the artifact and the magical lights envelop you once again.  In a heartbeat, you find yourself back home.  The dwarves will not be aiding you in your upcoming campaign.
			*set dwarf_help 0
			*goto Warprep_loop
		*label Dwarf_Giant_Dead
		
		You return to the dwarven hall where King Grolsch awaits.
		*if (kratog_gavesheep)
			
			"You gave away our sheep," he says in an incredulous tone.
			*choice
				*selectable_if (gold>=180) #Say, "I'll pay for them." (Needs 180 Gold)
					The dwarf king takes your gold and smiles.
					*if (showstats)
						*line_break
						(Gold -180)
					*set gold -180
					*goto Dwarf_Hurray
				#Say, "The giant is gone.  It was worth it."
					*if (charm>=70)
						You explain that the loss of a few sheep greatly outweighs the risk of death and injury from trying to fight the giant.  Eventually, he agrees with you.
						*if (showstats)
							*line_break
							(Charm +2)
						*set charm +2
						*goto Dwarf_Hurray
					"If we didn't care about the sheep, we could have just left the sheep," the dwarf king says angrily.  "No, you have failed us.  You may stay here until it is time for you to leave, but this is all."
					*if (showstats)
						(Needed 70 Charm)
					
					You spend two weeks among the dwarves, eating their food and listening to their songs, after which, the wizards back in Brightwater activate the artifact and the magical lights envelop you once again.  In a heartbeat, you find yourself back home.  The dwarves will not be aiding you in your upcoming campaign.
					*set dwarf_help 0
					*goto Warprep_loop	
		*else
			*goto Dwarf_Hurray

		*label Dwarf_Hurray
		
		"It feels good to have our grazing pasture back and to know that the rest of our sheep are now safe," King Grolsch exclaims.  "I am glad to have met you, ${name}."
		*set dwarf_help 1
		
		The dwarves clap you on the back and congratulate you.  Many of them want you to see their mines, which are the pride and joy of the dwarven community.  You spend the remainder of the two weeks among them…
		*choice
			# …drinking in their hall.
				Although the dwarves are shorter than humans, they are all wide and muscular.  And they can drink!  From morning until night, they seem to do very little other than drink their strong dwarven ales.  
				*if (currentfriend_name=theothea_name)
					${theothea_name} absolutely loves it!
					*if (showstats)
						*line_break
						(${theothea_name} Relationship +3)
						
					*set theothea_relationship +3
				The only time they aren't drinking is when they go to their mines, work their forges and practice their weaponry.  After a few days of steady drinking, you begin to gain an appreciation for their strong dwarven constitutions.
				*if (showstats)
					*line_break
					(Endurance +5)
				*set endurance +5
				*goto Dwarf_Afterward
			# …learning their songs.
				*if (class_bard=0)
					Although you aren't a bard,
				*if (class_bard>0)
					Being a bard,
				you appreciate the melodies and lyrics of their songs.  Many of the tunes are bawdy and rough, but the dwarven ballads speak of centuries of history.  They are filled with tales of the lands from the unique earthly perspective of the dwarves.
				*if (class_bard=0)
					*if (showstats)
						*line_break
						(History +5)
					*set history +5
					*goto Dwarf_Afterward
				*else
					*if (showstats)
						*line_break
						(History +7)
					*set history +7
					*goto Dwarf_Afterward
			# …studying their religion.
				The dwarves worship Auriel and Lucien like most of Daria, but they also say prayers to some of the stranger Gods of the mountains.  The dwarven Gods encourage hard work and appreciation of stone.
				*if (currentfriend_name=peterpetra_name)
					${peterpetra_name} is greatly changed by the talks.  Your holy friend has had a narrow view of the pantheon, but upon hearing how the dwarves worship their stone Gods, ${peterpetra_heshe} gains a greater appreciation of the world.  In return, the dwarves are honoured and encouraged by the respect ${peterpetra_name} shows.
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship +3, Nature +3, Religion +5 and Increased Dwarf Help)
					*set peterpetra_relationship +3
					*set nature +3
					*set religion +5
					*set dwarf_help +1
					*goto Dwarf_Afterward
				*if (showstats)
					*line_break
					(Religion +5)
				*set religion +5
				*goto Dwarf_Afterward
			# …working in their mines.
				The dwarves are as excited as children when you ask to see their mines.  Their eyes twinkle with pleasure as they happily outfit you with a pickaxe and lead you down into the narrow shafts.  You quickly lose all sense of direction, but your companions have no trouble leading the way.  They show you veins of iron, gold and silver, as well as pockets of every kind of gem you could think of.  You realize that they will happily chat all day about mining as proudly as new parents speak of their baby.
				
				With careful supervision, they let you swing the pick axe.
				*if ((strength>=45) and (endurance>=45))
					It is difficult work, but you spend the days breaking rock and searching through the stone for valuable materials.  You aren't as skilled as those who do the job every day, but you hold your own.  The dwarves gain great respect for your effort, talking to you about your plans of conquest.  Before long, most of the miners have volunteered to join you in the spring as you march upon your enemies.
					*if (showstats)
						*line_break
						(Strength +2, Endurance +2 and Increased Dwarf Help)
					*set strength +2
					*set endurance +2
					*set dwarf_help +1
					*goto Dwarf_Afterward
				The backbreaking labour quickly takes its toll on you.  You get blisters on your hands and your eyes sting as dust gets into them.  The dwarves smile condescendingly at your efforts.
				*if (showstats)
					(Needed 45 Strength and 45 Endurance)
				*goto Dwarf_Afterward

		*label Dwarf_Afterward
		
		As the two weeks come to an end, King Grolsch says that the dwarves he is sending to your aid have already left the mountain.  They will make it to Brightwater by spring so they can be with you when you begin your campaign.
		*if (circlet)
			The Circlet of Daria you are wearing impresses the dwarves even further.
			*set dwarf_help +1
		*if (dwarf_help=1)
			You will have dwarven blacksmiths to keep your army's equipment in excellent condition and a few dwarven warriors to supplement your troops.
			*if (showstats)
				*line_break
				(Army Power +5 and Army Size +7)
			*set army_power +5
			*set army_size +7
		*if (dwarf_help>=2)
			You will have dwarven blacksmiths to keep your army's equipment in excellent condition and a troop of dwarven warriors to supplement your own.
			*set dwarf_help 2
			*if (showstats)
				*line_break
				(Army Power +7 and Army Size +10)
			*set army_power +7
			*set army_size +10
		
		Magical lights suddenly rise around
		*if (currentfriend_name="None")
			you.
		*if (currentfriend_name!="None")
			you and ${currentfriend_name}.
		When the lights diminish, you see the wizards and the artifact and know that you are back in Brightwater.
		*goto Warprep_loop
	#Go to the elf queen in the Alderheart Forest.
		*set warprep_elves true
		*gosub Teleport
		*temp worm_hp 100
		The magical lights continue to fill your vision.  You hear the voice of one of the casting wizards.
		
		"We are experiencing some interference," the mage says from outside of the lights.  "The elven magic is repelling our attempts to place you in Oneiduin.  We'll transport you as close as we can.  You'll be in the Alderheart and the elven city will be to the south, Your Highness."
		
		You have no way to answer as the magical lights recede.  You find yourself standing in a dark snowy forest.  The trees are enormous and ancient.  The sun is completely blocked by the snow covered canopy overhead.
		*if (currentfriend_name!="None")
			
			"Which way is south?" ${currentfriend_name} asks.
		*if (currentfriend_name="None")
			There is no clear way to tell which direction is south.
		*label Elf_Find_South_loop
		*choice
			#Examine the moss growth on the trees.
				You had heard the old adage that moss only grows on the north side of trees.  You knock some of the snow off of a nearby trunk and look for moss.
				*if (nature>=45)
					You know of course that the saying is only partially true.  Moss grows all around the tree, but it grows slightly thicker on the north due to the fact that it enjoys more shade and the sun's rays are most diffuse from the north.  With this knowledge, you turn toward the south and begin walking.
					*if (showstats)
						*line_break
						(Nature +3)
					*set nature +3
					*goto Elf_South
				*else
					Unfortunately, you see moss all around it!  Perhaps that old saying is wrong, or means something else?
					*if (showstats)
						(Needed 45 Nature)
					*goto Elf_Find_South_loop
			#Cast a Divination spell to find south.
				*if (magic<20)
					You don't even know how to begin such a complicated spell.
					*if (showstats)
						(Needed 75 Magic)
					*goto Elf_Find_South_loop
				You take your time, not wanting to make a mistake with the incantation.  You feel a resistance to your magic.  It is likely the same resistance that the wizards felt.  The elven city is shielded and is preventing you from locating it.
				*if (magic>=75)
					You use the magical shield surrounding the elf city itself as a beacon.  The disruption of the scrying spell is coming from a certain direction.  Logic would dictate that Oneiduin lies in that direction.  With this knowledge, you begin walking toward the disruption.
					*if (showstats)
						*line_break
						(Magic +3)
					*set magic +3
					*goto Elf_South
				*else
					*if (showstats)
						(Needed 75 Magic)
					*goto Elf_Find_South_loop
			*if ((companion_type="fire elemental") and (companion_name!="None")) #Send ${companion_name} up through the snowy canopy to find out where the sun is.
				$!{companion_heshe} floats upward.  When ${companion_heshe} reaches the snow, the fire around ${companion_himher} melts a hole through it.
				*label Elf_Companion_South
				${companion_name} is gone for a few minutes, but when ${companion_heshe} returns, ${companion_heshe} is able to indicate which direction the sun lies.  It is still morning, so you know that way is east.  From there, you are able to find south.  You begin walking in the right direction.
				*goto Elf_South
			*if ((companion_type="water elemental") and (companion_name!="None")) #Send ${companion_name} up through the snowy canopy to find out where the sun is.
				$!{companion_heshe} floats upward.  When ${companion_heshe} reaches the snow, the water around ${companion_himher} melts a hole through it.
				*goto Elf_Companion_South
			*if ((companion_type="air elemental") and (companion_name!="None")) #Send ${companion_name} up through the snowy canopy to find out where the sun is.
				$!{companion_heshe} floats upward.  When ${companion_heshe} reaches the snow, the air around ${companion_himher} blasts a hole through it.
				*goto Elf_Companion_South
			*if ((((companion_type="owl") or (companion_type="firedrake")) or ((companion_type="griffin") or (companion_type="dove"))) and (companion_name!="None")) #Send ${companion_name} up through the snowy canopy to find out where the sun is.
				$!{companion_heshe} flies upward.  When ${companion_heshe} reaches the snow, ${companion_heshe} digs through it.
				*goto Elf_Companion_South
			#Climb a tree, dig through the snow and look for the sun.
				*if (cloak_of_spiders)
					The Cloak of Spiders makes your ascent much easier.  When you get to the top, you easily knock the snow away and see the sun shining.  Effortlessly, you climb back down the trunk.  Since it's early morning, you know the sun is in the east.  This allows you to find south and begin walking in the correct direction.
					*goto Elf_South
				You set your heavier belongings down on the ground before going up.
				*if ((strength>=40) and (agility>=40))	
					You manage to climb the trunk of a tree and knock the snow away to ascend even higher.  From there, you are able to see the sun.  Since it's early morning, you know the sun is in the east. You climb back down, gather your belongings and begin walking south.
					*if (showstats)
						*line_break
						(Strength +1 and Agility +1)
					*set strength +1
					*set agility +1
					*goto Elf_South
				*else
					You struggle to climb the tree and when you get to the top, you have trouble knocking the snow out of the way.  You finally dig a hole big enough to see the sun through when the branch you are standing on snaps!  You grab for another branch, but don't quite get it in time.  You fall to the ground with a solid thud.  At least you found what you needed.  Since it is early morning, the sun is in the east, so you know which direction south is.  You pick yourself up off the ground and begin walking in the correct direction.
					*set health -50
					*if (showstats)
						(Needed 40 Strength and 40 Agility)
						*line_break
						(Health -50 to ${health} / 100)
					*goto Elf_South
			*if (currentfriend_name!="None") #Ask ${currentfriend_name} to climb a tree.
				*if (currentfriend_relationship<60)
					"I don't think so, ${name}," ${currentfriend_name} says with a shake of ${currentfriend_hisher} head.
					*if (showstats)
						(Needed 60 ${currentfriend_name} Relationship)
					*goto Elf_Find_South_loop
				*if (currentfriend_name=jacejess_name)
					"I might have a better way," the Soulburner says.
					
					You watch as ${currentfriend_heshe} looks upward and ${currentfriend_hisher} eyes turn white with magic.  Twin beams of energy shoot up into the trees, melting a line in the snowy canopy above.  You see the error of this approach just as the circle completes and the snow-filled branches fall downward.  You and ${currentfriend_name} are hit by the debris.  You receive a few bruises, but ${currentfriend_name} breaks several bones from the branches and snow.  The only good thing is that you can see the sun through the hole and know which direction to go.  Battered and bruised, you and the chagrinned Soulburner begin walking in the correct direction.  You can't help but laugh quietly to yourself, knowing that you will be telling the story for years to come.
					*set health -35
					*if (showstats)
						*line_break
						(${jacejess_name} Relationship +15 and Health -35 to ${health} / 100)
					*set jacejess_relationship +15
					*set currentfriend_relationship +15
					*gosub Injure_CurrentFriend
					*goto Elf_South
				*if (currentfriend_name=theothea_name)
					"Okay, here I go," the big mountain-${theothea_manwoman} says.
					
					$!{currentfriend_name} isn't graceful, but at least ${currentfriend_heshe} is strong.  You watch ${currentfriend_himher} make it to the top and dig through the snow on the canopy.  $!{currentfriend_heshe} pokes ${currentfriend_hisher} head through the hole.  After a few minutes, ${currentfriend_heshe} climbs back down.
					
					"South is that way," ${currentfriend_heshe} says, pointing in a direction.
					
					$!{currentfriend_heshe} should have waited until ${currentfriend_hisher} feet were on the ground.  $!{currentfriend_heshe} loses ${currentfriend_hisher} balance and falls the rest of the way.  ${currentfriend_hisher} leg breaks with a sickening snap.  It is unfortunate, but at least you know the way.
					*gosub Injure_Currentfriend
					*goto Elf_South
				*if (currentfriend_name=gillgale_name)
					"Easy as pie," the thief says as ${currentfriend_heshe} looks upward.
					
					$!{currentfriend_name} has no problem climbing up the tree trunk and digging a hole in the snow on the canopy.
				*if (((currentfriend_name=karlkarla_name) or (currentfriend_name=branbrinn_name)) or (currentfriend_name=peterpetra_name))
					"Good idea," ${currentfriend_heshe} says, looking upward.
					
					$!{currentfriend_name} carefully climbs the tree trunk and digs a hole in the snow on the canopy.
				$!{currentfriend_heshe} pokes ${currentfriend_hisher} head through the hole.  After a few minutes, ${currentfriend_heshe} climbs back down.
				
				"South is that way," ${currentfriend_heshe} says, pointing in a direction.
				
				You turn to the south and begin walking in the indicated direction.
				*goto Elf_South
			*if (demonsummoner)
				*allow_reuse #Consider using a Demonstone.
					You open your runebag and consider your options.
					*choice
						*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and ((demonstone_xiatta_used=false) and (demonsummoner))) #Summon Xi'atta and tell it to fly up through the snowy canopy and tell you where the sun is.
							*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
							Xi'atta appears in front of you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
							
							"Yes, ${mastermistress}," Xi'atta says before flying upward.
							
							When Xi'atta reaches the snowy barrier over the canopy, it raises its tiny hands.  The snow moves of its own accord, creating a small hole that the demon flies through.  After a few minutes, Xi'atta returns and tells you where the sun lies.  Since it's early morning, you know the sun is in the east.  From there, you are able to find south.  You begin walking in the right direction as Xi'atta returns to its own realm.
							*goto Elf_South
						*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl and tell it to climb a tree.
							*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
							Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
							
							*if (willpower>=70)
								"Ugh, really?" Brahl says angrily.
								
								With no choice in the matter, the muscular demon attempts to do as you ask.  You watch as Brahl repeatedly fails to climb the icy trunk and eventually pops out of existence without getting any more than a few feet off the ground.
								*goto Elf_Find_South_loop
							*else
								"Climb it yourself," it says. The contest of wills is rejoined and the brawny demon pops out of existence.
								*if (showstats)
									(Needed 70 Willpower)
								*goto Elf_Find_South_loop
						*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and ((demonstone_zonch_used=false) and (demonsummoner))) #Summon Zon'ch and tell it to fly up through the snowy canopy and tell you where the sun is.
							*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
							Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one foot tall form.
							
							*if (willpower>=50)
								"Yes, ${mastermistress}," Zon'ch says before flying upward.
								
								When Zon'ch reaches the snowy barrier over the canopy, it blasts a small hole in it using a small burst of dusty wind.  It burrows through the tiny opening and disappears for a moment.  Soon after the demon returns and tells you where the sun lies.  Since it's early morning, you know the sun is in the east.  From there, you are able to find south.  You begin walking in the correct direction as Zon'ch returns to its own realm.
								*goto Elf_South
							*else
								"Too cold for me," the dusty demon rasps as the contest of wills is rejoined.  After a moment, Zon'ch  pops out of existence.
								*if (showstats)
									(Needed 50 Willpower)
								*goto Elf_Find_South_loop
						*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and ((demonstone_daanda_used=false) and (demonsummoner))) #Summon Daan'da and tell it to climb a tree.
							*comment Will of 0, but very stupid and weak.
							Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
							
							"Okay, ${mastermistress}," Daan'da says as it goes to the tree trunk.
							
							The thin demon tugs at the trunk of the tree, but doesn't have the strength to lift itself off the ground.  After a few minutes of trying, it pops out of existence.
							*goto Elf_Find_South_loop
						*if (((demonstone_tyborr) and (demonstone_tyborr_summoned)) and ((demonstone_tyborr_used=false) and (demonsummoner))) #Summon Tyborr and tell it to climb a tree.
							*comment Tyborr: Willing: 80, Small Struggle: 90, Against: 100
							Tyborr appears before you, wearing its brown robes.  The small five-and-a-half foot tall demon looks more like an old man with two stubby horns than a monster.
							
							"Do not call upon me," it says in a sad voice.  "I will not aid you."
							*if (showstats)
								(Needed 80 Willpower, which is not possible at this time)
							
							Its will is much greater than your own, but instead of taking control of you, it simply disappears.
							*goto Elf_Find_South_loop
						*allow_reuse #Close your runebag.
							*goto Elf_Find_South_loop

		*label Elf_South
		
		It is easy enough to walk along the forest floor, since the snow has gathered on the canopy above you.  The downside is that the forest is dark and full of shadows.
		*if (vampire)
			The lack of sun is strangely soothing to you.
		As you walk, you hear a grinding noise and feel the earth tremble beneath your feet.  Without any further warning, the ground explodes upward!  You see an enormous pink worm burrowing out of the ground.  The open maw of the worm is easily five feet in diameter and coming directly toward you.
		*label Elf_Worm_Firstcharge_loop
		*choice
			*if (sword) #Step aside and slash the forest worm with your sword.
				*if (blades>=60)
					Your sword slices a deep groove in the side of the worm as it passes by where you had been standing.
					*set worm_hp -50
					*if (showstats)
						*line_break
						(Blades +2 and Worm Health -50 to ${worm_hp} / 100)
					*set blades +2
					*goto Elf_Worm_CheckHealth1
				*else
					Your sword barely grazes the large worm as its teeth tear a large chunk of flesh from your arm as it passes.
					*set health -35
					*set worm_hp -10
					*if (showstats)
						(Needed 60 Blades)
						*line_break
						(Health -35 to ${health} / 100 and Worm Health -10 to ${worm_hp} / 100)
					*goto Elf_Worm_CheckHealth1
			*if (dagger) #Step aside and stab the forest worm with your dagger.
				*if (blades>=60)
					Your dagger pierces the soft side of the big worm and comes back out with a sticky splash as it passes by where you had been standing.
					*set worm_hp -35
					*if (showstats)
						*line_break
						(Blades +2 and Worm Health -35 to ${worm_hp} / 100)
					*set blades +2
					*goto Elf_Worm_CheckHealth1
				*else
					Your dagger barely scratches the large worm as its teeth tear a large chunk of flesh from your arm when it passes.
					*set health -35
					*set worm_hp -5
					*if (showstats)
						(Needed 60 Blades)
						*line_break
						(Health -35 to ${health} / 100 and Worm Health -5 to ${worm_hp} / 100)
					*goto Elf_Worm_CheckHealth1
			*if (magic_shield) #Hold up your magic shield between you and the worm.
				The force at which the worm smashes into your shield should have broken both your arms, but the magic of the shield absorbs the blow.  The worm crumples to the ground at your feet as the ringing sound of the blow slowly fades.
				*if (showstats)
					*line_break
					(Worm Health to 0 / 100)
				*goto Elf_Worm_Dead		
			*if (bow) #Step aside and fire arrows at the worm.
				It's nearly impossible to miss the big worm as it goes past. Although the arrows do very little damage to its enormous bulk, at least the monster veers slightly, trying to get away from you.
				*set worm_hp -10
				*if (showstats)
					*line_break
					(Archery +2 and Worm Health -10 to ${worm_hp} / 100)
				*set archery +2
				*goto Elf_Worm_CheckHealth1
			*if (demonsummoner)
				*allow_reuse #Consider using a Demonstone.
					You open your runebag and consider your options.
					*choice
						*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and ((demonstone_xiatta_used=false) and (demonsummoner))) #Summon Xi'atta.
							*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
							Xi'atta appears in front of you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
							*set demonstone_xiatta_used true
							
							The frosty demon doesn't get a chance to say anything as the large worm swallows it whole while passing you by!  You assume that Xi'atta returns to its own plane of existence as its physical form gets digested by the large monster.
							*goto Elf_Worm_CheckHealth1
						*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl.
							*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
							Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
							*set demonstone_brahl_used true
							
							The brawny demon doesn't get a chance to say anything as the large worm swallows it whole while passing you by!  You hear a lot of yelling occurring from within the worm's belly.  Suddenly, a demon claw erupts from the smooth flesh of the worm, followed by another and another as Brahl literally tears itself out of the worm.  The worm stops moving as Brahl disappears back to its own plane of existence with a blood covered smile on its face.
							*if (showstats)
								*line_break
								(Worm Health to 0 / 100)
							*goto Elf_Worm_Dead
						*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and ((demonstone_zonch_used=false) and (demonsummoner))) #Summon Zon'ch.
							*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
							Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one foot tall form.
							*set demonstone_zonch_used true
							
							The dusty demon doesn't get a chance to say anything as the large worm swallows it whole while passing you by!  You assume that Zon'ch returns to its own plane of existence as its physical form gets digested by the large monster.
							*goto Elf_Worm_CheckHealth1
						*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and ((demonstone_daanda_used=false) and (demonsummoner))) #Summon Daan'da.
							*comment Will of 0, but very stupid and weak.
							Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
							*set demonstone_daanda_used true
							
							The demon doesn't get a chance to say anything as the large worm swallows it whole while passing you by!  You assume that Daan'da returns to its own plane of existence as its physical form gets digested by the large monster.
							*goto Elf_Worm_CheckHealth1
						*if (((demonstone_tyborr) and (demonstone_tyborr_summoned)) and ((demonstone_tyborr_used=false) and (demonsummoner))) #Summon Tyborr.
							*comment Tyborr: Willing: 80, Small Struggle: 90, Against: 100
							Tyborr appears before you, wearing its brown robes.  The small five-and-a-half foot tall demon looks more like an old man with two stubby horns than a monster.
							
							"Do not…" it begins, but upon seeing the enormous worm jumping toward it with its mouth open wide, Tyborr simply returns to its own plane of existence before getting eaten.
							*if (showstats)
								(Needed 80 Willpower, which is not possible at this time)
							*goto Elf_Worm_CheckHealth1
						*allow_reuse #Close your runebag.
							*goto Elf_Worm_Firstcharge_loop
			#Cast a spell to move you out of harm's way.
				The nature of such a spell is that it has to be fast.  The enormous gaping maw of the worm looms larger and larger as it approaches you.
				*if (magic>=40)
					The very fabric of reality ripples and you find yourself standing a few feet away from where you were.  The worm has no familiar features to express surprise as it passes through the area where you had been standing.
					*if (showstats)
						*line_break
						(Magic +2)
					*set magic +2
					*goto Elf_Worm_CheckHealth1
				*else
					You don't quite complete the spell as the worm tears an enormous chunk of flesh from your side when it passes.
					*set health -75
					*if (showstats)
						(Needed 40 Magic)
						*line_break
						(Health -75 to ${health} / 100)
					*goto Elf_Worm_CheckHealth1
			#Throw some rocks away from you and stand still.
				*if (perception>=50)
					As the rocks land, the forest worm moves suddenly toward them.  Your hunch that it is feeling the vibrations of movement is correct.  You wait patiently as it burrows back into the ground.
					*if (showstats)
						*line_break
						(Perception +3)
					*set perception +3
					*goto Elf_TwoHoles_loop
				You watch as the rocks land and the worm turns toward them for a moment.  The creature doesn't fall for the distraction as it charges toward you and tears an enormous chunk of flesh from your side.  You briefly wonder if you would have had better luck had you thrown the rocks in another direction or different distance.
				*set health -75
				*if (showstats)
					(Needed 50 Perception)
					*line_break
					(Health -75 to ${health} / 100)
				*goto Elf_Worm_CheckHealth1
			*if (class_monk>0) #Use your monk training to dodge the worm.
				You wait patiently as the worm charges toward you.  At the last moment, you jump upward.  You soar high overhead as the worm continues to charge into the place you had been standing.  The worm strikes the tree with a resounding crash.  You land lightly on the ground as it shakes off the impact and burrows back into the ground near the tree's trunk.
				*if (showstats)
					*line_break
					(Agility +2)
				*set agility +2
				*goto Elf_TwoHoles_loop
			*if (class_druid>0) #Raise your hand and gently stroke the face of the giant worm.
				You know that the creature is simply reacting to a perceived threat or attempting to find food in a harsh winter.  It immediately slows down and closes its enormous mouth.  It allows you to place a calming hand on its face as it senses your druidic powers.
				*if (class_druid=1)
					A branch breaks somewhere in the forest and the worm starts.  It dives back into the ground and burrows away.  You continue walking, knowing that you have seen something wondrous.
					*if (showstats)
						(Needed More Druid Levels)
						*line_break
						(Nature +2 and Perception +2)
					*set nature +2
					*set perception +2
					*goto Elf_Oneiduin
				The worm lowers itself and you realize that you could ride it, if you wish.
				*if (showstats)
					*line_break
					(Nature +2 and Perception +2)
				*set nature +2
				*set perception +2
				*if (currentfriend_name!="None")
					
					${currentfriend_name} watches the display in amazement.
				*choice
					#Ride the worm.
						You put a leg over the worm and it begins to ripple beneath you.  It moves much faster than you would expect.
						*if (currentfriend_name!="None")
							${currentfriend_name} is forced to jog in order to keep up with you.
						*set wormrider true
						*goto Elf_Oneiduin
					#Release the worm back into the wild.
						The enormous worm nuzzles your hand one last time and then dives back into the ground.  You watch as it burrows away before you continue your journey.
						*goto Elf_Oneiduin
			#Dodge the worm as it passes.
				*if (agility>=35)
					You step aside as the worm flies past you.
					*if (showstats)
						*line_break
						(Agility +2)
					*set agility +2
					*goto Elf_Worm_CheckHealth1
				*else
					You clumsily try to step aside, but the worm tears an enormous chunk of flesh from your side as you narrowly avoid being swallowed whole.
					*set health -75
					*if (showstats)
						(Needed 35 Agility)
						*line_break
						(Health -75 to ${health} / 100)
					*goto Elf_Worm_CheckHealth1

		*label Elf_Worm_CheckHealth1
		*if (health<=0)
			*label Elf_Rescued
			*page_break Darkness…
			Your eyes open slowly and you see the branches overhead moving past you.  It takes a few more minutes until you realize that you are being carried by a group of elves!  When they see that you are conscious, they set you down.
			*if (currentfriend_name!="None")
				You see ${currentfriend_name} is walking with the elves.  $!{currentfriend_heshe} looks as badly injured as you are, but at least ${currentfriend_heshe} is still alive.
				*gosub Injure_CurrentFriend
			*if (showstats)
				*line_break
				(Health 10 / 100)
			*set health 10
			
			"You are lucky we came by when we did," one of the elves says.  "Forest worms are usually pickier eaters, but it has been a difficult winter for them.  Come, we are here."
			*goto Elf_Oneiduin
		*else
			*goto Elf_Worm_2

		*label Elf_Worm_2
		
		*if (currentfriend_name!="None")
			*if (currentfriend_injured)
				Due to ${currentfriend_hisher} injuries, ${currentfriend_name} barely dodges the worm as it goes by.
				*goto Elf_Worm_3
			*else
				*temp elf_friend_dam 0
				*if (currentfriend_name=theothea_name)
					${theothea_name} slams ${theothea_hisher} solid hammer into the worm as it passes.
					*set elf_friend_dam 50
				*if (currentfriend_name=gillgale_name)
					${gillgale_name} twirls and slashes ${gillgale_hisher} twin blades into the worm as it passes.
					*set elf_friend_dam 35
				*if (currentfriend_name=karlkarla_name)
					${karlkarla_name} puts an arrow to ${karlkarla_hisher} string and sends it into the side of the worm.  The talented archer follows the first arrow with two more before the worm passes.  Unfortunately, the arrows hardly faze the big monster.
					*set elf_friend_dam 10
				*if (currentfriend_name=peterpetra_name)
					${peterpetra_name} drives ${peterpetra_hisher} morningstar into the side of the worm as it goes by.
					*set elf_friend_dam 35
				*if (currentfriend_name=jacejess_name)
					${jacejess_name} burns the worm across the side of its body with a twin pair of lights from ${jacejess_hisher} eyes as it goes by.
					*set elf_friend_dam 35
				*if (currentfriend_name=branbrinn_name)
					${branbrinn_name} waits until the worm passes and then slashes ${branbrinn_hisher} longsword across the creature's side.
					*set elf_friend_dam 50
				*set worm_hp -elf_friend_dam
				*if (showstats)
					*line_break
					(Worm Health -${elf_friend_dam} to ${worm_hp} / 100)
				*if (worm_hp<=0)
					*goto Elf_Worm_Dead
				*if (showstats)
					
					*comment endif
				*goto Elf_Worm_3
		*else
			*comment no friends
			*goto Elf_Worm_3

		*label Elf_Worm_3
		You still can't accurately judge its length as it burrows into the ground behind you.  Once more you feel the grinding vibration beneath you, but the only sign of the worm is the two large holes it has left behind.
		*label Elf_TwoHoles_loop
		*choice
			#Leave the holes alone.
				You
				*if (currentfriend_name!="None")
					and ${currentfriend_name}
				know that the forest worm isn't your fight.  You have come for the elves, not to battle random monsters.  You walk away from the holes and after a few minutes, you find yourself far from the danger.  You continue walking toward the south.
				*goto Elf_Oneiduin
			#Lay a trap for the worm.
				You have a few ideas that might work.
				*if (rope=false)
					Unfortunately, they all include the use of a rope.  Any other ideas for a trap would take too long to construct.
					*goto Elf_TwoHoles_loop
				You cut several long branches into pointed spears and tie them to a big log.  You then tie the log to your rope and hoist the spiked contraption into the air.  Sure enough, the worm burrows up once more.  You simply release the rope and watch as the heavy log falls
				*if (devices>=45)
					onto the worm and the sharpened sticks pierce it in many places.  The worm twitches once and then falls still.  You take a moment to retrieve your rope.
					*if (showstats)
						*line_break
						(Devices +2 and Worm Health 0 / 100)
					*set devices +2
					*goto Elf_Worm_Dead
				*else
					to the ground beside the worm.  The large beast burrows back into the ground immediately.  You hear nothing from below you, telling you that the big creature has left.  You take your rope back and continue walking.
					*if (showstats)
						(Needed 45 Devices)
					*goto Elf_Oneiduin
			#Wait for the worm to return.
				Several minutes pass and you begin to wonder if the worm has left the area.
				*if (perception<40)
					You feel a sudden vibration a moment too late and see that the ground is opening directly underneath you!  You have no time to move
					*label Elf_Swallowed
					as the worm's enormous mouth engulfs your legs and continues to rise, threatening to swallow you whole!  You see movement in the trees as elves rush into the clearing, but the worm continues to rise around you until your view is blocked.
					*if (showstats)
						(Needed 40 Perception and 40 Agility)
						*line_break
						(Health 0 / 100)
					*set health 0
					*goto Elf_Rescued
				*else
					You feel a sudden vibration and realize that the worm is directly beneath you!
					*if (agility<40)
						You attempt to jump out of the way, but you are too slow
						*goto Elf_Swallowed
					You jump out of the way without a moment to spare as the worm bursts out of the ground directly where you had been standing!
					*if (showstats)
						*line_break
						(Perception +2 and Agility +2)
					*set perception +2
					*set agility +2
					
					You see movement all around you as elves appear from among the trees.  Their bows twang as the worm becomes riddled with arrows.  Two elves draw shining longswords and nimbly jump into battle, slashing at the worm until it stops moving.
					*if (showstats)
						*line_break
						(Worm Health 0 / 100)
					
					"Welcome to Oneiduin," one of the elves says as he wipes his blade clean with a rag.  "The forest worms are usually pickier eaters, but it has been a difficult winter for them."
					*goto Elf_Worm_Dead

		*label Elf_Worm_Dead
		
		The enormous worm twitches a few times as it lays on the forest floor.  You see its belly ripple and pulse.  It suddenly bursts open as a litter of young wormlings pour forth and disappear into the soil.  You see bits and pieces of armour, broken weapons and clothing from the worm's previous victims.  You also see a lot of shiny gold coins.
		*if (showstats)
			*line_break
			(Gold +267)
		*set gold +267
		
		You gather the gold and continue walking, leaving the horrific corpse behind.
		*goto Elf_Oneiduin

		*label Elf_Oneiduin
		
		You can feel the change in the air as you pass from one set of trees and into another.  The snow-filled canopy disappears overhead, revealing the bright light of the sun.
		*if (vampire)
			Its rays are uncomfortable to you, making you squint.
		You see many wooden walkways spanning the treetops and the weather is milder, no longer feeling like winter.  Hundreds of elves cover the walkways, standing between the trunks.  Some carry swords and many carry bows.  You have made it to the famed elven city of Oneiduin.
		
		You are surprised to see a half-elf come out to greet you.  Although elves are more accepting of their half-human progeny than orcs, you know that half-elves rarely rise to power in their society.  Your greeter is middle-aged, clean-shaven and more solidly built than the elves.  He is well-dressed and his black hair has white slivers and is sharply cut to his shoulders.
		
		"Greetings," he says in a very deep
		*if (wormrider)
			voice, looking more at your odd mount than at you.  "I have never seen anyone tame a forest worm before.  I
		*if (wormrider=false)
			voice.  "I
		am Naistalan Mubashair.  I am a cleric of the Light Bringing Goddess Auriel and I have been sent to greet you in the name of our queen."
		*label Elf_Intro_loop
		*choice
			*if ((holysymbol) and (god_good)) #Say, "I am $!{princeprincess} ${name}, follower of ${god_name}, and I come to seek an alliance with the elves."
				"Welcome.  Yes, an alliance is desired by us as well,"
				*goto Elf_Greet
			#Ask, "Why is the queen not here?"
				"She is giving birth to our heir.  I have been asked to give you our full support in her name,"
				*goto Elf_Intro_loop
			#Say, "I am $!{princeprincess} ${name}.  I have need of your warriors."
				"And you shall have them,"
				*goto Elf_Greet
			#Say, "I am $!{princeprincess} ${name}.  I have come to tell you of a great danger."
				"We know why you have come,"
				*goto Elf_Greet
			#Say, "I am $!{princeprincess} ${name}.  I seek an alliance with the elves."
				"We accept,"
				*goto Elf_Greet
			#Say, "I am $!{princeprincess} ${name}.  Let me guess, you have some task you need me to perform before your people will help me."
				The half-elf laughs at your words, an almost devilish smirk on his square jaw.
				
				"No, $!{princeprincess} ${name}, there are no hoops for you to jump through,"
				*goto Elf_Greet

		*label Elf_Greet
		the half-elf says.  "We understand the dangers of your demon-summoning enemies and we will do everything in our power to help you regain your stolen kingdom and stop the threat.  I will accompany the elven troops myself."
		*rand coinflip 1 2
		*comment for forest worm gender
		*choice
			#Ask, "How do you know of our problems?"
				"We aren't as far removed from the world as your people may think," Naistalan says with a smile.  "We have been watching you since you first arrived near our lands."
				
				You realize that Naistalan isn't referring to you, but rather the first human arrival, which occurred thousands of years ago.
				*goto Elf_Greet_After_Explanation
			#Ask, "What do you know about Zusak?"
				"Only that he is the High-Chancellor of the Consortium," Naistalan replies.  "And that he is the one who has sent the Demonstones into the hands of the untrained."
				*goto Elf_Greet_After_Explanation
			#Ask, "Are you using magic to spy on us?"
				"There is no need for such drastic measures," Naistalan says.  "Although I am sure that the elven spell-weavers could do so, if they wished.  We have simply been watching the events unfold and we see the inherent dangers."
				*goto Elf_Greet_After_Explanation
			#Ask, "So, you will help us?"
				"Yes, of course," Naistalan replies.
				*goto Elf_Greet_After_Explanation

		*label Elf_Greet_After_Explanation
		*if (wormrider)
			
			*temp worm_himher
			*if (coinflip=1)
				*set worm_himher "him"
			*if (coinflip=2)
				*set worm_himher "her"
			"Allow me to take your…mount," Naistalan says.  "I shall find a safe place for ${worm_himher} to rest."
			
			You know that the magic that will bring you back to Brightwater will not bring the forest worm back with you.
			*if (mount_name!="None")
				You already have ${mount_name}, your ${mount_type}, but you could ride the worm into battle instead.
			*choice
				#Ask, "Naistalan, can you bring ${worm_himher} to Brightwater when you come with your warriors?"
					*if (mount_name!="None")
						*set mount_sold_at_distance mount_value
					"Yes, ${name}," he says with a smile.  "I will do as you ask.  What do you call ${worm_himher}?"
					*choice
						#Tremor.
							*set mount_name "Tremor"
							*goto Done_Naming_Worm
						#Gipps.
							*set mount_name "Gipps"
							*goto Done_Naming_Worm
						#Warragul.
							*set mount_name "Warragul"
							*goto Done_Naming_Worm
						#Wyrm.
							*set mount_name "Wyrm"
							*goto Done_Naming_Worm
						#Something else.
							*label Name_Forest_Worm
							*input_text mount_name
							*if (mount_name="None")
								You must name the forest worm something!
								*goto Name_Forest_Worm
							*goto Done_Naming_Worm

					*label Done_Naming_Worm
					*set mount_type "forest worm"
					*if (worm_himher="him")
						*set mount_himher "him"
						*set mount_hisher "his"
						*set mount_heshe "he"
					*if (worm_himher="her")
						*set mount_himher "her"
						*set mount_hisher "her"
						*set mount_heshe "she"
					*set mount_value 0
					*set mount_level 6
					*achieve sweetride
					*set mount_desc "a wild"
					"I will see to ${mount_hisher} safe arrival myself."
					*goto Elf_Greet2
				#Tell the worm to return to the forest.
					The worm does as you ask.  It slithers back the way you came and then dives into the frozen earth, burrowing away to safety.  The elves all watch with expressions of genuine amazement on their faces.
					*set wormrider false
					*goto Elf_Greet2
		*else
			*goto Elf_Greet2

		*label Elf_Greet2
		
		The half-elf continues, "I wish that we had greater numbers to send to your aid. There are not as many elves in the world as there are humans. We must leave some of our warriors to guard our homes, but I shall personally accompany a troop of our finest archers to Brightwater. We will be there as the snow melts, you have my word."
		*if (showstats)
			*line_break
			(Army Power +5, Army Size +7 and Army Morale +5)
		*set army_power +5
		*set army_size +7
		*set army_morale +5
		
		You
		*if (currentfriend_name!="None")
			and ${currentfriend_name}
		are led through Oneiduin. The wondrous city of the elves is truly magical to behold. The rope bridges arc beautifully from treetop to treetop. The harsh winter doesn't seem to reach the elven city and many of the trees are covered in gorgeous blossoms. You soon arrive at a humble looking temple devoted to Auriel.  The half-elf leads you into the private chambers in the back.
		
		"Pardon the mess," Naistalan says, although his home looks very well-kept. "I have just returned to Oneiduin myself. Unfortunately, I have had a very troubling couple of months."
		*choice
			#Ask, "Is there anything I can help you with?"
				The half-elf studies your face for a moment before answering.
				
				"Perhaps you could be of assistance,"
				*goto Naistalan_Story
			#Say, "How does a half-breed like yourself rise to such a prominent position?"
				Naistalan tenses at your words, but then sighs.
				
				"It is true. Half-elves are not looked upon favourably by pure-blood elves. I enjoy an elevated position because of my ancestors,"
				*goto Naistalan_Story
			#Ask, "What happened?"
				"To explain this, I must tell you a little about myself," 
				*goto Naistalan_Story
			#Say nothing.
				The half-elf takes your silence as an indication to continue talking.
				
				*goto Naistalan_From_Silence

		*label Naistalan_Story
		he says.
		*label Naistalan_From_Silence
		"My family is well-honoured by the Goddess Auriel Herself."
		
		As he speaks, he removes the fancy leather bracers from his wrists. Each one has the face of a lion etched into it with vapours rising off the leather as though the lions are breathing. He also removes his longsword and his helm.
		
		I suppose there is no point in keeping this a secret," he continues. "Many centuries ago, an ancestor of mine named Rissa Mubashair met Auriel, the Goddess of Light. I know, this is hard to believe, but it is true. She was a young pregnant girl and she nearly drowned in a river not far from Oneiduin. The Goddess took pity upon her and made the sunbeams solid so she could pull herself to shore.
		
		"They talked for hours, although the contents of that conversation are lost in time. The evil Goddess Shadi became intrigued that Auriel would spend time with a mortal girl. That night, Shadi sent Shadows into the girl's home and strangled her to death. The rules of the Gods are not for mortals to understand, but Auriel was unable to bring her back.
		
		"When the morning light reached the dead girl, Auriel saw what Shadi had done.  Auriel helped birth the child and cried for Rissa, the child's mother.  A single tear solidified in the baby's hand.  This teardrop allowed the child to contact Auriel and it has been passed down through my family for generations.  We call it Auriel's Grief."
		*choice
			#Ask, "What happened next?"
				Naistalan continues to speak.
				*goto Naistalan_Stolen
			#Ask, "How does this affect me?"
				"It doesn't," Naistalan says. "Besides the fact that I have returned to Oneiduin to get help to retrieve it, and so I was here for the queen to ask me to aid you.  You see, the teardop is missing."
				*goto Naistalan_Stolen
			#Say, "Let me guess.  Someone stole it."
				"So it would seem," Naistalan says.
				*goto Naistalan_Stolen
			#Ask, "Can I use this teardop to gain Auriel's aid?"
				"Perhaps, except for the fact that it is gone," Naistalan says.
				*goto Naistalan_Stolen
			#Say nothing.
				Naistalan continues to speak.
				*goto Naistalan_Stolen

		*label Naistalan_Stolen
		
		*set teardrop_known true
		"Auriel's Grief was taken from my family's shrine last spring.  We have been using it to protect the elves for centuries.  It isn't safe in the world.  Shadi played one last evil trick on Auriel by allowing her shadow to pass over it.  Although it still contacts Auriel, it also contacts the other Gods and Goddesses.  The Mubashair family line train their entire lives so they can contact Auriel, but an uninitiated person is more likely to find themselves in communion with one of the many trickster Gods instead of our Fair Lady."
		*if (teardrop)
			
			You realize that you have already found the teardrop.  Lomi, the invisible halfling, must have been the thief who stole it.  You tried to make it work again, but were unable to, so you left it in Brightwater.
			*label Elf_Has_Teardrop_loop
			*choice
				#Say, "I have found Auriel's Grief."
					"Auriel be praised!" the cleric exclaims.  "This is wonderful news!"
					*if (showstats)
						*line_break
						(Good +3)
					*set good +3
					
					You tell Naistalan about Lomi and how he had turned himself invisible.  You explain it is currently sitting in Brightwater, since you didn't know what it was.  His entire demeanor changes and his movements are filled with a renewed purpose.
					
					I owe you everything, ${name}," Naistalan says in his deep voice.  "I will not abandon my duties to you.  I shall gather the elves and claim Auriel's Grief in the spring when I bring them to Brightwater."
					*set naistalan_quest "has and told"
					*goto Elf_Conclusion
				#Say, "I hope you find it."
					"Thank you," Naistalan says.  "I will spend the remainder of the winter searching, but fear not, I shall make sure that the elves are ready to fight come spring.  If I still haven't found it, I shall resume my search after you have defeated the demon summoners."
					*set naistalan_quest "has but silent"
					*goto Elf_Conclusion
				#Ask, "How much would such an artifact be worth?"
					"Its value transcends material wealth," the cleric says.
					*goto Elf_Has_Teardrop_loop 
				#Ask, "How do you use it?"
					"We simply hold it and pray.  Our Goddess finds us and gives us what we need.  All members of my family line train their entire lives for this event.  You see, each person may only use Auriel's Grief a single time.  After its use, we keep it safe for our descendants."
					
					It isn't difficult to realize that you have already used up your chance with the artifact.  Like Lomi, you didn't know the necklace's limits or function.  The halfling thought it had granted wishes.  It's impossible to say which God or Goddess had turned him invisible or which had obeyed your ignorant plea.
					*goto Elf_Has_Teardrop_loop 
				#Say nothing more about the teardrop.
					It is clear that the half-elf greatly desires the divine artifact.  You will be seeing him again in the spring.  You say nothing about the fact that his family's heirloom is sitting in your room back in Brightwater.
					*set naistalan_quest "has but silent"
					*goto Elf_Conclusion
		*else
			*set naistalan_quest "heard"
			*label Elf_No_Teardrop_loop
			*choice
				#Ask, "How was it stolen?"
					"Truly, I do not know.  My only guess is that a very stealthy thief came into my family's shrine and took it.  I have returned to Oneiduin to gather some of our most skilled trackers and magical diviners, although I fear that the artifact will hide itself from most types of searching."
					*goto Elf_No_Teardrop_loop
				#Ask, "How much would such an artifact be worth?"
					"Its value transcends material wealth," the cleric says.
					*goto Elf_No_Teardrop_loop 
				#Ask, "How do you use it?"
					"We simply hold it and pray.  Our Goddess finds us and gives us what we need.  All members of my family line train their entire lives for this event.  You see, each person may only use Auriel's Grief a single time.  After its use, we keep it safe for our descendants."
					*goto Elf_No_Teardrop_loop
				#Say nothing more about the teardrop.
					The topic of conversation turns to other things.
					*goto Elf_Conclusion
				#Say, "If I find it, I will let you know."
					Naistalan thanks you, although you both know that the chances of you stumbling across his precious family heirloom is next to none.
					*goto Elf_Conclusion

		*label Elf_Conclusion
		
		The two weeks among the elves are very calming.  Naistalan is an excellent host and you are visited by many elves during your stay.  You hear that the Elf Queen has given birth to a healthy girl, but you don't get a chance to meet the Elf Princess.
		*choice
			#Spend the days with the elven hunters.
				The elves happily take you out on their hunts.  Their quiet movements and skilled use of the bow border on the supernatural.  They show you many things as you spend the days hunting small game.
				*if (currentfriend_name=karlkarla_name)
					${karlkarla_name} comes out of ${karlkarla_hisher} shell and makes friends with the elves quickly.  You can tell that ${karlkarla_heshe} is happier to be among the fey creatures than with humans.
					*if (showstats)
						*line_break
						(${karlkarla_name} Relationship +3, Archery +2, Stealth +2 and Nature +2)
					*set karlkarla_relationship +3
					*set archery +2
					*set stealth +2
					*set nature +2
					*goto Elf_Lights
				*if (showstats)
					*line_break
					(Archery +2, Stealth +2 and Nature +2)
				*set archery +2
				*set stealth +2
				*set nature +2
				*goto Elf_Lights
			#Spend the days with the elven spellweavers.
				The spellweavers look as youthful as everyone else, but you see the flicker of ancient knowledge in their eyes.  They discuss many things with you.  You realize that you would need a lifetime to learn a fraction of what they know.
				*if (currentfriend_name=jacejess_name)
					${jacejess_name} is astounded to learn that the elves don't find Soulburning wrong at all.  Instead, the elves see the gift as a beautiful way to influence the world through a natural talent.  You can't help but to wonder how ${jacejess_name}'s personality would have been different had ${jacejess_heshe} been raised among the gentle elves.
					*if (showstats)
						*line_break
						(${jacejess_name} Relationship +3, Magic +3, Perception +2 and Arcana +5)
					*set jacejess_relationship +3
					*set magic +3
					*set perception +2
					*set arcana +5
					*goto Elf_Lights
				*if (showstats)
					*line_break
					(Magic +3, Perception +2 and Arcana +3)
				*set magic +3
				*set perception +2
				*set arcana +3
				*goto Elf_Lights
			#Spend the days talking to Naistalan about Auriel.
				Like any other priest, Naistalan is eager to talk to you about his Goddess.
				*if (god_name="Auriel")
					The fact that you also worship the Mistress of Light makes your conversations a joy to both of you.
					*if (showstats)
						*line_break
						(Religion +7, History +5, Geography +5 and Arcana +5)
					*set religion +7
					*set history +5
					*set geography +5
					*set arcana +5
					*goto Elf_Lights
				*if (god_good=false)
					The fact that you secretly serve an evil God makes such talks difficult to hear, but also valuable.  Every fighter knows that you must know your enemy.
				*if (currentfriend_name=peterpetra_name)
					${peterpetra_name} greatly enjoys the discussions as well.
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship +3, Religion +7, History +5, Geography +5 and Arcana +5)
					*set peterpetra_relationship +3
					*set religion +7
					*set history +5
					*set geography +5
					*set arcana +5
					*goto Elf_Lights
				*if (showstats)
					*line_break
					(Religion +5, History +3, Geography +3 and Arcana +3)
				*set religion +5
				*set history +3
				*set geography +3
				*set arcana +3
				*goto Elf_Lights
			#Spend the days with the elven warriors who will be joining you in the spring.
				The men and women who have agreed to march with you are all excellent archers and fighters.  They are devoted to the cause of protecting their elven brethren and all of Daria.  Their aid in the upcoming war will be of great value.
				*if (currentfriend_name=branbrinn_name)
					Captain ${branbrinn_name} is very happy to gauge the strength of your new allies.
					*if (showstats)
						*line_break
						(${branbrinn_name} Relationship +3, Army Morale +3, Blades +3 and Archery +3)
					*set branbrinn_relationship +3
					*set army_morale +3
					*set blades +3
					*set archery +3
					*goto Elf_Lights
				*if (showstats)
					*line_break
					(Army Morale +3, Blades +3 and Archery +3)
				*set army_morale +3
				*set blades +3
				*set archery +3
				*goto Elf_Lights
			#Spend the days listening to the elders telling their stories.
				You sit among the elven children as the elders talk about the past.  You can't help but to become enraptured by their stories.  Their ancient lore makes your human history seem pale by comparison.  The elves have been in the Alderheart since long before your kind arrived.
				*if (showstats)
					*line_break
					(History +5, Charm +3 and Geography +5)
				*set history +5
				*set charm +3
				*set geography +5
				*goto Elf_Lights

		*label Elf_Lights
		
		At the end of your stay, Naistalan bids you farewell as the magical lights rise around you.  Moments later, you find yourself back in Brightwater.
		*if (wormrider)
			You tell the stablemaster that you will no longer be needing your old mount.  He gets a fair price for the animal and gives you the proceeds.
			*if (showstats)
				*line_break
				(Gold +${mount_sold_at_distance})
			*set gold +mount_sold_at_distance
		*if (teardrop)
			*set teardrop_holding true
		*set elf_help 2
		*goto warprep_loop
	#Go to the gnomes.
		*set warprep_gnomes true
		*gosub Teleport
		*temp used_guild_sign
		*set used_guild_sign false
		As the magical lights fall away, you are surprised to see that you recognize the tall buildings around you.  You are in Tornassa, former capital of Daria and
		*if (warprep_uddodead)
			home to Duchess Selina!
		*if (warprep_uddodead=false)
			home to Duke Uddo!
		You were supposed to have been sent to the gnomes; why are you in the middle of the biggest human city on the continent?
		
		*if (questdetails="the city of Tornassa")
			You had hidden here during your time in exile, but now that your true identity has been revealed,
		*if (questdetails!="the city of Tornassa")
			You hadn't been back since the horrific night your parents were killed.  Perhaps it would have been okay to come before you revealed your identity, but now that everyone knows who you are,
		Tornassa is no longer safe for you.
		*if (currentfriend_name!="None")
			
			"What is this?" ${currentfriend_name} says.  "I thought we were supposed to have been sent to the gnomes?"
		
		You look up and down the dark alley.  At least there are no people about.  Judging from the three-storey stone buildings lining the road, you guess that you are in the warehouse district.  Suddenly, you hear a suspicious noise from behind you.  Nothing was there a moment ago.  Someone snuck up on you!
		*label Gnome_Man_Behind_loop
		*choice
			*if (sword) #Draw your sword quickly and stab backward.
				The sword flies out of its sheath and reverses direction, slamming backward and into your attacker.  You hear a low grunt of pain.  You turn around and see the man slide off your blade.
				*label Alley_Blade
				*if (showstats)
					*line_break
					(Blades +2)
				*set blades +2
				*goto Alley_Deadman
			*if (dagger) #Draw your dagger, spin and throw!
				Your attacker is caught by surprise as your dagger embeds itself into his chest.  He clutches the blade's hilt, but it is too late.  He falls to the ground with a startled expression on his face.  You quickly retrieve your blade.
				*goto Alley_Blade
			*if (currentfriend_name!="None") #Curl your finger in front of your chest to indicate to ${currentfriend_name} that someone is following.
				*if (currentfriend_name=theothea_name)
					The mighty warrior draws ${theothea_hisher} hammer and swings.  The person behind you doesn't stand a chance as the enormous mallet smashes into his head, killing him instantly.
					*if (showstats)
						*line_break
						(${theothea_name} Relationship +2)
					*set theothea_relationship +2
				*if (currentfriend_name=peterpetra_name)
					The holy warrior draws ${peterpetra_hisher} morningstar and swings.  The person behind you doesn't stand a chance as the spiked ball smashes into his head, killing him instantly.
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship +2)
					*set peterpetra_relationship +2
				*if (currentfriend_name=jacejess_name)
					The Soulburner's eyes glow bright white as ${jacejess_heshe} turns ${jacejess_hisher} head.  The beam slices off the top of the man's head, killing him instantly.
					*if (showstats)
						*line_break
						(${jacejess_name} Relationship +2)
					*set jacejess_relationship +2
				*if (currentfriend_name=karlkarla_name)
					The archer draws ${karlkarla_hisher} bow and puts an arrow to the string while shielding ${karlkarla_hisher} actions with ${karlkarla_hisher} body.  With a twirl and a release, the arrow is fired into the man's chest, killing him instantly.
					*if (showstats)
						*line_break
						(${karlkarla_name} Relationship +2)
					*set karlkarla_relationship +2
				*if (currentfriend_name=gillgale_name)
					The thief nods as ${gillgale_heshe} draws a dagger from ${gillgale_hisher} sleeve.  With a twirl and a release, the blade is thrown into the man's chest, killing him instantly.
					*if (showstats)
						*line_break
						(${gillgale_name} Relationship +2)
					*set gillgale_relationship +2
				*if (currentfriend_name=branbrinn_name)
					The captain of the guard draws ${branbrinn_hisher} longsword and swings as ${branbrinn_heshe} turns.  The man behind you doesn't stand a chance as the blade cuts deeply into his neck, killing him instantly.
					*if (showstats)
						*line_break
						(${branbrinn_name} Relationship +2)
					*set branbrinn_relationship +2
				*goto Alley_Deadman
			*if (bow) #Shoot the man with your bow.
				You carefully take an arrow from your quiver and put it to the string while shielding your actions with your body.  With a twirl and a release, you fire the arrow into the man's chest, killing him instantly.
				*if (showstats)
					*line_break
					(Archery +2)
				*set archery +2
				*goto Alley_Deadman
			#Step backwards and swing your elbow into the man's face at the same time.
				You feel your elbow connect solidly with someone's face.  When you turn around, you see the man falling backward and his eyes rolling upward in his head.  He falls flat on his back in the street and his head bounces off the stones.  You aren't sure which head injury kills him, but either way, he is dead.
				*if (showstats)
					*line_break
					(Unarmed +2)
				*set unarmed +2
				*goto Alley_Deadman
			*if (((companion_type="bear") or (companion_type="owlbear")) and (companion_name!="None")) #Signal to ${companion_name} to take care of the threat.
				Although ${companion_name} hasn't reached ${companion_hisher} full size yet, ${companion_heshe} is still deadly.  
				*goto Gnome_Companion_Killed_It
			*if (((companion_type="wolf") or (companion_type="dog")) and (companion_name!="None")) #Signal to ${companion_name} to take care of the threat.
				As a ${companion_type}, ${companion_name} is used to circling around prey and attacking it from the most strategical advantage point.  
				*goto Gnome_Companion_Killed_It
			*if ((companion_type="firedrake") and (companion_name!="None")) #Signal to ${companion_name} to take care of the threat.
				${companion_name} may not have the size of a dragon, but ${companion_hisher} teeth and claws are just as sharp.
				*label Gnome_Companion_Killed_It
				Your would-be attacker is so focused on attacking you that your ${companion_type} easily slips around him and springs upon the man.  By the time you turn around, you see that the man is dead.  ${companion_name} sits next to the corpse with a bloodstained smile on ${companion_hisher} face.
				*goto Alley_Deadman
			#Set the man on fire with magic.
				You don't know how much time you have before he will attack.  Carefully, you say the magic words and build the flame in your hands.  With your back to the man, he doesn't notice your gestures or see your lips moving.  He gives you all the time you need to finish the spell.  You turn and release the magic.  The man bursts into flames and falls to the street, dead.
				*if (showstats)
					*line_break
					(Magic +2)
				*set magic +2
				*goto Alley_Deadman
			*if ((demonsummoner) and (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner)))) #Summon Brahl and tell it to defend you.
				You shield your runebag with your body and carefully open it, without the man behind you seeing.  The moment you touch the stone and concentrate, Brahl appears behind your would-be attacker.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
				
				"Defend me," you say simply.
				
				The demon wraps its thick arms around the man's head and twists.  You hear a crunch as Brahl breaks your attacker's neck.  This crunch is followed by a soft pop as the brawny demon returns to its own plane.
				*goto Alley_Deadman
			#Turn around and speak to the sneaky man.
				*goto Meet_Gnome

		*label Alley_Deadman
		
		The dead man who snuck up on you is not what you had expected.  He is short and looks very old.  This doesn't change the fact that he had managed to get right behind you in a dark alley.  A second noise catches your attention; this time, it comes from the roof above.  You see a young boy who looks more like a traditional thief, wearing leather armour and wielding a short sword.  Tornassa is crawling with thieves!
		
		"The city guard is coming," the boy on the roof says nonchalantly.  "I can get
		*if (currentfriend_name="None")
			you away safely, for 100 gold."
		*if (currentfriend_name!="None")
			you both away safely for 100 gold each."
		
		The sounds of footsteps on both sides of the alley seem to corroborate his words.
		*label Bottom_Wall_Thief_Offer
		*choice
			#Say, "Okay, I'll pay."
				"Money first, my friend," the boy says.  "Toss it up."
				*choice
					*if (currentfriend_name="None")
						*selectable_if (gold>=100) #Give the boy the gold.  (Needs 100 Gold)
							You quickly take out the sum and throw it up to the boy, glad that you had the heavier 100-gold-piece on hand so you didn't have to spend precious moments counting out 100 coins.
							*if (showstats)
								*line_break
								(Gold -100)
							*set gold -100
							*goto Gnome_Thieves
					*if (currentfriend_name!="None")
						*selectable_if (gold>=200) #Give the boy the gold.  (Needs 200 Gold)
							You quickly take out the sum and throw it up to the boy, glad that you had the heavier 100-gold-pieces on hand so you didn't have to spend precious moments counting out 200 coins.
							*if (showstats)
								*line_break
								(Gold -200)
							*set gold -200
							*goto Gnome_Thieves
					*if (class_thief>0) #Use the Thieves' Cant to show the boy that you are a dues paying member of the Guild.
						"Why didn't you say so?" the boy says with a grin.
						*set used_guild_sign true
						*goto Gnome_Thieves
					#Say, "I don't have the money!"
						"Too bad for you," the boy says.
						
						The thief backs out of view just as the guards pour into the alley.
						*goto Gnome_Alley_Guards
			#Try to climb the side of the building without the boy's help.
				*if (agility<40)
					You awkwardly search for something to hold on to and pull yourself up, but the sheer wall is beyond your abilities to climb.
					*if (showstats)
						(Needed 40 Agility)
					*goto Bottom_Wall_Thief_Offer
				You carefully find small edges in the stone wall to climb up.  You demonstrate a tremendous feat of skill as you slowly begin to ascend.
				*if (showstats)
					*line_break
					(Agility +2)
				*set agility +2
				
				*goto Gotta_Pay_Toll
			*if (cloak_of_spiders) #Use the Cloak of Spiders to scale the side of the building.
				You climb up the sheer brick wall as the boy watches in amazement.  
				*label Gotta_Pay_Toll
				You are just about to climb onto the roof when the thief grins.
				
				"Gotta pay the toll," he says as he gives you a push.
				
				You fall through the air and land on your back in the middle of the street.  Your head bounces off the road, knocking you unconscious.  The guards that pour into the alley don't know why you are unconscious next to the dead body, but they attack anyway.
				*goto Gnome_GuardBeating
			#Say nothing and try to run from the guards without the boy's help.
				You
				*if (currentfriend_name!="None")
					and ${currentfriend_name}
				run away from the body as quickly as you can as the boy on the roof leaves you to the guards.
				*label Gnome_Alley_Guards 
				The number of sword-wielding soldiers who show up tells you that this is probably a set up.  You find yourself toe-to-toe with the guards with more coming up behind you.
				*choice
					#Fight your way free.
						You manage to catch the first guard by surprise, but one of the ones behind you strikes you over the head with the flat of their blade.  The blows that follow seem relentless.
						*label Gnome_GuardBeating
						Shield edges, fists and feet strike you repeatedly until you fall unconscious.
						*if (currentfriend_name!="None")
							You see that ${currentfriend_name} is overwhelmed just as you are and has already fallen unconscious.
						*if (showstats)
							*line_break
							(Lost All Health)
						*set health 0
						*gosub Injure_CurrentFriend
						*page_break Darkness…
						You wake up in a dark cell.  You don't know how many days have passed since your intense beating.  Slowly, you roll over onto your back and sit up.  You are pleasantly surprised to see that the guards have left you with all of your belongings.  The thick iron bars tell you that you are in the dungeons below the castle.
						*if (showstats)
							*line_break
							(Health +5)
						*set health +5
						*goto Gnome_Tornassa_Dungeon
					#Surrender.
						You surrender to the guards.  They take you into their custody and lead you down into the dungeons below the castle.  They feel so confident with their numbers that they surprise you by leaving you with all of your belongings.
						*label Gnome_Tornassa_Dungeon
						
						The days pass slowly in the dungeon.  You are asked very few questions by the guards.  The law has deteriorated badly in Tornassa.  It's clear that they don't know who you are.  Instead of properly investigating the murder, they seem to spend more time trying to find out if you know someone who can pay a ransom for your release.
						*if (companion_name!="None")
							The guards obviously don't know what to make of ${companion_name}, so they just leave ${companion_himher} with you in the cell.
						*if (fosterparent_name="Amos")
							You can't help but think of Amos, your foster parent.  He had spent years in these dungeons before being freed by Zusak's warriors on the night of your parents' murders.  His stories of those dark days and eventual release comfort you.  You spend the days becoming tougher and more resilient than ever.
							*if (showstats)
								*line_break
								(Strength +5 and Endurance +5)
							*set strength +5
							*set endurance +5
						*if (fosterparent_name!="Amos")
							You spend the days becoming tougher and more resilient than ever.
							*if (showstats)
								*line_break
								(Strength +2 and Endurance +2)
							*set strength +2
							*set endurance +2
						
						The guards never end up finding out who you are.  At the end of the two weeks, the magical lights come over
						*if (currentfriend_name="None")
							you,
						*if (currentfriend_name!="None")
							you and ${currentfriend_name},
						whisking you back to Brightwater.
						*label No_Gnome_Return
						
						"We are sorry, Your Highness," the wizards say after hearing your story.  "We were given that location by the gnomes, but they are a tricky species.  Perhaps this was simply their way of saying that they aren't interested in dealing with us."
						*set gnome_help 0
						*goto Warprep_loop

		*label Gnome_Thieves       				
		
		The boy throws a rope ladder over the edge of the roof.  You
		*if (currentfriend_name!="None")
			and ${currentfriend_name}
		quickly climb up to safety.  The thief runs lightly across the rooftops and you follow.  The sounds of confused shouts from below tell you that the guards have found the body.  You are taken to a rundown old building and let inside.  Although the exterior is in poor repair, the inside is fully functional.  A pair of large men with swords at the entrance shows you that it is heavily guarded.  You are escorted into a room to wait.
		
		"I don't want to know the details," a man says a few hours later.  "You murder someone in broad daylight.  That's your business.
		*if (used_guild_sign)
			You're a guild member,
		*if (used_guild_sign=false)
			You paid,
		so we'll keep you safe until the heat comes down.  Welcome to the Tornassa chapter of the Thieves Guild."
		*label Gnome_Thief_loop
		*choice
			#Thank the thief and lay low for a few weeks.
				The two weeks you spend in the safe house go by quickly.  You
				*if (currentfriend_name!="None")
					and ${currentfriend_name}
				are treated well enough.  As the days pass, your hosts begin to discuss how much to charge you for an extended use of their protection.  The magical lights cover you and you find yourself returning to Brightwater without having to worry about paying more.
				*goto No_Gnome_Return
			#Tell the thieves who you really are and ask them to join your cause.
				*goto Gnome_Tell_Thieves
			#Ask the Guild for a job.
				*if (class_thief=0)
					"I don't think that a life of thievery is a good fit for you," the thief says.  "You are already wanted for murder. The heat is too high."
					*goto Gnome_Thief_loop
				"Just enjoy the break, my friend," the thief says with a smile.  "It is for times like this that we pay our guild dues.  Sit back and enjoy it."
				*goto Gnome_Thief_loop

		*label Gnome_Tell_Thieves
		It takes a few days to convince them, but eventually you find yourself seated with the Guildmaster himself.  He listens to your words respectfully.
		
		"Truly, a remarkable story," he says.  "But I fail to see how we can help you.  Steal from
		*if (warprep_uddodead)
			Duchess Selina?
		*if (warprep_uddodead=false)
			Duke Uddo?
		Perhaps sabotage or even murder?  Or perhaps you'd like to use us as scouts in your army?  I am sorry, Your Highness, but the risks are too great.
		*if (used_guild_sign)
			The idea of a monarch who is also a guildmember is wonderful, and when you come into your full power, I am certain that we will have much to discuss."
		*if (used_guild_sign=false)
			I will refund your money, as a sign of good will, but I am afraid we cannot help you."
			*if (currentfriend_name!="None")
				*if (showstats)
					*line_break
					(Gold +200)
				*set gold +200
			*if (currentfriend_name="None")
				*if (showstats)
					*line_break
					(Gold +100)
				*set gold +100
		
		Despite the fact that the thieves will not aid you in your upcoming war, they do make your stay with them much more luxurious.
		*label Gnome_Thief_Aid
		*choice
			#Learn to move silently.
				The thieves find great pleasure in teaching the ${princeprincess} of the land how to move silently and without detection. 
				*gosub Gnome_Theives_DaysPass
				*if (showstats)
					*line_break
					(Stealth +3)
				*set stealth +3
				*goto No_Gnome_Return
			#Learn to pick locks and disarm traps.
				The thieves find great pleasure in teaching the ${princeprincess} of the land how to pick locks and disarm traps.
				*gosub Gnome_Theives_DaysPass
				*if (showstats)
					*line_break
					(Devices +3)
				*set devices +3
				*goto No_Gnome_Return
			#Work out with the thieves.
				The thieves find great pleasure in exercising with the ${princeprincess} of the land, especially since so many of the routines are used to build the skills for thievery.
				*gosub Gnome_Theives_DaysPass
				*if (showstats)
					*line_break
					(Agility +3)
				*set agility +3
				*goto No_Gnome_Return
			#Enjoy the break.
				The thieves treat you well, bringing you good food and treating you with the utmost respect.
				*gosub Gnome_Theives_DaysPass
				*goto No_Gnome_Return

		*label Gnome_Theives_DaysPass
		The days pass pleasantly.  As the end of the two weeks arrives, the magical lights cover you and you find yourself returning to Brightwater as the thieves applaud your magical vanishing act.
		*return
		
		*label Meet_Gnome
		He is very short and has grey hair around the fringe of his bald head.  He has wire rim glasses perched on an enormous nose.  He certainly doesn't look like the type of thief who could sneak up behind you so quietly.  You see a shimmer ripple over him.  The short man grows even shorter and his nose grows larger.  His skin takes on a ruddy appearance and his grey hair turns even more wiry.  You realize that he isn't an old human man at all.  He's a gnome.
		
		"Good day to you, $!{princeprincess} ${name}," the gnome says.  "I am Snarflan.  Come with me; we have been expecting you."
		
		He turns his back to you and steps toward the solid brick wall.  He takes another step and passes through it as though it were coloured fog.
		*if (currentfriend_name!="None")
			
			"Well, that explains how he snuck up on us," ${currentfriend_name} says before following the gnome and also walking through the wall.
			
		You step forward and put your hand out.  It passes through the illusionary wall with no resistance at all.  You take another step
		*if (companion_name!="None")
			with ${companion_name} at your side
		and walk through the brick wall.
		You find yourself in a very large warehouse.  The cavernous interior is filled with working gnomes!  Harmond, your childhood teacher, taught you that gnomes are like a cross between a halfling and a dwarf.  In some way, being in the big warehouse felt like being underground, with its windows all boarded up and many walkways twisting in different directions.  Judging from the size, you see that many warehouses have been interconnected to form a massive gnome colony.
		*choice
			#You walk next to Snarflan through the complex.
				The gnome treads purposefully through the controlled confusion.  You see a large crane with a big platform filled with crates swinging through the air.  Whether it's supplies, food or equipment, it doesn't matter.  What impresses you is that it's being moved by a single gnome using a series of ropes and pulleys.
				*gosub Gnome_Praise
				Your gnome guide smiles up at you when he sees that you are walking at his side.
				*if (showstats)
					*line_break
					(Charm +2)
				*set charm +2
				*goto Gnome_Burgomaster
			#You pause to examine the security of the warehouse.
				Despite being peaceful people, you spot gnomes standing on balconies overlooking the entrance.  They are holding complicated looking crossbows and guarding the entrance you have just passed through.  They each nod to you in a friendly manner.  You notice that their crossbows have special attachments that hold multiple bolts, which you suspect could be quickly loaded by moving levers.
				*gosub Gnome_Praise
				*if (showstats)
					*line_break
					(Perception +2)
				*set perception +2
				*goto Gnome_Come_Along
			#You pause to examine the entrance.
				Next to the illusionary wall, you see a real brick wall.  A gnome stands next to it and gives you a friendly nod.  Although small of stature, the gnome pushes the brick wall with ease and it swings into place over the entrance through the use of clever gears.  Someone on the outside would now feel bricks as well as see them.  You look closer at the movable brick wall and see that it has been attached to a series of complicated ropes and pulleys. 
				*gosub Gnome_Praise
				*if (showstats)
					*line_break
					(Devices +2)
				*set devices +2
				*label Gnome_Come_Along
				
				"Come along," your gnome guide says, leading you through the sprawling complex.
				*goto Gnome_Burgomaster

		*label Gnome_Praise
		This is a good example of gnome ingenuity.  Although masters of illusion, the diminutive race is also clever with physical devices and mathematics.  They could no doubt teach you many new things.
		*return

		*label Gnome_Burgomaster
		
		Snarflan leads you through tunnels within the warehouses and you soon find yourself in a small office.  A rare window shows a view of the warehouse district.  You see many short men working below and quickly realize that they are likely all gnomes in disguise.  You suspect that you are about to meet the Burgomaster, the leader of the gnomes.  To your surprise, Snarflan himself sits down at the desk across from you.
		
		"We are a simple and honest people," Snarflan says with a shrug.  "Simple enough that the Burgomaster himself was sent to bring you into our hidden kingdom.  We have taken an enormous risk in revealing ourselves to you."
		
		Snarflan, the Burgomaster of the gnomes, proceeds to tell you about their difficulties.  He tells you about how they were forced from their home by a band of orc raiders and how they migrated across Daria for many years and almost lost all hope before settling on such a unique plan.  You hear that it was
		*if (gender="male")
			King Brand, your father,
		*if (gender="female")
			Queen Jade, your mother,
		who gave the gnomes refuge in Tornassa.  In order to not anger the orcs, it was to be kept silent for a few years until the orcs lost interest in the gnomes.  Unfortunately, your parents were killed before the gnomes were revealed and they didn't trust Lord Uddo enough to tell him.
		*if (warprep_uddodead)
			Now that Selina has taken over, they trust her even less.
		
		"It was never meant to be a permanent solution.  Through our knowledge of simple machinery, we have made a good business of transporting and storing merchandise.  Our sound business practices have allowed us to thrive."
		
		The day wears on as you tell your story.  Your tale is given even more urgency as Snarflan tells you about the demonic possessions and rampages across Tornassa.  The crates of free Demonstones came to the lands around Tornassa
		*if (questdetails="the city of Tornassa")
			shortly after you left
		and everything changed over night.  It made no sense for
		*if (warprep_uddodead)
			Selina
		*if (warprep_uddodead=false)
			Duke Uddo
		to allow demon summoning, considering all of the troubles it had brought to the city.  But even then, summoning has been discouraged in the city itself, due to its destructive nature.
		
		"I wish we could help you, but alas, our hiding has stretched our resources to the limit and it isn't safe for us to reveal our presence during such troubling times."
		*label Gnome_FindWayToHelp_loop
		*choice
			#Say, "Thank you for your time.  Any help that you can give will be appreciated."
				*label Gnome_LittleHelp
				"I will spread the word among my people and anyone who volunteers to join you will have my blessing.  I am sure that a few will come, although they will keep their identities secret.  I wish I could do more."
				*if (showstats)
					*line_break
					(Army Size +5 and Army Power +5)
				*set army_size +5
				*set army_power +5
				*label Gnome_EndStay
				
				The remaining days pass comfortably among the gnomes.  They have created such a completely hidden community that you are never put in any danger of discovery.  They whistle and hum as they go about their work in the warehouses.  Finally, Snarflan bids you good luck as the magical lights rise around you at the end of your stay.  When the lights fall, you find yourself back in Brightwater.
				*goto warprep_loop
			#Beg the gnomes to help you.
				*if (charm<60)
					"I'm sorry," Snarflan says.  "We are in such a precarious situation already.  I don't think we can be of any use to you."
					*if (showstats)
						(Needed 60 Charm)
					*goto Gnome_FindWayToHelp_loop
				You explain your situation again and try to impress the dangers upon the Burgomaster.
				*if (showstats)
					*line_break
					(Charm +2)
				*set charm +2
				*goto Gnome_Idea
			#Say, "Tornassa is so large.  It's a strange place to hide."
				"Hidden in plain sight," Snarflan says with a smile.  "But living in the hub of civilization has other perks as well."
				
				*if (geography<65)
					The gnomes used to live under a mountain.  Living in a bunch of interconnected warehouses seems totally different and unrelated.  The fact that they've kept their presence secret for so many years shows that their concept of hiding in plain sight is working well for them.
					*if (showstats)
						(Needed 65 Geography)
					*goto Gnome_FindWayToHelp_loop
				"The commerce, right?" you say, understanding that the gnomes have tapped into Tornassa's centralized location and high population to utilize their expertise in business.
				*if (showstats)
					*line_break
					(Geography +2)
				*set geography +2
				*goto Gnome_Idea
			#Say, "I have heard stories of gnome ingenuity.  I'm surprised to hear that you would give up so easily."
				"Oh?" Burgomaster Snarflan says with a smile.  "What have you heard?"
				
				*if ((history<65) and (class_bard<2))
					You try to recall your lessons with Harmond about gnomish history, but can't come up with anything relevant.
					*if (showstats)
						(Needed 65 History or Bard Level 2)
					*goto Gnome_FindWayToHelp_loop
				You remember a story that Harmond told you about a gnome who used a family of otters to cross a river.  It was likely not historically accurate, but it made Snarflan smile.
				*if (showstats)
					*line_break
					(History +2)
				*set history +2
				*label Gnome_Idea
				
				The Burgomaster studies your face as he thinks.
				
				"Maybe there is a way for you to help after all," Snarflan says.  "Our business enterprises have been successful, but we have grown large in number.  We are on the verge of beginning a new enterprise which would be profitable enough to keep us going indefinitely.   We have completed the construction of a counting house, which we call a "bank."  We will keep other people's money safe and loan money to customers at reasonable interest rates.  It would be very beneficial to everyone.  Unfortunately, the Repus family is stealing our idea."
				
				You know the Repus family.  They are a powerful family of nobles in Tornassa who are known to be shrewd and ruthless in business.  Snarflan explains that when the gnomes applied to
				*if (warprep_uddodead)
					Duchess Selina
				*if (warprep_uddodead=false)
					Duke Uddo
				for a permit to open their counting house, the Repus family filed an injunction saying that they already had a counting house in place.  Snarflan says that it was a lie and that the Repus family is using the temporary injunction to rapidly build a counting house, so that when the investigation begins, there really will be a building in place and they will get the license instead.  The Burgomaster says that it will be close, but that the Repus counting house will be complete by the time the investigation takes place.
				*choice
					#Say, "Perhaps I should take a look at the building site."
						"If you think it will help," the gnome says.
						
						That night you find yourself standing in the nearly complete counting house of the Repus family.  The workers had been putting up bars and reinforcing the doors late into the night, but eventually, they took a break to sleep, allowing you access without their presence.  Although mostly stone, the wooden scaffolding covering the building is like kindling around an unlit campfire.  It is clear that the counting house is being constructed quickly to steal the gnome's idea.
						*choice
							#Set the scaffolding on fire with a spell.
								Without the pressures of combat, you are able to take your time and ignite all of the construction equipment.  The magical flames quickly turn to real flames as the wood catches.
								*if (showstats)
									*line_break
									(Magic +2)
								*set magic +2
								*goto Gnome_Fire
							*if (ki_strike) #Use your Ki Strike on the scaffolding.
								You feel the energy build and can see the power spinning around your fist.  You strike the scaffolding and it bursts into splinters and pieces.  The sheer power of your strike is enough for the rubble to catch fire and burn.  You realize that your power is growing.
								*goto Gnome_Fire
							*if (flintandsteel) #Use your flint and steel to start a fire.
								There are enough small pieces of wood and sawdust around that you have no problem setting the scaffolding on fire.
								*if (showstats)
									*line_break
									(Nature +2)
								*set nature +2
								*goto Gnome_Fire
							*if ((companion_type="fire elemental") and (companion_name!="None")) #Tell ${companion_name} to touch the wooden scaffolding.
								The fire elemental's hand didn't have to rest on the wood for long before it began to smoke and burst into flames.
								*if (showstats)
									*line_break
									(Magic +2)
								*set magic +2
								*goto Gnome_Fire
							*if ((companion_type="firedrake") and (companion_name!="None")) #Tell ${companion_name} to breath on the wooden scaffolding.
								The firedrake didn't have the full ability of a dragon, but ${companion_name} is able to puff out enough fire to set the construction equipment on fire.
								*if (showstats)
									*line_break
									(Magic +2)
								*set magic +2
								*goto Gnome_Fire
							*if (currentfriend_name=jacejess_name) #Listen to what ${jacejess_name} has to say.
								"I'm going to burn it to the ground," ${jacejess_name} says, ${jacejess_hisher} eyes already glowing white.
								
								Without waiting for your approval, the Soulburner proceeds to do just that.  The scaffolding is set ablaze within moments.
								*if (showstats)
									*line_break
									(${jacejess_name} Relationship +3)
								*set jacejess_relationship +3
								*goto Gnome_Fire
							#Return to the gnomes without doing anything to the building.
								Two wrongs don't make a right.  This is one of the first things every parent teaches a child.  What the Repus family was doing was unfair, but burning their building to the ground was wrong too.  Snarflan reluctantly agrees with your decision.
								*if (showstats)
									*line_break
									(Good +10)
								*set good +10
								
								*goto Gnome_LittleHelp
					#Say, "The Repus family is known for such maneuvers.  It looks like you were outplayed."
						"It is not the way that we conduct business, but yes, I suppose that it will be very profitable for them," Snarflan says with a sigh.  "We shall have to find another way to support ourselves until it is safe to reveal our presence."
						*goto Gnome_EndStay

				*label Gnome_Fire
				
				The fire gets hot enough to ignite the contents of the building as well.  You return to the gnomes and see that Burgomaster Snarflan is very pleased.
				
				"It's ironic," he says happily.  "By using the scaffolding to start the fire, the Repus family can't claim that their counting house was already built.  And if they deny that there was any scaffolding, the investigation will state that the counting house was unfit for business because it was so flammable.  Fantastic!  Our counting house will open as planned and the profits will support us until we can reveal our true identities.  Thank you!  You shall have our help in your war.  Soldiers will be the least of our contributions.  We can make you great siege engines which will collapse any wall in your path."
				*set gnome_help 2
				*if (showstats)
					*line_break
					(Army Size +7 and Army Power +7)
				*set army_size +7
				*set army_power +7
				*goto Gnome_EndStay
	#Go to the half-orc chief in the western wilderness.
		*set warprep_halforcs true
		*gosub Teleport		
		*temp orc_bound false
		*temp orc_allow_resist false
		The first thing that strikes you when the magical lights recede is the lack of snow.  It's even colder than Brightwater, but the ground is freezing and lifeless.  You 
		*if (currentfriend_name!="None")
			and ${currentfriend_name}
		have been sent across the entire continent into the wastelands of the far west.  Your studies with Harmond, your old tutor, remind you of the desolation of the place.  The lifeless wastelands of the west are a mystery.  It never snows and the only rain that falls is bitter and foul tasting.  The ground is parched and dry with only a few tough, gnarled weeds struggling to survive in the cracks.
		
		The guttural shouts all around you assault you at the same time that you feel sharpened spears pressed against your skin.  The hulking half-orcs surrounding you look angry and cruel.  Having been driven away from the pure-blood orc tribes but still considered to be orcs by humans, the half-orcs have been forced to band together for survival.  Their spears dig deeper into your skin, making you hope that their compassion and diplomatic human characteristics outweigh their tendency toward violence from their orc blood.  One of them pulls out some thick leather cords with the obvious intention of binding your hands together.
		*if (history>=50)
			
			Your knowledge of orc history makes it clear that you can't let them tie you up or you will lose their respect.  If they were full-blood orcs, they would kill you on sight.  With half-bloods, they may or may not release you, but they won't treat you as an equal after seeing you bound.
			*if (showstats)
				*line_break
				(History +2)
			*set history +2
			*set orc_allow_resist true
			*goto Orc_Allow_Tie_Decision
		*if (perception>=50)
			
			Your keen eye reveals that the half-orcs are holding the leather strips in disdain.  If they were full-blood orcs, they would kill you on sight.  With half-bloods, they may or may not release you, but you can tell from their expressions that they won't treat you as an equal after seeing you bound.
			*if (showstats)
				*line_break
				(Perception +2)
			*set perception +2
			*set orc_allow_resist true
			*goto Orc_Allow_Tie_Decision
		*label Orc_Allow_Tie_Decision
		*choice
			#Allow them to bind your wrists.
				They tie the leather cords around your
				*if (currentfriend_name!="None")
					wrists and do the same to ${currentfriend_name}.
				*if (currentfriend_name="None")
					wrists.
				You are led roughly across the plains by the half-orc band.
				*set orc_bound true
				*goto Orc_Camp
			#Say, "I am $!{princeprincess} ${name}.  Take me to your chieftain."
				The half-orcs snarl at you through thick orc tusks.
				
				"We have no chieftain, human," one of them growls, a thick accent making the words almost unrecognisable though they are in the common tongue.
				*goto Orc_Allow_Tie_Decision
			*if (orc_allow_resist) #Put your hands to your sides and refuse to let them bind you.
				You defiantly keep your hands at your sides as you look the half-orcs in the eyes.  They snort at your actions and discuss their options in their own language.  Eventually they decide to take you anyway.  You are led across the plains by the half-orc band.
				*set orc_bound false
				*goto Orc_Camp
			*if (sword) #Draw your sword.
				*label orc_fight_overwhelmed
				The butt end of a spear ends your resistance before it begins.  The magical teleportation had dropped you into the midst of the half-orcs, with enemies all around.  You have no chance.  The solid weapon strikes the back of your head, knocking you to the ground.
				*if (currentfriend_name!="None")
					You see ${currentfriend_name} getting hit in the same way, but much harder.  $!{currentfriend_heshe} falls to the ground unconscious.
					*set currentfriend_injured true
					*gosub Injure_Currentfriend
				*if (showstats)
					*line_break
					(Health -50)
				*set health -50
				
				One of the half-orcs punches the wielder of the spear in the face and yells at him.  There is a brief and intense fight among your would-be captors.  After a few more blows have landed, the half-orc with the leather cords puts them away and you are led across the plains without being tied up.
				*goto Orc_Camp
			*if (dagger) #Draw your dagger.
				*goto orc_fight_overwhelmed
			#Punch the half-orc in the face.
				*goto orc_fight_overwhelmed
			#Cast a spell to freeze all of the half-orcs in place.
				You barely say the first word of the spell.
				*goto orc_fight_overwhelmed

		*label Orc_Camp
		
		You walk toward a village that has been built beside a large jagged mountain-sized rock.  A palisade of sharpened wooden stakes encircle several dozen crudely built huts.  Several half-orc children run freely through the dirt streets with no clothes on.  The half-orc guards, both male and female, wear an assortment of mismatched armour.  They are all tall, muscular and aggressive looking.
		*if (orc_bound)
			Several of them spit at you as you are led through them, your wrists bound tightly by the leather cords.
		
		"We don't get many visitors," a huge half-orc woman says.
		
		She is larger than all of the other half-orcs in the village.  Her green arms are enormously thick and she has a big broadsword strapped to her back.  She is wearing a necklace filled with an assortment of animal teeth.  Her arms are crossed and she looks at you with a serious expression on her face.
		*label Orc_Talking_to_Gurstwin
		*choice
			*if (orc_bound) #Say, "I demand to be released immediately!"
				"No," the half-orc woman says.
				*goto Orc_Talking_to_Gurstwin
			#Ask, "Are you the leader?"
				"For now, I speak for all of us," the half-orc woman says.  "Until someone stronger defeats me and takes the position."
				*goto Orc_Talking_to_Gurstwin
			#Say, "A great evil is spreading that will harm your people as well as mine."
				*goto Orc_Explain_All
			#Say, "I want you to fight for me!"
				*goto Orc_Explain_All
			#Say, "I seek an alliance."
				*goto Orc_Explain_All

		*label Orc_Explain_All
		The half-orc woman listens as you tell her about the murder of your parents, your exile and the four duchies.  She makes an angry face when you tell her about Thuja, Selina and especially Zusak and his demons.  When you tell her that demon summoning has been made legal and that crates of Demonstones have been sent across the land, she spits on the ground.
		
		"Demon worship is evil.  You call orcs monsters, but even we know this is wrong.  I am Gurstwin.  My mother was a human prisoner and my father was an orc raider.  When I was born, I was thrown into the wildlands like all other half-breeds.  We made our own family, but this land is barren.  We can't live with our orc cousins, but I think we can find a place with our human relatives."
		*label Orc_Accept_Or_Not
		*choice
			#Say, "As long as your people follow the law, I will allow them in my kingdom."
				*goto Orc_Agreed
			#Say, "Okay, welcome to the kingdom."
				The half-orcs who understand you can hardly believe how easily you grant their request.
				
				*goto Orc_Agreed
			#Say, "As long as your people fight in my army, then I will allow them into my kingdom after the war is won."
				*goto Orc_Agreed
			#Say, "No, your people are nothing more than animals.  I will never allow them in my kingdom."
				*goto Orc_No
			#Say, "I cannot allow this.  Your people are too dangerous to live among humans."
				*label Orc_No
				"Then we will not fight for you," she says with a sadness in her voice.
				
				*if (orc_bound=false)
					The respect you had earned is stripped from you as they roughly put fresh leather straps around your wrists.
				*if (companion_name!="None")
					The half-orcs don't know what to make of ${companion_name}, so they simply drive ${companion_himher} out of their fortified camp.  You aren't worried for ${companion_himher}, since you know that when the wizards summon you back to Brightwater, ${companion_heshe} will return too.
				You
				*if (currentfriend_name!="None")
					and ${currentfriend_name}
				are roughly dragged into the centre of their camp and thrown into a deep pit.  The half-orcs then lay a heavy cross-hatched wooden frame over it.  The pit is too deep to reach the cover from the bottom.  Your prison is filled with smelly mud and excrement.  You see a few other wretched prisoners trapped with you.  As the days go by, they eventually speak to you.  They say that they are an adventuring party called the Silver Blades and that the half-orcs have held them captive in the pit for several months.
				*label Orc_Prisoner
				*choice
					*if ((companion_type="tanuki") and (companion_name!="None")) #Call for ${companion_name}.
						The little tanuki saunters back into camp in the middle of the night.  $!{companion_heshe} examines the wooden frame and then uses ${companion_hisher} nimble little fingers to untie the ropes until the frame falls to pieces, allowing you to get out of the pit!
						*goto Orc_Prisoner_Free
					*if (currentfriend_name=theothea_name) #Boost ${theothea_name} up and have ${theothea_himher} lift the wooden frame out of the way.
						The burly mountain-${theothea_manwoman}
						*if (theothea_injured)
							is in no shape to do such heavy lifting and is unable to move the frame.
							*goto Orc_Prisoner
						easily lifts the heavy frame out of the way.
						*goto Orc_Prisoner_Free
					#Get the other prisoners to boost you and then lift the wooden frame away.
						*if (strength<45)
							The wooden frame is too heavy for you to push away.
							*if (showstats)
								(Needed 45 Strength)
							*goto Orc_Prisoner
						Your muscles strain as you push the heavy wooden frame aside far enough to squeeze through.
						*if (showstats)
							*line_break
							(Strength +2)
						*set strength +2
						*goto Orc_Prisoner_Free
					#Cast a spell that will allow you to turn into smoke and float up through the frame to safety.
						*if (magic<30)
							The spell is much too advanced for you.  No matter how many times you try, you can't seem to get it to work.
							*if (showstats)
								(Needed 30 Magic)
							*goto Orc_Prisoner
						*if (magic<80)
							*if (currentfriend_name!="None")
								The spells works, but you quickly realize that it's not strong enough to take ${currentfriend_name} up with you.
								*if (showstats)
									(Needed 80 Magic)
								*choice
									#Take yourself to safety anyway.
										You see the despair in ${currentfriend_name}'s eyes as you leave ${currentfriend_himher}.  You spend the next few days fleeing from the half-orcs until the magical lights return you to Brightwater.  You are pleased to see that ${currentfriend_name} is returned as well, but judging from the many bruises and injuries across ${currentfriend_hisher} body, you know that ${currentfriend_hisher} stay in the pit with the half-orcs was not pleasant.
										*if (showstats)
											*line_break
											(${currentfriend_name} Relationship -20)
										*set friendinc 0
										*set friendinc -20
										*gosub Currentfriend_Increase
										*gosub Injure_CurrentFriend
										*goto Warprep_loop
									#Don't leave without ${currentfriend_name}.
										You can see the relief in ${currentfriend_name}'s eyes as you stay behind with ${currentfriend_himher}.
										*if (showstats)
											*line_break
											(${currentfriend_name} Relationship +10)
										*set friendinc 10
										*gosub Currentfriend_Increase
										*goto Orc_Prisoner
						The spell works and you find yourself able to lift you and everyone else up through the wooden frame.
						*if (showstats)
							*line_break
							(Magic +2)
						*set magic +2
						*goto Orc_Prisoner_Free
					*if (ki_strike) #Get the other prisoners to lift you and then use your Ki Strike on the grate.
						You feel the power build as you concentrate your spirit into a small focus.  You punch upward and the entire grate lifts off the ground with a supernatural force.  Instead of shattering, it falls back to the ground a few feet away.
						*goto Orc_Prisoner_Free
					#Get the other prisoners to lift you and then untie the ropes holding the wooden frame together.
						*if (devices<45)
							The wooden grate is lashed tightly together and it's difficult to get your fingers into position to untangle the ropes binding it.  Your attempts are noticed and the half-orcs give you a beating for your troubles before retying the ropes holding the wooden frame together.
							*if (health<20)
								*if (showstats)
									(Needed 45 Devices)
							*if (health>=20)
								*set health -10
								*if (showstats)
									(Needed 45 Devices)
									*line_break
									(Health -10 to ${health} / 100)
							*goto Orc_Prisoner
						Your agile fingers untie the ropes holding the wooden frame together.  You manage to pry the frame apart just enough to squeeze through.
						*if (showstats)
							*line_break
							(Devices +2)
						*set devices +2
						*label Orc_Prisoner_Free
						*choice
							#Escape the half-orc prison, taking the other prisoners with you.
								The entire group manages to sneak out of the half-orc camp without being seen.  It is the middle of the night and they simply don't expect you to escape.  The members of the Silver Blades thank you repeatedly for rescuing them.  You
								*if (currentfriend_name!="None")
									and ${currentfriend_name}
								spend the last days traveling away from the half-orcs until the magical lights return you to Brightwater.
								*set silver_blades_free true
								*goto Warprep_loop
							#Allow the human prisoners to escape, but remain within the prison.
								The half-orcs are very surprised to find the other prisoners gone the next morning.  They angrily discuss what to do with you as the days pass.  Before they make their decision as to your fate, the magical lights envelop you and return you to Brightwater.
								*if (showstats)
									*line_break
									(Good +10)
								*set good +10
								*set silver_blades_free true
								*goto Warprep_loop
							#Escape the half-orc prison, but leave the other prisoners behind.
								The human prisoners are in no shape to stop you as you leave them in the pit.  They groan softly, but their pitiful noise isn't loud enough to draw the half-orcs.  You
								*if (currentfriend_name!="None")
									and ${currentfriend_name}
								spend the last days traveling away from the half-orcs until the magical lights return you to Brightwater.
								*if (showstats)
									*line_break
									(Evil +15)
								*set good -15
								*goto Warprep_loop 
					#Wait patiently for the two weeks to pass.
						The half-orcs throw food down to you and lower a rusty bucket of water once a day.  The other prisoners seem to have lost the will to fight from their prolonged imprisonment as the half-orcs continually beat them for any transgressions.  You learn a few things about the world from the adventuring group as the days go by.  You are happy when the magical lights finally rise up and take you back to Brightwater.
						*if (showstats)
							*line_break
							(History +2 and Geography +5)
						*set history +2
						*set geography +5
						*goto Warprep_loop
			#Say, "Fight for me and we will discuss this afterward."
				"No!" Gurstwin says angrily.  "If we fight, we must fight for a kingdom we belong to."
				*goto Orc_Accept_Or_Not
			#Say, "Let me pay you to fight instead."
				Gurstwin turns to the other half-orcs and begins speaking rapidly in their guttural language.  She then turns back to you.
				
				"What good is gold if we may not go into your towns to spend it?  No, make us citizens or we will not fight for you."
				*goto Orc_Accept_Or_Not
			#Say, "I challenge you in combat for leadership of the half-orcs!"
				Gurstwin bursts into laughter as do all of the half-orcs who understand your words.  They translate what you have said for the others and soon everyone is laughing until tears are streaming down their green faces.
				
				"You are not half-orc," she eventually says.  "You have no orc blood in you at all."
				*goto Orc_Accept_Or_Not

		*label Orc_Agreed
		"This is a great moment in time for our people," Gurstwin says happily as she translates her words into orcish for the other half-orcs.  "There is only one small thing that you must do to show that you value my people as allies…."
		
		*if (orc_bound)
			The leather straps are removed from your wrists.
		Gurstwin leads you across the village and the other half-orcs walk alongside, cruel smiles on their eager faces.  You are taken to a deep pit in the centre of their fortified village.  You can see a few wretched shapes far below in the excrement-filled mud.  A rope ladder is lowered and a half-orc climbs down.  He carries the human prisoners up to the surface one at a time.  There are five of them in all.  They have the look of an adventuring party about them, but they have spent so long in the pit that they are weak and pitiful.
		
		"These are our enemies," Gurstwin says, looking upon the human prisoners in contempt.  "They attacked our hunters.  Kill them and show us that our enemies are your enemies."
		
		She hands you a heavy club that has a rusty chunk of iron hammered onto the end of it.  You realize that not all of the red is rust—some of it is old dried blood.
		*label Orc_Kill_Or_Not
		*choice
			*if (jeckel_potion) #You feel a rage begin to build within as Mazrim's potion overtakes your senses.
				You grip the club tighter and look at the pitiful prisoners.  You begin to tremble from the anger as your muscles tighten.  The half-orcs are making you do their dirty work!  You are breathing heavily when you lose control.  With a scream, you swing the club at one of the half-orcs watching.  The large muscular warrior falls to the ground and the spears are all raised once more.  Gurstwin steps back as you snarl and charge toward the spear-holders.
				
				The prisoners use the distraction to run away and the half-orcs are kept busy fighting you.  After a few minutes, the rage leaves you.  The bloody club falls from your fingers as you tremble from exhaustion.  You are covered with sweat and the half-orcs watch in amazement.
				*set silver_blades_free true
				
				"You have a furious passion!" Gurstwin says with a great smile.  "We would be honoured to fight for you!  Let those miserable humans run off into the wild.  They mean nothing."
				*goto Orc_Full_Support
			#Say, "I cannot kill them until they have had a fair trial."
				"A trial?" Gurstwin says, arching a thick black eyebrow.  "They have killed half-orcs.  They are murderers.  You must prove that you will stand with the half-orcs by killing our enemies."
				*goto Orc_Kill_Or_Not
			#Say, "I have vowed to never kill except in battle or direct defence of life or safety."
				The half-orcs snort at your comments, finding your words pompous and unrealistic.
				
				"They must be killed…" Gurstwin says.  "For the safety of our people."
				*if ((currentfriend_name=theothea_name) or (currentfriend_name=jacejess_name))
					
					"I have made no such vow," ${currentfriend_name} says.  "I'll do it."
					*choice
						#Say, "No, I don't want you to."
							"As you wish," ${currentfriend_name} says.
							*goto Orc_Kill_Or_Not
						#Nod in agreement.
							*if (currentfriend_name=theothea_name)
								The large mountain-${theothea_manwoman} takes the blood-stained club in ${theothea_hisher} large hands.  The club is heavy and cracks the first prisoner's skull open with ease.  The half-orcs shout and holler with excitement.  The second and third prisoners are killed before the last two realize that their end has come.  The half-orcs hold them down as ${theothea_name} finishes the executions.  The half-orcs growl and shout in approval as the heavy gore-covered club is taken from ${theothea_hisher} hands.
								*goto Orc_Full_Support
							${jacejess_name} looks at the blood-crusted club with disgust and doesn't take it.  Instead, the Soulburner's eyes glow white as ${jacejess_heshe} slices the heads off the prisoners with ease.  The half-orcs aren't certain what to make of the display, but considering that the prisoners are killed, they seem okay with it.
							*goto Orc_Full_Support
				*else
					*goto Orc_Kill_Or_Not
			#Ask the prisoners to tell their side of the story.
				The five humans are unable to speak, at first.  They have been beaten very badly and have been in the pit for a long time.  Eventually, one of them speaks.
				
				"We were hired by a farmer to stop some orc raids," he says hesitantly.  When he sees that the half-orcs aren't going to beat him for speaking, he gains some courage and begins to speak more coherently.  "We are an adventuring party: The Silver Blades, perhaps you have heard of us?  We tracked the raiders of a nearby village and attacked them.  Unfortunately for us, we didn't know that it was only half of their group and during the battle the other half returned and we were captured."
				
				Another of the humans nods at these words, hope sparking in his eyes.  Gurstwin says nothing.  It is clear that her judgement has not changed.
				*goto Orc_Kill_Or_Not
			#Try to talk Gurstwin into letting the prisoners go free.
				*if (orc_bound=false)
					Gurstwin listens to your impassioned plea.  The half-orcs look to one another as they try to decide whether or not to do as you ask.  Eventually, you are relieved to see the prisoners set free.
					*if (showstats)
						(Charm +3 and Citizen Reputation +3)
					*set citizen_reputation +3
					*set charm +3
					
					"As you wish, $!{princeprincess} ${name}," she says.  "I suppose that they are no longer our enemies, now that we are a part of the kingdom as well.  If it happens again, things will be different."
					*set silver_blades_free true
					*goto Orc_Full_Support
				*if (charm<80)
					"No, they must die," Gurstwin says angrily, despite your impassioned plea.
					*if (showstats)
						(Needed 80 Charm)
					*goto Orc_Kill_Or_Not
				By the time you are finished your impassioned plea, the half-orcs are all uncertain as to what the correct thing to do is.  After a few minutes of thinking silence, their leader decides.
				
				"If this is what must be done, then we shall do so," Gurstwin says after some thought.  "We shall swallow our pride.  As members of the Kingdom of Daria, we will have many opportunities to regain our lost honour."
				*if (showstats)
					*line_break
					(Charm +2)
				*set charm +2
				
				*set silver_blades_free true
				You watch as the prisoners are released.  Gurstwin leads you to a hut for you to stay in during your visit.  The green-skinned half-orcs spend the days gathering their weapons and getting ready to march.  Gurstwin vows to lead the contingent of half-orcs herself, although she says that the infamous berserker warriors will remain behind to guard the fortress.  As the magical lights rise around you and whisk you back home, you know that the half-orcs will arrive in time to march with the rest of your army. 
				*if (showstats)
					*line_break
					(Army Size +7 and Army Power +7)
				*set army_size +7
				*set army_power +7
				*set orc_help 1
				*goto Warprep_loop
			#Free the prisoners regardless of what the half-orcs say.
				Gurstwin holds up her hand just as the half-orcs are about to drive their spears into you.  The wretched prisoners limp away as the large green warrior shakes her head sadly.  You realize that the half-orc's honour concerning guests is preventing them from killing you on the spot, but they are not happy with your actions.
				*set silver_blades_free true
				*if (showstats)
					*line_break
					(Good +10)
				*set good +10
				*goto Orc_No_Support
			#Refuse to kill the prisoners, but allow the half-orcs to return them to the pit.
				The half-orcs are not happy with your decision.
				*goto Orc_No_Support_ns
				
				*label Orc_No_Support
				
				*label Orc_No_Support_ns
				You are put in a small hut for the remainder of your stay.  The half-orcs feel that you will never treat them as equals and will always side with humans in all disputes.  Your offer to let them join the kingdom is seen as fake and untrue.  At the end of the two weeks, the magic lights encompass you and you are returned to Brightwater.  The half-orcs will not be aiding you in the upcoming battle.
				*set orc_help 0
				*goto Warprep_loop
			#Club the prisoners to death.
				The club is heavy and cracks the first prisoner's skull open with ease.  The half-orcs shout and holler with excitement.  The second and third prisoners are killed before the last two realize that their end has come.  The half-orcs hold them down as you finish the executions.  The half-orcs growl and shout in approval as the heavy gore-covered club is taken from your hands.
				*if (showstats)
					*line_break
					(Evil +20)
					*set good -20
				*label Orc_Full_Support
				
				Gurstwin leads you to a hut for you to stay during your visit.  The green-skinned half-orcs spend the days gathering their weapons and getting ready to march.  Gurstwin vows to lead the contingent of half-orc warriors, including their infamous berserkers, to Brightwater the moment you are teleported away.  As the magical lights rise around you and whisk you back home, you know that the half-orcs will arrive in time to march with the rest of your army. 
				*if (showstats)
					*line_break
					(Army Size +10 and Army Power +10)
				*set army_size +10
				*set army_power +10
				*set orc_help 2
				*goto Warprep_loop
	#Go to the halflings.
		*set warprep_halflings true
		*gosub Teleport
		*temp halfling_know_name false
		*temp halfling_stolen_gold 0
		*temp halfling_told_invis false
		*temp halfling_noghost false
		The magical lights recede from your vision to reveal a snowy landscape of gently rolling hills ahead of you.  You
		*if (currentfriend_name!="None")
			and ${currentfriend_name}
		are standing in knee deep snow to the side of a frosty road that has been lined with the twin grooves of a sleigh.  The small paw prints of dogs show the type of animal that pulled the halfling sleighs.  You see many wafting columns of smoke coming from the various chimneys sticking out of the hills.
		
		You walk along the road toward the halfling
		*if (companion_name="None")
			community.
		*if (companion_name!="None")
			community as ${companion_name} ${companion_travels}.
		Despite the calm and friendly nature of the halflings, the experienced dog-riders easily spot your arrival and by the time you reach the first home, a small gathering of halflings are there to greet you.  You 
		*if (currentfriend_name!="None")
			and ${currentfriend_name}
		are invited into the home of Mayor Obban, the leader of the small people.  Your outer garments are hung on hooks near the door and you soon find yourself seated on the floor in front of a roaring fire, since their chairs are too small for you.
		
		"Greetings and well met, $!{princeprincess} ${name}," the halfling leader says.  "I am Mayor Obban.  I know why you have come.  You are reclaiming your human kingdom to prevent a wave of demon summoning fanatics from destroying the land and you wish to have our aid in your upcoming war."
		*label Halfling_Mayor_Talk
		*choice
			#Ask, "How do you know all that?"
				The mayor smiles knowingly.
				
				"We tread softly and unseen," he says in a grand tone and then breaks into a smile.  "But in this case, we were told by a wizard from your Academy.  We stay hidden from big folk and our hills are not easily found."
				*goto Halfling_Mayor_Talk
			#Say, "The demon threat will eventually come to your people as well."
				"Perhaps it will.  Perhaps it won't," the mayor says as he offers you food from a platter.  "We are a simple people.  We enjoy farming and eating.  I don't think the lure of power affects us the same, but I agree that the threat must be removed.  We will help you."
				*goto Halfling_However
			#Say, "Your people will be allowed to join my people, if I am the ruler."
				"There may be some among my kind who will wish to live among you, but not many.  Most of us are content to live in our holes and enjoy life as it comes.  But yes, a peaceful alliance with your kind would be very nice for everyone.  We will help you."
				*goto Halfling_However
			#Say, "I require warriors to help stop the threat."
				"We have no warriors," Mayor Obban says.  "But we have slingers and dog-riders.  Additionally, our scouts rival the elves in their stealth.  We will help you."
				*goto Halfling_However
			#Say, "I seek an alliance between our people."
				"We would welcome peace," Mayor Obban says.  "We will help you."
				*goto Halfling_However

		*label Halfling_However
		
		Your diminutive host continues to bring out food for your enjoyment.  Warm pastries, salted meats, sweet pickles, spicy cheeses…  It is easy to see how he got his rotund figure.  He discusses the militia he will send to Brightwater and how they could aid your campaign.
		
		"However…  Before we can aid you, we need your help,"  he says.  "A small matter, for one of your talents.  But, the situation is beyond our experience.  You see, we have an undead problem.  It has been plaguing us for several months now.  We are a simple people and our clerics have been unable to deal with it.  If you can lay the spirit to rest, we will be able to send you the aid you require.  Will you help us?"
		*temp help_me_first false
		*label Halfling_NeedsHelp_loop
		*choice
			*if (class_priest=0) #Say, "I am not a ${priestpriestess}, but I will try to help you."
				*goto Halflings_Help
			*if (((class_priest>0) and (god_good)) and (god_name!="Unknown")) #Say, "As a follower of ${god_name}, I will try to help you."
				*goto Halflings_Help
			*if (((class_priest>0) and (god_good=false)) and (god_name!="Unknown")) #Say, "As a follower of the Gods, I will try to help you."
				The halfling thinks you are referring to the good Gods of the world, but as a secret follower of ${god_name}, you have your own agenda.
				*goto Halflings_Help
			*if ((class_priest>0) and (god_hisher="Its")) #Say, "As a follower of the Great Unknown, I will try to help you."
				As a follower of the Unknown, you aren't even certain what your stance toward the undead is, but either way, you know your deity will aid you.
				*goto Halflings_Help
			#Say, "This is blackmail.  You must help me first, and then I will consider helping you."
				*set help_me_first true
				The halfling mayor shuffles uncomfortably in his small halfling-sized chair.
				"I'm sorry, but with a more immediate danger here in our community, we can't send our militia away.  Please, try to understand."
				*goto Halfling_NeedsHelp_loop
			*if (help_me_first) #Say, "Fine, I'll help, but I'll remember that you left me no choice."
				*goto Halflings_Help
			#Say, "No.  I will not help you."
				"As you wish," Mayor Obban says coldly.  
				*label Halfling_NoHelp
				"I understand that your magic will return you to whence you came…within a fortnight, if I recall correctly.  You shall be our honoured guest during this time.  If we are able to end the undead threat in time, we will still aid you.  Good night to you."
				
				The two weeks pass very comfortably and you see no undead during your stay.  Despite the fact that the mayor is not happy with your refusal to help, he feeds you very well and personally tends to your every need until the magical lights return you to Brightwater.  With no solution to their problem, you know that the halflings won't be helping you with your conquest.
				*set halfling_help 0
				*goto Warprep_loop

		*label Halflings_Help
		You
		*if (currentfriend_name!="None")
			and ${currentfriend_name} are given human-sized beds
		*if (currentfriend_name="None")
			are given a human-sized bed
		for the night.  In the morning, you are taken to a small round door to a halfling home on the other side of the community.  You see that several tables have been erected in front of the door and great heaps of food have been placed upon them.
		*if (((class_sage>0) or (history>=60)) or (arcana>=60))
			You have read about such offerings, but the circumstances of this situation seem all wrong.  As a well-read scholar, you have your doubts about the authenticity of this alleged ghost sighting.
			*set halfling_noghost true
			*if (showstats)
				*line_break
				(History +2 and Arcana +2)
			*set history +2
			*set arcana +2
			*goto Halfling_After_Knowledge_Check
		*else
			*if (showstats)
				(Needed 60 History or 60 Arcana)
			*goto Halfling_After_Knowledge_Check

		*label Halfling_After_Knowledge_Check
		
		"The ghost lives within," Mayor Obban says.
		*label Halfling_OutsideHouse_loop
		*choice
			#Ask, "Whose home is this?"
				"There was a halfling named Lomi who used to live here," Mayor Obban says.  "He was an adventurer, or something.  He was killed and now his ghost haunts his home."
				*set halfling_know_name true
				*goto Halfling_OutsideHouse_loop
			#Inspect the home carefully.
				*if (class_ranger>0)
					Your skill as a ranger comes in handy as you find the faintest of footprints around the table filled with food.  They belong to a halfling and they are very faint, but they are there.  You feel confident that you are not dealing with a ghost.
					*if (showstats)
						*line_break
						(Nature +2 and Perception +2)
					*set nature +2
					*set perception +2
					*set halfling_noghost true
					*goto Halfling_OutsideHouse_loop
				You search around the house carefully,
				*if (perception>=50)
					noticing something about the food table.  There are crumbs next to one of the plates.  Looking closer, you see that someone lifted one of the pastries and put it back, leaving a finger mark.  Ghosts don't eat food and they don't leave fingerprints.
					*if (showstats)
						*line_break
						(Perception +2)
					*set perception +2
					*set halfling_noghost true
					*goto Halfling_OutsideHouse_loop
				*else
					but you find nothing special.
					(Needed 50 Perception)
					*goto Halfling_OutsideHouse_loop
			#Enter the home.
				The mayor and his associates all gasp at your bravery and stand back as you open the door and walk in.  You see that the house looks like someone still lives there.  A fire is burning in the fireplace and there are empty plates in the kitchen sink.
				*if (currentfriend_name=peterpetra_name)
					
					"This is not the work of a spirit," ${currentfriend_name} says.  "I would sense such an occurrence.  Something else is happening here."
					
					*set halfling_noghost true
				*if (gold<=0)
					You feel something brush against your empty coin purse.
				*if (gold>0)
					You feel something brush against your coin purse and realize that it is lighter than it was before.
					*if (gold>=50)
						*if (showstats)
							*line_break
							(Gold -50)
						*set gold -50
						*set halfling_stolen_gold 50
						*goto Halfling_Inside
					*else
						*if (showstats)
							*line_break
							(Gold -${gold})
						*set halfling_stolen_gold gold
						*set gold 0
						*goto Halfling_Inside
				*goto Halfling_Inside
			*if ((class_priest>0) and (god_good)) #Call upon ${god_name} to drive away the undead.
				You say the words and raise your holy symbol.  You can feel the righteous divine power build.  A cleansing beam of holy light glows from your hands and onto the house.
				*goto Halfling_Divine
			*if ((class_priest>0) and (god_good=false)) #Call upon ${god_name} to dominate the undead creature for your own uses.
				You say the words and raise your holy symbol, which to outward appearances looks to belong to a good God, but you know otherwise.  You can feel the evil divine power build.  The shadows appear to darken and the mayor shivers with fear, although he doesn't know why.
				*label Halfling_Divine
				You feel an unfamiliar juxtaposition.  Nothing happens to the house or the contents, which leads you to believe that there is no undead within.  This might be the case, but what's strange is that you feel a divine power pulsing back all the same.  Something mystical is occurring and the source of the power is divine in nature.
				*if (showstats)
					*line_break
					(Religion +2 and Magic +2)
				*set religion +2
				*set magic +2
				*set halfling_noghost true
				*goto Halfling_OutsideHouse_loop
			#Refuse to enter.
				"You see why we can't aid you, at this time," the Mayor says.
				*goto Halfling_NoHelp

		*label Halfling_Inside
		
		"Be gone!!!" a voice suddenly says in the empty house.  "Or I shall lay my spectral hand upon you and drain your life!!"
		*choice
			*if (halfling_noghost) #Say, "I know you aren't a ghost.  Show yourself."
				"What gave it away?" the disembodied voice asks in a pouting tone.  "Oh, I'm tired of all this anyway.  All the food I could want, but it's so lonely…."
				*choice
					#Listen to the voice speak.
						"I am Lomi," the voice continues.  
						*label Halfling_Lomi
						"I found a magical artifact which turned me invisible.  But, I don't want to be invisible any more.  Place your hand here and say: 'Lomi, become visible!'"
						*choice
							#Do as the halfling asks.
								*label Halfling_Did_It
								You reach out your hand and feel something placed in it.  You say the words, "Lomi, become visible!" and the empty air in front of you changes.  To your surprise, you see a short halfling holding a silver necklace up for you to touch.  The necklace has a blue teardrop gem on it.  He releases the necklace into your hand.
								*if (showstats)
									*line_break
									(Gained Teardrop Necklace)
								*set teardrop true
								*set teardrop_used true
								*gosub DiscussNecklace
								*label Halfling_Lomi_Aftermath
								*choice
									#Ask Lomi, "Where did you get this necklace?"
										"Well…" the halfling begins.  "There was this elf priest.  Scary looking guy.  He had lions on his bracers!  Well, he dropped it.  When I tried to find him to give it back, he had already left.  Take it!  It's cursed.  I never want to see it again."
										*goto Halfling_Lomi_Aftermath
									*if (halfling_stolen_gold>0) #Demand, "Give me back the gold you stole from me!"
										"Oh!" the halfling says as he blushes a bright red.  "Sorry for the misunderstanding."
										
										He reaches into his coin pouch and retrieves a handful of gold, sheepishly giving it back to you.
										*if (showstats)
											*line_break
											(Gold +${halfling_stolen_gold})
										*set gold + halfling_stolen_gold
										*goto Halfling_Lomi_Aftermath
									*if (halfling_told_invis=false) #Ask, "How does the necklace's magic work?"
										The halfling goes wide-eyed as he answers.
										
										"It grants wishes!"
										*if (naistalan_quest="heard")
											
											You see how the halfling would think such a thing, since the artifact's connection to the Gods and Goddesses could result in gaining a blessing that aligns with your desires.
										*goto Halfling_Lomi_Aftermath
									#Tell the mayor that the problem is solved.
										The mayor is surprised to hear that the "ghost" was just Lomi.  The halfling claims that the necklace made him do it.  You don't believe him, of course.  The necklace made him invisible, but the halfling's actions were his own. 
										*goto Halfling_GhostFree
							#Reach out, but say nothing.
								You reach out and feel something cool placed in your hands.  You close your hands around it and suddenly, you can see it.  It's a silver necklace with a blue tear-shaped gem on the end.  You can hear Lomi getting excited when you don't say the words.
								*label Halfling_Has_Necklace
								*if (showstats)
									*line_break
									(Gained Teardrop Necklace)
								*set teardrop true
								*gosub DiscussNecklace
								
								"Please, make me visible again!  Just say the magic words while holding the necklace, please!"
								*label Halfling_Invis_Lomi_loop
								*choice
									#Say, "Lomi, become visible!"
										*set teardrop_used true
										The necklace feels cool for a second and then suddenly, the halfling is visible once more.  He seems very happy about the fact that you saved him.
										*if (showstats)
											*line_break
											(Good +10)
										*set good +10
										*goto Halfling_Lomi_Aftermath
									#Ask, "How does the necklace's magic work?"
										"It can turn one person invisible at a time, but it's cursed because you need a second person to turn the person visible again," the voice says.
										*set halfling_told_invis true
										*goto Halfling_Invis_Lomi_loop
									#Say, "I'm afraid I can't help you."
										You hear sobbing coming from the air in front of you as Lomi realizes that his curse is destined to continue.  The sobbing becomes faint as he leaves the house before you can say another word.
										*goto Halfling_GhostFree
									#Say, "No.  Go away and never return; you deserve what happened to you."
										You hear sobbing coming from the air in front of you as Lomi realizes that he is cursed to stay invisible forever.  The sobbing becomes faint as he leaves the house.
										*if (showstats)
											*line_break
											(Evil +15)
										*set good -15
										*goto Halfling_GhostFree
							#Don't do anything.
								"Please, you must help me!" the voice says.
								*choice
									#Reach out and say the words.
										*goto Halfling_Did_It
									#Say, "I won't do anything unless you tell me what's happening."
										"I found a cursed necklace that did this to me," Lomi says.  "Here."
										
										You feel something in your hand.  Suddenly, it becomes visible.  It's a silver necklace with a blue tear-shaped gem on the end.
										*goto Halfling_Has_Necklace
					*if (sword) #Strike the voice with your sword while it is distracted.
						You time the blow perfectly, striking something solid with your sword.
						*goto Halfling_Hit_Ghost
					*if (dagger) #Slash the voice with your dagger while it is distracted.
						You time the blow perfectly, striking something solid with your blade.
						*goto Halfling_Hit_Ghost
					*if (bow) #Unleash an arrow at the voice while it is distracted.
						Your arrow disappears from view as it hits something in the middle of the room.
						*goto Halfling_Hit_Ghost
					#Punch the owner of the voice while it is distracted.
						Your fist hits something solid.
						*goto Halfling_Hit_Ghost
					*if ((currentfriend_name=karlkarla_name) and (infinity_arrow)) #Tell ${karlkarla_name} to strike the ghost with the Infinity Arrow while it is distracted.
						*goto Halfling_Infinity
			*if (halfling_noghost=false) #Say, "Please, leave this place, foul spirit!"
				"No, I cannot," the voice says, this time from another location, and still, you see nothing.  "I must gather gold to pay the ferryman so I can cross the river of death!  I will leave, if you can give me the sum I need…200 gold!"
				*label Halfling_Ghost_loop
				*choice
					#Cast a blast of electricity at the ghost.
						*if ((magic<40) or (agility<40))
							The electricity smashes harmlessly into a wall.
							*if (showstats)
								(Needed 40 Magic and 40 Agility)
							*goto Halfling_Ghost_loop
						*else
							The blue sparks leap through the air and hit something other than the wall.
							*goto Halfling_Hit_Ghost
					#Kick at the air where the voice is coming from.
						*if ((unarmed<40) or (agility<40))
							Your foot hits nothing but air.
							*if (showstats)
								(Needed 40 Unarmed and 40 Agility)
							*goto Halfling_Ghost_loop
						*else
							Your foot strikes something solid.
							*goto Halfling_Hit_Ghost
					*if (sword) #Swing your sword toward the ghost's voice.
						*if (agility>=50)
							You time the blow perfectly, striking something solid with your sword.
							*label Halfling_Hit_Ghost
							You are rewarded with a yelp of pain.  You realize that this is definitely not a ghost.
							*if (showstats)
								*line_break
								(Agility +2)
							*set agility +2
							*label Halfling_Ghost_Reveal
							
							The moaning from the invisible being no longer sounds spooky in the least.  You can tell that the creature is hurt, but not fatally.  The sound tells you exactly where he is lying.
							
							"I surrender!  It's just me, Lomi," the voice of the invisible halfling says. 
							*choice
								#Listen to his story.
									*goto Halfling_Lomi
								#Kill the creature before it gets away.
									The voice doesn't see it coming.
									*if ((sword) or (dagger))
										A single thrust with your blade
									*if (((sword) or (dagger))=false)
										A single stomp of your foot
									and the creature speaks no more.
									*if (showstats)
										*line_break
										(Evil +15)
									*set good -15
									*label Halfling_Lomi_Dead
									
									You feel around on the ground and find the invisible body of a halfling. After a moment more of searching, you discover a silver necklace with a blue teardrop gem on it, which becomes visible as you take it off the corpse.  You also find a nice sized pouch of gold.
									*set halfling_stolen_gold +175
									*if (showstats)
										*line_break
										(Gold +${halfling_stolen_gold} and Gained Teardrop Necklace)
									*set teardrop true
									*set gold +halfling_stolen_gold
									*gosub DiscussNecklace
									*goto Halfling_GhostFree
						*else
							Your sword passes harmlessly through the air.
							*if (showstats)
								(Needed 50 Agility)
							*goto Halfling_Ghost_loop
					*if (dagger) #Slash your dagger toward the ghost's voice.
						*if (agility>=50)
							You time the blow perfectly, striking something solid with your dagger.
							*goto Halfling_Hit_Ghost
						*else
							Your dagger passes harmlessly through the air.
							*if (showstats)
								(Needed 50 Agility)
							*goto Halfling_Ghost_loop
					*if (bow) #Fire an arrow toward the ghost's voice.
						*if (agility>=75)
							You time the release perfectly, striking something solid with an arrow.
							*goto Halfling_Hit_Ghost
						*else
							Your arrow passes harmlessly through the air and sticks into a wall.
							*if (showstats)
								(Needed 75 Agility)
							*goto Halfling_Ghost_loop
					*if ((currentfriend_name=karlkarla_name) and (infinity_arrow)) #Tell ${karlkarla_name} to strike the ghost with the Infinity Arrow.
						*label Halfling_Infinity
						You aren't sure at first if the magical arrow will hit the target or not, but when ${karlkarla_name} fires ${karlkarla_hisher} bow, you hear a yelp of surprise and a thud as something falls to the ground and a pool of blood appears in the centre of the room.
						*set infinity_arrow false
						*goto Halfling_Lomi_Dead
					#Say, "Please, speak to me.  Maybe I can help?"
						"OOOooooooOOOOooo," the ghostly voice moans.  "Only gold can save my soul!"
						*goto Halfling_Ghost_loop
					#Say, "I'm not giving you any money."
						"OoooOOOoooo," the voice moans.  "Then leave my house!!"
						*goto Halfling_Ghost_loop
					*if (halfling_stolen_gold=50)
						*selectable_if (gold>=150) #Say, "You took 50 already.  I'll give you the other 150 now." (150 Gold Needed)
							You put the money out on the floor and watch as it disappears into thin air!  The house suddenly feels much emptier.
							*if (showstats)
								*line_break
								(Gold -150)
							*set gold -150
							*goto Halfling_GhostFree
					*selectable_if (gold>=200) #Count out 200 gold and give it to the ghost. (200 Gold Needed)
						You put the money out on the floor and watch as it disappears into thin air!  The house suddenly feels much emptier.
						*if (showstats)
							*line_break
							(Gold -200)
						*set gold -200
						*goto Halfling_GhostFree
					#Leave the house and give up.
						*goto Halfling_Leave_House
			#Leave the house.
				*label Halfling_Leave_House
				The mayor and his companions all nod at your wise decision as they stand a little farther back from the house.
				
				"You see why we can't aid you, at this time," the Mayor says.
				*goto Halfling_NoHelp

		*label Halfling_GhostFree
		
		Mayor Obban is overjoyed that the house is now ghost-free.  The next few days go by comfortably as you are fed a lot of food and many halflings come to meet you.  The mayor dispatches a pack of dog-riding halflings to Brightwater as well as a band of halfling slingers to augment your ranged troops in your upcoming war.
		*if (teardrop=false)
			At the end of the two weeks, the magical lights erupt around you and take you back to Brightwater.
		*if (showstats)
			*line_break
			(Army Size +7 and Army Power +7)
		*set army_size +7
		*set army_power +7
		*set halfling_help 1
		*if (teardrop)
			
			*if (teardrop_used)
				You examine
				*if (naistalan_quest!="heard")
					the teardrop necklace
					*set teardrop_holding false
				*if (naistalan_quest="heard")
					Auriel's Grief
					*set teardrop_holding true
				in great detail, but it doesn't do anything more.  At the end of the two weeks, the magical lights erupt around you and take you back to Brightwater.
				*goto warprep_loop
			*else
				You examine
				*if (naistalan_quest!="heard")
					the teardrop necklace in great detail and eventually your persistence pays off as a voice speaks in your mind, "What do you desire?"
					*set teardrop_holding false
				*if (naistalan_quest="heard")
					Auriel's Grief carefully, but despite your caution, a voice speaks in your mind:  "What do you desire?"
				*choice
					*if (naistalan_quest="heard") #Ask, "Is this Auriel?"
						You hear tinkling laughter in the air around you.  "Your request is granted.  No, this is not Auriel the Light Bringer."
						
						The voice fades away, but the laughter continues.  You dream of the Gods and Goddesses that night.  You realize that it is an extension of what you had asked.  Instead of having dreams of who you were speaking to, you have dreams of the many Gods and Goddesses you were not in contact with.  To your surprise, many of the visions are eerily accurate.
						*if (showstats)
							*line_break
							(Religion +10)
						*set religion +10
						*goto Halfling_Used_Wish
					#You wish to be stronger than Alexander Zusak.
						A warm glow fills your body for a moment and then subsides.  You feel stronger, but Zusak isn't dangerous because of his physical strength.  You figure that the voice probably knew this and intentionally misread your request.
						*if (showstats)
							*line_break
							(Strength +3 and Agility +3)
						*set strength +3
						*set agility +3
						*goto Halfling_Used_Wish
					#You wish to know Alexander Zusak's plans.
						A warm glow fills your body for a moment and then subsides.  You fall into a deep sleep where you see visions of the world around you: small towns, large villages, high mountains and rushing rivers.  Your sight finally settles on Vernex where you see Zusak preparing for bed.  Suddenly, you awake…knowing that he plans to go to bed early this evening.  You can't help but feel that you've been tricked.  Strangely enough, you now seem to know the names of the places you saw during your mystical trip to Vernex.
						*if (showstats)
							*line_break
							(Geography +10)
						*set geography +10
						*goto Halfling_Used_Wish
					#You wish for Alexander Zusak to die.
						"Granted!" the voice says.  "He will die…but not today and likely not tomorrow."
						
						You can't help but feel that you've been tricked.  All humans die, and Zusak will too someday.  You have gained nothing with your wish.
						*goto Halfling_Used_Wish
					#You wish for your army to be more powerful than your enemy's.
						You see several gold coins magically appear before you and you have the knowledge that they are coming right out of the coffers being used to fund the enemy soldiers.  With every coin that appears, you realize that you are closer to victory!  Without the means to pay for their soldiers, they will all desert and you will be able to march upon their cities without resistance!  But then, it stops.  You realize that you got your wish, but only to the smallest degree.
						*if (showstats)
							*line_break
							(Gold +234)
						*set gold +234
						*goto Halfling_Used_Wish
					#You say nothing.
						"You ask for nothing, then nothing you shall receive," the voice in your head says.  "Your request is granted! Enjoy the nothing!"
						*goto Halfling_Used_Wish

				*label Halfling_Used_Wish
				
				The warmth fades from the necklace and the voices stop speaking.  No matter what you try, the necklace remains silent after this.  At the end of the two weeks, the magical lights erupt around you and take you back to Brightwater.
				*set teardrop_used_on_self true
				*if (naistalan_quest!="heard")
					*set teardrop_holding false
				*if (naistalan_quest="heard")
					*set teardrop_holding true
				*goto Warprep_loop
		*else
			*comment no teardop
			*goto Warprep_loop

		*label DiscussNecklace
		*if (naistalan_quest="heard")
			
			It is Auriel's Grief!  You realize that you have stumbled upon Naistalan's divine family heirloom.
			*if (teardrop_used)
				You also realize that the halfling tricked you into using it.  You called upon the gods and had them make Lomi become visible again, without even knowing you were doing it.
		*return
	*if ((theothea_inparty) and (theothea_injured))
		*allow_reuse #Attempt to heal ${theothea_name}.
			*if ((class_priest>=2) or (class_cleric>=1))
				You pray to ${god_name} and watch as ${theothea_name}'s wounds heal before your eyes.
				*if (showstats)
					(Religion +3 and ${theothea_name} Relationship +3)
				*set religion +3
				*set theothea_injured false
				*set theothea_relationship +3
				*goto Warprep_loop
			*else
				*if (class_priest=0)
					Your prayers aren't answered at all.
					*if (showstats)
						(Needed Training as a $!{priestpriestess} or Cleric)
					*goto Warprep_loop
				The wounds are too grievous to fully heal, although ${theothea_name} says that the pain is much less.
				*if (showstats)
					(Needed Higher Training as a $!{priestpriestess} or Cleric)
				*goto Warprep_loop
	*if ((gillgale_inparty) and (gillgale_injured))
		*allow_reuse #Attempt to heal ${gillgale_name}.
			*if ((class_priest>=2) or (class_cleric>=1))
				You pray to ${god_name} and watch as ${gillgale_name}'s wounds heal before your eyes.
				*if (showstats)
					(Religion +3 and ${gillgale_name} Relationship +3)
				*set religion +3
				*set gillgale_injured false
				*set gillgale_relationship +3
				*goto Warprep_loop
			*else
				*if (class_priest=0)
					Your prayers aren't answered at all.
					*if (showstats)
						(Needed Training as a $!{priestpriestess} or Cleric)
					*goto Warprep_loop
				The wounds are too grievous to fully heal, although ${gillgale_name} says that the pain is much less.
				*if (showstats)
					(Needed Higher Training as a $!{priestpriestess} or Cleric)
				*goto Warprep_loop
	*if ((peterpetra_inparty) and (peterpetra_injured))
		*allow_reuse #Attempt to heal ${peterpetra_name}.
			*if ((class_priest>=2) or (class_cleric>=1))
				You pray to ${god_name} and watch as ${peterpetra_name}'s wounds heal before your eyes.
				*if (showstats)
					(Religion +3 and ${peterpetra_name} Relationship +3)
				*set religion +3
				*set peterpetra_injured false
				*set peterpetra_relationship +3
				*goto Warprep_loop
			*else
				*if (class_priest=0)
					Your prayers aren't answered at all.
					*if (showstats)
						(Needed Training as a $!{priestpriestess} or Cleric)
					*goto Warprep_loop
				The wounds are too grievous to fully heal, although ${peterpetra_name} says that the pain is much less.
				*if (showstats)
					(Needed Higher Training as a $!{priestpriestess} or Cleric)
				*goto Warprep_loop
	*if ((karlkarla_inparty) and (karlkarla_injured))
		*allow_reuse #Attempt to heal ${karlkarla_name}.
			*if ((class_priest>=2) or (class_cleric>=1))
				You pray to ${god_name} and watch as ${karlkarla_name}'s wounds heal before your eyes.
				*if (showstats)
					(Religion +3 and ${karlkarla_name} Relationship +3)
				*set religion +3
				*set karlkarla_injured false
				*set karlkarla_relationship +3
				*goto Warprep_loop
			*else
				*if (class_priest=0)
					Your prayers aren't answered at all.
					*if (showstats)
						(Needed Training as a $!{priestpriestess} or Cleric)
					*goto Warprep_loop
				The wounds are too grievous to fully heal, although ${karlkarla_name} says that the pain is much less.
				*if (showstats)
					(Needed Higher Training as a $!{priestpriestess} or Cleric)
				*goto Warprep_loop
	*if ((jacejess_inparty) and (jacejess_injured))
		*allow_reuse #Attempt to heal ${jacejess_name}.
			*if ((class_priest>=2) or (class_cleric>=1))
				You pray to ${god_name} and watch as ${jacejess_name}'s wounds heal before your eyes.
				*if (showstats)
					(Religion +3 and ${jacejess_name} Relationship +3)
				*set religion +3
				*set jacejess_injured false
				*set jacejess_relationship +3
				*goto Warprep_loop
			*else
				The wounds are too grievous to fully heal, although ${jacejess_name} says that the pain is much less.
				*if (class_priest=0)
					Your prayers aren't answered at all.
					*if (showstats)
						(Needed Training as a $!{priestpriestess} or Cleric)
					*goto Warprep_loop
				*if (showstats)
					(Needed Higher Training as a $!{priestpriestess} or Cleric)
				*goto Warprep_loop
	*if (branbrinn_injured)
		*allow_reuse #Attempt to heal ${branbrinn_name}.
			*if ((class_priest>=2) or (class_cleric>=1))
				You pray to ${god_name} and watch as ${branbrinn_name}'s wounds heal before your eyes.
				*if (showstats)
					(Religion +3 and ${branbrinn_name} Relationship +3)
				*set religion +3
				*set branbrinn_injured false
				*set branbrinn_relationship +3
				*goto Warprep_loop
			*else
				*if (class_priest=0)
					Your prayers aren't answered at all.
					*if (showstats)
						(Needed Training as a $!{priestpriestess} or Cleric)
					*goto Warprep_loop
				The wounds are too grievous to fully heal, although ${branbrinn_name} says that the pain is much less.
				*if (showstats)
					(Needed Higher Training as a $!{priestpriestess} or Cleric)
				*goto Warprep_loop
	*allow_reuse #Stop gathering allies.
		Captain ${branbrinn_name} and General Vale come to your room a few days later.
		*temp allies_to_get false
		*if (warprep_spies="None")
			
			"Your Highness," Captain ${branbrinn_name} says.  "I really need to speak to you about our intelligence network."
		*if ((((warprep_dwarves=false) or (warprep_elves=false)) or ((warprep_gnomes=false) or (warprep_halflings=false))) or (warprep_halforcs=false))
			
			*set allies_to_get true
			"Are you mad?" General Vale says angrily when he learns that you intend to stop gathering allies.  "We must get all the help we can."
		*choice
			*if ((allies_to_get) and (warprep_spies="None")) #Say, "I am done.  I don't want to speak about spies or gather any more allies."
				*label Quitting_Give_Hate
				Captain ${branbrinn_name} and General Vale both leave your room angrily.
				*if (showstats)
					*line_break
					(Captain ${branbrinn_name} Relationship -10 and General Vale Relationship -10)
				*set branbrinn_relationship -10
				*set vale_relationship -10
				*goto Warprep_AlliesGathered
			*allow_reuse *if ((allies_to_get) and (warprep_spies="None")) #Say, "Very well.  What else do I need to do."
				Captain ${branbrinn_name} and General Vale are happy to hear that you will reconsider.
				*goto Warprep_loop
			*allow_reuse *if ((allies_to_get=false) and (warprep_spies="None")) #Say, "I am done.  I don't want to speak about spies."
				*goto Quitting_Give_Hate
			*allow_reuse *if ((allies_to_get=false) and (warprep_spies="None")) #Say, "Very well.  Tell me about the spy network."
				*goto Warprep_GetSpies
			*allow_reuse *if ((allies_to_get) and (warprep_spies!="None")) #Say, "I am done."
				*goto Quitting_Give_Hate
			*allow_reuse *if ((allies_to_get) and (warprep_spies!="None")) #Say, "Very well.  I will consider finding more allies."
				*goto Warprep_loop
*label Teleport
*if (warprep_teleport=0)
	Archmage Cumari is as good as his word.  A team of wizards from the Academy arrive in Brightwater for the winter with a cart full of stones.  Samuel, the Head Steward, gives them a suite of large rooms for their use.  The wizards carefully assemble the stones into a large arch which they show you when you come to their rooms.
	*if (using_legacy)
	
		At one point the Wizard of Elmvale ${legacy_himher}self appears in the room to look over the device.
		
		"It's an amazing piece of magic," ${legacy_heshe} says.  "It will help you a lot.  I wish I had this thing when I was younger.  It would have saved me a lot of walking."
		
		$!{legacy_heshe} vanishes a moment later.
	
	*if (companion_name!="None")
		The wizards watch as ${companion_name} ${companion_travels}.
		
		"We can send you, your ${companion_type} and one more person,"
	*if (companion_name="None")
		"We can send you and one more person,"
	the lead wizard says.  "In two weeks time, we will cast the spell to bring you back again."
*if (warprep_teleport=1)
	You go to the suite where the wizards from the Academy are staying.  The mages gather around the portal, ready to cast their magic.
	
	"Yes," one of the wizards says.  "The artifact is ready to be used again."
*if (warprep_teleport=2)
	You go to the suite where the wizards from the Academy are staying.
	
	"The artifact is holding up well," the lead wizard says.  "It has never been used this often before, but yes, it is ready."
*if ((warprep_teleport=3) or (warprep_teleport=4))
	You go to the suite where the wizards from the Academy are staying.  They gather around the stone portal and prepare it for use.
*temp asked_theothea false
*temp asked_karlkarla false
*temp asked_jacejess false
*temp asked_branbrinn false
*temp asked_gillgale false
*temp asked_peterpetra false
*label Choose_CurrentFriend_loop
*choice
	*if ((theothea_inparty) and (asked_theothea=false))
		*allow_reuse #Bring ${theothea_name} with you.
			*set asked_theothea true
			*if (theothea_injured)
				"I'd like to go," the large mountain-${theothea_manwoman} says in ${theothea_hisher} low voice.  "But I'm just not up to it.  I'm still sore from our last trip."
				*goto Choose_CurrentFriend_loop
			The large mountain-${theothea_manwoman} pats ${theothea_hisher} massive warhammer and smiles as ${theothea_heshe} steps forward with you.
			*if (showstats)
				*line_break
				(${theothea_name} Relationship +3)
			*set theothea_relationship +3
			*set currentfriend_name theothea_name
			*set currentfriend_hisher theothea_hisher
			*set currentfriend_heshe theothea_heshe
			*set currentfriend_himher theothea_himher
			*set currentfriend_lover theothea_lover
			*set currentfriend_relationship theothea_relationship
			*goto CurrentFriend_Chosen
	*if ((jacejess_inparty) and (asked_jacejess=false))
		*allow_reuse #Bring ${jacejess_name} with you.
			*set asked_jacejess true
			*if (jacejess_injured)
				"I can't go," the Soulburner says.  "I'm still not fully healed from before."
				*goto Choose_CurrentFriend_loop
			${jacejess_name} says nothing as ${jacejess_heshe} steps forward with you.
			*if (showstats)
				*line_break
				(${jacejess_name} Relationship +3)
			*set jacejess_relationship +3
			*set currentfriend_name jacejess_name
			*set currentfriend_hisher jacejess_hisher
			*set currentfriend_heshe jacejess_heshe
			*set currentfriend_himher jacejess_himher
			*set currentfriend_lover jacejess_lover
			*set currentfriend_relationship jacejess_relationship
			*goto CurrentFriend_Chosen
	*if ((karlkarla_inparty) and (asked_karlkarla=false))
		*allow_reuse #Bring ${karlkarla_name} with you.
			*set asked_karlkarla true
			*if (karlkarla_injured)
				"I'm sorry, ${name}," your archer friend says.  "I won't be any good on this trip. I'm still hurt from last time."
				*goto Choose_CurrentFriend_loop
			${karlkarla_name} checks the string on ${karlkarla_hisher} bow as ${karlkarla_heshe} steps forward with you.
			*if (showstats)
				*line_break
				(${karlkarla_name} Relationship +3)
			*set karlkarla_relationship +3
			*set currentfriend_name karlkarla_name
			*set currentfriend_hisher karlkarla_hisher
			*set currentfriend_heshe karlkarla_heshe
			*set currentfriend_himher karlkarla_himher
			*set currentfriend_lover karlkarla_lover
			*set currentfriend_relationship karlkarla_relationship
			*goto CurrentFriend_Chosen
	*if ((peterpetra_inparty) and (asked_peterpetra=false))
		*allow_reuse #Bring ${peterpetra_name} with you.
			*set asked_peterpetra true
			*if (peterpetra_injured)
				"Alas, I may not," ${peterpetra_name} says.  "My wounds have not yet healed from before."
				*goto Choose_CurrentFriend_loop
			${peterpetra_name} moves forward with you, ${peterpetra_hisher} armour rattling with each step.
			*if (showstats)
				*line_break
				(${peterpetra_name} Relationship +3)
			*set peterpetra_relationship +3
			*set currentfriend_name peterpetra_name
			*set currentfriend_hisher peterpetra_hisher
			*set currentfriend_heshe peterpetra_heshe
			*set currentfriend_himher peterpetra_himher
			*set currentfriend_lover peterpetra_lover
			*set currentfriend_relationship peterpetra_relationship
			*goto CurrentFriend_Chosen
	*if ((gillgale_inparty) and (asked_gillgale=false))
		*allow_reuse #Bring ${gillgale_name} with you.
			*set asked_gillgale true
			*if (gillgale_injured)
				"Not this time," ${gillgale_name} says with a smirk.  "I need to spend some time in the local taverns while my injuries heal.  The ale is purely medicinal, I assure you."
				*goto Choose_CurrentFriend_loop
			${gillgale_name} gracefully steps forward with you.
			*if (showstats)
				*line_break
				(${gillgale_name} Relationship +3)
			*set gillgale_relationship +3
			*set currentfriend_name gillgale_name
			*set currentfriend_hisher gillgale_hisher
			*set currentfriend_heshe gillgale_heshe
			*set currentfriend_himher gillgale_himher
			*set currentfriend_lover gillgale_lover
			*set currentfriend_relationship gillgale_relationship
			*goto CurrentFriend_Chosen
	*if ((branbrinn_inparty) and (asked_branbrinn=false))
		*allow_reuse #Bring ${branbrinn_name} with you.
			*set asked_branbrinn true
			*if (branbrinn_injured)
				"I'm afraid that my injuries prevent me from accompanying you, Your Highness," ${branbrinn_name} says apologetically.
				*goto Choose_CurrentFriend_loop
			The captain of the Brightwater guard steps forward with military precision.
			*if (showstats)
				*line_break
				(${branbrinn_name} Relationship +3)
			*set branbrinn_relationship +3
			*set currentfriend_name branbrinn_name
			*set currentfriend_hisher branbrinn_hisher
			*set currentfriend_heshe branbrinn_heshe
			*set currentfriend_himher branbrinn_himher
			*set currentfriend_lover branbrinn_lover
			*set currentfriend_relationship branbrinn_relationship
			*goto CurrentFriend_Chosen
	*allow_reuse #Go by yourself.
		You leave all of your friends behind as you step forward.
		*if (companion_name!="None")
			Of course, ${companion_name} still comes with you.
		*set currentfriend_name "None"
		*goto CurrentFriend_Chosen_ns
*label CurrentFriend_Chosen

*label CurrentFriend_Chosen_ns
*set currentfriend_injured false
*if (warprep_teleport=0)
	The wizards cast a series of spells in unison and soon you see a multitude of lights cascading across the portal.
*if (warprep_teleport!=0)
	The wizards cast their spells once more and the familiar lights erupt across the portal.
*if (currentfriend_name="None")
	You
	*if (companion_name!="None")
		and ${companion_name}
	step forward and through the arch.
*if (currentfriend_name!="None")
	You and ${currentfriend_name} step forward and through the
	*if (companion_name="None")
		arch.
	*if (companion_name!="None")
		arch with ${companion_name} following closely behind.
*page_break Suddenly, you are elsewhere.
*set currentfriend_injured false
*set warprep_teleport +1
*return

*label Warprep_AlliesGathered
*if (vampire)
	
	As the winter solstice passes, the days begin to get longer.  You find these sunny days increasingly uncomfortable.  One night, while returning from the army camps, you find yourself alone on the streets at night.  A sudden pain tears through your stomach and you double over in agony.  There is no question as to what is happening to you.  The blood from the vampire has infected you.  Luckily the ritual was incomplete or you would undoubtedly become a full-fledged creature of the night.  Despite your only partial vampirism, the need to feed is still present.
	*choice
		#Give in and feed on the soldiers in your army.
			The strong healthy blood relieves the pain immediately.  Not only that, but you feel much stronger than ever before.  The sun's light continues to bother you, forcing you to cover as much skin as you can.  The light hurts, but the effects are mild and you find yourself able to push through the irritation.
			*if (showstats)
				(Strength +3, Endurance +3 and Agility +3)
			*set strength +3
			*set endurance +3
			*set agility +3
			
			At first, you try to feed without killing.  But, the hunger often becomes insatiable as you feed and some of your victims die.  You learn the knack of using a dab of your own blood to heal the puncture wounds of your teeth so that the corpses' cause of death is indeterminable, allowing you to continue your new existence without being caught.
			*if (showstats)
				(Army Size -3, Army Morale -3 and Evil +20)
			*set army_size -3
			*set army_morale -3
			*gosub Check_Army_Stats
			*set good -20
			*goto War_Prep_After_Vamp
		#Give in and feed on the citizens of Brightwater.
			The commoners' blood relieves the pain immediately.  Not only that, but you feel much stronger than ever before.  The sun's light continues to bother you, forcing you to cover as much skin as you can.  The light hurts, but the effects are mild and you find yourself able to push through the irritation.
			*if (showstats)
				(Stealth +3, Unarmed +3 and Strength +3)
			*set stealth +3
			*set unarmed +3
			*set strength +3
			
			At first, you try to feed without killing.  But, the hunger often becomes insatiable as you feed and some of your victims die.  Despite the fact that the citizens don't know it's you, as their leader, they still blame you for their ills.  You learn the knack of using a dab of your own blood to heal the puncture wounds of your teeth so that the corpses' cause of death is indeterminable, allowing you to continue your new existence without being caught.
			*if (showstats)
				(Citizen Reputation -10 and Evil +20)
			*set citizen_reputation -10
			*set good -20
			*goto War_Prep_After_Vamp
		#Give in and feed on the nobles of Brightwater.
			The nobles' blood relieves the pain immediately.  Not only that, but you feel much stronger than ever before.  The sun's light continues to bother you, forcing you to cover as much skin as you can.  The light hurts, but the effects are mild and you find yourself able to push through the irritation.
			*if (showstats)
				(Perception +3, Charm +3 and Magic +3)
			*set perception +3
			*set charm +3
			*set magic +3
			
			At first, you try to feed without killing.  But, the hunger often becomes insatiable as you feed and some of your victims die.  Luckily, the deaths are limited to minor nobles who are replaced without too much difficulty.  Despite the fact that the nobles don't know it's you, their nightmares and restlessness make them irritable to everyone, including you and each other.  You learn the knack of using a dab of your own blood to heal the puncture wounds of your teeth so that the corpses' cause of death is indeterminable, allowing you to continue your new existence without being caught. 
			*if (showstats)
				(General Vale Relationship -5, Lord Tovor Relationship -5, Archmage Cumari Relationship -5 and Evil +20)
			*set vale_relationship -5
			*set tovor_relationship -5
			*set cumari_relationship -5
			*set good -20
			*goto War_Prep_After_Vamp
		#Fight the hunger and do not feed.
			Those late winter nights are very trying as you struggle with the damning thirst.  To your great relief, the hunger begins to fade.  Eventually, the sunlight hardly even bothers you.  You have beaten the terrible disease and saved your soul!  The struggle has made you a much stronger person too.
			*set vampire false
			*if (showstats)
				(Good +10 and Endurance +10)
			*set good +10
			*set endurance +10
			*goto War_Prep_After_Vamp
*else
	*goto War_Prep_After_Vamp

*label War_Prep_After_Vamp

The temperature begins to rise as winter turns to early spring. The army camps around Brightwater fill with soldiers in anticipation of war.  The Demonstone that Alexander Zusak stole on the night of your parents' murders, which you then stole back that same night, begins to act even stranger.  It had been dark back then, but over the last year, it has begun to flicker with lights.  As winter progresses, it begins to glow like any other Demonstone. 
*if (demonsummoner)
	A winter of preparation and study has increased your mental fortitude even further.
	*if (((((demonstone_xiatta) and (demonstone_xiatta_known=false)) or ((demonstone_zonch) and (demonstone_zonch_known=false))) or  (((demonstone_kgirr) and (demonstone_kgirr_known=false)) or  ((demonstone_brahl) and (demonstone_brahl_known=false)))) or  ((demonstone_tyborr) or ((demonstone_daanda) and (demonstone_daanda_known=false))))
		It is nice to have the resources of a ruling monarch since you are able to delegate responsibilities, including asking a sage to identify your unknown Demonstones:
		*if ((demonstone_kgirr) and (demonstone_kgirr_known=false))
			*line_break
			The one that has started glowing is named Ki'Girr.
			*set demonstone_kgirr_known true
		*if ((demonstone_xiatta) and (demonstone_xiatta_known=false))
			*line_break
			The one glowing a soft blue is named Xi'atta.
			*set demonstone_xiatta_known true
		*if ((demonstone_zonch) and (demonstone_zonch_known=false))
			*line_break
			The one glowing a greyish brown is named Zon'ch.
			*set demonstone_zonch_known true
		*if ((demonstone_brahl) and (demonstone_brahl_known=false))
			*line_break
			The one glowing a dull green is named Brahl.
			*set demonstone_brahl_known true
		*comment demonstone_tyborr_known doesn't exist, always known
		*if ((demonstone_daanda) and (demonstone_daanda_known=false))
			*line_break
			The one glowing a dim grey is named Daan'da.
			*set demonstone_daanda_known true
		*if (showstats)
			*line_break
			(Willpower +5)
		*set willpower +5
		*goto Warprep_Demon_Summon
	*else
		*if (showstats)
			*line_break
			(Willpower +5 and Arcana +10)
		*set willpower +5
		*set arcana +10
		*goto Warprep_Demon_Summon

	*label Warprep_Demon_Summon
	
	The hypocrisy of being a demon summoner yet restricting the practice among your subjects does not go unnoticed.  Luckily, your inner circle understands that knowing what your enemy knows is essential to your victory.
	*if (good<40)
		Either that, or they are too afraid of you to say anything about it.
	You learn that the Planewalkers of the Consortium employ a useful practice for summoning new demons which you replicate in Brightwater.
	*if (showstats)
		(Citizen Reputation -5 and Citizen Fear +5)
	*set citizen_reputation -5
	*set citizen_fear +5
	
	You commandeer a warehouse near the docks and hire some discreet workers to set up a space to practice.  They erect a pair of cages in the centre of an open area, one for you to stand in and one for your demon to be summoned in.  The demon's cage is ringed with soldiers holding spears, ready to send the being back to its own plane if the summoning goes poorly.
	*label Warprep_Demon_Summon_loop
	*choice
		#Summon K'Girr.
			*comment Never, this is plot!
			The Demonstone doesn't react normally.  You feel something straining to come into existence, but nothing appears.  Although you don't see the demon trying to come through, you sense that it is much larger and stronger than anything you have experienced before.
			*goto Warprep_Demon_Summon_loop			
		*if (demonstone_xiatta) #Summon Xi'atta.
			*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
			*comment: Max of 65 and Min 50
			Xi'atta appears in the cage across from you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.  The frosty demon's will is easy to overpower, giving you full control over the creature.  Content that the demon is now yours to command, you return it to its own plane of existence.
			*set demonstone_xiatta_summoned true
			*goto Warprep_Demon_Summon_loop
		*if (demonstone_zonch) #Summon Zon'ch.
			*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
			*comment: Max of 65 and Min 50
			Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one foot tall form.  The dusty demon's will pushes against your own, but you still dominate it.  Content that the demon is now yours to command, you return it to its own plane of existence.
			*set demonstone_zonch_summoned true
			*goto Warprep_Demon_Summon_loop
		*if (demonstone_brahl) #Summon Brahl.
			*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
			*comment: Max of 65 and Min 50
			Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
			*if (willpower>=70)
				The demon's will is difficult to overpower, but you still manage to do so, giving you full control over the creature.
			*if (willpower<70)
				The demon's will pushes against your own, but you still dominate it.  You have no worry of it overpowering you, although you feel that you might be hard-pressed to make the demon do something it really didn't want to do.
			Content that the demon is now yours to command, you return it to its own plane of existence.
			*set demonstone_daanda_summoned true
			*goto Warprep_Demon_Summon_loop
		*if (demonstone_daanda) #Summon Daan'da.
			*comment Will of 0, but very stupid and weak.
			Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
			The demon doesn't give you any resistance at all as you dominate its will.  Content that the demon is now yours to command, you return it to its own plane of existence.
			*set demonstone_daanda_summoned true
			*goto Warprep_Demon_Summon_loop
		*if (demonstone_tyborr) #Summon Tyborr.
			*comment Tyborr: Willing: 80, Small Struggle: 90, Against: 100
			*comment Max of 65 and Min 50
			Tyborr appears before you, wearing its brown robes.  The small five-and-a-half foot tall demon looks more like an old man with two stubby horns than a monster.  The demon doesn't say a word as it overpowers your will.  Instead of dominating you, it simply returns to its own plane of existence with a sad shake of its head.
			*if (showstats)
				(Needed 80 Willpower, which is impossible at this time)
			*goto Warprep_Demon_Summon_loop
		#Put away runebag.
			You close the runebag and put it away.
			*goto Warprep_KidCheck
*else
	You have no clue as to what it could mean.
	*goto Warprep_KidCheck
	
*label Warprep_KidCheck
*if ((prisonchild_exists) and (prisonchild_job!="academy"))
	
	One day, while you are walking through the halls of the keep, Lord Tovor intercepts you with two guards following closely behind.  You see that the guards are escorting two bloody youths.  One of them is ${prisonchild_name} and the other is
	*if (prisonchild_job="page")
		a young noble ${prisonchild_boygirl}.
	*if (prisonchild_job="kitchen")
		a young kitchen ${prisonchild_boygirl}.
	*if (prisonchild_job="alone")
		a young servant.
	${prisonchild_name} has a black eye and the other ${prisonchild_boygirl} has a fat lip.
	
	"I can't get the full story out of either of them," Lord Tovor says,  "but it took three guards to pull them apart."
	*choice
		#Punish ${prisonchild_name} for fighting.
			The guards release the other ${prisonchild_boygirl} and you see Lord Tovor take ${prisonchild_himher} away.  You scold ${prisonchild_name} all the way back to ${prisonchild_hisher} room.
			*if (showstats)
				*line_break
				(${prisonchild_name} Relationship -10)
			*set prisonchild_relationship -10
			*goto Warprep_After_KidCheck
		#Scold the other ${prisonchild_boygirl} for fighting.
			The ${prisonchild_boygirl}'s eyes fill with tears as ${prisonchild_heshe} mutters something under ${prisonchild_hisher} breath.  When you are done, Lord Tovor also scolds the child as he takes ${prisonchild_himher} away.  You see a smug smile grow across ${prisonchild_name}'s face as ${prisonchild_heshe} returns to ${prisonchild_hisher} own room.
			*if (showstats)
				*line_break
				(${prisonchild_name} Relationship +5 and Citizen Reputation -3)
			*set prisonchild_relationship +5
			*set citizen_reputation -3
			*goto Warprep_After_KidCheck
		#Scold both ${prisonchild_boygirl}s for fighting.
			The two ${prisonchild_boygirl}s stand quietly as you speak.  You see a tightening around ${prisonchild_name}'s eyes and the other ${prisonchild_boygirl} begins to cry as the ${princeprincess} of the realm scolds them both.
			*if (showstats)
				*line_break
				(${prisonchild_name} Relationship -2)
			*set prisonchild_relationship -2
			*goto Warprep_After_KidCheck
		#Say, "$!{prisonchild_boygirl}s will be ${prisonchild_boygirl}s.  Let them both go. They will figure it out on their own."
			"As you wish," Lord Tovor says.
			
			The guards release the youths.  You watch as they warily go in their own directions.  ${prisonchild_name} walks quickly back to ${prisonchild_hisher} room and Lord Tovor smiles awkwardly.
			*if (showstats)
				*line_break
				(${prisonchild_name} Relationship +5)
			*set prisonchild_relationship +5
			*goto Warprep_After_KidCheck
*else
	*goto Warprep_After_KidCheck

*label Warprep_After_KidCheck

*if (banter_name=gillgale_name)
	"We sure have come a long way," ${gillgale_name} says one night before dinner as you are waiting for the servants to bring you your dinner.
	
	*if (friend1_name!=gillgale_name)
		*set currentfriend_name friend1_name
		*set currentfriend_hisher friend1_hisher
		*set currentfriend_heshe friend1_heshe
		*set currentfriend_himher friend1_himher
		*goto RandomBanter_GillGale_2
	*else
		*set currentfriend_name friend3_name
		*set currentfriend_hisher friend3_hisher
		*set currentfriend_heshe friend3_heshe
		*set currentfriend_himher friend3_himher
		*goto RandomBanter_GillGale_2
	*label RandomBanter_GillGale_2
	"What did you take?" ${currentfriend_name} says angrily as ${currentfriend_heshe} storms into the dining hall.  "The servants said they saw you in my room.  Speak up."
	
	"I didn't take anything!" ${gillgale_name} says.
	*choice
		#Say, "${gillgale_name}, this is like the ring all over again.  Give back whatever you stole."
			"${name}, I am innocent," ${gillgale_name} says with an earnest look on ${gillgale_hisher} face.
			*if (showstats)
				*line_break
				(${gillgale_name} Relationship -10 and ${currentfriend_name} Relationship +10)
			*set friendinc 10
			*set gillgale_relationship -10
			*gosub Currentfriend_Increase
			
			You watch as ${gillgale_name} storms out of the room.
			*goto RandomBanter_GillGale_3
			
			*label RandomBanter_GillGale_3
			*if (gillgale_relationship<50)
				After dinner, several guards enter the dining hall with armloads of random things.  ${currentfriend_name} pulls out a few items that belong to ${currentfriend_himher}.  You realize that ${currentfriend_heshe} had the guards search ${gillgale_name}'s room.  And, sure enough, all of the stolen items were found.
				*choice
					#Keep the other stolen things for yourself.
						You find jewellery, gold coins and other valuables among the treasure.  Once you sell it all, you find that ${gillgale_name}'s dishonesty is very profitable for you.
						*if (showstats)
							*line_break
							(Evil +5 and Gold +220)
						*set good -5
						*set gold +220
						*goto After_Random_Banter
					#Try to find the owners of the items and donate everything unclaimed to charity.
						The owners of the stolen items are very happy to get their things back.  The temples are also happy as the donated items help the needy. ${gillgale_name}'s dishonesty ends up helping a lot of unfortunate people.
						*if (showstats)
							*line_break
							(Good +10)
						*set good +10
						*goto After_Random_Banter
					#Try to find the owners of the items and keep the rest for yourself.
						The owners of the stolen items are very happy to get their things back.  Once you sell what is left over, you find that ${gillgale_name}'s dishonesty is very profitable for you.
						*if (showstats)
							*line_break
							(Good +3 and Gold +190)
						*set good +3
						*set gold +190
						*goto After_Random_Banter
					#Reprimand ${currentfriend_name} for having the guards search ${gillgale_name}'s room and return the goods to the thief.
						${currentfriend_name} sputters mutely at your words.  The next time you see ${gillgale_name} ${gillgale_heshe} gives you a conspiratorial wink.
						*if (showstats)
							*line_break
							(${gillgale_name} Relationship +10 and ${currentfriend_name} Relationship -10)
						*set friendinc 0
						*set friendinc -10
						*set gillgale_relationship +10
						*gosub Currentfriend_Increase
						*goto After_Random_Banter
			*else
				After dinner, several guards enter the dining hall.
				
				"We went through ${gillgale_hisher} rooms thoroughly, but we didn't find anything," they say to ${currentfriend_name}
				*if (showstats)
					(Needed Under 50 ${gillgale_name} Relationship)
				
				"Thank you," ${currentfriend_name} says to the guards before turning to you.  "I guess I was wrong."
				*choice
					#Say, "I think you owe ${gillgale_name} an apology."
						"I guess I do," ${currentfriend_name} says with a frown as ${currentfriend_heshe} leaves to find the innocent rogue.
						*goto After_Random_Banter
					#Say, "${gillgale_name} probably just hid the stolen things too well for the guards to find."
						"You're probably right," ${currentfriend_name} agrees with you.
						*if (showstats)
							*line_break
							(${currentfriend_name} Relationship +3)
						*set friendinc 3
						*gosub Currentfriend_Increase
						*goto After_Random_Banter
		#Say, "${currentfriend_name}, you can't blame ${gillgale_name} for everything that goes missing."
			${gillgale_name} nods at your words as ${currentfriend_name} glowers.  The rest of the meal passes without incident and ${gillgale_name} leaves happily.
			*if (showstats)
				*line_break
				(${gillgale_name} Relationship +10 and ${currentfriend_name} Relationship -10)
			*set friendinc 0
			*set friendinc -10
			*set gillgale_relationship +10
			*gosub Currentfriend_Increase
			
			*goto RandomBanter_GillGale_3	
*if (banter_name=karlkarla_name)			
	*if (friend1_name!=karlkarla_name)
		*set currentfriend_name friend1_name
		*set currentfriend_hisher friend1_hisher
		*set currentfriend_heshe friend1_heshe
		*set currentfriend_himher friend1_himher
		*goto RandomBanter_KarlKarla_2
	*else
		*set currentfriend_name friend3_name
		*set currentfriend_hisher friend3_hisher
		*set currentfriend_heshe friend3_heshe
		*set currentfriend_himher friend3_himher
		*goto RandomBanter_KarlKarla_2
	*label RandomBanter_KarlKarla_2
	One night, while waiting for the servants to bring out your dinner, ${currentfriend_name} starts speaking in a frustrated tone.
	
	"It's your friend ${karlkarla_name}," ${currentfriend_name} says.  "Look, we've all been working hard to get the army ready for the march, but ${karlkarla_heshe} isn't doing anything!"
	*choice
		#Say, "I'll get General Vale to tell ${karlkarla_name} that ${karlkarla_heshe} has to help out somewhere too."
			${currentfriend_name} seems pleased with this and nods.  The next day, ${karlkarla_name} is put to work.
			*if (karlkarla_relationship<50)
				$!{karlkarla_heshe} teaches the soldiers some of the finer points of archery, although you can tell that your shy archer friend hates being forced to speak to people ${karlkarla_heshe} doesn't know.
				*if (showstats)
					*line_break
					(${currentfriend_name} Relationship +10, ${karlkarla_name} Relationship -10 and Army Power +15)
				*set friendinc 10
				*set karlkarla_relationship -10
				*set army_power +15
				*gosub Currentfriend_Increase
				*goto After_Random_Banter
			$!{karlkarla_heshe} spends long days doing manual labour for the army, such as carrying supplies.  A few days later, your shy archer friend approaches you to explain ${karlkarla_himher}self.
			
			"I'm sorry," ${karlkarla_heshe} says.  "I just…I feel nervous speaking to people I don't know.  But, I'll work hard, I promise.  I can carry boxes and do the jobs nobody else wants to do."
			*if (showstats)
				(Needed Under 50 ${karlkarla_name} Relationship)
				*line_break
				(${currentfriend_name} Relationship +10)
			*set friendinc 10
			*set army_power +10
			*gosub Currentfriend_Increase
			*goto After_Random_Banter
		#Say, "$!{karlkarla_heshe} didn't enlist as a soldier, so ${karlkarla_heshe} can do as little as ${karlkarla_heshe} likes."
			${currentfriend_name} nods at your words and doesn't bring it up again.
			*if ((((currentfriend_name=theothea_name) and (theothea_relationship<50)) or ((currentfriend_name=gillgale_name) and (gillgale_relationship<50))) or (((currentfriend_name=jacejess_name) and (jacejess_relationship<50)) or ((currentfriend_name=peterpetra_name) and (peterpetra_relationship<50))))
				A couple of days later you see ${karlkarla_name} training a few soldiers in archery and learn that ${currentfriend_name} brought the matter to ${karlkarla_name} ${currentfriend_himher}self.
				*if (showstats)
					*line_break
					(${karlkarla_name} Relationship -10 and Army Power +15)
				*set karlkarla_relationship -10
				*set army_power +15
				*gosub Currentfriend_Increase
				*goto After_Random_Banter 
			You occasionally see ${karlkarla_name} hiding in ${karlkarla_hisher} room or rushing quickly through the halls to spend time outside and away from all of the soldiers.
			*if (showstats)
				(Needed Under 50 ${currentfriend_name} Relationship)
				*line_break
				(${currentfriend_name} Relationship -10 and ${karlkarla_name} Relationship +10)
			*set friendinc 0
			*set friendinc -10
			*set karlkarla_relationship +10
			*gosub Currentfriend_Increase
			*goto After_Random_Banter
*if (banter_name=peterpetra_name)
	*if (friend1_name!=peterpetra_name)
		*set currentfriend_name friend1_name
		*set currentfriend_hisher friend1_hisher
		*set currentfriend_heshe friend1_heshe
		*set currentfriend_himher friend1_himher
		*goto RandomBanter_PeterPetra_2
	*else
		*set currentfriend_name friend3_name
		*set currentfriend_hisher friend3_hisher
		*set currentfriend_heshe friend3_heshe
		*set currentfriend_himher friend3_himher
		*goto RandomBanter_PeterPetra_2
	*label RandomBanter_PeterPetra_2
	"I'm exhausted," ${currentfriend_name} says before dinner one evening as you wait for the servants to bring you your meal.  "$!{peterpetra_heshe} was at it all night."
	
	At that moment, ${peterpetra_name} came in and glared at ${currentfriend_name} before speaking.  "I was praying.  It was a religious rite.  You didn't need to send the rat-catcher and his ferrets into my room."
	
	"I thought it was vermin," ${currentfriend_name} says coldly.  "All that wailing and moaning.  How was I to know he'd send all of his mousers in before knocking?"
	*temp supported_p false
	*choice
		#Say, "${currentfriend_name}, that was unkind.  You know that Daria promotes freedom of religion."
			"Yes, of course," ${currentfriend_name} says.  "But it was late and I didn't hear any signs of it stopping."
			*if (showstats)
				*line_break
				(${currentfriend_name} Relationship -10 and ${peterpetra_name} Relationship +10)
			*set friendinc 0
			*set friendinc -10
			*set peterpetra_relationship +10
			*gosub Currentfriend_Increase
			*set supported_p true
			*goto RandomBanter_PeterPetra_3
		#Say, "${peterpetra_name}, perhaps you could pray a little quieter in the future?"
			"Thank the Gods!" ${currentfriend_name} exclaims sarcastically.
			*if (showstats)
				*line_break
				(${currentfriend_name} Relationship +10 and ${peterpetra_name} Relationship -10)
			*set friendinc 10
			*set peterpetra_relationship -10
			*gosub Currentfriend_Increase
			*set supported_p false
			*goto RandomBanter_PeterPetra_3
		#Say, "You're both adults.  Figure it out on your own."
			${currentfriend_name} and ${peterpetra_name} glare at each other.
			*set supported_p false
			*goto RandomBanter_PeterPetra_3

	*label RandomBanter_PeterPetra_3
	
	*if (peterpetra_relationship<50)
		"This is ridiculous," ${peterpetra_name}
		*if (supported_p)
			says, despite the fact that you just supported ${peterpetra_himher}.
		*if (supported_p=false)
			says.
		"The Gods and Goddesses are pleased to hear loud prayer.  Perhaps I should follow some of the other rites as well?  Team chanting, fragrant incense, singing, the Winter Fast …"
		
		The late night praying from ${peterpetra_name} gets even louder after that.  $!{peterpetra_heshe} also encourages all of ${peterpetra_hisher} fellow worshippers to do the same.  At least the Winter Fast ends up becoming popular that year and saves a lot of extra food for the coming march.
		*if (showstats)
			*line_break
			(Army Food +15)
		*set army_food +15
		*goto After_Random_Banter
	*else
		"I shall strive to be more respectful with my religious observances in the future," ${peterpetra_name} says.  "I am sorry if I kept you awake, ${name}."
		*if (showstats)
			(Needed Under 50 ${peterpetra_name} Relationship)
		*goto After_Random_Banter
*if (banter_name=theothea_name)
	*if (friend1_name!=theothea_name)
		*set currentfriend_name friend1_name
		*set currentfriend_hisher friend1_hisher
		*set currentfriend_heshe friend1_heshe
		*set currentfriend_himher friend1_himher
		*goto RandomBanter_TheoThea_2
	*else
		*set currentfriend_name friend3_name
		*set currentfriend_hisher friend3_hisher
		*set currentfriend_heshe friend3_heshe
		*set currentfriend_himher friend3_himher
		*goto RandomBanter_TheoThea_2
	*label RandomBanter_TheoThea_2
	"${name}, you have to help me," ${currentfriend_name} says as ${currentfriend_heshe} enters the dining hall where you are waiting for the servants to bring out your dinner.  "${theothea_name} is drunk and just passed out in
	*if (currentfriend_name=lover_name)
		our
	*if (currentfriend_name!=lover_name)
		my
	bed.  $!{theothea_heshe} is too heavy for me to move!"
	*temp cur_room true
	*choice
		#Say, "Just let ${theothea_himher} sleep it off."
			*if (currentfriend_name=lover_name)
				You and ${currentfriend_name} are
			*if (currentfriend_name!=lover_name)
				${currentfriend_name} is
			forced to get a different room for the night.
			*if (showstats)
				*line_break
				(${currentfriend_name} Relationship -10 and ${theothea_name} Relationship +10)
			*set friendinc 0
			*set friendinc -10
			*set theothea_relationship +10
			*gosub Currentfriend_Increase
			*set cur_room true
			*goto RandomBanter_TheoThea_3
		*if (theothea_name!=lover_name) #Say, "Okay, let's move ${theothea_himher} to ${theothea_hisher} own room."
			*label Shared_Room_Carry
			Together, you try to wake up and carry the large mountain-${theothea_manwoman} back to
			*if (theothea_name=lover_name)
				your
			*if (theothea_name!=lover_name)
				${theothea_hisher} own
			room.  The string of slurred cursing that erupts from the big warrior is enough to wake up everyone in the castle.
			*if (showstats)
				*line_break
				(${currentfriend_name} Relationship +10 and ${theothea_name} Relationship -10)
			*set friendinc 10
			*set theothea_relationship -10
			*gosub Currentfriend_Increase
			*set cur_room false
			*goto RandomBanter_TheoThea_3
		*if (theothea_name=lover_name) #Say, "Okay, let's move ${theothea_himher} to my room."
			*goto Shared_Room_Carry
	*label RandomBanter_TheoThea_3
	
	In the morning,
	*if (cur_room)
		${currentfriend_name} is even angrier when ${currentfriend_heshe} returns to ${currentfriend_hisher} room and finds food stains all over ${currentfriend_hisher} bed.
	*if (cur_room=false)
		${theothea_name} wakes up to see food stains all over
		*if (theothea_name=lover_name)
			the
		*if (theothea_name!=lover_name)
			${theothea_hisher}
		bed.
	The stains continue out of the room and down the hall to your throne room.  A large pile of food is smeared across the arm rests and the cushion is soaked in beer.  ${theothea_name}
	*if (theothea_relationship<50)
		laughs at the mess, saying that ${theothea_heshe} doesn't remember going for a late night snack and eating it in the throne room.  Not caring that such an act is disrespectful to you, ${theothea_heshe} tells the story to everyone.  Instead of hurting your reputation, the soldiers enjoy the tale so much that it becomes the talk of the city for the next couple of weeks.
		*if (showstats)
			*line_break
			(Army Morale +15)
		*set army_morale +15
		*goto After_Random_Banter
	*else
		is mortified by what ${theothea_heshe} has done and is careful to tell nobody about the embarrassing incident, afraid that the disrespectful tale would tarnish your reputation.
		*if (showstats)
			(Needed Under 50 ${theothea_name} Relationship)
		*goto After_Random_Banter
*if (banter_name=jacejess_name)
	*if (friend1_name!=jacejess_name)
		*set currentfriend_name friend1_name
		*set currentfriend_hisher friend1_hisher
		*set currentfriend_heshe friend1_heshe
		*set currentfriend_himher friend1_himher
		*goto RandomBanter_JaceJess_2
	*else
		*set currentfriend_name friend3_name
		*set currentfriend_hisher friend3_hisher
		*set currentfriend_heshe friend3_heshe
		*set currentfriend_himher friend3_himher
		*goto RandomBanter_JaceJess_2
	*label RandomBanter_JaceJess_2
	"${jacejess_name} got hit in the back with a rotten egg again this morning," ${currentfriend_name} says to a guard near the dining table while you are waiting for the servants to bring you your dinner one night.
	
	"Did ${jacejess_heshe} catch the person who threw it?" the guard asks.
	
	"I don't think ${jacejess_heshe} did.  I just made sure that I didn't get hit too."
	*temp got_help true
	*choice
		#Say, "${currentfriend_name}, you should have chased down the culprit and had them punished."
			"I suppose I should have," ${currentfriend_name} agrees with embarrassment.  "People have been doing stuff like that to Soulburners for so long, I guess I was kind of used to it.  I'll help ${jacejess_name} catch the person tomorrow morning."
			*if (showstats)
				*line_break
				(${currentfriend_name} Relationship -10 and ${jacejess_name} Relationship +10)
			*set friendinc 0
			*set friendinc -10
			*set jacejess_relationship +10
			*gosub Currentfriend_Increase
			*set got_help true
			*goto RandomBanter_JaceJess_3
		#Say, "You'll have to make sure to leave some space between you and ${jacejess_name} when you're walking together."
			"You're right," ${currentfriend_name} says with a laugh.  "Next time they might throw rotten fish or something even more disgusting."
			
			You look over to see ${jacejess_name} listening to your conversation with a frown on ${jacejess_hisher} face.
			*if (showstats)
				*line_break
				(${currentfriend_name} Relationship +10 and ${jacejess_name} Relationship -10)
			*set friendinc 10
			*set jacejess_relationship -10
			*gosub Currentfriend_Increase
			*set got_help false
			*goto RandomBanter_JaceJess_3
		#Say nothing.
			You listen as ${currentfriend_name} and the guard laugh over the incident some more.
			*goto RandomBanter_JaceJess_3_ns
	
	*label RandomBanter_JaceJess_3
	
	*label RandomBanter_JaceJess_3_ns
	The following night you receive a report that ${jacejess_name} sent a group of citizens to the dungeons for throwing food.
	*if (got_help)
		It doesn't mention ${currentfriend_name} in the report, but you assume that ${currentfriend_heshe} helped.
	*if (jacejess_relationship<50)
		The Soulburner pressured the judiciary officials to exert the fullest extent of the law as punishment, despite the fact that they were wealthy merchants.  The officials fined them with rates proportional to their wealth and in the form of food, as a form of balance for the food wasted.  The merchants were very unhappy with the result, but the extra food sent to your army will make the spring march a little easier.
		*if (showstats)
			*line_break
			(Army Food +15)
		*set army_food +15
		*goto After_Random_Banter
	*else
		The Soulburner was surprisingly gentle on the food-throwers, allowing the judiciary officials to handle the punishment on their own.
		*if (showstats)
			(Needed Under 50 ${jacejess_name} Relationship)
		*goto After_Random_Banter
*comment Should never reach here.
*page_break Error:  You have encountered a small error.  Please tell the developer that you had banter_name: ${banter_name} but reached this error message.  Sorry!  It shouldn't affect the rest of the game.

*label After_Random_Banter

The camps on the outskirts of Brightwater begin to fill as your recruitment of soldiers continues.
*if (elf_help=0)
	You are surprised to see a small contingent of elves arrive.  General Vale suddenly seems nervous and guilty.  You later learn that the General used the portal himself to speak to the elves.  You can't help but wonder how many more soldiers you could have gotten if you had gone yourself.
	*if (showstats)
		*line_break
		(Army Size +7 and Army Power +7)
	*set army_size +7
	*set army_power +7
	
	"Somebody had to do it and you refused," he says to you before you even ask.  "Unfortunately, I couldn't get the help of any of the other demi-human races."
	
The looks on the faces of your troops and citizens are priceless as they see the demi-humans arrive.  They can't help but to gather and stare as creatures from children's stories join them in the army camp.  The elves arrive before the spring thaw, marching into Brightwater in perfect formation.  They each carry a longsword and a bow.  Naistalan Mubashair,
*if (elf_help=0)
	a half-elf cleric, leads them.
	
	"Did you find your family heirloom?" the general asks the half-elf.
	
	"Alas, no," the cleric says sadly.  "I will continue to look for Auriel's Grief after the war."	
	*set elf_help 1
	*goto After_Naistalan
the half-elf, leads them.
*if (wormrider)
	You hear gasps from the human citizens watching their arrival when they see ${mount_name}, your faithful forest worm.  You greet your mount on the street and say welcoming words to Naistalan as well.
*if (wormrider=false)
	You greet the cleric with welcoming words.
*if (teardrop)
	*if (naistalan_quest="has but silent")
		He looks sad, which you assume is because he never did find his family's heirloom.  This doesn't surprise you, since you found it and never told him.
	*if (naistalan_quest="heard")
		He looks sad, which you assume is because he never did find his family's heirloom.  This doesn't surprise you, since you have found the necklace yourself.
	*if (naistalan_quest="has and told")
		He has a large smile on his face, obviously due to the fact that he knows you have his family's heirloom.
	*label Warprep_teardrop_choice
	*choice
		*if ((naistalan_quest="has but silent") or (naistalan_quest="heard")) #Tell Naistalan that you have found Auriel's Grief.
			*label Warprep_teardrop_toldhim
			*set naistalan_quest "has and told"
			The half-elf's face lights up with happiness at your words.  You can tell that you have given the cleric new hope.
			
			"Where did you find it?"  he asks.  "Thank Auriel!  You have saved my family's honour!"
			*goto Warprep_teardrop_choice
		*if ((naistalan_quest="heard") or (naistalan_quest="has but silent")) #Don't mention the necklace and sell it when you get a chance.
			The half-elf has no idea that you are holding his salvation in your pocket.  You know that it will fetch a great price.  Mages and priests alike will pay quite a bit for the relic.  Perhaps it will eventually find its way back into Naistalan's hands, but you will be sure to sell it discretely so he never knows that you once possessed it.
			*if (showstats)
				*line_break
				(Evil +15 and Gold +400)
			*set good -15
			*set gold +400
			*set naistalan_quest "sold it"
			*set teardrop false
			*goto After_Naistalan
		*if (naistalan_quest="has and told") #Give the necklace to Naistalan.
			"I cannot overstate my gratitude," the half-elf says in his deep voice.  "You have redeemed my family's line and given me back my honour among the elves.  I shall truly never forget what you have done."
			*set naistalan_quest "gave it"
			*set teardrop false
			*label After_Naistalan_GotIt
			*choice
				#Ask Naistalan if he can use the necklace to aid your cause.
					"We shall see," the half-elf says.  "The fact of the matter is, a person may only use the necklace once in their lifetime."
					
					Naistalan's eyes widen.  "Oh my, you have used it.  I…can see the divine residue on you."
					*choice
						*if (teardrop_used_on_self=false) #Say, "I used it to turn the halfling thief visible once more."
							"I see," Naistalan says.  "I
							*goto Naistalan_Explain_NoMoreUse
						*if (teardrop_used_on_self) #Say, "It was an accident.  I didn't mean to use it."
							"This has happened before," Naistalan says.  "The Gods of Trickery love to take advantage of the untrained.  I
							*label Naistalan_Explain_NoMoreUse
							am sorry, but you may not use it again.  About
							*label Naistalan_Explain_Used
							10 years ago there was a terrible disease spreading through Oneiduin.  I used the relic to stop it, so I am also unable to use it again.  Instead, I shall train my offspring in its ways so that one day they may also serve the elves of the Alderheart.  Alas, my child is not yet born, so no, the teardrop is of no use to us, for it would take many years to train someone to use it in such a way that we would gain what we asked for."
							*goto After_Naistalan_GotIt
						#Say, "What about you.  Can you use it to help us?"
							"Unfortunately, no," Naistalan says.  "About
							*goto Naistalan_Explain_Used
				#Graciously ask for nothing more.
					The half-elf's entire demeanor has changed now that he has his precious family heirloom back.
					*if (showstats)
						*line_break
						(Good +10)
					*set good +10
					*goto After_Naistalan
				#Suggest that Naistalan grant you a monetary reward for your service.
					"I suppose that such a thing is only right," the half-elf says as he gives you a small pile of gold.
					*if (showstats)
						*line_break
						(Gold +120)
					*set gold +120
					*goto After_Naistalan
		*if (naistalan_quest="has and told") #Tell Naistalan that he must pay you for the necklace.
			Naistalan's happy expression turns into a frown.  He doesn't have to think about your blackmail for very long though, since he clearly desires to have the necklace back at all costs.  He hands you a sizable sum of gold and you give him the teardrop in return.
			*if (showstats)
				*line_break
				(Evil +10 and Gold +240)
			*set good -10
			*set gold +240
			*set naistalan_quest "blackmail"
			*set teardrop false
			*goto After_Naistalan
		*if ((naistalan_quest="heard") or (naistalan_quest="has but silent")) #Don't mention the necklace and keep it, hoping to someday unlock its power.
			The half-elf has no idea that you are holding his salvation in your pocket.   It is clearly powerful, and you hope that in time you may learn more of its secrets.
			*if (showstats)
				*line_break
				(Evil +15)
			*set good -15
			*set naistalan_quest "kept it"
			*goto After_Naistalan
*else
	*set naistalan_quest "heard but never found"
	He looks sad, which makes you think that his search for his family's heirloom has not been successful.
	*goto After_Naistalan

*label After_Naistalan

The elves set up their own camp slightly apart from the rest of your army and keep to themselves.
*temp added_a_break false
*if (dwarf_help>0)
	The dwarves march into the city in orderly rows.  They immediately begin to set up their portable forges and start sharpening your soldiers' blades.  Once battle begins, their smiths will repair broken weapons and armour as well.
*if (gnome_help>0)
	The gnome crossbowmen arrive shortly after, no longer disguised to look human.  They eye up the elven archers and you see that a friendly rivalry is likely to ensue.
*if (gnome_help=2)
	In addition to the crossbowmen, the siege engineers join your army.  They don't seem like much right now, but when the time comes, their skills will be of great use.
*if (halfling_help=1)
	
	*set added_a_break true
	The halfling outriders join your army too.  Although small, their speedy dogs and deadly accurate slings greatly impress General Vale, who immediately begins to make plans for their use.
*if (orc_help>0)
	*if (added_a_break=false)
		
		*comment endif
	The half-orcs march into Brightwater with Gurstwin in the lead.  The other soldiers immediately reach for their weapons and bloodshed is narrowly avoided.  They look down upon everyone else with arrogance and hostility.  Their presence makes everyone very uncomfortable.  You hope that their powerful presence is worth the troubles they will undoubtedly cause.
	*if (showstats)
		*line_break
		(Army Morale -5)
	*set army_morale -5
	*gosub Check_Army_Stats
*if (((dwarf_help>0) and (gnome_help>0)) and ((halfling_help>0) and (orc_help>0)))
	*set achievement_alliance true
	*achieve alliance
*if (theothea_story=10)
	
	In addition to the demi-humans, you are surprised to see a contingent of northmen from the Norgan Mountains arrive.  They are all broad shouldered and wear animal furs.  ${theothea_name} claps each of them on the back and finds a portion of the field for them to set up camp.
	
	"As the future chief of the Norgan clan, the welfare of Daria is my responsibility too," ${theothea_name} says.  "I had the wizards send me home near the beginning of winter.  The snow-filled passes may stop most warriors, but my brethren were born there.  A little snow can't stop us!"
	*if (showstats)
		(Army Power +7 and Army Size +7)
	*set army_power +7
	*set army_size +7

A few days later, General Vale comes to you with a concern.

"We need wizards," he says.  "You need to speak to Archmage Cumari.  So far, he hasn't sent any wizards to our army.  Their ability to throw fireballs, enchant blades and scout ahead with their magical sight would be invaluable."

You set up a meeting with the archmage.
*if (using_legacy)
	
	"I lent you the teleportation device, which is already against the rules," Archmage Cumari says sternly.  "Our time-traveling friend has requested that I give you many other things, including the full support of the Academy, but ${legacy_heshe} comes from a time long since passed.  Many things have changed since ${legacy_hisher} day.  Frankly, I don't know if all of the legends about ${legacy_himher} are even true.  I'm afraid that I must make decisions for the benefit of the wizards of today, although I will take ${legacy_hisher} words into account."
	*if (showstats)
		*line_break
		(Legacy Advantage #8: Archmage Cumari Relationship +20.  More perks will arrive as the story progresses.)
	*set cumari_relationship +20
*choice
	#Demand that Archmage Cumari provide wizards.
		"Demand?" the archmage says, arching an eyebrow.  "You overstep your bounds.  The academy has always been separate from the kingdom.
		*if (cumari_relationship<50)
			*label Warprep_Cumari_Dislike
			I see no reason to change this.  We will help as we see fit, but no, we will not be joining your army.
			*if (showstats)
				(Needed 50 Cumari Relationship)
			*set academy_help 0
			*goto Warprep_Class_Boost
		*if (cumari_gotstaff)
			But, the fact that you have recovered the Staff of the Archmagi means a lot to me.  I shall ask members of the academy to consider joining the army."
			*goto Warprep_Some_Wizards
		*if (academy_autonomy)
			You have promised us our autonomy on paper.  The wizards of the Academy will not be joining your army."
			*if (showstats)
				(Archmage Cumari Relationship -10)
			*set cumari_relationship -10
			*set academy_help 0
			*goto Warprep_Class_Boost
		*if (academy_stay="graduate")
			As a graduate of the Academy yourself, you should know better.
		If anyone wishes to join you, they may, but I will not force any wizards to your cause."
		*label Warprep_Some_Wizards
		*if (showstats)
			*line_break
			(Army Size +7 and Army Power +7)
		*set army_size +7
		*set army_power +7
		*set academy_help 1
		*goto Warprep_Class_Boost
	#Suggest to Archmage Cumari that wizards should join the army too.
		"Wizards, in your army?" the archmage says, arching an eyebrow.  "The academy has always been separate from the kingdom, although it is true, the demon summoning threat is a danger to us all.
		*if (cumari_relationship<50)
			*goto Warprep_Cumari_Dislike
		*if (cumari_gotstaff)
			The fact that you have recovered the Staff of the Archmagi means a lot to me.  I will suggest that people join you, but I cannot command them to do so."
			*goto Warprep_Lots_Wizards
		*if (academy_autonomy)
			But, you have promised us our autonomy and we do not wish to lose that.  The wizards of the Academy will not be joining your army."
			*set academy_help 0
			*goto Warprep_Class_Boost
		If any wizards wish to volunteer to join you, they
		*if (academy_stay="graduate")
			may.  As a graduate of the Academy, I suspect that many will flock to your cause."
			*goto Warprep_Lots_Wizards
		may, but I will not force them."
		*goto Warprep_Some_Wizards
		
		*label Warprep_Lots_Wizards
		*if (showstats)
			*line_break
			(Army Size +7 and Army Power +12)
		*set army_size +7
		*set army_power +12
		*set academy_help 2
		*goto Warprep_Class_Boost
	#Say nothing to Archmage Cumari.
		The wizards of the academy have always been independent of the kingdom.  Luckily, they know that the demon summoning threat is a scourge to everyone and a few wizards join your army without even being asked.
		*if (showstats)
			*line_break
			(Army Size +5 and Army Power +5)
		*set army_size +5
		*set army_power +5
		*set academy_help 1
		*goto Warprep_Class_Boost

*label Warprep_Class_Boost
*choice
	#You give pep talks to the soldiers.
		*if (class_knight=1)
			The soldiers and common people are all very interested to hear you talk as a knight of the realm.  They appreciate your knowledge of warfare and often ask you about the tournament you won your knighthood in.  Your words strengthen the people's resolve and cause more citizens to flock to your banner.
			*if (showstats)
				*line_break
			(Army Morale +10, Army Size +10 and Citizen Reputation +10)
			*set army_morale +10
			*set army_size +10
			*set citizen_reputation +10
			*goto War_Prep_End
		*if (class_cleric>0)
			You understand a soldier's position as the military arm of your faith.  The soldiers enjoy hearing you speak and appreciate your presence among them.  Although you try not to be too "preachy", you still
			*if (god_good)
				spread the word of ${god_name}.
			*if (god_good=false)
				secretly convert people into following ${god_name}.
			*if (class_cleric=2)
				*if (showstats)
					*line_break
				(Army Morale +10, Religion +5 and Citizen Reputation +10)
				*set army_morale +10
				*set religion +5
				*set citizen_reputation +10
				*goto War_Prep_End
			*comment (class_cleric=1)
			*if (showstats)
				(Needed More Cleric Levels for Increased Bonus)
				*line_break
			(Army Morale +7, Religion +5 and Citizen Reputation +7)
			*set army_morale +7
			*set religion +5
			*set citizen_reputation +7
			*goto War_Prep_End
		*if (class_squire>0)
			The soldiers respect what you have to say as a squire.  They appreciate that you have spent a life studying arms and serving knights.  Your military background makes them feel better about going to war under your command.
			*if (class_squire=2)
				*if (showstats)
					(Needed to be Knighted for Increased Bonus)
					*line_break
				(Army Morale +7, Army Size +5 and Citizen Reputation +7)
				*set army_morale +7
				*set army_size +5
				*set citizen_reputation +7
				*goto War_Prep_End
			*comment (class_squire=1)
			*if (showstats)
				(Needed to be Knighted for Increased Bonus)
				*line_break
			(Army Morale +5, Army Size +3 and Citizen Reputation +3)
			*set army_morale +5
			*set army_size +3
			*set citizen_reputation +3
			*goto War_Prep_End
		*if (class_guard>0)
			The soldiers love the fact that you have spent time as a guard.  It makes you appear much more approachable and fills them with confidence in knowing that you have been in their shoes.  They share jokes with you and you find that your presence calms them.  They work hard to impress you by becoming even more diligent with their training and, as a result, even better soldiers.
			*if (class_guard=1)
				*if (showstats)
					(Needed More Guard Levels for Increased Bonus)
					*line_break
					(Army Morale +3 and Army Power +5)
				*set army_morale +3
				*set army_power +5
				*goto War_Prep_End
			*if (class_guard=2)
				*if (showstats)
					(Needed More Guard Levels for Increased Bonus)
					*line_break
					(Army Morale +7 and Army Power +7)
				*set army_morale +7
				*set army_power +7
				*goto War_Prep_End
			*comment (class_guard=3)
			*if (showstats)
				*line_break
				(Army Morale +10 and Army Power +10)
			*set army_morale +10
			*set army_power +10
			*goto War_Prep_End
		*if (charm<30)
			Your speeches often fall flat.  The soldiers aren't happy to be following someone who they feel has no military background.  Unfortunately, you also don't have the gift of gab that would help them to overlook this fact.
			*if (showstats)
				(Needed 30 Charm or Military Background)
				*line_break
				(Army Morale -5)
			*set army_morale -5
			*gosub Check_Army_Stats
			*goto War_Prep_End
		*if (charm<60)
			Your speeches and talk go pretty well, considering that you have no military background to create a common bond between you and the soldiers. They listen to you speak and take heart that you are trying to be a good leader.
			*if (showstats)
				(Needed 60 Charm or Military Background for Increased Bonus)
				*line_break
				(Army Morale +5)
			*set army_morale +5
			*goto War_Prep_End
		*else
			You are of great comfort to the soldiers under your command.  Although they would have preferred you to have some experience in warfare, you still win many of them over with your kind and sympathetic words.
			*if (showstats)
				(Needed Military Background for Increased Bonus)
				*line_break
				(Army Morale +7)
			*set army_morale +7
			*goto War_Prep_End
	#You play music for the troops.
		*if (class_bard=0)
			*if (lute=false)
				With no formal musical training and no instrument, the soldiers soon dread your visits to the camp.  Some of them clap along as you sing, but many of them avoid you altogether.
				*if (showstats)
					(Needed Lute or Bardic Background)
					*line_break
					(Army Morale -5)
				*set army_morale -5
				*gosub Check_Army_Stats
				*goto War_Prep_End
			*else
				Despite your having no formal musical training, the soldiers appreciate your efforts.  They sing along with you as you play your lute, enjoying the songs and the companionship.
				*if (showstats)
					(Needed Bard Level for Increased Bonus)
					*line_break
					(Army Morale +5 and Citizen Reputation +5)
				*set army_morale +5
				*set citizen_reputation +5
				*goto War_Prep_End
		You are a talented musician and your skills soothe the soldiers. You attempt to find the delicate balance between courageously inspiring the troops and calmingly relaxing them during the long wait. The fact that you are also their monarch makes them even happier as they see that you are taking an interest in their wellbeing.
		*if (class_bard=1)
			*if (showstats)
				(Needed More Bard Levels for Increased Bonus)
				*line_break
				(Army Morale +7 and Citizen Reputation +7)
			*set army_morale +7
			*set citizen_reputation +7
		*if (class_bard=2)
			*if (showstats)
				(Needed More Bard Levels for Increased Bonus)
				*line_break
				(Army Morale +10 and Citizen Reputation +10)
			*set army_morale +10
			*set citizen_reputation +10
		*if (class_bard=3)
			*if (showstats)
				*line_break
				(Army Morale +15 and Citizen Reputation +15)
			*set army_morale +15
			*set citizen_reputation +15
		*goto War_Prep_End
	*if (class_monk>0) #You meditate with your soldiers and share your views as a monk.
		Soldiers spend a lot of time thinking about life and death.  Your words have a great calming influence which spreads through the ranks.  You teach your soldiers to breathe and meditate, allowing them to cope with their stress in a more manageable way.
		*if (class_monk=1)
			*if (showstats)
				(Needed More Monk Levels for Increased Bonus)
				*line_break
				(Army Morale +7)
			*set army_morale +7
			*goto War_Prep_End
		*if (class_monk=2)
			*if (showstats)
				(Needed More Monk Levels for Increased Bonus)
				*line_break
				(Army Morale +15)
			*set army_morale +15
			*goto War_Prep_End
		*comment (class_monk=3)
		*if (showstats)
			*line_break
			(Army Morale +20)
		*set army_morale +20
		*goto War_Prep_End
	#You talk to your soldiers about the Gods.
		Religion has always played a large part in every war.  Soldiers spend a lot of time thinking about death and they know that many of them will meet their makers before the war ends.
		*if (class_priest=0)
			Since you aren't a ${priestpriestess}, your words hold as much worth as the next person's.  You spend many late nights philosophizing about what the Gods have in store for you.  The soldiers appreciate your presence and take strength from your words.
			*if (showstats)
				(Needed a Religious Background)
				*line_break
				(Army Morale +3 and Religion +10)
			*set army_morale +3
			*set religion +10
			*goto War_Prep_End
		*else
			*comment a priest
			As a follower of ${god_name},
			*if (god_good)
				you have a lot of encouraging things to say to the soldiers.
				*if (god_heshe!="It")
					They take great comfort in your words and you see attendance in the temple increase dramatically.
				*if (god_heshe="It")
					Speaking about the Unknown God appeals to them since their own fates are so uncertain.  Before long, another new temple has been built in Brightwater.
				*if (class_cleric>0)
					As a cleric, the soldiers find your military background to be similar to their own, making them more at ease around you.
				*if ((class_priest=1) and (class_cleric=0))
					*if (showstats)
						(Needed More Priest or Cleric Levels for Increased Bonus)
						*line_break
						(Good +10, Army Morale +5 and Religion +10)
					*set good +10
					*set army_morale +5
					*set religion +10
					*goto War_Prep_End
				*if (((class_priest=2) and (class_cleric=0)) or (class_cleric=1))
					*if (showstats)
						(Needed More Priest or Cleric Levels for Increased Bonus)
						*line_break
						(Good +10, Army Morale +7 and Religion +10)
					*set good +10
					*set army_morale +7
					*set religion +10
					*goto War_Prep_End
				*comment ((class_priest=3) or (class_cleric=2))
				*if (showstats)
					*line_break
					(Good +10, Army Morale +10, Army Power +5 and Religion +10)
				*set good +10
				*set army_morale +10
				*set army_power +5
				*set religion +10
				*goto War_Prep_End
			*else
				*comment (god_good=false)
				you have your work cut out for you.  The fear and stress of the upcoming war makes the soldiers' souls very fertile to your words.  On the surface, they think you support the good Gods, but insidiously, you make people long for ${god_name}.  Nightmares fill the camps as the soldiers realize that their day of reckoning is approaching.  Your words also fill the soldiers with rage, cruelty and aggression, which will make them fiends on the battlefield.
				*if (class_cleric>0)
					As a cleric, the soldiers find your military background to be similar to their own, making them more at ease around you.
				*if ((class_priest=1) and (class_cleric=0))
					*if (showstats)
						(Needed More Priest or Cleric Levels for Increased Bonus)
						*line_break
						(Evil +10, Religion +10,  Army Morale -2 and Army Power +7)
					*set good -10
					*set religion +10
					*set army_morale -2
					*set army_power +7
					*gosub Check_Army_Stats
					*goto War_Prep_End
				*if (((class_priest=2) and (class_cleric=0)) or (class_cleric=1))
					*if (showstats)
						(Needed More Priest or Cleric Levels for Increased Bonus)
						*line_break
						(Evil +10,  Army Morale -5, Religion +10, and Army Power +12)
					*set good -10
					*set army_morale -5
					*set religion +10
					*set army_power +12
					*gosub Check_Army_Stats
					*goto War_Prep_End
				*comment ((class_priest=3) or (class_cleric=2))
				*if (showstats)
					*line_break
					(Evil +10, Army Morale -10, Religion +10 and Army Power +15)
				*set good -10
				*set army_morale -10
				*set religion +10
				*set army_power +15
				*gosub Check_Army_Stats
				*goto War_Prep_End
	#You help heal training injuries.
		You can hardly believe the number of injuries that occur on a daily basis.  Learning swordplay and archery has their expected injuries, but even daily labour causes ankles to roll, wrists to sprain and frostbite to occur.  Small injuries like blisters and rashes can cause a soldier's life to be even worse than it has to be.
		*if (class_priest=0)
			*if (nature<40)
				Unfortunately, you have no medical knowledge, so you spend most of your time boiling water and rolling bandages.  The soldiers appreciate your efforts nonetheless.
				*if (showstats)
					(Needed 40 Nature or Priest Levels for Increased Bonus)
					*line_break
					(Army Morale +2, Nature +5 and Army Power +2)
				*set army_morale +2
				*set nature +5
				*set army_power +2
				*goto War_Prep_End
			*else
				Your knowledge of herbs and medicines helps to relieve a lot of pain and get the soldiers back to training even quicker.
				*if (showstats)
					(Needed Priest Levels for Increased Bonus)
					*line_break
					(Army Morale +5, Nature +5 and Army Power +5)
				*set army_morale +5
				*set nature +5
				*set army_power +5
				*goto War_Prep_End
		*else
			*comment a priest
			As a follower of ${god_name},
			*if (god_good)
				you have been taught to heal people using both natural remedies and divine magic.
				*if (god_heshe="It")
					You are pleased to see that your new Unknown God hears your pleas when it comes to helping others.
				With a simple touch and a prayer, your healing energies are constantly being put to good use.  Although you don't preach too much, you still manage to pass on some tenants of your faith and gather a few new followers to ${god_name}.
				*if (class_cleric>0)
					As a cleric, your healing isn't as strong as that of a ${priestpriestess}, but your military knowledge makes your soldiers happier to follow you.
				*if ((class_priest=1) and (class_cleric=0))
					*if (showstats)
						(Needed More Priest or Cleric Levels for Increased Bonus)
						*line_break
						(Good +5, Army Morale +3, Religion +5, Nature +5 and Army Power +5)
					*set good +5
					*set army_morale +3
					*set religion +5
					*set nature +5
					*set army_power +5
					*goto War_Prep_End
				*if (((class_priest=2) and (class_cleric=0)) or (class_cleric=1))
					*if (showstats)
						(Needed More Priest or Cleric Levels for Increased Bonus)
						*line_break
						(Good +5, Army Morale +7, Religion +7, Nature +7 and Army Power +7)
					*set good +5
					*set army_morale +7
					*set religion +7
					*set nature +7
					*set army_power +7
					*goto War_Prep_End
				*comment (class_priest=3) or (class_cleric=2)
				*if (showstats)
					*line_break
					(Good +5, Army Morale +10, Religion +5, Nature +5 and Army Power +10)
				*set good +5
				*set army_morale +10
				*set religion +5
				*set nature +5
				*set army_power +10
				*goto War_Prep_End
			*else
				*comment (god_good=false)
				you have to be careful about your actions.  Your healing skills are as strong as someone who follows a good deity, even though each touch damns your patients' souls.  Nightmares spread across the army, but so does a sense of rage and aggression.  You also manage to secretly convert several people into following ${god_name}.
				*if (class_cleric>0)
					As a cleric, your healing isn't as strong as that of a ${priestpriestess}, but your military knowledge makes your soldiers happier to follow you.
				*if ((class_priest=1) and (class_cleric=0))
					*if (showstats)
						(Needed More Priest or Cleric Levels for Increased Bonus)
						*line_break
						(Evil +5, Religion +5, Nature +5 and Army Power +7)
					*set good -5
					*set religion +5
					*set nature +5
					*set army_power +7
					*goto War_Prep_End
				*if (((class_priest=2) and (class_cleric=0)) or (class_cleric=1))
					*if (showstats)
						(Needed More Priest or Cleric Levels for Increased Bonus)
						*line_break
						(Evil +5, Army Morale -2, Religion +7, Nature +7 and Army Power +10)
					*set good -5
					*set army_morale -2
					*set religion +7
					*set nature +7
					*set army_power +10
					*gosub Check_Army_Stats
					*goto War_Prep_End
				*comment ((class_priest=3) and (class_cleric=0)) or (class_cleric=2)
				*if (showstats)
					*line_break
					(Evil +5, Army Morale -5, Religion +10, Nature +10 and Army Power +15)
				*set good +5
				*set army_morale -5
				*set religion +10
				*set nature +10
				*set army_power +15
				*gosub Check_Army_Stats
				*goto War_Prep_End
	#You leave the soldiers alone and let them train with their own commanders.
		The soldiers gather and train as they wait for the winter weather to go away.  Your reports say that they are in decent spirits as they sharpen their swords and practice their archery.  The winter delay may prove to be a blessing in disguise as it allows them to improve their skills.
		*if (showstats)
			*line_break
			(Army Power +7)
		*set army_power +7
		*goto War_Prep_End

*label War_Prep_end
*if ((lover_exists) or (gonna_date_b))
	*comment ---------- everyone gets a chance to be physical here
	
	*if (lover_name=jacejess_name)
		Your door closes softly and you look up from your desk to see that ${jacejess_name} has entered the room the two of you share.  $!{jacejess_hisher} straight black hair is covering ${jacejess_hisher} face, but you can tell by the way ${jacejess_heshe} is walking that ${jacejess_heshe} is upset.  It's easy to guess why.  Although the people of Brightwater have been kind to your Soulburner lover when you are around, you know that ${jacejess_heshe} is subject to jeers and taunts when you aren't there.  ${jacejess_name}'s entire life has been this way, and being the Royal Consort to the ${princeprincess} of Daria hasn't changed this.
		*choice
			#Suggest that the two of you go for a walk over the bridge, knowing that many citizens will be there.
				The Brightwater Bridge is an enormous structure which gracefully spans a large frozen river and gives the city its name.  ${jacejess_name} hesitantly agrees to go, but you can tell that ${jacejess_heshe} doesn't want to.  It's a beautiful night and many other people stroll along the bridge with you.  You take ${jacejess_name}'s hand and walk proudly.  The other people give you wary looks as you flaunt your relationship with the Soulburner, but nobody says anything.  It will take many years to remove the stigma and prejudices that the citizens hold toward Soulburners, but it will come.
				*if (showstats)
					*line_break
					(Citizen Reputation +5 and ${jacejess_name} Relationship +10)
				*set citizen_reputation +5
				*set jacejess_relationship +10
				
				After your walk, you return to your room.  ${jacejess_name} closes the door and steps toward you.  You feel ${jacejess_hisher} soft lips pressed against your own.
				*goto Warprep_jacejess_SleepOption
			#Suggest that the two of you go to a quiet tower in a remote section of the keep.
				${jacejess_name} nods at your idea, happy to be away from the prying eyes of the public.  The two of you climb the remote tower and find yourselves sitting under a star-filled sky.  It's cold, but ${jacejess_name}'s
				*if (jacejess_name="Jess")
					soft
				*if (jacejess_name="Jace")
					firm
				body is warm.  $!{jacejess_heshe} is tense when you put your arm around ${jacejess_himher}, but the tension goes away after a few minutes.  You quietly talk to each other about your lives and watch the stars together.
				*if (showstats)
					*line_break
					(Nature +5 and ${jacejess_name} Relationship +10)
				*set nature +5
				*set jacejess_relationship +10
				
				${jacejess_name}'s pale skin seems even paler under the light of the stars.  You turn to say something to ${jacejess_himher}, but before you speak, ${jacejess_hisher} lips press firmly against your own.
				*goto Warprep_jacejess_SleepOption
			#Say, "Take me to the ones who spoke ill of you."
				A cruel smile crosses ${jacejess_name}'s face as ${jacejess_heshe} happily complies.  You are led through the keep to the great hall.  A handful of servants are mopping the floor and changing the candles.  ${jacejess_name} crosses ${jacejess_hisher} slender arms and nods toward them.  The servants look nervous, but say nothing as they continue to work.  A pair of guards stand near the door, pretending to not watch, but failing miserably.
				*choice
					#Send the servants to the dungeons for a few days.
						The guards snap to attention and drag the servants away at your command.  They weep and cry as they go, but they should have known better than to have insulted the Royal Consort.  Their time in the dungeon will teach them some manners.
						*if (showstats)
							*line_break
							(Citizen Fear +3 and ${jacejess_name} Relationship +10)
						*set citizen_fear +3
						*set jacejess_relationship +10
						*label WarPrep_JaceJess_ReturnToRoom
						
						${jacejess_name}'s face fills with a content smile as you walk back to your room.  $!{jacejess_heshe} closes the door and steps toward you.  You feel ${jacejess_hisher} soft lips pressed against your own.
						*goto Warprep_jacejess_SleepOption
					#Send the servants to the dungeons for a few years.
						The guards snap to attention and drag the servants away at your command.  They weep and cry as they go, but they should have known better than to have insulted the Royal Consort.  Their time in the dungeon will teach them some manners.
						*if (showstats)
							*line_break
							(Evil +5, Citizen Fear +7 and ${jacejess_name} Relationship +10)
						*set good -5
						*set citizen_fear +7
						*set jacejess_relationship +10
						*goto WarPrep_JaceJess_ReturnToRoom
					#Have the servants put to death for insulting the Royal Consort.
						The guards snap to attention and drag the servants away at your command.  They weep and cry as they go, but they should have known better than to have insulted the Royal Consort.  Their deaths will be a lesson to everyone else that ${jacejess_name} is to be treated with respect.
						*if (showstats)
							*line_break
							(Evil +15, Citizen Fear +10 and ${jacejess_name} Relationship +10)
						*set good -15
						*set citizen_fear +10
						*set jacejess_relationship +10
						*goto WarPrep_JaceJess_ReturnToRoom
					#Fire the servants and hire new ones.
						The servants weep and cry as they are released from service.  The guards escort them out of the keep and Samuel, the Head Steward, is informed that replacements will be needed.  ${jacejess_name} watches the proceedings quietly with ${jacejess_hisher} slender arms folded in front of ${jacejess_himher}.
						*if (showstats)
							*line_break
							(${jacejess_name} Relationship +10)
						*set jacejess_relationship +10
						*goto WarPrep_JaceJess_ReturnToRoom
					#Tell the servants that you are disappointed in their actions.
						The servants are mortified by your lecture.  They quickly apologize and turn red in embarrassment.  ${jacejess_name} watches the proceedings quietly with ${jacejess_hisher} slender arms folded in front of ${jacejess_himher}.
						*if (showstats)
							*line_break
							(Citizen Reputation +5 and ${jacejess_name} Relationship +10)
						*set citizen_reputation +5
						*set jacejess_relationship +10
						*goto WarPrep_JaceJess_ReturnToRoom
			#Push ${jacejess_hisher} hair from ${jacejess_hisher} face and kiss ${jacejess_hisher} lips.
				You can feel the familiar tension in ${jacejess_name}'s body as your lips meet, but after a moment, ${jacejess_heshe} relaxes.  It will take years before ${jacejess_heshe} is used to kindness and tender touches, but ${jacejess_heshe} is learning.
				*if (showstats)
					*line_break
					(${jacejess_name} Relationship +10)
				*set jacejess_relationship +10
				
				${jacejess_name} pulls you gently toward the bed as you kiss.  Your paperwork sits abandoned on the desk as ${jacejess_heshe} runs ${jacejess_hisher} fingers down your neck and across your shoulders.
				*label Warprep_jacejess_SleepOption
				*if (jacejess_sleptwith)
					$!{jacejess_hisher} slender hands take hold of your shirt and lift it over your head, breaking the kiss for only a moment.  The rest of the night is filled with passion as ${jacejess_heshe} takes comfort from your presence.
					*goto Warprep_After_LoverCheck
				*else
					*choice
						#Remove your clothing.
							$!{jacejess_hisher} slender hands hesitantly remove your clothing as you spend a wonderful night together.
							*set virgin false
							*set jacejess_sleptwith true
							*goto Warprep_After_LoverCheck
						#Continue to kiss ${jacejess_name} but leave the relationship the way it is.
							You and ${jacejess_name} spend a wonderful night together.
							*goto Warprep_After_LoverCheck
			#Say nothing to ${jacejess_name} and return to your reports.
				*set army_power +3
				*set army_morale +3
				*set jacejess_relationship -10
				*temp temp_lover_relationship jacejess_relationship
				The citizens' views toward Soulburners won't change overnight and there isn't a lot you can say about it.  ${jacejess_name} gets into bed quietly as you continue to work on your reports.
				*goto MadeWarNotLove
	*if ((lover_name=gillgale_name) and (lover_name!="None"))
		It was after supper while you were working on the supply reports at your desk that Captain ${branbrinn_name} came to your study.
		
		"${gillgale_name} has been taken into custody," the captain tells you.
		
		You leave everything where it is and rush down to the dungeons.  Sure enough, you see ${gillgale_name} lounging against the bars of the cell with a grin on ${gillgale_hisher} face.  You learn that ${gillgale_heshe} had been caught on the roof of a wealthy merchant, but no stolen goods were found in ${gillgale_hisher} possession.  You have the cell unlocked and send the guards away so you can speak to your lover privately.
		*choice
			#Ask, "Where did you hide the stolen objects?"
				"I put them in a canvas bag and threw it across to a different roof," ${gillgale_name} says with a grin.  "It was a good score too.  I'll give you a cut."
				*if (showstats)
					*line_break
					(Gold +100 and ${gillgale_name} Relationship +10)
				*set gold +100
				*set gillgale_relationship +10
				
				"I didn't think I'd be seeing the ${princeprincess} of Daria in a place like this," ${gillgale_name} says with a mischievous grin, stepping toward you.
				
				*goto Warprep_GillGale_Advances
			#Say, "I will have the guards whipped for falsely accusing you."
				${gillgale_name} seems uncertain if you are telling the truth or not, but you can see a mischievous spark in ${gillgale_hisher} eyes from your words as ${gillgale_heshe} steps toward you.
				*if (showstats)
					*line_break
					(Evil +5 and ${gillgale_name} Relationship +10)
				*set good -5
				*set gillgale_relationship +10
				
				*goto Warprep_GillGale_Advances
			#Bluff and say, "Perhaps a few weeks in the cell will teach you to keep your hands off of what doesn't belong to you."
				"Perhaps," ${gillgale_name} says with a mischievous grin.  "Perhaps I'll just have to keep my hands on what DOES belong to me?"
				*if (showstats)
					*line_break
					(${gillgale_name} Relationship +10)
				*set gillgale_relationship +10
				
				*label Warprep_GillGale_Advances
				You feel the rogue's graceful fingers on the back of your neck as ${gillgale_heshe} presses ${gillgale_hisher} firm athletic body against you.  The bars are solid against your back as ${gillgale_hisher} soft lips find your own.
				*label Warprep_GillGale_SleepOption
				*if (gillgale_sleptwith)
					$!{gillgale_hisher} slender hands reach down into your pants.  The guards don't disturb you as you spend the next hour in the dungeon.
					*goto Warprep_After_LoverCheck
				*else
					*choice
						#Remove your clothing.
							${gillgale_name}'s slender hands reach down into your pants.  The guards don't disturb you as you spend the next hour in the dungeon.
							*set virgin false
							*set gillgale_sleptwith true
							*goto Warprep_After_LoverCheck
						#Continue to kiss ${gillgale_name} but leave the relationship the way it is.
							The guards don't disturb you as you spend the next hour in the dungeon together.
							*goto Warprep_After_LoverCheck
			#Tell ${gillgale_name} that ${gillgale_hisher} behaviour is interfering with your work and that ${gillgale_heshe} will need to stop.
				${gillgale_name}'s face turns serious and ${gillgale_heshe} apologizes for ${gillgale_hisher} actions.  You return to the task of building your army.
				*set army_power +3
				*set army_morale +3
				*set gillgale_relationship -10
				*temp temp_lover_relationship gillgale_relationship
				*goto MadeWarNotLove
	*if (lover_name=peterpetra_name)
		The training yard is cleared of snow as the combatants circle each other with wary respect.  ${peterpetra_name}'s polished armour shines brightly in the afternoon sun.  Plumes of white breath burst from ${peterpetra_hisher} mouth as ${peterpetra_heshe} strikes ${peterpetra_hisher} opponent in the chest with the padded staff, knocking him to the ground.  The soldiers watching cheer as ${peterpetra_name} helps the fallen soldier to his feet before leaving the circle.
		*if (showstats)
			*line_break
			(Army Morale +3)
		*set army_morale +3
		
		${peterpetra_name} removes ${peterpetra_hisher} breastplate.  You can't help but notice how ${peterpetra_hisher} 
		*if (peterpetra_name="Peter")
			hard muscles
		*if (peterpetra_name="Petra")
			soft curves
		glisten with sweat from ${peterpetra_hisher} training.  $!{peterpetra_heshe} smiles as ${peterpetra_heshe} modestly steps into a changing hut ${peterpetra_heshe} had requested on the training grounds to get into fresh clothes.
		*choice
			#Go to the temple for a mid-afternoon sermon with ${peterpetra_name}.
				The citizens of Brightwater are friendly and nod to you both as you pass.  Before long, you find yourself in the large temple that ${peterpetra_name} enjoys going to.  You find yourself studying ${peterpetra_hisher} stern face.  $!{peterpetra_hisher} green eyes shine with devotion as ${peterpetra_heshe} listens.
				*if (showstats)
					*line_break
					(Religion +5 and ${peterpetra_name} Relationship +10)
				*set religion +5
				*set peterpetra_relationship +10
				*goto Warprep_PeterPetra_EndDay
			#Take a walk through the city streets with ${peterpetra_name}.
				The citizens of Brightwater are friendly and nod to you both as you pass.  You find yourself having to stop at every beggar and homeless person as ${peterpetra_name} drops a coin or two into their needy hands.
				*if (showstats)
					*line_break
					(Citizen Reputation +3 and ${peterpetra_name} Relationship +10)
				*set citizen_reputation +3
				*set peterpetra_relationship +10
				*label Warprep_PeterPetra_EndDay
				
				At the end of the day, you return to the room you share with ${peterpetra_himher}.  You see that ${peterpetra_name} has a large smile on ${peterpetra_hisher} face from a productive day.  $!{peterpetra_hisher} green eyes sparkle as ${peterpetra_heshe} firmly places ${peterpetra_hisher} arms around you and kisses you.  Although religious, ${peterpetra_hisher} order doesn't include chastity.
				*goto Warprep_PeterPetra_SleepOption
			#Enter the changing room.
				${peterpetra_name} is wearing only the underpadding from ${peterpetra_hisher} armour as you enter and close the door behind you.  $!{peterpetra_heshe} smiles as you squeeze up against ${peterpetra_himher}. You feel ${peterpetra_hisher} strong arms wrap around you and ${peterpetra_hisher} firm lips press against your own.
				*if (showstats)
					*line_break
					(${peterpetra_name} Relationship +10)
				*set peterpetra_relationship +10
				
				Despite any ideas you may have, modesty and dignity are strong values that ${peterpetra_name} holds dear.  Although religious, ${peterpetra_hisher} order doesn't include chastity, so you aren't too surprised to find yourself led back to the room you share in the keep.  The moment you step through the door, ${peterpetra_hisher} lips are upon you once more.
				*label Warprep_PeterPetra_SleepOption
				*if (peterpetra_sleptwith)
					$!{peterpetra_hisher} confident hands gently undo your clothing and you spend the rest of the day together.  As you make pillow-talk in ${peterpetra_hisher} arms, you learn even more about ${peterpetra_hisher} views of the world, especially ${peterpetra_hisher} love of religion, charity and doing what's right.
					*goto Warprep_After_LoverCheck
				*else
					*choice
						#Remove your clothing.
							${peterpetra_name}'s confident hands gently undo your clothing and you spend the rest of the day together.
							*set virgin false
							*set peterpetra_sleptwith true
							*goto Warprep_After_LoverCheck
						#Continue to kiss ${peterpetra_name} but leave the relationship the way it is.
							You and ${peterpetra_name} spend the rest of the day together.  You learn even more about ${peterpetra_hisher} views of the world, especially ${peterpetra_hisher} love of religion, charity and doing what's right.
							*goto Warprep_After_LoverCheck
			#Leave ${peterpetra_name} and return to your troop inspections on your own.
				*set army_power +3
				*set army_morale +3
				*set peterpetra_relationship -10
				*temp temp_lover_relationship peterpetra_relationship
				To ${peterpetra_hisher} credit, ${peterpetra_name} doesn't complain a single time about being left alone.
				*goto MadeWarNotLove
	*if (lover_name=theothea_name)
		"Gods, this is boring!" ${theothea_name} says, throwing back ${theothea_hisher} head and pounding your desk with ${theothea_hisher} fists.
		
		It was after supper and you had been working on the army supply reports for longer than you had thought.  It had been dark outside for a while now and the candles had melted to small waxy nubs.  ${theothea_name} had returned to your study smelling strongly of beer.
		*choice
			#Suggest that the two of you visit the rougher bars near the docks which ${theothea_name} enjoys.
				"Now you're talking!" ${theothea_name} says, roughly pulling you to your feet and ushering you out of the keep.
				
				The bar smells of stale beer, tobacco and vomit…but ${theothea_name} loves it.  A musician plays in the corner, singing bawdy and lewd songs which have everyone pounding the dented tables with their flagons.  Most of the patrons don't recognize you, since they don't expect the ${princeprincess} of Daria to be in such a place.
				
				You aren't even sure who starts the fight as ${theothea_name} throws a ${theothea_manwoman} across the room.  You see another patron pick up a chair and smash it over your lover's back.  From there, it's a blur.  On the walk back to the keep, ${theothea_name} spits some blood into the snow and grins at you.
				
				"Gods, that was fun," ${theothea_heshe} says with a big grin.
				*if (showstats)
					(${theothea_name} Relationship +10 and Unarmed +5)
				*set theothea_relationship +10
				*set unarmed +5
				*goto Warprep_Theothea_SleepOption
			#Suggest that the two of you visit the upscale bars near the keep which are more suitable to your station.
				"Better than this," ${theothea_name} says in ${theothea_hisher} deep voice, motioning to your desk of papers as ${theothea_heshe} shoulders the door open.
				
				The bar is clean and tidy.  A musician plays in the corner singing soft ballads as the patrons talk quietly among themselves.  Several of them nod greetings to you, but they respect your privacy and don't intrude as you and ${theothea_name} take a table.
				
				Your big mountain-${theothea_manwoman} orders many drinks and laughs louder than everyone else in the room.  You receive many stern looks, but ${theothea_name} doesn't care.  At the end of the night, you walk back to the keep through the snowy streets.
				
				"Next time, I get to choose the bar," ${theothea_heshe} says with a big grin.
				*if (showstats)
					(${theothea_name} Relationship +10 and Citizen Reputation -5)
				*set theothea_relationship +10
				*set citizen_reputation -5
				*goto Warprep_Theothea_SleepOption
			#Suggest that the two of you raid the keep's wine cellar together.
				"I like how you think, ${name}," ${theothea_name} says in ${theothea_hisher} deep voice as ${theothea_heshe} shoulders the door open.
				
				You dodge around the few servants on the way through the kitchens.  Although you would have been allowed to enter the wine cellar anyway, it was more fun to try to do it without being seen.  ${theothea_name} cracks open the first small cask of wine and fills two pewter flagons ${theothea_heshe} had thought to bring along.  The two of you laugh and drink late into the night, enjoying each others' company.  You and ${theothea_name} manage to empty an entire cask before deciding to retire for the night.
				*if (showstats)
					(${theothea_name} Relationship +10 and Stealth +5)
				*set theothea_relationship +10
				*set stealth +5
				*label Warprep_Theothea_SleepOption
				
				As you enter your room, ${theothea_name} grabs you firmly and pulls you close.  You feel ${theothea_hisher} mouth mash into your own as ${theothea_heshe} kicks the door closed behind you.
				*if (theothea_sleptwith)
					$!{theothea_hisher} muscular hands tear into your clothing as you spend a wonderful night together.
					*goto Warprep_After_LoverCheck
				*else
					*choice
						#Remove your clothing.
							$!{theothea_hisher} muscular hands tear into your clothing as you spend a wonderful night together.
							*set virgin false
							*set theothea_sleptwith true
							*goto Warprep_After_LoverCheck
						#Continue to kiss ${theothea_name} but leave the relationship the way it is.
							You and ${theothea_name} spend a wonderful night together.
							*goto Warprep_After_LoverCheck
			#Tell ${theothea_name} that you are too busy to entertain ${theothea_himher} tonight.
				*set army_power +3
				*set army_morale +3
				*set theothea_relationship -10
				*temp temp_lover_relationship theothea_relationship
				${theothea_name} throws ${theothea_hisher} hands into the air and storms out of your study.
				*goto MadeWarNotLove
	*if (lover_name=karlkarla_name)
		"I still can't believe it," ${karlkarla_name} says one cold winter morning as ${karlkarla_heshe} shakes ${karlkarla_hisher} head in amazement.  "Royal Consort to the ${princeprincess}."
		
		The great Brightwater Bridge, for which the city was named, spans a river which flows into the Silver Sea.  Many citizens spend their leisure time on the frozen river, so you aren't surprised when ${karlkarla_name} suggests that the two of you do the same.  Your archer lover would always be a peasant at heart.  $!{karlkarla_hisher} blond hair lays on ${karlkarla_hisher} thin shoulders as ${karlkarla_heshe} waits for your response.
		*choice
			#Suggest that you try to glide across the ice using the odd contraption you've seen the citizens wearing, shiny boots with blades attached on the bottom.
				You carry the devices out to the clear ice with ${karlkarla_name} at your side.  Many citizens nod a friendly greeting to you as you attempt the strange hobby.  ${karlkarla_name}'s grace quickly allows ${karlkarla_himher} to manage the sport, staying upright and sliding over the ice.
				*if (agility>=40)
					You also have no real difficulty in staying upright.
				*if (agility<40)
					You have a lot of difficulty in staying upright, but this only makes the experience more enjoyable.
				*if (showstats)
					*line_break
					(${karlkarla_name} Relationship +10 and Citizen Reputation +5)
				*set karlkarla_relationship +10
				*set citizen_reputation +5
				
				Together, you and ${karlkarla_name} skate upriver and around many bends until you are completely alone.  The river is all yours with nobody around.  You see a mischievous look in ${karlkarla_hisher} eyes, and before you can stop ${karlkarla_himher}, ${karlkarla_heshe} glides directly into you, knocking you into the soft snow at the river's edge.  You find yourself pinned under your normally shy archer lover, ${karlkarla_hisher} blond hair falling onto your face.  $!{karlkarla_hisher} cheeks and ears are red from the cold, but ${karlkarla_hisher} soft lips are warm as ${karlkarla_heshe} presses them gently against your own.
				*goto Warprep_Karlkarla_SleepOption
			#Suggest that you cut a hole in the ice and attempt to catch a fish.
				${karlkarla_name} knows exactly what to do as ${karlkarla_heshe} brings two rods with line, bait, a small lunch and an ice saw.  You walk past many others as you find your own spot on the ice.  You can see that ${karlkarla_name} has done this before.  $!{karlkarla_heshe} even has ${karlkarla_hisher} own small wooden hut.  You sit on the bench with your line through the small hole and talk softly while you wiggle the line, hoping to entice a fish to bite.
				*if (showstats)
					*line_break
					(${karlkarla_name} Relationship +10 and Nature +5)
				*set karlkarla_relationship +10
				*set nature +5
				
				Sitting still on the ice for several hours would normally be cold, except for the fact that ${karlkarla_name} presses ${karlkarla_hisher} thin athletic body against you.  You turn to speak to ${karlkarla_himher} and find ${karlkarla_hisher} face closer than you had expected.  $!{karlkarla_hisher} cheeks and ears are red from the cold, but ${karlkarla_hisher} soft lips are warm as ${karlkarla_heshe} presses them softly against your own.
				*goto Warprep_Karlkarla_SleepOption
			#Suggest that you range upriver and try to hunt small game for sport.
				${karlkarla_name} was clearly in ${karlkarla_hisher} element as ${karlkarla_heshe} nimbly crept between the snowy trees with ${karlkarla_hisher} bow in ${karlkarla_hisher} hand.  It wasn't about the small rabbits that you hunted; it was the alone time you had found together.
				*if (showstats)
					*line_break
					(${karlkarla_name} Relationship +10 and Nature +5)
				*set karlkarla_relationship +10
				*set nature +5
				
				After a few hours, you suddenly see ${karlkarla_himher} spin on ${karlkarla_hisher} heels and shoot an arrow at you!  It strikes the snow covered branch over your head, dumping a huge drift of fluffy white flakes onto your head.  You hear ${karlkarla_hisher} laugh amidst the white-out as ${karlkarla_heshe} uses the distraction to close the distance and tackle you to the ground.  You find yourself pinned under your normally shy archer lover, ${karlkarla_hisher} blond hair falling onto your face.  $!{karlkarla_hisher} cheeks and ears are red from the cold, but ${karlkarla_hisher} soft lips are warm as ${karlkarla_heshe} presses them gently against your own.
				*label Warprep_Karlkarla_SleepOption
				*if (karlkarla_sleptwith)
					$!{karlkarla_hisher} agile fingers reach down and undo your clothing as you spend a wonderful afternoon together.
					*goto Warprep_After_LoverCheck
				*else
					*choice
						#Remove your clothing.
							$!{karlkarla_hisher} agile fingers reach down and help you to undo your clothing as you spend a wonderful afternoon together.
							*set virgin false
							*set karlkarla_sleptwith true
							*goto Warprep_After_LoverCheck
						#Continue to kiss ${karlkarla_name} but leave the relationship the way it is.
							You and ${karlkarla_name} spend a wonderful afternoon together.
							*goto Warprep_After_LoverCheck
			#Refuse to go to the river and inspect your growing army instead.
				*set army_power +3
				*set army_morale +3
				*set karlkarla_relationship -10
				*temp temp_lover_relationship karlkarla_relationship
				To ${karlkarla_hisher} credit, ${karlkarla_name} doesn't complain a single time. 
				*label MadeWarNotLove
				$!{lover_heshe} knows how important the army is and how you won't get a second chance to attack Ludd and Tornassa.  With no time to spend together, the two of you grow apart over the winter.
				*if (temp_lover_relationship <50)
					It wasn't too surprising when ${lover_name} officially revoked ${lover_hisher} status as Royal Consort, leaving you single and alone.
					*if (showstats)
						*line_break
						(Army Power +3, Army Morale +3 and ${lover_name} Relationship -10)
					*set lover_name "None"
					*set lover_exists false
					*comment lover_relationship is set before coming here.
					*goto Warprep_After_LoverCheck
				*if (showstats)
					*line_break
					(Army Power +3, Army Morale +3 and ${lover_name} Relationship -10)
				*goto Warprep_After_LoverCheck
	*comment Only BranBrinn is left.
	With your winter travelling complete, you realize that it is time to speak to Captain ${branbrinn_name} about being named the Royal Consort.
	*choice
		#Call the captain into your study and tell ${branbrinn_himher} the plan.
			${branbrinn_name} enters your study in full uniform and stands at attention as though accepting orders.
			*if (branbrinn_name="Bran")
				His short brown beard is perfectly trimmed
			*if (branbrinn_name="Brinn")
				Her brown hair is pertly cut
			and ${branbrinn_hisher} equipment is in tip-top condition, as always.  $!{branbrinn_hisher} shirt looks freshly ironed and ${branbrinn_hisher} tabard is crisp and clean.  You explain the need for you to have a Royal Consort and how ${branbrinn_hisher} history in Brightwater makes ${branbrinn_himher} a perfect choice.
			*choice
				#Tell the captain that this is ${branbrinn_hisher} duty.
					${branbrinn_name} continues to stand at attention.  You can see ${branbrinn_himher} thinking about your words carefully.
					*if (showstats)
						*line_break
						(${branbrinn_name} Relationship -20)
					*set branbrinn_relationship -20
					*label BranBrinn_Will_Do_It
					
					"I agree to be your Royal Consort, for the time being…for the sake of the kingdom.  But, if the terms of this duty need to be changed, I will decide upon such things in the future."
					*gosub Date_BranBrinn
					
					You realize that this is the captain's way of saying that ${branbrinn_heshe} will do what is needed, but will not sleep with you or marry you.  It is a very formal beginning to such a relationship, but it will be enough to make your advisers happy.  You dismiss the captain and return to your work.
					*goto Warprep_After_LoverCheck
				#Offer the captain a choice.
					${branbrinn_name} continues to stand at attention.  You can see ${branbrinn_himher} thinking about your words carefully.
					*goto BranBrinn_Will_Do_It
		#Ask the captain out to dinner.
			Captain ${branbrinn_name} is caught off-guard when you extend the invitation, but ${branbrinn_heshe} accepts anyway.  You aren't certain if ${branbrinn_heshe} agrees because you are ${branbrinn_hisher} ${princeprincess}, or for more personal reasons.
			
			${branbrinn_name} comes to your private dining room in a casual uniform.
			*if (branbrinn_name="Bran")
				His short brown beard is perfectly trimmed
			*if (branbrinn_name="Brinn")
				Her brown hair is pertly cut
			and ${branbrinn_hisher} equipment is in tip-top condition, as always.  $!{branbrinn_hisher} chainmail looks freshly oiled and ${branbrinn_hisher} tabard is crisp and clean.
			*if (charm<50)
				The mealtime conversation is extremely awkward
			*if (charm>=50)
				The mealtime conversation goes well, but remains exclusively small talk
			as you aren't certain how to broach the subject.
			
			You learn that ${branbrinn_name} has lived ${branbrinn_hisher} entire life in Brightwater and rose through the military ranks at an early age due to ${branbrinn_hisher} merit and diligence.  You can't help but to notice that ${branbrinn_heshe} is very
			*if (branbrinn_name="Bran")
				handsome
			*if (branbrinn_name="Brinn")
				pretty
			and well-mannered.
			*label BranBrinn_Kiss_Choice
			*choice
				#Lean forward and kiss ${branbrinn_himher}.
					The captain doesn't flinch back from the kiss, but ${branbrinn_heshe} also doesn't return it.  You sense a great gulf between the two of you and you are uncertain as to how to cross it.
					*goto BranBrinn_Kiss_Choice
				#Linger near the captain and wait for ${branbrinn_himher} to kiss you.
					No matter how 'available' you make yourself, the captain doesn't make a move.  You aren't certain if it is due to your much higher rank or if the captain simply isn't interested.
					*goto BranBrinn_Kiss_Choice
				#Say, "I like you, ${branbrinn_name}."
					*if (((good>=55) and (citizen_reputation>=55)) and (branbrinn_relationship>=60))
						"I must admit, I am attracted to you too, my ${princeprincess}.  But I am worried about the difference in our stations.  I fear…it would not be proper."
						*if (showstats)
							*line_break
							(${branbrinn_name} Relationship +10)
						*set branbrinn_relationship +10
						*set branbrinn_romance 1
						*choice
							#Say, "You are highly respected by the people.  I think you would make a very good Royal Consort."
								*goto BranBrinn_Accepts
							#Say, "My advisers suggested that you be my Royal Consort."
								*goto BranBrinn_Accepts
							#Say, "I like you and you like me.  This is all that matters."
								*label BranBrinn_Accepts
								${branbrinn_name} smiles at your words.
								
								"Very well, I accept."
								*gosub Date_BranBrinn
								*choice
									#Invite ${branbrinn_name} back to your room.
										"I think that it is too soon, my ${princeprincess}," Captain ${branbrinn_name} says with a shake of ${branbrinn_hisher} head.
										*if (showstats)
											*line_break
											(${branbrinn_name} Relationship -10)
										*set branbrinn_relationship -10
										
										*label WrapUpDinner
										The rest of the dinner goes well and
										*if (branbrinn_name="Bran")
											Bran gives you a kiss before leaving.
										*if (branbrinn_name="Brinn")
											you give Brinn a kiss before leaving.
										The captain of the guard is courteous and gentle, but you sense great strength behind ${branbrinn_hisher} calm demeanour.
										*goto Warprep_After_LoverCheck
									#Kiss ${branbrinn_name} some more.
										The rest of the dinner is very pleasant and filled with many kisses as you and ${branbrinn_name} get to know each other better.  The captain of the guard is courteous and gentle, but you sense great strength behind ${branbrinn_hisher} calm demeanour.
										*goto Warprep_After_LoverCheck
									#Enjoy the rest of the dinner with ${branbrinn_name}.
										*goto WrapUpDinner
					*else
						"I am sorry, my ${princeprincess}.  I respect you as my ruler, but I am not attracted to you in a romantic way."
						*if (showstats)
							(Needed 55 Good, 55 Citizen Reputation and 60 ${branbrinn_name} Relationship)
						*choice
							#Discuss the position of Royal Consort.
								*goto Tell_Captain
							#Send the captain away and forget about the plan.
								The captain thanks you for a nice meal and leaves.
								*goto NoRoyalConsort
				#Discuss the position of Royal Consort.
					*label Tell_Captain
					"I see," ${branbrinn_heshe} says after some thought.  "I understand why people would find such a thing comforting."
					*if (showstats)
						*line_break
						(${branbrinn_name} Relationship +10)
					*set branbrinn_relationship +10
					*goto BranBrinn_Will_Do_It
		#Change your mind and remain single.
			*label NoRoyalConsort
			As time passes, your advisers soon realize that you have no intention of following through with the plan.  They are very upset about it and tell you that your decision will bring unnecessary instability and hardship to the people.  But, as you are ${princeprincess}, they can do no more than complain.
			*if (showstats)
				*line_break
				(Archmage Cumari Relationship -7, General Vale Relationship -7, Lord Tovor Relationship -7, Army Morale -5 and Citizen Reputation -10)
			*set cumari_relationship -7
			*set vale_relationship -7
			*set tovor_relationship -7
			*set army_morale -5
			*set citizen_reputation -10
			*gosub Check_Army_Stats
			*goto Warprep_After_LoverCheck

	*label Date_BranBrinn
	*set lover_name branbrinn_name
	*set lover_exists true
	*set lover_hisher branbrinn_hisher
	*set lover_himher branbrinn_himher
	*set lover_heshe branbrinn_heshe
	*set branbrinn_lover true
	*return
*else
	*goto Warprep_After_LoverCheck

*label Warprep_After_LoverCheck

It is about a week before you are to leave Brightwater when
*if (warprep_spies="Brightwater")
	your spy network uncovers a serious plot.  Your undercover agents have been skulking around the city all winter and passing on their information to Captain ${branbrinn_name}.  It is all small things up until now, such as deserters and spies being where they shouldn't be as they gather information about your actions.  But this time, they have uncovered something big.
	
	A small strike force has been sent from Tornassa by Selina with the sole purpose of sabotaging your army's food supplies.  With no time to lose, you gather ${friend1_name},
	*if (friend2_exists)
		${friend2_name},
	${friend3_name} and Captain ${branbrinn_name}.  You rush to the supply depot just in time to see flames spreading across the food stores.  The information from your spies is good.  Had you arrived any later, all of the food could have been destroyed.
	*if (showstats)
		*line_break
		(Army Food -5)
	*set army_food -5
	*gosub Check_Army_Stats
*if (warprep_spies!="Brightwater")
	the alarm sounds.  Your army is under attack!  You gather ${friend1_name},
	*if (friend2_exists)
		${friend2_name},
	${friend3_name} and Captain ${branbrinn_name}.  You rush to the camps and see not a full-fledged battle, but that a small strike force has set fire to the food stores.
	*if (showstats)
		*line_break
		(Army Food -30)
	*set army_food -30
	*gosub Check_Army_Stats

Your soldiers hadn't seen it coming and they are a chaotic mess as the squad captains shout orders to try to get your troops into some semblance of order.  They hadn't been expecting any violence before they had even left the city.  Your presence causes the soldiers to part in front of you, allowing you easy access to the flaming food stores.  With the thick smoke billowing around you, you aren't certain if the arsons are still present or have already fled the city.
*temp warprep_soldiers "None"
*choice
	#Order the soldiers to get buckets and put out the flames.
		*set warprep_soldiers "buckets"
		Your troops do as you ask.  They rush out to find buckets while others begin to form a line from the flames to the river.  You hear the sounds of battle coming from the other side of the depot.  You and your companions run there immediately.
		*goto Food_Fire_Battle
	#Order the soldiers to draw their weapons and charge forward.
		*set warprep_soldiers "attack"
		Your troops do as you ask, charging into the smoke and fire.
		*goto Food_Fire_Battle
	#Order the soldiers to hold and guard your back.
		*set warprep_soldiers "defend"
		Your troops do as you ask, forming a perimeter around you and the food stores.  You hear the sounds of battle coming from the other side of the depot.  You and your companions run there immediately.
		*goto Food_Fire_Battle

*label Food_Fire_Battle
*if (prisoner1_name=karlkarla_name)
	A soldier falls to the ground with an arrow through the eye.  Before you can blink, another falls in the same manner.  You see Selina's strike team.  In the lead is a hooded ${prisoner1_manwoman} wearing a red cloak and holding a bow.
	
	"It's the ${prisoner1_nickname}!" a soldier yells.
	
	The ${prisoner1_manwoman} in red puts a third arrow to ${prisoner1_hisher} string and shoots it through the soldier's throat before turning ${prisoner1_hisher} back on you.
*if (prisoner1_name=theothea_name)
	A soldier falls to the ground with a thud.  Before you can blink, another falls.  You see Selina's strike team.  In the lead is a hooded ${prisoner1_manwoman} wearing a red cloak and holding a bloody red hammer.
	
	"It's the ${prisoner1_nickname}!" a soldier yells.
	
	The ${prisoner1_manwoman} in red swings ${prisoner1_hisher} weapon at the soldier and smashes his head into a pulpy mess before turning ${prisoner1_hisher} back on you.
*if (prisoner1_name=jacejess_name)
	A soldier falls to the ground with a smoking hole in his chest.  Before you can blink, another falls in the same manner.  You see Selina's strike team.  In the lead is a hooded ${prisoner1_manwoman} wearing a red cloak.
	
	"It's the ${prisoner1_nickname}!" a soldier yells.
	
	The ${prisoner1_manwoman} in red turns to the soldier and you see a beam of intense light strike the poor man in the chest.  It burns a hole right through him and he falls to the ground dead as the killer turns ${prisoner1_hisher} back on you.
*if (prisoner1_name=peterpetra_name)
	A soldier falls to the ground in agony.  Before you can blink, another falls in the same manner.  They both have black sores across their faces and their necks are swollen as they choke to death.  You see Selina's strike team.  In the lead is a hooded ${prisoner1_manwoman} wearing a red cloak with ${prisoner1_hisher} hand outstretched.
	
	"It's the ${prisoner1_nickname}!" a soldier yells.
	
	The ${prisoner1_manwoman} in red turns to the soldier. You see draw a wicked looking morningstar made from some dark metal from ${prisoner1_hisher} belt and bludgeon the poor man to death before turning ${prisoner1_hisher} back on you.
*if (prisoner1_name=gillgale_name)
	A soldier falls to the ground.  Before you can blink, another falls.  You see Selina's strike team but it takes you a moment to understand how the soldiers died.  Suddenly, a hooded ${prisoner1_manwoman} holding two sharp swords stands up from behind the dead soldiers.  $!{prisoner1_heshe} is wearing a red cloak, but through some mystical skill, ${prisoner1_heshe} still managed to hide from the guards and strike from behind.
	
	"It's the ${prisoner1_nickname}!" a soldier yells.
	
	The ${prisoner1_manwoman} in red spins quickly and slashes open the soldier's throat before turning ${prisoner1_hisher} back on you.
This must be Selina's new bodyguard whom she claims saved her from the assassin that killed Duke Uddo.  You suspect that Selina killed Uddo herself and likely had this ${prisoner1_manwoman}'s help.  The group of people with the ${prisoner1_nickname} draw swords and rush toward you as the ${prisoner1_manwoman} in red runs off in the other direction.
*choice
	*if (warprep_soldiers="buckets") #Tell your soldiers to drop their buckets and fight the enemy.
		*set warprep_soldiers "attack"
		*goto FoodFight_SoldiersFight
	*if ((warprep_soldiers="defend") or (warprep_soldiers="attack")) #Step back and allow your soldiers to deal with the enemy.
		*label FoodFight_SoldiersFight
		Your troops are eager to show their worth to you.  The battle is short and intense, but in the end, the strike force is wiped out except for the ${prisoner1_nickname}.
		*label FoodFight_WonFight
		
		*if (warprep_soldiers="buckets")
			The soldiers finish putting out the flames and no more food is burned.  The invaders have nothing identifiable on them, but you do find a suspicious package about the size of a small loaf of bread in one of their backpacks.  The rest of their belongings can be sold for gold.
			*if (showstats)
				*line_break
				(Gained Small Package and Gold +120)
			*set small_package true
			*set gold +120
			*goto After_StrikeForce
		*else
			Unfortunately, the food stores continue to burn before the battle is ended and the soldiers can deal with the flames.  The invaders have nothing identifiable on them, but you do find a suspicious package about the size of a small loaf of bread in one of their backpacks.  The rest of their belongings can be sold for gold.
			*if (showstats)
				*line_break
				(Army Food -10, Gained Small Package and Gold +120)
			*set army_food -10
			*set small_package true
			*set gold +120
			*gosub Check_Army_Stats
			*goto After_StrikeForce
	#Begin banging heads together and breaking kneecaps.
		*if (unarmed>=50)
			The good thing about fighting multiple opponents is that you can use them as living shields.  You can strike anyone you like, but they must be careful to not hit each other.  As your foot drives into the leg of one man, you grab another and throw him into a third.  The battle is short and intense, but in the end, the strike force is wiped out except for the ${prisoner1_nickname}.
			*if (showstats)
				*line_break
				(Unarmed +3)
			*set unarmed +3
			*goto FoodFight_WonFight
		You strike one man in the leg and miss your grab on another.  Luckily your companions are there to rush to your aid.
		*if (showstats)
			(Needed 50 Unarmed)
		*goto FoodFight_LostFight
	#Ignore the enemy and try to use magic to put out the fire.
		*if (magic>=50)	
			You cast your spell and watch as a cloud grows over the flames.  Rain begins to pour from your magical creation, dousing the fire.  Your quick actions stop any more food from burning, although the arsonists get away.
			*if (showstats)
				*line_break
				(Magic +3)
			*set magic +3
			*goto After_StrikeForce
		Your spell sputters and only a small puff of cloud appears.  The minimal amount of rain that comes from the cloud hardly affects the fire, but the arsonists get away anyway.  Eventually the soldiers lend a hand and the flames are extinguished.
		*if (showstats)
			(Needed 50 Magic)
			*line_break
			(Army Food -10)
		*set army_food -10
		*gosub Check_Army_Stats
		*goto After_StrikeForce
	*if (bow) #Draw your bow and attack.
		*if (archery>=40)
			Your arrow pierces one of the enemies in the heart.  Your companions rush to your aid.  The battle is short and intense, but in the end, the strike force is wiped out except for the ${prisoner1_nickname}.
			*if (showstats)
				*line_break
				(Archery +3)
			*set archery +3
			*goto FoodFight_WonFight
		Your arrow misses as your companions rush to your aid.
		*if (showstats)
			(Needed 40 Archery)
		*goto FoodFight_LostFight
	*if (sword) #Draw your sword and attack.
		*goto FoodFight_Blade
	*if (dagger) #Draw your dagger and attack.
		*label FoodFight_Blade
		*if (blades>=40)
			Your blade pierces one of the enemies in the heart.  Your companions rush to your aid.  The battle is short and intense, but in the end, the strike force is wiped out except for the ${prisoner1_nickname}.
			*if (showstats)
				*line_break
				(Blades +3)
			*set blades +3
			*goto FoodFight_WonFight
		Your blade is turned aside as your companions rush to your aid.
		*if (showstats)
			(Needed 40 Blades)
		*label FoodFight_LostFight
		
		The strike team scatters in different directions.  The battle is short and intense, but in the end, the ${prisoner1_nickname} and a few others get away.
		*if (warprep_soldiers="buckets")
			At least your soldiers managed to put the flames out before any more food was burned.
			*goto After_StrikeForce
		Even worse, more food burns before your soldiers turn their attention to putting out the fire.
		*if (showstats)
			*line_break
			(Army Food -10)
		*set army_food -10
		*gosub Check_Army_Stats
		*goto After_StrikeForce
	#Cast a spell of suffocation over the enemy.
		*if (magic<50)
			Your spell takes too long to have any effect as the enemy steps back and out of range of your spell.
			*if (showstats)
				(Needed 50 Magic)
			*goto FoodFight_LostFight
		The enemy soldiers grab their throats as they gasp for air.  Your companions rush to your aid, killing them before they can fight back.  The battle is short and intense, but in the end, the strike force is wiped out except for the ${prisoner1_nickname}.
		*if (showstats)
			*line_break
			(Magic +3)
		*set magic +3
		*goto FoodFight_WonFight
	#Let the enemy go free.
		The strike force turns toward the ${prisoner1_nickname} and runs after ${prisoner1_himher}.
		*if (warprep_soldiers="buckets")
			Your soldiers finish putting out the fire and nothing more is lost.
			*goto After_StrikeForce
		Without having to fight anyone, your soldiers turn their attention to the fire and put it out, only losing a little more food.
		*if (showstats)
			(Army Food -5)
		*set army_food -5
		*gosub Check_Army_Stats
		*goto After_StrikeForce

*label After_StrikeForce

In the morning, you receive a full report.  Seven soldiers dead, food stores burned and the ${prisoner1_nickname} escaped.
*if (small_package)
	The small package is identified to be a bundle of poison within a special dissolvable casing.  The poison is so toxic that you are told that opening it would likely kill the person and that it was made to be thrown into a water source.  Had the strike force put the package into the city's well system, your army would have been lost.  You aren't surprised to hear that Selina had tried to use poison against you again.
	*set poison_package true
	*set small_package false
*if (warprep_spies="Brightwater")
	It was a difficult loss, but it would have been worse had your spies not uncovered the plot when they did.
*if (warprep_spies!="Brightwater")
	It was a difficult loss, but it would have been worse had you not gotten to the fire when you did.
	*if (showstats)
		*line_break
		(Army Morale -3)
	*set army_morale -3
	*gosub Check_Army_Stats
*goto Check_Kid

*label Check_Kid
*if ((prisonchild_exists) and (prisonchild_job!="academy"))
	
	As you are getting ready to begin the march, ${prisonchild_name} shows up in your room fully dressed for travel.  It is clear that ${prisonchild_heshe} plans to come with you, even though a war camp is no place for a child.
	*choice
		#Take ${prisonchild_name} with you.
			Although it will be dangerous, at least you will be around to protect ${prisonchild_name}.  You see the glimmer of a small smile on ${prisonchild_hisher} face, which is the most emotion you've seen out of the troubled youth since you found ${prisonchild_himher}.  You leave your room.
			*if (showstats)
				*line_break
				(${prisonchild_name} Relationship +5)
			*set prisonchild_relationship +5
			*set prisonchild_inparty true
			*goto After_Check_Kid
		#Leave ${prisonchild_name} behind with Samuel, the Head Steward.
			${prisonchild_name} angrily throws ${prisonchild_hisher} travel bag at your feet and storms away.  When you inform Samuel that he is to look after ${prisonchild_name}, the Head Steward looks just as upset over the fact.  At least you know that ${prisonchild_name} will be safe in Brightwater.
			*if (showstats)
				*line_break
				(${prisonchild_name} Relationship -5)
			*set prisonchild_relationship -5
			*set prisonchild_inparty false
			*set prisonchild_job "Samuel"
			*goto After_Check_Kid
*else
	*goto After_Check_Kid

*label After_Check_Kid

*gosub ResetAdventure
It is nearly time to go.  Although you haven't been given full access to the treasury, you are paid a wage for your leadership.  The calculation of your wage is so convoluted that only Lord Tovor seems to understand it, but he says that it's connected to how well the economy is based upon what is projected.  You realize that it's your last chance to purchase what you may need.
*if (citizen_reputation<100)
	*if (showstats)
		(Increased Citizen Reputation Increases Gold Gained)
*temp temp_citizen_rep 0
*set temp_citizen_rep citizen_reputation
*temp temp_salary 0
*if (temp_citizen_rep>100)
	*set temp_citizen_rep 100
*if (temp_citizen_rep<0)
	*set temp_citizen_rep 0
*set temp_salary (temp_citizen_rep*2)
*set temp_salary round(temp_salary)
*set temp_salary +30
*if (showstats)
	*line_break
	(Gold +${temp_salary})
*set gold +temp_salary
*choice
	#You have what you need. Save your money.
		You put the stipend in your gold pouch.
		*goto_scene luddmarch
	#Stop by the markets one last time.
		You have several stores to choose from.
		*set store_scene "begin_luddmarch"
		*goto_scene store

*comment ---------------------Subroutines------------------------------

*label Currentfriend_Increase
*if (currentfriend_name=theothea_name)
	*set theothea_relationship +friendinc
	*return
*if (currentfriend_name=karlkarla_name)
	*set karlkarla_relationship +friendinc
	*return
*if (currentfriend_name=jacejess_name)
	*set jacejess_relationship +friendinc
	*return
*if (currentfriend_name=peterpetra_name)
	*set peterpetra_relationship +friendinc
	*return
*if (currentfriend_name=gillgale_name)
	*set gillgale_relationship +friendinc
	*return
*else
	*comment BranBrinn only one left
	*set branbrinn_relationship +friendinc
	*return

*label ResetAdventure
*set theothea_injured false
*set jacejess_injured false
*set gillgale_injured false
*set peterpetra_injured false
*set karlkarla_injured false
*set branbrinn_injured false
*set friend1_injured false
*set friend2_injured false
*set friend3_injured false
*set friend4_injured false
*set health 100
*set companion_injured false
*set demonstone_kgirr_used false
*set demonstone_xiatta_used false
*set demonstone_zonch_used false
*set demonstone_brahl_used false
*set demonstone_tyborr_used false
*set demonstone_daanda_used false
*return

*label Injure_CurrentFriend
*set currentfriend_injured true
*if (currentfriend_name=theothea_name)
	*set theothea_injured true
*if (currentfriend_name=jacejess_name)
	*set jacejess_injured true
*if (currentfriend_name=karlkarla_name)
	*set karlkarla_injured true
*if (currentfriend_name=gillgale_name)
	*set gillgale_injured true
*if (currentfriend_name=peterpetra_name)
	*set peterpetra_injured true
*if (currentfriend_name=branbrinn_name)
	*set branbrinn_injured true
*gosub InjureFriends
*return

*label InjureFriends
*if ((theothea_injured) and (friend1_name=theothea_name))
	*set friend1_injured true
*if ((theothea_injured) and (friend2_name=theothea_name))
	*set friend2_injured true
*if ((theothea_injured) and (friend3_name=theothea_name))
	*set friend3_injured true
*if ((theothea_injured) and (friend4_name=theothea_name))
	*set friend4_injured true
*if ((jacejess_injured) and (friend1_name=jacejess_name))
	*set friend1_injured true
*if ((jacejess_injured) and (friend2_name=jacejess_name))
	*set friend2_injured true
*if ((jacejess_injured) and (friend3_name=jacejess_name))
	*set friend3_injured true
*if ((jacejess_injured) and (friend4_name=jacejess_name))
	*set friend4_injured true
*if ((karlkarla_injured) and (friend1_name=karlkarla_name))
	*set friend1_injured true
*if ((karlkarla_injured) and (friend2_name=karlkarla_name))
	*set friend2_injured true
*if ((karlkarla_injured) and (friend3_name=karlkarla_name))
	*set friend3_injured true
*if ((karlkarla_injured) and (friend4_name=karlkarla_name))
	*set friend4_injured true
*if ((peterpetra_injured) and (friend1_name=peterpetra_name))
	*set friend1_injured true
*if ((peterpetra_injured) and (friend2_name=peterpetra_name))
	*set friend2_injured true
*if ((peterpetra_injured) and (friend3_name=peterpetra_name))
	*set friend3_injured true
*if ((peterpetra_injured) and (friend4_name=peterpetra_name))
	*set friend4_injured true
*if ((gillgale_injured) and (friend1_name=gillgale_name))
	*set friend1_injured true
*if ((gillgale_injured) and (friend2_name=gillgale_name))
	*set friend2_injured true
*if ((gillgale_injured) and (friend3_name=gillgale_name))
	*set friend3_injured true
*if ((gillgale_injured) and (friend4_name=gillgale_name))
	*set friend4_injured true
*return

*label Check_Army_Stats
*if (army_morale<=0)
	*set army_morale 0
*if (army_size<0)
	*set army_size 0
*if (army_food<0)
	*set army_food 0
*if (army_power<0)
	*set army_power 0
*if (citizen_reputation<0)
	*set citizen_reputation 0
*return
