*comment Copyright 2015 by Mike Walter
*comment The Lost Heir 2:  Forging a Kingdom
*comment Scene #7: luddbattle.txt
*comment 34900 Words - 225 subroutines = 34.7 k
*hide_reuse

*temp ludd_army 100
*temp ludd_buildings_fired false
*temp temp_failed_assassination false
*temp did_raid false
*temp poison_attempt false
*temp poisoned_ludd false
*temp poisoned_ludd_heard_once false
*temp parley_what_if false
*temp parley_over false
*temp borrowed_horse false
*temp cumari_favour_used false
*temp temp_lost_companions false
*temp food_source "None"
*temp parley_location "None"
*temp show_command_army_forward true
*temp considered_parlay false
*temp ludd_defences_food_dealt_with false
*if ((army_delays=0) or (army_delays=1))
	It is just after the first day of summer when you finally see Ludd, which makes General Vale happy since you are on schedule.  Your food stores continue to be used as the first leg of your march ends.
	*set food_needed 10
	*gosub Army_Use_Food
*if ((army_delays>1) and (army_delays<4))
	It is well past the first day of summer when you finally see Ludd, which makes General Vale worried because you are behind schedule.
	*if (showstats)
		(Needed 1 or Under Army Delays for Less Food Use)
		
	Your food stores continue to be used as the first leg of your march ends.
	*set food_needed 15
	*gosub Army_Use_Food
*if (army_delays>=4)
	It is well past the first day of summer when you finally see Ludd, which makes General Vale very worried because you are so far behind schedule.
	*if (showstats)
		(Needed 3 or Under Army Delays for Less Food Use)
		
	Your food stores continue to be used as the first leg of your march ends.
	*set food_needed 20
	*gosub Army_Use_Food
*label After_Ludd_Arrival_Food

The vast plains surrounding the city make hiding your army impossible.  Your war council has been discussing how to best take the city for many months now.  The fact that Ludd is famous for its horses tells you that you will be facing a very fast and skilled cavalry.  The good news is that the city has no true walls or fortifications.
*if (warprep_spies="Ludd")
	
	"Your Highness!" a man says at your elbow.
	
	He looks like a regular commoner and wears no weapons that you can see.
	
	"This man is a member of your spy network," Captain ${branbrinn_name} informs you.  "Although the last I heard, he was still stationed in Ludd."
	
	"I managed to escape the city this morning," the man says.  "They haven't been letting anyone in or out since their scouts noted your arrival a week ago.  I bribed a guard and rode here as fast as I could."
	*choice
		#Command, "Make your report."
			*goto Ludd_Spy_Report
		#Say, "You've done well.  What news do you bring?"
			*goto Ludd_Spy_Report
		#Ask, "What are you doing here?  Did you learn something?"
			*label Ludd_Spy_Report
			"Duke Eddan has laid a trap for you," the man says, getting the attention of your advisers as well.  "He's dug a large pit just north of here.  Very large.  He's got a number of soldiers and their horses within.  They've covered it with canvas and covered that with dirt.  They intend to attack your exposed right flank at any moment!"
			*choice
				#Say, "General Vale, tell our troops to prepare a defence."
					The general leaves your small group and quickly spreads the order.  The attack comes a few hours later with a great cloud of dust and burst of noise.  You watch from a safe location as the enemy riders seem to erupt from the flat plains.  Your troops are ready and fight the soldiers off.  The battle takes only a few minutes as the enemy is repulsed, turning back to Ludd amidst the cheers of your army's first victory.
					*label Ludd_Spy_Victory
					*if (showstats)
						*line_break
						(Army Morale +10)
					*set army_morale +10
					*goto After_Ludd_FirstAttack
				#Say, "General Vale, prepare an ambush of our own."
					Since you know where the enemy is and they don't know that you are aware of them, you are able to set up a surprise of your own.  The general leaves your small group and quickly spreads the orders.  The attack comes a few hours later with a great cloud of dust and burst of noise.  You watch from a safe location as the enemy riders seem to erupt from the flat plains.  Although your soldiers appear to be unprepared, they were more than ready for the attack.  The battle takes only a few minutes as the enemy is repulsed, turning back to Ludd amidst the cheers of your army's first victory.
					*goto Ludd_Spy_Victory
				#Say, "General Vale, prepare a counter attack."
					The general leaves your small group and quickly assembles a strike team.  You watch from a distance as your soldiers break away from the main force.  You can see the cloud of dust as the enemy fights their way out of the dirt-covered canvas.  They are surprised but manage to get away before inflicting any serious losses on your troops.  The battle takes only a few minutes as the enemy is scattered back to Ludd amidst the cheers of your army's first victory.
					*goto Ludd_Spy_Victory
				*if (poison_package) #Use the ${prisoner1_nickname}'s strike team's poison package against them.
					The poison would need to be put into their drinking water to be used most effectively, but since they are in a confined space, you suspect that the package could be doused with oil and lit on fire to create some noxious fumes.
					*set poison_package false
					*temp person_sent "None"
					*temp halfling_sent 0
					*temp soldier_sent 0
					*rand halfling_sent 1 2
					*rand soldier_sent 1 4
					*label Surprise_Poison_Loop
					*choice
						#Do the task yourself.
							*if (stealth>=60)
								It isn't easy to sneak across the open plain with only rocks and small shrubs to hide you, but you are very talented at what you do.  You find the large canvas and dirt covered pit without trouble.  Carefully, you light the package on fire and throw it inside.  You immediately see green choking smoke pouring from the edges and the soldiers inside begin to scream in agony.  The entire force is killed to the man before any of them can escape the small confined space.  You return to your camp amidst the cheers of your army's first victory.
								*set ludd_army -25
								*if (showstats)
									*line_break
									(Stealth +3, Army Morale +10 and Ludd Army -25 to ${ludd_army} / 100)
								*set stealth +3
								*set army_morale +10
								*goto After_Ludd_FirstAttack
							*else
								You attempt to cross the open plain, but the enemy must see you because the canvass is thrown clear and the troops pour forth.
								*if (showstats)
									(Needed 60 Stealth)
								
								Luckily General Vale has planned for this and you are able to return to your army in time for them to protect you.  The battle takes only a few minutes as the enemy is repulsed, turning back to Ludd.  Although your plan failed, the battle is still your army's first victory.
								*goto Ludd_Spy_Victory
						#Send a soldier to do it.
							*set person_sent "soldier"
							*label Send_Another
							The ${person_sent} takes the package, a flask of oil and a red coal in a sand-filled box with him.  You wait for some sign of success or failure, guessing that he has about
							*if (person_sent="soldier")
								an even
								*set coinflip soldier_sent
							*if (person_sent="halfling")
								a reasonable
								*set coinflip halfling_sent
							chance of success.
							*if (coinflip=1)
								Unfortunately, the rising dust cloud and yelling of horsemen tells you that the plan failed.  The poor ${person_sent} must have been caught and killed.  At least General Vale had the soldiers get ready for an attack.  The battle takes only a few minutes as the enemy is repulsed, turning back to Ludd amidst the cheers of your army's first victory on the field.
								*if (showstats)
									*if (person_sent="soldier")
										(Had a 50% Chance of Success)
									*if (person_sent="halfling")
										(Had a 75% Chance of Success)
								*goto Ludd_Spy_Victory
							You see greenish smoke rise from the north and then a bunch of pitiful screaming fills the air.  The poor ${person_sent} who set fire to the poison package is killed, but so is the entire group of hidden horsemen!  Your army cheers the victory, happy that only one of their number died.
							*set ludd_army -25
							*if (showstats)
								*line_break
								(Army Morale +10 and Ludd Army -25 to ${ludd_army} / 100)
							*set army_morale +10
							*goto After_Ludd_FirstAttack
						*if (halfling_help>0) #Send a halfling to do it.
							*set person_sent "halfling"
							*goto Send_Another
						*if (gillgale_inparty) #Send ${gillgale_name} to do it.
							*if (gillgale_relationship<60)
								"I'm not doing any suicide missions today," ${gillgale_name} says.  "Ask one of your soldiers to do it or do it yourself!"
								*if (showstats)
									(Needed 60 ${gillgale_name} Relationship)
								*goto Surprise_Poison_Loop
							${gillgale_name} grins as ${gillgale_heshe} takes the package, a flask of oil and a red coal in a sand-filled box with ${gillgale_himher}.  You don't have to wait very long for a sign of success as greenish smoke rises from the north and the air fills with pitiful screaming.  Your army cheers the victory as ${gillgale_name} returns triumphantly.  The entire group of hidden soldiers die before a single one gets out of the pit.
							*set ludd_army -25
							*if (showstats)
								*line_break
								(Army Morale +10 and Ludd Army -25 to ${ludd_army} / 100)
							*set army_morale +10
							*goto After_Ludd_FirstAttack
		#Say, "We don't have time for this.  We are planning our attack."
			The man tries to say more, but one of your soldiers takes him away.  You turn back to the city of Ludd and wonder what kind of tactician Duke Eddan will turn out to be.
			*goto Ludd_Attacked
*else
	*comment Spies not in Ludd 
	You don't know what to expect from Duke Eddan since his skill as a tactician is unknown.
	*label Ludd_Attacked
	
	You are broken from your thoughts as a great cloud of dust erupts on your right flank!  The sounds of battle suddenly explode there as well.  You see about fifty horsemen attacking your surprised soldiers.  They strike fast and hard before turning away from your main force and riding back to Ludd.  It takes some time to calm your army down after the surprise attack.
	
	"They must have been planning that attack all winter," General Vale says with a frown.  "Duke Eddan is more clever than I had thought.  They were hiding in a hole covered with canvas and dirt.  Our scouts missed them until it was too late."
	*if (showstats)
		*line_break
		(Army Morale -7, Army Power -5 and Army Size -7)
	*set army_morale -7
	*set army_power -5
	*set army_size -7
	*gosub Check_Army_Stats
	*goto After_Ludd_FirstAttack

*label After_Ludd_FirstAttack

Your army sets up a defensive position outside of Ludd.  Sharpened poles are placed around the perimeter and pits are dug so your troops can hide from mounted archers.  Latrine ditches are dug and small walls are raised.
*if (dwarf_help>0)
	The dwarves are tireless diggers, helping with everything from the holes for the poles to the trenches to hide in and the ditches for waste.
*if (using_legacy)

	"Ahhhh, Ludd," the familiar voice says.  "It's time to get you some weapons that can destroy Zusak once and for all.  There's a cave over here."
	
	You see that the Wizard of Elmvale has returned.  $!{legacy_heshe} seems older than some visits, but not as old as other times.  You gather your most trusted companions and several soldiers as you follow the wizard's directions.  The cave isn't very far away.  It takes a few minutes to clear the vegetation and to dig past the dirt which conceals the entrance.  As the soldiers dig, the wizard describes some of the amazing things ${legacy_heshe} has left for you.
	
	The moment you get inside, you see that the artifacts are all missing.  You see that the chests have been smashed open and torn asunder by sharp claws.
	
	"Blast it all!" ${legacy_heshe} shouts in frustration.  "T'dari has done it again."
	*choice
		#"Can you give the artifacts to people in your time and tell them to have their ancestors bring them to me?"
			"I've done this several times," the wizard says.  "I'm guessing that none of the items have reached you."
			*goto Legacy_New_Plan
		#"Can you go back to when Zusak was a child and kill him?"
			*label Afraid_Not
			"I'm afraid not," the wizard says.  "Such an event would create a paradox that would prevent my time-projection spell from working.  As I tried to cast the spell, my magic would fail me and the spell simply wouldn't work.  This is how reality protects itself."
			*goto Legacy_New_Plan
		#"Can you kill one of Zusak's ancestors to prevent him from being born?"
			*goto Afraid_Not
		#"Can you bury some gold under this spot here?"
			"Sure, I will," the wizard says.
			
			You dig in the indicated spot and find a chest!  Your companions all get excited as you pull it free from the ground and open it.  Unfortunately, it is also empty and has a deep claw mark across the bottom of it.  The glowing ${legacy_race} shrugs.  "It was worth a try."
			*goto Legacy_New_Plan
	
	*label Legacy_New_Plan
	
	The wizard idly walks among the broken chests as ${legacy_heshe} speaks.  "T'dari is a demon from the future.  It has the ability to project itself back in time, just as I have the spell to project myself here.  The fate that I am trying to prevent is the very fate that T'dari is trying to create."

	$!{legacy_heshe} turns to face you and smiles.  "I have an idea though.  I will make an amulet of great power, and with it, I will come to you in person.  T'dari may have the power to destroy my projections and to intercede with things that I have done in the past, but it won't be able to stop me if I can create a temporal bridge to actually cross into your time stream."
	
	The shimmering ${legacy_race} walks back to the cave's entrance and looks back the way you have come.
	
	"How is the war going?  If you fail to take Ludd and Tornassa in time, all of our plans will be for nothing."
	*choice
		#"My army needs to be stronger."
			*set legacy_help "army_power"
			*goto Legacy_Must_Leave
		#"The morale of my troops needs to be better."
			*set legacy_help "army_morale"
			*goto Legacy_Must_Leave
		#"I need more soldiers."
			*set legacy_help "army_size"
			*goto Legacy_Must_Leave
		#"My troops are starving."
			*set legacy_help "army_food"
			*goto Legacy_Must_Leave
		#"We aren't moving fast enough."
			*set legacy_help "army_delays"
			*goto Legacy_Must_Leave
	
	*label Legacy_Must_Leave
	*comment legacy_help: "army_power", "army_morale", "army_size", "army_food", "army_delays"
	"I will see what I can do, ${name}," the wizard says as ${legacy_heshe} begins to fade away.  "And I will begin to work on the amulet.  Farewell.  We shall meet again!"
	
	The glowing image vanishes.  You and your companions return to the army camp where you find Lord Tovor watching the enemy from a safe distance away.
	*goto After_Legacy_Cave
*else
	*goto After_Legacy_Cave

*label After_Legacy_Cave	
 
"Why is Duke Eddan letting us fortify ourselves so well?" Lord Tovor asks.

"Ludd has no real defences," General Vale says.  "He'd be happy if we tried a siege.  Time is against us and he knows it.  We need to end this quickly."
*label Ludd_Attack_loop
*gosub Check_Army_Stats
*if ((poisoned_ludd_heard_once=false) and (poisoned_ludd))
	*set poisoned_ludd_heard_once true
	
	You wait all through the next day for some signs that the poison took effect.  Finally, as sundown approaches you hear the wails of the survivors.
	*if (eddan_dead=false)
		You hope to hear a mourning bell ring out for the dead ruler, but apparently Duke Eddan did not drink the poisoned water.
	*set ludd_army -25
	*if (showstats)
		
		(Ludd Army -25 to ${ludd_army} / 100)
*choice
	*if (show_command_army_forward)
		*allow_reuse #Command your entire army to march forward and take the city.
			*if (did_raid)
				*goto Full_Army_Fight
			*if ((army_size<=75) or (ludd_army>=50))	
				"Your Highness," General Vale says.  "We simply don't have the soldiers for such a bold move.  We need to soften them up with a few raids first."
				*if (showstats)
					(Needed 75 Army Size and Ludd Army Under 50, Currently at ${ludd_army} / 100)
				*set show_command_army_forward false
				*goto Ludd_Attack_loop
			*else
				*goto Full_Army_Fight
	#Send a raid against the city.
		*set did_raid true
		*set show_command_army_forward true
		General Vale nods at your suggestion.
		*if (squire_name="None")
			The stablemaster
		*if (squire_name!="None")
			Your squire, ${squire_name},
		brings you
		*if ((mount_name!="None") and (mount_type!="mule"))
			${mount_name}, your ${mount_type}.
			*set borrowed_horse false
			*goto Raid_1
		*else
			a horse to
			*if (mount_type="mule")
				use, since ${mount_name}, your mule, won't be able to keep up.
			*if (mount_type!="mule")
				use.
			*set borrowed_horse true
			*goto Raid_1
			
		*label Raid_1
		The general starts to say something about the fact that you intend to participate, but then stops.  He knows of your skill, and for your war campaign to succeed, he will need your participation.  It is difficult to offensively fight an army of cavalry.  You leave behind the troops on foot and bring only mounted warriors with you so you can strike hard and fast.  Unfortunately, this means that most of your demi-human allies can't help
		*if (halfling_help=1)
			you, except for the halfling outriders who are overjoyed to join you when the others can't. 
		*if (halfling_help=0)
			you.
		
		As your force breaks free of the rest of the main body of your army, you see movement within the city.  You aren't surprised to see a large group of mounted warriors rush out to confront you and your soldiers.
		*if (demonsummoner)
			Due to the mobile nature of the fight, you realize that your Demonstones won't be very helpful since none of the demons can move as fast as a horse and fight at the same time.
		*comment ludd_army min: 75 (poison)
		*choice
			#Charge to the front.
				You find yourself immediately facing the enemy soldiers, making it impossible to cast any
				*if (bow)
					spells that need range or use your bow.
				*if (bow=false)
					spells that need range.
				*if (dagger)
					Your dagger is useless too, since the enemies are all using weapons with longer reaches.
				You have no time to think as a sword narrowly swishes over your head.
				*choice
					*if ((companion_type="wolf") and (companion_name!="None")) #Tell ${companion_name}, your wolf, to attack.
						${companion_name} darts between your soldiers and begins hamstringing the enemy horses.  $!{companion_heshe} is very fast and agile and doesn't bother going for the kill, allowing ${companion_himher} to take down many enemies while your soldiers finish them off.  $!{companion_hisher} success on the battlefield makes your soldiers fight even harder.  Unfortunately, you are so intent upon watching your companion in battle that you take an arrow in the leg.
						*set ludd_army -10
						*set health -25
						*if (showstats)
							*line_break
							(Ludd Army -10 to ${ludd_army} / 100 and Health -25 to ${health} / 100)
						*goto Raid_Continued
					*if (sword) #Attack the enemy with your sword.
						Your blade flashes in the sunlight as you swing it.
						*if (blades>=70)
							Many of the bodies that topple off their horses are from your attacks as you cut at everything within reach.  Your success on the battlefield makes your soldiers fight even harder.
							*set ludd_army -10
							*if (showstats)
								*line_break
								(Blades +3 and Ludd Army -10 to ${ludd_army} / 100)
							*set blades +3
							*goto Raid_Continued
						*else
							Your blade makes contact with a few enemies during the battle.
							*set health -25
							*if (showstats)
								(Needed 70 Blades)
								*line_break
								(Health -25 to ${health} / 100)
							*goto Raid_Continued
					#Shout words of encouragement to your troops.
						*if ((charm>=60) and (army_morale>=75))
							You see your soldiers take heart from your voice as they fight with a little more energy and ferocity.  Unfortunately, this also makes you a larger target and someone hits you with an arrow in the leg.
							*set ludd_army -10
							*set health -25
							*if (showstats)
								*line_break
								(Charm +2, Health -25 to ${health} / 100 and Ludd Army -10 to ${ludd_army} / 100)
							*set charm +2
							*goto Raid_Continued
						Your words are lost among the sounds of pounding hooves and the clashing of swords on shields.  Unfortunately, an enemy archer hears you and hits you with an arrow in the leg.
						*set health -25
						*if (showstats)
							(Needed 60 Charm and 75 Army Morale)
							*line_break
							(Health -25 to ${health} / 100)
						*goto Raid_Continued
					#Cast a wall of force to clear the way in front of you.
						You would need much more room to cast any good offensive spells, like fire bolts or fireballs.  Instead, you create a sphere of energy to push your way forward through the enemy.
						*if (magic>=70)
							The soldiers are knocked to the ground allowing you and your troops to trample over them.  Your success on the battlefield causes your soldiers to fight even harder.
							*set ludd_army -10
							*if (showstats)
								*line_break
								(Magic +3 and Ludd Army -10 to ${ludd_army} / 100)
							*set magic +3
							*goto Raid_Continued
						*else
							Your shield is too weak to be very effective due to the fact that you must keep it moving in front of you.  An enemy archer manages to fire an arrow into your leg during one of these repositionings.
							*set health -25
							*if (showstats)
								(Needed 70 Magic)
								*line_break
								(Health -25 to ${health} / 100)
							*goto Raid_Continued
					*if (magic_shield) #Hide behind your magic shield as you lead the charge.
						Your presence has a great effect on your troops as they see you in the lead.  The enemy weapons bounce and shatter on your magic shield as you push forward into the fray.
						*set ludd_army -10
						*if (showstats)
							*line_break
							(Ludd Army -10 to ${ludd_army} / 100)
						*goto Raid_Continued
			#Stay safely in the middle.
				The two forces meet with a large crash.  Your troops fight well, but so do the soldiers from Ludd.
				*if (eddan_dead=false)
					You look for Duke Eddan, but don't see him among the soldiers attacking.
				The city stands behind the defenders, empty of civilians.  You suspect that the non-combatants are hiding in their houses while their soldiers guard against you. 
				*choice
					*if (bow) #Use your bow against the enemies.
						Mounted archery is very different from standing on your own two feet.  To make matters even more difficult, your soldiers are between you and the enemy and everyone is moving all over the place.
						*if (archery>=70)
							Your arrows still find their targets and many of the bodies that topple off their horses are from your attacks.  Your success on the battlefield makes your soldiers fight even harder.
							*set ludd_army -10
							*if (showstats)
								*line_break
								(Archery +3 and Ludd Army -10 to ${ludd_army} / 100)
							*set archery +3
							*goto Raid_Continued
						*else
							You still manage to knock a few enemies from their saddles.
							*if (showstats)
								(Needed 70 Archery)
							*goto Raid_Continued
					*if ((companion_type="wolf") and (companion_name!="None")) #Send ${companion_name}, your wolf, to the front of the pack.
						${companion_name} darts between your soldiers and begins hamstringing the enemy horses.  $!{companion_heshe} is very fast and agile and doesn't bother going for the kill, allowing ${companion_himher} to take down many enemies while your soldiers finish them off.  $!{companion_hisher} success on the battlefield makes your soldiers fight even harder.
						*set ludd_army -10
						*if (showstats)
							*line_break
							(Ludd Army -10 to ${ludd_army} / 100)
						*goto Raid_Continued
					*if (class_priest>0) #Pray to your ${god_goddess} for ${god_hisher} blessing.
						You call upon ${god_name} and feel ${god_hisher} blessing come down upon your troops as
						*if (god_good)
							rays of soft sunlight illuminate your allies.
						*if (god_good=false)
							dark shadows gather around your enemies.
						*if (class_priest>=2)
							It is easy for you to see the difference as the majority of those falling from their saddles are now enemy soldiers.
							*set ludd_army -10
							*if (showstats)
								*line_break
								(Religion +3 and Ludd Army -10 to ${ludd_army} / 100)
							*set religion +3
							*goto Raid_Continued
						It seems likely that there are priests among the enemy who are praying to their own Gods and Goddesses as well, since soldiers from both sides seem to be falling in equal numbers.
						*if (showstats)
							(Needed More $!{priestpriestess} Training)
						*goto Raid_Continued
					#Shoot small bolts of fire at your enemies.
						Although it would be nice to fling a large fireball at the opposing army, it is difficult because your soldiers are between you and the enemy.
						*if (magic>=70)
							Your fiery projectiles find their targets and many of the bodies that topple off their horses are from your attacks.  Your success on the battlefield makes your soldiers fight even harder.
							*set ludd_army -10
							*if (showstats)
								*line_break
								(Magic +3 and Ludd Army -10 to ${ludd_army} / 100)
							*set magic +3
							*goto Raid_Continued
						*else
							You still manage to conjure a weak fireball which topples a few enemies from their saddles.
							*if (showstats)
								(Needed 70 Magic)
							*goto Raid_Continued
					#Shout words of encouragement to your troops.
						*if ((charm>=60) and (army_morale>=75))
							You see your soldiers take heart from your voice as they fight with a little more energy and ferocity.
							*set ludd_army -10
							*if (showstats)
								*line_break
								(Charm +2 and Ludd Army -10 to ${ludd_army} / 100)
							*set charm +2
							*goto Raid_Continued
						Your words are lost among the sounds of pounding hooves and the clashing of swords on shields.
						*if (showstats)
							(Needed 60 Charm and 75 Army Morale)
						*goto Raid_Continued
					*if (lute) #Play a powerful song on your lute commending the bravery of your soldiers.
						*if (class_bard>=2)
							You see your soldiers take heart from your voice as they fight with more energy, ferocity, strength and speed.  There is no doubt that your song has actual magic in it as your enemies fall and your troops advance.
							*set ludd_army -10
							*if (showstats)
								*line_break
								(Army Morale +3 and Ludd Army -10 to ${ludd_army} / 100)
							*set army_morale +3
							*goto Raid_Continued
						Your song is mostly ignored as your soldiers fight for their lives.
						*if (showstats)
							(Needed More Bardic Training)
						*goto Raid_Continued
		
		*label Raid_Continued
		
		The mobile army you are facing becomes denser as you ride into them.  You grip
		*if (borrowed_horse)
			your borrowed horse
		*if (borrowed_horse=false)
			${mount_name}
		tightly as you crash into a wall of horses, soldiers and swords.
		*comment ludd_army min: 65 (poison and raid), health: 75 
		*choice
			*if (mount_type="forest worm") #Encourage ${mount_name}, your forest worm, to feed.
				The worm opens its gaping maw and bites off a man's arm as he tries to swing his sword at you.  ${mount_name} then ducks lower and chews ${mount_hisher} way through a horse's legs, dropping its rider to the ground.
				*label Raid_Rally
				Your army rallies around you as you break through the enemy and into the city beyond!
				*set ludd_army -10
				*if (showstats)
					*line_break
					(Army Morale +3 and Ludd Army -10 to ${ludd_army} / 100)
				*set army_morale +3
				*goto Raid_Continued_2
			*if (mount_type="Dreadhorse") #Allow ${mount_name}, your Dreadhorse, free reign.
				Waves of revulsion and fear spread from your undead mount as ${mount_heshe} leads you forward.  $!{mount_hisher} rotting hooves strike enemy soldiers down into the mud and ${mount_hisher} yellow teeth tear out chunks of flesh with abandon.  Blood runs from dozens of wounds across your mount's body from the enemy attacks, but since the Dreadhorse is already dead, they do nothing to slow ${mount_himher} down.
				*goto Raid_Rally
			*if (mount_type="crocodile") #Allow ${mount_name}, your crocodile, free reign.
				${mount_name} hadn't been very useful during the initial charge, but now that ${mount_heshe} is within biting range, it's a different story.  You see arms get torn from their sockets and horse's legs bitten clean through as ${mount_name} snaps at anything within range.  Arrows and swords bounce off ${mount_hisher} scaly hide as you push forward.
				*goto Raid_Rally
			#Push forward.
				You push
				*if (borrowed_horse)
					your borrowed horse
				*if (borrowed_horse=false)
					${mount_name}
				forward toward the enemy.
				*if ((borrowed_horse) or ((borrowed_horse=false) and (mount_level<=4)))
					Your mount struggles against the superior horses of Ludd to no avail.  You feel a sword slash across your forearm as you are pushed back.  You turn your mount and ride away with the rest of your army.
					*set health -25
					*if (showstats)
						(Needed a Stronger Mount)
						*line_break
						(Health -25 to ${health} / 100)
					*goto Raid_Failed
				*else
					Your superior mount pushes its way through the front lines and your army rallies around you as you break through the enemy and into the city beyond!
					*goto Raid_Continued_2
			#Fall back and let your soldiers lead the way.
				You hold
				*if (borrowed_horse)
					your borrowed horse
				*if (borrowed_horse=false)
					${mount_name}
				back and let your trained soldiers attempt to break through the enemy.
				The crash of horses and riders hitting each other is astounding.
				*if (army_power>=70)
					You continue to ride and find that your army has done it.  Before you know it, you are breaking through the enemy ranks and into the city beyond!
					*goto Raid_Continued_2
				*else
					You follow the others and realize that you are turning away from the enemy as their front ranks hold firm.  Before you know it, you are riding back to your camp with the rest of your troops.
					*if (showstats)
						(Needed 70 Army Power)
					*goto Raid_Failed
			*if (halfling_help=1) #Allow your halfling outriders to punch a hole through enemy lines.
				The halflings are amazingly effective in mounted combat.  Their riding dogs are much smaller than the enemy horses, but this just means that they are more agile and find it easier to stick their short swords into the bellies of the larger horses around them.  Additionally, the Ludd army has trouble reaching down to strike the quickly moving smaller targets.  You follow the halflings and before you know it, you are past the front lines.
				*goto Raid_Rally
		
		*label Raid_Failed
		
		You return to your camp.  You can tell that your troops are disheartened that they didn't break into the city itself.  You also see several riderless horses as their soldiers lay dead in the field.
		*if (showstats)
			*line_break
			(Army Size -7, Army Power -7 and Army Morale -7)
		*set army_size -7
		*set army_power -7
		*set army_morale -7
		*gosub Check_Army_Stats
		*goto Ludd_Attack_loop
		
		*label Raid_Continued_2
		*gosub Check_Army_Stats
		*comment ludd_army min: 55 (poison and 2raid), health: 50
		*choice
			#Command your army to set fire to the buildings.
				The buildings quickly catch fire under the already warm sun.  The enemy army turns around to confront you, but since they are behind you, your forward momentum keeps you relatively safe.  Your soldiers are able to cause a lot of damage as you ride through the city.  You see stores, temples, houses, barracks and marketplaces burning as your troops leave the city from another angle.  Together, you and your army ride back to camp after having executed a very successful raid.
				*set ludd_army -25
				*if (showstats)
					*line_break
					(Future Citizen Reputation -30, Army Morale +10 and Ludd Army -25 to ${ludd_army} / 100)
				*set citizen_reputation -30
				*set army_morale +10
				*set ludd_buildings_fired true
				*goto Ludd_Attack_loop
			#Command your army to kill anything that moves.
				The majority of the people on the streets are soldiers, but you see a lot of civilians getting cut down too.  As word spreads that you have reached the city itself, people run out of the safety of their homes and get killed in the fighting.  A lot soldiers of who are on foot are also killed as you spread chaos across the enemy city.  Together, you and your army ride back to camp after having executed a very successful raid.
				*set ludd_army -10
				*if (showstats)
					*line_break
					(Evil +5, Future Citizen Reputation -20, Army Morale +10 and Ludd Army -10 to ${ludd_army} / 100)
				*set good -5
				*set citizen_reputation -20
				*set army_morale +10
				*goto Ludd_Attack_loop
			#Command your army to attack only the enemy soldiers.
				The majority of the people on the streets are soldiers, but you see a lot of civilians running around too.  As word spreads that you have reached the city itself, people run out of the safety of their homes and into the streets.  Your troops avoid these unfortunate people as they kill the soldiers on foot instead.  In the chaos, you see many of your troops getting killed as they hesitate over who to attack.  Together, you and your army ride back to camp after having executed a very successful raid.
				*set ludd_army -10
				*if (showstats)
					*line_break
					(Good +5, Future Citizen Reputation +5, Army Morale +5, Army Size -5, Army Power -5 and Ludd Army -10 to ${ludd_army} / 100)
				*set good +5
				*set citizen_reputation +5
				*set army_morale +5
				*set army_power -5
				*set army_size -5
				*gosub Check_Army_Stats
				*goto Ludd_Attack_loop
	*if (eddan_dead=false) #Fly the flags of parley and send word into the city that you wish to speak to Duke Eddan.
		*set considered_parlay true
		The flags flap in the wind for about an hour before a rider comes forward to deliver a message.
		
		*if (temp_failed_assassination)
			"Duke Eddan regrets to inform you that he must decline your invitation due to a recent attempt made upon his life."
			*if (good<30)
				*choice
					#Let the messenger return safely.
						The messenger returns to Ludd after delivering his message to you.
						*goto Ludd_Attack_loop
					#Do something terrible to the messenger.
						*goto Bad_To_Messenger
			*else
				
				The messenger returns to Ludd after delivering his message to you.
				*goto Ludd_Attack_loop
		"Duke Eddan will allow you and an honour guard of no more than 10 people to come into the city under the flag of parley," the messenger says as he reads the words from a scroll.  "You will be honour bound to bring no weapons and Duke Eddan will be honour bound to return you to your camp unharmed."
		
		*if (theothea_inparty)
			"What a load of horse shit!" ${theothea_name} exclaims loudly, causing the messenger to take a step back.
			
			"Those wouldn't be my choice of words," General Vale says.  "But I agree.  These
			*goto ludd_exclamation
		*if (gillgale_inparty)
			"Eddan is an imbecile if he thinks we'll agree to that!" ${gillgale_name} exclaims loudly, causing the messenger to take a step back.
			
			"I agree" General Vale says.  "These
			*goto ludd_exclamation 
		*if (peterpetra_inparty)
			"No," ${peterpetra_name} says firmly.  "These
			*goto ludd_exclamation 
		"This isn't right," ${friend1_name} says.  "These
		*label ludd_exclamation
		terms aren't fair and aren't safe."
		*choice
			#Accept the terms without changing them.
				*set parley_location "city"
				"You can't do this!" Lord Tovor says in amazement.
				
				The messenger returns to Ludd with your answer.
				${friend1_name},
				*if (friend2_exists)
					${friend2_name},
				${friend3_name} and ${friend4_name} all strip off their weapons, intending to come with you.
				*if (prisonchild_inparty)
					${prisonchild_name} also tries to come, but your friends shoo ${prisonchild_himher} back to ${prisonchild_hisher} tent.
				Archmage Cumari, General Vale and Lord Tovor all remain behind, in case something terrible happens and a rescue is needed.  The rest of your diplomatic party is filled with soldiers.  About an hour later, you and your 10 companions are ready to ride to Ludd.
				*if (squire_name="None")
					The stablemaster
				*if (squire_name!="None")
					Your squire, ${squire_name},
				brings you
				*if (mount_name!="None")
					${mount_name}, your ${mount_type}.
					*set borrowed_horse false
					*goto Parlay_2
				*else
					a horse to use.
					*set borrowed_horse true
					*goto Parlay_2
					
				*label Parlay_2
				Together, you ride into the city and are brought to the keep.  Your soldiers and the enemy troops are all impressed at your courage.  You enter the hall where the meeting will take place and see Duke Eddan.  As always, he is wearing the most fashionable clothing and his blond hair is wavy and stylish.  He smiles at you.
				
				"You look like your
				*if (gender="male")
					father,"
				*if (gender="female")
					mother,"
				he says as you take a seat at the table.
				*goto Parlay_Options
			#Offer the same terms in reverse, promising Duke Eddan's safety.
				*set parley_location "camp"
				The messenger returns to Ludd with your answer. About an hour later, you are surprised to see ten soldiers riding toward you from the city with Duke Eddan in the middle.  Your soldiers are obviously impressed at the man's bravery.  As he gets closer, you can see more details.  As always, he is wearing the most fashionable clothing and his blond hair is wavy and stylish.  He smiles at you and raises his hands to show that he has come with no weapons, guiding his horse with his knees.
				*if (orc_help>0)
					He hardly even flinches when the half-orcs in the camp bare their fangs at him.
				
				"You look like your
				*if (gender="male")
					father,"
				*if (gender="female")
					mother,"
				he says as he dismounts and walks toward you.
				
				Your soldiers set up a tent for your use and brought out ale and food.  Duke Eddan sits down and takes a piece of bread, eating it with a smile.  You know that he is a pompous and arrogant noble.  His game is simple.  He is playing the part of the brave and benevolent leader for everyone to see.
				*temp parley_what_if false
				*temp parley_over false
				*label Parlay_Options
				*choice
					#Ask, "Why did you join Zusak and kill my parents?"
						"Your parents were holding back demon summoning from the people for their own selfish reasons," he says.  "We liberated the country.  Duke Uddo, Duke Bandar, Duchess Selina Dumain and myself took rulership upon ourselves so the people could have their freedom."
						*choice
							#Say, "Demon summoning is destroying the land!  Farms are going unharvested, there is famine and people are dying from its use."
								"Alas, it is true," he agrees.  "Growing pains, I suppose.  We keep tighter restrictions in Ludd, Tornassa and Vernex to prevent these troubles from getting out of hand."
								*choice
									#Say, "So, you have given the people the same ban that my parents had. You killed them for nothing."
										"It is more complicated than this," Duke Eddan says as he shifts uncomfortably in his seat.  "The past is behind us and we must move on."
										*goto Parlay_Options
									#Say, "You will pay for what you have done."
										*label Eddan_Will_Pay
										"Every dethroned monarch throughout history has said those words," he says. "Very few actually succeed.  The majority just live their lives and their successors eventually get dethroned.  Your family line didn't find Daria either, I'll remind you."
										*goto Parlay_Options
							#Say, "You will pay for what you have done."
										*goto Eddan_Will_Pay
							#Say, "You are lying.  Demon summoning means nothing to you!"
								Duke Eddan smiles his white teeth at you and his wavy blond hair bounces as he nods.
								
								"You're right," he says.  "I couldn't care less.  But look at me now!  From a minor noble in your parents' court to one of the most powerful people in the world!"
								*goto Parlay_Options
					#Say, "Selina killed Uddo and she will kill you next."
						"Oh, I'm certain she'll try," he says bravely, and then grins at you.  "Besides, the way I heard it, it was your assassination attempt that killed Duke Uddo and Duchess Selina bravely stepped up to give Tornassa rulership after his death.  She was lucky the ${prisoner1_nickname} was there to save her."
						
						He laughs at his own words, knowing full well that you had no part in the assassination and that Selina had killed Uddo to expand her own holdings.
						*goto Parlay_Options
					#Say, "You need to surrender Ludd to me."
						"Why would I ever do that?" the blond duke says with a laugh.  "Tornassa lies a short distance north and Duchess Selina's army is much larger than yours.  Together, we will crush you."
						*choice
							#Say, "Even if you are right, I can still take Ludd before Selina can stop me.  Surrender now and I'll let you live."
								*if (((charm>=90) and (army_size>=70)) and (ludd_army<100))
									You see Duke Eddan's smile leave his face as he truly considers your words for the first time.  He knows that you aren't bluffing.  He releases a big sigh and then nods.
									*if (showstats)
										(Charm +3)
									*set charm +3
									
									"Very well," he says.  "But I want free passage out of Daria for me and my family."
									*choice
										#Agree to his terms.
											The now former duke reaches out and shakes your hand.  Scribes are called for and everything is put on paper.
											*if (parley_location="camp")
												You come out of the tent and pass the news on to your army.
											*if (parley_location!="camp")
												You leave Ludd without harm and return to your army to tell them the news.
											They cheer as they realize that they won't have to fight.  Many of them have friends in Ludd and the idea of fighting someone they know had been haunting them during the entire march.
											
											The people of Ludd clearly share this  feeling as your army is welcomed into the city with open arms.
											*if (ludd_buildings_fired)
												The blackened ruins of your raid is like a black-eye on the face of the peace you have wrought, but peace is still peace. 
											All over the city, you hear cheering and applause as you move your personal belongings into the keep.
											*goto Ludd_Victory
										#Deny his terms.
											"Then no," Duke Eddan says.  "We do not have a deal.  And furthermore, I will deny that I even considered such an offer.  I think we are done here.  Good day."
											*set parley_over true
											*goto Parlay_Options
								*else
									"I'd rather have you angry with me than Duchess Selina," the blond duke says.  "I believe we are done here.  Good day."
									*set parley_over true
									*if (showstats)
										(Needed 90 Charm, 70 Army Size and Ludd Army Under 100)
									*goto Parlay_Options
							#Say, "I will take Ludd from you whether you want me to or not."
								"You will try," the blond duke says.  "But we will stop you.  I believe we are done here.  Good day."
								*set parley_over true
								*goto Parlay_Options
					#Ask, "What's to stop me from killing you right now?"
						*set parley_what_if true
						*if (parley_location="camp")
							"We're under the banner of parley," he says smugly.  "We invoked the divine names of Lucien and Auriel.  You can't.  You are bound by honour."
							*goto Parlay_Options
						"You are in the middle of my city," he says smugly.  "You'd never make it out of here alive.  Besides, we invoked the divine names of Lucien and Auriel.  You can't.  You are bound by honour."
						*goto Parlay_Options
					*if ((parley_location="camp") and (parley_what_if)) #Command your soldiers to fill Eddan full of arrows and throw his body back into the city.
						He laughs at first, until he realizes that you are completely serious.
						
						"What?!" he says in shock as your soldiers drag him outside.  "NO!  YOU CAN'T DO THIS!"
						
						His yelling becomes unintelligible as the third arrow strikes him.  After the sixth arrow, he stops his whimpering.  You can't even count how many arrows fill his sorry-looking carcass.  Your army cheers as they drag his arrow-ridden body around the camp a few times before cutting it loose in front of the city.  General Vale frowns, but says nothing.
						*if (peterpetra_inparty)
							Even ${peterpetra_name} is silent as one of your parents' murderers is killed.
						*if (showstats)
							*line_break
							(Evil +20, Army Morale +5 and Citizen Fear +15)
						*set good -20
						*set army_morale +5
						*set citizen_fear +15
						*set eddan_dead true
						*set eddan_betrayed true
						*goto Ludd_Attack_loop
					*if ((parley_over) and (parley_location="camp")) #Allow Duke Eddan to return to Ludd.
						The duke and his 10 guards leave the tent and get back on their horses.  They ride back to Ludd as your companions talk among themselves.
						*goto Ludd_Attack_loop
					*if ((parley_over) and (parley_location="city")) #Leave Ludd and return to your camp.
						The duke doesn't stop you as you and your companions leave the keep.  You get back onto your mounts and ride toward your camp.
						*if ((citizen_reputation>=50) and (citizen_fear<10))
							You can practically hear the sound of every person in your army sighing in relief at your safe return.  An impromptu applause spreads as you enter your camp.
							*if (showstats)
								*line_break
								(Army Morale +5)
							*set army_morale +5
							*goto Ludd_Attack_loop
						You see your soldiers nodding to themselves upon your return.  They don't question your bravery, even if they don't have a great love for you.
						*if (showstats)
							(Needed 50 Citizen Relationship and Under 10 Citizen Fear)
						*goto Ludd_Attack_loop
			#Say, "Tell Eddan that he can cram his terms up his…."
				The messenger nods at your words and you can hear your soldiers chuckling around you.  The man gets back onto his horse and rides back to Ludd with your not-so-friendly message.
				*if (showstats)
					*line_break
					(Army Morale +3)
				*set army_morale +3
				*goto Ludd_Attack_loop
			#Do something terrible to the messenger.
				*label Bad_To_Messenger
				The purpose of a messenger is to convey a message.  Not all messages involve words.
				*choice
					#Send the messenger's head back to Ludd.
						The bloody offering is a clear message to Duke Eddan and anyone else who would betray you, as he did to your parents.  Your troops clearly don't like it, since they relate more with the dead messenger than with you, but that doesn't take away its effectiveness.
						*if (showstats)
							*line_break
							(Evil +20 and Citizen Fear +10)
						*set good -20
						*set citizen_fear +10
						*goto Ludd_Attack_loop
					#Work some terrible magic upon the man and force him to go back and kill Duke Eddan.
						The spells of mental domination are considered more foul than Soulburning and demon summoning combined.  It's on par with necromancy, since it takes away a person's free will.  Some even think it is more evil, since it can force a person to do things that may damn their immortal soul.
						*if ((magic>=90) and (arcana>=60))
							The messenger has to be held down while you work the ritual over him.  When you release him, he is your puppet.
							*if (showstats)
								*line_break
								(Evil +30,  Magic +2 and Citizen Fear +15)
							*set good -30
							*set magic +2
							*set citizen_fear +15
							
							The messenger returns to Ludd to tell Duke Eddan what you told him.  You don't see it happen, but you have no doubt that Duke Eddan is terribly surprised when his trusted servant thrusts a dagger into his eye.  One of the people responsible for the murders of your parents is now dead.  It won't stop the need to take the city, but perhaps it will make it a little easier.
							*set eddan_dead true
							*goto Ludd_Attack_loop
						Unfortunately, the spell doesn't take.  The man dies during the ritual before the domination takes hold.  Perhaps you can send your enemy his head after all?  Either way, you have killed Duke Eddan's messenger and have sent him a message yourself.
						*if (showstats)
							(Needed 90 Magic and 60 Arcana)
							*line_break
							(Evil +30 and Citizen Fear +15)
						*set good -30
						*set citizen_fear +15
						*goto Ludd_Attack_loop
					#Beat the man senseless and send him back to Ludd.
						The bloody babbling messenger is a clear signal to Duke Eddan and anyone else who would betray you, as he did to your parents.  Your troops clearly don't like it, since they relate more with the injured messenger than with you, but that doesn't take away its effectiveness.
						*if (showstats)
							*line_break
							(Evil +10 and Citizen Fear +10)
						*set good -10
						*set citizen_fear +10
						*goto Ludd_Attack_loop
	*if (eddan_dead=false) #Hire an assassin to kill Duke Eddan.
		*if (class_assassin>0)
			As part of the Guild of Assassins, you know how to contact a fellow member.
		*if (class_assassin=0)
			You discreetly ask a few people about the Guild of Assassins and wait for word to reach them.		
		It doesn't take long before a man comes to you.  It's interesting to know that there are members within your army, but not surprising.  He likely is an actual soldier who makes some money on the side by passing messages through the Guild.  You tell him that the mark is Duke Eddan.  It takes several hours before he returns with a reply.
		
		"It can be done," he says.
		*choice
			*if (temp_failed_assassination)
				*selectable_if (gold>=500) #Give the man the 500 gold to have Duke Eddan killed.  (Needs 500 Gold)
					He explains to you that there was already an attempt on the duke's life, so the price is higher than it normally would be.
					*if (poison_attempt)
						You suspect that this was when you were caught attempting to poison the water supply.
					You pay the man and he leaves, seeming to simply return to the camp and his tent.  You suspect that he will pass the gold and message on to another set of hands and another and so on.  You also suspect that a message will be sent to a contact in Ludd.  Whether it is magically sent, or simply a series of light flashes from a reflective surface, you don't know.  Either way, the message will spread into Ludd and be offered to hidden assassins within the city.
					*if (showstats)
						*line_break
						(Gold -500)
					*set gold -500
					*goto Someone_Else_Tries
			*if (temp_failed_assassination=false)
				*selectable_if (gold>=300) #Give the man the 300 gold to have Duke Eddan killed.  (Needs 300 Gold)
					You pay the man and he leaves, seeming to simply return to the camp and his tent.  You suspect that he will pass the gold and message on to another set of hands and another and so on.  You also suspect that a message will be sent to a contact in Ludd.  Whether it is magically sent, or simply a series of light flashes from a reflective surface, you don't know.  Either way, the message will spread into Ludd and be offered to hidden assassins within the city.
					*if (showstats)
						*line_break
						(Gold -300)
					*set gold -300
					*label Someone_Else_Tries
					
					"The garden has been weeded," a different man says to you in passing.
					
					You know that this means that Duke Eddan is dead.  The city still has an army and some commander is still running things over there, but the man responsible for helping Zusak to murder your parents is gone.
					*set eddan_dead true
					*goto Ludd_Attack_loop
			#Tell the man that you have decided to not place a mark on the duke's head.
				The man nods and leaves.  You assume that he will pass the information through a long and complicated chain of messengers until it reaches the Guild headquarters, wherever that may be.
				*goto Ludd_Attack_loop
	*if (eddan_dead) #Fly the flags of parley and send word that you wish to speak to whoever rules the city now that Duke Eddan is dead.
		An arrow is shot toward your army an hour later.  You can see that a white ribbon has been tied to the end to get your attention.  You send a runner for the arrow and he retrieves the message that is attached to it.
		
		"We will not surrender.  Leave and we will let you go."
		
		"Whoever rules the city now is taking the easy way out," General Vale comments.  "They are likely hoping that we will leave them, now that Duke Eddan is dead.  But we can't.  They would ride against our unprotected rear while we are attempting to siege Tornassa.  We must finish what we have begun."
		*goto Ludd_Attack_loop
	#Continue building defences and raid the surrounding countryside for food.
		*set ludd_defences_food_dealt_with true
		There are a few farms with grazing animals surrounding Ludd.  You manage to bring in some cattle, sheep and horses.  Your low walls become larger and you add more sharpened spears to your perimeter.  Any cavalry charge against your position would cost your attackers dearly.
		*if (showstats)
			*line_break
			(Army Food +10, Army Power +5 and Army Delays +1)
		*set army_food +10
		*set army_power +5
		*set army_delays +1
		*goto Ludd_Attack_loop
	*if (poison_package) #Wait until the still of night and then attempt to enter Ludd and poison the water system.
		*if ((temp_failed_assassination) and (eddan_dead=false))
			Unfortunately, the sentries are all wide awake with their torches lit.  They are still on high alert from when you entered Ludd and botched the assassination attempt on Duke Eddan.
			*goto Ludd_Attack_loop
		*set poison_attempt true
		*goto Sneak_Ludd
	*if (eddan_dead=false) #Wait until the still of night and then attempt to enter Ludd and assassinate Duke Eddan.
		*label Sneak_Ludd
		*if ((class_assassin>0) and (poison_attempt=false))
			As a member of the Guild, this is exactly the type of job which you have always wanted.
		You wait until it is very dark and then you attempt to sneak into the city.  You decide to leave your friends behind, knowing that extra bodies will only mean more of a chance to be discovered.
		*if (stealth<60)
			Unfortunately, as you approach, one of the sentries sees you and calls out.  Soon there are many torches lit.  You return quickly to your own camp, realizing that a city under siege is extremely difficult to sneak into.
			*if (showstats)
				(Needed 60 Stealth)
			*goto Ludd_Attack_loop
		
		You manage to sneak into the city without being detected.
		*if (poison_attempt)
			Under the cover of darkness, there is nobody to stop you.  You drop the package into the city well system and watch as it quickly dissolves into the water.  You return back to your camp and wait to see what happens.
			*if (showstats)
				*line_break
				(Stealth +2)
			*set stealth +2
			*set poisoned_ludd true
			*set poison_package false
			*set poison_attempt false
			*goto Ludd_Attack_loop
		*if (poison_package)
			You realize that now that you are in the city, you could drop the poison package into the city well.  It is only fair, considering that the ${prisoner1_nickname} and ${prisoner1_hisher} strike force were planning to do the same to you in Brightwater.
			*choice
				#Poison the wells.
					Under the cover of darkness, there is nobody to stop you.  You drop the package into the city well system and watch as it quickly dissolves into the water.
					*set poisoned_ludd true
					*set poison_package false
					
					*goto Assassin_Keep
				#Don't poison the wells.
					*goto Assassin_Keep
		*label Assassin_Keep
		You head to the keep, knowing that this is where the duke will be staying.  Compared to how difficult it was to sneak across an open plain filled with scouts, entering the keep is easy.  Unfortunately, you find yourself at the duke's door which is locked up tight for the night.
		*if (showstats)
			*line_break
			(Stealth +2)
		*set stealth +2
		*label Eddan_Door
		*choice
			#Knock on the door and pretend to be a servant.
				The duke asks you your name through the door.  Considering that his city is at siege, it isn't surprising to see that he is being extra cautious.  He would have no clue that you would try to come yourself, but after the false rumours spread that Duke Uddo was killed by one of your assassins, his precautions are justified.
				*if (charm<60)
					You answer as best as you can, but he continues with several personal questions.  After a few minutes, he starts yelling for the guards.
					*if (showstats)
						(Needed 60 Charm)
					
					You rush back the way you came and flee out of the city before you are caught.  The sentries don't see you at all.  You realize that the duke will have even more safety precautions after tonight.
					*set temp_failed_assassination true
					*goto Ludd_Attack_loop
				You make up answers as you go, and surprisingly, the duke opens the door!  The moment he sees that you aren't who you claimed to be, he draws his sword.
				*if (showstats)
					*line_break
					(Charm +2)
				*set charm +2
				*goto Assassin_Duke_Eddan
			#Pick the lock and enter.
				*if (lockpickset=false)
					Unfortunately, without a lockpick set, you have no chance of getting the door open.
					*goto Eddan_Door
				*if (devices<50)
					The door's lock is beyond your skill and you are unable to open it.
					*if (showstats)
						(Needed 50 Devices)
					*goto Eddan_Door
				The door opens quietly, allowing you to enter.  Unfortunately, the duke is wide awake and draws his sword.
				*if (showstats)
					(Devices +2)
				*set devices +2
				*goto Assassin_Duke_Eddan
			*if (ki_strike) #Smash open the door with a Ki Strike.
				You concentrate and feel the power build in your fist.  You strike forth and your hand goes right through the door!  Unfortunately, you are still unable to open the door or pass through the small hole you made.  Your only hope now is to batter down the door.
				*goto Ludd_Batter_Door
			#Attempt to knock down the door.
				*label Ludd_Batter_Door
				*if (strength<70)
					You smash into the door several times, but it holds firm.  You know that you must leave as the guards begin to shout and rush toward you.  Amazingly, you manage to get back to your own camp.
					*if (showstats)
						(Needed 70 Strength)
					*set temp_failed_assassination true
					*goto Ludd_Attack_loop
				The door breaks open.  As you stumble into the room, you see Duke Eddan with his sword in his hand waiting for you.
				*if (showstats)
					*line_break
					(Strength +2)
				*set strength +2
				*goto Assassin_Duke_Eddan
			*if ((cloak_of_spiders=false) and (thiefharness=false)) #Climb up the wall to the duke's window from the outside.
				*if (rope=false)
					You carefully climb the wall using no ropes.
					*if (agility>=75)
						*label Success_Climb_Agility
						You climb up the wall to the window high above with no trouble.  Unfortunately, as you step into the duke's room, you see that he is awake and holding a sword!
						*if (showstats)
							*line_break
							(Agility +2)
						*set agility +2
						*goto Assassin_Duke_Eddan
					*else
						No matter how hard you try, you can't seem to get the knack of climbing the wall without a rope.
						*if (showstats)
							(Needed 75 Agility)
						*goto Eddan_Door
				You use your rope to help you climb the wall.
				*if (agility>=45)
					*goto Success_Climb_Agility
				*else
					Unfortunately, even with the rope, you can't seem to get very far off the ground.
					*if (showstats)
						(Needed 45 Agility)
					*goto Eddan_Door
			*if (cloak_of_spiders) #Use the Cloak of Spiders to enter the duke's window from the outside.
				*goto Climb_In
			*if (thiefharness) #Use your thief harness to enter the duke's window from the outside.
				*label Climb_In
				You climb up the wall to the window high above with no trouble.  Unfortunately, as you step into the duke's room, you see that he is awake and holding a sword!
				*goto Assassin_Duke_Eddan
			#Return to your camp without killing the duke.
				You successfully sneak past the sentries and return to your army camp.
				*set temp_failed_assassination false
				*goto Ludd_Attack_loop

		*label Assassin_Duke_Eddan
		
		His blond hair bounces as he shifts his weight from foot to foot.  He holds his sword in the proper position, showing you that he knows how to use it.
		*choice
			*if (sword) #Attack the duke with your sword.
				The duke is an above average swordsman
				*if (blades>=60)
					but you are even better which means that you are able to kill him quickly before the guards are called.  He falls to the ground, clutching the red hole you made in his chest.
					*if (showstats)
						*line_break
						(Blades +2)
					*set blades +2
					*goto Assassin_Duke_Eddan_Success
				*else
					and much better with the blade than you are.  He manages to cut you a few times as he yells for the guards.  You barely escape the keep and the city with your life as you rush back to your own camp.
					*set health -25
					*if (showstats)
						(Needed 60 Blades)
						*line_break
						(Health -25 to ${health} / 100)
					*set temp_failed_assassination true
					*goto Ludd_Attack_loop
			*if (dagger) #Attack the duke with your dagger.
				Your dagger is much less effective than the longer reach of the duke's blade.  Duke Eddan is an above average swordsman
				*if (blades>=80)
					but your skill with the short blade is even better, which means that you are able to kill him quickly before the guards are called.  He falls to the ground, clutching the red hole you made in his chest.
					*if (showstats)
						*line_break
						(Blades +2)
					*set blades +2
					*goto Assassin_Duke_Eddan_Success
				*else
					and much better with the blade than you are.  He manages to cut you a few times as he yells for the guards.  You barely escape the keep and the city with your life as you rush back to your own camp.
					*set health -25
					*if (showstats)
						(Needed 80 Blades)
						*line_break
						(Health -25 to ${health} / 100)
					*set temp_failed_assassination true
					*goto Ludd_Attack_loop
			*if (bow) #Try to shoot the duke with an arrow.
				Your close proximity makes using the bow very
				*if (archery>=80)
					difficult, but you are an excellent archer.  You quickly release the arrow from very close range, killing him before the guards are called.  He falls to the ground, clutching the arrow protruding from his chest.
					*if (showstats)
						*line_break
						(Archery +2)
					*set archery +2
					*goto Assassin_Duke_Eddan_Success
				*else
					difficult.  He manages to cut you a few times as he yells for the guards.  You barely escape the keep and the city with your life as you rush back to your own camp.
					*set health -25
					*if (showstats)
						(Needed 80 Archery)
						*line_break
						(Health -25 to ${health} / 100)
					*set temp_failed_assassination true
					*goto Ludd_Attack_loop
			#Rush forward and try to snap the duke's neck with your hands.
				The duke's sword makes getting close to him extremely
				*if (unarmed>=90)
					difficult, but you are very talented.  You get past his blade and behind him.  Once you have his head in your arms, the battle is finished.  With a twist and a snap, the duke falls to the ground dead.
					*if (showstats)
						*line_break
						(Unarmed +2)
					*set unarmed +2
					*goto Assassin_Duke_Eddan_Success
				*else
					difficult.  He manages to cut you a few times as he yells for the guards.  You barely escape the keep and the city with your life as you rush back to your own camp.
					*set health -25
					*if (showstats)
						(Needed 90 Unarmed)
						*line_break
						(Health -25 to ${health} / 100)
					*set temp_failed_assassination true
					*goto Ludd_Attack_loop
			*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl and command the demon to kill the duke.
				*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
				*comment: Pt.2, Min 45
				Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
				
				*if (willpower>=60)
					"Yes, ${mastermistress}," Brahl says with a grin as it approaches the duke.
					
					The demon takes a few serious cuts from Eddan's blade before closing the distance and raking its claws into the duke's stomach.  The moment Eddan falls onto his back and drops his sword, the outcome of the match is decided as Brahl tears into him with teeth and claws.  The bloody corpse left behind barely even resembles the duke any more.  With its task complete, Brahl returns to the demon realm.
					*goto Assassin_Duke_Eddan_Success
				*else
					It sees the way the duke holds the blade and backs away.
					
					"No, he looks like he knows what he's doing," it says as the contest of wills is rejoined and the brawny demon pops out of existence.
					*if (showstats)
						(Needed 60 Willpower)
					
					Duke Eddan uses the time to yell for the guards.  You realize that you have lost your opportunity and barely escape back your own camp without getting hurt.
					*set temp_failed_assassination true
					*goto Ludd_Attack_loop
			#Cast a spell to create an acid splash.
				The spell's words tumble from your lips as a large glob of sticky acid forms in the air hovering over your palm.  You throw it at the duke who manages to
				*if (magic>=80)
					partially block it with his blade.  It melts the iron and then it melts his face.  He falls to the ground screaming as it burns him into a sticky pile of goo.
					*if (showstats)
						*line_break
						(Magic +2)
					*set magic +2
					*goto Assassin_Duke_Eddan_Success
				*else
					deflect it away from him with his blade!  He advances forward and cuts you a few times as he yells for the guards.  You barely escape the keep and the city with your life as you rush back to your own camp.
					*set health -25
					*if (showstats)
						(Needed 80 Magic)
						*line_break
						(Health -25 to ${health} / 100)
					*set temp_failed_assassination true
					*goto Ludd_Attack_loop
					
		*label Assassin_Duke_Eddan_Success
		You manage to return to your camp without being seen.  You can hardly believe that Duke Eddan is dead.  He was one of those responsible for the murder of your parents, and now he is gone!  The city still needs to be taken, but you are one step closer to achieving that goal now that its ruler is gone.
		*set eddan_dead true
		*goto Ludd_Attack_loop
	*allow_reuse #Gather your advisers and discuss strategy.
		General Vale, Lord Tovor, Archmage Cumari, ${friend1_name},
		*if (friend2_exists)
			${friend2_name},
		${friend3_name}, Naistalan the half-elf,
		*if (dwarf_help>0)
			Kergith the dwarf,
		*if (orc_help>0)
			Gurstwin the half-orc,
		*if (gnome_help>0)
			Runyan the gnome,
		*if (halfling_help>0)
			Yam the halfling,
		Captain ${branbrinn_name} and all of your commanders gather in the command tent.  A large map of Ludd is placed on the table with small wooden markers used to represent where your troops are.  General Vale has been telling you where to place the archers, pikemen and cavalry since before you even left Brightwater.  Now that you are within sight of Ludd and your scouts have given you updated information, his suggestions have become even more precise.
		*if (ludd_defences_food_dealt_with=false)
			
			"We need food," Lord Tovor says.  "We should continue to build our defences and raid the plains around us."
		*if (did_raid=false)
			
			"We need to soften them up a bit," General Vale says.  "We should send a raid."
		*if ((considered_parlay=false) and (eddan_dead=false))
			
			"You should speak to the duke," Archmage Cumari says.  "Perhaps he will surrender without a fight?"
		*if ((did_raid) and (considered_parlay))
			
			"It's time to attack," General Vale says.  "We must win decisively and quickly."
		*if ((eddan_dead=false) and (orc_help>0))
			
			"Kill Eddan," Gurstwin says as she slams her fist on the table.  "Cut the head off the snake!!"
		
		The conversations around the table continue for many hours as everyone gives their ideas and suggestions.
		*goto Ludd_Attack_loop

*label Full_Army_Fight
*comment ludd_army min: 30 (poison and 3raid/2raid+fire), health: 50
*comment No spaces needed
*label FlipAgain
*rand coinflip 1 4
*if ((friend2_exists=false) and (coinflip=2))
	*goto FlipAgain
*if (coinflip=1)
	*set currentfriend_name friend1_name
	*set currentfriend_hisher friend1_hisher
	*set currentfriend_heshe friend1_heshe
	*set currentfriend_himher friend1_himher
*if (coinflip=2)
	*set currentfriend_name friend2_name
	*set currentfriend_hisher friend2_hisher
	*set currentfriend_heshe friend2_heshe
	*set currentfriend_himher friend2_himher
*if (coinflip=3)
	*set currentfriend_name friend3_name
	*set currentfriend_hisher friend3_hisher
	*set currentfriend_heshe friend3_heshe
	*set currentfriend_himher friend3_himher
*if (coinflip=4)
	*set currentfriend_name friend4_name
	*set currentfriend_hisher friend4_hisher
	*set currentfriend_heshe friend4_heshe
	*set currentfriend_himher friend4_himher
You know that you can't stay where you are indefinitely, since you will run out of food.  Once you get into the city, the mounted enemy will lose their advantage of mobility.  The tough part will be crossing the no-man's-land between your camp and the city itself.  It is time for an all-out fight.  Your troops know what is at stake and are ready to take the city.
*if (squire_name="None")
	The stablemaster
*if (squire_name!="None")
	Your squire, ${squire_name},
brings you
*if ((mount_name!="None") and (mount_type!="mule"))
	${mount_name}, your ${mount_type}.
	*set borrowed_horse false
	*goto Full_Army_Fight_2
*else
	a horse to
	*if (mount_type="mule")
		use, since ${mount_name}, your mule, won't be able to keep up.
	*if (mount_type!="mule")
		use.
	*set borrowed_horse true
	*goto Full_Army_Fight_2
*label Full_Army_Fight_2
*gosub Check_Army_Stats

*if (friend1_name=theothea_name)
	${theothea_name} grins at you in excitement, clutching ${theothea_hisher} large hammer eagerly in ${theothea_hisher} hands.
*if (friend1_name=gillgale_name)
	${gillgale_name} gives you a wink as ${gillgale_heshe} holds a sword in each hand.
*if (friend1_name=peterpetra_name)
	${peterpetra_name} nods at you as ${peterpetra_heshe} checks over ${peterpetra_hisher} equipment.
*if (friend1_name=karlkarla_name)
	${karlkarla_name} gives you a weak smile as ${karlkarla_heshe} checks over ${karlkarla_hisher} equipment.
*if (friend1_name=jacejess_name)
	${jacejess_name} flips ${jacejess_hisher} hair out of ${jacejess_hisher} eyes as ${jacejess_heshe}  looks toward you.
*if (prisonchild_inparty)
	${prisonchild_name} will remain behind with Lord Tovor, 
*if (prisonchild_inparty=false)
	Lord Tovor will remain behind with
*if (class_tattooist>0)
	${tattooist_name},
the cooks, smiths and other camp followers.  You see
*if (friend2_exists)
	${friend3_name} and ${friend2_name}
*if (friend2_exists=false)
	${friend3_name}
speaking to ${branbrinn_name} nearby as well.  General Vale and Archmage Cumari are fully equipped and ready to ride into battle at your side.
*choice
	#Charge the city quickly.
		Your troops rush forward wildly, those with pikes leading the way.  Those with regular swords stand behind the pikemen, ready to kill anyone who breaks through.  Your cavalry ride at both sides of your main force, hoping to funnel the enemy into the centre while your archers follow last, planning to fire over your soldiers and into the enemy ranks.  The troops from Ludd surge forth from their city to meet you, their horses eating up the distance quickly.  The elves unleash a barrage of arrows that drop a few of the charging soldiers.  With a great crash, both sides meet as the true battle for Ludd begins.  During the chaos, a spear cuts a long gash across your side.
		*if (army_size<30)
			*if (ludd_army<=50)
				It is a good thing that you have already inflicted some injuries on the enemy, since your own army is so small.  You break through the front line, splitting the enemy force in two.
				*set ludd_army -20
				*set health -25
				*if (showstats)
					(Needed 30 Army Size)
					*line_break
					(Army Size -15, Army Power -10, Ludd Army -20 to ${ludd_army} / 100 and Health -25 to ${health} / 100)
				*set army_size -15
				*set army_power -10
				*goto Full_Army_Fight_3
			*else
				Your small army is nearly overwhelmed by the numbers alone.  You still manage to split the enemy force in two as you strike into their numbers like a small dagger into a big belly.
				*set ludd_army -10
				*set health -25
				*if (showstats)
					(Needed 30 Army Size and Ludd Army 50 or Under)
					*line_break
					(Army Size -15, Army Power -10, Ludd Army -10 to ${ludd_army} / 100 and Health -25 to ${health} / 100)
				*set army_size -15
				*set army_power -10
				*goto Full_Army_Fight_3
		*else
			*if (ludd_army<=50)
				You are glad that you have inflicted some casualties on the enemy army before engaging them.  It makes smashing through their forces a little easier as you split their defences in two while driving toward the city.
				*set ludd_army -25
				*set health -25
				*if (showstats)
					(Army Size -15, Army Power -10, Ludd Army -25 to ${ludd_army} / 100 and Health -25 to ${health} / 100)
				*set army_size -15
				*set army_power -10
				*goto Full_Army_Fight_3
			*else
				Both sides are very evenly matched.  You still manage to split the enemy force in two as you drive toward the city.
				*set ludd_army -15
				*set health -25
				*if (showstats)
					(Needed Ludd Army 50 or Under)
					*line_break
					(Army Size -15, Army Power -10, Ludd Army -15 to ${ludd_army} / 100 and Health -25 to ${health} / 100)
				*set army_size -15
				*set army_power -10
				*goto Full_Army_Fight_3
	#Approach the city cautiously.
		Your soldiers get well prepared before the final march into the city.  Those with pikes stand on the outside and those with swords stand behind them, ready to kill anyone who breaks through.  Your cavalry ride at both sides of your main force, hoping to funnel the enemy into the centre while your archers follow last, planning to fire over your troops and into the enemy ranks.   The soldiers from Ludd rush forth from their city to meet you the moment you leave your fortifications, their horses eating up the distance quickly.  The elves unleash a barrage of arrows that drop a few of the charging soldiers.  With a great crash, both sides meet as the true battle for Ludd begins.
		*if (army_size<30)
			*if (ludd_army<=50)
				It is a good thing that you have already inflicted some injuries on the enemy, since your own army is so small.  You push inexorably forward and into the city.
				*if (showstats)
					(Needed 30 Army Size)
					*line_break
					(Army Size -3 and Army Power -3)
				*set army_size -3
				*set army_power -3
				*goto Full_Army_Fight_3
			*else
				Your small army is nearly overwhelmed by the numbers alone.  You still manage to push inexorably forward and into the city.
				*if (showstats)
					(Needed 30 Army Size and Ludd Army 50 or Under)
					*line_break
					(Army Size -5 and Army Power -5)
				*set army_size -5
				*set army_power -5
				*goto Full_Army_Fight_3
		*else
			*if (ludd_army<=50)
				You are glad that you have inflicted some casualties on the enemy army before engaging them as you push inexorably forward and into the city.
				*set ludd_army -10
				*if (showstats)
					(Army Size -5, Army Power -5 and Ludd Army -10 to ${ludd_army} / 100)
				*set army_size -5
				*set army_power -5
				*goto Full_Army_Fight_3
			*else
				Both sides are very evenly matched.  You still manage to push inexorably forward and into the city.
				*set ludd_army -5
				*if (showstats)
					(Needed Ludd Army 50 or Under)
					*line_break
					(Army Size -5, Army Power -5 and Ludd Army -5 to ${ludd_army} / 100)
				*set army_size -5
				*set army_power -5
				*goto Full_Army_Fight_3
		
*label Full_Army_Fight_3
*gosub Check_Army_Stats

*comment ludd_army min: 5 (poison and 3raid/2raid+fire, last push), health: 25
The enemy fills in behind you on the outskirts of the city.
*if (squire_name!="None")
	You see ${squire_name} fighting on horseback a short distance away.
*if ((borrowed_horse) or (mount_level<=4))
	The press of bodies around you makes it difficult to fight.  Suddenly, you feel something solid crashing against your side and you are thrown off your mount!
	*set health -25
	*if (showstats)
		(Needed Mount Level 5 or Greater)
		*line_break
		(Health -25 to ${health} / 100)
	*if (health<=0)
		*goto Full_Army_KnockOut
	
	*label Full_Army_OnFoot
	The battle is even more chaotic and life threatening as you lay in the trodden dirt with hooves crashing all around you.  You get up and try to orientate yourself.
	*choice
		*if (sword) #Draw your sword and fight your way to the city.
			You swing at the enemies around you.  There is little skill needed in such close quarter fighting as you push your way into the city and rejoin your soldiers.
			*if (showstats)
				(Blades +2)
			*set blades +2
			*goto Full_Army_Fight_4
		#Cast a Fire Shield on yourself.
			*if (magic<30)
				The shield is weak, but the flicking flames are still enough to make the enemy soldiers nervous.
			*if (magic>=30)
				The flaming shield only feels warm to you, but those who bump into you receive terrible burns.
			Everyone gives you a little room, which you take advantage of as you run into the city to rejoin your soldiers.
			*if (showstats)
				(Magic +2)
			*set magic +2
			*goto Full_Army_Fight_4
		#Push your way into the city.
			You push and shove your way through the bodies.  With some luck, you manage to get into the city and rejoin your soldiers.
			*if (showstats)
				(Strength +2)
			*set strength +2
			*goto Full_Army_Fight_4
		#Dodge your way into the city.
			You dodge and weave your way through the bodies.  With some luck, you manage to get into the city and rejoin your soldiers.
			*if (showstats)
				(Agility +2)
			*set agility +2
			*goto Full_Army_Fight_4
*else
	${mount_name} carries you safely through the remainder of the no-man's-land and into the city.  Your troops take advantage of the buildings as they set up a defensive stance.  You dismount your ${mount_type} and hand the reins to
	*if (squire_name!="None")
		${squire_name}, who has also made it safely into the city.
	*if (squire_name="None")
		a waiting soldier.
	*goto Full_Army_Fight_4

*label Full_Army_Fight_4
*gosub Check_Army_Stats

*set temp_lost_companions true
*comment Currentfriend set earlier for rand error fix.
You look around to see who else made it.  You spot ${currentfriend_name}
*if (cumari_gotstaff)
	nearby, as well as Archmage Cumari,
*if (cumari_gotstaff=false)
	nearby,
but that is all.  You hope that General Vale and the others are okay, but there is no time to search for them.

"Your Highness!" a soldier yells from nearby.  "We are storming the keep!"

*if (cumari_gotstaff)
	You, Archmage Cumari
*if (cumari_gotstaff=false)
	You
and ${currentfriend_name} are rushed along with the soldiers until you are standing before the large fortified doors of the keep.  You can see the enemy soldiers in the upper windows exchanging arrows with your soldiers on the ground.  In the distance, the sound of fighting around the outskirts of the city tells you that the battle is still raging.
*if (eddan_dead=false)
	High up in one of the battlements, you see the unmistakable yellow of Duke Eddan's blond hair as he shouts orders at his soldiers.
*label Keep_loop
*gosub Check_Army_Stats
*choice
	*if (((eddan_dead=false) and (currentfriend_name=karlkarla_name)) and (infinity_arrow)) #Tell ${karlkarla_name} to shoot the duke with the Infinity Arrow.
		${karlkarla_name} nods at your words.  You watch as ${karlkarla_heshe} puts the magical arrow to ${karlkarla_hisher} string and releases.  It soars unerringly upward and between the enemy soldiers, striking Duke Eddan in the eye.  The dead duke tumbles off the battlement and one of his commanders begins to shout orders in his place.  You have no time to relish the fact that one of the people responsible for killing your parents is now dead.
		*set infinity_arrow false
		*set eddan_dead true
		*goto Keep_loop
	*if ((eddan_dead=false) and (bow)) #Try to shoot Duke Eddan with an arrow.
		You line up the arrow and take into account the wind.
		*if (archery>=95)
			The arrow soars unerringly upward and between the enemy soldiers, striking Duke Eddan in the throat.  The dead duke tumbles off the battlement and one of his commanders begins to shout orders in his place.  You have no time to relish the fact that one of the people responsible for killing your parents is now dead.
			*if (showstats)
				*line_break
				(Archery +3)
			*set archery +3
			*set eddan_dead true
			*goto Keep_loop
		It is nearly an impossible shot to make.  Your first arrow misses the battlement, the next hits an enemy soldier who gets in the way and the third gets sent astray by a gust of wind.  You can't seem to hit the duke from this distance.
		*if (showstats)
			(Needed 95 Archery)
		*goto Keep_loop
	*if (eddan_dead=false) #Cast a fireball at the battlement where the duke is standing.
		You say the magic words as you spin your hands in a circle.  The infamous fireball is a wizard's most well-known spell. 
		*if (magic<40)
			Unfortunately, you aren't a very good wizard and the fireball sizzles out of existence before you can make any flames.
			*if (showstats)
				(Needed 90 Magic)
			*goto Keep_loop
		You throw the large ball of flame at the battlement and watch as it
		*if (magic<90)
			splashes across your target.  When the flames subside, you see that the wall has been scorched black.  After a moment, the soldiers who had thrown themselves to the ground get back to their feet.  You see Duke Eddan among the survivors.
			*if (showstats)
				(Needed 90 Magic)
			*goto Keep_loop
		blows the entire battlement into pieces!  Stones and debris fly everywhere and when the dust settles, the entire top of the structure is gone.  You know that Duke Eddan had to have been killed in the blast.  You have no time to relish the fact that one of the people responsible for killing your parents is now dead.
		*if (showstats)
			*line_break
			(Magic +3)
		*set magic +3
		*set eddan_dead true
		*goto Keep_loop
	*if ((cumari_gotstaff) and (eddan_dead=false)) #Ask Archmage Cumari to blast the battlement with a fireball.
		*set cumari_favour_used true
		You watch as the archmage holds up the magic staff you helped him to acquire.  It's easy to see why Cumari was named as the Archmage of the Academy as an enormous ball of fire shoots from the tip of his staff.  It strikes the battlement with an enormous fiery explosion which smashes it into pieces.  When the smoke clears, the battlement is simply gone.  You know that Duke Eddan had to have been killed in the blast.  You have no time to relish the fact that one of the people responsible for killing your parents is now dead.
		*set eddan_dead true
		*goto Keep_loop
	#Cast a spell to warp the wood of the fortified door.
		You say the words of magic and watch as the wood twists and turns in on itself.
		*if (magic>=70)
			This leaves many gaps for your soldiers to grab hold of and pull.  The door comes loose with a jarring crash and your soldiers immediately begin to rush inside.
			*if (showstats)
				*line_break
				(Magic +3)
			*set magic +3
			*goto Inside_Keep
		Unfortunately, the door still holds firm.
		*if (showstats)
			(Needed 70 Magic)
		*goto Keep_loop
	#Help your troops batter the door down.
		Axes and swords chip away at the wooden door, but the metal braces and studs running through it make it difficult to damage.  You grab one of the soldiers' axes and help, cutting and chopping along with the others.
		*if (strength>=60)
			Once you have cut through enough to reach the bar on the other side, all you have to do it lift it out of place and push the door open.  The instant this happens, your soldiers rush through the door.
			*if (showstats)
				*line_break
				(Strength +3)
			*set strength +3
			*goto Inside_Keep
		Unfortunately, the door holds firm.
		*if (showstats)
			(Needed 60 Strength)
		*goto Keep_loop
	*if (cumari_gotstaff) #Ask Archmage Cumari to blast the door open.
		*if (cumari_favour_used)
			"I'm sorry," he says, panting with exertion.  "I have expended the rest of my magical energies on that last fireball."
			*goto Keep_loop
		You watch as the archmage holds up the magic staff you helped him to acquire.  It's easy to see why Cumari was named as the Archmage of the Academy as an enormous ball of fire shoots from the tip of his staff.  It strikes the door with an enormous fiery explosion which smashes it into pieces.  Your soldiers waste no time rushing inside.
		*set cumari_favour_used true
		*goto Inside_Keep
	#Wait for the soldiers to bring the battering ram.
		The battle continues around you as you wait.  Eventually, a large tree trunk with spikes driven into its side is brought forward.  Every now and then one of the soldiers carrying it is killed and a new person takes their place. The door has no chance as your soldiers smash it into small pieces and rush inside.
		*if (showstats)
			*line_break
			(Army Size -10 and Army Power -10)
		*set army_size -10
		*set army_power -10
		*goto Inside_Keep

*label Inside_Keep
*gosub Check_Army_Stats

You follow the troops inside and up the stairs.  You arrive to see
*temp last_foe "None"
*if (eddan_dead)
	a grey-haired commander
	*set last_foe "the commander"
*if (eddan_dead=false)
	Duke Eddan
	*set last_foe "Eddan"
fighting your soldiers with a sword.  There are bodies scattered all over the floor, casualties of both sides.
*label Last_Stand_loop
*choice
	*if (eddan_dead) #Shout, "It's over!  Lay down your sword and surrender!"
		*if ((charm>=50) and (ludd_army<=70))
			The commander looks at you and looks at his troops.  He then does just as you ask, dropping his sword onto the stones at his feet.  His soldiers do the same.  The last pockets of enemy fighters either surrender or die as the battle comes to an end.
			*goto Ludd_Victory
		*else
			"Never!" the man yells as he continues to fight.
			*if (showstats)
				(Needed 50 Charm and Ludd Army 70 or Under)
			*goto Last_Stand_loop
	*if (eddan_dead=false) #Shout, "It's over!  Lay down your sword and surrender!"
		*if ((charm>=70) and (ludd_army<=70))
			Duke Eddan looks at you and looks at his troops.  He then does just as you ask, dropping his sword onto the stones at his feet.  His soldiers do the same.  The last pockets of enemy fighters either surrender or die as the battle comes to an end.
			*choice
				#Order the duke killed.
					You see Eddan open his mouth in surprise as one of your soldiers rams his sword through the duke's stomach.  In war, casualties happen.  One of the people responsible for killing your parents is now dead.
					*set eddan_dead true
					*goto Ludd_Victory
				#Let the duke go.
					Eddan doesn't wait for a second invitation as he runs past you and your soldiers.  He rushes down the stairs and out of the keep.  Reports later say that people saw him leaving Ludd on horseback.
					*goto Ludd_Victory
		*else
			"Never!" Duke Eddan shouts as he continues to fight.
			*if (showstats)
				(Needed 70 Charm and Ludd Army 70 or Under)
			*goto Last_Stand_loop
	*if (cumari_gotstaff) #Ask Archmage Cumari to end this.
		*if (cumari_favour_used)
			"I'm sorry," he says, shaking his head in exhaustion.  "I have expended the rest of my magical energies on that last fireball."
			*goto Last_Stand_loop
		You watch as the archmage holds up the magic staff you helped him to acquire.  A man with a crossbow takes aim, but is too slow.  It's easy to see why Cumari was named as the Archmage of the Academy as an enormous ball of fire shoots from the tip of his staff.  The fire strikes ${last_foe} and the last of the enemy soldiers, killing them all.  The last pockets of enemy fighters either surrender or die as the battle comes to an end.
		*set eddan_dead true 
		*set cumari_favour_used true
		*goto Ludd_Victory
	*if (sword) #Attack ${last_foe} with your sword.
		You wade your way past your soldiers and swing your sword at the man.
		*if (eddan_dead)
			The commander is a decent swordsman
			*if (blades>=50)
				but you are better.  You kill the man with a sweeping blow to the neck.  Your soldiers help you to finish off the rest of the enemy.  The last pockets of fighters either surrender or die as the battle comes to an end.
				*if (showstats)
					*line_break
					(Blades +2)
				*set blades +2
				*goto Ludd_Victory
			and cuts you deeply across the side with his blade.
			*if (showstats)
				(Needed 50 Blades)
			*label Round1_blade_hit
			*set health -50
			*if (showstats)
				*line_break
				(Health -50 to ${health} / 100)
			*if (health<=0)
				*goto Full_Army_KnockOut
			*goto Round2
		*else
			Duke Eddan is a very good swordsman
			*if (blades>=70)
				but you are better.  You kill the man with a sweeping blow to the neck.  You have defeated one of those responsible for the murder of your parents.  Your soldiers help you to finish off the rest of the enemy.  The last pockets of fighters either surrender or die as the battle comes to an end.
				*if (showstats)
					*line_break
					(Blades +2)
				*set blades +2
				*set eddan_dead true
				*goto Ludd_Victory
			and cuts you deeply across the side with his blade.
			*if (showstats)
				(Needed 70 Blades)
			*goto Round1_blade_hit
	*if (dagger) #Attack ${last_foe} with your dagger.
		*if (blades>=70)
			You manage to hold the longer sword away from you, but only barely.  You realize that you are facing too skilled of a swordsman to fight with such a disadvantage.
			*goto Last_Stand_loop
		*else
			You take a cut across your forearms as you realize that your short blade is no match against such a skilled swordsman.
			*set health -25
			*if (showstats)
				(Needed 70 Blades)
				*line_break
				(Health -25 to ${health} / 100)
			*if (health<=0)
				*goto Full_Army_KnockOut
			*goto Round2
	#Cast a lightning bolt at ${last_foe}.
		You are only two words into the spell when you 
		*if (staff_archmagi=false)
			feel something painful tear into your shoulder.  You look down and see a crossbow bolt sticking out of you!  You realize that one of the men with ${last_foe} had been instructed to fire upon anyone who tried to use magic.
			*set health -25
			*if (showstats)
				*line_break
				(Health -25 to ${health} / 100)
			*goto Round2
		*else
			You are only two words into the spell when you see a man with a crossbow standing beside ${last_foe}.  He pulls the trigger, but you manage to deflect the projectile with your staff!  Your spell completes and lightning tears through the room,
			*if (magic>=60)
				striking ${last_foe} in the chest.  You watch as the man falls to the ground, ending the fight.  Your soldiers help you to finish off the rest of the enemy.  The last pockets of fighters either surrender or die as the battle comes to an end.
				*if (showstats)
					*line_break
					(Magic +2)
				*set magic +2
				*goto Ludd_Victory
			just missing ${last_foe}!
			*if (showstats)
				(Needed 60 Magic)
			*goto Round2
	#Close the distance and put ${last_foe} into a chokehold.
		You manage to dodge the long sword for a few swings, but just as you are about to close the distance, you catch a solid blow across your upper legs.  You see your blood splash to the ground and you become dizzy.
		*if (eddan_dead)
			*if (unarmed>=60)
				*label Unarmed_Success
				*set health -25
				*if (showstats)
					*line_break
					(Unarmed +2 and Health -25 to ${health} / 100)
				*set unarmed +2
				*if (health<=0)
					*goto Full_Army_KnockOut
				
				Fighting through the pain, you slip around ${last_foe} and grab him by the neck.  One of the soldiers with you drives his sword into the man's stomach, killing him before you have a chance to say otherwise.
				*if (eddan_dead=false)
					One of the people responsible for killing your parents falls to the ground dead at your feet.
				The last pockets of enemy fighters either surrender or die as the battle comes to an end.
				*goto Ludd_Victory
			*else
				You realize that ${last_foe} is too skilled with the sword to let you get close enough to choke him.
				*if (showstats)
					(Needed 60 Unarmed)
				*label Unarmed_Fail
				*set health -25
				*if (showstats)
					*line_break
					(Health -25 to ${health} / 100)
				*if (health<=0)
					*goto Full_Army_KnockOut
				*goto Round2
		*else
			*if (unarmed>=90)
				*goto Unarmed_Success
			*else
				You realize that ${last_foe} is too skilled with the sword to let you get close enough to choke him.
				*if (showstats)
					(Needed 90 Unarmed)
				*goto Unarmed_Fail
	*if (bow) #Fire an arrow at ${last_foe}.
		You wait for an opening between your soldiers and then fire your arrow.
		*if (eddan_dead)
			The commander is a decent swordsman
			*if (archery>=50)
				*label Arrow_Hit
				but it's difficult to fight against a speeding arrow.  It strikes him in the chest and he falls to the ground with blood frothing from his mouth.
				*if (eddan_dead=false)
					One of the people responsible for killing your parents falls to the ground dead at your feet.
				Your soldiers help you to finish off the rest of the enemy.  The last pockets of fighters either surrender or die as the battle comes to an end.
				*if (showstats)
					*line_break
					(Archery +2)
				*set archery +2
				*set eddan_dead true
				*goto Ludd_Victory
			and steps aside as the arrow strikes where he was.
			*if (showstats)
				(Needed 50 Archery)
			*goto Round2
		*else
			Duke Eddan is a very good swordsman
			*if (archery>=80)
				*goto Arrow_Hit
			and steps aside as the arrow strikes where he was.
			*if (showstats)
				(Needed 80 Archery)
			*goto Round2

*label Round2
*gosub Check_Army_Stats

You sense movement beside you and turn to find a large spiked metal ball on a chain coming straight for your head.  You didn't even see the enemy soldier come alongside
*if (((((currentfriend_name=theothea_name) and (theothea_relationship>=80)) or ((currentfriend_name=karlkarla_name) and (karlkarla_relationship>=80))) or (((currentfriend_name=jacejess_name) and (jacejess_relationship>=80)) or ((currentfriend_name=gillgale_name) and (gillgale_relationship>=80)))) or (((currentfriend_name=branbrinn_name) and (branbrinn_relationship>=80)) or ((currentfriend_name=peterpetra_name) and (peterpetra_relationship>=80))))
	you, but suddenly, ${currentfriend_name} is there.  You see the metal ball strike ${currentfriend_himher} in the arms as ${currentfriend_heshe} stops you from getting hit in the head.
	*goto Final_Round
*else
	you.  You see ${currentfriend_name} running for the man, but ${currentfriend_heshe} is too slow.  The ball crashes into the side of your head and sends you to the floor.
	*set health -50
	*if (showstats)
		(Needed 80 ${currentfriend_name} Relationship)
		*line_break
		(Health -50 to ${health} / 100)
	*if (health<=0)
		*goto Full_Army_KnockOut
	*else
		*goto Final_Round

*label Final_Round

$!{last_foe} uses the distraction to retreat down a hallway and barricade himself in an office.  Your soldiers continue to use their weapons to batter down the door and finally rush in.  By the time you get there, he is dead.
*if (eddan_dead=false)
	One of the people who helped to murder your parents is no more.
*set eddan_dead true 
*goto Ludd_Victory

*label Full_Army_KnockOut
*page_break Darkness takes you….
You wake up in a bed.  Waking up anywhere is good news, considering that the battle had been raging around you when you fell.  You see many white bandages covering you.
*if (lover_exists)
	
	"You're awake!" ${lover_name} says from beside your bed.
	
	$!{lover_heshe} rushes to your side and takes your hand.  You can tell from the bags under ${lover_hisher} eyes that ${lover_heshe} has been waiting beside your bed for some time.
You learn that the battle was victorious, but that you suffered great losses.
*if (eddan_dead=false)
	Duke Eddan was killed in the last defence of the city.  One of the people responsible for killing your parents is dead.
*set eddan_dead true 
*if (showstats)
	*line_break
	(Army Size -15, Army Morale -15, Army Power -15 and Health to 10 / 100)
*set army_size -15
*set army_morale -15
*set army_power -15
*set health 10
*goto Ludd_Victory
		
*label Ludd_Victory
*gosub Check_Army_Stats

*if (temp_lost_companions)
	You are happy to see General Vale and your other missing companions as order is restored.  They had also experienced some heavy fighting, but all of their injuries will heal with time.
*if (squire_name!="None")
	Squire ${squire_name} is found in the infirmary.
	*if ((squire_equipped) and (squire_trained))
		$!{squire_heshe} did well in the fight and will be back on ${squire_hisher} feet soon.  Your squire's success is a good reflection upon you.
		*if (showstats)
			*line_break
			(Army Morale +3)
		*set army_morale +3
		*label After_Squire
		
		*goto After_Squire_2
	*else
		By the time you get there, ${squire_heshe} is dead.
		*if (squire_equipped) and (squire_trained=false)
			$!{squire_hisher} armour is dented from heavy use and ${squire_hisher} sword is missing.  A soldier who was with ${squire_himher} when ${squire_heshe} fell says that ${squire_heshe} was overwhelmed by an enemy soldier with a two-handed greatsword.  ${squire_name} just wasn't skilled enough to repel such a strong attack.
			*if (showstats)
				*line_break
				(Squire Needed Training)
			*set squire_name "None"
			*goto After_Squire
		*if (squire_equipped=false) and (squire_trained=false)
			$!{squire_hisher} armour was in terrible shape before the battle, but now it is even worse.  A soldier who was with ${squire_himher} when ${squire_heshe} fell says that ${squire_heshe} was overwhelmed by an enemy soldier with a two-handed greatsword.  ${squire_name} just wasn't skilled enough to repel such a strong attack and ${squire_hisher} poor armour was too weak to stop the big blade.
			*if (showstats)
				*line_break
				(Squire Needed Training and Better Equipment)
			*set squire_name "None"
			*goto After_Squire
		*comment (squire_equipped=false) and (squire_trained)
		$!{squire_hisher} armour was in terrible shape before the battle, but now it is even worse.  A soldier who was with ${squire_himher} when ${squire_heshe} fell says that ${squire_heshe} was overwhelmed by an enemy soldier with a two-handed greatsword.  ${squire_name} was fighting off the big sword well, but ${squire_hisher} poor armour was just too weak to stop the blade on what should have been a glancing blow.
		*if (showstats)
			*line_break
			(Squire Needed Better Equipment)
		*set squire_name "None"
		*goto After_Squire
*else
	*comment No Squire
	*goto After_Squire_2

*label After_Squire_2		
The city of Ludd returns to normal in a surprisingly short amount of time.  The common people hardly care who their ruler is.  They have their own lives to lead.  They worry more about their children's wellbeing, about what to make for dinner, and about their jobs.  Within a few days, the city feels the same way it did when you lived there two years ago.
*if ((borrowed_horse) or (mount_level<=4))
	*if (mount_name!="None")
		You receive word that ${mount_name}, your ${mount_type}, survived the battle and was found wandering just outside the city.  $!{mount_heshe} was taken to the stables, bandaged and given some fresh food.
*if (dwarf_help>0)
	The dwarven smiths are kept very busy as armour and weapons are repaired from the battle.

"We will be ready to march in a few more days," General Vale says.

This isn't a delay.  Everyone knew that the army would need to spend some time in Ludd to refit themselves and gather the food needed to finish the march to Tornassa and take the city.  Lord Tovor was already neck-deep in Duke Eddan's ledgers as he sorted out what food, troops, cavalry and equipment now belonged to you.  You have many important decisions to make before you can get some rest.
*temp dealwith_soldiers false
*temp dealwith_looting false
*temp dealwith_ledgers false
*temp dealwith_food false
*temp dealwith_strategy false
*temp dealwith_civilians false
*label Aftermath_loop
*gosub Check_Army_Stats
*if ((((dealwith_soldiers) and (dealwith_looting)) and ((dealwith_ledgers) and (dealwith_food))) and ((dealwith_strategy) and (dealwith_civilians)))
	*goto Ludd_Freetime
*choice
	#Deal with the surviving enemy soldiers.
		*set dealwith_soldiers true
		"We have many prisoners of war," General Vale says.  "We could use the numbers, but it will cause trouble, since they were standing against us such a short time ago.  Some of them will feel loyal to Duchess Selina and try to hurt us from within our ranks, if we take them."
		*choice
			#Say, "We will accept them into the army.  We need the numbers."
				*goto Soldiers_Accept
			#Say, "I am unifying Daria.  They are a part of Daria once more.  Allow them into my army."
				*label Soldiers_Accept
				Your troops aren't happy with your decision.  Prudently, you separate the Ludd soldiers and scatter them across all of your troops so they don't form pockets of dissent.  Some of them cheer your decision and others stoically accept it.
				*if (showstats)
					*line_break
					(Army Size +20, Army Morale -7 and Army Power +5)
				*set army_size +20
				*set army_morale -7
				*set army_power +5
				*goto Aftermath_loop
			#Say, "Banish them for one year's time.  After that, they may return to Daria."
				"A very wise offer," General Vale says.  "In a year, the matter with Duchess Selina will be decided.  Some of them will go to her anyway, but I think most have seen enough war and will disappear."
				*if (showstats)
					*line_break
					(General Vale Relationship +5 and Citizen Reputation +7)
				*set vale_relationship +5
				*set citizen_reputation +7
				*goto Aftermath_loop
			#Say, "Let them do as they like, but I can't risk having traitors in my army."
				"As you wish," General Vale says, clearly not liking the idea.
				*if (showstats)
					*line_break
					(General Vale Relationship -3)
				*set vale_relationship -3
				
				Many of the soldiers leave Ludd before you change your mind, although many others try to take up their old lives in town.  Not all of them were career soldiers and these were the happiest since they could return to a semblance of their normal lives.  You know that some of them also joined Selina in Tornassa, but not nearly as many as General Vale had been afraid of.
				*if (showstats)
					*line_break
					(Citizen Reputation +10)
				*set citizen_reputation +10
				*goto Aftermath_loop
			#Say, "Execute them."
				General Vale is startled by the death sentence, but he nods at your command and sends out the orders.  This guarantees that none of them will join Selina.  Although it petrifies the troops under your command, it also firms their resolve since they are even more afraid of marching against you.
				*if (showstats)
					*line_break
					(Evil +20, Army Morale +10 and Citizen Fear +15)
				*set good -20
				*set army_morale +10
				*set citizen_fear +15
				*goto Aftermath_loop
	#Discuss strategy with General Vale.
		*set dealwith_strategy true
		"We are securing the city," he says.  "Unfortunately, we can't stay in Ludd for long.  As Duke Eddan found out, without any walls, this city is too easy to take.  Tornassa doesn't have that problem, which is why Duchess Selina will be happy to have us come to her.  And, if we don't attack her, she'll have a bigger army than us in the spring and she'll wipe us out wherever we are."
		*if (((vale_relationship>=75) and (class_guard>=2)) and ((history>=45) and (geography>=45)))
			
			"You did a great job planning this battle," General Vale says with a calculating eye.  "You should speak to me about furthering your knowledge of warcraft.  I see great things in your future."
			*if (showstats)
				*line_break
				(General Vale Relationship +5)
			*set vale_relationship +5
			*set considering_warmaster true
			*goto Aftermath_loop
		*else
			*if (showstats)
				(Needed 75 General Vale Relationship, Two Guard Levels, 45 History and 45 Geography)
		*goto Aftermath_loop
	#Decide what your army should do on the night of their victory.
		*set dealwith_looting true
		Victorious soldiers are known to celebrate in very barbaric ways.  You have no doubt that they would happily steal anything they can fit in their pockets, have their way with the womenfolk and get very drunk on whatever alcohol they can find.
		*choice
			#Say, "Let them celebrate."
				General Vale nods and passes on your words.  The citizens of Ludd would be wise to stay locked up in their larders tonight as your soldiers run riot over the city.  Tomorrow, you will put them back to work.
				*if (showstats)
					*line_break
					(Army Morale +20, Citizen Reputation -10 and Evil +10)
				*set army_morale +20
				*set citizen_reputation -10
				*set good -10
				*goto Aftermath_loop
			#Say, "No stealing and no raping, but give them the night off."
				General Vale nods and passes on your words.  The tavern keepers will do a brisk business tonight as the thirsty soldiers flood their establishment.  Tomorrow, you will put your troops back to work.
				*if (showstats)
					*line_break
					(Good +5, Army Morale +10 and Citizen Reputation +5)
				*set good +5
				*set army_morale +10
				*set citizen_reputation +5
				*goto Aftermath_loop
			#Say, "Put them straight to work, no time off."
				General Vale nods and passes on your words.  There are defences to replace, armour to repair and weapons to sharpen.  Keeping your soldiers in line will also keep your new citizens safe from their indulgences.  The troops grumble and complain, but they do as you command.
				*if (showstats)
					*line_break
					(Army Morale -7, Army Power +3 and Citizen Reputation +5)
				*set army_morale -7
				*set army_power +3
				*set citizen_reputation +5
				*goto Aftermath_loop
	#Gather the food found in Ludd.
		*set dealwith_food true
		*if (taking_food)
			Your army continues its practice of taking the food it needs, with or without the owner's consent.  The food in the barracks that fed the enemy soldiers is quickly added to your own stores as well.
			*if (ludd_buildings_fired)
				Even with the losses from the buildings you set on fire during the raid, you are surprised at just how little food can be found.  Something is wrong.  You need to consult Lord Tovor and find out where the food has gone.
				*if (showstats)
					*line_break
					(Citizen Reputation -10 and Army Food +7)
				*set citizen_reputation -10
				*set army_food +7
				*goto Aftermath_loop
			*else
				You are surprised at just how little food can be found.  Something is wrong.  You need to consult Lord Tovor and find out where the food has gone.
				*if (showstats)
					*line_break
					(Citizen Reputation -10 and Army Food +12)
				*set citizen_reputation -10
				*set army_food +12
				*goto Aftermath_loop
		*else
			Your army continues its practice of buying food and taking donations with the owner's consent.  The food in the barracks that fed the enemy soldiers is quickly added to your own stores as well.
			*if (ludd_buildings_fired)
				Even with the losses from the buildings you set on fire during the raid, you are surprised at just how little food can be found.  Something is wrong.  You need to consult Lord Tovor and find out where the food has gone.
				*if (showstats)
					*line_break
					(Army Food +5)
				*set army_food +5
				*goto Aftermath_loop
			*else
				You are surprised at just how little food can be found.  Something is wrong.  You need to consult Lord Tovor and find out where the food has gone.
				*if (showstats)
					*line_break
					(Army Food +10)
				*set army_food +10
				*goto Aftermath_loop
	#Consider recruiting from the civilians of Ludd.
		*set dealwith_civilians true
		Many of the civilians had joined Duke Eddan's army and many others had already joined Selina in Tornassa, but there were more who hadn't joined either.  Some of these people were injured, old or young, but others knew you were coming and were waiting to join you.
		*choice
			#Recruit anyone who will join you, regardless of fitness.
				*if (poisoned_ludd)
					Unfortunately, you learn that a great many of these civilians had been killed by the poison that you had placed in their water system.  Those remaining were mostly weak and inexperienced, but if they could hold a sword, you took them.
					*if (showstats)
						*line_break
						(Army Size +10)
					*set army_size +10
					*goto Aftermath_loop
				*else
					You accepted anyone who could hold a sword, regardless of age or infirmities.  Although they weren't all great warriors, they helped to fill in your ranks.
					*if (showstats)
						*line_break
						(Army Size +20)
					*set army_size +20
					*goto Aftermath_loop
			#Recruit only those who are healthy enough to be soldiers.
				*if (poisoned_ludd)
					Unfortunately, you learn that a great many of these civilians had been killed by the poison that you had placed in their water system.  After weeding out those who weren't able to wield a sword, you weren't left with very many.
					*if (showstats)
						*line_break
						(Army Size +5 and Army Power +5)
					*set army_size +5
					*set army_power +5
					*goto Aftermath_loop
				*else
					After weeding out those who weren't able to wield a sword, you weren't left with very many.
					*if (showstats)
						*line_break
						(Army Size +10 and Army Power +10)
					*set army_size +10
					*set army_power +10
					*goto Aftermath_loop
			#Don't recruit any of the people from Ludd.
				The civilians aren't certain why you won't let them join.  Some think it's because you don't trust them, others suspect that it's because you know that the best warriors had already been drafted into Eddan and Selina's armies.
				*goto Aftermath_loop
	*if (dealwith_food) #Consult Lord Tovor on what he found in the ledgers.
		*set dealwith_ledgers true
		"It's all gone!" Lord Tovor exclaims as he hammers his fist onto the ledger in front of him.  "Damn it!  Duchess Selina purchased every surplus scrap of food and spare blade in the city.  She paid almost ten times their value, with a spring due date."
		
		"She's smart," General Vale says grudgingly.  "She knew we'd attack Ludd, so she'd never have to pay.  Duke Eddan was an idiot.  We're in trouble.  Our plans all rested on the idea that we'd restock our food supplies here in Ludd before moving on to Tornassa."
		
		*if (army_food>0)
			"We have some food with us, but not much,"
		*if (army_food=0)
			"We're already out of food,"
		Lord Tovor says.  "We won't be able to keep our army fed long enough to march to Tornassa, let alone mount any type of siege."
		*choice
			#Say, "Send word to Brightwater.  We'll need to increase the food sent through our supply lines."
				*set food_source "The supply lines have reached us from Brightwater"
				*label YouGotTime
				General Vale nods in agreement.
				
				"It's the only way," he agrees.  "But it's going to take time.  We won't be able to march upon Tornassa until the end of summer.  We'll be lucky to see the walls of the city before the snows begin falling.  Looks like you'll have some free time in Ludd, Your Highness."
				*if (tovor_relationship>=75)
					
					"Your Highness," Lord Tovor says as he continues to read the ledgers.  "There's more here.  It looks like Duke Eddan has been funding some kind of expedition to the west.  It's cross referenced over here, but I can't make heads or tails of it."
					*if (((history>=60) and (arcana>=60)) and (geography>=60))
						
						"They found a dragon!" you exclaim as you skim through the text.  "See?  It refers to the birthplace of Ethar the Grim.  This is an ancient dialect here…I don't think Duke Eddan found the cave itself…but I think I could."
						*set considering_dragonrider true
						*goto Aftermath_loop
					
					You look over the text too.  It mentions someone named Ethar the Grim and uses a language you've never seen before.
					*if (showstats)
						(Needed 60 History, 60 Geography and 60 Arcana)
					
					"I don't know what this means either," you say.  "But it appears that he didn't find whatever he was looking for."
					*goto Aftermath_loop
				*else
					*if (showstats)
						(Needed 75 Lord Tovor Relationship)
					*goto Aftermath_loop
			#Say, "Start raiding the surrounding farms.  Many should be abandoned with crops untended in the fields."
				*set food_source "We have gathered enough food from the untended fields"
				*goto YouGotTime
			#Say, "Start foraging and hunting for food.  The plains are full of unowned horses, bison and other animals."
				*set food_source "We have foraged enough food from the plains"
				*goto YouGotTime

*label Ludd_Freetime
*if ((using_legacy) and (legacy_help="army_morale"))
	
	"Your Highness," Lord Tovor calls to you as he finds another interesting thing in the ledgers.  "Have you heard of the Elmvale Trading Company?  Apparently they have a large warehouse here in Ludd and it's filled with spices, soft blankets, kegs of ale, and all sorts of other luxuries.  And get this, according to these records, your family owns the business."
	
	Your family owned many businesses, but they were all in Tornassa and long since lost.  When you visit the warehouse, you see that the trading company was actually created by King Kyle, an ancestor of yours who ruled Daria when the Wizard of Elmvale was still alive.  The contents of the warehouse will go a long way towards making your army feel comfortable and happy.
	*if (showstats)
		*line_break
		(Legacy Advantage #9: Army Morale +20.  More perks will arrive as the story progresses.)
	*set army_morale +20
*if ((using_legacy) and (legacy_help="army_power"))
	
	"I don't think I care for the decorations," Lord Tovor comments as he continues to read the ledgers.
	
	You see a pair of swords mounted over the door.  Above another door, you see a full set of chain mail.  Over yet another, you see a shield.  The style looks to be several centuries old.
	
	"You had better get used to it," General Vale says.  "I think every door in Ludd is decorated this way.  I don't remember the story, but I think it started back during King Kyle's reign and never spread outside of Ludd.  You know, the style might be a little old-fashioned, but this is all serviceable equipment.  Our blacksmiths have been hard-pressed to outfit our militia.  I'll have the troops collect all of this equipment at once."
	
	You wonder if this is the work of the Elmvale Wizard.
	*if (showstats)
		*line_break
		(Legacy Advantage #9: Army Power +20.  More perks will arrive as the story progresses.)
	*set army_power +20

After having dealt with the military matters, you find yourself with free time once again as you wait on the food.
*if (prisonchild_inparty)
	${prisonchild_name}
	*if (prisonchild_job="kitchen")
		attempts to return to ${prisonchild_hisher} job in the kitchen, but the kitchen staff is already too large.  Duke Eddan was known to be a fussy eater.  Instead, you hear that ${prisonchild_name} begins to work in the kitchen for the Temple of Light, which is dedicated to Auriel and Lucien.
	*if (prisonchild_job="page")
		returns to running errands as a page, although ${prisonchild_heshe} now works for Lord Tovor.
	*if (prisonchild_job="alone")
		returns to terrorizing the servants while staying alone in ${prisonchild_hisher} room all day.
*if (lover_exists)
	${lover_name} joins you in your room in the keep, but like the rest of your companions, ${lover_heshe} fills ${lover_hisher} days with ${lover_hisher} own training.
*if (lover_exists=false)
	Your companions all take rooms in the keep with you and fill their days with their own training.
Everyone is preparing themselves for the final battle with Selina, including yourself.  How do you spend your summer?
*if (health<100)
	*if (showstats)
		*line_break
		(Health to 100 / 100)
*gosub ResetAdventure
*label Ludd_Job_loop
*choice
	*if (considering_tattooist) #Study with ${tattooist_name} to become an Arcane Tattooist.
		*set class_tattooist 1
		*achieve prestige
		${tattooist_name} is very happy with your growing skills as you study the runes and power structures of tattoos.  You learn how they can be linked together to create more powerful effects.  You learn that some primitive cultures use the tattoos to gain powers, but that an extinct society of Arcane Tattooists were truly masters of the art.  The effects they were able to create were staggeringly powerful.  These skills are beyond even ${tattooist_name}'s talent, but you feel with enough time you could learn them.  The summer days go by quickly as you learn and add a few tattoos to your own body.
		*if (showstats)
			*line_break
			(Gained Level in Arcane Tattooist)
		*set title "Arcane Tattooist"
		*temp tattoos_left 3
		*label Tattooing_loop
		*if (tattoos_left=0)
			*goto After_Ludd_Job
		
		Tattoos to add:  ${tattoos_left}
		*choice
			*if (tattoo_circles=false) #Get a tattoo of several concentric circles on the shoulder-blade which will promote health.
				The circles radiate out to the size of the palm of your hand.  In the days to come, when you are feeling extra tired or weary, they glow briefly and you feel a little more energized.
				*if (showstats)
					*line_break
					(Endurance +7)
				*set endurance +7
				*set tattoo_circles true
				*set tattoos_left -1
				*goto Tattooing_loop
			*if (tattoo_coins=false) #Get a tattoo of a pile of golden coins in the palms of your hands which will promote financial gain.
				The gold coins may seem merely symbolic, but the strange thing is, they work.  Your gambling becomes better, you find coins when you go for walks and people you don't even know grant you gifts of money for all of the special holidays.
				*if (showstats)
					*line_break
					(Gold +300)
				*set gold +300
				*set tattoo_coins true
				*set tattoos_left -1
				*goto Tattooing_loop
			*if (tattoo_stars=false) #Get a tattoo of a series of blue stars up the neck which will promote magical insight.
				As the image spreads, you feel more alert to your surroundings.
				*if (showstats)
					*line_break
					(Perception +7)
				*set perception +7
				*set tattoo_stars true
				*set tattoos_left -1
				*goto Tattooing_loop
			*if (tattoo_face=false) #Get a full-face tattoo of black swirls and runes which will promote strength and aggression.
				You immediately feel stronger, but you also feel more on edge and angrier.  It is a good and powerful feeling, considering that you are about to go to war.
				*if (showstats)
					*line_break
					(Strength +7 and Citizen Fear +15)
				*set strength +7
				*set citizen_fear +15
				*set tattoo_face true
				*set tattoos_left -1
				*goto Tattooing_loop
			*if (tattoo_sword=false) #Get a tattoo of a sword dripping blood on your bicep which will promote skill with blades.
				You feel the energy from the tattoo across your entire body.  It makes you faster and stronger with a blade.
				*if (showstats)
					*line_break
					(Blades +15)
				*set blades +15
				*set tattoo_sword true
				*set tattoos_left -1
				*goto Tattooing_loop
			*if (tattoo_rings=false) #Get a tattoo of rings across your fingers and toes which will make your punches and kicks stronger.
				You feel the energy build in your hands and feet, making you faster and stronger with your unarmed attacks.
				*if (showstats)
					*line_break
					(Unarmed +15)
				*set unarmed +15
				*set tattoo_rings true
				*set tattoos_left -1
				*goto Tattooing_loop
			*if (tattoo_spiral=false) #Get a tattoo of a spiralling vortex extending from your heart outwards which promotes magical energy.
				You feel the change immediately as your inner reservoirs of power seem to be fuller than ever.
				*if (showstats)
					*line_break
					(Magic +15)
				*set magic +15
				*set tattoo_spiral true
				*set tattoos_left -1
				*goto Tattooing_loop
			*if (tattoo_leaves=false) #Get a tattoo of leaves and vines around your wrists which promotes an affinity with nature.
				The leaves and vines are a deep green.  The detail of their drawing is so accurate that they seem as though they are blowing in an imaginary wind.
				*if (showstats)
					*line_break
					(Nature +15)
				*set nature +15
				*set tattoo_leaves true
				*set tattoos_left -1
				*goto Tattooing_loop
			*if (tattoo_flames=false) #Get a tattoo of flames at the base of your neck which promotes learning.
				The tattoo goes all around your neck and lower shoulders.  It seems as though each flame drawn makes you mentally more efficient.
				*if (showstats)
					*line_break
					(History +5, Geography +5 and Arcana +5)
				*set history +5
				*set geography +5
				*set arcana +5
				*set tattoo_flames true
				*set tattoos_left -1
				*goto Tattooing_loop
			*if (tattoo_blacksnakes=false) #Get a tattoo of a pair of black snakes climbing each leg which promotes stealth.
				The snakes are as dark as night.  When you attempt to move quietly and unseen, the shadows seem to gather closer around you.
				*if (showstats)
					*line_break
					(Stealth +15)
				*set stealth +15
				*set tattoo_blacksnakes true
				*set tattoos_left -1
				*goto Tattooing_loop
	#Use your knowledge of magic and nature to become an Alchemist.
		*if (((nature<70) or (magic<70)) or (arcana<40))
			Being an alchemist takes more than being willing to mix a bunch of stuff together and see what happens.  You must know the magical bonding properties of many different ingredients as well as the proper way to prepare them.  After many botched attempts, you realize that you don't have the skills necessary to be an Alchemist.
			*if (showstats)
				(Needed 70 Nature, 70 Magic and 40 Arcana)
			*goto Ludd_Job_loop
		The rare art of true alchemy isn't very popular in Daria.  If a person knew enough to cast magic, they became a wizard.  If a person wanted to heal someone, they became a priest or priestess.  The idea of using the magical aspects of naturally occurring ingredients which are collected and prepared in a specific way is seen as difficult and inconvenient.  The result is that there are very few practising alchemists.  It also doesn't help that the best alchemists always seem to blow themselves up after a few years of business.
		
		You begin by commandeering a large room in the keep to be your laboratory.  Next, you purchase the equipment needed to brew potions.  Glass piping, flasks, burners, mortars and pestles are all set up.  Finally, you purchase and find your ingredients.  By the end of the summer, you have a steady flow of people wanting to buy your various elixirs, which helps to pay for all the things you needed to get started.  You also manage to brew a few interesting potions which might be beneficial in the months to come.  You purchase a bandoleer and modify it to carry potions for quick access.
		*if (showstats)
			*line_break
			(Gained Level in Alchemist, Nature +15, Magic +15, Gold +50 and Potion Bandoleer)
		*set class_alchemist 1
		*achieve prestige
		*set nature +15
		*set magic +15
		*set gold +50
		*set bandoleer true
		*set title "alchemist"
		*goto After_Ludd_Job
	#Explore your prophetic dreams in great detail.
		You recall the dream you had the morning your parents were murdered.  It was years ago, but it had something to do with demons.  Was it just a coincidence?  Or was it a premonition?
		*if ((perception<75) or (magic<75))
			Your magical studies never fully satisfy your questions.
			*if (showstats)
				(Needed 75 Perception and 75 Magic)
			*goto Ludd_Job_loop
		Your magical studies speak of divination, but your dream occurred without any training.  You read books that speak of meditations and ways of thinking that promote such glimpses.  It's a difficult area of study with no firm results.  You begin to learn how to tap into the power and see things that others don't.  It's difficult to control, but you begin to see people and things that occurred in the past or will occur in the future.
		*if (showstats)
			*line_break
			(Gained Level in Seer, Perception +20 and History +20)
		*set title "seer"
		*set perception +20
		*set history +20
		*set class_seer +1
		*achieve prestige
		*goto After_Ludd_Job
	*if (considering_warmaster) #Study to become a War Master under General Vale's tutelage.
		General Vale doesn't cut you any slack for being the ${princeprincess}.  He is a much harsher tutor than Harmond ever was.  His knowledge of tactics and strategies is amazing, and after a summer of study, your knowledge increases a thousand-fold.  You learn all about sallies, routs and the art of the siege.  He has you read a great number of books and analyse historical battles.  In addition to tactics, he also has you physically practising maneuvers with him every day while taking a general's wages from the army's budget.
		*if (showstats)
			*line_break
			(Gained Level in War Master, History +15, Geography +15, Blades +10, Archery +10 and Gold +150)
		*set history +15
		*set geography +15
		*set blades +10
		*set archery +10
		*set gold +150
		*set class_warmaster 1
		*achieve prestige
		*set title "War Master"
		*goto After_Ludd_Job
	*if (considering_dragonrider) #Try to find the dragon's cave that Lord Tovor learned about in the ledgers.
		You take your companions with you as you make a speedy trek to the west.  You know you have the time, as long as you hurry.  After several days, you find the foothills of the mountain and climb the peak where you believe Ethar the Grim to have been born.
		
		You feel something calling to you.  Unerringly, you lead your small group to a cave that is mostly hidden by thorny vines and walk in.  Your companions light torches and hurry to follow you.  The tunnel leads you down into an enormous cavern.  You can see melted rock all around you.  Some great wyrm had likely spent centuries here, but now, it is empty.  Disappointment washes over you as you walk through the empty cavern.  There is nothing left.  Not even a single gold coin.
		
		The mystic call comes to you again.  You walk through the cavern and find the sharp edges of a shell the size of an ale barrel.  The shell must have been huge!  You realize that at least one dragon had hatched here recently.  A few more feet down the hall and you begin to find fresh bones.  Something has been using this corner of the cavern as a lair.  You don't have to wait long to find out what that something is as the entrance you had come through is suddenly filled with a large winged beast.
		
		It's a dragon!  You see scales of a deep green, shining with the light from your companions' torches.  The dragon is young, but still as large as a warhorse.  Dark eyes lock with yours from across the cavern and you feel a connection forming.
		*rand coinflip 1 2
		*choice
			#Accept the connection.
				The dragon walks toward you, but you feel no fear.  You raise your hands to stop your companions from attacking the majestic beast.  The connection strengthens as the dragon's head is lowered.  You realize that the creature wants you to climb onto
				*temp dragon_gender 0
				*if (dragon_gender=1)
					his
				*if (dragon_gender=2)
					her
				back.
				*if (mount_name!="None")
					If you take the dragon as a mount, you know that you won't be able to keep ${mount_name}, your ${mount_type}.
					*choice
						#Mount the dragon, knowing that you will have to get rid of ${mount_name}.
							*if ((mount_type="forest worm") or (mount_type="crocodile"))
								You make a mental note to release ${mount_name}, your ${mount_name}, back into the wild when you return to the cave.
								*goto DragonFlight
							*if (mount_type="Dreadhorse")
								The moment you decide that you no longer need ${mount_name}, your Dreadhorse, the undead animal falls to the ground.  It had looked like it was months dead before it fell, but now that it wasn't moving, it looked even worse.
								*goto DragonFlight
							You make a mental note to sell ${mount_name} when you return to Ludd.  You know that you will get a fair price for ${mount_himher}.
							*if (showstats)
								*line_break
								(Gold +${mount_value})
							*set gold +mount_value
							*goto DragonFlight
						#Shake off the strange connection.
							*goto NoDragon
				*label DragonFlight
				*if (coinflip=1)
					*set mount_hisher "his"
					*set mount_heshe "he"
					*set mount_himher "him"
				*if (coinflip=2)
					*set mount_hisher "her"
					*set mount_heshe "she"
					*set mount_himher "her"
				*set mount_level 6
				*achieve sweetride
				*set mount_value 0
				*set mount_desc "a mighty"
				*set mount_type "dragon"
				
				Your companions watch in amazement as you ride the dragon out of the cave.  $!{mount_heshe} leaps into the sky and easily carries you up into the clouds.  In excitement, your new ally breathes a burst of flame.  $!{mount_heshe} is more than simply a mount.  The call you had felt strengthens into a permanent bond.  You realise that you can communicate to the reptile without words and your body physically strengthens from this bond.  When ${mount_heshe} returns to the cave, you find that there is a small amount of dragon gold left behind after all.
				*if (showstats)
					*line_break
					(Gained Level in Dragonrider, Strength +15, Agility +15, Endurance +15 and Gold +150)
				*set strength +15
				*set agility +15
				*set endurance +15
				*set gold +150
				*set class_dragonrider 1
				*achieve prestige
				*set title "dragon-rider"
				
				You realize that ${mount_heshe} will need a name.  Although you know ${mount_hisher} true name through the mystical bond, it isn't something that can be said with words.  You decide to call ${mount_himher}…
				*choice
					#Draco.
						*set mount_name "Draco"
						*goto Done_Naming_Dragon
					#Firescale.
						*set mount_name "Firescale"
						*goto Done_Naming_Dragon
					#Parnaxxus.
						*set mount_name "Parnaxxus"
						*goto Done_Naming_Dragon
					#Smoke.
						*set mount_name "Smoke"
						*goto Done_Naming_Dragon
					#Something else.
						*label Name_Dragon
						*input_text mount_name
						*if (mount_name="None")
							That is a terrible name. You decide to call ${mount_himher} something else instead.
							*goto Name_Dragon
						*goto Done_Naming_Dragon
				*label Done_Naming_Dragon
				You return to Ludd with your new friend.  Everyone is amazed at the sight of your arrival.
				*if (showstats)
					*line_break
					(Army Morale +10 and Citizen Fear +10)
				*set army_morale +10
				*set citizen_fear +10
				*goto After_Ludd_Job
			#Fight the connection.
				*label NoDragon
				You fight off the strange feeling and the dragon roars at you.  It then turns around, squeezes back through the entrance and takes flight.  You never see the dragon again and find nothing else of use in the cavern.  With only an amazing tale to tell for your troubles, you return to Ludd.
				*goto Ludd_Job_loop
	*if (book_of_the_dead) #You try to become a Necromancer by reading the Book of the Dead.
		*if (good>30)
			The vile practices that you read about give you nightmares.  No matter how much you try to get past them, you can't.  You begin to think that necromancy isn't for you after all.
			*if (showstats)
				(Needed 70 Evil)
			*goto Ludd_Job_loop
		*if (arcana<50)
			Unfortunately, it still makes no sense to you.  You will have to find some other way to fill your time.
			*if (showstats)
				(Needed 50 Arcana)
			*goto Ludd_Job_loop
		The book is filled with the foulest magic you have ever seen.  You begin to wonder about the "chance" meeting of the stranger during your march.  Either way, the book is a treasure beyond value and filled with great power.
		*if ((class_priest>=2) and (god_good=false))
			*goto Become_Necromancer
		*if (((class_priest=1) and (god_good=false)) and (magic>=60))
			*goto Become_Necromancer
		*if (magic<80)
			Unfortunately, you can't seem to get any of the rituals to work properly.
			*if (showstats)
				(Needed Evil $!{priestpriestess} Levels or 80 Magic)
			*goto Ludd_Job_loop
		*label Become_Necromancer
		With every word you read, the world becomes a darker place.  Your skin becomes paler, your eyes become sunken and your shadow becomes deeper.  Everyone around you begins to fear you, but since you have taken Ludd and have an army at your command, they are unable to stop you.  Some of the bodies you exhume for your studies have valuables on them which you keep.
		*if (showstats)
			*line_break
			(Gained Level in Necromancer, Magic +20, Religion +10, History +10, Evil +20, Citizen Fear +50 and Gold +150)
		*set class_necromancer 1
		*achieve prestige
		*set title "Necromancer"
		*set magic +20
		*set religion +10
		*set history +10
		*set good -20
		*set citizen_fear +50
		*set gold +150
		You find one extremely evil ritual which has the power to raise a tormented undead spirit to do your bidding.
		*if (companion_name!="None")
			You had always been taught that bonding a being could only be done once in a life.  But with necromancy, you aren't limited to "life" any more.  Unfortunately, the magic of the spell would erase the bond you have with ${companion_name}.
			*choice
				#Lose ${companion_name} and complete the ritual.
					You send ${companion_name} away.  $!{companion_heshe} doesn't understand the reason why, but follows your command anyway.  When the bond is severed, you get a headache which lasts a full week. 
					*set companion_name "None"
					*set companion_type "None"
					*set companion_heshe "None"
					*set companion_hisher "None"
					*set companion_himher "None"
					*set companion_familiar true
					*set companion_travels "None"
					*set companion_injured false
					*goto Get_Shade
				#Keep ${companion_name} and ignore the ritual.
					*label Ignore_Shade_Rite
					There are many other great things to learn in the book.  Your days are spent reading things that would give lesser people nightmares.
					*goto After_Ludd_Job
		*label Get_Shade
		The spirit must be recently deceased through violent and painful means.  Luckily for you, there is a city full of people to choose from whom no one will miss.
		*choice
			#Torture and kill a homeless woman for the rite.
				*set companion_heshe "she"
				*set companion_hisher "her"
				*set companion_himher "her"
				The woman
				*goto Get_Shade_2
			#Torture and kill a homeless man for the rite.
				*set companion_heshe "he"
				*set companion_hisher "his"
				*set companion_himher "him"
				The man
				*goto Get_Shade_2
			#Change your mind and ignore the ritual.
				*goto Ignore_Shade_Rite
		
		*label Get_Shade_2
		you take from the streets has no friends or family to question ${companion_hisher} disappearance.  You follow the ritual, which includes weeks of torture and starvation.  At the moment of ${companion_hisher} miserable death, you invoke the powerful magic.  A dark Shade rises from the chest of the corpse.  The Shade is as black as midnight.  Everyone who sees ${companion_himher} feels a coldness in their heart.  Your companions don't ask where ${companion_heshe} came from or what ${companion_heshe} is, although they likely have their suspicions.
		*if (showstats)
			*line_break
			(Citizen Fear +15 and Evil +20)
		*set citizen_fear +15
		*set good -20
		*set companion_type "Shade"
		*set companion_familiar true
		*set companion_travels "floats alongside you"
		*set companion_injured false
		
		What do you call your new companion?
		*label Name_Shade
		*input_text companion_name
		*if (companion_name="None")
			That's a terrible name.  Pick something else.
			*goto Name_Shade
		*goto After_Ludd_Job
	#Try to find the best swordsman in the city and have them train you.
		You put out a request for a teacher, looking for someone to teach you true mastery of the blade.
		*if ((blades<80) or (agility<50))
			Although you get a few people offering to show you swordsmanship, none of them are as good as those in your army.  You realize that you could take an active command among your own troops and be trained just as well.
			*if (showstats)
				*line_break
				(Needed 80 Blades and 50 Agility)
			*goto Ludd_Job_loop
		*if (sword=false)
			You get a sword from the armoury to practice with while you wait for a teacher.
		It looks as though nobody will take the job, until a little man with a fancy hat appears in your keep one day.  He sits at your dining table with his feet propped on the surface.  As you enter the hall, your guards all warn you of an intruder.  They say that he systematically beat everyone who tried to get him to leave…but didn't seriously harm a single person.
		*if (sword=false)
			*if (showstats)
				(Gained Sword)
			*set sword true
		
		"Good day, my student!" the man says, jumping nimbly to his feet and sweeping his fancy hat off his head in a single motion.
		
		You see that he is wearing two swords on his hips, a longer blade and a shorter one.  He smiles at you and waits.
		*choice
			#Say, "I assume that you are here to teach me swordplay."
				"Oh yes," he says.
				*label Met_Blademaster
				"I hear that you wish to be trained by the best…and that is me.  I am Eagarro and I am a Blademaster."
				
				You have heard of Blademasters before.  They are mostly in legends and many people think that the old group disbanded hundreds of years ago.  The fact that this little man bested all of your guards shows that he is very skilled.
				
				"We have much to do," he says confidently.
				*if (dagger)
					"Let's begin!"
				*if (dagger=false)
					"You need a second blade.  Let's begin!"
					
					As he says this to you, he tosses you a dagger.
					*if (showstats)
						*line_break
						(Gained Dagger)
					*set dagger true
				*choice
					#Train under Eagarro to become a Blademaster.
						Your days are suddenly filled with hours upon hours of training.  Eagarro knows every form and stance that you have ever heard of, and a thousand more that you haven't.  He teaches you the best counter to each of them.  In addition to showing you this, he has you doing some of the strangest drills you have ever heard of.  You stand on one foot at the top of a tower every morning, you have rocks tied to your arms for a week and you are forced to balance through a home-made obstacle course as the short man throws fruits at your head.
						*if (showstats)
							*line_break
							(Gained Level in Blademaster, Blades +20 and Agility +15)
						*set class_blademaster 1
						*achieve prestige
						*set blades +20
						*set agility +15
						*set title "Blademaster"
						
						"When a student is ready, a master appears," he says near the end of your training.  "The true art of the blade is in decline.  Don't waste your energy using a shield.  You have two hands; use two blades!  It was nice knowing you…good day!"
						
						To your surprise, the little man walks away from you without another word.  When you ask him if your training is over, he laughs out loud.
						
						"Keep training!" he calls over his shoulder.  "A Blademaster never stops learning.  When a student is ready…a master appears!  Maybe it will be Eagarro once again!"
						
						Your teacher doesn't return during your time in Ludd.  You are now easily the best swordsman you have ever met…except for Eagarro himself.  But, you wonder, are you truly a Blademaster, or has your training only begun?
						*goto After_Ludd_Job
					#Decline the training.
						"As you wish," the man says, bowing one last time before sauntering out of your keep.
						*goto Ludd_Job_loop
			#Say, "I'm honoured to meet you, and it will be my great privilege to study with you if you will have me."
				"This is good!" the little man says.
				*goto Met_Blademaster
			#Say, "You embarrassed my guards. Be gone with you!"
				The man bows to you again, smiling the entire time, and then casually saunters out of your keep.
				*goto Ludd_Job_loop
	*if (bow) #Ask Archmage Cumari to enchant your bow.
		"Enchanting weapons is a long lost art," the Archmage says.  "Learn magic and you won't even need to own a bow!"
		*if ((cumari_relationship>=75) and ((archery>=80) and (magic>=40)))
			
			Cumari pauses for a moment, studying you.  "Maybe…no.  But maybe…."
			
			You can tell that he has something on his mind, but isn't certain whether to say it.  Finally, he breaks down and tells you his thoughts.
			
			"The old tomes speak of the Elemental Archer," he says.  "A wizard who can form a magical bow from pure energy and shoot arrows of great power.  To tell you the truth, I don't see the appeal.  I'd rather cast a firebolt at someone.  But, the tomes do speak of amazing skills that I would be unable to wield.  Arrows of Earth, Fire, Air and Water…  But, the training would be intense.  If you will give me the permission to register your skill with the Academy, I may be able to teach you…even though I couldn't cast the magic myself.  Are you interested?"
			*choice
				#Have Archmage Cumari train you to become an Elemental Archer.
					He teaches you meditation and ways to think that you have never encountered before.  Your knowledge of wind, trajectories and drag are all needed as well.  He quantifies this knowledge into mathematical formulae, after consulting with his books, and teaches you to do so as well.  The day that you learn to summon your Astral Bow is truly amazing.  Although it takes magic to create, he explains that more of the energy comes from within, which is why he is unable to create such a thing himself.
					
					The Astral Bow of the Elements appears to be made of yellow light and the string shimmers in the air.  You have no need of arrows.  When you draw back the bow…an arrow appears.  You find that arrows of Earth are the easiest to create and act nearly the same as a regular arrow.  But once, after a day of practice, you create an arrow of pure Fire.  Archmage Cumari is extremely excited with your success, saying that the bow is constructed from the Astral Plane and that there is no known record of anyone with your ability in hundreds of years!  Although you have learned to do something from legends, you still wonder how much more you could do…if you had the time to practice.
					*if (showstats)
						*line_break
						(Gained Level in Elemental Archer, Magic +10 and Archery +20)
					*set class_elementalarcher 1
					*achieve prestige
					*set magic +10
					*set archery +20
					*set title "Elemental Archer"
					*goto After_Ludd_Job
				#Decline the training in the unproven field of magic.
					"I don't blame you," he says.  "I can teach you traditional magic…. I think that would be better."
					*goto Ludd_Job_loop
		*else
			*if (showstats)
				*line_break
				(Needed 75 Cumari Relationship, 80 Archery and 40 Magic)
			*goto Ludd_Job_loop
	*if (((class_cleric>0) and (god_good)) and (god_heshe!="It")) #Try to become a paladin.
		*if (((god_good) and (good<60)) or ((god_good=false) and (good>40)))
			On the day that you decide to speak to the priests of your order about your decision, your holy symbol snaps in half.  You realize that this is a sign from ${god_name} saying that ${god_heshe} will not accept you as a ${priestpriestess} any longer, let alone as a paladin.  You have been led too far astray.
			*if ((god_good) and (good<60))
				*if (showstats)
					(Needed Over 60 Good and Lost All Levels in $!{priestpriestess} and Cleric)
					*line_break
					(Lost Holy Symbol)
				*set exgoodpriest true
			*if ((god_good=false) and (good>40))
				*if (showstats)
					(Needed Over 60 Evil and Lost All Levels in $!{priestpriestess} and Cleric)
					*line_break
					(Lost Holy Symbol)
				*set exevilpriest true
			*set holysymbol false
			*set class_priest 0
			*set class_cleric 0
			*goto Ludd_Job_loop	
		The priests are content that you have the necessary faith
		*if ((class_guard=0) and (class_squire=0))
			but they aren't certain that you have the requisite combat experience.
			*if (class_cleric>1)
				When you point out that you have been a member of the militant section of your faith all this time, they suggest that you continue your studies as a cleric.  In the end, your application to become a paladin of ${god_name} is turned down.
			*if (showstats)
				(Needed Level in Guard or Level in Squire)
			*goto Ludd_Job_loop
		and combat experience for the task.  They pray for several days to ${god_name} on your behalf as you fast.  By the end of the sacred ritual, you feel a great holiness fill you as you emerge from the temple as a paladin of ${god_name}.
		*if (showstats)
			*line_break
			(Gained Level in Paladin, Religion +10, Blades +15, Strength +7 and Endurance +7)
		*set class_paladin 1
		*set title "paladin of "&god_name
		*achieve prestige
		*set religion +10
		*set blades +15
		*set strength +7
		*set endurance +7
		
		*if ((mount_name!="None") and (mount_desc="a well-trained tournament"))
			The next morning, ${mount_name} undergoes a radical transformation the likes of which you have never seen.  The mighty warhorse seems to have gained muscle and intelligence overnight.  The stablemaster can hardly believe it is the same animal.  You know that ${god_name} has blessed your steed with ${god_hisher} divine grace to be your holy mount.
			*set mount_level 6
			*achieve sweetride
			*set mount_desc "a divine"
			*set mount_type "warhorse"
			*choice
				#Continue to ${mount_himher} ${mount_name}.
					Although ${mount_heshe} now glows softly with divine grace, you continue to call ${mount_himher} ${mount_name}.
					*goto After_Ludd_Job
				#Rename your legendary mount.
					*goto Give_Name_Holy_Mount
		The next morning, a magnificent destrier is found grazing outside the temple.  This is no palfrey, courser or rouncy, such as other people ride.  This is a stallion of such noble birth that he puts any other horse you have ever seen to shame.  Nobody knows where he came from or who he belongs to.  Everyone who tries to get near the powerful animal is warned away as he rears up on his hind legs, but the moment you see him, he lowers his head to you in a noble salute.
		*choice
			*if ((mount_name!="None") and (mount_level!=6)) #Sell ${mount_name} and keep the holy stallion.
				You sell the ${mount_type} for a fair price.
				*if (showstats)
					(Gained ${mount_value} Gold and Lost ${mount_name})
					
				*set gold +mount_value
				*goto Gain_Holy_Mount
			*if ((mount_name!="None") and (mount_level=6)) #Release ${mount_name} from your service and take the stallion as your own.
				You watch in wonder as ${mount_name} leaves Ludd without instruction.  You wonder if ${god_name} has plans for your old ${mount_type}, although you never see ${mount_himher} again.
				*goto Gain_Holy_Mount
			*if (mount_name="None") #Take the mighty stallion as your own.
				*label Gain_Holy_Mount
				The holy warhorse rides faster than you have ever seen, despite the weight of your body, armour and equipment.  He is truly a miracle.
				*set mount_level 6
				*achieve sweetride
				*set mount_value 0
				*set mount_desc "a divine"
				*set mount_hisher "his"
				*set mount_heshe "he"
				*set mount_himher "him"
				*set mount_type "warhorse"
				*label Give_Name_Holy_Mount
				*temp new_mount_name "None"
				What will you call ${mount_himher}?
				*choice
					#Chivalry.
						*set new_mount_name "Chivalry"
						*goto Done_Naming_Divine_Warhorse
					#Cloud Dancer.
						*set new_mount_name "Cloud Dancer"
						*goto Done_Naming_Divine_Warhorse
					#Dawnbreak.
						*set new_mount_name "Dawnbreak"
						*goto Done_Naming_Divine_Warhorse
					#Firestorm.
						*set new_mount_name "Firestorm"
						*goto Done_Naming_Divine_Warhorse
					#Galahad.
						*set new_mount_name "Galahad"
						*goto Done_Naming_Divine_Warhorse
					#Something else.
						*label Rename_Divine_Warhorse
						*input_text new_mount_name
						*if (new_mount_name="None")
							$!{mount_heshe} will need a name.
							*goto Rename_Divine_Warhorse
						*goto Done_Naming_Divine_Warhorse

				*label Done_Naming_Divine_Warhorse
				*if (new_mount_name=mount_name)
					You decide to continue calling ${mount_himher} by the same name.
					*goto After_Ludd_Job
				*else
					${mount_name} stamps ${mount_hisher} foot happily as though to indicate that ${mount_heshe} likes ${mount_hisher} new name.
					*set mount_name new_mount_name
					*goto After_Ludd_Job
			#Release the divine animal from your service.
				The warhorse seems to understand and canters out of Ludd without a word.  Nobody sees the amazing animal again.
				*goto After_Ludd_Job
	*if (class_knight=1) #You hone your skills as a knight.
		*if (good>=70)
			You have been an exemplary knight.  Chivalrous, kind and honourable.  The people of Ludd follow you around the city and are proud of your accomplishments.  One morning, you are presented with a new set of armour from your loving people.  The plates glisten in the sun and shine brilliantly for all to see.
			*if (showstats)
				*line_break
				(Gained Level in Knight, Citizen Reputation +10, Citizen Fear -10, Army Morale +10 and Gained Silver Plate Mail)
			*set class_knight 2
			*set citizen_reputation +10
			*set citizen_fear -10
			*set army_morale +10
			*goto Knight_2
		*if ((good>=50) and (good<70))
			You have been a mediocre knight.  Mostly good, but not as good as you could have been.
			*label Get_Knight_Stuff_Anyway
			*if ((holysymbol) and (god_good=false))
				You get the impression that ${god_name} is not overly fond of you any more either.  ${god_heshe} wants true evil to be in your heart, but you have only scratched the surface.
			The people of Ludd appreciate you for your skills in combat, but they hold no great appreciation of your valour as a knight.  One morning, your companions present you with a new set of armour they found in the Ludd treasury, thinking that it would fit you perfectly.  The plates glisten in the sun and shine brilliantly for all to see.
			*if (showstats)
				(Needed 70 Good or 70 Evil)
				*line_break
				(Gained Level in Knight and Gained Silver Plate Mail)
			*set class_knight 2
			*goto Knight_2
		*if ((good>30) and (good<50))
			You have been a poor knight.  You are the type of knight that gives the others a bad name.  You don't follow the knight's code, but you do just enough so nobody can take away your knighthood.  
			*goto Get_Knight_Stuff_Anyway
		*comment Very Evil!
		*if ((holysymbol=false) or ((holysymbol) and (god_good)))
			You have been a truly evil knight, but you are alone in the world.  There are evil Gods and Goddesses who would have made you into something powerful, had you been a believer.  At least your actions have not been noticed so nobody tries to take away your knighthood.
			*if (showstats)
				(Needed to Follow an Evil God or Goddess)
			
			*goto Get_Knight_Stuff_Anyway
		One morning, Sir Raymond, a knight from Ludd, visits you in your room.  He has a serious expression on his face.
		
		"I know what you have done," he says.  "You will come with me now.  I am afraid that your time as a false knight has come to an end."
		
		You aren't sure what crime or deed Sir Raymond knows about, or thinks you have done.  But, you know that he has the authority to undo you.  By his word, a full inquisition into all of your actions could be initiated and your knighthood stripped away….  But, you also know that in his naivety and honour, he has come to you first…and alone.  You also know that the time for hiding could be at an end.  You have taken Ludd and you have an army at your command.  You could become what you wish and nobody could stop you.
		*choice
			#Kill Sir Raymond and become a Dark Knight.
				Sir Raymond doesn't see the blade that kills him.  Because he is such a good and honourable person, he doesn't understand the darkness in your heart.  He falls at your feet and you feel a great relief.  You don't even bother to hide the fact that you killed the man.  At first, ${squire_name} and your companions are uncertain as to what you have become, but with all of your power, they slowly come to understand your true nature.  You feel a dark coldness enter your heart as ${god_name} wraps ${god_hisher} evil hand around your very soul.
				*if (showstats)
					*line_break
					(Evil +20, Gained Level in Dark Knight and Citizen Fear +50)
				*set good -20
				*set class_darkknight 1
				*achieve prestige
				*set title "Dark Knight"
				*set class_knight 0
				*set citizen_fear +50
				
				As you walk the streets of Ludd people cower from your might.  A few days after killing Sir Raymond, a gift appears in your room.  The plate mail is made from some dark metal and seems to pull the light from the room.  It is masterfully crafted and harder than any steel you have seen before.  With a wicked smile creeping on your face, you put on your new armour.
				*if (showstats)
					*line_break
					(Gained Dark Plate Mail)
				*goto Knight_2
			#Apologize to Sir Raymond and beg his forgiveness as you give up your knighthood.
				Sir Raymond listens sadly to your words.  Once more, his own honour as a knight sways his actions.  Instead of exposing your past, he accepts your words at face value.  You are able to give up your knighthood without Sir Raymond telling anyone why.  ${squire_name}, your squire, is assigned to someone else.  This all occurs in the first few days of your arrival in Ludd, allowing you to pursue other goals.
				*if (showstats)
					*line_break
					(Lost All Levels in Knight and Squire, Good +20 and Citizen Fear -20)
				*set class_squire 0
				*set class_knight 0
				*set good +20
				*set citizen_fear -20
				*set squire_name "None"
				*goto Ludd_Job_loop
		
		*label Knight_2
		
		You practice with your blade every day, strengthening your physical, mental and spiritual skills into something legendary.  You know that stories will be told of your abilities and deeds.  In addition, a knightly tournament is held in Ludd.  You don't know the squire who gets knighted, but you
		*if (class_knight=0)
			*comment Dark Knight
			do well in your own events and collect some prize money.
			*if (showstats)
				*line_break
				(Blades +15, Strength +10, Endurance +10 and Gold +150)
			*set gold +150
		*if (class_knight=2)
			win the knight's tournament itself, which helps to solidify you as one of the top knights in the land.
			*if (showstats)
				*line_break
				(Blades +15, Strength +10, Endurance +10 and Gold +400)
			*set gold +400
			*set title "knight champion"
			*achieve topclass
		*set blades +15
		*set strength +10
		*set endurance +10
		*goto After_Ludd_Job
	*if (class_bard>0) #You play songs and write new ones as a bard.
		*if (lute=false)
			One of your many fans delivers a lute to your room at the keep.
			*set lute true
		You craft many songs and play them before your audiences.  The people of Ludd, including those who came with you and those who were there when you arrived, are all happy to gather in your keep to hear them.
		*if (class_bard=3)
			Many of the songs you play will stand the test of time and be heard all through the ages.  The ability to sway the minds of the masses becomes very clear to you as a magical quality suffuses your melodies.
		*if (class_bard<3)
			You can't help but notice that your songs are becoming more than simple melodies.  A magical undertone has arisen within your music which you have difficulty explaining.
		*if (showstats)
			*line_break
			(Gained Level in Bard, Charm +10, Magic +10, History +15 and
			*if (class_bard=1)
				Gold +125)
			*if (class_bard=2)
				Gold +200)
			*if (class_bard=3)
				Gold +300)
		*if (class_bard=1)
			*set gold +125
			*set title "bard"
		*if (class_bard=2)
			*set gold +200
			*set title "mystical bard"
		*if (class_bard=3)
			*set gold +300
			*set title "legendary mystical bard"
		*set charm +10
		*set magic +10
		*set history +15
		*set class_bard +1
		*if (class_bard=4)
			*achieve topclass
			
			Your place in history is assured as your words spread across the land.
			*if (showstats)
				(History +15, Citizen Reputation +15 and Army Morale +15)
			*set citizen_reputation +15
			*set army_morale +15
			*set history +15
		*goto After_Ludd_Job
	*if ((class_thief=0) and (no_thief_vow=false)) #You join the Thieves Guild.
		*label Do_Thief_Stuff
		The Thieves Guild in Ludd finds your presence uncomfortable at first, but when they see that you are sincere, they rejoice in your decision to join them.  You pay your fees to the Guild as you do your jobs, which means that they will help you if you ever run into trouble during a heist.  They also train you in the art of thievery.
		*if (showstats)
			*line_break
			(Gained Level in Thief, Stealth +15, Devices +10, Agility +10, Blades +5 and
			*if (class_thief=0)
				Gold +100)
			*if (class_thief=1)
				Gold +150)
			*if (class_thief=2)
				Gold +200)
			*if (class_thief=3)
				Gold +300)
		*if (class_thief=0)
			*set gold +100
		*if (class_thief=1)
			*set gold +150
		*if (class_thief=2)
			*set gold +200
		*if (class_thief=3)
			*set gold +300
		*set class_thief +1
		*set stealth +15
		*set devices +10
		*set agility +10
		*set blades +5
		*set title "thief"
		*if (class_thief=4)
			*achieve topclass
			
			One day, when returning to the Guild to pay them their share of a particular good heist, you are surprised to see many of the thieves gathered and waiting for you.  Wary at first, you are surprised when they offer you the greatest promotion any thief could ever ask for: the position of Guildmaster of the Thieves Guild!  You later learn that the old Guildmaster retired happily in the country outside of Brightwater with acres of good land and a mansion.  Due to your conflicting role as ${princeprincess}, your duties are to be held until the end of the war.  But to support you in this goal, the thieves help the war effort by joining you, providing your army with food and by not stealing from your troops.
			*if (showstats)
				*line_break
				(Army Food +10, Army Size +10 and Army Power +10)
			*set army_food +10
			*set army_size +10
			*set army_power +10
			*set title "Guildmaster of the Thieves Guild"
		*goto After_Ludd_Job
	*if (class_thief>=1) #You perform many jobs for the Thieves Guild.
		*goto Do_Thief_Stuff
	#You take on the role of commander in your army, helping to guard your troops and the army camps.
		*if (class_guard>0)
			Your previous work as a guard makes you a good commander.
		You work hard with the troops every day, teaching them to use their blades and making them better soldiers.  You also go out on patrols with them, scouting the land around Ludd and making sure that Selina's troops don't try to attack you by surprise.
		*if (sword=false)
			You are given a sturdy sword by the quartermaster for your own use.
		On pay day, you are given a stipend from the army budget for fulfilling your duties.
		*if (showstats)
			*line_break
			(Gained Level in Guard, 
			*if (sword=false)
				Sword,
			Blades +10, Endurance +10, Strength +10, Army Power +5, Army Morale +5 and
			*if (class_guard=0)
				Gold +100)
			*if (class_guard=1)
				Gold +125)
			*if (class_guard=2)
				Gold +150)
			*if (class_guard=3)
				Gold +175)
		*if (class_guard=0)
			*set gold +100
		*if (class_guard=1)
			*set gold +125
		*if (class_guard=2)
			*set gold +150
		*if (class_guard=3)
			*set gold +175
		*set sword true
		*set class_guard +1
		*set title "commander"
		*set blades +10
		*set endurance +10
		*set strength +10
		*set army_power +5
		*set army_morale +5
		*if (class_guard=4)
			*achieve topclass
			
			General Vale meets you in the training yard one day with some amazing news.  He says that your abilities as a commander far exceed anyone else in the army and that he wishes to promote you to lieutenant.  As the ${princeprincess} of Daria, you already have full command of the army, but having rightfully earned the title of lieutenant causes your entire army to burst into applause.  You have some extra reading to do, as part of your training, but it's well worth the effort.  Your troops beam with pride during the ceremony  which accompanies your promotion.
			*set title "lieutenant"
			*if (showstats)
				*line_break
				(Charm +10, History +10, Geography +10, Army Morale +10, Army Power +10, Citizen Reputation +10 and Citizen Fear -15)
			*set charm +10
			*set history +10
			*set geography +10
			*set army_morale +10
			*set army_power +10
			*set citizen_reputation +10
			*set citizen_fear -15
		*goto After_Ludd_Job
	*if (((class_priest=0) and (holysymbol)) and ((exgoodpriest=false) and (exevilpriest=false))) #You follow your religious convictions and try to become a ${priestpriestess}.
		*if (((god_good) and (good<60)) or ((god_good=false) and (good>40)))
			As you pray upon your decision, your holy symbol snaps in half.  You realize that this is a sign from ${god_name} saying that ${god_heshe} will not accept you as a ${priestpriestess}.  You wonder if all new clergy are tested this way, or if you are being held to a higher standard due to your position as the ${princeprincess} of Daria.
			*if ((god_good) and (good<60))
				*if (showstats)
					(Needed More than 60 Good)
					*line_break
					(Lost Holy Symbol)
				*set exgoodpriest true
			*if ((god_good=false) and (good>40))
				*if (showstats)
					(Needed More than 60 Evil)
					*line_break
					(Lost Holy Symbol)
				*set exevilpriest true
			*set holysymbol false
			*goto Ludd_Job_loop	
		The temples of Ludd house all of the different Gods and Goddesses of the land.  You are a little old to hear the call, but you are ordained as a ${priestpriestess} all the same.  You receive a modest stipend as you perform several minor functions for your followers.
		*if (god_good=false)
			Your evil ${god_goddess} has a thriving community in the bowels of the city where you are accepted into the dark religion.
		*if (showstats)
			*line_break
			(Gained Level in $!{priestpriestess}, Religion +20, Charm +5, Magic +10 and Gold +100)
		*set class_priest 1
		*set religion +20
		*set charm +5
		*set magic +10
		*set gold +100
		*set title priestpriestess
		*goto After_Ludd_Job
	*if ((class_priest>=1) and (god_heshe="It")) #Spread the word of your new Unknown deity.
		The people of Ludd are ready for change.  War has always brought people to religion, so it is a ripe time for your Unknown deity to rise!  A new temple is built and many new priests, high priests and bishops are ordained.
		*goto Continue_Priest
	*if (((class_priest>=1) or (class_cleric>=1)) and (god_heshe!="It")) #You join the local temple dedicated to ${god_name} and continue your vocation as a ${priestpriestess}.
		*if (((god_good) and (good<60)) or ((god_good=false) and (good>40)))
			As you enter the temple, your holy symbol snaps in half.  You realize that this is a sign from ${god_name} saying that ${god_heshe} will not accept you as a ${priestpriestess} any longer.  You have been led too far astray.
			*if ((god_good) and (good<60))
				*if (showstats)
					(Needed More than 60 Good and Lost All Levels in $!{priestpriestess} and Cleric)
					*line_break
					(Lost Holy Symbol)
				*set exgoodpriest true
			*if ((god_good=false) and (good>40))
				*if (showstats)
					(Needed More than 60 Evil and Lost All Levels in $!{priestpriestess} and Cleric)
					*line_break
					(Lost Holy Symbol)
				*set exevilpriest true
			*set holysymbol false
			*set class_priest 0
			*set class_cleric 0
			*goto Ludd_Job_loop	
		The temples of Ludd house all of the different Gods and Goddesses of the land.
		*if (god_good=false)
			Your evil ${god_goddess} has a thriving community in the bowels of the city.
		*label Continue_Priest
		*choice
			#You deliver spiritual sermons.
				Your sermons are very introspective and life changing as you lead the worship of your congregation.  A portion of the gold donated to your temple goes to you as a stipend for your work.
				*if (showstats)
					*line_break
					(Gained Level in $!{priestpriestess}, Religion +15, Magic +10, Charm +10 and Gold +100)
				*set religion +15
				*set magic +10
				*set charm +10
				*set gold +100
				*set class_priest +1
				*set title priestpriestess
				*if (class_priest=3)
					*set title "high "&priestpriestess
				*if (class_priest=4)
					*achieve topclass
					
					One day, several bishops and high priests of your order arrive at your temple.  They all claim to have had a visit by ${god_name}.  In all of their dreams and visions, they were told that you were to be chosen as the new Archbishop.  They all bow to you as they lift their voices to your shared ${god_goddess}.  Their faith brings you the strength to work even harder to fulfill your ${god_goddess}'s divine will.
					*if (showstats)
						*line_break
						(Religion +15, Magic +7 and Charm +7)
					*set religion +15
					*set magic +7
					*set charm +7
					*set title "archbishop"
				*goto After_Ludd_Job
			#You lead a very militaristic sect of your order.
				You preach about action and lead by example as you promote the use of force to impose the will of your ${god_goddess}.  A portion of the gold donated to your temple goes to you as a stipend for your work.
				*if (showstats)
					*line_break
					(Gained Level in Cleric, Religion +10, Blades +10, Strength +5, Endurance +5 and Gold +100)
				*set religion +10
				*set blades +10
				*set strength +5
				*set endurance +5
				*set gold +100
				*set title "cleric"
				*set class_cleric +1
				*if (class_cleric=3)
					*achieve topclass
					
					One day, several bishops and high priests of your order arrive at your temple.  They all claim to have had a visit by ${god_name}.  In all of their dreams and visions, they were told that you were to be chosen as the new Holy Fist, the highest military position within your order.  They all bow to you as they lift their voices to your shared ${god_goddess}.  Their faith brings you the strength to work even harder to fulfill your ${god_goddess}'s divine will.
					*if (showstats)
						*line_break
						(Religion +15, Blades +7, Strength +5, Endurance +5 and Agility +5)
					*set title "Holy Fist"
					*set religion +15
					*set blades +7
					*set strength +5
					*set endurance +5
					*set agility +5
				*goto After_Ludd_Job
	*if (class_monk>0) #You meditate and practice your forms as a monk.
		You think upon your life and how you have been given the opportunity to make great changes in the world.  Your body becomes stronger and your mind becomes more perceptive of your surroundings.
		*if (holysymbol=false)
			Although you have no need of any formal religions, you understand more about deities and their place in the natural world.
		*if (holysymbol)
			You understand more about ${god_name}'s place in the natural world.
		*if (showstats)
			*line_break
			(Gained level in Monk, Strength +5, Agility +10, Unarmed +10, Endurance +7 and Religion +5)
		*set class_monk +1
		*set strength +5
		*set agility +10
		*set unarmed +10
		*set endurance +7
		*set religion +5
		*set title "monk"
		*if (class_monk=4)
			*achieve topclass
			
			You suddenly find yourself elsewhere.  You are without form as your consciousness washes over the land.  You can suddenly see and hear everything…and nothing.  You become more at peace with yourself than ever before.  When you open your eyes, you see that you are hovering a foot off the ground.  You smile as you realize that you have reached a new level of consciousness and enlightenment.
			*if (showstats)
				*line_break
				(Perception +20)
			*set perception +20
			*set title "enlightened monk"
		*goto After_Ludd_Job
	*if (class_wizard=0) #Speak to Archmage Cumari about learning to become a wizard.
		*if (spellbook)
			"You know, we of the Academy do not approve of these illegal spellbooks," he says with a frown, referring to the one you are carrying.  "But, as Archmage, I can grant you acceptance into the Academy community.  Here, let me replace this with an Academy approved spellbook."
			*if (showstats)
				*line_break
				(Archmage Cumari Relationship -10)
			*set cumari_relationship -10
		*if (spellbook=false)
			"I am overjoyed to hear this!" he exclaims.  "As Archmage, I can grant you acceptance into the Academy community.  Let me begin by giving you an Academy approved spellbook."
			*if (showstats)
				*line_break
				(Gained Spellbook and Archmage Cumari Relationship +3)
			*set cumari_relationship +3
			*set spellbook true
		
		He admits that he is very glad that you have come to him and is eager to "legitimize" your magical training under the umbrella of the Academy.
		*label Ludd_StartWizard
		Archmage Cumari's role as Archmage was given to him due to his advanced knowledge of magic and his ability to communicate to the people of the Academy.  These two skills compliment each other to make him an excellent teacher. 
		*if (showstats)
			*line_break
			(Gained Level in Wizard, Magic +15, History +10 and Arcana +10)
		*set magic +15
		*set history +10
		*set arcana +10
		*set class_wizard +1
		*set title "wizard"
		*if (class_wizard=3)
			*achieve topclass
			*set title "master wizard"
			
			"${name}," he says after you have been studying with him for several weeks.  "I'd like to show you some special books.  As a master wizard, I think you might be able to understand them better than me."
			
			It is at this point that you realize that you are truly a master of your craft and one of the most powerful magical practitioners in all of Daria.
			*if (showstats)
				*line_break
				(Magic +15 and Arcana +15)
			*set magic +15
			*set arcana +15
		*if (companion_name!="None")
			*goto After_Ludd_Job
		
		*if (class_wizard=1)
			"As a wizard," he says,  "you have the ability to bond a creature as a familiar.  Are you interested in such a thing?  I should warn you, it can only be done once in a lifetime."
		*if (class_wizard>1)
			"I am surprised that you have not bonded a familiar yet," he says.  "Perhaps you are like me and find the concept that we may only bond once in a lifetime to be terribly nerve-wracking.  If you wish to make the bond, I could help you with the spell."
		*choice
			#You use the spell to bond a male cat.
				A feline companion is a very popular choice for a wizard, likely due to their ease of bonding.
				*set companion_hisher "his"
				*set companion_heshe "he"
				*set companion_himher "him"
				You send a servant to find you a suitable cat and they return with a handsome looking male.
				*goto Bond_Cat
			#You use the spell to bond a female cat.
				A feline companion is a very popular choice for a wizard, likely due to their ease of bonding.
				*set companion_hisher "her"
				*set companion_heshe "she"
				*set companion_himher "her"
				You send a servant to find you a suitable cat and they return with a beautiful looking female.
				*label Bond_Cat
				*set companion_travels "pads along beside you"
				*set companion_type "cat"
				*set companion_familiar true
				
				You decide to name ${companion_himher}:
				*label Name_Cat
				*input_text companion_name
				*if (companion_name="None")
					That's a terrible name for a cat.  You decide to name ${companion_himher} something else instead.
					*goto Name_Cat
				The creature seems to like what you call ${companion_himher} and ${companion_travels}.
				*goto After_Ludd_Job
			#You use the spell to bond a male raven.
				*set companion_hisher "his"
				*set companion_heshe "he"
				*set companion_himher "him"	
				*goto Bond_Raven
			#You use the spell to bond a female raven.
				*set companion_hisher "her"
				*set companion_heshe "she"
				*set companion_himher "her"	
				*label Bond_Raven
				Archmage Cumari commends you on the choice of the raven.  You send an army forester out into the plains of Ludd to find you the bird.
				*set companion_type "raven"
				*set companion_travels "flies overhead"
				*set companion_familiar true
				
				You decide to name ${companion_himher}:
				*label Name_Raven
				*input_text companion_name
				*if (companion_name="None")
					That's a terrible name for ${companion_himher}!
					*goto Name_Raven
				The bird seems to like what you call ${companion_himher} and ${companion_travels}.
				*goto After_Ludd_Job
			#You decide to not use the spell in case you find something more suitable in the future.
				Archmage Cumari nods wisely, agreeing with your choice to wait.
				*goto After_Ludd_Job
	*if (class_wizard>=1) #Ask Archmage Cumari to train you in the arts of wizardry.
		*if (class_wizard=2)
			"I am honoured that you have come to me," Archmage Cumari says with a smile.  "In truth, I believe that I will learn as much from you as you will from me.  Your mystical accomplishments are becoming quite amazing.
			*if (showstats)
				*line_break
				(Archmage Cumari Relationship +10)
			*set cumari_relationship +10
			*goto Ludd_ResumeWizard
		*else
			"Certainly," Archmage Cumari says with a smile.
			*if (showstats)
				*line_break
				(Archmage Cumari Relationship +5)
			*set cumari_relationship +5
			*label Ludd_ResumeWizard
			*if (spellbook=false)
				
				"Let's begin by getting you an Academy approved spellbook," he says as he hands you a tome on the first day you begin to work together.
				*if (showstats)
					(Gained Spellbook)
			
			*set spellbook true
			*goto Ludd_StartWizard
	*if (class_druid>=1) #You spend your time communing with nature outside of Ludd as a druid.
		The plains of Ludd have their own unique ecosystem and animals, as all places do.  You pass through the land calmly and confidently, alarming your scouts when you suddenly pop up unexpectedly.
		*if (showstats)
			*line_break
			(Gained Level in Druid, Stealth +7, Endurance +5, Perception +7, Nature +10, Geography +5 and Magic +7)
		*set class_druid +1
		*set stealth +7
		*set endurance +5
		*set perception +7
		*set nature +10
		*set geography +5
		*set magic +7
		*set title "druid"
		*if (class_druid=3)
			*achieve topclass
			
			You begin to notice several changes in you as you speak to the other druids you meet in the wild.  One thing you see is that you appear to have stopped aging.  The other is that you rarely leave footprints when you are in a natural setting.  But the biggest change occurs the day that you are watching a herd of gazelles so intently that when they began to run away from a predator, you follow.  The amazing thing was that you kept up!  It wasn't until several minutes later that you realized that you were no longer human.  You had assumed the form of the animal you were watching.  You reverted back to human form shortly after, but you believe that the ability is still there.  The other druids begin to call you the Archdruid, although no such formal hierarchy exists.
			*if (showstats)
				*line_break
				(Nature +15, Stealth +10 and Magic +10)
			*set nature +15
			*set stealth +10
			*set magic +10
			*set title "Archdruid"
		*goto Ludd_companion
	*if (class_ranger>=1) #You roam over the lands around Ludd as a ranger.
		*if (bow=false)
			The army quartermaster gives you a bow, when he sees that you have lost yours.
			*set bow true
		You wander the plains far and wide, your legs taking comfortable strides that eat up the distance between.  You easily take down birds and animals at will and find food among the plant life.  When you finally return to Ludd, you realize that your skills as a hunter are even better than before.
		*if (showstats)
			*line_break
			(Gained a Level in Ranger, Nature +10, Stealth +10, Blades +5, Archery +10 and Geography +10)
		*set class_ranger +1
		*set nature +10
		*set stealth +10
		*set blades +5
		*set archery +10
		*set geography +10
		*set title "ranger"
		*if (class_ranger=3)
			*achieve topclass
			
			One day a commander in your army is complaining that an animal is getting into the food stores.  You search the area and find some tracks.  You lead the commander and several of his troops across the empty plains, over dry rocks and into a canyon bed.  The soldiers are laughing by the end of the journey, saying that it is impossible to track the way you are claiming.  When you reach into a prairie-dog hole in the ground and extract some of the missing food, they are astounded.  Word spreads quickly of your skills as the best tracker in all of Daria.  You also turn the potential food shortage into a food gain as you help the soldiers hunt the small animals for their meat.  As the soldiers see you hunting in the distance, they begin calling you the Horizon Walker.
			*if (showstats)
				*line_break
				(Perception +20 and Army Food +10)
			*set perception +20
			*set title "Horizon Walker"
			*set army_food +10
		*label Ludd_companion
		*if (companion_type="None")
			
			During your travels, you stumble upon a few animals which want to follow you, although you know that you can take only one.
			*rand coinflip 1 2
			*comment Rand covered.
			*if (coinflip=1)
				*set companion_hisher "his"
				*set companion_heshe "he"
				*set companion_himher "him"
			*if (coinflip=2)
				*set companion_hisher "her"
				*set companion_heshe "she"
				*set companion_himher "her"
			*choice
				#A small red fox.
					The fox is curious and quick as ${companion_heshe} trots along beside you.
					*set companion_type "fox"
					*set companion_familiar false
					*set companion_travels "trots along beside you"
					*label Ludd_KeepIt
					*choice
						#You keep the ${companion_type}.
							You decide to name ${companion_himher}:
							*label Rename_Companion_Ranger_Druid
							*input_text companion_name
							*if (companion_name="None")
								That's not a good name for ${companion_himher}.
								*goto Rename_Companion_Ranger_Druid
							The creature seems to like what you call ${companion_himher} and ${companion_travels}.
							*goto After_Ludd_Job
						#You shoo the ${companion_type} away.
							*set companion_type "None"
							Although it might have been nice to have had a small piece of nature with you wherever you went, you decide to send ${companion_himher} away.
							*goto After_Ludd_Job
				#A brown hawk.
					The hawk lands right on your shoulder as you stand in the middle of the plains.
					*set companion_type "hawk"
					*set companion_familiar false
					*set companion_travels "flies overhead"
					*goto Ludd_KeepIt
				*if ((class_druid=3) or (class_ranger=3)) #A ferocious bobcat.
					The bobcat is silent, deadly and totally enthralled with your presence.
					*set companion_type "bobcat"
					*set companion_familiar false
					*set companion_travels "pads silently along beside you"
					*goto Ludd_KeepIt
		*else
			*goto After_Ludd_Job
	*if (class_assassin>0) #You contact the Guild of Assassins and fill some contracts.
		The garden is always in need of weeding.  Your position allows you access into many areas of Ludd that others can't reach, although your contracts are for nobles and commoners alike.  Whoever has enough money to buy the contract can name another's death, and like the Gods, you kill indiscriminately.
		*if (showstats)
			(Gained Level in Assassin, Stealth +10, Devices +10, Nature +10, Blades +10 and Gold +300)
		*set class_assassin +1
		*set stealth +10
		*set devices +10
		*set nature +10
		*set blades +10
		*set gold +300
		*set title "assassin"
		*if (class_assassin=4)
			*achieve topclass
			
			After completing a particularly tricky contract, your guild contact informs you that you have risen to the very top of the list.  You have become the most skilled assassin in Daria and will be assigned the most prestigious contracts in the future.
			*if (showstats)
				*line_break
				(Stealth +15, Devices +10 and Gold +200)
			*set title "top assassin"
			*set stealth +15
			*set devices +10
			*set gold +200
		*goto After_Ludd_Job
	#You offer your services as a sage.
		The change of leadership in Ludd causes many uncertainties, meaning that many people have questions.  Sages are in high demand and people are willing to pay good coin for their services.
		*if ((arcana<40) and (class_sage=0))
			Unfortunately, your clients quickly learn that you don't know as much as they had hoped, so they stop hiring you.  Your life as a sage is extremely short-lived.
			*if (showstats)
				(Needed 40 Arcana)
			*goto Ludd_Job_loop
		*if (showstats)
			*line_break
			(Gained Level in Sage, Arcana +10, History +10, Geography +10, Nature +10 and
			*if (class_sage=0)
				Gold +200)
			*if (class_sage=1)
				Gold +250)
			*if (class_sage=2)
				Gold +350)
		*set arcana +10
		*set history +10
		*set geography +10
		*set nature +10
		*if (class_sage=0)
			*set gold +200
		*if (class_sage=1)
			*set gold +250
		*if (class_sage=2)
			*set gold +350
		*set class_sage +1
		*set title "sage"
		*if (class_sage=3)
			*achieve topclass
			
			You realize before long that your knowledge far surpasses the other sages in Ludd, and as such, you can charge much more.  Your knowledge of the obscure and practical makes you very highly sought after as you are able to find things others can't.
			*if (showstats)
				*line_break
				(Perception +20 and Gold +200)
			*set perception +20
			*set gold +200
			*set title "master sage"
		*goto After_Ludd_Job
	#Offer your service as a basher of skulls to the highest bidder.
		*if ((class_thug=0) and (strength<30))
			Your role is mostly intimidation, although you do occasionally need to break some bones to get the point across.  Unfortunately, you aren't very tough looking.  Nobody wants to hire a thug who looks weak, since such a person will constantly need to prove that they aren't.
			*if (showstats)
				(Needed 30 Strength)
			*goto Ludd_Job_loop
		You get hired for many reasons, from bodyguard to money collector.  As the ${princeprincess}, you have a lot of clout, but as hired muscle, you use a more physical form of coercion.  Your clients appreciate your ability to force others to do as needed. 
		*if (showstats)
			*line_break
			(Gained Level in Thug, Blades +10, Unarmed +15, Strength +15 and
			*if (class_thug=0)
				Gold +50)
			*if (class_thug=1)
				Gold +75)
			*if (class_thug=2)
				Gold +100)
			*if (class_thug=3)
				Gold +200)
		*if (class_thug=0)
			*set gold +50
		*if (class_thug=1)
			*set gold +75
		*if (class_thug=2)
			*set gold +100
		*if (class_thug=3)
			*set gold +200
		*set blades +10
		*set unarmed +15
		*set strength +15
		*set class_thug +1
		*set title "hired muscle"
		*if (class_thug=4)
			*achieve topclass
			
			The best thugs never have to do a thing.  By their presence alone, they are able to intimidate and force cooperation.  This means that the best protectors have a strong reputation for being dangerous and you are the best.  Although you would likely win most altercations you find yourself in, you are rarely tested.  This means that you spend less time injured and more time training to become even stronger.
			*if (showstats)
				*line_break
				(Strength +25)
			*set strength +25
			*set title "Intimidator"
		*goto After_Ludd_Job
	*if (demonsummoner) #Focus all of your time on learning to become a better demon summoner.
		You know that the training that people receive in Vernex with the Consortium of Planewalkers is much better than what you've managed to eke out, but you still continue to improve.  You find a few people who are willing to teach you a little of what they know.  Unfortunately, the ones you find are the dropouts and failures, so you don't learn as much as you would have liked.
		*if (showstats)
			*line_break
			(Willpower +10 and Arcana +30)
		*set willpower +10
		*set arcana +30
		*set title "demon summoner"
		*if (willpower>=70)
			*achieve knowenemy
			
			*set title "iron-willed demon summoner"
			Despite your lack of official training, you have managed to attain an iron will.  Your ability to control and command demons would rival the best summoners of the Consortium, you are told.  This mental fortitude gives you the ability to push yourself past your natural limits.
			*if (showstats)
				(Endurance +25)
			*set endurance +25
		
		You build a summoning room as they use in Vernex: two cages on opposite ends of the room.  One for the summoner and one for the demon.  Your companions agree to hold the spears and stand outside the demons' cage, ready to return any poorly summoned creatures back to their own plane of existence.
		*label Demon_Summoner_loop
		*choice
			*if (demonstone_xiatta) #Summon Xi'atta.
				*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
				*comment: End of Pt. 2, Min 45 Max 75, 55 min here
				Xi'atta appears within the cage. Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
				
				"Hello, ${mastermistress}," Xi'atta says.
				
				Xi'atta is fully under your control.  You return the frosty demon to its own realm, content that it is yours to command.
				*set demonstone_xiatta_summoned true
				*goto Demon_Summoner_loop
			*if (demonstone_brahl) #Summon Brahl.
				*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
				*comment: End of Pt. 2, Min 45 Max 75, 55 min here
				Brahl appears in its cage.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
				*set demonstone_brahl_summoned true
				
				*if (willpower>=70)
					"Yes, ${mastermistress}," Brahl says.
					
					The being pushes against your will, but you easily brush its desires aside.  The brawny demon is entirely yours to control.  You release it with a mental command and it returns to its own plane of existence.
					
					Your companions all applaud as the demon disappears.  You realize that your willpower has become ironclad.  Despite your do-it-yourself training, you have become a master demonsummoner.
					*goto Demon_Summoner_loop
				*if (willpower>=60)
					"What do ya want, ${mastermistress}?" Brahl asks.
					
					The demon pushes against your will and you push back.  You realize that you are no longer in any danger of losing a mental battle with this demon and could probably force it into doing things it doesn't want to do.  But, if Brahl really wants to refuse you, it probably could.  You release it with a command and it returns to its own plane of existence.
					*if (showstats)
						(Needed 70 Willpower)
					*goto Demon_Summoner_loop
				"What?" Brahl asks rudely.
				
				The demon pushes against your will and you push back.  You realize that you are no longer in any danger of losing a mental battle with this demon, but that forcing it to do your will would be difficult.  You release it with a command and it returns to its own plane of existence.
				*if (showstats)
					(Needed 60 Willpower)
				*goto Demon_Summoner_loop
			*if (demonstone_zonch) #Summon Zon'ch.
				*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
				*comment: End of Pt. 2, Min 45 Max 75, 55 min here
				Zon'ch appears amidst a small cyclone, but still within its cage.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
				*set demonstone_zonch_summoned true
				
				"Yes, ${mastermistress}," Zon'ch says in its raspy voice.
				
				You feel confident that you have Zon'ch entirely under your control.  You could force the demon to do anything and it would have to comply.  Content with your mastery, you return the demon to its own plane.
				*goto Demon_Summoner_loop
			*if (demonstone_daanda) #Summon Daan'da.
				*comment Will of 0, but very stupid and weak.
				*comment: End of Pt. 2, Min 45 Max 75, 55 min here
				Daan'da appears in its cage.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
				*set demonstone_daanda_summoned true
				
				"Okay, ${mastermistress}," Daan'da says, even though you haven't asked it anything.
				
				This demon is different from the others.  It came from the Som'Reth ruins and not from Zusak's runebag.  The drop-outs from the Consortium that you have recruited to teach you find this interesting.  They have only ever used Consortium Demonstones.  This particular one had sat idle for hundreds of years before you found it.  With a mental command, you send Daan'da back to its own plane.
				*goto Demon_Summoner_loop
			*if (demonstone_tyborr) #Summon Tyborr.
				*comment Tyborr: Willing: 80, Small Struggle: 90, Against: 100
				*comment: End of Pt. 2, Min 45 Max 75
				Tyborr appears in its cage, wearing its brown robes.  The small five-and-a-half foot tall demon looks more like an old man with two stubby horns than a monster.
				
				"Why do you insist on calling me?" it says in a sad voice.  "I will not aid you.  I will never aid you."
				*if (showstats)
					(Needed 80 Willpower, which is not possible at this time)
				
				Its will is much greater than your own, but instead of taking control of you, it simply disappears.
				
				This demon is different from the others.  It came from the Som'Reth ruins and not from Zusak's runebag.  The drop-outs from the Consortium that you have recruited to teach you find this interesting.  They have only ever used Consortium Demonstones.  This particular one had sat idle for hundreds of years before you found it. 
				*goto Demon_Summoner_loop
			*allow_reuse #Stop practising.
				*goto DemonSummoner2
		
		*label DemonSummoner2
		You put away your others stones and take out the K'Girr one.  This was the stone that Alexander Zusak stole from the royal treasury on the night your parents were killed.  It was unglowing back then, but in the last year, it has gained many colours.  You concentrate upon it and feel something very large trying to move into the world.  It is like trying to push a pumpkin through a mouse hole…there is no way it is going to fit.  This feeling is much different from the first time you tried to use the Demonstone.  You don't know if this is because you have become a more accomplished summoner or if it's because the stone has begun to glow.  You put the K'Girr Demonstone back into your runebag.
		*choice
			#Summon demons from the Demonstones that Zusak has flooded your kingdom with.
				*goto DemonSummoner3
			#Ignore the weak Demonstones.
				When you were in Vernex, you saw the cart-loads full of Demonstones being sent across Daria.  You've also seen Dobbton and the terrible effects that wide-spread summoning has had.  There are thousands of these Demonstones now across Daria, but you know they are all weak and worthless.  None of them are as good as the ones you have.  It would make sense that Zusak would keep the best stones for himself.
				*goto After_Ludd_Job
		
		*label DemonSummoner3
		*set demonstone_gaabon true
		When you were in Vernex, you saw the cart-loads full of Demonstones being sent across Daria.  You've also seen Dobbton and the terrible effects that wide-spread summoning has had.  There are thousands of these Demonstones for you to look at and you summon all that you have time for.  It's great practice, but none of them seem valuable.  They are all weaker than the ones you have.  They are slow to move and don't seem very intelligent.  It would make sense that Zusak would keep the best stones for himself.
		
		Just when you are certain that there is nothing of value in the free stones that the Consortium has been sending into your kingdom, you find something different, one Demonstone that stands out from the others.  The name on the stone is "Gaa'bon" and it shimmers a faint whitish-silver.
		
		At first, the demon seems much like the others.  Gaa'bon appears in a puff of smoke and just stands there.  It is one foot tall and is sluggish and uninterested in its surroundings.  You say its name and dominate its will so it can't control you.
		
		"Yaaa?" Gaa'bon says in a slow drawl as it looks over at you from within its own cage.
		*comment Gaa'bon: Willing: 45, Small Struggle: 55, Against: 65
		*comment: End of Pt. 2, Min 45 Max 75, current min is 55 here
		*temp temp_gaabon_punched false
		*temp gaabon_askedyou false
		*label Gaabon_loop
		*choice
			#Ask, "What can you do?"
				"Uhhhh, regular stuff," it says unhelpfully.
				*goto Gaabon_loop
			#Ask, "Who are you?"
				"I'm Gaa'bon," it says slowly.  "You said my name when you summoned me."
				*goto Gaabon_loop	
			#Test its willpower by saying, "Punch yourself in the face."
				It might not be a nice thing to do, but it's a sure way to gauge how strong the demon's mental fortitude is.  You wrestle with its will
				*if (willpower<65)
					as it tries to fight you, clearly not liking the command you gave it.  It makes a compromise, lightly tapping itself in the head.  You have a lot of control over Gaa'bon, but not complete mastery.
					*if (showstats)
						(Needed 65 Willpower)
					*goto Gaabon_loop
				and take control.  The demon punches itself in the face hard enough to cause its cheekbone to swell.  You have full mastery of it.
				*set temp_gaabon_punched true
				*goto Gaabon_loop
			*if (temp_gaabon_punched) #Say, "Sorry about that. I had to know."
				"I guess," the demon says with a pout.
				*goto Gaabon_loop
			#Say, "What do you know about Alexander Zusak?"
				"I don't know that name, sorry."
				*goto Gaabon_loop
			#Say, "Who was your last master?"
				"Uhhh, don't know," he says.  "Never said his name.  Just asked me what I could do.  Asked if I could fly, make elements appear and stuff like that.
				*set gaabon_askedyou true
				*goto Gaabon_loop
			*if (gaabon_askedyou) #Ask, "Can you do any of those things he asked you?"
				"No," he says simply.  "I can't do any of that stuff."
				*goto Gaabon_loop
			#Say, "You can go now."
				Finished with testing the Demonstone and tired from having tested so many that day, you didn't send the command to mentally return it to its own plane of existence.  Gaa'bon, taking the instruction at face value, walks out of its cage.  You see the short demon walk across the room toward the exit, its cage empty.  It simply passed through the bars as though they weren't there!  Your companions lower their spears to stop the demon.
				*choice
					#Let your companions kill it.
						Gaa'bon is stabbed from several angles and disappears back to its own realm to recuperate.  You realize that you have found a hidden gem amid Zusak's refuse.  You guess that nobody at the Consortium knew about this demon's gift.  You put the new Demonstone into your own runebag, happy with your find.
						*goto After_Ludd_Job
					#Command the demon to stop.
						Gaa'bon stops in its tracks and looks over at you.  You realize that you have found a hidden gem amid Zusak's refuse.  You guess that nobody at the Consortium knew about this demon's gift.  You command the demon to return to its own realm and it vanishes.  You put the new Demonstone into your own runebag, happy with your find.
						*goto After_Ludd_Job

*label After_Ludd_Job
*rand coinflip 1 2
*comment for future baby check
*if (circlet)
	
	A few days later a commotion on the outskirts of the city gets your attention.  Runners from your army tell you that scouts have spotted a group of mounted riders approaching rapidly.  After your soldiers have surrounded them, you are summoned to speak to them.
	
	"Your Highness," the leader of the riders says with a bow as he eyes the circlet on your head.  "I have horses to sell.  These are the finest in the land.  Duke Eddan and Duchess Selina have been wanting to buy them for promissory notes instead of good hard coin.  I understand that in times of war the budgets are tight, but perhaps we can come to an arrangement?"
	*label Circlet_Get_Horses_loop
	*choice
		*selectable_if (gold>=250) #Say, "I have 250 gold to offer you as a down payment."  (Needs 250 Gold)
			"It's better than what they offered," the leader says with a smile.  "Very well. The horses are yours."
			*if (showstats)
				*line_break
				(Gold -250)
			*set gold -250
			*goto Got_Horses
		#Take the horses without payment.
			"This is robbery!" the man yells.
			*if (showstats)
				*line_break
				(Evil +10, Citizen Reputation -25 and Citizen Fear +15)
			*set good -10
			*set citizen_reputation -25
			*set citizen_fear +15
			
			The man has no choice in the matter as your soldiers take the horses away from him.
			*goto Got_Horses
		#Offer the man promissory notes in exchange for the horses.
			*if (citizen_reputation>=75)
				The man sighs.
				
				"Very well," he says.  "I suppose I should have guessed that you would offer the same.  Perhaps I should be glad that you aren't just taking them, as Duchess Selina would do.  I hope you are victorious so I can get coin for these notes."
				*goto Got_Horses
			"Your Highness," the man protests.  "I need gold, not promises."
			*if (showstats)
				(Needed 75 Citizen Reputation)
			*goto Circlet_Get_Horses_loop
		#Say, "I'm sorry, but I don't have the gold to pay you."
			The riders take their horses away.
			*goto After_Horses
	*label Got_Horses
	
	The horses are of high quality and well-fed.
	*choice
		#Use the horses to build up your cavalry.
			Your quartermaster assigns the horses where needed.  Not only will your cavalry be stronger, but your foot soldiers will also be more rested as the horses carry some of the army supplies.
			*if (showstats)
				*line_break
				(Army Power +15)
			*set army_power +15
			*goto After_Horses
		#Allow your army to butcher the animals for food.
			Your troops have no qualms about eating horse meat.  They are just happy to be fed fresh food.
			*if (showstats)
				*line_break
				(Army Food +15)
			*set army_food +15
			*goto After_Horses
*label After_Horses
*if ((prisonchild_exists) and (prisonchild_job="academy"))
	
	One morning, a letter is delivered to you from the Academy.  It is from ${prisonchild_name}'s teachers.  You are surprised to hear that ${prisonchild_heshe} is doing extremely well and is learning ${prisonchild_hisher} letters and numbers at an astounding rate.  They are still worried because ${prisonchild_heshe} has yet to speak a single word.  Despite this, they are very proud of ${prisonchild_hisher} accomplishments.  Attached to the letter is a second letter.  It has two words on it, both written in blocky, childish lettering, but the fact that they exist at all is amazing.  It says "Thanks.  ${prisonchild_name}."
	*if (showstats)
		*line_break
		(${prisonchild_name} Relationship +20)
	*set prisonchild_relationship +20
*if(((class_priest>0) and (((god_good) and (good<60)) or ((god_good=false) and (good>40)))) and (god_heshe!="It"))
	
	As the days go by, you begin to feel less and less of a connection to your ${god_goddess}.  One day, while you are doing your morning prayers, your holy symbol snaps in half.  You realize that this is a sign from ${god_name} saying that ${god_heshe} has lost faith in you as a ${priestpriestess}.  You wonder if all clergy are tested this way, or if you are being held to a higher standard due to the fact that you are also the ${princeprincess} of Daria.
	*if ((god_good) and (good<60))
		*if (showstats)
			(Needed More than 60 Good)
			*line_break
			(Lost Holy Symbol and Lost All Levels in $!{priestpriestess} and Cleric)
		*set exgoodpriest true
	*if ((god_good=false) and (good>40))
		*if (showstats)
			(Needed More than 60 Evil)
			*line_break
			(Lost Holy Symbol and Lost All Levels in $!{priestpriestess} and Cleric)
		*set exevilpriest true
	*set holysymbol false
	*set class_priest 0
	*set class_cleric 0
*if (squire_name="Marla")
	
	One day, a messenger comes to you to tell you that Marla, your squire, has been arrested for public fighting.  He says that the innkeeper is charging 200 gold for the destruction caused in the fight.  When you go to the dungeon, you see Marla yelling insults through the bars at a guard.
	
	"I'm a war hero!" she shouts.  "The innkeeper should have just given me my meal for free.  I am squire to the ${princeprincess}!  I don't have to put up with the likes of you!"
	*choice
		*selectable_if (gold>=200) #Pay the fee.  (Needs 200 Gold)
			You pay the fee and Marla struts angrily out of the dungeon without thanking you.  You see the two men she beat up in another cell.  Your squire might be headstrong, but at least she can fight.
			*if (showstats)
				*line_break
				(Gold -200)
			*set gold -200
			*goto After_Squire_Balance
		#Tell Marla to pay the fine herself.
			Marla screams curses at you as you leave the dungeon.  The next day during training, Marla doesn't show up.  When you look into her whereabouts, you learn that she has left Ludd.  You have lost your squire.
			*set squire_name "None"
			*goto After_Squire_Balance
*if (squire_name="Gordon")
	
	One day Gordon, your squire, comes to you with a sheepish look on his face.
	
	"I got myself into a bit of trouble," he says as he looks down at his feet.  "I was gambling and I owe some rough men 200 gold."
	*choice
		*selectable_if (gold>=200) #Pay the debt. (Needs 200 Gold)
			"Thanks," Gordon says happily.  "I'll pay you back.  I promise."
			*if (showstats)
				*line_break
				(Gold -200)
			*set gold -200
			
			Despite his words, you suspect that you will never see the money again.
			*goto After_Squire_Balance
		#Tell Gordon to deal with his own troubles.
			Gordon gives you a dark look as he leaves your room.  The next day at training, Gordon doesn't show up.  You learn that his way of dealing with the debt was to flee Ludd.  You never see him again.
			*set squire_name "None"
			*goto After_Squire_Balance
*label After_Squire_Balance
*if ((likesgirls=false) and (likesboys=false))
	
	One morning, Archmage Cumari comes to your room with a strange idea.
	
	"Have you considered having a child?" he says.  "The kingdom will need an heir.  I know that you aren't seeing anyone, but…I may have a unique solution.  I have a spell which would allow you to have a child without needing a
	*if (mc_hisher="her")
		man.
	*if (mc_hisher="his")
		woman.
	The child would have the same random genetics as any other child."
	*label Pregnant_Want_An_Egg
	*choice
		#Say, "No, I don't want you to cast this spell."
			Archmage Cumari nods at your words.
			
			"As you wish," he says.  "I suppose that bringing a child into the world just before going into battle might be irresponsible."
			*goto After_Pregnancy_Options
		#Say, "Yes.  Cast your spell.  I would like to have a child."
			Archmage Cumari gathers several magical ingredients before casting the spell.
			*if (mc_hisher="her")
				When the spell is complete, you hardly notice a difference, but Archmage Cumari assures you that it was a success.  You are pregnant!
				*goto Informed_Pregnant
			The magical energies gather and you see a perfect black sphere grow and form in the room.  It is two feet in diameter and shines like glass.  The surface is warm to the touch and is entirely opaque.  Unlike glass, it has a resiliency similar to soft leather.
			
			"Kind of like an egg, isn't it," Archmage Cumari says with a smile.  "It will take several months before the baby is ready to be born.  Congratulations.  You will have your heir."
			*set child_egg true
			*goto Informed_Pregnant
*comment I use lover_sleptwith as a temporary variable that should not be trusted beyond this section.
*if (lover_name=jacejess_name)
	*set lover_sleptwith jacejess_sleptwith
*if (lover_name=theothea_name)
	*set lover_sleptwith theothea_sleptwith	
*if (lover_name=gillgale_name)
	*set lover_sleptwith gillgale_sleptwith
*if (lover_name=peterpetra_name)
	*set lover_sleptwith peterpetra_sleptwith
*if (lover_name=karlkarla_name)
	*set lover_sleptwith karlkarla_sleptwith
*if (lover_name=branbrinn_name)
	*set lover_sleptwith branbrinn_sleptwith
*if (lover_name="None")
	*goto After_Pregnancy_Options
*if ((lover_exists) and (lover_sleptwith))
	*if ((mc_hisher="his") and (lover_heshe="he"))
		
		One day Archmage Cumari pays you and ${lover_name} a visit.
		
		"Do you remember when I told you that I had a spell that would allow two men to have a baby?  I still have it.  It would combine both of your genetics into a child.  Do you want me to cast it?"
		*goto Pregnant_Want_An_Egg
	*if ((mc_hisher="her") and (lover_heshe="she"))
		*comment Set Earlier
		
		*if (coinflip=1)
			One morning, after vomiting into the chamber pot again, you begin to realize that your "flu" has lasted longer than expected.  Also, it routinely gets better as the day wears on.  Archmage Cumari breaks the news to you.
			
			"You are
			*set mc_pregnant true
			*label Pregnant_Cumari_Helped
			pregnant," he says.  "It's my fault."
			
			He suddenly turns a bright red as he realizes how his words sound.
			
			"No!" he exclaims.  "Not in that way!  Do you remember our conversation about choosing a Royal Consort and when I said that I have the magic to allow two women to have a child?  I was testing this magic, to be sure that I could do it.  I didn't realize until today that the spell completed.  I am sorry, but yes.  You and ${lover_name} are going to be parents."
			*goto Informed_Pregnant
		*else
			One morning, after watching ${lover_name} vomit into the chamber pot again, you begin to realize that her "flu" has lasted longer than expected.  Also, it routinely gets better as the day wears on.  Before you have to worry about her apparent infidelity, Archmage Cumari breaks the news to you.
			
			"${lover_name} is
			*set lover_pregnant true
			*goto Pregnant_Cumari_Helped
	*if ((mc_hisher="his") and (lover_heshe="she"))
		*set lover_pregnant true
		
		One morning, ${lover_name} rolls over in bed and looks you in the eye.
		
		*if (lover_name=theothea_name)
			"Well, you knocked me up," ${theothea_name} says without preamble, a large smile on ${theothea_hisher} face.
			*goto Informed_Pregnant
		*if (lover_name=gillgale_name)
			"Guess what?" ${gillgale_name} says with a smirk.  "I'm pregnant!"
			*goto Informed_Pregnant
		*if (lover_name=peterpetra_name)
			"The Gods and Goddesses have helped us to create a new life within me," ${peterpetra_name} says with a smile.  "We're going to be parents."
			*goto Informed_Pregnant
		*if (lover_name=karlkarla_name)
			"I'm pregnant," ${karlkarla_heshe} says with a soft smile.
			*goto Informed_Pregnant
		*if (lover_name=branbrinn_name)
			"I'm pregnant," ${branbrinn_heshe} says with a serious expression.
			*goto Informed_Pregnant
		*comment (lover_name=jacejess_name)
		"You've made me pregnant," ${jacejess_heshe} says with a mix of accusation and guarded happiness.
		*goto Informed_Pregnant
	*if ((mc_hisher="her") and (lover_heshe="he"))
		*set mc_pregnant true
		
		One morning, after vomiting into the chamber pot again, you begin to realize that your "flu" has lasted longer than expected.  Also, it routinely gets better as the day wears on.
		*if (class_priest>0)
			You say a few words of prayer to ${god_name}
			*label Pregnant_Touch
			and touch your stomach.  The flutter of life you feel confirms your suspicion.  You are pregnant.
			*goto Pregnant_Later
		*if (class_wizard>0)
			You cast a simple spell
			*goto Pregnant_Touch
		You leave your room to find a priestess.  The holy woman only needs to touch your belly and say a few words before a large smile spreads across her face.
		
		"You are pregnant," she says.
		
		*label Pregnant_Later
		Later that day, when you finally have ${lover_name} alone, you tell ${lover_himher} the news.
		*label Informed_Pregnant
		*rand coinflip 1 2
		*if (coinflip=1)
			*set child_heshe "he"
			*set child_himher "him"
			*set child_hisher "his"
		*if (coinflip=2)
			*set child_heshe "she"
			*set child_himher "her"
			*set child_hisher "her"
		*set child_exists true
		*choice
			#Use magic to find the sex of the baby.
				*if (class_priest>0)
					You pray to ${god_name} and ${god_heshe} reveals what you wish to know.
					
					*goto Know_Sex
				*if (magic<40)
					You cast the spell, but the result isn't certain.  You will learn the baby's gender in the fullness of time, the same as everyone else.
					*if (showstats)
						(Needed 40 Magic)
					*set child_sexknown false
					*goto Everyone_Knows
				*label Know_Sex
				*set child_sexknown true
				*if (child_heshe="he")
					"It's a boy!" you exclaim.
					*goto Everyone_Knows
				"It's a girl!" you exclaim.
				*goto Everyone_Knows
			#Don't find out the sex of the baby.
				*set child_sexknown false
				You will learn the baby's gender in the fullness of time, the same as everyone else.
				*goto Everyone_Knows_ns

				*label Everyone_Knows
				
				*label Everyone_Knows_ns
				The citizens of Daria explode with the news!
				*if (mc_pregnant)
					Everyone you pass wants to rub your belly for luck. 
					*if (lover_hisher="her")
						In a land of magic where you are often seen with the Archmage of the Academy of Wizards, the fact that two women have become pregnant is seen as just another magical mystery.
						*goto Everyone_Knows_2
					The fact that you are pregnant is a sign of great hope for the future of the kingdom.
					*goto Everyone_Knows_2
				*if (lover_pregnant)
					*if (mc_hisher="her")
						In a land of magic where you are often seen with the Archmage of the Academy of Wizards, the fact that two women have become pregnant is seen as just another magical mystery.
						*goto Everyone_Knows_2
					*else
						The fact that ${lover_name} is carrying your baby is a sign of great hope for the future of the kingdom.
						*goto Everyone_Knows_2
				*comment child_egg
				In a land of magic where you are often seen with the Archmage of the Academy of Wizards, the unique origins of your child's birth is seen as just another great magical mystery.
				*label Everyone_Knows_2
				Everyone in Daria is excited to know that an heir will be born!
				*if (showstats)
					*line_break
					(Citizen Reputation +5 and Army Morale +5)
				*set citizen_reputation +5
				*set army_morale +5
				*goto After_Pregnancy_Options
	*else
		*comment This never gets reached . . .
		ERROR!  PLEASE REPORT THAT YOU REACHED THIS SPOT AND SAY THAT NO OPTIONS IN AFTER_PREGNANCY ERROR WAS REACHED YET SLEPT_WITH LOVER.
		*page_break ERROR!
		*goto After_Pregnancy_Options
*else
	*comment Could have slept with lover and could have had lover, did neither, no baby.
	*goto After_Pregnancy_Options

*label After_Pregnancy_Options

"We are ready to march," General Vale says.  "${food_source} and we have enough supplies to reach Tornassa, but that's it.  A prolonged siege will find the weather turning against us
*if (army_food>0)
	and our food running out."
*if (army_food<=0)
	and we have no extra food."

Your army gets into formation outside of Ludd and begins to march.  The citizens of Daria
*if (citizen_fear>=50)
	gather in small groups to watch fearfully as you ride out.  Their dreams of a good and just ruler have been destroyed by reality.
*if (citizen_fear<50)
	*if (citizen_reputation>=60)
		cheer wildly as you pass.  Their dreams of a good and just ruler have been
		*if (good>=50)
			filled.
		*if (good<50)
			filled, in their eyes.
	*if (citizen_reputation<60)
		mutter amongst themselves as you pass.  Their dreams of a good and just ruler haven't panned out as they had hoped.
*if (class_darkknight>0)
	
	A great commotion gets your attention near the edge of your army.  When you arrive, you see a large horse-like creature standing over the body of a dead man.  The creature is as large as the biggest warhorse you have ever seen, but where it walks, it leaves burned cloven hoof prints on the ground.  More startling is the fact that fire flickers along its mane, tail and in its very eyes.
	*choice
		#Accept the beast that your ${god_goddess} ${god_name} has sent you.
			*if (mount_name!="None")
				${mount_name}, your ${mount_type}, suddenly begins to convulse and shake.  You jump aside just in time as ${mount_heshe} falls to the ground dead, blood pouring from ${mount_hisher} eyes and ears.
			The hellbeast steps toward you.  You put your hand on
			*if (coinflip=1)
				*set mount_hisher "his"
				*set mount_heshe "he"
				*set mount_himher "him"
			*if (coinflip=2)
				*set mount_hisher "her"
				*set mount_heshe "she"
				*set mount_himher "her"
			${mount_hisher} head, feeling the flames on your skin.  Instead of burning you, they feel ice cold, but cause you no discomfort.  ${god_name} has sent you a mount worthy of your new powers as a Dark Knight.
			*set mount_level 6
			*achieve sweetride
			*set mount_value 0
			*set mount_desc "a fiery"
			*set mount_type "hellbeast"
			*set mount_name "None"
			What do you name your new mount?
			*choice
				#Inferno
					*set mount_name "Inferno"
					*goto Done_Naming_HellBeast
				#Damnation.
					*set mount_name "Damnation"
					*goto Done_Naming_HellBeast
				#Brimstone.
					*set mount_name "Brimstone"
					*goto Done_Naming_HellBeast
				#Seekul.
					*set mount_name "Seekul"
					*goto Done_Naming_HellBeast
				#Something else.
					*label Name_HellBeast
					*input_text mount_name
					*if (mount_name="None")
						$!{mount_heshe} will need a name.
						*goto Name_HellBeast
					*goto Done_Naming_HellBeast
			*label Done_Naming_HellBeast
			You climb onto the fiery beast and watch the amazed reactions of those around you.
			*if (showstats)
				*line_break
				(Citizen Fear +50)
			*set citizen_fear +50
			*goto After_HellBeast
		#Decline the mount.
			The fiery animal snorts a burst of flame in disgust as you turn it down.  It suddenly erupts into flames and crumbles into ash as ${god_name} calls it back to ${god_hisher} side.
			*goto After_HellBeast
*label After_HellBeast

*if ((prisonchild_inparty) and (prisonchild_job!="page"))
	${prisonchild_name} is riding in the back of a wagon again.  Although war is no place for a child, leaving ${prisonchild_himher} in Ludd while you are gone would be worse…especially if something bad were to happen to you.
*if (child_egg)
	The sphere containing your "child" has been placed in a large chest and wrapped in blankets.
Lord Tovor will remain behind in
*if ((prisonchild_inparty) and (prisonchild_job="page"))
	Ludd with ${prisonchild_name}.  You are surprised to see how well the two of them get along.
	
	"This
	*if (prisonchild_hisher="his")
		lad
	*if (prisonchild_hisher="her")
		lass
	is a bright one," Lord Tovor says, tousling ${prisonchild_hisher} hair.  "$!{prisonchild_heshe} can't be much of a page without knowing ${prisonchild_hisher} letters.  I'm going to teach ${prisonchild_himher} to read while you're gone."
	
	To your surprise, ${prisonchild_name} runs forward and hugs you!  This is the most expression you have seen come out of the silent child.  You know that ${prisonchild_heshe} will be in good hands and much safer in Ludd than in your army.
	
	*set prisonchild_inparty false
	*goto PrisonChild_After_Tovor
*else
	Ludd.
	*goto PrisonChild_After_Tovor

*label PrisonChild_After_Tovor
There is much more that needs to be done before Ludd can function normally again.  Once Tornassa is secured, Lord Tovor will ride to the capital to help out there too.
*if ((using_legacy) and (legacy_help="army_food"))
	
	You are just about to leave when the soldiers spot a large cloud of dust coming from the south.  Defenses are prepared and your soldiers watch the oncoming riders cautiously.  To your surprise, you see a large contingent of travelers from across the southern desert.  Traders from the Empire of Jilal are very rare, but not unheard of.  Your troops gawk at the camels and odd clothing.
	
	"We bring food for Daria," the leader of the group says in a heavily-accented voice.
	
	The quartermasters in your army waste no time accepting the packages.  The lead rider explains that there is a bi-centennial custom where Jilal brings food to Daria for a large festival as a thank you for a service provided a very long time ago.  The Wizard of Elmvale's long-range plan seems to have been a success.
	*if (showstats)
		*line_break
		(Legacy Advantage #9: Army Food +20.  More perks will arrive as the story progresses.)
	*set army_food +20
	
	After the food has been stored, the desert riders turn around to begin their long trek back across the desert.  Your army also prepares for their own journey.
General Vale rides slowly between the rows of soldiers, making last minute changes to the orders as everyone marches forward.
*if (mount_name="None")
	You walk
*if (mount_name!="None")
	You ride on ${mount_name}
with ${friend3_name} at your side.  Nearby, you see ${friend4_name},
*if (friend2_exists)
	${friend2_name},
Naistalan and ${friend1_name}.
*if ((naistalan_quest="gave it") or (naistalan_quest="blackmail"))
	Auriel's Grief lies against the half-elf's chest as he chats with
	*if (friend1_name=jacejess_name)
		${friend1_name}, who eyes the teardrop artifact with covetous eyes.
	*if (friend1_name!=jacejess_name)
		${friend1_name}.
*if ((naistalan_quest!="gave it") and (naistalan_quest!="blackmail"))
	Naistalan rides silently, no doubt thinking about his missing family heirloom.
*if (companion_name!="None")
	${companion_name} nudges you slightly to get moving faster and then ${companion_travels}.
*goto_scene tornassa

*comment ---------------------Subroutines------------------------------

*label ResetAdventure
*set theothea_injured false
*set jacejess_injured false
*set gillgale_injured false
*set peterpetra_injured false
*set karlkarla_injured false
*set branbrinn_injured false
*set friend1_injured false
*set friend2_injured false
*set friend3_injured false
*set friend4_injured false
*set health 100
*set companion_injured false
*set demonstone_kgirr_used false
*set demonstone_xiatta_used false
*set demonstone_zonch_used false
*set demonstone_brahl_used false
*set demonstone_tyborr_used false
*set demonstone_daanda_used false
*set demonstone_gaabon_used false
*return

*label Army_Use_Food
*comment Input:  food_needed
*if (army_food>=food_needed)
	*comment Has enough food.
	*if (showstats)
		*line_break
		(Army Food -${food_needed})
	*set army_food -food_needed
	*return
*temp food_used 0
*temp food_still_needed 0
*set food_used army_food
*set food_still_needed food_needed-army_food
With the lack of food, your army begins to unravel as people desert in the middle of the night.
*if (army_food<=0)
	*if (showstats)
		(Needed ${food_needed} Army Food)
		*line_break
		(Army Morale -${food_still_needed} and Army Size -${food_still_needed})
	*set army_food 0
	*set army_morale -food_still_needed
	*set army_size -food_still_needed
	*gosub Check_Army_Stats
	*return
*else
	*if (showstats)
		(Needed ${food_needed} Army Food)
		*line_break
		(Army Food -${food_used}, Army Morale -${food_still_needed} and Army Size -${food_still_needed})
	*set army_food 0
	*set army_morale -food_still_needed
	*set army_size -food_still_needed
	*gosub Check_Army_Stats
	*return

*label Check_Army_Stats
*if (army_morale<=0)
	*set army_morale 0
*if (army_size<0)
	*set army_size 0
*if (army_food<0)
	*set army_food 0
*if (army_power<0)
	*set army_power 0
*if (citizen_reputation<0)
	*set citizen_reputation 0
*return
