*comment é x

*text_image chap4.png center Chapter Four: Star-Powered

"My dashing dachshund, you simply could not be any later!"

You're barely out of the limo when this voice assaults you, housed in the body of an enormous bejeweled man coming at you in a hot-pink people mover. His jowls shake and shimmy as he approaches, adding to his general air of cheeriness. 

"You're the last of the Final Select to arrive," the man says, reaching out to pull you forward. "Come along with me, come along and you'll see!"

The man pulls you away with surprising speed, through the guest entrance of The Hero Project's soundstage. A million different smells assault your newly grown dog snout, but the most overwhelming by far is the night-jasmine perfume coming off of—

"And GG was his name-O," MeChip Prodigal suddenly appears and informs you, responding to your latest thought. "Executive Producer extraordinaire and perhaps the most gorgeous goliath I've ever had the personal pleasure of meeting! Do be sure to say hello for me, won't you?"

[i]So this is the Executive Producer of The Hero Project,[/i] you think, as GG leads you down a narrow hallway. Time to get your game face on—though today, your face happens to be that of a:

*choice
	#Poodle.
		*goto firstall
	#Pit bull.
		*goto firstall
	#Greyhound.
		*goto firstall
	#Rottweiler.
		*goto firstall
	#Pug.
		*goto firstall
	#Beagle.
		*goto firstall
	#Dachshund.
		*goto firstall
	#Golden retriever.
		*goto firstall
	#Black Lab.
		*goto firstall
	#Another dog type.
		Today my face happens to be that of a:
		*input_text dogtype
		*goto firstall

*label firstall
*set meetproducers true

"First of all, let me just say that I'm loving your look, it's very canine chic," GG announces. "I'm also told you're now going by the moniker ${codenamed}, is that correct? Fabulous choice. Now, have you ever walked a Step & Repeat before?"

"Uh, what's a Step & Repeat?" you ask, trying to keep your voice from barking too much as you speak.

"It's a red carpet with a holo-logo banner, where you pose, interview, step and repeat," a new voice says. You smell her chlorine-soaked, lotion-covered skin before you see her.

You spin to find a tall athletic woman striding down the hall, holding a clipboard and wearing a headset. Her braided black hair is tied into a thick side ponytail, and she wears an expensive-looking white pantsuit draped over broad swimmer's shoulders. Her dark green eyes settle on GG with intimidating intensity.

"I thought we agreed that the last Finalist was mine to handle," she says. 

"I'm afraid you were nowhere to be found, darling dumpling," GG says, a subtle chill entering his voice. "Whatever was I supposed to do?"

*page_break

Ignoring GG, this new woman takes you by the arm and begins to lead you down the soundstage corridor, her heels clacking along the concrete as you walk.

"That's Lyra Vite, The Hero Project's new Co-Executive Producer," MeChip Prodigal chimes in. "She has been tasked with rebranding the show's second season, though it appears that there might be some trouble in producer paradise."

You find it strange that no one has felt the need to introduce themselves to you and that you don't have to introduce yourself to them, but you suppose that must be considered terribly old-fashioned now that everyone has MeChips to take care of introductions.

"I'm supposed to give you a big speech, but you're late," Lyra says, walking briskly beside you. "Do you have any questions?"

Only about a million, but you know that everything you say and do is going to matter for your success here, especially when it comes to the Executive Producers in charge of the entire operation.

"Sorry for being late, grooming issue," you say, hoping for a laugh from Lyra. When you don't get one, you instead say:

*choice
	#"I'm ready to put on whatever show you want me to."
		*set public %+15
		*set respected %-10

		"Right now I just need you to play catch-up," Lyra responds,
		*if (public > 50)
			*set rlshp_eps %+15
			a hint of a smile on her face.
			*goto lyrareact
		*else
			a hint of a frown on her face.
			*set rlshp_eps %-5
			*goto lyrareact 
	#"I'm ready to show the world who I am and what I stand for."
		*set public %+15
		*set respected %+10

		"That's the spirit," Lyra responds,
		*if (public > 50)
			*set rlshp_eps %+15
			a hint of a smile on her face.
			*goto lyrareact
		*else
			a hint of a frown on her face.
			*set rlshp_eps %-5
			*goto lyrareact 
	#"I'm just going to keep my head down and focus on the win."
		*set public %-15
		*set respected %+10

		"Good for you," Lyra responds,
		*if (public < 50)
			*set rlshp_eps %+15
			a hint of a smile on her face.
			*goto lyrareact
		*else
			a hint of a frown on her face.
			*set rlshp_eps %-5
			*goto lyrareact 
	#"Mostly I just want to get this over with."
		*set public %-15
		*set respected %-10
		
		"Right," Lyra responds,
		*if (public < 50)
			*set rlshp_eps %+15
			a hint of a smile on her face.
			*goto lyrareact
		*else
			a hint of a frown on her face.
			*set rlshp_eps %-5
			*goto lyrareact 

*label lyrareact
She then steps in front of a narrow red door and turns to you, remaining all business. 

"After the Step & Repeat, there will be a short cocktail party with the other contestants, before the Final Selection ceremony. Your mingling at this party will affect your Semi-Finals Leaderboard score, which will then determine which seven Rookies will advance through Final Selection. So whatever you do in there, make it count."

Lyra fires off the words and you try your best to keep up. Hearing this, you know you should probably focus on something else, like who to talk to or how to portray yourself, but all you can think is: this party will be your chance to handle the StarSoar situation, one way or another.

"When you step through this door, the show is on," Lyra continues. "Camera orbs will follow your every move: showmance cams, cry cams, fight cams, heroic cams, personal cams—the list goes on. Everything you say and do will potentially be seen and judged by tens of millions of people, but how long that ends up lasting depends entirely on your performance tonight."

*page_break
*set upa +15

This is something you've already come to know all too well, strangely. In the last two months, seven episodes of The Hero Project's second season have aired, featuring the Auditions and Semi-Finals. The ratings apparently went down from the first season, but the show still remains massively popular. To say it has been surreal to see yourself on 3V is an understatement—obviously you haven't been in every episode, but you have been given a nice chunk of airtime. 

In the interview auditions, you were portrayed as a somewhat
*if (respected > 50)
	noble and
*if (respected <= 50)
	ominous and
*if (public > 50)
	outspoken figure. 
*if (public <= 50)
	mysterious figure.

This was then reinforced in the Semi-Finals, where your hawk-self came across as graceful, strong, and badass. Of course, your takedown of Fistfull and Monk marked you and StarSoar as early standouts to watch.

Aside from this general buzz, you decided not to expose yourself to the public reaction too much. You haven't gone anywhere besides Dockerbay and your job at the Millennial Mews, and it's very easy not to get recognized by strangers, given your daily Ani-transformations. Other than that, you refused to look at any online commentary and you blocked MeChip Prodigal from trolling the MeBlogs. You only allowed JK to summarize the general reaction as each episode aired. 

*if newreader
	JK did convince you, however, to let her add Public Meters to your Show Stats screen. She then made it a point to tell you that your Public Stats are best kept at extremes—the higher or lower the levels the better, since being in the middle indicates that you're having lesser impact with viewers as a potentially unreadable figure.

*page_break
*set legended +5

Thankfully, just by appearing on the show, you've already begun to raise the general level of Underrepresented Powered Awareness. The only other thing you did allow JK to share with you is the scattered fan MeMessages from Disembodied, Ani, and Morpho-Powered viewers thanking you for appearing on the show. You can't believe anyone cares enough to write you messages specifically, but they serve as a potent reminder of the potential impact you can have by making it on this show.

Perhaps the most notable change so far has been to your Legend Level, which you've learned is the ultimate gauge of your heroic rise. Your Legend is an aggregation of public perception, personal achievements, and your place in the heroic landscape. Just from your brief time on the show, your Legend has already jumped from 0 to ${legended}, 
*if (legended > 15)
	*achieve legendcatone 
	*achieve legendcattwo
	*set legendleveltwo true
	advancing you from the "Civilian" Category to the "Trainee" Category.
	*goto onepos
*else
	*achieve legendcatone
	which still places you in the "Civilian" Category. You're hoping to rack up a few more points to get past 15, which will place you in the "Trainee" Category with the rest of the Final Selectants.
	*goto onepos

*label onepos

You quickly realized, however, that none of this public momentum will matter if no one can recognize you. Usually you don't mind the anonymity your Ani-transformations can provide, but it's not exactly ideal for building a 3V persona. Thanks to that brief birdy streak, the audience now identifies you mostly as an avian Ani-Powered, since you were a sparrow-hybrid for the interviews and a hawk-hybrid for the Semi-Finals.

Which of course means that today you look entirely unrecognizable in your dog form. This is why you decided to follow JK's advice and pick out one costume to wear, so viewers can clearly identify you through your evolving Ani-Morpho changes. 

*choice
	#I went with a bright, bold costume to stand out and show off my rotating Ani-features proudly.
		*set public %+20
		*set image %-20

		You and JK found a short-sleeve wetsuit in another thrift store, which looks like tight, bright spandex and leaves your head and limbs exposed. By leaving your face and your Ani-Powers bold and open, you hope to make a statement, primarily about your presence here, but also potentially about Underrepresented Powered issues. 
		*if (public > 55)
			*set legended +1
			*set rlshp_eps %+10
			*goto lockettime
		*else
			*set rlshp_eps %-5
			*goto lockettime
	#I went with a dark, intimidating head-to-toe costume topped off with a mask, to guard my identity and Ani-changes. 
		*set public %-20
		*set image %+20

		You and JK found a black wetsuit in another thrift store, one that gives you full coverage, then you topped it with a solid black bandana wrapped around your face, with eyeholes cut out so you can see. 
		*if (public < 45)
			*set legended +1
			*set rlshp_eps %+10
			*goto lockettime
		*else
			*set rlshp_eps %-5
			*goto lockettime
	#I went with a dark, masked costume to obscure my identity and highlight my Ani-transformations as much as possible.
		*set public %-20
		*set image %-20

		You and JK found a short-sleeve black wetsuit in another thrift store, which looks like spandex and leaves your head and limbs exposed. You then topped it with a solid black bandana wrapped around your face, with eyeholes cut out so you can see. By leaving your face obscured and your Ani-Powers exposed, you hope to make a bold statement about Underrepresented Powered issues. 
		*if (public < 45)
			*set legended +1
			*set rlshp_eps %+10
			*goto lockettime
		*else
			*set rlshp_eps %-5
			*goto lockettime
	#I went with a brightly colored, full-coverage costume and old-school mask. I want to stand out without highlighting my Ani-transformations.
		*set public %+20
		*set image %+20

		You and JK found a bright wetsuit in another thrift store, one that gives you full coverage, then you topped it with a matching bandana wrapped around your face, with eye holes cut out so you can see. You know you stand the best chance of surviving in this competition by blending in as much as possible, at least at first.
		*if (public > 55)
			*set legended +1
			*set rlshp_eps %+10
			*goto lockettime
		*else
			*set rlshp_eps %-5
			*goto lockettime
		
*label lockettime

This wetsuit style may not be a heroic costume from a fancy designer, but the price was right, and it still looks pretty slugging official. You and JK also managed to cut a little pocket in the front of the wetsuit to hold your locket, 
*if usejkstory
	to serve as a visible reminder of JK's story and your personal motivation.
	*goto costplash
*else
	even though no one aside from you and JK knows what this locket pocket contains.
	*goto costplash

*label costplash
For final effect, you and JK painted a ${triquetra} on the front, to symbolize the triple elements of your Underrepresented identity.

Luckily, this costume seems to make a splash as you walk onto the Step & Repeat red carpet for the first time. As you do, holo-flash bulbs begin to spot up your already-dimmed dog vision, and your ears are assaulted with "${codenamed}" and "${named}" calls.

[i]Here we go[/i], you think as you step forward.

*page_break A FEW REPEATS LATER

Fresh from a round of mind-numbing press interviews, you enter the great room of the Contestant Mansion only to be hit with another wall of sounds and smells, thanks to your enhanced dog senses. Through the sensory haze, you still manage to marvel at the impressive room. It looks like the lobby of some ultra-fancy hotel, all heavy carpets and chandeliers and polished wood—quite the departure from your thrown-together, discount-furnished loft. You can't believe this could actually be your home if you make it into the Live Finals of the show.

Closing your eyes, you force yourself to take a breath and focus through the overwhelming stimuli, because you are prepared for this. Again that's thanks to JK, since her Hero Project Boot Camp has educated you on the first season of the show. Most importantly, JK prepped you on the identities of your fellow Final Selection Rookies and MeChip Prodigal has been loaded with an arsenal of mental flash cards, ready to fire when you need them. 

Opening your eyes and scanning the party, you realize that you're going to need MeChip Prodigal's assistance right away. You easily pinpoint the other Rookies in the crowd of heroic glitterati, seeing that they've already broken into cliques.

"Fret not, my canine companion," MeChip Prodigal says, appearing in your peripheral vision—you keep forgetting that she can respond to your thoughts. "I'm here to keep track of all the daunting details for you. No matter who you come across, I'll inform you of the relevant information in the moment, then I'll load anything else you need to remember in the Show Stats screen. So remember, if it's not yet there, don't give it much care! Just soak in the experience and let me worry about keeping track of the important information. Deal?"

"Deal," you think at MeChip Prodigal, realizing why people are addicted to these things. You're comforted to know that MeChip Prodigal will handle remembering what you need to know, since you're sure to be inundated with loads of new people and information tonight. 

*page_break

You focus on the first group of Rookies standing near one of the balconies and recognize all of them from the Semi-Final finale stage: a seven-foot tall drag queen dressed like a Greek goddess, and a black-clad goth vampire, who today actually appears to be a…werewolf? They are standing with a pair of college-aged heroes, a sandy-haired brunette in a silver and navy costume and a tall, dark, and handsome guy in a white bodysuit with orange metallic plating. At least you think those are the colors, since you've gone just a tad color-blind thanks to your dog-eyes.

"All right chicken-dawg, here we go," MeChip Prodigal says. "Those are two Semi-Final pairings. The young duo are Crystalline and Ignite, partnered for their prodigal ambition, pun intended! Crystalline is on a one-year deadline from her parents to pursue heroics before going to college, and Ignite just graduated as the valedictorian of Melite Powered University. As you've already seen, they both were portrayed in the aired episodes as promising front-runners who may or may not be falling for each other. Oh, to be young and in love….

"The other pair are Nitewerq and Transfer, paired for their LGBTQIAPZ+ identities. Nitewerq is an underground NYC hero and drag queen—and get this, she actually believes that she is a goddess whose Powers run on the belief force of her fans. Fancy that! Her partner, Transfer, is a Morpho-Powered and gender activist who has the Power to rotate between zombie, werewolf, vampire, and human form cyclically every four days. Unfortunately, these two weren't featured much at all in the aired episodes compared to other Semi-Finalists, which is entirely frustrating, if you ask me. That Nitewerq is painted for the gods!"

As MeChip Prodigal finishes filling you in, you can't help but think that, as interesting as these other heroes might seem, Transfer must know exactly what you go through as a Disembodied, Morpho, and Animalistic Powered. You've never met anyone else who checks all three of these boxes too, so your first instinct is to… 

*choice
	#Eventually connect over this set of shared Powered identities.
		*set image %-15
		You definitely want to get to know Transfer, but you figure you should finish learning about the rest of the Rookies before you make a choice about who to mingle with.
		*goto nexttwoshoul
	#Attempt to separate myself from Transfer. I don't want to be painted as a stereotype too early.
		*set image %+15
		The last thing you want is to be pigeonholed as a certain narrow type. Besides, there are a whole list of other different and diverse Rookies you still have to learn about before deciding who to meet first.
		*goto nexttwoshoul 
	#Hold off on making a decision for now.
		You suppose you'll have to start deciding things like this once MeChip Prodigal finishes your little rundown…

		*if (image > 50)
			*set image %+10
			*goto nexttwoshoul
		*else
			*set image %-10
			*goto nexttwoshoul

*label nexttwoshoul

"Okay, these next two you should recognize from the Semi-Finals marathon route," MeChip Prodigal continues, forcing you to move on to the next group standing near a table of catered food. You recognize the velociraptor-pterodactyl dino-hybrid and the tarsier Animalistic Powered immediately.

"Tarsiero earned his spot in the Semi-Finals by winning The Hero Project Experience at the UniHero theme park where he worked. Since he is a fully unhybridized Ani-Powered, he was partnered with fellow Mutate-Powered contestant Velocityl, who is a recently escaped Korean refugee and the subject of illegal dino-human genetic experimentation. Given this pair's lack of heroic experience and training, they weren't expected to make it all the way to the Final Selection, but they've quickly become fan favorites. I already ordered myself a virtual Velocityl plush toy—that dino dynamo is simply irresistible, don't you think?"

You're not quite sure how to answer MeChip Prodigal, especially because you're all too used to people treating Animalistic Powereds like mascots or pets instead of real people….

"Whatever, not everyone can master the fine art of dino-appreciation," MeChip Prodigal says, seeming to ignore your latest thought. "Moving on, these two adorable Rookies are joined by Splint, a sixteen-year-old adopted child who separated from her Semi-Finals partner and gravitated towards these other quote-unquote 'misfits,' though I'm already going on record against that description."

You were so focused on Velocityl and Tarsiero that you barely even noticed the third Rookie who has joined them. Splint looks even younger than sixteen, with her flushed, round face and reinforced hero-glasses. It doesn't help that the broadsword hilt strapped to her back seems just about as big as her entire body, threatening to tip her over at any given moment.

*page_break

Thankful that you have MeChip Prodigal to help you keep this all clear, you move on to the final group standing together in the center of the room, basking in the glow of many camera orbs. Among them are the two heroines you saw riding the pink energy wave, the two male hotshots leaving the MillenniWheel pods, and a handsome new silver fox.

"These five have already deemed themselves 'The New Populars,' slugger save them," MeChip Prodigal sighs. "Reigna and Miss Boss are twenty-something best friends from Los Angeles looking for their big break. Much to their delight, they've been the breakout stars of this season so far, thanks to that mega-viral clip of them wiping out that goggle-conjoined team in the Semi-Finals."

You remember that particular wipeout vividly—as if it wasn't brutal enough, the clip aired on The Hero Project and found its way onto MeTube to become a massive viral hit. Someone even recorded an auto-tuned song to accompany the goggle-guy's awkward whelps and tumbles, named the Goggle Bobble.

"These two are rather unsurprisingly joined by Exile, a corporate-sponsored unPowered hero who was allegedly exiled from Saudi Arabia for his party-boy ways. Key word: allegedly. His partner is Griffin, South Carolina's official state hero, who is apparently looking to take his career national. Griffin then pulled in the fifth Rookie, O'Connell, since they are closest in age. O'Connell is a contractor and father of five looking for a better life for his family. These last two dudes scream midlife crisis if you ask me, but this entire pack has been deemed the show's heartthrobs, each of them getting a good chunk of airtime."

MeChip Prodigal is right—these five have dominated the airtime since the show premiered. You wonder if you're going to be forced to choose between these "popular" heroes and the other groups, or if you'll be able to find a way to break down this antiquated system 
*if trilogyreader
	from the first season and bring everyone together.
*if newreader
	and bring everyone together.

*page_break

This isn't the only choice you'll have to make, you realize as you spot the final Rookie, your own partner StarSoar, at the bar. He chats with the bored-looking bartender, probably waiting for you to arrive. Seeing him makes your stomach drop, since you still don't know exactly what to say to him yet, given all that Loa Shift told you. So you figure you should stall a bit and mingle first, before StarSoar eventually spots you.

"Remember poochy-poo, your relationships matter for your future success on the show, both in terms of alliances and Leaderboard points," MeChip Prodigal jumps in, sounding eerily like JK on this matter. "You must ask yourself who you want on your side, knowing that the public and the producers will judge you based on who you choose to identify with. How are you going to treat them? Are you out to make friends or enemies, allies or pawns? 

"While you consider your options, rest assured that I will post bios of whoever you choose to talk to in the Stats Screen, for your reference. Now it's time for you to make a move, so who's it going to be? The suspense is positively murdering me!"

As you scan the other Rookies, it is not lost on you that they have mostly gathered in groups that fall along traditional Powered lines—earth- and nature-based Powers, unique transformative Powers, and the good old-fashioned glamorous energy and strength Powers. You wish you could say these Powered dividing lines were unusual, but you at least do your best to ignore them by deciding to:

*choice
	#Mingle with Ignite, Crystalline, Transfer, and Nitewerq.
		*set finalselectionmingle true
		*set mingleprodigies true
		*set showcrystalline true
		*set showignite true
		*set showtransfer true
		*set shownitewerq true
		*goto mnprodigies
	#Mingle with Velocityl, Tarsiero, and Splint.
		*set finalselectionmingle true
		*set minglemisfits true
		*set showvelocityl true
		*set showtarsiero true
		*set showsplint true
		*goto mnmisfits
	#Mingle with "The New Populars."
		*set finalselectionmingle true
		*set minglepopulars true
		*set showmissboss true
		*set showreigna true
		*set showgriffin true
		*set showexile true
		*set showoconnell true
		*goto mnpopulars

*label mnprodigies

"Hey, mind if I join you?" you say as you approach the group. "It's ${named}, by the way, though I guess I'm going by ${codenamed} now."

"I thought that was you," Crystalline says, reaching out to shake your paw and smiling a row of perfect white teeth underneath her freckled cheeks. "You and StarSoar killed it in the Semi-Finals. Watching you take down Monk and Fistfull was so epic."

"I agree," Ignite adds, resting his serious, almost-black eyes on you. You try to focus on Ignite's words, but are overwhelmed by the smell of scorched soil buried underneath a layer of deodorant and sweat. "I'd love to talk to you about your ${maspecialty} technique, if we get the chance."

"Don't mind Ignite—he thinks he's still in school competing for grades," Crystalline jokes, nudging Ignite. In contrast, Crystalline has almost no scent, nor do the rows of crystals that poke out of her silver belt holster-slots. You only get the faintest whiff of shampoo as she moves her shoulder-length sandy-brown hair. It's a wild experience having these canine senses, to most easily identify people by smell instead of sight.

"This is just another test for you to ace, right?" Crystalline adds, causing Ignite's cheeks to turn the same orange as his metallic mask and costume accents. Crystalline stares back dreamily at Ignite and you can practically smell the pheromones raging between these two….

Strangely, all of these minor details seem to come into sharper focus than the entire impression of each person, no doubt thanks again to your altered dog-senses. Between the details and the smells, it's all you can do to focus on behaving like a normal, social person.

*page_break

"How are your fingers doing?" Transfer asks, hir werewolf snout twitching. Ze smells familiar, not quite like anything you can put your human finger on, just a certain…unique sameness?

"Huh?" you ask, unable to focus enough for a more coherent response.

"My fingers always hurt on the werewolf days, from the claws growing in," Transfer says, holding up hir own werewolf paws. You nod and smile, mostly because you're now fighting off an overwhelming urge to lean down and sniff Transfer's behind. Somehow, you catch Transfer's eye and can tell ze is doing the same.

"Mindless chatter, doesn't matter," Nitewerq proclaims, interrupting a brief stretch of awkward silence between you and Transfer. Turning your attention to the towering queen, you find that her night-black skin smells like sea salt and sandalwood, pairing nicely with the twine coming off the heavy ropes tied into her Grecian goddess getup. 

"Patience wears thin, awaiting the win," she proclaims to seemingly everyone and no one, her deep purple eyes unblinking under her full-coverage face mask. 

*page_break

"Amen, sister," Crystalline adds. "I'm so nervous, I've peed like eight times today."

"Yeah, I don't even want to think about the actual Final Selection," Ignite grimaces. "Though I guess we should all just be happy that we've made it this far."

"I can't wait to see who the Veterans will be, too," Crystalline says as she bounces on her heels, unable to hide her excitement. "I so, so, so hope Mach Girl comes back. We would make the coolest team-up pairing ever."

"I wonder if we'll get to meet The American Protectorate at some point, too," Ignite responds. "I'd like to have a sit-down with Summit." Ignite seems to retreat into thought after that, his chiseled jaw clenched shut.

"So, how are you feeling?" Transfer then asks, leaving Crystalline and Ignite to their daydreaming aspirations. "I mean, this is all pretty surreal for me. How are you doing with it?"

Once Transfer's question is posed, everyone turns to you, along with a set of camera orbs that have been filming since your arrival. Their presence reminds you that your answer here is going to have layers of consequences, so you pause to think a moment before you speak.
*goto minglechoice

*label mnmisfits

"Hey, mind if I join you?" you say as you approach the group. "It's ${named}, by the way, though I guess I'm going by ${codenamed} now."

"Season's greetings!" Tarsiero says first, his voice purring as he speaks. "I'm so glad you decided to join with us. #AnimalUnity #FriendsForever #TarsieroTime!"

Tarsiero smiles up at you from his crouched position and you have no idea how to respond. No one has used hashtags like that since social media was invented back in the early twenty-first century. Even then, no one spoke them aloud like this. Maybe Tarsiero is trying to make this his thing on the show?

"Are you okay? You seem pained?" Tarsiero asks, looking immediately skittish. You must have been making a face, since the only thing more jarring than Tarsiero's hashtag-speak is the sour smell coming from his matted fur. Something about the damp, unwashed smell makes you both queasy and uneasy. 

"Have you been trained to shake hands yet? #JustKidding #LOL #TarsieroTime!" Tarsiero jokes nervously.

*page_break

"Everything okay with you?" Splint asks, stepping in front of Tarsiero protectively. That's when you realize that you've bared your teeth and have started to growl in a low, guttural rumble. You force yourself to stop, mortified to have exhibited any instinctually aggressive Ani-behavior on camera.

"Yes, sorry," you say, forcing a smile. "I'm just a bit overwhelmed, with these new dog-senses and all. My apologies. Really."

Splint nods, wafting over a distinct mix of unwashed hair and sweat. It's not unpleasant, it's just not altered by anything, like most of the other people you've encountered. It's a wild experience having these canine senses, to most easily identify people by smell instead of sight.

Splint then steps back and starts to scratch Tarsiero behind the ears, causing him to smile and rub against her leg adoringly. The sight threatens to turn your stomach. [i]You're human, damn it,[/i] you want to scream at Tarsiero.

You know you should connect with other Ani-Powereds most easily, but truth be told, you've always had trouble feeling comfortable with them. Something about being around other Ani-Powereds always reminds you that you just don't fit in anywhere, especially in the one community that's supposed to be a source of support. You try to give Tarsiero the benefit of the doubt, but he's making it hard, pandering like a mascot and acting like a human pet.

*page_break

You force yourself to focus on something else, so you study Splint's thin, five-foot frame and pale blue eyes, which seem to be altered with colored contacts. Right now those eyes tick back and forth underneath her glasses, which you then realize are part of the MeChip GamerComm headset, equipped with state-of-the-art gamer holo-glasses.

"Sorry, I'm just trying to clear one last level in CCQ," Splint says, her eyes still not quite focused on you. "I patched into an unblocked MeSignal. I, uh…hate parties like this."

"You play [i]Creatures of Crests & Quests[/i]?" you blurt out. "I'm a Level 16 Dragicorn! Sorry, I've never met another CCQ'er in real life. I've also never seen a mobile console headset like that—it's absolutely incredible."

You try to stop yourself from drooling from your dog jaw as you look over the sleek headset, especially as Splint focuses her eyes excitedly on you for the first time.

"I'm a Level 50 Needlebeast," she says, proudly gloating over the look of jealousy and shock on your face. "But Level 16 is great, it's so hard to level up past that. I've had to play pretty nonstop to get this high."

*page_break

"I should like learn such game," Velocityl suddenly says, causing you to nearly jump and bark. His voice sounds almost prehistoric, deep and gravelly, even through his thick Korean accent. In all your Ani-discomfort and gamer excitement, you totally forgot the dino-hybrid was standing there too—which is insane, given his imposing presence. Though you notice Velocityl is fairly scentless, which might have helped you forget about him momentarily.

You turn to him now and marvel at the rough, reptilian skin that cuts into his much softer human flesh. Massive pinkish-red wings crease his back, looming even taller than his own eight-foot height. Taking in Velocityl's impressive stature, you realize that he must also know what it's like to be treated as something less-than-human. Though as you focus on the places where his dinosaur limbs cut into his human flesh in raw, sewn-together seams, you realize that Velocityl must feel even worse, because nature didn't make him this way—other people did.

Strangely, all of these minor details you now notice come into sharper focus than the entire impression of each person, no doubt thanks again to your altered dog-senses. Between the details and the smells, it's all you can do to focus on behaving like a normal, social person. Which is probably why you stare up at Velocityl, forgetting to speak. Luckily, that seems to be the trend in this group. None of them seem bothered by your silence except for Tarsiero, who pipes up again to say:

"How are you feeling to be here, fellow Ani-friend? #TheFeels #Reality3DTV #TarsieroTime!"

Everyone then turns to you, along with a set of camera orbs that have been filming since your arrival. Their presence reminds you that your answer here is going to have layers of consequences, so you pause to think a moment before you speak.
*goto minglechoice

*label mnpopulars

"Hey, mind if I join you?" you say as you approach the group. "It's ${named}, by the way, though I guess I'm going by ${codenamed} now."

"Who?" Reigna asks, staring at you with blank eyes. You are immediately hit with the smell of makeup and perfume, which makes sense, since Reigna has perfectly shiny jet-black hair and flawless brown skin. 

"Babe, ${youdze} ${youdzewas} the hawk-hybrid in the Semi-Finals," Miss Boss says, reaching out her hand to shake your paw—though you're more distracted by the strong scent of leather coming from her jacket and the body oil coming from her tan skin. It's a wild experience having canine senses, to most easily identify people by smell instead of sight.

"Don't mind Reigna, she's a regular space cadet," Miss Boss adds, looking a bit freaked out by your twitching dog-nose.

"Oh slugger, my bad, I'm so sorry," Reigna gushes, looking wary of shaking your clawed paws. "There are still so many of us left, I get confused."

You know you should say something, but you're too busy taking in the details of Reigna's manicured nails and Miss Boss's red…brown…wait, maybe maroon-trimmed bodysuit. Strangely, all of these minor details seem to come into sharper focus than the entire impression of each person, no doubt thanks again to your altered dog-senses. Between the details and the smells, it's all you can do to focus on behaving like a normal, social person.

*page_break

"You must get that a lot, huh?" Exile says, patting you on the back and flashing you a killer smile. He reeks of musky cologne and aftershave, which mingles unpleasantly with the sterilized metallic upgrades covering his tech-costume. "I can't imagine how it must be to look different every day; that must be so jarring." 

You nod at Exile, thinking that underneath that flimsy mask covering his high cheekbones, he must be very used to everyone responding well to his movie-star good looks. His buzzed hair, angular jaw, and dark-ringed eyes light up with the glow of someone quite used to attention. He must feel right at home here on The Hero Project.

"It keeps me on my toes," you say, figuring you should speak up. "Well, on my paws, today." 

You offer a little laugh at your own joke, but only O'Connell seems amused by it, drawing your attention to his towering seven-foot stature and baby powder-covered scent.

"Ha, yeah," he says, smiling so that his laugh lines and forehead wrinkles crease. "Hey, one of my daughters just found out she's Ani-Powered. It's…a lot to adjust to, isn't it?" 

O'Connell says this while holding his smile, but his blue eyes betray his words. You can tell that he hasn't exactly worked through what having an Ani-Powered child means to him just yet, since most people consider it something to be ashamed of. Sadly, you're used to this kind of reaction, so you just nod at O'Connell, offering as much of a smile as your dog snout will allow.

*page_break

"Well, the more the merrier," Griffin jumps in, giving you a handshake that threatens to crack your paw. It's almost as overwhelming as the scent of bronzer wafting off of his strong jaw, or the sight of the biceps bulging through his very retro cape-and-spandex costume. "We're all pretty hopeful about making the Final 14, given all of our airtime. You should be too!"

"We certainly deserve it," Reigna says. "I mean, I can't imagine coming this far only to get cut."

"I doubt you'll have to worry about that," Exile says, sliding his hand around Reigna's waist and causing her to giggle and lean into him.

Miss Boss seems to have to force herself from rolling her eyes at this display, instead sighing and saying: "I don't know what else we could have possibly done to qualify. Anyway, ${codenamed}, how are you feeling about everything?"

Once Miss Boss asks this, everyone turns to you, along with a duo of camera orbs that have been filming since your arrival. Their presence reminds you that your answer here is going to have layers of consequences, so you pause to think a moment before you speak.
*goto minglechoice

*label minglechoice
*set meetrookies true

*choice
	#"I'm happy to meet you all. Everyone here just seems so awesome."
		*label lovedroute
		*set respected %+20

		*if (respected > 55)
			*set legended +1
			*set lb +5
			*set rlshp_rookies %+25

			Everyone smiles hearing you say this, and from what you can tell, the smiles all seem entirely genuine.
			*goto ssinterrupt
		*else
			*set rlshp_rookies %+15

			Everyone smiles hearing you say this, but you can tell not all of them are genuine—everyone is still trying to figure you out.
			*goto ssinterrupt
	#"Honestly, I just hope that all of the other Rookies besides us get cut. We're the most deserving, without a doubt."
		*label hatedroute
		*set respected %-20

		*if (respected < 45)
			*set legended +1
			*set lb +5
			*set rlshp_rookies %+25

			Everyone smiles hearing you say this, and from what you can tell, the smiles all seem entirely genuine.
			*goto ssinterrupt
		*else
			*set rlshp_rookies %+15

			Everyone smiles hearing you say this, but you can tell not all of the smiles are genuine—everyone is still trying to figure you out. And trying to determine if you really mean what you say.
			*goto ssinterrupt
	#"I just want to get this experience over with."
		*set rlshp_rookies %-25
		*set lb +5

		Hearing this, no one really knows how to react. Instead, you're met with lots of awkward nods and half-smiles.

		*if (respected > 50)
			*set respected %+10
			*goto ssinterrupt
		*else
			*set respected %-10
			*goto ssinterrupt
	#"I really feel confident about my own chances, so I don't feel any need to be nervous."
		*goto hatedroute
	#"I'm so nervous. I have no idea what I'm even doing here!"
		*goto lovedroute
	#"I'm so happy to be here, especially since everyone seems so unique and interesting."
		*goto lovedroute

*label ssinterrupt

*if mingleprodigies
	*set rlshp_crystalline rlshp_rookies
	*set rlshp_transfer rlshp_rookies
	*goto ssinterruptreal
*elseif minglemisfits 
	*set rlshp_tarsiero rlshp_rookies
	*goto ssinterruptreal
*else
	*set rlshp_griffin rlshp_rookies
	*set rlshp_missboss rlshp_rookies
	*goto ssinterruptreal

*label ssinterruptreal

"${named}, there you are!"

Before you can further gauge the Rookies' reaction, you spin to find StarSoar approaching—though really, you catch the scent of jet fuel before you even see him.

"Apologies for the interruption, everyone. I have been waiting for ${named} to arrive," StarSoar says to the Rookies before turning to face you. "Do you mind if we have a moment alone? You know, to discuss important partner business?"

StarSoar smiles at you and you try to smile back, despite the fact that your heart starts thundering in your chest. Even with the past two months to think it over, you're still not entirely sure what to do about Loa Shift's "advice" on StarSoar's secret. The Great Loa ended up being right about the Veteran twist, but could she be right about the elimination coming down to either you or StarSoar? More importantly, could she be right about StarSoar's expulsion from NASA's Powered Cadet Program? 

JK did some of her best hacker digging, but still couldn't find anyone willing to talk about any experiences with Loa Shift. And while she couldn't corroborate StarSoar's expulsion, JK couldn't find any record of StarSoar's current enrollment, either. Both were very troubling discoveries, mostly because neither proves anything definitively one way or the other.

*page_break

Whatever the truth might be, JK implored you not to publicly ruin StarSoar's reputation. Her budding crush aside, JK believes that nothing is worth the price of selling out another Powered afflicted with a potential ability-related burden, not even her own health. JK also pointed out how betraying StarSoar would make you look, ruining your credibility as a potential positive Underrepresented Powered figure.

Still, you know the decision is yours alone to make—it's your job to take care of JK, whether she approves of your methods or not. But right now, standing across from StarSoar in person, you feel even more undecided than you did before.
*if ssknowsclinic
	Especially since StarSoar knows about your visit to the Shiftsite Clinic. Whatever you do, you cannot allow him to reveal this information. You don't think he'd be capable of doing that, but then, there might be a side to StarSoar you don't know anything about. Besides, he probably wouldn't think you're capable of doing what you're currently considering, either.
*comment endif

"Uh, hey," you say after you make your way back over to the bar with StarSoar. "How was your mission?"

"I am afraid those details are classified, but I can say that it went quite well. Thank you for asking," StarSoar answers, retracting his helmet visor to reveal his freckled face. "Why did you not come talk to me when you got here? I have been very excited to see you. Is something wrong?"

"Oh no, I'm just, uh…really nervous," you say, knowing this is not untrue and trying to buy some time to finally make up your mind.

*page_break

"Oh, good," StarSoar sighs. "I tried to mingle, but that is not my greatest talent. The group of picture-perfect heroes did not want anything to do with me, but Ignite and Crystalline seemed really nice."

"So for this mission, were you off-planet?" you ask, hoping to glean some new shred of information before making this terrible decision. "I mean, what required your attention for a whole two months?"

"I am sorry, but I am not at liberty to inform you. Like I said, it is classified," StarSoar says, eyeing you with some mild suspicion. "Anyway, how is JK doing?"

StarSoar waits for you to respond and you take a deep breath, knowing that you can't stall anymore. You're going to have to get into this now, while you still have the chance. You have to decide whether you believe Loa Shift's information and what you're going to do about it…

Especially because hearing JK's name is all the motivation you need to snap things into focus.

*comment The stats for this choice have been moved into the writing chunks, to affect Stats after the event happens, not before. Also, the Rookie relationship is just for show (and an achievement), individual relationships are affected once the episode airs in Chapter Four (or really, the end of the Production Vignette).

*choice
	#Reveal StarSoar's secret publicly in front of the cameras right now, in order to ensure my own safety.
		*gosub trial_end
		*set sspublic true

		You need to do this to discredit StarSoar and bolster your own status in the Final Selection. It's the only way to guarantee everything happens the way you need it to tonight. JK definitely won't like it, but you'd rather her be angry and healthy than content and…you won't even allow yourself to consider that alternative.
		*goto revealpublic
	#Blackmail StarSoar off-camera; tell him that I'll reveal the truth about him if he doesn't quit the competition immediately.
		*gosub trial_end
		*set ssblackmail true
		
		Unfortunately, you know this is the only way to do what you need to do for Loa Shift and JK without totally ruining StarSoar's reputation.
		*goto blackmailss
	#Warn StarSoar in advance off-camera, to give him a chance to do the right thing and quit before this all inevitably comes out as a scandal and ruins his reputation.
		*gosub trial_end
		*set sswarn true

		This may be the best way to get StarSoar help, if he indeed needs it. You know a secret like this will eventually come out, so you want to try to spare StarSoar that ordeal in a way that can also benefit JK.
		*goto blackmailss
	*selectable_if (elimthree = false) #I believe there must be more to StarSoar's potential expulsion than Loa Shift suggests, so I won't risk sabotaging him with potentially faulty information.
		*gosub trial_end
		*set ssmorestory true
		*set ssprove true

		You're not willing to bet your values on the whims of Loa Shift. Besides, even if she is right about everything, you won't compromise your ideals unless you have absolutely no choice—and maybe not even then. You may be taking a risk, but you believe there's always another way, even if you have to invent one out of thin air.
		*goto provecoding
	*selectable_if (elimthree = false) #Prove to Loa Shift that you and StarSoar can advance together—or, at the very least, that you can advance on your own merit without sabotaging StarSoar.
		*gosub trial_end
		*set ssprove true

		You won't compromise your ideals unless you have absolutely no choice—and maybe not even then. You believe there's always another way, even if you have to invent one out of thin air.

		*label provecoding
		*set societal %+30
		*set rlshp_jk %+30
		*set rlshp_starsoar %+30
		*set rlshp_shift %-30
		*set upa +10
		*set lb -10
		
		*if (societal > 70)
			*set legended +3
			*set respected %+20
			*set rlshp_eps %+15
			*set rlshp_rookies %+15
			*if (public > 50)
				*set public %+20
				*goto provess
			*else
				*set public %-20
				*goto provess
		*else
			*set legended +1
			*set respected %+10
			*set rlshp_eps %-15
			*set rlshp_rookies %+10
			*if (public > 50)
				*set public %+10
				*goto provess
			*else
				*set public %-10
				*goto provess

*label revealpublic

"StarSoar, why are you lying to me about this supposed NASA mission?" you ask, realizing that you have bared your teeth and started to growl a bit. You force yourself to stop and hold it together.

"I do not know what you mean," StarSoar answers, but you can smell the sweat and fear starting to drip off of him. It almost turns your stomach as you realize the ugly truth.

"You're lying," you say. "As your partner, I feel betrayed. I didn't want it to come out this way, but I feel it's my responsibility to the competition and the public."

As you speak, a few more camera orbs show up to film, like automated moths to a drama-fueled flame. StarSoar's eyes grow wide—he's not sure how to react to your seemingly spontaneous speech.

"StarSoar, you were forcibly discharged from NASA's Powered Cadet Program, weren't you?"

You say the words and the room goes silent. You must have been bark-speaking more loudly than you realized. Oh well, they're all going to find out one way or another now, you suppose.

*page_break

StarSoar turns a whiter shade of pale underneath his helmet, beads of sweat collecting on his forehead.

"How do you know that?" he whispers. "It's supposed to be—"

"Classified?" you say. "StarSoar, it would be wrong to keep hiding the truth about why you were discharged."

"No, you're supposed to be my friend," StarSoar tries, his eyes wide with panic. "You don't understand."

"You're right, I don't," you interrupt again. "You can't really believe that we're being secretly invaded by aliens, can you? Because StarSoar, you have to know that sounds—"

"No, it wasn't supposed to happen like this, not again," StarSoar chokes, placing his hands on your shoulders and locking his eyes on yours. "I am not crazy, ${named}. You have to believe me. But there are these voices from space, warnings from the galaxy beyond. I do not know how, but my Powers let me hear them. It is a frequency that they have not yet discovered I have access to. I know that sounds—"

"Do you have any proof of these claims? Recordings of these voices?" you ask, feeling increasingly sick about the way this is turning out. Luckily, StarSoar falls silent at this question, giving you all the answer you need. So you keep talking, removing yourself from his grip. 

"Is that why you tried out for The Hero Project, to get a platform where people might listen to you?

*page_break

"You can't do that, StarSoar. It's not fair to cause that kind of panic, to spread your delusions that way," you say, on a roll. "I think your Powers have altered your judgment and you need—"

"No, my Powers let me hear and see things that no one else can!" StarSoar cries. "You could not possibly understand!"

"I understand what it's like to have Powers that cloud your perception of the world," you say, trying to remain calm as StarSoar appears increasingly frantic. "But you cannot let them control you. I think you need help, StarSoar. I know that's hard to hear, but as your former partner and your friend, I feel it's my responsibility to—"

"You are no friend of mine!" StarSoar shouts, slamming his fist down on the bar. "I do not know who put you up to this, but do not dare pretend this is some selfless gesture."

Whatever else you believe, that comment stings, because you know it's partially true. You wish you could tell StarSoar the real reason you're doing this, that it's all for JK—that on some level you are trying to be selfless. But you know that you can't do that, not without jeopardizing everything.
*if ssknowsclinic
	Which reminds you—StarSoar knows about JK's visit to the Shiftsite clinic, so you need to shut this down before he starts putting those pieces together. 
*page_break

*set societal %-30
*set rlshp_jk %-30
*set rlshp_starsoar %-50

*if (societal < 40)
	*set legended +3
	*set lb +5
	*set public %+20
	*set upa +10
	*set rlshp_shift %+20
	*set rlshp_eps %+15
	*set rlshp_rookies %-10
	*if (respected > 50)
		*set respected %+20
		*goto iamwhoreal
	*else
		*set respected %-20
		*goto iamwhoreal
*else
	*set legended +1
	*set public %+10
	*set upa -10
	*set rlshp_shift %+10
	*set rlshp_eps %-15
	*set rlshp_rookies %-15
	*if (respected > 50)
		*set respected %+10
		*goto iamwhoreal
	*else
		*set respected %-10
		*goto iamwhoreal

*label iamwhoreal

"I know what is real! I am not crazy! They are coming and we have to stop them!" StarSoar begins to scream, sweat now pouring down his face as blue thrust starts to charge around his body. "Wait, did they get to you? Is that why you did this to me? Are you the one they put here?"

By now, the whole room is gawking at StarSoar, and six more camera orbs have arrived to film. Slugger, you didn't know what to expect, but you didn't expect StarSoar to seem so…desperate. Or afraid. 
*if trilogyreader
	You can't help but think that you just added to the long list of heroes The Hero Project has ruined. 
Is that really what you want your legacy to be? Discrediting other Powereds for struggling to cope with the issues their Powers can present?

As soon as this thought forms, however, it is replaced by another: The only legacy that matters is JK's.

"Oh, StarSoar," you say, taking a few steps back. "We'll get you the help that you need. I promise."

StarSoar then sets his gaze on you, looking just about ready to explode. You have to force a defensive growl from creeping into your throat as the standoff continues…until StarSoar abruptly turns and storms away.

You allow yourself to breathe again, though as you do, you are suddenly aware that you are not  alone—all eyes in the room fall on you now that StarSoar is gone. Noticing the weight of their collective gaze, all you can feel is:

*label feelsschoice
*choice
	#Absolutely horrible.
		*set respected %+10
		*label hypo

		You feel like a complete hypocrite for what you've just done: using another Powered individual's issues against them for personal gain—especially a Powered individual who trusted you as a friend.

		You just fed into the culture of oppression, further stigmatizing Underrepresented Powereds and those with mental health issues as unstable, second-class citizens. You might have had a good reason, but do any ends really justify these kinds of means?

		You suppose, for better or worse, that the answer for you today was yes.
		*page_break
		*goto bigsplashe
	#Satisfied to have pulled that conversation off and to have made such a moment of it, whether I meant to or not.
		*set respected %-10
		*label nagging

		Advancing in the competition has to be your priority, to save JK's life, and you just did everything you needed to ensure that will happen. Still, you can't help the nagging feeling that you just fed into the culture of oppression, further stigmatizing Underrepresented Powereds and those with mental health issues as unstable, second-class citizens. 

		As soon as this thought forms, however, you remind yourself that in this case, the ends justify any means necessary. And that's something you can live with.
		*page_break
		*goto bigsplashe
	#Courageous, oddly. I am now convinced that StarSoar really does need help. Maybe I just did him a favor, in the long run?
		*set upa +5

		You want to tell yourself that, but what if you're somehow wrong about this? Or even if you're totally right about StarSoar, was that really the way to help him, given that Underrepresented Powereds and those with mental health issues are stigmatized as unstable, second-class citizens? 

		You can't help but have your doubts, but at least in this moment, you feel you tried to do the right thing. 
		*goto bigsplashe
	#Numb. That just set Underrepresented Powereds back quite a bit, I'm sure.
		*set societal %+10
		*goto hypo
	#Like I did what I needed to do for JK. Period.
		*set societal %-10

		Advancing to save JK's life has to be your priority, and you just did everything you needed to ensure that will happen. Still, you can't help the nagging feeling that you just fed into the culture of oppression, further stigmatizing Underrepresented Powereds and those with mental health issues as unstable, second-class citizens. 

		As soon as this thought forms, however, you remind yourself that in this case, making sure JK lives a happy and healthy life must remain your priority. To you, nothing else can be more important.
		*goto bigsplashe
	#Loa Shift seems to have been right about StarSoar's expulsion, but what if she and everyone else is wrong about the true nature of his Powers?
		StarSoar certainly seems to think these voices and this threat are both real, but you can't really imagine that either could be—at least until StarSoar shows some kind of concrete proof.

		Still, what if you're somehow wrong about all of this? And even if you're not, you can't help but feel that you just fed into the culture of oppression, further stigmatizing Underrepresented Powereds and those with mental health issues as unstable, second class-citizens. You might have had a good reason, but do any ends really justify these kinds of means?

		You suppose, for better or worse, that the answer for you today was yes. You just hope this decision doesn't come back to haunt you, somehow.
		*if (societal > 50)
			*set societal %+5
			*goto bigsplashe
		*else
			*set societal %-5
			*goto bigsplashe
	*if (ssknowsclinic) #Worried. I just hope StarSoar doesn't decide to use his knowledge of JK's Shiftsite treatments against me now. 
		*set societal %+10
		Though now that StarSoar is discredited, you suppose no one will believe anything else he has to say, anyway. 

		Realizing this, you can't help but feel that you just fed into the culture of oppression, further stigmatizing Underrepresented Powereds and those with mental health issues as unstable, second-class citizens. You might have had a good reason, but do any ends really justify these kinds of means?

		As soon as this thought forms, however, you remind yourself that in this case, making sure JK lives a happy and healthy life must remain your priority. To you, nothing else can be more important.
		*goto bigsplashe

*label bigsplashe

No matter what, this scene is going to make a big splash and get you lots of attention on the show, if the producers decide to feature it. And really, how can they not? Whatever your intentions, you can be sure that this decision, along with your first Rookie mingle, will be the next major impression defining who you are on The Hero Project—assuming you advance through the Final Selection, of course.

*if sspublic
	Knowing this, you're about to say something to the crowds of partygoers staring at you when all eyes shift to a spotlight on the stage erected on the other side of the great room. Colton Quick stands there, holding a microphone. 

	"Sorry to interrupt the festivities everyone, but the time for the Final Selection Ceremony has come."

	[i]Saved by the bell[/i], you think, as everyone starts to chatter again. Which is just as well—you could use a few moments to yourself to process what you've just done, not to mention a good distraction.
	*goto finalselection
*else
	Knowing this, you're about to say something to the hidden cameras when Colton Quick's voice starts to boom over a set of loudspeakers.

	"Sorry to interrupt the festivities everyone, but the time for the Final Selection Ceremony has come."

	[i]Saved by the bell[/i], you think, as the announcement ends. Which is just as well—you could use a few moments to yourself to process what you've just done, not to mention a good distraction.
	*goto finalselection

*label blackmailss

"Hey, I have to go to the bathroom," you say. "Mind coming with me to block the door? You know, dog issues."

"Um, okay," StarSoar says, looking too polite to admit this makes him uncomfortable. That's fine though, because you know you don't actually have to go to the bathroom. JK made sure to tell you before coming here that the only place you can hope to be free of cameras is the restroom, so you know this is your only chance at privacy.

One short walk later, you quickly pull StarSoar inside one of the private bathrooms and lock the door before any camera orbs can follow.

"Hey, what are you—" StarSoar starts, but you cut to the chase before he can finish.

"StarSoar, I know about your expulsion from the Powered Cadet Program," you say, point-blank.

*page_break

"That…that is not true," StarSoar tries, but you can smell the sweat and fear starting to drip off of him. It almost turns your stomach as you realize the ugly truth. 

StarSoar sees your nose twitching and must realize there will be no lying his way out of this, because he then asks: "How did you find out?"

Slugger.

"It doesn't matter how I know. All that matters is that I'm not going to tell anyone," you say.
*if ssblackmail
	"At least, I won't tell anyone if you drop out of the competition now, before the Final Selection Ceremony."

	Hearing this, StarSoar turns a whiter shade of pale underneath his helmet, beads of sweat collecting on his forehead.

	"Why are you doing this?" he whispers. 

	"Believe it or not, because I'm your friend. I think you need to quit, before this secret inevitably comes out and ruins your reputation."
	*goto moreconvo
*else
	"But as your friend, StarSoar, I need you to listen to me. You have to know that if you stay on the show, someone else is going to find out too, sooner or later. I think you need to quit, before this publicly ruins your reputation."
	*goto moreconvo

*label moreconvo
*page_break

"No, you don't understand," StarSoar tries, his eyes suddenly growing wide with panic.

"You're right, I don't," you answer before StarSoar can continue. "You can't really believe that we're being secretly invaded by aliens, can you? Because you have to know that sounds—"

"No, it wasn't supposed to happen like this, not again," StarSoar chokes, placing his hands on your shoulders and locking his eyes on yours. "I am not crazy, ${named}. You have to believe me. But there are these voices from space, warnings from the galaxy beyond. I do not know how, but my Powers let me hear them. It is a frequency that they have not yet discovered I have access to. I know that sounds—"

"Do you have any proof of these claims? Recordings of these voices?" you ask, feeling increasingly sick about the way this is turning out. StarSoar falls silent at this question, giving you all the answer you need. 

*page_break

"Is that why you tried out for The Hero Project, to get a platform where people might listen to you?" you ask. "StarSoar, I think your Powers have altered your judgment and your perception of reality. I've seen this happen before, it—"

"No, my Powers let me hear and see things that no one else can!" StarSoar cries. "You could not possibly understand!"

"I understand what it's like to have Powers that cloud your perception of the world," you say, trying to remain calm as StarSoar grows increasingly frantic. "But you cannot let your Powers control you. I think you need help, StarSoar."

You say the words and wonder if you're trying to convince StarSoar or yourself. You realize that you don't know the answer—but either way, it's too late now.

*if ssblackmail
	"And you think the best way to help me is to blackmail me into quitting?" StarSoar asks, looking shattered. "If that is your true goal here, please do not mask it with some false selfless agenda."

	Whatever else you believe, that comment really stings, because you know it's partially true. You wish you could tell StarSoar the real reason you're doing this, that it's all for JK—that on some level you are trying to be selfless. But you know that you can't do that, not without jeopardizing everything.
	*if ssknowsclinic
		Which reminds you—StarSoar knows about JK's visit to the Shiftsite clinic, so you need to shut this down before he starts putting those pieces together. 
	*goto moreconvotwo
*else
	"I don't understand. Did someone put you up to this?" StarSoar asks, looking stricken. 

	You wish you could tell StarSoar the real reason you're doing this, that it's all for JK, that on some level you are trying to be selfless. But you know that you can't do that, not without jeopardizing everything.
	*if ssknowsclinic
		Actually, hearing this reminds you that StarSoar knows about JK's visit to the Shiftsite clinic, so you need to shut this down before he starts putting the pieces together. 
	*goto moreconvotwo

*label moreconvotwo
*page_break

"StarSoar, my motivations don't really matter, do they?" you say. "All that matters is that I know this is the best thing for you."

"I know what is real! I am not crazy! They are coming and we have to stop them!" StarSoar begins to scream, sweat now pouring down his face as blue thrust starts to charge around his body. "Wait, did they get to you? Is that why you did this to me? Are you the one they put here?"

Slugger. You didn't know what to expect, but you didn't expect StarSoar to seem so…desperate. Or afraid. Or potentially…dangerous?

"Oh, StarSoar," you say, taking a few steps away to put some distance between you and him. As you do, suddenly your dog-ears pick up an almost-imperceptible whir. And you freeze. 

[i]Slugger. No.[/i]

You turn to look at the mirror and realize with a burst of pure dread that it's tinted one-way glass. Which means that behind that mirror, a wall of camera orbs must be taping this entire conversation.

*page_break

"Oh no," you whimper, causing StarSoar to turn towards the mirror. He immediately arrives at the same conclusion and matches your look of horror. All you can think is that you should have known, that you were warned everything you said and did would be up for grabs. Still, hidden cameras in the bathrooms? That feels like such a…violation.

*if ssblackmail
	Once the initial shock fades, all you can think is that trying to blackmail StarSoar off-camera like this is going to make you look horrible. Though as soon as the thought forms, your next one is of how this show is already changing you.

	*set societal %-15
	*set rlshp_jk %-30
	*set rlshp_starsoar %-30
	*set upa -10

	*if (societal < 50)
		*set legended +3
		*set lb +5
		*set public %-20
		*set rlshp_shift %+20
		*set rlshp_eps %+15
		*set rlshp_rookies %-10
		*set respected %-20
		*goto sinkit
	*else
		*set legended +1
		*set public %-10
		*set rlshp_shift %+10
		*set rlshp_eps %-15
		*set rlshp_rookies %-15
		*set respected %-10
		*goto sinkit
*else
	Once the initial shock fades, all you can think is that, at the very least, you're probably going to come off looking good by choosing to try and help StarSoar like this off-camera. Though as soon as the thought forms, your next one is of how this show is already changing you.

	*set societal %+15
	*set rlshp_jk %+15
	*set rlshp_starsoar %-15
	*set upa +10

	*if (societal > 50)
		*set legended +3
		*set lb +5
		*set public %-20
		*set rlshp_shift %+10
		*set rlshp_eps %+15
		*set rlshp_rookies %+15
		*set respected %+20
		*goto sinkit
	*else
		*set legended +1
		*set public %-10
		*set rlshp_shift %+5
		*set rlshp_eps %-15
		*set rlshp_rookies %+10
		*set respected %+10
		*goto sinkit

*label sinkit

*if trilogyreader
	As this realization sinks in, you can't help but think that you just added to the long list of heroes The Hero Project has ruined. 
Is this really what you want your legacy to be? Discrediting other Powereds for struggling to cope with the issues their Powers can present? As soon as this thought forms, however, it is replaced by another: the only legacy that matters is JK's.

StarSoar then sets his gaze back on you, looking just about ready to explode. You have to force a defensive growl from creeping into your throat when you see the pained look that warps StarSoar's face. 

That is, until StarSoar abruptly turns and storms out of the bathroom. You allow yourself to breathe again, though as you do, you are suddenly aware that you are not alone—a dozen hidden cameras are probably focusing solely on you, now that StarSoar is gone. Noticing the weight of their collective gaze, all you can feel is:
*goto feelsschoice

*label provess

"So, what do you think we should do here to push up our Leaderboard scores?" you ask.

"Well, I don't know about that, but I do have something to tell you," StarSoar says, keeping his eyes on the floor. "I have been trying to build up the courage to do so ever since I saw you back home in Dockerbay."

You freeze—could StarSoar be about to tell you the secret you might already know? In front of all these cameras? You just nod and stay silent, not sure what else to do.

"I am terrible at these kinds of things, but my mom told me to just come out and say it. So that is precisely what I am going to do," StarSoar says, taking a deep breath in. You realize you've been holding your own breath, waiting for StarSoar's announcement, so you exhale cautiously.

StarSoar raises his eyes to meet yours, and then he says…

*page_break

"I believe I have a crush on you, ${named}."

As StarSoar says the words, suddenly a rush of camera orbs flood into the space around you, like automated moths to a drama-fueled flame.

"Oh," you say, having no idea how to respond. Mostly because you're very unaccustomed to anyone professing any feelings for you. Actually, you don't know if you can recall that happening…ever?

"Well, maybe this dog day is not my favorite," StarSoar laughs, trying to break the silence left in the wake of your shock. "But none of that Ani-stuff really matters to me. All that matters is that I like the person underneath."

*page_break

As StarSoar speaks, all you can think is how horrible it would have been if you had chosen to expose him or sell him out, now that you know he feels this way about you. Though your next thought, rather unfortunately, is of whether StarSoar could just be doing this for the sake of the cameras and your Leaderboard scores. 

A quick canine read of StarSoar's flop sweat and thundering heartbeat tells you otherwise, but that momentary comfort fades as you have another thought: poor JK will be very disappointed by this, given her own crush on StarSoar.

Your next thought is that you should probably say something. Anything.

*page_break

Before you can respond, however, all eyes shift to a spotlight on the stage erected on the other side of the great room. Colton Quick stands there, holding a microphone. 

"Sorry to interrupt the festivities everyone, but the time for the Final Selection Ceremony has come."

[i]Saved by the bell[/i], you think—because you need to consider very carefully how you respond to StarSoar. However you really feel, you also realize that leaving the question of your feelings open-ended may help push you and StarSoar both through to the Final Selection together, if the producers think they might get a showmance out of it. And really, you need all the help you can get now, since you've gone directly against Loa Shift's advice.

You realize that you still have no way to know whether Loa Shift's claims about StarSoar's delusion-based expulsion are true, but you also know that it isn't your place to decide whether that information is revealed or not.

"We'll talk about this when we both make the Live Finals—how about that?" you say, hoping this vague response will be enough to push you and StarSoar through together. You can be sure that answering this question, along with your first Rookie mingle, will be the next major impression defining who you are on The Hero Project—assuming you manage to advance, of course.
*goto finalselection

*label finalselection
*page_break THE CEREMONY BEGINS

*if elimthree
	Next thing you know, you find yourself on The Hero Project soundstage, sitting in a hooded chair and awaiting the Final Selection results. Your only thought is of what will happen next.

	*goto suspenstime
*else
	*goto sitonthestage

*label sitonthestage

You sit onstage, bright lights shining down and burning spots in your vision. You're seated among the other Rookies, each of you next to your partners—though StarSoar currently refuses to look in your direction. Instead, you both stare down at your plastic chairs, which are rigged with some intricate mechanics and blinking lights. You figure these will help reveal the results somehow during the ceremony, which is now being filmed in front of an actual live audience. You can't see them beyond the stage lights, but you can certainly smell them—and hear them.

Especially since they're all currently cheering the newly revealed panel of Judges sitting at a glass table facing the stage. You have trouble processing the reality of this sight: everything feels so surreal, like someone has placed a plastic film over your eyes and you're watching this on 3V. And yet every time you remind yourself that this is actually real, you're flooded with a fresh surge of nerves.

Surveying the Judges, you see that The Hero Project has cleaned house from the first season and replaced the original Judges with an entirely new panel. Which makes sense, since two of the original Judges are either shamed or in jail after last season's controversy.
*if newreader
	To make a trilogy-worthy story short, JK explained to you during her Hero Project Boot Camp that a secret cabal of powerful figures created the The Hero Project as a vehicle to gain enough popularity to begin dePowering Infini-Class Powereds, who are gifted with near limitless levels of Power. This cabal and the winners of the first season came close to doing just that with their de-Powering Infinity Regulator weaponized technology. 
*comment endif

Considering what JK explained to you during her Hero Project Boot Camp, it's shocking this show got a second season after all of the failures of the first season. Apparently The Hero Project was just too big of a cultural juggernaut and ratings smash to not warrant this second season.

*page_break

For you, the main takeaway from this first season was actually the existence of this de-Powering Infinity Regulator and how it might be helpful in treating Disembodied Powereds like JK. You understand why such technology has since been destroyed and banned—it sets a very dangerous precedent. Besides, you're not sure that JK would ever really want to be de-Powered. Her Powers, for better or worse, are an important part of who she is.

But the sensational first season made you realize that being a part of The Hero Project could eventually grant you access to better health care and Herologist resources, or the financial ability to explore new experimental options for JK outside of what Loa Shift can offer. You've never had access to any kind of wealth or influence, so you're curious what even a taste of both might afford you. 

However, you were also quick to remind yourself that none of these options will exist if you get eliminated tonight. Which is why you force yourself to refocus on the ceremony now, especially the pair of new Judges that you have to impress. You recognize both as heroic icons who stood against last season's corruption, but you wait for MeChip Prodigal to fill you in on the exact details.

*page_break

"The decadent Diva redefines herself yet again!" MeChip Prodigal proclaims, right on cue, as you focus on the first Judge. "From cardiothoracic surgeon to Millennial Group leader to Infini advocate to The Hero Project Judge, The Diva's mega-sonic vocals, couture costumes, and legendary heroics have made her one of the world's foremost Infini icons—aside from yours truly, of course."

You look down at The Diva, who wears a striking white jumpsuit with golden metal seams, topped off with an attached white cape featuring a neon-pink interior. Her jet-black hair falls down to her waist, streaked with slivers of grey that pop against her flawless caramel skin. Instantly, you can tell why she's an icon—she radiates presence.

"I am absolutely thrilled to be here," The Diva says without need for a microphone, her voice sounding smooth and sophisticated at once. "I have dedicated my life to leading and mentoring emerging heroes, so I am looking forward to grooming and selecting the next generation. I also feel it is my responsibility to right the wrongs perpetrated by this Judges Panel in the past."

*if trilogyreader
	"Ooh, sounds like someone isn't quite over her rivalry with the once-great Rebellion," MeChip Prodigal whispers, as if she's dishing some grade-A gossip. "Can you really blame her?"
*if newreader
	The Diva pauses, allowing her silence to punctuate the seriousness of her statement.
*comment endif

"Of course, you can be sure that I will remain brutally honest, as always," The Diva finishes, lifting a frosted martini glass and turning towards the audience. "Let us now raise a toast to the future of our heroes and the future of The Hero Project!"

*page_break

Once the crowd's roaring applause dies down, all attention turns to the second Judge, who sits bolt-straight beside The Diva.

"Sluggedy-cluck, The Crush gives even me the willies—and some would call me a viably vile villain," MeChip Prodigal shivers. "The Crush is an equally iconic Infini figure, but for a very different set of reasons: he is a former cult leader turned hero, having triumphed over last season's efforts to vilify him. I'd be happy to see him here if I wasn't so positively frightened!"

You look over at The Crush and can see why MeChip Prodigal feels intimidated—he seems to course with calm power and influence.

"As you all know, I come to The Hero Project as a living symbol of the power of redemption," The Crush begins. "The Diva and I chose to pause our Infini Advocacy campaign and return to The Hero Project because we truly believe it can be a force for monumental positivity. This show has already proven it is capable of changing the world, but we are here to ensure that this season will be about changing it for the better."

The Crush and The Diva both seem to be in their sixties, but project different auras of wisdom and experience. The Crush seems almost ancient, with his curly white hair, amber eyes, and creased brown skin, while The Diva feels elegantly timeless. They both happen to be equally imposing, however.

*choice
	#I can learn much from these two about public heroics and Powered advocacy.
		*set traditional %+15

		Infini Powereds recently stood at the forefront of Anti-Powered Sentiment, but you know that now it is time to shed light on the less fortunate Underrepresented Powered classifications that you inhabit.
		*if ((ssprove) or (sswarn)) or (ssmorestory)
			*goto thprs
		*else
			After the way you handled things with StarSoar, though, you're not necessarily doing the best job so far.
			*goto thprs
	#How am I ever going to impress these two?
		Then you remind yourself that you already have in some way, getting this far. The Diva and The Crush know firsthand what it's like to be misunderstood and feared because of their Power. You hope they can find a way to see how much more difficult this experience is for those Powereds with fewer resources at their disposal, or for those who don't look the way traditional heroes are "supposed" to look.
		
		*if (traditional > 50)
			*set traditional %+10
			*goto thprs
		*else
			*set traditional %-10
			*goto thprs
	#These Judges don't impress me all that much.
		*set traditional %-15

		You've never been one to fall at the feet of Powered heroes and you're not going to start now. Still, The Diva and The Crush know firsthand what it's like to be misunderstood and feared because of their Powers. If they're smart, perhaps they'll see how much more difficult this experience is for those Powereds with fewer resources at their disposal, or for those who don't look the way traditional heroes are "supposed" to look.
		*goto thprs

*label thprs

"For this reason," The Crush continues, "we have decided to name this The Hero Project: Redemption Season. This year is all about second chances and renewed hope, not just for our show, but also for The American Protectorate, the national Powered team our winners will join."

"In keeping with this mission statement, we decided to further shake up the Judges Panel," The Diva adds. "As you've probably noticed, there are only two of us, leaving one seat empty. This seat will be filled by a rotating series of guest Judges and Mentors from the heroic community that our show hopes to emulate. I've arranged for many of these guest stars to come from my very own heroic home, The Millennial Group, especially since many of the first season's more successful alumni ended up there."

*if trilogyreader
	"Ouch!" MeChip Prodigal laughs. "Note that no one has mentioned the winners on the current roster of The American Protectorate. The Producers must be hiding them away for now, what with their role in all of last year's controversy. I wonder when our giggling GG will allow them to show their fraudulent faces!"
*comment endif

"Most importantly, this season will be a second chance for our Veterans!" Colton Quick suddenly shouts as he runs out on stage, causing the audience to go crazy with cheers and applause. "Well, we are going to find out who those Veterans are very soon! However, we have a twist for you all, one that actually involves our rising Rookies…"

*page_break

"For the early part of the Live Finals, we're going to keep the Rookie and Veteran rosters secret from each other, so that neither will know who they're really up against until they finally face off!"

Hearing this, you figure it's just as well to wait—as much as you might want to learn which Veterans you'll be up against this season, you know it's much more important to see whether you'll even advance to this next stage in the first place—and, of course, to learn which Rookies you'll be fighting alongside if you do. 

Though you wonder if you'll even get to learn that as your chair suddenly begins to hum and whine. Within seconds, a dark hood unfolds from the back of the chair like a hardtop convertible, beginning to cover you inside its shell.

"So for the time being, we're going to tuck our Rookies away," Colton announces, waving goodbye from across the stage. "We'll be seeing you again later…if you're lucky!"

As Colton says this, the hood fully descends above you and its interior lights gradually brighten. Your focus remains on a holo-screen in front of you, which reads [i]Hold For Results[/i]. You quickly realize that you're probably going to have to wait in here until your results come, left to stew in your own nerves for slugger knows how long.

*page_break

Luckily, MeChip Prodigal must sense your nerves, because she appears immediately to keep you company.

"Oh me oh my," MeChip Prodigal sing-speaks. "I simply must know, now that it's just us: Do you fancy anyone so far? You do know how audiences love their little showmances!"

Almost laughing at Prodigal, you realize that you haven't given that particular question much thought at all. But now that Prodigal mentions it, you do know this:

*choice
	#I am only attracted to men.
		*set attractmen true

		Thankfully, American culture has evolved to a place where most sexual and gender identities have been generally accepted, so you've had some freedom to explore any curiosity you may have had. In the end, you found that while others may have more fluid attractions, you are most consistently attracted to men.

		You just wish this spirit of freedom and equality extended to the categories that currently divide the culture of American Powereds.

		"Ah, well in that case, you'll have plenty of potential showmances to choose from," MeChip Prodigal teases, holding up a set of hero holo-cards and plucking them like rose petals. "Shall you initiate ignition with Ignite? Get lost with Exile? Attempt to tame the mighty Griffin? Oh, silly me, I suppose your answer will depend entirely on who makes it through the Final Selection in the first place…."

		*if ssprove
			*goto sstest
		*else
			*page_break
			Before you can respond to MeChip Prodigal,
			*goto lbtime
	#I am only attracted to women.
		*set attractwomen true
		*set weaverze "she"
		*set weaverhir "her"
		*set weaverhis "her"
		*set weaverne "niece"

		Thankfully, American culture has evolved to a place where most sexual and gender identities have been generally accepted, so you've had some freedom to explore any curiosity you may have had. In the end, you found that while others may have more fluid attractions, you are most consistently attracted to women.

		You just wish this spirit of freedom and equality extended to the categories that currently divide the culture of American Powereds.

		"Ah, well in that case, you'll have plenty of potential showmances to choose from," MeChip Prodigal teases, holding up a set of heroic holo-cards and plucking them like rose petals. "Shall you be trying to make it Reigna? Attempting to crystallize Crystalline? Taking orders from Miss Boss? Oh, silly me, I suppose your answer will depend entirely on who makes it through the Final Selection in the first place…."

		*if ssprove
			Honestly, you're more concerned with how you're going to let StarSoar down easy, when the time comes. He doesn't know yet that you aren't into guys, unfortunately.
			
			*page_break

			Before you can respond to MeChip Prodigal,
			*goto lbtime
		*else
			*page_break
			Before you can respond to MeChip Prodigal,
			*goto lbtime
	#I don't see gender, I see people. My attractions aren't limited by gender.
		*set bisex true
		*set attractmen true
		*set attractwomen true

		Thankfully, American culture has evolved to a place where most sexual and gender identities have been generally accepted, so you've had the freedom to explore any curiosity you've had.

		You just wish this spirit of freedom and equality extended to the categories that currently divide the culture of American Powereds.

		At any rate, usually you just let your attractions be your guide, but if you had to guess, you've been feeling lately like you next might be interested in:

		*choice
			#Someone male.
				*goto bisexafter
			#Someone female.
				*set weaverze "she"
				*set weaverhir "her"
				*set weaverhis "her"
				*set weaverne "niece"
				*goto bisexafter
			#Someone with a non-binary gender identity.
				*set weaverze "ze"
				*set weaverhir "hir"
				*set weaverhis "hir"
				*set weaverne "niephew"

				*label bisexafter
				However, you know that any expectations you've had like these in the past are usually overridden by who you meet. You know it's best for you to remain as open-minded as possible. You've been attracted to all kinds of people and you value having the freedom to be attracted to whomever you want, without any restrictions.

				"Ah, well in that case, you'll have plenty of potential showmances to choose from," MeChip Prodigal teases, holding up a set of heroic holo-cards and plucking them like rose petals. "Shall you crossbreed with Tarsiero? Make it Reigna? Get lost with Exile? Oh, silly me, I suppose your answer will depend entirely on who makes it through the Final Selection in the first place…."

				*if ssprove
					*goto sstest
				*else
					*page_break
					Before you can respond to MeChip Prodigal,
					*goto lbtime
	#I'm most attracted to androgyny and uncategorizable gender identities, but I try not to limit myself to any narrow expectations or limitations.
		*set pansex true
		*set attractmen true
		*set attractwomen true
		*set weaverze "ze"
		*set weaverhir "hir"
		*set weaverhis "hir"
		*set weaverne "niephew"

		Thankfully, American culture has evolved to a place where most sexual and gender identities have been generally accepted, so you've had the freedom to explore any curiosty you've had. You don't limit your attractions to gender or anything else—you've been attracted to all kinds of people and you value having the freedom to be attracted to whomever you want, without any restrictions.

		You just wish this spirit of freedom and equality extended to the categories that currently divide the culture of American Powereds.

		"Ah, well in that case, you'll have plenty of potential showmances to choose from," MeChip Prodigal teases, holding up a set of heroic holo-cards and plucking them like rose petals. "Will you dino-dance with Velocityl? Attempt to tempt Transfer? Crossbreed with Tarsiero? Kiki with Nitewerq? Oh, silly me, I suppose your answer will depend entirely on who moves on through the Final Selection in the first place…."

		*if ssprove
			*goto sstest
		*else
			*page_break
			Before you can respond to MeChip Prodigal,
			*goto lbtime
	#I identify as asexual.
		*set asexual true

		While you might be interested in developing a romantic relationship with someone if you choose, you aren't currently interested in engaging in a sexual relationship.

		That said, if you do develop feelings for someone, they usually tend to be:

		*choice
			#Male.
				*set attractmen true

				*label asexsstest
				*if ssprove
					*goto sstest
				*else
					You're distracted from this thought, however, as
					*goto lbtime
			#Female.
				*set attractwomen true
				*set weaverze "she"
				*set weaverhir "her"
				*set weaverhis "her"
				*set weaverne "niece"

				*if ssprove
					Honestly, you're more concerned with how you're going to let StarSoar down easy, when the time comes. He doesn't know yet that you aren't into guys, unfortunately.
			
					You're distracted from this thought, however, as
					*goto lbtime
				*else
					You're distracted from this thought, however, as
					*goto lbtime
			#Either male or female.
				*set bisex true
				*set attractmen true
				*set attractwomen true
				*set weaverze "ze"
				*set weaverhir "hir"
				*set weaverhis "hir"
				*set weaverne "niephew"
				*goto asexsstest
			#Neither male nor female.
				*set pansex true
				*set attractmen true
				*set attractwomen true
				*set weaverze "ze"
				*set weaverhir "hir"
				*set weaverhis "hir"
				*set weaverne "niephew"
				*goto asexsstest

*label sstest

MeChip Prodigal then pauses, a wild smile spreading across her face.

"Truly, I suppose I should just be asking if you hope to launch skyrockets in flight with StarSoar!"

Knowing that's a very good question, you decide to think your answer at MeChip Prodigal.

*choice
	#Yes, I think I do have feelings for StarSoar. We'll have to see, though.
		*set sscrush true

		*label beforetire
		As MeChip Prodigal said earlier, how and when you tell StarSoar this will depend entirely on whether you both make it through tonight's elimination. Just as you think this,
		*goto lbtime
	#No, I don't feel that way about StarSoar.
		*goto beforetire
	#I'm not quite sure yet, to be honest. I guess I'm open to the possibility.
		*set sscrush true
		*goto beforetire

*label lbtime
the screen in front of you suddenly shifts into a live feed of Colton and the Judges, back outside on the soundstage.

"Are we ready to learn which seven Rookies will be advancing to the Live Finals, to face off against the Veterans?" Colton asks, booming through speakers inside your hooded chair. Whatever news they delivered while you've been sequestered in here must have happened very quickly—though you remind yourself that, since this is a pre-taped episode to be edited and aired later, they could have revealed no news at all. Nothing says they have to film things in the order the episode will end up being broadcast.

"The Diva and The Crush were responsible for selecting these fourteen Rookies in the final stage of the Semi-Finals and tonight these same Judges must decide which seven Rookies will continue to advance. Of course, this selection is based on the Leaderboard scores already assigned by the Judges, from both the Semi-Finals and today's meet-and-greet interactions."

"We're simply choosing the best heroes to potentially round out The American Protectorate," The Diva announces. "There will be no Wildcards or Judges Saves this season, for The Crush and I are only interested in picking the best of the best."

"That said, all of us here have been given a second chance in some form or another," The Crush adds. "We fully recognize, however, that this is the first chance for many of these Rookies. In that spirit, we are looking for heroes who bring a new and vital energy to this season."

*page_break

"We have a packed show tonight, so why don't we get right down to it?" Colton announces, shouting over the roar of the audience. He waits for the noise to die down to suspenseful silence before he goes on. 

"Tied with high scores of 99, the first Rookies moving on to the Live Finals will be…"

You find yourself once again holding your breath. Whether you're ready or not, Colton is about to announce the reality you will be living for the next several months—or much longer than that, for better or worse.

*page_break
*set crystallineignitenameon true
*set showcrystalline true
*set showignite true
*set showtransfer false
*set shownitewerq false
*set showtarsiero false
*set showvelocityl false
*set showsplint false
*set showmissboss false
*set showreigna false
*set showgriffin false
*set showexile false
*set showoconnell false

"Semi-Final partners Crystalline and Ignite!" Colton shouts, causing another burst of adulation to roar from the audience. It's so loud that you can hear and feel its vibrations through your soundproof chair.

You watch on your screen as Ignite and Crystalline emerge from their hooded chairs, looking completely overwhelmed. Their early advancement isn't terribly surprising, since these two have been painted as promising frontrunners from the beginning of the season. You're sure that their potential for a starry-eyed showmance has also helped to cement their spot in the Live Finals.

Before you even have time to process this announcement, Colton steps between Crystalline and Ignite, waving to silence the audience. "We want to hear from our first two Rookie Finalists, but first, I have a very important announcement about the rest of the results."

The crowd falls silent almost immediately, seeming to match the somber tone set by the now-serious look on Colton's face.

*page_break

"The Judges have informed me that, according to the remaining Leaderboard scores, this will be the only pair of Semi-Final partners moving forward together," Colton says, mugging his best look of sorrow. "That's right, America. This means that one Rookie pairing will be eliminated entirely, and the rest of our Rookie Semi-Finals pairings will be split apart."

As Colton lets this news settle and the crowd begins to boo, your hooded holo-screen suddenly cuts out, leaving you to chew on this ominous news by yourself. 

So it really is going to come down to you or StarSoar, quite literally. 

You immediately feel your stomach drop, because you also realize that Loa Shift was right about her prediction. 
*if (ssprove) or (ssmorestory)
	Which makes this the second of Loa Shift's precognitive tips proven to be correct, so far.
	*goto precogtip
*else
	Which means that all three of Loa Shift's precognitive tips have proven to be correct so far: the Veteran twist, StarSoar's secret, and this partner elimination.
	*goto precogtip

*label precogtip
Seeing how everything has now played out, does this change or confirm what you believe about The Great Loa's Powers?

*choice	
	*if (loabeliever) #I was right to believe in Loa Shift.
		*achieve sameloa
		*set rlshp_shift %+20

		The Great Loa's advice has always been spot-on, so until you see proof otherwise, you're smart to trust her visions.
		*goto suspenstime
	*if (loabeliever) #Actually, now it seems more like Loa is using the extensive connections from her healing exploits to gather information and pass it off as precognitive visions. 
		*set loabeliever false
		*set loaskeptic true
		*achieve switchloa
		*set rlshp_shift %-15

		All of what Loa Shift has predicted so far is just information that could be obtained by anyone with the right resources—and given her position, you know Loa Shift doesn't lack for resources. You'd be foolish to keep believing Loa Shift is anything other than a mob boss in the guise of a benevolent spiritual healer. You see that clearly, for better or worse.
		*goto suspenstime
	*if (loaskeptic) #Perhaps I was wrong to doubt Loa Shift. Maybe she really can see parts of the future as well as heal others.
		*set loabeliever true
		*set loaskeptic false
		*achieve switchloa 
		*set rlshp_shift %+15

		The Great Loa's advice has always been spot-on, so as much as you want to be skeptical, it would be foolish to keep ignoring a truth proved right before your face over and over again.
		*goto suspenstime
	*if (loaskeptic) #All this does is prove that Loa's political reach is very far. She must have an inside track with someone on the production team.
		*achieve sameloa
		*set rlshp_shift %-20

		All of what Loa Shift has predicted so far is just information that could be obtained by anyone with the right resources—and given her position, you know Loa Shift doesn't lack for resources. You'd be foolish to believe that Loa Shift is anything other than a mob boss in the guise of a benevolent spiritual healer. Knowing that will give you an advantage…you hope.
		*goto suspenstime
	#I'll need to see proof that Loa can predict something truly unknowable before I believe in any precognative Power. That said, I do know that I can at least trust her tips now.
		*achieve sameloa
		*set loaskeptic false
		*set loabeliever false
		*set rlshp_shift %+10

		You're not sure if Loa Shift is a clever mob boss or a benevolent spiritual healer, but how she gets her information isn't as important as the fact that it's continually correct. At least for now.
		*goto suspenstime

*label suspenstime

This thought is eclipsed, however, by the nerves that immediately overtake you. Questions begin to race through your mind: Will you or StarSoar move on? Will you both get cut together? Which other Rookies are going to survive the elimination? When will you find out?

Your heart skips a beat as the holo-screen in front of you shifts displays, but it answers none of your questions. All it reveals is a bit of simple text, reading: 

[b]FIVE SPOTS REMAINING.[/b]

You sit staring at this image for what feels like hours before it finally shifts again to read…

*page_break

[b]FOUR SPOTS REMAINING.[/b]

Slugger.

The same questions fill your mind: who just took the third Rookie spot? Which partner was cut as a result? How much longer are you going to have to endure this?

*if (lb > 84)
	Not very long, you suddenly realize as your chair begins to swivel around and the hardshell hood begins to retract. All you can wonder now is: Will you emerge to good news…

	Or the unthinkable?

	*page_break
	*set legended +5
	*achieve highlbthree

	This question is also answered immediately, however, as your chair fully opens and you emerge to thunderous applause and cheering from the audience. That paired with a blinding white smile from Colton tells you all you need to know:

	You're the fourth Rookie to advance to the Live Finals.

	Your first thought is: thank slugger, JK is going to get her second treatment from Loa Shift. You did it. You made the Final 14.

	Though this bleeds immediately into your second thought: for you to advance, StarSoar has been eliminated. And that's probably largely because of what you did tonight—you must have tipped the scales in your favor by revealing what you did.

	You look across the stage and see that StarSoar's still-hooded chair is retreating backstage automatically. You can only imagine the message of failure displayed across his screen inside that dreaded chair. Thinking about it makes your stomach flip uncomfortably.
	*goto endofceremony
*else
	*goto cercontinues

*label cercontinues

Time seems to blur together endlessly from then on, just an indiscernible jumble of nerves punctuated by numbers counting down. 

[b]THREE SPOTS.[/b]

*page_break

[b]TWO SPOTS.[/b]

*page_break

[b]ONE SPOT.[/b]

You stare at this last number and feel your whole body go numb. What are you going to do if you don't take that last spot?

What is JK going to do?

*page_break

You realize the wait is finally over as your chair begins to swivel around and the hardshell hood starts to retract. All you can wonder now is: Will you emerge to good news…

Or the unthinkable?

Does this mean you beat StarSoar? Does it mean you're going to watch StarSoar advance? Or are you both getting cut, given what happened back at the Final Selection party?

Did you make a terrible mistake?

*page_break

*if (ssprove) or (ssmorestory)
	*if (lb > 74) or (societal > 64)
		These questions are answered immediately, however, as your chair fully opens and you emerge to thunderous applause and cheering from the audience. That paired with a blinding white smile from Colton tells you all you need to know:

		You're the last Rookie to advance to the Live Finals.

		Your first thought is: thank slugger, JK is going to get her second treatment from Loa Shift. You did it. You made the Final 14.

		Though this bleeds immediately into your second thought: StarSoar has been eliminated. 

		"While we wish to offer you congratulations, ${codenamed}," The Diva's voice suddenly rings out, piercing through your thoughts, "we also wish to offer you some advice. This final spot was indeed down to you and StarSoar, and to be truthful, it was meant to go to StarSoar.

		"However, the Judges Panel learned some hard truths about StarSoar prior to tonight's episode—truths we had to share with the audience about his expulsion from the NASA Powered Cadet Program."

		*page_break
		*set legended +5
		*achieve lbprovethree

		Hearing The Diva's words, you feel your joy shrivel into a hard point. StarSoar's truth has been outed after all. Your mind immediately turns to The Great Loa, realizing that her third and final piece of information was also correct. You can't help but wonder if she somehow had something to do with the revelation of StarSoar's secret, but then you rethink this—it's not her style to interfere with matters directly, you've seen that already. 

		There are a thousand other ways the Judges and producers could have found out the truth about StarSoar over the last two months, or even earlier. Whatever the case, it is still extremely sad that they decided to reveal it in this way.

		"We cannot have StarSoar featured in the Live Finals, knowing what we do now about the voices he claims to hear," The Diva continues. "His loss is your gain tonight, ${codenamed}. But just barely. In the future, we expect you to earn your spot."

		The Diva's deep, dark eyes seem to cut you to ribbons from across the stage. Something tells you that if this decision were The Diva's alone, you wouldn't be standing here right now.

		*page_break

		But you can't find it in you to care, at the moment. No matter what anyone thinks, you took your fate into your own hands tonight and stood up for the right thing. You shudder to think what would have happened if you had sold out StarSoar yourself. 

		Whatever The Diva says, your Leaderboard was still strong enough to beat out the remaining two Rookies—the Semi-Final pairing that has also now been eliminated. You're proud of what you've done, even if you couldn't save both you and StarSoar in the end.

		You look across the stage and see that StarSoar's still-hooded chair is retreating backstage automatically. You can only imagine the message of failure displayed across his screen inside that dreaded chair. Thinking about it makes your stomach flip uncomfortably.
		*goto endofceremony
	*else
		These questions are answered immediately, however, as your chair fully opens and you emerge to find yourself backstage staring at a sad-looking producer, along with The Hero Project's appointed therapist and a pair of camera orbs.

		The terrible truth then sinks in: you've been eliminated.

		Once again, questions invade your frozen mind: Did you do the wrong thing, choosing to protect StarSoar? Did he get cut too, or move on instead of you? Were you wrong to ever doubt Loa Shift? What is going to happen to JK now?

		How could you have failed her?

		*page_break
		*achieve lbloserthree

		Then a new realization quakes you: you stood up and did what you believed was the right thing. And you're getting punished for that? It's slugging crap.

		Unfortunately, doing the right thing isn't always easy—sometimes it requires you to be better and stronger than everyone else. Maybe if you had a higher Leaderboard score or had a more societal focus, deciding to go against Loa Shift's explicit advice would have worked out more favorably…

		As this horrible reality settles, all you can think is: If you could go back and do it all again, would you do things differently?

		Would you take the chance to do so, if you could?

		*choice
			#Return to the beginning of the evening to see if I can save myself. (Legend Cost 20)
				Faced with this fate, you realize you'd do anything to save JK—perhaps even the unthinkable?

				You know now that you have to do something different to reveal the truth about StarSoar, otherwise you'll just end up right back here. So how will you handle the StarSoar situation differently, given this second chance? 

				You're about to find out.

				*set elimthree true
				*set legended -20
				*set ssprove false
				*set ssmorestory false
				*set sscrush false
				*set societal %-30
				*set rlshp_jk %-30
				*set rlshp_starsoar %-30
				*set rlshp_shift %+30
				*set upa -10
				*set lb +10
				*set legended -3
				*set respected %-20
				*set rlshp_eps %-15
				*set rlshp_rookies %-15
				*set public 50
				*page_break
				*goto ssinterruptreal
			#Restart The Hero Project from the beginning. I know if I achieve a higher Semi-Finals Leaderboard score or have a more societal focus, I can protect StarSoar and survive the elimination, too.
				You're going to find a way, no matter how many times it takes you.

				Better luck next time, ${codenamed}!
				*ending
*else
	These questions are answered immediately, however, as your chair fully opens and you emerge to thunderous applause and cheering from the audience. That paired with a blinding white smile from Colton tells you all you need to know:

	You're the last Rookie to advance to the Live Finals.

	Thank slugger, JK is going to get her second treatment from Loa Shift. You did it. You made the Final 14.

	Though this bleeds immediately into your second thought: StarSoar has been eliminated. 

	"While we wish to offer you congratulations, ${codenamed}," The Diva's voice suddenly rings out, piercing through your thoughts, "we also wish to offer you some advice. This final spot was indeed down to you and StarSoar, and to be truthful, it was meant to go to StarSoar. However, what you revealed tonight about him turned the tables."

	*page_break
	*set legended +1
	*achieve lowlbthree

	Hearing The Diva's words, you have no idea whether to feel great or terrible about them.

	"We cannot have StarSoar featured in the Live Finals, knowing what we do now," The Diva continues. "Your actions shifted the Leaderboard in your favor tonight, ${codenamed}. But just barely. In the future, we expect you to earn your spot more…honorably."

	The Diva's deep, dark eyes seem to cut you to ribbons from across the stage. Something tells you that if this decision were The Diva's alone, you wouldn't be standing here right now.

	But you can't find it in you to feel anything other than relieved, at the moment. No matter what anyone thinks, you took your fate into your own hands tonight and changed the outcome in your favor. You shudder to think about what would have happened tonight if Loa Shift had not armed you with the truth.

	You look across the stage and see StarSoar's still-hooded chair retreating backstage automatically. You can only imagine the message of failure displayed across his screen inside that dreaded chair. Thinking about it makes your stomach flip uncomfortably.
	*goto endofceremony

*label endofceremony
*page_break

Once StarSoar's chair disappears backstage, you wonder when you'll get to see him again. Then you remember that you won't be allowed any contact with him while you're on The Hero Project—once someone is eliminated, they're gone for good… 

At least until you're eliminated as well.

You consider saying something onstage here and now to address StarSoar's elimination, but Colton seems to want to usher you backstage already. Besides, 
*if (sspublic) or (ssblackmail)
	even if you could say something, only the absolute truth about JK and Loa Shift would change anything. Since you cannot reveal that particular truth, StarSoar is going to leave the show hating you anyway, so why insult him further with empty words that will only serve to make yourself feel better?

	You only hope that you have the chance to make it up to StarSoar someday.

	*page_break
	*achieve ssendhate
	*goto threeeend
*elseif sswarn
	even if you could say something, only the absolute truth about JK and Loa Shift would change anything. StarSoar will leave the show feeling terrible about how you confronted him, even if you never meant to reveal his secret. Why insult him further with empty words that will only serve to make yourself feel better?

	You only hope that you have the chance to make it up to StarSoar someday.

	*page_break
	*achieve ssendhate
	*goto threeeend
*elseif sscrush
	professing any potential feelings for StarSoar this way would only cheapen them and seem like some kind of attention grab. When you tell StarSoar about any feelings you may or may not have, you want to make sure it's reality—not reality show.

	You wish you could say something about the way The Hero Project just outed StarSoar, but until you know all the facts of how it went down, you had better keep quiet. The last thing you'd want to do is reveal something the Judges somehow didn't. 

	You only hope that you have the chance to make it up to StarSoar someday.

	*page_break
	*achieve ssendhappy
	*goto threeeend
*else
	until you know all the facts of how it went down, you had better keep quiet. The last thing you'd want to do is reveal something the Judges somehow didn't. 

	You only hope that you have the chance to make it up to StarSoar someday. At the very least, you know he left the show on good terms with you—and you avoided having to tell him, at least for a little while, that you don't return his feelings.

	*page_break
	*achieve ssendhappy
	*goto threeeend

*label threeeend
*set lb 0

As you turn to walk backstage, the reality sets in: now that you've made it, your whole life is about to change. Which also means that you're about to spend all of your time secluded and scheduled, interacting with only the production team and six other Rookies: 

Ignite, Crystalline, and the four others who will advance alongside you.

You wonder who those other four might be. You certainly know who you'd like them to be, and the Rookie who currently tops your wish list is:

*choice
	#Transfer.
		Which means that Nitewerq
		*goto findoutseeonenough
	#Nitewerq.
		Which means that Transfer
		*goto findoutseeonenough
	#Tarsiero.
		Which means that Velocityl
		*goto findoutseeonenough
	#Velocityl.
		Which means that Tarsiero
		*goto findoutseeonenough
	#Splint.
		Which means that O'Connell
		*goto findoutseeonenough
	#O'Connell.
		Which means that Splint
		*goto findoutseeonenough
	#Griffin.
		Which means that Exile
		*goto findoutseeonenough
	#Exile.
		Which means that Griffin
		*goto findoutseeonenough
	#Miss Boss.
		Which means that her best friend and heroic partner, Reigna,
		*goto findoutseeonenough
	#Reigna.
		Which means that her best friend and heroic partner, Miss Boss,
		*goto findoutseeonenough

*label findoutseeonenough
would be eliminated. You suppose it's useless to guess at this, though, since you'll find out soon enough.

Besides, in all the craziness now swirling around you backstage, one consideration seems to dominate all of the others:

What the slugger did you just get yourself into?

*achieve lvfourteen
*finish INTERLUDE ONE: WEAVING

*label trial_end
*check_purchase adfree
*if choice_purchased_adfree or not(choice_purchase_supported)
	*label purchased
	*return
Remember earlier how we told you that the first four chapters are available for free? This is the end of the free content.

[i]To find out what happens next, please purchase the remaining chapters.[/i]

*purchase_discount adfree 2019-07-09 $4.99 $2.99 purchased
*abort
