*comment Copyright 2015 by Mike Walter
*comment The Lost Heir 2:  Forging a Kingdom
*comment Scene #9: theend.txt
*comment 4147 Words - 626 achievements = 3.5 k
*temp count_stones 0
*if (demonstone_xiatta)
	*set count_stones +1
*if (demonstone_brahl)
	*set count_stones +1
*if (demonstone_zonch)
	*set count_stones +1
*if (demonstone_daanda)
	*set count_stones +1
*if (demonstone_tyborr)
	*set count_stones +1
*if (demonstone_gaabon)
	*set count_stones +1
*if (won_battle_of_tornassa)
	*page_break Aftermath
	*set stage 5
	*set health 100
	*set army_size 100
	*set army_morale 100
	*set army_power 100
	Your soldiers have no trouble taking the castle after that.  A lot of good people died that day, but as the hours go by, each of your companions
	*if (squire_name!="None")
		and your squire
	are found alive and well.
	*if (mount_name!="None")
		${mount_name}, your ${mount_type}, is brought to the castle and placed in the royal stables.
	The winter months are filled with many projects as the city's defences are restored and your army is filled to capacity.
	*if (mc_pregnant)
		The child in your womb continues to grow as the days go by.
	*if (lover_pregnant)
		The child in ${lover_name}'s womb continues to grow as the days go by.
	*if (child_egg)
		Your child in the magical sphere continues to grow as the days go by.
	
	Spring finds you sitting in a large tent just outside of Tornassa's walls awaiting Duke Bandar with your army arrayed neatly on the walls behind you.  It is merely a formality, since the ruler of the Bandar duchy has no army.  The broad shouldered duke enters the tent with a small honour guard around him.  Your own honour guard is much larger and contains many of your companions.
	*if (eddan_betrayed)
		You are surprised that he would agree to the meeting, considering what you did to Duke Eddan.
	*choice
		#Say, "Greetings, Duke Bandar."
			The duke nods solemnly to you.
			
			"Greetings, Your Highness,"
			*goto Victory_End_2
		#Say, "Sign the surrender.  I will offer you no terms."
			"I understand, Your Highness,"
			*goto Victory_End_2
		#Say, "I'm going to hang you when this is over."
			The duke grimaces at your words, but bravely he enters the tent anyway.  He knows that with your army, his life is forfeit no matter what he does.
			
			"Please, just make it quick, Your Highness,"
			*goto Victory_End_2
	*label Victory_End_2
	he says as he sits down at the table across from you.
	
	This treaty will help to legitimize your claim to the throne, although at this point, it isn't really needed.  He signs the legal documents that have been put on the table in front of him.  One of his attendants steps to his side and places his arm around the duke in what you think is a consolatory gesture, until you see the duke's eyes go wide in surprise.  You immediately notice two things at once.  The first is the knife protruding from the duke's back as the attendant drives the blade deeply into his body.  The other is the identity of the man.  It is none other than Alexander Zusak, high-chancellor of the Consortium of Planewalkers…the man responsible for murdering your parents and tearing Daria apart!
	
	"The Academy wants to paint demon summoning as a great evil," he says with a grin, showing you his perfect white teeth.  "So what the hells, I might as well dabble in a little necromancy too."
	*page_break Betrayal
	Duke Bandar slumps in the chair and a dark black shadow erupts from his chest.
	*if ((companion_type="Shade") and (companion_name!="None"))
		The process is not very different from how you summoned ${companion_name}, your Shade.
	Zusak points toward your runebag and the shadow flies forward like a black lightning bolt.  It tears through the fabric, spilling
	*if (count_stones=0)
		the remaining Demonstone to the floor.  The shadow fades away, its purpose fulfilled.  Zusak dives forward and grabs the stone he stole so many years before.
	*if (count_stones>0)
		your Demonstones to the floor.  The shadow fades away, its purpose fulfilled.  Zusak dives forward and grabs the stone he stole so many years before,
		*if (count_stones=1)
			ignoring the other one entirely.
		*if (count_stones>1)
			ignoring the others entirely.
	*set runebag false
	*set demonstone_kgirr false
	
	"K'Girr, I summon thee!" he shouts before anyone can do anything.
	
	You feel a great shaking and your soldiers begin to yell in fear.  An enormous black leathery creature the size of a two-storey house grows between you and Zusak, pushing you both back.  The demon is larger than any you have seen before.  It sits on the ground and turns its massive head toward Zusak as it is bound to the high-chancellor's will.
	
	"Bring me Bozar!" Zusak commands.
	
	The enormous demon nods its haystack-sized head.  Suddenly a second demon appears.  This one is much smaller, perhaps only six inches tall.
	
	"Shield me!" Zusak says.
	
	A glimmering bubble suddenly appears around Zusak and the small demon, which crawls onto his shoulder.  You realize that he has summoned a demon without using a Demonstone.  Or rather, K'Girr, the enormous demon, has done so for him.  And even worse, there had been no battle of wills with the smaller demon.
	*choice
		*if ((bow) or (class_elementalarcher>0)) #Fire an arrow at Zusak.
			The arrow bounces harmlessly off of his shield.
			*goto Victory_End_3
		*if ((bow) or (class_elementalarcher>0)) #Fire an arrow at K'Girr.
			The arrow is as harmless as an insect bite to the giant demon.
			*goto Victory_End_3
		*if (sword) #Swing your sword at Zusak.
			Your blade bounces harmlessly off of his shield.
			*goto Victory_End_3
		*if (sword) #Swing your sword at K'Girr.
			Your blade is as harmless as an insect bite to the giant demon.
			*goto Victory_End_3
		*if (dagger) #Stab Zusak with your dagger.
			Your blade bounces harmlessly off of his shield.
			*goto Victory_End_3
		*if (dagger) #Stab K'Girr with your dagger.
			Your blade is as harmless as an insect bite to the giant demon.
			*goto Victory_End_3
		#Cast a firebolt at Zusak.
			*if (magic<30)
				The firebolt fizzles as you make a mistake in the casting.
				*goto Victory_End_3
			The firebolt bounces harmlessly off of his shield.
			*goto Victory_End_3
		#Cast a firebolt at K'Girr.
			*if (magic<30)
				The firebolt fizzles as you make a mistake in the casting.
				*goto Victory_End_3
			The firebolt is as harmless as an insect bite to the giant demon.
			*goto Victory_End_3
		#Punch Zusak.
			Your fist bounces harmlessly off of his shield.
			*goto Victory_End_3
		#Punch K'Girr.
			Your fist is as harmless as an insect bite to the giant demon.
			*goto Victory_End_3

	*label Victory_End_3
	
	"I spent a decade trying to figure out a way to get into a runebag without destroying the Demonstones within," Zusak says calmly as your soldiers fire arrows at him, each one stopped by the shimmering shield.  "I figured that if that old bore Harmond could do it accidentally, then I could learn to do so on purpose.
	
	"Your parents knew that every demon that was brought into our world weakened the Boundary, but they had no idea why that was bad," he says lazily as he swats an imaginary piece of dust from his shoulder, all sense of his previous urgency now gone.  "K'Girr couldn't cross while the Boundary was intact, but as you see, that is no longer a problem."
	
	Zusak begins to rattle off a series of demonic names and K'Girr brings them each into existence.  They all serve him without exception.  After a moment, he doesn't even bother saying names and just asks for more servants.  Soon the light from the sun itself is darkened by the horde of demons flying overhead and the earth shakes from the number of demons walking on the ground.
	*if ((demonsummoner) and (count_stones>0))
		You get on your knees
		*if (count_stones=1)
			and grab the remaining Demonstone before jumping back to your feet.
		*if (count_stones>=2)
			and grab the remaining Demonstones before jumping back to your feet.
		*goto Victory_End_4
	*else
		*goto Victory_End_4
	
	*label Victory_End_4
	
	Your companions draw their weapons, but the shield around Zusak is impenetrable and the press of demons continues to increase.
	*if (using_legacy)
		*gosub Legacy_Endscene
		
	As Zusak summons an army into existence, you use the distraction to flee back to your castle within the city of Tornassa.
	*page_break Demon War
	You stand upon the walls of your castle as you survey the ruins of the city below you.  You don't know where Zusak has gone, but his demons are everywhere.  They have killed many of your citizens and set fire to most of the buildings of the city.  Your soldiers fight to defend the walls as summoned nightmares lay siege to the castle itself.
	*if (using_legacy)
		
		The amulet from the most powerful wizard in Daria's history still sits around your neck.  You don't know what it's capable of, but you know that a lot of energy was spent in order to get it into your hands.
	
	You have reunited Daria, but that was against human foes.  You know that it is only a matter of time before the demon horde overwhelms your defences.  Luckily you have your companions at your side and the castle of your birth under your control.  You will find a way to save the city and get to Zusak to make him pay for his crimes against humanity.
	*goto The_End
*else
	*page_break Misery
	*set health 10
	You have no idea how much time has passed from within your cell.  You know that you have been beaten senseless for several months at least.
	*if (mc_pregnant)
		The child in your womb continues to grow as the days go by, despite your injuries.
	*if (lover_pregnant)
		The child in ${lover_name}'s womb would be getting very big, assuming that ${lover_name} is still alive.
	*if (child_egg)
		Your child in the magical sphere would be getting very big, assuming that someone has managed to keep it safe.
	One day, you are led out of the dungeons by Selina and ${prisoner1_name}.  The shackles on your wrists make it difficult to keep up with them as they drain you of most of your strength and prevent you from using any of the equipment you are still wearing.  You don't know why Selina hasn't taken anything from you, but you suspect that it may be to give you hope so she can snatch it away later.
	
	You are taken through the streets of Tornassa to a small house away from the castle.  When you enter, you are surprised to see two familiar faces sitting at the table inside.  One of them is Duke Bandar, his dark beard and broad shoulders emphasizing his profile as a great warrior.  The other
	is Alexander Zusak himself, his carefully trimmed goatee and fancy clothing making him look even more like a delicate court fop.
	*choice
		#Ask, "What are you going to do to me?"
			*goto Captive_End_2
		#Ask, "Where are my friends?"
			*goto Captive_End_2
		#Say, "You will pay for what you have done."
			*goto Captive_End_2
		#Plead, "Please…let me go.  I beg of you!"
			*goto Captive_End_2
		#Say, "The kingdom will not stand for this."
			*goto Captive_End_2
	
	*label Captive_End_2
	You are ignored as Selina sits down at the table.
	
	"Have you taken any of ${mc_hisher} belongings?" Zusak calmly asks Selina, who shakes her head indicating that she hasn't.  "Excellent.  You have done well.  Bandar's duchy is yours, as promised."
	
	Duke Bandar looks surprised at this statement but looks even more shocked as Zusak slides a sharp dagger across his throat, splashing everyone with dark red blood.  You now understand why this meeting is taking place away from the castle.
	
	"The Academy wants to paint demon summoning as a great evil," Zusak says with a grin, showing you his perfect white teeth.
	"So what the hells, I might as well dabble in a little necromancy too."
	*page_break Betrayal
	Duke Bandar slumps in the chair and a dark black shadow erupts from his chest.
	*if ((companion_type="Shade") and (companion_name!="None"))
		The process is not very different from how you summoned ${companion_name}, your Shade.
	Zusak points toward your runebag and the shadow flies forward like a black lightning bolt.  It tears through the fabric, spilling
	*if (count_stones=0)
		the remaining Demonstone to the floor.  The shadow fades away, its purpose fulfilled.  Zusak calmly steps forward and picks it off the floor.
	*if (count_stones>0)
		your Demonstones to the floor.  The shadow fades away, its purpose fulfilled.  Zusak calmly steps forward and picks up the stone he stole so many years before,
		*if (count_stones=1)
			ignoring the other one entirely.
		*if (count_stones>1)
			ignoring the others entirely.
	*set runebag false
	*set demonstone_kgirr false
	
	"K'Girr, I summon thee!" he says, causing Selina's eyes to open in surprise.
	
	You feel a great shaking as the small building rocks back and forth.  An enormous black leathery creature the size of a two-storey house grows within the room.  The roof is torn free and one of the exterior walls falls over.  The demon is larger than any you have seen before.  It sits partially outside as half the house is destroyed.  It turns its enormous head toward Zusak as the high-chancellor binds it to his will.
	
	"Bring me Bozar!" Zusak commands.
	
	The enormous demon nods its haystack-sized head.  Suddenly a second demon appears.  This one is much smaller, perhaps only six inches tall.
	
	"Shield me!" Zusak says.
	
	A glimmering bubble suddenly appears around Zusak and the small demon, which crawls onto his shoulder.  You realize that he has summoned a demon without using a Demonstone.  Or rather, K'Girr, the enormous demon, has done so for him.  And even worse, there had been no battle of wills with the small imp.
	*choice
		#Use the distraction to throw your shackles around Selina's throat and strangle her.
			${prisoner1_name} grabs you by the back of your shirt and pulls you away before you can do it.
			*goto Captive_End_3
		#Throw yourself at Zusak, trying to batter him with your shackled fists.
			Your blow bounces harmlessly off the shield covering him.
			*goto Captive_End_3
		#Interlace your fingers and try to smash them into ${prisoner1_name}.
			${prisoner1_name} easily steps out of reach as the runes on your shackles make you slow and ponderous.
			*goto Captive_End_3
		#Cast a spell to blast Zusak with fire.
			*label NoMagic_Captive_3
			The shackles glow briefly and your spell unravels without materializing.
			*goto Captive_End_3
		#Cast a spell to blast ${prisoner1_name} with fire.
			*goto NoMagic_Captive_3
		#Cast a spell to blast Selina with fire.
			*goto NoMagic_Captive_3

	*label Captive_End_3
	"I spent a decade trying to figure out a way to get into a runebag without destroying the Demonstones within," Zusak says as Selina stares at the large demon in amazement.  "I figured that if that old bore Harmond could do it accidentally, then I could learn to do so on purpose.
	
	"Your parents knew that every demon that was brought into our world weakened the Boundary, but they had no idea why that was bad," he says lazily as he swats an imaginary piece of dust from his shoulder.  "K'Girr couldn't cross while the Boundary was intact, but as you see, that is no longer a problem."
	
	Zusak begins to rattle off a series of demonic names and K'Girr brings them each into existence outside the house.  They all serve him without exception.  After a moment, he doesn't even bother saying names and just asks for more servants.  He walks out through the broken wall and the enormous demon lumbers along beside him as he continues to bring forth even more demons.  Soon the light from the sun itself is darkened by the horde of creatures flying overhead and the earth shakes from the number of demons walking on the ground.  The large hole in the side of the house shows a nightmarish scene as Zusak leaves you alone with Selina.
	
	"He has his servants and I have mine," Selina says as she turns toward you and takes a vial of red liquid out of her pocket.
	
	You hear ${prisoner1_name} let out a small whimper as ${prisoner1_heshe} stares at the poison.  The ${prisoner1_nickname} begins to sweat and shake uncontrollably.  You can see the fear in ${prisoner1_hisher} eyes as ${prisoner1_heshe} looks at the small vial in Selina's hands.
	
	"This isn't for you," Selina says in disgust to ${prisoner1_name} as she approaches you.  "The pain and nightmares this poison brings are worse than anything known to man.  After a few doses, you'll beg for me to kill you.  After a few more, you'll do whatever I ask of you.  The best part is, you'll hate the stuff but you'll die unless you keep drinking it."
	
	She grabs hold of your magical shackles in one hand and brings the vial up to your lips with the other.
	*choice
		#Close your mouth tightly.
			Selina
			*goto NoMagic_Captive_4
		#Shake your head.
			Selina pulls on the shackles and you feel your strength drain even more until you don't even have the energy to move your head.  She then
			*goto NoMagic_Captive_4
		#Pull your whole body back.
			Selina pulls on the shackles and you feel your strength drain even more until you don't have the energy to fight back.  She then
			*goto NoMagic_Captive_4
		#Say, "No!  Stop!"
			Selina ignores your cries as she
			*goto NoMagic_Captive_4
	
	*label NoMagic_Captive_4
	pushes the vial between your lips and tips it up.  The liquid trickles through your teeth and into your mouth regardless of your struggles.  The nauseatingly sweet substance makes your eyes water.
	
	The vial suddenly comes away from your lips and falls to the floor with a shattering sound.  You see
	*if (prisoner1_name=theothea_name)
		${prisoner1_name}'s bloody hammer in ${prisoner1_hisher} hands as ${prisoner1_heshe} stands over Selina's dead body.
	*if (prisoner1_name=peterpetra_name)
		${prisoner1_name}'s bloody morningstar in ${prisoner1_hisher} hands as ${prisoner1_heshe} stands over Selina's dead body.
	*if (prisoner1_name=gillgale_name)
		${prisoner1_name}'s bloody swords in ${prisoner1_hisher} hands as ${prisoner1_heshe} stands over Selina's dead body.
	*if (prisoner1_name=karlkarla_name)
		${prisoner1_name}'s bow in ${prisoner1_hisher} hands as ${prisoner1_heshe} stands over Selina's dead body, an arrow sticking out of Selina's back.
	*if (prisoner1_name=jacejess_name)
		${prisoner1_name}'s shining white eyes as ${prisoner1_heshe} stands over Selina's dead body, a smoking hole clearly visible in Selina's chest.
	
	"I could kill you," ${prisoner1_name} says haltingly with a blank stare as you spit the poison onto the floor before it goes down your throat.  "But I couldn't let her do to you what she did to me.  The Red Poison is a fate worse than death."
	*achieve saviour
	*if ((demonsummoner) and (count_stones>0))
		
		You get on your knees
		*if (count_stones=1)
			and grab the remaining Demonstone before jumping back to your feet.
		*if (count_stones>2)
			and grab the remaining Demonstones before jumping back to your feet.
		*goto Captive_End_4
	*else
		*goto Captive_End_4
	
	*label Captive_End_4
	*if (using_legacy)
		*gosub Legacy_Endscene
	*page_break Demon War
	*set stage 7
	You stand upon the outskirts of Tornassa with hollow-eyed ${prisoner1_name} shivering at your side as you watch the city burn.  With ${prisoner1_name}'s help, you managed to get the enchanted shackles off.  You don't know where Zusak has gone, but his demons are everywhere.  They run rampant through the city, killing everyone and setting fire to everything.
	*if (using_legacy)
		
		The amulet from the most powerful wizard in Daria's history still sits around your neck.  You don't know what it's capable of, but you know that a lot of energy was spent in order to get it into your hands.
	
	*if ((mount_name!="None") and (companion_name!="None"))
		Miraculously, you found both ${companion_name}, your ${companion_type}, and ${mount_name}, your ${mount_type}, on the outskirts of the city.
	*if ((mount_name="None") and (companion_name!="None"))
		Miraculously, you found ${companion_name}, your ${companion_type}, on the outskirts of the city.
	*if ((mount_name!="None") and (companion_name="None"))
		Miraculously, you found ${mount_name}, your ${mount_type}, on the outskirts of the city.
	You don't know if any of your companions survived the battle or if ${prisoner1_name} will be able to live through the withdrawal of the Red Poison.  All hope seems lost, but you know that Alexander Zusak is out there and that the people of Daria need you now more than ever.
	*goto The_End

*label Legacy_Endscene
*comment using_legacy

The demons continue to pour forth like black blood from an infected wound.  A flash of blue light draws your attention away from the spectacle.  You see that the Wizard of Elmvale has appeared beside you.  $!{legacy_heshe} is the youngest you've ever seen ${legacy_himher}.

*if (legacy_good)
	"It's a pleasure to meet you, $!{princeprincess} ${name}," ${legacy_heshe} says with a smile.
*if (legacy_good=false)	
	"I will stop this entire thing right now," ${legacy_heshe} says with a cold expression on ${legacy_hisher} face.
"You now know the identity of the ${prisoner1_nickname}.  We can use this knowledge to our advantage.  I'm going to go back to the dungeon under Brightwater and cast a spell that will kill ${prisoner1_himher} before Selina can infect ${prisoner1_himher}.
*if (legacy_good)
	It's a terrible sacrifice, but it will give you the advantage you need to stop Zusak before this can happen."
*if (legacy_good=false)
	You'll have no trouble killing Zusak after that."
*fake_choice
	#"No, don't go!"
	#"Yes, hurry!"
	#"Wait.  I need help right now!"
*if (won_battle_of_tornassa=false)
	${prisoner1_name} says nothing as ${prisoner1_heshe} stands beside you, clearly not seeing the wizard at all.
The ${legacy_race} vanishes without answering you.  A second flash of blue appears immediately in the exact same place.  You see the wizard once more, but this time ${legacy_heshe} looks much older.

"I just met you for the first time a moment ago, didn't I," ${legacy_heshe} says as ${legacy_heshe} looks towards the demons pouring into existence.
*if (legacy_good)
	"I felt so old and wise at the time, but I was still foolish.  Those events had already occurred in your timeline, so I was unable to change them.  That doesn't mean I'm helpless though.  Please, come with me."
*if (legacy_good=false)
	"I was weak back then, but I am much more powerful now.  Those events had already occurred in your timeline, so I was unable to change them."

The glowing wizard floats away from you and urges you to follow.

"Hurry.  This is the moment we've been waiting for.  I need you to grab the next demon that is summoned forth.  Ready?  Now!"

The multitude of demons appearing before you is a blur, but when the wizard speaks, you reach out and grab one.  Your fingers dig deep into the web-like wings of the tiny creature just as it appears.  It struggles against you, but you hold on tightly.  It isn't very strong and is unable to break free of your
*if (won_battle_of_tornassa)
	grasp.
*if (won_battle_of_tornassa=false)
	grasp, despite the fact that you are still shackled and the magic of the manacles makes you extremely weak.
	
"That's it.  Bring the creature over here," the wizard says urgently, leading you a few feet away.

"Such a pitiful attempt," a deep voice says from nearby.

You see that it's the creature who attacked the wizard under the statue in Elmvale.  It has grey skin that looks as thick as leather.  Its muscles are well-defined and its eyes glow bright red.  A pair of yellow horns jut from its forehead and sharp teeth fill its mouth.  The large demon is standing in a blue aura of its own as it watches you.  You look at the small demon in your hands and see the similarities immediately.  Although the creature you have captured is much smaller, younger, and weaker, it's the same being.  You have captured T'dari.

"What do you plan to do with me?" the full-grown T'dari asks in an amused tone as the younger version of the demon continues to struggle in your grasp.  "I haven't even learned how to cross the boundaries of time yet.  You waste your magic.  I will see my future unfold as I desire.  Go ahead and try to kill me."

"It's correct, of course," the wizard says as ${legacy_heshe} searches the ground nearby.  "If you kill it, you'll create a paradox so powerful that it will stop both of us from visiting you in the past or in the future.  Many paradoxes can occur when you try to interact with your past selves.  Ahh, there it is."

"What?" the full-grown T'dari shouts as it rushes over to see what the wizard has discovered.

"What's wrong, demon?" the wizard says smugly.  "You didn't see this coming, did you?  It's hard to see events that occur within your own time-stream, isn't it?  Quickly, ${name}, flip over this rock."

You do as you're asked and kick the indicated rock aside while still holding the struggling demon by the wings.  You see something silver in the dirt beneath it.
*fake_choice
	#Smash the small demon onto the rock.
		You bring the demon down firmly onto the rock.  It screams loudly as some of its bones break.
		*label Legacy_Demon_Biting
		You feel its sharp teeth dig into your hand, forcing you to let it go.
		*goto Legacy_Demon_Fly_Away
	#Strangle the small demon.
		You adjust your grip until you're holding the creature around the throat.  It squeals in pain as you try to crush its windpipe.
		*goto Legacy_Demon_Biting
	#Throw the demon away and take what you've found.
		The smaller version of T'dari tumbles through the air until it is able to correct its flight by flapping its wings.
		*goto Legacy_Demon_Fly_Away

*label Legacy_Demon_Fly_Away
As the young demon flies away with the other demons, you pick up the silver object.

"You play a dangerous game, Wizard," the glowing version of T'dari says angrily in its low voice.  "The magic in that amulet could unravel this entire plane of existence."

"Begone, demon," your many-great ${legacy_grand} says dismissively with a shooing motion.

You watch as both the wizard from the past and the demon from the future vanish.  You see that you've picked up a silver amulet on a fine chain.  You put the artifact around your neck.
*if (showstats)
	*line_break
	(Legacy Advantage #10:  Gained the Wizard's Amulet)
*set legacy_amulet true
*return

*label The_End
*page_break The End
Congratulations upon completing the Lost Heir 2:  Forging a Kingdom.

*temp top_of_class_achievement false
*temp prestige_achievement false
*temp demon_achievement false
*if (((((class_bard=4) or (class_monk=4)) or ((class_assassin=4) or (class_priest=4))) or (((class_thief=4) or (class_wizard=3)) or ((class_druid=3) or (class_ranger=3)))) or ((class_knight=2) or (((class_thug=4) or (class_guard=4)) or ((class_sage=3) or (class_cleric=3)))))
	*set top_of_class_achievement true
*if (((((class_tattooist=1) or (class_dragonrider=1)) or ((class_warmaster=1) or (class_necromancer=1))) or (((class_darkknight=1) or (class_paladin=1)) or ((class_alchemist=1) or (class_seer=1)))) or (((class_blademaster=1) or (class_elementalarcher=1))))
	*set prestige_achievement true
*if ((demonstone_gaabon) and (willpower>=70))
	*set demon_achievement true
You have completed the following Achievements:
*line_break
*if (won_battle_of_tornassa)
	*line_break
	[b]A Kingdom Reunited[/b]:  You have reunited Daria.
*if (won_battle_of_tornassa=false)
	*line_break
	[b]A Friend in Need[/b]:  You have rescued ${prisoner1_name}, the ${prisoner1_nickname}.
*if (mount_level=6)
	*line_break
	[b]Sweet Ride[/b]:  ${mount_name}, ${mount_desc} ${mount_type}, is your legendary mount.
*if (top_of_class_achievement)
	*line_break
	[b]Top of the Class[/b]:  You have become
	*if (class_bard=4)
		a Legendary Mystical Bard.
	*if (class_knight=2)
		a Champion Knight.
	*if (class_monk=4)
		an Enlightened Monk.
	*if (class_assassin=4)
		the Top Assassin.
	*if (class_priest=4)
		the Archbishop.
	*if (class_thief=4)
		the Guildmaster of the Thieves Guild.
	*if (class_wizard=3)
		a Master Wizard.
	*if (class_druid=3)
		the Archdruid.
	*if (class_ranger=3)
		a Horizon Walker.
	*if (class_thug=4)
		an Intimidator.
	*if (class_guard=4)
		a Lieutenant.
	*if (class_sage=3)
		a Master Sage.
	*if (class_cleric=3)
		the Holy Fist.
*if (prestige_achievement)
	*line_break
	[b]Prestigious Position[/b]: You have become
	*if (class_tattooist=1)
		an Arcane Tattooist.
	*if (class_dragonrider=1)
		a Dragon Rider.
	*if (class_warmaster=1)
		a Talented War Master.
	*if (class_necromancer=1)
		an Evil Necromancer.
	*if (class_darkknight=1)
		a Dark Knight.
	*if (class_paladin=1)
		a Holy Paladin.
	*if (class_alchemist=1)
		a Magical Alchemist.
	*if (class_seer=1)
		a Mystical Seer.
	*if (class_blademaster=1)
		a Legendary Blademaster.
	*if (class_elementalarcher=1)
		an Elemental Archer.
*if (demon_achievement)
	*line_break
	[b]Know Thine Enemy[/b]:  You have become a demon summoner with an iron will.
*if (achievement_alliance)
	*line_break
	[b]Friends in All Places[/b]:  You have achieved an alliance with all 5 demi-human races.
*if (((amos_spider_statue) or (grady_letter)) or ((emaline_letter) or (geri_ring)))
	*line_break
	[b]A Life of Regret[/b]:  You have learned of your foster parent's great regret.
*label Achievements_loop
*choice
	*if (won_battle_of_tornassa=false) #[b]A Kingdom Reunited[/b]
		Reunite Daria.
		*goto Achievements_loop
	*if (won_battle_of_tornassa) #[b]A Friend in Need[/b]
		Save ${prisoner1_name}, the ${prisoner1_nickname}.
		*goto Achievements_loop
	*if (mount_level!=6) #[b]Sweet Ride[/b]
		Acquire a legendary mount.
		*goto Achievements_loop
	*if (top_of_class_achievement=false) #[b]Top of the Class[/b]
		Become the best in your class.
		*goto Achievements_loop
	*if (prestige_achievement=false) #[b]Prestigious Position[/b]
		Learn a prestige class.
		*goto Achievements_loop
	*if (demon_achievement=false) #[b]Know Thine Enemy[/b]
		Become a demon summoner with 70 willpower.
		*goto Achievements_loop
	*if (achievement_alliance=false) #[b]Friends in All Places[/b]
		Achieve an alliance with all 5 demi-human races.
		*goto Achievements_loop
	*if (((amos_spider_statue=false) and (grady_letter=false)) and ((emaline_letter=false) and (geri_ring=false))) #[b]A Life of Regret[/b]
		Learn of your foster parent's great regret.
		*goto Achievements_loop
	#Stop looking at possible achievements.
		*goto End_Achievements

*label End_Achievements
Stay tuned for the thrilling conclusion….
*image lh3.jpg
[b]The Lost Heir 3:  Demon War[/b] by Mike Walter

Make sure to save your game below! You'll need your saved game to continue where you left off in the next episode.
*save_game save_lostheir2

We hope you've enjoyed playing [i]The Lost Heir 2: Forging a Kingdom.[/i]

*feedback

Choice of Games releases new games like this one on a regular basis.
*subscribe
*page_break
[b][i]A note from the author[/i][/b]

I hope you have enjoyed playing The Lost Heir trilogy.  Please take the time to rate this game.  If you send me an email saying "Add Me" to lucid519@gmail.com, I will put you on my personal mailing list and tell you when I release new games.  Also, please be sure to try out my other games and follow me on Facebook at:
*link https://www.facebook.com/LucidsGames

*ending
