*comment é x

*text_image chap1.png center Chapter One: Deep Throw

You have no idea what to expect next, but that's nothing new for you. Instead, you focus on the immediate things: the morning dew sloshing on the grass underneath your boots, the sun shifting into position above you, the gleam reflecting off of the enormous Ferris wheel in the distance. You bet that's going to be your first challenge: beating out the dozens of Powered heroes who have gathered here to gain access to that behemoth. Who knows what they'll want you to do once you get inside…if you get inside.

But you quickly erase any trace of "if" from your mind—there can be no doubt for you, not today. You have to win. You don't have any other option.

So you look to your left, where a row of contestants stretches across the open field, a sea of flexing supermuscles, whining turbines, and crackling energy. To your right is more of the same: the nation's boldest and brightest, assembled to tear each other apart for their one big shot.

You're not here for that, though—at least not like everyone else. You're here because your little sister's life depends on it. Fail today and she will die, plain and simple.

Which is why you're going to win.

*page_break

"There are one hundred of you gathered here today, selected as the best of the best from our national auditions," a smooth voice suddenly announces. 

You crane your neck up to find a holographic image hovering in front of you, duplicated several times down the row of contestants. The holo-image depicts a handsome man wearing a suit, his face animated as much as its altered plasticity will allow.

"By the end of today's Semi-Finals, only fourteen of you will remain," the host announces, his voice filled with manufactured suspense. "As you know, you've all been paired into teams of two and will partake in an astonishing race. Each round, the slowest teams will be eliminated, until only seven teams are left standing."

You look to your right, where your own partner stands. His face is mostly obscured by his sleek astronaut helmet, but you can still see that he nods at you, as if to say, "we've got this." You nod back—you may have only recently met this StarSoar guy, but luckily you've already become fast friends.

*page_break

"In Round One, your task is simple," the host continues, commanding your attention. "Race across this open field to the newly constructed MillenniWheel. There are twenty available pods that will hold two teams each, which means that the last ten teams to arrive will be eliminated. So you'd better make sure you get there by. Any. Means. Necessary."

As the host finishes, a fleet of floating camera orbs descends to film the proceedings. One of the melon-sized orbs hovers between you and StarSoar, serving as a potent reminder that this is all for America's number-one reality show. What you do will soon be seen by millions of viewers—if you're lucky, that is. You know that part of your success here will depend on being somehow worthy of attention.

Fortunately, you look pretty slugging awesome today, though you know all too well that it's not always like this. You have the unique ability to wake up every day with a different Animalistic Power set, but these transformations are not under your control. Some days your Power manifestations can be useless or jarring or downright ridiculous, but today you find yourself in half-hawk mode. Currently, your favorite change is:

*fake_choice
	#The set of impressive wings that crease my back.
		The wings hurt like hell coming in
		*goto likehellcom
	#My eyes, which are now speckled amber with multispectral vision.
		The eyes burned like hell as they developed
		*goto likehellcom
	#The talons hidden underneath my fingernails, ready to unsheathe when I need them.
		The talons hurt like hell coming in
		*goto likehellcom
	#The fact that these were the only changes today, so I look completely human otherwise.
		The wings hurt like hell coming in
		*goto likehellcom

*label likehellcom
earlier this morning, but at least you didn't grow a beak this time—those are twice as painful and always end up obscuring your face. You never know what your Powers will bring on a daily basis, but today they did you justice. 

Which means that you and StarSoar are going to crush this. 

"You're all about to enter this nation's most prestigious competition, The Hero Project," the host continues, clearly gearing up for the end of his speech—and causing your muscles to strain from your pent-up adrenaline. "Now only one question remains…

"How high will you rise?"

*set legended +5
*page_break

Apparently understanding that this somehow means "Go," StarSoar bursts forward in an explosion of blue thrust, instantly living up to his name. You flap your wings and shoot forward with surprising speed, your avian eyes protected under transparent eyelids as you keep pace with StarSoar. 

You break in front of the pack and follow StarSoar's lead as he climbs high into the sky, obviously hoping to soar above the fray. Despite your speed, you can already see that you're going to be targeted—directly below you, a pair of rabbit and rat Ani-Powered human hybrids leap and scramble forward. Knowing what comes next, you try to flap faster to outfly the furry duo, but you watch as the rat-man latches onto the back of the rabbit-woman. She then pumps her rabbit legs, and the pair leap into the sky towards you, their teeth and claws bared.

Unfortunately, you're all too used to this kind of Ani-discrimination. On your bird days, rodent and reptile Ani-Powereds always end up harassing you. Ani-order rivalries run deep, especially where you're from. That's okay, though, because today…

You're the predator.

*choice
	#Once the duo get close enough, strike them with my talon-hands. (Power Cost 10)
		*set defensive %-10
		*set physical %+10

		You pretend not to see the approaching attackers until the last second, when you flick your human fingers forward and unsheathe hooked talons. 

		Jerking left, you spin around and use your momentum to slash at the duo. Their rodent reflexes make them fast enough to dodge your swipe, but this still forces them to uncouple and lose their momentum.
		*goto afterfurry
	#Knock them out of the sky with a sonic screech. (Power Cost 10)
		*set defensive %-10
		*set physical %-10

		Once the duo have leaped close enough, you jerk left and spin around to face them. Opening your mouth wide, you scream at the top of your lungs, unleashing an invisible beam of sonic screeching force.

		Your vocal blast lands directly in the spot where the rat-man clings to the rabbit-woman's back, forcing them to uncouple and lose their momentum.
		*goto afterfurry
	#Grab the duo and fly them higher, then drop them to the ground helplessly. (Power Cost 10)
		*set defensive %+10
		*set physical %+10

		You pretend not to see the approaching attackers until the last second, when you flick your human fingers forward and unsheathe hooked talons. 

		Jerking left, you spin around and reach out to hook into both opponents. Catching them off guard, you flap your wings fiercely upward, pulling the rabbit-woman and rat-man with you. Then, before either of them can react enough to fight back, you let go.
		*goto afterfurry
	#Stare them down with my hawk intimidation. (Power Cost 10)
		*set defensive %+10
		*set physical %-10

		You jerk left and spin around to face the duo, narrowing your hawk-eyes with a look of pure intensity. The duo can't help but meet your gaze, and you see it immediately: a primal fear sparks their animal instincts.

		This intimidation distracts the duo just long enough for them to lose their focus, which in turn causes them to lose the momentum of their airborne attack.
		*goto afterfurry

*label afterfurry
*set power -10

You watch for a moment as the rabbit-woman and rat-man tumble helplessly back towards the earth, fighting your own animal urge to swoop down for their broken bodies. Instead, you swivel back to resume your flight pattern.

"Alert. You have used 10 Power. You have raised your 
*if (defensive < 50)
	Offensive
	*goto physinttest
*else
	Defensive
	*goto physinttest

*label physinttest
*if (physical > 50)
	and Physical Power Use
	*goto physinttestend
*else
	and Intangible Power Use
	*goto physinttestend

*label physinttestend
Stats," an automated voice sounds in your head. You know that this voice belongs to your MeChip assistant, or at least the temporary one assigned to you for the Semi-Finals. 

*if newreader
	While mostly everyone these days has a MeChip—tablet technology embedded in the underside of their wrists—not everyone can afford full functionality. You're sure the other contestants are used to more dynamic personalities and advanced features, but today the playing field has been leveled because everyone has been provided with the same MeChip Warning System generic personality. Since you aren't used to this guided tutorial function, you plan to listen to all of the insights and advice offered by the nonvisual assistant.
*if trilogyreader
	You're sure the other contestants are used to more dynamic personalities and advanced features, but today the playing field has been leveled because everyone has been provided with the same generic, nonvisual personality in their MeChip Warning System.
*comment endif 

*page_break

Refocusing on the task at hand, you resume flight beside StarSoar, who has just plowed through a team of contestants who were trying to rise above the race in a lightweight, neon bubble. You're happy to have a partner as impressive as StarSoar—he is basically a human comet, hurtling forward in a streak of howling contrail. He also told you that his sleek white-and-blue astronaut exoskeleton keeps him protected from harm, so he can use his body like a living asteroid. Apparently NASA made the suit for him before he left the Powered Cadet program to pursue his heroic dreams. 

That's the level of talent you're up against in The Hero Project—people who thought being a slugging astronaut wasn't challenging enough. Meanwhile, you're a nobody, forced into being here to save your sister. What chance could you possibly stand?

Then you remind yourself that your Powers are currently allowing you to keep up with StarSoar, pushing you to the front lines in this first round. So maybe you actually do stand a chance at this, despite the odds?

*page_break

Though you're reminded of these odds once again as two twenty-something heroines suddenly ride to the front of the pack on a wave of pink energy, trailed by no less than five camera orbs. You're very used to the world paying attention to traditional-looking Powereds like them instead of Ani-Powereds like you, so you suddenly find yourself wondering: is that what the producers are really looking for here? 

One of the heroines wearing a pink fabric headband generates the wave of energy effortlessly, an easy smile on her face. Her partner, a dark beauty wrapped in a black-and-maroon spandex bodysuit, pulls off streams of the wave energy and balls it between her palms.

The heroines catch up to another team across the field—a short, skinny guy in oversized goggles riding on the back of a triple-wide set of conjoined triplets who leap in great, unison bounds. The goggled guy spots the oncoming heroines and projects an image from his lenses overhead: a white flag waving above a peace sign. He nods at the duo excitedly as they race alongside, sending them a thumbs-up.

Without hesitating, the spandex heroine tears loose a stream of energy from her partner's wave and pummels the triplet-man with pink force. He and the goggle-guy are immediately sent reeling, tumbling so awkwardly that the conjoined triplets separate, bouncing off of each other like human ping-pong balls. Helpless, the goggle guy face-plants hard before being trampled underfoot by the surge of racing contestants. The heroines then speed forward over the fallen team without a second glance and you can't help but wince—that was a seriously humiliating wipeout.

*fake_choice
	#I usually identify as one of those less cool-looking heroes, so I wish I could swoop down and help them.
	#Given the fact that my appearance today makes me look more like one of those shining idols, I suppose I should withhold judgment on any other heroes.
	#I'm going to do whatever it takes to win today, so I'd better get used to ruthlessness and attention-seeking. 
	#I just shake this sight off and redouble my focus on flying.

No matter what, you can't afford for a wipeout like that to happen to you, so you divebomb a bit lower to kick up your speed. Veering underneath StarSoar, you figure that you must be going at least seventy miles per hour—certainly fast enough to outrun the grisly scene below.

As the Ferris wheel finally veers into focus, you start to pull upwards and slow down for your approach. Looking up, you see that StarSoar is beginning to flame out above you. He seems to have only one speed setting: full throttle. Nodding at him, you drift until the last sparks of sapphire thrust die out and StarSoar drops down onto your winged back.

"Excellent observation, friend!" StarSoar shouts down at you, patting you on the shoulder. "I believe it might benefit us to aim for one of the pods at the apex of the wheel, to grant us the best vantage point." 

"On it," you shout back up at StarSoar, your voice coming out with an unintended squawk. Ignoring this, you aim towards a pod at the very top of the wheel, realizing that the height will further separate you from the rest of the Semi-Finalists, since most of them seem to be aiming for the lower pods.

*page_break
*set lb +20

You glide into the highest pod without any further interruption, setting StarSoar down next to you. Inside, you see that the pod's bottom half is made of smooth, seamless silver that gives way to an entirely glass top half, which provides spectacular 360-degree views of Millennia City. The egg-shaped pod is bigger than you expected, too—it could probably fit about twenty people, so you wonder why only two teams are allowed per pod….

You're distracted from this thought as StarSoar holds out his hand, a grin stretching underneath his slate-colored helmet visor. You reach out your own hand and initiate the Dockerbay Bomb, a secret handshake known only to residents of the six-block radius where you live. In fact, from this high up, you can make out the tops of the enormous container cranes that line Dockerbay's shores, just north of Millennia City's gleaming towers.

You and StarSoar assumed that this shared background was exactly why you two were paired up, given the fact that it's pretty rare to live in the unglamorous Dockerbay area. It certainly makes you both underdogs heading into this competition, despite StarSoar's astronomical accomplishments. 

As you finish the handshake and turn to look outwards, you wonder what commonalities might connect the rest of the teams. You try to make out some of the other pairs scrambling into the remaining pods, but StarSoar gasps as a second team lands inside your own pod.

You can immediately tell that this other team must be famous from the way they carry themselves and StarSoar's reaction, but admittedly, you don't know much about the hero world.

*choice
	#I'm fascinated by heroes, but can't really afford the 3V cable service or MeChip news content I would need to follow them.
		*set traditional %+10
		*goto sssplain
	#I'm not interested in mainstream heroic propaganda. Period.
		*set traditional %-10
		*goto sssplain
	#I'm too busy working and taking care of my sister to care about anything else.
		*set societal %-15
		*goto sssplain
	#I don't know any heroes who represent my own story and background as an Ani-Powered, so I don't follow many.
		*set societal %+15
		*goto sssplain

*label sssplain

You informed StarSoar about your relative lack of heroic knowledge, and luckily he turned out to be the biggest hero nerd you've ever met—he even showed you his expansive holo-card collection on his MeChip. Noting your lack of a reaction now, StarSoar tries to whisper as quietly as his helmet microphone will allow:

"That's Fistfull and Monk, from The Millennial Group."

You may not know much about professional heroics, but you do know that The Millennial Group is one of the most prestigious Powered teams in the world. In fact, they're rivaled only by The American Protectorate—and the only way onto that national franchise is to win this very show, The Hero Project.

You look over Fistfull's towering, ten-foot body, and your hawk-eyes focus on the orange spray-tanned muscles bulging underneath his tank top—judging from those, you figure he must be superstrong and superdurable. You also notice that he sports an impressive wedding band on his sausage-like ring finger, which matches the one on Monk's hand. Monk floats in midair beside Fistfull, hir ivory robes brushing the pod's floor. From hir meditative pose, you figure that Monk must have some serious fighting skill to accompany whatever telekinetic Powers currently keep hir afloat.  

"I truly hope that we have to work with these two and not against them," StarSoar gulps, taking in the sight of this intimidating supercouple.

*page_break

Before Monk or Fistfull can say anything, the host's holographic image appears once again, directly between you. 

"All forty of our Semi-Finalist teams have been checked in for Round Two," the host announces, just as you hear the pod doors close and lock shut ominously. "Each team will remain locked in their pods until they knock out the other team—or are knocked out themselves. The faster you defeat the opposing team, the faster you'll be able to race to the final location. 

"Two teams have entered each pod, but only one team will leave," the host finishes, his holo-image beginning to fade. "Good luck, Semi-Finalists! You'll need it."

As the host disappears, you're not sure if it's your heightened hawk senses or your imagination, but you swear you can feel the fear radiating out of StarSoar's exo-suit.

Slugger, you're both screwed.

*page_break

You allow yourself a moment of unbridled panic, but then you force yourself to dig deep. So what if those two are famous and you two are nobodies? You'll have to turn that particular strength into their biggest weakness. 

No one here knows what you can do, especially not the fact that you've been studying martial arts your entire life. You may not be a seasoned hero, but no Ani-Powered survives in a modern city without learning ways to keep protected.

"StarSoar, let's do that thing we talked about," you whisper, falling back as Monk and Fistfull confer quietly in their own corner. "You know, the element of surprise." 

Hearing this, you see StarSoar shake his helmet, trying to snap himself out of his stupor. He turns to you and nods—suddenly you're very thankful that StarSoar insisted that you spend some time this morning talking strategy. Being a hero nerd has its advantages, apparently.

[i]So does being desperate[/i], you tell yourself as Fistfull and Monk turn to you. It's now or never, make it or break it, the moment of truth—and every other cliché you can muster.

Ready or not, here you come.

*choice
	#Utilize my Physical Powers, including my wings and talons. (Power Cost 5-10)
		*if (physical > 50)
			*set lb +15
			*set power -5
			*set legended +2

			You may be a master fighter, but you figure you should take full advantage of your hawk Powers while you have them. Besides, using your Physical Powers worked seamlessly on the rodent duo earlier.

			*label physstand
			*set physical %+15
			*set fighting %-15
			
			Conventional wisdom would match StarSoar's brute force up against Fistfull's girthy durability, pitting you against the more graceful Monk—so you're going to do exactly the opposite. 

			Taking the lead for StarSoar to follow, you roll at Fistfull, catching him off guard with a deadly swipe as you unsheathe hooked talon-claws from your fingertips. Fistfull manages to dodge the blow at the last second, but this only pivots him into the path of your wing, which you slam into his chest full-force.
			*goto ffullfight
		*else
			*set lb +10
			*set power -10

			You may be a master fighter, but you figure you should take full advantage of your hawk Powers while you have them. You're going to try out your Physical Powers this time, instead of the Intangible Powers you used on the rodent duo.
			*goto physstand
	#Utilize my Intangible Powers, including my sonic screech and flight. (Power Cost 5-10)
		*if (physical < 50)
			*set lb +15
			*set power -5
			*set legended +2

			You may be a master fighter, but you figure you should take full advantage of your hawk Powers while you have them. Besides, using your Intangible Powers worked seamlessly on the rodent duo earlier.

			*label intanstand
			*set physical %-15
			*set fighting %-15

			Conventional wisdom would match StarSoar's brute force up against Fistfull's girthy durability, pitting you against the more graceful Monk—so you're going to do exactly the opposite.

			Taking the lead for StarSoar to follow, you roll at Fistfull, catching him off guard by spreading your wings wide as you untuck. Fistfull expects you to strike with your wings, but instead you let a sonic screech rip from your lips. The force of the vocal blast knocks Fistfull backwards as it slams into his chest and he grips his ears in pain.
			*goto ffullfight
		*else
			*set lb +10
			*set power -10

			You may be a master fighter, but you figure you should take full advantage of your hawk Powers while you have them. You're going to try out your Intangible Powers this time though, instead of the Physical Powers you used on the rodent duo.
			*goto intanstand
	#Launch a surprise offensive attack with my fighting ability. (Health Cost 5-10)
		Why waste Power when you can rely on your master fighting skills, which Fistfull and Monk won't see coming? 
		*if (defensive < 50)
			*set lb +15
			*set health -5
			*set legended +2
			You fought offensively against the rodent duo with success, so you figure that you should rely on that strength once again.

			*label offstand
			*set defensive %-15
			*set fighting %+15

			Conventional wisdom would match StarSoar's brute force up against Fistfull's girthy durability, pitting you against the more graceful Monk—so you're going to do exactly the opposite.

			Taking the lead for StarSoar to follow, you roll at Fistfull, catching him off guard with a sloppy right hook thrown at his face. Fistfull dodges around the punch easily, but that was your hope. As Fistfull jumps away, you swing seamlessly into a roundhouse kick with your left leg. Your foot slaps across Fistfull's face, catching him off guard, then you plant your feet and pivot your open palm into his throat. Your own blows sting as they fall against Fistfull's tough skin, but they're effective.
			*goto ffullfight
		*else
			*set lb +10
			*set health -10
			You fought defensively against the rodent duo before, so you're going to switch it up with an offensive attack this time.
			*goto offstand
	#Maneuver into a surprise defensive attack with my fighting ability. (Health Cost 5-10)
		Why waste Power when you can rely on your master fighting skills, which Fistfull and Monk won't see coming? 
		*if (defensive > 50)
			*set lb +15
			*set health -5
			*set legended +2
			You fought defensively against the rodent duo with success, so you figure that you should rely on that strength once again.

			*label defstand
			*set defensive %+15
			*set fighting %+15

			Conventional wisdom would match StarSoar's brute force up against Fistfull's girthy durability, pitting you against the more graceful Monk—so you're going to do exactly the opposite.

			Taking the lead for StarSoar to follow, you roll at Fistfull, catching him off guard with a feign. Fistfull takes your bait and throws a punch, which you're prepared for. You spin around the deadly blow and use Fistfull's momentum against him, flipping his heavy body faceup on the floor with a crashing thud. The effort of doing so is tremendously strenuous, but the maneuver is effective.
			*goto ffullfight
		*else
			*set lb +10
			*set health -10
			You fought offensively against the rodent duo before, so you're going to switch it up with a defensive attack this time.
			*goto defstand
		
*label ffullfight
*set health -15

You can tell that you hurt Fistfull from his screams, but he is apparently tough enough to react through the pain. You don't expect him to recover so rapidly—or to have such fast reflexes—so Fistfull manages to wrap his enormous hand around your right wing. He squeezes hard, and you squawk in pain as the wingbones nearly crack. Then Fistfull tosses you clear across the pod.

You are sent reeling, but stop your momentum by crashing into the ground. This may hurt and you might seem uncoordinated as you pop back onto your feet, but this actually all plays perfectly into your plan….

*page_break
*set power -20

"Now!" you scream, signaling StarSoar to switch opponents. Still facing Fistfull, you hear StarSoar's fiery blue thrust ignite behind you and you immediately fly upwards. As you curve over into a graceful backflip, you look down at StarSoar streaking underneath you and think: you must look pretty slugging cool right now.

Even cooler as you twist the flip in midair and unsheathe your talons from your fingertips. You spot Monk preparing to stop your attack telekinetically, but you know ze isn't counting on your next move. You fire the talon-nails from your fingers, pinning Monk to the silver metal of the pod wall.

Then, before Monk can use hir telekinesis to dislodge hirself, you unleash a full sonic screech. The vocal blast rips across the pod and slams Monk into its reinforced glass with crushing force. Once the blast clears, Monk hangs limply against the wall, propped up only by your talon-posts.

You then spin around to check on StarSoar and see him landing beside you, having left Fistfull imprinted in the glass on the opposite side of the pod. StarSoar leans over with his hands on his knees, looking like he needs a moment to recover—you really hope he doesn't vomit inside his helmet.

"It's a very good thing we had a plan worked out," you say, taking a second to catch your own breath. "That'll teach anyone to underestimate us, huh?"

*page_break

"Alert," the MeChip assistant suddenly echoes in your head. 
*if (lb = 35)
	"You executed both of your attacks with consistency, which grants higher efficiency outcomes. 
	*goto finishalert
*else
	"You executed both of your attacks with different focuses. While this split concentration is occasionally advantageous, it is more favorable to attack with consistency, which grants higher efficiency outcomes. 
	*goto finishalert

*label finishalert
Reminder: your Health and Power Levels were lowered from this combat situation. You must maintain Levels above 0 to survive. Please refer to the Show Stats screen section for other statistical changes."

Taking this all in, you realize that when it comes to Offensive and Defensive attacks and Physical and Intangible Power uses, it's best to remain consistent. That's an interesting way to frame battle choices that you never—

"Stars above, I cannot believe we just won that fight," StarSoar says, pulling you back to reality. "Besting those two is going to be a huge upset. We are most certainly going to receive some attention for that."

Sure enough, as StarSoar finishes speaking, the door to the pod unlatches and two more camera orbs enter to film you and StarSoar—followed by a pair of clearance drones to remove Monk and Fistfull. Even though that's undoubtedly a good sign, it also means the pressure is on. There were no expectations before, but now you've got to keep up your momentum as front-runners.

*page_break

"Oh, there is Colton Quick again," StarSoar says, turning towards the holo-image of the host reappearing inside the pod. So that must be his name—actually, you now recognize him as the former host of [i]Quickies[/i], your favorite daytime talk show as a kid. You and your sister used to watch that nonsense for hours…. The thought of her snaps you back into focus, reminding you what you're here to do. And what's at stake.

"Welcome to Round Three, Semi-Finalists," Colton announces, laying the dramatics on even thicker than before. "Your next task is to race along a guided route to The Hero Project compound just outside of downtown MC. You have two options in front of you: solve a puzzle to unlock a faster transportation method, or travel to the compound on your own.

"Choose wisely, because only the first twelve teams to arrive will advance to the final round…which means another eight teams will be eliminated."

As Colton's holo-image cuts out, a floating puzzle image is left in his place—a miniaturized version of the half-glass egg-pod. Behind it, you see that two ripped heroes have already exited the neighboring pod and are racing towards the predetermined marathon path on their own, their oiled biceps gleaming through their sleeveless costumes. An older, white-bread actor-type in a classic cape jumps down next to a younger, Middle-Eastern model-type, who suddenly produces a hover platform from his gadget-filled costume. It folds out in impressive chunks as the striking pair careen away from the MillenniWheel.

Slugging great, another two famous-looking hero-types trying to outpace you. Though all this really reminds you is that you have no time to waste.

*choice
	#Decipher the puzzle with my heightened hawk-eyes. (Power Cost 5-10)
		*if (physical < 50)
			*set lb +20
			*set rlshp_starsoar %+15
			*set power -5
			*set physical %-15
			*set legended +3

			You focus your eyes on the mini-pod puzzle and hope to uncover something unseen with your activated hawk vision, which can pick up magnetic and ultraviolet spectra. As you focus on the puzzle, you make out extra waves radiating from a small section of the mini-pod.

			Turning to this matching spot in the actual pod, you bypass the puzzle and press against the wall. Your hand pushes into a hidden panel located there, causing a control station and steering wheel to unfold from the wall.

			"I do not know how you managed that, but color me impressed," StarSoar says. "I would have had us flying there on our own already. Do you think you can drive this vehicle?"

			"You're the NASA-trained pilot," you say, stepping aside. "I think you should do the honors."

			"Alert," your MeChip sounds once again as StarSoar approaches the mini cockpit. "You utilized your Intangible Power statistical strengths and were awarded maximum Leaderboard points.
			*goto bulletpod
		*else
			*set lb +10
			*set rlshp_starsoar %+5
			*set power -10
			*set physical %-15
			*set legended +1
			
			You focus your eyes on the mini-pod puzzle and hope to uncover something unseen with your activated hawk vision, which can pick up magnetic and ultraviolet spectra. Walking around the puzzle, however, you can't make anything out.

			"I think we should fly there on our own," StarSoar interrupts. "We must be one of the fastest teams here, given our respective Power sets."

			Just as you're about to give up and agree with StarSoar, you make out extra waves radiating from a small section of the mini-pod. Turning to this matching spot in the actual pod, you bypass the puzzle and press against the wall. Your hand pushes into a hidden panel located there, causing a control station and steering wheel to unfold from the wall.

			"Sorry that took a little longer," you say. "Think you can make up the time now, Mr. NASA-Trained-Pilot?"

			"Alert," your MeChip sounds once again as StarSoar approaches the mini cockpit. "You did not utilize your Physical Power statistical strengths. Points deducted from your Leaderboard score.
			*goto bulletpod
	#Forget the puzzle and fly with StarSoar using my wings. (Power Cost 5-10)
		"We have to be one of the fastest teams here," you say, seeing that StarSoar is already thinking the same thing. He nods at you and jumps out of the pod door within seconds, lighting up and shooting off into the sky in another blue explosion.

		*if (physical > 50)
			*set lb +20
			*set rlshp_starsoar %+15
			*set power -5
			*set physical %+15
			*set legended +3

			You immediately follow, spreading and flexing your wings to see just how fast you can really fly. No matter what, you're going to keep up with StarSoar and be one of those twelve advancing teams.

			"Alert," your MeChip sounds once again as you fly. "You utilized your Physical Power statistical strengths and were awarded maximum Leaderboard points.
			*goto flythere
		*else
			*set lb +10
			*set rlshp_starsoar %+5
			*set power -10
			*set physical %+15
			*set legended +1

			You immediately follow, spreading and flexing your wings to see just how fast you can really fly. You can already tell it's going to be quite a strain to keep up with StarSoar—hopefully you can fight through the pain to be one of those twelve advancing teams.

			"Alert," your MeChip sounds once again as you fly. "You did not utilize your Intangible Power statistical strengths. Points deducted from your Leaderboard score.
			*goto flythere
	#I'm not playing by the rules. I'm going to invent my own option by looking for extra clues inside the pod. (Power Cost 5-10)
		*set lb +10
		*set rlshp_starsoar %+15
		*set power -10
		*set legended +2

		You focus your eyes and hope to uncover something unseen inside the pod with your activated hawk vision, which can pick up magnetic and ultraviolet spectra.

		"I think we should fly there on our own," StarSoar interrupts. "We must be one of the fastest teams here, given our respective Power sets."

		Ignoring StarSoar, you make out some extra waves radiating from a hidden panel in the silver wall of the pod. Bypassing the puzzle, you run over and press against the panel, which causes a control station and steering wheel to unfold from the wall.

		"I do not know how you managed that, but color me impressed," StarSoar says. "Do you think you can drive this vehicle?"

		"You're the NASA-trained pilot," you say, stepping aside. "I think you should do the honors."

		"Alert," your MeChip sounds once again as StarSoar approaches the mini cockpit. "You did not focus on utilizing your Intangible or Physical Power statistical strengths. However, you relied on your instincts and were awarded maximum Leaderboard points.
		*if (physical > 50)
			*set physical %+10
			*goto bulletpod
		*else
			*set physical %-10
			*goto bulletpod

*label bulletpod
Leaderboard points are accumulated during challenges and help determine future eliminations. You currently have ${lb} out of a possible 60 Leaderboard points."

[i]Good to know[/i], you think, as StarSoar studies the newly emerged dashboard.

*if (physical < 40)
	*achieve intangibleone 
	*goto metalweehl
*else
	*goto metalweehl

*label metalweehl
*page_break

Once StarSoar figures out the controls, the pod unlatches from the metal wheel frame and turns on its side. You imagine once the real MillenniWheel opens, the pods won't be capable of detaching like this—especially since, as the wheel shifts and the glass half of your pod becomes the true cockpit, you realize that the pod isn't shaped like an egg—it's shaped like a bullet. Who on earth would think of something like this? 

StarSoar begins to steer the speeding hoverpod along a newly lit "marathon" route and you look below you to find a gathered audience cheering you along-though you can tell instantly that this audience is in fact holographic. You wonder if they will appear to be real in the actual show, once it airs? That thought is overwritten, however, as another racing team comes into sight, keeping pace below your hoverpod. 
*goto finalspot

*label flythere
Leaderboard points are accumulated during challenges and help determine future eliminations. You currently have ${lb} out of a possible 60 Leaderboard points."

*if (physical > 60)
	*achieve physicalone 
	*goto flytherute
*else
	*goto flytherute

*label flytherute
*page_break
*set power -10

[i]Good to know,[/i] you think as you fly along a newly lit marathon route, panting heavily and trying to keep up. You look below you to find a gathered audience cheering you along, though you can tell instantly that this audience is in fact holographic. You wonder: will they appear to be real in the actual show, once it airs?

That thought is overwritten, however, as another racing team comes into sight, keeping pace below you and StarSoar.
*goto finalspot

*label finalspot

The first thing you see are the sweeping pterodactyl wings, which must span at least twenty feet. They're attached to the body of a man, who also appears to have the head and legs of a velociraptor. You've never seen a dinosaur human hybrid before, since they are tremendously rare—they're actually the result of illegal gene splicing, since Dino-Power sets don't occur naturally.

Perhaps equally breathtaking is the sight of the Ani-Powered that rides on the dino-hybrid's back, in the form of a giant tarsier. This is particularly remarkable because Ani-Powereds usually take on some kind of hybridized human form, but this guy is full-on animal, except for the fact that he's sized more like a human than a tarsier. His bulging eyes take up most of his furry face and remain fixed in position, so that he has to turn his entire head to check the perimeter for threats. As he does, he also swings his ten-foot tail in a defensive sweeping pattern.

As refreshing as it is to see other less traditional, Ani-Powered heroes included in the competition, you realize that you should probably focus on your own progress instead.

*page_break MERE MINUTES LATER

Before you know it, you and StarSoar are approaching your final destination: a sprawling compound of several massive structures, including a full stadium, a headquarters tower, and an enormous mansion. A giant holographic emblem floats above the center of the compound, reading [b]T H P[/b] in gold-lit letters, which clearly stands for The Hero Project.

Despite yourself, you feel a little rush, taking in the epic sight. For a moment, the gravity of what you're doing settles in—this is a very, very big deal. But as soon as this feeling takes hold, it seems to flutter away. Which is just as well, you think, as you see the end of the arrow-lit marathon route you've been following, because you don't need any more pressure placed on you right now.

The arrows lead to the back of the stadium, towards what appears to be some kind of shipping entrance. There's an elaborate set of scaffolding built there, one that clearly has twelve numbered entry spots. Your stomach drops as you see this, not necessarily because of its size, but because eleven of the spots have already been taken by other teams.

Looking around, you see that there's only one other team in proximity—a pair of molten ladies running down the route with impossible speed. They seem to be using some form of lava-like propulsion to push them forward, fast enough that they very well could overtake you.

"StarSoar, incoming," you shout, but StarSoar waves you off.

"Affirmative," he shouts back. "You might want to hang on."

Following StarSoar's advice, you grab hold of his arm just as he slams the speed on, rocketing you both forward in a crash of color and sound. The warp blurs your vision, which is actually fine, since you don't need to see how fast you must be approaching that scaffolded spot…all you need to know is that you outpaced those molten ladies.

*page_break

Within seconds, StarSoar cuts the speed entirely and you find yourself tumbling across a metal floor, bracing for the worst as you use your wings to skid to a halt. Once you gain your bearings enough to sit up and open your eyes, you look around to find…

You occupy the twelfth entrance spot in the scaffolding structure, looking out on the glow of the eliminated molten ladies below. 

"We did it!" StarSoar shouts. "We are among the Final 24 heroes! That is bonkers."

"Not as bonkers as the fact that we're about to be in the Final 14," you say as the two doors in front of you open, evidently leading into the stadium. 

Or so you thought, until you and StarSoar step forward into a small confessional booth lined with soundproof walls. Straight ahead stands a wall of stacked camera orbs, and all you can think is: What the slugger do they have in store for you next?

*page_break

"Congratulations on making it to the Final Round of the Semi-Finals," Colton says, somehow still holographically appearing inside the relatively small confessional booth. "You've proven your ability to react to your surroundings, think fast, fend off opponents, fight in close quarters, make sound split-second decisions, and complete assigned missions. You're all clearly capable of acting in the field as professional heroes. However, if you are to take one of the Finalist Spots, we want to know what truly motivates you.

"In order to advance in this last round of the Semi-Finals, you must answer one question. Then, based on your answers, our panel of prestigious secret judges will select the fourteen heroes they feel are most worthy of advancing.

"So, are you ready to hear the question?" Colton asks, as if you would respond with anything other than yes. "The question is… 

"Why do you want to be on The Hero Project?"

Although this seems like a relatively straightforward inquiry, you still experience a wave of dread. You have a feeling that "I was forced into being here to save my sister's life" probably isn't going to be a worthy response—nor is it a particularly smart one, for you. Unfortunately, you haven't really sorted out yet whether you're here for any other reason.

You know your continued success depends upon delivering a heartfelt answer—audiences tend to see through phoniness on these shows. Feeling panicked, you turn to StarSoar and say, "You go first," hoping this will buy you a few moments to think. 

*page_break

StarSoar pulls off his helmet, shaking loose a mop of short reddish hair that is currently matted down with sweat. With the freckles scattered across the bridge of his nose, the wisps of facial hair growing in unevenly across his jaw, and the acne scarring on his forehead, he looks much younger than you expected. Still, there's something entirely endearing about his face, which grows emotional as he looks directly into the nearest camera orb.

"Ever since I was a child, I have dreamed of pushing the frontiers of humanity forward with my Powered talents," StarSoar begins, placing his helmet over his heart as if he is taking some kind of oath. "I thought the best way to achieve this goal was to become an astronaut, so I devoted many years of my life to this important endeavor.

"However, I recently realized that becoming a Powered hero would be the surest way to protect, serve, and inspire the human race. I now believe that the truest way to push humanity's frontiers forward is to enter The Hero Project, in the hope of winning a spot on The American Protectorate."

As StarSoar finishes, actual tears appear to well in his eyes. Whatever else you think of his answer, you have to admit it was pretty slugging stellar. Which means that your answer is going to have to be equally inspirational.

The problem is, you were so wrapped up in listening to StarSoar that you still don't have one. Your whole life has been about protecting your sister and dealing with your ever-changing Ani-Powers. You haven't had a spare second to consider loftier hopes and dreams.

As the camera orbs swivel to you, you realize that you'd better think of something fast.

*choice
	#"I like the idea of being a hero; I just never thought that would be in the cards for me. I'm here to prove to myself that it's possible, I guess."
		*set traditional %+10
		*set public %-15
		*goto fallsflat
	#"I'm not here to be a hero; I'm here because I have a lot to say about the world. And how it should be changed."
		*set traditional %-10
		*set public %+15
		*goto fallsflat
	#"You don't need to know why I'm here. All you need to know is that I'll get the job done."
		*set traditional %-10
		*set public %-15
		*goto fallsflat
	#"I guess I just want to show that heroes can come in lots of different packages, even ones that don't fit the norm."
		*set traditional %+10
		*set public %+15
		*goto fallsflat

*label fallsflat
*set lb +30

StarSoar turns to you, obviously expecting more, but you don't have anything else to say. You wanted to keep it short and sweet, but now you second-guess yourself as StarSoar's eyes urge you to go on. 

However, before either of you can say any more, your MeChip assistant speaks once again: "Final Leaderboard score set. Good luck." 

With that, you can feel the MeChip assistant go offline, leaving a hollow shadow in your mind where its presence once was. Slugger, you can already tell that you're hooked on this thing. You're probably going to want to upgrade your own MeChip as soon as possible to feature—

"Thank you for your answers, Semi-Finalists," Colton's voice interrupts, as his holo-image reappears in front of you. "The confessional doors will soon open for the seven teams selected for the Final 14. Best of luck and congratulations on making it this far!"

Hearing this, you can only wonder if you've done enough to secure your place—this experience has whipped by in an instant. You certainly did kick butt, but compared to the other heroes who seemed to be advancing, you definitely feel like a bit of a misfit. Your hawk-self may look cool today, but wait until everyone sees you as a mollusk or a poodle or any number of the embarrassing Ani-hybrid forms you're prone to waking up as. Against these muscled beauties and heroic icons, how do you fit in? 

You realize you're going to have a lot of thinking to do if you move on…and even more if you don't.

*page_break

"We did our best," StarSoar says, placing a hand on your shoulder. "No matter what happens now, we know we will both be featured on the Semi-Final episodes. We took down Fistfull and Monk, for slugger's sake!"

StarSoar covers his mouth after this, as if cursing is the worst thing he possibly could have done. As you laugh and nod at StarSoar, he decides to put his helmet back on, taking a deep breath. You take one too, because your heart is pounding away in your chest as you wait to see if your door will open.

Have you done enough to make it to the Final 14?  Will it be enough to save your sister?

You get your answer more quickly than you expected.

*page_break
*if (lb > 76)
	*achieve lbonehigh
	*goto podunl
*else
	*achieve lbonemid
	*goto podunl

*label podunl
Your confessional door swings open, releasing the wall of camera orbs as they rise like balloons into a massive soundstage. You look to StarSoar, your chest melting into a puddle of relief.

You did it.

You step forward, walking out onstage before a roaring crowd. Confetti showers down in front of blinding stage lights. It's completely overwhelming, though once your hawk-eyes adjust, you realize that this crowd is all holographic once again. Somehow it doesn't take away from the effect on the stage—it's singularly exhilarating.

*page_break
*achieve fsfourteen

You've made it into the Final 14, beating out eighty-six of the nation's best Powered heroes. This automatically makes you think of the ten other heroes still stuck in their confessional booths behind you, having made it all the way here only to be forced to listen to the celebration going on right outside. You realize how easily that could have been you, but thankfully the combination of StarSoar's eloquent answer and your succinct one pulled you both through.

Which means that your sister is going to be okay. You can finally breathe again.

You look over the thirteen other heroes advancing alongside you, already spotting a few you recognize: the pink energy heroines, the ripped hero dudes, and the dino-tarsier duo all appear to have made it to the finish line as well. Celebrating beside them you see everything from teenage prodigies to drag queen deities to goth vampires. Taking in this vivid and improbable sight, all you can think is:

What the slugger did you just get yourself into?

*finish NEXT CHAPTER: READY FOR THIS JELLY
