*comment Choice of Rebels: Uprising written by Joel Havenstone, copyright 2017.
*comment Using ChoiceScript (copyright 2010 by Dan Fabulich) under the terms of the ChoiceScript license:
*comment  http://www.choiceofgames.com/LICENSE-1.0.txt

*temp makeup 0
*temp threattarg 0
*temp hostages 0
*temp retaltick 0
*temp hambush 0
*temp caleayell false
*temp simzstalk false
*temp kalstalk false
*temp cuthand true
*temp hectheu 0
*temp myblood 0
*temp hectarg true
*temp hecslam false
*temp impaled false
*temp imptheu false
*temp a_his "his"
*temp a_he "he"
*temp a_name "name"
*temp holdfast 0
*temp parley false
*temp close true
*temp b_his "her"
*temp b_he "she"
*temp b_name ""
*temp b_him "her"
*temp c_his "his"
*temp c_he "he"
*temp c_name "Zvad"
*temp c_him "him"
*temp d_his "his"
*temp d_he "he"
*temp d_name "Zvad"
*temp d_him "him"
*temp e_he he
*temp e_his his
*temp e_him him
*temp e_name "Ciels"
*temp f_name "Terret"
*temp f_he "he"
*temp g_he xhe
*temp g_his xhis
*temp g_name "Breden"
*temp simzwme false
*temp simzacc false
*temp zvlw false
*temp casred 3
*temp cas 0
*temp labtick false
*temp bsheep false
*temp ksheep false
*temp ssheep false
*temp bredbreck false
*temp plan 0
*temp lifestory false
*temp shepherds 0
*temp ktick 0
*temp zvadgo false
*temp loanetick1 false
*temp loanetick2 false
*temp loanetick3 false
*temp loanetick4 false
*temp theucatch 0
*temp sheepsmell false
*temp sheeploss false
*temp shepwis 0
*temp randshep 0
*rand randshep 0 11
*temp slain false
*temp elnope false
*set sa_foll 0
*comment repurposed to track ganelon
*if (horion >= 0) and (horion < 10)
  As it happens, your next crisis 
*if (horion > 9) or (horion < 0)
  The first
  *if religion < 0
    real
  crisis of the spring
comes a mere eight days later.  

You aren't too worried, at first, that your mule train bringing barley up from the Rim is late. It's no longer winter, and you get by well enough on venison.
*if nonkids < 39
  *set makeup (39-nonkids)
  *if makeup <= 5
    The arrival of
    *set d2n_num makeup
    *gosub d2n
    more runaway
    *if makeup = 1
      helot
    *if makeup > 1
      helots
    has hardly increased your risk of
  *if makeup > 5
    Even with another
    *set d2n_num makeup
    *gosub d2n
    runaway helots having trickled in to join the band, there seems no great danger of your 
  going hungry.
  *set followers +makeup
  *set nonkids 39
  
  *comment endif
But by dusk of the next day, you wonder uneasily why you've heard nothing from 
*if makeup = 0
  them—no 
*if makeup > 0
  the mule train—no 
advance runner to explain the delay.  By the second afternoon, you send a group of trackers led by Ciels to find the muleteers and help with whatever's gone wrong. 

The tracking party returns a day later, shaken and grim-faced. "$!{addressu} ${lname}—they were slaughtered.  Beheaded.  The mules gutted and left for the wolves.  Only one survivor, young Glena…"  Ciels swallows.  "She'd been nailed up by her wrists to a tree.  Too high for the wolves to reach.  She's with
*if rescuer = 0
  Terret Abler 
*if rescuer > 0
  Algarn the healer
now, but Angels only know what he'll be able to do for her."

You grip your ${weapon} so tightly that your knucklebones are clearly visible under your skin. "Alastors?  Phalangites?"

*if aristo
  Ciels searches your face for a reaction as ${he} growls,
"Hector
*if helot
  bloody
Keriatou.  With ten other young nobles.  Called them his veneurs, his hunting party.  Told Glena that she was being left alive to give
*if aristo
  you fair
*if helot
  us
warning that the hunt was afoot."

*if aristo
  [i]Cousin Hector.[/i]
*if helot
  [i]The young master.[/i]
"No.  He did it to start a panic.  Or flush us out."  You look sharply back down the ridge.  "You're sure you weren't followed?"  Ciels gives a curt nod, and you try to turn your mind to the implications.  

*set followers -rollover1
*set nonkids -rollover1
*set dead +rollover1
The Keriatou attack has cost you a fortnight's supply of grain, 
*if mules > 7
  seven mules,
  *set mules -7
  *if freemules > 0
    *set freemules -7
*if mules = 0
  all the mules you'd painstakingly acquired since winter,
*if (mules <= 7) and (mules > 0)
  all your mules,
  *set mules 0
and 
*set d2n_num rollover1
*gosub d2n
followers—unless Glena pulls through.  Your gut tells you:
*fake_choice
  #We've been betrayed by someone in the band.
  *if s_rel > 19
    #${simon} de Firiac betrayed us after fleeing the band.
  #We've been betrayed by one of our fences.
  *if aristo
    #We got unlucky.  Cousin Hector's an excellent hunter, and he picked up our trail.
  *if helot
    #We got unlucky.  The Keriatou boy's an excellent hunter, and he picked up our trail.
${deputy}'s expression has grown darker with each word from Ciels.  Now ${dephe} turns to you.  "How will we respond?"
*if aristo

  You wonder if ${dephe} can see in your eyes what you feel for your dynamic, talented older cousin Hector:
  *choice
    #The competitiveness that has defined our relationship since earliest childhood.
      *set hector 1
      Somehow it was never good enough for Hector to be
      *if com = 0
        stronger and more dexterous
      *if cha = 0
        more charming
      *if int = 0
        better read
      than you.  Nor did it seem to matter that he was heir to the aristarch of the Outer Rim, while your family was only a few steps away from losing what remained of your land and respectability.

      No, he was determined to
      *if com = 2
        best you physically as well, constantly challenging you to wrestle or duel with sticks.  Once he turned a friendly mudfight with other children at the river into a pitched battle—and as he'd ensured that the oldest ones were all on his side, all your skill couldn't spare you and the other youngsters a thrashing.  You'll never forget the taste of that dank gray mud.
      *if cha = 2
        be better liked than you as well—to ensure that for all your charm, the other youth of Rim Square would keep you at arm's length.  He never laughed at your wit, and if there was any danger of another young noble in the group warming to you, he was quick to fire off a cutting remark or humiliating story.
      *if int = 2
        seem more knowledgeable as well. Whenever you shared some idea you'd recently learned, he'd go out of his way to argue against it—taking full advantage of the tutors and books that the Keriatou could afford and the ${orig_lname} could not.
      For her part, cousin Calea mercilessly teased whichever of you was failing at any task, ensuring that everything felt like a test.

      *if com = 2
        You wonder how many of Hector's so-called veneurs are the same children he picked for the mudfight.
      "Damned if he's going to win this one," you snarl under your breath.
      *goto retaliation
    #The intense dislike born of Hector's demeaning attitude and casual cruelties.
      *set hector 2
      You were your Keriatou cousins' closest relation in the district, thanks to the highly unwise love match between their great-grandfather's brother and your great-grandmother.  They were the aristarch's children, while your own family was only a few steps away from losing land and respectability. To have such a social distance between close cousins was both unusual and uncomfortable.

      Depending on the day, Calea found your relative poverty fascinating, embarrassing, worthy of merciless teasing, or simply boring.  Hector, on the other hand, seemed to feel nothing but irritation that a lowly ${orig_lname} could call on the duties of family. You were beneath his notice—unless you did anything which he saw as unduly presuming upon your kinship, in which case he would punish you.  

      Once he abruptly turned a friendly mudfight with other noble children at the river into a gang assault on you; you'll never forget the taste of the dank gray mud he pushed into your mouth while three others sat on you.  Another time, knowing how much you valued your
      *if com = 2
        first steel sword,
      *if int = 2
        family's copy of [i]The Dawn of the Shayardene Monarchy[/i],
      *if cha = 2
        visits with the Keriatou rhetoric tutor,
      he contrived to
      *if com = 2
        lose it down a well.
      *if int = 2
        knock the book into a hearthfire.
      *if cha = 2
        have the ${woman} accused of improper association with students and sent away in shame.
      
      Unfortunately, your cousins were all but inescapable growing up. As the children of the aristarch, they were the heart of every social occasion among Rim Square's small population of young nobles.  So for your whole life, you've had to swallow some measure of Hector's brutality.  Now it's directed not just at you, but at the followers who look to you for guidance and protection.  What will you do?
      *goto retaliation
    *selectable_if ((malepref) or (acepref and not(aropref))) #The infatuation which I've never been able to escape, however unlikely a Keriatou-${orig_lname} marriage alliance.
      *label hewasheir
      He was heir to the aristarch of the Outer Rim.  Your family was one bad year away from losing all that remained of your land.  You always knew that Hector would be wed to the scion of an even more powerful House elsewhere in Shayard—and that Lord Keriatou would never allow his heir to repeat the highly unwise love match that had linked your families in your great-grandmother's generation.

      None of it mattered.
      *if (acepref and not(aropref))
        You were fascinated by your older cousin, awed by his confidence and fearlessness. Day and night, you found him in your dreams. If as your father insisted you would one day need to marry, to make the alliances and adopt the heirs that would keep the ${lname} alive, you couldn't imagine it with anyone other than Hector Keriatou.
        *gosub chaperon
        *set hector 5
        *choice
          #It broke my heart every time I saw him furtively trysting with another young noble.
            When you glimpsed him groping some other girl or boy in the forest or under the stairs, it would reduce you to wordless misery for days. You were sure one day he would end up wed to one of them and pursue discreet entanglements with most of the others, all happy to break chastity for an aristarch. And you? Just a hopeless cousin, neither sharing his House nor sating his appetites. 
            *goto asyoufeared
          #I managed to callous myself to his many dalliances.
            It wasn't as if you had any interest in sating Hector's appetites yourself. You did your best to enjoy his presence and ignore his entanglements—pushing back the painful awareness that one day you would lose him for good to someone else.
            *goto asyoufeared
          #Why would those matter to me? I yearned for a closeness that had nothing to do with bodies.
            Hector could never give much of his time to those secret trysts, and it was his time you craved—his words, his smile, his glorious presence. Only at your most feverishly impatient could you begrudge him the time he took to fulfil other appetites.
            *goto asyoufeared
      As a child, you were awed by your older cousin's strength and fearlessness. When you passed from childhood, that awe transmuted into something hungrier. You had learned from Hector what it looked like to be driven and ambitious, to pursue your desires and aspirations without hesitation.  Now you longed to be the thing pursued.
      *gosub chaperon
      *choice
        #I pined after him unrequitedly, unwilling to risk my reputation.
          *set hector 5
          What else was there to do?  He was the highest-profile young noble in the Outer Rim–even a fleeting entanglement with him would be unlikely to escape notice.  And if your reputation were anything but immaculate, your near-impossible dream of ending up with Hector would be permanently extinguished.

          In desperation, you tried to make yourself despise him, focusing on his undeniable arrogance and cruel streak.  But a single vibrant smile or look of worried intensity would instantly undo weeks of cultivated dislike; the best you could achieve was an aching resignation.
          *goto infatfin
        #I acted on my passion once—only once.
          *set hector 6
          *set cred_a -5
          It was during the Angelday ball on his family estate three years ago.  Both Calea and you were determined to be seen as full adults, and had discussed extensively (and in her case with uncommon generosity) what you would both wear to drive the point home.  You don't think Hector had ever seen you clad in so elaborate a
          *if male
            doublet and cloak
          *if female
            gown and bodice
          before, and when he paused to take you in properly, you eyed him back with equal frankness.  His stare was practically tangible for the next few hours while you worked up your courage.

          Then, a shared glass of Aveche wine; a casual reminiscence about your childhood mock-hunts in the Keriatou gardens, and how easy it was to feel lost in the more mazelike corners; and minutes later it was just the two of you in a distant bower, panting, groping, crushed against each other through your finery.  

          While your brief absence was observed by the others at the ball, you were circumspect enough in returning separately to escape most comment.  Neither of you spoke of it the next day, and without any encouragement from his side, you never quite dared to try it again.
          *if (bred_lover = 6) or (bred_lover = 7)
            The shame that settled into you after this breach has no doubt contributed to your determination to remain chaste with Breden.
          *goto infatfin
        #The two of us had a summer, two years ago.
          *set hector 7
          *set cred_a -10
          It happened when Lord Keriatou was away for some months—first to seal an agreement with another House in the Southriding, then to take counsel with the other aristarchs of the region in the city of Rimmerford.  In his father's absence, Hector seemed more restless and unhappy than usual.  At any rate, he was churlish to most of the other noble youth, including you.  

          Between his unkindness and your nagging dread that the Southriding agreement was Hector's arranged marriage, you spent weeks in deepening misery.  Cousin Calea's regular jibes about the 
          *if orig_lname = lname
            ${lname}'s
          *if orig_lname != lname
            ${orig_lname}'s
          poverty became unbearable.  After one particularly cutting remark while out hunting, you rounded on her and Hector and thoroughly damned them for their blind, heartless arrogance toward everyone below their station.  All your anguish poured out as vitriol, leaving you emptied and intolerably close to tears. Before either astounded Keriatou cousin could respond, you rode out into the wilderness.

          Hector's horse was slower than the one he'd lent you, but he closed the gap enough for you to realize that what he was bellowing was an apology.  Shocked, you let him catch up…and when he greeted you with a rough, wordless kiss, you returned it with all the passion you'd just put into scolding him.  No furies or rumor-spreading by Calea could spoil the delirious happiness of that day and the weeks that followed.
          *page_break
          In your stolen moments together, he was tender in a way you'd never imagined before.  For the first time, he spoke honestly of what went on during the Season when he, Calea, and thousands of other nobles converged on Shayard City.  Previously, you'd only heard boasts of how glorious it was; now you heard Hector's dread of it, of emerging from the Rim and finding himself condescended to as an amusing bumpkin, or shamed for his ignorance of the fashion and politics of the heartlands.  "Everything you said to us…I've wanted to say to others so many times."

          You tried to imagine your brash, brutal cousin afraid to speak his mind.  "But…you haven't?"

          Hector's arms tightened around you.  "It's a different world out there, ${fname}.  If you…"  He caught himself.  "One day you'll see it.  Then you'll understand."

          It all ended when his father returned.  You both knew it would—that of all the 
          *if he = "he"
            men
          *if he = "she"
            women
          Hector Keriatou could afford to be caught romancing, his impoverished cousin was nearly the last.  But the change when it happened was swift and total; if you had hoped for any fond glances or hints of what had passed between you, let alone any more secret trysts, you were utterly disappointed.
          *if (bred_lover = 6) or (bred_lover = 7)
            The humiliation you felt after this breach has no doubt contributed to your determination to remain chaste with Breden.
          *goto infatfin
      *label infatfin
      As the years passed, you became calloused to Hector's furtive courtships of other young noblemen and women.
      *label asyoufeared
      
      Now—as you've feared ever since leaving Rim Square—your cousin has turned his strength, ingenuity, and cruelty toward ending your rebellion.  What do you intend to do?
      *goto retaliation
*label retaliation
*choice
  *if (aristo and (hector < 3)) and ((retaltick < 1) and (int = 2))
    #First, I get a message to cousin Calea in secret, trying to convince her to restrain her brother.
      *goto caleaparley
  *if (hector >= 4) and (retaltick < 1)
    #First, I try to get a message to cousin Hector in secret.  Surely the two of us can stop this before it escalates further.
      *goto hectorparley
  *if(retaltick < 4) #We go after Hector and his hunters directly, using another mule train as bait for an ambush.
    *goto hectorviolence
  *if (labtick) #We go after House Keriatou's flocks of sheep.
    *goto labreconsider
  *if (labtick=false) #We hit back at the wealth of House Keriatou.
    *goto tothebrecks
  *if ((s_rel > 9) and (s_rel < 20)) and ((horion > 1) and (horion < 10))
    *hide_reuse #We kill our noble hostages and leave their heads outside the Keriatou gate.
      *goto killhostages
  *if (s_rel < 9) and ((horion > 1) and (horion < 10))
    *hide_reuse #We kill our noble hostage and leave his head outside the Keriatou gate.
      *goto killhorion
  *if (((s_rel > 9) and (s_rel < 19)) and ((horion < 1) or (horion > 9))) and ((retaltick != 1) and (retaltick < 5))
    *hide_reuse #We kill our noble hostage and leave ${zhis} head outside the Keriatou gate.
      *goto killsimzane
  #We'll protect ourselves better.  I don't want Hector to have any chance to do this again.
    *goto playdefensive
      
      
      *label caleaparley
      *set retaltick 1
      When the idea first occurs to you, you discard it out of hand.  Calea was rarely much more than cruel to you, and she despises weakness; of all the times that you might make an overture to her, surely the worst is when her brother has you on the defensive.
      
      But something nags at you through a day and a night—some reason she would listen to you, some leverage you have over her.  It feels like more than mere wishful thinking.  All your life, you've applied your intellect to understanding what moves your cousins, to making the most of the shreds of power you have in your relationship.  Now you sit down to think it through again.
      
      And while you're breaking fast, the key suddenly comes to you: a vivid memory of Calea staring after her father as he left for one of his journeys south. "[i]He mustn't fail.  Failure is unforgivable.[/i]"  Almost dropping your food in your haste to get back to the Leaders' Tent, you pull out one of your few, precious rolls of parchment and write in your most florid hand:
      
      [i]Young milady—from one who watches from afar but cannot speak ${his} feelings before the world—[/i]
      *line_break
      [i]My presumption is unforgivable, but where forgiveness is truly impossible, there most of all must we cleave to each other[/i]
      *line_break
      [i]In such an hour as this, who can you trust but one who bears you such love?[/i]
      *line_break
      [i]I implore you to meet me—alone—an hour after dawn, where your stallion dropped its shoe last spring.[/i]
      
      Then you hesitate, wondering how best to hide from the band the fact that you're seeking a parley with your loathed cousins.
      *goto keriestate
      
      *label hectorparley
      *set retaltick 1
      For the first time since you entered the Whendward, you face a task utterly alone.  There's not a single bandit who you believe would accept a parley with bloody-handed Hector Keriatou.  
      
      *label keriestate
      "I need to find out who these 'veneurs' of his are, first," you
      *if hector < 4
        finally
      suggest to your fellow outlaws.  "They'll be women and men I grew up with.  Once I know their names, we'll know the threat we're truly facing here."  It's a good reason—and a good excuse for reconnaissance alone around the Keriatou estate.  

      *if hector < 4
        *page_break
      As ever, servants burble in a steady stream through the gates, heading to and from town on all the business that keeps a great House alive.  It's unlikely that any Keriatou retainer would recognize "young
      *if male
        lord
      *if female
        lady
      ${orig_lname}" beneath your hood,
      *if male
        beard,
      *if female
        unkempt thicket of hair,
      and general grime. Still, you wait the better part of a day until you spy two unfamiliar washer-girls heading out to the nearest spring with armfuls of linen.
      
      Naturally, at first they take you for a bandit. "The House I serve as a forester is close in honor to your master's, gilly," you counter chidingly, producing a rolled parchment bound with ribbon in one hand and a drachem in the other.  "And a young ${daughter} of the House has engaged me for some discreet communication with young
      *if wealth > 0
        *set wealth -1
      *if hector >= 4
        kurios Hector."
      *if hector < 4
        kuria Calea."

      The girls' nervousness dissolves into throaty laughter at this all-too-familiar game.  
      *if hector >= 4
        "No bandit, then, but a procurer."  
      *if hector < 4
        "What, for the young kuria, not her brother?
        *if female
          She's never fancied a girl that I heard of.
        I think your 
        *if male
          master 
        *if female
          mistress
        will be disappointed, bandit.  But as you've come all this way…"
      The bold one takes the message and coin, wagging a finger at you.  "Go make atonement to the Angels, ${girl}…and tell your
      *if male
        lord
      *if female
        lady
      that
      *if hector >= 4
        kurios Hector
      *if hector < 4
        kuria Calea
      shall have ${his} proposition."
      *page_break
      *if hector >= 4
        *achieve lovenote
        The whispering aspen trees above your bivouac obscure the moon and all but a scattering of stars.  Staring up at the isolated glints of light, you can't stop wondering how Hector will have received your note. Surely he'll spot the chalk-white flag of truce sketched among love-flowers, and understand the inscription:
      
        [i]Young milord—[/i]
        *if hector = 5
          [i]from one who never openly confessed the depth of ${his} love for you—${he} implores you for a final chance. Pray[/i]
        *if hector = 6
          [i]for that one Angelday's sake,[/i]
        *if hector = 7
          [i]for our lone summer's sake,[/i]
        [i]meet me alone an hour after dawn, where your sister's stallion dropped its shoe last spring.[/i]
      
        "Trust me," you breathe into the wind…and in your fitful half-sleep, you dream of Hector running a sword into your chest.
        *fake_choice
          #I want to trust him.
          #I do trust him.
          #I'd be a fool to trust him.
        At first light, you shake off the apprehension and bleariness.  It takes half an hour to reach the hilltop overlooking your
      *if hector < 4
        The dawn finds you perched on a hilltop, cautiously scanning your proposed
      rendezvous: a stretch where the ill-kept road heading directly south from Rim Square crosses a broad, grassy plain.  The steep ridge you're on juts out into the grassland and ends in a forested scree slope a few dozen yards from the track.  
      
      You chose it because from here, you should be able to see if
      *if hector >= 4
        Hector's tried to set up an ambush for you 
      *if hector < 4
        your cousins are attempting an ambush
      anywhere in the plain.  The closest point where horses could be hiding is a copse a half-mile back toward Rim Square.  If things go amiss, you'll be able to regain the cover of this slope before any riders reach you. And you're sure that once you're all on foot in the woods you can outrun any of Hector's veneurs.  A winter in the wild and a spring of deerstalking on foot has left you lean, fleet, and tireless.
      
      Then all other thoughts flee your mind at the sight of the great black horse standing at your rendezvous point, alone in the grassy expanse.
      *if hector < 4
        The arrogant stance of the kermes-clad figure holding the bridle is unmistakable, even at a distance.  Calea has answered your invitation…and as long as she truly is alone, it means you were right.  You can use her.
        *choice
          #I shoot an arrow toward her, to see if it flushes anyone out of hiding.
            *set caleayell true
            You pull out one of the whistling bone arrows you use for signaling to other bandits.  As soon as Calea hears its piercing whine, she darts behind her horse.  "Parley!" she howls, voice thin but audible from where you stand.  "Damn it all, ${fname}, you called a truce!  Parley!"
            
            Across the plain and all the forest you can see, no one breaks cover.  [i]Well, I asked her here for a reason.[/i]
            *goto caleachat
          #I give the whistling call that we used to summon each other when hunting.
            Your Keriatou cousin's head snaps up, turns in your direction.  "${fname}?  You called?"  When you give another cautious whistle, she throws up her hands and echoes the call back at you.  If anyone could make a whistle sound sarcastic, you suppose it would be Calea. "Cousin, every unchaperoned minute we're wasting is one more I'll have to explain to father.  I don't have the time for a hard climb.  Let alone a kidnapping by your notorious gang of thugs—thank you kindly, ${milady} ${lname}.  [i]You[/i] come down [i]here[/i]."
            
            [i]Fair enough.[/i]
            *goto caleachat
          #I cautiously descend.
            *goto caleachat
      A moment later, your shock gives way to a new flood of disappointment and anger.  The kermes-clad figure holding the bridle isn't Hector; it's Calea.
      *choice
        #Something's gone wrong.  I've got to get out of here now.
          *label calearetr
          You retreat into the brush as silently as you came, though your heart is drumming hard enough that it should be audible from Rim Square.  If Calea's out there
          *if not(caleayell)
            where you can see her, 
          *if caleayell
            shouting at you,
          then Hector's surely in a place of greater advantage—which in this case can only be in these woods, stalking you.  
          
          [i]Probably watching you down an arrow right now,[/i] your mind yammers.  [i]The bastard's only waiting because he wants to see who else has your back.  And when he decides you're alone…Ah, fool, fool![/i]
          
          As soon as you reach deeper cover, you break into a sprint, and only begin to feel remotely safe an hour later.  The sense of having narrowly escaped a trap remains strong, along with your fury at
          *if caleayell
            Calea's duplicity, and at
          Hector for betraying your trust.  Returning to camp—to your followers, the only people on earth who will protect and care for you—has rarely felt so blessedly comforting.
          
          You can't let yourself be that exposed again any time soon.  However you respond to Hector, it's not going to be face to face.
          *goto retaliation
        #I shoot an arrow toward her, to see if it flushes anyone out of hiding.
          *set caleayell true
          You pull out one of the whistling bone arrows you use for signaling to other bandits.  As soon as Calea hears its piercing whine, she darts behind her horse.
          *if com = 2
            The arrow lands two yards away from her with a loud smack and a puff of road dust—a magnificent shot from the distance, you can't help thinking.
          "Parley!" she howls, voice thin but audible from where you stand.  "Damn it all, ${fname}, you called a truce!  Parley!"
          
          You scan the plain and all the forest you can see.  No one breaks cover.  But then, it would probably take more than a single arrow to draw Hector out if he's hiding nearby.
          *choice
            #I call out to Calea.
              "What are you doing here, cousin?"  You try not to let your rue creep into your voice.
              
              "Saving your life," Calea petulantly yells back.  "Risking my own.  And ruining my throat with all this shouting.  Come down here, Angels damn it."
              *choice
                #"All right."
                  *goto caleachat
                #"Why don't you come up here?  Bind the horse at the bottom of the slope."
                  Calea gives a testy laugh.  "Cousin, every unchaperoned minute we're wasting is one more I'll have to explain to father.  I don't have the time for a hard climb.  Let alone a kidnapping by your notorious gang of thugs—thank you kindly, ${milady} ${lname}.  You come down here."
                  *choice
                    #Fine.  I'll go to her.
                      *goto caleachat
                    #So, she's trying to keep me talking and get me out of cover….
                      *goto calearetr
                    #This is surely meant as a trap of some sort.  I'll spring it.
                      You've always been confident that in the last resort, you're
                      *if int != 0
                        cleverer
                      *if int = 0
                        more resourceful
                      than your Keriatou cousins.  Perhaps it's just the delirium of a mostly sleepless night, but that confidence has never felt stronger than it does now.
                      
                      *goto caleachat
                #The only place I'm going is away from this obvious trap.
                  *goto calearetr
            #I slowly head out, an arrow at the ready—this one steel-tipped.
              *goto caleachat
            #I smell a trap.  Time to go.
              *goto calearetr
        #I walk out to meet her, keeping an arrow nocked in my bow.
          *goto caleachat
      *label caleachat
      You descend the slope, scanning every rock and bush around you for signs of an ambush.  When you finally step out into the tussocky grass, fully exposed to whatever dangers you've overlooked, your heart begins to drum in earnest.
      
      "Cousin ${fname}," Calea greets you levelly as you approach.  Her lustrous black hair is bound back.  She's wearing hunting leathers in Keriatou crimson, and has a saber at one hip and a dirk on the other.  
      *if hector >= 4
        Her own bow remains on her saddle, and she doesn't reach for it despite your hovering arrow.  
      *if orig_lname != lname
        "Or '${lname}.'  Is that really what you're calling yourself now?"
        
        "Cousin Calea.  You're well informed as ever."
        
        "Hm.  What a singular choice.  I suppose in your place, I'd change my name as well."  Her lips bend in the slight, infuriating curl you know far too well.
      *if rescuer > 0
        "A shame we weren't able to meet last time you paid a visit to the estate.  However did you manage to poison those guards and escape?"
        
        *if hector < 4
          "Those of us from the lesser families need to be resourceful, aristarche."  You keep your voice light despite the memory of that agonizing night.
          
          "Well, if nothing else, you've shown yourself to be that." Your
        *if hector >= 4
          It's hard to keep from flinching at the memory of that agonizing night.  When you remain silent, your
        cousin gives a humorless chuckle.
      "You know, Father always grumbled that our close association with your swinish little House would bring dishonor on the family…but let me congratulate you on the sheer enormity of your achievement.  Truly.  It beggars anything we could have imagined."
      
      *if hector < 4
        You bow smoothly, as if accepting the sincerest of compliments. "And let me congratulate you, my dear cousin, on retaining your position despite 
        *if rescuer = 0
          losing all your helots to a revolt.
        *if rescuer > 0
          failing to contain a condemned rebel in your dungeon.
        Your father must have groveled to an entirely new depth to remain aristarch."
        
        Calea regards you with low-lidded disdain, then waves your note.  "What do you dream that you can offer us?  Besides yielding up your head to me before Hector takes it off your shoulders."
        
        "If you thought my blood would save the Keriatou, you wouldn't be meeting me out here alone." You're absolutely confident that it's true.  "No, Calea—you need my head right where it is.  We both know it.  And I'd like you to convince Hector of the fact."
        
        Your cousin blinks, then breaks into an uproarious laugh.  "Ah, ${fname}, ${fname}.  I think you overestimate my persuasive skills—or perhaps you underestimate quite how much my brother hates you.  Even if I agreed with you, he wouldn't have the wit to see that we need you alive.  He's taken your betrayal of our House very personally indeed."
        
        *if hector = 2
          "Oh, believe me, the feeling is mutual," you grate.
        *if hector = 1
          "He always has hated losing," you smile.
        "But surely he also understands that however many of us he manages to kill, it won't keep you in the aristarchate.  As soon as the chaos subsides a bit, the Pelematou will take your place.  The Karagonds don't forgive failure.  You taught me that."  [i]And that any weakness is the first step toward failure.[/i]
        
        "And you came here today to gloat?" Calea says thinly.
        *choice
          #"No. I came here today to save you."
            "House Pelematou are no kin to me, after all." With some difficulty, you resist indulging in the mockery she's so often turned on you. "You're the only one in the family who's clever enough to see this.  But—if you're willing to give me what I need, cousin—we could agree on the one path forward which leaves the Keriatou as the aristarchs of the Outer Rim, despite a rebellion starting on your watch."
            
            "Forgive me if I'm not unduly impressed by your offering not to die," Calea snorts.
            *goto caleadrive
          #Well, yes.  A little pointed gloating is irresistible.
            "All those years, Calea…all my life, you've mocked me, shamed me, kept me in my place."  A near-choking bitterness rises up in your throat. "Did you ever wonder whether one day, my goodwill would mean anything to you?  Were you so confident that you'd never need me for anything except to be the object of your jokes?"
            
            Your defiant Keriatou cousin raises an eyebrow, and her chin.  "You seem curiously certain that I was mistaken."
            
            You lean toward her, thin-lipped.  "We both know I'm the only one who can keep the Keriatou atop your precious perch, despite a rebellion springing up in your district.  So give me one reason I should try."
            
            "Because the only way you can bring us down is to die." Calea laughs, still visibly unmoved. 
            *label caleadrive
            "Isn't that what you're driving at, ${fname}?  If you're crushed by the Phalangite host that's massing in Rimmerford, it will be the end for us all.  But if you manage to survive the Archon's own troops, Father's failure to contain your revolt will look more tolerable."  She inclines her head with a sly smile. "And I agree: from that point, having kin on both sides of the rebellion could be useful for us all.  Prosecuting our struggle with…an element of restraint, in areas of mutual interest."
            *choice
              #"For example, you could tell me everything you know about those Phalangites, to reduce the chances of their killing us."
                *goto calphal
              #"For example, you could tell me about Hector's veneurs, so we can better defend ourselves against their attacks."
                *goto caleabrows
              #"But it can only work if Hector stops sending his veneurs against my people."
                *goto caleabequest
              #I want nothing more to wipe that familiar smirk from her face. "I'm glad you agree, cousin.  But I would die before I help your damned House stay in power."
                *goto calspurn
              #"Why don't we discuss it further in my camp?"  I raise my bow and aim for her heart.
                *set calea 3
                *goto calpois
          #"No. I came here today to take you hostage." I raise my bow and aim for her heart. "I hope Hector will find that persuasive."
            *goto calpois
      "Where is Hector?"  You do your best to keep your voice calm.
      
      "Not here," your cousin snaps.  "Though if it's any consolation for your poor bruised heart, I'm sure that had he seen this, nothing would have deterred him."  She brandishes a familiar bit of parchment.
      
      Heat flares in your cheeks and ears. "How did you…"
      
      "My brother hasn't managed an assignation without my acquiescence since I was thirteen." Calea smugly tosses your note back to you.  You let it flutter into the grass, keeping your bowstring taut and your focus on your surroundings.  "The servants know that if they want to keep their posts, they'll deliver any messages of that nature to me first.  I only let Hector receive the suitable ones.  If a candidate is unsuitable…they may find me keeping the tryst, to give them a piece of my mind."
      *choice
        #"How generous, cousin.  Does Hector similarly canvass the helots for you?"
          *set calea 1
          For all the times that you've lashed out in response to some verbal cruelty from Calea, you've never seen her eyes bulge or her mouth crumple as they do now.  No one else in the Rim would have dared so openly to refer to her penchant for taking helot boys as lovers.  No one would dare so brazenly to shame the aristarch's daughter.
          
          Before she regains her tongue, you grate, "You petty child, this isn't an assignation. What and who you deem suitable for Hector is of no consequence. I need to speak to him before it's too late…."
          
          Calea spits, "Oh, please.  You think I don't know what you want, ${fname}?  All of it?"  Her eyes burn into you.
          *goto diedtoday
        #"Angels, cousin.  How many times have you resisted gloating to me about that?  It must have been painful."
          *set calea 4
          Calea laughs at your bantering commiseration.  "Anguish most exquisite."  Still smug but not venomous, she adds,
          *if not(acepref)
            "I might well have shared it with you, cousin…if I hadn't always known that, one day, I'd be canvassing a proposition written in your hand."
          *if acepref
            "I'll confess to being surprised on every level by your note, ${fname}. I'd never thought you held any interest in such things."
          
          Is that a trace of actual compassion in her eyes?  You find it hard to paper over the recurring ache with a light, witty tone.  "In light of the past half-year…I can hardly deny my manifest unsuitability.  But there are some specific details I'd rather hoped to explore with Hector himself.  Which—unless you're one of his so-called veneurs—I doubt you'll be able to illuminate."
          
          "On that, you'll get more illumination from me than you would have from him."  Her voice becomes brisk, matter-of-fact.
          *goto diedtoday
        #"Then give me whatever piece of your mind you deem worth the risk to your life."
          *set calea 3
          Calea moistens her lips and 
          *if not(caleayell)
            hesitates at your
          *if caleayell
            hesitates before speaking.  The arrow clearly left her shaken, as has your
          blunt tone and implied threat.
          *goto diedtoday
      *label diedtoday
      "If he had got your note, at least one of you would have died here today."
      
      "No."  You shake your head vehemently, remembering 
      *if hector = 7
        Hector's vulnerability and fierceness of two summers ago.
      *if hector = 6
        the way Hector looked at you that night in the garden.
      *if hector = 5
        how Hector relented when he seemed to realize why you sought his company.
      "I wouldn't have…"
      
      "So you'd have been the one to die," she snaps.  "Listen to me, 
      *if calea >= 2
        ${fname}.  
      *if calea < 2
        fool.
      Hector hates you as he has hated nothing else in his life.  He rails against you—and not just to the Hegemony's servants or to Father.  To his lovers. In his cups.  He calls you death-leech and matriphage spider, feeding off the Keriatou all through your childhood and then trying to destroy us."  Calea pauses, seeing from your flinch how deep those words have cut.  "If he had come here today,
      *if com < 2
        he would have put a sword through you within the first minute.
      *if com = 2
        it would have been with a dozen hunters creeping through the woods.
      There would have been no parley—let alone anything else you might have dreamed."
      
      *if calea != 3
        *page_break
      "Say it's true.  Say he would have killed me."  Your voice cracks despite your best effort at impassivity.  "You could have just let it happen."
      *if calea < 2
      
        "Maybe I should have…you vicious, resentful little churl."  Calea's hate spills ugly and frustrated across her face.
        
      *if calea >= 2
        The silence stretches out between you until finally you rasp,
      "Why didn't you?"
      
      It's a few moments more before your cousin responds, "Because they're all afraid of you."
      *page_break
      *if (theuknown >= 10)
        "And not just because of whatever cod-${wisardry} you've managed to invoke."
      Calea steps closer to you, searching your face with
      *if calea < 2
        bitterly angry
      *if calea >= 2
        shrewd
      eyes.  "Father, the other aristarchs, the new Ecclesiast…there's something in how they talk of you and your band.  They want to call you 'bandits' and 'brigands,' and when they set their minds to it, they do.  But in normal conversation, they constantly slip and call you [i]the rebels[/i]."  She waves a hand in the direction of the wilderness.  "No one had ever used that word for that hopeless thief-pack out in the Whendward before you
      *if rescuer > 0
        magicked yourself out of our dungeon
      *if rescuer = 0
        lured away everyone's helots
      and joined them.  Only merchants truly fear bandits.  But everyone with power fears rebels." 
      
      Under other circumstances, you'd have been gratified to hear all this.  At the moment, it feels frustratingly petty.  "For that, you'd spare me?"
      
      "As I explained when I greeted you this morning."  Calea briefly slips into a familiar pitying tone that informs you you're being dull.  "Father only ever saw the potential for the ${orig_lname} to drag us down.  Now Hector's desperate to save the Keriatou by severing the link once and for all.  All he'd have seen in your note was a chance for some conspicuous, bloody show of usefulness and loyalty."  She shakes her head.  "My brother can't face the truth.  The Karagonds don't forgive a failure this grand, and they don't give second chances.  Once the chaos dies down, they're sure to elevate House Pelematou to the aristarchate.  And that's why I praised the enormity of what you've achieved: a shame so great, so beyond our imagining, that it could become quite indispensable."
      *fake_choice
        *selectable_if (int<2) #"Speak sense, Calea." I roll my eyes in impatience.
        *selectable_if (int<2) #"I still don't see what you're getting at."
        *if (int > 1) 
          #"You'd succor us in secret?"
      *if int < 2
        "Oh, forgive my overestimation of your wit," she sniffs.  "In simplest terms:
      *if int = 2
        "Succor is a strong word," she replies, wrinkling her nose. "Let's be honest:
      there's every chance that you'll be crushed by the Phalangite host that's currently massing in Rimmerford.  That would be the end for us all.  But if you manage to survive the Archon's own troops—as the aristarchs fear you will—Father's failure to contain your revolt will look more tolerable.  And from that point, having family on both sides of the rebellion could be useful for us all."
      
      *if int < 2
        The idea of trusting Calea comes harder than trusting Hector; at least he's straightforward, even in his cruelty.  "You're offering to succor us in secret?"
        
        Your cousin frowns.  "Don't misunderstand me, my dear ${fname}.  We remain aristarchs of the Hegemony.  We are bound to war with you, and you will lose friends and comrades to us.  But as family, we nonetheless honor our mutual interests…and should be able to agree some limits to our war.  Things we both value and wish to protect.  We could perhaps go so far as to share information regarding mutual rivals."  When you look unconvinced, she leans toward you beseechingly.
      *if int = 2
        Calea was always the cleverest of Rim Square's young nobles, but this is a level of subtlety you hadn't expected from her.  With a pang, you accept that this offers an opportunity better than you'd expected from Hector.  "You truly think we could fight while preserving…some degree of mutual interest?"
        
        She arches an eyebrow at you.
      "Whom would you rather have on the other side?  Lady Pelematou, who claims you're a Xaos-demon able to possess the mind of any helot who spends too much time in your company?  Or your beloved cousins, determined that you should not lose too quickly—or, in the end, to anyone other than us?"
      
      You wonder
      *if int = 2
        how blatant Lady Pelematou has been in linking your purported Xaos-taint with all the time you've spent with Calea and Hector.
      *if int < 2
        how a former Pelematou helot like Radmar would answer that question.
      "What you suggest would require a great deal of trust."
      
      "That's what family is for." Calea
      *if calea >= 2
       smiles without particular warmth.
      *if calea < 2
       eyes you dispassionately.
      "We each presumed on that trust today, cousin—although you were a fool to expect it from Hector.  Admit it: you owe me your life."
      *choice
        #"If you can get Hector to stop attacking our mule trains, I'll owe you."
          You lower your arrow.  "And, perhaps, believe that there's some future in the arrangement you describe."

          *label caleabequest          
          "As well ask me to have Father write you into his will!" Calea scoffs.  "You were listening when I 
          *if hector >= 4
            described 
          *if hector < 4
            mentioned
          how much my brother despises you, ${fname}?  Getting him to call off his hounds is too great a favor.  Start with something achievable."
          
          "No."  
          *if hector >= 4
            A weary disgust overwhelms you; the idea of Hector's hatred is coming to feel more like a millstone than a dagger.  
          *if hector < 4
            You know she needs you; it's time to see whether she really believes it.
          "Farewell, cousin.  I doubt we'll speak again in this life.  Good luck fending off the Pelematou."
          
          You're halfway back to the trees when you hear the
          *if calea < 2
            furious
          *if calea >= 2
            exasperated
          shout: "I'll do all I can, damn you!  Give me two weeks."
          
          Without turning around, you call, "The Phalangites mustered in Rimmerford—how many?"
          
          After a long silence, you glance back and see her remounted, riding toward you.  "Speaking treason against the Archon is rash enough without shouting it," she comments
          *if calea < 2
            icily
          *if calea >= 2
            reproachfully
          when she's close enough.  "At least two hundred.  And there's talk of more on the way."
          
          "When they move toward the Whendward, find a way to get me warning.  And an accurate number.  Including Theurges."
          
          Calea sees the bleak expression on your face and swallows whatever else she had been about to say.  "I will, cousin.  Until then."
          *set calea +10
          *page_break
          When you return to camp two days later, you tell the outlaws to wait a week or two before retaliating against House Keriatou.  "I found an opportunity to convey a very personal threat to my cousin Hector.  I'm hoping that as a result he decides to refrain from attacks against us."
          
          Radmar stares at you in belligerent confusion.  "A threat?  If it's one the Keriatou boy would believe…couldn't we just follow through on it and rid ourselves of him once and for all?"
          
          You return his glare, mind racing.  "At great risk…and likely great cost in lives.  I don't want anyone to try it.  But Hector cares little enough for helot life.  Were he in my shoes, there's no question that he'd do it.  So let's see how he reacts before we take further action."
          *if cha > 0
            The other outlaws seem to accept your bluff, and even Radmar gives way.
          *if cha = 0
            Radmar snorts with contempt over your fumbling bluff, but doesn't openly challenge you.

          And no further attacks take place.  You have no idea how Calea managed it; but your mule trains go unmolested, and your trackers don't see any evidence of Hector and his veneurs.
          *if bred_here
            
            Breden is the only one to question you further, in a low voice after dinner one night.  "You made a bargain with them, didn't you?  With your cousins?"  When you don't answer, ${xhe} leans in, looking upset.  "What was our end?"
            
            You try to assuage ${xhis} obvious worries.  "There was no bargain.  No 'end' for us to uphold.  It's as I said, Breden—the Keriatou have just realized that attacking us isn't in their best interest."
            
            $!{xhe} searches your face for a few more moments before shaking ${xhis} head.  "Take care, ${bfname}. They may be your cousins, but they'd betray us as soon as look at us, and don't you forget it."
          *goto reinforce
        #"Tell me everything you know about Hector's veneurs and their raids—and then, yes, I'll owe you."
          *label caleabrows
          Calea's eyebrows narrow at your request.  "I don't want to lose a brother, ${fname}."
          
          *if hector >= 4
            "Do you think I want to lose him?"  She doesn't immediately answer, so you lean in closer.  
          *if hector < 4
            "Then convince him to stop attacking me.  If not…" You shrug.
          "If it comes to a fight, I'll do my best to spare him.  That's all I can offer."
          
          Calea shakes her head in frustration.  "I 
          *if hector >= 4
            didn't come here to hand you a victory, any more than I came to betray you.  
          *if hector < 4
            may not have come here to kill you, but nor did I come to hand you a victory.
          If either of you dies, we all lose."
          
          "While I appreciate the sentiment…if Hector keeps bleeding my band, I'll just die when the Phalangites arrive." When she remains stubbornly silent, you make a brusque bow in her direction. "It seems we won't find much mutual interest after all.  Farewell, cousin.  Good luck fending off the Pelematou."
          
          "Damn it, ${fname}." Calea glowers at you savagely—and then begins describing each of Hector's fellow hunters to you.  
          *page_break
          Most of the young nobles have hunted with you in the past.  You know something of their habits and their talents in the woods, as well as their areas of weakness and overconfidence.  While Calea shares what she knows of their tactics, half your mind is planning how to exploit your knowledge in an ambush.  
          *if hector >= 4
            
            The other, aching half is wondering how you could possibly spare Hector if it comes to that.  
          "And the Phalangites mustered in Rimmerford?"
          
          "At least two hundred—with more likely to come."
          
          "When they move toward the Whendward, find a way to get me warning.  And an accurate number.  Including Theurges."
          
          Calea sees the bleak expression on your face and swallows whatever else she had been about to say.  "I will, cousin.  Until then."
          *set calea +10
          *set hambush +3
          *goto retaliation
        #"A fascinating proposal—but one to which I can't presently commit."
          Calea caught you off guard by coming here in Hector's place, and you don't want to commit to anything while you're off your guard.  "Give me time to consider it further, cousin.  Assuming I do survive the summer, I'll find a way of getting you another message, and we can discuss it again at that time."
          
          The young Keriatou purses her lips irritably, but nods.  "Fair enough, ${fname}."
          
          "To increase the likelihood of that day coming…would you care to tell me more of these Phalangites you mentioned?"
          
          *label calphal
          Calea doesn't blink or hesitate.  "At least two hundred.  And there's talk of more on the way.  They're sure to come for you soon."

          "When they move toward the Whendward, find a way to get me warning.  And an accurate number.  Including Theurges."
          
          *if hector >= 4
            Calea sees the bleak expression on your face and swallows whatever else she had been about to say.  "I will, cousin.  Until then."
          *if hector < 4
            After a long moment, she nods, a wry smile breaking across her face. "You know, ${fname}…there's something in how they talk of you and your band.  Father, the other aristarchs, the new Ecclesiast.  They want to call you 'bandits' and 'brigands,' and when they set their minds to it, they do.  But in normal conversation, they constantly slip and call you [i]the rebels[/i]."  She waves a hand in the direction of the wilderness.  "No one had ever used that word for that hopeless thief-pack out in the Whendward before you
            *if rescuer > 0
              magicked yourself out of our dungeon
            *if rescuer = 0
              lured away everyone's helots
            and joined them.  Only merchants truly fear bandits.  But everyone with power fears rebels.  They fear that you're going to survive the summer somehow.  And I think you will.  Or at any rate, I'll take a risk on it." 
            
            It's oddly disarming to hear such an encouraging word from her.  "And Hector…" you begin, but Calea is already shaking her head.  
            
            "I've given you what I can, ${fname}.  And I'll give you more. But that makes it all the more important for Hector to keep his attacks up, lest anyone suspect us of disloyalty."  She swings up into the saddle.  "Against him, my dear cousin…you are on your own."
          *set calea +10
          *goto retaliation
        #"I owe you nothing, Calea.  And the Keriatou can go to Taratur—all of you."
          *label calspurn
          You ignore Calea's choked attempts at a retort. 
          *if hector >= 4
            "How dare you try to claim me as family, cousin?  All my life, you've mocked me, shamed me, kept me in my place.  Now for the first time in your life, you're the one at risk—and you think you can use me to keep the Keriatou atop your precious perch?  You expect me to trust you?  To help you…or Hector?"  
          *if hector < 4
            "You pitiful little harpy.  Even now, you can't bear for us to meet as equals.  You're still convinced that everything has to go your way, however much you mock and sneer at me, just because you're an Angel-kissed Keriatou.  Well, you can go to Taratur."
          Your spit has a bitter tang in your mouth.  "Fail, fall, and be damned."
          
          "Are you done?"  Calea's voice cracks with uncontainable spite.  "Your House owed everything to ours, you ${orig_lname} cur.  Your father, a beggar who whimpered constantly for crumbs from our table…and you—a soot-faced, pottage-eating ${girl} playing at nobility with our horses, our garb, our servants!  You think the Keriatou will fall to one such as you?"
          
          "Whether I live or die."  You start walking back toward the woods, pausing only to shout over your shoulder, "Be sure Hector knows that."
          *goto retaliation
        #"An interesting proposal.  Why don't we discuss it further in my camp?"  You raise your bow and aim for her heart.
          *label calpois
          Calea slowly raises her hands in the air, eyes wide and furious.  "Don't kill me, cousin ${fname}.  I'll do as you say."
          
          "All your weapons, on the ground, now," you order.  When she's complied, you beckon her twenty yards down the road, far enough that she can't make a grab for her sword.  "Now turn around.  Kneel.  Hands behind your back.  I've a dagger which will do as well as an arrow—so don't try anything foolish while I'm binding your hands."
          
          "Don't worry.  I'll do nothing foolish."  There's nothing in her mild tone to warn you; just her wrists suddenly twisting in your hands, and something jabbing deep into the flesh of your palm.  [i]A ring?  What is she…[/i]  Roaring in pain, you drop the rope and fumble for your dagger.
          *page_break
          But as Calea scrambles away, you find the fingers of your injured dagger hand are suddenly thick and clumsy.  When you finally manage to pull the dagger from its sheath, it slips from your weakening grip.  There's a numbness radiating from your palm, and tremors starting all through your body.  You manage to pursue your Keriatou cousin for only twelve steps before your legs—and bowels—disastrously betray you.

          Calea picks herself up and walks back to where you're thrashing in the dirt.  "${fname}, you idiot," she 
          *if calea >= 2
            groans, wrinkling her nose.  
          *if calea < 2
            hisses.  
          "You should have known I'd never let you kidnap me.  Or let myself be truly disarmed."  
          
          You try to answer, but your tongue is now as nerveless as your limbs.  
          *if calea < 2
            Calea kneels next to you and purses her lips with distaste.  
            *if hector >= 4
              "You're forcing me to play hero after all, cousin.  I hope you know how much I'd have preferred you to see things my way."  While she 
            *if hector < 4
              "I'm surprised at you, cousin—and sorely disappointed.  I thought you truly intended an arrangement of mutual interest.  But since I can't trust you in that…"  While she 
          *if calea >= 2
            While Calea
          strides out of your field of vision, you try desperately to shake off the paralysis.  [i]Focus, damn it all! Breathe…breathe…br…[/i]  Finding that your lungs can only manage a constricted wheeze, your vision blurs with panic.
          
          *if calea >= 2
            *set calea 9
            A minute later, you hear slow hoofbeats approaching.  "Hush now, cousin."  Calea's serene voice echoes down from what feels like a great height.
            *gosub alchempoison
            The ringing in your ears is growing, and darkness encroaching at the edges of your vision.  "You've greatly irritated me today.  But I hope when you recover, you'll take this as evidence of my 
            *if hector >= 4
              intent.  I didn't kill you.  Next time we meet, take more seriously what I have to offer."
            *if hector < 4
              goodwill.  I'm willing to consider an arrangement of mutual interest.  Next time, be wise enough to accept it on my terms—not yours."
            *page_break
            Your breathing begins to steady as your cousin rides away.  Within an hour, you've regained enough control of enough muscles to roll yourself off the road.  By noon, you've made it to the forest again—and only just in time, as a small party of riders go by.  But you're feverish, weak, and prone to fits while the poison slowly works its way out of your system.  You can barely gather roots and berries, let alone hunt.
            
            Five days pass before Ciels and ${his} younger trackers find you, starving and delirious in the wild.  Your ravings give them a good enough idea of how you fell into this state. And while Ciels is discreet, the others are not.  Soon the whole band has some idea of how Calea Keriatou left you helpless in your own filth.
            
            By the time you've recovered, ${deputy} and the band have done what they can to conceal the mule trains from Hector and his gang.  No one has the stomach for a more aggressive approach to the Keriatou just now.
            *set morale -5
            *if deputy = "Breden"
              *set bred_lead +2
            *achieve survivepoison
            *goto reinforce
          *else
            "Sssh.  Sssh now, cousin."  Through the haze you see Calea returning, dirk in hand.
            *gosub alchempoison
            She kneels and wraps an arm around your convulsing shoulders; you feel the blade brush your throat.  "It'll all be over—ah!—[i]quickly[/i]," and it is—an acute agony, a spray of blood across her face, and nothing more.
            *goto_scene death
            *label alchempoison
            "The paralysis doesn't last long, the alchemist said.  Not long enough for you to suffocate.  It's frightening and unpleasant, but that's all."
            *return

    *label hectorviolence
    *set violence +1
    *if nonkids < 50
      You try to plan a retaliatory ambush against Hector…but you soon conclude that you simply don't have the
      *if kids > 2
        adult
      followers to carry it off.  Even scraping together some of your less able-bodied outlaws to accompany the "bait" mule train,
      *if com = 0
        Zvad insists that
      you wouldn't have enough fighters remaining to stand a chance against the veneurs.
      *if com > 1
        All your instincts say that this is a fight to avoid—and when it comes to combat, you trust those instincts.
      You turn your mind to other possibilities.
      *set retaltick 4
      *goto retaliation
    *if (hector >= 4) and (calea < 10)
      A mortal enemy is a mortal enemy.  The fact that you're in love with him doesn't change the wretched fact that this will end either with his death or yours.

      *set ruth %+10
    *set retaltick 8
    By this point, the cautious planning of an ambush is second nature—who you trust enough to involve, who you don't, who you don't yet trust but need to involve anyway for practical purposes.  
    *if helot and (elery > 0)
    
      Elery Skinner's tactical skills will be indispensable…but when you first take her aside to explain, she looks troubled and exhales sharply through her nostrils.  "Hunting the hunters?  Damn me, Captain,
      *if e_rel < 0
        you may be a grasping smutweed…but
      you've got brass."  After several moments visibly on the verge of saying more, she blurts, "Are we good enough?"
      
      You understand the tension in her voice all too well.  No helot was ever allowed a "hunt" that went beyond entangling small game with bolas, and even former yeoman archers like Ciels and Alira were forbidden to bring down large game.  Meanwhile, you all grew up watching the nobles practice their spectacular forms of hunting: the lethal stealth of deerstalking, the thunderous pageantry of horse and hounds.
      
      No one you've spoken to thus far believes you can match up to an average noble hunter.  And the brutal ease with which Hector's eleven nobles killed 
      *set d2n_num rollover1
      *gosub d2n
      of your own followers has frightened as well as angered all of you.
      
      "We're good enough." You try to fill your words with a certainty you don't feel.
      
      Elery looks away for a minute, then turns searchingly back to you.  "How is it, then? Going after your old master?"
      *fake_choice
        #Exhilarating.  To finally strike a blow back, after all the blows struck at us!
          "A long time coming."  You pause for a moment, trying to give voice to the bitter warmth in your chest.  "The worst thing, you know…for all the times we cursed him into our beer, the worst thing was knowing that—even if he'd heard—he wouldn't have had to care.  If he'd killed us, it wouldn't have been out of any real fear.  What did the aristarch's son have to fear from a pack of helots?"  Just thinking of it, your hands clench on air.  "After this, they'll know differently.  So will we."
        #Mostly terrifying.  I know just how good a hunter kurios Hector is.
          But you pry the fear from your throat and push it down until it's too deep to be heard.  "A long time coming," you answer grimly.  "He never thought he'd need to fear us.  Now he'll learn."
        #No different from any other enemy.
          "I'd not have gone for him if he hadn't come for us," you say with a shrug, "but since he has, we'll show him the error of his ways.  Him, his friends, and any other noble who comes for us."
        #I feel regret.  Did it really have to come to this?
          "I'd rather save our strength for the Karagonds," you say ruefully.  "But the Keriatou boy has forced us to spend ourselves on him as well."

      Elery nods and after a moment turns the conversation toward practical ideas for an ambush.  But by the time she leaves, you know you've only partly dispelled the uncertainty she shares with most of your other followers.
    *if aristo or (elery = 0)
      In this case, however, you quickly discover that the less seasoned members of your band (even fighters like 
      *if elery > 0
        Elery and
      Radmar) are deeply apprehensive about trying to out-hunt a noble hunting party.

      Former
      *if aristo
        helots, 
      *if helot
        helots like you,
      who have only ever been allowed to entangle small game with bolas, can't easily shed their reverence for aristocratic hunting—whether the lethal stealth of deerstalking or the thunderous pageantry of horse and hounds.  Even former yeoman peasants like Ciels and Alira, who were raised to be archers and trackers but forbidden to go after large game, don't really believe themselves the equals of an average noble hunter.  And the brutal ease with which Hector's eleven nobles killed 
      *set d2n_num rollover1
      *gosub d2n
      of your own followers has frightened as well as angered your outlaws.

      For your part, you've hunted enough with Hector to admire his woodcraft, cunning, and courage—but you can honestly state that Ciels, for example, is Hector's better.  Your followers want to believe you, and almost do.
      *set hambush +1
    *if (s_rel = 8) or (s_rel = 7)
      *set simzstalk true
      
      Fortunately, ${simon}'s promotion from hostage to rebel has come at just the right time to
      *if aristo
        further
      hearten them.  $!{zhe} turns out to be an outstanding tracker and hunter; "$!{zhis} father holds a chase of more than three thousand acres," one of ${zhis} former helot companions explains proudly, "where the ${zkuria} spent many a week in ${zhis} youth."
      *goto stalk
    *if (simz_here) and (s_rel < 7)
      *set simzstalk true
      *page_break
      At first you do your best to exclude ${simon} from all your plans about Hector.  The last thing you need is ${zhim} urging you to find a peaceful resolution, avoid alienating the nobility, and the rest of ${zhis} amiable mush.  Yet to your ire, one day the idealistic young blademaster pokes ${zhis} nose into the tent where you're planning the raid alongside ${deputy}, Ciels,
      *if elery > 0
        Elery,
      and two other outlaws whose loyalty you've tested. Every head turns at once to the noble intruder. 
      *if aristo and (kuria = "Captain")
        "De
      *if helot or (kuria != "Captain")
        "$!{zmilady} de 
      Firiac," you snap, "you were not invit…"

      "They're afraid out there, ${addressu}," ${simon} interrupts sharply. "Talking of this Keriatou boy and his veneurs as if they're more than human.  And yet we're not without noble hunters of our own.  Why haven't you told them that I'll be part of our counterattack?"

      You narrow your eyes at ${zhim}.  
      *if aristo
        "From what you've said so far, I didn't think you'd approve of retaliation against the Shayardene nobility.
      *if helot
        "With all due respect, ${zmilady}, I didn't think you would be joining us against the nobles.
      Haven't you said a dozen times that we need to treat them as potential allies, not enemies?"

      "Angels of Xthonos, ${addressu}. The miscreants tortured a young girl nearly to death."  There's a cold rigidity in ${simon}'s face that you've not seen before.  "Did you truly think I'd consider such as these our allies?"
      *choice
        #Very well.  I let ${zhim} fight.
          "Well then."  Striding over, you clap ${zhim} on the shoulder with dawning enthusiasm.  "Go back out there and make sure everyone knows that we have 
          *if helot
            a
          *if aristo
            another
          hunter to top any of Hector's veneurs."
          *if aristo
            You glance pointedly at Ciels, who shakes ${his} head in modest denial but can't restrain a slight smile.
          
          ${simon} nods intently.  "We'll catch them in their own snares, ${addressu}.  Their arrogance will make it easy."
          *goto stalk
        *if (s_sword = 2) #…and I give ${zhim} back ${zhis} family sword.
          *gosub sswordback
          *goto stalk
          *label sswordback
          *set s_sword 1
          As you unclasp the scabbard from your belt, ${simon}'s eyes go wide with hope—and when you hand it to ${zhim}, tears of elation stream down ${zhis} cheeks.  "You'll put this to better use than I will," you say wryly.  "And against Hector Keriatou, you'll need every advantage."

          $!{zhe} falls to one knee.  "As you have returned my honor to me, ${milady}, so I will ever strive to do you honor.  This I vow on my
          *if eclect
            soul and my
          life."
          *return
        #As well as fighting in the raid, I invite ${zhim} to help us with the planning.
          *label splan
          You beckon ${zhim} into the inner circle. As you'd hoped, ${zhe}'s full of ideas on how you could turn the tables on Hector and his veneurs.  "We'll catch them in their own snares, ${addressu}.  Their arrogance will make it easy."
          *if elery > 0
            ${simon} and Elery play off each other particularly well, each gifted with tactical intuition and woodcraft.
          *goto stalk
        *if (s_sword = 2) #…and I give ${zhim} back the sword.
          *gosub sswordback

          *goto splan
        #I refuse ${zhis} offer.  $!{zhe}'s still a long way from proving ${zhim}self.
          "I thought you understood, de Firiac.  You don't tell us when it's time to entrust you with a mission of this magnitude.  You obey orders, and wait for us to tell you when you've earned that trust."

          ${simon}'s lips press together tightly.  "I obey, ${addressu}," ${zhe} finally grates before storming off.
          *set simzstalk false
          *goto stalk
    *if kal_here
      *set kalstalk true

      Fortunately, ${kalt} entirely lacks the typical helot reverence.  "Angelspit, people.  Out there in the wild, Ciels is worth two of any noble.  Alira too.  These are our woods.  We know them, every crag and corner.  What are we afraid of?"
      *if elery > 0
        *if helot
          *set hambush +2
        $!{zhe} turns to the diffident Elery.  "And I've heard enough about your eye for terrain to know that we're going to destroy them."
      $!{zhis} profane assurance carries the band along; for the first time, your outlaws begin to believe that they actually can hunt Hector Keriatou.
      *goto stalk
    *label stalk
    *page_break
    *if (mules < 7) and (nonkids > 50)
      You've left yourself with few enough mules that you can't quickly dispatch another convoy to bring in grain.  Instead, you need to send another
      *if (gandhi < 10)
        raiding party into the Rim.  
        *set followers -12
        *set dead +12
        *set nonkids -12
        *set morale -50
      *if (gandhi > 9)
        begging party into the Rim to claim a few more mules.
        *set followers -5
        *set dead +5
        *set nonkids -5
        *set morale -30
      They take a long time returning, while hunger and dread take their toll on the rest of the band.  
      *if rescuer > 0
        "It's to be the winter all over again," you hear some whisper. 
      
      *set mules +5
      The party finally makes it back with a handful of mules and some barley, but 
      *if (gandhi < 10)
        twelve fewer outlaws than when they'd set out.  The high number of casualties pushes the band to the verge of panic.
      *if (gandhi > 9)
        five fewer outlaws. A deep dread settles into your band at the growing number of casualties.
        
      You order another party out with the mules at once for another grain run.
    *if (mules >= 7) or (nonkids < 51)
      The next grain run has to get through if the band's not to run low on food again.  So you send an escort of 
      *if nonkids > 30
        thirty
      *if nonkids <= 30
        half your
      outlaws to protect it as soon as it passes from the road into the wild.  
    You also send a party of hunters led by
    *if simzstalk
      *set hambush +3
      ${simon}, 
    *if elery > 0
      Elery, 
      *set hambush +2
    Ciels and Alira to range discreetly within eyeshot of the mules.  Their official task is protection; their secret one is to assess the possibilities for using the terrain to entrap the Keriatou.
    
    When they return, the hunting party
    *if not(simzstalk)
      are still nervous but offer a few
    *if simzstalk
      are bubbling over with
    ideas for how and where you could lure Hector's gang into an ambush along that route.
    *if simzstalk

      "We'll run all our mule trains up this valley," ${simon} declares, "where we can surround them without them knowing it.
      *if elery > 0
        Elery's found a dozen places we can hide fighters within earshot of the track.
      And Ciels found the stretch where the Keriatou will almost surely choose to attack.  Where the track is open enough for horses, but still confined enough that escape would be unlikely—and one where our raiders can hide on the high ground."
      
    *if kalstalk
      ${kalt} seizes on those ideas with ferocious enthusiasm, and drags the trackers into the Leaders' Tent with you the next morning for a six-hour grilling.  
      
      By the time you stagger out bleary-eyed to take some food, you've got both a plan and a level of confidence you'd lacked before.
      *set hambush +1
    *if (theurgy >= 10)
    
      Through every conversation, you're privately mulling whether you could use ${wisardry} to counter Hector's ambush.  Everything you can imagine doing to break a charging band of noble riders would be obviously supernatural—not the discreet ${wisardry} you've managed thus far. [i]Is it time to reveal myself?[/i] you wonder uneasily.
      
      You tell no one the decision you eventually come to, of course.
    *if com > 1
      You think your own contributions to the ambush planning will save a few lives, and perhaps cost a few more on Hector's side.
      *set hambush +2
    *if morale >= followers
      With the band's morale strong, you're ready to order the attack.
      *set hambush +2
      *goto sprungwhere
    *elseif morale > ((followers*2)/3)
      Considering the band's generally positive morale, you decide to order the attack.
      *set hambush +1
      *goto sprungwhere
    *elseif morale > (followers/2)
      *set hambush -1
      Despite the band's struggling morale, you push forward with the attack.
      *goto sprungwhere
    *else
      Despite the band's dismal morale, you push forward with the attack.
      *set hambush -3
      *goto sprungwhere
    *label sprungwhere

    On the afternoon that your trap is finally sprung, you're…
    *choice
      #Bait—trudging alongside the mules.
        *set hambush +2
        You're sweating profusely, thanks mostly to the padded leather jerkin and skullcap you're wearing over your other clothes.  The conspicuous armor is meant to protect you from arrows—and to encourage the attackers to leave cover.  You couldn't scavenge a leather neckpiece, though, so you've wrapped a brown scarf there in the hope that it'll look impenetrable from a distance.  The skin under the scarf never stops crawling.
        
        It's the third mule train you've accompanied along this route. You're just about to exit the stretch where your hunters thought an attack most likely.  Surely Hector and his veneurs are still hunting you…but their persistent absence has you beginning to worry.  What if they've seen through your ambush plans?  What if they've hunted down your archers in the woods, and will be coming for you once that's done?
        
        Then as the track begins to traverse a rugged, open slope below a densely wooded hill, you hear a reverberant blast on a hunting horn.  Whirling to face the sound, you feel relief alongside the jolt of battle-fear—as you'd hoped,
        *if aristo
          cousin Hector has
        *if helot
          the Keriatou and his veneurs have
        opted to ride you down rather than pick you off from hiding.  [i]Now,[/i]
        *if simzstalk
          [i]${simon}[/i],  
        *if not(simzstalk) and (elery > 0)
          [i]Elery[/i],
        *if not(simzstalk) and (elery < 1)
          [i]Ciels[/i],
        [i]just get down here before they kill us![/i] Zvad at the rear and Radmar in the van are bellowing orders and pulling the frightened, balky pack animals into a circle behind you.  Every outlaw scrambles to retrieve a wooden pike and shield from the back of the nearest mule.
        
        Half a mile back along the mule-path, the noble riders storm into view with ear-splitting howls and whoops.  Some are brandishing hunting lances, others short bows.  Riding at their head, the kermes-clad Hector Keriatou blows his horn once again. Then he draws his sword, and even from the distance, you can hear his roar clearly: "[i]Gut the swine!  Take their heads![/i]"
        
        The twelve wide-eyed young bandits around you shift from foot to foot.  Most don't know about the ambush plan; they think you're facing Hector alone. "$!{addressu} ${fname}?" one of them croaks.
        *if com > 0
          You glance around you.  There's enough space between the track and the thick forest that they might well be able to flank your little band, but not at any great speed—not on that craggy and tree-dotted slope.  
          *if com > 1
            Hector will likely try to ride you down on the mule-track, trusting that your helots will break.
        *if com = 0
          You try to suppress your own fear and remember what you'd agreed with Zvad.
        *choice
          #I shout, "Set spears!" and let the nobles close for combat.
            *label zvadspear
            Zvad musters the bandits closest to him into a V-shaped line of spears.  Just behind them, the remaining handful shakily raise shields overhead to protect themselves and their companions.
            *if int = 2
              The veneurs thunder ever nearer.  The first half-dozen of their arrows slice the air, and while most clatter off shields, one pierces the arm of the boy next to you.  He screams, and you can see your frightened followers turning to look to him.
              *choice
                #I shout, "Hold! Keep formation!"
                  It's no good. The terrified outlaws see each other waver, and their spear wall collapses in disarray.  
                  *if parley
                    Any hope you had of parley with Hector Keriatou is gone.
                  In half a minute the noble hunters will ride you down.
                  *if theurgy >= 10
                    If you're going to stop them with ${wisardry}, it'll need to be something dramatic—nothing discreet would work now.
                  *choice
                    #I use ${wisardry} to unseat Hector and those closest to him.
                      *label treeunseat
                      *if theurgy < 2
                        *label theufail
                        You cut your hand and try to remember the incantation from the scroll. "I see myself without a mirror…" but you can't remember it all, it's been too long since you last practiced it, and fear scatters your thoughts like dry leaves.  There's no time, not nearly enough.

                        Zvad's shoulder is the final interruption, knocking the wind out of you.  The big ${whend} has seen you frozen and taken matters into his own hands.  
                        *label spearintheback
                        Borne up and away like a sack of barley, you're still trying to regain your breath when the horses thunder into your fleeing party, and everything is lost in dust and shrieks.

                        You don't recognize the jarring, hot sensation in your back until it reverses—becomes a pull, a howling agony like nothing you've ever imagined.  Above and behind you, a noble roars a curse, losing her grip on the spear stuck in your ribs and spine.

                        As the spear shaft swings free, you feel the blade twist excruciatingly inside you, and the world goes black.
                        *goto_scene death
                      *if blood > 0
                        *gosub theuhurry
                      *set hectheu 1
                      There's a fallen pine along the side of the
                      *if close
                        mule-track.
                      *if not(close)
                        mule-track—rather closer to you than you'd like, but you don't see a better opportunity at long distance.
                      To the eyes of a ${wisard}, it's a skeleton laced with elemental fire, pent up in its dry sap and needles.  You thrust your bloody fist toward it and urge the fire in two-thirds of the trunk upward.

                      The spin you create by rapidly levitating only part of the tree sends it cartwheeling up and outward across the path, into the faces of the horrified riders.
                      *if cuthand
                        In that instant you feel sure that if only you drew on more of your own blood, you might be able actually to ignite the tree.
                        *choice
                          #I grit my teeth and push the latent fire into life.
                            *set hectheu 2
                            *set myblood +1
                            For anything less flammable than a dry pine, you don't think you could have coaxed a fire out of it—and as it is, the fleeting burst of flame only consumes the needles before you reach the verge of unconsciousness and let go.  But you're sure that the fireball and smell of scorched hair will add to the visceral shock of seeing comrades unhorsed by a tree.
                            *set hambush +2
                            *if hectarg
                              *set hambush +1
                            *goto treeknockout
                          #No—I don't want to risk falling unconscious.
                            You release the power quickly before you begin to feel drained.
                            *goto treeknockout
                      *label treeknockout
                      
                      *if hectarg
                        Hector Keriatou and the
                      *if not(hectarg)
                        The 
                      two riders just behind
                      *if hectarg
                        him
                      *if not(hectarg)
                        Hector Keriatou
                      vanish with human and equine shrieks and the sound of branches splintering.  Dust hides most of the bloody aftermath.
                      *if not(hectarg)
                      
                        Hector twists in the saddle to see what's gone wrong, then reins in his horse abruptly.  You can see in his wide eyes the realization that your ${wisardry} has momentarily cut him off from the rest of his veneurs.
                        *choice
                          #I levitate him from the saddle.
                            *label heclev
                            *if blood > 0
                              Do you use a phial, or your own blood?
                              *choice
                                #A blood phial.
                                  *set blood -1
                                  *set usedblood +1
                                  *goto hectorfly
                                #My own blood.
                                  *set myblood +1
                                  *goto hectorfly
                            *label hectorfly
                            *if myblood > 1
                              The strain is too much.  You've barely lifted Hector before you fall unconscious.
                              *set hambush -2
                              *goto wakeup
                            Hector manages to keep hold of the reins and his wits despite the shock of being pulled suddenly upward. "To me, to me!" he howls, flapping like a crimson flag in the wind.
                            *if theuknown > 5
                              *if aristo
                                "My demon cousin
                              *if helot
                                "The demon ${lname}
                              is here!  Kill ${him} now!"
                            *choice
                              #I order one of our archers to drop her spear and put an arrow in Hector.
                                *if hector >= 4
                                  You hope your bandits don't notice or consider the way your voice cracks when giving the order.
                                  
                                It's no easy shot given the wind, Hector's writhing, and his terrified horse rearing up.  The shaken young outlaw only manages to graze the Keriatou's leg.
                                *goto veneurcharge
                              #I reverse the levitation and send him crashing onto the dusty track.
                                Focusing on the heavy elements in the blur that is Hector, you pull 
                                *if aristo
                                  your cousin
                                *if helot
                                  the Keriatou
                                down as sharply as you beckoned him upward. He bounces off his horse with a wail and slams into the dirt.
                                *set hecslam true
                                *goto veneurcharge
                              #I try to tear him away from the horse and send him higher.
                                Gritting your teeth, you increase the upward pull on Hector. 
                                *if aristo
                                  Your cousin
                                *if helot
                                  The Keriatou
                                pulls himself howling down the reins and knots one fist in his horse's mane just as the corded leather snaps.  The animal rears up, whinnying in pain and fear.
                                
                                *goto veneurcharge
                            *label veneurcharge
                            Then the next three veneurs emerge from the dust cloud. They
                            *if hectheu = 2
                              are manifestly terrified, but
                            surround their
                            *if hecslam
                              fallen leader with weapons drawn.
                            *if not(hecslam)
                              leader and pull him down, shielding him with their bodies.
                            
                            "It's ${orig_lname}!" howls Hector 
                            *if theuknown > 5
                              again
                            *if hecslam
                              from somewhere in the dust, voice cracked and wheezing.  "Leave me,
                            *if not(hecslam)
                              as they drag him backward.  "Let go of me,
                            damn it! Charge!  Take ${him} now!"
                            
                            *if hectheu = 2
                              You think if you hadn't set the tree alight, they would have done it; the balance between rage and terror in their expressions is fine indeed.  But they keep an uneasy distance, and one shakily shouts, "Fill them with arrows!"  Your young outlaws curse and fall back, raising their shields again.  As they jostle around you and arrows clatter off wood, you lose any Theurgic sense of Hector Keriatou.
                              
                              Just when you're sure the nobles are about to regain their nerve and charge, a flight of arrows falls into their own midst from the woods.  Two veneurs fall from their horses; the survivors yell in shock, wheel about, and ride frantically for Rim Square.
                              *if (simzstalk) and (s_rel < 5)
                                ${simon}
                              *if ((not(simzstalk)) or (s_rel > 3)) and (elery > 0)
                                Elery
                              *if ((not(simzstalk)) or (s_rel > 3)) and (elery < 1)
                                Ciels
                              and the ambush party feather one or two more before they ride out of sight.
                              *label zvadwhoop
                              *if (theuknown < 5) and (hectheu > 0)
                                *gosub theureveal
                              *page_break
                              Zvad joins the ecstatic whoops of your small party of muleteers, then doubles over coughing.  "Damn the dust," he rasps, still smiling as he spits thickly onto the ground.  "I'll be tasting this fight for a week."
                              
                              Your own heart has not stopped hammering, but you satisfy yourself that your Abler is attending to the injured, then bring a waterskin to Zvad. 
                              *if holdfast > 0
                                "They held."
                                
                                The big ${whend} shakes his head.  "You were right, ${addressu}.  Didn't expect they'd stand shoulder to shoulder against a charging horse, even after
                                *if sybla > 0
                                  Sybla's and
                                my time with them.  But they found the brass somewhere."
                                
                              *if holdfast = 0
                                "The spear wall needs work."
                              
                                The big ${whend} shakes his head.  "Takes a lot of drill and a lot of trust before you'll stand shoulder to shoulder against a charging horse, ${addressu}. We knew that.
                                *if sybla > 0
                                  Sybla didn't pretend she'd
                                *if sybla = 0
                                  I haven't yet
                                got them that far." Rinsing out his mouth, he spits again, then nods off to where the whoops of the pursuing ambushers can be heard in the woods.  "Could have gone badly if they'd been any later. Or if you'd not 
                                *if int > 1
                                  been a ${wisard}."
                                *if com > 1
                                  pushed the Keriatou back."
                                *if cha > 1
                                  kept the Keriatou talking as long as you did."
                                
                              *if (simzstalk) and (s_rel < 5)
                                You're interrupted by the voice of ${simon} de Firiac: "$!{kuria}—${kuria} ${lname}? How have you all fared?  Where is the ${kuria}?"  $!{zhe}'s been running at a sprint from the forest. As ${zhis} eyes fall on you, an enormous smile bursts across ${zhis} dust-streaked face. "Thank Angels."
                                *set hambush -2
                                *choice
                                  #"The plan came off," I say, grinning back. "Thanks for the timely arrows."
                                    "I hope they were as timely as you say." $!{simon} wipes sweat from ${zhis} brow and glances around the chaos of the mule train. "We could have come closer before shooting them, ${addressu}—probably felled more with that first volley."
                                    
                                    "If you'd waited, we'd likely have been under their hooves."  
                                    *label shriekwave
                                    From down the dusty track you can hear, faintly, another wave of shrieks. "Who's leading the second ambush?"  You'd have expected ${simon} to be leading one wave or another of the ambushers, not pausing here to confirm your welfare.
                                    
                                    *if elery > 0
                                      "Elery,"
                                    *if elery < 1
                                      "Ciels,"
                                    ${simon} declares. "They should be able to hold them at the draw, long enough for the rest of us to come up from behind.  Forgive me—I must join them."  $!{zhe} turns on ${zhis} heel and runs down the mule-path.
                                    
                                    *if int = 2
                                      You and Zvad follow ${zhim} a few moments later, as far as the place
                                      *gosub finishfallen

                                    It's a few hours before the ambushers return.
                                    *goto ambushreturn
                                    
                                    *label finishfallen
                                    where your catapulted pine came to rest.  The felled horses are thrashing, with broken ribs and limbs; one has a crumpled corpse still caught in the saddle.
                                    *if hectarg
                                      You quickly confirm that it's not Hector, nor is your
                                      *if helot
                                        former master
                                      *if aristo
                                        cousin
                                      anywhere to be found.

                                    As your outlaws end the animals' misery, you walk over to the second veneur: Ganelon Tarakatou.
                                    *if helot
                                      The only lordling in Rim Square to have spoken with you, beyond a word or two.
                                    *if aristo
                                      Quiet, thoughtful Ganelon, who might have been your closest friend but for your father's hatred.
                                    The reason you discovered ${wisardry} in the first place.

                                    Now he stares up at you, glassy-eyed, hands clenched around the snapped-off pine bough impaling his abdomen.  
                                    *if aristo
                                      "$!{orig_lname}…is
                                    *if helot
                                      "T'Keriatou…is
                                    that you?"  His voice is ragged with fear and thirst.
                                    *set sa_foll 906
                                    *choice
                                      *if aristo
                                        #"It's me, Ganelon," I say hoarsely, kneeling beside him.
                                          *label ganelontrap
                                          *set sa_foll 908
                                          The dirk in Ganelon's left hand, concealed behind bloody rags, comes within a hairsbreadth of your great-vein.  Even your reflexes might not have saved you if Zvad hadn't met the dying youth's lunge with a boot in the chest, knocking him prone.
                                          
                                          You spring backward while Ganelon rolls shrieking on the ground.  "Xthonos damn you!  You've murdered 
                                          *if theuknown > 5
                                            me…Goete, monster!  
                                          *if theuknown <= 5
                                            me…traitor, monster!
                                          Hector will kill y…."
                                          
                                          Zvad brings his maul down twice. "Have a care, ${addressu}," he says bluntly. 
                                          
                                          From behind you, Radmar adds, "That would have been a damned silly way to die."
                                          *choice
                                            *if aristo
                                              #I find myself stricken silent.  The wild hatred in Ganelon's voice, his terrible death…he was a fellow noble, a friend.
                                                *set sa_foll 910
                                                You take a moment to collect yourself.  At last you say aloud, levelly, "It's no light thing to kill a one-time friend."
                                              
                                                "True spoken, ${addressu} ${lname}," rumbles Zvad.  "Yet you did it without pause, when every outlaw here was ready to run.  No shame to you."  When you turn, you see the big ${whend} sternly eyeing Radmar, who returns to sullen silence.
                                                *return
                                            #I give a bleak nod. Why did I act as if a fatal wound make the Tarakatou veneur any less my enemy?
                                              *set ruth %+5
                                              *return
                                            #"It's worth taking some risks to comfort and honor the dying—lest we risk losing what makes us human."  I look pointedly at Radmar.
                                              Radmar glares back. "What makes me human is that I breathe and eat and think.  You'd have lost that just now, if it hadn't been for Zvad, ${kuria}."
                                              *if arrog > 0
                                                He stalks off, leaving you fuming silently at his unpardonable insolence.
                                              *set ruth %-5
                                              *return
                                            *if arrog > 0
                                              #I whirl on the insufferable helot.  "Damn your eyes, boy.  He was worth ten of you.  Worth a moment's trust."
                                                Radmar's lips peel back in a grimace, and he looks around meaningfully at the other helots in your band. "Ten of us, eh, ${kuria}?  I thought we'd left that sort of talk behind."
                                                
                                                "Ten of you, boy."  Infuriated by his attempt to intimidate you, you press on forcefully.  "Your carping, sullen, insolent, ignorant self, with your constant sour words and bucking at authority.  No leader, noble or common, could rely on such as you!"
                                                
                                                The big helot's eyes blaze with fury, and he takes two steps toward you—before Zvad moves to your side, raising his eyebrows and his bloodied maul.  Then Radmar halts, breathing thickly through flared nostrils.  "I'll show deference to any leader who earns it, [i]${kuria}[/i]."  He begins to stalk away even while he hurls the last word at you, heavy with scorn.
                                                *set r_rel -2
                                                *set cred_h -5
                                                *return
                                      #"Aye, Tarakatou.  It's me."
                                        Ganelon's eyes focus, flickering back and forth between you.
                                        *if com > 0
                                          You realize he's gauging the distance.  Reaching out with your ${weapon}, you move aside the bloody rags around his left hand to reveal a small dirk.  
                                          
                                          The dying noble sags backward, releasing the concealed blade.
                                          *if helot
                                            "Xthonos damn you, ${girl}.
                                          *if aristo
                                            "Should have known…you trust as little as your damned father.
                                          Finish me and have done."
                                          
                                          *set sa_foll 907
                                          *if aristo
                                            "What took you out of your books, Ganelon?" you ask, feeling suddenly bereft. "What turned you into this…'veneur'?"  You can't reconcile the bookish boy from your childhood with the image of Glena staked to a tree.
                                            
                                            His dry laugh is cut off in a spasm of pain.  At length, the young Tarakatou whispers, "You…can ask?
                                            *if theuknown < 10
                                              With whatever Goety you just turned on us?
                                            What in all our books turned…you into the unnatural beast that you have become?"
                                            
                                            "Haven't you guessed?" you say, a little sharply; he had tried to kill you, was still trying to hurt you.  "[i]Nature beyond nature. I see the world without its masks[/i].  You might have seen it too."
                                            
                                            Ganelon clearly hadn't guessed.  His mouth goes slack as you quote the much-mocked scroll.  "Then…in truth
                                          *if helot
                                            You search his face for any trace of that affinity which you had shared in your talks.  "Kurios…I remember you as one who was always ready to share learning with a helot." It's hard to reconcile your memories of the avid, soft-spoken scholar with the image of Glena staked to a tree.
                                            
                                            "Would that I had known…what you truly were." Ganelon's face contorts with pain. "If I encouraged you in your arrogance,
                                          this is my just penalty.  How much worse…will your torment be?"  The hatred in his stare is unnerving.
                                          *if helot
                                            *choice
                                              #"Encouraged me?  More than that, milord."  You quote the scroll he gave you: "[i]Nature beyond nature. I see the world without its masks[/i]. Understand it now?"
                                                Ganelon's mouth goes slack, then he rolls himself over with a shriek and pushes.  "Ah, Angels forgive me!" he howls.  You
                                                *goto zvadganmaul
                                              #I don't tell him.  What point in adding to his torment?
                                                *goto loveknowgan
                                              #I'd happily salt his wounds—but I don't want to give even the slightest hint to my fellow outlaws of how ${wisardry} works.
                                                *goto loveknowgan

                                          *label loveknowgan
                                          "We both loved knowledge as few do, 
                                          *if aristo
                                            Ganelon,"
                                          *if helot
                                            kurios,"
                                          you say, stepping back. 
                                          *if aristo
                                            Tears burn just behind your eyes.  "And we both had few friends because of it. I
                                          *if helot
                                            "I 
                                          suppose it was foolish to hope that that could ever unite us." You hadn't realized until this moment how deeply that hope had taken root.
                                          
                                          When his eyes glaze over again with agony, you 
                                          *label zvadganmaul
                                          nod to Zvad, who ends Ganelon's misery with a blow of his maul.
                                          *fake_choice
                                            #Grief hits me like a landslide.  I can't breathe or see.
                                              *set sa_foll 910
                                              *if aristo
                                                The young nobles of Rim Square were for the most part a preening, shallow bunch, vying for your cousins' attention.  Ganelon never allowed himself to be drawn into those games.  In particular, you don't remember him ever joining when Calea led the rest in mocking you.
                                                
                                                While Father's grudges forced you apart, you always assumed that you and Ganelon would become closer in time.  If not before, it would happen once your father grew frail or passed away.  One day you'd open your libraries to each other, spend long afternoons over cups of Sorettyn on a balcony, debating the things that truly mattered.  One day you'd have a friend.
                                              *if helot
                                                You'd had few enough friends as a ${girl}, and none with much interest in debating the things that mattered—the truths of the wider world, all the things that you could experience only in books.  You'd never fostered much hope of finding such a friend, not until you met
                                                the 
                                                *if not(malepref)
                                                  serious 
                                                *if malepref
                                                  beautiful
                                                young Tarakatou.  
                                                
                                                It was unthinkable—ridiculous!—to imagine an aristo and a helot sustaining a friendship.  Every philosopher counseled that true friend-love could emerge only between equals.  But for a time, you'd thought the books mistaken.
                                                
                                              You press your fingers against your skull and try to blink away the stinging blur.  The world feels empty but for the smoke in your nostrils, senseless chatter against your ears.  At last you force yourself back into the unbearable present with its unfinished battle.
                                            #I spit on the corpse, wishing I could kill the traitor a second time.
                                              *set sa_foll 909
                                              *if aristo
                                                How different the 
                                                *if not(malepref)
                                                  serious 
                                                *if malepref
                                                  beautiful
                                                young Tarakatou had seemed from the preening coterie around the aristarchs.  He'd always held back from their little games, especially the contests of escalating scorn and cruelty that your cousins encouraged in their darker moments.  You'd hoped he would be a 
                                                *if not(malepref)
                                                  friend.
                                                *if (malepref)
                                                  friend, if not more.
                                                
                                                Yet in the end, 
                                              *if helot
                                                *if malepref
                                                  Beautiful young
                                                Ganelon had been the one young noble who'd given you some hope—some idea that They might one day offer you some crumb of respect.  And 
                                              he took the first chance he had to join Hector Keriatou's gang of torturers.
                                            #He meant little to me, and his death means less.
                                              I turn briskly away from the broken young noble.  This battle's not done yet.
                                          *return
                                        *else
                                          *comment if com = 0
                                          He mutters something hoarse and unintelligible, ending in "…water."
                                          *choice
                                            #I crouch to give him a waterskin.
                                              *set ruth %-5
                                              *goto ganelontrap
                                            #I walk away.  Let him die slowly, as Glena did.
                                              *set ruth %+10
                                              *if aristo
                                                *set ruth %+10
                                                Your one-time friend
                                              Ganelon's howls and curses quickly weaken; from back at the mule train, you can't hear them at all.
                                              *return
                                            #I end his life wordlessly.
                                              You
                                              *goto zvadganmaul
                                      #"This is for Glena—the girl you 'veneurs' slaughtered."  I kick the bough.
                                        *set sa_foll 909
                                        *set ruth %+10
                                        Ganelon shrieks in unutterable agony.  His hands fly wide—one of them losing its grip on a dirk that had been hidden in bloody rags near his wound.  Clearly, he'd been hoping for a last chance to stab at you. There's no opportunity to gloat over his failure, though; the young noble lolls unconscious, overwhelmed by pain. 
                                        
                                        "He'll be dead in minutes," Radmar observes coolly from behind you.  "You've been kinder to him than he was to Glena, ${addressu}."
                                        
                                        "By the time we're done with them all, they'll have paid the full price," you promise.
                                        *return
                                      #I end his life wordlessly.
                                        *if aristo
                                          Whatever fragile bond you and Ganelon Tarakatou shared was broken long before now; you don't want even to speak to the dying youth.
                                        You
                                        *goto zvadganmaul
                                  #I run up and throw my arms around ${zhim}. "We're alive—because of you."
                                    ${simon} almost falls down with surprise, then gingerly returns your embrace, almost as if ${zhe}'s afraid that touching you will cause you to flee.  "I…it was only…"  $!{zhe} clears ${zhis} throat, wide-eyed.  "You were acquitting yourself rather well, I thought, ${addressu}."
                                    
                                    "Nonsense."  There's a growing warmth in your blood; you reluctantly let go of the young noble while you still can. The former helots around you share meaningful glances, but no one here seems to begrudge you the show of affection after ${simon} saved your lives.  "We would have been under their hooves if you'd waited any longer."
                                    *goto shriekwave                                
                                  #"Why aren't you leading the pursuit, de Firiac?" I demand harshly.
                                    *set s_rel 4
                                    *set simz_lead -1
                                    All expression vanishes from ${simon}'s face.  "To see if…${addressu},
                                    *if elery > 0
                                      Ciels is leading them, and Elery
                                    *if elery < 1
                                      the pursuers just need to set a strong pace.  Ciels
                                    is ready to lead the second ambush at the draw.  They're capable enou…"
                                    
                                    "For Angels' sake, de Firiac," you bark, "stop talking—and lead where I sent you to lead!"  You can't believe the lovestruck noble chose to confirm whether you were alive, even when it took ${zhim} away from ${zhis} party.
                                    
                                    "$!{addressu}."  Visibly shamed, ${zhe} dashes away. 
                                    
                                    *if int = 2
                                      You and Zvad follow ${zhim} a few moments later, as far as the place
                                      *gosub finishfallen
                                      *page_break
                                    It's a few hours before the ambushers return.
                                    *goto ambushreturn
                              *elseif simzstalk and (s_rel > 4)
                                *if int = 2
                                  His eyes flicker toward the screaming horses, and the two of you walk up the track
                                  *gosub finishfallen
                                
                                It's a few hours before ${simon} de Firiac returns, leading both parties of ambushers—${zhis} own small band, which saved your lives here, and a second one led by
                                *if elery > 0
                                  Elery, 
                                *if elery < 1
                                  Ciels, 
                                *label narrowdraw
                                which had cut off your enemies' retreat at a narrow draw.
                                *goto ambushreturn
                              *else
                                *if int = 2
                                  His eyes flicker toward the screaming horses, and the two of you walk up the track
                                  *gosub finishfallen
                                
                                It's a few hours before
                                *if kalstalk
                                  ${kalt},
                                *if elery > 0
                                  Elery
                                *if elery < 1
                                  Ciels 
                                and both ambush parties return—the small band which saved your lives here, and a second one
                                *goto narrowdraw
                              *label ambushreturn
                              *if hambush > 11
                                *set morale +10
                                Their jubilation is obvious from a hundred yards away.  "Every single veneur, ${addressu}!" crows Ciels.  "And they broke without felling a single one of us.  None of them will trouble us again."
                                *label andhector
                                *set sa_foll 903
                                
                                "And Hector?" you demand,
                                *if hector >= 4
                                  hoping the thickness in your throat isn't audible to the others.
                                *if hector < 5
                                  feverish with hope.

                                "The one body we didn't find,"
                                *if simzstalk
                                  ${simon} says flatly.
                                *if kalstalk
                                  ${kalt} shrugs.
                                *if not(simzstalk) and not(kalstalk)
                                  *if elery > 0
                                    Elery
                                  *if elery < 1
                                    Ciels 
                                  admits ruefully.
                                "But if he lives…let him crawl back and try to find more volunteers to die at our hands!"  The other outlaws erupt in raucous cheers, swarming round to clap 
                                *if simzstalk or kalstalk
                                  ${zhim} 
                                *if not(simzstalk) and not(kalstalk)
                                  *if elery > 0
                                    she
                                    *set el_lead +2
                                  *if elery < 1
                                    ${him}
                                on the back.
                                *if simzstalk
                                  ${simon} looks incredulous, then grins in relief at the enthusiastic show of acceptance.
                                  *set simz_lead +2
                                *if kalstalk
                                  ${kalt} grins fiercely and grips the hands of each former helot in turn.
                                  *set kal_lead +2
                                
                                *if hector < 5
                                  While disappointed that Hector seems to have slipped your trap, you can't let it cast a pall on the day's victory.
                                *if arrog > 0
                                  "The fallen
                                *if arrog < 1
                                  "Our sisters and brothers
                                are avenged!" you bellow.
                                *if hector >= 4
                                  The joy in your voice hides the relief you can't help feeling at your cousin's survival.
                                "They 
                                *set hec_cred 9
                                *set cred_h +10
                                *set cred_y +10
                                *set cred_a -5
                                *label thoughtgame
                                thought we were their game—that they could hunt us with no more consequence than a boar or stag.  Now let the world know: [i]we are hunters[/i].  We are warriors.  And we will not be slain without cost!"  The bloodied band around you howl and shake their bows and spears in the air.
                                *if arrog > 0
                                  You try to silence the qualm that speaks in your father's voice: [i]What do we unleash by teaching helots to see themselves as hunters of nobles?[/i]
                                *goto reinforce
                              *elseif hambush > 9
                                *set morale +8
                                *set followers -2
                                *set nonkids -2
                                *set dead +2
                                Their smiles as they draw near are triumphant.  "Three of the veneurs crawled off wounded, ${addressu}," Ciels reports.  "All the rest of them fell—and we've only lost two.  I doubt they'll trouble us again."
                                *goto andhector
                              *elseif hambush > 6
                                *set morale +2
                                *set followers -7
                                *set nonkids -7
                                *set dead +7
                                They look weary but satisfied.  "We brought down a few more, ${addressu}," Ciels reports.  "Bloody Hector escaped, with six others—most of them wearing an arrow.  Even if they all survive, I doubt they'll trouble us again without an army at their backs."
                                *label howmanylost
                                *set sa_foll 902
                                 
                                "Well fought.  And how many did we lose?" you ask, scanning the party.
                                *if hector > 5
                                  You hope you've managed to hide the relief you can't help feeling at your cousin's survival.
                                
                                "Seven,"
                                *if simzstalk
                                  *set simz_lead +1
                                  ${simon} declares somberly. "Good warriors all, and true."
                                  *if s_rel < 5
                                    The guilt is plain in ${zhis} face; how many fewer might have fallen had ${zhe} been there from the moment the battle was joined?
                                *if kalstalk
                                  *set kal_lead +1
                                  ${kalt} says curtly. "But believe me, they'll feel their loss more than we feel ours."
                                *if not(simzstalk) and not(kalstalk)
                                  *if elery > 0
                                    *set el_lead +1
                                    Elery says, her eyes flashing defensively. "And if it takes two of us for every one of them…I call that a good fight."
                                  *if elery < 1
                                    Ciels says flatly. "More than we will next time, ${addressu}."

                                "Well fallen—and well fought," you repeat to the band.  "Before today, 
                                *if helot
                                  the nobles 
                                *if aristo
                                  my cousins
                                *set hec_cred 11
                                *set cred_h +5
                                *set cred_y +5
                                *set cred_a -2
                                *goto thoughtgame
                              *elseif hambush > 4
                                *set morale -8
                                *set followers -12
                                *set nonkids -12
                                *set dead +12
                                *label miseryambush
                                *set hec_cred 21
                                Their misery is clear even from a distance.
                                
                                You stride out to meet them on the mule-track, searching for the missing faces.  "What happened?"
                                
                                "The second group loosed arrows too soon,"
                                *if simzstalk
                                  ${simon} says in a low voice.
                                  *if s_rel < 5
                                    The guilt is plain in ${zhis} face; how many fewer might have fallen had ${zhe} been there from the moment the battle was joined?
                                *if kalstalk
                                  ${kalt} growls.
                                *if not(simzstalk) and not(kalstalk)
                                  *if elery > 0
                                    Elery says grimly. 
                                  *if elery < 1
                                    Ciels says, flat-voiced.
                                "One more veneur went down—but the others rallied round Hector and found cover.  They killed
                                *if hambush > 4
                                  twelve
                                *if hambush < 5
                                  twenty
                                of us and fought free."
                                
                                "How do a few injured, ambushed nobles kill that many?" you demand in disbelief.                                
                                *label betterthanus
                                *set sa_foll 901
                                
                                "By being better than us."  Ciels 
                                *if (elery > 0) or (simzstalk or kalstalk)
                                  speaks up without meeting
                                *if (not(simzstalk) and not(kalstalk)) and (elery < 1)
                                  doesn't meet
                                your gaze.  $!{his} despair hangs over the whole band.
                                
                                Over the next few weeks, you switch to a defensive posture, doing whatever you can to conceal your mule trains from Hector and his gang.  No one has the stomach for a more aggressive approach to the Keriatou anymore.
                                *goto reinforce
                              *elseif hambush > 2
                                *set morale -10
                                *set followers -20
                                *set nonkids -20
                                *set dead +20
                                *goto miseryambush
                              *else
                                *set morale -10
                                *set followers -31
                                *set nonkids -31
                                *set dead +31
                                *set hec_cred 21
                                It takes several minutes before you realize that the wretched handful limping toward you will not be joined by others.
                                
                                "What happened?" you demand, almost inaudibly, when they reach you.
                                *label wewererouted
                                
                                "They routed us, ${addressu},"
                                *if simzstalk
                                  ${simon} says miserably.
                                  *if s_rel < 5
                                    The guilt is plain in ${zhis} face.
                                    *set simz_lead -3
                                *if kalstalk
                                  ${kalt} snarls, ${zhis} face drawn with rage.
                                *if not(simzstalk) and not(kalstalk)
                                  *if elery > 0
                                    Elery says dully. Some hope has died in her that will not easily be rekindled.
                                    *set el_lead -3
                                  *if elery < 1
                                    Ciels gulps, tears streaking ${his} face.
                                *if kalstalk
                                  "The bastards had recovered by the time they reached us.  Hit us hard."
                                *if not(kalstalk)
                                  "We…they charged us, and we came to pieces."

                                You scan the survivors of the catastrophe.  Thirty…thirty-one gone?  "How?  How did they kill so many?"
                                *goto betterthanus
                              
                            *if hectheu != 2
                              The veneurs roar their assent.  Six mounted nobles abandon Hector 
                              *label venchargeyou
                              and charge straight for you.  Your scattered bandits resume their mad dash for cover—all save Zvad, who stands at your shoulder, shield raised high. 
                              
                              If you don't join them, you'll need to use ${wisardry} again, even more decisively.
                              *choice
                                *selectable_if (blood > 0) #I use a blood phial.
                                  *set blood -1
                                  *set usedblood +1
                                  *goto targethorse
                                #I use my own blood.
                                  *set myblood +1
                                  *if myblood > 1
                                    The strain of attempting ${wisardry} is too much.  As hard as you resist, you find your consciousness seeping away with your blood.  You grope at Zvad, sway, and collapse.
                                    *set hambush -4
                                    *goto wakeup
                                  *label targethorse
                                  *gosub blindhorse
                                  Your fleeing bandits hear it, pause in their flight, and then run back down the hill howling and waving their fists at the veneurs' rears.
                                  *goto zvadwhoop
                                  *label blindhorse
                                  The blood vaporises from your palm, and you desperately search the blur of the veneurs' charge for something you recognize enough to Change.  As you stare into their steeds' black eyes, your study of optics leaps to mind; the horses' eyes (like yours and everyone else's) emit light in order to see.  You focus until you can see that light, reach out with your mind, and cut it off.
                                  
                                  Only a few seconds before overrunning you, the blind horses break off their charge with whinnies of terror.  All of the veneurs are expert riders, and manage to keep their saddles despite their frantically bucking mounts.  But all their energies are spent on controlling their horses.  You fight to keep the animals blinded as their heads whip back and forth, in and out of your field of vision; you can feel the light pushing back from their eyes as your blood dries.
                                  *set hambush +2
                                  
                                  Then at last the arrows begin to fall around your enemies.  There aren't many; you suspect that 
                                  *if (simzstalk) and (s_rel < 5)
                                    ${simon}
                                  *if ((not(simzstalk)) or (s_rel > 3)) and (elery > 0)
                                    Elery
                                  *if ((not(simzstalk)) or (s_rel > 3)) and (elery < 1)
                                    Ciels
                                  and the ambush party are holding back to avoid hitting you.  But even a few arrows are enough to spur a retreat by the appalled young nobles.  
                                  *return
                                #I run for the trees.
                                  *label runfortrees
                                  You sprint for cover, faster than you've ever run, and for several frantic moments you believe you're going to make it. You don't understand why your leg gives way beneath you. The arrow you see juddering in the flesh of your thigh doesn't hurt, hardly feels like anything at all.
                                  
                                  Then Zvad is there, hoisting you wordlessly onto one broad shoulder.
                                  *goto spearintheback
                            *goto zvadwhoop
                          #I roar, "Take him now!" and lead a charge of spear-wielding outlaws.
                            *if com = 0
                              Your modest charisma is just enough to bring the rest of the band after you. Zvad is at your side and Radmar close behind…which should hopefully make up for the fact that you don't know have the first idea what you're doing with your spear.
                              
                            Give Hector credit for courage: he doesn't falter even when outnumbered by more than a dozen to one.  He blows three quick blasts on his horn and bellows, "$!{orig_lname}!  The 
                            *if theuknown > 5
                              demon 
                            *if theuknown <= 5
                              beast
                            ${him}self has stuck ${his} neck out!  To me, to me!"  Then he 
                            *label heccourride
                            spurs his horse up the rugged slope at the trackside, trying to flank your little band.
                            *if aristo and (theuknown > 5)
                              "Your aim is no better with trees than with arrows, cousin," he sneers
                            *if aristo and (theuknown <= 5)
                              "You'd resort to Goety, you unnatural filth?" he snarls
                            *if helot
                              "I should have strangled you years ago, churl," he spits
                            at you.
                            *if aristo and (theuknown <= 5)
                              "May Xaos eat your bloody soul."
                            
                            Ignoring his insults, you charge your little party up the slope toward him.  The Keriatou heir sounds his horn again, then wheels his mount directly toward you.  You scramble to set your spear. It feels as flimsy as a reed in the face of Hector's thundering horse and raised sword.
                            
                            But you hold, howling at the top of your lungs to vent the terror that might otherwise undo you.  From behind you, you hear a chorus of other howls, and catch sight of bristling spears from the corner of your eye.  Against a single horseman, without arrows falling around them, your bandits have managed to hold the line.
                            
                            Hector veers away, a few yards from the end of your spear, close enough for you to see the savagely disappointed twist in his mouth. Radmar's hurled spear glances off the Keriatou's kermes-dyed leather vest.  At the same moment, you hear Zvad shout three muleteers' names and, "Circle up!"  The other surviving veneurs have emerged from the dust and are riding toward you, scattered but still formidable; the big $!{whend} is desperately trying to reform your spears to hold them off.
                            *set morale +3
                            *choice
                              #I use ${wisardry} to stop the veneurs.
                                *if blood > 0
                                  *gosub theuhurry
                                *if myblood > 1
                                  The strain of continuing to use your own blood is too much.  The last thing you hear are the cries of dismay and despair from your outlaws as you collapse.
                                  
                                  You never feel the hooves that trample your body into an unrecognizable heap.
                                  *goto_scene death
                                *gosub blindhorse
                                
                                *label hectorsag
                                Hector sags in his saddle, an arrow protruding from his shoulder. His eyes meet yours; the roil of fear, hate, and shame you see there makes you take an involuntary step back. Then he shrieks and spurs his horse into a gallop, charging past your stunned muleteers to rejoin the retreat of his veneurs.
                                *goto zvadwhoop
                              #I join Zvad in encouraging the outlaws to circle up.
                                *set followers -5
                                *set nonkids -5
                                *set dead +5
                                You lose three followers to the first charge of the veneurs. Only the awareness that you're surrounded, with Hector returning from your uphill flank, keeps the others from breaking. And with a sort of detached horror, you realize the next charge will be the end.
                                
                                "Xthon'damn 
                                *if kalstalk
                                  ${kalt}
                                *if simzstalk
                                  ${simon}
                                *if not(simzstalk) and not(kalstalk)
                                  you
                                for killing us with this plan," Radmar spits as the veneurs circle back again.
                                
                                Then, just as the nobles close for the kill, a shower of arrows falls all around you.
                                *if (simzstalk) and (s_rel < 5)
                                  ${simon}
                                *if ((not(simzstalk)) or (s_rel > 3)) and (elery > 0)
                                  Elery
                                *if ((not(simzstalk)) or (s_rel > 3)) and (elery < 1)
                                  Ciels
                                clearly felt they couldn't hold back to avoid hitting you, and two more of your bandits go down.  But a noble also falls, and the others veer off, howling, "Scatter! A trap, a trap!"

                                *goto hectorsag
                              #I call on them to keep chasing Hector.  If we bring him down now, the veneurs will break.
                                "Keriatou!" you howl.  "After him, after him!"
                                
                                Hector rides off, easily outpacing your shaken, confused band—and as his hoofbeats fade, the thunder of his veneurs' charge grows loud in your ears.  You turn too late to face them; the sight of your muleteers scattering is the last thing you take in before the spear in your neck cuts off voice, vision, and life.
                                *goto_scene death
                          #I shout, "The next one will be aimed at you, milord Keriatou.  Accept my mercy and flee."
                            Hector's face twists into something grotesque and savage.  "Mercy?" he snarls. "No mercy between us, Goete."
                            *if hector >= 4
                              Your eyes search his for an anguished moment and find 
                              *if hector = 5
                                nothing but loathing.
                              *if hector > 5
                                no trace of the affection that you've cherished so vividly in memory.
                            He blows three quick blasts on his horn and cranes his neck back to bellow, "$!{orig_lname}!  The demon ${him}self has stuck ${his} neck out!  To me, to me!"
                            *choice
                              #I levitate him from the saddle.
                                *goto heclev
                              #I lead a charge against him.
                                Give Hector credit for courage: he doesn't falter even when outnumbered by more than a dozen to one.  He sounds the horn again and
                                *goto heccourride
                              #I call over my own shoulder to the ambushers who I hope are in position: "Now would be a good time…"
                                Hector's eyes snap up to the woods for an instant, then back to you with a sneer. "What manner of fool do you take me for?"  The first of his veneurs ride out of the dust to his side.
                                
                                "Are…is someone truly there, ${addressu}?" whispers a terrified muleteer from over your shoulder, as Zvad tries to get them to reform the spear wall.
                                
                                *if (simzstalk) and (s_rel < 5)
                                  "${simon}
                                *if ((not(simzstalk)) or (s_rel > 3)) and (elery > 0)
                                  "Elery
                                *if ((not(simzstalk)) or (s_rel > 3)) and (elery < 1)
                                  "Ciels
                                and Alira and enough archers to send every veneur here to Taratur," you 
                                *if close
                                  growl.
                                *if not(close)
                                  repeat.
                                "If we can hold them but a minute more, you'll see the trap close on them."

                                The truth in your voice keeps them from breaking—and the sight of the previously panicking outlaws raising their spears to face him gives Hector pause, despite his scorn.  He holds a hand out, mutters something doubtful to his comrades. 
                                
                                Just when you're sure the young nobles have decided to charge, a flight of arrows whistles toward them out of the woods.  "Ambuscade!" Hector roars at once, wheeling his horse away and beckoning the others after him.  With yells of shock and at least two shrieks as an arrow finds a limb, the veneurs break frantically for Rim Square.
                                *goto zvadwhoop
                      *else
                        For long moments, nothing emerges from the haze but the shrieks of men and horses.  The veneurs on the far side have clearly halted their charge.  Then, just as you've begun to hope that you've stopped them, Hector's cracked voice rises from the cloud: 
                        *if (theuknown > 5)
                          *if aristo
                            "My demon cousin
                          *if helot
                            "The demon ${lname}
                          is here!  Kill ${him}!  
                        *if (theuknown <= 5)
                          "This Goety is feeble stuff.  Strangle the Xaos-swivers!
                        Ride, damn you all, ride!"
                        
                        Radmar curses at the top of his lungs as the remaining veneurs burst into view
                        *goto venchargeyou
                      
                      *label theuhurry
                      You cry out in a loud voice, and in that single instant, with every eye on you…
                      *choice
                        #I cut my hand.
                          *set myblood +1
                          *return
                        #I draw out a phial of blood.
                          *set cuthand false
                          *set blood -1
                          *set usedblood +1
                          *return
                    #I use ${wisardry} to unseat those just behind Hector.  I want him spared.
                      *set hectarg false
                      *goto treeunseat
                    #I use ${wisardry} to sharpen my outlaws' spears.
                      *if theurgy < 2
                        *goto theufail
                      *if blood > 0
                        *gosub theuhurry
                      *set hectheu 3
                      The wooden spearpoints were honed with a single intent: to pierce whatever runs into them.  You stretch out your bloody hand toward them, feeling at least a handful respond to your hurried ${wisardry}. Even as you concentrate on their sharpness, you're bellowing, "[i]Throw the spears![/i]"

                      The crude wooden pike is no javelin, far too long and dull for throwing, and most of the outlaws hesitate at your tactically bizarre order.  But Radmar responds at once, hurling his toward Hector Keriatou.  With Radmar's arm behind it, the spear reaches Hector's stallion—and instead of glancing off, a four-foot length of wood disappears straight into the unfortunate animal.  The horse collapses with a bubbling scream, sending your
                      *if helot
                        former master
                      *if aristo
                        cousin
                        *if hector > 5
                          and one-time lover
                      crashing to the trail.

                      Even as he falls, seven more of your outlaws hurl their spears with a ragged war-shout.  If you weren't on the verge of being overrun, the clumsy throws would have been unlikely to strike home, and several fall short—but nonetheless, two more horses are spitted and go down thrashing, and Zvad's spear passes straight through one of Hector's veneurs and lames a third horse.  With no third chance, you brace for the remaining riders to find their way through the tangle of fallen horses and trample you down.

                      But all that hits you is a cloud of dust.  Through it, you can dimly see the remaining veneurs peel away or pull up, howling, "Goety!  Ware Goety!" 
                      *if theuknown > 5
                        and "The bastard ${orig_lname}'s here ${him}self!"  
                      A few more arrows whine through the air. 
                      *page_break
                      *if cuthand
                        Head throbbing from ${wisardry},
                      *if not(cuthand)
                        Casting aside your phial,
                      you look around you and feel your momentary elation collapse. Your outlaws, now mostly unarmed, are sprinting for cover; Zvad is trying to drag a few back toward the mules, his bellowed commands largely ignored.  The mules are beginning to bolt, braying frantically, bumping up against you.

                      Just as you decide to run for the woods yourself, there's a terrible jolt in your arm, a gurgling bray from just behind you.  You find yourself wrenched backward, bicep and bone suddenly aflame with agony.  As you slam to the ground, your other hand grasps at the source of the pain and flails against a long wooden shaft.  You're pinned to a now-dead mule by a spear so sharp you barely felt its point pierce you—but whose rough wood is now stuck fast in both the mule and the fleshy part of your arm.

                      Hector Keriatou runs out of the dust, face streaked pale with dirt, one arm flapping limp at his side.
                      *if helot
                        "Damned dirty beast," he rasps, drawing a dirk from his belt.
                      *if aristo
                        [/i]"${fname}!"[/i] he snarls, drawing a dirk from his belt.
                        *if hector >= 4
                          There's nothing but hatred in his face.
                      "Have a taste of 
                      *if theuknown > 5
                        your own Goety."
                      *if theuknown <= 5
                        whatever bloody Goety you've turned on us."
                      *set impaled true
                      *choice
                        #I levitate him.
                          *set imptheu true
                          You slide your free hand down to the blood streaming from your wound.  "Fly," you gasp, and Hector's feet leave the ground…for the five heartbeats before you fall unconscious.  
                          *label lastthingsee
                          The last thing you see is Radmar charging back toward
                          *if aristo
                            your cousin,
                          *if helot
                            the Keriatou,
                          swinging a shield.

                          You regain consciousness only slowly.
                          *if simzstalk
                            ${simon}
                            *set a_his zhis
                            *set a_he zhe
                            *set a_name simon
                            *set hambush -2
                          *if not(simzstalk) and (elery > 0)
                            Elery
                            *set a_his "her"
                            *set a_he "she"
                            *set a_name "Elery"
                          *if not(simzstalk) and (elery < 1)
                            Ciels
                            *set a_his his
                            *set a_he he
                            *set a_name "Ciels"
                          is hovering just above your face.
                          
                          *if aristo
                            "Hector?" 
                          *if helot
                            "The Keriatou?"
                          you rasp. Your head has somehow become too heavy to turn or lift.  Then your arm blazes with pain, and you suck air.
                          
                          "Don't worry, ${addressu}.  Just try to stay still."  Through the haze of pain and lightheadedness, you see an outlaw frantically sawing at the spear shaft, while ${a_name} tries to staunch the flow from your arm.  From the tone of ${a_his} voice, it's going badly.
                          
                          Then you lose yourself to another burst of anguish as ${a_his} fingers close just below your armpit, pressing relentlessly against bone. If a third outlaw weren't gripping your other arm, you'd have knocked ${a_name} off you.  As it is, you buck and writhe beneath them, all rational thought driven out by the pain.
                          *if a_name = simon
                            "Forgive me, ${addressu}!" the blood-streaked ${simon} pleads, voice shaking but hands implacable. "We must stop the bleeding."
                          *if (a_name = "Elery") and (e_rel > 0)
                            "Damn it, ${addressu}," Elery groans, scrabbling in your blood, "I almost…lost hold there."
                          *if (a_name = "Elery") and (e_rel < 1)
                            "Damn your eyes," Elery snarls, clawing your arm ever tighter.  "If you want to bleed to death…"
                          *if a_name = "Ciels"
                            "Keep still, ${addressu}." Ciels's voice is sympathetic but ${his} hands implacable.
                          *page_break
                          You both hear and feel the snap as the spear shaft comes apart; it adds nothing to what you're already enduring.  "Now the other side," ${a_name} orders sharply.
                          
                          "Can't reach it!" the outlaw protests. "With you and Yetta all over the ${kuria}…."
                          
                          *if a_name != "Ciels"
                            "Sweet 
                            *if a_name = "Elery"
                              sodding
                            Xthonos!  That 
                          *if a_name = "Ciels"
                            Ciels's level voice begins to hint at strain. "That
                          spear and my hand are the only things keeping ${his} blood in ${him}."
                          
                          As you plummet toward delirium, for a trancelike moment you can see yourself dying—see your body desperately but vainly striving to heal itself, to close the wound, while your vital essence seeps rapidly away.  Through clenched teeth, you whisper, "Pull me off."
                          
                          "No, ${addressu}…."
                          
                          "Quickly," you gasp, "while I've strength!"
                          
                          You don't know if they're going to obey until you suddenly feel bone grating on wood, muscle tearing.  With a blaze of utter agony, you're free of the spear.  At once, blood gouts from your wound despite ${a_name}'s grip.  And you pour all your Theurgic strength into knitting up the hole Hector put in your arm—forcing your flesh to close the gap, reweaving muscle to muscle and vein to vein with every remaining second of consciousness.
                          *goto afterheal
                          
                        #I blind him.
                          *set imptheu true
                          You slide your free hand down to the blood streaming from your wound.  Hector curses shrilly and staggers to a halt, the light from his eyes cut off…for the five heartbeats before you fall unconscious. 
                          *goto lastthingsee
                        *if hector >= 4
                          #I shout, "Run, Hector!  Run, and live!"
                            The genuine anguish in your voice gives him a moment's pause, and he looks around warily.  You try to speak again, but your lightheadedness is suddenly overwhelming.
                            *goto lastthingsee
                        #I bare my teeth in a grin.  "Got you now…you bastard."
                          *if cha = 0
                            He doesn't believe your bluff, or pause for even an instant.  You try in vain to fend off his charge with your remaining arm.  
                            
                            Radmar charges back, roaring, a moment too late; Hector's dirk has already found your throat.
                            *goto_scene death
                          You put the truth of the coming ambush into your voice and eyes—even though no arrow has fallen and there's not a whisper to suggest that your ambushers have arrived.  And for an instant, Hector believes you.  
                            
                          As he glances around warily, you try to speak again but feel the world slipping away from you.
                          *goto lastthingsee
                        #I try to pull myself off the spear and run.
                          You lunge toward Hector—and the world goes white around your eyes, in an agony like nothing you've ever imagined.  Your legs lose all strength and your whole weight hangs forward from the spear impaling your arm, bone grating on wood.  As you lose consciousness, you see Radmar charging back at Hector.

                          But your attempts to free yourself have opened your wound wider.  By the time your outlaws drive off the surviving veneurs and reach you, you have long since bled to death.
                          *goto_scene death

                          *label afterheal
                          *page_break
                          *set limb 1
                          *achieve healer
                          *if imptheu and cuthand
                            You wake to utter darkness, but your nostrils catch the familiar tang of sweat, moldering canvas, and smoke.  You're weak as a suckling, but—to your own astonishment—alive and back in camp.  
                            
                            For a long time you just lie there, aching and bone-parched but overcome with relief.  [i]I healed myself.[/i]  "Water," you finally wheeze.
                            
                            You can't see who puts the waterskin to your lips, but when you've drunk your fill, $!{deputy}'s voice murmurs,
                            *if deputy = "Zvad"
                              "So you're still with us, ${addressu}."
                              
                              "It'll take…more than that…."  You run out of breath and abandon bravado.
                            *if deputy = "Breden"
                              "We thought you'd not live."
                              *if bred_heart < 10
                                The relief in $!{xhis} tone is joyous.  "${fname}, when they brought you back…even after we'd washed you clean of all the blood, you looked like there was barely a drop left in you."
                                
                                You feel like there's barely a drop left in you. "I'm here."
                              *if bred_heart >= 10
                                $!{xhis} tone gives no hint as to whether this was for ${xhim} a fear or a hope.
                                
                                "I have."
                              You don't have the energy to say more.  After several more moments, you manage,
                            *if (theuknown < 5) or (theurgy = 3)
                              *if theurgy != 3
                                "Suppose you want an explanation."
                                
                                "You're a Theurge.  Or a Goete?" $!{dephe} rubs ${dephis} chin with a barely noticeable tremor in ${dephis} hands.
                                
                                "A ${wisard}," you declare.
                                *if wisard = "Goete"
                                  "No trafficking with dark powers.  None of that—I swear to you.  But because it will frighten the Hegemony."
                                  *set morale -15
                                  *set cred_p -50
                                *if wisard = "Wisard"
                                  *set natl %+5
                                  "The old Shayardene art.  Stolen by Karagonds for themselves."
                                
                                ${deputy} stares at you for a few more moments without speaking.  "It'll take getting used to, ${addressu}.  But I reckon the band will get there.  Today was…like something out of a legend."
                              *if theurgy = 3
                                "That was ${wisardry}."
                              
                                "We gathered that, ${addressu}," ${deputy} says carefully. "And that you're still learning the limits.  Impressive, still.  More than impressive.  Like something out of a legend."
                              
                              "Casualties…" You swallow hard.
                            "How many?"
                            
                            *gosub tenttoll
                            you try and fail to raise the waterskin to your lips for another drink.  The injured arm will barely lift, its fist won't close tight enough to grip.  Groping around gingerly with your other hand, you discover the limb has withered, with little left but skin and bone.  You can't suppress a moan of dismay.  "Ah, ${oath}.  My arm."
                            
                            *if deputy = "Zvad"
                              *if hambush > 6
                                Zvad sounds reassuringly calm.
                              *if hambush < 7
                                Zvad gives a gusty sigh.
                              "Your sword arm was never what won you our loyalty, ${addressu}.  We'll see what some practice does to rebuild it.  I've seen folk recover from worse after a bad wound."
                            *if deputy != "Zvad"
                              *if (bred_heart < 10) and (hambush > 6)
                                Breden's tone shifts at once to sympathy.
                              "I'm so sorry, ${addressu}."
                              *if (bred_lover >= 4) or (bred_heart = 3)
                                $!{xhe} tenderly folds your hand between ${xhis}, sounding stricken.
                              *if (bred_lover < 4) and (bred_heart != 3)
                                $!{xhe} clears ${xhis} throat.
                              "Zvad says he's seen the same before after a bad break has healed, and that with some work the arm may grow strong again."

                            You
                            *if (deputy = "Breden") and ((bred_lover >= 4) or (bred_heart = 3))
                              manage to squeeze Breden's hand and
                            force yourself away from self-pity.  "Had to hurry.  There's a cost.  But…now I can heal wounds."
                            *if hambush < 7
                              [i]That's one good thing we take from this disaster.[/i]
                            From your flash of near-death insight, you've learned to encourage the flesh and veins to reknit themselves.  Now, if given more than a few desperate seconds, you think you could heal others without withering their muscles.  In a future battle, that might make a great difference.
                            *goto reinforce
                            
                            *label tenttoll
                            *if hambush > 9
                              *if hambush > 11
                                *set morale +10
                                "All but the Keriatou dead. And they broke without felling a single one of us.
                              *if hambush < 12
                                *set morale +8
                                *set followers -2
                                *set nonkids -2
                                *set dead +2
                                "Three of the veneurs and the Keriatou ran off wounded, ${addressu}. All the rest of them fell—and we lost only two.
                              *set sa_foll 903
                              I doubt Hector will find anyone else to come hunting us after a loss like that."
                              
                              You release a breath you hardly knew you were holding.
                              *if (not(simzstalk) and not(kalstalk)) and (elery > 0)
                                Elery did well.  That will boost her standing in the band.
                                *set el_lead +2
                              *if simzstalk
                                ${simon} did well.  No one should question now where ${zhis} loyalties lie.
                                *set simz_lead +2
                              *if kalstalk
                                ${kalt} did well.  That will boost ${zhis} standing in the band.
                                *set kal_lead +2
                              *if (not(simzstalk) and not(kalstalk)) and (elery < 1)
                                Your ambushers won, and Hector Keriatou lost.
                              *set hec_cred 9
                              *set cred_h +10
                              *set cred_y +10
                              *set cred_a -5
                              
                              Your elation fades when
                              *return
                            *elseif hambush > 6
                              *set morale +2
                              *set followers -7
                              *set nonkids -7
                              *set dead +7
                              *if (not(simzstalk) and not(kalstalk)) and (elery > 0)
                                *set el_lead +1
                              *if simzstalk
                                *set simz_lead +1
                              *if kalstalk
                                *set kal_lead +1
                              *set sa_foll 902
                              "The young Keriatou escaped with four veneurs, most wearing an arrow.  We lost seven."  $!{deputy} sighs.  "We can't afford the loss—but he can afford it even less."
                              
                              It's true—Hector won't readily find other noble hunters when the prey fights back so fiercely.  Your satisfaction quickly fades as
                              *set hec_cred 11
                              *set cred_h +5
                              *set cred_y +5
                              *set cred_a -2
                              *return
                            *elseif hambush > 4
                              *set morale -20
                              *set followers -12
                              *set nonkids -12
                              *set dead +12
                              *label miseryambush2
                              *set hec_cred 21
                              "The second group of ambushers loosed arrows too soon.  One more veneur went down.  The others rallied round Hector and found cover.  They killed
                              *if hambush > 4
                                twelve
                              *if hambush < 5
                                twenty
                              of us and fought free."
                              *label shockcurdle
                              
                              Your shock curdles into gloom.  After a loss like that, there's nothing to do but switch to a defensive posture, doing whatever you can to conceal the mule trains from Hector's hunters.  Few will believe you can beat the nobles now.
                              
                              Your despair deepens when
                              *set sa_foll 901
                              *return
                            *elseif hambush > 2
                              *set morale -30  
                              *set followers -20
                              *set nonkids -20
                              *set dead +20
                              *goto miseryambush2
                            *else
                              *set morale -41
                              *set followers -31
                              *set nonkids -31
                              *set dead +31
                              *set hec_cred 21
                              $!{deputy} says nothing for a long while. "We lost thirty-one outlaws. The ambush failed; the veneurs routed us."
                              *if (not(simzstalk) and not(kalstalk)) and (elery > 0)
                                *set el_lead -3
                              *if simzstalk
                                *set simz_lead -3
                              *if kalstalk
                                *set kal_lead -3
                              *goto shockcurdle
                          *else
                            *comment if not(imptheu) or not(cuthand)
                            *set morale +5
                            This time when you come to yourself, there's a small band of outlaws from the ambush party gathered around you.  You're no longer lying against a dead mule, but on a grassy slope some yards away.  A blood-spattered ${a_name} is kneeling at your side, eyes wide and incredulous.  
                            
                            You feel utterly drained, but when you look down at your arm, the hole torn by Hector's spear is only a white circle of skin.  The arm itself is shockingly withered—barely more than skin and bone—and as you try and fail to raise it, you can't suppress a groan of dismay.
                            
                            *if a_name != simon
                              "Xthonos, ${addressu}.  You should be dead."
                            *if a_name = simon
                              "${addressu}…I grieve for your arm, but not half so much as I had expected to be grieving."
                            ${a_name} shakes ${a_his} head slowly.  "To see it…to see your living flesh tie itself back together.  
                            *if a_name != simon
                              I still don't know if I believe it."
                            *if a_name = simon
                              You are a worker of miracles, ${addressu} ${lname}."  You're used to hearing devotion in ${zhis} voice, but nothing like this.
                            
                            You push away self-pity, force your parched throat to croak out, "And now I know how to heal wounds with ${wisardry}."  If given more than a few desperate seconds to heal a wound, you think you could do the same without withering the muscles.  In a future battle, that might make a great difference.  
                            
                            Hearing your voice, ${a_name} grimaces and beckons for a waterskin.  You drink greedily, take a moment to breathe, then 
                            *if (theuknown < 5)
                              croak, "You likely want an explanation."
                              
                              "You're a Theurge," ${a_he} 
                              *if wisard = "Theurge"
                                echoes you.  "How?"
                                
                                "Can't say too much.  But yes—I've learned the art."
                              *if wisard != "Theurge"
                                ventures. "Or a…${wisard}?"
                                
                                *if wisard = "Goete"
                                  *set morale -15
                                  *set cred_p -50
                                  Seeing the seeds of terror in ${a_his} eyes, you say, "Not from any dark power.  Nothing like that.  But yes, to scare the Hegemony…we'll call it that."
                                *if wisard = "Wisard"
                                  *set natl %+5
                                  "The old Shayardene art.  Stolen by Karagonds and called Theurgy."
                              You take another long drink, and then
                            repeat:
                            *if aristo
                              "Hector?" 
                            *if helot
                              "The Keriatou?"

                            "Fled
                            *if hambush > 5
                              on the horse of a fallen comrade,"
                            *if hambush < 6
                              on the rump of a friend's horse,"
                            *if simzstalk
                              the young noble says grimly.  "And thank Angels he was too much a coward to face down an unarmed man to slay you."
                            
                              Thinking back to Hector's one limp arm and Radmar's bulk, you're not sure you'd call it cowardice.
                            *if not(simzstalk) and (elery > 0)
                              the former helot says shortly.  "With one arm, he was no match for our Rad, and he knew it."
                            *if not(simzstalk) and (elery < 1)
                              the young tracker reassures you.  "Overrun by Radmar, who has only a scratch for it."
                            *if hector > 5
                              *choice
                                #I try to hide my relief that my cousin survived.
                                  What you feel for Hector has survived years of petty cruelties and his cruel assault on your band.  It's unsurprising that it survived him impaling you on a spear.
                                  
                                  *goto hectanswer
                                #I shake my head, remembering the hate in his eyes.  Whatever feelings I had for him are gone forever.
                                  *set hector 8
                                  *goto hectanswer
                                #The bastard loathes me and put a spear through me.  I'm only glad he survived so I can return the favor.
                                  *set hector 9
                                  *goto hectanswer

                            *label hectanswer
                            "And the ambush?"
                            
                            *if hambush > 11
                              *set morale +10
                              *set sa_foll 903
                              "Every other veneur dead, ${addressu}. And they broke without felling a single one of us.  I doubt Hector will find anyone else to come hunting us after a loss like that."
                              *label didok
                              *if (not(simzstalk) and not(kalstalk)) and (elery > 0)
                                Elery speaks with quiet, weary pride.
                                *set el_lead +2
                              *if simzstalk
                                There's a sadness in ${simon}'s voice, but pride in ${zhis} bearing. If the band had any doubt about ${zhis} loyalties, you think today's work will have laid them to rest.
                                
                                *set simz_lead +2
                              *if kalstalk
                                *if elery > 0
                                  Elery 
                                *if elery < 1
                                  Ciels
                                speaks with a kind of incredulous awe. "We wouldn't have believed we could do it, especially those of us who saw you fall…but ${kalt} kept pressing us after them.  And one by one, our arrows found them."
                                
                                *set kal_lead +2
                              The news revives you enough that you manage to half-sit.  An ever-growing band of returning ambushers has joined your wide-eyed muleteers.  They're staring at your bloodied form, clearly wondering if you're dying.  You take a deep breath and declare, shakily but loudly, "They 
                              *set hec_cred 9
                              *set cred_h +10
                              *set cred_y +10
                              *set cred_a -5
                              *goto thoughtgame
                                
                            *elseif hambush > 9
                              *set morale +8
                              *set followers -2
                              *set nonkids -2
                              *set dead +2
                              *set sa_foll 903
                              "Three of the veneurs crawled off wounded, ${addressu}. All the rest of them fell—and we've only lost two.  I doubt they'll trouble us again."
                              *goto didok
                              *label jaccuse
                              *choice
                                #"Why weren't you with them, de Firiac?"  My voice is cool. $!{zhe} was meant to be there, and ${zhis} leadership might have saved those lives.
                                  *set s_rel 4
                                  *set simz_lead -1
                                  *set cred_h +5
                                  The young noble's face twists with guilt and anger.  "I made a decision, ${addressu} ${fname}, that letting the rebellion's leader die would cost more lives in the long run.  If I was mistaken, I ask your pardon."
                                  
                                  "It's their pardon you should ask."  You gesture brusquely at the surviving outlaws, who are mostly avoiding ${simon}.  "Next time, follow the plan."
                                  *return
                                #I don't say a thing. $!{zhe} likely saved my own life by choosing to stay.
                                  You can hear the hidden guilt in ${simon}'s voice; ${zhe} knows as well as anyone what ${zhis} decision cost. You reach out with your good arm to grip ${zhis} hand.  "Thank you," you say quietly.
                                  *return
                                #I don't say a thing. $!{zhe} should have been with the ambush party, but I don't want to shame ${zhim} in front of the others.
                                  You can hear the hidden guilt in ${simon}'s voice; ${zhe} already knows as well as anyone what ${zhis} decision cost.
                                  *return
                            *elseif hambush > 6
                              *set morale +2
                              *set followers -7
                              *set nonkids -7
                              *set dead +7
                              *set sa_foll 902
                              "We brought down a few more, ${addressu}. Four escaped with young Keriatou, most of them wearing an arrow."
                              
                              "Well fought.  And we lost…?" you ask, scanning the party.
                              
                              "Seven,"
                              *if simzstalk
                                ${simon} declares somberly. "The first ambush party overextended themselves in the initial pursuit."
                                *set simz_lead +1
                                *gosub jaccuse
                              *if kalstalk
                                ${kalt} says curtly. "But believe me, they'll feel their loss more than we feel ours."
                                *set kal_lead +1
                              *if not(simzstalk) and not(kalstalk)
                                *if elery > 0
                                  *set el_lead +1
                                  Elery says, her eyes flashing defensively. "And if it takes two of us for every one of them…I call that a good fight."
                                *if elery < 1
                                  Ciels says flatly. "More than we will next time, ${addressu}."

                              An ever-growing band of returning ambushers has joined you—and they're staring at your bloodied form, clearly wondering if you're dying.  You take a deep breath and declare, shakily but loudly, "Well fallen—and well fought. Before today, 
                              *if helot
                                the nobles 
                              *if aristo
                                my cousins
                              *set hec_cred 11
                              *set cred_h +5
                              *set cred_y +5
                              *set cred_a -2
                              *goto thoughtgame
                            *elseif hambush > 4
                              *set morale -20
                              *set followers -12
                              *set nonkids -12
                              *set dead +12
                              *label miseryambush3
                              *set hec_cred 21
                              The group's awe rapidly dissipates into misery.  "The second group of ambushers loosed arrows too soon,"
                              *if simzstalk
                                ${simon} says in a low voice.  "And the first overextended themselves."
                                *gosub jaccuse
                              *if kalstalk
                                ${kalt} growls.
                              *if not(simzstalk) and not(kalstalk)
                                *if elery > 0
                                  Elery says grimly. 
                                *if elery < 1
                                  Ciels says, flat-voiced.
                              "One more veneur went down—but the others rallied round Hector and found cover.  They killed
                              *if hambush > 4
                                twelve
                              *if hambush < 5
                                twenty
                              of us and fought free."
                                
                              "How do a few injured, ambushed nobles kill that many?" you demand in disbelief.  
                              *goto betterthanus
                            *elseif hambush > 2
                              *set morale -30
                              *set followers -20
                              *set nonkids -20
                              *set dead +20
                              *goto miseryambush3
                            *else
                              *set morale -41
                              *set followers -31
                              *set nonkids -31
                              *set dead +31
                              *set hec_cred 21
                              There's a wretched silence, and you realize that the handful around you will not be joined by others.
                              
                              "What happened?" you demand, almost inaudibly.
                              *if simzstalk
                                But you know at least part of it. [i]${simon} stopped to save my life, and the ambush went to pieces without ${zhis} leadership.[/i]
                                *set s_rel 4
                              *goto wewererouted

                    #I break for the woods.
                      *goto runfortrees
                    #I pick up one of the fallen spears and try to kill Hector.
                      Bringing down Hector Keriatou is the one thing you think might break the veneurs.
                      *if hector >= 4
                        You'll grieve him, but in the heat and terror of the moment, you see no other choice.
                      The spears are too long to throw effectively, so you catch one up and turn, looking for the chance to gut Hector.
                      
                      You had never truly appreciated how earth-shattering a charge of horses is until you tried to stand up to one—or how little room it leaves for one ${woman} with a spear to reach a rider in the saddle.  The last thing you hear is Hector's howl of triumph as he knocks your spear aside and sweeps his blade into your neck.
                      *goto_scene death
                #I use ${wisardry} to unseat Hector and those closest to him.
                  *goto treeunseat
                #I use ${wisardry} on those just behind Hector.  I want him spared.
                  *set hectarg false
                  *goto treeunseat
            *elseif com = 2
              *comment from label zvadspear if you don't have int 2
              As the veneurs thunder ever nearer, you quickly scan the formation and bark orders to three of your followers to get their shields in line.  The nobles' first half-dozen arrows slice the air above you, but those which fall on your little group clatter harmlessly away.
              *if not(close)
                *goto radjav
              
              "This is our trap, not theirs," you inform the frightened muleteers, nodding to the trusted handful who were in the know. They have already retrieved their concealed javelins and bows.  "As soon as that horn sounded, 
              *if simzstalk
                ${simon}
              *if kalstalk
                ${kalt}
              *if not(simzstalk) and not(kalstalk)
                *if elery > 0
                  Elery
                *if elery < 1
                  Ciels
              and a band of archers began moving into position to kill them. Hold, and we'll live." 
              *if cha > 0
                The muleteers glance uphill toward the trees, and you can see new hope in their stance.
                *set holdfast 1
              *if cha = 0
                They still look terrified and uncertain, their wooden pikes wobbling.
                *if parley
                  
                  *goto oops
              
              *if parley
                *goto earththrum
              *label radjav
              Seizing a javelin from Radmar, you:
              *choice
                #Hurl it at Hector Keriatou.
                  "Hector is mine!" you tell the others, and smoothly fit the javelin to its throwing strap.
                  *if aristo
                    Are you aiming to kill your cousin?
                    *choice
                      #Yes, if I can.
                        *if hector >= 4
                          You silence the foolishly hopeful voice which always held out hope for a future with Hector.  There's no room for sentiment in a time like this.
                          *set ruth %+5

                        *goto plotarmor
                      #No, just to injure.
                        As you let fly, you tell yourself that you hope only to wound him—ignoring the fact that, with a javelin in the heat of battle, aiming for limb rather than torso is a meaningless distinction.
                        
                        In the event, you hit neither.
                        *goto plotarmor
                      #No, I intend to narrowly miss.
                        If you can possibly avoid it, you don't want your cousin to die at your hand.  You let fly, and your aim is true; Hector ducks reflexively to one side, but it would have missed him anyway.
                        *goto breakcharge
                  *label plotarmor
                  Your aim is true—but Hector is agile as a hunting cat.  He glimpses the javelin coming and reflexively ducks low in the saddle; it flies over his shoulder and vanishes into the dust.
                  *goto breakcharge
                #Hurl it at Hector's horse.
                  The javelin slices a long gash along the horse's shoulder.  It rears up, whinnying with pain, and Hector fights to keep in the saddle.
                  *set holdfast 2
                  *goto breakcharge
                #Hurl it at one of the other veneurs at the front of the charge.
                  The short spear flies true, and one of Hector's young hunters flips backward out of the saddle.
                  *set holdfast 3
                  *goto breakcharge
              *label breakcharge
              Radmar's javelin fells another veneur in the first rank, and you see a few of your arrows sprout in the nobles' shields and light armor.
              
              *if holdfast > 0
                *label earththrum
                Then the earth is thrumming under your feet as
                *if holdfast != 2
                  Hector and 
                *if holdfast != 3
                  three 
                *if holdfast = 3
                  two
                surviving veneurs arrive to ride you down.  You bellow some wordless defiance, unheard.
                *if cha > 1
                  *page_break
                And your terrified muleteers keep their spears together, lent just enough confidence by
                *if holdfast = 1
                  your promise of impending rescue.
                *if holdfast > 1
                  the disruption of the nobles' charge.
                The horses shy away from the thicket of pikes.  
                
                *if (cha > 1) or parley
                  *goto highcha
                Swearing loudly enough to be heard above the hooves, Hector 
                *if holdfast = 2
                  belatedly arrives and
                orders the hunters to ride around you, to strike at the flanks of your formation.  In the dust of the charge, he doesn't immediately see 
                *label bolas
                two of your outlaws crouched at each flank, a whirling blur above their heads. Many helots are adept at using bolas to catch small game—and you've had Zvad training a few with larger ones, suitable for deer, cattle, and horses.
                
                The first two veneurs to try flanking you abruptly crash to the ground, both horses and humans shrieking in agony.  You don't think any of their comrades can see their mounts' legs entangled by weighted cords.  Hector pulls back, uncertainty mingling with fury on his face.  While he scans your band to see what felled his veneurs, the second rank sends another volley of arrows toward you.  This time, your shield cover is incomplete and one arrow takes a young muleteer in the shoulder.  The boy screams in horror; half of your frightened followers turn to look to him, their pikes wavering.
                *set followers -1
                *set nonkids -1
                *set dead +1
                *set morale -1
                *if parley
                  *goto holdagain
                
                Then: "$!{lname}!" Hector bellows, spittle flying from his lips.
                *if aristo
                  "My Angels-damned cousin 
                *if helot
                  "The bloody churl 
                is here ${him}self! Take ${him}—take ${him} now!"
                *label holdagain
                
                "Hold!" you roar 
                *if parley
                  at them.
                *if not(parley)
                  to your outlaws.  
                The surviving nobles wheel and ride as one toward you.  "Hold, for all our lives!"
                *page_break
                And they hold.  The pikes come back up; Zvad
                *if r_rel > 0
                  and Radmar 
                *if r_rel < 1
                  and a scar-faced bandit
                raise their shields to either side of you, protecting you from the missiles of the veneurs.  Three arrows whistle through the air around you, and a javelin point judders through Zvad's shield to stop not an inch from your cheek.  But they don't touch you, and once again, Hector's charge falters before your unified spears.
                
                *label hectaunt
                *if aristo
                  "Face me, cur!" he screams, leaning out of the saddle as if straining to spit you on his sword.  
                  *if hector >= 4
                    In his crazed eyes you see no trace of the affection you once longed for.
                  "Stand forth and face me—just us two!"
                  *fake_choice
                    #"Ask your blademaster how that will end, cousin," I taunt him.
                      His face contorts at your mockery.  Plenty of his veneurs would have seen the results of your practice 
                      *if holdfast > 0
                        sessions. 
                      *if holdfast = 0
                        sessions—and they all just saw him forced back in a direct confrontation with you.
                      "Coward and villain," he spits, and
                    #"You expect me to trust your honor?"
                      *if hector = 2
                        All the disdain you've felt for the bullying young Keriatou spills into your voice, unguarded for the first time.  His eyes flare wide, then narrow.
                      "Coward and villain," he spits, and
                    #"Flee, cousin.  Flee now, if you want to live."
                      Hector only laughs and
                    #I maintain a cold silence.
                      When it's clear that you won't be drawn, Hector spits and
                *if helot
                  "Filthy beast!" the Keriatou screams, leaning out of the saddle as if straining to spit you on his sword. "Bastard get of a scullion!  You dare to stand before your lord and master? I'll see you grovel and eat my horse's dung before you die."
                  *fake_choice
                    #"You'll see your house burned and your damned father on a gibbet first," I snarl back at him.
                      Hector spits at you and
                    #"How long will your Karagond lords let you live after I send you whimpering back to them like a dog?"
                      Hector's lips curl, and he
                    #"You're the beast, Keriatou—a quarry that's mistaken itself for a hunter."
                      For a moment, you think the smug confidence in your voice gives Hector pause.  Then he sneers at you and
                    #I maintain a cold silence.
                      When it's clear that you won't be drawn into a battle of taunts, Hector spits at you and
                beckons sharply to the others.  They fall back, plainly intending to wear your little band down with archery before charging again.  Your heart sinks. How soon will your wide-eyed outlaws crack under the strain?
                
                *label splitwhistle
                Then the sky is split by the whistle of arrows—but out of the woods, falling among the veneurs.  "Ambuscade!" Hector cries in furious realization, wheeling his horse away.  With yells of shock (and at least two shrieks as an arrow finds a limb), the surviving nobles break frantically for Rim Square.
                *goto zvadwhoop
                
              *else
                *comment if holdfast = 0
                *label oops
                *set followers -4
                *set nonkids -4
                *set dead +4
                Then the charge is upon you, and your wavering wall of pikes only deters two of the horses.  Hector and one other veneur, Ganelon Tarakatou, spur their protesting mounts through the gaps and trample into the middle of your formation.  Two of your followers fall at once beneath their hooves; the others scramble back, trying clumsily to bring their weapons to bear against the armored nobles.
                *if parley
                  Any hope of parley flees your mind.  Under these circumstances, it will be all you can do to survive.
                
                You press urgently toward Hector—and glimpse young Ganelon's long, bloodied iron spear stabbing toward you.  [i]$!{oath}![/i]  He must have cut through at least one or two outlaws to get so close, so quickly.  You barely manage to get your shield up in time, and it splits from the blow.  As you cast it aside and raise your
                *if weapon = "sword"
                  sword,
                *if weapon != "sword"
                  javelin,
                you see Zvad leap up to grab Ganelon's shield arm. The big ${whend} drags the noble halfway from the saddle, forcing him to drop his spear to stay a-horse.  Other outlaws press in, trying to push Ganelon back with their pikes and close up the gap in the spear wall.
                
                You turn away from that struggle to where the real danger is—and find him staring into your eyes, only a few yards away.  "$!{lname}!" Hector howls. "To me, to me!
                *if aristo
                  My Angels-damned cousin 
                *if helot
                  The bloody churl 
                is here ${him}self!  To me!"  The surviving veneurs wheel toward your fragmented formation, as the Keriatou tries desperately to bring you within his sword's reach.
                *page_break
                "Bolas!" you bellow. Many helots are adept at using the weighted cords to catch small game; you've had Zvad training a few with larger ones, suitable for deer, cattle, and horses.  Two outlaws step out of formation and whirl them above their heads before releasing. Two charging veneurs crash abruptly to the ground, horses and humans shrieking alike in agony.  That slows the nobles' charge—as does the sight of Ganelon's horse bursting out of your muleteers' midst, dragging the young Tarakatou's inert body from its stirrups.
                
                Meanwhile, you push toward Hector, who is battering at Radmar's shield from horseback.  You need to force the Keriatou back and close the gap before his veneurs press in behind him and widen the gap he's made in your formation.  Just now, his death is less important than his retreat.
                *choice
                  #I pick up a pike and thrust it at his horse.
                    *if aristo
                      As you're well aware,
                    Hector's steed was trained for hunting rather than war; it has little more tolerance than any other horse for a sharp object in its face.  You lunge in again and again with your crude wooden spear, driving the horse back despite all of the Keriatou's furious efforts to remain and engage you.  
                    
                    "Close the wall!" you cry, and your outlaws respond, bringing their spears up alongside yours.  
                    *label thunderup
                    The surviving veneurs thunder up to you—but Hector has been forced back and, this time, your bristling line of pikes is just solid enough that the charge falters.
                    
                    Hector gallops over to where Ganelon Tarakatou hangs lifeless from his steed, then turns back to you.
                    *goto hectaunt
                  #I attack Hector from the opposite flank to Radmar.
                    *if helot
                      "Keriatou!" 
                    *if aristo
                      "Cousin!" 
                    you snarl as you close with him.  Assailed from two sides, Hector has nowhere to go but backward.
                    *if aristo
                      Even with the tremendous advantage of fighting from horseback, he can't counter your greater skill and creativity with the sword—at least, not with Radmar hammering away at his right side.
                    *if helot
                      At first, his lips are peeled back with ferocious joy—finally, you're within his reach!  But his grimace becomes less joyous by the second, as you dodge or turn aside his blows while forcing him to evade your own.  Soon his face is contorted with outright disbelief: he's losing to a helot.
                    *label closethewall
                    
                    "Close the wall!" you cry, and your outlaws respond, bringing their spears up all around the young Keriatou's frightened horse.
                    *goto thunderup
                  #I try to wound Hector with a javelin badly enough that he'll pull back.
                    You hurl another javelin at him.  This one, he manages to catch in his shield, but he sees you bringing up a third, with a fourth ready to hand.  For one moment, staring into his frenzied eyes, you think he'll try his luck.  
                    
                    Then Radmar lands a glancing blow on his armored side.  Hector twists in the saddle, curses, and allows his skittish horse to break free of combat. "Close the wall!" you cry, and your outlaws respond, bringing their spears up into the gap.
                    *goto thunderup

            *else
              *comment from zvadspear if cha = 2
              *if not(close)
                *goto halfdoz
              As the veneurs thunder ever nearer, you address your frightened followers.  
              *if religion > 0
                "$!{addressc}: 
              *if religion <= 0
                "Hear me: 
              this is our trap, not theirs.  As soon as that horn sounded, 
              *if simzstalk
                young de Firiac
              *if kalstalk
                ${kalt}
              *if not(simzstalk) and not(kalstalk)
                *if elery > 0
                  Elery
                *if elery < 1
                  Ciels
              and a band of archers began moving into position to kill them. So hold the line—hold! And I swear to you, we'll avenge Glena on these 
              *if aristo
                blackguards'
              *if helot
                noble bastards' 
              bones."
              
              *label halfdoz
              
              The first half-dozen of the veneurs' arrows slice the air; while most clatter off shields, one pierces the arm of the boy next to you.  He shrieks, and half your muleteers glance at him, their spears momentarily wavering. "[i]Hold![/i]" you bark, and the force of your command recalls them at once to the defense.
              *set holdfast 1
              *goto earththrum
              *label highcha
              Before Hector has a chance to speak, you shout at the top of your lungs:
              *choice
                *if aristo
                  #"Cousin Hector!  We offer one chance at parley!"
                    *label hecblazeparl
                    Hector's eyes blaze at the sight of you.  
                    *if aristo
                      "Cousin!" 
                    *if helot
                      "Dog of a rebel!" 
                    he cries, teeth bared and sword raised.  "Thrice-damned ${orig_lname}! [i]You[/i] presume to offer [i]us[/i] parley?"
                      
                    *if hector >= 4
                      Searching his face for any sign of the affection you once craved, you find only loathing.
                    *if aristo
                      "Cousin Hector: 
                    *if helot
                      "Kurios Keriatou:
                    you are outnumbered and surrounded.  Miles of wilderness stand between you and home.  Our wilderness."  You wield your voice like a weapon, doing your best to drown out the sobs of your injured outlaw.  "Your only hope is to surrender and accept the terms on which we offer mercy."
                      
                    "Surrounded?" The kermes-clad young noble scans the forests to either side of you. "Are you so desperate for every minute that you resort to such ruses?"

                    "No ruse, 
                    *if aristo
                      cousin,"
                    *if helot
                      milord,"
                    *if cha < 2
                      you begin—but Hector only laughs contemptuously and beckons the veneurs back along the mule-track.  You bark a reminder to keep shields up, just before another flight of arrows peppers them. And then the nobles are wheeling, charging toward you again.  You're sure they intend to flank you.  Both you and Hector know that your little group won't be able to shift pikes quickly enough to prevent them breaking into your formation.
                        
                      The dust of their two charges makes it difficult for the veneurs to see
                      *goto bolas
                    *else
                      you laugh, and see him hesitate at the utter confidence in your voice. "As my archers will demonstrate when I give the sign.  You thought to trap us…but this deep in the wild, we are the hunters."
                       
                      A visible ripple of discomfort runs through the veneurs. "Amuse me, then, 
                      *if aristo
                        [i]cousin[/i]." 
                      *if helot
                        [i]Captain.[/i]"
                      Hector's eyes are wide and unblinking, his voice savage. "On what terms would you accept our surrender?"
                      *choice
                        #"Your weapons, armor, and anything else we find on you and choose to retain."
                          "Nothing but a petty thief, in the end," Hector sneers.  "What, no interest in our horses?  If you're to be Harrowed for thievery, it might as well be for something of true value."
                            
                          You
                          *if aristo
                            sniff 
                          *if helot
                            snort
                          disdainfully.  "The deep forest's no place for hard riding—as you're like to discover if you reject our terms." Then you affect a change of mind and eye up the animals speculatively. "Though on second thought, a bit of horsemeat would be a welcome change from venison."  
                            
                          You know how much
                          *if aristo
                            your fellow
                          nobles value their steeds; every veneur looks outraged at your provocation.  One of them cries, "Kurios Keriatou!  Shall we truly sit and listen to this excrescence?"
                            
                          "No more." Hector stands in the saddle and leans toward you, his face twisted with disgust.
                          *goto hecrej
                        #"Your sworn and written word that you shall not take up arms against me or my rebels again."
                          None of your outlaws blink. They clearly don't believe that you'd let the Keriatou go on his word alone.  Unfortunately, nor does Hector.  "Bah.  
                          *if aristo
                            Any word I gave under duress would be void—as you well know.
                          *if helot
                            No honorless thrall would release us on the strength of our word.
                          Frivolous terms to hide a non-existent trap."
                          
                          Before you can say another word, Hector has spurred his horse around the right flank of your group, beckoning the other veneurs after him.  
                          *label vensweep
                          They sweep in from both sides; the trapped muleteers howl and swing their pikes toward whichever attacker they see first.  Hector and four other nobles press easily into the gaps that open up in your formation, impaling your 
                          *if helot or (kuria = "Captain")
                            fellow 
                          outlaws on lances or felling them with swords.
                          *set holdfast 0
                            
                          *if com = 0
                            *set followers -7
                            *set nonkids -7
                            *set dead +7
                            You frantically bring up your own ${weapon} to block a thrust…and stumble off-balance, falling mere inches from the hooves of a veneur's horse.  For several long moments rolling in the dirt, all you hear are screams and the thunder of combat above you.  By the time Zvad's strong hand pulls you back to your feet, the nobles have wheeled away from your spears uninjured, leaving seven of your outlaws dead or dying.
                              
                            *label dustdespair
                            As Hector calls his veneurs to again raise bows against your disordered, terrified band—the prelude to a final charge—you can't tell how much of the choking feeling in your throat is dust and how much despair.
                              
                            *goto splitwhistle
                          *else
                            You press boldly toward 
                            *if aristo
                              Hector,
                            *if helot
                              the Keriatou,
                            spear out-thrust—and the greater length of your simple wooden pike tells against his greater experience with the sword.  For seconds that seem like hours, he hacks at you with one hand while hauling on the horse's bridle with the other, trying to force it into some gap from which he can strike a decisive blow.  In his feverish determination to cut you down, Hector ignores the muleteers, likely saving several of their lives.
                              
                            Still, when the young aristarch finally wheels away from the growing hedge of pikes around you, his veneurs have left four outlaws dead or dying.
                            *set followers -4
                            *set nonkids -4
                            *set dead +4
                            *goto dustdespair
                        #"Your oath to join our rebellion and fight in secret against the Karagonds after you return to Rim Square."
                          Several of your outlaws look as shocked as the veneurs, 
                          *if aristo
                            *set morale -2
                            and the gaze Radmar turns on you is like flint.  His growl is all too audible.  "We came here for your bloody cousin's head, ${kuria}, not to ease a family reunion."
                              
                            Hector
                          *if helot
                            and Radmar gapes openly at you. "Captain—you truly think he'd fight alongside us?  Or we alongside [i]him[/i]?"
                            
                            The Keriatou lordling 
                          laughs out loud.  "Will your rabble even accept these…preposterous terms you offer, ${orig_lname}?"
                            
                          You keep your eyes steadily on him, ignoring the mutinous mutters from your own side.  "Sooner or later, the nobility of Shayard will rise up and join us.  You're the first to face the choice…and I'm giving you your only chance to join the winning side."
                            
                          *if aristo
                            "Traitorous swine!" 
                          *if helot
                            "Blasphemous filth!"
                          cries one of the other veneurs.  "Do you imagine we'd truly betray our Houses
                          *if aristo
                            as you have yours?" There's a hint of doubt in her voice, and her eyes flicker to your cousin.
                          *if helot
                            at the word of a murderous helot?"  Surprisingly, there's a hint of doubt in her voice, and her eyes flicker to your former master.  You wonder what the Keriatous might have done or said to seed even so slight a suspicion.

                          "No.  No, ${he} doesn't.  
                          *if aristo
                            $!{he} knows me well enough for that.
                          $!{he}'s only trying to sow slander and dissension to the very last."  Hector's voice is adamant. He spurs his horse a few steps forward as if to reclaim the initiative from you.
                          *goto hecrej
                        #"Throw down your arms, and hand over one of your veneurs to meet the same fate as Glena."
                          *set morale +4
                          A ragged cheer goes up from your band, even as the veneurs explode with outraged refusals. Hector himself just barks out an incredulous laugh.  "Glena? She had a name?"  
                            
                          "One we mean you to remember,
                          *if aristo
                            cousin,"
                          *if helot
                            milord Keriatou,"
                          you call bleakly.  "We didn't meet you here today by chance, or even to protect our food.  We came in Glena's memory, and to avenge her death."
                            
                          "Vengeance," Hector breathes.  He leans in the saddle, sword outstretched as if to overreach the thicket of pikes and impale you.  "You dare to speak of revenge?  Whose 
                          *if helot
                            brazen revolt
                          *if aristo
                            vile treachery 
                          has threatened my House to the roots?  For the sake of a blaspheming helot girl, you would dare to assail House Keriatou—the House which
                          *if aristo
                            nurtured you in its very breast?"
                          *if helot
                            fed you, sheltered you, gave to you of our hard-won wealth?"
                          For a moment his voice grows shrill; his nostrils flare as he regains control.
                          *goto hecrej
                      *label hecrej
                      "Your so-called terms are beneath contempt, ${orig_lname}…much like your so-called rebellion.  End this charade.  
                      *if aristo
                        I call you villain,
                      *if helot
                        You're a
                      coward and liar.  If ever you had any sneak-thieves waiting to shoot us in the back, they fled at our appearance."  Chin out-thrust defiantly, he spreads his arms as if waiting for arrows to fall.
                        
                      There's just a trace of tension in his stance; when that last uncertainty fades, you know he'll order the veneurs to flank your formation.  You need to buy a little more time—you 
                      *if skepreal <= 50
                        pray—for
                      *if skepreal > 50
                        hope—for
                      *if simzstalk
                        ${simon} and
                      *if kalstalk
                        ${kalt} and
                      your ambush party to arrive.  You raise your arm as if about to give the signal…then pause.
                      *choice
                        *if hector >= 4
                          #I stare into those seething eyes and make one final appeal from the heart.  "Cousin.  Don't let it end this way between us…."
                            "Attack!" Hector shrieks at once, waving the veneurs around to your flanks.
                            *goto vensweep
                        #"Would you rather I sent your head to your father or the Karagonds?"
                          "Enough!" roars Hector and spurs his horse around your right flank, beckoning the others after him.
                          *goto vensweep
                        #I address the veneurs. "We'll spare whichever of you is first to put an arrow in the Keriatou's back."
                          *if aristo and (hector != 2)
                            Perhaps if you truly hated Hector, you could have convinced them.  As it is, Hector merely sneers, "$!{he} plays for time," and spurs his horse around the right flank of your group, confidently beckoning the other veneurs after him.
                            *goto vensweep
                          *else
                            The vicious gleam in your eye is just convincing enough, and Hector's trust in his veneurs evidently fragile enough, that he glances over his shoulder rather than laughing off the threat.  The other young nobles immediately and loudly protest the unthinkability of their treachery—half to you, half to the Keriatou.  You just wait and let them shout, keeping your hand poised in the air.
                              
                            At length, Hector waves them into silence and turns back to you, lips thin.  "See, 
                            *if aristo
                              cousin?  Their loyalty is stronger than yours.  Stronger than a viper like you could dream.  
                            *if helot
                              animal?  No highborn could even imagine the perverse dishonor that infests your mind.
                            Give your signal and be done."
                            *label sharpsig
                              
                            You bring your hand down sharply, affecting so fierce and joyous a smile that Hector flinches despite himself and the muleteers around you catch their breath.  Nothing happens.
                              
                            Within seconds, the young aristarch recovers himself and raises his own hand to call the attack.
                            *goto splitwhistle
                        #"Before you die, there's one thing I want you to know."
                          "Yes?" Hector barks, lip curling in contempt.
                          *choice
                            *if (calea > 9)
                              #"Your sister is the one who gave you all into my hand."
                                *set calea 8
                                *achieve betrayal
                                "Pah!" your cousin snarls, raising an arm to beckon his veneurs. "You'd defame anyon…"
                                  
                                "You're blind, she says—blind to the only course of action that can now save the Keriatou."  Hector pauses, lips tightening; as you'd hoped, Calea must have insinuated as much to him.  "She won't have you drag down the House with this pack of fools.  So she found a way to reach me, and told me the name of every 'veneur'…told me when and where you'd next come hunting us."  You pause, seeing the doubts grow in the other young nobles' eyes.  They all know Calea as well.  "This trap would have been impossible without her.  I want you to die knowing the full depth of your failure—knowing that you couldn't even command the loyalty of your own sister."
                                  
                                The part of you that loved Hector is wrung by the depth of pain that comes over his face.  "Damn you, ${orig_lname}! Liar, thrice liar, slanderer, [i]helot-lover[/i]!"  His voice cracks with fury as he points a trembling finger at you. "Give your signal!  Let us end this."
                                *goto sharpsig
                            *if (calea > 9)
                              #"The Karagonds have already promised the aristarchate to House Pelematou.  Your death here will accomplish nothing for the Keriatou."
                                Your cousin's expression of contempt never shifts. "You expect me to believe that the Karagonds have informed you of their intentions for the governance of the Outer Rim?  Or any who might lower themselves to speak to you?"
                                  
                                From hearing Calea, you'd guessed that this would hit a nerve.  The fact that Hector is still talking rather than ordering the charge confirms it. "More people speak to me than you'd believe, cousin. The same ones who told me to expect you here today. And ask your own veneurs: have they truly not heard the same?"  The other young nobles immediately and loudly protest that they've heard nothing of the sort—half to you, half to the Keriatou.  You just wait and let them shout, keeping your hand poised in the air.
                              
                                At length, Hector waves them into silence and turns back to you, lips thin.  "Even were it true, ${orig_lname}, I would still relish taking revenge on you. Give your signal and be done."
                                *goto sharpsig
                            #"You've lost—and I want to hear you admit that you've failed."
                              "Be damned, ${orig_lname}." Hector spurs his horse around your right flank, beckoning the others after him.
                              *goto vensweep
                            #"Many among your House servants are secretly with us.  Even as we kill you, they will be poisoning your father and sister—and the kin of others who ride here today."
                              It's a complete fabrication, of course; but you find the confidence to smile as you say it, and Hector loses his smirk.  "Recreant dog! Vile schemer! And liar, once more.  We'll return home from slaying you and…and prove the lie!"
                                
                              "So sure?" You shake your head, still grinning at the flustered young noble.
                              *if aristo
                                "You were always blind to those you considered beneath you, cousin.  You lacked the imagination to see any of this coming. I wanted you to understand: it's that lack of imagination which will cost you not only your own lives, but those of your families.  And will no doubt cost House Keriatou its aristarchate."  The other veneurs burst into incoherent insults and denials.  You just stand there, keeping your hand poised in the air.
                                  
                                Hector
                              *if helot
                                "Blind to the end, 'master' Hector. What we whispered, you never dreamed—never imagined that your chattel could dream of rebellion, or find the means to strike at you.  And now you'll all be lost, for your blindness."  
                                  
                                They did dream it, you're sure—feared it every day, whether they thought about it or not.  You've seen that nightmare in the nobles' eyes during floggings and Harrowings, heard it in the mutters you weren't supposed to catch.  And you hear it now as half the veneurs begin to shout incoherent insults and denials at you.
                                  
                                Your former master 
                              stares at you with utter revulsion, and finally waves his comrades into silence.  "Give your signal, then, dog.  And let us end this."
                              *goto sharpsig
                            *selectable_if (eclect) #"I am the Eclect of the Angels.  By attacking me, you may well have earned damnation as well as death."
                              Hector and the veneurs just stare at you, momentarily dumbstruck.  "Pray to the Merciful Angels for Their forgiveness," you conclude sternly, "in the seconds that you have left."
                              
                              "They believe you?" Hector rasps, and you realize he's actually been staring at the unwavering muleteers. "You…you've truly got this pack of thieves believing that 
                              *if helot
                                some shit-stained helot slave is
                              *if aristo
                                some jumped-up bastard's get is
                              the Chosen of the Bloody Angels?"
                                  
                              "Watch your tongue, kurios," growls one of your outlaws. "What you say here is heard in Elysia."
                                  
                              Your kermes-clad
                              *if aristo
                                cousin
                              *if helot
                                former master
                              bursts into shrill laughter; the other nobles look torn between outrage, disgust, and incredulity.  Finally, Hector regains control and shakes his head.  "I'd offer you a last chance to beg the Angels for mercy…but if there were ever any doubt about where you're bound, ${orig_lname}, you've just erased it.  Give your signal, and end this."
                              *goto sharpsig
                *if helot
                  #"Keriatou!  We offer one chance at parley!"
                    *goto hecblazeparl
                #"Fools!  Flee now, or be utterly destroyed!"
                  "$!{orig_lname}!" Hector bellows in return, spittle flying from his lips.
                  *if aristo
                    "My Angels-damned cousin 
                  *if helot
                    "The bloody churl 
                  is here ${him}self! Take ${him}—take ${him} now!"
                    
                  Ignoring your threat, 
                  *label beckvenflank
                  he beckons the veneurs toward the sides of your formation. 
                  *if com > 1
                    The Keriatou clearly expects to be able to break it up from the flanks while your untrained muleteers struggle to reposition their pikes.  In the dust of the charge, none of the nobles immediately spy
                    *goto bolas
                  *goto vensweep
                #"Dogs of the Karagonds!  Lackeys and traitors to Shayard!"
                  *set natl %+10
                  Hector begins to laugh ecstatically at the sight of you and reins in his horse.  "$!{orig_lname}!  My thrice-damned
                  *if aristo
                    cousin
                  *if helot
                    churl
                  has come ${him}self!  I'd not thought to have your head for a month yet."
                  
                  You pointedly ignore him, calling out to the other veneurs instead.  
                  *if helot
                    "This aristarch boy 
                  *if aristo
                    "My cousin
                  has led you directly into our trap—but worse, he leads you to betray your homeland.
                  *if helot
                    Listen, while you still can.  Listen to a child of Shayard's soil.  It's to your shame that you name us rebels and ride against us.  If you nobles would only have resisted the damned Karagonds, the helots wouldn't have had to lead the way…."
                  *if aristo
                    How long, by Xthonos, how long until you see?  How long will you heed the Karagond lies and ignore our sacred rights as free folk of Shayard?  How great a shame, that the nobility of the Rim name us rebels and leave the battle for our fatherland to the yeomanry and helotry!"

                  You'd hoped to keep them talking, and several of Hector's hunters become visibly uneasy at your speech.  But your
                  *if aristo
                    cousin
                  *if helot
                    former master
                  just spits on the ground. "The only traitors I see are cowering in the dust before me.  And if this is a trap, spring it and be damned."  Without listening to your retort,
                  *goto beckvenflank
          #I try keeping them at a distance.
            *set close false
            *if int = 2
              Do you want to use ${wisardry}?
              *choice
                #Yes—to unseat Hector and those closest to him.
                  *goto treeunseat
                #Yes, but not on Hector.  I want him spared.
                  *set hectarg false
                  *goto treeunseat
                #No, bows will do.
                  *goto pepperem
            *label pepperem
            "Bows!" you shout to the trusted handful of outlaws who knew of the ambush.  Four are already retrieving their hidden bows, calmly stringing them, gauging when the veneurs will come into range.  "This is our trap, not theirs," you inform the rest of the frightened little group.  "As soon as that horn sounded, 
            *if simzstalk
              ${simon}
            *if kalstalk
              ${kalt}
            *if not(simzstalk) and not(kalstalk)
              *if elery > 0
                Elery
              *if elery < 1
                Ciels
            and a band of archers began moving into position to kill them. Hold, and we'll live." 
            
            *if cha > 0
              The muleteers glance uphill toward the trees, and you can see new hope in their stance.
              *set holdfast 1
            *if cha = 0
              The muleteers still look terrified and uncertain despite your promises.
            "You lot—point those pikes at the veneurs," Zvad growls, and they hasten to do so.  Seconds later, your four seasoned bandits begin to loose arrows toward Hector's party.  
            
            The nobles slow their charge when the first shafts whistle past them, circling three hundred-odd yards away from you.  When they take in how few of you are carrying bows, however, Hector laughs aloud and spurs his horse back into a gallop.  His ten veneurs follow close behind, raising their own bows and howling mockery at your archers.  You have bought the ambush a minute or so at best.
            *page_break
            *goto zvadspear
          #I let them close with us and try to parley with them.
            *set parley true
            *goto zvadspear

      #With the ambush force, ready to flank and crush the nobles.
        *set hambush +2
        Though sharp rocks jab your hips and belly and pine needles prick your shoulders, you do your best to stay motionless on the clifftop.  Far below you, small as mice, a dozen outlaws herd a chain of mules up the dusty Whendward track.  Even from here, their fear is visible in their constant scanning of the slopes and crags.  It was in terrain not unlike this that Hector Keriatou slaughtered your other supply train.
        
        You wonder how they would look if they knew that the attack would come today.  Yesterday, Alira spotted a pair of noble veneurs on the far side of the valley from you, spying out the muleteers.  They soon vanished, and unless they've smelt a trap, you expect them back soon.
        
        A hand taps your boot, and you slither back into the hilltop pine copse to see Young Earnn.  The baby-faced tracker's eyes dance with nervous excitement. "It's time, ${kuria}," he breathes.  "They've returned with the other nine, all a-horse.  Moving slow for the moment, but I reckon it won't be long till they make their charge."
        
        His eagerness almost hides how haggard Earnn's face has grown over the days of constant thirst, running, and half-sleep.  The mule train moves slowly, but it's been hard work to shadow it—especially while keeping yourselves far back and well hidden enough to not alert the veneurs.  You hope
        *if elery > 0
          Elery and her
          *set b_name "Elery"
        *if elery = 0
          *set b_name "Ciels"
          *set b_his his
          *set b_him him
          *set b_he he
          Ciels and ${b_his}
        smaller party are still shadowing you, far enough back to close the trap.
        
        And you hope you chose the right person to lead the mule trains:
        *choice
          #Zvad.
            *set zv_lead +2
            *if simzstalk
              *set simzwme true
            *if deputy = "Zvad"
              Your ${whend}ish deputy
            *if deputy != "Zvad"
              The ${whend}ish bandit 
            had accepted the role stoically as usual. "I'll get them practicing with their pikes in the evenings, ${addressu}.
            *if sybla > 0
              The drills Sybla taught them.
            See if they can't keep the veneurs' horses off us until you arrive."
            
            *goto ambushparty
          #Radmar.
            *set rad_lead +2
            *if simzstalk
              *set simzwme true
            *set c_name "Radmar"
            *set r_rel +1
            The brawny youth had eyed you suspiciously when you asked him to start accompanying the mule trains. "If your archers are too slow coming when the Keriatou attacks, it's my neck."
            
            "We won't be slow," you had promised.  Of the former helots whose loyalty you've now discreetly tested, few can match Radmar in a fight; you think he'll be a rock holding the muleteers together. "Just hold the line when the attack comes."
            
            *if ruth > 60
              Radmar had continued to stare at you, visibly unpersuaded.  "You'll need to keep the archers well back and protected before the ambush. They're your veneur-killers—you won't want to lose a one of them.  But the muleteers…you could lose nearly all of them and still beat Hector.  And you're ruthless enough to do it.  Why should I put myself on that side of the arrows?"
              *if r_rel < 1
                In his eyes had been the unspoken challenge, [i]Are you trying to rid yourself of me?[/i]
              
              You'd sighed. "The Archon's troops will be coming for us, Radmar, in large numbers.  I can't afford to lose anyone if I can help it.  I'm sending you because I think it'll save us some men and women who can hold a spear. Will you do it?"
              
              After a lengthy silence, Radmar had growled, "I will.  But you'd best be there when we need you…or by Xthonos I'll survive long enough to pay you out for it."
              *page_break
            *goto ambushparty
          *if kalstalk
            #${kalt}.
              *set kal_lead +3
              *set c_name kalt
              *set c_he zhe
              *set c_his zhis
              *set hambush +1
              ${kalt} had agreed to lead the mule trains immediately, with a broad, unperturbed grin.  "You'd best hurry down when the attack comes, Captain—else we might just fell them all before you reach us."
              
              *goto ambushparty
          *if simzstalk
            #${simon}.
              *set c_name simon
              *set c_he zhe
              *set c_his zhis
              *set hambush +1
              *set simz_lead +1
              ${simon} had nodded gravely when you offered it to ${zhim}. "But, ${addressu}…you're quite certain I shouldn't be with you?  In the hunting party?  I excel at woodcraft."
              
              "We have several good archers and trackers, but only one 
              *if s_sword != 1
                *if aristo
                  other
                noble,"
              *if s_sword = 1
                blademaster," 
              you replied.  "And it may give Hector pause to find you the target of his ambush. Every pause is a boon to us."
              
              *goto ambushparty
        *label ambushparty
        Now you scramble back up to the cliff-edge with 
        *if simzwme
          ${simon},
        Earnn and Alira.  The smell of sap and dust is thick with your nostrils this close to the ground. You fight to stifle a sneeze while you make your last survey of the terrain.  Far below you, ${c_name} and the rest are beginning to traverse a gentle slope.  To either side of the track, the ground is rugged but mostly treeless for a hundred yards or so.  
        *if com > 0
          This is surely 
        *if com = 0
          From what your hunters have said, you're sure that this is 
        where Hector will ride out against them.  "Where will we best command the mule-track?" you breathe.
        
        Alira pauses for only a few seconds before pointing to three forested outcrops far below.  
        *if simzwme
          ${simon} smiles ${zhis} silent approval.
        "Right," you agree.  
        *if com = 0
          "We'll
        *if com > 0
          "I'll 
        take that one."  You need to be closest to the fighting, as you'll be giving the signal to attack.
        *if com = 0
          Of course,
          *if simzwme
            ${simon}
          *if not(simzwme)
            Alira
          will be at your side advising you on the best moment; with your combat inexperience it would be folly to rely entirely on your own judgment.
          
          Earnn gives a barely perceptible nod; he'll be
          *if not(simzwme)
            directing archers to the other two perches.
          *if simzwme
            on the third perch, with Alira in the middle.
        *if com > 0
          Earnn gives a barely perceptible nod toward the further perch, exchanges hand signals with Alira, and shoots you a grin.
        "You'll be there first—it's straight down from here.  We'll be at the others a minute behind you.  Angels speed you, 
        *if religion < 21
          ${addressu}."
        *if religion > 20
          ${addressu}.  Er, I mean, kenon speed y…"  His whisper trails off uncomfortably.
        
        You 
        *if religion > 20
          let it go—old habits of speech are slow to erode—and all of you
        slither back down on your bellies to the rest of the ambush party. All their bows are already strung, and they're split into the agreed groups.  "Haste, haste," you hiss. "Fast as you can without being heard or spied.  The veneurs will be on ${c_name} soon."  Without waiting for their assent, you turn and begin half-sliding, half-running down the stony slope.  Two archers
        *if simzwme
          and ${simon} de Firiac
        *if (com = 0) and not(simzwme)
          and Alira
        follow close at your heels.
        *page_break
        You've descended perhaps three quarters of the thickly forested slope when Hector Keriatou's hunting horn blares from the mule-track. Despite yourself, 
        *if aristo
          a thrill jolts through you—that was the sound of a thousand ${girl}hood rides, of deer running before you or hounds bursting from the undergrowth after some great boar.
        *if helot
          it sends a jolt of terror down your spine—the fear of the young master suddenly coming upon you in the forest, to accuse you of poaching or fornication or some other such pretext.
        "Damnation!" you growl, and break into as close to a sprint as you dare.  Little need now for stealth, with the din of cheers, howls, and hooves carrying up the breeze.  
        *if helot
          The Keriatou 
        *if aristo
          Your cousin 
        is definitely charging the muleteers, not coming for you.
        
        Seconds stretch out painfully as you careen down the slope.  Branches whip at you, scree tumbles underfoot; ahead of you, the outcrop looms closer and closer.  You spring up the boulders, then drop and crawl the last few yards to overlook the battle.
        
        *if (c_name = "Zvad") or (c_name = "Radmar")
          *set followers -5
          *set nonkids -5
          *set dead +5
          *set morale -7
          A disaster is unfolding on the track.  Half your outlaws are already down; the remaining six are back-to-back with ${c_name}, their pikes thrusting frantically at the nobles circling them.  As you watch, the kermes-clad Hector spurs his reluctant horse inward, hacking at the wooden spears and howling, "Filth, brigands!  Take the leader!  Take his head!"
          *if c_name = "Radmar"
            Radmar stabs back at the Keriatou while roaring to the survivors, "Spears up!  Keep'm high, keep'm off!  Go for the eyes!"
          *if c_name = "Zvad"
            The big ${whend} fends him off grimly, his pike juddering and splintering under Hector's sword.
          
          Just as you're sure the knot of outlaws is about to come apart, Hector spits a curse and lets his terrified horse carry him back.  He beckons the veneurs back up the trail, where most of them trade blades for bows.  You don't know what another flight of arrows will do to your muleteers—several of whom have dropped their pikes to raise shields overhead—but Hector's probably counting on breaking their spirits before a decisive charge.
        *if c_name = kalt
          *set followers -3
          *set nonkids -3
          *set dead +3
          *set morale +4
          The screams, both animal and human, are earsplitting even at a distance.  At first you stare in amazement at the slowly clearing dust cloud—not understanding how ${kalt} managed to bring down three riders, horses and all, around ${zhis} beleaguered knot of muleteers. Then you see the cords around the still-thrashing legs of one animal and understand. Bolas. Not the small ones that helots typically use for petty game, but big enough to fell a charging stallion at twenty yards.  
          
          You've occasionally wondered what ${kalt} has been up to in the mornings, taking a few other young bandits out for 'weapons practice.'  Now you know.
          *page_break
          Three of your outlaws at least are also down, felled by veneur arrows or lances.  But the survivors stand shoulder to shoulder, presenting an
          *if sybla < 1
            almost
          unwavering circle of pikes.  Above the cacophony, you pick out Hector's furious shriek. "…I'll wind out your guts over a flame while you live, ${zgirl}!  Do you know who I am?  Do you know what I did to the last dung-chewing helot filth who dared to touch one of my horses, let alone…"
          
          ${kalt} interrupts with something that Hector could (improbably) do with his horses.  Then ${zhe} calls joyously, "Hold, spearmates!  Hold but a few moments longer, till ${kuria} ${lname} sticks these piss-bladders full of pins."
          
          Three of the surviving veneurs turn with obvious wariness to scan the treeline and crags, including your hiding place.  But the sunshine is against them, as you'd hoped, and their gaze passes you by.  The kermes-clad Hector just gapes at ${kalt}—clearly unable to comprehend this degree of defiance from helots who should be cowering before his wrath, if not fleeing in total disarray.  Then, "Lying clod!" he snarls, and spurs his horse savagely toward your muleteers.  
          
          In a single smooth movement, $!{kalt} lets go of ${zhis} long spear, brings up a javelin from ${zhis} side, and hurls it straight at the charging noble's head.  Hector flings himself to one side with a squawk, dodging the blow but almost unhorsing himself.  Uncontrolled, his wide-eyed stallion dances back away from the row of pikes.  Your outlaws hoot and cheer, adding their gleeful obscenities to ${kalt}'s.
          
          You don't think you've ever seen
          *if aristo
            your cousin
          *if helot
            your former master
          so disheveled and shaken as he is now. He regains the saddle, barks an order to the other nobles; they canter back down the trail, trading blades for bows, and wheel about. ${kalt} curses, losing ${zhis} grin, and yells, "Shields up!"  
          
          The pikes waver or drop altogether as your muleteers clumsily scramble to get shields overhead.  You don't know what another flight of arrows will do to them, but Hector's probably counting on breaking their spirits before a decisive charge.
        *if c_name = simon
          *set followers -1
          *set nonkids -1
          *set dead +1
          The veneurs are circling your terrified muleteers, bows and javelins at the ready, but for the moment hurling only taunts.  Two outlaws are down—injured, if not dead, from the initial clash—but the others are maintaining a steady circle of pikes.  In the center of the group, ${simon} de Firiac holds a shield at the ready while gesturing with ${zhis} 
          *if s_sword = 1
            sword.
          *if s_sword != 1
            spear.
          "Consider, milord Keriatou, before throwing away your chance to parley with me.
          *if aristo
            Your cousin is not here; 
          *if helot
            As the only noble-born in Whendward,
          the terms I give will be kinder than you may expect from 
          *if aristo
            ${him}." 
          *if helot
            others."
          $!{zhis} voice is clear, only slightly frayed.
          
          Hector looks poised to spring from the saddle, and you can all too easily imagine the accompanying
          *if aristo
            grin—you saw that stance whenever he knew the quarry was in his grasp.
          *if helot
            grin—the one which always preceded his punishment of some unresisting helot.  
          "I'd wondered if we'd come across you here, de Firiac.  Outside this wilderness, some are talking of your rescue…and some of dragging you back to be Slow-Harrowed like your traitor sister should have been.  Now we know which were right."  He leans forward, his voice turning venomous. "And I'll hear no terms from a helot-kissing blackguard."
          
          ${simon} bares ${zhis} teeth, points ${zhis} weapon at the young aristarch.  "Then I offer challenge, Hector Keriatou. Upon your body I'll prove my honor."
          
          "What?  You've none to prove.  Caught here, sneaking through the woods amongst rebels and donkeys?  I'll not sully my sword with your traitor blood."  Hector spits onto the stony track and—before ${simon} has a moment to retort—beckons the veneurs back down the trail.  
          
          "Coward!" ${simon} shouts after him, and your haggard-looking muleteers shakily take up the insult.  "You'll nail a helot mule-driver to a tree, but you won't face me armed?  Shame, Keriatou!"
          
          Your kermes-clad
          *if aristo
            cousin
          *if helot
            former master
          ignores the insults and, like the other nobles, trades his blade for a bow.  As the veneurs wheel around, ${simon} yells, "Shields up!" and the outlaws clumsily scramble to protect themselves. You don't know what another flight of arrows will do to them, but Hector's probably counting on breaking their spirits before a decisive charge.
        
        Do you
        *if helot
          order your archers to
        loose arrows at the 
        *if helot 
          veneurs?
        *if aristo
          veneurs, and order the others with you to do the same?
        *choice
          #Yes, while there's clear space between Hector and my beleaguered followers.
            *set hambush -2
            *set ruth %-10
            If you delay, your muleteers will likely be slaughtered.
            *if helot
              "Now!" you growl to
              *if simzwme
                ${simon} and
              *if not(simzwme) and (com < 1)
                Alira and
              the archers.  "Take them!"
              *if not(simzwme) and (com < 1)
                For an instant, Alira looks like she's going to question you…but then she shakes her head and draws her bow.
              
            *if aristo
              You rise, draw your bow, and loose an arrow at Hector Keriatou.
              *if com < 1
                It flies wild, of course, but
              *if simzwme
                ${simon} and
              *if not(simzwme) and (com < 1)
                Alira and
              *if not(simzwme) and (com > 0)
                Behind you, you hear
              your archers 
              *if com < 1
                shoot with greater accuracy.
              *if com > 0
                stand to do the same.

            *if aristo and (com = 2)
              Your arrow comes within a hand's span of your
              *if hector = 2
                loathed
              *if hector >= 4
                once-beloved
              cousin's face, and he ducks away, causing his own arrow to fly wild.
            *if helot or (com < 2)
              As arrows whirr past their horses, the veneurs lower their bows and duck, cursing.
            "Ambuscade!" Hector bellows in furious realization.
            *if aristo
              For just a moment, his eyes scour the slope; you're sure he knows you're behind the attack.  Then he wheels his horse and cries,
            "Retreat!"  Your little ambush party feathers one of the veneurs as they flee. It's hard to tell how badly she's injured before the trees hide her from your sight.
            
            You break into a run and pursue them as far as the next bend in the hill, hoping for another chance. But the next time you catch sight of them, they're too far away, through too much foliage. All you can do now is hope that ${b_name} manages to do more damage than you did.
            *page_break
            *if simzwme
              "Well done, ${addressu}," ${simon} says 
              *if not(eclect)
                fervently, 
              *if (eclect)
                reverently,
              lowering ${zhis} 
              *if not(eclect)
                bow and clapping you on the shoulder.  
              *if (eclect)
                weapon and offering a deep bow.
              "You saved all their lives down there."  Far behind you, you can still hear the ragged cheers rising from the surviving muleteers with ${c_name}.
              
              You cast a troubled look back at ${simon}, finding it hard to share the general relief.  "If Hector and the veneurs aren't broken today, we'll lose more people than that.  We won't ambush them this easily again."
              
              The young de Firiac
              *if eclect
                straightens and
              inclines ${zhis} head, neither agreeing nor disagreeing.  "Let's see how ${b_name} does with them."
              
            *if not(simzwme) and (com < 1)
              Alira lowers her bow, grim-faced.  "If Hector and the veneurs escape that lightly, ${addressu}…"
              
              "They'll come hunting again, and not be caught so easily next time.  I know."  You try to keep the defensive edge out of your voice.  "But we couldn't stand by while the muleteers were slaughtered."
              
            Back at the battle site, ${c_name} is making sure the injured are tended and the mules rounded up.  $!{c_he} looks up as you approach and
            *if c_name = "Zvad" 
              offers a look of wry commiseration.  "We didn't hurt them much, ${addressu}…but I can't say I'm sorry you chose to attack early."  He glances around.   "I don't think any of us would have been here had you waited."
              
              "What happened?"
              
              Zvad wipes the dust and blood from his forehead. "Takes a lot of drill and a lot of trust before you'll stand shoulder to shoulder against a charging horse, ${addressu}. We knew that.
              *if sybla > 0
                Sybla didn't pretend she'd
              *if sybla = 0
                I haven't yet
              got them that far."  He rinses out his mouth from a waterskin, shakes his head somberly, and returns his attention to the dead and wounded.
              
              You see Young Earnn and his archers emerge from the woods, and walk up to explain the early ambush to them.
              *goto ambushoutcome
            *elseif c_name = "Radmar"
              snarls, "What by Taratur was that?  First you hold off while they slaughter us, then you loose arrows with only a handful of archers?  What did these die for, if Hector bleeding Keriatou gets away?"
              *choice
                #I snap, "You'd rather I'd waited until you were all dead?"
                  Radmar surges toward you, face wrung with anger and pain. When he halts mere inches away, blood spatters against you from a deep gash in his scalp. "I'd rather you'd been close enough to hit them when they first broke cover, damn you, [i]${kuria}[/i].  I'd rather not have been alone out here with a dozen mule-herders against eleven armed nobles a-horse."  The survivors wince or scowl, looking away from both of you.
                  
                  You keep your anger in check.  "Next time you won't be, Millstone.  Nor anywhere near command of a raid."
                  *label bynowearnn
                  
                  By now, 
                  *if (com > 0) or simzwme
                    Alira,
                  Young Earnn and the other archers have also come down from their perches.  "Calm down, Radmar," Earnn says, hands outspread soothingly.  "We were as close as we could be.  Any closer, and they might well have been the ones ambushing us.  All of us."
                  
                  The fuming former helot hurls down his axe and stalks off to recover a balky mule.
                  *goto ambushoutcome
                *if aristo
                  #I return a stern glare.  "Radmar.  You [i]will not[/i] take that tone when addressing your leader."
                    "Xthonos eat your eyes, you highblood papejay!" 
                    *label nonpapejay
                    Radmar roars, charging toward you. He halts mere inches away; blood spatters against you from a deep gash in his scalp. "I'll talk as I damned well please.  You think you can treat us like so much meat and still lead us?"
                    
                    "I treated you like a future leader, Millstone." You refuse to back away by even a hair—pushing down the knowledge that Radmar might be able to snap your neck before anyone could separate you.  
                    *if aristo
                      "Clearly a mistake I shan't repeat.  
                    *if helot
                      "Damn me for that mistake if you want to.
                    Yes, I chose to chase the Keriatou off unharmed to ${b_name}, to keep the veneurs from overrunning you.  And you call that treating you like meat?"
                    
                    "I call it…" Radmar begins, but you interrupt him. 
                    *label acceptconseq
                    
                    "When a fight goes against us, I need someone in command who will own what comes of it—not curse at another leader to hide his own shame."
                    *goto bynowearnn
                *if helot
                  #I match him glare for glare.  "Show some respect or hold your tongue, Radmar."
                    "Respect?"
                    *goto nonpapejay
                #I just look at him levelly.  "We came as fast as we could—and if we'd waited, the rest of you would be dead too."
                  "As fast as you could," Radmar jeers. "From whatever far-off peak you were cowering on.  It wasn't good enough, ${kuria}.  Their blood is on your hands."
                  
                  "And not on yours?" You keep your anger barely in check.
                  *goto acceptconseq
            *elseif c_name = kalt
              nods expectantly.  "You catch them?"  Blood is smeared copiously along ${zhis} arms, head, and chest, but from ${zhis} smooth movements you doubt much of it's ${zhis} own.
              
              "No—but ${b_name} should yet be able to."
              
              ${kalt}'s shoulders sag, and ${zhe} looks suddenly as weary as you've ever seen ${zhim}.  "Let's hope so, ${kuria}.  It would be a shame to have lost these boys and girls for nothing."
              
              "Hardly nothing," you retort, walking   
              *label nearestfelledhorse
              over to the nearest felled horse.  "I'd expected you to hold until we arrived, not to bring any of them down."
              
              Both the animal and its rider have broken limbs, but the circle of earth churned up by the thrashing horse and the crawling posture of the veneur tell you that they survived their fall.  The blood blackening the ground came from slashes to their throat-veins.  
              *if int < 2
                You 
              *if int > 1
                With a shock, you 
              recognize the veneur:
              *if aristo and (int < 2)
                Ganelon Tarakatou, a bookish youth from one of the lesser Houses of the Outer Rim.  The last time you saw him, he'd been trying to explain some drama he was writing—a tale of ill-fated passion between a Diakon and a young Phalangite officer.  You struggle to imagine him taking to the woods to hunt helots.
              *if helot and (int < 2)
                a boy from the Tarakatou family, Ganno or something.  Not one with a reputation for helot-baiting, or you'd have known him with certainty.
              *if aristo and (int > 1)
                Ganelon Tarakatou, your fellow bibliophile.  An almost-friend who, but for your father's spite, might have been a close one.
              *if helot and (int > 1)
                Ganelon Tarakatou, the bookish noble who shared his library with you and eagerly discussed history with a helot.
              *if int > 1
                The man responsible for you learning the secret of ${wisardry}.
              *set sa_foll 904
              *choice
                *if (int > 1) and helot
                  #Grief hits me like a landslide.  I hadn't realized how much I'd hoped that we could win over a noble like Ganelon.
                    *set sa_foll 905
                    You'd had few enough friends as a ${girl}, and none with much interest in debating the things that mattered—the truths of the wider world, all the things that you could experience only in books.  You'd never fostered much hope of finding such a friend, not until you met the 
                    *if not(malepref)
                      serious 
                    *if malepref
                      beautiful
                    young Tarakatou.
                    
                    It was unthinkable—ridiculous!—to imagine an aristo and a helot sustaining a friendship.  Every philosopher counseled that true friend-love could emerge only between equals.  But for a time, you'd thought the books mistaken.
                    
                    Pressing your fingers against your skull, you try to blink away the stinging blur.  The world feels empty but for the smoke in your nostrils, senseless chatter against your ears.  You stride off up the slope, but ${kalt} follows you, rubbing dust along ${zhis} arms to remove the blood.  It's a practiced, almost thoughtless gesture; you recognize it from the Keriatou pigkeepers you grew up with.  
                    
                    "You knew him," ${zhe} says quietly.
                    
                    "We knew of them all.  Didn't have much cause to know of this one, though.  He was no helot-baiter."  You try not to let your emotion show to ${kalt} of all people.
                    
                    "He show you some kindness?" $!{zhe} waits for you to respond, then drops ${zhis} voice even lower.  "You two were…"
                    
                    "No!" you snap. For a moment, you find yourself fiercely hating ${zhim}—as much for reducing learned Ganelon to a shrieking, mud-spattered victim as for the killing itself.  "Damn it, ${kalt}, let it go."
                    
                    After a moment, ${kalt} nods.  "I know it's hard, Captain.  Believe me, I know."  $!{zhis} weariness is plainly audible again.  "But look at him.  Remember that he stood there while that Keriatou nailed Glena to a tree.  Maybe helped."
                    
                    You round on ${zhim} furiously, struggling to keep your voice below a shout.  "${kalt}, will you just…"
                    
                    "They find it pretty damned easy to harden their hearts to us, Captain," ${kalt} growls.  "They can do it at the drop of a leaf. If 
                    *label wecantdo
                    we can't do the same?  There's no hope for us.  And no hope for…whatever you imagine this rebellion to be."  
                    *if k_rel < 5
                      $!{zhe} glares at you for another moment, then shakes ${zhis} head.  "But it gives me no joy to hurt you.  For what that's worth."
                    *if k_rel > 4
                      The rage you heard in ${zhis} voice during your earlier clash is back again, stronger than ever.
                      *set k_rel +1
                    *page_break
                    *goto ambushoutcome
                *if (int > 1) and aristo
                  #Grief hits me like a landslide.  I hadn't realized how much I'd hoped that our friendship could be rekindled—that I could win him over.
                    *set sa_foll 905
                    The young nobles of Rim Square were for the most part a preening, shallow bunch, vying for your cousins' attention.  Ganelon never allowed himself to be drawn into those games.  In particular, you don't remember him ever joining when Calea led the rest in mocking you.
                    
                    While Father's grudges forced you apart, you always assumed that you and Ganelon would become closer in time.  If not before, it would happen once your father grew frail or passed away.  One day you'd open your libraries to each other, spend long afternoons over cups of Sorettyn on a balcony, debating the things that truly mattered.  One day you'd have a friend.
                    
                    Pressing your fingers against your skull, you try to blink away the stinging blur.  The world feels empty but for the smoke in your nostrils, senseless chatter against your ears.  You stride off up the slope, but ${kalt} follows you, rubbing dust along ${zhis} arms to remove the blood.  It's a practiced, almost thoughtless gesture; you remember that ${zhe} was raised a pigkeeper.  "You knew him," ${zhe} says in a low voice.
                    
                    "I knew them all." You try not to let your emotion show to ${kalt} of all people.
                    
                    "This one was different." $!{zhe} waits for you to respond, then sighs and shrugs.  "I'm sorry, ${kuria}."
                    
                    For a moment, you find yourself fiercely hating ${zhim}—as much for reducing learned Ganelon to a shrieking, mud-spattered victim as for the killing itself.  "I didn't think butchering nobles was something you found cause to regret."
                    
                    ${kalt}'s weary voice takes on an edge. "And maybe you don't understand me as well as you think, ${milady}."  $!{zhe} points to Ganelon.  "Or your friend there, either.  I'm sure he was a pleasant enough fellow…but he found it pretty easy to harden his heart to us when your cousin was nailing Glena to a tree."  
                    
                    You round on ${zhim} furiously, struggling to keep your voice below a shout.  "${kalt}, will you just…"
                    
                    "Most nobles can do it at the drop of a leaf," ${kalt} growls.  "If 
                    *goto wecantdo                    
                *if aristo
                  #"Angels, Swineherd—he wasn't one of your pigs." There are good deaths and shameful deaths; for a wounded noble to be butchered by some helot knife is unseemly at best.
                    *set cred_h -5
                    *set kal_lead +1
                    *if k_rel < 5
                      *set k_rel 6
                    *if k_rel > 4
                      *set k_rel +1
                    ${kalt}'s lips vanish into a tight scowl. "It's a shame you weren't here to nobly behead him with your sword, ${milady}. My little blade could only get halfway through.  But if you command, I can try for the rest."  Two or three of the muleteers snort with suppressed laughter.
                    
                    Glancing around, you confirm that both the other veneurs died similarly. "It's no laughing matter.  We're rebels, not cutthroat brigands.  Even our enemies merit an honorable death."
                    
                    "This was a battle, ${kuria}," ${kalt} says flatly.  "They came trying to kill us, and as I remember, you wanted me to try killing them.  Now they're dead.  I reckon it won't matter to them how they got there.  And if it matters to you, they'll use that—they'll use any weakness you show, believe me."
                    *if k_rel > 6
                      The anger on ${zhis} face is shifting to something resembling contempt.

                    Seeing that the fierce young helot clearly has the sympathies of the band, you just shake your head.  
                    *label cleanthebodies
                    "Clean them up and prepare mules to bear them back."  You can't return them directly to their families—the most honorable course—but you can leave them on a road where they'll be found quickly, rather than abandoning their bodies in the wilderness.
                    
                    *goto ambushoutcome
                #"He'd have made a good hostage," I say reprovingly.
                  "We don't need hostages, ${kuria}.  We need them to fear us."  ${kalt} folds ${zhis} bloodied arms across ${zhis} 
                  *if kalt = "Kalt"
                    chest.
                  *if kalt = "Kala"
                    breasts.

                  "Hostages mean ransoms.  If you'd starved here with us over the winter, you wouldn't be so quick to turn those away," you reply drily. The surviving muleteers grunt their agreement.  
                  *if aristo
                    "This one's family were well off enough.  They'd have paid well for their son's return."
                    *if int > 1
                      [i]And I'd have had a chance to find out whether he had any more books on ${wisardry}.[/i]
                  
                  "I'll keep it in my mind next time, ${milady} ${lname}." ${kalt} sounds decidedly unconvinced, and unconvincing; but ${zhe} walks off before you can press the point.
                  *if aristo
                    
                    You sigh, gesture at the other two veneurs as well as Ganelon.
                    *goto cleanthebodies
                  *goto ambushoutcome
                #I say nothing.  It needed to be done.
                  *goto ambushoutcome
                #"Well done." I clap ${kalt} on the shoulder.
                  *set ruth %+5
                  *set kal_lead +1
                  *if k_rel = 6
                    *set k_rel 5
                  $!{zhe} grins up at you, some of ${zhis} weariness receding.  "They came in with shields up, expecting arrows or javelins.  I reckoned that noble hunters wouldn't think too much about how helots hunt."
                  
                  *goto ambushoutcome
            *else
              *if c_name != simon
                *bug should be simon
              *label simzsavedhug
              beams.  "You saved us, ${addressu}!"  $!{zhe} looks like ${zhe}'s barely checking ${zhis} desire to throw ${zhis} arms around you.
              
              "You were holding them off well enough," you note. "For a moment there, I thought 
              *if helot
                the Keriatou
              *if aristo
                Hector 
              was going to take you up on that duel."
              
              ${simon} shakes ${zhis} head ruefully.  "Alas, he knew better.  Shameless coward.  Perhaps if he escapes ${b_name}, I'll have another chance at him."
              *goto ambushoutcome
          #No—my other archers won't be in place for a minute yet.  Shooting now will just spur a retreat by Hector and the veneurs.
            *set ruth %+10
            Unless you break the veneurs, all the lives sacrificed in this ambush will be in vain—and you'll never catch Hector off guard this easily again.  You need to wait until the ambush can be decisive, whatever the cost to the "bait."
            *if simzwme
              
              ${simon} is at your side, gripping your arm.  "$!{addressu}—we must strike now."
              
              "No," you whisper 
              *if ruth < 55
                hoarsely.
              *if ruth > 54
                coolly.
              "Hold for Earnn and Alira."
              
              "$!{addressu}—they'll all die."  The de Firiac sounds disbelieving…or as if ${zhe} wishes ${zhe} could disbelieve.
              
              "We hold."  
            You begin a slow count to fifty.
            *if not(simzwme) and (com < 1)
              Alira maintains a grim silence at your shoulder; she understands what you're doing.
              
              *comment endif
            New howls and screams burst from the muleteers as the veneurs and Hector loose one arrow after another into their midst.  ${c_name}'s
            *if c_name = "Radmar"
              booming,
            desperate voice rises above the others: "Shields up!  Keep them up!  Hold, hold!"
            
            *if c_name = simon
              Your young noble, practiced in basic Phalangite tactics, manages to get a decent shield cover out of the muleteers.  Only two more of your followers lie crumpled on the ground at the end of the barrage, though several more are bleeding from broad gashes.  They glance around at each other, seeming to take heart from how many are still upright.
              
              "Is that the best you can do, coward?  You and your so-called veneurs?" ${simon} howls furiously as the nobles once again trade their bows for lances and swords.  "Do all your quarries die of tedium?  Ah, no, I forget myself. You're no hunters—you're a pack of grubby-handed carpenters, who only know how to kill with mallet and nails."
              
              Hector laughs contemptuously, but when he speaks, there's a murderous edge to his voice.  "We're coming for you now, de Firiac.  You'll die in no honorable duel. A lance in the gut and a sword to the throat…my word on it."
              *set followers -2
              *set nonkids -2
              *set dead +2
              *goto pepperthem
            *elseif c_name = kalt
              *set followers -3
              *set nonkids -3
              *set dead +3
              When the barrage ends, four more of your followers are on the ground, dead or badly hit.  ${kalt} raises ${zhis} shield enough to howl, "Is that the best you can do, you aristo yaudswivers?" through a toothy grin.  The rest of the standing muleteers join the chorus of abuse, their voices only slightly tremulous.
              
              "Take ${zhim} alive!" Hector barks to his surviving veneurs, who are again trading their bows for hunting lances and swords.  "Whatever's left of ${zhim} by evening will be our message to ${orig_lname}."
              *goto pepperthem
            *else
              *set followers -4
              *set nonkids -4
              *set dead +4
              By the time the nobles once again trade their bows for hunting lances and swords, only two muleteers and ${c_name} are still upright—and only because they're leaning heavily against each other.
              *if simzwme
                You glance at ${simon}, then quickly avert your eyes from ${zhis} sympathetic anguish.
              *if c_name = "Radmar"
                "Ah, Angelspit, ${addressu}, be damned to you!" Radmar bellows
              *if c_name = "Zvad"
                "Now, ${addressu}!" Zvad bellows, 
              loudly enough to be heard a mile off.  "Kill them now, before they escape!"
              
              Hector and his veneurs burst into mocking laughter—but they also take a moment to scan the treeline and crags, including your hiding place.  The sunshine is against them, as you'd hoped, and their gaze passes you by.  "The most pathetic bluff I've ever heard," your
              *if helot
                former master
              *if aristo
                cousin
              scoffs.  "You're alone, brigand…and you'll die alone."
              *goto pepperthem
            *label pepperthem
            He blows his horn and vaults forward into a final charge.  Your surviving outlaws huddle together and raise their pikes, yelling something hoarse and wordless to keep themselves from fleeing.  
            
            "Fifty," you finish, and
            *if helot or (com < 1)
              bring your arm down sharply.
            *if aristo and (com > 0)
              loose your first arrow toward your cousin.
            *if com = 0
              Three
            *if com > 0
              Two
            *if aristo and (com > 0)
              more
            notched, whistling arrows fly down from your outcrop—followed seconds later by a small cloud from the two other perches where Young Earnn and
            *if (com < 1) and not(simzwme)
              his archers
              *goto aliraq
            *else
              Alira
              *goto aliraq
            *label aliraq
            have arrived.
            
            "Ambuscade!" Hector yelps in shock and jerks up his shield arm as the veneur next to him drops from the saddle.
            *if aristo
              For just a moment, his eyes scour the slope; you're sure he knows you're behind the attack.  Then he wheels his horse and cries,
            "Retreat!" By the time they reach tree cover, two more have died and you've feathered at least three of the survivors. You break into a run and pursue them as far as the next bend in the hill, sending them off toward ${b_name} with a few more arrows in their armor.
            *page_break
            When you return to the battle site,
            *if c_name = "Radmar"
              Radmar is crouched next to a dying outlaw, whispering something under his breath.  Young Earnn and his archers are tending to those who still have a chance of pulling through.  
              
              The brawny former helot struggles to his feet when he sees you approach.  He's bleeding through three different bandages on his limbs and head.  "I ought to kill you," he says, thick-voiced. "You took so bloody long…."
              
              "You won't." You wave away a worried-looking Alira and walk up to the enraged Radmar.  "You know it was the right thing.  It worked, and it's what you would have done in my place.  It's what gives their sacrifice a purpose."  You nod to the fallen muleteers.  "You held—and because you held, we killed enough veneurs today to give pause to the others.  Whether or not ${b_name} finishes off the rest."
              
              Radmar stares wildly at you for a few moments more.  "I…ah, damn it, ${kuria}."  He buries his head in his hands for a moment, then draws a shuddering breath and wipes the blood from his brow and cheeks. "Hope they put a javelin through the Keriatou's guts."
            *if c_name = "Zvad"
              you seek out Young Earnn and find him crouched in the middle of the dead and dying.  Something in the stance of the other archers tells you what you're going to see.
              
              Zvad is lying against a boulder; his big hands are clenched at his chest, with an arrow's fletching emerging from one fist.  His lips are bright with his own blood, his eyes distant and glazed.  They refocus as you approach, and he wheezes something too quiet and thick-throated to make out.
              
              You immediately kneel at his 
              *if int > 1
                side…
                *choice
                  #And try to heal him with ${wisardry}.
                    You cut your 
                    *if theurgy < 2
                      hand and try to remember the incantation from the scroll. "I see myself without a mirror…" but you can't remember it all, it's been too long since you last practiced it.  The blood pools in your palm, then runs off to the ground.  
                      
                      Earnn and the others stare at you curiously, wondering what kind of ${woman} gashes ${his} hand as a sign of grief.  At last you rock back onto your heels. Zvad's chest stopped moving some moments ago.
                      *goto zvaddie
                    hand, enter the now-familiar light-headed trance, and stare at Zvad, trying to make out something in the blur that you can Change.  Several times you think there's something that might be his body trying to heal itself…blood clotting?  Flesh knitting?  But it eludes you every time you try to come to grips with it.  
                    
                    Instead, you cause the big ${whend} even more pain, as your clumsy ${wisardry} inadvertently interferes with some element in his body.  He flinches and writhes each time you bring your attention to a Change.  But he does so silently, eyes fixed on yours in desperate hope.  You flinch yourself each time, groan an apology, and keep trying.
                    
                    Until at last the bubbles stop appearing on Zvad's lips, and the blur around him dissipates into something far more recognizable: blended earth, fire, water, air.
                    *goto zvaddie
                  #And try to hear what he's saying.
                    You lean in close.  "Try again, Zvad."
                    *label zvadlastword
                    *set zvlw true
                    
                    "We're not…ready," Zvad whispers, craggy face contorted with anguish and the effort of forming words.  "Not for this."  A red froth bubbles up between his lips, and he sags backwards, still clutching the arrow.  Within moments, his chest is still.
                    *goto zvaddie
                  #And grip his shoulder in silent consolation.
                    Trying to talk is obviously causing him agony. You shake your head wordlessly and he subsides. For another minute or two Zvad lies against the boulder, his breathing shallow and wet.
                    *if (theuknown >= 5)
                      "Do something, ${addressu}," Radmar implores.  He is bleeding through three bandages himself, but seems barely to notice. "Angels' sake, you can't just let him die!"
                      
                      "I don't know how to heal," you reply helplessly.  "If I tried using what ${wisardry} I do know, I'd be more likely to break or burn something than heal him.  Give him peace."  
                      
                      Zvad gives a barely perceptible nod, and moves one hand up consolingly to yours.
                    At last, the bubbles stop appearing on his lips.
                    *goto zvaddie
              *if int < 2
                side.  "You held well.  You led well.  Rest now."
                *goto zvadlastword
              *label zvaddie
              
              "He knew the risks," Alira says, stepping up next to you.
              *if zvlw
                She sounds almost as if she's arguing with Zvad, unsettled by his last words.
              "Zvad never walked into a fight unless he was ready to die in it."
              
              "Ah, damn it all!"  Radmar slams his fists against the boulder, again and again, tears mixing with blood on his unshaven cheeks.  "Xthon'damn it, we can't lose men like Zvad for this.  Tell me we're at least going to bring home Hector Keriatou's head today, ${addressu}."
              
              You remove Zvad's hands from the kermes-colored fletching.  Even if you hadn't known it was House Keriatou's color, there's no other House in the Rim extravagant enough to use a costly dye to identify their kills. "Let's hope so."
              *set morale -2
              *set zvad -50
              *if hor_guard = "Zvad"
                *set hor_guard "Radmar"
              *set zv_here false
            *if c_name = kalt
              ${kalt} strides over to meet you with a fierce grin on ${zhis} bloodied face.  Behind him, Young Earnn and his archers are binding up wounds among the surprisingly cheerful muleteers.  "That was fine timing, ${addressu}.  I was just beginning to worry that the bastards would crack us open…and then you arrived."
              
              "Seemed to me that you'd been doing well enough without us."  You walk
              *goto nearestfelledhorse
            *if c_name = simon
              you hear ${simon} giving orders to survivors and ambushers alike, making sure the injured are tended and the mules rounded up.  $!{zhe} looks up as you approach and
              *goto simzsavedhug
            *goto ambushoutcome
        *label ambushoutcome
        
        What feels like a very long time later, you spy ${b_name} and ${b_his} returning hunters through the trees.
        *if hambush > 10
          *set morale +5
          *set hec_cred 9
          *set cred_h +10
          *set cred_y +10
          *set cred_a -5
          Their jubilation is obvious from a hundred yards away.  "None of the veneurs who reached us escaped, ${addressu}!" crows Ciels.  "And they broke without felling a single one of us.  None of them will trouble us again."
          
          "And Hector?" you demand,
          *if hector >= 4
            hoping the thickness in your throat isn't audible to the others.
          *if hector < 5
            feverish with hope.
          
          "The one body we didn't find," ${b_name} admits ruefully. "But if he lives…let him crawl back and try to find more volunteers to die at our hands!"  
          *label restclapback
          *if sa_foll < 1
            *set sa_foll 903
          The rest of the outlaws swarm round to clap ${b_him} on the back.          
          *if zvad <= 0
            *label zvadwake
            *page_break
            Radmar lets slip a string of curses, and the others fall silent in shock.  The wounded Rimsman is leaning on Zvad's great maul. From the look in his eyes, if he weren't on the verge of collapse himself he'd be smashing it into rocks, or people.  "Zvad died for this?  For a few petty aristos, and not even the Keriatou boy among them?"
            
            ${b_name} blinks, looks over to the boulder.  "Ah, Angels, no!"  ${b_he} runs to the fallen ${whend}.
            *if b_name = "Elery"
              *if elezvad > 7
                "No, no, no, you…"  She stops, swaying in place for a moment; it's all too plain that Zvad is beyond anyone's help.  Then with a shriek of rage, she whirls and throws herself at you.  
                
                In your shock and exhaustion, you barely bring your hands up, and Elery's fist flies past them to connect between your eyes. She hits you twice more, snapping your head back, before the others drag her backward.  "[i]Damn you, ${lname}![/i]" you hear through the thunder of pain and blurred vision. "Damn you and your swiving ambush and all your swiving plans!"
                *goto reinforce
              *if elezvad < 8
                When she properly sees Zvad's injuries, she bends over and rocks on her heels, crying in great ragged gasps.
            "Oh, no."
            *if (elezvad < 8) and (b_name = "Elery")
              
              *comment endif
            The other hunters join ${b_him} and stare bleakly down at Zvad's body, many weeping openly.  It isn't just the Whendward bandits who had followed him before your arrival—many of the helots who 
            *if rescuer < 1
              accompanied you from Rim Square or
            joined the band in the spring had come to care for the former mercenary, thanks to his gruff but gentle encouragement during weapons practice or the long journeys between camps.
            
            You can't leave them sunk in this gloom.  At length you say quietly, "He wouldn't have seen this as a waste.  And he wouldn't want us to."
            
            Radmar looks up balefully at you. "A great victory, then, ${addressu}?"
            
            "Our fallen comrades are avenged—including those who fell today.  And before this, the nobles thought we were their game—that they could hunt us with no more consequence than a boar or stag." You turn from Radmar to address the whole group. "Now the world will know: we are hunters, and we will not be slain without cost.  Zvad would have thought it was worth dying to send that message."
            
            You see nods and straightened shoulders around the mourning circle. Even Radmar's anger seems to recede—and with it, the energy to stay upright.  ${b_name} and Alira catch him.  "Time to get the injured home," you declare.  "The rest of us will build the cairn here for 
            *if arrog > 0
              the fallen."
            *if arrog < 1
              our friends."
            *goto reinforce
          
          *if hector < 5
            While disappointed that Hector seems to have slipped your trap, you can't let it cast a pall on the day's victory.
          *if arrog > 0
            "The fallen
          *if arrog < 1
            "Our sisters and brothers
          are avenged!" you bellow.
          *if hector >= 4
            The joy in your voice hides the relief you can't help feeling at your cousin's survival.
          "They 
          *goto thoughtgame

        *elseif hambush > 9
          *set morale +2
          *set hec_cred 9
          *set cred_h +5
          *set cred_y +5
          *set cred_a -2
          They look weary but satisfied.  "We brought down a few more of them, ${addressu}," ${b_name} reports.  "Bloody Hector escaped, with 
          *if c_name != kalt
            four
          *if c_name = kalt
            two
          others—all wearing at least one arrow.  Even if they all survive, I doubt they'll trouble us again without an army at their backs."
          
          "Well fought.  And how many did we lose?" you ask, scanning the party.
          *if hector > 5
            You hope you've managed to hide the relief you can't help feeling at your cousin's survival.

          *if c_name != kalt
            "Two," ${b_name} says ruefully. "To the Keriatou boy—he took cover and fought back while the others fled.  Some of us were too confident.  Next time, if there is a next time, we'll lose none."
            *set followers -2
            *set nonkids -2
            *set dead +2
          *if c_name = kalt
            "Not a one," ${b_name} grins.  "They were in such disarray when they hit us, it was all they could do to keep their heads down and keep running."
            *goto restclapback
          *if zvad <= 0
            *goto zvadwake

          "Well fallen—and well fought," you repeat to the band.  "Before today, 
          *if helot
            the aristos
          *if aristo
            my cousins
          *if sa_foll < 1
            *set sa_foll 903
          *goto thoughtgame
        *elseif hambush > 4
          *set morale -11
          *set followers -7
          *set nonkids -7
          *set dead +7
          *set hec_cred 11
          *label miserables
          Their misery is clear even from a distance.
          
          You stride out to meet them on the mule-track, searching for the missing faces.  "What happened?"
          
          "We loosed arrows too soon," ${b_name} says, flat-voiced. "One more veneur went down—but the others rallied round Hector and found cover.  They killed
          *if hambush > 4
            seven
          *if hambush < 5
            eleven
          of us and fought free."
          
          "How do a few injured, ambushed nobles kill that many?" you demand in disbelief.
          
          "By being better than us."  Ciels 
          *if b_name = "Elery"
            speaks up without meeting
          *if b_name != "Elery"
            doesn't meet
          your gaze.  
          *if c_name = kalt
            
            "To Taratur with that!" ${kalt} barks, striding up to Ciels and slapping ${him} across the face.  The young tracker staggers backward, taken completely off guard. "You think they're saying that now? 'Alack, the dirty helots killed seven of us.  They must be better than we are.' Damned if they are.  They're telling each other that we had luck and low cunning on our side, and that next time they'll scythe us down like the weeds we are."
            
            "We had the advantage over them.  We lost it." ${b_name} shakes ${b_his} head, but at least now ${b_he} looks angry instead of merely wretched.  "They shouldn't have been able to come back."
            
            "And next time we won't lose the advantage," ${kalt} insists.  $!{zhe} strides over to the body of 
            *if int = 2
              Ganelon Tarakatou,  
            *if int < 2
              the Tarakatou,
            pulls the dead youth's partly-severed head up by the hair so everyone can see his expression of shock and horror.  All the surviving muleteers cheer loudly.  "I say we are better than…this.  We came up with something they didn't expect, and it killed them.  You think I'm the only one of us who can do that?  Next time it'll be you—or you, or you."
            
            As ${kalt} continues to talk, you see hope returning to your outlaws.  You also see the admiration and gratitude in their eyes—the way they look at a leader.
            *set morale +4
            *set kal_lead +1
            *fake_choice
              #I'm worried.  ${kalt}'s influence on the band could clash with my leadership.
              #I'm appalled.  This ${zgirl} is becoming a monster.
              #I'm relieved.  $!{zhe} brought them back from despair after a major setback.  $!{zhe}'s earned their respect.
              #I'm delighted.  ${kalt} is just the sort of leader this rebellion needs, and it's good to see ${zhim} growing into it.
            *goto reinforce
          *if sa_foll < 1
            *set sa_foll 901
          $!{his} despair hangs over the whole 
          *if zvad > 0
            band.
          *if zvad <= 0
            band, and it only deepens when they learn of Zvad's death.

          Over the next few weeks, you switch to a defensive posture, doing whatever you can to conceal your mule trains from Hector and his gang.  No one has the stomach for a more aggressive approach to the Keriatou anymore.
          *goto reinforce
        *else
          *set morale -19
          *set followers -11
          *set nonkids -11
          *set dead +11
          *set hec_cred 21
          *goto miserables
                  
      #Back at camp, impatiently awaiting news.
        *set hambush -2
        You chose to stay behind today because…
        *fake_choice
          #If this does go badly, I don't want the band to lose its leader.
          #I don't feel my skills are best suited to ambush.
          *if (hector >= 4) 
            #I can't bring myself to watch that beautiful bastard Hector die.
              Let alone strike the blow yourself.
          *if (hector = 2) 
            #I fear my hatred for Hector Keriatou would lead me to do something rash.
          *if aristo and (hector < 5) 
            #I don't think I can bring myself to kill my cousin.
              And you don't want the band to see your weakness.
        Instead, you gave the lead to:
        *choice
          *if (kalstalk) #${kalt}.
            *set hambush +2
            *set d_name kalt
            *set d_his zhis
            *set d_him zhim
            *set d_he zhe
            *goto hecresults
          *if (simzstalk) #${simon}.
            *set hambush +1
            *set d_name simon
            *set d_his zhis
            *set d_him zhim
            *set d_he zhe
            *goto hecresults
          #Zvad
            *goto hecresults
          *if (bred_here) #Breden.
            *set d_name "Breden"
            *set d_his xhis
            *set d_him xhim
            *set d_he xhe
            *goto hecresults
          *if (elery > 0) #Elery.
            *set d_name "Elery"
            *set d_his "her"
            *set d_him "her"
            *set d_he "she"
            *goto hecresults
          #Radmar.
            *set d_name "Radmar"
            *set d_his "his"
            *set d_him "him"
            *set d_he "he"
            *goto hecresults
    *label hecresults
    It's evening when you get the news that ${d_name} has returned.  You hurry down to the meadow where ${d_he} and the ambush party are being welcomed back.
    *if hambush > 9
      *set morale +8
      *set followers -2
      *set nonkids -2
      *set dead +2
      The sounds of cheers and jubilant banter set your mind half at ease even before you join the crowd.
      
      Ciels, who led one of the archer bands,
      *if (ciels = 2) and (bred_here)
        breaks off a kiss with Breden and
      runs up to you with a lopsided grin.  "Three of the veneurs crawled off wounded, ${addressu}," ${he} reports.  "All the rest of them fell—and unless one of our lightly wounded dies, we've only lost two.  I doubt they'll trouble us again."
      
      "And Hector?" you demand,
      *if hector >= 4
        hoping the thickness in your throat isn't audible to the others.
      *if hector < 5
        feverish with hope.

      ${d_name} appears at Ciels's shoulder.  "Escaped, wearing an arrow," ${d_he}
      *if (d_name = simon) or (d_name = "Radmar")
        says flatly.  Anger at the Keriatou still boils in ${d_his} eyes.
      *if (d_name = kalt)
        shrugs.
      *if (d_name = "Zvad")
        sighs. "Reckon it should discourage him, though."        
        *goto slipgrip
      *if (d_name = "Elery")
        says, briefly scowling.
      *if (d_name = "Breden")
        admits ruefully.
      "But if he lives…let him crawl back and try to find more volunteers to die at our hands!"  The other outlaws erupt in raucous cheers, swarming round to clap ${d_him} on the back.
      *if (d_name = simon)
        ${simon} looks incredulous, then grins in relief at the enthusiastic show of acceptance.
        *set simz_lead +1
      *if (d_name = kalt)
        ${kalt} grins fiercely and grips the hands of each former helot in turn.
        *set kal_lead +1
      *if (d_name = "Elery")
        Elery laughs and pulls the other ambush leaders into the circle of congratulations.
        *set el_lead +1
      *label slipgrip

      *if hector < 5
        While disappointed that Hector seems to have slipped your trap, you can't let it cast a pall on the day's victory.
      *if arrog > 0
        "The fallen
      *if arrog < 1
        "Our sisters and brothers
      are avenged!" you bellow.
      *if hector >= 4
        The joy in your voice hides the relief you can't help feeling at your cousin's survival.
      "They 
      *set hec_cred 9
      *set cred_h +10
      *set cred_y +10
      *set cred_a -5
      *set sa_foll 903
      *goto thoughtgame
    *elseif hambush > 6
      *set morale +2
      *set followers -7
      *set nonkids -7
      *set dead +7
      They look weary but satisfied.  "We caught them off guard, and brought down a few, ${addressu}," ${d_name} reports.  "Bloody Hector escaped, with six others—most of them wearing an arrow.  Even if they all survive, I doubt they'll trouble us again without an army at their backs."
      
      "Well fought.  And how many did we lose?" you ask, scanning the party.
      *if hector > 5
        You hope you've managed to hide the relief you can't help feeling at your cousin's survival.

      "Seven,"
      *if d_name = simon
        ${simon} declares somberly. "Good warriors all, and true."
      *if (d_name = kalt) or (d_name = "Radmar")
        ${d_name} says curtly. "But believe me, they'll feel their loss more than we feel ours."
      *if d_name = "Elery"
        Elery says, her eyes flashing defensively. "And if it takes two of us for every one of them…I call that a good fight."
      *if (d_name = "Breden") or (d_name = "Zvad")
        ${d_name} says flatly. "More than we will next time, ${addressu}."

      "Well fallen—and well fought," you repeat to the band.  "Before today, 
      *if helot
        the nobles 
      *if aristo
        my cousins
      *set hec_cred 11
      *set cred_h +5
      *set cred_y +5
      *set cred_a -2
      *set sa_foll 902
      *goto thoughtgame
    *elseif hambush > 4
      *set morale -20
      *set followers -12
      *set nonkids -12
      *set dead +12
      *set hec_cred 21
      The groans and wails are audible long before you actually arrive in the crowd of the dead and wounded.
      
      You find ${d_name} with the Ablers, bleeding through bandages on ${d_his} head and limbs while trying to ensure that the more severely injured receive care.  "What happened?" you demand.
      
      "Both groups of archers loosed arrows too soon,"
      *if (d_name = simon) or (d_name = "Breden")
        ${d_name} says, low-voiced.
      *if (d_name = kalt) or (d_name = "Radmar")
        ${d_name} growls.
      *if d_name = "Elery"
        Elery says grimly.
      *if (d_name = "Zvad")
        ${d_name} says, flat-voiced.
      "One veneur went down—but the others rallied round Hector and found cover.  They killed
      *if hambush > 4
        twelve
      *if hambush < 5
        twenty
      of us and fought free."
                                
      "How do a gang of injured, ambushed nobles kill that many?" you demand in disbelief.
      *label betterthanus4
      
      "By being better than us."  Ciels speaks up without meeting your gaze.  $!{his} despair hangs over the whole band.
      
      Over the next few weeks, you switch to a defensive posture, doing whatever you can to conceal your mule trains from Hector and his gang.  No one has the stomach for a more aggressive approach to the Keriatou anymore.
      *if sa_foll < 1
        *set sa_foll 901
      *goto reinforce
    *elseif hambush > 2
      *set morale -30
      *set followers -20
      *set nonkids -20
      *set dead +20
      *goto miseryambush
    *else
      *set morale -41
      *set followers -31
      *set nonkids -31
      *set dead +31
      *set hec_cred 21
      It takes several minutes before you realize that the handful limping through the trees will not be joined by others.
                                
      "What happened?" you demand, almost inaudibly, when they reach you.
      *label wewererouted2
      
      "They routed us, ${addressu},"
      *if (d_name = simon) or (d_name = "Breden")
        ${d_name} says wretchedly. "We…they charged us, and we came to pieces."
        *if (d_name = simon)
          *set simz_lead -3
        *if (d_name = "Breden")
          *set bred_lead -3
      *if (d_name = kalt) or (d_name = "Radmar")
        ${d_name} snarls, ${d_his} face drawn with rage. "The bastards had recovered by the time they reached us.  Hit us hard."
        *if (d_name = kalt)
          *set kal_lead -3
      *if d_name = "Elery"
        Elery says dully. Some hope has died in her that will not easily be rekindled. "They charged us, and we came to pieces."
        *set el_lead -3
      *if (d_name = "Zvad")
        ${d_name} says, sounding unspeakably weary. "We couldn't stand up to charging horse."

      You scan the survivors of the catastrophe.  Thirty…thirty-one gone?  "How?  How did they kill so many?"
      *goto betterthanus4

    *label wakeup
    *if hambush < 7
      You never feel the hooves that trample you, or the multiple spears that pierce your fallen body.
      *goto_scene death
    *page_break
    You slowly become aware of your aching, prone body again, and force your eyelids open.  The haze above you resolves itself into
    *if simzstalk
      ${simon}'s
    *if not(simzstalk)
      Ciels's 
    *if (theuknown < 5) or (theurgy = 3)
      stunned face.
      *if (theurgy = 3)
        "So…that's the ${wisardry} you spoke of back in the winter, ${addressu}?"
        
        "It is," you croak. "As you can see…it has limits.  Which I'm still learning."
        
        Ciels crouches next to you.  "Angels.  Even so.  You didn't tell us you could throw flaming trees.  I can think of a few times before now that might have been useful."
        *goto whathapp
      "Xthonos, ${addressu}.  What by all Angels was that?"
      
      You close your eyes, wishing your head wasn't splitting in two—and wishing that the first your band saw of your power wasn't this humiliating collapse. "${wisardry}," you croak. 
      *gosub theuexplain
      
      *if wisard = "Goete"
        *if simzstalk
          ${simon} stares at you, looking stricken. "I'd…well, if you say there's nothing evil to it, ${addressu}…"
        *if not(simzstalk)
          Ciels looks somewhat ill. "They'll tremble, all right.  They won't be the only ones."
      *if wisard != "Goete"
        *if simzstalk
          ${simon}'s eyes shine, and ${zhis} confidence seems to still others' fears. "This is glorious, ${addressu}.  With this power on our side, they cannot hope to prevail!"
        *if not(simzstalk)
          Ciels whistles appreciatively.  "Damn me ${addressu}. So we have a mage leading us."
      *goto whathapp
    relieved face.  "Thank Angels.
    *if simzstalk
      Ah, ${addressu}, if you'd killed yourself for so small a thing as this…"  $!{zhe} breaks off, wiping a tear from one eye, and calls, "Zvad!
    $!{he}'s awake!"
    *label whathapp
    
    "What happened?" you rasp, looking around.  You've been borne away into a dusky glade.  
    *if hambush > 9
      All around you are grinning bandits brandishing trophies—noble swords, bows, armor.  Three horses are whickering nervously amongst the mules.
    
      "The ambush sprang just as you fell, ${addressu}," Zvad rumbles, stepping into view.  
      *if hambush > 11
        *set morale +10
        His craggy face splits in a jubilant smile.  "And every single veneur is slain.  With no losses on our part.  None of them will trouble us again." 
        *goto andhector
      *else
        *set morale +8
        *set followers -2
        *set nonkids -2
        *set dead +2
        "Three of the veneurs crawled off wounded.  All the rest are slain—and we've only lost two.  I doubt they'll trouble us again."
        *goto andhector
    *else
      *set morale +2
      *set followers -7
      *set nonkids -7
      *set dead +7
      The outlaws who remain look weary but satisfied.
        
      "Lucky the ambush sprang as you fell, ${addressu}," Zvad rumbles, stepping into view.  "A hard fight, though.  Bloody Hector escaped, with six others—most of them wearing an arrow.  Even if they all survive, I doubt they'll trouble us again without an army at their backs."
      *goto howmanylost
    *label labreconsider
    "So you didn't settle on a better plan?" Grey Labedan inquires when you bring him back to the Leaders' Tent.
      
    "We decided the risk was worth it—as long as you'll help us bring it off."
    *goto sheepplan

    *label tothebrecks
    You all know the main source of the Keriatou's wealth: the vast flocks of sheep which are about to return from their winter pasture in the Southriding.  Most of the droveways run through the Great Brecks, a dry grassland which (from all you've ever heard) is inhabited only by shepherds and desperately poor, semi-nomadic peasants.
    
    One of the Whendward bandits, Grey Labedan, grew up as a herdboy in the middle Brecks before being accused of sheeptheft and fleeing north.  When you and ${deputy} privately sound him out on the possibility of attacking the Keriatou flocks there, he gives a sepulchral chuckle.  "Not an easy thing to do, my ${kuria}."
    
    "How far from easy?"
    
    The old outlaw scratches a contemplative finger along his sun-cracked nose.  "Well.  When the sheep come up out of the Brecks, a good-size Alastor force will be waiting to welcome them to the inhabited Rim.  These days, who knows who else might be on guard with them—some Phalangites, a Theurge?  So you'd want to lead your raiding party well south of where they'd go…say, a good seven days' walk from the edge of the Whendward forests."  
    
    "Through exposed grassland all the way," ${deputy} notes gloomily.
    
    "Makes it easier to see the wolves coming," Labedan grins.  "Then you'd need to find the Keriatou flocks, some five thousand head—at the time of year when four thousand thousands are on the move in the Brecks—and scatter them beyond recovery.  Without being stopped by the big dogs and forty-odd roughnecks, old and young, who will have care of the sheep.  Then get back to the forests before some Theurges fly out to set you all on fire."
    
    You stare at him in consternation for a moment.
    *choice
      #"So it's a poor plan, then."
        *set labtick true
        "You might find a less risky one," Grey Labedan shrugs.
        *goto retaliation
      #I return his grin.  "Would you help us do it?"
        *set retaltick 8
        "Damn me!" Grey Labedan convulses with mostly soundless laughter.  "$!{girl}, that's the question I've been waiting to hear from a leader of the Whendward band for a good forty years."
        *goto sheepplan
    *label sheepplan
    *set violence +1
    
    By this point, the cautious planning of a raid is second nature—who you trust enough to involve, who you don't, who you don't yet trust but need to involve anyway for practical purposes.  In addition to your deputy ${deputy}, you bring in your best trackers, Ciels and Alira, to talk with Labedan.
    *if elery > 0
      You ask Elery Skinner to join you as well; her eye for terrain will be vital in carrying off the raid.
    *choice
      *if (bred_here) and (deputy != "Breden") 
        #I also include Breden.
          *set bsheep true
          *goto theplanchoice
      *if (kal_here) #I also include ${kalt}.
        *goto inckal
      *if ((simz_here) and (s_rel < 9)) #I also include ${simon}.
        *goto incsimz
      *if ((deputy != "Breden") and (kal_here and bred_here)) #I include both Breden and ${kalt}.
        *set bsheep true
        *label inckal
        *set ksheep true
        "Sheep?" ${kalt} says incredulously when you ask ${zhim} to join the planning. 
        *if helot
          "The Keriatou
        *if aristo
          "Your cousin
        nails one of your followers to a tree, and in exchange you want to kill his sheep?"
        
        "The family will miss the sheep more than Hector," you retort. "They'll still have
        *if aristo
          Calea
        *if helot
          the girl
        to pass on the name. But their flocks are the heart of their wealth. They'll have to dig deep to replace them, and to guard them better next year."
        
        ${kalt} flings ${zhis} hands behind ${zhim} in disgust.  "$!{kuria}, don't talk to me about the drachems you're going to cost them. Blood for blood.  That's the language they'll understand."
        
        "That's not how we'll win," you say flatly. 
        *label nowareyoug
        "Now, are you going to join us or not?"
        
        *goto theplanchoice
      *if ((deputy != "Breden") and ((simz_here and bred_here) and (s_rel < 9))) #I include both Breden and ${simon}.
        *set bsheep true
        *label incsimz
        ${simon} initially tries to talk you out of the idea.  "There's no way to do this without killing most or all of the Keriatou shepherds, ${addressu}.  And they're no soldiers, just hirelings doing their job.  It's a dishonor for us to target innocent folk—and the younger, the more dishonor."
        
        "${simon}…they're well armed for a fight.  All of them, even the youths.  To protect the wealth of the aristarchs."  You should have expected that ${zhe} would urge you to find a peaceful resolution, avoid actions that the Shayardene nobility will deem Xaotic, and the rest of ${zhis} amiable mush. "If we can't target armed hirelings of the Keriatou, how by ${oath} do you expect this rebellion to survive?  Their flocks are the heart of 
        *if helot
          House Keriatou's 
        *if aristo
          my cousins'
        wealth.  They'll have to dig deep to replace them, and to guard them better next year.  Nothing else we could do would have the same impact at a cost of so few lives—ours as well as theirs."
        
        ${simon}
        *set ssheep true
        *if eclect
          still looks dubious, but finally bows to you.  "I will submit my own judgment to that of the Eclect in this matter."
          
          *goto theplanchoice
        *else
          chews ${zhis} lips discontentedly for a minute before allowing, "It's fair game, ${addressu}.  You're right about that, I suppose."
          
          "And it's the game we're after," you state.
          *goto nowareyoug
      #I don't include anyone else.
        *goto theplanchoice
    *label theplanchoice
    *if deputy = "Breden"
      *set bsheep true
    After much discussion, you decide to:
    *choice
      *selectable_if (nonkids > 49) #Bring a large raiding party—which will make it easy to crush the shepherds, but hard to travel unnoticed.
        *set plan 1
        Even with the largest force you dare to bring across exposed grass, you'll still need to hit the Keriatou drovers hard from ambush at a distance to break their will to fight—otherwise, enough of them might well survive to put you in real danger.  Having seen Grey Labedan bring down a stag with a stone from his sling, you have a healthy respect for the shepherd's customary weapon.
        
        *goto brecktrav
      #Bring a small ambush force.
        *set plan 2
        *goto brecktrav
      #Try to incite Brecklander peasants to attack the shepherds and take the sheep themselves.
        *set plan 3
        *goto brecktrav
    *label brecktrav
    Three days later, your
    *if plan > 1
      small raiding party
    *if plan = 1
      force of fifty seasoned outlaws
    arrives at the last hill of the Whendward wilds.  Ahead of you, the trees break up into stunted copses, eventually giving way to an expanse of heath and grass that stretches off to the horizon on all sides.  Out there, in the blazing sun, you'll be visible from leagues away. Leaving the precious cover of the trees makes your throat go dry.
    
    Grey Labedan gestures off to the east. Squinting, you can just make out a pale yellow line amid the green.  "That's the droveway.  Can't build or farm within a mile to either side—Alastors would kill you for that.  Not that many yeomen would want to, with a soil this sour and sandy."  
    
    "I don't see anyone for miles, not shepherd nor Alastor,"
    *if bsheep
      Breden
    *if not(bsheep)
      Ciels
    frowns.  "Have we come too late?"

    The old bandit chews his lips.  "Shouldn't be, unless they've dropped all the old grazing arrangements.  The pasture hills around Rim Square are the end of this road, and it takes a good long time to travel all the way up here from the Southriding Brecks.  I make it a week and a half still until the first flocks start arriving; longer for the big ones."
    
    Alira nods.  "Scouts report no sign of the Hegemony anywhere about yet, ${addressu}.  If they're worried about us raiding the sheep, they aren't expecting us to head out into the grassland to do it."
    
    "Or they're just expecting to catch us on the way back," 
    *if ksheep
      ${kalt} notes, sounding half-hopeful.
      *goto wellchat
    *elseif ssheep
      ${simon} suggests.
      *goto wellchat
    *elseif plan = 1
      Radmar growls.
      *goto wellchat
    *else
      you note.
      *goto wellchat
    *label wellchat
    *page_break
    You travel for days without seeing another soul—only the great flocks of cranes, pigeons, and thrushes that traverse the grasslands by spring, and the hawks and vultures that spiral far overhead.
    *if plan = 1
      Sometimes you walk with the small vanguard, traveling an hour ahead to scout out the route and guide your main force away from any witnesses.  
    Young Earnn occasionally points out wolf spoor to you, but whatever packs are abroad on the Brecks leave you well alone.
    
    Between Grey Labedan's memories and Alira's eye for the land, you find enough remote wells and rivulets to keep you alive in the drylands.  For your meals you eat sparingly of sun-dried venison or boar along with breadrusk; even the smallest fire is too great a risk. Thankfully, the weather remains cloudless and hot, and after sunset those of you not on watch can see each other clearly by moon and starlight.  You chew on salty Breckland fennel and share stories, songs, and jokes late into the night.
    
    *if ksheep
      And on a nightly basis, you again get to hear ${kalt} making the case that this raid isn't enough—that however many sheep we boldly slaughter, we're missing the chance to strike at the murdering veneurs themselves.  Calmly or hotly, with laughter or bared teeth, the young firebrand circles back to the same demand: Hector Keriatou's death.  Several of your raiders nod at first, but by the third night even they have begun to weary of the theme.
      
      "Here's the problem, ${zgirl}…you've only been eating breadrusks this whole journey," Grey Labedan scolds ${zhim} amiably on the fifth night.  "That won't bring your choler down.  Chew on some pursley—or here, eat the venison, it'll cool you off."
      
      ${kalt} waves the strip of meat away impatiently.  "I only eat aristos."
      *choice
        #I raise an eyebrow and say, "So you're sulking out of hunger."
          "That I bloody well am, ${addressu}." ${kalt} gives an oddly mournful-sounding laugh.  "That I am."
          
          *if bsheep
            "Phalangite commanders are noble, ${kalt}.  You'll get to chew on them soon enough, I reckon."  Breden takes the venison strip from Labedan and pops it into ${xhis} mouth. "We'll all have our fill of fighting then."
            *if (ciels = 3) or ((ciels = 13) or (ciels = 23))
              Ciels wraps an arm around ${xhim}, a gesture at once protective and possessive.
            
            ${kalt} just glares at Breden, clearly irked by ${xhis} indulgent tone. "If whatever's coming this summer gives you your fill…perhaps you should
            *if deputy = "Breden"
              hand your lead to someone with more stomach for it, and
            hide yourself away until it's over.  Save yourself for the bigger battles yet to come."  
            *if plan = 1
              Radmar gives a grunt of approval.

            *if deputy = "Breden"
              Your deputy
            *if deputy != "Breden"
              Breden 
            chuckles without mirth. "If I thought there were a place we could hide away, Swineherd, I'd be there now.  Standing up to Phalangites is a fool's battle.  We can't beat the Archon's army toe-to-toe, not with our numbers and their Theurges."
            
            "Oh, you're wrong, so wrong!" ${kalt} leans forward, almost incandescent with certainty. "Those shiny-armored geese are so sure they can't be beaten that they'll make mistakes.  They'll underestimate us, as They always do.  We have here everything we need to beat them—in our woods, on ground of our choosing." $!{zhe} turns back to you, almost dancing with pent-up frustration. "And forgive me, ${addressu}…but right now, we're passing up on a chance to prove it.  To prove to ourselves that we can take on armed aristos and win."
            
            Whatever the troubled-looking Breden might have responded is lost in groans and laughs 
          *if not(bsheep)
            Good-natured groans rise
          from around the circle.  "Ah, give over, ${kalt}," 
          *if elery > 0
            Elery 
          *if elery = 0
            Ciels
          says.  "We heard it yesterday."
          *if not(bsheep)
            
            "Did you, truly?" The young
            *if helot
              former
            helot throws up ${zhis} hands. "And after all these nights, still no one says a word for or against it?"
            
            Grey Labedan leans back, chewing on the venison he'd just offered ${kalt}.  "I don't fancy our chances, toe to toe with a gang of noble hunters."
            
            "That's exactly why we need to take them, now!  To prove we can!"  ${kalt} turns to you, almost dancing with pent-up frustration. "Do you hear this, ${addressu}?  They don't believe we can beat a handful of aristo pococks on ground of our own choosing, here in the woods.  How do you expect them to believe they can defeat Phalangites?"
            
            "You think we can?" Ciels says incredulously, as others burst out laughing.
            
            "Of course we can!  And we'll bloody well need to, won't we?" ${kalt} is almost incandescent with certainty. "They'll underestimate us, as They always do.  They'll come in expecting an easy fight, thinking they'll haul half of us back in shackles to be Harrowed.  And as long as we stand up to them hard, here where the terrain favors us…Angels, yes, we can win!  But only if we believe it ourselves."
            
          You lean in, wait for the chatter to die down.  "See—if all you say is right, ${kalt}, then it's as well we're not fighting Hector now. It might give them a hint that they're underestimating us. Let's just surprise them in the summer."
            
          ${kalt} 
          *if k_rel > 4
            just shakes ${zhis} head
            *if k_rel > 6
              contemptuously
            and scowls. "If I thought you really believed it, 
            *if bsheep
              ${addressu}…you or your…"  $!{zhe} jerks ${zhis} head toward Breden, then 
            *if not(bsheep)
              ${addressu}…" $!{zhe}
            lapses into grim silence.
          *if k_rel < 5
            stares at you for a moment, then grins reluctantly. "Ah, damn it all.  There's the first good reason you've given for being here, ${addressu}. So be it, then—let no sheep survive to bear word of our skills!"
            
            Later, as you leave the circle, you see that ${kalt} has wandered off alone. $!{zhe}'s gazing out across the starlit sweep of the Brecks.
            *choice
              #I walk over to ${zhim}.  We need to discuss ${zhis} provocations.
                *label joinkalta
                You hail ${zhim} in a low voice when you're close enough, and ${kalt} turns ${zhis} head with a grimace. "More to say on my aristo-eating habits?" $!{zhe} sounds mildly embarrassed.
                *if aristo
                  "Fear not, ${kuria}, you're off limits."
                
                *if aristo
                  "Now that my mind's set at ease…"
                You step to ${zhis} side and fold your arms.
                *goto whysav
              *selectable_if (kalpref) #$!{oath}, ${zhe}'s attractive. I join ${zhim}, trying not to make my interest [i]too[/i] embarrassingly obvious.
                *set k_rel 2
                *goto joinkalta
              #Enough argument for tonight.  I head to my bedroll.
                *goto firstflock
          *goto firstflock
        #I shake my head, exasperated by ${kalt}'s unrelenting ferocity.  "Bleeding Angels, ${kalt}.  Why always so savage?"
          *set k_rel 8
          "Why so meek, ${addressu}?" ${kalt} snaps back at once.
          
          "Anyone not a cannibal is meek, now?" you say incredulously. "${kalt},
          *if aristo
            you sound like a damned play-actor, determined to make his Goete the most blood-curdling fiend that ever stalked a stage.
          *if helot
            who jokes about eating the enemy?
          It's as if every day you wake up wondering what new thing you'll say to put fear into the bowels of…all those nobles who will never hear you.  It's ridiculous, and I for one am sick to death of it."
          
          ${kalt} stares flatly at you, then over to the other outlaws who are trying to keep their gales of laughter quiet. 
          *if aristo
            *set cred_h -3
            "We've none of us seen play-actors, ${milady}," he says, voice coolly venomous. "And maybe all those years in your fine House, you never saw real hatred. Just the play-acted sort."
          *if helot
            *set kal_lead -1
            "You mistake me, Captain ${fname}. I know I'm not talking to any aristos.  And if what I say is too strong, it's only because nothing else so far has sufficed to put a bit of backbone into this pack of buffoons and cowards playing at rebellion."
            
            The laughing abruptly stops. As the shock fades, ${kalt} storms off to ${zhis} tent, followed by glares and unamused mutters from the other outlaws.
            *if bsheep
              Breden just looks at you and shakes ${xhis} head, thin-lipped.
          *goto firstflock
        #I hold my tongue, but ask ${zhim} later, privately.
          When almost everyone else has retired, you walk over to ${kalt}'s side and repeat quietly, "You only eat aristos?"
          
          $!{zhis} lips twist with mild chagrin. "It was…it was a bit strong. I know."
          
          You shake your head.  
          *label whysav
          "Why the savagery?  Yes, I know you hate them, and you've reason.  Why the constant…well, boasting about it?  How much you hate them, all the things you're going to do…it's as if you're
          *if aristo
            a play-actor holding up a toothy mask
          *if helot
            a jongler chanting the Xaos-lover's verse of a ballad over and over again
          for the band."
          
          *if k_rel > 5
            For a moment, ${kalt} looks as if ${zhe}'s going to answer—then an old anger crosses ${zhis} face again. "Don't reckon you'd understand, ${addressu}."  Nothing else you say manages to shift ${zhim}, and eventually you retire to your tent.
            *goto firstflock
          *else
            *if aristo
              ${kalt} gives an exasperated but amused snort.  "I don't know what that means, ${kuria}.  Jonglers sometimes stopped in our camp, but not play-actors."
              
              "All right then—a jongler chanting the Xaos-lover's verse of a ballad over and over again."
              
            ${kalt}'s eyes flare at the indignity; then ${zhe} grins despite ${zhim}self and shakes ${zhis} head.  "Damn me, ${kuria}.  A jongler with just one verse.  That's good."  For several moments, ${zhe} looks out across the plains without speaking.  "So what ballad are you chanting from, ${milady} ${fname}?"
            
            "Five or six different ones.  At least, that's my aim."
            
            "I've tried the others."  ${kalt} wrinkles ${zhis} flattened nose. "Or seen them tried."
            *choice
              #"Tell me about it."  I lean back and wait for ${zhim} to speak.
                *set lifestory true
                *goto kaltstory
              #I don't need to hear ${zhis} life's story.  "You think anything better will come of this one?"
                ${kalt} leans in, eyes flashing.  "They need to fear us, ${kuria}.  That's the only thing that will move Them, the only thing that will make a change: if they're terrified that we're going to tear down their whole world around their bloody ears.
                *if ruth > 60
                  I reckon you think so too.
                *if ruth < 40
                  I know you disagree, but it's true.
                *if (ruth > 39) and (ruth < 61)
                  I can't tell whether you agree with me or not…but it's true.
                And right now, you've got a band full of outlaws who are still scared little helots in their minds.  If I'm a Xthon'damned jongler, it's for their sake, so they start chanting a different story about themselves."
                *choice
                  #$!{zhe}'s right, and ${zhe} can play the role better than anyone else here.  "Very well.  Keep it up."
                    *set ruth %+5
                    $!{zhe} blinks in surprise, then breaks into an elated grin.  "Truly?"
                    
                    "We need 
                    *if aristo
                      helots 
                    to stop thinking like helots, ${kalt}. Let them have you as a model."  You lean forward.  "Just remember, though: sometimes we need to strip away the armor before going for the throat.  You haven't believed it so far, but trust me, these sheep are the Keriatou's armor.  This is a necessary step."
                  
                    ${kalt} nods at once, still beaming.  "I'm sorry, ${kuria}. You'll hear no more complaint from me."
                    *if k_rel = 2
                      $!{zhe} pauses, then says, "$!{kuria},
                      *goto kalflirt
                    *goto firstflock
                  #"Wrong story, ${kalt}."  I shake my head adamantly.  "I don't want the band to believe that only monsters can win."
                    *set ruth %-5
                    "Maybe you need to have another think about what makes someone a monster, ${kuria}," ${kalt} says, voice low and angry.  "Maybe that's a name we should give to anyone who won't do [i]whatever's necessary[/i] to save more helot lives from the Karagonds and the aristos.  I say all the paths to that end are going to run with blood a foot deep—and if we don't start giving our followers a taste for blood now, they'll falter when they get there."
                    
                    "Our followers?" you say with a sharply raised eyebrow.
                    
                    ${kalt} fumes, defiant, for a moment…then sullenly backs down. "Just advising you, ${addressu}.  Meant 'your' followers, of course.  You're the one making all the decisions around here."
                    *if k_rel < 6
                      *set k_rel 6
                    *goto firstflock
                  #"Just now, hitting the nobles' interests is more important than stoking their fears. That's why we're here.  Are you going to keep trying to stir up the band about it?"
                    ${kalt} scowls. "Not if I want to stay, eh?"
                    
                    "Not if you want to stay on raids like this, certainly."  You say nothing to indicate how much insubordination it would take to get ${zhim} kicked out of the band altogether. "You've been heard on this, ${kalt}. You've had more voice than anyone else in the band.  But the decision's gone against you, and you need to accept that."
                    
                    ${kalt} fumes, defiant, for a moment…then sullenly backs down. "Just advising you, ${addressu}. I'll stop talking about it if that's what you wish."
                    *if k_rel < 5
                      *set k_rel 5
                    *goto firstflock
              #"You've got a new audience now.  Try some of the old ones again."
                "I'll see what I can do, ${addressu}." ${kalt} sounds and looks 
                *if k_rel = 2
                  dubious for a moment. Then ${zhis} eyes flicker up to yours, and ${zhis} expression dissolves into a sly smile.  "$!{kuria},
                  *goto kalflirt
                dubious.  "Anyway, I'll try to be a little less…strong."
                *goto firstflock
            *label kaltstory
            "As a rule, I don't…" ${kalt} stares at you, then exhales sharply through ${zhis} nose, half laugh, half sigh.  
            *if k_rel = 2
              "You don't need to feign interest in my life, ${kuria}.  
              *label kalflirt
              I've seen the way you look at me.  I know why you came over here, what you're looking for."  $!{zhe} puts a hand on yours. $!{zhis} skin is cooler than you'd expected; ${zhis} gaze is anything but.  "I'm looking for the same thing."
              *choice
                #I lean in to kiss ${zhim}.
                  *label kalhookup
                  *set k_rel 4
                  ${kalt}'s response is as fierce and hungry as you'd hoped. When your lips and ${zhis} part for a moment, ${zhe} clings to your face with both hands and murmurs, 
                  *if (bred_lover >= 4) and (bred_here)
                    "Last chance to call that a mistake and go back to…${xhim}."
                    *choice
                      #It was a mistake.  Angels, what am I doing?
                        "I'm sorry, ${kalt}," you mutter, pulling back with some reluctance.  Your heart hammers. "It…it was a mistake."
                        
                        ${kalt} stares at you with eyes so wild, for a moment you wonder if ${zhe}'s going to stab you.  Then ${zhe} rasps, "Then best to know that now, I reckon."  $!{zhe} disengages quickly and strides back to the camp.  By the time you follow, ${zhe}'s already in ${zhis} bedroll and feigning sleep.  You do the same for the rest of the night.
                        *set k_rel 7
                        *goto firstflock
                      #"I don't know what I want, ${kalt}."
                        *if aristo
                          ${kalt} breaks away from you as vehemently as ${zhe} had been pressing against you.  "Like Taratur.  You know exactly what you want, ${kuria}.  A string of helots who don't give a damn how many others you're groping out on the heath."  $!{zhis} head darts back toward you just long enough to hiss, "You're no different from the rest."
                          
                          And then, before you can make more than an inchoate noise of protest, ${zhe}'s running back toward the camp, too fast for you to catch ${zhim}.  When you return to the ring of bedrolls and try approaching ${zhim}, ${zhe} jabs a long knife in your direction with such venom that you abandon any further attempt to talk.
                          *set k_rel 9
                        *if helot
                          "Don't you, then." ${kalt} breaks away from you, a coldness settling into ${zhis} eyes. "Well, best wait until you get your head round it." $!{zhe} disengages quickly and strides back to the camp.  By the time you follow, ${zhe}'s already in ${zhis} bedroll and feigning sleep.  You do the same for the rest of the night.
                        *goto firstflock
                      #"It's no mistake.  I'll tell ${xhim} as soon as I see ${xhim}."
                        ${kalt} searches your face with intense eyes.  Then ${zhe} breathes, "Get your bedroll—now."
                        *gosub bedrollch
                        *if bsheep
                        
                          In the morning, you walk back from the dell where you and ${kalt} spent the night.  Finding Breden in the queue for breakfast rations, you pull ${xhim} aside and begin to say, "Breden…I've something…"
                        
                          $!{xhe} strikes your hand away so hard that for an instant you wonder if it's broken. "[i]${kalt}[/i], ${fname}? Truly?"  There are no tears on ${xhis} face, just incredulous fury. $!{xhe}'ll hear no more explanation from you, nor say anything more ${xhim}self.
                          *set bred_lover 3
                        *goto firstflock
                  *else
                    "Your bedroll—now."
                    *gosub bedrollch
                    *goto firstflock
                #I've lost my interest in seducing ${kalt}, and try to tell ${zhim} so.
                  *set k_rel 0
                  "I'm sorry, ${kalt}.  It's true, I've looked…" You try to think of a reason for the change that wouldn't completely alienate the young volunteer, and give up after a few seconds. "But I don't think it would be wise to do more."
                  
                  $!{zhe} slides quickly away with a forced laugh.  "Stay wise, then, ${kuria}.  You're right—best not to tangle things up too much."  $!{zhe} excuses ${zhim}self and stumbles off to bed; you soon retire to your own lonely bedroll.
                  *goto firstflock
                *if (lifestory)
                  #"It's not feigned, ${kalt}. Tell me what brought you here."
                    "Bleeding Angels." ${kalt} pulls ${zhis} hand away, staring at you uncertainly.  "It's no…it's hardly a story to warm the loins, ${kuria} ${fname}."
                  
                    "I don't know you, ${kalt}," you point out quietly. "I'd like to find out more."
                  
                    $!{zhe} finally nods, a resigned look coming over ${zhis} face.
                    *goto kaltlifestory
            *label kaltlifestory
            "Very well then, ${kuria}.  We'll see what you make of me."
            
            You sit in silence while ${zhe} plucks a fennel stem and chews meditatively on the seeds.  At length, ${zhe} glances over at you and says, "You know the first thing I remember my ma teaching me? 'Do as you'd be done by, ${kalt}.' It wasn't that some Diakon had said it to her, either.  Ma'd figured it out for herself when she was a girl, along with all kinds of other oughts-and-shoulds. And she loved to talk about them.  She loved that the pattern Xthonos put in the world was as clear to her as to any highborn or priest.
            
            "Our lord kurios…well, he thought it was funny to have a helot pigkeeper who'd tell him what was right and wrong."  A small, bitter smile settles on ${kalt}'s face. "He'd stop by to argue with her after Helsday services, sometimes.  They'd go back and forth, and she wouldn't hold back, she'd speak her mind about how she thought things were faring on the estate.  Always friendly-like, and with a smile, earnest as anything. 

            "And sometimes it'd change things.  One time he came swearing that he was going to flog and sell off a young couple who'd got themselves caught in a hayloft…but he'd waited until he spoke with Ma, and after they'd argued for a good hour, he stormed off to the Diakon and had the two married instead.  If I ever spoke up when he was about, he'd smack me across the head, tell me to mind my place.  But he didn't lay a finger on my ma.
            
            "His chamberlain, on the other hand…" ${kalt}'s lips twist, and ${zhe} looks down at the grass. "He reckoned anyone who'd speak so bold must be…well."
            *fake_choice
              *if aristo
                #"Say no more."  I don't want ${zhim} to shame ${zhim}self or ${zhis} mother by speaking of it further.
                  "Well, there won't be much of a tale if I shy away from this bit, ${kuria}." ${kalt} doesn't look up.  "It
              *if helot
                #"Doesn't take much boldness for them to use that excuse."  I don't want ${zhim} to think the shame is ${zhis} alone.
                  ${kalt} shrugs, still looking down.  "It
              #"Did you kill him?" I wouldn't put it past ${kalt}.
                $!{zhe} laughs, still looking away. "I was nine, ${kuria}—too young to even understand what was happening. It
              #I stay silent.  Best to say nothing.
                "It
            had been going on for about a month when the kurios found out about it.  I found out too, then, 'cause he came and had a shouting fight with my mother.  Called her unchaste and other names I hadn't heard before…while she yelled right back about his not protecting the folk in his care, and blinding himself to the liberties his retainers had been taking.  I was hiding in with the pigs, wondering if his guards would kill me when they came to kill Ma.  But instead kurios Anthanos walks back up to the grand house and dismisses the chamberlain as a scoundrel."
            
            "Truly?"  You'd also been braced to hear the story of ${zhis} mother's death.
            
            ${kalt} meets your quizzical stare, and you can see tears standing in ${zhis} eyes. "My ma was so happy. Thought it proved what she'd been saying all along.  Most people see the pattern. Most folk understand [i]Do as you'd be done by.[/i]  There aren't many folk who are too bad to be reasoned with…and if you run into one of the bad ones, get help from someone else who can be reasoned with."
            
            $!{zhis} voice trails off. Both of you look up at the stars for a minute without speaking.  "And then?"
            
            "The kurios kept coming back for those chats with my ma.  At different hours than he had before. Doing as he'd be done by." ${kalt}'s voice is savage for a moment. Then ${zhe} sighs, shakes ${zhis} head. "The lady kuria had just died, and my da'd been Harrowed when I was five, so no one living had reason to complain.  In truth, ${kuria}, while that lasted, I don't think my ma was all that troubled."
            
            *if aristo
              You shift uncomfortably;
              *if bred_lover > 10
                whatever your own judgment on the chastity code, 
              it's a strain to hear someone talk thus about their mother.
            *if helot
              It's not hard for you to imagine what's coming.
            "But it didn't last?"
            *page_break
            "Kuria Aline arrived. And my ma had another shouting fight with kurios Anthanos.  She thought it was ten-ways obvious that things had to end then.  He didn't think so—and in the end, he didn't give a damn what she thought." ${kalt}'s hands clench at ${zhis} sides. "Four more years, he'd make his visits.  No more friendly chats in the pig-yard; no one wanted the new kuria to see them together, and besides, they didn't have much to talk about any more. 
            
            "I had a brother and sister, both older, both big enough to make the kurios nervous at their looks.  Soon they got moved out to work-gangs on far bits of the estate.  We didn't hear that they'd been sold until a month after it had happened.  Also had an aunt, who tried to shame the kurios by talking loudly about what the Angels and Canon have to say on unchastity and abuse of widows.  He heard her out for about five minutes…then declared that if he ever heard some letterless yaud quote Canon at him again, he'd send the Ecclesiast round our camp to sniff out heresy.
            
            "My ma stopped smiling the way she'd used to. After a few months, she stopped crying, too." ${kalt}'s voice is completely steady despite the tears streaming down ${zhis} own cheeks.  "And she knew that if she didn't keep eating mullow, the lord kurios would sell her away from me in a heartbeat.  Of course, every year without
            *if aristo
              breeding makes the Theurges look closer at you for Harrowing.  Four years…and it was her time."
            *if helot
              breeding…"  $!{zhe} doesn't need to finish the thought; you both grew up knowing that the barren are more likely to get Harrowed. "Four years, and it was her time."
            *fake_choice
              *if aristo
                #"$!{oath}…I'm so sorry," I breathe, trying to imagine myself trapped in anything like the same morass of shame and fear.
                  "Sorry's no help to anyone," ${kalt} snaps—then stops, wipes ${zhis} cheeks.  "Forgive me, ${kuria} ${fname}.  You deserve a bit better than that."
                  
              *if aristo
                #Nothing I can say will do justice to this. I sit in appalled silence.
                  ${kalt} wipes ${zhis} cheeks but says nothing.
              *if helot
                #"Taken, never gone."  The well-worn helot words for acknowledging the memory of the Harrowed come to my lips.
                  "Gone before she was taken," ${kalt} says desolately, wiping ${zhis} cheeks.
                  
              *if helot
                #"Damn him," I growl fervently.
                  "Maybe one day," ${kalt} says, hoarse-voiced.  "Done my part now, I suppose."
                  
              #It's just the way of the world; I say nothing.  But I know it's always hard to lose a mother.
            After a time, you venture: "So his son…there was more revenge to that than you'd told us."
            
            "Aye, Markos." ${kalt} sucks in air between ${zhis} teeth and blows it out again. "The lord kurios' only child by the late lady kuria.  The first time he showed up in the pig-yard, I thought he was there to kill me, even though my mother'd been gone a good five years by then.  Took me a time or two to realize that no, I'd somehow caught his eye, and that he was trying to find some corner where he could know me better."
            
            "So you took the firedog to his skull."
            
            ${kalt} nods, but with nothing like the vehemence you were expecting. After a long pause, ${zhe} says, barely audible: "Not the first time." When you just sit in silence, ${zhe} eventually tumbles on. "I hated his father.  I didn't hate him—didn't know him.  That first time he caught up to me when I was digging roots in the woods…how could I say no?  He could have…ah, he could have done whatever he wanted.  Angels, did I even want to say no?  He didn't have the look of his father.  He seemed more honest. Straightforward, anyway."
            
            "The second time, you killed him?"
            
            ${kalt} closes ${zhis} eyes. "Took me a month and more, ${kuria}." 
            *page_break
            "We'd talk sometimes, too.  Young kurios Markos was a cheery fellow afterwards, liked to talk about his estate.  He loved the land, loved finding ways to get the most out of his kine and his grain.  Seemed to enjoy listening, too; seemed fond of me.  Had me wondering for a bit whether I could live with it.
            
            "Then there was a day…we'd just finished butchering a few pigs outside the Great House, for the lord's table.  Pigs had been screaming, as they do.  Some young guests of the family came out to complain about the noise, saw a few of us helots washing up, and thought they'd have a bit of sport.  Took a horsewhip off the stable wall, had us run round naked, then roll around with the pig carcases for a while in the blood and shit."
            
            *if aristo
              You have
              *if arrog < 1
                to admit, you've
              seen similar games.
            *if helot
              You shake your head grimly at the all-too-familiar tale.
            "Markos too?"
            
            "No.  He just watched.  Said nothing, did nothing." ${kalt}'s bared teeth are shining in the moonlight. "That day I knew.  No hope of any of Them ever treating me anything close to how I wanted treating—let alone how they'd like to be treated themselves.  We were just so many more swine to Them. Had I thought twice about butchering the pigs, however loud they'd scream?  Why would I expect anything more from an aristo?  The next time the young kurios got me alone, he started by telling me he 'regretted' how his guests had behaved.  I told him I didn't want his swiving regrets and I bashed his swiving skull in.
            
            "I've seen what happens when 
            *if helot
              They 
            *if aristo
              your noble cousins
            see us as friendly, or reasonable, or humble, ${kuria}.  I've seen how far appeals to the Angels or the pattern of Xthonos get us.  If we're ever going to be any freer, we need their fear.  They need to see us for a ruthless pack of killers—too strong to beat, too hard to crack, and absolutely sure to hit back."
            *set kaltale true
            *choice
              *if (ruth > 40) and helot
                #"I know," I agree bleakly. "I've realized the same thing."
                  *set ruth %+5
                  "Which is why I came to find you."
                  *goto heardofya
              *if (ruth > 40) and aristo
                #I nod bleakly. "I've realized the same thing about the Karagonds."
                  *set ruth %+5
                  "Which is why I came to find you."
                  *goto heardofya
              *if ruth > 40
                #"Anyone hearing you talk for five minutes would believe it, too," I say with approval.
                  *set ruth %+5
                  "Well, if you sing the same verse of the same ballad enough…"
                  *goto heardofya
              *if ruth < 60
                #"Even though that's not who you really are?" I say compassionately.
                  *set ruth %-5
                  $!{zhe} slams a fist into the ground. "Damn you, ${kuria}.  Listen to me talk for five minutes, and you think you know what I am?"
                  
                  "I hadn't noticed until Labedan spoke up."  But then you'd thought back over your weeks with the lean helot, and you were sure. "When did you stop eating meat?"
                  
                  ${kalt} falls silent, finally muttering, "Didn't have the same savor any more."
                  *goto heardofya
              *if ruth < 60
                #I shake my head. "We can't give up trying to win them over.  Meeting brutality with brutality will only make matters worse."
                  *set ruth %-5
                  *goto heardofya
              *if aristo
                #"Some of us aristos are capable of compassion or reason," I gently point out.
                  "Not enough so you'd notice.  Not enough to change how things work.  So it doesn't matter.  Except maybe in your case."
                  *goto heardofya
              #"And that's what you think we are?"
                *goto heardofya
              #"What makes you think causing fear is going to work where the other ways failed?"
                ${kalt} laughs despairingly. "If it doesn't work…well then, we're plowed anyway, ${kuria}. Might as well have a try."
                *goto heardofya
            *label heardofya
            $!{zhe} turns to face you, and there's a yearning in ${zhis} eyes as strong as any you've ever seen or felt.  "I'd heard about you, ${fname} ${orig_lname}.
            *if (ruth > 40) and (ruth < 60)
              I didn't know whether you understood what it would take to beat them.  But just from hearing the stories…I thought if anyone did, if anyone could be made to, it would be you.  
            *if ruth > 59
              You were making yourself into [i]exactly[/i] what I wanted to be.  You would understand the cost that had to be borne, for them and for us.
            *if ruth < 41
              A rebel who was trying to show compassion to the enemy.  Just as determined as my ma to treat people as if they would listen, as if they'd change their ways through anything short of a blade to the throat.
            I knew I had to offer myself to you.  To
            *if ruth < 41
              save you from yourself, if I could—but no matter what, to
            fight at your side."
            *choice
              *if kalpref
                #I fold my arms around ${zhim} and kiss ${zhim}.
                  *goto kalhookup
              *if (k_rel = 2)
                #No, I don't intend to seduce ${kalt} any more—but I'm glad ${zhe}'s with the band, and I thank ${zhim} gravely.
                  *set k_rel 0
                  As you stand rather than embrace ${zhim}, you see a flicker of disappointment cross ${zhis} face.  But it soon vanishes as you say, "I'm honored that you thought that of me, and grateful that it brought you here.  Your strength and your passion are just what this rebellion needs."
                  
                  *goto kalglow
              *if ruth > 59
                #"And you're just the kind I need at my side."  I clap ${zhim} on the shoulder. "We'll avenge them all—mother, brother, sister."
                  *label kalglow
                  ${kalt} glows.  "Thank you, ${addressu}. That means…means a great deal to me."  $!{zhis} voice has become husky.
                  
                  "You've made a good beginning, ${kalt}. And you know what it'll take to beat them."  You lean forward.  "Just remember that sometimes we need to strip away the armor before going for the throat.  You haven't believed it so far, but trust me: these sheep are the Keriatou's armor.  This is a necessary step.  And I need you to stop trying to stir up the band against it."
                  
                  ${kalt} nods at once.  "I'm sorry, ${addressu}. I see now.  You'll hear no more insubordination from me."
                  
                  "My thanks.  And thanks as well for your honesty tonight," you venture. "Can't have been easy."
                  
                  $!{zhe} shrugs, sounding a little wistful. "Easier than I'd have thought it would be, ${addressu}.  Thanks for your ear."
                  *goto firstflock
              *if ruth < 41
                #"Maybe I'll save you instead," I counter.  "You're not a monster…and you don't have to make yourself one."
                  ${kalt} stares at you for a long time, a dozen emotions warring visibly across ${zhis} battered face. "I wish I could believe that, ${addressu}.  I truly do."  $!{zhe} abruptly stands and strides off into the grass.
                  *goto firstflock
              #"We'll fight, and we'll win.  But it's a long fight, and sometimes hitting their interests will be more important than stoking their fears. Can you accept that?"
                ${kalt} gives a gusty sigh. "Seems I have to if I want to stay, don't I?"  
                
                "At the least, you need to stop trying to stir up the band against it," you say quietly. "The decision's been made, ${kalt}.  Argue with me as you need to, but keep it between us."
                
                "I can do that, ${addressu}.  Forgive me." For a while longer, ${zhe} says nothing.  Then, "Thanks for your ear tonight," ${zhe} says, a little wistful-sounding, and heads off to bed.
                *goto firstflock
              #I say nothing, troubled by ${kalt}'s intentions for the band and wishing ${zhe}'d never come to us.
                *if k_rel = 2
                  *set k_rel 0
                After a moment, ${kalt} looks away again.  You sit next to each other without speaking for what feels like an eternity.
                
                "I know you don't want me," ${kalt} says huskily at last. "I mean, that you don't want me here, pulling at your yoke and trying to drag things in a way you don't agree with.  But you're stuck with me, ${addressu}.  I've nowhere else to go."
                
                "As long as you remember that you're not leading the band," you reply sharply. 
                *if ruth > 59
                  "When you disagree with me, talk to me.  Stop trying to stir up the band against my decision."
                *if ruth < 60
                  "And that however much you want them to fear us, you don't need to keep the monster mask constantly up when you're here in the woods with us.  I understand it now, better than I did—and I'm grateful for your honesty.  But by ${oath}, ${zgirl}, you need to find a second verse to your ballad.  And to stop trying to stir up the band against decisions you mislike."

                You expect ${zhim} to lash out in response. Instead, ${zhe} just says, "I hear you, ${addressu}.  You'll hear no more insubordination from me," in a subdued voice, gets up, and walks off.
                *goto firstflock
    *if ssheep
      On the third night, Ciels abruptly says to ${simon}, "If you'll hear me say so, you're a damned fine tracker, ${zkuria} de Firiac.
      *if aristo and (kuria = "Captain")
        I mean…${simon}, sorry, Captain.
      Even for an aristo, you've got a good eye for it."
      
      A small, proud smile plays across ${simon}'s face. "My thanks, Ciels.  Coming from you, that's praise indeed."
      
      The young tracker looks flustered at receiving a compliment from a noble.  "You, er…come from a family of hunters?"
      
      "Hunters and soldiers," ${simon} answers, ${zhis} smile fading slightly.  "Though really we should call ourselves shepherds, I suppose—our wealth is in sheep, no less than the Keriatou.  Our flocks will be somewhere out here on their way back to the Rim as well.  Never been out on the Brecks myself before."
      
      "What have you hunted?" Ciels asks eagerly, not diverted by talk of sheep.
      
      "Deer, of course.  Wolves, boar.  A bear, once, with my father."  The young noble sounds wistful.
      
      "And poachers?" Alira cuts in, her voice colder than Ciels's. "Most Inner Rim Houses with a bit of forest to their names end up hunting as many humans as wolves, I reckon."
      *page_break
      ${simon} snaps out of ${zhis} brief reverie and looks levelly at her. "I've tracked poachers, yes.  Shot at least four, seen one beheaded."
      
      "Beheaded, now?" Alira raises her eyebrows.  At a blink, the murmurs around the circle have turned ugly; half of your bandit archers are yeoman hunters who had to flee a charge of poaching. "Quite the punishment for someone you happened to catch on your land."
      
      "She was taken chewing a haunch of our stag at her cookfire.  There was no doubt as to her guilt, and I thought it kinder to use a sword than a Harrower."  For someone usually keen to please, ${simon} has turned remarkably stern. "That forest has been a de Firiac possession since before Calebre.  A House that cannot protect its lands has no more honor than a House which cannot protect its people.  The whole reason I'm here with you tonight is that as long as the Karagonds hold power over us, we can do neither."
      
      "What do you reckon, ${addressu}?" Alira turns to you, her weathered face deceptively expressionless. "Is that what we're fighting for?  The aristos' right to protect their lands…by killing us on the spot if need be?"
      *choice
        #I glare at ${simon}.  Why did ${zhe} walk into this needless argument? "After our rebellion succeeds, no one will die for killing a deer."
          The young de Firiac turns ${zhis} eyes stubbornly downward. "Poaching is no small crime, ${addressu}.  If you treat it as such, within a year the game will be gone from every estate between Rimmersford and Aveche."
          
          *if aristo
            Hunting was also a core part of your Keriatou cousins' identity; the prospect of losing all their game to common-born poachers would for them have been almost as terrible as losing their land.  But your own near-landlessness and total reliance on your cousins for the means of hunting have given you a different perspective.
          "That's because thousands of peasants are hungry and can't afford meat, de Firiac."
          
          "Forgive me, ${addressu}…but thousands are poor and can't earn enough drachems.  Does that mean that you'll withhold punishment if they begin to march into our houses and rob us?  Should a householder not defend their hearth, or a judge not sentence the thief to die?"  ${simon} meets your eyes again, unrelenting.  "A right that cannot be defended is no right at all.  As 
          *if helot
            any helot 
          *if aristo
            our helot comrades
          should surely be able to appreciate."
          
          Alira's voice rises above the hostile murmurs from the rest of the band.  "So you'd defend your two hundred deer while the yeomanry starve."
          
          "No, I'd give meat to the hungry," ${simon} says stiffly, "but I'd not suffer them to sneak onto my land and take it."
          
          "There are ways to stop trespassers and thieves short of killing them," you cut in, determined to end the conversation before ${simon} kindles any further resentments. 
          *set simz_lead -2
          *choice
            #"But if nobles persist in killing poachers, that's murder.  And there's only one way to deal with murderers."
              *if aristo
                *set cred_h +5
                *set cred_y +15
              *set cred_a -7
              ${simon} looks stricken and hotly protests, "I'm no murderer, ${addressu} ${lname}, for Angels' sake.  Nor is my father, for all his faults."  $!{zhe}'s clearly struggling to keep ${zhis} voice at a safe volume.
              
              "And killing a helot isn't murder as long as the law says otherwise."
              *if elery > 0
                Elery's eyes glint in the starlight.
                *goto nevermurd
              *elseif plan = 1
                Radmar cracks his knuckles.
                *goto nevermurd
              *else
                Alira glances at
                *if helot
                  you.
                *if aristo
                  the former helot hunters in your little group.
                *goto nevermurd
              *label nevermurd
              "But if the law changes…that day, there'll suddenly be a lot more murderers."
              
              ${simon} opens ${zhis} mouth to defend ${zhim}self again, but a terse, "Enough, de Firiac!" from you silences ${zhim}.  No one else speaks at all, and after a few minutes, your outlaws get up one by one and leave the circle for their bedrolls. The still-fuming ${simon} is third to go.
              *goto firstflock
            #"There are ways of punishing a lot of other crimes short of killing, at that.  When we put an end to Harrowing, and don't need to justify packing the machines with lawbreakers any more."
              *set ruth %-5
              "Lighter penalties breed contempt for the law, ${addressu}."  ${simon}'s brow furrows.  "Most thieves go uncaught—and don't think they don't know it.  If the consequences for those who are caught become less grave, ever fewer will see any reason to refrain."
              
              "Angels' sake," Alira snarls, her voice rising above the restrained murmur you've all managed thus far. "My forebears might have held their farm since Calebre, for all I know.  Didn't keep the aristos from whittling it down to nothing, backed up by Alastors at every step.  Yeomen get pushed off their land, they starve away to nothing…and you talk about 'consequences,' ${zgirl}?  What's the consequence of you losing some deer, when your House has got a thousand sheep out here in the Brecks?"  She points across the circle toward ${simon}.  "When I've seen you as hungry as we were this winter before you got here, then I'll hear more of what you have to say about choice and consequence.  Until then, I don't want to hear a damned word."
              *label enow
              
              "Enough," you declare sharply, forfending ${simon}'s retort. "Any more of this, and the Keriatou shepherds will hear us coming.  Make peace or go to bed."  Within a few minutes, most of the stormy-looking outlaws have chosen the latter option.
              *goto firstflock
            #"And that's all I want to hear on it tonight."
              Some of your followers look sour at your cutting off the argument—not least Alira and ${simon}—but they accept it and fall silent.  Within a few minutes, most of the outlaws have headed to their bedrolls.
              *goto firstflock
        *if aristo
          #"The first thing is to restore the rights the Karagonds took from us.  After that, we'll look at what may need to change."
            *set cred_a +7
            *set cred_h -10
            *set cred_y -20
            ${simon} nods emphatically and offers Alira a conciliatory smile.  The hunter's voice remains dry.  "My forebears might have held their land since Calebre, for all I know.  Didn't keep the aristos from whittling it down to nothing, backed up by Alastors at every step.  Now it sits with one lord or another.  Whose rights are we going to see restored when the Karagonds are beaten, ${milady}?"
            
            "The yeomanry of Shayard have suffered many and great abuses," you agree fervently.  "And my family's lands were also lost piecemeal to lords who were closer to the Thaumatarchy.  Trust me, Alira: after we've toppled them, we'll see justice done.  Three hundred years' worth of it."
            
            A handful of hunters look satisfied with that, but the usually-pliable Ciels leans in, frowning.  "My family never held land, ${addressu}—at least, not that anyone remembers.  We'd always hunted the commons until we became gamekeepers.  After the rebellion, will folk like ours still be prey to any landowner if we cross unknowing from the common woods into their forest?"
            
            ${simon} gives a soft, knowing chuckle. "Come, Ciels—how often is the crossing made unknowing, in truth?"
            
            Ciels's face hardens further.  "My father was hanged because he tried to show mercy to three hungry souls who'd made that mistake."
            
            "Another injustice," you say, hurrying to fill the bleak silence.  "A terrible one.  And until justice is meted out by folk like us, rather than the Karagonds and their collaborators, we'll see no end to them.  But trust me, it'll be a different world when the rebellion succeeds."
            
            Your outlaws share skeptical glances.  "Folk like us, eh?" Alira mutters almost inaudibly.  The circle soon breaks up for the night, earlier than usual.
            *goto firstflock
        *if aristo
          #I consider for a moment, then say, "If we want more nobles to join us, Alira, we've got to protect as many traditional rights as possible."
            *set cred_a +5
            *set cred_h -7
            *set cred_y -15
            *if plan = 1
              "So to get more of your kind on board, we'll let them kill more hunters?" Radmar's rumble is even darker than usual.
              
            *label aliraplead
            "$!{addressu}…why aren't the helotry and yeomanry enough?" Alira pleads. "Excepting those nobles who come to fight for us like 
            *if aristo
              you and 
            ${zkuria} de 
            *if aristo
              Firiac.  Why 
            *if helot
              Firiac." The scorn in her voice belies her words. "Why
            should we try bringing the rest in, if they care so little for our lives? The Thaumatarchy will fall to our numbers, not their gold."
            
            "Remember the Westriding, Alira." ${simon} tries to sound reasonable, but ${zhe}'s visibly holding back anger. "The yeomanry tried rebelling without the nobility.  It brought nothing but devastation and a heavier Karagond yoke."
            
            Alira whirls on ${zhim}, no longer hiding her own emotion.  "Ester Cabel was betrayed by the nobility.  Maybe some stripling Rimmer
            *if zhe = "he"
              lord
            *if zhe = "she"
              lady
            doesn't have reason to remember it, four and a half decades on.  But those of us whose kin fought and died alongside her do not forget."
            *goto enow
        *if helot
          #I raise an eyebrow to Alira.  "If that's what it takes to get more nobles on our side? Damned right it is."
            *set cred_a +5
            *set cred_h -3
            *set cred_y -8
            "We have to split the Thaumatarchy against itself if we're going to have a hope of winning," you continue, despite the hostile silence from the other outlaws. "We need some of those who are powerful now to take our side.  That's going to come at a cost.  As long as they'll also shoot at Alastors, I'll not stop them shooting at poachers."
            
            *goto aliraplead
        #I firmly change the subject—but take ${simon} aside later to talk about it.
          Both Alira and ${simon} respect you enough to stop arguing when they hear the tone of finality in your voice.  The conversation never recovers, however, and the other outlaws soon begin to take themselves off for the night. 
          
          You stand at the same time that the young de Firiac excuses ${zhim}self, and follow ${zhim} out of the circle.  When you're out of earshot of the others, you say quietly, "Do you find it hard to have poachers as 
          *if aristo and (kuria = "Captain")
            comrades?"
          *if helot or (kuria != "Captain")
            comrades, ${zmilady}?"

          ${simon} blurts out an instant denial.
          *if s_rel = 6
            "And regardless, I'll fight alongside whatever manner of brute I need to, ${kuria}," ${zhe} says pointedly, glares at you, and strides away.
            *goto firstflock
          As you walk on, however ${zhe} turns reflective and slightly abashed.  "In truth, ${addressu} ${lname}?  I suppose it is hard.  Having grown up thinking of them as a good sight worse than wolves, and dealt with them as such.  I don't usually think in those terms of Earnn or Alira or Ciels, though.  Or I try not to.  They're comrades, and seem good enough sorts."
          *choice
            *if arrog > 0
              #"Good enough, for a common-born pack of bandits."  I shake my head ruefully.
                ${simon} eyes you cautiously.  "You struggle with it too, ${addressu}?"
                
                You glance around to confirm that none of the other outlaws are in earshot.  "It's necessary, obviously.  They have so much less to lose, it needs very little courage for them to rebel.  And before we're done, we'll need thousands more like them; the Thaumatarchy won't fall to fewer.  But their small-mindedness, their importunities, their Xaos of action or word…ah, de Firiac, it's like wading through a swamp every day. I long for more of our peers to find their pluck and join us in rebellion."

                *if (s_rel > 6) and (s_sword != 1)
                  "That's what you long for, eh?"  The young de Firiac's lips twist.  "Well, as the only one who's come looking thus far, ${addressu}, let me just say…you've a damned odd way of showing it."
                  *goto firstflock                
                The two of you trudge on silently through the grass for a while, well away from the rest of the sleeping band.  Just as you're beginning to wonder if ${zhe} disagrees, 
                *label hereforyou
                ${simon} speaks with warm pride, "I'm glad I can be here for you, ${addressu}."
                *choice
                  *if simzpref
                    #I reach out a hand to halt ${zhim}, then bring it up to caress ${zhis} cheek. "Are you also lonely, ${zmilady} ${simon}?"
                      *label simzcaress
                      *set s_lover 5
                      ${simon} regards you wide-eyed, ${zhis} face hot under your fingers, 
                      *if (bred_lover >= 4) and (bred_here)
                        *set s_lover 2
                        before pulling away.  "$!{addressu} ${lname}…don't dishonor yourself.  Or…or Breden Reaper."  
                        *if aristo
                          $!{zhe} sounds almost surprised to find ${zhim}self adding the latter. "$!{xhe} deserves your faithfulness."
                        *choice
                          #"I'll end matters with Breden."
                            "No!" ${simon} barks, a look of profound despair coming over ${zhis} face.  "Ah, ${milady}…why could you not have been…"  Without finishing the sentence, ${zhe} whirls and runs back to the camp.  By the time you follow, ${zhe}'s already in ${zhis} bedroll, feigning sleep.
                            *goto firstflock
                          #"You're right, ${zmilady}—forgive my weakness."
                            "It's not my forgiveness you should be asking, ${addressu}." ${simon} brushes ${zhim}self off; if the sheen on ${zhis} face is tears, ${zhe} gives no other sign of it.
                            *goto firstflock
                      neither moving in nor pulling away.  $!{zhis} eyes flicker toward the distant camp, then back to yours. "I…${milady} ${fname}, I…"
                      *choice
                        #I dare to lean forward and kiss ${zhim}.
                          *set s_lover 3
                          *if helot
                            $!{zhe} gasps when your lips touch ${zhis}, and a shudder runs through ${zhis} whole body.  A moment later ${zhe} breaks away with such force that ${zhe} almost topples over backward.  "Captain…I am not to be treated so." Anger and shame are shrill in ${zhis} voice—but you think you hear a throatier note, as well.
                            *choice
                              #"You'll tell me you haven't wanted me to kiss you?" I say incredulously.
                                "Want has nothing to do with it." ${simon} stares at you with nostrils flared and eyes wide.  "Or rather, everything."
                                
                                "I don't understand you, ${zmilady}."
                                
                                "If we cannot control our desires, we become puppets of Xaos." $!{zhis} voice is intent and pleading. 
                                *label concublaze
                                "To keep the, the blaze of concupiscence in check, there are…there are constraints that must be observed.  Rules of courting and of wedlock.  Which become all the more vital, the stronger the passion."
                                
                                "Those rules would have me Harrowed for kissing you."  You lean forward, holding ${zhis} wary stare with your own. "Wedlock?  ${simon}…those rules will never have room for us."
                                
                                "We can make room, in time," ${simon} cries.  "We can…there will be some honorable…but not now, not here, not like this.  Angels, Captain, are we to begin by groping in the shadows like trulls?" 
                                
                                Before you can answer, ${zhe} breaks away and runs back to the camp.  By the time you return, ${zhe} is already in ${zhis} bedroll and feigning sleep.  You do the same through a long and unhappy night.
                                *goto firstflock
                              #"By a helot?" you demand angrily.
                                "By anyone, under such improper circumstances as these," ${simon} retorts, ${zhis} nostrils flared and eyes wide.
                                *goto concublaze
                              #Perhaps ${simon} takes the code of chastity more seriously than your Keriatou masters did.  I apologize.
                                "I don't know…what you imagine an honorable courtship between noble and helot might look like, ${zmilady}," you say, trying to bring your breathing back under control. "But it's clear that whatever it is, it isn't this.  Forgive me.  You know I don't mean to do you any dishonor."
                                
                                Some of the look of panic recedes from ${simon}'s eyes.  "I…no, forgive me, Captain.  You are right that I've…well."  $!{zhe} swallows, then exhales deeply.  The first, sad hint of a smile returns to ${zhis} face.  "For all the imagining I have indeed done, Captain…you'd think I'd have some better idea by now of how to proceed with honor.  But I don't."
                                
                                It takes all your willpower not to kiss ${zhim} again.  "At least we both know where we stand now, ${zmilady} de Firiac."
                                
                                "Forgive me, Captain," ${simon} echoes, ${zhis} face twisting with rue.  "I had wanted to speak what I was feeling—so many times—but I didn't know…I didn't imagine that you would also…"
                                
                                "You didn't need to say anything," you say, shaking your head and forcing a smile.  "But perhaps now you'll give a bit more time to thinking on how we proceed with honor.  That's not an area I can speak to."
                                
                                "I will give it my fullest attention, Captain," ${simon} promises fervently.
                                *set s_lover 6
                                *goto firstflock
                          *if loanetick1
                            $!{zhe} shivers under your lips—and for a long, delicious moment, returns your kiss with all the intensity that's been heating ${zhis} stares.  Then ${zhe} breaks away, shaking ${zhis} head vehemently.  "No, ${milady}.  Forgive me…ah Angels, forgive me.  We mustn't."
                            *goto simzkch
                          No sooner have your lips brushed ${simon}'s than ${zhe} leaps backward, flailing ${zhis} arms and almost falling down in ${zhis} haste to escape. "$!{milady}!"  $!{zhis} voice cracks with outraged rebuke. Or is it desperate longing?
                          *label simzkch
                          *choice
                            #$!{zhe} clearly holds dear the ideals of chastity with which we were all raised.  I apologize profusely for dishonoring ${zhim}.
                              "I plead your forgiveness, ${zmilady}," you groan, taking a few steps back yourself and raising your hands.
                              *if loanetick1
                                You take refuge in the stilted formality of noble etiquette.
                              "My long solitude and the influence of low company have left me weak and prone to Xaos.  I had not intended to express my admiration for you in so improper a manner.  Please know that my actions assumed no dishonorable weakness on your own part, and your own response has confirmed your virtue beyond doubt.  I…I shall absent myself at once."
                              
                              ${simon}'s eyes are downturned, ${zhis} lips pressed tightly together. "Please, ${addressu}—you repent too much.  Under such isolated circumstances as we find ourselves in,
                              *if loanetick1
                                after hearing a story of great pathos… truly,
                              even a virtuous ${woman} may find ${him}self swept away by Xaotic passion."  $!{zhe} looks up again, and while ${zhe} moves not an inch closer to you, ${zhis} yearning is stark across ${zhis} moonlit face. "Under other, more proper circumstances, duly chaperoned by a person of honor…I think you know I should welcome your court."
                              
                              After several deep breaths, you manage, "I eagerly await the hour when we find ourselves in better circumstances."
                              *set s_lover 6
                              *goto firstflock
                            #I shake my head, smiling.  "${simon}…can you tell me that you do not love me?"
                              "We…" ${simon} stares at you in 
                              *if loanetick1
                                anguish, ${zhis} mouth moving uncertainly as if to shape more words.  Then ${zhe} shuts it, breathes deeply through flared nostrils.
                              *if not(loanetick1)
                                shock, then shakes ${zhis} own head vehemently.  
                              "I…I cannot but think that I must have misled you, ${milady}.  Forgive me.  I shall absent myself at once."
                              
                              You pursue ${zhim}, trying to apologize, but nothing you say gets more than a
                              *if loanetick1
                                miserable, 
                              monosyllabic response.  When you reach your night watch, you finally stop in frustration and let the lovely de Firiac stalk back to ${zhis} bedroll.
                              *goto firstflock
                            #I press after ${zhim}, seeking ${zhis} lips again.  "${simon}, my love…"
                              $!{zhe} escapes your embrace and 
                              *if not(loanetick1)
                                starts walking stiff-legged back toward the camp.  
                              *if loanetick1
                                backs away, eyes wild and darting.
                              "$!{milady} ${lname}, please don't dishonor yourself like this."
                              
                              *if not(loanetick1)
                                "${simon}!" You pursue ${zhim}, incredulous.  "In 
                              *if loanetick1
                                You stare at ${zhim} in dismay.  "${simon}…surely you see?  In
                              the world's eyes, we're dishonored already.  The stories they'll be telling…you can't think that either of us has a reputation to return to.  All we have left is each other."
                              
                              "It isn't a matter of reputation alone, ${milady}."  The young de Firiac 
                              *if not(loanetick1)
                                spins to face you, visibly distraught.  
                              *if loanetick1
                                buries ${zhis} face in ${zhis} hands.
                              *if helot
                                "Forgive me, Captain ${lname}—I shouldn't have assumed that you would understand."
                              *if aristo
                                "I thought you would understand.  
                                *if arrog > 0
                                  You of all people."
                                *if arrog < 1
                                  I thought…"
                              
                              "Understand what?"
                              
                              "That which sets us apart from the lower orders.  Our capacity to resist the Xaos within.  To follow the will of Xthonos of our own volition, without being cuffed or constrained into it." ${simon}'s pained expression only grows as ${zhe} stares at you. "Let that go…and what does our honor even mean?"  
                              
                              $!{zhe} doesn't wait to hear your answer, breaking into a run back toward the other outlaws.  You stare after ${zhim} in frustration before following ${zhim} to a cold bedroll and a largely sleepless night.
                              *goto firstflock
                        #"Did you truly not know what I feel for you?"
                          ${simon} swallows with difficulty. "I had not dreamed…oh, ${kuria}, were we only in a place where an honorable courtship could be conducted…"
                          
                          *if helot
                            You can't help smiling, but there's a bitterness to it.  "I don't know what you imagine an honorable courtship between noble and helot might look like, ${zmilady}. Or its outcome."
                            
                            ${simon} shakes ${zhis} head slowly, ${zhis} voice hot with embarrassment.  "For all the imagining I have indeed done, Captain…you'd think I'd have some better idea by now of how to proceed with virtue.  But I don't."
                            
                            It takes all your willpower not to kiss ${zhim} at that moment.  "At least we both know where we stand now, ${zmilady} de Firiac."
                            
                            "Ah, forgive me, Captain!" ${simon} cries, ${zhis} face twisting with rue.  "I had wanted to speak what I was feeling—so many times—but I didn't know…I didn't imagine that you would also…"
                            
                            You bring your hand down to cover ${zhis} lips; ${zhis} eyes widen further, then close as you remove your hand. "You didn't need to say anything," you murmur.  "But give some thought to how you want us to proceed."
                            
                            "I'll think of nothing else, Captain."  An uneasy, incredulous joy breaks across ${simon}'s face.
                            *goto firstflock    
                          "Will we ever be?" you ask intently.  "Can rebels have an honorable courtship?  And even if we find an Ecclesiast willing to preside over a marriage…what will it mean in the eyes of the world?"
                          
                          "What would it mean to you, ${milady} ${fname}?" $!{zhe} has still neither removed your fingers nor stepped away.
                          *choice
                            #"No more than the words you and I could speak to each other, here and now."
                              *set s_lover 4
                              ${simon} lowers ${zhis} head, breaking the contact with your hand.  "Is that so, ${addressu}?"  $!{zhe} steps away, and when ${zhe} looks back up at you, ${zhis} face is creased with bitter disappointment.  "Vows taken before Xthonos and witnesses of noble blood…worth no more than words murmured in nighttime passion?"
                              
                              "We speak 
                              *if religion < 20
                                before Xthonos 
                              *if religion > 19
                                the truth in kenon
                              now," you counter, trying not to sound defensive.  "And what do noble witnesses add?"
                              
                              "Restraint," ${simon} replies at once, soft-voiced and unyielding.  "A barrier against one's animal urges—against the pull of Xaos. The most important thing there is."
                              
                              You stare at ${zhim} in acute frustration for several moments. "Then we'd best spend no more of our time testing our capacity for it, ${zmilady} de Firiac."
                              
                              "I'm afraid I agree, ${kuria} ${lname}." ${simon} sighs, gesturing
                              *goto backtobedroll
                            *if religion > 19
                              #"A sign that we were still prisoner to the priests and their superstitions."
                                *set skep %+5
                                *set s_lover 4
                                ${simon} looks down, breaking contact with your hand.  "I had feared as much when you began this…this talk of kenon, ${kuria}."
                                
                                "You don't agree with us?" You try to keep the instant surge of dismay and anger from your voice.
                                
                                "You talk about kenon bringing truth.  But when you ignore all voices quiet enough to be ignored…are not your own appetites the loudest remaining?"  ${simon}'s lips press tightly together for a moment as ${zhe} tries to slow ${zhis} breathing.  At length, ${zhe} continues with a sad smile, "It would be terribly convenient, in moments like these, if the rites of courtship and marriage were mere superstition, ${kuria}."
                                
                                "I concluded that they were some time ago, in cold blood, ${zmilady} de Firiac," you reply, a bit stiffly.
                                
                                "And perhaps one day I'll come to the same conclusion." $!{zhe} sounds sad and skeptical.  "But I have not yet—and forgive me, ${kuria}, but just now my blood is anything but cold."
                                *goto firstflock
                            #"A symbol of our devotion to Order.  But the world will not care."
                              "I will." ${simon} raises ${zhis} hand to yours, presses it tighter against ${zhis} cheek for a long moment—and then moves both your hands away, ${zhis} fingers trembling slightly.  "Should that day come, ${addressu}.  Should it come."
                              *goto firstflock
                            #I slowly pull my hand back from ${zhis} cheek.  "It would mean everything."
                              "As it would to me," ${simon} whispers.
                              *goto eyeslocked
                        *if (aristo) #I reluctantly release ${zhim}. "We cannot honorably court each other in these circumstances. For now, please know that you have my warmest regard."
                          "And I think you know you have mine, ${milady} ${fname}," ${simon} replies breathlessly.  
                          *label eyeslocked
                          
                          Your eyes remain locked together long after you have stepped apart.  The heat you felt in ${zhis} cheek seems to have kindled fires all up and down your body; the urge to kiss those slightly parted, smiling lips nearly overpowers you.
                          
                          But you manage to bow instead, murmuring, "Until circumstances allow, sweet ${zmilady}," and gesture 
                          *label backtobedroll
                          back in the direction of the camp.  The two of you walk back to separate bedrolls and a night of hotly troubled sleep.
                          *goto firstflock
                  #"When the others do come…I won't forget that you were the first.  I'll never forget that."
                    ${simon} sounds almost overcome with emotion.  "Ah, ${addressu}, you do me too much honor.  Having 
                    *if temple = 0
                      heard of 
                    *if temple > 0
                      seen
                    you and the work you were about…how could I have done anything but come to your side?"  There's a fleeting suggestion in ${zhis} voice that ${zhe} has more to say, but ${zhe} falters into silence instead.
                    
                    "You're the only one so far who has seen it that way," you point out ruefully.  "Why do you think that is?"
                    *label feargreed
                    
                    "Fear, of course.  Greed, hunger for power.  And even among the virtuous, not everyone sees the path of honor as clearly as they might." $!{zhe} inclines ${zhis} head in the more refined equivalent of a shrug.  "My sister Loane taught me exceptionally well.  Were she still alive, she'd be with us now."
                    *choice
                      #"Tell me about her," I ask, genuinely curious.
                        *label aboutloane
                        ${simon} stares out uncertainly across the starlit Brecks for a few moments, gathering ${zhis} thoughts. "Loane was a soldier, ${addressu} ${fname}.  And even in a family of soldiers, she was extraordinary.  I was nine years her junior, and my whole life I admired her. Her bow and sword hand, to be sure, but even more her presence, her utter confidence…she was a born commander, ${kuria}.  Not even the most puffed-up Southriding peer could have dismissed her as some hickard from the Rim.
                        
                        "She swore she would fight where her skills were most needed and the chance at honor the greatest.  This was when the war in the east had just broken out again, so you can imagine where Loane had her eye.  When she won her commission as a Kentarch, Father tried to have her assigned to the Abhuman Border Watch instead.  You could tell he was proud that she wanted to go east, and a bit ashamed to gainsay her…but in the end, he said the de Firiac didn't have enough heirs for him to let the Angels play dice with his eldest.
                        
                        "Father managed to arrange a personal audience with Turmarch Baryatou in Grand Shayard that Season.  Hoped to impress him with his prodigy of a daughter." ${simon}'s lips quirk. "In front of half the Court, Loane asked the Turmarch how much honor he found in marching his brigade safely back and forth in front of a Ward.  She took a beating from Father afterward.  How he yelled at her—all the work Mother and he had done to redeem our House in the eyes of the Hegemony, to rebuild our reputation, and Loane had thrown it away.
                        
                        "But she got her way.  Kurios Baryatou took revenge—or so he thought—by having her dispatched to the hottest fighting along the Errets-Halassur border."
                        *label loanetale
                        *choice
                          *hide_reuse #"The de Firiacs needed redeeming in the eyes of the Hegemony?" I cut in.
                            ${simon} nods with some satisfaction.  "Aye, ${kuria}. My grandmothers had a grudge with the local Alastors.  Spoke out against their thefts and their disrespect for the liberties of Shayard.  It ended as these things usually do—with us losing half our land.  
                            
                            "When one of my grandmothers died in her sleep, the Ecclesiast said it was Xthonos's warning to us all to stop stirring people up against Its appointed Order.  Of course, others whispered about Kryptasts." $!{zhis} smile flickers into a strained grin.  "I was only three when the whispering started.  All I understood was that the Kryptast was a creature who was always invisibly walking around our house—and I decided he would be my friend.  So I walked the halls chattering back to him for a year or two, until my mother worked out what I was doing and made me stop.
                            
                            "Of course, everyone is oblique when speaking about certain things.  I don't remember what Mama said, but it didn't really change anything I believed.  Except that now I understood that the Kryptast wasn't my friend: he was looking for a chance to kill us.  
                            
                            "It made for a…watchful childhood.  I must have been thirteen before I realized Kryptasts were humans, and that there probably wasn't one left in our house by that time."
                            *goto loanetale
                          *hide_reuse #"And your sister died fighting the Halassurqs?"
                            "They couldn't kill her," ${simon} retorts.  
                            *label heathengoetes
                            *set loanetick1 true
                            "A pack of heathen Goetes could never bring down Loane de Firiac!  She came back after two years' service, decorated for valor and on the verge of promotion to Tagmatarch.  
                            
                            "Father made sure to parade his hero daughter in every corner of the Rim; I'm sure your 
                            *if aristo
                              cousins 
                            *if helot
                              aristarch masters
                            would have met her, ${kuria}.  She had saved the life of some Theurge, and he made the rounds with her and a little honor guard of Alastors, praising her to the skies.  Then the Turmarch had her sent back to the newest front in the war, for another two years—and she survived again."
                            *goto loanetale
                          *if loanetick1
                            *hide_reuse #"How then did Loane die?"
                              "In a duel, in the woods near our estate."  $!{zhis} tone is matter-of-fact, but ${zhis} shoulders tense and hunch as ${zhe} keeps talking. "That second time, 
                              *label camebackmad
                              *set loanetick2 true
                              Loane came back from Halassur angry.  Furious with anyone who spoke about the war.  She had refused promotion in Errets, and refused any attempt by Father to make a spectacle of her again." $!{zhe} glances at you. "This was also when she beheaded the poacher we caught on our land."
                              
                              "Ah."  You nod slowly. "What so affected her?"
                              
                              "The war, ${kuria}." The heat is growing in ${simon}'s voice.  "She said there was no honor in it.  Said it should have bloody ended a century ago—could have ended, if the Karagonds didn't need an enemy to keep their provincial nobility occupied.  We've got a Ward between us and them, she said, and the Hegemony could choose to let it stand…but instead, every time they get enough strong Nereish and Whendish and Shayardene captains on the ground, they send them to push it out further.  And when the Magi have decimated the Phalangite nobles, why, then the Karagond Strategoi let the war ease off again."
                              *goto loanetale
                          *if loanetick2
                            *hide_reuse #Even as an open rebel, it still sends shivers down my back to hear someone speak an unfamiliar sedition aloud.  "Which of her views did she hint at openly?"
                              "Too much of it, to too many people." ${simon} exhales a long, trembling breath.  "On hunts, in winehouses…I think she was seeking an end, ${kuria}.  I don't think she saw any honorable path left to her, and my parents' desperation to be respectable again only increased her own desperation.
                              
                              "The Alastors didn't know quite what to do at first when their hero of the eastern war became the local malcontent.  But soon enough, their captain was paying visits to my mother and father, warning them to rein in their daughter.  Other families began avoiding us as much as they could, terrified that our Kryptast would be reappearing.
                              
                              "As it turned out, the Hegemony didn't need to go to the trouble.  The aristarchs of the Norther Rim had a son who was also back from Halassur.  He took strong exception to my sister's views, and challenged her on behalf of all the other young kentarchs.  My sister welcomed the challenge, knowing that he was as good a blade as she."
                              
                              ${simon} pauses, ${zhis} eyes glistening in the moonlight. "Of course, the Alastors saw no need to investigate the duel, nor to hold anyone responsible for my sister's death."
                              *goto loanetale
                          *if (not(loanetick3)) 
                            *hide_reuse #"So you sought to follow in her footsteps, training as a Kentarch?"
                              *set loanetick3 true
                              "Not exactly, ${kuria}." ${simon} sighs. "The other Houses in the northern Rim knew that Loane had made an enemy of the Southriding Turmarch.  
                              *if loanetick1
                                Before she returned as a hero, those 
                              *if not(loanetick1)
                                Those
                              youths who hoped to become soldiers thought they might win favor by tormenting her beloved little
                              *if zhe = "he"
                                brother
                              *if zhe = "she"
                                sister
                              at weapons practice. So as a ${zgirl} I turned to the hunt more than to soldiery—a pursuit my father was more than happy to encourage, believing that my military career was doomed before it began."
                              *goto loanetale
                          *if loanetick3
                            *hide_reuse #"And yet, you're a blademaster…."
                              *if not(loanetick2)
                                "After my sister's death, my perspective changed," ${simon} replies simply.
                                *set loanetick4 true
                                *goto loanetale
                              *label loanedied
                              ${simon} rests a hand
                              *if s_sword = 1
                                on ${zhis} sword hilt.
                              *if s_sword != 1
                                where ${zhis} sword would be, had you not taken it.
                              "After Loane fell, I knew that as soon as I was of age, the clique of loyalist nobles who saw my sister dead would challenge me.  It was too convenient a resolution for the local Alastors…to permanently bring an end to de Firiac provocations and see our remaining land passed to an adopted heir of the aristarchs' approving.
                              
                              "To prepare, I needed to find a way to hide from them for a time. Though of what time in my life could you not say that?" The young noble gives a dry chuckle.   
                              *if aristo
                                "I think you'll know, ${kuria}, that 
                              *if helot
                                "I don't know how it is for the simple folk in your camps, Captain, but
                              it's no easy thing to grow up knowing yourself ever under a hostile and oppressive eye.  To survive, to remain sane, you have to build yourself a secret world. A place they can't touch, where you can escape from them…where you can be free."
                              *fake_choice
                                *if helot
                                  #I stare at ${zhim} in amazement.  "You [i]don't know[/i] whether that's how life is for a helot?"
                                    "I thought…I didn't want to…" ${simon} stammers as ${zhe} meets your incredulous gaze.  "I just wondered whether it was easier for someone common-born to accept the authority under which they live.  To take the world as it is, rather than feeling the constant need for a greater freedom."
                                    
                                    "$!{zkuria} de Firiac, just how and where do you think this rebellion began?"  You snort and shake your head.  "We may not be as refined as you.
                                    *if s_rel > 4
                                      You may think me a brute.
                                    But no soul living could survive under that eye without needing to create refuges that They don't touch."
                                    
                                    "Forgive me, Captain," ${zhe} says, hotly abashed.  After a few moments, ${zhe} ventures, "For my part, then…our
                                *if int > 1
                                  #I think about how I immersed myself in every scrap of knowledge I could find.  "Mine was built of books."
                                    ${simon} nods in
                                    *if helot
                                      slightly surprised
                                    appreciation. "Well, our estate's
                                *if helot
                                  #"Ours was shared," I say quietly. "The tales no aristo would ever hear, let alone the Karagonds.  The games they'd not see, or understand if they saw."
                                    ${simon} gives a wistful nod.  "I wish I'd had someone to share it with. Even before Loane went off to Errets, there was too great a gap between us in age." $!{zhe} sighs and continues. "In any case, our
                                *if aristo
                                  #"I, too, had my refuges."  [i]And like ${simon},[/i] I think, [i]I lived in them alone.[/i]
                                    You think back
                                    *if introhlt
                                      to your childhood expeditions into the wild…remembering both the day the horrors followed you there, and the determined rejection of them that settled into you afterward. 
                                    *if introrel
                                      *if skepreal <= 50
                                        to Ecclesiast Olynna and the world of the Naos she opened up to you.
                                      *if skepreal > 50
                                        to the hours you spent challenging the Ecclesiasts' superstitions in your mind, building up a world in which they were untrue.
                                    *if intronat
                                      to Carles's tales and the far-off lands they conjured.
                                    ${simon} nods and continues: "Our
                                #I nod but say nothing.
                                  "Our estate's
                              forest was always part of my secret world.  A place I imagined as safe—a place that had sheltered and fed my ancestors for time out of mind.  The place I knew better than any other.  Everyone knew that I was accustomed to spend days out there; no one would be surprised if that time increased after Loane's death.
                              
                              "So I approached the blademaster who had trained my sister, and asked whether he would meet me in the woods to teach me the sword.  He was also mourning her loss, and readily agreed.  
                              
                              "After I came of age…well, as I had anticipated, one of the loyalists promptly insulted Loane to my face.  Thankfully, he wasn't of my sister's caliber, and my years of training had left me far more skilled than he'd expected.  I left him alive, if missing some fingers and a few pints of blood. To save face, his friends didn't tell the Alastors of our duel.  The Karagonds knew, of course.  But they did nothing.  Nor did the other loyalist youth, while they waited for the blademaster who killed Loane to return." $!{zhe} shrugs.  "I elected not to wait."
                              
                              You say nothing for several minutes.  "So we have your blademaster and
                              *if helot
                                kuria Loane
                              *if aristo
                                Loane 
                              to thank for your presence here."
                              
                              "My sister most of all, ${kuria}."
                              *set loanetick1 true
                              *goto loaneinsp
                          *if loanetick4
                            *hide_reuse #"Why did you decide to take up the sword?"
                              *if not(loanetick1)
                                "Well, ${kuria}…my sister survived the Halassurqs, much to the Turmarch's annoyance," ${simon} explains proudly.
                                *goto heathengoetes
                              *if not(loanetick2)
                                "After my sister was killed in a duel…" ${simon} breaks off, shaking ${zhis} head.  "After her second deployment, 
                                *goto camebackmad
                              *goto loanedied
                          #"She sounds a remarkable woman.  An inspiration."
                            "That she was, ${kuria}." 
                            *label loaneinsp
                            *set simztale true
                            ${simon} gazes out across the grass for a minute before turning back to you.  "But she lost hope, ${kuria}—she despaired of finding any honorable way to live in our present predicament.  She died 
                            *if not(loanetick2)
                              needlessly in a duel with a loyalist noble.  
                            *if loanetick2
                              needlessly.
                            I kept looking for a way to see the Karagonds driven out.  
                            
                            "Then I heard of your revolt, my ${kuria}." 
                            *if s_rel > 4
                              ${simon} sighs, a bit wistfully, and looks away again.  "And I live in hope that you will lead us on a path with greater honor than dishonor."
                              *goto firstflock
                            No one has ever looked at you with such naked admiration as ${simon} at this moment. 
                            *if helot
                              "A helot rebellion, but one led with honor and order.  And
                            *if aristo
                              "And 
                            I believed that this was the opportunity, the battle one still might fight with honor.  Following your vision; under your lead."
                            *choice
                              *if (simzpref) #I meet ${zhis} eyes for a long moment, then slowly reach out a hand to caress ${zhis} cheek.
                                *goto simzcaress
                              *if (aristo) #"Thank you, ${simon}.  I'll do my best to earn your trust."
                                *goto simzmoreen
                              *if (helot) #"Thank you, ${zkuria} ${simon}.  I'll do my best."
                                *label simzmoreen
                                "And that will be more than enough, my ${kuria}."
                                
                                You can't suppress a smile at the worshipful tone in ${zhis} voice.
                                *goto honestshare
                              #I raise an eyebrow. "Don't put me on too high of a pillar, de Firiac."
                                "No one is always perfect," ${simon} agrees at once.  "Don't fear, ${addressu} ${fname}—my loyalty will not be shaken by missteps or errors."
                                
                                You suppose that's as much concession as ${zhis} hero worship will allow for now.  
                                *label honestshare
                                "Thank you for sharing so honestly with me tonight."
                                
                                "All things, ${addressu}," ${simon} says, sounding for a moment a bit wistful. "At any time."
                                *goto firstflock
                      #"I'm sure she would be glad that you're following her example," I smile, not really interested in the de Firiac family.
                        "I pray so," ${simon} says quietly.  "Thank you, my ${addressu}."
                        *goto firstflock
                  #"How do you think we'll draw more to us?"
                    "Show ourselves capable of order, and of mercy," ${simon} replies at once, still glowing at your kindness.  "As I've said before, ${addressu} ${fname}."
                    
                    "I'd thought I was already showing that," you say ruefully.  "What's keeping the aristocracy from flocking to my side?"
                    *goto feargreed
            *if aristo
              #"Good enough, as you say.  But there are things they'll never understand."
                "No, of course not," ${simon} agrees at once.  "But we mustn't blame them for it, though.  
                *if (s_rel > 6) and (s_sword != 1)
                  I can't say that I always understand your choices either, ${addressu}."  There's still a faint edge of bitterness there.
                  *goto sistchoice
                I'll do my best to follow your example, ${addressu}."
                
                You incline your head gratefully.  "Just remember, they're the foundation of our rebellion—and before we're done, we'll need thousands more like them. The Thaumatarchy won't fall to fewer."
                
                "My helot friends would tell you that I understand that, ${kuria}.  And them."
                
                "Not that I wouldn't be grateful if more of our peers found their pluck and joined us in rebellion."  Your chuckle sounds even drier and wearier than you intended. "It's not easy spending every day surrounded by the illiterate and unmannered crowd.
                *label gladfriend
                *if s_rel = 2
                  I'm glad of your friendship, de Firiac.  Without it, I don't know how I would have endured."
                  
                  *goto hereforyou
                Your company has been a most welcome contrast."
                
                You walk on for a time without speaking.  Then
                *goto hereforyou
            #"Do you understand why they might find it hard to fight alongside a murdering noble?"
              ${simon} whirls on you, looking stricken. "I'm no murderer, ${kuria} ${lname}, for Angels' sake.  Nor was my sister—and nor is my father, for all his faults." 
              
              "And they're no wolves.  But you'd never have known it from the tone you took back at the camp circle."
              
              After a moment, ${simon} offers a grudging nod.  "I take your point, ${kuria}."
              
              "Good. I trust you'll keep it in mind next time you sense an argument about to start."
              *label sistchoice
              *choice
                #I bring our conversation to a close and return to the camp.
                  *goto firstflock
                #I glance over at ${zhim}. "I didn't know you had a sister.  You've never mentioned her."
                  "Loane died two years ago, ${kuria}."  ${simon} walks on for a minute or so without speaking.  Finally ${zhe} says, "But were she still alive, she'd be with us now."
                  
                  "Tell me about her," you ask, intrigued.
                  
                  *goto aboutloane
            #"Might be best to keep your thoughts on poaching to yourself in the future."
              "I'm sorry, ${addressu}," ${simon} says, looking genuinely ashamed.  "Please know that I didn't intend to sow division in the band."
              
              "The life out here is hard for you in many ways, I'm sure."
              
              *if aristo
                "Is it not for you?"
                
                "It's…certainly not what I was accustomed to," you say ruefully.  "But it's a cost worth paying to have some chance of overthrowing the Hegemony.  I keep my mind on that goal, and it makes it easier to endure the fleas, the flux, and the damp."
                
                *if s_rel > 4
                  ${simon} shrugs. "In truth,
                  *goto nearasmuch
                *goto hereforyou
              *if helot
                ${simon} shrugs it off with a small grin.  "Ah, 
                *label nearasmuch
                I've spent near as much time in the woods hunting with my sister, ${addressu}.  A bit of physical discomfort is just a reminder of those days."
                *goto sistchoice
    *label firstflock
    *page_break
    The next morning, you come upon your first flock—about fifty sheep, driven by a single shepherd with his son and three large dogs.  He eyes your little
    *if plan = 1
      scouting
    party warily, and shouts when you're thirty yards off, "Close enough, you lot.  Don't want the ewes taking fright."  The sheepdogs growl and bristle at you from a distance.
    
    Grey Labedan ambles over alone to have a chat, while you 
    *if plan = 1
      surreptitiously dispatch Young Earnn to keep the main raiding force out of sight.
    *if plan != 1
      hang back with the rest of the raiders.
    The old bandit returns ten minutes later, chuckling under his breath.  "Reckon he was pissing himself when he saw us come over the hill, ${addressu} ${lname}.  Pushing a half-week ahead of the other flocks can give you first pick of the high pastures…but if there are sheep-thieves about, a shepherd and a boy with no friends for days could end up in a very bad way."
    
    "He took us for bandits?" you say sharply.
    
    "Not after talking to me," Labedan grins.  "Like we planned, ${addressu}…I convinced him we're herders, looking for work on a proper-sized flock that could use the extra protection this close to Whendward.  He said he left the biggest ones a week ago, but he's given us the direction to look for them."
    
    "And if he didn't truly believe you?"
    *if bsheep 
      Breden
    *if not(bsheep)
      *if ssheep
        ${simon}
      *if ksheep
        ${kalt}
      *if not(ssheep) and not(ksheep)
        Alira
    asks, staring after the shepherd and his son.  "This is days earlier than we'd hoped to be spotted.  If he comes out of the Brecks and tells the Alastors that some outlaws are going after a big flock, they'd have more than enough time to send Theurges after us.  Maybe Phalangites, too."
    
    "They might ask why a gang of thieves wouldn't just rob the first shepherd they met," Labedan offers, eyebrows lowering.     
    *if bsheep or ksheep
    
      "And if they've got us on their minds, it wouldn't take them long to come up with a 
      *if bsheep
        reason," Breden persists.
        *if ksheep
          
          *goto klevstr
    *if not(bsheep)
      *if ssheep
      
        The young de Firiac inclines ${zhis} head, still looking troubled.  "We'll need to be ready in case they come up with the right answer."
        
        "Well, that's one option."  Labedan turns a bleak eye on the men he just chatted with, then looks back to you.
      *if ksheep
        reason."  
        *label klevstr
        ${kalt} fixes you with a level stare.  "$!{kuria}—you know what we have to do."
      *if not(ssheep) and not(ksheep)
        Alira glances at you, still looking troubled.
    *if int = 2
    
      "Don't worry," you say quietly.  "I've a plan."  That ends the discussion; your outlaws have come to trust your intellect.
      *if ksheep
        ${kalt} still looks
        *if k_rel > 5
          disgruntled and
        doubtful, but holds ${zhis} tongue for once. 
      *page_break
      *goto planoutwork
    *if int < 2
      *choice
        #We can't take the chance that these two will report our presence.  I tell my best archers to bring them down.
          *if ssheep
            "$!{addressu}, no!" ${simon} implores you, an appalled look on ${zhis} face. "These are innocents.  They don't deserve to die just for stumbling across our path."
            *choice
              #Very well.  We'll tie them up.
                *goto bond
              #I sigh.  We'll let them go.
                You glance back only once as the shepherds amble toward the northern horizon.  "If the Theurges catch us because of this, de Firiac…"
                
                ${simon} still sounds overwhelmingly relieved—and just a tiny bit smug.  "I hope they don't, ${addressu}.  But I'd rather die doing the right thing than spare myself by spilling innocent blood."
                
                "The rest of the band might not 
                *if aristo
                  be inclined to 
                *if helot
                  make
                the same choice," you growl.
                
                $!{zhis} lips curve vexingly upward. "That, my dear ${addressu}, is why we need a leader wise enough to make it for us all."
                *if s_lover > 4
                  $!{zhis} voice drops to a nearly inaudible level. "The sort of leader one might love."
                *page_break
                *goto planoutwork
              #"I won't risk them getting us killed, de Firiac.  Loose arrows."
                ${simon} doesn't touch ${zhis} bow, of course—but your other archers obey, if shamefacedly.
                *set morale -2
                *goto shootshep
          *label shootshep
          *set ruth %+20
          *set shepherds 2
          The shepherd's young son doesn't die from the first arrow, and manages to run screaming for a good hundred yards before Alira finally fells him.  The dogs charge at you in a frenzy; one of them gets close enough to injure an outlaw before dying.  Terrified sheep flee bleating in all directions.
          
          "Bury the dead," you order. "Hopefully the Brecks will swallow up fifty sheep, and it'll be weeks before anyone comes looking for them."
          
          *if ssheep
            *if eclect and (s_rel < 6)
              "$!{addressu} ${lname}…" ${simon} looks on the verge of tears. "I cannot believe this brutality to be the work of…of…"
              
              "I am the Eclect of the Angels, ${simon} de Firiac," you state flatly. "Beware of listening to other voices.  I say the path of mercy would have killed many more." 
              
              "The Codex calls on us to lay down our lives rather than murder the innocent!"
              
              "It also allows for 
              *if aristo
                sacrifice, as our former helot comrades know all too well." 
              *if helot
                sacrifice—as we know far better than you, ${zkuria} de Firiac."
              You shake your head to clear the sound of the shepherd boy's shrieks from your mind. "There are times when the lives of innocents count for less than the lives of those who risk themselves in the Angelic cause."
              
              ${simon} stares at you for a long time
              *if cha < 2
                before ${zhis} shoulders sag in defeat.  "As you say, Eclect."
                *page_break
                *goto planoutwork
              with an expression of growing horror.  "Almighty Xthonos.  I…I cannot believe it.  You speak like a brute and monster, no servant of the Angels."
              
              You glance around and are reassured to see no other bandit inclined to join the de Firiac's sudden irresolution.  Instead, they're poised to defend you if the noble raises ${zhis} weapon.  "Will you stake your soul on that feeling, ${zkuria}?"
              
              $!{zhe} ignores the ring of menacing outlaws, looking only to the fallen shepherds.  "I have already forfeited it.  All that remains is to do what I may against the Thaumatarchy."  Tears in ${zhis} eyes, ${simon}
              *set s_rel 6
              *goto gravestalk
            "You're a damned brute, ${kuria} ${lname}." ${simon} 
            *if s_lover > 4
              looks on the verge of tears.  "Such dishonor…how could you?  This isn't who you…"
              
              "I won't let honor kill my followers," you say flatly, ignoring the ache in your own throat.  "This is who I am, ${simon}, and if you had any other illusions, best to lay them to rest."
              
              The two of you glare at each other for a long moment.  Then, "Very well," ${zhe} says stiffly, and
              *set s_rel 6
              *goto gravestalk
            *if s_rel = 6
              breathes.
              
              "Surely we knew that already?" you say wearily.  "And since you didn't help in that fight, de Firiac, I have some spadework for you."
              
              "Fight?  Is that what you call it?" $!{zhe}
            *if s_rel < 6
              *set s_rel 6
            stares scornfully at you for a moment, then 
            *label gravestalk
            stalks off to dig the graves.
            *page_break
          *goto planoutwork
        #I have them captured, tied securely, and left next to a spring.  They should live until the next shepherds arrive.
          *label bond
          *set shepherds 1
          *set ruth %+15
          When your raiders stalk back toward them, bows drawn, the shepherds surrender at once; the son's curses are rapidly silenced by his stricken-looking father.  Their three dogs, by contrast, go into a frenzy and manage to inflict some injuries before two are killed and the third subdued. Terrified sheep flee bleating in all directions.
          
          Ignoring them, your hunters go to work at immobilizing your captives.  When the job's finally done, and you've tied their ankles to a stake within crawling distance of the spring, a disbelieving look comes over the older shepherd's face.  "You're just going to let our sheep run free and leave us here for the wolves?"
          
          "We'll stake your last dog here on the far side of the spring," Ciels replies, gruffly unconvincing. "The wolves will find the sheep easy pickings; they won't want to come near an angry dog."
          
          "Don't you lie at me, ${girl}." The man's eyes remain wide and outraged. "If it's a pack with a taste for human, there's nothing one hound can do about it, especially one on a lead."
          
          "Choose then," you say curtly. "We kill you now, quick and clean, or you take your chances with the wolves."  
          *if ssheep
            ${simon} gives you a reproving look but says nothing.
          Perhaps this has ended up even crueler than just shooting them—but there's no going back on it now if you want to have any chance of evading the Hegemony.
          *page_break
          *goto planoutwork
        #I let them go.  We'll take the risk that they report us early.
          *goto planoutwork
    *label planoutwork
    *if plan < 3
      It's two days until you spy another flock.  Once again Grey Labedan heads over for a talk with the drovers, and comes back rubbing his hands eagerly.  "We're in luck, ${addressu}: he passed the Keriatou shepherds a day ago.  They'd run west of the droveway to Edder's Wells.  We can catch them as they come north."
      
      You hear your
      *if aristo
        cousins'
      *if helot
        former masters'
      flock an hour before you see anything: the din of five thousand sheep can be heard from miles off, punctuated by the dogs' sharp barks and the long, baying calls of the shepherds.  The animals' smell also carries quickly on the dry air, that familiar musk of wool-oil and dung that permeates Rim Square in the late spring.  There's plenty of time to plan your ambush and spread your outlaws out far enough to
      *if plan = 2
        halfway
      surround the vast, slowly moving mass.
      
      You signal the attack when the first Keriatou shepherds have just crossed a stony watercourse at the base of a gentle slope.
      *if theurgy > 0
        *choice
          #I use ${wisardry} to demoralize them at once.
            *goto theushep
          #I use ${wisardry}, but discreetly, so that no one will recognize it.
            *set shepwis 1
            *if blood > 0
              In the moment between your signal and the attack, when no one is looking at you…
              *choice
                #…I cut my hand.
                  *set myblood +1
                  *goto attackherd
                #…I draw out a phial of blood.
                  *set cuthand false
                  *set blood -1
                  *set usedblood +1
                  *goto attackherd
            *set myblood +1
            *goto attackherd
          #My raiders don't need any supernatural help to deal with some herders.
            *goto attackherd
      *label attackherd
      Springing up from the rocks and heath banks where they've been crouched, your archers shoot at the far herders first—then use their second and third arrows on the clamorous hounds that are bounding up the slopes at you.
      *if introhlt
        (The dogs' howls send an old chill through you; you've never been able to abide the sound since your encounter with the Plektoi.)
      Before you, the dense sea of sheep begins to break up, taking flight in bleating, panicking dozens.
      
      *if shepwis > 0
        You focus on the sling-stones that whip up into the sky, and keep them rising, high enough to fly harmlessly over their targets.
      *if plan = 1
        Because you brought enough bandits to outnumber the shepherds, the fighting is over quickly.
        *if com = 0
          *if ssheep
            ${simon} de Firiac's eye for the field makes up for your own lack of combat skill; each time a gang of drovers tries to find cover and pelt you with deadly sling-shot, ${zhis} arrows find them and send them fleeing again.  The young noble's movements are unhesitating and ${zhis} face as unmoving as marble, but you think you see ${zhis} eyes flicker with each shepherd who falls to ${zhis} bow.
            
            You lose not a single outlaw.  Knowing that you're no general, your hunters stare admiringly at ${simon}; ${zhis} place in the band is beyond question now.
            *set simz_lead +1
            *goto shepsurv
          *elseif ksheep
            When one gang of drovers manages to regroup behind a craggy rock and begins pelting your bandits with deadly sling-shot, ${kalt} charges right over the boulder with a chilling shriek, knife raised high overhead.  Several choked screams later, a single young shepherd breaks cover, yammering in terror—and then drops, ${kalt}'s blade protruding from between his shoulders.
            
            You lose not a single outlaw. Knowing that you're no general, your hunters stare admiringly at ${kalt}, who grins back at each in turn.
            *set kal_lead +1
            *goto shepsurv
          *else
            *if elery > 0
              Elery Skinner's eye for the field makes up for your own lack of combat skill; each time a gang of drovers tries to find cover and pelt you with deadly sling-shot, she orders archers to a new vantage from which to send them fleeing again.  Soon the surviving Brecklanders drop to the ground and yell for mercy.
              
              You lose not a single outlaw.  Knowing that you're no general, your hunters stare admiringly at Elery, who grins back at each in turn.
              *set el_lead +1
              *goto shepsurv
            *if shepwis > 0
              *goto shepsurv
            You lose only two of your own party to the shepherds' slings.
            *set followers -2
            *set nonkids -2
            *set dead +2
            *goto shepsurv
      *if plan = 2
        *if com = 2
          You've placed your archers well to give the appearance that you have the shepherds totally surrounded.  A handful flee; most soon drop to the ground and begin yelling for mercy.  Only after they have surrendered and are disarmed and securely bound do they realize that they outnumber you.
          
          *goto shepsurv
        *else
          It's no easy matter to ambush the widely dispersed drovers with your small raiding party, though.  Halfway through the fight, a few of them realize that they actually outnumber you and begin yelling for the others to fight back.  They're accustomed to fending off wolf-packs and bears with their slings, and their stone missiles begin to
          *if shepwis > 0
            fly in greater numbers than you can fend off.
            *set followers -2
            *set nonkids -2
            *set dead +2
          *if shepwis = 0
            fell your outlaws.
            *set followers -3
            *set nonkids -3
            *set dead +3
          *if com = 0
            *set followers -2
            *set nonkids -2
            *set dead +2
          *if ssheep
            Only ${simon} de Firiac's fine archery, taking down foe after foe, prevents a rout.  In the end, the surviving shepherds drop to the ground, cursing you but pleading for mercy.
            *set simz_lead +1
            
            *goto shepsurv
          *if ksheep
            Only ${kalt}'s ferocious charge into the midst of one gang prevents a rout.  In the end, the surviving shepherds drop to the ground, cursing you but pleading for mercy.
            *set kal_lead +1
            
            *goto shepsurv
          *if elery > 0
            Only Elery's cool head and shouted orders allow your small party to keep outmaneuvering them. In the end, the surviving shepherds drop to the ground, cursing you but pleading for mercy.
            *set el_lead +1
            
            *goto shepsurv
          *if int > 1
            *if shepwis > 0
              Seeing your followers begin to fall, you wonder if the time for discretion has passed.
            *choice
              #I use ${wisardry} to terrify them.
                *label theushep
                *if shepwis = 0
                  *gosub theuhurry
                An out-thrust hand at the two nearest shepherds, and they fly off their feet with a
                *if theuknown >= 10
                  familiar
                *if theuknown < 10
                  disbelieving
                shriek: "Goety, goety!"
                *if theuknown >= 10
                  
                  "It's the Whendward demons!" one of the drover boys howls.  
                All across the broad stretch of grassland, your foes break and flee, or drop to the ground and plead for mercy.
                
                *if theuknown >= 5
                  "Well timed, ${addressu}," Ciels whispers, nursing a badly bruised arm.
                  *if c_rel < 10
                    $!{his} voice is far from warm, but ${his} gratitude is clear.
                *if theuknown < 5
                  Your own followers seem scarcely less shaken. "Xthonos, ${addressu}," Ciels gasps. "What by all Angels was that?"
                  
                  "${wisardry}," you say triumphantly. 
                  *if wisard = "Goete"
                    Seeing the terror kindle in their eyes, you hasten to add, "Or so the Hegemony will call it.  I swear to you, I learned it through no ill means, let alone trafficking with any dark powers.  But let us accept the name that they've laden with so much fear; we'll wield it against them."
                    *set morale -15
                  *if wisard = "Wisard"
                    *set natl %+5
                    "The old Shayardene art.  Stolen by Karagonds for themselves."
                *set shepwis 2
                
                *goto shepsurv
              #I don't use ${wisardry}.
                *goto sheprout
          *label sheprout
          Unfortunately, there are simply too many shepherds for the small ambush party you chose to bring.  Grey Labedan dies from a sling-stone to the skull, and Alira has an arm broken.  You flee back to the Whendward with a handful of survivors—who are further reduced when Theurges set upon you from the air on your return.
          
          It takes some time before morale begins to recover from the debacle.
          *set followers -12
          *set nonkids -12
          *set dead +12
          *set morale -12
          *goto reinforce
      *label shepsurv
      You consider the survivors' smoldering faces; there will be no recruits for your rebellion here, especially as some of the younger boys and girls died in the ambush.  Their mothers, fathers, brothers and sisters now stare at you as if dreaming of gutting you like a sheep.  You can't afford to have them slowing you down on your retreat to the Whendward.
      
      At this point, you could release them without fear of them alerting the Hegemony to your presence—by the time they reach the edge of the wilderness, you should be back in the Whendward yourself.  But if they instead tried to regather the scattered Keriatou flocks, they might rescue enough to significantly weaken the impact of your raid.  It will take days for five thousand sheep to fall victim to the wild or lose themselves beyond easy recovery.
      
      *if (theuknown < 10) and (shepwis = 2)
        There's one other thing to consider.  You've managed thus far to keep your ${wisardry} a secret
        *if theuknown >= 5
          outside the circle of
        *if theuknown < 5
          even from 
          *set theuknown 5
        your followers.  If you let these shepherds live, your powers will be known across Shayard within a month, for better and worse.
        
      You give the order to:
      *choice
        #Disarm them and release them.  With most of their dogs dead, they should struggle to bring too many sheep back.
          *set ruth %-5
          *label shepruneast
          *if shepwis > 1
            *if theuknown < 10
              *set cred_p -50
            *set theuknown 10
            *if wisard = "Goete"
              *set cred_p -50
          "Start running east," you order the surviving shepherds grimly, leaving their wrists bound but ankles free.  "If we see any one of you again, you'll take an arrow in the throat."
          *if (hec_cred = 1) or (hec_cred = 3)
            
            "Thank you, ${addressu}," ${simon} murmurs.
            
            You mutter back,
            *set hec_cred 2
            *choice
              #"I don't want your bloody thanks, de Firiac.  I want your obedience."
                ${simon} 
                *if eclect and (s_rel < 6)
                  looks uncomfortable and abashed. "You are the Eclect, ${addressu}.  I know this.  But it does not make you incapable of error, and I seek to offer good counsel where I may."
                  
                  *goto accchoice
                thrusts out ${zhis} chin.  "You'll have it, ${addressu}, whenever I can offer it without grave dishonor."
                
                *goto accchoice
              #"If you ever gainsay me again, I'll kill you."
                *if s_rel < 6
                  *set s_rel 6
                  ${simon}'s face hardens.  "So you are a damned brute after all, ${addressu}."
                $!{zhe} shakes ${zhis} head. "You may kill me, but I'll not stop speaking out when you're about to lead us into grave dishonor."
                
                *goto accchoice
              #"It was the right choice."
                *goto accchoice
            *label accchoice
            You stalk away without saying more.
            *choice
              #But soon after we get back to camp, I intend to arrange an accident for young ${zkuria} de Firiac.
                You can't allow your authority to be so openly flouted—and it's clear that nothing will stop ${simon} from doing that while ${zhe} lives.
                *set ruth %+20
                *set simzacc true
                
                *goto backtoww
              #I let it go.  $!{zhe} was right.
                *goto backtoww
              #I let it go.  We need a blademaster.
                *goto backtoww
          *set hec_cred 2
          *goto backtoww
        #Kill the adult drovers—when they took service with the Keriatou, they made themselves our rightful prey—but spare the younger ones.
          *set ruth %+10
          *set hec_cred 1
          *if ssheep
            *goto simzpleads
          *label shepboywail
          *if shepwis > 1
            *if theuknown < 10
              *set cred_p -50
            *set theuknown 10
            *if wisard = "Goete"
              *set cred_p -50
          The wails of the shepherd boys and girls follow you for miles as you lead your band away from the bloodstained watercourse.
          *if ssheep
            ${simon} half-strides, half-runs at the front of the party, tears streaking the dust on ${zhis} face.
            *if s_rel < 6
              *set s_rel 6
          *goto backtoww
        *if (shepwis = 2)
          #Kill them all.  I can't let word of my ${wisardry} reach the Archon's forces.
            *set shepwis 3
            *goto killemall
        #Kill them all.  I want every Keriatou sheep to be lost—and Hector should know that his ruthlessness will be met with ruthlessness.
          *label killemall
          *set hec_cred 3
          *if ssheep
            *label simzpleads
            "No, ${addressu}!" ${simon} pleads, dropping to ${zhis} knees in front of the first 
            *if hec_cred = 3
              young, 
            wide-eyed shepherd.  "They surrendered—they're helpless.  Killing them now would be an act of honorless, orderless butchery."
            
            *if shepherds = 2
              "Damn it, de Firiac.  If I didn't spare those two others, what mercy do you expect for these?" you snap.  "You need to leave these qualms behind if you expect the aristarchs and the Karagonds to do more than laugh and butcher us."  You gesture emphatically to your hunters.
              
              *goto shepqualms
            You glower at ${zhim} in exasperation.  "If 
            *if shepwis = 3
              they spread word of what they've seen here, de Firiac, we've thrown away our best chance to surprise the Hegemony on a few sheep."
              
              "Please, ${addressu} ${lname}," the shepherd whimpers, "we didn't see anything. 
              *goto jwtlive
            we let them go retrieve sheep, 
            *if helot
              ${zmilady}
            de Firiac, we're losing the best chance we have to weaken the Keriatou.  They'll not leave their flocks so ill-defended again."
            
            "They'll have lost enough to hurt them. We'll have victory enough," ${simon} insists. $!{zhe} drops ${zhis} voice. "I know you want to beat your
            *if aristo
              cousins
            *if helot
              masters
            as thoroughly as you may, ${addressu}—but think again.  How many needless deaths is it worth to make your victory total?"
            
            "Please, ${addressu} ${lname}," the shepherd snivels, "we don't give a helot's damn for the sheep.  
            *label jwtlive
            We just want to live."
            *if hec_cred = 3
              Looking at him again, you think under all the dirt he's probably twelve years old.
            *choice
              #"You should have thought about that before taking service with the aristarchs."
                *label shepqualms
                *if hec_cred = 1
                  *goto shepboywail
                *if cha > 1
                  ${simon} looks in desperation around the rest of the outlaws, but your charisma has swayed them; any doubts they may have are hidden behind an implacable facade. "We will be damned if we go down this road," ${zhe} mourns.
                  
                  "This is the only road that leads to the fall of the Thaumatarch," you say levelly to ${zhim}.  Then, to the rest: "Kill them."
                  *goto butchery
                *if simz_lead > 0
                  "$!{addressu}, wait." ${simon} looks in desperation around the group. "Ask your followers.  They know.  They won't do this."

                  The other outlaws are shifting from foot to foot, swayed by ${simon}'s appeal; their respect for ${zhim} as a leader has grown more than you'd have expected.  Grey Labedan wrings his hands as he looks out over his fellow Brecklanders.  "$!{addressu}," Ciels murmurs, stepping to your side. "The de Firiac is an ass at times, but ${zhe}'s not wrong now.  They're helpless; they're not nobles or Hegemonics.  
                  *if c_rel > 4
                    Spare them."
                  *if c_rel < 5
                    This once, try not to be a bloody-handed monster." $!{his} voice is cool and unwavering.
                  
                  Staring hotly into all their faces, you find yourself worryingly unsure that any of your hunters would obey an order to kill a shepherd—or even that they'd stay with you if you did it yourself.  You swallow your fury and salvage what you can of your authority.
                  *goto shepruneast
                *goto shepboywail
              #I relent and let the Keriatou drovers go.
                *goto shepruneast
              *if hec_cred = 3
                #I spare the young ones but still kill the older ones.
                  *goto shepboywail
          *label butchery
          The shepherds shriek and curse you as they die.
          *if ssheep and (s_rel < 6)
            ${simon} stares at you in disbelief, and you can see a hope dying in ${zhim} as well.
            *set s_rel 6
          *set ruth %+20
          *set cred_a -5
          
          *goto backtoww
    *else
      *comment if plan = 3
      The next day, you notice a smudge in the sky around noon and veer east to investigate it.  As you'd hoped, it's smoke rising from a tent settlement: a good thirty or forty scrappy shelters built of hide, thatch, and whatever else the Brecks yield to scavengers.  The makeshift village is built around a muddy depression with a patch of standing water in the middle.  Goats, hounds, and children scamper through the narrow aisles between tents, all ringed by a fence of cut thorn-brush as high as a tall man.
      
      "Who would you expect to find in this kind of camp?" you ask Grey Labedan.
      
      The old bandit scratches his chin.  "The poorest of peasants, ${addressu}—tenants displaced by helots, or other folk with no claim to better land, pushed out here to scratch a living.  Here in the Brecks a bit of mule-plowed land may get a crop, once, if the rains come at the right time.  Then not again for a decade.  The soil tires quickly, out here."
      
      "So how do they survive?"  You stare down with 
      *if aristo
        pitying fascination.
      *if helot
        fascination—you've never before encountered anyone whose life made a helot's sound comfortable.

      "Move, year to year.  Raise thirsty goats.  Trap rabbits and trade some to drovers.  Cut gorse, bracken, and broom to haul back to the nearest village in the civilized Rim.  And that's about all, save for a few who know enough to shepherd for hire."  Labedan stares down, shaking his head.  "When I was a boy, you'd only see a camp of this size at a good-sized stream.  If this many are all trying to make a go of it in this patch, things must be worse than ever out in the wet country."
      
      When your small party approaches the thorn fence, you're met by a cluster of gaunt farmers carrying staves and sickles. Four of them are largely blocking the gap into their tent village.  "Welcome, strangers," their white-haired leader says warily.  "Who are you, and what brings you to the Brecks?"
      *choice
        #"My name is ${fname} ${lname}—and we've business with the flocks of House Keriatou."
          *label whoreallyare
          You get only a raised eyebrow and a few mutters. "Heard of you," the old Brecklander allows. "That matter with the Theurge in Rim Square was all the autumn drovers would talk about.  And then there have been tales in the villages since."
          
          "What 
          *if aristo
            manner 
          *if helot
            sort
          of tales?" you ask curiously.
          
          The leader clears her throat and spits before answering. "Meaning no offense…that you're some
          *if aristo
            traitor noble.
          *if helot
            rabid helot.
          *if (theuknown >= 10)
            That you're a Goete, of course.
          *if demerre > 3
            That you 
            *if demerre = 5
              burn
            *if demerre = 4
              slaughter
            *if aristo
              other
            aristos in their beds.
          *if liebreaker
            That the Ecclesiasts are damning you from every Naos between here and Rimmersford.
          *if childkiller
            That you murder children.
          *if bleys > 8
            That you nabbed an Architelone on her winter rounds.
          *if openhanded
            That you rob the rich and give to the poor.
          *if simz_here
            That you kidnapped some ${zkuria} or other and are holding ${zhim} in the woods.
          That you and your bandits call yourselves rebels, and have thrown the whole North and Outer Rim into an uproar."
          
          "Well, that last is certainly true."  
          *if cha < 2
            When the Breckland farmers just keep staring stonily at you, you explain your intentions—and try to inspire them to join you. "They've pushed you out here to the edge of everything.  You owe them some return for that.  And if we overwhelm the Keriatou drovers, the mutton alone could feed you for half a year."
            
            They glance at each other, but none of them seem to have found your appeal compelling. "Best be leaving now, ${kuria} ${lname}," the white-haired woman says at last, flat-voiced. "We don't want any trouble. Not with you, and not with the Karagonds."
            
            Unfortunately, nothing you say will change their minds.
            *if bsheep
              *set bred_lead +2
              *page_break
              *set bredbreck true
              Only Breden's intervention turns the tide.  Stepping to your side, ${xhe} speaks up with a greater passion than you could manage. "That's a great shame, goodwoman.  I'd have said that what this place needs is a damned sight more trouble—far more than anything we've created so far." $!{xhis} gesture takes in the whole expanse of tattered tents and shanties.
              
              The old leader's skeptical eye turns at once to ${xhim}.
              *goto meanbythat
            *choice
              #I grudgingly accept defeat.  Time to get back to the woods before we're discovered.
                Thankfully, your hurried retreat across the Great Brecks goes without incident.  
                *gosub spottheurges
                "You turned us around at the right time."
                
                For a moment, your whole party stares back.  Your skin crawls at the thought of being caught out there, totally exposed on the Brecks.  "Press on," you order at last.  "Keep to cover."
                
                Though it's humbling to trail back into the camp with no success to report, you soon learn that your raid succeeded in unexpected fashion.  One of your fences mentions that for some reason, the Keriatou have become afraid of bandits targeting their wealth—and have sent young 
                *label patribits
                Hector and Calea to defend various bits of their patrimony.  No more veneurs trouble you through that spring and summer.
                *if (mules < 7) and (nonkids > 50)
                
                  Unfortunately, you discover that the party you sent into the Rim to 
                  *if (gandhi < 10)
                    steal 
                  *if (gandhi > 9)
                    beg 
                  a few more mules for the grain run came back late, and with
                  *set mules +5
                  *if (gandhi < 10)
                    twelve
                    *set followers -12
                    *set nonkids -12
                    *set dead +12
                    *set morale -50
                  *if (gandhi > 9)
                    *set followers -5
                    *set nonkids -5
                    *set dead +5
                    *set morale -30
                    five 
                  fewer outlaws.  The week of hunger followed by even more casualties deals a lasting blow to your morale.  If only you'd had enough mules to shrug off Hector's attack.
                *goto reinforce
              #I'll take the small band I have and try to ambush the Keriatou after all.
                *set plan 2
                *goto planoutwork
          *else
            *comment if cha = 2
            You look out across the tattered tents. "But seeing this, I'm just ashamed at how little we've done."

            *label meanbythat
            "And what do you mean by that, 
            *if not(bredbreck)
              then?"
              
              Your
            *if bredbreck
              then, ${xgirl}?"
              
              Breden's
            voice rings out with righteous conviction.  "If we'd created half the uproar we mean to, goodwoman…so many honest
            *if (natl > 50) or bredbreck
              Shayardene
            yeomen would never have been pushed off their good soil and forced to scrape the Brecks.  We'd rather the drovers were telling the tale of ${kuria} ${lname} who challenged the power of the
            *if helot
              aristos
            *if aristo
              Karagonds
            so far, they had to stop grabbing land because all any of them dared to grab was a weapon.  We'd rather our rebellion meant that your little children didn't have to drink mud and fear the wolf-pack."
            
            The Brecklander's weathered lips hover on the verge of a smile.  "They also said
            *if bredbreck
              some of
            you gave fine speeches.  But some of us grew up on this land, 
            *if not(bredbreck)
              ${kuria}.  
            *if bredbreck
              ${xgirl}.
            Some of us are as much wolf as yeoman by now."
            
            "And when you were growing up," 
            *if bredbreck
              Breden presses
            *if not(bredbreck)
              you press 
            on without pause, "did you ever have to pitch your tents for a season around a waterhole that your goats might balk at?  Or would a camp this size have been near a good-sized stream, back when there were still enough streams for shepherds and Brecklanders alike?  
            
            "Mark me: when our rebellion succeeds, the only folk who'll live on the Brecks are those who love it, who know it well enough to thrive here.  No one will be forced out of the Rim."
            
            By now, several dozen lean, ragged Brecklanders of all ages have gathered at the fence, listening intently to you.  For a long moment, no one speaks. Then, "Come in, ${kuria} ${lname}." The old woman
            *if bredbreck
              looks to you from Breden,
            chuckles and steps out of the entry. "My name's Uthwen, and I head this band.  Share our fire and tell us
            *if bredbreck
              more of
            why you've come with your fine speeches."
            *if bredbreck
              *fake_choice
                #I grin ruefully and mouth [i]Thank you[/i] at Breden as we pass into the Brecklander village.
                #Despite my anger at being upstaged by Breden, I force myself to give ${xhim} a nod of acknowledgment.
                #I see both Whendward outlaws and Brecklanders gazing admiringly at Breden—and it worries me.
            *page_break
            *set uthwen 1
            When you leave the next morning, you're yawning from a night with far more talk than sleep—but you have a hundred and sixty Breckland peasants following you.  They pack up their tents and few possessions with the brisk efficiency of long practice, ready to scatter across the drylands once the fighting is done.  Now you look like what you (mostly) are: a Great Brecks village on the move, something far less likely to arouse concern than even a small gang of armed outsiders.
            
            Uthwen and Labedan speak freely with other drovers you meet on the road, and you follow their stories to find the Keriatou flocks near Edder's Wells, a day and a half later.  The din of five thousand sheep can be heard from miles off, punctuated by the dogs' sharp barks and the long, baying calls of the shepherds.  The animals' smell also carries quickly downwind to you on the dry air, that familiar musk of wool-oil and dung that permeates Rim Square in the late spring.  
            
            You have plenty of time for your new allies to conceal their faces with ragged scarves and take up positions behind low rocks, heather banks, or clumps of grass.  Uthwen watches them go and comments, "We're enough to frighten them into surrender, ${kuria}."
            *choice
              #I nod.  "As we agreed.  No need for you to kill fellow Brecklanders."
                *set hec_cred 2
                *set ruth %-5
                *goto leadingedge
              *if (theuknown >= 10)
                #I nod.  "Possibly even without ${wisardry}—but let's not take that chance."
                  *set hec_cred 1
                  *set ruth %-5
                  Uthwen nods. If she feels any discomfort with your abilities, it's not visible.  Perhaps Breden has already talked her into accepting you, with ${xhis} famously golden tongue.
                  
                  *goto leadingedge
              #I glance at her impatiently. "But as we agreed, we need to hit them hard from ambush. I don't want to lose even one of us."
                *set hec_cred 3
                *set ruth %+5
                Uthwen's lips tighten, but she recognizes that it's too late to make any changes now.
                *if ssheep
                  ${simon} de Firiac, who had argued just as strongly for mercy, looks for a moment as if ${zhe}'s about to speak…but then lets it go, shaking ${zhis} head.
                
                *goto leadingedge
            *label leadingedge
            The leading edge of the flock moves ever nearer to your hiding place. You wait until the first Keriatou drovers accompany their sheep across a stony watercourse, at the bottom of a gentle rise.  One of their dogs sniffs suspiciously, catching some hint of you up the wind.
            
            At your gesture, a bone arrow whistles into the air…and in a great arc that stretches over a mile to either side of you, small groups of archers stand and 
            *if hec_cred = 3
              loose arrows at the nearest gang of shepherds.  The Keriatou hirelings are desperately outnumbered; those who don't fall dead or injured drop to the ground, screaming their surrender.  Most of your raiders quickly use their second and third arrows on the clamorous hounds that are bounding up toward you.  Before you, the dense sea of sheep begins to break up, taking flight in bleating, panicking dozens.
              *if introhlt
                The dogs' howls send an old chill through you, even as they die; you've never been able to abide the sound since your encounter with the Plektoi.

              *goto bindblind
            *if hec_cred < 3
              fix their arrows on the nearest gang of shepherds.
              *if hec_cred = 1
                At the same moment, you try something you'd seen Theurges do at a few Harrowings: use the blood streaming down your hand to enhance the audibility of your words.
              You bellow 
              *if hec_cred = 1
                loudly enough that you feel it in your toes:
              *if hec_cred = 2
                in an attempt to be heard even over the cacophony of bleats:
              "I am ${addressu} ${fname} ${lname} of the Whendward Band!  Surrender or die."
              
              *if hec_cred = 1
                The boom of your ${wisardry}-amplified voice raises dust out to the horizon and sends the sheep into a blind panic.  Every Keriatou herder who had been reaching for a sling collapses or staggers back, terrified.  Faintly, over the cacophony of bleats, you hear the whimpers: "Goety! Goety!"
                
                "Xthon'damn, ${addressu}," Uthwen whispers, rubbing her ears and visibly trying to regain her aplomb.  "I'd had a fair hope that I'd die before I went deaf."
              *if hec_cred = 2
                *set followers -4
                *set nonkids -4
                *set dead +4
                The head Keriatou herdsman grabs for his sling…then takes in the fact that you've brought enough bandits to surround a flock of thousands. He lets it drop limp, raising his hands, and yells frantically for his sheepdogs to come to heel.  As far as you can see, most of his companions are making the same judgment—though a few skirmishes are going on around the far edges of the flock, and the shepherds are not the only ones to fall in them. 
              
              "You're mad, ${lname}!" the chief drover 
              *if hec_cred = 1
                stammers, barely audible in the panic. "Run…r-run 
              *if hec_cred = 2
                roars up to you, thick-voiced with fury.  "Run 
              back to Whendward now.  Even if you kill us all, you'll have been spied…and the Theurges will soon come hunting."
            
              "Throw down your weapons, and tie up your dogs," you roar back.  "We're here for your masters' sheep, not for you.  We'll bind your hands and set you walking—unless you make us kill you."
            
            *label bindblind
            You bind and blindfold the 
            *if hec_cred > 1
              surviving
            drovers, while some of your hungry raiders begin to catch and slaughter sheep.  Then you release your prisoners to shuffle off to the east.  Even had you wanted to kill every Keriatou hireling, you don't think your new allies would have stood for it.
            *page_break
            Once they're out of earshot, those Brecklanders who have worked as shepherds-for-hire begin using their dogs to recover some of the vast flock.  The others work with practiced efficiency to hobble live sheep and butcher the slaughtered ones.  Despite her years, Uthwen is spry and tireless, outworking most of her neighbors.
            
            Within a few hours of hard labor, some fourteen hundred of the Keriatou animals have been recovered or disposed of on the spot.  The Brecklanders assure you that they, the wolves, or other shepherds will catch most of the rest in the days to come.  Uthwen says brisk farewells to each of her folk as they disperse into individual family groups, each bearing away some meat and enough live sheep to have been plausibly found roaming the range.
            
            "And believe me—unless your
            *if aristo
              cousins
            *if helot
              old masters
            pay them almost as many drachems as the sheep are worth, the Alastors won't go round the Brecks reclaiming their flock for them, twelve at a time."  Uthwen clasps your hands 
            *if hec_cred = 3
              without much warmth. "Well fought, ${kuria} ${lname}. I'd still have done it without the killing, though.  Unless none of those drovers recognized us, there'll be feuds coming out of this…which will be more trouble for us than just another pack of Hegemonics storming about."
              
              "None of us lost our lives today.  If you lose any in the weeks to come,
              *if aristo
                I ask your pardon."
              *if helot
                I'm truly sorry."
            *if hec_cred < 3
              *set hec_cred 2
              with satisfaction and utters a surprisingly young-sounding laugh. "Seems a bit unfair that you'll get all the blame while we get all the mutton."
              
              "Any of you who wants to share the credit is welcome to join us in the Whendward wilds, once the hue and cry have faded."
              *set uthwen 2
            You squeeze her hands and release them. "Meanwhile…we've all still got some running to do if we're to 
            *if hec_cred < 3
              avoid the consequences of our crimes."
            *if hec_cred = 3
              evade those Alastors."
            *page_break
            *goto backtoww
        *if alias != ""
          #"My name is ${alias}.  We're looking for a flock that wants protecting."
            *goto breckintro
        *if alias = ""
          #I introduce myself under an alias, and claim we're guards seeking a job with one of the larger flocks.
            You 
            *if not(choice_randomtest)
              call yourself:
              *input_text alias
              *set alias "$!{alias}"
            *if (choice_randomtest)
              *set alias "Alias"
              declare:
            "I'm ${alias}.  We're looking for a flock that wants protecting."
            
            *label breckintro
            "You'll not find one here," the old leader points out brusquely. "Nor much in the way of hospitality, Angels forgive us.  The seed we kept from last year hasn't come up yet.  What we have may need to stretch us for months, so we're not minded to share it."
            
            Neither she nor her companions show any sign of inviting you into the tent village, so you abruptly change tack.  "Then instead of finding a flock to protect—what about a flock to eat?  My true
            *goto honestintro
        #I let Grey Labedan introduce us as shepherds for hire.
          *set sheepsmell true
          "Your friends don't smell a bit of sheep," the white-haired Brecklander says levelly when the old bandit is finished.  "Nor do you, old one, though you have the Brecks in your voice.  Under a trace of Brecks-dust, I smell…tree mulch.  And deer scat.  How long has it been since your last hire?"  She raises an eyebrow.
          
          There's nothing for it but honesty if you're to have any chance of overcoming their suspicion.  You step to the fore.  "In truth, then: my
          *label honestintro
          name is ${fname} ${lname}, leader of the Whendward Band.  Hector Keriatou just butchered 
          *if rollover1 < 16
            a dozen or so
          *if rollover1 > 15
            a score or so
          of our people. We're here to return the favor with a few thousand of his sheep.  And we were hoping to interest you in some mutton."
          
          *goto whoreallyare
      *label bonetree
      You hear that the Hegemony paraded the burnt bodies of your outlaws through Rim Square before nailing their limbs above the Keriatou gate like a tiny provincial bonetree.
      *return
      *label simzmurder
      It isn't until your last night together—when ${simon}'s guard is down and you know you're nowhere near the other outlaws—that you slip over to the sleeping de Firiac and cut ${zhis} throat. Though ${zhis} eyes flutter open as soon as the blade presses home, you're fairly sure that ${zhe}'s dead before regaining any conscious awareness.  $!{zhis} horrified expression is just a reflex.
      
      "Sorry, ${zkuria}," you mutter
      *if ruth < 70
        dully, moistening your suddenly dry lips.
      *if ruth > 69
        coolly.
      "You shouldn't have set yourself against me." You'll conceal the body and tell the band that ${zhe} slipped while you were fording one of the fierce mountain rivers—an entirely plausible story.
      *set followers -1
      *set nonkids -1
      *set s_rel -50
      *if hor_guard = simon
        *set hor_guard "Radmar"
      *set simz_here false
      *set dead +1
      *page_break
      You stagger back into the camp alone the next day, suitably distraught.  
      *return
      *label backtoww
      "The raid's only halfway done," you remind your hunters. "Now we need to get back to cover—quickly, quietly, and preferably all alive."  There's a long, hard run ahead of you.
      *if ((shepherds = 0) and (randshep > 7)) or (((shepherds = 1) and (randshep < 7)) or ((shepherds = 2) and (randshep < 2)))
        *set theucatch 1
      *if ((shepherds = 0) and (randshep < 3)) or ((shepherds = 1) and (randshep > 7))
        *set theucatch 2
      *choice
        #I split the party.  Smaller groups will be better able to avoid detection.
          Splitting your 
          *if plan > 1
            already small party into pairs, 
          *if plan = 1
            large raiding party into twos and threes, 
          you order them to take different headings back to the Whendward. You and 
          *if simzacc
            ${simon}
            *set e_name simon
            *set e_he zhe
            *set e_his zhis
            *set e_him zhim
            *goto hurryhome
          *if bsheep and ((bred_lover > 1) or (bred_heart < 10))
            Breden
            *set e_name "Breden"
            *set e_he xhe
            *set e_his xhis
            *set e_him xhim
            *goto hurryhome
          *elseif ksheep and (k_rel = 4)
            ${kalt}
            *set e_name kalt
            *set e_he zhe
            *set e_his zhis
            *set e_him zhim
            *goto hurryhome
          *elseif ssheep and ((s_lover = 0) and (s_rel != 6))
            ${simon}
            *set e_name simon
            *set e_he zhe
            *set e_his zhis
            *set e_him zhim
            *goto hurryhome
          *elseif (elery > 0) and (e_rel > 0)
            Elery
            *set e_name "Elery"
            *set e_he "she"
            *set e_his "her"
            *set e_him "her"
            *goto hurryhome
          *else
            Ciels
            *goto hurryhome
          *label hurryhome
          take the most direct route.  Throughout those endless, exposed days on the Brecks, the two of you lope as fast as you can without exhausting yourselves, avoiding the din of distant flocks.
          *if plan > 1
            *if theucatch = 0
              The profound relief when you finally reach the cover of the Whendward woods is like nothing you've felt before.

              *if simzacc                
                *gosub simzmurder
                To your relief,
              *if not(simzacc)
                To your joy, 
              over the following two days the other outlaws return safely.  Alira, whose pair arrives last of all, reports that on their last afternoon they could see Theurges flying off to the south. "And let me tell you, ${addressu}…two hours of running never felt so bloody long."  There's a strained look to her that takes days to recede.
            *if theucatch > 0
              *gosub spottheurges
              
              *if simzacc
                *gosub simzmurder
                It's not hard to distract Zvad and the other shocked outlaws from the tragedy of ${simon}'s death—you just occupy them with organizing search parties to support the other returning raiders.  "They'll have had to keep low to avoid the Theurges," you tell them grimly. "Keep your eyes up, and keep to cover."
                
              Afterward, you wonder whether it would have been better to let everyone take the shortest route home.
              *if theucatch = 1
                Two
              *if theucatch = 2
                Three
              of the widely scattered groups fall afoul of the vengeful Theurges, leaving
              *if theucatch = 1
                three
              *if theucatch = 2
                five
              dead and one severely injured.
              *gosub bonetree
              *set followers -3
              *set nonkids -3
              *set dead +3
              *set morale -5
              *if theucatch = 2
                *set followers -2
                *set nonkids -2
                *set dead +2
                *set morale -5
              *set sheeploss true
          *if plan = 1
            *if theucatch = 0
              The profound relief when you finally reach the cover of the Whendward woods is like nothing you've felt before.
              
              *if simzacc                
                *gosub simzmurder
              Sadly, not all of the outlaws who went into the Brecks with you return to camp.  Three of the groups vanish—and you soon learn that they were caught by vengeful Theurges while trying to sneak home.
              *gosub bonetree
              *set followers -8
              *set nonkids -8
              *set dead +8
              *set morale -15
              *set sheeploss true
            *if theucatch = 1
              *gosub spottheurges
              
              *if simzacc
                *gosub simzmurder
                It's not hard to distract Zvad and the other shocked outlaws from the tragedy of ${simon}'s death—you just occupy them with organizing search parties to support the other returning raiders.  "They'll have had to keep low to avoid the Theurges," you tell them grimly. "Keep your eyes up, and keep to cover."

              In the following days, the cost of your raid out into the Brecks becomes brutally clear.  Five of your small groups never return, and a single scorched survivor returns from the sixth.
              *gosub bonetree
              *set followers -14
              *set nonkids -14
              *set dead +14
              *set morale -22
              *set sheeploss true
            *if theucatch = 2
              
              At dawn on the last morning, you wake to gentle shaking by ${e_name}.  "$!{addressu}," ${e_he} whispers thickly, and points a shaking finger at the eastern sky.  Three specks are visible, black against the pink light, moving with unnatural smoothness and speed.
              *page_break
              A day spent on your belly is more grueling by far than all the running of the past week. You crawl through long grass from shrub to rock, agonizingly aware of just how little any of it conceals.  For the five hours around noon you barely dare to move at all, scrambling onward only during the stretches when faint shrieks in the east confirm that the vengeful Theurges are occupied with your retreating comrades.  You don't dare to seek out any wells or rills, and before long you're nearly delirious with thirst.
              
              When the sun sinks low in the west, the wild-eyed ${e_name} rises to a crouch—but your firm hand on ${e_his} arm brings ${e_him} supine again.  Ten minutes later, the twilight is broken by despairing screams from not two miles away.  You wonder numbly if the smell of burning flesh is just delirium and fear…surely it couldn't travel so quickly, even on the early evening breeze.  As stars appear one by one overhead, you try to focus on counting them—anything to clear your mind of panic.  You try to make out the constellations your mother taught you.
              
              Only when you can distinguish every star in the faint constellation of the Kraken do you 
              *if simzacc
                crawl over to the wide-eyed ${simon} and point to the west.  "Over there," you breathe—and when ${zhe} turns to search the empty horizon, you knife ${zhim} in the throat-vein.  $!{zhis} body spasms, but the only sound ${zhe} makes is a few seconds' wet sputtering.  You wipe your blade clean on ${zhis} kyrtle and leave the body for the wolves.
                
                *comment endif
              *if not(simzacc)
                rise and beckon ${e_name} to flee.
              The rest of the night is a blur, running past the point where you can feel your legs, running after your stomach has emptied itself.  It's nearly dawn again before you drag yourself up the last slope and into the blessed safety of the trees at last.
              
              In the following days, the cost of your Breckland raid becomes brutally clear.  Nearly half of your outlaws never return.
              *gosub bonetree
              *set followers -23
              *set nonkids -23
              *set dead +23
              *set morale -32
              *set sheeploss true
          *goto kerreact
        #I keep us all together.  We'll be more visible to Theurges, but if we meet soldiers or Alastors we'll have a better chance of fighting free.
          *if plan > 1
            Alira nods emphatically when you announce your decision. "Surely a party as small as this can evade notice, even moving together."  
            
          *if plan = 1
            Several of the hunters look doubtful, but they recognize that if the Phalangites have begun patrolling by the time you return, there will be some advantage in numbers.
          "All depends on whether
          *if shepherds = 0
            those shepherds recognized us,"
          *if shepherds > 0
            anyone found those shepherds in time to call a Theurge,"
          *if ksheep
            ${kalt}
            *set e_name kalt
            *set e_he zhe
            *set e_his zhis
            *set e_him zhim
            *goto exposeddays
          *elseif ssheep
            *if elery > 0
              Elery
            *if elery = 0
              Ciels
            *set e_name simon
            *set e_he zhe
            *set e_his zhis
            *set e_him zhim
            *goto exposeddays
          *elseif bsheep
            Breden
            *set e_name "Breden"
            *set e_he xhe
            *set e_his xhis
            *set e_him xhim
            *goto exposeddays
          *elseif elery > 0
            Elery
            *set e_name "Elery"
            *set e_he "she"
            *set e_his "her"
            *set e_him "her"
            *goto exposeddays
          *else
            Ciels
          *label exposeddays
          says bleakly.
          
          Throughout endless, exposed days on the Brecks, you and your outlaws lope as fast as you can without exhausting yourselves.  You encourage each other to keep up a
          *if plan > 1
            stiff 
          *if plan = 1
            good
          pace, and head well to the west, avoiding the din of distant flocks.
          *if theucatch = 0
            *if plan > 1
              And your gamble pays off.  The profound relief when you finally reach the cover of the Whendward woods is like nothing you've felt before.
            *if plan = 1
              You nearly make it.
              
              The Theurges appear only in the last hour before you reach the Whendward, black motes in the sky that quickly grow as they soar toward you.  From the air, a group as large as yours cannot be hidden.  All you can do is break into a desperate sprint, in a loose enough formation that they can't incinerate all of you at once.
              
              You make it into the cover of the trees minutes before the vitriolic fire starts falling around you.  It's enough to save most of your followers—in the end, only ten die—but you can't help wondering if you could have achieved the same victory with a small enough group to escape unseen.
              *gosub bonetree
              *set followers -10
              *set nonkids -10
              *set dead +10
              *set morale -16     
              *set sheeploss true              
          *if theucatch = 1
            *if plan = 1
              *goto lastdawn
            *gosub spottheurges
            "We were just fast enough."
              
            For a moment, your whole party stares back.  Your skin crawls at the thought of being caught out there, totally exposed on the Brecks.  "Press on," you order at last.  "Keep to cover."  
              
            None of you sleeps well until your wearily triumphant return to camp three days later.
          *if theucatch = 2
            *label lastdawn
            
            At dawn on the last morning, you wake to gentle shaking by ${e_name}.  "$!{addressu}," ${e_he} whispers thickly, and points a shaking finger at the eastern sky.  Three specks are visible, black against the pink light, moving with unnatural smoothness and speed.
              
            It takes 
            *if plan > 1
              only seconds 
            *if plan = 1
              a minute
            to get everyone on their feet; some are on the verge of immediate flight, but you force them to roll up their beds first and don the packs you'd all loaded last night.  The last thing you need is to leave a visible camp behind you.  "Split up into
            *if plan > 1
              three 
            *if plan = 1
              ten 
            groups," you hiss, fighting to stay calm when surrounded by wide, panicked eyes.  "You lot with Alira, 
            *if plan = 1
              you with Radmar,            
            you with 
            *if e_name != simon
              ${e_name}.
            *if e_name = simon
              *if helot or (kuria != "Captain")
                ${zmilady}
              de Firiac.
            Go.  We're only a few hours out.  Keep low, keep loose, move fast."
            *page_break
            The 
            *if plan > 1
              hours 
            *if plan = 1
              minutes
            you spend sprinting half-crouched through the northern Brecks take more out of you than the last five days' exertions combined. You lead your group, darting from shrub to rock to dry streambed, agonizingly aware of just how little any of it conceals.  It's hard to keep your eyes on the increasingly rugged ground rather than constantly looking back to those circling specks in the sky.  You don't dare to stop at any wells or rills, and before long you're nearly delirious with thirst.
            
            *if plan > 1
              If there were more of you, or if you'd not been running well to the west, you're sure the Theurges would have spotted you much earlier than they do.  
              
              It's noon, and the Whendward woods are a tantalizingly visible smear on the horizon, 
            *if plan = 1
              Of course, a group as large as yours can hardly go unseen for long.  Barely an hour and a half has passed
            when you hear Young Earnn give a gasping sob from behind you.  "They're coming.  Oh, Angels, ${addressu}, they're coming."  Your head snaps up, staring eastward…and there's no doubt about it, the three small dark forms are speeding straight toward you, growing by the second.
              
            "Scatter!" you order shrilly, and your five outlaws spread into an even looser formation.  In your despair, all you can think is that it should now cost the Theurges more blood to incinerate you all.  It hardly seems possible that you could run any faster than you have been, but the sight of those inexorably growing shadows in the sky lends you all an unimagined energy.  You flee like frantic rabbits 
            *if plan > 1
              up the long and gently rising slope.
            *if plan = 1
              across the endless Brecks.
            *fake_choice
              #We're all going to die.  We're all going to die.  We're all going to die.
              #No thoughts will form in my exhausted mind, and the terror has grown so big it hardly feels like an emotion any more.
              #For a desperate moment, I find myself wishing my father were here.
              #Some tiny part of me clings to hope.
            They find Alira's group first, a mile or so to your right.  You hear the calls in fluid Karagond accents, the shrieks, and (you think?) the distant snap of bowstrings. But you refuse to look, focusing only on the 
            *if plan > 1
              woods looming out of the grass far above 
            *if plan = 1
              plains before
            you—until a resounding boom draws your eyes.  You see a cloud of oily smoke rising from the grassland; one Theurge is hovering in the air, hand out-thrust downward, while the others circle and cry out to each other. 
            
            *if plan = 1
              And so it goes for hours, as the Theurges destroy first one group of your raiders, then another, then another.  They fly away for a time, no doubt to restock on the blood and vitriol.  The Whendward woods loom up ahead of you, a tantalizingly visible smear on the northern horizon.  But around noon the three hovering figures reappear in the east, and soon you hear the screams rising again from fleeing, dying outlaws.
              
              Even as you ascend the last, long rise, you know your group will be next.  The world is growing blurry in front of you, and you've already stumbled and fallen in exhaustion six times.
            Then as your eyes snap back to the slope ahead, you see what you hadn't dared to hope for—a dry wash opening up in the long grass to your left.
            *if plan = 1
              
              *comment endif
            At first it's just a jumble of stones and a dip in the slope, but the ground rises quickly to either side as you sprint onward, and within five minutes you can no longer see those eagle-like Theurges circling
            *if plan > 1
              Alira.  
            *if plan = 1
              your doomed comrades.
            Ten minutes more, and you feel tears prick your eyes at the sight of trees rising overhead.
              
            As you run underneath the forest canopy, the world goes white and blazing hot; you feel yourself picked up and flung forward as though the air itself had lashed out at you.  You keep crawling, sobbing for breath…you wipe blood from your brow, cough uncontrollably in the sulfurous smoke, and finally collapse in the shadow of a great boulder.  
              
            When the air clears, you see two bodies, the stragglers in your group of six, blackened in the gully far behind you.  The rest of your group have, like you, scrambled to shelter and are cowering.  But the Theurges seem only to have spotted the two, and flown after other targets.  Within a minute, you've recovered enough to wave your survivors deeper into the blessedly dense woods.
            *page_break
            You regroup in the forest and begin to make your way home, keeping yourselves well hidden during the day and doing most of your travel by night.  To your surprise and delight, the scorched, limping Alira soon rejoins you; she is the sole survivor of her group, having feigned death until she could crawl away by cover of darkness.  She warns you that she spied an Alastor force marching after you from the Brecks; but back on your own ground, with your best hunters concealing your trail, you manage to evade them.
            
            *if plan = 1
              Only once you've crawled back to your camp and the stragglers stop arriving does the scale of the disaster become clear.  Some thirty-one of your bandits died out there in the Brecks.  The survivors are profoundly shaken; if three Theurges can inflict this sort of devastation on you, how can you possibly survive whatever the Archon intends to throw at you?
              *set followers -31
              *set nonkids -31
              *set dead +31
              *set morale -43
              *set sheeploss true
            *if plan > 1
              All told, you have lost only seven raiders.
              *set followers -7
              *set nonkids -7
              *set dead +7
              *set morale -10
              *set sheeploss true
            *goto kerreact
          *goto kerreact
        *selectable_if (int>1) #There's a trick I read about in a book that I think is worth trying.
          "I've an idea that may keep the Theurges from catching our trail." You turn to your outlaws. "Everyone
          *if plan < 3
            kill and
          skin one sheep—and catch two others alive."
          
          Even without the help of sheepdogs, most of your outlaws are adept with bolas; it's not difficult for them to nab some animals out of the still-large clusters around you.  "Let's start for home," you order once everyone has a new fleece and two hobbled sheep joined by a length of rope.  You're determined to put some distance between you and the site of the raid before you act on your plan.
          
          "We'll move far slower with them, ${addressu},"
          *if ksheep
            ${kalt}
            *goto poqz
          *elseif elery > 0
            Elery
            *goto poqz
          *else
            Young Earnn
            *goto poqz
          *label poqz
          points out quizzically.
          
          "Slower but safer," you promise.  That evening, in the moonlit circle, you explain the trick in full. "There's a ${nere}ish tale I once read, of Jyrk the Navigator and how he escaped the Great Roc…"  Your outlaws' initial skepticism gives way to cautious enthusiasm; everyone cleans their gory fleeces as best they can before settling down to rest next to their unhappily lowing sheep.
          
          In the morning, you split up the raiding party into pairs, each of you wearing a sheepskin over your packs and walking between the two live sheep.  You claim 
          *if simzacc
            ${simon}
            *set e_name simon
            *set e_he zhe
            *set e_his zhis
            *set e_him zhim
            *goto hurryhome2
          *elseif ksheep and (k_rel = 4)
            ${kalt}
            *set e_name kalt
            *set e_he zhe
            *set e_his zhis
            *set e_him zhim
            *goto hurryhome2
          *elseif bsheep and ((bred_lover >= 4) or (bred_heart = 3))
            Breden
            *set e_name "Breden"
            *set e_he xhe
            *set e_his xhis
            *set e_him xhim
            *goto hurryhome2
          *elseif ssheep and ((s_lover = 0) and (s_rel != 6))
            ${simon}
            *set e_name simon
            *set e_he zhe
            *set e_his zhis
            *set e_him zhim
            *goto hurryhome2
          *elseif (elery > 0) and (e_rel > 0)
            Elery
            *set e_name "Elery"
            *set e_he "she"
            *set e_his "her"
            *set e_him "her"
            *goto hurryhome2
          *elseif bsheep and ((bred_trust < 9) and (bred_heart < 10))
            Breden
            *set e_name "Breden"
            *set e_he xhe
            *set e_his xhis
            *set e_him xhim
            *goto hurryhome2
          *else
            Ciels
            *goto hurryhome2
          *label hurryhome2
          as your partner and set out toward the safety of Whendward, keeping a vigilant eye on the skies.  By the end of the day, you can no longer see any of the other bandits; each pair has taken a different heading back across the grasslands.
          
          Whenever you see any dark specks appear over the horizon, you and ${e_name} immediately drop to your knees between the two hobbled animals, covering your heads and packs with the fleece.  From the air—you fervently hope—you will appear as nothing more than a handful of scattered Keriatou livestock.  Nothing worth the close attention of a Theurge attempting to scan the vastness of the Brecks for bandits.
          
          For the first few days, the specks in the air prove to be vultures or eagles, and you spend only minutes at a time on your hands and knees.  From the morning of the 
          *if theucatch = 2
            fifth
          *if theucatch = 1
            sixth 
          *if theucatch = 0
            seventh
          day, however, the small flying shadows are too large to be birds, and move along too smooth an arc.  From that point on, you crawl most of the way back to Whendward.
          *page_break
          There are only two moments on your slow retreat when you fear for your life.  The first comes on the sixth evening, when your sheep begin to shuffle and bleat with increasing distress.  You find out why within minutes, when five gray wolves lope out of the grass and regard you with shining, unreadable eyes.
          
          "Get!" hisses ${e_name}, whipping a knife from ${e_his} belt and pointing it at the beasts.  You do the same, keeping your voice low—drawing down Theurges while saving yourself from wolves would be almost proverbially ironic.  The wolves circle you for a long, heart-pounding minute.  Then three of them yawn and break off.  You notice for the first time that their bellies are distended, their movements languid; they have no need to dare a steel blade when the Brecks are full of defenseless livestock.
          
          The second moment of raw terror comes when a Theurge flies so close to you, you can make a pretty fair guess that she's a Karagond woman.  But she's still hundreds of feet above you, and flies past without more than a cursory scan of yet another clump of sheep.  Several minutes nonetheless pass before either you or ${e_name} feel inclined to do anything but huddle, unmoving in the long grass while your animal companions graze placidly beside you.
          
          You wait for nightfall on the edge of the Brecks before finally abandoning your sheep (and, with even more satisfaction, your decomposing fleeces) and scrambling up the starlit slope to the Whendward forests.  As soon as you're under cover, ${e_name} turns to you and throws ${e_his} arms around you, sounding on the verge of joyous tears.  "$!{addressu}, it worked!  You're bloody brilliant, and it worked!"
          
          *if simzacc
            *page_break
            You return ${zhis} embrace warmly—and plunge your knife in and out of ${zhis} back, three times.  ${simon} gasps and stiffens in futile disbelief, ${zhis} hands scrabbling weakly at your shoulders. 
            *if kuria = "Captain"
              "C-Captain…"
            *if kuria != "Captain"
              "K-${kuria}…"
            And then ${zhe} slides bloodily from your grip and lies still.
            
            "Sorry, ${zkuria}," you mutter
            *if ruth < 70
              dully, moistening your suddenly dry lips.
            *if ruth > 69
              coolly.
            "You shouldn't have set yourself against me." You'll conceal the body and tell the band that ${zhe} slipped while you were fording a fierce mountain river—an entirely plausible story.
            *set followers -1
            *set nonkids -1
            *set s_rel -50
            *if hor_guard = simon
              *set hor_guard "Radmar"
            *set simz_here false
            *set dead +1
            *page_break
          Two days later, you begin to meet other surviving outlaws who are also converging on your Whendward camp.
          *if simzacc
            While at first they're shocked and dismayed to hear of ${simon}'s tragic death, their elation at the success of your ruse quickly reasserts itself.
          They clap you on the shoulders, beaming and praising you to the skies.  
          *if theuknown >= 5
            "The swiving Theurges didn't spot a single one of us!  Reckon they'll be wondering what kind of ${wisardry} you used to spirit us all away." 
          
          Of course, the pungent aroma of uncured, week-old sheepskins still hangs around all of you, even after scrubbing yourselves clean in the first stream you find.
          *if sheepsmell and (plan = 3)
            ("Angels," Breden groans, "I'd like to hear that old Uthwen tell us now that we don't smell of sheep.  Don't reckon I'll ever smell of anything bloody else.")
          But it's a small price to pay for successfully having struck at the Keriatou in the Brecks—and brought back every single one of your raiders to tell the tale.
          *set morale +5
          *goto kerreact

      *label kerreact
      *page_break
      News soon comes from Rim Square about the Keriatou reaction to your attack on their flocks.
      *if hec_cred = 1
        While there's no question that it was a major blow, you also hear tales about the heroic shepherd girls and boys who spent days recovering their masters' sheep, ignoring the blistering threats of the monstrous rebel ${lname} who murdered their parents.  It's a powerful story; if you were hearing it as a stranger, you're sure you'd cheer the children and hiss ${lname} yourself.
        
        "Can they really have recovered two thousand sheep?" you ask incredulously after hearing one account.
        
        ${deputy} shrugs. "It's possible.  Hate can inspire some astonishing things.  But it's also possible that the number's been fattened to spare the Keriatou's shame."
        
        You also hear that Hector
        *if helot
          Keriatou
        is accompanying the brave children to tell the tale around the Outer Rim—hoping, you imagine, to draw you out for another attack.  You're happy to leave him there, however…as long as it means a long pause in veneur attacks.
        *if sheeploss
          It's some consolation for the outlaws who died on this raid.
        *set cred_a -10
        *set cred_h -10
        *set cred_y -10
        *set cred_m -10
        *set cred_p -10
        *goto reinforce
      *if hec_cred = 2
        Apparently the shepherds you released crept back and managed to save 
        *if uthwen <= 0
          eleven 
        *if uthwen > 0
          six
        hundred-odd sheep—enough 
        *if uthwen <= 0
          that the aristarchs reportedly have to laud them as heroes rather than punish them as failures.  
        *if uthwen > 0
          to earn some measure of mercy from the aristarchs.
          
        But there's no question that you struck them a painful blow.
      *if hec_cred = 3
        By the time the Alastors deployed to the Brecks, barely any sheep were recoverable; the aristarchs will be reeling from the loss of so much wealth.
        
        *comment endif
      *if sheeploss
        All in all, it offers some consolation to the band for their comrades who died on this raid.
      You hear that Hector has promised to strangle you and your sheep-thieves with your own guts.  But according to one of your fences, your raid has deeply alarmed old Lord Keriatou, who deploys
      *goto patribits
      
      *label killhostages
      *if horion < 4
        Does that include Horion and Linos, ostensibly your guests?
        *choice
          #How else would we expect to get Hector Keriatou's attention?
            *goto executeallofem
          #No—just the de Firiac fool.
            *goto justsimzane
      *label executeallofem
      *set retaltick +1
      *set hostages 2
      *set s_rel -50
      *set simz_here false
      *set anarchy +7
      *set ruth %+15
      *set cred_a -30
      *set cred_p -20
      *if aristo
        *set cred_h +20
        *set cred_y +20
      *set notoriety +40
      "$!{kuria}—what are you doing?" ${simon} tries to keep ${zhis} voice level as you, ${deputy}, and Radmar stalk into the prisoners' enclosure.  Horion blinks up at you fearfully as you truss their hands behind their backs; for once, the garrulous ${delelle} seems at a loss for words.

      "One of our girls is dying with the healers right now because
      *if aristo
        my bloody cousin
      *if helot
        a bloody noble
      nailed her to a tree."  You turn back toward the crowd of outlaws that has followed you and shout, "For each one of ours they take, we'll take one of theirs!"

      ${simon} takes a shuddering breath, then draws ${zhim}self up to ${zhis} full height.  Tears glint unshed in ${zhis} eyes as ${zhe} cries out, "I am one of yours, ${kuria}!  And kurios ${delelle}
      *if (horion < 6)
        *set hostages +1
        and Ecclesiast Linos
      would be as well, if you could only allow it."  You can see ${zhe} has no intention of pleading further for ${zhis} life.

      When he sees it too, Horion starts pleading and weeping for both of them,
      *if (horion < 6)
        backed up by a terrified Linos,
      but the only mercy they get is a death far quicker than Glena's.  
      *label headsback
      *set horion 0
      Radmar bears the hostages' heads back to Rim Square by night, with a scrap of paper on which 
      *if aristo or (int = 2)
        you have
      *if helot and (int < 2)
        Zvad has painstakingly 
      written their names—and on the other side, the names of the 
      *set d2n_num rollover1
      *gosub d2n
      outlaws killed by Hector and his veneurs. It ends with:

      *set threattarg (rollover1-hostages) 
      *set d2n_num threattarg
      *gosub d2n_np
      [i]$!{display_numb} more to even the score.[/i]
      *set slain true

      *set violence +1
      *if simz_here
        *gosub simonflee
      *goto retaliation

      *label killhorion
      *set retaltick +1
      *set hostages 1
      *set anarchy +5
      *set ruth %+10
      *set cred_a -20
      *set cred_p -20
      *if aristo
        *set cred_h +15
        *set cred_y +15
      *set notoriety +30
      Horion scrambles to his feet as you, ${deputy}, and Radmar stalk into the prisoners' enclosure.  "$!{addressu}…${addressu} ${fname}?"  His voice quakes as you truss his hands behind his back, then push him to his knees.  "My family…th…they've sent some word?"
      *if (horion < 6)
        *set hostages +1
        Ecclesiast Linos shakes his head in wordless resignation.

      "One of our girls is dying with the healers right now because
      *if aristo
        my bloody cousin
      *if helot
        a bloody noble
      nailed her to a tree."  You turn back toward the crowd of outlaws that has followed you and shout, "For each one of ours they take, we'll take one of theirs."

      "No!  No…" Horion pitches forward to prostrate himself in the dirt.  "$!{addressu}, I implore you—think!  Think! There's so much more we can offer you alive…."

      "I don't need what you have to offer me, kurios ${delelle}."  You crouch and pull his tear-streaked face up toward yours. "The love of nobles like you?  There aren't enough of
      *if aristo
        us
      *if helot
        you
      to matter.  What I need is the fear of all the others."  Stepping away, you nod to the axe-wielding Radmar.  "And the certainty that a blow against us will not go unavenged."

      *if (horion < 6)
        "[i]Their[/i] fear?"  Linos's harsh voice resounds across your camp—the intonation of an Ecclesiast wielding his full, sacred authority—and although he's bound and kneeling, you find yourself seized with a paralyzing dread that goes deeper than thought.  "$!{kuria} ${lname}! For this unprovoked violence to the guests at your gate, be accursed of the Angels and 
        *if deputy = "Breden"
          Xtho…" 
          *page_break
          Linos's anathema ends abruptly in a wet crunch and a wail.  Bleak-faced, Breden raises ${xhis} boot again and brings it down hard on the sprawled priest's skull.  "No, Ecclesiast.  Don't you claim the authority of the Angels—you who murdered so many in Their name."  $!{xhis} own voice is a snarl with no trace of fear in it.

          Shaking off his own wide-eyed dread, Radmar puts his boot between Horion's shoulder blades and beheads the howling noble with a single stroke.  Horion's legs kick the air for a few macabre seconds, then go still. 

          In the ensuing silence, Breden strides out of the enclosure and points to the corpse of the Ecclesiast behind ${xhim}.  "That liar only had one weapon left.  It's a powerful one, because it nests in every heart here.  But it's a lie, 
          *if religion > 0
            ${addressc}, 
          *if religion = 0
            friends,
          with no power unless we believe it.  The Angels have heard us—not him!  They're on our side—not the side of the Thaumatarchy.  Let every priest hear that truth and fear it."

          Moved by Breden's conviction, your other followers slowly nod and return to their day's work.  You wonder if you're the only one close enough to see the tremor in ${xhis} face.  $!{xhe} acted before any of the rest of you could, but not without cost.
          *set bred_lead +2
          *fake_choice
            #And I'm grateful.
              You walk over to Breden and place a hand on ${xhis} shoulder.  "Thank you."

              "It had to be done." $!{xhe} exhales raggedly.  "Bastard priest.  Wasn't about to let him put the fear of Xaos back into us."  $!{xhe} walks away without turning to look at you.

            #I'm worried that it's going to make ${xhim} look like the natural leader of the band.
              [i]Next time[/i], you berate yourself, [i]you have the be the one who shows no fear.[/i]  "Are you all right?" you ask Breden, as loudly as you can without seeming obvious.  "You're trembling."

              "Just on the outside," ${xhe} replies at once, ${xhis} voice still level.  "It'll pass in a moment, ${kuria}.  Don't fear."  $!{xhe} walks away without turning to look at you.

            #I'm alarmed by ${xhis} unaccustomed brutality.
              You walk over to Breden and place a cautious hand on ${xhis} shoulder.  "That was…"  [i]Ugly.  Savage.[/i]  "No easy way to kill a man."

              "Easier than you'd think." $!{xhis} mouth twists, with a quiver in the corner you can see.  "It had to be done, and done hard.  Bastard priest.  Wasn't about to let him put the fear of Xaos back into us."  $!{xhe} walks away without turning to face you.

            *if (bred_lover >= 4) or (bred_heart = 3)
              #I just want to get ${xhim} somewhere where I can comfort ${xhim}.
                You turn Breden to face you and search ${xhis} eyes.  The mix of horror and relief you see there looks akin to what you're feeling.  "Are you all right?" you breathe, not wanting to publicly undermine the confidence that ${xhe}'s given the rest of the band.

                "I…will be, love." $!{xhe} exhales raggedly.  "That's an ugly way to kill a man.  I'll feel it a while."  After a few moments, ${xhe} adds, "And the curse, too.  It's easy to say that he doesn't speak for the Angels…"  Hearing ${xhis} own voice begin to crack, Breden hastily pulls away from you.  "I'll go get the graves started."

          *goto headsback
        *if deputy != "Breden"
          Xthonos.  You and all who follow you are damned to Taratur, beyond hope of restitution or redemption.  May Xaos consume you in this life, as It most assuredly shall in the…"
          *page_break
          With a roar, Radmar brings his axe down on the kneeling Ecclesiast's head, then strides over to dispatch the howling noble.  Most of your outlaws look stricken, and several are visibly trembling or weeping; it takes several minutes before they disperse, muttering darkly to each other.  Although you try to encourage them one by one, you realize that Linos's dying curse has tapped into a deep terror that will not quickly be relieved.
          *if skepreal <= 50
            If you're honest,
            *if religion < 11
              Eclect or no Eclect,
            you feel it yourself.
            *set morale -2
          *if (skepreal > 50) and ((religion < 1) or (religion > 20))
            Your own longstanding refusal to believe in Angelic curses is a comfort 
            *if skep > 50
              to only a few of your followers.
            *if skep <= 50
              only to yourself, as you continue your public profession of piety.
            *set morale +2
          *set morale -6

          *goto headsback
      Radmar takes Horion's head back to Rim Square by night, with a scrap of parchment 
      *set horion 0
      *if aristo or (int = 2)
        bearing
      *if helot and (int < 2)
        on which Zvad painstakingly writes
      the noble's name—and on the other side, the names of the
      *set d2n_num rollover1
      *gosub d2n
      outlaws killed by Hector and his veneurs. It ends with:

      *set threattarg (rollover1-hostages) 
      *set d2n_num threattarg
      *gosub d2n_np    
      [i]$!{display_numb} more to even the score.[/i]
      *set slain true
      *set violence +1
      *if simz_here
        *gosub simonflee
      *goto retaliation

      *label killsimzane
      *set retaltick +1
      *set threattarg (rollover1-1) 
      *label justsimzane
      You find Radmar and tell him to fetch an axe; the big man's strength should make it quick and clean.  
      *if bred_here
        But as you approach the enclosure where you've been keeping ${simon}, Breden runs up to you and catches your arm.  "Don't do it, ${bfname}."

        *if arrog > 0
          "How dare y…"
        You glare at ${xhim} and shake yourself out of ${xhis} grip.  "Breden.  This is no time to soften our hearts.  The mere fact that the de Firiac ${zgirl} came looking for us shows that we're not feared enough.  We need to send a message to
        *if helot
          the Keriatou
        *if aristo
          Hector
        in the only language he'll heed."

        "Will he really care?  Who is ${simon} de Firiac to him?"  Breden exhales sharply and scornfully through ${xhis} nose.  "Take a moment to think it through, ${kuria}.  You're about to throw away whatever ransom we'd get for the noble ${zgirl}…"

        "Which is nothing," Radmar interrupts, looming beside you.  "Or as good as.  You truly think ${zhis} father will pay for a child spoilt by bandits? Rash, traitorous, unmarriageable?"

        Breden ignores him as if he'd never spoken.  
        *if (horion = 2) or (horion = 3)
          *if rollover2 > 1
            "When the only hostages we have that Hector would care about in the least are Horion ${delelle} and his priest."
          *if rollover2 < 2
            "On a gesture that will have no meaning unless you kill all three of the hostages we hold.  Hector simply won't care for anything less.  Killing ${simon} alone is a waste."
          The sudden flintiness in ${xhis} eyes takes you aback.
          *choice
            #$!{xhe} has a point.  I'll execute all three hostages.
              *goto executeallofem
            #No.  Just the de Firiac.
              *goto reallyjustsim
        "…To throw it away for nothing.  And when the band realize that—when they see you killing people in a fit of anger—they'll trust you less, think less of you."
        *choice
          #I take a few deep breaths, then concede, "You're not wrong. I'll spare ${zhim}."
            Radmar tosses the axe onto the grass with a curse.  "How much more food will you waste on a dead ${zgirl}, ${kuria}?"

            Breden
            *if bred_heart < 10
              breaks into a relieved smile.  "Thank you, my ${kuria}.  For being willing to change your mind."
            *if bred_heart >= 10
              folds ${xhis} arms with stubborn satisfaction.  "It's the right choice, ${bfname}."

            "Radmar's not wrong, either.  But I've not given up all hope of a ransom."  You grimly consider what else you can do now, in a language Hector will heed.
            *goto retaliation
          #"The band would think less of me if I didn't avenge our fallen friends."
            *label reallyjustsim
            You beckon Radmar onward, ignoring Breden's continued protests.
            *goto simtodie
          #My eyes bore hotly into ${xhim}. "Trust me less…and you more?  Is that what you're saying?"
            *if bred_heart >= 10
              Breden glowers back at you with equal heat. "No, damn it.  This isn't about me and you.  The band needs a leader who will…"  $!{xhe} breaks off and flings ${xhis} arms up in disgust.  "Angels.  Why am I wasting my breath?  Do what you will, ${kuria}."
            *if bred_heart < 10
              Breden steps away from you sharply, eyes wide.  "What…${fname}, where does that come from?"

              *if bred_lead > 4
                The anger bursts out of you. "I've seen how they listen to you, how they hang on your every word as you play the captain…."

                *if deputy = "Breden"
                  "You did that, ${fname}.  When you made me your second.
                *if deputy != "Breden"
                  "Damn it, ${fname}—all I've done is serve in the ways you've asked me to.
                Now you're blaming me for it?"  $!{xhe} spreads ${xhis} arms in bafflement.
                
              "Can you tell me you don't miss it?" you say, voice low and accusatory.  "Before this started, when you were the leader—the one everyone trusted, everyone looked to.  Can you tell me you're not trying to get that back?"

              Breden's lips vanish into a thin, angry line.  When ${xhe} finally manages to speak, ${xhe} sounds choked with bitterness.
              *if (bred_lover >= 4)  or (bred_heart = 3)
                "I'd not…all we've shared, and this is what you truly think of me?"
              *if (bred_lover < 4) and (bred_heart != 3)
                "So this is what it truly is to serve the great ${addressu} ${lname}."
              *set bred_heart +10
              $!{xhe} whirls and heads off at a pace just short of a run.
            Radmar laughs his approval and beckons you on down the hill.

            *goto simtodie
      *else
        *comment if not bred here
        *label simtodie
        "$!{kuria}—what are you doing?" ${simon} tries to keep ${zhis} voice level as you stalk into the prisoners' enclosure.

        "One of our girls is dying with the healers right now because
        *if aristo
          my bloody cousin
        *if helot
          a bloody noble
        nailed her to a tree."  You turn back toward the crowd of outlaws that has followed you and shout, "For each one of ours they take, we'll take one of theirs!"

        *if horion < 1
          "Murder me then, and be damned, ${kuria}!"  ${simon}'s anguished voice carries even further than yours, freezing your followers' cheers in their throats.  "Murder me as you murdered Horion ${delelle}.  This revolt is a mere frenzy that consumes the innocent and its allies as readily as its enemies.  And I deserve to die for my folly in dreaming it was more."

          *goto simzexecute
        ${simon} takes a shuddering breath, then draws ${zhim}self up to ${zhis} full height.  Tears glint unshed in ${zhis} eyes as ${zhe} cries, "I am one of yours, ${kuria}.  If you won't see that—then yes, slay me."  You can see ${zhe} has no intention of pleading further for ${zhis} life.
        *choice
          #I gesture brusquely to Radmar.
            *goto simzexecute
          #I relent.
            "One of ours?" you echo, stone-faced.  "After we've held you hostage, and now that we're about to kill you…you expect us to believe your loyalties are to us?"

            $!{simon}'s out-thrust chin remains steady. "Unto death, ${kuria} ${lname}.  I know no other kind of loyalty."

            You shake your head, impressed despite yourself.
            *if bred_here
              Perhaps Breden was right.
            "Well, I'll say this for you, ${zmilady} de Firiac: you're not easily put off."
            *choice
              #I keep ${zhim} for ransom.
                "I believe you're sincere, ${zmilady}.  And your lonely head would be a poor exchange for the 
                *set d2n_num rollover1
                *gosub d2n
                Hector took from us."  You study ${zhim} for a few seconds more before waving a disgruntled Radmar away.  "We're not about to welcome 
                *if aristo
                  another
                *if helot
                  a
                noble to the band.  But your loyalty deserves a better trade than this.  We'll wait on your ransom."

                "If you truly believe that to be the best way for me to serve, ${kuria}."  ${simon} remains rigidly at attention.

                "Oh, sit down," you say wearily.
                *if bred_here
                  You wonder if your about-face and mercy to the young noble will reduce your band's confidence in you…but over the next few days, as Breden suggested, it actually seems to increase it.
                  *set morale +2
                Now you just need to decide what (if anything) you're actually going to do in response to Hector's attack.
                *goto retaliation
              #I let ${zhim} join the band as ${zhe} so badly desires.  We could use ${zhis} skills against Hector.
                *gosub simonzjoin
                *set violence -1
                free.  "We belatedly accept your allegiance to our cause, ${simon} de Firiac."
                *goto retaliation
                *label simonzjoin
                Sensing the mood of the crowd behind you, you turn and address them again.  
                *if religion > 0
                  "$!{addressc}: 
                *if religion = 0
                  "Tell me:
                how hard a test do we set for a noble who wants to prove ${zhis} loyalty to our cause?  What do we say when even in the face of certain death, ${zhe} still doesn't waver?"

                *if elery > 0
                  You hadn't expected Elery to be the first one to speak, but she barely hesitates in her reply: "Welcome."

                  Radmar groans, "Damn it, Skinner…."

                  "Shut it, Radmar," she snaps, striding toward ${simon} with an appraising look on her face.  "I'm no lover of aristos.  But
                  *if aristo
                    we chose to follow ${kuria} ${lname} when ${he} proved ${him}self our ally.  And as for this de Firiac,
                  anyone who can watch you brandish that great bloody axe at ${zhim} without pissing ${zhim}self is someone I want next to me when the Karagonds arrive."

                To Radmar's 
                *if elery < 1
                  visible 
                *if elery > 0
                  continuing
                disgruntlement, the rumble that rises from the other outlaws is affirming.  
                *if aristo
                  "Sounds a harder test than the one we set for you, ${addressu},"
                  *if demerre > 2
                    Ora
                  *if demerre < 3
                    a weathered old bandit
                  calls with a bark of laughter.

                  You look sternly back toward ${simon}, restraining a smile.  
                *if helot
                  You glance back sternly toward ${simon}.
                "Would you turn your hand against
                *if aristo
                  our 
                *if helot
                  your
                own kind, de Firiac?  If we suffer you to live, could we trust you to slay Hector Keriatou and his veneurs?"
                *if hector >= 4
                  The catch in your throat when you speak of killing Hector is—you hope—barely audible.
                
                Somehow ${simon} keeps a rein on ${zhis} obvious elation. "Is it true that, as I've heard, these nobles tortured a young girl nearly to death?"

                "It is.  And beheaded 
                *set d2n_num rollover1
                *gosub d2n
                of our other comrades."

                ${simon} bares ${zhis} teeth and thrusts ${zhis} bound wrists firmly toward the earth.  "Then by mighty Xthonos, ${kuria}: I'll fight the miscreants with all the strength the Angels give me."

                You draw your knife and cut ${zhim}
                *set s_rel -3
                *set morale +2
                *return
              *if (s_sword = 2) #…and I give ${zhim} back ${zhis} family sword.
                *gosub simonzjoin
                free; then you unclasp the ornate scabbard from your waist.  "Start with this.  I'm not about to hold back the band's best sword from our sole blademaster."

                At this, the young noble finally begins to shake—the emotional swings of the last few minutes have overwhelmed ${zhim}.  But ${zhe} takes the sword from you and manages a bow.  "You…you have my oath, ${kuria}.  In life and death, I serve you.  I swear, you shall never have cause to regret trusting me."

                As your outlaws cheer, your mind has already turned to how you're going to use ${simon} against Hector Keriatou.
                *set s_sword 1
                *goto retaliation
      *label simzexecute
      Your hostage kneels of ${zhis} own accord, and ${zhis} beheading is swift and soundless.  Scattered cheers rise from the band, but many look troubled or moved by the young noble's courage—you wonder if some of the cheers were even intended for ${zhim}.

      *set s_rel -50
      *set simz_here false
      *set violence +1
      *set anarchy +2
      *set ruth %+10
      *set cred_a -10
      *set cred_p -10
      *if aristo
        *set cred_h +10
        *set cred_y +10
      *set notoriety +10
      Radmar takes ${simon} de Firiac's head back to Rim Square by night, with a scrap of parchment 
      *if aristo or (int = 2)
        bearing
      *if helot and (int < 2)
        on which Zvad has painstakingly written
      the noble's name—and on the other side, the names of the 
      *set d2n_num rollover1
      *gosub d2n
      outlaws killed by Hector and his veneurs. It ends with:

      *set d2n_num threattarg
      *gosub d2n_np    
      [i]$!{display_numb} more to even the score.[/i]
      *goto retaliation

    *label playdefensive
    *if kal_here
      *if ktick = 0
        When ${zhe} finds out, ${kalt} objects fervently to this approach.  "Angels, ${kuria}, when They kill one of us, you don't just cower away until they do it again.  Blood for blood!  You strike back, and you strike back hard."
        *set ktick 1
        *choice
          #$!{zhe}'s right.  I reconsider other more forceful options.
            As before, you consider different ways you might make the Keriatou pay.
            *goto retaliation
          #"Hector wants us to come looking for him.  He thinks he'll bleed us more that way—and he's right."
            ${kalt} argues with you, but eventually gives up—though you overhear ${zhim} continuing to grumble about it with other outlaws. Radmar seems to be particularly sympathetic.
            *goto protsend
          #"Don't be a fool, ${kalt}. Your bloodthirst may cost you your life one day; I don't intend it to cost anyone else's."
            *if k_rel < 5
              *set k_rel 5
            *set k_rel +1
            ${kalt}'s eyes blaze at the insult, but ${zhe} backs down—at least, to your face.  Over the next few days, you catch snatches of conversation between the young
            *if aristo
              helot 
            firebrand and ${zhis} friends which sound decidedly disgruntled, and are usually cut off with hostile glares in your direction.
            *set morale -2
            
            *goto protsend
      This time, you ignore ${kalt}'s objections.
    *label protsend
    *if (mules >= 7) or (nonkids <= 50)
      You
    *if (mules < 7) and (nonkids > 50)
      Unfortunately, you're left with few enough mules that you can't quickly dispatch another convoy to bring in grain.  Instead, you need to send another
      *if (gandhi < 10)
        raiding party into the Rim.  
        *set followers -12
        *set nonkids -12
        *set dead +12
        *set morale -50
      *if (gandhi > 9)
        begging party into the Rim to claim a few more mules.
        *set followers -5
        *set nonkids -5
        *set dead +5
        *set morale -30
      They take a long time returning, while hunger and dread take their toll on the rest of the band.  "It's to be the winter all over again," you hear some whisper. 
      
      *set mules +5
      The party finally makes it back with a handful of mules and some barley, but 
      *if (gandhi < 10)
        twelve fewer outlaws than when they'd set out.  The high number of casualties pushes the band to the verge of panic.
      *if (gandhi > 9)
        five fewer outlaws. A deep dread settles into your band at the growing number of casualties.
        
      Thereafter, you
    send out your best hunters and trackers to scout around each mule train at a distance, to give early warning of any threats and guide the muleteers along alternate paths as needed.  You also:
    *set casred 1
    *label safechoice
    *choice
      *hide_reuse #Send Zvad to advise both the muleteers and the hunters, putting his experience as a caravan guard to good use.
        The big ${whend} shoulders his maul with an expression of bleak satisfaction.  "Hope the Keriatou does try again.  I'd like a crack at the bloody-handed bastard."
        
        "He'll come, never fear," you say grimly.
        *set zvadgo true
        *set casred +3
        
        You also:
        *goto safechoice
      *if elery > 0
        *hide_reuse #Send Elery Skinner out to judge the terrain and find new, safer routes.
          Elery eagerly takes to the hills for days with
          *if (ciels > 9)
            Breden's lover
          Ciels, in search of routes a mule train can take under the greatest possible cover.  They return with a long, enthusiastically described list of ravines, rhododendron forests, dry riverbeds, and other promising new tracks.  "It's Elery's work, truly," Ciels offers, grinning.  "I thought I knew these woods by now, but she's got an eye for the ways I'd never thought to pursue."
          
          Unsurprisingly, as Elery guides the mule trains and trackers along these better-protected routes, you overhear more and more outlaws speaking of her with admiration and gratitude.
          *set el_lead +1
          *set casred +2
          
          You also:
          *goto safechoice
      *if aristo
        *hide_reuse #Accompany your trackers periodically to build up their confidence.
          The less seasoned members of your band are deeply apprehensive about traversing the same woods as noble "veneurs."  Former helots, who have only ever been allowed to entangle small game with bolas, can't easily shed their reverence for aristocratic hunting—whether the lethal stealth of deerstalking or the thunderous pageantry of horse and hounds.  Even former yeoman peasants like Ciels and Alira, who were raised to be archers and trackers but forbidden to go after large game, don't really believe themselves the equals of an average noble hunter.  

          For your part, you've hunted enough with Hector to admire his woodcraft, cunning, and courage, but you can honestly state that Ciels, for example, is Hector's better. Your followers want to believe you.  As you accompany them, passing on some of your own hunting skills, their confidence and competence increases.  
          
          Each time you set out with them, you brace yourself to face your cousin at swordspoint or down an arrow—but it never happens.  Thanks in part (no doubt) to your own efforts at stealth, you never encounter a single veneur.
          *set casred +1
          *set morale +1
          
          You also:
          *goto safechoice
      *if (simz_here) and (s_rel < 9)
        *hide_reuse #Send ${simon} de Firiac to lead the hunting parties.
          The young noble turns out to be an extraordinary 
          *if zhe = "he"
            woodsman;
          *if zhe = "she"
            woodswoman;
          having ${zhim} at the head of your trackers greatly increases their stealth, perceptiveness, and confidence.
          
          When you congratulate ${zhim}, an unexpectedly sad smile breaks across ${simon}'s face.  "You can thank my father for that, ${addressu}—however little else he'd contribute to our cause.  Our family are hunters and soldiers, and he was determined that I should be one of the finest."
          
          "The two of you often went hunting together?" you ask gently.
          
          "They were our best times, I think.  Simplest, certainly." ${simon} shakes ${zhis} head and says no more.
          *set casred +3
          *set simz_lead +2
        
          You also:
          *goto safechoice
      
      *if (elery > 0) and (aristo or ((s_rel>0) and (s_rel<9)))
        #Do all of the above, of course.
          *set casred 9
          *if elery < 1
            *set casred -1
          *if helot
            *set casred -1
          *if (s_rel < 0) or (s_rel > 8)
            *set casred -2
          *set zvadgo true
          *goto nexttry
      #Do nothing else.
        *goto nexttry
    *label nexttry
    *set cas (rollover1-casred)
    *set followers -cas
    *set nonkids -cas
    *set dead +cas
    Hector does try to ambush you again, more than once.  But this time, thanks to your precautions, his attacks fail to cut off your food supply or stop even a single mule train.  
    
    Over several small clashes, your followers
    *if violence > 0
      manage to 
    injure at least two noble veneurs—at the cost of another 
    *set d2n_num cas
    *gosub d2n
    outlaws dying.
    *if zvadgo
      *set zvad -50
      *if hor_guard = "Zvad"
        *set hor_guard "Radmar"
      *set zv_here false
      
      One of the casualties is Zvad.  
      *page_break
      The news reaches you while you're out hunting.  Hurrying back into camp, you hear
      *if nonkids > 39
        dozens of young
      *if nonkids < 40
        more than half your
      outlaws wailing in
      *if natl > 50
        Shayarin,
      ${whend}ish and Koine.  It isn't just the bandits who had followed Zvad before your arrival who mourn him now—many of the helots who 
      *if rescuer < 1
        accompanied you from Rim Square or
      joined the band in the spring are sobbing too.  The ex-mercenary's gruff but gentle encouragement during weapons practice or the long journeys between camps long ago won him their affection and loyalty.
      *if ((elezvad > 0) and (elezvad < 8)) and el_here
        Elery is crying in great, gasping sobs.
      
      As your eyes adjust to the dimness of the Ablers' tent, you blink down at Zvad's unmoving form on a hide pallet. You knew that a body looks smaller with the life fled from it, but the sight never felt so incongruous as it does with the burly ${whend}.  "How did he die?"
      
      Radmar sways to his feet despite being swathed in bloodstained 
      *if poric > 0
        bandages and Poric's attempts to keep him prone.  
      *if poric = 0
        bandages.
      The
      *if aristo
        former helot
      *if helot
        big fighter
      is shaking with violent emotion. "He and I hung back to keep the Xthon'damned veneurs off the mule train, ${addressu}.  He took an arrow in the chest as we began to pull back.  Kept his feet until we were halfway back to the camp."
      
      You pick up the shaft that killed Zvad.  The bright kermes fletching plainly makes it a Keriatou arrow.  Not only is it their House's color, but no other family in the Rim is extravagant enough to use a costly dye to identify their kills. "Mark me, Radmar—Hector Keriatou will pay dearly for this.  I swear it."
      *goto reinforce
    *if not(zvadgo)
      But your hunters work hard to hide the casualties, carrying bodies back through the wilderness.  As you'd hoped, this disheartens the veneurs—or at any rate, the pace of their attacks soon drops off.
    *goto reinforce

*label spottheurges
You've never felt such immense relief as when you reach the top of the last grassy slope and step into the shade of the Whendward forest again.
          
Half an hour later, ${e_name} hisses sharply and grabs your shoulder.  Looking back up through the trees to where ${e_he}'s pointing, at first you see nothing but cloudless blue.  Then you spot the three dark specks soaring in parallel through the clear sky above the grassland.  "Not birds, ${addressu}," ${e_he} whispers needlessly. 
*return

*label reinforce
*if hectheu > 0
  *if theuknown < 10
    *set cred_p -50
  *set theuknown 10
*if (zvad < 0) and (elezvad > 7)
  *if b_name != "Elery"
    *page_break
    When Elery learns of Zvad's death, 
    *if elezvad > 7
      her first reaction is to find you and punch you in the face.
      
      "Your fault, ${kuria}, damn you!" she howls as you try belatedly to fend off her fists.  Her own face is swollen and streaked from weeping—and taut with rage. "Damn you!  You and your Xthon'damned sneaking around!  If we'd gutted Hector rather than trying to avoid him, we'd still have Zvad!"
      
      Four of your other followers pull her off you and away, shrieking incoherently.  Much later, as the somber band is settling down for the night, you seek her out again.
  *if b_name = "Elery"
    
    That night, nursing your bruises and aching head, you seek out Elery.
  *fake_choice
    #I can barely contain my anger. But I can't afford to lose her now.
    #She needs to know she's not the only one mourning Zvad.
    #I just want to know whether she's all right.
  *if (elezvad > 9)
    Elery turns as you approach her.  "I'm sorry, ${kuria}," she rasps, glassy-eyed. "You…you didn't deserve that.  Zvad would have been the first to say so."  Tears leak from between her eyelids as she squeezes them shut.
    
    "We all do things we regret," you allow. 
    
    "Weeks, ${kuria}.  We only had weeks."  Her voice is numb, choked-sounding. "If there are Angels, damn Them for Their shitty little mercies."
    
    *if skepreal < 55
      You recoil in shock from her blasphemy. "You mustn't say such things, Skinner.  Even in a time like this.  We need all the mercies we can get."
      
      "What I need right now, ${kuria}?  Either Hector Keriatou or myself dead.  If They want to, the bloody Angels can kill me and welcome."  Elery's voice is beginning to crack again by her last sentence, and she stalks off in the middle of it.
    *if skepreal > 54
      While you might not express it so crudely, you can hardly argue with the sentiment. "Aye, Skinner.  But hold on to that time together for what it was.
      *if ruth > 55
        And one day we'll pay back Hector Keriatou and all the rest for what they've cost us."
      *if ruth < 56
        Small mercies are all the world offers to 
        *if helot
          folk like us."
        *if aristo
          slaves and rebels."
  *if (elezvad < 10)
    Elery turns hollow eyes on you—but you can see the embers of the hatred that will soon rekindle there.  "You robbed me of whatever time I could have had with him, ${lname}.  Don't speak to me of him, ever again."  
    
    She hurries away from you, pausing to say over her shoulder, "In fact, don't speak to me at all unless you must, ${kuria}."
    *set e_rel -10
*page_break
*if c_name = kalt
  On the way back, you turn to ${kalt}.  "Why did you hide the bola practice from me?"
  
  *if k_rel < 5
    "I'm sorry, ${kuria}," ${zhe} says, looking abashed. "I thought best to keep it as much a secret as possible.  It helped the plan, rather than going against it…so I didn't see the need to tell the rest of the planners.  Just in case one of them spoke to the wrong person." 
    
    [i]Or was the wrong person[/i], you hear behind ${zhis} words. "You could tell me without telling all the rest."
    
    "Next time I will, ${kuria}," ${kalt} promises.
  *if k_rel > 4
    $!{zhe} doesn't look at you. "I didn't know who else might hear if I did."
    
    You blink incredulously. "Say again?"
    
    "It went with the plan, not against it."  Now ${zhe} turns to you, defiance 
    *if k_rel > 6
      and contempt 
    clear on ${zhis} face. "So I didn't see reason to tell anyone else.  If Hector had known it was coming, I'd have lost three of my people rather than him losing three of his."
    
    The outlaws around you have noticed that you're talking, and are fairly transparently trying to listen in.  You try to keep the extent of your anger out of your face and voice.  "I have to judge that risk on every raid, ${kalt}.  Next time, tell me.  You might not have heard every part of the plan; your surprise might not go as well next time."
    
    ${kalt} responds with an entirely noncommittal nod.  For the time being, that's all you'll get out of ${zhim}.
  *page_break
  *goto reinforce2
*if (zvad < 0) and (deputy = "Zvad")
  Among the many gaps that Zvad's death will leave is the responsibility of being your second-in-command.  Your experience of the last two seasons has driven home how vital it is to have someone competent to keep the band together when you're planning a raid or otherwise occupied.  
  
  You don't think anyone else from the old Whendward Band is keen to take a leading role.  Considering the options, you finally settle on:
  *label dep_choice
  *choice
    *if (bred_here)
      #Breden Reaper.
        *set deputy "Breden"
        *set dephe xhe
        *set dephis xhis
        *if bred_heart > 9
          Breden glares at you when you ask ${xhim}. "What makes you think I'd want to be your second, ${lname}?"
          
          "I'm not looking for a deputy who agrees with me on all things, Reaper.  I want one who'll inspire the band.  Get them ready to stand up to whatever's coming this summer."  You fold your arms, glare back. "If you don't want it, then say so and I'll ask someone else."
          
          $!{xhe} looks hesitant and still angry. "Don't think I'll just accept all you say, ${addressu} ${lname}.  You may need to choose another deputy soon enough."
          
          "If it comes to that, I'll gladly do so.  But before I think better of the offer: do you accept?"
          
          "Aye then."  Breden shakes ${xhis} head, visibly bemused. "Now go tell the band before I think better of it."
        *if bred_heart <= 9
          "Are you sure, ${bfname}?" Breden says soberly. "The band may want someone who's better in a scrap, with a battle in the wind."
        
          "I'd rather have someone who I know can inspire them to fight."
         
          "Unless there's some way other than fighting to survive, ${addressu}…" $!{xhe} looks pensive for a moment before saying, "Very well.  I accept."
        *set bred_lead +2
        *page_break
        *goto reinforce2
    *if (simz_here) and (s_rel < 9)
      #${simon} de Firiac.
        *if (s_rel = 5) or (s_rel = 6)
          "Never, ${addressu}," ${simon} says flatly.  "I'll fight for the rebellion, but not share in your cruelty."
          *goto dep_choice
        *set deputy simon
        *set dephe zhe
        *set dephis zhis
        *set simz_lead +2
        "My thanks, ${addressu}," ${simon} beams, almost bursting with pride.  "You won't regret it."

        *goto reinforce2
    *if kal_here
      #${kalt} Swineherd.
        *set deputy kalt
        *set dephe zhe
        *set dephis zhis
        *set kal_lead +2
        "My thanks, ${addressu}," ${kalt} beams, puffing out ${zhis} lean chest with pride.  "You won't regret it."
        
        *goto reinforce2
    *if el_here and not(elnope)
      #Elery Skinner.
        *if elezvad > 7
          *if elezvad = 10
            She flatly refuses, and won't hear otherwise.  "For Xthonos's sake, ${kuria}.  I'm in mourning, and in no mind to take the job that killed Zvad."
          *if elezvad < 10
            Her lips twist bitterly when you broach the topic.  "Did I not make myself sufficiently clear, ${kuria}?  I'd rather not see your face ever again.  The last thing I want is to have to talk to you every day about your Xthon'damned decisions."
          *set elnope true
          
          With a sigh, you instead choose:
          *goto dep_choice
        *goto elpicked
    #Radmar Millstone.
      When you find Radmar to tell him your decision, 
      *if poric > 0
        he's being tended by mute Poric.  The two of them just blink at you. 
      *if poric < 1
        he just blinks at you.
      "$!{kuria},
      *if not(rad_mutiny)
        no disrespect to Zvad, but I thought you'd want someone who wouldn't challenge you all that much," 
      *if (rad_mutiny)
        I led half the band in a mutiny against your half-hearted foolishness,"
      the truculent 
      *if aristo
        helot 
      *if helot
        fighter
      growls at last. "What are you thinking, asking me?"
      *if rad_mutiny
        *choice
          #"I think you're no Kryptast.  Just now, that's the most important thing."
            "First sensible thing you've said in months, ${milady}," Radmar snorts.  "Aye, then. I'll be your second."  
            
            For a moment, you wonder about the wisdom of choosing a deputy who so clearly doesn't respect you.  But you've made the decision, and you'll stick with it.
            *goto raddepyes
          #"I think you'd have the courage and will to lead the band.  And I want a chance to convince you to support my foolishness."
            Radmar snorts.  "Good luck to you, ${kuria}."
            
            "Is that acceptance?" you persist.
            
            "If it means you'll go away and let me recover?  Aye, once I'm out of these damned tents, I'll be your second.  However little I like it.  Or you."  He rolls over pointedly, pulling the canvas bedwrap over his head.
            *goto raddepyes
          #What am I thinking?  I hastily back out of the offer.
            *set r_rel -1
            *goto dep_choice
      
      "I think you won't betray me," you say soberly.  "I wish I could say that for more people."
      
      *label raddepyes
      *set deputy "Radmar"
      *set dephe "he"
      *set dephis "his"
      *set rad_lead +2
      
      *goto reinforce2
      *label elpicked
      *set deputy "Elery"
      *set dephe "she"
      *set dephis "her"
      *set el_lead +2
      "Take Zvad's place?"  She stares at you, sad, angry, and incredulous all at once.
      *if (bred_here)
        "It was Breden brought me into this.  Pick ${xhim}.  $!{xhe}'s twice the leader I am."
        *if e_rel < 2
          [i]And you are,[/i] say her eyes.
        
        "I won't have Breden as deputy," you say, quiet but firm.
      
        "Why not?" Elery demands, furious for her friend's sake.
        *choice
          #"$!{xhe} made a huge mistake, back in Rim Square."
            "Oh, and we can't make mistakes?" Elery's eyes stay afire with indignation.
            
            "I want ${xhim} to have every chance to redeem ${xhim}self before I put ${xhim} in front of the band again," you say steadily.  "Then when ${xhe} makes another mistake one day—as ${xhe} will, as we all do—the others won't take it as a sign of worthlessness and give up on ${xhim}."
            
            She pauses, seeing the sense in your words despite herself.  "You haven't given up on ${xhim}?"
            
            "Of course not."
            
            Elery seems unsure whether or not she believes you; but she grudgingly accepts the role of second-in-command.
            *page_break
            *goto reinforce2
          *if bred_lover >= 4
            #"I can't be seen to favor ${xhim} while we're lovers."
              Elery's anger slips away with a grin. "Well, fair enough, I suppose.  My being deputy is a better solution than you abandoning Breden."
              
              *goto reinforce2
          #"$!{xhe} doesn't have the qualities I'm looking for."
            "And what qualities are those?" Elery asks incredulously.
            
            "Well, for one thing, the willingness to argue that ${xhe}'s the wrong person to be my deputy," you say, smiling slightly. 
            *label toabdicate
            "Elery, this isn't about Breden.  If you turn me down, I won't choose ${xhim}.  Are you going to accept that and advise me in ${xhis} stead, or will you keep denying it?"
            
            Elery throws her hands in the air and stalks off…but later (after talking with Breden, you imagine) she returns and accepts the role with a scowl.
            *page_break
            *goto reinforce2
          *if bred_trust > 8
            #I'm fairly sure she knows it's because I don't trust ${xhim}.  I just shake my head.
              "What's wrong with you, ${kuria}?" Elery snaps, seeing the answer in your eyes.  "How can you possibly think…"
              
              "What I think and why I think it is neither here nor there," you cut in firmly.
              *goto toabdicate
      *else
        *comment if bred not here
        "You think I've learned enough from him?"
        
        "What you knew before ever you met Zvad would have been enough," you declare. "Anything you've learned from him is 
        *if aristo
          gilt on ivory."
          
          Elery 
          *if e_rel > 9
            half-smiles.
          *if e_rel < 10
            gives a grim shake of the head.
          "Xthonos, you're still every inch an aristo.  Salt for the bread, we'd say, ${kuria}."
          
          "Your first advice as my deputy?" you ask drily.
          
          "Aye, damn it.  I suppose so.
        *if helot
          salt for the bread."
          
          Elery pauses a moment, eyeing you
          *if e_rel > 9
            hesitantly.
          *if e_rel < 10
            grimly.
          "Aye, then.  I'll do it.  
        And Angels help us all."
        *page_break
        *goto reinforce2      
*label reinforce2
In the last weeks of the spring, you're heartened by the arrival of reinforcements: another twenty-odd runaway helots, petty criminals, and displaced yeomen from across the Rim. The usual recruits for the Whendward Band.  
*if (hec_cred = 9) or (hec_cred = 11)
  
  Then comes an unusual surge: another
*if (hec_cred = 9)
  forty-six
  *set followers +46
  *set nonkids +46
  *set morale +46
*if hec_cred = 11
  thirty-one
  *set followers +31
  *set nonkids +31
  *set morale +31  
*if (hec_cred = 9) or (hec_cred = 11)
  club-wielding former helots from estates across the Outer Rim.  "As soon as we heard that you'd stood up to Hector Keriatou and sent him fleeing for his life, ${addressu}, we knew we had to join you," one of them says with an admiring, angry grin. "Anyone who faces down the young aristarch bastard like that in the wild…ah, I just wish we could have been at your side and seen his swiving face."
  
Normally your pleasure at the newcomers' arrival would be balanced by your concern about having to search for spies in their midst. But while you will search, of course, your main feeling is pure relief. With the Archon sure to send an army after you by midsummer, you're in a poor position to turn down anyone.

You celebrate their arrival with another feast of venison and ale. They'll hear enough stories of hunger from the winter, and you don't want them to worry about going hungry themselves.
*set followers +23
*set nonkids +23
*set morale +23
*if addressc = ""
  Before eating, you greet the eager but still somewhat frightened-looking newcomers. "Welcome to the Whendward, my…"
  *choice
    #"Rebels!"
      *set addressc "rebels"
      *set addressm "rebel"
      *set addressf "rebel"
      *goto welcomeall
    #"Sisters and brothers!"
      *set addressc "sisters and brothers"
      *goto welcomeall
    #"Comrades!"
      *set addressc "comrades"
      *set addressm "comrade"
      *set addressf "comrade"
      *goto welcomeall
    #"Soldiers!"
      *set addressc "soldiers"
      *set addressm "soldier"
      *set addressf "soldier"
      *goto welcomeall
    *if not(choice_randomtest)
      #Actually, I've been calling my followers something else.
        You've been calling your followers:
        *input_text addressc
        Which means when you address an individual, you refer to him or her as:
        *input_text addressm
        *set addressf addressm
        So to a group, you'd say, "Welcome, ${addressc}!" and to an individual, "Welcome, ${addressm}"…
        *choice
          #That's right.
            *goto welcomeall
          #Well, I've tried that, but I don't really like the way it sounds.
            So instead you'll address a group of followers as:
            *input_text addressc
            And an individual as:
            *input_text addressm
            *set addressf addressm
            *goto welcomeall
*label welcomeall
After everyone has eaten their fill, you raise your voice above the cheery babble.  "You've joined us in time to face our greatest test together.  Welcome to the 
*if addressc != "rebels"
  rebellion, 
*if addressc = "rebels"
  uprising, 
${addressc}!"

*if religion > 0
  *page_break
*if ((natl > 74) or (natl < 26)) or ((skep > 74) or (skep < 26))  
  You also receive some more unusual volunteers.  It begins with
  *if natl < 26
    *set korszata 2
    two towering ${whend}s stepping through the door of your tent one morning.  Just as you're registering that you've never seen them before, they sweep their great cloaks aside and kneel. "$!{addressu} ${lname}: we have come to make oath to you."  Their Koine is fluent but far more thickly accented than from any other ${whend} you've heard.
    
    Blinking, you take a second look at the bright red scale mail that their genuflection has revealed. You've never seen that armor, but you've heard it described, and the silver omphalos symbol on it is unmistakable.  "Who are you, kurioi—and what are two Phalangites doing in my tent?"
    
    "I am Korszata—this is Bjel.  And we are here because we have deserted the army of faithless Karagon."  Korszata shows his bright white teeth. "In order, as I said, to make oath to you.  With our friends!"  The tent doorflap swings open to reveal another twenty or so ${whend}ish warriors, accompanied by 
    *if zvad > 0
      a somewhat embarrassed-looking Zvad.
    *if zvad <= 0
      Pitrj, who after Zvad's death has become the informal leader of your band's ${whend}ish contingent.
    
    You rise and encourage the two strapping ex-soldiers to do the same. "You're welcome to our rebellion, one and all.  And…perhaps you'd best explain."
    *page_break
    Apparently your reputation for a cosmopolitan vision that goes beyond the borders of Shayard has spread to ${whendery}—as well as your reputation for wisely leading a band made up of folk from different backgrounds and nations. Bjel informs you that the group before you comprises the most outspoken dissidents from six different clans.  Unfortunately, their common cause of glorious defiance against the Thaumatarch is only barely stronger than their long history of inter-clan squabbles. To avoid clashes and duels, they've agreed that you should be their Oath-Holder.  
    
    At their great insistence, you accept their Oath—a long string of Old Wiendzna that you don't begin to understand.  Only afterward does 
    *if zvad > 0
      Zvad twinklingly 
    *if zvad <= 0
      Pitrj stolidly
    explain that this has in essence made you the leader of a new ${whend}ish clan.  "At some point, if you live, there will be folk in Wiendwic who will want to talk with you about that.  But for now, all it means is that you can trust these warriors with your very soul."
    *if (sybla > 0) and ((deputy != "Zvad") and (zvad > 0))
      His smile soon fades, and he looks troubled.
      *fake_choice
        #Ask him what the problem is.
          "Clan loyalties can be untidy things for ${whend}s, ${addressu}."  But he'll say nothing more, save that it's his worry, not yours.
          
        #Let it go.
    *gosub lithelp
    *set followers +22
    *set literate +22
    *set nonkids +22
    *set arms +22
    *set morale +22
    *if (natl > 74) or ((skep > 74) or (skep < 26))
      *page_break
      Next comes
  *if skep > 74
    the day when your scouts inform you that what appears to be an entire village has left the Norther Rim and is moving toward you. 
    
    You send ${deputy} to meet their leaders and find out who they are and why they're coming.  ${deputy} returns and, sounding slightly bemused, explains: "They're coming to meet
    *if liebreaker
      ${fname} Lie-Breaker—the
    *if not(liebreaker)
      the 
    Great Disbeliever."
    
    Apparently your well-known skepticism has attracted a heretical community from the far-distant mountains where ${whendery} meets the Shayard Reach.  The Disbelievers have been persecuted for years by the Ecclesiasts, in part for their agnosticism about the existence of Angels, but especially for their radical insistence that to believe anything based solely on authority is a sin.  
    
    They were inspired to begin the long trek southwest when they heard (an apparently somewhat exaggerated account) of your defeat of Zebed and Chirex, spread by Theurges in the Reach, which made you sound like the epitome of sacrilegious disbelief. 
    
    Their leader Etthena is a persuasive, charismatic woman of middle years—but she's willing for now to cede to you.
    *comment came from forest mountains near Wrakehold, ca 700 mile journey, three months' travel on roads of West Laconne, Hethe, Norther Rim
    *set etthena 1
    *if religion > 19
      "You are the prophet of kenon, ${addressu}," she declares delightedly.  "As soon as I heard of it, I knew we were right to seek you out."
      *set etthena 11
    While the
    *if religion > 19
      remaining
    more traditionally devout members of your band are intensely uncomfortable with your new allies at first, Etthena's warmth wins over all but the most hard-headed.
    *if religion > 19
      And her endorsement of your new message helps to reconcile some of your followers who have remained dubious or hostile.
      *set morale +10
    *gosub lithelp
    *set followers +43
    *set literate +20
    *set nonkids +43
    *set arms +13
    *set morale +53
    *if (natl > 74) or (skep < 26)
      *page_break
      Soon afterward comes    
  *if skep < 26
    *set diakon +10
    the descent of the Diakons, twelve of the priests responsible for the spiritual welfare of the helotry.  
    
    Your reputation for devotion to the Angels as revealed in the original Shayardene Codex has drawn them to you—and they bring with them 
    *if religion < 11
      forty 
    *if religion > 10
      seventy
    more helots, all armed with steel maces liberated from a lord's armory.
    *if eclect
      All of them bow to the ground when you descend to meet them.  "Your presence honors us, ${addressu}," the oldest Diakon rasps. "Praise the Angels for sending an Eclect at last!" 
    *if diakon > 13
    
      One of the priests looks familiar.  "Weren't you…" you ask in wonder.
      
      "Aye, aye, you can tell me that you were right and I was wrong," the Diakon growls, rising from his deep bow.  "Or maybe I just came back because I couldn't keep away from your fine victuals."
      
      Your reluctant winter visitor now introduces himself as Diakon Edwer, and admits that his visit to your band sent him down a path of answering questions he'd been avoiding for some time.  While he doesn't treat you with quite the same reverence as the rest, there's still a glow of admiration behind his jests.
    *if cred_p < 140
    
      It's impossible to resist asking: "By all accounts, hieros, the Ecclesiasts loathe me and our rebellion.
      *if (theuknown >= 10)
        To say nothing of my
        *if wisard != "Goete"
          so-called
        Goety.
      How is it that you've chosen to join me?"
      
      The lead Diakon shrugs, looking uneasy.  "We've heard some things that gave us pause, ${addressu}, it's true.  But we've also been waiting all our lives for someone to take a stand on the truth of the Shayardene Codex.  How can we not join the ${woman} who finally does so?"  He gives a slight, rueful smile. "But aye…you shouldn't expect too many more to follow in our footsteps."
    *if religion > 10
      
      You wonder warily whether they've heard of your new doctrine—that any yeoman or helot can hear the voice of the Angels as truly as any priest—and what they'll make of it.  But it soon becomes clear that this is one of the things that drew them to you.  
      
      "We always knew the Angels were at work in the camps, ${addressu}," an older Diakon explains. "We've seen the least and the lowest respond to the Angels' word, saying it's what they've heard in dreams or the silence of their hearts.  We've seen the leaders guided, and the sick comforted in their last hour.  Not something we could speak about to any Ecclesiast, of course, or even to the helotry themselves.  But when we heard 
      *if helot
        it was why you rebelled,
      *if aristo
        a noble speaking it aloud, 
      well, that's what has brought so many along with us."
      *set followers +32
      *set nonkids +32
      *set arms +32
      *set morale +32
    *set literate +12
    *set followers +52
    *set nonkids +52
    *set arms +52
    *set morale +52
    *if (natl > 74)
      *page_break
      Then follows
  *if natl > 74
    the morning when twenty-six sturdy Westriding yeomen are escorted into your camp.  These are clearly not your usual hungry farmers who have fled in desperation after losing all their livelihoods.
    *if intronat and (intro_bad = 0)
    
      You have an odd feeling that you should recognize the strapping old man who strides at their head, though you never had occasion to meet many Westriding folk.  Then the leader cocks his head in an oddly theatrical pose…and you're running down the meadow to grip his hand.  "Carles?  Carles the jongler?"
      
      "Up to the Rim, to a woody vale, with oaks enough to break the gale…" Carles sings a few bars, then beams broadly down at you.  "$!{girl}, I never thought I'd have a chance to thank you for my life. And then I hear that you've gone and bearded a Theurge in the same place as that damned Alastor.  Since then, my heart's been set on a return trip."
      
      "What…how did you hear?  And who are your friends?"
      
      "I've spent the last few years telling more seditious tales in the bits of Shayard where the Alastors don't yet know me.  Plus sneaking back to a few of the rest. It's remarkable what has survived of old rebellions…these patchwork groups still holding on to their losses and long grudges."  The grinning jongler gestures at the stout fighters behind him.  "And for some, I've not just told them stories of the old days, but suggested where they might find like-minded folk to revive their tradition."
      *page_break
      *achieve carles
    You learn that each of your new warriors is a scion of those who fought and died with Ester Cabel in the Great Rising, forty-five years ago.  They have been preparing to reignite the rebellion—and now your famous passion for Shayard has drawn them to you.
    
    "They say Jac Cabel is on the move, ready to avenge his mother's betrayal," the yeomen's fiery young leader Bethune declares.  "The Alastors can't catch him, just like they can't catch you…and he's left half the Westriding tinder-dry.  But we'd not heard of anyone in the other regions who seemed more than a petty bandit—until word reached us of your vision, ${addressu}.  We're here because we believe if you survive the summer, the Rising will begin again.  And this time, all of Shayard will fight at our side!" 
    *set bethune 1
    *if intronat and (intro_bad = 0)
    
      While their strength is more than welcome, Carles's reappearance in your camp is a gift undreamed of.  That first night, after supper, he regales you all with songs and tales for hours, then calls for silence and bows in your direction. "Most of you won't know that as a 
      *if female
        lass,
      *if male
        lad,
      your Captain saved my life.  Bravely distracted the Alastors long enough for me to vanish."  He lets the applause rise and fall, then plucks a few familiar chords.  "It was part way through an old song ${he}'d requested of me.  So, with apologies for the nine years' interruption…"
      
      Carles runs through the entire Lay of Samena twice: once in Koine for the ${whend}s' benefit, then in the Shayarin you remember so well from that night in Iarla Wester's winehouse.  Not even the sight of your father's miserable face can temper the glory of hearing half your followers join Carles in singing without fear or restraint the final words:
      
      [i]Let none forget[/i]
      *line_break
      [i]What steel and majesty here wrought,[/i]
      *line_break
      [i]The foe o'erthrown, the land made new;[/i]
      *line_break
      [i]While life remains[/i]
      *line_break
      [i]Let Shayard's children face the fire[/i]
      *line_break
      [i]Unyielding, unafraid, and true[/i]
      
      Every night thereafter the old jongler performs for the band, raising their spirits and inspiring them for the battles to come.  Every day, he wanders from group to group, listening and sharing jests, knitting folk together.  "You have a new deputy," $!{deputy} comments, only half in jest.
      *set morale +20
    *set literate +9
    *set followers +26
    *set nonkids +26
    *set arms +26
    *set morale +52
*page_break
*if ruth > 75
  Over these weeks, you find that your reputation for extraordinary ruthlessness is
  *if ((natl > 74) or (natl < 26)) or ((skep > 74) or (skep < 26))  
    also
  bearing fruit.  A stream of helots and peasants come to join you, grimly encouraged by the impact of your violence to date.  Your band knows that you will do whatever it takes to destroy the Thaumatarchy, and their morale rises to new heights.
  *set morale +78
  *set followers +53
*if ruth < 25
  Over these weeks, you find that your reputation for extraordinary compassion is
  *if ((natl > 74) or (natl < 26)) or ((skep > 74) or (skep < 26))  
    also
  bearing fruit.  A stream of helots and peasants come to join you, drawn to the new order you're modeling—one with far less oppression and bloodshed.  Your band is inspired by your vision, and trusts you to protect them.  Morale rises to new heights.
  *set morale +78
  *set followers +53

*if ((natl > 74) or (natl < 26)) or ((skep > 74) or (skep < 26))  
  *if bred_here
    While the sudden arrival of so many like-minded folk leaves you delighted, you find Breden in a somber mood.  
    
    "Does it occur to you, ${addressu}, that we might have been spared this long for a reason?"  $!{xhe} turns a bleak gaze to the suddenly crowded camp.  "We've drawn the other rebels and would-be rebels across the Rim out of hiding.  We're all in one camp, one forest.  It's just what the Thaumatarchy will have wanted.  Now the blow falls."
    *fake_choice
      #My heart begins hammering against my ribs. $!{xhe}'s right.
        This is all part of the Thaumatarch's plan.  Everything you've done has surely been tried dozens of times in the centuries-long Hegemony.  They've learned how to respond, how to make the most of every revolt.  "Then we'll…we'll turn the blow as best we can," you manage.  The words sound limp and ridiculous to your own ears.
        
        "Or dodge it," Breden offers, still looking pensive. "What if the Archon were to send her Phalangites this summer and find no one here?  Because we've managed to take our message back into the Rim, back to the camps?"
        
        "Something to think on."  But you're in no mood to consider so radical an option now. When Breden sees that, ${xhe} nods apologetically and takes ${xhis} leave.
      #"If that's true, they've made a grave mistake."
        "They can't have imagined how many others would flock to our cause," you reply boldly.  "We're too many now for them to crush—especially out here in the wilds, where they can't send too great an army for long."
        
        "Angels, ${bfname}, I hope that's true."  Breden sounds more wistful than hopeful.
      #"That's nonsense," I snap. "They've not been sparing us."
        Breden recoils, looking
        *if bred_trust < 10
          hurt.
        *if bred_trust >= 10
          angry.
        "They haven't sent as many Theurges as they could have, ${bfname}.  It's been long weeks since we've seen one.  And they could have ordered all the nobles in the Rim to come after us by now."
        
        "Maybe they don't have the blood to keep the Theurges after us.  Maybe they did try to order the nobles, and everyone just pretended to follow the order."  You dismiss ${xhis} protest with a curt gesture. "Truth is, we don't know what they've tried and not tried.  I don't want the band hearing that we should despair because the Hegemony's only now about to start after us."
        
        "I'm not saying it to the band, ${bfname}.  But, Xthonos, I thought 
        *if bred_trust >= 10
          I'd best
        *if bred_trust < 10
          I could 
        say it to you."  Breden exhales raggedly and walks off.
      #"I doubt it," I say, shaking my head firmly. "Let's not think them cleverer than they are."
        "That's the way of thinking that gets people seeing Kryptasts behind every bush."
        
        Breden almost manages a smile. "You're likely right, ${bfname}.  We can surely hope so."
*page_break
The very last person to join your band that spring is the strangest and most unsettling by far.

You're camped as far west as you ever go, in a grassy vale where little streams thread between high, steep pillars of rock.  This far out, you can afford to be a bit more relaxed when it comes to campfires; you've never seen a Theurge so far from Rim Square.  From the thick greenery atop one crag, a scout suddenly gives the crane-call that warns of an incoming stranger.  

As you glance up to her, you have to shield your eyes from the sinking sun.  And it strikes you that whomever she's spied is coming from the wrong side of the camp—the side where there's nothing between you and the Ward.

Whoever's approaching isn't interested in stealth; you can hear them crashing through the undergrowth even as you stride across the camp to meet them.  But you're as unprepared as any of the guards beside you for the shadowy form that finally lurches out of the brambles—a nightmarish mix of plant and human, bent and three-limbed, with long vines trailing from its torso and thick hairy tendrils from half of its ragged-looking head.

"[i]Xaos![/i]" 
*if elery > 0
  yelps Elery,
*if elery < 1
  bellows Radmar,
leaping back; you don't think it was meant as a curse.  The creature stops and casts its head about as if sniffing the air.  Your wide-eyed scouts bring up their bows.

*if alless > 0
  It's Alless Stonehewer who cries out, "Stop—he's hurt!"  When she takes in the terrified expressions, she pleads, "It's a man—he's just a man. Don't hurt him."

"Stay your arrows," you shout to the outlaws, and then to the shadow: "Who are you?  What brings you to us?"

"Xaos," the stranger croaks, echoing
*if elery > 0
  Elery,
*if elery < 1
  Radmar,
and then topples forward like a tree.  From the low brush, you hear a dry, desperate weeping: "Mercy, oh mercy. Xaos."
*page_break
You cautiously approach, and take in a figure more human but scarcely less disturbing than your initial impressions.  He's naked and gaunt, thoroughly entangled in bramble-vines which have spilled small rivulets of blood over most of his body.  He was running forward with his right arm held over his face; his left arm is nothing but a smooth black stump, an inch long at his shoulder. Half his face is thickly bearded.  The other half is a ruin of raw cuts, bone and teeth visible through tatters of flesh.  He stares back at you, delirium in his eyes, making great, dry gasps which you take for crying.

It takes all your self-command not to flinch away from him.  "Someone fetch an Abler."
*if pin > 0
  A bleak-looking Pin Thatcher runs off at once to do so.

"$!{addressu}," Radmar growls uneasily, crouching at your side, "you actually mean to bring him into the camp?"  Like all of you, the burly youth will have grown up on dark tales of Xaos-demons crept across the Wards—blood-drinkers, soul-eaters, and child-thieves, lacking only an invitation to enter a house and devour everyone there.  And everyone knows that one consequence of being cast into Xaos is losing your soul.
*choice
  #"We don't turn away a stranger who asks our mercy." [i]Even if he is a demon, or soulless.[/i]
    *set ruth %-10
    *set morale -1
    Half of the outlaws within earshot murmur unhappily—but Radmar just exhales sharply through his nostrils and growls, "I'll 
    *label carryhimthen
    carry him, then." He turns to the broken man, speaking with unexpected gentleness.  "Hear that, stranger?  We'll get the thorn vines off you, and then I'll carry you to the Abler."
    
    "Mercy," the man whimpers, curling in on himself.  Radmar's hand hovers a reluctant inch away from him before finally closing around the man's good shoulder; with his other hand he begins to carefully pull away the brambles.
    *goto abler
  #"Not until he's well enough to satisfy me that he's nothing unnatural."
    *set morale +1
    *set ruth %+5
    Radmar nods his fervent approval, as do half the outlaws within earshot.
    *if alless < 1
      The intruder curls in on himself, sobbing incoherently.
    *if alless > 0
      But before anyone can grab at her, Alless runs up to the intruder and brings her waterskin to his lips. "He's no monster," she declares with a chiding glare.  Her hand rests, feather-light, against the remains of his face while he gulps noisily. "He's no Soulless.  He's just hurt.  Can't you see?"
      
      "I can't see his soul, girl," Radmar rumbles unhappily.  "And don't tell me you can either.  Take care."

    At length
    *if bleys > 10
      Huette Meriwether
      *set f_name "Huette"
      *set f_he "she"
      *goto arrive
    *elseif rescuer = 0
      Terret Abler  
      *goto arrive
    *else
      the bandits' healer, Algarn,
      *set f_name "Algarn"
      *goto arrive
    *label arrive
    pushes through the crowd to join you.
    *if bleys > 10
      The Telone's wife takes in the man's injuries and sniffs.  "Hmmm. Not as bad as they made it sound."
    $!{f_he} briskly checks the fallen stranger, touches the smooth, burned arm stump. "How did this happen?"  The man only whimpers, and ${f_name} shakes his head. "Let's bring him to the healing tent, ${addressu}.  I need to clean him up, inspect him.  Hopefully he'll calm down and come to himself."
    
    "Bring a tent here," you counter quietly. "You'll have what you need—but I'll not have him brought into the camp until we know more of what ails him."  You turn to the cluster of fascinated-looking outlaws around you and order them to disperse. "No one's to go near him who hasn't already.  We'll tell you what we find out."
    
    An hour later, ${f_name} emerges from the lean-to where ${f_he}'s been tending to the stranger.  $!{f_he} walks up to you and Ciels—who you've asked to stay because of ${his} experience hunting out toward the Xaos-Lands.
    *goto medreport
  #"I'll not believe in Xaos-demons till I see one, Radmar.  This is just a man, and one who needs our help."
    *set skep %+10
    *set morale -1
    *if religion > 19
      "Kenon, Radmar," you remind him.  
    "Don't let a myth frighten you."
    
    Radmar's face knots up with outrage. "Frightened?  See if I don't
    *goto carryhimthen
*label abler

*if bleys > 10
  Huette Meriwether
  *set f_name "Huette"
  *set f_he "she"
  *goto exam
*elseif rescuer = 0
  Terret Abler  
  *goto exam
*else
  The bandit healer, Algarn,
  *set f_name "Algarn"
  *goto exam
*label exam
examines the stranger with brisk interest in the healers' tent.  When ${f_he}'s finished, ${f_he} quietly beckons you and a couple of others out of the tent for a report.
*label medreport
"The arm looks burnt off, ${addressu}…but along a perfect straight cut.  As if the Thaumatarch's own chirurgeon had severed it, then cauterized the stump."

"He was caught across a Ward," Ciels interjects, ${his} expression a mix of awe and certainty.  "$!{addressu}, I've seen a Storm or two break against the Wards when I was camped out west.  I saw a tree once that had fallen across the Ward, and it was cut off flatter and smoother than anything I've seen in my life."

You're sure the others feel the same lurch of nausea that you do.  The thought of being caught in a Xaos-storm…of having your body dissolve while your very soul is stripped away by the Enemy of 
*if skepreal > 50
  Xthonos…even if you don't
  *if skepreal < 65
    think you
  believe the myth of Xaos and Xthonos any more, it
*if skepreal <= 50
  Xthonos…it 
touches a fear deeper than thought.
*if skepreal > 50
  
  "But
*if skepreal <= 50
  "Could…could that be enough to destroy his soul?"
  
  Your healer's voice is reassuringly dry. "I don't treat the soul, ${addressu}.  But for what it's worth, I never heard it lived in a man's arm.  And as for
his face…" ${f_name}'s lips twist. "Well, I'd warrant most of that was no Xaos-storm. Not unless it works with a blunt knife.  Only a few bits are burned."

You shake your head, bile hot in the back of your throat.  "$!{sweetoath}. Will he live?"

"I've done what I can, ${addressu}.  Tomorrow we'll see."

You find it hard to sleep that night, haunted by…
*fake_choice
  #Dreams of an unnameable shadow rising from the man's broken body.
  #Worries that he'll bring some plague or madness from the Xaos-lands to your band.
  #Sympathy for the stranger's hideously mauled face.
  #The inevitable Theurge and Phalangite attack coming this summer.  Today's mystery doesn't affect that.
At length you sigh, accepting that you'll get no sleep. 
*if bred_lover > 9
  Breden's eyes flutter open as you disengage from ${xhis} arms and slip out of the bedroll. "${fname}?" ${xhe} breathes drowsily.
  
  "Need some air," you whisper back.
  
  $!{xhe} shakes ${xhim}self awake, pulls a tunic over ${xhis} nakedness.  "I'll come with you."
*if k_rel = 4
  At your side, ${kalt} has also been staring up at the canvas; ${zhe} turns a weary gaze to you as you sit up. "Good idea, ${fname}.  May as well take some air."  $!{zhe} pulls a tunic over ${zhis} nakedness and straps a dagger on before stepping out.

You're not entirely surprised to find ${f_name} awake too, sitting in the moonlight outside the tent where ${f_he}'s been tending to your maimed guest. $!{f_he} scrambles up as you approach. "$!{addressu}—I thought you'd be resting, or I'd have fetched you. The fever's receding, and he's come to himself."

You
*if k_rel = 4
  and ${kalt}
*if bred_lover > 9
  and Breden
hurry into the dark enclosure and crouch next to the gaunt intruder's pallet.  The man's right eye shines, bright and bloodshot, in the flicker of a lamp-flame. The other half of his face is bound up in cataplasm-stained bandages.  You speak just loudly enough to be audible above his rapid, raspy breath.  "I'm ${addressu} ${fname} ${lname}. Who are you?  And what happened to you?"

"Thought it'd be plain, ${kuria}.  Xaos happened to me." His words are slurred by sickness and the bandage, but his broad Souther accent is clearer than it was when he first crashed out of the woods. It makes him seem a more familiar sort of stranger.  "You're…outlaws?"
*fake_choice
  #"Aye.  The Whendward Band."
    "Wish I'd known how to find you lot a year ago."  
  #"Rebels—against the Thaumatarch and all his servants."
    "Angels.  Didn't know there were any of them hidden up here."
  #"I'm more interested in knowing who you are."
    "Suppose that's understandable."
It takes a moment for you to realize that the bared teeth and grimace are his effort at a smile.  "Yed Gaverne.  Of the Southriding.  Ostler's hand, and burglar."

"How did you come to be 
*if helot
  all the way up 
here, 
*if helot
  Yed?"
*if aristo
  goodman Gaverne?"

"Blamed for murdering some noble.  Didn't do it,
*if aristo
  don't worry, ${milady},
but Alastors were after me with hounds.  If they'd have caught me…"  Yed licks his lips, ventures a shrug. "Ran straight for the Ward.  Made it across an hour or so ahead of them.  Thought I'd made it safe.  But that night, four great jackals showed up…walking upright, carrying blades. Said I could cross back, or keep moving north."

The skin crawls on the back of your neck; you've heard tales of the Abhuman werebeasts, but you'd not really known whether to believe them.  "They chased you into the Xaos-lands?"

"Heh. Don't like humans in their desert. You cross into their bit…they chase you to where the Storms start.  Or just eat you."

"And you survived the Storms."  You
*if rollover3 > 40
  think of Horion's story, and 
can't suppress a shudder—or hide your incredulity.

"Aye, survived. Kept running.  Planned to cross back, once I was far enough north that I wouldn't be known."  The stranger leans over, closes his trembling hand around the cup ${f_name} left for him.  "I've been out there a year, ${kuria}."

You stare into that bright, feverish eye.  "They say the only way to survive a day out there is to cut a deal with Xaos—to become Its tool."

"$!{kuria} ${lname}, after seeing my first Storm…if the Enemy'd shown up? I'd've cut whatever swiving deal It asked."  Yed drinks, spilling much of the ale into his matted beard.  "But I didn't have the chance.  Never saw no Enemy.  Nor've the hundreds of other folk I met out there…who you'd still recognize as human.  Least, I reckon not."
*fake_choice
  #"Hundreds?  How is that even possible?" I can't conceal my shock. No human should be able to survive Xaos, at least not without losing their soul—that's one of the key reasons given for the Wards.
  #[i]Hundreds?[/i]  My mind has already leapt to the possibility of recruiting the folk across the Ward…tough survivors, with nothing to lose.
  #What if there's a way for us to retreat across a Ward, to a haven where no Theurge or armed Phalangite could follow us?  Could I convince the band to follow me into the Xaos-lands?
Yed Gaverne clears his throat, seemingly stronger for the drink.  "Storms are worst along the Ward.  Get trapped there…break over and over until they're spent.  That's where the world goes crazy.  No one settles within ten miles of a Ward.  Or goes there at all, unless they're hoping to cross back.  

"But elsewhere…Storms roll in slow.  Skimming the surface.  You can sometimes outrun them.  And there are deep ravines and caves Storms don't touch, not directly.  Those are the villages where folk live, and farm or herd." He shrugs weakly. "The things that come out of a Storm…can find their way down.  But you dodge them, or kill them, or run faster."

"Until you don't."  You stare at him.  "Your arm—your face?"

"No, ${kuria}.  Wasn't no beast of Xaos did that."  The Southriding man closes his one visible eye for a moment. "Once a Storm has Changed you…once it's touched your flesh, you can't pass back through a Ward.  And everyone gets brushed, if not fully Changed.  If you're lucky…just leaves some bits of you looking odd.  Scales for skin, a limb stretched out but still working.  Or it might kill you, or blind you.  Turn your leg to water, turn your arm to a snake.

"I was grazed, a month back.  Turned me part tree—one arm and half my face hard as oak bark."  His hand brushes the cataplasm that ${f_name} has bound over his ruined cheek, and his voice begins to shake.  "No steel blades out there. Naught like that can get past the Wards. But sometimes Storms leave glass, or obsidian. I couldn't stay out there, ${kuria}.  I'd sooner die.  Or leave behind…whatever of me couldn't get across."
*fake_choice
  #[i]$!{oath}.[/i]  "How…how could you bring yourself to do it?"
    Yed croaks out a laugh, while tears stream from his single eye.  "Stood at the Ward a while having second thoughts.  Then saw the Storm coming.  Easy to see it would take care of…whatever of me was stuck on the wrong side when it got there.  And when you're staring a Storm in the face?  Xthonos, ${kuria}.  Xthon'damn us all.  There's nothing I wouldn't have done."
    
    After a few moments' aghast silence, Yed's breathing and speech slow down again. "So.
  #"It was truly that unbearable?"  I try to imagine what could get me to do the same.
    Yed's lips twist painfully.  "Turning a little less human…every month, every year.  What if the next time left me all tree?  No, I had to try the Ward. And Storm took care of all…that was stuck on the wrong side.
  #I just nod in grim, wordless respect for his sacrifice.
    After a few moments' silence, Yed's breathing and speech slow down again.  "Anyhow.
Got through, and started running.  Saw your camp smoke.  Took me a day to…to you." His words begin to break up, and within moments his eyelids are sagging closed again.

"Still human, I think, ${addressu}," ${f_name} says in a hushed voice. "And not mad—though Xthonos knows he's seen enough to be.  Just very ill."

You gaze out across the moonlit forest as you try to take it all in.  "We need to hear more of what he knows.  About the Abhumans…and these 'hundreds' who live in Xaos.  What it takes to survive there."
*if k_rel = 4
  
  ${kalt}'s words come slow but taut with excitement. "${fname}…if a man can live out there for a year without being eaten by the Enemy, and others live long enough to build villages and bloody farm the place…if it's just a matter of learning to dodge mindless Storms, or living with some skin turned to leather…"
  *choice
    *if helot
      #I've had the same thought. "Then…are the Wards what we've always been taught?  The only protection from Xaos, worth any sacrifice?"
        ${kalt} nods intently.  "Or is it not worth slaughtering tens of thousands of helots a year to keep them up?"  
        
        ${f_name} is staring at you both 
        *label staredisb
        in disbelief.  "Did you not hear the man?  Or see what it did to him?"
        
        "I've seen what Harrowing does to a man, too," ${kalt} snaps. "And it's a damned sight uglier than Yed's chewed-up face.  Maybe we still will need to pack the Harrowers with Karagonds and aristos…but maybe we won't.  Maybe it'll be easier for all of us to loose a few Storms and live with them."
        *label welldonts
        
        "Well, don't speak on it until we've heard more," you say slowly. "We won't be the only ones to think of it…but there's no reason to start any more folk wondering than will be anyway."
        *goto nextmornyed
    *if aristo
      #$!{zhis} implication is clear. "You're wondering if the Wards are really the only way to protect ourselves from Xaos."
        "Our whole lives, we've been told that's our highest calling, ${milady}.  Diakons every week, Ecclesiasts at the Harrowing, nobles like you with a bit of a thank-you meal at the Dark Solstice—all telling us that we're keeping up the Wards that hold the Enemy back from eating all our souls.  All telling stories about the unspeakable horrors on the other side." ${kalt} leans forward, eyes blazing. "But what if life goes on there just a little differently to here?  What if it isn't so bad that it takes tens of thousands of helot lives a year to keep it back?"
        
        "Just a little different?" ${f_name} is staring at ${kalt}
        *goto staredisb
    #I stare at ${zhim} in horror.  "$!{sweetoath}, ${kalt}.  The man was willing to scrape off half his face to get back on this side of a Ward."
      "He wasn't born a helot.  Maybe if he had been, he wouldn't have thought a bit of bark on his skin was the end of the world."  ${kalt} scowls defensively. "All I'm saying, ${addressu}, is that tens of thousands of us get slaughtered every year in the name of holding back whatever's across there.  But if it's not the Enemy's personal stalking ground, just a bit of land with some nasty magic weather…are we so sure that letting the Storms loose over here would kill anything like the same number?"
      
      "It would kill a damned sight too many," you reply with a shudder.
      *if skepreal > 50
        Even if you don't believe that the Enemy of Xthonos personally hunts the Xaos-lands, you've heard enough reports on the impact of Storms.
      "There's got to be a different way to keep the Wards up, ${kalt}."
      
      "Wish I was so sure."  The 
      *if aristo
        former helot 
      *if helot
        young former swineherd
      shrugs, still looking defiant.  "Might not need to pack the Harrowers with so many Karagonds and aristos after all, if we could just find a way to live with a few Storms."
      
      *goto nextmornyed
    #"Let's not get too far ahead of ourselves." I shake my head skeptically. "It's one thing for a few villages to be able to survive—millions of Shayardenes, quite another."
      "Fair enough, ${addressu}," ${kalt} shrugs—but ${zhis} eyes continue to burn. "It's just…our whole life, we've heard that our purpose is to keep up the wall around the Enemy's personal stalking ground.  Tens of thousands of us get slaughtered every year for it.  Now here comes old Yed, and the way he talks about it, it sounds like it's just a patch of land with some nasty magic weather."
      
      *if helot
        "Don't think it hasn't occurred to me. But like any helot knows…"  You point to the sky.
      "Doesn't take much nasty weather for the crops to fail, magic or no.  And if Shayard's crops fail,
      *if helot
        I reckon
      hundreds of thousands of people are going to die."
      
      "Fair enough," ${kalt} repeats. "Might be something we could threaten them with, anyhow.  Worth thinking more on."
      
      *goto nextmornyed
*elseif bred_lover > 9
  Glancing over at Breden, expecting ${xhis} assent, you find ${xhim} looking even more troubled than you'd expect.  "What is it?"
  
  "When the rest hear this story, ${fname}…when anyone born a helot hears about villages and farms out in the Xaos-lands, and a man living there for a year without having his soul eaten by the Enemy…"
  *choice
    *if helot
      #I've had the same thought. "They'll ask if the Wards are what we've always been taught.  The only protection from Xaos, worth any sacrifice."
        Breden nods.  "We've already got them to stop believing that their highest calling is to die for the Wards.  If it's possible to live on the far side…maybe they'll start asking if we need Wards at all."
        
        *label reallyaskthat
        ${f_name} is staring at you both in disbelief.  "And when they hear the man—and see what it did to him—you think they'll still ask that?"
        
        Breden's face is drawn.
        *if f_name = "Terret"
          "Angels, Terret, you've
        *if f_name != "Terret"
          "You're no helot, ${f_name}. I don't know if you've ever
        seen what a Harrower leaves behind.  Every bone cracked open, eyes scooped out…the sacrifice needs pain to work best, they say. I don't believe poor Yed here went through half as much agony as any one of the helots who get Harrowed round the Hegemony every day."  $!{xhe} shrugs.  "I don't want to live with Xaos-storms, either…but then, I'd never even thought it was possible until today.  Is it worth bleeding someone else to keep the Wards up, or should we be looking for a way to do without them altogether?"
        *goto welldonts
    *if aristo
      #$!{xhis} implication is clear. "They'll wonder if the Wards are really the only way to protect ourselves from Xaos."
        "Our whole lives, we've been told it's our highest calling, ${fname}—to keep up the Wards that hold the Enemy back from eating all our souls.  We've already got our folk believing that they don't have to be the ones to die.  Now seeing Yed here, and hearing his tale…" Breden shakes ${xhis} head. "Is the Enemy of Xthonos really hunting on the other side of the Ward?  Or are there just Storms which can be dodged or survived—which even allow for some sort of normal life?"
        
        "Normal?"
        *goto reallyaskthat
    #I stare at ${xhim} in horror.  "$!{sweetoath}, Breden.  The man was willing to scrape off half his face to get back on this side of a Ward."
      Breden's voice is steady. "I've seen helots who've done more or less the same to escape their masters, ${fname}.  Maybe if Yed had been born one of us, he'd not have found the other side so unbearable."

      *if aristo
        "I can't imagine anyone…" you exclaim.
        
        "No, you likely can't, 
        *if male
          milord." 
        *if female
          milady." 
        Breden leans forward.
      *if helot
        "Sounds bad enough to me," you say incredulously.
        
        "Didn't the Keriatou estate feed you the same stories we heard out east, ${fname}?" Your lover leans forward.
      *label alwtold
      "We were always told that the Enemy of Xthonos stalked the far side of the Ward.  That's what the Diakons told us our sacrifice was for—that in Its wisdom Xthonos chose lowly souls like us to achieve glory by holding back Xaos.  Now Yed tells us that maybe it's just the Storms over there, and they're only really bad along the Ward.  You can't see how some folk would think that we might be able to just let the Wards go?"
      
      You still find it hard not to shudder when thinking about it.  "Let's not start any conversations ourselves until we know more.  It might be that next time Yed speaks, he'll tell us why it's impossible."
      *goto nextmornyed
    #"Even if a few villages are able to survive, surely they wouldn't expect a Shayard wracked by Xaos to be livable."
      Breden inclines ${xhis} head doubtfully. "A minute ago, I didn't think Xaos-storms were survivable for anyone but demons.  Who's to say what's possible?"
      
      "It's one thing to keep a few scattered villages alive.  But the great farms that feed hundreds of thousands across Shayard…you think those would survive a Xaos-storm?"
      
      "A good question.  Important for folk to ask it.  But they'll be seeing the whole thing through different eyes, once they've had a chance to think about Yed's tale."  Your lover leans forward.
      *goto alwtold
*elseif helot
  *choice
    #It's survivable.  That undercuts everything the Diakons told us about why the Wards are needed.
      Over and over in your childhood, you heard the same refrain: you are called to sacrifice yourselves to protect all humanity from Xaos, the Enemy of Xthonos, whose power is unchecked in the Xaos-lands.  This is the helotry's glory and highest purpose.
      *if introrel
        You can still hear Ecclesiast Olynna's sympathetic voice explaining it to you and the other helot children before you witnessed your first Harrowing.
      Tens of thousands of helots die every year because of this story.

      If it's not true—if the lands beyond the Wards are hostile but inhabitable, rather than stalked by an Enemy that hunts you down to consume your soul—is it conceivable that you could live without the Xaos-Ward?  Are the hardships and horrors Yed describes really worse than the ones you grew up with?
      *goto nextmornyed
    #I'm sure that others will think that—and it horrifies me.  [i]Of course[/i] we need to keep the Wards up.
      Perhaps Xaos is more survivable than you've always been told; perhaps it's just a landscape of mindless Storms rather than an Enemy purposefully hunting you to consume your souls.  None of that changes the fact that Yed Gaverne was willing to scrape off half his face to get back on this side of the Ward.  
      
      *goto nextmornyed
*else
  *goto nextmornyed
*label nextmornyed

In the morning you explain to the band what you know of Yed's travels—and that he'll be staying with you until he's recovered and you can hear more of his story.  One or two people look a bit nervous, but for the most part your outlaws agree and accept Yed as a successful escapee from Xaos rather than a suspected envoy.
*if (natl > 74) and (intronat and (intro_bad = 0))
  *page_break
  Afterwards, Carles finds you alone in the Leaders' Tent and claps you on the back jovially.  "You're a lodestone for tales, my Captain. 'The man who came back from Xaos.' We'll see if anyone believes it, out in the civilized world."
  
  It takes a moment for you to grasp his implication.  "Wait—you're leaving?"
  
  "The road's calling, ${girl}, and no jongler can resist that sweet voice.  I've tales to tell in the lowlands."  He winks, offers a rueful smile.  "I'll try to send a few more strong yeomen your way. Assuming you survive the summer."
  
  That's all well and good, but no one can inspire your followers like Carles—and you suspect you're going to need morale as strong as it can be when the Hegemony finally comes for you.
  *choice
    #I try to convince him to stay.  He can do more good here, encouraging the band and sharing his knowledge.
      *label convincecarles
      You grip his shoulder imploringly.  "Carles…this is the reality behind the stories you tell.  This is how we'll truly see the ancient liberties of Shayard restored.  And you want to go spin more tales of Katta-kack?"
      
      Mild-faced, the old jongler scratches at a grizzled cheek.  "You seem to have taken a lot from those tales, ${kuria} ${fname}."
      
      "When I was a child!" you counter with some heat.  "We don't need any more children than we've already got.  We need your skills here."
      
      "None of my tales were for children," Carles says patiently.  "Here's counsel, ${kuria}, though you'll think it folly.  A tale is how you get a truth into someone.  And if they fear that truth, you may have to smuggle it into their ears.  So make it a nurse-tale, or a parable; tell it aslant, with nonsense-words.  That'll plant the truth deeper than they know, and it'll take root unseen."  He claps a hand on your shoulder.  "And you'll know it when you see them joining you.  This is how I'll help you best."
      *goto horfate
    #Maybe he'd do more good recruiting for us on the road—but I still want him to stay.
      *goto convincecarles
    #I let him go.  We need the people he'll send us more than we need his encouragement here.
      "Very well."  You sigh and reluctantly return his clap to the shoulder.  "But don't 
      *goto stayaway
    #He's free to come and go as he pleases; I send him off with my blessing and gratitude.
      After you've finished thanking Carles, you embrace him and return his clap to the shoulder.  "Don't
      *label stayaway
      stay away too long.  The evenings will feel empty without your song."
      
      "No fear, Captain.  Saving my life is worth at least three performances of the Shayarin Samena."  Carles grins.  "I'll be back for the others."
      *goto horfate
*label horfate
*if simz_here and simzacc
  *page_break
  The appearance of Yed Gaverne presents you with a long-awaited opportunity.  After dispatching the other rangers on credible tasks, you ask ${simon} de Firiac if ${zhe}'ll accompany you some ways along the man's backtrail to confirm that he's no spy from the Rim.  "With Ciels and Alira out, you're the finest tracker we have left, ${zkuria}—and I know you won't fear approaching a Ward."
  
  ${simon} nods at once.  The two of you follow Yed's trail for two hours, mostly in silence, into a craggy waste that must be halfway back to Xaos.  Then the de Firiac says quietly, "You've brought me here to kill me."
  
  Your guts knot up at once.  You'd counted on ${simon}'s honor blinding ${zhim} to your purpose; confronting a blademaster alone in the wild was never part of the plan.  "Don't speak such madness, ${simon}."
  
  Tears stream down ${simon}'s face.  "I saw it in your eyes, ${addressu}.  When I raised my voice against yours in the Brecks.  Why else are we here alone?"  $!{zhe} breaks and runs into the underbrush.  You follow, cursing and yelling for ${zhim} to come back.
  
  But ${zhe}'s not fleeing you.  The bushes open onto a precipice; far below, a rain-swollen Whendward stream churns in its gorge.  Turning to you, ${simon} de Firiac tosses ${zhis} weapon aside and lets ${zhis} arms fall to ${zhis} sides.  "Be swift, ${addressu}.  I'll not raise my hand against the leader of the rebellion.  But I was a fool to think it had a place for me."
  *choice
    #I push ${zhim} from the cliff.
      *set violence +1
      *if (s_rel = 5) or (s_rel = 6)
        Or rather, you try.  
        
        An instant before your palm lands on ${simon}'s shoulder, ${zhe} seizes your wrist and whirls away, pulling you forward.  You yelp in shock, flail desperately to catch ${zhim} and steady yourself…but ${zhe}'s already released you, and there's nothing there where ${zhis} body should be. 
        
        You hear the bleak final whisper from somewhere just beyond reach: "Goodbye, monster."  Then there's only the lurch, the air whipping past you, the fast-approaching boulders and white water.
        *goto_scene death
      *set ruthreal %+10
      You've never seen surprise and despair so clearly writ together on a human face.  To the end, ${zhe}'d hoped ${zhe} was wrong, even while knowing ${zhe} wasn't.  
      
      ${simon}'s arms flail out just after your vehement hands have left ${zhis} chest—far too late to catch anything.  $!{zhis} scream as ${zhe} topples into the gorge is shattering but brief.
      
      When you race back into camp and give the news, a good dozen outlaws insist on setting out at once to find the de Firiac.  It's dusk by the time you find ${zhis} body, battered almost beyond recognition by the fall and the rapids.  Perhaps one or two others from the Breckland raid saw then what ${simon} saw in your eyes; but most see only your tears over ${simon}'s corpse, and no whispers of suspicion ever reaches your ears.
      *set simz_here false
      *set s_rel -50
      *set followers -1
      *set nonkids -1
      *set dead +1
      *goto twodays
    #$!{zhe}'s not sincere.  This is a trap.  I insist that ${zhe}'s wrong.
      You proffer a hand slowly, fingers outstretched—but ready to be snatched back at once if ${zhe} actually tries to grab you. "${zkuria} ${simon}…come back from there before you fall.  I was angry, it's true.  But I'm not the monster you think me, nor half as great a fool.  We need you in the rebellion."
      
      The young noble's face remains bleak and tremorous.  "If you're going to kill me, ${addressu}, kill me now."
      
      "Damn it all, de Firiac.  Take your weapon and strike me down, if this is how much trust you have in me."  Your lips twist with genuine bitterness.  "Or if you intend to keep undermining me as you did in the Brecks.  Better to kill me than disobey me.  It'll come to the same thing in the end."
      
      Slowly, ${simon} steps away from the edge, looking if anything more desolate. "Better to kill me than ask me to embrace dishonor, ${addressu}."
      
      "I'm not going to swiving kill you," you growl, also stepping warily back.  [i]Not today.[/i]  "I can't stop you jumping off a cliff.  But don't ask me to push you."
      *goto twodays
    #Shame sweeps over me.  How could I have planned this for one of my most loyal followers?
      You slowly proffer a hand, fingers outstretched to ${zhim}.  "No, ${simon}.  I was angry, it's true—but if my anger drove you to this, I'm the fool.  The rebellion needs you."
      
      The young noble blinks rapidly, still trembling. "Does it need someone to oppose you when you're in the wrong, ${addressu}?  Or just a blademaster?"
      
      "Both." You grimace but keep your hand extended. "You're wrong more often than you think, de Firiac.  But I know you're loyal, and I'd not lose that…however much trouble you stir up with your precious honor."
      
      After a moment's swaying, ${simon} leaves the edge and walks up to you, still ignoring ${zhis} fallen weapon.  "Better to kill me than ask me to give up my honor, ${addressu}."
      
      "Believe me, I'll keep it in mind," you say testily, then gesture back through the brush. "Now.  Do you think we've followed the trail back far enough to believe that our friend crossed a Ward?"
      
      ${simon} nods, managing a smile.  "Aye, I think we've gone far enough, ${addressu}."
      *goto twodays
*label twodays
*page_break
Two days after Yed's arrival
*if (natl > 70) and (intronat and (intro_bad = 0))
  and Carles's departure,
*if rollover4 or slain
  news
*if not(rollover4) and not(slain)
  a rumor 
reaches you from
*if (alaine > 0) and (protection != 1)
  your fence, Alaine Leybridge.
*if (alaine <= 0) or ((alaine > 0) and (protection = 1))
  Cacelon, one of your more reliable fences.
*if rescuer = 0
  Gillian Adze, returning with a lone mule,
*if rescuer > 0
  The bandit who brings it
*if horion < 1
  *if not(rollover4) and not(slain)
    shakes her head.  
    *if horion < 0
      "Odd 
    *if horion = 0
      "There's a
    story going about in the Rim, ${addressu}.  They say some cousin of Conte Phrygia has disappeared…and the last place that this kurios Horion Leilatou was seen was in some village a few miles south of Rim Square."
    
    *if horion < 0
      You try to hide your shock as your mind leaps to the strangers ${rollover5} killed in the Whendward Pass. 
    *if horion = 0
      You nod grimly, unsurprised that the word has crept out.
    "Anyone saying that we had anything to do with it?"
    
    "Folk are wondering.  But the Alastors and aristarchs haven't said anything, so the rumor's still just feathers on the breeze."
    *choice
      #Good.  We're not ready to become the Archon's top military priority.
        With
        *if horion < 0
          this
        Horion Leilatou buried under some unknown heap of rocks in the wilderness, there should never be any evidence linking you to the death.  
        
        *goto traitorcheck
      #I send a night message taking credit for the Leilatou's death.
        *if (simz_here) and (s_rel < 9)
          When ${simon} de Firiac hears about it, ${zhe} confronts you, aghast.  "$!{addressu}! How could you? You've just ensured that the Archon will send force sufficient to destroy us.  With her cousin dead at our hands, she can do no other."
          *goto widelyknownw
        *else
          When the news is widely known, your father bursts in on you, white-eyed with outrage. "You idiot ${girl}—what are you thinking?  You've just ensured that Conte Phrygia will throw everything she has against us."
          *goto widelyknownw
        *label widelyknownw
        
        "And I've also ensured that our name will be known all through the realm."  You're becoming accustomed to that nervous flutter in your ribs.  "When it's widely known that we did it—that we were able to strike at her own cousin?  It 
        *label drawfence
        will draw others off the fence.  Who else has done so much, dared so much?  It gives other would-be rebels their best reason yet to join us."
        *page_break
        *set anarchy +7
        *set cred_a -30
        *set cred_p -20
        *if aristo
          *set cred_h +20
          *set cred_y +20
        *set notoriety +40
        *page_break
        *goto traitorcheck
  *if slain
    shakes her head grimly.  "Well, everyone's talking about Horion Leilatou across the Rim."
    
    "That was why we killed him," you point out.
    *goto aye
  *if rollover4
    *if horion < 0
      looks drawn and fearful. "$!{addressu}…that noble we killed and left at the crossroad?  He was from House Leilatou.  A cousin of Conte Phrygia."
      
      "What?"  You gape at her for a moment.  The last three governors of Shayard have come from the Leilatou family; you'd never have imagined finding one this far from the Southriding.  "How…what by ${oath} was a Leilatou doing in our woods?"
      
      "There are rumors saying everything—that he was trying to join us, that he was hunting us, that he was sneaking off to Whendery for some reason or other."  Her voice quavers. "But 
      *label everyonesays
      everyone says that the Archon will be doubling the troops she sends after us, to be sure her cousin is avenged."
      
      *if not(slain)
        Shaking off your shock, you 
      *if slain
        You
      do your best to fill your voice with confident satisfaction.  "She'd always have sent as many troops as she thought it would take to destroy us.  But this…this
      *goto drawfence
    *else
      *if horion > 0
        *bug undead horion, should be 0
      sounds tense and unhappy.  "They found the body of that Leilatou we left at the crossroads, ${addressu}."
      
      "That was why we left him there."
      *label aye
      
      "Aye, 
      *if (rescuer = 0) and helot
        baiting the Harrower as ever." Gillian purses her lips, as disapproving as if you were still a thirteen year-old Keriatou helot. "It was folly, young ${lname},
      and now
      *goto everyonesays
  *else
    *bug drop out of choice
*elseif horion < 10
  hails you from the bottom of the meadow.  "Word has got out that we're holding
  *if delelle = "de Lelle"
    milord Horion for ransom, ${addressu}."  
    
    You take the quaver in her voice for breathlessness—until she gets close enough for you to see how rapidly she's blinking.  "What is it?"
    
    "They didn't call him 'de Lelle,' ${addressu}.  Horion [i]Leilatou[/i], they said.  The Archon's own bloody cousin."
    
    For a moment, you can do nothing but gape at her.  The last three governors of Shayard have come from the Leilatou family.  You'd never have imagined finding one this far from the Southriding.  "Do they say what by ${oath} a Leilatou would be doing in our woods?"
    
    The rumors from the Rim offer no illumination, and when you confront your haggard-looking hostage a few minutes later, he's scarcely more helpful. "I was trying to reach ${whendery} to argue philosophy with the Pan of Szeric, ${addressu}.  All I've told you is true, save only my unfortunate family name.  And surely you understand my desire to travel a bit more quietly than the name would allow."
    
    "Quietly, kurios?"  Anger throbs in your throat at the man's morose uselessness.  "They say every noble west of Rimmersford is competing to offer help in rescuing poor Horion Leilatou.  And that Conte Phrygia has vowed to double the troops she sends after us this summer."
    
    If Horion is frightened at your rage, his despair hides it entirely.  "You'd truly have acted differently if you'd known you had a chance at ransoming the Archon's cousin, ${kuria}?  The de Lelles would never have paid to redeem a family member.  The Leilatou might."  Then he lapses into near-silence, refusing to be drawn into further conversation.
    *goto kidnapstats
  the Archon's cousin 
  *if (horion = 2) or ((horion = 8) or (horion = 9))
    hostage.
    *goto rimmersroar
  *else 
    for ransom.
    *goto rimmersroar
  *label rimmersroar
  They say all Rimmerford is in an uproar."
  
  "Grand Shayard too, I'd hope," you retort mildly.  You've never 
  *if aristo
    even been 
  *if helot
    imagined traveling
  to the Rim's foremost city, let alone the archonty's capital; for a moment, you savor the idea of both great cities thrown into chaos by your choices out here in the wild.
  
  "Can't speak for the City, but sounds as if every noble in the Rim is competing to offer help in rescuing poor Horion Leilatou.  We should have a good-sized horde descending on us when they finally come this summer."
  
  *if aristo
    "I'd be surprised if the Archon wanted too many backcountry nobles and their retainers getting in the way of her Phalangites." 
  *if helot
    "Nobles tend to promise a lot more than they actually do."
  You keep your voice cheery, aware of the rest of the band pausing in their work around you.  
  *if (horion > 3) and (horion < 8)
    "Any suggestion that Conte Phrygia intends to pay?"
  
    *if rescuer = 0
      Gillian
    *if rescuer > 0
      The bandit
    shakes her head skeptically.  "Nothing."
  *label kidnapstats
  *page_break
  *set anarchy +2
  *set cred_a -20
  *set cred_p -10
  *if aristo
    *set cred_h +10
    *set cred_y +10
  *set notoriety +20
  *goto traitorcheck
*else
  looks troubled. "$!{addressu}…they're saying that the Archon's cousin has been found dead in the forests on the far side of the Whendward Pass."
  
  *if horion < 12
    At first, the idea is too bizarre to take seriously.  "What, the Archon of Shayard?  What would any Leilatou be doing out here?"
    
    "Traveling with some priest friend of his, from the sounds of it."  She nods at your dawning comprehension.  "Aye, ${addressu}…from the way they're described, it sounds like 
    *if horion = 11
      our friend kurios 'de Lelle.' Who'd have guessed?"
    *if horion = 10
      the two strangers ${rollover5} let travel across the pass."

    *if s_rel = 9
      *gosub anddefir
    "How did they die?" 
    *if s_rel != 9
      you demand.
    *if horion = 11
      You're still reeling from the idea that anyone of House Leilatou would pass through your hands without you realizing it.
  *if horion >= 12
    "What?" you gasp.  It's been less than four weeks since 
    *if horion > 12
      Horion and Linos left you—a
    *if horion = 12
      you allowed the two strangers to cross the pass—a 
    short time for them to be found in the wilds and news to get around the Rim.
    *if s_rel = 9
      *gosub anddefir
    "How did they die?"
  
  "Filled with arrows.  Everyone's saying it was the Whendward bandits that did it."  You can see doubt in her eyes, and in the others around the circle.
  
  "We didn't," you insist.  "$!{oath}, 
  *if horion > 12
    I'd have killed them here if I'd meant to do them harm."
  *if horion = 12
    I'd have killed them in the pass if I'd meant to do them harm."
  *if (horion = 11) or (horion = 10)
    you can see I'd no idea who they were."
  *if (int > 0) and (horion > 12)
    It takes a moment for the explanation to sink in. "His enemies.  They…they must have known he was going to Szeric.  Perhaps they thought we would do their work for them.  Regardless, they must have been waiting just on the other side."
  
  *if rescuer = 0
    Gillian shrugs,
  *if rescuer > 0
    The bandit nods, 
  looking fretful.  "That's as may be.  But everyone says that the Archon's promised to double the troops she sends after us, to be sure her cousin is avenged.  And the nobles all across the Rim are competing to offer their guards to hunt us down."

  *if aristo
    "Well, I'd be surprised if the Archon wanted too many backcountry nobles and their retainers getting in the way of her Phalangites." 
  *if helot
    "Nobles tend to promise a lot more than they actually do."
  You try to present a mask of confidence rather than the shock and dismay you feel.  "Conte Phrygia was always going to send as many troops as she thought it would take to destroy us.  We just need to be sure we're ready for them—the same as if we'd never heard of this Leilatou."
  *set anarchy +7
  *set cred_a -30
  *set cred_p -20
  *if aristo
    *set cred_h +20
    *set cred_y +20
  *set notoriety +40
  *choice
    #I do my best to counter the rumors that we're responsible.
      There's little you say that anyone will believe—even 
      *if (int > 0) and (horion > 12)
        when you try to spread evidence of a conspiracy by Horion's enemies in Grand Shayard.  Your contacts in the Rim don't really know enough about Court politics to speak credibly on the matter;
      your fences are politely incredulous when you ask them to find ways to counter the rumors.  But your efforts may persuade a few people to see 
      *if horion > 12
        Horion's 
      *if horion <= 12
        the traveling noble's
      death as a mystery rather than your doing.
      
      *set anarchy -2
      *set notoriety -5
      *set cred_h -10
      *set cred_y -10
      *set cred_a +5
      *goto traitorcheck
    #I have a bloodcurdling night message left outside several noble estates and temples, accepting responsibility for the killing.  If we're to be blamed, might as well be feared.
      *set ruth %+5
      *set anarchy +2
      *set notoriety +5
      *goto traitorcheck
    #I don't try to interfere with the rumors one way or the other.
      *goto traitorcheck
*label anddefir
"And the de Firiac?"
      
"Didn't hear anyone speaking of ${zhim} at all.  Course, I didn't ask—didn't want to get anyone thinking ${zhe} wasn't still with us."
      
"Wise choice."  You shake your head, trying to understand.
*return

*label traitorcheck
*if (rescuer = 0) and not(nohunt)
  Over the course of the spring, you've given almost every suspect from Rim Square some opportunity to betray you.  Each one has been on some run out into the Rim, where they were allowed a chance to sneak off and convey what they know to an Alastor.  
  
  To all appearances, no one has taken that opportunity.
  *if (radmar < 2) or (radmar > 3)
    Certainly not big Radmar, who's now gone on several successful missions to the Rim.
  *fake_choice
    #But I think whoever betrayed us to Chirex is still with us, just lying low.
    *if not(bred_here)
      #It just makes it all the clearer that it was Breden.
    *if ((bred_trust = 2) or (bred_trust = 3)) and (bred_here)
      #I can't help wondering whether I was wrong to trust Breden after all.
    *if (bred_trust = 4) and (bred_here)
      #I wish we'd arranged to test Breden.
    *if (radmar = 2)
      #I knew we should have tested Radmar.
    #Perhaps the traitor didn't survive our months in the wilderness after all.
    #Is it thinkable that the capture of Breden's gang truly was just a coincidence?
  *if bred_here and ((bred_trust > 4) or (bred_trust < 2))
    Of course, no final judgment can be possible until you see whether Breden takes the opportunity to betray your future camp location to the Hegemony.  It's hard to imagine any traitor swallowing information that might allow a Theurge to wipe out the whole rebellion with one ambush.
    
    You 
    *if zv_here
      and Zvad have been conspiring 
    *if not(zv_here)
      had planned with Zvad for
    for weeks to set the snare, and
    *if not(zv_here)
      despite the big ${whend}'s death,
    the opportunity has finally come.  Breden has agreed to take a few days to go to a helot encampment and stir up word of the rebellion.  It may be the last chance ${xhe}'ll get to visit the Rim before the Archon sends her troops after you.
    
    *if not(zv_here)
      No one leaving the wilderness for Hegemonic territory is allowed to know the location of the band's next 
      *if deputy = "Breden"
        camp—not even you or your deputy.
      *if deputy != "Breden"
        camp, of course.
      But shortly before Breden leaves, you let slip with ${xhim} in earshot that you'll all soon be at 
      *if (rescuer = 0)
        Corras's 
      *if (rescuer != 0)
        Charen's 
      Cave, a destination it would take a good ten days to reach.  A Rim-bound traitor could easily ensure that there are Theurges there before the band arrives.  Breden gives no sign of having heard you, but you don't see how ${xhe} could have missed it.
      
      You don't bring the band to 
      *if (rescuer = 0)
        Corras's 
      *if (rescuer != 0)
        Charen's 
      Cave, of course, just a handful of your most discreet rangers.  They return two and a half weeks later, just before Breden ${xhim}self comes back from the Rim. "Saw no one and nothing save a few foxes, ${addressu}," Alira reports quietly to you. "No Theurges in the sky, no scouts on the ground.  If you heard anyone was meant to be sniffing around there, they must have changed their minds."
      *choice
        #Well, that exonerates Breden.
          *if bred_trust < 9
            It feels like releasing a breath that you've been holding for months.  If the Rim Square traitor is still alive, at least you've good reason to think it's not your
            *if bred_lover >= 4
              lover.
              
              *goto dad
            *elseif deputy = "Breden"
              deputy.
              
              *goto dad
            *else
              band's most charismatic young leader.
              
              *goto dad
          *else
            You could continue to distrust ${xhim}, of course—but at some point, surely, you have to accept the growing likelihood of ${xhis} innocence. $!{xhe}'s had ample chances to betray you and not taken them, including this last hard-to-resist one.  It will take some time to truly feel in your heart that you trust ${xhim}, but in your mind, at least, the question is closed.
            *set bred_trust 5
            
            *goto dad
        #Perhaps after all Breden just didn't hear me, or understand what ${xhe}'d heard.
          Were you too subtle after all?  There's no way to know for sure, of course.  The absence of an attack proves nothing, and never could have.
          
          *goto dad
        #$!{xhe} surely heard me, but saw through the trap and chose not to take it.
          There's no proof, nor any chance of getting it now.  But in your heart you're sure ${xhe} heard you and understood your purpose.
          
          *goto dad
        #Damn it all, I don't know what to think.
          *goto dad  
    On the morning of ${xhis} departure, however, Breden beckons you aside, ${xhis} brows low over troubled eyes. "$!{bfname}…when Zvad and I put our heads together to name a rendezvous point, he let something else slip.  Or I think he did, at any rate.  Were you planning to have the whole band camped back in 
    *if (rescuer = 0)
      Corras's 
    *if (rescuer != 0)
      Charen's 
    Cave in a week's time?"
    
    You can only hope ${xhe} doesn't correctly interpret the frustration on your face.  "Well, we're not now.  I can promise you that."  
    *if deputy = "Breden"
      No one leaving the wilderness for Hegemonic territory is allowed to know the location of the band's next camp—not even you or your deputy.
    
    "Angels, ${bfname}." Breden speaks in a near-whisper, but is plainly struggling to keep from shouting. "Zvad needs to guard his damned tongue.  Could there be a worse time to slip than with someone heading back into the Rim?" $!{xhis} dark eyes hold yours 
    *if bred_trust > 9
      grimly,
    *if bred_trust < 10
      steadily,
    alight with a fury you fear you understand.
    
    "He'll plead your pardon on your return."  You do your best not to blink or look askance.  "Believe me, I'll see to it."
    
    After a moment, Breden steps away, still scowling.  "No need for that.  Just so long as
    *if male
      he doesn't 
    *if female
      she—I mean, he—doesn't 
    [i]bloody[/i] do it again."
    *page_break
    *goto dad
  *if radmar = 3
    Of course, no final judgment can be possible until you see whether Radmar betrays your future camp location to the Hegemony.  The raids he's led in the Rim might conceivably have been opportunities he passed up to build trust.  But it's hard to imagine any traitor swallowing information that might allow a Theurge to wipe out the whole rebellion with one ambush.
    
    You and Zvad have been conspiring for weeks to set the snare, and the opportunity has finally come.  Radmar has agreed to take a few days to go to a helot encampment and stir up word of the rebellion.  It may be the last chance he'll get to visit the Rim before the Archon sends her troops after you.
    
    After Radmar sets off, Zvad finds you in your tent.  "I let it slip while we were talking about rendezvous points.  A word or two about 
    *if (rescuer = 0)
      Corras's 
    *if (rescuer != 0)
      Charen's 
    And I reckon he took my meaning, ${addressu}."
    
    No enemy comes anywhere near 
    *if (rescuer = 0)
      Corras's 
    *if (rescuer != 0)
      Charen's 
    Cave at the end of the week.  The scouts you left there return a day or two after Radmar does, having seen nothing but jackals.
    *fake_choice
      #That rules out Radmar.
      #Perhaps Zvad was too subtle.  Radmar might not have taken the hint.
      #I should never have included Radmar in the traitor hunt.  It alerted him to the trap.
    Regardless, it's too late now to arrange another snare.  Like it or not, you're coming into the summer with no traitor caught.
    *goto dad
  You can't know for sure.  It's maddening to have put so much effort into your snares, only for all of them to come up empty.
  *if zvad > 0
    
    "We'll just keep half an eye on them all, ${addressu}," Zvad replies when you vent your frustration to him. "Sooner or later the Thaumatarchy will get its spies in.  We have to assume it."
  
    You shake your head, feeling sick. "No chance at a band we can trust?"
  
    "A whole band?  If you find five or six you know you can trust, that's a treasure, ${addressu}."  Zvad chuckles bleakly.  "Maybe you think you have that already.  If so, make the most of it."
  *page_break
  *goto dad
*label dad
A week before your twentieth birthday, the great rupture finally comes.
*if helot
  
  You've been noticing odd looks and murmurs from some of the new arrivals, but you've not had the time to follow up on them.  To be honest, you'd not thought much of them at all until the day
  *if (bred_here) and (bred_heart < 10)
    Breden
    *goto dadwhat
  *elseif (kal_here and (k_rel < 6))
    *set g_he zhe
    *set g_his zhis
    *set g_name kalt
    ${kalt}
    *goto dadwhat
  *else
    Radmar
    *set g_he "he"
    *set g_his "his"
    *set g_name "Radmar"
    *goto dadwhat
  *label dadwhat
  takes you aside, frowning.  "A moment,
  *if ((g_name = "Radmar") or (bred_lover < 3)) or ((g_name = kalt) and (k_rel != 4))
    ${addressu}
  ${fname}.  You hear anything odd from the last helot gang to join us?"
  
  "I reckoned a few of them had been giving me a strange eye."
  
  "Aye, I'd seen the same." $!{g_he} breathes out through ${g_his} teeth, looking uncomfortable.  "They'd heard the ${lname} name before they'd heard of you.  But they'd not heard any family name for '${addressu} ${fname}' until they got here…and now they're afraid, and they're saying things that need answering."  
  
  "I don't understand."
  
  *if ((bred_lover >= 4) or (bred_heart = 3)) and ((bred_trust < 9) and (g_name = "Breden"))
    "Love…"  Breden rubs ${xhis} forehead worriedly.
  "I think you need to speak with them."
  *if g_name = kalt
    ${kalt}'s eyes are suddenly hard. "And not only with them."
  *if (g_name = "Radmar") and (r_rel < 2)
    Radmar's expression is dark, foreboding. "And then share some answers with the rest of us."
  *page_break
  After supper, with your stomach still twisted in knots from the afternoon's conversation, you beckon your father out of the familiar cluster of his old t'Keriatou plow-mates.  He follows you with a tolerant, almost good-natured smile on his face. "What do you want, ${girl}?  Some new victory you want to tell me about—convince me we've a chance after all?"
  
  You round on him as soon as you think you're out of the band's earshot.  "You remember Aryn Weller?"
  
  "Do I…what?"  His face is suddenly flinty in the red twilight.  "What are you on about, then?"
  
  "Aryn Weller t'Keriatou.  Caught practicing the bow…convicted of being a poacher and rebel.  Had her hands and feet cut off and eyes put out, before she was locked up for a month to wait for the next Harrowing.  Her man was Harrowed too, and her children sold away from Rim Square."
  
  "I remember her, aye.  You're too damn young to know a thing about it.  So why are you asking me now?"
  
  The looks you'd got from the recently arrived men are still eating at you…as if no one could believe you'd never heard the allegations, never even suspected.  "Two of her grown children just joined the band.  And they claim ${lname} is the name of the man who betrayed their mother to the Alastors."  You try to remember the times you met with Breden, back in Rim Square.  Could your father ever have been there—ever have followed you?  Surely there was no way for him to have known the names of so many of the youth who attended those meetings.
  
  Your father takes a step back, draws himself up to his full height.  His voice quavers as he demands, "Now, you take care, ${girl}.  You just take good Xthon'damned care how you talk to me, and what you think you're saying."
  *fake_choice
    #"What do you think I'm saying?"
      He spits loudly onto the pine needles.  "Nothing but what every helot who reaches forty years gets to hear.  As long as their luck holds.  
      *if rescuer = 0
        Ask Hetten, ask Gillian, ask your precious bloody Joana Orchard.  
      Every elder has to live with those mucking whispers."
      
      "And none of them true," you say, as levelly as you can manage.  "No one ever found a way to stay alive by…making themselves useful."
      
      "I don't know a damned thing about that," your father snarls, still wide-eyed and off-balance.  "I'm not one to toss around accusations like some swiving Alastor."
      
      You persist, bitterness thickening your voice.  "You wouldn't be, no.  Just a helot who only ever managed to have one child and never remarried, but somehow stayed alive all these years."
      
      "Managed to have…?"
    #"If you didn't sell Aryn, who did you sell?" I bark.  "How are you still alive and un-Harrowed, old man?"
      Your father's eyes are wider than you've ever seen them.  "So that's how it's to be, then."
      
      "I can't believe I didn't see it before."  You glower at him—some part of you still half-hoping he'll lash back at you convincingly, that you'll hear his innocence in his rage. "An old helot who only ever had one child and never remarried…"
      
      "Just one…?"
    #"Tell me it's not true," I plead.  [i]Tell me so I can believe it.[/i]
      "You need me to tell you?  You want me to defend myself against some swiving stranger?" Your imploring eyes seem to infuriate him past the point of sanity. "Then damn you, ${girl}!  Xthonos eat you.  May the Theurges burn you slow, and when they're done, may Xaos find some new spit to roast you on in Taratur.  And may it be somewhere that I can watch."
      
      "How can you…"  How is it possible that he can still hurt you this much?  "I'm your child."
      
      "My child?"
  You'd thought you knew how fast your father could move; maybe it's just that he hasn't dared lay a hand to you in so long.  But before you know it, his fists are clenched in your kyrtle collar, his breath seething on your face.  "My child's been dead these twenty-one years, ${girl}. You're the one that should never have been."
  
  Your pulse throbs deafeningly in your ears as you bat at his hands.  For a wretched moment, you feel five years old again. "What…what are…"
  
  He pushes you off with disgust.  "Oh, I'll own there's my blood in your veins, my nose on your damned face."  His face twists further, and he's suddenly wiping desperately at his eyes with one wrist. "I had a child, damn you.  My son, my beautiful son…I had a child."
  
  It's a moment before you can speak.  "By Mother…?"
  
  Your father drives on, savage and shrill.  "Your [i]mother[/i] was a worthless bit of [i]meat[/i].  All I asked from her was a child every few years.  Enough to keep us both alive.  Did you think it was my fault you were our only get?  I'd sired another, before her, before you.  Her seed was weak, not mine.  Why didn't they bloody Harrow her—did you think of that?  Was she so righteous?  For all her pretending that [i]she'd[/i] never stoop to being 'useful' to Them?  If it were my seed that was weak, you might have had a dozen little sisters and brothers, all looking like some Alastor or other.  
  
  "But no—she couldn't even protect us that way. She left it all to me. And you dare, you dare to come here and hurl it in my face, with your mother's voice, her righteous air?  You miserable little beast."  His eyes are dry and bulging now, but his voice comes in sobs.  "I wish I'd strangled you in your cot.  A hundred times, I wanted to.  Looking down at you, you ugly little thing…in the place he should have been. You could never have been him."
  *choice
    #I strike him.
      *set ruth %+5
      *set morale -2
      *set violence +1
      You aren't carrying a weapon. If you had been, you're not sure what you would have done.  But you lash out at your father's vicious, contorted face with the wide backhand swing he so often used on you.
      
      He doesn't even raise his hands to protect himself.  The stretched skin and shallow bone of his cheeks feel frail beneath your knuckles; at your first blow he flies backward, collapsing like a scarecrow made of old rags and cornstalks.  Prone at your feet, he begins to laugh, a rattling sound like sticks washed down a drainpipe.  "Let them see." Blood wells darkly around his teeth as he smiles up at you.  "Let them see the beast you are.  To beat your aged father.  Let them see what this rebellion really means."
      
      *goto todowdad
    #I lock eyes with him, filled with a hatred too strong for words.
      "There it is," your father whispers, a joyless grin stretching his face.  "There it is.  That's my ${girl}.  That's what I always knew you'd feel."
      
      *goto todowdad
    #I stare at him, furious and lost and sick to my core.
      "What?" your father barks at you, spittle flying from his lips.  "What do you want from me, you mooncalf?"
      
      "$!{oath}. What's left to hope for?"
      *goto todowdad
  *label todowdad  
  You struggle to regain control.  "Now every time folk see me talking to you…they'll think some of it will find its way back to your Alastor friends."
  
  "Like Taratur they will," he snarls back at once. "Unless they'd wonder the same thing when they see you talking to 
  *if rescuer = 0
    Gillian, or Hetten, or 
  any other helot with enough white in their hair.  This is your shame talking, ${girl}—no, your hate.  You're the one who's made the problem here by deciding to believe the lies of some bitter lads whose mother was caught breaking Canon."
  *choice
    #I turn away.  "When we return to camp, I'll announce that you're to be tried for the betrayal and murder of Aryn Weller."
      Despite the excitement and upheaval caused by your decision to try your own father, the eventual outcome is much as he would have predicted.  
      
      The judges whose verdict is most likely to be respected as impartial inevitably include several senior helots as well as some older bandits.  They are sympathetic but unsparing in asking Aryn Weller's children what evidence they have for their allegations—and all that emerges is decade-old hearsay.  
      *if rescuer = 0
        Not even old Joana Orchard, much as she dislikes your father, can say anything to confirm any treachery on his part.  
      It's as if no one's ever seen him talk to an Alastor, for all that they're willing to say so before a judge.
      
      "Happy now, ${girl}?" he hisses to you after the judgment.  "You dragged me through the mud…and for what?  Think they'll thank you for it?  The ones who hate me will still hate me.  Everyone else will wonder what kind of ${woman} falsely calls ${his} own father a traitor."
      
      You glance at him, fury bubbling under the numbness.  "No.  They'll know what kind of father inspired it."
      *finish
    #"It's an easy problem to solve.  By never speaking to you again."
      He begins to snarl out some retort, but you turn on your heel without paying heed.  Over the next few days, you disregard him however furiously he rants; in time, his will to shout at you seems to wither away.
      
      There's nothing more he can do to hurt you than he's already done, and nothing else he'll ever do.  You don't have to listen—not now, not ever again.
      *finish
    #"Do you truly think I'll believe it a lie?"  I shake my head, bitterly incredulous.
      "I don't give a jongler's damn what you believe, ${girl}," your father spits back at you. "Think what you will.  Never made a difference before, and won't now."
      
      "They'll all know, now," you say, swallowing hard.  "They'll know you have no part of my trust or respect.  They'll know you're alive not because we can prove nothing, but because you're powerless to harm anyone.  Just a bitter old dog barking away in the wilderness, for whatever days remain to you."
      
      The hatred in his eyes is ebbing into something duller again. "As if there will be many of those.  You've seen to that. My child."
      
      "Goodbye, Father."  You walk away from him.
      *finish

*if (aristo) and ((bred_lover < 11) or not(bred_here))
  
  You've barely had to think of your father in weeks; since 
  *if horion = 0
    Horion's death and
  *if (horion > 0) and (horion < 10)
    Horion's imprisonment and
  *if horion > 10
    Horion's departure and
  Hector's attack, he's been a sullen, brooding presence at the margins of your awareness.  Perhaps it should have been less surprising when you hear his voice raised histrionically from the center of the camp where you met Yed.  "Let them be remembered, O Xthonos, for all that they wrought during their brief hour in the sunlit lands…."
  
  As you hurriedly approach, you can both see and smell an unusually sweet smoke: cedar, honeysuckle, pine.  He's managed to get a few 
  *if kids > 60
    dozen children 
  *if kids <= 60
    of your followers
  to help him build and light a massive bonfire, and has been throwing on fistfuls of flowers, vines, and aromatic woods. 
  *if followers > 100
    Scores of 
  *if followers <= 100
    Most of your
  outlaws have gathered to watch, but no one has challenged him.  At the end of the day, however mad, he carries some of your authority.
  
  "Father," you yell incredulously.  "What by ${oath} do you think you're doing?"
  
  "I am taking advantage of the momentary possibility of a pyre to perform the customary memorial for the death of a once great House," he shouts back at you, teeth bared.  "As you have so clearly ensured that none others will perform them for us…"
  *choice
    #I try to convince him to come speak with me in private.
      Your father begins laughing, bats away your protests.  "What, ${fname}, do you imagine there's any dignity left to us?  Any secrets that a hundred helots don't already know?"
      
      *goto dadrant
    #I throw up my hands.  "If you wish to be a play-actor in your own drama, Father, could you at least rehearse more quietly?"
      As the outlaws begin to laugh, you expect to see your father's face contort with the familiar shame and hatred—but this time it never gets past his eyes.
      *goto dadrant
    #"Douse that fire," I order the nearest spectators.  "And next time he tries any such nonsense, for ${oath}'s sake stop him."
      Your father catches up a burning brand from the bonfire and takes a swordsman's pose.  "Let anyone try who cares not for their eye!"  No one obeys your order; none of them wants to try to disarm your madly grinning father.
      
      *goto dadrant
  *label dadrant
  He turns to hurl a fistful of dirt onto the flames. "We meet in memory of ${fname} 
  *if slur != ""
    ${orig_lname} ${slur}, 
  *if slur = ""
    ${orig_lname},
  last of the name." Some of the amused expressions in the crowd fade.  For a father to declare his ${daughter} dead is no matter for mirth.  "$!{hers} was the burden, ${hers} the shame. $!{hers} the 
  *if orig_lname = lname
    failure to pass on 
  *if orig_lname != lname
    murder of
  the name—the failure to wed, the failure to beget or to adopt,
  *if orig_lname != lname
    and at last the abandonment of the very name of ${orig_lname},
  dishonor compounded by disdain for filial duty."
  
  "Wedding? 
  *if (malepref and female) or (femalepref and male)
    Begetting?" 
    *goto begetadopt
  *else
    Adopting?"
    *goto begetadopt
  *label begetadopt
  You stare at him in exasperated disbelief. "$!{sweetoath}, Father."
  
  "By the time you actually attain the age of consummation, we are unlikely to be in a place where I can properly celebrate the occasion."  He gestures, thin-lipped, toward his pyre.  "After all the work I poured into trying to arrange your betrothal and the continuation of the family name, you can surely appreciate my desire for a bit of commemoration."
  
  "Isn't it a bit early to despair when I'm not yet twenty?"  While several of your peers in Rim Square are already safely betrothed, virtually none actually wed before the start of their life's third decade. 
  *if (malepref and female) or (femalepref and male)
    Even if married, if you'd begun having children, your reputation would have suffered for your inability to control your passions.
    *goto whowouldbe
  *else
    And no one would have expected you to adopt a child into the family for years afterward.
    *goto whowouldbe    
  *label whowouldbe
  
  "Who would
  *if female
    sire
  *if male
    bear
  your children now?  Or who will you adopt to continue 
  *if orig_lname = lname
    our name?"
  *if orig_lname != lname
    the name you forsook?"  
  Your father waves an arm to take in the ragged crowd of bandits.  "What scabby helot would stoop to become 
  *if orig_lname != lname
    ${orig_lname}—let alone [i]${lname}[/i]—after
  *if orig_lname = lname
    ${orig_lname} after
  what you've made of us?"
  
  There's an unsteadiness in his movements that you've rarely seen since fleeing Rim Square.  "Are you drunk?"
  
  The note of scorn in your voice seems to strip him of any remaining control.  "I was the hope of our House!  The last of the name!"  His howl rocks him up on his toes, as if drawing force from his whole body.  "Every day my mother reminded me of that burden.  When I did aught to shame the name, she'd stripe me for it.  And I passed it on to you—a hope that you never cared a whit for.  Traitor, ingrate, familicide.  You're your mother's child, you careless, weakling harpy.  I'll have none of you!" His voice drops to a hiss.  Wreathed in pyre-smoke, there's suddenly something uncanny about his lean, hunched form. "Be damned of your father and a hundred generations of ${orig_lname}. May all who follow you in this rebellion share in your curse.  May the Angels hear our voices from beyond the grave and repay you in anguish everlasting!"  
  
  No one is smiling now.  All around you, young outlaws are drawing back uneasily.
  *choice
    #And my bravado crumbles into horror.  Cursed by my father, burned on the pyre—I've been unmoored, cut off from who I was.
      You hadn't thought he still had such power over you—until this moment of dizzy paralysis.  Tears sting at your eyes, and you struggle to speak past a great knot in your throat.  How can you consider yourself a
      *if orig_lname != lname
        ${orig_lname} or
      ${lname} when your own father has so thoroughly damned you?  How can you consider yourself noble at all?
      
      "Stop, Father," you plead at last.  Your voice is thin and raspy in your own ears.  "Unsay it.  I'm still your child.  I…I won't be the last of the ${lname}.  I swear it by 
      *if skep <= 50
        all Angels."
      *if (skep > 50) and (religion < 20)
        earth and sky."
      *if (skep > 50) and (religion > 19)
        kenon."
      
      He staggers up to you, eyes rheumy from the smoke, and for a moment you think he's going to fall weeping onto your shoulders. Instead, he spits in your face.
      *goto nochild
    #"Enough," I bark, catching his arm to pull him away.
      With a shriek of denial, he swings wildly at you with his free fist.
      *choice
        #I block his arm.
          You'd not realized quite how thin and wasted your father has grown over your months in the woods.  Catching his blow not only doesn't hurt as you'd expected, it barely takes effort at all.  It's like fending off a child.
          *label tent
          
          "Go to your tent, Father," you breathe.
          
          He spits in your face.  
          *label nochild
          "You're no child of mine, demon.  Don't call me father.  Never again."
          *finish
        #I duck the blow and strike back.
          *label ouch
          *set violence +1
          He doesn't even raise an arm to protect himself.  The stretched skin and shallow bone of his cheeks feel frail beneath your knuckles. At your first blow he flies backward, collapsing like a scarecrow made of old rags and cornstalks.  Prone at your feet, he begins to laugh, a rattling sound like sticks washed down a drainpipe.  "Let them see!" Blood wells darkly around his teeth as he smiles up at you.  "Let them see the beast you are.  Let them see what this rebellion really means."

          "Go to your tent, Father," you breathe.  "Or jump onto the pyre.  I don't care."
          
          He staggers to his feet, spits redly at you.
          *goto nochild
        #I take it without flinching.
          You'd not realized quite how thin and wasted your father has grown over your months in the woods.  Accepting his blows doesn't rock you as it used to; it's like being pummeled by a child.  After a few moments, he realizes it too and lurches back from you, the image of dismay and humiliation.
          *goto tent
    #"You, the hope of the House?" I cry back at him. "Listen to yourself! Cursing the last one of us? You've poisoned everything, all your life.  If we survive, it's despite you."
      *label despiteyou
      Your father's eyes widen; something in what you've said has struck home.  "You murderous whelp…you dare to stand in judgment on…" he begins, trying to regain his fury.
      
      "Stop speaking!" you yell. "Stop.  You think anything you've done in your whole hateful life made us stronger as a family?  $!{oath}…you think anything I took from you deserves the name [i]hope[/i]?  Just bloody stop, Father."
      
      He stares at you for a moment, looking frail and lost.
      *goto nochild
    #I stride up to him and lash out with the same wide, backhand blow he so often used on me.
      *goto ouch
    #"You're wrong, old man," I say hoarsely. "I'll bring more glory to the ${lname} name than you'd ever dreamed."
      Your father's lips twist into a bloodless snarl. "If there's any justice in the world, you'll be Slow-Harrowed before the leaves change.  You'll die as long and hard as the worst murderer in Shayard.  And I'm just sorry I'll be dead in these woods so I won't be there to see it."
      
      "Grandmother told you that only great deeds could revive the ${orig_lname}. What great thing did you ever even try to do?" you demand, your pulse thundering in your ears. "What has your life been besides intrigues and backbiting?  And punishing everyone who came close enough to see the petty creature you are?"  
      
      Your father lurches back as if you'd physically struck him.  "Hear, O Angels!  Hear with what disrespect…"
      
      "I'll be the one, Father." You cut him off in mid-wail.  "I'll do what you were too small to do.  By ${oath}, you will be there to see it.  You'll know I did it in spite of you; everyone here will know it was despite your curses.  The ${lname} will be greater than any of our ancestors dreamed.  And none of the glory will be yours."
      
      He sways in the smoke for a moment, looking frail and lost.  Then he tries to speak—something choked, unintelligible.  He clears his throat, tries again.
      *goto nochild
    #"I'm so sorry, Father."  Sorry this is all that's left—that we missed whatever chance there might have been to save it.
      "You're sorry?"  His eyes are still bulging half out of his skull, rheumy from the smoke.
      
      "I thought there'd be time," you say hoarsely. "Some chance, once we'd survived the summer.  But everything…there's just been so much, so many lives resting on every choice…"
      
      "What are you on about, you mooncalf?"
      
      "I know I've hardly had time for you, Father, and the times we have talked haven't been good.  I've belonged to the band, ever since we left Rim Square.  Ever since I so angered you."  You swallow hard, trying to hold his hateful gaze.  "But till now I'd thought there'd be some time yet, some moment of peace.  Some chance to mend matters between us."
      
      Neither of you speaks again; the crackle of the pyre is the only sound.  Your father's face is unyielding, unsoftening, in the way you saw so many times when he stood over your mother.  At last, you shake your head and rasp again, "I'm sorry," before walking away.
      *finish
    #I've nothing to say to this ranting, hateful creature.  I walk away.
      *label rantinghate
      His voice rises to a shriek behind you: "If there's any justice in the world, ${girl}, you'll be Slow-Harrowed before the leaves change.  You'll die as long and hard as the worst murderer in Shayard.  And I'm just sorry I'll be dead in these woods so I won't be there to see it!"
      *finish
  
*if (aristo) and ((bred_lover > 10) and (bred_here))
  Later, you will think: [i]It was bound to happen sooner or later.[/i]

  *if (rescuer = 0) and ((bred_trust > 4) or (bred_trust < 2))
    When
  Breden
  *if (rescuer = 0) and ((bred_trust > 4) or (bred_trust < 2))
    returns from ${xhis} final visit to the Rim, all ${xhe} seems to be interested in is getting you alone.  For a few days you make excuses, worried that ${xhe} means to punish your failed attempt at testing ${xhis} loyalty.  But ${xhis} affection seems so sincere and impassioned; you can't hold out forever.
    
    $!{xhe}
  finally manages to extricate you from the daily business of the band and spirit you away to the woods.  The destination you'd agreed on was a grassy willow arbor some six furlongs away; but that plan rapidly begins to unravel when you're out of eyeshot of the camp.  
  
  Soon your jerkin and kyrtle are half-shed, you're completely absorbed in Breden's face…and you hear a strangled noise from the underbrush behind you.

  Even before you disentangle yourself, you know what you'll see: your father clutching at a tree, his lips twisted and agape, his eyes wide as fists. You're sure he's not seen your exposed chest since you were a
  *if male
    hairless
  *if female
    breastless
  child.
  *fake_choice
    #I yelp and scramble to get my clothes back over my shoulders.
      By the time you're modestly clad again, your father has disappeared
    #I shout, "Damn it all, Father…what by Xaos are you doing out here?"
      Your father splutters, "Filth…how dare…"  Then his voice dies, and he turns and crashes blindly back
    #Without moving, I say in as level a voice as I can manage, "Does the band need me?"
      Your father's face bulges.  "Shameless," he says hoarsely.  "Filth…how dare…"  Then he turns and crashes blindly back
  into the forest.
  *choice
    #I run after him.
      He doesn't respond to your calls of "Father!" and it takes a minute for you to catch up to him.  

      Just as you're about to overtake him, he whirls on you, hands raised and clawed. His voice is a shrill garble.
      *goto fornic
    #After a long silence, I turn back to Breden and nod numbly in the direction we were originally going.
      Neither of you speaks as you walk, and when you get to the willow arbor, you just sit and stare at each other for minutes, as joyless as if your father were still hovering nearby.
      
      "I'm sorry, ${fname}," Breden finally says, thick-voiced.  "Xthonos, I wish we'd waited until we were here.  I'd have done anything to spare you that.  But…shame is going to dog our steps wherever we go.  If you don't think you can shrug it off…or live with it…"
      *choice
        #$!{xhe}'s right.  We have no future.
          "I can't live with it," you echo, sounding lifeless even to your own ears. To be shamed to this extent again would be intolerable because of your need for:
          *choice
            #Public respectability. If I'm not thought to be virtuous, I'll never win the better parts of society over to my cause.
              "Our rebellion…the leader has to be beyond reproach, Breden…"
              *goto breddump
            #Self-respect. I can't bear the thought of others reacting like my father just did.
              "If anything like this ever happened again…if others found out…"
              *goto breddump
            #Piety. Anything that makes me feel like this must be against the will of the Angels.
              "It's not right, Breden…living by the Order of the Angels, such shame shouldn't be…"
              *set skepreal %-20
              *goto breddump
            #Something else I can't articulate—but I know I won't attain it as long as I'm with Breden.
              You turn miserable eyes toward ${xhis}.  "There's simply no way…"
              *goto breddump
          *label breddump

          "Stop.  Please. Just…don't say more."  Breden takes one long, shuddering breath, stands stiffly, and walks away.

          When you finally trudge back up the hill above the camp, your waiting father spies you and stalks straight through the woods in your direction.  Numb, not knowing what on earth you want to say—something to placate him, divert him, curse him?—you open your mouth to speak, but he gives you no chance.
          *goto fornic
        #"We have to keep this completely secret from now on," I implore ${xhim}. "I can't live with another scene like that."
          "Completely…?"  As Breden stares at you, you see ${xhis} face harden. "So let's be clear, ${fname}. You will never acknowledge me as your lover—any more than you would have if I were a field ${xgirl} on your estate.  Really, for all the difference this rebellion has made, we might as well still be there."

          You blink back at ${xhim} in shock.  "That's…that's both cruel and unfair, Breden! And untru—"
          *goto breddump
        #I put my head in my hands.  "Angels, Breden. My father just saw me half-naked."
          The sympathetic silence is broken, astonishingly, by a half-stifled chuckle.  "I'm sorry, I'm sorry, ${fname}," Breden pleads, ${xhis} smile vanishing before your affronted glare. "It's just…I never really imagined you nobles could be so modest that your own flesh and blood never saw under your kyrtle.  How can you…I thought…Angels.  How is it possible to live in the same house and not…"

          "I assure you, it is entirely possible," you retort, sounding stilted and chilly even to your own ears. You've seen the boys and girls in helot field gangs working unclad above the waist, of course; but how could Breden have just assumed that you would be equally shameless about it? "For our part, we would find it hard to imagine…"

          As you trail off, Breden leans in, voice newly curt.  "Then let me help you, ${kuria}. Imagine you own just the one kyrtle, and you not only have to make it last the year, but keep it clean enough that you can wear it to the Naos Xthonos. Because if the Ecclesiast notices you coming before the Angels soiled, he'll have you beaten, or worse."
          *choice
            #$!{xhe} laughs at me, then berates me? I stalk away.
              "That's what it takes?" Breden calls after you incredulously.  "We're at an end because your father saw your chest?"
              *choice
                #"We're at an end because we're too different, Breden."
                  "It was never…How often can two people from completely different orders…?"
                  *goto breddump
                #"This isn't the end.  Just…I don't care to be laughed at right now."
                  Breden sounds unamused.   "Oh?  You can talk down to us all you like, but Xthonos forbid the dignity of ${milady} ${fname} ${lname} be bruised."
                  
                  You whirl on ${xhim}, furious.  "Do you want this to be the end of us?"
                  
                  $!{xhe} walks up to your side, looking pained but determined.  
                  *label worryridic
                  "I don't want to have to worry about whether I can laugh when you do something ridiculous.  Or scrap with you when you're wrong.  If you were a helot like me, there'd be no question of whether that was all right."

                  Your hands momentarily seem the best place to rest your face.  "Whereas if you were a noble…there'd be no question of laughing or scrapping.  A courting couple treat each other with dignified respect. Not telling the other they're ridiculous, or wrong."
                  
                  At that moment you can't see ${xhim} through your fingers, but you hear the helplessness in Breden's chuckle.  "Aren't we the pair."  $!{xhe} rests a hand tentatively on your shoulder.  "$!{bfname}…I'd see this through. I know it's no simple thing."
                  
                  After a moment's hesitation, you raise your head and bring your hand up to ${xhis}.  "I'd see it through, too."
                  *label trudgeback
                  *page_break
                  When you finally trudge back up the hill above the camp, your waiting father spies you and stalks straight through the woods in your direction.  You brace yourself and try to remember the best things you'd been considering saying—but he gives you no chance.
                  *goto fornic
            #$!{xhe}'s right. I do my best to shake off the humiliation.
              "Very well. I understand."  If you still sound a little stiff, surely that's natural under the circumstances.
              
              "${fname}…" Breden shakes ${xhis} head, looking pained. 
              *goto worryridic
        #"You're right." I shake off the hurt and kiss ${xhim} long and hard.
          *goto bredferoc
    #I tug Breden's clothes off.  Damned if I'm going to let the old man ruin this.
      *label bredferoc
      Breden echoes the silent ferocity of your lovemaking.  Afterward, you find yourself staring comfortably at the place where your arm curves around ${xhis} back—skin on skin, wearing the same sheen of intermingled sweat.  There's a tautness in ${xhis} shoulders that you're coming to recognize.  "Forget him.  You're mine."
      
      "And you're mine."  $!{xhe} stretches, relaxes slightly, looks over ${xhis} naked arm at you.  "Breaks Canon every time I say that—that's the problem, isn't it?  Your father wasn't expecting his child to belong to a helot."
      *fake_choice
        #To be honest, I find that particular phrasing a bit unseemly myself.  But now's hardly the time to challenge it.
          You make a noncommittal sound, and Breden wriggles free of your embrace.
        #As ever, when Breden says that it sends a shiver of pleasure through me.
          "Mmm.  Never expected it myself."
          
          Breden gives you one last kiss, then pulls free of your embrace.
        #"I don't imagine it was high on his list of betrothal options," I say drily.
          Breden's smile soon fades.
      "You've got to face him, ${fname}.  Maybe this was for the best.  Whatever you have to say to him, best to say it and have done."
      
      "It shouldn't be any of his concern." You suspect Breden's right, but the thought of having this conversation with your father fills you with dread.
      
      "No?"  Breden rolls away from you and begins shrugging ${xhis} kyrtle back on.  "Maybe if we were all still back in Rim Square, ${kuria}. Use me for a month or two in secret until you get bored.  Trust in everyone's discretion to avoid a scandal.  Or, well, the nobles' discretion and the helots' raw fear.  Stay marriageable.  Nothing there to affect the ${lname} name."
      
      "We both know we're past that."
      
      $!{xhe} nods, something fierce and frightened in ${xhis} eyes. "Then it's his bloody concern."
      *goto trudgeback
*label fornic
"It's not enough for you to fornicate with that creature in the dark? Now you're disporting yourselves in the broad daylight!"
*choice
  #I try to apologize, overwhelmed by shame.
    It's been weeks since you felt any sense of wrongness in your times with Breden.  Now it returns in a blinding wave of guilt.  How quickly and lightly you've discarded your chastity…succumbing to the most contemptible form of animal disorder…
    
    Your father negates your first fumbles toward repentance with a savage chop of his arm.  "Sniveling little dastard.  You contaminate the ${orig_lname} bloodline, rutting before the Angels and everyone with this, this flyblown beast!  You think you can undo that?"
    
    A surge of anger temporarily pushes the shame aside.  "$!{xhe}'s no beast, Father.  $!{xhe}'s braver and wiser and better than half the nobles I've met."
    *goto dadcurse
  #"Have you no honor, Father, peeping after us in the woods?"
    "What?" he all but shrieks.  "Do you dare…you dare imply I meant to walk into your filth?"
    
    "It's a damned big forest, Father.  You truly expect me to think you stumbled on us innocently?"
    *goto dadcurse
  #I glower at him in silent resentment.
    His forearm swings up, an all too familiar silhouette.  In another second, the back of his hand will crack across your face.
    *choice
      #I block his arm.
        You'd not realized quite how thin and wasted your father has grown over your months in the woods.  Catching his blow not only doesn't hurt as you'd expected, it barely takes effort at all.  It's like fending off a child.
        *goto dadcurse
      #I duck the blow and strike back.
        *goto ouch2
      #I take it without flinching.
        You'd not realized quite how thin and wasted your father has grown over your months in the woods.  Accepting his blows doesn't rock you as it used to; it's like being pummeled by a child.  After a few moments, he realizes it too and lurches back from you, the image of dismay and humiliation.
        *goto dadcurse
  #Overcome with rage, I strike my own father.
    *label ouch2
    *set violence +1
    He doesn't even raise an arm to protect himself.  The stretched skin and shallow bone of his cheeks feel frail beneath your knuckles. At your first blow he flies backward, collapsing like a scarecrow made of old rags and cornstalks.  
    
    Prone at your feet, he begins to laugh, a rattling sound like sticks washed down a drainpipe.  "Now let them all see!" Blood wells darkly around his teeth as he smiles up at you.  "Let them see the vile beast you are.  Let them see what this rebellion really means."
    
    "All they'll see is a hateful old man whose bile finally got some return."  Your breath is a rapid, furious whistle in your nostrils. "They know who the beast among us is."
    *goto dadcurse
  #"It's no longer your concern," I retort, heart pounding in my ears. "I'm no longer your concern."
    Your father's face contorts further into a sneer.  "What—you've so demeaned this family that you think your depravity can bring me no further shame?"
    
    You fight to keep your voice steady.  "You destroyed this family long ago.  I'm a faithful scion of the ${orig_lname}… but you?  You've no more claim on me, you hateful old man."
    *goto dadcurse
*label dadcurse

"Ah, Xthonos [i]damn[/i] you, ${girl}!" It's all you can do not to recoil from his rabid tone.  
*if (male and (xhe = "she")) or (female and (xhe = "he"))
  "Xthonos wither your issue in the womb, before any blood of mine be mingled with a [i]helot's[/i]!"
  *goto dadthroat
*else
  "Xthonos wither your loins and gall your blood, you helot-consorting filth."
  *goto dadthroat
*label dadthroat

Your throat contracts painfully.  "Is that what we've come to?  You'd curse the last of the ${lname} to die heirless?"

"I and the hundred generations before me!" your father roars without a moment's hesitation. The words spill from him, barely coherent in their venom. "How many years have I sought to find a match for you? A young
*if xhe = "he"
  man
*if xhe = "she"
  woman
from a House small enough to assume our name.  Just as my mother did for me.  Every day she reminded me that I was the hope of our House—the last of the name!  When I did aught to shame it, she'd stripe me until I learned to carry the burden.  And I passed it on to you—a hope that you never cared a whit for.  Traitor, ingrate,
*if orig_lname != lname
  name-forsaking
familicide.  You're your mother's child, you careless filth.  None of mine."
*choice
  #"I've found my own match, Father.  Someone worthy of me."
    "Aye, that you have," he breathes, with the expression of someone about to vomit. "A dog to a dog, a swine to a swine…"
    
    "Someone worthy of the ${orig_lname} at their bravest and best!" you shout, as if answering all the others who would share your father's contempt.  "Worthy to assume our name, if ${xhe}'ll take it."
    
    "You're mad, ${girl}—possessed by bloody Xaos itself!  As well declare some writhing maggot to be your adopted heir…"
    
    "Because the nobility are of a better nature than the peasants.  Made of finer stuff, and all the rest."  You fix empty eyes on him.  "All my life, I've known better than that. Father."
    
    His lips writhe as if he's about to weep or spit.
    *goto nochild
  #"You, the hope of the House?" I cry back at him. "Listen to yourself! You've poisoned everything, all your life.  If we survive, it's despite you."
    *goto despiteyou
  #"You're wrong, old man," I say hoarsely. "I'll bring more glory to the ${lname} name than you'd ever dreamed."
    Your father's lips twist into a bloodless snarl. "If there's any justice in the world, you and your mucky little helot consort will be Slow-Harrowed before the leaves change.  You'll die as long and hard as the worst murderer in Shayard.  And I'm just sorry I'll be dead in these woods so I won't be there to see it."
    
    "Grandmother told you that only great deeds could revive the ${orig_lname}. What great thing did you ever even try to do?" you demand, your pulse thundering in your ears. "What has your life been besides intrigues and backbiting?  And punishing everyone who came close enough to see the petty creature you are?"  
    
    He lurches back from you.  "Hear, O Angels!  Hear with what disrespect…"
    
    "I'll be the one, Father." You cut him off in mid-wail.  "I'll do what you were too small to do.  By ${oath}, you will be there to see it.  You'll know I did it despite you, despite your curses.  The ${lname} will be greater than any of our
    *if orig_lname != lname
      ${orig_lname}
    ancestors dreamed.  And none of the glory will be yours."
    
    He sways there for a moment, looking frail and lost.  Then he tries to speak—something choked, unintelligible.  He clears his throat, tries again.
    *goto nochild
  #I've nothing to say to this ranting, hateful creature.  I walk away.
    *goto rantinghate

*label simonflee
*set s_rel +20
*set simz_here false
*set followers -1
*set nonkids -1
*set dead +1
*page_break
The next day, when it becomes clear what you've done, ${simon} de Firiac vanishes.  No farewells, none of the recriminations or hard choices you'd been braced for; ${zhe} simply flees the band.

As soon you realize ${zhe}'s gone, you send Ciels after ${zhim}. $!{he} returns empty-handed a day later, looking rueful and impressed.  "I knew the young ${zkuria} had spent ${zhis} time on the hunt as well as with the blade, ${milady}.  But I hadn't realized ${zhis} woodcraft was near enough to mine.  Whichever way ${zhe} passed, ${zhe}'s hidden ${zhis} tracks like a master."
        
You shake your head in frustration.  "Put the word about, then.  If anyone comes across ${zhim}…"
*choice
  #"…tell ${zhim} to come back to us.  $!{zhe} was always welcome here."
    *return
  #"…find out what ${zhe} intends to do, and make sure ${zhe} isn't causing us any trouble."
    *return
  #"…kill ${zhim} on sight."
    *return

*label theuexplain
"The power to break them—to set things right."
      
*if wisard = "Theurge"
  An awed murmur ripples around you, still tinged with alarm.  "Theurgy," someone breathes. "The Angels have sent us a Theurge."
  *return
*elseif wisard = "Goete"
  *set morale -15
  *set cred_p -50
  You hear some of the surrounding bandits whimper at this. For a moment, you wonder if they're going to stone you. "From…from Xaos?" one breathes.
        
  "I didn't traffick with any spirit, Angel or demon, to learn this," you say levelly.  "But it's going to bring down the Order of the Thaumatarch…so yes, call it Goety, and let the Hegemony tremble."
  *return
*elseif wisard = "Wisard"
  *set natl %+5
  In your outlaws' murmurs you hear confusion, fascination, alarm.  "What is it?" one young bandit demands.  "And where'd you learn how to do it?"
      
  You intend to remain extremely vague on both points. "The right question, girl," you retort weakly, "is when did the Karagonds learn it from us, start calling it Theurgy, and claim it as knowledge the Angels gave them?"
  *return
*else
  *bug not a theuwisgoete?  

*label theureveal
*page_break
"[i]What by Xaos was that?[/i]" bellows Radmar, staring at you with wide, white eyes.

"That was ${wisardry}," you say steadily, fighting the simultaneous urge to laugh and run away.
*gosub theuexplain
                                
Your followers mill around you for a few silent, unsettled moments.  Then Radmar bursts out with, "Xthon'damn, ${addressu}—we truly are going to break the Hegemony!
*if hectheu = 1
  Flying trees?
*if hectheu = 2
  Burning trees?
*if hectheu = 3 
  Spears through horses?
We're going to bloody win!"
*return

*label bedrollch
*choice
  #They're the last coherent words either of us utters for a long time.
    *return
  #I shake my head, press a finger to ${zhis} lips.  "This is all I want tonight."
    ${kalt} tilts ${zhis} head to one side.  You can see the pulse throbbing fast in ${zhis} throat. "And…the night after?  Or the night after that?"
    *choice
      #"Let's see, when we've had time to know each other better."
        "Give it some time.  You'd barely trusted me before tonight.  You've been fighting me since you arrived in the band."
        
        ${kalt} looks dubious. "Lovers fight too,
        *if aristo
          ${kuria}.
        *if helot
          ${fname}.  
        I won't always agree with you."

        "I don't want you to."  You kiss ${zhim} again.  "But if we're going to keep fighting, I need to know I can trust you.  That you're not the kind to give hurt."
        
        When you pull away, ${kalt} groans and breaks free of your embrace. "Best wait on the kisses, then, too.  I don't do half-measures, ${kuria}.  Until you trust me enough to put yourself in my hands, let's keep things as they were." $!{zhe} starts to walk back to camp, then glances back at you sharply. "And no. I'm not your father."
        *set k_rel 3
        *return
      #"Not unless I wed you honestly."
        *if bred_lover > 9
          *label bredkaltlover
          *set k_rel 7
          "So Breden Reaper gets to have you in the middle of the camp, but I don't until we're wed?"  ${kalt} breaks away, lips twisting furiously.  "Don't swiving toy with me, ${lname}.  There's no reason it should matter with me when it didn't with ${xhim}."  Before you can make any response, ${zhe}'s gone.
          *return
        *if aristo
          ${kalt} stares at you, incredulous.  "And what chance is there of that, 
          *if female
            milady
          *if male
            milord 
          ${lname}?"
          
          "If I find I can trust you?  If I come to believe you're my lost half?" You offer ${zhim} a grin.  "I don't see who's going to stop me.  It's not as if they still consider me a true noble, in any case."
          
          "They'll look differently on a noble who wed an animal, and you know it." ${kalt} doesn't return the smile.  "It's one thing to rebel against the Karagonds, ${kuria}.  It's another to break every noble's idea of what's clean and unclean."
          
          "Which I'm doing already."  You kiss ${zhim} again.  "In a dozen different ways."  
          
          $!{zhe} runs a hand along your flank and murmurs: "Why wait, then?  If it's not to protect a reputation you'd kill anyway by wedding me?"
        *if helot
          ${kalt} blinks at you. "That's not stopping anyone else in the band, ${fname}.  We could all be killed tomorrow if a Theurge finds us.  Why not take what joy we can, while we can?"
        *set k_rel 3
        *choice
          #I've heard my whole life that un-Ordered sexual union invites jealousy, madness, and chaos.
            *if bred_lover != 6 
              It's not just the sacred Canon; the popular
              *if helot
                fireside tales
              *if aristo
                 storybooks
              you grew up with were full of examples.  Most famously, there's the epic tragedy of Kevin and Leir, two young nobles who became illicit lovers when their parents refused them permission to marry.  Uncurbed by matrimony, their passion led to a spiral of worsening distrust and jealousy, with each one increasingly convinced that the other had betrayed him.  Finally Kevin took revenge by accepting the advances of the pirate king Redegard, leading in the end to the Battle of Six Storms in which all three were drowned.
              
            *if bred_lover = 6 
              As you'd said to Breden, when ${xhe} asked.
            "We need to fend off Xaos any way we can, ${kalt}.  All the more so as rebels.  I don't."
            *label comecourtme
            
            ${kalt} sighs and pulls away.  "Best wait on the kisses, then, too.  I don't do half-measures, ${kuria}.  Come court me like I'm some virtuous
            *if zhe = "she"
              noble maiden, 
            *if zhe = "he"
              aristo lad,
            if you will, and we'll see what you decide."
            *return
          *selectable_if (skepreal < 51) #The Angels bless the intimate union of bodies—but only within the sacred covenant of matrimony.
            *set skepreal %-10
            You ruefully trace a helix in the air. "I can't afford to lose their blessing."
            *goto comecourtme
          #A reputation for chastity may win us allies who would otherwise dismiss us as Xaotic.
            *if aristo
              ${kalt}'s not wrong when ${zhe} says that you'd lose reputation by marrying ${zhim}.  But you know all too well 
            *if helot
              You've heard
            how important chastity is to devout or traditional noble families; it's the most widely respected evidence of loyalty and orderliness.  "There are nobles all over Shayard who will look to this to see if we're slaves to our passions.  To Xaos.  And not just the nobles, either: merchants, priests, and those who listen to them.  I can't keep the band from their habits, but I can set an example that others will speak of."
            
            "You truly care what They think?" ${kalt}'s voice is growing thin with anger. "Damn it all, ${kuria}, they'll never see us
            *if aristo
              helots
            as more than animals."
            
            "Some will, if we act the part.  Enough to make a difference."
            
            ${kalt} scowls and pulls away.  "Best wait on the kisses, then, too.  I don't do half-measures, ${kuria}."
            *return
      #"Probably not," I admit. Kissing ${kalt} is pleasant enough, but ${zhe}'s too unstable for me to want more.
        *if bred_lover > 9
          *goto bredkaltlover
        ${kalt}'s lips twist as ${zhe} steps back to arm's length.  
        *if aristo
          "Only so much contamination you'll risk from us filthy helots then, ${kuria}?"
          
          "Only so much hurt." You work to keep your voice level. "Hear yourself, ${kalt}.  Hear the part of you that hates me, that comes out when you don't get what you want.  $!{oath}, I get enough of that from my father.  Why would I take a lover who sounds like him?"

          $!{zhe} glares at you for a moment more before walking off to ${zhis} bedroll alone.
        *if helot
          "And if I'm not satisfied with so little?"
          
          You stare back at ${zhim}, unwavering.  "There'll be plenty of others who offer more.  You can take up with them as you please."
          
          "You're the one I want, ${kuria} ${fname}."  The fire is growing in ${kalt}'s voice. "If you don't feel the same, if a few kisses are all you're keen for… then don't bloody toy with me."
        *set k_rel 7
        *return
  #I pull away, holding ${zhim} at arm's length.  "Not until I know you'll back me up."
    "What?" ${kalt}'s voice is low, deceptively emotionless.
    
    "A kiss is well and good.  I can kiss someone who fights me on half the decisions I make.  Might even enjoy it more, for that."  You swallow, trying to keep your voice steady.  "But I'll not take anyone as a lover who'll undercut me before the band."
    
    "Can't bear to be argued with, then?"  There's a bit more emotion creeping in this time.
    
    "Bandits heed their captain's lover."  In every story you ever heard, anyway. "You'd be closer than my deputy, and more dangerous for it.  No, ${kalt}: if you decide to challenge me for the lead, it won't be from my bedroll."
    
    *if aristo
      "That's…swiving bloody Angels." ${kalt}'s eyes snap with a fury too intense for speech. After a moment, ${zhe} manages to choke out, "Play the lapdog, just so you don't feel threatened, mighty ${kuria}?  You're damned right, it won't be from your bedroll.  Not ever."
      *set k_rel 7
    *if helot
      ${kalt} stares at you for a long time before folding ${zhis} arms and stepping away. "So.  Then I might ask you again, Captain, when you seem to trust me better." $!{zhis} lips quirk.  "Or after the band choose me as their new leader.  I wouldn't be troubled by a lover who fought with me."
      *set k_rel 5
    *return

*label chaperon

At first when you started constantly seeking out his company, he mistook it for a new level of presumption upon your kinship.  He lashed out at you, determined to put you back in your place.  Then he seemed to understand, or at least, the punishments stopped.  He suffered you to spend your days with him and Calea, or him and a chaperon.
*return

*label lithelp
Having another twenty or so rebels who know their alphabeta may well prove 
*if literate > 10
  useful.
*if literate <= 10
  useful, with so few in your current band able to read or write.
*return
    
*label d2n_np
*set np true
*label d2n
*set display_numb ""
*set thousands 0
*set hundreds 0
*set tens 0
*set single 0
*if d2n_num = 0
    *set display_numb "zero"
    *goto finish_d2n
*if d2n_num < 0
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if d2n_num > 999
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if (d2n_num modulo 1) > 0
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if d2n_num < 10
    *set single d2n_num
    *goto single_digit
*label thousands_digit_addition_repeat
*comment leaving this here in case we want to switch the thousands back on
*if d2n_num > 999
    *set d2n_num -1000
    *set thousands +1
    *goto thousands_digit_addition_repeat
*label hundreds_digit_addition_repeat
*if d2n_num > 99
    *set d2n_num -100
    *set hundreds +1
    *goto hundreds_digit_addition_repeat
*if (d2n_num > 9) and (d2n_num < 20)
    *goto skip_tens_and_singles
*label tens_digit_addition_repeat
*if d2n_num > 9
    *set d2n_num - 10
    *set tens + 1
    *goto tens_digit_addition_repeat
*set single d2n_num
*label skip_tens_and_singles
*if thousands = 1
    *set display_numb "one thousand"
*if thousands = 2
    *set display_numb "two thousand"
*if thousands = 3
    *set display_numb "three thousand"
*if thousands = 4
    *set display_numb "four thousand"
*if thousands = 5
    *set display_numb "five thousand"
*if thousands = 6
    *set display_numb "six thousand"
*if thousands = 7
    *set display_numb "seven thousand"
*if thousands = 8
    *set display_numb "eight thousand"
*if thousands = 9
    *set display_numb "nine thousand"
*if ((thousands > 0) and ((tens > 0) or (single > 0))) and ((hundreds < 1) and (d2n_num < 10))
    *set display_numb &" and"
    *goto tens_digit
*if ((thousands > 0) and (d2n_num > 9)) and (((hundreds < 1) and (tens < 1)) and (single < 1))
    *set display_numb &" and"
    *goto tens_digit
*if ((thousands > 0) and ((tens > 1) and (single > 0))) and (hundreds < 1)
    *set display_numb &" and"
    *goto tens_digit
*if (thousands > 0) and ((hundreds > 0) and ((tens > 0) or ((single > 0) or (d2n_num > 9))))
    *set display_numb &","
*if (thousands > 0) 
  *set display_numb &" "
*if hundreds = 1
    *set display_numb &"one hundred"
*if hundreds = 2
    *set display_numb &"two hundred"
*if hundreds = 3
    *set display_numb &"three hundred"
*if hundreds = 4
    *set display_numb &"four hundred"
*if hundreds = 5
    *set display_numb &"five hundred"
*if hundreds = 6
    *set display_numb &"six hundred"
*if hundreds = 7
    *set display_numb &"seven hundred"
*if hundreds = 8
    *set display_numb &"eight hundred"
*if hundreds = 9
    *set display_numb &"nine hundred"
*if ((hundreds > 0) and (tens < 1)) and ((single > 0) or (d2n_num > 9))
    *set display_numb &" and"
*label tens_digit
*if (hundreds > 0) 
  *set display_numb &" "    
*label teens
*if d2n_num = 10
    *set display_numb &"ten"
    *goto finish_d2n
*if d2n_num = 11
    *set display_numb &"eleven"
    *goto finish_d2n
*if d2n_num = 12
    *set display_numb &"twelve"
    *goto finish_d2n
*if d2n_num = 13
    *set display_numb &"thirteen"
    *goto finish_d2n
*if d2n_num = 14
    *set display_numb &"fourteen"
    *goto finish_d2n
*if d2n_num = 15
    *set display_numb &"fifteen"
    *goto finish_d2n
*if d2n_num = 16
    *set display_numb &"sixteen"
    *goto finish_d2n
*if d2n_num = 17
    *set display_numb &"seventeen"
    *goto finish_d2n
*if d2n_num = 18
    *set display_numb &"eighteen"
    *goto finish_d2n
*if d2n_num = 19
    *set display_numb &"nineteen"
    *goto finish_d2n
*if tens = 1
    *bug Should not be reachable
*if tens = 2
    *set display_numb &"twenty"
*if tens = 3
    *set display_numb &"thirty"
*if tens = 4
    *set display_numb &"forty"
*if tens = 5
    *set display_numb &"fifty"
*if tens = 6
    *set display_numb &"sixty"
*if tens = 7
    *set display_numb &"seventy"
*if tens = 8
    *set display_numb &"eighty"
*if tens = 9
    *set display_numb &"ninety"
*if (single > 0) and (tens > 0)
    *set display_numb &"-"
*label single_digit
*if single = 1
    *set display_numb &"one"
*if single = 2
    *set display_numb &"two"
*if single = 3
    *set display_numb &"three"
*if single = 4
    *set display_numb &"four"
*if single = 5
    *set display_numb &"five"
*if single = 6
    *set display_numb &"six"
*if single = 7
    *set display_numb &"seven"
*if single = 8
    *set display_numb &"eight"
*if single = 9
    *set display_numb &"nine"
*label finish_d2n
*if not(np)
    ${display_numb}
*set np false
*return
