*comment Copyright 2015 by Mike Walter
*comment The Lost Heir 2:  Forging a Kingdom
*comment Scene #4: politics.txt
*comment 15705 - 41 = 15.7 k words
*hide_reuse
*temp prisonchild_not_dealt_with true
*temp politics_daysleft 14
*temp politics_met_vale false
*temp politics_met_tovor false
*temp politics_met_cumari false
*temp politics_vale_spending "None"
*temp politics_tovor_spending "None"
*temp vale_know_to_watch false
*temp tovor_know_to_watch false
*temp cumari_made_choice false
*temp politics_troop_visits 0
*temp politics_treasury_visits 0
*temp politics_other_visits 0
*temp temp_days_spent 0
*temp politics_thoughtofcumari false
*temp politics_nofriends true
*temp travel_days 0
*temp nervous_laughter false
*temp knows_opposition false
*temp inspect_soldiers_done_once false
*temp study_books_done_once false
*temp new_horse_cost 300
*temp plan_to_meet false
*set stage 4
*set store_scene "None"
With only two weeks to get enough votes, you begin to ply the fine art of politics.
*label Politics_loop
*if (politics_daysleft<=0)
	*goto GrandCouncil

Days until Grand Council:  ${politics_daysleft}
*choice
	*if (prisonchild_exists) #Decide what to do with the child you saved in the prison.
		*set prisonchild_not_dealt_with false
		The child still hasn't spoken since being brought out of the dungeons.  You ask the child ${prisonchild_hisher} name, but ${prisonchild_heshe} says nothing.  Ultimately, you end up calling ${prisonchild_himher}…
		*label Prison_Child_Name_TryAgain
		*input_text prisonchild_name
		*if (prisonchild_name="Nothing")
			That's a terrible name for a child!  $!{prisonchild_heshe}'ll need to be called something else.
			*goto Prison_Child_Name_TryAgain
		*label Where_Child_Go_loop
		*choice
			#Spend a day preparing a spot in your suites so ${prisonchild_name} can stay with you.
				${prisonchild_name} is no trouble and never speaks.  ${branbrinn_name},
				*if (friend2_exists)
					${friend2_name},
				${friend1_name} and ${friend3_name} all help you look after ${prisonchild_himher} when you are out.  You know that you'll have to find ${prisonchild_himher} a real home eventually, but for now, the ${prisonchild_boygirl} is happy to be with you.
				*if (showstats)
					*line_break
					(Good +5 and Lost 1 Day)
				*set politics_daysleft -1
				*set good +5
				*goto Politics_loop
			#Send ${prisonchild_name} to an orphanage.
				The priests and priestesses of Lucien and Auriel generously take the child into their custody.
				*if (showstats)
					*line_break
					(Good +5)
				*set good +5
				*set prisonchild_exists false
				*goto Politics_loop
			#Kick the child out of the house.
				You are too busy to take care of a child.  Life on the streets is better than a life in prison.  You never hear from ${prisonchild_name} again.
				*if (showstats)
					*line_break
					(Evil +3)
				*set good -3
				*set prisonchild_exists false
				*goto Politics_loop
			#Send the child back to prison.
				${branbrinn_name} clearly doesn't like the idea, but since the child was incarcerated for some crime or another, the captain doesn't say anything as you send ${prisonchild_name} back to the dungeons.
				*if (showstats)
					*line_break
					(Evil +10)
				*set good -10
				*set prisonchild_exists false
				*goto Politics_loop
			#Ask ${prisonchild_name} where ${prisonchild_heshe} would like to live.
				The child doesn't say a word.  No matter how many options, descriptions and pictures you offer, you can't seem to get ${prisonchild_name} to respond.
				*goto Where_Child_Go_loop
	*allow_reuse #Speak to Lord Vale, general of the eastern armies.
		*if (politics_met_vale=false)
			*set politics_met_vale true
			Lord Vale is a stern man in his mid-fifties.  His iron-gray hair gives him a look of authority and his body is rock hard from disciplined exercise and eating.  He was a gifted commander for your parents and is acknowledged as one of the finest strategic minds in the four duchies.  His ability as a general would be invaluable.  As a busy man, he requests that you walk with him during his daily inspections of the soldiers, battlements and fortifications of Brightwater.
			*if (breakout_killed_guards)
				
				"It's a pity that you had to kill those poor soldiers who were guarding your friend," Lord Vale says.  "Although I agree that you had no choice."
				*if (showstats)
					*line_break
					(Lord Vale Relationship -10)
				*set vale_relationship -10
			
			"Let me be blunt, $!{princeprincess} ${name}," he says.  "I'm happy that you're alive and I don't doubt your story about Zusak's betrayal.  Despite being a military man, I don't like war and I don't want to see my soldiers getting killed needlessly.  Duchess Selina keeps the peace.  In fact, she may even join her Dumain duchy to that of Uddo for even more security.  If you led us, you'd have no choice but to march the army southwest to invade Ludd in order to take over the duchy of Eddan.  Then, you'd march us north to take Tornassa and the Uddo duchy, then continue north to defeat Zusak in Vernex, annexing the Bandar duchy to reunite Daria.  Once started, you'd have to keep going or else we'll have years of civil war."
			*choice
				#Agree with his assessment of the situation.
					Lord Vale nods as you agree with him.
					*if (showstats)
						*line_break
						(Lord Vale Relationship +3)
					*set vale_relationship +3
					*goto Vale_loop
				#Deny the need to invade the other duchies.
					Lord Vale doesn't react as you disagree with his statement that you will want to war on the other duchies.
					*if (showstats)
						*line_break
						(Lord Vale Relationship -3)
					*set vale_relationship -3
					*goto Vale_loop
		*else
			Lord Vale agrees to speak to you.
			*label Vale_loop
			*choice
				*if (politics_vale_spending="None")
					*allow_reuse #Discuss war spending.
						Lord Vale becomes extremely interested in your words as you discuss how tax revenue should be used for military spending.  Fortifications, soldier pensions, salaries, equipment maintenance, supplies and thousands of other details all cost gold.
						*choice
							#Promise Lord Vale that you will increase military spending.
								*set politics_vale_spending "increase"
								*if (politics_tovor_spending!="None")
									*if (politics_tovor_spending="increase")
										*goto Vale_increase_spending
									*else
										*label Vale_Liar
										"I'll not call you a liar, Your Majesty, but Lord Tovor already told me that
										*if (politics_tovor_spending="same")
											you plan to leave the spending at its current level.
										*if (politics_tovor_spending="decrease")
											you plan to cut the military budget.
										You will do as you must, but please don't forget the men and woman who will bleed for your decisions."
										
										*if (charm<90)
											You know that word will get back to Lord Tovor as well.  You hope that your dishonesty doesn't destroy your chances of winning the vote.
											*if (showstats)
												(Needed 90 Charm)
											*if (politics_vale_spending="increase")
												*if (politics_tovor_spending="decrease")
													*if (showstats)
														*line_break
														(Evil +5, Lord Tovor Relationship -40 and Lord Vale Relationship -20)
													*set good -5
													*set tovor_relationship -40
													*set vale_relationship -20
													*goto Vale_loop
												*else
													*comment (politics_tovor_spending="same")
													*if (showstats)
														*line_break
														(Evil +5, Lord Tovor Relationship -25 and Lord Vale Relationship -20)
													*set good -5
													*set tovor_relationship -25
													*set vale_relationship -20
													*goto Vale_loop
											*else
												*comment Told Vale Same
												*comment And told Tovor decrease, since telling Tovor same is not lie and telling Tovor increase is dumb and penalized for both, so only one option left . . .
												*if (showstats)
													*line_break
													(Evil +5, Lord Tovor Relationship -25 and Lord Vale Relationship -20)
												*set good -5
												*set tovor_relationship -25
												*set vale_relationship -20
												*goto Vale_loop
										*else
											It takes some fancy talking to convince Lord Vale that you are telling him the truth.  You know that word will get back to Lord Tovor as well, but perhaps he will also believe you as you bandy the truth.
											*if (politics_vale_spending="increase")
												*if (politics_tovor_spending="decrease")
														*if (showstats)
															*line_break
															(Evil +5, Charm +2, Lord Tovor Relationship -5 and Lord Vale Relationship +15)
														*set good -5
														*set charm +2
														*set tovor_relationship -5
														*set vale_relationship +15
														*goto Vale_loop
												*else
													*comment (politics_tovor_spending="same")
													*if (showstats)
														*line_break
														(Evil +5, Charm +2 and Lord Vale Relationship +5)
													*set good -5
													*set charm +2
													*set vale_relationship +5
													*goto Vale_loop
											*else
												*comment Told Vale Same
												*comment And told Tovor decrease, since telling Tovor same is not lie and telling Tovor increase is dumb and penalized for both, so only one option left . . .
												*if (showstats)
													*line_break
													(Evil +5, Charm +3, Lord Tovor Relationship -5 and Lord Vale Relationship +5)
												*set good -5
												*set charm +3
												*set tovor_relationship -5
												*set vale_relationship +5
												*goto Vale_loop
								*label Vale_increase_spending
								"Thank you, Your Highness," Lord Vale says.  "This is a wise decision.  The men and women have the heart, but they also need the gold to keep their steel sharp."
								*if (showstats)
									*line_break
									(Lord Vale Relationship +20)
								*set vale_relationship +20
								*goto Vale_loop
							#Promise Lord Vale that you will keep military spending the same.
								*set politics_vale_spending "same"
								*if (politics_tovor_spending!="None")
									*if (politics_tovor_spending="decrease")
										*goto Vale_Liar
									*else
								*comment told Tovor same or increase, or haven't spoke
								"If that is your decision, Your Majesty," Lord Vale says.  "Although we may run into some difficulties if the army is called upon without any increase in funding."
								*if (showstats)
									*line_break
									(Lord Vale Relationship +5)
								*set vale_relationship +5
								*goto Vale_loop
							#Tell Lord Vale that you will need to lower military spending.
								*set politics_vale_spending "decrease"
								"If that is your decision, Your Majesty," Lord Vale says, his manner brisk and formal.  "Thank you for being honest with me, although I must tell you, cutting funds will greatly weaken our army."
								*if (showstats)
									*line_break
									(Lord Vale Relationship +2)
								*set vale_relationship +2
								*goto Vale_loop
							*allow_reuse #Make no firm commitment to Lord Vale about military spending.
								The general accepts your empty words with grace.  He is a soldier at heart and used to orders being given from higher up.
								*goto Vale_loop
				*if (vale_know_to_watch=false) #Ask Lord Vale what you could do to assure his vote.
					"The army is made to be used; only a fool would ask you to not use it.  I only ask that you treat your soldiers with respect.  Show them respect by learning their names, knowing the patrol routes, watching their training and understanding their needs.  And of course, don't cut the military budget.  We need the money for our salaries, pensions and to maintain our weapons and armour."
					*set vale_know_to_watch true
					*goto Vale_loop
				*if (vale_know_to_watch) 
					*allow_reuse #Inspect the soldiers and watch their training.
						*if (inspect_soldiers_done_once=false)
							You only get one chance to make a good first impression.
							*set inspect_soldiers_done_once true
							*if ((blades>=40) or (unarmed>=40))
								Luckily, this works in your favour.  You have seen combat and you know how to take care of yourself in a fight.  General Vale seems happy to have a warrior for a potential monarch.
								*if (showstats)
									*line_break
									(Strength +3 and General Vale Relationship +5)
									
								*set strength +3
								*set vale_relationship +5
								*goto After_FirstInspection
							*else
								The soldiers are uncertain of having you as a potential monarch.  General Vale hides his disappointment and you can tell that despite your militaristic shortcomings, he still appreciates all of the efforts you make when it comes to inspecting the soldiers.
								*if (showstats)
									(Needed 40 Blades or 40 Unarmed)
									
								*goto After_FirstInspection
						*label After_FirstInspection
						There are many soldiers in and around Brightwater.  Lord Vale knows the locations of all of them and knows what each company is doing.  If you are to gain the respect of the general and some day command the troops, he expects you to know all of the fine details as well.  There
						*if (politics_daysleft=1)
							is only 1 day left; the Grand Council is tomorrow.
							*choice
								*allow_reuse #Spend the final day inspecting the troops.
									You spend your last day speaking to soldiers and their commanders.
									*if (showstats)
										*line_break
										(Lord Vale Relationship +3)
									*set vale_relationship +3
									*set politics_troop_visits +1
									*set politics_daysleft -1
									*goto GrandCouncil
								*allow_reuse #Do something else.
									You decide to spend your final day doing something else.
									*goto Politics_loop
						*else
							are ${politics_daysleft} days left until the Grand Council.  How many days will you spend inspecting the troops?
							*input_number temp_days_spent 0 politics_daysleft
							*if (temp_days_spent=0)
								You change your mind about inspecting the troops.
								*goto Politics_loop
							*set politics_troop_visits +(temp_days_spent)
							*set politics_daysleft -(temp_days_spent)
							You speak to soldiers and their commanders, learning the details of the composition of the army, their training regimen and how they function.
							*line_break
							*temp temp_relationship_boost
							*set temp_relationship_boost (temp_days_spent*3)
							*if (showstats)
								*line_break
								(Lord Vale Relationship +${temp_relationship_boost})
							*set vale_relationship +(temp_relationship_boost)
							*goto Politics_loop
				*if (politics_troop_visits>1) #Spend some time training with the soldiers.
					*if (endurance<50)
						Although you would like to train with the soldiers, your days are filled with speaking to the nobles and you are too tired at night to do much else.
						*if (showstats)
							(Needed 50 Endurance)
						*goto Vale_loop
					*if ((blades>=25) or (archery>=25))
						The soldiers are very pleased to see a potential ruler picking up a training sword and bow in order to practice with them.  Through the sweat of your hard work, you gain the respect of the soldiers and of General Vale.
						*if (showstats)
							*line_break
							(Blades +2, Archery +2, Endurance +2 and Lord Vale Relationship +5)
						*set blades +2
						*set archery +2
						*set endurance +2
						*set vale_relationship +5
						*goto Vale_loop
					*else
						At first, the soldiers are very pleased to see a potential ruler picking up a training sword and bow in order to practice with them.  Unfortunately, your lack of combat skills makes your presence seem contrived and insincere.  The soldiers see your actions as posturing and fake.
						*if (showstats)
							(Needed 25 Blades or 25 Archery)
							*line_break
							(Endurance +2 and Lord Vale Relationship -5)
						*set endurance +2
						*set vale_relationship -5
						*goto Vale_loop
				*allow_reuse #Speak to someone else.
					You decide to speak to someone else.
					*goto Politics_loop
	*if ((politics_thoughtofcumari) and (politics_met_cumari=false))
		*allow_reuse #Travel to the Academy of Wizards to meet Archmage Cumari.
			*goto CheckMount
	*if ((politics_thoughtofcumari) and (politics_met_cumari=false))
		#Plan to meet Archmage Cumari when he comes to Brightwater for the Grand Council.
			*set plan_to_meet true
			*set politics_met_cumari true
			You make a mental note to be sure to find the Archmage when he arrives in Brightwater.
			*goto Politics_loop
	*if (politics_thoughtofcumari=false) #Speak to Archmage Cumari, head of the Academy of Wizards.
		*set politics_thoughtofcumari true
		When you ask ${branbrinn_name} where you can meet the Archmage, ${branbrinn_heshe} informs you that Archmage Cumari rarely leaves the Academy.  Although the Academy is technically in the Dumain duchy, it has always held itself apart from everyone else, similar to when your parents ruled Daria.  If you wish to speak to the Archmage, you will have to
		*if (questdetails="the Academy of Wizards")
			return
		*if (questdetails!="the Academy of Wizards")
			go
		to the Academy.
		*label CheckMount
		*if (mount_name="None")
			Without a mount, it will take you 5 days to walk there and another 5 days to walk back.
			*set travel_days 5
			*goto Politics_CheckTime
		*else
			*if (mount_type="mule")
				Traveling by mule isn't much better than walking. It will take you 5 days to ride there and another 5 days to ride back.
				*set travel_days 5
				*goto Politics_CheckTime
			*if (((mount_level=1) or (mount_level=2)) or (mount_level=3))
				Riding ${mount_desc} ${mount_type} is better than walking, but it will still take you 4 days to ride there and another 4 days to ride back.
				*set travel_days 4
				*goto Politics_CheckTime
			Riding ${mount_desc} ${mount_type} is better than walking, but it will still take you
			*if (mount_value=4)
				3 days to ride there and another 3 days to ride back.
				*set travel_days 3
				*goto Politics_CheckTime
			*else
				*comment only level 5 mounts left
				2 days to ride there and another 2 days to ride back.
				*set travel_days 2
				*goto Politics_CheckTime

		*label Politics_CheckTime
		*temp round_trip 0
		*set round_trip travel_days*2
		*comment Trip can be done with fastest horse in 4 days, so the offer to buy a horse only happens then.
		*if (politics_daysleft<4)
			Unfortunately, the Grand Council is
			*if (politics_daysleft=1)
				tomorrow,
			*if (politics_daysleft!=1)
				in ${politics_daysleft} days,
			and since the journey takes a total of ${round_trip} days to get there and back, you don't have enough time, even with a very fast horse.
			*goto Politics_Loop
		*else
			*goto Politics_Travel_Or_Not
		
		*label Politics_Travel_Or_Not
		*choice
			*allow_reuse #Travel to the great Academy of Wizards.
				*if (round_trip>politics_daysleft)
					Unfortunately, the Grand Council is
					*if (politics_daysleft=1)
						tomorrow,
					*if (politics_daysleft!=1)
						in ${politics_daysleft} days,
					and since the journey takes a total of ${round_trip} days to get there and back, you don't have enough time.  Perhaps you should buy a
					*if (mount_name="None")
						horse?
					*if (mount_name!="None")
						better mount?
					*goto Politics_Travel_Or_Not
				*goto Travel_To_Academy
			*if (mount_name="None") #Purchase a mount.
				Captain ${branbrinn_name} takes you to a reputable horse trader to find something suitable.  Unfortunately, the merchant doesn't have a lot of animals in stock on such short notice, but he does have one horse for sale that could take you to the Academy in 3 days instead of ${travel_days}, for a round trip of 6 days instead of ${round_trip}.
				*choice
					*selectable_if (gold>=300) #Buy the horse and go to the Academy.  (Needs 300 Gold)
						*goto Buy_Horse_For_Academy_Visit
					#Don't buy the horse.
						You decide to not buy the horse.
						*goto Politics_Travel_Or_Not
			*if ((mount_level<4) and (mount_name="None")) #Purchase a better mount.
				Captain ${branbrinn_name} takes you to a reputable horse trader to find something suitable.  Unfortunately, the merchant doesn't have a lot of animals in stock on such short notice, but he does have one horse for sale that could take you to the Academy in 3 days instead of ${travel_days}, for a round trip of 6 days instead of ${round_trip}.  He even offers to take ${mount_name} off your hands for ${mount_value} gold, bringing the cost of the new horse to
				*set new_horse_cost 300-mount_value
				${new_horse_cost} gold.
				*choice
					*selectable_if (gold>=new_horse_cost) #Buy the horse and go to the Academy.  (Needs ${new_horse_cost} Gold)
						*goto Buy_Horse_For_Academy_Visit
					#Don't buy the horse.
						You decide to not buy the horse.
						*goto Politics_Travel_Or_Not
				*label Buy_Horse_For_Academy_Visit
				*rand coinflip 1 2
				*if (coinflip=1)
					*set mount_hisher "his"
					*set mount_heshe "he"
					*set mount_himher "him"
				*if (coinflip=2)
					*set mount_hisher "her"
					*set mount_heshe "she"
					*set mount_himher "her"
				*temp randommountname
				*rand randommountname 1 28
				*if (randommountname=1)
					*set mount_name "Angel"
				*if (randommountname=2)
					*set mount_name "Apple Jack"
				*if (randommountname=3)
					*set mount_name "Angel Eyes"
				*if (randommountname=4)
					*set mount_name "Autumn"
				*if (randommountname=5)
					*set mount_name "Babe"
				*if (randommountname=6)
					*set mount_name "Basil"
					*set mount_hisher "his"
					*set mount_heshe "he"
					*set mount_himher "him"
				*if (randommountname=7)
					*set mount_name "Blackie"
				*if (randommountname=8)
					*set mount_name "Boots"
				*if (randommountname=9)
					*set mount_name "Blossom"
				*if (randommountname=10)
					*set mount_name "Breeze"
				*if (randommountname=11)
					*set mount_name "Cactus"
				*if (randommountname=12)
					*set mount_name "Checkers"
				*if (randommountname=13)
					*set mount_name "Cinnamon"
				*if (randommountname=14)
					*set mount_name "Firecracker"
				*if (randommountname=15)
					*set mount_name "Felicity"
					*set mount_hisher "her"
					*set mount_heshe "she"
					*set mount_himher "her"
				*if (randommountname=16)
					*set mount_name "Ginger"
					*set mount_hisher "her"
					*set mount_heshe "she"
					*set mount_himher "her"
				*if (randommountname=17)
					*set mount_name "Hazel"
					*set mount_hisher "her"
					*set mount_heshe "she"
					*set mount_himher "her"
				*if (randommountname=18)
					*set mount_name "Indigo"
				*if (randommountname=19)
					*set mount_name "Jasper"
				*if (randommountname=20)
					*set mount_name "Jewel"
				*if (randommountname=21)
					*set mount_name "Lady"
					*set mount_hisher "her"
					*set mount_heshe "she"
					*set mount_himher "her"
				*if (randommountname=22)
					*set mount_name "Lucky"
				*if (randommountname=23)
					*set mount_name "Nutmeg"
				*if (randommountname=24)
					*set mount_name "Patches"
				*if (randommountname=25)
					*set mount_name "Pebbles"
				*if (randommountname=26)
					*set mount_name "Rusty"
				*if (randommountname=27)
					*set mount_name "Saffron"
				*if (randommountname=28)
					*set mount_name "Tango"
				${mount_name} is a fine animal who will get you to the Academy and back in great time.
				*if (showstats)
					*line_break
					(Gained Mount and Gold -${new_horse_cost})
				*set gold -new_horse_cost
				*set mount_value 150
				*set mount_level 4
				*set travel_days 3
				*set round_trip 6
				*set mount_type "horse"
				*set mount_desc "a healthy riding"
				*goto Travel_To_Academy
			*allow_reuse #Stay in Brightwater, for now.
				You decide to stay in Brightwater, for now.
				*goto Politics_loop	
					
		*label Travel_To_Academy
		The trip up the coast from Brightwater to the Academy of Wizards is uneventful.
		*if (showstats)
			*line_break
			*if (travel_days=1)
				(Lost 1 Day)
			*if (travel_days>1)
				(Lost ${travel_days} Days)
			
		*set politics_met_cumari true
		*set politics_daysleft -(travel_days)
		*if (questdetails="the Academy of Wizards")
			It hasn't been very long since you left the Academy.
			*if (((academy_stay="student") or (academy_stay="bard")) or ((academy_stay="sage") or (academy_stay="graduate")))
				You go directly to the main tower itself, where you had been living for the past year.
				*goto Describe_Tower
			*else
				You had lived in the city surrounding the Academy, but today, you travel directly to the main tower itself.
				*goto Describe_Tower
		*if (questdetails!="the Academy of Wizards")
			You go directly to the main tower itself.
		*label Describe_Tower
		*if (academy_robes)
			Your blue robes with the yellow stars and moons make the students part around you with respect.
		It is a feat of magical engineering that can be found nowhere else.  The tower is unnaturally tall, disappearing into the clouds high above.  Now that you have let the world know that you are the lost ${princeprincess} of Daria, you are given no difficulties as you are granted an immediate audience with Archmage Cumari himself.
		
		"Well met, Your Highness," the Archmage says cautiously.  "Thank you for paying me this visit.
		*if (academy_metcumari)
			It is good to see you again.  I must say, I am surprised to learn who you really are."
		*if (academy_metcumari=false)
			*if (((academy_stay="student") or (academy_stay="bard")) or ((academy_stay="sage") or (academy_stay="graduate")))
				I must say, I am surprised to find out who you really are.  You stayed with us for a year without me suspecting a thing."
		*if (showstats)
			*line_break
			(Archmage Cumari Relationship +5)
		*set cumari_relationship +5
		*label Cumari_loop
		
		*label Cumari_loop_ns
		Days until Grand Council:  ${politics_daysleft}
		*choice
			*if (cumari_made_choice=false) #Ask, "What can I do to assure your vote?"
				*comment academy_stay "bodyguard", "bard", "priest", "student", "druid", "ranger", "monk", "sage", "graduate"
				*set cumari_made_choice true
				"I appreciate your candor," Archmage Cumari says.  "Your parents were always very respectful of the Academy's relationship to the nation.  There is only one thing that we truly desire, and that is our own autonomy and independence.  Would you be willing to sign a legal contract saying that you and your successors will never try to command or annex the Academy in any way in perpetuity?"
				
				Historically, the Academy has always been apart from the kingdom.  This has been more of a tradition than a law.  To write up such a document would severely tie your hands when it comes to dealing with the Academy in the future.  But, if you can't get the votes to become ruler, it won't matter anyway.
				*choice
					#Agree and sign the document.
						*set academy_autonomy true
						Archmage Cumari is obviously thrilled when you agree to sign the document.  You know that you have pretty much assured his vote in the Grand Council and that he will lobby for the other lords and ladies to vote for you as well.  Only time will tell how big of a concession such a document will be to you and to your future heirs.
						*if (showstats)
							*line_break
							(Archmage Cumari Relationship +30)
						*set cumari_relationship +30
						*goto Cumari_loop
					#Decline to sign the document.
						Archmage Cumari doesn't push the issue, but you can tell that he is disappointed.  It would have been an enormous boon for the Academy to know that it would forever be kept apart from matters of state.
						*goto Cumari_loop
			*if (cumari_made_choice) #Ask, "Is there anything else I can do?"
				"Well, there is one thing," Archmage Cumari says with a slight hesitation in his voice.  "But it's very dangerous."
				*choice
					#Say, "Just tell me what it is."
						"Have you heard of the Staff of the Archmagi?" he asks rhetorically.  "It's a mighty staff that has traditionally been held by the Archmage of the Academy.  About 50 years ago, a coven of Necromancers were found working in the Academy.  When they were discovered, they went to the Archmage's quarters and tried to steal the staff.  Fortunately, the wards on the staff stopped them from taking it, but in petty retaliation, they cast a ward of their own over it.  Follow me."
						
						Archmage Cumari leads you through the tower and into his own chambers.  In the centre of the room, on a pedestal, you see a staff.  There is a black shadowy cloud hovering over it.  The Archmage puts out a hand to hold you back before you touch it.
						
						"The warding is similar to the touch of a wraith.  It drains the life of a person.  All of our attempts to break the spell have been futile.  If you could get the staff free, I would be forever in your debt."
						*temp politics_academy_archmage_present true
						*temp politics_academy_made_attempt false
						*label Academy_Staff_loop
						
						Days until Grand Council:  ${politics_daysleft}
						*choice
							#Spend a day studying the enchantment.
								*if (politics_daysleft=(travel_days))
									Unfortunately, you don't have the time to do so.  You only have ${politics_daysleft} days left and it will take all that time to return to Brightwater.
									*goto Academy_Staff_loop
								*else
									*set politics_daysleft -1
									You spend a day studying the aura surrounding the staff.  During this time, Master Cumari leaves you to your task, asking for you to summon him before making any attempt to dispel the aura.
									*set politics_academy_archmage_present false
									*if (showstats)
										*line_break
										(Arcana +2)
									*set arcana +2
									*goto Academy_Staff_loop
							*if (god_heshe="It") #Call upon the Unknown God to dispel the evil enchantment.
								An ancient presence is felt in the room as your deity scours the evil ward from the world.  Your master is a jealous deity and does not like other divines.
								*if (showstats)
									(Religion +5)
								*set religion +5
								*if (politics_academy_archmage_present)
									
									*goto Politics_Give_Staff
								*if ((no_thief_vow) and (politics_academy_archmage_present=false))
									
									*goto Politics_Call_To_Get_Staff
								*else
									*choice
										#Call for Archmage Cumari and give him the staff.
											*goto Politics_Call_To_Get_Staff
										#Put a fake staff in its place.
											Your ${god_goddess} does as you request.  As you place the fake staff on the pedestal, It restores the aura, protecting the counterfeit instead.
											*goto Politics_Disguise_Take_Staff
							*if (((class_priest>0) and (god_good=true)) and (god_heshe!="It")) #Call upon ${god_name} to dispel the evil enchantment.
								You call upon your ${god_goddess} to remove the foul enchantment.
								*if (good<60)
									You aren't too surprised when you get no response.  You have not been following your ${god_goddess}'s teachings and you have lost ${god_hisher} divine favour.  You feel your holy symbol fall to dust in your fingers as you realize that you are no longer a ${priestpriestess} of ${god_name}.
									*if (showstats)
										(Needed 60 Good)
										*line_break
										(Lost Holy Symbol and Lost All Levels of $!{priestpriestess} and Cleric)
									*set class_priest 0
									*set class_cleric 0
									*set holysymbol false
									*set exgoodpriest true
									*set title "ex-"&priestpriestess
									*goto Academy_Staff_loop
								*else
									A wave of light erupts from your holy symbol as ${god_name} answers your call.  Similar to banishing a wraith, your ${god_goddess} scours the evil spell from existence.
									*if (showstats)
										(Religion +5)
									*set religion +5
									
									*if (politics_academy_archmage_present)
										*goto Politics_Give_Staff
									*else 
										*goto Politics_Call_To_Get_Staff
							*if (((class_priest>0) and (god_good=false)) and (god_heshe!="It")) #Call upon ${god_name} to allow you to pass through the evil enchantment.
								You call upon your ${god_goddess}.
								*if (good>40)
									You aren't too surprised when you get no response.  You have not been following your ${god_goddess}'s teachings and you have lost ${god_hisher} divine favour.  You feel your holy symbol fall to dust in your fingers as you realize that you are no longer a ${priestpriestess} of ${god_name}.
									*if (showstats)
										(Needed 60 Evil)
										*line_break
										(Lost Holy Symbol and Lost All Levels of $!{priestpriestess} and Cleric)
									*set class_priest 0
									*set class_cleric 0
									*set holysymbol false
									*set exevilpriest true
									*set title "ex-"&priestpriestess
									*goto Academy_Staff_loop
								*else
									The shadows darken around your hand as ${god_name} answers your call.  You can feel your ${god_goddess} forcing the evil aura to obey your command and move aside.
									*if (showstats)
										(Religion +5)
									*set religion +5
									
									*if (politics_academy_archmage_present)
										"Amazing!" Archmage Cumari says as he takes the staff from you, assuming that you have dispelled the enchantment through the power of a benevolent deity.
										*goto Politics_AchmageTakeStaff
									*else
										*label Academy_swapstaffs
										*if ((no_thief_vow) and (politics_academy_archmage_present=false))
											
											*goto Politics_Call_To_Get_Staff
										*choice
											#Call for Archmage Cumari and give him the staff.
												*goto Politics_Call_To_Get_Staff
											#Put a fake staff in its place.
												You have no difficulty positioning a fake staff in the place of the real one.
												*goto Politics_Disguise_Take_Staff
							#Study the pedestal for a mundane way to remove the staff.
								The staff is firmly wrapped in the shadowy aura.
								*if (thief_token)
									The small thief token glows warmly as you consider the task at hand.
									*goto Academy_StealIt
								*if ((devices<70) and (agility<40))
									Perhaps a more skilled thief would know of an alternate way to retrieve the treasure, but unfortunately, you do not.
									*if (showstats)
										(Needed 70 Devices or 40 Agility)
									*goto Academy_Staff_loop
								*else
									*label Academy_StealIt
									Although the nature of the trap is different from what you have seen before, it is still just another type of lock to keep the unskilled away from the treasure.  A truly talented thief would be able to dexterously reach through the twisting shadows, grab the staff, and pull it free of the ward without touching the life-draining darkness.  Luckily for you, you are that good.  Carefully, you pull the staff free of the spell without touching the aura.
									*if (showstats)
										*line_break
										(Devices +3 and Agility +3)
									*set devices +3
									*set agility +3
									
									*if (politics_academy_archmage_present)
										"Amazing!" Archmage Cumari says in awe of your talent.
										*goto Politics_AchmageTakeStaff
									*else
										*goto Academy_swapstaffs
							*if (demonsummoner) #Consider using a Demonstone.
									You open your runebag and consider your options.
									*label Academy_TryDemonsAgain
									*choice
										*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and ((demonstone_xiatta_used=false) and (demonsummoner))) #Summon Xi'atta and tell it to get the staff.
											*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
											Xi'atta appears in front of you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
											*set demonstone_xiatta_used true
											*label Academy_Demon_Fail
											
											The demon shrugs its shoulders and approaches the pedestal.  The necromantic aura quickly drains the creature of all life force, forcing the demon to return to its own plane.  You realize that demons are even more susceptible to the enchantment than humans are.
											*goto Academy_Staff_loop
										*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl.
											*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
											Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
											*set demonstone_brahl_used true
											*goto Academy_Demon_Fail
										*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and ((demonstone_zonch_used=false) and (demonsummoner))) #Summon Zon'ch.
											*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
											Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
											*set demonstone_zonch_used true
											*goto Academy_Demon_Fail
										*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and ((demonstone_daanda_used=false) and (demonsummoner))) #Summon Daan'da.
											*comment Will of 0, but very stupid and weak.
											Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
											*set demonstone_daanda_used true
											*goto Academy_Demon_Fail
										*if (((demonstone_tyborr) and (demonstone_tyborr_summoned)) and ((demonstone_tyborr_used=false) and (demonsummoner))) #Summon Tyborr.
											*comment Tyborr: Willing: 80, Small Struggle: 90, Against: 100
											Tyborr appears before you, wearing its brown robes.  The small five-and-a-half foot tall demon looks more like an old man with two stubby horns than a monster.
											
											"Do not call upon me," it says in a sad voice.  "I just want to be left alone."
											*goto Academy_TryDemonsAgain
										#Give up on the idea of using demons to get the staff.
											You put away your runebag and consider your other options.
											*goto Academy_Staff_loop
							#Attempt to take the staff without removing the shield.
								*if (vampire)
									As your hand passes through the shielding, something strange happens.  Instead of draining your life force, you feel a soothing calmness pass over you.  Your semi-vampiric blood has the same ancient necromantic magic within it.  You take hold of the staff and pull it free.  You have done it.
									*if (politics_academy_archmage_present)
										
										"Amazing!" Archmage Cumari says as he takes the staff from you, assuming that you have dispelled the enchantment in a way he doesn't understand.
										*goto Politics_AchmageTakeStaff
									*if ((no_thief_vow) and (politics_academy_archmage_present=false))
										
										*goto Politics_Call_To_Get_Staff
									*else
										*choice
											#Call for Archmage Cumari and give him the staff.
												*goto Politics_Call_To_Get_Staff
											#Put a fake staff in its place.
												It is just as easy for you to replace the magical staff with a counterfeit.
												*goto Politics_Disguise_Take_Staff
								*if (politics_academy_archmage_present)
									Archmage Cumari gasps as you reach out your hand to take the staff.
								*if (politics_academy_archmage_present=false)
									You reach out to take the staff.
								The black shadow feels ice cold as you pass your hand through it.  You feel no pain. In fact, you feel nothing at all.  You attempt to close you fingers around the staff, but nothing happens.  You pull your hand away.  It takes several minutes before warmth and feeling return to your fingers.
								*if (showstats)
									*line_break
									(Strength -2, Endurance -2 and Agility -2)
								*set strength -2
								*set endurance -2
								*set agility -2
								*goto Academy_Staff_loop
							#Use a stick to knock it free of the pedestal.
								The stick won't budge the staff.  You suspect that such a mundane solution has already been tried before, but you had to make sure.  The spells holding the staff in place are very powerful.
								*goto Academy_Staff_loop
							#Attempt to dispel the necromantic aura, knowing that it will take at least 2 days' preparation.
								*if (politics_daysleft<(travel_days+2))
									Unfortunately, you only have ${politics_daysleft} days left.  Such a massive spell would take at least 2 days to prepare and the return trip to Brightwater will take another ${travel_days}.
									*goto Academy_Staff_loop
								*set politics_academy_made_attempt true
								*if (arcana<70)
									*set politics_daysleft -1
									You are halfway through your preparations when you stumble across an insurmountable problem.  The Necromancers who cast the ward had done a very good job at preventing wizards from breaking it.  Despite your best efforts, you are unable to dispel the aura and you have wasted a day trying.
									*if (showstats)
										(Needed 70 Arcana)
										*line_break
										(Lost a Day)
									*goto Academy_Staff_loop
								*else
									You have an idea to break the spell.
									*set politics_daysleft -2
									*if (magic<80)
										Unfortunately, the amount of magical energies it requires is far beyond your ability to produce.  You suspect that many wizards have tried this approach over the years, and like you, they have all failed.  To make matters worse, you have wasted 2 days trying to break the enchantment.
										*if (showstats)
											(Needed 80 Magic)
											*line_break
											(Arcana +2 and Lost 2 Days)
										*set arcana +2
										*goto Academy_Staff_loop
									*else
										Archmage Cumari asked to be present when you made your attempt.
										*choice
											#Call for the Archmage.
												*set politics_academy_archmage_present true
												*goto Academy_Weave_Spell
											#Make the attempt without the Archmage present.
												*set politics_academy_archmage_present false
												*goto Academy_Weave_Spell

										*label Academy_Weave_Spell
										You weave a complex net of positive life energy.  The ward immediately attacks the weaves, as you knew it would.  While the necromantic spell is occupied, you cast a subtle mix of counter-spells onto the root of the spell.  The shadows dissipate almost immediately as you complete your powerful incantation.
										*if (showstats)
											*line_break
											(Magic +2 and Arcana +2)
										*set magic +2
										*set arcana +2
										
										*if (politics_academy_archmage_present)
											*label Politics_Give_Staff
											"Amazing!" the Archmage says as he reaches out and takes the staff.  
											*label Politics_AchmageTakeStaff
											"You have done myself and the Academy a great service.  Thank you."
											*if (showstats)
												*line_break
												(Archmage Cumari Relationship +20)
											*set cumari_relationship +20
											*set cumari_gotstaff true
											*goto Cumari_loop
										*else
											You have done it.  You have broken the enchantment and can take the Staff of the Archmagi.
											*if ((no_thief_vow) and (politics_academy_archmage_present=false))
												
												*goto Politics_Call_To_Get_Staff
											*choice
												#Call for Archmage Cumari and give him the staff.
													*label Politics_Call_To_Get_Staff
													You step out into the hall and stop one of the passing wizards, asking her to go get the Archmage.  She nods to you and leaves.  Archmage Cumari returns to the quarters a few minutes later.
													
													*goto Politics_Give_Staff
												#Put a fake staff in its place and recast the enchantment.
													It takes almost as much magical knowledge to recast the spell, but having learned its inner workings to dispel it, you are able to do so.
													*label Politics_Disguise_Take_Staff
													You disguise the real staff and place it among your belongings until you have left the Academy.  Many magic users and travelers carry staffs.  Even if he sees you with it in the future, he'll never suspect that it is the Staff of the Archmagi.  After it is safely put away, you call for Archmage Cumari to tell him that you were unsuccessful.
													*if (showstats)
														*line_break
														(Evil +10 and Gained the Staff of the Archmagi)
													*set good -10
													*set staff_archmagi true
													*set magic +(staff_archmagi_bonus)
													*goto Politics_Academy_GiveUp
							#Stop trying to recover the staff.
								*if (politics_academy_archmage_present)
									*label Politics_Academy_GiveUp
									"It was an idle dream," Archmage Cumari says with a sigh.  "Perhaps some day I will find a way to penetrate the spell and regain the
									*if (politics_academy_made_attempt)
										staff.  Thank you for trying."
										*if (showstats)
											*line_break
											(Archmage Cumari Relationship +10)
										*set cumari_relationship +10
										*goto Cumari_loop
									*else
										staff."
										*goto Cumari_loop
								*else
									You step out into the hall and stop one of the passing wizards, asking her to go get the Archmage.  She nods to you and leaves.  Archmage Cumari returns to the quarters a few minutes later.
									
									*goto Politics_Academy_GiveUp
					#Say, "Then why bring it up?"
						"I'm sorry, you are right," Archmage Cumari says.  "Just the ramblings of an old man.  No, I can't think of anything else besides giving the Academy autonomy,
						*if (academy_autonomy)
							which you have already agreed to do."
							*goto Cumari_loop
						*else
							which you have refused to do."
							*goto Cumari_loop
			*if (((((gloves_archery) or (necklace_nature)) or ((gem_seeing) or (magic_shield))) or (((cloak_of_spiders) or (feather_of_glibness)))) or ((infinity_arrow) or (cape_of_shadows)))
				*allow_reuse #Give the Academy a magical item from your possessions.
					*label Cumari_Give_Items
					*if (((((gloves_archery=false) and (necklace_nature=false)) and ((gem_seeing=false) and (magic_shield=false))) and (((cloak_of_spiders=false) and (feather_of_glibness=false)))) and ((infinity_arrow=false) and (cape_of_shadows=false)))
						*goto Cumari_loop
					*choice
						*if (gloves_archery) #Give the Gloves of Archery to the Academy.
							"Wonderful!" Archmage Cumari says as he accepts the magical gloves.
							*if (showstats)
								*line_break
								(Lost the Gloves of Archery, Archmage Cumari Relationship +15 and Archery Bonus -${gloves_archery_bonus})
							*set cumari_relationship +15
							*set archery -gloves_archery_bonus
							*set gloves_archery false
							*goto Cumari_Give_Items
						*if (necklace_nature) #Give the Necklace of Nature to the Academy.
							"Amazing!" Archmage Cumari says as he accepts the magical necklace.
							*if (showstats)
								*line_break
								(Lost the Necklace of Nature, Archmage Cumari Relationship +15 and Nature Bonus -${necklace_nature_bonus})
							*set cumari_relationship +15
							*set nature -necklace_nature_bonus
							*set necklace_nature false
							*goto Cumari_Give_Items
						*if (gem_seeing) #Give the Gem of Seeing to the Academy.
							"Astounding!" Archmage Cumari says as he accepts the magical necklace.
							*if (showstats)
								*line_break
								(Lost the Gem of Seeing, Archmage Cumari Relationship +15 and Perception Bonus -${gem_seeing_bonus})
							*set cumari_relationship +15
							*set perception -gem_seeing_bonus
							*set gem_seeing false
							*goto Cumari_Give_Items
						*if (magic_shield) #Give the Magic Shield to the Academy.
							"Stupendous!" Archmage Cumari says as he accepts the magical shield.
							*if (showstats)
								*line_break
								(Lost the Magic Shield and Archmage Cumari Relationship +15)
							*set cumari_relationship +15
							*set magic_shield false
							*goto Cumari_Give_Items
						*if (cloak_of_spiders) #Give the Cloak of Spiders to the Academy.
							"Excellent!" Archmage Cumari says as he accepts the magical cloak.
							*if (showstats)
								*line_break
								(Lost the Cloak of Spiders and Archmage Cumari Relationship +15)
							*set cumari_relationship +15
							*set cloak_of_spiders false
							*goto Cumari_Give_Items
						*if (feather_of_glibness) #Give the Feather of Glibness to the Academy.
							"Fabulous!" Archmage Cumari says as he accepts the magical feather.
							*if (showstats)
								*line_break
								(Lost the Feather of Glibness, Archmage Cumari Relationship +15 and Charm Bonus -${feather_of_glibness_bonus})
							*set cumari_relationship +15
							*set charm -feather_of_glibness_bonus
							*set feather_of_glibness false
							*goto Cumari_Give_Items
						*if (cape_of_shadows) #Give the Cape of Shadows to the Academy.
							"Incredible!" Archmage Cumari says as he accepts the magical cape.
							*if (showstats)
								*line_break
								(Lost the Cape of Shadows, Archmage Cumari Relationship +15 and Stealth Bonus -${cape_of_shadows_bonus})
							*set cumari_relationship +15
							*set stealth -cape_of_shadows_bonus
							*set cape_of_shadows false
							*goto Cumari_Give_Items
						*allow_reuse #Change your mind and give nothing, for now.
							*goto Cumari_loop_ns
			#Return to Brightwater
				Archmage Cumari thanks you again for coming to the Academy to speak to him.  He is an intelligent man.  He understands your predicament and your hurry to get the vote finished before Selina returns.
				*if (showstats)
					*line_break
					(Archmage Cumari Relationship +5)
				*set cumari_relationship +5
				
				"I will be there for the Grand Council," he says.
				*set politics_daysleft -(travel_days)
				*goto Politics_loop
	*allow_reuse #Speak to Lord Tovor, Master of the Treasury.
		*if (politics_met_tovor=false)
			*set politics_met_tovor true
			Lord Tovor is a thin short man who wears glasses.  Despite being a noble, Lord Tovor is a diligent and extremely intelligent clerk.  As Master of the Treasury, he knows how taxes work and knows where all of the money is spent.  His office is kept meticulously clean and organized.  He stands up as you enter and gestures for you to take a seat opposite his desk.
			
			"I am honoured to meet you, Your Highness," he says.  "The treasury is not well.  We have as many liquid assets ready as we can for emergencies and we have begun work on a few infrastructure projects.  It's a precarious time, but we are managing.  Selina discourages the use of demon summoning in Brightwater, so we aren't having the same troubles as the rest of the four duchies, but she is still bleeding our resources dry."
			*goto Tovor_loop
		*else
			Lord Tovor closes the folders on his desk and looks up at you as you enter his office.
			*label Tovor_loop
			*choice
				*if (politics_tovor_spending="None")
					*allow_reuse #Discuss war spending.
						"Ahhh, yes," Lord Tovor says.  "This is our greatest expense.  We really need to get it under control or we will not have the funds necessary for our other capital projects."
						*choice
							#Promise Lord Tovor that you will cut military spending.
								*set politics_tovor_spending "decrease"
								*if (politics_vale_spending!="None")
									*if (politics_vale_spending="decrease")
										*goto Tovor_decrease_spending
									*else
										*label Tovor_Liar
										"Strange, General Vale told me
										*if (politics_vale_spending="same")
											to expect no changes under your leadership.
										*if (politics_vale_spending="increase")
											to look closer at my budgets and to prepare for military increases.
										This is certainly awkward."
										
										*if (charm<90)
											You know that word will get back to Lord Vale as well.  You hope that your dishonesty doesn't destroy your chances of winning the vote.
											*if (showstats)
												(Needed 90 Charm)
											*if (politics_tovor_spending="decrease")
												*if (politics_vale_spending="increase")
													*if (showstats)
														*line_break
														(Evil +5, Lord Vale Relationship -40 and Lord Tovor Relationship -20)
													*set good -5
													*set vale_relationship -40
													*set tovor_relationship -20
													*goto Tovor_loop
												*else
													*comment (politics_vale_spending="same")
													*if (showstats)
														*line_break
														(Evil +5, Lord Vale Relationship -25 and Lord Tovor Relationship -20)
													*set good -5
													*set vale_relationship -25
													*set tovor_relationship -20
													*goto Tovor_loop
											*else
												*comment Told Tovor Same
												*comment And told Vale increase, since telling Vale same is not lie and telling Vale decrease is dumb and penalized for both, so only one option left . . .
												*if (showstats)
													*line_break
													(Evil +5, Lord Vale Relationship -25 and Lord Tovor Relationship -20)
												*set good -5
												*set vale_relationship -25
												*set tovor_relationship -20
												*goto Tovor_loop
										*else
											It takes some fancy talking to convince Lord Tovor that you are telling him the truth.  You know that word will get back to Lord Vale as well, but perhaps he will also believe you as you bandy the truth.
											*if (politics_tovor_spending="decrease")
												*if (politics_vale_spending="increase")
														*if (showstats)
															*line_break
															(Evil +5, Charm +2, Lord Vale Relationship -5 and Lord Tovor Relationship +15)
														*set good -5
														*set charm +2
														*set vale_relationship -5
														*set tovor_relationship +15
														*goto Tovor_loop
												*else
													*comment (politics_vale_spending="same")
													*if (showstats)
														*line_break
														(Evil +5, Charm +2 and Lord Tovor Relationship +5)
													*set good -5
													*set charm +2
													*set tovor_relationship +5
													*goto Tovor_loop
											*else
												*comment Told Tovor Same
												*comment And told Vale increase, since telling Vale same is not lie and telling Vale decrease is dumb and penalized for both, so only one option left . . .
												*if (showstats)
													*line_break
													(Evil +5, Charm +3, Lord Vale Relationship -5 and Lord Tovor Relationship +5)
												*set good -5
												*set charm +3
												*set vale_relationship -5
												*set tovor_relationship +5
												*goto Tovor_loop
								*label Tovor_decrease_spending
								"This is very welcome news," Lord Tovor says with a smile.  "The kingdom will be in great hands, if you should win the vote at the Grand Council."
								*if (showstats)
									*line_break
									(Lord Tovor Relationship +20)
								*set tovor_relationship +20
								*goto Tovor_loop
							#Promise Lord Tovor that you will keep military spending the same.
								*set politics_tovor_spending "same"
								*if (politics_vale_spending!="None")
									*if (politics_vale_spending="increase")
										*goto Tovor_Liar
									*else
								"The status quo is often a wise idea," Lord Tovor says.  "Although I hope that you will find new revenue streams, if that is the case."
								*if (showstats)
									*line_break
									(Lord Tovor Relationship +5)
								*set tovor_relationship +5
								*goto Tovor_loop
							#Tell Lord Tovor that you will need to raise military spending.
								*set politics_tovor_spending "increase"
								"Such a move may prove disastrous," Lord Tovor says.  "You will need to raise taxes in order to compensate."
								*if (showstats)
									*line_break
									(Lord Tovor Relationship -5)
								*set tovor_relationship -5
								*goto Tovor_loop
							*allow_reuse #Make no firm commitment to Lord Tovor about military spending.
								The Master of the Treasury is unhappy that you won't tell him your intentions.
								*if (showstats)
									*line_break
									(Lord Tovor Relationship -2)
								*set tovor_relationship -2
								*goto Tovor_loop
				*if (tovor_know_to_watch=false) #Ask Lord Tovor what you could do to assure his vote.
					"The treasury is always a house of cards," the bespectacled man says.  "Taxes coming in, payments going out.  I would be much happier to have a ruler who understood this balance."
					*set tovor_know_to_watch true
					*goto Tovor_loop
				*if (tovor_know_to_watch)
					*allow_reuse #Study the books.
						*if (study_books_done_once=false)
							You look over the books
							*set study_books_done_once true
							*if (arcana>=40)
								and immediately have a good understanding of how they work.  Lord Tovor seems happy at the prospect of having an intellectual monarch who has the ability to understand the ledgers as well as he does.
								*if (showstats)
									*line_break
									(Arcana +3 and Lord Tovor Relationship +5)
									
								*set arcana +3
								*set tovor_relationship +5
								*goto After_FirstBookLook
							*else
								but don't know where to begin.  There are piles of them and they are all interconnected using some strange cross-referencing system that is beyond your ability to grasp.  Lord Tovor tries not to be condescending or patronizing as he explains how it works.  Although he seems saddened by the fact that the future monarch is not very scholarly, you can tell that he still appreciates the effort.
								*if (showstats)
									(Needed 40 Arcana)
									
								*goto After_FirstBookLook
						*label After_FirstBookLook
						The tax laws are not always easy to understand.  But even more challenging is understanding how certain laws influence economic growth and balance.  There
						*if (politics_daysleft=1)
							is only 1 day left—the Grand Council is tomorrow.
							*choice
								*allow_reuse #Spend the final day studying the books.
									You spend your last day reading the long lists of numbers.
									*if (showstats)
										*line_break
										(Lord Tovor Relationship +3)
									*set tovor_relationship +3
									*set politics_treasury_visits +1
									*set politics_daysleft -1
									*goto GrandCouncil
								*allow_reuse #Do something else.
									You decide to spend your final day doing something else.
									*goto Politics_loop
						*else
							are ${politics_daysleft} days left until the Grand Council.  How many days will you spend studying the books?
							*temp temp_days_spent
							*input_number temp_days_spent 0 politics_daysleft
							*if (temp_days_spent=0)
								You change your mind about studying the books.
								*goto Politics_loop
							*set politics_troop_visits +(temp_days_spent)
							*set politics_daysleft -(temp_days_spent)
							You read about tax laws, revenue streams and expenditures.  It is not easy to follow, making you gain more respect for Lord Tovor and the work he does.
							*temp temp_relationship_boost
							*set temp_relationship_boost (temp_days_spent*3)
							*if (showstats)
								*line_break
								(Lord Tovor Relationship +${temp_relationship_boost})
							*set tovor_relationship +(temp_relationship_boost)
							*goto Politics_loop
				#Ask Tovor if he can teach you any magic.
					"It's the glasses, isn't it," the clerk says as he takes the lenses off of his face.  "They aren't magic.  They are a clever invention.  You see, they heat sand until it's…"
					
					Lord Tovor continues to explain the process of curved glass and the refracting of light in great detail.  It's clear that he enjoys the sound of his own voice as he rambles on and on.  Unfortunately, you realize that he doesn't know any magic at all.
					*if (showstats)
						*line_break
						(Nature +1 and Lord Tovor Relationship +2)
					*set nature +1
					*set tovor_relationship +2
					*goto Tovor_loop
				*allow_reuse #Speak to someone else.
					You decide to speak to someone else.
					*goto Politics_loop
	*allow_reuse #Spend time speaking to the other eastern lords and ladies.
		${branbrinn_name}'s plan was to focus on the three most influential voters and hope that they could sway the others enough to win you the election.  Although it might be a good strategy, it seems foolish to ignore the rest of the voters entirely.  There
		*if (politics_daysleft=1)
			is only 1 day left—the Grand Council is tomorrow.
			*choice
				#Spend the final day speaking to the lords and ladies of the east.
					You spend your last day visiting the lords and ladies of the east.
					*set politics_other_visits +1
					*set politics_daysleft -1
					*goto GrandCouncil
				*allow_reuse #Do something else.
					You decide to spend your final day doing something else.
					*goto Politics_loop
		*else
			are ${politics_daysleft} days left until the Grand Council.  How many days will you spend with the eastern lords and ladies?
			*temp temp_days_spent
			*input_number temp_days_spent 0 politics_daysleft
			*if (temp_days_spent=0)
				You change your mind about visiting with the eastern nobility.
				*goto Politics_loop
			*set politics_other_visits +(temp_days_spent)
			*set politics_daysleft -(temp_days_spent)
			You visit the lords and ladies of the east.  You introduce yourself to several of them and learn about their thoughts and concerns.
			*goto Politics_loop
	#Try to find out which nobles will not vote for you and deal with them.
		Assassination of rivals is a time-honoured tradition in politics.  It takes a balance of showing others what you are willing to do so they will fear acting against you, without making it so blatant that they all band together to stop your ascension.
		*temp got_branbrinn_help false
		*choice
			*selectable_if (politics_daysleft>=5) #Spend up to 5 days to find out who your most vocal opponents are.
				*if (perception>=60)
					You ask a few really good questions and manage to cut your investigation down to 3 days.  In the end, you have the names of the three nobles who are most against you.
					*if (showstats)
						*line_break
						(Perception +2 and Days Used: 3)
					*set perception +2
					*set politics_daysleft -3
					*goto Eliminate_2
				*if (perception>=40)
					You ask a few good questions and manage to cut your investigation down to 4 days.  In the end, you have the names of the three nobles who are most against you.
					*if (showstats)
						(Needed 60 Perception)
						*line_break
						(Days Used: 4)
					*set politics_daysleft -4
					*goto Eliminate_2
				*label Perception_FindOut_2
				With a little time, it isn't difficult to find the names of the three nobles who are most against you.
				*if (showstats)
					(Needed 40 Perception)
					*line_break
					(Days Used: 5)
				*set politics_daysleft -5
				*goto Eliminate_2
			#Ask Captain ${branbrinn_name} who is against you.
				${branbrinn_name} is eager to help you and knows all of the nobles.  It doesn't take long before you have the names of the three nobles who are most against you.
				*set got_branbrinn_help true
				*goto Eliminate_2
			#Don't bother trying to kill those who are against you.
				You decide to leave your vocal opposition alone.
				*goto Politics_loop

		*label Eliminate_2
		*set knows_opposition true
		*label Opposition_loop
		*choice
			#Threaten the three nobles and try to urge them into voting for you.
				*set nervous_laughter true
				*if (class_thug>0)
					As a thug, you are used to making people do what you want.  The dainty nobles don't expect someone like you coming to visit them.
					*label Intimidation_Leave
					When you leave their rooms, they are shaking with fear, but you feel confident that they won't be saying anything bad about you in the future.
					*set politics_other_visits +10
					*if (showstats)
						*line_break
						(Charm +3 and Evil +10)
					*set charm +3
					*set good -10
					*goto Politics_loop
				You speak to them about physical threats and try to persuade them into cooperation. 
				*if ((charm>=50) and (strength>=40))
					Eventually, they begin to come around.
					*goto Intimidation_Leave
				Unfortunately, they don't seem to take your threats very seriously.
				*if (showstats)
					*line_break
					(Needed 50 Charm and 40 Strength, or Levels in Thug)
				*goto Opposition_loop
			*selectable_if (gold>=40) #Hire some thugs to beat up the three nobles.  (Needs 40 Gold)
				The rough men you hire are not gentle.  The opposition against you becomes much quieter as the three nobles stop sharing their negative views about you.  You aren't certain if it is enough to help you or not.
				*if (showstats)
					*line_break
					(Gold -40, Evil +10 and Citizen Fear +10)
				*set gold -40
				*set good -10
				*set citizen_fear +10
				*set politics_other_visits +10
				*set nervous_laughter true
				*goto Beat_Up_Opposition
			#Beat up the three nobles and urge them into voting for you.
				*if ((strength>=40) or (unarmed>=40))
					The poor nobles clearly don't expect the physical abuse that you deliver upon them.  After a few broken noses, fat lips and black eyes, they begin to see things your way.  They stop talking about you to the other nobles and you feel fairly confident that they will vote in your favour.
					*if (showstats)
						*line_break
						(Strength +2, Unarmed +2, Evil +10 and Citizen Fear +10)
					*set strength +2
					*set unarmed +2
					*set good -10
					*set citizen_fear +10
					*label Beat_Up_Opposition
					*set nervous_laughter true
					*set politics_other_visits +10
					*if (got_branbrinn_help)
						
						Although Captain ${branbrinn_name} never accuses you of anything, you can tell that ${branbrinn_heshe} must have made a connection between your questions and the injured nobles.
						*if (showstats)
							*line_break
							(${branbrinn_name} Relationship -20)
						*set branbrinn_relationship -20
						*goto Politics_loop
					*else
						*goto Politics_loop
				Although the nobles are a little pudgy and dainty, they still manage to fight back against your physical arguments.  You must be careful in your bullying so that you don't get caught.  This makes it difficult to administer proper beatings.
				*if (showstats)
					(Needed 40 Strength or 40 Unarmed)
				*goto Opposition_loop
			*selectable_if (gold>=120) #Hire an assassin to kill the three nobles.  (Needs 120 Gold)
				You contact a member from the Guild of Assassins.
				*if (class_assassin>0)
					Being a member yourself, it is easy for you to find them.
				The person who speaks to you names the guild's price and you pay it.  The three nobles disappear while you are seen attending a feast.  With a rock-solid alibi, nobody can accuse you of the wrongdoing, although rumours still spread.
				*if (showstats)
					*line_break
					(Gold -120, Evil +20 and Citizen Fear +10)
				*set gold -120
				*set good -20
				*set citizen_fear +10
				*label Killed_Opposition
				*set nervous_laughter true
				*set politics_other_visits +10
				*if (got_branbrinn_help)
					
					Although Captain ${branbrinn_name} never accuses you of anything, you can tell that ${branbrinn_heshe} must have made a connection between your questions and the missing nobles.
					*if (showstats)
						*line_break
						(${branbrinn_name} Relationship -40)
					*set branbrinn_relationship -40
					*goto Politics_loop
				*else
					*goto Politics_loop
			#Kill the three nobles yourself.
				*if (class_assassin>0)
					As an assassin, such work is easy for you to do.  You manage to arrange for all three of them to have accidents.  A fall from a tower, a poison in a drink and a mugging in the streets.  In the end, the three nobles aren't alive to vote against you.  Although you aren't caught, rumours still spread.
					*if (showstats)
						*line_break
						(Evil +30 and Citizen Fear +10)
					*set good -30
					*set citizen_fear +10
					*set politics_other_visits +10
					*goto Killed_Opposition
				If it were just one person, you might have been able to do it.  But three targets makes things very tricky, and you aren't confident that you would be able to get away with it.  In the end, you realize that you will likely need to hire a professional.
				*if (showstats)
					*line_break
					(Needed Levels in Assassin)
				*goto Opposition_loop
			#Change your mind about doing anything against the nobles who don't like you.
				In the end, you decide to do nothing about your vocal opposition.
				*goto Politics_loop
*label GrandCouncil

The day of the Grand Council is cool and windy as summer ends and autumn begins.
*if (plan_to_meet)
	A servant knocks on your door only a few minutes before the meeting to tell you that the Archmage has just arrived.  You had expected the Archmage to arrive a few days in advance, like the other nobles who had travelled from a distance.  Instead, the servant explains that he had been seen walking through the hallway of the keep only a moment before and that the stablehands hadn't even taken a horse from him.
	*choice
		#Meet the Archmage.
			Archmage Cumari meets you in the hallway just as he is about to enter the main hall. 
			
			"Greetings, Your Highness," the Archmage says.
			*if (academy_metcumari)
				"It is good to see you again.  I must say, I am surprised to learn who you really are."
			*if (academy_metcumari=false)
				*if (((academy_stay="student") or (academy_stay="bard")) or ((academy_stay="sage") or (academy_stay="graduate")))
					"I must say, I am surprised to find out who you really are.  You stayed with us for a year without me suspecting a thing."
			*if (showstats)
				*line_break
				(Archmage Cumari Relationship +3)
			*set cumari_relationship +3
			
			The lords and ladies nod in greeting to you as they attempt to squeeze past.  You hear the Master of Ceremonies banging his staff on the floor from within as he attempts to get everyone to sit down.
			
			"Pardon me, but it seems I need to find my seat," Archmage Cumari says as he leaves you in order to enter the hall.  "I wish we had more time to talk."
			
			*goto GrandCouncil_AfterCumari_Consideration
		#Prepare for the council.
			Although you had intended to speak to Archmage Cumari before the Council, you realize that you are too busy.
			*set politics_met_cumari false
			*goto GrandCouncil_AfterCumari_Consideration
*else
	*goto GrandCouncil_AfterCumari_Consideration

*label GrandCouncil_AfterCumari_Consideration
It is likely wise to assume that Selina now has word of what you are doing, but as suspected, she didn't make it back to Brightwater in time.  ${branbrinn_name} has done well since the great hall of the keep is filled with the lords and ladies of the eastern duchy.
*if ((prisonchild_exists) and (prisonchild_not_dealt_with))
	$!{branbrinn_heshe} had a very busy week.  You even hear that ${branbrinn_heshe} found the time to take the child from the prison to an orphanage.
	*set prisonchild_exists false
*if (politics_met_vale=false)
	
	You see a stern man in his mid-fifties.  From the description, this is Lord Vale.  His iron-gray hair gives him a look of authority and his body is rock hard from disciplined exercise and eating.  He was a gifted commander for your parents and is acknowledged as one of the finest strategic minds in the four duchies.  His ability as a general is invaluable.  He glances coldly in your direction and you wonder if it was wise to not have spoken to him before now.
	*if (showstats)
		*line_break
		(Lord Vale Relationship -10)
	*set vale_relationship -10
*if (politics_met_tovor=false)
	
	A thin short man wearing glasses studies you closely from his seat among the other nobles.  This must be Lord Tovor, Master of the Treasury.  He scrutinizes you from a distance and likely wonders why you haven't spoken to him yet.
	*if (showstats)
		*line_break
		(Lord Tovor Relationship -10)
	*set tovor_relationship -10
*if (politics_met_cumari=false)
	
	*if ((politics_met_vale) and (politics_met_tovor))
		You see Lord Vale and Lord Tovor among the assembled lords and ladies.
	*if ((politics_met_vale=false) and (politics_met_tovor))
		You see Lord Tovor among the assembled lords and ladies.
	*if ((politics_met_vale) and (politics_met_tovor=false))
		You see Lord Vale among the assembled lords and ladies.
	A group of men and women in bright blue robes covered in yellow stars and moons sit apart from the other nobles.  In the midst of these wizards you spot the Archmage of the Academy.  He is the only voter in the hall who is not a noble, but his influence and power manifest themselves by the fact that he is allowed a small retinue of retainers and a vote.  Archmage Cumari looks over toward you with curiosity as he likely ponders why you didn't make an effort to speak to him before the vote.
	*if (questdetails="the Academy of Wizards")
		He looks much more impressive in this setting than he did when you saw him in the Academy a year ago.
	*if (showstats)
		*line_break
		(Archmage Cumari Relationship -10)
	*set cumari_relationship -10
*if (politics_met_cumari)
	
	*if ((politics_met_vale) and (politics_met_tovor))
		You see General Vale and Lord Tovor among the assembled nobles.  You also
	*if ((politics_met_vale=false) and (politics_met_tovor))
		You see Lord Tovor among the assembled nobles.  You also
	*if ((politics_met_vale) and (politics_met_tovor=false))
		You see Lord Vale among the assembled nobles.  You also
	*if ((politics_met_vale=false) and (politics_met_tovor=false))
		You 
	see a group of men and women in bright blue robes covered in yellow stars and moons sitting apart from the other nobles.  In the midst of these wizards you see Archmage Cumari.
	*if (plan_to_meet=false)
		He gives you a nod of greeting from across the hall.

"$!{princeprincess} ${name}," the herald intones as you enter.  "First and only child of the late King Brand and Queen Jade, heir presumptive to the former Kingdom of Daria."

*if (nervous_laughter)
	There is a lot of nervous energy in the hall and shifting of feet.
	*goto After_Nervous
*if (politics_other_visits=0)
	The hall is silent as you are introduced.
*if ((politics_other_visits>=1) and (politics_other_visits<=2))
	A few of the nobles clap as you are introduced.  You recognize them as the ones you had a chance to visit.
*if ((politics_other_visits>=3) and (politics_other_visits<=4))
	Several of the nobles clap as you are introduced.  You recognize them as the ones you had a chance to visit.
*if ((politics_other_visits>=5) and (politics_other_visits<=13))
	Many of the nobles clap as you are introduced.  You recognize them as the ones you had a chance to visit.
*if (politics_other_visits=14)
	The hall explodes into applause as you are introduced.  You recognize many of the nobles from your two weeks of campaigning. 
*label After_Nervous
The proceedings are very formal as a cleric of Lucien steps forward and proclaims that you are indeed who you claim to be.  The tension in the room skyrockets as a tall, bald man in expensive clothing stands up and speaks.

"This is a farce," the man says.  "Daria is no more.  Duchess Selina is the ruler of the Dumain duchy and this relic of our past is no longer relevant!"
*if (knows_opposition)
	
	Lord Weslo's name came up during your investigation, but because he wasn't sharing his views with the other nobles, you didn't consider him much of a threat.
*choice
	#Say, "She was made ruler by error.  Since I am still alive, my right to the throne supersedes her claim!"
		The hall murmurs in agreement at your words.  The priests and priestesses of Lucien and Auriel confer among themselves and then nod.  It is clear that the nobles will be allowed to vote.
		*if (showstats)
			*line_break
			(History +2)
		*set history +2
		*goto DemonWarning
	#Say, "Selina murdered your rightful king and queen!"
		The nobles in the hall glance down at their feet and over your head.  Nobody seems able to look you in the eye as you pronounce the fact that their duchess is a killer and guilty of regicide.  You know that it will be hard for them to keep Selina as their ruler and have a clear conscience.
		*if (showstats)
			*line_break
			(Perception +2)
		*set perception +2
		*goto DemonWarning
	#Say, "You are the true power in the land.  You may vote as you please."
		The nobles nod as the truth behind your words hits home.  A ${kingqueen} is only a single person, after all.  It is through the power invested in them that they have the strength to command and rule.
		*if (showstats)
			*line_break
			(Charm +2)
		*set charm +2
		*goto DemonWarning
	#Say, "The Gods and Goddesses themselves ordained my position as the heir!"
		The priests and priestesses nod in agreement.  Before your parents died, you were presented before the nobles of the land within the great temple in Tornassa and proclaimed the heir.  It was a religious vow which no mortal should be allowed to usurp.
		*if (showstats)
			*line_break
			(Religion +2)
		*set religion +2
		*goto DemonWarning

*label DemonWarning

The bald noble is daunted by your words, but speaks one more time.  "The vote shall take place, as is the law.  But Duchess Selina has been a fair and just ruler.  Empires fall and dynasties crumble.  Why should we return to a monarchy when our four duchies are serving us so well?"
*temp get_the_circlet 0
*set politics_nofriends true
*if (((academy_autonomy) or (cumari_gotstaff)) or (cumari_relationship>=80))
	
	"You are a fool, Lord Weslo," Archmage Cumari's voice says loudly as all eyes turn toward him.  "Selina is a pawn of the Consortium.  They have unleashed a great plague upon the land.  Every day hundreds of people are being dominated by demons and forced to do terrible things.  Even Selina knows that demon summoning is evil, since she doesn't allow it in Brightwater.  The rightful heir is alive and I will be voting for $!{princeprincess} ${name}."
	*if (showstats)
		*line_break
		(Archmage Cumari Relationship +2 and Gain a Faction of Voters)
	*set get_the_circlet +1
	*set cumari_relationship +2
	*set politics_nofriends false
*if (vale_relationship>=70)
	
	"Duchess Selina serves only herself, Lord Weslo," General Vale's voice says loudly as all eyes turn toward him.  "We have soldiers dying every day as we are forced to fight demons who have gone free upon the land because of the removal of the summoning ban.  Even she knows it is wrong, since she doesn't allow it in Brightwater, but she still lets the ignorant people outside the city do it.  I will be voting for $!{princeprincess} ${name}
	*if (politics_nofriends=false)
		too
	so that we can restore order to our kingdom."
	*if (showstats)
		*line_break
		(General Vale Relationship +2 and Gain a Faction of Voters)
	*set get_the_circlet +1
	*set vale_relationship +2
	*set politics_nofriends false
*if (tovor_relationship>=70)
	
	"The Dumain duchy is failing," Lord Tovor's voice says quietly as all eyes turn toward him.  "Our treasury is nearly empty and we receive less taxes every month.  The harvests are sitting in the field and our citizens do not labour.  Instead, they summon demons to try to get their work done.  But for every successful summoning, two go wrong.  We need to ban demon summoning again, and not just in Brightwater.  But Selina won't do that.  She's too closely tied to the Consortium.  I
	*if (politics_nofriends=false)
		also
	will be voting for $!{princeprincess} ${name}."
	*if (showstats)
		*line_break
		(Lord Tovor Relationship +2 and Gain a Faction of Voters)
	*set get_the_circlet +1
	*set tovor_relationship +2
	*set politics_nofriends false
*if (politics_other_visits>=5)
	
	"The fields lay unharvested!" a voice shouts from one of the nobles you had visited.
	
	"Citizens die at the hands of the demons!" says another, quickly followed by a third.
	
	"Selina is a hypocrite!  She keeps the ban in Brightwater but allows the uneducated citizens outside the city to die.  She's too closely tied to the Consortium.  The rightful heir is alive!"
	*if (showstats)
		*line_break
		(Charm +3 and Gain a Faction of Voters)
	*set get_the_circlet +1
	*set charm +3
	*set politics_nofriends false
*if (politics_nofriends)
	
	"The Dumain duchy is under duress," ${branbrinn_name} says to the assembled nobles.  "The people are dying at the hands of the demons they summon, yet Duchess Selina refuses to put the demon summoning law back in place outside of Brightwater.  The rightful heir is alive.  Let us take the vote and restore order to our kingdom!"

Things move quickly after this.  The bald noble returns to his seat and the ballots are passed around.  The lords and ladies talk amongst themselves as they vote.  You hear more about the demon woes troubling the lands and how Selina does nothing to stop it.  Once more, you ponder Zusak's motives.  What use did he have for the broken Demonstone you carry?  After killing your parents and creating the duchies, he could have lived like a king without any of the responsibilities of governing.  Why would he cause needless chaos by sending out crates of Demonstones and lifting the ban?  What did he stand to gain?  It makes no sense.

The ballots are cast and the votes are counted.
*page_break The Results
"Hear ye, hear ye," the herald shouts.  "The assembly of lords and ladies hereby proclaim that the duchy of Dumain is no more!  The Kingdom of Daria hereby recognizes $!{princeprincess} ${name} as the true and rightful heir to the throne!"
*if (using_legacy)
	
	The room breaks into applause and you hear some of your companions shouting with exuberance.  A blue glow catches your attention.  You see the wizard of Elmvale standing off to the side.  $!{legacy_heshe} looks very young and you know that this is one of ${legacy_hisher} earlier visits.  $!{legacy_heshe} is
	*if (legacy_good)
		applauding along with the others.
	*if (legacy_good=false)
		standing to the side with ${legacy_hisher} arms folded in front of ${legacy_himher}.  $!{legacy_heshe} has a look of satisfaction on ${legacy_hisher} face.  It's clear that ${legacy_heshe} is proud at your consolidation of power.
	$!{legacy_heshe} nods a greeting toward you before vanishing.

The herald continues the formalities, but you are only partially listening.  One thing that you take note of is the fact that you won by a
*if (get_the_circlet=4)
	unanimous decision.
*if (get_the_circlet=3)
	vast majority.
*if (get_the_circlet=2)
	large margin.
*if (get_the_circlet=1)
	narrow margin.
*if (get_the_circlet=0)
	very narrow margin.

The council decides that your coronation will take place after you have reclaimed all of Daria.  After the civil uncertainty of the last decade, it is decided that continuing to call you a ${princeprincess} will help the populace see the validity of your rule as a connection to the past.
*if (get_the_circlet>=3)
	
	Despite the fact that you aren't being named ${kingqueen} yet, you are still given a circlet.  You are stunned to learn that it is the same circlet your
	*if (mc_hisher="his")
		father
	*if (mc_hisher="her")
		mother
	wore.  Selina had it in her private quarters.  You wonder about the ambitions of the red-haired poisoner and if she had plans to be named queen of the four duchies.  The nobles urge you to wear it as a symbol of your new authority.  You have no time to celebrate as dozens of nobles clamour to speak to you.
	*if (showstats)
		*line_break
		(Gained the Circlet of Daria)
	*set circlet true
*if (get_the_circlet<3)
	You have no time to celebrate as dozens of nobles clamour to speak to you.
	*if (showstats)
		(Needed 3 of 4 Factions of Voters for Reward)
*set stage 5
*temp so_much_vale false
*temp so_much_tovor false
*temp so_much_branbrinn false
*temp so_much_speech false
*temp so_much_cumari false
*label So_Much_To_Do_loop
*if ((((so_much_vale) and (so_much_tovor)) and ((so_much_speech) and (so_much_branbrinn))) and (so_much_cumari))
	*goto Settle_In
*choice
	*if (so_much_branbrinn=false) #Speak to ${branbrinn_name}.
		*set so_much_branbrinn true
		"Congratulations, Your Highness," ${branbrinn_name} says.  "You have done it.  The Brightwater City Guard is firmly in your control,
		*if (breakout_killed_guards)
			naturally.  It was unfortunate that you killed those prison guards, but it couldn't have been helped.
			*if (showstats)
				*line_break
				(Army Morale -7)
			*set army_morale -7
			*gosub Check_Army_Stats
		*if (breakout_killed_guards=false)
			naturally.  It is good that only Bunta was killed in your prison break and no guards were harmed.
			*if (showstats)
				*line_break
				(Army Morale +5)
			*set army_morale +5
		
		"The news of your victory is being celebrated across the city.  But, what do you wish the guards to do about those who are deserting and going to Tornassa to rejoin Duchess Selina alongside Duke Uddo?"
		*choice
			#Say, "Let them go.  There is nothing we can do about it."
				${branbrinn_name} nods acceptance at your order and then salutes you before returning to ${branbrinn_hisher} duties.
				*if (showstats)
					*line_break
					(Citizen Reputation +5)
				*set citizen_reputation +5
				*goto So_Much_To_Do_loop			
			#Say, "Help them on their way.  When Tornassa is mine again, they will still be my citizens."
				${branbrinn_name} nods acceptance at your orders.  Your newly minted kingdom was small, but in time, you hoped it would cover all of its former lands again.  They were just scared families, fleeing for the familiar.
				*if (showstats)
					*line_break
					(Good +5, Army Size -5 and Citizen Reputation +10)
				*set good +5
				*set army_size -5
				*set citizen_reputation +10
				*gosub Check_Army_Stats
				*goto So_Much_To_Do_loop
			#Say, "Let them go, but record their names."
				${branbrinn_name} nodded acceptance at your order.  It would be a large undertaking, but at least you'd have a record of those citizens who were disloyal to you.  $!{branbrinn_heshe} salutes you.
				*goto So_Much_To_Do_loop
			#Say, "Execute the deserters."
				${branbrinn_name} blinks in surprise, but that is all.  $!{branbrinn_heshe} is the captain of your guard and takes security threats very seriously.  $!{branbrinn_heshe} salutes you and leaves to follow your orders.  Selina would not be building her army from your citizens.
				*if (showstats)
					*line_break
					(Citizen Fear +10 and Citizen Reputation -20)
				*set citizen_fear +10
				*set citizen_reputation -20
				*goto So_Much_To_Do_loop
	*if (so_much_vale=false) #Speak to General Vale.
		*set so_much_vale true
		"Time is critical," the general says.  "Selina already has Duke Uddo's support in Tornassa.  She'll be gathering her army alongside Duke Eddan of Ludd.  At least Duke Bandar has no troops worth mentioning.  By this time next year, they will march on us and either way, we will fail."
		*choice
			#Say, "We shall defeat them."
				"Perhaps," the general says dubiously.  "But at a great cost.  You will be the ruler of a small kingdom here in the east while they rule the rest of the land.  It will take years to rebuild a new army and they will be doing the same, but faster and bigger.  The second confrontation will be an assured victory for them. No, we must strike first.
				*goto General_Talk_2
			#Say, "What do you suggest?"
				"There is only one option.  We must strike first.
				*goto General_Talk_2
			#Say, "We will take the fight to them."
				The general nods in agreement.  "Yes, we must strike first.
				*goto General_Talk_2
			
		*label General_Talk_2
		
		"You will have the winter to build the strongest army you can muster.  We must then march southwest to Ludd and defeat Duke Eddan.  With the Eddan duchy under your rule, we must immediately continue north and defeat Duke Uddo and Duchess Selina in Tornassa.  After reclaiming Tornassa, their might will be broken and it will be simple to march north to take the Bandar duchy as well.  It must be done in one season or they will have time to build insurmountable defences against you.  As it stands, it will be a longshot to success, but it will be our only chance."
		
		You realize that General Vale's knowledge and reputation among the troops will prove invaluable as you take back your kingdom.
		*if (vale_relationship>=70)
			It is a good thing that you have gained his respect.
			*if (showstats)
				*line_break
				(Army Power +3 and Army Morale +3)
			*set army_power +3
			*set army_morale +3
			*goto So_Much_To_Do_loop
		*else
			It is a pity that you have not gained his respect, since it will make working with him much more difficult.
			*if (showstats)
				(Needed 70 Lord Vale Relationship)
			*goto So_Much_To_Do_loop
	*if ((so_much_vale) and (so_much_tovor=false)) #Speak to Lord Tovor.
		*set so_much_tovor true
		"So, we are going to war," Lord Tovor says.  "It is only natural that you would strive to reclaim the rest of your kingdom.
		*if (politics_tovor_spending="decrease")
			But, how can we do this if we are lowering war funding as we discussed?"
		*if (politics_tovor_spending="same")
			But, how can we do this if we are keeping the war funding the same, as we discussed?"
		*if (politics_tovor_spending="increase")
			This is why you told me that you are increasing the war funding, of course."
		*if (politics_tovor_spending="None")
			What do you intend to do with the war funding?"
		*choice
			#Say, "We are increasing the war spending.  Reallocate the tax revenues immediately."
				*set army_budget "increase"
				*if ((politics_tovor_spending="decrease") or (politics_tovor_spending="same"))
					"You lied to me," Lord Tovor says in a quiet voice.  "I will do as you say, my ${princeprincess}."
					
					The clerk bows to you formally and leaves.  The influx of money will allow you to hire more soldiers, buy better equipment and give the troops better salaries.
					*if (showstats)
						*line_break
						(Citizen Reputation -20, Army Food +10, Army Size +5, Army Morale +5, Army Power +5 and Lord Tovor Relationship -50)
					*set citizen_reputation -20
					*set army_food +10
					*set army_size +5
					*set army_morale +5
					*set army_power +5
					*set tovor_relationship -50
					*goto So_Much_To_Do_loop
				*else
					"It will be difficult, but I shall do as you have asked, my ${princeprincess}."
					
					The clerk bows to you formally and leaves.  The influx of money will allow you to hire more soldiers, buy better equipment and give the troops better salaries.
					*if (showstats)
						*line_break
						(Citizen Reputation -20, Army Food +10, Army Size +5, Army Morale +5 and Army Power +5)
					*set citizen_reputation -20
					*set army_food +10
					*set army_size +5
					*set army_morale +5
					*set army_power +5
					*goto So_Much_To_Do_loop
			#Say, "We are leaving the war spending the same."
				*set army_budget "same"
				*if (politics_tovor_spending="decrease")
					"You lied to me," Lord Tovor says in a quiet voice.  "I will do as you say, my ${princeprincess}."
					
					The clerk bows to you formally and leaves.  It will be difficult to build an army without increasing the spending, but at least the common people will be happy.
					*if (showstats)
						*line_break
						(Citizen Reputation +10, Army Morale -2, Army Power -2 and Lord Tovor Relationship -40)
					*set citizen_reputation +10
					*set army_morale -2
					*set army_power -2
					*set tovor_relationship -40
					*gosub Check_Army_Stats
					*goto Check_Vale_Same
				*else
					"A wise and prudent course of action, my ${princeprincess}."
					
					The clerk bows to you formally and leaves.  It will be difficult to build an army without increasing the spending, but at least the common people will be happy.
					*if (showstats)
						*line_break
						(Citizen Reputation +10, Army Morale -5 and Army Power -5)
					*set citizen_reputation +10
					*set army_morale -5
					*set army_power -5
					*gosub Check_Army_Stats
					*label Check_Vale_Same
					*if (politics_vale_spending="increase")
						
						You know that General Vale will not be happy that you have broken your word to him, but now that you are the legitimate ruler, there is nothing he can do about it.
						*if (showstats)
							*line_break
							(Lord Vale Relationship -50)
						*set vale_relationship -50
					*goto So_Much_To_Do_loop
			#Say, "We are cutting the war budget."
				*set army_budget "decrease"
				"This is wonderful news, my ${princeprincess}!  The people will rejoice when they hear."
				*if (politics_tovor_spending="decrease")
					*if (showstats)
						*line_break
						(Lord Tovor Relationship +5)
					*set tovor_relationship +5
				*if (politics_tovor_spending="same")
					*if (showstats)
						*line_break
						(Lord Tovor Relationship +10)
					*set tovor_relationship +10
				*if (politics_tovor_spending="None") or (politics_tovor_spending="increase")
					*if (showstats)
						*line_break
						(Lord Tovor Relationship +40)
					*set tovor_relationship +40
				
				The clerk bows to you formally and leaves.  It will be very difficult to build an army with even less money, but at least the common people will be happy.
				*if (showstats)
					*line_break
					(Citizen Reputation +25, Army Food -5, Army Size -10, Army Morale -10 and Army Power -10)
				*set citizen_reputation +25
				*set army_food -5
				*set army_size -10
				*set army_morale -10
				*set army_power -10
				*gosub Check_Army_Stats
				*if (politics_vale_spending="increase") or (politics_vale_spending="same")
					
					You know that General Vale will not be happy that you have broken your word to him, but now that you are the legitimate ruler, there is nothing he can do about it.
					*if (showstats)
						*line_break
						(Lord Vale Relationship -60)
					*set vale_relationship -60
				*goto So_Much_To_Do_loop
	*if ((so_much_vale) and (so_much_cumari=false)) #Speak to Archmage Cumari.
		*set so_much_cumari true
		"So, you plan to begin your reign with war," Archmage Cumari says thoughtfully.  "General Vale is correct, of course.  You have no other option.  Time is against you.  The other three duchies will grow faster than you and then they will attack.  You have to attack first, but I'm afraid that you will lose.

		The archmage straightens his wizardly robes before continuing.
		
		"Your army is too small.  Tornassa always held the bulk of Daria's soldiers and they are firmly in the hands of Duke Uddo.  Even if you drafted every able-bodied man and woman across the east, you wouldn't have enough.  That is, if you restrict your soldiers to being human."
		*choice
			#Ask, "What are you talking about?"
				"The other races, of course," Archmage Cumari says.  "Dwarves, elves, half-orcs, halflings and gnomes.  They have always kept to themselves, but if you are going to be triumphant, you'll need their aid."
				*goto So_Much_Cumari_Talk2
			#Say, "You refer to the demi-humans?"
				"Yes.  The dwarves, elves, half-orcs, halflings and gnomes.  They have always kept to themselves, but if you are going to be triumphant, you'll need their aid."
				*goto So_Much_Cumari_Talk2
			#Say, "You mean the demons?"
				"What?!" Archmage Cumari says, thrown off-guard.  "Of course not!  They are an abomination!  I refer to the other races, of course.  Dwarves, elves, half-orcs, halflings and gnomes.  They have always kept to themselves, but if you are going to be triumphant, you'll need their aid."
				*goto So_Much_Cumari_Talk2
			#Scoff, "Fairy tales won't help us."
				"Not fairy tales," Archmage Cumari says.  "I refer to the other races, of course. Dwarves, elves, half-orcs, halflings and gnomes.  They have always kept to themselves, but if you are going to be triumphant, you'll need their aid."
				*goto So_Much_Cumari_Talk2
		
		*label So_Much_Cumari_Talk2
		
		The other races are so aloof that many common people don't even realize they really exist.  Occasionally, someone will see an elf, and a few very rich nobles own weapons made by the dwarves, but that is it.  Even the raids in the west are blamed solely on orcs.  The idea of an orc-human baby is disgusting, in many people's eyes.  For as long as people can remember, the other races have stayed clear of humans.  Your parents respected this unspoken truce and peace held.
		
		"It is time for a true alliance to be formed," Archmage Cumari says.  "They will join you.  The demon threat is too powerful for them to ignore humans any longer."
		*choice
			#Say, "Their aid would be most beneficial."
				"The Academy of Wizards has an artifact which can teleport you and a few others over great distances," Archmage Cumari says.  "Journeys that would have taken months can be done in mere seconds.
				*goto So_Much_Cumari_Talk3
			#Say, "Even if I wanted their aid, how would I find them?"
				"The Academy of Wizards knows of their locations," Archmage Cumari says smugly.  "And even better, we have the means to get you there quickly.  We have an artifact which can teleport you and a few others over great distances.  Journeys that would have taken months can be done in mere seconds.
				*goto So_Much_Cumari_Talk3
			#Say, "The army must march by spring. We don't have time for this."
				"The Academy of Wizards has an artifact which will greatly help you.  With it, you and a few others will be able to teleport where you need to go.  Journeys that would have taken months can be done in mere seconds.
				*goto So_Much_Cumari_Talk3
			#Say, "Yes, they shall serve us or die."
				Archmage Cumari clears his throat and looks at you with an uncomfortable expression on his face.  "They are powerful and they are sovereign nations, even if they lack the cities we have.  Please, be cautious and respect them.  The Academy of Wizards has an artifact which can teleport you and a few others over great distances.  Journeys that would have taken months can be done in mere seconds.
				*goto So_Much_Cumari_Talk3

		*label So_Much_Cumari_Talk3
		*if (using_legacy)
			You see, I found a letter."
			
			Archmage Cumari smiles at you.
			
			"A time-traveling wizard from the past," he says.  "$!{legacy_heshe} found a powerful artifact and donated it to the Academy under the single condition that we loan it to you this winter.
		*if (using_legacy=false)
			I will loan you this artifact for the winter.
		If you do well, come spring, you may have an army strong enough to reclaim the rest of your kingdom.  We must remove this demon summoning threat and I believe that you are our only chance to do so."
		*goto So_Much_To_Do_loop
	*if (so_much_speech=false) #Give a speech to the citizens of Daria.
		*set so_much_speech true
		There are many lords and ladies trying to speak to you.  Some of them want favours, some of them want the prestige of having spoken to the ${princeprincess} and some of them have legitimate questions.  You put it all on hold as you prepare to speak to the people themselves.  Hundreds gathered to hear the results of the vote, but when it is known that you will be speaking to them directly, the crowd swells into the thousands.  As you step onto the balcony,
		*if (get_the_circlet=0)
			the crowd is silent.  Having won by a narrow margin has made the citizens leery of their new ruler.
			*if (showstats)
				*line_break
				(Citizen Reputation -20)
			*set citizen_reputation -20
		*if (get_the_circlet=1)
			the crowd cheers politely.  As you won by just a few votes, the citizens are uncertain about their new ruler.
		*if (get_the_circlet>=2)
			the crowd cheers.
			*if (citizen_reputation<50)
				They may not like you personally, but they are still hopeful over the fact that their nobles have agreed upon a leader.
			*if (circlet)
				When they see that you are wearing the Circlet of Daria, they go wild with excitement.
				*if (showstats)
					*line_break
					(Citizen Reputation +15)
				*set citizen_reputation +15
			*if (circlet=false)
				*if (showstats)
					*line_break
				(Citizen Reputation +5)
			*set citizen_reputation +5
		*choice
			#You tell the people that you plan to serve them faithfully and with their best interests at heart.
				*if (charm>=50)
					The crowd roars in approval at your words.  You can practically see them swell with pride and hope as you speak to them.
					*if (showstats)
						*line_break
						(Charm +3 and Citizen Reputation +10)
					*set charm +3
					*set citizen_reputation +10
					*goto So_Much_To_Do_loop
				*else
					The crowd applauds at your words, but you can see that they are hesitant to believe you.  After living under Selina's rule for so many years, and knowing that the other three duchies will not be happy with their separation, they are fearful of the uncertain future.
					*if (showstats)
						(Needed 50 Charm)
						*line_break
						(Citizen Reputation +5)
					*set citizen_reputation +5
					*goto So_Much_To_Do_loop
			#You tell the people that they are yours to command and that any disloyalty will not be tolerated.
				The smiles in the crowd quickly vanish as they learn that they are now subjects to a ruler who plans to govern with an iron fist.  A few of them nod in agreement, showing respect for a strong leader, but most of them look fearful of an uncertain future.
				*if (showstats)
					*line_break
					(Citizen Fear +5)
				*set citizen_fear +5
				*goto So_Much_To_Do_loop
	*if (jacejess_inparty) #Speak to ${jacejess_name} about legalizing Soulburning.
		"Soulburning isn't illegal," ${jacejess_name} says.  "People just hate us.  Necromancy is illegal and maybe demon summoning should be
		*if (demonsummoner)
			too, but I guess you'd disagree with that.
		*if (demonsummoner=false)
			too.
		*if (soulburner_knowledge)
			Of course, after reading the book at the Academy, I see the reason for the hatred.  Ancient Soulburners used to steal the energy from innocent people to fuel their magic.  As far as I know, I'm the only person alive today who knows how to do this."
			*if (showstats)
				*line_break
				(History +5)
			*set history +5
			*goto So_Much_To_Do_loop
		But Soulburning?  It's something a person is born with.  How could it be illegal?"
		*goto So_Much_To_Do_loop

*label Settle_In

The leaves on the trees begin to fall and the temperature drops quickly during the first few weeks of your rule.  Samuel, the Head Steward, cleans out Selina's quarters and gives them to you.  You don't find anything valuable among her belongings.  
*if (prisonchild_exists)
	${prisonchild_name} and your companions
*if (prisonchild_exists=false)
	Your companions
are assigned guest quarters in your new
*if (lover_exists)
	keep, although ${lover_name} shares your room.
*if (lover_exists=false)
	keep.

Being the ruler of a kingdom brings many benefits, including a fair wage for your services.  Lord Tovor informs you that your stipend will be paid to you after a legislated length of time.  For now, weapons and equipment are offered to you from the store rooms.  Access to the royal treasury will remain off limits.  The charter is clear that the tax money belongs to the people.  After you have conquered Tornassa, you might have a chance to reclaim your family's wealth, if there is anything left.  But for now, you have to be careful with your spending.
*label Free_Stuff_loop
*if (((((sword) and (dagger)) and ((bow) and (rope))) and (((lantern) and (waterskin)) and ((flintandsteel) and (sleepingroll)))) and (hammerspikes))
	*goto End_Of_Politics
*choice
	*if (sword=false) #Take a sword.
		You take a sword from the armoury.
		*if (showstats)
			*line_break
			(Gained a Sword)
		*set sword true
		*goto Free_Stuff_loop
	*if (dagger=false) #Take a dagger.
		You take a dagger from the armoury.
		*if (showstats)
			*line_break
			(Gained a Dagger)
		*set dagger true
		*goto Free_Stuff_loop
	*if (bow=false) #Take a quiver of arrows and a bow.
		You take a bow from the armoury.
		*if (showstats)
			*line_break
			(Gained a Bow)
		*set bow true
		*goto Free_Stuff_loop
	*if (rope=false) #Take a rope.
		You take a rope from the storerooms.
		*if (showstats)
			*line_break
			(Gained a Rope)
		*set rope true
		*goto Free_Stuff_loop
	*if (hammerspikes=false) #Take a hammer and some spikes.
		You take a hammer and some spikes from the storerooms.
		*if (showstats)
			*line_break
			(Gained a Hammer and Spikes)
		*set hammerspikes true
		*goto Free_Stuff_loop
	*if (lantern=false) #Take a lantern.
		You take a lantern from the storerooms.
		*if (showstats)
			*line_break
			(Gained a Lantern)
		*set lantern true
		*goto Free_Stuff_loop
	*if (waterskin=false) #Take a waterskin.
		You take a waterskin from the storerooms.
		*if (showstats)
			*line_break
			(Gained a Waterskin)
		*set waterskin true
		*goto Free_Stuff_loop
	*if (flintandsteel=false) #Take a flint and steel.
		You take a flint and a piece of steel from the storerooms.
		*if (showstats)
			*line_break
			(Gained Flint and Steel)
		*set flintandsteel true
		*goto Free_Stuff_loop
	*if (sleepingroll=false) #Take a sleeping roll.
		You take a sleeping roll from the storerooms.
		*if (showstats)
			*line_break
			(Gained a Sleeping Roll)
		*set sleepingroll true
		*goto Free_Stuff_loop
	#Continue onward.
		You leave the storerooms and armoury as they are, content with the belongings you are currently carrying.
		*goto End_Of_Politics

*label End_Of_Politics
*goto_scene warprep

*comment ---------------------Subroutines------------------------------

*label Check_Army_Stats
*if (army_morale<=0)
	*set army_morale 0
*if (army_size<0)
	*set army_size 0
*if (army_food<0)
	*set army_food 0
*if (army_power<0)
	*set army_power 0
*if (citizen_reputation<0)
	*set citizen_reputation 0
*return
