*comment Copyright 2015 by Mike Walter
*comment The Lost Heir 2:  Forging a Kingdom
*comment Scene #2: exile.txt
*set stage 1
*hide_reuse
*temp talk_options 0
*temp used_dagger false
*temp tornassa_innocent true
*temp had_one false
*temp knight_archery 0
*temp knight_jousting 0
*temp knight_total 0
*temp norgan_escape "None"
*temp academy_hanger false
*temp book_needs_returning false
*temp tornassa_lostfight false
*temp tookmoney false
*temp bear_exists true
*temp wilderness_seenarm false
*temp wilderness_fredaseen false
*temp wilderness_knowofpotion false
*temp wilderness_silent false
*temp exile_learned_new false
*temp temp_willpower 0
*temp sided_sherman_bill "None"
*temp dobbton_disapproval false
*if (store_scene="exile_knightstore")
	*goto exile_knightstore
*if (store_scene="exile_dobbton")
	*goto exile_dobbton
*gosub ResetAdventure
*if (questdetails="the Norgan Mountains")
	*goto Norgan
*if (questdetails="the Academy of Wizards")
	*goto Academy
*if (questdetails="the city of Tornassa")
	*goto Tornassa
*if (questdetails="the wilderness")
	*goto Wilderness
*page_break ERROR
*bug Sorry, you shouldn't have reached this spot.  Please inform the developer that your "questdetails" was "${questdetails}" and that you got this error.

*comment ----------------------------------------Norgan-------------------------------------
*label Norgan
The noise that started the avalanche no longer matters.  The entire mountain ahead of you has disappeared from view as the white wall of deadly snow races toward you and ${friend1_name}.
*if (mount_name!="None")
	The eyes of your ${mount_type}, ${mount_name}, are wide open in fright.

*if (friend1_name=theothea_name)
	${friend1_name} stands beside you.  The muscular warrior grips ${friend1_hisher} oversized warhammer in ${friend1_hisher} hand out of habit.
*if (friend1_name=jacejess_name)
	${friend1_name} stands beside you with ${friend1_hisher} usual arrogant expression no longer on ${friend1_hisher} fine-featured face.  The white streak through ${friend1_hisher} jet black hair shines brightly from the sunlight.
*if (friend1_name=gillgale_name)
	${friend1_name} stands beside you, ${friend1_hisher} hands casually resting on the hilts of ${friend1_hisher} two short swords out of habit.
*if (friend1_name=peterpetra_name)
	${friend1_name} stands beside you with a stern look on ${friend1_hisher} face.  $!{friend1_hisher} hand rests on the handle of ${friend1_hisher} morningstar.
*if (friend1_name=karlkarla_name)
	${friend1_name} stands beside you with a nervous expression on ${friend1_hisher} face.  $!{friend1_heshe} holds ${friend1_hisher} bow in ${friend1_hisher} hands out of habit as ${friend1_hisher} eyes watch the oncoming danger with growing panic.
*label Norgan_Avalanche_loop
*choice
	#Search for a cave to hide in.
		Your eyes dart over the landscape, searching for any type of opening.  The rumbling of a mountain's worth of snow slides toward you, making it difficult to search carefully and not miss any small areas which might keep you safe.
		*if (showstats)
			*line_break
			(Perception +3)
		*set perception +3
		*set norgan_escape "cave"
		*goto Norgan_Job
	#Create a magical dome around you and ${friend1_name} to keep you safe.
		You cast the spell quickly, causing a shimmering blue sphere of force to appear around you both.  You hope that it will be strong enough to hold back the avalanche.
		*if (showstats)
			*line_break
			(Magic +3)
		*set magic +3
		*set norgan_escape "dome"
		*goto Norgan_Job
	*if (mount_name="None") #Run away from the avalanche as fast as you can.
		You turn your back on the snow and start running.  You aren't sure how far you'll need to go as you hear the wall of death tumbling quickly after you, getting closer and closer by the second.
		*set norgan_escape "run"
		*if (showstats)
			*line_break
			(Endurance +3)
		*set endurance +3
		*goto Norgan_Job
	*if (mount_name!="None") #Ride away from the avalanche as fast as you can.
		You turn ${mount_name} around and start riding.  You aren't sure how far you'll need to go as you hear the wall of death tumbling quickly after you, getting closer and closer by the second.
		*set norgan_escape "run"
		*if (showstats)
			*line_break
			(Agility +3)
		*set agility +3
		*goto Norgan_Job
	*if (demonsummoner)
		*allow_reuse #Consider using a Demonstone.
			You open your runebag and consider your options.
			*label Norgan_Demon_loop
			*choice
				*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and (demonstone_xiatta_used=false)) #Summon Xi'atta and tell the demon to stop the snow.
					*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
					*comment Min 45 to Max 60
					Xi'atta appears in front of you.  Its fragile blue body is only one foot tall, and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
					
					"I'll see what I can do, ${mastermistress}," Xi'atta says, looking at the oncoming snow and holding up its tiny hands.
					*set norgan_escape "xiatta"
					*goto Norgan_Job
				*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and (demonstone_brahl_used=false)) #Summon Brahl and tell the demon to stop the snow.
					*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
					*comment Min 45 to Max 60
					Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
					
					"How in the hells am I supposed to do that?" Brahl growls as it looks at the oncoming snow.  "I can't fight this!"
					
					The muscular demon's will pushes against your own.  It then pops out of existence, returning to its own realm.
					*if (showstats)
						(Needed 70 Willpower, which is not possible at this time)
					*goto Norgan_Demon_loop
				*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and (demonstone_zonch_used=false)) #Summon Zon'ch and tell the demon to stop the snow.
					*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
					*comment Min 45 to Max 60
					Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
					
					"Ice and snow isn't really my thing, ${mastermistress}," Zon'ch says as it looks at the oncoming snow.
					*if (willpower<50)
						
						The dusty demon's will pushes against your own.  It then pops out of existence, returning to its own realm.
						*if (showstats)
							(Needed 50 Willpower)
						*goto Norgan_Demon_loop
					*set norgan_escape "zonch"
					*goto Norgan_Job
				*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and (demonstone_daanda_used=false)) #Summon Daan'da and tell the demon to stop the snow.
					*comment daanda: Willing: 10, Small Struggle: 10, Against: 10
					Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
					*comment Will of 0, but very stupid and weak.
					
					"Okay, ${mastermistress}," Daan'da says as it stands in front of you with its arms outstretched.
					*set norgan_escape "daanda"
					*goto Norgan_Job
				*allow_reuse #Close your runebag.
					*goto Norgan_Avalanche_loop

*label Norgan_Job

It was nice to finally be leaving the Norgan Mountains after nearly a year.  They were every bit as cold and treacherous as you had expected.
*if (using_legacy)
	Although you've looked for ${legacy_himher} in your exile, the time-traveling wizard from the past hasn't visited you a single time since leaving Vernex.

After leaving Vernex, you travelled for a month until you found the mountainmen tribes and rented a yurt to stay in.  There was one mountain in particular which seemed to radiate magic in a way you couldn't quite explain.  Master Harmond's tutoring alone had been sufficient for you to sense that it was a place of power…a focal point and nexus of immense arcane energies.  The mountainmen worshipped their mountain Gods and Goddesses, knowing that the place was powerful, but not truly understanding the reason why.
*if (friend1_name=theothea_name)
	*if (theothea_story!=3)
		
		Although ${friend1_name} was from the Norgan Mountains, ${friend1_heshe} refused to take you to ${friend1_hisher} clan's holdings, so you resided among another tribe of mountainmen.
	*if (theothea_story=3)
		It was interesting to be living among ${friend1_name}'s tribe.
*label Norgan_jobloop
*choice
	*if (class_squire>0) #You asked for the location of the next grand tournament and trained hard for it.
		The life of a squire was filled with training and serving your fellow knights.  With no tournament currently taking place, you concentrated on perfecting your techniques.  In addition to swordplay and horsemanship, you studied the knight's code and its history.
		*gosub Level_Squire
		*goto Norgan_AfterJob
	*if (class_bard>0) #You learned the music of the mountainmen and played for them.
		Songs about battle and love were the most popular, especially in the form of drinking songs, although the rough men and women of the Norgan also appreciated songs about the majesty of their mountain home.
		
		You were often invited to play in their long-houses before roaring fires.  To your delight, your songs and ballads spread across the entire land as you built a fan base.
		*gosub Level_Bard
		*goto Norgan_AfterJob
	*if ((class_thief=0) and (no_thief_vow=false)) #You joined the Thieves Guild.
		*label Norgan_Thief
		The Guild didn't have a very strong presence that far north, but it was still there.  This meant that the percentage they took was lower as well.  Unfortunately, there also wasn't as much to steal.  All in all, you still managed to make a decent living.
		*gosub Level_Thief
		*goto Norgan_AfterJob
	*if (class_thief>=1) #You stole whatever you could as a professional thief.
		*goto Norgan_Thief
	#You joined the patrols with the mountainmen as a guard.
		The muscular warriors were tireless as they went from mountain range to mountain range, patrolling the areas around their villages for dangers.   You weren't paid very well, but your efforts were appreciated.  It was a much different guarding experience than you would have received in a regular city or town, but you learned a lot from it.
		*gosub Level_Guard
		*goto Norgan_AfterJob
	*if (((class_priest=0) and (exgoodpriest=false)) and (exevilpriest=false)) #You followed your religious convictions and became a ${priestpriestess}.
		There was a small frontier temple in the mountain village.  It was crude and rough, compared to the temples of the big cities like Tornassa and Ludd, but it was just as well honoured, in its own way.
		*gosub Level_Priest
		*if (god_good=false)
			
			Even in the middle of nowhere, a small group of worshippers followed the teachings of your evil ${god_goddess}.
		*goto Norgan_AfterJob
	*if ((class_priest>=1) or (class_cleric>=1)) #You joined a frontier temple and continued your religious vocation.
		*if (god_good=false)
			Your evil ${god_goddess} had to be hidden, as always, but the generic temple to all of the Gods and Goddesses that you joined allowed you to find worshippers of ${god_name} and bring new converts to your faith.
		The mountain people were rough and crude, but their worship was still strong and heart-felt.
		*choice
			#You delivered spiritual sermons.
				Your sermons were very introspective and life changing as you led the worship of your congregation.
				*gosub Level_Priest
				*goto Norgan_AfterJob
			#You led a very militaristic sect of your order.
				You preached about action and led by example as you studied the sword and shield.
				*gosub Level_Cleric
				*goto Norgan_AfterJob
	*if (monkquest=3) #You searched for the monastery known as the Eye of Heaven.
		It took a lot of inquiries before you finally found the ancient monastery high up in the mountains.  It shouldn't have surprised you that it was very close to the energy vortex you sensed.  After climbing an impossible number of stairs, you arrived at the monastery where ${brothersister} ${monk_veri} had trained.
		
		You didn't need to follow any doctrines or organized religions to find self-enlightenment, allowing your personal growth to occur anywhere, but the Eye of Heaven was still very special.  The things that the monks were doing there were amazing.  They accepted you as one of their own, teaching you things that you never thought were possible.
		*gosub Level_Monk
		
		One wizened master looked to be about a hundred years old, but he moved with a supernatural grace.  He sat outside meditating as the snow fell around him, even though he wore only light clothing.
		
		"Every motion our bodies make is mirrored from within," he said.  "Every piece of nature is connected by our spirit…or chi, or ki…depending upon where you are from."
		
		To your amazement he waves his hand in front of his face and a swirl of snow lifts up off the ground and hovers in midair without being touched.  This new manipulation of reality wasn't exactly magic, it was more primal than that.  And the best part was, the old monk was willing to teach you it.
		
		"I have a lifetime of wonders to share," he says.  "But, for our short time together, let me show you this."
		
		He shows you how to build your ki and strike with your fist.  He warns that at your level, the Ki Strike works best with an unmoving target.  But, with practice, there is nothing that couldn't be done with it.
		*set ki_strike true
		*goto Norgan_AfterJob
	*if ((class_monk>0) and (monkquest!=3)) #You meditated by yourself, high in the mountains.
		The air was clear and you could see for miles.  The energy vortex that you felt nearby may also have had an effect.  You didn't need to follow any doctrines or organized religions to find self-enlightenment, allowing your personal growth to occur anywhere.  You grew into a spiritually stronger person as you meditated upon your deepest thoughts.
		*gosub Level_Monk
		*goto Norgan_AfterJob
	*if (class_wizard>=1) #You studied the arcane energies found at the strange mountain.
			You weren't the only wizard examining the phenomenon.  The way that the magic seemed to be leaking into the world caused many of your familiar spells to work in strange ways.  You learned quite a bit from the odd vortex of energy.
			*gosub Level_Wizard
			
			One day, while you were working near the vortex, an unusual creature came through the thin layer between the worlds.  It was only loosely affiliated with the physical plane and would need some type of anchor, if it was to survive.  Your studies suggested that you should be able to bond it to your soul, but it would need a physical link as well.  This was a once in a lifetime ritual; you would only be able to create such a bond a single time.
			*rand coinflip 1 2
			*choice
				#You bonded the creature to the fire in the camp and to your soul.
					The creature already had sentience, but soon it was also merged with the fiery blaze of the campfire.  The fire elemental cooled down, not being a very powerful entity, but it retained its fiery red appearance.
					*set companion_type "fire elemental"
					*set companion_travels "hovers beside you"
					*label Norgan_elemental
					*if (coinflip=1)
						*set companion_hisher "his"
						*set companion_heshe "he"
						*set companion_himher "him"
					*if (coinflip=2)
						*set companion_hisher "her"
						*set companion_heshe "she"
						*set companion_himher "her"
					
					You decided to name ${companion_himher}:
					*label Name_Elemental
					*input_text companion_name
					*if (companion_name="None")
						You need to name ${companion_himher} something!
						*goto Name_Elemental
					*set companion_familiar true
					The creature seemed to like what you called ${companion_himher} and ${companion_travels} happily.
					*goto Norgan_AfterJob
				#You bonded the creature to the water in your waterskin and to your soul.
					The creature already had sentience, but soon it was also merged with the water.  The water elemental solidified, but retained its watery blue appearance.
					*set companion_type "water elemental"
					*set companion_travels "hovers beside you"
					*goto Norgan_elemental
				#You bonded the creature to the blowing wind and to your soul.
					The creature already had sentience, but soon it was also merged with the air from the cold mountain wind.  The air elemental solidified, but retained its airy light-blue appearance.
					*set companion_type "air elemental"
					*set companion_travels "hovers beside you"
					*goto Norgan_elemental
				#You bonded the creature to the rocky ground at your feet and to your soul.
					The creature already had sentience, but soon it was also merged with the rock at your feet.  The earth elemental solidified, but retained its stony grey appearance.
					*set companion_type "earth elemental"
					*set companion_travels "crawls along beside you"
					*goto Norgan_elemental
				#You didn't bond the creature, allowing it to return to the energy vortex.
					The oddity winked out of existence since it had no way to remain in your world.  The concept was very similar to how wizards bonded familiars, so you stored what you learned in your spellbook.
					*goto Norgan_AfterJob
	*if (class_druid>=1) #You explored the frozen tundra as a druid.
		Your magic allowed you to ignore the cold as you lightly walked through the snow, hardly leaving a trace.  The sheer number of living creatures in the mountain environment was a testament to the tenacity of nature.
		*gosub Level_Druid
		*goto Norgan_companion
	*if (class_ranger>=1) #You hunted for food in the frozen tundra as a ranger.
		The sheer number of living creatures in the mountain environment was a testament to the tenacity of nature.  The mountainmen were good at finding food, but your hunting skills are even better.
		*gosub Level_Ranger
		*label Norgan_companion
		
		It was during one of these excursions that you came across a wild animal who began to follow you around.
		*rand coinflip 1 2
		*if (coinflip=1)
			*set companion_hisher "his"
			*set companion_heshe "he"
			*set companion_himher "him"
		*if (coinflip=2)
			*set companion_hisher "her"
			*set companion_heshe "she"
			*set companion_himher "her"
		*choice
			#A timber wolf.
				The noble wolf was an amazing creature.  Like man, it had learned that there was safety in numbers and was a fearsome fighter.  The large wolf that you found had been badly injured by the arrow of a careless trapper.  Instead of slaying the beast, you tended its wounds and it began to follow you faithfully.
				*set companion_type "wolf"
				*set companion_travels "walks along beside you"
				*set companion_familiar false
				*label Norgan_NameCompanion
				
				You decided to name ${companion_himher}:
				*label Name_Wolf
				*input_text companion_name
				*if (companion_name="None")
					You need to name ${companion_himher} something!
					*goto Name_Wolf
				The creature seemed to like what you called ${companion_himher} and ${companion_travels} happily.
				*goto Norgan_AfterJob
			#A white snowy owl.
				The white feathers of the owl made it very hard to see in the frigid tundra.  It was a silent companion as it joined you one day.  Its ability to feed itself made it more of a friend than a pet as it began to follow you around.
				*set companion_type "owl"
				*set companion_travels "flies overhead"
				*set companion_familiar false
				*goto Norgan_NameCompanion
			#You left the animals in the snowy wild.
				Although you found their presence reassuring, you decided to not take any of them with you.
				*goto Norgan_AfterJob
	*if (class_assassin>0) #You contacted the Guild of Assassins and got to work.
		There weren't many contracts in the Norgan Mountains, but there were a few.  Even the most remote gardens needed weeding.  Some of the more difficult marks had fled other assassins, hoping to hide in the remote tundra.  Your presence brought an end to their lives and a completion to their contracts.
		*gosub Level_Assassin
		*goto Norgan_AfterJob
	#As a sage, you wrote books about the history of the northmen and their lands.
		*if ((arcana>=40) or (class_sage>=1))
			The northmen had only an oral history, so recording their stories and legends into books was very valuable for future generations.  Their mountain homes and their lineages played only minor roles in the history of Daria and the four duchies, but you came across a few interesting facts which made your books very famous across the land.
			*gosub Level_Sage
			*goto Norgan_AfterJob
		*else
			Although you tried to write interesting and knowledgeable books, you simply weren't that good at it.  After a few failed attempts, you gave up on the idea altogether.
			*if (showstats)
				(Needed 40 Arcana or 1 Sage Level)
			*goto Norgan_jobloop
	#You joined a gang of bruisers.
		The northmen were tough individuals and they appreciated intimidation and violence as a way of life.  The gang you joined was good at pushing people around and getting what they wanted.
		*gosub Level_Thug
		*goto Norgan_AfterJob

*label Norgan_AfterJob
*if ((friend1_name=theothea_name) and (theothea_story=3))
	
	"Well, I guess I better present myself to the chief," ${theothea_name} said upon your arrival.
	
	The other mountainmen were silent as you and ${theothea_name} entered the chief's long-house and walked up to where he stood near the fire, surrounded by many muscular northern warriors.
	
	"Look who has returned from the soft south," a voice called from the crowd.
	
	"Silence, ${theothea_foe}," the chief said.  "Let ${theothea_name} speak."
	*choice
		#Wait to hear what ${theothea_name} says.
			"I have come back to challenge ${theothea_foe}," ${theothea_name} said.  "I loved ${theothea_love} and ${theothea_love_heshe} loved me!  ${theothea_foe} killed ${theothea_love_himher}!"
			
			The mountainmen all began shouting at once.  The chief raised a wrinkled old hand and they stopped.
			
			"Challenge accepted," ${theothea_foe} replied grimly, drawing a large broadsword that was strapped to ${theothea_hisher} back.  "I will prove that my words are true by trial of combat!"
			
			Justice was swift, in the north.  Within seconds a ring of warriors was formed and the battle was under way.  You watched as ${theothea_name} squared off against ${theothea_foe}.  They circled each other and fought for several minutes, but after a few swings of the mighty warhammer and broadsword, it looked like ${theothea_name} was going to lose.
			*choice
				*if (class_priest>0) #You prayed to ${god_name} to grant ${theothea_name} strength.
					*if (god_good)
						The clouds parted slightly as a ray of sunshine descended upon your friend.
					*if (god_good=false)
						The clouds became darker as a shadow crept across your friend.
					${theothea_name} stood up straighter as ${theothea_hisher} warhammer swung through the air with greater speed.  It struck ${theothea_foe}'s broadsword and the blade cracked under the blow.  The warhammer continued its momentum, smashing solidly into ${theothea_hisher} body.
					*goto Norgan_TheoThea_Won
				#You quietly incanted a spell to make ${theothea_foe}'s fingers spasm.
					You muttered the words softly under your breath and wiggled your fingers.
					*if (magic>=30)
						${theothea_foe} fumbled ${theothea_hisher} sword during an easy swing, allowing ${theothea_name} to knock the blade free using ${theothea_hisher} warhammer.  The blade fell to the ground and ${theothea_name} followed through with another strike, knocking ${theothea_foe} to the ground.
						*if (showstats)
							*line_break
							(Magic +3 and Evil +3)
						*set magic +3
						*set good -3
						*goto Norgan_TheoThea_Won
					*else
						${theothea_foe}'s eyes opened wide as ${theothea_hisher} fingers tingled, but didn't spasm enough to make ${theothea_himher} drop ${theothea_hisher} broadsword.
						*if (showstats)
							(Needed 30 Magic)
							*line_break
							(Evil +3)
						*set good -3
						*label Norgan_TheoThea_EndingBlow
						
						You watched as the broadsword came down in a fast arc, catching ${theothea_name} in the shoulder.  Your friend fell to ${theothea_hisher} knees.
						*set theothea_story 11
						*label Norgan_Lost
						
						"Enough!" the chief yelled, stopping the fight.  "You have had your combat trial.  It is as ${theothea_foe} says.  Now leave, ${theothea_name}.  I won't have another death over this matter."
						
						You left the clan village immediately after, spending the remainder of the time with a different mountain tribe.
						*goto Norgan_AfterTheoThea
				#You pushed ${theothea_foe} in the back when ${theothea_heshe} came near.
					*if (agility>=30)
						As one of the ring of warriors surrounding the fight, it was easy for you to give ${theothea_foe} a push at the right time.  It left ${theothea_himher} off-balance and ${theothea_name} took advantage, knocking ${theothea_hisher} opponent's broadsword aside and striking ${theothea_himher} in the stomach with the mighty warhammer.
						*if (showstats)
							*line_break
							(Agility +3 and Evil +3)
						*set agility +3
						*set good -3
						*goto Norgan_TheoThea_Won
					*else
						Your timing wasn't as good as it could have been, allowing ${theothea_foe} to recover from being shoved.
						*if (showstats)
							(Needed 30 Agility)
							*line_break
							(Evil +3)
						*set good -3
						*goto Norgan_TheoThea_EndingBlow
				#You shouted encouragement to ${theothea_name}.
					*if (charm>=30)
						Although ${theothea_name} was tiring and the relentless broadsword continued to fall, ${theothea_heshe} never gave up.  Eventually ${theothea_foe} began to tire as well.  The sheer tenacity of the combatants was worthy of sagas.  Slowly, the tide turned and ${theothea_name}'s warhammer battered aside ${theothea_foe}'s broadsword until your friend was standing victorious over ${theothea_hisher} foe.
						*if (showstats)
							*line_break
							(Charm +3)
						*set charm +3
						*goto Norgan_TheoThea_Won
					*else
						${theothea_name} was tiring and the relentless broadsword continued to fall, but ${theothea_heshe} never gave up.
						*if (showstats)
							(Needed 30 Charm)
						*goto Norgan_TheoThea_EndingBlow
				#You looked for an opening in ${theothea_foe}'s defences and called it out to ${theothea_name}.
					*if (perception>=30)
						Although ${theothea_name} was tiring and the relentless broadsword continued to fall, ${theothea_heshe} never gave up.  Eventually you saw what you were looking for.
						
						"Low right, ${theothea_heshe} is slow to recover from a slash!"
						
						${theothea_foe} quickly dropped the blade to cover the hole in ${theothea_hisher} defences, but ${theothea_name}'s warhammer got there first, thudding solidly into ${theothea_foe}'s stomach and dropping ${theothea_himher} to the ground.
						*if (showstats)
							*line_break
							(Perception +3)
						*set perception +3
						*goto Norgan_TheoThea_Won
					*else
						${theothea_name} was tiring and the relentless broadsword continued to fall, but ${theothea_heshe} never gave up.  You kept waiting for an opportunity that never came.
						*if (showstats)
							(Needed 30 Perception)
						*goto Norgan_TheoThea_EndingBlow
				#You stood back and watched.
					${theothea_name} was tiring and the relentless broadsword continued to fall, but ${theothea_heshe} never gave up.
					*goto Norgan_TheoThea_EndingBlow
		#You shouted, "I challenge you, ${theothea_foe}.  $!{theothea_heshe} lied and killed ${theothea_love}!"
			${theothea_name} showed mixed emotions on ${theothea_hisher} face.  It was clear that ${theothea_heshe} was happy that you were defending ${theothea_himher}, but also upset that you had interfered with ${theothea_hisher} own potential challenge.
			
			"Challenge accepted," ${theothea_foe} replied, drawing a large broadsword that was strapped to ${theothea_hisher} back.  "I will prove that my words are true by trial of combat!"
			
			Justice was swift, in the north.  Within seconds a ring of warriors was formed and the battle was under way.  You watched as ${theothea_foe} squared off against you with ${theothea_hisher} large broadsword in ${theothea_hisher} hands.  You circled each other as you both looked for your opportunity.
			*choice
				*if (sword) #You attacked ${theothea_foe} with your sword.
					*label Norgan_YouSwordFight
					The fight was fast and furious as you dodged and struck back with your own sword.  
					*if (blades>=40)
						Although ${theothea_foe} was skilled, ${theothea_heshe} was no match for your skills with the blade.  With one last swing, ${theothea_foe}'s head was taken from ${theothea_hisher} body.
						*if (showstats)
							*line_break
							(Blades +3)
						*set blades +3
						*goto Norgan_YouWon
					*else
						${theothea_foe} was more skilled than you thought as your defences were mercilessly battered down by ${theothea_hisher} broadsword.  You saw the large blade coming for your face and knew the end was near.
						*if (showstats)
							(Needed 40 Blades)
						*set theothea_story 13
						*goto Norgan_Lost
				*if (sword) #You left your sword on your belt and attacked with your hands.
					*goto YouHandFight
				*if (sword=false) #You accepted one of the northerner's blades and fought.
					Wordlessly, you were passed a sword from one of the warriors in the ring.
					*if (showstats)
						*line_break
						(Gained a Sword)
					*set sword true
					*goto Norgan_YouSwordFight
				*if (sword=false) #You declined the sword and fought with your hands.
					*label YouHandFight
					The warriors cheered at your bold move, although they thought you had a death wish.  The fight was fast and furious as you dodged and struck back with your fists.  
					*if (unarmed>=40)
						Although ${theothea_foe} was skilled, ${theothea_heshe} was no match for your speed and talent.  You sidestepped the broadsword one last time and circled behind your foe.  Your arms grabbed ${theothea_himher} around the neck and twisted, snapping it clean.
						*if (showstats)
							*line_break
							(Unarmed +3)
						*set unarmed +3
						*goto Norgan_YouWon
					*else
						${theothea_foe} proved to be more skilled than you thought as your defences were mercilessly battered down by ${theothea_hisher} broadsword.  You saw the large blade coming for your face and knew the end was near.
						*if (showstats)
							(Needed 40 Unarmed)
						*set theothea_story 13
						*goto Norgan_Lost
				#You cast a spell to electrocute ${theothea_foe} before ${theothea_heshe} could attack.
					You raised your hands and said the words.
					*if (magic>=40)
						${theothea_foe} convulsed as blue electricity streaked from your hands.  Although it was intended to be a physical fight, it was a northern challenge for honour, so there were no rules.  Within seconds, ${theothea_foe} lay dead at your feet.
						*if (showstats)
							*line_break
							(Magic +3)
						*set magic +3
						*goto Norgan_YouWon
					*else
						Unfortunately, your magic didn't come fast enough as ${theothea_foe} closed the distance quickly and knocked you down.  Before you could do anything else, you saw the large blade coming for your face and knew the end was near.
						*if (showstats)
							(Needed 40 Magic)
						*set theothea_story 13
						*goto Norgan_Lost
*else
	*goto Norgan_AfterTheoThea

*label Norgan_YouWon

"It's over," the chief said.  "${name}'s actions have proven that ${theothea_foe} lied.  My ${theothea_love_sondaughter} died by nefarious means.  I thank you, ${name}, and I apologize to you, ${theothea_name}.  Welcome home."

With ${theothea_foe} dead, the banishment was lifted.  ${theothea_name} smiled at you for your aid, but you could sense that the big warrior felt bad that ${theothea_foe} hadn't been killed by ${theothea_hisher} own mighty warhammer.

*goto Norgan_FoeGone

*label Norgan_TheoThea_Won

${theothea_name} looked over to you for guidance.
*choice
	#"Kill ${theothea_himher}," you said.
		The warhammer came down and landed on ${theothea_foe}'s head with a sickening wet crunch.  The chief and the other warriors all cheered as ${theothea_name} stood victorious.
		*if (showstats)
			*line_break
			(Evil +5)
		*set good -5
		*goto Norgan_FoeGone
	#"Spare ${theothea_himher}," you said.
		"Go and never return," ${theothea_name} said.
		*if (showstats)
			*line_break
			(Good +5)
		*set good +5
		${theothea_foe} got to ${theothea_hisher} feet and left the long-house.  Nobody watched ${theothea_himher} go as ${theothea_heshe} left the north forever.
		*goto Norgan_FoeGone

*label Norgan_FoeGone

"My ${theothea_love_sondaughter} loved you, ${theothea_name}, and you would have been married," the old chief said.  "I decree that you were married in the eyes of nature and the eyes of the Gods and Goddesses.  This makes you my
*if (theothea_hisher="his")
	son
*if (theothea_hisher="her")
	daughter
and heir to the Norgan Kingdom.  You will be chief, as you were always meant to be."

"I can't leave my friend, ${name}," ${theothea_name} said.  "$!{mc_heshe} has a job to do."
*if (showstats)
	*line_break
	(${theothea_name} Relationship +10)
*set theothea_relationship +10

"I'm not dead yet," the chief said with a grin.  "Go, and I will watch our clan while you are away.  And when you return, you shall rule."

The remainder of the stay with the mountainmen was spectacular as you were treated like royalty (which you are), albeit in a rough and frontier sort of way.
*set theothea_story 10
*goto Norgan_AfterTheoThea

*label Norgan_AfterTheoThea

You stayed in the mountains for nearly a year and were on your way back to civilization when the avalanche hit.
*if (norgan_escape="cave")
	*if (perception>=30)
		You see the small cave only moments before the snow comes.  You
		*if (mount_name!="None")
			spur ${mount_name}
		*if (mount_name="None")
			run
		toward the cave with ${friend1_name} at your side.  The crashing of snow and debris flies past the cave's opening, but
		*if (companion_name!="None")
			you, ${companion_name} and ${friend1_name} are safe.
		*if (companion_name="None")
			you and ${friend1_name} are safe.
		*goto Norgan_CampForNight
	*else
		You almost see the cave in time. You
		*if (mount_name!="None")
			ride ${mount_name}
		*if (mount_name="None")
			run
		quickly toward it, ${friend1_name} at your side.  The crashing of snow and debris slams into your back, covering you over and threatening to crush the life from you.
		*if (showstats)
			(Needed 30 Perception)
		*goto Norgan_UnderTheSnow
*if (norgan_escape="dome")
	Your shimmering dome of magic is put to the test as the wall of snow blasts into it.
	*if (magic>=30)
		*if (mount_name!="None")
			${mount_name} watches the onslaught with fear, but holds still as the snow parts around you.
		After a few moments, the snow stops pushing against the dome.
		*if (companion_name!="None")
			You, ${companion_name} and ${friend1_name} are safe.
		*if (companion_name!="None")
			You and ${friend1_name} are safe.
		*goto Norgan_CampForNight
	*else
		It takes most of the initial blast, but it still crumbles under the enormous onslaught.  The crashing of snow and debris slams into you, covering you over and threatening to crush the life from you.
		*if (showstats)
			(Needed 30 Magic)
		*goto Norgan_UnderTheSnow
*if (norgan_escape="xiatta")
	The avalanche rumbles toward you in a churning mass of ice and snow.  Xi'atta stands in front of you with its tiny hands in the air.  It looks futile, but as the snow pours forward, the icy demon diverts it with its demon-magic.  After a few minutes, the snow stops and you find yourself standing safely with the danger parted around you.  Xi'atta smiles and pops out of existence.
	*goto Norgan_CampForNight
*if (norgan_escape="zonch")
	The avalanche rumbles toward you in a churning mass of ice and snow.  Zonch stands in front of you throwing up a futile cloud of dust between you and the avalanche.  It looks useless and sure enough, the snow crushes the demon out of existence.  You feel the impact as you are buried under!
	*set demonstone_zonch_used true
	*goto Norgan_UnderTheSnow
*if (norgan_escape="daanda")
	The avalanche rumbles toward you in a churning mass of ice and snow.  Daan'da stands in front of you with its slender hands in the air.  It looks futile and sure enough, the snow crushes the demon out of existence.  You feel the impact as you are buried under!
	*set demonstone_daanda_used true
	*goto Norgan_UnderTheSnow
*if (norgan_escape="run")
	*if (mount_name="None")
		You run as fast as you can away from the churning avalanche rumbling behind you.
		*if (belt_of_speed)
			The Belt of Speed suddenly glows brightly for a moment and you find yourself easily outrunning the avalanche.  You even have time to go back and push ${friend1_name} along too before the belt loses its glow.
			*goto Norgan_CampForNight
		*if (endurance>=35)
			You are panting heavily when the bulk of the snow finally stops tumbling toward you.
			*goto Norgan_CampForNight
		*else
			You are unable to keep up the strenuous pace and you feel yourself slow down.  The snow slams into your back as you hope that you have at least outrun the worst of it.
			*if (showstats)
				(Needed 35 Endurance)
			*goto Norgan_UnderTheSnow
	*else
		You ride ${mount_name} as fast as ${mount_heshe} will go as the churning snow rumbles behind you.
		*if (mount_level>=3)
			Your poor ${mount_type} is panting heavily when the bulk of the snow finally stops tumbling toward you.
			*goto Norgan_CampForNight
		*else
			Your poor ${mount_type} is unable to keep up the strenuous pace and you feel ${mount_himher} slow down.  The snow slams into you as you hope that you have at least outrun the worst of it.
			*if (showstats)
				(Needed a Stronger Mount)
			*goto Norgan_UnderTheSnow

*label Norgan_CampForNight

"That was a little close for comfort," ${friend1_name} comments.

*if (norgan_escape="cave")
	You spend the night in the cave, thankful to be alive.
	*goto Leaving
You make camp in the churned up snow, thankful to be alive.
*goto Leaving

*label Norgan_UnderTheSnow

You feel ${friend1_name}'s hands on you as ${friend1_heshe} digs you free and pulls you
*if (companion_name!="None")
	and ${companion_name}
*if (norgan_escape="cave")
	safely into the cave.
*if (norgan_escape!="cave")
	out of the snow.
*if (companion_name!="None")
	You are glad to see that ${companion_name} survived the avalanche too.
*if (((rope) or (lute)) or ((lockpickset) or (lantern)))
	Unfortunately some of your belongings are lost.
	*if (showstats)
		*line_break
		*if (((rope) and (lute)) and ((lockpickset) and (lantern)))
			(Lost Rope, Lost Lute, Lost Lockpick Set and Lost Lantern)
		*if (((rope=false) and (lute)) and ((lockpickset) and (lantern)))
			(Lost Lute, Lost Lockpick Set and Lost Lantern)
		*if (((rope) and (lute=false)) and ((lockpickset) and (lantern)))
			(Lost Rope, Lost Lockpick Set and Lost Lantern)
		*if (((rope) and (lute)) and ((lockpickset=false) and (lantern)))
			(Lost Rope, Lost Lute and Lost Lantern)
		*if (((rope) and (lute)) and ((lockpickset) and (lantern=false)))
			(Lost Rope, Lost Lute and Lost Lockpick Set)
		*if (((rope=false) and (lute=false)) and ((lockpickset) and (lantern)))
			(Lost Lockpick Set and Lost Lantern)
		*if (((rope=false) and (lute)) and ((lockpickset=false) and (lantern)))
			(Lost Lute and Lost Lantern)
		*if (((rope=false) and (lute)) and ((lockpickset) and (lantern=false)))
			(Lost Lute and Lost Lockpick Set)
		*if (((rope) and (lute=false)) and ((lockpickset=false) and (lantern)))
			(Lost Rope and Lost Lantern)
		*if (((rope) and (lute=false)) and ((lockpickset) and (lantern=false)))
			(Lost Rope and Lost Lockpick Set)
		*if (((rope) and (lute)) and ((lockpickset=false) and (lantern=false)))
			(Lost Rope and Lost Lute)
		*if (((rope) and (lute=false)) and ((lockpickset=false) and (lantern=false)))
			(Lost Rope)
		*if (((rope=false) and (lute)) and ((lockpickset=false) and (lantern=false)))
			(Lost Lute)
		*if (((rope=false) and (lute=false)) and ((lockpickset) and (lantern=false)))
			(Lost Lockpick Set)
		*if (((rope=false) and (lute=false)) and ((lockpickset=false) and (lantern)))
			(Lost Lantern)
	*set rope false
	*set lute false
	*set lockpickset false
	*set lantern false
*goto Norgan_CampForNight

*comment ----------------------------------------Academy-------------------------------------
*label Academy
The enormous eight-foot-tall iron golem drives its fist toward you.  You barely dodge the blow in time.  The metal knuckles dislodge the rest of the stone in the tower wall right where you were standing.  The gaping hole is filled with the blue of sky and the hint of green from the ground a mile below you.

*if (friend1_name=theothea_name)
	${friend1_name} stands beside you.  The muscular warrior grips ${friend1_hisher} oversized warhammer tightly as the stone slab you both stand on begins to slide toward the lethal drop to the ground far below.
*if (friend1_name=jacejess_name)
	${friend1_name} stands beside you with an arrogant expression on ${friend1_hisher} fine-featured face.  The white streak through ${friend1_hisher} jet black hair shines brightly from the sunlight pouring through the hole behind you as the stone slab you both stand on begins to slide toward the lethal drop to the ground far below.
*if (friend1_name=gillgale_name)
	${friend1_name} stands beside you, ${friend1_hisher} hands casually resting on the hilts of ${friend1_hisher} two short swords.  A mischievous grin curls the corners of ${friend1_hisher} mouth upward as the stone slab you both stand on begins to slide toward the lethal drop to the ground far below.
*if (friend1_name=peterpetra_name)
	${friend1_name} stands beside you with a stern look on ${friend1_hisher} face.  $!{friend1_hisher} hand rests on the handle of ${friend1_hisher} morningstar as ${friend1_hisher} eyes shine with holy conviction.  The stone slab you both stand on suddenly begins to slide toward the lethal drop to the ground far below.
*if (friend1_name=karlkarla_name)
	${friend1_name} stands beside you with a nervous expression on ${friend1_hisher} face.  $!{friend1_hisher} dexterous hands are only inches away from ${friend1_hisher} bow and quiver.  The stone slab you both stand on suddenly begins to slide toward the lethal drop to the ground far below.
*choice
	#Punch the golem in the face.
		The metal monster doesn't flinch as you do more harm to your hand than to its face.
		*if (showstats)
			*line_break
			(Unarmed +2 and Health -25)
		*set unarmed +2
		*set health -25
		*goto Academy_Job
	*if (bow) #Fire arrows at the golem.
		The arrows bounce off the metal monster without even causing a scratch.
		*if (showstats)
			*line_break
			(Archery +2)
		*set archery +2
		*goto Academy_Job
	*if (sword) #Attack the golem with your sword.
		The metal monster's iron skin is so hard that your sword gets chipped and the edge becomes so badly dented that the sword is ruined.
		*if (showstats)
			*line_break
			(Lost Sword and Blades +2)
		*set blades +2
		*set sword false
		*goto Academy_Job
	*if (dagger) #Throw your dagger at the golem.
		The metal monster's iron skin is so hard that your dagger's blade breaks as it clatters against its chest.
		*if (showstats)
			*line_break
			(Lost Dagger and Blades +2)
		*set blades +2
		*set dagger false
		*goto Academy_Job
	#Watch as ${friend1_name} attacks the golem.
		*if (friend1_name=theothea_name)
			${friend1_name} swings ${friend1_hisher} enormous warhammer at the golem, but besides an enormous gonging sound, the golem is unharmed.
		*if (friend1_name=jacejess_name)
			${friend1_name} fights at your side, ${friend1_hisher} eyes glowing a blinding white.  Bright beams of energy dart toward the golem, but instead of cutting through it, they bounce off its reflective surface.
		*if (friend1_name=gillgale_name)
			${friend1_name} strikes the golem repeated with both of ${friend1_hisher} blades, but besides making many dinging sounds, the monster doesn't even get a scratch.
		*if (friend1_name=peterpetra_name)
			${friend1_name} swings ${friend1_hisher} morningstar at the golem, but besides an enormous gonging sound, the golem is unharmed.
		*if (friend1_name=karlkarla_name)
			${friend1_name} sends a steady stream of arrows at the golem, but they all bounce off its hard skin without leaving a scratch.
		*goto Academy_Job
	#Cast a spell to throw fire from your fingertips.
		You say the magical words and watch as the flames dance between your fingers.
		*if (magic>=30)
			The fire washes over the metal monster, making him glow a bright red from the intense heat.  Unfortunately, besides the colour change, the golem ignores the gout of flame.
			*if (showstats)
				*line_break
				(Magic +3)
			*set magic +3
			*goto Academy_Job
		*else
			Unfortunately, the fire burns your hands and you are forced to stop casting as the pain becomes unbearable.
			*if (showstats)
				(Needed 30 Magic)
				*line_break
				(Health -25)
			*set health -25
			*goto Academy_Job

*label Academy_Job

You have been here for several months now.
*if (using_legacy)
	Although you've looked for ${legacy_himher} in your exile, the time-traveling wizard from the past hasn't visited you a single time since leaving Vernex.
The grand Academy of Wizards was full of opportunities for everyone, not just for those who were magically inclined.  As the central location for the study of magic, the enormous tower is surrounded by a full city, which supports and serves the mages within.
*label Academy_jobloop
*choice
	*if (class_squire>0) #You asked for the location of the next grand tournament and trained hard for it.
		The life of a squire was filled with training and serving your fellow knights.  With no tournament currently taking place, you concentrated on perfecting your techniques.  In addition to swordplay and horsemanship, you studied the knight's code and its history.
		*gosub Level_Squire
		
		You had just finished one of these history classes in the Academy when the golem attacked.
		*goto Academy_AfterJob
	*if (class_bard>0) #You enrolled in the Academy to learn the magical side of your bardic music.
		Luckily you didn't have to know as much magic as a regular wizarding student, although your requirements were just as strict in their own way.  The Academy's desire to be linked to all things magical made them offer special programs, such as yours.
		
		In addition to your studies as an arcane musician, you also performed regularly in a tavern in the city.  It wasn't long before you had a very full fan base with a surprisingly large number of wizards as admirers.
		*set academy_stay "bard"
		*gosub Level_Bard
		
		You had just finished one of your classes in the Academy and were walking past another classroom when the golem attacked.
		*goto Academy_AfterJob
	*if ((class_thief=0) and (no_thief_vow=false)) #You joined the Thieves Guild.
		*label Academy_Thief
		The Guild was very strict about the pilfering of magical items.  The entire Academy was strictly off-limits.  As for the surrounding city, it held the same rules as any other city in the four duchies.
		*gosub Level_Thief
		
		Although stealing from the mages in the tower was forbidden, selling your stolen wares to them wasn't.  You had just finished meeting with a buyer and was passing by a classroom in the Academy when the golem attacked.
		*goto Academy_AfterJob
	*if (class_thief>0) #You performed many jobs for the Thieves Guild.
		*goto Academy_Thief
	#You offered your services as a bodyguard to a wizard, helping to protect his belongings.
		The wizards of the Academy were always looking for someone to hold a sword and guard their possessions and their backs.  They paid well and most thieves weren't foolish enough to try anything against them.
		*set academy_stay "bodyguard"
		*gosub Level_Guard
		
		You had just escorted a client back to his room in the Academy and were passing a classroom when the golem attacked.
		*goto Academy_AfterJob
	*if (((class_priest=0) and (exgoodpriest=false)) and (exevilpriest=false)) #You followed your religious convictions and became a ${priestpriestess}.
		The city below the tower had several temples devoted to different Gods and Goddesses of the land.  You were a little old to hear the call, but you were ordained as a ${priestpriestess} all the same.
		*set academy_stay "priest"
		*gosub Level_Priest
		*label Academy_PriestStory
		
		*if (god_good=false)
			Your evil ${god_goddess} had a small sect following the old ways hidden within one of the legitimate temples.
		You had just left the bedside of an old aging wizard who followed your faith and were passing by a classroom in the Academy when the golem attacked.
		*goto Academy_AfterJob
	*if ((class_priest>=1) or (class_cleric>=1)) #You joined the local temple dedicated to ${god_name} and continued your religious vocation.
		The city below the Academy had several temples devoted to different Gods and Goddesses of the land.
		*set academy_stay "priest"
		*choice
			#You delivered spiritual sermons.
				Your sermons were very introspective and life changing as you led the worship of your congregation.
				*gosub Level_Priest
				*goto Academy_PriestStory
			#You led a very militaristic sect of your order.
				You preached about action and led by example as you studied the sword and shield.
				*gosub Level_Cleric
				*goto Academy_PriestStory
	*if (class_monk>=1) #You moved into one of the local monasteries.
		You didn't need to follow any doctrines or organized religions to find self-enlightenment, allowing your personal growth to occur anywhere.  The small monastery in the city is very scholarly.  They even have an arrangement with the Academy to use some of their non-magical libraries.
		*set academy_stay "monk"
		*gosub Level_Monk
		
		You had just left the library in the upper floors of the Academy when the golem attacked.
		*goto Academy_AfterJob
	*if ((spellbook) and (class_wizard=0))
		*selectable_if (gold>=100) #You paid your tuition and enrolled in the Academy itself.  (Needs 100 Gold)
			*set academy_stay "student"
			You paid the coins and were given a full schedule of classes.  You had to lie about where you got your spellbook, since you had gotten it illegally, which saved you a little money.
			*if (showstats)
				*line_break
				(Gold -100)
			*set gold -100
			*label Academy_LearnMagic
			
			There was no other place in the four duchies where magic was so accepted and studied.  The classes are amazing and you learned a lot from the Master Wizards who taught you.
			*gosub Level_Wizard
			
			As part of your studies, you were taught how to bond an animal's soul to your own.  Not every wizard takes advantage of such an opportunity, but some do.  The ritual can only be done once, so many wizards wait for just the right familiar, although some wait their entire lives and die alone.
			*choice
				#You used the spell to bond a cat.
					*rand coinflip 1 2
					*if (coinflip=1)
						*set companion_hisher "his"
						*set companion_heshe "he"
						*set companion_himher "him"
					*if (coinflip=2)
						*set companion_hisher "her"
						*set companion_heshe "she"
						*set companion_himher "her"
					A feline companion was a very popular choice for a wizard, likely due to their ease of bonding and finding.  A store near the Academy sold cats for this very purpose and the Academy reimbursed wizards for the purchase.  The cat seemed smart when you purchased ${companion_himher}, but after the ritual, ${companion_hisher} intelligence grew even more.
					*set companion_travels "pads along beside you"
					*set companion_type "cat"
					*set companion_familiar true
					
					You decided to name ${companion_himher}:
					*label Name_Cat_Academy
					*input_text companion_name
					*if (companion_name="None")
						You need to name ${companion_himher} something!
						*goto Name_Cat_Academy
					The creature seemed to like what you called ${companion_himher} and ${companion_travels}, happily.
					*goto Academy_AfterFamiliar
				#You used the spell to bond a firedrake.
					*rand coinflip 1 2
					*if (coinflip=1)
						*set companion_hisher "his"
						*set companion_heshe "he"
						*set companion_himher "him"
					*if (coinflip=2)
						*set companion_hisher "her"
						*set companion_heshe "she"
						*set companion_himher "her"
					The wizards of the Academy were very envious when you had the good fortune to find a firedrake to bond.  Firedrakes are remotely related to dragons, although they are only the size of a large house cat.  Your own familiar could fly and occasionally produced a small burst of flame.  
					*set companion_type "firedrake"
					*set companion_familiar true
					*set companion_travels "flies overhead"
					
					You decided to name ${companion_himher}:
					*label Name_FireDrake
					*input_text companion_name
					*if (companion_name="None")
						You need to name ${companion_himher} something!
						*goto Name_Firedrake
					The creature seemed to like what you called ${companion_himher} and ${companion_travels} happily.
					*goto Academy_AfterFamiliar
				#You secretly used the spell to bond a small spider.
					*rand coinflip 1 2
					*if (coinflip=1)
						*set companion_hisher "his"
						*set companion_heshe "he"
						*set companion_himher "him"
					*if (coinflip=2)
						*set companion_hisher "her"
						*set companion_heshe "she"
						*set companion_himher "her"
					Most wizards' familiars were much larger and well known.  But the small spider you bonded was the size of a gold coin.  $!{companion_heshe} had a shiny black back and a pair of sharp white fangs.  The venom in ${companion_hisher} fangs was somewhat mild when you first bonded ${companion_himher}, but you knew that it would become stronger as ${companion_heshe} got older.
					*set companion_type "spider"
					*set companion_travels "sits in your sleeve"
					*set companion_familiar true
					
					You decided to name ${companion_himher}:
					*label Name_Spider
					*input_text companion_name
					*if (companion_name="None")
						You need to name ${companion_himher} something!
						*goto Name_Spider
					The creature seemed to like what you called ${companion_himher} and ${companion_travels}, happily.
					*goto Academy_AfterFamiliar
				#You didn't use the spell.
					You decided to not use the spell at that time.
					*goto Academy_AfterFamiliar
			*label Academy_AfterFamiliar
			You were going to your next class when the golem attacked.
			*goto Academy_AfterJob
	*if ((spellbook=false) and (class_wizard=0))
		*selectable_if (gold>=200) #You paid your tuition and enrolled in the Academy itself.  (Needs 200 Gold)
			*set academy_stay "student"
			You paid the coins and were given an official Academy spellbook of your very own.
			*if (showstats)
				*line_break
				(Gold -200 and Gained Spellbook)
			*set gold -200
			*set spellbook true
			*goto Academy_LearnMagic
	*if (class_wizard>=1) #You enrolled in the Academy of Wizards.
		*set academy_stay "student"
		Xino, the enchanter you met in Ludd, had been a wonderful teacher and was a well-respected wizard.  Using your former master as a reference you were admitted into the Academy on a full scholarship.
		*goto Academy_LearnMagic
	*if (class_druid>=1) #You helped the Academy wizards gather herbal reagents using your knowledge as a druid.
		*set academy_stay "druid"
		The woods near the Academy were filled with odd animals and strange plants, likely from its close proximity to the strange magics of the Academy.  You were kept busy as a purveyor of such natural ingredients.
		*gosub Level_Druid
		*goto Academy_companion
	*if (class_ranger>=1) #You accompanied the Academy wizards into the woods to gather herbal reagents, using your knowledge as a ranger.
		*set academy_stay "ranger"
		The woods near the Academy were filled with odd animals and plants, likely from its close proximity to the strange magics of the Academy.  You were kept busy as wizards were constantly needing a guide to enter these forests to collect the natural ingredients.
		*gosub Level_Ranger
		*label Academy_companion
		
		It is during one of these excursions that a strange animal wanted to accompany you.
		*rand coinflip 1 2
		*if (coinflip=1)
			*set companion_hisher "his"
			*set companion_heshe "he"
			*set companion_himher "him"
		*if (coinflip=2)
			*set companion_hisher "her"
			*set companion_heshe "she"
			*set companion_himher "her"
		*choice
			#A small griffin.
				You weren't sure how such a magical beast ended up getting loose in the forest nearby.  With the body of a lion and the wings and head of an eagle, griffins could grow large enough to ride.  The one that you found was young and small, but no less amazing for its lack of size.
				*set companion_type "griffin"
				*set companion_travels "pads along beside you"
				*set companion_familiar false
				*label Academy_NameCompanion
				
				You decided to name ${companion_himher}:
				*label Name_Griffin
				*input_text companion_name
				*if (companion_name="None")
					You need to name ${companion_himher} something!
					*goto Name_Griffin
				The creature seemed to like what you called ${companion_himher} and ${companion_travels} happily.
				*label Academy_AfterCompanion
				
				*if (class_druid>0)
					You had just dropped off a batch of natural ingredients to an alchemist in the Academy when you were attacked by the golem.
					*goto Academy_AfterJob
				*else
					You had just escorted a wizard back to the Academy when you were attacked by the golem.
					*goto Academy_AfterJob
			#A small owlbear.
				You weren't sure how such a magical beast ended up getting loose in the forest nearby.  With the body of a bear and the head of an owl, owlbears were known to grow larger than their bear counterparts.  The one that you found was young and small, but no less amazing for its lack of size.
				*set companion_type "owlbear"
				*set companion_travels "walks beside you"
				*set companion_familiar false
				*goto Academy_NameCompanion
			#A tanuki.
				You weren't sure how such a magical beast ended up getting loose in the forest nearby.  The tanuki resembled a raccoon in many ways, except for the fact that it walked on two legs and had human-like hands.  Its curious nature meant that it was always getting into mischievous trouble.
				*set companion_type "tanuki"
				*set companion_travels "waddled along beside you"
				*set companion_familiar false
				*goto Academy_NameCompanion
			#You left all of the strange animals in the woods.
				Although interesting, you decided to not take any of them with you.
				*goto Academy_AfterCompanion
	*if (class_assassin>0) #You contacted the Guild of Assassins and got to work.
		The city of the Academy had many of the usual contracts, but the interesting jobs were when the marks were Academy wizards.  Even in the Academy, there were gardens that needed weeding.  Mages made people angry as much as, or even more than, regular people.  They were no harder to kill either, as long as they didn't see you coming.  Your handler was a wizard who lived in the tower, which was great because he taught you several mystical ways to move without being seen.
		*gosub Level_Assassin
		
		You had just finished speaking to your handler when you were attacked by the golem outside of an Academy classroom.
		*goto Academy_AfterJob
	#You offered to work in the Academy libraries as a sage.
		The great libraries of the Academy were the largest in the land.  They were always hiring people for many different tasks.
		*set academy_stay "sage"
		*if ((arcana>=40) or (class_sage>=1))
			Your knowledge quickly made the head librarian give you a job working among the books.
			*gosub Level_Sage
			
			You were on your way to the libraries when you were attacked by the golem.
			*goto Academy_AfterJob
		*else
			Unfortunately, your knowledge of the tomes in the libraries wasn't good enough for the head librarian to give you the job.
			(Needed 40 Arcana or Level 1 Sage)
			*goto Academy_jobloop
	#You mugged the untrained wizards for profit as a thug.
		Young wizards were often weak and easily intimidated, before they learned their magic.  Luckily, they also had big egos, so they didn't take your muggings to the authorities.
		*set academy_stay "thug"
		*gosub Level_Thug
		
		You were just leaving the room of a young mage whom you had bullied into giving you some coins, when you were attacked by the golem.
		*goto Academy_AfterJob

*label Academy_AfterJob

Judging from all of the panicked young wizards who rush out of the classroom behind the golem, you suspect that the mighty construct was accidentally awakened by one of their miscast spells.  An aged master wizard stands among the students, eyes wide as the golem advances on you and the stone slab continues to slide toward the large hole behind you.
*label Academy_Golem_loop
*choice
	#Attempt to circle around the golem and go back to the safety of the hallway behind it.
		*if (belt_of_speed)
			Thuja's Belt of Speed suddenly glows brightly around your waist.  You are a blur as you speed back to the safety of the hallway before the belt stops glowing again.
			*goto Academy_Safe
		*if (agility>=40)
			The golem swings its mighty fists at you again, but you manage to dodge the blows and return to safety.  Small chunks of stone fly about the room as you join the master wizard and his class of students.
			*if (showstats)
				*line_break
				(Agility +3)
			*set agility +3
			*label Academy_Safe
			
			The teacher of the class raises both hands over his head and casts a spell.  Bright white motes of colour erupt from his hands and splash over the golem like foam from a shaken ale keg.  The metal monster stops moving as it is immobilized by the magic.
			*if (academy_hanger)
				Several of the students rush forward to help you back into the tower.
			*label Academy_Stop_Golem
			
			Sometimes you question the sanity of having so many students learning magic in one place.  It seems like there are always magical accidents happening and the death rate in the Academy is frighteningly high.
			*goto Academy_AfterGolem
		*else
			The golem's fist catches your shoulder as you attempt to get away.  You are spun in a circle from the impact and fall to the ground.
			*if (showstats)
				(Needed 40 Agility)
			*label Academy_Failed
			
			The teacher of the class raises both hands over his head and casts a spell.  Bright white motes of colour erupt from his hands and splash over the scene like foam from a shaken ale keg.  The white particles cover both you and the golem, causing both of you to completely stop moving.  The pain from the immobilization spell causes you to pass out almost right away.
			*page_break Blackness…
			You wake up in the Academy infirmary several weeks later.  Sometimes you question the sanity of having so many students learning magic in one place.  Although you feel the painful side effects of the magic for the rest of your life, you know the fact that you survived makes you one of the luckier victims of the Academy's magic.
			*if (showstats)
				*line_break
				(Health to 100, Agility -1, Charm -1, Endurance -1, Perception -1 and Strength -1)
			*set health 100
			*set agility -1
			*set charm -1
			*set endurance -1
			*set perception -1
			*set strength -1
			*goto Academy_AfterGolem
	#Attempt to push your way through the broken walls and into an adjacent room.
		*if (strength>=40)
			The broken masonry allows you to push your way through the wall and into safety.
			*if (showstats)
				*line_break
				(Strength +3)
			*set strength +3
			*goto Academy_Safe
		*else
			The broken masonry is too heavy to push out of the way.  The golem advances upon you as you fail to dig your way free.
			*if (showstats)
				(Needed 40 Strength)
			*goto Academy_Failed
	#Attempt to dispel the animation spell upon the golem.
		*if (magic>=55)
			The spell is complex, but you are up to the task.  Bright white motes of colour erupt from your hands and splash over the golem like foam from a shaken ale keg.  The metal construct  becomes immobile as your magic deactivates it.  The master wizard nods at you in appreciation as the students applaud your heroics.
			*if (showstats)
				*line_break
				(Magic +2)
			*set magic +2
			*goto Academy_Stop_Golem
		The magic is complex and you stumble over the incantation.  You create a few flecks of white between your fingers, but this is all.
		*if (showstats)
			(Needed 55 Magic)
		*goto Academy_Failed
	*if (demonsummoner)
		*allow_reuse #Consider using a Demonstone.
			You open your runebag and consider your options.
			*comment Max Willpower is 50
			*label Academy_Demon_loop
			*choice
				*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and (demonstone_xiatta_used=false)) #Summon Xi'atta and tell the demon to attack the golem.
					*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
					*comment Min 45 to Max 60
					Xi'atta appears in front of you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
					
					"Yes, ${mastermistress}," Xi'atta says, although you find yourself forcing the demon against its will.
					
					The imp raises its fingers and blasts the golem with cold.  Although this doesn't harm the metal monster, you see that its actions are slowed.  You take advantage of this to slip around the construct to the safety of the hall.
					*goto Academy_Safe
				*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and (demonstone_brahl_used=false)) #Summon Brahl and tell the demon to attack the golem.
					*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
					*comment Min 45 to Max 60
					Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
					
					*if (willpower>=60)
						*set demonstone_brahl_used true
						"Yes, ${mastermistress}," Brahl says, although you find yourself forcing the demon to do your bidding, but it doesn't exert its full strength against you.  "I'll give it a go."
						
						The large creature attacks the golem, raking its claws against the golem's metal surface to no avail.  The strong demon puts up a bit of a fight, although it doesn't look like it will win.  You use the distraction to circle around to the safety of the hallway.  The golem smashes Brahl into a sticky pulp, causing the demon to return to its own plane of existence to heal, but at least you are safe.
						*goto Academy_Safe
					*else
						"I like a good fight, but that thing looks too tough," Brahl says as the contest of wills is rejoined and the brawny demon pops out of existence.
						*if (showstats)
							(Needed 60 Willpower)
						*goto Academy_Demon_loop
				*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and (demonstone_zonch_used=false)) #Summon Zon'ch and tell the demon to attack the golem.
					*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
					*comment Min 45 to Max 60
					Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
					
					*if (willpower>=50)
						*set demonstone_zonch_used true
						"Yes, ${mastermistress}," Zon'ch says, although you find yourself forcing the demon against its will.
						
						The dusty imp throws a handful of windy dust at the golem.  The construct doesn't even notice as it crushes the demon with a single punch.  Zon'ch disappears from reality, returning to the demonrealm to heal.
						*goto Academy_Demon_loop
					*else
						"I don't think so," Zon'ch rasps as the contest of wills is rejoined and the dusty demon pops out of existence.
						*if (showstats)
							(Needed 50 Willpower)
						*goto Academy_Demon_loop
				*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and (demonstone_daanda_used=false)) #Summon Daan'da and tell the demon to attack the golem.
					*comment daanda: Willing: 10, Small Struggle: 10, Against: 10
					Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
					*comment Will of 0, but very stupid and weak.
					*set demonstone_daanda_used true
					
					"Okay, ${mastermistress}," Daan'da says.
					
					Daan'da lowers its head as though it plans to run, but instead, it merely waddles toward the golem.  The iron construct lifts a foot and squashes the demon into a gooey mess.  The debris pops out of existence, returning to its own realm to heal.
					*goto Academy_Demon_loop
				*allow_reuse #Close your runebag.
					*goto Academy_Golem_loop		
	#Allow yourself to fall through the hole, grab the ledge and hang there.
		The golem continues its rampage by smashing at the walls as you hang from the edge of the tower.
		*if (endurance>=40)
			*if (showstats)
				*line_break
				(Endurance +3)
			*set endurance +3
			*set academy_hanger true
			*goto Academy_Safe
		*else
			You feel your arms burning as you fight to hang on.  Knowing that you are going to fall to your death, you are forced to climb back into the dangerous room.
			*if (showstats)
				(Needed 40 Endurance)
			*goto Academy_Failed
	*if (cloak_of_spiders) #Use the Cloak of Spiders to climb the outside of the tower.
		You quickly jump through the hole and climb up the outside wall for a short distance while the golem smashes the walls and floor where you had been.
		*set academy_hanger true
		*goto Academy_Safe
	*if (magic_shield) #Hide behind your magic shield.
		The golem's fists repeatedly smash against your magic shield as you hide behind it.  After a bit, it gets bored and turns its attention to the walls again.  You rush quickly into the safety of the hallway as soon as you can.
		*goto Academy_Safe

*label Academy_AfterGolem
*if ((jacejess_story=4) and (friend1_name=jacejess_name))
	
	A few weeks after the incident with the golem, ${friend1_name} finds what ${friend1_heshe} has been looking for.  $!{friend1_heshe} has taken your advice and applied for readmission to the Academy.  The new Archmage, Master Cumari, is much more liberal than his predecessor and ${jacejess_name} is accepted with open arms.  The wizards of the Academy are thrilled to have a Soulburner present to answer all of their questions.
	*set academy_metcumari true
	
	"It's a really old tome," ${friend1_name} says excitedly.  "Unfortunately, it's in the forbidden section, which is why nobody knows about it."
	
	It makes you wonder who ${friend1_name} has been speaking to, to learn of its existence.  It also makes you wonder if Soulburning truly is as evil as people say, or if it's simply the wizards' own fear which made them hide the tome away with other magic considered to be evil.
	*label Academy_Forbidden_loop
	*choice
		#Talk Master Cumari into letting ${friend1_name} look at the book.
			"The book is in the forbidden section because it contains something dangerous," the old Archmage says.
			
			You tell him many reasons why ${jacejess_name} should be allowed to see the book anyway.  You try your best to explain that knowledge by itself isn't good or evil; instead, it is how a person chooses to use it.  Eventually, he puts up his hands to make you stop speaking.
			
			*if (charm>=35)
				*set book_needs_returning true
				"Okay, I'll let your friend look at the book," he relents.
				*if (showstats)
					*line_break
					(Charm +3)
				*set charm +3
				*goto Academy_forbidden_success
			*else
				"I'm afraid it's off limits and I won't change my mind," he says, ending the conversation.
				*if (showstats)
					(Needed 35 Charm)
				*goto Academy_Forbidden_loop
		*selectable_if (gold>=100) #Hire someone from the Thieves Guild to steal the book.  (Needs 100 Gold)
			Although it's against the Guild's rules to steal from the Academy, you eventually find a thief brave (or stupid) enough to do it.
			*if (showstats)
				*line_break
				(Gold -100)
			*set gold -100
			*goto Academy_forbidden_success
		*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and ((demonstone_daanda_used=false) and (demonsummoner))) #Summon Daan'da and tell the demon to open the door to the forbidden section.
			*comment Daan'da will of 0, but very stupid and weak.
			Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
			
			"Okay, ${mastermistress}," Daan'da says as it tries to open the door.
			
			"It's locked," it says stupidly before popping out of existence.
			*goto Academy_Forbidden_loop
		#Pick the lock of the door to the forbidden section.
			*if (lockpickset=false)
				With no lockpick set, you find yourself unable to get the door open.
				*goto Academy_Forbidden_loop
			You carefully apply all of the different tools of your lockpick set to the door.
			*if (devices>=30)
				Eventually you open it.  ${friend1_name} quickly rushes inside and gets the book before you close the door again.  Your theft must have been noticed because the next time you pass the door a wizard guard is posted to prevent any further burglaries.
				*if (showstats)
					*line_break
					(Devices +3)
				*set devices +3
				*goto Academy_forbidden_success
			*else
				You try to open the door with your lockpicks, but despite all of your trying, it won't open for you.
				*if (showstats)
					(Needed 30 Devices)
				*goto Academy_Forbidden_loop
		#Steal the Archmage's key.
			Master Cumari is a friendly man who happily speaks to everyone.
			*if (stealth>=30)
				You find it very easy to take the key out of his pocket during a friendly conversation and give it to ${friend1_name}.
				*if (showstats)
					*line_break
					(Stealth +3)
				*set stealth +3
				*label Academy_forbidden_success
				
				${friend1_name} becomes very withdrawn and silent after getting the book.
				*if (book_needs_returning )
					$!{friend1_heshe} returns it to Archmage Cumari a few weeks later.
				
				"It was a terrible book," ${friend1_name} says.  "Ancient Soulburners learned a way to use someone else's lifeforce to fuel their magic.  All that power, with none of the cost to themselves.  I think I see why people don't like us very much."
				*set soulburner_knowledge true
				*choice
					#Ask, "Will you use the knowledge?"
						*if (good>=50)
							"No," ${friend1_name} says.  "It's terrible.  It would kill an innocent person.  I won't use it."
						*if (good<50)
							"I don't know," ${friend1_name} says.  "It would kill an innocent person."
						*goto Academy_AfterJaceJessQuest
					#Say, "You should use the knowledge…power is power."
						"I imagine I could," ${friend1_name} says thoughtfully.
						*if (showstats)
							*line_break
							(Evil +5)
						*set good -5
						*goto Academy_AfterJaceJessQuest
					#Say, "It's terrible!  Promise me you'll never use it."
						"I promise," ${friend1_name} says.  "It would kill an innocent person."
						*if (showstats)
							*line_break
							(Good +5)
						*set good +5
						*goto Academy_AfterJaceJessQuest
					#Offer no advice.
						"I won't use it, "${friend1_name} says.
						*if (good>=50)
							"It would kill an innocent person.  I wish I'd never seen the vile book."
						*if (good<50)
							
							Despite ${friend1_hisher} words, you wonder if ${friend1_heshe} will be able to resist the temptation of power.
						*goto Academy_AfterJaceJessQuest
			*else
				Unfortunately, no matter how many conversations you have with him, you never seem to find a chance to take the key out of his pocket.
				*goto Academy_forbidden_loop
		#Say, "I'm sorry, I have no idea how to get into the forbidden section."
			${friend1_name} is saddened by your words, but with no way to get to the secret books, there's nothing ${friend1_heshe} can do about it.
			*goto Academy_AfterJaceJessQuest
		#Say, "I'm sorry, ${friend1_name}, I won't help you get the book.  It's forbidden for a reason."
			${friend1_name} is saddened by your words, but with no way to get to the secret books, there's nothing ${friend1_heshe} can do about it.
			*if (showstats)
				*line_break
				(Good +3 and ${jacejess_name} Relationship -5)
			*set good +3
			*set jacejess_relationship -5
			*goto Academy_AfterJaceJessQuest
*else
	*goto Academy_AfterJaceJessQuest

*label Academy_AfterJaceJessQuest
*if (book_of_wizardry)
	
	The Academy textbook you found among Jowal's books was of great interest to the Academy.  Although they were eager to share knowledge, they wanted control of the process since freely distributed books were dangerous and took away their control of magic use across the land.  As such, they paid good coin to get them back.
	*label Book_loop
	*choice
		#Return the book to the Academy.
			The Academy librarian is very happy to get the tome back.
			
			"Did you read it?" he asks as he looks over the book.
			*choice
				*if (read_book_of_wizardry) #Lie and say, "No, I didn't."
					He looks at you for a moment longer and then hands you some coins for your troubles as he takes the book.
					*goto Academy_ReturnReward
				*if (read_book_of_wizardry) #Tell the truth and say, "Yes, I did."
					*label Academy_Readit
					"It's a pretty big temptation, huh," he says with a twinkle in his eye.  "Thank you for your honesty and thank you for returning the book."
					*label Academy_ReturnReward
					*set book_of_wizardry false
					*if (showstats)
						*line_break
						(Lost Book of Wizardry, Charm +3 and Gold +75)
					*set charm +3
					*set gold +75
					*goto Academy_Afterbook
				*if (read_book_of_wizardry=false) #Lie and say, "Yes, I did."
					*goto Academy_Readit
				*if (read_book_of_wizardry=false) #Tell the truth and say, "No, I didn't."
					"Really?" he says as he studies your face.  "You have more willpower than I do.  Feel free to come by any time.  I have access to many interesting books which you may enjoy."
					
					During your time at the Academy you read a few of the books the old librarian suggests.  He also gives you a few coins for your troubles.
					*set book_of_wizardry false
					*if (showstats)
						*line_break
						(Good +5, Lost Book of Wizardry, History +5, Geography +5, Arcana +5 and Gold +95)
					*set good +5
					*set history +5
					*set geography +5
					*set arcana +5
					*set gold +95
					*goto Academy_Afterbook
		*if (read_book_of_wizardry=false) #Read the book, even though it is illegal to do so.
			The Academy's monopoly on all things magical is solid for a reason.  The text is insightful and cuts to the heart of many issues.
			*if (showstats)
				*line_break
				(Magic +5 and Evil +2)
			*set magic +5
			*set good -2
			*set read_book_of_wizardry true
			*goto Book_loop
		*if(read_book_of_wizardry) #Read the book a second time.
			There are many passages which you still don't entirely understand.  This is the reason the Academy gives for wanting to keep all magic under its thumb.  It's entirely possible that the book's concepts are flawed and may harm a student's progress.  Or, it could be due to your own lack of understanding. With greater insight, perhaps you might glean even more knowledge from it in the future.
			*goto Book_loop
		#Keep the book.
			You keep the book in your backpack and make sure that nobody from the Academy sees it.
			*goto Academy_AfterBook
*else
	*goto Academy_AfterBook

*label Academy_AfterBook
*if (unfinished_magicdagger)
	
	The odd magic dagger that Vitus Malichotti made you steal has many strange magical properties.  The most obvious property is its lack of a sharp edge, making it useless as a regular dagger. The wizards of the Academy are eager to look at it.  They quickly conclude that the enchanting process had been left unfinished.  One of them even offers to conclude the rite, for a fee.
	*label Academy_dagger
	*choice
		*selectable_if (gold>=200) #Pay the wizard to finish the enchantment.  (Needs 200 Gold)
			The wizard takes the money and allows you to come back a few weeks later when the spell is ready to be cast.  The mage lights several candles and inscribes runes all around the dagger before chanting the magic words.  To your surprise, the dagger shrinks until it's the size of a plum.
			*if (showstats)
				*line_break
				(Gold -200)
			*set gold -200
			*goto Academy_dagger_success
		#Attempt to finish the spell yourself.
			You gather the necessary components and research what will be needed.  Not knowing what has already been done makes things a lot more difficult.  You light the candles, place the unfinished dagger in the centre of a bunch of carefully drawn runes and chant the magic words.
			*set unfinished_magicdagger false
			*if (magic>=50)
				To your surprise, the dagger shrinks until it's the size of a plum.
				*if (showstats)
					*line_break
					(Magic +2)
				*set magic +2
				*label Academy_dagger_success
				*set unfinished_magicdagger false
				
				The finished product isn't a dagger at all, but a talisman.  You put it onto a chain and wear it around your neck.  You feel some of its effects immediately but also wonder what else it may be capable of.
				*if (showstats)
					*line_break
					(Stealth +${thief_token_bonus}, Devices +${thief_token_bonus} and Agility +${thief_token_bonus})
				*set thief_token true
				*set stealth + thief_token_bonus
				*set devices + thief_token_bonus
				*set agility + thief_token_bonus
				*goto Academy_AfterDagger
			*else
				The dagger shines briefly for a moment and then returns to normal.  You realize that you don't have the magic needed to finish the ritual.
				*if (showstats)
					(Needed 50 Magic)
				*goto Academy_dagger
		*allow_reuse #Offer to sell the blade to the wizard.
			"Well, I suppose I could take it off your hands.  I must admit, I am curious as to its nature."
			*choice
				#Sell the blade for 100 coins.
					The wizard pays you and takes the unfinished dagger.
					*if (showstats)
						*line_break
						(Gold +100 and Lost Unfinished Dagger)
					*set gold +100
					*set unfinished_magicdagger false
					*set thiefquest 10
					*goto Academy_AfterDagger
				*allow_reuse #Don't sell it.
					*goto Academy_dagger
		#Put the unfinished dagger back into your backpack, even though it is useless.
			In the end, you decide to keep the unfinished dagger.
			*goto Academy_AfterDagger
*else
	*goto Academy_AfterDagger

*label Academy_AfterDagger
*goto Leaving

*comment ----------------------------------------Tornassa-------------------------------------
*label Tornassa
"Come out with your hands up," the guard yells through the broken window.

You take a moment to look through the shattered glass.  The night is dark, but the city guards are holding torches, like a lynch mob, which light up their shiny armour with flickers of colour.
*if (friend1_name=theothea_name)
	${friend1_name} stands beside you.  The muscular warrior glares at the men through ${friend1_hisher} messy black hair as ${friend1_heshe} grips ${friend1_hisher} oversized warhammer.
*if (friend1_name=jacejess_name)
	${friend1_name} stands beside you with an arrogant expression on ${friend1_hisher} fine-featured face.  The white streak through ${friend1_hisher} jet black hair shines brightly in the torchlight.
	
	"Here we go again," the Soulburner grumbles under ${jacejess_hisher} breath.
*if (friend1_name=gillgale_name)
	${friend1_name} stands beside you, ${friend1_hisher} hands casually resting on the hilts of ${friend1_hisher} two short swords.  A mischievous grin curls the corners of ${friend1_hisher} mouth upward as ${friend1_heshe} surveys the scene.
*if (friend1_name=peterpetra_name)
	${friend1_name} stands beside you with a stern look on ${friend1_hisher} face.  $!{friend1_hisher} hand rests on the handle of ${friend1_hisher} morningstar as ${friend1_hisher} eyes shine with holy conviction.
*if (friend1_name=karlkarla_name)
	${friend1_name} stands beside you with a nervous expression on ${friend1_hisher} face.  $!{friend1_hisher} dexterous hands are only inches away from ${friend1_hisher} bow and quiver.
*choice
	#The guards have the wrong ${mc_manwoman}.
		You know that it would be futile to call out and declare your innocence.  They believe you are guilty and that's all that matters to them at the moment.
		*set tornassa_innocent true
		*goto Tornassa_Job
	#You are guilty, but that doesn't mean that you will turn yourself in.
		The guards have found you.  They are angry and upset.  You know that they won't take it easy on you if they catch you.
		*set tornassa_innocent false
		*goto Tornassa_Job

*label Tornassa_Job

The enormous city had fallen on hard times since you had lived there as a child.  Crime is running rampant and everyone looks out only for themselves.  It's still a large city, though, and full of opportunities.
*if (using_legacy)
	Although you've looked for ${legacy_himher} in your exile, the time-traveling wizard from the past hasn't visited you a single time since leaving Vernex.
*label Tornassa_jobloop
*choice
	*if (class_squire>0) #You asked for the location of the next grand tournament and trained hard for it.
		The life of a squire was filled with training and serving your fellow knights.  With no tournament currently taking place, you concentrated on perfecting your techniques.  In addition to swordplay and horsemanship, you studied the knight's code and its history.
		*gosub Level_Squire
		*goto Tornassa_AfterJob
	*if (class_bard>0) #You enrolled in the famous Bardic College of Tornassa.
		You were already talented before you joined, but the classical training really improved your music.  The best part was, they had a large building called a 'theatre'.
		
		The theatre gig was much better than any tavern could provide.  It was a novel concept for patrons to spend money for entrance into the building to watch the performers.  As the months went by, your fan base grew.  Before long you were headlining the shows.
		*gosub Level_Bard
		*goto Tornassa_AfterJob
	*if ((class_thief=0) and (no_thief_vow=false)) #You joined the Thieves Guild.
		Tornassa had the largest chapter of the Thieves Guild.  The compound was enormous and not hidden at all.  Many merchants were well-known members.  You were taught the secret hand gestures of the Guild and attended formal classes in the arts of stealthy walking, pick pocketing and trap disarming.
		*gosub Level_Thief
		*goto Tornassa_AfterJob
	*if (class_thief>=1) #You performed many jobs for the Thieves Guild.
		Tornassa had the largest chapter of the Thieves Guild.  The compound was enormous and not hidden at all.  Many merchants were well-known members.  Your skills were quickly noticed and you rose through the ranks.
		*gosub Level_Thief
		*goto Tornassa_AfterJob
	#You offered your services as a guard.
		The large city of Tornassa was ripe with opportunities.  Although the city itself hired guards, the best jobs were those held privately. You quickly found a position working for a prominent merchant.
		*gosub Level_Guard
		*goto Tornassa_AfterJob
	*if (((class_priest=0) and (exgoodpriest=false)) and (exevilpriest=false)) #You followed your religious convictions and became a ${priestpriestess}.
		The large temples of Tornassa housed all of the different Gods and Goddesses of the land.  You were a little old to hear the call, but you were ordained as a ${priestpriestess} all the same.
		*gosub Level_Priest
		*if (god_good=false)
			
			Your evil ${god_goddess} had a thriving community in the bowels of the great city.
		*goto Tornassa_AfterJob
	*if ((class_priest>=1) or (class_cleric>=1)) #You joined the local temple dedicated to ${god_name} and continued your religious vocation.
		The large temples of Tornassa housed all of the different Gods and Goddesses of the land.
		*if (god_good=false)
			Your evil ${god_goddess} had a thriving community in the bowels of the great city.
		*choice
			#You delivered spiritual sermons.
				Your sermons were very introspective and life changing as you led the worship of your congregation.
				*gosub Level_Priest
				*goto Tornassa_AfterJob
			#You led a very militaristic sect of your order.
				You preached about action and led by example as you studied the sword and shield.
				*gosub Level_Cleric
				*goto Tornassa_AfterJob
	*if (class_monk>0) #You moved into one of the local monasteries.
		You didn't need to follow any doctrines or organized religions to find self-enlightenment, but the large monastery on the edge of the city gave you a small room to sleep in and food to eat while you meditated and cultured your spirit.  The large library in the monastery allowed you to nurture your mind as well.
		*gosub Level_Monk
		*goto Tornassa_AfterJob
	*if ((spellbook) and (class_wizard=0)) #You spent your days reading your spellbook.
		*label Tornassa_LearnMagic
		The city of Tornassa had many people doing many things.  Your time spent studying your spellbook taught you a lot of interesting spells and techniques.
		*gosub Level_Wizard
		*goto Tornassa_AfterJob
	*if ((spellbook=false) and (class_wizard=0))
		*selectable_if (gold>=100) #You bought a spellbook and taught yourself magic. (Needs 100 Gold)
			It wasn't difficult to get a spellbook, although it was horribly overpriced.  It wasn't an Academy textbook, since those were illegal to sell outside of the school, but it was still full of great information.
			*if (showstats)
				*line_break
				(Gold -100 and Gained Spellbook)
			*set gold -100
			*set spellbook true
			
			*goto Tornassa_LearnMagic
	*if (class_wizard>=1) #You tried to find another master wizard to apprentice under.
		Xino had been a wonderful teacher and was a well-respected wizard.  It wasn't easy to find another wizard who would take on an apprentice, but with Xino as a reference, you found one.
		
		Edmund was a real old curmudgeon, but he knew his magic.  He helped you with a lot of your spells and even taught you how to summon a familiar, although he warned you that such a ritual could only be used once.  He said that many wizards waited their whole lives to find a familiar and that many ended up dying alone due to indecision.
		*gosub Level_Wizard
		*choice
			#You used the spell to bond a cat.
				A feline companion was a very popular choice for a wizard, likely due to their ease of bonding.
				*rand coinflip 1 2
				*if (coinflip=1)
					*set companion_hisher "his"
					*set companion_heshe "he"
					*set companion_himher "him"
					The tom cat you found was a smart old alley cat, but after the ritual, his intelligence grew even more.
				*if (coinflip=2)
					*set companion_hisher "her"
					*set companion_heshe "she"
					*set companion_himher "her"
					The cur you found was a smart old alley cat, but after the ritual, her intelligence grew even more.
				*set companion_travels "pads along beside you"
				*set companion_type "cat"
				*set companion_familiar true
				
				You decided to name ${companion_himher}:
				*label Name_Cat
				*input_text companion_name
				*if (companion_name="None")
					You need to name ${companion_himher} something!
					*goto Name_Cat
				The creature seemed to like what you called ${companion_himher} and ${companion_travels}, happily.
				*goto Tornassa_AfterJob
			*selectable_if (gold>=1) #You paid a boy to catch you a mouse for the spell.  (Needs 1 Gold)
				Tornassa was filled with vermin, so the boy you hired had no trouble catching you a small mouse.  The brown furred rodent looked petrified as the boy handed it over to you.  Once the ritual was complete, the creature's fear was gone.
				*if (showstats)
					*line_break
					(Gold -1)
				*set gold -1
				*rand coinflip 1 2
				*if (coinflip=1)
					*set companion_hisher "his"
					*set companion_heshe "he"
					*set companion_himher "him"
				*if (coinflip=2)
					*set companion_hisher "her"
					*set companion_heshe "she"
					*set companion_himher "her"
				*set companion_type "mouse"
				*set companion_travels "sits on your shoulder"
				*set companion_familiar true
				
				You decided to name ${companion_himher}:
				*label Name_Mouse
				*input_text companion_name
				*if (companion_name="None")
					You need to name ${companion_himher} something!
					*goto Name_Mouse
				The creature seemed to like what you called ${companion_himher} and ${companion_travels} happily.
				*set companion_familiar true
				*goto Tornassa_AfterJob
			#You saved the spell for later.
				You put the spell away, planning to save it for a more worthy animal.
				*goto Tornassa_AfterJob
	*if (class_druid>=1) #You spent your time communing with nature outside of Tornassa.
		The woods were sparse and not very private.  Loggers, hunters and poachers were constantly tromping through it.  Despite this, you still found the peacefulness of nature soothing.
		*gosub Level_Druid
		*goto Tornassa_companion
	*if (class_ranger>=1) #You got a job as a hunting guide.
		The woods were sparse and not very private.  Loggers, hunters and poachers were constantly tromping through it.  Despite this, you still found the peacefulness of nature soothing. Your clients appreciated your knowledge as you took them to the best hunting spots.
		*gosub Level_Ranger
		*label Tornassa_companion
		*if (companion_type="None")
			
			Although your exposure to wild animals was extremely limited in the well-traveled surrounding forests, something strange happened one day.  You were walking through the city streets when an animal approached you.
			*rand coinflip 1 2
			*if (coinflip=1)
				*set companion_hisher "his"
				*set companion_heshe "he"
				*set companion_himher "him"
			*if (coinflip=2)
				*set companion_hisher "her"
				*set companion_heshe "she"
				*set companion_himher "her"
			*set companion_familiar false
			*choice
				#A pigeon flew down from the sky and landed on your shoulder.
					The city bird simply sat there, looking at you.  $!{companion_heshe} was a beautiful deep grey with a bright white stomach.  After a more careful examination, you realized that it was actually a dove.
					*set companion_type "dove"
					*set companion_travels "flies overhead"
					*label Tornassa_KeepIt
					*choice
						#You kept the ${companion_type}.
							It felt nice, having a small piece of nature with you wherever you went.
							
							You decided to name ${companion_himher}:
							*label Name_Pigeon_Dog
							*input_text companion_name
							*if (companion_name="None")
								You need to name ${companion_himher} something!
								*goto Name_Pigeon_Dog
							The creature seemed to like what you called ${companion_himher} and ${companion_travels} happily.
							*goto Tornassa_AfterJob
						#You shooed the ${companion_type} away.
							*set companion_type "None"
							Although it might have been nice to have had a small piece of nature with you wherever you went, you decided to send ${companion_himher} away.
							*goto Tornassa_AfterJob
				#A mangy dog curled up around your legs.
					The city mutt was smelly and ragged, but you saw some potential in the animal through the layers of filth. The dog was strong, energetic and extremely loyal.
					*set companion_travels "walks along beside you"
					*set companion_type "dog"
					*goto Tornassa_KeepIt
		*else
			*goto Tornassa_AfterJob
	*if (class_assassin>0) #You contacted the Guild of Assassins and got to work.
		The sheer number of contracts available in a city the size of Tornassa was staggering.  Larger gardens meant more weeds.  There seemed to be an unlimited amount of work for a hired killer such as yourself.
		*gosub Level_Assassin
		*goto Tornassa_AfterJob
	#You offered your services as a sage.
		The work in a large city like Tornassa was varied and interesting.  There were a lot of requests for mathematics, especially as it related to business.  Merchants often hired you to plan their trade routes, balance their books and help them make sound financial decisions.
		*if ((arcana>=40) or (class_sage>=1))
			*gosub Level_Sage
			*goto Tornassa_AfterJob
		*else
			Unfortunately, your knowledge of the finer points of finance was not as good as you would have liked.  Word spread of your ineptitude and you soon found yourself without any clients.
			*if (showstats)
				(Needed 40 Arcana or Level 1 Sage)
			*goto Tornassa_jobloop
	#You worked as a hired thug for a rich merchant.
		The business people of Tornassa were always looking for muscle.  Often this simply meant standing next to the client and glaring at people, although occasionally your skills were put to the test when someone didn't pay their bills on time.
		*gosub Level_Thug
		*goto Tornassa_AfterJob

*label Tornassa_AfterJob

Currently, however, the warehouse that you are trapped in is deep in the tanning district.  The smell of dead animals and tanning agents fills the air.  It used to be a prosperous, albeit lowbrow, type of place.  In recent years, it has fallen deeply into the hands of the city's criminal element.

You can hear the guards all around you.  They have all of the doors covered and will soon be charging in to lock you up.  These aren't bad people.  They are simply men and women doing a difficult job.
*if (tornassa_innocent)
	You aren't exactly sure who they think you are,
*if (tornassa_innocent=false)
	You aren't exactly sure which crime they are accusing you of,
but since you are hiding from Alexander Zusak, you know that you can't let them take you.
*label Tornassa_trapped
*choice
	#Punch the captain of the guard in the face with lethal force.
		*if (unarmed>=50)
			The captain falls flat on his back.  With their leader out of the fight, the rest of the guards are easy to beat.  You don't pull any punches as you snap necks and break bones.
			*if (showstats)
				*line_break
				(Unarmed +3 and Evil +10)
			*set unarmed +3
			*set good -10
			*goto Tornassa_BeatGuard
		*else
			The captain ducks the blow and his men come quickly to his aid.
			*goto Tornassa_LostGuard
	*if (bow) #Fire arrows at the guards.
		The first arrow catches the guard captain in the throat.
		*if (archery>=45)
			The second takes out another of their number.  From there, it is confusion as arrows fly and swords clash.
			*if (showstats)
				*line_break
				(Archery +3 and Evil +15)
			*set archery +3
			*set good -15
			*goto Tornassa_BeatGuard
		*else
			Unfortunately, the second arrow misses its mark and the archers' own arrows begin to fly.
			*if (showstats)
				(Needed 45 Archery)
			*goto Tornassa_LostGuard
	*if (sword) #Attack the guards with your sword.
		*if (blades>=45)
			Your sword strikes solidly into the captain of the guard.  From there, it is confusion as arrows fly and swords clash.
			*if (showstats)
				*line_break
				(Blades +3 and Evil +15)
			*set blades +3
			*set good -15
			*label Tornassa_BeatGuard
			
			*if (friend1_name=theothea_name)
				${friend1_name} fights at your side, swinging ${friend1_hisher} enormous warhammer with ease.
			*if (friend1_name=jacejess_name)
				${friend1_name} fights at your side, ${friend1_hisher} eyes glowing a blinding white.  Bright beams of energy slice into your enemies as the Soulburner unleashes ${friend1_hisher} deadly magic.
			*if (friend1_name=gillgale_name)
				${friend1_name} rolls through the guards and begins to attack from behind them.  $!{friend1_hisher} blades are deadly as ${friend1_heshe} slashes at the backs of their legs, dropping them to the ground for you to finish off.
			*if (friend1_name=peterpetra_name)
				${friend1_name} fights at your side, swinging ${friend1_hisher} morningstar with ease.
			*if (friend1_name=karlkarla_name)
				${friend1_name} fights at your side, sending arrow after arrow into your foes.
			A few seconds later and the fight is over.  The guards chose the wrong people to harass.  You look over their corpses before moving on.
			*label Tornassa_Loot
			*if (((sword) and (dagger)) and ((bow) and (tookmoney)))
				*goto Tornassa_AfterGuard
			*choice
				*if (sword=false) #Take a sword.
					You take the guard captain's sword.  It is a sturdy blade with a good edge.
					*if (showstats)
						*line_break
						(Gained Sword)
					*set sword true
					*goto Tornassa_Loot
				*if (dagger=false) #Take a dagger.
					You take one of the guards' daggers.  It has been well cared for and has a comfortable balance.
					*if (showstats)
						*line_break
						(Gained Dagger)
					*set dagger true
					*goto Tornassa_Loot
				*if (bow=false) #Take a bow.
					You take a bow from one of the archers as well as a quiver of arrows.
					*if (showstats)
						*line_break
						(Gained Bow)
					*set bow true
					*goto Tornassa_Loot
				#You take the coins from their money pouches.
					*set tookmoney true
					You gather the coins together into a small pile.
					*choice
						#Split the money with ${friend1_name}.
							You divvy up the money and put you share of the coins into your pouch.
							*if (showstats)
								*line_break
								(${friend1_name} Relationship +3 and Gold +35)
							*set friendinc 3
							*gosub Friend1_Increase
							*set gold +35
							*goto Tornassa_Loot
						#Keep all of the money for yourself.
							You put all of the coins into your pouch.  ${friend1_name} frowns at your actions, but doesn't say anything.
							*if (showstats)
								*line_break
								(${friend1_name} Relationship -5 and Gained 70 Gold)
							*set friendinc 0
							*set friendinc -5
							*gosub Friend1_Increase
							*set gold +70
							*goto Tornassa_Loot
						#Give all of the money to ${friend1_name}.
							${friend1_name} seems surprised by your generosity but happily takes the money.
							*if (friend1_name=peterpetra_name)
								
								"I will be sure to donate this money to a good cause," ${friend1_name} says.
							*if (showstats)
								*line_break
								(${friend1_name} Relationship +5)
							*set friendinc 5
							*gosub Friend1_Increase
							*goto Tornassa_Loot
				#Go on your way.
					You leave the corpses behind and go on your way.
					*goto Tornassa_AfterGuard
		*else
			You manage to injure the captain of the guard, surprising him with your actions, but when one of the archers puts an arrow into your side you aren't able to properly defend against the others.
			*if (showstats)
				(Needed 45 Blades)
			*label Tornassa_LostGuard
			*set tornassa_lostfight true
			*if (showstats)
				*line_break
				(Evil +15)
			*set good -15
			
			${friend1_name} does ${friend1_hisher} best to help you, but after a few minutes of heavy fighting, you are both overwhelmed.
			*if (showstats)
				*line_break
				(Lost all Health)
			*set health 0
			*page_break Blackness…
			You wake up a few minutes later, still lying on the warehouse floor.  You see that ${friend1_name} is lying on the floor beside you.
			*if (showstats)
				*line_break
				(Gained 10 Health)
			*set health 10
			
			*goto Tornassa_fromlost
	#Cast a spell to create an illusion of you and ${friend1_name} escaping across the rooftops.
		You say the magical words and craft the best illusion that you are able to.
		*if (magic>=50)
			The likeness is uncanny.  You walk your dopplegangers across the rooftop of the building next door.  The guards see the illusion and run off in pursuit.  This allows you and ${friend1_name} to quickly escape the warehouse.
			*if (showstats)
				*line_break
				(Magic +3)
			*set magic +3
			*goto Tornassa_AfterGuard
		*else
			Unfortunately, the illusionary forms are rudimentary at best.  The guards see them, but they don't fall for the ruse.
			*if (showstats)
				(Needed 50 Magic)
			*goto Tornassa_trapped
	#Sneak out the back door.
		*if (stealth>=50)
			Your skillful movements allow you to lead ${friend1_name} safely away from the guards without them seeing you.  Looking back, you see that they have the warehouse completely surrounded.
			*if (showstats)
				*line_break
				(Stealth +3)
			*set stealth +3
			*goto Tornassa_AfterGuard
		*else
			You don't get far before one of the guards shouts and points toward you and ${friend1_name}.  You quickly step back into the warehouse.
			*if (showstats)
				(Needed 50 Stealth)
			*goto Tornassa_trapped
	*if (demonsummoner)
		*allow_reuse #Consider using a Demonstone.
			You open your runebag and consider your options.
			*label Tornassa_Demon_loop
			*choice
				*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and ((demonstone_xiatta_used=false) and (demonsummoner))) #Summon Xi'atta and tell it to attack the guards.
					*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
					*comment Min 45 to Max 60
					Xi'atta appears in front of you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
					
					One of the guards puts an arrow into the demon the moment it appears.  Although the arrow turns icy for a moment, the demon still pops out of existence as it returns to its own plane.
					*set demonstone_xiatta_used true
					*goto Tornassa_Demon_loop
				*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl and tell it to attack the guards.
					*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
					*comment Min 45 to Max 60
					Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
					
					*if (willpower>=60)
						"Yes, ${mastermistress}," Brahl says, eager to attack and not fighting your will as much as it could.  "Let's have some fun."
						
						An arrow thunks into the demon as it steps forward and disembowels one of the guards with its sharp claws.  A second arrow strikes it and then a third, but it manages to kill two more guards before it finally succumbs to its wounds, popping out of existence as it returns to its own realm to heal.
						*set demonstone_brahl_used true
						*goto Tornassa_BeatGuard
					*else
						"I'd love to kill a few of these scum," Brahl says.  "But I don't like the idea of getting hacked apart by their blades.  Too many of them."
						
						The contest of wills is rejoined and the brawny demon pops out of existence just before an arrow strikes it.  You get the feeling that it didn't fight you too hard, as though it would have been happy to lose for the excuse to do some violence.
						*if (showstats)
							(Needed 60 Willpower)
						*goto Tornassa_Demon_loop
				*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and ((demonstone_zonch_used=false) and (demonsummoner))) #Summon Zon'ch and tell it to attack the guards.
					*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
					*comment Min 45 to Max 60
					Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
					
					*set demonstone_zonch_used true
					One of the guards fires an arrow at it, but the small demon raises a hand and a dusty wind blows it off course.  Another guard strikes Zon'ch with a sword blade which cuts the demon in half.  Both halves of the demon's body pop out of existence as it returns to its own plane.
					*goto Tornassa_Demon_loop
				*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and ((demonstone_daanda_used=false) and (demonsummoner))) #Summon Daan'da and tell it to attack the guards.
					*comment Will of 0, but very stupid and weak.
					Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
					*set demonstone_daanda_used true
					
					Daan'da balls its hands into fists and turns slowly toward the guards to fight as you command.  A guard hacks off its head before Daan'da even begins to draw back its arm to punch.  Head and body pop out of existence as it returns to its own plane.
					*goto Tornassa_Demon_loop
				*allow_reuse #Close your runebag.
					*goto Tornassa_trapped
	#Surrender to them.
		*label Tornassa_disarming
		The guards rush in and surround you.  They immediately begin searching you and taking away your weapons.
		*label Tornassa_fromlost
		*if (friend1_name=theothea_name)
			${friend1_name} reluctantly gives up ${friend1_hisher} warhammer.
		*if (friend1_name=jacejess_name)
			${friend1_name} gives up a dagger, but you know that ${friend1_hisher} real weapon is ${friend1_hisher} magic.
		*if (friend1_name=gillgale_name)
			${friend1_name} reluctantly gives up ${friend1_hisher} short swords and several knives.
		*if (friend1_name=peterpetra_name)
			${friend1_name} reluctantly gives up ${friend1_hisher} morningstar.
		*if (friend1_name=karlkarla_name)
			${friend1_name} reluctantly gives up ${friend1_hisher} bow and quiver.
		*if (((dagger=false) and (bow=false)) and (sword=false))
			After a few moments of searching, the guards realize that you are carrying no weapons.
			*goto Tornassa_AfterSearch
		*if (showstats)
			*line_break
			*if (((dagger) and (bow=false)) and (sword=false))
				(Lost Dagger)
			*if (((dagger=false) and (bow)) and (sword=false))
				(Lost Bow)
			*if (((dagger=false) and (bow=false)) and (sword))
				(Lost Sword)
			*if (((dagger) and (bow)) and (sword=false))
				(Lost Dagger and Bow)
			*if (((dagger) and (bow=false)) and (sword))
				(Lost Dagger and Sword)
			*if (((dagger=false) and (bow)) and (sword))
				(Lost Bow and Sword)
			*if (((dagger) and (bow)) and (sword))
				(Lost Dagger, Bow and Sword)
		*set sword false
		*set bow false
		*set dagger false
		*set friend1_disarmed true
		*goto Tornassa_AfterSearch
	*if (cloak_of_spiders) #Use your magical Cloak of Spiders to escape.
		${friend1_name} looks at you dubiously as you scale the wall with only your hands and feet.  ${friend1_name} is forced to climb the normal way, but with your help, you both escape the warehouse without getting caught.
		*if (mount_name!="None")
			You're glad that you didn't have ${mount_name}, your ${mount_type}, with you today.
		*goto Tornassa_AfterGuard
	#Try to talk your way out of it.
		"You have the wrong person," you say as the guards enter the building.
		
		*if (charm>=35)
			"Come along, we'll see if we can get this mistake cleared up," the captain of the guard says.
			*if (showstats)
				*line_break
				(Charm +3)
			*set charm +3
			*goto Tornassa_AfterSearch
		*else
			"So you say," the captain of the guard says dubiously.
			*if (showstats)
				(Needed 35 Charm)
			
			*goto Tornassa_disarming

*label Tornassa_AfterSearch

The guards escort you away from the warehouse.  You have only gone a few blocks when you see large clouds of black smoke in the distance.  This is just another indication that the kingdom is falling to ruin.  The captain of the guard talks urgently with the others and they make a quick decision.
*if (tornassa_lostfight)
	
	They leave you and ${friend1_name} tied up on the ground, planning to return for you later.  Whatever caused the fire must have taken them longer to deal with than they thought, because you have over an hour to wiggle free of the ropes and leave the area.
	*goto Tornassa_AfterGuard
You and ${friend1_name} are released as they rush off to investigate the blaze.
*label Tornassa_AfterGuard
*if (mount_name!="None")
	
	When you return to your room later that night, you are pleased to see that the guards aren't there waiting for you.  Your ${mount_type}, ${mount_name}, is safely asleep in the stable too.
*if ((karlkarla_story=2) and (friend1_name=karlkarla_name))
	
	${karlkarla_name} spends the months trying to craft the Infinity Arrow.  It is an interesting concept.  To craft a single arrow so perfectly that the spell to enchant it would be easy enough for a non-wizard to cast.  This form of enchanting is cumbersome and difficult to get correct.  Apparently, such an artifact would be unerringly accurate.  The thousands of failed attempts that ${karlkarla_name} makes still produce high quality arrows that ${karlkarla_heshe} sells to buy the more expensive components.
	
	"Stone or bone," ${karlkarla_heshe} says thoughtfully.  "Normally, I'd say metal, but I've heard that this artifact needs something different.  Or perhaps another ingredient entirely?  It has to be just so.  I've carved and chiseled hundreds, but none of them feel quite right."
	*label KarlKarla_Arrowhead_loop
	*choice
		*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and ((demonstone_zonch_used=false) and (demonsummoner))) #Summon Zon'ch and ask the dusty demon if it has any ideas.
			*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
			*comment Min 45 to Max 60
			Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
			
			"I don't really work in stone, ${mastermistress}," Zon'ch says dubiously.
			
			You force your will upon the demon a little
			*if (willpower>=50)
				more.
				
				"Fine then!  Let me think for a moment…." it says.  "I may be able to chip away at an arrowhead, one dust piece at a time."
				
				The months pass slowly as Zon'ch follows ${karlkarla_name}'s instructions.  In the end, your archer friend is very happy with the finished product.
				*goto KarlKarla_Shaft
			more, but it isn't enough.  The demon vanishes without helping you.
			*if (showstats)
				(Needed 50 Willpower)
			*goto KarlKarla_Arrowhead_loop
		#Attempt to sculpt the arrowhead from a piece of stone yourself.
			You spend a few nights working on the stone, using ${karlkarla_name}'s small hammer and chisel.
			*if (agility>=40)
				Your nimble fingers and patience impress your friend as you create an arrowhead that seems to be without any flaw.
				*if (showstats)
					*line_break
					(Agility +3)
				*set agility +3
				*goto KarlKarla_HeadWorks
			*else
				Unfortunately, none of the arrowheads you make are up to your friend's high standards.
				*if (showstats)
					(Needed 40 Agility)
				*goto KarlKarla_Arrowhead_loop
		#Help ${karlkarla_name} to make the arrowhead ${karlkarla_himher}self.
			You spend a few nights watching ${karlkarla_name} use ${karlkarla_hisher} small hammer and chisel.
			*if (perception>=40)
				Under your supervision and guidance, one of the arrowheads looks perfect.
				*if (showstats)
					*line_break
					(Perception +3)
				*set perception +3
				*goto KarlKarla_HeadWorks
			*else
				Unfortunately, the arrowheads that you think look perfect don't finish the ritual, so clearly you missed seeing some small flaw.
				*if (showstats)
					(Needed 40 Perception)
				*goto KarlKarla_Arrowhead_loop
		*selectable_if (gold>=50) #Hire a craftsman to carve the arrowhead.  (Needs 50 Gold)
			The man you hire is very talented and sculpts the arrowhead for an exorbitant fee.  His attention to detail is unsurpassed and the final product is exactly as you had asked for.
			*if (showstats)
				*line_break
				(Gold -50)
			*set gold -50
			*label KarlKarla_HeadWorks
			
			"I think this might just work," ${karlkarla_name} says happily.
			*goto KarlKarla_Shaft
		#Give up on the Infinity Arrow.
			*label KarlKarla_GaveUp
			Many people have tried to craft the legendary artifact, but if it was easy to do, then they would have succeeded.
			
			"It's a dream," ${friend1_name} says with a shrug.  "Maybe it'll be realized someday."
			*goto After_KarlKarlaQuest
	*label KarlKarla_Shaft
	
	"None of the shafts I've made seem right," ${karlkarla_heshe} says.  "Perhaps a rare type of wood?  I'm not certain what to use."
	*label KarlKarla_Shaft_loop
	*choice
		#Use your knowledge of magical items to suggest the right type of wood.
			*if (arcana>=40)
				You suggest using the Silver Ash for its properties of flight, accuracy and synergy with the realm of air.
				*if (showstats)
					*line_break
					(Arcana +3)
				*set arcana +3
				*goto KarlKarla_ShaftWorks
			*else
				You suggest using the Black Oak.  ${karlkarla_name} makes a few shafts using this wood, but isn't happy with the outcome.  You begin to think that it might not be the right type of wood after all.
				*if (showstats)
					(Needed 40 Arcana)
				*goto KarlKarla_Shaft_loop
		#Consult the history books about the Infinity Arrow.
			*if (history>=40)
				It takes some digging, but you eventually see reference to the Silver Ash in conjunction with the Infinity Arrow.
				*if (showstats)
					*line_break
					(History +3)
				*set history +3
				*goto KarlKarla_ShaftWorks
			*else
				No matter how many books you read, none of them mention the type of wood used to make the legendary arrow.
				*if (showstats)
					(Needed 40 History)
				*goto KarlKarla_Shaft_loop
		#Use a divination spell to find the right type of wood.
			You cast the augury and consult the results.  The tea leaves, cloud patterns, mirrors and water pans you consult
			*if (magic>=60)
				all say the same thing:  The Silver Ash is the best wood to use.
				*if (showstats)
					*line_break
					(Magic +3)
				*set magic +3
				*goto KarlKarla_ShaftWorks
			*else
				each suggest a different type of wood.  In the end, you realize that divination is not going to give you the answer.
				*if (showstats)
					(Needed 60 Magic)
				*goto KarlKarla_Shaft_loop
		#Use your knowledge of trees to select the right type of wood.
			*if (nature>=40)
				Although many types would probably work, you know that the Silver Ash is probably the best suited for its balance of strength and malleability.
				*if (showstats)
					*line_break
					(Nature +3)
				*set nature +3
				*goto KarlKarla_ShaftWorks
			*else
				You suggest a sturdy oak.  ${karlkarla_name} makes a few shafts using this wood, but isn't happy with the outcome.  You begin to think that it might not be the right type of wood after all.
				*if (showstats)
					(Needed 40 Nature)
				*goto KarlKarla_Shaft_loop
		*selectable_if (gold>=50) #You pay a sage to choose the correct type of wood.  (Needs 50 Gold)
			The sage you hire pores over many arcane tomes and eventually returns with her opinion.
			*if (showstats)
				*line_break
				(Gold -50)
			*set gold -50
			
			"I think that you should use the Silver Ash," the sage says.
			*label KarlKarla_ShaftWorks
			
			${karlkarla_name} crafts the shaft using the special white wood.  It looks much like any other shaft, but when ${karlkarla_heshe} is done ${karlkarla_heshe} claims that it is special.
			*goto KarlKarla_Feathers
		#Give up on the Infinity Arrow.
			*goto KarlKarla_GaveUp

	*label KarlKarla_Feathers
	
	"The last part is the fletching.  I know exactly what I need: the tail feather of a phoenix.  There's even a man, here in Tornassa, who owns such a feather, but I can't afford his price."
	*label KarlKarla_Feathers_loop
	*choice
		*if (no_thief_vow=false) #Sneak into the man's house and steal it.
			*if (stealth>=40)
				The old man with the feather has a few security measures in place, but not enough for one of your skill.  The next morning, you present the feather to ${karlkarla_name}.
				*if (showstats)
					*line_break
					(Stealth +3)
				*set stealth +3
				*goto KarlKarla_FeathersWorks
			*else
				The old man has more security than you can get past.  Not wanting to get caught, you eventually give up on stealing the feather.
				*if (showstats)
					(Needed 40 Stealth)
				*goto KarlKarla_Feathers_loop
		#You try to talk the old man into giving you the feather.
			*if (charm>=40)
				You speak nicely to his personal guards and are granted a meeting.  You explain what ${karlkarla_name} is attempting to create.  The old man eventually agrees that it is an exciting endeavour and gives you the feather.  The next morning, you present the feather to ${karlkarla_name}.
				*if (showstats)
					*line_break
					(Charm +3)
				*set charm +3
				*goto KarlKarla_FeathersWorks
			*else
				The old man's guards reluctantly grant you a meeting, but after a few minutes of trying to explain what you need the feather for, he says no and asks you to leave.
				*if (showstats)
					(Needed 40 Charm)
				*goto KarlKarla_Feathers_loop
		*selectable_if (gold>=50) #You offer to buy the feather from the man. (Needs 50 Gold)
			The rich old coot charges you a small fortune for the small item.
			*if (showstats)
				*line_break
				(Gold -50)
			*set gold -50
			*label KarlKarla_FeathersWorks
			
			"Yes!" ${karlkarla_name} exclaims.  "I have the interior lining, bonding agents, curing solution and everything else.  I even have the ancient spell that needs to be cast.  I can make it!"
			
			Your friend looks exhausted but happy when you see ${karlkarla_himher} a week later.  ${karlkarla_name} shows you the perfect white arrow in ${karlkarla_hisher} quiver.  $!{karlkarla_heshe} did it.  $!{karlkarla_heshe} has crafted the legendary Infinity Arrow.  The only downside was that it could only be used once, but when it was used, it would not miss.
			*set infinity_arrow true
			*goto After_KarlKarlaQuest
		#Give up on the Infinity Arrow.
			*goto KarlKarla_GaveUp
*else
	*goto After_KarlKarlaQuest

*label After_KarlKarlaQuest
*if ((priestquest=1) and (strangeamulet))
	
	The unholy amulet in your pocket was
	*if (god_good)
		vile
	*if (god_good=false)
		gloriously vile
	to touch.  The notion that it could somehow subvert someone's soul and send it to another deity was unheard of, as far as you knew.
	*if ((exgoodpriest) or (exevilpriest))
		Even though you had left the priesthood, the amulet's presence still filled your mind.
	You had been told that the peddler had gotten the artifact here in Tornassa.
	*choice
		#Spend time looking through the markets.
			It doesn't take long before you find several more copies of the amulet being sold.  From there, it's simply a matter of following one of the peddlers to see where he obtained it.  The salesman closes up shop and goes deep into the sewers.  You and ${friend1_name} follow until you see an enormous shrine dedicated to the unknown God.
			*goto Tornassa_amulet2
		#Ask people about the amulet.
			Everyone seems very nervous about your investigation, but eventually you find an old man whose eyes keep shifting toward a sewer grate in the road.  With no other leads, you and ${friend1_name} go deep into the sewers.  It doesn't take long before you find yourself standing before an enormous shrine dedicated to the unknown God.
			*goto Tornassa_amulet2
	*label Tornassa_amulet2
	
	The moment you look upon the shrine, the world seems to shudder.  You see people slinking back into the shadows.  These must be the strange God's priests and priestesses.  They are the ones passing the amulets on to the peddlers to distribute through the four duchies.
	*choice
		*if ((class_priest>0) and (holysymbol)) #Call upon ${god_name}, your ${god_goddess}, to destroy the shrine.
			The sewer shakes as your ${god_goddess} reacts to your call.
			*if (((god_good) and (good<50)) or ((god_good=false) and (good>50)))
				Your holy symbol breaks in half in your hands.  Your ${god_goddess} is clearly not happy with your service.  Although you feel that you are no longer ${god_hisher} servant, your former ${god_goddess} also doesn't seem to like the strange shrine and does what you ask anyway.
				*if (god_good)
					*if (showstats)
						(Needed Over 50 Good)
					*set exgoodpriest true
				*if (god_good=false)
					*if (showstats)
						(Needed Over 50 Evil)
					*set exevilpriest true
				*if (showstats)
					*line_break
					(Lost Holy Symbol and Lost all levels in $!{priestpriestess} and Cleric)
				*set class_priest 0
				*set class_cleric 0
				*set holysymbol false
				*if (god_good)
					*set exgoodpriest true
				*if (god_good=false)
					*set exevilpriest true
				
			The shrine to the Unknown Deity crumbles to pieces as large chunks of stone fall from the ceiling.  The priests and peddlers run from the sewers like rats abandoning a ship.
			*if (god_good)
				A brilliant holy light fills the tunnels as the evil is scoured from existence.
			*if (god_good=false)
				A shadow even darker than what is already there fills the tunnels as the evil is replaced with a different evil.
			*set strangeamulet false
			*set priestquest 2
			*if (holysymbol=false)
				Your time as a holy${mc_manwoman} is over.
			*if (god_good)
				*if (showstats)
					*line_break
					(Good +10 and Religion +10)
				*set good +10
				*set religion +10
				*goto Tornassa_AfterAmulet
			*else
				*if (showstats)
					*line_break
					(Evil +10 and Religion +10)
				*set good -10
				*set religion +10
				*goto Tornassa_AfterAmulet
		*if (holysymbol) #Break your holy symbol and call upon the strange God.
			The shrine shakes as your holy symbol snaps in half.
			*label Tornassa_NewMaster
			You feel a strange vibration run through your body.  ${friend1_name} looks upon you in fear, but manages to stay at your side.
			
			"[b]I am pleased by your devotion,[/b]" a voice says in your head.  "[b]My day shall come.  I shall rise and you shall be rewarded.[/b]"
			*set god_name "the Unknown"
			*set god_heshe "It"
			*set god_hisher "Its"
			*set god_himher "Its"
			*set god_goddess "deity"
			*set god_good false
			
			*if (holysymbol)
				The two pieces of your holy symbol fall onto one of the amulets and merge back into one piece.  It
			*if (holysymbol=false)
				The amulet twists and turns until it
			looks like a regular holy symbol dedicated to a good God.  This is the nature of worshipping an evil being—it must be done secretly.
			*if (showstats)
				*line_break
				(Gained a New Holy Symbol)
			*set holysymbol true
			*set strangeamulet false
			
			You glance over to ${friend1_name}, curious to see what ${friend1_heshe} thinks of your new deity.  You are surprised to see a dazed look in ${friend1_hisher} eyes.  You leave the shrine and watch as ${friend1_heshe} slowly wakes up after you've left, with no knowledge of what has just transpired.  You are in uncharted waters, worshipping a being which you've never heard of before.
			*if (showstats)
				*line_break
				(Evil +10 and Religion +10)
			*set good -10
			*set religion +10
			*goto Tornassa_AfterAmulet
		*if (holysymbol=false) #Call upon the strange God.
			*if (good>50)
				Nothing happens.  You drop the amulet on the ground and leave the place since there is nothing more that you can do.
				*if (showstats)
					(Needed to be Evil)
				*goto Tornassa_AfterAmulet
			*else
				*goto Tornassa_NewMaster
		#Throw the strange amulet on the ground and walk away.
			The powers at work are beyond the scope of a mortal ${mc_manwoman}.  The moment the amulet leaves your hands, you feel better.  You exit the shrine and nobody stops you from returning to the surface.
			*if (showstats)
				*line_break
				(Lost Strange Amulet and Religion +10)
			*set strangeamulet false
			*set religion +10
			
			"By the Gods," ${friend1_name} says.  "I don't know if we've done the right thing today, but I am glad to be away from that place."
			*goto Tornassa_AfterAmulet
*else
	*goto Tornassa_AfterAmulet

*label Tornassa_AfterAmulet
*goto Leaving

*comment -------------------------------Wilderness----------------------------------------
*label Wilderness
The young bear stands up on its hind legs and roars at you.  Strands of drool fly from its muzzle as it yells in defiance.
*if (friend1_name=theothea_name)
	${friend1_name} stands beside you, the muscular warrior glaring at the bear through ${friend1_hisher} messy black hair as ${friend1_heshe} grips ${friend1_hisher} oversized warhammer.
*if (friend1_name=jacejess_name)
	${friend1_name} stands beside you with an arrogant expression on ${friend1_hisher} fine-featured face.  The white streak through ${friend1_hisher} jet black hair shines brightly in the afternoon light.
*if (friend1_name=gillgale_name)
	${friend1_name} stands beside you, ${friend1_hisher} hands casually resting on the hilts of ${friend1_hisher} two short swords.  A mischievous grin curls the corners of ${friend1_hisher} mouth upwards as ${friend1_heshe} surveys the scene.
*if (friend1_name=peterpetra_name)
	${friend1_name} stands beside you with a stern look on ${friend1_hisher} face.  $!{friend1_hisher} hand rests on the handle of ${friend1_hisher} morningstar as the afternoon light makes ${friend1_hisher} resplendent metal armour shine like the holy conviction in ${friend1_hisher} eyes.
*if (friend1_name=karlkarla_name)
	${friend1_name} stands beside you with a nervous expression on ${friend1_hisher} face.  $!{friend1_hisher} dexterous hands are only inches away from ${friend1_hisher} bow and quiver.
*choice
	*if (sword) #Swing your sword at the animal.
		Your sword whistles through the air
		*if (blades>=30)
			and slices deeply across the bear's midriff.  It roars again, this time in pain and fury.  Now that it's been hurt, it will be twice as dangerous.
			*if (showstats)
				*line_break
				(Blades +5)
			*set blades +5
			*goto Wilderness_AfterBear
		*else
			but the bear steps back and out of reach of the blade.  It roars again as one of its sharp claws slashes across your stomach, drawing blood.
			*if (showstats)
				(Needed 30 Blades)
				*line_break
				(Health -25)
			*set health -25
			*goto Wilderness_AfterBear
	*if (bow) #Fire an arrow into the bear.
		Your arrow whistles through the air
		*if (archery>=30)
			and plunges deeply into the bear's midriff.  It roars again, this time in pain and fury.  Now that it's been hurt, it will be twice as dangerous.
			*if (showstats)
				*line_break
				(Archery +5)
			*set archery +5
			*goto Wilderness_AfterBear
		*else
			and strikes the tree beside the bear. The bear roars again as one of its sharp claws slashes across your stomach, drawing blood.
			*if (showstats)
				(Needed 30 Archery)
				*line_break
				(Health -25)
			*set health -25
			*goto Wilderness_AfterBear
	*if (dagger) #Throw your dagger at the bear.
		Your dagger whistles through the air
		*if (blades>=30)
			and plunges deeply into the bear's midriff.  It roars again, this time in pain and fury.  Now that it's been hurt, it will be twice as dangerous.
			*if (showstats)
				*line_break
				(Blades +5 and Lost Dagger)
			*set blades +5
			*set dagger false
			*set used_dagger true
			*goto Wilderness_AfterBear
		*else
			and strikes the tree beside the bear. The bear roars again as one of its sharp claws slashes across your stomach, drawing blood.
			*if (showstats)
				(Needed 30 Blades)
				*line_break
				(Health -25 and Lost Dagger)
			*set health -25
			*set dagger false
			*set used_dagger false
			*goto Wilderness_AfterBear
	#Cast a spell to set the bear on fire.
		Your words tumble quickly from your mouth
		*if (magic>=30)
			and the bear bursts into flames.  The flames go out as its fur burns up.  It roars again, this time in pain and fury.  Now that it's been hurt, it will be twice as dangerous.
			*if (showstats)
				*line_break
				(Magic +5)
			*set magic +5
			*goto Wilderness_AfterBear
		*else
			but before you finish, the bear roars again as one of its sharp claws slashes across your stomach, drawing blood.  Your spell ends abruptly as it is disrupted before completion.
			*if (showstats)
				(Needed 30 Magic)
				*line_break
				(Health -25)
			*set health -25
			*goto Wilderness_AfterBear
	#Punch the bear in the nose.
		*if (unarmed>=40)
			You time your strike well and hit the animal on the nose.  It roars again, this time in pain and fury.  Now that it's been hurt, it will be twice as dangerous.
			*if (showstats)
				*line_break
				(Unarmed +5)
			*set unarmed +5
			*goto Wilderness_AfterBear
		*else
			You attempt to get close, but as you get near, the bear roars again and swipes one of its sharp claws across your stomach, drawing blood.
			*if (showstats)
				(Needed 40 Unarmed)
				*line_break
				(Health -25)
			*set health -25
			*goto Wilderness_AfterBear
	*if ((class_ranger=1) or (class_druid=1)) #Attempt to soothe the wild beast.
		*set bear_exists false
		You make soft noises and extend your hand.  The animal goes back down on all fours and sniffs your hand.
		*choice
			#Allow the young bear to travel with you.
				*rand coinflip 1 2
				*if (coinflip=1)
					*set companion_hisher "his"
					*set companion_heshe "he"
					*set companion_himher "him"
				*if (coinflip=2)
					*set companion_hisher "her"
					*set companion_heshe "she"
					*set companion_himher "her"
				*set companion_familiar false
				*set companion_travels "shuffles along beside you"
				*set companion_type "bear"
				The young bear seems happy to follow you around.
				
				You decide to name ${companion_himher}:
				*label Name_Bear
				*input_text companion_name
				*if (companion_name="None")
					You have to name ${companion_himher} something!
					*goto Name_Bear
				The creature seems to like what you call ${companion_himher} and ${companion_travels} happily.
				*set companion_familiar false
				*goto Wilderness_AfterBear
			#Leave the bear.
				The young bear wanders off into the forest peacefully.
				*if (showstats)
					*line_break
					(Nature +3)
				*set nature +3
				*goto Wilderness_AfterBear

*label Wilderness_AfterBear

It has been nearly a year since you left Vernex after ${fosterparent_name}
*if (deadfriend_name!="None")
	and ${deadfriend_name} were
*if (deadfriend_name="None")
	was
killed by Thuja.
*if (using_legacy)
	Although you've looked for ${legacy_himher} in your exile, the time-traveling wizard from the past hasn't visited you a single time since leaving Vernex.
Life in the wilderness has been
*if (nature>=30)
	comfortable.  You built a nice little shelter, regularly trap food and have found many plants to forage from.  ${friend1_name} has been your constant companion since your arrival.
	*if (showstats)
		*line_break
		(${friend1_name} Relationship +3)
	*set friendinc 3
	*gosub Friend1_Increase
*if (nature<30)
	hell.  You built a leaky little shelter, rarely trap enough food to eat and have been harassed by insects the entire time.  ${friend1_name} has been cursing about the conditions since your arrival.
	*if (showstats)
		(Needed 30 Nature)
		*line_break
		(${friend1_name} Relationship -5)
	*set friendinc 0
	*set friendinc -5
	*gosub Friend1_Increase

Despite being in the middle of nowhere, a nearby camp was often filled with the hustle and bustle of loggers and hunters.  You have also seen a forest witch living in a small hut close to your shelter.
*comment Can't become priest.
*label Wilderness_jobloop
*choice
	*if (class_squire>0) #You asked for the location of the next grand tournament and trained hard for it.
		The life of a squire was filled with training and serving your fellow knights.  With no tournament currently taking place, you concentrated on perfecting your techniques.  In addition to swordplay and horsemanship, you studied the knight's code and its history.
		*gosub Level_Squire
		*goto Wilderness_AfterJob
	*if (class_bard>0) #You sang for the people in the nearby camp every night, gathering a true following of fans.
		Your music might even be the reason they kept coming back to the same remote place.  They said that many of your songs were sung in taverns across the four duchies and that you've grown a real reputation for yourself.  Your lyrics are often nature based and you have a lot of time to craft amazing melodies.
		*gosub Level_Bard
		*goto Wilderness_AfterJob
	*if (no_thief_vow=false) #You spent all of your time stealing from the nearby camp whenever you could.
		*if (class_thief=0)
			On one of your trips, you met a woman who flashed some hand gestures at you.  After you didn't respond, she approached you and spoke directly.
			
			"You're new, huh," she said.  "Look, the Thieves Guild always gets their cut.  I'll show you the hand signals, but you have to pay."
			
			You reluctantly agreed.  The woman happily taught you the thief hand language and even stood look-out during some of your heists.
			
			*goto Wilderness_ContinueThief
		*else
			*label Wilderness_ContinueThief
			Your stealthy stalking and light fingers allowed you to gain a lot of practice from the loggers.  The hunters were perceptive people, meaning that your skills as a thief were tested to the extreme.  The percentage that had to be paid to the Thieves Guild was much smaller than what was paid in the cities.
			*gosub Level_Thief
			*goto Wilderness_AfterJob
	#You offered your services to the camp as a guard.
		The loggers were always looking for someone to watch their backs against forest predators, wild beasts and forest bandits.  They paid you for your time and you spent your nights watching the camp's edge for dangers.
		*gosub Level_Guard
		*goto Wilderness_AfterJob
	*if (class_priest=0) #You tried to become a ${priestpriestess}.
		Unfortunately, there were no temples in the wild.  As such, there was no way to become a ${priestpriestess}. 
		*goto Wilderness_jobloop
	*if ((class_priest>=1) or (class_cleric>=1)) #You built a frontier temple to spread the word of ${god_name}.
		The temple got funding from your superiors and soon you had a thriving sanctuary filled with converts.  Since you were the only temple within hundreds of miles, you gained a lot of new followers.
		*if (god_good=false)
			It was one of the few temples in the four duchies that openly supported what was considered an "evil ${god_goddess}."  But, with nobody to contradict your teachings, it became very popular.
		*choice
			#You delivered spiritual sermons.
				Your sermons were very introspective and life changing as you led the worship of your congregation.
				*gosub Level_Priest
				*goto Wilderness_AfterJob
			#You led a very militaristic religion.
				You preached about action and lead by example as you studied the sword and shield.
				*gosub Level_Cleric
				*goto Wilderness_AfterJob
	*if (class_monk>0) #You spent your days meditating upon nature as a monk.
		You didn't need to follow any doctrines or organized religion to find self-enlightenment.  The calmness of a forest pond, the ferocity of a rainstorm…nature itself was your guide.  A year of meditation went a long way to soothing your soul and nurturing your skills.
		*gosub Level_Monk
		*goto Wilderness_AfterJob
	*if (class_wizard=0) #You asked the witch to teach you magic.
		*if (spellbook)
			*goto Wilderness_Witch_Lessons
		*else
			Despite the fact that the witch's magic was nontraditional, your lack of spellbook made learning from her very difficult.  In the end, you were forced into giving up on learning magic from her.
			*if (showstats)
				(Needed Spellbook)
			*goto Wilderness_jobloop
	*if (class_wizard>=1) #You spent your days with the witch, learning her secrets.
		*label Wilderness_Witch_Lessons
		Hazel knew a lot of shamanistic magic and showed you how to work with 'spirits'.  Her magical practice was much different from you had seen anywhere else.
		*gosub Level_Wizard
		*if (companion_type="None")
			
			"It's time that you bonded with something," Hazel said.  "I'd recommend a rat or a toad.  Both of them are worthy animals that can allow you to focus your magic through them."
			*choice
				#You allowed her to bond a toad to your soul.
					*rand coinflip 1 2
					*if (coinflip=1)
						*set companion_hisher "his"
						*set companion_heshe "he"
						*set companion_himher "him"
					*if (coinflip=2)
						*set companion_hisher "her"
						*set companion_heshe "she"
						*set companion_himher "her"
					The toad that you were presented with was a miserable squat warty lump of a thing.  $!{companion_heshe} looked at you with ${companion_hisher} dull black eyes as Hazel helped you with the magic which linked your souls together.  When it was over, you had a new respect for the critter and saw beauty in it where others didn't.  You named ${companion_himher}…
					*set companion_type "toad"
					*set companion_familiar true
					*set companion_travels "sits on your shoulder"
					
					You decided to name ${companion_himher}:
					*label Name_Toad
					*input_text companion_name
					*if (companion_name="None")
						You have to name ${companion_himher} something!
						*goto Name_Toad
					The creature seemed to like what you called ${companion_himher} and ${companion_travels}, happily.
					*goto Wilderness_AfterJob
				#You allowed her to bond a rat to your soul.
					*rand coinflip 1 2
					*if (coinflip=1)
						*set companion_hisher "his"
						*set companion_heshe "he"
						*set companion_himher "him"
					*if (coinflip=2)
						*set companion_hisher "her"
						*set companion_heshe "she"
						*set companion_himher "her"
					The rat that Hazel caught looked disease-ridden and mangy.  You were somewhat skeptical, at first, but as her magic linked your soul to that of the rat, you grew an appreciation for the rodent.  $!{companion_heshe} looked up at you with shiny black eyes as your souls were joined.
					*set companion_type "rat"
					*set companion_travels "scurries along beside you"
					*set companion_familiar true
					
					You decided to name ${companion_himher}:
					*label Name_Rat
					*input_text companion_name
					*if (companion_name="None")
						You have to name ${companion_himher} something!
						*goto Name_Rat
					The creature seemed to like what you called ${companion_himher} and ${companion_travels}, happily.
					*goto Wilderness_AfterJob
				#You declined the honour.
					The witch glared at you with her bulging eyes, thinking you were crazy for not taking her up on the offer.  You asked about the details of the ritual and stored the knowledge for a more worthy animal.
					*goto Wilderness_AfterJob
		*else
			*goto Wilderness_AfterJob
	*if (class_druid>=1) #You created and consecrated a hidden druidic grove.
		The small grove was hidden far from the loggers in the middle of the densest part of the forest.  A pond in the centre of the grove brought all kinds of amazing animals to it and natural predators honoured your intentions by causing no bloodshed nearby.  You learned a lot about nature as you contemplated the flora and fauna around you.
		*gosub Level_Druid
		*goto Wilderness_AfterJob
	*if (class_ranger>=1) #You spent your days tracking and hunting as a ranger.
		You were in your element as you traveled through the forest with ease.  You learned to track all of the different animals and bring them down with well-aimed arrows.  You also studied your swordplay, knowing that when the prey came too close, an arrow wasn't the best tool for the task.
		*gosub Level_Ranger
		*goto Wilderness_AfterJob
	#As a sage, you wrote books about the properties of the plants and the history of the people who have lived there.
		*if ((arcana>=40) or (class_sage>=1))
			You had a lot of time on your hands, so you used it to write books about history and nature.  You occasionally had access to others' books, which you purchased, read and then sold again.  The books that you wrote were scribed into many languages and spread across the four duchies.
			*gosub Level_Sage
			*goto Wilderness_AfterJob
		*else
			Although you tried to write interesting and informative books, you simply weren't that good at it.  After a few failed attempts, you gave up on the idea altogether.
			*if (showstats)
				(Needed 40 Arcana or Level 1 Sage)
			*goto Wilderness_jobloop
	*if (class_assassin>0) #You contacted the Guild of Assassins and mastered the art of poison.
		You were correct in thinking that there were jobs to be had, even in the remoteness of the wilderness.  You learned that gardens everywhere needed weeding.  Many hunters, loggers, herbalists and farmers who bordered on the forests went missing as you fulfilled your contracts.  You also learned how to craft an amazing number of poisons from the plants of the forest, making you one of the most lethal poisoners in the world.
		*gosub Level_Assassin
		*goto Wilderness_AfterJob
	#You helped the loggers settle their disputes with each other as a hired thug.
		As long as men gathered, there would be problems.  The strong preyed upon the weak, unless the weak could pay for protection.  That's where you came in, intimidating first and then breaking bones if the person was too stupid to not heed your threats.  The loggers were no different and you were kept busy as a mercenary for hire.
		*gosub Level_Thug
		*goto Wilderness_AfterJob

*label Wilderness_AfterJob

*if (bear_exists)
	The roaring bear suddenly pitches forward and falls onto its stomach with an arrow sticking out of its back.  Standing behind the bear is
*if (bear_exists=false)
	The bear had just
	*if (companion_type="bear")
		joined you
	*if (companion_type!="bear")
		wandered back into the trees
	when a feathered arrow struck deeply into the dirt at your feet.  You see
a small group of men and women wearing black masks.  You count at least ten of them and realize that you and ${friend1_name} are in trouble.  You've heard of a group of bandits working out of the forest and now you are face-to-face with them.

"This is our forest and you've been wandering too close to our hideout," the bandit leader says.  "Two choices, my friends.  Give us all the money you have and leave…or die."
*label Wilderness_Bandits
*choice
	#Say, "Easy, we're leaving.  Sorry for your troubles."
		*if (charm>=30)
			The bandits watch you suspiciously, but it's clear that they are after bigger targets than you and ${friend1_name}.  You certainly don't look very wealthy and they are content to let you go after speaking with them for a bit.
			*if (showstats)
				*line_break
				(Charm +3)
			*set charm +3
			*goto Wilderness_AfterBandits
		*else
			"Ahem," the bandit leader says before you can leave.  "The money?"
			*if (showstats)
				(Needed 30 Charm)
			*goto Wilderness_Bandits
	*if (class_thief>0) #Say, "I'm with the Guild."
		You flash the leader the appropriate hand gestures and the entire group lowers their weapons.  The leader claps his hand on your back and allows you to pass without harm.
		*if (showstats)
			*line_break
			(Charm +3)
		*set charm +3
		*goto Wilderness_AfterBandits
	*if (bow) #Start laying waste to the bandits with your bow and arrow.
		The first arrow catches the bandit leader in the throat.
		*if (archery>=45)
			The second takes out one of the archers.  From there, it is confusion as arrows fly and swords clash.
			*if (showstats)
				*line_break
				(Archery +3)
			*set archery +3
			*goto Wilderness_BeatBandits
		*else
			Unfortunately, the second arrow misses its mark and the archers' own arrows begin to fly.
			*if (showstats)
				(Needed 45 Archery)
			*goto Wilderness_LostBandits
	#Punch the leader in the face.
		The bandit leader is clearly waiting for you to pull a weapon and doesn't expect you to simply punch him.
		*if (unarmed>=50)
			He stumbles back as blood drenches the front of his shirt.
			*if (showstats)
				*line_break
				(Unarmed +3)
			*set unarmed +3
			*goto Wilderness_BeatBandits
		*else
			He takes the blow as he jams his sword into your side.
			*if (showstats)
				(Needed 50 Unarmed)
			*goto Wilderness_LostBandits
	*if (sword) #Attack the thieves with your sword.
		*if (blades>=45)
			Your sword slides into the bandit leader before he can draw another breath.  From there, it is confusion as arrows fly and swords clash.
			*if (showstats)
				*line_break
				(Blades +3)
			*set blades +3
			*label Wilderness_BeatBandits
			
			*if (friend1_name=theothea_name)
				${friend1_name} fights at your side, swinging ${friend1_hisher} enormous warhammer with ease.
			*if (friend1_name=jacejess_name)
				${friend1_name} fights at your side, ${friend1_hisher} eyes glowing a blinding white.  Bright beams of energy slice into your enemies as the Soulburner unleashes ${friend1_hisher} deadly magic.
			*if (friend1_name=gillgale_name)
				${friend1_name} rolls through the bandits and begins to attack them from behind.  $!{friend1_hisher} blades are deadly as ${friend1_heshe} slashes at the backs of their legs, dropping them to the ground for you to finish off.
			*if (friend1_name=peterpetra_name)
				${friend1_name} fights at your side, swinging ${friend1_hisher} morningstar with ease.
			*if (friend1_name=karlkarla_name)
				${friend1_name} fights at your side, sending arrow after arrow into your foes.
			A few seconds later and the fight is over.  The bandits chose the wrong people to attack.  You look over their corpses before moving on.
			*if (mount_name!="None")
				${mount_name}, your ${mount_type}, and ${friend1_name}'s mount wait patiently while you search the bodies.
			*label Wilderness_Loot
			*if (((sword) and (dagger)) and ((bow) and (tookmoney)))
				*goto Wilderness_AfterBandits
			*choice
				*if (sword=false) #Take a sword.
					You take the bandit leader's sword.
					*if (showstats)
						*line_break
						(Gained Sword)
					*set sword true
					*goto Wilderness_Loot
				*if (dagger=false) #Take a dagger.
					You take one of the bandits' daggers.
					*if (showstats)
						*line_break
						(Gained Dagger)
					*set dagger true
					*goto Wilderness_Loot
				*if (bow=false) #Take a bow.
					You take a bow from one of the archers as well as a quiver of arrows.
					*if (showstats)
						*line_break
						(Gained Bow)
					*set bow true
					*goto Wilderness_Loot
				#You take the coins from their money pouches.
					*set tookmoney true
					You gather the coins together into a small pile.
					*choice
						#Split the money with ${friend1_name}.
							You divvy up the money and put the coins into your own pouch.
							*if (showstats)
								*line_break
								(${friend1_name} Relationship +3 and Gold +35)
							*set friendinc 3
							*gosub Friend1_Increase
							*set gold +35
							*goto Wilderness_Loot
						#Keep all of the money for yourself.
							You put all of the coins into your pouch.  ${friend1_name} frowns at your actions, but doesn't say anything.
							*if (showstats)
								*line_break
								(${friend1_name} Relationship -5 and Gained 70 Gold)
							*set friendinc 0
							*set friendinc -5
							*gosub Friend1_Increase
							*set gold +70
							*goto Wilderness_Loot
						#Give all the money to ${friend1_name}.
							${friend1_name} seems surprised by your generosity but happily takes the money.
							*if (friend1_name=peterpetra_name)
								
								"I will be sure to donate this money to a good cause," ${friend1_name} says.
							*if (showstats)
								*line_break
								(${friend1_name} Relationship +5)
							*set friendinc 5
							*gosub Friend1_Increase
							*goto Wilderness_Loot
				#Go on your way.
					You leave the corpses behind and go on your way.
					*goto Wilderness_AfterBandits
		*else
			You manage to kill the bandit leader, surprising him with your actions, but when one of the archers puts an arrow into your side you aren't able to properly defend against the others. 
			*if (showstats)
				(Needed 45 Blades)
			*label Wilderness_LostBandits
			
			${friend1_name} does ${friend1_hisher} best to help you, but after a few minutes of heavy fighting, you are both overwhelmed.  As you lay on the forest floor, the bandits help themselves to your coin and leave you for dead.
			*if (mount_name!="None")
				They don't bother stealing your mounts, leaving you with ${mount_name}, your ${mount_type}.
			*if (gold<=75)
				*if (showstats)
					*line_break
					(Lost all Health and Lost all Gold)
				*set health 0
				*set gold 0
			*if (gold>75)
				Luckily you weren't carrying all of your coins in your coin pouch and the bandits don't find them all.
				*if (showstats)
					*line_break
					(Lost all Health and -75 Gold)
				*set health 0
				*set gold -75
			*page_break Blackness…
			Several hours later, you come to.  You see that ${friend1_name} is still unconscious, but breathing.  Slowly, you pull yourselves together and get back onto your feet.
			*if (showstats)
				*line_break
				(Gained 10 Health)
			*set health 10
			*goto Wilderness_AfterBandits
	*if (demonsummoner)
		*allow_reuse #Consider using a Demonstone.
			You open your runebag and consider your options.
			*label Wilderness_Demons_loop
			*choice
				*if (((demonstone_xiatta) and (demonstone_xiatta_summoned)) and ((demonstone_xiatta_used=false) and (demonsummoner))) #Summon Xi'atta and tell it to attack the bandits.
					*comment Xi'atta: Willing: 20, Small Struggle: 30, Against: 40
					*comment Min 45 to Max 60
					Xi'atta appears in front of you.  Its fragile blue body is only one foot tall and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
					
					One of the bandits puts an arrow into the demon the moment it appears.  Although the arrow turns icy for a moment, it still strikes Xi'atta in the chest.  The frosty demon pops out of existence as it returns to its own plane.
					*set demonstone_xiatta_used true
					*goto Wilderness_Demons_loop
				*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl and tell it to attack the bandits.
					*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
					*comment Min 45 to Max 60
					Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
					
					*if (willpower>=60)
						"Yes, ${mastermistress}," Brahl says as you force it to attack against its will.  "I like a good fight, but these odds don't look good."
						
						You get the feeling that Brahl wanted to fight and didn't push against your will as hard as it could have.  An arrow thunks into the demon as it steps forward and disembowels one of the bandits with its sharp claws.  A second arrow strikes it and then a third, but it manages to kill two more bandits before it finally succumbs to its wounds, popping out of existence as it returns to its own realm to heal.
						*set demonstone_brahl_used true
						*goto Wilderness_BeatBandits
					*else
						"No, these odds are terrible," Brahl grumbles. The contest of wills is rejoined and the brawny demon pops out of existence just as an arrow is fired toward it.
						*if (showstats)
							(Needed 60 Willpower)
					*goto Wilderness_Demons_loop
				*if (((demonstone_zonch) and (demonstone_zonch_summoned)) and ((demonstone_zonch_used=false) and (demonsummoner))) #Summon Zon'ch and tell it to attack the bandits.
					*comment Zon'ch: Willing: 30, Small Struggle: 40, Against: 50
					*comment Min 45 to Max 60
					Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
					
					*set demonstone_zonch_used true
					One of the bandits fires an arrow, but the demon waves a small hand and a dusty wind blows it aside.  Unfortunately, a bandit's blade cuts deeply into Zon'ch a moment later.  It pops out of existence as it returns to its own plane.
					*goto Wilderness_Demons_loop
				*if (((demonstone_daanda) and (demonstone_daanda_summoned)) and ((demonstone_daanda_used=false) and (demonsummoner))) #Summon Daan'da and tell it to attack the bandits.
					*comment Will of 0, but very stupid and weak.
					Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
					*set demonstone_daanda_used true
					
					Daan'da turns to the bandits and waves to them with a lopsided smile before balling its hands into fists to fight.  One bandit returns the greeting with an arrow, which strikes Daan'da in the forehead.  The demon pops out of existence as it returns to its own plane.
					*goto Wilderness_Demons_loop
				*allow_reuse #Close your runebag.
					*goto Wilderness_Bandits	
	#Cast a spell to put the bandits to sleep.
		You quickly begin to cast the spell.
		*if (magic>=50)
			The bandit leader tries to attack, but drops to the ground unconscious.
			*if (showstats)
				*line_break
				(Magic +3)
			*set magic +3
			*goto Wilderness_BeatBandits
		*else
			Unfortunately, the bandit leader reacts faster than you expect and you feel his blade slam into your side.
			*if (showstats)
				(Needed 50 Magic)
			*goto Wilderness_LostBandits
	*if (class_druid>0) #Command the trees to attack your enemy.
		Nature itself rises to your defence as the trees grab the archers and smash them into the ground.  The bandit leader turns around in surprise just as a heavy oak branch crashes into his head.
		*if (showstats)
			*line_break
			(Magic +3)
		*set magic +3
		*goto Wilderness_BeatBandits
	*if (gold>=10) #You hand over some of your gold, but try to hide the rest.
		You offer the bandits a small handful of gold as you slip the rest down your pants, into your shoe and under a bush.  The leader looks at the five coins in your hand with disgust.
		
		*if (stealth>=35)
			"I guess you can't get blood from a stone," he says.  "Fine, just get out of here."
			*if (showstats)
				*line_break
				(Stealth +3 and Gold -5)
			*set stealth +3
			*set gold -5
			*goto Wilderness_AfterBandits
		"Nice try," he says with a grin before searching you himself.
		
		*if (mount_name!="None")
			They don't bother stealing your mounts, leaving you with ${mount_name}, your ${mount_type}.
		*if (gold<=75)
			They take all your gold before disappearing back into the forest.  ${friend1_name} grumbles and complains about losing ${friend1_hisher} money, but at least you got away with your lives.
			*if (showstats)
				*line_break
				(Lost all Gold)
			*set health 0
			*set gold 0
		*if (gold>75)
			Although they find more than you would have liked, they don't find all of it.  After they are done robbing you, they disappear into the forest.  ${friend1_name} grumbles and complains about losing ${friend1_hisher} money, but at least you got away with your lives.
			*if (showstats)
				*line_break
				(Lost 75 Gold)
			*set gold -75
		*goto Wilderness_AfterBandits
	#You hand over all your gold.
		The bandits happily take all of your coins.  They are surprisingly honourable after that, letting you leave without slitting your throats.  ${friend1_name} grumbles and complains about losing ${friend1_hisher} money, but at least you got away with your lives.
		*if (mount_name!="None")
			Surprisingly, they let you leave with ${mount_name}, your ${mount_type}.
		*if (showstats)
			*line_break
			(Lost all Gold)
		*set gold 0
		*goto Wilderness_AfterBandits

*label Wilderness_AfterBandits
*if (used_dagger)
	
	You pick up your dagger before leaving.
	*if (showstats)
		(Regained Dagger)
	*set dagger true
*if ((peterpetra_story=4) and (friend1_name=peterpetra_name))
	*goto PeterPetraQuest
*if ((gillgale_story=5) and (friend1_name=gillgale_name))
	*goto GillGaleQuest
*else
	*goto Wilderness_AfterChildhoodfriend_Quest

*label Wilderness_AfterChildhoodfriend_Quest
*goto Leaving

*label GillGaleQuest

"Come, let's see how my mother fares," ${friend1_name} says after the encounter with the bandits.

Freda was an old lady when you were a child.  She should be happily retired somewhere looking after her grandbabies, not working for a tyrant like Mazrim.  The nobleman's manor is at the edge of the wilderness where you had been staying.  With ${friend1_name} at your side, you go to the manor to see the ex-royal cook.
*choice
	#Go straight to the kitchen.
		*label Wilderness_kitchen
		*set wilderness_fredaseen true
		"${name}!" a voice cries the moment you enter.
		
		You should have known that Freda would recognize you instantly.  ${friend1_name} hugs ${friend1_hisher} mother and she hugs ${friend1_himher} back.  You notice that the cook holds her arm at a crooked angle and winces during the embrace.
		*label Wilderness_Freda_loop
		*choice
			#Ask, "Freda, what happened to your arm?"
				You notice that the old woman breaks eye contact with you and looks at the floor.  She stammers something about spilling some freshly made biscuits.
				*set wilderness_seenarm true
				
				"It was Mazrim, wasn't it?" ${friend1_name} shouts angrily, causing some of the kitchen staff to look around uncomfortably.
				*goto Wilderness_Freda_loop
			#Ask quietly, "Freda, you know I'm in hiding, right?"
				"Of course, my ${princeprincess}," the old lady says softly.  "Your secret is safe with me."
				*goto Wilderness_Freda_loop
			*if (wilderness_seenarm) #Ask, "Where is Mazrim?"
				"Stay away from him," Freda warns.  "He is…different.  He drinks, but not alcohol.  The potion gives him energy and strength, but it makes him so angry.  He'll be in his bedroom, sleeping it off, but please, just stay away."
				*set wilderness_knowofpotion true
				*goto Wilderness_Freda_loop
			*if (wilderness_knowofpotion) #Go up to Mazrim's room and confront him.
				*goto Wilderness_Sneaky
			#Say, "Freda, you need to leave here.  Mazrim is clearly a madman.  Go, get a job somewhere else."
				*label Wilderness_fleehim
				It takes some time, but eventually you and ${friend1_name} talk Freda into finding employment elsewhere.
				*set gillgale_story 10
				*label Wilderness_hasmoney
				${friend1_name} has some money which ${friend1_heshe} gives to ${friend1_hisher} mother, but it clearly won't be enough for her to retire on.
				*choice
					*selectable_if (gold>=200) #Give Freda the funds needed to retire.  (Needs 200 Gold)
						The old woman hugs you tightly and ${friend1_name} beams a smile at you.  The three of you leave the manor and never look back.
						*if (showstats)
							*line_break
							(Good +10, Gold -200 and ${gillgale_name} Relationship +10)
						*set good +10
						*set gold -200
						*set gillgale_relationship +10
						*goto Wilderness_AfterChildhoodfriend_Quest
					#Offer no money.
						The old woman hugs you tightly and ${friend1_name} helps ${friend1_hisher} mother out the door.  The three of you leave the manor and never look back.  At least Freda will be safe, even if she will have to find work elsewhere.
						*if (showstats)
							*line_break
							(Good +3 and ${gillgale_name} Relationship +3)
						*set good +3
						*set gillgale_relationship +3
						*goto Wilderness_AfterChildhoodfriend_Quest
			#Say goodbye and leave the mansion.
				You say goodbye.
				*label Wilderness_LeaveNoHelp
				${friend1_name} is clearly upset that you have chosen to do nothing about ${friend1_hisher} mother's plight, but in the end, ${friend1_heshe} continues to travel with you.
				*line_break
				(${gillgale_name} Relationship -5)
				*set gillgale_relationship -5
				
				"When this is all over," ${friend1_name} vowed, "I will find a way to help my mother."
				
				You leave the mysteries of Mazrim's manor behind.
				*goto Wilderness_AfterChildhoodfriend_Quest
	#Snoop around a bit.
		The manor is very large and has many servants.  They all seem skittish and nervous.  You notice that several have black eyes and nearly all show bruises.
		*choice
			#Visit Freda in the kitchen.
				*goto Wilderness_kitchen
			#Ask to see Mazrim himself.
				*goto Wilderness_Mazrim
			#Sneak upstairs and try to find Mazrim yourself.
				*goto Wilderness_Sneaky
	#Ask to speak to Mazrim.
		The footman who answers the front door has a fat lip and walks with a limp, as though his foot is troubling him.
		
		*label Wilderness_Mazrim
		"I am sorry, Mazrim is not to be disturbed and is not taking visitors at this time."
		*label Wilderness_footman_loop
		*choice
			#Visit Freda in the kitchen.
				*goto Wilderness_kitchen
			#Ask the man what happened to his foot.
				"Nothing," he answers quickly.
				*if (showstats)
					*line_break
					(Perception +2)
				*set perception +2
				
				You notice that he looks frightened, but he won't say anything more about it.
				*goto Wilderness_footman_loop
			#Sneak into the house and try to find Mazrim on your own.
				*label Wilderness_Sneaky
				The servants are all so timid and shy that nobody stops you and ${friend1_name} from walking through the manor house.  You soon find yourself outside the master bedroom door.  The sounds of someone sleeping can be heard from within, but the door is locked tight.
				*label Wilderness_lockeddoor
				*choice
					#Pick the lock.
						*if (lockpickset=false)
							Without a lockpick set, you are unable to open the lock.
							*goto Wilderness_lockeddoor
						*if (devices>=30)
							*set wilderness_silent true
							The lock easily opens as you use your lockpicks to turn back the tumblers.
						*if (devices<30)
							*set wilderness_silent false
							It takes you a few tries, but with the person on the other side of the door asleep and the servants too afraid to tell you to stop, you eventually get the lock open, although your efforts have awoken the sleeper.
						*if (showstats)
							*line_break
							(Devices +3)
						*set devices +3
						*goto Wilderness_Inside
					#Smash open the door.
						The door smashes into pieces as you step into the bedroom.
						*set wilderness_silent false
						*goto Wilderness_Inside
					*if ((demonstone_daanda) and ((demonstone_daanda_used=false) and (demonsummoner))) #Summon Daan'da and tell the demon to open the door.
						*comment Daan'da will of 0, but very stupid and weak.
						Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.
						
						"Okay, ${mastermistress}," Daan'da says as it tries to open the door.
						
						"It's locked," it says stupidly before popping out of existence.
						*goto Wilderness_lockeddoor
					#Ask a servant to open the door.
						The servants all shy away from your request.
						*if (charm>=35)
							Eventually one of them does as you ask.
							*if (showstats)
								*line_break
								(Charm +3)
							*set charm +3
							*set wilderness_silent true
							*goto Wilderness_Inside
						*else
							*if (showstats)
								(Needed 35 Charm)
							*goto Wilderness_lockeddoor
					#Knock on the door.
						*set wilderness_silent false
						Nobody answers.
						*goto Wilderness_lockeddoor
					#Go to the kitchen and tell Freda to leave, leaving Mazrim alone.
						*goto Wilderness_fleehim
					#Leave the manor and abandon Freda to her fate.
						*goto Wilderness_LeaveNoHelp
				*label Wilderness_Inside
				
				*if (wilderness_silent)
					You see a large barrel-chested man asleep on the bed.  This must be Mazrim.  He is snoring loudly but wakes up as you enter.
				*if (wilderness_silent=false)
					You see a large barrel-chested man awake on the bed.  This must be Mazrim.
				
				"Your days of abusing my mother are over!" ${friend1_name} exclaims dramatically.
				*choice
					#Let Mazrim speak.
						"I am so sorry," the man says.  "It's the alchemist's fault.  I wanted something to give me energy and make me stronger throughout the day.  He found something ancient and sold it to me.  But it's terrible.  It's made me so angry that I do horrible things.  Please, take it away!"
						
						To your surprise, he pulls out an ornate bottle from his nightstand.  There are a few inches of liquid sloshing around inside of it.
						*choice
							#Drink it.
								You put the bottle to your lips and finish it off.  ${friend1_name} looks at you with surprise and Mazrim is flabbergasted.  You feel the strange effects immediately and wonder what the long term consequences may be.
								*set jeckel_potion true
								*if (showstats)
									*line_break
									(Strength +3, Endurance +3, Agility +3 and Perception -3)
								*set strength +3
								*set endurance +3
								*set agility +3
								*set perception -3
								
								"Well, that's one way, I suppose," Mazrim says with wide eyes.  "That's much more than I've ever taken at once.  I was told that drinking a little at a time would mitigate any permanent effects.  I hope you know what you're doing."
								*label Wilderness_Mazrim_NoPotion
								
								"Thank you, ${name}," ${friend1_name} says.  "And Mazrim, we'll be watching.  If you return to your old ways, we'll come back."
								
								*if (wilderness_fredaseen=false)
									Freda is surprised to see you when you visit her after dealing with Mazrim.  She is careful to not give away your identify as she hugs you and comments about how much you've grown.
								*if (wilderness_fredaseen)
									You return to the kitchen and sit with Freda once more.
								She brings out a freshly baked pie to eat while you visit.  The change over Mazrim is evident even before you leave as servants begin to gossip over his new attitude and kind demeanour.
								*set gillgale_story 11
								*goto Wilderness_AfterChildhoodfriend_Quest
							#Smash the bottle.
								You smash the bottle against the wall.  Shards of glass fall onto the floor, but one of them cuts your hand.  One of the last remaining drops of potion gets into the wound and you feel something strange.  You wonder if you have accidentally infected yourself.  It was meant for drinking; there is no way to tell what permanent effects may occur by delivering the potion straight into your bloodstream.
								*set jeckel_potion true
								*if (showstats)
									*line_break
									(Good +5, Strength +3, Endurance +3, Agility +3 and Perception -3)
								*set good +5
								*set strength +3
								*set endurance +3
								*set agility +3
								*set perception -3
								
								"Thank you," Mazrim says.  "You have saved my life."
								*goto Wilderness_Mazrim_NoPotion
					*if (sword) #Cut off his head with your sword.
						Mazrim has no chance as you neatly decapitate him where he stands.
						*goto wilderness_bladekill
					*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl and tell it to kill Mazrim.
						*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
						Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
						
						"Happily," Brahl says with a cruel grin.
						
						The demon launches itself onto the man and buries its teeth in his throat.  It's a bloody mess as the demon feasts upon the corpse.  After a few minutes, Brahl pops out of existence.
						*if (showstats)
							*line_break
							(Evil +10)
						*set good -10
						*goto Wilderness_Murderer
					#Snap his neck before he can speak.
						You move quickly forward and break his neck before he has a chance to say or do anything.  He falls to the ground with a thud.
						*if (showstats)
							*line_break
							(Evil +10 and Unarmed +3)
						*set good -10
						*set unarmed +3
						*goto Wilderness_Murderer
					*if (dagger) #Slash his throat with your dagger.
						Mazrim doesn't have an opportunity to defend himself as you end his life.
						*label wilderness_bladekill
						*if (showstats)
							*line_break
							(Evil +10 and Blades +3)
						*set good -10
						*set blades +3
						*label Wilderness_Murderer
						*if (wilderness_knowofpotion)
							*choice
								#Search for the potion Freda mentioned.
									You find the bottle in Mazrim's side table.
									*choice
										#Drink it.
											You put the bottle to your lips and finish it off.  ${friend1_name} looks at you with surprise but says nothing.  You feel the strange effects immediately and wonder what the long term consequences may be.
											*set jeckel_potion true
											*if (showstats)
												*line_break
												(Strength +3, Endurance +3, Agility +3 and Perception -3)
											*set strength +3
											*set endurance +3
											*set agility +3
											*set perception -3
											*goto Wilderness_Freda_Free
										#Smash the bottle.
											You smash the bottle against the wall.  Shards of glass fall onto the floor, but one of them cuts your hand.  One of the last remaining drops of potion gets into the wound and you feel something strange.  You wonder if you have accidentally infected yourself.  It was meant for drinking; there is no way to tell what permanent effects may occur by delivering the potion straight into your bloodstream.
											*set jeckel_potion true
											*if (showstats)
												*line_break
												(Good +5, Strength +3, Endurance +3, Agility +3 and Perception -3)
											*set good +5
											*set strength +3
											*set endurance +3
											*set agility +3
											*set perception -3
											*goto Wilderness_Freda_Free
										#Leave it.
											*goto Wilderness_Freda_Free_ns
								#Go tell Freda that she is free.
									*goto Wilderness_Freda_Free_ns
						*else
							*label Wilderness_Freda_Free
							
							*label Wilderness_Freda_Free_ns
							*set gillgale_story 12
							With Mazrim dead, all of the servants are free.
							*if (wilderness_fredaseen=false)
								You go down to the kitchen and find Freda.  She hugs you, but she is silent as she sees that something serious has happened.
							*goto Wilderness_hasmoney
	#Leave without going in.
		*goto Wilderness_LeaveNoHelp

*label PeterPetraQuest

${friend1_name} reminds you that you aren't very far from where ${friend1_hisher} parents were seduced by the vampire.  Your only clues to the vampire's location are the letters that ${friend1_name}'s parents wrote to ${friend1_himher}.
*label FindTheVamp_loop
*choice
	#Attempt to use your knowledge of the landmarks mentioned to find the vampire's lair.
		*if (geography<35)
			Unfortunately, you don't recognize the features mentioned.
			*if (showstats)
				(Needed 35 Geography)
			*goto FindTheVamp_loop
		*else
			The mention of a waterfall and the proximity to a small farming community tip you off to the location.
			*if (showstats)
				*line_break
				(Geography +3)
			*set geography +3
			*goto AtVampLair
	#Cast a divination spell to learn the location.
		You ask ${friend1_name} to concentrate on thoughts of ${friend1_hisher} parents while holding the letters themselves.  You say the magic words and make the necessary symbols.
		*if (magic<40)
			You get the faint impression of a waterfall, but nothing else.
			*if (showstats)
				(Needed 40 Magic)
			*goto FindTheVamp_loop
		*else
			The image of a waterfall fills your mind's eye.  You expand your vision and see a small farming community nearby.  Piece by piece, day by day, you gather many small images until you have enough to pinpoint the location on a map.
			*if (showstats)
				*line_break
				(Magic +3)
			*set magic +3
			*goto AtVampLair
	*selectable_if (gold>=120) #You hire a man to find the vampire.  (Needs 120 Gold)
		The man takes the gold and leaves.  He is gone for months and you soon start to think that he was killed or simply stole your money.  Shortly after the incident with the thieves he returns with news.  He has found the small town where ${friend1_name}'s parents have disappeared to.
		*if (showstats)
			*line_break
			(Gold -120)
		*set gold -120
		*goto AtVampLair
	#Tell ${friend1_name}, "We have to help our friends. The vampire will have to wait."
		Reluctantly, ${friend1_name} agrees with you.
		*goto Wilderness_AfterChildhoodfriend_Quest

*label AtVampLair

The small farming village on the edge of the forest looks somber and miserable.  Nobody smiles as they go about their business while giving you dark looks.
*choice
	#Spread the word that you are looking for someone to help you with some special troubles.
		Everyone in the town gives you the same tight lipped shake of the head.  You can't help but think that they are all involved somehow.
		*goto Wilderness_vampire_thatnight
	#Get a room at the inn to use as a headquarters to search for ${friend1_name}'s parents.
		You get a room and undress, happy to be sleeping in a real bed again after all those months spent in the hut you built in the forest.
		
		That night, while you are in bed,
		*goto Wilderness_vampire_thatnight_nodesc
	#Go to the local temple and ask the priests for help.
		The village priests of Lucien and Auriel seem like hollow shells compared to the holy men and women you have met elsewhere.  They shuffle about and flinch at any loud noises.
		
		"We're looking for the vampire that killed my parents," ${friend1_name} says bluntly.
		
		"Get out!" they yell at you both.
		
		It appears that you will get no help after all.
		*goto Wilderness_vampire_thatnight

*label Wilderness_vampire_thatnight
That night, while staying in a rented room at the local inn,
*label Wilderness_vampire_thatnight_nodesc
the shutters suddenly fly open.
*if (friend1_lover)
	${friend1_name}, lying next to you in your shared bed, jumps to ${friend1_hisher} feet and grabs the long wooden stake from the floor beside ${friend1_himher}.  You get out of bed as well.
*if (friend1_lover=false)
	You barely have time to get out of bed before ${friend1_name} bursts into your room with a long wooden stake in ${friend1_hisher} hands.

"You've been looking for me," a man says from the shadows.
*line_break
He is slender and wearing very expensive clothing.  You can't help but notice how engaging his eyes are.  They seem to almost draw you in with a power of their own.  You find yourself suddenly trusting the man, despite the warning bells dimly sounding in the back of your mind.
*set used_dagger false
*choice
	#Offer your neck and honestly say, "I've come to join you."
		${friend1_name} looks over at you with surprise.  The vampire smiles at you, showing sharp pointed teeth through his parted lips.  He seems to float toward you.  You feel the sting as your neck is pierced and your mind starts to drift away.  You have just damned your soul to the hells.
		*if (showstats)
			*line_break
			(Evil +30)
		*set good -30
		*goto Wilderness_OfferedVamp
	#Offer your neck, as a distraction, and deceitfully say, "Drink from me.  I am yours."
		${friend1_name} looks over at you with surprise.  The vampire smiles at you, showing sharp pointed teeth through his parted lips.  He seems to float toward you.  You feel the sting as your neck is pieced and your mind starts to drift away.  You struggle to maintain control and hope that ${friend1_name} uses the distraction in time.
		*label Wilderness_OfferedVamp
		*set vampire true
		
		The man cuts a deep wound across his wrist and brings the bloody gash to your lips.  The warmth fills your mouth for a brief moment before the vampire suddenly pulls away.
		
		You see ${friend1_name} standing behind the vampire.  $!{friend1_hisher} hands are empty, the wooden stake having been driven deep into the vampire's back!  The vampire screams in rage and pain as smoke billows from the wound.
		
		"That is for my parents," ${friend1_name} says as the vampire turns to dust and falls to pieces.
		*label DeadVamp
		
		"I'll never forget this.  Your diversion worked.  I almost didn't break free of its enchantment in time.  I never would have succeeded without your help."
		*label wilderness_friendhappy
		*set peterpetra_story 10
		*if (showstats)
			*line_break
			(${peterpetra_name} Relationship +10)
		*set peterpetra_relationship +10
		*if (vampire)
			
			The taste of the vampire's blood in your mouth sends strange thoughts through your head.  You don't think that it was enough to have contracted true vampirism, but you can't be certain.
			*if (showstats)
				*line_break
				(Perception +5, Strength +5, Endurance +5 and Agility +5)
			*set perception +5
			*set strength +5
			*set endurance +5
			*set agility +5
		*goto Wilderness_AfterChildhoodfriend_Quest
	*if (holywater) #Throw your holy water at the creature.
		The vial smashes against the foul creature, burning the evil thing with its holiness.  ${friend1_name} uses the distraction to get behind the vampire and push the long wooden stake through his back and into his dark heart.  Your mind clears instantly as the creature turns to ash and falls to pieces.
		*if (showstats)
			*line_break
			(Good +10, Religion +10 and Lost Holy Water)
		*set good +10
		*set religion +10
		*set holywater false
		*goto DeadVamp
	*if (bow) #Fire an arrow into the vampire's heart.
		*if (archery>=30)
			The vampire doesn't react in time as your wooden arrow plunges deeply into his chest.  He shudders with convulsions as smoke wafts from the wound.  With a sudden crack, the vampire explodes into dust.
			*if (showstats)
				*line_break
				(Good +10 and Archery +5)
			*set good +10
			*set archery +5
			
			"You did it," ${friend1_name} says in awe.  "He's dead."
			*goto wilderness_friendhappy
		*else
			The arrow misses the vampire's heart.  He pulls the wooden shaft free of his shoulder and drops it to the ground as he advances toward you.
			*if (showstats)
				(Needed 30 Archery)
			*goto LostToVamp			
	*if (dagger) #Throw your dagger into the creature's chest.
		The dagger strikes true, but the vampire doesn't even flinch.  He simply pulls the blade free and drops it to the ground.  You see the bloodless wound close.
		*if (showstats)
			*line_break
			(Good +10, Blades +5 and Lost Dagger)
		*set used_dagger true
		*set dagger false
		*set good +10
		*set blades +5
		*goto LostToVamp
	#Punch the creature in the face.
		You land a solid blow, but the man doesn't even blink as his nose breaks.  The injury quickly resets itself and he appears as though you never even hit him.
		*if (showstats)
			*line_break
			(Good +10 and Unarmed +5)
		*set good +10
		*set unarmed +5
		*goto LostToVamp
	*if (sword) #Hit the creature with your sword.
			The blade sinks deeply into his side, but the creature doesn't bleed.  He simply reaches down and pulls the blade free.  You see the wound close.
			*if (showstats)
				*line_break
				(Good +10 and Blades +5)
			*set good +10
			*set blades +5
			*label LostToVamp
			*set peterpetra_story 11
			
			${friend1_name} rushes behind the vampire and attempts to drive the stake through his back and into his heart, but the creature is ready for it.  He raises his hand and ${friend1_name} is thrown backwards and into the wall.
			
			"I suppose that I have been in this town for too long," the vampire says.  "Good night to you both."
			
			The creature turns to mist and floats away on the night wind out the open window.  ${friend1_name} groans from the floor, both due to the pain of ${friend1_hisher} injuries as well as from the frustration of having failed ${friend1_hisher} lifelong quest.
			*if (used_dagger)
				Without a word, you pick up your dagger from the floor.
				*if (showstats)
					*line_break
					(Regained Dagger)
				*set dagger true
			*goto Wilderness_AfterChildhoodfriend_Quest

*comment ------------------------------------------------------------Level up------------

*label Level_Squire
*set class_squire +1
*if (showstats)
	*line_break
	(Gained level in Squire, Gold +50, Blades +10, Strength +5, Agility +5, Endurance +5, Charm +10, History +10 and Geography +5)	
*set gold +50
*set blades +10
*set strength +5
*set agility +5
*set endurance +5
*set charm +10
*set history +10
*set geography +5
*set title "squire"
*return

*label Level_Bard
*set class_bard +1
*if (questdetails="the Academy of Wizards")
	*if (showstats)
		*line_break
		(Gained level in Bard, Charm +5, History +10, Geography +10, Agility +5, Blades +5, Magic +20 and Gold +110)
	*set charm +5
	*set history +10
	*set geography +10
	*set agility +5
	*set blades +5
	*set magic +20
	*set gold +110
	*goto Bard_Title
*if (showstats)
	*line_break
	(Gained level in Bard, Charm +10, History +10, Geography +10, Agility +10, Blades +10, Archery +5, Magic +10 and Gold +180)
*set charm +10
*set history +10
*set geography +10
*set agility +10
*set blades +10
*set archery +5
*set magic +10
*set gold +180
*label Bard_Title
*if (class_bard=3)
	*set title "world-famous bard"
	*return
*else
	*set title "bard"
	*return

*label Level_Assassin
*set class_assassin +1
*if (questdetails="the wilderness")
	*if (showstats)
		*line_break
		(Gained level in Assassin, Nature +20, Agility +10, Perception +10, Unarmed +5, Blades +5, Archery +10 and Gold +150)
	*set nature +20
	*set agility +10
	*set perception +10
	*set unarmed +5
	*set blades +5
	*set archery +10
	*set gold +150
	*set title "poisoner"
	*return
*if (questdetails="the Academy of Wizards")
	*if (showstats)
		*line_break
		(Gained level in Assassin, Nature +5, Agility +5, Perception +10, Stealth +15, Unarmed +5, Blades +5, Archery +5 and Gold +150)
	*set nature +5
	*set agility +5
	*set perception +10
	*set stealth +15
	*set unarmed +5
	*set blades +5
	*set archery +5
	*set gold +150
	*set title "assassin"
	*return
*if (showstats)
	*line_break
	(Gained level in Assassin, Nature +5, Stealth +5, Devices +5, Agility +10, Perception +10, Unarmed +5, Blades +5, Archery +5 and Gold +175)
*set nature +5
*set stealth +5
*set devices +5
*set agility +10
*set perception +10
*set unarmed +5
*set blades +5
*set archery +5
*set gold +175
*set title "assassin"
*return

*label Level_Monk
*set class_monk +1
*if (questdetails="the wilderness")
	*if (showstats)
		*line_break
		(Gained level in Monk, Gold +50, Nature +20, Agility +10, Perception +10 and Unarmed +10)
	*set gold +50
	*set nature +20
	*set agility +10
	*set perception +10
	*set unarmed +10
*if (questdetails="the Norgan Mountains")
	*if (monkquest!=3)
		*if (showstats)
			*line_break
			(Gained level in Monk, Gold +50, Nature +10, Arcana +5, Geography +5, Agility +5, Perception +10 and Unarmed +10)
		*set gold +50
		*set nature +10
		*set arcana +5
		*set geography +5
		*set agility +5
		*set perception +10
		*set unarmed +10
	*if (monkquest=3)
		*if (showstats)
			*line_break
			(Gained level in Monk, Gold +50, Religion +10, Nature +10, Arcana +10, Magic +15 and Unarmed +10)
		*set gold +50
		*set religion +10
		*set nature +10
		*set arcana +10
		*set magic +15
		*set unarmed +10
*if ((questdetails="the city of Tornassa") or (questdetails="the Academy of Wizards"))
	*if (showstats)
		*line_break
		(Gained level in Monk, Gold +50, History +5, Geography +5, Arcana +5, Agility +10, Perception +10 and Unarmed +10)
	*set gold +50
	*set history +5
	*set geography +5
	*set arcana +5
	*set agility +10
	*set perception +10
	*set unarmed +10
*set title "monk"
*return

*label Level_Thief
*set class_thief +1
*if (showstats)
	*line_break
	(Gained level in Thief, Devices +10, Stealth +10, Agility +10, Blades +5 and Gold +180)
*set devices +10
*set stealth +10
*set agility +10
*set blades +5
*set gold +180
*if (class_thief=3)
	*set title "master thief"
	*return
*else
	*set title "thief"
	*return

*label Level_Wizard
*set class_wizard +1
*if (questdetails="the Academy of Wizards")
	*if (showstats)
		*line_break
		(Gained level in Wizard, Gold +50, History +10, Magic +20 and Arcana +15)
	*set gold +50
	*set history +10
	*set magic +20
	*set arcana +15
	*set title "Academy trained wizard"
	*return
*if (questdetails="the wilderness")
	*if (showstats)
		*line_break
		(Gained level in Wizard, Gold +50, Geography +5, Magic +10, Nature +20 and Arcana +10)
	*set gold +50
	*set geography +5
	*set magic +10
	*set nature +20
	*set arcana +10
	*set title "shaman"
	*return
*if (questdetails="the city of Tornassa")
	*if (showstats)
		*line_break
		(Gained level in Wizard, Gold +50, Magic +10, History +10, Geography +5 and Arcana +10)
	*set gold +50
	*set magic +10
	*set history +10
	*set geography +5
	*set arcana +10
	*set title "wizard apprentice"
*if (questdetails="the Norgan Mountains")
	*if (showstats)
		*line_break
		(Gained level in Wizard, Gold +50, Magic +10, Geography +5 and Arcana +15)
	*set gold +50
	*set magic +10
	*set geography +5
	*set arcana +15
	*set title "magic researcher"
*return

*label Level_Sage
*set class_sage +1
*if (questdetails="the wilderness")
	*if (showstats)
		*line_break
		(Gained level in Sage, Gold +50, Magic +5, Religion +5, Nature +20, History +5, Geography +5 and Arcana +5)
	*set gold +50
	*set magic +5
	*set religion +5
	*set nature +20
	*set history +5
	*set geography +5
	*set arcana +5
	*set title "author"
	*return
*if (questdetails="the city of Tornassa")
	*if (showstats)
		*line_break
		(Gained level in Sage, Gold +50, Magic +5, Religion +5, Nature +5, History +10, Geography +15 and Arcana +5)
	*set gold +50
	*set magic +5
	*set religion +5
	*set nature +5
	*set history +10
	*set geography +15
	*set arcana +5
	*set title "sage"
	*return
*if (questdetails="the Academy of Wizards")
	*if (showstats)
		*line_break
		(Gained level in Sage, Gold +50, Magic +10, Religion +5, Nature +5, History +10, Geography +5 and Arcana +10)
	*set gold +50
	*set magic +10
	*set religion +5
	*set nature +5
	*set history +10
	*set geography +5
	*set arcana +10
	*set title "librarian"
	*return
*comment (questdetails="the Norgan Mountains")
*if (showstats)
	*line_break
	(Gained level in Sage, Gold +50, Magic +5, Religion +5, Nature +5, History +10, Geography +10 and Arcana +5)
*set gold +50
*set magic +5
*set religion +5
*set nature +5
*set history +10
*set geography +10
*set arcana +5
*set title "historian"
*return

*label Level_Priest
*set class_priest +1
*if (class_priest=1)
	*if (holysymbol=false)			
		*choice
			#You follow a good deity.
				The embodiment of all that is good in the world.  Light, compassion, healing, justice, truth, kindness…the list could go on for hours.
				*set god_good true
				*choice
					#You follow Lucien, a good and kind God.
						*set god_name "Lucien"
						*set god_goddess "God"
						*set god_goddess "God"
						*set god_hisher "His"
						*set god_himher "Him"
						*set god_heshe "He"
						*goto BecomingAPriest
					#You follow Auriel, a good and kind Goddess.
						*set god_name "Auriel"
						*set god_goddess "Goddess"
						*set god_hisher "Her"
						*set god_himher "Her"
						*set god_heshe "She"
						*goto BecomingAPriest
					#You follow a different God.
						*label Name_God
						*input_text god_name
						*if ((god_name="the Unknown") or (god_name="None"))
							Your God has to have a name.
							*goto Name_God
						*set god_goddess "God"
						*set god_hisher "His"
						*set god_himher "Him"
						*set god_heshe "He"
						*goto BecomingAPriest
					#You follow a different Goddess.
						*label Name_Goddess
						*input_text god_name
						*if ((god_name="the Unknown") or (god_name="None"))
							Your Goddess has to have a name.
							*goto Name_Goddess
						*set god_goddess "Goddess"
						*set god_hisher "Her"
						*set god_himher "Her"
						*set god_heshe "She"
						*goto BecomingAPriest
			#You follow an evil deity.
				The embodiment of all that is evil in the world.  Darkness, shadows, disease, corruption, deceit…the list could go on for hours.  In addition to these things, your deity encourages wealth, power and domination over other creatures: living and dead.
				*set god_good false
				*choice
					#You follow Noct, an evil and cruel God.
						*set god_name "Noct"
						*set god_goddess "God"
						*set god_hisher "His"
						*set god_himher "Him"
						*set god_heshe "He"
						*goto BecomingAPriest
					#You follow Shadi, an evil and cruel Goddess.
						*set god_name "Shadi"
						*set god_goddess "Goddess"
						*set god_hisher "Her"
						*set god_himher "Her"
						*set god_heshe "She"
						*goto BecomingAPriest
					#You follow a different God.
						*label Name_God_Evil
						*input_text god_name
						*if ((god_name="the Unknown") or (god_name="None"))
							Your God has to have a name.
							*goto Name_God_Evil
						*set god_goddess "God"
						*set god_hisher "His"
						*set god_himher "Him"
						*set god_heshe "He"
						*goto BecomingAPriest
					#You follow a different Goddess.
						*label Name_Goddess_Evil
						*input_text god_name
						*if ((god_name="the Unknown") or (god_name="None"))
							Your Goddess has to have a name.
							*goto Name_Goddess_Evil
						*set god_goddess "Goddess"
						*set god_hisher "Her"
						*set god_himher "Her"
						*set god_heshe "She"
						*goto BecomingAPriest
	*else
		*label BecomingAPriest
		The holy symbol dedicated to ${god_name} represents ${god_hisher} divine will.
		*if (god_good=false)
			Of course, you can't openly show that you worship an evil ${god_goddess}, so the symbol looks similar to that of a good deity that is commonly worshipped.  Only a trained eye looking at the symbol very closely would see how it has been corrupted to serve ${god_name}.  This allows you to pray in public temples.
		*if ((holysymbol=false) and (showstats))
			*line_break
			(Gained level in $!{priestpriestess}, Blades +5, Religion +20, Charm +5, History +10, Arcana +10, Magic +20, Gold +60 and Gained Holy Symbol)
		*if ((holysymbol) and (showstats))
			*line_break
			(Gained level in $!{priestpriestess}, Blades +5, Religion +20, Charm +5, History +10, Arcana +10, Magic +20 and Gold +60)
		*set blades +5
		*set religion +20
		*set charm +5
		*set history +10
		*set arcana +10
		*set magic +20
		*set gold +60
		*set holysymbol true
		*set title priestpriestess
		*return
*else
	*comment Not a first time priest.
	*if (showstats)
		*line_break
		(Gained level in $!{priestpriestess}, Religion +10, Charm +5, Arcana +10, History +10, Magic +10 and Gold +80)
	*set religion +10
	*set charm +5
	*set arcana +10
	*set history +10
	*set magic +10
	*set gold +80
	*if (class_priest=3)
		*set title "high "
		*set title title&priestpriestess
		*return
	*else
		*set title priestpriestess
		*return

*label Level_Cleric
*set class_cleric +1
*if (showstats)
	*line_break
	(Gained level in Cleric, Religion +10, Charm +3, Blades +10, Archery +5, Strength +10 and Gold +80)
*set religion +10
*set charm +3
*set blades +10
*set archery +5
*set strength +10
*set gold +80
*set title "cleric"
*return

*label Level_Druid
*set class_druid +1
*if (questdetails="the Academy of Wizards")
	*if (showstats)
		*line_break
		(Gained level in Druid, Magic +15, Nature +10, Arcana +15 and Gold +80)
	*set magic +15
	*set nature +10
	*set arcana +15
	*set gold +80
	*set title "druid herbologist"
	*return
*if (questdetails="the Norgan Mountains")
	*if (showstats)
		*line_break
		(Gained level in Druid, Blades +5, Nature +10, Endurance +15, Magic +10, Geography +10 and Gold +50)
	*set blades +5
	*set nature +10
	*set endurance +15
	*set magic +10
	*set geography +10
	*set gold +50
	*set title "tundra explorer"
	*return
*if (showstats)
	*line_break
	(Gained level in Druid, Gold +50, Magic +10, Nature +10, Stealth +15 and Geography +10)
*set gold +50
*set magic +10
*set nature +10
*set stealth +15
*set geography +10
*set title "druid"
*return

*label Level_Ranger
*set class_ranger +1
*if (questdetails="the Academy of Wizards")
	*if (showstats)
		*line_break
		(Gained level in Ranger, Blades +5, Nature +10, Stealth +5, Archery +5, Arcana +10 and Gold +110)
	*set blades +5
	*set nature +10
	*set stealth +5
	*set archery +5
	*set arcana +10
	*set gold +110
	*set title "ranger guide"
	*return
*if (questdetails="the Norgan Mountains")
	*if (showstats)
		*line_break
		(Gained level in Ranger, Blades +5, Nature +10, Endurance +15, Geography +10, Archery +10 and Gold +55)
	*set blades +5
	*set nature +10
	*set endurance +15
	*set geography +10
	*set archery +10
	*set gold +55
	*set title "tundra hunter"
	*return
*if (showstats)
	*line_break
	(Gained level in Ranger, Blades +10, Nature +10, Stealth +10, Archery +10, Geography +10 and Gold +80)
*set blades +10
*set nature +10
*set stealth +10
*set archery +10
*set geography +10
*set gold +80
*set title "ranger"
*return

*label Level_Guard
*set class_guard +1
*if (questdetails="the Norgan Mountains")
	*if (showstats)
		*line_break
		(Gained level in Guard, Endurance +20, Perception +10, Archery +5, Blades +10 and Gold +60)
	*set endurance +20
	*set perception +10
	*set archery +5
	*set blades +10
	*set gold +60
	*set title "patrolling guard"
	*return
*if (showstats)
	*line_break
	(Gained level in Guard, Endurance +10, Perception +10, Archery +10, Blades +10 and Gold +100)
*set endurance +10
*set perception +10
*set archery +10
*set blades +10
*set gold +100
*if (questdetails="the Academy of Wizards")
	*set title "bodyguard"
	*return
*if (class_guard=3)
	*set title "guard captain"
	*return
*else
	*set title "guard"
	*return

*label Level_Thug
*set class_thug +1
*choice
	#You mostly used your blade to settle disputes.
		The sharp end of a blade is a quick way to remove a problem.
		*if (sword=false)
			The first time someone pulled a sword on you, you took it for yourself.
		*if ((showstats) and (sword))
			*line_break
			(Gained level in Thug, Charm +10, Agility +10, Endurance +10, Blades +10 and Gold +130)
		*if ((showstats) and (sword=false))
			*line_break
			(Gained level in Thug, Gained a Sword, Charm +10, Agility +10, Endurance +10, Blades +10 and Gold +130)
		*set charm +10
		*set agility +10
		*set endurance +10
		*set blades +10
		*set gold +130
		*set sword true
		*goto ThugOptions
	#You mostly used your fists to settle disputes.
		Your hands were always with you and the show of force could often prevent needless deaths.
		*if (showstats)
			*line_break
			(Gained level in Thug, Charm +10, Strength +10, Endurance +10, Unarmed +10 and Gold +130)
		*set charm +10
		*set strength +10
		*set endurance +10
		*set unarmed +10
		*set gold +130
		*goto ThugOptions

*label ThugOptions
*if (questdetails="the wilderness")
	*set title "mercenary"
	*return
*if (questdetails="the city of Tornassa")
	*set title "bodyguard"
	*return
*if (questdetails="the Norgan Mountains")
	*set title "bruiser"
	*return
*set title "thug"
*return

*label Leaving
*if (demonsummoner)
	
	During your time in exile, you had a lot of time to study your Demonstones.  Although you were getting better, you knew that your skill growth had been through sheer determination instead of academic progression.  You can't help but wonder what skills the Consortium of Planewalkers has learned that you have not stumbled upon.
	*if (showstats)
		*line_break
		(Arcana +5)
	*set arcana +5
	
	During your travels, you learned a few things.  The runes on the unglowing Demonstone that Zusak had stolen from your parents' treasury say the name "K'Girr." And, even stranger, you have noticed the briefest flicker of a glow beginning within it.
	*set demonstone_kgirr_known true
	*if (((demonstone_xiatta_known) and (demonstone_zonch_known)) and ((demonstone_brahl_known) and (demonstone_daanda_known)))
		*goto Exile_Summoning
	*if (((demonstone_zonch) and (demonstone_zonch_known=false)) and (arcana>=40))
		*gosub Learned_New_Check
		The one glowing a greyish brown says "Zon'ch."
		*set demonstone_zonch_known true
	*if (((demonstone_daanda) and (demonstone_daanda_known=false)) and (arcana>=35))
		*gosub Learned_New_Check
		The one glowing a dim grey says "Daan'da."	
		*set demonstone_daanda_known true
	*if (((demonstone_brahl) and (demonstone_brahl_known=false)) and (arcana>=30))
		*gosub Learned_New_Check
		The one glowing a dull green says "Brahl."
		*set demonstone_brahl_known true
	*if (((demonstone_xiatta) and (demonstone_xiatta_known=false)) and (arcana>=20))
		*gosub Learned_New_Check
		The one glowing a soft blue says "Xi'atta."
		*set demonstone_xiatta_known true
	*if (showstats)
		*if ((demonstone_xiatta) and (demonstone_xiatta_known=false))
			(Needed 20 Arcana)
			*goto Exile_demons_sage
		*if ((demonstone_brahl) and (demonstone_brahl_known=false))
			(Needed 30 Arcana)
			*goto Exile_demons_sage
		*if ((demonstone_daanda) and (demonstone_daanda_known=false))
			(Needed 35 Arcana)
			*goto Exile_demons_sage
		*if ((demonstone_zonch) and (demonstone_zonch_known=false))
			(Needed 40 Arcana)
			*goto Exile_demons_sage
	*goto Exile_demons_sage
	
	*label Learned_New_Check
	*if (exile_learned_new=false)
		You also learned some other new rune names:
		*set exile_learned_new true
	*return

	*label Exile_demons_sage
	*if ((((demonstone_zonch) and (demonstone_zonch_known=false)) or ((demonstone_brahl) and (demonstone_brahl_known=false))) or (((demonstone_daanda) and (demonstone_daanda_known=false)) or ((demonstone_xiatta) and (demonstone_xiatta_known=false))))
		
		One night, you meet a priestess of Lucien who says that she is traveling to a religious site to translate some ancient writings found on a pillar.  When asked, she says that she knows Som'Rethese very well.  She offers to translate your Demonstones, for a donation to her order.
		*label Exile_DecipherDemonstones
		*if (((((demonstone_zonch) and (demonstone_zonch_known=false)) or ((demonstone_brahl) and (demonstone_brahl_known=false))) or (((demonstone_daanda) and (demonstone_daanda_known=false)) or ((demonstone_xiatta) and (demonstone_xiatta_known=false))))=false)
			*goto Exile_Summoning
		*choice
			*if (demonstone_zonch_known=false)
				*selectable_if (gold>=100) #Decipher the one glowing a greyish brown. (Needs 100 Gold)
					The one glowing a greyish brown says "Zon'ch."
					*if (showstats)
						*line_break
						(Gold -100)
					*set gold -100
					*set demonstone_zonch_known true
					*goto Exile_DecipherDemonstones
			*if ((demonstone_daanda_known=false) and (demonstone_daanda))
				*selectable_if (gold>=60) #Decipher the one glowing a dim grey. (Needs 60 Gold)
					The one glowing a dim grey says "Daan'da."
					*if (showstats)
						*line_break
						(Gold -60)
					*set gold -60
					*set demonstone_daanda_known true
					*goto Exile_DecipherDemonstones
			*if ((demonstone_brahl_known=false) and (demonstone_brahl))
				*selectable_if (gold>=50) #Decipher the one glowing a dull green. (Needs 50 Gold)
					The one glowing a dull green says "Brahl."
					*if (showstats)
						*line_break
						(Gold -50)
					*set gold -50
					*set demonstone_brahl_known true
					*goto Exile_DecipherDemonstones
			#Continue.
				*goto Exile_Summoning_ns
	*else
		*goto Exile_Summoning

	*label Exile_Summoning
	
	*label Exile_Summoning_ns
	Your hard life of trials and tribulations during your exile is the perfect forge for a demon summoner.  Your willpower and tenacity are honed by your need of patience and determination.
	*if (using_legacy)
		Although demon summoning was much different when the wizard of Elmvale had been alive, you wonder if your ancestor's magical skill has passed on to you and strengthened your own resolve because your mental fortitude has grown drastically.
		*set temp_willpower (60-willpower)
		*if (temp_willpower<=0)
			*comment They have over 60 or more Willpower, which really shouldn't be possible, so I won't give them more.)
			*goto Exile_SummoningLoop
		*if (showstats)
			*line_break
			(Legacy Advantage #5: Maximum Willpower at this stage.  Willpower +${temp_willpower})
		*set willpower +temp_willpower
		*goto Exile_SummoningLoop
	*if (willpower>=35)
		*if (showstats)
			*line_break
			(Willpower +10)
		*set willpower +10
		*goto Exile_SummoningLoop
	*else
		*set temp_willpower (35-willpower)
		*set temp_willpower +10
		*if (showstats)
			*line_break
			(Willpower +${temp_willpower})
		*set willpower +temp_willpower
		*goto Exile_SummoningLoop
	
	*label Exile_SummoningLoop
	*choice			
			*if (demonstone_xiatta) #Summon Xi'atta.
				*comment Name Always Known
				*comment Willing: 20, Small Struggle: 30, Against: 40
				*comment 45-60 willpower are possible
				*if (demonstone_xiatta_firstseen)
					The rune-covered stone glows a soft blue which seems to fill your mind as you concentrate.  Suddenly, a fragile-looking blue creature appears in front of you.  It is only about one foot tall and has a delicate web of ice connecting its arms to its body and ice webbing between its fingers and toes.
				*if (demonstone_xiatta_firstseen=false)
					Xi'atta appears in front of you. Its fragile blue body is only one foot tall, and it has a delicate web of ice between its fingers and toes as well as between its arms and its torso.
				*set demonstone_xiatta_firstseen false
				
				"Hello 
				*if (demonstone_xiatta_summoned)
					again,
				${mastermistress}," Xi'atta says in a frosty voice.
				*set demonstone_xiatta_summoned true
				*set talk_options 2
				*label Exile_Xiatta_loop
				*if (talk_options=0)
					
					Having finished questioning the frosty demon, you return it to its own domain.
					*goto Exile_SummoningLoop
				*choice
					#Say, "Tell me about your previous owner."
						*set talk_options -1
						The small demon shakes and stutters for a moment, but its will is no match for your own.  Zusak likely commanded all of his demons to not speak about him, but with your dominance, Xi'atta has no choice.
						
						"Alexander Zusak, high-chancellor of the Consortium of Planewalkers," Xi'atta says with a note of resignation.
						
						Further questioning reveals that Xi'atta doesn't know very much more than this.  It seems that Zusak only used the demon to cool his drinks on warm days.
						*goto Exile_Xiatta_loop
					#Say, "Be prepared to come when I summon you."
						*set talk_options -1
						"As you wish, ${mastermistress}."
						*goto Exile_Xiatta_loop
					#Command, "Return to your own domain."
						"Yes, ${mastermistress}," the creature says.
						
						With a soft popping noise, the imp vanishes from sight.
						*goto Exile_SummoningLoop	
			*if (demonstone_brahl_known) #Summon Brahl.
				*comment Willing: 50, Small Struggle: 60, Against: 70
				*comment 45-60 willpower are possible
				*if (demonstone_brahl_firstseen)
					The rune-covered stone glows a dull green which seems to fill your mind as you concentrate. Suddenly, a large being in dark leathery skin is standing in front of you.  It's about six feet tall with large square shoulders.  Its skin looks like it's covered in scaly warts and it has short stubby horns protruding from its forehead.
				*if (demonstone_brahl_firstseen=false)
					Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.
				*set demonstone_brahl_firstseen false
				*if (willpower<50)
					
					You feel a pressure building in your head as the demon overpowers your mind.
					*if (showstats)
						(Needed 50 Willpower)
					*page_break Blackness…
					"I think that one's still beyond your skills," ${friend1_name} says.
					*if (friend1_name=jacejess_name)
						"I blasted you with my magic the moment I saw you losing control."
						
						Your throbbing head attested to the fact that the Soulburner's magic had knocked you out, but at least Brahl didn't have a chance to make you do something you'd regret.  It would take a stronger resolve to control the brutish demon.
						*goto Exile_SummoningLoop
					"I cracked you over the head the moment I saw you losing control."
					
					The lump on the back of your head throbbed, but at least Brahl didn't have a chance to make you do something you'd regret.  It would take a stronger resolve to control the brutish demon.
					*goto Exile_SummoningLoop
				*set demonstone_brahl_summoned true
				*set talk_options 2
				*label Exile_Brahl_loop
				*if (talk_options=0)
					
					Having finished questioning the muscular demon, you return it to its own domain.
					*goto Exile_SummoningLoop
				*choice
					#Say, "Tell me about your previous owner."
						*set talk_options -1
						The husky demon loses its smile as it clenches its sharp teeth.  You feel a pressure in your mind and realize that you don't have complete control of Brahl.  It may not be able to dominate you, but it still has some will of its own.
						
						"I ain't talking," Brahl growls.
						*goto Exile_Brahl_loop
					#Say, "Be prepared to come when I summon you."
						*set talk_options -1
						"Sure," Brahl says with a shrug of its muscular shoulders.
						*goto Exile_Brahl_loop
					#Command, "Return to your own domain."
						"Okay," the creature says.
						
						With a soft popping noise, the demon vanishes from sight.
						*goto Exile_SummoningLoop
			*if (demonstone_zonch_known) #Summon Zon'ch.
				*comment Willing: 30, Small Struggle: 40, Against: 50
				*comment 45-60 willpower are possible
				*if (demonstone_zonch_firstseen)
					The rune-covered stone glows a greyish brown which seems to fill your mind as you concentrate.  Suddenly, a brown-skinned creature appears amidst a small cyclone.  It's hard to see the demon's shape as the dust spins around it, but it's small, perhaps only one foot tall.
				*if (demonstone_zonch_firstseen=false)
					Zon'ch appears amidst a small cyclone.  Its brown skin is obscured by the dust as it spins around its one-foot-tall form.
				*set demonstone_zonch_firstseen false
				
				"I come, ${mastermistress}," the demon says in its raspy voice.
				*set demonstone_zonch_summoned true
				*set talk_options 2
				*label Exile_Zonch_loop
				*if (talk_options=0)
					
					Having finished questioning the dusty demon, you return it to its own domain.
					*goto Exile_SummoningLoop
				*choice
					#Say, "Tell me about your previous owner."
						*set talk_options -1
						You see the demon's eyes close and a ball of dust rise around it as it fights your command.
						*if (willpower>=50)
							You bear down on the imp and soon have it fully under your control.
							
							"I worked for a man named Alexander Zusak," Zon'ch replies.
							
							You try to learn more about Zusak, but realize that Zon'ch knows little besides the man's name.  It was used mostly as a cleaning servant to dust the high-chancellor's private quarters and never heard anything important.
							*goto Exile_Zonch_loop
						*else
							
							"I may not," Zon'ch finally says as it disappears in a cloud of dirt.
							*if (showstats)
								(Needed 50 Willpower)
							
							Although you don't have full control over the demon, you know that it doesn't have enough power to dominate you and that you can force it to do small tasks.
							*goto Exile_SummoningLoop
					#Say, "Be prepared to come when I summon you."
						*set talk_options -1
						"As you wish, ${mastermistress}," Zon'ch says in its gravelly voice.
						*goto Exile_Zonch_loop
					#Command, "Return to your own domain."
						"Okay," the creature says.
						
						With a soft popping noise, the imp vanishes from sight.
						*goto Exile_SummoningLoop
			*if (demonstone_daanda) #Summon Daan'da.
				*comment Will of 0, but very stupid and weak.
				Daan'da appears in front of you.  The thin imp is four feet tall and its greyish limbs are pencil thin.  It moves slowly with a vacant look in its eyes.  This demon is clearly among the oldest you own, having served the Som'Reth themselves.
				*set demonstone_daanda_summoned true
				*set talk_options 4
				*label Exile_Daanda_loop
				*if (talk_options=0)
					
					Having finished questioning the dim-witted demon, you return it to its own domain.
					*goto Exile_SummoningLoop
				*choice
					#Say, "Tell me about your previous owner."
						*set talk_options -1
						"Uhhhh, bunch of owners," Daan'da says, putting up no fight, which meant that it simply didn't remember all their names.
						*goto Exile_Daanda_loop
					#Say, "Be prepared to come when I summon you."
						*set talk_options -1
						"Okay," the demon says.
						*goto Exile_Daanda_loop
					#Ask, "What were the Som'Reth like?"
						*set talk_options -1
						"Ummm, they asked for the door to open," Daan'da answers in its slow voice.  "And sometimes close."
						*goto Exile_Daanda_loop
					#Ask, "What can you do?"
						*set talk_options -1
						"I can open doors," Daan'da answers in its slow voice.  "And close them too."
						*goto Exile_Daanda_loop
					#Command, "Return to your own domain."
						"Okay," the demon says.
						
						With a soft popping noise, the imp vanishes from sight.
						*goto Exile_SummoningLoop
			*if (demonstone_tyborr) #Summon Tyborr.
				*comment Tyborr: Willing: 80, Small Struggle: 90, Against: 100
				Tyborr appears before you, wearing its brown robes.  The small five-and-a-half foot tall demon looks more like an old man with two stubby horns than a monster.  This demon is clearly among the oldest you own, having served the Som'Reth themselves.
				
				"I will never aid you," it says in a sad voice before it disappears.
				*if (showstats)
					(Needed 80 Willpower, which is not possible at this time)
				*goto Exile_SummoningLoop
			#Put the Demonstones away.
				You carefully put the rune-covered stones back into your runebag.			
				*goto Exile_Check_Romantic
*else
	*goto Exile_Check_Romantic

*label Exile_Check_Romantic
*if (friend1_lover)
	
	The escape from Vernex had been a harrowing experience, but at least you had ${friend1_name} by your side.
	*comment I use lover_sleptwith as a temporary variable that should not be trusted beyond this section.
	*if (lover_name=jacejess_name)
		*set lover_sleptwith jacejess_sleptwith
	*if (lover_name=theothea_name)
		*set lover_sleptwith theothea_sleptwith	
	*if (lover_name=gillgale_name)
		*set lover_sleptwith gillgale_sleptwith
	*if (lover_name=peterpetra_name)
		*set lover_sleptwith peterpetra_sleptwith
	*if (lover_name=karlkarla_name)
		*set lover_sleptwith karlkarla_sleptwith
	*choice
		*if (lover_sleptwith=false) #Your relationship deepened to include physical love.
			*set friend1_sleptwith true
			*set virgin false
			*if (friend1_name=theothea_name)
				*set theothea_sleptwith true
				The large warrior was a surprisingly gentle lover.  $!{theothea_heshe} was enormously strong and had amazing endurance, which kept you awake through most of the nights, but also filled your bedtime with great pleasure.
			*if (friend1_name=jacejess_name)
				*set jacejess_sleptwith true
				The Soulburner was surprisingly timid at first, but as your relationship grew, ${jacejess_heshe} became hungry with passion for you.  $!{jacejess_heshe} had a depravity to ${jacejess_hisher} soul that made your nights together unspeakable, but entirely enjoyable.
			*if (friend1_name=karlkarla_name)
				*set karlkarla_sleptwith true
				The timid archer was hesitant at first, but ${karlkarla_hisher} love for you was so great that ${karlkarla_heshe} lost all inhibitions once you were alone.  $!{karlkarla_hisher} dexterous fingers and graceful physique made your nights together a great joy. 
			*if (friend1_name=gillgale_name)
				*set gillgale_sleptwith true
				The rogue was a wildcat in bed.  $!{gillgale_hisher} dexterous fingers and graceful physique made your nights together a great joy.
			*if (friend1_name=peterpetra_name)
				*set peterpetra_sleptwith true
				The holy warrior was a strong and passionate lover.  It was clear that ${peterpetra_heshe} had no celibacy or chastity restrictions within ${peterpetra_hisher} religious order.  Although ${peterpetra_name} didn't care for public displays of affection, what occurred behind closed doors was another matter.
			
			*goto Bittersweet
		#You had continued to date ${friend1_himher} since you went into hiding.
			*label Bittersweet
			It was a bittersweet time,
			*if (questdetails="the wilderness")
				to be nestled away with ${friend1_name} in the middle of nowhere for an entire year.
			*if (questdetails="the city of Tornassa")
				to be hiding in a city full of strangers with ${friend1_name} for an entire year.
			*if (questdetails="the Norgan Mountains")
				to snuggle in a warm bed in the freezing cold of the mountains with ${friend1_name} for an entire year.
			*if (questdetails="the Academy of Wizards")
				to be hiding in the Academy of Wizards with ${friend1_name} for an entire year.
			It was as though your life was on pause since you couldn't plan for the future.
			*if (friend1_name=theothea_name)
				*if (theothea_story=10)
					You wonder if your parents would have approved the match, since ${theothea_name} had been made chief of ${theothea_hisher} people.  It would have been an interesting diplomatic union.
				*if (theothea_story!=10)
					Your parents would never have approved of ${theothea_name}.
				You could only imagine what your old tutor, Harmond, would have thought of the muscular mountain-${theothea_manwoman}.
			*if (friend1_name=jacejess_name)
				Your parents would never have approved of ${jacejess_name}.  The idea that the sole heir of Daria would be consorting with a Soulburner would have caused an uproar among the citizens and nobles.
			*if (friend1_name=karlkarla_name)
				Your parents probably would have liked ${karlkarla_name}, although the idea that the sole heir of Daria was having a dalliance with a peasant would have been gossip for the entire kingdom.
			*if (friend1_name=peterpetra_name)
				Your parents would probably be very pleased that you were seeing ${peterpetra_name}.  Whether they would have officially approved of the courtship was unknown, but the fact that it was with a noble certainly boded well.
			*if (friend1_name=gillgale_name)
				Your parents would have been mortified to learn that ${gillgale_name} had grown up to be a thief, and the idea that the sole heir of Daria was having a dalliance with a rogue would have been gossip for the entire kingdom.
			*goto Continue_Leaving
		#You and ${friend1_name} had drifted apart over the last year.
			Perhaps it was the stress of your self-imposed exile, but the romantic involvement between you and ${friend1_name} had not stood the test of time.
			*set lover_exists false
			*set lover_name "None"
			*set friend1_lover false
			*if (friend1_name=theothea_name)
				*set theothea_lover false
			*if (friend1_name=jacejess_name)
				*set jacejess_lover false
			*if (friend1_name=karlkarla_name)
				*set karlkarla_lover false
			*if (friend1_name=peterpetra_name)
				*set peterpetra_lover false
			*if (friend1_name=gillgale_name)
				*set gillgale_lover false
			*goto Continue_Leaving
*else
	*goto Continue_Leaving
*label Continue_Leaving

That evening, your thoughts turn back to the murder of your parents.  It's like an old wound that refuses to heal.
*if (deadfriend_name!="None")
	The deaths of ${deadfriend_name} and ${fosterparent_name} are much fresher, and just as painful.  Although Thuja swung the axe, you know that Zusak is the one responsible for their deaths.
*if (deadfriend_name="None")
	The death of ${fosterparent_name} is much fresher, and just as painful.  Although Thuja swung the axe, you know that Zusak is the one responsible for ${fosterparent_hisher} death.
*if (belt_of_speed)
	Gaining his Belt of Speed wasn't worth the loss, although it truly was a wonder to behold.  Most of the time, it was just a belt.  But sometimes, usually in moments of stress, it would suddenly glow and the world seemed to slow down.
You haven't given up on finding out exactly why Alexander Zusak killed your parents and what his plans are for the recently glowing Demonstone he tried to steal.

*if (using_legacy)
	You had been hiding for nearly a year when a familiar voice gets your attention.
	
	"It's time to leave," the ghostly-blue figure of the ${legacy_race} from Elmvale
	*if (legacy_good)
		says.
	*if (legacy_good=false)
		says briskly.
	
	$!{legacy_heshe} is the youngest you've ever seen ${legacy_himher}.
	*fake_choice
		#"Is this your first time coming to me?"
			"Almost," the wizard
			*if (legacy_good)
				says with a smile.
			*if (legacy_good=false)
				says coldly.
			"Your task will fail if you continue your exile for too long.
		#"Where have you been?"
			"I have to limit my visits," the wizard says seriously.  "It takes a lot of energy to cross through the temporal barriers.
		#"Where are you in your time-line?"
			*if (legacy_good)
				"I've been asked to become the court wizard," ${legacy_heshe} says proudly.  "I'll miss my adventuring friends, but my new living quarters in the palace are very nice.  I don't think my king has any idea of how far I'm going to protect his family's interests.
			*if (legacy_good=false)
				"I've taken the role of court wizard," ${legacy_heshe} says.  "I should be able to gain a great deal of power from this new position."
		#"What help have you brought me?"
			"I'm here to tell you that your exile is over," the wizard says.  "Daria will not be reunited if you stay here any longer.
	It's time to rescue ${prisoner1_name} and ${prisoner2_name}.  These trials and tribulations have made you stronger than ever."
	*if (showstats)
		(Legacy Advantage #6: Agility +5, Charm +5, Endurance +5, Perception +5, and Strength +5.  More perks will arrive as the story progresses.)
	*set agility +5
	*set charm +5
	*set endurance +5
	*set perception +5
	*set strength +5
	
	It was true.  You are a quick learner, much like your many-great ${legacy_grand}.
	*choice
		#Your skill in archery has grown.
			Your practice has paid off as you have become a more skilled archer.  Your accuracy with the bow and arrow has improved greatly this past year.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: Archery +20.  More perks will arrive as the story progresses.)
				
			*set archery +20
			*goto After_Legacy_Advantage_7
		#Your knowledge of devices has grown.
			Your practice has paid off as you have gained a greater understanding of devices and mechanical contraptions.  Your ability to pick locks and disarm traps has grown over the year.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: Devices +20.  More perks will arrive as the story progresses.)
				
			*set devices +20
			*goto After_Legacy_Advantage_7
		#Your skill in magic has grown.
			Your practice has paid off as you have gained a greater understanding of magic.  Your skill with incantations and your personal reservoir of magic has grown over the year.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: Magic +20.  More perks will arrive as the story progresses.)
				
			*set magic +20
			*goto After_Legacy_Advantage_7
		#Your skill with blades has grown.
			Your practice has paid off as you have become a more skilled swordsman.  Your movements are more precise and more powerful.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: Blades +20.  More perks will arrive as the story progresses.)
				
			*set blades +20
			*goto After_Legacy_Advantage_7
		#Your skill in moving silently has grown.
			Your practice has paid off as you have become more skilled at moving without being seen or heard.  Your footsteps are soft and your fingers are light.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: Stealth +20.  More perks will arrive as the story progresses.)
				
			*set stealth +20
			*goto After_Legacy_Advantage_7
		#Your skill in fighting without weapons has grown.
			Your practice has paid off as you have become better at fighting with your hands.  Your punches and kicks are much more powerful than they were a year before.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: Unarmed +20.  More perks will arrive as the story progresses.)
				
			*set unarmed +20
			*goto After_Legacy_Advantage_7
		#Your knowledge of the arcane has grown.
			Your general knowledge of obscure details and facts have become greater as you learn many new things over the year.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: Arcana +20.  More perks will arrive as the story progresses.)
				
			*set arcana +20
			*goto After_Legacy_Advantage_7
		#Your knowledge of geography has grown. 
			Your knowledge of locations and maps have become even greater.  Not only do you know more about distant places, you have also learned the best ways to get there.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: Geography +20.  More perks will arrive as the story progresses.)
				
			*set geography +20
			*goto After_Legacy_Advantage_7
		#Your knowledge of history has grown. 
			Your knowledge of dates and people from the past have become even greater as you learn many new things over the year.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: History +20.  More perks will arrive as the story progresses.)
				
			*set history +20
			*goto After_Legacy_Advantage_7
		#Your knowledge of nature has grown. 
			Your knowledge of animals and plants have become even greater as you learn many new things.  Your understanding of how the natural ecosystem all fits together have grown over the year.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: Nature +20.  More perks will arrive as the story progresses.)
				
			*set nature +20
			*goto After_Legacy_Advantage_7
		#Your knowledge of religion has grown. 
			Your knowledge of the gods and goddesses have become even greater as you learn many new things.  Your knowledge of religious practices and rituals have grown over the year.
			*if (showstats)
				*line_break
				(Legacy Advantage #7: Religion +20.  More perks will arrive as the story progresses.)
				
			*set religion +20
			*goto After_Legacy_Advantage_7
	
	*label After_Legacy_Advantage_7
	With the message delivered, ${legacy_heshe} fades away.
	*comment - - end of (using_legacy)
	*if (academy_stay="student")
		*if (class_wizard=1)
			Although your studies were coming along nicely, you know that it could still take years before you graduate from the Academy.
		*if (class_wizard>=2)
			You feel that you are ready to take the final tests for graduation.  Thanks to what you had learned before coming to the Academy, you are much further advanced than other students your age.  The exit tests go quite well and you are given your robes showing that you are a graduate from the Academy.  The magical garments are bright blue and covered with yellow stars and moons.
			*if (showstats)
				(Gained Academy Graduate Robes and Magic +2)
			*set academy_robes true
			*set magic +2
	
	*goto The_idea_that
After a year of hiding,
*if (academy_stay="student")
	*if (class_wizard=1)
		you feel that you have only just begun your studies and know that it would be impossible to graduate from the Academy with haste.  It is time to rescue ${prisoner1_name} and ${prisoner2_name}.
	*if (class_wizard>=2)
		you feel that you are ready to take the final tests for graduation.  Thanks to what you had learned before coming to the Academy, you are much further advanced than other students your age.  The exit tests go quite well and you are given your robes showing that you are a graduate from the Academy.  The magical garments are bright blue and covered with yellow stars and moons.
		*if (showstats)
			(Gained Academy Graduate Robes and Magic +2)
		*set academy_robes true
		*set magic +2
		
		It is time to rescue ${prisoner1_name} and ${prisoner2_name}.
		*set academy_stay "graduate"
	*goto The_idea_that
*else
	you know that it's time to rescue ${prisoner1_name} and ${prisoner2_name}.
	*goto The_idea_that
*label The_idea_that
*if (prisoner1_lover)
	The idea that Selina has held your precious ${prisoner1_name} in her dungeon for nearly a year is very difficult for you to stomach.
*if (prisoner2_lover)
	The idea that Selina has held your precious ${prisoner2_name} in her dungeon for nearly a year is very difficult for you to stomach.
You hope that the time away has lowered Selina's guard and will allow you to break them out of her dungeon with less risk.  ${friend1_name} agrees, and you decide to set out in hopes of rescuing your companions.
*if (questdetails="the Academy of Wizards")
	You pack up your belongings and head toward Brightwater, which is also in the duchy of Dumain.  The beautiful city on the Silver Sea where Selina now rules is only a few days away from the Academy.
*if (questdetails!="the Academy of Wizards")
	You pack up your belongings and head east into the duchy of Dumain to Brightwater, the beautiful city on the Silver Sea where Selina now rules.	
*if (friend2_name!="None")
	It will be good to see ${friend2_name} again after a year's absence.
	*if (friend2_lover)
		You wonder if ${friend2_heshe} still has the same feelings for you.
*if (friend1_disarmed)
	${friend1_name} buys a new weapon to replace the one ${friend1_heshe} lost.
*if (mount_name!="None")
	Your ${mount_type}, ${mount_name}, is happy to be moving
	*if (companion_name!="None")
		again as ${companion_name} ${companion_travels}.
	*if (companion_name="None")
		again.
*if (mount_name="None")
	*if (companion_name!="None")
		${companion_name} seems happy to be moving as ${companion_heshe} ${companion_travels}.
*set friend1_disarmed false
*goto Dobbton

*label Dobbton
*gosub ResetAdventure

After a few days of travel, you and ${friend1_name} find yourselves approaching a small village named Dobbton in the heart of what used to be the Kingdom of Daria.
*if (vampire)
	The bright sun overhead makes your skin feel itchy and forces you to squint.  You have heard that a true vampire can't stand the touch of the sun.  Although it makes you uncomfortable, it doesn't hurt.  Perhaps that means that you did not contract the vampire's disease.
It looks much like every other small town you have ever seen.
*choice
	#Continue on your way.
		*goto Dobbton_streets
	#Visit the shops along the main street.
		The small town has most of the things you may need.  Weapon smiths, armourers, temples…you even find a beggar willing to sell you tools of a less-legal nature.
		*set store_scene "exile_dobbton"
		*goto_scene store
		*label exile_dobbton
		*set store_scene "None"
		*goto Dobbton_streets
*label Dobbton_streets
As you walk through Dobbton, you notice that the streets appear quite empty.  Considering that it's harvest season in the middle of the day, this doesn't seem too strange, at first.  You glance toward the fields on the edge of town and see something very alarming.

Creatures ranging in height from one to three feet are shuffling around through the farmer's fields. You think that they must be the farmer's children at first, until you notice their black leathery skin. The field is infested with demons!  There are perhaps a dozen of them walking among the cornstalks.  You notice that they are haphazardly collecting the cobs of corn and walking them individually to a wagon in the centre of the field.  You and ${friend1_name} suddenly hear shouting coming from the inn.
*label Dobbton_loop
*choice
	*if (sword) #Draw your sword and rush in.
		With your sword held high and ${friend1_name} right behind you, you burst into the common room.
		*goto Dobbton_AggressiveEntrance
	*if (dagger) #Draw your dagger and rush in.
		With your dagger in hand and ${friend1_name} right behind you, you burst into the common room.
		*goto Dobbton_AggressiveEntrance
	*if (bow) #Put an arrow on your string and rush in.
		With your bow drawn and ${friend1_name} right behind you, you burst into the common room.
		*goto Dobbton_AggressiveEntrance
	#Cast a shielding spell over yourself and then enter.
		*if (magic<50)
			Despite your best incantation, the spell flickers and goes out.
			(Needed 50 Magic)
			*goto Dobbton_loop
		*else
			A shimmering blue sparkle twinkles all over your body as you step into the common room.
			*goto Dobbton_Bar
	#Throw open the door and rush in.
		*goto Dobbton_AggressiveEntrance
	#Motion for ${friend1_name} to lead the way in.
		*if (friend1_name=theothea_name)
			The large mountain${theothea_manwoman} draws ${theothea_hisher} hammer and steps forward.
		*if (friend1_name=jacejess_name)
			The Soulburner's eyes flash white for a moment as ${jacejess_heshe} activates ${jacejess_hisher} magic before stepping forward.
		*if (friend1_name=karlkarla_name)
			${karlkarla_name} places an arrow onto ${karlkarla_hisher} bowstring before stepping forward.
		*if (friend1_name=peterpetra_name)
			The holy warrior draws ${peterpetra_hisher} morningstar and shield before stepping forward.
		*if (friend1_name=gillgale_name)
			The thief draws ${gillgale_hisher} swords, one in each hand, before stepping forward.
		*goto Dobbton_AggressiveEntrance
	#Enter the bar calmly.
		*goto Dobbton_Bar

*label Dobbton_AggressiveEntrance
All eyes turn to you and ${friend1_name} as you burst in.  You see a fat man with his finger pressed against the chest of a thin man.  Judging from the white apron, you guess that the fat man is the bartender or owner of the establishment.  Upon seeing that you aren't going to attack them, they resume their argument.
*goto Dobbton_Bar2

*label Dobbton_Bar
You see a very angry fat man yelling at a dishevelled thin man, jamming his pudgy finger into the other's chest as he speaks.  Judging from the white apron, you guess that the man yelling is the bartender or owner of the establishment.

It's clear that they are having a disagreement, but based on the passive faces of everyone else in the room, you determine that nobody is fearing for their lives.  The two men continue their discussion, ignoring your presence.
*label Dobbton_Bar2

"I'm good for it!" the thin man says.  "Give me a second chance."

"Your bar tab was big enough before you chopped down my cellar door and emptied a barrel of mead, you lout!"

A bystander leans toward you, upon seeing your confused expression, and explains the situation.

"Sherman here," he says, indicating the thin man, "he's had a rough go lately.  One of his farmhands summoned a demon too big for him this spring.  It ate the farmhand on the spot.  So, Sherman didn't get his field fully planted and didn't make enough money to pay his bar tab.  So, he goes to Bill here, the owner of the Blue Crab, and offers to chop wood to clear the debt.  But the demon Sherman conjured to cut the wood was too strong for him.  Next thing you know, the demon has Sherman chopping down the cellar door and drinking up Bill's mead."

"The demon drank first!" Sherman argued.  "But they can't get drunk, so it forced me to drink.  I couldn't have drunk a full barrel all by myself!  I'll chop the rest of the wood and a bit more to pay for some of the missing mead."
*label Dobbton_Bar3
*choice
	#Say, "What's with all of the demon summoning?"
		"You been hiding under a log?  Ever since the dukes agreed to legalize summoning and the Consortium sent out free Demonstones, everyone and their brother have been using demon labour."
		
		You realize another thing that had struck you as odd.  The bar was filled with people and it was only early afternoon.  Normally, these people would be working the fields and doing other daily tasks.  The demons in the field suddenly made even more sense.
		*if (showstats)
			*line_break
			(Perception +2)
		*set perception +2
		*goto Dobbton_Bar3
	#Say, "Sherman's right.  If he didn't drink it, he shouldn't pay for all of it."
		*label ShermanRight
		Sherman nods vigorously at your words.
		
		"Fine then, just do the work you owe me, including the portion you drank," Bill says, attempting to get at least some payment out of the situation.
		*set sided_sherman_bill "Sherman"
		*goto Dobbton_Bar4
	#Say, "Bill's right.  It was Sherman's incompetent demon summoning that caused the creature to waste the mead."
		*label BillRight
		"Exactly!" Bill says.  "I don't care if you drank it, fed it to your dog or bathed in it.  You lost me the value of the mead, so you owe me!"
		
		"Fine then, I'll pay for your damn mead," Sherman mumbles angrily.
		*set sided_sherman_bill "Bill"
		*goto Dobbton_Bar4
	#Yell, "There are demons in the field as we speak!  Get your swords, quickly!"
		The townspeople laugh out loud at your words and make no move to follow your suggestions or to even look out the door.
		
		"It's not an invasion then," ${friend1_name} says.  "Looks like the Consortium's Demonstones and removal of the summoning ban has reached across the four duchies."
		*goto Dobbton_Bar3
	#Say nothing.
		You say nothing as Bill and Sherman continue to argue over who should pay for the mead that the demon drank.  It's clear that they aren't going to come to an agreement on their own.
		*choice
			#Say, "Sherman's right.  If he didn't drink it, he shouldn't pay for all of it."
				*goto ShermanRight
			#Say, "Bill's right.  It was Sherman's incompetent demon summoning that caused the creature to waste the mead."
				*goto BillRight
			#Say nothing and leave.
				You leave the bickering men and the tavern behind.  Nobody even notices the passing of two strangers.
				*set sherman_exists false
				*goto Leave_Dobbton_ns

*label Dobbton_Bar4

You watch as Sherman walks out of the bar and around the back.  Several of the townspeople follow him, as though they are curious to see what will happen.  A large tangle of logs and lumber has been piled nearby.  Instead of picking up the axe and getting to work, Sherman pulls a small Demonstone out of his pocket.  He looks tired and defeated before he even begins.  The townspeople watch him with a morbid eagerness as he prepares himself to summon the demon to chop the wood.
*choice
	#Stop him, saying, "Sherman, your will is not up to the task."
		He looks over to you and says, "I'm exhausted, but I have to try.  It needs to be a big demon since a smaller one won't be able to do the work."
		*if (showstats)
			*line_break
			(Good +2)
		*set good +2
		*label StoppingSherman_loop
		*choice
			#Say, "Don't use a demon then.  Cut the wood yourself."
				*if (charm>=50)
					"You're probably right.  It will take a few weeks to get it all done, but if I lose control of the demon again, it would likely get me into more trouble.  Thank you for your wisdom, stranger."
					
					You watch as Sherman puts away the Demonstone and picks up the axe himself.  He gives a weary sigh before starting work.  The townspeople, sad that they won't be seeing a humiliating summoning failure, return to the common room of the inn.
					*if (showstats)
						*line_break
						(Charm +2)
					*set charm +2
					*set sherman_exists true
					*goto Leave_Dobbton
				*else
					"Why would I do that?" Sherman says.  "I have magic now.  I can just summon a creature to do the work for me."
					*if (showstats)
						(Needed 50 Charm)
					*goto StoppingSherman_loop
			*if (demonsummoner) #Say, "Allow me to summon the demon for you."
				The watching townspeople open their eyes in surprise at your strange offer.  Sherman, realizing that he has nothing to lose, hands you the Demonstone and tells you the demon's true name.  You hold the stone and concentrate.   It glows briefly, and suddenly a short, squat demon with thick arms appears in front of you.  You say the demon's true name and immediately feel the contest of wills begin.
				*if (willpower>=50)
					Your skill quickly overpowers the demon as you bend its will to your own.
					*if (showstats)
						*line_break
						(Good +5)
					*set good +5
					
					"Command me, ${mastermistress}," the demon says.
					
					"Cut and stack wood where this man tells you.  When the task is complete, return to where you came from."
					
					The demon gets to work immediately.  It doesn't seem very intelligent or fast.  It wouldn't be much good in combat, but for general labour, it would get the task done.
					
					"Thank you," Sherman says.  "I could have done it after a little rest.  You saved me the risk, and for that, I am thankful."
					
					The townspeople, sad that they won't be seeing a humiliating summoning failure, return to the common room of the inn along with Sherman.
					*set sherman_exists true
					*goto Leave_Dobbton
				*else
					You feel the demon's mind overcome your own and remember no more.
					*if (showstats)
						(Needed 50 Willpower)
						*line_break
						(Good +5)
					*set good +5
					*page_break Darkness
					When you finally come to your senses, it is dark out and you feel terrible.  The smell of vomit is everywhere and you are lying on a wooden floor.  Slowly, you sit up and see ${friend1_name} perching on a bed and looking at you with disgust.
					
					"You lost control of it," ${friend1_name} says, stating the obvious.  "It marched you straight back to the tavern's cellar with the axe in your hand.  I reasoned with it and made a deal.  Instead of chopping down the door and drinking in the cellar, the demon allowed you to drink the ale in the common room without damaging anything besides your liver.  When you finally passed out, the demon returned to its own realm."
					
					*if (gold<50)
						*if (gold<=0)
							"You owe me some gold."
						*if (gold>0)
							"You owe me some gold.  Your own funds ran out early."
							*if (showstats)
								*line_break
								(Gold -${gold})
						*set gold 0
					*if (gold>=50)
						"Bill was happy to sell you the ale and charge you for the room."
						*if (showstats)
							*line_break
							(Gold -50)
						*set gold -50
					
					It takes the entire day for you to recover from the monstrous hangover and leave Dobbton behind.  You see Sherman chopping the wood by hand as you exit the tavern, having learned from your mistake.
					*set sherman_exists true
					*goto Leave_Dobbton
			*allow_reuse #Say, "Let us chop the wood with you."
				You realize that it would take a few days to do the work, which would mean you'd need to rent a room in the inn and pay for your meals while you stayed there.
				*choice
					*selectable_if (gold>=15) #Get a room and start chopping wood. (Needs 15 Gold)
						You count out the money needed to spend a few days in Dobbton.
						*if (showstats)
							*line_break
							(Gold -15)
						*set gold -15
						*goto Dobbton_ChoppingTime
					*allow_reuse #Consider an alternative.
						*goto StoppingSherman_loop

				*label Dobbton_ChoppingTime
				
				*if (friend1_name=theothea_name)
					${theothea_name} spits into ${theothea_hisher} hands and eagerly grabs the axe.  $!{theothea_heshe} has split several logs before you even have a chance to join in.
					
					"Good workout," the large ${theothea_manwoman} says with a grin.  "We'll have this done in no time."
					*if (showstats)
						*line_break
						(${theothea_name} Relationship +5)
					*set theothea_relationship +5
					*label Dobbton_HelpedChopping
					
					The townspeople, sad that they wouldn't be seeing a humiliating summoning failure, return to the common room of the inn.  With the three of you working, the large pile of wood is dealt with much more quickly.  Sherman is very happy to get his bar tab cleared and Bill is happy to have his money.  The job itself only takes a couple of days to finish.  Sherman happily waves to you as you leave the town.
					*if (showstats)
						*line_break
						(Good +5 and Strength +2)
					*set strength +2
					*set good +5
					*set sherman_exists true
					*goto Leave_Dobbton
				*if (friend1_name=jacejess_name)
					"Seriously?" ${jacejess_name} says as ${jacejess_heshe} rolls ${jacejess_hisher} eyes.
					*if (showstats)
						*line_break
						(${jacejess_name} Relationship -5)
					*set jacejess_relationship -5
					*goto Dobbton_HelpedChopping
				*if (friend1_name=karlkarla_name)
					"Reminds me of doing chores back home," ${karlkarla_name} says with a shrug as ${karlkarla_heshe} grabs the axe.
					*if (showstats)
						*line_break
						(${karlkarla_name} Relationship +2)
					*set karlkarla_relationship +2
					*goto Dobbton_HelpedChopping
				*if (friend1_name=peterpetra_name)
					"Yes, this is the right thing to do," ${peterpetra_name} says as ${peterpetra_heshe} steps forward.  "That vile magic should be avoided at all costs.  We shall help."
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship +5)
					*set peterpetra_relationship +5
					*goto Dobbton_HelpedChopping
				*comment (friend1_name=gillgale_name)
				"Ugh," ${gillgale_name} says with a groan.  "I became a thief so I could avoid these kinds of jobs."
				*if (showstats)
					*line_break
					(${gillgale_name} Relationship -3)
				*set gillgale_relationship -3
				*goto Dobbton_HelpedChopping
			*if (sided_sherman_bill="Bill")
				*selectable_if (gold>=80) #Say, "Let me pay your tab instead." (Needs 80 Gold)
					"Really?  You'd do that for me?  Thank you so much!  I just need a little rest, then I'll get myself back on my feet.  Thank you!"
					*if (showstats)
						*line_break
						(Gold -80)
					*set gold -80
					*goto Dobbton_Paybill
			*if (sided_sherman_bill="Sherman")
				*selectable_if (gold>=60) #Say, "Let me pay your tab instead." (Needs 60 Gold)
					"Really?  You'd do that for me?  Thank you so much!  I just need a little rest, then I'll get myself back on my feet.  Thank you!"
					*if (showstats)
						*line_break
						(Gold -60)
					*set gold -60
					*label Dobbton_Paybill
					
					The townspeople, sad that they won't be seeing a humiliating summoning failure, return to the common room of the inn along with Sherman.  You can hear Bill's happy shout of surprise as the tab is paid in full.
					*if (showstats)
						*line_break
						(Good +5)
					*set good +5
					*set sherman_exists true
					*goto Leave_Dobbton
			#Say nothing more as he attempts to summon the demon.
				*goto ShermanTries
	#Say nothing, knowing that he will likely fail.
		Like the rest of the townsfolk, you watch as he prepares to summon a demon that is clearly out of his ability to control.
		*if (showstats)
			*line_break
			(Evil +2)
		*set good -2
		
		*label ShermanTries
		*set sherman_exists false
		Sherman holds the Demonstone tightly in his hands as he concentrates upon it.  It glows briefly, and suddenly a short squat demon with thick, muscular arms appears in front of him.  Sherman says the demon's true name from memory.  You watch as beads of sweat appear on the man's forehead as he mentally battles the creature.  The loss is apparent as Sherman's face goes slack.  The demon laughs and starts whispering to the man.  Sherman picks up the axe and begins to walk toward the newly repaired cellar door, clearly intending to chop it down and get back into the ale stores.  The onlookers laugh uproariously at the impending debacle.
		*label Dobbton_ShermanTries_loop
		*choice
			#Laugh and watch the action.
				*set dobbton_disapproval false
				*label Dobbton_PoorBill
				By the third swing of the axe, Bill rushes outside and begins to plead with the possessed man.  All of his arguments are futile as the demon tells Sherman to continue to chop.  Bill steps in front of the door to protect his livelihood.  The demon frowns for a moment and then gives a startling command.  The axe falls on Bill instead of the door, and the innkeeper is hacked to pieces before anyone can react.  The villagers draw their swords and slay the demon, but it is too late for poor Bill.  You watch as Sherman slowly comes to his senses and learns what he has been forced to do.  There is nothing left for you in Dobbton.
				*if (dobbton_disapproval=false)
					*if (showstats)
						*line_break
						(Evil +5)
					*set good -5
				*set sherman_exists false
				*goto Leave_Dobbton
			#Silently watch the action in disapproval.
				*set dobbton_disapproval true
				*goto Dobbton_PoorBill
			#Bludgeon the demon into submission with your fists.
				*goto Dobbton_killdemon
			#Blast the demon with a bolt of electricity.
				The demon gives you all the time in the world to complete your spell.
				*goto Dobbton_killdemon
			*if (sword) #Hack down the demon with your sword.
				*goto Dobbton_killdemon
			*if (bow) #Fire an arrow into the demon.
				*goto Dobbton_killdemon
			*if (dagger) #Stab the demon in the neck with your dagger.
				*label Dobbton_killdemon
				The strong-armed demon is so slow that it can't stop you from destroying its corporeal being and returning its essence back to the demon realm.  You see that the creature would be terrible in combat and is only suitable for physical labour.  Sherman awakes and looks around dumbly as the villagers groan in disappointment.  They leave the scene as they realize that Sherman won't be making a fool of himself after all.
				
				"Thanks," he says after he learns what had nearly happened.  "I guess I'll chop that wood by hand after all."
				*if (showstats)
					*line_break
					(Good +3)
				*set good +3
				*set sherman_exists true
				*goto Leave_Dobbton


*label Leave_Dobbton

*label Leave_Dobbton_ns
You leave the tiny town and continue on your way.  Your parents had always been against demon summoning, but since the ban was lifted a year ago and the Consortium has supplied the populace with Demonstones, it seems like the practice has really taken hold among the common people.  This inevitably forces you to wonder:  Why did Alexander Zusak want this?  What is he getting out of such misery?  You realize that this small scene from the four duchies is happening across the entire land; work not getting done, demons running wild and commoners possessed into doing heinous acts.  Zusak's changes are destroying the realm.  Something must be done before all is lost.
*if (class_squire>0)
	
	As you approach the Silver Sea, you hear news of a knightly tournament.  It will be occurring in the town of Opal Cove, just a few days away from Brightwater.  Your skills have greatly improved over the past year.  If you were to enter the tournament, not only might you win a few of the events, but you would have a chance to gain your knighthood itself.
	
	"A week's delay won't change anything.  You should go," ${friend1_name} urges.
	*choice
		#Go to Opal Cove and try to win the knight's tournament.
			*set knight_went_to_tourney true
			The tournament will be difficult, since squires from all four duchies will be present, yet only one can win and become knighted.  A few days later finds you entering the small town.   Many tents and flags are spread across the surrounding fields as knights and squires from across the land gather for the tournament.  You recognize several of the banners since many knights spend their entire lives travelling from one tournament to the next.  Sir Maxson, the mentor whom Sir Grady had you squire under, was not present.
			
			"Hello, welcome to the Opal Cove tourney…name?"
			
			The registration process takes a few minutes as you fill in the paperwork.  One of the requirements is a list of deeds.  Only good, honest and moral squires who have conducted themselves within the knight's code of honour may participate, since the winner will be knighted.
			*if (good>=70)
				You are surprised to find that your record is full of comments from observers whom you didn't even notice, all attesting to the fact that you are a good person.
				*goto After_Good_Check
			*if (good>=50)
				Your record is relatively thin, but there are a few comments from observers whom you didn't even notice, and they are mostly positive.  This is enough to get you in.
				*goto After_Good_Check
			You are a little nervous about this part.  You have not been following the code.  You are surprised when you are accepted anyway.  Whomever has been observing you must have been fooled by your outward appearances.
			*label After_Good_Check
			The observations all come from your time in Elmvale and during your adventuring before Vernex.  Your time in exile is an empty space in your list of deeds, but squires often disappear for lengths of time during personal quests to show valour.
			
			The schedule of events shows that you will be competing in two preliminary contests that will lead into a grand melee at the end of the tournament, the winner of which will gain knighthood.  But first, a registration fee must be paid.
			*label Knight_Fee_loop
			*choice
				*selectable_if (gold>=50) #Pay the 50 gold entrance fee. (Needs 50 Gold)
					You count out the coins and hand them to the man.
					*if (showstats)
						*line_break
						(Gold -50)
					*set gold -50
					*goto KnightQuest_2
				#Ask to borrow the money from ${friend1_name}.
					*gosub Friend1_getrelationship
					*if (temp_relationship<65)
						"Sorry, I'm low on funds," ${friend1_name} says.
						*if (showstats)
							(Needed 65 ${friend1_name} Relationship)
						*goto Knight_Fee_loop
					*if ((friend1_name=theothea_name) or (friend1_name=gillgale_name))
						"The great Knight of Rags begins ${mc_hisher} saga," ${friend1_heshe} quips as ${friend1_heshe} pays your entrance fee.
						*goto KnightQuest_2
					"Of course," ${friend1_name} says as ${friend1_heshe} pays your entrance fee.
					*goto KnightQuest_2
				#Refuse to pay and continue on to Brightwater.
					Without paying the entry fee, you are not allowed to compete.  You continue on to Brightwater as the tournament proceeds without you.
					*goto After_Knightquest

			*label KnightQuest_2
			
			You are given a tent to use, as a part of your entrance package.  Many small shops and smithies have been erected nearby as the knights and squires prepare their gear for the various contests.  You see that most of the squires own their own horses, swords and bows.
			*choice
				#Visit the stores.
					The small stalls and shops are eager to sell you anything which you may require.
					*set store_scene "exile_knightstore"
					*goto_scene store
					*label exile_knightstore
					*set store_scene "None"
					*goto KnightQuest_3_ns
				#Don't visit the stores.
					*goto KnightQuest_3_ns
			
			*label KnightQuest_3_ns
			Your first event is in archery.
			*if (infinity_arrow)
				
				"Would you like to use the Infinity Arrow?" ${friend1_name} asks.  "It wouldn't be cheating.  The greatest knights often use legendary equipment to mark their places in the world."
				
				It would be a great boon, but the arrow could only be used once.
				*choice
					#Use the Infinity Arrow.
						You wait until the timing is just right before using the legendary artifact.  You stand back at a nearly impossible distance and when you fire the arrow, it hits the target perfectly in the centre.  The crowd cheers wildly at the spectacle.
						*set infinity_arrow false
						*set knight_archery 3
						*goto KnightQuest_AfterKarlKarla
					#Save the Infinity Arrow for another day.
						${friend1_name} nods in agreement as ${friend1_heshe} puts the arrow away again.
						*goto KnightQuest_KeepShooting
			*label KnightQuest_KeepShooting
			*if (gloves_archery)
				The audience is in awe of your Gloves of Archery.  Many great knights have legendary artifacts to aid them, and with your gloves, you score very well in the archery
				*if (bow)
					event.
					*set knight_archery 3
					*goto KnightQuest_AfterArrow
				*else
					event, despite the fact that you have to borrow a practice bow.
					*set knight_archery 2
					*goto KnightQuest_AfterArrow
			*if (archery<25)
				You were never a great
				*if (bow=false)
					archer and the fact that you had to borrow one of the practice bows didn't help at all.
					*set knight_archery 0
				*if (bow)
					archer, but at least you owned your own bow.
					*set knight_archery 1
				*if (showstats)
					(Needed 25 Archery)
			*if (archery>=25) and (archery<45)
				You were a decent
				*if (bow=false)
					archer, but the fact that you had to borrow one of the practice bows made things a little difficult.
					*set knight_archery 1
				*if (bow)
					archer and held your own in the competition.
					*set knight_archery 2
				*if (showstats)
					(Needed 45 Archery)
			*if (archery>=45)
				You were a great
				*if (bow=false)
					archer, but the fact that you had to borrow one of the practice bows made things a little difficult.
					*set knight_archery 2
				*if (bow)
					archer and it showed.
					*set knight_archery 3
			*goto KnightQuest_AfterArrow
			
			*label KnightQuest_AfterArrow
			*if (friend1_name=karlkarla_name)
				
				You are glad to have ${friend1_name} at your side for the remainder of the event.
				*if (knight_archery=0)
					You would have failed miserably without ${karlkarla_himher}, but with ${karlkarla_hisher} aid, you manage to hit a couple of targets.
					*set knight_archery 1
					*goto KnightQuest_AfterKarlKarla
				*if (knight_archery=3)
					Your skills with the bow are good enough on their own, but with ${karlkarla_name}'s advice, your victory is assured.
					*goto KnightQuest_AfterKarlKarla
				The advice ${karlkarla_heshe} gives you helps you score a few targets that you may not have gotten on your own.
				*set knight_archery +1
				*goto KnightQuest_AfterKarlKarla
			*else
				*goto KnightQuest_AfterKarlKarla
				
			*label KnightQuest_AfterKarlKarla
			
			*if (knight_archery>3)
				*set knight_archery 3
			*set knight_total knight_archery
			*if (knight_archery=3)
				"Congratulations to Squire ${name}, squire to Sir Maxson," the herald proclaims.  "Winner of the Archery Competition."
				
				This gives you 3 points and places you in the lead.
				*goto KnightQuest_Jousting
			"Congratulations to Squire Artemis, squire to Sir Ryerson," the herald proclaims.  "Winner of the Archery Competition."
			
			*if (knight_archery=2)
				You did very well in the contest, giving you 2 points and placing you near the top of the leaderboard.
				*goto KnightQuest_Jousting
			*if (knight_archery=1)
				You didn't do very well in the contest, but at least you managed to get 1 point, which places you slightly above the bottom of the leaderboard.
				*goto KnightQuest_Jousting
			You were a disgrace in the contest, scoring 0 points and placing at the bottom of the leaderboard.
			*goto KnightQuest_Jousting

			*label KnightQuest_Jousting
			
			The days continue and you soon find yourself in the jousting competition.
			*if ((mount_type="mule") or (mount_name="None"))
				*set knight_jousting 0
				Unfortunately, you don't own a horse of your own.
				*if (mount_type="mule")
					${friend1_name} jokes that you should use ${mount_name}.  Of course, mules aren't allowed, so you are forced to ride one of the tourney rentals, an old nag that can barely reach a full trot.
					*goto KnightQuest_Jousting_2
				The old nags they have for those who are unmounted are hardly fit for riding and can barely reach a full trot.
				*goto KnightQuest_Jousting_2
			*else
				You lead ${mount_name} into the
				*if (mount_desc="a poorly trained tournament")
					competition, hoping that ${mount_heshe} will fare better than the last time ${mount_heshe} competed.  To your delight, you see that the time ${mount_name} has been with you has served ${mount_himher} well.  $!{mount_hisher} training is complete and you are given many compliments on your fine mount.
					*set mount_level 5
					*set mount_desc "a well-trained tournament"
					*set knight_jousting 3
					*goto KnightQuest_Jousting_2
				*if (mount_level<3)
					competition, knowing that ${mount_heshe} will be hard pressed to keep up.
					*if (showstats)
						(Needed a Stronger Mount)
					*set knight_jousting 1
					*goto KnightQuest_Jousting_2
				*if (mount_level=4)
					competition, knowing that ${mount_heshe} will serve you well.
					*set knight_jousting 2
					*goto KnightQuest_Jousting_2
				*comment mount 5 or better
				competition, knowing that ${mount_hisher} superior stamina will make the competition much easier for you to win.
				*set knight_jousting 3
				*goto KnightQuest_Jousting_2
				
			*label KnightQuest_Jousting_2
			*choice
				#You rely on your mount's skill to carry you through the event.
					*goto KnightQuest_Jousting_3_ns
				*if (friend1_name=jacejess_name) #Ask ${friend1_name} to use ${friend1_hisher} Soulburning magic to help you.
					*if (jacejess_relationship>=70)
						"Very well," ${jacejess_name} says as ${jacejess_hisher} eyes glow white for a moment.
						
						You see that your mount is suddenly much stronger and faster than before.  This isn't considered cheating, since many squires have horses that are of unusual strength.  It would have been different had the magic drained your opponent's mount.
						*set knight_jousting +1
						*goto Knightquest_Jousting_2
					*else
						"I will not expend my lifeforce for a mere contest," ${jacejess_name} says angrily.
						*if (showstats)
							(Needed 70 ${jacejess_name} Relationship)
							*line_break
							(${jacejess_name} Relationship -2)
						*set jacejess_relationship -2
						*goto KnightQuest_Jousting_2
				#You rely on your own skill to carry you through the event.
					*if ((agility>=45) and (strength>=45))
						You are fast and you are strong.  You manage to knock a few more people off their mounts due to your high level of physicality.  You wait patiently for the results, hoping that it is enough to win.
						*set knight_jousting +1
						*goto KnightQuest_Jousting_3
					*else
						You aren't quite as fast or as strong as you had hoped.  It looks as though you will need to rely on your mount's skill after all.
						*if (showstats)
							(Needed 45 Agility and 45 Strength)
						*goto KnightQuest_Jousting_3

			*label KnightQuest_Jousting_3
			
			*label KnightQuest_Jousting_3_ns
			*if (knight_jousting>3)
				*set knight_jousting 3
			*set knight_total knight_total+knight_jousting
			*if (knight_jousting=3)
				"Congratulations to Squire ${name}, squire to Sir Maxson," the herald proclaims.  "Winner of the Jousting Competition."
				
				This gives you 3
				*if (knight_total=0)
					points and puts you onto the leaderboard.
					*goto KnightQuest_Melee
				more points, giving you a total of ${knight_total} points.
				*goto KnightQuest_Melee
			"Congratulations to Squire Benjamin, squire to Sir Richard," the herald proclaims.  "Winner of the Jousting Competition."
			
			*if (knight_jousting=0)
				This gives you 0 points.
				*if (knight_archery=3)
					Luckily you won the archery portion of the tournament and are invited to continue with your 3 points.
					*goto KnightQuest_Melee
				*else
					*label Knight_BigLoser
					*if (class_squire=2)
						*goto KnightQuest_Melee
					Unfortunately, between your lack of archery skills and your ineptness at jousting, you have no chance of winning the tournament and are not invited into the grand melee.  You continue on to Brightwater, destined to be a squire for the rest of your life.
					*goto After_Knightquest
			*if (knight_jousting=1)
				*if (knight_archery=0)
					This gives you a single point.
					*goto Knight_BigLoser
				*if (knight_archery=1)
					This gives you only 2 points.
					*goto Knight_BigLoser
			This gives you
			*if (knight_jousting=1)
				1 more point
			*if (knight_jousting=2)
				2 more points
			for a total of ${knight_total} points.
			*goto KnightQuest_Melee
				
			*label KnightQuest_Melee
			
			On the last day of the tourney,
			*if (knight_total=6)
				all eyes are on you as the winner of the last two events.
			*if ((knight_total=4) or (knight_total=5))
				many eyes are on you as a squire near the top of the leaderboard.
			*if (knight_total<4)
				you are still relatively
				*if (knight_archery=3)
					unknown, despite having won the Archery Competition.
				*if (knight_jousting=3)
					unknown, despite having won the Jousting Competition.
				*if ((knight_jousting!=3) and (knight_archery!=3))
					unknown.
			The grand melee is the big event whose winner will be knighted.
			*if (knight_total=0)
				With 0 points,
				*goto Bottom_LB
			*if (knight_total=1)
				With only 1 point,
				*goto Bottom_LB
			*if (knight_total=2)
				With only 2 points,
				*label Bottom_LB
				you are at the bottom of the leaderboard and will have to enter the arena first. This means that you will have to fight the most opponents and will have the greatest chance of being knocked out early and not winning the tournament.
			*if ((knight_total=3) or (knight_total=4))
				With ${knight_total} points, you will be able to watch the people at the bottom of the leaderboard enter the arena first.  After a certain number have been eliminated, you will enter it yourself.  This means that you will have to fight many opponents and will have a greater chance of being knocked out early and not winning the tournament.
			*if ((knight_total=5) or (knight_total=6))
				Since you are at the top of the leaderboard, you have the advantage of watching the other squires enter the arena first.  After many of them have been eliminated, you will then enter it yourself.  This will give you a great advantage in becoming the winner of the tournament.
			
			*if (knight_total=2)
				You enter the arena with the other lowest ranked contestants.
			*if (knight_total>2)
				The first eliminations occur rapidly and before you know it, you are sent into the arena.
			*if (sword=false)
				The grip on the sword you have borrowed for the event feels unfamiliar, causing you some hesitation in your strikes.
			*if (sword)
				You swing the sword mightily, knocking one poor squire into the sand and out of the tournament.
			You sidestep a mighty swing, which puts you off balance when a second squire
			*if ((blades<50) and (class_squire<2))
				strikes you across the ribs with their blade.  Luckily your armour prevents the blow from cutting you, but as the wind is knocked from your lungs, you feel a second strike across the back of the head which eliminates you from the tournament.  Your hopes of achieving knighthood during this event are over.  You pack up your belongings and continue on to Brightwater, destined to continue life as a squire.
				*if (showstats)
					(Needed 50 Blades or 2 Levels in Squire)
				*goto After_Knightquest
			*else
				swings their blade at you.  Your skill with the sword serves you well as you duck the blow and recover.  One by one, you see opponents fall to the ground.
				
				After some time, there is only yourself and two others left.
				*choice
					#Stand back and let them fight each other, then attack the one who is still standing.
						It's a sound strategy.  You keep your distance, and when one of them bests the other, you jump forward.  The battle is hard pressed, but in the end, your opponent falls to the ground!  You are victorious!
						*if (showstats)
							*line_break
							(Perception +5)
						*set perception +5
						*goto KnightQuest_Knighted
					#Attempt to fight both of them at once.
						The crowd roars its approval as you slash at one man and then at the other.  It is a close match, but when one of them slips in the sand, you are able to knock him on the top of the head with your sword.  The other man's blade swings toward you, but you get your sword up just in time to parry the blow.  After a few moments, you manage to best the second man as well.  You are victorious!
						*if (showstats)
							*line_break
							(Good +5)
						*set good +5
						*goto KnightQuest_Knighted
					#Drive an elbow into one of them while attacking the other with your sword.
						The crowd roars its approval as your elbow smashes into the man's face.  Such brutality and aggressiveness shows true passion and commitment.  Your sword knocks the other man out of the contest, and when you turn to deal with the one you hit with your elbow, you see that he is dazed enough to eliminate him quickly as well.  You are victorious!
						*if (showstats)
							*line_break
							(Unarmed +5)
						*set unarmed +5
						*goto KnightQuest_Knighted
					#Kick a foot full of sand up into your opponents' eyes.
						It's a dirty trick, but not illegal.  Some of the more conservative knights frown at your actions, but it is effective.  The men are both stunned for a minute, and as they blink the sand from their eyes, you are able to eliminate both of them.  You are victorious!
						*if (showstats)
							*line_break
							(Evil +5)
						*set good -5
						*goto KnightQuest_Knighted

			*label KnightQuest_Knighted
			
			"Congratulations to Squire ${name}!" the herald announces.
			
			The rest of the day is a blur as you are congratulated countless times.  The knighting ceremony takes place later that day.  You are dubbed Sir ${name}, knight of the realm!  Your duties are to protect the common man and right wrongs as you see fit.  You know that Sir Grady and Sir Maxson would be proud of you.
			*if (showstats)
				*line_break
				(Blades +3, Archery +3, Strength +3, Agility +3 and Endurance +3)
			*set blades +3
			*set archery +3
			*set strength +3
			*set agility +3
			*set endurance +3
			*set title "knight"
			*set class_knight 1
			*if (good<=45)
				
				In the midst of your congratulations, you begin to hear voices.  They whisper in the corners of your mind.  Over the course of the day, you begin to realize that they are real and that they are evil.  You have attracted the attention of dark forces.
				*if ((holysymbol) and (god_good))
					It is enough to make you wonder about praying to ${god_name}.  $!{god_heshe} has never given you such personal attention—perhaps it is time for a dark master?
					*choice
						#Convert to an evil deity.
							It's relatively easy to stop worshipping ${god_name}. You just have to discard the holy symbol.
							*if (showstats)
								*line_break
								(Lost Holy Symbol)
							*set holysymbol false
							*set had_one true
							*label Get_Evil_God
							
							*label Get_Evil_God_ns
							The moment you decide to listen to the voices, something wickedly profane hears you.  A man selling cobs of corn at the tournament approaches you, having heard dark voices of his own.  He welcomes you to the fold and gives you a
							*if (had_one)
								new
							holy symbol.  He explains that lying to hide your true nature is expected.  As such, the holy symbol looks to be devoted to the good Gods and Goddesses to the untrained eye, but in actuality, it is devoted to the embodiment of all that is evil in the world.  Darkness, shadows, disease, corruption, deceit…the list could go on for hours.  In addition to these things, your deity encourages wealth, power and domination over other creatures: living and dead.
							*if (holysymbol=false)
								*if (showstats)
									*line_break
									(Gained Holy Symbol)
								*set holysymbol true
							*set god_good false
							*choice
								#You follow Noct, an evil and cruel God.
									*set god_name "Noct"
									*set god_goddess "God"
									*set god_hisher "His"
									*set god_himher "Him"
									*set god_heshe "He"
									*goto Get_Evil_God_2
								#You follow Shadi, an evil and cruel Goddess.
									*set god_name "Shadi"
									*set god_goddess "Goddess"
									*set god_hisher "Her"
									*set god_himher "Her"
									*set god_heshe "She"
									*goto Get_Evil_God_2
								#You follow a different God.
									*label Name_God_Evil_2
									*input_text god_name
									*if ((god_name="the Unknown") or (god_name="None"))
										Your God has to have a name.
										*goto Name_God_Evil_2
									*set god_goddess "God"
									*set god_hisher "His"
									*set god_himher "Him"
									*set god_heshe "He"
									*goto Get_Evil_God_2
								#You follow a different Goddess.
									*label Name_Goddess_Evil_2
									*input_text god_name
									*if ((god_name="the Unknown") or (god_name="None"))
										Your Goddess has to have a name.
										*goto Name_Goddess_Evil_2
									*set god_goddess "Goddess"
									*set god_hisher "Her"
									*set god_himher "Her"
									*set god_heshe "She"
									*goto Get_Evil_God_2
							*label Get_Evil_God_2
							The dark voices continue to speak to you, urging you to new levels of depravity with promises of great power.  Now, you know who the voices belong to.  It makes you wonder what ${god_name} has planned for you.
							*goto After_Dark_Thoughts
						#Pray harder so the voices go away.
							*comment has holysymbol and good god
							Eventually, they do.  ${god_name} is not weak and does not give up ${god_hisher} followers lightly.
							*goto After_Dark_Thoughts
				*if ((holysymbol) and (god_good=false))
					It is ${god_name}, your ${god_goddess}, and ${god_heshe} is proud of you.
					*goto Get_Evil_God_2
				*comment has no holysymbol
				*choice
					#Listen to the evil voices and do as they ask.
						*goto Get_Evil_God_ns
					#Ignore the evil voices and hope they go away.
						They eventually fade as you try hard to ignore them.
						*goto After_Dark_Thoughts
			*else
				*comment Not Evil
				*goto After_Dark_Thoughts

			*label After_Dark_Thoughts
			
			After the celebrations are concluded, you pack up your belongings and continue on to Brightwater.
			*if ((knight_archery>=3) and (knight_jousting>=3))
				As the champion of all three squire events, you are given a large trophy before you leave.  It is a golden statue of a fully armoured knight on a rearing stallion.  When you ask a fellow knight what you should do with it, he suggests that you melt the gold down and buy something nice with it.
				*if (showstats)
					*line_break
					(Gold +300)
				*set gold +300
			*if ((knight_archery>=3) and (knight_jousting<3))
				As the champion of the squires' Archery Competition, you are given a large trophy before you leave.  It is a golden statue of a man holding a bow.  When you ask a fellow knight what you should do with it, he suggests that you melt the gold down and buy something nice with it.
				*if (showstats)
					*line_break
					(Gold +200)
				*set gold +200
			*if ((knight_archery<3) and (knight_jousting>=3))
				As the champion of the squires' Jousting Competition, you are given a large trophy before you leave.  It is a golden statue of a man on a horse.  When you ask a fellow knight what you should do with it, he suggests that you melt the gold down and buy something nice with it.
				*if (showstats)
					*line_break
					(Gold +200)
				*set gold +200
			*goto After_Knightquest
		#Continue to Brightwater.
			You leave your dreams of knighthood behind and continue toward Brightwater.
			*goto After_Knightquest
*else
	*goto After_Knightquest
	
*label After_Knightquest
*gosub trial_end
*goto_scene brightwater

*comment ------------------------- Subroutines

*label ResetAdventure
*set theothea_injured false
*set jacejess_injured false
*set gillgale_injured false
*set peterpetra_injured false
*set karlkarla_injured false
*set branbrinn_injured false
*set friend1_injured false
*set friend2_injured false
*set friend3_injured false
*set friend4_injured false
*set health 100
*set companion_injured false
*set demonstone_kgirr_used false
*set demonstone_xiatta_used false
*set demonstone_zonch_used false
*set demonstone_brahl_used false
*set demonstone_tyborr_used false
*set demonstone_daanda_used false
*return

*label Friend1_getrelationship
*if (friend1_name=theothea_name)
	*set temp_relationship theothea_relationship
	*return
*if (friend1_name=karlkarla_name)
	*set temp_relationship karlkarla_relationship
	*return
*if (friend1_name=jacejess_name)
	*set temp_relationship jacejess_relationship
	*return
*if (friend1_name=gillgale_name)
	*set temp_relationship gillgale_relationship
	*return
*if (friend1_name=peterpetra_name)
	*set temp_relationship peterpetra_relationship
	*return
*set temp_relationship branbrinn_relationship
*return

*label Friend1_Increase
*if (friend1_name=theothea_name)
	*set theothea_relationship +friendinc
	*return
*if (friend1_name=karlkarla_name)
	*set karlkarla_relationship +friendinc
	*return
*if (friend1_name=jacejess_name)
	*set jacejess_relationship +friendinc
	*return
*if (friend1_name=peterpetra_name)
	*set peterpetra_relationship +friendinc
	*return
*else
	*comment GillGale only one left
	*set gillgale_relationship +friendinc
	*return

*label trial_end
*check_purchase adfree
*if choice_purchased_adfree or not(choice_purchase_supported)
	*label purchased
	*return
Remember earlier how we told you that the first two chapters are available for free? This is the end of the free content.

[i]To find out what happens next, please purchase the remaining chapters.[/i]

*purchase_discount adfree 2023-02-23 $5.99 $3.99 purchased
*abort
