*comment é x
*temp first_page true
*temp youpower_force_appear false
*label restart
*label startmenu
[i]Heroes Rise Presents:[/i]

*text_image stat_title.png center The Hero Project: Redemption Season

By
*line_break
*link https://twitter.com/zacharysergi Zachary Sergi

*if not(choice_is_web or choice_is_steam)
	*temp skip_description
	*config skip_description false
	*if skip_description
		*advertisement
		*goto youpower_purchase
*check_purchase adfree
*if choice_purchase_supported and not(choice_purchased_adfree)
	America's #1 reality show for heroes is back for another season! Harness your superpowers to steal the spotlight, win votes, and save your sister!

	[b]The Hero Project:[/b] [i]Redemption Season[/i] is the first installment in a new series of interactive novels by Zachary Sergi set in the "Heroes Rise" universe. Your choices control the story. It's entirely text-based--129,000 words, without graphics or sound effects--and fueled by the vast, unstoppable power of your imagination.

	In a contest where everyone has superpowers, your opponents can cause earthquakes and explosions, but you're an average Ani-Powered who wakes up with different animal attributes every day. Will your hawk eyes or canine claws take you far enough in the competition to satisfy the only person who can help your sister? And what happens if winning isn't enough?

	As you advance, the decisions you make will transform viewers' ideas of what it means to be a hero. Will you fight for your own goals, or make sacrifices for the good of society? Strive for what you believe is right by following the rules, or take down the whole system with more radical methods? Would you take wealth and fame over changing the world?

	Choose wisely. It's Redemption Season.

	[i]You can play the first four chapters of the game for free. Purchase the rest of the game below.[/i]
	*if choice_is_advertising_supported
		[i]Purchasing the rest of the game will also turn off in-game advertisements.[/i]
	*comment endif

	*purchase_discount adfree 2019-07-09 $4.99 $2.99 purchased
	*page_break Play Now for Free

*label youpower_purchase
*check_purchase adfree youpower
*check_achievements
*if (((choice_purchase_supported) and not(choice_purchased_youpower)) and ((((choice_achieved_fsfourteen) or (not(choice_purchased_adfree))) or ((choice_is_ios_app))) or youpower_force_appear))
	[i]The YouPower Project[/i] is a short story developed by Zachary Sergi and written by Michael Alan Nelson. It's set in the months following [i]The Hero Project: Redemption Season,[/i] but contains no spoilers for [i]The Hero Project.[/i]

	*purchase youpower $0.99 purchased
	*page_break Play Redemption Season
*advertisement

*label purchased

*page_break

[b]The Hero Project:[/b] [i]Redemption Season[/i] is the first novel in a stand-alone series that takes place in the Heroes Rise universe, focusing on a brand new main character. New to Heroes Rise? Great, you can get started right away without any prior reading!

Though if you have read [b]The Heroes Rise Trilogy[/b], you can load your [b]Heroes Rise:[/b] [i]HeroFall[/i] saved games below for historical accuracy and some special surprises.

*check_purchase youpower
*check_achievements
*choice
	#I'm a new reader.
		*set first_page false
		*set newreader true

		If you want more Heroes Rise, check out [b]The Heroes Rise Trilogy[/b]:

		*link https://www.choiceofgames.com/heroes-rise/redirect.php?src=hr4 Heroes Rise: The Prodigy (Book One)
		*line_break
		*link https://www.choiceofgames.com/heroes-rise-2-hero-project/redirect.php?src=hr4 Heroes Rise: The Hero Project (Book Two)
		*line_break
		*link https://www.choiceofgames.com/heroes-rise-3-herofall/redirect.php?src=hr4 Heroes Rise: HeroFall (Book Three)

		You don't have to read these to enjoy [i]Redemption Season[/i] though, so get ready to dive right in, Hero Riser!

		*goto readytostart
	#I'd like to load my saved game from [b]Heroes Rise:[/b] [i]HeroFall[/i].
		*set first_page false
		Please note, you must load a game from [i]HeroFall[/i] for [i]Redemption Season[/i] to work properly. 

		Games loaded from [i]The Prodigy[/i] or [i]The Hero Project[/i] WILL NOT work.

		*choice
			#Yes. Load my saved game from [b]Heroes Rise:[/b] [i]HeroFall[/i].
				*comment Need to load code in a way that it re-writes the relevant code in startup.
				*restore_game cancel=restart
				*goto readytostart
			#Never mind, I want to start as a new reader.
				*set newreader true
				*goto readytostart
	*if (choice_purchased_youpower) #I want to read [i]The YouPower Project.[/i]
		*goto_scene youpower
	*if (not(choice_purchased_youpower)) #I'd like to purchase [i]The YouPower Project[/i] side story.
		*set youpower_force_appear true
		*goto youpower_purchase
	
*label readytostart

*finish REDEMPTION SEASON
