*comment é x

*text_image interlude2.png center Interlude Two: Lyrical
([i]New Character Perspective[/i])

*set power 100
*set health 100
*page_break
*achieve lyrapersp

Your eyes blink open, and for a moment you forget what has happened. For a moment, all you feel is the California king mattress underneath you, the down comforter and Egyptian cotton sheets above you, the cool central air conditioning on your face. For a moment you feel how lucky you are, until you remember. Then a wave of dread grips you as your mind latches on to reality. 

You slip out of the plush bed and into your equally plush robe, then cross the room to the kitchenette to start the coffee pot. Once it's percolating, you do the same thing you do every morning: you stand in front of the balcony doors and take in the view you've worked so hard to earn.

The first thing you see is your own ghostly reflection in the glass, your dark-brown skin against the white robe and your braided hair peeking out underneath your scarf wrap. Looking through yourself, you cast your eyes over the now-quiet Hero Project compound and out to the skyline of Millennia City, where you see the usual early morning Powereds taking flight. The sun is just peeking over the mountains to the east, the same way it does every day.

Taking it all in, you ask yourself: If everything looks the same, why does nothing feel the same?

*page_break

"Lyra, you okay, babe?"

You turn to find Aaron stretching across his side of the bed, his pale skin rippling over his stomach muscles as the covers fall away. Immediately you think: [i]dating someone way younger: PRO.[/i]

"Just have a lot on my mind this morning," you say, forcing your eyes back out the window and off of Aaron's flat stomach. You wonder what would happen if you ignored the world out there, if you just stayed in this luxurious room with your gorgeous man-boy and ordered room service until none of this nightmare mattered anymore.

Next thing you know, Aaron is handing you a cup of coffee, hugging you from behind, and resting his chin on your shoulder. [i]Staying here forever: PRO[/i], you think. Then Aaron speaks.

"You know, if you took The American Protectorate off the bench, we could help get justice for Miss Boss."

[i]Dating someone younger than you and staying here forever: CONS.[/i]

*page_break

"This season is all about redemption, and who needs that more than us?" Aaron continues, oblivious to your mounting discomfort. "Who needs it more than me, the world's least-liked former First Son?"

"Not today, Aaron," you say, stepping out of his arms. You never know exactly when it's going to happen, but kind and fun Aaron always inevitably transforms into his self-centered and egotistical alter ego, Jury.

"You say that every day," Aaron sighs. "I just don't understand why The American Protectorate needs to be kept so secluded. We're the grand-prize winners of the first season, but no one even remembers we exist."

And you know that's exactly the way it needs to stay, with the focus on the franchise's future promise instead of its troubled past. Whether its members had a choice or not, The American Protectorate was aligned with 
*if trilogyreader
	the corrupt Victon regime—and no one more so than Aaron
	*if jennydead
		Victon, who was also just recently acquitted of the murder charges brought against him for the death of Jenny Yu.
		*goto ifthebf
	*else
		Victon.
		*label ifthebf
		*page_break

		*if juryboyfriend
			It also doesn't help that Aaron recently went through a very public, holo-tabloid-splashed breakup with ${codename}. Apparently, with ${codename}'s career hitting its highest peak yet and Jury's hitting an all-time low, ${codename} just didn't have the time that Jury increasingly demanded of ${youdhir}. Though as much as Aaron claims it's over now, you have a feeling that he'd go back to ${codename} in an instant if ${youze} asked.
			*goto verdictisout
		*else
			*label verdictisout

			"Plus you know how hard I've been training, working with my new tech Powers and combat skills to live up to the new codename I picked out for my rebranding," Aaron makes sure to add. "I just want to know when I can say goodbye to Jury and let the world finally meet the new me: Verdict."
			*goto gotaplan
*else
	the corrupt regime of now-impeached President Victon—and no one more so than Aaron Victon. He may have stood up against his father in the end, but that was only after a long tenure of compliance.
	*goto gotaplan

*label gotaplan

You and GG have always had a plan to reintroduce the four remaining American Protectorate members in the final missions of this Hero Project season, but that feels so insignificant in the face of what has now happened. So you turn to look at Aaron, struggling to keep your cool.

*choice
	#"You really want to press this issue two days after what happened to Miss Boss?"
		"I'm sorry," Aaron says, immediately looking embarrassed. "You're right. It's just, I'm going crazy cooped up in the residence. All four of us are. Wintry's ice-sculpture garden is going to need a new wing pretty soon."

		You smile at Jury and run your fingers across the line of his jaw. Slugger, he can be so handsome when he's not taking himself too seriously.
		*goto gottagoemer
	#"We've been through this. The American Protectorate will be a part of the finale mission…assuming we even get to have a finale, now."
		"We will," Aaron says immediately. "I know you, you're going to bounce back from this. We all will. For Miss Boss."

		You smile at Jury and run your fingers across the line of his jaw. Slugger, he can be so handsome when he behaves like an actual hero. [i]PRO.[/i]
		*goto gottagoemer
	#"Acting this way, what makes you think you're ready for a shot at redemption?"
		"I'm sorry," Aaron says, his eyes hitting the floor. "I just hate feeling like there's nothing I can do to help."

		You nod at Jury, not feeling particularly bad for him, given what happened to Miss Boss and the day you have ahead of you.
		*goto gottagoemer

*label gottagoemer

"I have to run an emergency production meeting soon," you say. "So everyone on this floor will be up soon."

"Translation: I need to sneak back up to my apartment, where no one can see me," Aaron sighs. "Ever again."

"That's the verdict, Mr. Invisible," you say, causing Aaron to pout and cross his arms across his muscled chest.

Attempting to ignore how good Aaron looks, you give him a goodbye kiss and ruffle his blonde hair. Then you turn and hope you have enough time to get in a morning swim, to clear your head before this dreaded meeting.

*page_break ONE SHORT SWIM LATER

You're a pretty formidable woman and you know it, but something about walking next to The Diva still makes you feel like a little girl. Descending the stairs beside her in your now-daily morning walk, you always force yourself to stand a little taller than usual.

"I saw your boy toy creeping back through the hero residence halls earlier," The Diva says, her voice as smooth and commanding as ever. "You two lovebirds should really be more careful."

"First of all, you know we are most definitely not lovebirds," you return. "Second of all, you're just jealous."

"Darling, please," The Diva laughs. "I've never found toddlers to be particularly appealing."

"Ordinarily I'd argue with you there," you sigh. "But he wouldn't stop whining about the American Protectorate seclusion, today of all days."

"That's the thing about toddlers," The Diva starts, "they throw tantrums."

Though perhaps prone to exaggeration, The Diva is probably right. What started as one drunken rebound fling has turned into a recurring event, one you've had to keep secret given the fact that you're technically Jury's boss.

*page_break

"Aaron can be a real hero, you've seen that yourself," you say, trying to convince yourself as much as The Diva. "He just needs another chance to show it."

"Another chance and another decade of maturation, if you ask me," The Diva answers. "But if he is taking some stress off your plate, I'm all for it, darling. You had just better make sure that shrew Di doesn't find out. She'd be like a dog with a bone, and a rabid one at that."

Another [i]CON[/i] of flinging with Aaron: his ex-stepmother, the nation's former First Lady, is one of your Finalists on The Hero Project—and one of your more ruthless Finalists, at that. The Diva is right—if Di were to find out about you and Jury, there's no doubt she'd find a way to leverage this information into a win for her, one way or another.

"Unfortunately, that's the least of my problems today," you say. "I still can't believe we let this happen to Miss Boss."

You say the words and feel the now-familiar tightness in your chest harden its grip, because you can't help but feel that you've failed at protecting your heroes. Little Jagged and ${codenamed} managed to make it out of that hellhole alive, but Little Jagged quit the show the moment she emerged, checking herself directly in for another stay in rehab.

${codenamed} has decided to stay on the show, thankfully, but ${youdze} still ${youdzehas}n't been able to speak a word about what happened in that second clearing after the cameras stopped recording.

*page_break

*if (trytosavemb) and (missbossdead)
	Whatever did happen in there, it appears that ${codenamed} tried to save Miss Boss from a deadly fall using ${youdhis} cryptobiotic Powers. The search for Miss Boss off that cavernous cliff went on for hours after the mission ended: she fell a great distance, into some internal river. Everyone held out hope as best they could.

	However, when they finally did find Miss Boss, you all learned that ${codenamed}'s efforts weren't enough to save her from the impact of her fall.
*if missbossdead
	Whatever did happen in there, it cost Miss Boss her life.

	To make everything infinitely worse, the murderer was a former Hero Project Semi-Finalist, the very one that Miss Boss and the show went out of their way to humiliate.
*if (missbossdead = false)
	Whatever did happen in there, it appears that ${codenamed} tried to save Miss Boss from a deadly fall using ${youdhis} cryptobiotic Powers. The search for Miss Boss off that cavernous cliff went on for nearly a day after the mission ended: she fell a great distance, into some internal river. Everyone held out hope as best they could.

	When they did finally find Miss Boss, you were all relieved to learn that she was indeed still alive. The only problem? 

	No one knows how to wake Miss Boss up from this cryptobiotic stasis she has been placed in, especially since ${codenamed}'s Powers had already transformed by the time Miss Boss was found.
*comment endif

"Sadly, most people tend to forget the dangers of becoming a hero these days," The Diva says, frowning beside you. "So many young heroes I meet seem to be in it for the wrong reasons: for money, fame, and influence. They don't realize these shouldn't be the end goals of becoming a hero, but rather the perks of working hard, training, honing their talent, and wanting to make the world a better place. Given all of the nonsensical reasons people try to become heroes these days, we should consider ourselves fortunate that this kind of tragedy doesn't happen more often.

"That said, what matters now is 
*if (missbossdead = false)
	ensuring justice is served for Miss Boss." 
*if missbossdead
	honoring Miss Boss's legacy and ensuring justice is served in her name."

*choice
	#"I'm going to start by making sure all of the footage of Miss Boss talking about who she really is and what she believes in finally airs," I say in response.
		"Yes, that's certainly the least we can do," The Diva says. "Let's just hope it won't be too little, too late."
		*goto divamother
	#"We're going to tear down The Voiceless and everything they stand for," I say with fierce determination.
		"Yes, we are," The Diva says with audible force. "I might even consider vacating my Judge's chair to aid in that particular effort."
		*goto divamother
	#"I just want to make sure The Hero Project survives this blow," I say, my voice full of doubt.
		"Are you kidding?" The Diva almost laughs, bitterly. "If anything, this awfulness will only mean a ratings surge. The only thing the public loves more than a Cinderella story is a fall from grace."
		*goto divamother
	*if ((missbosskiss) and (asexual = false)) #"Absolutely. And I'm going to ask ${codenamed}'s permission before we air the footage of ${youdhis} kiss with Miss Boss. I want to respect ${youdhis} wishes on this."
		"Yes, that's a very good idea," The Diva says. "Let's just hope GG agrees with that sentiment."
		*goto divamother

*label divamother

The Diva shakes her head as you reach the bottom of the stairwell, turning to face you. "Though whatever happens in this meeting, know that I will have your back one hundred percent. Together, we will make this right."

You match The Diva's intense stare and wonder how you've been lucky enough to end up at her side. Sometimes she feels like your best friend and other times like a mother figure. One thing she manages to be all of the time, however, is inspiring. You may start off feeling small next to her, but she always leaves you standing tall.

"Yes, we will," you respond, actually starting to feel it may be true.

*page_break AT THE PRODUCTION MEETING

You've had the moment of silence. You've given the speech you prepared about Miss Boss and the future of The Hero Project. Which means that now comes the part you've been dreading: the DRPR briefing on the revealed face of the Ani-cide murders, The Voiceless.

"We're going to start with the holo-video that The Voiceless posted when their MeSite went public yesterday," you say, turning towards the holo-screen. "The information in this video has been corroborated with DRPR intelligence and appears to be true, as far as we can tell."

You've already watched this video about a hundred times, but still, seeing its opening words again you feel your stomach tighten and your breath run short. The entire holo-video features The Voice's textual representations punctuated by the occasional image, all with absolutely no sound—which only enhances the eeriness of the presentation.
*if trytosavemb
	The fact that The Voice is a former Hero Project Semi-Finalist, the very one that Miss Boss and the show went out of their way to humiliate, makes everything infinitely creepier.
*comment endif

[b]We may be The Voiceless, but we are not Powerless.[/b]

[b]We are here to reinvent what it means to be a modern Powered hero. To establish a new world order of heroes who don't compromise, who represent the Underrepresented. Too long have we been cast aside and misunderstood, but now The Voiceless demand to be heard.[/b]

[b]But who are The Voiceless?[/b]

*label whoaretv
*choice
	*disable_reuse #[b]We are Less.[/b]
		A candid picture of Less appears, showing her sitting in a corner clad in her ballerina inspired attire. A deep, introspective look of sadness settles on her plain face, which can't be much older than twenty.

		[b]Before she became Less, Sybil Vance was a quiet girl who dreamed of being a prima ballerina, until her Powered manifestation externalized her nerve endings. Left without the ability to speak or feel physical sensation, Sybil lost the two things most imortant to her: her home and her fine-tuned ability to dance.[/b] 

		[b]Disembodied and disinherited, Sybil was taken in by the infamous MC underworld figure Madame Vice and forced to become Synn Vice to survive, trained to use her pain and pleasure Powers to protect herself—and to serve others.[/b]

		[b]After Madame Vice was murdered as a victim of Ani-gang and Powered hero violence, Synn found herself homeless once again. With no voice to speak and a life spent discarded and used as a tool for others, it wasn't until Synn found a fellow voiceless Powered that she found herself.[/b]
		*goto whoaretv
	*disable_reuse #[b]We are The Voice.[/b]
		A professional headshot of The Voice appears, featuring him in his standard costume: a blue bodysuit with silver stripes to match his chrome projection goggles. Here he looks much younger and more hopeful than in the footage of him from the Ani-shelter caves.

		[b]Formerly known as the aspiring hero Imager, Hector Vaughan's Power to project images from his mind also rendered him physically speechless. Although able to project literally any image and studied in dozens of languages, Imager faced scorn from the traditional Powered hero community, who scoffed at his "harmless" or "useless" Power, always overlooking or ostracizing him.[/b]

		[b]From the moment Sybil and Hector met, they understood and valued each other in ways no one else ever had. After quickly getting married, they opened up Hector's inherited Northern Fringes townhouse to another fellow Disembodied Powered, Imager's best friend.[/b]
		*goto whoaretv
	*disable_reuse #[b]We are Reduct.[/b]
		An image of Reduct appears, standing with crossed arms in a bold red-and-gold costume and flanked by several smaller, brutish copies of himself.

		[b]An aspiring Powered hero with the ability to duplicate himself, Reduct worked tirelessly to break into the competitive Millennia City hero scene alongside Imager—so tirelessly that Reduct pushed his duplicative Powers too far on his very first professional team job, after being pressured by his heroic peers.[/b] 

		[b]Since Reduct splinters his mental faculties slightly with the creation of each duplicate, when he splintered himself too many times to meet the demands of his mission, the original Reduct found his mind so simplistic and fractured that he lost the ability to function.[/b] 

		[b]Hector and Sybil were the only ones willing to take Reduct in and they rehabilitated him to the extent they could, given their limited resources.[/b]
		*goto whoaretv
	*disable_reuse #[b]We are Nancy.[/b]
		A picture of a young girl wearing overalls appears, her skin made entirely of tree bark. Her big blue eyes stare into the camera lovingly, a giant smile on her scratchy face.
		
		[b]Next to join the growing Voiceless family was their neighbor in the Northern Fringes, Nancy. Nancy was a thirteen-year-old girl whose Power transformed her skin into tree bark. Not sure how to handle this Disembodied Power set, Nancy's loving and supportive parents sent Nancy to spend time with neighbors Hector and Sybil after school, so she could learn from other Powereds like her.[/b] 

		[b]Nancy, who still possessed the use of her voice, was instrumental in bringing Reduct out of a vegetative state and back to a place where he could respond to commands. Nancy also introduced her new friends to The Disspace, an online community for Disembodied Powereds.[/b] 
		*goto whoaretv
	*disable_reuse #[b]We are Outlet.[/b]
		In place of a image of Outlet, three pictures appear showing masses of different kinds of energy: fire, lightning, and light.
		
		[b]The expanding Voiceless family then met their final member on The Disspace: Outlet, a vastly powerful Infini being who can transform himself into various energy signatures, but has no corporeal body. This lack of a body is extremely traumatizing for Outlet, so he had spent the majority of his life in one of the few existing Disembodied Clinics on the East Coast of America, trying to learn to rehabilitate himself.[/b]

		[b]However, when this clinic was shut down from a lack of funding, Outlet was put out on the streets—or rather, systems of electrical wires and battery cells, until he found a home living mostly on the MeWeb and frequenting The Disspace.[/b] 

		[b]Outlet had decided to become a Disembodied anarchist long before meeting his new surrogate family, and his beliefs spread among them like wildfire.[/b]
		*goto whoaretv
	#I'm finished meeting The Voiceless.
		*goto brokenopen

*label brokenopen

[b]The Voiceless family had formed, but would soon be broken apart.[/b]

[b]After years of trying and failing to break into the mainstream Powered hero industry, Imager and Reduct were beyond thrilled to be selected as Semi-Finalists for The Hero Project. However, Outlet warned them that they'd only find ridicule and failure on The Hero Project, and he was absolutely right.[/b] 

[b]Imager and Reduct were reduced to little more than human punchlines on The Hero Project, at the hands of Reigna, Miss Boss, and an army of heartless producers.[/b]

Here, an image from the infamous Goggle Bobble video appears, showing The Voice and Reduct wiping out in the Semi-Finals.

[b]On the heels of this devastating rejection, the unthinkable then happened: Nancy was killed at a nearby playground, the victim of Ani-gang violence that had now reestablished itself in the Northern Fringes.[/b] 

The most chilling image in the video appears then: the lifeless body of Nancy, lying limp on a playground slide in a pool of her own blood, splinters of her bark-skin scattered all around. Littered amongst the bark shards are several uprooted shark fangs, left behind like bullet casings.

[b]Finally heeding Outlet's call, Imager (now The Voice), Sybil (now Less), and Reduct decided to form The Voiceless, to avenge Nancy's thoughtless death at the hands of unchecked Ani-criminals and remedy all they saw was wrong with Powered society, by any means necessary.[/b]

*page_break THE VOICELESS MISSION STATEMENT

[b]The Voiceless will shine a spotlight on Disembodied Powereds. We will avenge the victims of Ani-violence. And we will reclaim the fame and respect awarded to lesser heroes.[/b]
	
[b]We will tear down everything that stigmatizes our community, starting with The Hero Project: the epicenter of all of these corrupt structures.[/b]

[b]Who are The Voiceless? We are you.[/b] 

[b]So join us.[/b]

*page_break

The holo-screen goes black and you take a deep breath, knowing it's now up to you to fill in the blanks left unexplained by this video. 

"This partially explains what led The Voiceless to commit the Ani-cide hate crimes, including their most recent attack on the Ani-shelter cave, which is being dubbed The Slaughtering," you begin. "The rest of the story has been related to the DRPR by our only inside source on The Voiceless: JK, ${codenamed}'s little sister and the founder of The Disspace. She was unwittingly in contact with Outlet through The Disspace and was able to learn the following before communication with Outlet was cut off.

"After Nancy's death and Imager and Reduct's embarrassing viral elimination from The Hero Project, Less felt her surrogate family going through too much pain. Thinking it her duty as the mother of The Voiceless, Less visited Reduct and Imager in the middle of the night and used her externalized empathetic Powers to disconnect their emotional pain centers, along with her own.

"Less only meant to give her family relief for a day, but as Outlet has reported to JK, Less has since been unwilling or unable to reconnect these emotional centers. As a result, we suspect that not only has The Voiceless's capacity to feel emotional pain been numbed, but that their capacity for compassion, morality, and rationality has also been numbed. 

"To ease her family's pain, Less accidentally turned The Voiceless into textbook sociopaths." 

*page_break

This news settles over the gathered production team and causes a heavy silence to fall across the room. You take one final breath, adding your conclusion to this disturbing tale.

"Outlet was the only member not to undergo this treatment, given his lack of a physical body. However, it is Outlet's anarchist beliefs that have been amplified within The Voiceless, who now wholeheartedly believe they are doing the right thing by murdering violent Ani-Powereds and attacking The Hero Project."

You expect it will take everyone a moment to process this grim reality, but are surprised instead to see Kevin, one of your Rookie handlers, raising his hand. You nod at him, so he stands.

"I'm sorry, I don't mean to speak out of turn, but I have to ask," Kevin begins, looking both overwhelmed and frightened. "I can't be the only one thinking that we've somehow made all of this worse by doing this show. I mean, after all, we did capitalize on Imager's embarrassment and validate all their beliefs about mainstream hero culture. So I'm sorry, but I have to ask… 

"Are we creating worse villains by giving them this platform, by featuring them on The Hero Project?"

*page_break

The question pierces you like a bullet—and you can immediately tell it has the same effect on the rest of the production staff. Unfortunately, it's a question you've already had to give much thought to, and you can see by the reaction in the room that you're not the only one. 

Everyone has been doubting their place on The Hero Project since The Slaughtering—and this question has only given voice to that doubt.

And now it's your job to answer this question.

*choice
	#"Yes, The Hero Project, or at the very least the Powered fame culture that The Hero Project reinforces, created the conditions that allowed The Voiceless to rise."
		*goto continuespeech
	#"I've seen firsthand how the popularity of this show has made so-called villains clamor to become our targeted enemy, to gain a national platform for their various beliefs or exploits." 
		"The creation of this platform has escalated the heinous nature of these villains' crimes, as they compete with each other to stand out and move to the front of the target line—almost like a reverse reality competition for these criminals.
		*goto continuespeech
	#"We now need to focus on what we can do to stop this trend, on our biggest responsibility moving forward: to raise Underrepresented Powered Awareness and create a support system for these underserved communities."
		*goto continuespeech

*label continuespeech

"The Voiceless may be terribly misguided in their methods, but that doesn't mean they are wrong about the flaws in our heroic Powered culture—a culture The Hero Project has embraced. We're just giving the public what they want, right? Bigger, better heroes to fight against bigger, badder villains. But Kevin's question is a valid one: in trying to create brighter heroes, are we inadvertently creating more terrible villains?"

You pause, letting that notion sink in before you move on to the part of your speech you hope will matter most.

"Whatever the answer is, it's not as important as the fact that we now have a responsibility to be better, to carefully examine what created The Voiceless and do our part to change the conversation. There is a blatant lack of support infrastructure for Underrepresented Powered communities like Disembodieds and Ani-Powereds. The Voiceless turned to each other for support when no other existed, just like those poor souls in the Ani-shelter did. So it is our job to start calling for the kind of support that these communities need.

"There is also a media system in place that sensationalizes acts of violence, which in turn brings fame to those who commit these acts of violence. The Voiceless were following the same basic human instinct we all follow: people simply want recognition, to be heard. Here on The Hero Project, we are guilty of denying The Voiceless an opportunity to be heard, at least until they resorted to acts of terrible violence, which we were all too willing to broadcast to the world."

*page_break

"The solutions to these problems are clearly more complicated and difficult than any one person, or any one organization, can solve single-handedly. However, I know this much: action follows attitude. And if 3V has proved anything throughout history, it's that it has the potential to shape the attitudes of its audience. In that way, we have immense power here—and instead of feeding into stigma, we can use The Slaughtering to pivot the national attitude towards awareness and acceptance.

"The last season of this show, for all its flaws, successfully brought attention to the Infini Powered issue with The Crush, The Diva, Black Magic, and ${codename}. This season, we have the tools to do the same with Underrepresented Powereds. Not just the tools, but living, breathing examples of true heroism in Finalists like
*if griffingone
	Tarsiero, Transfer, and ${codenamed}.
*if transfergone
	Tarsiero and ${codenamed}.
*comment endif

"It is now our job to right any wrongs we have perpetuated. We will stop the Ani-cides. We will shut down The InfraCircle. We will shine the spotlight on our own Underrepresented Powereds. We will be the change The Voiceless want to see. And when this season is over, we will find a way to run this show so nothing like this ever happens again.

"I understand if any of you need to walk out right now, if you still feel The Hero Project is a bigger part of the problem than the solution. But to the rest of you, those of you who believe we can effect some change here, I only have one question:

"Who is with me?"

*page_break

You finish speaking and find that the room of producers is staring back at you silently, unmoving. Feeling sick to your stomach, you have no idea what the reaction to your speech will be…is everyone about to walk out on you?

Your fear washes away as The Diva rises to her feet and begins to applaud you, a mix of conviction and pride on her face.

It isn't long before the entire gathered production staff, including GG, are clapping too, rallying around the mission statement you've just laid before them.

And in this moment, despite all the wrong that has happened, you actually believe that you will find a way to make this right, together.

*page_break ONCE THE OTHERS HAVE GONE

You sit alone in the conference room with GG, unsure which part of your body aches the most. You ignore all of the different cramps and pains, however, taking another sip of your now-cold coffee. You and GG have far too much to do today for you to be tired.

"Obviously we want our final mission to be about shutting down The Voiceless," you say, suppressing a yawn. "The DRPR is working all angles, but The Voiceless have made themselves pretty untraceable so far, thanks to Outlet's unique teleportation frequency and evidence-scrubbing energy washes. The Voiceless MeSite has also remained impossible to take down because of Outlet's unprecedented MeNet access—we don't even want to begin imagining the kind of damage he could do there if he really wanted.

"Anyway, The Voiceless remain in hiding, thanks most likely to The Voice's upgraded illusion-imagery Powers. We're working to see if we can send a mole into their secret location, but this is all to say: the DRPR needs more time."

"Then time they shall have," GG says, an uncharacteristically somber look on his face. You already know there will be no nonsense from GG today—actually, he has been nothing but remarkably cooperative since The Slaughtering, following your lead in the aftermath.

"As we discussed, we're pausing the competition and focusing all of our resources on
*if missbossdead
	the funeral services for Miss Boss tomorrow,"
*if (missbossdead = false)
	a service dedicated to honoring Miss Boss tomorrow, which we'll use to frame a special awareness episode,"
GG continues. "We're going to do this as tastefully as possible, and of course, The Hero Project will be paying for everything. I've already been in touch with the aunt who raised Miss Boss, Camilla.

"Then after these services we'll give the Finalists a brief hiatus—we'll say it's for Thanksgiving, but really it will be a chance for the Finalists to catch their breath and meet with grief and PTSD counselors.

*page_break

"Speaking of, do you think this would be a good time to discuss ${codenamed}?"

*if (lb = 100)
	*set legended +5
	*goto godtimeany
*elseif (lb > 75)
	*set legended +3
	*goto godtimeany
*else
	*set legended +1
	*goto godtimeany

*label godtimeany
"As good a time as any, I suppose," you say, your heart hurting for ${codenamed}. In so many ways, this experience must be much more than ${youdze} bargained for. Given ${youdhis} unique position as both a Disembodied and Ani-Powered individual, ${youdhis} experience with Miss Boss at The Slaughtering, and JK's unexpected connection to Outlet, ${codenamed} is going to play a crucial role in the conversations to come, whether ${youdze} want${youdzes} to or not.

Which means it's going to be up to you, Weaver, and GG to protect and prepare ${codenamed} as best you can.
 
*if (rlshp_eps > 50)
	In service of this goal, you've told Weaver to remain completely focused on taking care of ${codenamed} and JK in person. This makes it your job to adjust ${codenamed}'s Statistics, knowing ${youdhis} Respected & Feared Levels are sure to be most important in the days to come. 
	*goto stattweak
*else
	*goto pvlabelext

*label stattweak
*choice
	*selectable_if (defensive < 72) #I boost ${youdhis} Defensive Stat.
		*set defensive %+20
		*goto pvlabelext
	*selectable_if (defensive > 28) #I boost  ${youdhis} Offensive Stat.
		*set defensive %-20
		*goto pvlabelext
	*selectable_if (physical < 80) #I boost ${youdhis} Physical Stat.
		*set physical %+20
		*goto pvlabelext
	*selectable_if (physical > 20) #I boost ${youdhis} Intangible Stat.
		*set physical %-20
		*goto pvlabelext
	*selectable_if (traditional < 87) #I boost ${youdhis} Traditional Stat.
		*set traditional %+20
		*goto pvlabelext
	*selectable_if (traditional > 13) #I boost ${youdhis} Radical Stat.
		*set traditional %-20
		*goto pvlabelext
	*selectable_if (societal < 90) #I boost ${youdhis} Societal Stat.
		*set societal %+20
		*goto pvlabelext
	*selectable_if (societal > 10) #I boost ${youdhis} Personal Stat.
		*set societal %-20
		*goto pvlabelext
	*selectable_if (public < 86) #I boost ${youdhis} Public Stat.
		*set public %+20
		*goto pvlabelext
	*selectable_if (public > 14) #I boost ${youdhis} Private Stat.
		*set public %-20
		*goto pvlabelext
	*selectable_if (respected < 87) #I boost ${youdhis} Respected Stat.
		*set respected %+20
		*goto pvlabelext
	*selectable_if (respected > 13) #I boost ${youdhis} Feared Stat.
		*set respected %-20
		*goto pvlabelext
	*if (legended = 65) #I boost  ${youdhis} Legend to 66.
		*set legended +1
		*goto pvlabelext
	*if (legended = 64) #I boost ${youdhis} Legend to 66.
		*set legended +2
		*goto pvlabelext
	*if (legended < 64) #I boost ${youdhis} Legend by 3.
		*set legended +3
		*goto pvlabelext
	*if ((freewsone) and (warningsysnine = false))  #I unlock a free MeChip Warning System for ${codenamed}, courtesy of the MeChip Corp.
		*set warningsysnine true
		*achieve achievethewar

		The MeChip Warning System 9.0 has been automatically loaded onto ${codenamed}'s MeChip and will activate when ${youdze} need${youdzes} it next.
		*goto pvlabelext
	#I decide that ${codenamed}'s Stat Levels are already in their ideal ranges, so I don't boost any of the available options.
		*goto pvlabelext

*label pvlabelext

"Market research indicates," GG begins, his eyes scanning a holo-report, "that after this horrific Slaughtering event, the majority of the audience sees ${codenamed} as incredibly brave, not backing down in the face of impossible odds. As a result, most viewers currently think of our dear ${codenamed} as
*if (respected > 50)
	the Dark Horse of our competition, the unexpected hero who has come from behind to now have the greatest chance of winning a spot on The American Protectorate."
	*if (respected > 70)
		*achieve respectedfinal
		*set extravote true
	*goto lbump
*else
	the Dark Upstart of our competition, a hero who stands poised to effect great change, especially since most odds are now in ${youdhis} favor to win a spot on The American Protectorate."
	*if (respected < 30)
		*achieve fearedfinal
		*set extravote true
	*goto lbump

*label lbump

Hearing this, you think it sounds right on point—and hopefully in line with what ${codenamed} would want, too.

*if (rlshp_eps <= 50)
	*page_break

*set legended -10

"As expected, however, all of our Finalist heroes took a small Legend hit after news of what happened broke to the public. I fully expect this will be remedied once our own episode coverage airs, but in the meantime this deduction has 
*if (legended < 16)
	stuck ${codenamed} at the Civilian Legend Level.
	*goto legendsecover
*elseif (legendleveltwo = false)
	*achieve legendcattwo
	*set legendleveltwo true
	*goto legendtests
*else
	*goto legendtests

*label legendtests
*if (legended >= 56)
	still left ${codenamed} with the best Legend we could expect, upgrading ${youdhir} to the Amateur Legend Level.
	*goto legrewards
*elseif (legended > 40)
	still left ${codenamed} with a respectable Legend, upgrading ${youdhir} to the Amateur Legend Level.

	*label legrewards
	*achieve legendcatthree
	*set legendlevelthree true
	*set hiddenimmunitychance true
	*goto legendsecover
*else
	left ${codenamed} positioned at the Trainee Legend Level.
	*goto legendsecover

*label legendsecover

"Now, perhaps most importantly, my team and I have been trying to track all of the Finalists' backgrounds, choices, and character profiles in the hopes of pinpointing some key lessons they might be able to learn during their time on the show."

*if (rlshp_eps > 50)
	*page_break

You're stunned to hear GG say these words—this isn't something you'd expect from the drama-master, at all. This sentiment must express itself on your face, because GG smirks at you as he continues.

"We can go over the entire list later if you'd like, but for ${codenamed}, we've been silently tracking how ${youdze} decide${youdzes} to cope with ${youdhis} Ani-Morpho-transformations. If we want to help ${codenamed} evolve even further into an Underrepresented representative, we should try to help ${youdhir} realize that 
*if (image > 50)
	${youdze} should never be self-conscious about ${youdhis} Ani-Morphs, since ${youdze} occasionally can be.
*if (image <= 50)
	sometimes ${youdze} use${youdzes} ${youdhis} Ani-Morphs as a self-defense mechanism to separate ${youdhir}self from others, especially when ${youdze} ${youdzeis} afraid of how ${youdze} might be judged for them. 
*comment endif

"${codenamed} has already started to change this behavior, but if we can continue to push ${youdhir} to use ${youdhis} unique individuality to connect instead of divide, it would be incredibly powerful. Do you think we'll still be able to help ${codenamed} do that, after all that has happened?"

Listening to this insight, you fight your urge to seem continually surprised and answer GG's question instead.

*fake_choice
	#"I certainly hope so."
	#"It's our job to make sure we do, isn't it?"
	#"I don't think ${codenamed} is going to agree with that assessment at all."

"Well, I can always send Mara in to—"

"That monster is never getting near any of my Rookies ever again," you interrupt forcefully. "Especially not after that nonsense she pulled with Transfer at the voting ceremony."

"Suit yourself," GG sighs, crossing his arms across his massive chest.

"Why do you insist on doing things that way, on using people like Mara?" you can't help but ask, feeling like all the progress you've just made with GG is about to be washed away.

"My dear, I think you're starting to learn that this business has some very necessary evils," GG says, his eyes set directly on yours. "So, my luscious Lyra, don't you see? I do these things so that you don't have to."

*page_break

You look back at GG and suddenly, something clicks: Could it actually be that GG doesn't underestimate you at all? That really, all this time, GG has been looking out for you? 

For a moment you see it in GG's face—maybe there's even something about you that he admires, something that he wants to…protect?

Whether that's true or just in your head, it then becomes clear that for you and GG, only one thing matters.

You're a team.

Which is good to finally know, because there is so much work still left to do.

*finish NEXT CHAPTER: REDEMPTION CODES
