*comment Copyright 2015 by Mike Walter
*comment The Lost Heir 2:  Forging a Kingdom
*comment Scene #6: luddmarch.txt
*comment 15985 Words - 164 subroutines = 15.8 k
*hide_reuse
*temp dreadhorse_has_horse false
*temp dreadhorse_has_supplies false
*temp dreadhorse_new_horse false
*temp dreadhorse_began false
*if (store_scene="begin_luddmarch")
	*set store_scene "None"
*if (store_scene="luddmarch_buyhorse")
	*goto luddmarch_buyhorse
Your advance scouts report that the winter snows have melted and the roads are clear.  Everything is muddy and wet from the spring thaw, but General Vale tells you that you can't wait.  Time is of the essence.  You must march upon Ludd through the spring and defeat Duke Eddan's forces before proceeding to Tornassa to fight Duchess Selina and take back the capital.

Duke Bandar of the north has no standing army and will be no trouble.  But, if Ludd is not taken, their cavalry will crush you upon the walls of Tornassa.  And if Tornassa is not taken before the winter snows come again, your army won't survive until next spring.  It will be a tight schedule, but if Tornassa is left unchallenged until next year, they will grow faster than you and destroy you wherever you are.
*label Delay_or_Not_loop
*choice
	#Begin the march.
		*goto After_Food_Delay_ns
	#Delay the departure so you can gather more food to replace what was burned by the ${prisoner1_nickname}.
		General Vale bows to your wisdom.  If you run out of food, your soldiers won't make it to Tornassa.  The treasuries are emptied and more food is gathered for your troops.  Soon Brightwater and the surrounding area has been picked clean.
		*if (showstats)
			*line_break
			(Army Delays +1 and Army Food +20)
		*set army_delays +1
		*set army_food +20
		*goto After_Food_Delay
	#Ask General Vale if you have enough food.
		"We have enough to survive," General Vale says with some hesitation in his voice.  "But if the troops feel that they aren't eating to their satisfaction, their morale will be terrible and some will desert.  But if we delay our departure, we might get stuck travelling in the winter which would be even worse.  This is your decision to make."
		*goto Delay_or_Not_loop

*label After_Food_Delay

*label After_Food_Delay_ns
The early spring sky is full of clouds and threatens to rain upon your army.
You
*if (mount_name="None")
	stand
*if (mount_name!="None")
	sit upon ${mount_name}
at the front of the assembled mass of men and woman with your hand in the
*if (cape_of_shadows)
	air and your cape billowing behind you.
*if (cape_of_shadows=false)
	air.
*if (mount_type="mule")
	You can't help but notice that some of the assembled people are laughing at the fact that you are riding a donkey into battle.
*if (prisonchild_inparty)
	${prisonchild_name} looks toward you from where ${prisonchild_heshe} sits in one of the supply wagons.
The flags and pennants flap in the wind as an expectant hush falls over the troops behind you.  You lower your hand and everyone takes a lurching step forward.
*if (holysymbol)
	*if ((god_good) and (good>=55))
		The clouds break for a moment, sending a small ray of sunshine down toward you.  It would seem that ${god_name} is pleased with your actions.
	*if ((god_good=false) and (good<=45))
		The clouds get even darker for a moment and a peal of thunder fills the air.  It would seem that ${god_name} is pleased with your actions.
*if (citizen_reputation>=50)
	The citizens of Brightwater cheer from the windows and sides of the road as your army marches forward.
	*if (showstats)
		*line_break
		(Army Morale +7)
	*set army_morale +7
*if (citizen_reputation<50)
	The sounds of stomping feet fill the air as your army marches forward.
	*if (showstats)
		(Needed 50 Citizen Reputation)

*if (theothea_inparty)
	"It's like the time we met," ${theothea_name} says.  "Marching to Ludd again.  Last time, we were herding sheep.  This time, we're herding people.  We're moving a lot slower this time."
*if (theothea_inparty=false)
	*if (karlkarla_inparty)
		"This reminds me of when you left Elmvale," ${karlkarla_name} says.  "Marching off to Ludd.  That time, you were herding sheep.  This time, you're herding people…and I'm with you.  I have to say, we sure are moving slowly."
	*if (karlkarla_inparty=false)
		"I knew armies moved slowly," ${friend3_name} says.  "But this will take a long time to reach Ludd."

"The ballads and stories always skip this part," Archmage Cumari says from nearby while riding an old grey mare.

"I see why," Lord Tovor grumbles while struggling with his own spirited brown stallion which seems too frisky for the clerk, but probably cost a lot of money.

"By the grace of the Gods and Goddesses, we will have Daria reunited before the snows fall again," Captain ${branbrinn_name} says.

"We must," General Vale adds from where he sits atop his own sturdy warhorse.  "We won't be able to survive a winter siege in the field.  This spring and summer campaign is a gamble, but it's also our only chance of success."

You and your companions are silent as the army continues to march out of Brightwater and toward the
*if (companion_name!="None")
	west as ${companion_name}, your ${companion_type}, ${companion_travels}.
*if (companion_name="None")
	west.
*if (using_legacy)

	The now-familiar, glowing wizard floats along beside you.  "This is the beginning of the march against Ludd?  Good.  I'll have the artifacts ready for you when you arrive."
	
	The wizard vanishes as quickly as ${legacy_heshe} had arrived.
*page_break Marching Army
The first trouble comes that very night when your soldiers begin to cut down trees for their campfires.  The elves are livid!  Even Naistalan cannot get his brethren to calm down.  Many of the elves have never been away from Oneiduin and they find the idea of burning living trees to be utterly evil.
*label TreeTrouble_loop
*choice
	#Instruct your troops to take only deadwood.
		"Your Highness," General Vale says upon hearing your orders.  "There are too many of us.  Winter hasn't let up its grip upon us yet; our soldiers need the fires.  Will you rescind your order?"
		*choice
			#Don't change your mind.  Make the soldiers use only wood which has fallen naturally from the trees.
				The elves are happy with your orders, but your troops are cold.  The General is correct and many cases of frostbite are reported.  After the coldest nights, a few soldiers are missing as they desert your army.				
				*if (showstats)
					*line_break
					(Nature +3, Army Power -3, Army Morale -3 and Army Size -5)
				*set nature +3
				*set army_power -3
				*set army_morale -3
				*set army_size -5
				*goto FirstTrouble_End
			#Change your mind, but ask your soldiers to be mindful of the amount of live trees they cut down.
				*label Unhappy_Elves
				The elves aren't happy, but at least your troops don't lose fingers and toes from frostbite.  Naistalan tries to soothe the soldiers under his command, explaining that humans aren't as hardy as the fey, but you still receive a lot of cold looks from the elves.
				*if (showstats)
					*line_break
					(Army Morale -5)
				*set army_morale -5
				*goto FirstTrouble_End
	#Tell the elves that the troops need the fires and let them continue cutting down the trees.
		*goto Unhappy_Elves
	#Explain to the elves that the Gods gave the world trees for this purpose.
		*if (religion>=40)
			The elves are forced to agree that the soldiers' health must come before the trees', although they still don't like the idea that the trees might be harmed needlessly.  Your troops hear your words and take it upon themselves to cut only what is needed.
			*if (showstats)
				*line_break
				(Religion +3)
			*set religion +3
			*goto FirstTrouble_End
		The elves explain that the Gods made trees to be protected and respected.  They say that the burning of the deities' creations is blasphemous and that all life needs to be treated with respect.
		*if (showstats)
			(Needed 40 Religion)
		*goto TreeTrouble_loop
	#Teach your soldiers how to take the maximum amount of wood from the trees without hurting them.
		*if (nature>=40)
			The elves are happy to help you spread your knowledge to the soldiers.  The fires are still smaller than they would have liked, but many trees are saved and nobody loses any toes or fingers from frostbite.
			*if (showstats)
				(Nature +3 and Army Morale +5)
			*set nature +3
			*set army_morale +5
			*goto FirstTrouble_End
		*else
			You borrow an axe and remove a partially dead limb from a tree, but the elves still moan and complain that you are killing the plants.
			*if (showstats)
				(Needed 40 Nature)
			*goto TreeTrouble_loop
	*if (academy_help>0) #Ask the wizards from the Academy to make fire without trees.
		"It can be done, of course," Archmage Cumari says as their spokesman.  "But the toll on their energy reserves would be immense.  We should save their power for battle and let the soldiers use trees."
		*choice
			#Command the wizards to use their magic.
				The wizards do as you ask.  The campfires of your army are blue, red, purple and green…but they are warm enough that nobody loses any toes or fingers from frostbite.  The elves are happy that the trees are saved, but Archmage Cumari worries continuously that the wizards will be too weak to be effective when the fighting starts.
				*if (history>=70)
					You remind the archmage about the warlocks of Westwood that you read about in an old history text.  In the story, the warlocks were trapped in a lightless cavern for three months by their enemies.  Every day they were forced to cast spells to create food, water and light.  When they were finally rescued, their magic was more powerful than ever before due to the forced practice.  They ended up getting slaughtered by a pack of lava hounds, but your point is still valid.  With a chuckle, the archmage grudgingly agrees that this may be the case.
					*if (showstats)
						*line_break
						(History +3, Archmage Cumari Relationship +3 and Army Morale +5)
					*set history +3
					*set cumari_relationship +3
					*set army_morale +5
					*goto FirstTrouble_End
				*else
					*if (showstats)
						(Needed 70 History)
						*line_break
						(Archmage Cumari Relationship -10 and Army Morale +5)
					*set cumari_relationship -10
					*set army_morale +5
					*goto FirstTrouble_End
			#Let the wizards save their magic.
				The wizards nod sagely at your decision and Archmage Cumari is happy that you listened to him, but the problem of the trees still remains.
				*if (showstats)
					*line_break
					(Archmage Cumari Relationship +2)
				*set cumari_relationship +2
				*goto TreeTrouble_loop

*label FirstTrouble_End
*gosub Check_Army_Stats
*if ((dwarf_help>0) and (orc_help>0))
	
	More trouble comes a few days later when a bloody half-orc and a bloody dwarf are brought before you.  You can see from their black eyes and fat lips that they have been fighting.  A small ring of half-orcs, dwarfs and humans gather to hear how you will deal with their behaviour.
	*temp know_of_puppy false
	*temp know_of_suppersteal false
	*label Dwarf_Orc_Trouble1_loop
	*choice
		#Ask the half-orc what happened.
			"Crazy runt steal supper!" he snarls through his yellow tusks.  "Took meat from fire and ran away!  Dirty stinking thief!"
			*set know_of_suppersteal true
			*goto Dwarf_Orc_Trouble1_loop
		#Ask the dwarf what happened.
			"The murdering green-skin caught a puppy and was roasting it alive!" the dwarf spat angrily.  "Most disgusting thing I ever seen.  Poor little guy was yelping and this lug was just licking his lips."
			*set know_of_puppy true
			*goto Dwarf_Orc_Trouble1_loop
		#Let both soldiers off with a warning.
			The two soldiers grumble and glare at each other as they leave.
			*label Dwarf_Orc_Trouble1_unhappy
			You instruct your commanders to be sure that the half-orc and dwarf camps are on opposite sides of the field from now on, but even with this precaution, you receive nightly reports of troubles between the two groups.
			*if (showstats)
				*line_break
				(Army Morale -3)
			*set army_morale -3
			*goto After_Dwarf_Orc_Trouble1
		#Have both soldiers whipped for their actions.
			The half-orc accepts the punishment without complaint but the dwarf grumbles bitterly.  During the actual lashings, both soldiers stoically endure the whipping with minimal crying out.  You instruct your commanders to be sure that the half-orc and dwarf camps are on opposite sides of the field from now on.  Tales of your decision spread quickly, reducing the number of incidents between the groups.
			*if (showstats)
				*line_break
				(Army Power +3, Citizen Fear +10 and Citizen Reputation -5)
			*set army_power +3
			*set citizen_fear +10
			*set citizen_reputation -5
			*goto After_Dwarf_Orc_Trouble1
		*if (know_of_puppy) #Side with the dwarf and tell the half-orc to not eat any more puppies!
			The half-orc doesn't seem to understand the trouble.  He says that the fresh meat wasn't owned by anyone and was just running around.
			*goto Dwarf_Orc_Trouble1_unhappy
		*if (know_of_suppersteal) #Side with the half-orc and tell the dwarf to pay for the stolen meat.
			The dwarf grumbles and complains, saying that he'll never forget the disgusting sight and sound.  The half-orc is happy with the gold he receives in restitution.
			*goto Dwarf_Orc_Trouble1_unhappy
		*if ((know_of_puppy) and (know_of_suppersteal)) #Try to explain the cultural differences to both sides.
			*if (charm>=40)
				The half-orc doesn't really understand why the dwarf was upset about the fresh meat, but in the end, he agrees to make sure his meals are fully dead before cooking.  The dwarf grumbles something about speaking to his commander about problems in the future instead of dealing with the issue himself.  You instruct your commanders to be sure that the half-orc and dwarf camps are on opposite sides of the field from now on.
				*if (showstats)
					*line_break
					(Charm +2 and Army Morale +5)
				*set charm +2
				*set army_morale +5
				*goto After_Dwarf_Orc_Trouble1
			*else
				Neither side is able to see the other's viewpoint.  The half-orc doesn't understand what's wrong with eating fresh unowned meat and the dwarf is traumatized by the sight of the puppy being burned alive.  In the end, both parties agree to speak to their commanders instead of using their fists to settle future disputes.  You instruct your commanders to be sure that the half-orc and dwarf camps are on opposite sides of the field from now on.
				*if (showstats)
					(Needed 40 Charm)
					*line_break
					(Army Morale -2)
				*set army_morale -2
				*goto After_Dwarf_Orc_Trouble1
*else
	*goto After_Dwarf_Orc_Trouble1

*label After_Dwarf_Orc_Trouble1
*gosub Check_Army_Stats
*if (halfling_help>0)
	
	The halflings prove to be a bigger problem than you had anticipated.  At first, you are afraid that their light fingers will cause troubles, but they respect other people's belongings.  (Either that, or they never get caught.)  Instead, it is their enormous appetites that cause trouble.  Your food stores are already low, due to the ${prisoner1_nickname} and ${prisoner1_hisher} strike force, but now the halflings are eating double the amount of food as the people twice their size!
	*label Halfling_Trouble1_loop
	*choice
		#Instruct the army cooks to feed the halflings a single share of food, the same as everyone else.
			The small-folk wail and cry out at their perceived injustices, but none of them die.  In fact, some of them even lose a little weight from the full day's marching, but not very much.
			*if (showstats)
				*line_break
				(Army Morale -5)
			*set army_morale -5
			*goto After_Halfling_Trouble1
		#Instruct the army cooks to continue to feed the halflings double shares.
			The halflings waddle along with the rest of the army, content and happy.  The ones mounted on dogs continue to range outward, acting as an effective advance scout for your army.  The rest of the army doesn't care for the special treatment, but since travelling with demi-humans is new to everyone, they understand the magical need for the small-folk to eat more than them.
			*if (showstats)
				*line_break
				(Army Food -5)
			*set army_food -5
			*goto After_Halfling_Trouble1
		#Instruct the army cooks to feed the halflings half a share of food, due to their small size.
			The small-folk curse loudly, which is something you have never heard of before.  They also faint during the long day's marching and have trouble keeping up.  They try to explain to you that they need twice the amount of food as a full-grown person and that if you continue to starve them, they will have to leave.
			*choice
				#Change your mind.
					*goto Halfling_Trouble1_loop
				#Continue to feed them half the rations of a full-grown person.
					True to their word, one morning you wake up and find the halfling area of the camp empty.  When you ask the night sentries when they left, they are amazed to hear that the halflings are gone.  Nobody heard them leave.  At least you have some extra food now that they don't need to be fed at all.
					*set halfling_help 0
					*if (showstats)
						*line_break
						(Army Food +5, Army Size -5 and Army Power -3)
					*set army_food +5
					*set army_size -5
					*set army_power -3
					*goto After_Halfling_Trouble1
		#Consider how much a halfling should eat.
			*if (history>=40)
				You know your history and you understand that halflings are hungry little fellows.  Although they would like to eat as much as they like, you also know that they can get away with a regular ration.  The halflings grudgingly agree that this is true and stop asking for more food.
				*if (showstats)
					*line_break
					(History +2)
				*set history +2
				*goto After_Halfling_Trouble1
			*if (nature>=40)
				Halflings are animals, the same as everyone else.  And, they are small animals.  There is no reason that they shouldn't be able to live on a single ration, the same as everyone else.  The halflings grudgingly agree that this is true and stop asking for more food.
				*if (showstats)
					*line_break
					(Nature +2)
				*set nature +2
				*goto After_Halfling_Trouble1
			You don't know how much a halfling should eat.  Sure, they are small, but they are also magical beings.  Perhaps they do need more food?  Or perhaps they could get away with less?  You simply don't know.
			*if (showstats)
				(Needed 40 History or 40 Nature)
			*goto Halfling_Trouble1_loop
*else
	*goto After_Halfling_Trouble1

*label After_Halfling_Trouble1
*gosub Check_Army_Stats
*if (gnome_help>0)
	
	The gnomes brought their own set of problems too.  Rumours of preferential treatment began to surface across the camp, saying that the gnomes were travelling in luxury.  Reports said that they had large beds, overstuffed chairs, rugs, golden candlesticks and so on.  It was known that gnomes were good with money, so the second wave of rumours claimed that the gnomes were paying you to cart along their finery so they could camp in style.
	*choice
		#Ignore the rumours, since you know that you are doing no such thing.
			The soldiers continue to complain, but since they consider it your right to treat the gnomes as you please, they don't do very much about it.
			*if (showstats)
				*line_break
				(Army Morale -3)
			*set army_morale -3
			*goto After_Gnome_Trouble1
		#Inspect the gnome camp.
			*if (perception>=40)
				As you walk toward their camp, you suddenly see a large fanciful tent in the distance!  It looks like a circus tent and is three times bigger than your own command tent.  Strangely, when you arrive, it is nowhere to be seen.  One of the gnomes smiles nervously as you inspect his tent and then admits the truth.
				*label Gnomes_Admit_Truth
				
				"I am sorry, $!{princeprincess} ${name}!" he says.  "We've been casting illusions.  They help us to feel better about the difficult march, but they are visual only.  My apologies."
				*choice
					#Tell the gnomes to stop it, since it is making the rest of the army feel bad.
						The gnomes apologize again and soon the rumours stop.
						*if (showstats)
							*line_break
							(Magic +3 and Army Morale +3)
						*set magic +3
						*set army_morale +3
						*goto After_Gnome_Trouble1
					#Tell the gnomes to show the rest of the army what they have been doing.
						The gnomes are hesitant at first, but when they show the other soldiers that their comfortable looking beds and big thrones are just magical mirages, the soldiers stop complaining.  Before long, they are laughing as the gnomes entertain them with grand illusions of fancy clothing, golden thrones and expensive looking surroundings.
						*if (showstats)
							*line_break
							(Magic +3 and Army Morale +5)
						*set magic +3
						*set army_morale +5
						*goto After_Gnome_Trouble1
			*if (magic>=50)
				As you walk toward the camp, you sense magic being used.  It isn't difficult to guess what the gnomes have been doing and when you corner one of them, he quickly spills the truth.
				*goto Gnomes_Admit_Truth
			You walk through the gnome camp, but it looks the same as you would expect.  They have nothing different from anyone else.  Shaking your head, you return to your own tent.
			*if (showstats)
				(Needed 40 Perception or 50 Magic)
				*line_break
				(Army Morale -3)
			*set army_morale -3
			*goto After_Gnome_Trouble1
*else
	*goto After_Gnome_Trouble1

*label After_Gnome_Trouble1
*gosub Check_Army_Stats

During the long march, the food stores are continuously used.
*set food_needed 15
*gosub Army_Use_Food
*goto First_Food_Shortage_food

*label First_Food_Shortage_food

"The army budget should have been enough to pay for this march," Lord Tovor
*if ((army_budget="increase") or (army_budget="same"))
	exclaims.
*if (army_budget="decrease")
	exclaims, despite the fact that the war spending budget had been cut.
"It's all Duchess Selina's and that damn ${prisoner1_nickname}'s fault!"

"We'll need to start appropriating food from the villages and farms we pass through," General Vale says.
*choice
	#Agree with the general and give the command for your army to take what is needed.
		Lord Tovor clearly doesn't like the idea, but he doesn't say anything.  Your commanders pass on the orders.  You can see your troops searching farmhouses and barns as they move along.  A supply line from Brightwater to the army is created and your food stores refill slowly as you continue to march toward Ludd leaving a wake of angry citizens behind you.
		*if (showstats)
			*line_break
			(Lord Tovor Relationship -10, Army Food +20, Citizen Reputation -20 and Citizen Fear +10)
		*set tovor_relationship -10
		*set army_food +20
		*set citizen_reputation -20
		*set citizen_fear +10
		*set taking_food true
		*goto After_First_Food_Shortage
	#Give the command to take the food, but carefully document every appropriation.
		Lord Tovor clearly doesn't like the idea, but he doesn't say anything.  Your commanders pass on the orders.  You can see your troops searching farmhouses and barns as they move along.  They ransack the farmhouses and leave behind pieces of paper saying that you will repay them at some future date.  A supply line from Brightwater to the army is created and your food stores refill slowly as you continue to march toward Ludd leaving a wake of angry citizens behind you.  Legal documents don't feed hungry children.
		*if (showstats)
			*line_break
			(Lord Tovor Relationship -5, Army Food +10 and Citizen Reputation -10)
		*set tovor_relationship -5
		*set army_food +10
		*set citizen_reputation -10
		*set taking_food true
		*goto After_First_Food_Shortage
	#Tell the general to not take any food without paying for it.
		*if (army_food=0)
			General Vale is extremely upset at this news, but he salutes you and returns to his tasks.  The food stores are empty.  If something doesn't change soon, you won't have an army by the time you reach your enemies.
			*if (showstats)
				*line_break
				(General Vale Relationship -15)
			*set vale_relationship -15
			*goto After_First_Food_Shortage
		*if (army_food<30)
			General Vale is extremely upset at this news, but he salutes you and returns to his tasks.  The food stores are dangerously low.  If something doesn't change soon, you won't have an army by the time you reach your enemies.
			*if (showstats)
				*line_break
				(General Vale Relationship -10)
			*set vale_relationship -10
			*goto After_First_Food_Shortage
		The general salutes you and returns to his tasks.  Although the food stores are low, you have a little left.  Lord Tovor is happy with your decision to not rob the citizens of their food.
		*if (showstats)
			*line_break
			(Lord Tovor Relationship +5)
		*set tovor_relationship +5
		*set taking_food false
		*goto After_First_Food_Shortage

*label After_First_Food_Shortage
*gosub Check_Army_Stats

One of the first larger towns you come to is Opal Cove.
*if (knight_went_to_tourney)
	It doesn't look very different from the last time you were here when you participated in the knight's tournament
	*if (class_knight=0)
		and lost.
	*if (class_knight>0)
		and won your knighthood.
The town's true claim to fame is the infamous Opal Cove Weapon Masters.
*if (sunosuna_firsttime=false)
	You had the good fortune of meeting one of their members in Elmvale named ${sunosuna_name}.

"If we can recruit the Weapon Masters, they'll be a valuable addition to our army," General Vale says.

"It seems unlikely that they would join," Lord Tovor says.  "We have no money to pay
*if (army_food=0)
	them and no food for them to eat."
*if (army_food>0)
	them."

*temp took_weaponmasters_food false
"Very true," General Vale agrees.  "They are mercenaries and won't work for
*if (taking_food)
	free.  At least they'll have some food stores for our army to take."
*if (taking_food=false)
	free."
*choice
	*if (taking_food) #Continue to let the army take the food it needs and don't bother speaking to the Weapon Masters.
		The Weapon Masters complain as much as everyone else, but in the end, your army gets its food.  Although they are skilled warriors, you outnumber them many times over.  Your food stores fill up even more as you pass through the town.
		*if (showstats)
			*line_break
			(Army Food +10 and Citizen Reputation -10)
		*set army_food +10
		*set citizen_reputation -10
		*goto After_Opal_Cove
	*if (taking_food) #Don't take the food from the Weapon Masters and speak to them.
		*goto Speak_To_WeaponMasters_ns
	*if (taking_food) #Take the food and speak to the Weapon Masters.
		*set took_weaponmasters_food true
		The Weapon Masters can hardly believe your audacity as you take their food and then request an audience to speak to them about joining you.
		*if (showstats)
			*line_break
			(Army Food +10 and Citizen Reputation -10)
		*set army_food +10
		*set citizen_reputation -10
		*label Speak_To_WeaponMasters
		*gosub Check_Army_Stats
		
		*label Speak_To_WeaponMasters_ns
		"Welcome to Opal Cove, $!{princeprincess} ${name}," a short fat man from the Weapon Masters says.
		
		Although he has many layers of fat, you can tell by the way he walks that he also has many layers of muscle under the fat.  He has an economy of movement which shows just how dangerous he is.
		
		"Let me save you some time," he says.  "We aren't going to join you for
		*if (army_food<10)
			free and even if we were inclined to work for nothing, you don't have the food to keep us alive.
			*label Sorry_No_WeaponMasters
			I'm sorry, but we won't be joining you."
			*if (showstats)
				(Needed 10 Army Food, 40 Army Morale and 40 Citizen Reputation)
			
			No matter what you say or offer, nothing changes the man's mind.  With no other options, you continue your march.
			*goto After_Opal_Cove
		*if (army_morale<40)
			free and even if we were inclined to work for nothing, your soldiers are sad and miserable.
			*goto Sorry_No_WeaponMasters
		*if (citizen_reputation<40)
			free and even if we were inclined to work for nothing, quite frankly, we don't like you very much.
			*goto Sorry_No_WeaponMasters
		free."
		*label Weapon_Master_loop
		*choice
			*if (sunosuna_firsttime=false) #Ask the Weapon Master about ${sunosuna_name}.
				*if ((sunosuna_talk=7) or (sunosuna_talk=11))
					"As a matter of fact, I have," he says with a smile.  "$!{sunosuna_heshe} told me what you did for ${sunosuna_himher}.  Okay…you have a deal.  We will join you now and you can pay us after you have regained your throne."
					*goto Got_WeaponMasters
				*else
					"I haven't seen ${sunosuna_himher} in a long time," he says with a shrug.
					*goto Weapon_Master_loop
			*selectable_if (gold>=300) #Say, "I have 300 gold and there will be more after I have reclaimed my throne." (Needs 300 Gold)
				"I won't mince words," the fat man says.  "We fight for coin.  But, every fight is a gamble, and I like to think that this is a good 
				*if (took_weaponmasters_food)
					investment, except that you already took our food without payment.  Let's make that 400 gold now and we'll negotiate the rest once you have your throne.  Do we have a deal?"
					*choice
						*selectable_if (gold>=400) #Pay the man 400 gold.  (Needs 400 Gold)
							You pay the man the gold he requests.
							*if (showstats)
								*line_break
								(Gold -400)
							*set gold -400
							*label Got_WeaponMasters
							
							The few dozen men and women who join you are more impressive than their fat leader.  They each wear dozens of weapons and are deadly in the use of all of them.  The mercenaries add their experience and might to your army.
							*if (showstats)
								*line_break
								(Army Power +10 and Army Size +3)
							*set army_power +10
							*set army_size +3
							*goto After_Opal_Cove
						#Refuse to pay the man.
							The man doesn't budge from his price.  With no other options, you continue your march out of Opal Cove.
							*goto After_Opal_Cove
				*else
					investment.  You have a deal."
					*if (showstats)
						*line_break
						(Gold -300)
					*set gold -300
					*goto Got_WeaponMasters
			#Leave the meeting without the Weapon Masters.
				With no other options, you continue your march out of Opal Cove.
				*goto After_Opal_Cove
	*if (taking_food=false) #Speak to the Weapon Masters.
		*goto Speak_To_WeaponMasters_ns
	#March through Opal Cove without speaking to the Weapon Masters.
		You leave the Weapon Masters of Opal Cove alone as you pass through the town.
		*goto After_Opal_Cove

*label After_Opal_Cove
*gosub Check_Army_Stats

You are on the outskirts of Opal Cove and camping for the night when a dirty beggar slips between your soldiers and stands in front of you.
*if (religion<40)
	*if (showstats)
		(Needed 40 Religion)
	*choice
		*selectable_if (gold>=10) #Give the man some money.  (Needs 10 Gold)
			You give the man a few coins and he leaves you be.
			*if (showstats)
				*line_break
				(Gold -10 and Good +3)
			*set gold -10
			*set good +3
			*goto After_Dreadhorse
		#Wait for your soldiers to clear the man away.
			Your soldiers are quick to react to the security breach and drag the man away.
			*goto After_Dreadhorse
*else
	You see him make a secret sign of shadows with his fingers which you recognize as a calling to those who follow the evil Gods and Goddesses of the world.
	*if (showstats)
		*line_break
		(Religion +2)
	*set religion +2
	*goto Recognize_Sign
	
*label Recognize_Sign

Your soldiers grab him roughly and begin to drag him out of the way.  Not only is he a security breach, but they also find the idea of a dirty beggar approaching their ${princeprincess} to be distasteful.
*choice
	*selectable_if (gold>=10) #Ignore the sign, give the man some money and tell him to be on his way.  (Needs 10 Gold)
		You give the man a few coins and he nods a thanks to you.  The soldiers release him and he scurries out of your way.
		*if (showstats)
			*line_break
			(Gold -10 and Good +3)
		*set gold -10
		*set good +3
		*goto After_Dreadhorse
	#Tell your soldiers to put the man in irons.
		The soldiers nod as they take the man away, kicking him as they go.  You visit him later that night to see why he gave you the secret sign.
		*goto Dreadhorse_1
	#Tell your soldiers to give the man some food and a place to rest for the night.
		The soldiers are surprised at your actions, but they do as you request.  They give him room in one of the tents and hand him a warm meal.  You visit him later that night to see why he gave you the secret sign.
		*if (showstats)
			*line_break
			(Citizen Reputation +3)
		*set citizen_reputation +3
		*goto Dreadhorse_1
	#Ignore the sign and allow your soldiers to push the man away.
		*if ((holysymbol) and (god_good=false))
			You don't know why the man would show you the secret sign in full public.  He was risking your secrets by doing such a thing.  You watch your soldiers drag him safely away and never see him again.
			*goto After_Dreadhorse
		Your soldiers do their duty and drag the man away.
		*goto After_Dreadhorse

*label Dreadhorse_1

"I have something you may want," the dirty man says smugly.

He takes out a large leather bound book from inside his ragged clothes.  You are quite sure that the leather isn't from a wild animal, but instead, made from human skin.

"250 gold and not a coin less."
*choice
	*selectable_if (gold>=250) #You pay the man.  (Needs 250 Gold)
		The man takes the gold and hands you the book.  He then slips away into the night as you look down at what you have purchased.
		*if (showstats)
			*line_break
			(Gold -250 and Gained the Book of the Dead)
		*set gold -250
		*set book_of_the_dead true
		*goto Dreadhorse_2
	*if (vampire) #Feed upon the man.
		The man raises his hands in futility as you rush forward and sink your fangs into his neck.  You drink the blood until you are full and then release him.
		*goto Dreadhorse_DeadMan
	#Kill the foolish man and take the book.
		*label Dreadhorse_DeadMan
		The body of the idiot lays on the ground still bleeding as you take the book from him.  You will have to dispose of the corpse before morning, but you have lots of time.
		*if ((holysymbol) and (god_good=false))
			You know that ${god_name} will not mind.  When followers are weak and foolish enough to be murdered so easily, your dark ${god_goddess} encourages their disposal.
		*if (showstats)
			*line_break
			(Evil +15 and Gained the Book of the Dead)
		*set good -15
		*set book_of_the_dead true
		*goto Dreadhorse_2
	*selectable_if (gold>=100) #Threaten to kill the man unless he lowers the price.  (Needs 100 Gold)
		*label Threaten_For_Deal
		The man complains but eventually accepts the deal.  He takes the gold and hands you the book.  While you look at what you have purchased, he slips away into the night.
		*if (showstats)
			*line_break
			(Evil +5, Gold -100 and Gained the Book of the Dead)
		*set good -5
		*set gold -100
		*set book_of_the_dead true
		*goto Dreadhorse_2
	*selectable_if (gold>=100) #Threaten to lock the man in a dungeon, unless he lowers the price.  (Needs 100 Gold)
		*goto Threaten_For_Deal
	#Tell the man you aren't interested and leave him.
		You turn your back on the crazy man with his expensive book.  In the morning, the soldiers send him on his way and you never see him again.
		*goto After_Dreadhorse
	#Summon your soldiers and have the man arrested for carrying what appears to be an evil book.
		Your soldiers aren't far away while you are talking to the man.  Archmage Cumari shows up shortly after you lay your charges.
		
		"Yes, Your Highness, this is a foul book," he says.  "It's necromancy, all right."
		
		Your soldiers take the man back to Opal Cove and the book is destroyed.  You see many dark shadows rise from the evil tome as it is put to the flames.
		*if (showstats)
			*line_break
			(Good +10, Archmage Cumari Relationship +5 and Religion +5)
		*set good +10
		*set cumari_relationship +5
		*set religion +5
		*goto After_Dreadhorse

*label Dreadhorse_2

The book is clearly evil and more than likely full of necromancy.  You know that it would also be very valuable, in the right hands.
*choice
	#Sell the book to a suitable buyer.
		*goto Dreadhorse_SellBook
	#Destroy the evil book.
		*label Destroy_Book
		The moment you lay a flame to the book it seems to scream in agony.  You aren't sure where the sounds come from, but you feel great misery and see dark shadows flowing out of the evil tome.  When the flames finally consume the last of the book, you suddenly feel a great peace upon you.
		*if (showstats)
			*line_break
		(Religion +5, Good +20 and Lost the Book of the Dead)
		*set religion +5
		*set good +20
		*set book_of_the_dead false
		*goto After_Dreadhorse
	#Attempt to use the evil book.
		*goto Use_Evil_Book
*label Use_Evil_Book
*if (((class_priest>0) and (god_good)) and (god_heshe!="It"))
	The moment you touch the vile book, your holy symbol bursts into flames and crumbles to dust on your chest!  ${god_name}'s divine disgust at your behaviour overwhelms you for a moment.  You realize that you have lost all favour with ${god_himher}.
	*if (showstats)
		*line_break
		(Lost Holy Symbol and Lost all Levels of $!{priestpriestess} and Cleric)
	*set holysymbol false
	*set class_priest 0
	*set class_cleric 0
	*set exgoodpriest true
	
*if (arcana<50)
	The book is incomprehensible to you as it uses some ancient language that you've never seen.
	*if (showstats)
		(Needed 50 Arcana)
	*label KeepOrSell_choice
	*choice
		#Keep the book.
			You put the old book into your backpack.
			*goto After_Dreadhorse
		#Sell the book.
			*goto Dreadhorse_SellBook
		#Destroy the book.
			*goto Destroy_Book
The book is written in an ancient language, which you know, and tells of a very evil rite, clearly necromantic.  You have no idea where the smelly man could have gotten it from.
*if (good>30)
	The things which must be done for the magic to work turn your stomach.  In the end, you realize that you can't go through with it.
	*if (showstats)
		(Needed 70 Evil)
	*goto KeepOrSell_choice
You are certain that it's authentic.  Your only question is whether you have the power or inclination to try it.
*choice
	#Follow the instructions and see what happens.
		Physically, the rite is very simple.  All you will need is 13 black candles, a shovel, a pound of salt and a strong horse.
		*label Dreadhorse_Equipping_loop
		*choice
			*selectable_if (gold>=45) #Purchase the candles, shovel and salt from the quartermaster.  (Needs 45 Gold)
				The quartermaster doesn't question you as you take away what you paid for.  He likely assumes that the candles are dark so that they can be set up as a secret signal somewhere…unseen until they are lit.  Who knows what he thinks about the salt and shovel.
				*if (showstats)
					(Gained Rite Ingredients and Lost 45 Gold)
				*set gold -45
				*set dreadhorse_has_supplies true
				*goto Dreadhorse_Equipping_loop
			*if (((mount_type="horse") or (mount_type="warhorse")) and ((dreadhorse_has_horse=false) and (mount_name!="None"))) #Get ${mount_name} from the stable.
				The army stablemaster doesn't question your need for your mount as you lead ${mount_name} away.
				*set dreadhorse_has_horse true
				*set dreadhorse_new_horse false
				*goto Dreadhorse_Equipping_loop
			*if (dreadhorse_has_horse=false)
				*selectable_if (gold>=75) #Buy a horse from the army stablemaster for your rite.  (Needs 75 Gold)
					*label Buy_New_Horse_Ritual
					The stablemaster isn't happy to be awoken in the middle of the night, so he doesn't give you many options.  You purchase the most suitable horse he will sell at the moment and lead it away.
					*if (showstats)
						*line_break
						(Gold -75)
					*set gold -75
					*set dreadhorse_has_horse true
					*set dreadhorse_new_horse true
					*if (dreadhorse_began)
						*goto LeadingHorse
					*goto Dreadhorse_Equipping_loop
			*if ((dreadhorse_has_horse) and (dreadhorse_has_supplies))
				*allow_reuse #Begin the rite.
					*label LeadingHorse
					You lead
					*if (dreadhorse_new_horse)
						the horse
					*if (dreadhorse_new_horse=false)
						${mount_name}
					out of the camp to a quiet area away from prying eyes.  The next step is to kill the horse and bury it.
					*choice
						*if (dreadhorse_new_horse) #Kill the horse you purchased and bury it.
							*goto Dreadhorse_3
						*if (dreadhorse_new_horse=false) #Kill ${mount_name} and bury ${mount_himher}.
							*goto Dreadhorse_3
						*if (dreadhorse_new_horse=false)
							*selectable_if (gold>=75) #Go back to the army stablemaster and buy a different horse to kill. (Needs 75 Gold)
								*set dreadhorse_began true
								*goto Buy_New_Horse_Ritual
						#Change your mind about the ritual.
							*label ChangedMind_Stop
							*if (dreadhorse_new_horse)
								The stablemaster is very grumpy when you return the horse to him, but he takes the animal and gives you back your money.
								*if (showstats)
									*line_break
									(Gold +75)
								*set gold +75
								*goto KeepOrSell_choice
							You decide to not go through with the ritual.
							*goto KeepOrSell_choice
			#Change your mind and don't do the rite.
				You decide to not go through with the ritual.
				*goto ChangedMind_Stop
	#Don't follow the rite and sell the book when you get a chance.
		*label Dreadhorse_SellBook
		You eventually find a woman who deals in odd things.  She doesn't have anything that you are interested in buying, but she is willing to purchase the book.  You sell it to her, knowing that it will likely fall into evil hands, but content with the profit it brings you.
		*if (showstats)
			*line_break
			(Evil +5, Gold +200 and Lost the Book of the Dead)
		*set good -5
		*set gold +200
		*set book_of_the_dead false
		*goto After_Dreadhorse
	#Don't follow the rite, but keep the book.
		You store the book in your backpack.
		*goto After_Dreadhorse

*label Dreadhorse_3
There is an enormous amount of blood, which mixes with the dirt from the grave that you dig for the dead beast.  You cast the shovel aside and place the candles on the fresh mound as the book instructs.  You begin to light the candles, feeling a drain on your being with each new flame.
*if (magic<50)
	You wake up in the morning realizing that you passed out before all 13 candles were lit.
	*if (showstats)
		(Needed 50 Magic)
	*label Failed_Rite_Over
	*if (showstats)
		*line_break
		(Evil +10 and Arcana +5)
	*set good -10
	*set arcana +5
	*if (dreadhorse_new_horse)
		*comment Used a new horse
		*if (mount_name="None")
			*comment Used new horse and had no horse.
			*goto Offer_To_Buy_New_Horse
		*else
			*comment Used new horse and had a backup horse.
			*goto KeepOrSell_choice
	*else
		*comment Used own horse and it's dead.
		*set mount_level 0
		*set mount_type "None"
		*set mount_name "None"
		*set mount_desc "None"
		*set mount_value 0
		*set mount_heshe "None"
		*set mount_himher "None"
		*set mount_hisher "None"
		*label Offer_To_Buy_New_Horse
		*choice
			#Purchase a new mount to replace the one you lost.
				You speak to the stablemaster.
				*set store_scene "luddmarch_buyhorse"
				*goto_scene store
				*label luddmarch_buyhorse
				The stablemaster likely assumes that you sold your old mount somewhere, but is happy to have supplied you with a new one.
				*goto KeepOrSell_choice
			#Continue the march on foot.
				The stablemaster likely assumes that you sold your mount somewhere, since you show up at muster the next morning on foot.
				*goto KeepOrSell_choice
*comment Magic>=50
By the time the last flame is lit, you feel exhausted.  The next page tells you to cut your own wrists and splash the candles with your blood and the salt.
*choice
	#Do as the book asks.
		The blood and salt seem to boil in the dirt over the grave.  You continue to read from the text.  You suddenly feel exhausted as the spell takes something from you.
		*if (showstats)
			*line_break
			(Strength -3 and Endurance -3)
		*set strength -3
		*set endurance -3
		*goto Dreadhorse5
	#Stop the rite, knowing that such an act of blood magic will weaken you permanently as it draws from your own life force.
		You stop the rite and the candles go out by themselves.
		*goto Failed_Rite_Over

*label Dreadhorse5

*rand coinflip 1 2
*comment for future horse gender
A deathly silence fills the air as you read the last line of the rite.  This peace is broken as noises come from the blood covered grave.  You see it roiling and suddenly a hoof breaks free.  You watch in awe as your new Dreadhorse claws itself from its grave.  It looks to have been dead for a month!  Its eyes are sunken in and you see insects and worms crawling through its rotted flesh.  Despite this, it is bigger and stronger than any horse you have ever seen before!  It gives off waves of revulsion and terror, but you can tell that your undead mount will never tire and never shy from battle.  Your stablemaster will think that the beast is badly diseased, but upon your command, he will find a pen for it when you aren't riding it.
*if (dreadhorse_new_horse)
	*if (mount_name!="None")
		You know that you won't be able to keep both mounts.  You will have to get rid of ${mount_name}, if you wish to keep the Dreadhorse.
		*choice
			*if (mount_type="forest worm") #Release ${mount_name} into the wild and keep the Dreadhorse.
				${mount_name} does as you ask and leaves you.  You smirk at what the stablemaster is going to think.  He didn't like tending ${mount_name}, since he was afraid of the enormous worm.  He'll wish he had the natural beast back once he is forced to look after the Dreadhorse.
				*goto Get_Dreadhorse
			*if (((mount_type="horse") or (mount_type="warhorse")) or (mount_type="mule")) #Sell ${mount_name} and keep the Dreadhorse.
				The stablemaster takes ${mount_name} off your hands and gives you ${mount_value} gold, a fair trade.
				*if (showstats)
					*line_break
					(Gold +${mount_value})
				*set gold +mount_value
				*goto Get_Dreadhorse
			#Let the Dreadhorse return to the grave and keep ${mount_name} instead.
				The moment you make the decision, the Dreadhorse falls over as it loses its false life.  It decomposes even further until you can see bone through the rotted flesh.  It doesn't even remotely resemble the horse you had purchased only a few hours before.  You return to your tent, having wasted the entire night.
				*goto After_Dreadhorse
	*else
		*comment Has no other mount.
		*goto Get_Dreadhorse_ns
*else
	*comment Animated current mount.
	*goto Get_Dreadhorse_ns

*label Get_Dreadhorse

*label Get_Dreadhorse_ns
*set mount_level 6
*achieve sweetride
*set mount_type "Dreadhorse"
*set mount_desc "an undead"
*set mount_value 0
*if (dreadhorse_new_horse)
	*if (coinflip=1)					
		*set mount_heshe "he"
		*set mount_himher "him"
		*set mount_hisher "his"
	*if (coinflip=2)					
		*set mount_heshe "she"
		*set mount_himher "her"
		*set mount_hisher "her"
	*label New_Name_Dreadhorse
	What do you name your new evil undead mount?
	*choice
		#Death.
			*set mount_name "Death"
			*goto Dreadhorse6
		#Pestilence.
			*set mount_name "Pestilence"
			*goto Dreadhorse6
		#Midnight.
			*set mount_name "Midnight"
			*goto Dreadhorse6
		#Shadow.
			*set mount_name "Shadow"
			*goto Dreadhorse6
		#Something else.
			*label Pick_Dreadhorse_Name
			*input_text mount_name
			*if (mount_name="None")
				That is a terrible name.  Pick a new name for your undead mount.
				*goto Pick_Dreadhorse_Name
			*goto Dreadhorse6
*else
	You wonder if ${mount_name} is a suitable name for your new mount.
	*choice
		#Keep calling your Dreadhorse ${mount_name}.
			*goto Dreadhorse6
		#Give your undead horse a new name for its new unlife.
			*goto New_Name_Dreadhorse

*label Dreadhorse6
You take ${mount_name} to the stablemaster and watch as the horrified man leads the undead animal to its own pen.  The other animals are clearly terrified of your mount and the stablemaster voices his concern that the disease will spread.  In the end, he finds a pen for your mount that is safely away from the other animals.  You have unleashed a great evil into the world and it will serve you faithfully, for as long as you are worthy.
*if (showstats)
	*line_break
	(Evil +25 and Citizen Fear +25)
*set good -25
*set citizen_fear +25
*goto After_Dreadhorse

*label After_Dreadhorse

"What are the chances that we just happen to have a washout this spring when we are in such a hurry?" Lord Tovor says as the army comes to a halt on the banks of the Falcon River.

The river is wide, fast flowing and dangerous as the winter melt makes it surge higher than normal.  The bridge that the army planned to use is gone.  Only rubble remains on either side.

"This was no coincidence," General Vale says with a frown.  "Duchess Selina knows that time is our enemy and her ally.  She had this bridge destroyed and probably destroyed all of the others as well.  Our only option is to travel north to where the river is wider and shallower.  We will be able to ford there."
*label Crossing_loop
*choice
	#Lead the army north to the shallow area and accept the delays this will bring.
		The army marches north alongside the fast-moving waters.  The crossing isn't pleasant as everyone gets wet in the cold river.  The camp is silent and subdued once everyone has finally crossed as the soldiers dry out their soggy clothing and tents.
		*if (showstats)
			*line_break
			(Army Delays +2 and Army Morale -3)
		*set army_delays +2
		*set army_morale -3
		*goto After_Crossing
	*if (class_druid>=2) #Use your druidic power to alter the landscape.
		You stand before the raging river and call upon the power of nature itself.  There is a low rumbling and suddenly the river widens under your command.  Rocks grow and break through the surface of the river and the water level itself goes down as the banks recede.  When you are done, the river is easily crossable by a natural landbridge.  Your army cheers as they cross without delay.
		*if (showstats)
			*line_break
			(Nature +3, Magic +3 and Army Morale +5)
		*set nature +3
		*set magic +3
		*set army_morale +5
		*goto After_Crossing
	*if (gnome_help=2) #Consult with the gnome engineers.
		"Sure we can build a bridge," they say as they study the rubble from where the bridge was before.  "It doesn't need to be permanent, so we can make it faster than it would take to travel north and it will be strong enough for the troops to cross."
		
		The soldiers help by cutting down large trees for the gnomes to use.  The elves frown at this, but even they can't deny that it is necessary.  You watch as the gnome engineers instruct the troops on where to put the trees and stones from the rubble.  You also notice that they use a little of their illusion magic when they are finished to make the bridge appear more solid than it really is.  General Vale wastes no time in getting the army to cross the makeshift bridge.  The gnome engineers are congratulated by the rest of the soldiers for their ingenuity once everyone has crossed.
		*if (showstats)
			*line_break
			(Army Delays +1 and Army Morale +3)
		*set army_delays +1
		*set army_morale +3
		*goto After_Crossing
	*if ((companion_type="water elemental") and (companion_type!="None")) #Listen to what ${companion_name}, your water elemental, has to say.
		Your companion doesn't speak in actual words, but you can divine what ${companion_heshe} is trying to tell you.  ${companion_name}'s affinity with water makes ${companion_himher} more powerful than ever while near the raging torrent.  You watch as ${companion_heshe} enters the river and merges with it in a unique way.  Suddenly, the waters arc overhead, creating a tunnel over the muddy river floor.  General Vale doesn't need to be told to hurry the army through.  It is unnerving to travel under the waters, but the army crosses quickly without delay.  Once on the other side, they applaud you and your familiar.
		*if (showstats)
			*line_break
			(Army Morale +5)
		*set army_morale +5
		*goto After_Crossing
	*if (soulburner_knowledge) #Listen to what ${jacejess_name} has to say.
		"I have a solution," the Soulburner says quietly.  "But it's not nice.  Remember that book we found in the Academy?  I think I can get us across…but it would mean the death of a few soldiers.  Should I do it?"
		*choice
			#Tell ${jacejess_name} to do what is necessary.
				${jacejess_name} raises ${jacejess_hisher} face toward the water.  $!{jacejess_hisher} eyes glow bright white and suddenly shoot forth.  A white shimmering bridge solidifies across the raging torrent.  General Vale wastes no time in getting the army to move.  It takes several hours to cross, but the delay is minimal compared to travelling north.  You notice what nobody else sees as three soldiers gasp in agony.  Black veins of death cross their faces and arms as ${jacejess_name} drains them fully of their life's essence.  They fall into the roaring water and wash away.  The army mourns their passing, but believe it to be an accident.
				*if (showstats)
					*line_break
					(Evil +10)
				*set good -10
				*goto After_Crossing
			#Tell ${jacejess_himher} that you will find another way.
				You notice the relief on ${jacejess_hisher} face.
				*if (showstats)
					*line_break
					(${jacejess_name} Relationship +5)
				*set jacejess_relationship +5
				*goto Crossing_loop
	#Study the maps for a closer crossing.
		*if (geography>=75)
			The maps don't show it, but you have heard that the river does a sharp bend to the south and a scattering of very large rocks make a natural landbridge for those who know about it.  Selina will be disappointed that all of her hard work goes to waste as you lead your army across the stones with hardly any delay.
			*if (showstats)
				*line_break
				(Geography +3)
			*set geography +3
			*goto After_Crossing
		*else
			The maps don't show anything closer.
			*if (showstats)
				(Needed 75 Geography)
			*goto Crossing_loop
	#Force the army to cross the raging river where you are.
		You get many horrified looks at your suggestion.
		
		"With all due respect, Your Highness, this is not a good idea," General Vale says.  "We will lose many soldiers in the crossing. Are you sure that this is what you wish us to do?"
		*choice
			#Say, "Yes, we will cross here."
				The troops are outraged at your decision, but with their commanders preventing anyone from deserting, they do as you say.  Several people drown during the crossing and many supplies are washed away by the fast flowing waters.
				*if (halfling_help>0)
					The short halflings don't even try to cross, disappearing into the landscape the moment your back is turned.
					*set halfling_help 0
				*if (showstats)
					(Army Size -10, Army Food -5, Army Morale -10 and Citizen Fear +10)
				*set army_size -10
				*set army_food -5
				*set army_morale -10
				*set citizen_fear +10
				*goto After_Crossing
			#Say, "No, we will find another way."
				The general looks very relieved when you change your mind.
				*goto Crossing_loop

*label After_Crossing
*gosub Check_Army_Stats

The weather gets warmer and the trees fill with leaves as spring comes into full effect.  You leave the former duchy of Dumain, which you now call Daria once more, and skirt along the eastern border of the duchy of Uddo.  You must travel across the edge of Selina's land on your way to the duchy of Eddan, which is where Ludd lies.  A familiar sight greets you.  The small town of Dobbton lies on your path.  You see even more evidence of the destruction that wide-spread inexperienced demon summoning has brought.  The town is simply gone.  The fields are unplanted and many of the farmhouses are burned out husks.  The senseless waste makes you wonder once more why Alexander Zusak has done all of this.  You manage to find a few refugees living among the ruins.
*label Refugees_loop
*choice
	#Ask the refugees what happened.
		"Demons," one of them says while scratching his dirty hair.  "Between the escaped demons and the possessed summoners, the land has turned to hell.  It's the same everywhere, I hear.  Only the three capitals are still functioning:  Ludd, Tornassa and Vernex.  The rest of the world is going back to seed."
		*choice
			#Tell him that Brightwater is no longer a part of the duchies and that it is thriving.
				"Perhaps," he says.  "There are rumours that you've returned, but there are just as many rumours saying that Brightwater is worse off than the rest of the land.  Hard to tell what's true and what's not."
				*goto Refugees_loop
			#Don't tell him about Brightwater.
				*goto Refugees_loop
	*if (sherman_exists) #Ask the refugees if they know a man named Sherman.
		You are surprised to hear that they do.  One of them runs off into the countryside and returns a short time later with the man you met last autumn.  He is extremely happy to see you.
		
		"I owe you my life!" Sherman exclaims.  "I don't summon any more.  I threw away those cursed stones and my luck changed right away."
		
		He leans in toward you and speaks softly.  "I have a small farm community of like-minded individuals hidden in the woods.  When rumours of who you were came to us here in Dobbton, I couldn't believe it.  We've just hauled in an early harvest; we're double planting this year.  It's yours, if you want it."
		*choice
			#Accept the food donation.
				True to his word, Sherman leads a few of your soldiers into a hidden grove where they find a large cache of food.  Sherman smiles broadly and waves to you as you leave his small community.
				*if (showstats)
					*line_break
					(Army Food +10)
				*set army_food +10
				*goto Refugees_loop
			#Tell Sherman to keep his food, since he will need it to survive.
				"You are a saint!" Sherman exclaims joyously before returning to his hidden community.  "I hope you succeed and save Daria."
				*if (showstats)
					*line_break
					(Citizen Reputation +20 and Good +10)
				*set citizen_reputation +20
				*set good +10
				*goto Refugees_loop
	#Recruit anyone who will swear allegiance to you.
		*if (army_food<10)
			Unfortunately, you simply don't have the food needed to feed the newcomers and the refugees desert as quickly as they join.  They tell you that those who aren't living in the ruins have gone to Ludd and Tornassa to join the armies being gathered.
			*goto After_Refugees
		The poor refugees look pathetic and sad, but you know that with some food and a weapon, they will help your army to grow in size.  They tell you that those who aren't living in the ruins have gone to Ludd and Tornassa to join the armies being gathered.
		*if (showstats)
			*line_break
			(Army Size +10 and Army Food -10)
		*set army_size +10
		*set army_food -10
		*gosub Check_Army_Stats
		*goto After_Refugees
	#Continue marching to Ludd.
		The refugees silently watch you pass.  You wonder if many of them are from Dobbton or if they had travelled to these ruins because it was safer than where they were coming from.  After a few minutes of travelling, they are far behind you.
		*goto After_Refugees

*label After_Refugees
*if ((lover_name=branbrinn_name) or ((warprep_b_suggested) and (lover_name="None")))
	
	The army camps beside a narrow river after a long day's march.  Many of the weary soldiers make their way to its banks to splash around and wash some of the road dirt from their bodies.  It had been a hot day and the river is a welcome distraction.
	
	You are a short distance upriver from the rest of the army.  The scouts have already scanned the area and have kept the rest of the troops away so you could have some privacy.  Your clothes are piled on a rock at the shore and you are lying back in the cool water when you hear a splash.  You look over to see that you aren't alone.
	
	The first thing you notice is the ${branbrinn_manwoman}'s muscular body.  $!{branbrinn_hisher} glistening back moves gracefully as ${branbrinn_hisher} arms pull ${branbrinn_himher} through the water.  As ${branbrinn_heshe} turns, you see ${branbrinn_hisher}
	*if (branbrinn_hisher="his")
		brown beard and
	serious eyes.  It's ${branbrinn_name}.
	*if (lover_name=branbrinn_name)
		As Royal Consort,
	*if (lover_name!=branbrinn_name)
		As Captain of the Guard,
	${branbrinn_heshe} likely wasn't stopped when ${branbrinn_heshe} came to your section of the river.
	
	The moment ${branbrinn_heshe} notices you, ${branbrinn_hisher} eyes go wide in surprise.
	*if (branbrinn_hisher="his")
		You see his well defined chest and hard abs through the clear water.
	*if (branbrinn_hisher="her")
		You see her flat stomach and round breasts through the clear water.
	$!{branbrinn_heshe} immediately mumbles an apology and turns around as ${branbrinn_heshe} begins to swim back to the opposite side of the river where ${branbrinn_hisher} own clothes are piled.
	*choice
		#Swim forward, turn ${branbrinn_name}'s head toward you and kiss ${branbrinn_himher}.
			*if (branbrinn_relationship>=70)
				You catch ${branbrinn_himher} easily, making you wonder if ${branbrinn_heshe} wanted to be caught.  The moment your lips meet, you feel
				*if (branbrinn_hisher="his")
					his strong hands sliding up your neck and holding your face as you kiss.
				*if (branbrinn_hisher="her")
					her strong hands sliding up your back and holding you close as you kiss.
				*label BranBrinn_Kiss
				The kiss is passionate and firm as the many days on the road and the stress-filled winter tension are forgotten.  Your naked wet bodies press against each other in the cool river water.  You feel ${branbrinn_hisher} strong hands on your body as ${branbrinn_heshe} pulls you even closer.
				*if (showstats)
					*line_break
					(${branbrinn_name} Relationship +10)
				*set branbrinn_relationship +10
				*choice
					#Pull ${branbrinn_name} toward yourself and become intimate.
						You are both already naked and the passion of the kiss has made the two of you very eager.  It takes only a moment before you are sharing yourselves entirely.  Some time later, you return to the camp
						*set branbrinn_sleptwith true
						*set virgin false
						*label BranBrinn_ToCamp
						fully clothed, hand-in-hand, with large smiles on your faces.
						
						The troops take note of your arrival as they smile and word of your romance gives them hope for the future.
						*if (lover_name!=branbrinn_name)
							Word of your tryst reaches your council a few days later and before you know it, ${branbrinn_name} is named Royal Consort.
						*set lover_name branbrinn_name
						*set lover_hisher branbrinn_hisher
						*set lover_himher branbrinn_himher
						*set lover_heshe branbrinn_heshe
						*set branbrinn_lover true
						*set lover_exists true
						*if (showstats)
							*line_break
							(Army Morale +5)
						*set army_morale +5
						*goto After_BranBrinn_Tryst
					#Stop ${branbrinn_himher} from going any further and keep your relationship non-physical.
						You can tell that ${branbrinn_heshe} is eager to be with you in all ways, but ${branbrinn_heshe} also respects your wishes.  Being naked in a river together is very difficult, but ${branbrinn_heshe} has an iron will and extreme respect toward you.  You kiss, swim and talk some more before returning to camp,
						*goto BranBrinn_ToCamp
			*else
				"I can't do this," ${branbrinn_heshe} says as ${branbrinn_heshe} swims away from you, keeping a safe distance between you both.  "I'm
				*if (lover_name=branbrinn_name)
					sorry.  I will have to withdraw my status as Royal Consort.  I will continue to serve you as I have done before, but not in this way."
				*if (lover_name!=branbrinn_name)
					sorry."
				*if (showstats)
					(Needed 70 ${branbrinn_name} Relationship)
				
				${branbrinn_name} gets out of the water, takes ${branbrinn_hisher} clothing and leaves you by yourself in the river.
				*label BranBrinn_resigns
				*if (lover_name=branbrinn_name)
					*set lover_exists false
					*set lover_name "None"
					*set branbrinn_lover false
					True to ${branbrinn_hisher} word, ${branbrinn_heshe} officially
					*if (branbrinn_hisher="his")
						withdraws his request to court you and
					resigns the title of Royal Consort.  The citizens of Daria will be saddened to hear of this, but it is war time, and they will have to understand.
					*goto After_BranBrinn_Tryst
				*else
					*goto After_BranBrinn_Tryst
		#Say, "Wait, you don't need to go."
			*if (branbrinn_relationship>=70)
				*goto B_Kisses_You
			${branbrinn_name} ignores your words and keeps going.
			*if (showstats)
				(Needed 70 ${branbrinn_name} Relationship)
				
			*goto BranBrinn_ThatNight
		#Let ${branbrinn_himher} go without a word.
			*if (branbrinn_relationship>=70)
				*label B_Kisses_You
				You see ${branbrinn_name} glance back at you and then stop.  The captain suddenly seems determined as ${branbrinn_heshe} splashes back toward you.  Before you realize what ${branbrinn_heshe} is intending to do, ${branbrinn_hisher} lips are on yours and you feel
				*if (branbrinn_hisher="his")
					his strong hands sliding up your neck and holding your face as ${branbrinn_heshe} kisses you.
				*if (branbrinn_hisher="her")
					her strong hands sliding up your back and holding you close as ${branbrinn_heshe} kisses you.
				*choice
					#Kiss ${branbrinn_himher} back.
						*goto BranBrinn_Kiss
					#Step away.
						You step back and ${branbrinn_name} looks at you with a mixture of embarrassment and hurt.  $!{branbrinn_heshe} turns away from you, scoops up ${branbrinn_hisher} clothes and leaves you standing in the water.
						*if (showstats)
							*line_break
							(${branbrinn_name} Relationship -10)
						*set branbrinn_relationship -10
						*if (lover_name!=branbrinn_name)
							*goto After_BranBrinn_Tryst
						*else
							*goto BranBrinn_ThatNight
			*else
				*label BranBrinn_ThatNight
				When you return to camp, ${branbrinn_heshe} is waiting for you.  $!{branbrinn_hisher} chainmail seems even more polished and ${branbrinn_heshe} is standing even more erect than normal.
				*if (lover_name!=branbrinn_name)
					*goto After_BranBrinn_Tryst
				
				"I am sorry, but I cannot be your Royal Consort any longer," ${branbrinn_heshe} says.  "I feel that it is a lie to the people.  I will continue to serve you as I did before, but I can no longer live with the deception."
				
				*goto BranBrinn_resigns					
*else
	*goto After_BranBrinn_Tryst

*label After_BranBrinn_Tryst

A few days later finds you swatting another fly from the back of your neck as you walk through thick black muck.  Your feet are covered in the smelly goo up to your knees.
*if (mount_name!="None")
	You were forced to dismount ${mount_name} as the army passed through the swamp and the mud got too thick.
The road was in bad shape, yet another sign of the present times.

"What a stinking mess," ${friend1_name} says.  "No wonder nobody lives here."

"That isn't quite true," Archmage Cumari says as he slogs through the mud with you.  "I am always surprised how many mystics become hermits and live in places like this."
*choice
	#Ask, "Do you know the location of any of these mystics?"
		*if (cumari_relationship>=70)
			*label HaveYouHeard
			"As a matter of fact, yes," the Archmage says.  "Have you ever heard of an Arcane Tattooist?  They study a very interesting branch of magic connected to runes and words of power.  There is a ${tattooist_manwoman} named ${tattooist_name} who refused to come to the Academy.  Such power…such a waste, to live out here all alone."
			*choice
				#Say, "Have the army continue without me; I wish to meet this Arcane Tattooist.  I will catch back up with you once you have left the swamp."
					"My ${princeprincess}," General Vale says.  "We don't have time for this.  Any delays will bring us that much closer to winter.  Are you sure you wish to do this?"
					*choice
						#Say, "Yes, go on without me."
							*goto TattooAdventure
						#Say, "No, you are right.  We have no time to be side-tracked."
							*goto NoTattooist
				#Say, "Unfortunately, we have no time for delays."
					*label NoTattooist
					Everyone nods at your wisdom.  The sooner you can get through the swamp, the sooner you can get to Ludd.  Your soldiers are happy that they will not have to spend any extra time in the swamps.  Perhaps the Tattooist would be worth meeting after Daria has been reunited.
					*if (showstats)
						*line_break
						(General Vale Relationship +3 and Army Morale +3)
					*set vale_relationship +3
					*set army_morale +3
					*goto After_Tattooist
		*else
			"It's a large swamp," the Archmage says.  "They could be anywhere."
			*if ((perception>=40) and (charm>=50))
				
				"But you are thinking of someone specific," you say, noticing a glimmer of something in the Archmage's eyes.
				*if (showstats)
					*line_break
					(Perception +2 and Charm +2)
				*set perception +2
				*set charm +2
				
				*goto HaveYouHeard
			*if (showstats)
				(Needed 70 Cumari Relationship or Needed 40 Perception and 50 Charm)
			*goto After_Tattooist
	#Say nothing and keep pushing your way through the mud.
		"They can have this place," ${friend1_name} says.  "I'll be glad to leave this swamp behind."
		*goto After_Tattooist

*label TattooAdventure
"We can move faster than the army," ${friend3_name} says.  "Perhaps we can keep the delay down to a minimum."

You speak to Archmage Cumari and get the best directions you can, since he refuses to come with you.  You, ${friend1_name},
*if (friend2_exists)
	${friend2_name},
*if (prisonchild_inparty)
	${prisonchild_name},
${friend3_name} and ${friend4_name} venture off into the swamp to find the hermit.
*if (companion_name!="None")
	${companion_name} ${companion_travels} as you wade through the stinking bogs and push the vines out of your way.
Without having to wait for the baggage train and the mounts, your group makes much better time as you go deep into the swamp, although you can't help but to wonder if the delay will be worth it.
*if (showstats)
	(Army Delays +1)
*set army_delays +1

The wetlands seem to continue forever as you swat bugs, pull leaches from your skin and wade through the stagnant water.  You are a few days away from the army when suddenly ${friend1_name} vanishes under the water with a large splash!
*temp saved_self false
*label Find_Friend_Underwater_loop
*choice
	*if (gem_seeing) #Use your Gem of Seeing to find your friend.
		You hold the gem to your eye and the water suddenly appears to be perfectly clear.
		*gosub See_Friend_blurb
		*goto SeeFriend
	#Dive into the water to save ${friend1_himher}.
		You swim toward the splash and peer through the murky water.
		*if (perception>=40)
			*gosub See_Friend_blurb
			*if (showstats)
				*line_break
				(Perception +2)
			*set perception +2
			*goto SeeFriend
		*else
			Unfortunately, the water has been churned up and it's all muddy.
			*if (showstats)
				(Needed 40 Perception)
			*goto Find_Friend_Underwater_loop
	*if ((companion_type="toad") and (companion_name!="None")) #Send ${companion_name}, your toad, into the water.
		Although ${companion_name} is not a frog, ${companion_heshe} can still swim through the muddy water and see better than you can.  You get a clear image through your familiar's eyes.
		*gosub See_Friend_blurb
		*goto SeeFriend
	*if ((companion_type="water elemental") and (companion_name!="None")) #Send ${companion_name}, your water elemental, into the water.
		${companion_name} tries to expand into the murky water, but can't.  There is too much mud and vegetation in the stagnant filth interfering with ${companion_hisher} natural affinity toward water.  You have no doubt that ${companion_heshe} would eventually find ${friend1_name}, but you are worried that it would be too late.
		*goto Find_Friend_Underwater_loop
	#Call out to ${friend1_himher}.
		You yell but get no response.  Everyone is now splashing around in the water, but there is no sign of ${friend1_himher}.
		*goto Find_Friend_Underwater_loop
	*if (class_priest>0) #Cast a divine spell to locate ${friend1_name}'s life force.
		You say the prayer quickly and ${god_name} responds.  Suddenly, everything living glows with its own aura.
		*gosub See_Friend_blurb
		*if (showstats)
			*line_break
			(Magic +3)
		*set magic +3
		*goto SeeFriend
	#Give up searching.
		It appears that your friend has been lost to the swamp.
		*label Saved_By_Tattoos
		You see a small ${tattooist_manwoman} suddenly step out from the ferns.  $!{tattooist_heshe} is wearing rough brown robes and stands in bare-feet at the water's edge.  You see that every inch of the ${tattooist_manwoman}'s body is covered with colourful tattoos.  Several of the images suddenly glow vibrantly and you see the murky water part.
		
		${friend1_name} gasps from the mud as a large scaly creature opens its mouth and releases ${friend1_himher}.  You realize from the bulk of the creature that this is no ordinary animal.  The dire crocodile is twice the size of its largest cousin.  Another section of the ${tattooist_manwoman}'s tattoos glows and the huge creature turns its tail and scampers off into the water that is still being held back by the ${tattooist_manwoman}'s magic.
		*goto Tattoo_Talk
		
*label See_Friend_blurb
You see ${friend1_name} pinned to the muddy swamp floor by a large scaly creature!  $!{friend1_hisher} hands are beating ineffectually at the thick green skin of the monster.
*return

*label SeeFriend
*choice
	*if (sword) #Drive your sword into the creature.
		*if (blades>=40)
			Your blade has trouble at first, but once it pierces the creature's thick scaly hide, it sinks deep.  The creature releases ${friend1_name}, who swims to the surface and gasps for air.  Injured, the enormous crocodile-like monster swims away.
			*if (showstats)
				*line_break
				(Blades +3)
			*set blades +3
			*goto Tattooist_Comes_Forth
		*else
			Your blade glances off the creature's thick scaly hide.  You drive it forward again, but no matter which angle you try, you can't seem to injure the monster.
			*if (showstats)
				(Needed 40 Blades)
			
			*goto Saved_By_Tattoos
	*if (dagger) #Stab the creature's soft belly with your dagger.
		*if (blades>=60)
			You dive into the water and spin your body at the right moment so that your small blade can piece deeply into the large creature's underside.  You pull hard and it tears a big gash through the creature's white belly.  It releases ${friend1_name}, who swims to the surface and gasps for air.  Injured, the enormous crocodile-like monster swims away.
			*if (showstats)
				*line_break
				(Blades +3)
			*set blades +3
			*goto Tattooist_Comes_Forth
		*else
			Your small blade glances off the creature's thick scaly hide. You drive it forward again, but no matter which angle you try, you can't seem to injure the monster.
			*if (showstats)
				(Needed 60 Blades)
			
			*goto Saved_By_Tattoos
	*if ((class_druid>0) or (class_ranger>0)) #Command the crocodile to release ${friend1_name}.
		*rand coinflip 1 2
		*comment for future croc gender
		The scaly creature is larger than any crocodile you have seen before.  It slowly releases ${friend1_name} and floats to the surface.  It looks toward you with reptilian eyes and blinks twice.
		*if ((class_druid=2) or (class_ranger=2))
			You realize that this creature would follow you, if you wished.  Even better, it is so much larger than a regular crocodile, you suspect that you could ride it.
			*if (mount_type="forest worm")
				Unfortunately, it would not get along well with ${mount_name}, your forest worm.  So, you'd need to release the worm, to keep the crocodile.
			*choice
				*if ((mount_name!="None") and (mount_type="forest worm")) #Release ${mount_name} when you get back to camp and keep the dire crocodile.
					You know that it's the only way, since they would both try to eat each other.
					*goto Get_Croc_Mount
				*if ((mount_name!="None") and (mount_type!="forest worm")) #Sell ${mount_name} when you get back to camp and keep the dire crocodile.
					You know that you will get a fair price for ${mount_name} from the army quartermaster.
					*if (showstats)
						*line_break
						(Gold +${mount_value})
						
					*set gold +mount_value
					*label Get_Croc_Mount
					*if (coinflip=1)
						*set mount_hisher "his"
						*set mount_heshe "he"
						*set mount_himher "him"
					*if (coinflip=2)
						*set mount_hisher "her"
						*set mount_heshe "she"
						*set mount_himher "her"
					What do you name ${mount_himher}?
					*choice
						#Chompers.
							*set mount_name "Chompers"
							*goto Done_Naming_Croc
						#Gustave.
							*set mount_name "Gustave"
							*goto Done_Naming_Croc
						#Sobek.
							*set mount_name "Sobek"
							*goto Done_Naming_Croc
						#Toothy.
							*set mount_name "Toothy"
							*goto Done_Naming_Croc
						#Something else.
							*label Rename_Mount
							You decide to name ${mount_himher}…
							*input_text mount_name
							*if (mount_name="None")
								That is a terrible name.
								*goto Rename_Mount
							*goto Done_Naming_Croc

					*label Done_Naming_Croc
					*set mount_desc "a wild"
					*set mount_type "crocodile"
					*set mount_value 0
					*set mount_level 6
					*achieve sweetride
					"I'd just like to say," ${friend1_name} says,  "I think that taking this monster is a terrible idea."
					*goto Tattooist_Comes_Forth
				*if (mount_name="None") #Keep the crocodile as a mount.
					*goto Get_Croc_Mount
				#Release the crocodile into the wild.
					You pat the large crocodile on the back and it swims away into the murky water.
					*goto Tattooist_Comes_Forth
		*else
			It then turns away and disappears into the murky water.
			*if (showstats)
				(Needed Level 2 Ranger or Level 2 Druid)
			*goto Tattooist_Comes_Forth	
	*if (bow) #Shoot the creature with your bow.
		*if (archery>=60)
			The first arrow plunges through the water and sticks into the creature's back.  The second arrow does as well.  You aren't certain how much this is damaging the monster, but it releases ${friend1_name}, who swims to the surface and gasps for air.  Injured, the enormous crocodile-like monster swims away.
			*if (showstats)
				*line_break
				(Archery +3)
			*set archery +3
			*goto Tattooist_Comes_Forth
		*else
			Your arrows strike the water with a splash, but they don't have enough force to also penetrate the creature's thick scaly hide.
			*if (showstats)
				(Needed 60 Archery)
			
			*goto Saved_By_Tattoos
	*if ((friend1_name!=karlkarla_name) and (infinity_arrow)) #Tell ${karlkarla_name} to shoot the creature with the Infinity Arrow.
		The arrow slices through the water and strikes the enormous crocodile in the head, burying itself up to the feathers.  ${friend1_name} is released and swims to the surface and gasps for air.  The beast twitches a few more times and then floats belly up.
		*set infinity_arrow false
		*goto Tattooist_Comes_Forth
	#Cast a spell to instill fear into the crocodile.
		*if (magic>=80)
			There are very few things that could scare such a ferocious beast, but your magic is able to do just that.  The monster grunts and releases ${friend1_name}, who quickly swims to the surface and gasps for air.  Terrified, the enormous crocodile-like monster swims away.
			*if (showstats)
				*line_break
				(Magic +3)
			*set magic +3
			*goto Tattooist_Comes_Forth
		*else
			You realize that although you've frightened the beast, it still isn't letting go.  You would need much more magical energy to amplify the terror to a level high enough to be effective.
			*if (showstats)
				(Needed 80 Magic)
			
			*goto Saved_By_Tattoos
	*if (ki_strike) #Swim to the crocodile and use your Ki Strike upon it.
		You draw back your fist and concentrate.  You feel the power build and then you punch.  Your fist passes through the water as though it were air and strikes the crocodile in the side.  The beast's eyes open wide as it releases ${friend1_name} and floats up to the surface belly up, its internal organs having been decimated by your strike.
		*goto Tattooist_Comes_Forth
	#Jump onto the beast and pull it off your friend.
		You dive onto the enormous crocodile's back.
		*if ((unarmed>=80) or (strength>=60))
			It is still busy with ${friend1_name}, so you are able to wrap your legs around it and grip its head.  You pull back with all of your weight, angling the creature's head upward.  It releases ${friend1_name} and then bucks you off.  Luckily, instead of fighting you, it swims away into the murky water as ${friend1_name} gasps for air.
			*if (showstats)
				*line_break
				(Unarmed +3 and Strength +3)
			*set unarmed +3
			*set strength +3
			*goto Tattooist_Comes_Forth
		*else
			Unfortunately, it is much too strong for you and bucks you off.
			*if (showstats)
				(Needed 80 Unarmed or 60 Strength)
			
			*goto Saved_By_Tattoos

*label Tattooist_Comes_Forth
*set saved_self true

"That was close," a voice says calmly from the shore.

You look up to see a small ${tattooist_manwoman} standing among the ferns.  $!{tattooist_heshe} is wearing rough brown robes and stands in bare-feet at the water's edge.  You see that every inch of the ${tattooist_manwoman}'s body is covered with colourful tattoos.
*label Tattoo_Talk
*choice
	#Ask, "Are you ${tattooist_name}?"
		"Yes, that is me," ${tattooist_heshe} says.  "Why have you come?"
		*goto Tattoo_Talk2
	*if (saved_self) #Shout, "Why didn't you help us?"
		"I only just arrived," ${tattooist_heshe} says.  "I would have tried to do something, had you not dealt with the dire crocodile on your own.  Why have you come here?"
		*goto Tattoo_Talk2
	*if (saved_self=false) #Say, "Thank you for your aid."
		"You are most welcome," ${tattooist_heshe} says.  "But, why are you here?"
		*goto Tattoo_Talk2
	#Say, "I am $!{princeprincess} ${name} of Daria."
		"Greetings," ${tattooist_heshe} says.  "I am ${tattooist_name}.  Why have you come to my home?"
		*goto Tattoo_Talk2

*label Tattoo_Talk2

You begin to tell your long story, but ${tattooist_name} stops you.  $!{tattooist_heshe} leads you and your friends to a small hut in the swamp.  The house is built on stilts that keep it out of the water and a small shallow boat is tied to the dock.  $!{tattooist_heshe} gives you all tea and strange biscuits made from some type of dried root while you tell your story.

"I see," ${tattooist_heshe} says.  "Demon summoning is a foul art, but what can I do to help you?"
*temp give_tattoo false
*label Talk_To_Tattooist_loop
*choice
	#Ask, "Can you give me a magical tattoo?"
		*gosub Check_Delay
		*if (give_tattoo)
			"Very well," ${tattooist_name} says.  "Take a seat."
			
			*label Tattoo_Self
			$!{tattooist_heshe} gets out a few jars of ink and some needles.
			*choice
				#Get a tattoo of several concentric circles on the shoulder-blade which will promote health.
					The circles radiate out to the size of the palm of your hand.  It hurts when it is applied, but it heals the same as any other tattoo.  In the days to come, when you are feeling extra tired or weary, it glows briefly and you feel a little more energized.
					*if (showstats)
						*line_break
						(Endurance +7)
					*set endurance +7
					*set tattoo_circles true
					*set tattoo_gotsome true
					*label Return_From_Tattooist
					
					You return to your army a few days later and find that they are waiting for you at the edge of the swamp.
					*if (tattoo_face)
						They look at your new facial tattoo with fear and uncertainty.
					*if (tattoo_face=false)
						
						"I see you found the Arcane Tattooist," Archmage Cumari says.  "A pity that ${tattooist_heshe} won't share ${tattooist_hisher} knowledge with the Academy.
					
					General Vale gives the orders and soon your army is marching forward once more.
					*if (class_tattooist>0)
						${tattooist_name} is given room in a wagon and begins instructing you on magical tattoos.
					*goto After_Tattooist
				#Get a tattoo of a series of blue stars up the neck which will promote magical insight.
					${tattooist_name} concentrates as ${tattooist_heshe} makes the incantation.  The stars are drawn with needle and ink, but also with magic.  As the image spreads, you feel more alert to your surroundings.
					*if (showstats)
						*line_break
						(Perception +7)
					*set perception +7
					*set tattoo_stars true
					*set tattoo_gotsome true
					*goto Return_From_Tattooist
				#Get a full-face tattoo of black swirls and runes which will promote strength and aggression.
					You immediately feel stronger, but you also feel more on edge and angrier.  It is a good and powerful feeling, considering that you are about to go to war.
					*if (showstats)
						*line_break
						(Strength +7 and Citizen Fear +15)
					*set strength +7
					*set citizen_fear +15
					*set tattoo_face true
					*set tattoo_gotsome true
					*goto Return_From_Tattooist
		*else
			*goto After_Tattooist
	#Ask, "Can you give me and my friends magical tattoos?"
		*gosub Check_Delay
		*if (give_tattoo)
			*if (prisonchild_inparty)
				${tattooist_name} refuses to give ${prisonchild_name} a tattoo, saying that ${prisonchild_heshe} is too young to make such a permanent decision.
				
			"Very well," ${tattooist_name} says.  "Take a seat.  What tattoo would you and your friends like?"
			
			$!{tattooist_heshe} gets out a few jars of ink and some needles.
			*choice	
				#A round circle on the shoulder-blade which will promote health.
					The small circle is about the size of a coin.  It hurts when it is applied, but it heals the same as any other tattoo.  In the days to come, when you are feeling extra tired or weary, it glows briefly and you feel a little more energized.  It also acts as a unifying symbol for you and your companions, making you feel more like a team.
					*if (showstats)
						*line_break
						(
						*gosub Tattoo_Friend_Bump
						and Endurance +5)
					*set endurance +5
					*set tattoo_circle true
					*set tattoo_gotsome true
					*goto Return_From_Tattooist
				#A blue star on the side of the neck which will promote magical insights.
					The small star is about the size of a coin.  It hurts a lot when it is applied, but it heals the same as any other tattoo.  You can't quite put your finger on the changes, but it makes you feel like you are more aware of your surroundings.  It also acts as a unifying symbol for you and your companions, making you feel more like a team.
					*if (showstats)
						*line_break
						(
						*gosub Tattoo_Friend_Bump
						and Perception +5)
					*set perception +5
					*set tattoo_star true
					*set tattoo_gotsome true
					*goto Return_From_Tattooist
				#A full-face tattoo of black swirls and runes which will promote strength and aggression.
					Your friends are more than a little hesitant to get the ink work done.  A full-face tattoo is a serious commitment, after all.
					*if (theothea_inparty)
						
						*if (theothea_relationship>=70)
							"What the hells, let's do it," ${theothea_name} says.
							*if (showstats)
								(${theothea_name} Relationship +10)
							*set theothea_relationship +10
						*if (theothea_relationship<70)
							"Hells no!!" ${theothea_name} says angrily.
							*if (showstats)
								(Needed 70 ${theothea_name} Relationship)
								*line_break
								(${theothea_name} Relationship -10)
							*set theothea_relationship -10
					*if (jacejess_inparty)
						
						*if (jacejess_relationship>=70)
							"Why not," ${jacejess_name} says with a smirk.  "People hate me anyway."
							*if (showstats)
								(${jacejess_name} Relationship +10)
							*set jacejess_relationship +10
						*if (jacejess_relationship<70)
							"I am not doing this," ${jacejess_name} says.  "People hate me enough anyway."
							*if (showstats)
								(Needed 70 ${jacejess_name} Relationship)
								*line_break
								(${jacejess_name} Relationship -10)
							*set jacejess_relationship -10
					*if (gillgale_inparty)
						
						*if (gillgale_relationship>=70)
							"This is bad ass!" ${gillgale_name} says, agreeing to do it.
							*if (showstats)
								(${gillgale_name} Relationship +10)
							*set gillgale_relationship +10
						*if (gillgale_relationship<70)
							"Uhhhh, no," ${gillgale_name} says, shaking ${gillgale_hisher} head.
							*if (showstats)
								(Needed 70 ${gillgale_name} Relationship)
								*line_break
								(${gillgale_name} Relationship -10)
							*set gillgale_relationship -10
					*if (peterpetra_inparty)
						
						*if (peterpetra_relationship>=70)
							"As a symbol of friendship and unity, I shall do this," ${peterpetra_name} states.
							*if (showstats)
								(${peterpetra_name} Relationship +10)
							*set peterpetra_relationship +10
						*if (peterpetra_relationship<70)
							"My body is sacred. I will not do this," ${peterpetra_name} states.
							*if (showstats)
								(Needed 70 ${peterpetra_name} Relationship)
								*line_break
								(${peterpetra_name} Relationship -10)
							*set peterpetra_relationship -10
					*if (karlkarla_inparty)
						
						*if (karlkarla_relationship>=70)
							"I suppose so," ${karlkarla_name} says softly.
							*if (showstats)
								(${karlkarla_name} Relationship +10)
							*set karlkarla_relationship +10
						*if (karlkarla_relationship<70)
							"No, thank you," ${karlkarla_name} says softly.
							*if (showstats)
								(Needed 70 ${karlkarla_name} Relationship)
								*line_break
								(${karlkarla_name} Relationship -10)
							*set karlkarla_relationship -10
					*if (branbrinn_inparty)
						
						*if (branbrinn_relationship>=70)
							"As you wish," Captain ${branbrinn_name} says.
							*if (showstats)
								(${branbrinn_name} Relationship +10)
							*set branbrinn_relationship +10
						*if (branbrinn_relationship<70)
							"I do not believe that such a tattoo is becoming of an officer," ${branbrinn_name} says.
							*if (showstats)
								(Needed 70 ${branbrinn_name} Relationship)
								*line_break
								(${branbrinn_name} Relationship -10)
							*set branbrinn_relationship -10
					
					When you get the tattoo yourself, you feel stronger, but you also feel more on edge and angrier.  It is a good and powerful feeling, considering that you are about to go to war.
					*if (showstats)
						*line_break
						(Strength +5 and Citizen Fear +15)
					*set strength +5
					*set citizen_fear +15
					*set tattoo_face true
					*set tattoo_gotsome true
					*goto Return_From_Tattooist

			*label Tattoo_Friend_Bump
			*if (theothea_inparty)
				${theothea_name} Relationship +5,
				*set theothea_relationship +5
			*if (jacejess_inparty)
				${jacejess_name} Relationship +5,
				*set jacejess_relationship +5
			*if (gillgale_inparty)
				${gillgale_name} Relationship +5,
				*set gillgale_relationship +5
			*if (peterpetra_inparty)
				${peterpetra_name} Relationship +5,
				*set peterpetra_relationship +5
			*if (karlkarla_inparty)
				${karlkarla_name} Relationship +5,
				*set karlkarla_relationship +5
			*if (branbrinn_inparty)
				${branbrinn_name} Relationship +5,
				*set branbrinn_relationship +5
			*return
		*else
			*goto After_Tattooist
	#Ask, "Can you give everyone in my army a magical tattoo?"
		The ${tattooist_manwoman} laughs at your request.
		
		"Such an undertaking would be enormous!" ${tattooist_heshe} says.  "I'd need a tremendous amount of ink and it would take months to build that amount of
		*if (saved_self=false)
			energy.  I helped you once already.  I have no desire to leave my home here."
			*goto Talk_To_Tattooist_loop
		energy."
		*choice
			#Say, "Yes, and I shall make it worth your while."
				"I will need a few days to gather the ingredients and supplies needed to make such an enormous number of tattoos," ${tattooist_name} says.  "But yes, I believe I can help you."
				*choice
					#Spend a few days helping the Arcane Tattooist to pack up.
						$!{tattooist_heshe} has several jars of inks already prepared, but it takes time for ${tattooist_himher} to collect extra amounts of strange swamp plants that will be ground up into the inks needed for ${tattooist_hisher} work.  Eventually, you return to the army with ${tattooist_name}.
						*if (showstats)
							*line_break
							(Army Delays +1)
						*set army_delays +1
						*goto Pack_Up_Tattooist
					*if (gold>=150) #Tell ${tattooist_himher} that you must leave immediately, but that you will purchase the ingredients ${tattooist_heshe} will need instead of gathering them.  (Needs 150 Gold)
						${tattooist_name} grabs the things ${tattooist_heshe} will need that can't be purchased and then leaves ${tattooist_hisher} home in the swamp.  When you return to the army, you give ${tattooist_himher} the money to buy the ingredients that you had no time to collect. 
						*if (showstats)
							*line_break
							(Gold -150)
						*set gold -150
						*label Pack_Up_Tattooist
						
						Much like the smiths that travel with your army, ${tattooist_name} sets up a travelling hut to work out of.  You send your soldiers to ${tattooist_himher} one at a time for a tattoo to help them.
						
						"What tattoo would you like me to give to you and your soldiers?"
						*label Tattoo_Soldiers_loop
						*choice
							#A round circle on the shoulder-blade which will promote health.
								The small circle is about the size of a coin.  It hurts when it is applied, but it heals the same as any other tattoo.  In the days to come, when you are feeling extra tired or weary, it glows briefly and you feel a little more energized.  It also acts as a unifying symbol for your soldiers as they line up near ${tattooist_name}'s hut at the end of each day's march to get their tattoos.
								*if (showstats)
									*line_break
									(Army Power +3, Army Morale +3 and Endurance +5)
								*set army_power +3
								*set army_morale +3
								*set endurance +5
								*set tattoo_circle true
								*set army_tattoo_circle true
								*set tattoo_gotsome true
								*goto After_Tattooist
							#A blue star on the side of the neck which will promote magical insights.
								The small star is about the size of a coin.  It hurts a lot when it is applied, but it heals the same as any other tattoo.  There aren't many soldiers who willingly come for the tattoo, but those who do are happy to have it.  You can't quite put your finger on the changes, but it makes you feel like you are more aware of your surroundings.
								*if (showstats)
									*line_break
									(Army Power +3, Army Morale +3 and Perception +5)
								*set army_power +3
								*set army_morale +3
								*set perception +5
								*set tattoo_star true
								*set army_tattoo_star true
								*set tattoo_gotsome true
								*goto After_Tattooist
							#A full-face tattoo of black swirls and runes which will promote strength and aggression.
								Your soldiers refuse to go through with it.  They refuse to get the tattoo.
								*choice
									#Force the troops to get the tattoo.
										The first soldiers have to be dragged into ${tattooist_name}'s hut.  When you get the tattoo yourself, it becomes a little easier to force others to get it too.  You feel stronger, but you also feel more on edge and angrier.  It is a good and powerful feeling, considering that you are about to go to war.
										*if (showstats)
											*line_break
											(Army Power +10, Army Morale -10, Strength +5, Citizen Fear +15 and Evil +10)
										*set army_power +10
										*set army_morale -10
										*set strength +5
										*set citizen_fear +15
										*set good -10
										*set tattoo_face true
										*set army_tattoo_face true
										*set tattoo_gotsome true
										*gosub Check_Army_Stats
										*goto After_Tattooist
									#Get the tattoo yourself, but don't force the soldiers.
										You feel stronger, but you also feel more on edge and angrier.  It is a good feeling, considering that you are about to go to war.  Since your troops refuse to get the tattoos, ${tattooist_name} leaves your army once your ink-work is complete.
										*if (showstats)
											*line_break
											(Strength +5, Citizen Fear +15 and Evil +10)
										*set strength +5
										*set citizen_fear +15
										*set good -10
										*set tattoo_face true
										*set tattoo_gotsome true
										*goto After_Tattooist
									#Get a different tattoo for you and the soldiers.
										*goto Tattoo_Soldiers_loop
					#Change your mind, due to the fact that you have no time for delays.
						*goto Talk_To_Tattooist_loop
			#Say, "I understand.  But perhaps you could still help me…."
				*goto Talk_To_Tattooist_loop
	#Ask, "Can you teach me to become an Arcane Tattooist?"
		"You wish to learn what I know?" ${tattooist_name} says incredulously.
		
		$!{tattooist_heshe} asks you many questions about runes and about the properties of various plants.  $!{tattooist_heshe} explains that ${tattooist_heshe} learned the art from another Arcane Tattooist from a far away land and has been looking for an apprentice to some day share the knowledge.
		
		*if ((arcana>=75) and ((nature>=50) and (magic>=30)))
			"Very well," ${tattooist_heshe} says.  "I accept you as my apprentice.  I will come with you, but I will not make any tattoos for anyone."
			
			$!{tattooist_heshe} continues to talk pleasantly about things, but refuses to elaborate on your apprenticeship.  $!{tattooist_heshe} does, however, offer to help you craft a single tattoo for yourself.
			
			*set considering_tattooist true
			*goto Tattoo_Self
		*else
			"I am sorry," ${tattooist_heshe} says.  "But you are not the one I seek."
			*if (showstats)
				(Needed 75 Arcana, 50 Nature and 30 Magic)
			*goto Talk_To_Tattooist_loop
	#Drink your tea and eat your biscuits, but get no tattoos.
		*set tattoo_gotsome false
		The magical nature of the tattoos is intriguing, but in the end, you decide to not get one.  You return to your army and find them on the edge of the swamp waiting for you.
		*goto After_Tattooist

*label Check_Delay
*if (saved_self=false)
	"Alas, I cannot," ${tattooist_heshe} says.  "The focused and acute use of my tattoos to save your friend drained me of my energies.  It will take some time before my energies refresh enough to create any new tattoos."
	*choice
		#Say, "We can wait."
			Your friends are all surprised to hear your decision.  The troops will already be waiting for you.  You hope that your decision to further delay the army is worth it.
			*if (showstats)
				*line_break
				(Army Delays +1)
			*set army_delays +1
			*set give_tattoo true
			
			*return
		#Say, "I have no time to wait."
			Your friends are very happy with your decision.  You finish your tea and return to the army.  Sure enough, they are already waiting for you at the edge of the swamp.
			*if (showstats)
				(${friend1_name} Relationship +1,
				*if (friend2_exists)
					${friend2_name} Relationship +1,
				${friend3_name} Relationship
				and ${friend4_name} Relationship)
			*if (theothea_inparty)
				*set theothea_relationship +1
			*if (jacejess_inparty)
				*set jacejess_relationship +1
			*if (gillgale_inparty)
				*set gillgale_relationship +1
			*if (peterpetra_inparty)
				*set peterpetra_relationship +1
			*if (karlkarla_inparty)
				*set karlkarla_relationship +1
			*set branbrinn_relationship +1
			*set give_tattoo false
			*return
*else
	*set give_tattoo true
	*return
	
*label After_Tattooist
*goto_scene luddbattle

*comment ------------------------- Subroutines

*label Army_Use_Food
*comment Input:  food_needed
*if (army_food>=food_needed)
	*comment Has enough food.
	*if (showstats)
		*line_break
		(Army Food -${food_needed})
	*set army_food -food_needed
	*return
*temp food_used 0
*temp food_still_needed 0
*set food_used army_food
*set food_still_needed food_needed-army_food
With the lack of food, your army begins to unravel as people desert in the middle of the night.
*if (army_food<=0)
	*if (showstats)
		(Needed ${food_needed} Army Food)
		*line_break
		(Army Morale -${food_still_needed} and Army Size -${food_still_needed})
	*set army_food 0
	*set army_morale -food_still_needed
	*set army_size -food_still_needed
	*gosub Check_Army_Stats
	*return
*else
	*if (showstats)
		(Needed ${food_needed} Army Food)
		*line_break
		(Army Food -${food_used}, Army Morale -${food_still_needed} and Army Size -${food_still_needed})
	*set army_food 0
	*set army_morale -food_still_needed
	*set army_size -food_still_needed
	*gosub Check_Army_Stats
	*return

*label Check_Army_Stats
*if (army_morale<=0)
	*set army_morale 0
*if (army_size<0)
	*set army_size 0
*if (army_food<0)
	*set army_food 0
*if (army_power<0)
	*set army_power 0
*if (citizen_reputation<0)
	*set citizen_reputation 0
*return
