*comment é x

*image chap2.png center Chapter Two: Ready for this Jelly

*set power 100
*set health 100

Your eyes flutter open and you're flooded with a rush of anxiety. Why are you here? Why do you want to do this? Who do you want to be? All eyes are on you, waiting for your answer, counting on you to….

This anxiety subsides, however, as your brain blurs from sleep into reality. Unfortunately, it is only replaced with a different wave of anxiety as you feel the feathers covering your skin and the squishy comb hanging across your forehead.

You roll over to face the standing mirror beside your bed, the one you use every morning to see what new form you've woken up in. The first thing you see is the beak, which surprises you. Usually you can feel those coming in, so you must have been sleeping particularly soundly this morning—which makes sense, given your Semi-Finals experience yesterday.

You take in the rest of yourself to find that your human body is covered with feathers and you've acquired the head of a chicken. You lift your arms to push your covers down further and realize that you've also grown chicken wings. Slugging great, that will make things difficult today.

You stare into the mirror, completely unable to recognize yourself.

*choice
	#Is it any wonder I have identity issues, waking up as a different Ani-hybrid every day? 
		*set image %+15

		You feel like a stranger in your own body.
		*goto birdstreak
	#I appreciate the changes. Good or bad, these transformations make me unique, and I don't care what anyone else thinks.
		*set image %-15

		You find your Ani-transformations exciting, since no two days are ever quite the same. Still, you're not sure you'll ever get used to feeling like a stranger in your own body.
		*goto birdstreak
	#I'm proud of who I am and my Powers, but that doesn't make my life easy.
		*set image %-15

		Your Ani-transformations make you who you are, and you're not ashamed of them, but you're not sure you'll ever get used to feeling like a stranger in your own body.
		*goto birdstreak
	#Some days I love it; other days I hate it. Mostly, I really just wish I were normal.
		*set image %+15

		You feel like a stranger in your own body—a stranger that doesn't even feel human most of the time.
		*goto birdstreak

*label birdstreak
Lately you seem to have been on a bird streak, which tends to happen every so often with varying animal types.

While you looked intimidating and mostly human yesterday, today you look especially ridiculous. Your chicken feathers are speckled black and white and you sport a halo of long feathers around your face, which is mostly covered with chunky red comb formations.

"Chicken, you're a chicken!"

You nearly jump out of your speckled skin, because you're still adjusting to your new MeChip assistant as well. After realizing what you were missing yesterday, you decided to spend what little money you had saved to upgrade your MeChip. You couldn't afford one of the custom MeChip personalities, so you had to go with one of the generic free options, which is based on some crazed villain-turned-martyr named… 

*set moneyed -500
*if newreader
	Prodigal.
	*page_break
	*goto fancymott
*else
	*page_break
	Prodigal.
	*goto fancymott

*label fancymott

"And a fancy Mottled Houdan chicken, to boot!" MeChip Prodigal coos, clapping her hands as she bounces in miniaturized holographic form before you.

You didn't really follow her story, but apparently this Prodigal person died in a tragic display earlier this year. She had some kind of tech-based Powers, so she was somehow able to upload her personality to the MeChip servers posthumously. So far, you've found MeChip Prodigal to be rather…eccentric, though you suppose everything about this MeChip experience is going to take some getting used to.

"Trust me, the last thing I feel at the moment is fancy," you cluck-speak, feeling even more absurd.

"Nonsense! Chickens are the finest creatures ever to strut their stuff across this green earth!" MeChip Prodigal shouts, flapping her own faux chicken wings. This appears particularly out-of-character, since MeChip Prodigal wears a black bodysuit with a red stripe running up the middle, continuing to cover her face as a kind of partial mask. She looks more like a killer assassin than a great lover of chickens, honestly.

"Now, I've got a full rundown on all the mottled mightiness and Houdan hijinks you could possibly stomach," MeChip Prodigal continues, presenting you with several holo-report options. "However, you need to upgrade to have access to that compilation."

"MeChip Prodigal, you can see my bank account," you sigh, standing to find that your feet are webbed into scratchy chicken prongs. "You know I can't afford any new upgrades, even the basic ones."

*page_break

"Welcome to the twenty-second century, where tablet functionality determines class status," MeChip Prodigal monologues, holding her hands behind her back. "Lucky for you, I made the grand gesture of sharing my sparkling personality with the world, positively free of charge!"

Despite MeChip Prodigal's generosity, you think of all the upgrades you could buy for your MeChip if you had the money. You have your MeChip to thank for your Powers in the first place—when humans integrated with tablet technology decades ago, these tablets began to cover many basic functions like memory and navigation. Once fully adjusted to this technological enhancement, the human body was able to evolve and unlock new potential in the form of superhuman Powers.

*if trilogyreader
	Most of these Powereds now flock to your home, Millennia City, to become famous heroes—but you haven't had much time to think about being a hero.
*if newreader
	As a result, one out of every three people today are born with Powered abilities and most of them seem to want to become famous heroes in Millennia City, the Powered capital of the world. Nestled between Los Angeles and San Francisco, MC is also the city you've called home your entire life.
	
	However, you haven't had much time to think about being a hero. 
Slugger, you didn't even wear any special costume for your appearance on The Hero Project, just jeans and a black t-shirt that highlighted your hawk features. You didn't choose a codename either, instead going with your real name:

*choice
	#Blake.
		*set named "Blake"
		*goto anyhoo
	#Taylor.
		*set named "Taylor"
		*goto anyhoo
	#Alex.
		*set named "Alex"
		*goto anyhoo
	#Sam.
		*set named "Sam"
		*goto anyhoo
	#Jesse.
		*set named "Jesse"
		*goto anyhoo
	#Jamie.
		*set named "Jamie"
		*goto anyhoo
	#Drew.
		*set named "Drew"
		*goto anyhoo
	#Leslie.
		*set named "Leslie"
		*goto anyhoo
	#Choose my own name.
		Your first name is:
		*input_text named
		*goto anyhoo

*label anyhoo
*set meetjk true

"Anyhoo, that's all folks," MeChip Prodigal says. "Till next time, chicken-${named}!"

As MeChip Prodigal fades from sight, you try to retract your bedroom screen with your chicken wing, nearly knocking it over in the process. Once you finally manage to exit, you find your little sister in her usual spot in the loft, settled in front of the 3V and sipping an extra large SlugGlug.

"How many hours have you been awake and watching 3V already?" you ask, trying and failing to open your beak wide enough for a yawn. 

"Hey Judgy McJudgerson, you do know it's noon, right?" JK says, looking over at you. "Did you have a good roost?"

"How long have you been plotting chicken puns?" you sigh.

"Ever since you started clucking in your sleep around 7am. Once I checked that you weren't dying, I got to work. So, how do you feel about eggs for breakfast?"

*page_break

"Very funny," you cluck, waddling into the space you and JK have designated as the living room. "Sounds like you were up early. Have trouble sleeping?"

"I had another episode," JK sighs. "This one was better than the last, but still—not fun."

You look over JK's body and don't notice any visible changes, but then again, you were told there wouldn't be any. She's still the same Jelly Kelly, with her jellified, translucent skin and amber-clear tendrils. 

"Could you pinpoint this one?" you ask. "Was it in your main body or jellyfish stem?"

"I know I'm supposed to be able to tell, but I still can't," JK answers. "Is there any discoloration? I couldn't find any in the mirrors."

*page_break

You waddle closer to JK, spinning her wheelchair sideways. You begin your inspection at the top of JK's conical head, where her pinkish jelly-tendril hair is gathered into two braids. No neon spotting there. Your eyes then travel down JK's clear jellyfish-shaped head, through the bundled nerve-net coils that connect to her main body through her neck. No discoloration there, either—just the normal amber-clear translucence.

Finally you look over the bluish jellified skin on JK's human body, or at least the parts not covered by her sweatpants and hoodie. You'd ask her to take them off, but you know how difficult that is—JK still has the use of her arms, but she lost the use of her legs when her spine partially jellified. Ani-Powered hybridizations are supposed to enhance the individual seamlessly, but you know better than anyone that sometimes the transformations can be less than ideal. This has been JK's reality ever since her Ani-Powers manifested on her thirteenth birthday.

"I don't see any problem areas, but that could just mean you haven't been getting enough calcium," you say, looking over the four cups of SlugGlug strewn across the floor.

*choice
	#"I know you think it helps with the pain, but no more energy soda today," you say, ever the stern older sibling.
		*set rlshp_jk %-5
		*set traditional %+5

		*label jksorry
		"I'm sorry, but studies show that SlugGlug is beneficial for any growing jellygirl," JK answers.

		*goto jkresponse
	#"Why didn't you save one for me?" you say. "You know the best part of waking up is SlugGlug in my cup!"
		*set rlshp_jk %+5
		*set traditional %-5
		*goto jksorry
	#"Did you drink all my SlugGlug, too?" you whine, always the annoyed older sibling. "How could you even stomach that much?"
		*set rlshp_jk %-5
		*set traditional %-5

		*label jkstudies
		"It's not exactly like I have to worry about keeping my trim figure," JK laughs, rolling her jellybelly. "Besides, you know that one study says the patented SlugGlug sugar-caffeine-taurine combination helps soothe my chronic nerve-net pain."
		*goto jkresponse
	#"Nothing is going to save you if you keep drinking that sugary garbage," you say, ever the overprotective older sibling.
		*set rlshp_jk %+5
		*set traditional %+5
		*goto jkstudies

*label jkresponse

"That study was done by the only other living jellyfish Ani-Powered, who also happens to be your best friend," you reply. 

"The power of the worldwide MeWeb, bringing jellyladies together one forum at a time," JK proclaims. "But I can't have a best friend that lives all the way in China, that'd be a very depressing assessment of my social life. You know that you're my real best friend."

JK clasps her hands and bats her luminescent eyelashes at you, but you know her far too well to fall for this display.

"Aw, thanks JK," you start, turning back towards your room. "But no amount of flattery will get you out of going to your treatment today. Turn off the boob tube and start getting ready."

*page_break

"Come on, how else am I going to get through the first season of The Hero Project before Ms. Rosado realizes that I hacked her MeFlix account?" JK whines. "I just got to the episode where Scoundrel the turkey-girl gets eliminated. Hey, do you find her superhot all of a sudden?"

"Still not funny," you answer, glancing over the wall you use to separate the living room from the kitchen. It's made entirely of fish tanks filled with every kind of sea creature you and JK can responsibly get your hands on. The fish are mostly for JK—you're not a huge fan of having pets around, given how they tend to respond to your various Ani-states.

"Did you feed the fish?" you ask.

"Every last one," JK calls. "And you'll be thrilled to know I took an extra-long salt bath this morning. See, look at me, handling all of my responsibilities. Now, when are you going to handle yours and watch some of The Hero Project? You know, now that you're actually on the show."

"We both know I'm only there for you," you say. "I'm not sure I'll even stay once your treatment is over."

"Well, that makes sense, since these opportunities just fall out of the sky for people like us all the time," JK snarks.

*page_break 

JK has a point there—you both have a difficult time finding jobs. JK can't really leave the apartment for long stretches of time, but she was lucky enough to find a steady gig as a copy editor, taking advantage of her biggest Ani-Powered talent: multiple jellyfish eyes. 

You, on the other hand, never know what Animalistic skill set you'll have each day—nor do you know how you'll look. This combination makes it nearly impossible to find regular employment, but you've managed to scrape by working as a security guard at the Millennial Mews, a gated community for rich and famous Powereds. You got the job thanks to your martial-arts expertise, but they still stick you on lookout duty alone most of the time. You were hoping to maybe someday get promoted to the Powered Security Team to get off minimum wage, but your promotion seems to have been delayed indefinitely. 

Just another day in the life of an Ani-Powered in America…

*page_break

And another reason to start seriously considering what this potential Hero Project experience might mean to you. You weren't lying when you said you did it just for JK, but that doesn't mean it has to be the only reason you stay in the competition…right?

"Whatever, it doesn't matter if you watch, because I'm becoming an expert on your behalf," JK continues. "The first season is actually pretty epic. There's this whole—"

"You can tell me all about it on the way to the Shiftsite Clinic!" you shout, heading back towards your room to get dressed, though you have no idea what you're going to wear that doesn't clash with these speckled feathers. You figure your best bet will be to just throw on your favorite t-shirt,

*choice
	#Which reads, "Equality For All."
		*goto nogobro
	#Which reads, "Please don't feed the animals."
		*goto nogobro
	#Which depicts the logo of your favorite video game, [i]Creatures of Crests & Quests[/i].
		*goto nogobro
	#Which has the verses to your favorite song.
		The lyrics are:
		*input_text favlyric
		*goto nogobro
	#Which has your personal symbol…
		A triple-edged symbol representing the triple elements of your identity, in the shape of:
		*input_text triquetra
		*goto nogobro

*label nogobro

"I don't think we should go, ${named}," JK calls after you. "We would have been called in for the next treatment if it was ready. Besides, the deal was that you make it to the Final 14. I've been doing some research on the MeBlogs and I don't think you've actually made it yet. There's all this chatter about some twist that will—"

"JK," you say, sticking your head out past your screen to face her. "I know you hate leaving the apartment almost as much as you hate those treatments, but—"

"Hey, you try rolling this mess through the streets," JK fires back, pointing at herself. "I basically have a dong for a forehead."

"And I have the face of a constantly surprised chicken," you cluck-speak, pointing at your own mug. "That should divert enough attention for today."

JK smiles, but you can tell that she's still afraid, which rattles you more than you'd like to admit. You're used to the fearless JK—she has refused to let this disruptive Ani-manifestation be anything other than positive for her. 

In fact, the first thing Kelly did after the change was rename herself Jelly Kelly, or JK for short. The second thing she did was buy an ancient paper poster of her favorite vintage girl-group, Destiny's Child. The chorus of their song "Bootylicious" immediately became JK's personal anthem: "I don't think you're ready for this jelly." 

*page_break

Despite JK's indomitable attitude, you both know that she faces more than daily pain and physical struggle: JK's Powered condition has cut her life expectancy devastatingly short. Local Herologists discovered that JK's body can't maintain itself in this degenerative form for more than a few years, and they've been useless in finding a way to treat her—not that you could afford any expensive experimental treatments or access to top specialists who might actually be able to help.

Which is precisely why you've entered The Hero Project, as part of your unconventional plan to get underground treatments for JK. You are both thankful for this glimmer of hope that might just save her life, but it doesn't make the treatments any less painful—or less frightening.

So you waddle up to JK, synchronizing your wings and mentally commanding MeChip Prodigal to start playing Bootylicious from your MeChip.

"All the chicken-heads, be quiet," MeChip Prodigal shouts, appearing to jump up and down with DJ headphones pressed against her ears. "All the chicken-heads, make noise!"

"Kelly, can you handle this?" you sing as the song starts, bobbing your chicken-head back and forth with surprising swagger.

JK sighs for a moment, but then she can't help but smile. "I don't think they can handle this," JK sings back, raising her jellyfingers in the air to join your little dance party.

*page_break ONE DANCEOFF LATER

You wait outside your building, feeling the ocean breeze funnel through the concrete wind tunnel and rustle your feathers. You pull your coat across your chest, not because you're cold, but because you're molting—and mortified. You should know better: Süper cars never actually arrive when they say they will. 

Still, they're your only option, since cabs never come to this mostly industrial area. Dockerbay may feel like a ghost town and reek of fish from the abandoned market, but it's the only place where you could afford a view of the ocean. JK absolutely loves it, even though the water is as grimy as the activity that happens on the actual docks. 

Thankfully, a budding and tight-knit community of artists and young families has begun to form as more warehouse spaces have been converted to loft apartments. You and JK have grown to love Dockerbay, with its cobblestone streets and salty air and graffiti-laden brick walls. Though there has been a major downside recently—one of the re-formed Ani-gangs has been trying to take up residency in Dockerbay ever since the Eastern Fringes began to
*if trilogyreader
	*if (power_town) or (kill_town)
		gentrify, after the redevelopment from Prodigal's Death Wave.
		*goto epxlainwhy
	*else
		gentrify.
		*goto epxlainwhy
*else
	gentrify. 
	*goto epxlainwhy

*label epxlainwhy

Which actually might explain why, when the Süper driver finally pulls up, he immediately locks his doors and cracks his window.

*page_break

"My wheelchair access is broken," the driver shouts through the cracked window. "You should have specified a wheelchair passenger in your request."

"I did," you cluck, trying to keep your voice even.

"That's right, you most certainly did," MeChip Prodigal says, appearing with a holo-record of your Süper request. "I bet he just thinks you're a member of The Fouls, that Ani-gang sullying the name of fine fowls everywhere."

"Yes, MeChip Prodigal, I know," you say out loud, realizing that you must seem insane, since these days most users master the art of mental communication with their MeChip assistants. 

Before you can get another word in, the Süper driver peels off, leaving you and JK stranded on the curb. You wish you could say this is an unusual occurrence, but you're painfully accustomed to this kind of treatment as an Ani-Powered.

*page_break

What you can't stand is anyone using JK's condition as an excuse. As if this Ani-discrimination wasn't bad enough, you both have to deal with the stigma of being "Disembodied Powereds." This is a relatively new term for the small percentage of Powereds whose abilities don't manifest seamlessly, leading them to develop a potentially dissociative relationship with their own bodies.
*if trilogyreader
	While the nation has largely responded to the Infini Crisis, because Infini Powereds possess the means to become famous and successful, Disembodied Powereds are mostly hidden underneath the surface of society and given no voice, swept under the rug or written off as "defects."
	*goto thusforce
*else
	Disembodied Powereds are mostly hidden underneath the surface of society with no voice, swept under the rug or written off as "defects."
	*goto thusforce

*label thusforce

As a result, Disembodied Powereds like you and JK have been forced to cope with your issues on your own. JK does so by running the premier Disembodied online community, The Disspace. It's a safe place for Disembodied Powereds to connect, share their stories, and raise awareness. It also happens to be where JK publishes her somewhat-popular space-travel fan-fiction. JK has been obsessed with space since she was little, but ever since her Powered change, she copes with her situation more and more by escaping into galactic fantasies.

For you, martial arts has helped you feel like you have some level of control over your Disembodied Ani-transformations. Your primary martial-arts focus remains in the practice of Chinese Kung Fu, specifically the Southern Shaolin Boxing style. This style further divides into the Five Animal specialties, which you selected because of your obvious talent for animal mimicry. Plus, the internal and external practices apply nicely to your shifting Intangible and Physical Power sets. 

You've diversified your study as much as possible, but have also trained hard to become an expert in one unique specialty: 

*choice
	#The Crane, an internal specialty that focuses on keeping an opponent at a distance using limb length and well-balanced circular evasion movements.
		*set kungfucrane true
		*set kungfuspecialty "Crane-Style Shaolin Boxing"
		*set physical %-15

		This Intangible
		*goto secondmma
	#The Tiger, an external specialty that focuses on charging and attacking an opponent directly with brute force.
		*set kungfutiger true
		*set kungfuspecialty "Tiger-Style Shaolin Boxing"
		*set physical %+15

		This Physical
		*goto secondmma
	#The Leopard, an external specialty that focuses on quick strikes to inflict pain on the soft-tissue vital areas of opponents.
		*set kungfuleopard true
		*set kungfuspecialty "Leopard-Style Shaolin Boxing"
		*set physical %+15

		This Physical
		*goto secondmma
	#The Snake, an internal specialty that focuses on enhancing awareness and balance in order to enact delicate coiling motions and locking techniques.
		*set kungfusnake true
		*set kungfuspecialty "Snake-Style Shaolin Boxing"
		*set physical %-15

		This Intangible
		*goto secondmma
	#The Dragon, an external specialty that focuses on full fist strikes and dragon-tail kicks to take down opponents directly.
		*set kungfudragon true
		*set kungfuspecialty "Dragon-Style Shaolin Boxing"
		*set physical %+15

		This Physical
		*goto secondmma

*label secondmma
animal specialty has definitely helped you learn how to begin harmonizing the human and Animalistic elements of your identity.

Once you mastered this technique, you decided to spend time developing a second martial-arts skill, in order to stay fresh and sharp.

This secondary skill set has helped to hone and diversify your existing abilities, allowing you to blend them into an individual fighting style that remains completely unique to you.

*choice
	#My secondary skill is judo, a primarily defensive Japanese style that focuses on pins and takedowns. 
		*set majudo true
		*set maspecialty "Judo"
		*set defensive %+15
		*goto findthephsy
	#My secondary skill is capoeira, a primarily offensive Brazilian style that focuses on highly mobile striking techniques.
		*set macapoeira true
		*set maspecialty "Capoeira"
		*set defensive %-15
		*goto findthephsy
	#My secondary skill is karate, a primarily offensive Japanese style that focuses on the art of striking with one's hands. 
		*set makarate true
		*set maspecialty "Karate"
		*set defensive %-15
		*goto findthephsy
	#My secondary skill is jujitsu, a primarily defensive Japanese style that focuses on using an opponent's force against them. 
		*set majujitsu true
		*set maspecialty "Jujitsu"
		*set defensive %+15
		*goto findthephsy
	#My secondary skill is taekwondo, a primarily offensive Korean style that focuses on striking with kicks. 
		*set mataekwondo true
		*set maspecialty "Taekwondo"
		*set defensive %-15
		*goto findthephsy
	#My secondary skill is Krav Maga, a primarily defensive Israeli style that focuses on avoiding confrontation and using targeted blows to end fights swiftly. 
		*set makravmaga true
		*set maspecialty "Krav Maga"
		*set defensive %+15
		*goto findthephsy
		
*label findthephsy

You find that the physicality of both practices helps you deal with your Disembodiment better than talking about it, but then again, you're a less typical Disembodied type than most. Your physical condition isn't constant—on some days your Powers make you feel strong and healthy, while on others they make you feel helpless and tortured.

This shifting facet of your Powers places you in yet another wonderful group: the Morpho-Powered. Powered culture has been built entirely around the creation of narrow ability categories: the energy wielders and the psychics, the telepaths and the fliers—the divisions and subdivisions are endless. Naturally, some Power types are considered better or fancier than others, and any Powered person that doesn't fit into a neat category is usually dubbed a "Gene Hazard."

Ani-Powers are considered the worst kind of Power set by far, usually producing hybridizations that are considered ugly or less than human—hence your difficulty finding a decent job. Ani-Powereds also have the double negative of being hyper-stratified: Rodent-Powereds hate Avian-Powereds, Fish-Powereds hate Feline-Powereds, and all of these "instinctual" conflicts tend to lead to violence within the Ani-community.

So not only are you ostracized from the larger Powered community by being both Morpho- and Ani-Powered, but the fact that your Ani-Powers defy traditional categorization makes you even more of an outcast within the smaller Ani-community.

*page_break   

You've met other Ani-Powereds, Disembodied Powereds, and Morpho-Powereds, but you've never met anyone else who checks all three boxes. In that way, you're the only person you know who embodies the entire spectrum of Underrepresented Powereds. 

Which also means you have the distinct pleasure of experiencing a complex web of intersecting discriminations, a web you’ve never been sure you’ll be able to escape. You've always felt lucky to at least have JK at your side, but even she fits into Powered culture more neatly than you do as a more traditional Disembodied and Ani-Powered.

In many ways, you've always felt alone against the world, so you have a lot to say about society and Underrepresented Powered rights. Your hope has always been to someday:

*choice
	#Fight for rights within our existing society and raise awareness for Underrepresented Powered issues.
		*set traditional %+20
		*set societal %+20

		You believe the only way things will get better for you, JK, and all those like you is if you act in the best interest of the entire Underrepresented umbrella. Much more can be done if these currently separate communities work together and unite under a single cause to raise awareness and change the culture.
		*goto thonestly
	#Take advantage of the existing system to make the best life for JK and myself that I possibly can.
		*set traditional %+20
		*set societal %-20

		Since you don't have faith that change is coming any time soon, you know it's much smarter to get what you can, while you can. It may sound harsh, but America was built on a foundation of capitalism and favors those who find ways to work the system. The wheel of inequality will always exist—you know that breaking it is impossible, so you just want to find your way from the bottom to the top.
		*goto thonestly
	#Drastically change the current societal norms to make the world a better place for everyone, especially for Underrepresented Powered communities.
		*set traditional %-20
		*set societal %+20

		You know that the only path to true change is to oppose the kind of normative standards and categories that cause divisions: the haves and the have-nots, the normals and the abnormals, the ins and the outs. Not too long ago, American society divided itself by race and gender and sexual preference, and although culture has tried to evolve beyond those biases, they seem to have simply been replaced by Powered categories. You know the only way to end this cycle is to break the wheel of inequality altogether, instead of just gaining equality for the minority group of the moment.
		*goto thonestly
	#Find a way to eradicate the societal systems that discriminate against us and create a new order where JK and I can be on top.
		*set traditional %-20
		*set societal %-20

		Society is already broken beyond repair, so you know someone needs to smash it altogether and build a new system—one that will favor people like you and JK.
		*goto thonestly
	#Just keep my head down and try to live as normal a life as possible.
		*set traditional %+20
		*set societal %-20

		You just want to work hard and build a good life for you and JK. You've been so focused on scraping by and protecting JK, you haven't had time to consider any loftier goals than getting through the day in front of you. 
		*goto currentmood

*label thonestly

Honestly, you've been so focused on scraping by and protecting JK, you haven't had time to consider any loftier goals than getting through the day in front of you. 
*label currentmood
Which currently involves finding a way to get JK over to the Shiftsite Clinic.

"Maybe we can borrow Madge's van again?" JK offers, looking up and down the empty block.

"I could try to fly us there," you say, doubtful your chicken wings could handle anything remotely as useful as that.

"Even if you could, we can't risk the illegal flying ticket," JK says. "You know how the police are cracking down on Ani-Powered public displays these days."

You don't even want to think about that—and luckily you don't have to, as you suddenly hear a familiar thrust rushing above you. 

*page_break

Looking up, you're stunned to find none other than StarSoar dropping out of the sky in an evaporating cloud of blue flame. But you shouldn't be that surprised—Dockerbay is StarSoar's home, too.

"Sweet spacey slugger," JK whispers, her jellyjaw hanging open in awe. "Who is that?"

"${named}, I was hoping to catch you!" StarSoar says as he touches down on the sidewalk. "Just my luck that you happened to be here on my way out."

"You know him?" JK asks you, stars in her eyes as she gazes up at StarSoar.

"I was going to tell you after your treatment, as a surprise," you answer. "JK, meet StarSoar, my partner in The Hero Project Semi-Finals and a fellow Dockerbay Bomber."

*page_break

StarSoar reaches out to initiate the Dockerbay Bomb handshake with you, which proves rather difficult to perform with your chicken-winged claw-hand. After fumbling through, StarSoar retracts his helmet visor and turns to JK.

"You must be the infamous Jelly Kelly," StarSoar says. "It is most excellent that you were here, otherwise I might not have recognized ${named} here in chicken form."

StarSoar shakes JK's jellyhand and you can tell that she's struggling to keep her cool. You knew JK would like StarSoar, but you didn't anticipate quite this level of a reaction….

"Uh, if you're from Dockerbay, how have we never met before?" JK asks. "Because I am just about the biggest—"

"The biggest space nerd ever?" StarSoar interrupts. "${named} already informed me. I actually visited The Disspace this morning, and let me say, it is rather impressive. I might even have some secret space tips for you, but only if you admit to being the second-biggest space nerd ever."

JK stares up at StarSoar, completely speechless—a phenomenon you rarely ever remember witnessing.

*page_break

"As for your question, we have never met before because I have been enrolled in the NASA Powered Cadet program since you two moved to Dockerbay," StarSoar continues. "You actually know my mother though, Mrs. Hill. I have been visiting her while I am in town for The Hero Project Semi-Finals, but sadly I am not back for long. I am currently on my way to one last mandatory NASA mission, before the next Hero Project episode films. Which is precisely why I wanted to find you two: I watched that Süper car leave you here; could I offer you a ride somewhere?"

You suddenly freeze, because while StarSoar clearly knows about JK's condition, he doesn't know the true nature of the treatments you've signed her up for. No one does, besides you and JK—it was a requirement of your involvement in the regimen. 

Then again, you already think of StarSoar as a friend, which is rare for you—it's very difficult to make friends given your ever-revolving Ani-Powers. JK is really your only friend, a thought that further reminds you of the importance of protecting her treatments.

Knowing you most definitely need StarSoar to give you a ride, how are you going to respond?

*choice
	#Be honest with StarSoar. I will need to trust him fully, both inside and outside the competition.
		*set ssknowsclinic true
		*set rlshp_starsoar %+20
		*set societal %+10

		"We actually do need a ride," you answer. "To the Shiftsite Clinic."

		StarSoar takes a moment to process this, then nods at you knowingly. He must understand the need for secrecy, because he just steps forward without inquiring further.
		*goto ssriding
	#Tell StarSoar I need a ride, but have him drop us off a few blocks from the clinic to keep him in the dark.	
		*set rlshp_starsoar %-10
		*set societal %-10

		"We actually do need a ride," you answer. "To the corner of Breaker and Burns, for a…uh, group meeting."

		StarSoar nods and smiles, clearly not thinking it necessary to question you further.
		*goto ssriding
	#Just tell StarSoar the corner where we need to go—if he cares enough to figure out what it is, at least I won't have told him directly and broken my vow of silence.
		*set ssknowsclinic true
		*set rlshp_starsoar %+10

		"We actually do need a ride," you answer. "To the corner of Black and Bay."

		StarSoar takes a moment to process this, then nods at you knowingly—he must recognize this generally abandoned spot as the Shiftsite Clinic. He must also understand the need for secrecy, because he just steps forward without inquiring further.

		*if (societal > 50)
			*set societal %+5
			*goto ssriding
		*else
			*set societal %-5
			*goto ssriding

*label ssriding

"Then off we go, into the wild blue ether," StarSoar says, striking a cheesy spaceflight pose. "JK, have you ever flown before?"

"Uh, that would definitely be a no," JK answers, practically vibrating with excitement. "But it's only, like, my number-one dream of all time."

"Well then, Houston," StarSoar says, finding a sturdy spot to grip JK's wheelchair. "Prepare for liftoff."

*finish NEXT CHAPTER: SHIFTS
