*comment é x

*image chap5.png center Chapter Five: Animaul

You are one. You are all. You are the hivemind. You are in charge, and your team is depending on you.

As the Rookies rush away from your command position, you close your eyes and feel your thoughts touch theirs, connecting in a circular honeycomb woven together. Your bloated bee body, with its flimsy wings and fatal stinger, has sidelined you from this fight. Luckily you have a different role to fill in this mission: leader. 

The role is a perfect fit for you today, thanks to your newly acquired eusocial hivemind connection and your experience with Ani-abilities. You pay attention as the impending battle unfolds in your hivemind like a tabletop game, a mental chessboard with shifting pawns. As you survey the scene, MeChip Prodigal also springs into coordinated action.

"Honeybee baby, best of luck! Remember, if you need extra help, you can always activate my Warning System functions."

MeChip Prodigal has been trying to talk you into one of the most valuable MeChip upgrades, the MeChip Warning System 9.0, which will enable MeChip Prodigal to inform you of strategic advantages, help you make efficient and consistent decisions, and warn you if you're about to make a decision with a high level of risk. You knew it would come in handy keeping you alive in dangerous situations just like this one, so you decided to…

*check_purchase warningsysnine
*if choice_purchase_supported
	*if choice_purchased_warningsysnine
		[i]You've paid to unlock Prodigal's MeChip Warning System with an in-app purchase.[/i]
		*choice
			#Unlock Prodigal's MeChip Warning System again, at no additional charge.
				*label purchased
				*set warningsysnine true
				*achieve achievethewar

				"You won't regret it, chicken!" MeChip Prodigal says, turning her hands into mini-canons while she performs a deadly chicken dance.
				*goto primalprayer
			#Hold off for now.
				*label noWarningSys
				"Cluckedy-cluck, chicken, I understand," MeChip Prodigal sighs. "The option to upgrade will remain in your Home Menu though, so go there to activate at any time if you're feeling frisky!"
				*goto primalprayer
	*else
		[i]Prodigal's MeChip warning system is available as an in-app purchase.[/i]

		*purchase warningsysnine $0.99 purchased
		*page_break No, Thanks
		*goto noWarningSys
*else
	[i]Prodigal's MeChip warning system is available as an in-app purchase.[/i]

	*choice
		*selectable_if (false) #Purchase Prodigal's MeChip Warning System.
			*bug
		#Hold off for now.
			*goto noWarningSys

*label primalprayer

Ignite and Crystalline are the first Rookies to come up against their designated foe, commanding your initial attention. You've been sequestered at The Hero Project compound for a week, since the Final Selection Ceremony, and have had limited time to interact with the other Rookies. However, everyone still knows that Crystalline and Ignite have become an official showmance couple, which is why they've also been paired together for this mission. They currently face The Prayer, a praying mantis Ani-hybrid who is wicked fast—so fast that she is on Ignite and Crystalline before anyone can get their bearings, including you.

Thankfully these two heroes are trained to react quickly: Crystalline pulls a precharged shield crystal out of her silver utility belt and throws it to the ground, generating a hard-light force field that blocks The Prayer's spiked raptorial foreleg jabs. Behind the yellowish field, Ignite waves his orange-gloved hands at the ground and causes a localized earthquake, which knocks The Prayer back on her hind legs.

While this budding couple is clearly quite capable, it's your job to inform them how to take down The Prayer as quickly and efficiently as possible.

*page_break

Your primary concern during this mission is to act as a superb leader to accrue Leaderboard points. While you don't have to worry about group politics and dynamics fully yet, you do know that you also have to start deciding how you want to play this game. Your advice and commands to the Rookies should be tempered by whatever goal you're trying to achieve in the long run, as always. 

So do you want to make sure you remain allies with everyone? Or do you want to favor certain Rookies and distance yourself from others to build stronger bonds? Do you want to instill fear and respect in everyone as a solo threat? Or should you genuinely focus on what's best for the mission, as a hero?

*if warningsysnine
	"The Prayer is a fast, deadly fighter," MeChip Prodigal chimes in, operating on her newly activated Warning System protocols. "She has compound vision to see moves coming, camouflage wings to shift in and out of sight, agility-hopping, and indestructible armor plating. So Crystalline and Ignite should most definitely not engage hand to hand."
	*goto prayertime
*else
	The Prayer is a fast, deadly fighter aided by her praying-mantis abilities: she has compound vision to see moves coming, camouflage wings to shift in and out of sight, agility-hopping, and indestructible armor plating. No matter how good Crystalline and Ignite are, you know they probably shouldn't engage The Prayer in close-range hand-to-hand combat.

	You deduce this all yourself from your Ani-experience, but you wonder if MeChip Prodigal's Warning System would pick up extra things you've missed. It doesn't matter this time, anyway, because you'll have to do without for now.
	*goto prayertime

*label prayertime

Crystalline and Ignite are about to engage in a close-range fight, which you know won't work in their favor. So how do you advise them?

*set lb +15
*set power -5
*choice
	#Let the duo engage in a close-range fight for a second, then advise them to pull back and fight long-range. This will make me look great and dent their Leaderboard scores.
		*set rlshp_crystalline %-25
		*set loyalgmbt +1
		*set solostar +1

		Once Crystalline's shield dissipates, Ignite tumbles forward to engage The Prayer. But before he can even roll to his feet, The Prayer bats him away with her raptorial legs and in one fluid motion rounds on Crystalline with a leaping kick.

		"Fall back immediately!" you hive-scream. "Do not fight directly, I repeat, fall back for long-range attacks!"

		On command, Crystalline detonates a flash-bang crystal to disorient The Prayer and jumps back to join Ignite. Your eusocial connection lets you feel their frustration over this delayed order from you, but you choose to ignore it.
		*goto fallbackci
	#Order the duo to fall back immediately and fight long-range, to make sure the outcome is most positive for everyone. 
		*set rlshp_crystalline %+15
		*set truehero +1
		*set manipulater +1

		"Fall back immediately!" you hive-scream. "Do not fight directly, I repeat, fall back for long-range attacks!"

		"Affirmative," Ignite responds, as Crystalline immediately detonates a flash-bang crystal to disorient The Prayer. As they prepare to fall back, you can feel their thankful compliance through your eusocial connection.
		*goto fallbackci
	#Recommend that the duo fall back, but don't buzz orders. You want to indicate that you trust them to fight intelligently with your assistance.
		*set rlshp_crystalline %+25
		*set floating +1
		*set loyalcit +1

		"The Prayer is incredibly fast," you hive-scream. "I think you'd do best falling back for long-range attacks, what do you think?"

		"Affirmative," Ignite responds, while Crystalline detonates a flash-bang crystal to disorient The Prayer. As they prepare to fall back, you can feel their trust through your eusocial connection.
		*goto fallbackci

*label fallbackci
To gain some further distance, Crystalline backflips away in an impressive gymnastic display, while Ignite rumbles the earth into a rocky platform to ride after her.

Once they've gained enough distance, you recall your own experience as a praying-mantis-hybrid. Your armor was pretty thick, but you remained vulnerable in the separations between your plates, where your human parts were exposed. Knowing this, how should you advise Crystalline and Ignite to attack?

*if warningsysnine
	"Oh waspy one, you have high rates of success no matter which option you choose here," MeChip Prodigal kicks in, operating once again on her Warning System protocols. "Though if I were you, I'd keep your Offensive & Defensive and Physical & Intangible prowess in mind when advising."

*set power -5
*choice
	#Have Crystalline and Ignite double down with crystal energy bombs and plasma fire-blast attacks.
		*set defensive %-20
		*set physical %-20

		Going on the offensive, Crystalline and Ignite utilize their Intangible Powers in tandem, launching a barrage. Suddenly The Prayer is engulfed in a storm of exploding pink crystals skillfully thrown by Crystalline, while the rest of her armor is scorched by blasts of fire shot from Ignite's fists. The combined effect fries the skin between the plates of The Prayer's hard shell, instantly knocking her out.
		*goto prayerdown
	#Have Crystalline and Ignite double down with dagger crystals and seismic-punch attacks.
		*set defensive %-20
		*set physical %+20

		Going on the offensive, Crystalline and Ignite utilize their Physical Powers in tandem, launching a barrage at The Prayer. Crystalline's skillfully thrown clear dagger crystals pierce the soft spots between the plates of The Prayer's armor, rendering her immobile. Then, while he has the chance, Ignite smashes his fists into the ground and sends a devastating ripple of seismic aftershocks at The Prayer. The combined effect is more than enough to stun The Prayer into submission.
		*goto prayerdown
	#Have Crystalline run a diversion with flash crystals so that Ignite can strike with long-range magma-fountain bursts.
		*set defensive %+20
		*set physical %-20
		
		Keeping a defensive distance, Crystalline and Ignite utilize their Intangible Powers in tandem to set The Prayer up and knock her down. Crystalline distracts The Prayer by tossing several strobe-light exploding crystals into the air, allowing Ignite to wave his hands and cause several magma fountains to erupt around The Prayer. The fiery magma scorches The Prayer's armor and fries the skin between the plates of her shell, instantly knocking her out.
		*goto prayerdown
	#Have Ignite run a diversion by erupting a rock wall so that Crystalline can slam The Prayer into it with concussive-force crystals.
		*set defensive %+20
		*set physical %+20

		Keeping a defensive distance, Crystalline and Ignite utilize their Physical Powers in tandem to set The Prayer up and knock her down. Ignite distracts The Prayer by raising a massive, jagged rock wall into the air behind her with a simple wave of his hand. This then allows Crystalline to skillfully throw several clear concussive crystals. The Prayer is fast enough to dodge the direct hits, but the concussive-force explosions of the near-miss crystals still send The Prayer reeling into the hard rock wall, knocking her out.
		*goto prayerdown

*label prayerdown
*set lb +5

You're not sure which impresses you more, the seemingly limitless applications of Crystalline's crystal constructs, or the earth-shattering levels of Power at Ignite's command. Once The Prayer is down, Crystalline and Ignite high-five to celebrate, posing for the camera orbs.

"You're on fire, Iggy," Crystalline jokes.

"That's crystal clear, Crys," Ignite forces out through his teeth—Crystalline must have put him up to that little exchange earlier. Standing side by side, this couple couldn't look more different: their costume colors, height, and skin colors are all at odds as opposites, but somehow they still look like they belong together.

*page_break

Before you can congratulate Crystalline and Ignite, you hear Lyra speaking in your ear through the comm channel from mission control, a sound that is much louder and more intrusive than your hivemind connection.

"Well done, ${codenamed}," Lyra says. "The others are about to come up against the rest of The Primals—are you sure you can handle coordinating their fights simultaneously?"

"Not if you keep distracting me," you buzz-speak, refocusing as you close your eyes and try to drown out the burst of noise. You don't mean to be short with Lyra, but this mission has you on edge, for many reasons….

Reason number one is that this is your very first Hero Project Live Finals mission in the real world. Which means it's also your first heroic mission, period. Reason number two is that you're fighting against a deadly gathering of Ani-gang Generals, which is not only terrifying, but also poses quite a few ethical questions for you as an Ani-Powered. 

*page_break
*set smytherstructure true

Lyra briefed you on The InfraCircle, and you've reviewed the overall structure in your Stats Screen. Unfortunately, The DRPR has no leads on Scoundrel's Strike Squad or Culic's base hidden in the Big Sur wasteland (which Mechip Prodigal was very quick to remind you she created, back in her more villainous days). However, a DRPR undercover agent was able to learn the details of an Ani-gang summit arranged by Smyther, so your briefing focused mostly on that.

Smyther has been able to finance the InfraCircle's entire operation by re-forming his infamous Ani-gangs in New Fringe, an area of MC just north of the Eastern Fringes and east of Dockerbay. Smyther decided to simplify the organization, so he is gathering his key generals at his newly acquired Smyther Manor. 

Details on this new organization have been loaded to your Stats Screen if you're interested, but all you need to know is this: there's heavy security in place for this summit, after none other than Prodigal crashed Smyther's last summit and wiped out most of his original Generals. The security forces for this summit include not just a deadly gathering of Ani-Generals, but also Smyther's elite Ani-Powered defense unit, the Primals, whom the Rookies have been tasked with taking down. 

You've already realized that for a non-Ani-Powered, Smyther certainly does keep a small army of Ani-Powereds at his disposal. Since his rise as an Ani-gang boss, some Ani-Powereds see Smyther as an advocate empowering the community, while others view him as a criminal exploiting your societal disadvantages.

You've barely had time to process your position on Smyther or the InfraCircle, but so far:

*choice
	#I feel like I'm on the wrong side of this battle. Honestly, I agree with what I've heard of the InfraCircle's agenda and methods.
		*set traditional %-15
		*set respected %-15

		Underrepresented Powereds like the Animalistic need a voice and a space in society. You believe you're only going to get it if you take it by force, like the InfraCircle mean to. Unfortunately, today you don't have much of a choice in this matter—but you hope that will change sometime very soon.
		*goto thirdreas
	#I believe that no cause justifies criminal activity. Plus, I've seen the negative effects of the re-formed Ani-gangs in Dockerbay firsthand.
		*set traditional %+15
		*set respected %+15

		Underrepresented Powereds like the Animalistic need a voice and a space in society, but not in ways that make the world worse for everyone else.
		*goto thirdreas
	#I don't want to be seen fighting other Ani-Powereds; that just feeds into divisive Ani-stereotypes. I'm also intrigued by the InfraCircle's ideas, if not their criminal methods.
		*set traditional %-15
		*set respected %+15

		Underrepresented Powereds like the Animalistic need a voice and a space in society, but you believe you're only going to get it if you stand united. You want to represent that unity, not pit yourself against other Underrepresented Powereds. Unfortunately, today you don't have much of a choice in this matter, but you hope that might change sometime very soon.
		*goto thirdreas
	#I'm happy to be shutting down Ani-cells that give the rest of us Ani-Powereds a bad name. I want to be a symbol that strikes fear into the heart of Ani-idiots like these.
		*set traditional %+15
		*set respected %-15

		Underrepresented Powereds like the Animalistic need a voice and a space in society, but not in ways that make the world worse for everyone else. You've got a zero-tolerance policy when it comes to illegal Ani-activity.
		*goto thirdreas

*label thirdreas

This brings you to the third and final reason to be nervous: you're the sole leader of the Rookie squad storming the rear entrance to Smyther Manor, racing against the still-secret Veteran squad. Being assigned this leadership role means you're in a high-risk, high-reward, and politically precarious situation with a group of Rookies you've only just met.

You know you can gain allies or make enemies based on how you behave, just as you're doing with Ignite and Crystalline. You may have successfully navigated their matchup, but now you need to handle three more Rookie battles coming up against The Primals. These battles will happen simultaneously, but you can handle them all thanks to your split hivemind focus.

"Queen Bee, full Rookie rundowns will be loaded to your Stats Screen as they come across your battle-plate," MeChip Prodigal reminds you. "You should pay special attention to the Powers sections in order to best advise each Rookie when the time comes!"

Which fight to handle in what order is up to you, but you know that success in these upcoming battles will determine your own Leaderboard score for this mission. Your life in the competition—and, as always, JK's life—depends on how you perform here. You take a second to touch your locket pocket to remember this, before the chaos continues.

*label battleops
*choice
	*disable_reuse #Battle A.
		*goto battleone
	*disable_reuse #Battle B.
		*goto battletwo
	*disable_reuse #Battle C.
		*goto battlethree
	*selectable_if (((showtransfer) and (showgriffin)) and (showtarsiero)) #Move on from the initial Primal Battles.
		*goto moveonprimal

*label battleone
*set showtransfer true
*set transfernameon true

You shift part of your split focus to Battle A, where you find none other than…

Transfer, awaiting your orders in full vampire form.

Transfer advancing meant that hir partner Nitewerq was cut, an outcome that didn't seem to bother the surly drag queen. Instead, Transfer was the one who seemed shocked to be advancing, given hir relatively minimal show edit. Perhaps this is also why you barely got to see hir in the Sequester House. 

*if (sspublic) or (ssblackmail)
	However, you're pretty sure Transfer was trying to keep hir distance from you after seeing what you did to StarSoar in the Final Selection. This incident became the central focus of the episode when it aired last week, at least the parts you were allowed to watch. Transfer wasn't the only one who seemed wary of you—so did Ignite and Crystalline, and you don't even want to think about how upset JK still is with you.

	You already know you're going to have to start deciding now if you care about doing damage control, or if you're going to let this intimidating portrayal stand.
	*goto adivsci
*elseif sswarn
	However, you're pretty sure Transfer was trying to keep hir distance from you after seeing what happened with StarSoar in the Final Selection. This incident became the central focus of the episode when it aired last week, at least the parts you were allowed to watch. It wasn't made clear at all that you attempted to have this conversation with StarSoar in private, unfortunately. As a result, Transfer seemed wary of you and ze wasn't the only one—so did Ignite and Crystalline. But no one is as upset about what happened to StarSoar as JK.

	You already know you're going to have to start deciding now if you care about doing damage control, or if you're going to let this intimidating portrayal stand.
	*goto adivsci
*else
	*goto adivsci

*label adivsci
*page_break

However, your first priority is to make sure that Transfer beats hir Primal opponent, Pumala. You watch as Pumala leaps around Transfer with his catlike reflexes, toying with hir like prey. Transfer stands hir ground in response, hir pale fists clenched and hir gleaming fangs bared. Pumala may be fast, strong, and possess deadly claws, but Transfer matches all those strengths pretty evenly in hir vampire form.

Which means this is going to be a straight-up brawl.
*if warningsysnine

	"Bee-bop, make sure to focus on the balance between Powers and Fighting in this matchup," MeChip Prodigal advises. "Keep in mind this is the only Battle Stat that's best kept as close to the middle as possible. Make sure to constantly switch between Powers and Fighting, to keep both sharp. You don't want to favor one too much, unlike the other Stats, which work better the stronger you make them. Mmm'kay I say?"
	*goto pumalalala
*else
	You should probably focus on balancing Fighting & Powers, keeping the Stat steady in the middle to keep both sets of skills sharp.
	*goto pumalalala

*label pumalalala

While Pumala prances, he notices the nearest camera orb and pauses to say: "When you're ready come and get it." He then performs a graceful backflip before adding a pseudo-seductive meowing roar.

"Oh, please just shut up," Transfer sighs, just before ze lurches at Pumala unexpectedly.

*set power -5
*choice
	#Order Transfer to use hir hypnotizing Powers to immobilize Pumala and then use hir vampire bite to drain him into submission.
		*set rlshp_transfer %-15
		*set fighting %-15

		Transfer doesn't say anything in response to your order, but you can tell via your eusocial connection that ze is not necessarily appreciative of your commanding tone. Still, Transfer twists to execute your order as ze soars through the air.

		*label hypnopower
		*if (fighting > 39) and (fighting < 61)
			*set lb +20
			*set legended +1
			*achieve fourfightpowerbal

			Transfer lands in front of Pumala with one leg outstretched and one hand on the ground. Pumala is ready to pounce, but before he can, he catches the intense red glare in Transfer's eyes. Pumala suddenly sways on his feet, caught in Transfer's hypnotizing gaze.

			*label imeedhyp

			Transfer then tumbles forward and rolls behind Pumala. Just as the hypno-stare seems to wear off, Transfer wraps hir arms around Pumala's chest and plunges hir fangs deep into his neck. Pumala struggles against Transfer's firm vampire grip, but it's only a matter of seconds before Pumala's eyes roll into the back of his head.

			Once Pumala drops to the ground, Transfer turns away from the nearest camera orb and wipes hir face, smearing red across the black sleeve of hir costume. Feeling a bit queasy at the grisly sight, you send Transfer a quick congratulations before turning your attention back to the battlefield.
			*goto battleops
		*else
			*set lb +10
			
			Transfer lands in front of Pumala with one leg outstretched and one hand on the ground. Transfer then raises hir glowing red eyes to meet Pumala's, only to find he has pounced more quickly than Transfer anticipated. Transfer dodges with incredible speed, but Pumala still manages to catch Transfer with a claw-swipe that rips open hir upper arm.

			Diving away, Transfer gains some distance and turns back towards Pumala with such ferocity in hir eyes that Pumala can't help but match hir gaze. Before Pumala can move another inch, he suddenly sways on his feet, caught in Transfer's hypnotizing stare.
			*goto imeedhyp
	#Order Transfer to utilize hir enhanced speed and strength to fight Pumala hand to hand.
		*set rlshp_transfer %-15
		*set fighting %+15

		Transfer doesn't say anything in response to your order, but you can tell via your eusocial connection that ze is not necessarily appreciative of your commanding tone. Still, Transfer twists to execute your order as ze soars through the air.

		*label sspeedpower
		*if (fighting > 39) and (fighting < 61)
			*set lb +20
			*set legended +1
			*achieve fourfightpowerbal

			Transfer lands in front of Pumala with one leg outstretched and one hand on the ground. Pumala pounces at Transfer the moment ze does, but Transfer is ready for that. 
			*label speefist
			Ze spins around to avoid a deadly claw-swipe and swings hir clenched fist into the back of Pumala's skull. As Pumala is sent reeling forward, Transfer spins back impossibly fast and kicks hir boot up into Pumala's falling chin.

			The sound of Pumala's jaw cracking echoes across the lawn before he crumbles to the grass in a thudding heap. Feeling a bit queasy at the grisly sight, you send Transfer a quick congratulations before turning your attention back to the battlefield.
			*goto battleops
		*else
			*set lb +10

			Transfer lands in front of Pumala with one leg outstretched and one hand on the ground. Pumala pounces at Transfer the moment ze does, more quickly than Transfer must have anticipated. Transfer dodges with incredible speed, but Pumala still manages to catch Transfer with a clawed kick that rips open hir upper arm.

			Pumala then goes for another deadly clawed paw-swipe, but Transfer is ready for it.
			*goto speefist
	#Advise Transfer to use hir hypnotizing Powers to immobilize Pumala and then use hir vampire bite to drain him into submission.
		*set rlshp_transfer %+15
		*set fighting %-15

		Transfer doesn't say anything in response to your advice, but you can tell via your eusocial connection that ze is appreciative you didn't just bark orders at hir. Contented, Transfer twists to execute the advised maneuver as ze soars through the air.
		*goto hypnopower
	#Advise Transfer to utilize hir enhanced speed and strength to fight Pumala hand to hand.
		*set rlshp_transfer %+15
		*set fighting %+15

		Transfer doesn't say anything in response to your advice, but you can tell via your eusocial connection that ze is appreciative you didn't just bark orders at hir. Contented, Transfer twists to execute the advised maneuver as ze soars through the air.
		*goto sspeedpower

*label battletwo
*set griffinnameon true
*set showgriffin true
*set missbossnameon true
*set showmissboss true

You shift your focus to Battle B, where you find none other than…

Griffin and Miss Boss, posing together in all their spandex-and-leather-wrapped glory.

These two were the only "New Populars" to advance, which meant that Exile, Reigna, and O'Connell were eliminated. While there was tons of drama surrounding the split-up of best friends and heroic partners Miss Boss and Reigna, the real focus ended up falling on Exile, who claims he was eliminated because of some dispute between his corporate sponsor, YouPower Inc., and the MeChip Corporation. Naturally, The Hero Project has denied these allegations, but you've heard that Exile has managed to make a meal of his elimination in a tour of national exit interviews, nonetheless.

Despite these disruptions, Griffin and Miss Boss have stuck together like glue in the Sequester House. Everyone knows this is because Miss Boss's energy telekinesis requires a Power source, and without access to her usual partner Reigna's cascading energy, Griffin became the next best option.

Everyone also expected a potential romance to evolve between these two, but actually, both Griffin and Miss Boss seemed very flirty with you in your limited interactions, an experience you definitely are not accustomed to. 
*if (sspublic) or (ssblackmail)
	Apparently these two really loved your StarSoar move, claiming that they were happy to see someone "take a stand and play the game." 
	*goto alignwith
*elseif (sswarn)
	Apparently these two really loved your StarSoar move—they seemed to believe that you knew there would be cameras in the bathroom all along and that you made some brilliant game move to gain attention, despite your attempts to convince them otherwise.
	*goto alignwith
*else
	You can't tell if this flirtation is at all genuine, however, because you can tell that Miss Boss and Griffin both seem to be very eager to play this game hard. 
	*goto alignwith

*label alignwith

They've already indicated interest in aligning with you in the potential votes to come, but you haven't made a decision yet. You still have to discern if their enthusiasm for strategy and game-playing coincides with your own agenda.

*page_break

It appears this is a decision you'll have to make sooner than later, since Griffin was particularly miffed that you were "handed" the leadership role in this mission. Apparently Griffin felt entitled to this honor, given his "heroic seniority," as he passive-aggressively mentioned in the transport. You suppose that if you care at all, it will be best to tread carefully around his ego here.

Griffin and Miss Boss are now squaring off against their Primal opponent, an ostrich-hybrid Ani-Powered named Ostro. He fans his tailfeathers in an aggressive standoff display against Griffin, who charges blue energy blasts around his fists, and Miss Boss, who poses in a dramatic fighting stance.

"Your goose is about to be cooked," Griffin says, flashing a winning smile. Miss Boss seems to fight a grimace beside him, but she doesn't actually say anything. Instead, you can feel her straining to connect with Griffin's energy source for some telekinetic manipulation.

You know these two will stand there forever posturing for the camera orbs unless you say something, so you quickly strategize about how they should engage Ostro—who is both light on his feet and heavy on his wing-strength.

*if specialhint
	"${codenamed}, you've earned a special hint as a reward here," Lyra's voice suddenly rings through your comms.
	*if (rlshp_missboss > 50)
		"Let Griffin take the lead here; it'll be best for the mission and for both of your Leaderboard scores. Trust me on this one."

		*label notabsolutey

		You're not absolutely sure if you should trust Lyra, but she did say this was the special Viewer Reward you unlocked, so her advice has to be good. Plus, she has given you no reason not to trust her, yet.
		*goto alignwithout
	*else
		"Make sure you issue a firm direct order here; that'll be best for the mission and for both of your Leaderboard scores in the long run. Trust me on this one."
		*goto notabsolutey
*elseif warningsysnine
	"Focus on striking the right tone with these two," MeChip Prodigal advises. "They'll ignore you if you don't play this right and that'll just make everyone look bad. If you're on good terms, ease up. Otherwise, make sure they listen to you!"
	*goto alignwithout
*else
	So you should probably focus on making sure Griffin and Miss Boss respond well to your orders.
	*goto alignwithout

*label alignwithout
*set power -5
*choice
	#I need to earn their respect and make them listen to me, so I give Griffin and Miss Boss a direct order.
		"Your best strategy is to fake Ostro out, given his superspeed," you project in your most authoritative voice. "Griffin, fire a concussive-force blast directly at Ostro that'll get him dodging. Then Miss Boss, use your TK to redirect the blast to hit Ostro from behind. He won't see that coming."

		*if (rlshp_missboss < 50)
			*set lb +20
			*set legended +1
			*set rlshp_griffin %-15
			*set rlshp_missboss %-15

			"Perfect plan, ${codenamed}," Griffin responds. "I was just thinking that myself."

			With that slightly annoying comment cleared, Griffin raises his fists and fires off two near-clear beams of concussive force. The blasts rocket forward on a direct crash course with Ostro, and he prepares to dodge, until the blasts suddenly slow their progression and one sputters out entirely.

			Straining that chiseled face of his, Griffin pushes harder and re-speeds the remaining blast—but way too slowly to even come close to hitting Ostro, as he dodges with ease. The blast shoots by him in a wavy streak, which you know is fine, because that's when Miss Boss steps in. Twisting her fingers, Miss Boss redirects Griffin's concussive blast so that it suddenly curves and redoubles back towards Ostro.

			*page_break

			As Ostro leaps forward to attack Griffin with his girthy body, the blast connects with Ostro's back and sends him smashing into the ground in a heap of feathers and stringy limbs. 

			*label goodthinkinggrif

			"Nice work, faking Ostro out by making that blast lose Power," Miss Boss says, running beside Griffin. Griffin flashes her a big smile, but you can feel waves of relief radiating off of him. Maybe no one else can tell, but you know something just malfunctioned with his Powers—and that Miss Boss just covered for him.

			That's a consideration for another time, however, you think as you refocus on the other unfolding lawn battles.
			*goto battleops
		*else
			*set lb +10
			*set rlshp_griffin %-10
			*set rlshp_missboss %-10
			
			"I've got an even better plan to fake him out," Griffin responds, rolling forward towards Ostro. Instead of blasting him long-range the way you commanded, Griffin charges rings of concussive force around his fists. He then moves to fight Ostro at close range, swinging his encircled fists like bricks. You realize that he must want to show he can use his Powers in unexpected ways, to steal the spotlight.

			Unfortunately for Griffin, Ostro is far too fast and weaves around his blow with ease. Ostro takes off towards Miss Boss instead, hoping to catch her off guard—which he does.

			This is unfortunate for you too, since their defying your orders like this is bound to ding all three of your Leaderboard scores. Before you can intervene, however, Griffin finally follows some of your order and fires the concussive force energy in two strong beams—past Ostro and directly at Miss Boss.

			*label luckilymbses
			*page_break

			Luckily Miss Boss sees the blasts coming and prepares to redirect the energy into Ostro before he can reach her. The blasts rocket forward on a direct crash course, until they suddenly slow their progression and one sputters out entirely.

			Straining that chiseled face of his, Griffin pushes harder and re-speeds the remaining blast, which reaches a worried-looking Miss Boss just in time. As Ostro leaps forward to attack Miss Boss with his girthy body, the blast connects with Ostro's back and sends him smashing into the ground in a heap of feathers and stringy limbs.
			*goto goodthinkinggrif
	#Let Griffin and Miss Boss act on their own; tell them I trust them the most and need to focus my attention elsewhere.
		"I have a lot of battles on my plate right now, can I trust you two to handle Ostro on your own?"

		*if (rlshp_missboss > 50)
			*set lb +20
			*set legended +1
			*set rlshp_griffin %+15
			*set rlshp_missboss %+15
			
			"Of course you can!" Griffin responds cheerily. "Happy to do our part and take charge. I was just formulating a plan myself!"

			Griffin then rolls forward towards Ostro without hesitation, charging rings of concussive force around his fists. 
			*label brickfists
			Griffin then fights Ostro at close range, swinging his encircled fists like bricks. He must want to show he can use his Powers in unexpected ways, to steal the spotlight—and rack up Leaderboard points for himself.

			Unfortunately for him, Ostro is far too fast and weaves around Griffin's blows with ease. Ostro then takes off towards Miss Boss instead, hoping to catch her off guard—which he does.

			But that seems to be part of Griffin's plan, as he calmly fires the concussive force in two strong beams—past Ostro and directly at Miss Boss.
			*goto luckilymbses
		*else
			*set lb +10
			*set rlshp_griffin %+10
			*set rlshp_missboss %+10
			"Don't worry, ${codenamed}, I used to get overwhelmed when I first started leading, too," Griffin responds. "Happy to do our part and take charge. I was just formulating a plan myself!"

			Griffin then rolls forward towards Ostro without hesitation and you force yourself not to respond to his belittling comment. Instead, you watch as Griffin pops to his feet and charges rings of concussive force around his fists.
			*goto brickfists
	#Advise Griffin and Miss Boss on their strategic options, but let them decide the best course of action instead of ordering it.
		*set lb +10
		*set rlshp_griffin %+10
		*set rlshp_missboss %+10

		"Your best strategy is to fake out Ostro, given his superspeed," you start. "Griffin, what do you think about engaging Ostro with an energy beam near-miss, one that Miss Boss can redirect unexpectedly? What kind of energy and maneuvering do you think will work best?"

		"I'm very glad you asked," Griffin responds cheerily. "Happy to do our part and take charge. I was just formulating a plan myself!"

		Griffin then rolls forward towards Ostro without hesitation, charging rings of concussive force around his fists. 
		*goto brickfists


*label battlethree
*set tarsieronameon true
*set showtarsiero true

You shift your focus to Battle C, where you find none other than…

Tarsiero, his wide eyes staring down his opponent with an almost creepy intensity.

Tarsiero advancing was quite the shocking twist, especially because it came at the cost of the much-beloved Velocityl. Splint was also unfortunately eliminated, but rumor has it that the two ousted contestants have become a close pair on the exit-interview circuit, even drumming up talk of an official heroic partnership. Their time on The Hero Project may be over, but you have a feeling this isn't the last you'll see of Splint and Velocityl.

Despite Tarsiero's consistent attempts to engage in "#TarsieroTime" and "#AniBonding" with you in the Sequester House, you mostly tried to avoid him. Just because you're both Ani-Powered, everyone expects you to instantly get along. 
*if (minglemisfits = false)
	However, the only thing more jarring than Tarsiero's weird hashtag speak is the sour smell that always comes from his matted fur—something about the damp, unwashed smell makes you both queasy and uneasy. You know you should probably connect with other Ani-Powereds like Tarsiero more easily, but really you've always had trouble feeling comfortable around them—it just reminds you that you just don't fit in anywhere, especially in the one community that's supposed to be a source of support.

	*goto stilrelei
*else
	*goto stilrelei

*label stilrelei
You were a bit relieved to find you weren't the only one uncomfortable with Tarsiero's awkward interactions and dated attempts at catchphrases—the other Rookies seemed to steer clear of him as well.

At any rate, you felt slightly guilty about avoiding Tarsiero, since he was the only one who 
*if ((ssprove) or (ssmorestory)) or (sswarn)
	seemed uninterested in judging you or engaging in politics—he just seems genuinely happy to be here.
	*goto notinter
*else
	seemed not to care about everything that happened with StarSoar. He doesn't seem interested in judging you or engaging in politics—he just seems genuinely happy to be here. 
	*goto notinter

*label notinter
Which makes sense, since no one would ever have predicted he would make it this far.

*page_break

Right now you understand why he has, though, because you're watching Tarsiero face off fearlessly against BoaCon, an enormous boa-constrictor-hybrid Ani-Powered. Other furry prey Ani-Powereds would usually cower before BoaCon's might, but Tarsiero stands his ground. In fact, it's the first time since you've met Tarsiero that he doesn't seem anxious.

You know that BoaCon not only possesses incredible brute strength in her coiled torso and writhing limbs, but that she also has a wide array of Intangible Powers, including a flicking tongue that can smell prey and heat sensors that identify movement. All of this makes BoaCon a heavyweight brawler and an acutely aware fighter at the same time.

*if warningsysnine
	"Sweethornet, Tarsiero is going to have quite the time taking down BoaCon. Luckily his tarsier Powers match up against BoaCon's, though who'd a thunk it?" MeChip Prodigal muses. "Anyway, focus on utilizing your Defensive & Offensive prowess to make sure Tarsiero wins out against this particular predator."
*comment endif

Tarsiero's eyes remain fixed on BoaCon as she slithers through the grass, then follow her upwards as she stretches her long torso into a fully intimidating ten-foot height. "You look deliciousssssss," BoaCon hisses, looking eager to strike.

"And you look famished. Prepare to stay that way!" Tarsiero attempts to quip back, adding a feeble "#TarsieroTime" shout at the end.

*set power -5
*choice
	#Have Tarsiero climb the nearest tree with his clinging paws, high enough that when BoaCon follows, he can use his leaping ankles to make her fall to her doom.
		*set defensive %+15

		Tarsiero seems to register your command, and within the blink of an eye he is scrambling up the nearest tree with his gripping paws. 

		*if (defensive > 60)
			*set lb +20
			*set legended +1
			*set physical %+15
			*set rlshp_tarsiero %+10
			*achieve fourdefensivehigh
			*goto triumphtarsi
		*else
			*set lb +10
			*set physical %+5
			*set rlshp_tarsiero %-10
			*goto triumphtarsi
	#Have Tarsiero strike mercilessly with his superlong tail, wrapping it around BoaCon's human throat to strangle her into submission.
		*set defensive %-15

		Tarsiero seems to register your command, and within the blink of an eye he is spinning to strike with his ten-foot tail.

		*if (defensive < 40)
			*set lb +20
			*set legended +1
			*set physical %+15
			*set rlshp_tarsiero %+10
			*achieve fouroffensivehigh
			*goto triumphtarsi
		*else
			*set lb +10
			*set physical %+5
			*set rlshp_tarsiero %-10
			*goto triumphtarsi
	#Have Tarsiero use his enhanced hearing to predict BoaCon's movements and maneuver her into striking a tree trunk.
		*set defensive %+15

		Tarsiero seems to register your command, and within the blink of an eye he is flipping backwards towards the nearest tree, his round ears twitching madly.

		*if (defensive > 60)
			*set lb +20
			*set legended +1
			*set physical %-15
			*set rlshp_tarsiero %+10
			*achieve fourdefensivehigh
			*goto triumphtarsi
		*else
			*set lb +10
			*set physical %-5
			*set rlshp_tarsiero %-10
			*goto triumphtarsi
	#Have Tarsiero use his enhanced eyesight to pinpoint weak spots in BoaCon's body, then have him strike at them directly.
		*set defensive %-15

		Tarsiero seems to register your command, and within the blink of an eye he is dilating his pupils to see as sharply as possible.

		*if (defensive < 40)
			*set lb +20
			*set legended +1
			*set physical %-15
			*set rlshp_tarsiero %+10
			*achieve fouroffensivehigh
			*goto triumphtarsi
		*else
			*set lb +10
			*set physical %-5
			*set rlshp_tarsiero %-10
			*goto triumphtarsi

*label triumphtarsi

As he does, a wave of screeching feedback suddenly floods your senses, causing you to scream out in a buzzing cry. The pain of the feedback is so intense that it takes several seconds for the sharpness to recede into enough of a dull ache for you to reengage your eusocial hivemind connection to Tarsiero.

When you finally do, you find that Tarsiero is standing with his hands on his hips and his long tail waving defiantly behind him, striking a pose of heroic triumph. Below him lies BoaCon's limp, unconscious body.

*page_break

"${codenamed}, we did it! #AniPower! #TarsieroTime!" Tarsiero cries, tears of relief and pride brimming in his oversized eyes. 

You have no idea how Tarsiero managed to down BoaCon so quickly, but you are highly impressed that he did. 

You're also not sure why Tarsiero's fighting suddenly distorted your hivemind connection, but there are lots of things about your ever-changing Ani-Powers that don't always add up. You're used to them reacting oddly to certain Powered combinations, so you brush off this incident, along with Tarsiero's outdated hashtag-speak, knowing you have plenty of battle still left to fight.
*goto battleops

*label moveonprimal

With The Primals now fully downed, you temporarily disengage your hivemind connection just as Lyra begins to speak over the collective Rookie comms.

"That was incredibly fast! Well done, Rookies. You're cleared to enter the Manor, stat."

Hearing this, you roll forward from your command position in a fast-moving wheelchair—your bloated bee body and puny wings make it pretty impossible for you to move on your own. This isn't your first foray into debilitating Ani-Powers, but every time you have some, it serves as a potent reminder of what JK has to deal with every single day.

Joining the other Rookies, you all rush ahead as fast as you can move, because each one of you knows this isn't just a fight—it's a race, too. The still-secret Veteran team was tasked with clearing and entering through the front of the Manor, while you Rookies are to storm the back entrance. The overall objective is to detain the generals for arrest, and the first team to enter the Manor gets to engage the generals directly—racking up additional Leaderboard points, no doubt. The second team to enter will be tasked with guard duty and will most likely lose the mission.

You all know the stakes: the losing team will face a fourteenth-place Leaderboard elimination and a thirteenth-place Finalist vote, while the winning team will advance straight to the Final 12 mission. Everyone wants that assured safety, but as usual, the stakes feel even higher for you.

*page_break

After Loa Shift administered JK's second treatment successfully, she set your next goal: make it to the Final 12, where you will be given one last task to secure JK's third and final treatment. Complete this last, mysterious task and then your debt will be paid, so JK can be fully "healed and harmonized." However, if you get cut before the Final 12, JK will receive no further treatments and regress backwards over time, as if the healing had never even happened.

Obviously this is enough incentive for you to win this mission and advance directly to the Final 12, but you also don't want to consider the possibility of facing the Leaderboard elimination because this week's guest Judges happen to be Fistfull and Monk, the Millennial Group members you eliminated from the competition in the Semi-Finals. You're sure they won't be looking to do you any favors, so you have to be perfect. Right now your Leaderboard is ${lb},
*if (lb > 69)
	which means that so far you've been as close to perfect as you can manage.
	*goto catchape
*else
	which means that you have some serious catching up to do.
	*goto catchape

*label catchape

However, as you climb the Manor's back porch and run into the kitchen, you find a massive rhinoceros-hybrid knocked unconscious, his giant wrinkled chest heaving in shallow breaths. You immediately recognize him as Noc, The Primal's Infini-Class leader, who was guarding the front entrance with a hoard of Ani-gang minions. If Noc is laid out here, that must mean that the Veterans have already entered the Manor.

Slugger.

*page_break

Your first thought is: Did the Veterans only had to defeat one Primal? Noc may be their Infini Powered, heavy-hitting leader, but that still doesn't seem fair compared to the full team of Primals the Rookies had to battle in the backyard. Shelving your frustration for now, you focus on Lyra's voice as she delivers an update through the comms.

"Rookies, the Veterans have already engaged Smyther and his generals in the subbasement bunker below, but that doesn't mean you're out of this yet," Lyra says, not pausing for the series of groans and curses that come from the Rookies. "See that door in the corner of the kitchen? That's the subbasement bunker exit and we need you to guard it. If any generals attempt to escape, or if the Veterans fail for some reason, you're the final line of defense." 

The Rookies all eye each other warily—seven heroes placed on guard duty doesn't sound particularly action-packed—or Leaderboard-worthy. Griffin looks particularly annoyed and is about to speak up when Lyra issues another order.

"${codenamed}, we also need you to send a small group out to the front lawn to do recon," Lyra says. "Choose now."

[i]Slugger[/i], you think, as you realize what Lyra must be doing. 

*page_break

You're sure that whoever you send out on this recon mission will be likely to miss any potential action here and will be at a Leaderboard disadvantage should you face an elimination. Lyra must need some drama to air for the Rookies, and forcing you to choose favorites will only add fuel to whatever political fires might currently be burning. You're not sure whether Lyra's efforts will be enough to save the Rookies from losing, but you have to do your part to coordinate this next phase.

Before you can make a decision, Griffin steps in front of the group of Rookies. Then, before he can even speak, he is interrupted by Ignite, who steps forward ahead of him.

"I'll volunteer to perform the recon," Ignite says, his face set with a look of determination.

You're not sure whether Ignite is stepping up to be a martyr or to steal the spotlight, but either way, you can tell Griffin is clearly not pleased about it.  

Still, as team leader, you get to make the decision. So who are you going to send out, potentially to their doom?

*choice
	#Choose to keep the most experienced heroes here with me and send out the heroes with enhanced senses, because that's what's best for the mission.
		*set lb +10
		*set rlshp_griffin %+20
		*set rlshp_missboss %+20
		*set rlshp_tarsiero %-5
		*set rlshp_crystalline %+20
		*set rlshp_transfer %-20
		*set solostar +1
		*set truehero +1

		"Thanks for the offer, Ignite," you say. "However, I believe Transfer and Tarsiero are best suited for recon, given their enhanced senses. Ignite, Crystalline, Griffin, and Miss Boss, stay here with me to guard the exit."

		If Transfer or Tarsiero know they've been assigned cleanup duty, they don't show it as they take off through the kitchen towards the front of the house. Tarsiero even does a jaunty little flip as he swings out of the room.
		*goto lawntime
	#Keep Ignite, Crystalline, and Transfer here with me on guard duty, to favor them and widen subtle cracks already splitting the group.
		*set lb +10
		*set rlshp_griffin %-20
		*set rlshp_missboss %-20
		*set rlshp_tarsiero %-5
		*set rlshp_crystalline %+20
		*set rlshp_transfer %+20
		*set loyalcit +1
		*set manipulater +1

		"Thanks for the offer, Ignite," you say. "However, I believe Tarsiero is best suited for recon, given his enhanced senses. Griffin and Miss Boss, go with him as backup. Ignite, Crystalline, and Transfer will stay here with me to guard the exit."

		If Tarsiero knows he has been assigned cleanup duty, he doesn't show it as he takes off through the kitchen towards the front of the house, performing a jaunty little flip as he swings out of the room. Griffin and Miss Boss, on the other hand, are sure to send you looks of pure contempt before they turn to follow Tarsiero.

		They've clearly clocked the line you just drew in the sand, but once they've gone, you notice the smiles now showing up on Crystalline and Transfer's faces. Ignite, as usual, looks too serious and focused for any other emotions.
		*goto lawntime
	#Keep Griffin, Miss Boss, and Tarsiero here with me on guard duty, to favor them and widen subtle cracks already splitting the group.
		*set lb +10
		*set rlshp_griffin %+20
		*set rlshp_missboss %+20
		*set rlshp_tarsiero %+20
		*set rlshp_crystalline %-20
		*set rlshp_transfer %-20
		*set loyalgmbt +1
		*set manipulater +1

		"Thanks for the offer, Ignite," you say. "Crystalline will join you, along with Transfer, given hir enhanced senses. Griffin, Miss Boss, and Tarsiero will stay here with me to guard the exit."

		Ignite follows your order immediately, turning on his heels and running through the kitchen towards the front of the house. Crystalline and Transfer, on the other hand, are sure to send you looks of unhappiness before they turn to follow Ignite.

		They've clearly clocked the line you just drew in the sand, but once they've gone, you notice the smiles now showing up on Griffin and Miss Boss's faces. Tarsiero doesn't quite seem to understand what's going on, but he waves his tail happily nonetheless.
		*goto lawntime
	#Send Ignite and Griffin out on recon duty together to make the fewest disruptions for the team.
		*set lb +5
		*set rlshp_griffin %+15
		*set rlshp_missboss %+15
		*set rlshp_tarsiero %+15
		*set rlshp_crystalline %+15
		*set rlshp_transfer %+15
		*set floating +1
		*comment Floater has lower leaderboard, but is benefited balanced with generally stronger relationships across the board. These relationships/compromise comes at a price. The Private Stat is also lower Leaderboard generally, should have a benefit somewhere as well.

		"Thanks for the offer, Ignite," you say. "Griffin will join you for backup, since I think he was about to say the same thing. Transfer, Crystalline, Miss Boss, and Tarsiero will stay here with me to guard the exit."

		Ignite follows your order immediately, turning on his heels and running through the kitchen towards the front of the house. Griffin, happy to be singled out, also seems to ignore the potential negative consequences and smiles as he follows. Knowing Griffin, you're sure he'll find a way to steal the spotlight anyway, despite any potential disadvantage.

		Once they've gone, you also notice the faint traces of smiles on the rest of the Rookies' faces. Tarsiero doesn't seem to understand quite what's going on, but he waves his tail happily nonetheless. You've managed to make everyone happy, which means you also avoided any drama…though this may not be great for your Leaderboard score. You'll just have to wait and see.
		*goto lawntime

*label lawntime
*page_break
*set power -5

Now that the lawn squad has split off, you reestablish a hivemind connection among all of the Rookies. Once that's done, you turn to physically check the subbasement bunker entrance—and that's when you realize that the door has been pushed slightly ajar. 

You roll your wheelchair forward towards the door, finding it odd that you hear no sounds of battle raging from below. Could it somehow be soundproof down there? Or have the Veterans already finished taking down Smyther and all his generals? Could they really be that good?

But as you open the door wider and lean forward to peer down the staircase, your whole body freezes and the breath catches in your throat. 

*page_break

Splayed across the upper steps is the alligator-hybrid Ani-Powered general, Ali, lying in a pool of her own greenish-red blood. On the steps surrounding her are brittle shards of scales, which have somehow been scraped off of her skin in large swaths. She lies perfectly still while cradling something between her limp arms…

…and you nearly vomit when you realize it's her own severed tail.

A wave of panic and disgust courses through you as you realize there is no way the Veterans could have done this. Which means something terrible must be going on down there in the subbasement bunker.

"Lyra?" you speak out loud into your comm, trying desperately to find a way to regain your breath.

"Oh my…" Lyra whispers. "Hold. Everyone freeze." Lyra tries to sound commanding, but she can't help but follow up with: 

"Oh god…they're all…"

*page_break

Each second feels like an hour as you sit at the top of the stairs, unable to take your eyes off of the slaughtered Ani-Powered general. Your pounding heart sounds like thunder in your ears as you await Lyra's next words. You're sure they'll only confirm what you already fear: The Hero Project has just unwittingly stumbled upon the latest of these horrific Ani-cide hate-crime murders.

"Rookies, I have an update for you," Lyra speaks through the comms, her voice now sounding slightly more composed. "The Veterans are accounted for and have secured the subbasement bunker. However, all of Smyther's Ani-Generals have been found dead. Smyther himself remains at large, as well as whoever may have done this. So please remain on high alert."

If the sole survivor of this attack was Smyther, the only non-Ani-Powered down there, then this only confirms your suspicions about this being another Ani-cide murder—unless Smyther did this himself, which seems unlikely, given that these are his most trusted allies. You hope there could be another reason, but your stomach turns and your skin crawls all the same. Who could hate your kind so much that they're systematically murdering you? Even though the targets still remain Ani-criminals, the message is clear:

Someone has decided Ani-Powered criminals deserve death over due process. 

*page_break

The Ani-Generals here may not be innocents, but you know all too well how easy it is for lost Ani-Powereds to fall through the cracks of society and into organizations like Smyther's. You think of someone butchering more lost Ani-Powereds, or even JK, and you nearly cry out loud. You force that thought from your mind, however, because it's too much to bear. 

Whoever this Ani-cide serial killer is, they're obviously incredibly resourceful and Powerful, if they were able to secretly penetrate The Hero Project and The DRPR's combined security perimeter, not to mention Smyther's own considerable defenses. Whoever you're dealing with, they're a formidable enemy.

And they just made this fight very personal.

As these thoughts race across your mind, you realize that several new camera orbs have arrived to capture your reaction to these murders. Feeling increasingly sick, you turn to the nearest orb and fight the urge to scream.

*choice
	#"Get out of my face. This is disgusting."
		*set public %-15

		"${codenamed}, I'm sorry, there was some static interference," The Hero Project's director of photography suddenly says over the comms in your ear. "Can you repeat that for the cameras?"

		Rage pours through your mind in a cold waterfall, washing all reason away. The world flashes red, and next thing you know, all of the camera orbs that were surrounding you now lie smashed around your wheelchair.

		"Did you get that?" you whisper, unclenching your fists at your sides. 

		*if (public < 45)
			*set lb +10
			*set legended +2
			*set rlshp_eps %+15
			*set respected %-15
			*goto ignitefail
		*else
			*set lb +5
			*set rlshp_eps %-15
			*set respected %-5
			*goto ignitefail
	#"We're going to find who did this. And we're going to stop them."
		*set public %+15

		*if (public > 65)
			*set lb +10
			*set legended +2
			*set rlshp_eps %+15
			*set traditional %+15
			*goto sorrystaticrage
		*else
			*set lb +5
			*set rlshp_eps %-15
			*set traditional %+5

			*label sorrystaticrage
			"${codenamed}, I'm sorry, there was some static interference," The Hero Project's director of photography suddenly says over the comms in your ear. "Can you repeat that for the cameras?"

			Rage pours through your mind in a cold waterfall, but you force yourself to keep your composure. Instead of smashing all of the cameras surrounding you, you manage to repeat your words as evenly as possible.

			"Did you get that?" you then whisper, clenching your fists at your side. 
			*goto ignitefail
	#"Take a good look. This is how Ani-Powereds are treated."
		*set public %+15

		*if (public > 65)
			*set lb +10
			*set legended +2
			*set rlshp_eps %+15
			*set traditional %-15
			*goto sorrystaticrage
		*else
			*set lb +5
			*set rlshp_eps %-15
			*set traditional %-5
			*goto sorrystaticrage
	#Don't say anything. This situation requires the respect of silence.
		*set public %-15

		"${codenamed}, can you tell us what you're seeing?" The Hero Project's director of photography suddenly says over the comms in your ear.

		Rage pours through your mind in a cold waterfall, washing all reason away. The world flashes red, and next thing you know, all of the camera orbs that were surrounding you now lie smashed around your wheelchair.

		"You're seeing nothing," you whisper, unclenching your fists at your side. 

		*if (public < 45)
			*set lb +10
			*set legended +2
			*set rlshp_eps %+15
			*set respected %+15
			*goto ignitefail
		*else
			*set lb +5
			*set rlshp_eps %-15
			*set respected %+5
			*goto ignitefail


*label ignitefail
*page_break

"I've got a live one!"

Ignite's voice sounding over your hivemind connection suddenly snaps you back into reality. You spin your chair around and look through the kitchen to find Ignite kneeling in the living room. You have no idea how he got in there or why he's alone, but you roll forward immediately.

"It's the Ani-General, Lolli," Ignite says into his comms. "One of her shoulder antlers is broken, but she's still alive. She must have played dead to…"

Ignite seems to lose his words then, looking frozen as he kneels over Lolli's bruised body. Just like you, Ignite has never been in the field before, so perhaps he is now realizing that this is no simulation—there are real lives on the line here.

While Ignite might be at a loss for words, you find that dozens are scrambling for attention in your own mind—unconscious or not, Lolli is rumored to be the most heartless and sadistic Ani-general of all time. Ignite should be securing her safely, just in case she really is still playing dead.

"Wait, Ignite, fall back," you shout through your hivemind connection. "You need to restrain Lolli before—"

*page_break

Your command is interrupted, however, as Lolli suddenly jerks upwards. 

You watch in helpless horror as her remaining rhinestone-encrusted shoulder-antler slashes at Ignite. Luckily he is fast enough to dodge away, but the antler still manages to catch his arm, cutting his costume open. His tough skin remains unpenetrated, but Ignite is caught off guard, enough for Lolli to kick him away with a heel to his gut.

Jumping to her feet, Lolli then makes a break for the front door as best she can, limping as she attempts to run. You push your wheelchair forward and prepare to contact the Rookies, but before you can, a yellowish crystal explodes at Lolli's feet.

*page_break

As an energy containment field suddenly appears to trap Lolli, Crystalline runs past her creation and across the living room to make sure Ignite is okay. Luckily, the only thing that seems bruised is Ignite's ego, from the the look on his face. But that call was still way too close for comfort.

You breathe a sigh of temporary relief and hear Lyra's voice crackle over the comms once again.

"That's a wrap, Rookies," she says, the heaviness in her voice unhidden. "Please return to the transport for debrief."

You have no idea how to feel about this mission being over, other than completely exhausted and overwhelmingly anxious. Looking around at the other Rookies, it would appear they all feel the same way.

Because you all know that after what just happened, there's going to be hell to pay.

*finish NEXT CHAPTER: REAL TALK
