*comment Choice of Rebels: Uprising written by Joel Havenstone, copyright 2017.
*comment Using ChoiceScript (copyright 2010 by Dan Fabulich) under the terms of the ChoiceScript license:
*comment  http://www.choiceofgames.com/LICENSE-1.0.txt
*text_image chap3.png center Chapter Three: Strangers in the Woods

*temp lead "you"
*temp orders "none"
*temp releasedem false
*temp simenemy false
*temp unmarked false
*temp id 0
*temp knowwhy 0
*temp askmoot false
*temp nointerro false
*temp notthere false
*temp linosqq 0
*temp lingoety 0
*temp guest "guest"
*temp tone 0
*temp tell "Tell"
*temp linch 0
*temp linch2 0
*temp forever false
*temp linbless false
*temp bpreach false
*temp horch 0
*temp horch2 0
*temp horch3 0
*temp doorway_xaos "pizza"
*temp doorch 0
*temp revival 0
*temp luse false
*temp linkid 0
*temp ransomarrow 0
*temp xroad false
*temp randfoll 0
*rand randfoll 10 20

*if rollover3 > 0
  *set rollover3 0

*if choice_randomtest
  *choice
    #Starting Ch 3, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.
      *goto postchoice
*label postchoice
*set gamgee "three"
*if demerre > 3
  *set hor_rel -5

[i]Why climb a mountain on this day, of all days?[/i] you ask yourself wearily.  The sky is cloudless, and the sun blazes with the imminent promise of summer.  You're sweating, scratched, and filthy from a long uphill scramble through dense underbrush.

But tomorrow you will move on from your current camp, which makes this the last day to investigate a promising future site.  One of your trackers discovered a mountain dell which sounds ideal: well-watered and defensible, with a fine high vantage over the wilderness but still plenty of tree cover to conceal you from Theurges.

So while most of the outlaws have taken advantage of the fine weather to go hunting, you've spent the morning clambering up a steep, brush-choked watercourse.  Most of the band's other leaders and would-be leaders have joined your exploration.

*if (bred_here) and (bred_trust > 8)
  Breden is one of them, of course.  To distract yourself from the pain of the climb, you've been considering how this trip could lead to an ideal chance to test ${xhis} loyalty.  [i]In a week or two, Zvad could "accidentally" mention our timeframe for returning here.  It would seem natural, because Breden was up here scouting it out with us…and if it's a good site, it's all the more likely that a traitor would try to find a way to pass the information on….[/i]  

  Your reverie is abruptly broken
*if not(bred_here) or (bred_trust < 9)
  You are all equally taken aback
when one of the camp scouts appears on the slope below you, whistling to attract your attention.  Alira should be ranging much closer to your current camp.  There's only one reason she would come here, and she confirms it as soon as she reaches you.  

"Strangers in the woods, ${kuria}.  Two men, one pack mule.  Both have swords on them.  Nothing else that shines, but their cloaks look like a solid, rich weave."
*page_break
You wonder immediately if they're servants of the Hegemony—but you know that if any visible sign suggested that they were Theurges or Alastors, Alira would have said so.  "Are they heading toward the camp?"

"No—toward the pass, as fast as they can."  She gestures up to the west.  "Which isn't all that fast. Young Earnn is keeping an eye on them.  He'll be leaving range-sign for us to follow, if you want to go see them for yourself, ${kuria}."

You glance over to your companions—Zvad,
*if kal_here
  ${kalt},
*if simz_here and (s_rel < 9)
  ${simon},
*if el_here
  Elery,
*if (s_rel >= 9) and (elery <1)
  Radmar,
*if bred_here
  Breden,
and three others.  All of them look mildly interested in Alira's news.  "Don't sound like traders, ${kuria}," Zvad offers.  "Not unless they've got something very small and valuable on that mule.  Must have some other reason for trying to reach Wiendrj without being seen…which means they're probably not Hegemonics, either."
*choice
  #Hmmm.  I want to see these travelers myself.
    *goto strangers
  #The strangers are less important than confirming a safe camp for my band.  I'll send one of the others to deal with them.
    You've already climbed most of the way to the new camp.  Why run off into the woods now for a couple of travelers who will probably have no intention of joining you, nor anything worth stealing?
    
    You decide whom to send back with Alira, and the orders you'll give them:
    *choice Leader Order
      #Zvad.
        #"Watch them, but let them pass unhindered unless you see good reason."
          "Aye, ${kuria}."
          *set lead "Zvad"
          *set orders "watch"
          *goto campsite
        #"Bring them back to the camp.  I want to hear what brings them to Whendward."
          "Aye, ${kuria}."
          *set lead "Zvad"
          *set orders "bring"
          *goto campsite
        #"Relieve them of their swords and anything else of value.  And find out what brings them here."
          "Aye, ${kuria}."
          *set lead "Zvad"
          *set orders "steal"
          *goto campsite
      *if kal_here
        #${kalt}.
          #"Watch them, but let them pass unhindered unless you see good reason."
            "Aye, ${kuria}."
            *set lead kalt
            *set orders "watch"
            *goto campsite
          #"Bring them back to the camp.  I want to hear what brings them to Whendward."
            "Aye, ${kuria}."
            *set lead kalt
            *set orders "bring"
            *goto campsite
          #"Relieve them of their swords and anything else of value.  And find out what brings them here."
            "Aye, ${kuria}."
            *set lead kalt
            *set orders "steal"
            *goto campsite
      *if simz_here and (s_rel < 9)
        #${simon}.
          #"Watch them, but let them pass unhindered unless you see good reason."
            "Aye, ${kuria}."
            *set lead simon
            *set orders "watch"
            *goto campsite
          #"Bring them back to the camp.  I want to hear what brings them to Whendward."
            "Aye, ${kuria}."
            *set lead simon
            *set orders "bring"
            *goto campsite
          #"Relieve them of their swords and anything else of value.  And find out what brings them here."
            The young de Firiac looks like protesting for a moment; ${zhe}'s still uncomfortable with the necessity of theft.  But ${zhe} doesn't want to publicly argue with you, and you would agree on the need for weapons.  "Aye, ${kuria}."
            *set lead simon
            *set orders "steal"
            *goto campsite
      *if el_here
        #Elery.
          #"Watch them, but let them pass unhindered unless you see good reason."
            "Aye, ${kuria}."
            *set lead "Elery"
            *set orders "watch"
            *goto campsite
          #"Bring them back to the camp.  I want to hear what brings them to Whendward."
            "Aye, ${kuria}."
            *set lead "Elery"
            *set orders "bring"
            *goto campsite
          #"Relieve them of their swords and anything else of value.  And find out what brings them here."
            "Aye, ${kuria}."
            *set lead "Elery"
            *set orders "steal"
            *goto campsite
      *if (s_rel >= 9) and not(el_here)
        #Radmar.
          #"Watch them, but let them pass unhindered unless you see good reason."
            "Aye, ${kuria}."
            *set lead "Radmar"
            *set orders "watch"
            *goto campsite
          #"Bring them back to the camp.  I want to hear what brings them to Whendward."
            "Aye, ${kuria}."
            *set lead "Radmar"
            *set orders "bring"
            *goto campsite
          #"Relieve them of their swords and anything else of value.  And find out what brings them here."
            "Aye, ${kuria}."
            *set lead "Radmar"
            *set orders "steal"
            *goto campsite
      *if bred_here
        #Breden.
          #"Watch them, but let them pass unhindered unless you see good reason."
            "Aye, ${kuria}."
            *set lead "Breden"
            *set orders "watch"
            *goto campsite
          #"Bring them back to the camp.  I want to hear what brings them to Whendward."
            "Aye, ${kuria}."
            *set lead "Breden"
            *set orders "bring"
            *goto campsite
          #"Relieve them of their swords and anything else of value.  And find out what brings them here."
            "Aye, ${kuria}."
            *set lead "Breden"
            *set orders "steal"
            *goto campsite
*label campsite
*set campsite 1
*set delelle "de Lelle"
As ${lead}, Alira, and two other outlaws start running west, the rest of you set your faces once again to the slope.  A breeze ripples to life around you, cooling your weary limbs and easing the last hour of the ascent.  

At long last you reach the promised dell—a dimple in the mountain's broad shoulder, just below its shattered crown of crags and ravines.  Tall dark evergreens blanket the area, threaded with the bright greens and whites of birch.  The tiny stream whose cascades you've been following turns out to be fed from a broad, flat pool with enough water to sustain your band for a month.  After your long, thirsty climb, the sky-blue water is irresistible. 
*fake_choice
  #I kneel at the edge, dunk my head in to cool it, then drink my fill.
    You sigh and relish the cool water running out of your tangled hair across your shoulders and chest.
    *if (simz_here and (s_rel < 9)) and (lead != simon)
      *gosub simonwash
    *if (kal_here) and (lead != kalt)
      A few yards away, you notice ${kalt} crouched and drinking more cautiously from ${zhis} hand, not relaxing for an instant.  $!{zhe} sees you looking at ${zhim} and breaks into a grin that's half-rueful, half-defiant.  "Don't think I wouldn't enjoy it too, ${kuria}.  But in strange terrain, I don't let down my guard."
      *if (bred_here) and (lead != "Breden")
        
        *comment endif
    *if (bred_here) and (lead != "Breden")
      Then the whole party is splashed as Breden flings ${xhim}self into the pond.  $!{xhe} comes up gasping and crowing with delight.  "Angels! 'S'cold!  Bloody cold!"
      *if (bred_lover >= 4) and ((kal_here) and (lead != kalt))
        ${kalt} just gives a small, disapproving shake of the head.
  #I crouch and lap from my cupped hand, keeping a wary eye on the forest and the sky.
    The rest of the raiding party follows your example.  A few splash their faces quickly with water and run wet hands through their tangled hair.  
    *if (bred_here) and (lead != "Breden")
      "Ah, for a swim," Breden says with a grin both mournful and impish.
      *if (kal_here) and (lead != kalt)
        ${kalt} just shakes ${zhis} head, 
        *if bred_lover < 4
          grinning as well; 
        *if bred_lover >= 4
          looking impatient;
        you get the feeling ${zhe}'d never let down ${zhis} guard enough for a mountain swim.
  #With a whoop, I fling myself bodily into the pool.
    The shock of the frigid water instantly drives every care from your mind.
    *if (bred_here) and (lead != "Breden")
      As you come up for air, a mighty splash tells you that Breden has just followed you in.  $!{xhe} emerges a second later, gasping and crowing with delight.  "Angels! 'S'cold!  Bloody cold!"
      *if bred_lover >= 4
        You pull ${xhim} to you for a fervent kiss, far from your father's condemning eye.
      *if bred_lover = 3
        It's hard not to feel a pang of regret, seeing ${xhim} so joyous, so full of the life that drew you to ${xhim}…but you've made your choice, and there's no going back now.
      *if (kal_here) and (lead != kalt)

        *comment endif
    *if ((simz_here) and (s_rel < 9)) and (lead != simon)

      *gosub simonwash
    *if (kal_here) and (lead != kalt)
      A few yards away, you notice ${kalt} crouched and drinking more cautiously from ${zhis} hand, not relaxing for an instant.  $!{zhe} sees you looking at ${zhim} and breaks into a grin that's half-rueful, half-defiant.  "Don't think I wouldn't enjoy it too, ${kuria}.  But in strange terrain, I don't let down my guard."
      *if ((bred_here) and (lead != "Breden")) and (bred_lover >= 4)
        $!{zhis} smile falters as Breden kisses you again.
    You enjoy a few minutes of swimming while the rest of the party refreshes themselves.
*comment endif
    
Thirst quenched, you leave the pool for the rim of the dell and its commanding view of the Whendward wilds.  From this height, you can see halfway back to Rim Square; your hometown itself is concealed by wooded ridges, but far off to the southeast you see the shimmer where forest gives way to cultivated land.  You could spy an army coming from a long way off.  "It's a fine spot, no doubt about that."

On the other side of the dell,
*if (elery > 0) and (lead != "Elery")
  Elery suddenly
  *set campsite 2
*if (elery < 1) or (lead = "Elery")
  *if lead != "Zvad"
    Zvad
  *if lead = "Zvad"
    Radmar
calls, "There are caves up here, ${kuria}.  Where the mountain starts rising again."
*if (lead = "Elery") and (lead != "Zvad")
  The big ${whend} sounds intrigued.

You turn around and squint for a moment before also picking out the dark gaps in the crags.  "Let's have a look.  Good to know if we'd be sharing the area with a bear or catamount."
*page_break
There are no immediate signs of large predators, but you quickly realize that the caves you can see are part of a far broader network of tunnels, fissures and crevices in the mountain's crown.  Some give access to ledges far above your heads, others plunge down and become steep watercourses like the one you took to get here.

"We could retreat through these in a pinch,"
*if (elery > 0) and (lead != "Elery")
  Elery calls as she clambers up to a sheltered vantage point.  "And put a few archers up here…and over there…and they could hold off a small army.  Or make it even smaller, at any rate.
*if (elery < 1) or (lead = "Elery")
  *if lead != "Zvad"
    Zvad
  *if lead = "Zvad"
    Radmar
  muses. "Aye, ${kuria}.
This is the best site we've found yet."

The sun has sunk halfway to the horizon by the time you finish exploring and leave the dell.  All the way back to camp, you're thinking through how you might use the broken mountaintop terrain in a battle against the Hegemony.  Only when you're actually greeting the perimeter guard do you suddenly remember ${lead} and Alira, and wonder how they've got on with the strangers heading for the Whendward Pass.
*goto home_camp

*label simonwash
${simon} de Firiac rushes over to you, looking concerned.  "$!{kuria}!…take care.  You'll catch your death."

You laugh and toss water in ${zhis} direction.  "That's right—you lowlanders try not to get wet in the open air, don't you?  Up in the Rim, we're made of tougher stuff."

${simon}'s lips twist as ${zhe} averts ${zhis} eyes from your wet kyrtle.  "So I've seen, ${kuria}.  Seems a silly risk to take, that's all."
*return

*label strangers 
You nod to one of your companions. "Take the lead on the mountain camp reconnaissance.  I'll go back with Alira to have a look at these travelers." 
 
"Aye, ${kuria}," ${he} replies crisply.
 
You beckon Zvad along with you; you'll want his experienced eyes on the strangers.
*if ((bred_here) and (elery > 0)) and (s_rel >= 9)
  Breden and Elery
*if ((bred_here) and (elery > 0)) and (s_rel < 9)
  Breden, Elery, and
*if not(bred_here) and (elery > 0)
  Elery and
*if (bred_here) and (elery < 1)
  Breden and
*if kal_here
  ${kalt}
*if (simz_here) and (s_rel < 9)
  ${simon}
*if (s_rel >= 9) and (elery < 1)
  Radmar
also
*if (bred_here) or (elery > 0)
  hurry
*if not(bred_here) and (elery < 1)
  hurries
to your side, clearly not intending to be left behind.
*if ((simz_here) and (s_rel < 9))
  You reckon that ${simon} has shown ${zhim}self useful and trustworthy enough to join you.
*if (bred_here) and (bred_trust > 8)
  For a moment you consider asking Breden to stay with the camp scouting party…but that would probably awaken ${xhis} suspicions that you were testing ${xhim}.  With a sigh, you let go of your morning scheme.

Alira nods her approval and gestures westward.  "Assuming they're still heading to the Pass, ${kuria}, we should be able to meet Young Earnn or pick up his trail at that ridge."
 
It takes two hours to traverse the mountain and then scramble up to the line of crags that overlooks the Whendward approach.  Alira sets a swift and seemingly effortless pace which the rest of you struggle grimly to match.  Just before you reach the top of the ridge, the scout points with satisfaction to a broken, notched branch, whispers, "Earnn," and steers you away on a trail only she can see.

For another half hour, you stay below the craggy ridgeline.  Finally, Alira raises a hand for you to stop and trills out a bird call.  Another bird answers from the brush-choked rocks above.  You drop to your bellies and crawl upward until the dappled shadows suddenly resolve themselves into a boyish scout.  Young Earnn grins at you and nods silently over the sheer drop.  You slither to the brink and look downward.
*page_break
Far below, two dun-cloaked men are guiding their mule up the stream bed toward the Whendward Pass.  They've clearly found it hard going; the stream is still swollen from winter, and spring has choked off the path with an explosion of new greenery.  Watching them stumble from rock to rock, you feel slightly better about your own aching muscles.  The two strangers look like they're on the verge of collapse, especially the stouter one, but they push on with all the speed they can muster.
 
"They keep scanning around the valley," the scout Earnn breathes.  "Seems like they know enough to keep a watch out for us.  But they jump at the wrong bird noises—the ones not even Alira could make—and I doubt they could tell us from the wind in the brush until we were in spitting distance."
*temp recontick1 false
*temp recontick2 false
*label reconchoice
*if recontick1 and recontick2

  *goto actiontime
*choice
  *if not(recontick1)
    #"Any sign of Theurgy?"
      Young Earnn shakes his head.  "Reckon if they could, they'd have sharpened their eyes by now."
      *set recontick1 true
      *goto reconchoice
  *if not(recontick2)
    #"Any guesses as to who they are?"
      *goto whotheyare
  #"Time to see what brings them here." 
    *goto actiontime
*label whotheyare
*set recontick2 true
"They don't move like woodsmen, ${kuria}," Zvad murmurs.  "And the man who bound the packs on that mule had never packed one for hard travel before.  City dwellers, I make them."

*if (kal_here) or ((simz_here) and (s_rel < 9)) 
  "Nobles,"
  *if kal_here
    ${kalt}
  *if not(kal_here)
    ${simon}
  hisses.
 
  You look over sharply, wondering if that was a note of recognition you heard in ${zhis} voice.  "What gives you that?"
 
  *if kal_here
    "The way they hold their heads and hands," ${kalt} replies gruffly. 
    *if aristo
      "Isn't that something they teach all of you, ${kuria}?  Or at least teach you to recognize, so you can know the real aristos from the pretenders?"
      
      Ignoring the gibe, you try to judge how quickly they'll move up the valley.
  *if not(kal_here)
    "I think I've seen the stout one before, ${kuria}," ${simon} confirms.  "Can't place him from this distance, though…."
  *goto reconchoice
*elseif (elery > 0)
  "Nobles?" Elery whispers, squinting down at them.  "There's something in how the stout one holds his head."
  *goto reconchoice
*elseif (bred_here)
  "Nobles?" Breden whispers, squinting down at them.  "There's something in how the stout one holds his head."
  *goto reconchoice
*else
  "Nobles?" Radmar whispers, squinting down at them.  "They look lofty-nosed enough."
  *goto reconchoice

*label actiontime
You beckon your little group back from the edge.  "Let's head around, over the ridge behind that outcrop, and meet them just below the treeline."  You'll stay hidden until you're within easy bow range.  Then you'll order your outlaws to…
*choice
  #Fix arrows on the strangers, while I tell them to throw down their swords or be killed.
    *set hor_rel -1
    *gosub hikechat
    *if kal_here
      *set horion 1
      *set hor_rel -5

      Even as he moves, though, you hear a bow twang behind you.  In an eyeblink an arrow appears in the stout noble's shoulder and his face goes blank with shock.  As he drops out of sight, everyone starts shouting—even the mule, which rears on its hind legs and brays deafeningly.

      Zvad's roar rises above it all: "${kalt}, what the…"

      "Damn it!" ${kalt} keens. Though ${zhe} is clearly the one who shot the noble, ${zhe} is clutching at ${zhis} own arm in anguish.  "Watch him!  Ware Theurgy!"  $!{zhe} tries fumblingly to nock a second arrow.
      *choice
        #Theurgy?  Kill them—quick!
          *set violence +1
          "Ware Theurgy!" you shout, echoing the injured ${kalt}—and within seconds, arrows fly from all sides to silence the protesting strangers.
          *label kalkilled
          
          *set guest "traveler"
          *set horion -10
          In the silence afterward, seeing ${kalt} holding ${zhis} arm, you suddenly think you know how ${zhe} was injured—and it had nothing to do with magic. Like many helots learning to use a bow, ${zhe} inadvertently bent ${zhis} elbow into the path of the bowstring and released some of the weight of the draw into ${zhis} own inner arm.  The bruise will be magnificent.
          
          "$!{kalt}—what just happened?" you inquire warily.
          
          "Saw him reach for a blood phial, ${kuria}," the young helot gasps, wide-eyed.  "Or something that looked damn like it."
          
          No phials are found on either body.  You settle back, trying to hide your frustration that you seem to have just killed two intriguing strangers because of a jumpy
          *if aristo
            helot. 
          *if helot
            comrade.
          ${kalt} has the good grace to look embarrassed.
          *goto murder2
        #I blink in shock, unsure what to do.
          "We're not Theurges!" shrieks the bearded traveler, but ${kalt} has already abandoned ${zhis} bow and is lunging in with a knife. $!{zhe} swiftly cuts off the strangers' screams.
          *goto kalkilled
        #I bellow for ${kalt} to stop before ${zhe} kills either stranger.
          *goto kalthold
      *label kalthold
      "${kalt}!" you grate out.  "Hold!  Damn your eyes, hold!"

      ${kalt} is still trying to draw the bow and barely slows in ${zhis} movement toward the fallen strangers.  The savage expression on ${zhis} face leaves no doubt as to ${zhis} intentions.
      *fake_choice
        #I leap down and slap sense into ${zhim}.
          As you charge ${zhim}, ${kalt}'s eyes widen with surprise and a flash of visceral terror.  For an instant ${zhis} arrow swings up toward you, and you believe ${zhe}'s going to kill you on a defensive reflex.  But it's too late to stop now.  The young helot's much-battered face snaps back as the heel of your hand connects with ${zhis} cheekbone.

          Several breaths later, you see that ${kalt}'s bow has swung outward in one hand, the arrow in ${zhis} other.  $!{zhe} stares at you with a wounded expression and slowly 
        #I grab ${zhis} bow before ${zhe} can nock another arrow.
          An instant later, and you think ${zhe}'d have put a shaft in the bearded stranger's eye…but you get your hand round the bow in time, and ${kalt}'s arrow loses purchase.  $!{kalt} howls as the bowstring stings ${zhis} fingers; ${zhe} tries to pull the weapon back, and the glare ${zhe} turns on you is so savage, for an instant you expect ${zhim} to claw at your eyes.
          
          Then ${zhe} recognizes you.  The fury barely abates in ${zhis} face, but ${zhe} halts and
        #I bark out, "Zvad, if ${kalt} doesn't stop moving, shoot ${zhim} dead."
          To your relief, ${kalt} freezes in place.  $!{zhis} eyes fly to Zvad and confirm that the big Whend has an arrow fixed on ${zhim}.  Drawing a ragged breath, ${zhe} 
      says, "This is a poor reward, Captain ${lname}."  $!{zhis} bow drops to the ground as ${zhe} cradles ${zhis} injured elbow.

      "For killing a man without my order?"  Your voice is reverberant with fury.  Seeing how ${kalt}'s holding ${zhis} arm, you're suddenly sure you know what happened. Like many helots learning to use a bow, ${zhe} inadvertently bent ${zhis} elbow into the path of the bowstring and released some of the weight of the draw into ${zhis} own inner arm.  The bruise will be magnificent.

      "For saving you from a Theurge."  ${kalt} is cool now, facing you directly.  "Did you not see him reaching for the blood phial?"

      "I'm not actually dead," a strained, faint voice rises from behind the mule.  "Certainly not a Theurge.  Though I admit, I do seem to have rather a lot of blood…."

      "Hush, kurios," hisses the other man, then calls, "We surrender, Captain ${lname}—hold fire!  Our drachems are yours.  Our weapons, our mule…just spare our lives."
      *page_break
      You stalk around ${kalt} until you can see the two strangers.  The older one is crouched over the stout man, obscuring him with his body; his wide, angry eyes implore your mercy.  You can see no sign of a blood phial anywhere.  "Unsheathe your sword slowly and slide it toward me, hilt-first," you order.  When he complies, you say, "Now step away from your companion.  We need to see how bad his wound is."

      "I can tend his wound, ${kuria} ${lname}," the lean old man demurs in a taut voice.  He unhooks a purse from the inner wall of his coat and throws it to you with a clink of coins.  "It's not mortal.  Please, just take what you will, but leave us be."
      *set wealth +22
      *set arms +2
      *choice
        #Take their money and weapons and leave them.
          *set violence +1
          "As you like, old man," you reply.  "Keep the mule—your friend looks in no condition to walk.  We may be thieves, but we don't kill those who are no enemy to us."  You glower at ${kalt} as you pick up the travelers' silver and swords.

          $!{kalt} visibly works to master ${zhis} outrage, but seeing you beckon the group to leave, ${zhe} erupts, "No enemy?  Xthonos!" $!{zhe} stalks over to you, arms rigidly outstretched. "This is too important for games. Ask the aristocrat his name. And then tell me there's no enemy here, Captain."

          The stout noble pushes away his companion with his good arm and directs a baleful stare at ${kalt}.  "Thought I was a Theurge, eh?"  His eyes shift to you; though he looks faint from blood loss, his voice remains level.  "I've told you no lies, Captain ${lname}—unlike your murderous little friend here.  And I'll tell you none now.  My name is Horion Leilatou.  I'm cousin to the Archon of Shayard.  But I'm no enemy to you or yours.  Wherever your archer saw me, I'll stake my life ${zhe} never saw me treat a helot ill."
          *set id 2
          *set delelle "Leilatou"
          
          When ${kalt} stays stubbornly silent and you don't react, Horion's voice grows imploring. "Captain. Let me and my retainer limp away from here, as you clearly intended a moment ago…and I promise, if I live and return to my estates, you'll receive more than just my gratitude and that meager purse as a reward."
          *if demerre > 3
            There's sweat on his brow; you would guess he's heard about the fate of the de Merre.
          *page_break
          "Your family are good at buying off people," ${kalt} says with cold scorn.  "Have to be, to stay on top for two decades. What do you say, Captain?  What does forgiveness cost, for bleeding the province on behalf of the Thaumatarch…."

          "Stop talking, ${kalt}," you snap.  You're well aware that the last three governors of Shayard have come from the Leilatou family.  None of the Leilatou Archons have been extraordinarily tyrannical; as ${kalt} implied, they're better known for intrigue than brutality.  On the other hand, provincial Archons rule at the pleasure of the Thaumatarch—so they must have been quite effective at keeping him happy.  And ${kalt} has a point: if the Leilatou aren't responsible for keeping Shayard in Karagond bondage, who is?
          *choice
            #Let them go—but first find out what they're doing here.
              *set hor_rel +5
              You crouch down beside the injured noble. "What brings someone so exalted to the Whendward Pass?"

              "It's much the shortest route from Shayard City to Szeric," Horion says.  His attempted shrug fails with a gasp, but he manages a pained grin.  "Can't think why you don't get more travelers through here."

              You smile back, thinly. "There are rather a lot of brambles. And you'd be well advised not to play the jester with me, kurios Leilatou."

              His grin vanishes.  "I want to meet the Pan of Szeric, ${kuria} ${lname}. And my enemies would try to stop me if they knew."

              You cast a quizzical glance at Zvad, who looks equally puzzled.  Szeric is one of the two closest districts of ${whendery}.  As far as you've heard, it's a poor, undistinguished bit of hill country; you struggle to imagine why the Archon's cousin would want to meet its top noble.  "The other passes are thoroughly patrolled by Alastors.  They couldn't protect you from these enemies?"

              Horion gives a humorless laugh. "Some of my enemies…"

              "Kurios!" the bald retainer coughs, dark eyebrows raised in warning.

              "Linos, it's clearly time to be frank."  Horion rubs his forehead with his good hand.  "My enemies command Alastors, ${kuria}. We'd be in worse danger crossing the Owlscap Pass than we are here. And I say that even now, with your arrow in my collar and that youngster drooling for my blood."
              *page_break
              *set knowwhy 2
              Alastors don't take orders from many people. Under normal circumstances, the Archon of a province is in charge of deploying its Alastors and Ecclesiasts—but the Hegemony's institutions also have separate hierarchies, answerable only to the Thaumatarach, which can override an Archon's order. "You're not talking about a family rivalry, kurios Leilatou?" you say quietly.

              Horion blinks, then shakes his head, chuckling. "Oh, Cousin Phrygia may not always see eye to eye with me—and I've not mentioned this little trip to her—but I'd hardly call her an enemy. Strategos Nomiki, on the other hand, has been known to gratuitously use the phrase 'traitor to the Hegemony' when my name arises." He sees the blank expression on your face and hastens to add, "Nomiki is the top Alastor in Shayard, ${kuria}. Their general."

              His companion Linos throws up his hands and interrupts, "Kurios, that arrow needs to come out before you spill more blood." With one eye on you, he tears a long strip off his smock and growls, "…or words."

              You fight back a laugh and raise your voice: "${kalt}: fetch agrimony and yarrow leaves. Now." Then you kneel next to Horion while Linos inspects the wound. To your relief, you can see the arrow point poking through the noble's sleeve; it seems to have pierced flesh rather than sticking in a bone. "Strategos Nomiki has left standing orders to kill you if you travel to ${whendery}, milord? Or is there something specific in Szeric to alarm the Alastors?"

              "No standing order. She'd just jump at any chance."  Horion eyes you for a moment, then clears his throat and shoots a guilty, sidelong look at his priest.  "There is, however, a…complicated rumor coming out of Szeric, ${kuria}.  It would take longer than it's worth to explain.  Indeed, I've yet to share it with my faithful companion Linos, who knows only that I intend to argue philosophy with Pan Szeric.  But I want to see what may actually be going on there, without drawing attention to it. Particularly Hegemonic attention." He yelps and grits his teeth. "Blast it, priest, that stung."

              "Barbed? Or soiled?" the bald Ecclesiast demands over your shoulder.

              "Neither," ${kalt} replies sullenly, and sets to chewing the wound-herbs you ordered.
              
              "Be grateful I'm not a vindictive man, kurios," Linos says, drying his palms and getting a good grip on ${kalt}'s arrow.  "Consider this merely the Angels' punishment for hiding the truth from your faithful companion."
              *page_break 
              Horion howls as the arrowhead pushes fully through his shoulder. The Ecclesiast snaps the shaft, pulls the half-arrow free, and swiftly binds a cataplasm of clotting leaves against the wound. Then he pats his master on his good shoulder and stands, covered in blood. "We'll come back this way after our meeting with Pan Szeric, ${kuria} ${lname}," he says in a firm voice. "There will be time then to speak of these things, and more. But if we're to descend the pass before nightfall, I need to get kurios Horion on his mule now."

              You look dubiously down at the gray-faced noble. "You won't accept our hospitality while he recovers?"

              Linos sounds chiding as he helps Horion to his feet. "With respect, ${kuria}, I'd rather he recovered in Szeric. I don't know how many of your band will share ${kalt}'s reaction."

              Horion rasps, "But we'll return…when you've had some time to prepare them for the prospect."  He sounds surprisingly sincere.
              *if (theuknown >= 10)
                "Whatever we find in Szeric…I'll want to speak more. Get your. Unique perspective."
              
              Having decided to free them, you agree with Linos that it's probably best not to keep them here talking—even though you'd like to delve more into the reasons for their travel. "Very well. Earnn here will see you safely to the pass."

              "Til our return, ${kuria}." Horion manages a bow, then struggles onto the mule with Linos's help.

              You wait until they are out of earshot and turn to ${kalt}. The young
              *if kalt = "Kalt"
                man's
              *if kalt = "Kala"
                woman's 
              rage appears to have subsided, but ${zhis} contempt for you is plain on ${zhis} face.
              *set cred_a +5
              *set cred_h -5
              *set cred_y -5
              *set horion 12
              *choice
                #Wipe the sneer off with the rebuke ${zhe} deserves.
                  You stride over to ${zhim}. "Explain yourself."

                  "Explain myself?" ${kalt}'s voice swerves incredulously upward. "I recognized a Leilatou. I shot him. That's what needs explanation here?"

                  "You seemed to think so when you cried Theurge," you say coldly. "When you kept swallowing the truth and spat out the first idiot lie that came to mind.  You're false, feckless, cowardly—and if you had any competence with the bow, you'd be a murderer to boot. So yes, explain yourself, ${zgirl}! Explain why I should trust you again.  Explain why I shouldn't give you one day to quit our woods before we hunt you down as a traitor."

                  ${kalt} inadvertently steps back, eyes white with shock. "Wha…Xthonos' sake, Captain, we're at war!  And I thought we were on the same side."

                  "And you thought we were ready to make ourselves into Conte Leilatou's first military priority? When did you plan to inform me that we had murdered her cousin? How long did you expect we would need to prepare? We barely survived the winter—you think we can survive every Phalangite in Shayard marching into Whendward this summer?" When ${zhe} falters, looking down, you lean in implacably and find ${zhis} eyes. "Don't you ever try to force my hand, ${kalt}. You disagree with me, you tell me. But if I catch you hiding the truth from me on something this important again…you'll be lucky if I give you a running start."

                  $!{zhe} retreats behind an injured scowl. "I didn't mean to…it won't happen again, Captain."
                  *set k_rel 6
                  *page_break
                  *goto wanttofound
                #Expel ${zhim} from the band.
                  "${deputy}," you say coldly. "How did this look from where you stand? From here, seems that ${kalt} decided that the leaders of the band didn't need to know that we had just murdered the Archon's cousin."

                  "Looks the same." ${deputy} gives a deliberate nod.

                  "That's hardly a small decision." You stalk over to ${kalt}. "Since you think the important decisions need to be taken out of our hands, you should really be leading your own band. I'm giving you one day to quit the Whendward Hills."

                  ${kalt}'s face goes slack with disbelief. When ${zhe} finally finds ${zhis} tongue, it's thick and unsteady. "Truly, ${kuria}? You'd let a Leilatou and his Ecclesiast walk free, but banish me?"

                  "Banishment's a kind return for treachery, ${kalt}." You lean in close. "You thought we were ready to make ourselves into Conte Leilatou's first military priority? How long did you expect we would need to prepare? We barely survived the winter—you think we can survive every Phalangite in Shayard marching into our woods this summer?"

                  "This is already a war, ${kuria}," ${kalt} retorts shrilly, dashing tears from ${zhis} cheeks with a fist. "Which side are you on?"

                  "The weaker side.  The side that can't afford idiotic gestures."  You turn away. "Alira.  Give ${kalt} your ranging pack. $!{zhe} won't be coming back to the camp with us."
                  *page_break
                  ${kalt} sounds lost. "I truly…truly thought you were the one.  I thought I could make you understand."  $!{zhe} looks around to the other bandits, then back to you.
                  *gosub kaltrant
                  ${deputy} cuts ${zhim} off before either of you can say anything more.  "${kalt}—no more.  $!{kuria} ${fname}'s right: you betrayed us when you hid who the aristo was.  Start walking."

                  The wiry young helot struggles to regain some composure. "You'll repent of this one day, ${lname}.  You and ${deputy} both."
                  *choice
                    #I walk away, ignoring ${kalt}'s threats. 
                      You beckon the rest of the scouting party after you. "We're finished here." You glance back once at ${kalt} as you pass into the woods.  All the fire has fled ${zhim}; the corners of ${zhis} mouth hang as slack as ${zhis} arms, and tears stream unchecked down either side of ${zhis} battered nose.

                      Up above the treeline, Horion Leilatou, Linos, and Young Earnn are climbing rapidly toward the pass. "Alira," you say gruffly.  "Follow ${kalt} to the edge of the woods.  Don't speak to ${zhim}, or be seen if you can help it.  If ${zhe} tries to follow the Leilatou, or if you see ${zhim} heading in the direction of the camp, kill ${zhim} at once."

                      "Aye, ${kuria}." Alira sounds subdued, but you think she'll carry out the order.
                      *set k_rel 10
                      *goto bred_chat
                    #${kalt} is bound to be a thorn in my side.  If I don't kill ${zhim} now, it'll be twice as hard later.
                      *set violence +1
                      "I'm sorry, ${kalt}."  As you close the remaining distance between you, you see ${zhis} eyes shine with the desperate yearning to win you over, stronger than any anger or contempt—or instinct for self-preservation.  Even as you draw your knife, ${kalt}'s arms stay disbelievingly outstretched, and ${zhis} reflexes are too slow to block your thrust.
                      *if ruthreal < 50
                        You've never struck a blow that felt so much like stabbing yourself.  You manage a hoarse whisper:
                        *set ruth %+10
                        *set ruthreal %+10
                      "I tried to be kind.  You replied with threats."

                      "Capt…?"  ${kalt}'s face contorts, and ${zhis} hand grapples wetly along yours.  Then both go slack, and ${zhe} slides to the earth.

                      The others stare at you in shock.  They've 
                      *if ruth < 53
                        never seen you so ruthless before—least of all to a member of the band.  "You know I'm a compassionate ${woman}," you tell them, trying to keep your voice steady.  "But
                      *if ruth > 52
                        seen your ruthlessness, but never so starkly against one of your own band.  "No mercy to enemies."  You're curt as you clean your blade.  "Especially the enemy within.
                      I'll brook no treachery."

                      *if cha = 2
                        They nod, looking shaken but persuaded.  Zvad is the first to step to your side.  
                      *if cha < 2
                        One by one, they avert their eyes from you, looking more horrified than loyal.  Zvad grimly forestalls anyone else's response.
                      "Let's get ${zhim} in the ground."
                      *set ruth %+10
                      *set k_rel -50
                      *label bred_chat
                      *set kal_here false
                      *set followers -1
                      *set nonkids -1

                      None of you feels much like talking on the journey back to the camp.  
                      *if not(bred_here)
                        Breden's voice echoes in your head, faint and bitter: [i]It's a grave offense to fall in love with ${fname} ${lname}.[/i]  You press on, hoping that your exhaustion will silence it. 
                        *page_break
                        *goto wanttofound
                      But on one uphill scramble, the scree unexpectedly skids away under your feet and Breden reaches out quickly to steady you.  "You well, ${fname}?"

                      "Fine," you reassure ${xhim}.  There's a strained note in ${xhis} voice that makes you turn.  "Are you all right?"

                      $!{xhe} nods at once, but doesn't resume walking.  At length, ${xhe} speaks again quietly.  "$!{zhe} loved you—would have followed you into the lowest dungeon of Aekos.  Was it at all hard to
                      *if k_rel > 0
                        banish
                      *if (k_rel < 0) or (s_rel < 0)
                        kill
                      ${zhim}?"

                      "I can't help what other people feel about me."  Both of you study each other for a moment.  "You think it was wrong?"

                      "No.  It needed to happen."
                      *if s_rel < 0
                        $!{xhe} sighs. "As did the Leilatou and his priest.  Now we just need to be ready to receive what comes next."
                        *page_break
                        *if unmarked
                          *goto wanttofound
                        *goto crossroads
                      $!{xhis} eyes grow bleak.  "But you should
                      *if k_rel < 0
                        also
                      have killed the Leilatou and his priest.  It won't sit well with the band."
                      *choice
                        #"Truly?  You also want all the Archon's forces coming after us?"
                          "They'll come anyway, now."  Breden gives you a sad smile and resumes ${xhis} climb.
                          
                          *goto wanttofound
                        #"Perhaps so.  But it's too late now."
                          "Too late for now, anyway."  Breden looks pensively back toward the pass.  "But if they do pass through here again, ${fname}…"

                          *goto wanttofound
                #Try to convince ${zhim} that Horion is a potential ally.
                  "You don't see it."  You pour incredulity into your voice, hoping to shock ${zhim} out of ${zhis} scorn.

                  ${kalt} snarls, "See what, Captain?  See you letting a Leilatou walk free?"  $!{zhe} is bitterly cradling ${zhis} self-injured arm.

                  "To Taratur with his family name!  That was exactly the kind of noble our rebellion needs, and you almost killed him."  You see ${kalt}'s eyes widen in shock, but give ${zhim} no chance to retort.  "What a feckless, short-sighted…nothing you just heard gave you pause?  You've still got no fear that you might have been doing a favor to the Strategos of Shayard's Alastors?"

                  "$!{kuria}—nobles lie.  Nobles who think they're about to die, doubly so."  $!{zhis} lip stays resolutely curled.  "I can't believe you'd be so naive as to swallow a single word from his lips."

                  You shake your head in exasperation.  "What if he was lying?  Then I've thrown away the chance to kill an eccentric cousin of Conte Phrygia.  You think that would bring us one step closer to ending the Thaumatarch's reign?"  ${kalt} just scowls, stubborn and wordless, so you press on.  "Of course, the blow to the Archon's honor would likely turn hunting us into her first military priority.  And you're so sure that we're ready to face that onslaught, you're willing to lie to your own leaders to bring it on."  At this, ${kalt} has the grace to look slightly ashamed.
                  *label ifgenuine
                  *page_break
                  "But if he's genuine," you continue, "he could be an irreplaceable ally inside the Archon's Palace—able to give warning when they attack us, or be an advocate for our cause to the other nobles…."

                  "To other nobles?" ${kalt} regards you with an expression of growing horror.
                  *gosub kaltrant
                  A silent moment passes after ${zhe}'s finished.  "You're wrong, ${kalt}," you finally say.  
                  *if aristo
                    "I'm not the only noble with a conscience.  This isn't a war of the helots against everyone else.  It's a war
                    *if natl > 50
                      of all Shayardenes
                    against the Thaumatarchy."

                    "I'll believe it when I see one noble not named ${orig_lname} raise their voice at a Harrowing."
                  *if helot
                    "This isn't a war of the helots against everyone else.  It's a war
                    *if natl > 50
                      of all Shayardenes
                    against the Thaumatarchy.  And if we only accept allies who have suffered as much as we've suffered…we'll lose."

                    "No, Captain.  We'll lose if our leaders go looking for friends among our natural enemies."
                  ${kalt} turns on ${zhis} heel and strides off toward the camp.  After a grim shared glance with ${deputy}, you beckon the rest of the party after ${zhim}.
                  *set k_rel 5
                  *page_break
                  *goto wanttofound
            #Bring them back to the camp and decide what to do with them later.
              *set hor_rel +1
              You sigh.  "${kalt}: fetch agrimony and yarrow leaves."  Without waiting for an answer, you stride over to Horion's retainer, the one called Linos.  "You said you could tend his wound?  Do what you can, here and now.  It's a long walk back to our camp."

              "Really, ${kuria}, while I appreciate your solicitude, there's no need…" Horion begins, a slight tremor marring his voice.

              "Kurios Leilatou," you cut in firmly.
              *choice
                #"Until I decide what to do with you, you aren't going anywhere."
                  *set hor_rel -1
                  The nobleman recoils from your blunt, slightly hostile response.  "I don't…"

                  "And I want you to live long enough to answer my questions.  So I need you mended.  After we return to the camp, I'll hear more about what brings a Leilatou to our woods."

                  "As you say, ${kuria}," Horion murmurs grudgingly.
                  *goto blastitstung
                #"As we are responsible for your injury, I must regretfully insist that you accept our hospitality."
                  *set hor_rel +1
                  Horion's lips twist into a humorless grin.  "How can I refuse so gracious an invitation?"
                  *goto blastitstung
              *label blastitstung
              Then he yelps and grits his teeth. "Blast it, priest, that stung."

              "Barbed? Or soiled?" the bald Ecclesiast demands over your shoulder.

              "Neither," ${kalt} replies sullenly, chewing the wound-herbs you ordered.
              
              Horion howls as the arrowhead pushes fully through his shoulder. The Ecclesiast snaps the shaft, pulls the half-arrow free, and holds out a brisk hand under ${kalt}'s chin; he then binds the soggy mass of clotting leaves as a cataplasm against the wound.  "By your favor, ${kuria}, give him a moment. Once I'm sure the bleeding's stopped and his heart isn't going to give out, we can bind him onto the mule."

              "As you say."  While you wait, ${deputy} conducts a more thorough search of the two strangers and their mule, but finds no concealed weapons, wealth, or blood phials—or any cargo that would explain their presence here.  "You haven't said where you were bound."

              "I want to meet the Pan of Szeric, ${kuria} ${lname}," Horion explains hoarsely as you bind him to the mule. "This is much the shortest route to his demesne."

              You cast a quizzical glance at Zvad, who looks equally puzzled.  Szeric is one of the two closest districts of ${whendery}.  As far as you've heard, it's a poor, undistinguished bit of hill country; you struggle to imagine why the Archon's cousin would want to meet its top noble.  "The longer routes do have fewer outlaws, kurios.  As your retainer mentioned earlier."

              Horion attempts a faint smile.  "Yes.  Upon reflection, perhaps we should have given more weight to that fact."
              *goto home_camp3
            #Execute them.
              *set hor_rel -5
              You heft the older man's broadsword.  "Kurios Leilatou, we aren't normally in the business of killing nobles.  But your family have oppressed Shayard for a generation.  The blood of ten thousand helots is on your hands."

              The injured nobleman crawls toward you on his knees, gabbling frantically. "I'm not your enemy, ${kuria}, for Angels' sake.  The Alastors hate me, they know I'm trying to break their power in Shayard!  They'd love for you to kill me…."
              *choice
                #"Keep talking."
                  *set knowwhy 3
                  *set linosqq 1
                  Horion Leilatou lurches to a halt, his face ashen and contorted.  "Why do you think we're in this pass, ${kuria}?  Any other route into Whendery would be thick with Alastors—why would any noble choose to risk meeting ${orig_lname}'s bandits instead?"  He doesn't wait for a reply.  "Strategos Nomiki—the general of all the Alastors in Shayard—prays Xthonos daily for my demise.  And because no one knows about this journey, if she finds out where I am, she'll see to it that I vanish, with the rest of my family none the wiser."

                  "Why would any Alastor seek to murder a Leilatou?" you ask, frowning.

                  "Xthonos knows, your family's done nothing to restrain them," ${kalt} adds, a hungry edge to ${zhis} voice.

                  "You say so?"  A bitter laugh bursts out of Horion.  "What—because we haven't brought Harrowing to an end and packed all the Alastors back to Aekos, you think we've done nothing?  Then cut my throat and be damned.  Our struggle with the Strategos may not look like your little fights here…but we'll see who's accomplished more for a free Shayard when all's said and done."  He folds over, barely catching himself on his good arm; you guess he'll swoon from blood loss in a moment.
                  *choice
                    #Take them back for more questioning.
                      You sigh and lower the broadsword.  "${kalt}: fetch agrimony and yarrow leaves."  

                      "What?" the young helot says, ${zhis} fierce glee faltering.  "Captain, what are…"

                      You whirl to ${zhim}, one finger outstretched like a blade.  "Not another word, ${kalt}.  I've had as much treachery as I'll stomach from you."  Then you walk over to Horion's retainer, the one called Linos.  "You said you could tend him?  Do it here and now.  I've got more questions, and I want him to live long enough to answer them."

                      "Aye, ${kuria}," Linos murmurs, keeping his eyes averted from yours.  Horion yelps incoherently as the priest inspects his wound.  "Barbed? Or soiled?"

                      "Neither," ${kalt} replies sullenly, chewing the wound-herbs you ordered.
                      *page_break
                      Horion howls and falls unconscious as the arrowhead pushes fully through his shoulder. The Ecclesiast snaps the shaft, pulls the half-arrow free, and holds out a brisk hand under ${kalt}'s chin; he binds the soggy mass of clotting leaves as a cataplasm against the wound.  Then he slides his master to the earth, keeping one thumb lightly against his throat.  "By your favor, ${kuria}, give him a moment. Once I'm sure the bleeding's stopped and his heart isn't going to give out, we can bind him onto the mule."

                      "As you say."  While you wait, ${deputy} conducts a more thorough search, but finds no concealed weapons, wealth, or blood phials—or any cargo that would explain their presence here.  When Horion at last stirs, Linos nods toward the mule and you begin binding him on.  "Your master didn't say where you were heading," you point out.

                      "To Szeric, ${kuria}," the bald priest replies at once.  "Kurios Horion hoped to meet with the Pan of Szeric.  The two have been corresponding for some time."

                      You cast a quizzical glance at Zvad, who looks equally puzzled.  Szeric is one of the two closest districts of ${whendery}.  As far as you've heard, it's a poor, undistinguished bit of hill country; you struggle to imagine why the Archon's cousin would want to meet its top noble. "Well, we'll hear the reason from him soon enough.  Let's get back to camp."
                      *goto home_camp3
                    #Why listen to more feeble self-justifications?  None of this changes their guilt.
                      "Have your power games in Shayard City spared a single helot life?" you ask, almost gently.  Horion responds with wordless gasps; either he's got no answer, or is beyond answering.  You lift the broadsword again.  "Well, as you say, kurios Horion: we'll see whether our rebellion can accomplish more."
                      *goto killed_em
                #Enough talking.
                  His pleas turn into a wordless scream as your sword falls.  
                  *goto killed_em
        #Bring them back to the camp.
          *set id 1
          *set delelle "de Lelle"
          You sigh.  "${kalt}: fetch agrimony and yarrow leaves."  

          "What?" the young helot says, ${zhis} fierce glee faltering.  "Captain, what are…"

          You whirl to ${zhim}, one finger outstretched like a blade.  "Not another word, ${kalt}.  I've had as much treachery as I'll stomach from you."  Then you walk over to the bald man.  "Your name?" 

          "Ecclesiast Linos, ${kuria}," the man says at once.  "Retainer to kurios Horion de Lelle."

          "You said you could tend him?  Do it here and now.  I've got more questions, and I want him to live long enough to answer them."

          "Aye, ${kuria}," Linos murmurs, keeping his eyes averted from yours.  Horion yelps incoherently as the priest inspects his wound.  "Barbed? Or soiled?"

          "Neither," ${kalt} replies sullenly, chewing the wound-herbs you ordered.
          *page_break
          Horion howls and falls unconscious as the arrowhead pushes fully through his shoulder. The Ecclesiast snaps the shaft, pulls the half-arrow free, and holds out a brisk hand under ${kalt}'s chin; he binds the soggy mass of clotting leaves as a cataplasm against the wound.  Then he slides his master to the earth, keeping one thumb lightly against his throat.  "By your favor, ${kuria}, give him a moment. Once I'm sure the bleeding's stopped and his heart isn't going to give out, we can bind him onto the mule."

          "As you say."  While you wait, ${deputy} searches them more thoroughly, but finds no concealed weapons, wealth, or blood phials.  When Horion at last stirs weakly, Linos nods toward the mule and you begin binding him on.  "Your master didn't say where you were heading," you point out.

          "To Szeric, ${kuria}," the bald priest replies swiftly.  "Kurios Horion hoped to meet with the Pan of Szeric.  The two have been corresponding for some time."

          You cast a quizzical glance at Zvad, who looks equally puzzled.  Szeric is one of the two closest districts of ${whendery}.  As far as you've heard, it's a poor, undistinguished bit of hill country. "Well, we'll hear the reason from him soon enough.  Let's get back to camp."
          *goto home_camp3
        #Finish what ${kalt} started.  I need the aristocracy to fear me.
          *set hor_rel -5
          You pick up the older man's broadsword and give it a few practice swings.  "You actually advised your friend that the Owlscap Pass was more dangerous than the Whendward?  We've got a reputation to defend, you know."

          Sweat breaks across the stranger's brow.  "$!{kuria}…by mighty Xthonos and Its Blessed Angels I pray your mercy."

          "You're an Ecclesiast?" you ask, recognizing the liturgy. 
          *if skep <= 50
            "How can you hope for mercy, who have denied it to so many others?  Justify yourself to the Angels, if They'll hear you."
          *if skep > 50
            "Clearly, you don't know anything about me.  You're about to find out firsthand just how many of your stories are lies."

          As you raise the blade, the stout noble cries out, "Wait!"
          *choice
            #Let him have his last words.
              "I'm Horion Leilatou," he gasps.  "Cousin to the Archon of Shayard.  Worth nothing dead, but quite a bit alive."
              *set id 3
              *set delelle "Leilatou"
              *choice
                #That changes things.
                  You don't lower the sword.  "That's quite the claim, kurios.  I'm supposed to believe that a Leilatou is crossing the Whendward, accompanied only by a single Ecclesiast?"

                  Horion jabs an accusatory finger over your shoulder.  "Look, ${kuria}!"  You snap your head round and find a fierce, knowing smile on ${kalt}'s face, an instant before it turns to surprised anger.  "Your lying little friend knows who I am.  Thought I was a Theurge, did you?"

                  ${kalt} spits into the fallen leaves.  "$!{kuria} ${lname}, end his babbling.  He's the enemy.  What else matters?"

                  You sigh and bring the point of the blade down.  "Damn it, ${kalt}.  You knew he was the Archon's cousin."

                  "I saw him once on my old master's estate," the young helot admits. $!{zhe} stalks over to you, an urgent plea in ${zhis} eyes.  "What does that matter?  $!{kuria}, tell me this doesn't change anything—tell me he can't buy you off!"
                  *page_break
                  "You're so sure that we're ready to be Conte Leilatou's first military priority?" you ask, anger seeping into your voice. "Tell me, ${kalt}—when did you plan to inform me and ${deputy} that we had murdered her cousin? How long did you expect we would need to prepare for every Phalangite in Shayard marching into Whendward?"  Glancing back at the cowering strangers, you leave unsaid the fact that you barely survived the winter.

                  ${kalt} swallows visibly, and ${zhis} eyes flicker to where your fingers are clenched on the sword hilt.  "Truly, ${kuria}? I didn't think it would make a difference. If it would—if we aren't already the nobles' first priority—what are we doing wrong?"  The last words burst out of ${zhim} with anguished force.

                  The two of you lock eyes in silence, which you finally break with a curt order: "Fetch agrimony and yarrow leaves."  Giving ${zhim} no chance to demur, you turn to Horion's tall, bald retainer.  "Priest, get that arrow out.  I've got questions, and I want him to live long enough to answer them."

                  Ecclesiast Linos goes to work with alacrity, lest you change your mind again—extracting the arrow with a single shriek from Horion, then binding ${kalt}'s grudgingly delivered clotting-herbs as a cataplasm against the wound.  "He'll live, by your grace, ${kuria}."

                  "Good."  You keep your voice grim.  "But, kurios Horion—don't imagine that you've yet convinced me you're worth more alive than dead."

                  "I'm grateful…for any chance to…argue the case, ${kuria}," the plump noble says faintly as he's tied to the mule.
                  *goto home_camp3
                #That seals his fate.
                  Your lips draw back from your teeth.  "Kurios—your family have kept Shayard under the Thaumatarch's yoke for a generation.  The blood of
                  *if arrog < 1
                    ten thousand helots 
                  *if arrog > 0
                    countless betrayed nobles
                  is on your hands.  So you see, your death is worth quite a lot to us."
                  
                  *goto killed_em
            #Enough talking.
              Whatever he was going to say turns into a wordless scream as your sword falls.  
              *label killed_em
              *set violence +1
              *set guest "traveler"
              Moments later, both travelers are sprawled unmoving on the rocks.  Their mule flees into the thorny undergrowth with great honks of terror.

              You rip off 
              *if id = 0
                one man's
                *set horion -10
              *if id > 0
                Horion's
                *if id = 1
                  *set horion -10
                *if id > 1
                  *set horion 0
              cloak and wipe the blood from your arms and blade.  Then you stalk back to ${kalt}, pulse hammering furiously in your throat.  "You.  The next time you shoot anyone without my orders—because you're afraid I'll be merciful? I'll leave you looking like these two.  Understood?"

              The helot stares at you.  "Understood, ${kuria}."
              *goto murder2
    "Throw down your weapons and we'll let you live."

    A voice rises shakily: "We mean no harm to you, neighbor."  A purse comes flying over the back of the animal and clinks to the path.  "There's twenty-two drachems there—and Xthonos boil me if I lie, you'd find no more silver on our bodies.  Why don't we go our separate ways in peace?"
    *choice
      #I courteously insist that they disarm.
        *set hor_rel +1
        "Kurios: 
        *if aristo
          it pains me to insist that you  
        *if helot
          I'm sorry to ask you to 
        leave yourselves defenseless," you call.  "I 
        *if aristo
          regret the indignity, and 
        fully understand your desire to retain some sort of weapon. But weapons are scarce—worth far more to us than silver.  And you have my promise that you'll come to no harm in these woods."
        *goto simonvouch
      #I brusquely give them one more chance to obey.
        *set hor_rel -1
        "For Angels' sake," you growl.  "This isn't a negotiation.  If I don't see your swords come the same way as that purse, we'll shoot the mule and have you butcher it and carry the meat back to our camp."
        *goto simonvouch
      #I just explain that we'd much rather have their weapons than their coin.
        *set hor_rel +2
        "Your swords are worth more to us than your purse, kurios," you call.  "Hand them over and you'll come to no harm."
        *label simonvouch

        *if s_rel < 9
          *set hor_rel +1
          ${simon} calls out, "$!{kuria} ${lname} is a ${woman} of ${his} word. If ${he} says you will live, you will. I vouch for ${him} on my honor as a de Firiac."

          There is a pause. "${simon} de bloody Firiac? Heard you'd been abducted, ${zgirl}. Sold to the bandits by a traitor helot."

          "I came of my own free will," ${simon} says heatedly, "seeking the ${woman} who will end Shayard's unjust subjugation to the Karagond."

          "Mmm." A sword rises slowly from behind the mule, then flips over and drops to the stony path. The rotund noble emerges, hands above his head, and beckons his companion to disarm. "Heard that too. Can't blame your father for putting the other story about, though, can you?"
          *page_break
          ${simon} blinks, sudden recognition sweeping across ${zhis} face. "You…Kurios, what are you…"

          "Manners, my dear ${zgirl}, manners. You and I know each other, but I've not been introduced to your
          *if aristo
            new liege.
          *if helot
            captain.
          I'm Horion Leilatou—cousin to the Archon of Shayard." He bows at you, ignoring the astonished glances of the other bandits.
          *set id 2
          *set delelle "Leilatou"
          *goto introhorion
        *else
          *set hor_rel -2
          "Mmm.  Is that what you told young ${simon} de Firiac before you took ${zhim} hostage?"

          You hadn't known how far the word of your abduction had spread.  "De Firiac surrendered ${zhim}self to me."

          "And now you're proposing we should do the same. How is the young…idealist, by the way? Alive? All major limbs intact?"

          "Wouldn't fetch much of a ransom any other way,"
          *if elery > 0
            Elery remarks.
          *if elery < 1
            Radmar rumbles.
          "Kurioi: I can see enough of you from this side, so let's stop pretending one jumpy mule gives you cover."
          *goto introhorion2
  #Keep their bows at their sides, while I ask the strangers what business brings them to Whendward.
    *gosub hikechat
    "If we were going to shoot you, you'd have heard bowstrings before you heard my voice," you assure them.  "Throw down your swords, come out from behind the animal, and tell me who you are."
    *label introhorion2

    After a long pause, two swords clatter onto the stony path, and the rotund noble steps cautiously into full view.  "I'm Horion de Lelle," he announces.  
    *set id 1
    *set delelle "de Lelle"
    *label introhorion
    "My Ecclesiastical companion is Linos—a long-time friend and advisor to my House.  And I have the honor of speaking to…"
 
    There's no reason to hide your identity.  "${fname} ${lname}."
 
    "Ah yes."  Horion grins winsomely as the lean man emerges to join him.  "Linos mentioned you.
    *if orig_lname != lname
      Known until recently as ${orig_lname}?
    I understand that as Archon Phrygia has embarrassingly neglected the security of Whendward Pass, you and your generous band of volunteers have assumed responsibility for passing travelers."

    Behind you, you hear Zvad chuckle. 
    *if kal_here
      Glancing around to share a grin with him, you are surprised to notice a thin-lipped ${kalt} raising ${zhis} half-drawn bow in the direction of the noble.  
      *fake_choice
        #I bark, "Arrows down, ${kalt}!  Did you hear me say otherwise?"
          "No, Captain," ${kalt} shouts back at once.
        #I leap down and slap sense into ${zhim}.
          As you charge ${zhim}, ${kalt}'s eyes widen with surprise and a flash of visceral terror.  For an instant ${zhis} arrow swings up toward you, and you believe ${zhe}'s going to kill you on a defensive reflex.  But it's too late to stop now.  The young helot's much-battered face snaps back as the heel of your hand connects with ${zhis} cheekbone.

          Several breaths later, you see that ${kalt}'s bow has swung outward in one hand, the arrow in ${zhis} other.  $!{zhe} stares at you with a wounded expression.
          
          "Did I order an attack?" you demand.
          
          "No, Captain!" ${kalt} snarls.
      "But ware Theurgy—I saw the other one reaching inside his cloak."
 
      Linos raises his empty hands slowly above his head.  "No, neighbor.  I think your eyes mislead you.  And in any case, I'm no Theurge."
 
      "Search them, ${kalt}," you order.  $!{zhe} is visibly reluctant to put ${zhis} bow down, but obeys with poor grace and roughly turns out the travelers' cloaks, coats, and saddlebags.  Finding nothing incriminating, ${zhe} shrugs and brings their purses and swords back to you.
      *page_break
    *if not(kal_here)
      You beckon Earnn down to search the strangers' coats, cloaks, and mule.
    "Yes, we're the protectors of this Pass," you confirm.  "And we don't get many visitors.  So we're always curious to find out what brings them here."
 
    "It's much the shortest route from Shayard City to Szeric," the noble shrugs.  "Can't think why you don't get more travelers through here."
    *if demerre > 3
      There's sweat on his brow; you would guess he's heard about the fate of the de Merre.
    *if ((simz_here) and (s_rel < 9)) and (id <= 1)
      *page_break
      *set hor_rel +1
      "Kurios de Lelle," ${simon} interjects, ${zhis} voice simultaneously amused and tense. "While I would not be so discourteous as to imply an untruth on your part, I believe your lapse into archaism may have given my comrades a mistaken impression."

      "Angels…is that the missing de Firiac?" Horion blinks in chagrin. "You're meant to be kidnapped or worse."

      ${simon} gives a slight shrug. "From my father's perspective, this is no doubt worse." 

      "As from mine, damn it.  One would think that if there's one place it's still possible to travel anonymously, it would be the Whendward Pass." The noble turns to you with a grimace. "Your protégé is right: it's been more than three centuries since my family went by de Lelle."
      *goto duh
    *if kal_here

      "Never heard of House de Lelle," ${kalt} cuts in abruptly.  "Where're they from when they're at home?"
      
      "The Southriding." Horion remains affable.  "Not surprised you haven't heard of us—it's been centuries since a de Lelle did anything of note."
      
      ${kalt}'s teeth show in a non-smile, and you hear ${zhis} bowstring tauten again.  "Captain ${lname}, how do we deal with spies and arrant liars?"  Every outlaw glances incredulously at the broken-nosed helot, while Horion sputters and flaps his hands.
      *choice
        #"We give them to the wolves and vultures.  If the crime's proven."
          *set hor_rel -1
          "You have some reason to think he's not who he claims to be?"
          
          *goto arrantli
        #"We don't lightly use such language of guests passing through our woods."
          *set hor_rel +1
          *goto arrantli
        #I lift an eyebrow silently, waiting for ${zhim} to explain ${zhim}self.
          "Strong language, ${kalt}," murmurs ${deputy}.
          
          *goto arrantli
      *label arrantli
      "My masters didn't respect petty nobles," ${kalt} snarls.  "But when this one visited a year ago, they treated him like a bloody Archimandrite.  Didn't call him de Lelle, either."
      
      "My family swapped the name for one in the Karagond style," Horion concedes weakly.  "A decision I always felt was a bit over-hasty.  But then, it was some three hundred years before I was born, so who am I to judge?"
      *label duh
      
      *set id 3
      *set delelle "Leilatou"
      "Leilatou,"
      *if elery > 0
        Elery
        *goto sezincred
      *elseif (bred_here)
        Breden
        *goto sezincred
      *else
        Alira
        *goto sezincred
      *label sezincred
      says incredulously. 
      
      "A lowly cousin of Her Glory the Archon. So please, let's not stand on ceremony." Horion's grin has a visible quiver at the corners.
      *if (simz_here) and (s_rel < 9)
        
        "$!{kuria} ${fname} has opened ${his} hands in welcome to me.  I'll vouch for ${his} honorable treatment of you, milord Horion."  $!{simon}'s confident words are belied by ${zhis} worried tone.
    *if id > 1

      Your mind is racing.
      *label leilexpl
      The last three governors of Shayard have come from House Leilatou.  Though the family is better known for intrigue than brutality, a provincial Archon rules at the pleasure of the Thaumatarch, so they must have been quite effective at keeping him happy. And now a Leilatou has fallen into your hands.
    *label liechoice
    *choice
      *if id > 2
        *hide_reuse #"You thought it best to lie to us, kurios Leilatou?"
          "Of course I did." Horion's tone barely hints at apology. "No disrespect meant, ${kuria}.  If you were born with so unfortunate an appendage, would you flaunt it in present company?"
          *if kal_here
            He nods to the ferociously scowling $!{kalt}.
          *goto liechoice
      *if id <= 1
        *hide_reuse #"Why Szeric?"
          *goto whysz
      *if id > 1
        *hide_reuse #"Why is the Archon's cousin going to Szeric?"
          *if knowwhy > 0
            "I swear, ${kuria}—to meet the Pan of Szeric and discuss philosophy.  As to why we've chosen the Whendward…"
            *goto admission
          *label whysz
          You glance at Zvad, who looks equally curious.  Szeric is one of the two closest districts of ${whendery}.  As far as you've heard, it's a poor, undistinguished bit of hill country.
          
          "I want to meet the Pan of Szeric.  We've been corresponding for some time, and he's a thinker of some repute.  Little to do in his demesne but think, from the sounds of it."  Horion grimaces.  "I hold some faint hope that he has a decent cellar, to carry us through the inevitable lulls in conversation."

          "And you chose to cross the Whendward rather than one of the safe passes?"
          
          *if id <= 1
            "A folly," the noble admits.  "But there are those in Grand Shayard who bear me no great love…and while the court is not yet Erezziano enough for me to fear an assassin at home, an accident in the wild borderlands would be well within the realm of the possible.  Best to go where no one would look to find me."
            *set knowwhy 1
          *if id > 1
            *label admission
            The noble looks over to his companion Linos, then sighs ruefully.  "As you'll know, ${kuria}, the 'safe' passes are only so for those whom the Alastors deign to protect.  Whereas Strategos Nomiki has been known to gratuitously use the phrase 'traitor to the Hegemony' when my name arises." He sees the blank expression on your face and hastens to add, "Nomiki…the top Alastor in Shayard, their general.  I've done my best to keep knowledge of this trip from her, for the sake of my own continued good health."
            *set knowwhy 2
          *goto liechoice
      *if knowwhy = 2
        *hide_reuse #"So you're an enemy of the Alastors, just as we are?  How very convenient."
          "It was one reason I dared this pass."  Horion's voice is entirely earnest.
          *if cred_a > 199
            "You have your admirers among the aristocracy, ${kuria},
            *if ((simz_here) and (s_rel < 9))
              and not just the mad ones like de Firiac who enjoy bedding down in the mud.
            *if (s_rel >= 9)
              notwithstanding your unfortunate habit of holding them for ransom.
            *if not(simz_here)
              notwithstanding the anarchy you've spread across the Outer Rim.
          *if cred_a < 200
            "You may not have endeared yourself to the aristocracy, ${kuria}—but in my experience, nothing brings enemies together like a stronger foe.
          Those of us who would see a freer Shayard have been following your exploits with some interest.  I half-hoped we'd encounter each other—though you'll understand that I didn't go out of my way to arrange an introduction."
          *if (theuknown >= 10)
            He swallows hard and ventures, "In particular, the rumors regarding your ${wisardry} are…a matter of considerable interest."
          *set linosqq +1
          *goto liechoice
      *if knowwhy = 2
        *hide_reuse #"What does the Alastor Strategos hold against you, kurios?"
          "Strategos Nomiki is under the unfortunate impression that I aspire to see Shayard ruled by Shayardenes, rather than a foreign hegemon," Horion says lightly.
          
          You glance at the Ecclesiast Linos, who appears remarkably unmoved.  "A most grave impression.  How did she come by it?"
          
          Horion waves a plump, dismissive hand.  "The court spawns rumor like a sewer spawns flies.  Also, I said it, rather loudly, when in my cups last Angelday."
          *set linosqq +10
          *goto liechoice
      *if linosqq > 0
        *hide_reuse #I frown.  "You're awfully free with your tongue around this Ecclesiast."
          "What, Linos?"  Horion chuckles.  "He's built up the stomach for my treasons."
          
          "Not many priests have so strong a constitution,"
          *if (bred_here)
            Breden
            *goto convenient
          *elseif elery > 0
            Elery
            *goto convenient
          *else
            Radmar
            *goto convenient
          *label convenient
          comments, cool-voiced.  You turn a dubious stare on the gray-bearded Ecclesiast.
          
          "Kurios Horion's passion for Order is easily overlooked on first acquaintance," Linos says impassively.  "Those who have known him long enough, however,
          *if linosqq > 9
            and heard him when not in his cups,
          may come to sympathize with the vision of justice that moves him."  His eyes bore into you with unsettling intensity.  "And ${kuria}, not all who wear the surplice believe that the Order of Xthonos and the Order of the Thaumatarchy are identical."
          *if introrel
            
            A memory of Ecclesiast Olynna leaps into your mind with extraordinary clarity.  Could this conceivably be another priest of her ilk?
          *set linosqq +20
          *goto liechoice
      #"Well, don't let us detain you any longer, kurios.  And keep your swords."
        *if kal_here
          ${kalt} makes an incredulous choking noise, but a glare and curt gesture from you keep ${zhim} in check.
          
        The stout, unshaven noble tilts his head to regard you warily. "That's a more generous offer than I'd expected, ${kuria} ${lname}."
        
        *if knowwhy > 1
          "I've heard enough to believe you're no enemy of ours, kurios.  And we don't rob our friends."  His look of suspicion only intensifies, but you shrug it off.  "From the sounds of it, you may need your swords out there."
        *if knowwhy < 2
          "We're not brutes, kurios.  I don't believe you mean us harm, so we'll do you none."
        
        Ecclesiast Linos is the first to pick up his weapon, while Horion just keeps staring at you. "So that's…you're letting us go?"
        
        *label inviteback
        You step aside and gesture up the pass.  "Perhaps on your return, you'll accept our hospitality for a time.  When there's no doubt that you're visiting as a guest, not a hostage.  I'm sure we have more to discuss."
        
        "I think we may, at that."  The nobleman's face unknots itself into a grin.  "We may indeed, ${kuria} ${fname}.  Thank you.  And look for us in a month's time."
        
        As the two strangers and their mule hurry away up the pass, you turn to your followers.
        *set releasedem true
        *if (cha = 2) or ((simz_here) and (s_rel < 9))
          They appear to trust your judgment in letting the noble
          *if not(kal_here)
            go.
            *if s_rel < 9
              ${simon}, in particular, is beaming from ear to ear.  "Well done, ${kuria}," ${zhe} murmurs.
            *if not(bred_here)
              *page_break
              *if id > 1
                *set horion 12
              *if id <= 1
                *set horion 11
              *goto wanttofound
            Only Breden looks discontented.
            *label breddissent
            *choice
              #Ask ${xhim} whether ${xhe}'d have chosen differently.
                "Truly, ${kuria}?" Breden shakes ${xhis} head. "I'd not have let 
                *if id > 1
                  a Leilatou and his minion 
                *if id <= 1
                  them
                pass.  Who knows what brings two like that to Whendward?  Not what they've told us—that's as close to certain as anything is."

                *if s_rel < 9
                  ${simon} scowls.  
                "So you'd have us…what?  Take them hostage?  Kill them?"
                
                "The second," Breden says coolly.  "Too difficult to collect a ransom without the Karagonds killing us all."
                *choice
                  *if (id > 1) #I try to persuade Breden to see Horion as a potential ally.
                    "You don't think
                    *if knowwhy > 1
                      that killing the Leilatou might be doing a kindness to the Strategos of the Alastors?"
                      
                      "I don't know which of his little hints were true, ${kuria}—if any."
                    *if knowwhy < 2
                      that he might be more use to us alive, and friendly?"
                      
                      "I don't think we'll ever see them again, ${kuria}—let alone as friends."
                    *label nofriend
                    Breden gazes up the pass at the retreating figures.  "All I know is that we aren't likely to have another chance to strike a blow this close to the Archon."
                    
                    "And I don't think that killing an eccentric cousin of Conte Phrygia would bring us one step closer to ending the Thaumatarch's reign," you say firmly.  "But I do think the chance of a friend in the Court of Shayard is worth a gamble."
                    *label bredcline
                    
                    Breden inclines ${xhis} head, still looking troubled.  "Well, if they do return this way, ${kuria}…we'll see how matters look then."
                    *set cred_a +5
                    *set cred_h -5
                    *set cred_y -5
                    *set horion 12
                    *page_break
                    *goto wanttofound
                  *if (id > 1) #I explain to ${xhim} that harming Horion would bring us much trouble and little good.
                    "I can't imagine that killing an eccentric cousin of Conte Phrygia will do much to weaken the Thaumatarch's grip on Shayard.  But I do think the slight to her honor would make us the Archon's foremost military priority."
              
                    "We're not already?" Breden presses.  "Don't helot rebellions come early in the list of what the Hegemony expects its governors to prevent?"

                    "She's hunted us with rather less vigor than she would someone who had struck at her family," you counter.  
                    *if s_rel < 9
                      $!{simon} nods ${zhis} forceful agreement.
                    "Perhaps we could survive more—but I wouldn't risk it just for the satisfaction of killing some traveling popinjay."
                    *goto bredcline
                  *if (id > 1) #On second thought, if we could collect it safely, Horion's ransom would get us through four bad winters.
                    *goto psych
                  *if (id <= 1) #I tell Breden that we're not in the business of killing every noble who passes by.
                    "Nor did I advise killing young ${zkuria} ${simon} when ${zhe} showed up,
                    *if arrog > 0
                      ${kuria}
                    ${fname}.  But collecting one ransom will be enough of a risk."  $!{xhe} gazes up the pass after the retreating figures. "And something felt different about these two.  Their tale rang false."
                    
                    "Not to me," you say shortly.  "Or at any rate, not enough to justify holding them, let alone killing them."
                    *goto bredcline
                  *if (id <= 1) #On second thought, if we could collect it safely, Horion's ransom would buy us more than a few rusty maces.
                    *goto psych
                  #Breden's right.  I order my outlaws to shoot to kill.
                    *goto shotintheback
              #Tell ${xhim} to cheer up.
                "That might just be a friend well made."
                
                "A friend, ${kuria}?  Perhaps, perhaps not."
                *goto nofriend
              #Ignore ${xhis} qualms and head for home.
                *set cred_a +5
                *set cred_h -5
                *set cred_y -5
                *if id > 1
                  *set horion 12
                *if id <= 1
                  *set horion 11
                *goto wanttofound
          *if kal_here
            go—with one obvious exception.
        *if cha < 2
          *set morale -4
          They look
          *if id > 1
            stunned; how could you simply release so valuable a hostage?
          *if id <= 1
            unimpressed.
          *if (simz_here) and (s_rel < 9)
            Only ${simon} looks satisfied.  "Well done, ${kuria}," ${zhe} murmurs, beaming from ear to ear.
        *if kal_here
          
          "It's not too late, Captain," ${kalt} pleads in disbelief.  "Will you truly let a Leilatou walk away alive?  A cousin to the Karagonds' most loyal lackey?"
          *choice
            #I try to convince ${zhim} that Horion is a potential ally.
              "That's exactly the kind of noble our rebellion needs—and you would kill him?"  Ignoring the uncertain murmurs from the other raiders, you keep your eyes leveled on ${kalt}.
              *if knowwhy > 1
                "You don't think that might be doing a favor to the Strategos of Shayard's Alastors?"

                "$!{kuria}—nobles lie.  Nobles at the point of an arrow, doubly so."  $!{zhis} lip stays resolutely curled.  "I can't believe you'd swallow a single word from his lips."

                You shake your head in exasperation.  "And what if he was lying?  Then I've thrown away 
              *if knowwhy < 2
                
                "Our rebellion?  As if we'll ever see him again?" $!{zhis} lip stays resolutely curled.  "$!{kuria}, that fat little bantam will get his friend in Szeric to send him back over the Owlscap with an escort of two dozen Alastors.  He'll never come near Whendward again."
                
                "Perhaps so.  Then I've thrown away
              the chance to kill an eccentric cousin of Conte Phrygia.  You think that would bring us one step closer to ending the Thaumatarch's reign?  You truly think we're ready to turn ourselves into the Archon's foremost military priority?"  ${kalt} just scowls, stubborn and wordless.
              *set cred_a +5
              *set cred_h -5
              *set cred_y -5
              *set horion 12
              *goto ifgenuine
            #I explain to ${zhim} that harming Horion would bring us much trouble and little good.
              "Do you truly think that killing an eccentric cousin of Conte Phrygia would bring us one step closer to ending the Thaumatarch's reign?"  ${kalt}'s face darkens further at your exasperated tone.  "I don't. But I do think the slight to her honor would make hunting us the Archon's foremost military priority."
              
              "And you think we're…" ${zhe} says thickly.
              
              You cut ${zhim} off.  "We're not ready.  Not now.  And certainly not for any gain as small as the satisfaction of killing some traveling popinjay."

              "What will it take, then, ${kuria} ${fname}?  If we aren't already the nobles' first priority—what are we doing wrong?"  Without waiting for an answer, ${kalt} storms back up the trail.
              *set cred_a +5
              *set cred_h -5
              *set cred_y -5
              *set horion 12
              *set k_rel 5
              *page_break
              *goto wanttofound

            #On second thought, Horion's ransom could get us through four bad winters.
              *label psych
              You stalk after the two departing strangers.  "$!{delelle}!  Do true friends ever seize on the first chance to part company?"  Embarrassment at your about-face puts genuine heat into your bluster.  "I'm wounded that you didn't insist on dining with us.  Do you hold the hospitality of the greenwood in such contempt?"
              
              As the initial horror vanishes from his face, Horion responds stiffly, "I…misunderstood, ${kuria} ${lname}.  We meant no offense."
              
              "Nonetheless, most severe offense was given."
              *if kal_here
                You glare back at ${kalt} to make sure ${zhe} doesn't take this as excuse to shoot them. 
              *if not(kal_here)
                You ignore
                *if s_rel < 9
                  ${simon}'s stricken expression
                *if (s_rel >= 9) and bred_here
                  Breden's prediction of doom
                *if (s_rel >= 9) and not(bred_here)
                  his dismay
                and continue,
              *if id <= 1
                "We'll see what your family will do to
              *if id > 1
                "In recognition of your name, we'll see whether your glorious cousin will 
              redeem your error before we make you answer for it."
              
              The downcast noble unbelts his sword and gestures to the Ecclesiast to do the same.  
              *label inyourhands
              "We are in your hands, ${kuria}.  Do with us what you will."
              *set horion +4
              *set hor_rel -5
              *goto home_camp3
            #No, ${kalt}'s right.  I order my outlaws to shoot to kill.
              *label shotintheback
              *set violence +1
              "Alira, Earnn: you can take them down cleanly from here?"  It's not really a question.
              
              "Of course, ${kuria}," Young Earnn replies in a similarly low voice, readying an arrow.  "No helms; they'll never know."
              
              *if kal_here
                You glare back at ${kalt}.  "Of course I won't let them live.  But their last thoughts will be hope, not terror.  No reason to deny them that small mercy."  
              *if (simz_here) and (s_rel < 9)
                Before ${simon}'s protest grows beyond a choked noise, you
                *goto nod
              You 
              *label nod
              nod to the two trackers, who draw and fire as one.  Forty yards up the hill, Horion and Linos drop like cloaks suddenly unpegged from a drying line.
              
              *if kal_here
                ${kalt} stares at the bodies for a moment, then shrugs.  "If that's what compassion means to you, ${kuria}, I'm all for it."
              *if not(kal_here)
                Though no sound comes from the fallen strangers, Breden runs up the slope as if ${xhe} expects an escape.  By the time the rest of you stride up to ${xhim}, ${xhe}'s crouched next to Horion's sprawled corpse, a somber but satisfied expression on ${xhis} face.  "It was well done, ${kuria}."
              *if (simz_here) and (s_rel < 9)
                
                ${simon} clutches your shoulder,
                *goto simonhorror
              *goto murder
        *if bred_here
          Breden just shakes ${xhis} head dubiously.
          *goto breddissent
        *if not(bred_here)
          "Well, they're gone now, ${kuria}."
          *if el_here
            Elery's
          *if not(el_here)
            Radmar's
          voice is flat.  "May as well be off home."
        *set horion 11
        *if id > 1
          *set horion +1
        *set cred_a +5
        *set cred_h -5
        *set cred_y -5
        *page_break
        *goto wanttofound
      #"You'll be unsurprised to hear that the price of passage through Whendward is your swords and silver."
        "Entirely reasonable." Horion nods ruefully.  "You have a pass to patrol.  It takes silver to traverse the Corlune Turnpike, as well.  May we keep our cloaks?  It's particularly cold in the high passes, I'm told."
        *choice
          #"Come to think of it, we'll need those, too."
            *set hor_rel -1
            *set violence +1
            Horion opens his mouth as if to protest—then silently unbuckles his cloak and nods to Linos to do the same.  When they're handed over, everyone shifts uneasily for a few moments.
            
            Then Horion ventures, "If we're not to freeze in the pass, ${kuria}, we'll need to set a fast pace."
            *choice
              #"On your way."
                Relief begins to soften Horion's face as it sinks in: you really are letting them go.
                *goto inviteback
              #"On second thought, kurios…I can't let you take that risk.  Why don't you come back with us."
                Horion nods mournfully, without any real surprise.
                *goto inyourhands
              #"Now that it won't soil the cloaks: kill them."
                *label arrowfly
                *set ruth %+10
                *set violence +1
                Horion and Linos barely have time to yelp and raise their arms before the arrows strike home. Their mule bolts, honking in terror.
                
                *if (simz_here) and (s_rel < 9)
                  $!{simon} whirls on you, 
                  *label simonhorror
                  mouth agape.  "You…$!{kuria}, I staked my word that they would go unharmed!"
                  
                  "The more fool you," you retort.
                  *choice
                    *if id > 2
                      #"They shouldn't have lied to me."
                        *goto deathsent
                    #"I'll not let a Leilatou pass unharmed."
                      "He could have been an ally to us, ${kuria}," ${simon} pleads, tears in ${zhis} eyes.  "He could…you're
                      *label betterthant
                      better than this.  I was sure you were better than this."
                      
                      "This is who I am, ${zmilady} de Firiac," you reply simply. "This is what we are.  Stand with us, or walk away."
                      
                      $!{simon} looks stricken.  $!{zhis} mouth works silently for several moments; then ${zhe} turns on ${zhis} heel and stalks away up the pass.
                      *set followers -1
                      *set nonkids -1
                      *choice
                        #I let ${zhim} go.
                          *label letsgo
                          *set s_rel +20
                          *set simz_here false
                          You didn't ask 
                          *if helot
                            the damned aristo
                          *if aristo
                            ${zhim} 
                          to join you in the first place, and you're not going to ask now.  Beckoning the rest of the raiding party around you, you begin the long, weary walk home.

                          *goto wanttofound
                        #I call out, "Where do you imagine you're going?"
                          "Walking away," comes the retort.  $!{zhe} doesn't look back.
                          *choice
                            #Let ${zhim} go.
                              *goto letsgo
                            #There's no walking away.
                              You give Alira an unmistakable gesture.
                              *goto shootsim
                        #I glance at Alira and gesture at her bow.
                          *label shootsim
                          *set violence +1
                          Without hesitation, the bandit tracker looses another arrow.  ${simon} abruptly lurches forward, hand clawing vainly at ${zhis} 
                          *if s_sword = 1
                            sword hilt.
                          *if s_sword != 1
                            empty hip.
                          $!{zhe} spins around just enough for you to see the disbelief in ${zhis} eyes…then pitches unceremoniously to the stones.
                          
                          No one objects.  You're sure some had liked the young de Firiac well enough, but anyone who would try to leave the band over the death of a Leilatou is fair game.  "Let's get ${zhim} in the ground," ${deputy} says quietly.
                          
                          "And the others?" Earnn asks.
                          *set ruth %+10
                          *set s_rel -50
                          *set simz_here false
                          *set morale +3
                          *goto murder
                    #"You came to join us.  They had no such intent."
                      *label deathsent
                      "And that earns them a death sentence?" ${simon} demands, shrill with outrage.  "$!{kuria}, you're
                      *goto betterthant
                *goto murder
          #"Did I ask for your cloaks?"
            *set hor_rel +1
            Your tone is level, very slightly chiding.  "The price of passage is what it is.  Don't think that false humility will avail you aught now."
            
            Horion shrugs with the resigned amusement of a man caught in a prank.  "Then…now that you have our silver and swords, ${kuria}…may we continue to the pass?"
            
            "Of course.  You've paid your way; you're no enemy of ours."
            *goto inviteback
          #"Of course you can keep your cloaks, kurios."
            "You're no enemy; we'd not send you into the winter unprotected."
            *goto inviteback
      #"Kurios, there are many things I'd like to discuss with you.  Please accept the hospitality of the Whendward Band."
        Horion pauses for a moment, as if to demur—then breaks into a smile which seems only slightly forced.  "How could we possibly refuse?  Conversation with the wardens of Whendward Pass is an unlooked-for kindness.  I've nothing new to say to Linos after all these years, and I'd been resigned to hearing nothing but old catechisms until we reached Szeric."  He bows deeply to you, and dips his head to your outlaws.  "$!{kuria} ${lname}, I am your guest, and in your hands."
        *goto home_camp3
      *if id <= 1
        #"Nobles aren't welcome here, kurioi. Make your peace with Xthonos."  I gesture to my archers.
          *set hor_rel -3
          "Wait—I'm a Leilatou!" Horion yelps, waving his arms vainly.  When he sees that your outlaws have frozen at the name, he gabbles, "Cousin to the Archon of Shayard.  Worth nothing dead, but quite a bit alive."
          *choice
            #That changes things.
              "Hold," you confirm to the archers, keeping one hand raised.  [i]Can he possibly be telling the truth?[/i]  "I'm supposed to believe a cousin of Conte Phrygia is crossing the Whendward, escorted by nothing more than one old Ecclesiast?"
              
              "Ask the de Firiac you're holding hostage," Horion pleads.  "$!{zhe}'ll know my face from the Season in Grand Shayard, ${kuria}.  $!{zhe} can confirm that I am who I claim."
              
              Your mind is racing.
              *set id 3
              *set delelle "Leilatou"
              *goto leilexpl
            #That seals his fate.
              "Kurios," you say coolly, "your House has kept Shayard under the Thaumatarch's yoke for a generation.  The blood of
              *if arrog < 1
                ten thousand helots 
              *if arrog > 0
                countless betrayed nobles
              is on your hands.  So you see, your death is worth quite a lot to us."
              
              *goto arrowfly
      *if id > 1
        #"Given your family's long service to Karagon, kurios, you can hardly expect me to let you live."
          *set hor_rel -3
          "Wait, wait!"
          *if (simz_here) and (s_rel < 9)
            Horion's voice is echoed by the shocked ${simon}'s.
          The stout noble drops to his knees.  "You don't see the whole picture, ${kuria}, I swear it. Our struggle with the Strategos may not look like rebellion to you…but she knows we could free Shayard.  That's why she wants me quietly dead.  Don't do her a kindness. Don't kill us."
          *set knowwhy 3
          *if (simz_here) and (s_rel < 9)
          
            "I've staked my honor on your mercy, ${kuria}."  ${simon} sounds nearly as desperate as the Leilatou.  "Will you take that
            *if s_sword != 1
              too
            from me?"
          *choice
            #Very well—I'll take them back for more questioning.
              "We'll bring you back to the camp.  There are questions I'd have you answer at our leisure."  You keep your voice grim.  "But kurios Horion—don't imagine that you've yet convinced me you're worth more alive than dead."

              "I'm grateful for any chance to argue the case, ${kuria}," the noble says thinly.
              *goto home_camp3
            #Enough talk.  I nod to Alira.
              *goto arrowfly
  #Shoot the strangers as soon as they come into range and loot their bodies.
    *set ruth %+25
    Your outlaws nod 
    *if not(kal_here)
      grimly.  
    *if kal_here
      grimly—${kalt} with enthusiasm.
    They understand the reason for your order:
    *choice
      #This could well be a trap.  If the strangers are Theurges, our best tactic is to kill them before they know we're here.
        Better to play it safe.  A few dead traders is a small price to pay to protect the band from a Theurgic ambush.
        *goto sneakkill
      *if (s_rel = 0) or (s_rel > 9)
        #The strangers look like nobles, and I've put it about that any nobles entering my territory will be killed on sight.
          *set anarchy +3
          *set cred_a -10
          *set cred_h +5
          *set cred_y +5
          You're determined to strike dread into the hearts of the Shayardene aristocracy, while emboldening the helotry.
          *if simz_here
            While you look forward to receiving the ransom money, you don't want anyone else to make ${simon} de Firiac's mistake; it shows that your reputation isn't nearly as fearsome as you need it to be.
          *goto sneakkill
      #To increase the legend of my ruthlessness and violence.
        *set anarchy +1
        *set cred_m -5
        *set cred_a -5
        *set cred_p -5
        Your reputation needs to be fearsome if people are going to believe you can beat the Thaumatarchy.
        *if simz_here
          *if (s_rel > 9)
            While you look forward to receiving the ransom money, you don't want anyone else to make ${simon} de Firiac's mistake.
        *goto sneakkill
      #I don't want anyone but my band to use the Whendward Pass.
        Hardly anyone uses this pass in any case, but you want total, unquestioned control over it.
        *if alaine = 2
          You don't want the least chance of interference with your smuggling arrangements.
        *goto sneakkill
    *label sneakkill

    *if (simz_here) and (s_rel < 9)
      Of course, ${simon} would argue fiercely on this in private, but for the moment ${zhe}'s determined not to overtly undermine your leadership.  When you give the order, ${zhis} face twists with helpless anger and disappointment…but ${zhe} makes no protest other than a curt shake of the head.  You know ${zhe}'ll never kill a stranger from ambush.  But you've enough other archers here, so you're not asking ${zhim} to.
      *if (s_rel = 3) or (s_rel = 2)
        It's just a shame that your
        *if s_rel = 2
          attempts to befriend
        *if s_rel = 3
          hopes of seducing
        ${simon} have foundered on your turn to brutality.
      *set s_rel 6
      
    You settle into your ambush long before the two men reach you.  From behind your boulder, you can hear their labored progress up the hill: first the thrashing of bushes, then an intermittent hum of conversation, and finally a clearly audible oath: "Pissing Angels, Linos!"

    "Please, kurios Horion," comes a second voice, which you strain to hear.  "Until we've crossed the pass, you really should keep your blasphemies low."

    "I no longer give a Diakon's damn for the bandits, Your Reverence," the first speaker wheezes. "Ha…[i]aaaarrgh![/i]"
    
    The two travelers flail backwards, arrows sprouting from their chests, then sprawl unmoving on the rocks.  Their mule flees into the thorny undergrowth with great honks of terror.
    *set horion -10
    *set guest "traveler"
    *set violence +1
    *if (simz_here) and (s_rel < 9)
      *page_break
      *set horion 0
      While the rest of your party are chasing down the mule, ${simon} de Firiac walks slowly over to the dead men.  $!{zhe} kneels as if to pray for their Elysian revival—then starts back in horrified shock.  "Angels!" ${zhe} wails. "Ah, Angels, ${kuria}.  What have we done?"
      
      "You know them?"  That much is plain from ${zhis} face.
      
      "Know them?  $!{kuria}…this is a Leilatou.  Ah, Angels, this is the Archon's cousin.  I've seen him in court."  ${simon} points one shaking hand at a tall, soft-bellied man.  The corpse's round face is a rictus of confused fear.
      
      Hearing it, you feel a mix of terror and exhilaration clench in your own belly.  The last three governors of Shayard have come from House Leilatou.  Though the family is better known for intrigue than brutality, a provincial Archon can hardly allow the murder of her cousin to pass unanswered.  And she has all the resources of the Hegemony's greatest province to send after you.
      *fake_choice
        #I'm horrified.  We're not ready to be the Conte Phrygia Leilatou's top military priority.
        #I'm elated.  I couldn't have imagined that we'd be able to strike so close to the heart of power from out here in the wilderness.
        #I don't know what to think.  What by Taratur was the Archon's bloody cousin doing in these woods?
      $!{simon} regains control and gives a bleak shake of ${zhis} head.  "If this is discovered, ${kuria}…Shayard will send force sufficient to eradicate us.  We must not let it be known that we just killed Horion Leilatou."
    *goto murder2

*label hikechat
You settle into your ambush long before the two men reach you.  From behind your boulder, you can hear their labored progress up the hill: first the thrashing of bushes, then an intermittent hum of conversation, and finally a clearly audible oath: "Pissing Angels, Linos!"

"Please, kurios Horion," comes a second voice, which you strain to hear.  "Until we've crossed the pass, you really should keep your blasphemies low."

"I no longer give a Diakon's damn…for the bandits, Your Reverence," the first speaker wheezes.  
*if aristo
  He has the unmistakable, resonant accent of the Shayard City nobility.
"Had you properly warned me about the brambles…I'd have chosen the Owlscap route."

"I did try to do justice to the relative perils of the Whendward, kurios," the second man replies, exhaustion and amusement warring in his voice.  "Fewer eyes.  Fewer enemies.  More vegetation.  I apologize if I understated the latter."

"Hush.  And help me free my damned legs."  You hear much rustling and snapping, and a mule bray.  A minute later, the plaintive voice resumes, somewhat subdued but much closer to you.  "Are there 
*if (theuknown >= 10)
  dreadful sorcerer 
bandits on the Whendery side too? Or shall I be free to curse as I please?"

You whistle to the other outlaws, vault to the top of the boulder, and say, "We mostly keep to the Shayard side, kurios. The hunting's worse in ${whendery}."
*page_break
You see the two men clearly for the first time as they lurch away from you with startled yells.  Both are tall, but the first speaker is rounder and softer: bulbous belly, floppy hair, moon face traced with sparse stubble and the gentle wrinkles of middle age.  The second man is wiry and visibly older; his weathered head is hairless except for his ferocious black eyebrows and the close-cropped gray beard on his chin.  He recovers first from the shock, seizing his companion by the shoulders to drag him behind the mule. 

*return

*label kaltrant
*if helot
  "You never lost family to a Harrower, did you, Captain?"

  You recoil with a surge of defensive anger. "I lost plenty of people I grew up with—people I cared about.  What does that have to…"
*if aristo
  "Do you care about helots at all, ${kuria}?  For all your fine words, what would look different in a Shayard ruled by House ${lname}?"

  "I've risked everything to end Harrowing," you reply, trying not to sound defensive.

${kalt} cuts in savagely. "If you'd lost your own flesh and blood, you might find it harder to haggle with the ones who grew fat off it!"  $!{zhe} strides across the clearing. "Make no mistake, ${kuria}, the nobles of Shayard understand what's at stake. Even the ones who hate Karagon know that if the Harrowing of helots stops, all their wealth and comfort will dry up and blow away.  If you're not frightening them, all of them—if you're not their first military priority—then you're doing it wrong."

*return

*label murder
*if id <= 1
  *set horion -10
*if id > 1
  *set horion 0
*label murder2
*set notthere true
*set ruth %+10
*set ruthreal %+10
*set guest "traveler"
*choice
  #We bring the bodies back with us, to be left in some appropriately conspicuous place.
    *if s_rel < 0
      *goto bred_chat
    *if (simz_here) and (s_rel < 9)
      "What?"  ${simon}'s control is clearly beginning to unravel again.  "$!{kuria}! Have you lost y…have you not heard a thing I've said?"
      
      "${simon}.  There's no undoing what we've done—and no keeping the secret."  You place a calming hand on ${zhis} arm, though your own nerves are frayed to near-snapping.  "You think no one knows this Leilatou was here?  When he goes missing, whether there's a body or not, the blame will fall to us."
      
      "So you're going to embrace it?"  The young de Firiac stares at you, wild-eyed.  "Admit that we murdered him?"
      
      "Yes.  The Archon's vengeance is coming, no matter what we do.  But if it's widely known that we did it—that we were able to strike at her own cousin?  It will draw others off the fence.  Who else has done so much, dared so much?  It gives other would-be rebels their best reason yet to join us."  You lower your voice so only ${zhe} is likely to hear it.  "${simon}, the forbearance that drew you to us will drive others away.  They won't believe we have the ruthlessness to survive.  Killing this lone Leilatou proves that we have teeth."
      
      ${simon} takes a deep breath.  $!{zhe} still looks unconvinced and repelled, but ${zhe} no longer looks on the verge of walking away from you.
    
    *goto crossroads
  #We bury them in the woods.  Best if no one outside the band ever knows they were here.
    *goto unmarkedgrave

*label home_camp
*page_break
*if lead = "Zvad"
  *if orders = "watch"
    At first, Zvad is much more interested in hearing about your reconnaissance.  When you persist in asking about the strangers, the broad-shouldered ${whend} shrugs. "Odd ones, ${kuria}.  A stout noble and his priest retainer, from what I could hear of their converse.  If I'd heard anything that hinted at wealth on that mule, I'd have stopped them for a look…but it looked like bundles of food, garb, and a tent.  So as you said…they never knew we were there."
    
    You rub your chin, wondering again why a noble would risk traversing your woods.  "They'll be over the pass now?"  Zvad just nods.
    *label wellifpass
    "Well, if they pass this way on their return, we'll ask more of them."  Putting the travelers out of your mind, you begin describing the new camp to ${lead}.
    *set horion 10
    *page_break
    *goto wanttofound
  *if orders = "bring"
    *set hor_guard "Zvad"
    *label hereweare
    *set id 1
    You see the thick cluster of outlaws before you spot ${lead} in the middle with the two fretful-looking strangers.  Both of the travelers are tall, but one is rounder and softer: bulbous belly, floppy hair, moon face traced with sparse stubble and the gentle wrinkles of middle age.  The second man is wiry and visibly older; his weathered head is hairless except for his ferocious black eyebrows and the close-cropped gray beard on his chin.
    
    ${lead} spies you and beckons you over.  "$!{kuria} ${lname}.  
    *if lead = simon
      May I introduce our guests to you in private?"  There's a strained look in ${zhis} eyes that belies ${zhis} calm, cheery voice.

      *goto simonintrohor
    This is Horion de Lelle and his retainer, Ecclesiast Linos.  
    *if orders = "bring"
      I've brought them back as you asked."
    *if orders = "steal"
      Their story was odd enough that I thought I'd best bring them back."

    The plump Horion gives you a bow; his beaming smile is slightly belied by the sweat sheen on his forehead.  "Ah, my dear ${kuria}!  It's both a pleasure and an honor.  Your name is renowned even in the Southriding.  I understand that as Archon Phrygia has embarrassingly neglected the security of Whendward Pass, you and your generous band of volunteers have assumed responsibility for passing travelers."
    
    The mostly unsmiling crowd of bandits looks to you, clearly wondering how you intend to welcome this aristocrat and his priest.
    *choice
      #I greet them warmly.
        *set hor_rel +2
        "I'm honored that you accepted my invitation, kurios de Lelle."
        *if helot
          After a lifetime's training in deference, it's harder than you'd expected to hold your head up and speak above a murmur.  You do your best to recall how you've heard the nobility greet each other, and repeat it as if you were yourself one of Them.
        *if aristo
          You return the bow, with the flourish that signifies sincerity.
        *if cha < 2
          *set morale -2
          Many of the other outlaws look sour at your friendly tone.  
        "If I may ask: what brings so exalted a presence across the Whendward?"
        
        The moon-faced aristo seems put at ease by your tone.  "Oh, it's much the shortest route to Szeric.  Can't think why you don't have visitors through here all the time."
        
        Zvad shrugs at your quizzical glance.  Szeric is one of the two closest districts of ${whendery}.  As far as you've heard, it's a poor, undistinguished bit of hill country.  
        *if helot
          "And what draws you there, kurios?"
        *if aristo
          "Indeed…can't think why."  You arch an eyebrow.

        "I've been corresponding with the Pan of Szeric on matters philosophical for some time, and felt it was past time we met in person.  Little to do in his demesne but philosophize, from the sounds of it."  Horion grimaces.  "I hold some faint hope that he has a decent cellar, to carry us through the inevitable lulls in conversation."
        
        Though not satisfied by his glib answer, you think you'll save further questions for a more private conversation—including with the impassive Ecclesiast Linos.  
        *if helot
          "Well, the hospitality of Szeric will shame ours—but 
        *if aristo
          "Alas, our cellar is unlikely to compete.  But  
        what we have is yours, kurios." You
        *goto campyouask
      #I demand to know why they're trespassing on our range.
        *set hor_rel -3
        *if helot
          After a lifetime's training in deference, it's harder than you'd expected to hold your head up and speak above a murmur to this noble.   For a moment, you can't say anything at all.  Then you give full vent to your anger, letting it breach those walls inside you.
        "You're mistaken, kurios.  We're no protectors.  We're at war with the Hegemony and all its servants."  You rest your eyes forbiddingly on the Ecclesiast.  "And you say you're travelers.  I say trespassers—or worse, spies.  You'd best start trying to convince me otherwise."
        
        *set morale +2
        *set knowwhy 1
        A growl of assent rises from most of the other outlaws around you.  Horion de Lelle 
        *label notspies
        instantly loses his smile and takes on a pleading tone.  "Forgive us, ${kuria}.  We mean no harm—and in truth, we have no love for the Karagonds and their Thaumatarch, or we would never have dared these woods!  Nor did we seek you out, to spy upon you.  We are traveling to Szeric, whose lord is a philosopher like myself."  He senses your skeptical reaction; Szeric is one of the two closest districts of ${whendery}, and you've only heard it described as a poor, undistinguished bit of hill country.  "Unpromising corners of the continent often hold its cleverest thinkers, ${kuria}.  It may be hard to credit, but the Pan of Szeric is a philosopher of some repute.  And we're taking your pass not only because it's the shortest route…but because it's the one my enemies are least likely to be watching…."
        
        Holding up one hand, you cut him off.  This talk of enemies is intriguing, but you'd rather question them on it privately—and separately.  "Enough.  I'm trail-weary and there's much yet to be done before I dine.  Tomorrow, I'll hear more."  You
        *goto campyouask
      #I don't speak to him at all.  That can wait for their interrogation.
        *set hor_rel -5
        "Where did they say they were bound?" you ask ${lead} coldly, ignoring the perspiring noble and his priest.
        
        "To Szeric."
        
        Szeric is one of the two closest districts of ${whendery}.  As far as you've heard, it's a poor, undistinguished bit of hill country.  "They truly expect us to believe there's something in Szeric worth visiting?"
        
        "The Pan of Szeric is a philosopher of some repute, ${kuria}," Horion cuts in with a desperate smile.  "He and I have been in correspondence for some years…."  Your glare silences him.
        *if helot
          After a lifetime's training in deference, it's impossibly sweet to wield that wordless, all-too-familiar power.

        "We're all trail-weary.  Tomorrow, we'll get answers we can believe."  You
        *goto campyouask
        
  *if orders = "steal"
    *label thefty
    *set arms +2
    *set wealth +22
    ${lead} displays two swords and a modest purse of silver.  "Also brought back their mule.  They had little enough else on them; whatever they need, they can carry across the pass.  They were a pair of philosophers, one noble, one priest.  Named Horion and Linos."
    
    "Philosophers?"  You blink in surprise.  "In the Whendward?"
    
    ${lead} nods with amusement.  "Off to see the Pan of Szeric.  Apparently he's a sophist too.  Don't think they properly realized what they were doing when they picked the shortest route."
    
    "Curious."  Could any noble really be so cloud-skulled as to choose a wilderness pass just because it's the shortest route as the hawk flies?
    *goto wellifpass
    
*if lead = "Elery"
  *if orders = "watch"
    You find Elery at dinner, and she 
    *label erfillin
    fills you in while you gnaw your way through barley loaves and stew.  "Odd ones, ${kuria}.  A stout noble and his priest retainer, from what I could hear of their converse.  If I'd heard anything that hinted at wealth on that mule, I'd have stopped them for a look…but it looked like bundles of food, garb, and a tent.  So as you said…they never knew we were there."
    
    You nod, wondering again why a noble would risk traversing your woods.  "They'll be over the pass now?"
    
    "Aye."
    
    *goto wellifpass
  *if orders = "bring"
    *set hor_guard "Elery"
    *goto hereweare
    
  *if orders = "steal"
    *set arms +2
    *set wealth +22
    *set hor_guard "Elery"
    *goto hereweare

*if lead = kalt
  *set arms +2
  *set wealth +22
  *set horion -10
  *set notoriety +100
  *set anarchy +5
  *if orders = "steal"
    *set violence +1
  As soon as you re-enter camp, ${kalt} strides over and greets you tautly.  "Thank Angels you're safe, ${kuria}.  No Theurges in the woods, then…save the two you sent me after?"

  "What?"  You scan ${zhim} for wounds, then search out the other trackers in the crowd.  When you spy Alira, something immediately strikes you as wrong; she has the flustered, angry look of someone who's just walked away from a fruitless argument, not someone who's narrowly escaped death.  "You all survived?  Unscathed?"

  "We heard them talking Theurgy—so I made sure I had them down an arrow when we hailed them.  And when they slipped their hands down to do their magic…"  ${kalt} shrugs stiffly.  "Had to move fast, ${kuria}."
  
  The wrongness begins to make sense.  "You found blood phials on their bodies?"

  "No.  But
  *if int < 2
    I've heard
  it doesn't always take 
  *if int < 2
    phials.
  *if int = 2
    phials, does it, ${kuria}?
    *if (theuknown > 4)
      Not for such as you.
  Some are able to kill folk with just a gesture.  And this one was gesturing."  $!{zhe} folds ${zhis} arms and stares at you unrepentantly.

  *if (theuknown > 4)
    "It needs a lot more than a damned gesture."
  You beckon Alira over, feeling your temper rise.  "So what you're saying is that we'll never know if they were Theurges.
  *if orders = "watch"
    What by Taratur were you doing hailing them, when all I told you to do was watch?"

    "One looked like he was catching wind of us."  At this, Alira clears her throat with a scowl, but ${kalt} presses on.  "I trusted my gut, ${kuria}.  And I still think it saved our lives.  Possibly all of ours, if they'd been spying.  Who knows what they'd already seen
  *if orders != "watch"
    Most likely, they were just nobles."

    "Most likely they were spies."   At this, Alira clears her throat with a scowl, but ${kalt} tosses you a pouch of drachems and two swords.
    *if orders = "steal"
      "Here's what you asked me for—and there was nothing
    *if orders != "steal"
      "Nothing 
    more than this on them.  It's common sense, ${kuria}.  No one sets out across a smuggler's pass with nothing to trade.  Can we take the chance that they were heading back with a full account 
  of how we move and keep watch?"

  Alira says grimly, "Nothing I saw made them out a threat, ${kuria}.  A couple of harmless eccentrics, I'd have said."
  *choice
    #I rebuke ${kalt} publicly.
      Your scornful voice carries across the camp, cutting off any retort from ${kalt}.  "Theurges?  Spies?  Stop adding nonsense to nonsense, ${kalt}—it only makes your error look worse."  Dozens of heads turn, and ${kalt}'s face twists with furious shame.  You press on:
      *set k_rel 6
      *choice
        #"We're not a gang of brigands, murdering any passing stranger."
          *set ruth %-5
          "You killed those two men without reason.  It'll make us look like beasts of Xaos.  It plays into the hands of the Archon and the Thaumatarchy."

          ${kalt}'s eyes burn into yours.  "We're fighting a war, ${kuria} ${lname}.  We treat the enemy like the beasts they are.  Else we're fighting it wrong."

          "But you don't even know that they were the enemy,"
          *label counteranger
          you counter angrily.  "Nothing you've given me so far stands up to a puff of wind.  You killed them based on a guess."

          ${kalt} opens ${zhis} mouth, then bites back whatever ${zhe} had been about to say. "Reckon it was a good guess.  See if anyone even notices they're gone, ${kuria}.  One of us might have occasion to change our mind."
          *page_break
          *goto wanttofound
        #"It's reckless to stick an arrow into someone before we know who they are."
          "You should have enough sense to get a bit more of a story off them first.  They could have been useful to us.  Or they could have family who'll come hunting us."

          "We're fighing a war, ${kuria} ${lname}."  ${kalt} sounds incredulous.  "Believe me, they were on the other side.  And their friends and relations, too."

          "You don't know that, damn it,"
          *goto counteranger
        #"Don't ever ignore my orders again."
          *goto colddefy
    #I quietly tell ${zhim} not to expect to be given the lead on a raid again.
      *set k_rel 5
      "At least not until you've learned to do as you're asked."

      *label colddefy
      ${kalt} stares at you with cold defiance.  "I'll put saving our lives over following orders any day.  And that's the kind of raid leader you need, ${kuria}—even if just now you're too bloody-eyed to see it."

      "You weren't saving anyone's life,"
      *goto counteranger
    #I shrug it off.  It will have increased our reputation for ferocity, at least.
      *set ruth %+10
      You put out placating hands to both ${kalt} and Alira. "It was probably a mistake. But you did what you thought you had to.  And at the least, it'll put the fear into a few more of the enemy."

      ${kalt} beams at the unexpected vindication.  "Aye, ${kuria}. That it will, when they hear of it."

      "So we need to ensure they hear of it."  You aren't going to let ${zhim} off entirely for ignoring orders.  "Take their mule back out there tomorrow, load up their bodies, and drop them at the crossroad outside Rim Square."

      ${kalt}'s face falls at the prospect of several long days' hard work.  When you don't assign anyone else to help ${zhim}, ${zhe} straightens ${zhis} shoulders with a wry chuckle.  "So it shall be done, ${kuria}."
      *set xroad true
      *page_break
      *goto wanttofound
  
*if lead = simon
  *if (orders = "watch") or (orders = "steal")
    You find ${simon} sitting cross-legged in the Leaders' Tent; ${zhe} scrambles up and bows as you enter.  "$!{kuria}.  How was the camp?"

    "It'll serve well."  You briefly describe the pool, crags, and caves.  "And what of your two strangers?"

    ${simon} grins wryly and shakes ${zhis} head.  "Nothing of interest, ${kuria}.  Two eccentrics—philosophers traveling from the Southriding to ${whendery} by the shortest route.  I suppose it made sense when they looked at a map."
    *if orders = "steal"
      *set arms +2
      *set wealth +22
      $!{zhe} gestures to two swords along the tent wall.  "Besides their swords and a bit of coin, there was naught to bring back."

      After waiting for a few moments, you tilt your head to one side.  "What—no complaint about being asked to play the thief?  Even now that it's just the two of us?  No homily on an honest rebellion?"

      The young noble's equanimity dissolves into flustered stammering.  "I, I…well, I've argued that before.  To no avail.  What…what use in trying to change your mind again?"

      In the time you've known ${simon}, you've never seen ${zhim} tire of trying to argue people into their better selves.  You sense something under the surface here—something ${zhe}'s trying to keep from you.  "You knew them?"

      "What makes you…no.  No, ${kuria}, I've never met them before."
      *choice
        #$!{zhe}'s acting strangely, but I let it go.
          You don't want to alienate the young noble by pushing too hard.  If there were anything significant going on, you'd trust ${simon} to tell you.

          *goto wanttofound
        #"But you recognized them?" I gently probe.
          *set id 2
          *set delelle "Leilatou"
          ${simon} moistens ${zhis} lips before continuing.  "One was an Ecclesiast I'd never even seen.  However, it is possible…if memory serves me from my single Season in Grand Shayard…that the other traveler was a lesser member of House Leilatou."

          "What?"  You stare at ${zhim} in disbelief.  The last three governors of Shayard have come from the Leilatou family; they're the most powerful House between here and Karagon.  "'If memory serves?'  You took his sword, but not his name?"

          "Well.  I greeted him as [i]kurios Horion[/i], and he answered to it," ${simon} admits.  "So yes, it is likely…I believe…he was one Horion Leilatou, a cousin to Conte Phrygia.  My father spoke of him as an amiable, harmless fellow, not deeply involved in politics."

          "Angels, ${simon}."  Your head is still reeling from the idea that a cousin of the Archon has passed a few hours' walk from your camp—and from ${simon}'s half-hearted attempt to hide the fact.  "What's any Leilatou doing in our woods?"  
          
          "As I said, ${kuria}—taking the shortest route to Szeric in ${whendery}, to debate philosophy with the Pan of that obscure district.  Or, or so he said.  He was happy to pay us for passage."  The young de Firiac tosses you a purse of silver, and gestures weakly again at the two blades.
          *label simadmit
          *choice
            *if (simenemy) 
              *hide_reuse #"You would fight your fellow rebels to spare an enemy?"
                ${simon}'s face turns to anguish.  "To spare a guest, ${kuria}.  One who might not be an enemy, were he not treated as one.  I'd hoped you at least would see that."
              
                *goto angrysimz
            *hide_reuse #"You believed his ridiculous story?"
              "I had no reason to doubt it, ${kuria}," ${simon} retorts, regaining some of ${zhis} usual poise.  "What else would bring them here?  They weren't smugglers, that's a certainty.  They barely brought supplies enough to keep body and soul together."
              
              "Spying on our camp?  Assessing routes through the wild for the Phalangites to follow?"
              
              $!{zhe} shakes ${zhis} head vehemently.  "I don't believe it.  And you wouldn't either, had you been there to hear their conversation. Both before and after I halted them.  They were hiding from us, ${kuria}.  They thought you'd abducted me—that's the story my father's put about, it seems.  And no army would send them to spy out a route!  They were, to put it kindly, no woodsmen."
              *goto simadmit
            *hide_reuse #"And you didn't see fit to bring this Leilatou and his companion back to me?"
              ${simon} runs ${zhis} hands fretfully through ${zhis} hair.  "You did not order me to do so, ${kuria}.  I felt that left me free to exercise judgment."
              
              You throw your own hands up in exasperation.  "Yes!  Yes, it did!  It's the failure of judgment that I'm struggling to understand."
              
              "$!{kuria}, you may not be aware of it…"  The rebel aristocrat looks pained.  "But I have not been welcomed by everyone in the band.  There are many who barely suffer my presence, and a few who might have been inclined to do me violence, were they not deterred by my reputation as a blademaster."
              
              You knew ${simon} was not universally welcome
              *if kids > 2
                (though the children all love ${zhim})
              but you hadn't thought ${zhe} was under physical threat.  "You were afraid to bring a Leilatou to our camp?"
              
              "I was afraid that if I did—if I invited the man back as a guest, under sacred guest-right—I would have to fight to protect him from those who could only see an enemy."  ${simon}'s eyes search out yours imploringly.
              *set simenemy true
              *goto simadmit
            *if (not(simenemy)) 
              *hide_reuse #"You allowed one of our greatest enemies to pass unhindered?"
                "I do not count him an enemy," ${simon} says steadily.  "Why make him an enemy by treating him as one?  If a de Firiac can join your revolt, why might not a Leilatou?"
              
                "A Leilatou would not.  Not in a thousand years."
                *label angrysimz
                You struggle to keep your anger from your voice.  "Damn it all,
                *if helot
                  mil…${simon}, 
                *if aristo
                  ${simon}, 
                *if helot
                  they're not 
                *if aristo
                  those Grand Shayard Houses won't be
                like you.  They've too much to lose if we win, and too great an interest in keeping the Hegemony in power.  We can't pretend that the Leilatou, of all people, would be our allies.  They're enemies unless proven otherwise."
              
                "I'm grieved to know your mind on this, ${kuria}."  ${simon} stares at ${zhis} boots for a moment; then ${zhis} eyes flash hotly back up to you.  "You're wrong.  Wrong, and good people will die for it.  You can't expect everyone to prove their loyalty by running off to join you like I did!  There are many others who would support us in quieter ways, if given the chance.  Even at the heights of power…even the Leilatou, or those close to them, anyway.  If you don't make them all into enemies."
                *goto simadmit
            #"When exactly did you plan to tell me?"
              ${simon} swallows repeatedly as if against a knot in ${zhis} throat.  "I don't know, ${kuria}.  Before he returned this way.  When there was time to talk with you properly about what we should do.  Time to prepare the band for the idea of hosting a noble guest."
              
              "But not until he was far enough away that I couldn't have him fetched back tomorrow."
              
              "Yes."  ${simon}'s mouth twists. "Yes, that's the full truth of it, ${kuria}.  Perhaps I should have been readier to lie to you now.  As it is, I've failed."
              *achieve simzlie
              *choice
                #I send a party led by Ciels and Alira to bring the two travelers back to our camp.
                  You dismiss the miserable ${simon} and swiftly dispatch your best trackers after the Leilatou and his priest.  

                  Four days later, you hear a commotion and look out from your tent to see your two "guests" arriving.  Both are tall, but the one you take to be Horion is rounder and softer: bulbous belly, floppy hair, moon face traced with sparse stubble and the gentle wrinkles of middle age.  The Ecclesiast is wiry and visibly older; his weathered head is hairless except for his ferocious black eyebrows and the close-cropped gray beard on his chin.  They're visibly fighting panic as Ciels beckons them into the boisterous crowd of outlaws.

                  ${simon} de Firiac runs up to you, ${zhis} face drawn with worry and guilt.  "$!{kuria}, I urge you…treat them as you would myself.  Don't assume kurios Horion is an enemy merely thanks to his family name."
                  *choice
                    #I ask ${zhim} to protect them while they're here.  That should set ${zhis} mind at ease.
                      *set hor_guard simon
                      $!{simon} beams at you in relief.  "Thank you, ${kuria} ${fname}.  I'll ensure they come to no harm."

                      You
                      *goto campyouask
                    #I tell him they're our guests, and that Zvad will ensure they're well looked after.
                      *set hor_guard "Zvad"
                      The young de Firiac beams at you in relief.  "Thank you, ${kuria} ${fname}.  I'll be sure they know they'll come to no harm."

                      You
                      *goto campyouask
                    #I make no promises.
                      *set hor_guard "Zvad"
                      Silencing ${simon} with a stern look, you
                      *goto campyouask
                #I send raiders to kill Horion Leilatou.  When else will we have the chance to strike so close to the Archon's heart?
                  *set horion 0
                  *set notoriety +100
                  *set anarchy +5
                  Radmar is eager to take the mission, and while Ciels looks unconvinced at first, ${he} sits up with a start when you tell them that their quarry is a Leilatou.  "Angels.  And the de Firiac let them go?"  

                  "I'd not given orders to bring them in," you say placatingly, not wanting fights to start within the band.  "$!{zhe} informed me in time to go after them—that's the main thing."

                  "The Archon's cousin," Radmar rumbles, eyes alight. "That'll turn heads across Shayard."

                  "And turn crushing us into the Archon's first priority," Ciels points out.  "Are we ready for that?"

                  "She'll do her best to crush us anyway."  You keep your voice matter-of-fact.  "And however ready we are, that's going to hurt us—make no mistake.  But this is a chance to hurt her that won't come round again."

                  Ciels stares distractedly out of the tent for a few moments more, then gives a sharp nod.  "If it weren't a new moon, I'd leave now.  But from the top of the pass, it's still at least three days to the outlying homesteads in Szeric, maybe more if they don't know the way.  We should be able to catch them if we leave at first light."

                  They return on the fourth day, filthy and ragged but wearing fierce smiles.  "It's done, ${kuria}.  Caught them at camp, and felled them both from cover."
                  *gosub simonflee
                  *goto wanttofound
                #I let the travelers go.
                  "Your only failure was in not trusting me," you say with quiet reassurance.  "I won't send anyone after them.  Next time, don't hesitate to tell me.  You've trusted me with enough else."
                  
                  To your surprise, when the first shock fades, ${simon} looks utterly miserable rather than relieved.  "Forgive me…forgive me, ${kuria}!  I won't betray your trust again."  $!{zhe} flees the tent without another word.
                  *set horion 12
                  *page_break
                  *goto wanttofound
        #"You're terrible at lying, ${zkuria} de Firiac."
          Sweat is visible on ${simon}'s brow.  "I resent the implication, ${kuria} ${lname}.  Does my honor truly mean so little to you?"

          "Who were they?"

          "A Southriding noble and his priestly retainer.  Two eccentrics."  ${simon} glares at you defiantly.  "I've brought back what you asked of me, ${kuria}, without argument or dissent.  I'm sorry that this seems to have offended you."
          
          You get nothing more out of ${zhim}.  Separately, your tracker Alira confirms all the details of his story, and looks dubious when you ask whether ${simon} recognized the strangers.  "He greeted the noble, 'kurios Horion,' as if they were friends—but the priest had called his master by name while we were still listening from cover.  I thought it was just the lordling's way.  $!{zhe} greets everyone as if ${zhe}'s known them all ${zhis} life.  And this Horion answered with the same courtesy."
          
          "What was this lord Horion's House?"
          
          "De Lelle, I think he said?" Alira shrugs.  "Never heard of them.  Some small family with more books than acres, I reckon."
          
          Something about it still sits ill with you, but you put it out of your mind for the time being.  Perhaps ${simon} will be more forthcoming later, when ${zhis} temper has had a chance to settle.
          *set horion 11
          *page_break
          *goto wanttofound
    
    "Truly?"  Could any noble really be so cloud-skulled as to choose a wilderness pass just because it's the shortest route as the hawk flies?

    The young noble laughs, clearly sharing your incredulity.  "They said something about the Pan of Szeric.  Apparently he's a sophist, too."
    
    Baffling.  Szeric is one of the remotest hill districts in ${whendery}—you wouldn't have expected its aristarch to have a reputation that crossed borders.
    *set horion 10
    *goto wellifpass
  *if (orders = "bring")
    *set hor_guard simon
    *goto hereweare
    *label simonintrohor
    *set id 2
    *set delelle "Leilatou"
    Even after the four of you and ${deputy} have withdrawn to the Leader's Tent, an uncomfortable silence stretches out as ${simon} visibly searches for words.  "$!{kuria}…I have offered these strangers our hospitality, in keeping with your orders, and assured them that they'll come to no harm in our company."  $!{zhe} pauses, clearly hoping that you'll echo the sentiment.
    *choice
      #"I'm grateful that you've treated our guests with the honor they deserve."
        *set hor_rel +2
        You bow to the two strangers to set them at ease.
        *if helot
          After a lifetime's training in deference, it's harder than you'd expected to hold your head up and speak above a murmur.  You do your best to recall how you've heard the nobility greet each other, and repeat it as if you were yourself one of Them.
        "Kurioi, I'm honored that you accepted our invitation."

        The plump one beams with relief.
        *goto simintrohor2
      #"I didn't offer them hospitality, de Firiac.  I asked you to bring them for questioning.  Who are they?"
        *set hor_rel -2
        ${simon}'s face falls at your hard tone, but ${zhe} persists stubbornly.  "Our guests, ${kuria}. Under the Angels' protection—and mine."

        The plump traveler hastens to bow to you; his beaming smile is slightly belied by the sweaty sheen on his forehead.  
        *goto simintrohor2
      #I raise one noncommittal eyebrow.
        At your silence, the plump traveler bows and begins to babble.  His beaming smile is slightly belied by the sweaty sheen on his forehead.  
        *goto simintrohor2
    *label simintrohor2
    "My dear ${kuria} ${lname}, it's both a pleasure and an honor.  Your name is renowned even in the Southriding.  I understand that as Archon Phrygia has embarrassingly neglected the security of Whendward Pass, you and your generous band of volunteers have assumed responsibility for passing travelers."
    
    ${simon} leans in and
    *if hor_rel < 20
      resignedly
    declares, "$!{kuria}, allow me to introduce kurios Horion Leilatou and his retainer, the Ecclesiast Linos."

    There's an astounded silence in the tent.  The last three governors of Shayard have come from the Leilatou family; they're the most powerful House between here and Karagon.  You would never have imagined that a Leilatou would pass through your wilderness.

    "A lowly cousin of Her Glory the Archon. So please, let's not stand on ceremony." Horion's grin has a visible quiver at the corners.
    *choice
      #I'll treat them as honored guests.
        *set hor_rel +2
        "Kurios Horion, you are welcome to our humble camp."  At your friendly tone, everyone
        *if deputy = "Breden"
          except a troubled-looking Breden
        visibly relaxes.  "If I may ask, what brings so exalted a presence across the Whendward?"
        
        The moon-faced aristo laughs dismissively.  "Oh, it's much the shortest route to Szeric.  Can't think why you don't have visitors through here all the time."
        
        Szeric is one of the two closest districts of ${whendery}.  As far as you've heard, it's a poor, undistinguished bit of hill country.  
        *if helot
          "And…what draws you there, kurios?"
        *if aristo
          "Indeed…can't think why."  You arch an eyebrow.
        
        "I've been corresponding with the Pan of Szeric on matters philosophical for some time, and felt it was past time we met in person.  Little to do in his demesne but philosophize, from the sounds of it."  Horion grimaces.  "I hold some faint hope that he has a decent cellar, to carry us through the inevitable lulls in conversation."
        
        Though not satisfied by his glib answer, you think you'll save further questions for a more private conversation—including with the impassive Ecclesiast Linos.  
        *if helot
          "Well, the hospitality of Szeric will shame ours—but 
        *if aristo
          "Alas, our cellar is unlikely to compete.  But  
        what we have is yours, kurios." You
        *goto campyouask
      #I demand to know why a Leilatou is trespassing on our range.
        *set hor_rel -3
        "We're no protectors, kurios Leilatou.  We're at war with the Hegemony and all its servants."  You rest your eyes forbiddingly on the Ecclesiast.  "And you say you're travelers.  I say trespassers—or worse, spies.  You'd best start trying to convince me otherwise."
        
        Horion 
        *goto notspies
      #I order ${deputy} to imprison them as spies.
        *set hor_rel -4
        "${deputy}," you growl, "take these spying lackeys of the Thaumatarch and bind them until I have time to question them further."

        "$!{kuria}, ${kuria}, you're mistaken!" Horion protests wildly.  "We're no spies—we're just traveling to Szeric for converse with its aristarch.  He's a philosopher like myself.  My cousin Phrygia does not even know of our journey, I swear to you on all I hold dear."

        "I pray you to reconsider, ${kuria}," ${simon} implores.  "Please…don't dishonor me by treating these guests as our prisoners."

        Szeric is an impoverished district of ${whendery}; their story is implausible at best.  But you're too tired to get to the bottom of it now. "Enough.  We'll hear more on the morrow."  You ask ${deputy}
        *goto settlein
*if lead = "Breden"
  *if orders = "watch"
    You find Breden at dinner, and ${xhe}
    *goto erfillin

  *else
    *set arms +2
    *set wealth +22
    *set horion -10
    *if orders = "steal"
      *set violence +1
    "I killed them, ${kuria}."

    You blink at Breden in astonishment.  
    *if deputy = "Breden"
      Your deputy
    *if deputy != "Breden"
      The former
      *if helot
        de Rose
      helot
    stares back, a tremor in ${xhis} cheeks.  "What threat were they?" you finally ask.

    "I don't know that they were a threat, ${kuria}."  Breden's face crumples into a mask of misery.  "I'd thought…they were speaking of Theurgy, and in the heat of the moment I took away the idea that at least one of them was a Theurge.   So when we halted them, I had them at arrowpoint.  And when the tall one reached to his belt, I gave the call to let fly.  But all we found on them were their two swords," ${xhe} gestures to the corner of the tent, "and a small purse of silver drachems.  No blood phials.  He was…"  $!{xhe} looks away, ashamed.  "He was likely trying to disarm so that we would not kill them."

    You give ${xhim} a moment before gently probing, "Nothing else from their talk?"

    "Only names.  Horion and Linos, they called each other.  The first a noble, the second an Ecclesiast."  Breden rubs ${xhis} cheeks and ${xhis} voice steadies.  "Sounded like they were from the Southriding.  Bound to Szeric on some errand.  I'm sorry—I took away nothing else.  Perhaps Alira will have other ideas?"

    You stare at ${xhim}, 
    *if ruth <= 50
      sympathizing with ${xhis} obvious regret.
    *if ruth > 50
      wondering why it's affected him so.  
    "An understandable mistake, Breden.  Don't blame yourself."
    *if (bred_lover >= 4) or (bred_heart = 3)
      When tears start in ${xhis} eyes, you pull ${xhim} into your 
      *if bred_lover >= 4
        arms and kiss them away.  
      *if bred_lover < 4
        arms.
      "Just a mistake."
      
      "A mistake," ${xhe} echoes, thick-voiced, and embraces you back.
    *if (bred_lover < 4) and (bred_heart != 3)
      $!{xhe} nods shakily, and you conclude, "We'll see if anyone comes looking for our mysterious travelers.  We may yet find out more."
    *page_break
    *goto wanttofound
*if lead = "Radmar"
  *if orders = "watch"
    You find Radmar at dinner, and he
    *goto erfillin

  *elseif orders = "bring"
    *goto hereweare
  *else
    *goto thefty

*label home_camp3
*page_break
On the walk back,
*if not(kal_here)
  *if s_rel < 9
    ${simon} does ${zhis} best to reassure Horion and Linos that the rebels of Whendward will do them no harm.
    *set hor_guard simon
    They seem
    *if (hor_rel < 19) and (hor_rel > 15)
      barely
      *goto convinced
    *else
      not wholly 
      *goto convinced
    *label convinced
    convinced.
  *if s_rel >= 9
    Horion tries to strike up a conversation with
    *if elery > 0
      Elery
      *set hor_guard "Elery"
    *if elery < 1
      Radmar
      *set hor_guard "Radmar"
    about the kidnapped ${simon} de Firiac.  His cheery tone does a poor job of masking his apprehension, and the
    *if elery > 0
      terse
    *if elery < 1
      gruff
    former helot does little to reassure him.  Finally he gives up and settles into a morbid silence.
*if kal_here
  ${kalt} doesn't even glance at Horion and Linos, but the set expression on ${zhis} face promises nothing good.  You're not sure how many nights the unexpected travelers will be staying with you, but 
  *if horion > 3
    if you want to collect that ransom,
  *if horion < 4
    even if it's just one or two, 
  you'd better do something to fend off an untimely "accident."
  *choice
    *if bred_here
      #I'll ask Breden to protect them.
        You lean in to Breden as you round an outcrop.  "I need someone to make sure no harm comes to our noble guests while they're in our care…."
        
        $!{xhe} nods without pause.  "I'd had the same thought myself, ${bfname}.
        *if bred_lover > 10
          Much as I'll miss you abed,
        I'll take the night's watch over them."
        *set hor_guard "Breden"
        *goto camp_descent
    *if elery > 0
      #I'll ask Elery to protect them.
        Elery arches an eyebrow when you whisper your thoughts.  "You'd have to convince me not to help ${kalt} first, ${kuria}.  A Leilatou's no friend to us."
        
        "I'm not asking you to be his friend.  I'm asking you to consider where he'll be of most use to us.  Are you sure that he's best off dead?"
        
        She doesn't answer for another furlong's climb.  "I wouldn't say 'sure.'"
        
        "When you are sure, come and tell me.  You might even convince me.  Until then, all I'm asking is that you don't let anyone else do anything rash."
        
        She still looks dubious, but says, "Aye, ${kuria}."
        *set hor_guard "Elery"
        *page_break
        *goto camp_descent
    #I'll ask Zvad to protect them.
      You murmur your worries in Zvad's ear, and the big ${whend} just nods.  "They'll come to no harm, ${kuria}—I'll see to it."
      *set hor_guard "Zvad"
      *goto camp_descent
    *if aristo
      #I'll ask my father to protect them.
        He'll 
        *if id > 1
          certainly not want to see any harm come to a cousin of the Archon—and he'd
        be the only person in the band who understands the usual courtesies.
        *set hor_guard "your father"
        *goto camp_descent
    #I'll just make sure ${kalt} knows the consequences if they die prematurely.
      You allow the rest of the party to pass you, then lean in to ${kalt} and speak quietly.  "Anyone who harms them without my word will be making ${zhis} next camp under a cairn."
      
      "They'll see no harm from me," ${kalt} snaps.  "But 
      *if id > 1
        this is madness, 
      *if id <= 1
        we shouldn't be welcoming nobles to the greenwood,
      ${kuria}, and don't think I won't say it to your face."
      
      "Say whatever you will.  Just don't do anything you'll regret."
      *set hor_guard deputy
      *goto camp_descent
*label camp_descent

When you finally descend to the camp, you 
*label campyouask
ask
*if (hor_guard = "Breden") or (hor_guard = "Elery")
  ${hor_guard}
  *goto settlein
*elseif (hor_guard = simon)
  the young de Firiac
  *goto settlein
*else
  Zvad
  *goto settlein
*label settlein
to get your new guests settled in.  For your part, you
*if lead = simon
  remain in
*if lead != simon
  escape into 
the cool dark of the Leader's Tent 
*if id > 1
  to think through the explanation you're going to give to the rest of the band.  
*if id <= 1
  to consider how you'll deal with them.

In another few hours, this space will be packed with sleepers; you don't yet have enough tents to dedicate one for your
*if bred_lover > 10
  and Breden's
bedroll alone.  But during the day, it's the one place you can meet privately and think in peace.

Then:
*if aristo or (id > 1)
  "You [i]kidnapped a Leilatou[/i]?" your father sputters from the entry flap.

  *if id <= 1
    *set delelle "Leilatou"
    "A [i]who[/i]?"  You don't think the peace of the tent has ever been shattered quite so dramatically.
    *page_break
    Wide-eyed with outrage, your father lets the flap fall behind him and stalks up to you.  "I may not have attended a Season in Grand Shayard since you were a babe…but Horion Leilatou was well known when last I did.  It was whispered that he might even rise to Archon one day.  I'd not mistake the man."
    
    Your mind is racing.  The last three governors of Shayard have come from House Leilatou—a family better known for intrigue than brutality, but still obviously quite effective at keeping the Thaumatarch happy.  "He said his name was de Lelle…."
    
    Your father gives a mocking snort.  "Three and a half centuries ago, maybe.  Not since."  He leans toward you, incredulous.  "So you kidnapped him unknowingly?"
    *set id 4
    *goto kidnap_choice
*if helot and (id <= 1)
  "You kidnapped
  *if s_rel >= 9
    [i]another[/i]
  *if s_rel < 9
    a
  noble?" your father sputters from the entry flap.
  
Peace is, as ever, fleeting.
*label kidnap_choice
*choice
  *selectable_if (horion < 4) #"No, father.  He'll enjoy our hospitality, answer some questions…and in a day or two, he'll be on his way."
    *set horion +2
    *set hor_rel +2
    Your father glowers at you.  "Hospitality?  Bandits don't offer hospitality, ${girl}."
    
    "But rebels may."  You meet his skepticism with an earnest stare.
    *if hor_guard = "your father"
      *gosub dadlookaf
    *if hor_guard != "your father"
      "I just want to find out what brings them here.  Then I'll let them go."
      
      Now he seems to believe you, but his scowl doesn't shift.
    "Pah.  No good will come of this."  Turning on his heel, he leaves the tent as abruptly as he arrived.
    *goto band_dinner
  #"That's a harsh word for it.  Call him a paying guest."
    *label abductdem
    Your father fumes,
    *if aristo
      his worst fears fulfilled.  
    "Your nerve, ${girl}…."
    *label cuthimoff
    
    *if horion < 4
      *set horion +4
    You cut him off:
    *if hor_guard = "your father"
      *gosub dadlookaf
    *if hor_guard != "your father"
      "I won't see the band starve through another winter.  If that means claiming a ransom on kurios ${delelle}, so be it."
      
      He just stares at you in disgust and disbelief.
    "Too far, ${girl}.
    *if aristo
      You'll draw nothing but the earth's worst scum to such a revolt as this.
    *if helot
      *if (id <= 1) and (s_rel > 9)
        How many aristos do you think you can keep tied up here?
      This will have 
      *if id > 1
        the Archon herself demanding your liver on a stick.
      *if id <= 1
        every noble in Shayard hunting us like wolves.
    You've gone too far."  Turning on his heel, he leaves the tent as abruptly as he arrived.
    *goto band_dinner
  #"Yes."  I struggle to restrain a fierce grin.
    *if id = 4
      [i]Even better that he's a Leilatou[/i], you think with satisfaction.
    *goto abductdem
  *if democ > 9
    #"I'll ask the ${moot}."  Which will almost surely lead to our holding him for ransom.
      *set askmoot true
      *if aristo
        If you'd wondered whether it was possible to scandalize him further, there's no doubt now.  "You'd place 
        *if id > 1
          a Leilatou's 
        *if id <= 1
          his
        fate into the hands of this putrid rabble?"
      *if helot
        He's no more illusions about the likely outcome than you have.  "Oh, there's a grand difference."
      *goto cuthimoff

      *label dadlookaf
      "And I need you to look after him."
    
      "What do you mean?"  He's caught off guard.  "Another shame, to involve me in
      *if horion < 4
        whatever crumbs of so-called hospitality we can now offer to a great l…?"
      *if horion > 3
        your crimes as an…?"
    
      "For Angels' sake, Father.  I'm asking you to make sure no one kills him.  Stay close to him."
      
      His eyes widen, and he gives a sharp nod, though his scowl does not abate.
      *return
*label band_dinner
*if horion > 3
  *set guest "hostage"
*if (id <= 1) and (bleys > 9)
  *page_break
  Before joining the evening meal, you have Bleys Meriweather brought to your tent, as the former tax collector is the only one in the band with any chance of knowing more about this lord Horion.

  *if lead = "you"
    "We've 
  *if lead != "you"
    "${lead} 
  just brought back a noble ${guest}," you explain, "who was trying to cross the Whendward without us noticing.  He has an unlikely story about wanting to talk philosophy with a ${whend}ish lord…but he doesn't seem a smuggler.  Do you happen to know anything about a House de Lelle from the Southriding, and what might send one of their scions across our Pass?"
  
  The stoop-shouldered Telone 
  *if bleys < 12
    shakes his head stiffly.  "Never heard of them, ${kuria} ${lname}.  But then, I've only heard of a tiny fraction of the noble Houses of Shayard.  They could be quite powerful, for all I know."
    
    "That's all?"  You wonder if he's holding back something behind that surly demeanor.  He usually provides more useful information than this.
    
    "That's all."  Bleys meets your eyes coolly until you accept his word and dismiss him.
    *page_break
  *if bleys = 12
    *set id 4
    *set delelle "Leilatou"
    blinks several times. "There…was a House de Lelle, ${kuria}.  If I am not wrong.  I once had to deal with a tax on some land that they had long ago granted to a loyal client."
    
    "They don't exist any more?"  You lean in with heightened interest.
    
    "They took a Karagond name several centuries ago."  A thin grin appears on Bleys' face.  "You may know them better as Leilatou."
    
    "What?"  You jolt upright again, eyes wide and mind racing.  The last three governors of Shayard, including the present Archon, have come from House Leilatou.  "Surely not.  What would a Leilatou be doing in this wilderness?"
    
    Bleys shrugs, still smiling.  "A question worth asking him, ${kuria}."
    *page_break
After another half-hour of reflection, you clean up and head to the gap in the trees where the band is taking dinner.

"Hear me," you call to the assembled outlaws.  
*if id > 1
  "The Archon's cousin, Horion Leilatou, is our guest
*if id <= 1
  "We have a noble guest
tonight."  
*if lead != "you"
  *if (id < 4) and (lead != simon)
    That much, of course, they knew from ${lead}'s public display of your two ${guest}s earlier.
  *if (id = 4) or (lead = simon)
    An astonished babble goes around the clearing—no one had dreamed that your noble visitor could have so lofty a House.
*if lead = "you"
  A
  *if horion > 3
    ripple of incredulous laugher
  *if horion < 4
    half-surprised rumble
  goes around the clearing—plainly, word had already spread of the aristocrat's presence.
*if askmoot
  "What says the ${moot} on this?  Does the greenwood hospitality come free for nobles—or do we look for a ransom?"
  
  A number of bandits cheer your decision to put so momentous a question to the full ${moot}, and a debate begins that occupies nearly an hour.  While a vocal minority
  *if simz_here and (s_rel < 10)
    (earnestly led by ${simon} de Firiac)
  argues for treating Horion and Linos as honored guests,
  *if id > 1
    far more call for a ransom, "if not his bloody Leilatou head on a stake."
  *if id <= 1
    in the end the ransomers win out.  "We've no great likelihood of making noble friends, ${kuria}, nor any need," Radmar growls.
  *set morale +20
  *goto horblink
*if horion > 3
  "His ransom will see us
  *if id <= 1
    well
  armed and
  *if id > 1
    fed through four winters to come.
  *if id <= 1
    fed.
*if horion < 4
   "He travels under my personal protection.
So no one is to lift a finger to harm him or his companion.  Understood?"  

Your followers respond with
*if horion > 3 
  a delighted 
  *if id > 1
     cheer, admiring the audacity of kidnapping a Leilatou.  If any of them are afraid of the Archon's retaliation, they don't show it.
  *if id <= 1
    cheer.
  *set morale +5
  *goto horblink
*elseif (cha = 2)
  an amused mutter and shakes of the head.  They clearly don't feel any affection for your 
  *if id > 1
    Leilatou 
  "guest"…but thanks to your charm, they're willing to trust you.
  *goto horblink
*else
  *set morale -10
  grudging nods and unhappy murmurs.  The idea of 
  *if id > 1
    a Leilatou 
  *if id <= 1
    an aristocratic
  guest
  *if releasedem
    is clearly no more palatable to most of them than it was to
    *if kal_here
      ${kalt}.
      *goto horblink
    *else
      Breden.
      *goto horblink
  *else
    clearly fills them with nothing resembling enthusiasm.
    *goto horblink
*label horblink

Then ${hor_guard} brings Horion and Linos blinking into the 
*if (horion = 5) or (horion = 3)
  firelight; the stout noble is still swaying unsteadily from blood loss.
*if (horion != 5) and (horion != 3)
  firelight.
Both your ${guest}s are visibly
*if (horion < 4) and (cha = 2)
  relieved at their tolerant reception.
  *if id = 4
    *if (horion = 5) or (horion = 3)
      The groggy-looking
    Horion flinches at the first murmur of "Leilatou," but relaxes as it becomes clear that you're not immediately punishing them for their lie.
  *goto eve_choice
shaken to be greeted by a ring of hostile
*if id = 4
  faces—and their barely containable horror when they hear the first mutters of "Leilatou" is almost punishment enough for their lie.
  *goto eve_choice
*else
  faces.
  *goto eve_choice
*label eve_choice
*choice
  #I'm jovial with them all evening.
    *set hor_rel +1
    *if (lead = simon) and (orders = "steal")
      *set hor_rel +1
      *if helot
        After a lifetime's training in deference, it's harder than you'd expected to hold your head up and speak above a murmur.  You do your best to recall how you've heard the nobility greet each other, and repeat it as if you were yourself one of Them.
      "The hospitality of the greenwood is yours, kurios ${delelle}."

      The plump Horion returns your bow with a 
      *if horion < 4
        winsome
      *if horion > 3
        strained
      smile.  "Ah, my dear ${kuria}!  It's both a pleasure and an honor.  Your name is renowned even in the Southriding.  I understand that as Archon Phrygia has embarrassingly neglected the security of Whendward Pass, you and your generous band of volunteers have assumed responsibility for passing travelers."
    
      "I'm honored that you accepted my invitation, kurios.  If I may ask, what brings so exalted a presence across the Whendward?"
        
      The moon-faced aristo shrugs lightly.  "Oh, it's much the shortest route to Szeric.  Can't think why you don't have visitors through here all the time."
      
      *if helot
        "And what draws you there, kurios?"
      *if aristo
        "Indeed…can't think why."  You arch an eyebrow.
      
      "I've been corresponding with the Pan of Szeric on matters philosophical for some time, and felt it was past time we met in person.  Little to do in his demesne but philosophize, from the sounds of it."  Horion grimaces.  "I hold some faint hope that he has a decent cellar, to carry us through the inevitable lulls in conversation."
      *goto nextam
    *elseif (horion > 3) or (hor_rel < 15)
      *if id = 4
        Horion's smile is sickly.  "You…you are most gracious to us, ${kuria} ${lname}."  He and the grimly silent Linos are clearly braced for you to inflict some sort of dreadful punishment for their lie.  Your consistent good cheer, far from reassuring them, seems only to intensify the agony of waiting.
        *goto nextam
      Horion responds with strained cheer, and Ecclesiast Linos is stonily silent.
      *goto nextam
    *else
      *if id = 4
        Horion responds at first with a faltering, uncertain smile.  "$!{kuria}…I owe you some explanation of my discourtesy.  We travel under my family's old name so as…"
        
        You hold up a hand.  "My dear kurios Leilatou.  Please, there's no need to explain.  You are our guest under any name!  Any more discussion can wait until the morning."
        
      Horion beams with relief and is soon enthusiastically laughing along to your jokes.
      *if cha < 2
        Your camaraderie with the ${delelle} does not sit well with many others in the band, however; many take their food and walk off into the trees, muttering as they go.
        *set morale -3
      *goto nextam
  #I apologize tersely for the simple fare and rough accommodation.
    *if (lead = simon) and (orders = "steal")
      *set hor_rel +1
      "Please, ${milady} ${lname}, I could never accept your apology." Horion ${delelle} bows deeply, a visible sheen of sweat belying his cheery voice.  "We'd not expected to find so friendly a hearth in the midst of the Whendward. I was resigned to having no conversation save with Linos here for many days to come—and I already know everything he's got to say."
      *goto nextam
    "Not at all, not at all.  Though you might consider what you can do to get the aristarchs' [i]cook[/i] to rebel," Horion says
    *if horion > 3
      while tremorously attempting a smile.
    *if horion < 4
      contemplatively, gnawing at a barley loaf.
    *goto nextam
  *selectable_if (horion > 3) #I don't feed them.  I want them hungry and frightened for the interrogation tomorrow.
    *if hor_rel > 18
      "I'd thought you a friendlier host than this, ${kuria} ${lname}," Horion ventures, clearly unsure of how to interpret your sudden coldness.
      
      *if id = 4
        "That was before I found you'd lied to me."
        
        "$!{kuria}…we implore your pardon," the noble whispers, shakily kneeling.  "We have been traveling under my family's old name, it's true.  We thought it would bring us safety at a time when enemies pursue us—enemies you might share."

        *if knowwhy < 1
          *set knowwhy 1
      You shrug.  "Depending on our conversation and your honesty, we may be friends by suppertime tomorrow.  If we're not…then you'll reckon tonight's treatment generous indeed."
      
      *set hor_rel -1
    *set hor_rel -1
    Horion and Linos huddle together miserably while the rest of the band tuck into a sparse evening meal.
    *goto nextam
*label nextam
*if aristo

  Then your father arrives, accompanied by a low, impressed hum.  Somehow he's cleaned both himself and his clothes, trimmed his beard, and done something that has his hair falling in well-oiled gray ringlets rather than bound back in a dusty tail.  When he speaks, his voice is strong and joyless.  "Kurios Leilatou.  The 
  *if horion < 4
    inconvenience
  *if horion > 3
    offense 
  my ${daughter} has
  *if horion < 4
    caused 
  *if horion > 3
    inflicted upon
  you is unforgivable.  If ${he}'d left me the option, I'd put my neck beneath your sword."
  
  "Nonsense, my dear kurios ${lname}," Horion cries,
  *if horion < 4
    sounding pleasantly dismissive.
  *if horion > 3
    looking greatly relieved.
  *if orig_lname != lname
    
    "$!{orig_lname}!" your father snaps at once, before his lips vanish into a trembling line. "Forgive my rudeness, kurios, but I've yet to accept my child's extinguishment of our line."
    
    "Not at all, kurios ${orig_lname}—you must forgive me." The Leilatou bows to cover his momentary embarrassment.
  "It's an honor to be your guest.  
  *if horion < 4
    As I've already said, the road to Szeric would have been quite unbearable without your hospitality and conversation."
    
    Your father relaxes at the stout noble's evident good cheer.
  *if horion > 3
    Until my cousin ransoms us, we'll enjoy your company."
    
    Your father grimaces at the overt reference to kidnapping, then proceeds stiffly as if it hadn't been mentioned.
  "You'll not remember, but we last spoke some…seventeen years back, under the Archonate of your great-uncle."
  
  Horion
  *if horion < 4
    beams.
  *if horion >= 4
    manages a weak, distracted smile.
  "Ah, and I was wondering why you looked so familiar, kurios.  Perhaps we met once or twice in our long-fled youth, as well?"
  *page_break
  "Perhaps.  I was the last scion of the ${orig_lname} in my generation," your father growls, seating himself next to your noble ${guest}s. "My responsibilities in Acron have usually prevented me from attending the Season."
  
  "A pity.  No cousins to relieve you?"  The evening has begun to feel incongruously like the formal dinners of your childhood, with a noble guest delicately probing your House's web of relations.
  
  The snort your father returns is rather less delicate.  "My mother's sister and brother desperately sought adoption into larger Westriding Houses—and when they succeeded, forsook every connection to the Rim.  Meanwhile, Mother hunted for years to find a husband from a weaker House to keep the ${orig_lname} name alive.  When she found him…the marriage survived five years.  I was the only child.  The hope of the House."  As his voice quavers, he pauses to bite off a hunk of stale bread, ignoring the slightly embarrassed silence from the Leilatou.  Then he turns a savagely shining eye to you.  "My own luck with marriage was worse.  More than twice as long, for still but a single fruit.  And a rotten one at that."
  *choice
    #"As you can see, kurios Horion," I say with a forced smile, "I owe everything to my father's loving care."
      *goto dadglower
    #I glance at the helots who are pretending not to listen.  "I wonder what our orchard-keepers would say if they heard a diseased branch try to blame its fruit?"
      *if rescuer = 0
        Joana Orchard barks out a pointed laugh, and your 
      *if rescuer = 1
        Your
      father's scowl becomes a snarl.  "Go on, ${girl}.  Defame your House and your sire before guests and churls.  What new depths will tomorrow bring?"
      
      Before you have time to reply,
      *goto horionlean
    #"Mother was the unlucky one," I retort hotly.
      *set hor_rel -1
      Your father is still plainly unprepared for such direct confrontation from you, especially before another noble.  "Shame, ${girl}!  Shame upon you!  To defame your sire before guests and churls?"

      Before you have time to reply,      
      *goto horionlean
    #I shake my head, swallow my feelings, and say nothing.
      *label dadglower
      *set hor_rel +1
      While your father continues to glower at you,
      *goto horionlean
  *label horionlean
  Horion leans in, looking pained. "Seventeen years, you say, kurios ${orig_lname}? Why, then you must remember Killen de Gambre…"  His babbling recollections fill the hostile silence, and he eventually draws your father into curt dialogue about Rim aristocracy of their generation.
*if (id = 4) and ((kal_here) and (lead = "you"))
  
  Just before you retire that night, you beckon ${kalt} into the shadows a few yards from everyone else. "Now, regarding our Leilatou guest…"

  "Unbelievable!"  The fierce young helot laughs, ${zhis} eyes shining joyously.  "How'd you find out they were lying, ${kuria}?"
  
  "How did you?"

  $!{kalt}'s smile vanishes as ${zhe} takes in your expression.  Without any further dissembling, ${zhe} says, "He visited my old master's estate, once.  They used his name." 
  *page_break
  "So when he arrives in Whendward, you take it on yourself to put an arrow in him.  Without so much as telling me."  You pause for a moment, trying to check your fury.  "And when did you plan to inform me and ${deputy} that we had murdered the Archon's cousin?" 
  
  "$!{kuria}…"
  
  "How long did you expect we would need to prepare for every Phalangite in Shayard marching into Whendward?"

  ${kalt} swallows visibly.  "Truly, ${kuria}? I didn't think it would make a difference. If it would—if we aren't already the Archon's first priority—what are we doing wrong?"  The last words burst out of ${zhim} with anguished force.
  
  You ignore ${zhis} words.  "Don't you ever try to force my hand, ${kalt}. You disagree with me, you tell me. But if I catch you hiding the truth from me on something this important again…you'll be lucky if I give you a running start."
  
  For a moment, ${zhe} looks as if ${zhe}'d say more—but in the end, ${kalt} just mutters, "Understood, ${kuria}."

In the morning, you eat a spare breakfast while considering how best to question your ${guest}s. Upon reflection, you decide you want them to see you as:
*choice
  #Friendly host.
    *set tone 1
    *set tell "Pray tell"
    *set hor_rel +1
    *if horion > 3
      Horion seems to like maintaining the host-guest facade.  You'll indulge his pretensions.
    *if horion < 4
      They are your guests, and (conceivably) future allies.  You don't want to alienate them.
    *goto bringme
  #Pragmatic outlaw.
    *set tone 2
    *set hor_rel +2
    No need to be over-friendly, nor to threaten.  You just want to know what brings them here, and draw out the information that will help you respond in the most advantageous way.
    *goto bringme
  #Menacing interrogator.
    *set tone 3
    *set hor_rel -1
    Let there be no mistake: they are in your power, and if you don't like their answers, they'll never leave the wilderness.
    *goto bringme
*label bringme

You ask ${hor_guard} to bring you:
*choice
  #Linos.
    *label linoshi
    The grizzled, bald priest stoops as he enters the tent. 
    *if tone = 1
      You clasp his hand in greeting and offer him a wooden stool.  "Welcome, Ecclesiast Linos.  I hope our rough pallets didn't wholly ruin your sleep?  You have my thanks for agreeing to talk with me."
      
      *comment endif
    *if hor_rel > 20
      "How may I be of service, ${kuria} ${lname}?"  His face is guarded but not unfriendly.
    *if hor_rel < 21
      "Angels grace your morning, ${kuria}."  
      *if hor_rel < 15
        His voice is hoarse but his face devoid of emotion.
      *if tone = 1
        Linos seats himself and waits for you to speak.
      *if tone > 1
        
        "You look calm enough, Ecclesiast, given the
        *if (horion = 3) or (horion = 5)
          injury to your master and the
        disruption to your journey by bandits."

        Linos spreads his hands apart, palms upraised.  "The Angels of Compassion take away fear."

        "Praise be."  
        *if tone = 2
          You offer him a wooden stool, and seat yourself next to him.  "Then we should be able to speak freely on some matters of interest to me."
        *if tone = 3
          You regard him coldly.  "I've yet to meet an Ecclesiast who was free from
          *if introrel
            fear."
          *if not(introrel)
            fear.  Or particularly compassionate, at that."

          "Well, I'm sure we all have our limits.  And I won't tempt you to find mine."  The tall priest folds his arms around his chest.  "Ask what you will, ${kuria} ${lname}."
    *label linoschat
    *choice
      *hide_reuse #"$!{tell} me about yourself, Ecclesiast."
        "I hail from the Reach," Linos replies.  "The further end.  A few days' ride from Aveche."
        
        *if tone = 1
          "So far to the northeast?" You offer him a disarming smile.
        *if tone < 3
          "I'd have taken you for a Southriding man by your speech."
        *if tone = 3
          "You have the Southriding in your voice."  Your tone is a shade less than accusatory.

        "Two decades in Court will have that effect on the best of us."  The bearded priest 
        *if tone < 3
          slips easily into
        *if tone = 3
          defensively adopts
        a clipped northern accent. "But no.  
        *if tone = 3
          Believe it or not,
        I'm a Reacher born, ${kuria}.  Third scion of a House which lost its land to the Alastors generations ago.  Now no one but my father thinks of our family as noble; none but I ever saw the Court of Shayard."
        
        "And taking the vows brought you back there."
        *if id > 1
          You raise an eyebrow.  "Into the retinue of a Leilatou, no less."

        "Myself—not my House."  Linos's voice is matter-of-fact.  "I've no heirs, and if I did, the vow of commonality would leave me naught to pass to them save my vocation."
        *goto linoschat
      *hide_reuse #"What do you make of our rebellion?"
        Linos
        *if hor_rel > 20
          tilts his head, looking curious. 
        *if hor_rel < 21
          stares at you with evident reluctance.
        "What do you expect me to answer, ${kuria}?"
        
        *if tone = 3
          "The question."
        *if horion > 3
          *if tone < 3
            "Whatever you truly think, Ecclesiast Linos."  You lean back, spreading your hands.

          The wiry priest sighs.  "The Thaumatarchy loves a helot rebellion."
          
          So bold a riposte leaves you off balance.  "Isn't that the sort of thing you're supposed to Harrow people for saying?"
          
          "Karagon does not fear bandits, ${kuria}—not
          *if (theuknown >= 10)
            even bandits led by a self-taught ${wisard}. You've gathered 
          a few angry helots in the wild."  Linos leans forward, voice neither mocking nor threatening.  "This is part of the Order of the Thaumatarch.  A rebellion every few years keeps the prosperous classes afraid of the lower orders.  The uprising's failure disheartens the helotry, so that only the most desperate and abused will dare it again.  And the rebels' blood feeds the Theurges who crush them."
          *choice
            #"Until a rebellion succeeds."
              *if tone = 3
                "Indeed."  Linos's tone is studiedly neutral.
              
                "Dismiss it all you like, priest.  That arrogance is why Karagon will fail."

                Despite the thrum of anger in your own voice, 
              Linos remains mild.  "In nearly four hundred years and four conties, no armed rebellion has succeeded against the Hegemony.  What have you learned from those failures that will prevent you repeating them, ${kuria}?  What is different about this rebellion?"
              *choice
                *if (theuknown >= 10)
                  #"With ${wisardry} on our side, we can win."
                    *goto notfirsttheurge
                *if gandhi > 0
                  #"The others relied upon violence.  For us, it will be the last resort."
                    *goto unruthless
                *if (gandhi = 0) and (ruth <= 50)
                  #"The vision of an Order not based in theft and bloodshed will win people to our side."
                    *label unruthless
                    *set ruth %-10
                    "You've said it yourself: the Hegemony relies on the free folk of the 
                    *if natl < 50
                      provinces 
                    *if natl > 49
                      Karagonds' subject realms
                    fearing the helotry too much to join the rebellion."
                    
                    Linos rubs his gray beard.  "The nobility might not fear a gentle bandit, ${kuria}.  But nor would the Phalangites—and how many Shayardenes will join you, if they expect the Hegemony to overrun you?"  Before you can respond, he gives a dry, unexpected laugh.  "Not that I want to talk you out of it.  I haven't been expecting to survive my stay in your company; 'an Order not based in bloodshed' sounds very appealing at the moment."
                    *goto linoschat
                *if ruth > 50
                  #"Others had some hesitation…some limit to what they would do to destroy their enemies.  We won't."
                    *set ruth %+10
                    Linos opens his mouth to reply…then swallows hard and closes it again.
                    *goto linoschat
                *if natl > 55
                  #"The vision of a free Shayard will bring together all Shayardenes as one."
                    *set natl %+10
                    *if helot
                      "A powerful vision, but forgive me, Captain: how many are prepared to hear it from a helot?"  Linos shrugs.
                    *if aristo
                      "Well, ${milady}, you've taken one grand step yourself toward uniting the aristocracy of Shayard with the helotry.
                      *if simz_here
                        And you've drawn one madcap ${zgirl} to join you.  But how many more
                      *if not(simz_here)
                        But how many 
                      of your fellow nobles will come stand alongside an army of helots or landless peasants?" Linos shakes his head.
                    *if cred_a < 211
                      "You've a long ways to go
                    *if cred_a > 210
                      "True, your relatively gentle behavior so far has begun 
                    to convince the nobles, ${kuria}.  The way you deal with my master will be watched…and may convince some more."
                    *goto linoschat
                *if natl < 45
                  #"We will bring all four provinces into rebellion, not just Shayard."
                    *set natl %-10
                    "It's a long way to go from having a few Wiends in your band to bringing Wiendrj behind your banner, ${milady}—to say nothing of the Nyr and Erezziano.  But if you survive long enough…"  Linos shrugs.  "It's been tried before, but
                    *if cha = 2
                      one with your charisma might just succeed."
                    *if cha < 2
                      perhaps you'll find a way where others have failed."
                    *goto linoschat
                *if skep > 55
                  #"We won't be held back by the dogma of Ecclesiasts."
                    *set skep %+10
                    "Rebellion has been tried by the skeptics of Nyr as well, ${kuria}," Linos murmurs.  "Whatever the flaws of the Karagonds' vision of Order, escaping it is not so simple as rejecting the Karagond religion."
                    
                    "It's a first step," you
                    *if tone = 3
                      growl.
                    *if tone < 3
                      say drily.
                    *goto linoschat
                *if skep < 45
                  #"The Angels are guiding us.  The time has come."
                    *set skep %-10
                    Linos bends forward, eyes intent on yours.  "So sure, ${kuria}?  A revelation has come to you?  The voice of an Angel?"
                    
                    *if tone = 3
                      You've got no patience for debating the Codex with this false priest.  "Ask them yourself when I send you to Elysia."
                      
                      The Ecclesiast leans away again wordlessly.
                      *goto linoschat
                    "[i]Say unto to the scoffers who demand a Word: Walk first the well-marked road of mercy and justice; then only will the Angels speak more to you than They have already said.[/i]"
                    
                    "Quoting the Codex to an Ecclesiast."  Linos leans away again, a wry twist to his lips.  "Your reputation for devotion is not entirely groundless, ${kuria} ${lname}."
                    
                    "And yours, 
                    *if tone = 2
                      priest?"  You pursue him with your eyes.
                    *if tone = 1
                      Ecclesiast Linos?"  There's a limit to how much you're willing to soften hard truths to play the gracious host.
                    "You must see the wrongs of the Thaumatarch's so-called Order—neither just nor compassionate.  And yet you lend it your authority and talk as if the Angels bless it.  Would you hear Them if they truly spoke? Or recognize Them if they appeared to you?"
                    
                    "Now have a care of that tongue, young ${woman}."  Linos's eyes flare and his voice sharpens.  "As we both clearly care for our souls, I'll remind you that the Canon—in whatever version you read it—has much to say about obedience to appointed Order.  Even an imperfect Order. When you kill me, I'm ready to answer to the Angels for how I've sought to change it while yet submitting to it. Give thought to where this rebellion may have caused you to drift from Their path."
                    *goto linoschat
                #"I'm supposed to tell that to an Ecclesiast?"
                  "An Ecclesiast you likely intend to kill.  I'd have thought it no great risk."  Linos sighs.  "But as you will, ${kuria}."
                  *goto linoschat
            *if ((tone = 1) and not(forever))
              #"Forgive me, Ecclesiast, but this is somehow part of the Angelic Order proclaimed in the Naos?" 
                *goto backinthepass
            *if ((tone > 1) and not(forever)) #"And…this is the Divine Order you proclaim in the Naos, priest?"
              *label backinthepass
              *if linosqq > 20
                You stare at him intently.  "Back in the pass, you implied otherwise."

              "No earthly Order can attain the perfection of Xthonos," Linos replies at once.  "And the Thaumatarchy is particularly lacking in some respects."
              
              "Such as?"
              
              "The Hegemony seeks to dominate too many peoples, across far too much of the world.  It must thus use more violence than a less ambitious, more natural Order."  You've heard many a priest take on this assured, lecturing tone; you never imagined you'd hear it used to deliver sweeping seditions.  "Their mastery of Theurgy led the Karagonds into hubris.  Now to keep their bloated empire alive they treat their conquered peoples with neither justice nor compassion.  Moreover, they have succumbed to greed, draining the provinces of blood and wealth to turn Karagon into a garden of luxuries."
              
              You blink, trying to fathom the Ecclesiast's nonchalance.  "Is this treason the stuff of idle ballroom chat in the 
              *if id > 1
                Archon's palace?
              *if id <= 1
                Court of Shayard?
              Because in Rim Square, to whisper this sort of thing would earn you a Harrowing." 
              
              Linos's smile doesn't reach his eyes. "Few dare to whisper it in Grand Shayard either.  But the truth can not be swallowed forever."
              *set forever true
              *goto linoschat
            *if (theuknown >= 10)
              #"You don't think ${wisardry} changes that story?"
                *label notfirsttheurge
                The Ecclesiast offers a delicate shrug.  "With all respect, ${kuria},
                *if helot
                  while you might be the first helot,
                you aren't the first rebel to discover Theurgy."
                
                "I've come across none other in the histories," you retort, trying to keep the stung pride from your voice.
                
                Linos sighs.  "There's not been one in three generations, no—though Sarcifer might yet begin to gather rebels about him.  But the Hegemony quietly deals with self-taught wonder-workers all the time.  Don't let your admirable achievement blind you, ${kuria}: you aren't yet a Theurge.  You haven't the training or the depth of experience.  You haven't the secret to making aetherial blood.  You haven't honed your skills in battle against the Magi of Halassur."
                *choice
                  *if tone = 3
                    #"True—I do need practice in killing with ${wisardry}."  I regard him with pointed irritation.
                      The Ecclesiast chokes on whatever he was going to say next, and subsides into silence.
                      *goto linoschat
                  *selectable_if (rescuer = 0) #"I defeated two Theurges in Rim Square."
                    Linos gives a curt nod.  "Quite famously, ${kuria} ${lname}.  And next time you face Theurges in battle, you'll judge how much of that victory to attribute to surprise and circumstance."
                    *goto linoschat
                  #"'Admirable achievement'?  You don't think I've consorted with Xaos to gain my powers?"
                    "Have you?" Linos asks drily.  
                    
                    "Of course not.  Nor the Angels, for that matter."  You consider his equanimity and its implications.  "So…how widely is it known among Ecclesiasts that Theurgy is a gift of intellect, not of 
                    *if tone = 1
                      devotion?"
                    *if tone > 1
                      devotion?  Do they all knowingly lie to the laity, or are the priests dupes as well?"
                    
                    Linos's lips curve in a minute fraction of a smile.  "Those of us who accompany our noble masters to the Court of Shayard have seen enough Theurges to know full well that not all are pious or good.  Some of my Ecclesia nonetheless sincerely believe Theurgy to be a grace of the Angels, bestowed upon unworthy as well as worthy vessels.  Others of us believe that if our minds were as quick as a Theurge's, we could do all that they do."  He shrugs.  "I have no wish to dabble in such Changes, myself.  Even if they do not require Xaotic power, they are not the province of an Ordered mind."
                    *goto linoschat
                  #"I don't need to duel Theurges to win."
                    "The value of my ${wisardry} isn't in what I do with it.  The mere fact that I can do these things will 
                    *if wisardry = "Goety"
                      *set lingoety 1
                      strike fear into the hearts of those who oppose us."
                      
                      *gosub lingoete
                      
                      *if skep > 50
                        "If the demons of Taratur are more than a children's story, we'll see whether they notice me."  
                        *if skepreal >= 50
                          It's surprisingly easy to shrug off the prospect; the Angels were a more significant, active part of your childhood beliefs than the powers of Xaos.  
                        *if skepreal < 50
                          You wish you were as confident of this as you sound.  
                        "Meanwhile, since the Thaumatarchy will make a monster of me, I'll make the most of it."                        
                      *if skep < 50
                        "The Angels protect me," you reply, 
                        *if skepreal <= 50
                          trying not to make your own doubt audible.  
                        *if skepreal > 50
                          glibly confident that They'll protect you as much as They protect anyone.
                        "They know, as do my followers, that I'm Their faithful servant.  But what else am I supposed to call myself?  The name of Theurge is tainted by Karagon, and they'll call me Goete regardless.  Very well, then; let them fear me."
                        
                        "${fname} the Angelic Goete."  Linos shakes his head. "It will only frighten and confuse those you seek to lead, ${kuria}.  As for the favor of the Angels…well, we shall see."
                      *if skep = 50
                        You shrug; 
                        *if skepreal = 50
                          you've never been much 
                        *if skepreal != 50
                          you still don't want anyone to think you're much 
                        engaged with this talk of Angels and demons, one way or another.  "If the Thaumatarchy is set on making a monster of me, I'll make the most of it."
                      *goto linoschat
                      *label lingoete
                      Linos eyes you with wary disapproval.  "You embrace the name of Goete, ${kuria}…but I've heard nothing to suggest that you've truly given yourself over to the powers of the Void that Burns.  It's a dangerous game, making a monster of yourself—to say nothing of what might happen if you truly drew those powers' attention."
                      *return
                    draw people to our side.  It's a sign that the favor of the Angels doesn't rest solely on the other side."
                    
                    "Interesting."  Linos's heavy black eyebrows rise, and he looks on the verge of a smile.  "For most Theurges, the ability to Change the world with a thought inspires hubris.  It's refreshing to hear one whose confidence is less in ${his} own powers than in the beliefs of the laity.  More like my own vocation."  He shrugs.  "However, ${kuria}, I must ask whether people's confidence in your ${wisardry} will remain if they hear you've been defeated by the Thaumatarch's magi."
                    
                    "I plan to avoid that defeat."  You return the conversation to other topics.
                    *goto linoschat
            #I change the subject.
              You shift back to your main line of questioning:
              *goto linoschat
        *else
          *comment if horion <=3
          *if tone < 3
            "That it's an unnatural offense against the Angelic Order," you suggest.
          *if tone = 3
            When he hesitates, you add cuttingly, "I don't believe there's a gentler way to say 'unnatural offense against the Angelic Order.'"

          *if helot or (hor_rel < 21)
            *label linossedit
            The bald priest studies you carefully.  "I do not consider the Angelic Order and the Order of Karagon to be identical,
            *if linosqq > 20
              ${kuria}."
              
              "So you implied, back in the pass.  What do you mean by it?"
            *if linosqq < 20
              ${kuria}.  And your offense against one is clearer than the other."
              
              You raise your eyebrows.  "That bears explaining, Ecclesiast."
              *set linosqq +20
            *label linossedit2
            
            "The Hegemony seeks to dominate too many peoples, across far too much of the world.  It must thus use more violence than a less ambitious, more natural Order."  You've heard many a priest take on this assured, lecturing tone; you never imagined you'd hear it used to deliver sweeping seditions.  "Their mastery of Theurgy led the Karagonds into hubris.  Now to keep their bloated empire alive they treat their conquered peoples with neither justice nor compassion.  
            
            "Moreover, they have succumbed to greed, draining the provinces of blood and wealth to turn Karagon into a garden of luxuries.  Such flaws and failings make rebellion all but inevitable—including by
            *if helot
              helots like yourself, 
            *if aristo
              nobles like yourself, 
            ${kuria}
            *if anarchy < 20
              ${lname}, who display considerable orderliness of mind."
            *if anarchy >= 20
              ${lname}."

            You blink, trying to fathom the Ecclesiast's nonchalance.  "Does everyone idly talk treason like this in the 
            *if id > 1
              Archon's palace?
            *if id <= 1
              Court of Shayard?
            Because in Rim Square, to whisper two words of what you just said would earn a Harrowing." 
            
            Linos's smile doesn't reach his eyes. "Few dare to whisper it in Grand Shayard either.  But the truth can not be swallowed forever."
            *set forever true
            *if nointerro
              He kneads his bearded chin for a moment, but shows no other sign of nervousness.
              *goto relpitch
            *goto linoschat
          *else
            "Unnatural?"  The Ecclesiast utters a short laugh without ever actually smiling.  "All too natural, I would have thought."  
            
            "Meaning?"
            
            "In most cases, ${kuria}, as long as humans act according to their nature and purpose, we serve Xthonos.  Thus the Enemy's usual tactic is to spur us into perverse and unnatural actions—for example, when helots refuse to accept that their purpose is service."  He pauses.  "But there are exceptions.  The areas of greatest danger—where human nature itself creates an opening for Xaos."

            "The Doorways of 
            *if int = 0
              Xaos?" You vaguely remember hearing something similar from a priest growing up.
            *if int > 0
              Xaos." You're familiar with the concept.

            "Yes.  These are the areas where we must take the most care—where a strong fence of rules and laws is most needed to keep our very nature in check.  And do you know which of the Doorways of Xaos is the most dangerous?"
            *choice
              #The answer is obvious.
                You say:
                *input_text doorway_xaos
                *if (((doorway_xaos = "compassion") or (doorway_xaos = "Compassion")) or ((doorway_xaos = "compassion ") or (doorway_xaos = "Compassion "))) or ((doorway_xaos = "compasion") or (doorway_xaos = "Compasion"))
                  *achieve doorway
                  "Yes, compassion.  I expected you to understand."  Linos nods approvingly.
                  *goto getit
                *else
                  "No, not ${doorway_xaos}.  A strong motivator of human action, one might argue…but not the most dangerous."
                  *goto doorwaysx
              #I'll have a guess.
                *goto doorwaysx
              #I'm not really interested.
                "I've no time for guessing games.  Tell me."

                *goto nopatience
          *label doorwaysx
          *hide_reuse
          *choice
            #"Carnal passion?"
              *set doorch +1
              You imagine this Ecclesiast will be as fixated on the subject as Zebed was.  But Linos shakes his head at once, and his voice is light and amused.  "A reasonable, even an obvious guess.  One of the strongest natural hungers is to reunite with one's missing half—and how easily we overstep the mark and fall into concupiscence and jealous violence!  But no."
              *goto doorwaysx
            #"Ambition?"
              *set doorch +1
              Linos sounds dismissive.  "Most so-called ambition is a whisper of Xaos, plain and simple.  True, there is an ambition which is according to nature, calling people to the greatest glory compatible with their station.  But much of what passes by that name is as unnatural as earth wishing to ascend to the same heights as fire."
              *goto doorwaysx
            #"Coming of age?"
              *set doorch +1
              "A Doorway whose significance becomes easier to forget the further we travel from it."  Linos rubs his beard thoughtfully.  "No doubt the challenges and uncertainties of that time are fresher in your mind than mine.  But I believe the rites of adulthood are generally sufficient to bring a girl or boy through those changes without yielding too much to Xaos."
              *goto doorwaysx
            #"Imagination?"
              *set doorch +1
              "Mmmm.  A strong contender.  The natural purpose of the human mind is to produce images that correspond to reality, but that very faculty also makes possible the temptation of phantasmata.  Losing ourselves in the false shadow-images of painters, jonglers, and other peddlers of the lovely lie…"  Linos visibly stops himself from heading into a long and well-worn homily.  "However, I cannot agree that imagination is the most dangerous Doorway, if only because it is so easily dulled in the mass of humanity."
              *goto doorwaysx
            *if (doorch > 1) #"Give me a hint."
              The priest's eyes gleam.  "Any Ecclesiast will tell you that it is the apex of both human and Angelic nature.  Few will admit, however, that it also holds the greatest threat of Xaos."
              
              You say, "Then it's…"
              *input_text doorway_xaos
              *if (((doorway_xaos = "compassion") or (doorway_xaos = "Compassion")) or ((doorway_xaos = "compassion ") or (doorway_xaos = "Compassion "))) or ((doorway_xaos = "compasion") or (doorway_xaos = "Compasion"))
                *achieve doorway
                "Indeed: compassion.  I expected you to understand."  Linos nods approvingly.
                *goto getit
              *else
                "No, not ${doorway_xaos}."
                *goto nopatience
            #I'm losing patience.  "I've no time for guessing games.  Tell me."
              *label nopatience
              Linos looks mildly disappointed.  "I thought you would have grasped this by now, ${kuria}.  It's compassion."
              
              "What, a virtue?" you say incredulously.

              *label getit
              "Along with justice, the highest virtue in the Canon.  The only thing which makes Order between humans possible at all.  If we could not feel what others feel, how could we possibly live in Angelic harmony with them?  And what could be a more obvious part of human nature?"  The priest spreads his hands wide, warming to the topic.  "And yet…compassion also makes us flinch from the sacrifices that are necessary to preserve Order.  Compassion lies behind every misguided attempt to free helots, to end Harrowing, to make peace with the Xaos-loving nations beyond the borders of Hegemony.  The highest virtue, and the greatest danger."
              
              *if introrel
                "I heard another Ecclesiast from the Reach speak this way of 'false compassion.'  Quoting the Psalm of Kapirus."
                
                Linos shakes his head.  "Your Reacher priest made the matter too simple.  There's no 'true compassion' which is safe from Xaos.  Compassion always threatens Order as much as it underpins it.  Always."
                *page_break
                You shake your head warily.
              "Sounds a heresy if ever I heard one."
              
              "Then you may denounce me to the Archimandrite of Shayard."  Linos's amusement is plain.  "His Eminence teaches this doctrine to the circle of priests closest to himself—those responsible for ensuring that the highest nobility are guided away from the paths of Xaos."
              
              "So you teach it to me?"
              
              The wiry Ecclesiast inclines his head with a small, strained smile.  "In the unlikely event that you survive the spring, ${kuria}, you might just become one of the most influential nobles in the land.
              *if skep < 40
                And you are known to be devout.
              I would be remiss to let the opportunity pass."
              
              "And you believe I started this rebellion out of compassion for the helotry?"
              *if ruth < 50
                
                "A 
                *if ruth < 41
                  famously compassionate ${woman} 
                *if ruth > 40
                  noble${woman}
                like yourself, who forsook ${his} privilege for the greenwood?"  Ecclesiast Linos leans in.  "Here is what I think of your rebellion, ${kuria}.  I fear you are too compassionate, and that this will lead you to undermine the wrong elements of Order—while failing to drive home the changes that might actually remedy the wrongs of the Hegemony."
              *if ruth > 49
                You furrow your brow.
                
                "They seem to think so.  At least, that's why they're tolerating your leadership.  And why else would a noble forsake ${his} privilege for greenwood banditry?"  Ecclesiast Linos leans in.  "If 
                *if ruth > 59
                  your famed ruthlessness extends to them as well, 
                *if ruth < 60
                  you truly feel no compassion for them,
                ${kuria}?  Then beware the day they realize it.  The wrongs of the Hegemony that move them to rebel may not be the same ones that have moved you."
              *choice
                #"A priest admits that the sacred Order of the Hegemony has wrongs?"
                  *goto linossedit
                #"While your advice and speculations on these matters are fascinating, Holiness…"  You're more than ready to talk about something else.
                  You pointedly clear your throat.  "There's a more pressing topic I wanted to discuss with you."
                  *goto linoschat
      *hide_reuse #"$!{tell} me more about where you're going, and why."
        "My master Horion has been corresponding with the Pan of Szeric for several years on matters philosophical."  Linos runs his fingers through his beard.  "He is now determined to meet him in person.  They have greatly divergent views on the age-old question of how the pursuit of beauty relates to the pursuit of truth.  Where many densely argued letters have not yielded a concession, my master hopes to prevail through sheer force of personality."
        
        *if szth > 0
          "That's all?"  You search his face for any sign that he knows of Pan Szeric's secret Theurge.
          
          *goto seriousphil
        *if tone > 1
          "You jest."  When it becomes clear that he doesn't, you lean forward. "You truly expect us to believe that you
        *if tone = 1
          "Forgive me, Ecclesiast, but I'm not sure I understand you. You
        *if id > 1
          and the 
          *if helot
            bloody 
          Archon's cousin
        set out across a rebel-infested wilderness to better debate
        *if int = 2
          the finer points of aesthetics
        *if int < 2
          philosophy 
        with a ${whend}ish lord?"

        *if helot and (int = 2)
          Linos visibly struggles to hide his surprise at hearing a helot speak in philosophers' jargon.
        *label seriousphil
        "Kurios Horion takes his debates very seriously, I'm sad to say."  The Ecclesiast shakes his head wearily.  "And as for the danger,
        *if knowwhy < 1
          well…there are powerful folk in Shayard City who bear kurios Horion no great love.  We feared that if we took the more circuitous route to Szeric, it would give them time and opportunity to stage a fatal accident in the wild."
          
          "So you chose the Whendward Hills?"
          
          Linos looks rueful.  "It ensured that any fatality would at any rate not come from my master's enemies in Shayard."
          *set knowwhy 1
          *goto linoschat
        *if knowwhy > 0
          we've already spoken of the enemies who keep us from choosing the longer, surer path."
          *if knowwhy = 3
            
            You narrow your eyes, dubious. "Your master spoke of himself as a threat to the Alastors—as if he were somehow engaged in freeing Shayard.  This trip has nothing to do with that?"
          
            "If he told me it did, ${milady}, I'd be elated."  Linos blows out his cheeks in a gusty sigh.  "As it is, I can only sympathize with your obvious incredulity."
            *if szth > 0
              Nothing in his demeanor suggests that he knows what Horion's shared with you.
        *goto linoschat
      *hide_reuse #"$!{tell} me more about your master Horion."
        *if id <= 1
          "Kurios de Lelle comes from a small Southriding family, with an estate on the outskirts of the capital."
          
          "Big enough to keep its own Ecclesiast?" you ask skeptically.  All of the Houses you know attend the Naos of Rim Square alongside the common folk—even the Keriatou and Pelematou.
          
          Linos blinks in surprise, then gives a slow, knowing nod.  "Captain…if you traveled from the Outer Rim toward the heart of Shayard, you would find it quite common for even small Houses to have their own family priest.  In the many great-towns, let alone cities, there are far too many people to be served by a single Ecclesiast—and far more priests willing to serve.  For all their wealth, your former Keriatou masters would struggle to attract a second trained Ecclesiast to so remote a seat as Acron."
          
          *if tone < 3
            "Fair enough," you reply, feeling a 
          *if tone = 3
            You ignore the 
          mortified warmth in your cheeks.  "And within his House, kurios Horion is…"
          
          "Third child of a second child.  Scant likelihood of inheriting the land; no heart for expanding the family interests in trade.  But a passion for the life of the mind, and a fearless candor which has 
        *if id > 1
          Linos searches your face for some sign of your intentions.  "Kurios Horion will never inherit the Leilatou land or house—he stands too far from the eldest line.  Instead, he has always had a passion for the life of the mind, and in particular, for the great Karagond tradition of philosophy, natural history, and political doctrine.  His candor and irreverence on these matters make him an often inconvenient scion for a family known for Xthonic devotion and loyalty to the Thaumatarch."  The priest waves a hand dismissively.  "Of course, his name still draws fools seeking to win favor with Her Glory Archon Phrygia.  But in truth, she keeps her distance from him, and his influence in Court is that of a gadfly."
          
          *if aristo
            "So he is not much involved in the Court's games of influence?"
          *if helot
            "Not much for courtly power games, then?"
          The Leilatou are certainly known for devotion and loyalty, but you'd also always heard them described as ruthless practitioners of inter-House intrigue.
          
          "Philosophy leaves little time for such matters."  The priest gives a rueful shrug.  "Though his uncompromising honesty has
        won him some friends and many foes."
        *label linrehor
        *choice
          *if (linosqq < 20) and (linosqq > 1)
            *hide_reuse #"And an Ecclesiast who is strangely tolerant of his treasons against the Hegemony."
              Linos shrugs impassively.  "Kurios Horion's passion for Order is easily overlooked on first acquaintance.  Those who have known him long enough, however, may see past the irreverence and come to sympathize with the vision of justice that moves him."  
              *if forever
                *goto linrehor
              He folds his arms across his chest.  "And ${kuria}, not all who wear the surplice believe that the Order of Xthonos and the Order of the Thaumatarchy are identical."
              *set linosqq +20
              
              "What's that mean?"
              
              "The Order of the Hegemony is plainly flawed.  It seeks to dominate too many peoples, across far too much of the world.  It must thus use more violence than a less ambitious, more natural Order."  You've heard many a priest take on this assured, lecturing tone; you never imagined you'd hear it used to deliver sweeping seditions.  "Their mastery of Theurgy led the Karagonds into hubris.  Now to keep their bloated empire alive they treat their conquered peoples with neither justice nor compassion.  Moreover, they have succumbed to greed, draining the provinces of blood and wealth to turn Karagon into a garden of luxuries."
            
              Blinking, you try to fathom the Ecclesiast's nonchalance.  "Does everyone idly talk treason like this in the 
              *if id > 1
                Archon's palace?
              *if id <= 1
                Court of Shayard?
              Because in Rim Square, to whisper two words of what you just said would earn a Harrowing." 
            
              Linos's smile doesn't reach his eyes. "Few dare to whisper it in Grand Shayard either.  But the truth can not be swallowed forever."
              *goto linrehor
          *hide_reuse #"What manner of philosophy so occupies kurios Horion?"
            "All manner," sighs Linos.  "Physics and metaphysics, ethics and poetics, politics, logic and natural history.  To read them in the original, he's become fluent in High Karagond, Erezziano, and Nyryq as well as Koine…and has started in on Wiendzna, the better to argue with Pan Szeric."
            *goto linrehor
          *if horion > 3
            *hide_reuse #"How much would his House pay for him in ransom?"
              Linos moistens his lips, looking uncomfortable.
              *if id <= 1
                "The de Lelle are not the poorest of families, ${kuria}.  I obviously can not speak on their behalf, but I should think that for the safe return of kurios Horion and myself, they would find a way to provide two hundred gold staters."
                
                "Do they 
              *if id > 1
                "If the kidnapping is discovered by the Hegemony, Her Glory the Archon will be under great scrutiny.  I cannot swear that she would pay a ransom for her gadfly cousin.  Certainly I would not expect more than…say, two hundred gold staters."
              
                "Does she then
              value him so little?"  That's half the cost of feeding your band for the year.
              
              *if id > 1
                "She values her kin greatly.  But
                *if knowwhy > 1
                  Strategos Nomiki would demand that the Archon pay no ransom, merely promise revenge if any harm befalls kurios Horion.  As the Strategos hopes it will."
                *if knowwhy < 2
                  kurios Horion's powerful enemies would demand that she invade the Whendward, not pay a ransom; and even an Archon must listen to some voices."
                  *set knowwhy 1
              *if id <= 1
                "To be caught paying even that to a rebel band would risk the Harrower."
              The priest clears his throat.  "$!{kuria}…a trusted go-between might be able to negotiate an appropriately discreet exchange—and call on some other sources of which the ${delelle} may not be aware.  Kurios Horion is valued by his friends almost as much as by his family."
              *goto linrehor
          #"And how long have the two of you been lovers?"  I'm keen to see how he reacts to the scandalous suggestion.
            *set hor_rel -1
            Linos's lips vanish into each other and his dark eyes flare.  "You shame only yourself by such an insinuation, ${kuria}."
            
            *if tone < 3
              "Come now, Ecclesiast.  You're nobly born; a secret marriage would not be unthinkable."
            *if tone = 3
              "And you risk both your own throat and his by an insolent response."

            *if hor_rel > 6
              The priest looks as if he's struggling not to punch you in the face.  
            *if hor_rel <= 6
              Terror and fury war across the priest's face.  
            *if tone < 3
              "A secret marriage is a contradiction in terms.  We 
            *if tone = 3
              "We
            are not wed.  And any unchaste entanglement of the sort you suggest would be 
            *if hor_rel > 6
              unthinkable."  Regaining control, he retreats into a stony silence.
            *if hor_rel <= 6
              un…unthinkable."  You can hear his voice beginning to fracture.
            *if tone < 3
              *choice
                #I apologize.
                  "I didn't intend to imply unchastity on anyone's part, hieros Linos.  Please forgive my poor choice of words."
                  
                  The priest looks coldly at you for a moment before saying, "I don't know how you imagined your words would be understood, ${kuria} ${lname}.  But…I feel it would be inadvisable for me to hold a grudge."
                  *goto linoschat
                #I steer back to other topics.
                  *goto linoschat
            *goto linoschat
          #I steer back to other topics.
            *goto linoschat
      *if (linosqq < 20) and (linosqq > 1)
        *hide_reuse #"What makes you so tolerant of your master's heresies?"
          "I share most of them."  Linos's eyes glint.  "Or, to be precise, I believe that on these matters many of my fellow Ecclesiasts have fallen into heresy—wrongly believing the Angelic Order and the Order of Karagon to be identical."
          
          "That bears explaining."
          *set linosqq +20
          *goto linossedit2
      *if knowwhy = 1
        *hide_reuse #"Who are these enemies who are so alarming that they've sent you into the Whendward?"
          *goto enemytalk
      *if (knowwhy > 1) and (linch2 < 1)
        *hide_reuse #"Why hasn't Strategos Nomiki already disposed of your master?"
          *label enemytalk
          "On this matter, ${kuria}, you should ask my master, not me."  Linos's forehead wrinkles in an expression of apology.
          *choice
            *if horch > 0
              #"I already have."
                "Then you know more than I do."  The Ecclesiast watches you intently.  "He complains to me about the philosophers with whom he argues by epistle.  But of his true enemies, he lets only fragments slip; I know the 
                *if id > 1
                  Strategos of the Alastors 
                *if id <= 1
                  most traditionalist Houses
                would see him destroyed, but no more than that."
                *goto linoschat
            #"I'm asking you."
              *if (hor_rel < 7) and (id > 1)
                At your steely response Linos draws back, his jaw clenched but trembling.  You can see the moment where he decides that you will indeed kill him if he doesn't answer.
                *if knowwhy = 1
                  "My master's greatest enemy is a Karagond named Nomiki.  The Strategos of all the Alastors in Shayard."
                  
                  You blink.  "Why would the Alastors' general want to kill a Leilatou?"
                  
                  "Because my master has been reasonably open with his belief that a Karagond Hegemony has no business ruling Shayard."
                  
                  "Don't you dare lie to me, priest."  Your tone makes the Ecclesiast flinch away.  "If your master were truly one step short of rebellion, why wouldn't she have killed him long ago?"
                  
                *set knowwhy +3
                "Kurios Horion is not as much a fool as he might seem, ${milady}." The words flood out of him.  "His name makes it impossible for Nomiki to take him without proper trial—and he ensures that when he speaks his treasons, it's only among friends.  Those who would bear witness against him have only heard reports at third or fourth hand.  Some months ago she had him tried for sedition.  He made her look a fool in the Archon's court."
                
                You step closer.  "You tell me that a Leilatou truly wishes to see the Karagonds gone from Shayard."
                
                "Not wholly gone, no; he wishes to benefit from their knowledge and trade.  But not ruling as they do today.  He would see the nations united in a [i]koinon[/i] or Great League, not a Hegemony."  Linos spreads his trembling hands.  "Kurios Horion can say many things on this vision which stop just short of treason.  This is what maddens the Strategos."
                
                You press on before he has a chance to recover his poise.
                *label linfear
                *if linch2 = 13
                
                  You fix the trembling priest with a long, silent stare.  At length you say:
                  *goto linoschat
                *hide_reuse
                *choice
                  #"Who else in Shayard would count him an enemy?"
                    *set linch2 +1
                    *set luse true
                    "The…the traditionalist Houses loathe him.  The ones who pride themselves on being true Shayardenes, with old names and bloodlines going back before the Conquest.  Kurios Horion mocks them and their rituals.  Says they've confected things that have no roots in the histories.  They want to end foreign influence in Shayard…so it maddens them when he traces the genealogy of their practices to the Wiends and Erezziano."
                    
                    "Give me a name."
                    
                    "Luse de Toman," Linos gasps.  "Lady of Erelyne Manor.  She's the chief of the traditionalists."
                    
                    *if aristo
                      You furrow your brow, wondering you've heard that family name before—from your Keriatou cousins, perhaps?  They may have taken a Karagond name, but Calea and Hector's father was always complaining about foreign contamination of the old Shayardene ways.
                    "And none of them ensured his fall when Nomiki had him on trial?  None of them accused him of wanting this…Great League rather than a Hegemony?"
                    
                    The priest shakes his head rapidly.  "Those Houses are too vulnerable to sedition charges themselves, ${kuria}.  They're known to whisper about restoring the monarchy, about a pure Shayardene religion.  They'd not risk a public denunciation when the accusation might just as easily end up falling on them."
                    *goto linfear
                  #"What did you say at kurios Horion's trial?"
                    *set linch2 +1
                    "Me?"  The Ecclesiast wipes sweat from his brow.  "I testified that while I had heard kurios Horion utter some things in his cups which were unbecoming or unsavory, I had heard nothing which I would consider treason against the Order of the Angels."
                    
                    "And what consequences have you faced for this?  With no Leilatou name to protect you?"
                    
                    "The name offers some protection to those who serve it."  Linos manages a faltering, grim smile.  "The Strategos sought to have the Archimandrite send me to serve in Corlune, where I could be punished at leisure.  But kurios Horion intervened personally and was able to keep me in the Court."
                    
                    "She has not moved against your family?"  Every officer of the Hegemony you've known was a great believer in indirect and collective punishment.
                    
                    "There has never been love lost between me and my elder sisters, ${kuria}."  Linos's face twists. "Petty traders with neither vision nor devotion…Strategos Nomiki doubtless knows that sending Alastors after them would give me more satisfaction than grief."
                    *goto linfear
                  #"How has she moved against him since the trial?"
                    *set linch2 +10
                    The priest shakes his head. "Nothing overt, ${kuria}.  To strike at him and fail a second time might lead the Hegemony to revoke her office.  No Strategos can survive who is a laughingstock to the nobility of her archonty."
                    
                    "But she still seeks to destroy him."
                    
                    "Doubtless."
                    
                    "She might, for example, have got someone he trusted to lead him up into the Whendward Pass…in the hope that the rebels would permanently remove him."
                    
                    Linos's eyes gape in shock; his voice is so choked as to be barely audible.  "$!{kuria}…unthinkable…the love I bear kurios Horion…"  His mouth works silently for several moments before he manages to say, "I would never do such a thing.  Never.  Not for my soul, and certainly not for a damned Karagond!"
                    *goto linfear
                  *if (linch2 > 9) #"Lies!" I bark.  "Safer here than in the Owlscap?  You expect me to believe that any true friend to Horion Leilatou would bring him to [i]me[/i]?"
                    "I…"  Two tears course down Linos's cheeks. "$!{kuria}, I had truly hoped…that if we did meet, we would find common ground.  That you would understand.  We are no friends to Karagon.  We seek change."  His lips contort with shame.  "If I have instead condemned us both to death…it is by folly, not treachery.  Nor any lack of love for milord Horion."  It would be hard to misinterpret the fervency in his final words.
                    *set linch2 +1
                    *goto linfear
                  #"Enough of this."
                    You abruptly switch topics on the trembling priest.
                    *goto linoschat
              "Forgive me, ${kuria}. I simply don't know enough."  Linos leans forward with a pleading expression.  "I would be inventing ideas, based on fragments overheard in recent years.  I would get it wrong.  And then you'd
              *if hor_rel < 16
                likely kill us."
              *if hor_rel > 15
                believe me a liar."
              *goto linoschat
            *if horch = 0
              #"Very well."
                You'll speak to Horion soon enough.
                *goto linoschat
      *if linch = 0
        *hide_reuse #"Give me one good reason to keep you alive, priest."
          *if hor_rel < 7
            The priest emits a long, shuddering sigh before steeling himself to speak.
          "I've lived a full life, by the grace of the Angels.  If this is my time, it's my time."
          *if hor_rel < 7
            His voice becomes a wheeze and ends in choked silence; it takes him a moment to regain control.
          *if hor_rel > 6
            The priest's eyes bore into you.
          "But ${kuria}…with my help, you can bring such order to your followers that they will obey your word not only now, but when they have grown into an army a hundred times this size."
          
          "Threaten a man's life, and he'll make some big promises."
          
          Linos persists despite your unimpressed tone.
          *goto relpitch
      *if (horion < 4) and (linch = 0)
        *hide_reuse #"Do you have any other advice to offer, Ecclesiast?"
          Linos's black brows lower until his eyes are completely shadowed.  "That depends on whether you intend to remain a bandit in the woods…or actually aspire to overturn the Karagond Hegemony."
          *label aspiration
          
          *if aristo
            "I thought I'd have a stab at the latter," you say drily.
          *if helot
            "I think you know which one I intend,
            *if tone = 1
              Ecclesiast."
            *if tone > 1
              priest."
          
          "Then you must bring such order to your followers that they will obey your word not only now, but when they have grown into an army a hundred times their size."
          
          "And you
          *if nointerro
            mean me to think…"  You pause, studying the calm-faced Eccelesiast. "A devout priest like yourself is offering to help us overthrow the Angels' Order?"
            *page_break
            *goto linossedit
          can tell me how to do this?"
          
          The wiry priest hesitates for a moment, then gives a stern nod.
          *label relpitch
          *set linch 1
          "Every soul in your band was raised to revere the Blessed Angels, and to follow without question the orders of the Angels' Eclect."
          
          "The Thaumatarch and his Nine."
          
          "So they were told.  Now—thanks to the abuses of the Karagonds and your challenge—they don't believe it.  That leaves what the philosophers call a [i]kenon[/i]: an emptiness, a void hungry to be filled.  Your followers don't know who speaks for Xthonos any more."  Linos leans toward you.
          *if hor_rel < 7
            Sweat streaks his bald head, but the passion in his voice goes beyond fear.
          "There were Eclectoi before there was a Thaumatarch, ${kuria}.  The older books in the Codex are quite clear on this.  If a monarch betrayed the Order of Xthonos, the Angels would send Their Chosen to repair and reinstate it."
          
          You can feel your face twist with incredulity.
          *if skep < 50
            "Those Chosen were always from the ruling houses."  You're familiar with the accounts in the ancient Codex.
          "You're suggesting that the Angels would choose a
          *if helot
            helot?  Someone that all the world thinks filthy and crude, barely higher than an animal?"
          *if aristo
            petty noble rebel?"
          *page_break
          Ecclesiast Linos hesitates only a moment before drawing himself up and declaiming, "I believe the Word of the Angels, ${kuria}…as recorded in the original Shayardene Codex, before the blaspheming Karagonds rewrote it and added their Latter Books to justify the Hegemony.
          *if helot
            In those books, it is clear that the helotry are worthy of the compassion due to any other human."
            
            "But surely not the respect."
            *if skepreal <= 50
              It pains you to say it. "Would anyone reading the Codex believe that the Angels would choose someone from the lower orders to hold authority over Their priesthood?"
            *if skepreal > 50
              There's a hard edge to your voice.
            
            "The Angels may choose as They will, however shocking Their choice.  And
          I do not believe 
          *if aristo
            the Angels 
          *if helot
            They
          will suffer the flawed Order of the Thaumatarch for ever.  Already, They are calling Their Eclectoi, the Chosen Ones who will set the world to rights."  He gestures
          *if hor_rel < 7
            with a shaking hand
          at you.  "In so dire a situation, should it be a surprise that among Their Chosen is one
          *if helot
            furthest from the corruptions of power—one
          who threatens the Hegemony with force?"
          
          "You would bless a rebellion…in Xthonos's Name?"  A devout if heretical Shayardene priest, from the capital…his support would mean a great deal, not only to your band but throughout the realm.  But you still struggle to believe that it's a sincere offer.  "You're so sure that the future I'll build is to your liking, Ecclesiast?"
          
          "No Order perfectly reflects the Order of the Angels, ${kuria} ${lname}."  
          *if anarchy > 20
            Linos's mouth twists slightly; you're sure he's heard tales of the anarchy you've spread across the Rim.  
          *if anarchy < 21
            Linos seems to have no problem shrugging off the petty anarchy your rebellion has created so far. 
          *if (wisardry = "Goety") and (theuknown >= 10)
            *if lingoety = 0
              
              "And one built on Goety?"
              
              *gosub lingoete
              He swallows hard. "Can 
            *if lingoety > 0
              "Your self-described Goety is something of a stumbling block.  Can
            I not persuade you, for the sake of all we seek, to adopt a name that more befits the Angels' Eclect?"
            *choice
              #Oh, very well.  I'll call myself a Theurge.
                *set wisardry "Theurgy"
                *set wisard "Theurge"
                *label wisewis
                "A wise decision, ${kuria}.  It strengthens greatly my confidence in your vision."  Linos looks relieved.
                *goto ifeclect
              #Oh, very well.  I'll call myself a Wisard.
                *set wisardry "Wisardry"
                *set wisard "Wisard"
                *goto wisewis
              #No—I'm a Goete.
                You shake your head sharply.  "If the Thaumatarchy is set on making a monster of me, I'll make the most of it."
                
                "Then we shall convince them that you are an Angelic Goete."  Linos sighs.
                *goto ifeclect
          *label ifeclect
          "If you are Chosen, as I suspect, the Angels will reveal to you where you fall short of Xthonos's Order.  But your movement will be constantly vulnerable to Xaos unless your followers are wholly devoted to the Word of the Angels and prepared to follow their leader without question.  Let me help you—and you will see the effect not just on this band, but on other priests of the Angels all across Shayard who hear you named Eclect."
          
          *if skep > 50
            *choice
              #I burst out laughing.  "Are you Horion's priest or his jester?  Chosen of the Angels?  Do you know anything of me at all?"
                Linos's face goes momentarily blank, then tautens with a contained blend of fury and fear. "If this is how you respond to my…"
                
                You cut him off.  
                *if aristo
                  "My dear man, I thank you for 
                *if helot
                  "Priest, it's
                the best joke I've heard since coming to the greenwood.  But all this 
                *if aristo
                  business 
                *if helot
                  talk
                of Eclect is
                *if aristo
                  arrant
                nonsense—and I've no intention of trying to build a rebellion on nonsense."
                
                *goto lindone
              #I shake my head—but Linos has got me thinking of an alternative. A ritual to free my followers from fear of Angels, Xthonos, and all other phantasms.
                *goto kenoninspire
              *if (skepreal >= 50) 
                #Despite my skepticism, I give the offer a moment of serious consideration.
                  *goto hardlythefirst
              *if (skepreal < 50) 
                #Despite wanting to keep up my reputation for skepticism, I give the offer a moment of serious consideration.
                  *goto hardlythefirst
          
          *label hardlythefirst
          It's hardly the first time you've wondered how to address your band's hunger for Angelic
          *if diakon <= 1
            blessing.
          *if diakon > 1
            blessing—especially since 
            *if diakon = 2
              trying and failing to commission a Diakon.
            *if diakon > 2
              the Diakon visited your camp.
          You regard the eager old priest silently while considering your options.
          *label eclectchoice
          *choice
            *hide_reuse #"What are the signs of a true Eclect?" I demand. "How can you know?"
              "Well, of course, the gift of a Talisman would be the clearest sign, allowing you to perform Theurgic miracles without the shedding of blood.  But that's so rare, it's hardly a necessity." The priest rubs his bearded chin.  "In some of the stories, an Eclect hears the Angels speak.  But in many others, there is no sign that the Eclect was receiving such words; they make decisions which only in retrospect, after an unlikely victory, are recognized as subtle Angelic guidance. In all of the stories, the Eclect speaks truths that others are not ready to hear, but that must be heard."  Linos inclines his head to look at you. "And an Eclect is always recognized by a true priest of Xthonos.  A priest who can sense the power of the Angels at work."
              
              "And you sense that in me?"
              
              Linos is trembling slightly.  "Angels save me. I do."
              *goto eclectchoice
            #Yes—I want Linos to proclaim me the Chosen of the Angels.
              *set religion 1
              *set linbless true
              *if skepreal > 50
                It may all be a load of rubbish—but from the mouth of an Ecclesiast like Linos, it will have a power you can't deny.  Even if he is only offering it to save his own life.
              *if skepreal <= 50
                "I am the Angels' Eclect," you say slowly to yourself.
                *choice
                  #And I believe it.
                    *gosub iameclect
                    The old priest's eyes reflect the same certainty back at you.  Overcome with emotion, you manage to say,
                    *goto linvwell
                    *label iameclect
                    *set religion 5
                    *set skep %-30
                    Everything makes sense now.  
                    
                    For a
                    *if aristo
                      noble to end up at the head of a helot uprising—that
                    *if helot
                      helot to survive a confrontation with two Theurges and their Alastors—that
                    doesn't happen by mere coincidence!
                    *if not(notthere)
                      Nor does an encounter like this one with Horion and Linos.
                    You feel a weight lift from you, and wonder if your face is actually shining, so powerful is your sudden sense of the Angels' presence.

                    *return
                  #Who knows—it might even be true.
                    There's no concrete evidence that the Angels have Chosen you or anyone else in your rebellion.  One old Ecclesiast offering to bless you…it doesn't necessarily mean anything.
                    *gosub maybeeclect
                    *goto linvwell
                    *label maybeeclect
                    *set religion 3
                    *set skep %-20
                    But a tingle of excitement courses through you at the thought that it might.
                    
                    [i]Mighty Angels…[/i]am [i]I Eclect?[/i]  You send the prayer out tentatively, and feel no particular thought or impulse that might constitute a response.  But you feel no sense of negation, either; the enticing warmth of possibility remains.
                    *return
                  #I'm not, of course.
                    *gosub baheclect
                    *goto linvwell
                    *label baheclect
                    *set skep %-10
                    But the power the idea will give you is too strong to deny.
                    *return
              *label linvwell
              "Very well, Ecclesiast Linos."
              
              Linos nods, looking relieved.  "Let me plan what I'm to say, then, ${kuria}."
               
              You nod, still
              *if religion = 5
                feeling giddy and ecstatic.
              *if religion != 5
                unsure yourself of how to live up to so grand a claim.
              "We'll speak on it again tomorrow."
              *goto lindone
            #No—I want to declare myself Eclect, without relying on the priest.
              *set religion 1
              *if skepreal <= 50
                "I am the Angels' Eclect," you say slowly to yourself.
                *choice
                  #And I believe it.
                    *gosub iameclect
                    It's a real struggle to quell your ecstasy long enough to deal with the priest.
                    *goto linject
                  #Who knows—it might even be true.
                    There's no concrete evidence that the Angels have Chosen you or anyone else in your rebellion.  
                    *gosub maybeeclect
                    *goto linject
                  #I'm not, of course.
                    *gosub baheclect
                    But the power the idea will give you is too strong to deny.
                    *goto linject
              *label linject
              "It's a good idea, Ecclesiast.  I just don't see why I need you."
              
              Linos's face goes momentarily blank, then tautens with a contained blend of fury and fear.  "$!{kuria}…forgive me.  But how many people will believe a ${woman} who declares ${him}self Chosen of the Angels?  With…with no sacred authority to confirm it?"
              
              You aren't interested in answering his protests.  "We'll soon see."
              *goto lindone
            #I want to lead them myself in a new ritual of devotion to the Angels—one which requires neither Eclect nor Ecclesiast.
              *set religion 11
              "I thank you for inspiring me, Ecclesiast," you say slowly.  "But I don't think you can help."
              
              Linos's thick eyebrows draw together in baffled dismay.  "Do you mean…$!{kuria}, to make such a claim without sacred authority…"
              
              "You swore a vow of conformity, Ecclesiast.  And like it or not, you're still following it."  The ideas that have been coalescing in your head finally find voice.  "You say you'd see change from one Order to another. But in both, the Ecclesiasts would be the ones to control us, steer us, tell us what or who the Angels have Chosen."
              
              "And whom would you elevate to that place, ${kuria} ${lname}?"  Despite a hint of scorn, his perplexity seems genuine—and you know you were right.  His mind is too rigid to conceive of true change.
              
              "Tell me, Ecclesiast Linos…how do your fellow-priests go about perceiving the Angels' will?"
              
              "We steep ourselves in the Canon and the wisdom of centuries.  In time, just as a seasoned hunter can sense north despite a cloudy sky…or know at a glance where a deer has passed on stony ground…we come to naturally perceive both the Order of Xthonos and the subtle snares of Xaos."  As he recites the well-worn examples, you can hear the old priest's defensiveness curdling into ire.  "Only then might the Angels Themselves speak, audible in the silence of a hallowed heart."
              
              "And yet the Ecclesiasts have, almost to a soul, supported the Hegemony.  This 'wisdom' that was meant to reveal Order has in fact blinded them to truths obvious to a helot child in my camp."  You press on over Linos's appalled babble.  "I say that any of us can know Order in our hearts, if we attend properly.  Any of us can sense the call of compassion, of justice.  [i]Any of us can hear Angels.[/i]  And I'd have my fellows know that—not look to any Eclect or Ecclesiast to tell them the way of Xthonos."
              
              A speck of blood appears where Linos has bitten his lip.  "$!{kuria}…this is madness.  What you describe is true Xaos."
              *choice
                #No.  I'm sure this is the will of the Angels.
                  *set religion 15
                  *set skep %-10
                  *set skepreal %-20
                  Joy floods you at finally speaking aloud the truths that have been growing in your heart.  "This is the deeper rebellion to which the Angels have called me, priest.  And if I am Eclect, it was to bring this message.  Go now, and beseech Them to speak to you as well."
                  *goto lindone
                #I'm not quite sure if it's true—but I'm sure it's less wrong than the Ecclesiasts.
                  *set religion 13
                  *set skepreal %-10
                  *if arrog > 0
                    The idea that helots can perceive the Angels' Order for themselves sits uneasily with you, too—but better that than to keep them in thrall to misguided Ecclesiasts.
                  *goto giftangel
                #Of course it's not true, but it's what I need my followers to believe.
                  What's important is breaking the hold the Ecclesiasts have on them—setting them at odds with the priests and freeing them from the lingering threat of Ecclesiastic condemnation.  You're confident that you and your chosen leaders can keep order without a priestly hierarchy.
                  *label giftangel
                  
                  "What I describe is the gift of the Angels to every human soul, priest.  And from tomorrow you'll see it begin.  Tell me then whether you believe it to be of Xaos or the Angels."
                  *goto lindone
            *selectable_if (skep > 50) #I want to lead them in a ritual which will free them from fear of Angels, Xthonos, and all other phantasms.
              *label kenoninspire
              *set religion 21
              Something falls into place in your head.  "Ecclesiast…you
              *if int < 2
                used some philosopher's word for emptiness."
                
                "Kenon.  The void which nature abhors and seeks to fill."  Linos's voice is expectant with a hint of confusion.
                
                You nod slowly.
              *if int = 2
                spoke of kenon, the philosophers' void.  Are there not ${nere}ish writers who say that kenon is the source of all things?"
                
                "That was not the sense in which…" Linos begins, but you cut him off.
                
                *comment endif
              "As you say, my followers no longer know who speaks for Xthonos.  And that is precisely where I intend to keep them.  Tomorrow, you'll understand my intent."
              *goto lindone
            #No.  I would only accept if more than one priest hailed me as Eclect.
              "Hieros, with all respect for your wisdom and rank—I can not accept so great a title on the word of one priest, however holy.  The word of at least three should surely be required."
              *if skepreal <= 50
                Would even three be enough to silence your nagging fear of blasphemy—of claiming a name far too great and holy for you?
              *if skepreal > 50
                Otherwise your own followers might find it hard to credit, let alone the outside world.
              
              Linos's expression remains level, but there is a strain in his voice—perhaps anger, perhaps desperation.  "We do not have three priests in the greenwood, ${kuria}, nor may we ever."
              
              "Nonetheless, it must wait until such a time.  If I release you and your master, and if you truly believe the name you've just given me…then seek out two others who will confirm it."
              
              The Ecclesiast bows resignedly.  "I shall pray for the opportunity, ${kuria}."
              
              *goto lindone
            #No.  All I want is for Linos to lead the band in a Sacrament of Compassion.
              "I cannot accept."  You raise both hands, cutting off Linos's protest. "I am no Eclect, hieros.  You do me too great an honor.  But you are right that many of my followers yearn for the authority of the Angels.  If you would administer Sacrament to them today, I would be grateful."
              
              The Ecclesiast sighs, straightens himself.  "It is my vocation, ${kuria}; speak not of gratitude.  Let them be mustered.  And I pray that you'll think more on this matter."
              *set skep %-10
              *set morale +10
              
              *goto lindone
            #No—I don't want to meddle with religion at all.
              "An interesting idea.  But I don't think I'll take you up on it."  You cut off Linos's protest with a 
              *if tone = 1
                gracious clearing of the throat.  "I'm grateful for the time and wisdom you've shared this morning, Ecclesiast.  Enjoy the hospitality of the greenwood."
              *if tone > 1
                sharp hand gesture.  "Enough."
              *goto lindone
      #I've nothing more to ask Linos.
        *if linch = 0
          "Then I think we've nothing more to…"
          
          Before you can finish dismissing him, Linos interrupts.  "$!{kuria}, forgive me, but before you conclude that I'm of no use to you…do you intend to remain a bandit in the woods, or actually aspire to overturn the Karagond Hegemony?"
          *goto aspiration
        You've heard all you need to from the Ecclesiast.
        *label lindone
        *if (horch = 0) and not(nointerro)
          Dismissing him, you send for Horion.
          
          *goto horionhi
        *else
          Dismissing him, you contemplate your ${guest}s' future.
          *if religion > 0
            *page_break
            Before anything else, you 
            *if religion < 10
              *if linbless
                need Linos to declare you 
              *if not(linbless)
                intend to declare yourself
              Eclect of the Angels.
            *if religion > 10
              want them to be present for your experiment in religion.
            *goto foundreligion
          *goto whattodowt
  #Horion.
    *label horionhi
    The moon-faced aristocrat 
    *if (horion != 5) and (horion != 3)
      steps into the tent.
    *if (horion = 5) or (horion = 3)
      appears in your tent doorway, leaning heavily on a young bandit guard.
    "Good morning to you, ${kuria} ${lname}."
    *if horion > 3
      He sounds calm, but is blinking a little more than you consider natural.
    *if (horion = 5) or (horion = 3)
      The sweat on his face tells you how much effort he's spent to get here, and he breaks off his attempt at a bow, groaning deep in his throat.
      *goto wthanx
    *if aristo and (horion < 4)
      With your etiquette training, you recognize the inflections of his deep bow: trust, respect, gratitude.
    *if helot and (horion < 4)
      He makes a deep and elaborate bow—the first time any noble
      *if simz_here
        other than ${simon}
      has offered you such courtesy.
    *label wthanx
    "Warmest thanks for your hospitality."
    *label horionchat
    *if horch > 0
      You've asked Horion everything you care to.
      *goto hordone
    *choice
      *if (horion = 5) or (horion = 3)
        *hide_reuse #"How is the shoulder?"
          Horion grimaces, glancing at the brown and crusted bandages.  "Well…I dare say I'll live."
          
          *if tone = 3
            "Oh?  Let's not be too hasty."
            
            The noble strives for a feeble smile.  "Very well.  I don't think it'll be the shoulder that kills me."
            *goto horionchat
          *if tone = 2
            "Glad to hear it.  And apologies again for greeting you with an arrow."
          *if tone = 1
            "I 
            *if aristo
              can't possibly apologize enough for the violence to your person, 
            *if helot
              am so very sorry for your injury, 
            kurios ${delelle}."

          "Accepted, of course."  Horion takes a moment to seat himself at your side, gingerly, with jerky movements and a few ragged gasps.  "I've been on hunts where a friend's over-excited hound gave me a nip, and I'd no sooner hold this against you.  I reckon a ${woman} in your place has many uses for a beast like this ${kalt}."
          *goto horionchat
      *hide_reuse #"$!{tell} me more about yourself, kurios Horion."
        *if id = 4
          "Well, as you've seen through our little subterfuge…"
        The stout noble
        *if (id = 4) or (hor_rel < 14)
          uncomfortably
        scratches his 
        *if hor_rel > 13
          chin.
        *if hor_rel < 14
          chin and adopts a tone of strained levity.
        *if id > 1
          "Where to begin, ${kuria}?  I came of age just before our family was elevated to the Archonate—a thoroughly unpleasant shock, I must say.  We all knew that old Great-Uncle Meletos was both an insufferable prig and a backstabbing intriguer; who'd have thought that would be enough to win him a decade as Conte Shayardene?  And thus uproot us all from a comfortable middle Westriding existence to permanent residence in a snakepit."  Horion's scowl lightens slightly.  "Fortunately, I was far enough from heritance to be left to my own preoccupations.  The family have done their best to ignore me for some time now."
          *label abouthor
          *if (horch2 > 2) or ((id != 4) and (horch2 > 1))
            *goto horionchat
          *choice
            *if ((horion > 3) and (tone = 3)) 
              *hide_reuse #"Best pray they don't ignore you now."
                *set hor_rel -1
                The grin slips off his stubbly moon face.  "Trust me, ${kuria}—the Angels shall be hearing a great deal from me on that topic."
                *goto abouthor
            *hide_reuse #"What sort of preoccupations do you pursue?"
              *set horch2 +1
              *gosub horlifemind
              *goto abouthor
              *label horlifemind
              "The life of the mind, my dear ${kuria}.  Reading the giants of old, and arguing about them with my fellow dwarfs."
              *if hor_rel < 15
                Despite the strain in his voice,
              Horion's eyes come alive.  "I continually tell my fellows they must spend more time immersed in the histories and politics of our Golden Age, the Nyrnakan Republic, and the pre-Hegemonic city-states of Karagon.  All the truly interesting thinking was done then, all the options attempted.  All lost today, reduced to decadent power games."
              
              *if aristo
                "I can imagine your advice is warmly received."
              *if helot
                "I'm sure they're happy to hear that."

              "Indeed."  The unshaven noble
              *if tone = 3
                sighs.
              *if tone < 3
                winks.  
              "I am among the best-loved men in the Court of Shayard."
              *return
            *hide_reuse #"$!{tell} me of your cousin the Archon."
              *set horch2 +1
              Horion exhales gustily.  "Ah, Phrygia.  Always so clever.  So eloquent.  It was obvious that she would be the Archon chosen from our generation.  I felt sorry for her, really—having to be so very, very proper all the time.  Now she has everyone hanging on her every word, angling for her favor, trying to drag her into a thousand disputes…and–oh!–the amount of time she spends being flown about the place by Theurges!  I've only done it once myself, and it made me thoroughly ill.  Worse than the seasickness I had after that one visit to Scarthe Isle.  Cousin Phrygia's half-accustomed to it by now, but I still see her legs shake every time she returns, and she can't eat properly for a fivenight after."
              
              You try to keep up with this string of barely imaginable experiences.  "Can't the Archon travel as she wishes?"
              
              "Hmmm, well, 
              *if tone < 3
                I'm not sure you appreciate the vastness of the realm, my dear  
              *if tone = 3
                the realm is vast,
              ${kuria} ${lname}." The Leilatou scratches one stubbly cheek.  "We stand here a hundred leagues from Shayard City—but it's another three hundred from the Court out to Linos's home in the Easter Reach.  The monarchs of old had knit together quite an impressive little empire in the name of Shayard before the first Theurges burst onto the scene, you know.  No, I'd not take Conte Phrygia's place for all the silver of Erezza."
              *goto abouthor
            *if (aristo and ((id = 4) and (horch2 > 1))) 
              *hide_reuse #"My father said that when he last visited Shayard, there were whispers that you would rise to the Archonate."
                The Leilatou blinks, visibly taken aback.  "Oh, I'm sure there's been some misunderstanding. Me? I've never had the least hope or desire to be Archon."
                *set horch2 +1
                *choice
                  #"Shall we ask him to explain what he heard, milord?"  The discrepancy sits uneasily with you.
                    *if hor_rel < 12
                      "Of course, ${kuria}—whatever you wish."  The stout Leilatou shifts uncomfortably while you call for an outlaw to bring your father.
                    
                      Moments after he steps into the tent, you see your father's lips twitch in response to the tension on Horion's face.  "Father," you hurriedly say, "yesterday you spoke of our guest as a one-time candidate for the Archonate."
                    
                      "Did I?"  He sniffs, rolls his eyes sourly toward the ceiling.  "Mmmmm…I don't recall my precise words.  But at my last Season, anyone named Leilatou was being mooted for Archon.  Same for kurios Horion as anyone else.  Didn't mean to imply he was a likely candidate."
                    
                      Horion settles back, visibly relieved.  "As I said, young ${kuria}, I was sure there'd been some misunderstanding."
                    
                      "Now, if there's nothing else?"  Your father raises an eyebrow with asperity.  "I have other matters to attend to—and it shames me to be privy to the interrogation of one higher-born than myself."
                    
                      Before Horion can finish his voluble assurance that he doesn't feel the least bit interrogated, you wave a hand in irritation.  "Forgive me for bothering you over so simple a question, Father."  When he's left, you turn back to your noble ${guest}.
                      *goto horionchat
                    *else
                      The tall, portly noble eyes you thoughtfully for a few moments, then says, "Indeed, ${kuria}.  I'd be quite interested to hear who he was speaking to."  When your father arrives, Horion gives him an immediate and enthusiastic welcome, then leans in to say confidentially, "My dear fellow—I understand from your child that when you were last in Shayard, someone mentioned my name in connection with the succession to the Archonate?  Whoever could that have been?"
                    
                      "I…well…"  Your father blinks, looking suspiciously at you and then back to the Leilatou.  "It was a long time ago, kurios, and I might have misunderstood.  Something the lady of Erelyne Manor said in confidence."
                    
                      "Luse de Toman."  Horion's smile looks warm on his lips, but doesn't reach his eyes.  "Of course.  She's got some connection with the aristarch of your district, House What's-their-names…"
                    
                      "Keriatou.  Our cousins.  Not that they'll now admit the relation…"
                      
                      "Yes, yes.  In fact, come to think of it, I heard her hothead grandson, young Abelard de Toman, was recently sent out here for your cousins to try keeping him out of trouble."  Horion laughs.  "He arrived just as your little uprising was starting—and was sent back sharpish!"
                    
                      *if (rescuer = 1) and (int > 0)
                        *set rescuer 2
                        *achieve abelard
                        You try to conceal the shock that runs through you.  A young, male noble whose voice you'd never heard before, who was visiting the Keriatou just as your uprising began?
                      *if hor_rel < 20                      
                        "I, I wasn't aware of that, kurios," your father stammers in response, clearly unsure of the direction to take the conversation.
                        *page_break
                        "In any case, it's typical Southriding pretension," Horion continues cheerily.  "As if she had some idea of who would be the next Archon!  These Souther nobles, all determined to give the appearance of exclusive Court knowledge…as you'll know, milord ${orig_lname}, it can lead to some truly preposterous predictions."
                      
                        "Clearly, kurios!" your father hastens to agree.  "I didn't credit it, even at the time.  But it's the reason I remembered your face."
                      
                        *if rescuer = 2
                          "Who's this hothead Abelard?" you cut in.
                        
                          "A traditionalist.  Gets into fights with youths whose Houses recently swapped their 'de' for an 'atou'—wears the old garb, insists on speaking in Shayarin."
                        The stout noble claps your father on the shoulder.  "Well, Luse de Toman never much liked me…she's no time for philosophy, and doesn't trust anyone who knows more than two languages. But I'm flattered nonetheless."
                        *label dadbowz
                      
                        Your father bows, still looking a bit bemused, and takes his leave.  Turning back to Horion, you
                        *if rescuer = 2
                          calm your racing thoughts and
                        continue your
                        *if horion > 3
                          questioning.
                        *if horion < 4
                          conversation.
                        *goto horionchat
                      Your father
                      *if rescuer = 2
                        (who doesn't seem to have made the same connection)
                      hesitantly continues, "Well, if I remember aright, kuria de Toman did say that…while you might well not be the next Archon…"  He looks at you again, then in query to Horion.
                    
                      "Go on, my dear fellow.  On this matter, I have no feelings to spare."
                      *page_break
                      "…that you'd be the one playing the tune to which the Archon danced."  Your father is plainly unsure of how apologetic to be.
                    
                      "Did she, now," Horion says pensively.  "Now that does have a waft of sense to it.  And I imagine she wasn't best pleased with the idea?"  Not waiting for your father's reply, he looks to you.  "The de Tomans are traditionalists, ${kuria}.  Among other things, they'd like a Court that speaks only Shayarin, save when a Karagond official is present, our children educated on just the Canon and traditional Shayardene texts, with no foreign philosophy, and a policy to make Shayard self-providing in all things, rather than trading with the other provinces.  I don't know how much of that your Keriatou cousins agree with, but it's clearly enough to keep them on friendly terms."
                    
                      *if natl > 65
                        To be frank, it sounds broadly appealing to you as well.
                      "And they thought you would be able to keep all this from happening?"
                    
                      Horion snorts.  "I've only been the most vocal at mocking their benighted schemes.  We won't restore the greatness of Shayard by curling into a ball and suckling on our own toes!  For all that Cousin Phrygia and I disagree on, we are equally resolved on that point."  He glances back to your father.  "I've also done my part to laugh down the idea that bloodlines establish the right to rule—as if leaders could be bred like cattle.  I imagine milady de Toman was incensed that House Leilatou have no link to the old royal line?"
                    
                      "She may have said, ah, something of the sort, kurios."
                    
                      "Well, bless them and their regal blood.  My
                      *if xhe = "he"
                        nephew
                      *if xhe = "she"
                        niece
                      Teren tells me that young Abelard has been muttering about a restored monarchy…and if ${xhe}'s heard it, I imagine the Kryptasts have too.  In any case, milord, many thanks for sharing your memories."  Horion claps your father on the shoulder.  "I'm relieved that no one actually expected me to take the Archonate."                    
                      *goto dadbowz
                  #"As you say."
                    *goto abouthor
            #"On other matters…"
              I return the conversation to another topic.
              *goto horionchat
        *if id <= 1
          "What to say?  House de Lelle's best days were past long ago.  I thank the Angels that I was born far enough from heritance that I don't need to trouble myself with our position or wealth.  It frees me to pursue my own preoccupations."
          
          "Such as?"
          
          *gosub horlifemind

          You 
          *if tone < 3
            can't help but
          *if tone = 3
            resist the urge to
          laugh. "Do you to Court 
          *if tone = 1
            often, milord?"
          *if tone > 1
            often?"

          "Yes—but petty Southriding nobility are thick as mice in the Court, and paid roughly as much attention."  Horion shakes his head ruefully.  "I'm a man of no real influence, ${kuria}, I'm afraid.  My sisters do well enough in trade, but I wouldn't be known at all if I didn't occasionally speak my mind in ways that irritate the powerful."
        *goto horionchat
      *hide_reuse #"What do you make of our rebellion?"
        *label horionbrow
        Horion's brows leap up his forehead.  "Ah, now, there's a dangerous question!  In truth, ${kuria}, I don't yet know.  I've heard tales of your exploits…but not enough to know where you're going, and where you hope to stop."
        
        *if tone < 3
          "Pray explain, milord?"
          
        *if tone = 3
          You give him a cold stare.  "I'd thought it was clear by now, kurios: I'll stop at nothing.  Perhaps I need to provide a more convincing demonstration?"
          
          His eyelids flutter and his tongue darts out to moisten his lips before he ventures,
        "Any rebellion is defined by one choice, ${kuria}: what to preserve, and what to tear down."  The ${delelle} leans
        *if horion > 3
          pleadingly
        *if horion < 4
          earnestly
        toward you.  "Linos and I are in our own way rebels too.  Ones who have been faced with that choice in a slightly different form—and perhaps answered it differently.  But we agree that the Hegemony cannot persist as it is."
        
        "Indeed?"
        
        *if tone = 3
          Your sarcastic tone has no apparent effect on Horion.
        "Absolutely.  And I'm intrigued by your
        *if aristo
          choice to lead a
        helot uprising.  If I may dare a question to you, ${kuria}…should your rebellion succeed, how much would the lot of the helotry be changed?"
        *choice
          *if (arrog > 0) #I lower my voice to a prudent level.  "Angels, I don't want to bloody change their lot."
            *set horch3 1
            "They're fit for service—in war, in peace.  The Thaumatarchy's injustice is against the free folk of 
            *if natl > 49
              Shayard,
            *if natl < 50
              the nations,
            not the chattel."
            
            "Hmmm."  Horion strokes his stubble, looking slightly disappointed.
            *goto aygul
          *if (aristo) #"We'll have a fairer system of Harrowing helots—that's all."
            *set horch3 2
            "First Harrow any condemned criminals; then institute a yearly bloodletting from all helots, after the harvest, when they've time to recover their strength."  Surely tapping every helot in every year of their life would yield more blood than the current annual slaughter of a few?  "Only if that somehow fails to bring in enough blood would we resort to Harrowing the innocent—and we'd choose them by lot, not by an Ecclesiast's whim."
            
            "Yes, I've also wondered whether a leech's tapping could be used to produce aetherial blood.  The Theurges claim that sacrifice of life is necessary, but they're suspiciously vague on the wherefores."  
            *label hstubble
            Horion strokes his stubble thoughtfully.
            *goto aygul
          *if (aristo) #"We'll end Harrowing."
            *goto nomoreharrow
          *if (aristo) #"They suffer many unjust abuses.  That must change."
            *set horch3 3
            "A noble may treat a helot worse than a horse or hound without consequence.  Save, perhaps, the disapprobation of their peers."  You shake your head firmly.  "That cannot continue.  An order which allows such cruelty to the servile classes is both unjust and fragile."
            
            The moon-faced ${delelle} gives a slow nod.  "And who'd hold the nobles to account on this, ${kuria}?  If an abuse took place, who'd complain to the court and see that consequences ensued?"
            *fake_choice
              #"The helots."
                "So you'd see helots able to take their own masters before the courts?  Unthinkable, most would say!  But look far back enough, and there's a hint of precedent."  
              #"Other nobles.  The aristarch."
                "That would require quite a sweeping change of heart, ${kuria}."
            *goto hstubble
          *if (aristo) #"They'll be free servants of the noble estates, as in the old days before the Conquest—not disposed of like chattel."
            *set horch3 4
            "But would they be content to serve as they do today, without their masters holding the power of life and death over them?  The change might be deeper than you expect."
            *goto hstubble
          *if (aristo) #"I'll make them yeoman smallholders—break up the great estates and give each helot family a few acres."
            *label andamule
            *set horch3 5
            "Aha!  Now there's a prospect to bring twenty million Shayardene helots behind your banner—and unite the nobility of every province behind the Thaumatarch."  Horion laughs, sounding remarkably unshaken.
            *goto aygul
          *if (helot) #"There'll be no more Harrowing."
            *label nomoreharrow
            *set horch3 20
            Horion regards you intently.  "And the Wards?  The Xaos on the other side?"
            *fake_choice
              #"We'll find another way to fend Xaos off."
                "That's quite the gamble, ${kuria}."
              #"I've never seen a Xaos-storm.  Are they truly great enough to warrant sacrificing thousands?"
                "Yes. Yes, they are."
              #"I don't know.  But I know that the Harrowing must stop."
                "Easily said, ${kuria}."
            Horion's customary joviality fades.  "You know, as a much younger and perhaps slightly dafter man, I accompanied the Phalangites into the Xaos-lands."
            
            "Truly?"  You've never met nor heard of anyone
            *if (bleysfam = 10) or (bleysfam = 11)
              —other than Huette Meriweather after your kidnapping—
            who's willingly crossed [i]that[/i] Ward.
            
            "Aye—when the border was pushed out to add a new stretch of pasture to the Southriding.  Most of the land was to go to a friend's House, and I was curious.  The Archimandrite assured us that a few days on the far side wouldn't taint us."  The noble's eyes are distant with memory.  "All of us had to lay down our weapons before we could pass through the Ward, of course. I saw a woman who'd forgot a paring knife in her boot, and until she took it out, she could no more bring her foot over that wall than she could have forced it through a sheer rock-face.  Meanwhile, a band of Theurges had come through the Abhuman Gate far to the South and flown up to meet us with fifty long steel chisel-bars.  That was what we were to use—both for breaking rock for the new wall, and for defense against reivers and creatures of Xaos."
            *label xaostale
            *hide_reuse
            *choice
              #"That's madness.  Barely armed, against Xaos-beasts?"
                Horion nods his wry agreement.  "I believe the idea was that the reivers wouldn't have weapons themselves, having fled across the Ward from whatever justice pursued them.  The Phalangite commander and a few others had swords; the Theurges had brought them, along with an ample blood supply.  And Phalangites are trained to believe they're invincible, you know.
                
                "At night we'd pile up a bonfire of desert gorse from the Shayard side, and see it glinting off huge eyes that shone like cats' a half-mile out in the dark.  That began to give the soldiers second thoughts."  The noble gives a mirthless chuckle.  "The one time we were attacked, it wasn't my camp.  The Phalangites who fought them off spoke of men who had grown shells like great beetles and hooks for hands, who could leap ten feet in the air.  We lost three soldiers and a dozen of our steel bars that night.  It didn't bode well—for our wall, or for the next time the abominations wanted to pay us a visit."
                *goto xaostale
              #"A new Ward-wall, you say?  How high?"
                "Three stones bloody high, ${kuria}.  That's all that holds back Xaos, and Halassur, and the Unquiet Dead.  Any less, and you couldn't even call it a wall.  Even as it is, you could almost step over it without noticing."  Horion shakes his head slowly.  "We brought sacks of mortar and waterskins across the existing Ward, and out there in the accursed desert we built miles of that tiny wall.  It was no help to us, of course—whatever the Theurges' Ward-change is, it doesn't take effect till after the new wall's been finished and joined up to the old one."
                *goto xaostale
              #"What were the Xaos-lands like?"
                "Well, my friend had left Grand Shayard smug at getting some more acres of pasture for his family demesne.  But after a day or two out there…"  Horion gives a humorless chuckle.  "There were trees and boulders that burst like bubbles when you touched them and filled the air with poison.  There were steel-shelled snails the size of dogs, chewing through the rock itself.  There was a mile-wide swathe where everything had turned to glass.  And half the plants had grown thorns or tendrils or spores where they didn't belong.  If a sheep survived a week on that pasture, I'd exorcise it before ever I'd eat it.  
                
                "The Theurges were very keen about one particular hillock where everything had transformed into something unpleasantly alchemical-smelling, and it wasn't hard to see that this was why they were going to all the trouble of moving the Ward.  They told us that once the new wall was ready, they would blast everything with fire to cleanse the Xaos-taint from the land."
                *goto xaostale
              #"And the Storms?"
                *set horch3 50
                Horion sucks a breath through his teeth and blows it tremorously out again.  "Well, on the fifth day, toward evening, in flies a Theurge—and I'd never seen one pissing scared before.  We were a good two miles out from the Ward, then.  [i]Run[/i], he said.  [i]Leave the bars.  Run, for your souls.[/i]  And you'd best believe we ran."
                
                "Did you see it?"
                
                "Heard it, first.  A scream down the wind, like the air was being ripped apart.  And then a rumble of things breaking, bursting, igniting in flame…almost like thunder, but from the earth, not the sky.  I wasn't looking back by then."  He wipes his brow.  "The only one who died was that Theurge—still flying high when he hit the Ward.  Maybe in his fear he'd forgot you can't get aetherial blood through, or that you can't go over it…or just hadn't realized he was that close.  But we saw him bounce off it like sling-shot off a shield.  We crossed the Ward-wall with the Storm on our bloody heels."
                
                "And the Ward held."
                
                "The Ward held."  The stout noble shakes his head.  "Angels, it held.  We lay there gasping like fish, and everything behind us was swallowed up in spinning clouds thick as pitch.  Lightning in every color you could imagine and some I didn't have a name for. When it flashed, or when a big flame-gout broke the edge of the Storm, you could see the desert tossing like the sea, boulders flying through the air and twisting into new shapes.  And all of it perfectly pent up behind an invisible wall in the sky, rising from that three-stone-high foundation."
                *goto xaostale
              *if (horch3 = 50) #"Did you go back in when the Storm passed?"
                Horion gives a guttural chuckle.  "I was never that daft, ${kuria}.  But some of the Theurges went back a day later to see what had survived.  They said the steel bars had grown into thorn-trees, and brought us back the little iron flowers that had sprouted on them.  I still have one on a necklace, back in Shayard."  He kneads his cheeks for a moment with trembling fingers.  "They also said that they found a few traces of our wall.  Melted into a line across the face of a new crag, or blown into a wave of mortared stone ten feet high and an inch thick.  One particular hundred-yard stretch had grown legs like a centipede and run a half-mile before collapsing.  They reckoned it had been chasing us.  That's the bit I still dream about."
                
                You can't help imagining what would become of Rim Square if it were in the path of such a Storm.
                *achieve xaosland
                *fake_choice
                  #"$!{oath}.  We can't risk those Wards coming down."
                    "I'd agree—much as I 
                    *if aristo
                      admire your compassion for the lesser orders."
                    *if helot
                      appreciate your desire to end the plight of the helotry."
                  #"And yet…there must be a way to protect ourselves without sacrificing helots."
                    *if aristo
                      "You're a kindly ${woman}, ${kuria}.  It's remarkable the lengths you'll go to to avoid harm to the lesser orders."
                    *if helot
                      "Well, I can certainly understand your desire for there to be one, Captain.  And for the helotry's sake, I hope you find it."
                  #"That's quite the fireside fright-tale, kurios.  How much of it is true?"
                    "Ha!"  Your rudeness seems to break his gloom and bring him back to himself.  "I dearly wish I could disown any of it, ${kuria} ${lname}.  I can certainly understand your desire for it not to be true.  But there's no need for me to convince you. 
                    *label hadwanted
                    I had wanted to hear your vision for the helotry, and this has become a bit of a distraction."
                Horion recovers some of his aplomb.
                *goto aygul
              #I change the subject.
                *if tone = 3
                  You cut off his reminiscences with a stony glare.
                "While I'm sure it's a fascinating tale, milord Horion…"
                
                "Indeed, ${kuria}!
                *goto hadwanted
          *if (helot) #"We'll be the ones deciding who goes to the Harrower—not the ones being sent."
            *set horch3 6
            "And on what basis do you expect to choose, Captain ${lname}?"
            *choice
              #"Everyone benefits: everyone sacrifices."
                You've reasoned it out in whispers with young helots any number of times, but despite yourself, your throat goes dry when you first begin laying it out to a noble, even the amiable and powerless ${delelle}.  "First we Harrow any condemned criminals, of any birth or station.  Then institute a yearly bloodletting for every person in the realm.  Surely that would yield enough blood to feed the Wards."

                "I've always wondered whether a leech's tapping could be used to produce aetherial blood," Horion muses agreeably.  "The Theurges claim that sacrifice of life is necessary…but they're suspiciously vague on the wherefores."  

                "If we did have to Harrow the innocent, we'd choose them by lot.  From everyone, not only the helotry."
                
                "So the cost is borne by all equally, not according to their natural deserts."
                *goto hstubble
              #"No Shayardenes if we can help it.  Karagonds first."
                "While there's a rough justice in that, Captain,"  Horion spreads his hands,  "I'm not sure there are enough Karagonds to feed the Wards for long.  It's a far smaller country than ours, you know."
                
                *if tone = 1
                  "An excellent point, kurios."
                You shrug.  "Then perhaps we'll outlaw mullow for Karagonds.  The free ones, anyway.  Bring up their numbers."
                
                "A most amusing inversion!"
                *goto hstubble
              #"We'll start with the Alastors, Ecclesiasts, and other lackeys of the Hegemony."
                "That may not suffice to feed the Wards for long, Captain."
                
                You shrug.  "It'll make a start."

                *goto hstubble
              #"We'll start with the nobles, Alastors, and Ecclesiasts."
                "Ah.  Well."  Horion swallows with some difficulty, but forces a smile and pleasant tone.
                *goto aygul
          *if (helot) #"We'll not be sold like chattel.  We'll be free as any yeoman and serve whom we will."
            *set horch3 4
            "Freedom for helots."
            *goto hstubble
          *if (helot) #"I'll break up the great noble estates and give every helot household six acres of land."
            *goto andamule
          #"I'm not yet sure."
            *set horch3 9
            "It bears some thinking, ${kuria}."
            *goto hstubble
          *if (tone > 1) #"I'm the one asking the questions, kurios."
            *set horch3 9
            "Fair enough, fair enough."  Horion raises his hands in surrender.
            *goto aygul
        *label aygul
        "You know, two centuries back, the Nyr philosopher Aygul objected to the rule of aristocrats over the helotry.  [i]The distinction between helot and free is one of law only, not nature,[/i] she wrote, [i]and being counter to nature is thus unjust.[/i] I'd been wondering if you were one of her followers."
        *if horch3 < 3
          
          "Xthonos, no."  
          *label firmshake
          You shake your head firmly.
          *label cantimagine
          "I can't imagine she came to any good end?"

          "Condemned a heretic, of course.  The Canon of Xthonos is law [i]and[/i] nature, the priests reminded her before popping her into a Harrower.  And the Canon's quite clear that from birth, some are marked for service, others for rule.  That said…"  
          *if hor_rel < 15
            Through his visible weariness,
          Horion's eyes flare with mischievous energy.
          *goto helothistory
        *choice
          *selectable_if (arrog < 1) #"Never heard of her.  But it sounds plainly true."
            *if helot
              As the words pass your lips, your ingrained childhood terror returns in a rush—but you
              *if hor_rel < 15
                furiously
              defy the urge to avert your eyes from the ${delelle}.  "There's nothing a noble can do, milord, that a helot with the same learning couldn't.  Perhaps
              *if skep <= 50
                the Angels give
              *if skep > 50
                fate gives
              some folk a nature better suited to lead—but if so,
              *if skep <= 50
                They give it to
              *if skep > 50
                it appears among
              noble and helot alike."
              
              "And in you, Captain, we have a chance to see that much-debated principle proven."  Horion beams with what seems genuine
              *if hor_rel < 14
                if slightly shaky
              enthusiasm.
              *goto helothistory
            "The gifts and strengths I saw in my kin, I've seen also in the helotry.  Some lie dormant, perhaps, in the absence of training…and some are crushed by the Hegemony.  But why should I believe that nature gave me anything that it might not have given to a helot?"
            
            *if democ > 0
              *goto nodagreeably
            Horion arches his eyebrows at you.  "And yet, ${kuria}, you appear to make all the choices for your band.  Your purported equals."
            *fake_choice
              #"Someone needs to be leader—and they've chosen me."
                "Because they recognized your native gifts?" Horion presses.
                
                *if tone = 3
                  Your glare warns him not to test you further.
                *if tone < 3
                  "Perhaps.  But not gifts they're lacking."  You shake your head.
                "I was simply in the right place, at the right time."
                
                "More than fair."
              #"Because of the skills I was born with.  Not my noble blood."
                "You believe the two to be unrelated?" Horion looks mildly dubious.
                
                "I've known helots who are as
                *if com = 2
                  good in battle
                *if int = 2
                  quick-minded
                *if cha = 2
                  persuasive
                as I."  You think of
                *if com = 2
                  Radmar,
                *if int = 2
                  Elery,
                *if cha = 2
                  Breden,
                and there's no question in your mind that if 
                *if com = 2
                  he'd
                *if int = 2
                  she'd
                *if cha = 2
                  ${xhe}'d
                benefited from your education and training, 
                *if com = 2
                  he'd
                *if int = 2
                  she'd
                *if cha = 2
                  ${xhe}'d
                equal if not surpass you.
                
                "Well, you must introduce us at some point."
              #"For now.  They take part in the decisions—and one day soon, they'll be ready to take over."
                "Well, you must introduce me to these prodigies who will succeed you at some point."                
              #I cough uncomfortably.  Now that he points it out…
                "It's…well, it's easy to stay in old habits.  For all of us.  But likely for me most of all."  You rub your forehead, feeling weary and adrift.  "I tell myself that when there's more time, I'll step back—make fewer of the choices, hand more things over to them.  But that time never quite seems to come."
                
                "Well, let me say, ${kuria} ${lname}: I admire your candor with all my heart."
            *label nodagreeably
            The stout ${delelle} nods agreeably.
            *label helothistory
            "Did you know that in some of the free cities of old Karagon, helots could become citizens if they committed feats of sufficient bravery?"
            
            "What?" You
            *if horch3 < 3
              recoil, trying to
            *if horch3 > 2
              struggle to
            imagine the Karagonds, of all people, allowing any blurring of the line between helot and free.
            
            "Unthinkable, unnatural, yes, yes.  But read between the lines of the old histories, and it's clear enough."  Horion is clearly enjoying your astonishment.  "While in other cities, they declared war on the helotry once a year and encouraged young nobles to kill them by stealth.  The Krypteia, they called it.  Some of the less kindly bits of the Codex were written in those cities; and it's their vision of what's natural that's been passed down to us."  He shakes his head.
            *goto empsize
          *if (arrog > 0) #"What—aristos and helots, equal by nature?  Arrant nonsense."
            *goto firmshake
          #"I don't follow some dead Nere's thinking, no."
            *set natlreal %+10
            Horion leans in as if to argue…then plainly thinks better of it, and settles back with a shrug.  "Wisdom has many voices, ${kuria}.  Including dead Neres, and those who argued with them.  Shut your ears to them, and you'll miss quite a bit."
            
            You ignore the mild rebuke.
            *goto cantimagine
          #"I don't know what's nature and what's law—and I'm not sure it matters."
            "You don't think it's important?"  Horion blinks at you.              
            *if int < 2
              
              "I just don't care."
              
              *label clearthroat
              "Ah."  The ${delelle} clears his throat.
              *goto empsize
            "Forgive me, ${kuria}…but then I'm not sure we're using the words 'nature' and 'law' to mean the same thing."
            *choice
              #"I just don't care."
                *goto clearthroat
              #"Any law that runs counter to nature will fail eventually.  That's what 'nature' means."
                *gosub philosopher
                "Sustaining a state of affairs counter to nature requires great effort—ask any Theurge.  But when an unnatural polity is subject to a shock, the natural order has a chance to reassert itself.  Like a mighty river breaking free of a dam.  As long as the dam is in place, who can say what the natural course of the river is?"  You pause, but Horion avidly gestures at you to complete your thought. 
                
                "Our rebellion is the shock which will break the unjust, unnatural polity of the Thaumatarch and allow things to flow according to their natural purpose for the first time in nigh onto four centuries.  Watch as the false laws crumble…and only then will it be possible to see whether helots, free folk, and nobles are truly equal by nature."
                
                "Or perhaps we'll see only Xaos?" Horion counters.
                
                "Which is the stronger?
                *if skep > 50
                  If 'Xthonos' means anything, it means the Natural Law which
                *if skep <= 50
                  Surely we know that Xthonos
                turns every stratagem of Xaos against itself, bringing Order out of seeming disorder."
                
                *if helot
                  "Hmmph.  Whether I agree or not, Captain…hearing so well-spoken a helot does call the traditional view into question."
                The ${delelle} steeples his fingers contemplatively.
                *goto empsize
                *label philosopher
                Horion's eyes widen.  "Now, this is an unexpected pleasure—a
                *if helot
                  helot
                philosopher in the Whendward!"
                
                You 
                *if tone > 1
                  shrug off his praise.
                *if tone = 1
                  give a modest bow before continuing.
                *set hor_rel +1
                *achieve philosopher
                *return
              #"Your philosopher meant that law can change, nature can't.  But everything changes.  Even what we call nature."
                *gosub philosopher
                "All things are in flux, and flux is the deepest nature of things.  The more something resists change, the more likely people will give it the name of Nature…but nothing resists change forever.  Ask any Theurge, or anyone who has faced the Plektoi."
                *if introhlt
                  The musky, metallic smell of the hounds comes back to you with a shudder.
                *if not(introhlt)
                  Everyone's heard tales of the Twisted Ones: hounds, horses, or humans transformed by Theurgy into lethal armored giants.
                "A dram of blood makes only a brief change in nature, but a Harrower-full can change a Plektos's bones to iron.  Bleed a province, and you can turn air into an impenetrable Ward or make a mountain float in Aekos.  Spend enough blood, milord ${delelle}, and you can change anything."
                
                "'All things are flux'?  Sounds like the anti-Xthonic philosophers of Old Erezza."  Horion sounds
                *if helot
                  flabbergasted at hearing the line from a helot—and
                uneasy. "They've been condemned even longer than Aygul of Nyr."
                
                *if skep > 50
                  "And they're all the more likely to be true for it."
                *if skep <= 50
                  "The essence of Xthonos is [i]That Which Is[/i]—which surely includes Change.  To see sacrilege in that is a fallacy."
                Despite his obvious enthusiasm, you decide not to sidetrack the conversation into theology.  "Returning to the point: even should there be some difference in nature between helots and nobles, who's to say that makes it immutable?  The Order we call Nature is harder to change than the Order we call Law.  But if there were need to change it, we would make a way."
                
                The ${delelle} looks slightly queasy but impressed.
                *goto empsize
        *label empsize
        "Well, that helps me envision the shape of your future realm, ${kuria} ${lname}.  Many thanks.  One more question, if you'll humor me: how big is it?"
        
        "What—my future realm?"
        
        Horion nods, eyes alight and curious.  "How much of the world do you foresee coming under your new Order?"
        *choice
          #"However much we can carve out.  Small or great…the important thing is that we end with a space where the Thaumatarch's tyranny doesn't hold."
            *if tone = 3
              "$!{kuria}…you'll punish me for my boldness, but do
            *if tone != 3
              "$!{kuria}…do
            you truly think that you'd be able to 'carve out' anything smaller than the Hegemony itself?"  Horion's tone is incredulous.  "As long as the Thaumatarch and his Theurges retain power anywhere, they'll fight to claw back or destroy whatever you take from them.  They'll stop at nothing.  They've been warring with Halassur for three centuries.  How much more fiercely would they seek the ruin of a rebel district, region, or province?"
            *choice
              #"Obviously, we'll kill the Thaumatarch."
                "The first Thaumatarch was assassinated.  The second died of old age, or so they say. For all we know, an assassin found her as well.  Now we're on to the third."  You give a bleak grin.  "As I see it, that gives me at least one chance in two of killing him."
                
                Horion throws back his head and laughs.  "Pissing Angels, ${girl}. If you could fuel a rebellion on audacity alone…you don't think they'll just elevate another to his place?  The assassination of Hera the Great didn't end the Hegemony, after all."
                
                "Then we'll just keep killing them until they let us alone."
                
                The aristocrat shakes his head.  "You could be more ambitious, ${kuria}."
                
                "How do you mean?"
                *page_break
                *goto shayking
              #"I'll ensure there's enough Xaos elsewhere that they won't be able to attend to us."
                "We'll spread the rebellion beyond Shayard."  It's a heady thought, on which you've whiled away many a long day's climb through the wilderness.  "When they face helot revolts in all their 
                *if natl > 49
                  so-called
                provinces and Karagon itself, they might find they've more pressing matters than avenging themselves on me."
                
                "I think you underestimate their vengeful nature."  Horion shakes his head.  "More importantly, ${kuria}…you don't think you could draw those revolts together into something more ambitious?"
                
                "What would you suggest, kurios?"
                
                *goto shayking
              #"What would you suggest, then, kurios?"
                *goto shayking
          #"I won't stop until Shayard is free from Rim to Coast."
            *set natl %+10
            "Our rebellion will last as long as the Thaumatarch holds an inch of Shayardene soil."
            
            "And where does Shayardene soil stop?"
            
            You cock your head, intrigued at the intensity of his questions.  "You've clearly an idea, milord. I'm guessing it extends beyond the archonty's borders?"
            
            *goto shayking
          #"I'll free all the lands currently in Karagon's thrall, and lead as many as will follow me."
            You expect the nobleman to chuckle at your hubris—but his spreading smile has no discernable trace of mockery. "Now there's a vision worth rebelling for, ${kuria} ${fname}.  Reclaiming the lead that was stolen from us."
            *goto shayking
          #"I'll not stop until we've built a new Hegemony over all the lands in Karagon's thrall."
            You expect the nobleman to chuckle at your outsize ambition, but he just strokes his chin pensively.  "Linos would warn you not to repeat the Karagonds' error—that their empire's too big to be held together indefinitely.  Me, I'm just glad you're looking beyond the borders of what is today called Shayard."
            
            "How so?"
            
            *goto shayking
          #He's supposed to be answering my questions, not the other way round.
            *if tone < 3
              "Why are you so interested, milord?"
              
            *if tone = 3
              "Keep plaguing me with questions, kurios, and you'll be the next casualty of this rebellion."
              
              His throat works convulsively, but—surprisingly—he persists.  "Of course, of course.  But…"
            *goto shayking
        *label shayking
        The ${delelle} raises his hands as if to frame an imagined painting or map. "Consider a history different from the one we know, ${kuria}.  Imagine that Theurgy remained undiscovered.  Which nation would today be strongest—the obvious premier among its neighbors?"
        
        *if natl < 60
          *if tone = 3
            You scowl but say,
          "Shayard?"
          
        *if natl > 59
          "Shayard."
          
          Your unhesitating, fervent response sparks a smile.
        "Had you lived sixteen-score years ago, ${kuria}, 
        *if natl < 60
          there'd be no question.  
        *if natl > 59
          the world would perforce agree with you.
        Our conqueror kings and queens had brought all the continent's richest farmland and half the great trade-ports under one crown.  The revelations of the Angels to the prophets of the Shayard Reach had already won over the Karagonds and Erezziano, and the Codex was being written mostly in Shayarin.  Until Thaumatarch Hera succeeded in brewing other people's blood into Theurgy-fuel, history's great theme was the ascent of Shayard."
        
        *if tone = 1
          "Forgive me if I've misunderstood you, kurios, but…" You blink.
        "You're saying we would have been the Hegemons?"
        
        "At the very least, we'd still have Aveche, and the Veldrine Hills, and Steswick…all the lands the Karagonds severed from Shayard in the conquest."  Horion inclines his head, eyes gleaming.  "Would we have conquered Nyryal and Wiendrj?  I don't know.  But the rest of the continent was certainly on its way to being united in a Shayard-led Commonwealth—not a damned Karagond Hegemony."
        
        *if hor_rel < 10
          You narrow your eyes, wondering what in this history lesson is important enough for the ${delelle} to risk your wrath.
        "And you dream of the same?  Today?"
        *page_break
        Horion shakes his head and sighs.  "Well,
        *if rescuer > 1
          whatever some of the de Tomans might mutter in their wilder moments,
        we can't recover the power that might have been.  As much as I'd love to see bits of it under our rightful rule, the time's past when Shayard might have conquered Erezza.  They've got used to being unified, and they've been honed by three centuries on the frontline with Halassur.
        
        "But a [i]koinon[/i], or Great League, led by a free and strengthened Shayard rather than a Karagond tyrant?  All that would take is victory over the Thaumatarch—not over all the other nations.  That, I can dream."

        "Because you know how to 
        *if aristo
          accomplish a victory over
        *if helot
          beat
        the Thaumatarch?"
        
        The stout ${delelle} shrugs. "I know that the Hegemony only works because the provincial nobility collaborate with it, from the aristarchs in the districts to the Archon in the capital.  What if they start demanding a higher price for their collaboration?"  
        
        "They'll be Harrowed."
        
        "I think not. The
        *if aristo
          Thaumatarchy could Harrow half its helots and survive—but if it Harrowed a tenth of the nobles, it would lose the rest for good."
        *if helot
          Thaumatarchy…well, they can only murder so many before they turn an entire province against them from top to bottom.  They prefer to reserve their severity for the bottom, as I'm sure you know all too well.  And to keep the top playing the Hegemonic game."
        A trace of pride becomes visible in his
        *if horion > 3
          shaky
        smile.  "That's why I put so much of myself into philosophy, ${kuria}.  In particular, the politics of the pre-Hegemonic era.  Get enough people to realize there's an alternative to the way of things…and it will change."  He stares at you almost expectantly.
        *goto horionchat
      *hide_reuse #"$!{tell} me more about where you're going, and why."
        "The Pan of Szeric is an intelligent man—and profoundly, desperately mistaken in matters philosophical, in ways to which a lesser mind could never aspire."  Horion gives a reproachful sniff. "Now this cocky Wiend has declared that if I'm to truly understand his stance, I should present myself in his district, where he shall give me an incontestable 'proof' in support of his 
        *if knowwhy > 0
          errors."
          
          *comment endif
        *if knowwhy < 1
          errors.  And your pass is not only the most direct route there—it's also one where my enemies are most unlikely to find me."
          *set knowwhy 1
          
          He clearly expects you to ask about these enemies rather than persisting with your question.
        "Matters philosophical."  You
        *if helot and (int < 2)
          refuse to be intimidated by Horion's long words and learning.
          *goto matphil
        *else
          raise an eyebrow.
          *goto matphil
        *label matphil
        "Justice?  Theurgy?  Monarchy? Some other idea 
        *if aristo
          too dangerous to argue save 
        *if helot
          so dangerous you can only argue it
        in person?"
        
        "Not exactly."  Your aristocratic ${guest} clears his throat uncomfortably.  "Pan Szeric holds that beauty is perceived by its own distinctive faculty, not by the same faculty of reason that we use to judge matters of truth and morality."  There's a long pause, after which he offers an apologetic shrug. "It's preposterous thus to divide the mind.  Shatters the unity of human experience."
        
        *if linch = 0
          You stare at him incredulously.  "You expect me to believe you'd cross a rebel-infested wilderness to 
          *if int = 2
            argue aesthetics with a ${whend}ish lord?"
          *if int < 2
            argue…that?"
        *if linch > 0
          You study him, shaking your head.  
          *if tone < 3
            "Ecclesiast Linos 
          *if tone = 3
            "Your priest
          told me.  And I couldn't believe it."

        "I'm afraid it's true."
        *if hor_rel > 20
          *set szth 1
          Horion holds your skeptical gaze for a long moment; then his lip curves up in one corner, and his eyes take on a mischievous light.  "But…I'll grant you, my dear ${kuria} ${fname}, it's not the most interesting aspect of the truth."
          *page_break
          *achieve whyszeric1
          You lean forward, feeling your pulse speed up.  "Pray explain, kurios?"
          
          "In our long disputation, Pan Szeric and I have discovered a few minor points of agreement between us.  The contemptibility of the Thaumatarch, for example, or the desirability of a new Order between nations.  We have both lamented the Karagonds' insuperable advantage in Theurgy, and speculated on ways we might counter it."  The ${delelle} glances around, then speaks in a near-whisper.  "And now he has hinted…in the least penetrable bits of our correspondence…that he has been joined in his demesne by a Theurge of the third rank.  An Erezziano who has forsaken the Thaumatarchy."
          
          "A rebel Theurge?"  Your mind races to the implications and finds too many to grasp.
          
          "Perhaps—or perhaps merely disgraced and on the run.  The hints aren't entirely clear.  But the hint is enough to bring me across your pass, ${kuria}."  Horion's round face is split by a boyish, blazing grin.  "For the chance of learning a seasoned Theurge's secrets, I'd risk quite a lot.  And I suspect what I learn there will be valuable to you as well."
          *if (theuknown >= 10)
            
            "You don't need to go as far as ${whendery} to meet a ${wisard}, kurios," you point out.

            "And I'd be fascinated to learn as much of your powers as you'll share with me, ${kuria}.  But others have got as far as you, I'm afraid…the Hegemony's quelled many a self-taught mage down the years. The real Karagond advantage is the ability to refine aetherial blood—a secret only the Halassurq magi share."  The ${delelle} looks apologetic.  "Unless I'm much mistaken, you don't have that knowledge.  And no number of ${wisard}s using only their own blood is going to threaten the Hegemony."
          *if linch > 0
          
            "Does 
            *if tone = 3
              your priest
            *if tone < 3
              Linos 
            know?"
            
            "Angels, no.  I get my dear confessor in enough trouble for tolerating my seditions. The least I can do is spare him knowledge of my actual attempts at treason."  Horion's eyes twinkle affectionately. "Depending on what I find in Szeric, however, I'll bring him in on the secret.  If there's a true chance here to undermine the Thaumatarchy, he'll perceive it and how we can best put it to use."
          *goto horionchat
        He looks only slightly embarrassed.  "Life is philosophy, ${kuria} ${lname}.  To better understand how a man as clever as the Pan of Szeric becomes fixed on such a fundamental folly…well, that's worth risking quite a lot.  And with the enemies I've made in Shayard, there are other risks that are even more on my mind."
        *goto horionchat
      *if knowwhy > 1
        *hide_reuse #"You actually believe Strategos Nomiki would pursue you into ${whendery}?"
          *if knowwhy > 3
            "Ah, so Linos told you of the mortal enmity between the Strategos and myself."  Horion's smile falters and his voice becomes flatly serious.
          "Yes, ${kuria}—she'd be delighted to see me dead.  Not only does she know me for an enemy of the Hegemony, but I've made her look a fool in a public trial, and there's nothing a ruler can abide 
          *if knowwhy > 3
            less.  Moreover…as Linos may also have mentioned, there are families who'd happily betray my whereabouts to her once I step out of Cousin Phrygia's immediate protection."

            "This Luse de Toman?"
              
            "She and her fellow 'traditionalists,' yes."  Horion looks sour.  "They say they want to see the Hegemony fall, but all of their ridiculous child-games about so-called Old Shayardene ways undermine the Karagonds not at all.  The de Tomans are friendly with the aristarchs of your district—the what's-their-names."
            
            "Keriatou."
            
            "Yes, your
            *if aristo
              cousin,
            *if helot
              master,
            Lord Keriatou, has done a decent job balancing his traditionalist sympathies with loyalty to the Thaumatarch.  Come to think of it, I heard milady Luse's hothead grandson, young Abelard de Toman, was recently sent out here for your cousins to try keeping him out of trouble."  Horion manages a tremorous laugh.  "He arrived just as your little uprising was starting—and was sent back sharpish!"

            *if (rescuer > 0) and (int > 0)
              *set rescuer 2
              *achieve abelard
              You try to conceal the shock that runs through you.  A young, male noble whose voice you'd never heard before, who was visiting the Keriatou just as your uprising began?
              
              Your voluble hostage continues, "I reckon your Keriatou will find it harder to keep the balance now that a rebellion has blazed up in their–"

              "Who's this hothead Abelard?" you cut in.
              
              Horion blinks.  "Just another young man with more choler than sense. But thanks to his grandmother, it all flows into defense of supposed Shayardene traditions.  Wearing that confected garb, insisting on speaking in Shayarin…getting into fights with youths whose Houses recently swapped their 'de' for an 'atou.' That sort of thing."
              *page_break
            You stare grimly at him.  "So the enmity of the Strategos and these traditionalists…it truly left you thinking your safest option was to dare the Whendward?"
            
            "No option was safe, ${kuria}.  To stay in Shayard, and await the inevitable arrival of a Kryptast in my retinue?  Or to take the main road, patrolled by the servants of my worst enemies?"  The Leilatou looks beseechingly at you, then wilts at your merciless expression.  "I…I had hoped that if we did encounter each other, ${kuria}, you'd see…ah, that we were seeking a similar goal.  By different means."
            
            It's the same story you'd heard from Linos.  With audible impatience, you say:
            *goto horionchat
          less."
          
          *if (linosqq > 9) and (linch < 1)
            "So, this 'indiscretion' in your cups last Angelday?"
            
            "How
          *if (linosqq < 10) or (linch > 0)
            "How did she discover your treasonous views?"
            
            "I was deliberately indiscreet, of course.  How 
          better to spread one's seditions than to provoke a sedition trial in the Archon's court?"  Horion grins 
          *if hor_rel > 18
            with sudden, effervescent delight. 
          *if hor_rel < 19
            despite himself.
          "Of course, I did my best to ensure that none of the evidence against me was robust—all hearsay at third or fourth hand.  And fortunately, the Strategos is unaccustomed to making a case according to the strictures of the Canon.  To convict a cousin of the Archon, her usual tactics were quite inadequate.  She came off looking like a lawless bully…and much worse, an incompetent one."
          
          You shake your head, trying to imagine the level of privilege that could allow any Shayardene—even a Leilatou—to deliberately bait an Alastor general and survive.  "You can't use their rules against them.  Everyone knows that if you try, they'll just kill you anyway."
          
          "Oh, I expect they'll do their best.  And if I stayed in one place, I'd expect them to succeed, despite Cousin Phrygia's half-hearted protections."  Horion scratches his lank hair.  "To avoid having the inevitable Kryptast placed in my retinue, I thought it best to shed the retinue entirely and play the itinerant philosopher for a few years.  Just me and my long-suffering Linos, visiting far-flung friends, using unexpected routes and means of travel."  He extends his hands palm upward in your direction. "Someone who's humiliated the Strategos of Shayard will face risks on any road.  And
          *if hor_rel < 15
            even after the last two days,
          I'd rather my life were in your hands than Nomiki's, ${kuria}."
          *goto horionchat
      *if knowwhy = 1
        *hide_reuse #"Who are these enemies, and why are they so determined to destroy you?"
          *label toocharming
          Horion's lips quirk upward in the corners. "My fundamental problem is, ${kuria}, I'm just too charming."
          
          "I'd thought that was supposed to make friends, not enemies."
          
          "Plenty of both.
          *if cha = 2
            As you'll know soon enough."  He offers you a look of wry sympathy.  "You're plainly an inspiring, eloquent ${woman}, and it's served you in good stead thus far—but don't expect it to win over
            *if arrog < 1
              the nobility.
            *if arrog > 0
              anyone who truly benefits from the Hegemony.
          There's nothing more terrifying than a charismatic person on the wrong side."
          
          "So whose wrong side are you on, kurios?"
          
          *if id > 1
            *set knowwhy 2
            "Strategos Nomiki." At your blank stare, he hastens to explain, "Nomiki…the top Alastor in Shayard, their general.  She knows I aspire to see Shayard ruled by Shayardenes, and to see the Hegemony fall."
            *goto horionchat
          *if id <= 1
            "The 'traditionalist' Houses, so-called.  Those who pride themselves on being true Shayardenes, with old names and bloodlines going back before the Conquest."  Horion snorts. "In truth, they've confected a mess of rituals and bywords and costumes that have no roots in the histories.  Despite claiming to purge Shayard of foreign influence, they've borrowed half their farrago from the Wiends or Erezziano—loyalty oaths, hooded capes, elaborate greetings."
            
            "And they'd kill you?"
            
            "After the amount I've mocked them, ${kuria}…yes, I'm told they're actively seeking my death.  That, too, they have from the Erezziano—a penchant for disposing of their enemies in secret.  I'm hoping that a year or two of playing the itinerant philosopher will throw them off my scent."
          *goto horionchat
      *if (horion > 3) and helot
        *hide_reuse #"How much are you worth to your family?"
          Horion's face 
          *if hor_rel > 15
            takes on an expression of distaste.  "Oh, don't let's haggle, ${kuria}. 
          *if hor_rel < 16
            goes tense. "I'm afraid
          I've no idea what my family will pay for me—and believe me, I'll be as interested as you are to find out."
          *goto horionchat
      *if (horch = 0) and (horion > 3)
        *hide_reuse #"Tell me, kurios, why I should take the risk of ransoming you—rather than leaving your body in Rim Square."
          *set horch 1
          *if hor_rel < 18
            His attempted bonhomie dissolves in the face of so overt a threat.
          *if hor_rel > 17
            *set hor_rel -4
            His mouth hangs open for a moment before he splutters out an answer to your threat.
          "To kill me gains you nothing, ${kuria}.  Save perhaps some fleeting satisfaction.  What lesson do you think will be taken by the undecided nobles in Shayard City who have been awaiting the consequences of my sedition?  They will see me fleeing the Alastors and dying, and they will see you as a mere servant of Xaos."
          
          *if hor_rel < 8  
            "Which is just how I want them to see me."  Visibly unmoved, you call for a guard.
            
            Horion falls to his knees and clutches at yours, his voice low and frantic.  "My journey to Szeric, ${kuria}…it's not just a philosopher's whim, nor flight from my enemies.  Not even Linos knows.  But there's something there that might doom the Thaumatarchy."
            
            "Lies," you growl contemptuously.
            
            "Theurgy," he blurts.  "An Erreziano Theurge, of third rank, turned against Karagon.  Pan Szeric has written hints to me…hints that would be opaque to anyone else but are clear as day to me.  He's been looking for years, and he's found a Theurge at last."
            
            A bandit appears in the tent doorway; you pause a moment, then wave him away.

            *set szth 1
            *achieve whyszeric2
            *if (theuknown >= 10)
              "Surely you know that I already practice ${wisardry}.  Somehow this Theurge in your ${whend}ish friend's demesne is more of a threat to the Thaumatarchy that I am?"
              
              "Tell me that you've discovered how to refine blood, ${kuria} ${lname}, and I'll gladly name you the Thaumatarch's bane.  But I don't believe you have."  Horion's wide eyes are blinking rapidly, as if to fend off tears.  "That's the secret that keeps the Hegemony strong.  Forgive me, but they'll never be fundamentally threatened by a self-taught mage using ${his} own living blood.  You need to store much more up—your own, and others'—if you're to beat them.  And a Third Kyklos Theurge will know how to refine blood." 
              *page_break
              [i]The secret of aetherial blood.[/i]  You try to get your head around the implications. [i]Who would willingly give that up?[/i]
            "A rebel Theurge?"
            
            "I don't know," Horion admits, hurriedly adding, "A lover of her homeland; of that I'm sure.  Dissatisfied with the Thaumatarchy.  Fleeing the authorities.  That much is clear from Pan Szeric's little hints.  But whether this Theurge would take the name of rebel or just wishes to hide away…that I won't know until I arrive."
            
            "Until you arrive?"  You scowl at the presumption.
            
            The ${delelle} doesn't shift from his imploring posture. "Either you'll kill us, ${kuria}…or you'll decide that the chance of making contact with a like-minded Theurge in Szeric is worth sparing our lives.  There's no one else who could make that link—no one else Pan Szeric will trust."  He can't manage a smile.  "I am ever the optimist."
            
          *goto horionchat
      *if (horion < 4) and (horch = 0)
        *hide_reuse #"What next, then, kurios?"
          *set horch 1
          *if (theuknown >= 10)
            "Well, ${kuria},
            *if szth > 0
              as I mentioned earlier,
            I'd certainly be intrigued to hear more of your experience with ${wisardry}."  The noble's eyes sparkle with
            *if hor_rel < 18
              cautious
            interest.
            *choice
              #I give him an outline of what I've discovered and done.
                *set horthe 1
                You briefly describe your first experiment with Theurgy, and the times you've used it since—but you're careful to leave out anything you think would actually enable this clever aristocrat to try it for himself.
                
                *gosub horiontelos
                *goto connect
                *label horiontelos
                "Hmmm."  Horion's cheeks invert as he gnaws at them.  "So when you use this philosophers' litany and spill blood,
                *if blood > 0
                  either aetherial or your own,
                it briefly alters your senses.  You see differently, and can change what you see.  For example, you directly perceive the striving of elements to rise or fall…and you can tamper with them?"
                
                "Yes, but that's only part of it.  One of the parts that's easier to focus on."  You shake your head, thinking of your
                *if aristo
                  sword.
                *if helot
                  knife.
                "When I look at a blade, I'm not just seeing what it's made of.  It's like I'm directly seeing what it was made for—cutting, severing, injury.  All together, in a sort of blur.  And most of what's in the blur, I don't recognize."
                
                *if horthe > 1
                  He skims over the scroll again, then looks up with a new gleam in his eyes.  "So,
                *if horthe < 2
                  "Fascinating.  So 
                when you look at clothes, besides their constituent elements, you see…" 
                
                You try to put words to the fleeting, barely describable experience.  "Warmth…modesty…"
                
                "Protection?"  When you nod, Horion gives a triumphant laugh.  "And thus the Theurges turn their coats and cowls as hard as armor.  Screw me with an Angel!  I'd wondered.
                *if aristo
                  I assume you're thoroughly 
                *if helot
                  Are you 
                familiar with the concept of [i]telos[/i], ${kuria}?"
                
                *if helot
                  You raise your eyebrows.  "I may not have your grasp of the subject, milord ${delelle}, but I have read more than enough philosophy to know what telos means."
                  *fake_choice
                    #I'm sure he can hear my anger at his condescension.  Yes, I'm a helot…but he's had more than enough evidence to assume that I'm acquainted with the basics.
                      When you see him looking abashed, you continue sternly:
                    #I keep my tone neutral.
                      "Of course, of course, Captain," Horion says placatingly.
                      
                      In case he's still in any doubt, you say,
                    #My amusement is plain in my voice.  I relish people's surprise when I know more than a helot should.
                      Feeling slightly smug, you continue,
                  "Telos means purpose.
                *if aristo
                  Of course you are—it's a fundamental concept in Karagond philosophy. "Purpose.  
                The heart of a thing's nature.  The goal towards which it moves…that which fulfills its reason for being."
                
                "The Xthonos-given objective of every last bit of creation.  And when each thing pursues its natural telos, the consequence is Order, harmony, and so on and so forth."  Horion's words start to stumble and blur into each other, unable to keep pace with his thoughts. "Yet Theurges never talk of teloi. They speak of the power of the Angels, of blood hallowed by sacrifice and preserved with alchemy.  Allowing them to move you, curse you, set you on fire.  Sometimes, they hint at a deeper 'nature beyond nature' that the Angels have shown them.
                
                "But perhaps all that they've truly figured out is how to perceive directly a thing's telos—the intent woven into a thing by its maker, be it human, Angel, or Xthonos—and change it."

                *if aristo
                  *page_break
                "Changing teloi?"  Hearing it aloud, it sounds both obvious and preposterous. Every philosophy text you've read has used the word "unchanging" to describe teloi.  To alter a thing's "final cause" would be to destroy or unmake it.  And yet, reflecting on the changes you've made and the language of that cryptic scroll…it feels like an insight you've nearly arrived at yourself several times.  "It's been easiest when I've tried to make a Change that goes with the grain of a thing's nature."
                
                "In keeping with its telos.  So encouraging the elements of air and fire to rise would be easier than levitating an object made almost entirely earth or water.  And ripening crops would be easier than withering them."  Horion clicks his tongue thoughtfully.  "I've often heard of war-Theurges sharpening Phalangite blades for war against Halassur.  I've yet to hear of them dulling the enemy's blades.  Perhaps outright reversing a telos demands too much blood to be effective.  You should experiment, ${kuria}—see what you find."
                *achieve telos
                *return
              #I explain all my experiences in depth and show him the scroll.
                *set horthe 2
                After you've finished describing your works of ${wisardry} to date, he takes a few moments to peruse the scroll.
                *gosub horiontelos
                *goto connect
              #I lie to him.
                *set horthe -1
                You tell Horion that your Theurgic powers come from mentally reflecting on:
                *fake_choice
                  #The sacred text of the Canon.
                  #The tension between Order and Xaos.
                  #A nonsense-language you found recorded in an old codex.
                Horion listens intently to your fabrications, posing the occasional question.  When you're done, he shakes his head with a look of awe.  "Truly fascinating, ${kuria}.  I'd never have expected that."
                
                "The Theurges are very effective at hiding their secrets." You nod solemnly.
                *goto connect
              #I refuse to tell him anything.
                He seems neither surprised nor particularly dismayed by your refusal.
                *goto hospitalwel
            *label connect
            *if horthe > 0
              *page_break
              You'll need more time to think through the implications of the nobleman's insight.
            "We really must speak more on this."
            
            *goto hospitalwel
          *label hospitalwel
          "Well, while your hospitality is most welcome, ${kuria} ${lname}…the road to Szeric beckons."  Horion clears his throat and smiles apologetically.
          *if szth > 0
            "You'll understand that I'm eager to meet with this renegade Theurge as soon as possible."

          *if knowwhy > 1
            "And after Szeric?"

            "Angels willing, I'll stay a step ahead of the Strategos and her thugs, in places where my name will not be known save to friends.  I'm keen to see how many in the other provinces are receptive to my vision of a Great League rather than a Hegemony…and to start talking of specific paths that could bring us there."

          "Do you see your path bringing you back to the Whendward?"
          *if hor_rel > 20

            "My dear ${kuria}, having met you, I can't imagine not returning to you," Horion says with seemingly genuine warmth. 
            *if szth > 0
              "In particular, if this Theurge is willing to 
              *if (theuknown >= 10)
                share the secret of refining blood. 
              *if (theuknown < 10)
                join an outright rising against the Thaumatarch. 
              You can expect to come across us again this time next year—as
            *if szth = 0
              "As 
            long as you survive the Hegemony's inevitable attempt to destroy you."  He leans toward you with avuncular concern. "Were I you, I'd pull back as soon as possible to the deepest wilderness, where the Phalangites will struggle to reach you. The Theurges will inevitably come after you with flame from the air…but you should be able to survive that."
            *page_break
            *goto horionchat
          *else

            "My dear ${kuria} ${lname}, you couldn't keep me away," Horion beams.  "I'm keen to see how your revolt develops, and to share with you what I learn on my own travels."
            *page_break
            *goto horionchat
      #I've nothing more to ask Horion.
        *set horch 1
        You've heard all you need to from your noble ${guest}.
        *label hordone
        *if linch = 0
          Dismissing him, you send for Ecclesiast Linos.
          
          *goto linoshi
        *else
          Dismissing him, you contemplate your ${guest}s' future.
          *if religion > 0
            *page_break
            Before anything else, you 
            *if religion < 10
              *if linbless
                need Linos to declare you 
              *if not(linbless)
                intend to declare yourself
              Eclect of the Angels.
            *if religion > 10
              want them to be present for your experiment in religion.
            *goto foundreligion
          *goto whattodowt
  #Neither—it doesn't really matter to me what they know or where they're going.
    *set nointerro true
    *if horion < 4
      They're your guests,
    *if horion > 3
      They're only valuable for the ransom you can get from them,
    and you don't need to know more.
    
    Having decided to ignore them, you're surprised to find Ecclesiast Linos awaiting you in the Leaders' Tent the next morning.  ${hor_guard} offers an embarrassed shrug.  "Said he had one simple question to ask you, ${kuria}…that it wouldn't take but a moment of your time."

    You shake your head with mingled ire and understanding; even as rebels, it's not easy to deny a priest of Xthonos.  "Give us the tent, then."  When you're alone, you turn to the gray-bearded Linos.  
    *if tone > 1
      "Well?"
    *if tone = 1
      "My ear is yours, Ecclesiast."

    "Forgive my boldness, ${kuria} ${lname}.  I wished only to understand the extent of your ambition.  Do you intend to remain a bandit in the woods…or actually aspire to overturn the Karagond Hegemony?"
    *goto aspiration
    *label whattodowt
    *choice
      *if religion < 20
        *disable_reuse #I offer them a place in the band.
          When you suggest they join you, Horion's
          *if horion < 4
            face creases with regret.  "Alas, ${kuria} ${lname}…it pains me to decline.  I've enjoyed my time in the greenwood.  But Szeric and its 
            *if szth = 0
              lord 
            *if szth > 0
              Theurge
            beckon…and beyond that, a world where I'm better placed to use my tongue and name against the Hegemony.  As much as the rebellion needs you in the Whendward, it'll need folk like me in the courts."
            
            *if linbless
              *if hor_rel >= 10
                Somewhat to your surprise, 
              *if hor_rel < 10
                You're not entirely surprised when
              Ecclesiast Linos also gruffly declines your offer. "I've acclaimed you Eclect, ${kuria}.  But for now, my path is with kurios ${delelle}.  I owe him a more immediate if less fundamental allegiance.  And you shouldn't need my presence—your band's devotion is clear.  Let me accompany my lord, and I'll send a like-minded confrere to you when I can next dispatch a message safely to Shayard."
            *if not(linbless) and (religion > 0)
              When you glance at Linos, he just shakes his head stiffly.  "$!{kuria}…you've already shown what you think of what I have to offer."
            *if religion = 0
              Linos spreads his hands.  "And I accompany kurios Horion."
            *choice
              #I grudgingly accept that they won't join the band.
                In which case…
                *goto whattodowt
              #I cheerfully accept it, thank them, and send them on their way.
                *goto horrelease
              #"You've misunderstood me, kurios.  This is not the kind of offer that can be turned down."
                "Ah."  Horion's face
                *if hor_rel >= 20
                  goes blank with shock and disappointment.
                *if hor_rel < 20
                  falls.
                "Then…is it an offer of longstanding membership?  Or are we to remain only until my family, ah, buys our release from our indenture in the band?"
                *choice
                  #I don't care whether his family ransom him or not, he's staying here.
                    *goto hostagehl
                  #I'll happily release him once the gold comes in.
                    *goto ransomhl
          *else
            brows narrow.  "A place that would last longer than the ransom we both hope my family will pay?"
            
            "If, as you say, you're no friend of the Thaumatarch…why not?  The rebellion can use both the ransom and your skills."
            
            Horion gives a slightly forced-sounding laugh.  "I wish your rebellion well, ${kuria}.  And in truth, I don't begrudge you the ransom.  But to continue deploying my skills against the Thaumatarchy…well, I don't see that being best done from the wilderness.  I'm afraid I must decline the offer."
            *goto whattodowt
      #I release them.
        *label horrelease
        *if askmoot
          *if eclect
            Though you've gone against the will of the ${moot}, Linos's role in declaring you Eclect has changed the band's opinion almost entirely.  There's only a little grumbling from
            *if kal_here
              ${kalt},
            Radmar and a few others at your reversal.
          *if not(eclect)
            The band almost mutinies
            *if rad_mutiny
              again
            at your refusal to respect the will of the ${moot}.  "Damn it, ${kuria}," Radmar shouts, "there's no point in pretending to consult us if you're just going to play the swiving aristarch in the end."
            *set morale -50
            
          *if hor_rel > 12
            *goto simzappeal
        *if horion < 4
          *label simzappeal
          The ${delelle} and his retainer stay with you for two more days.  
          *if kal_here
            You and ${hor_guard} keep a close eye on them and on ${kalt}, ensuring that nothing goes amiss.
          *if (s_rel > 9)
            On the last evening, Horion beckons you aside with an imploring smile.  "$!{kuria}…the hospitality you've shown me is near-miraculous in a rebel camp in the remotest wild.  I am amazed, and to add that I'm grateful would be wholly inadequate to the debt I owe you.  But I daren't refrain from pointing out that another young noble continues to enjoy your hospitality rather against ${zhis} will."
            
            "${simon} de Firiac came of ${zhis} own free will, milord," you point out. 
            *if aristo
              "The terms of ${zhis} service were merely rather different from what ${zhe} had presumed."
            *if helot
              "We just have ${zhim} serving in a slightly different way from what ${zhe}'d imagined."

            "I'll grant ${zhim} a fool, ${kuria}.  I like to think I'd never have been such a pipwit, even at ${zhis} age."  Horion leans close to you.  "You owe me nothing, ${kuria} ${fname}; any debt between us runs the other way, and don't think I've forgotten it.  But if we are truly to be friends…will you free the silly ${zgirl}?  I fear for ${zhis} safety."  
            
            "Surely you don't…" 
            
            He cuts you off with a clap on the shoulder. "Not from you, my dear ${kuria}.  I thought that went without saying."  Horion's chuckle turns grim. "No: 
            *label simzmartyr
            I fear a Theurge might aim to make a martyr of young ${simon} from the air.  Keeps ${zhis} father from paying you a single drachem, and further tarnishes your name with the nobility."
            
            That's a very real risk,
            *if int < 2
              come to think of it.
            *if int = 2
              which you've considered yourself more than once.
            You frown. "So you'd have me release ${zhim} to you and Linos?"
            
            "We can introduce ${zhim} to someone else who can keep ${zhim} from doing further harm to ${zhim}self or anyone else.
            *if szth > 0
              If not Pan Szeric, then another 
            *if szth = 0
              Some 
            like-minded friend in one of the conties."
            *choice
              #Very well.
                *label simzrelease
                *set violence -1
                *set horion 11
                *if id > 1
                  *set horion 13
                *if szth > 0
                  *set horion 14
                $!{deputy} brings ${simon} the following morning while Horion and Linos are loading up their mule.  The young noble wades through the onlooking outlaws towards you, arms stiffly outstretched in a posture of harmlessness.  $!{zhe}'s thinner and muddier than when ${zhe} arrived, and there's a grim set to ${zhis} jaw, but ${zhe} hasn't shed an ounce of determination. 
 
                "One last time, ${kuria} ${lname}: don't cast me away.  I came to fight, not to hide."  $!{zhe} is shaking with barely contained anger. "If you don't want my father's ransom, 
                *if s_rel = 11
                  or to kill me as you'd threatened,
                then why would you send me away with them?"
                *choice
                  *if (helot) #"Because this rebellion is against you and your kind, no less than the Thaumatarchy."
                    *goto rebelnoble
                  *if (aristo) #"Because this rebellion is against the aristocracy, no less than the Thaumatarchy."
                    *label rebelnoble
                    *set cred_a -10
                    *set cred_h +20
                    *set cred_y +20
                    ${simon} isn't the only one to flinch at that.  Horion and Linos don't look your way, but their movements become faster and somehow furtive.  A mostly-approving rumble rises from the small crowd of outlaws. 

                    "You'll fail," ${simon} pleads, hoarse and incredulous.  "And you don't have to.  Not all nobles are 
                    *label theenemy
                    the enemy!  
                    *if aristo
                      You of all people know that.
                    Together, our strength…"

                    From the crowd, Radmar interrupts loudly, "Our?  We've got plenty of stout arms already, ${zmilady}. And there's more out there in the world—a lot more of us than you, begging your noble pardon.  What does your strength add to ours?"

                    To ${zhis} credit, ${simon} doesn't pretend that ${zhis} blademastery is indispensable.  "I'm just one more pair of arms, true.  But back beyond the Rim, there are others like me who could be convinced to bring so much more.  Soldierly experience, gold, land, learning, relations…"
                    
                    Radmar spits onto the forest floor.  "Oh, that strength.  We know all about that, ${zmilady}. That's what's kept us quiet through the whipping, the hunger months, the come-with-me-behind-the-stable-now, the children sold off after harvest."  He stalks up to ${simon}, eyes dark and violent. "We're not quiet, now.  We know our own strength, now.  Maybe we'll kill the Karagonds, maybe they'll kill us.  But either way, it'll be us that does it—and us deciding what comes after."
                    
                    "Which is why you've chosen to forgo the wealth you'd have got from our ransoms." Horion steps in with a peaceable smile and grips ${simon}'s trembling shoulder. "I have nothing but admiration for your consistency, young man.  And for the restraint that drew young ${simon} to your band in the first place, and which has now spared our lives. It gives me hope for, as you say, 'what comes after'—that it will be a true Order, and not the anarchy that many would fear…"  Without pausing in his speech, he turns an appealing gaze to you.
                    
                    "On your way, milord ${delelle}," you confirm brusquely.  The three intruders leave in a brittle silence; none of your outlaws says a word until Linos disappears into the underbrush.
                    *set s_rel 9
                    *set simz_here false
                    *goto hectoratk
                  #"Because I can't trust you."
                    "This is how the Kryptasts come, ${zkuria}. Smiling, swearing vows, full of fire and promise."  You keep talking over ${zhis} rising protest.  "No one here knows you.  No one can vouch for you." 

                    "But…so, wh…you, you won't take help from anyone who wasn't raised within ten miles of Rim bloody Square?"  ${simon}'s voice cracks despite ${zhis} audible attempt to retain control.

                    "Someone who arrives like you did?  I'd think twice. Someone who then tries to convince me to keep ${zhim} on after I've threatened ${zhim}, held ${zhim} hostage, took ${zhis} precious sword, and treated ${zhis} honor like dirt?"  You shake your head slowly.  "You fail the test, de Firiac."

                    Horion coughs loudly to interrupt the outraged ${simon}.  "Give over, ${zgirl}.  The ${kuria} isn't wrong to be cautious.  Come with me and we'll try to leave you in the company of someone less, ah, targeted by Kryptasts.  Someone who might even one day vouch for you to ${kuria} ${lname}, if we all live long enough to see each other again."

                    Judging from ${zhis} livid face, seeing you again is presently the last thing ${simon} wants.  But ${zhe} swallows whatever ${zhe} was about to say and stalks over to join Linos.  Horion blows out his cheeks and offers you a rueful grin.  "Right.  We'll be off then.  All the best to you, ${kuria}—and again, all my thanks."
                    *set s_rel 9
                    *set simz_here false
                    *goto hectoratk
                  #"I told you: I won't ask my band to fight alongside their oppressor."
                    *set cred_a -5
                    *set cred_h +10
                    *set cred_y +10
                    ${simon}'s face darkens with outrage.  "Damn it all, ${lname}—I'm not
                    *goto theenemy
                  #"Because you're a reckless child."
                    ${simon} staggers as if stabbed.  "You?
                    *if helot
                      You truly think…"
                    *if aristo
                      You, of all people?"
                    
                    "The band doesn't need impulsive dreamers," you say coldly.  "What did you think we'd make of you—arriving with two helots, a horse, and the clothes on your back? That we'd admire your bravery?  Our chevalier arrived to the rescue?  Here's my thought: [i]That's the last person I want at my shoulder.[/i]  Who knows what nonsense you'll think of when the Karagonds are actually on us?  Come back when you've learned the difference between courage and foolery, ${zkuria}."

                    "I believe ${zhe}'s taken your point, ${kuria}," Horion cuts in, sounding more than a little cold himself. Beside him, the young de Firiac just blinks wordlessly.  
                    *label suzcomenow
                    "Come now, ${zgirl}.  We'll be on our way—should clear the pass by midday if we hasten.  Thanks again for your hospitality, ${kuria}."  Tugged by the ${delelle}, ${simon} turns with brittle self-control and strides out into the brush without looking back.
                    *set s_rel 9
                    *set simz_here false
                    *goto hectoratk
                  #"That's a fair question, ${zmilady} de Firiac."  Perhaps you should reconsider.
                    The ${zgirl}'s been through enough
                    *if helot
                      to demonstrate ${zhis} loyalty, 
                    *if aristo
                      to satisfy any helot, 
                    surely.  Sensing the direction of your thought, ${simon} flings ${zhim}self to ${zhis} knees before you. "$!{kuria}—I understand it all.  Your concern about Kryptasts, your desire to not just bring
                    *if aristo
                      another
                    *if helot
                      a
                    noble so quickly into the band.  Even the ransom—Angels know that feeding the band is challenge enough to call for desperate measures.  But accept me now!  I'm a blade, not a philosopher like kurios ${delelle}.  I belong with the band."

                    "Not so fast, ${zgirl}," Horion says, sounding troubled.  "You're not just another pair of hands to swing a weapon.  You'd be a target for every Kryptast and Theurge in the archonty.  And if they kill you, they'll say it was the rebels who did it, and paint ${kuria} ${lname} as the monster ${he}'s so evidently not."  

                    "Let them hunt me."  ${simon}'s eyes blaze up at you.  "They'll find me no easy quarry.  But in life or death, this is where I'd serve."

                    Through some priestly gift or trick of diction, Linos's voice suddenly resounds with an almost unanswerable authority.  "$!{zkuria} de Firiac: come with us.  Accept safety, until the time coming when none of us can be safe.  Until a rebellion starts outside this wood."

                    ${simon}'s throat works for a moment, but ${zhe} still manages to shake ${zhis} head. "Let my ${kuria} decide."
                    *choice
                      #$!{zhe} can stay.
                        *set s_rel -3
                        "You pass the test, 
                        *if helot or (kuria != "Captain")
                          ${zkuria}
                        de Firiac," you declare.  "If all this hasn't caused you to lose heart, or to take the chance of freedom when it's offered,
                        *if (aristo) and (kuria = "Captain")
                          who here could force you to leave, so much against your will?"

                          "Captain…"  Despite ${zhim}self, the young blademaster looks as if ${zhe} can hardly believe your words.

                          *set cred_h +10
                          You cut ${zhim} off.  "Which reminds me.  We don't do noble titles here.  I don't want to hear anyone calling you ${zkuria}, or ${zmilady}, or any title you haven't earned by fighting the Thaumatarch.  Understood?"  ${simon} gives a fervent nod; you hope ${zhis} humility will mollify those outlaws not satisfied by ${zhis} humiliation. "Then 
                        welcome to the band."

                        The murmur that ripples through the other outlaws is hard to read—not obviously disapproving, nor pleased.  ${simon} leaps to ${zhis} feet, beaming fiercely.  "Oh, ${kuria}—thank you.  Thanks upon thanks.  I vow to you, on my life and honor, you won't regret this!"
                        *if s_sword = 2
                          *choice
                            #I give ${simon} back ${zhis} family sword.
                              "You'll make better use of this than I."  You unbelt the fine scabbard and offer it back to ${zhim}—not without a tinge of reluctance.

                              The last of ${simon}'s anger seems to melt away.  "$!{milady}…my liege."  $!{zhe} reverently accepts the blade from you, draws it, and raises it in salute.  "I wield it at your command, in service to you and to our cause, until my life's end."
                              *set s_sword 1
                              *goto horgonow
                            #I'll keep the sword until such time as we need ${zhim} to fight for us.
                              *goto swordmine
                            #$!{zhis} sword?  It's mine.
                              *label swordmine
                              You note approvingly that ${simon}'s eyes don't even flicker once toward the blade scabbarded at your waist.  If ${zhe} has any expectation of regaining his family heirloom, ${zhe} doesn't let it show.
                              *goto horgonow
                        *label horgonow

                        Horion clears his throat.  "Well then.  You've made the choice, and Angels grant it won't be one for any of us to regret.  We'll be off, now—hope to clear the pass before dusk sets in."

                        *if skep <= 50
                          "Angels grant you safe
                        *if skep > 50
                          "Safe 
                        travel, kurios," you say, turning from the elated ${simon} to the rueful-looking ${delelle}.  "I look forward to our next meeting."
                        *goto hectoratk
                      #No—I want ${zhim} gone.
                        "Ecclesiast Linos is right, ${zkuria} de Firiac," you say quietly.  "Your courage and heart are admirable.  But there will be a better time for you to fight alongside us—when the rebellion's grown, when we've left the woods.  Here and now, you're more of a threat than a help."

                        "I can keep myself safe," ${simon} pleads, reaching out ${zhis} hands as if to grab what you're wrenching away. "$!{kuria}, please…"

                        "$!{kuria} ${lname}'s right, I'm afraid."  Horion gently catches ${simon}'s hand and encloses the outstretched fingers.
                        *goto suzcomenow
              #No.
                Horion hesitates for a long moment, then ventures, "How much do you think you'll get for ${zhim}, ${kuria}?  Is it worth souring the sympathies of every noble who hears the tale?"
                *choice
                  #"All five who weren't already soured?  Perhaps six?"
                    "Ah, ${kuria}, ${kuria}.  Do you truly think no 
                    *if aristo
                      other noble could travel a road like yours?"
                    *if helot
                      noble could see a helot rising as the hope of Shayard?"
                    Horion stares at you intently.  "You may not feel it here in the distant Rim as we do in the central Ridings, but there is a sickness in the veins of the Hegemony.  Every year, more scions of the aristocracy lose their land and honor to the Karagonds.  Every year, the greatest Houses expand their power while the discontent of the lesser Houses grows.  The renewed war with Halassur may distract some into soldiery or piety, but not enough.  My faithful Linos is one of a multitude—a once-noble name reduced to ministering the sacraments to a richer House.  And look where it's led 
                    *if not(linbless)
                      him.  A devout, orderly soul won over to heresy and sedition."
                    *if linbless
                      him—O Blessed Eclect of the Angels."
                    The ${delelle}'s eyes twinkle, even as his face remains grave.

                    Your mind races through the implications.  "All this discontent you describe…and you think a ransom will turn them against us?"

                    Horion shrugs.  "It's one of the crimes the rich fear most.  Kill all the Alastors you like—Angels know, enough nobles dream of doing the same!  But if they think you're a kidnapper, they'll want you hunted down before anyone else follows your example."
                    *goto releasechoicez
                  #"Oh, come.  Every noble knows that ransom is part of war."
                    Horion shakes his head.  "But this isn't war.  Not to them.  
                    *if helot
                      Not—if you'll hear it from me, Captain—from a helot.
                    *if (religion > 0) and (religion < 11)
                      Not before they hear you named the Eclect of the Angels, and not for a time even then.
                    *if aristo
                      A minor noble of the Outer Rim can start a rebellion, not a war.
                    And while the rumors disagree as to whether young de Firiac was abducted by ${zhis} servants or trying to volunteer on your side, all agree that ${zhe} wasn't a combatant.  The nobles will see this ransom demand as
                    *if hor_rel > 17
                      the vilest form of 
                    *if hor_rel < 18
                      mere
                    banditry.  And  they'll want you hunted down before anyone else follows your example."
                    *label releasechoicez
                    *choice
                      #He has a point.  I'll release ${simon}.
                        *goto simzrelease
                      #I don't agree.  The ransom money will outweigh any damage to our reputation.
                        *goto asyouwill
                      #I don't care.  I'm not trying to win over the aristocracy.
                        *label asyouwill
                        Horion gives a gusty sigh.  "As you will, ${kuria}."  He's evidently
                        *if horion > 3
                          afraid that pushing you any further might lead to you reversing your decision on him and Linos.
                        *if horion < 4
                          given up on persuading you.
                        *goto horiondepart
                  #"I'm more concerned about the sympathies of the helots and drudges of Shayard."
                    "There are a lot more of them."  You look levelly at him.  "And most of them have known no kindness from a noble.
                    *if aristo
                      It's hard enough asking them to join me; each new noble we add to the rebellion will make it harder.
                    If they think this will just end with the nobles still using them, why would they join a rising?  For every young fool like ${simon} de Firiac who tries to join us, we might lose two hundred helots and drudges."

                    "Perhaps—but some nobles would bring five hundred souls with them.  Not just serfs and retainers, but guards, blademasters…"

                    "De Firiac brought two helots.  If the ransom keeps others like ${zhim} at bay, it will serve its purpose."  You shake your head.  "Also, we need the gold.  You weren't here for the rains, milord ${delelle}.  You'd have found us less able to extend hospitality then.  I won't lose more of my band to another hard winter."

                    *goto asyouwill
          *goto horiondepart
        *if horion > 3
          The ${delelle} goes very still when you inform him—hardly the reaction you were expecting.  "Released?  How do you mean, ${kuria}?"
          
          Meeting his barely blinking eyes, you suddenly recognize his emotion and its cause.  "Oh, for…I'm not going to kill you, kurios ${delelle}.  I'm going to take you and your priest back to the Whendward and send you on your way."
          
          Horion remains wary. "That would be a remarkable change of heart, ${kuria}.  I don't mean to sound ungrateful, but…why?"
          *choice
            *if (szth > 0) #"Because I want to meet this curious Theurge."
              Horion nods vigorously, reassurance plain on his face. "Of course, of course, ${kuria}!"
              
              "I want an introduction, milord Horion.  As early as can be arranged."  You lean back, keeping your eyes locked on his. "I've been hard on you and your priest because I wanted your honesty.  But you're right—we are working toward a common cause.  And unless we can bring together all of the Thaumatarch's enemies to fight as one, we'll be swept away.  So send me word from Szeric when you know more of this Theurge, and we'll arrange a meeting on the ${whend}ish side of the pass."
              
              "You can rely on me, ${kuria} ${lname}," the noble babbles. "We'll not forget your mercy."
              *goto horiondepart
            #"Having spoken with you, kurios, I've concluded you're no enemy to our cause."
              "Angels' Blood, ${kuria}…I'm glad we've reached agreement on that!"
              *label horionappeal
              The sudden brightening of Horion's prospects seems to leave him on the verge of hysterical laughter; his smile is quivering and cheek-crackingly wide.
              *if s_rel > 9
                Then a hint of gravity returns to his voice.  "But if you'll forgive my boldness…what of our fellow guest?  This pipwit de Firiac?
                *goto simzmartyr
              "We'll not forget your mercy.  Nor will you find us ungrateful."
              *goto horiondepart
            #"Your friendship would be worth more to us than your ransom."
              "And you have it, my dear ${kuria} ${fname}!"
              *goto horionappeal
            *if linbless 
              #"I owe Ecclesiast Linos a great deal.  It would be unworthy of the Angels' Eclect to demand a ransom for him—or his master."
                "I was hoping you would see it that way, my dear ${kuria}!"
                *goto horionappeal
            #"How could I hold hostage a true-hearted son of Shayard?"
              *set natl %+10
              "And together, we'll see Shayard rise to greatness again, ${kuria}!"
              *goto horionappeal
            *if (s_rel < 9) #"I believe kidnapping is against the Angels' will."
              *set skep %-10
              "Then bless you, ${kuria}, and may the Angels grant you fair return!"
              *goto horionappeal
            *if (s_rel >= 9) #"I believe kidnapping is against the Angels' will.  In fact, I'm releasing the young de Firiac as well."
              *set skep %-10
              You hadn't expected any further protest at your mercy, and indeed, Horion is voluble in his gratitude.  Then 
              *goto simzrelease
            #"Trying to collect your ransom is too risky, and I'm not feeling inclined to kill you in cold blood."
              Horion just stares at you for a moment.  "Then…my thanks, ${kuria}.  For my life, and the life of my man.  We'll not forget your mercy."
              *goto horiondepart
        *label horiondepart
        
        *set horion 11
        *if id > 1
          *set horion 13
        *if szth > 0
          *set horion 14
        At daybreak on the third morning, you and Alira escort them back to the pass where you first found them.  It's hard going and the sun is soon ablaze, but your two former ${guest}s seem to gain strength and mettle with each step they take toward Szeric.
        
        When Alira finally stops and points them up the trail, Horion bows deeply to you.  "One last time: all my thanks for your hospitality, 
        *if aristo
          gentle
        ${kuria}." The tall, plump ${delelle} is bubbling over with relief.  "I'll be following news of the spring to see how you fare—and I'll be sure to spread word of what you've accomplished already."

        *if skep <= 50
          "Angels grant you safe
        *if skep > 50
          "Safe 
        travel, kurios," you reply, clasping his hand and bowing to
        *if religion >= 20
          a grimly silent
        Linos.  "I look forward to our next meeting."
        *goto hectoratk
      *if id > 1
        #I demand a ransom from the Archon.
          *label ransomhl
          *set violence +1
          *if linbless
            *gosub linblesskidnap
            *if linkid = 1
              *goto horrelease
          *if not(linbless) and (horion < 4)
            *gosub dishonorable

          How do you intend to get the ransom demand to
          *if id > 1
            Conte Phrygia?
          *if id <= 1
            House de Lelle?
          Sending an outlaw with a message would be
          *if id <= 1
            time-consuming and unlikely to succeed.
          *if id > 1
            a death sentence.
          *choice
            #I send Ecclesiast Linos.  He's the most convincing proof that we really do have Horion.
              *set horion 6
              Linos looks torn between relief, repugnance, and reluctance to leave his master alone.  "I'll bear your message, ${kuria}," he rasps at last. 
              *if id <= 1
                "Remember, the distances are long.  Even with all due haste, you may not hear from me before midsummer.  But be assured that I will bring back the ransom, from kurios Horion's friends and family."
              *if id > 1
                "Because I believe it's the only hope for kurios Horion to leave here alive.  If word reaches the Alastors about the kidnapping, it will become all but impossible for Archon Phrygia to pay a ransom."

                "If by midsummer, the full amount of gold has not been delivered to the Forked Peak…" you say quietly.  It's a long journey to Grand Shayard, but the Archon should be able to send the ransom in a day or two by Theurge.
              
                Linos gives a sharp shake of his head.  "You'll 
                *if knowwhy > 1
                  know if I fail before then, ${kuria}—when Strategos Nomiki sends all her Theurges to blast kurios Horion from the air.  Watch the skies.  And watch your backs."
                *if knowwhy < 2
                  get your ransom, ${kuria}.  I'll not fail."
              *label horiongrieve

              On the morning when the Ecclesiast is blindfolded and borne away, Horion ${delelle}'s cheery facade finally dissolves.  You watch his eyes grow dull as Linos's party wends their way down the stream course.  Without his customary smile, the wrinkles in his round face look deeper, starker.  When the party passes out of sight, Horion slumps to the ground.
              
              "There's reason to hope…" you begin.
              
              "Don't." Horion lifts his sagging face toward yours.  "We've nothing to say to each other, ${lname}."  He barely moves for the rest of the day, until ${hor_guard} finally cajoles him to rejoin the band for the evening meal.
              *goto hectoratk
            *if id <= 1
              #I get a merchant who fences our goods to contact the family.
                You travel back for a late night consultation with
                *if (alaine > 0) and (protection != 1)
                  Alaine Leybridge 
                *if (alaine <= 0) or (protection = 1)
                  Cacelon, one of your more reliable fences,
                and agree a story: Horion and Linos asked
                *if (alaine > 0) and (protection != 1)
                  her
                *if (alaine <= 0) or (protection = 1)
                  his
                cousin Janen to help them find a way over the pass, and all three were taken by outlaws.  "Now the horrid bandit ${fname} ${lname} tells me that if we're to see young Janen alive again, we've got to quietly arrange a ransom for kurios Horion…and we thought we'd best come to the de Lelles before we went to the Alastors."
                *if (alaine > 0) and (protection != 1)
                  Alaine's
                *if (alaine <= 0) or (protection = 1)
                  Cacelon's
                eyes gleam with amusement.
                
                "You know where to find House de Lelle?" you ask.
                
                "Never heard of them—but I haven't heard of most Houses in Shayard."  The trader waves away the problem.  "I'll make the link through my contacts in the Southriding.  We should know in a month or two.  And don't worry, ${kuria}—I won't claim more than a tithe of the ransom for my part in it."
                *goto hectoratk
            #I tie a message to an arrow and have it shot into the Keriatou estate.
              *set ransomarrow 1
              *label wtdlinos
              While ${deputy} and you are working on the message, your deputy is struck by a sudden thought.  "What do we say about the Ecclesiast, ${kuria}?  The ${delelle} will never pay ransom on a retainer."
              *choice
                #"Then I suppose we'll give them two for the price of one."
                  *goto arrowker
                #"We'll ask a ransom for him anyway."
                  *goto arrowker
                *selectable_if (linbless = false) #"The priest's of no value to us.  Dispose of him."
                  *set horion 7
                  *label dispose_of
                  *set violence +1
                  *set ruth %+20
                  *set cred_p -20
                  *if deputy = "Zvad"
                    Zvad blinks at you.  "Truly?  An Ecclesiast?"  He runs his fingers through matted hair.  "Some of the band will like that less than others, ${kuria}."
                    
                    *if skep > 50
                      "They'll learn. They don't need to fear Angels, and I won't have them fearing priests.
                    *if skep <= 50
                      "They need to learn that the Ecclesiasts don't represent the Blessed Angels.  
                    The longer we let Linos stay here, the more they'll fall back into the old habits of deference."  You've watched it starting already around the meal circle. "Best to make the break quick, and 
                    *if ransomarrow = 0
                      early."
                    *if ransomarrow > 0
                      early.  We'll leave the body at the crossroads just outside Rim Square—we can mention it in the message.  It's good evidence."  [i]Evidence both of whom we've got, and what we're willing to do to them.[/i]
                    
                    Zvad shifts uncomfortably under your stare, but finally nods.  "I'll see it done, ${kuria}
                  *if (deputy = "Breden") and bred_here
                    Breden stares at you for a moment as if judging your seriousness.  Then ${xhe} takes a deep breath and nods curtly.  "As you say,
                    *if aristo
                      ${kuria}
                  ${fname}.
                  *if ((hor_guard != deputy) and (hor_guard != "Radmar")) and (kal_here)
                    Just be sure ${hor_guard} is told not to interfere.
                  Tonight I'll take the Ecclesiast for a walk with
                  *if kal_here
                    ${kalt} and
                  one or two others."
                  *if (deputy = "Breden") and (ransomarrow > 0)
                  
                    You smile your approval. "Have his body left at the crossroads outside Rim Square—we can mention it in the message.  It's good evidence."  [i]Evidence both of whom we've got, and what we're willing to do to them.[/i]
                  *page_break
                  Halfway through the morning, the normal hubbub of camp is broken by a throat-splitting wail.  Horion ${delelle}'s voice is barely recognizable in its grief and fury: "Bastard!  $!{lname}, you unspeakable bastard!  A priest, an innocent!  What kind of monster…what kind of honorless dog…"
                  
                  By the time you press through the startled crowd of outlaws and children, the ${delelle} has already been roughly silenced by an unsmiling ${deputy}.  When he sees you, Horion breaks free with fists outstretched—but a casual blow from Radmar topples the noble to the grass before he's gone three steps.  Crouched there on hands and knees, Horion utters a low snarl: "Murderers."
                  
                  "Executioners," you reply coldly.  "Of any who served the Thaumatarch and supported his Hegemony with their preaching."

                  "He was a rebel at heart, you bloodthirsty little shit!" Horion howls. 
                  *if s_rel > 9
                    You notice your other hostage ${simon} de Firiac is standing nearby, face similarly contorted in outrage.
                  "He'd sooner have served you than the Thaumatarch."
                  
                  "I didn't want his service."  You stride forward and drag the noble back to his feet, sure that he won't dare actually to strike you.  "And let me be clear, kurios Horion.  If
                  *if ransomarrow > 0
                    your cousin doesn't pay for you, 
                  *if ransomarrow = 0
                    you cause me any further trouble,
                  you'll go the same way."
                  
                  With another curse, Horion spits in your face.
                  *choice
                    #I kill him.
                      *set morale -6
                      *set ruth %+15
                      *set horion 0
                      *set cred_a -20
                      It takes only a second to draw your knife and ram it into Horion's belly.  For an instant, the shock on his tear-streaked face looks like relief.  Then the pain arrives with a visible, whole-body spasm; he collapses and begins to shriek.
                      
                      *if s_rel > 9
                        "Monster!" shouts ${simon} de Firiac, tears spilling down ${zhis} cheeks.  "Bloody, vile, honorless monster!"
                        
                        *set s_rel 19
                      Four young bandits quickly 
                      *if s_rel > 9
                        gag the noble ${zgirl} and bear the screaming Horion
                      *if s_rel <= 9
                        bear him 
                      away out of earshot, leaving a stunned silence.  
                      *if ransomarrow > 0
                        "Well…so much for that ransom," ${deputy} says bleakly, glancing around.  
                      You can tell that your impulsive act of retribution has not impressed your fellow outlaws.  
                      *if kids > 2
                        Several children have begun to cry.
                      *choice
                        #We leave our two ${guest}s' bodies at a crossroads where they'll be quickly found and identified.
                          *label crossroads
                          *set xroad true
                          *set notoriety +100
                          *set anarchy +5
                          A small party led by Radmar bears the corpses to the main road outside Rim Square.  They dump them unceremoniously at the crossroads, 
                          *if id = 0
                            where they'll be found by the first traders or nobles to ride by.  You await the rumors that might tell you who your victims were.
                          *if id > 0
                            along with a scrap of parchment identifying them as Horion ${delelle} and his retainer Linos.  
                          *if id > 1
                          
                            When Radmar and his group finally reappear on the ridge above your camp, the normal chatter of the band dies away, and an unnatural silence prevails for the rest of the day.  How far behind them can Archon Phrygia's vengeance be?  
                            *if kids > 2
                              Even the children too young to understand the meaning of your provocation are subdued, grasping the mood, if not its cause.
                            
                            It persists through dinner; you've never seen the band so uniformly morose and silent save after a death.
                            *if bred_here
                              At last Breden stands and speaks out. "Sisters, brothers…before today, do you know what the Archon thought of us?  Nothing.  If she knew of our rebellion at all, she'd have considered it a headache for the aristarchs of some backwater district of the Rim."  $!{xhis} smile is hard, brittle.  "I reckon we just changed her mind.  I reckon now she knows who we are.  As will others all over Shayard.  
                              
                              "Yes, now she'll hit us as hard as she can—but the wilderness will protect us.  We'll survive.  And after that the world will truly be watching."
                              
                              Breden's fierce, confident
                              *goto toneband
                            *if elery > 0
                              "Well, that's jabbed a stick well and truly in the Conte's eye," Elery Skinner finally says in a loud voice, wiping quail-grease from her fingers. "Now it's time to stop all this bloody moping about and brace ourselves for whatever comes next."  
                              
                              Her matter-of-fact
                              *label toneband
                              tone brings the band back to themselves.  By the time everyone heads for the tents, there's a more typical thrum of conversation—and, perhaps, a more-than-typical amount of pairing off between the sleeping skins that night.  In the morning, as you once again pack up camp to move, the collective mood is wary but resolute.
                              *goto hectoratk
                            *elseif cha = 2
                              At last you speak out. "$!{addressc}…before today, do you know what the Archon thought of us?  Nothing.  If she knew of our rebellion at all, she'd have considered it a headache for the aristarchs of some backwater district of the Rim."  Seeing hard smiles begin to appear on your followers' faces, you nod with them.  "Yes.  We just changed her mind.  She knows who we are—as will others all over Shayard.
                              
                              "And as you're all thinking: we won't get by unscathed.  No, she'll hit us as hard as she can.  But the wilderness will protect us.  We'll survive.  And after that the world will truly be watching."
                              
                              Your confident
                              *goto toneband
                            *else
                              The meal breaks up, a few grim outlaws at a time, until at last everyone has trudged back to the tents for a sleepless night.
                              
                              *if kids > 2
                                Thankfully, the children's mettle can't be repressed for long, and most adults also 
                              *if kids <= 2
                                Most of your followers finally
                              begin to shake off the gloom as they pack up camp in the morning.  Still, the band's mood definitely remains more fearful and uncertain than it was a week ago.
                              *set morale -6
                              *if notthere
                                *page_break
                                *goto wanttofound
                              *goto hectoratk
                          *if notthere
                            
                            *goto wanttofound
                          *goto hectoratk
                        #We bury them in the woods.  Best if no one outside the band ever knows they were here.
                          *label unmarkedgrave
                          *set unmarked true
                          *if id = 0
                            Within an hour, the two strangers
                          *if id > 0
                            Before the day is out, Horion and Linos 
                          share a deep and anonymous grave.  Not in a thousand years would anyone find them—not this far out in the wilderness.
                          
                          *if s_rel < 0
                            Nor will anyone find ${simon} de Firiac.
                            *goto bred_chat
                          However, in the following days you often overhear nervous conversations about your slain ${guest}s. You can't help worrying that some of those stories might find their way back to civilization.
                          *set anarchy +2
                          *set notoriety +50
                          *if notthere
                            *goto wanttofound
                          *goto hectoratk
                    #I strike him.
                      *if s_rel > 9
                        "Oh, shame!" cries ${simon} de Firiac as your fist bloodies Horion's face. "Dishonor upon dishonor!"
                        
                        *set s_rel 19
                      The ${delelle} staggers backward, raising his arms to fend off further blows.  
                      *label glarewild
                      His eyes glare wildly at you through his matted hair. "Kill me now, bastard.  Have done with it."
                      
                      "Bind milord ${delelle}," you growl to the outlaws, wiping the spittle from your cheek.  "I don't want him doing any harm to himself which might reduce
                      *if ransomarrow = 0
                        his usefulness as a hostage."
                      *if ransomarrow > 0
                        the value of his ransom."
                      *if s_rel > 9
                        You glance at the livid de Firiac.  "And as for you, ${zmilady}…your father's ransom is unlikely to be worth much more of your 
                        *if aristo
                          insolence."
                        *if helot
                          lip."  
                        $!{simon}'s mouth twists with contempt, but ${zhe} says no more and does not resist as your followers tie him and Horion securely to a tree.
                      *goto hectoratk
                    #I hurl him back to the ground.
                      *if s_rel > 9
                        "Oh, shame!" cries ${simon} de Firiac as the older aristocrat topples backward.

                      Your shove sends Horion hard onto the grass.  To your slight surprise, the plump noble rolls like a practiced wrestler and comes up breathing heavily but not obviously hurt.
                      *goto glarewild
                    *if aristo and (id <= 1)
                      #I look at him with restrained scorn.  This only confirms his powerlessness.
                        *label bindhim
                        "Bind milord Horion," you order, wiping the spittle from your cheek.  "I don't want him doing any harm to himself which might reduce
                        *if ransomarrow = 0
                          his usefulness as a hostage."
                        *if ransomarrow > 0
                          the value of his ransom."
                        *goto hectoratk
                    *if helot or (id > 1)
                      #I laugh.  This is all this ${delelle} can do to harm me?
                        You couldn't have imagined it a year ago—standing face to face with an enraged
                        *if helot and (id <= 1)
                          noble,
                        *if aristo or (id > 1)
                          cousin of the Archon,
                        and he has no power even to physically strike you?
                        
                        *goto bindhim                        
              *label arrowker
              Once
              *if aristo or (int = 2)
                you have
              *if helot and (int < 2)
                Zvad has clumsily
              written out the ransom demand, Ciels and two other hunters bear it back toward Rim Square.  They attach it to an arrow, 
              *if ransomarrow = 1
                hide until dusk, and then fire it from a distance into the front gate of the Keriatou estate, just as the aristarchs' daytime retainers are leaving for their homes.  In the ensuing confusion, your raiders escape easily.
              *if ransomarrow = 2
                wait until nightfall, then creep into the outskirts of town and try to leave the message just ahead of an Alastor patrol.  After two unsuccessful attempts in which the Hegemonic enforcers fail to spot the arrow, they finally stick it into a fence post where it's too obvious to be missed.
              *set anarchy +2
              *set notoriety +30
              
              *if (ransomarrow > 0) and (knowwhy > 1)
                When Linos hears about it, he charges into your tent, a protesting ${hor_guard} two steps behind him.  "Are you mad, ${kuria}?  Telling the 
                *if ransomarrow = 2
                  Alastors 
                *if ransomarrow = 1
                  aristarchs
                you have us?  That's the same as telling Nomiki."
                
                "She was always going to find out, Ecclesiast," you retort.  "Now we'll see whether the Archon sends an assassin or a ransom."
              *goto hectoratk
            #I have it left by night where the Alastors of Rim Square will find it.
              *set ransomarrow 2
              *goto wtdlinos
              
              *label dishonorable
              It's wildly dishonorable after declaring them your guests…but you can't let the opportunity pass.  When you inform Horion, his face collapses.  "I…I suppose this should not come as so great a surprise.  We are at your mercy, ${kuria} ${lname}."
              *set horion 4
              *return
              
              *label linblesskidnap
              You find your kidnapping somewhat complicated by the fact that one of the hostages just declared you Eclect of the Angels.  When you first raise the question of ransom arrangements with ${deputy},
              *if deputy = "Zvad"
                he
              *if deputy = "Breden"
                ${xhe}
              blinks at you uncomfortably for several moments before venturing, "You don't think…ah, that the Ecclesiast might have something to say about that?"
              
              "When did Ecclesiast Linos start swaying our decisions?"
              
              *if deputy = "Zvad"
                The big ${whend} just grimaces and shakes his head.  "The band have been showing him respect since he acclaimed you, ${kuria}.
                *if askmoot
                  Any ${moot} you held today would tell you to let him go his way.
                I'd reckon we
              *if deputy = "Breden"
                Breden's voice becomes slightly waspish.  "I don't know.  When you stood him up in front of the whole band and had him attest to your Angelic call?"  $!{xhe} holds ${xhis} hands up to forestall your response.  "No.  I don't know what you were thinking, but think again, ${kuria}.  You
              can't have both a ransom and a blessing."
              *choice
                #That's true, damn it.  I'd best release them.
                  *set linkid 1
                  *return
                #We'll see what Ecclesiast Linos has to say about that.
                  You have Linos brought to your tent and congratulate him again on the success of the Sacrament.  "Now, 
                  *if aristo
                    however, we come to a practical question: the terms on which kurios Horion is to be released
                  *if helot
                    we need to talk about the terms of kurios Horion's release
                  to his family."
                  
                  *if hor_rel > 19
                    "Why, Eclect ${fname}…I understood that you had accepted us as guests."  Linos's ferocious black eyebrows leap upward.  "I'm sure I've misunderstood you, but to be clear: kidnapping for ransom is a grave crime under any Order.  It is simply unthinkable that any true servant of the Angels would resort to it.  Unthinkable."
                    
                    "And were an Angelic Eclect to think it?"
                    
                    Linos's voice is unruffled, but his eyes grow flinty.  "Your own followers could answer that for you, I think, ${kuria}.  They would 
                    *label theydstruggle
                    struggle to understand how a ${woman} who supposedly revered the Angels could justify threatening the very priest who recognized ${his} calling.  They would doubtless question whether the priest had been correct in the first place."
                    *goto linkidchoice
                  *elseif hor_rel > 10
                    Linos's ferocious black eyebrows lift slightly. "The Eclect of the Angels need not resort to ransom, surely.  Some crimes are further from Order than others, ${kuria}."
                    
                    You give him a hard stare.  "Having declared me Eclect, isn't it a bit late to try laying down the law on this?"
                    
                    "The law of nature itself has led every civilized nation to abhor the threat of kidnapping."  The Ecclesiast's tone is cautious, but his eyes remain steady on yours. "Your followers might
                    *goto theydstruggle
                  *else
                    "$!{kuria}…" The priest moistens his lips, but his fear doesn't entirely quench the defiance in his eyes. "I thought it was clear that when you accepted my offer, you made it…complicated to claim a ransom on me or my master."
                    
                    "That was no part of the bargain."  Bringing your face inches from his, you snarl, "There was no bargain.  You thought it was clear that I'd release you?  I didn't even agree not to kill you."
                    
                    Linos cowers away.  "Our lives are yours, ${kuria}.  But…forgive me, but I must say it.  Your followers might
                    *goto theydstruggle
                  *label linkidchoice
                  *choice
                    #"Naturally, you are our guests…and we won't detain you a moment longer than you desire."
                      *set linkid 1
                      "Naturally."  Linos 
                      *if hor_rel > 10
                        bows to you and exits the tent, not waiting to be dismissed.
                        
                      *if hor_rel < 11
                        turns his cringe into a low bow.  "Your mercy and wisdom…"
                        
                        "You'd best leave now, Ecclesiast."
                        
                        "Indeed, ${kuria}." The priest flees the tent.
                        *page_break
                      *set violence -1
                      *return
                    #"You are in error, priest.  The Angels permit ransom in a war, and this is war."
                      *label inerror
                      *if hor_rel < 11
                        "As you say, ${kuria}." Linos remains in his cringe.
                        
                        The argument doesn't seem to sway many others, however.
                      *if hor_rel > 10
                        Linos shakes his head bitterly.  "When you recognize this for the error it is, ${kuria}, I hope it is not too late to regain your followers' faith."
                        
                        Much as you hate to admit it, the priest is vindicated over the next few days.
                      *goto linkidmorale
                    #"If you want to survive the week, you'll support the ransom of kurios Horion."                      
                      *goto inerror
                #Then I'll take the ransom.
                  *label linkidmorale
                  When it becomes widely known that you
                  *if horion > 3
                    still
                  intend to hold Ecclesiast Linos and his master hostage, the morale of your band is badly shaken.  Each day, you hear fewer people referring to you as "Eclect." Instead, you begin to overhear the word murmured in tones of bitter contempt.  Some of your more pious outlaws actually sneak away during the night.
                  
                  *set morale -20
                  *set cred_p -10
                  *set followers -9
                  *set nonkids -9
                  *return
      *if id <= 1
        #I demand a ransom from House de Lelle.
          *goto ransomhl
      #I hold them hostage without ransom, to reduce the odds of the Karagonds raining down fire on our camps.
        *label hostagehl
        *set violence +1
        Claiming a ransom would be too dangerous and complicated.  Instead, you deliver a message by arrow to House Keriatou, informing 
        *if helot
          the aristarchs 
        *if aristo
          your cousins
        that you now hold Horion ${delelle} hostage and that you will not be responsible for his safety in any attack on your camp.
        *if horion < 4

          *gosub dishonorable
        *if horion > 3
          *set horion 2
        *choice
          #I also keep Ecclesiast Linos hostage.
            Linos refuses to leave Horion in any case.
            *if not(linbless)
              "Any threat my master faces, I shall face at his side," he declares stoutly.
            *if linbless
              "This choice ill befits the Eclect of the Angels," he
              *if hor_rel > 15
                growls.
              *if hor_rel < 16
                says, eyeing you warily.
              "A threat to the priest who acclaimed you.  How will your followers understand that?"
            
            "No threat, Ecclesiast," you counter at once.  "We're demanding no ransom for your safety.  But this is the season when the servants of the Thaumatarchy will be hunting us most.  I can't let you continue alone over so exposed an area as the Whendward Pass.  One Theurge flying past, and all would be lost.  Wait with us until the fighting season is past again."
            
            *label accustomhost
            The band quickly grows accustomed to the constant presence of the hostages, with $!{hor_guard} as their guard and protector.  Indeed, Horion's wry, warm sense of humor soon begins to win the ${delelle} some friends in the meal circle.
            *if religion > 9
              Linos also attracts the loyalty of a few Angel-loving outlaws—though as far as you're aware, they all hold back from actually performing the old Sacraments.
            *if religion < 10
              The pious outlaws look to Linos to lead them in Sacrament.
            *if linbless
              *label natlrite
              It soon feels natural to glimpse his stern, paternal figure at the head of a small crowd in the evenings, leading them through
              *if religion > 9
                something not entirely unlike
              the familiar rite.
              *goto hectoratk
            *else
              *choice
                #And I allow it to happen.
                  *set skep %-10
                  *goto natlrite
                #I discourage it.
                  You make it known that you're not happy having so many of the band looking to an Ecclesiast of the Hegemony for guidance.  Even given Linos's own seditious tendencies, he's not an outlaw; you don't want him building up authority over your followers.
                  *if cha > 0
                    The pious outlaws grumble but seem to respect your will.
                    *if cha < 2
                      For now.
                  *if cha < 1
                    You find, however, that there's a limit to how much your pious followers will respect your will.  From the whispers and children's gossip you overhear, it's clear people are finding ways to receive some kind of surreptitious ritual blessing from the priest.
                  *goto hectoratk
                #I forbid it.
                  *set skep %+10
                  Having an Ecclesiast—even a captive—lead them in the familiar rituals is a step back toward subjection to the Hegemony.  You let the band know in no uncertain terms that you won't tolerate anyone taking part in a Sacrament led by Linos.  Your strong line leads to much grumbling, but no outright mutiny.
                  *if cha < 2
                    *set morale -3
                  *goto hectoratk
          #I release the Ecclesiast.
            When you inform Ecclesiast Linos that you're going to return him to the outskirts of Rim Square, he scowls defiantly through his gray beard.  "Any threat my master faces, I face at his side."
            *if linbless
              Though it rankles, you have to accept his refusal; after he acclaimed you Eclect of the Angels, it would be unwise to order your followers to take him away by force.
              
              *goto accustomhost
            *choice
              #I grudgingly accept his refusal.
                *goto accustomhost
              #I have Radmar bind the Ecclesiast and take him away blindfolded on the back of a mule.
                *set horion 8
                "I'm afraid it wasn't a choice, Ecclesiast," you retort.  "I won't feed you, I won't kill you.  If you won't go of your own free will, I'll have you bound to a mule and left by the roadside."
                
                Linos is visibly struggling to hold back his fury.  "$!{kuria}, this is…I can not and will not abandon my master.  Bear me away, and I'll just come seeking you again."
                
                "And I'd just have you borne away again.  If you truly want to serve your master, go convince the Hegemony that attacking us will mean his death."
                *goto horiongrieve
              #I'm not going to feed a useless hostage.  If he won't go, I have him killed.
                *label informdep
                *set horion 9
                You inform your deputy of your decision later that afternoon.
                *goto dispose_of
          *selectable_if (not(linbless)) #I dispose of him.  He's of no use to me.
            *goto informdep
      *if (not(linbless)) #I leave their bodies at the crossroads just outside Rim Square.
        *set violence +1
        Killing
        *if id <= 1
          them
        *if id > 1
          Conte Phrygia's cousin
        gives you something you can't buy with any amount of ransom: notoriety.  Upon reflection, you'd rather face the Archon's full fury than molder away inconsequentially in the forest.
        *gosub execuchoice
        *if (simz_here) and (s_rel < 9)
          *gosub simonflee
        *goto crossroads
        *label execuchoice
        *set horion 0
        *if id <= 1
          *set horion -10
        *choice
          #I carry out the executions myself.
            You have 
            *if (hor_guard != "your father") and (hor_guard != simon)
              ${hor_guard}
            *if hor_guard = "your father"
              ${kalt}
            *if hor_guard = simon
              Radmar
            *if hor_guard != deputy
              and ${deputy}
            bind your ${guest}s and bring them to a rocky clearing some distance from the camp.  When you arrive, brandishing 
            *if weapon = "sword"
              your sword,
            *if weapon != "sword"
              one of their swords,
            Horion realizes your intention at once.  
            
            "$!{kuria}, please…" he pleads, eyes wide and round as two small moons—and despite yourself, something in you quails in sympathy with his helplessness.  
            *if aristo and (demerre < 5)
              What in your nineteen years has prepared you for killing a fellow noble, bound and in cold blood?
            *if aristo and (demerre = 5)
              You'd thought the deaths of House de Merre would have hardened you, but there's something different about killing this bound captive in cold blood.
            *if helot
              How many times have you heard your fellows plead just as pitiably for their lives?

            Then
            *if (hor_guard != "your father") and (hor_guard != simon)
              ${hor_guard}
            *if hor_guard = "your father"
              ${kalt}
            *if hor_guard = simon
              Radmar
            kicks the backs of the ${delelle}'s knees, breaking your eye contact and sending him to the ground.  You rush in and bring the sword down before his wails turn back into words.  Linos begins screaming incoherently and tries to charge at you.
            *if com = 0
              It takes several of your inexperienced blows before both of them stop moving.
            *if com > 0
              Of course, with his hands tied, all he can do is die on your blade.

            There's a tremor to your hands afterward.  By nightfall, it's passed.
            *return
          #I get my deputy to do it.
            *if deputy = "Zvad"
              Zvad is clearly reluctant when you first raise it with him.  "What about a ransom, ${kuria}?"
              
              "Too hard to collect."  You're surprised at his qualms.  "More importantly: nothing else we could do would make us as notorious across Shayard as this.  The opportunity won't come again."
              
              The big ${whend} shifts uncomfortably. "Very well, ${kuria}
            *if deputy = "Breden"
              Breden stares at you for a moment as if judging your seriousness.  Then ${xhe} takes a deep breath and nods curtly.  "As you say,
              *if aristo
                ${kuria}
            ${fname}.
            *if ((hor_guard != deputy) and (hor_guard != "Radmar")) and (kal_here)
              Just be sure ${hor_guard} is told not to interfere.
            Tonight I'll take them for a walk with
            *if kal_here
              ${kalt} and
            one or two others."

            By morning, your two ${guest}s are dead.
            *return
          #I have their food poisoned.  It's against the Angels' Canon, but it's cleaner than physical violence.
            *set skep %+10
            *set skepreal %+10
            *if rescuer = 0
              Terret Abler hesitates, but doesn't challenge your request for the nightshade roots he's gathered for his dwale.  
            It's simple to add a mash
            *if rescuer > 0
              of nightshade roots
            to your ${guest}s' bowls for their evening meal.  Around midnight, you faintly hear the thrashing and strangled gasps from their tent.
            *if skepreal < 75
              Despite yourself, you can't sleep for the rest of the night.  The condemnation of the "poisoner and assassin" to the torments of Taratur in the sacred Codex echoes through your mind until dawn.
            *return
      *if (not(linbless)) #I dispose of them quietly.
        *set violence +1
        The last thing you want is to draw down the Archon's full fury.  Best for no one outside the band to know they were ever here.
        *gosub execuchoice
        *page_break
        *if (simz_here) and (s_rel < 9)
          *gosub simonflee
        *goto unmarkedgrave
        
        *label simonflee
        *set s_rel +20
        *set simz_here false
        *page_break
        The next day, when it becomes clear what you've done, ${simon} de Firiac vanishes.  No farewells, none of the recriminations or hard choices you'd been braced for. $!{zhe} simply flees the band.
          
        As soon you realize ${zhe}'s gone, you send Ciels after ${zhim}. $!{he} returns empty-handed a day later, looking rueful and impressed.  "I knew the young ${zkuria} had spent ${zhis} time on the hunt as well as with the blade, ${milady}.  But I hadn't realized ${zhis} woodcraft was near enough to mine.  Whichever way ${zhe} passed, ${zhe}'s hidden ${zhis} tracks like a master."
        
        You shake your head in frustration.  "Put the word about, then.  If anyone comes across ${zhim}…"
        *choice
          #"…Tell ${zhim} to come back to us.  $!{zhe} was always welcome here."
            *return
          #"…Find out what ${zhe} intends to do, and make sure ${zhe} isn't causing us any trouble."
            *return
          #"…Kill ${zhim} on sight."
            *return
*label wanttofound
*set notthere true
*if horion <= 0
  As word spreads of the killing, a debate flares up in the camp.  
  *label guestcode
  Everyone knows that hospitality to traveling strangers is an obligation under the Karagond Canon, but you hadn't realized that for ${whend}s, it's an absolute cornerstone of sacred and social Order.  Most of the ${whend}s in your band are vocally outraged when they discover
  *if lead = kalt
    ${kalt}'s
  *if lead = "Breden"
    Breden's
  *if (lead != "Breden") and (lead != kalt)
    your 
  appalling violation of the guest-code.

  Several of your Shayardene followers respond with scorn and anger.  "You wouldn't have us offer bread and shelter to a Kryptast or Alastor, or keep them alive if they fell into our grasp," Radmar snaps at an affronted ${whend}ish outlaw.  "How is a noble any less our enemy?"

  "Don't ask us," she grates back at him.  "Ask the Angels.  They're the ones you've offended.  They're the ones who'll send the pestilence on us."

  *if not(notthere)
    *if religion > 0
      The argument is your first chance to apply the religious principles you've established.
      *set notthere true
      *choice
        #I tell the ${whend}s they're wrong.
          You summon the dissidents to a meeting in your tent.  
          *if religion < 21
            "The Angels don't ask us to give guest-right to an enemy," you declare forcefully, well aware that ${whend}ish tradition insists on the opposite.  "It may be hard for you to accept—but this is exactly where the wrong sort of compassion can lead us from the right path.  Do you think I would have dared such an act without hearing clearly from the Angels?"

            *label shiftuncom
            *if religion < 11
              The ${whend}ish outlaws shift uncomfortably.  They were some of the most passionate in acclaiming you Eclect, and can't lightly dismiss your authority.
            *if (bred_here)
              Breden backs you up with all ${xhis} eloquence, arguing that your so-called "guests" were too dangerous to be allowed to live.
              *if cha < 2
                *set bred_lead +1
            *if religion < 11
              At last, 
              *if not(bred_here)
                they 
              *if bred_here
                the ${whend}s 
              mumble their apologies for questioning you.  You don't think they're wholly persuaded, but at least the debate stops without any evident damage to morale.
              *goto hectoratk
            *else
              But the ${whend}s stubbornly refuse to accept your authority on this point.  "You told us we could all hear Angels, ${kuria}," one of them growls.  "Well, this is what we hear in our hearts.  Just as clearly as you claim to.  So what do you expect us to do?"

              *goto nooneleaves
          *else
            "$!{addressc}: the idea that we have to give guest-right to an enemy is groundless folly.  Stand in kenon.  Cling only to what you must believe.  Surely you see that that doesn't include this mad excess of hospitality."
            *label stubbornsilent

            They remain stubbornly silent.  
            *if (cha = 2)
              Your extraordinary charm was enough to get them to accept the practice of kenon, but now you sense that they're dangerously close to deciding that your smooth tongue has led them into blasphemy.
            *if (bred_here) and (lead != "Breden")
              *set bred_lead +2
              Only when Breden comes to your aid, arguing passionately that these so-called "guests" were too dangerous to live, do the ${whend}s relent.  "If you think there's something in the ${kuria}'s words, Breden…well, we'll consider it further," one growls.

              "Good—but consider it amongst yourselves," Breden says pointedly.  "No need to keep raising bile in the rest of the band with your grumbling."

              At first you don't think they'll take the rebuke from ${xhim}, but they just mutter an abashed apology and file out of the tent.  It's perhaps the clearest sign yet of how Breden's authority in the band has been growing.
              *goto hectoratk
            One of them finally growls, "If kenon strips away guest-right, ${kuria}…maybe you're emptying your mind of too much.  I can't believe that it's right to murder a passing stranger.  Not even in kenon."

            *goto nooneleaves
        *if (religion < 11) #I tell them they're right—but that an Eclect stands outside the normal rules.
          "Reflect on the stories in the Codex, ${addressc}," you implore them.  "The Angels call a Chosen when the existing rulers have betrayed their trust.  The normal rules of Order do not–must not–apply to this sort of Chosen.  The Angels call us to break the old powers through extraordinary measures.  And I ask you to trust me that—in this case—those strangers needed to die."

          *goto shiftuncom
        #I ask them to stop stirring up discontent and reflect on whether they're sure they're right.
          *if religion < 11
            They glance at each other with uncomfortable frowns.  "Eclect…it sounds like the Angels haven't spoken anything to you on this," one woman says gruffly.  "So why should we rethink what Canon tells us, if you've not heard anything new?"

            You furrow your brow, recalling that these were some of the outlaws who most enthusiastically acclaimed you as Chosen.  "You might decide it's not so simple—that those of us who protected the rebellion by killing the noble have the right of it.  Is my judgment so easy to dismiss?"

            "We know what's right on this, ${kuria} ${fname}." The speaker for the dissidents shakes her head, looking disappointed.  "Tell us if the Angels say differently.  We'll reflect then."

            In her hard dark eyes, you see an alarming readiness to disbelieve.  You dismiss them without another word, 
            *if religion < 5
              unwilling to risk your credibility on a feigned Angelic revelation.
            *if religion > 3
              and spend the next hour vainly imploring the Angels to send you a revelation.
            *goto nooneleaves
          *elseif religion < 21
            You summon the dissidents to your tent.  "Listen.  Before you keep raising the bile of the band…stop and listen to the Angels."  

            One of the ${whend}s immediately retorts, "It's the Angels who say that murdering a stranger's damnable, ${kuria}!"

            "You heard that by listening to Their voices in your soul?  Or is it just what you've always been told—by priests, nobles, Karagonds?"  You shake your head in disappointment.  "Of course they'll say that all travelers need to be protected by guest-right, without exception.  They know their enemies can't reach them in their homes; so they try to make us afraid of harming them when they travel.  Meanwhile, do you truly think guest-right would keep them from harming a traveling peasant?"

            They exchange uncomfortable glances.  "$!{kuria}…"

            "Think on it.  Go away and listen, and consider whether what you've been echoing around the band is truly the voice of the Angels—or just the voice of the Ecclesiasts."
 
            The grumbling stops after that meeting.  You don't know what the dissident ${whend}s hear from the Angels in their hearts, but one way or another, it seems to sap their confidence in criticizing you. 
            *goto hectoratk
          *else
            You summon the dissidents to a meeting in your tent.  "First, step away from what you've always been told was the Angels' will.  Bathe your minds in the openness of kenon."  They scowl and shuffle their feet through the long moment of silence.  "Now reflect: who benefits from the idea that all travelers are always protected by guest-right?"

            "Everyone who's ever been a stranger on any road," one of the ${whend}s growls.

            "Truly?"  You shake your head chidingly. "So guest-right would keep a noble from harming a traveling peasant?"

            The outlaws share uncertain glances.  One finally says, "It ought."

            "But it doesn't.  A peasant has no more protection outside her home's walls than within them.  Now, the nobles, priests, Karagonds…they're safe behind their walls.  They know their enemies can't reach them there.  So they try to make us afraid of harming them when they travel, and they put the authority of the Angels behind it."  You find their reluctant eyes each in turn, demanding their attention and assent.  "It's one of the lies that keeps them safe.  This mad excess of hospitality, extending it even to enemies…it's groundless folly.  And the calm of kenon should free us from it."
            *goto stubbornsilent
        #I stand aloof from the argument.
          *label nooneleaves
          No one leaves the band over the issue—they've just enough loyalty for that.  But morale plunges among both the dissident ${whend}s and those who disagree with them.
          *set morale -10
          *set notthere true
          *goto hectoratk
    *elseif religion < 0
      Unfortunately, having failed to convince them of your religious vision, you're in no place to intervene in the argument.
      *goto nooneleaves
    *else
      The
      *goto aloofrel
  Though you think it best to let the argument die down without your intervention, the 
  *label aloofrel
  fierce quarrel reminds you of the power that the Word of the Angels has over your band.  You may have led them away from the Ecclesiasts, but many are still hungry for guidance.
  *if not(notthere)
    You can't help thinking again about Linos's offer.
  *label dareclaim
  Do you dare to claim some of the authority that the Ecclesiasts have to interpret Canon?
  *goto foundchoice
*elseif horion = 10
  Over the next few days, you can't help noticing how many of your bandits are trying in small ways to carry on the rituals of Xthonos, even in the absence of any Diakon or Ecclesiast—little dust-swabbing ceremonies and invocations with stones and ash.  They crave assurance that the Angels are on your side.

  You're uncomfortably aware of how vulnerable your authority would be to any priest who promised them that assurance.  Not for the first time, you wonder whether there's anything you could do to meet their needs without going through the
  *if skepreal <= 50
    desperately compromised
  *if skepreal > 50
    lie-peddling
  Karagond clergy.
  *goto dareclaim
*elseif horion > 10
  Back in camp, the word spreads quickly that you released a noble and his retainer rather than killing or ransoming them.  You're aware that 
  *if not(rad_mutiny) and (winterfail != 1)
    a vocal minority in the band have begun to question your leadership, 
  *if (rad_mutiny) or (winterfail = 1)
    much of the band has been questioning your leadership since the winter,
  and this adds fuel to the fire.  "Is ${he} truly hard enough to beat the Keriatou and the Karagonds?" you overhear
  *if (demerre = 3)
    Ora
    *goto sayoneday
  *elseif (e_rel < 1) and (elery > 0)
    Elery
    *goto sayoneday
  *elseif (bleys = 11)
    Bleys
    *goto sayoneday
  *else
    Radmar
    *goto sayoneday
  *label sayoneday
  muttering one day to a small crowd of other outlaws.

  Thinking of ways to reinforce your authority, you reflect on your many devout followers who try in small ways to carry on the rituals of Xthonos.  They crave assurance that the Angels are still on your side.
  *goto dareclaim
*else
  In the wake of your encounter with Horion and Linos, you consider once again the power that the Word of the Angels has over your band. Former helots and outlaws have every reason to hate Ecclesiasts—and yet there was a reverence in the way most looked at and spoke to Linos.  You wonder whether there's a way to harness some of that authority for your rebellion.
  *goto foundchoice
*label foundchoice
*set notthere true
*choice
  #Yes—I want my band to follow me as the Chosen One of the Angels.
    *set religion 1
    The sacred Codex includes many stories of the times the Angels called an "Eclect," a Chosen hero who heard Their voice and restored Order to a corrupt or decadent kingdom.  Several of the books of the Codex were written by Eclectoi or their closest companions.

    Of course, for the last few centuries, the only purported Eclectoi have been the Thaumatarch and his Nine archmages.  Every Ecclesiast you've known has heavily emphasized this fact.  It's past time the Angels called someone else.

    "I am the Eclect of the Angels," you whisper to yourself.
    *choice
      #And I believe it.
        *set religion 5
        *gosub iameclect
        *goto foundreligion
      #Who knows—it might even be true.
        *set religion 3
        There's no concrete evidence that the Angels have Chosen you or anyone else in your rebellion.  
        *gosub maybeeclect
        *goto foundreligion
      #I'm not, of course.
        But the power the idea will give you is too strong to deny.
        *goto foundreligion
  #No—but I want them to believe that we can all hear the Angels, freeing them from the hunger for Ecclesiastic authority.
    *set religion 11
    Everyone in the band was raised to believe that the Thaumatarch was the Chosen of the Angels—the "Eclect"—with a unique ability to hear the divine voice.  But why would you claim a title which has been so tainted by the Karagonds?

    Instead, over the course of the winter you've been increasingly drawn to the idea that each of your followers should listen for the voice of the Angels within their own hearts.  That will free them from the authority of the Ecclesiasts and any so-called Eclect.
    *choice
      #And they'll find the true voice of the Angels there, just as I have.
        *set religion 15
        *set skepreal %-20
        *set skep %-10
        Delighted awe floods through you again at the idea.  A year ago, you'd have thought it blasphemy. Now, for the better part of an hour you find yourself trembling, filled to overflowing by the glorious truth. A thought resonates clearly through your mind: [i]This is the gift of the Angels to every human soul.   This is the message I was sent to bring.[/i]
        *goto foundreligion
      #I'm not quite sure if it's true—but I'm sure it's less wrong than the Ecclesiasts.
        *set religion 13
        *set skepreal %-10
        *if arrog > 0
          The idea that helots can perceive the Angels' Order for themselves sits uneasily with you—but better that than to keep them in thrall to misguided Ecclesiasts.
        *if arrog < 1
          You and your followers certainly won't misconstrue the will of the Angels as horribly as the priests have done.
        *goto foundreligion
      #It's nonsense, but it's what I need my followers to believe.
        What's important is breaking the hold the Ecclesiasts have on them—setting them at odds with the priests and freeing them from the lingering threat of Ecclesiastic condemnation.  You're confident that you and your chosen leaders can keep order without a priestly hierarchy.
        *goto foundreligion
  #No—I could lose them all by meddling with religion.
    *goto hectoratk

*label foundreligion

*if religion = 0
  *bug founding religion with no religion 
*if religion < 21
  The next morning, you have the whole band assemble before moving camp.
*if religion < 10
  *if linbless
    *label linosbl
    *set cred_p +20
    Ecclesiast Linos
    *if linbless
      joins
    *if not(linbless)
      hurries to join
    you on the rocky outcrop overlooking your followers.  "Children of Shayard and Wiendrj!" he shouts, his voice strikingly resonant for his tall, wiry frame.  "For thirty years now, I have served as a vicar of the Angels on earth.  And in keeping with my oath of conformity, I have always sought to obey the will of the Angels' Eclect.
    
    "I had been taught, like you, that these Chosen Ones were Thaumatarch Kleitos and his Nine, heirs to the Angelic Talismans.  But in my first decade of service, I saw that this could not be.  The injustice, the brutality, the exploitation of the provinces by their merciless Hegemons—how could these be hallmarks of the Chosen?  No!  If ever the favor of the Angels rested on the Karagond usurpers, it passed from them long ago.
    
    "Yet—could I believe in a world without Eclectoi, a world abandoned by Angels?  May it never be!  I told myself the calling had surely found another place to rest.  So for twenty years, I have sought those to whom it has passed.
    
    "For the past ten years, I sought it in Grand Shayard, in the heart of power.  But the closest I found there was this man," he gestures to a diffident-looking Horion, "who speaks as much truth about the evils of the Hegemony as anyone can and live.  And for all his boldness, for all the joy I have found in his service…no, I could not persuade myself that he was the Eclect.
    
    "I had almost given up hope.  Yet I find the voice of the Angels singing to me in the most improbable of places."  His tone is all awe and fervor, without any trace of incredulity.
    *if linbless and ((simz_here) and (s_rel < 9))
      Out in the crowd, you see ${simon} gasp, ${zhis} face coming alight with the ecstatic realization.
    "Far from any other priest. Among outlaws. On the very edge of Xaos. Here I have found, at last, the Chosen to whom my vows bind me."
    *page_break
    *if not(linbless)
      As your shocked followers fall silent again,
    *if linbless
      Ignoring the excited babble that emerges from your followers, 
    Ecclesiast Linos turns to you.
    *if hor_rel < 10
      His continuing fear of you is obvious in small flickers of his expression, but his voice and overall posture betray nothing but reverent joy.
    "${fname} ${lname}.  Clasp yourself to Xthonos's solid earth."  You kneel at once and place your hands on the outcrop, keeping your face upturned.  The priest's voice echoes off the cliffs behind you, as if the stones themselves were joining the acclamation. "Before the Angels we serve: will you accept this solemn name of Eclect?  Will you heed the voice of the Angels and advance Their blessed Order, even unto death?"
    
    "I will ever answer Their call," you reply steadily,
    *if religion = 1
      keeping your true feelings about the charade sealed away.
    *if religion = 3
      wondering whether you'd know it if you heard it.
    *if religion = 5
      despite the ecstatic tears that streak your face.
    "Mindful of my own unworthiness, but confident in Their power."
    
    Linos
    *if hor_rel > 15
      smiles, then
    *if hor_rel < 16
      swallows hard,
    then dips a finger into mud and traces a helix on your forehead.  "Rise, Eclect of the Angels."
    
    You turn away from the priest and discover a field of kneeling outlaws.  Some are weeping
    *if religion = 5
      like you
    *if (simz_here) and (s_rel < 9)
      *if religion = 5
        and 
      *if religion != 5
        like
      ${simon} 
    with devotion, others
    *if kal_here
      like ${kalt}
    are stone-faced or doubtful, but not one has kept their feet.
    *if winterfail > 0
      *gosub rememberwinter
    *if not(linbless)
      The complainers have been quelled.
      *set linbless true
    *gosub outreach
    *goto numberarr
  *if not(linbless)
    *if cha < 2
      You stand atop a rocky outcrop and tell them that a vision has come to you—that you are the Angels' Eclect, Chosen to unseat the Thaumatarch.
    
      There's a moment of stunned silence.  
    *if cha = 0
      Then one of the children bursts out laughing.  Within seconds, half the band is convulsing on the ground.  The contrast is simply too great between your grandiose claims and the humble reality—both of your circumstances in the wilderness
      *if winterfail > 0
        (especially during the winter catastrophe)
      and your own charisma as a leader.  
      *if (simz_here) and (s_rel < 9)
        ${simon} stares at you in anguish, clearly wanting to believe…but even ${zhis} faith in you can't survive the derision of the whole band.
      Many of the outlaws are drifting away even before you make yourself heard again.
    
      *if religion = 5
        [i]But…I[/i] am [i]Chosen![/i] You've never known such fury or humiliation. [i]One day…one day they'll see, damn them.[/i]
      You stiffly dismiss the band and 
      *set morale -5
      *if not(notthere)
        descend to Horion and Linos.  The Ecclesiast is shaking his head in despair.  However eloquent he might be, no words could salvage this disaster.
      *if notthere
        stalk away.
        *goto hectoratk
      *goto notchosen
    *if cha = 1
      Your followers clearly don't know what to make of such a grandiose claim.  Some
      *if (simz_here) and (s_rel < 9)
        like ${simon}
      are staring at you with a new kind of hope, but many more look dubious or openly scornful.  Murmurs spread rapidly across the group, and you hear "blasphemy" uttered more than once.
    
      *if notthere or (horion <= 0)
        *gosub blasphemy
        *goto hectoratk
      Ecclesiast Linos catches your eye pleadingly.
      *choice
        #I give him a grudging nod.  Let him acclaim me, then.
          *goto linosbl
        *if (bred_here) #No.  I turn to Breden, hoping ${xhis} charisma can bring this off.
          Breden's eyes widen in disbelief, and ${xhe} gives a curt shake of ${xhis} head.  
          *if bred_heart < 10
            "I can't do that, ${fname}.  This isn't something I'll lie about."
          *if bred_heart >= 10
            "You're mad, ${kuria}.  I'll not blaspheme for you."
          
          *if religion = 5
            "But it's true!" you plead.  "Breden, I swear it.  I've felt their call."
          
            Breden's eyes change as ${xhe} sees that you really do believe it—${xhis} anger giving way to some kind of fear.  "No,
            *if bred_heart >= 10
              ${kuria}
            ${fname}.  Whatever you've felt, whatever you believe…No."
          *choice
            #Damn it. I beckon Linos to my side.
              *goto linosbl
            #No—I refuse to make myself dependent on an Ecclesiast.
              *goto notbeholden
        #No.  I'll not be beholden to the priest.
          *label notbeholden
          Grumbles and doubts soon win the day in the crowd of outlaws.
          *gosub blasphemy
      *label notchosen
      *set religion -50
      With the possibility of being acclaimed as Chosen out of reach, you consider what to do with your two ${guest}s.
      *goto whattodowt
  *if cha = 2
    You find a perch on a rocky outcrop and raise your hands for silence.  "Over the winter, as we fought for each bite, each breath, I often found myself asking, 'where are the Angels?'"  Some outlaws nod at once. Others look nervous or wary.  "Do They watch injustice and do nothing?  Do They not Choose servants to aid humanity—and if so, where are the Chosen?
    
    "The Thaumatarch and his servants have an answer.  They claim that they are the Eclectoi, like the great heroes of old.  They claim that they have been Chosen by the Angels to establish the Order of Almighty Xthonos among humanity.  They claim that the Hegemony is this Order.
    
    "It cannot be true.
    
    "For my part, each time despair gnawed at me, a thought in some corner of my mind rebuked me: [i]How can you, of all folk, ask what the Angels are doing to bring justice?[/i]  And as we reached spring, this voice grew stronger, saying, [i]The Angels have guided your steps and preserved you, when to rights you should have been Harrowed by the Theurge.  They have raised you up as a leader of free folk and brought you through the winter alive.[/i]
    
    "I hear the voice saying: [i]How can you ask, where are the Angels' Chosen?  How can you ask who is Eclect?[/i]"  A low hum ripples across the crowd as the first few take your meaning.
    *if not(notthere)
      You see Horion shaking his head bemusedly, and Ecclesiast Linos's bitter scowl.
    "I hear the voice: [i][b]You[/b] are called.  [b]You[/b] are Chosen."
    *page_break
    As the gasps and murmurs become an uproar, you raise your hands and voice in
    *if religion = 1
      feigned
    *if religion = 3
      an ecstasy you almost feel.
    *if religion = 5
      heartfelt
    *if religion != 3
      ecstasy.
    *if (simz_here) and (s_rel < 9)
      Out in the crowd, you see ${simon} shouting, "Yes!" and weeping with joy.
    At a time like this, you can sense your words flying like sparks into the kindling of your followers' hope. "[i]Straighten the paths which the oppressors have bent.  Shatter the reign of disorder and injustice.  Reclaim the authority that the Hegemony has usurped.  In the name and power of Xthonos and Its Angels.[/i]"
    
    Zvad is the first to kneel; the rest are close behind.  Some of your outlaws are weeping
    *if religion = 5
      like you
    with devotion, a handful
    *if el_here and (e_rel < 10)
      like Elery
    are stone-faced or dubious, but not one has kept their feet.
    *if winterfail > 0
      *gosub rememberwinter
    *gosub outreach
    *label numberarr
    *set skep %-50
    *set morale +30
    *set epithet "the Eclect"
    *set eclect true
    *achieve eclect
    "…know that however great the numbers arrayed against us, we will prevail.  The Power that guides and fights for us is that which moves the celestial spheres; how can any mere Theurge hope to stand against it?"
    *if linbless
      *choice
        #I allow hieros Linos to lead us in the Sacrament of Compassion.
          *goto loudintone
        #I want to lead the Sacrament myself.
          As the Ecclesiast opens his mouth, you speak over him: "The false priests of the Hegemony despise us as a rabble to be crushed.  But you will enjoy a glorious blessing that neither they nor Phrygia Leilatou herself has ever known, ${addressc}.  You will receive the Sacrament from the hand of the Angels' own Eclect!"  Linos steps away from you, face expressionless.
          
          *goto ileadlit
        #I want to lead my followers in a new Sacrament that I've devised.
          You've long felt dissatisfied with the Sacrament that calls you dust of dust.  Earth is a symbol of Almighty Xthonos, but also of lowliness; it's well known that the human soul is a blend of the other, lighter elements.
          *if religion = 5
            Now you're sure that your dissatisfaction was an Angelic gift, leading up to this moment, to the revelation of a new and more fitting Sacrament.
          
          As the Ecclesiast opens his mouth, you speak over him: "And as your Eclect, ${addressc}, I tell you a new thing.  Because the false priests of the Hegemony have abused the dust of Xthonos, twisting its meaning to degrade 
          *if arrog < 1
            you 
          *if arrog > 0
            us all
          as dirt…we shall no longer give or receive the Sacrament in this element.  The soul is not earthy.  The Angels wish 
          *if arrog < 1
            you to remember that you are free souls.
          *if arrog > 0
            all free-souled folk to know it and rejoice.
          We are wrought of air and fire, and free-flowing as water.  Why should we think only of dust when we come before Them?"
          *if (cha = 2)
            Linos's eyes are wide and horrified, but at the near-unanimous cheering of your band he holds his tongue.
            
            Rather than earth, 
            *gosub sacramental
            Your followers mill about at the end of your new Sacrament, aglow with elation.
            *goto amongn
          *if (cha < 2)
            
            Uneasy murmurs break out across the band, and Linos claws at your shoulder.  "This…you must unsay what you have said, ${addressu}.  An Eclect may not blaspheme."
            
            "Who may tell an Eclect what is blasphemy?" you counter.
            
            The priest's eyes are fierce beneath his thick brows.  "The one who recognized ${him}."
            *choice
              #He's right.  My authority right now rests on his word.  "Very well."
                Pushing back the bitterness, you wave your hands for silence.  "Do not misunderstand me, ${addressc}.  I do not say that we shall abandon the blessed Sacrament.  But at the end, let us breathe deep of the air, feel the fire and water within us…and remember that we are more than just dust."
                
                Your followers look relieved.  Hurrying to the fore,
                *goto loudintone
              *if (religion = 5) 
                #No.  This is the will of the Angels.
                  "You are in error, hieros."  You try to put all your desperate conviction into your eyes and voice. "This is revelation, no mere whim."
                  
                  Linos shakes his head once, curtly.  "It cannot be."
                  
                  *goto no_newsac
              #No.  I'll not give over to any Ecclesiast.
                 *label no_newsac
                 Turning back to the troubled crowd, you cry, "We must have a new Sacrament, one befitting the elements of the soul.  So say the Angels!"
                 
                 *gosub blasphemy
                 *goto visfail
      *label loudintone
      Ecclesiast Linos loudly intones, "All praise to the Angels of Xthonos," and the band thunder back, "Mighty Angels, show us mercy," pouring their zeal into the
      *if diakon <= 2
        Sacrament of Compassion.  As he continues the liturgy,
      *if diakon > 2
        sacramental liturgy.  Like the Diakon who visited you earlier, 
      Linos pointedly dispenses with the usual line invoking Xthonic vengeance on the rebel.  Instead, he calls out, "To the oathbreaker?" 
      
      "Vengeance!" comes back the roar. 
      
      "But to the loyal?" 
      
      "Mercy."  Every eye is fixed on you; no one mistakes the priest's intent.
      
      *if diakon > 2
        When the Sacrament is finished, your followers' faces radiate joy.
      *if diakon <= 2
        "To the murderer—vengeance.
        *line_break
        But to the life-giver—mercy.
        *line_break
        To the thief—vengeance.
        *line_break
        But to the generous—mercy."

        The litany goes on at some length, covering all the main forms of chaotic and orderly behavior, while Linos walks up and down among the kneeling rebels, releasing fistfuls of dust over their heads.  Afterward, their dirt-smudged faces radiate joy.  Not only are they cleansed, but they have a priest's word that their uprising is led by the Angels' representative on earth.
      *label amongn
      *gosub amongnations
      
      *gosub pinquery
      Your outlaws turn to the routine of striking camp with a new passion and efficiency; the excited chatter and oft-repeated word "Eclect" seem not to distract the band from their purpose.  
      
      You're soon on the trail, contemplating what to do with this useful Ecclesiast and his master.
      *goto whattodowt
    The little crowd responds in a thunder of praise, assent, and wordless elation.  For the moment, most of your followers forget their illness and weariness.  For the moment, swept along by their faith in the Angels and their admiration of you, they are already victors.  
    
    Now you want to bring them together around shared words: a liturgy to channel their incoherent energy into a common vision.
    *gosub liturgy
    *goto ftpm
  *goto whattodowt
*elseif religion < 21
  *set cred_p -20
  You stand beside a stream in a gently sloped dale, where your voice will carry up to the outlaws around you.  
  
  *if not(notthere)
    "Yesterday, Ecclesiast Linos offered to acclaim me as the Angels' Eclect."  As your followers react to your announcement with shock or mirth, the priest's face remains impassive.  "To be fair to him, it wasn't just to save his life.  He thought I would say yes.  And for a moment, I was tempted.  After all, I can hear Angels."

    The clamor 
  *if notthere
    "I've heard many of you lament the fact that we have no Ecclesiast among us." A murmur rises from your followers—scornful from some, mournful from others. "No one to tell us which way the Angels want us to walk.  No one to reassure us that we're still within Xthonos's sacred will.  And I know some of you have wondered whether I feel the same lack.
    
    "Why should I?  I can hear the Angels as well as any priest."
    
    The hum of conversation
  comes to an abrupt stop.  Your bandits stare suspiciously at you and uneasily at each other, wondering what hubris or blasphemy you're about to utter.
  
  You press on boldly:
  *if cha < 2
    "And you can.  And you can.  We all can."  You try to get them to see the vision that came to you so clearly
    *if not(notthere)
      during your confrontation with Linos,
    *if notthere
      yesterday,
    but when spoken aloud it sounds
    *if aristo
      prosaic and uninspiring. 
    *if helot
      frankly a bit daft.  
    "We are all Eclect!" The crowd's mood soon shifts to boredom, or worse, turning against you.
    *if cha = 0
    
      *gosub blasphemy
      *label visfail
      *set religion -50
      
      *if notthere
        The collapse of your vision leaves you trying to repair your threadbare credibility while hoping for some chance to regain the band's confidence.
        *goto hectoratk
      *if not(notthere)
        Still smarting from the failure of your vision, you consider what to do with your two ${guest}s.
        *goto whattodowt
    *choice
      *if (bred_here) #I cast a glance to Breden, hoping ${xhis} charisma will succeed where I've failed.
        *if (lead = "Breden") and (orders != "watch")
          Breden tries to back you up as best ${xhe} can—but in this case, the aggrieved ${whend}ish outlaws are even more suspicious of ${xhim} than they are of you.  "What is this?" one of them snaps.  "Is this all about justifying your murder of those strangers, Reaper?  Is that what you think the Angels tell you in your heart?"

          *gosub blasphemy
          *goto visfail
        *if bred_heart >= 10
          $!{xhe} raises ${xhis} hands in denial.  "I don't know what you're on about, ${kuria}. Best say what you mean to say."
            
          Scowling at ${xhim}, you turn back to the unsympathetic outlaws.
          *gosub blasphemy
          *goto visfail
        *set bred_lead +3
        *set bpreach true
        "I think I understand, ${kuria}," Breden offers, in a voice that carries to the edges of the dale. You certainly hope ${xhe} does, after the time you spent talking about it with ${xhim} yesterday.
        *gosub canonvis
        *if not(notthere)
          Ignoring the venomous glower of Ecclesiast Linos, 
        Breden turns to you.  "Is that what you were trying to say, ${fname}?"
        
        "The very thing," you reply gratefully.
        *gosub canonvis2
        
        "This is the message we are meant to bring," Breden cries out, visibly impassioned by your challenge—and you can see ${xhis} conviction swaying the band.
        *if kal_here
          
          "You're saying, the Ecclesiasts…"  ${kalt} springs forward, all ${zhis} sullenness swallowed up in fervor.
        "We don't need them."  
        *if kal_here
        
          "Damned right we don't," Breden roars.
        $!{xhe} 
        *if not(notthere)
          points a stern finger at Linos, who looks as if only self-preservation is keeping him silent.  
        *if notthere
          pauses, repeats that sacrilege, then does it again and again until it begins to take on the ring of truth.
        "We know the meaning of Canon well enough.  We don't need go-betweens to tell us the way of the Angels."
        
        "Or to offer us Sacrament," you add firmly.  A doubt flickers across Breden's face, but
        *if kal_here
          ${kalt} is enthusiastically leading a cheer of assent, and
        ${xhe}'s poured too much of ${xhis} own credibility behind you to gainsay you at this moment.  $!{xhis} nod quells many of the other doubters in your band.
        *if winterfail > 0
          *gosub rememberwinter
        *achieve innervoice
        *label sacpick
        *choice
          *if (diakon > 2) #I want to lead a Sacrament of Compassion myself.
            *goto saccom
          *if (diakon <= 2) #I want to lead a Sacrament of Compassion—the familiar monthly ceremony of forgiveness.
            *label saccom
            *gosub outreach
            *gosub angven
            *choice
              #I stick closely to the traditional liturgy of punishment and mercy.
                *label ileadlit
                It's hard to describe the feeling you get as you stand before your band and call out the words, "All praise to the Angels of Xthonos"—the liturgy you've heard a hundred times from
                *if aristo
                  an Ecclesiast.
                *if helot
                  a Diakon.
                An intermingled shock of fear and exhilaration runs through you, combined with a giddy awareness of power.
                *if diakon <= 2
                
                  "To the murderer—vengeance.
                  *line_break
                  But to the life-giver—mercy.
                  *line_break
                  To the thief—vengeance.
                  *line_break
                  But to the generous—mercy."

                  The litany goes on at some length, covering all the main forms of chaotic and orderly behavior, while you stride up and down among your kneeling rebels,
                *if diakon > 2
                  You are the one speaking the sacred words, you are the one
                releasing fistfuls of dust over their heads.  
                *if cha > 0
                  They leave with faces streaked with tears as well as dirt.  Caught up in the mood of your meeting, they know themselves to be the true servants of the Angels on earth.
                
                *goto ftpm
              #I follow the Sacrament, but amend some of the words to better fit our situation.
                *gosub liturgy
                *goto ftpm
          #I've an idea for an entirely new ritual to replace the old Sacrament.
            *gosub outreach
            *gosub angven
            
            "And because the false priests of the Hegemony have abused the dust of Xthonos, twisting its meaning to degrade 
            *if arrog < 1
              you 
            *if arrog > 0
              us all
            as dirt…we shall no longer give or receive the Sacrament in this element.  The soul is not earthy.  The Angels wish 
            *if arrog < 1
              you to remember that you are free souls.
            *if arrog > 0
              all free-souled folk to know it and rejoice.
            We are wrought of air and fire, and free-flowing as water.  Why should we think only of dust when we come before Them?"
          
            Rather than dirt, 
            *gosub sacramental
            
            As with the Xthonic rite, alongside the elements, you want to use a spoken liturgy to bring people together.
            *gosub liturgy
            *goto ftpm
            *label angven
            "…the Angels Themselves call us to vengeance; the Angels Themselves promise us mercy.  Do we need an Ecclesiast to echo Their words to us in Sacrament?  Does a promise of the Angels only have power if an Ecclesiast says it over again?"
            
            Of course, the answer you all grew up with was an unequivocal "[i]Yes[/i]."
            *if cha = 1
              And in the uncomfortable silence you think some of your more pious outlaws are going to offer it. But Breden adds a perfectly timed, perfectly incredulous, "Does it?" and
            *if cha = 2
              But swept along by the beautiful
              *if religion = 11
                feigned
              conviction in your voice,
            the crowd shouts, "No, ${addressu}!"
            *return
        *label ftpm
        *if notthere
          *goto hectoratk
        *page_break
        When all but a handful of your flock have left, you look to your ${guest}s. Linos just stares, visibly appalled—but you think you see something more in his face, as well.  A doubt?  Uncertainty as to whether, after all, this might not be the Chosen way?  For his part, Horion looks utterly fascinated but uneasy.  
        
        You consider again what you're going to do with these two.
        *goto whattodowt
      *if not(notthere) 
        #I turn reluctantly to Linos.  Can the priest salvage this mess?
          The tall, wiry Ecclesiast shakes his head in disgruntlement, but his voice is deep and serene. "My children…your ${kuria} is trying to describe the voice of a rightly ordered conscience.  It is indeed true that…in this sense…the Angels speak to each one of us."
        
          "Well, didn't need to be told that, did we?" grumbles a bandit.  Still, the majority of your followers seem reassured that their leader hasn't launched ${him}self so far into soul-endangering territory that a priest can't (or won't) rescue ${him}.  They leave the dale and retreat to the familiar routine of striking camp.
          *set morale -2
          *goto visfail
      #I appeal one last time to the band myself.
        *gosub blasphemy
        *goto visfail
  *gosub canonvis
  
  You continue,
  *gosub canonvis2
  *page_break
  Your followers blink at each other, some astonished, some fearful, a few mocking—but you can see the elation begin to spread from those who believe what they've heard.  

  For the moment, most of your followers forget their illness and weariness.  For the moment, swept along by their ingrained faith and their admiration of you, they believe they are hearing the will of Angels.
  
  "We don't need Ecclesiasts or Eclect to echo the words of the Angels back to us," you declare, arms spread wide, hands outstretched toward the sky.  "And we don't need them to offer us Sacrament, either."  That's something you intend to do yourself.
  *goto sacpick
  *label canonvis
  "We know from Canon what the voice of the Angels sounds like.
  *if helot or bpreach
    It's the voice of conscience that tells us what's just.  It's fellow-feeling and compassion.  It's the sun through the clouds helping us find our way.
  *if aristo and not(bpreach)
    It is the voice of conscience, calling us to justice.  It is the voice of fellow-feeling, moving us to compassion.  It is the moral compass in every heart, pointing us towards Order and away from Xaos.
  
  "The Ecclesiasts tell us that only they and the Eclect can hear that voice.  But is that really true?  They'd have us believe that their great learning 
  *if helot or bpreach
    makes them best able to reckon
  *if aristo and not(bpreach)
    heightens their ability to perceive 
  the Angels' will.
  
  *if helot or bpreach
    "Seems to me their learning is a cloud in front of the sun.  Seems to me they've closed their ears, because they want to make the rulers happy."
  *if aristo and not(bpreach)
    "I say that it has only obscured it.  Their compasses are skewed by the pursuit of power, by compromises with our corrupt rulers."  
  A rumble of assent rises from the outlaws; like most rural folk, their piety toward the Angels is matched by their mistrust of the priesthood.
  *return
  *label canonvis2
  "This is the gift of the Angels to every human soul—great or small.  A helot can hear the Angels' voice just as clearly as any priest or noble.  Look in your hearts and tell me it isn't true!"
  *return
  
*else
  *set cred_p -35
  *set skep %+50
  *if elery > 0
    *set e_rel +2
  Your skepticism is fairly well known to your
  *if temple > 0
    band—especially after you made the priesthood a target in your raids—so 
  *if temple <= 0
    band; 
  when word spreads that you're mustering them for a Sacrament, several of them laugh out loud.  By the time the band actually assembles along the stream bank you've chosen, though, their mirth has faded to apprehension.  What blasphemy might you be about to involve them in?
  
  You offer a wry smile to the band and begin, 
  *if not(notthere)
    "Yesterday, 
  *if notthere
    "Before he left us,
  our guest Ecclesiast Linos offered to proclaim me the Eclect of the Angels."  
  *if not(notthere)
    Every eye snaps toward the priest; his shock-contorted face is all the confirmation anyone would need.  "It's a lie.  But he says it's a necessary lie.  He says that 
  *if notthere
    There's a general gasp of astonishment, and several faces light up with sudden hope. You raise your hands and shake your head in firm negation.  "Make no mistake: he was offering to lie.  But he said it was a necessary lie.  He said that
  without the Thaumatarch's servants to tell us the will of Xthonos, we're living with a kenon—an emptiness.  The void that's left when everything has been removed.
  
  "According to him, that's the choice we face.  A lie, or kenon.  Oppression, or kenon.  Continued submission to the Ecclesiasts…or kenon."  You let the silence stand. Some of the other outlaws edge about nervously, but no one speaks. "And for my part?  I would go empty rather than fill myself with a lie."
  
  *if cha < 2  
    That's when the unhappy murmurs begin.  
    *if int = 2
      To your dismay, they only intensify when you try to explain the ${nere}ish philosophers' account of all things springing from a primordial kenon.  
      *if not(notthere)
        Horion's is the only friendly nod in the crowd.
      
      *comment endif
    You press on, trying to convince your followers that confident embrace of kenon will protect them from the lies of the priests.  But it pushes them farther than they're willing to go.
    *if not(notthere)
      Their eyes turn once again to Ecclesiast Linos, filled with an anxiety you can't relieve.
    *gosub blasphemy
    *goto visfail
  There's a collective catch of breath; now your more devout followers are avoiding your eyes.  You stride out into the crowd, refusing to let them go. "[i]Do not fear it.[/i]  They want us to be afraid of what we don't know.  They want us to flee back to what they tell us: that we'll be well as long as we submit to Karagond rule,
  *if natl > 50
    cast aside our own folkways,
  *if natl < 50
    shut out the wisdom of other lands,
  bend the knee to Ecclesiast and Theurge.  All these lies that lend them power.
  
  "The only safety from their lies…is in embracing kenon."
  *page_break
  "What are you saying, ${kuria}?" 
  *if bred_here
    Breden 
    *if bred_heart >= 10
      growls.  $!{xhis} own hackles are clearly up at your apparent blasphemy.
    *if bred_heart < 10
      asks levelly.  You can see ${xhim} warily trying to decide whether what you're saying is blasphemy.
  *if not(bred_here)
    young Earnn asks uneasily.
  "Surely we avoid lies by embracing truth?"
  
  "The embrace of kenon is the path to truth, 
  *if int = 0
    *if bred_here
      Breden."
    *if not(bred_here)
      Earnn."  
    You nod solemnly, hoping it seems as obvious to the band as it does to you…because you've got no idea how to articulate the idea further.
    *if elery > 0
      Elery gives a sudden, excited nod, as if something just slipped into place in her mind. 
    *if not(bred_here)
      And to your great relief, Earnn swallows, nods back to you, and backs away.  
      
      The
      *goto restoband
    *if bred_here
    
      Unfortunately, Breden seems unconvinced.  "No, ${kuria}.
      *if bred_heart < 10
        You know I'll follow you into any battle…but
      I won't embrace this kenon business.  It doesn't sit right."
      *if elery > 0
        Elery opens her mouth, then looks at Breden and swallows whatever she was about to say.
      
      Having the charismatic former helot oppose you opens the floodgates for less restrained critics.
      *gosub blasphemy
      *goto visfail
  *if bred_here
    Breden.
  *if not(bred_here)
    Earnn.
  Kenon is the discipline that winnows out lies, even when they're louder and prettier than truth.  It leaves standing only the things we cannot doubt."  You walk up to
  *if bred_here
    Breden, grasp ${xhis}
  *if not(bred_here)
    Earnn, grasp his
  hands. "Believe only what you must—that's what it means to embrace kenon.  Believe what is self-evidently true or proven to you, when your mind is cool and your blood steady in your veins."
  *if elery > 0
    
    Elery gives a sudden, excited nod, as if something just slipped into place in her mind. "$!{he}'s right.
    *if bred_here
      Breden.
    Damn me if ${he}'s not."
    *set e_rel +1
  
  Slowly, reluctantly, 
  *if bred_here
    Breden 
  *if not(bred_here)
    Earnn
  nods…and the 
  *label restoband
  rest of the band erupts in awed, unsettled conversation.
  *if winterfail > 0
    *gosub rememberwinter
  *gosub outreach
  "Will you join me on the path of kenon?  This isn't the last time an Ecclesiast will try to ensnare us.  Not to set me up as a false Eclect—they won't be such fools twice."  Now you flood your voice with contempt and
  *if not(notthere)
    menace; Linos's folded arms tighten miserably around his chest.
  *if notthere
    foreboding.
  "Next time, they'll appeal to you, ${addressc}."
  *choice
    #"The priests…"
      *goto psnake
    #"The liars…"
      *set cred_p -5
      *goto psnake
    #"The snakes…"
      *set cred_p -10
      *goto psnake
  *label psnake
  "…will try to get you believing that our rebellion can only succeed when we submit ourselves to their authority.  To their rules.  To their pretense that they alone hear the Angels' voice.  They'll try to entice you back onto their path."  You raise your voice until it cracks.  "This day, this moment, ${addressc}, we need to set our eyes together on a new path.  The one they try to frighten us away from.  The path of truth.  The path of kenon."
  
  "You're telling us to give up the Angels?" 
  *if rescuer = 0
    *if aristo
      helot elder
    Gillian Adze
  *if rescuer > 0
    Ciels
  protests shrilly.
  *choice
    #"There are no Angels.  They're just one of the lies we've been fed."
      *if bred_here
        Breden is only the first to raise ${xhis} voice in outraged denial.
      *if elery > 0
        Elery recoils, her smile shriveling into a grimace.
      Such blatant rejection of Xthonic doctrine is more than your outlaws can take, even from a leader of your charisma.
      *gosub blasphemy
      *goto visfail
    #"No. But you don't wait for the Angels to cook your meals.  I say, don't wait for Them to show us a way to justice."
      *if elery > 0
        *set e_rel +1
        Elery laughs and shouts, "They haven't done it in three centuries—why would they start now?"
        
        While a quarter of the band grumbles at her irreverence, you extend placating hands and say, "The
      *if elery < 1
        "Three and a half centuries have passed with no hint of deliverance from the Thaumatarchy.  The
      Angels have not set us a path to freedom.  It's one we've been left to discover ourselves.  And as we search, the lies of the so-called priesthood of Xthonos are a snare and distraction.  Only kenon will free us."
      
      Some of the outlaws are still wavering, but most
      *goto sweardiak
    #"No, of course not.  Just don't believe those who tell you they know the Angels' will."
      *if elery > 0
        You can see Elery drinking in the message, and meet her eyes as you say,
        *set e_rel +1
      "Empty your mind of the Ecclesiasts' lies…and I promise you, in that quiet place of kenon you'll be far better able to hear the voice of compassion, of truth, of justice."
      
      Most of the outlaws
      *goto sweardiak
  *label sweardiak
  *set oath "kenon"
  *set sweetoath "sweet kenon"
  are slowly nodding now.  Still, you know intuitively that you'll not win them over by words alone.  They'll need some ritual to replace the Sacrament—something just as communal, tangible, and elemental, a reassuring balance to the kenon you hope to fix in their minds.  "So this I swear to you: I will never
  *if diakon > 2
    again
  bring some Diakon to shake dirt over you and tell you that you must be forgiven for rebelling against what the Karagonds call Order.  How dare they?  We are the hope for righteousness.  We are the ones whose compassion matters.  We are not dust!  We are souls wrought of air and fire, free as the water.
  
  "So, ${addressc}, let us not belittle each other with dust."  Instead,
  *gosub sacramental
  No Sacrament is complete without 
  *if diakon <= 2
    shared words.
  *if diakon > 2
    a liturgy of condemnation and redemption.
  *gosub liturgy
  
  Your outlaws return to the routine of striking camp with a new passion and efficiency; the excited chatter and oft-repeated word "kenon" seem not to distract them from their purpose.
  *achieve kenosis
  *if notthere
    *goto hectoratk
  *else
    
    *if pin > 0
      *page_break
    "Eclect of the Angels?"  Linos's whisper behind you is choked and wretched.  "What was I thinking?  This…blasphemous charade is worse than anything concocted by the most depraved of the Nyr."

    Horion clears his throat uncomfortably. "Linos…"
  
    "No.  No, kurios.  Your wilder philosophical speculations are as nothing compared to…this."  The Ecclesiast's eyes glower implacably into yours as you face him. "Before Xthonos I can not stay silent.  Let this monster kill me.  I would rather be a martyr of Xthonos than betray It by my silence now!"

    You contemplate what you're going to do now with the outraged priest and his master.
    *goto whattodowt

*label outreach
You reach out your arms to them and say,
*choice
  #"Sisters and brothers…"  As their equal—as I want them to address me.
    *set addressc "sisters and brothers"
    *if male
      *set addressu "brother"
    *if female
      *set addressu "sister"
    *return
  #"Children…"  As an Ecclesiast would.
    *set addressc "children"
    *set addressm "my son"
    *set addressf "my daughter"
    *if male
      *set addressu "hieros"
    *if female
      *set addressu "hiera"
    *return
  *if (religion < 21) #"Fellow soldiers of the Angels…"
    *set addressc "soldiers"
    *set addressm "soldier"
    *set addressf "soldier"
    *set addressu kuria
    *return
  *if (religion > 20) #"Fellow soldiers of truth…"
    *set addressc "soldiers"
    *set addressm "soldier"
    *set addressf "soldier"
    *set addressu kuria
    *return
  
*label blasphemy
*set religion 0
One of the band's best archers 
*if (theuknown > 4)
  stares at you with haunted eyes.  Then ${xhe} blurts out, "It's true.  You do get your powers from damned Xaos.  You're 
  *if wisard != "Goete"
    no ${wisard}, you're a Goete."  
  *if wisard = "Goete"
    a monster." 
*if (theuknown < 5)
  spits onto the ground and makes a sign against the evil eye.  "Damned if I'll keep following a blasphemer!"
$!{xhe} runs away before you or anyone else can reply, and the meeting breaks up in pandemonium.

When all the arguing is done, the majority of the band continue to accept your leadership. But over the next few days, several dissenters leave in twos and threes.  "And no wonder," your father says acidly.  "If you weren't my flesh and blood, I would leave too."
*if wisard = "Goete"
  *set followers -10
  *set nonkids -10
  *set morale -10
*if followers > 21
  *set followers -15
  *set nonkids -15
*if followers < 21
  *set followers 7
  *set nonkids 7
  *set kids 0
  *if pin > 0
    *set kids +1
    *set followers +1
  *if alless > 0
    *set kids +1
    *set followers +1
*set morale -15
*set skep %-10
*return

*label sacramental
you want your new ritual to be based around the element of:
*choice
  #Water, for cleansing.
    *set sacrament 1
    Bending down to the stream, you bring frigid water up in your cupped hands.  "Let us offer cleansing, each to the other."  
    
    You give Zvad no more than a glance to warn him before you open your hands above his matted black hair.  While he is still gasping from cold and shock, you gesture for him to do the same to you.  Hesitantly, he scoops up water and pours it over your head.  "$!{addressm},
    *if religion < 20
      in the Angels' name:
    show me mercy," you say steadily.
    *if addressc = "children"
      It feels desperately odd to address an older man as if he were your child, but the Ecclesiasts clearly get used to it, and you will too.
    
    "$!{kuria}, show me mercy," Zvad says, 
    *if addressc = "soldiers"
      saluting you.
    *if addressc != "soldiers"
      then stumbles as you shake your head.  "I mean,
      *if religion < 20
        in the Angels' name,    
      ${addressu}, show me mercy."
    
    "Be cleansed, ${addressm}.  Feel the dirt roll from you."
    
    You turn to the rest of the band, spreading your arms in a gesture of invitation.  One by one, they follow your example, lifting water from the stream and murmuring forgiveness to each other.
    *goto whendone
  #Air, for freedom.
    *set sacrament 2
    You spread your arms wide, letting your tattered coat ripple in the breeze.  "Feel the wind, ${addressc}!  Feel its freedom, rushing where it will.  That same
    *if religion < 20
      Angelic
    breath enlivens each one of us.  We are not dust.  We are wind—unstoppable and free.
    
    "So breathe.  Feel the wind within you.  Close your eyes, and breathe deep.  We are wind.  Breathe…Breathe."  The susurrus of
    *set d2n_num followers
    *gosub d2n
    people inhaling and exhaling in unison becomes audible throughout the glade.  "Hark.  Your breath is not yours alone.  As it passes from you, it fills another.  
    
    "We are wind.  We are one band, with one breath, one soul.  And in that shared breath…we know ourselves to be free, ${addressc}.  
    
    "We are wind.  We are mighty.  We are free.  We are one.  We are the
    *if religion < 20
      Angels'
    storm, the bearers of lightning, who scour away oppression before us!"
    
    A handful of your followers have begun weeping in silent ecstasy. Others cry out, "Yes, ${addressu}!" with arms outstretched to you.
    *if addressc = "children"
      It feels desperately odd to have older bandits call you ${addressu}, but the Ecclesiasts evidently get used to it, and you will too.
    *goto whendone
  #Fire, for elevation.
    *set sacrament 3
    You raise one of the band's few oil lamps from just behind your heels, and are relieved to see the tiny flicker persisting at its lip.  "A single flame is weak.  It can be extinguished by the dust.  It strives upward—but who can believe that it was made to rise to the empyrean, higher than any other element?"
    
    Then you raise a dry pine branch and dip its needles into the lampflame.  They ignite with a crackle, sending bright yellow flames into the air.  You nod to Zvad—who you'd earlier asked to set aside enough branches for everyone in the band.
    
    "We are not dust.  We are souls of air and fire.  We were made to rise!"  The outlaws rumble their assent, each passing an unlit torch to the next.  You can see an intoxicating excitement spark from person to person. "We shall spread faster than anyone can extinguish us—and
    *if religion < 20
      by the power of the glorious Angels,
    [i]we shall ascend[/i]."
    
    You turn to Zvad and thrust your brand against his. "$!{addressm}: we ascend!"
    *if addressc = "children"
      It feels desperately odd to address an older man as if he were your child, but the Ecclesiasts clearly get used to it, and you will too.
    
    "$!{kuria}," Zvad says, 
    *if addressc = "soldiers"
      saluting you.  "We ascend!"
    *if addressc != "soldiers"
      then stumbles as you shake your head.  "I mean…${addressu}, we ascend!"

    The blaze spreads from follower to follower, and the same eager shout bursts from
    *set d2n_num followers
    *gosub d2n
    throats: "We ascend!"
    *goto whendone
*label whendone
The reticent are swept along by your conviction and their fellows' passion. 
*if sacrament = 3
  Within moments, the torches are being thrust into the air in unison, over and over.  "WE ASCEND!  WE ASCEND!"

[i]It's done.[/i]  Watching the band perform your crude rite, you feel an incredulous joy judder through you from hair to heels.  It's barely distinguishable from terror.
*page_break
*return

*label liturgy
*if diakon <= 2
  The Sacramental liturgy usually takes the form, "To the murderer, vengeance. But to the life-giver, mercy," and so on.  You've reflected on how to change 
  *if religion < 20
    the old words into something new.
  *if religion >= 20
    this demeaning, contemptible rite into something fitting for a free soul.
  
Today, you begin with
*if religion < 20
  the traditional opening: "All praise to the Angels of Xthonos," and the band thunders back, "Mighty Angels, show us mercy."
  
  Then you shout,
*if religion >= 20
  "$!{addressc}, show each other mercy.
  
  *comment endif
"To the Thaumatarch, we will bring the vengeance of righteousness…"
*choice
  #"…And to all who have benefited from oppression, we will exact retribution."
    *set ruth %+10
    *goto litnob
  #"…But to all who turn away from their oppression, we will show mercy and compassion."
    *set ruth %-10
    *goto litnob
*label litnob
Your reference to oppressors isn't specific enough for some in your band.  Emboldened by your willingness to adapt the liturgy,
*if demerre > 2
  Ora 
*if demerre = 1
  a hulking former helot 
*if demerre = 0
  a one-eyed former helot 
leans forward and shouts, "To the nobles? Who have connived with the Hegemony?"

*if arrog > 0
  [i]Contemptible little rat,[/i] you think. [i]How dare you snipe at your betters?[/i]
Without missing a beat, you shout,
*choice
  #"Vengeance."
    A cheer rises from the band.
    *if kal_here
      ${kalt} is one of the loudest and most enthusiastic voices.
    *if simz_here and (s_rel < 9)
      ${simon} de Firiac gives a small shake of ${zhis} head.
    *if not(notthere)
      Horion is statue-still except for his throat, which pulses as he swallows over and over.
    *set cred_a -10
    *set cred_h +10
    *set cred_y +10
    *set ruth %+5
    *set morale +3
    *goto litpriest
  #"Vengeance—to any who will not repent and join our cause."
    *if aristo
      With you standing there as the example of someone who did join the cause, it's hard for anyone to argue with that.  Your father scowls and shakes his head bitterly.
    *if helot
      The band murmurs uncertainly; the idea of nobles joining the revolt is clearly not one which everyone savors.
    *if simz_here and (s_rel < 9)
      ${simon} de Firiac folds ${zhis} arms across ${zhis} chest and gives a brief nod.
    *goto litpriest
  *if (arrog > 0) #"Vengeance—but to those who stood firm, the rule which is their birthright."
    *set cred_a +15
    *set cred_h -15
    *set cred_y -15
    *set morale -3
    It may not be a popular sentiment among upstart helots, but you won't shy away from it.
    *if kal_here
      ${kalt} just raises an incredulous eyebrow and scowls at you.
    *if simz_here and (s_rel < 9)
      ${simon} de Firiac folds ${zhis} arms across ${zhis} chest and gives a brief nod.
    
    *goto litpriest
  #"Mercy."
    *if not(notthere)
      You see Horion relax almost imperceptibly.
    *if kal_here
      ${kalt}'s scowl is mirrored by 
      *if nonkids > 50
        dozens of 
      *if nonkids <= 50
        many
      other bandits.
    *if simz_here and (s_rel < 9)
      ${simon} de Firiac gives an approving smile and nod.
    *set cred_a +10
    *set cred_h -10
    *set cred_y -10
    *set ruth %-5
    *if demerre > 2
      Ora's lips press bloodlessly against each other, but she says no more—just shakes her head.
    *if cha = 1
      *if bred_here
        Breden's approving nod helps silence any overt dissent in your ranks.
      *if not(bred_here)
        There's a rumble of unhappy dissent in your ranks.
        *set morale -2
    *goto litpriest
*label litpriest
*if not(notthere)
  Looking squarely at Linos, 
*if radmar > 0
  Radmar
*if radmar < 1
  another of your followers 
cries out, "And to the lying priests?  To the Ecclesiasts?"
*choice
  #"Vengeance."
    *if not(notthere)
      Linos shudders once and then regains control.
    *set cred_p -10
    *set ruth %+5
    *goto litmer
  #"Vengeance—to any who will not turn from their lies."
    *if not(notthere)
      Linos's face becomes an implacable mask.
    *goto litmer
  #"Mercy."
    *set cred_p +10
    *set ruth %-5
    *if not(notthere)
      Linos looks astonished and relieved.  
    Your more devout followers appear reassured; others look merely confused.
    *goto litmer
*label litmer
*if elery > 0
  Now Elery Skinner
*if elery < 1
  Yet another outlaw 
cries, "To the merchants who profit from the rule of the oppressor?"
*choice
  #"Vengeance."
    *set cred_m -10
    *set ruth %+5
    You don't have any sympathy for those who have grown fat off the Hegemony.
    *goto litend
  #"Vengeance—to any who won't share their wealth with our cause."
    You don't care if they grew fat off the Hegemony, as long as they support you now.
    *goto litend
  #"Mercy."
    *set cred_m +10
    *set ruth %-5
    The merchants of Shayard have had to survive in an oppressive system, just as you have; you don't intend to punish them for it.
    
    *goto litend
*label litend
When no other voices push in, you run through the rest of the liturgy, promising vengeance to other malefactors and mercy to the righteous.  At last you reach the final adjuration: "So may all who embrace the good receive their just reward…"
*choice
  #"And may the blemish of wrongdoing never be without the beauty of punishment."
    *goto dismissed
  #I change the words.  "And may our mercy kindle compassion in the hearts of wrongdoers, turning them from their ways."
    *set ruth %-10
    *goto dismissed
*label dismissed
Then you ceremonially dismiss your followers.

*if eclect
  *gosub amongnations
  *goto pinquery
*label pinquery
*if pin > 0
  Pin bursts out of the crowd and runs to your side, all eyes and excitement.  "Is it…${kuria}, it's all true?"  You don't hear the least fear in her voice; unlike some of the older bandits milling nervously about the clearing, she's ready to believe without reservation.
  
  You kneel at her side, smiling warmly, knowing that everyone in earshot is listening.  "Never forget this day, Pin.  Outside this clearing, no one knows it yet…but the world just changed.  One day, they'll say that this is where the power of the Thaumatarch was broken.  And you were here.  You witnessed the beginning."  
*return

*label hectoratk
*if addressu = ""
  *set addressu kuria
*page_break
*if (horion <= 0) and not(notthere)
  The murders of
  *if id > 0
    Horion and Linos
  *if id < 1
    the two strangers
  spur one more small crisis in the life of your band.
  *goto guestcode
*set rollover1 randfoll
*set rollover2 id
*set rollover3 horch3
*set rollover4 xroad
*set rollover5 lead
*finish

*label rememberwinter
Many, you're sure, thought at least fleetingly of the catastrophic winter…but the bandits who were completely disillusioned with you left then, and those who remain want desperately to believe.
*return

*label amongnations

"To Shayard!" one of them cries in a loud voice, ecstasy shading into pride.  "The Angels have sent Their Eclect to Shayard!  The glory of Xthonos to Shayard!"
*choice
  #"As the first and truest revelations were given to Shayard," I agree passionately. "Our homeland is Eclect among nations!"
    *set natl %+20
    *set morale -1
    Your band erupts in deafening cheers.
    *return
  #I see the wavering smiles on the faces of my ${whend}ish followers, and say, "As Eclect, I belong to all nations, ${addressf}—not only to Shayard."
    *set natl %-20
    *set morale -3
    There's a hint of disappointment from several of the Shayardenes, especially the embarrassed outlaw who spoke out so loudly.  But to you, the full-throated cheers from the ${whend}s more than make up for it.
    
    *return
  #I just try to steer them back onto safer ground of devotion to Xthonos, rather than being distracted into talk of nations.
    "The glory of Xthonos is over Shayard, and ${whendery}, and all the world," you shout in response. "All glory to Xthonos, and to Its Angels."
    
    *set natl%-5
    You can see that a handful of the Shayardenes are disappointed by your firm attempt to refocus on That Which Is, but their frowns are lost in an outpouring of cheers and prayers.
    *return

*label d2n
*set display_numb ""
*set thousands 0
*set hundreds 0
*set tens 0
*set single 0
*if d2n_num = 0
    *set display_numb "zero"
    *goto finish_d2n
*if d2n_num < 0
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if d2n_num > 999
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if (d2n_num modulo 1) > 0
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if d2n_num < 10
    *set single d2n_num
    *goto single_digit
*label thousands_digit_addition_repeat
*comment leaving this here in case we want to switch the thousands back on
*if d2n_num > 999
    *set d2n_num -1000
    *set thousands +1
    *goto thousands_digit_addition_repeat
*label hundreds_digit_addition_repeat
*if d2n_num > 99
    *set d2n_num -100
    *set hundreds +1
    *goto hundreds_digit_addition_repeat
*if (d2n_num > 9) and (d2n_num < 20)
    *goto skip_tens_and_singles
*label tens_digit_addition_repeat
*if d2n_num > 9
    *set d2n_num - 10
    *set tens + 1
    *goto tens_digit_addition_repeat
*set single d2n_num
*label skip_tens_and_singles
*if thousands = 1
    *set display_numb "one thousand"
*if thousands = 2
    *set display_numb "two thousand"
*if thousands = 3
    *set display_numb "three thousand"
*if thousands = 4
    *set display_numb "four thousand"
*if thousands = 5
    *set display_numb "five thousand"
*if thousands = 6
    *set display_numb "six thousand"
*if thousands = 7
    *set display_numb "seven thousand"
*if thousands = 8
    *set display_numb "eight thousand"
*if thousands = 9
    *set display_numb "nine thousand"
*if ((thousands > 0) and ((tens > 0) or (single > 0))) and ((hundreds < 1) and (d2n_num < 10))
    *set display_numb &" and"
    *goto tens_digit
*if ((thousands > 0) and (d2n_num > 9)) and (((hundreds < 1) and (tens < 1)) and (single < 1))
    *set display_numb &" and"
    *goto tens_digit
*if ((thousands > 0) and ((tens > 1) and (single > 0))) and (hundreds < 1)
    *set display_numb &" and"
    *goto tens_digit
*if (thousands > 0) and ((hundreds > 0) and ((tens > 0) or ((single > 0) or (d2n_num > 9))))
    *set display_numb &","
*if (thousands > 0) 
  *set display_numb &" "
*if hundreds = 1
    *set display_numb &"one hundred"
*if hundreds = 2
    *set display_numb &"two hundred"
*if hundreds = 3
    *set display_numb &"three hundred"
*if hundreds = 4
    *set display_numb &"four hundred"
*if hundreds = 5
    *set display_numb &"five hundred"
*if hundreds = 6
    *set display_numb &"six hundred"
*if hundreds = 7
    *set display_numb &"seven hundred"
*if hundreds = 8
    *set display_numb &"eight hundred"
*if hundreds = 9
    *set display_numb &"nine hundred"
*if ((hundreds > 0) and (tens < 1)) and ((single > 0) or (d2n_num > 9))
    *set display_numb &" and"
*label tens_digit
*if (hundreds > 0) 
  *set display_numb &" "    
*label teens
*if d2n_num = 10
    *set display_numb &"ten"
    *goto finish_d2n
*if d2n_num = 11
    *set display_numb &"eleven"
    *goto finish_d2n
*if d2n_num = 12
    *set display_numb &"twelve"
    *goto finish_d2n
*if d2n_num = 13
    *set display_numb &"thirteen"
    *goto finish_d2n
*if d2n_num = 14
    *set display_numb &"fourteen"
    *goto finish_d2n
*if d2n_num = 15
    *set display_numb &"fifteen"
    *goto finish_d2n
*if d2n_num = 16
    *set display_numb &"sixteen"
    *goto finish_d2n
*if d2n_num = 17
    *set display_numb &"seventeen"
    *goto finish_d2n
*if d2n_num = 18
    *set display_numb &"eighteen"
    *goto finish_d2n
*if d2n_num = 19
    *set display_numb &"nineteen"
    *goto finish_d2n
*if tens = 1
    *bug Should not be reachable
*if tens = 2
    *set display_numb &"twenty"
*if tens = 3
    *set display_numb &"thirty"
*if tens = 4
    *set display_numb &"forty"
*if tens = 5
    *set display_numb &"fifty"
*if tens = 6
    *set display_numb &"sixty"
*if tens = 7
    *set display_numb &"seventy"
*if tens = 8
    *set display_numb &"eighty"
*if tens = 9
    *set display_numb &"ninety"
*if (single > 0) and (tens > 0)
    *set display_numb &"-"
*label single_digit
*if single = 1
    *set display_numb &"one"
*if single = 2
    *set display_numb &"two"
*if single = 3
    *set display_numb &"three"
*if single = 4
    *set display_numb &"four"
*if single = 5
    *set display_numb &"five"
*if single = 6
    *set display_numb &"six"
*if single = 7
    *set display_numb &"seven"
*if single = 8
    *set display_numb &"eight"
*if single = 9
    *set display_numb &"nine"
*label finish_d2n
*if not(np)
    ${display_numb}
*set np false
*return
