
*comment é x

*image interlude1.png center Interlude One: Weaving
([i]New Character Perspective[/i])

*page_break
*achieve weaverpersp

"This is exactly the kind of juvenile nonsense that derailed the first season."

"That's rather dreary, dearie. And dramatic. The only reason that first season wasn't a complete disaster was that the producers knew how to do their jobs."

"It actually was a complete disaster, let's be clear on that. It just happened to get ratings as a result. We're supposed to be doing things differently this season. Hiring back that producer who pushed Black Magic over the edge and manipulated Wintry into switching sides is absolutely—"

"Necessary. Mara is going to help us get the show we need, especially given our little ratings decline. Want to know what won't? Hiring your ${weaverne} to do a job ${weaverze} can't possibly—"

"Finish that sentence. I dare you."

They don't know you can hear them through the door and down the hall, that you can practically feel the righteousness charging Aunt Lyra's words and the animosity dripping off of GG's. Not that this is anything new for you—you're used to people talking about you as if you're not really there. Just because you're visually impaired, people tend to assume you can't hear them, either.

*page_break

"I was going to say, my anxious apple, that your ${weaverne} has no production experience," GG answers. "I'd never dream of discriminating otherwise."

"You were singing a very different tune when I first showed you Weaver's costume sketches," Aunt Lyra fires back. "What did you call them, 'divine designs?'"

"Divine they remain, which is only further proof of the fact that design is also where Weaver ${weaverhir}self should remain. $!{Weaverze} will make a scrumptious stylist! It's certainly enough to be handed that position on a silver platter, why must ${weaverze} also take the place of a production handler?"

Hearing GG's question, you have to admit it's a potentially valid one.

*choice
	#After all, I want to be a famous costume designer, not a producer.
		You're still not sure you'd be any good at producing, since it's not exactly something you ever wanted to do.
		*goto manyathang
	#This is my first job out of design school, so Aunt Lyra is giving me quite a bit of responsibility.
		If Aunt Lyra thinks being a producer is also a good thing, you're not about to question her decision. You'll do anything to get this first opportunity in design.
		*goto manyathang
	#Whatever I'm doing, I know the most important thing here is gaining experience and getting the heroes here to like my costume designs.
		Producer, stylist, both, or neither—your goal here is to make as many heroic friends as possible to launch your costume-designer career.
		*goto manyathang
	#I want to prove GG wrong. Just because I was born blind doesn't mean I can't do both jobs.
		Most people assume you're not able to do the things they take for granted.
		*goto manyathang

*label manyathang

Many things about this experience are bound to be new to you, but one thing you're quite used to is people underestimating you. Even with all the advancements made by MeChip technology to aid the visually impaired, you still don't see the world the way everyone else does. However, you've always known that's actually your greatest strength, especially as a designer. Your costume designs aren't influenced by anyone, since they are singularly inspired by the visions in your own mind.

These visions are also fueled by your unique Power to generate fabrics of all kinds—you can spin anything from cashmere to cotton to brand-new inventions, like your favorite carbon-fiber bulletproof crossbreeds. You were quite literally born to be a costume designer, and Aunt Lyra has always been one of the few people who truly values the fact that you "see" the world differently from everyone else. Which is why you trust her, even if you don't always agree with her.

*page_break

"If you knew Weaver, you wouldn't be questioning ${weaverhis} ability," Aunt Lyra counters. "Give ${weaverhir} one week and ${weaverhis} assigned Finalists will trust ${weaverhir} completely."

"I can say the same of the ever-experienced Mara," GG counters. "Tit for tat. See, the art of compromise? I handle the Veterans with my team and you handle the Rookies with yours, as we agreed. All is as it should be."

GG's words sound innocent enough, but you know a dig when you hear one. So does Aunt Lyra: her current stretch of silence must be building to something.

"Look at all the natural drama we have in this high-pressure situation, with egos clashing and different personality types having to work together," Aunt Lyra says calmly. "We will get what we need with nudges and inspiration, not manipulation and brainwashing."

"You think there wasn't a time I believed that too?" GG almost laughs. "It's an inspiring speech, my peach, but one spoken like a true amateur."

*page_break

[i]Oh no[/i], you think—Aunt Lyra isn't going to like that. She isn't going to like that at all.

"Let me remind you that I am the youngest and most successful PR director for the Department for the Regulation of Powered Resources," Aunt Lyra begins. "I am also the only reason your dysfunctional American Protectorate survived the operational transition under the DRPR's jurisdiction. I am now this show's official liaison to the DRPR, which also makes me your completely equal co-executive Producer. I am many things, but an amateur is not one of them. And don't ever slugging forget it."

You don't hear any response for several seconds, save for the sound of GG rolling towards the door, his people mover straining against the wooden floorboards as he moves.

"The proof, as they say, shall be in the producer pudding," GG finally sighs. "Since we're unlikely to agree any time soon, why don't we embrace the spirit of competition we inspire among the production handlers? I will take charge of the Veterans production and you will take charge of the Rookies production. Until the merge, may the best producer win."

"All I care about is The Hero Project and the future American Protectorate winning," Aunt Lyra responds. "So I will ensure that they survive your antiquated antics."

"She catches on quickly, this one," GG laughs, opening the door so his voice booms even louder. "There may be hope for you yet, little Lyra. Enjoy your handler meetings—I know I will enjoy mine."

*page_break

As you listen to GG rolling down the hall away from you, you figure that's probably your cue. You pocket the strand of silk you were spinning between your fingers, then straighten your bionic glasses and stand. Stepping forward, the hallway suddenly vibrates into focus, showing you the outlines and shapes of everything in front of you.

You can only make out the impressions of things in grayscale, but whatever you might miss is more than covered by the sonar stabilizer and MeGuide companion loaded into your MeChip. There are some visually impaired individuals who opt for full 3D holographic renderings, but you prefer to see the world as it is, not as it is digitally represented—even if that means maintaining certain limitations.

As you step into the conference room where Aunt Lyra sits, your MeGuide, Seamstress Seamanda, appears holographically in your peripheral mind-vision wearing the classic carbon-fiber costume you designed for her—one of your first designer creations ever. MeChip Seamanda offers to verbally communicate Lyra's identity, but you dismiss the option, instead making your way towards the nearest chair.

*page_break

"I assume you heard all of that from down the hall?" Aunt Lyra says, apparently typing furiously on the holo-keyboard glowing on the table before her. "Just another reason you're going to be an invaluable asset." 

Aunt Lyra mutters this last part to herself as she wraps up whatever she is typing. You sit down, causing the grayscale projections to cease—you find them to be pretty exhausting, so you usually only use them when you're moving. Besides, you can still tell that Aunt Lyra raises her head to face you from the sonar stabilizer and the whiff of her post-swim lotion wafting your way.

You take this gesture as your opportunity to speak up.

*choice
	#"GG will come around once he sees the results we'll get doing it your way."
		"I agree, but you just leave GG to me," Aunt Lyra says. 
		*goto alreadytold
	#"I don't want you to use precious political capital sticking up for me, Aunt Lyra."
		"You leave GG to me," Aunt Lyra says. 
		*goto alreadytold
	#"Let's get to work and prove GG wrong."
		"You leave GG to me," Aunt Lyra says. 
		*goto alreadytold
	#"I'm fine just being the costume designer. That's more than enough for me; you know that."
		"I know that," Aunt Lyra says. 
		*goto alreadytold

*label alreadytold
"And I've already told you, hiring you isn't some grand selfless gesture. I need someone I can trust in the trenches, because GG is right about one thing: everyone is going to see me as the newbie amateur until I prove myself otherwise.

"So you're going to be my hidden set of ears around here—people feel free to talk in front of you, and you can hear things no one else can. And given all the time you're going to be spending with the Finalists to design their customized costumes for the finale, you're going to be seen as a trusted designer first and foremost. The fact that you're my little producer secret weapon is going to be invaluable."

You fight the urge to smirk at Aunt Lyra—she has such a finely tuned moral compass and sense of justice that it's very easy to forget how cunning and calculating she can be. Most people assume these qualities are mutually exclusive, which always works to her advantage.

"What?" Aunt Lyra says, clearly reading your expression. "I believe in building a better show and writing new rules on how that's done, but that doesn't mean we're immune to the politics here. But enough, I've got a million things to do, so let's get through this. I just sent you the full background files on your assigned Finalists."

*page_break

On cue, MeChip Seamanda arrives with your MeMail from Aunt Lyra. You mentally activate dictation as Aunt Lyra speaks—you've gotten very good at listening to multiple voices at once.

"So I'm assigning you three Rookies and giving four to my other production handler," Aunt Lyra begins. "You'll meet Kevin later, because you two are going to be working closely together. We want the Rookies to feel like a unified team as much as we can, like we're all in this together against the Veterans. And really, we are, because as you know your paycheck depends on how far your three Rookies make it in the show. To ensure their success, priority number one will be getting them prepared to do their heroic job. Priority number two is getting them to open up to you and the cameras. 

"All right, let's start with ${codenamed}," Aunt Lyra rolls on. "Battle Stats place ${youdhir} as 
*if (defensive > 50)
	a defensive
*if (defensive <= 50)
	an offensive
fighter who prefers using ${youdhis}
*if (fighting > 50)
	${kungfuspecialty} Kung Fu and ${maspecialty} martial-arts specialties
*if (fighting <= 50)
	Ani-Powers
in battle scenarios. When ${youdze} ${youdzedo} utilize ${youdhis} Ani-Powers, ${youdze} tend${youdzes} to favor more
*if (physical > 50)
	physical
*if (physical <= 50)
	intangible
applications. This is all important to remember for missions, though that will be more my responsibility as DRPR liaison. You should really focus on ${codenamed}'s character profile.

"So far, ${youdze} seem${youdzes} to be in the competition for
*if (societal > 50)
	socially responsible, societal motivations, to spread awareness about Underrepresented Powered issues. On these issues,
*if (societal <= 50)
	personally responsible, individual motivations, to make a better life for ${youdhir} and ${youdhis} sister. On Underrepresented Powered issues,
${youdze} tend${youdzes} to fall more on the 
*if (traditional > 50)
	traditional spectrum.
*if (traditional <= 50)
	radical spectrum.
Understanding and remembering this will help you bond well with ${codenamed}. Most importantly for our purposes, viewers seem to
*if (respected > 50)
	really respect
*if (respected <= 50)
	be fearful of
${codenamed} so far, thanks largely in part to ${youdhis} tendency to be
*if (public > 50)
	open to public transparency."
*if (public < 50)
	less showy and more private."

*page_break

*if (legended < 30)
	*set legended +1
*if legendleveltwo
	*goto nexttime
*else
	*achieve legendcattwo
	*set legendleveltwo true
	*goto nexttime

*label nexttime

"All of this has added up to a Legend Level of ${legended}, which is indicative of ${codenamed}'s overall impact with viewers. 
*if (legended > 15)
	It also places ${youdhir} firmly in the DRPR Legend Trainee category.

*if (rlshp_eps > 50)
	"${codenamed} has impressed me and the rest of the producers thus far, so we're committed to doing any image therapy that might seem prudent. Are there any areas that need improving?" Aunt Lyra asks, evidently leaning back in her chair from the sound of leather stretching.

	Your MeReport lets you hear all of these metrics that Aunt Lyra just summarized, which is good, since you can tell this is a mini test of how closely you've been paying attention. Knowing that right now ${codenamed}'s Public & Private and Legend Stats matter most, you decide:
	*goto improvestatstime
*else
	"So what do you think?" Aunt Lyra asks, evidently leaning back in her chair from the sound of leather stretching. 

	"I think I need to work on strengthening ${codenamed}'s relationship with the producers in general," you say. "I know if that relationship improves, ${codenamed} will receive more support and attention in meetings like this that will help ${youdhir} advance."  

	"Great," Aunt Lyra responds, seeming pleased with your logic.
	
	*page_break
	*goto skipmoveon

*label improvestatstime
*choice
	*selectable_if (defensive < 60) #"I'm going to boost ${youdhis} Defensive Stat."
		*set defensive %+20
		*goto pvlabel
	*selectable_if (defensive > 40) #"I'm going to boost ${youdhis} Offensive Stat."
		*set defensive %-20
		*goto pvlabel
	*selectable_if (physical < 66) #"I'm going to boost ${youdhis} Physical Stat."
		*set physical %+20
		*goto pvlabel
	*selectable_if (physical > 34) #"I'm going to boost ${youdhis} Intangible Stat."
		*set physical %-20
		*goto pvlabel
	*selectable_if (traditional < 76) #"I'm going to boost ${youdhis} Traditional Stat."
		*set traditional %+20
		*goto pvlabel
	*selectable_if (traditional > 24) #"I'm going to boost ${youdhis} Radical Stat."
		*set traditional %-20
		*goto pvlabel
	*selectable_if (societal < 81) #"I'm going to boost ${youdhis} Societal Stat."
		*set societal %+20
		*goto pvlabel
	*selectable_if (societal > 19) #"I'm going to boost ${youdhis} Personal Stat."
		*set societal %-20
		*goto pvlabel
	*selectable_if (public < 77) #"I'm going to boost ${youdhis} Public Stat."
		*set public %+20
		*goto pvlabel
	*selectable_if (public > 23) #"I'm going to boost ${youdhis} Private Stat."
		*set public %-20
		*goto pvlabel
	*selectable_if (respected < 77) #"I'm going to boost ${youdhis} Respected Stat."
		*set respected %+20
		*goto pvlabel
	*selectable_if (respected > 23) #"I'm going to boost ${youdhis} Feared Stat."
		*set respected %-20
		*goto pvlabel
	*if (legended = 29) #"I'm going to boost ${youdhis} Legend to 30."
		*set legended +1
		*goto pvlabel
	*if (legended = 28) #"I'm going to boost ${youdhis} Legend to 30."
		*set legended +2
		*goto pvlabel
	*if (legended < 28) #"I'm going to boost ${youdhis} Legend by 3."
		*set legended +3
		*goto pvlabel
	#"$!{Youdhis} Stat Levels are looking great right now, so I don't need to boost any of the available options," I say, knowing that passing up a boost now will give me the potential to unlock a free MeChip Warning System upgrade later, after the Rookie-Veteran merge, if ${codenamed} advances that far.
		*set freewsone true
		*goto pvlabel

*label pvlabel

"Great," Aunt Lyra responds, seeming pleased with your choice. 
*label skipmoveon
"Moving on, I don't want to assign any strict storylines or personas to the Finalists just yet, but based on ${youdhis} behavior so far, we can begin to think of ${codenamed} for now as our resident
*if (public > 50)
	Outspoken Role Model.
	*achieve outspokenactivist
	*goto batrung
*else
	Mysterious Wildcard.
	*achieve mysteriouswildcard
	*goto batrung

*label batrung
Your goal now is to nudge ${youdhir} in that direction, as long as ${youdze} seem${youdzes} amenable. 

"Also, you've been given the history file on ${codenamed}'s background. So far ${youdze} ${youdzehas} been 
*if usejkstory
	open about ${youdhis} little sister, JK. Viewers seem to love her and love ${codenamed} as a protective older sibling figure, so make sure ${youdze} keep${youdzes} that up.
	*goto subparents
*else
	relatively quiet about ${youdhis} little sister, JK. I have a feeling viewers would love her and love ${codenamed} even more as a protective older sibling figure, so see if you can get ${codenamed} to open up about JK slowly, if ${youdze} seem${youdzes} comfortable with it.
	*goto subparents

*label subparents
It turns out JK will be living in ${codenamed}'s room in The Hero Project mansion, since ${youdze} ${youdzeis} JK's sole guardian, so that might help us out on this front.

"The subject of their parents, however, is extremely touchy," Aunt Lyra sighs. "${codenamed} doesn't seem willing to talk about it, but I think viewers will respond well if ${youdze} ${youdzedo}. Though this will only benefit ${codenamed} if ${youdze} really want${youdzes} to open up about it, so don't try to push it too hard. Just make sure ${codenamed} knows all of what I'm telling you now, in rosier terms.

"Which brings me to my final point: never force any of your Finalists to go beyond what they seem comfortable sharing with the world. Your first priority is protecting them, and your second priority is ensuring they succeed on the show. If you can get them to a place where they can better connect with viewers, go for it. Just never try to turn these heroes into anything they aren't already. Our goal is to enhance and magnify what is already there.

"And that, my dear ${weaverne}, is how we're going to beat GG at his own game."

*page_break

Taking this all in, you have to admit that you think Lyra's strategy sounds much better than what you saw on the first season of The Hero Project, where the Finalists seemed to warp into extreme versions of themselves under the glare of the spotlight. If you can help protect the new Rookie heroes from falling into this trap, then Aunt Lyra is right—you most certainly do belong here.

After all, your mission as a costume designer has always been to enhance what makes each hero unique and make them look their absolute best. So why can't that be your mission as a production handler and friend to the hero-stars, as well?

"All right," Aunt Lyra resumes, pulling your attention back into the room. "Before we move on to your next Finalist, there's one last piece of ${codenamed} business to tend to. We're instituting a new feature this season, Viewer Rewards. Based on each Finalist's Legend Level, the viewers can vote for which Finalists they'd like to reward with extra advantages.

"This first Viewer Reward will assign extra Leaderboard points or Power & Health booster packs for the upcoming Live Finals Mission. ${codenamed} has earned one Reward from the viewers already, so what do you think ${youdze} would prefer?"

Mulling this over a bit, you definitely think ${codenamed} will be most excited about:

*choice
	#"Extra Leaderboard points."
		*if (legended > 22)
			*set lb +10
			"Great, that earns ${codenamed} 10 extra Leaderboard points at the start of the next mission,"
			*goto otherangle
		*else
			*set lb +5
			"Great, that earns ${codenamed} 5 extra Leaderboard points at the start of the next mission,"
			*goto otherangle
	#"A Power & Health booster pack."
		*if (legended > 22)
			*set phtwenty true
			*set power 120
			*set health 120
			"Great, that earns ${codenamed} a starting level of 120 Power & Health for the next mission,"
			*goto otherangle
		*else
			*set phten true
			*set power 110
			*set health 110
			"Great, that earns ${codenamed} a starting level of 110 Power & Health for the next mission,"
			*goto otherangle
	#"A special hint in the next mission."
		*set specialhint true
		"Great, that earns ${codenamed} a secret special hint, which will come in handy in the next mission,"
		*goto otherangle

*label otherangle
Aunt Lyra says. "I almost forgot, there is one last angle I want you to work with ${codenamed}: Ani-rights. Especially since the focus of this season's missions will be a fight to shut down The InfraCircle."

"Wait, weren't we supposed to be looking into the Ani-cides for the official missions?" you ask. You've been following this deadly string of Animalistic hate-crime murders, dubbed the Ani-cides, which has targeted Ani-gang members and Ani-villains specifically. Given that these targets are all Ani-criminals, no one knows if these serial murders are the work of some new vigilante or an outright geneist, but they have been deemed hate crimes nonetheless. Which surprises you—usually Ani-Powereds don't receive the same protection or attention from the police or the media as other Powered groups. It's unfortunate that it took a crime spree of such heinous magnitude to change that.

"We are still looking into the Ani-cides, but the DRPR just doesn't have enough hard intel to form a full mission yet, let alone an entire season worth of live missions," Aunt Lyra sighs. "Though we're hoping we might come across some leads on the Ani-cides by going after InfraCircle.

"Unfortunately, in selecting a mission target, we've witnessed an unexpected power struggle among Millennia City's villainous community, with many of them vying for enough prominence to be featured as the villains of The Hero Project's Live Finals," Aunt Lyra continues. "Thankfully most have not been threatening enough, save for the InfraCircle. Thematically, they actually serve as a perfect target enemy, since they grew out of the first season's Ani-terrorist villains, The InfraOrder."

*page_break
*set infracirclepicto true

"We'll be briefing the Finalists soon, so you'll receive more comprehensive information later, but what you need to know to get started is that
*if trilogyreader
	after a mass breakout at The Devoid, many former members of Smyther's Splice Circle and Culic's InfraOrder have formed this new organization of Ani-activists. 
*if newreader
	many former members of dissolved Ani-activist criminal organizations escaped from The Devoid prison complex for Powereds during a mass breakout earlier this year. They have united these two groups, The Splice Circle and The InfraOrder, to form this new Ani-group: The InfraCircle.
*comment endif

"Their goal is to create a sovereign space for Ani-Powereds to live free of oppression and American law, police brutality, and hate-crime sprees like these Ani-cides. These radicals have decided to create a hidden base in the Big Sur wasteland east of Millennia 
*if trilogyreader
	City. 
*if newreader
	City created by the late Prodigal, before she became a MeChip personality template. 
There's more information on all of this loaded in to the Stats Screen, but here are the bare-bones basics, for now," Aunt Lyra says, just as MeChip Seamanda appears in your mind. 

[b]THE INFRACIRCLE[/b]
*line_break
[b]Big Sur Haven[/b]: CULIC
*line_break
[b]Strike Team Recruitment[/b]: SCOUNDREL
*line_break
[b]Ani-Gang Funding[/b]: SMYTHER

"We can go after The InfraCircle not just because their leaders are all fugitives that top the DRPR Ten Most Wanted List, but also because their entire operation is illegal," Aunt Lyra explains. "The InfraCircle haven is hidden in a secret location in the quarantined Big Sur Wasteland, led by Ani-terrorist Culic, camouflaged by tech-Powered fugitive Splicina, and apparently kept running by a newly united group of Natural-Resource Powereds.

"Meanwhile Scoundrel, the turkey-Powered mole from the first season of The Hero Project, runs their elite Recruitment & Strike Squad. Perhaps worst of all, The InfraCircle funds this entire endeavor through Millennia City's reformed Ani-gang network, run by the infamous crime boss Smyther." 

*page_break

"What about ${codename} and The Millennial Group?" you ask, always eager to hear anything about your favorite heroes of all time. The idea that you might get to design for The Diva, the most epic Millennial Group member ever, as a new Hero Project Judge is almost too much. The honor of dressing her is definitely considered the ultimate heroic costume designer achievement—though you haven't even worked up the courage to ask Aunt Lyra if you can meet The Diva, let alone design a costume for her at some point.

"Isn't The InfraCircle usually their territory?" you ask, forcing yourself to stay on topic. "And if not The Millennial Group, what about The American Protectorate?"

*if (newreader) or (mgleader)
	"The Millennial Group is dealing with a crisis of its own right now,
	*goto riserleader
*else
	"${codename} has teamed with The Millennial Group as a consulting member to deal with a new crisis,
	*goto riserleader

*label riserleader
some new Infini despot named Infinitum who is wreaking havoc up near the Canadian border," Aunt Lyra explains. "Since they have their hands full, The Hero Project has been given primary jurisdiction over The InfraCircle, thanks to my internal DRPR connections. But ${codename} and many Millennial Group members will be helping out as guest Judges and Mentors this season, so we'll get advice and intel about the InfraCircle from them as they rotate through.

"As for The American Protectorate, they're a complete mess. When they're not threatening to tear each other's heads off, they're simply not Powerful enough to face any credible threat. They're currently a PR nightmare, so we're keeping them sequestered here until we can team them up with the future group of merged Finalists later in the competition. 
*if trilogyreader
	None of them are happy—Jury has thrown near-daily fits—but as far as I'm concerned, this is the bed they made for themselves.
*comment endif

"But enough about them," Aunt Lyra sighs. "For the very first Live Finals mission, we're going after Smyther's Ani-gang generals, in hopes of cutting off the InfraCircle's funding. So before we move on to your next Finalist, I wanted your insight—what do you think ${codenamed} will think of this mission?"

*choice
	#"I don't think ${youdze} ${youdzeis} going to like it. $!{Youdhis} politics fall more in line with The InfraCircle's than against them."
		*set traditional %-15
		*set societal %+10

		You know this is going to be a very loaded mission for ${codenamed}, so you're going to have to do your best to get ${youdhir} comfortable with it and make sure ${youdhis} opinions on these matters are heard.
		*goto weavend
	#"I think ${youdze} will want to stand up as a positive force against potentially negative Ani-stereotypes."
		*set traditional %+15
		*set societal %+10

		You figure this is the exact reason ${codenamed} signed up for The Hero Project in the first place, to combat existing negative Ani-Powered stereotypes.
		*goto weavend
	#"No matter how ${youdze} feel${youdzes}, ${youdze} will serve as a great asset in the mission, given ${youdhis} breadth of Ani-knowledge. 
		*set traditional %+15
		*set societal %-10
		 
		You're not going to put words in ${codenamed}'s mouth; you'll have to wait to see how ${youdze} feels about this mission. You're also going to have to do you best to get ${youdhir} comfortable with it and make sure ${youdhis} opinions on the matter are heard.
		*goto weavend
	#"I'm not sure ${codenamed} will care, since ${youdze} seem${youdzes} to be here for very personal reasons.
		*set traditional %-15
		*set societal %-10
		 
		${codenamed} gives off the impression that ${youdze} ${youdzeis} here for some deeper personal reason, one that doesn't seem as important as Ani-politics. You suppose you'll find out what it is soon enough, if you do your job right.
		*goto weavend

*label weavend

"Whatever ${codenamed} ends up thinking, I'm very excited to meet ${youdhir}," you say. "I've already got some ideas for a flexible and easily adjustable costume that complements ${youdhis} Ani-Morpho transformations. It'll be breathable or insulated depending on the changes that—"

"I'm sure it's going to be as exceptional as all of your other costume designs," Aunt Lyra interrupts. "But time is short. Let's move on to your next Rookie Finalist assignment."

You nod at Aunt Lyra, knowing she is probably right. Still, as she keeps talking, you start penciling a mental sketch of the costume for ${codenamed} in your mind, aided by MeChip Seamanda, of course.

*comment Ignite is accounted for in Crystalline stat, Tarsiero only affected by how you treat him (doesn't care about others and gossip and rumors).
*if ssprove
	*set rlshp_crystalline %+15
	*set rlshp_transfer %+15
	*set rlshp_griffin %-15
	*set rlshp_missboss %-15
	*goto movealonge
*else
	*set rlshp_crystalline %-15
	*set rlshp_transfer %-15
	*set rlshp_griffin %+15
	*set rlshp_missboss %+15
	*goto movealonge

*label movealonge
*set partonefinrlshp false
*set parttwofinrlshp true

*comment Finalist Rlshps Stats Screen should read Crystalline & Ignite, then four unnamed Rookie bars (StarSoar and Rookies should disappear)

*finish NEXT CHAPTER: ANIMAUL
