*comment Copyright 2015 by Mike Walter
*comment The Lost Heir 2:  Forging a Kingdom
*comment Scene #3: brightwater.txt
*comment 19402 Words - 516 subroutines = 18.9 k
*hide_reuse
*temp dagger_used false
*set prisonchild_hisher mc_hisher
*set prisonchild_heshe mc_heshe
*set prisonchild_himher mc_himher
*if (mc_hisher="his")
	*set prisonchild_boygirl "boy"
*if (mc_hisher="her")
	*set prisonchild_boygirl "girl"
*temp breakout_metguards false
*temp breakout_foundthem false
*temp bunta_health 100
*temp bunta_dead false
*temp breakout_silenced_door false
*temp breakout_metpimp false
*temp breakout_disguiseworks false
*temp breakout_considereddisguise false
*temp breakout_usingdagger false
*temp breakout_tempfriend_name "None"
*temp temp_prisoner2_relationship 0
*gosub ResetAdventure
*page_break Onwards to Brightwater
The city of Brightwater is as marvellous as the stories say.  An assortment of narrow towers and precariously high bridges rise high over the coastal city.  The sparkling blue water to the east fills the air with a clean, salty smell and the cawing of sea birds joins the background sounds of the city.

Selina has chosen her duchy well.  Not only is the eastern part of the former Kingdom of Daria beautiful, the capital of the recently forged Dumain duchy has one of the most defensible keeps in the land.  The tall towers of the great Brightwater keep are even higher than the rest of the city, although you know that your destination is far beneath the walls, in the dark dungeons of the keep.  This is where ${prisoner1_name} and ${prisoner2_name} are being kept.

${friend1_name} leads you to an inn called the Siren, where you rent a room to plan the prison break.
*if (friend2_exists)
	*if (friend2_name=theothea_name)
		*set theothea_inparty true
	*if (friend2_name=gillgale_name)
		*set gillgale_inparty true
	*if (friend2_name=peterpetra_name)
		*set peterpetra_inparty true
	*if (friend2_name=karlkarla_name)
		*set karlkarla_inparty true
	*if (friend2_name=jacejess_name)
		*set jacejess_inparty true
	
	"${name}!" a familiar-sounding voice says, causing you to turn.
	
	You see ${friend2_name} coming toward you.
	*gosub Friend2_getrelationship
	*if (temp_relationship<50)
		$!{friend2_heshe} nods, acknowledging your presence.  Although the two of you aren't great friends, you can tell that ${friend2_heshe} is still glad to see you alive and well after a year apart.
		*if (friend2_lover)
			$!{friend2_hisher} detached attitude is enough to tell you that any budding romance from the year before is now firmly in the past.
			*if (showstats)
				(Needed 50 ${friend2_name} Relationship)
			*label Brightton_Breakup_Friend2
			*set friend2_lover false
			*set lover_exists false
			*set lover_name "None"
			*if (friend2_name=theothea_name)
				*set theothea_lover false
			*if (friend2_name=jacejess_name)
				*set jacejess_lover false
			*if (friend2_name=peterpetra_name)
				*set peterpetra_lover false
			*if (friend2_name=gillgale_name)
				*set gillgale_lover false
			*if (friend2_name=karlkarla_name)
				*set karlkarla_lover false
			
			*goto Breakout_friend2_back
		*else
			*goto Breakout_friend2_back
	*else
		*comment (temp_relationship>=50)
		$!{friend2_heshe} smiles at you and
		*if (friend2_lover)
			*if (friend2_heshe="he")
				gathers you into ${friend2_hisher} arms.
			*if (friend2_heshe="she")
				wraps ${friend2_hisher} arms around you.
			${friend2_name} kisses you soundly, very happy to see you safe and alive after a year apart.  So many things have changed since your budding romance.
			*choice
				#Kiss ${friend2_name} back.
					You share a tender moment together on the street as ${friend1_name} looks toward the sea with a barely hidden smile on ${friend1_hisher} face.  Real life intrudes upon your kiss as the sounds of the city break up your reunion.
					*if (showstats)
						*line_break
						(${friend2_name} +10)
					*set friendinc 10
					*gosub Friend2_Increase
					*set lover_exists true
					*set lover_name friend2_name
					*set lover_hisher friend2_hisher
					*set lover_himher friend2_himher
					*set lover_heshe friend2_heshe
					*goto Breakout_friend2_back
				#Step back coldly, showing ${friend2_himher} that the romance is over.
					You can see the hurt in ${friend2_hisher} eyes, but ${friend2_heshe} doesn't say anything about it.  A year apart is a long time and things have changed.
					*if (showstats)
						*line_break
						(${friend2_name} Relationship -10)
					*set friendinc 0
					*set friendinc -10
					*gosub Friend2_Increase
					*goto Brightton_Breakup_Friend2
		*else
			*if (friend2_heshe="he")
				gives you a friendly hug, clapping you on the back.
			*if (friend2_heshe="she")
				gives you a warm hug.
			*goto Breakout_friend2_back
	*label Breakout_friend2_back
	Together, the three of you
	*goto Breakout_IntoInn
*else
	The two of you
	*goto Breakout_IntoInn

*label Breakout_IntoInn
go up to your cramped room to discuss how you are going to free your companions.

*if (theothea_inparty)
	*if (friend2_exists)
		*rand coinflip 1 2
		*if (coinflip=1)
			*if ((friend1_name=gillgale_name) or (friend2_name=gillgale_name))
				*goto GillGale_Breakout_Banter
			*if ((friend1_name=peterpetra_name) or (friend2_name=peterpetra_name))
				*goto PeterPetra_Breakout_Banter
			*if ((friend1_name=karlkarla_name) or (friend2_name=karlkarla_name))
				*goto Karlkarla_Breakout_Banter
			*if ((friend1_name=jacejess_name) or (friend2_name=jacejess_name))
				*goto JaceJess_Breakout_Banter
	"We should just attack the dungeons," ${theothea_name} suggests.
	*choice
		#Say, "The dungeon will be filled with guards.  I think we'll need to sneak in."
			The big mountain-${theothea_manwoman} merely shrugs ${theothea_hisher} large shoulders.
			
			"More guards just means more fighting," ${theothea_heshe} says with a smile.
			*goto After_Breakout_Banter
		#Say, "The guards are just regular people.  It would be good if we could do this without any bloodshed."
			${theothea_name} rolls ${theothea_hisher} eyes at your words.  It's clear that the big mountain-${theothea_manwoman} would rather solve the problem with ${theothea_hisher} enormous hammer.
			*if (showstats)
				*line_break
				(${theothea_name} Relationship -2)
			*set theothea_relationship -2
			*goto After_Breakout_Banter
		#Say, "I'm sure you'll get a chance to break some bones."
			The big mountain-${theothea_manwoman} grins happily at the prospect of fighting.  $!{theothea_hisher} barbaric nature makes ${theothea_himher} a good fighter, but it also makes ${theothea_himher} a little violent at times.
			*if (showstats)
				*line_break
				(${theothea_name} Relationship +3)
			*set theothea_relationship +3
			*goto After_Breakout_Banter
		#Say, "That's ridiculous.  There'll be a team of guards.  We need a plan."
			${theothea_name} rolls ${theothea_hisher} eyes at your words.  It's clear that the big mountain-${theothea_manwoman} would rather solve the problem with ${theothea_hisher} enormous hammer.
			*if (showstats)
				*line_break
				(${theothea_name} Relationship -3)
			*set theothea_relationship -3
			*goto After_Breakout_Banter
*if (gillgale_inparty)
	*if (friend2_exists)
		*rand coinflip 1 2
		*if (coinflip=1)
			*if ((friend1_name=peterpetra_name) or (friend2_name=peterpetra_name))
				*goto PeterPetra_Breakout_Banter
			*if ((friend1_name=karlkarla_name) or (friend2_name=karlkarla_name))
				*goto Karlkarla_Breakout_Banter
			*if ((friend1_name=jacejess_name) or (friend2_name=jacejess_name))
				*goto JaceJess_Breakout_Banter
	*label GillGale_Breakout_Banter
	"They've been locked up for nearly a year," ${gillgale_name} says with a grin.  "Surely they can spend one more day in the dungeons while we check out the Brightwater taverns."
	*temp gillgale_pays false
	*choice
		*selectable_if (gold>=20) #Say, "You're right.  We need to take a break.  My treat!" (Needs 20 Gold)
			*label GillGale_Drinking
			${gillgale_name} smiles happily at your words.  Together,
			*if (friend2_exists)
				you, ${friend1_name} and ${friend2_name}
			*if (friend2_exists=false)
				you and ${gillgale_name}
			go downstairs into the common-room of the tavern.  After a few drinks, you feel much more relaxed.  ${gillgale_name} smiles happily as you drink and talk about the past year.
			*if (showstats)
				*line_break
				*if (gillgale_pays=false)
					*if (friend2_exists)
						(Gold -20, ${friend1_name} Relationship +3 and ${friend2_name} Relationship +3)
					*if (friend2_exists=false)
						(Gold -20 and ${friend1_name} Relationship +3)
					*set gold -20
				*if (gillgale_pays)
					*if (friend2_exists)
						(${friend1_name} Relationship +3 and ${friend2_name} Relationship +3)
					*if (friend2_exists=false)
						( ${friend1_name} Relationship +3)
			*set gillgale_relationship +3
			*if ((friend1_name=theothea_name) or (friend2_name=theothea_name))
				*set theothea_relationship +3
			*if ((friend1_name=peterpetra_name) or (friend2_name=peterpetra_name))
				*set peterpetra_relationship +3
			*if ((friend1_name=karlkarla_name) or (friend2_name=karlkarla_name))
				*set karlkarla_relationship +3
			*if ((friend1_name=jacejess_name) or (friend2_name=jacejess_name))
				*set jacejess_relationship +3
			*goto After_Breakout_Banter
		#Say, "You're right.  We need to take a break…but you're paying."
			*if (gillgale_relationship>=70)
				"Sure, why not?" ${gillgale_name} says with a smile.
				*set gillgale_pays true
				*goto GillGale_Drinking
			"On second thought, that's our friends trapped in that dungeon," ${gillgale_name} says.  "You're right, we should be trying to get them free."
			*if (showstats)
				(Needed 70 ${gillgale_name} Relationship)
				*line_break
				(${gillgale_name} Relationship -5)
			*set gillgale_relationship -5
			*goto After_Breakout_Banter
		#Say, "What if it was you, ${gillgale_name}?"
			"If it were me," ${gillgale_name} says,  "I'd say you had better not be drinking without me.  Okay,
			*label GillGale_PointMade
			point made.  We need to get ${prisoner1_name} and ${prisoner2_name} out as soon as we can."
			*if (showstats)
				*line_break
				(Good +3)
			*set good +3
			*goto After_Breakout_Banter
		#Say, "We can go tavern hopping after our friends are free."
			"That's why you're the ${princeprincess} and I'm just a lowly thief," ${gillgale_name} says with a mocking bow.  Okay,
			*goto GillGale_PointMade
		#Say, "Shame on you, ${gillgale_name}.  Our friends are locked up."
			"Sorry, ${name}," ${gillgale_name} says sheepishly.  "You're right, of course."
			*if (showstats)
				*line_break
				(${gillgale_name} Relationship -2 and Good +3)
			*set gillgale_relationship -2
			*set good +3
			*goto After_Breakout_Banter
*if (peterpetra_inparty)
	*if (friend2_exists)
		*rand coinflip 1 2
		*if (coinflip=1)
			*if ((friend1_name=karlkarla_name) or (friend2_name=karlkarla_name))
				*goto Karlkarla_Breakout_Banter
			*if ((friend1_name=jacejess_name) or (friend2_name=jacejess_name))
				*goto JaceJess_Breakout_Banter
	*label PeterPetra_Breakout_Banter
	"Before we get to work," ${peterpetra_name} says,  "I think we should say a prayer."
	*choice
		#Say, "That sounds like a good idea."
			${peterpetra_name} closes ${peterpetra_hisher} eyes and prays to ${peterpetra_hisher} God for aid in making a good plan to save ${prisoner1_name} and ${prisoner2_name}.  It starts out well, but then it begins to drag on.
			*choice
				#Let your holy friend take as long as ${peterpetra_heshe} needs.
					The prayer lasts for over an hour as ${peterpetra_name} goes from asking for help to thanking ${peterpetra_hisher} God for the help already received.  When it is over, ${peterpetra_heshe} seems more at peace.
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship +3 and Religion +3)
					*set peterpetra_relationship +3
					*set religion +3
					*goto After_Breakout_Banter
				#Impatiently clear your throat.
					${peterpetra_name} gives you a dark look and then finishes ${peterpetra_hisher} prayer hastily.
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship -3)
					*set peterpetra_relationship -3
					*goto After_Breakout_Banter
				#Say, "This is rubbish.  We have work to do."
					*goto PeterPetra_Rubbish
		#Say, "We don't have time for that."
			*label PeterPetra_Rubbish
			"You don't have time for the Gods and Goddesses?" ${peterpetra_name} begins.  "After all they have done for you in your life!  It is only through their divine grace that you have…"
			
			As your friend drones on and on about how wonderful ${peterpetra_hisher} deity is, you begin to wish that you had just let the prayer take place.  After nearly an hour of lecturing, ${peterpetra_heshe} finally stops scolding you.
			*if (showstats)
				*line_break
				(${peterpetra_name} Relationship -5)
			*set peterpetra_relationship -5
			*goto After_Breakout_Banter
*if (karlkarla_inparty)
	*if (friend2_exists)
		*rand coinflip 1 2
		*if (coinflip=1)
			*if ((friend1_name=jacejess_name) or (friend2_name=jacejess_name))
				*goto JaceJess_Breakout_Banter
	*label Karlkarla_Breakout_Banter
	"Do you think they're being tortured?" ${karlkarla_name} asks quietly.  "I hate the fact that we had to leave ${prisoner1_name} and ${prisoner2_name} locked up for so long.  What if they had their fingernails pulled out, or something like that?"
	*choice
		#Say, "We had no choice.  If we had tried to rescue them right away, we would have been caught."
			It was true. Selina would have known you were coming.  Your gentle archer friend nodded at this, taking comfort from your words.
			*if (showstats)
				*line_break
				(${karlkarla_name} Relationship +3)
			*set karlkarla_relationship +3
			*goto After_Breakout_Banter
		#Say, "Probably a lot worse than that.  Thumb screws, iron maiden, the rack…"
			You continue to name off various torture methods, watching as ${karlkarla_name} becomes a bit more pale with each one.  ${karlkarla_heshe} suddenly excuses ${karlkarla_himher}self and rushes off to the privy to empty the contents of ${karlkarla_hisher} stomach.  When your gentle archer friend returns, ${karlkarla_heshe} asks no more questions.
			*if (showstats)
				*line_break
				(${karlkarla_name} Relationship -3)
			*set karlkarla_relationship -3
			*goto After_Breakout_Banter
		*if (((god_name!="None") and (god_good))=false) #Say, "Breath of Lucien, I hope not."
			${karlkarla_name} takes no offence at your blasphemous use of the God of Light's name.
			*goto God_Curse
		*if ((god_name!="None") and (god_good)) #Say, "Breath of ${god_name}, I hope not."
			${karlkarla_name} takes no offence at your blasphemous use of the God's name.  
			*label God_Curse
			Instead, ${karlkarla_heshe} nods in agreement, happy to see that you are just as worried over the fate of your friends as ${karlkarla_heshe} is.
			*if (showstats)
				*line_break
				(${karlkarla_name} Relationship +3)
			*set karlkarla_relationship +3
			*goto After_Breakout_Banter
		#Say, "We'll make Zusak and Selina pay for what they have done."
			${karlkarla_name} nods quietly at your words.  Thoughts of revenge and vengeance don't make your gentle archer feel any better.
			*goto After_Breakout_Banter
*if (jacejess_inparty)
	*label JaceJess_Breakout_Banter
	"We shouldn't bother breaking ${prisoner1_name} and ${prisoner2_name} out," ${jacejess_name} says haughtily.  "We should be working on getting your throne back instead."
	*choice
		#Say, "They were caught helping me.  We have to save them."
			"If you wish," ${jacejess_name} says dismissively.  "I just don't see how much help they are going to be in the future."
			*if (showstats)
				*line_break
				(Good +3)
			*set good +3
			*goto After_Breakout_Banter
		#Say, "What if it was you who had been caught?"
			"I wouldn't have gotten caught," ${jacejess_name} says as ${jacejess_heshe} shrugs ${jacejess_hisher} shoulders dismissively.
			*goto After_Breakout_Banter
		#Say, "I'll need their skills to aid me."
			"You're right," ${jacejess_name} agrees with you.  "They have their uses.  Very well, where do we start."
			*if (showstats)
				*line_break
				(${jacejess_name} Relationship +3)
			*set jacejess_relationship +3
			*goto After_Breakout_Banter
		#Say, "You're a cold hearted monster."
			"Perhaps," the Soulburner says with a dismissive shrug.  "I've been called worse."
			*if (showstats)
				*line_break
				(${jacejess_name} Relationship -3)
			*set jacejess_relationship -3
			*goto After_Breakout_Banter
*page_break ERROR!  This shouldn't be reached.  Please tell the developer that you found no conversations during the Breakout_Banter.	
			
*label After_Breakout_Banter

Before any rescue attempt is made, you'll need to know exactly where your friends are being held.
*label Breakout_GetInformation_loop
*choice
	#Sneak into the keep and investigate the clerk's offices yourself.
		*if (stealth<60)
			You barely slip past the guards before one of them turns toward you and glares.  You certainly don't want Selina to know that you are back already, so you leave quietly and pretend that you had entered the wrong door.  The clerk's offices are more heavily guarded than you had suspected.
			*if (showstats)
				(Needed 60 Stealth)
			*goto Breakout_GetInformation_loop
		You quietly slip past the guards and into the offices.  It's dark and nobody is working late, so you have no trouble reaching one of the clerk's desks.  Many important papers have been placed into lockboxes for the night, making things a little more difficult.
		*if (showstats)
			*line_break
			(Stealth +2)
		*set stealth +2
		*choice
			#Open the boxes.
				You look at the well-crafted locks and examine the sturdy iron bands holding the lockboxes in place.
				*if (lockpickset=false)
					Without a set of lockpicks, you realise that you won't be able to open the boxes.
					*if (showstats)
						(Needed Lockpicks)
					*goto Breakout_GetInformation_loop
				You take out your lockpick set and get to work.
				*if (devices<60)
					After an hour of failure, you realize that the locks are above your skill to open.  Frustrated, you return to the Siren.
					*if (showstats)
						(Needed 60 Devices)
					*goto Breakout_GetInformation_loop
				It doesn't take long for you to open the boxes.  There is no money inside; instead you find dungeon manifests, including maps and prisoner names.  Clearly labelled, the plans tell you exactly where your friends are being held.
				*if (showstats)
					*line_break
					(Devices +2)
				*set devices +2
				*set breakout_foundthem true
				*goto Breakout_Preparation
			#Give up and go back to the Siren.
				You manage to return to your room without getting caught, but unfortunately, you are no closer to finding out where your friends are being held.
				*goto Breakout_GetInformation_loop
	*if (gillgale_inparty) #Ask ${gillgale_name} to sneak into the clerk's office.
		*if (gillgale_relationship<70)
			${gillgale_name} agrees to go, but you can tell that ${gillgale_heshe} is reluctant about the idea.  It takes most of the night before ${gillgale_heshe} returns to the Siren.
			
			"Sorry, ${name}," ${gillgale_name} says.  "No luck.  I couldn't get in."
			*if (showstats)
				(Needed 70 ${gillgale_name} Relationship)
			*goto Breakout_GetInformation_loop
		*else
			"Wish me luck," ${gillgale_name} says before slipping out the door.
			
			Most of the night passes and you can't help but to remember how ${prisoner1_name} and ${prisoner2_name} had been sent on a similar scouting mission to find out about Zusak.  Fortunately, ${gillgale_name} returns just before dawn with a large smile on ${gillgale_hisher} face.
			
			"It took some patience, but here you go," your thief friend says, handing you the blueprints of the dungeon that ${gillgale_heshe} had stolen.
			
			The map clearly shows which cell your friends are being held in.
			*set breakout_foundthem true
			*goto Breakout_Preparation
	#Cast a Divination spell.
		*if (magic<40)
			You don't even know how to start such a spell, making you give up on the idea of a magical solution before you even begin.
			*if (showstats)
				(Needed 70 Magic)
			*goto Breakout_GetInformation_loop
		You cast your spell of clairvoyance and use it to look through the offices and the dungeons themselves.  
		*if (magic<70)
			Unfortunately, your vision is blurry and difficult to manipulate.  No matter how hard you try, you can't seem to find which cell your friends are being held in.
			*if (showstats)
				(Needed 70 Magic)
			*goto Breakout_GetInformation_loop
		You are appalled to see that many of the prisoners are being held in unlit cells, which stops your magical sight as well.  Eventually, you find a solid looking door with a pair of guards standing in front of it.  They mention ${prisoner2_name}'s name.  After a few minutes of spying on them with your magic, they mention ${prisoner1_name}'s name as well.  There is no doubt; you have found your friends.
		*if (showstats)
			*line_break
			(Magic +2)
		*set magic +2
		*set breakout_foundthem true
		
		"I found them," you say out loud as you rub your tired eyes.
		*goto Breakout_Preparation
	*if (breakout_metguards)
		*allow_reuse #Speak to the prison guards you met.
			You return to the inn that they frequent.
			*goto Breakout_prisonguardbar_loop
	*if (breakout_metguards=false)
		*selectable_if (gold>=10) #Learn who the prison guards are and buy them drinks.  (Needs 10 Gold)
			It doesn't take long to learn who works in the dungeons.  A few of the men have been working in the dungeons for dozens of years, well before Selina took over as duchess in Brightwater. 
			*if (showstats)
				*line_break
				(Gold -10)
			*set gold -10
			*label Breakout_prisonguardbar_loop
			*choice
				#Befriend the guards and try to pry the information from them.
					You learn the names of their children and their spouses.  You make up stories about yourself and slowly you try to pick some information from them.
					*if (charm<30)
						Unfortunately, they don't really like you and get very quiet when you are around.
						*if (showstats)
							(Needed 65 Charm)
						*goto Breakout_prisonguardbar_loop
					*if (charm<65)
						Although they seem to like you well enough, they become extremely tight-lipped about who they are guarding or any particulars about their jobs.
						*if (showstats)
							(Needed 65 Charm)
						*goto Breakout_prisonguardbar_loop
					They are good men.  It's clear that they are loyal to their jobs and discreet, but your charming personality has them saying things that they shouldn't.  It doesn't take long before you know exactly which cell your friends are being held in.  Unfortunately, it's clear that this is as much help as your new associates are willing to give.
					*if (showstats)
						*line_break
						(Charm +2)
					*set charm +2
					*set breakout_foundthem true
					*goto Breakout_Preparation
				*selectable_if (gold>=250) #Bribe one of the guards into giving you the information you need.  (Needs 250 Gold)
					The man you approach is nearing retirement and obviously hasn't set any funds aside for his geriatric years.  You suspect that the guard's pension is not very good either.  Carefully, you broach the idea of getting a map with the names of all the prisoners.  The man will not take his disloyalty any further than this, but eventually you learn exactly where your friends are and the man retires from service the moment you hand him his gold.
					*if (showstats)
						*line_break
						(Gold -250)
					*set gold -250
					*set breakout_foundthem true
					*goto Breakout_Preparation
				#Capture one of the guards and force the information from them.
					The man that you pull off the street is tough.  You did well to drag him into a dark alley without letting him see who you are.  You are also careful in your questioning, asking for all kinds of information so that he can't figure out exactly what you want.  He holds up well under pressure.  You begin to wonder if he is going to give you the information or not.
					*choice
						*if (class_thug>0) #Use the intimidation skills you learned as a thug.
							Being a thug wasn't only breaking bones and beating people up.  More of your clients got what they wanted through your threats and warnings.  The guard was no different and soon told you exactly which cell your friends were being held in without you having to raise another fist.  Even better, he said that he would use up some holiday time and get out of the city for the next couple of weeks.  From the way he was trembling, you believe him.
							*if (showstats)
								*line_break
								(Charm +3)
							*set charm +3
							*set breakout_foundthem true
							*goto Breakout_Preparation
						#Make him speak by any means necessary.
							*if (friend2_exists)
								${friend1_name} and ${friend2_name} turn
							*if (friend2_exists=false)
								${friend1_name} turns
							away from your tortuous ministrations.  Eventually the man spills it all, telling you exactly where your friends are being held.
							*if (showstats)
								*line_break
								(Evil +10)
							*set good -10
							*set breakout_foundthem true
							*choice
								#Kill the man to cover your tracks.
									After what you have done to the man, his death is a mercy.
									*if ((holysymbol) and (god_good=false))
										You can practically feel ${god_name}'s praise upon your evil actions.
									*if (showstats)
										*line_break
										(Evil +10)
									*set good -10
									*goto Breakout_Preparation
								#Threaten the man with death and leave him in the alley.
									The guard blubbers in fear and promises to say nothing to anyone about your 'conversation'.  You leave him broken and bleeding in the alley.  He proceeds to use some vacation time and leaves the city the very next day.
									*goto Breakout_Preparation
						#Let the man go.
							He hadn't seen your face and your questioning had been very general, so you let him go.  You leave the man in the alley and return to the Siren, hoping that his rough handling won't interfere with your plans.
							*goto Breakout_GetInformation_loop
				*allow_reuse #Try something else.
					You leave the guards and return to your room to continue plotting.
					*goto Breakout_GetInformation_loop
	*if ((((companion_type="rat") or (companion_type="mouse")) or ((companion_type="spider") or (companion_type="toad"))) and (companion_name!="None")) #Send ${companion_name}, your ${companion_type}, into the dungeon.
		You spend the night lying in bed with your eyes open, but unseeing as
		*if (friend2_exists)
			${friend1_name} and ${friend2_name} watch
		*if (friend2_exists=false)
			${friend1_name} watches
		over you.  You see the moldy walls of the dungeon tunnels through the ${companion_type}'s eyes.  The jailers and prisoners ignore you as you pass among many other vermin in the dirty and disease ridden cells.  Eventually, you find a solid looking door with a pair of guards standing in front of it.  They mention ${prisoner2_name}'s name.  After a few minutes of spying on them, they mention ${prisoner1_name}'s name as well.  There is no doubt, you have found your friends.  Carefully, you walk ${companion_name} back through the tunnels and into your inn room.
		
		"I found them," you say out loud as you open your own eyes.
		*set breakout_foundthem true
		*goto Breakout_Preparation
	#Give up on finding out exactly where your friends are being held.
		*goto Breakout_Preparation_ns

*label Breakout_Preparation

*label Breakout_Preparation_ns
You spend nearly a week gathering information about the dungeons.
*if (breakout_foundthem=false)
	Although it is unfortunate that you couldn't find the exact cell  in which your friends are being held, you manage to learn many other useful things.
*if (breakout_foundthem)
	In addition to finding out where your friends are being held, you learn many other useful things.
The warden of the dungeons is an obese man named Bunta.  Rumour says that he isn't entirely human, that he has ogre-blood in his veins.  Bunta is seven feet tall and weighs over 500 pounds.  They say that he has the only keys to all the cells, and because of his enormous size, he never leaves the dungeon.  With a foul temper and perverse tastes, the monster in charge of guarding your friends will need to be dealt with for you to be successful.  But first, you have to get down into the dungeon.
*label Breakout_GettingIn
*choice
	*if (breakout_metguards) #Try to get your guard friends to let you in.
		It doesn't take long to realize that they won't help you.  They take their jobs seriously, and despite having Selina for a duchess, they are honourable people.  Most of the prisoners aren't political.  Keeping rapists, murderers and thieves off the streets is a noble profession and the guards refuse to help you get into the tunnels.
		*if (peterpetra_inparty)
			Despite even this, ${peterpetra_name} surprises you by coming away from the bar with a key.
			
			"He was a devoted follower of my God and was very open in speaking to me.  I hope that stealing this key is less evil than not taking it and leaving our friends in the dungeon."
			*choice
				#Ease ${peterpetra_hisher} conscience by telling ${peterpetra_himher} that it was the right thing to do.
					You can see the relief on ${peterpetra_name}'s face at your words.
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship +5)
					*set peterpetra_relationship +5
					*goto Breakout_GotOutsideKey
				#Say, "We got what we needed.  Stop moping about and let's get to work."
					You see a tightness about ${peterpetra_name}'s eyes at your words, but ${peterpetra_heshe} nods and hands over the key.
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship -5)
					*set peterpetra_relationship -5
					*goto Breakout_GotOutsideKey
				#Say nothing.
					You say nothing.  You notice ${peterpetra_name} looking glum and morally uncertain about ${peterpetra_hisher} actions.
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship -3)
					*set peterpetra_relationship -3
					*goto Breakout_GotOutsideKey
			*label Breakout_GotOutsideKey
			
			*if (friend2_exists)
				You, ${friend1_name} and ${friend2_name}
			*if (friend2_exists=false)
				You and ${friend1_name}
			wait until the wee hours of the morning.  Carefully, you go to the door that leads down into the dungeons.  You aren't surprised to find it locked up tight.  This is merely the exterior door that keeps out people who shouldn't be there.  The real security will be downstairs.  The guard's key works perfectly, granting you entrance to the dungeons without raising an alarm.
			*goto Breakout_PrisonTunnel
		*else
			*goto Breakout_GettingIn
	*allow_reuse #Wait for night and sneak in.
		*if (friend2_exists)
			You, ${friend1_name} and ${friend2_name}
		*if (friend2_exists=false)
			You and ${friend1_name}
		wait until the wee hours of the morning.  Carefully, you go to the door that leads down into the dungeons.  You aren't surprised to find it locked up tight.  This is merely the exterior door that keeps out people who shouldn't be there.  The real security will be downstairs.
		*label Breakout_OutsideDoor
		*choice
			#Attempt to unlock the door.
				*if (((lockpickset=false) or (devices<60)) and (gillgale_inparty))
					After a few minutes of bungling with the lock, ${gillgale_name} steps forward and uses ${gillgale_hisher} own lockpicks to open the exterior door.  Together, you continue into the tunnels.
					*goto Breakout_PrisonTunnel
				*if (lockpickset=false)
					You bungle with the lock for a few minutes before realizing that without a proper set of lockpicks, even the exterior door to the dungeons is beyond your skill.
					*goto Breakout_OutsideDoor
				You take out your lockpicks and get to work.
				*if (devices<60)
					Unfortunately, no matter what you do, you can't seem to get the door open.
					*if (showstats)
						(Needed 60 Devices)
					*goto Breakout_OutsideDoor
				While holding down one of the tumblers, you manage to work your way through a second set, then push and turn at the same time.  With a soft click, the lock opens.  You quickly put away the lockpicks and open the door.
				*if (showstats)
					*line_break
					(Devices +2)
				*set devices +2
				*goto Breakout_PrisonTunnel
			*if (ki_strike) #Use your Ki Strike on the door.
				You feel the power grow and then you punch the door.  Although the punch itself was solid, the movement of the lock was unexpected as it pops out of the door in a single piece, allowing the door to swing quietly open.  You reach out at the last second and catch the lock mechanism before it lands on the ground, making your entry completely silent.
				*goto Breakout_PrisonTunnel
			*if (gillgale_inparty) #Ask ${gillgale_name} to pick the lock.
				*if (gillgale_relationship>=80)
					"I'm on it," your thief friend says with a grin.
					
					You watch as ${gillgale_heshe} takes out ${gillgale_hisher} lockpick set and gets to work.  One of ${gillgale_hisher} picks snaps and ${gillgale_heshe} shakes ${gillgale_hisher} head in frustration.  Eventually, ${gillgale_heshe} manages to open the lock.
					*goto Breakout_PrisonTunnel
				*else
					"I don't know," ${gillgale_name} says as ${gillgale_heshe} looks at the door.  "I can try."
					
					You watch as the thief takes out ${gillgale_hisher} lockpick set and gets to work.  One of ${gillgale_hisher} picks snaps and ${gillgale_heshe} curses silently under ${gillgale_hisher} breath.
					
					"No, this is beyond my skills," ${gillgale_name} says.
					*if (showstats)
						(Needed 80 ${gillgale_name} Relationship)
					*goto Breakout_OutsideDoor
			#Cast a spell to blast the door off its hinges.
				*if (magic>=50)
					The door flies across the room as your spell completes.
					*if (breakout_silenced_door)
						The Silence spell you cast wasn't designed for such a thing
					*if (breakout_silenced_door=false)
						A series of crashing sounds erupt around you
					as the door clatters down the stairs and into the dungeon.  Your hear the answering sound of footsteps as guards run up to meet you.
					*if (showstats)
						*line_break
						(Magic +2)
					*set magic +2
					*goto Breakout_GuardsOnlyFight
				The door shakes abruptly as you finish your spell, but the force of the spell isn't enough to break it down.
				*if (breakout_silenced_door)
					Since nobody investigates the loud noise, you assume that your Silence spell is working.
					*if (showstats)
						(Needed 50 Magic)
					*goto Breakout_OutsideDoor	
				To your surprise, the door opens a moment later anyway.  A pair of startled guards look at you, obviously surprised to see you there.
				*if (showstats)
					(Needed 50 Magic)
				*goto Breakout_GuardsOnlyFight
			#Smash down the door.
				You put your shoulder forward and run into the door.
				*if (strength<45)
					There is a loud smashing noise, but the door holds firm, causing you to bounce back.  You look around, hoping that nobody has heard you.
					*if (breakout_silenced_door=false)
						To your surprise, the door opens wide as a pair of guards emerge from the other side to investigate the noise!
						*if (showstats)
							(Needed 45 Strength)
						*goto Breakout_GuardsOnlyFight
					*else
						*if (magic>=30)
							Considering just how loud you were, you realize that your Silence spell is doing its job.
							*if (showstats)
								*line_break
								(Magic +2)
							*set magic +2
							*label Breakout_keepsmashing
							
							*if (friend2_exists)
								You, ${friend2_name}
							*if (friend2_exists=false)
								You
							and ${friend1_name} continue to throw yourselves at the door until the stone around the hinges finally breaks.  You carefully remove the door and enter the dungeon.
							*goto Breakout_PrisonTunnel
						*else
							To your surprise, the door opens wide as a pair of guards emerge from the other side to investigate the noise!  You realize that this must mean that your Silence spell didn't take hold.
						*if (showstats)
							(Needed 45 Strength or 30 Magic)
						*goto Breakout_GuardsOnlyFight
				*else
					The door makes little noise as it pops off its hinges.  You wait for a moment to hear if the guards were alerted.  When nobody comes up the stairs, you assume that your entrance has gone unnoticed.
					*if (breakout_silenced_door)
						You aren't sure if this quiet entry was from the Silence spell or if you simply broke down the door too quickly for anyone to notice the sound.
					*if (showstats)
						*line_break
						(Strength +2)
					*set strength +2
					*goto Breakout_PrisonTunnel
			*if ((perception>=50) or (gem_seeing=true)) #Look at the loose brick beside the door.
				*if (gem_seeing)
					Your Gem of Seeing shines a bright light on the hiding spot.
				*if ((friend1_name=jacejess_name) or (friend2_name=jacejess_name))
					"Really?" ${jacejess_name} scoffs as you remove the brick and retrieve a key to the door.  "Are these people that stupid?  Remarkable."
					
				*if (((friend1_name=jacejess_name) or (friend2_name=jacejess_name))=false)
					${friend1_name} laughs out loud as you remove the brick and retrieve a key to the door.
				You put the key into the lock and it pops open immediately.
				*if (showstats)
					*line_break
					(Perception +2)
				*set perception +2
				*goto Breakout_PrisonTunnel
			#Try to cast a spell of Silence on the door.
				*if ((magic>=30) and (spellbook))
					You weave the spell and complete the incantation.  Unfortunately, you have no way of knowing if it worked or not.
					*set breakout_silenced_door true
					*goto Breakout_OutsideDoor
				*if (spellbook=false)
					You go over the few spells you know but can't seem to find what you are looking for.  Perhaps if you were to buy a spellbook you could learn the incantation?
				*if (spellbook)
					You look through your spellbook, but when you find a spell about silencing things, it is beyond your skills to cast.
				*if (showstats)
					(Needs Spellbook and 30 Magic)
				*goto Breakout_OutsideDoor
			*allow_reuse #Return to the Siren and consider other options.
				You return to the inn without anyone knowing where you were.
				*goto Breakout_GettingIn
	*if ((breakout_metpimp) and (breakout_considereddisguise=false))
		*allow_reuse #Return to the man who sends down Bunta's prostitutes.
			You return to the man's dark alley, once more seeing his hired thugs all around him.
			*goto Breakout_darkalley
	*if ((breakout_metpimp) and (breakout_considereddisguise))
		*allow_reuse #Return to the man in the alley and say that you wish to try the deception after all.
			The man is surprised to hear that you'd like to be smuggled down to Bunta despite not looking the part.  He agrees to let you try, although he doesn't hide the fact that he thinks you will fail.
			*set breakout_disguiseworks false
			*goto Breakout_TryDisguise
	*if (breakout_metpimp=false) #Learn what you can about Bunta.
		*set breakout_metpimp true
		It seems that everyone in Brightwater has a horror story to tell about their local bogeyman.  The common elements include his enormous size and his repulsive lusts.  Young prostitutes, male and female, are steadily purchased and sent down for his entertainment.  It doesn't take long to find the man responsible for conveying these poor souls to the monster.  You are clearly not alone in the dark alley you meet him in.  The shadows around him are likely his hired muscle and you undoubtedly have a crossbow aimed at you while you speak.
		*label Breakout_darkalley
		*choice
			*if (gold>=100) #Bribe the man into sending one of you to Bunta.  (Needs 100 Gold)
				The man greedily takes your money.
				*if (showstats)
					*line_break
					(Gold -100)
				*set gold -100
				*goto Breakout_Darkalley_Deal
			#Ask the man to send one of you to Bunta.
				*if (charm>=50)
					It takes some smooth talking to get the man to start listening, but as you explain your idea, he begins to pay attention.
					*if (showstats)
						*line_break
						(Charm +2)
					*set charm +2
					*goto Breakout_Darkalley_Deal
				*else
					The man who sends the prostitutes refuses to listen to your words.
					*if (showstats)
						(Needed 50 Charm)
					*goto Breakout_darkalley
			*if (class_thug>0) #Use your street smarts to approach the man.
				Due to your checkered past, you have worked with such men before.  A few slang words and rough laughs allow you to get close enough to talk to him.
				*goto Breakout_Darkalley_Deal
			*allow_reuse #Leave the alley and return to your room in the inn.
				You leave the alley and return to the Siren.
				*set breakout_metpimp true
				*goto Breakout_GettingIn

*label Breakout_Darkalley_Deal

"So you want to break someone out," the man says as he cleans his fingernails with a sharp dagger.  "You know what?  I'm fine with that.  That fat bastard is rough on my charges.  More trouble than he's worth.  You slit his throat and we all walk away happy.  If this falls flat, I'm claiming that I didn't know anything about it.  So, which of you is going to be Bunta's sex toy?"
*label Breakout_WhoGoes
*choice
	*if (theothea_inparty) #Say, "${theothea_name} will."
		The man laughs out loud and so do some of the people in the shadows.
		
		"Bunta likes his toys innocent and delicate.  Your brutish friend will never pull it off."
		*goto Breakout_WhoGoes
	*if (jacejess_inparty) #Say, "${jacejess_name} will."
		"I will not," the Soulburner says with a vehemence that you haven't seen in some time.
		*if (showstats)
			*line_break
			(${jacejess_name} Relationship -3)
		*set jacejess_relationship -3
		*goto Breakout_WhoGoes
	*if (peterpetra_inparty) #Say, "${peterpetra_name} will."
		"I'm sorry, ${name}, but I cannot do this."
		
		You can see the distaste in your holy friend's eyes.  Although ${peterpetra_heshe} would like nothing more than to bring down this monster, ${peterpetra_heshe} would never be able to pull such an act off anyway.
		*goto Breakout_WhoGoes
	*if (gillgale_inparty) #Say, "${gillgale_name} will."
		"I don't think I could stomach it," ${gillgale_name} says with an honest shrug.  "Can't we just sneak down past him and stick a dagger in his back?"
		*goto Breakout_WhoGoes
	*if (karlkarla_inparty) #Say, "${karlkarla_name} will."
		"Me?" ${karlkarla_heshe} says in a strangled voice.
		
		"Oh yes," the man says, looking ${karlkarla_name} up and down as his thugs chuckle in deep voices.  "This little mouse is exactly Bunta's type."
		
		A few nights later, when Bunta requests some company to be sent down to him, you are ready.
		*if (friend2_exists)
			You and
			*if (friend1_name!=karlkarla_name)
				${friend1_name}
			*if (friend2_name!=karlkarla_name)
				${friend2_name}
			dress up as thug protectors and escort
		*if (friend1_exists=false)
			You dress up as a thug protector and escort
		${karlkarla_name} to the exterior dungeon door.  ${karlkarla_name} dresses up in clothing to make ${karlkarla_himher} appear even more innocent looking.  The scared look on ${karlkarla_hisher} face doesn't need to be faked.
		
		The guards let you in without any trouble, used to Bunta's trysts.
		*if (breakout_metguards)
			Your heart skips a beat as you recognize one of the guards from your talks in the bar, but you can see that he doesn't recognize you.
		The guards lead you deep through the dungeons and into a small room.  You see a dirty cot, a wooden table covered in dirty dishes and the fattest man you have ever seen.  He is wearing a warden's uniform but holds no weapons, although a large crossbow hangs from his hip.  The rumours of Bunta's ogre heritage seem very real as the slug of a man turns his head toward ${karlkarla_name}.  You can see the violent lust in his eyes as he licks his lips in eager anticipation.  A slight movement from the cot catches your attention.  You see a young ${prisonchild_boygirl} sitting there, ${prisonchild_hisher} eyes blank and ${prisonchild_hisher} face empty of any emotion.  $!{prisonchild_heshe} is likely a prisoner and lacks any hope of release at all.
		
		"Get out!" Bunta shouts at his guards, his waddles of neck fat quivering with the effort.
		*choice
			#Attack Bunta immediately.
				The guards begin to follow the command, heading toward the door to leave the monstrously fat man alone with his toys.
				*goto Breakout_BuntaFight_WithGuards
			#Leave ${karlkarla_name} alone with Bunta and exit the room.
				Bunta gets to his feet, large flabs of fat hanging over his belt and jiggling as he stomps toward the door.  You see ${karlkarla_name}'s petrified face one last time as the door closes between you.  The guards depart as well, leaving you alone outside the door.  You don't have to wait long before you hear a grunt of pain.  Quickly, you open the door and see ${karlkarla_name} standing in front of Bunta with a determined look on ${karlkarla_hisher} face.  You also see the hilt of a dagger sticking out of Bunta's chest.  He reaches down and plucks it free, dropping it to the floor as murderous rage fills the fat man's face.
				*if (showstats)
					*line_break
					(Bunta's Health -50 to 50 / 100)
				*set bunta_health -50
				*goto Breakout_BuntaFight_NoGuards
	#I will.
		"You're brave," the man says.  "I'll give you
		*if ((strength<30) and (endurance<30))
			that."
			*set breakout_disguiseworks true
			*label Breakout_TryDisguise
			
			A few nights later, when Bunta requests some company to be sent down to him, you are ready.
			*if (friend2_exists)
				${friend1_name} and ${friend2_name} dress up as thug protectors and escort
			*if (friend2_exists=false)
				${friend1_name} dresses up as a thug protector and escorts
			you to the exterior dungeon door.  You are wearing clothing to make you look like an innocent waif.
			*if (companion_name!="None")
				You command ${companion_name} to travel with ${friend1_name} to help maintain the disguise of a helpless victim.
			
			The guards let you in without any trouble, used to Bunta's trysts.
			*if (breakout_metguards)
				Your heart skips a beat as you recognize one of the guards from your talks in the bar, but you can see that he doesn't recognize you.
			The guards lead you deep through the dungeons and into a small room.  You see a dirty cot, a wooden table covered in dirty dishes and the fattest man you have ever seen.  The rumours of Bunta's ogre heritage seem very real as the slug of a man turns his head toward you.
			*if (breakout_disguiseworks=false)
				
				"What is this?" Bunta bellows.  "I don't want this.  Take ${mc_himher} back and bring me something delicate."
				
				The guards turn toward you and look at you in greater detail than before.  A movement from the cot catches your attention.  You see a young ${prisonchild_boygirl} sitting there, ${prisonchild_hisher} eyes blank and ${prisonchild_hisher} face empty of any emotion.  $!{prisonchild_heshe} is likely a prisoner and lacks any hope of release at all.
				
				"Wait a minute…who are you people?" one of the guards says upon realizing that
				*if (friend2_exists)
					${friend1_name} and ${friend2_name} are not the ones who usually bring
				*if (friend2_exists=false)
					${friend1_name} is not the one who usually brings
				Bunta's distractions.
				
				They immediately draw swords as they correctly suspect that a prison break is in progress.
				*goto Breakout_BuntaFight_WithGuards
			*else
				You can see the violent lust in his eyes as he licks his lips in eager anticipation.  A movement from the cot catches your attention.  You see a young ${prisonchild_boygirl} sitting there, ${prisonchild_hisher} eyes blank and ${prisonchild_hisher} face empty of any emotion.  $!{prisonchild_heshe} is likely a prisoner and lacks any hope of release at all.
			
			"Get out!" Bunta shouts at his guards, his waddles of neck fat quivering with the effort.
			*choice
				#Attack Bunta immediately.
					The guards begin to follow the command, heading toward the door to leave the monstrously fat man alone with his toys.
					*goto Breakout_BuntaFight_WithGuards
				*if (friend2_exists) #Nod to ${friend1_name} and ${friend2_name}, indicating that they should leave you alone with Bunta.
					The fat man waits for ${friend1_name}, ${friend2_name} and the guards to leave.
					*goto Breakout_AloneWithBunta
				*if (friend2_exists=false) #Nod to ${friend1_name}, indicating that ${friend1_heshe} should leave you alone with Bunta.
					The fat man waits for ${friend1_name} and the guards to leave.
					*label Breakout_AloneWithBunta
					You catch a final glimpse of ${friend1_name}'s worried eyes as the door is closed behind ${friend1_himher}.  The fat man turns his terrifying gaze to you and lumbers toward you like a bull in heat.
					*choice
						*if (sword) #Draw your hidden sword and attack Bunta.
							It was difficult to hide the long blade from the man and even more difficult to swing it without him seeing it coming, but you manage to strike him solidly across the stomach anyway.  He grunts in rage, but miraculously, he does not fall!
							*if (showstats)
								*line_break
								(Bunta's Health -50 to 50 / 100)
							*set bunta_health -50
							*label Breakout_friendsrescue
							
							*label Breakout_friendsrescue_ns
							*if (friend2_exists)
								${friend1_name} and ${friend2_name} throw open the door immediately and rush
							*if (friend2_exists=false)
								${friend1_name} throws open the door and immediately rushes
							to your side.  The guards are gone, having followed Bunta's command to leave.
							*goto Breakout_BuntaFight_NoGuards
						*if (dagger) #Draw your hidden dagger and attack Bunta.
							You plunge the dagger into the man's chest to the hilt, but miraculously, he does not fall!  He grunts in rage and steps forward as you drive the dagger into his blubbery belly several more times.
							*if (showstats)
								*line_break
								(Bunta's Health -50 to 50 / 100)
							*set bunta_health -50
							*goto Breakout_friendsrescue
						#Take an eating knife off the table and jam it into Bunta's neck.
							You plunge the knife deep into one of the blubbery folds of Bunta's neck, but miraculously, the monster of a man does not fall!  He grunts in rage and swats the knife out of his skin with a free hand as he steps toward you.
							*if (showstats)
								*line_break
								(Bunta's Health -50 to 50 / 100)
							*set bunta_health -50
							*goto Breakout_friendsrescue
						#Clap your hands over both of Bunta's ears at the same time.
							You strike the fat man so viciously that he grunts from the pain.  You aren't sure if you've ruptured his ear drums or not as he puts his own hands to the sides of his head for a moment.
							*if (showstats)
								*line_break
								(Bunta's Health -50 to 50 / 100)
							*set bunta_health -50
							*goto Breakout_friendsrescue
						#Call for help.
							*goto Breakout_friendsrescue_ns
		*else
			that.  But you're too old and too big.  Bunta won't be interested in you."
			*if (showstats)
				(Needed Under 30 Strength and Under 30 Endurance)
			*choice
				#Say, "I'll try it anyway."
					"It's your funeral," the man says with a shrug.
					*set breakout_disguiseworks false
					*goto Breakout_TryDisguise
				*if (class_druid>0) #Use your druidic magic to temporarily change your nature.
					The years seem to melt away and moments later, you appear to be younger and more innocent looking than ever before.  ${friend1_name}'s jaw drops in surprise and one of the shadows behind the man in the alley whistles in amazement.  Many druids learn to stop aging, but some, like yourself, have the ability to temporarily roll back the years as well.
					*if (showstats)
						*line_break
						(Magic +2)
					*set magic +2
					*set breakout_disguiseworks true
					*goto Breakout_TryDisguise
				*if (feather_of_glibness) #You notice that the Feather of Glibness in your hat is glowing.
					The token of the God of Mischief suddenly begins to work its magic upon you.  You feel the same, but an illusion of youth spreads over you, making you appear younger than you are.  ${friend1_name}'s jaw drops in surprise and one of the shadows behind the man in the alley whistles in amazement.
					*set breakout_disguiseworks true
					*goto Breakout_TryDisguise
				*allow_reuse #Say, "You're right, I don't think this is going to work."
					It would be a pity if you went through such a humiliating experience for nothing.
					*set breakout_considereddisguise true
					*goto Breakout_WhoGoes
	*allow_reuse #Give up on the idea of using subterfuge to get closer to Bunta.
		There are other ways to proceed and you return to your room to consider them.
		*goto Breakout_GettingIn

*label Breakout_BuntaFight_WithGuards
*choice
	*if (sword) #Draw your own sword and deal with the guards first.
		*if (blades>=50)
			The guards are quickly overwhelmed,
			*label Blades_Guards_Especially
			especially when
			*if (friend2_exists)
				${friend1_name} and ${friend2_name} lend you support.
			*if (friend2_exists=false)
				${friend1_name} lends you support.
			Within seconds, they are all lying dead at your feet.  Unfortunately, Bunta is not so easily subdued.  One of his meaty fists strikes you across the head, causing you to see double.
			*if (showstats)
				*line_break
				(Blades +2 and Health -50)
			*set blades +2
			*set health -50
			*set breakout_killed_guards true
			*goto Breakout_BuntaFight_WithGuards_2
		*else
			The guards assume a defensive formation and lash out with their own swords.  You manage to kill one of them, but the others quickly fill in the gap.  Bunta uses the distraction to get too close.  One of his meaty fists strikes you across the head, causing you to see double.
			*if (showstats)
				(Needed 50 Blades)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
	#Throw one of the guards into the others.
		*if (unarmed>=60)
			The surprised guard pinwheels into his companions, knocking three of them to the ground.  This is all the help
			*if (friend2_exists)
				${friend1_name} and ${friend2_name} need to finish off the rest of the guards.
			*if (friend2_exists=false)
				${friend1_name} needs to finish off the other guards.  Between the two of you, all of them are killed.
			Unfortunately, Bunta is not so easily subdued.  One of his meaty fists strikes you across the head, causing you to see double.
			*if (showstats)
				*line_break
				(Unarmed +2 and Health -50)
			*set unarmed +2
			*set health -50
			*set breakout_killed_guards true
			*goto Breakout_BuntaFight_WithGuards_2
		*else
			The guard slashes you in the arm with his sword when you try to grab him.  They then assume a defensive formation as Bunta shambles closer as well.
			*if (showstats)
				(Needed 60 Unarmed)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
	*if (dagger) #Draw your dagger and deal with the guards first.
		*if (blades>=65)
			The guards are quickly overwhelmed, despite the fact that you are using just a dagger,
			*goto Blades_Guards_Especially
		*else
			The guards assume a defensive formation and lash out with their own swords, which makes reaching them with your short dagger very difficult.  Bunta uses the distraction to get too close.  One of his meaty fists strikes you across the head, causing you to see double.
			*if (showstats)
				(Needed 65 Blades)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
	*if (bow) #Draw your bow and fire upon the guards first.
		*if (archery>=50)
			The guards can't defend themselves with their swords as you fire arrows into them.  They are quickly overwhelmed, especially when
			*if (friend2_exists)
				${friend1_name} and ${friend2_name} lend you support.
			*if (friend2_exists=false)
				${friend1_name} lends you support.
			Within seconds, they are all lying dead at your feet.  Bunta uses the distraction to get too close.  One of his meaty fists strikes you across the head, causing you to see double.
			*if (showstats)
				*line_break
				(Archery +2 and Health -50)
			*set archery +2
			*set health -50
			*set breakout_killed_guards true
			*goto Breakout_BuntaFight_WithGuards_2
		*else
			You manage to kill two of the guards before they close the distance, making your bow inefficient in the tight confines of the prison tunnels.  Bunta uses the distraction to get too close.  One of his meaty fists strikes you across the head, causing you to see double.
			*if (showstats)
				(Needed 50 Archery)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
	#Summon flames to blast against the guards.
		*if (magic>=50)
			The guards can't defend themselves as the fire washes over them.  They fall quickly as
			*if (friend2_exists)
				${friend1_name} and ${friend2_name} lend you support.
			*if (friend2_exists=false)
				${friend1_name} lends you support.
			Within seconds, they are all lying dead at your feet.  Bunta uses the distraction to get too close.  One of his meaty fists strikes you across the head, causing you to see double.
			*if (showstats)
				*line_break
				(Magic +2 and Health -50)
			*set magic +2
			*set health -50
			*set breakout_killed_guards true
			*goto Breakout_BuntaFight_WithGuards_2
		*else
			The guards dodge out of the way of the fire as your clumsy casting makes it slow to take effect.  Bunta uses the distraction to get too close.  One of his meaty hands strikes you across the head, causing you to see double.
			*if (showstats)
				(Needed 50 Magic)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
	*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl to attack the guards.
		*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
		Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.  It grins happily at the chance to do some violence as it rushes forward to fight the guards.
		
		*set demonstone_brahl_used true
		Within seconds, they are all lying dead at your feet.  Having killed the guards, Brahl returns to its own realm.  Bunta uses the distraction to get too close.  One of his meaty hands strikes you across the head, causing you to see double.
		*if (showstats)
			*line_break
			(Health -50)
		*set health -50
		*set breakout_killed_guards true
		*goto Breakout_BuntaFight_WithGuards_2
	*if (((companion_name!="None") and (companion_injured=false)) and ((((companion_type="firedrake") or (companion_type="wolf")) or ((companion_type="griffin") or (companion_type="owlbear"))) or (companion_type="bear"))) #Tell ${companion_name}, your ${companion_type}, to attack the guards.
		The ${companion_type} does as ${companion_heshe} is told, rushing forward and tearing into the poor guards.  With
		*if (friend2_exists)
			${friend1_name} and ${friend2_name}
		*if (friend2_exists=false)
			${friend1_name}
		lending support, the battle is quickly ended.  Unfortunately, one of the blades strikes ${companion_name} in the side, cutting deeply into ${companion_himher}.  $!{companion_heshe} will live, but likely won't be much use in another fight right away.  Meanwhile, Bunta uses the distraction to get too close.  One of his meaty fists strikes you across the head, causing you to see double.
		*set companion_injured true
		*if (showstats)
			*line_break
			(Health -50)
		*set health -50
		*set breakout_killed_guards true
		*goto Breakout_BuntaFight_WithGuards_2
	*if (sword) #Draw your own sword and deal with Bunta first.
		*if (blades>=75)
			The big fat man does not expect such a swift response.  You slash at his bulk a few times, cutting large red gashes across his side.  The guards don't stand idle as they swing their blades at you, slicing a deep gash across your own side.
			*set bunta_health -50
			*if (showstats)
				*line_break
				(Blades +2, Health -50 and Bunta Health -50 to ${bunta_health} / 100)
			*set blades +2
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
		*else
			You have trouble penetrating the thick skin of the blubbery warden. The guards don't stand idle as they swing their blades at you, slicing a deep gash across your own side. 
			*if (showstats)
				(Needed 75 Blades)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
	#Kick Bunta between the legs.
		*if (unarmed>=75)
			The big fat man does not expect such a swift response.  You strike him solidly between the legs and he groans from the pain.  The guards don't stand idle as they swing their blades at you, slicing a deep gash across your side.
			*set bunta_health -50
			*if (showstats)
				*line_break
				(Unarmed +2, Health -50 and Bunta Health -50 to ${bunta_health} / 100)
			*set unarmed +2
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
		*else
			The big fat man turns his body so that you strike his blubbery leg instead of where you were aiming.  The guards don't stand idle as they swing their blades at you, slicing a deep gash across your side. 
			*if (showstats)
				(Needed 75 Unarmed)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
	*if (dagger) #Throw your dagger at Bunta.
		*if (blades>=40)
			The big fat man does not expect such a swift response.  Your dagger lodges deeply into his enormous bulk.  You can't be sure how much damage it does, considering the mountainous rolls of fat that it has embedded itself into.
			*set bunta_health -50
			*if (showstats)
				*line_break
				(Lost Dagger, Blades +2, Health -50 and Bunta Health -50 to ${bunta_health} / 100)
			*set dagger_used true
			*set dagger false
			*set blades +2
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
		*else
			The fat ogre-like man swats the small blade out of the air as though it were a bothersome fly.  His meaty hand draws back a second time and clubs you in the face in the same manner, causing you to see double. 
			*if (showstats)
				(Needed 40 Blades)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
	*if (bow) #Draw your bow and fire upon Bunta first.
		*if (archery>=75)
			The big fat man does not expect such a swift response.  Your arrows drive deep into his bulk a few times, forcing him to slow down.  The guards don't stand idle as they swing their blades at you, slicing a deep gash across your side.
			*set bunta_health -50
			*if (showstats)
				*line_break
				(Archery +2, Health -50 and Bunta Health -50 to ${bunta_health} / 100)
			*set archery +2
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
		*else
			You have trouble penetrating the thick skin of the blubbery warden with your arrows, turning what should have been lethal strikes into mere annoyances for the man. The guards don't stand idle as they swing their blades at you, slicing a deep gash across your side. 
			*if (showstats)
				(Needed 75 Archery)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
	#Summon flames to blast against Bunta.
		*if (magic>=75)
			The fire washes over the blubbery warden and causes a terrible smell to fill the air, but it doesn't stop him.  The guards don't stand idle as they swing their blades at you, slicing a deep gash across your side.
			*set bunta_health -50
			*if (showstats)
				*line_break
				(Magic +2, Health -50 and Bunta Health -50 to ${bunta_health} / 100)
			*set magic +2
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
		*else
			The fire washes over the blubbery warden and causes a terrible smell to fill the air, but the fire is not as punishing as it should have been.  The guards don't stand idle as they swing their blades at you, slicing a deep gash across your side.
			*if (showstats)
				(Needed 75 Magic)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_WithGuards_2
	*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl to attack Bunta.
		*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
		Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.  It grins happily at the chance to do some violence as it rushes forward to fight Bunta.
		
		*set demonstone_brahl_used true
		Although the demon cuts deeply into the fat man, Bunta barely slows down.  With two meaty hands, he reaches out and breaks the demon's neck, causing Brahl to return to its own realm.  The guards don't stand idle as they swing their blades at you, slicing a deep gash across your side.
		*set bunta_health -50
		*if (showstats)
			*line_break
			(Health -50 and Bunta Health -50 to ${bunta_health} / 100)
		*set health -50
		*goto Breakout_BuntaFight_WithGuards_2
	*if (((companion_name!="None") and (companion_injured=false)) and ((((companion_type="firedrake") or (companion_type="wolf")) or ((companion_type="griffin") or (companion_type="owlbear"))) or (companion_type="bear"))) #Tell ${companion_name}, your ${companion_type}, to attack Bunta.
		Although ${companion_name} cuts deeply into the fat man, Bunta barely slows down.  With two meaty hands, he grabs hold of ${companion_name} and throws ${companion_himher} across the room and into the wall.  Your poor ${companion_type} falls to the ground dazed, clearly out of the fight. The guards don't stand idle as they swing their blades at you, slicing a deep gash across your side.
		*set bunta_health -50
		*set companion_injured true
		*if (showstats)
			*line_break
			(Health -50 and Bunta Health -50 to ${bunta_health} / 100)
		*set health -50
		*goto Breakout_BuntaFight_WithGuards_2

*label Breakout_BuntaFight_WithGuards_2
*comment Bunta can be at 50/100 health at this point, but no lower since the only other damage would come from fighting Bunta alone.
*if (health<=0)
	You feel darkness closing in as your wounds overwhelm you, causing you to fall to the ground.
	*goto Breakout_Health0
*if (breakout_killed_guards)
	*if (theothea_inparty)
		${theothea_name} swings ${theothea_hisher} mighty warhammer at Bunta with blinding speed.  The blubbery warden grunts at the
		*set bunta_health -50
		*if (bunta_health<=0)
			impact as his head cracks open.  You see Bunta's lifeless corpse collapse to the ground.
			*if (showstats)
				*line_break
				(Bunta Health -50 to 0 / 100)
			*goto Breakout_BuntaHealth0
		impact, but does not fall.  With a mighty backhand, Bunta strikes ${theothea_name} back, sending your friend to the ground in a daze.
		*set theothea_injured true
		*gosub InjureFriends
		*if (showstats)
			*line_break
			(Bunta Health -50 to ${bunta_health} / 100)
		*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*if (jacejess_inparty)
		${jacejess_name}'s eyes glow white and the scorching begins.  Bunta takes a long sizzling burn across his blubbery
		*set bunta_health -50
		*if (bunta_health<=0)
			neck, nearly cutting his head right off.  You see Bunta's lifeless corpse collapse to the ground.
			*if (showstats)
				*line_break
				(Bunta Health -50 to 0 / 100)
			*goto Breakout_BuntaHealth0
		belly, but with a mighty backhand, he strikes ${jacejess_name} in the face, sending your friend to the ground in a daze.
		*set jacejess_injured true
		*gosub InjureFriends
		*if (showstats)
			*line_break
			(Bunta Health -50 to ${bunta_health} / 100)
		*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*if (karlkarla_inparty)
		${karlkarla_name} uses your distraction to draw ${karlkarla_hisher} bow and begin peppering Bunta with arrows.
		*set bunta_health -50
		*if (bunta_health<=0)
			You see Bunta's lifeless corpse collapse to the ground.
			*if (showstats)
				*line_break
				(Bunta Health -50 to 0 / 100)
			*goto Breakout_BuntaHealth0
		The blubbery warden charges toward your friend and knocks ${karlkarla_name} to the ground in a dazed heap.
		*set karlkarla_injured true
		*gosub InjureFriends
		*if (showstats)
			*line_break
			(Bunta Health -50 to ${bunta_health} / 100)
		*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*if (gillgale_inparty)
		${gillgale_name} uses your distraction to draw both of ${gillgale_hisher} short swords.  With a mighty leap, ${gillgale_heshe} drives them both into Bunta's
		*set bunta_health -50
		*if (bunta_health<=0)
			back.  You see Bunta's lifeless corpse collapse to the ground.
			*if (showstats)
				*line_break
				(Bunta Health -50 to 0 / 100)
			*goto Breakout_BuntaHealth0
		back, but amazingly, the blubbery warden pushes backward into a wall and crushes ${gillgale_name} between his bulk and the stone, dropping your friend to the ground in a daze.
		*set gillgale_injured true
		*gosub InjureFriends
		*if (showstats)
			*line_break
			(Bunta Health -50 to ${bunta_health} / 100)
		*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*comment Just PeterPetra left
	A holy fervor enters ${peterpetra_name} as ${peterpetra_heshe} draws ${peterpetra_hisher} morningstar and begins to strike
	*set bunta_health -50
	*if (bunta_health<=0)
			Bunta in his unprotected head.  You see Bunta's lifeless corpse collapse to the ground.
			*if (showstats)
				*line_break
				(Bunta Health -50 to 0 / 100)
			*goto Breakout_BuntaHealth0
	Bunta.  With a mighty backhand, Bunta strikes ${peterpetra_name} back, sending your friend to the ground in a daze.
	*set peterpetra_injured true
	*gosub InjureFriends
	*if (showstats)
		*line_break
		(Bunta Health -50 to ${bunta_health} / 100)
	*goto Breakout_BuntaFight_ThirdRound_NoGuards
*else
	*set breakout_killed_guards true
	*if (theothea_inparty)
		${theothea_name} swings ${theothea_hisher} mighty warhammer with such ferocity that ${theothea_heshe} manages to kill two guards with each blow.  It takes only a few seconds before they are all dead.
		*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*if (jacejess_inparty)
		${jacejess_name}'s eyes glow white and the burning begins.  The guards don't stand a chance against the might of the Soulburner as ${jacejess_heshe} cuts them into quivering smoking pieces.
		*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*if (karlkarla_inparty)
		${karlkarla_name} uses your distraction to draw ${karlkarla_hisher} bow and turn the guards into pin cushions.  They futilely attempt to block the arrows with their swords, but within seconds, they are all dead.
		*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*if (gillgale_inparty)
		${gillgale_name} uses your distraction to circle around the guards and draw both of ${gillgale_hisher} short swords.  $!{gillgale_heshe} makes short work of their unprotected backs, cutting them to ribbons and leaving their bloody corpses on the floor.
		*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*comment Just PeterPetra left
	A holy fervour enters ${peterpetra_name} as ${peterpetra_heshe} draws ${peterpetra_hisher} morningstar and engages the guards.  It takes only a few seconds before they are all dead.
	*goto Breakout_BuntaFight_ThirdRound_NoGuards

*label Breakout_BuntaFight_NoGuards
*comment Either killed guards, or went around guards, or snuck in, so Bunta could be at 50 / 100
*choice
	*if (sword) #Draw your sword and attack Bunta.
		*if (blades>=75)
			You slash at his bulk a few times, cutting large red gashes across his side.
			*label BuntaFight_NoGuards_BladeHit
			*set bunta_health -50
			*if (showstats)
				*line_break
				(Blades +2 and Bunta Health -50 to ${bunta_health} / 100)
			*set blades +2
			*goto Breakout_BuntaFight_ThirdRound_NoGuards
		*else
			*label BuntaFight_NoGuards_BladeMiss
			You have trouble penetrating the thick skin of the blubbery warden as your blade slashes ineffectually across his stomach.  Your vision blurs for a moment as Bunta's enormous fist drives into your face.
			*if (showstats)
				(Needed 75 Blades)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*if (dagger) #Draw your dagger and attack Bunta.
		*if (blades>=75)
			You stab into his bulk a few times, causing many red holes to leak blood.
			*goto BuntaFight_NoGuards_BladeHit
		*else
			*goto BuntaFight_NoGuards_BladeMiss
	*if (bow) #Draw your bow and fill Bunta full of arrows.
		*if (archery>=75)
			The big fat man does not expect such a swift response.  Your arrows drive deep into his bulk a few times.
			*set bunta_health -50
			*if (showstats)
				*line_break
				(Archery +2 and Bunta Health -50 to ${bunta_health} / 100)
			*set archery +2
			*goto Breakout_BuntaFight_ThirdRound_NoGuards
		*else
			You have trouble penetrating the thick skin of the blubbery warden with your arrows, turning what should have been lethal strikes into mere annoyances for the man. Your vision blurs for a moment as Bunta's enormous hamfist drives into your face.
			*if (showstats)
				(Needed 75 Archery)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_ThirdRound_NoGuards
	#Try to punch Bunta while staying out of his reach.
		Big men like Bunta are often enormously strong, but also very slow.  Bunta is no different.
		*if (unarmed>=75)
			You are able to keep out of his reach when he swings his big punches at you and then get in close and pepper his face with short brutal jabs.  His cheeks swell up and his nose breaks.  He was ugly before, but your ministrations make him look even worse.
			*set bunta_health -50
			*if (bunta_health<=0)
				One final punch into his temple causes his eyes to roll back in his head.
			*if (showstats)
				*line_break
				(Unarmed +2 and Bunta Health -50 to ${bunta_health} / 100)
			*set unarmed +2
			*goto Breakout_BuntaFight_ThirdRound_NoGuards
		*else
			You punch at his bulk, but it's like striking a bag of clay.  You get a little too close and your vision blurs for a moment as Bunta's enormous fist drives into your face.
			*if (showstats)
				(Needed 75 Unarmed)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_ThirdRound_NoGuards
	#Summon flames to blast against Bunta.
		*if (magic>=75)
			The fire washes over the blubbery warden and causes a terrible smell to fill the air.
			*set bunta_health -50
			*if (showstats)
				*line_break
				(Magic +2 and Bunta Health -50 to ${bunta_health} / 100)
			*set magic +2
			*goto Breakout_BuntaFight_ThirdRound_NoGuards
		*else
			You barely begin your spell when your vision blurs for a moment as Bunta's enormous hamfist smashes into your face, driving the spell out of your mind.
			*if (showstats)
				(Needed 75 Magic)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl to attack Bunta.
		*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
		Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.  It grins happily at the chance to do some violence as it rushes forward to fight Bunta.
		
		*set demonstone_brahl_used true
		Brahl's claws slash their way into the fat man's blubbery belly as though they are digging through mud.  Gore flies until Bunta takes hold of Brahl and twists the demon's neck, making it pop out of existence.
		*set bunta_health -50
		*if (showstats)
			*line_break
			(Bunta Health -50 to ${bunta_health} / 100)
		*goto Breakout_BuntaFight_ThirdRound_NoGuards
	*if (((companion_name!="None") and (companion_injured=false)) and ((((companion_type="firedrake") or (companion_type="wolf")) or ((companion_type="griffin") or (companion_type="owlbear"))) or (companion_type="bear"))) #Tell ${companion_name}, your ${companion_type}, to attack Bunta.
		${companion_name} cuts deeply into the fat
		*set bunta_health -50
		*if (bunta_health<=0)
			man, staying out of Bunta's pudgy reach while tearing him up.  You see Bunta's lifeless corpse collapse to the ground.
			*if (showstats)
				*line_break
				(Bunta Health -50 to 0 / 100)
			*goto Breakout_BuntaHealth0
		man.  With two meaty hands, Bunta grabs hold of ${companion_name} and throws ${companion_himher} across the room and into the wall.  Your poor ${companion_type} falls to the ground dazed, clearly out of the fight.
		*set companion_injured true
		*if (showstats)
			*line_break
			(Bunta Health -50 to ${bunta_health} / 100)
		*goto Breakout_BuntaFight_ThirdRound_NoGuards

*label Breakout_BuntaFight_ThirdRound_NoGuards
*comment If fought guards, then Bunta or MC may have 0 health
*comment If snuck in, Bunta may be 0, MC can only be down to 50
*comment If bypassed guards, or fought guards, Bunta can only be half health.
*if (health<=0)
	*goto Breakout_Health0
*if (bunta_health<=0)
	
	You see Bunta's ruined body collapse to the ground as a final gasp escapes his dying lips.
	*goto Breakout_BuntaHealth0_ns
	
	*label Breakout_BuntaHealth0
	
	*label Breakout_BuntaHealth0_ns
	*set bunta_dead true
	You catch your breath as you
	*if (dagger_used)
		*set dagger_used false
		pick up your dagger and
		*set dagger true
	look around the fat warden's room. A small lockbox under the cot gets your attention. It looks like Bunta had been stealing precious mementos from his prisoners.  When you pry the box open, you find it empty!  But as you look closer, you realize that what you had first thought was a very dark shadow is actually a cape.  You pull the Cape of Shadows from the box and look at it in amazement.  There is no way to know who owned the valuable artifact and its owner is likely dead now anyway.
	*if (showstats)
		*line_break
		(Gained the Cape of Shadows and Gained +${cape_of_shadows_bonus} Stealth Bonus)
	*set cape_of_shadows true
	*set stealth +cape_of_shadows_bonus
	
	The ${prisonchild_boygirl} on the bed watches on and says nothing.
	*label Breakout_TakeOrLeaveChild
	${friend1_name} staggers over to the body and takes the keys from the fat warden's
	*if (dagger_used=false)
		corpse.
	*if (dagger_used)
		corpse while you retrieve your dagger.
		*set dagger_used false
		*set dagger true
	*choice
		#Leave the child.
			The ${prisonchild_boygirl} doesn't even look up as you leave ${prisonchild_himher} on the bed.
			*if (showstats)
				*line_break
				(Evil +5)
			*set good -5
			*set prisonchild_exists false
			*goto Breakout_NoBunta_CheckGuard
		#Take the child with you.
			The ${prisonchild_boygirl} follows you like a lost puppy.
			*if (showstats)
				*line_break
				(Good +5)
			*set good +5
			*set prisonchild_exists true
			*label Breakout_NoBunta_CheckGuard
			*if (breakout_killed_guards=false)
				
				*if (breakout_foundthem=false)
					You leave the room and resume your search for your friends' cell.  Since you don't exactly know where to look, you end up stumbling upon a group of guards.  Seeing you in the halls without the fat warden, they don't even bother to speak as they draw their swords and attack.
					*if (health>0)
						*goto Breakout_GuardsOnlyFight_choice
					*else
						*goto Breakout_KillGuards
				*else
					You leave the room and go directly to where you know your friends' cell is.
					*goto Breakout_NoGuardsNoBunta_noexplain
			*else
				*goto Breakout_NoGuardsNoBunta
*if (health<=0)
	*label Breakout_Health0
	
	Everything is dim and grey as you struggle to keep your eyes open.  You watch in horror as Bunta takes hold of ${friend1_name}'s head and smashes it against the floor, knocking ${friend1_himher} out.
	*if (friend2_exists)
		${friend2_name} tries to use the distraction, but Bunta picks up ${friend1_name}'s unconscious body and throws ${friend1_himher} into ${friend2_name}, knocking them both to the ground in a tangled heap.
	You watch helplessly as Bunta advances upon you, a sick and sadistic smile spreading across his flabby face.  His thick sausage fingered hands reach out for you and wrap tightly around your neck.  Darkness begins to fill your vision, when suddenly, Bunta's eyes open wide in surprise.
	*if (health<5)
		*if (showstats)
			*line_break
			(Health +5 to 5 / 100)
	*set health 5
	
	You barely roll aside as Bunta's enormous body comes crashing down toward you, a large crossbow bolt emerging from his back.  Still sitting on the bed and holding the crossbow itself is the young ${prisonchild_boygirl}.  $!{prisonchild_heshe} still has a blank stare as ${prisonchild_heshe} lets the spent weapon fall from ${prisonchild_hisher} grip and onto the floor.  You aren't even sure when the child took the crossbow from Bunta's belt.
	*set bunta_dead true
	*goto Breakout_TakeOrLeaveChild
*else
	*comment Bunta alone, may be half, MC may be half, demons, companion and friend may be injured
	
	Bunta interlocks his big fingers and cracks them before taking a lumbering step toward you.
	*choice
		*if (sword) #Swing your sword at Bunta.
			To your surprise, the fat man catches the sword in mid-air and grins.  His thick skin stops the blade from slicing off his fingers as he steps closer toward you.
			*goto Breakout_BuntaClose
		*if (dagger) #Slash your dagger at Bunta.
			To your surprise, the fat man catches the dagger in mid-air and grins.  His thick skin stops the blade from slicing off his fingers as he steps closer toward you.
			*set breakout_usingdagger true
			*goto Breakout_BuntaClose
		#Punch Bunta.
			To your surprise, the fat man catches your fist in mid-air and grins.  Holding your hand in his, he steps closer to you.
			*goto Breakout_BuntaClose
		#Cast a bolt of electricity at Bunta.
			You are in mid-gesture when the fat man catches your hand in mid-air and grins.  The spell breaks without going off as he steps closer to you.
			*goto Breakout_BuntaClose
	*label Breakout_BuntaClose
	*choice
		*if (ki_strike) #Hit Bunta with your Ki Strike.
			The fat man was foolish to let a ${mc_manwoman} of your talent get so close.  You strike him in the stomach with the palm of your hand.  Ripples of fat radiate from the blow as he releases you and steps back.  You know that you have liquidated the majority of the big man's organs.  You see Bunta's ruined body collapse to the ground as a final gasp escapes his dying lips.
			*if (showstats)
				*line_break
				(Bunta Health -${bunta_health} to 0 / 100)
			*goto Breakout_BuntaHealth0
		*if (jeckel_potion) #Let the rage build.
			The veins in your neck begin to bulge and the blood pounds in your temples.  Was this what Mazrim felt?  Bunta's eyes open wide as you struggle to control your anger.  Mindlessly, you find yourself lashing out with your free hand, striking Bunta in the face again and again.  You feel his nose smashing under your fist and he staggers back.  You step forward, pounding him with both hands.  There is no finesse to your attack and no intelligence.  You snarl and spit.
			
			When you finally calm down, you see that your hands are covered in blood to your wrists and Bunta is struggling to breathe as his heart gives out from your violent assault.  Bunta's ruined body collapses to the ground as a final gasp escapes his dying lips.  ${friend1_name} stands back cautiously as you get to your feet.  For a brief second, you consider resuming your pounding on your friend, and then the urge passes.
			*if (showstats)
				*line_break
				(Bunta Health -${bunta_health} to 0 / 100)
			*goto Breakout_BuntaHealth0
		*if (infinity_arrow) #Tell ${karlkarla_name} to use the Infinity Arrow.
			*if (karlkarla_injured)
				Despite ${karlkarla_name}'s injury,
			*if (karlkarla_injured=false)
				${karlkarla_name} wastes no time as
			${karlkarla_heshe} sets the arrow to ${karlkarla_hisher} bowstring.  The arrow flies with uncanny accuracy into Bunta's heart.  The big man releases his hold on you and staggers back a step.  You see Bunta's ruined body collapse to the ground as a final gasp escapes his dying lips.  The Infinity Arrow is no more.
			*set infinity_arrow false
			*if (showstats)
				*line_break
				(Bunta Health -${bunta_health} to 0 / 100)
			*goto Breakout_BuntaHealth0
		*if ((companion_type="spider") and (companion_name!="None")) #Watch as ${companion_name}, your spider, crawls out of your sleeve, down your arm and onto Bunta's hand.
			The spider digs its fangs into the fat man and injects its poison.  Bunta releases you and throws ${companion_name} across the room.  You see ${companion_name} sitting on the ground in a daze.  Injured, but okay.
			*set companion_injured true
			*set bunta_health -50
			*if (showstats)
				*line_break
				(Bunta Health -50 to ${bunta_health} / 100)
			*goto Breakout_Bunta_LastChanceToKill
		#Grab Bunta's wrist and twist.
			*if (unarmed>=70)
				Big fat men often think that strength and bulk are all that is needed to win a fight.
				*label Breakout_TwistAndSnap
				You disabuse Bunta of that notion as you twist his wrist and pull him forward, using his own weight against him.  You hear the bones snap as he
				*set bunta_health -50
				*if (bunta_health<=0)
					grunts with pain.  His great bulk makes the fall fatal as his head bounces off the stone floor with a sickening crunch. 
				*if (bunta_health>0)
					pulls his hand free.
				*if (showstats)
					*line_break
					(Unarmed +2 and Bunta Health -50 to ${bunta_health} / 100)
				*set unarmed +2
				*goto Breakout_Bunta_LastChanceToKill
			*if (strength>=70)
				The fat man thinks he is stronger than you.
				*goto Breakout_TwistAndSnap
			Bunta holds firm, showing that he is much stronger than you.  He drives his massive forehead into your face.  You feel blood pour from your nose as you stagger away from the big man.
			*if (showstats)
				(Needed 70 Strength or 70 Unarmed)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_Bunta_LastChanceToKill
		*if ((dagger) and (breakout_usingdagger=false)) #Draw your dagger with your other hand and repeatedly ram it into Bunta's side.
			*if (blades>=70)
				You stab him repeatedly into his unprotected side, feeling the warm blood splash against your hand.  He lets go of you and staggers back.
				*set bunta_health -50
				*if (showstats)
					*line_break
					(Blades +2 and Bunta Health -50 to ${bunta_health} / 100)
				*set blades +2
				*goto Breakout_Bunta_LastChanceToKill
			*else
				You barely cut into his massive bulk with the tiny blade.  He drives his massive forehead into your face.  You feel blood pour from your nose as you stagger away from the big man.
				*if (showstats)
					(Needed 70 Blades)
					*line_break
					(Health -50)
				*set health -50
				*goto Breakout_Bunta_LastChanceToKill
		#Call out to ${friend1_name} for help.
			*if (friend1_injured)
				You can tell from the dazed look in ${friend1_name}'s eyes that ${friend1_heshe} is unable to help you due to ${friend1_hisher} injuries.
				*goto Breakout_BuntaClose
			*set breakout_tempfriend_name friend1_name
			*goto Breakout_Bunta_FriendHelps
		*if (friend2_name!="None") #Call out to ${friend2_name} for help.
			*if (friend2_injured)
				You can tell from the dazed look in ${friend2_name}'s eyes that ${friend2_heshe} is unable to help you due to ${friend1_hisher} injuries.
				*goto Breakout_BuntaClose
			*set breakout_tempfriend_name friend2_name
			*label Breakout_Bunta_FriendHelps
			*if (breakout_tempfriend_name=theothea_name)
				${theothea_name} uses the distraction to swing ${theothea_hisher} warhammer at Bunta's head.  It strikes the fat man with a sickening plunk.
			*if (breakout_tempfriend_name=jacejess_name)
				${jacejess_name} uses the distraction to place a hand on Bunta's fat neck.  ${jacejess_name}'s eyes glow white for a moment and smoke erupts from where ${jacejess_hisher} hand is touching the flesh.
			*if (breakout_tempfriend_name=gillgale_name)
				${gillgale_name} uses the distraction to plunge one of ${gillgale_hisher} swords into Bunta's back.
			*if (breakout_tempfriend_name=peterpetra_name)
				${peterpetra_name} uses the distraction to slam ${peterpetra_hisher} morningstar against the back of Bunta's head.  It strikes the fat man with a sickening plunk.
			*if (breakout_tempfriend_name=karlkarla_name)
				${karlkarla_name} uses the distraction to knock an arrow onto ${karlkarla_hisher} string.  The projectile strikes Bunta in the back of the neck with a sickening plunk.
			*set bunta_health -50
			*if (showstats)
				*line_break
				(Bunta Health -50 to ${bunta_health} / 100)
			*goto Breakout_Bunta_LastChanceToKill

	*label Breakout_Bunta_LastChanceToKill
	*if (bunta_health<=0)
		*goto Breakout_BuntaHealth0
	*if (health<=0)
		*goto Breakout_Health0
	
	Bunta roars in challenge and rushes toward you, intending to end the fight.
	*choice
		*if (magic_shield) #Raise your magic shield.
			Any normal shield would have simply been bashed into you, sending you flying across the room by the enormous man's charge.  But instead, the magic of this shield causes Bunta to stop abruptly as his head cracks open on its surface.  You see Bunta's ruined body collapse to the ground as a final gasp escapes his dying lips.
			*if (showstats)
				*line_break
				(Bunta Health -${bunta_health} to 0 / 100)
			*goto Breakout_BuntaHealth0
		#Dodge out of the way.
			*if (agility>=70)
				You step aside at the last moment.  Bunta runs headfirst into the wall behind you, smashing his skull open.  He staggers back for a moment as blood runs from the massive wound.  You see Bunta's ruined body collapse to the ground as a final gasp escapes his dying lips.
				*if (showstats)
					*line_break
					(Agility +2 and Bunta Health -${bunta_health} to 0 / 100)
				*set agility +2
				*goto Breakout_BuntaHealth0
			*else
				You try to get out of the way, but your reflexes aren't what you thought.  Bunta crashes into you, knocking you to the ground.
				*if (showstats)
					(Needed 70 Agility)
					*line_break
					(Health -${health})
				*set health 0
				*goto Breakout_Health0
		#Cast a dimensional Blink spell to get out of the way.
			*if (magic>=90)
				Bunta roars as he runs toward you, but suddenly, you are two feet to the left.  The fat man rushes headfirst into the wall behind where you had been, smashing his skull open.  He staggers back for a moment as blood runs from the massive wound.  You see Bunta's ruined body collapse to the ground as a final gasp escapes his dying lips.
				*if (showstats)
					*line_break
					(Magic +2 and Bunta Health -${bunta_health} to 0 / 100)
				*set magic +2
				*goto Breakout_BuntaHealth0
			*else
				You are just about to finish the spell when Bunta crashes into you, knocking you to the ground.
				*if (showstats)
					(Needed 90 Magic)
					*line_break
					(Health -${health})
				*set health 0
				*goto Breakout_Health0
		*if (sword) #Take the hit and attempt to strike Bunta with your sword.
			*label Breakout_Bunta_LastBladeStrike
			*set health -50
			*if (health<=0)
				Bunta's charge knocks you to the ground and makes you forget all about trying to strike back.
				*if (showstats)
					*line_break
					(Health -50)
				*goto Breakout_Health0
			*else
				You drive your blade downward and into the massive man as the breath is knocked out of you.  He staggers backward, causing your sword to slide out of him with a slow smucking sound.  You see Bunta's ruined body collapse to the ground as a final gasp escapes his dying lips.
				*if (showstats)
					*line_break
					(Blades +2, Health -50 and Bunta Health -${bunta_health} to 0 / 100)
				*set blades +2
				*goto Breakout_BuntaHealth0
		*if (dagger) #Take the hit and attempt to strike Bunta with your dagger.
			*goto Breakout_Bunta_LastBladeStrike
		*if ((class_bard>=0) and (lute)) #Strum a discordant arpeggio on your lute.
			The terrible sound is enough to make Bunta miss a step and allow you to step to the side.  The fat man's momentum causes him to run headfirst into the wall behind you, smashing his skull open.  You see Bunta's ruined body collapse to the ground as a final gasp escapes his dying lips.
			*if (showstats)
				*line_break
				(Bunta Health -${bunta_health} to 0 / 100)
			*goto Breakout_BuntaHealth0

*label Breakout_GuardsOnlyFight

*set breakout_killed_guards true
The guards are startled at first, but they know their job and immediately draw their swords.
*if (breakout_metguards)
	One of them even seems to recognize you, but you can tell that he will try to stop you anyway.
*label Breakout_GuardsOnlyFight_choice
*choice
	*if (sword) #Draw your own sword and deal with them swiftly.
		*if (blades>=50)
			The guards are quickly overwhelmed, especially when
			*if (friend2_exists)
				${friend1_name} and ${friend2_name} lend you support.
			*if (friend2_exists=false)
				${friend1_name} lends you support.
			Within seconds, they are all lying dead at your feet.
			*if (showstats)
				*line_break
				(Blades +2)
			*set blades +2
			*goto Breakout_AfterGuardFight
		*else
			The guards assume a defensive formation and lash out with their own swords.  You manage to kill one of them, but the others quickly fill in the gap.  You feel a stinging sensation on your shoulder and glance down to see a bloody cut from one of their blades.
			*if (showstats)
				(Needed 50 Blades)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_GuardsOnlyFight_Round2
	#Fight the guards with your fists and feet.
		Normally, you'd think that being outnumbered would work against you.  But, in the cramped corridors, they had to come at you one at a time anyway.
		*if (unarmed>=50)
			The guards are quickly overwhelmed, especially when
			*if (friend2_exists)
				${friend1_name} and ${friend2_name} lend you support.
			*if (friend2_exists=false)
				${friend1_name} lends you support.
			Within seconds, they are all lying dead at your feet.
			*if (showstats)
				*line_break
				(Unarmed +2)
			*set unarmed +2
			*goto Breakout_AfterGuardFight
		*else
			The guards assume a defensive formation and lash out with their swords.  You manage to kill one of them, but the others quickly fill in the gap.  You feel a stinging sensation on your shoulder and glance down to see a bloody cut from one of their blades.
			*if (showstats)
				(Needed 50 Unarmed)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_GuardsOnlyFight_Round2
	*if (bow) #Draw your bow and attempt to end the fight.
		*if (archery>=50)
			The guards can't defend themselves with their swords as you fire arrows into them.  The battle ends quickly as
			*if (friend2_exists)
				${friend1_name} and ${friend2_name} lend you support.
			*if (friend2_exists=false)
				${friend1_name} lends you support.
			Within seconds, they are all lying dead at your feet.
			*if (showstats)
				*line_break
				(Archery +2)
			*set archery +2
			*goto Breakout_AfterGuardFight
		*else
			You manage to kill two of the guards before they close the distance, making your bow inefficient in the tight confines of the prison tunnels.  You feel a stinging sensation on your shoulder and glance down to see a bloody cut from one of their blades.
			*if (showstats)
				(Needed 50 Archery)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_GuardsOnlyFight_Round2
	#Summon flames to blast against the guards.
		*if (magic>=50)
			The guards can't defend themselves as the fire washes over them.  The battle ends quickly as
			*if (friend2_exists)
				${friend1_name} and ${friend2_name} lend you support.
			*if (friend2_exists=false)
				${friend1_name} lends you support.
			Within seconds, they are all lying dead at your feet.
			*if (showstats)
				*line_break
				(Magic +2)
			*set magic +2
			*goto Breakout_AfterGuardFight
		*else
			The guards dodge out of the way of the fire as your clumsy casting makes it slow to take effect.  You feel a stinging sensation on your shoulder and glance down to see a bloody cut from one of their blades.
			*if (showstats)
				(Needed 50 Magic)
				*line_break
				(Health -50)
			*set health -50
			*goto Breakout_GuardsOnlyFight_Round2
	*if (((demonstone_brahl) and (demonstone_brahl_summoned)) and ((demonstone_brahl_used=false) and (demonsummoner))) #Summon Brahl to attack the guards.
		*comment Brahl: Willing: 50, Small Struggle: 60, Against: 70
		Brahl appears before you.  It's six feet tall with large square shoulders and dark leathery skin that's covered in scaly warts.  It has a pair of short stubby horns protruding from its forehead.  It grins happily at the chance to do some violence as it rushes forward to fight the guards.
		
		*set demonstone_brahl_used true
		Within seconds, they are all lying dead at your feet.  Having killed the guards, Brahl returns to its own realm.
		*goto Breakout_AfterGuardFight
	*if (((companion_name!="None") and (companion_injured=false)) and ((((companion_type="firedrake") or (companion_type="wolf")) or ((companion_type="griffin") or (companion_type="owlbear"))) or (companion_type="bear"))) #Tell ${companion_name}, your ${companion_type}, to attack.
		The ${companion_type} does as ${companion_heshe} is told, rushing forward and tearing into the poor guards.  With
		*if (friend2_exists)
			${friend1_name} and ${friend2_name}
		*if (friend2_exists=false)
			${friend1_name}
		lending support, the battle is quickly ended.  Unfortunately, one of the blades strikes ${companion_name} in the side, cutting deeply into ${companion_himher}.  $!{companion_heshe} will live, but likely won't be much use in another fight right away. 
		*set companion_injured true
		*goto Breakout_AfterGuardFight

*label Breakout_GuardsOnlyFight_Round2
*if (health<=0)
	*comment Possible, if Bunta is fought first, then goes to Guards.
	The blood loss makes you fall to the floor, but you manage to hold onto consciousness.
	*if (showstats)
		*line_break
		(Health +5 to 5 / 100)
	*set health 5
*label Breakout_KillGuards
*set breakout_killed_guards true

*if (theothea_inparty)
	${theothea_name} swings ${theothea_hisher} mighty warhammer with such ferocity that ${theothea_heshe} manages to kill two guards with each blow.  It takes only a few seconds before they are all dead.
	*goto Breakout_AfterGuardFight
*if (jacejess_inparty)
	${jacejess_name}'s eyes glow white and the burning begins.  The guards don't stand a chance against the might of the Soulburner as ${jacejess_heshe} cuts them into quivering smoking pieces.
	*goto Breakout_AfterGuardFight
*if (karlkarla_inparty)
	${karlkarla_name} uses your distraction to draw ${karlkarla_hisher} bow and turn the guards into pin cushions.  They futilely attempt to block the arrows with their swords, but within seconds, they are all dead.
	*goto Breakout_AfterGuardFight
*if (gillgale_inparty)
	${gillgale_name} uses your distraction to circle around the guards and draw both of ${gillgale_hisher} short swords.  $!{gillgale_heshe} makes short work of their unprotected backs, cutting them to ribbons and leaving their bloody corpses on the floor.
	*goto Breakout_AfterGuardFight
*comment Just PeterPetra left
A holy fervour enters ${peterpetra_name} as ${peterpetra_heshe} draws ${peterpetra_hisher} morningstar and engages the guards.  It takes only a few seconds before they are all dead.
*label Breakout_AfterGuardFight

*if (bunta_dead=false)
	With the guards subdued, you can continue searching for your friends' cell.
	*goto Breakout_FoundBunta
*else
	With the guards subdued, you can take your time searching for your friends' cell.
	*goto Breakout_NoGuardsNoBunta
		
*label Breakout_PrisonTunnel

The tunnel leads straight down.  Every step you take seems to make the air damper, smellier and more oppressive.
*if (breakout_foundthem)
	*label Breakout_FoundBunta
	You follow the many branching tunnels on your way to your destination.  You know that you are very close, but as you open the second to last door, you receive a terrible shock.  It's a small guard room with a dirty cot, a wooden table covered in dirty dishes and the fattest man you have ever seen.  The rumours of Bunta's ogre heritage seem very real as the slug of a man turns his head toward you.  He is wearing a warden's uniform but holds no weapons, although a large crossbow hangs from his hip.  A squeak from the cot catches your attention.  You see a young ${prisonchild_boygirl} sitting there, ${prisonchild_hisher} eyes blank and ${prisonchild_hisher} face empty of any emotion at all.  $!{prisonchild_heshe} is likely a prisoner and lacks any hope of release.
	*goto Breakout_BuntaFight_NoGuards
*else
	At the base of the stairs, the corridor splits in three directions.  Without knowing the way, you take one at random.  To your frustration, the tunnels split again…and again…and again.  One-by-one, you investigate the paths, looking into the cells and seeing hopeless prisoners chained to the walls.  As you round one turn, you inevitably walk into a bunch of guards who are patrolling the dungeons.
	*goto Breakout_GuardsOnlyFight

*label Breakout_NoGuardsNoBunta

You continue onwards and eventually find the door to the cell that is holding your friends.
*label Breakout_NoGuardsNoBunta_noexplain
Using the key salvaged from Bunta's corpse, you unlock the door.  The inside of the cell makes your heart drop into your stomach.  It's empty.
*if (breakout_foundthem)
	This was the cell where your friends were being held.
*if (breakout_foundthem=false)
	You had checked all of the others, and you knew this had to be the cell where your friends were being held.

"We're too late," ${friend1_name} says softly, looking at the empty room.  "They're dead."

"That's half true," a calm voice says from behind you.
*choice
	#You see a man wearing chainmail and a tabard with the Brightwater insignia on it.
		*set branbrinn_name "Bran"
		*set branbrinn_hisher "his"
		*set branbrinn_heshe "he"
		*set branbrinn_himher "him"
		*set branbrinn_manwoman "man"
		The man stands at a very respectable six and a half feet tall.  He has a serious look on his face.  He wears a longsword on his hip and his chainmail looks meticulously well oiled.  His brown hair is well-groomed and his short brown beard is neatly trimmed.  His movements are graceful and you can tell from his athletic build that he is in excellent shape.
		*goto Brightwater_Met_BranBrinn
	#You see a woman wearing chainmail and a tabard with the Brightwater insignia on it.
		*set branbrinn_name "Brinn"
		*set branbrinn_hisher "her"
		*set branbrinn_heshe "she"
		*set branbrinn_himher "her"
		*set branbrinn_manwoman "woman"
		The woman stands at a very respectable six feet tall.  She has a serious look on her face.  She wears a longsword on her hip and her chainmail looks meticulously well oiled.  Her brown hair is of medium length, functional yet stylish.  Her movements are graceful and you can tell from her athletic build that she is in excellent shape.
		*goto Brightwater_Met_BranBrinn

*label Brightwater_Met_BranBrinn
*set stage 2
*set branbrinn_inparty true
*gosub Friend3_getrelationship
*set prisoner1_relationship temp_relationship
*gosub Friend4_getrelationship
*set temp_prisoner2_relationship temp_relationship
*if (prisoner1_lover)
	*goto Keep_P1
*if (prisoner2_lover)
	*goto Keep_P2
*if prisoner1_relationship= temp_prisoner2_relationship
	*rand coinflip 1 2
	*if (coinflip=1)
		*goto Keep_P1
	*else
		*goto Keep_P2
*if (prisoner1_relationship> temp_prisoner2_relationship)
	*label Keep_P1
	*comment This makes sure that friend3 is the friend that stays and friend4 is ready to be lost (and turned into BranBrin)
	*comment NOTE:  In both cases, Prisoner1 is now Selina's bodyguard.
	*set friend3_name prisoner1_name
	*set friend3_hisher prisoner1_hisher
	*set friend3_heshe prisoner1_heshe
	*set friend3_himher prisoner1_himher
	*set friend3_lover prisoner1_lover
	*set friend4_name prisoner2_name
	*set friend4_hisher prisoner2_hisher
	*set friend4_heshe prisoner2_heshe
	*set friend4_himher prisoner2_himher
	*set friend4_lover prisoner2_lover
	*set prisoner1_name prisoner2_name
	*set prisoner1_hisher prisoner2_hisher
	*set prisoner1_heshe prisoner2_heshe
	*set prisoner1_himher prisoner2_himher
	*set prisoner1_relationship temp_prisoner2_relationship
	*set prisoner2_name "None"
*if (prisoner1_relationship< temp_prisoner2_relationship)
	*label Keep_P2
	*comment This makes sure that friend3 is the friend that stays and friend4 is ready to be lost.
	*set friend3_name prisoner2_name
	*set friend3_hisher prisoner2_hisher
	*set friend3_heshe prisoner2_heshe
	*set friend3_himher prisoner2_himher
	*set friend3_lover prisoner2_lover
	*set friend4_name prisoner1_name
	*set friend4_hisher prisoner1_hisher
	*set friend4_heshe prisoner1_heshe
	*set friend4_himher prisoner1_himher
	*set friend4_lover prisoner1_lover
	*set prisoner2_name "None"
*if (prisoner1_hisher="his")
	*set prisoner1_manwoman "man"
*if (prisoner1_hisher="her")
	*set prisoner1_manwoman "woman"
*if (prisoner1_name=karlkarla_name)
	*set prisoner1_relationship karlkarla_relationship
	*set prisoner1_nickname "Red Archer"
*if (prisoner1_name=theothea_name)
	*set prisoner1_relationship theothea_relationship
	*set prisoner1_nickname "Red Warrior"
*if (prisoner1_name=jacejess_name)
	*set prisoner1_relationship jacejess_relationship
	*set prisoner1_nickname "Red Wizard"
*if (prisoner1_name=peterpetra_name)
	*set prisoner1_relationship peterpetra_relationship
	*if (prisoner1_hisher="his")
		*set prisoner1_nickname "Red Priest"
	*if (prisoner1_hisher="her")
		*set prisoner1_nickname "Red Priestess"
*if (prisoner1_name=gillgale_name)
	*set prisoner1_relationship gillgale_relationship
	*set prisoner1_nickname "Red Assassin"

You see ${friend1_name}
*if (friend1_name=theothea_name)
	grip ${friend1_hisher} warhammer tightly
*if (friend1_name=gillgale_name)
	grip ${friend1_hisher} short swords tightly
*if (friend1_name=peterpetra_name)
	grip ${friend1_hisher} morningstar tightly
*if (friend1_name=jacejess_name)
	narrow ${friend1_hisher} glowing white eyes
*if (friend1_name=karlkarla_name)
	put an arrow to ${friend1_hisher} bowstring
and turn toward the newcomer.
*if (friend2_exists)
	${friend2_name} also looks prepared to fight.

*if (friend3_name=theothea_name)
	*set theothea_inparty true
	"Hold on, ${name}," a gruff voice says.
	
	To your surprise, you see the hulking shape of ${theothea_name} step around the ${branbrinn_manwoman} in the chainmail.
	*if (friend3_hisher="his")
		The mountain-man has a full beard and is wearing dirty rags,
	*if (friend3_hisher="her")
		The mountain-woman's hair is longer than you've ever seen it and she's wearing dirty rags,
*if (friend3_name=gillgale_name)
	*set gillgale_inparty true
	"Easy, ${name}," a familiar voice says.
	
	To your surprise, you see your childhood friend ${gillgale_name} gracefully step around the ${branbrinn_manwoman} in the chainmail.
	*if (friend3_hisher="his")
		The thief has a full beard and is wearing dirty rags,
	*if (friend3_hisher="her")
		The thief's hair is longer than you've ever seen it and she's wearing dirty rags,
*if (friend3_name=peterpetra_name)
	*set peterpetra_inparty true
	"At ease, ${name}," a familiar voice says.
	
	To your surprise, you see your childhood friend ${peterpetra_name} confidently step around the ${branbrinn_manwoman} in the chainmail.
	*if (friend3_hisher="his")
		The holy warrior has a full beard and is wearing dirty rags,
	*if (friend3_hisher="her")
		The holy warrior's hair is longer than you've ever seen it and she's wearing dirty rags,
*if (friend3_name=jacejess_name)
	*set jacejess_inparty true
	"It's me, ${name}," a familiar voice says.
	
	To your surprise, you see ${jacejess_name} step around the ${branbrinn_manwoman} in the chainmail.
	*if (friend3_hisher="his")
		The Soulburner has a full beard and is wearing dirty rags,
	*if (friend3_hisher="her")
		The Soulburner's hair is longer than you've ever seen it and she's wearing dirty rags,
*if (friend3_name=karlkarla_name)
	*set karlkarla_inparty true
	"It's me, ${name}," a soft voice says.
	
	To your surprise, you see ${karlkarla_name} step around the ${branbrinn_manwoman} in the chainmail.
	*if (friend3_hisher="his")
		The archer has a full beard and is wearing dirty rags,
	*if (friend3_hisher="her")
		The archer's hair is longer than you've ever seen it and she's wearing dirty rags,
but otherwise ${friend3_heshe} seems healthy.  You look around for ${prisoner1_name}, but don't see ${prisoner1_himher}.
*if (friend3_lover)
	
	You see the hesitancy in ${friend3_name}'s eyes and the questioning glance.  There had been a connection between the two of you and it was clear that ${friend3_heshe} was uncertain if there still was or not.
	*choice
		#Put your arms around ${friend3_name} and hope that ${friend3_heshe} still feels the same.
			*gosub Friend3_getrelationship
			*if (temp_relationship<55)
				${friend3_name} feels tense in your arms and doesn't hug you back.  The time ${friend3_heshe} spent in the dungeons must have cooled any romantic feelings ${friend3_heshe} had toward you.
				*if (showstats)
					(Needed 55 ${friend3_name} Relationship)
				*label Brightton_Breakup_Friend3
				*set friend3_lover false
				*set lover_exists false
				*set lover_name "None"
				*if (friend3_name=theothea_name)
					*set theothea_lover false
				*if (friend3_name=jacejess_name)
					*set jacejess_lover false
				*if (friend3_name=peterpetra_name)
					*set peterpetra_lover false
				*if (friend3_name=gillgale_name)
					*set gillgale_lover false
				*if (friend3_name=karlkarla_name)
					*set karlkarla_lover false
				*goto After_Friend3_RomanceCheck
			*else
				*if (friend3_name=theothea_name)
					The big mountain-${theothea_manwoman}
					*label Still_With_TheoThea
					lifts you into the air with ${theothea_hisher} enormous arms.  You feel yourself twirled about as ${theothea_heshe} plants a firm kiss on your mouth, relieving any doubts that ${theothea_heshe} still likes you.
					*if (showstats)
						*line_break
						(${theothea_name} Relationship +10)
					*set theothea_relationship +10
				*if (friend3_name=karlkarla_name)
					The shy archer turns bright red in your arms, but ${karlkarla_heshe} still manages to give you a happy kiss on the lips.  Immediately after the kiss, ${karlkarla_heshe} blushes even redder.
					*if (showstats)
						*line_break
						(${karlkarla_name} Relationship +10)
					*set karlkarla_relationship +10
				*if (friend3_name=peterpetra_name)
					The stern cleric's demeanour softens for a moment as ${peterpetra_heshe} hugs you back.
					*label Still_With_PeterPetra
					$!{peterpetra_hisher} strong arms wrap around you and pull you close as ${peterpetra_hisher} soft lips meet your own.
					*if (showstats)
						*line_break
						(${peterpetra_name} Relationship +10)
					*set peterpetra_relationship +10
				*if (friend3_name=gillgale_name)
					The merry rogue
					*label Still_With_GillGale
					kisses you passionately for everyone to see.  $!{gillgale_heshe} steps nimbly back to get a better look at you, laughs happily and kisses you again.
					*if (showstats)
						*line_break
						(${gillgale_name} Relationship +10)
					*set gillgale_relationship +10
				*if (friend3_name=jacejess_name)
					The Soulburner struggles with the emotion of seeing you again, but allows ${jacejess_himher}self to be hugged.
					*if (showstats)
						*line_break
						(${jacejess_name} Relationship +10)
					*set jacejess_relationship +10
				*set lover_exists true
				*set lover_name friend3_name
				*set lover_hisher friend3_hisher
				*set lover_himher friend3_himher
				*set lover_heshe friend3_heshe
				*goto After_Friend3_RomanceCheck
		#Stand back and stare awkwardly.
			*gosub Friend3_getrelationship
			*if (friend3_name=theothea_name)
				*if (temp_relationship>=75)
					The big mountain-${theothea_manwoman} rushes toward you and 
					*goto Still_With_TheoThea
				*else
					The big mountain-${theothea_manwoman}
					*label Break_Up_Relationship_Needed
					stares back and makes no move to close the distance either.  The time ${friend3_heshe} spent in the dungeons must have cooled any romantic feelings ${friend3_heshe} had toward you.
					*if (showstats)
						(Needed 75 ${friend3_name} Relationship)
					*goto Brightton_Breakup_Friend3
			*if (friend3_name=karlkarla_name)
				The shy archer
				*label Break_Up_No_Relationship_Needed
				stares back and makes no move to close the distance either.  The time ${friend3_heshe} spent in the dungeons must have cooled any romantic feelings ${friend3_heshe} had toward you.
				*goto Brightton_Breakup_Friend3
			*if (friend3_name=peterpetra_name)
				*if (temp_relationship>=75)
					The stern cleric's demeanour softens for a moment as ${peterpetra_heshe} steps forward and hugs you.
					*goto Still_With_PeterPetra
				*else
					The stern cleric
					*goto Break_Up_Relationship_Needed
			*if (friend3_name=gillgale_name)
				*if (temp_relationship>=75)
					The merry rogue rushes forward and
					*goto Still_With_GillGale
				*else
					The rogue
					*goto Break_Up_Relationship_Needed
			*comment only JaceJessleft
			The Soulburner
			*goto Break_Up_No_Relationship_Needed
		#Cross your arms in front of you to indicate that things have changed.
			You see the heartbreak in ${friend3_hisher} eyes, but to ${friend3_hisher} credit, ${friend3_heshe} says nothing to make the situation any more awkward.
			*if (showstats)
				*line_break
				(${friend3_name} Relationship -10)
			*set friendinc 0
			*set friendinc -10
			*gosub Friend3_Increase
			*goto Brightton_Breakup_Friend3
*else
	*goto After_Friend3_RomanceCheck

*label After_Friend3_RomanceCheck

*if (breakout_killed_guards)
	"It's unfortunate that you killed the guards.  They were good men and women," the unknown ${branbrinn_manwoman} says.  "Although everyone will be glad to learn that Bunta has finally been put down like the dangerous dog he was.  Hurry!
*if (breakout_killed_guards=false)
	"Everyone will be glad to learn that Bunta has finally been put down like the dangerous dog he was," the unknown ${branbrinn_manwoman} says.  "Hurry!
We must go before more guards
*if (prisonchild_exists)
	come.  The child is coming too?"
	
	The silent ${prisonchild_boygirl} says nothing but ${friend1_name} nods in answer, indicating that you are bringing the young prisoner with you.
*if (prisonchild_exists=false)
	come."
*if (using_legacy)

	*if (legacy_good)
		"One moment please," another voice says
	*if (legacy_good=false)
		"Stop," a voice commands
	as the cell begins to glow with a soft-blue light.
	
	You see that the wizard of Elmvale has returned.  The ${branbrinn_manwoman} in chainmail pauses as ${branbrinn_heshe} sees that you are distracted with something.  It's clear that only you are able to see and hear the apparition.
	
	The ${legacy_race} studies the wall of the dungeon with great care.  "I used a very powerful spell here.  It was very long ago, but that shouldn't matter.  For some reason, it didn't activate."
	
	You look at the wall and see that several runes have been carved into the stone.  A series of deep gashes have been scored through the runes as though a wild animal had clawed at the magic.
	
	"I'm sorry," ${legacy_heshe} says as ${legacy_heshe} shakes ${legacy_hisher} head.  "I had hoped to give you some help, but it appears that the time-travelling creature whom we faced in Elmvale is still countering my actions.  I will have to think more upon this."
	
	The wizard vanishes, taking ${legacy_hisher} blue light with ${legacy_himher}.
	
	"We must go," the ${branbrinn_manwoman} in chainmail says again.

Together, you walk quickly through the dungeon tunnels until you are standing before a blank wall.  The ${branbrinn_manwoman} pushes a brick, and to your surprise, a large section of the wall swings open to reveal a secret passage.  You are led through the hidden pathway until you surface just outside the outer wall of Brightwater's keep.  You walk through the dark streets until you reach a small, nondescript house.  Once you are inside and the door is closed, ${friend3_name} smiles happily.

"So, this is $!{princeprincess} ${name}, the lost heir to the throne of Daria," the ${branbrinn_manwoman} says as ${branbrinn_heshe} takes a seat at the wooden table in the main room while ${friend3_name} does the same.
*choice
	#Say, "Yes, and you are?"
		*label Brightwater_ThisIs
		"This is ${branbrinn_name}, captain of the city guard of Brightwater," ${friend3_name} explains.
		*goto Brightwater_Introduction
	#Say, "Who are you?"
		"I am ${branbrinn_name}, captain of the city guard of Brightwater," the ${branbrinn_manwoman} says.
		*goto Brightwater_Introduction
	#Say, "Where is ${prisoner1_name}?"
		The smile leaves ${friend3_name}'s face.
		
		*goto Brightwater_ThisIs
	#Say, "${friend3_name}, what's going on here?"
		*goto Brightwater_ThisIs
	#Say, "Thank you for helping us."
		The ${branbrinn_manwoman} in chainmail nods in reply.
		
		*goto Brightwater_ThisIs

*label Brightwater_Introduction

"There was a demon hidden in Zusak's room," ${friend3_name} says.  "It caught ${prisoner1_name} and me almost immediately.  Zusak had no use for us, since he caught you right afterwards.  He gave us to Selina.  ${name}, you were right to not have tried to rescue us right away.  After you escaped Zusak, Selina turned the dungeon into a big trap for you.  She is an evil woman.  She poisoned ${prisoner1_name} and me every day.  Hallucinations, burning pain, nausea…I have to admit, we both prayed for death to take us.  Unfortunately, ${prisoner1_name} got ${prisoner1_hisher} wish and died in that cell.

"As weeks turned to months, Selina's attention was drawn elsewhere and soon she stopped visiting me altogether.  That's when ${branbrinn_name} rescued me and brought me here."

${branbrinn_name} clarifies, "I couldn't just release ${friend3_name}, or Selina would have tracked us down, recaptured ${friend3_name} and killed me.  I brought ${friend3_himher} here, instead of leaving ${friend3_himher} with Bunta.  I bribed him a lot of gold to do this.  The occasional times that Selina wanted to interrogate ${friend3_name} after those first few months, I used the secret passage to return ${friend3_himher} to the cell."

"It hasn't been that bad, but honestly, I'm looking forward to
*if (friend3_hisher="his")
	shaving off this itchy beard."
*if (friend3_hisher="her")
	not having to roll around in mud at a moment's notice and rush back to the cell."
*set stage 3
*set friend4_name branbrinn_name
*set friend4_hisher branbrinn_hisher
*set friend4_heshe branbrinn_heshe
*set friend4_himher branbrinn_himher
*set friend4_lover branbrinn_lover
*fake_choice
	#Ask, "What now?"
	#Ask ${branbrinn_name}, "What do you get out of it?"
	#Ask, "What will stop you from telling Selina about me and collecting any reward she may offer?"
	#Say, "Thank you for all you have done for us."
	#Say nothing.
"$!{princeprincess} ${name}," ${branbrinn_name} says as ${branbrinn_heshe} looks at you with ${branbrinn_hisher} serious eyes.  "I have served Brightwater faithfully all my life.  Selina is a monster, but she is the legal ruler.  I had to obey her commands.  But now that you are here, I have a glimmer of hope in my heart.  You are the rightful ruler and I am your most loyal subject.  ${friend3_name} and I will help you in any way we can to regain your lost kingdom and to reunite the Kingdom of Daria once more."

*if ((friend1_name=jacejess_name) or (friend2_name=jacejess_name))
	*if (friend2_exists)
		*if (friend1_name=jacejess_name)
			${jacejess_name} appears bored as ${friend2_name} listens to ${branbrinn_name} and ${friend3_name} with a rapt expression on ${friend2_hisher} face.
			*goto Friend_Reaction
		*else
			${jacejess_name} appears bored as ${friend1_name} listens to ${branbrinn_name} and ${friend3_name} with a rapt expression on ${friend1_hisher} face.
			*goto Friend_Reaction
	*else
		${jacejess_name} appears bored as ${branbrinn_name} and ${friend3_name} speak.
		*goto Friend_Reaction
*else
	*if (friend2_exists)
		${friend2_name} and ${friend1_name} listen to ${branbrinn_name} and ${friend3_name} with rapt expressions on their faces.
		*goto Friend_Reaction
	*else
		${friend1_name} listens to ${branbrinn_name} and ${friend3_name} with a rapt expression on ${friend1_hisher} face.
		*goto Friend_Reaction

*label Friend_Reaction
*if (prisonchild_exists)
	Meanwhile, the young ${prisonchild_boygirl} has fallen asleep on the floor next to the fire.
The talk continues through the night as a plan is laid out before you.

You learn that Selina is in Tornassa, where she has been spending a lot of time over the last year.  The red-haired poisoner has been seen exclusively in the company of Duke Uddo, the ruler of the westernmost duchy which holds many important cities, including Tornassa.  The short, pock-marked duke with the bulging eyes is known to have a shrewd mind, so uniting the duchies of Dumain and Uddo could have been either of their ideas.  Either way, it means that Selina is not currently in Brightwater and gives you a great opportunity to steal away her duchy.  Unfortunately, it will mean that you'll have to work quickly.
*label Need_A_Plan
*choice
	#Think about any historical precedents.
		*if (((history>=30) or (class_bard>=2)) or (class_sage>=1))
			"A Grand Council," you say, remembering your lessons with Harmond.  "I could still be proclaimed ${kingqueen} if the lords and ladies of the Dumain duchy acknowledge my right as heir and accept my claim over Selina's."
			*if (showstats)
				*line_break
				(History +2 and ${branbrinn_name} Relationship +2)
			*set history +2
			*set branbrinn_relationship +2
			*goto Need_A_Plan_2
		*else
			You wrack your brain, but come up with nothing.  You know that your old tutor, Harmond, would have been disappointed that you had forgotten so many of his teachings.
			*if (showstats)
				(Needed 30 History or Level 2 in Bard)
			*goto Need_A_Plan
	#Consider how other countries have changed rulership.
		*if (geography<30)
			Daria is a secluded little nation and rarely has dealings with outside nationalities.  As such, the only rulership changes you know of were started by bloody conquests.
			*if (showstats)
				(Needed 30 Geography) 
			*goto Need_A_Plan
		*else
			"Remember Laslonia?" you say, recalling a small country far to the north, way past the Norgan Mountains.  "They gave the crown to the second oldest, because the heir had been lost at sea.  A year later, he was rescued from a desert island.  The nobles of the land voted and gave the crown back to the first born when he returned."
			*if (showstats)
				*line_break
				(Geography +2 and ${branbrinn_name} Relationship +2)
			*set geography +2
			*set branbrinn_relationship +2
			*goto Need_A_Plan_2
	#Say, "It is my Gods' given right to rule.  I am the true heir."
		*if (religion<40)
			Everyone in the room nods and agrees with you.
			*if (showstats)
				(Needed 40 Religion)
			*goto Need_A_Plan
		*else
			"Selina only got her dukedom because I was thought to be dead," you say.  "But I was proclaimed the rightful heir to the throne before all of the Gods and Goddesses by my parents.  That should supersede any claims."
			*if (showstats)
				*line_break
				(Religion +2 and ${branbrinn_name} Relationship +2)
			*set Religion +2
			*set branbrinn_relationship +2
			
			"Yes, it is your divine right," ${branbrinn_name} agrees.  "With you back, the eastern lords and ladies could have a vote to reinstate and coronate you as the ${kingqueen} of Daria.
			*goto Need_A_Plan_2
	*if (familyring) #Show ${branbrinn_name} your signet ring.
		"Exactly," ${branbrinn_name} says as ${branbrinn_heshe} looks at your family's ring.  "With you back, the eastern lords and ladies could have a vote to reinstate and coronate you as the ${kingqueen} of Daria.
		*if (showstats)
			*line_break
			(Charm +2 and ${branbrinn_name} Relationship +5)
		*set charm +2
		*set branbrinn_relationship +5
		*goto Need_A_Plan_2
	#Ask, "Any suggestions on how we can use her absence to our advantage?"
		"Maybe," ${branbrinn_name} says hesitantly.  "The eastern lords and ladies could have a vote to reinstate and coronate you as the ${kingqueen} of Daria.
		*goto Need_A_Plan_2
*label Need_A_Plan_2

"We'll need to move quickly," ${branbrinn_name} says.  "As soon as Selina hears of the vote, you can be sure that she'll hurry back here and put an end to it.  A fast rider would take a week to get to Tornassa and Selina would take a week to get back to Brightwater.  I will call for a Grand Council in two weeks' time so Selina will have no chance to stop us."

"There won't be enough time to speak to all the nobles," ${friend3_name} says.

"$!{mc_heshe} won't need to," ${branbrinn_name} says with a serious face.  "There are three lords in Brightwater who are the most influential.  If you can gain their support, enough of the other lords and ladies will follow their lead."

You talk late into the night about your plans to reunite Daria, during which ${friend3_name}
*if (friend3_hisher="his")
	cuts his beard and
washes away the prison filth.  It's good to see ${friend3_himher} back
*if (friend3_name=theothea_name)
	in ${friend3_hisher} mountain-${theothea_manwoman} clothing with ${friend3_hisher} warhammer hanging from ${friend3_hisher} belt once more.
*if (friend3_name=gillgale_name)
	in ${friend3_hisher} leather armour with ${friend3_hisher} twin swords on ${friend3_hisher} belt once more.
*if (friend3_name=peterpetra_name)
	in ${friend3_hisher} plate armour with ${friend3_hisher} morningstar hanging from ${friend3_hisher} belt once more.
*if (friend3_name=jacejess_name)
	in ${friend3_hisher} robes with ${friend3_hisher} jet black hair and white streak clean once more.
*if (friend3_name=karlkarla_name)
	in ${friend3_hisher} normal clothing with ${friend3_hisher} bow and quiver on ${friend3_hisher} back once more.
$!{friend3_hisher} dungeon days are over.

You wake up early the next morning, knowing that you have only 14 days to gain the support needed to be declared the rightful ruler of the Dumain duchy.  Since Selina's spies will know about your existence the moment you begin trying to persuade the nobles anyway, you begin your plan by announcing your existence to the world.  This bold move gives your bid for the throne a sense of confidence that you hope will help sway the more timid nobles.  Word spreads quickly and the house that you are staying in becomes surrounded by curious city folk.
*gosub ResetAdventure
*choice
	#Begin meeting with the eastern nobility.
		*goto_scene politics
	#Visit the shops before you start the diplomacy.
		Many men and women greet you as you walk through the stores.  Children gather around you and some of them reach out to touch your clothing.  The storekeepers are honoured to have you visit their shops.
		*set store_scene "brightwater_to_politics"
		*goto_scene store

*comment ---------------------Subroutines------------------------------
	
*label Friend2_Increase
*if (friend2_name=theothea_name)
	*set theothea_relationship +friendinc
	*return
*if (friend2_name=karlkarla_name)
	*set karlkarla_relationship +friendinc
	*return
*if (friend2_name=jacejess_name)
	*set jacejess_relationship +friendinc
	*return
*if (friend2_name=peterpetra_name)
	*set peterpetra_relationship +friendinc
	*return
*if (friend2_name=gillgale_name)
	*set gillgale_relationship +friendinc
	*return
*else
	*comment BranBrinn only one left
	*set branbrinn_relationship +friendinc
	*return

*label Friend3_Increase
*if (friend3_name=theothea_name)
	*set theothea_relationship +friendinc
	*return
*if (friend3_name=karlkarla_name)
	*set karlkarla_relationship +friendinc
	*return
*if (friend3_name=jacejess_name)
	*set jacejess_relationship +friendinc
	*return
*if (friend3_name=peterpetra_name)
	*set peterpetra_relationship +friendinc
	*return
*if (friend3_name=gillgale_name)
	*set gillgale_relationship +friendinc
	*return
*else
	*comment BranBrinn only one left
	*set branbrinn_relationship +friendinc
	*return

*label Friend2_getrelationship
*if (friend2_name=theothea_name)
	*set temp_relationship theothea_relationship
	*return
*if (friend2_name=karlkarla_name)
	*set temp_relationship karlkarla_relationship
	*return
*if (friend2_name=jacejess_name)
	*set temp_relationship jacejess_relationship
	*return
*if (friend2_name=gillgale_name)
	*set temp_relationship gillgale_relationship
	*return
*if (friend2_name=peterpetra_name)
	*set temp_relationship peterpetra_relationship
	*return
*set temp_relationship branbrinn_relationship
*return

*label Friend3_getrelationship
*if (friend3_name=theothea_name)
	*set temp_relationship theothea_relationship
	*return
*if (friend3_name=karlkarla_name)
	*set temp_relationship karlkarla_relationship
	*return
*if (friend3_name=jacejess_name)
	*set temp_relationship jacejess_relationship
	*return
*if (friend3_name=gillgale_name)
	*set temp_relationship gillgale_relationship
	*return
*if (friend3_name=peterpetra_name)
	*set temp_relationship peterpetra_relationship
	*return
*set temp_relationship branbrinn_relationship
*return

*label Friend4_getrelationship
*if (friend4_name=theothea_name)
	*set temp_relationship theothea_relationship
	*return
*if (friend4_name=karlkarla_name)
	*set temp_relationship karlkarla_relationship
	*return
*if (friend4_name=jacejess_name)
	*set temp_relationship jacejess_relationship
	*return
*if (friend4_name=gillgale_name)
	*set temp_relationship gillgale_relationship
	*return
*if (friend4_name=peterpetra_name)
	*set temp_relationship peterpetra_relationship
	*return
*set temp_relationship branbrinn_relationship
*return

*label ResetAdventure
*set theothea_injured false
*set jacejess_injured false
*set gillgale_injured false
*set peterpetra_injured false
*set karlkarla_injured false
*set branbrinn_injured false
*set friend1_injured false
*set friend2_injured false
*set friend3_injured false
*set friend4_injured false
*set health 100
*set companion_injured false
*set demonstone_kgirr_used false
*set demonstone_xiatta_used false
*set demonstone_zonch_used false
*set demonstone_brahl_used false
*set demonstone_tyborr_used false
*set demonstone_daanda_used false
*return

*label InjureFriends
*if ((theothea_injured) and (friend1_name=theothea_name))
	*set friend1_injured true
*if ((theothea_injured) and (friend2_name=theothea_name))
	*set friend2_injured true
*if ((theothea_injured) and (friend3_name=theothea_name))
	*set friend3_injured true
*if ((theothea_injured) and (friend4_name=theothea_name))
	*set friend4_injured true
*if ((jacejess_injured) and (friend1_name=jacejess_name))
	*set friend1_injured true
*if ((jacejess_injured) and (friend2_name=jacejess_name))
	*set friend2_injured true
*if ((jacejess_injured) and (friend3_name=jacejess_name))
	*set friend3_injured true
*if ((jacejess_injured) and (friend4_name=jacejess_name))
	*set friend4_injured true
*if ((karlkarla_injured) and (friend1_name=karlkarla_name))
	*set friend1_injured true
*if ((karlkarla_injured) and (friend2_name=karlkarla_name))
	*set friend2_injured true
*if ((karlkarla_injured) and (friend3_name=karlkarla_name))
	*set friend3_injured true
*if ((karlkarla_injured) and (friend4_name=karlkarla_name))
	*set friend4_injured true
*if ((peterpetra_injured) and (friend1_name=peterpetra_name))
	*set friend1_injured true
*if ((peterpetra_injured) and (friend2_name=peterpetra_name))
	*set friend2_injured true
*if ((peterpetra_injured) and (friend3_name=peterpetra_name))
	*set friend3_injured true
*if ((peterpetra_injured) and (friend4_name=peterpetra_name))
	*set friend4_injured true
*if ((gillgale_injured) and (friend1_name=gillgale_name))
	*set friend1_injured true
*if ((gillgale_injured) and (friend2_name=gillgale_name))
	*set friend2_injured true
*if ((gillgale_injured) and (friend3_name=gillgale_name))
	*set friend3_injured true
*if ((gillgale_injured) and (friend4_name=gillgale_name))
	*set friend4_injured true
*return
