*comment Copyright 2015 by Mike Walter
*comment The Lost Heir 2:  Forging a Kingdom
*comment Scene #8: tornassa.txt
*comment 47721 Words - 228 subroutines = 47.4 k
*hide_reuse
*temp used_dagger false
*temp who_with "None"
*temp temp_towers false
*temp temp_defences false
*temp t_army 100
*temp siege_type "None"
*temp damage_done 0
*temp its_snowing false
*temp selina_hurt false
*temp red_health 100
*temp grand_reveal false
*temp round5_prayer_bonus_given false
*temp got_poisoned false
*temp banter_name "None"
*label Random_Banter_loop
*rand coinflip 1 5
*if ((coinflip=1) and (gillgale_inparty))
	*set banter_name gillgale_name
	*goto After_Pick_Banter
*if ((coinflip=2) and (karlkarla_inparty))
	*set banter_name karlkarla_name
	*goto After_Pick_Banter
*if ((coinflip=3) and (peterpetra_inparty))
	*set banter_name peterpetra_name
	*goto After_Pick_Banter
*if ((coinflip=4) and (theothea_inparty))
	*set banter_name theothea_name
	*goto After_Pick_Banter
*if ((coinflip=5) and (jacejess_inparty))
	*set banter_name jacejess_name
	*goto After_Pick_Banter
*goto Random_Banter_loop

*label After_Pick_Banter

The trip from Ludd to Tornassa is very quiet as everyone thinks about what the future is going to bring.
*if ((using_legacy) and (legacy_help="army_delays"))
	The journey is very easy due to the well-maintained road that lead to the capital.
	
	"We're making really good time here," General Vale says.  "I'm glad that old King Kyle was so adamant about proper infrastructure."
	
	That was the monarch whom the Elmvale Wizard served.  The mind-boggling reach of the wizard from the past was enough to give you a headache.  As though thinking about ${legacy_himher} could change the landscape of Daria itself, you find yourself marching into Elmvale,
	*if (showstats)
		*line_break
		(Legacy Advantage #9: Army Delays -4.  More perks will arrive as the story progresses.)
	*set army_delays -4
*if (((using_legacy) and (legacy_help="army_delays"))=false)
	You aren't really thinking about where you are when you enter a small village that looks very familiar.  It is Elmvale,
the village where ${fosterparent_name} raised you.  Much like the other towns and villages in the duchies, you see that Elmvale has fallen on hard times.
*label Elmvale_loop
*choice
	#Ask the citizens what has happened to the formerly happy village.
		You get a lot of hollow-eyed stares and one-line answers, but eventually, you put together the pieces of information.  The story is much the same as Dobbton.  When the Demonstones arrived, the citizens used them.  Possessed summoners and loose demons made regular life impossible.  Farms went untended, people were killed and property was destroyed.  It was like an addiction.  The foolish kept trying to use the Demonstones and failed, while those who had success continued to use them, but they also eventually came across demons too powerful for them to control.
		*goto Elmvale_loop
	#Treat Elmvale no differently than any other place.
		*if (taking_food)
			Your soldiers take anything needed.  Food, spare shoes, extra pieces of leather…anything that the army needs, they take.  You see a few familiar faces glaring at you, but nobody approaches you.
			*if (showstats)
				*line_break
				(Army Food +5)
			*set army_food +5
		*if (taking_food=false)
			Your soldiers pass through the village.  The citizens of Elmvale watch from windows and from their front doors as the army goes by.
		*goto Elmvale
	#Command your army to veer off the road and walk around Elmvale.
		General Vale grumbles a little about 'sentimentality', but he does as you ask.  Elmvale is a small village and it causes no delay to go around instead of through the streets.  Many of the remaining villagers come to the edge of the village to watch the army pass.
		*goto Elmvale
	#Command your army to halt so you can visit the small village.
		General Vale grumbles a little about 'sentimentality', but he does as you ask.
		*goto Elmvale

*label Elmvale

*if (karlkarla_inparty)
	"I hope my parents are okay," ${karlkarla_name} says as ${karlkarla_heshe} starts walking toward ${karlkarla_hisher} parents' store.
	*choice
		#Go with ${karlkarla_name}.
			*label Go_With_K
			Together, you go to ${karlkarla_hisher} parents' store on the main street.  When you enter, you see that there aren't very many items for sale on the shelves.  Like the rest of the country, ${karlkarla_name}'s business is struggling.  The small couple rush out and hug ${karlkarla_name} the moment ${karlkarla_heshe} enters.
			*if (karlkarla_relationship>=60)
				They smile at you and greet you warmly.
			*if (karlkarla_relationship<60)
				They glare at you when they see you.
			
			"So, little ${name} is actually the $!{princeprincess} of Daria," ${karlkarla_name}'s father says to you.
			*if (lover_name=karlkarla_name)
				
				"We're dating," ${karlkarla_name} says in a soft voice.
				*if (lover_pregnant)
					"And I'm pregnant."
				*if ((mc_pregnant) or (child_egg))
					"And we're having a
					*if (child_egg=false)
						baby."
					*if (child_egg)
						baby with the help of the Archmage's magic."
				
				${karlkarla_name}'s parents blink in surprise at this announcement.  They are good people, but they have no experience with royalty or nobility.  Since they knew you as a child growing up in Elmvale with ${fosterparent_name}, their attitude toward you is mixed.  It will take time before they are comfortable with you.
			*temp impatient_with_k false
			*choice
				#You are polite and well-mannered during the visit.
					*set impatient_with_k false
					*label K_Visit_2
					You watch as ${karlkarla_name}'s parents dote over their
					*if (karlkarla_hisher="his")
						son.
					*if (karlkarla_hisher="her")
						daughter.
					Despite the fact that you are the leader of the nation, all of the attention is placed upon ${karlkarla_name}.  You can't help but to think of your murdered parents and the future that had been stolen from you by Zusak.
					*if (impatient_with_k)
						
						"We have to go," you say, much sooner than ${karlkarla_name} would have liked.
						
						${karlkarla_name} says goodbye and hugs ${karlkarla_hisher} parents before leaving with you.
						*if (showstats)
							*line_break
							(${karlkarla_name} Relationship -3)
						*set karlkarla_relationship -3
						*goto After_KarlKarla_Elmvale					
					The visit is kept brief since the army is still moving.  You say goodbye and return to the troops with ${karlkarla_name} at your side.
					*if (showstats)
						*line_break
						(${karlkarla_name} Relationship +3)
					*set karlkarla_relationship +3
					*goto After_KarlKarla_Elmvale
				#You are impatient and eager for the visit to be over.
					*set impatient_with_K true
					*goto K_Visit_2
		#Allow ${karlkarla_name} to go alone.
			*if (lover_name=karlkarla_name)
				"${name}, you need to come too," ${karlkarla_heshe} says when you don't start to follow.
				*if (showstats)
					*line_break
					(${karlkarla_name} Relationship -3)
				*set karlkarla_relationship -3
				*choice
					#Say, "You go.  I'm too busy."
						${karlkarla_name} frowns at your words, but doesn't argue.  Your quiet archer obviously isn't happy with your decision to not come, but arguing over such things isn't in ${karlkarla_hisher} nature.  $!{karlkarla_heshe} returns to your army an hour later but doesn't speak about what ${karlkarla_heshe} found.
						*if (showstats)
							*line_break
							(${karlkarla_name} Relationship -5)
						*set karlkarla_relationship -5
						*goto After_KarlKarla_Elmvale
					#Say, "Okay.  I'm coming."
						*goto Go_With_K
			${karlkarla_name} is gone for about an hour.  When ${karlkarla_heshe} returns, ${karlkarla_heshe} seems content.  You assume that ${karlkarla_hisher} parents must be alive and well.
			*goto After_KarlKarla_Elmvale
*else
	*comment At this point, could be dead from Vernex or as the Red Archer
	Although it will be a sad conversation, you consider delivering the news of ${karlkarla_name}'s death to ${karlkarla_hisher} parents.
	*choice
		#Visit ${karlkarla_name}'s parents.
			*if (deadfriend_name=karlkarla_name)
				You tell them that ${karlkarla_name} died nearly two years ago in Vernex.  They don't seem very surprised, since they hadn't heard anything in all of that time.  Although sad, they are happy to finally have some closure as you tell them that their
				*if (karlkarla_hisher="his")
					son
				*if (karlkarla_hisher="her")
					daughter
				has passed on.  It helps a little when you say that ${karlkarla_heshe} died a hero by saving you from Thuja's axes in the dungeons of Vernex.
				*goto KarlKarla_Dead_Talk_Rep
			*else
				You tell them that ${karlkarla_name} died about two years ago in Selina's dungeon in Brightwater.  They don't seem very surprised, since they hadn't heard anything in all of that time.  Although sad, they are happy to finally have some closure as you tell them that their
				*if (karlkarla_hisher="his")
					son
				*if (karlkarla_hisher="her")
					daughter
				has passed on.
				*label KarlKarla_Dead_Talk_Rep
				
				"Thank you for taking the time to personally tell us," ${karlkarla_name}'s father says.
				*if (showstats)
					*line_break
					(Good +3 and Citizen Reputation +10)
				*set good +3
				*set citizen_reputation +10
				*goto After_KarlKarla_Elmvale
		#Don't visit.
			You decide to not bother speaking to ${karlkarla_name}'s parents.
			*goto After_KarlKarla_Elmvale

*label After_KarlKarla_Elmvale
*choice
	*if (fosterparent_name="Amos") #Visit the tavern where Amos raised you.
		The Full Cup Inn is still serving drinks to the remaining citizens.  It is in rough shape with damaged walls, chairs and tables, but it is holding up better than many of the other local businesses.  The owner of the bar, a big woman wearing a dirty apron, bypasses all protocol and picks you up in a large hug the moment you enter.  Your soldiers are uncertain what to think of the matronly lady treating you like a child, standing back and waiting to see what you will do.
		*choice
			#Push the strange lady away.
				The big woman steps back, but her smile doesn't go away.
				*goto Amos_2
			#Hug the strange lady back.
				The big woman is all encompassing as she folds you into her massive arms.  She steps back smiling and looking at you face.
				*goto Amos_2
		*label Amos_2
		
		"You don't remember me, do you," she says.  "I'm Aida.  I babysat you a few times when you were a little
		*if (gender="male")
			boy.
		*if (gender="female")
			girl.
		Where is Amos?  Is he with you?"
		*choice
			#Say, "Amos is dead."
				"Oh, my poor dear!" she says, rushing forward to hug you once more.
				
				"He sent me a letter about a year ago saying that something might happen to him.  He sold me the tavern, but he left something for you."
				
				She goes into the back room and returns with a small box.  She hands it to you and you open it.
				*if (fosterparent_relationship>=70)
					Inside the box, you find a little bit of money, a statue of a spider and a letter.  
					
					"Dear ${name}," the letter reads.  "I never thought I'd be a father.  I led a carefree life of thieving and whoring, before I met you.  I always thought my life would end in the dungeons beneath Tornassa, until the night I was freed and found you in the castle.  You changed everything for me.  If you're reading this, then I didn't survive the trip to Vernex.  I left you a little something as an inheritance, but I also left you my greatest regret.  I stole this statue from a wizard named Luimar.  I spent the other stuff I stole from him, but when I heard that he killed himself after the theft, I felt terrible.  It was just a silly spider statue; why would he kill himself over it?
					
					"When I was arrested years later for killing that other man, I brought the statue into the dungeon with me.  The guards inspected it very closely, but it contained no magic and no value.  Worthless.  But, now I have two deaths to atone for.  If you can ever find a way to make things right, maybe my soul will have one less burden upon it.  Take care.  Amos."
					*if (showstats)
						*line_break
						(Gold +150 and Gained Spider Statue)
					*set gold +150
					*set amos_spider_statue true
					*achieve regret
					
					With nothing else to do in the tavern, you leave Aida and return to your army.
					*goto Elmvale_2
				*else
					There is a small sum of money in it.  An inheritance.
					*if (showstats)
						(Needed 70 Amos Relationship)
						*line_break
						(Gold +50)
					*set gold +50
					
					With nothing else to do in the tavern, you leave Aida and return to your army.
					*goto Elmvale_2
			#Say, "I don't know where he is."
				"Oh, that's a shame," she says.  "He is such a handsome man.  I can't believe that he was hiding the ${princeprincess} here all this time.  If there's anything I can do to make your stay better, you just let me know."
				
				You inform the woman that you won't be staying and continue on your way.
				*goto Elmvale_2
	*if (fosterparent_name="Sir Grady") #Visit the farm where Sir Grady raised you.
		The farm is right where you left it, but like all of the others, it has fallen on hard times.  The livestock is all skinny and nearly dead.  When you approach, you recognize the farm hands from your childhood.  They greet you and tell you that Sir Grady left them the farm.  They seem embarrassed by the state that it's fallen to.  Like everyone else, they succumbed to the temptation of easy power and misused the free Demonstones.
		*if (fosterparent_relationship>=70)
			One of them goes into the farmhouse and returns with a tightly bound scroll with your name on it.  It is from Sir Grady.
			
			"If you're reading this, then I am dead," the scroll reads.  "I was married once, when I was young.  Drusilla was a patient woman, but we still separated a few years later.  We had a daughter named Lacey and she went to live with her mother.  It was my fault; I devoted my life to my career and never saw them again.  Your parents were wonderful to me.  When I became too old to be worthwhile, they let me continue to stay in the barracks instead of sending me off to die somewhere in retirement.  I never thought I'd have a second chance to be a father, but then I found myself responsible for you.
			
			"A bachelor for most of my life and then an old man,  I wasn't equipped to raise a child, but by the grace of the Gods and Goddesses, I did the best I could.  I hope I didn't mess up too badly.  Living with you showed me what life with a family could have been like.  I never told you about my family, because I didn't want you to think poorly of me.  The ego of an old man is very fragile.  If you ever find Lacey, tell her that I came around in the end and that I missed her terribly.  Tell her that her father died a foolish old man, but in the end, he loved her dearly.  Sir Grady."
			*if (showstats)
				*line_break
				(Gained Sir Grady's Letter)
			*set grady_letter true
			*achieve regret
			
			You take the scroll and leave the farm.
			*goto Elmvale_2
		*else
			*if (showstats)
				(Needed 70 Sir Grady Relationship)
			
			They seem relieved when you finally leave the farm and return to your army.
			*goto Elmvale_2
	*if (fosterparent_name="Sister Geri") #Visit the temple where Sister Geri raised you.
		The temple where you grew up is gone.  Only a few blackened stones remain from the fire that burned it down.  While you are looking at the ruins, an old woman approaches you.
		
		"You are ${name}," she says.  "Do you remember me?  I cleaned the temple when you and Sister Geri lived here.  Some priest lost control of a Demonstone and burned it to the ground a few months ago.  A
		*if (fosterparent_relationship>=70)
			shame.
			
			"One moment," the woman says.  "Sister Geri left you something."
			
			She returns a short time later with a small brown sack tied with a cord.  You untie the cord and open the sack.  Inside, you find a ring and a letter.
			
			"The cycle is complete and I am dead," the letter reads.  "All things come to an end and every end is a new beginning.  If you are reading this, then I am with the Gods and Goddesses now.
			
			"I never thought that I would be a mother.  The Gods and Goddesses must have a sense of humour, to have sent me you.  I was content to serve Them for the majority of my life, but I wasn't always a bald old monk.  You will find this hard to believe, but I was an exceptionally beautiful young woman and had many suitors before I joined the monastery.  A man named Stanton even asked me to marry him.  But, the young are foolish, and I was as foolish as I was beautiful.  He was older than me, so I let him buy me gifts but I continued to see other men.
			
			"I think he hoped that marriage would make me stay with him.  He gave me his grandmother's wedding ring and hoped that I would return his love.  I was foolish.  I sold it.  He found me in the arms of another man closer to my own age a few days later.  He didn't rant and rave, just left us there.  We laughed at him at the time.  He threw himself from the top of one of the towers.  I left my lover and never courted another man since.  I joined the monastery and bought back the ring.  I haven't a clue what to do with it or how to make amends.  I suppose that I am telling you this to clear my own conscience.
			
			"You were my final redemption.  The life of a monk may have atoned for some of my sins, but it was through raising you that I was given a second chance at life itself.  For that, I owe you much.  I love you, ${name}.  Avoid the follies of youth, for they will follow you to your grave.  Sister Geri."
			*if (showstats)
				*line_break
				(Gained Sister Geri's Golden Ring)
			*set geri_ring true
			*achieve regret
			
			You leave the ruins of the temple and return to your army.
			*goto Elmvale_2
		*else
			shame."
			*if (showstats)
				(Needed 70 Sister Geri Relationship)
			*goto Elmvale_2
	*if (fosterparent_name="Lady Emaline") #Visit the store where Lady Emaline raised you.
		The shop is closed when you get there.  It looks like it had been abandoned and surely no longer has wares stocked in its shelves.  You knock anyway and are surprised when the door opens.  An older couple say that they bought the store from Lady Emaline when she left for Vernex last year.
		*if (fosterparent_relationship>=70)
			
			"You're ${name}," the man states as he recognizes you.
			
			He leaves and returns a moment later with a small lock box.  He gives it to you and you open it.  Inside, you see some coins and a letter.
			*if (showstats)
				*line_break
				(Gold +200 and Gained Lady Emaline's Letter)
			*set gold +200
			*set emaline_letter true
			*achieve regret
			
			"${name}," the letter reads.  "If you are reading this, then I did not survive the trip to Vernex.  I have seen a lot of death in my life, most of it from my own hand.  I have worn so many disguises that I hardly know who I really am.  I never had a husband and I never birthed a child.  My business was death, not life.  You changed this for me.
			
			"I may have begun raising you thinking that it was my duty to your parents, but my thoughts changed somewhere along the way.  I never understood children.  I always thought of them as simply smaller and less intelligent adults.  Is this love I feel for you?  I am not a sentimental woman, but I suppose that there is no other name for this feeling.  With this love, I have gained a new perspective on life.  Let me just say, in my line of work, these new feelings are very troublesome.
			
			"I never experienced guilt before.  I suppose this was why I was so good at my job as the Royal Assassin.  But, I feel it now.  I killed a prostitute named Lori because she was supposedly pregnant with some noble's bastard.  This was a side job.  Your parents never knew this.  The information was wrong; turns out she already had the child.  A little boy named Eli.  My contract was for the woman, not the boy, so I left him in that cradle in that rat's nest of an apartment.  Yes, I was that cold.  But now, I feel terrible remorse for this.  If you ever find the boy, give him this money.  It is a small restitution for having lost his mother, but it is all I can do.
			
			"I never expressed my love for you," the letter concludes.  "But know that I felt it.  Emaline." 
			
			You take the money and the letter before leaving the shop.
			*goto Elmvale_2
		*else
			*if (showstats)
				(Needed 70 Lady Emaline Relationship)
			*goto Elmvale_2
	#Continue by Elmvale without stopping.
		The past was in the past and there was nothing in Elmvale which would change it.  Your future lay in Tornassa.
		*goto Elmvale_2

*label Elmvale_2

*if (killed_master_jett=false)
	"${name}!" a man says just as you are about to leave Elmvale.
	
	To your surprise, you see that it's Master Jett, the owner of the sheep you transported from Elmvale to Ludd during your first days of adventuring!
	
	"I can't believe I hired the ${princeprincess} of Daria as a low paid guard for my caravan!" he says with a big smile as he extends his hand for you to shake.
	*choice
		#Shake the man's hand.
			Master Jett happily shakes your hand and smiles some more.
			
			*if ((citizen_reputation>=70) and (citizen_fear<50))
				"I know that you're marching on Tornassa and I just wanted to tell you that we're all behind you," he says.  "I sold all my sheep, as you know, but my neighbour hasn't.  I'm sure he'll sell them to you, if you want.  He'll need some money right away though.  Times are tough and he'll need something to get by until you can pay the full amount."
				*choice
					*selectable_if (gold>=200) #Buy the sheep.  (Needs 200 Gold)
						The entire transaction doesn't take long as you pay Master Jett's neighbour and your army takes away the sheep.  The flock was held far enough outside of Elmvale that your army wouldn't have found it without Master Jett's assistance.
						*if (showstats)
							*line_break
							(Gold -200 and Army Food +15)
						*set gold -200
						*set army_food +15
						*goto To_Tornassa
					#Take the sheep without paying.
						Master Jett is very upset at this.  He knew that you wouldn't pay the full amount right away, but without the 200 gold, the rancher and his family will have nothing to survive on.  War is difficult for all and your army needs to eat, so you take the sheep.
						*if (showstats)
							*line_break
							(Army Food +15, Citizen Reputation -15 and Evil +10)
						*set army_food +15
						*set citizen_reputation -15
						*set good -10
						*goto To_Tornassa
					#Decline the offer.
						"Well, it sure was nice seeing you again," Master Jett says.  "Good luck and I hope everything goes well for you."
						
						You leave Master Jett and continue out of Elmvale.
						*goto To_Tornassa
			*else
				"It's nice seeing you again," he says before releasing your hand and disappearing back into the village.
				*if (showstats)
					(Needed 70 Citizen Reputation and Under 50 Citizen Fear)
				*goto To_Tornassa
		#Turn away and return to your army.
			Master Jett watches you as you walk away.  After a moment, he lowers his hand, shakes his head and goes back the way he came.
			*goto To_Tornassa
*else
	"${name}!" a woman yells from nearby.  "Please, speak to me."
	*choice
		#Allow the woman to approach.
			"I am Jett's widow," she says.  "You were with my husband on his fatal trip to Ludd.  I got word back from the Guild of Adventurers that bandits killed him and stole all the sheep.  They said that you and ${theothea_name} barely got away with your lives.  I miss him so much.  We were supposed to retire on the money from the sale of the sheep, but the bandit attack changed all that.  I work as a farm hand on my neighbour's fields now."
			
			She pauses from her rambling and collects herself.  "I'm sorry for prattling on.  I heard that you are actually the $!{princeprincess} of Daria.  But, I just wanted to know…did my poor Jett suffer badly before he died?"
			*choice
				#Say, "No, he died quickly."
					The woman smiles weakly at your words as tears run down her face.  She nods thanks to you and then leaves.  You depart Elmvale shortly after.
					*if (showstats)
						*line_break
						(Good +2)
					*set good +2
					*goto To_Tornassa
				#Say, "Oh yes, he got an arrow in the belly and it took him forever to die."
					The woman puts a startled hand to her mouth and bursts into tears.  She runs off crying as you depart Elmvale.
					*if (showstats)
						*line_break
						(Evil +5)
					*set good -5
					*goto To_Tornassa
				#Lean in close and whisper, "He cried like a baby when I cut his throat and stole all your sheep."
					The woman's eyes go wide and she staggers backward, away from you.  You know that whatever she says won't be believed, but will likely turn into new rumours and half-truths about you.  You watch as she stumbles away from you and into the streets of Elmvale.  You leave the village a short time afterwards.
					*if (showstats)
						*line_break
						(Evil +10 and Citizen Fear +10)
					*set good -10
					*set citizen_fear +10
					*goto To_Tornassa
		#Ignore the woman.
			You ignore the woman and continue on your way out of Elmvale.
			*goto To_Tornassa

*label To_Tornassa
*if (kratog_gavesheep)
	
	Your army isn't far from Elmvale when an enormous commotion gets your attention.  The initial reports say that a giant attacked your left flank.  The troops are all terrified that Selina has somehow gotten the monsters of the land to fight for her.  When you arrive, you see Kratog sitting on the grass at the side of the road with nearly thirty soldiers surrounding him.
	
	"Kratog hungry," he says as he gets to his feet while your soldiers assume a battle stance, intending to protect you from the creature.
	*choice
		#Tell your soldiers to stand down.
			Kratog hardly even notices how close he had been to getting killed.
			*choice
				*selectable_if (army_food>=10) #Say, "Kratog, I'll get you some food, but I'll need you to fight for me."
					"Okay," the giant says simply.
					
					Your troops have mixed feelings about seeing the food go to the giant.  Although the loss of food bothers them, they can't help but to wonder what it will be like to see Kratog fighting alongside them.
					*if (showstats)
						*line_break
						(Army Food -10 and Army Power +10)
					*set army_food -10
					*set army_power +10
					*set kratog_hired true
					*goto Tornassa_Marching
				*if (army_food<=20) #Say, "We're hungry too.  Kill the giant.  We're going to have a lot of fresh meat soon."
					*goto Kill_Kratog
				*if (army_food<=0) #Say, "Sorry, Kratog.  I have no food for you."
					*goto No_Food_Kratog
				*if (army_food>0) #Say, "Sorry, Kratog.  I have no food to spare."
					*label No_Food_Kratog
					"Kratog hungry," the giant says again as he turns around and lumbers away.
					
					The soldiers watch the large monster in amazement as it leaves without another word.
					*goto Tornassa_Marching
		#Say nothing.
			*label Kill_Kratog
			Swords and spears strike forward as Kratog tries to ward off the attack with his enormous hands.  He manages to grab one poor man and throw him nearly twenty feet.  Miraculously, the man's broken leg is the only injury as Kratog is killed.
			*if (army_food>20)
				*goto Tornassa_Marching
			*else
				Looking at the large dead body of the giant and thinking about your 
				*if (army_food<=0)
					empty
				*if (army_food>0)
					low
				food stores gives you a grizzly idea.
				*choice
					#Say, "Butcher the giant for its meat."
						Your troops are aghast at the idea for a moment, but rumbling bellies prevail and soon Kratog is gutted and cleaned.  Everyone tries not to think about the fresh meat in their bellies that night or the smoked jerky that is served for the next several weeks.
						*if (showstats)
							*line_break
							(Army Food +15)
						*set army_food +15
						*goto Tornassa_Marching
					#Say, "Burn the body.  The last thing we need is disease."
						Your troops pile some wood and set the corpse on fire.  The smell of roasting meat causes people's mouths to water, despite the source.
						*if (peterpetra_inparty)
							
							"You have done well," ${peterpetra_name} says.  "A funeral pyre is the correct thing to do in the eyes of the Gods and Goddesses."
							*if (showstats)
								*line_break
								(Religion +5)
							*set religion +5
						*goto Tornassa_Marching
					#Say, "Leave the body.  We don't have time for this."
						Your troops march onward and soon Kratog is left far behind.
						*goto Tornassa_Marching
*else
	*goto Tornassa_Marching

*label Tornassa_Marching

*label Tornassa_March_Banter
*if (banter_name=jacejess_name)
	It was pouring rain and miserably cold about a week after leaving Elmvale.  The army was trudging along through the mud and hoping for the rain to let up when a wagon axle snapped in the supply train.  It wasn't until that night when the soldiers were setting up camp that you learned about it.  ${jacejess_name} was yelling at the poor wagon driver and ${jacejess_hisher} eyes were turning white.  From the shouting, you quickly learned that the Soulburner's belongings had been in the broken wagon and ${jacejess_hisher} clothing had scattered into the mud.
	*choice
		#Say, "${jacejess_name}, let the poor fellow go.  It wasn't on purpose."
			${jacejess_name} glares at you for a moment and then stops.  "Of all the wagons and all the personal belongings in the entire army, it was mine that fell in the mud.  This was no coincidence.  Just more intolerance and prejudice against a Soulburner."
			*if (showstats)
				*line_break
				(${jacejess_name} Relationship -5 and Citizen Reputation +3)
			*set jacejess_relationship -5
			*set citizen_reputation +3
			
			Before you can say another word, ${jacejess_name} storms away.  The wagon driver gives you a look of thanks before leaving as well.
			*goto After_Tornassa_March_Banter
		#Suggest, "Have the man whipped and make him wash out your clothes."
			The wagon-driver looks terrified, but your sentence is carried out.  ${jacejess_name} watches the whipping with a pleased expression on ${jacejess_hisher} face.
			*if (showstats)
				*line_break
				(${jacejess_name} Relationship +5, Citizen Reputation -2, and Evil +5)
			*set jacejess_relationship +5
			*set citizen_reputation -2
			*set good -5
			*goto After_Tornassa_March_Banter
		#Say nothing.
			There is a flash of white and the wagon driver shouts in pain.  It is a small burn and probably scared the man more than injured him.  ${jacejess_name} yells at him for a few more minutes before letting the diver run away.  You watch as ${jacejess_name} gathers ${jacejess_hisher} muddy belongings and stomps away in anger.  Tales of your volatile companion spread through the troops.
			*if (showstats)
				*line_break
				(Army Morale -3)
			*set army_morale -3
			*goto After_Tornassa_March_Banter
*if (banter_name=peterpetra_name)
	It was about a week after leaving Elmvale when ${peterpetra_name} demanded that the army stop marching.  General Vale was outraged.
	
	"It's Ludentime," ${peterpetra_name} explains when you arrive.  "We can't march during Ludentime."
	
	The religious observance of doing no work for Ludentime was very traditional.  Families spent the week inside and any business that could be delayed was postponed until the holiday was over.
	*choice
		#Say, "It's Ludentime.  We will stop."
			${peterpetra_name} is very happy with your decision.  Your army settles in alongside the road and rests.  Stories are told and groups of soldiers gather to pray to their Gods and Goddesses.  It is a very calming and soothing experience, although General Vale begrudges the delay.
			*if (showstats)
				*line_break
				(Army Delays +1, Army Morale +10, Religion +5, ${peterpetra_name} Relationship +5 and General Vale Relationship -5)
			*set army_delays +1
			*set army_morale +10
			*set religion +5
			*set peterpetra_relationship +5
			*set vale_relationship -5
			*goto After_Tornassa_March_Banter
		#Say, "Marching is not work.  We can keep going."
			${peterpetra_name}
			*if (religion>=50)
				agrees with your interpretation and the army starts to move once again.  General Vale grumbles about "religious zealots," but with the army moving again, he doesn't complain very much.
				*if (showstats)
					*line_break
					(${peterpetra_name} Relationship +3 and Religion +3)
				*set peterpetra_relationship +3
				*set religion +3
				*goto After_Tornassa_March_Banter
			*else
				is furious with your decision.  General Vale grumbles about "religious zealots," but with the army moving again, he doesn't complain very much.
				*if (showstats)
					(Needed 50 Religion)
					*line_break
					(${peterpetra_name} Relationship -5)
				*set peterpetra_relationship -5
				*goto After_Tornassa_March_Banter
		#Say, "General Vale is right.  We aren't going to stop the entire army to sit around and pray.  Keep moving."
			${peterpetra_name} glares at you and General Vale grumbles about "religious zealots."  Your army doesn't waste any time with delays as Ludentime passes the same as any other week.
			*if (showstats)
				*line_break
				(${peterpetra_name} Relationship -10 and General Vale Relationship +10)
			*set peterpetra_relationship -10
			*set vale_relationship +10
			*goto After_Tornassa_March_Banter
*if (banter_name=gillgale_name)
	The party was camped for the night about a week after leaving Elmvale when 
	*if (gillgale_relationship>=60)
		${gillgale_name} invites you to play dice with the soldiers.
	*if (gillgale_relationship<60)
		you find out that ${gillgale_name} has been playing dice with the soldiers.
	
	"They're terrible!" ${gillgale_name} says happily.  "I've been gambling with them since we left Brightwater.  I've made a tidy little profit from their bad playing."
	*choice
		#You join them that night.
			When you arrive at the tent, the soldiers all straighten up in their chairs.  You see that one of them has a bottle of liquor which he tries to unsuccessfully hide in his cloak.
			*choice
				#Take a drink and join them at the table.
					Your soldiers laugh nervously
					*if (charm<45)
						as you attempt to join them.  They quickly make excuses and leave before the game begins.  ${gillgale_name} laughs out loud as you are deserted.  At least the troops won't have to worry about gambling debts and hangovers any more.
						
						"Your charming personality strikes again," ${gillgale_name} says with a grin.
						*if (showstats)
							(Needed 45 Charm)
							*line_break
							(Army Power +5)
						*set army_power +5
						*goto After_Tornassa_March_Banter
					at first, but when you take a drink from the bottle, they become more relaxed.  Soon the dice are brought out and a game is begun.
					*if (showstats)
						*line_break
						(Charm +3)
					*set charm +3
					*choice
						#Play normally.
							There isn't very much skill involved
							*rand coinflip 1 2
							*if (coinflip=1)
								but you have a lucky night and end up winning some coins.  The dice game becomes a nightly occurrence and your soldiers begin to enjoy your company.
								*if (showstats)
									*line_break
									(${gillgale_name} Relationship +3, Army Morale +3 and Gold +75)
								*set gillgale_relationship +3
								*set army_morale +3
								*set gold +75
								*goto After_Tornassa_March_Banter
							*else
								and your luck is terrible.  The dice game becomes a nightly occurrence and your soldiers begin to enjoy your company.
								*if (gold>=75)
									*if (showstats)
										*line_break
										(${gillgale_name} Relationship +3, Army Morale +3 and Gold -75)
									*set gillgale_relationship +3
									*set army_morale +3
									*set gold -75
									*goto After_Tornassa_March_Banter
								*if (gold<=0)
									*if (showstats)
										*line_break
										(${gillgale_name} Relationship +3 and Army Morale +3)
									*set gillgale_relationship +3
									*set army_morale +3
									*set gold 0
									*goto After_Tornassa_March_Banter
								*else
									*if (showstats)
										*line_break
										(${gillgale_name} Relationship +3, Army Morale +3 and Gold -${gold})
									*set gillgale_relationship +3
									*set army_morale +3
									*set gold 0
									*goto After_Tornassa_March_Banter
						#Cheat with ${gillgale_name}.
							Your rogue friend surprises you by revealing a pair of weighted dice.  The dice game becomes a nightly occurrence, and despite losing a lot of money, the soldiers enjoy your company.  After each session, you and ${gillgale_name} split the winnings.
							*if (showstats)
								*line_break
								(${gillgale_name} Relationship +5, Army Morale +3, Gold +135 and Evil +5)
							*set gillgale_relationship +5
							*set army_morale +3
							*set gold +135
							*set good -5
							*goto After_Tornassa_March_Banter
						*selectable_if (gold>=80) #Let the soldiers win.  (Needs 80 Gold)
							${gillgale_name} knows what you are doing, but says nothing.  The dice game becomes a nightly occurrence and the men enjoy your company while making a little extra coin on the side.
							*if (showstats)
								*line_break
								(${gillgale_name} Relationship +5, Army Morale +10 and Gold -80)
							*set gillgale_relationship +5
							*set army_morale +10
							*set gold -80
							*goto After_Tornassa_March_Banter
				#Scold the soldiers for gambling and drinking.
					The soldiers scatter after your reprimand.  ${gillgale_name} rolls ${gillgale_hisher} eyes, but the last thing your troops need is gambling debts and hangovers.
					*if (showstats)
						*line_break
						(${gillgale_name} Relationship -3, Army Power +5 and Army Morale -3)
					*set gillgale_relationship -3
					*set army_power +5
					*set army_morale -3
					*goto After_Tornassa_March_Banter
		#Suspecting that the soldiers will be more comfortable without the ${princeprincess} present, you don't attend.
			The soldiers need an outlet and gambling is relatively harmless.  They get the thrill of winning and their thoughts are filled with the risks of losing.  It helps them to pass the time and ${gillgale_name} is happy to play with them.  You decide to not interrupt their entertainment and simply stay away.
			*if (showstats)
				*line_break
				(Army Morale +3)
			*set army_morale +3
			*goto After_Tornassa_March_Banter
*if (banter_name=theothea_name)
	It was about a week after you left Elmvale when you saw the bruises on ${theothea_name}'s face.  When you asked ${theothea_himher} about them, ${theothea_heshe}
	*if (theothea_relationship>50)
		happily told you all about it.
	*if (theothea_relationship<=50)
		grudgingly told you about it.
	
	"Bare knuckle fighting," ${theothea_name} says.  "I know we aren't supposed to be doing it, but the soldiers like it and it gives everyone something to look forward to after a long day of marching."
	*choice
		#Tell your commanders about the fighting and put an end to it.
			${theothea_name} grumbles bitterly as the nightly activity comes to an end.  Your healers are happy when they stop being asked to patch up broken noses and swollen faces.  The strict discipline you exert makes your army run more efficiently.
			*if (showstats)
				*line_break
				(${theothea_name} Relationship -5 and Army Power +10)
			*set theothea_relationship -5
			*set army_power +10
			*goto After_Tornassa_March_Banter
		#Attend the fight and watch.
			The soldiers panic when they see you arrive.  When you don't say anything, they continue.  A pair of combatants enter a crude dirt circle and begin to fight.  It is fairly civilized and when one of them is knocked to the ground, the fight is over.  ${theothea_name} claps at the spectacle.
			*choice
				#Applaud the victor and keep watching.
					The next fight involves two smaller men.  They don't have the big muscles that the fighters of the first match did, but they are much faster.
					*goto Fight_Club
				#Ask to join in.
					The soldiers become very uncomfortable.  When you stand in the ring, nobody steps forward to fight you.  The soldiers return to their tents and the nightly fights stop.  ${theothea_name} claps you on the back and grins.
					
					"You didn't really think your troops would be able to throw a punch at their ${princeprincess}, did you?"
					*if (showstats)
						*line_break
						(${theothea_name} Relationship +5 and Citizen Reputation +5)
					*set theothea_relationship +5
					*set citizen_reputation +5
					*goto After_Tornassa_March_Banter
				#Encourage ${theothea_name} to fight.
					"Sounds good!" ${theothea_name} says with a grin as ${theothea_heshe} steps forward.
					
					You watch as a big soldier gets into the circle to try his luck against the mountain-${theothea_manwoman}.  Punches are exchanged and the soldiers applaud.
					*label Fight_Club
					You can see that everyone enjoys the sport and now that you know about it, they don't need to do it secretly any more.  The commanders in your army regulate the fights after that, making sure that they don't go too far.  It helps build skills and entertains the troops during the long march.
					*if (showstats)
						*line_break
						(${theothea_name} Relationship +5, Army Morale +5 and Army Power +5)
					*set theothea_relationship +5
					*set army_morale +5
					*set army_power +5
					*goto After_Tornassa_March_Banter
*if (banter_name=karlkarla_name)
	It is about a week after leaving Elmvale when you see ${karlkarla_name} carrying a tray of food back from the army cooks.  You watch as ${karlkarla_heshe} sits down in the back of a wagon and sets the tray on ${karlkarla_hisher} lap.  $!{karlkarla_heshe} peeks under the cover and then groans out loud at what ${karlkarla_heshe} sees.
	*choice
		#Ask, "What's wrong?"
			"What?" ${karlkarla_name} says in surprise as you speak.  "Oh, sorry.  It's nothing.  It's just…I told the cook I didn't care for onion gravy and asked to not have any on my meat.  That was a week ago and ever since then he's been covering all of my food in the stuff.  I suppose it's a prank or something."
			*label Tornassa_KarlKarla_Banter_loop
			*choice
				#Say, "Food is food.  Just eat it."
					"Oh, I know," ${karlkarla_name} says quietly.  "Sorry for complaining.  I shouldn't have said anything."
					*if (showstats)
						*line_break
						(${karlkarla_name} Relationship -3)
					*set karlkarla_relationship -3
					*goto After_Tornassa_March_Banter
				#Say, "I'll speak to the cooks."
					"Oh no, you don't need to do that," ${karlkarla_name} says.
					
					You talk to the cooks anyway.  They are embarrassed and say that they will stop the petty retaliation.
					*if (charm<60)
						You see them muttering to themselves about your companions getting "special treatment," but they do it quietly enough that you can't scold them for it.  The next time you see ${karlkarla_name} getting some food, ${karlkarla_heshe} seems much happier.
						*if (showstats)
							(Needed 60 Charm)
							*line_break
							(Army Morale -3 and ${karlkarla_name} Relationship +3)
						*set army_morale -3
						*set karlkarla_relationship +3
						*goto After_Tornassa_March_Banter
					*else
						The next time you see ${karlkarla_name} getting some food, ${karlkarla_heshe} seems much happier.
						*if (showstats)
							*line_break
							(Charm +2 and ${karlkarla_name} Relationship +3)
						*set charm +2
						*set karlkarla_relationship +3
						*goto After_Tornassa_March_Banter
				#Say, "You need to stand up for yourself.  Tell them to stop."
					"Oh, it's not that bad," ${karlkarla_name} says quietly as ${karlkarla_heshe} looks at the gravy-covered food.
					*goto Tornassa_KarlKarla_Banter_loop
				#Say nothing more.
					*goto Say_Nothing_KarlKarla
		#Say nothing.
			*label Say_Nothing_KarlKarla
			${karlkarla_name} quietly eats the food on the tray with an annoyed expression on ${karlkarla_hisher} face.
			*goto After_Tornassa_March_Banter
*goto Tornassa_March_Banter

*label After_Tornassa_March_Banter

Your army makes very good time as it reaches Tornassa.  The weather is turning cool and the leaves are changing.  You look at the great city laid out before you.
*if (questdetails="the city of Tornassa")
	It looks much the same as it did during the year you lived there in hiding.
It has many tall towers and the thick walls surrounding it are filled with troops.  You see siege weaponry mounted high on the walls and all of the entrances are sealed up tight, including the enormous front gate.  Selina will be expecting you.
*if ((using_legacy) and (legacy_help="army_size"))
	
	Suddenly, a horn begins to blast as one of the scouts spots something.  Your companions and soldiers gather closely around you as messengers are sent in all direction.  You see a large group of soldiers approaching from behind you.
	
	"Why would Selina attack us when she has Tornassa's sturdy walls as defense?" General Vale ponders as your soldiers get into position.
	
	One large ${legacy_manwoman} rides forward ahead of the others.  You see that the crest on ${legacy_hisher} shield resembles your own family's design, although there are a few differences.  Your soldiers let the messenger through.
	
	"Greetings to the true ${kingqueen} of Daria!" ${legacy_heshe} says.  "We have been waiting for you."
	
	$!{legacy_heshe} proceeds to explain that they belong to a special sect of knights who have trained and remained hidden through the ages until this moment.  They say that King Kyle himself tasked their order with this quest.  They said that there would come a time when the lost heir would return and reclaim the throne.  They've been preparing for this moment for generations.  The Wizard of Elmvale's long-range plan seems to have been a success.
	*if (showstats)
		*line_break
		(Legacy Advantage #9: Army Size +20.  More perks will arrive as the story progresses.)
	*set army_size +20

Your army sets up camp and places some rudimentary defences around it.  Similar to Eddan, Selina allows you to set up without trouble.  She would be very happy if you were to try to wait her out.  If you are still outside the thick walls when the snow falls, your army will dwindle away to nothing.  As it is, your food supplies are nearly non-existent as you survey the thick walls of Tornassa.
*set food_needed 15
*gosub Army_Use_Food

You, Naistalan the elf,
*if (orc_help>0)
	Gurstwin the half-orc,
*if (gnome_help>0)
	Runyan the gnome,
*if (halfling_help>0)
	Yam, the halfling,
*if (dwarf_help>0)
	Kergith, the dwarf,
General Vale and your companions all gather in the command tent with a large map of Tornassa spread across the wooden table that was brought for just this purpose.
*label War_Talk_loop
*choice
	*if (warprep_spies="Tornassa") #Ask, "Captain ${branbrinn_name}, what news of the spies in Tornassa?"
		"Nothing, Your Highness," ${branbrinn_name} says.  "They could have been caught by Selina.  There hasn't been word from them in some time.  Sorry, we just don't know."
		*goto War_Talk_loop
	*if (gnome_help>0) #Ask, "Runyan, can your brethren in the city open the gates for us?"
		"I'm sorry, Your Highness," the gnome says.  "Burgomaster Snarflan sent his best warriors.  All that remain are the children and the old.  They would be killed if they attempted to do anything from within the walls.  They will be hiding in our warehouse home until this is settled."
		*goto War_Talk_loop
	#Ask, "General Vale, how would you have us proceed?"
		"We have no time to be overly cautious," he says.  "I suggest that we make siege towers so we can battle their soldiers and not spend our time banging our swords against the base of the walls.  But then, we must attack right away.  I am sure Duchess Selina will send sorties out to harass us, but she won't commit her entire strength to such a maneuver.  She'll want to wait us out.  We'll need to attack them with waves of soldiers until we weaken them enough to mount a full offensive.  Any delays will only hurt us and make Duchess Selina stronger."
		*goto War_Talk_loop
	#Ask, "Naistalan, how would you have us proceed?"
		"We will need to be cautious," the elf says in his deep voice.  "I would suggest that we fortify ourselves so that the duchess doesn't destroy us with a strong sally."
		*goto War_Talk_loop
	*if (orc_help>0) #Ask, "Gurstwin, how would you have us proceed?"
		"We attack!" the half-orc warrior says without pause.  "We strike first, we strike hard and we don't stop until we have taken the city!"
		*goto War_Talk_loop
	*if (dwarf_help>0) #Ask, "Kergith, how would you have us proceed?"
		"We must soften their resolve with axes and hammers to their faces," the fierce bearded dwarf says.  "Once we have knocked some sense into them, we should demand their surrender."
		*goto War_Talk_loop
	*if (halfling_help>0) #Ask, "Yam, how would you have us proceed?"
		"I haven't a clue!" the small halfling says.  "I've never seen such a thing as this city.  The walls are enormous.  I'm sorry, $!{princeprincess} ${name}."
		*goto War_Talk_loop
	#Tell everyone what you will do.
		*goto War_Talk_2

*label War_Talk_2
Tornassa is the most heavily fortified city in all of Daria.  It is ironic that as the heir to the kingdom, it has fallen to you to attack your own capital.  The outer walls are amazingly thick and have held back many attacks in the past.  After careful consideration, you have only three real choices.
*choice
	#You will go through the walls by building siege machines.
		*set siege_type "machines"
		Siege warfare has always called for siege machines.  Ballistas, mangonels and trebuchets are some of the various designs you have your troops start building.  There are forests nearby for the structures and there are great rocks to be thrown.  You will have to smash through the walls, if you are to succeed.  Naistalan hates the idea of using the trees, but he understands the need.
		*if (gnome_help=2)
			Runyan is quick to point out that the gnome engineers will be very good at helping to create these machines.
		*goto War_Talk_3
	#You will go under the walls by digging a great tunnel.
		*set siege_type "tunnel"
		The good thing about a tunnel is that you can get past any thickness of wall…as long as they aren't too deep.  In addition, if things begin to go poorly, your sappers can dig up under the walls themselves to make them fall.
		*if (dwarf_help=2)
			Kergith is very happy with this plan, stating that the dwarven miners who joined your army will be of great use.
		*goto War_Talk_3
	#You will go around the walls by creating a covered ram to smash through the front door.
		*set siege_type "ram"
		The entrance of a castle is always the weakest point, since it must be made lighter and with motion to allow passage.  The walls are unbelievably thick…and you will leave them just as they are.  You will need to build a cradle to carry the ram, large wheels to push it along and a thick leather cover to protect the pushers from archers as they push it to the door.
		*if (orc_help=2)
			Gurstwin exclaims that she loves the idea and says that her half-orc berserkers will be happy to lead the fight through the front door of the enemy.
		*goto War_Talk_3

*label War_Talk_3

"Very well," you conclude.  "We have a lot of work to do.  You are all dismissed."

*if ((using_legacy) and (legacy_help="army_power"))
	
	To your surprise, you see a large contingent of soldiers already laying siege to the city.
	
	"We bring food for Daria," the leader of the group says.
	
	The quartermasters in your army wastes no time accepting the packages.  The lead-rider explains that there is a bi-centennial custom where Jilal brings food to Daria for a large festival as a thank you for a service provided a very long time ago.  The Wizard of Elmvale's long-range plan seems to have been a success.
	*if (showstats)
		*line_break
		(Legacy Advantage #9: Army Food +25.  More perks will arrive as the story progresses.)
	*set army_food +25
*if (army_delays<=1)
	Although the leaves are changing colour and the weather is getting cooler, you have done well in getting to Tornassa so quickly.
*if ((army_delays>=2) and (army_delays<=4))
	You recall the frost on the ground that morning and realize you are short on time.
*if (army_delays>=5)
	You can feel a bitterness in the air and know it could begin snowing any day now.
*temp temp_didsomething false
*label War_Preparation_loop
*choice
	#Build siege towers to attack the soldiers on the walls, knowing that it will divert your forces from their work on the ${siege_type}.
		*set temp_towers true
		The tall towers on wheels have leather aprons over them to prevent archers from striking those pushing the towers forward.  They are designed so that when they reach the walls, a door opens and your troops inside can run directly onto the wall.  Additionally, ladders run up the middle so those on the ground can climb right up and into the castle as well.  It delays you from working on the ${siege_type}.  You hope that the extra offence is worth it.
		*if (showstats)
			*line_break
			(Army Power +15 and Army Delays +1)
		*set army_delays +1
		*set army_power +15
		
		During the extra time it takes to make the defences, your army continues to eat.
		*set food_needed 10
		*gosub Army_Use_Food
		*goto War_Preparation_loop
	#Build up your defences, knowing that it will divert your forces from their work on the ${siege_type}.
		*set temp_defences true
		Although Selina will be happy to see you and your army starve at the base of her walls, if she sees that you are unprotected, she will likely still attack you and end the threat once and for all.  Your soldiers dig trenches and mount sharpened sticks all around your army camp.  Additionally, piles of sand and buckets of water are gathered to put out any fires which might be started.  It delays you from working on the ${siege_type}.  You hope that the extra defences are worth it.
		*if (showstats)
			*line_break
			(Army Delays +1)
		*set army_delays +1
		
		During the extra time it takes to make the defences, your army continues to eat.
		*set food_needed 10
		*gosub Army_Use_Food
		*goto War_Preparation_loop
	#Raid the surrounding countryside for food, knowing that it will divert your forces from their work on the ${siege_type}.
		You know that without food, your army can't function.  Duchess Selina is very smart and has set many of the surrounding fields to the torch, but she could only burn so much.  By ranging a little farther, you find unharvested fields and silos of food.  Additionally, there are still wild animals to be caught whose meat can fill many soldiers' bellies.
		*if (showstats)
			*line_break
			(Army Food +10 and Army Delays +1)
		*set army_food +10
		*set army_delays +1
		*goto War_Preparation_loop
	*if (temp_didsomething=false) #Focus all of your troops' efforts on the ${siege_type}.
		*goto Camp_Followers_Grow
	*if (temp_didsomething) #Have your troops work on the ${siege_type}.
		*goto Camp_Followers_Grow

*label Camp_Followers_Grow
The non-combatants of your army are camped farther back than the others.  You are surprised at how many extra people slowly fill your camp.  Many of them are profiteers, finding a way to make money from all of the assembled people.  Prostitutes, religious clergy, sellers of charms, honest merchants and craftsmen for hire create an entire network of commerce.
*if ((silver_blades_free) and (orc_help=0))
	
	"So, you really are the ${princeprincess} of Daria," a voice calls out to you as you walk among your troops.
	
	You see a group of adventurers standing behind a few guards who had stopped them from getting too close to you.  The warrior is wearing a sturdy suit of plate armour.  The wizard has the blue robes with yellow moons and stars, indicating that he is Academy trained.  The rogue stands back a bit, but you can see the knives lined across his belt.  The priest has a mace on his belt and is wearing a holy symbol.  It takes you a few moments to realize that they are the Silver Blades…the group that was being held prisoner by the half-orcs.
	
	"We're looking for work," the fighter says.  "Are you hiring?"
	
	You realize just how far you have come.  Adventurers are now showing up on YOUR doorstep asking if you have any jobs for them to do.
	*label Hire_Silver_Blades_loop
	*choice
		*selectable_if (gold>=300) #Say, "I'll pay you 300 gold to join my army." (Needs 300 Gold)
			The group turns toward each other and discusses the matter for a moment.  You can see the greed in the rogue's eyes and the desire for fame in the eyes of the fighter.  After a few minutes, they turn back to you.
			
			"You have yourself a deal!" the rogue says.  "We'll fight for you."
			*if (showstats)
				*line_break
				(Army Power +10 and Gold -300)
			*set army_power +10
			*set gold -300
			*label Hired_Silver_Blades
			
			*label Hired_Silver_Blades_ns
			*set silver_blades_hired true
			The Silver Blades saunter over to one of the camp fires.  You occasionally see them asking the individual soldiers how they are doing and if they have any problems they need help with.
			*goto Begin_First_Wave
		*if (class_bard>0) #Say, "Why don't you join us and I'll make you famous in song."
			*if (class_bard<2)
				"No offence, Your Highness," the fighter says.  "But your songs aren't that famous yet."
				*if (showstats)
					(Needed at Least 2 Levels in Bard)
				
				"We work for money," the rogue adds helpfully.
				*goto Hire_Silver_Blades_loop
			"Deal!" the fighter says, stepping forward and shaking your hand without discussing it with the rest of his group.
			*if (showstats)
				*line_break
				(Army Power +10)
			*set army_power +10
			
			Your reputation as a bard has preceded you.  The fighter knows that you have the ability to immortalize the Silver Blades in song and he is eager to take you up on the offer.
			*goto Hired_Silver_Blades_ns
		#Say, "Why don't you help me now and I'll reward you handsomely after the battle?"
			*if (charm>=60)
				"You have a deal," the priest of the group says, stepping forward and shaking your hand without discussing it with the rest of his group.
				*if (showstats)
					*line_break
					(Charm +2 and Army Power +10)
				*set charm +2
				*set army_power +10
				*label Silver_Blades_Opportunities
				
				Adventuring parties are used to doing things for free as they build their reputations.  They know that if they can gain a good relationship with you, you are likely to provide them with larger opportunities in the future.
				*goto Hired_Silver_Blades_ns
			"We need money," the rogue of the group says bluntly.
			*if (showstats)
				(Needed 60 Charm)
			*goto Hire_Silver_Blades_loop
		*if ((demonstone_xiatta) and (demonstone_xiatta_known)) #Take out your Xi'atta Demonstone and say, "I'll give you this Demonstone, if you fight for me."
			*goto Gave_Xiatta
		*if ((demonstone_xiatta) and (demonstone_xiatta_known=false)) #Take out the Demonstone which is glowing a soft blue and say, "I'll give you this Demonstone, if you fight for me."
			*label Gave_Xiatta
			*set demonstone_xiatta false
			*label Silver_Blade_Gave_Stone
			The wizard of the group studies the Demonstone for a bit as he decides whether it is valuable or not.
			
			"You have a deal," the wizard says, stepping forward and shaking your hand.
			*if (showstats)
				*line_break
				(Army Power +15 and Lost Demonstone)
			*set army_power +15
			
			Adventuring parties are used to working for magical items and this group is no different.
			*goto Hired_Silver_Blades_ns
		*if ((demonstone_zonch) and (demonstone_zonch_known)) #Take out your Zon'ch Demonstone and say, "I'll give you this Demonstone, if you fight for me."
			*goto Gave_Zonch
		*if ((demonstone_zonch) and (demonstone_zonch_known=false)) #Take out the Demonstone which is glowing a greyish brown and say, "I'll give you this Demonstone, if you fight for me."
			*label Gave_Zonch
			*set demonstone_zonch false
			*goto Silver_Blade_Gave_Stone
		*if ((demonstone_brahl) and (demonstone_brahl_known)) #Take out your Brahl Demonstone and say, "I'll give you this Demonstone, if you fight for me."
			*goto Gave_Brahl
		*if ((demonstone_brahl) and (demonstone_brahl_known=false)) #Take out the Demonstone which is glowing a dull green and say, "I'll give you this Demonstone, if you fight for me."
			*label Gave_Brahl
			*set demonstone_Brahl false
			*goto Silver_Blade_Gave_Stone
		*if (demonstone_tyborr) #Take out your Tyborr Demonstone and say, "I'll give you this Demonstone, if you fight for me."
			*set demonstone_tyborr false
			*goto Silver_Blade_Gave_Stone
		*if ((demonstone_daanda) and (demonstone_daanda_known)) #Take out your Daan'da Demonstone and say, "I'll give you this Demonstone, if you fight for me."
			*goto Gave_Daanda
		*if ((demonstone_daanda) and (demonstone_daanda_known=false)) #Take out the Demonstone which is glowing a dim grey and say, "I'll give you this Demonstone, if you fight for me."
			*label Gave_Daanda
			*set demonstone_daanda false
			*goto Silver_Blade_Gave_Stone
		*if (demonstone_gaabon) #Take out your Gaa'bon Demonstone and say, "I'll give you this Demonstone, if you fight for me."
			*set demonstone_gaabon false
			*goto Silver_Blade_Gave_Stone
		#Say, "You have the opportunity to become very powerful by fighting for me."
			You tell them of many famous adventurers who learned great magic, gained powerful artifacts and mastered legendary skills by fighting alongside kings and queens.
			
			*if (history>=60)
				"You have a deal," the wizard of the group says, stepping forward and shaking your hand without discussing it with the rest of his group.
				*if (showstats)
					*line_break
					(History +2 and Army Power +10)
				*set history +2
				*set army_power +10
				*goto Silver_Blades_Opportunities
			"We need money," the rogue of the group says bluntly.
			*if (showstats)
				(Needed 60 History)
			*goto Hire_Silver_Blades_loop
		#Say, "Sorry, I'm not hiring mercenaries at this time."
			"As you wish, Your Highness," the priest of the group says with a bow.
			
			You watch them walk away.  They continue to ask random people if they need any help as they leave your army.  Adventuring parties are notorious for being nosy and meddling in other people's affairs.
			*goto Begin_First_Wave
*else
	*goto Begin_First_Wave_ns
*label Begin_First_Wave

*label Begin_First_Wave_ns
The flags of Tornassa continue to flap in the wind as the soldiers look down upon your assembled troops in wary anticipation.
*if (siege_type="machines")
	The catapults are in their early stages, which means they are mostly just raw logs being cut and tied together.
*if (siege_type="ram")
	The ram being made is in its early stages, which means that it is mostly just a big log with a rudimentary cradle being built around it.
*if (siege_type="tunnel")
	The tunnel being dug is several feet deep already, but you had to start a long way from the wall to prevent archers or enemy soldiers from discovering it.
*choice
	#Send waves of attackers against the wall.
		There is no way to surprise the enemy, so you don't bother to try.  Your cavalry prepare their horses and your infantry get their swords ready.  Your archers line up together and make sure that their bows are strung well.
		*if (temp_towers)
			The siege towers are filled with soldiers and more troops gather at their bases, ready to push.
		*if (class_warmaster>0)
			All of this is done under your guidance as a War Master.
		With the luck of the Gods and Goddesses, you might even take the city on your first attempt.
		*choice
			#Participate in the attack yourself.
				General Vale is red-faced with anger when he hears that you will be going with the first wave.
				
				"Are you crazy?" he says loudly.  "You are more valuable back here, where it is safe."
				*if (showstats)
					*line_break
					(General Vale Relationship -5)
				*set vale_relationship -5
				
				Despite the fact that the general isn't happy, your army is very pleased to see that you will be coming with them.  Your companions know that their place is with you, so they get their weapons
				*if (squire_name="None")
					ready.
				*if (squire_name!="None")
					ready, as does ${squire_name}, your squire.
				*if (kratog_hired)
					You see Kratog, the giant, standing with the pikemen.
				*if (showstats)
					*line_break
					(Army Morale +10)
				*set army_morale +10
				
				You watch
				*if (mount_name!="None")
					from the back of ${mount_name}
				as your soldiers get into position and begin their charge.
				*choice
					#Join the archers.
						*set who_with "archers"
						*goto After_Who_With
					#Join those on foot.
						*set who_with "infantry"
						*goto After_Who_With
				*label After_Who_With
				Your
				*if (karlkarla_inparty)
					archers, with ${karlkarla_name} among them,
				*if (karlkarla_inparty=false)
					archers
				pelt the enemy in order to prevent them from being too accurate with their own bows.
				*if (halfling_help=1)
					The halfling slingers and elven archers do very well in keeping the enemy occupied.
					*set t_army -5
					*if (showstats)
						*line_break
						(Tornassa Army -5 to ${t_army} / 100)
					*goto First_Wave_With
				*else
					The elven archers do very well in keeping the enemy occupied.
					*set t_army -3
					*if (showstats)
						*line_break
						(Tornassa Army -3 to ${t_army} / 100)
					*goto First_Wave_With
				*label First_Wave_With
				*if (academy_help>0)
					
					The open field of battle is good for the wizards in your group, allowing them to cast their magics against the walls from a distance.  Unfortunately, the enemy is very careful to aim all of their arrows at such casters, making them pay dearly for each spell they perform.
					*if (academy_help=1)
						*set t_army -3
						*if (showstats)
							*line_break
							(Tornassa Army -3 to ${t_army} / 100)
					*if (academy_help=2)
						You are glad to have so many of the wizards with you, since each magic-user is worth many regular soldiers.
						*set t_army -5
						*if (showstats)
							*line_break
							(Tornassa Army -5 to ${t_army} / 100)
				*if (who_with="archers")
					*if (jacejess_inparty)
						
						${jacejess_name} shoots beams of white light from ${jacejess_hisher} eyes at the soldiers on the wall.
						*set t_army -2
						*if (showstats)
							*line_break
							(Tornassa Army -2 to ${t_army} / 100)
					*choice
						*if ((bow) or (class_elementalarcher>0)) #Shoot arrows at your enemy.
							*if (class_elementalarcher=1)
								You extend your hand and your Astral Bow appears from thin air.  Every projectile you fire hits its intended target with deadly accuracy.  Stone arrows, ice arrows and fire arrows strike the guards on the walls without mercy.
								*set t_army -10
								*if (showstats)
									*line_break
									(Archery +3 and Tornassa Army -10 to ${t_army} / 100)
								*set archery +3
								*goto After_Archer_With_MC
							You fire many arrows at the guards on the tower.  With every successful shot, your archers gain encouragement and begin striking better themselves.	
							*if (archery<30)
								You don't hit many targets, but with enough arrows and enough soldiers on the walls, you manage to take out a few.
								*set t_army -2
								*if (showstats)
									(Needed 30 Archery for Greater Bonus)
									*line_break
									(Tornassa Army -2 to ${t_army} / 100)
								*goto After_Archer_With_MC
							*if (archery<60)
								You are a decent archer, not as good as some others, but you hit most of your targets.
								*set t_army -4
								*if (showstats)
									(Needed 60 Archery for Greater Bonus)
									*line_break
									(Tornassa Army -4 to ${t_army} / 100)
								*goto After_Archer_With_MC
							*if (archery<90)
								You are one of the best archers in your army, taking out targets left and right.
								*set t_army -6
								*if (showstats)
									(Needed 90 Archery for Greater Bonus)
									*line_break
									(Tornassa Army -6 to ${t_army} / 100)
								*goto After_Archer_With_MC
							*comment (archery>=90)
							You are a force to be reckoned with as you hit every target you aim for.
							*set t_army -8
							*if (showstats)
								*line_break
								(Archery +3 and Tornassa Army -8 to ${t_army} / 100)
							*set archery +3
							*goto After_Archer_With_MC
						#Cast magic at your enemy.
							Lighting and fire are both great weapons when used from a distance.	
							*if (magic<30)
								Many of your spells falter and miscast, but the ones that complete cause devastation on the walls.
								*set t_army -2
								*if (showstats)
									(Needed 30 Magic for Greater Bonus)
									*line_break
									(Tornassa Army -2 to ${t_army} / 100)
								*goto After_Archer_With_MC
							Your fingers erupt with arcane energies as you bathe your enemies in death.
							*if (magic<60)
								You have to take a few breaks to catch your breath, but you do well.
								*set t_army -4
								*if (showstats)
									(Needed 60 Magic for Greater Bonus)
									*line_break
									(Tornassa Army -4 to ${t_army} / 100)
								*goto After_Archer_With_MC
							*if (magic<90)
								*set t_army -7
								*if (showstats)
									(Needed 90 Magic for Greater Bonus)
									*line_break
									(Tornassa Army -7 to ${t_army} / 100)
								*goto After_Archer_With_MC
							*comment (magic>=90)
							There hasn't been a display of such power since the time of legends.
							*set t_army -10
							*if (showstats)
								*line_break
								(Magic +3 and Tornassa Army -10 to ${t_army} / 100)
							*set magic +3
							*goto After_Archer_With_MC
						*if (class_priest>0) #Call upon ${god_name} to bless your archers.
							You say the words and your ${god_goddess} answers.
							*if (god_good)
								Your troops suddenly feel calmer and braver, allowing them to shoot with greater accuracy as goodness fills their hearts.
							*if (god_good=false)
								Your troops suddenly feel cold and murderous, allowing them to shoot without hesitancy as evil fills their hearts.
							*if (class_priest=1)
								*set t_army -2
								*if (showstats)
									(Needed $!{priestpriestess} Level 2 for Greater Bonus)
									*line_break
									(Tornassa Army -2 to ${t_army} / 100)
								*goto After_Archer_With_MC
							*if (class_priest=2)
								*set t_army -4
								*if (showstats)
									(Needed $!{priestpriestess} Level 3 for Greater Bonus)
									*line_break
									(Tornassa Army -4 to ${t_army} / 100)
								*goto After_Archer_With_MC
							*if (class_priest=3)
								*set t_army -7
								*if (showstats)
									(Needed $!{priestpriestess} Level 4 for Greater Bonus)
									*line_break
									(Tornassa Army -7 to ${t_army} / 100)
								*goto After_Archer_With_MC
							*comment (class_priest=4)
							*set t_army -10
							*if (showstats)
								*line_break
								(Tornassa Army -10 to ${t_army} / 100)
							*goto After_Archer_With_MC
						*if (class_bard>0) #Encourage your archers with song.
							Your mystical words of encouragement seep into your troops.
							*if (class_bard=1)
								*set t_army -2
								*if (showstats)
									(Needed Bard Level 2 for Greater Bonus)
									*line_break
									(Tornassa Army -2 to ${t_army} / 100)
								*goto After_Archer_With_MC
							*if (class_bard=2)
								*set t_army -4
								*if (showstats)
									(Needed Bard Level 3 for Greater Bonus)
									*line_break
									(Tornassa Army -4 to ${t_army} / 100)
								*goto After_Archer_With_MC
							Suddenly, they are shooting like figures from legend.
							*if (class_bard=3)
								*set t_army -7
								*if (showstats)
									(Needed Bard Level 4 for Greater Bonus)
									*line_break
									(Tornassa Army -7 to ${t_army} / 100)
								*goto After_Archer_With_MC
							*comment (class_bard=4)
							*set t_army -10
							*if (showstats)
								*line_break
								(Tornassa Army -10 to ${t_army} / 100)
							*goto After_Archer_With_MC
					*label After_Archer_With_MC
					
					Unfortunately, you are recognized as the ${princeprincess} and the archers on the walls try to end the war early by aiming at you.  You manage to avoid a lot of the arrows, but one of them escapes your guard and lodges itself in your shoulder.
					*set health -20
					*if (showstats)
						*line_break
						(Health -20 to ${health} / 100)
				*comment both Archer and Infantry here again
				*if (army_size<15)
					
					The attack goes poorly after this.  You simply don't have the manpower to do any real damage.
					*if (temp_towers)
						All of your siege towers are destroyed before reaching the walls.
						*set temp_towers false
					Your troops rush back to your camp, crestfallen at how poorly the first assault went.
					*if (showstats)
						(Needed 15 Army Size)
					*if (army_size>0)
						*if (showstats)
							*line_break
							(Army Size -${army_size} and Army Morale -10)
						*set army_size 0
						*set army_morale -10
						*gosub Check_Army_Stats
						*goto Check_Necromancy
					*else
						*if (showstats)
							*line_break
							(Army Morale -10)
						*set army_morale -10
						*gosub Check_Army_Stats
						*goto Check_Necromancy
				*set damage_done 5
				
				Your swordsmen,
				*if (theothea_story=10)
					${theothea_name}'s northmen,
					*set damage_done +2
				*if (orc_help=1)
					Gurstwin's half-orcs,
					*set damage_done +2
				*if (orc_help=2)
					Gurstwin's berserker half-orcs,
					*set damage_done +4
				*if (dwarf_help>0)
					Kergith's dwarves,
					*set damage_done +2
				your spear-wielders and your pikemen rush toward the wall
				*if (temp_towers)
					alongside your siege towers, which are filled with even more of their number.  You watch as many of the towers are destroyed by enemy magic and siege weapons, but a few of them meet the walls and unload your troops into the midst of the enemy soldiers.
					*set damage_done +10
					*goto On_the_wall_With_MC
				*else
					carrying various implements.  Siege ladders and ropes with grappling hooks are thrown upward and the troops climb bravely.  Many soldiers are killed, but a few make it on to the walls.
					*goto On_the_wall_With_MC
					
				*label On_the_wall_With_MC
				*set t_army -damage_done
				*if (showstats)
					*line_break
					(Tornassa Army -${damage_done} to ${t_army} / 100)
				*if (who_with="archers")
					*goto Battle_On_Walls_both
				*comment Infantry Only
				
				You are with the front line the entire
				*if (mount_type="dragon")
					way, flying over your troops on ${mount_name}.  Your mighty dragon breathes fire down upon the soldiers on the walls as you pass.  Your troops are eventually driven from the walls, but not before you do great damage to the enemy.
					*set t_army -10
					*if (showstats)
						*line_break
						(Agility +3 and Tornassa Army -10 to ${t_army} / 100)
					*set agility +3
					*goto Battle_On_Walls_both
				*if (mount_name!="None")
					*if (((mount_type="crocodile") or (mount_type="hellbeast")) or ((mount_type="forest worm") or (mount_type="Dreadhorse"))) 
						way, although your fearsome mount doesn't find any enemies to fight.
						*goto Need_To_Dismount
					*else
						way.
						*label Need_To_Dismount
						*if (mount_type="Dreadhorse")
							A stray arrow strikes ${mount_name} in the throat!  Dark black blood trickles from the wound, but that is all.  Your undead mount is long past feeling any such injuries.
						*choice
							#Dismount ${mount_name} and join your soldiers on the walls.
								You get off of ${mount_name} and join your troops on foot.
								*goto After_Mount_Check
							#Stay on your ${mount_type}.
								*goto Options_From_Below
				*label After_Mount_Check
				*if (temp_towers)
					You are close to one of the siege towers and could probably climb it up to the walls.
					*choice
						#Climb the siege tower.
							*goto On_The_Walls_ns
						#Stay on the ground.
							*goto Options_From_Below
				*else
					You look up at the men and women on the walls fighting.
					*label On_Ground
					*choice
						*if (rope) #Throw your rope up to the soldiers and join them.
							*if (agility<40)
								You start climbing, but in all of the excitement, your hand slips!  You fall to the ground dazed as the fight ends without you.
								*set health -20
								*if (showstats)
									(Needed 40 Agility)
									*line_break
									(Health -20 to ${health} / 100)
								*goto Battle_On_Walls_both
							You climb the rope easily and join the soldiers on the walls.
							*if (showstats)
								*line_break
								(Agility +2)
							*set agility +2
							*goto On_The_Walls
						*if (thiefharness) #Tie your thief harness to your rope and throw it up to the men and women on the wall.
							*if (rope=false)
								You realize suddenly that you don't have a rope to tie it to!
								*goto On_Ground
							*else
								Your men haul you up to join them on the walls.
								*goto On_The_Walls_ns
						*if (class_monk=4) #Levitate to the walls.
							You meditate and allow your enlightened mind to counter reality itself.  You rise swiftly to the top of the walls.
							*goto On_The_Walls_ns
						#Cast a spell to allow you to jump to the top of the wall.
							*if (magic<40)
								You cast the spell, but when you try to jump, you can only get a few feet off the ground.
								*if (showstats)
									(Needed 40 Magic)
								*goto On_Ground
							You cast the spell and jump!
							*if (magic<60)
								Unfortunately, the spell was not calibrated perfectly and you smash into the wall!  You fall to the ground dazed as the fight ends without you.
								*set health -20
								*if (showstats)
									(Needed 60 Magic)
									*line_break
									(Health -20 to ${health} / 100)
								*goto Battle_On_Walls_both
							You land on the walls without a problem.
							*if (showstats)
								*line_break
								(Magic +2)
							*set magic +2
							*goto On_The_Walls
						*if (cloak_of_spiders) #Use the Cloak of Spiders to crawl up the wall.
							You have no trouble scampering up the sheer wall and joining your soldiers up top.
							*goto On_The_Walls_ns
						#Stay on the ground.
							*goto Options_From_Below
				*label Options_From_Below
				You see the soldiers on the walls engaging the enemy and consider your options from the ground below.
				*choice
					*if (class_priest>0) #Call upon ${god_name} to bless your troops.
						You say the words and your ${god_goddess} answers.  You suspect that the divine spell would be more effective if you could have been closer to the soldiers on top of the wall.
						*if (god_good)
							Your troops suddenly feel calmer and braver, allowing them to hit harder as goodness fills their hearts.
						*if (god_good=false)
							Your troops suddenly feel cold and murderous, allowing them to fight without hesitancy as evil fills their hearts.
						*if (class_priest=1)
							*set t_army -1
							*if (showstats)
								(Needed $!{priestpriestess} Level 2 for Greater Bonus)
								*line_break
								(Tornassa Army -1 to ${t_army} / 100)
							*goto Battle_On_Walls_both_ns
						*if (class_priest=2)
							*set t_army -2
							*if (showstats)
								(Needed $!{priestpriestess} Level 3 for Greater Bonus)
								*line_break
								(Tornassa Army -2 to ${t_army} / 100)
							*goto Battle_On_Walls_both_ns
						*if (class_priest=3)
							*set t_army -4
							*if (showstats)
								(Needed $!{priestpriestess} Level 4 for Greater Bonus)
								*line_break
								(Tornassa Army -4 to ${t_army} / 100)
							*goto Battle_On_Walls_both_ns
						*comment (class_priest=4)
						*set t_army -5
						*if (showstats)
							*line_break
							(Tornassa Army -5 to ${t_army} / 100)
						*goto Battle_On_Walls_both_ns
					*if (class_bard>0) #Encourage your soldiers with song.
						Your mystical words of encouragement are difficult to hear from the base of the wall, but the magical melody manages to reach some of the troops above.
						*if (class_bard=1)
							*set t_army -1
							*if (showstats)
								(Needed Bard Level 2 for Greater Bonus)
								*line_break
								(Tornassa Army -1 to ${t_army} / 100)
							*goto Battle_On_Walls_both_ns
						*if (class_bard=2)
							*set t_army -2
							*if (showstats)
								(Needed Bard Level 3 for Greater Bonus)
								*line_break
								(Tornassa Army -2 to ${t_army} / 100)
							*goto Battle_On_Walls_both_ns
						Suddenly, they are fighting like figures from legend.
						*if (class_bard=3)
							*set t_army -4
							*if (showstats)
								(Needed Bard Level 4 for Greater Bonus)
								*line_break
								(Tornassa Army -4 to ${t_army} / 100)
							*goto Battle_On_Walls_both_ns
						*comment (class_bard=4)
						*set t_army -5
						*if (showstats)
							*line_break
							(Tornassa Army -5 to ${t_army} / 100)
						*goto Battle_On_Walls_both_ns
					*if (demonsummoner) #Open your runebag and consider summoning some demons.
						You consider using a Demonstone to help the men and women above.  You know that you will want to be careful, since you might need the demons again soon and if they are killed, they will require time to recover.
						*label Demon_Under_Walls_loop
						*choice
							*if ((demonstone_xiatta) and (demonstone_xiatta_summoned)) #Summon Xi'atta and tell it to freeze the stones beneath the enemy soldiers' feet.
								*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
								*comment: End of Pt. 2, Min 45 Max 75
								Xi'atta appears in front of you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
								*set demonstone_xiatta_used true
								
								"Right away, ${mastermistress}," Xi'atta says happily.
								
								The frosty little imp flies around casting ice upon the stones.  The ensuing chaos is great fun to watch as the soldiers slip and slide all over the place!  Many enemies fall right off the walls and many of those who keep their feet are killed by your soldiers while they lower their guard to maintain balance.  Eventually, Xi'atta is killed, but not before inflicting many deaths from its meddling.
								*set t_army -5
								*if (showstats)
									*line_break
									(Tornassa Army -5 to ${t_army} / 100)
								*goto Demon_Under_Walls_loop
							*if ((demonstone_brahl) and (demonstone_brahl_summoned)) #Summon Brahl on top of the wall.
								*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
								*comment: End of Pt. 2, Min 45 Max 75
								Brahl appears on the wall above you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
								
								*if (willpower>=70)
									"Yes, ${mastermistress}," Brahl says before going to work.
									
									The muscular demon throws enemy soldiers off the wall with glee.  Those that keep their feet are disembowelled by the demon's sharp claws.  It cuts a bloody swath through the enemy before a group of archers finally kill it, sending it back to the demon-realm to recuperate.
									*set demonstone_brahl_used true
									*set t_army -10
									*if (showstats)
										*line_break
										(Tornassa Army -10 to ${t_army} / 100)
									*goto Demon_Under_Walls_loop
								*else
									"Are you crazy?  That's a death sentence!" Brahl says. The contest of wills is rejoined and the brawny demon pops out of existence.
									*if (showstats)
										(Needed 70 Willpower)
								*goto Demon_Under_Walls_loop
							*if ((demonstone_zonch) and (demonstone_zonch_summoned)) #Summon Zon'ch and tell it to throw dust into the eyes of the enemy soldiers.
								*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
								*comment: End of Pt. 2, Min 45 Max 75
								Zon'ch appears amidst a small cyclone at the top of the wall.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
								
								*if (willpower>=50)
									"Yes, ${mastermistress}," Zon'ch says.
									
									It does just as you ask it to, sending puffs of dirty wind into the faces of the enemy soldiers.  This distraction gives your troops the opportunity to cut them down.  Zon'ch gets a little too close to an enemy soldier who promptly rams his sword through the demon, popping it out of existence.
									*set demonstone_zonch_used true
									*set t_army -5
									*if (showstats)
										*line_break
										(Tornassa Army -5 to ${t_army} / 100)
									*goto Demon_Under_Walls_loop
								*else
									"No way, uh uh," Zon'ch says. The contest of wills is rejoined and the dusty demon pops out of existence.
									*if (showstats)
										(Needed 50 Willpower)
									*goto Demon_Under_Walls_loop
							*if ((demonstone_daanda) and (demonstone_daanda_summoned)) #Summon Daan'da and tell it to kill the enemy soldiers.
								*comment Will of 0, but very stupid and weak.
								*comment: End of Pt. 2, Min 45 Max 75
								Daan'da appears at the top of the wall.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It promptly takes a single step forward without looking and falls off the wall.  It lands at your feet in a broken heap and then pops out of existence as it returns to the demon realm to heal.
								*set demonstone_daanda_used true
								*goto Demon_Under_Walls_loop
							*if (demonstone_gaabon) #Summon Gaa'bon and tell it to use its phasing ability to kill the enemy guards.
								*comment Gaa'bon: Willing: 45, Small Struggle: 55, Against: 65
								*comment: End of Pt. 2, Min 45 Max 75
								Gaa'bon appears in a puff of smoke at the top of the wall.  It is one foot tall and appears sluggish and uninterested in its surroundings.  It slowly glances down at you.
								*if (willpower>=65)
									
									"I guess," Gaa'bon says in its slow drawl as you batter down its will.
									
									The slow moving demon phases into the first guard it sees and then unphases.  Both demon and man yell as their body parts fuse together.  They both fall to the ground in agony.  Gaa'bon disappears back to the demon realm and the man dies in a bloody mess as the demon parts vanish, leaving holes behind.
									*set demonstone_gaabon_used true
									*goto Demon_Under_Walls_loop
								*if (showstats)
									(Needed 65 Willpower)
								
								"No, not going to do that," Gaa'bon says in its slow drawl as it battles your will and then returns to its own realm.
								*goto Demon_Under_Walls_loop
							#Watch the soldiers fight.
								*goto Battle_On_Walls_both_ns
					#Shout encouragement at your troops.
						You call out to them and the soldiers take heart in your words, fighting as best they can.
						*if (showstats)
							*line_break
							(Army Morale +3)
						*set army_morale +3
						*goto Battle_On_Walls_both
					#Silently watch the men and women fight.
						*goto Battle_On_Walls_both_ns
				
				*label On_The_Walls
				
				*label On_The_Walls_ns
				The enemy soldiers quickly rush toward you, eager to bring down the ${princeprincess}.  You have lost track of all of your companions and find yourself with the regular soldiers.  You feel a sword slice across your shoulder before you can even react.
				*set health -20
				*if (showstats)
					*line_break
					(Health -20 to ${health} / 100)
				*choice
					*if (class_blademaster>0) #Draw your sword and your dagger and fall into the forms Eagarro taught you.
						You are a whirlwind of complete destruction!  The enemy soldiers fall to your feet as your blades flash in the sunlight.
						*set t_army -10
						*if (showstats)
							*line_break
							(Blades +3 and Tornassa Army -10 to ${t_army} / 100)
						*set blades +3
						*goto After_Infantry_On_Wall
					#Cast a spell that will fill your hands with electricity.
						Blue sparks begin to jump from finger to finger as you advance upon the enemy soldiers.	
						*if (magic<30)
							The voltage is too low to do much damage, but it is enough to distract them while your troops finish them off.
							*set t_army -2
							*if (showstats)
								(Needed 30 Magic)
								*line_break
								(Tornassa Army -2 to ${t_army} / 100)
							*goto After_Infantry_On_Wall
						Balls of electricity form around each hand,
						*if (magic<60)
							causing large burns to every person you touch.
							*set t_army -4
							*if (showstats)
								(Needed 60 Magic for Greater Bonus)
								*line_break
								(Tornassa Army -4 to ${t_army} / 100)
							*goto After_Infantry_On_Wall
						*if (magic<90)
							causing large burns to every person you touch.
							*set t_army -6
							*if (showstats)
								(Needed 90 Magic for Greater Bonus)
								*line_break
								(Tornassa Army -6 to ${t_army} / 100)
							*goto After_Infantry_On_Wall
						*comment (magic>=90)
						killing every person you touch.  Such a display of magical prowess hasn't been seen in ages.
						*set t_army -8
						*if (showstats)
							*line_break
							(Magic +3 and Tornassa Army -8 to ${t_army} / 100)
						*set magic +3
						*goto After_Infantry_On_Wall
					*if (sword) #Draw your sword and fight the enemy soldiers.
						You draw your blade as you advance upon the enemy soldiers.	
						*if (blades<30)
							Your swordsmanship is weak, but your troops rally to your side, killing many of the soldiers for you.
							*set t_army -2
							*if (showstats)
								(Needed 30 Blades for Greater Bonus)
								*line_break
								(Tornassa Army -2 to ${t_army} / 100)
							*goto After_Infantry_On_Wall
						*if (blades<60)
							You are as good as any of the other soldiers on the wall and your troops fight harder seeing you with them.
							*set t_army -4
							*if (showstats)
								(Needed 60 Blades for Greater Bonus)
								*line_break
								(Tornassa Army -4 to ${t_army} / 100)
							*goto After_Infantry_On_Wall
						*if (blades<90)
							You are better than most of the enemies who come at you, which heartens your troops and causes them to fight harder.
							*set t_army -6
							*if (showstats)
								(Needed 90 Blades for Greater Bonus)
								*line_break
								(Tornassa Army -6 to ${t_army} / 100)
							*goto After_Infantry_On_Wall
						*comment (blades>=90)
						Your sword is a blur as you fight like a hero from legends.  Your troops rally around you, inflicting heavy casualties on the enemy.
						*set t_army -8
						*if (showstats)
							*line_break
							(Blades +3 and Tornassa Army -8 to ${t_army} / 100)
						*set blades +3
						*goto After_Infantry_On_Wall
					*if (belt_of_speed) #Take advantage of the Belt of Speed's bright glow.
						The belt suddenly glows brilliantly and you are unstoppable!  You weave between the enemies, pushing and throwing them down to their deaths.  Your troops rally around you as you inflict heavy casualties upon the enemy before the belt stops glowing again.
						*set t_army -10
						*if (showstats)
							*line_break
							(Tornassa Army -10 to ${t_army} / 100)
						*goto After_Infantry_On_Wall
					#Throw as many enemies off the wall as you can.
						You advance upon the enemy soldiers with empty hands.  It is difficult to close the distance against people with	
						*if (unarmed<70)
							swords.  You manage to throw one or two people off the walls and your troops rally to your side, killing a few more.
							*set t_army -2
							*if (showstats)
								(Needed 70 Unarmed for Greater Bonus)
								*line_break
								(Tornassa Army -2 to ${t_army} / 100)
							*goto After_Infantry_On_Wall
						swords, but your superior skills allow you to get inside their guard.  From there, you are able to push or throw the soldiers off the wall to their deaths below.  With every man you kill, your troops surge in around you, killing dozens more.
						*if (unarmed<90)
							*set t_army -5
							*if (showstats)
								(Needed 90 Unarmed for Greater Bonus)
								*line_break
								(Tornassa Army -5 to ${t_army} / 100)
							*goto After_Infantry_On_Wall
						*set t_army -8
						*if (showstats)
							*line_break
							(Unarmed +3 and Tornassa Army -8 to ${t_army} / 100)
						*set unarmed +3
						*goto After_Infantry_On_Wall
				*label After_Infantry_On_Wall
				
				After a few minutes of intense fighting, you see that you are still greatly outnumbered.  You and your soldiers leave the walls before you are overwhelmed.
				*goto Battle_On_Walls_Both_ns
			#Send your troops and watch from a safe distance.
				General Vale nods sagely at your side.  Your companions know that their place is with you, so they also remain
				*if (squire_name="None")
					behind.
				*if (squire_name!="None")
					behind, as does ${squire_name}, your squire.
				
				"You are the leader," General Vale states.  "You are more valuable back here, where it is safe."
				*if (showstats)
					*line_break
					(General Vale Relationship +5)
				*set vale_relationship +5
				
				You watch as your soldiers get into position and begin their charge.
				*if (kratog_hired)
					Kratog, the giant, stands with the pikemen, ready to attack.
				Your archers pelt the enemy in order to prevent them from being too accurate with their own bows.
				*if (halfling_help=1)
					The halfling slingers and elven archers do very well in keeping the enemy occupied.
					*set t_army -5
					*if (showstats)
						*line_break
						(Tornassa Army -5 to ${t_army} / 100)
					*goto First_Wave_NoGo
				*else
					The elven archers do very well in keeping the enemy occupied.
					*set t_army -3
					*if (showstats)
						*line_break
						(Tornassa Army -3 to ${t_army} / 100)
					*goto First_Wave_NoGo
				*label First_Wave_NoGo
				*if (academy_help>0)
					
					The open field of battle is very good for the wizards in your group, allowing them to cast their magics against the walls from a distance.  Unfortunately, the enemy is very careful to aim all of their arrows at such casters, making them pay dearly for each spell they perform.
					*if (academy_help=1)
						*set t_army -3
						*if (showstats)
							*line_break
							(Tornassa Army -3 to ${t_army} / 100)
					*if (academy_help=2)
						You are glad to have so many of the wizards with you, since each magic-user is worth many regular soldiers.
						*set t_army -5
						*if (showstats)
							*line_break
							(Tornassa Army -5 to ${t_army} / 100)
				
				*if (army_size<15)
					
					Unfortunately, the attack goes poorly after this.  You simply don't have the manpower to do any real damage.
					*if (temp_towers)
						All of your siege towers are destroyed before reaching the walls.
						*set temp_towers false
					Your troops rush back to your camp, crestfallen at how poorly the first assault went.
					*if (showstats)
						(Needed 15 Army Size)
					*if (army_size>0)
						*if (showstats)
							*line_break
							(Army Size -${army_size} and Army Morale -10)
						*set army_size 0
						*set army_morale -10
						*gosub Check_Army_Stats
						*goto Check_Necromancy
					*else
						*if (showstats)
							*line_break
							(Army Morale -10)
						*set army_morale -10
						*gosub Check_Army_Stats
						*goto Check_Necromancy
				*set damage_done 5
				Your swordsmen,
				*if (theothea_story=10)
					${theothea_name}'s northmen,
					*set damage_done +2
				*if (orc_help=1)
					Gurstwin's half-orcs,
					*set damage_done +2
				*if (orc_help=2)
					Gurstwin's berserker half-orcs,
					*set damage_done +4
				*if (dwarf_help>0)
					Kergith's dwarves,
					*set damage_done +2
				your spear-wielders and your pikemen rush toward the wall
				*if (temp_towers)
					alongside your siege towers, which are filled with even more of their number.  You watch as many of the towers are destroyed by enemy magic and siege weapons, but a few of them meet the walls and unload your troops into the midst of the enemy soldiers.
					*set damage_done +10
					*goto On_the_wall_nogo
				*else
					carrying various implements.  Siege ladders and ropes with grappling hooks are thrown upward and the troops climb bravely.  Many soldiers are killed, but a few make it to the walls.
					*label On_the_wall_nogo
					*set t_army -damage_done
					*if (showstats)
						*line_break
						(Tornassa Army -${damage_done} to ${t_army} / 100)
					*label Battle_On_Walls_Both
					
					*label Battle_On_Walls_Both_ns
					The battle on the walls is intense, but the castle's defences hold fast.  Great casualties are felt on both sides, but at the end of the day, Tornassa still stands.
					*if (army_power>=70)
						*if (showstats)
							*line_break
							(Army Size -3 and Army Power -3)
						*set army_size -3
						*set army_power -3
						*goto After_First_Wave_both
					*if (army_power>=50)
						*if (showstats)
							(Needed 70 Army Power for Greater Bonus)
							*line_break
							(Army Size -7 and Army Power -7)
						*set army_size -7
						*set army_power -7
						*goto After_First_Wave_both
					*if (army_power>=30)
						*if (showstats)
							(Needed 50 Army Power for Greater Bonus)
							*line_break
							(Army Size -10 and Army Power -10)
						*set army_size -10
						*set army_power -10
						*goto After_First_Wave_both
					*if (showstats)
						(Needed 30 Army Power for Greater Bonus)
						*line_break
						(Army Size -15 and Army Power -15)
					*set army_size -15
					*set army_power -15
					*goto After_First_Wave_both
					
					*label After_First_Wave_both
					*gosub Check_Army_Stats
					
					*if (who_with!="None")
						You are happy to see that all of your friends made it through the first skirmish with only minor wounds.
					Your army cheers happily, despite their losses.  After months of marching and living through the Battle of Ludd, it felt good to finally be taking part in the last battle.  Every enemy soldier killed is seen as one step closer to the end of the war altogether.
					*if (showstats)
						*line_break
						(Army Morale +10)
					*set army_morale +10
					*if (class_warmaster>0)
						
						Your contributions to the plan of attack don't go unnoticed.  The timing of the archers, the distance between them and your infantry and the positions of all of the troops all played a part in inflicting extra damages to the enemies at every opportunity.  General Vale is clearly impressed by your tactical skills.
						*set t_army -10
						*if (showstats)
							*line_break
							(Tornassa Army -10 to ${t_army} / 100)
					*goto Check_Necromancy
	#Continue to hold Tornassa at siege.
		You know that it is a gamble to risk everything on the ${siege_type}, but if it works, you will need all of your troops to execute the plan.
		*goto Check_Necromancy

*label Check_Necromancy
*gosub Check_Army_Stats
*if ((t_army<100) and (class_necromancer>0))
	
	Looking out over all of the dead bodies at the foot of the wall brings many ideas to mind.  Necromancy has always been considered the Forbidden Art, but everyone knows that the victor writes the rules.
	*choice
		#Command your troops to bring you the bodies and rise them as undead soldiers.
			*set necromancer_known true
			The moment you rise the first zombie, Archmage Cumari is at your side and screaming.
			
			"I will not stand by idly while you defy nature with this evil magic!" he shouts.
			
			He blusters a bit more, but doesn't leave your army.  He likely plans to let you deal with the demon threat first and then try to remove you afterwards.
			*if (academy_help>0)
				Unfortunately, you suspect that the Academy wizards among your troops will support him.
				*set academy_help 0
			As your zombie troops reach a dozen, Naistalan comes to you with shock in his eyes.  Much like the archmage, he does little more than shout his displeasure before returning to the other elves.
			*if (showstats)
				*line_break
				(Archmage Cumari Relationship -75)
			*set cumari_relationship -75
			
			*if (peterpetra_inparty)
				You are most surprised by ${peterpetra_name}'s reaction.
				
				"I suppose that the end will justify the means," ${peterpetra_heshe} says sadly.
				
				You realize that the time you have spent with ${peterpetra_name} and your other companions has finally taken its toll on their morals.  You have corrupted them to your evil ways.
			*if (peterpetra_inparty=false)
				Your companions don't seem nearly as alarmed as you would have thought.  You realize that the time you have spent with them has finally taken its toll on their morals.  You have corrupted them to your evil ways.
			The number of deserters you don't catch is greatly outweighed by the number of undead soldiers now under your command.
			*if (showstats)
				*line_break
				(Evil +30, Army Size +20, Army Morale -10, Citizen Fear +50 and Citizen Reputation -50)
			*set good -30
			*set army_size +20
			*set army_morale -10
			*set citizen_fear +50
			*set citizen_reputation -50
			*goto First_Wintertime_Check
		#Leave the bodies where they are, knowing that the world is not ready to see the true power of a Necromancer in their midst.
			The dead bodies of their comrades and slain enemies would likely unnerve even the most stalworth soldier in your service.  You decide to leave them rotting on the ground and not raise them.
			*goto First_Wintertime_Check
*goto First_Wintertime_Check
	
*label First_Wintertime_Check
*gosub Check_Army_Stats
*if (army_delays>=4)
	*comment army_delays 0 - 8
	
	*set its_snowing true
	Your various delays have finally come back to haunt you as you wake up one morning to see snow falling on the ground.  The dangers of frostbite, exposure and fatigue suddenly become a reality as your troops trudge through the cold to complete their daily tasks.  The weak and loyal don't wake up on the coldest mornings, but the strong and disloyal simply desert.
	*if (army_morale>=50)
		*if (showstats)
			(Needed 3 or Fewer Army Delays)
			*line_break
			(Army Size -3 and Army Power -3)
		*set army_size -3
		*set army_power -3
		*goto First_Wintertime_Check2
	*else
		*if (showstats)
			(Needed 3 or Fewer Army Delays and 50 Army Morale)
			*line_break
			(Army Size -7 and Army Power -7)
		*set army_size -7
		*set army_power -7
		*goto First_Wintertime_Check2
*else
	*goto First_Wintertime_Check2
		
*label First_Wintertime_Check2
*gosub Check_Army_Stats

*if (siege_type="ram")
	*goto Ram_Event
*if (siege_type="tunnel")
	*goto Tunnel_Event
*comment only "machines" left
*goto Machines_Event

*label Tunnel_Event
*if (dwarf_help>0)
	"She's flooded!" the mud-covered dwarf shouts angrily at you.  "It wasn't a dwarf.  I can be telling you that right now!  We can sense pockets of underground water and have the smarts not to dig where there be moisture.  It's one of your soldiers who did this!"
*if (dwarf_help=0)
	"We have a problem, Your Highness," a mud-covered man says to you.  "We've tunnelled into a water pocket."

Your tunnel was a little over halfway to the walls when your sappers broke into an underground spring.  You are led into the hidden entrance and down into the dark.  Wooden supports brace the earth around the tunnel and lanterns are hung on spikes to provide light.  You can smell the humidity immediately and hear the water rushing into your tunnel.  You reach the end of the tunnel, but it is already soaked in three feet of water and filling rapidly.
*label Tunnel_Event_loop
*choice
	*if (class_alchemist>0) #Create a gunky resin to seal the breach using alchemy.
		You return to your tent and set up your equipment.  You have the ingredients that you need and it takes only a few hours to make the potion.  You go back down the tunnel and see that the water is a little deeper.  Carefully, you throw the potion into the breach and watch as the magic takes hold.  The water turns grey and spongy.  As the thickening sludge solidifies, the water stops pouring.  Your miners will have to dig through the new substance, but as long as they stay away from the spring, they should be able to keep going straight with no delays.
		*if (showstats)
			*line_break
			(Nature +2)
		*set nature +2
		*goto After_Protect_Event
	*if (dwarf_help>0) #Ask the dwarves which way you should tunnel.
		"Not into the spring!" the muddy bearded fellows say.  "Just tunnel around it.  We'll get there eventually."
		*goto Tunnel_Event_loop
	*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and ((demonstone_zonch_used=false) and (demonsummoner))) #Summon Zon'ch and have it seal the breach.
		*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
		*comment: End of Pt. 2, Min 45 Max 75
		Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.  It inspects the pouring water and the soggy dirt around the hole.  It throws a few gusts of dirty wind at the breach, but the blasts do nothing.
		
		"Sorry, ${mastermistress}," it says.  "Not dusty enough.  I can't do anything with this."
		*goto Tunnel_Event_loop
	*if (((demonstone_gaabon) and (demonstone_gaabon_used=false)) and (demonsummoner)) #Summon Gaa'bon and have the demon phase into the earth and learn where the spring lies.
		*comment Gaa'bon: Willing: 45, Small Struggle: 55, Against: 65
		*comment: End of Pt. 2, Min 45 Max 75
		Gaa'bon appears in a puff of smoke and just stands there.  It is one foot tall and appears sluggish and uninterested in its surroundings.  It slowly glances up at you as you give it your orders.
		
		"Ya," Gaa'bon states in its drawl and then slowly walks through the tunnel wall.
		
		After a few minutes, it returns and tells you exactly where the spring lies.
		*goto Safe_Tunnel
	*if ((companion_type="water elemental") and (companion_name!="None")) #Tell ${companion_name}, your water elemental, to seal the breach.
		You watch as ${companion_name} steps toward the water and then flows into it.  $!{companion_heshe} is gone for several minutes, but the water doesn't stop.  Eventually, ${companion_heshe} returns.  $!{companion_heshe} could probably increase the flow, but it's the earth that's the problem, since that is what's allowing the water to fall into the tunnel, and ${companion_name} has no control over that element.
		*goto Tunnel_Event_loop
	*if ((companion_type="earth elemental")and (companion_name!="None")) #Tell ${companion_name}, your earth elemental, to seal the breach.
		You watch as ${companion_name} melds into the earth walls of the tunnel near the pouring water.  The dirt solidifies very slowly into stone and then spreads, like melted wax, toward the hole.  The pouring water becomes less and less…and then stops altogether.  The water in the tunnel will take a day or two to drain away completely, but your soldiers can work in the mud until it's clear.
		*goto After_Protect_Event
	*if (mount_type="forest worm") #Get your forest worm, ${mount_name}, to help dig a new tunnel.
		$!{mount_heshe} can't tell where the water lies any better than your soldiers, meaning that several exploratory tunnels still have to be dug.  Fortunately, the digging process is much quicker with ${mount_name}'s help.
		*goto Safe_Tunnel_nowords
	*if (class_seer=1) #As a seer, divine where the water lies.
		You don't need a silly forked stick to work your powers.  You simply close your eyes and wait for the vision to come.  You suddenly see the exact shape and size of the spring and now know exactly which direction your soldiers need to dig.
		*goto Safe_Tunnel
	*if (class_monk=4) #As a monk, astrally project yourself through the rock and find which direction would be the safest to dig.
		You sit down in the tunnel with your legs crossed and meditate.  The miners aren't sure what to make of you, but knowing that you are a monk, they suspect that you are thinking about the situation.  You release yourself from your body and pass through the tunnel walls.  When you return, you feel confident that you know exactly where the spring lies.
		*if (showstats)
			*line_break
			(Perception +2)
		*set perception +2
		*label Safe_Tunnel
		
		Your insights limit the time it takes to dig a new tunnel, but the delay is still bothersome.
		*label Safe_Tunnel_nowords
		*if (showstats)
			*line_break
			(Army Delays +1)
		*set army_delays +1
		*goto After_Protect_Event
	#Look carefully at the rock and the land formations around the area as you try to guess which way would be safest to dig.
		*if (geography<80)
			Unfortunately, you can't tell any more than anyone else.
			*if (showstats)
				(Needed 80 Geography)
			*goto Tunnel_Event_loop
		You can see the way the hills are, where the rock lies and which way the waters flow.  You feel confident that you know which way would be safest to tunnel.
		*if (showstats)
			*line_break
			(Geography +2)
		*set geography +2
		*goto Safe_Tunnel
	#Tell the miners to fill in the tunnel and dig around the spring, regardless of the delays it will cause.
		The cold weather is going to take a heavy toll on your troops, but the tunnel needs to be completed and your soldiers can't dig through water.  At least the water had come in slowly and nobody had been killed.  You hope that they won't have to detour too much to get around the spring.
		*if (showstats)
			*line_break
			(Army Delays +3)
		*set army_delays +3
		*goto After_Protect_Event

*label Machines_Event
"It's sabotage!" one of the engineers shouts as he enters the command tent.

"We're ruined!" another yells, following closely behind.

It takes a few minutes for you to get the full story from the men and women who are building your siege engines.  Eventually, you learn that all five copies of an essential arithmetic book have gone missing.  The book is filled with the tables of values concerning sinusoidal angles of elevation, torque tension settings, adjacent side distances and other things.  Without the book, the siege engines will be too inaccurate and dangerous to use.  Selina must have several saboteurs in your camp to have stolen all five books without getting caught.
*label Machines_loop
*choice
	#Question the master engineers whose books were stolen.
		Each of the five master engineers had guarded their copies with great care.  Thick lock boxes, traps and magical deterrents had all been used, but the thieves had still gotten away with the books.
		*if (class_thug>=3)
			One of them looks a little nervous.  You have seen this look before during your work as a money collecting thug.  It's clear that he's holding out on you.
			*if (showstats)
				*line_break
				(Perception +3)
			*set perception +3
			*choice
				#Beat the answers out of the man.
					Your fist only makes contact with the engineer a few times before he is telling you everything.
					*label Sabateur_Tell_All
					He tells you that a man bought his arithmetic book for a ridiculous sum of money.  The man is still hiding with your soldiers.  From there, the rest of the story comes out.  He is one of six people working for Selina.  The group managed to steal the other four books, but the fifth was held in such a strong lock box that they were forced to purchase it.  With the books back, no time is lost.
					*label Deal_With_Sabateurs
					*choice
						#Hang the traitors.
							Your soldiers waste no time setting up a gallows and hanging those responsible.  Knowing that the saboteurs are dead makes everyone feel better.
							*label Sabateurs_Dealth_With
							*if (showstats)
								*line_break
								(Army Morale +3)
							*set army_morale +3
							*goto After_Protect_Event
						#Put the traitors into a cell to await trial.
							Your prison isn't more than a cage, but they won't get out.  Knowing that the saboteurs are captured makes everyone feel much better.
							*if (showstats)
								*line_break
								(Good +5 and Army Morale +3)
							*set good +5
							*set army_morale +3
							*goto Sabateurs_Dealth_With
				#Threaten the man with torture.
					As you describe what you intend to do to the engineer, he blanches and begins to shake.  It only takes a few descriptive sentences until the story pours from his lips.
					*goto Sabateur_Tell_All
				#Torture the man.
					The engineer screams as you do many terrible things to his body.  The noise of his confession fills the camp, setting everyone's teeth on edge.
					*if (showstats)
						*line_break
						(Evil +3)
					*set good -3
					
					*goto Sabateur_Tell_All
		*else
			*if (showstats)
				(Needed 3 Levels in Thug)
			*goto Machines_loop
	#Ask the engineers if they can finish the siege engines without the book.
		"No, Your Highness," they say, aghast at the thought.  "If we set the tensions wrong, the machines could explode and kill our own soldiers.  And, if we get them right, we would have no way of knowing how to aim them to hit our targets.  We would waste all of our ammunition, falling short or shooting too far."
		*goto Machines_loop
	#Examine the empty lock boxes where each book was held.
		*if (class_seer=1)
			You close your eyes and concentrate.  Your soldiers expect you to be looking for physical clues, but as a seer, you have other ways to search.  You have a vision.  You see the thief who stole the book and follow him in your mind's eye.  He leads you to the others and soon you know where the books and saboteurs are.
			*goto Deal_With_Sabateurs
		*if (class_ranger>0)
			You search for signs of the thefts, and within a few minutes, you have an enormous collection of clues.  Bent grass, finger prints and the scuffs of a boot.  You track the signs through the army camp,
			*if (class_ranger=1)
				but unfortunately, you lose the trail.  There are just too many conflicting tracks to search through.
				*if (showstats)
					(Needed 2 Levels in Ranger)
				*goto Machines_loop
			which takes every trick you know to see through the heavy traffic area.  Eventually, you reach the tent of a common soldier and find the books hidden in a chest.  From there, it only takes a few pointed questions to get the names of the thieves themselves.
			*goto Deal_With_Sabateurs
		You search for any clues or signs, but such tracking knowledge is beyond your skills.
		*if (showstats)
			(Needed 2 Levels in Ranger)
		*goto Machines_loop
	#Speak to the Thieves Guild about the missing books.
		*if (class_thief=4)
			You speak to the necessary people and wait for the answers.  As the Guildmaster, you know that the theft wasn't sanctioned, but that doesn't mean you can't find out who did it.  The Guild always investigates unauthorized heists in order to protect their interests, and in this situation, your interest in the matter is very large.  It doesn't take long before your contacts deliver the names of all of the men and women involved.
			*goto Deal_With_Sabateurs
		*if (class_thief=0)
			You ask around, but you have trouble even finding someone from the Guild.
			*if (gillgale_inparty)
				${gillgale_name} is also unable to find someone to speak with, having cut ties with the Thieves Guild a long time ago.
			Perhaps if you had been in a city, you could have found out, but being in an army camp, locating the Thieves Guild is tricky business.
			*if (showstats)
				(Needed a Level in Thief)
			*goto Machines_loop
		*if (class_thief=1)
			Unfortunately, being a lowly cutpurse within the Guild, you have no pull.
		*if (class_thief=2)
			Unfortunately, being only a mid-level burglar within the Guild, you have no pull.
		*if (class_thief=3)
			Despite being a high-ranking thief within the Guild, you can't get the information you are looking for.
		You have no way of learning if the Guild was even involved with the thefts, let alone finding out who stole the books.
		*if (showstats)
			(Needed 4 Levels in Thief)
		*goto Machines_loop
	#Help the engineers to write down all of the values they can recall from memory.
		*if (class_sage=3)
			Your work as a sage makes you an ideal candidate for such a difficult task.  You have scribed tomes before and you have seen the arithmetic book in question.  Utilizing the collective knowledge of the master engineers, you are able to help jog their memories enough to create a crude copy of the missing book for them to use.
			*goto After_Protect_Event
		*if (devices<60)
			The engineers smile condescendingly at you and talk to you as though you are a child who has wandered into an adult conversation.  They tell you that the books are the product of years of calculations and that they can't simply "recall" what was written in them.
			*if (showstats)
				(Needed 60 Devices)
			*goto Machines_loop
		At first, they think that such an activity is the height of foolishness.  Fortunately, some of the engines are already complete and their measurements can be used on the others.  In addition, collectively many of the other numbers are recalled and soon you have a decent makeshift arithmetic book that they can use with
		*if (devices>=80)
			only a little delay.
			*if (showstats)
				*line_break
				(Devices +2 and Army Delays +1)
			*set devices +2
			*set army_delays +1
			*goto After_Protect_Event
		*else
			less delay than it would have taken to get a new book.
			*if (showstats)
				(Needed 80 Devices)
				*line_break
				(Army Delays +2)
			*set army_delays +2
			*goto After_Protect_Event
	*if (class_dragonrider=1) #Fly ${mount_name}, your dragon, back to Ludd to get a copy of the book they need.
		You take to the skies and ${mount_name} beats ${mount_hisher} wings.  The countryside whizzes past as you eat up the distance quickly.  It's amazing how much faster you are able to move compared to your army.  You find Lord Tovor who wastes no time in getting your hands on the needed arithmetic book.  You fly back right away, forgoing sleep in your effort to reduce the delay.  Your engineers are thankful when you put the book into their hands for them to finish the machines.
		*if (showstats)
			*line_break
			(Geography +3 and Army Delays +1)
		*set geography +3
		*set army_delays +1
		*goto After_Protect_Event
	#Send a rider back to Ludd to find another book, knowing that the delays will be unavoidable.
		You choose the best rider you have and send her with a spare horse.  She will ride them both to death, if she has to.  Once in Ludd, another soldier will do the same coming back with the book.  The waste of time for a single book is galling, but your engineers tell you that there is no other option.
		*if (showstats)
			*line_break
			(Army Delays +3)
		*set army_delays +3
		*goto After_Protect_Event
	
*label Ram_Event
"It warped!" one of your soldiers says in frustration one morning.  "The ram, Your Highness.  It took a lot of work to find the biggest tree around.  The thing is enormous.  We cut off all the branches and charred it all to make it less susceptible to fire.  But, the thing is bending like a banana.  It ain't natural.  Must be enemy magic at play."

Sure enough, the ram has been curved into uselessness and no longer even fits in the cradle designed to transport it to the front gates.
*label Ram_Event_loop
*choice
	*if (class_druid>0) #As a druid, call upon the wood and coax it to turn straight again.
		*if (class_druid=1)
			It takes a while to bend the big log, but you manage to salvage the ram into being useful once more.  The handles, wheels and coverings still need to be made, but you save some time using your nature magic.
			*if (showstats)
				(Needed More Druid Training)
				*line_break
				(Nature +3 and Army Delays +2)
			*set nature +3
			*set army_delays +2
			*goto After_Protect_Event
		*if (class_druid=2)
			It takes a while to bend the big log, but you manage to salvage the ram into being useful once more.  The handles, wheels and coverings still need to be made, but you save a lot of time using your nature magic.
			*if (showstats)
				(Needed More Druid Training)
				*line_break
				(Nature +3 and Army Delays +1)
			*set nature +3
			*set army_delays +1
			*goto After_Protect_Event
		It takes only a few hours to bend the big log, as you salvage the ram into being useful once more.  The handles, wheels and coverings still need to be made, but you save a lot of time using your nature magic.
		*if (showstats)
			*line_break
			(Nature +3)
		*set nature +3
		*goto After_Protect_Event
	*if (class_sage>=1) #As a sage, use a method you read about to curve the ram back to normal.
		You explain the process to the others.  You will need to submerge the ram in water and let it soak.  Then, while it's wet, you will have to tie several ropes to supports and slowly bend it back.  Once it is straight, all you will need to do is let it dry.
		*if (devices<40)
			This process is met with a lot of hesitation.  It is suggested by many that it might take less time to just go out and get a new tree, even if a new cradle must be made to fit it.
			*if (showstats)
				(Needed 40 Devices)
			*goto Ram_Event_loop
		*else
			*if (showstats)
				*line_break
				(Devices +3)
			*set devices +3
			*goto Faster_Tree
	#Help them search for a new tree.
		*if (nature>=70)
			Your knowledge of the woods makes it easier to find the perfect tree, which saves a lot of time since it will fit into the existing cradle.
			*if (showstats)
				*line_break
				(Nature +3)
			*set nature +3
			*label Faster_Tree
			
			Your help reduces the delays substantially, but the extra time needed is still very frustrating.
			*if (showstats)
				*line_break
				(Army Delays +1)
			*set army_delays +1
			*goto After_Protect_Event
		*else
			You search with your troops, but you don't find a suitable tree any faster than your soldiers.
			*if (showstats)
				(Needed 70 Nature)
			*goto Ram_Event_loop
	*if ((companion_name!="None") and (((companion_type="hawk") or (companion_type="raven")) or ((companion_type="owl") or (companion_type="dove")))) #Ask ${companion_name}, your ${companion_type}, to fly over the forests and find a suitable tree.
		The ${companion_type} is able to cover great distances and finds a large tree much faster than your soldiers could have done.
		*goto Faster_Tree
	*if ((jacejess_inparty) and (soulburner_knowledge)) #Listen to ${jacejess_name}'s solution.
		"I could use my powers," ${jacejess_name} says.  "It would cost me more energy than I possess, but…I could use someone else's."
		
		You know that the innocent person ${jacejess_heshe} drains will be killed.  You know that this wouldn't be simply another war casualty; this would be murder.  Although it might be worth it to save the delays.
		*choice
			#Say, "Yes, do what is necessary."
				${jacejess_name} places ${jacejess_hisher} slender hands on the warped ram.  $!{jacejess_hisher} eyes turn bright white as ${jacejess_heshe} uses the knowledge learned in the Academy's forbidden book to syphon the energy from an unsuspecting source.  In the end, it doesn't kill a single person…it kills three.  The soldiers are found dead nearby, the veins of their bodies black and evil looking.  The ram itself is perfectly straight and you dispose of the bodies without the troops realizing what the cost had been.
				*if (showstats)
					*line_break
					(Evil +10)
				*set good -10
				*goto After_Protect_Event
			#Say, "No, we will find another way."
				${jacejess_name} nods to you with relief clearly visible in ${jacejess_hisher} eyes.
				*if (showstats)
					*line_break
					(${jacejess_name} Relationship +5 and Good +5)
				*set jacejess_relationship +5
				*set good +5
				*goto Ram_Event_loop
	#Tell the soldiers to start over, regardless of the delays it will cause.
		The current ram is useless.  You don't know how Selina did it, but it can't be used.  They will just have to find another big tree and cut it down.  Unfortunately, they will also either need to build a new cradle or modify the existing one to fit the new log.
		*if (showstats)
			*line_break
			(Army Delays +3)
		*set army_delays +3
		*goto After_Protect_Event

*label After_Protect_Event

It is late at night when you hear the noise coming from inside your personal tent, awakening you from a deep sleep.
*if (lover_exists)
	${lover_name} isn't with you tonight, having taken a late shift with the night watch.
*if ((prisonchild_inparty) and (prisonchild_job="kitchen"))
	${prisonchild_name} is
	*if (lover_exists)
		also
	absent, spending the night with the Priests of the Light.  Since ${prisonchild_heshe} had begun working in the temple kitchens, ${prisonchild_heshe} spent all ${prisonchild_hisher} days and most of ${prisonchild_hisher} nights in the temple now.
You are lying on your cot with a blanket tucked up to your neck.
*choice
	#Roll quickly out of bed.
		*if ((prisonchild_inparty) and (prisonchild_job="alone"))
			You roll out of bed and on to your feet.  A grunt comes from across the room.
			*label Prisonchild_Saviour
			You see two shapes struggling next to your bed.  One of them is a full-grown man with a knife in his hands.  On his back is a much smaller shape.  You see that ${prisonchild_name} has jumped onto the man's back and is stabbing him with a small knife!  The would-be assassin falls to the ground and ${prisonchild_name} rolls free with a snarl on ${prisonchild_hisher} face.  Your guards rush in, alerted by the noise.  Everyone is upset by the silent assailant who managed to sneak into the heart of your camp and nearly kill you.  There is no doubt that the assassin was sent by Selina.
			
			"$!{prisonchild_heshe} got lucky," General Vale says gruffly, although you hear a note of respect in his voice.  "If ${prisonchild_heshe} is going to stay in your room all day and night, ${prisonchild_heshe} might as well serve a purpose.  A personal bodyguard to the ${princeprincess} needs to be trained properly and will need a better weapon."
			
			At first you wonder if the general is simply congratulating ${prisonchild_name}, but true to his word, General Vale has his best soldiers begin training ${prisonchild_name} with various weapons.  Instead of becoming upset by the intrusions, as ${prisonchild_name} was with the servants, ${prisonchild_heshe} accepts the visiting soldiers with a serious calm, practising everything that is taught to ${prisonchild_himher}.  One day you are surprised to see the silent child give you a shy smile while gripping a short sword on ${prisonchild_hisher} hip.  This is the most expression you have ever seen from ${prisonchild_himher}.
			*if (showstats)
				*line_break
				(${prisonchild_name} Relationship +7)
			*set prisonchild_relationship +7
			*goto After_Assassin_Attempt
		You roll out of bed just as a knife drives down toward you.
		*if (agility<60)
			It catches you across the side instead of through the heart.
			*set health -20
			*if (showstats)
				(Needed 60 Agility)
				*line_break
				(Health -20 to ${health} / 100)
			*goto Assassin_2
		It slams into the mattress where you had been sleeping, digging deep into the stuffing.
		*if (showstats)
			*line_break
			(Agility +2)
		*set agility +2
		*goto Assassin_2
	*if ((((companion_type="spider") or (companion_type="mouse")) or (companion_type="toad")) and (companion_name!="None")) #${companion_name}, your ${companion_type}, woke you early enough to see what was happening.
		Your tiny familiar suddenly sends an enormous feeling of pain toward you as ${companion_heshe} is stepped on!  A larger familiar would have been seen and walked around, but poor ${companion_name} is overlooked and the intruder doesn't see ${companion_himher} in time.
		*if ((prisonchild_inparty) and (prisonchild_job="alone"))
			A moment later and a grunt comes from across the room.
			
			*goto Prisonchild_Saviour
		*goto Assassin_2
	#Reach out and grab at the noise.
		*if ((prisonchild_inparty) and (prisonchild_job="alone"))
			You reach out, but before you can grab the noise maker, a grunt comes from across the room.
			*goto Prisonchild_Saviour
		You are startled to catch a knife coming directly toward your chest.
		*if ((strength<60) and (unarmed<60))
			The blade cuts your skin, but you manage to hold it from piercing your heart.
			*set health -20
			*if (showstats)
				(Needed 60 Strength or 60 Unarmed)
				*line_break
				(Health -20 to ${health} / 100)
			*goto Assassin_2
		You hold the hand of the person trying to stab you, preventing them from ramming the knife into your heart.  They pull free of your grip and step back.
		*if (showstats)
			*line_break
			(Strength +1 and Unarmed +1)
		*set strength +1
		*set unarmed +1
		*goto Assassin_2
	#Look around to see what is happening.
		*if ((prisonchild_inparty) and (prisonchild_job="alone"))
			*goto Prisonchild_Saviour
		You see the dull flash of a blade just in time to move out of the way as it
		*if (perception<60)
			slashes into your side instead of your heart.
			*set health -20
			*if (showstats)
				(Needed 60 Perception)
				*line_break
				(Health -20 to ${health} / 100)
			*goto Assassin_2
		slams into the mattress where you had been sleeping.
		*if (showstats)
			*line_break
			(Perception +2)
		*set perception +2
		*goto Assassin_2

*label Assassin_2
*choice
	*if (sword) #Pick up your sword and attack the man.
		*label Blade_Attack_Assassin
		The assassin clearly isn't ready for your quick attack.  Your blade slides deeply into his neck before he can bring his short blade up to stop you.  Your guards rush into your tent.
		*if (showstats)
			*line_break
			(Blades +2)
		*set blades +2
		*goto Assassin_Dead
	*if (dagger) #Pull out your dagger and stab the man.
		*goto Blade_Attack_Assassin
	#Punch the man.
		Your fist connects solidly with the man's chin.
		*if (unarmed>=50)
			He falls to the ground unconscious as the guards rush in.
		*if (unarmed<50)
			He staggers back as the guards rush in.  A few sword swings later and the man falls to the ground dead.
		*if (showstats)
			*line_break
			(Unarmed +2)
		*set unarmed +2
		*goto Assassin_Dead
	#Cast a spell to throw the man across the tent.
		You say the words quickly and raise your hand.
		*if (magic>=50)
			The man is lifted off the floor as he sails backward through the air.  He lands on the ground with a thud as your guards rush into the tent.
		*if (magic<50)
			Although the spell miscasts, your guards rush into the tent and kill the man with their swords, having been alerted by your casting.
		*if (showstats)
			*line_break
			(Magic +2)
		*set magic +2
		*goto Assassin_Dead
	#Call out to your guards.
		The man looks around in surprise as your soldiers rush into the tent.  They make short work of the assassin with their swords.
		*goto Assassin_Dead
		
*label Assassin_Dead

Your guards are amazed that the man snuck into the heart of your camp under their watchful eyes.  Selina's hired assassin was very skilled and you realize that you are lucky to be alive.
*if (companion_name!="None")
	${companion_name} takes the attempt on your life very personally, since it all happened before ${companion_heshe} could do anything to help you.
*if ((prisonchild_inparty) and (prisonchild_job="kitchen"))
	${prisonchild_name} is very upset.  Although ${prisonchild_heshe} still doesn't speak, ${prisonchild_heshe} shows the most expression you've seen yet as ${prisonchild_heshe} looks you over for injuries.  You notice for the first time that ${prisonchild_heshe} is wearing a pair of holy symbols, one dedicated to Auriel and the other to Lucien.
*goto After_Assassin_Attempt

*label After_Assassin_Attempt

Your soldiers have been like a big group of needy children as they clamour for your attention.  They constantly need to be fed, entertained and disciplined.  You sit in your command tent with piles of reports heaped upon your desk as you struggle to keep the entire campaign organized.
*temp tweaks_paid_food false
*label Last_Army_Tweaks_loop
*gosub Check_Army_Stats
*choice
	#Tell General Vale to send home the weakest soldiers in order to save food.
		*if (army_size<30)
			"Your Highness," General Vale says.  "We have no weak soldiers to send home.  We need every person we have."
			*if (showstats)
				(Needed 30 Army Size)
			*goto Last_Army_Tweaks_loop
		"As you wish, Your Highness," he says.
		*if (showstats)
			*line_break
			(Army Size -10 and Army Food +10)
		*set army_food +10
		*set army_size -10
		*goto Last_Army_Tweaks_loop
	#Command your soldiers to work double-shifts to gather more food.
		*if (army_power<30)
			"Your Highness," General Vale says.  "The soldiers simply can't work any harder."
			*if (showstats)
				(Needed 30 Army Power)
			*goto Last_Army_Tweaks_loop
		"Your Highness," General Vale says.  "Our soldiers need their rest.  The extra shifts will affect their fighting prowess."
		*choice
			#Say, "We need the food.  Relay the order."
				"As you wish," General Vale says.
				
				You can see that he is right.  Your soldiers look tired as they range far and wide to scavenge for food while still working on the ${siege_type}.
				*if (showstats)
					*line_break
					(Army Power -10 and Army Food +10)
				*set army_power -10
				*set army_food +10
				*goto Last_Army_Tweaks_loop
			#Say, "Okay, cancel the order."
				The general nods as you rescind the order.
				*goto Last_Army_Tweaks_loop
	*if (army_food>10) #Increase everyone's food rations.
		You hear cheers come from all over the camp as word spreads that the meals will be larger.  Despite the fact that the soldiers are marching to battle, the basic need for good food is still a great motivator.
		*if (showstats)
			*line_break
			(Army Food -10 and Army Morale +10)
		*set army_food -10
		*set army_morale +10
		*goto Last_Army_Tweaks_loop		
	*if (army_power>10) #Tell your commanders to reduce the time spent training and give the soldiers more freedom.
		General Vale frowns at this command, but he understands your motivation.  The troops need to be ready for battle, but they also need personal time to cope with the stress and difficulties of the long march.
		*if (showstats)
			*line_break
			(Army Power -10 and Army Morale +10)
		*set army_power -10
		*set army_morale +10
		*goto Last_Army_Tweaks_loop
	#Tell your commanders to send home anyone with a bad attitude.
		*if (army_size<20)
			General Vale reports that the commanders didn't find very many people to send home.  With such a small army, every person capable of holding a sword was needed.
			*if (showstats)
				(Needed 20 Army Size)
				*line_break
				(Army Morale +2)
			*set army_morale +2
		The mood around camp improves immediately.  It's amazing how a few pessimistic bad apples can make a whole army feel terrible.  By sending these people away, everyone feels much better.
		*if (showstats)
			*line_break
			(Army Size -10 and Army Morale +10)
		*set army_size -10
		*set army_morale +10
		*goto Last_Army_Tweaks_loop
	#Command your officers to take personal items away from your soldiers to sell for food.
		*if (army_morale<30)
			"Your Highness," General Vale says after a few days of trying this.  "The soldiers don't trust you and they're hiding their valuables from us."
			*if (showstats)
				(Needed 30 Army Morale)
			*goto Last_Army_Tweaks_loop
		Your troops are very upset at your actions as jewellery, tobacco pouches, extra clothing and other things are sold to the nearby villages.  These emergency "taxes" are all recorded so that they can be paid back in the future, but this doesn't make your army any happier.  New food is suddenly found as farmers bring in hidden reserves, eager to make a large profit from your troops' misery.
		*if (showstats)
			*line_break
			(Army Morale -10 and Army Food +10)
		*set army_morale -10
		*set army_food +10
		*goto Last_Army_Tweaks_loop
	*allow_reuse *selectable_if (gold>=300) #Tell the quartermaster to increase the soldiers' pay, enhancing your army's morale.  (Needs 300 Gold)
		A few hundred gold doesn't go very far when paying an entire army, but using your own money gives the soldiers a few coins in their pocket right away, which makes them a lot happier.
		*if (showstats)
			*line_break
			(Gold -300 and Army Morale +10)
		*set gold -300
		*set army_morale +10
		*goto Last_Army_Tweaks_loop
	*allow_reuse *selectable_if (gold>=300) #Spread the word that you will pay extra for food.  (Needs 300 Gold)
		The
		*if (tweaks_paid_food)
			increased reward does even better.
		*if (tweaks_paid_food=false)
			reward does wonders.
		*set tweaks_paid_food true
		Not only do the farmers and citizens from the villages nearby take the reward, even your own soldiers sell back any extra food they had been hoarding.
		*if (showstats)
			*line_break
			(Gold -300 and Army Food +10)
		*set gold -300
		*set army_food +10
		*goto Last_Army_Tweaks_loop
	*allow_reuse *selectable_if (gold>=300) #Hire any mercenaries who are willing to pledge their swords to your cause, increasing your army's power.  (Needs 300 Gold)
		Many mercenaries have already enlisted in your army, but many others had been waiting for this announcement.  They are eager to get paid and willing to fight, but they don't want to do the general labour that your commanders order the enlisted soldiers to do.  Although they won't dig ditches or work on the ${siege_type}, they will be helpful during the battle itself.
		*if (showstats)
			*line_break
			(Gold -300 and Army Power +10)
		*set gold -300
		*set army_power +10
		*goto Last_Army_Tweaks_loop
	*allow_reuse *selectable_if (gold>=300) #Hire any camp followers to join your army, increasing your army's size.  (Needs 300 Gold)
		The camp followers include old men and women, injured soldiers and children previously thought to be too young.  General Vale bites his lip and frowns as he accepts these people into your ranks.  Every person who can hold a sword will be valuable during the final battle.
		*if (showstats)
			*line_break
			(Gold -300 and Army Size +10)
		*set gold -300
		*set army_size +10
		*goto Last_Army_Tweaks_loop
	*allow_reuse #Consult with your advisers.
		You gather your war council into your command tent to get their opinions.
		*temp gave_advice false
		*if (army_size<40)
			*set gave_advice true
			
			"We could use some more soldiers," Captain ${branbrinn_name} says.
		*if (army_power<40)
			*set gave_advice true
			
			"Our troops are weak," General Vale says.  "They need to be stronger."
		*if (army_morale<40)
			*set gave_advice true
			
			"I have seen that your troops are not happy," Naistalan, the half-elf, says.
		*gosub Check_Army_Stats
		*if (army_delays<0)
			*set army_delays 0
		*set food_needed army_delays*3
		*set food_needed +10
		*if (food_needed<army_food)
			*set gave_advice true
			
			"We might not have enough food to feed our soldiers," the quartermaster of your army says.
		*if (gave_advice=false)
			They all reassure you that things are going well.
		*goto Last_Army_Tweaks_loop
	#Make no more changes as you wait for the ${siege_type} to be finished.
		*goto After_Last_Tweaks_ns

*label After_Last_Tweaks_ns
The end of the war is nearly upon you, for better or worse.
*if ((siege_type="tunnel") and (dwarf_help=2))
	The dwarven miners are invaluable as they complete the long tunnel under the walls of Tornassa.
	*label Big_Help
	*if (showstats)
		*line_break
		(Army Delays -1)
	*set army_delays -1
	*gosub Check_Army_Stats
	*goto Check_Defenses
*if ((siege_type="machines") and (gnome_help=2))
	The gnome engineers are invaluable as they complete the siege engines you will use to destroy the walls of Tornassa.
	*goto Big_Help
*if ((siege_type="ram") and (orc_help=2))
	The half-orc berserkers are invaluable as they complete the ram you will use to destroy the gates of Tornassa.
	*goto Big_Help
The day finally arrives when your soldiers complete the
*if (siege_type="tunnel")
	long tunnel under the walls of Tornassa.
*if (siege_type="machines")
	siege engines you will use to destroy the walls of Tornassa.
*if (siege_type="ram")
	ram you will use to destroy the gates of Tornassa.
*label Check_Defenses
*if (temp_defences=false)
	
	Selina's scouts or spies must have noticed something.  You hear your soldiers shouting and a runner reports that the gates have opened and enemy soldiers are pouring forth.  By the time you get your things and reach a vantage point to see the attack, it is already over.
	*if (showstats)
		*line_break
		(Needed Army Camp Defences)
	
	You see the last of Selina's soldiers retreating back behind the walls.  They hadn't struck too deeply into your camp, but the celebratory mood that came from finishing the ${siege_type} is spoiled by the deaths of your soldiers.
	*if (showstats)
		
		(Army Size -5 and Army Morale -5)
	*set army_size -5
	*set army_morale -5
	*gosub Check_Army_Stats
	*goto Winter_Is_Here
*else
	*goto Winter_Is_Here

*label Winter_Is_Here

*if (its_snowing)
	The bitter winter snow continues to fall as the temperature plummets even further.
	*if (army_delays>=7)
		*comment army_delays 0 - 11
		Frostbite, exposure and fatigue keep plaguing you as well.  More soldiers don't wake up in the morning and more of them desert in the middle of the night.
		*if (army_morale>=50)
			*if (showstats)
				(Needed 7 or Fewer Army Delays)
				*line_break
				(Army Size -5 and Army Power -5)
			*set army_size -5
			*set army_power -5
			*goto Last_Wintertime_Check2
		*else
			*if (showstats)
				(Needed 7 or Fewer Army Delays and 50 Army Morale)
				*line_break
				(Army Size -7 and Army Power -7)
			*set army_size -7
			*set army_power -7
			*goto Last_Wintertime_Check2
	*else
		*goto Last_Wintertime_Check2
*else
	*if (army_delays>=5)
		General Vale's worst nightmare began several days ago as the bitter winter snow started to fall.
	*if (army_delays<5)
		General Vale's worst nightmare begins the day you finish the ${siege_type} as the bitter winter snow starts to fall.
	*if (army_delays>=5)
		*comment army_delays 0 - 11
		The dangers of frostbite, exposure and fatigue suddenly become a reality as your soldiers trudge through the cold to complete their daily tasks.  The weak and loyal don't wake up on the coldest mornings, but the strong and disloyal simply desert.
		*if (army_morale>=50)
			*if (showstats)
				(Needed 4 or Fewer Army Delays)
				*line_break
				(Army Size -5 and Army Power -5)
			*set army_size -5
			*set army_power -5
			*goto Last_Wintertime_Check2
		*else
			*if (showstats)
				(Needed 4 or Fewer Army Delays and 50 Army Morale)
				*line_break
				(Army Size -7 and Army Power -7)
			*set army_size -7
			*set army_power -7
			*goto Last_Wintertime_Check2
	*else
		*goto Last_Wintertime_Check2
		
*label Last_Wintertime_Check2
*gosub Check_Army_Stats
*if (army_delays<0)
	*set army_delays 0
*set food_needed army_delays*3
*set food_needed +10

*if (army_food<=0)
	Your starving army continues to hunger for the food it doesn't have.  There will be many rumbling stomachs during the final battle.
	*goto Check_Last_Food
*if (army_food<=food_needed)
	Your army eats the last of the food stores before the final battle.
	*goto Check_Last_Food
Your army will begin the final battle with food left over.
*label Check_Last_Food
*if (army_delays>=1)
	One last time, you are frustrated by the delays you experienced since those wasted days meant you needed even more food.
	*if (showstats)
		(Increased Army Delays Increases Army Food Needed)
*gosub Army_Use_Food
*if (army_food>0)
	*choice
		#Give the troops extra food the night before the battle.
			*if (army_food>=10)
				The soldiers cheer your generosity as they enjoy the extra food.
				*if (showstats)
					*line_break
					(Army Food -10 and Army Morale +10)
				*set army_food -10
				*set army_morale +10
				*goto Final_Battle
			*else
				The soldiers cheer your generosity as they enjoy the extra food.
				*if (showstats)
					*line_break
					(Army Food -${army_food} and Army Morale +${army_morale})
				*set army_morale +army_food
				*set army_food 0
				*goto Final_Battle
		#Don't make any changes to the food rations.
			You have no promises that there will be food for your troops within Tornassa.  Although, if your final assault fails, the extra food will likely be scavenged by the enemy forces.  At least you won't be alive to see it.
			*goto Final_Battle
*else
	*goto Final_Battle

*label Final_Battle

The morning of the last battle of what would become known as the Siege of Tornassa is very cold.  The tree branches are all laced with frost and thick clouds threaten to dump snow over friend and foe alike.  The knowledge that there will be a great amount of killing today helps warm everyone's
*if (necromancer_known=false)
	blood.
*if (necromancer_known)
	blood, except for the undead, who show no emotion at all.  They stand in a rotting group all by themselves, ready to serve your will.
*comment t_army:  -5 halflinghelp, -5 academy, and -23 with towers and all allies, -15 with help, +3 warmaster
*comment t_army:  max of -51 to 49/100 and health 50/100 and demons used

*if (siege_type="ram")
	*goto Ram_Final
*if (siege_type="tunnel")
	*goto Tunnel_Final
*comment only "machines" left
*goto Machines_Final

*label Ram_Final
The ram is enormous.  The tree that had been used must have been centuries old, to the elves' dismay.  The cradle it rests in is huge and the wheels are gigantic.  Your soldiers will be able to push the thing right up to the gates and with a few gigantic swings, bash through the doors.  The biggest weakness will be enemy archers.  To counter this, a leather apron had been built to drape over the dozens of soldiers who will push it.  Many extra soldiers will also hide under the apron behind the ram, using its protection to get to the wall so they can be the first to pour through the gates.

*if (companion_name!="None")
	*if (((companion_type="spider") or (companion_type="mouse")) or ((companion_type="toad") or (companion_type="rat")))
		Your soldiers don't notice ${companion_name} curled up in your pocket.
		*goto AfterCompanion_Text
	Your soldiers find ${companion_name} unnerving to be in such tight quarters with, but you simply can't leave ${companion_himher} behind.
	*goto AfterCompanion_Text
*label AfterCompanion_Text
Your companions have all agreed to come with you under the leather cover. 
*if (theothea_inparty)
	${theothea_name} eagerly holds one of the handles of the ram.  $!{theothea_hisher} muscles will be put to good use.
*if (gillgale_inparty)
	${gillgale_name} stands with the attacking soldiers, holding two short blades, one in each hand.
*if (karlkarla_inparty)
	${karlkarla_name} is clearly nervous as ${karlkarla_heshe} holds ${karlkarla_hisher} bow in ${karlkarla_hisher} hands while flinching away from the thick cover over ${karlkarla_hisher} head.
*if (branbrinn_inparty)
	Captain ${branbrinn_name}'s longsword is sheathed and ${branbrinn_heshe} holds one of the handles to push.
*if (peterpetra_inparty)
	${peterpetra_name}'s eyes are closed in prayer, ${peterpetra_hisher} hands resting on the ram, ready to push once the signal is given.
*if (jacejess_inparty)
	${jacejess_name}'s hands are empty, but you know that ${jacejess_hisher} Soulburning magic is always ready.
*if (squire_name!="None")
	${squire_name} takes hold of one of the handles, ready to do ${squire_hisher} part.
*if (kratog_hired)
	Kratog, the giant, is too big to take a handle and just pushes the ram from the back.

*if (prisonchild_inparty)
	${prisonchild_name} had waved goodbye that morning
	*if (prisonchild_job="alone")
		when you left your room.
	*if (prisonchild_job="kitchen")
		before joining the healers of the temple.
General Vale and Archmage Cumari wish you good luck before returning to their positions with the rest of the army.
*gosub LastChanceMoreHealth	
*temp holding_ram false
*choice
	#Take one of the handles of the ram.
		*set holding_ram true
		The grip is cool to the touch.  The moment the archers and infantry begin to move, you hear the signal and start pushing with all of your strength.
		*if (strength>=80)
			The ram moves along well with your help and the soldiers notice your contribution.
			*if (showstats)
				*line_break
				(Strength +3 and Army Morale +10)
			*set strength +3
			*set army_morale +10
			*goto Final_Ram_2
		*if (strength>=60)
			The ram moves along well with your help and the soldiers notice your contribution.
			*if (showstats)
				(Needed 80 Strength for Greater Bonus)
				*line_break
				(Army Morale +5)
			*set army_morale +5
			*goto Final_Ram_2
		*if (strength>=35)
			The ram moves along well with your help and the soldiers notice your contribution.
			*if (showstats)
				(Needed 60 Strength for Greater Bonus)
				*line_break
				(Army Morale +3)
			*set army_morale +3
			*goto Final_Ram_2
		The ram moves along well despite your help.  You see some stronger soldiers standing among those who aren't pushing.  They are obviously wondering why you have taken one of the handles instead of them.
		*if (showstats)
			(Needed 35 Strength)
			*line_break
			(Army Morale -3)
		*set army_morale -3
		*gosub Check_Army_Stats
		*goto Final_Ram_2
	#Stand among the soldiers under the leather cover behind the ram.
		*set holding_ram false
		You can't see very much, but when the signal is given, the cover lurches forward as those pushing move the ram.  You and the other troops under the apron move along with it.
		*goto Final_Ram_2

*label Final_Ram_2

*if (mount_name!="None")
	${mount_name}, your ${mount_type}, must be left behind, since ${mount_heshe} won't fit under the cover.
You can hear the screaming of dying men and women around you as they distract the archers on the wall.  You step over the body of a dead soldier, seeing that she is one of your own.  Another soldier shrieks suddenly as an arrow gets under the leather cover and sticks into his shin.  You are nearly at the wall when you hear the splashing sound of liquid falling onto the cover above you.  There is a mighty whooshing noise as the liquid is set aflame!  The heat is intense as the ram catches fire.
*if (showstats)
	*line_break
	(Army Size -5)
*set army_size -5
*gosub Check_Army_Stats
*label Ram_Fire_loop
*choice
	*if (class_alchemist>0) #You don't worry, having been sure to coat the cover with an alchemical mixture.
		The fire burns out almost immediately and the heat goes away.  You had been uncertain of the binding agent you had used in the mixture, but now that you have seen it in action, you are pleased with the results.  The covering is completely fireproof.
		*goto Final_Ram_3
	*if ((companion_name!="None") and (companion_type="water elemental")) #Tell ${companion_name} to put out the fire.
		Your water elemental is clearly uncertain if ${companion_heshe} is up to the task.  $!{companion_heshe} squeezes out from under the cover and splashes water across the burning surface.  Unfortunately, the liquid that had been used as an accelerant mixes with the water and continues to burn anyway!
		*goto Ram_Fire_loop
	*if ((companion_name!="None") and (companion_type="fire elemental")) #Tell ${companion_name} to put out the fire.
		You can tell that ${companion_name} didn't even realize the danger of the fire until you asked ${companion_himher} to help.  The fire elemental flows around the soldiers and floats above the leather cover.  The fire suddenly grows smaller and winks out as ${companion_heshe} absorbs it into ${companion_himher}self.  Satisfied that the danger is gone, ${companion_name} returns to your side.
		*goto Final_Ram_3
	*if (holding_ram) #Release the handle so you can cast a spell to help fight the fire above you.
		You let go of the ram, causing it to slow slightly as the other soldiers are forced to pick up the slack.
		*if (showstats)
			*line_break
			(Army Morale -3)
		*set army_morale -3
		
		*goto Ram_Magic_Fire_Stop
	*if (holding_ram=false) #Cast a spell to help fight the fire above you.
		*label Ram_Magic_Fire_Stop
		You weave your hands in an intricate pattern.  It's difficult to cast with the smoke, heat and closely pressed people all around you.
		*if (magic>=80)
			The cover suddenly glows blue and the heat disappears as you freeze the flames above.  The fire dies as ice coats the leather.
			*if (showstats)
				*line_break
				(Magic +2)
			*set magic +2
			*goto Final_Ram_3
		*else
			A blue light begins to spread from your hands, but the flaming liquid over the cover is too large to be stopped by your magic.
			*if (showstats)
				(Needed 80 Magic)
			
			*goto Ram_Burn_Anyway
	*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and ((demonstone_xiatta_used=false) and (demonsummoner))) #Summon Xi'atta and tell it to freeze the fire.
		*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
		*comment: End of Pt. 2, Min 45 Max 75
		*if (holding_ram)
			You continue to push with one hand while fumbling in your runebag with the other.
		Xi'atta appears under the cover, scaring everyone.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
		
		"Yes, ${mastermistress}," Xi'atta says as it lays its small hands on the leather cover above you.
		
		Blue frost spreads from its fingers and the heat stops immediately.  Xi'atta frowns as the fire continues to burn.  It lets go for a moment and zips through the soldiers' legs as it flies out of the enclosure.  From above, it finishes freezing the liquid and the leather, extinguishing the flame.  The archers on the wall see the meddling demon and fire an arrow through Xi'atta's small body.  The demon falls to the cover with a thump and then vanishes as it returns to its own realm.
		*set demonstone_xiatta_used true
		*goto Final_Ram_3
	#Let the fire burn, knowing that there is nothing that can be done for it.
		*label Ram_Burn_Anyway
		A flame retardant mixture had been spread across the cover to help keep the fire at bay, but it could only do so much.  The heat causes the leather to turn hard and crack.  Smoke begins to fill the enclosed area and the soldiers start to cough.  As some of the soldiers fall to the ground choking to death, others take their place.
		*if (nature>=65)
			*if (showstats)
				*line_break
				(Army Size -3 and Army Power -3)
			*set army_size -3
			*set army_power -3
			*goto Final_Ram_3
		*if (class_monk>=2)
			As a monk, you have great control over your body.  You stop breathing and slow your heart rate to preserve the oxygen already in your system so that you don't need to breath the smoke.  Unfortunately, the others can't do the same.
			*if (showstats)
				(Needed 65 Nature)
				*line_break
				(Army Size -5 and Army Power -5)
			*set army_size -5
			*set army_power -5
			*goto Final_Ram_3
		Your own lungs burn from the heat and the smoke.
		*if (endurance>70)
			*if (showstats)
				(Needed 65 Nature)
				*line_break
				(Endurance +2, Army Size -5 and Army Power -5)
			*set endurance +2
			*set army_size -5
			*set army_power -5
			*goto Final_Ram_3
		*set health -20
		*if (health<=0)
			*if (showstats)
				(Needed 65 Nature, 70 Endurance or Level 2 Monk)
				*line_break
				(Health -20 to 0 / 100)
			*goto Final_Battle_Knocked_Out
		*if (showstats)
			(Needed 65 Nature or Level 2 Monk)
			*line_break
			(Army Size -5, Army Power -5 and Health -20 to ${health} / 100)
		*set army_size -5
		*set army_power -5
		*goto Final_Ram_3

*label Final_Ram_3
*gosub Check_Army_Stats

The mighty ram is pulled back and then pushed forward in its cradle.  The head of the ram makes contact with the gate with a resounding crash.  The second strike causes a large crack to appear across the enormous door.  The third strike makes the metal bars reinforcing the door bend.  The fourth causes the hinges in which the door is mounted to shake violently and small puffs of stone dust appear around where they are mounted.  The gate can't stand against such abuse and soon it is smashed out of the way.  The ram is dropped and everyone grabs their weapons while screaming defiance and rushing forward.  You and your companions surge forward along with everyone else.
*set t_army -3
*if (showstats)
	*line_break
	(Tornassa Army -3 to ${t_army} / 100)
*goto Courtyard

*label Tunnel_Final
The key to tunnelling under the walls is secrecy.  This is why you and your army get ready behind canvas screens that have been erected for just this purpose.
*if (temp_defences=false)
	Although Selina attacked you when you finished the tunnels and may even suspect what you are doing, she likely doesn't know the specifics.
You stand at the entrance of the tunnel with your troops.  It has been calculated that the tunnel's other end is only a few feet short of the surface…on the other side of the wall.

*if (theothea_inparty)
	${theothea_name} stands near you, holding ${theothea_hisher} enormous warhammer.
*if (gillgale_inparty)
	${gillgale_name} is ready for the close quarter fighting, holding two short blades, one in each hand.
*if (karlkarla_inparty)
	${karlkarla_name} is clearly nervous.  Fighting in a tunnel isn't good for an archer, but ${karlkarla_heshe} holds a long hunting knife and is ready to join you anyway.
*if (branbrinn_inparty)
	Captain ${branbrinn_name} has ${branbrinn_hisher} longsword in hand and ${branbrinn_hisher} chainmail gleams in the torchlight.
*if (peterpetra_inparty)
	${peterpetra_name}'s eyes are closed in prayer while ${peterpetra_heshe} holds ${peterpetra_hisher} morningstar tightly in one hand.
*if (jacejess_inparty)
	${jacejess_name}'s hands are empty, but you know that ${jacejess_hisher} Soulburning magic is always ready.
*if (squire_name!="None")
	${squire_name} holds ${squire_hisher} sword tightly, ready to join you.

*if (prisonchild_inparty)
	${prisonchild_name} had waved goodbye that morning
	*if (prisonchild_job="alone")
		when you left your room.
	*if (prisonchild_job="kitchen")
		before joining the healers of the temple.
	The tunnels are no place for a child.
General Vale and Archmage Cumari wish you good luck before leaving to join the rest of your army.  They will be leading the remainder of your troops for the final assault.
*if (kratog_hired)
	Kratog, the giant, was too big for the tunnel, so he went with the other troops.
*gosub LastChanceMoreHealth	

You and your companions lead the troops underground.  The tunnel is dark as you soon stand in the front ranks with your soldiers, just behind the miners.
*if (mount_name!="None")
	${mount_name}, your ${mount_type}, is on the surface.  The tunnel is too small to bring ${mount_himher}.
*if (companion_name!="None")
	${companion_name}, your ${companion_type}, watches from beside you.
Shovels and picks work furiously ahead of you.  When the first chunk of dirt falls from above, sunlight streams into the
*if (vampire=false)
	tunnel.
*if (vampire)
	tunnel, causing you to flinch as it irritates your vampiric skin.
You had considered attacking at night, but in the end, it was decided that the noise of people during the day would hide the last of the digging and give you the larger surprise.  Within moments, large chunks of earth are falling into the tunnel and your soldiers begin to rush forward and crawl upward through the choking dirt.
*choice
	#Wait for some of the soldiers to get through.
		Your soldiers pour around you, pulling dirt aside and making the hole wider as others climb through.  You can hear swords striking metal and the shouts of pain.  The battle has begun!
		*if ((army_size>=20) and (army_power>=40))
			*set t_army -7
			*if (showstats)
				*line_break
				(Tornassa Army -7 to ${t_army} / 100 and Army Size -3)
			*set army_size -3
			*goto Final_Tunnels_Let_Others_Lead
		*else
			*set t_army -3
			*if (showstats)
				(Needed 20 Army Size and 40 Army Power for Greater Bonus)
				*line_break
				(Tornassa Army -3 to ${t_army} / 100 and Army Size -3)
			*set army_size -3
			*label Final_Tunnels_Let_Others_Lead
			
			After a few minutes you see that the hole has become as large as the rest of the tunnel.  You move forward and climb upward.  You find yourself standing in the middle of the courtyard.
			*goto Final_Tunnels_2
	#Be the first to climb through.
		You push dirt away as you seem to swim through the ground and claw your way upward.  A large cobblestone slides through the dirt toward you, threatening to crush you!
		*choice
			#Push the cobblestone aside.
				*if (strength>=50)
					You take hold of the large stone and lower it down to the waiting soldiers around you.  With the obstacle clear, you step up into the sun.
					*if (showstats)
						*line_break
						(Strength +2)
					*set strength +2
					*label Final_Tunnels_You_Lead
					
					Your troops cheer when they see you, taking heart at your presence as the enemy soldiers surround you all.  Both sides swing their weapons in earnest.  The battle has begun!
					*if ((army_size>=20) and (army_power>=40))
						*set t_army -7
						*if (showstats)
							*line_break
							(Army Size -3, Army Morale +7 and Tornassa Army -7 to ${t_army} / 100)
						*set army_size -3
						*set army_morale +7
						*goto Final_Tunnels_2
					*else
						*set t_army -3
						*if (showstats)
							(Needed 20 Army Size and 40 Army Power for Greater Bonus)
							*line_break
							(Army Size -3, Army Morale +7 and Tornassa Army -3 to ${t_army} / 100)
						*set army_size -3
						*set army_morale +7
						*goto Final_Tunnels_2
				*else
					The cobblestone is much heavier than you thought, pushing you back down into the dark hole.  Your arms and legs are cut up against the rocks before your fellow soldiers pull the stone off of you.  You climb past the obstacle and up into the sun.
					*set health -20
					*if (showstats)
						(Needed 50 Strength)
						*line_break
						(Health -20 to ${health} / 100)
					*goto Final_Tunnels_You_Lead
			#Dodge the falling cobblestone.
				*if (agility>=50)
					The large stone slides past you as you squeeze against the dirt.  Once it is past, you climb up through the hole and into the sun.
					*if (showstats)
						*line_break
						(Agility +2)
					*set agility +2
					*goto Final_Tunnels_You_Lead
				*else
					There is nowhere to dodge as the large stone pushes you back down into the dark hole.  Your arms and legs are cut up against the rocks before your fellow soldiers pull the stone off of you.  You climb past the obstacle and up into the sun.
					*set health -20
					*if (showstats)
						(Needed 50 Agility)
						*line_break
						(Health -20 to ${health} / 100)
					*goto Final_Tunnels_You_Lead
			*if (theothea_inparty) #Let ${theothea_name} grab the big stone for you.
				The large mountain-${theothea_manwoman} has no trouble grabbing the heavy stone and holding it off of you.  All by ${theothea_himher}self, ${theothea_heshe} passes the cobblestone down to the other soldiers.  You climb upward into the sun with your friends close behind you.
				*goto Final_Tunnels_You_Lead
			#Cast a spell to hold the stone in place.
				The spell itself isn't very difficult.  What causes the trouble is the fact that you have to cast it quickly.
				*if (magic>=80)
					The large stone hovers in place as you climb past it into the sun above.  When you are certain there is nobody beneath it, you release your hold on it and it falls safely into the dark.
					*if (showstats)
						*line_break
						(Magic +2)
					*set magic +2
					*goto Final_Tunnels_You_Lead
				*else
					Your incantation stops abruptly as the large stone pushes you back down into the dark hole.  Your arms and legs are cut up against the rocks before your fellow soldiers pull the stone off of you.  You climb past the obstacle and up into the sun.
					*set health -20
					*if (showstats)
						(Needed 80 Magic)
						*line_break
						(Health -20 to ${health} / 100)
					*goto Final_Tunnels_You_Lead

*label Final_Tunnels_2
*gosub Check_Army_Stats

The fight is fast and furious.  You have caught the enemy soldiers by surprise, but you are also standing within the bailey of their fortified city.  You can see the main gates a short distance away, but your soldiers are surrounded and can't easily open it to let the rest of your troops in.  The great din of battle outside the walls reaches your ears and you know that General Vale has ordered your soldiers outside to attack the city.  If the gate isn't opened quickly, they will not survive to see the full battle.
*if (karlkarla_inparty)
	${karlkarla_name} sheaths ${karlkarla_hisher} hunting knife and draws ${karlkarla_hisher} bow as your other companions ready themselves too.
*label Final_Tunnels_loop
*choice
	*if (sword) #Draw your sword and charge toward the gate with your soldiers.
		*if (blades>=80)
			You lead them forward, killing any soldier who gets within reach.
			*gosub With_Help_Raise_blurb
			*set t_army -3	
			*if (showstats)
				*line_break
				(Army Size -5, Blades +2 and Tornassa Army -3 to ${t_army} / 100)
			*set army_size -5
			*set blades +2
			*goto Courtyard
		*else
			You lead them forward, trying to fight the soldiers off.  Unfortunately, a blade comes in under your guard and slices across your stomach.
			*set health -20
			*if (health<=0)
				*if (showstats)
					(Needed 80 Blades)
					*line_break
					(Health -20 to 0 / 100)
				*goto Final_Battle_Knocked_Out
			*gosub With_Help_Raise_blurb
			*set t_army -3	
			*if (showstats)
				*line_break
				(Army Size -5, Health -20 to ${health} / 100 and Tornassa Army -3 to ${t_army} / 100)
			*set army_size -5
			*goto Courtyard
	#Push your way toward the gate with your troops.
		*if ((unarmed>=80) or (strength>=80))
			You lead them forward, pushing the enemy out of your way.  
			*gosub With_Help_Raise_blurb
			*set t_army -3	
			*if (showstats)
				*line_break
				(Unarmed +2, Strength +2, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*set unarmed +2
			*set strength +2
			*goto Courtyard
		*else
			You lead them forward, trying to push your way through.  Unfortunately, a blade comes in under your guard and slices across your stomach.
			*set health -20
			*if (health<=0)
				*if (showstats)
					(Needed 80 Unarmed or 80 Strength)
					*line_break
					(Health -20 to 0 / 100)
				*goto Final_Battle_Knocked_Out
			*gosub With_Help_Raise_blurb
			*set t_army -3	
			*if (showstats)
				*line_break
				(Health -20 to ${health} / 100, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*goto Courtyard
	#Cast a spell to turn the winch from where you stand.
		*if (magic>=80)
			The winch begins to turn and the gate slowly rises as the enemy soldiers watch helplessly.  Your troops fight to keep you safe as you cast your spell.  You soon see many of your soldiers squeezing under the gate and rushing to join your defence.  Within moments you have breached the city.
			*set t_army -3	
			*if (showstats)
				*line_break
				(Magic +2, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*set magic +2
			*goto Courtyard
		*else
			You cast the spell, but it's not strong enough to raise the gate.  While you are casting, your troops are dying on both sides of the wall.
			*if (showstats)
				(Needed 80 Magic)
				*line_break
				(Army Size -3)
			*set army_size -3
			*gosub Check_Army_Stats
			*goto Final_Tunnels_loop
	*if ((bow) or (class_elementalarcher>0)) #Tell your soldiers to charge the gate while you give cover fire with your bow.
		*if (archery>=80)
			You kill enemy soldier after enemy soldier as they try to stop your troops from surging forward.  
			*gosub With_Help_Raise_blurb
			*set t_army -3	
			*if (showstats)
				*line_break
				(Archery +2, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*set archery +2
			*goto Courtyard
		*else
			You fire many arrows at the enemy soldiers, but not all of them hit their targets.  One of the soldiers you miss gets too close and a blade comes in under your guard and slices across your stomach.
			*set health -20
			*if (health<=0)
				*if (showstats)
					(Needed 80 Archery)
					*line_break
					(Health -20 to 0 / 100)
				*goto Final_Battle_Knocked_Out
			*gosub With_Help_Raise_blurb
			*set t_army -3	
			*if (showstats)
				*line_break
				(Health -20 to ${health} / 100, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*goto Courtyard
	*if (class_warmaster>0) #Strategically order your troops into a wedge formation and drive them toward the gate.
		*label Tunnels_Warmaster
		It works perfectly, allowing your troops to drive toward the gate with minimal losses on your side.  They fight valiantly to hold off attacking soldiers as the large winch is turned.  You see many of your soldiers squeezing under the gate and rushing to join your defence.  Within moments you have breached the city.
		*set t_army -3
		*if (showstats)
			*line_break
			(Tornassa Army -3 to ${t_army} / 100)
		*goto Courtyard
	#Command your soldiers to charge the gate.
		*if (class_warmaster>0)
			*goto Tunnels_Warmaster
		Every second that passes means that you have more soldiers at your disposal as they continue to surge out of the tunnel.  Unfortunately, the enemy is able to send several times that number at you in all directions.  Many of your troops are killed as you push toward the gate, but in the end, you make it.  They fight valiantly to hold off attacking soldiers as the large winch is turned.  You see many of your soldiers squeezing under the gate and rushing to join your defence.  Within moments you have breached the city.
		*if (((army_size>=20) and (army_power>=40)) and (army_morale>=50))
			*set t_army -3
			*if (showstats)
				*line_break
				(Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*goto Courtyard
		*else
			*set t_army -3
			*if (showstats)
				(Needed 20 Army Size, 40 Army Power and 50 Army Morale)
				*line_break
				(Tornassa Army -3 to ${t_army} / 100 and Army Size -10)
			*set army_size -10
			*goto Courtyard

*label With_Help_Raise_blurb
With your help, your army is able to expand your perimeter until your soldiers can reach the winch as well.  There are casualties on both sides, but you continue to push forward.  Your companions immediately begin to crank the winch as you fight, holding the enemy at bay as the gate slowly raises.  You soon see many of your soldiers squeezing under the gate and rushing to join your defence.  Within moments you have breached the city.
*return

*label Machines_Final
There is no need for secrecy as you stand with the largest catapult in your arsenal.  The soldiers have named the monstrous device the Behemoth…a fitting moniker.  Your troops gather around it, ready to push it forward.  An enormous boulder sits within its cup, ready to be thrown against the walls.

*if (theothea_inparty)
	${theothea_name} stands near you, holding ${theothea_hisher} enormous warhammer.
*if (gillgale_inparty)
	${gillgale_name} is holding two short blades, one in each hand.
*if (karlkarla_inparty)
	${karlkarla_name} is clearly nervous as ${karlkarla_heshe} holds ${karlkarla_hisher} bow in ${karlkarla_hisher} hands.
*if (branbrinn_inparty)
	Captain ${branbrinn_name} has ${branbrinn_hisher} longsword in hand and ${branbrinn_hisher} chainmail gleams in the sunlight.
*if (peterpetra_inparty)
	${peterpetra_name}'s eyes are closed in prayer while ${peterpetra_heshe} holds ${peterpetra_hisher} morningstar tightly in one hand.
*if (jacejess_inparty)
	${jacejess_name}'s hands are empty, but you know that ${jacejess_hisher} Soulburning magic is always ready.
*if (squire_name!="None")
	${squire_name} holds ${squire_hisher} sword, ready to join you.

*if (prisonchild_inparty)
	${prisonchild_name} had waved goodbye that morning
	*if (prisonchild_job="alone")
		when you left your room.
	*if (prisonchild_job="kitchen")
		before joining the healers of the temple.
General Vale and Archmage Cumari wish you good luck before returning to their positions.
*gosub LastChanceMoreHealth	

You and your companions watch as the infantry lead the way, followed by the archers.  The engineers and soldiers who will push the catapults wait anxiously for the signal to begin moving.
*if (mount_name!="None")
	You sit upon ${mount_name}, your ${mount_type}.
*if (companion_name!="None")
	${companion_name}, your ${companion_type}, watches from beside you.
You wait until your advance forces have reached the designated distance and then give the signal.

The catapults all begin moving at once, rolling quickly forward and into position.  The Behemoth moves forward with the others and you
*if (mount_name!="None")
	ride
*if (companion_name!="None")
	march
alongside it.
You can hear the screaming of dying men and women ahead of you as the siege engines finally reach their destination.  Well out of archer range, the engineers begin cutting ropes and pulling levers.  Enormous boulders soar silently through the air and then hit the walls with a deafening crash.  Selina is clearly ready for this as the side gates open to allow her cavalry access to the field.  They swing out wildly to the sides, threatening to flank the siege engines as the bulk of the army fights closer to the walls.  Unlike the fast horses of Ludd, these animals are wearing full metal barding and their riders are well armoured.
*if (kratog_hired)
	You see Kratog, the giant, among the troops ready to stop the onslaught.
*set t_army -3
*if (showstats)
	*line_break
	(Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
*set army_size -5
*gosub Check_Army_Stats
*choice
	*if (sword) #Draw your sword and defend the Behemoth.
		The steel-plated cavalry is difficult to defend against as they ride fast and hard.  Their goal is to kill your engineers and set fire to your catapults.
		*if (blades>=80)
			Your blade strikes swiftly, sliding deeply between the joints of the enemy's armour.  Several catapults are destroyed, but the Behemoth stands tall.
			*set t_army -3	
			*if (showstats)
				*line_break
				(Blades +2, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*set blades +2
			*goto Machines_Final_Behometh
		*else
			Your blade has trouble against the armoured riders and many of the catapults around you are destroyed.  Unfortunately, a blade comes in under your guard and slices across your stomach.
			*set health -20
			*if (health<=0)
				*if (showstats)
					(Needed 80 Blades)
					*line_break
					(Health -20 to 0 / 100)
				*goto Final_Battle_Knocked_Out
			With your help, your army manages to keep the Behemoth safe.
			*set t_army -3
			*if (showstats)
				*line_break
				(Health -20 to ${health} / 100, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*goto Machines_Final_Behometh
	#Try to drag the riders from their saddles.
		*if (unarmed>=80)
			The heavily armoured soldiers move quickly on horseback, but their steel plate mail makes them very clumsy.  As you pull them from their steeds, they have difficulty getting back onto their feet and your soldiers are able to kill them quickly.  Several catapults are destroyed, but the Behemoth stands tall.
			*set t_army -3
			*if (showstats)
				*line_break
				(Unarmed +2, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*set unarmed +2
			*goto Machines_Final_Behometh
		*else
			The heavily armoured soldiers cling tightly to their horses and swing their swords to prevent you from getting close enough to knock them off their steeds.  A blade comes in under your guard and slices across your stomach.
			*set health -20
			*if (health<=0)
				*if (showstats)
					(Needed 80 Unarmed)
					*line_break
					(Health -20 to 0 / 100)
				*goto Final_Battle_Knocked_Out
			Many catapults are destroyed, but with luck, the Behemoth stands tall.
			*set t_army -3
			*if (showstats)
				*line_break
				(Health -20 to ${health} / 100, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*goto Machines_Final_Behometh
	#Cast chain lighting against the metal-clad riders.
		The conductive armour of the enemies makes your spell a sure thing.  
		*if (magic>=80)
			The blue electricity arcs from your hands and into the first of the riders.  From there, it streaks out onto the next and the next.  The entire first wave crash to the ground at your feet as both horse and rider are killed by your magic.  Several catapults are destroyed, but the Behemoth stands tall.
			*set t_army -3
			*if (showstats)
				*line_break
				(Magic +2, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*set magic +2
			*goto Machines_Final_Behometh
		*else
			Unfortunately, one of the brave riders throws themselves at you and before you can cut off your spell, the electricity surges into you as well.
			*set health -20
			*if (health<=0)
				*if (showstats)
					(Needed 80 Magic)
					*line_break
					(Health -20 to 0 / 100)
				*goto Final_Battle_Knocked_Out
			Many catapults are destroyed, but with luck, the Behemoth stands tall.
			*set t_army -3
			*if (showstats)
				*line_break
				(Health -20 to ${health} / 100, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*goto Machines_Final_Behometh
	*if ((bow) or (class_elementalarcher>0)) #Defend the Behemoth with your bow.
		*if (archery>=80)
			Your arrows manage to find the joints between the steel plates, dropping the enemy soldiers from their large horses.  Several catapults are destroyed, but the Behemoth stands tall.
			*set t_army -3
			*if (showstats)
				*line_break
				(Archery +2, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*set archery +2
			*goto Machines_Final_Behometh
		*else
			You fire many arrows at the mounted riders, but their steel armour repels the majority of your shots.  One of the soldiers you miss gets too close and a blade comes in under your guard and slices across your stomach.
			*set health -20
			*if (health<=0)
				*if (showstats)
					(Needed 80 Archery)
					*line_break
					(Health -20 to 0 / 100)
				*goto Final_Battle_Knocked_Out
			Many catapults are set ablaze, but with your help, the Behemoth stands tall.
			*set t_army -3
			*if (showstats)
				*line_break
				(Health -20 to ${health} / 100, Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*goto Machines_Final_Behometh
	*if (class_warmaster>0) #Use your skills as a War Master to strategically arrange the defence of the Behemoth.
		*label Machines_Warmaster
		You tell your infantry and archers to wait as the riders get closer and closer.  The tension builds as the heavily-armoured riders close the distance.  You know that the archers will have trouble finding the gaps between the plates, so you keep them in reserve.  At the last minute, you give the order and the infantry raise their pole arms.  They quickly brace them to the ground, forming a bristly defence.  With the butts of the long spears secured in the ground, the sharpened ends puncture the armour of the riders.  Even the pole arms which don't break through the armour do damage as the riders are lifted from their mounts to crash to the ground.  Once the initial charge is broken, the pole arms are discarded in favour of short blades which quickly kill the injured riders.  You hear a cheer from around you as only a few catapults are set on fire and the Behemoth stands untouched.
		*set t_army -3
		*if (showstats)
			*line_break
			(Tornassa Army -3 to ${t_army} / 100)
		*goto Machines_Final_Behometh
	*if (class_dragonrider>0) #Take to the skies and have ${mount_name} breathe fire upon the advancing riders.
		The steel plates glow bright red as the fire washes over the enemy.  The cooked soldiers and horses inside their metal skins fall to the ground in agony.  Although the enemy manages to destroy a few catapults, the Behemoth is left untouched as you land softly beside it.
		*set t_army -3
		*if (showstats)
			*line_break
			(Tornassa Army -3 to ${t_army} / 100)
		*goto Machines_Final_Behometh
	#Command your troops to defend the Behemoth.
		*if (class_warmaster>0)
			*goto Machines_Warmaster
		You knew that Selina would send cavalry to destroy the siege engines; it was a textbook counter to the big machines.  As such, you kept a contingent of soldiers back to defend.  You watch as they fight to keep the catapults from being set ablaze.
		*if (((army_size>=20) and (army_power>=40)) and (army_morale>=50))
			*set t_army -3
			*if (showstats)
				*line_break
				(Tornassa Army -3 to ${t_army} / 100 and Army Size -5)
			*set army_size -5
			*goto Machines_Final_Behometh
		*else
			*set t_army -3
			*if (showstats)
				(Needed 20 Army Size, 40 Army Power and 50 Army Morale)
				*line_break
				(Tornassa Army -3 to ${t_army} / 100 and Army Size -10)
			*set army_size -10
			*goto Machines_Final_Behometh

*label Machines_Final_Behometh
*gosub Check_Army_Stats

The world had never seen a catapult quite like the Behemoth.  Each boulder that is lobbed toward the city cracks the thick walls and kills many of Selina's soldiers.  Your troops wait down below, ready to rush through the growing hole and into the city itself.
*choice
	#Lead the soldiers into the breach before more of them die at the base of the wall.
		You rush forward with your companions at your side.
		*label Machines_EnterCity_Dismount_If_Needed
		*if (mount_name="None")
			The hole in the wall allows you to enter the city itself.
		*if (mount_name!="None")
			The hole in the wall is a tight squeeze, forcing you to get off ${mount_name} in order to enter the city.
		*goto Courtyard
	#Continue smashing the walls for as long as you can.
		Each boulder lobbed over the walls kills more enemy soldiers.  More boulders explode against towers and battlements.  Unfortunately, your troops are exposed at the base of the wall and there are a few casualties from falling bricks and many more from the enemy archers still on the wall.
		*if (army_size>=20)			
			*set t_army -10
			*if (showstats)
				*line_break
				(Tornassa Army -10 to ${t_army} / 100 and Army Size -10)
			*set army_size -10
			
			It doesn't take long before the enemy soldiers have left the destroyed walls and fallen back into the city.  With no more targets, you and your soldiers march forward.
			*goto Machines_EnterCity_Dismount_If_Needed
		You see that your force is dwindling fast.  You will need your soldiers to breach the inner city, so you are forced to stop firing upon the walls and command your troops to enter the hole.
		*set t_army -5
		*if (showstats)
			(Needed 20 Army Size)
			*line_break
			(Tornassa Army -5 to ${t_army} / 100 and Army Size -5)
			
		*set army_size -5
		*goto Machines_EnterCity_Dismount_If_Needed

*label LastChanceMoreHealth
*if (health>=100)
	*set health 100
	*return
Your injuries haven't healed fully and although the magical healing of the temples has hurried your recovery, you still feel the wear and tear on your body.
*label LastChanceMoreHealth_loop
*choice
	#Speak to the high priests and priestesses in your army and urge them for some stronger healing.
		*if ((((class_priest=4) or (class_cleric=3)) or (class_paladin=1)) and (prisonchild_job!="kitchen"))
			"Of course, your grace," they say as they apply stronger magic to your wounds, causing them to heal at an even faster rate.
			*goto LastChanceMoreHealth_Healed
		"I am sorry," they all say.  "The Gods and Goddesses place limits upon our talents for a reason.  We can ease the pain, but this is all.  We need to save our more powerful blessings for the upcoming war."
		*if (prisonchild_job="kitchen")
			
			As you speak your need to the priests, you are surprised to see young ${prisonchild_name} step forward.  $!{prisonchild_heshe} had been spending a lot of time in the temple kitchens.  Without a word, ${prisonchild_heshe} places a hand over your wounds and looks over to the high priest.  The priest sighs and nods.  The holy man reaches out and says some words to his deity.  You feel a warmth fill you as the powerful magic heals the wounds that a regular priest or priestess could not.  ${prisonchild_name} nods in satisfaction before returning to the kitchens.
			*label LastChanceMoreHealth_Healed
			*set health +20
			*if (showstats)
				*line_break
				(Health +20 to ${health} / 100)
			*return
		*if (showstats)
			(Needed 4 Levels in $!{priestpriestess}, 3 Levels in Cleric, or a Level in Paladin)
		*goto LastChanceMoreHealth_loop
	#Attempt to heal the wounds more thoroughly.
		The clergy had done a good job, but you know that greater divine magic could heal it even more.
		*if (class_priest<3)
			Unfortunately, such powerful magic is not known to you.
			*if (showstats)
				(Needed Level 3 in $!{priestpriestess})
			*goto LastChanceMoreHealth_loop
		*else
			You pray to ${god_name} and feel an even stronger healing envelop you.
			*goto LastChanceMoreHealth_Healed
	#Continue with your plans, despite your injuries.
		Such is the nature of war.  You aren't the only person injured as you prepare for the final battle.
		*if (showstats)
			*line_break
			(Health:  ${health} / 100)
		*return

*label Courtyard
*gosub Check_Army_Stats
*comment t_army:  -5 halflinghelp, -5 academy, and -23 with towers and all allies, -15 with help, +3 warmaster
*comment t_army:  Tunnel -7 and -3, machines -12
*comment t_army:  max of -63 to 37/100 and health 20/100 and demons used

Your soldiers fight the enemy in all directions as you stand in a pocket of calm.  You march forward with the rest of your troops down the main street of Tornassa toward the castle itself to confront Selina and the ${prisoner1_nickname}.  You can see the blackened walls from the fires that burned on the night your parents were murdered, but you can also see the new construction of the repairs.  The castle is fully intact and ready to defend its new inhabitants.  Suddenly, you see the enemy soldiers all back away, suspiciously giving you room to move forward an entire block without any resistance.
*if (warprep_spies="Tornassa")
	A group of six men and women walk out of the buildings toward you.
	
	"Boom!" one of them says with a smile, holding up their hands with their fingers spread.
	*choice
		*if ((bow) or (class_elementalarcher>0)) #Shoot the man with an arrow.
			Your arrow strikes the man in the stomach.  His eyes open widely in surprise.  The soldiers with you begin firing their bows as well and all six people are killed.  Your troops continue forward toward the waiting army without any casualties.
			*if (showstats)
				*line_break
				(Archery +2)
			*set archery +2
			*goto Base_Of_Castle
		*if (sword) #Attack the man with your sword.
			Your blade cuts deeply into the man's neck.  His eyes open widely in surprise.  Your soldiers rush forward and finish off the rest of them without taking a single casualty.
			*label War_Spies_Blades
			*if (showstats)
				*line_break
				(Blades +2)
			*set blades +2
			*goto Base_Of_Castle
		*if (dagger) #Throw your dagger at the man.
			Your blade plunges deeply into the man's throat.  Your soldiers rush forward and finish off the rest of them without taking a single casualty, allowing you to retrieve your dagger.
			*goto War_Spies_Blades
		#Punch the man in the throat.
			Your quick thinking causes the man to sputter without being able to speak.  His eyes open widely in surprise.  Your soldiers rush forward and kill all six of them without taking a single casualty.
			*if (showstats)
				*line_break
				(Unarmed +2)
			*set unarmed +2
			*goto Base_Of_Castle
		#Cast a spell to silence the man before he can say another word.
			You unleash your magic and the man's mouth moves without a sound.  His eyes open widely in surprise.  Your soldiers rush forward and kill all six of them without taking a single casualty.
			*if (showstats)
				*line_break
				(Magic +2)
			*set magic +2
			*goto Base_Of_Castle
		#Hold your hand up so your soldiers don't attack them.
			"It's safe, Your Highness," a woman behind the man says as all six approach with smiles on their faces.  "They were going to fill all of these buildings with barrels of explosives.  They hoped to kill as many of you as they could, if you got this far.  We couldn't get out of the city, so we sabotaged their plans.  The barrels are filled with water and the explosive mixture is safely disposed of."
			*if (showstats)
				*line_break
				(Army Morale +3)
			*set army_morale +3
			
			"It's our spies!" Captain ${branbrinn_name} says.
			
			The six spies join your army as you advance down the street toward the waiting soldiers.
			*goto Base_Of_Castle
*else
	*temp temp_found_door_locked false
	*label War_Spies_Caution_loop
	*choice
		*if (class_seer>0) #A vision forms in your mind….
			You hold up a hand and watch.  The vision shows people carrying heavy barrels into the buildings on both sides.  You guess that this happened several days ago.  Suddenly, the vision catches up to the present and you see a few miserable soldiers lighting the barrels and running out the back doors of the buildings.
			*goto War_Spies_Small_Boom
		*if (companion_type="tanuki") #Look up at ${companion_name} who is sitting on the roof of one of the buildings.
			Your mischievous tanuki gets to its feet and waddles across the roof.  You aren't even sure how ${companion_heshe} got up there.  You hear someone shout in alarm from inside the building.  ${companion_name} waves to someone in the back of the building that you can't see, making you realize that someone is leaving.  Suddenly, the tanuki starts running and jumps off the building!  You catch ${companion_himher} before he falls and take the small creature's warning seriously.
			*goto War_Spies_Small_Boom
		*if (((demonstone_gaabon) and (demonstone_gaabon_used=false)) and (demonsummoner)) #Summon Gaa'bon and have it search the buildings.
			*comment Gaa'bon: Willing: 45, Small Struggle: 55, Against: 65
			*comment: End of Pt. 2, Min 45 Max 75
			Gaa'bon appears in a puff of smoke and just stands there.  It is one foot tall and appears sluggish and uninterested in its surroundings.  It slowly glances up at you.
			
			"Yaaaa?" Gaa'bon asks in its slow drawl.
			
			You tell the demon to look into the buildings.  It walks unhurriedly toward one of them and goes right through the door.  A moment later and you see it moving faster than ever as it passes through the door coming out at a run.
			
			"Explosives!" Gaa'bon yells.
			
			You and your soldiers dive to the ground just as the buildings explode on both sides.  Gaa'bon is thrown across the street in a bloody heap, its carcass popping out of existence as it returns to its own realm to heal.  Several of your soldiers are killed by the blast, but the demon's warning saved many others.  You get back to your feet and continue forward.
			*set demonstone_gaabon_used true
			*goto War_Spies_Small_Boom_No_Words
		#Send a few scouts ahead while holding back your main body.
			The soldiers cautiously approach, but nothing happens.  When they reach the enemy soldiers, some of them fight and some of them rush back to you.  Those who fight are killed to a man.
			*goto War_Spies_Caution_loop
		#Send a few scouts into the buildings while holding back your main body.
			*set temp_found_door_locked true
			The soldiers go to the doors, but they are all locked up tight.  They go to the windows, but those are boarded up just as securely.
			*goto War_Spies_Caution_loop
		*if (temp_found_door_locked) #Unlock one of the doors to the buildings yourself.
			*if (lockpickset=false)
				Without a good set of lockpicks, you have no chance of opening one of the doors.
				*goto War_Spies_Caution_loop
			*if (devices>=70)
				You take out your set of lockpicks and get to work.  You have to move quickly, as your entire army fights behind you and nobody moves down the empty street ahead of you.  The moment the door opens, you see that the building is filled with barrels and you spot a man running out the back door, having lit a small fire under them!
				*if (showstats)
					*line_break
					(Devices +2)
				*set devices +2
				*goto War_Spies_Small_Boom
			You simply don't have enough time, since your entire army is right behind you and fighting for their lives.  You try for a little longer, but have no success.
			*if (showstats)
				(Needed 70 Devices)
			*goto War_Spies_Caution_loop
		#Continue forward cautiously.
			*if (perception>=60)
				You see movement in one of the buildings and suddenly smell the acrid smoke of an incendiary device.
				*if (showstats)
					*line_break
					(Perception +2)
				*set perception +2
				*label War_Spies_Small_Boom
				
				"Get down!" you shout.
				
				Your troops and companions all dive to the ground as the buildings on both sides explode into flames!  Bricks, lumber and debris rain down upon you.  Some of your soldiers are caught in the blast, but you realize that it could have been a lot worse.  The enemy soldiers grin as you get back to your feet and continue forward.
				*label War_Spies_Small_Boom_No_Words
				*if (showstats)
					*line_break
					(Army Size -5 and Army Power -5)
				*set army_size -5
				*set army_power -5
				*goto Base_Of_Castle
			Without any warning, the buildings on both sides of you explode into flames!  Bricks, lumber and debris blast toward you from both directions, knocking you off your feet.
			*set health -20
			*if (health<=0)
				*if (showstats)
					(Needed 60 Perception)
					*line_break
					(Health -20 to 0 / 100)
				*goto Final_Battle_Knocked_Out
			*if (showstats)
				(Needed 60 Perception)
				*line_break
				(Army Size -7, Army Power -7 and Health -20 to ${health} / 100)
			*set army_size -7
			*set army_power -7
			*goto Base_Of_Castle
		#Go around the suspicious street, knowing that you will take heavy casualties.
			Your troops are well-trained and they are also suspicious of the empty street.  Once you get a few people going the long way around, others follow.  Unfortunately, you have to fight many more enemy soldiers as you go.  You see men and women from both sides lying on the ground as you continue forward.
			*if (showstats)
				*line_break
				(Army Size -7 and Army Power -7)
			*set army_size -7
			*set army_power -7
			*goto Base_Of_Castle

*label Base_Of_Castle
*gosub Check_Army_Stats

The royal castle of Tornassa stands before you.  This is where you were born and where you should have grown up.  It is the rightful home to the heir of Daria.  You see the assembled might of Selina's army arrayed across its courtyard.  Your soldiers line up behind you and the fighting slowly ceases as everyone waits for your command.  The enemy army parts as a small group of people advance forward.  You see a woman with straight red hair, intelligent eyes and a short sword on her hip.  It is Selina, the person responsible for poisoning your parents.  Beside her is
*if (prisoner1_name=theothea_name)
	a large
*if (((prisoner1_name=karlkarla_name) or (prisoner1_name=gillgale_name)) or (prisoner1_name=jacejess_name))
	a slender
*if (prisoner1_name=peterpetra_name)
	an athletic
*gosub Prisoner1_Man_Woman
wearing a red cloak.  It's Selina's deadly bodyguard, the ${prisoner1_nickname}.	

"So, we meet at last!" Selina says loudly from behind her soldiers.  "I will only offer you this once.  Surrender now or die!"
*choice
	#Shout, "Never!"
		*if (army_morale<20)
			*goto Mutiny
		"Very well," Selina says as she waves her hand forward.
		*goto All_Out_Battle
	#Sincerely surrender.
		Selina smiles as your soldiers all shift about nervously.
		
		"Tell your soldiers to throw down their weapons and allow themselves to be bound!" Selina says.  "You too."
		*choice
			#Do as Selina asks.
				*if (army_size<30)
					Your small army understands.  You have been defeated and they know that attacking now would only bring more deaths.
				*if (army_size>=30)
					Your large army doesn't understand.  You have come so far and you have a chance to end the threat in a final battle.
				*label Surrender_To_Selina
				Swords, shields and pole arms clatter to the ground as your soldiers disarm themselves.  Your companions do the same.
				*if (theothea_inparty)
					${theothea_name} drops ${theothea_hisher} large hammer.
				*if (gillgale_inparty)
					${gillgale_name} drops both of ${gillgale_hisher} swords.
				*if (karlkarla_inparty)
					${karlkarla_name} drops ${karlkarla_hisher} bow.
				*if (branbrinn_inparty)
					${branbrinn_name} drops ${branbrinn_hisher} longsword.
				*if (peterpetra_inparty)
					${peterpetra_name} drops ${peterpetra_hisher} morningstar.
				
				*label Gave_Up_Battle_Lost
				It is over.  You have lost the Siege of Tornassa.  As your companions and soldiers are bound with chains, Selina orders the ${prisoner1_nickname} to put a special pair of shackles on your wrists.  They are dark black and covered in runes.  The moment they are clamped shut, you feel weak and realize that you can't summon your magic or move freely.  The runes glow bright white as they hold you secure.  You are taken into your family's castle and down the long stairs to the dungeon.  The large iron doors are closed behind you, leaving you completely alone.
				*goto Lost_Battle_In_Cell
			#Say, "No, I want to tell you my terms."
				*if (army_morale<20)
					*goto Mutiny
				"I will grant you no terms.  My offer has expired," Selina says as she waves her hand forward.
				*goto All_Out_Battle

*label Mutiny
Your words go unheeded as your soldiers begin to drop their weapons.  They have had enough.  You watch in amazement as your troops surrender without your consent.
*if (showstats)
	(Needed 20 Army Morale)
*choice
	#Surrender to Selina.
		*goto Surrender_To_Selina
	#Heroically fight, despite the numbers.
		You fight as well as you can, but the superior numbers inexorably wash over you and your companions.  You are struck by an arrow as you see your friends fall around you.  You double over in pain, allowing an enemy soldier to slash you with his sword.  You fall to the ground.
		*if (showstats)
			*line_break
			(Health 0 / 100)
		*set health 0
		*goto Final_Battle_Knocked_Out

*label All_Out_Battle

Selina's army surges forward with a renewed vengeance.  Your own troops rush to meet them.  The bloodshed is enormous as the final battle erupts around you.
*if (army_size<30)
	*label Army_Size_Under_30_End
	Unfortunately, Selina's army is much larger than your own.  You simply don't have enough troops to do any more damage.  You fight as well as you can, but the superior numbers inexorably wash over you and your companions.  You are struck by an arrow as you see your friends fall around you.  You double over in pain, allowing an enemy soldier to slash you with his sword.  You fall to the ground.
	*if (showstats)
		(Needed 30 Army Size)
		*line_break
		(Health 0 / 100)
	*set health 0
	*goto Final_Battle_Knocked_Out
*else
	*goto All_Out_Battle_2

*label All_Out_Battle_2
Your archers fire and your soldiers defend you with their lives.  Swords rend open flesh and arrows pierce deeply into exposed skin.  You see Naistalan briefly as he drops his bow and rushes forward with his sword.
*comment t_army:  max of -66
*temp possible_damage 17
*if (elf_help=2)
	The elves you recruited fight alongside your human troops.
	*set possible_damage +3
*if (orc_help>0)
	Gurstwin growls as she picks up one man and throws him into two others.
	*if (orc_help=1)
		*set possible_damage +3
	*if (orc_help=2)
		*set possible_damage +5
*if (dwarf_help>0)
	Kergith grunts with satisfaction as he buries his dwarven axe into an enemy soldier's stomach.
	*set possible_damage +3
*if (halfling_help>0)
	Yam, the halfling, leaps onto the back of a soldier, his small dagger digging through the man's armour.
	*set possible_damage +4
*if ((theothea_story=10) and (theothea_inparty))
	One of ${theothea_name}'s mountain-men grabs a soldier in each hand, each by the throat, and squeezes.
	*set possible_damage +3
*if (academy_help>0)
	Streaks of fire fly from the hands of the Academy wizards.
	*if (academy_help=1)
		*set possible_damage +3
	*if (academy_help=2)
		*set possible_damage +5
*if (army_power<30)
	*label Army_Power_Under_30_Loss
	But in the end, it simply isn't enough.  You see your army fall to Selina's superior forces.  You fight as well as you can, but to no avail.  You are struck by an arrow as you see your friends fall around you.  You double over in pain, allowing an enemy soldier to slash you with his sword.  You fall to the ground.
	*if (showstats)
		(Needed 30 Army Power)
		*line_break
		(Health 0 / 100)
	*set health 0
	*goto Final_Battle_Knocked_Out
*set t_army-possible_damage
*if (t_army>20)
	*if (showstats)
		(Needed 20 or Under Tornassa Army)
*if (showstats)
	*line_break
	(Tornassa Army -${possible_damage} to ${t_army} / 100 and Army Size -15)
*set army_size -15
*if (t_army<=20)
	*goto Fight_Red
*label Final_Battle_Round1_loop	
*comment t_army:  max of -108
*choice
	*allow_reuse #Try to kill Selina.
		You see Selina standing in the middle of her soldiers with the ${prisoner1_nickname} beside her.  Your eyes meet briefly across the field of battle before she returns her attention to directing her troops.
		*choice
			*if ((karlkarla_inparty) and (infinity_arrow)) #Ask ${karlkarla_name} to shoot Selina with the Infinity Arrow.
				You watch as the slim archer takes a deep breath.  The battle rages all around as ${karlkarla_name} carefully takes out the magical arrow and puts it onto ${karlkarla_hisher} bow string.  $!{karlkarla_heshe} releases the Infinity Arrow and it soars over the battling men and women.  It strikes true, hitting Selina in the chest!  She falls to the ground with a scream of pain.  You see the ${prisoner1_nickname} stand over Selina protectively and glare at you from under ${prisoner1_hisher} red hood.  Selina's army takes many casualties as they panic over the loss of their leader.
				*set selina_hurt true
				*set infinity_arrow false
				*set t_army -15
				*if (showstats)
					*line_break
					(Tornassa Army -15 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (class_elementalarcher=1) #Shoot a fiery arrow at Selina from your Astral Bow.
				You extend your hand and your Astral Bow appears from thin air.  With your other hand, you draw back the shimmering string.  A flaming arrow appears in your hand.  When you release it, the projectile flies over the heads of the battling soldiers and strikes Selina in the chest!  She falls to the ground with a scream of pain.  You see the ${prisoner1_nickname} stand over Selina protectively and glare at you from under ${prisoner1_hisher} red hood.  Selina's army takes many casualties as they panic over the loss of their leader.
				*set selina_hurt true
				*set t_army -15
				*if (showstats)
					*line_break
					(Tornassa Army -15 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (bow) #Shoot an arrow at Selina.
				You carefully release the string and watch as your arrow flies over the battling men and women.	
				*if (archery>=90)
					The arrow flies true, striking Selina in the chest.  She falls to the ground with a scream of pain.  You see the ${prisoner1_nickname} stand over Selina protectively and glare at you from under ${prisoner1_hisher} red hood.  Selina's army takes many casualties as they panic over the loss of their leader.
					*set selina_hurt true
					*set t_army -15
					*if (showstats)
						*line_break
						(Archery +2 and Tornassa Army -15 to ${t_army} / 100)
					*set archery +2
					*goto Final_Army_Battle_Round2
				It lands short, striking harmlessly into the dirt near Selina's feet.  Meanwhile, your troops battle on.
				*set t_army -5
				*if (showstats)
					(Needed 90 Archery)
					*line_break
					(Tornassa Army -5 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			#Cast a spell that will strangle Selina from a distance.
				You raise your hand and cast the spell.  Everyone's body has a natural defence against intrusive magic, but there are ways to counter such things.
				*if (magic>=90)
					You watch as Selina grabs her throat and her eyes bulge.  You see the ${prisoner1_nickname} trying to help her, but to no avail.  Selina's army takes many casualties as they panic over the loss of their leader.
					*set selina_hurt true
					*set t_army -15
					*if (showstats)
						*line_break
						(Magic +2 and Tornassa Army -15 to ${t_army} / 100)
					*set magic +2
					*goto Final_Army_Battle_Round2
				Selina puts her hand to her throat and you can see her cough, but this is all.  Your magic simply isn't strong enough to strangle her from so far away.  Meanwhile, your troops battle on.
				*set t_army -5
				*if (showstats)
					(Needed 90 Magic)
					*line_break
					(Tornassa Army -5 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*allow_reuse #Leave Selina alone for now.
				You turn away from Selina.
				*goto Final_Battle_Round1_loop	
	*allow_reuse #Try to kill the ${prisoner1_nickname}.
		The ${prisoner1_nickname} stands beside Selina, ${prisoner1_hisher} face obscured by ${prisoner1_hisher} red cloak.
		*choice
			*if ((karlkarla_inparty) and (infinity_arrow)) #Ask ${karlkarla_name} to shoot the ${prisoner1_nickname} with the Infinity Arrow.
				You watch as the slim archer takes a deep breath.  The battle rages all around as ${karlkarla_name} carefully takes out the magical arrow and puts it onto ${karlkarla_hisher} bow string.  $!{karlkarla_heshe} releases the Infinity Arrow and it soars over the battling men and women.  It strikes the ${prisoner1_nickname} in the chest!  Despite the perfect shot, ${prisoner1_heshe} simply pulls the expended arrow from ${prisoner1_hisher} chest and snaps it in half.  Meanwhile, your men battle on.
				*set infinity_arrow false
				*set red_health -35
				*comment Red was at minimum 100, now 65
				*set t_army -5
				*if (showstats)
					*line_break
					(${prisoner1_name} Health -35 to ${red_health} / 100 and Tornassa Army -5 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (class_elementalarcher=1) #Shoot a fiery arrow at the ${prisoner1_nickname}.
				You extend your hand and your Astral Bow appears from thin air.  With your other hand, you draw back the shimmering string.  A flaming arrow appears in your hand.  When you release it, the projectile flies over the heads of the battling soldiers and strikes the ${prisoner1_nickname} in the chest!  Despite the perfect shot, ${prisoner1_heshe} simply pats out the fire that has burned ${prisoner1_hisher} chest and continues to stand there.  Meanwhile, your troops battle on.
				*set red_health -35
				*comment Red was at minimum 100, now 65
				*set t_army -5
				*if (showstats)
					*line_break
					(${prisoner1_name} Health -35 to ${red_health} / 100 and Tornassa Army -5 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (bow) #Shoot an arrow at the ${prisoner1_nickname}.
				You carefully release the string and watch as your arrow flies over the battling men and women.	
				*if (archery>=90)
					The arrow flies true, striking the ${prisoner1_nickname} in the chest.  Despite the perfect shot, ${prisoner1_heshe} simply pulls the arrow free and lets it fall to the ground while continuing to stand next to Selina.  Meanwhile, your troops battle on.
					*set red_health -35
					*comment Red was at minimum 100, now 65
					*set t_army -5
					*if (showstats)
						*line_break
						(Archery +2, Tornassa Army -5 to ${t_army} / 100 and ${prisoner1_name} Health -35 to ${red_health} / 100)
					*set archery +2
					*goto Final_Army_Battle_Round2
				It lands short, striking harmlessly into the dirt.  Meanwhile, your troops battle on.
				*set t_army -5
				*if (showstats)
					(Needed 90 Archery)
					*line_break
					(Tornassa Army -5 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			#Cast a spell that will strangle the ${prisoner1_nickname} from a distance.
				You raise your hand and cast the spell.  Everyone's body has a natural defence against intrusive magic, but there are ways to counter such things.
				*if (magic>=90)
					You watch as the ${prisoner1_nickname} grabs ${prisoner1_hisher} throat.  Despite the obvious damage that the spell is doing to the
					*gosub Prisoner1_Man_Woman
					${prisoner1_heshe} somehow stays on ${prisoner1_hisher} feet until the spell fades.  Meanwhile, your troops battle on.
					*set red_health -35
					*comment Red was at minimum 100, now 65
					*set t_army -5
					*if (showstats)
						*line_break
						(Magic +2, ${prisoner1_name} Health -35 to ${red_health} / 100 and Tornassa Army -5 to ${t_army} / 100)
					*set magic +2
					*goto Final_Army_Battle_Round2
				The ${prisoner1_nickname} puts a hand to ${prisoner1_hisher} throat for a moment, but that is all.  Your magic simply isn't strong enough to strangle ${prisoner1_himher} from so far away.  Meanwhile, your troops battle on.
				*set t_army -5
				*if (showstats)
					(Needed 90 Magic)
					*line_break
					(Tornassa Army -5 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*allow_reuse #Leave the ${prisoner1_nickname} alone for now.
				You turn away from the ${prisoner1_nickname}.
				*goto Final_Battle_Round1_loop
	*allow_reuse #Join the battle against the enemy soldiers.
		You know that victory can only come by defeating Selina's army.
		*choice
			*if (class_elementalarcher=1) #Rain ice arrows down upon the enemy soldiers.
				You extend your hand and your Astral Bow appears from thin air.  With your other hand, you draw back the shimmering string.  An ice arrow appears in your grip.  You aim it high over ahead and release it.  It shatters into many smaller deadly projectiles, killing several men and women at once.  Without a pause, you continue to fire the frozen arrows at your enemies.
				*set t_army -12
				*if (showstats)
					*line_break
					(Tornassa Army -12 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (bow) #Shoot arrows at the enemy.
				Your hand is a blur as you launch arrow after arrow at the enemy soldiers.	
				*if (archery>=90)
					Every hit is a death.  Your troops become more confident and fight harder as they are led by your positive example.
					*set t_army -10
					*if (showstats)
						*line_break
						(Archery +2 and Tornassa Army -10 to ${t_army} / 100)
					*set archery +2
					*goto Final_Army_Battle_Round2
				*if (archery>=60)
					The majority of your arrows strike true.  Your troops become more confident and fight harder as they are led by your positive example.
					*set t_army -7
					*if (showstats)
						(Needed 90 Archery for Greater Bonus)
						*line_break
						(Tornassa Army -7 to ${t_army} / 100)
					*goto Final_Army_Battle_Round2
				It's difficult to miss, since the enemy soldiers are so closely packed together.  Your troops become more confident and fight harder as they are led by your positive example.
				*set t_army -5
				*if (showstats)
					(Needed 60 Archery)
					*line_break
					(Tornassa Army -5 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			#Cast a spell to summon a meteor storm into the enemy soldiers.
				They aren't true meteors, of course.  The science behind meteors is complex and difficult to understand.  Instead, you open a passage into the Elemental Planes of Earth and Fire.
				*if (magic>=90)
					Many men and women are killed as the flaming balls of stone fall upon your enemy.
					*set t_army -12
					*if (showstats)
						*line_break
						(Magic +2 and Tornassa Army -12 to ${t_army} / 100)
					*set magic +2
					*goto Final_Army_Battle_Round2
				*if (magic>=60)
					Many men and women are killed as the flaming balls of stone fall upon your enemy.
					*set t_army -7
					*if (showstats)
						(Needed 90 Magic for Greater Bonus)
						*line_break
						(Tornassa Army -7 to ${t_army} / 100)
					*goto Final_Army_Battle_Round2
				The spell is beyond your ability to cast to its fullest, but a few small stones still fall from the sky and strike your enemy.  Your troops grow confident from the display, fighting even harder.
				*set t_army -5
				*if (showstats)
					(Needed 60 Magic)
					*line_break
					(Tornassa Army -5 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (class_blademaster>0) #Draw both sword and dagger as you wade into the battle using the skills of a Blademaster.
				Your blades are a blur as you strike every enemy who comes close to you.  Your soldiers give you room and protect your back as you walk deeper into the fray.  You are the bringer of death and you meet no opponent who is nearly as skilled as you are.
				*set t_army -12
				*if (showstats)
					*line_break
					(Tornassa Army -12 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (sword) #Join your soldiers with your sword in hand.
				You close the distance and begin to kill the enemy soldiers with your sword.  Your companions try to keep you safe, but in the middle of a battle as large as this, it's difficult.
				*if (blades>=90)
					Your talent with the blade allows you to kill many enemy soldiers and your troops grow confident when seeing your success.
					*set t_army -10
					*if (showstats)
						*line_break
						(Blades +2 and Tornassa Army -10 to ${t_army} / 100)
					*set blades +2
					*goto Final_Army_Battle_Round2
				*if (blades>=60)
					Your friends are hard pressed to keep you from injury as the enemy soldiers fall at the end of your blade.
					*set t_army -7
					*if (showstats)
						(Needed 90 Blades for Greater Bonus)
						*line_break
						(Tornassa Army -7 to ${t_army} / 100)
					*goto Final_Army_Battle_Round2
				When pulling your blade from the chest of one man, another soldier's sword cuts deeply into your upper leg, splashing a large amount of blood onto the ground.
				*set health -20
				*if (health<=0)
					*if (showstats)
						(Needed 60 Blades)
						*line_break
						(Health -20 to 0 / 100)
					*goto Final_Battle_Knocked_Out
				Your soldiers continue to fight around you, killing the man who injured you.
				*set t_army -5
				*if (showstats)
					(Needed 60 Blades)
					*line_break
					(Health -20 to ${health} / 100 and Tornassa Army -5 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (belt_of_speed) #The Belt of Speed begins to glow….
				Suddenly, the battle seems to slow down.
				*if (sword=false)
					You step forward and easily pull the sword out of the hands of an enemy soldier.
				It takes no skill to stab your blade into the unprotected necks of your opponents.  You step aside from their counter-attacks with ease.  At one point an arrow comes toward you and you watch it approach.  When it gets within reach, you simply pull it out of the air and drop it to the ground.  By the time the belt stops glowing again, you have killed many men and women.
				*set t_army -15
				*if (showstats)
					*line_break
					*if (sword=false)
						(Gained Sword, Blades +2 and Tornassa Army -15 to ${t_army} / 100)
					*if (sword)
						(Blades +2 and Tornassa Army -15 to ${t_army} / 100)
				*set sword true
				*set blades +2
				*goto Final_Army_Battle_Round2
			#Join your troops, fighting with your hands and feet.
				Your companions try to keep you safe, but in the middle of a battle as large as this, it's difficult.  It's not easy to fight armed soldiers with bare hands, since their long reach makes getting close a difficult task.
				*if (unarmed>=90)
					Your skills allow you to duck under their weapons and reach vital targets on their bodies.  You leave behind a wake of injured men and women.  Those that you don't kill are finished off by your soldiers.
					*set t_army -8
					*if (showstats)
						*line_break
						(Unarmed +2 and Tornassa Army -8 to ${t_army} / 100)
					*set unarmed +2
					*goto Final_Army_Battle_Round2
				When trying to close the distance, a soldier's sword cuts deeply into your upper leg.  A large amount of blood splashes onto the ground.
				*set health -20
				*if (health<=0)
					*if (showstats)
						*line_break
						(Health -20 to 0 / 100)
					*goto Final_Battle_Knocked_Out
				*set t_army -4
				Your soldiers continue to fight around you, killing the man who injured you.
				*if (showstats)
					(Needed 90 Unarmed)
					*line_break
					(Health -20 to ${health} / 100 and Tornassa Army -4 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (demonsummoner) 
				*allow_reuse #Open your runebag and consider summoning some demons.
					*goto Final_Battle_Round1_Demons
			*if (class_alchemist>0) #Throw alchemical smoke bombs at the enemy soldiers.
				*goto Final_Army_Battle_Alchemist
			*allow_reuse #Consider your other options.
				You consider your other options.
				*goto Final_Battle_Round1_loop
	*allow_reuse #Support your troops.
		You know that victory can only come by defeating Selina's army, so you concentrate on helping your own troops.
		*choice
			*if (class_warmaster>0) #Use your knowledge as a War Master to command your troops.
				You spot holes in your enemy's defence and send your troops to exploit them.  When Selina's troops try to overwhelm your own, you send exactly the right amount of soldiers to stop them.  Your knowledge of strategy and tactics turns the tide of the battle strongly in your favour.
				*set t_army -15
				*if (showstats)
					*line_break
					(Tornassa Army -15 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (class_priest>0) #Call upon ${god_name} to bless your troops.
				You chant the words and your ${god_goddess} answers.
				*if (god_good)
					Your soldiers suddenly feel calmer and braver, allowing them to fight with more courage as goodness fills their hearts.
				*if (god_good=false)
					Your soldiers suddenly feel cold and murderous, allowing them to fight without hesitancy as evil fills their hearts.
				*if (class_priest=1)
					*set t_army -5
					*if (showstats)
						(Needed More Levels in $!{priestpriestess} for Greater Bonus)
						*line_break
						(Tornassa Army -5 to ${t_army} / 100)
					*goto Final_Army_Battle_Round2
				*if (class_priest=2)
					*set t_army -7
					*if (showstats)
						(Needed More Levels in $!{priestpriestess} for Greater Bonus)
						*line_break
						(Tornassa Army -7 to ${t_army} / 100)
					*goto Final_Army_Battle_Round2
				*if (class_priest=3)
					*set t_army -10
					*if (showstats)
						(Needed More Levels in $!{priestpriestess} for Greater Bonus)
						*line_break
						(Tornassa Army -10 to ${t_army} / 100)
					*goto Final_Army_Battle_Round2
				*comment (class_priest=4)
				*set t_army -12
				*if (showstats)
					*line_break
					(Tornassa Army -12 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (class_bard>0) #Encourage your troops with song.
				Your mystical words of encouragement seep into your soldiers, causing them to fight more courageously and with greater skill.
				*if (class_bard=1)
					*set t_army -5
					*if (showstats)
						(Needed More Levels in Bard for Greater Bonus)
						*line_break
						(Tornassa Army -5 to ${t_army} / 100)
					*goto Final_Army_Battle_Round2
				*if (class_bard=2)
					*set t_army -7
					*if (showstats)
						(Needed More Levels in Bard for Greater Bonus)
						*line_break
						(Tornassa Army -7 to ${t_army} / 100)
					*goto Final_Army_Battle_Round2
				Suddenly, they are battling like figures from legend.
				*if (class_bard=3)
					*set t_army -10
					*if (showstats)
						(Needed More Levels in Bard for Greater Bonus)
						*line_break
						(Tornassa Army -10 to ${t_army} / 100)
					*goto Final_Army_Battle_Round2
				*comment (class_bard=4)
				*set t_army -12
				*if (showstats)
					*line_break
					(Tornassa Army -12 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (class_alchemist>0) #Throw alchemical smoke bombs at the enemy soldiers.
				*label Final_Army_Battle_Alchemist
				The small glass vials explode upon contact.  The smoke chokes the enemies and makes it difficult for them to attack effectively.  Your troops cut through the distracted soldiers with ease, killing many of them at once.
				*set t_army -12
				*if (showstats)
					*line_break
					(Tornassa Army -12 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			#Shout encouragement.
				You call out to your troops, telling them that they are doing the right thing and that they look strong.  You call attention to the deaths of the enemy soldiers and tell them that they are winning.
				*if (charm>=90)
					The confidence that you inspire has a great effect upon your troops as they fight the enemy in front of you.
					*set t_army -10
					*if (showstats)
						*line_break
						(Charm +2 and Tornassa Army -10 to ${t_army} / 100)
					*set charm +2
					*goto Final_Army_Battle_Round2
				The confidence that you inspire has some effect upon your troops as they fight the enemy in front of you.
				*set t_army -5
				*if (showstats)
					(Needed 90 Charm)
					*line_break
					(Tornassa Army -5 to ${t_army} / 100)
				*goto Final_Army_Battle_Round2
			*if (class_necromancer>0) #Raise the dead and send them forth.
				*if (necromancer_known)
					The enemy watch in terror as friends and foes rise up to fight for you, filling in the ranks of the undead creatures they have managed to lay back to rest.
					*set t_army -12
					*if (showstats)
						*line_break
						(Army Size +5 and Tornassa Army -12 to ${t_army} / 100)
					*set army_size +5
					*goto Final_Army_Battle_Round2
				The enemy watch in terror as friends and foes rise up to fight for you.  Your own soldiers scream in terror to see such evil in their midst.
				*set necromancer_known true
				*set t_army -10
				*if (showstats)
					*line_break
					(Evil +20, Army Size +5, Citizen Fear +50, Citizen Reputation -50 and Tornassa Army -10 to ${t_army} / 100)
				*set good -20
				*set army_size +5
				*set citizen_fear +50
				*set citizen_reputation -50
				*goto Final_Army_Battle_Round2
			*if (demonsummoner) 
				*allow_reuse #Open your runebag and consider summoning some demons.
					*label Final_Battle_Round1_Demons
					You look into your runebag and consider your options.
					*label Final_Battle_Round1_Demons_loop
					*choice
						*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and (demonstone_xiatta_used=false)) #Summon Xi'atta and tell it to attack.
							*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
							*comment: End of Pt. 2, Min 45 Max 75
							Xi'atta appears in front of you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
							
							"Yes, ${mastermistress}," Xi'atta says.
							
							The frosty little imp flies around casting ice upon the hands of the enemy soldiers.  Swords fall from numb fingers and icy grips, allowing your own soldiers to kill the enemies easier.  Xi'atta gets too close to one soldier and his sword cuts the frosty demon in half, sending it back to the demon realm.
							*set t_army -5
							*if (showstats)
								*line_break
								(Tornassa Army -5 to ${t_army} / 100)
							*set demonstone_xiatta_used true
							*goto Final_Battle_Round1_Demons_loop
						*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and (demonstone_brahl_used=false)) #Summon Brahl and tell it to attack.
							*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
							*comment: End of Pt. 2, Min 45 Max 75
							Brahl appears in front of you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.  The raging battle makes the demon's eyes glisten in excitement.
							
							*if (willpower>=70)
								"This is going to be fun," Brahl says as it charges forward with both claws and teeth.
								
								Gore is strewn about as it tears into the enemy soldiers with abandon.  It takes an entire troop of soldiers to finally kill it, sending it back to the demon realm to recuperate.
								*set demonstone_brahl_used true
								*set t_army -15
								*if (showstats)
									*line_break
									(Tornassa Army -15 to ${t_army} / 100)
								*goto Final_Battle_Round1_Demons_loop
							*else
								"Are you crazy?  As much fun as that looks, I'm not eager to get myself disembowelled," Brahl says. The contest of wills is rejoined and the brawny demon pops out of existence.
								*if (showstats)
									(Needed 70 Willpower)
								*goto Final_Battle_Round1_Demons_loop
						*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and (demonstone_zonch_used=false)) #Summon Zon'ch and tell it to attack.
							*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
							*comment: End of Pt. 2, Min 45 Max 75
							Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
							
							*if (willpower>=50)
								"Yes, ${mastermistress}," Zon'ch says.
								
								It does just as you ask it to, sending puffs of dirty wind into the faces of the enemy soldiers.  This gives your troops the opportunity to cut them down.  Zon'ch gets a little too close to an enemy soldier who promptly rams his sword through the demon, popping it out of existence.
								*set demonstone_zonch_used true
								*set t_army -5
								*if (showstats)
									*line_break
									(Tornassa Army -5 to ${t_army} / 100)
								*goto Final_Battle_Round1_Demons_loop
							*else
								"No way, uh uh," Zon'ch says. The contest of wills is rejoined and the dusty demon pops out of existence.
								*if (showstats)
									(Needed 50 Willpower)
								*goto Final_Battle_Round1_Demons_loop
						*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and (demonstone_daanda_used=false)) #Summon Daan'da and tell it to attack.
							*comment Will of 0, but very stupid and weak.
							*comment: End of Pt. 2, Min 45 Max 75
							Daan'da appears nearby.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It walks toward the battle with its arms outstretched.  An enemy soldier turns to it and lops off its head with a single blow.  Both head and body disappear back to the demon realm to heal.
							*set demonstone_daanda_used true
							*goto Final_Battle_Round1_Demons_loop
						*if ((demonstone_gaabon) and (demonstone_gaabon_used=false)) #Summon Gaa'bon and tell it to attack.
							*comment Gaa'bon: Willing: 45, Small Struggle: 55, Against: 65
							*comment: End of Pt. 2, Min 45 Max 75
							Gaa'bon appears in a puff of smoke next to you.  It is one foot tall and appears sluggish and uninterested in its surroundings.  It slowly glances up at you.
							*if (willpower>=65)
								
								"I guess," Gaa'bon says in its slow drawl as you batter down its will.
								
								The slow moving demon phases through your troops as it travels across to the enemy.  It claws at one of the soldiers, cutting him lightly in the leg.  The man kicks the demon away and another soldier skewers it with his sword, sending Gaa'bon back to the demon realm to heal.
								*set demonstone_gaabon_used true
								*goto Final_Battle_Round1_Demons_loop
							*if (showstats)
								(Needed 65 Willpower)
							
							"No, not going to do that," Gaa'bon says in its slow drawl as it battles your will and then returns to its own realm.
							*goto Final_Battle_Round1_Demons_loop
						*allow_reuse #Close your runebag.
							You close your runebag and look up at the battle occurring around you.
							*goto Final_Battle_Round1_loop
			*allow_reuse #Consider your other options.
				You consider your other options.
				*goto Final_Battle_Round1_loop

*label Final_Army_Battle_Round2
*comment t_army:  max of -127
*if (t_army<20)
	*goto Fight_Red
*if (companion_name!="None")
	*if ((((companion_type="spider") or (companion_type="tanuki")) or ((companion_type="cat") or (companion_type="mouse")))  or (((companion_type="toad") or (companion_type="rat")) or (companion_type="fox")))
		*goto Final_Army_Battle_Round3
	
	${companion_name}, your ${companion_type}, is eager to help.
	*temp companion_dam 0
	*choice
		#Send ${companion_name} against the enemy soldiers.
			*if (companion_type="fire elemental")
				${companion_name} raises ${companion_hisher} arms and bursts into even brighter flames.  $!{companion_heshe} runs forward, touching every enemy soldier ${companion_heshe} can.  Burning men and women scream as flesh sizzles.  Eventually a group of soldiers bring buckets of water to douse the elemental into submission.
				*set companion_injured true
				*set companion_dam 5
				*goto Final_Battle_Companion_End
			*if (companion_type="air elemental")
				${companion_name} raises ${companion_hisher} arms and rushes forward, throwing large gusts of wind into each enemy soldier.  Arrows are blown safely to the side and many soldiers are thrown to the ground.  The elemental is untouchable as swords pass through its body.
				*set companion_dam 5
				*goto Final_Battle_Companion_End
			*if (companion_type="earth elemental")
				${companion_name} raises ${companion_hisher} stone fists and marches forward.  Each mighty swing kills or injures a soldier as ${companion_heshe} causes havoc among the enemy troops.  Eventually a group of swordsmen hack ${companion_name} into submission, but thankfully ${companion_heshe} is only injured and not killed.
				*set companion_injured true
				*set companion_dam 5
				*goto Final_Battle_Companion_End
			*if (companion_type="water elemental")
				${companion_name} raises ${companion_hisher} arms and water splashes everywhere.  $!{companion_heshe} runs forward, pushing ${companion_hisher} hands into the soldiers' faces, which causes them to struggle to breathe and eventually drown.
				*set companion_injured false
				*set companion_dam 3
				*goto Final_Battle_Companion_End
			*if ((companion_type="wolf") or (companion_type="dog"))
				${companion_name} snarls with ${companion_hisher} hackles raised as ${companion_heshe} runs forward.  Many soldiers have their hamstrings and throats torn out.  Eventually a group of swordsmen hack ${companion_name} into submission, but thankfully ${companion_heshe} is only injured and not killed.
				*set companion_injured true
				*set companion_dam 5
				*goto Final_Battle_Companion_End
			*if (companion_type="firedrake")
				${companion_name} snarls and puffs out a small gout of flame as ${companion_heshe} runs forward.  Many soldiers are injured by ${companion_hisher} sharp claws.   Eventually a group of swordsmen hack ${companion_name} into submission, but thankfully ${companion_heshe} is only injured and not killed.
				*set companion_injured true
				*set companion_dam 5
				*goto Final_Battle_Companion_End
			*if (companion_type="griffin")
				${companion_name} ruffles ${companion_hisher} feathers as ${companion_heshe} runs forward on ${companion_hisher} lion's feet.  Many soldiers are injured by ${companion_hisher} sharp beak and claws.  $!{companion_heshe} is very difficult to bring down as ${companion_heshe} takes to the air as needed.  Eventually a group of swordsmen hack ${companion_name} into submission, but thankfully ${companion_heshe} is only injured and not killed.
				*set companion_injured true
				*set companion_dam 10
				*goto Final_Battle_Companion_End
			*if (companion_type="owlbear")
				${companion_name} roars and then shuffles forward.  Many soldiers are injured by ${companion_hisher} sharp beak and mighty bear claws.  Eventually a group of swordsmen hack ${companion_name} into submission, but thankfully ${companion_heshe} is only injured and not killed.
				*set companion_injured true
				*set companion_dam 10
				*goto Final_Battle_Companion_End
			*if (companion_type="bear")
				${companion_name} roars and then shuffles forward.  Many soldiers are injured by ${companion_hisher} mighty claws.  Eventually a group of swordsmen hack ${companion_name} into submission, but thankfully ${companion_heshe} is only injured and not killed.
				*set companion_injured true
				*set companion_dam 10
				*goto Final_Battle_Companion_End
			*if (companion_type="bobcat")
				${companion_name} roars and raises ${companion_hisher} hackles as ${companion_heshe} pounces onto the first enemy ${companion_heshe} sees.  Many soldiers are injured by ${companion_hisher} mighty claws.  Eventually a group of swordsmen hack ${companion_name} into submission, but thankfully ${companion_heshe} is only injured and not killed.
				*set companion_injured true
				*set companion_dam 10
				*goto Final_Battle_Companion_End
			*if (companion_type="Shade")
				${companion_name} floats ominously forward.  $!{companion_heshe} reaches out a spectral hand and every touch fills ${companion_hisher} targets with dread.  Soon there are many men and women running away from ${companion_himher}.  Those who aren't killed by your soldiers eventually get their courage back and attack elsewhere, staying far away from your Shade.  
				*set companion_dam 3
				*goto Final_Battle_Companion_End
			*if (((companion_type="owl") or (companion_type="dove")) or ((companion_type="hawk") or (companion_type="raven")))
				${companion_name} flies over the enemy soldiers and begins swooping down.  Eyes are mercilessly torn out, allowing your troops to kill the blind men.  A carefully shot arrow eventually knocks ${companion_name} to the ground, but thankfully ${companion_heshe} is only injured and not killed.
				*set companion_injured true
				*set companion_dam 3
				*goto Final_Battle_Companion_End
			ERROR:  Sorry, the program couldn't find the companion_type "${companion_type}."  Please report this error to the developer.
			*page_break Continue Playing….
			*goto Final_Army_Battle_Round3
			
			*label Final_Battle_Companion_End
			*set t_army -companion_dam
			*if (showstats)
				*line_break
				(Tornassa Army -${companion_dam} to ${t_army} / 100)
			*goto Final_Army_Battle_Round3
		#Keep ${companion_name} safe beside you.
			$!{companion_heshe} listens to your words and stays back as your troops fight.
			*goto Final_Army_Battle_Round3
*else
	*goto Final_Army_Battle_Round3

*label Final_Army_Battle_Round3
*comment t_army:  max of -137
*if (t_army<=20)
	*goto Fight_Red

The battle rages on as arrows fly and soldiers die.  The base of the castle is soaked with blood and the air is filled with the sounds of the
*set army_size -10
*set army_power -10
*gosub Check_Army_Stats
*if ((army_power<30) or (army_size<30))
	injured.
	*if (showstats)
		(Needed 20 or Under Tornassa Army)
		*line_break
		(Army Size -10 and Army Power -10)
	
	*if (army_power<30)
		*goto Army_Power_Under_30_Loss
	*if (army_size<30)	
		*goto Army_Size_Under_30_End		
injured, yet your troops continue to fight for you.  A large group of enemy soldiers break away from the main force and rush directly toward you, trying to end the fight once and for all.
*set t_army -10
*if (showstats)
	(Needed 20 or Under Tornassa Army)
	*line_break
	(Army Size -10, Army Power -10 and Tornassa Army -10 to ${t_army} / 100)
*if (t_army<20)
	*goto Fight_Red

You duck under a sword and side step an arrow, but the increased attention begins to prove too much.  Suddenly, two more arrows fly directly toward you!  
*choice
	*if (magic_shield) #Hold up your magic shield.
		The two arrows bounce harmlessly off of the artifact as your troops continue to fight.
		*set t_army -10
		*if (showstats)
			*line_break
			(Tornassa Army -10 to ${t_army} / 100)
		*goto Final_Army_Battle_Round4
	*if (theothea_inparty) #Let ${theothea_name} protect you.
		*set theothea_injured true
		The large ${theothea_manwoman}
		*if (theothea_relationship>=90)
			grabs an enemy soldier and holds them up in the air.  Both arrows thud into the body.  $!{theothea_heshe} throws the corpse aside and grins at you.  Another arrow comes from a different angle and hits ${theothea_himher} in the back, knocking ${theothea_himher} to the ground.  $!{theothea_name} will live, but ${theothea_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set t_army -10
			*if (showstats)
				*line_break
				(${theothea_name} Relationship +2 and Tornassa Army -10 to ${t_army} / 100)
			*set theothea_relationship +2
			*goto Final_Army_Battle_Round4
		*else
			hesitates for a moment and then watches the two arrows helplessly.  One of them misses you, but the other drives deeply into your side, knocking you to the ground!  Another arrow comes from a different angle and hits ${theothea_name} in the back, knocking ${theothea_himher} to the ground too.  $!{theothea_name} will live, but ${theothea_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set health -20
			*set t_army -10
			*if (showstats)
				(Needed 90 ${theothea_name} Relationship)
				*line_break
				(Health -20 to ${health} / 100 and Tornassa Army -10 to ${t_army} / 100)
			*goto Final_Army_Battle_Round4
	*if (peterpetra_inparty) #Let ${peterpetra_name} protect you.
		*set peterpetra_injured true
		The holy warrior
		*if (peterpetra_relationship>=90)
			raises ${peterpetra_hisher} shield in front of you, allowing both arrows to bounce harmlessly aside.  Another arrow comes from a different angle and hits ${peterpetra_name} in the back, knocking ${peterpetra_himher} to the ground.  Meanwhile, your troops continue to battle.
			*set t_army -10
			*if (showstats)
				*line_break
				(${peterpetra_name} Relationship +2 and Tornassa Army -10 to ${t_army} / 100)
			*set peterpetra_relationship +2
			*goto Final_Army_Battle_Round4
		*else
			hesitates for a moment and then watches the two arrows helplessly.  One of them misses you, but the other drives deeply into your side, knocking you to the ground!  Another arrow comes from a different angle and hits ${peterpetra_name} in the back, knocking ${peterpetra_himher} to the ground too.  $!{peterpetra_name} will live, but ${peterpetra_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set health -20
			*set t_army -10
			*if (showstats)
				(Needed 90 ${peterpetra_name} Relationship)
				*line_break
				(Health -20 to ${health} / 100 and Tornassa Army -10 to ${t_army} / 100)
			*goto Final_Army_Battle_Round4
	*if (gillgale_inparty) #Let ${gillgale_name} protect you.
		*set gillgale_injured true
		The slim thief
		*if (gillgale_relationship>=90)
			jumps into the air and slashes out with both of ${gillgale_hisher} blades, cutting the arrows out of the sky before they can strike you.  Another arrow comes from a different angle and hits ${gillgale_name} in the back, knocking ${gillgale_himher} to the ground.  $!{gillgale_name} will live, but ${gillgale_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set t_army -10
			*if (showstats)
				*line_break
				(${gillgale_name} Relationship +2 and Tornassa Army -10 to ${t_army} / 100)
			*set gillgale_relationship +2
			*goto Final_Army_Battle_Round4
		*else
			hesitates for a moment and then watches the two arrows helplessly.  One of them misses you, but the other drives deeply into your side, knocking you to the ground!  Another arrow comes from a different angle and hits ${gillgale_name} in the back, knocking ${gillgale_himher} to the ground too.  $!{gillgale_name} will live, but ${gillgale_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set health -20
			*set t_army -10
			*if (showstats)
				(Needed 90 ${gillgale_name} Relationship)
				*line_break
				(Health -20 to ${health} / 100 and Tornassa Army -10 to ${t_army} / 100)
			*goto Final_Army_Battle_Round4
	*if (karlkarla_inparty) #Let ${karlkarla_name} protect you.
		*set karlkarla_injured true
		The slender archer
		*if (karlkarla_relationship>=90)
			jumps in front of you with ${karlkarla_hisher} hands outstretched.  Gruesomely, both arrows strike ${karlkarla_hisher} arms, keeping you safe as ${karlkarla_heshe} falls to the ground at your feet with a cry.  $!{karlkarla_name} will live, but ${karlkarla_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set t_army -10
			*if (showstats)
				*line_break
				(${karlkarla_name} Relationship +2 and Tornassa Army -10 to ${t_army} / 100)
			*set karlkarla_relationship +2
			*goto Final_Army_Battle_Round4
		*else
			hesitates for a moment and then watches the two arrows helplessly.  One of them misses you, but the other drives deeply into your side, knocking you to the ground!  Another arrow comes from a different angle and hits ${karlkarla_name} in the back, knocking ${karlkarla_himher} to the ground too.  $!{karlkarla_name} will live, but ${karlkarla_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set health -20
			*set t_army -10
			*if (showstats)
				(Needed 90 ${karlkarla_name} Relationship)
				*line_break
				(Health -20 to ${health} / 100 and Tornassa Army -10 to ${t_army} / 100)
			*goto Final_Army_Battle_Round4
	*if (jacejess_inparty) #Let ${jacejess_name} protect you.
		*set jacejess_injured true
		The
		*if (jacejess_relationship>=90)
			Soulburner's eyes flash white as twin beams of light strike forth to burn the arrows in mid-flight.  A soft puff of ash is all that makes its way to you.  Another arrow comes from a different angle and hits ${jacejess_name} in the back, knocking ${jacejess_himher} to the ground.  $!{jacejess_name} will live, but ${jacejess_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set t_army -10
			*if (showstats)
				*line_break
				(${jacejess_name} Relationship +2 and Tornassa Army -10 to ${t_army} / 100)
			*set jacejess_relationship +2
			*goto Final_Army_Battle_Round4
		*else
			Soulburner hesitates for a moment as ${jacejess_heshe} decides what to do.  One of the arrows misses you, but the other drives deeply into your side, knocking you to the ground!  Another arrow comes from a different angle and hits ${jacejess_name} in the back, knocking ${jacejess_himher} to the ground too.  $!{jacejess_name} will live, but ${jacejess_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set health -20
			*set t_army -10
			*if (showstats)
				(Needed 90 ${jacejess_name} Relationship)
				*line_break
				(Health -20 to ${health} / 100 and Tornassa Army -10 to ${t_army} / 100)
			*goto Final_Army_Battle_Round4
	*if (branbrinn_inparty) #Let ${branbrinn_name} protect you.
		*set branbrinn_injured true
		The Captain
		*if (branbrinn_relationship>=90)
			doesn't think twice before throwing ${branbrinn_himher}self into the line of fire.  Both arrows thud into ${branbrinn_hisher} side as ${branbrinn_heshe} falls to the ground, keeping you safe.  $!{branbrinn_name} will live, but ${branbrinn_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set t_army -10
			*if (showstats)
				*line_break
				(${branbrinn_name} Relationship +2 and Tornassa Army -10 to ${t_army} / 100)
			*set branbrinn_relationship +2
			*goto Final_Army_Battle_Round4
		*else
			hesitates for a moment as ${branbrinn_heshe} decides what to do.  One of the arrows misses you, but the other drives deeply into your side, knocking you to the ground!  Another arrow comes from a different angle and hits ${branbrinn_name} in the back, knocking ${branbrinn_himher} to the ground.  $!{branbrinn_name} will live, but ${branbrinn_heshe} is out of the fight.  Meanwhile, your troops continue to battle.
			*set health -20
			*set t_army -10
			*if (showstats)
				(Needed 90 ${branbrinn_name} Relationship)
				*line_break
				(Health -20 to ${health} / 100 and Tornassa Army -10 to ${t_army} / 100)
			*goto Final_Army_Battle_Round4

*label Final_Army_Battle_Round4
*if (health<=0)
	*goto Final_Battle_Knocked_Out
*comment t_army:  max of -157

The bodies pile higher and higher.  You realize that one way or another, the battle is going to end soon and only the crows will be happy with the outcome.
*if (showstats)
	*line_break
	(Army Size -10 and Army Power -10)
*set army_size -10
*set army_power -10
*gosub Check_Army_Stats
*if ((army_power<30) or (army_size<30))
	
	*if (army_power<30)
		*goto Army_Power_Under_30_Loss
	*if (army_size<30)	
		*goto Army_Size_Under_30_End
*goto Fight_Red	
	
*label Fight_Red
*set grand_reveal true
*set stage 6

The battle moves and shifts, like a living thing.
*if (silver_blades_hired)
	At one point you see the Silver Blades fighting a group of soldiers, but then other combatants get in the way and you can't see them any more.
You lose sight of your companions as they fight nearby.  Before you know it, you are standing face to face with the ${prisoner1_nickname}.
*if (selina_hurt)
	Selina's body lies nearby as the
*if (selina_hurt=false)
	Selina stands behind ${prisoner1_himher} as the
*gosub Prisoner1_Man_Woman
in red steps forward.  $!{prisoner1_heshe} reaches up and pushes back ${prisoner1_hisher} hood.  Although the eyes are deeply sunken and bloodshot, you recognize the face of
*if (prisoner1_name=theothea_name)
	your first adventuring partner.  It is ${theothea_name}!  $!{theothea_heshe} raises ${theothea_hisher} enormous war hammer over ${theothea_hisher} head, ready to kill you.
*if (prisoner1_name=peterpetra_name)
	your childhood friend.  It is ${peterpetra_name}!  $!{peterpetra_heshe} raises ${peterpetra_hisher} hand and begins a prayer to Noct and Shadi, the most evil deities in the world.
*if (prisoner1_name=gillgale_name)
	your childhood friend.  It is ${gillgale_name}!  $!{gillgale_heshe} draws two incredibly sharp blades from ${gillgale_hisher} belt and drives one of them toward you.
*if (prisoner1_name=karlkarla_name)
	your friend from Elmvale.  It is ${karlkarla_name}!  $!{karlkarla_heshe} raises ${karlkarla_hisher} bow and draws back an arrow, aiming it at your face.
*if (prisoner1_name=jacejess_name)
	the Soulburner.  It is ${jacejess_name}!  $!{jacejess_heshe} faces you and you see ${jacejess_hisher} eyes begin to glow white with deadly intent.
*comment Red's health, max gone: -35
*temp allow_talk_temp true
*choice
	#Say, "Wait!  It's me, ${name}!"
		You see a slight flicker of recognition in ${prisoner1_hisher} pain-filled eyes, but it disappears as quickly as it came.
		*if (prisoner1_relationship>=75)
			During this hesitation an arrow strikes ${prisoner1_name} in the leg from one of your own soldiers.  The man who fired the shot is killed quickly by one of Selina's soldiers.
			*set red_health -35
			*if (showstats)
				*line_break
				(${prisoner1_name} Health -35 to ${red_health} / 100)
			*comment Red's maxed health lost is 65, now 30
			*goto Fight_Red_Round2
		*else
			*if (showstats)
				(Needed 75 ${prisoner1_name} Relationship)
				
			*label Red_Hits_First_Round
			*if (prisoner1_name=theothea_name)
				${theothea_name}'s large hammer smashes into your chest and the breath is knocked out of you.
			*if (prisoner1_name=peterpetra_name)
				You feel an icy chill fill your soul as Shadi and Noct attempt to overcome you.
				*if ((god_name="Shadi") or (god_name="Noct"))
					The fact that you serve the same Gods matters nothing as the ${prisoner1_nickname} has more of their evil favour at the moment.
			*if (prisoner1_name=gillgale_name)
				${gillgale_name}'s sword slices deeply into your side.
			*if (prisoner1_name=karlkarla_name)
				You move quickly, but ${karlkarla_name}'s arrow still hits you solidly in the shoulder.
			*if (prisoner1_name=jacejess_name)
				Hot white fire burns across your side as you try to dodge ${jacejess_name}'s blazing white eyes.
			*set health -20
			*if (showstats)
				*line_break
				(Health -20 to ${health} / 100)
			*if (health<=0)
				*goto Final_Battle_Knocked_Out
			*else
				*goto Fight_Red_Round2		
	#Duck and roll.
		*if (agility>=50)
			You throw yourself to the ground and roll as
			*if (prisoner1_name=theothea_name)
				${theothea_name}'s large hammer smashes into the ground where you had been standing.
			*if (prisoner1_name=peterpetra_name)
				${peterpetra_name}'s divine magic strikes nothing but air.
				*if ((god_name="Shadi") or (god_name="Noct"))
					The fact that you serve the same Gods matters nothing as the ${prisoner1_nickname} has more of their evil favour at the moment.
			*if (prisoner1_name=gillgale_name)
				${gillgale_name}'s sword just misses you.
			*if (prisoner1_name=karlkarla_name)
				${karlkarla_name}'s arrow strikes the dirt where you had been standing.
			*if (prisoner1_name=jacejess_name)
				hot white fire from ${jacejess_name}'s eyes strikes the dirt where you had been standing.
			*if (showstats)
				*line_break
				(Agility +2)
			*set agility +2
			*goto Fight_Red_Round2
		*else
			Unfortunately, you are too slow.
			*if (showstats)
				(Needed 50 Agility)
				
			*goto Red_Hits_First_Round
	#Attack the ${prisoner1_nickname}.
		You waste no time trying to reason with the monster that ${prisoner1_name} has become.  Whatever Selina has done to ${prisoner1_himher} is clearly irreversible.
		*set allow_talk_temp false
		*goto Fight_Red_Round2

*label Fight_Red_Round2
*comment Red's health, max: -70
*choice
	*if (sword) #Strike your old friend with your sword.
		You swing your blade quickly
		*if (blades>=85)
			*set red_health -35
			*if (red_health<=0)
				lopping off ${prisoner1_hisher} head.
			*if (red_health>0)
				and it strikes ${prisoner1_name} deeply in the side.
			*if (showstats)
				*line_break
				(Blades +2 and ${prisoner1_name} Health -35 to ${red_health} / 100)
			*set blades +2
			*goto Fight_Red_Round3
		*else
			but ${prisoner1_heshe} is quicker.
			*if (showstats)
				(Needed 85 Blades)
				
			*label Red_Hits_Second_Round
			*if (prisoner1_name=theothea_name)
				${theothea_name} twirls the big hammer and jabs the handle into your ribs, cracking several of them.
			*if (prisoner1_name=peterpetra_name)
				${peterpetra_name}'s morningstar swings in a low arc, smashing into your ribs, cracking several of them.
			*if (prisoner1_name=gillgale_name)
				${gillgale_name} swings one sword high and the other low, catching you solidly across the chest, cutting you deeply and cracking a few ribs.
			*if (prisoner1_name=karlkarla_name)
				${karlkarla_name} steps to the side and sends an arrow into your chest, narrowly missing your heart.
			*if (prisoner1_name=jacejess_name)
				${jacejess_name} sends a beam of fire across your shoulder and into your neck, burning deeply.
			*set health -20
			*if (showstats)
				*line_break
				(Health -20 to ${health} / 100)
			*if (health<=0)
				*goto Final_Battle_Knocked_Out
			*else
				*goto Fight_Red_Round3
	*if (dagger) #Throw your dagger at ${prisoner1_himher}.
		The blade turns over once in the air
		*if (blades>=85)
			*set red_health -35
			and sinks solidly into ${prisoner1_name}'s
			*if (red_health<=0)
				chest, piercing ${prisoner1_hisher} heart.
			*if (red_health>0)
				chest, just missing ${prisoner1_hisher} heart.
			*if (showstats)
				*line_break
				(Lost Dagger, Blades +2 and ${prisoner1_name} Health -35 to ${red_health} / 100)
			*set dagger false
			*set used_dagger true
			*set blades +2
			*goto Fight_Red_Round3
		*else
			*if (prisoner1_name=theothea_name)
				but ${theothea_heshe} swats it aside with a big meaty hand.
			*if (prisoner1_name=peterpetra_name)
				but ${prisoner1_heshe} raises ${prisoner1_hisher} shield and blocks it.
			*if (prisoner1_name=gillgale_name)
				but ${gillgale_heshe} agilely dodges it.
			*if (prisoner1_name=karlkarla_name)
				but	${karlkarla_heshe} ducks under it.
			*if (prisoner1_name=jacejess_name)
				but ${jacejess_heshe} ducks under it.
			*if (showstats)
				(Needed 85 Blades)
				*line_break
				(Lost Dagger)
				
			*set dagger false
			*set used_dagger true
			*goto Red_Hits_Second_Round
	#Try to grab ${prisoner1_himher}.
		You reach out and
		*if (unarmed>=85)
			take hold of ${prisoner1_hisher} arms.  Although ${prisoner1_name} tries to fight back, you throw ${prisoner1_himher} over your hip, making ${prisoner1_himher} crash solidly to the ground.
			*set red_health -35
			*if (red_health<=0)
				You hear ${prisoner1_hisher} neck snap upon impact.
			*if (red_health>0)
				$!{prisoner1_heshe} quickly gets back to ${prisoner1_hisher} feet.
			*if (showstats)
				*line_break
				(Unarmed +2 and ${prisoner1_name} Health -35 to ${red_health} / 100)
			*set unarmed +2
			*goto Fight_Red_Round3
		*else
			try to grab ${prisoner1_himher},
			*if (prisoner1_name=theothea_name)
				but ${prisoner1_heshe} is too strong.
			*if (prisoner1_name=peterpetra_name)
				but ${prisoner1_heshe} knocks your hand away with ${prisoner1_hisher} shield.
			*if (prisoner1_name=gillgale_name)
				but ${prisoner1_heshe} slips out of your grip.
			*if (prisoner1_name=karlkarla_name)
				but	${prisoner1_heshe} steps back, farther out of reach.
			*if (prisoner1_name=jacejess_name)
				but	${prisoner1_heshe} steps back, farther out of reach.
			*if (showstats)
				(Needed 85 Unarmed)
				
			*goto Red_Hits_Second_Round
	*if (class_paladin>0) #Attempt to lay your hands on ${prisoner1_name} and let ${god_name} work through you.
		Your touch begins
		*goto Round_2_Healing
	#Attempt to heal ${prisoner1_name} from ${prisoner1_hisher} affliction through prayer.
		*if (class_paladin>0)
			Your touch begins
			*goto Round_2_Healing
		*if (class_priest=0)
			Unfortunately, the Gods and Goddesses of the land don't answer you.
			*if (showstats)
				*line_break
				(Needed 2 Levels of $!{priestpriestess})
			
			*goto Red_Hits_Second_Round
		You pray to ${god_name}, hoping that you can somehow get through to ${prisoner1_himher}.
		*if (class_priest<=1)
			Unfortunately, your prayers are not answered.
			*if (showstats)
				*line_break
				(Needed 2 Levels of $!{priestpriestess})
			
			*goto Red_Hits_Second_Round
		*if (god_good=false)
			Your evil prayers are answered, but not with kind healing.  Instead, ${prisoner1_name} screams in agony as ${god_name} causes ${prisoner1_hisher} body to be filled with searing pain.
		*if (god_good)
			Your prayers begin
			*label Round_2_Healing
			to heal ${prisoner1_himher}, but the process causes ${prisoner1_himher} to scream out in pain.  You realize that the cure is beyond even your great abilities.
		*set red_health -35
		*if (red_health<=0)
			Suddenly ${prisoner1_hisher} face goes slack and ${prisoner1_heshe} falls to the ground, grabbing ${prisoner1_hisher} chest as ${prisoner1_hisher} heart stops beating from the intense stress.  The ${prisoner1_nickname} falls to the ground, dead.
		*if (showstats)
			*line_break
			(${prisoner1_name} Health -35 to ${red_health} / 100)
		*goto Fight_Red_Round3
	#Cast a spell to turn the stone at ${prisoner1_hisher} feet into sticky mud.
		You say the words of the spell quickly
		*if (magic>=85)
			and are rewarded by seeing the stone melt.  ${prisoner1_name} slides in up to ${prisoner1_hisher} knees, totally immobilized.  To your astonishment, ${prisoner1_heshe} begins to flail about like a rat caught in a
			*set red_health -35
			*if (red_health<=0)
				trap, bashing ${prisoner1_hisher} head into the stone around ${prisoner1_himher}.  One of the strikes is so hard that ${prisoner1_heshe} stops moving and blood pours from ${prisoner1_hisher} ears while ${prisoner1_hisher} eyes glaze over.
			*if (red_health>0)
				trap until the stone cracks and ${prisoner1_heshe} is able to get free.
			*if (showstats)
				*line_break
				(Magic +2 and ${prisoner1_name} Health -35 to ${red_health} / 100)
			*set magic +2
			*goto Fight_Red_Round3
		*else
			but in your haste, you say a word wrong and the spell falls apart.
			*if (showstats)
				(Needed 85 Magic)
				
			*goto Red_Hits_Second_Round
	*if (allow_talk_temp) #Ask, "Why are you doing this?  We were friends!"
		*set allow_talk_temp false
		The dark circles under ${prisoner1_hisher} eyes and ${prisoner1_hisher} sunken cheeks show that something terrible has been done to ${prisoner1_himher}.
		*if (showstats)
			*line_break
			(${prisoner1_name} Relationship +5)
			
		*set prisoner1_relationship +5
		*gosub set_prisoner1_relationship
		*if (selina_hurt=false)
			Selina laughs out loud and claps her hands in amusement.
			
			"$!{prisoner1_heshe} is mine now," Selina says coldly.  "A couple months of poisoning with the right ingredients can really get into a person's head."
			*choice
				#Attack ${prisoner1_name}, since you have no choice.
					Selina's poison has taken away ${prisoner1_name}'s life as surely as death would have.
					*goto Round2_Talk_Over
				#Say, "I will not fight you."
					"Then surrender," Selina says.  "Lay down your weapons and allow yourself to be bound!"
					*choice
						#Do as she asks.
							*goto Gave_Up_Battle_Lost
						#Continue fighting.
							Selina's poison has taken away ${prisoner1_name}'s life as surely as death would have.
							*goto Round2_Talk_Over
		*else
			*label Round2_Talk_Over
			*if ((prisoner1_relationship<55) and (charm<85))
				*if (showstats)
					(Needed 55 ${prisoner1_name} Relationship or 85 Charm)
				
				*goto Red_Hits_Second_Round
			*if (selina_hurt=false)
				Despite Selina's words, you see ${prisoner1_name} clutch ${prisoner1_hisher} head and scream as ${prisoner1_heshe} tries to fight the chemicals running through ${prisoner1_hisher} veins.
			*if (selina_hurt)
				${prisoner1_name} suddenly clutches ${prisoner1_hisher} head and screams in pain for reasons you don't understand.
			*set red_health -35
			*if (red_health>0)
				You can see the agony and suffering that the internal struggle brings.
			*if (red_health<=0)
				Suddenly ${prisoner1_hisher} face goes slack and ${prisoner1_heshe} falls to the ground, grabbing ${prisoner1_hisher} chest instead as ${prisoner1_hisher} heart stops during ${prisoner1_hisher} mental struggles.  The ${prisoner1_nickname} falls to the ground, dead.
			*if (showstats)
				*line_break
				(${prisoner1_name} Health -35 to ${red_health} / 100)
			*goto Fight_Red_Round3

*label Fight_Red_Round3
*if (red_health<=0)
	*goto Red_is_Dead
*comment Red's health only -35 with 1 attack, but also possible to be at -70, if dead, gone to Red_is_Dead
*comment selina may be selina_hurt
*if (selina_hurt=false)
	*choice
		#Use the distraction of fighting the ${prisoner1_nickname} to attack Selina.
			You circle around ${prisoner1_name}, keeping your eyes forward and watching Selina out of the corner of your eye.  Soon, you are within striking distance.  Unfortunately, ${prisoner1_name} capitalizes on your lack of focus and hits you with
			*if (prisoner1_name=theothea_name)
				${prisoner1_hisher} hammer.
			*if (prisoner1_name=peterpetra_name)
				${prisoner1_hisher} morningstar.
			*if (prisoner1_name=gillgale_name)
				one of ${prisoner1_hisher} short swords.
			*if (prisoner1_name=karlkarla_name)
				an arrow.
			*if (prisoner1_name=jacejess_name)
				a beam of light.
			*set health -20
			*if (showstats)
				*line_break
				(Health -20 to ${health} / 100)
			*if (health<=0)
				*goto Final_Battle_Knocked_Out
			*choice
				*if (sword) #Slash at Selina with your sword.
					The blade lashes out and cuts Selina across the neck as she watches your duel.  Her eyes go wide and she stumbles to the ground.
					*goto Fight_Red_Round3_FreeAttack_ns
				#Slam Selina with your shoulder as hard as you can while keeping your guard up.
					Selina is so intent on the fight that she doesn't see it coming at all.
					*if (strength>=30)
						She is thrown backward and her head bounces off the cobblestone.  Blood runs from her ears as she convulses from a cracked skull.
						*if (showstats)
							*line_break
							(Strength +2)
						*set strength +2
						*goto Fight_Red_Round3_FreeAttack
					She stumbles backward, but keeps her balance.  She likely won't give you another opportunity like that one.
					*if (showstats)
						(Needed 30 Strength)
					*goto Fight_Red_Round4
				#Cast a spell to shoot a spike of stone, but aim it at Selina instead.
					The spike appears in your hand, but ${prisoner1_name} is ready for it.  When you turn and throw it at Selina instead, she is caught entirely off-guard.
					*if (magic<40)
						Unfortunately, you must have said a wrong word because the spike crumbles to dust when it hits her.  She likely won't give you another opportunity like that one.
						*if (showstats)
							(Needed 40 Magic)
						*goto Fight_Red_Round4
					The spike pierces her chest and she falls to the ground clutching the rocky protrusion sticking out of her.
					*if (showstats)
						*line_break
						(Magic +2)
					*set magic +2
					*goto Fight_Red_Round3_FreeAttack
		#Focus all of your attention on ${prisoner1_name}.
			Although it was tempting to attack Selina, you know that it would be foolish to let down your guard.  Instead, you focus on ${prisoner1_name}.
			*goto Fight_Red_Round4
			
	*label Fight_Red_Round3_FreeAttack
	
	*label Fight_Red_Round3_FreeAttack_ns
	${prisoner1_name} lowers ${prisoner1_hisher} guard and stumbles toward her, watching the death in surprise and leaving ${prisoner1_himher}self wide open for an attack.
	*set selina_hurt true
	*choice
		*if ((sword) or (dagger)) #Use the distraction to strike at ${prisoner1_name}.
			*if (blades>=40)
				The double distraction works great, allowing you to slice a long cut across ${prisoner1_name}'s
				*set red_health -35
				*if (red_health>0)
					chest.
				*if (red_health<=0)
					stomach, spilling ${prisoner1_hisher} guts onto the stones!  $!{prisoner1_heshe} wobbles unsteadily and falls to the ground, dead.
				*if (showstats)
					*line_break
					(${prisoner1_name} Health -35 to ${red_health} / 100)
				*goto Fight_Red_Round4
			*else
				${prisoner1_name} sees it coming and steps back just in time.
				*if (showstats)
					(Needed 40 Blades)
				*goto Fight_Red_Round4
		#Use the distraction to spray fire across ${prisoner1_name}'s back.
			*if (magic>=40)
				The double distraction works great, allowing you time to complete the spell and cover ${prisoner1_name} with fire.
				*set red_health -35
				*if (red_health>0)
					$!{prisoner1_name} roars in pain and turns back to you.
				*if (red_health<=0)
					The smell of burning flesh fills the air as ${prisoner1_name} falls to the ground, dead.
				*if (showstats)
					*line_break
					(${prisoner1_name} Health -35 to ${red_health} / 100)
				*goto Fight_Red_Round4
			*else
				Instead of fire, all you get is a little smoke and a burned finger.
				*if (showstats)
					(Needed 40 Magic)
				*goto Fight_Red_Round4
		#Use the distraction to jump onto ${prisoner1_name}'s back and put ${prisoner1_himher} into a choke hold.
			The double distraction works great, allowing you to wrap your arms around ${prisoner1_hisher} neck and squeeze.
			*if (unarmed>=40)
				*set red_health -35
				*if (red_health>0)
					${prisoner1_name} struggles under your grip and breaks free before going unconscious.
				*if (red_health<=0)
					${prisoner1_name}'s eyes bulge as you choke the life from ${prisoner1_himher}.  After a few moments, ${prisoner1_heshe} stops struggling and dies in your arms.
				*if (showstats)
					*line_break
					(${prisoner1_name} Health -35 to ${red_health} / 100)
				*goto Fight_Red_Round4
			*else
				${prisoner1_name} breaks the hold almost immediately and turns back to you.
				*if (showstats)
					(Needed 40 Unarmed)
				*goto Fight_Red_Round4
*else
	*goto Fight_Red_Round4

*label Fight_Red_Round4
*if (red_health<=0)
	*goto Red_is_Dead
*choice
	#Call to the watching soldiers and tell them to attack ${prisoner1_name}.
		This is war and good strategy means fighting as a team.
		*if (citizen_reputation>=50)
			Two men come forward, ready to help you.
			*if (selina_hurt=false)
				Selina moves to intercept them.  She is a good swordsman and very fast.  She dances in quickly and flicks her sword out.  She nicks one of the soldiers and then grazes another.  The soldiers are well trained and dodge only as far as necessary, knowing that her strikes don't have enough reach to do any real damage.  Their training never considered that their opponents might use a strong paralysing poison against them, however.  Their movements become sluggish, allowing Selina to get past their guard and kill them easily.
				*goto Fight_Red_Round5
			*if (prisoner1_name=theothea_name)
				${prisoner1_name} smashes one of the soldiers with ${prisoner1_hisher} hammer, but the other comes in from behind and jams his sword into ${prisoner1_name}'s side.
			*if (prisoner1_name=peterpetra_name)
				${prisoner1_name} smashes one of the soldiers with ${prisoner1_hisher} morningstar, but the other comes in from behind and jams his sword into ${prisoner1_name}'s side.
			*if (prisoner1_name=gillgale_name)
				${prisoner1_name} slices one of the soldiers with both of ${prisoner1_hisher} swords, but the other comes in from behind and jams his sword into ${prisoner1_name}'s side.
			*if (prisoner1_name=karlkarla_name)
				${prisoner1_name} kills the first man with an arrow to the eye, but the second reaches ${prisoner1_himher} and jams his sword into ${prisoner1_name}'s side.
			*if (prisoner1_name=jacejess_name)
				${prisoner1_name} cuts one of the soldiers nearly in half with a beam of light, but the other closes the distance and jams his sword into ${prisoner1_name}'s side.
			*set red_health -35
			*if (red_health<=0)
				$!{prisoner1_heshe} falls to the ground.
			*if (showstats)
				*line_break
				(${prisoner1_nickname} Health -35 to ${red_health} / 100)
			*if (red_health<=0)
				*goto Red_is_Dead
			*if (prisoner1_name=theothea_name)
				${prisoner1_name}'s hammer strikes again, killing the other soldier too.
			*if (prisoner1_name=peterpetra_name)
				${prisoner1_name}'s morningstar strikes again, killing the other soldier too.
			*if (prisoner1_name=gillgale_name)
				${prisoner1_name}'s swords strike again, killing the other soldier too.
			*if (prisoner1_name=karlkarla_name)
				${prisoner1_name} fires a second arrow at point-blank range, killing the other soldier too.
			*if (prisoner1_name=jacejess_name)
				${prisoner1_name}'s light beam moves onto the other soldier and kills him too.
			*if (showstats)
				*line_break
				(${prisoner1_nickname} Health -35 to ${red_health} / 100)
			*goto Fight_Red_Round5
		*else
			Unfortunately, none of the soldiers watching meet your eyes or come to your aid.
			*if (showstats)
				(Needed 50 Citizen Reputation)
			*goto Fight_Red_Round5
	#Honourably fight ${prisoner1_name} one-on-one and wave your soldiers back.
		It would be cowardly to team up on an opponent.  Your soldiers stand back and watch you fight.  You see that a large crowd has formed to see who will win the great battle.
		*if (showstats)
			*line_break
			(Good +10 and Citizen Reputation +10)
		*set good +10
		*set citizen_reputation +10
		*goto Fight_Red_Round5

*label Fight_Red_Round5

You and ${prisoner1_name} continue to circle one another, looking for an opening.
*if (prisoner1_name=theothea_name)
	${prisoner1_heshe} decides to use ${prisoner1_hisher} great strength against you.  $!{prisoner1_heshe} throws ${prisoner1_hisher} hammer at your head, and as you duck, ${prisoner1_heshe} rushes forward and scoops you up in a large bear hug, pinning your arms to your sides!
	*choice
		#Fight your way free.
			You push and struggle against the enormous crushing weight that the mountain-${theothea_manwoman} is able to apply against you.
			*if (jeckel_potion)
				You feel the effects of Mazrim's potion surge within you.  Your muscles stretch and bulge against the fabric of your sleeves!
				*goto Round5_TheoTheaWin
			*if ((strength>=50) and (endurance>=50))
				*label Round5_TheoTheaWin
				You finally break ${prisoner1_hisher} hold and step back.
				*if (showstats)
					(Strength +2 and Endurance +2)
				*goto Fight_Red_Round6
			*else
				Unfortunately, it is too great.
				*label Round5_TheoThea_Fail
				You feel a few ribs break as ${prisoner1_heshe} squeezes you tighter.
				*set health -20
				*if (health>0)
					Thinking that you have passed out, ${prisoner1_name} drops you to the ground.  You struggle to take a breath and slowly get back to your feet.
				*if (showstats)
					(Needed 50 Strength and 50 Endurance)
					*line_break
					(Health -20 to ${health} / 100)
				*goto Fight_Red_Round6
		*if (vampire) #Bare your vampiric fangs and bite ${prisoner1_name}'s neck.
			The watching soldiers see you bite deeply, but they don't see your sharp fangs as they bury into ${prisoner1_name}'s neck.  They also don't see you swallow some of the blood as it trickles down your throat.  ${prisoner1_name} is quick to release you.  You step back and wipe the blood from your lips as your fangs retract once more.
			*goto Fight_Red_Round6
		#Play dead and allow ${prisoner1_name} to squeeze you.
			*goto Round5_TheoThea_Fail
*if (prisoner1_name=peterpetra_name)
	${prisoner1_name} suddenly steps back, lowers ${prisoner1_hisher} morningstar and begins saying a deep and dark prayer.  You feel the chill of it through your bones and realize that ${prisoner1_heshe} is attempting to drain the life out of you!  You can feel terror building as both Noct and Shadi turn Their foul attention toward you.
	*if ((god_name="Shadi") or (god_name="Noct"))
		You aren't surprised to find your own ${god_goddess} punishing you.  ${god_name} helps the strong and if the ${prisoner1_nickname} proves stronger than you, you will be killed for your weakness.
	*choice
		#Fight your way free.
			*label Round5_PeterPetra_Struggle
			You struggle against the terror and coldness that fills your body.
			*if ((endurance>=50) and (religion>=50))
				Sweat beads upon your forehead as you fight the effects of the terrible prayer.  Slowly, you feel warmth come back and the dread lifts.
				*if (round5_prayer_bonus_given=false)
					*if (showstats)
						(Religion +2 and Endurance +2)
					*set religion +2
					*set endurance +2
				*goto Fight_Red_Round6
			*else
				Unfortunately, it is too great.  You fall to your knees as your skin begins to rot before your eyes.  The pain becomes unbearable and you fall to the ground.
				*set health -20
				*if (health>0)
					Thinking that you have passed out, ${prisoner1_name} stops the prayer.  Shaking from the ordeal, you slowly get back to your feet.
				*if (showstats)
					(Needed 50 Religion and 50 Endurance)
					*line_break
					(Health -20 to ${health} / 100)
				*goto Fight_Red_Round6
		*if (god_heshe="It") #Pray to the Unknown God for salvation.
			You learned of the Unknown God by finding an amulet which allowed It to subvert and steal the souls being sent to other Gods and Goddesses.  You aren't surprised when It helps you to battle Noct and Shadi by forcing Them to let go of Their hold on you, causing ${prisoner1_name}'s prayer to fail.
			*if (showstats)
				*line_break
				(Religion +2)
			*set religion +2
			*goto Fight_Red_Round6
		*if (god_heshe!="It") #Pray to the good Gods for salvation.
			*if ((class_priest>0) and (god_good=false))
				Your holy symbol crumbles to dust on your chest as ${god_name} leaves you for your lack of faith.  The pain increases even stronger as Noct and Shadi torment you further.
				*if (showstats)
					*line_break
					(Lost Holy Symbol and Lost All $!{priestpriestess} and Cleric Levels)
				*set holysymbol false
				*set class_priest 0
				*set class_cleric 0
				*set exevilpriest true
				
				*goto Round5_PeterPetra_Struggle
			*if ((class_priest>0) and (good<55))
				The tenants of your faith are suddenly called into question and found lacking.  ${god_name} sees your struggle, but due to the choices you made in life, ${god_heshe} leaves you to your fate.  You feel your holy symbol crumble to dust on your neck.
				*if (showstats)
					(Needed 55 Good)
					*line_break
					(Lost Holy Symbol and Lost All $!{priestpriestess} and Cleric Levels)
				*set holysymbol false
				*set class_priest 0
				*set class_cleric 0
				*set exgoodpriest true
				
				*goto Round5_PeterPetra_Struggle
			*if (holysymbol=false)
				Your lack of faith through the good times in your life now plagues you as the good Gods and Goddesses of the world leave you to fend for yourself.
				*goto Round5_PeterPetra_Struggle
			${god_name} listens to your pleas and you feel ${god_hisher} strength fill your body.  The minds of Gods are not for mortals to understand.  The combined might of Shadi and Noct continue to work upon you, but you have been made stronger in order to withstand their punishment.
			*if (showstats)
				*line_break
				(Good +5, Religion +2 and Endurance +2)
			*set good +5
			*set religion +2
			*set endurance +2
			*set round5_prayer_bonus_given true
			
			*goto Round5_PeterPetra_Struggle
		*if (god_heshe!="It") #Pray to the evil Gods for mercy.
			*if ((class_priest>0) and (god_good))
				Your holy symbol crumbles to dust on your chest as ${god_name} leaves you for your lack of faith.  The pain increases even stronger as Noct and Shadi torment you further.
				*if (showstats)
					*line_break
					(Lost Holy Symbol and Lost all $!{priestpriestess} and Cleric Levels)
				*set holysymbol false
				*set class_priest 0
				*set class_cleric 0
				*set exevilpriest true
				
				*goto Round5_PeterPetra_Struggle
			*if ((class_priest>0) and (good>45))
				The tenants of your faith are suddenly called into question and found lacking.  ${god_name} sees your struggle, but due to the choices you made in life, ${god_heshe} leaves you to your fate.  You feel your holy symbol crumble to dust on your neck.
				*if (showstats)
					(Needed 65 Evil)
					*line_break
					(Lost Holy Symbol and Lost all $!{priestpriestess} and Cleric Levels)
				*set holysymbol false
				*set class_priest 0
				*set class_cleric 0
				*set exevilpriest true
				
				*goto Round5_PeterPetra_Struggle
			*if (holysymbol=false)
				Your lack of faith through the good times in your life now plagues you as the evil Gods and Goddesses of the world leave you to fend for yourself.
				*goto Round5_PeterPetra_Struggle
			${god_name} listens to your pleas and you feel ${god_hisher} strength fill your body.  The minds of Gods are not for mortals to understand.  Shadi and Noct do not grant mercy, favouring the strong over the weak.  They continue to work upon you, despite also helping you.
			*if (showstats)
				*line_break
				(Evil +5, Religion +2 and Endurance +2)
			*set good -5
			*set religion +2
			*set endurance +2
			*set round5_prayer_bonus_given true
			
			*goto Round5_PeterPetra_Struggle
*if (prisoner1_name=karlkarla_name)
	${prisoner1_name} suddenly steps back and pulls out the last few arrows from ${prisoner1_hisher} quiver.  Wasting no time, ${prisoner1_heshe} sends one last deadly barrage toward you.
	*choice
		#Dodge the arrows.
			*label Round5_KarlKarla_Struggle
			All of the arrows are in the air at the same time.
			*if (belt_of_speed)
				Thuja's belt suddenly glows brightly for you, allowing you to move between them with ease.
				*goto Round5_KarlKarlaWin
			*if ((agility>=50) and (perception>=50))
				*label Round5_KarlKarlaWin
				You are thankful to see the last arrow narrowly miss you, leaving ${prisoner1_name} without any ammunition.
				*if (showstats)
					(Agility +2 and Perception +2)
				*set agility +2
				*set perception +2
				*goto Fight_Red_Round6
			*else
				Unfortunately, there are simply too many!  You feel one in your leg, one in your arm and one in your side.
				*set health -20
				*if (health>0)
					Finally running out of arrows, ${prisoner1_name} lowers ${prisoner1_hisher} bow as you waver unsteadily on your feet.
				*if (showstats)
					(Needed 50 Agility and 50 Perception)
					*line_break
					(Health -20 to ${health} / 100)	
				*goto Fight_Red_Round6
		*if (magic_shield) #Raise your magic shield.
			The arrows bounce harmlessly off of the surface.  It performs better than a normal shield.  It is as though the arrows are actually drawn to its centre, making sure that ${prisoner1_name} can't hit any exposed flesh.
			*goto Round5_KarlKarlaWin
		#Run away into the crowd of onlookers.
			${prisoner1_name} has no guilt over killing anyone between you and ${prisoner1_heshe}.  Your soldiers and Selina's troops alike fall to the ground with arrows in their chests as ${prisoner1_heshe} seeks you out.
			*if (showstats)
				*line_break
				(Citizen Reputation -5)
			*set citizen_reputation -5
			
			*goto Round5_KarlKarla_Struggle
*if (prisoner1_name=jacejess_name)
	The white streak through ${prisoner1_hisher} black hair gets even wider as the Soulburner builds one last enormous surge of killing light.  You don't know if it will come out as a single blast, a fan-shape or as a moving ray.  You have never seen ${prisoner1_himher} try to harness so much energy at once before.
	*choice
		#Study ${prisoner1_name} and attempt to dodge the blast when it comes.
			*label Round5_JaceJess_Struggle
			You know that if you guess the form of the attack incorrectly, you may be killed.
			*if ((perception>=50) and (arcana>=50))
				*label Round5_JaceJessWin
				At the last moment, you see that it will be a series of pulses.  Instead of ducking, jumping or throwing yourself to the ground, you run in a straight line.  The pulses narrowly miss you as your one-direction momentum doesn't allow ${jacejess_name} to hit you.
				*if (showstats)
					(Arcana +2 and Perception +2)
				*set arcana +2
				*set perception +2
				*goto Fight_Red_Round6
			*else
				Unfortunately, you guess it wrong.  You throw yourself to the ground, allowing the first pulse of white light to soar harmlessly over you.  But the next one grazes you and despite your roll, the third one hits your back.
				*set health -20
				*if (health>0)
					You slowly return to your feet, despite the pain.
				*if (showstats)
					(Needed 50 Arcana and 50 Perception)
					*line_break
					(Health -20 to ${health} / 100)
				*goto Fight_Red_Round6
		*if (magic_shield) #Raise your magic shield.
			${prisoner1_name}'s magical blasts hit in a series of three pulses.  You feel the burning heat warp around your shield, narrowly keeping you safe from harm from behind it.
			*goto Fight_Red_Round6
		*if (belt_of_speed) #Allow Thuja's belt to help you dodge the beams.
			You realize that you could never have dodged the beams without the magic of the belt, but with it, the three pulses of brilliant white light miss you.  The belt stops glowing almost immediately afterwards.
			*goto Fight_Red_Round6
		#Run away into the crowd of onlookers.
			${prisoner1_name} has no guilt over killing anyone between you and ${prisoner1_heshe}.  Your soldiers and Selina's troops alike fall to the ground with burning holes in their chests as ${prisoner1_heshe} seeks you out.
			*if (showstats)
				*line_break
				(Citizen Reputation -5)
			*set citizen_reputation -5
			
			*goto Round5_JaceJess_Struggle
*if (prisoner1_name=gillgale_name)
	${prisoner1_name}'s two swords twirl through the air independently of each other.  It is more like fighting two people than just one.  With an amazing feat of acrobatics, you see ${prisoner1_name} jump upwards toward you and tuck into a roll as ${prisoner1_heshe} soars over your head.  $!{prisoner1_heshe} lands lightly and springs back toward you with both blades extended.  Off balance and out of position, your only chance is to feint in one direction and hope that ${prisoner1_name} leaps to the other!
	*choice
		#Feint left, but move right.
			*goto Round5_GillGale_Struggle
		#Feint right, but move left.
			*label Round5_GillGale_Struggle
			You put everything into your deception.  Darting your eyes, turning your head and moving your feet.
			*if ((charm>=50) and (agility>=50))
				*label Round5_GillGaleWin
				You trick the ${prisoner1_nickname}, narrowly dodging the twin blades as ${prisoner1_heshe} sails through the air in the wrong direction.  $!{prisoner1_heshe} twists in mid-air in an attempt to recover, but the motion takes ${prisoner1_hisher} feet from under ${prisoner1_himher} and ${prisoner1_heshe} falls roughly, ${prisoner1_hisher} swords clattering loose from ${prisoner1_hisher} hands.
				*if (showstats)
					(Charm +2 and Agility +2)
				*set charm +2
				*set agility +2
				*goto Fight_Red_Round6
			*else
				Unfortunately, you guess it wrong.  You feel both blades slice deeply across your neck and down your shoulder.
				*set health -20
				*if (showstats)
					(Needed 50 Charm and 50 Agility)
					*line_break
					(Health -20 to ${health} / 100)
				*goto Fight_Red_Round6

*label Fight_Red_Round6
*if (health<=0)
	*goto Final_Battle_Knocked_Out
*comment Red has disadvantage, use it!

*if (prisoner1_name=theothea_name)
	${prisoner1_name} stands before you without ${prisoner1_hisher} hammer.
*if (prisoner1_name=peterpetra_name)
	${prisoner1_name} stands before you with shield and morningstar lowered after having cast the divine spell.
*if (prisoner1_name=karlkarla_name)
	${prisoner1_name} stands before you, out of arrows.
*if (prisoner1_name=jacejess_name)
	${prisoner1_name} stands before you, exhausted and out of magic.
*if (prisoner1_name=gillgale_name)
	${prisoner1_name} gets back to ${prisoner1_hisher} feet and stands before you with no weapons.
*choice
	*if (sword) #Stab ${prisoner1_himher} with your sword.
		*goto Round6_Blades
	*if (dagger) #Stab ${prisoner1_himher} with your dagger.
		*label Round6_Blades
		Your blade digs deeply into ${prisoner1_hisher}
		*set red_health -35
		*if (red_health<=0)
			chest and ${prisoner1_heshe} falls to the ground, dead.
			*if (showstats)
				*line_break
				(${prisoner1_nickname} Health -35 to 0 / 100)
			*goto Red_is_Dead
		stomach.  It should have killed ${prisoner1_himher}, but somehow, ${prisoner1_heshe} keeps going.
		*if (showstats)
			*line_break
			(${prisoner1_nickname} Health -35 to ${red_health} / 100)
		*goto Fight_Red_Round7
	#Put your hands around ${prisoner1_himher} neck and squeeze.
		Your hands tighten around ${prisoner1_hisher} neck and you see ${prisoner1_hisher} eyes bulge as you try to strangle the life out of ${prisoner1_himher}.
		*set red_health -35
		*if (red_health<=0)
			${prisoner1_name} tries to break free, but after a few moments of struggling, ${prisoner1_heshe} falls to the ground.  You see the blank stare indicating that ${prisoner1_heshe} is dead.
			*if (showstats)
				*line_break
				(${prisoner1_nickname} Health -35 to 0 / 100)
			*goto Red_is_Dead
		${prisoner1_name} manages to break free and gasp for air.
		*if (showstats)
			*line_break
			(${prisoner1_nickname} Health -35 to ${red_health} / 100)
		*goto Fight_Red_Round7
	#Cast a spell to set ${prisoner1_himher} on fire.
		It doesn't take any skill to complete the spell, since ${prisoner1_heshe} is helpless before you.  The fire erupts around ${prisoner1_himher}, but ${prisoner1_heshe} doesn't cry out.
		*set red_health -35
		*if (red_health<=0)
			After a moment, the blackened corpse that had been ${prisoner1_name} falls to the ground.
			*if (showstats)
				*line_break
				(${prisoner1_nickname} Health -35 to 0 / 100)
			*goto Red_is_Dead
		The fire subsides after a moment, leaving ${prisoner1_himher} burned, but not dead.
		*if (showstats)
			*line_break
			(${prisoner1_nickname} Health -35 to ${red_health} / 100)
		*goto Fight_Red_Round7
	*if ((bow) or (class_elementalarcher>0)) #Shoot ${prisoner1_himher} with an arrow.
		*if (class_elementalarcher>0)
			You draw your Astral Bow and create an arrow of stone.
		The arrow plunges deeply into ${prisoner1_hisher}
		*set red_health -35
		*if (red_health<=0)
			heart and ${prisoner1_heshe} falls to the ground, dead.
			*if (showstats)
				*line_break
				(${prisoner1_nickname} Health -35 to 0 / 100)
			*goto Red_is_Dead
		chest, but ${prisoner1_heshe} doesn't fall.
		*if (showstats)
			*line_break
			(${prisoner1_nickname} Health -35 to ${red_health} / 100)
		*goto Fight_Red_Round7
	#Say, "I won't kill you, ${prisoner1_name}."
		You see ${prisoner1_himher} blink slowly as your words slowly penetrate ${prisoner1_hisher} addled brain.
		*if (showstats)
			*line_break
			(${prisoner1_name} Relationship +15)
		*set prisoner1_relationship +15
		*gosub set_prisoner1_relationship
		*goto Fight_Red_Round7

*label Fight_Red_Round7

*if (selina_hurt=false)
	Selina moves quickly, bringing her sword down toward you.  You raise your hands in defence and receive only a small nick on the wrist from the attack.  Selina steps back and smiles.
*if (selina_hurt)
	${prisoner1_name} drops to ${prisoner1_hisher} knees.  You aren't sure if ${prisoner1_heshe} is dying or simply giving up.  There is a flash of light and you feel a slight sting across your arm.  ${prisoner1_name} is holding Selina's short sword and has cut you lightly.
Within moments, you feel the poison of the blade seeping into you.
*set got_poisoned true
*choice
	*if (class_alchemist>0) #Drink a potion of anti-venom from your bandoleer.
		As an alchemist, you made many such antidotes.  You feel the competing chemicals battle in your blood.  After a few seconds, you feel much better.
		*set got_poisoned false
		*goto Fight_Red_Round8
	*if (class_monk>0) #As a monk, slow your metabolism and suck out the poison.
		You have learned to slow your breathing and heart rate.  It is a race against time as you suck out the poison and spit, while slowing the rest of the poison from reaching your heart.
		*if (class_monk>=3)
			You feel better almost immediately.		
			*set got_poisoned false
			*goto Fight_Red_Round8
		*set health -20
		*if (health>0)
			Although you get most of the poison out, you can still feel the damage to your system.
		*if (health<=0)
			Unfortunately, you aren't fast enough.
		*if (showstats)
			(Needed 3 Levels in Monk)
			*line_break
			(Health -20 to ${health} / 100)
		*if (health<=0)
			*goto Final_Battle_Knocked_Out
		*set got_poisoned false
		*goto Fight_Red_Round8
	*if (class_druid>0) #As a druid, allow the poison to be absorbed harmlessly into your system.
		Poison is found all through nature from plants to animals.  You concentrate upon it and attempt to make it harmless.
		*if (class_druid>=3)
			You feel better almost immediately.		
			*set got_poisoned false
			*goto Fight_Red_Round8
		*set health -20
		*if (health>0)
			Although you get most of the poison out, you can still feel the damage to your system.
		*if (health<=0)
			Unfortunately, you aren't fast enough.
		*if (showstats)
			(Needed 3 Levels in Druid)
			*line_break
			(Health -20 to ${health} / 100)
		*if (health<=0)
			*goto Final_Battle_Knocked_Out
		*set got_poisoned false
		*goto Fight_Red_Round8
	#Cast a spell of healing.
		*if (class_priest>0)
			*set got_poisoned false
			As a ${priestpriestess}, such spells are within your grasp.  You call out to ${god_name} and feel the poison
			*if (class_priest>=3)
				*if (god_good)
					gently purged
				*if (god_good=false)
					burned violently
				from your system.
				*goto Fight_Red_Round8
			*else
				*if (magic>=90)
					lessen and disappear entirely.
					*set got_poisoned false
					*if (showstats)
						*line_break
						(Magic +2)
					*set magic +2
					*goto Fight_Red_Round8
				lessen.
				*set health -20
				*if (health>0)
					You feel weak from the ordeal, but at least you are still alive.
				*if (health<=0)
					Although the poison is gone, the damage to your body still causes you to pass out.
				*if (showstats)
					(Needed 3 Levels in $!{priestpriestess} or 90 Magic)
					*line_break
					(Health -20 to ${health} / 100)
				*if (health<=0)
					*goto Final_Battle_Knocked_Out
				*goto Fight_Red_Round8
		Such spells are the domain of divine magic, but since you follow no religious order, you are forced to work with the arcane arts.
		*if (magic<40)
			Unfortunately, such a spell is beyond your grasp.
			*label Round7_Failed_By_Magic
			You feel the burning sensation almost immediately as the poison courses through your blood.
			*set health -20
			*if (health>0)
				When it doesn't get any worse, you realize that you will be okay.
			*if (showstats)
				(Needed 90 Magic)
				*line_break
				(Health -20 to ${health} / 100)
			*if (health<=0)
				*goto Final_Battle_Knocked_Out
			*goto Fight_Red_Round8
		*set got_poisoned false
		You work the spell and feel it taking effect.  Your blood boils within your veins and the poison slowly exhausts itself.
		*if (magic<90)
			*set health -20
			*if (health>0)
				The pain is intense, but it slowly subsides.
			*if (health<=0)
				It is a case of the cure being as bad as the ailment.  Although the poison is gone, the pain of the magic knocks you unconscious.
			*if (showstats)
				(Needed 90 Magic)
				*line_break
				(Health -20 to ${health} / 100)
			*if (health<=0)
				*goto Final_Battle_Knocked_Out
			*goto Fight_Red_Round8
		*if (showstats)
			*line_break
			(Magic +2)
		*set magic +2
		*goto Fight_Red_Round8
	#Grit your teeth and hope that the cut was too small to have gotten very much poison into your system.
		You feel the burning sensation almost immediately as the poison courses through your blood.
		*if (endurance>=60)
			Your hardiness allows you to fight through the pain and soon you feel normal again.  You were lucky that it was such a small cut.
			*if (showstats)
				*line_break
				(Endurance +2)
			*set endurance +2
			*set got_poisoned false
			*goto Fight_Red_Round8
		You feel the burning sensation almost immediately as the poison courses through your blood.
		*set health -20
		*if (health>0)
			When it doesn't get any worse, you realize that you will be okay.  You were lucky that it was such a small cut.
		*if (showstats)
			(Needed 60 Endurance)
			*line_break
			(Health -20 to ${health} / 100)
		*if (health<=0)
			*goto Final_Battle_Knocked_Out
		*goto Fight_Red_Round8

*label Fight_Red_Round8

*if (selina_hurt=false)
	Selina uses the distraction of the poison to close the distance.  The deadly short sword is gripped tightly in her hands.
	*choice
		#Try to turn the blade toward Selina.
			*if ((unarmed>=70) and (red_health<=35))
				You twist the poisoned blade in her hands and slide it deeply between her ribs as ${prisoner1_name}'s injuries make ${prisoner1_himher} too slow to react in time.
				
				"Nooooo!" ${prisoner1_name} shouts as ${prisoner1_heshe} rushes forward to stop you.
				
				You draw the blade out of Selina's corpse and stab ${prisoner1_name} through the eye.  The ${prisoner1_nickname} falls to the ground right beside Selina.
				*set red_health -35
				*if (showstats)
					*line_break
					(Unarmed +3 and ${prisoner1_name} Health -35 to ${red_health} / 100)
					*set unarmed +3
				*set selina_hurt true
				*goto Red_Is_Dead
			*else
				You try to grab the blade, but ${prisoner1_name} pushes you to the ground.  Selina steps forward and lays the poisoned edge against your throat.  You realize that you have run out of options.
				*if (showstats)
					(Needed 70 Unarmed and ${prisoner1_name} Health 35 or Under)
				*goto Fight_Red_LastChance
		#Try to cast a spell to stop the poisoned blade from reaching you.
			*if ((magic>=70) and (red_health<=35))
				Your spell pushes the blade backward with such force that it slides deeply into Selina's throat as ${prisoner1_name}'s injuries make ${prisoner1_himher} too slow to react in time.
				
				"Nooooo!" ${prisoner1_name} shouts as ${prisoner1_heshe} rushes forward to stop you.
				
				You draw the blade out of Selina's corpse and stab ${prisoner1_name} through the heart.  The ${prisoner1_nickname} falls to the ground right beside Selina.
				*set red_health -35
				*if (showstats)
					*line_break
					(Magic +3 and ${prisoner1_name} Health -35 to ${red_health} / 100)
					*set magic +3
				*set selina_hurt true
				*goto Red_Is_Dead
			*else
				Your spell is interrupted as ${prisoner1_name} pushes you to the ground.  Selina rushes forward and lays the poisoned blade against your throat.  You realize that you have run out of options.
				*if (showstats)
					(Needed 70 Magic and ${prisoner1_name} Health 35 or Under)
				*goto Fight_Red_LastChance
		*if (dagger) #Raise your dagger.
			*goto Last_Chance_Blade_Selina
		*if (sword) #Raise your sword.
			*label Last_Chance_Blade_Selina
			*if ((blades>=70) and (red_health<=35))
				You hold your blade up and feel it slide deeply into Selina's ribs as ${prisoner1_name}'s injuries make ${prisoner1_himher} too slow to react in time.
				
				"Nooooo!" ${prisoner1_name} shouts as ${prisoner1_heshe} rushes forward to stop you.
				
				You draw the blade out of Selina's corpse and stab ${prisoner1_name} through the eye.  The ${prisoner1_nickname} falls to the ground right beside Selina.
				*set red_health -35
				*if (showstats)
					*line_break
					(Blades +3 and ${prisoner1_name} Health -35 to ${red_health} / 100)
					*set blades +3
				*set selina_hurt true
				*goto Red_Is_Dead
			*else
				Before you can get your blade into position, ${prisoner1_name} pushes you to the ground.  Selina rushes forward and lays the poisoned blade against your throat.  You realize that you have run out of options.
				*if (showstats)
					(Needed 70 Blades and ${prisoner1_name} Health 35 or Under)
				*goto Fight_Red_LastChance
*else
	${prisoner1_name} quickly gets back to ${prisoner1_hisher} feet and uses the distraction of the poison to close the distance.  The deadly short sword is gripped tightly in ${prisoner1_hisher} hands.
	*choice
		#Try to turn ${prisoner1_name}'s blade toward ${prisoner1_himher}.
			*if (unarmed>=70)
				*set red_health -35
				*if (red_health<=0)
					You turn the blade at the last moment and it plunges deeply into ${prisoner1_name}'s chest instead of your own.  $!{prisoner1_hisher} eyes go wide as ${prisoner1_heshe} falls to the ground.
					*if (showstats)
						*line_break
						(Unarmed +3 and ${prisoner1_name} Health -35 to ${red_health} / 100)
					*set unarmed +3
					*goto Red_Is_Dead
				You turn the blade briefly and it cuts ${prisoner1_name} across the chest, but ${prisoner1_heshe} manages to turn it back and lay it against your throat.  You realize that you have run out of options.
				*if (showstats)
					*line_break
					(Unarmed +3 and ${prisoner1_name} Health -35 to ${red_health} / 100)
				*set unarmed +3	
				*goto Fight_Red_LastChance
			*else
				*label Grab_Blade_Fail
				You try to grab the blade, but ${prisoner1_name} is too fast as ${prisoner1_heshe} lays the poisoned edge against your throat.  You realize that you have run out of options.
				*if (showstats)
					(Needed 70 Unarmed)
				*goto Fight_Red_LastChance
		#Try to pull the blade from ${prisoner1_hisher} hands.
			*if (unarmed>=70)
				You grab hold of ${prisoner1_hisher} hands in an attempt to take the sword, but ${prisoner1_heshe} manages to lay the blade against your throat before you can stop ${prisoner1_himher}.  You realize that you have run out of options.
				*if (showstats)
					*line_break
					(Unarmed +3)
				*set unarmed +3	
				*goto Fight_Red_LastChance
			*else
				*goto Grab_Blade_Fail
		#Try to cast a spell to stop the poisoned blade from reaching you.
			*if (magic>=70)
				*set red_health -35
				Your spell pushes back at ${prisoner1_name} with such force that the sword turns
				*if (red_health<=0)
					and slides deeply into ${prisoner1_hisher} chest.  $!{prisoner1_hisher} eyes go wide as ${prisoner1_heshe} falls to the ground.
					*if (showstats)
						*line_break
						(Magic +3 and ${prisoner1_name} Health -35 to ${red_health} / 100)
					*set magic +3
					*goto Red_Is_Dead
				and cuts ${prisoner1_name} across the chest.  $!{prisoner1_heshe} grits ${prisoner1_hisher} teeth through the poison and pain while pressing forward against your magic.  You feel the blade get pushed against your throat and the spell releases its hold.  You realize that you have run out of options.
				*if (showstats)
					*line_break
					(Magic +3 and ${prisoner1_name} Health -35 to ${red_health} / 100)
				*set magic +3	
				*goto Fight_Red_LastChance
			*else
				Your spell hardly even slows ${prisoner1_name} down as ${prisoner1_heshe} pushes forward and lays the poisoned blade against your throat.  You realize that you have run out of options.
				*if (showstats)
					(Needed 70 Magic)
				*goto Fight_Red_LastChance
		*if (dagger) #Raise your dagger.
			*goto Last_Chance_Blade_Red
		*if (sword) #Raise your sword.
			*label Last_Chance_Blade_Red
			*if (blades>=70)
				You hold your blade up and feel it slide deeply into ${prisoner1_name}'s ribs.
				*set red_health -35
				*if (red_health<=0)
					You see ${prisoner1_name}'s eyes go wide as ${prisoner1_heshe} falls to the ground.
					*if (showstats)
						*line_break
						(Blades +3 and ${prisoner1_name} Health -35 to ${red_health} / 100)
					*set blades +3
					*goto Red_Is_Dead
				You feel ${prisoner1_name}'s poisoned blade against your throat and realize you have run out of options.
				*if (showstats)
					*line_break
					(Blades +3 and ${prisoner1_name} Health -35 to ${red_health} / 100)
				*set blades +3	
				*goto Fight_Red_LastChance
			*else
				${prisoner1_name} pushes your blade aside and then presses ${prisoner1_hisher} own poisoned sword against your throat.  You realize that you have run out of options.
				*if (showstats)
					(Needed 70 Blades)
				*goto Fight_Red_LastChance

*label Fight_Red_LastChance
*choice
	#Say, "Do it."
		*goto Fight_Red_Conclusion
	*if (selina_hurt=false) #Turn to ${prisoner1_name} and plead, "Help me."
		*goto Fight_Red_Conclusion
	*if (selina_hurt) #Beg, "Don't do this."
		*goto Fight_Red_Conclusion
	#Say, "I surrender."
		*goto Fight_Red_Conclusion
	#Say nothing.
		*goto Fight_Red_Conclusion

*label Fight_Red_Conclusion
*if (prisoner1_relationship>=85)
	*if (selina_hurt)
		${prisoner1_name}'s hand begins to shake which causes the blade at your throat to dimple the skin.  You can see ${prisoner1_himher} having a mental fight with ${prisoner1_himher}self.  $!{prisoner1_heshe} raises ${prisoner1_hisher} other hand and places it around the bare blade, then pulls it back from your neck!  You can see blood running from ${prisoner1_hisher} hand and you know that the last of the poison is rushing into 
		*if (prisoner1_name=theothea_name)
			the mountain-${theothea_manwoman}.
		*if (prisoner1_name=peterpetra_name)
			the holy warrior.
		*if (prisoner1_name=karlkarla_name)
			the archer.
		*if (prisoner1_name=jacejess_name)
			the Soulburner.
		*if (prisoner1_name=gillgale_name)
			the rogue.
		
		"Forgive me," ${prisoner1_name} says weakly before falling to the ground as the poison stops ${prisoner1_hisher} heart.
		*if (showstats)
			*line_break
			(${prisoner1_name} Health 0 / 100)
		*goto Red_is_Dead
	*else
		*comment (selina_hurt=false)
		Selena's sword is just about to cut your throat when ${prisoner1_name} calmly reaches over and takes hold of the blade with ${prisoner1_hisher} bare hand!  You can see blood running from ${prisoner1_hisher} fist and you know that the poison will be flooding into
		*if (prisoner1_name=theothea_name)
			the mountain-${theothea_manwoman}
		*if (prisoner1_name=peterpetra_name)
			the holy warrior
		*if (prisoner1_name=karlkarla_name)
			the archer
		*if (prisoner1_name=jacejess_name)
			the Soulburner
		*if (prisoner1_name=gillgale_name)
			the rogue
		as well.  ${prisoner1_name} pulls the sword out of Selina's hand, reverses it and drives it into Selina's chest!  They both fall to the ground as the last of the poison on the blade kills both of them.
		*set selina_hurt true
		*if (showstats)
			*line_break
			(${prisoner1_name} Health 0 / 100)
		*goto Red_is_Dead
*else
	*if (selina_hurt)
		${prisoner1_name} keeps the blade against your neck and walks around behind you.  You anticipate the sharp edge slashing your throat, but instead, ${prisoner1_heshe} turns the sword around and strikes you in the back of the head with the hilt!
	*if (selina_hurt=false)
		Selena keeps the blade against your neck and walks around behind you.  You anticipate the sharp edge slashing your throat, but instead, she turns the sword around and strikes you in the back of the head with the hilt!
	*if (showstats)
		*line_break
		(Needed 85 ${prisoner1_name} Relationship)
		*line_break
		(Health 0 / 100)
	*set health 0
	*goto Final_Battle_Knocked_Out

*label Red_is_Dead

*if (selina_hurt)
	*goto Both_Are_Dead_ns
Upon seeing that her champion has fallen, Selina rushes forward with her short sword raised high, hoping to catch you by surprise.
*choice
	*if (sword) #Raise your sword to stop her.
		Your sword slides smoothly into her stomach before she can reach you.  She drops her short sword and falls backward, sliding off your blade and onto the stones at your feet.
		*if (showstats)
			*line_break
			(Blades +2)
		*set blades +2
		*goto Both_Are_Dead
	*if (dagger) #Raise your dagger to stop her.
		Your dagger slides smoothly into her heart before she can reach you.  She drops her short sword to the ground with a clatter and falls backward onto the stones at your feet.
		*if (showstats)
			*line_break
			(Blades +2)
		*set blades +2
		*goto Both_Are_Dead
	#Punch her in the throat.
		With her sword raised high, her neck is completely exposed.  You feel the soft windpipe crush under your knuckles.  Selina's eyes go wide as she stumbles backward, dropping her sword onto the stones at your feet.  She grabs her throat and falls to the ground as she chokes for breath.  After a few gurgles, she stops moving.
		*if (showstats)
			*line_break
			(Unarmed +2)
		*set unarmed +2
		*goto Both_Are_Dead
	#Cast a spell to blast her off her feet.
		*if (magic<30)
			Despite your usual miscasts, the
		*if (magic>=30)
			The
		spell completes quickly and accurately.  Selina is lifted off the ground and thrown back a few feet.  Her head smashes into the wall behind her, cracking open like an overripe melon.
		*if (showstats)
			*line_break
			(Magic +2)
		*set magic +2
		*goto Both_Are_Dead
	#Push her back.
		Selina is caught off guard as you push her.  She stumbles backwards and falls, her head smashing into the wall behind her with a loud crack.  She convulses on the ground for a few moments and then stops.
		*if (showstats)
			*line_break
			(Strength +2)
		*set strength +2
		*goto Both_Are_Dead

*label Both_Are_Dead

*label Both_Are_Dead_ns
You hear cheering erupt all around you as Selina's army begins to scatter.  Your own troops have taken the castle.  You have won the Siege of Tornassa!
*if (used_dagger)
	While your troops celebrate, you retrieve your dagger.
*achieve victory
*if (used_dagger=false)
	*if (showstats)
		*line_break
		(Citizen Reputation +10)
*if (used_dagger)
	*if (showstats)
		*line_break
		(Citizen Reputation +10 and Regained Dagger)
	*set dagger true
*set citizen_reputation +10
*set won_battle_of_tornassa true
*goto_scene theend

*label Final_Battle_Knocked_Out
*set health 0
*gosub Check_Army_Stats
*page_break Blackness…
You wake up in a dark room.  Looking down, you see that you are wearing dull black shackles with bright white glowing runes etched across them.  You feel weak and realize that you can't use your magic or reach any of your belongings, even though they have been left on your body.  The shackles do more than just stop you from moving—they also sap your strength and make it difficult to think clearly.
*if (got_poisoned)
	At least the poison seems to have run its course through your system and didn't kill you.
It is deathly quiet in your dungeon cell.  You have lost the Siege of Tornassa. 
*label Lost_Battle_In_Cell
*set black_shackles true
*set won_battle_of_tornassa false
*if (health<=0)
	*set health 10
	*if (showstats)
		(Army Size 0, Army Power 0, Army Morale 0 and Health 10 / 100)
	*goto Lost_Battle_In_Cell_2
*else
	*if (showstats)
		(Army Size 0, Army Power 0 and Army Morale 0)
	*goto Lost_Battle_In_Cell_2

*label Lost_Battle_In_Cell_2

The door to your cell opens
*if (selina_hurt)
	and you see a terrible sight.  Selina herself enters.  You could have sworn that she was dead, and although she needs support to stand, you see that she is still alive.  You wonder what kind of magic had been used to bring her back from the brink of death.
*if (selina_hurt=false)
	and Selina enters.

"I understand that Thuja had you in a similar predicament before you killed him and escaped," she says.  "Thuja was a fool.  I am not.  I have brought my bodyguard with me."

*if (grand_reveal=false)
	*set stage 6
	Standing beside Selina is the
	*gosub Prisoner1_Man_Woman
	in red.  The ${prisoner1_nickname} pushes back ${prisoner1_hisher} hood.  Although the eyes are deeply sunken and bloodshot, you recognize the face of
	*if (prisoner1_name=theothea_name)
		your first adventuring partner.  It is ${theothea_name}!
	*if (prisoner1_name=peterpetra_name)
		your childhood friend.  It is ${peterpetra_name}!
	*if (prisoner1_name=gillgale_name)
		your childhood friend.  It is ${gillgale_name}!
	*if (prisoner1_name=karlkarla_name)
		your friend from Elmvale.  It is ${karlkarla_name}!
	*if (prisoner1_name=jacejess_name)
		the Soulburner.  It is ${jacejess_name}!
*if (grand_reveal)
	You aren't surprised to see ${prisoner1_name}, the ${prisoner1_nickname}, standing next to her.
*if (prisoner1_name=theothea_name)
	Before you can say a word, the large mountain-${theothea_manwoman} drives a thick fist into your stomach, causing you to double over in pain.
	*goto Batter
*if (prisoner1_name=peterpetra_name)
	Before you can say a word, ${peterpetra_heshe} strikes you across the face with a closed fist, knocking a tooth loose.
	*goto Batter
*if (prisoner1_name=gillgale_name)
	Before you can say a word, ${gillgale_heshe} brings a knee up into your stomach, knocking the wind out of you and causing you to double over in pain.
	*goto Batter
*if (prisoner1_name=karlkarla_name)
	Before you can say a word, ${karlkarla_heshe} punches you squarely in the nose, which makes a cracking noise and causes your blood to flow.
	*goto Batter
*if (prisoner1_name=jacejess_name)
	Before you can say a word, ${jacejess_hisher} eyes turn white and you feel fire across your stomach as ${jacejess_heshe} burns your flesh.
	You dimly hear Selina laughing as the pain from the Soulburner's magic renders you
	*if (health=10)
		back
	into unconsciousness.
	*set health 0
	*goto_scene theend
*label Batter
You dimly hear Selina laughing as ${prisoner1_name} proceeds to beat you
*if (health=10)
	back
into unconsciousness.
*set health 0
*goto_scene theend

*comment ---------------------Subroutines------------------------------

*label set_prisoner1_relationship
*if (prisoner1_name=theothea_name)
	*set theothea_relationship prisoner1_relationship 
*if (prisoner1_name=peterpetra_name)
	*set peterpetra_relationship prisoner1_relationship 
*if (prisoner1_name=gillgale_name)
	*set gillgale_relationship prisoner1_relationship 
*if (prisoner1_name=karlkarla_name)
	*set karlkarla_relationship prisoner1_relationship 
*if (prisoner1_name=jacejess_name)
	*set jacejess_relationship prisoner1_relationship 
*return

*label Prisoner1_Man_Woman
*if (prisoner1_hisher="his")
	man
*if (prisoner1_hisher="her")
	woman
*return

*label Army_Use_Food
*comment Input:  food_needed
*if (army_food>=food_needed)
	*comment Has enough food.
	*if (showstats)
		*line_break
		(Army Food -${food_needed})
	*set army_food -food_needed
	*return
*temp food_used 0
*temp food_still_needed 0
*set food_used army_food
*set food_still_needed food_needed-army_food
With the lack of food, your army begins to unravel as people desert in the middle of the night.
*if (army_food<=0)
	*if (showstats)
		(Needed ${food_needed} Army Food)
		*line_break
		(Army Morale -${food_still_needed} and Army Size -${food_still_needed})
	*set army_food 0
	*set army_morale -food_still_needed
	*set army_size -food_still_needed
	*gosub Check_Army_Stats
	*return
*else
	*if (showstats)
		(Needed ${food_needed} Army Food)
		*line_break
		(Army Food -${food_used}, Army Morale -${food_still_needed} and Army Size -${food_still_needed})
	*set army_food 0
	*set army_morale -food_still_needed
	*set army_size -food_still_needed
	*gosub Check_Army_Stats
	*return

*label Check_Army_Stats
*if (army_morale<=0)
	*set army_morale 0
*if (army_size<0)
	*set army_size 0
*if (army_food<0)
	*set army_food 0
*if (army_power<0)
	*set army_power 0
*if (citizen_reputation<0)
	*set citizen_reputation 0
*if (army_delays<0)
	*set army_delays 0
*return
