*comment é x

*image chap3.png center Chapter Three: Shifts

You can't remember the last time you saw JK this enthralled—seeing her this happy makes that stupid Süper experience almost worth it. Unfortunately, as StarSoar rockets off to his next destination and you make your way across the street to the clinic, JK's excitement from this first flight with her newest crush is already beginning to fade.

If you ever feel like you and JK drew a rotten lot in life, coming to the Shiftsite Clinic always makes you feel a bit luckier. There's the usual desperate Disembodied crowd assembled outside, some even camping out in a mini-tent city in the hopes of procuring treatment. Modern medicine has largely ignored Disembodied health issues, so many Powereds have nowhere to turn but here. 

Those gathered at the front of today's crowd are particularly grim: a man with a massively oversized head propped up by steel bars, a teenager lit permanently on fire, and an ethereal ghost girl tethered to the ground by a vibrating anchor. You used to be one of these beggars yourself, camping outside the Clinic and hoping to access treatment for JK from the infamous Loa Shift, healer of the Disembodied.

Now you and JK are among the chosen, which is why you feel guilty as you push through to the front of the crowd with her. You approach the ornate front doors carved with dragons and flower blossoms, which are oddly juxtaposed with the abandoned warehouses and shipping containers lining this part of the oceanfront. Two metallic bouncers stand outside the front doors—former clients of Loa Shift herself, majestic examples of the good work she does.

*page_break

"Hey Travis, Kyle," you say as you step up to the twin bouncers. "We're here for JK's next treatment."

"You don't have an appointment," says Travis, the copper twin. "Sorry."

"But I completed the terms that—"

"No one sees The Great Loa without being summoned," Kyle the bronze twin adds, crossing his arms.

"Why did the chicken cross the road?" JK mutters by your side. "To get a big, fat 'I told you so.'"

Ignoring JK, you step up to the metal twins, attempting to stand your ground. Really, though, you have absolutely no idea what threat you'd pose to these two in your current frail chicken body. 

*page_break

Luckily, before things can get ugly, the heavy wooden doors behind the twins open inward and a woman made entirely of clear glass appears, wearing her usual blue cloak-dress. 

[i]"Krystal!"[/i] 
*line_break
[i]"—please, we have to see—"[/i]
*line_break
[i]"—been waiting here for—"[/i]

Krystal ignores the calls from the crowd, instead whispering something to the metal twins. Whatever she says, it causes both of them to step aside and indicate that you may enter. Feeling a flush of relief, you nod a silent "thank you" at the twins.

"Always a pleasure, gents," JK says as she rolls inside behind Krystal. "See you on the other side."

*page_break

You follow Krystal and JK through the succulent front garden, thinking of all the time you spent outside wondering what it might look like inside this place. You were convinced for a long time that you and JK would never be deemed worthy of seeing The Great Loa, since she only takes on a few cases a year.

However, several months ago JK's condition grew sharply worse—she had a particularly traumatic nerve-net episode and lost the use of her arms. The lingering pain from the episode was so severe that the only thing she could do for it was to stay in an epsom-salt bath all day and night. You were terrified that JK was declining into something she wouldn't recover from, and you had no idea where to turn, so you did the only thing you could: you camped outside of the Shiftsite Clinic until The Great Loa finally deemed you worthy of selection.

It seemed like a miracle, especially since Loa Shift agreed to come to your Dockerbay loft to administer the first treatment immediately. You weren't allowed to witness what happened in your bathroom that day; you were forced instead to endure JK's screams while you waited outside with Krystal. The experience was nearly unbearable, but the results were undeniable. Once Loa Shift was done, JK's nerve-net pain receded, she regained the use of her arms, and she was able to live once again outside of the salt bath.

As overjoyed as you were about this reversal, you were also consumed with anxiety. You had always heard that Loa Shift's miraculous treatments came with unusually demanding and bizarre costs. However, never in your wildest dreams could you have anticipated what Loa Shift would ask in return for JK's continued treatment.

*page_break

Loa Shift declared that she could do more than just restore JK to her pre-episode Disembodied state—over the course of two increasingly strenuous treatments, Loa could harmonize JK's Ani-Powers so that she could become a fully healthy Ani-Powered. It was the best news you had ever heard—until, that is, Loa Shift delivered the incredibly weird price. 

The Great Loa would only administer JK's next treatment in the event that you, ${named}, made it to the Final 14 of The Hero Project's second season.

When you asked why you had to complete this highly specific and wildly difficult task, Loa Shift claimed not to know herself, that she "was simply an instrument for a higher order." There have always been rumors that The Great Loa's transformative Powers include some kind of prescient element, though no one has ever figured out whether this extra element is truly mythic or purely manipulative.

Whatever the case, Loa Shift was quick to remind you that if you wanted your sister to live, the reasons for your task didn't matter. JK would soon spiral back into her former condition if left untreated, and since this was the designated cost of her cure, what choice did you have? Once you agreed, Loa Shift was able to acquire a Department for the Regulation of Powered Resources (DRPR) Hero License for you and arrange for your spot in The Hero Project general auditions. She was quite clear that the rest would be up to you. 

You didn't realize what a truly insane task this was until you arrived for your audition interview. Out of thousands of heroic applicants, you had to somehow be worthy of selection as one of only one hundred Semi-Finalists. Knowing you were also under strict orders from Loa Shift not to reveal the real reason you were competing, you decided quickly how to spin your interview.

*choice
	#I went with as much honesty as I could, sharing my personal story about bettering my little sister's life.
		*set traditional %+15
		*set public %+20
		*set usejkstory true

		*if (traditional > 55)
			*set legended +2
			*set rlshp_jk %+10
			Luckily JK's story really seemed to resonate, since you knew how to make it as relatable as possible. 
			*goto workeditout
		*else
			*set rlshp_jk %+5
			You struggled at first to make JK's story seem relatable to the general public, since you're not used to buying into traditional, mainstream culture. Luckily, you got the hang of it quickly.
			*goto workeditout
	#I communicated my desire to use this platform to raise awareness about Underrepresented Powereds, but I revealed as little about my personal life as possible.
		*set traditional %+15
		*set public %-20

		*if (traditional > 55)
			*set legended +2
			*set rlshp_jk %+20
			Luckily, you're used to making these issues seem relatable, so the producers really seemed to respond well. 
			*goto workeditout
		*else
			*set rlshp_jk %+10
			You had to force yourself to make these issues seem relatable to the producers and the general public, since you're not used to buying into traditional, mainstream culture. Luckily, you got the hang of it quickly.
			*goto workeditout
	#I don't buy into the idea that reality shows have anything to do with actual reality, so I made it clear what reality is really like for JK and me.
		*set traditional %-15
		*set public %+20
		*set usejkstory true

		*if (traditional < 45)
			*set legended +2
			*set rlshp_jk %-10
			Luckily, as a proud and genuine counterculture radical, you're used to making these issues resonate.
			*goto workeditout
		*else
			*set rlshp_jk %-20
			You struggled at first with how to make this story resonate with the producers, given your usual countercultural persona.
			*goto workeditout
	#I played the mystery card, revealing as little about myself as possible. I tried to seem above the entire competition, as if I were only in it to further an important secret agenda.
		*set traditional %-15
		*set public %-20

		You're a private person, so you decided you'd have to use that privacy to your advantage.
		*if (traditional < 45)
			*set legended +2
			*set rlshp_jk %+10
			Luckily, this mystery played right into your identity as counter-cultural radical.
			*goto workeditout
		*else
			*set rlshp_jk %+5
			This more radical persona felt a bit forced to you at first, however.
			*goto workeditout

*label workeditout
Whatever you said must have ultimately been effective, because you were selected as one of the one hundred heroes to compete in the Semi-Finals. Knowing JK's future was on the line, you then obviously did what it took to fight your way into the Final 14 alongside StarSoar.

Now you find yourself approaching Loa Shift's inner sanctum once again, wondering what she might ask you to do next to earn JK's third and final treatment. Krystal walks ahead of you, her glassy footsteps ringing like chimes with every step she takes. JK rolls along beside you, taking in her surroundings.

"I think our dear Loa might be confused," JK whispers to you, tugging on your sleeve. "Her name is vodou-inspired, but this lair is dripping with straight-up Japanese mysticism. I mean, is this supposed to be a Haitian Hounfour or a Shinto shrine? I swear I saw a Mambo altar back there behind that—"

JK snaps into silence, however, as Krystal suddenly turns to face you, her clear limbs reflecting the light of a dozen paper lanterns. Her face is all sharp angles, making it impossible to read her expression. You had almost forgotten that this is JK's first time inside the Shiftsite Clinic—the last time you were here, you had been so distracted and panicked that you didn't notice any of the things that JK already has. That's JK for you: she is incredibly well read, and nothing gets past her, especially not with her multiple jellyfish eyes.

"The Great Loa will see you now," Krystal says, her voice echoing internally through her own glass body. She turns to open a pair of sliding doors, stepping aside as she motions for you to enter. 

*page_break
*set meetshift true

As you and JK step into the expansive office, Krystal stays outside and pulls the doors shut tightly behind you. You are immediately hit with the smell of burning incense and you squint against the sunlight pouring through a roof that's mostly glass. Loa Shift stands in her usual spot behind her enormous oak desk, with her back turned to you.

The Great Loa wears her lavender hair tied into a bun, and when she turns to face you, two long bangs frame her leathery, purple face. The many amethyst necklaces she wears clang together as she turns, serving as the only distinguishable feature among her all-black robes. You are surprised to find that Loa Shift's face looks even more creased with age than the last time you saw her and you are struck with a thought: could the treatments she offers somehow sap her of her own youth and vitality? If that's true, it would explain why she's so selective with her cases….

Forcing yourself to focus, you stand a bit taller beside JK, trying to stop your heart from thundering in your chest. Since there are no chairs to sit in, you must stand before The Great Loa to once again plead your case.

"Great Loa," you start, attempting to pitch your scratchy chicken voice as low as it can go. "Thank you so much for agreeing to see—"

"Kelly," Loa Shift interrupts, setting her pearl eyes directly on JK. "You will not receive your second treatment today."

*page_break

"But I did what you asked," you sputter, without thinking. "I made it to the Final 14 of The Hero Project."

"You have not," Loa Shift says, turning her piercing gaze on you. Her thin lips purse together, barely moving as she speaks. "There soon will be what they call a 'twist' in The Hero Project. Seven 'Veteran' Finalists will return to compete against seven 'Rookie' Finalists. You are now one of the Final 14 Rookies. You must advance one round further to fulfill the terms of our agreement."

"Told you so," JK snickers at your side, though her tone betrays her attempt at humor. You know that she is probably as frustrated and disappointed to hear this as you are.

"Great Loa, forgive me, but the next Hero Project episode doesn't film for another two months," you try. "JK has been experiencing nerve-net episodes again, she won't—"

"These are the terms. You must honor them," Loa Shift proclaims, her chin tilted up and her hands pulled behind her back—the stance of a woman who is not used to being questioned. "Kelly will be fine until then. I guarantee it."

Your mind spins, trying to keep up with Loa Shift's newest declarations. Your stomach also drops—you thought you were in the clear, at least for a little while. Will JK really be okay waiting for another two months? And what are you going to have to do to make sure you survive the next elimination in The Hero Project? Most importantly, what the slugger will you do if you don't?

*page_break

"Okay, so I clear the next round to make it to the real Final 14, then you administer JK's second treatment," you say, not even bothering to consider any alternatives. "What will I have to do after that, to earn the third treatment?"

"This I do not yet know," Loa Shift says. "The terms will reveal themselves to me when the time comes."

You stare back at Loa Shift, forcing your expression to remain even. Inside, though, you can't stop your mind from racing, because this is where the lines start to get blurry. What do you make of Loa Shift's alleged precognitive Powers?

*choice 
	#I have seen proof of Loa Shift's transformative healing Powers, so why should I doubt this second set of prescient abilities? 
		*set rlshp_shift %+10
		*set loabeliever true

		Many Powereds have sets of multiple abilities—and what sets could be more consonant than this mystic combination?
		*goto knowlook
	#I believe in The Great Loa as a spiritual figure, so I must also believe that she works in mysterious ways.
		*set rlshp_shift %+20
		*set loabeliever true
		Many Powereds have sets of multiple abilities, and what set could be more consonant than this mystic combination?
		*goto knowlook
	#Honestly, I think it's all a load of slugger.
		*set rlshp_shift %-20
		*set loaskeptic true

		Instead of offering her healing Powers freely, Loa Shift uses them to exploit people in need, and then she uses this pseudo-psychic nonsense as a front to further hide her true intentions. You think she is more of a mob boss than a true spiritual guru.
		*goto knowlook
	#I don't necessarily believe Loa Shift is truly precognitive, but I do believe she has mysterious reasons for wanting me in The Hero Project.
		*set rlshp_shift %-10
		*set loaskeptic true

		Otherwise, why wouldn't she just ask for money or personal service, like many of her other rumored clients?
		*goto knowlook
	#It doesn't matter what I believe: I'm going to do what Loa Shift wants, no matter who she truly is underneath all the mystery.
		*set rlshp_shift %+10
		*set loaskeptic true

		Whether her prescient abilities are real or fake is of no consequence to you, at least for now.
		*goto knowlook
	#JK and I will need to do some digging before I make a decision either way, to see if we can find any prior proof of Loa's Power.
		*set rlshp_shift %-10
		*set loaskeptic true

		Despite her considerable Disspace connections, so far JK has had trouble finding anyone who has met Loa Shift before—or at least anyone willing to admit they have. That doesn't mean you'll give up trying just yet, however.
		*goto knowlook

*label knowlook

Even though you make no visible sign of this judgment, Loa Shift gazes back at you with a knowing look. Could she possibly be able to sense your thoughts? Just how far do her abilities really reach? Or is she just very good at reading people?

"Why did you agree to see us, then?" JK says, breaking the silence. "No offense, but I assume you can send a messenger for this kind of thing."

Loa Shift looks back at JK, her thin lips almost curving into the impression of a smirk. She obviously respects directness, and JK possesses no shortage of that.

"I have gleaned a valuable piece of information, one that is too important to communicate secondhand," Loa Shift says. "Of course, I also knew that you would come here today."

Once again, you find yourself wondering whether Loa Shift knew this because she foresaw it, or because she's smart enough to know you and JK would come here the day after you thought you made the Final 14. You suppose you're going to have to get used to Loa Shift's blurred lines, for the time being….

"${named}, I cannot help you advance to this next stage; you must accomplish this task on your own once again," Loa Shift resumes. "However, I have learned something that will help you achieve this goal. When the time comes, either you or your partner StarSoar will be chosen for the Final 14…

*page_break

"The other must be eliminated."

Your mind reels once again—is this another of Loa Shift's visions? Or does she have some kind of insider knowledge on The Hero Project? How could she possibly know this, otherwise?

"Why are you telling me this?" you decide to ask instead.

"To advise you as best I can," Loa Shift answers. "The elimination will inevitably come down to you or StarSoar, and since this is the reality, I have also uncovered the means to secure your position against him. For it appears StarSoar is not who he claims to be."

"Excuse me?" you and JK say at the same time.

*page_break

"StarSoar did not leave the Powered Cadet Program; he was forcibly expelled," Loa Shift announces, as if this were the most mundane of facts. "StarSoar suffers from paranoid delusions. He believes that an alien invasion has befallen the earth. This is why he joined NASA in the first place, to investigate this alleged invasion, but when the truth of his delusions were revealed, he was expelled."

"How could he have possibly kept that secret from The Hero Project?" you sputter, trying desperately to make sense of this supposed revelation.

"You underestimate what people are capable of hiding," Loa Shift says, raising her eyebrows at your own ability to keep your motivations secret in The Hero Project, no doubt. "Mental health records are kept private as a rule, but more importantly, it is not in NASA's interest for this story to become public. StarSoar advanced rather deeply into their most elite program.

"Now StarSoar hopes to do the same in The Hero Project as he did in the Powered Cadet Program: to gain a platform to continue his doomed investigation," Loa Shift continues. "His Powers are quite the gift, but it would appear they also beleaguer him with the curse of his paranoia. Of course, if The Hero Project were to learn of StarSoar's history, he would assuredly be eliminated…thus guaranteeing your own position."

*page_break

Suddenly it becomes crystal clear what Loa Shift is suggesting: she wants you to use this information against StarSoar so you can advance in his place. 

You immediately think of StarSoar, your loyal partner and new friend, and can't imagine that any of this is true. Though if it somehow is, it's yet another example of someone's Powered condition putting them in a tough situation. Could you really exploit that for your own gain?

On the other hand, could you ever live with yourself if you didn't do whatever it takes to save JK?

You suppose that before any of these considerations come into play, it's most important to decide whether you even believe Loa Shift's newest tip.

*choice
	#I don't believe this story about StarSoar. It can't be true.
		*set rlshp_shift %-10
		*set rlshp_starsoar %+10

		Still, what angle could Loa Shift possibly be playing by making something like this up? Could there be some element of truth to her claims, some piece that might be part of some larger puzzle? Or is it all a load of slugger?
		*goto prepra
	#First I must corroborate whether the rest of Loa Shift's intel is correct, especially the part about only me or StarSoar being able to advance.
		*set rlshp_shift %+5
		*set rlshp_starsoar %+5

		One way or another, once you learn more you'll be able to make an informed decision about whether the rest of Loa Shift's tips are truths or fabrications.
		*goto prepra
	#I believe Loa Shift, as much as I might not want to.
		*set rlshp_shift %+10
		*set rlshp_starsoar %-10

		You've seen firsthand how Powers can change a person, or change the way a person sees the world. Unfortunately, these changes aren't always for the best.
		*goto prepra
	#If this is true, then StarSoar is a danger to everyone and deserves to be removed from the competition.
		*set rlshp_shift %+10
		*set rlshp_starsoar %-10

		What is your responsibility as a fellow Underrepresented Powered? To protect StarSoar from public scrutiny? To protect the public from StarSoar's potentially harmful delusions? To protect the Underrepresented community from a potentially negative representation? There's no clear-cut answer, obviously…at least not yet.
		*goto prepra
	#I honestly don't know what to think.
		*set rlshp_shift %-5
		*set rlshp_starsoar %-5

		Hopefully, once you have more information, you'll be able to make an informed decision about whether the rest of Loa Shift's tips are truths or fabrications.
		*goto prepra

*label prepra

"Clearly, you have much to consider," Loa Shift says, passing her cloudy eyes from you to JK. "I have much to attend to as well. However, before you go, may I offer one last insight?"

You're not sure you can stand many more of The Great Loa's insights, but you nod your head anyway.

"If you are to succeed in your task, you must start preparing yourself for this 'reality' experience," Loa Shift advises. "Preparing for the public's response as the audition episodes begin to air. For the politics you are sure to face. For the diverse cast of Powereds you must meet and overcome. Making it this far was quite a feat, I must admit, but you will need a different set of skills if you are to continue advancing."

You keep your eyes fixed on Loa Shift as she speaks, because you know if the situation weren't this heavy, JK would undoubtedly be singing "I told you so" at your side.

*page_break

"In short, you must choose who you want to be, and choose wisely," Loa Shift concludes. "If I were you, I would start crafting this heroic persona rather carefully…starting with a codename. And perhaps a costume."

You think you almost see Loa Shift smile after this, but the twitch fades almost as soon as it appears. Are you really getting PR and fashion advice from a faux-ancient mystical healer? 

Whatever the source, the message comes through loud and clear: you need to start taking this Hero Project experience more seriously if you're going to get what you need out of it. After all, you now realize that half of the Final 14 Rookies will be going home in the next cut to make room for the incoming Veterans. 

"Don't worry, Great Loa," JK says, already turning her wheelchair towards the door. "This is the part where I make myself useful. Thank you for your time."

With that, JK wheels herself towards the door, looking even more pained by all of this than you.

*page_break TOO SOON AFTER

You stand in the dressing room of a thrift store, thankful that the mirror in here is both small and scratchy. JK insisted that you go shopping to find a costume directly after your meeting with Loa Shift. Aside from this, neither of you has said a word so far, especially not about all of the things that Loa Shift revealed.

You're supposed to be trying costume items on, but all you can do is stand still and feel frustrated—frustrated that JK didn't get her second treatment. Frustrated that you still haven't made the Final 14. Frustrated that you learned this potentially troubling news about StarSoar. Frustrated that you have so much to worry about. Frustrated that you're even in this situation in the first place…

Especially since, in your current fowl form, trying on costumes is just about the last thing you want to do. You feel bloated and ugly, plus you have no idea how to pick a costume that suits your daily transformations beyond this unfortunate chicken shape.

Looking at your nearly naked body in the distorted mirror, you are at least comforted that your gender identity remains consistent through the changes.

*choice
	#I'm female.
		*set femaled true
		*set youdze "she"
		*set youdhir "her"
		*set youdhis "her"
		*goto boardingtimehp
	#I'm male.
		*set maled true
		*goto boardingtimehp
	#I was assigned as male at birth, but am truly female.
		*set femaled true
		*set mtftg true
		*set youdze "she"
		*set youdhir "her"
		*set youdhis "her"

		You've already undergone the gender confirmations (if any) you felt were necessary to become the woman you were always meant to be. Thankfully such transitions are no longer considered taboo, because slugger knows your Ani-Morpho changes give you enough normative grief. 
		*goto boardingtimehp
	#I was assigned as female at birth, but am truly male.
		*set maled true
		*set ftmtg true

		You've already undergone the gender confirmations (if any) you felt were necessary to become the man you were always meant to be. Thankfully such transitions are no longer considered taboo, because slugger knows your Ani-Morpho changes give you enough normative grief. 
		*goto boardingtimehp
	#I was born with intersex characteristics.
		*set intersex true

		Thankfully such characteristics are no longer considered taboo, because slugger knows your Ani-Morpho changes give you enough normative grief.

		Personally, you are at ease with this element of your identity and you consider yourself to be:

		*choice
			#Male.
				*set maled true
				*goto boardingtimehp
			#Female.
				*set femaled true
				*set youdze "she"
				*set youdhir "her"
				*set youdhis "her"
				*goto boardingtimehp
			#Intersex.
				*goto pronounchoice
			#I don't identify with binary gender categories.
				*goto pronounchoice
			#None of these options suit me, so I'd like to enter my own vocabulary.
				*goto inyouowngenrs
	#I don't identify with binary gender categories.
		*label pronounchoice
		*set genderneut true

		Gender is a spectrum with many identities--potentially as many identities as there are people. Language is imperfect thus far at naming these identities, but you try your best to find one that fits day to day.

		Thankfully, this kind of thinking also makes it easier to cope with your ever-changing Ani-Morpho manifestations.

		You've also chosen to identify with these pronouns:

		*choice
			#Ze and hir.
				*set youdze "ze"
				*set youdhir "hir"
				*set youdhis "hir"
				*goto boardingtimehp
			#They, them, and their.
				*set youdze "they"
				*set youdhir "them"
				*set youdhis "their"
				*set youdzedo "do"
				*set youdzes ""
				*set youdzehas "have"
				*set youdzeis "are"
				*set youdzewas "were"
				*goto boardingtimehp
			#Zhe, zhim, and zhir.
				*set youdze "zhe"
				*set youdhir "zhim"
				*set youdhis "zhir"
				*goto boardingtimehp
			#I'm still comfortable using she and her.
				*set youdze "she"
				*set youdhir "her"
				*set youdhis "her"
				*goto boardingtimehp
			#I'm still comfortable using he, him, and his.
				*goto boardingtimehp
			#I'd like to input my own pronouns.
				Instead of he, she, or they, I prefer:

				*input_text youdze

				Instead of him, her, or them, I prefer:

				*input_text youdhir

				Instead of his, her, or their, I prefer:

				*input_text youdhis
				*goto boardingtimehp
	#None of these options suit me, so I'd like to enter my own vocabulary.
		*label inyouowngenrs
		You identify as:
		*input_text genderinputrs
		*goto pronounchoice

*label boardingtimehp

You're pulled from your mirrored daze, however, as JK returns with another pile of clothes. You're barely able to throw on some pants before JK pulls back the curtain and starts chattering through slips of a SlugGlug she must have had stashed somewhere in her wheelchair.

"Here are some more options. This place has way more than I thought it would, not that I'm any great fashionista. Anyway, I already scoured The Hero Project MeBlogs while I was browsing, and it looks like Loa Shift is right about this whole Veterans twist. I found tons of shadow posts about it once I knew where to look. We can't be sure how or why Loa Shift knows this, but it does seem to be true."

As this grim thought settles, all you can think is: What else might Loa Shift be right about?

*page_break

"So after you pick your costume, I think we should go back and start watching the first season of The Hero Project together from the beginning. That way we can start to flag who these potential Veterans might be and cross-reference them against the shadow post rumors. Plus, you said you saw the other twelve Rookies besides you and StarSoar who advanced to the Final Selection, right? I know you signed a stack of nondisclosure agreements taller than me, but we should still try to figure out who your competition will be, in secret, between the two of us."

JK talks a mile a minute, throwing even more ridiculous neon clothing onto your pile as she downs the SlugGlug in another wild gulp.

"This is all stuff we'll have to do if you're going to move on," she rattles off. "Just like Loa Shift said, you have to start taking this more seriously and—"

"I will do my best for you, JK!" you snap, throwing an absurd purple onesie back down onto the pile. "I just need a break for a second, okay?" 

*page_break

The moment the words leave your lips you regret them, especially as JK freezes in place, clutching her empty cup of SlugGlug. You sigh and shake your head, giving JK just enough time to spin her chair away from you.

"You know I'd do this for myself if I could," JK says, her voice suddenly sounding small. "And you know it means everything to me, you doing it for me."

"I know," you say, feeling terrible. "JK, I'm sorry, I didn't meant to—"

"I'm just trying to focus on the things we can control," JK says, turning back to face you with mounting anger. Now here's the JK you're used to—though you know this also means you're about to be in for a mouthful. "I don't want to believe what Loa Shift said about StarSoar either, but so far all of her calls have been right on the money. Still, we can figure that out later; that's not the point right now."

"JK, really, I know, I just—"

"Let me finish," JK says, holding up one jellyfinger. "As thankful as I am for what you're doing, you really need to find a reason to do this whole Hero Project thing for yourself, too. If you'd bothered to pay any attention, you'd know that in The Hero Project Finals you'll start fighting missions against actual public threats. That's a chance for you to do some real good. Not to mention you could become a Disembodied and Ani-Powered hero in the public eye, the kind of representative and role model both communities desperately need.

"This can be about so much more than my treatments, if you let it be," JK sighs, finally seeming to wind down. "I don't know whether to believe if Loa Shift is more kingpin or high priestess, but I know this much: she has put you in The Hero Project for her own reasons. And I have you there for my reasons. But what are your reasons?"

*page_break

As JK's words sink in, you begin to realize that she's right, of course. After JK's Powered change, your whole life became about taking care of her. You never really got to think much about what you wanted to do, but now that you’ve been given this rare opportunity, shouldn't you be taking advantage of it? Sure, you might have been set up in the beginning, but that doesn't mean you didn't earn your spot in the Final Selection against all the odds.

You did that on your own.

You allow yourself to consider the potential upsides: The chance to make new, Powerful friends like StarSoar. Having a focused purpose and career that might make you some real money. The opportunity to become famous and gain a platform for Underrepresented Powereds. Maybe this is your chance to speak out and try to change some things—or, at the very least, to make a better life and have access to better medical care for you and JK.

For someone who has no choice but to work a dead-end minimum-wage job, you'd be crazy not to let this opportunity change your life somehow. Sure, you want to cure JK, but could you decide to get something else from this experience at the same time? 

*choice
	#I need to use this platform while I have it, to raise awareness about Underrepresented Powered issues.
		*set societal %+20

		While your and JK's personal well-being is obviously of great importance, you really feel that your societal duty is just as important—and that ultimately the two are inextricably linked.
		*if (societal > 56)
			*set legended +3
			*set respected %+10
			*set rlshp_jk %+15
			*set traditional %+10
			*goto scrutiny
		*else
			*set legended +1
			*set respected %+5
			*set rlshp_jk %+5
			*set traditional %+5
			You haven't always thought this way before now, but you realize that you might need to start doing so more and more.
			*goto scrutiny
	#I think this reality 3V slugger is beneath me, but if I'm forced to play the game, I'm going to make sure to invent my own rules to start changing minds about the Underrepresented.
		*set societal %+20

		As much as reality 3V feels cheap or fake, it's still an incredible platform—one you plan to use to create radical change.
		*if (societal > 56)
			*set legended +3
			*set rlshp_jk %+15
			*set respected %-10
			*set traditional %-10
			*goto scrutiny
		*else
			*set legended +1
			*set rlshp_jk %+5
			*set respected %-5
			*set traditional %-5
			You haven't always thought this way before now, but you realize that you might need to start doing so more and more.
			*goto scrutiny
	#I'm going to do my absolute best in The Hero Project so that I can build a better life for JK and me in every way.
		*set societal %-20

		More than anything, this is your shot at money, influence, and stability. You believe in Underrepresented Powered issues, but JK's well-being is your responsibility and must always come first.
		*if (societal < 44)
			*set legended +3
			*set rlshp_jk %+10
			*set respected %+10
			*set traditional %+10
			*goto scrutiny
		*else
			*set legended +1
			*set rlshp_jk %+5
			*set respected %+5
			*set traditional %+5
			You realize now that you need to start prioritizing your and JK's life over any potential societal responsibilities.
			*goto scrutiny
	#What still matters most is getting JK's next two treatments. And I'm willing to tear down anything and anyone standing in the way of that.
		*set societal %-20

		JK's well-being is your responsibility and must always come first. There's nothing you won't do to save her or to make the world a better place for her. If that requires some destruction and mayhem, then so be it.
		*if (societal < 44)
			*set legended +3
			*set rlshp_jk %-5
			*set respected %-10
			*set traditional %-10
			*goto scrutiny
		*else
			*set legended +1
			*set rlshp_jk %-15
			*set respected %-5
			*set traditional %-5
			You realize now that you need to start prioritizing JK's well-being over any potential societal responsibilities.
			*goto scrutiny

*label scrutiny
*if (traditional > 50) and (societal > 50)
	*achieve traditionalsocietalthree
	*set emergingadvocate true
	*goto threehpcheck 
*elseif (traditional > 50) and (societal < 50)
	*achieve traditionalspersonalthree
	*set emergingstriver true
	*goto threehpcheck 
*elseif (traditional < 50) and (societal > 50)
	*achieve radicalsocietalthree
	*set emergingrevolutionary true
	*goto threehpcheck 
*else
	*achieve radicalpersonalthree
	*set emerginganarchist true
	*goto threehpcheck

*label threehpcheck

Whatever your motivations, you suppose the question you really need to ask right now is: Are you ready for the public scrutiny you're about to face by starring on a reality 3V show? Now that the Semi-Finals have taped, the debut episodes of the second season of The Hero Project will be hitting the airwaves over the next two months—episodes you are sure to be featured in, one way or another.

"I was going to save this for when you had to film the next episode," JK says, interrupting your thoughts as she digs into one of her wheelchair pouches. "I didn't have a chance to wrap it, but I think you could use it today."

JK holds up a thin blue chain, and the first thing you notice is that its color matches the bluish tint of her translucent skin perfectly. The second thing you notice is that attached to the chain hangs a pale blue locket…

*page_break

One that opens to reveal a picture of you and JK nestled inside. You immediately recognize the picture, which was taken not too long ago on a day when you woke up as a squid-hybrid. It was the closest Morpho-transformation to JK's jellyfish form you'd ever had, and it gave you a whole new understanding of her condition. Instead of wallowing in the squishiness and fishiness of it all, you took off work to spend the day at the beach with JK.

You both agree this was perhaps your favorite day ever, and this is without a doubt your favorite picture you've ever taken with JK, looking like true siblings at the beach. Seeing it right now nearly makes you cry.

"I got it to remind you when you're away that you're not in this alone," JK says, trying to hold her emotions in check. "You know, a reminder that I'm always fighting beside you, in my own way."

Ignoring MeChip Prodigal as she appears blubbering with a box of tissues, you take the locket from JK and put it around your neck. Then you lean down to hug JK, because she is right: you'll always keep this locket on, to remember all of the things you're fighting for.

*page_break

"All right, enough of the mushy stuff," JK says, pulling out of your hug and rolling away. "Once we've got your costume sorted, JK's Official Hero Project Boot Camp begins! And don't worry, I'll use all of my Disspace connections to see if we can confirm this stuff about StarSoar, too. Luckily he won't be back from his 'mission,' whatever that is, until the next taping, so that gives us plenty of time."

JK shudders at this thought for a moment, clearly not wanting to dwell on it. "Now let's find you a costume and choose you a good codename."

"Oh, we don't need to talk about my codename," you say. "Because I've already decided on…"

*choice
	#The Daily.
		*set codenamed "The Daily"
		*goto braidwrk
	#AniBody.
		*set codenamed "AniBody"
		*goto braidwrk
	#The Docker Bomber.
		*set codenamed "The Docker Bomber"
		*goto braidwrk
	#Docker Bae.
		*set codenamed "Docker Bae"
		*goto braidwrk
	#Jel.
		*set codenamed "Jel"
		*goto braidwrk
	#AniMorpho.
		*set codenamed "AniMorpho"
		*goto braidwrk
	#The UnderRep.
		*set codenamed "The UnderRep"
		*goto braidwrk
	#Dismorphani.
		*set codenamed "Dismorphani"
		*goto braidwrk
	#Amorphous.
		*set codenamed "Amorphous"
		*goto braidwrk
	#Choose my own codename.
		Your codename name will be:
		*input_text codenamed
		*goto braidwrk

*label braidwrk

"${codenamed}," JK repeats, tilting her head to the side in consideration before singing, "I don't think they can handle it."

"Because my body's too Ani-licious for you baby!" you sing back, throwing some of the more hideous costume choices at JK.

"Oh, that lyric is so going on the poster," JK shouts, tossing her jellybraids from side to side. As JK whips her hair back and forth, you pause to think:

[i]${codenamed}[/i].

It may be a small step, but it's also a big sign that you're finally taking this Hero Project experience seriously—and perhaps even embracing all of the possibilities that lie ahead.

*finish NEXT CHAPTER: STAR-POWERED
