*comment Choice of Rebels: Uprising written by Joel Havenstone, copyright 2017.
*comment Using ChoiceScript (copyright 2010 by Dan Fabulich) under the terms of the ChoiceScript license:
*comment  http://www.choiceofgames.com/LICENSE-1.0.txt
*temp votetick 0
*temp votetotal 3
*temp zvote false
*temp bvote false
*temp kvote false
*temp svote false
*temp evote false
*temp rvote false
*temp gvote false
*temp jvote false
*temp avote false
*temp pvote false
*temp korvote false
*temp warvote 0
*temp runvote 0
*temp govote 0
*temp strategy 0
*temp popular 0
*temp wareld 0
*temp runeld 0
*temp goeld 0
*temp eldchoice 0
*temp refused false
*temp pleksecret false
*temp phalangites 240
*temp phal1 0
*temp phal2 0
*temp phal3 0
*temp phal4 0
*temp phal5 0
*temp intel 0
*temp aristroops 0
*temp merchtroops 0
*temp priestroops 0
*temp alastroops 0
*temp yeotroops 0
*temp alltroops 0
*temp allmain 0
*temp theirtotal 0
*temp alastroops_orig 0
*temp phal_orig 0
*temp mainmules 0
*temp theirintel 0
*temp theirmorale 0
*temp theurges 3
*temp radbetray false
*temp kalbetray false
*temp releasepromise false
*temp horhostage false
*if ((horion > 3) and (horion < 10)) or (horion = 2)
  *set horhostage true
*temp linhostage false
*if (horion = 4) or (horion = 5)
  *set linhostage true
*temp spcas ""
*temp ask "ask"
*temp armtwist false
*temp inwoods 0
*temp outkids 0
*temp inkids 0
*temp inadults 0
*temp rangers 0
*temp rangermax 0
*temp housenum 0
*temp hosthem "them"
*temp spouse "wife"
*if male
  *set spouse "husband"
*temp accounting 0
*temp armsale 0
*temp armsalelimit 0
*temp armsfoll 0
*temp spendtick false
*temp intelsale 0
*temp intelsalelimit 0
*temp intest 0
*temp heldonate 0
*temp yeodonate 0
*temp pridonate 0
*temp mulesale 0
*temp muleneed 0
*temp robin 0
*temp morcheck 0
*temp deserters 0
*temp desertkids 0
*temp kidmess false
*temp babysitters 0
*temp cas 0
*temp flanktick 0
*temp flanktotal 0
*temp flanktroops 0
*temp zv_flank 0
*temp rad_flank 0
*temp bj_flank 0
*temp simz_flank 0
*temp br_flank 0
*temp al_flank 0
*temp meh_flank 0
*temp priestfail false
*temp alastfail false
*temp aristofail false
*temp merchfail false
*temp yeofail false
*temp harryloss false
*temp atkboth false
*temp atkboth2 false
*temp harrytick false
*temp snapsand false
*temp kidcas 0
*temp phalcas 0
*temp phaltick 0
*temp armshare 0
*temp morshare 0
*temp supply 0
*temp supplycut 0
*temp consc 4
*temp discreet false
*temp landslide false
*temp wipecut false
*temp cut2 false
*temp martyr simon
*temp mhe zhe
*temp mhis zhis
*temp elrefuse false
*temp radrefuse false
*temp bredvom 0
*temp elsick false
*temp lostem false
*temp plektoi 1
*temp plekkeepers 1
*temp plekreinforce 0
*temp plekfight 0
*temp cavein 0
*temp hostages "hostages"
*temp hdead 0
*temp abler "Terret"
*if rescuer > 0
  *set abler "Algarn"
*temp theuthey "they"
*temp xspouse "lover"
*temp cragprep false
*temp fire false
*temp flee 0
*temp fleelead ""
*temp bred_pris false
*temp yebsac false
*temp swaymtick false
*temp theucatch 0
*temp roundone false
*temp onslope true
*temp savior kalt
*temp savior_he zhe
*temp savior_his zhis
*temp tagmatick true
*temp tobreed "to breed"
*temp bear "bear"
*if xhe = "he"
  *set bear "sire"
*temp breedreason 0
*temp proposal false
*temp bredwed false
*temp bredupset false
*temp aceprop false
*temp bloodcheck false
*temp bloodthem "them"
*temp nonvio false
*temp myownname false
*temp bredrel false
*temp bredconsent false
*temp slowedthem false
*temp earnndead false
*temp glention false

*set sc_foll 0
*if wonfight < 0
  *set sc_foll 900
  *set wonfight 0
  *comment tracking namesake
*if (bred_lover >= 4) or (bred_heart = 3)
  *set bredrel true
*set nonkids (followers-kids)
*if nonkids < 1
  *set nonkids 1
*if zv_here
  *set runvote +zv_lead
*if bred_here
  *set govote +bred_lead
*if el_here
  *set runvote +el_lead
*set warvote +rad_lead
*if rad_mutiny
  *set warvote +1
*if nonkids < 45
  *set warvote -10
*if arms < (nonkids/2)
  *set warvote -3
*if arms > (nonkids/2)
  *set warvote +1
*if arms >= nonkids
  *set warvote +2
*if sybla < 1
  *set warvote -20
*if kal_here
  *set warvote +kal_lead
*if simz_here
  *set govote +simz_lead
*if mules < (followers/25)
  *set runvote -2
*if ((zhe = "he") and (aristo and (kuria = "Captain"))) and (s_rel < 10)
  *set zmilady addressm
  *set zkuria addressm
*if ((zhe = "she") and (aristo and (kuria = "Captain"))) and (s_rel < 10)
  *set zmilady addressf
  *set zkuria addressf
*if sworddonor > 0
  *set rollover2 sworddonor
  *set sworddonor 0
*set gamgee "four"
*text_image chap4.png center Chapter Four: Hounds of Karagon

*if choice_randomtest
  *choice
    #Starting Ch 4, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.
      *goto postchoice
*label postchoice
*if democ < 10
  The tension is palpable among the cluster of outlaws sitting cross-legged in the Leaders' Tent.  Your meeting space feels smaller than usual this morning, resonant not only with the drone of summer mosquitoes but with shifting of seats and clearing of throats.
*if democ > 9
  It's no easy matter to get your 
  *if kids > 2
    *set d2n_num nonkids
    *gosub d2n
    adult
  *if kids < 3
    *set d2n_num nonkids
    *gosub d2n
  outlaws into a single rocky basin where they can see and hear not only you, but each other.  It's all the more difficult when small but intense arguments keep breaking out, drawing in some of your followers while forcing others to rise and hasten away to a new perch.
All around you, comrades who have saved each others' lives exchange wary, mistrustful glances.  

Everyone is acutely aware that the choices you make
*if democ > 9
  in the ${moot}
today represent life and death for your rebellion—and opinions are (to say the least) strongly divided as to which course will yield which outcome.

At your signal, ${deputy} clears ${dephis} throat and beckons for silence.
*if democ > 9
  It takes nearly ten minutes before the last squabble subsides, but eventually ${dephe}'s able to make ${dephis} voice heard.
"Right.  We've weeks left, at best, to prepare before the Archon sends her full force against us.  We need to finally agree what we're preparing to do. So ${addressu} ${lname} has brought us here to discuss it—and none of us will leave until we're agreed on a course of action."

*if democ = 0
  For this critical decision, you've
*if democ = 1
  You've 
*if democ < 2
  *set ask "choose"
  made sure that the most influential people in your little rebellion are here.  Agree with them or not, you need to be able to gauge their proposed strategies and the extent of their support.  If you can get enough of them to agree on the course you choose, it will go ahead. If not, you'll have to defer to the strategy with the greatest support—or risk the collapse of your authority as the rebellion's paramount leader.
*page_break
Your deputy is the first to speak.
*if deputy = "Zvad"
  *set runeld +2
  *gosub zvadcounsel
*if deputy = "Breden"
  *set goeld +2
  *gosub bredcounsel
*if deputy = kalt
  *set wareld +1
  *gosub kalcounsel
*if deputy = simon
  *set goeld +1
  *gosub simzcounsel
*if deputy = "Elery"
  *set runeld +1
  *gosub elcounsel
*if deputy = "Radmar"
  *set wareld +1
  *gosub radcounsel

${deputy} pauses for a moment, then shrugs. "But the ${addressu} no doubt wants to hear from the rest of you before making ${his} decision."  There's a flicker of uncertainty in ${dephis} eyes; perhaps you don't want to hear from everyone. If there's a course you strongly favor, it might be better to just let those who share your view speak.

First, you
*if bred_here
  *set votetotal +1
*if simz_here and (s_rel < 10)
  *set votetotal +1
*if kal_here
  *set martyr kalt
  *set votetotal +1
*if rescuer = 0
  *set votetotal +2
*if el_here
  *set votetotal +1
*if korszata > 0
  *set votetotal +1
*label plansurvey
*if votetick = votetotal
  declare the discussions finished. "It's time to decide."
  *goto whattodo
nod to:
*choice
  *if (zv_here) and not(zvote)
    *hide_reuse #Zvad.
      The big ${whend} stands.
      *gosub zvadcounsel
      He sits down.
      *if zv_lead > 4
      
        You're unsurprised by the number of people nodding along emphatically. Zvad is one of the more influential leaders in the 
        *if deputy != "Zvad"
           band;
        *if deputy = "Zvad"
          band, not only as your deputy but in his own right;
        his counsel on this will sway many others.
      *gosub nextyou
      *goto plansurvey
  *if (bred_here) and not(bvote)
    *hide_reuse #Breden.
      *gosub bredcounsel
      *if bred_lead > 4
        
        Many of the other outlaws nod at this, including 
        *if bred_lead > 9
          a few you were sure would scoff at the idea.
        *if bred_lead < 10
          some you would have expected to be more skeptical.
        It's a sign of how much influence Breden has built up in the band
        *if deputy = "Breden"
          as
        *if deputy != "Breden"
          despite never being
        your deputy.
      *gosub nextyou
      *goto plansurvey
  *if (kal_here) and not(kvote)
    *hide_reuse #${kalt}.
      *gosub kalcounsel
      *gosub nextyou
      *goto plansurvey
  *if ((simz_here) and (s_rel < 9)) and not(svote)
    *hide_reuse #${simon} de Firiac.
      *gosub simzcounsel
      *gosub nextyou
      *goto plansurvey
  *if (el_here) and not(evote)
    *hide_reuse #Elery.
      *gosub elcounsel
      *if el_lead > 4
      
        Several outlaws cheer at her speech, and you can see smiles and nods from others.  Elery's raid leadership over the winter has clearly won her a loyal following.
      *gosub nextyou
      *goto plansurvey
  *if bethune > 0
    *hide_reuse #Bethune, the Westriding rebel leader.
      "You all know that my grandfather fought with Ester Cabel against the Karagonds."  Bethune looks coolly around the circle. "He told us that through all that rebellion, he had never once regretted a battle, however painful the losses.  
      
      "His regrets were the battles unfought, the moments when he and his allies chose to wait or hide.  The moments when greater boldness might have won the day…before the Karagonds were able to bring their full strength against them.
      
      "I believe we face such a moment now."  The young war leader pauses, then folds her arms. "I'm new to the band, so I'll say no more than that.  But I hope we don't make the kind of decision that we'll still be regretting in a generation and more."
      *set warvote +1
      *if democ > 2
        *set warvote +1
      *set wareld +1
      *gosub nextyou
      *goto plansurvey
  *if korszata > 0
    *hide_reuse #Korszata the former Phalangite.
      *set votetick +1
      *set korvote true
      Korszata has once again donned his omphalos mail for the occasion, and stands to the rippling sound of scale on scale.  His voice is sonorous inside his helm.  "This armor well hides my weakness.  Phalangites do not always win.  An unlucky truth for me.  A lucky one for the band.
      
      "I did not suffer with you last winter.  I am still almost a stranger, and have no right of clan-voice today.  But since my Oath-Holder asks: I say 
      *if ((nonkids < 250) or (arms < (nonkids-20))) or ((morale < followers) or (sybla < 1))
        we win by surviving.  Against the force they send, we should not hope to break them.  But to hide, keep moving, survive the summer?  This, I am sure, we can do."
        
        From your own private conversations with the ${whend}ish soldier, you know that if he thought your outlaws had the numbers, arms, and morale to beat the Archon's forces—or even to have a realistic chance—he'd be advocating for a battle.  The fact that he's advising caution is telling.
        *set runvote +1
        *if democ > 2
          *set runvote +1
        *set runeld +1
      *if ((nonkids >= 250) and (arms >= (nonkids-20))) and ((morale >= followers) and (sybla > 0))
        take the bold road.  Choose the battlefield with care—but aim to break their force, not just to evade it.  They do not know our true strength.  This is the hour to show them."
        *set warvote +1
        *if democ > 2
          *set warvote +1
        *set wareld +1
      *gosub nextyou
      *goto plansurvey
  *if not(zv_here)
    *hide_reuse #Pitrj the ${whend}.
      *set votetick +1
      *set pvote true
      *set runvote +1
      *if democ > 2
        *set runvote +1
      *set runeld +1
      The slight-framed man who replaced Zvad as the foremost ${whend}ish bandit inclines his head thoughtfully.  "$!{addressu}…the Whendward Band has always lived by a simple rule. When they come for you, you run.  You keep three steps ahead of them, and you wait for them to get hungry and uncomfortable enough to declare victory and go home.  I think if Zvad were still with us,
      *if evote
        as Elery said,
      he'd be telling us to hew to what we know."
      *gosub nextyou
      *goto plansurvey
  *if (rescuer = 0)
    *hide_reuse #Helot elder Gillian Adze.
      *set votetick +1
      *set gvote true
      *set runvote +1
      *if democ > 2
        *set runvote +1
      *set runeld +1
      The former t'Keriatou elder looks around the assembled outlaws grimly. "Can't say I've any desire to fight with a Phalangite.  Seems to me the only sane thing to do is hide from them.  Split up if we need to, but stay in the woods, under cover."
      *gosub nextyou
      *goto plansurvey
  *if (rescuer = 0)
    *hide_reuse #Helot elder Joana Orchard.
      *set votetick +1
      *set jvote true
      *set govote +1
      *if democ > 2
        *set govote +1
      *set goeld +1
      Your mother's old friend spreads her hands and chuckles drily.  "Angels, look at us.  We're no soldiers.  Most of us are barely woodsfolk.  Look at young Pereth—never laid hand on a bow before a half year ago, and I know the same's true of most of the rest of you.  This isn't our place.  
      
      "What we know,
      *if aristo
        ${addressu}
      ${fname}, is the Rim.  We know how to hide among the other helots.  We know how to talk to them, how to persuade them.  No rebellion is going to win from the woods.  Or anyhow ours isn't.  If we win, it will be from the camps.  So I say we go back there—to the Rim, aye, and all of Shayard!"
      *gosub nextyou
      *goto plansurvey
  *if not(rvote)
    *hide_reuse #Radmar.
      *gosub radcounsel
      *gosub nextyou
      *goto plansurvey
  *hide_reuse #Alira.
    *set votetick +1
    *set avote true
    *set runvote +1
    *if democ > 2
      *set runvote +1
    *set runeld +1
    The chief tracker shrugs.  "If you ask me, anything other than staying on the run is folly.  And even that may not be enough to save us.  They're going to put a lot into hunting us this time, I fear—more than anything we've ever had to face before."
    *gosub nextyou
    *goto plansurvey
  *if (democ > 1) #I don't want anyone else to address the ${moot}.
    *goto whattodo
  *if (democ <= 1) #I've heard all the opinions I care to.
    *goto whattodo
*label whattodo
*if democ > 1
  When the last speaker has finished, the ${moot} dissolves into dozens of intense conversations.  It's impossible to precisely gauge the mind of the band, but you think a majority are leaning toward
  *if (warvote > govote) and (warvote > runvote)
    *if kvote
      ${kalt}'s
    *if not(kvote) and rvote
      Radmar's
    *if (not(kvote) and not(rvote)) and korvote
      Korszata's
    argument: that it's time to stand and fight.
    *goto howfarsway
  *elseif (govote > warvote) and (govote > runvote)
    *if bvote
      Breden's
    *if not(bvote) and svote
      ${simon}'s
    *if not(bvote) and (not(svote) and jvote)
      Old Joana's
    *if not(bvote) and (not(svote) and not(jvote))
      the least aggressive
    proposal: that it's time to return to the Rim.    
    *goto howfarsway
  *else
    *if zvote
      Zvad's
    *if not(zvote) and evote
      Elery's
    *if not(zvote) and not(evote)
      the standard bandit
    view: that you should run and hide.
    *goto howfarsway
  *label howfarsway
  How far you'll be able to sway them is hard to say.
  
*if rescuer > 0
  *set plekspear true
  *set weapon "spear"
  Before speaking, you hesitate a moment, wondering whether you should tell the other outlaws about the extraordinary gifts you received yesterday.
  
  *if democ > 1
    *page_break
  It began when a scout informed you of a lone muleteer who had been found approaching the Whendward Pass.  "The mule's carrying a bundle of long poles, ${addressu}, with what looks like a couple of spears wrapped up inside.  Not your typical smugglers' cargo.  He says he came up here to make us a gift of it—and asked for a discreet word with our leader.  No weapons on him, bar the two on the mule."
  
  When you and ${deputy} headed out to the woods to meet him, the thick-bearded stranger gave his name as Deyn.  His lean nose twitched as he looked you up and down.  "So you're ${fname} ${lname}, then?"
  
  "Why do you think that?" ${deputy} cut in. $!{dephis} fist had never left the handle of ${dephis} knife since the stranger came into view.
  
  The muleteer chuckled.  "Had a description of you from the aristo who gave me this cargo in the Southriding, back at the start of the winter.  Said you'd hopefully remember him—the fellow who helped you out of a bad spot by poisoning some guards and letting you out the postern."
  *if deputy = "Breden"
    Deyn turned his deep-set eyes on your deputy. "And you'd be
    *if aristo
      the helot
    Breden Reaper, by the same token."
  
  *if rescuer = 2
    [i]Abelard de Toman?[/i]
  You did your best to hide your shock, saying:
  *fake_choice
    #"If he sent you, tell me: what did his face look like?"
      "Ha!  A mask.  Old-fashioned like, holes for the eyes and a beaklike nose.  The kind they say aristos used to wear to their parties before the Karagonds came along."  Deyn chuckled wryly.  "And when he met you, my ${girl}, he wore a hood.  So best of luck catching me out on his face."
      
      "You generally in the business of bearing cargo for unknown aristos?" ${deputy} asked curtly.
      
      "That I am, that I am," the smuggler beamed. "As long as the price is good enough.  And believe me, for this one it was very good."
      
      "For a
    #"It's taken you a while to get here, then, hasn't it?"
      The bearded smuggler gave a wry chuckle.  "I took the long way round.  No main roads, no inns.  Didn't want no Theurge to sniff out what I was paid to bring you, did I?"
      
      "A 
    #"And what did he send you with?"
      "Just a
  mule and two weapons?"  You raised an eyebrow, glancing at the wrapped bundle on the animal's back.
  
  Deyn unbound the staves, which fell to the ground with a clatter; in their midst, you saw a glint of metal. "Boar spears, ${kuria}," he explained, unwrapping canvas from the heads. "Two of the Southriding's finest."
  
  "Long for boar, aren't they?" you said warily, picking one up.  It was extraordinarily heavy; not just the point, but the entire spear was made of steel.  Curious dark whorls ran along its span, a liquid pattern imprinted into the metal.  The broad, double-bladed spearhead was as long as your arm from elbow to fingertips, almost big enough for a short sword.  At the base, a crescent blade and two dull, straight spikes gave the head an odd star shape.
  
  "Hold it straight up, ${kuria}. Got it?  Now I'll show you something fine." A showman's grin breaking through his thicket of beard, Deyn found a decent-sized rock and dropped it onto the tip of the spear.  
  
  You'd assumed it would be a demonstration of how well the weapon held its point.  The last thing you'd expected was for the stone to slide onto the blade like a ripe pumpkin, not slowing until it hit the crescent at the base of the spearhead and cracked open.
  
  "Aye, it might be a bit much for boar, ${kuria} ${lname}."  The smuggler scratched his forehead as you and ${deputy} gaped at the split stone.  "But I reckon it would put a good sized hole in a Plektos hound."
  *page_break
  *if introhlt
    The mention of Plektoi sends you at once into a cold sweat—the memory of their metallic smell in your nostrils, the snap of their jaws echoing in your ears.  And yet you also feel a surge of elation as you turn your eyes back to the spear.  Could it truly be possible to kill the invulnerable beasts?
  *if not(introhlt)
    Plektoi, the Twisted: reshaped by Theurgic sorcery, the giant war-hounds of Karagon could seize a man's waist between their jaws and worry him as a normal hound might do a rabbit.  Your late grandmother had told you that the bones of a Twisted One were as weighty as iron, its teeth like knives.  Her tales had given you screaming nightmares—which, you have to admit, have been recurring in recent weeks.
  
  "Theurge-forged?" ${deputy} 
  *if deputy = "Breden"
    whispered,
  *if deputy = "Zvad"
    growled in disbelief,
  running ${dephis} hand gingerly along the liquid pattern in the steel. "Where did…where could…"  Even for Phalangites, Theurge-wrought arms were so rare that only a high-ranking captain or Plektos warrior on the Halassur front would ever be seen with one.
  
  "Quite the gift, eh?  They'd sell for a small province's worth, Angels' truth." There was a rueful pragmatism in Deyn's tone. "If you could find someone who you were sure would buy, rather than name you Goete or traitor, for keeping a weapon only a rebel would want.  And if you were sure that whoever gave them wasn't able to track you down, unnatural-like, and put a good sized hole in you."
  
  "Who could possibly have these to give in the first place?" you demanded, hearing a tremor in your own voice.
  *if int > 1
    You've read somewhere that in Halassur, Theurgic weapons are more commonplace—some lurid tale about how the Goetic magi of the Empire routinely sacrifice their children and concubines in the forges, quenching the blades in the hearts of enslaved ${erretsin} nobility.  Could these spears have come from the Hegemony's great adversary?  The thought is disconcerting.
  [i]And what can they possibly expect of us in return?[/i]
  
  The bearded muleteer hefted the second spear and jabbed it into a rocky cliff, where it stuck.  "Our mask-wearing friend said they were courtesy of the Laconniers."
  *fake_choice
    #The who?
      Suddenly you remembered the story you once heard from Breden.  It's been three hundred fifty years since the Shayardene royal line was supposedly extinguished.  The last Queen fell in battle to the Thaumatarch; the last Prince fled into the forest of Laconne and was never seen again.  But from then until now, there have been rumors of a secret order among the nobility who hid the prince in the woods and ensured the persistence of the lineage.

      Over the past century, at least three Shayardene Pretenders have declared themselves heirs of the Lost Prince of Laconne and won swathes of the nobility to their banner.  All three rebellions were swiftly quelled: two with Kryptast assassins alone, one with massed military and Theurgic force.  Still, the rumors persist that the Pretenders were only lesser scions of the Sovereign Bloodline, sent to test the waters by the deeper Laconnier conspiracy.
    #The Laconniers! Perhaps the Last Scion of the Lost Prince?  I felt an inescapable sense of awe.
      When you first heard their story, it had sounded like a child's tale, too good to be true.  How could the true heir to the Shayardene throne have been preserved through centuries of ruthless Karagond Hegemony?  The Kryptasts would have infiltrated any loyalist noble conspiracy ten times over.  Would any survivors with a right to the throne have dared even to whisper it to their children?  Surely, any such claim would have been forgotten within a generation or two.
      
      Yet looking at the spear juddering from the rocky outcrop, you found yourself a believer—at least for a few moments.  There is a True Queen somewhere, or True King.  Hearing that a rebellion had begun at last, They have sent you Their most precious weapons to bear in defense of Shayard.  It sent a shiver down your spine.
    #The Laconniers? From all I've heard, I don't want to be pulled into their benighted schemes.
      Restoration of the Shayardene monarchy?  Even if it were possible,
      *if aristo
        and the claim rightful,
      it's the last thing you want.
      *if helot
        The lot of serfs before the Karagonds came might well have been better than the helotry today—but 
      *if aristo
        Why would any noble like yourself now swear fealty to the royal bloodline, simply because of ancient custom—to the family that, in the end, wasn't able to defend their realm against the Karagonds?  No,
      you want a new order, not a coterie of nobles with dreams three centuries old.
  *comment endif
  
  You came out of your reverie and looked sharply to Deyn.  "And what did he want in exchange for these treasures?"
  
  "Nothing."  The smuggler spread his hands wide.  "The spears are yours.  Oh, and the mule in the bargain."  When you and ${deputy} shared baffled glances, Deyn rolled his eyes and murmured: "Just a guess, ${kuria}?  He wants you to kill some swiving Plektoi with them."
  
  You quickly decided that:
  *choice
    #I want the band to know that we have these weapons.
      *set warvote +3
      And it was obvious that the best time to tell them would be at the imminent
      *if (democ > 1)
        ${moot}
      *if (democ <= 1)
        gathering
      where you decided your strategy for the summer.
      
      *gosub nowyou
      raise a whorled steel spear above your head. "Before I say aught else, I want the band to know: we are not defenseless against the Hegemony's beasts."  
      *if democ > 1
        With a shout, you bring the spearhead down into a boulder before your feet. 
      *if democ < 2
        Repeating Deyn's demonstration, ${deputy} impales a stone on the spearhead while you hold it steady.
      "Let them send their Plektoi against us!  We'll gut them as if their armor-skin were so many feathers."
      
      "Where by Xthonos…"
      *if ((deputy != "Breden") and bred_here) and bvote
        Breden exclaims, eyes wide and disbelieving.
        *goto seemallies
      *elseif ((deputy != "Zvad") and zv_here) and zvote
        Zvad bellows, as stunned as you think you've seen him.
        *goto seemallies
      *elseif ((deputy != kalt) and kal_here) and kvote
        ${kalt} cries, his grin practically splitting ${zhis} face.
        *goto seemallies
      *elseif ((deputy != simon) and simz_here) and svote
        ${simon} gasps, visibly stunned.
        *goto seemallies
      *else
        Ciels exclaims, eyes wide and incredulous.
      *label seemallies
      
      You pull the spear out of the stone and display the undulled blade. "We have allies in the Southriding, it seems.  Resourceful folk, who wouldn't share their names, but plainly want us to survive the summer.  And on that point, having heard your advice…"
      
      The excited clamor renders you inaudible; no one in the band has ever seen a Theurge-forged weapon, 
      *if korszata < 2
        of course, 
      *if korszata > 1
        even Korszata and Bjel,
      and your outlaws crowd around now to touch it.  After tolerating the hubbub for a few minutes, you raise your hands and loudly
      *goto clearmythr
    #I want to keep them a secret.  No one but ${deputy} should know, for now.
      *set pleksecret true
      *if (deputy = "Radmar") and (not(rad_mutiny) and (cha > 0))
        It had taken all your 
        *if cha > 1
          considerable 
        persuasive powers to convince Radmar to keep it a secret.  "If they know, ${addressu}, it'll change everything," he pleaded, hot-eyed with excitement, as you carried the great spears back toward camp. "The courage it'll lend them, knowing we can kill Plektoi…"
        
        "We don't know that yet," you retorted sternly. "Angels know we need to be ready to try—a spear with you and one with me at all times.  But we've seen them crack stone, not iron, let alone whatever the Plektoi are truly made of.  Let's not get the band making decisions based on an untried weapon."
        
      *if ((deputy = kalt) and kvote) or ((deputy = "Radmar") and rvote)
        When ${deputy} addressed the 
        *if democ > 1
          ${moot},
        *if democ < 2
          other outlaws in your tent just now,
        ${dephis} eyes had flickered to yours. For an instant you had seen how badly ${dephe} wanted to reveal your secret weapons.  But ${dephe} had swallowed it and sat down again.
        
      *gosub nowyou
      *goto clearmythr
You
*label clearmythr
clear your throat.  "Very well, ${addressc}.  Having heard everything suggested—both in this group today, and from others in the band—I
*if democ = 0
  have decided that we will…"
*if democ > 0
  propose that we…"
*choice
  #"Lure them deep into the wild, fight them, and wipe them out!"
    *set strategy 1
    *if democ = 0
      *set warvote +2
    *if morale >= (followers+40)
      *set warvote +2
    *if morale > followers
      *set warvote +1
    *if morale < followers
      *set warvote -3
    *if (theurgy > 2) and (theurgy < 9)
      *set warvote +1
    *if eclect
      *gosub eclectspoken
      *set warvote +5
    The cheers from 
    *if kvote
      ${kalt} and 
    *if rvote and (nonkids >= 45)
      Radmar 
    *if (rvote and not(kvote)) and (nonkids >= 45)
      and his cronies
    *if not(rvote) or (nonkids < 45)
      the band's younger warmongers
    almost drown out the frightened murmur from many of the others.
    *goto vote
  #"Evade them—keep one step ahead and harry them from afar until they give up hunting us."
    *set strategy 2
    *if democ = 0
      *set runvote +2
    *if morale >= (followers+40)
      *set runvote +2
    *if morale > followers
      *set runvote +1
    *if eclect
      *gosub eclectspoken
      *set runvote +5
    *if zvote
      Zvad and
    *if pvote
      Pitrj and
    *if evote
      Elery
      *if not(zvote) and not(pvote)
        and a handful of seasoned bandits
    *if not(evote) and ((zvote) or (pvote))
      *if gvote
        Gillian
      *if not(gvote)
        many of his fellow bandits
    *if not(evote) and not(zvote)
      Many of the seasoned bandits
    applaud your decision, but others around the circle look dissatisfied.
    *goto vote
  #"Split up, melt away—and take our message back to helot camps all across Shayard."
    *set strategy 3
    *if democ = 0
      *set govote +2
    *if morale >= (followers+40)
      *set govote +2
    *if morale > followers
      *set govote +1
    *if morale < followers
      *set govote -3
    *if eclect
      *gosub eclectspoken
      *set govote +5
    *if bvote
      Breden and
    *if svote
      ${simon} 
      *if not(bvote)
        and
    *if (not(svote) or not(bvote)) and jvote
      Joana
      *if (not(svote) and not(bvote))
        and one or two of her protégés
    *if (bvote and (not(jvote) and not(svote))) or (svote and (not(jvote) and not(bvote)))
      one or two close friends
    *if (bvote or (jvote or svote))
      stand and cheer, but most others are looking uncertain. 
    *if (not(svote) and not(bvote)) and not(jvote)
      Your suggestion takes the assembled outlaws completely by surprise.
    *goto vote
*label vote
*if (strategy = 1) and (sybla = 0)
  The terror spreads 
  *if democ > 1
    faster than Radmar's
    *if nonkids < 45
      half-hearted
    cheers.
  *if democ < 2
    all the quicker when you head out and inform the rest of the band of the decision.
  *if nonkids < 45
    [i]There aren't enough of us[/i], you hear again and again.
  "We can't stand against them, ${addressu} ${lname}," one outlaw shouts shrilly. 
  *if arms = 0
    "Without any forged arms?
  *if (arms > 0)
    He holds out his sword with a shaking hand.  "You think I know the first thing about how to use this?
  How am I supposed to last five eyeblinks against a swiving Phalangite?"
  *goto strat1object
*if ((strategy > 1) and pleksecret) and ((((deputy = kalt) and (((strategy = 2) and ((runvote-warvote) < 6)) or ((strategy = 3) and ((govote-warvote) < 6))))) or ((deputy = "Radmar") and ((rad_mutiny  or (cha = 0)) or (r_rel < 10))))
  *if (deputy = kalt) and (((strategy = 2) and ((runvote-warvote) < 6)) or ((strategy = 3) and ((govote-warvote) < 6)))
    *set kalbetray true
    *gosub depbetray
    cries,
    *if k_rel > 5
      eyes glinting vengefully.
    *if k_rel < 6
      a hint of genuine regret in ${zhis} eyes and tone. 
    "But I can not let you conceal our greatest hope from the rest of the band.
  *if (deputy = "Radmar") and ((rad_mutiny  or (cha = 0)) or (r_rel < 10))
    *set radbetray true
    *gosub depbetray
    roars. "But I can't keep this a 
    *if not(rad_mutiny)
      secret.
    *if rad_mutiny
      secret, any more than I could follow your lead when you were wrong in the winter.
  Brothers, sisters, we don't need to fear them!  Not Theurges with their stone-hard robes, nor even Plektoi."  $!{dephe} impales a stone on the spear,
  *if democ > 1
    just as Deyn did.
  *if democ < 2
    then strides out of the tent again and begins calling the other outlaws to gather round, "In moot, 
    *if addressc != "children"
      ${addressc}—there's 
    *if addressc = "children"
      sisters and brothers—there's 
    a grand decision to be made!"
  
  There's a shocked silence, followed by utter chaos.
  *if democ < 2
    You scramble after your treacherous deputy, but it's too late to undo what ${dephe}'s started. 
  The whole band is swarming around you and ${deputy}, clamoring to hear more.  Though you try to make yourself heard, it soon becomes clear that your decision to hide the spears from the band has angered them, and that they more than half-believe that with "magic weapons," you really do have the chance to beat the Thaumatarchy's forces in open battle.
  
  ${deputy} shakes the stone from the spearhead and turns to you, ${dephis} voice rising above the din. "Lead us, ${addressu}!  Lead us to war!"
  *if (deputy = kalt) and (k_rel > 5)
    $!{zhis} smile is broad and triumphant. After the times ${zhe}'s felt humiliated or let down by you, ${zhe}'s clearly relishing your own humiliation.
  *if (deputy = kalt) and (k_rel < 6)
    There's a plea in ${zhis} voice.
  *if (deputy != kalt)
    In his relentless glare, you can almost hear the words: [i]Last chance[/i].
  *choice
    #"You filthy traitor!" I roar, beside myself with fury. "I'll have your bloody head for this!"
      Despite your rage, it does briefly occur to you that threatening an outlaw carrying a Theurgic weapon is a risky choice.  
      *label surprise
      And yet it still comes as a surprise when ${deputy}'s eyes go flat and ${dephe} swings the spear down in a short, decisive arc.
      
      The Theurge-forged blade parts your skull so swiftly and cleanly that you don't feel the steel—just a momentary, terrifying sensation of coming apart.
      *goto_scene death
    #"Never!" I grate.  If I were ever inclined to choose ${deputy}'s preferred course, I surely wouldn't now.
      *gosub popcalc
      *if popular != 1
        For a few heady moments, you wonder if you're going to be killed by ${deputy} and ${dephis} young warmongers.  But at the end of the day, despite ${deputy}'s spear-waving appeal, there are still more outlaws afraid to stand against the Phalangites than otherwise—and they quickly crowd around you, shouting their agreement.
        
        The course of action with the most support in the
        *if democ < 2
          impromptu
        ${moot} is clearly
        *if popular = 2
          running and hiding, as Zvad would have wanted.
          *set strategy 2
        *if popular = 3
          returning to the 
          *if bred_here
            Rim; apparently Breden's quiet advocacy over the past few weeks has influenced more people than you realized.
          *if not(bred_here)
            Rim to infiltrate helot camps, a few at a time.
          *set strategy 3
        And that's the course you now throw your influence behind, as the only alternative to ${deputy}'s attempted takeover.
        
        ${deputy} soon sees that ${dephe}'s lost the band, despite ${dephis} intense rhetoric.
        *if (deputy = "Radmar") and ((popular = 3) and (bred_here))
          But he can't bring himself to accept Breden's victory any more than you could accept his. "No!" he howls, nearly deafening those close to him. 
          *gosub radmurder
          $!{xhe} clearly won't be fit to organize the relocation of small outlaw groups to the Rim for some time, even though it was ${xhis} idea first and foremost.
          *choice
            #I ${ask} ${xhim} to be my new deputy anyway.
              *label breddep
              That gets a hollow laugh from ${xhim}, at any rate.  "Bloody Taratur.  Now's a fine time for it.  See if I manage to hold it any longer than ${deputy} did."
              *if deputy = "Elery"
                $!{xhis} face crumples at ${xhis} own final words, and ${xhe} hurries away from you with a choked, "Ah, Angels."
              *set deputy "Breden"
              *set dephis xhis
              *set dephe xhe
              *set bred_lead +1
              *goto stalemate
            *if (simz_here) #I ${ask} ${simon} de Firiac to be deputy.
              *label willsimzdep
              *if (s_rel < 9)
                ${simon} seems subdued when you raise the prospect.  "Forgive me, ${addressu}.  I was but a few steps behind Elery Skinner when she died.  If I'd been quicker, perhaps she might still be with us."  
                
                "Or you might both have died," you say starkly.
                *if not(plekspear)
                
                  "No, Radmar wasn't that good.  And I might have been better able than Elery to block his blow.  But still…"
                *if plekspear
                  "That spear could have gone through two as easily as one."
                
                  "You're right, of course, ${addressu}."  
                $!{zhe} shakes off ${zhis} gloom, squares ${zhis} shoulders.  "Forgive my self-preoccupation. It would be my very great honor to serve as your deputy, for however long remains to us both." 
              *if (s_rel > 9)
                Two mornings after the disaster, you find de Firiac
                *if not(horhostage)
                  in a corner of the nearly abandoned encampment,
                *if horhostage 
                  in the previous night's prisoners' enclosure,
                ${zhis} hands tied together and lashed to a tree.
                *if horhostage 
                  Horion
                  *if linhostage
                    and Linos have
                  *if not(linhostage)
                    has
                  already started the walk to today's camp, but you'd asked for ${simon} to be held back.
                $!{zhe} glances up coolly as you approach, tosses ${zhis} matted hair back out of ${zhis} eyes. "Rumor has it things are going ill, ${kuria}?"
                
                *if plekspear
                  "Not all bad.  We've been sent two Theurge-forged spears that can supposedly get through a Plektos's armor.  The kind of weapon you might look to find in the personal guard of the Archon of ${errets}, not a Whendward bandit camp."  You sit down heavily next to the de Firiac, noting from ${zhis} unsurprised expresssion that ${zhe}'s heard that news already. "On the other hand…my deputy betrayed me and killed one of the band's finest with one of those spears."
                *if not(plekspear)
                  *if deputy = "Radmar"
                    "My deputy 
                  *if deputy != "Radmar"
                    "One of our strongest raid leaders
                  lost his temper and killed
                  *if deputy = "Radmar"
                    another outlaw—someone who'd been his friend but disagreed with him on the band's direction."
                  *if deputy != "Radmar"
                    the band's second-in-command."
                  You sit down heavily next to ${zhim}. "So yes, a bad week.  I need to find a new deputy whose judgment and temper I can trust."
                
                ${simon} gives a short, pained nod.  "Excuse my boldness, ${kuria}, but your judgment of whom to trust—and whom not to trust—is perhaps not your most compelling quality as a leader."
                
                "I've been coming to think that myself, alas."  You regard ${zhim} for a few moments before venturing, "Indeed, I've been mad enough to wonder whether the person I could trust most as deputy is currently in shackles."
                
                *if s_rel = 19
                  ${simon} stares at you for a moment, then spits at your feet. $!{zhis} voice when ${zhe} speaks is shrill with anger.  "Have you forgotten what I've seen of you already, ${kuria}?  Angels.  Did you think I could overlook your despicable treatment of Horion ${delelle} and his priest?
                  
                  "Kill me if you will—I'd rather die than bring in a single drachem's ransom for your bloodthirsty pack of Xaos-lovers.  Let alone serve as your…deputy."  The word drips scorn.  "Xthonos, you must be desperate."
                  
                  You stand, barely able to restrain the helplessness and anger.  "Enough, ${zgirl}.  You've made yourself clear.  Don't think you'll goad me into killing you and abandoning your only remaining use to us."
                  *page_break
                  *goto simzrefuse
                ${simon} blinks three times rapidly, but otherwise gives no sign of astonishment.  
                *if horhostage
                  "You'll free
                  *if linhostage
                    Ecclesiast Linos and
                  kurios Horion."  It's not a question.
                  *choice
                    #Very well.
                      *label horionrelease
                      *set releasepromise true
                      *set horion +11
                      "I'll release
                      *if linhostage
                        them
                      *if not(linhostage)
                        him
                      within a few days, as we circle back toward the Whendward Pass," you promise.  You'll soon be near enough that Horion should be able to get over into Szeric what he
                      *if linhostage
                        and Linos
                      can carry—no need to send one of your mules.
                      *label simzbelieve
                      
                      ${simon} eyes you for a moment, as if weighing the credibility of your offer.
                      *if s_sword = 2
                        "And my family sword?"
                        
                        "Yours, of course," you say at once, with only a tinge of reluctance.  You don't want ${zhim} to refuse you now, and a blademaster will make better use of the sword than you will.
                        
                        "I should say so," ${simon} breathes, eyes flashing.
                      *set s_rel 5
                      Then ${zhe} thrusts ${zhis} hands wordlessly toward you.  As you cut ${zhim} free, ${zhe} stands and offers a stiff bow. "Let us be clear with each other, ${kuria} ${lname}.  At the moment, I neither like you nor respect you…though the latter may perhaps be achievable in time.  But I believe in the cause you've chosen. I believe that a rebellion against the Thaumatarchy can and must succeed.  And in that cause, I pledge you my whole-hearted service."
                      *goto simzdep
                    #"You think you're back in a position to make demands, ${zkuria}?" I ask drily.
                      "If you truly want me to help you lead the band," ${simon} retorts, "then yes, I am."
                      *choice
                        #Very well.
                          *goto horionrelease
                        #Absolutely not.
                          *goto simzshrug
                    #"Absolutely not."
                      *label simzshrug
                      ${simon} shrugs, looking unsurprised. "Then I can not accept, ${kuria}.  And I fear we are now wasting more of each other's time."
                      
                      *label simzrefuse
                      You make Alira your new deputy instead.
                      *goto aliradep
                "What has you thinking such…uncharacteristic thoughts, ${kuria}?"  The young noble's face remains wary, unmoved by any visible hope.
                
                "When you came, above all things you offered me loyalty.  At the time, I counted it cheap.  In light of all that's happened 
                *if helot
                  since…well, I was clearly wrong."
                *if aristo
                  since, I've had occasion to reconsider."
                *goto simzbelieve
              *label simzdep
              *set simz_lead +1
              *set deputy simon
              *set dephis zhis
              *set dephe zhe
                
              It takes some time for the rest of the band to accustom themselves to your new 
              *if helot
                aristocratic 
              deputy.  ${simon}'s earnest goodwill, woodcraft, and swordsmanship quickly win ${zhim} some allies and followers—but as many outlaws grumble that ${zhe} should still be where ${zhe}'d do the most good.
              *goto stalemate                
            #I ${ask} the band's lead tracker, Alira, to be my new deputy.
              *label aliradep
              She's well respected in the band, and you've come to appreciate her crisp, decisive response to events.  But in the event, she struggles to mobilize your 
              *if spcas != ""
                shocked and 
              divided outlaws behind a still-controversial strategy.  
              
              It doesn't help that Alira herself would rather be preparing to hide in the woods, rather than maneuvering small groups back into helot camps in the Rim.
              *set deputy "Alira"
              *set dephis xhis
              *set dephe xhe
              *goto stalemate
        "Very well," ${dephe} growls, lowering the spear. "As the moot wills."  $!{dephis} eyes flash a warning at you and anyone else who might even think of trying to take the Theurgic weapon from ${dephis} hands. "Angels send we aren't making the greatest mistake of this rebellion."
        *goto stalemate
      *elseif eclect
        The crowd of outlaws shouts you down, rage escalating in their voices.  For several long seconds, ${deputy} just stares at you with almost no expression, the spear trembling slightly in his hands.
        
        Later, you realize that the only thing that saved your life is that your followers still believe you to be the Eclect of the Angels.  A young Eclect, a mistaken-in-this-case Eclect, one whose failure to see the obvious can be put to inexperience.  Someone it would be risky and unseemly to kill over one mistake.  Even a major one, a deception, that weakened the band in its hour of greatest vulnerability.
        
        The
        *if democ < 9
          impromptu
        ${moot} breaks up in great acrimony an hour later.  Divided between the majority who support ${deputy}'s call to prepare for battle, and a large minority who won't countenance it, you are paralyzed as a band.
        *goto stalemate
      *else
        You knew that refusing ${dephis} ultimatum before an enraged crowd would be dangerous.
        *goto surprise
    #"Very well, then.  We'll stand and fight."
      *set strategy 1
      As you step forward and stiffly offer your hand to your deputy, the raucous cheers of the band are like live coals in your ears.  But painful as it is to swallow the betrayal and back down, the alternatives are all worse.  
      
      Even if you survived an outright confrontation with ${deputy} and ${dephis} supporters now, the conflict would likely leave the band divided to the point of paralysis.  Better to work toward a common goal than have the Phalangites find you consumed by infighting.
      *if bred_here
        *if zv_here
          Zvad,
        Breden and others who might otherwise have protested the decision seem to be making the same judgment; at any rate, they swallow their objections and fall in line behind you and ${deputy}.
      
      Only once the rest of the band have returned to the day's work do you lean over to your second-in-command and murmur, "You betrayed me, ${deputy}.  Don't think I'll forget it."
      
      *if deputy = kalt
        *set k_rel 8
      "I kept you from betraying the rebellion, ${kuria}," ${deputy} replies grimly. "Don't think I'd not do it again."
      *page_break
      *goto outwork
*gosub popcalc
*if popular = 1
  *if strategy = 1
    *if democ > 1
      It takes time for the excitement to spread to every corner of the grove—for it to become clear that despite some qualms, 
    *if democ < 2
      Only when you head out to announce your decision to the whole band and they break into whoops and war-cries does it become clear that yours is the most popular choice—that
    most of your followers truly do want to stand and face the Archon's troops.
    *if (religion > 10) and (religion < 20)
      
      "The Angels have spoken to me, ${addressu}," one cries ecstatically, "and promised us victory!"
      *set morale +10
    A 
    *if nonkids < 45
      bleak-faced
    *if nonkids >= 45
      laughing 
    Radmar waves his axe at the sky and vows he'll take a dozen Phalangites himself.
    *label strat1object
    *if zv_here
      
      "$!{addressu}," Zvad cuts in desperately, loud enough for the whole band to hear. "I'd not lightly speak against your lead.
      *if deputy != "Zvad"
        I'm not even your deputy.
      But this is madness.  These Phalangites are skilled soldiers.  They'll bring Theurges, maybe even Xthon'damned Plektoi.  We can't beat them."
      *if kal_here
        
        "We can't run from Theurges or Plektoi, either," ${kalt} counters hotly. "So it's time to turn our mind
        *if (theurgy > 2) and (theurgy < 9)
          and ${addressu} ${fname}'s ${wisardry}
        to killing them."
        *if plekspear and not(pleksecret)
          $!{zhe} points to the mage-forged spears. "These might work well on Theurges, too."
      *if bred_here
      
        "If we fight them, [i]we will die[/i]," Breden cries—and though Radmar immediately begins roaring a denial, you can see more than a few outlaws wavering at the utter conviction in Breden's voice.  "Don't make this mistake, ${addressu}.  Lead us back to the camps, not to a battle we cannot win!"
    *if not(zv_here) and bred_here
      
      "$!{bfname}," Breden says 
      *if bred_heart < 10
        shakily 
      *if bred_heart >= 10
        tautly
      in your ear. "Why are you taking your lead from
      *if kvote
        ${kalt}
      *if not(kvote) and rvote
        Radmar
      *if not(kvote) and not(rvote)
        *if plekspear and (deputy = "Breden")
          some faceless Laconnier
        *if not(plekspear) or (deputy != "Breden")
          your gut
      on this?  This
    *if (not(zv_here) and not(bred_here)) and el_here
      
      "Damn it, ${addressu}!" Elery grips your arm, her haunted eyes searching for yours. "This 
    *if not(zv_here)
      is madness.  Zvad would tell you so, were he still alive.  We aren't nearly strong enough to beat the Phalangites.  If you try, you're sentencing us all to death."
    *if ((zv_here or bred_here) or el_here) or (sybla = 0)
      *choice
        *if (sybla > 0) #I'm not changing my mind.  This is the time to crush the Hegemony in battle.
          "The rest of the band disagrees with you,
          *if zv_here
            *if bred_here
              Breden,
            Zvad,"
          *if not(zv_here)
            Breden,"
          *if (not(zv_here) and not(bred_here)) and el_here
            Elery,"
          you say curtly. "We're rebels fighting to destroy the Thaumatarchy…and they're going to treat us like it, so we'd damned well better act like it."
          
          *goto outwork
        #All right.  We'll evade them in the woods instead.
          *if eclect
            *set warvote -4
          *if democ > 0
            *goto mindchange
          *else
            *set warvote -3
            *set runvote +3
            *set strategy 2
            *gosub popcalc
            *if runvote < (warvote-5)
              *gosub protests
              *goto stalemate
            *gosub okmindch
            *goto outwork
        #All right.  We'll split up and infiltrate the Rim instead.
          *if bred_here and (sybla > 0)
            *label radvbred
            *set strategy 3
            Radmar
            *if (nonkids < 45)
              almost protests—but then he glances around the circle, takes in again how few your bandits are.  With a disgruntled shake of the head and a glower in Breden's direction, the hot-tempered fighter accepts your judgment.
              
              *goto outwork
            whirls on you, his eyes white with shock and denial. "$!{addressu}—no!"  He lowers the axe he's been waving, then gestures brutally at Breden with it.
            *gosub radmurder
            *if (deputy = "Radmar") or (((spcas = "Elery") and (deputy = "Elery")) or ((spcas = simon) and (deputy = simon)))
              The deaths also leave you in need of a new deputy.
              *choice
                *if bred_here
                  #I ${ask} Breden—although at the moment I'm sure ${xhe}'ll struggle with the responsibility.
                    *goto breddep
                *if (simz_here) #I ${ask} ${simon} de Firiac.
                  *goto willsimzdep
                #I ${ask} our chief tracker, Alira.
                  *goto aliradep
            *goto stalemate
          *if eclect
            *set warvote -4
          *if democ > 0
            *goto mindchange
          *if democ = 0
            *set warvote -3
            *set govote +3
            *set strategy 3
            *gosub popcalc
            *if govote < (warvote-5)
              *gosub protests
              *goto stalemate
            *gosub okmindch
            *goto outwork
    *goto outwork
  *else
    *comment if strategy != 1
    *gosub wrongstrat
    "We don't want to run any more, ${addressu}," a dozen outlaws roar, brandishing their 
    *if arms > 5
      captured Alastor maces.
    *if arms < 6
      bows and axes.
    *if arms >= nonkids
      The fact that you've got enough arms to equip the whole
      *if sybla = 1
        band—and that after Sybla's training, they feel that they know how to use them—has
      *if sybla != 1
        band has
      put fire into your rebels' bellies.
    "We want to stand and fight!"
    *if (mules < (followers/25)) and (strategy = 2)
      
      "We don't have enough bloody mules to move the band fast enough, anyway, ${addressu}," an outlaw calls. "We'd need more if we're to outrun them."
    *if (religion > 10) and (religion < 20)
      More than one begins to cry out loudly about what they've heard from the Angels, promises of victory and vindication.
      *set warvote +2
      *set morale +10
    *if rad_mutiny and (nonkids >= 45)
    
      Radmar raises an axe toward the sun-dappled leaves, and all around him young fighters erupt with whoops and war-cries. "$!{addressu}?" He finds your eyes with a relentless stare. "What do you choose…this time?"  The reference to mutiny is unmistakable.
    *if kvote and not(rad_mutiny)
    
      "Heed them, ${addressu}!" ${kalt} cries, spreading ${zhis} hands in an imploring gesture.  "This is our hour!"
    *if (kal_here and not(kvote)) and (not(rad_mutiny) or (nonkids < 45))
      
      It's clear that, even though you didn't invite ${kalt} to 
      *if democ > 9
        address the ${moot},
      *if democ < 10
        your meeting,
      ${zhis} influence has gone deeper in the band than you'd realized.  You look around and see ${zhim} leading the outlaws nearest him in a war-cry.
    *if not(kal_here) and not(rad_mutiny)
      
      Radmar is at the center of the whoops and war-cries, 
      *if nonkids < 45
        but you can see that despite himself he's not wholly convinced.  "We've only 
        *set d2n_num nonkids
        *gosub d2n
        fighters," he snaps out at last, waving impatiently at the other young hawks.  "If ${addressu} ${lname} were willing to risk it, I'd back ${him}.  But I'll not stand against the cautious choice—not this time."
        
        *goto outwork
      waving his axe in the air and bellowing about gutting any Phalangite that enters the Whendward. All of
      *if zv_here
        Zvad's
        *goto waraccchoice
      *elseif el_here
        Elery's
        *goto waraccchoice
      *elseif bred_here
        Breden's
        *goto waraccchoice
      *else
        Alira's
        *goto waraccchoice
      *label waraccchoice
      attempts to calm him are in vain.
    *choice
      #I grudgingly accept the will of the band.  We'll find a place where we can break the Phalangites.
        *label warchange
        "Well chosen, ${addressu}," 
        *if kal_here
          *set kal_lead +1
          ${kalt} smiles
          *if k_rel > 5
            thinly
          at you.
        *if not(kal_here)
          Radmar says flatly.
        *set rad_lead +1
        *set strategy 1
        
        *goto outwork
      #I'm not going to change my mind.
        *label warnochange
        *if ((cha = 2) or eclect) and (morale > (followers/1.5))
          You stubbornly pour all your 
          *if not(eclect)
            eloquence 
          *if eclect
            authority as Eclect
          into winning your followers back to your view—but
          *if kal_here
            ${kalt} and
          Radmar's faction are irreversibly committed to the illusion that they can lure the Phalangites into a decisive ambush.  The argument goes on for several fraught hours, with your opponents growing increasingly savage in their arguments. 
          
          "This is the will of the band, ${addressu}," Radmar snarls at last, his knuckles white on his axe.
          *if kal_here
            You can see ${kalt} behind him, nodding grimly.
          "If you won't heed it…if you want to lead us to piecemeal death instead of victory…what can we call that but treachery?  To the band, to the rebellion?"  Your throat goes dry at the expression on his face. If there hadn't been a small gang of like-minded outlaws at your side in that moment, you're sure he
          *if kal_here
            and ${kalt}
            *set k_rel 8
          would have killed you.  
          
          When you finally do walk away, the dissension among your followers is worse than it's been since
          *if rad_mutiny
            Radmar's mutiny
            *if winterfail > 0
              and
          *if winterfail > 0
            the band's dissolution
          in the winter.
          *goto stalemate
        *else
          Had your followers been less demoralized, or you a more charismatic leader, the majority who are determined to defeat the Archon's forces might have accepted your refusal.  
          
          As it is, barely any allies are standing at your side when Radmar finally snaps. With you so plainly the only obstacle between him and his vision, the fury you've always seen in him becomes incandescent. 
          *label radkillyou
          "If you won't heed the will of the band, and you won't take the chance to truly defeat the Hegemony?  If all you'll do is stand in our way and try to frighten us?  Then I name you
          *if eclect
            false Eclect and
          traitor to the rebellion, ${fname} ${lname}, as Angels are my witness."
          
          All your focus is on Radmar's charging bulk, his upraised axe.  Even as you dodge the blow,
          *if poric < 1
            another outlaw's 
          *if poric > 0
            silent Poric's
          knife takes you in the back.  
          *goto_scene death
      *if (rad_mutiny or not(kal_here)) #I ask Radmar to change his mind and support me.
        The other outlaws who want to fight the Phalangites are clearly looking to Radmar for leadership.
        *if rad_mutiny
          Several followed him to mutiny before, and are ready to do so again.
        If you can sway him, the rest may follow.
        
        "Radmar," you implore, "I know you care about the band losing lives.  Especially 
        *if kids < 3
          the weak
        *if kids > 2
          children 
        or the sick.  Please, if ever you trusted my judgment…think again about the consequences for them if we try to fight the Archon's army."
        
        *if (poric < 1) and (alless < 1)
          "Thanks to you, ${addressu}, the folk I cared most about have already lost their lives." Radmar's face twists into a mask of hatred.
          *goto radkillyou
        *if (poric > 0)
          You know Poric is still frequently in ${abler}'s care; it's the only line of argument you can think of that might convince Radmar.
        *if r_rel < 10
          But he's unmoved. "If ever I trusted your judgment, ${kuria}, I stopped a swiving long time ago," the big fighter snarls.  It's soon clear that he won't be persuadable, so you appeal directly to the outlaws who support him.
          
          *goto warnochange
        *else
          He hesitates, lips pressed tightly together.  "Always so sure you're right, ${kuria}.  What are the consequences for them if we don't fight, if we're not willing to sacrifice ourselves to break this army, and it catches them?  Because the other choices I've heard so far—hiding in the woods, or back to the swiving camps? I don't believe the
          *if kids > 1
            children or the
          sick and weak are going to do well out of any of those."
          
          *if (cha > 0) and (poric > 0)
            "[i]Sacrifice ourselves[/i] to break the army?" You spotted the flicker of uncertainty in Radmar's followers' eyes when he used those words.  Now you press with sudden fierceness into what may well be his one vulnerability, your one chance to sway the debate.  "Is that truly the course you counsel, Radmar?  Defeat them, at any cost to the rebellion?  As long as it helps keep your Poric alive?"
            
            "I didn't…" Radmar sputters, outraged.
            
            "I care for the sick and the weak—but also for the rest of the band," you press on relentlessly.  "And this is the worst choice for the greatest number, Radmar.  Where even if things go as well as they can, we'll surely see dozens of us fall.  There must be other, better ways to protect the sick at a more tolerable cost."
            
            Putting all your
            *if cha = 1
              moderate
            charisma to work, you manage to end the day with a fragile consensus on your chosen strategy.  Radmar, however, is still refusing any part of it—and plainly dreaming of disemboweling you with his axe. 
            *if deputy = "Radmar"
              *label newdepneed
              There's no way that you can continue to work together as leader and deputy after so bitter a confrontation.  You need someone who supports the course you've chosen.
              *choice
                *if ((strategy = 2) and (el_here)) #I ${ask} Elery Skinner.
                  *if elezvad > 7
                    *if elezvad = 10
                      She flatly refuses, and won't hear otherwise.  "Angels, ${kuria}.  I'm in mourning, and in no mind to take the job that killed Zvad."
                    *if elezvad < 10
                      Her lips twist bitterly when you broach the topic.  "Did I not make myself sufficiently clear after Zvad died, ${kuria}?  I'd rather not see your face ever again, let alone be your deputy."
                    *goto alirasettle
                  "Very well, ${addressu}," Elery says briskly.  Any reluctance she might have felt at
                  *if e_rel < 10
                    working with you
                  *if e_rel > 9
                    taking on such a high responsibility
                  was driven out by the near-schism in the band today.  "We'll get everyone too busy preparing to slip back into arguing."
                  
                  *set deputy "Elery"
                  *set dephis "her"
                  *set dephe "she"
                  *set el_lead +1
                  *goto outwork
                *if (strategy = 2) #I ${ask} our chief tracker Alira.
                  *goto aliradep
                *if ((strategy = 3) and (bred_here)) 
                  #I ask Breden.
                    "Aye, ${bfname}," Breden says at once.  "And we'll get right down to it."
                    *set deputy "Breden"
                    *set dephis xhis
                    *set dephe xhe
                    *set bred_lead +1
                    
                    *goto outwork
                *if ((strategy = 3) and (simz_here and (s_rel < 9))) #I ${ask} ${simon} de Firiac.
                  "An honor, ${addressu}," ${simon} says, bowing deeply.  "We'll begin at once."
                  *set deputy simon
                  *set dephis zhis
                  *set dephe zhe
                  *set simz_lead +1
                  
                  *goto outwork
                  
                *if ((strategy = 3) and (not(bred_here) and (not(simz_here) or (s_rel > 9))))
                  #But I've no one of leadership caliber who supports it.
                    *if rescuer = 0
                      Old Joana Orchard supports the idea, but she's made it clear she won't be your deputy.  "Too frail for that, my dear ${fname}," she says ruefully. "You'll need someone with the energy for it—someone who's taken a bit less of the hard side of the hand."
                    *label alirasettle
                    
                    You settle in the end on Alira, your chief tracker.
                    *goto aliradep
            *page_break
            *set r_rel -10
            *set rad_lead -2
            *goto outwork
          You keep trying but fail to convince him.  After an exhausting day of debate, the band remains profoundly divided on the best way forward.
          *goto stalemate
      *if ((kal_here) and not(rad_mutiny)) #I ask ${kalt} to change ${zhis} mind and support me.
        *if k_rel < 5
          "You ask a lot, ${fname}," ${kalt} says in a low voice, sounding suddenly uncertain. "This may be the best chance we get while I'm alive to strike at the bastards."
          
          "The first chance—not the best," you insist.  "I'm sure of that…and if you trust my judgment at all, don't put the band at odds with me like this."
          
          $!{zhe} sighs and seemingly comes to a decision.  "We'll be ready for the fight," ${zhe} shouts to the assembled bandits. "One day.  One day, after we've worn them down. But ${addressu} ${lname} is right. This may be too early for a decisive battle."
          
          Radmar is furious at ${kalt}'s betrayal, and stalks away from the assembly as soon as it's clear that ${kalt}'s influence will tip the outcome toward you.
          *set kal_lead +2
          *set rad_lead -2
          *if deputy = "Radmar"
            *goto newdepneed
          *page_break
          *goto outwork
        *else
          ${kalt} shakes ${zhis} head vehemently.  "You're wrong, ${kuria} ${fname}. 
          *if k_rel > 7
            But you'd never admit that, would you?  So ready to preach to others, and make threats or shame us."  The resentment in ${zhis} eyes is turning to something like glee. As you realize what that must mean, your heart begins to pound.
            
            Radmar raises his axe, his own face ugly with resolution.
            *goto radkillyou
          You think we're weaker than we truly are.  Change your mind while you can."  
          
          $!{zhe} gives a small, meaningful nod toward Radmar. The big fighter's ferocity is visibly reaching levels you've only previously seen when he was in battle and about to cut someone down with his axe.
          *choice
            #Very well.  We'll prepare to face the Phalangites and win.
              *goto warchange
            #No—that path leads to disaster, and I won't be bullied into choosing it.
              *goto warnochange

*elseif popular = 2
  *if strategy = 2
    *if democ > 1
      It takes time to pacify the grumblers.  In the end, though, the
    *if democ < 2
      When you head out and announce your decision to the whole band, it soon becomes clear that most of them back your lead. The 
    minority who dream of beating the Thaumatarchy give way to the more cautious majority.  
    *if (religion > 10) and (religion < 20)
      Some of whom aren't all that cautious: "The Angels have spoken to me, ${addressu}," one cries ecstatically, "and promised that we'll survive if we only follow the path They've shown us!"
      
      *set morale +10
    *if nonkids < 45
      Radmar scowls but doesn't gainsay you, and 
      *if kal_here
        for all ${zhis} fury, ${kalt} soon accepts
      *if not(kal_here)
        the other young hawks grudgingly accept
    *if nonkids >= 45
      *if kal_here
        With ${kalt}'s support,
      Radmar holds out furiously for a while, but it's soon clear even to him 
    that most outlaws don't have the appetite to go toe to toe with the Archon's army.
    
    *if bred_here
      Just when you think the debate is over and the band behind you, Breden cuts in smoothly. "I'm glad we don't think we can beat the Thaumatarchy, ${bfname}.  But think again before you commit us to hide in these woods.  Would escaping them really be that much more likely than defeating them?  Our only real safety is in splitting up—dividing into too many coveys for them to catch us, and creating hundreds—no, thousands!—of new coveys back in the helot camps and smallholds of the Rim."
      *choice
        #"Going back to the Rim is hardly safe, whether we do it in groups or as a mass."  I'm not changing my mind.
          *goto outwork
        #$!{xhe} might be describing the future of our rebellion—but not until after we've survived the summer.
          "No course is without risk, Breden—but our best chance of surviving is here in the wilderness, where outlaws have always had free rein."  Most of your followers loudly agree with you, and Breden reluctantly accedes.
          
          *goto outwork
        #"You're right.  Let's send as many back as we can before the attack—it'll make it easier for those who remain to hide here."
          At first, the change of strategy spurs a chorus of protest from the rest of the band—but
          *if cha = 2
            your and
          Breden's charisma carries you through.  
          *gosub okmindch
          
          By the end of the day, you've forged a fragile consensus around the new plan of returning to the Rim.
          *set strategy 3
          
          *goto outwork
    *goto outwork
  *else
    *comment if strategy != 2
    *gosub wrongstrat
    *if strategy = 1
      *if kal_here
        ${kalt} and Radmar don't
      *if not(kal_here)
        Radmar doesn't
      have enough influence to win people over.
    "We don't want to 
    *if strategy = 1
      throw our lives away
    *if strategy = 3
      run back to the Rim, 
    ${addressu}," 
    *if el_here
      Elery
    *if not(el_here)
      your tracker Alira
    protests, speaking for the majority of your followers.  "All we want to do is get ready to evade 
    *if strategy = 1
      them."
    *if strategy = 3
      them here, in the woods we know."
    *if (religion > 10) and (religion < 20)
      
      Another cries out wildly, "The Angels have spoken to me, ${addressu}—and promised that we'll survive if we only follow the path They've shown us!"
      *set morale +10
      *set runvote +2
    
    *if zv_here
      Zvad steps forward, clearing his throat.  "$!{addressu}, I'd not lightly speak against your lead.
      *if deputy != "Zvad"
        I'm not even your deputy.
      But 
      *if strategy = 1
        this is madness.  These Phalangites are skilled soldiers.  They'll bring Theurges, maybe even Xthon'damned Plektoi.  We can't beat them."  He stares at you imploringly.
      *if strategy = 3
        I can't help but feel there's far more risk in splitting up and trying something none of us have done before, rather than moving together as one band in the wilderness we 
        *if rescuer = 0
          all now 
        know."
    *choice
      #I grudgingly accept the will of the band.  We'll hide in the woods and try to evade the attackers.
        *if zv_here
          *set zv_lead +1
        *if el_here
          *set el_lead +1
        *set strategy 2
        *goto outwork
      #I insist on my original decision.
        *label argueorig
        *if (cha = 2) or eclect
          Thanks to
          *if cha = 2
            your charisma as a leader,
          *if cha != 2
            your authority as Eclect,
          you manage to sway much of the band to your side.
          *label isitenuf
          *if ((strategy = 1) and ((warvote+2) > runvote)) or ((strategy = 3) and ((govote+2) > runvote))
            By the end of a long day's debate, you've created a fragile consensus.
            
            *goto outwork          
          But it's not enough to overcome the majority who want nothing but to stay in the woods.
          *goto stalemate
        *if (cha < 2) and not(eclect)
          You do your best—but your charisma simply isn't enough to overcome the band's determination.  It's clear that whatever you declare, for the time being they're going to prepare for the strategy they believe in: staying in the Whendward wilds and evading the Phalangites.
          *set strategy 2
          
          *goto outwork
      *if (zv_here) #Ask Zvad to change his mind and support me.
        *if deputy = "Zvad"
          *set armtwist true
          "You are the Whendward Band's deputy, Zvad," you say in a low, intent voice, "and I expect your full loyalty."
          
          Zvad's jaw works for a moment before he growls, "And you have it, ${kuria}.  Thought you knew already. When I advise you, it's out of loyalty.  Disagree or agree."
          
          "Today, I need more than just your advice."  Your gesture takes in the band members behind you. "Today I need you to agree.  And I need them to agree."
          
          After a stretch of silence, Zvad turns to the band and gruffly joins you in making the case for
          *if strategy = 1
            defeating the Archon's forces.
          *if strategy = 3
            infiltrating the Rim.
          *if elezvad > 7
            Elery stares at him in disbelief for a moment, then turns a gaze of scalding contempt on you and redoubles the heat and volume of her argument.
            *set runvote +3
            *set e_rel -8
          *goto isitenuf
        *if deputy != "Zvad"
          Zvad's skepticism about 
          *if strategy = 1
            defeating a Phalangite army
          *if strategy = 3
            infiltrating the Rim
          proves too deep-seated to shift.  So you turn your efforts back to the rest of your assembled outlaws.
          
          *goto argueorig
      *if (el_here) #Ask Elery to change her mind and support me.
        *if e_rel > 9
          Elery shakes her head, looking pained. "$!{kuria}, I just don't think we can
          *if strategy = 1
            defeat a Phalangite army,
          *if strategy = 3
            infiltrate the Rim,
          and I don't want to see my brother die trying."
          
          "If we fail, there will be a remnant who can run and hide—including Yebben.  But if the first thing we try is hiding from the Theurges hunting us…what can we try when that fails?"  You lean forward, catching her arm.  "Just think for a moment that you might be wrong.  And ask yourself if you can trust me."
          
          She pulls away from you and stalks off.  To your relief, a minute or two later she rejoins the debate, this time arguing fiercely against the idea that hiding in the woods is the safest course.
          *if elezvad > 7
            Taken aback by her reversal, Zvad falters and lapses into a gloomy silence.
            *if strategy = 1
              *set warvote +3
            *if strategy = 3
              *set govote +3
          *goto isitenuf
        *elseif (e_rel > 0)
          *if (bvote) and (strategy = 3)
            "You've heard Breden make the case, Elery," you whisper. "If you won't listen to me, listen to ${xhim}."
            
            Elery glares at you and snorts…but a moment her eyes flicker guiltily to her friend.  Over the next few minutes of debate, her position shifts until she's arguing for a return to the Rim as the wisest course.
            *if elezvad > 7
              Taken aback by her reversal, Zvad falters and lapses into a gloomy silence.
              *set govote +3
            *goto isitenuf
          "If we try what I'm suggesting and fail, there will be a remnant who can run and hide.  But if the first thing we try is hiding from the Theurges…what can we try when that fails?"
          
          Elery shakes her head.  "We won't fail, ${kuria}.  At any rate, we're less likely to fail at this than we are at…whatever you'd have us do."  Her voice is heavy with distrust. 
          
          In frustration, you turn back to the rest of your assembled outlaws.
          *goto argueorig
        *else
          Elery's lip curls as she listens to your appeal. When she speaks, it's with a note of honest bafflement.  "Why by Xthonos did you think I would listen to a damned thing you have to say,
          *if aristo
            ${kuria}
          ${lname}?  You've been wrong about the most important things so far." 
          
          In frustration, you turn back to the rest of your assembled outlaws.
          *goto argueorig
*elseif popular = 3
  *if strategy = 3
    *if democ > 1
      It takes time for the excitement to spread to every corner of the grove—for it to become clear that despite some qualms, 
    *if democ < 2
      Only when you announce your decision to the whole band and they break into cheers does it become clear that yours is the most popular choice—that
    most of your followers truly do want to return to the Rim and covertly spread rebellion through the helot camps.
    *if zv_here
      
      Zvad looks skeptical, murmuring that with stakes like these, he'd rather keep to what your bandits know best.  But he yields to the band's enthusiasm for returning to the Rim.
    *if (religion > 10) and (religion < 20)
      "The Angels have spoken to me, ${addressu}," one band member cries, "and revealed that the path of victory runs backward!"
      *set morale +10
      
      *if not(kal_here) and (nonkids >= 45)
        Notwithstanding the Angelic revelation,
    *if not(kal_here) and (nonkids < 45)
      You think Radmar would have protested had there been only a handful more fighters in your band—but he grudgingly accepts the reality that you can't take on the Archon's forces with so few.
      
      *goto outwork
    *if not(kal_here) and (nonkids >= 45)
      Radmar remains the most vocal opponent of the idea.  "It worked out pretty damned badly last time, ${addressu}," he 
      *if not(bred_here)
        warns, voice loud enough to carry to the whole band.
      *if bred_here
        shouts, silencing Breden with a caustic, threatening glare.
      "Why by Xaos do you think we'll be able to evade their notice?  We failed at that even before there was an actual rebellion to keep them all on edge!"  Turning from you, he bellows,
    *if kal_here
    
      "But why in Xthonos's name are we here?" ${kalt} suddenly shouts, striding to the fore of the assembly. "Why did we flee to a place where we have to eat our bread flat and half-raw, where the bears stalk us in summer and the wolves in winter?  Because there [i]is no place[/i] in the camps for rebels.  
      
      "Have you already forgotten?  Have you forgotten the foremen listening, the traitors whispering, the Theurges picking any troublemaker out and feeding them into the Harrower?  Why would you think it would be any different now?"
      
      *if not(bred_here)
        The disheartened-looking Radmar straightens up at this speech and bellows his assent.
      *if (bred_here)
        "This rebellion started in a helot camp, ${kalt}," Breden retorts hotly.  "It…"
        
        "This rebellion almost died in a helot camp," Radmar snarls, hefting his axe and marching to ${kalt}'s side.
        *if nonkids < 45
          A few minutes ago, he was visibly uncertain about your ability to break a Phalangite army, but Breden's voice seems to have put the fury back into him.
        "You dare raise your voice on this, Reaper?  You dare to pretend—again!—that we could avoid Their eyes, that we can talk sedition without Them hearing?  What by Xaos do you truly want for this rebellion, ${xgirl}?"
        
        As Breden falters, ${kalt} calls,
        *set govote -3
    "Stand and fight, 
    *if addressc != "children"
      ${addressc}!  
    *if addressc = "children"
      sisters and brothers!
    The Whendward is the only place we can do it—the only place we can beat them.  Take the chance!"
    *choice
      #I'm not changing my mind.  We'll not win the rebellion in these woods.
        "The rest of the band disagrees with you,
        *if kal_here
          ${kalt} and
        Radmar," you say curtly.  "There's danger down any road we choose—but what you're calling for is madness!" You glance at
        *if zv_here
          Zvad,
        *if not(zv_here) and el_here
          Elery,
        *if not(zv_here) and not(el_here)
          Alira,
        who nods in forceful agreement.  "We need to take the risk that has the greatest chance of spurring a true rebellion.  That means not throwing ourselves under their swords like fools.  And it means leaving the woods."
        
        In the end, 
        *if kal_here
          ${kalt} and 
        Radmar's dissent isn't persuasive enough to shake the majority who support you.
        
        *goto outwork
      #All right.  We'll prepare to stand, fight, and break them.
        *if eclect
          *set govote -4
        *if democ > 0
          *goto mindchange
        *if democ = 0
          *set govote -3
          *set warvote +3
          *set strategy 1
          *gosub popcalc
          *if warvote < (govote-5)
            *gosub protests
            *goto stalemate
          *gosub okmindch
        *goto outwork        
      #We'll evade them in the woods instead.
        *if eclect
          *set govote -4
        *if democ > 0
          *goto mindchange
        *else
          *set govote -3
          *set runvote +3
          *set strategy 2
          *gosub popcalc
          *if runvote < (govote-5)
            *gosub protests
            *goto stalemate
          *gosub okmindch
          *goto outwork                
  *else
    *comment if strategy != 3
    *gosub wrongstrat
    *if strategy = 1
      But the
    *if strategy = 2
      The 
    reluctant voices soon grow in volume and intensity.
    
    "The rebellion won't be won in these woods, ${addressu} ${fname},"
    *if bred_here
      Breden
    *if not(bred_here) and (simz_here and (s_rel < 10))
      ${simon}
    *if not(bred_here) and (not(simz_here) or (s_rel > 9))
      *if rescuer = 0
        Old Joana Orchard
      *if rescuer > 0
        one of them
    declares, quietly but firmly.
    *if bred_here
      Only now do you realize how well ${xhe}'s been preparing the ground for this moment, using ${xhis} credibility as a leader to win half the band over to ${xhis} plan before it ever came to
      *if democ > 1
        ${a_moot}.
      *if democ < 2
        a decision.
      "Most of us understand that.  I'd hoped that you would, too."  $!{xhe}'s leaving open the possibility for you to save face.
    *if (mules < (followers/25)) and (strategy = 2)

      "We don't have enough bloody mules to move the band fast enough, ${addressu}," one of your followers shouts. "We'd need more if we're to outrun them."      
    *if (religion > 10) and (religion < 20)
    
      "The Angels have spoken to me, ${addressu}," another outlaw cries ecstatically, "and revealed that the path of victory runs back through the tents of the helotry!"
      *set morale +10
      *set govote +2
    *choice
      #I grudgingly accept the will of the band.  We'll move back to the Rim.
        *if simz_here and (s_rel < 10)
          *set simz_lead +1
        *if bred_here
          *set bred_lead +1
          *if strategy = 1
            When you announce your change of mind, a furious chorus of protest rises from the young hawks who wanted to take on the Hegemony.
            *goto radvbred
        *set strategy 3
        Though
        *if kal_here
          ${kalt} and
        Radmar 
        *if not(kal_here)
          and his loyalists
        protest loudly, in the end they have to accept that most of the band are unwilling to join their rash stand against the Hegemony.
        
        *goto outwork
      #I insist on my original decision.
        *label argueorig2
        *if (cha = 2) or eclect
          Thanks to
          *if cha = 2
            your charisma as a leader,
          *if cha != 2
            your authority as Eclect,
          you manage to sway much of the band to your side.
          *label isitenuf2
          *if ((strategy = 1) and ((warvote+2) > govote)) or ((strategy = 2) and ((runvote+2) > govote))
            By the end of a long day's debate, you've created a fragile consensus.
            
            *goto outwork          
          But it's not enough to overcome the majority who are determined to return to the Rim.
          *goto stalemate
        *else
          You do your best—but your charisma simply isn't enough to overcome the band's determination.  It's clear that whatever you declare, for the time being they're going to prepare for the strategy they believe in: leaving the Whendward wilds and returning to the Rim.
          *set strategy 3
          
          *goto outwork
      *if (bred_here) #Ask Breden to change ${xhis} mind and support me.
        *if (strategy = 2) and ((bred_trust < 10) and (bred_heart < 10))
          $!{xhe} answers you with an equally passionate appeal of ${xhis} own. "$!{bfname}…would escaping the Hegemony really be that much more likely than defeating them?  Our only real safety is in splitting up. Divide into too many coveys for them to catch us, and create hundreds—no, thousands!—of new coveys back in the helot camps and smallholds of the Rim."
          
          Lowering your voice, you point out, "Breden…those coveys wouldn't be safe.  Any more than we were in Rim Square.  And when they start being caught like we were,
          *if (bred_lover >= 4) or (bred_heart = 3)
            love,
          when they start being Harrowed…who do you think people are going to blame?"  You glance at Radmar, who's still trying to convince other outlaws to stand and fight.
          
          Breden looks stricken, and more than a little angry. "Are you always going to see that stain on me, ${bfname}?  Will I never work it off?"
          
          You give a small, firm shake of your head.  "Help us escape the Phalangites in the woods this summer.  Yield now—and I swear, when we have more time and can take more care, we'll plan to start sneaking our coveys back into the Rim.  A plan we can all share.  After we've survived."
          
          After glaring at you for a minute, ${xhe} purses ${xhis} lips and turns back to the band. "This may not yet be the time," ${xhe} begins, ${xhis} tone reluctant but firm.  You fight to keep your relieved smile from being too provocatively broad.
          *set strategy 2
          *page_break
          *goto outwork
        *if strategy = 1
          "I can't do that, ${bfname}," Breden says
          *if bred_heart >= 10
            angrily
          under ${xhis} breath.
          *if (bred_lover >= 4) or (bred_heart = 3)
            $!{xhe} sounds pained but unrelenting.
          "Maybe for some other strategy, but not for a stand that will kill us all.  I simply can't."
          
          "It's not going to kill us!" you snap.
          *if deputy = "Breden"
            "$!{oath}! I need a deputy who won't sow fear among the band before a battle."
        *if (bred_trust > 9) or (bred_heart >= 10)

          "No, ${bfname}."  There's no hint of doubt in Breden's refusal. "And don't ask me to trust you, when you've 
          *if deputy != "Breden"
            not 
          *if deputy = "Breden"
            only grudgingly
          given me the trust you'd give a wolf in the woods."
          
        In frustration, you turn your back on ${xhim} and address the rest of your assembled outlaws.
        *goto argueorig2
      *if (simz_here and (s_rel < 9)) #Ask ${simon} to change ${zhis} mind and support me.
        *if (s_rel > 4)
          The young noble shakes ${zhis} head coolly. "No, ${addressu}.  I'll not support your leading the band into unnecessary violence.
          *if strategy = 1
            Especially when it's likely to kill us all."
          *if strategy = 2
            Even if it's just more hiding in the woods."
          
          In frustration, you turn your back on ${zhim} and address the rest of your assembled outlaws.
          *goto argueorig2  
        *if (s_rel = 4)
          You lean in and say quietly but firmly, "${simon}…when we ambushed Hector, you failed us by not pressing the pursuit hard enough.  I understand that you'd want to avoid that kind of situation again.  But it's the wrong choice, and it's hurting the band."
          
          $!{zhe} looks stricken, and begins protesting that ${zhe} had no such thing in mind.  You cut ${zhim} off.  
        "We fled out here for a reason, de Firiac. No rebel movement can survive in the camps.  Not yet.  Don't push us back there when time is against us, when we need all our resources for survival."
        
        The doubt is obvious in ${simon}'s eyes. "If you're so sure, ${addressu}, then aye.  This time I'll back you."  $!{zhe} stops arguing for infiltration of helot camps, and ventures a few thoughts in support of your preferred strategy.
        *if bred_here
          $!{zhis} defection leaves Breden as the sole leader advocating for the majority.  But of course, even in isolation, Breden's charisma makes ${xhim} a formidable opponent.  
          
          You argue with ${xhim} and ${xhis} supporters for hours, making the case for
          *if strategy = 1
            trying to deal the Hegemony a stinging defeat.
          *if strategy = 2
            keeping to the woods and evading the Archon's forces.
        *goto isitenuf2
*else
  *bug shouldn't be another "popular" option
  
*label mindchange
*set morale -3
Your shift throws the whole band into an uproar.  If their
*if eclect
  supposedly Angel-Chosen
leader is so divided in ${his} own mind that ${he} can publicly advocate two different strategies within minutes, then why should
*gosub popcalc
*if democ = 1
  the band's "elders" allow ${him} to determine their direction?  The influential outlaws you chose to invite into the Leaders' Tent return there now with ${deputy} to argue it out amongst themselves, largely ignoring your attempts to re-enter the discussion.
  
  It soon becomes clear that the course which has the greatest support amongst these "elders" is
  *if eldchoice = 1
    standing and fighting.
    *if (popular != 1)
      *gosub bandpref
      *if (govote > (warvote+(wareld*2))) or (runvote > (warvote+(wareld*2)))
        *gosub followband
        *goto acceptchoice
      *gosub whocares
  *if eldchoice = 2
    running and hiding.
    *if (popular != 2)
      *gosub bandpref
      *if (warvote > (runvote+(runeld*2))) or (govote > (runvote+(runeld*2)))
        *gosub followband
        *goto acceptchoice
      *gosub whocares
  *if eldchoice = 3
    returning in small groups to the helot camps and smallholds of the Rim.
    *if (popular != 3)
      *gosub bandpref
      *if (warvote > (govote+(goeld*2))) or (runvote > (govote+(goeld*2)))
        *gosub followband
        *goto acceptchoice
      *gosub whocares
  *set strategy eldchoice
*if democ > 1
  the ${moot} be guided by ${him} further?  The assembled
  *if kids > 2
    adult
  bandits fall to debate, with ${deputy} and other influential leaders clearly having more sway than you do.
  
  It soon becomes clear that the course with the greatest popular support is
  *if popular = 1
    standing and fighting.
  *if popular = 2
    running and hiding.
  *if popular = 3
    returning in small groups to the helot camps and smallholds of the Rim.
  *label acceptchoice
  *set strategy popular
*choice
  *if (democ > 1) #I accept the band's choice.
    *set strategy popular
    *goto outwork
  *if (democ = 1) #I accept the elders' judgment.
    *set strategy eldchoice
    *goto outwork
  #I refuse to accept it.
    *set refused true
    By the end of the long day's brutal debate, you've very narrowly avoided a mutiny—but your followers are divided to the point of paralysis.
    *goto stalemate
    
*label stalemate
Your 
*if refused
  rivals'
attempts to 
*if strategy = 1
  ready the band for battle
*if strategy = 2
  mobilize the band for a run-and-hide strategy
*if strategy = 3
  dispatch rebel infiltrators to helot camps
over the following weeks 
*if not(refused)
  are challenged at every step, 
*if refused
  undercut your own counter-efforts,
and the resulting preparations are half-hearted at best.
*if refused
  
  At long last, you recognize that you're going to have to be the one to relent if the rebellion is to have any hope of prevailing.  Having allowed
  *if democ = 1
    the elders their role,
  *if democ > 1
    rule by ${moot}, 
  you can't now reject the outcome.  But the damage is already done.
*set popular 10
*set morale -10
*page_break
*goto keephosts

*label outwork
Over the following weeks, you begin outworking the strategy
*if democ > 9
  chosen at the ${moot}.
*if democ = 1
  agreed upon with the band's "elders."
*if democ = 0
  you've chosen.
*if strategy = 1
  The band's warriors drill endlessly with bow and arrow,
  *if arms > 0
    as well as captured swords, spears, and maces,
  preparing to wear down the enemy before breaking them.
  *if kal_here
    ${kalt} practices with them at all times, and ${zhis} stream of fiery rhetoric (as well as Radmar's determined, vaguely menacing presence) keeps anyone from too publicly airing their fears. 
    
    "Let them come already!" ${kalt} laughs. "We've enough arrows to put one in both eyes of every Phalangite, with a few left over for whatever Alastors and other scum they dredge up." $!{zhe} also widely hints that the band's leaders have settled on a strategy for felling the enemy Theurges—though from your private councils, you know that this remains one of the areas where your plans are most tenuous.
    *set kal_lead +2
  *if not(kal_here)
    Radmar leads the weapons 
    *if zv_here
      practice along with a still-reluctant Zvad.  
    *if not(zv_here)
      practice.
    The big former helot is up with the dawn every day, moving from group to group of fighters. His determined, vaguely menacing presence keeps anyone from too public an airing of their fears.
    *set rad_lead +2
  *if korszata > 0
    *page_break
    *set intel +1
    Korszata and Bjel spend hours conferring with you and ${deputy}, discussing what to expect from the Archon's forces.  It's hard to quell your fluttering innards as they describe the efficiency of Phalangite tactics.
    
    "So to sum up," you say a bit hoarsely at the end, "they'll locate us from the air, encircle us with their soldiers, break us with a hard Theurgic hit, or possibly Plektoi hounds, and then wipe us out when we flee."
    
    Bjel nods, looking pensive. "They will not send massed arms against bows in the woods, or attack a fortified position.  They will not need to, when their Theurges can burn us out."
    
    "Why bring the swords at all?  Why not just destroy us when they first spot us?" ${deputy} queries. "Fly in a few dozen Theurges, then set every tree for miles around ablaze, or pull down a mountain on our heads?"
    
    "Against Halassurqs, the battle might go so.  But I think it takes a Theurge much blood to kill or destroy even one person, let alone 
    *if followers > 199
      hundreds,  
    *if followers < 200
      dozens,
    or to lay waste to an area." Korszata exhales through his teeth. "Theurges who put down rebels want to come back with more blood, not less.  So they break us and capture as many as they can, drag us to nearest Harrower in the Rim.  As long as they are believing they can break us and take prisoners, they will try to defeat us with soldiers instead of Theurgy."
    
    "Then damn their eyes."  You lean forward, almost trembling with the intensity of the moment, the importance of what you need to devise.  "Let's find a way to turn their plan against them."
    *page_break
*if strategy = 2
  *if el_here
    Elery and Alira disappear into the woods with the band's finest trackers to identify more places where you can trap Phalangites or strike from hiding.  Meanwhile,
  *if zv_here
    Zvad and
  *if not(zv_here) and rad_here
    Radmar and
  *if not(zv_here) and not(rad_here)
    you and
  your outlaws drill endlessly at the skills you've acquired since fleeing Rim Square: how to make and break camp quickly, cook without smoke, move from cover to cover.  It helps that in the dry, warm summer weather most of you aren't sleeping under canvas.
  
  The test comes one morning when you and ${deputy} rouse everyone just before dawn.  Despite their surprise, within minutes all your followers have snatched up their gear and are hiding in small groups under thick tree cover. "We're ready, ${addressu} ${fname}." ${deputy}'s smile betrays only a slight nervousness. "Let them come."
  *page_break
  From that point on, you begin practicing the even greater challenge: moving by night.  After the last daylight is gone, you begin seeing how much further you can travel in an hour or two before bivouacking in total darkness.  The first few times, you allow the outlaws to talk, but soon you're trying it in silence, albeit one often broken by discontented mules or scree slipping downhill.  
  
  You've soon confirmed that the lightly forested Whendward slopes get enough moonlight to make a midnight march dangerous but possible.  As long as your scouts can identify a route ahead of time that won't lead to a cliff or a densely forested valley, your band can move by night, when neither Theurges nor enemy scouts should be about.
  *if (int > 1) or el_here
    
    On one grueling drill, another young outlaw just ahead of you slips off a boulder with a yelp.  By the time you've rescued him, confirmed that nothing's broken, and get moving again, you've completely lost touch with the train ahead of you and have to shout to reestablish contact. "Well, that'll have roused every Theurge within a mile or two,"
    *if rad_here
      Radmar
    *if not(rad_here)
      Alira
    says wryly when you finally reconnect.
    
    The next morning, 
    *if int > 1
      you're inspired to create
    *if (int < 2) and el_here
      Elery offers an idea to improve your cohesion in the dark:
    an agreed marching order, where each bandit knows who should be ahead of and behind them, as well as a set of simple tapped signals, finger to palm, to communicate what's going on.  That night, all 
    *set d2n_num followers
    *gosub d2n
    of your followers arrive at the night's bivouac point within 
    *if followers < 20
      a few minutes
      *goto howlongnite
    *if followers < 50
      fifteen minutes
      *goto howlongnite
    *if followers < 150
      half an hour
      *goto howlongnite
    an hour
    *label howlongnite
    of each other—a great improvement on your previous marches.
    *if (int < 2) and el_here
      No one can see how Elery responds to the band's hushed but heartfelt cheer, but you can imagine her grin.
      *set el_lead +1
*if strategy = 3
  *set helcamp +round(followers/7)
  *gosub helcampcheck
  During the winter, you identified a few 
  *if cred_y > 170
    smallholder villages and
    *set helcamp +round(followers/7)
    *gosub helcampcheck
  helot camps which you hope are friendly enough to host a small group from your band.
  *if (rescuer > 0) or not(zv_here)
    You and ${deputy}
  *if (rescuer = 0) and zv_here
    "It'll end our plan of testing everyone who might be a traitor, ${addressu}," Zvad rumbles to you in one final protest.  "We haven't yet finished everyone, you know."
    
    "Yes, but it also reduces the consequences.  They'll have fewer people to betray, whether here or back in the camps."  Later, 
    *if deputy != "Zvad"
      with ${deputy},
    you 
  scan the crude map of the Outer Rim ${dephe} has sketched in the dirt. "If we can send our coveys out quickly and thoroughly enough…by the time the Phalangites arrive they'll be combing the wilderness for a rebel army that simply isn't here."
  
  "At which point they'll return to the Rim and scour every camp and hamlet for us," your deputy points out 
  *if (deputy != "Breden") and (deputy != simon)
    nervously.
    
    "We'll be ready.
  *if (deputy = "Breden") or (deputy = simon)
    calmly.  "We need to be prepared for that, too."
  
    "We will be.
  They won't be…and by just storming into every helot tent looking for us, they'll win us new credibility and new followers."  It's a plausible enough story, even if you put a bit more confidence into your prediction than you truly feel.
  *if followers < 40
    "But there are so few of us, ${deputy}.  We need to take care in choosing the right camps, or the whole rebellion could be wiped out by one or two betrayals."
    
    $!{dephe} nods ${dephis} assent.  "Few enough of us that the Phalangites will find it hard to hunt us down, ${addressu}.  So we shouldn't need to rush out of these woods.  Let's take the time to make sure we've found the right hosts first."
  *page_break
  *if cha = 2
    You throw yourself into the campaign, visiting several camps in person to introduce your small rebel coveys.  Thanks to your
    *if bred_here
      and Breden's
      *set helcamp +round(followers/7)
      *gosub helcampcheck
    charismatic appeal, the helots give you a cautious welcome.
    *set helcamp +round(followers/7)
    *gosub helcampcheck
  *if cha < 2
    It takes a lot of persuading to get helot camps to accept a rebel presence—and your 
    *if cha = 1
      moderate
    *if cha = 0
      poor
    charisma is not much help.  But
    *if bred_here
      Breden partly makes up for it; and
      *set helcamp +round(followers/7)
      *set bred_lead +1
      *gosub helcampcheck
    a few at a time, your coveys begin to find a welcome.
  *if kids > 2
    Unsurprisingly, groups that include some of the band's 
    *if kidsdead > 9
      surviving 
    children are especially likely to be received well.
    *set helcamp +round(kids/6)
    *gosub helcampcheck
  *if religion > 0
  
    The first outlaws you send back to the Rim are some of your most passionate devotees, bringing not just the word of rebellion but a 
    *if religion > 20
      call to the life of kenon.  The strange Nereish-seeming rites alienate more helots than they attract, at least at first.
      *set helcamp -round(followers/7)
      *gosub helcampcheck
      *set cred_h -5
      *goto friendlycamps
    *elseif religion > 10
      testimony to the voice of the Angels.  The idea that any yeoman or helot can hear revelations as truly as any Ecclesiast catches like a spark in dry grass.  Soon, your small groups are getting invitations to come deeper into the Rim, in towards Rimmersford, to begin spreading the word in places you'd never heard of before.
      *set helcamp +round(followers/5)
      *gosub helcampcheck
      *set cred_h +10
      *goto friendlycamps
    *else
      call to follow the rebel Eclect.  The idea that the Angels have Chosen an earthly leader outside the priesthood is polarizing; some helots immediately throw out your followers, shouting that the last thing they need is blasphemers as well as rebels.  But rather more are cautiously curious…and your small outlaw groups find a temporary home, and your legend grows.
      *set helcamp +round(followers/6)
      *gosub helcampcheck
      *set cred_h +5
      *goto friendlycamps
  *label friendlycamps
  
  *if literate > 2
    You find it also proves very helpful that 
    *if diakon > 9
      (since the arrival of the Diakons)
      *goto nowlit
    *elseif etthena > 0
      (since the arrival of Etthena and the Disbelievers)
      *goto nowlit
    *elseif bethune > 0
      (since the arrival of Bethune and her fellow Westriding yeomen)
      *goto nowlit
    *else
      *goto nowlit
    *label nowlit
    you now have
    *set d2n_num literate
    *gosub d2n
    outlaws who can read and write.  Their ability to leave coded messages for each other, carved into trees and walls across the Rim, helps them maintain and protect the steady flow of your followers back to the camps.
    *set helcamp +(literate*4)
    *gosub helcampcheck
    
  *if cred_h < 160
    *set helcamp -round(followers/9)
    *gosub helcampcheck
    Still, thanks to your
    *if aristo
      noble background and
    choices of the past winter, your reputation with the helotry is weak. "There just aren't enough friendly camps," 
    *if bred_here
      Breden 
    *if not(bred_here) and (simz_here or (s_rel < 9))
      ${simon}
    *if not(bred_here) and (not(simz_here) or (s_rel > 8))
      ${deputy}
    groans after the third week. "We've not done enough to bring the helots onto our side, ${addressu}."
    
    "Keep working," you plead. "We need 
    *if followers >= 40
      to get more of the band out before the attack comes."
    *if followers < 40
      their support if we're to carry the rebellion out of these woods."
*label keephosts
*if ((s_rel > 9) and simz_here) or horhostage
  *set hdead 1
  
  *if (not(linhostage) and (s_rel < 10))
    *set hosthem "him"
  *if not(horhostage)
    *set hosthem zhim
  *if strategy < 3
    *if horhostage and (hosthem != "them")
      Horion ${delelle} is
    *if ((s_rel > 9) and simz_here) and (hosthem != "them")
      ${simon} de Firiac is
    *if hosthem = "them"
      Your noble hostages are
    an increasing burden as you prepare for the summer fighting.
    *if deputy = simon
      "Free Horion, ${addressu}," ${simon} pleads again. "We'll have no ransom for him, nor anything but the enmity of the nobles if we kill him."
    *if deputy != simon
      "A drag on us, ${addressu}," ${deputy} describes ${hosthem} frankly. "Keeping ${hosthem} from dying or escaping—or even revealing us to the Theurges—won't be easy when the Archon's forces get here."
      *if deputy = kalt
        The lethal glint in ${zhis} eyes suggests ${zhis} preferred solution.
  *if strategy = 3
    One thing you can't do back in the helot camps of the Rim is keep noble hostages.
  *if ((horion > 3) and (horion < 8)) or ((s_rel > 9) and simz_here)
    You've had no response to your ransom demands, and the hour is fast approaching when you'll need to take decisive action.
  *choice
    *if (strategy = 3) #I'll hold onto ${hosthem} until the last group, with me and ${deputy}, sneaks back into the Rim.  Then I'll decide what to do.
      *goto lastweeks
    *if (strategy < 3) #I want to keep ${hosthem} with us.  It may give the Theurges some pause before trying to set us all afire.
      *goto lastweeks
    #I want to free ${hosthem} now.
      *if horion > 0
        *set horion +11
      You let ${hosthem} go in a day or two, when you next swing close to the Whendward Pass.
      *if deputy != kalt
        "Wise move, ${addressu}," ${deputy} agrees. "Too much trouble to try keeping ${hosthem}."
      *set hdead 0
      
      *if (horion < 1) and ((s_rel > 9) and simz_here)
        *gosub simzfree
      *set violence -1
      *page_break
      *goto lastweeks
    #I want to execute ${hosthem} now.
      *set violence +1
      The 
      *if hosthem = "them"
        killings of your hostages are
      *if hosthem != "them"
        killing of your hostage is
      quick and undramatic.
      *if rad_here
        Radmar 
      *if not(rad_here) and (demerre > 2)
        Ora
      *if not(rad_here) and (demerre < 3)
        The young bandit you have guarding ${hosthem} through the third watch
      agrees to do it early in the morning, without drawing attention.
      *if (not(rad_here) or (hor_guard != "Radmar")) and (hor_guard != "Alira")
        "As long as ${hor_guard} isn't around to interfere, ${addressu}."
      *if (deputy = "Breden") and not(horhostage)
      
        "That was needless, ${bfname}." Breden glares at you when ${xhe} learns of it. "The young de Firiac was a fool, but we might yet have got some benefit from ${zhis} release."
        
        "We don't need fools," you retort. "We need nobles to take us seriously when we demand a ransom."
      *if (deputy = "Radmar") 
      
        "Done, ${addressu}," he growls when he sees you at the meal circle.  "Took ${hosthem} out
        *if hosthem = "them"
          one by one
        to the rocks.  Axe to the neck.  All over quickly and cleanly."  He tucks into his breakfast with gusto.
      *if ((deputy != simon) and (deputy != "Radmar")) or ((deputy = "Breden") and horhostage)
      
        "Well, ${addressu}," ${deputy} says resignedly when ${dephe} learns of it, "we were never likely to get a ransom for ${hosthem} anyway."
      *if (s_rel < 9) and simz_here
      
        *gosub simonflee
        Meanwhile, you have to decide what to do with
        *if linhostage
          Linos and Horion's bodies.
        *if not(linhostage)
          Horion's body.
      *set simz_here false
      *set hdead 0
      *if horhostage
        *set horion 0
        *if delelle = "de Lelle"
          *set horion -1
        *gosub horbody
        *goto lastweeks
      *page_break
      *goto lastweeks
*page_break
*label lastweeks
*if (uthwen > 1)
  The next afternoon, to your surprise, you hear that a party of warriors are approaching your camp.  It turns out to be twenty-three Brecklanders from Uthwen's village, guided in from the forest by Grey Labedan. 
  
  "Heard you're about to have some trouble, ${kuria} ${lname}," their leader Treth drawls.  He's got a bow on his back and four knives in a sheepskin bandolier. "Thought after all that mutton you gave us, coming to lend a hand was the least we could do."
  *if strategy = 1
  
    "Just in time," you beam, clasping their hands.  "Every hand raised against the Thaumatarch is welcome here."
    *goto trethmorale
  *if strategy != 1
    *choice
      #"Welcome!" I beam, clasping their hands.
        *goto trethmorale
      #"We're grateful, goodman Treth—but the fewer there are of us just now, the better."
        "Oh?" scowls the Brecklander leader, folding his arms across his chest.
        
        "We're
        *if strategy = 2
          planning to evade them, not stand and fight."
        *if strategy = 3
          on our way to helot camps across the Rim—not staying here to wait for the blow to fall."
        You hastily explain your plan, and describe some of the ways you're preparing.
        
        Treth's annoyance fades as he listens, and in the end he shrugs tolerantly and claps you on the shoulder.  "Sounds enough to keep you busy, ${kuria}.  Let us do a bit of hunting for you, then—put venison on the plate and lay away some dried meat for you, while you all look to your preparations."
        *set uthwen 3
        *if religion > 0
        
          During the Brecklanders' days with you, several of your more passionate outlaws
          *if religion < 10
            proclaim you as the Eclect of the Angels.
          *if religion > 19
            explain to them the liberating embrace of kenon.
          *if (religion > 9) and (religion < 20)
            tell them that they can hear the voice of the Angels for themselves.          
          At first, seeing their aghast faces, you fear that it'll send them straight back to the Brecks.  But they are moved by your band's conviction.  By the time they bid you farewell, 
          *if religion < 10
            most of them are regarding you with no less awe than your devout followers.
          *if religion > 19
            you notice that more than a few have picked up your followers' oath, "By kenon!"
          *if (religion > 9) and (religion < 20)
            many of them whisper messages of encouragement that 
            *if religion < 13
              they believe 
            the Angels personally gave them for your sake.
          *set uthwen 4
        *goto horhostin
  *label trethmorale
  It tangibly raises your followers' mettle to have the Brecklander gang show up, spoiling for a fight with the Archon's troops.
  *if strategy != 1
    Even if you're not planning a direct confrontation, it's deeply encouraging that others are willing to join you just before the Phalangites descend.
  *set followers +23
  *set nonkids +23
  *set morale +38
  *page_break
*label horhostin
*if horion > 14
  *set horhostage false
  *set hdead 0
  *if releasepromise
    *set violence -1
    You keep your promise to ${simon}, releasing Horion
    *if linhostage
      and Linos
    as soon as you approach the Whendward Pass again.
  *if horion = 16
    The plump noble is mostly recovered from ${kalt}'s arrow—well enough to make it into ${whendery} on foot, in any case.
  It's an overcast morning, with a late spring thunderstorm in the offing.  "Best get on the road while the weather is with you," you say gruffly.  "Off to find your
  *if szth > 0
    Theurge,
  *if szth < 1
    philosopher,
  then?"
  
  *if (horion = 18) or (horion = 20)
    Horion stares at you with no visible emotion on his hollowed-out face. Just as you're about to break the silence and bid him farewell, he says, "If Phrygia somehow fails to bring you down this summer, ${kuria}?  I'll find a way where she can't.  Sooner or later, look to see me again."
    
    You snort, aware of ${simon}'s wary eyes on you. "Off with you, ${delelle}.  Even if you're so desperate to join your lover, you'll not provoke me with so empty a threat."
    
    "Aye, aye, ${kuria}.  But all the same: look for me," Horion repeats, with a tremor of a smile on his lips.  Then he trudges off toward Szeric.
  *if (horion != 17) and (horion != 20)
    "With your permission, ${kuria} ${lname}," Horion says, thin-voiced, offering the slightest of bows.
    *if linhostage
      Linos just glares at you, not even pretending at courtesy.
    "Good luck surviving the summer."
*if (horhostage)
  *if kal_here and (((hor_guard = "your father") or ((hor_guard = "Breden") and (horion < 6))) or ((hor_guard = "Radmar") and rad_here))
    *set horion 27
    *set hdead 0
    A week into the summer, however, you wake to an outcry. "The 
    *if not(linhostage)
      ${delelle}—the ${delelle} is
    *if (linhostage)
      hostages—the hostages are 
    dead!"
    
    Racing down to the prisoner enclosure, you see that
    *if not(linhostage)
      Horion is
    *if (linhostage)
      both Horion and Linos are
    lying prone in a puddle of blood, 
    *if not(linhostage)
      throat
    *if (linhostage)
      throats 
    smoothly cut in
    *if not(linhostage)
      his
    *if (linhostage)
      their
    sleep.  There's no sign of struggle.  The young bandit guard who had been assigned the third watch swears that he'd only stepped away for a minute to relieve himself, and was close enough to have heard if anyone had cried out.
    
    *if hor_guard = "Alira"
      "${kalt}, surely," growls Alira. "$!{zhe}'s always been the one complaining about us making them guests rather than examples."
      *goto kaltdeny
    "After you put them in my care, 
    *if hor_guard = "Breden"
      ${bfname},
    I've checked every night at least once per watch to make sure they were safe," ${hor_guard} declares 
    *if hor_guard = "Breden"
      shakily.  "For a moment last night after I checked in, I thought I spotted someone hiding in the woods…but I couldn't find anything in the dark.  Decided it was just my mind playing tricks.  What a fool!"
      
      "Who did it look like?" you growl.  "${kalt}?"
      
      "I honestly couldn't tell," Breden says apologetically. "Looked like a shadow—that's all."
      *goto kaltdeny
    vehemently. "It must have been
    *if (hor_guard = "your father")
      *if aristo
        that damnable skinny helot—what's
      *if helot
        the skinny one with the loud mouth—what's 
      their name—that
    ${kalt}, watching for ${zhis} chance…and finally found it, damn ${zhim}."
    *label kaltdeny
    
    To no one's surprise, ${kalt} insists ${zhe} had nothing to do with it. "Angels, ${addressu}, I would have killed them after we got a ransom," ${zhe} insists, laughing without warmth.  "Nothing but a waste to do it before." 
    
    You have ${zhim} searched at once, but there's no trace of blood on ${zhis} knife, hands, or kyrtle.  Unless ${zhe}'d committed the murder stark naked, it's hard to imagine how ${zhe} could have escaped being bloodied.
    *choice
      #I try to get ${kalt} to confess. 
        *if k_rel = 4
          Your lover folds ${zhis} arms and glares at you.
        *if k_rel < 6
          *set k_rel 5
        *set k_rel +1
        "Taratur, ${addressu}. I didn't do it. 
        *if k_rel = 4
          After I left you,
        I slept in my usual tent.  Ask anyone."  
        *if hor_guard = "Alira"
        
          As it turns out,
          *goto nonewoke
        While you're sending the shamefaced young guard to question ${kalt}'s tentmates, ${zhe} steps to your side and lowers ${zhis} voice. "Ask ${hor_guard} again who did it.  Who else spent so much time around the ${delelle}?  Who had an excuse to be down there in the enclosure at any hour?"
        
        Word comes back than 
        *label nonewoke
        none of ${kalt}'s tentmates heard ${zhim} leave or return in the night; if ${zhe} did sneak out, ${zhe} managed to do it without being noticed. 
        *if hor_guard = "Alira"
          With no evidence pointing to anyone in the band, this is no time to provoke a split by punishing or accusing someone.  Though frustrated, you let it go.
          *goto postmurd
        And like
        *goto horgconf
      *if (hor_guard = "your father") #I try to get Father to confess.
        Like
        *goto horgconf
      *if ((hor_guard != "your father") and (hor_guard != "Alira")) #I try to get ${hor_guard} to confess.
        Like 
        *label horgconf
        ${kalt}, ${hor_guard} hotly denies any involvement.
        *if (hor_guard = "your father")
          "You mewling, insinuating little parasite!" he barks. "How dare you suggest that I might be party to this manner of blasphemous crime?"
        *if (hor_guard = "Radmar")
          "Damn it all, ${kuria}," he snaps, "if I'd known you would be throwing around accusations like this, I'd have stood back and let ${kalt} gut the swiving noble a month ago."
          *set r_rel -1
        *if (hor_guard = "Breden")
          "Angels' truth, ${kuria}, I'd nothing to do with it."
        
        At the end of the day,
        *if linhostage
          Linos's and
        Horion's death remains a mystery—one you have no more time to explore. This is no time to risk provoking a split in the band by punishing or accusing someone without evidence.  Though frustrated and angry, you let it go.
        *goto postmurd
      #To be honest, killing them would probably have been my decision anyway.  I'm not going to raise too much of a hue and cry over it.
        "If I find out who did this, they'll be expelled from the band," you say sternly. "I didn't much care for kurios ${delelle}, 
        *if linhostage
          let alone his priest. But
        *if not(linhostage)
          but
        anyone who takes a decision like this into their own hands has no place here."
        
        Despite your threat, you have no intention of hunting further for the murderer.  There's far too much else to be getting on with.
        *goto postmurd
    *label postmurd
    *gosub horbody
    *goto zv_leave
  *if (s_rel > 9)
    *set simz_here false
    *set horion +17
    *set hdead 0
    A week into the summer, however, you wake to an outcry. "The hostages—the hostages are gone!"  Racing down to the prisoner enclosure, you find it empty.  The young bandit who'd had the third watch is lying groggily on his back, being 
    *if bred_here
      questioned by a grim-looking Breden:
    *if not(bred_here)
      shouted at by
      *if rad_here
        Radmar:
      *if not(rad_here)
        a stony-faced Alira:
    "If you tied them properly, how by Xaos could they have cracked you on the head and tied you up?"
    
    "They can't have got far," you call at once to the outlaws milling around the enclosure. "And they'll have left a trail.  After them, and bring them back alive!"
    
    The next morning, you're staring in disbelief at
    *if c_rel > 0
      Ciels
    *if c_rel < 1
      Alira 
    and their abashed-looking tracking party. "How is it possible that we can't find them?"
    
    "The Whendward is a damned big place, ${addressu},"
    *if c_rel > 0
      Ciels
    *if c_rel < 1
      Alira 
    offers glumly.  "We're not hounds, we can't track them by smell.  We haven't had rain lately to muddy the ground, and the young ${zkuria} is very good at hiding ${zhis} traces.  We got as far as a stream that they could have gone up or down, with rocky banks. I reckon ${zhe} spotted it on our walk yesterday and decided it was their way out."
    
    "Bloody Taratur." ${simon} and perhaps Horion must have been less afraid of you than you'd all assumed; their guards had relaxed, become less vigilant. Frustration grips you so tightly you almost scream.
    *fake_choice
      *if (horion != 2)
        #We needed that ransom.
      #We needed them to deter the Theurges from attacking us.
      #We didn't need them, but this makes us look weak.
      #I was considering freeing them, so they wouldn't necessarily leave as enemies.  Now it's too late.
    You send a small party to the Whendward Pass to catch the escapees if they try to cross—but they come back a week later, not having seen a soul.  At last, you have to accept that 
    *if linhostage
      Linos,
    Horion and ${simon} are gone.  
    *set horhostage false
    *set linhostage false
    *goto zv_leave
*label zv_leave
*if zv_here and (((deputy = "Breden") and (sybla > 0)) or (strategy = 1))
  *page_break
  *if horion > 20
    A few days later, things go from bad to worse.
  *if horion < 21
    One morning, 
  Zvad puts his head into the Leaders' Tent, looking uncomfortable but determined. "A word with you, ${addressu}?"  When you've invited him in and the two of you are sitting cross-legged on the floor, he ventures, "It's a decade or so I've been out here.  A long time to live the greenwood life."
  
  You feel suddenly dizzy. "Zvad…are you thinking of leaving?"
  
  The big former mercenary sighs raggedly.  
  *if sybla > 0
    "Back in the early spring, Sybla told me that no one's hunting me now—the Alastors who knew me have forgotten.  She's ready to give me a new name and a place in her band.  We can head north and protect caravans across the Nyrish border rather than the Shayard side.  And…aye.  Aye, I'm taking her offer."
  *if sybla = 0
    "Aye, I am.  The Alastors who were after me won't remember me now, if I work the Nyrish border instead of this one.  Some of my old friends are still up there.  It's time."
  
  "$!{oath}, Zvad." It's hard to believe this isn't some sort of waking nightmare; the last person you'd have expected to abandon you was the gruff, loyal ${whend}. "This winter, without you, we'd have been lost.  You're like a father—you're one of the most respected leaders the band has.  How can you leave us just when we're about to need you most?"
  
  "I'm not needed as much as all that, ${addressu}.  I make a good enough second-in-command, but 
  *if deputy = "Breden"
    being third to a ${xgirl} nearly young enough to be my child…"  Zvad shrugs with a wry smile. "I've shown the two of you what I know,
  you can sort things out well enough now.  And 
  *if strategy = 2
    for the summer, plenty of other bandits can help you plan the rest of the run-and-hide.  All the skills are there."
  *if strategy != 2
    you've chosen a course for the summer that
  *if strategy = 1
    is likely to swiving kill us all. 
  *if strategy = 3
    I don't really understand.
  *if strategy != 2
    Not much I could contribute to that."
  *if sybla > 0
  
    For a few moments, neither of you speak.  Then you say, thick-tongued, "She told you we're all going to die when the Phalangites come.  She told you we're doomed.  And you believe it."
  
    Zvad exhales in a great gust through flared nostrils. 
    *if strategy = 1
      "I didn't want to, ${kuria}.  But with the course you've chosen for us?"  He falls silent and looks away.
    *if strategy > 1
      "No. No, I don't.  But if she's right…there's nothing more I can do to stop it than I've already done.  And I've another life, ${kuria}.  From before you knew me.  I want it back."
  *if elezvad > 6

    "And Elery?"
    
    His cheek twitches as if you'd just raised a hand to slap him. "She'll not leave her brother here alone with you.  He won't leave the band.  So."
  *choice
    #"We need every leader we have, Zvad.  At least stay out the summer."
      *if elezvad < 7
        Zvad shakes his head. "I've served the band, and then your rebellion, ${kuria}.  But 
      *if elezvad > 6
        "$!{kuria}," Zvad says mournfully, "if Elery couldn't convince me to stay…you've got damned poor odds.
      I'm sick to death of these woods, and I want to get back to other roads."
      
      "The rebellion won't stay in these woods!" you exclaim.  "Have patience, Zvad, and you'll see those other roads with us."

      *if strategy = 1
        The big warrior rises abruptly.  "I don't know how to say it any more clearly, ${kuria}.  You're going to bloody die, and so's the rebellion.
        *if elezvad > 6
          Elery knows it but will stand with you anyway.
        I won't watch it happen."
      *if strategy = 2
        "We just chose to stay here, ${kuria}," Zvad points out. "Because it's the safer choice.  It'll stay the safer choice.  I wish you well, but Sybla's right—I belong on the road with my clanmates."
      *if strategy = 3
        "From hiding, around a helot camp?"  Zvad's mouth twists wryly. "No, 
        *if (zvad > 2) and bred_here
          ${kuria}. I don't want to stake my life on any plan Breden supports so strongly. And
        Sybla's right. I belong on the road with my clanmates."
      *goto zvadgoes
    #"It's a blow to us, Zvad.  But if you're set on leaving, I can't keep you."
      Zvad stands and clasps your hand gratefully. "I'm grateful that you understand, ${addressu}."
      *goto zvadgoes
    #I reach out to clasp his hand.  "We owe you more than I can ever say.  Go with our thanks."
      Losing Zvad now is a small disaster for the band…but with all he's given you, you owe him the respect of letting him go in peace.
      *if strategy = 1
        You bite your tongue, don't argue about the band's strategy, and do your best to smile.

      Zvad blinks, and when he speaks again, his voice is thicker than usual. "I'm grateful that you understand, ${addressu}."
      *goto zvadgoes
    #"Someone who knows as much as you do, trying to leave us just when the Archon's troops are moving into place?"  I shake my head, eyes hardening.  "I think not."
      Zvad's eyes widen, then his lips curl back from his teeth and he rises.  "Why don't you say what you mean, then, ${kuria}?"
      
      "How much clearer can I be?" you snap. "There might be fortunes and pardons to be had for anyone who knows where we camp, how we move, who our fences are.  Until we've survived the summer, I'd be a fool to let anyone leave who's been so much a part of our planning."
      
      "So now 
      *if rescuer = 0
        even 
      I might be a traitor.  Xthonos." The big ${whend} folds his arms hastily and forcefully, as if to keep himself from seizing you by the ears and shaking you. "Don't embarrass us both, ${girl}.  You can not keep me here.
      *if eclect
        You may
        *if cha > 1
          have a silver tongue and
        be Eclect of the bloody Angels.
      You're leader of this band.  But if you tell those outlaws to stop me because I might betray you…the kindest response you'll have is laughter.  Don't hurt your authority this close to
      *if strategy != 1
        what might be
      the battle of your life.  Don't get everyone else talking about whether they should leave too.  Let me go quietly."
      
      The two of you face off in furious silence for what seems a very long time. But in the end, you're wise enough to believe him.
      *goto zvadgoes
    *if ((religion > 0) and (religion < 10)) #"You'd abandon the Angels' Eclect?" I say incredulously. "For the sake of some merchants?"
      Zvad shakes his head bitterly. "Damn it, ${addressu}, you're the one who's at the heart of Their purposes.  I'm just a sellsword.  I'm free."
      
      "This is no light matter, Zvad.  How can you walk away from the rebellion the Angels Themselves support?"
      
      *if cha < 2
        The scarred ${whend}ish bandit is unyielding.  "They'll give you victory with or without me, ${addressu}.  But the Angels aren't going to give me another chance at my old life back."
        *goto zvadgoes
      *else
        For a moment, you sense hesitation beneath the surface.  "Have the Angels spoken to you on this, ${addressu} ${fname}?  On me?"
        *goto zvadrevel
    *if ((religion > 10) and (religion < 20)) #"Listen to what the Angels tell you, Zvad."
      *if cha > 1
        "Damn it, ${addressu}, I have.  Are you saying you've heard something different?"  Beneath Zvad's unyielding exterior, you sense the slightest hesitation.
        *label zvadrevel
        *choice
          #"No," I say honestly.
            "Well, then."  Zvad rises, gives you a short bow.  There's regret in his eyes. 
            *if strategy = 1
              "Ask Them again, ${addressu}.  Ask the Angels how you're going to survive the Thaumatarchy descending on you, besides running away."
              
              "Keep an ear out when you've gone," you say levelly.  "You'll hear how we've done it."
            *if strategy != 1
              "For what it's worth, ${addressu}, this is no easy thing for me.  But I believe it's the right thing.  Memory find you."
            *goto zvadgoes
          #"I didn't think I'd need to ask Them." I close my eyes for just long enough to be plausible.  "But yes—They're saying you should stay."
            *if (religion = 3) or (religion = 13)
              You'd hoped that some hint of "rightness," some sense of Angelic approval, might resonate once you'd made the claim.  Or perhaps an immediate sense of guilt and wrongness; you're poised to repent if you feel it.  But there's only the increasingly familiar silence.
              *set religion -1
            *if (religion = 5) or (religion = 15)
              *set religion -1
              A pang of guilt goes through you, and you send a mental appeal to the Angels for forgiveness.  But you don't have time to truly seek Their will, and you're sure in any case that Zvad's selfish, faithless decision isn't in accordance with it.
              
            Zvad stares at you with a mix of disbelief, anger, and awe. "$!{addressu}, are you…"
            
            "Are you surprised?" you cut him off, eyes intensely fixed on his.  "You're here for a reason, Zvad.  There's a reason you came to the band when you did, and that you didn't claim leadership but waited for others to come.  All things are part of the Order of Xthonos.  And It's not done with you yet."
            *if strategy = 1
            
              "Even us dying at the hands of the Thaumatarchy?" The big warrior's eyes are wide, his voice shaking.  The prospect of the Angels telling him to stay is clearly one of the most terrifying moments of his life.
              
              "Stay."  You put your hand out to clasp his.  "Believe.  Wait for the miracle."
            *if elezvad < 7
              
              It takes another hour or so of conversation, but when Zvad finally leaves, you're confident that you've won him over.
              *if (religion = 14) or (religion = 4)
                [i]Forgive me, Merciful Angels[/i], you think again—and once again, feel nothing in response. [i]If I truly am still your messenger, forgive me, and make the way ahead clear….[/i]
            *if elezvad > 6
              
              Elery finds you later that day, 
              *if e_rel > 6
                beaming like someone who's just had a reprieve from the aristarch's court.
              *if e_rel < 7
                brow furrowed with grudging appreciation.
              "I don't know what you did to change his bloody mind, ${addressu} ${lname}.  But…thank you."  She
              *if e_rel > 6
                gives you a quick kiss on the cheek, then hurries away.
              *if e_rel < 7
                manages a small bow, then hurries off before you can say anything more.
              *set e_rel +2
            *page_break
            *goto yebcheck
      *else
        "I've done that, ${addressu}," Zvad says, his voice softening slightly. "Just like you taught us.  And this is what They're saying to me."
        *goto zvadgoes
  *label zvadgoes
  *set zvad +10
  *set zv_here false
  
  You agree that to avoid drawing other outlaws with him, he'll leave the band by night, and that you'll tell the rest of the band that he's gone to discreetly spread word of the rebellion in ${whendery}.  On the morning after he leaves,
  *if rad_here
    Radmar
  *if not(rad_here)
    Alira
  and
  *if el_here
    *if elezvad > 6
      a devastated-looking
    Elery
  *if not(el_here) and (c_rel > 0)
    Ciels
  *if not(el_here) and (c_rel < 1)
    Zvad's friend Pitrj
  confirm the story.  Many people take Zvad's departure hard, especially on the eve of the Archon's attacks.
  *set morale -10
  *set theirintel +3
  *if deputy = "Zvad"
    
    You'll need a new deputy, and you'll need to choose one quickly.
    *set morale -10
    *choice
      *if (bred_here) #I ${ask} Breden.
        *set deputy "Breden"
        *set dephis xhis
        *set dephe xhe
        *set bred_lead +1
        *goto yebcheck
      *if (el_here) #I ${ask} Elery.
        *if strategy = 1
          "You drove Zvad away," Elery growls.
          *if elezvad > 5
            Tears are streaking her face.
          "Why by Xaos should I say yes to you?"
        
          "You chose to stay," you point out.  "You know that the band needs you if we're going to survive."
          
          Elery's lips peel back from her teeth.  "We're not going to bloody survive, ${kuria}.  This time next year, we'll all be bones in the bushes.  And you're asking me to join you in taking us there."
          
          The sheer hatred in her eyes takes you aback.  "If that's truly what you think, then why didn't you go with him?"
          
          *if elezvad > 0
            "Because damn him."  Elery turns her back on you, wipes her cheeks with a brusque gesture. "And damn you too.  But yes, 
          *if elezvad < 1
            She stares at you for a few moments longer, then shakes her head sharply.  "What more does Zvad have to offer me, or my brother?  Aye,
          I'll be your bloody deputy.  If we're going to our deaths, it might as well be me pointing out the best way there."
        *if (strategy > 1)
          *if e_rel < 10
            Despite her apparent disapproval of you,
          Elery replies with a fierce and instantaneous yes. "That bastard Zvad may run off as he likes, but I'm not going to let him leave the band rudderless."
        *set deputy "Elery"
        *set dephis "her"
        *set dephe "she"
        *set el_lead +1
        *page_break
        *goto yebcheck
      *if (simz_here and (s_rel < 9)) #I ${ask} ${simon}.
        *set deputy simon
        *set dephis zhis
        *set dephe zhe
        *set simz_lead +1
        *goto yebcheck
      *if (kal_here) #I ${ask} ${kalt}.
        *set deputy kalt
        *set dephis zhis
        *set dephe zhe
        *set kal_lead +1
        *goto yebcheck
      *if (rad_here) #I ${ask} Radmar.
        *set deputy "Radmar"
        *set dephis "his"
        *set dephe "he"
        *set rad_lead +1
        *goto yebcheck
      #I ${ask} Alira.
        *set deputy "Alira"
        *set dephis "her"
        *set dephe "she"
        *goto yebcheck
  *goto yebcheck
*label yebcheck
*if (((theurgy > 2) and (theurgy != 11)) or ((zvad > 10) and (elezvad > 6))) and (yebben > 0)
  *set theu_spread +5
  *if ((zvad > 10) and (elezvad > 6))
    *page_break
    Later that day, you find Yebben Skinner at the venison drying racks.  He raises his head as you approach, nods to himself when you shoo away the children nearby.  
    *if rad_mutiny
      "Same question as last time, ${addressu}?"
      
      You almost manage a smile.
    *if not(rad_mutiny)
      "I was sorry to hear the news, ${addressu}.  We'll all miss him."
      
      "But you could have gone with him." You're desperate for some reassurance after Zvad's desertion.
      *if strategy != 1
        Whether he admits it or not, you can't escape the conviction that he left to save his own life.
    "Why did you stay?"
    
    Yebben mutters a couple of numbers to himself, then steps away from the dried meat and turns his full attention to you.  "These are my people, whom I've known since I was born.  And I'm their quartermaster.  A damned good one.
    
    "Zvad's a fine man, but…to be frank, ${addressu}, he doesn't quite know what to do with me.  In his band, I'd just be Elery Skinner's blind brother.  Treated like a child or an old man too frail to cut his own meat."
    *if (theurgy < 3) or (theurgy = 11)
      He smiles wryly toward you. "By everyone but Elery, anyhow. I'd rather stay where I'm known."
      
      "You think we're going to survive?"
      
      "Angels, ${addressu}, I don't know."  Yebben's face twists with something like pain.  "But I reckon there's a chance.  And a better one with Elery here.  It's a shame she couldn't convince Zvad, too. But here we are."
      *page_break
      *goto lastspend
    He pauses, moistens his lips nervously.  "And I know I can be more.  More than quartermaster, even."
      
    "Go on," you say, curious.
  *if (zvad < 11) or (elezvad < 7)
    *page_break
    Late in the afternoon one day after camp has been set up, Yebben finds his way to your tent and hovers in the entry flap. "Trouble with the food stocks?" you query, drawing him in.
    
    "No, no, all's well," Elery's brother assures you as he lowers himself to the floor.  He pauses, moistens his lips. "In truth, ${addressu}, there's something else I'd wanted to talk to you about."
    
    "Go on, ${addressm}," you offer, sitting next to him.
  
  Yebben's voice takes on a faraway tone. "Have you heard tales of Salareo of Aveche, ${addressu}?  From the last great Halassurq War before our current one.  Salareo Mage-Bane, who once killed more than a dozen magi of Halassur in a single great battle."
  
  "Of course. The Blind Theurge." As soon as the epithet has left your tongue, you 
  *if theuknown < 5
    fall silent.
    
    A faint smile bends Yebben's mouth.  "I've listened to many stories of your raids, ${addressu}. Of odd things that have befallen our enemies when you were in the lead.  Some say it's luck, or Angels.  And before you say the same, consider: maybe Salareo knew something that gave him an advantage over magi who could see.  Maybe I could learn as he did, and even the odds a little."
    *choice
      #"Wait, wait—you think I'm a [i]Theurge[/i]?"  I break out laughing.  "I'm sorry, Yebben, but whatever stories you've been hearing…"
        *set yebben 8
        Yebben rises; his smile broadens, but his voice is pained. "Of course.  Forgive my foolishness, ${kuria}."  He pauses at the tent flap. "You may be relieved to hear that, as far as I am aware, no one else in the band has come to the same mistaken conclusion as myself.
        *if el_here
          Not my sister, in particular.
        *if bred_here
          Not Breden.
        I'll do my best to keep anyone else from sharing my folly."
        
        *goto lastspend
      #"I barely know what I'm doing myself," I say quietly. "I can't teach you.  I can only ask for your absolute discretion."
        *set yebben 9
        "You have it, ${addressu}," Yebben says at once. "No one else suspects, as far as I can tell.  All I ask, in return, is that if you ever think you might teach anyone…please, ${addressu}, think of me on that day."  He rises and leaves you in silent turmoil.
        
        *goto lastspend
      #After several minutes' silence, I finally say, "There are some exercises I can teach you.  Mental reflections."
        Tears spring to Yebben's unfocused eyes.  "Thank you, ${addressu}."
        
        *goto yebscroll
  recoil in realization. "So."
  
  "It must be possible, ${kuria}."  Yebben's mouth parts in the broad, fixed smile that seems to reflect merely intense rather than positive emotion. "Maybe more than just possible.  Perhaps Salareo knew something that gave him an advantage over magi who could see."
  
  "He was a Hegemonic hero.  Whatever he learned, it's presumably taught in the Lykeion of Aekos these days."
  
  "Perhaps.  And of course it might not have been a matter of his blindness at all."  The young man dismisses his own speculations with a wave. "But whether or not I can even the odds against a pack of Theurges…I can learn, ${addressu} ${fname}.  Maybe not the same way you do it, but if Salareo could do it, so can I."
  *choice
    #I start teaching him the mental exercises that I discovered in Rim Square.
      *label yebscroll
      *set yebben 10
      Where you found memorizing the exercises from Ganelon's scroll both challenging and tedious, Yebben rapidly commits them all to memory and spends hours a day practicing them.  You share with him
      *if horthe > 0
        much of what you and Horion guessed regarding telos, as well as
      your experiences as a ${wisard} so far. "I see things before I Change them—most of it's a blur, but what I see with clarity, I can change.  If I were blind, I wouldn't even know where to begin.  It must be possible, as you say.  But completely different."
      
      "But sometimes you see through other things, ${addressu}?" Yebben's head is tilted toward you, ear-first, in his equivalent of an intense stare.  "Like a knife through a sheath, or people through their clothes?"
      
      "I see the elements that make them up, not their…"  You clear your throat uncomfortably.  "Yes.  But only if I know that what I'm 'seeing' is there.  And not through anything more than a finger's width thick.  I can't see through walls."
      
      "At least, not yet." Yebben gives a single, sharp 
      *if horthe = 0
        nod and returns to his contemplations.
      *if horthe > 0
        nod.  "So you can sense the telos of something you can't see.  As long as you know it's there and you understand it…."
      *page_break
      *goto lastspend
    #If we survive the summer, then I'll teach him.
      *set yebben 8
      "I can wait, ${addressu}," Yebben beams.  "And I…well.  Thank you, ${addressu} ${fname}—thank you so much."
      
      "Wait to thank me until you know we've both survived," you say grimly.
      *page_break
      *goto lastspend
    #Absolutely not.  I want to be the only ${wisard} in this rebellion, and I tell him so.
      *set yebben 7
      "Yebben…what I've learned isn't something I intend to teach."
      
      The young man tilts his head, nostrils flaring.  "You don't trust me enough."
      
      "It's not a matter of trusting one person or another. Should anyone else ask me, I'd give the same reply.  There'll be one ${wisard} in our rebellion, no more."
      
      "Even the Thaumatarch has his Nine, ${addressu}."  Yebben sounds disapproving as much as disappointed.  "What becomes of us if you fall?  The one ${woman} with the power to bring down a Theurge?"
      
      "I'd like the rest of the band to set their minds to keeping me alive, not imagining what would come to pass if I died."  Your curt tone has the intended effect.  Yebben makes a stiff bow in your direction and walks off with no further appeal.
      *page_break
      *goto lastspend
    #Absolutely not.  I'll try to come up with some other reason to put him off.
      *set yebben 6
      "It's dangerous work, Yebben—and I'm not sure where I'd start teaching you, when you can't see.  Yes, it's possible.  Salareo shows that.  But he learned from masters, not from a self-taught
      *if aristo
        backwater noble."
      *if helot
        helot."
      You shake your head.  "I have to say no."
        
      Yebben nods, disappointment stark on his face.  "Will you teach others, ${addressu}?  Can't I sit in?"
        
      "Until I know who almost got you killed in Rim Square, I'll not be teaching anyone."
      *if nohunt
        It makes a convenient excuse, whatever you may believe about Breden.
      *page_break
      *goto lastspend
    #I need more time to think about it.
      "It's no easy choice, Yebben, and I won't make it lightly.  Let me consider it some more."
      
      "Aye, ${addressu}," your young quartermaster says, trying to mask the disappointment in his voice.
      *set yebben 9
      *page_break
      *goto lastspend
*label lastspend
*if wealth > 0
  *if not(spendtick)
    *page_break
    "Last chance to spend some silver before the Phalangites arrive, ${addressu}," ${deputy} points out. "Anything you want to use it on?"
    
    You consider dispatching the last handful of missions you could send to the Rim to spend your 
    *set d2n_num wealth
    *gosub d2n    
    drachems.
    *set spendtick true
  *choice
    *if ((mules-freemules) > 0) and (mulesale > 0)
      #I'll sell some more of our mules.
        You still have
        *set d2n_num mules
        *gosub d2n
        remaining
        *if freemules > 0
          mules, and can sell all save the
          *set d2n_num freemules
          *gosub d2n
          that wear the Architelone's brand.
        *if freemules = 0
          mules.
        *if muleneed > mules
          Your deputy recommends keeping at least
          *set d2n_num muleneed
          *gosub d2n
          for the band.
        *goto sellinmules
    *if ((mules-freemules) > 0) and (mulesale = 0)
      #First, I'll sell some of our mules.
        *set muleneed round(inwoods/20)
        Any of your 
        *set d2n_num mules
        *gosub d2n
        mules could be fenced for around seven gold staters, or seven hundred 
        *if freemules > 0
          drachems—except, alas, the 
          *set d2n_num freemules
          *gosub d2n
          surviving mules that wear the Architelone Xedia's brand.
        *if freemules = 0
          drachems.
        *if muleneed > freemules
          ${deputy} 
          *if muleneed <= mules
            recommends keeping 
            *if muleneed < mules
              at least
            *if muleneed = mules
              all
          *if muleneed > mules
            discourages you from selling, suggesting that you'd ideally want
          *set d2n_num muleneed
          *gosub d2n
          mules for the band. "If we live to see another winter, we'll need at least that many, ${addressu} ${fname}."
        
        *label sellinmules
        You choose to sell:
        *input_number mulesale 0 (mules-freemules)
        *set wealth +(mulesale*700)
        *set mules -mulesale
        *gosub howelsespend
        *goto lastspend
    *selectable_if (wealth > 99) #Buy forged weapons—swords, steel maces, spears—for the band. (At least 100 silver.)
      *set armsalelimit round(wealth/100)
      *if armsalelimit > (wealth/100)
        *set armsalelimit -1
      Cacelon the fence still has a few weapons for sale at a gold stater (one hundred drachems) apiece.
      
      Your current wealth amounts to 
      *set d2n_num wealth
      *gosub d2n
      drachems. That could buy you 
      *if armsalelimit = 1
        one 
        *if arms > 0
          additional 
      *if armsalelimit > 1
        up to 
        *set d2n_num armsalelimit
        *gosub d2n
      *if arms <= 0
        *if armsalelimit = 1
          weapon
        *if armsalelimit > 1
          weapons 
        for your band, which is currently armed only with bows, staves, and a few wood-axes—nothing that will stand up well to the Alastors' steel.
      *if arms > 0
        *if armsalelimit = 1
          weapon,
        *if armsalelimit > 1
          weapons, 
        adding to the 
        *set d2n_num arms
        *gosub d2n
        forged
        *if arms = 1
          weapon
        *if arms > 1
          arms 
        you already have for your 
        *set d2n_num nonkids
        *gosub d2n
        *if kids > 2
          adult 
        bandits.  
      How many weapons do you want to order?
      *if (choice_randomtest)
        *set armsalelimit (nonkids-arms)
        *if armsalelimit <= 0
          *set armsalelimit 1
        *if armsalelimit > (wealth/100)
          *set armsalelimit round(wealth/100)
        *if armsalelimit > (wealth/100)
          *set armsalelimit -1
      *input_number armsale 0 armsalelimit
      *if armsale = 0
        Is there anything you actually want to spend on?
        *goto lastspend
      The 
      *set d2n_num armsale
      *gosub d2n
      *if armsale > 1
        weapons arrive by mule train 
      *if armsale = 1
        weapon arrives
      at the end of the week.
      *set arms +armsale
      *set armsfoll arms
      *if arms > followers
        *set armsfoll followers
      *set wealth -(armsale*100)
      *gosub howelsespend
      *goto lastspend
    *hide_reuse *selectable_if (wealth > 369) #Pay some informants in the Rim to keep me apprised of the Phalangite force's movements. (At least 370 silver.)
      *if calea > 9
        Even if Calea does manage to get you the information she promised, you'd be a fool to trust solely in her word.
      *if deputy != simon
        "It'll be bloody costly, but for enough silver
      *if deputy = simon
        "For a sufficient quantity of silver, ${addressu}, I believe
      we could get some folk to take the risk of speaking to us," ${deputy} advises you.
      *if ((cred_y > 230) or (cred_p > 200)) or ((cred_h > 159) or ((cred_a > 215) or (cred_m > 215)))
        "Regardless, I reckon we'll also get word from some sympathetic
        *if (cred_y > 230) 
          yeomen,
          *set intest +5
        *if (cred_p > 215)
          Diakons,
          *set intest +10
        *if (cred_h > 159)
          helots,
          *set intest +2
          *if (cred_h > 250)
            *set intest +3
        *if (cred_a > 215)
          nobles,
          *set intest +10
        *if (cred_m > 215)
          merchants,
          *set intest +10
        maybe a few others.  
        *if intest < 30
          *set intelsale (30-intest)
          But still, we could use 
          *set d2n_num intelsale
          *gosub d2n
          or so paid ears, to balance what we're hearing from the others."
        *if intest > 29
          Reckon they'll give us all we really need.  I don't know if we'd get much more from paying folk, to be honest."
      *choice
        #I accept ${deputy}'s advice.
          *if intelsale = 0
            No need to pay for informants, then. 
            *gosub howelsespend
            *goto lastspend
          *if (intelsale*370) > wealth
            *set intelsale round(wealth/370)
            *if intelsale > (wealth/370)
              *set intelsale -1
            Alas, your
            *set d2n_num wealth
            *gosub d2n
            silver will stretch to only 
            *set d2n_num intelsale
            *gosub d2n
            *if intelsale = 1
              informant.
            *if intelsale > 1
              informants.  
            You send the drachems anyway, and order your scouts on the edge of the Rim to periodically check in with such spies as they can find.
          *goto intelbought
        #I'd rather choose the numbers myself.
          *goto intelch
      *label intelch
      *set intelsalelimit round(wealth/370)
      *if intelsalelimit > (wealth/370)
        *set intelsalelimit -1
      How many informants do you want to hire, at three hundred seventy silver apiece?
      *input_number intelsale 0 intelsalelimit
      *if intelsale = 0
        At the last minute you can't quite bring yourself to spend that much on spies.  Is there anything you actually do want to spend on?
        *goto lastspend
      Your scouts on the edge of the Rim will periodically check in with your
      *set d2n_num intelsale
      *gosub d2n
      *if intelsale = 1
        informant.
      *if intelsale > 1
        informants.  
      *label intelbought
      *set intel +intelsale
      *set wealth -(intelsale*370)
      *gosub howelsespend
      *goto lastspend
    *hide_reuse #Share my wealth with the helotry.
      *gosub robinhood
      How many of your band's 
      *set d2n_num wealth
      *gosub d2n
      drachems do you want to discreetly send to the helotry?
      *input_number heldonate 1 wealth
      Your
      *if heldonate < 30
        petty
      generosity wins you 
      *if heldonate < 30
        scarce love among
      *if (heldonate > 29) and (cred_h < 190)
        some friends among
      *if (heldonate > 29) and (cred_h > 189)
        the deeper admiration of
      the helotry.  
      *if (heldonate > 29)
        Hopefully that will be useful in the imminent battle.
      *if heldonate <= 800
        *set cred_h +round(heldonate/8)
      *if heldonate > 800
        *set cred_h +round(100+((heldonate-800)/50))
      *set wealth -heldonate
      *gosub howelsespend
      *goto lastspend
    *hide_reuse #Share my wealth with smallholder farmers.
      *gosub robinhood
      How many of your band's
      *set d2n_num wealth
      *gosub d2n
      drachems do you want to send discreetly to the yeomanry?
      *input_number yeodonate 1 wealth
      *if yeodonate <= 1200
        *set cred_y +round(yeodonate/12)
      *if yeodonate > 1200
        *set cred_y +round(100+((yeodonate-1200)/50))
      You hear that your
      *if yeodonate < 49
        petty donations have changed few minds
      *if yeodonate >= 49
        generosity is reasonably well received 
      among the yeomanry.
      *set wealth -yeodonate
      *gosub howelsespend
      *goto lastspend
    *hide_reuse *selectable_if (wealth > 24) #Donate it to Diakon-priests who might be open to my movement. (At least 25 silver.)
      *if cred_p < 100
        Unfortunately, while Diakons who don't despise you may exist somewhere, you can't find any 
        *if diakon < 10
          on short notice.
        *if diakon >= 10
          who haven't already joined your band.  With the Ecclesiasts so violently opposed to you, any sympathetic Diakons have to keep the lowest of profiles.
        *goto lastspend
      Over your time as a bandit, you've identified a scattering of Diakons across the Rim who seem cautiously supportive of your movement.
      *if diakon > 9
        *if diakon > 13
          Edwer and his fellow rebels
        *if diakon <= 13
          The Diakons who recently joined your rebellion
        help you identify a few more.
        *set cred_p +10
      How many of your band's 
      *set d2n_num wealth
      *gosub d2n
      drachems do you want to discreetly donate to them?
      *input_number pridonate 25 wealth
      *set cred_p +round(pridonate/50)
      Your generosity is
      *if pridonate < 90
        barely noticed by the priesthood.
        *goto pridon
      reasonably well received among the Diakonry, and goes
      *if pridonate < 250
        a little ways
      *if (pridonate > 249) and (pridonate < 1000)
        some ways
      *if pridonate > 999
        a long ways
      toward redeeming your reputation with the priesthood.
      *label pridon
      *set wealth -pridonate
      *gosub howelsespend
      *goto lastspend
    #I intend to survive to spend the rest another day.
      *goto weden
*label weden
*if (((bred_lover >= 4) or (bred_heart = 3)) and bred_here) and (bred_heart < 10)
  *page_break
  *if strategy = 3
    Breden is so busy supporting the deployment of your infiltrators to the Rim, you barely see ${xhim} for a week or two.  Every day ${xhe} seems to be working with another group, boosting their confidence, reviewing all the ways to keep yourself unnoticed on a big estate.
  *if strategy = 2
    Throughout the preparations, Breden is constantly on the move, mostly helping to train those less experienced rebels who joined you after the winter's end.  Between ${xhis} work and yours, you barely see ${xhim} for a week.
  *if strategy = 1
    You haven't seen much of Breden since the meeting where you settled on a strategy.  You know ${xhe} was bitterly disappointed in the choice—that ${xhe} considers it rash, nearly suicidal.  And yet while ${xhe}'s not been speaking much to you, nor has ${xhe} been sulking in a corner.  $!{xhe}'s thrown ${xhim}self into the planning, drilling constantly with the other outlaws and doing ${xhis} best to encourage them.
  
  The prolonged separation from Breden puts a strain on you, especially with half your mind on the imminent clash with the Hegemony.  One night you wake up aching from a dream of ${xhim}, unsure whether the salt on your lips is sweat or tears.  Through your half-alert haze, a certainty floats up into your mind: without Breden, life will be a wretched thing.
  *choice
    #That morning, I ask Breden to marry me.
      *set proposal true
      *if xhis = "his"
        *set xspouse "husband"
      *if xhis != "his"
        *set xspouse "wife"
      It takes you the better part of an hour to find ${xhim}.  When you do, it's an age before you can pull ${xhim} away from
      *if strategy = 3
        the covey of infiltrators ${xhe}'s advising.
      *if strategy = 2
        a team practicing rapid camp-breaking.
      *if strategy = 1
        archery practice with Young Earnn and a gang of outlaws.
      At long last ${xhe} joins you, looking 
      *if strategy = 3
        tired but happy. "Those ones will do well.  Their leader had to cross half the Rim before she escaped to the Whendward.  She knows as much as anyone about moving discreetly through the camps…but I'm sorry, you
      *if strategy = 2
        weary but satisfied. "They were stragglers at the last drill.  Reckon they won't be at our next one.  But, I'm sorry…you
      *if strategy = 1
        wary but curious. "So.  You 
      wanted to talk, ${bfname}?"
      
      "I've been wanting to do more than talk.  And with so little time left to us, I'd best come straight to it."   Your mouth goes dry, and you have to swallow twice before continuing.
      *if aristo
        For all the weeks that you've yearned to say these words, some part of you still struggles to speak them to a helot.  How can you address ${xhim} with the formality the occasion demands?  "Breden Reaper, love of my soul,
        *if xhe = "he"
          son
        *if xhe = "she"
          daughter
        of the 
        *if natlreal > 49
          Shayardene soil,
        *if natlreal < 50
          honest helotry, 
      *if helot
        "Breden, 
      will you be my ${xspouse}?  Will you marry me?  Today?"
      *if bred_trust > 9
        *page_break
        To your dismay, ${xhis} face empties with shock.  Seconds later, anger flares across it.  "What are…is this a joke?  You think I might have betrayed you, ${addressu}.  How by Xthonos could you want to marry me?"  $!{xhe} waves away your attempt to reply.  "No!  No, I didn't want to hear you answer that.  
        
        "Hear me now, ${fname} ${lname}."  Breden presses a finger hard against your chest. "We're about to see the Conte bloody Leilatou and her Theurges throw everything they have at us.  Any traitor still living would have tried to run off weeks ago, rather than get trapped here and killed by magi or Phalangites.  But I don't reckon that's enough for you to let go your doubts.
        
        "So when we've come through this summer's fight alive and unbetrayed…then, then and only then, will I hear you tell me that you trust me.  Only then will I hear your apologies.  And only then will I have any time for…any other such talk."  $!{xhe} 
        *if aristo
          bows stiffly and 
        walks off to rejoin ${xhis} group.
        *set xspouse "lover"
        *goto set_troops
      
      *if (acepref) and (bred_lover < 10)
        The dumbstruck look on ${xhis} face is rare enough that you almost laugh. "Angels, ${fname}.  Those are the last words I'd thought to hear from you.  Even on the verge of death."
        
        "Did you not think I loved you enough to share my whole life with you?"  
        
        "Of course not, but…" Breden shakes ${xhis} head, smiling despite ${xhim}self. "Not to be over-bold, love…but marriage tends to involve 
        *if aristo
          what you call carnal intimacy."
        *if helot
          swiving."
        *if (ciels > 9) and (c_rel > 0)
        
          "I thought you were getting enough of that from Ciels."  You try to keep the tension out of your voice.
          
          "And you reckon I should keep that arrangement as your ${xspouse}."  It starts off sounding like a question, but by the end you've both realized it's not.
          *choice
            #"I don't see why we shouldn't."
              "Angels." Breden gives a hollow-sounding laugh. "Maybe you're right, ${fname}, but…Angels.  I thought I'd left behind the chance of being forced to marry a safe-mate ${spouse} plus a lover on the side when we broke that Harrower.  It's not what I'd choose for life, love.  Would you?  Truly?"
              *label hastoinvolve
              
              "So you think marriage has to involve swiving?"  You fight to keep the helpless anger from your voice.
              
              *goto aboutswive
            #"It would give us a reputation for Xaos…but could it really be any worse than what we have already?"
              "I'm not talking about our Xthon'damned reputation, ${fname}."  $!{xhe} casts a despairing laugh toward the sky. "I'm talking about what marrying someone means.  Back in the camps, it often enough meant a safe-mate ${spouse} plus a lover on the side.  Is that truly what you want now, for the rest of our lives?"
              *goto hastoinvolve
            #"You wouldn't want that?"
              "No offense to Ciels, ${fname}, but…no, I Xthon'damned well wouldn't."  $!{xhis} face twists . "I grew up seeing plenty of folk with a safe-mate ${spouse} plus a lover on the side.  You know how many of them were happy?"
              
              "How can you compare this to…that?" you demand. "$!{oath}, Breden.  No one is forcing us into anything.  No one is threatening anyone with death."
              
              "It's just not what I would have chosen, love. Is it truly what you want?  For the rest of our lives?"  $!{xhe} cuts ${xhim}self off, turning away. "Well, obviously it is.  Angels."
              *goto hastoinvolve
        *choice
          #"Must it always?"
            *label aboutswive
            Breden is silent for a moment, then exhales in a ragged burst.  "For me, ${fname}?  Yes.  Yes, it does.  I love you, but…I can't go on like this for the rest of our lives."
            *if (ciels > 9) and (c_rel < 0)
              A shadow crosses ${xhis} face; you're sure ${xhe}'s thinking of Ciels.
            *choice
              #I've been dreading the day ${xhe}'d say this. "And I can't give you what you want."
                $!{xhe} presses ${xhis} hands against ${xhis} forehead.  "I'll always love you, ${fname}.  But…Angels.  I won't marry you."  The two of you stare at each other unspeaking for a long time before ${xhe} finally turns and runs away.
                
                At dinner that evening you can't bear to eat in company, and take your venison up the slope to a narrow glen.  That's where Breden finds you, appearing out of the twilight without warning.  "${fname}." $!{xhis} face is wrung with remorse. "Can you…will you talk with me?"
                *choice
                  #"You've said all that needs saying."  I get up and return to the band.
                    $!{xhe} doesn't try to follow.
                    *set bred_heart 6
                    *goto set_troops
                  #"Will it change anything either of us said this morning?"
                    *if ciels > 9
                      "It might."  Breden waits for a minute, then sighs and seats ${xhim}self next to you. "I do want to marry you, ${fname}.  
                      *label cielsaccept
                      That's why your asking me this morning hit so hard.  I'd thought it would never be more than a dream.  And what I'd dreamed was…something very different to what we have now."
                      
                      "If it could be…"
                      
                      "But it can't." $!{xhe} cuts you off, tears standing in ${xhis} eyes. "I understand.  You are who you are.  So the choice I have is between having you on your terms and not having you at all.  And one of those is impossible."
                      
                      You turn to ${xhim}, wishing you could forget the look on ${xhis} face this morning.  "Breden.  Don't make any promises you can't live up to."
                      
                      "I don't want any ceremony, or anyone to call me your ${xspouse}, ${fname}.  I don't want people thinking they understand us, or thinking I've broken a vow when they see me with Ciels, or whoever else may one day follow in ${his} place."  $!{xhe} leans in, grave and fragile.  "But if you'll have me, my life is yours."
                      *choice
                        #I take ${xhis} hand, barely managing to say, "And mine is yours."
                          Tears spill down ${xhis} cheeks. "Thank you, my love.  Thank you."
                          
                          *goto account3
                        #Saying no is the hardest thing I've ever done.
                          "Breden…I love you too much to accept."  You stand, barely able to see, fighting to keep your voice level. "I saw the truth this morning.  There are things you want too much to be truly happy with anyone who can't give them."
                          
                          $!{xhis} own voice is shaking almost out of control.  "I can't promise you're wrong, ${fname}.  But I think you are.  It's a cloudy road, and a rough one, but I'd walk it with you."
                          
                          "No, Breden."  Before ${xhe} can speak again, or your will weaken, you hurry away.
                          *set bred_heart 7
                          *goto set_troops
                    "No." Breden looks steadily at you. "No, all of that was true."
                    
                    "Then let it end.  Why should we keep hurting each other?"
                    *label indecentproposal
                    
                    *if (ciels = 2)
                      $!{xhe} looks down, as if studying some point beyond your toes.  "When we spoke in the spring, ${fname}, I asked if you could ever bear for me to…take a measure of satisfaction with someone else."
                      *choice
                        #I jump to my feet, furious. "Is that all you've come to offer?  When I asked you to wed me?"
                          Breden raises ${xhis} tear-streaked face toward yours.  "I can't lie to you, ${fname}.  The things that satisfy you…they bring me more joy than I can say, but also stoke other desires.  Without some way to sate…"
                          
                          "Don't say another word."  You stalk blindly away; ${xhe} doesn't try to follow.
                          *set bred_heart 6
                          *goto set_troops
                        #"It's no more bearable now than it was then."
                          $!{xhis} shoulders sag forward, as if a stick propping them up had been abruptly removed. "Then I'm sorry, ${fname}.  You're right, and we should stop hurting each other."
                          
                          After ${xhe} leaves, you force yourself to finish the venison, but you might as well be chewing on bonfire ash for all the satisfaction it gives.
                          *set bred_heart 6
                          *goto set_troops
                        #I realize I'd rather share ${xhim} than lose ${xhim}.
                          *set ciels 12
                          "If it's the only way…"  Your voice is hoarse.  "So long as it can stay a matter of bodies, not of hearts, then yes.  I could accept it."  
                          
                          Breden's eyes search your face for a silent minute. "I wish I believed you, ${fname}."
                          
                          Seeing ${xhis} obvious anguish, some of the jealousy escapes you in a long, ragged sigh.  "Ah, ${oath}, my love.  Yes, I could will you to go without.  And that would 
                          *if aristo
                            accomplish as much 
                          *if helot
                            be about as much use
                          as your willing my desires to be different.  If we're to have any future together, we've each got to accept that things won't be as we dreamed."  You hold ${xhis} eyes with your own. "But they can still be good."
                          
                          "Yes.  They can."  Tears spill from Breden's eyes, and ${xhe} hesitantly embraces you. "They will."
                          *page_break
                          *goto account3
                    "${fname}, the things that satisfy you…they bring me more joy than I can say, but also stoke other desires."  You can almost feel the ashamed heat from ${xhis} cheeks.  "I haven't spoken much of them, because I understand that you can't fulfill them.  But I can't keep them forever sealed in a cask.  If we're to have a future together, I'd need some chance at release."
                    
                    "You want to lie with others," you say slowly, not quite sure that you've understood ${xhim}.  In your mind's eye, an image flickers to life of ${xhis} passionate springtime dance with
                    *if c_rel < 0
                      now-dead
                    Ciels. "And yet…still marry me?"
                    
                    "I don't want any ceremony, or anyone to call me your ${xspouse}.  I don't want people thinking they understand us, or thinking I've broken a vow when they see me coming out of someone else's tent."  $!{xhis} voice is choked, and tears streak ${xhis} face.  "I want to give you my life, ${fname}, in a way that doesn't go against your desires—but also doesn't deny mine."
                    *choice
                      #I jump to my feet, furious. "Is that all you've come to offer?  When I asked you to wed me?"
                        $!{xhis} shoulders sag forward, as if a stick propping them up had been abruptly removed. "I'm sorry, ${fname}.  You're right.  We should stop hurting each other."
                          
                        "$!{sweetoath}.  Just…don't say another word."  You stalk blindly away; ${xhe} doesn't try to follow.
                        *set bred_heart 6
                        *goto set_troops
                      #"Love…why didn't you ask me this before?"  It seems a perfect solution.
                        *if c_rel < 0
                          *set ciels 11
                        "As long as you and I can stay as close as we are…why would it matter to me if you're twining bodies with someone else?"
                        *if aristo
                          You can't say it without a tremor. It's no light thing to so flagrantly rebel against the chastity code ground into you from childhood.  But it's unquestionably what your heart feels.
                        *if helot
                          You've known plenty of helots who had to make some similar accommodation between their heart's love and their safe-mate.
                        "Satisfy yourself as you please, love.  Only come back to me."
                        *label btociels
                        
                        Breden looks up sharply at you. "Can you truly mean that, ${fname}?"
                                    
                        "Breden…"  You almost have to laugh at the mix of hope and guilty hunger on ${xhis} face.  What an odd thing it must be to have such a small thing matter so much. "If I'd known this was eating at you so, I'd have asked you to go clear your head months ago.  Please, please don't let this get in the way of loving me."
                        
                        $!{xhe} swallows hard, then reaches out to embrace you. "You're an extraordinary ${woman}, love.  Thank you.  Thank you so for understanding me."
                        *page_break
                        *goto account3
                      #"As long as it stays just a matter of bodies, not of hearts."
                        *if c_rel < 0
                          *set ciels 12
                        You couldn't bear for Breden to fall in love with anyone else—but it seems obvious to you that twining souls and twining bodies are two very different things. "As long as it doesn't end up with you giving more of your heart to someone else than you do to me…satisfy your body as you please."
                        *goto btociels
                      #"No, Breden.  Find someone else who meets your desires…and let me go."
                        "That's the problem, ${addressu} ${lname}," Breden says, a hopeless smile stretching ${xhis} lips. "I don't think I can let you go.  And I don't think you'll find it easy to let me go, either.  What I'm suggesting isn't at all what I've dreamed.  After growing up in the camps, seeing countless unhappy people with a safe-mate and a lover on the side?  No. I just can't face the other option."
                        
                        You stand, swallowing against a suddenly dust-dry throat. "Well, I can't share you."  The idea of Breden being intimate with anyone else, body or heart, sickens you. "So we'll each just have to find a way of facing it." You stride blindly off down the hill.  This time ${xhe} doesn't try to follow.
                        *set bred_heart 6
                        *goto set_troops            
                  #"I don't want to lose you, Breden."
                    "Nor will you, as long as that stays true."  $!{xhe} seats ${xhim}self next to you. "I couldn't bear to lose you 
                    *if ciels > 9
                      either.
                      *goto cielsaccept
                    either."
                    
                    "But even so, if what we have isn't enough for you…" It's hard for you even to say it. "Perhaps we need to end it, Breden.  Stop hurting each other."
                    *goto indecentproposal
              #"Then let's try."  I don't want it, but nor do I mind giving Breden what ${xhe} needs.
                *goto letstry
              #"You won't need to." All these months of closeness have kindled a new kind of desire in me.
                *goto kindle
          #"I know it's important to you, love.   So let's try."
            *label letstry
            *set bred_lover 11
            *set aceprop true
            Breden looks up sharply at you. "Truly, ${fname}?  I mean…you said you'd never wanted…"
            
            "I don't.  But I can see how much you do, and I love you."
            
            Breden tries and fails to return your smile.  "I know how generous that offer is, love.  But I'd still like to be…truly wanted."
            
            With some annoyance, you overcome the urge to argue about the relative importance of different kinds of wanting. "I truly want to make you happy.  Can that be good enough?"
            
            After a moment's silence, ${xhe} leans forward and slowly brings ${xhis} lips to yours.  It's as odd a sensation as you'd always suspected; there's clearly some trick to avoiding ${xhis} nose that you'll have to work out.  But you don't mind it, and quite enjoy the stupefying impact it seems to have on Breden.  
            
            "Angels," ${xhe} says hoarsely, pressing ${xhis} fingers into your back. "That's something I've been dreaming of for a long time now."
            *page_break
            $!{xhis} look of bliss fades quickly, to your chagrin.
            *goto tensenote
          #"I know.  I want that with you." All these months of closeness have kindled a new kind of desire in me.
            *label kindle
            Breden looks up sharply at you. "Truly, ${fname}?  I mean…you said you'd never…"
            
            "I never have, for anyone else."  You reach out to cradle ${xhis} face, then lean in and press your lips against ${xhers}.  It's as odd a sensation as you'd always suspected, and there's clearly some trick to avoiding each other's noses that you'll have to work out.  "But I've never twined as much of my soul with anyone else as I have with you."
            *set bred_lover 12
            *set aceprop true
            
            A delighted, incredulous smile flashes across ${xhis} lips—but fades quickly, to your chagrin.
            *goto tensenote
      $!{xhis} eyes widen—but not as sharply as you think they might have. That and ${xhis} hint of a smile tell you ${xhe}'s been wondering if you'd ask.  
      *if aristo
        "${fname} ${lname}, why by all your illustrious ${orig_lname} ancestors would you choose this day to wed a helot?"
      *if helot
        $!{xhis} voice remains soft and steady.  "Why now, love?"
      *fake_choice
        *if (bred_lover < 10) and not(acepref)
          #"Because I won't wait another day to be one with you."
            "You know you don't need to."  Breden folds ${xhis} arms across ${xhis}
            *if xhe = "she"
              breasts
            *if xhe = "he"
              chest
            and eyes you levelly.
            
            "And you know I do."
            
            "So you'd wed me to justify 
            *if aristo
              lying with 
            *if helot
              swiving 
            me."
        #"To spend my life with you—whether that be six days or sixty years."
          "I'd like to hope for something in between."  Breden's smile lasts only a moment.
        #"To prove that I'm not planning to die this summer."
          "Try to give everyone a sliver more hope?"
        *if (aristo)
          #"Because just being your lover isn't rebellion.  Being your ${spouse} is."
            A delighted, incredulous smile splits Breden's lips. "In what mad dream…ah, Angels, ${kuria}.  Who'd have thought I'd meet an aristo who could say those words?"  The smile fades as ${xhe} speaks.
      *label tensenote
      There's a tense note in ${xhis} voice now, a shade of unhappiness on ${xhis} face.
      *if ((xhe = "he") and (he = "he")) or ((xhe = "she") and (he = "she"))
        *set tobreed "children"
      *if strategy = 1
        "I'd be tempted—if I didn't think we were all going to die within the month because of your folly."
        
        "Breden…" you attempt, but ${xhe} shakes ${xhis} head resolutely.
        
        "Ask me again if we're both alive at the end of this, ${fname}.  Maybe you'll beat them, somehow, or maybe 
        *if religion > 19
          your bloody kenon
        *if religion < 20
          the Angels 
        will smile upon us.  But I've no interest in being your ${xspouse} for a week, or however long it takes for the Archon to chew us up."  $!{xhe} stares at you angrily for a long moment—then pulls you in for a savage kiss.  $!{xhis} tears are hot against your cheeks. "Damn you for only asking me now.  And damn me for not being able to just walk away from you."
        *set xspouse "lover"
        *set bredupset true
        *goto account2
      *if hypocrite > 1
        "Which ${addressu} ${lname} is asking, ${fname}? The one I first met…or the one I first saw here in the Whendward, who'd
        *if hypocrite = 2
          supposedly slaughter anyone who stands in ${his} way?"
        *if hypocrite = 3
          hide behind a gentle smile and make promises of kindness ${he} doesn't intend to keep?"
        *if hypocrite = 4
          deny the Blessed Angels if ${he} thought it would win ${him} a few more followers?"
        *if hypocrite = 5
          call on Angels ${he} doesn't believe in to win a few more followers?"
        *if hypocrite = 6
          feign a passion for anything beyond the borders of Shayard?"
        *if hypocrite = 7
          supposedly do anything for ${his} homeland?"
        *if hypocrite = 8
          hide ${his} true beliefs to appear less extreme?"
        
        You can't help flinching back. $!{xhe}'s the only one in the band who knew your hidden feelings well enough to wield them against you.  "I'm the ${fname} who's never hid ${his} true face from you—even when I had to hide it from others."
        
        "Are you sure, ${fname}?"  Breden's eyes hold yours, grave and unblinking. "Play at something long enough, you might find yourself truly feeling it.  You've somehow managed to keep yourself the same person?"
        *choice
          #Yes.  My true passions haven't changed.
            *if hypocrite = 2
              *set ruthreal %-10
            *if hypocrite = 3
              *set ruthreal %+10
            *if hypocrite = 4
              *set skepreal %-10
            *if hypocrite = 5
              *set skepreal %+10
            *if hypocrite = 6
              *set natlreal %+10
            *if hypocrite = 7
              *set natlreal %-10
            *label unchanged
            "I'm who I've always been, Breden," you insist.  "The same person you first loved.  The person you've always been able to see through."
            
            "The person who suddenly wants to marry me."  $!{xhis} mouth twists wryly.
            *goto nottobreed
          #After a long silence, I break ${xhis} stare.  "No.  No, you're right."
            *gosub disorientation
            
            "I'm not who I was," you admit, a little queasily. "You saw it before I did.  So when I tell you I've not changed what I feel for you—not one whit—I think you'll know that's true, too.  And I think you know you can trust that not to change."
            
            $!{xhis} breath hisses unhappily in and out of flared nostrils.
            *goto nottobreed
          #$!{xhe}'s right, but I'm not going to admit it.
            *gosub disorientation
            
            *goto unchanged
      *label nottobreed
      "And if I said I didn't want ${tobreed}, ${fname},
      *if tobreed = "children"
        even to adopt them,
      would that change what you want with me?"
      *label adoptbreed
      *choice
        *if helot
          #"No. I don't want ${tobreed} either."
            Breden blinks warily at you.  "Truly?  Why not?"
            *fake_choice
              *if (breedreason = 0) 
                #"You can ask that?  After all these years knowing you'd be killed if you didn't ${bear} children?"
                  The tears spill in earnest down Breden's face now, even as ${xhe} breaks into a smile. "Always felt the same, ${fname}.  The first time I heard a foreman say I'd breed or be Harrowed…Angels, it still eats at me."
              *if (breedreason = 1) 
                #"Same reason as you, love."
                  The tears spill in earnest down Breden's face now, even as ${xhe} breaks into a smile. "Ah, Angels, ${fname}.  You're not just saying that?"
              *if female and (xhe = "he")
                #"The risk.  The pain.  I've got enough of that already."
                  "Reckon I'd say the same if I were the one bearing rather than siring."  Breden grins faintly. "For me…from the first time I heard a foreman say I'd breed or be Harrowed, I wanted to fight back."
              *if acepref
                #I shrug.  "Just one more common desire that I seem to have been born without."
                  Breden breaks into a shaky smile.  "In this case, love, we seem to be a good fit with each other.  From the first time I heard a foreman say I had to breed or be Harrowed, I knew I'd have none of it."
              #"I've too many other things to spend my life on."
                Breden gives an emphatic nod, tears streaking ${xhis} face. "We're free from the Harrower now—and from all the bastards who told us we had to breed or die."
              #"I've just never felt much need for children."
                Breden breaks into a smile. "Well, thank 
                *if religion < 20
                  Angels.
                *if religion > 19
                  kenon.
                For me, from the first time I heard a foreman say I had to breed or be Harrowed, I knew I'd have none of it."
              #"Bring a child into this rebellion?"
                *if kids > 2
                  You lower your voice so no one else can hear it crack.
                  *if religion > 19
                    "Kenon
                  *if religion < 20
                    "Xthonos 
                  knows there are more than enough already."
                  
                Breden nods, bleak-faced. "Even before the rebellion, I'd thought it no kindness to ${bear} another little helot.  Not until the Hegemony is broken—along with every bastard who tries to tell us our only choices are to breed or be Harrowed."
            *label wellbringmore
            
            "Both you and I will bring better things into the world than children." You wrap your arms around ${xhim}.
            *if tobreed = "children"
              "And we don't need to adopt anyone.  There's others in the rebellion will do that."
            *label lipstoear
            
            After a long silence, Breden brings ${xhis} lips to your ear. "Yes.  I'll be your ${xspouse}, ${fname} ${lname}.  For whatever time we have."
            *goto weddingcer
        *if aristo
          #"No. I would be happy to be the last of the ${lname} line."
            You're flooded with both shame and relief as the words leave your tongue.  Never
            *if religion >= 20
              before—not even when you led the band to kenon!—have
            *if religion < 20
              before have 
            you so utterly flouted your father's precepts.  Breden stares at you in silent incredulity before at last saying: "Truly?"
            
            "What's a family name worth, Breden?  Or…or noble blood, when almost every so-called highborn has groveled before the Hegemony?  None of them will recognize House ${lname}
            *if orig_lname != lname
              or ${orig_lname}
            as noble any longer, anyway.  What would an heir to the name gain?"  You swallow against a dry throat. "My father spent his life trying to revive our family glory.  What has it gained him, or me?  Let it go.  Let it bloody go.  Especially if there's any chance it keeps me from getting you."
            
            *label aristotears
            Tears are streaking ${xhis} cheeks now, and ${xhis} voice comes cracked and breathless.  "Angels.  You say it now, 
            *if he = "she"
              kuria,
            *if he = "he"
              kurios,
            and don't think it's not sweet to my ears.  But can you really tell me you'll feel it the same in a year, a decade?  You don't think you'll find yourself hungering to leave some heir in the world?"
            *goto wellbringmore
        #"To be with you, I'm ready to give up a lot more than that."
          *if aristo
            *goto aristotears
          Tears course down Breden's smiling face; it takes a few moments before ${xhe} can speak.  "Can you see yourself regretting it, though, ${fname}?  I don't want you turning bitter on me in ten years."
          *goto wellbringmore
        *if ((tobreed != "children") and (breedreason = 0)) 
          *hide_reuse #"Would we take in an orphan?  Adopt a child?"
            "In time…we might.  I reckon it's possible.  But…"  Breden groans, shakes ${xhis} head.  "It's not just that I don't want to ${bear} a child, ${fname}.  My whole life, I've heard Ecclesiasts say one way or another that we're only worth as many children as we produce.  It's a lie.  One I've hated from the minute I heard it.  
            
            "So, no.  I don't want to adopt or ${bear} anyone.  
            *label bredwanthel
            I want the helots who follow
            *if deputy != "Breden"
              you
            *if deputy = "Breden"
              us
            to see that their lives can have value without a child."
            
            You nod slowly, trying to find your bearings.  "I…understand."
            
            Breden hesitates for a moment; you can see ${xhis} pulse pounding in ${xhis} throat. "And does it change what you're asking me?"
            *set breedreason 1
            *goto adoptbreed
        *if (breedreason = 0) 
          *hide_reuse #"It might depend on the reason you didn't want ${tobreed}."
            *label takesamin
            It takes a minute before Breden finally says, "Ever since I was a small ${xgirl}, I've had Ecclesiasts telling me one way or another that 
            *if aristo
              we helots are 
            *if helot
              we're
            only worth as many children as we produce."
            
            *if int > 0
              "It's a heresy," you point out. "Not all…"
            *if int = 0
              "Isn't that…" You're struggling to remember. "I'd thought I'd heard it called heresy by at least one Eccles…"
              
            $!{xhe} cuts you off, eyes ablaze.  "Heresy or not: it's a lie.  One I've hated from the minute I heard it.  I don't want any part of it in my life.
            *goto bredwanthel
        *hide_reuse #I can't fully hide my dismay.  "Children are important to me, Breden.  I can't lie."
          $!{xhe} nods, lips twisting sadly. "Important enough that you could only marry where there's the chance of a child?"
          *choice
            #"No.  No, there's something more important to me."  I reach out and take ${xhis} hand.
              "Ah, ${fname}."  Tears course down Breden's face, meeting an uncertain smile. "They're sweet words.  But how bitter will you turn in ten years with no 
              *if aristo
                heir to the ${lname} name?"
              *if helot
                child on your shoulders?"
                
              "You know it won't be easy for me, love."  You swallow back the regret, force your own lips to curve upward.  "But if it's the price to be with you, I'll pay it.  And I promise I'll not let it pull us apart."
              *goto lipstoear
            *if breedreason = 0
              #"Why do you not want ${tobreed}?  Is it that important to you?"
                *goto takesamin
            #"I…I don't know.  I need to think more on it."
              Breden turns ${xhis} face away from you; when ${xhe} finally speaks, ${xhis} voice is thick with emotion. "Let's say no more on it until we've survived the Phalangites, ${fname}.  No use in torturing ourselves about a future that neither of us lives to see."  Then ${xhe} turns back, pulls you close enough to kiss. $!{xhis} tears are hot against your cheeks. "But, ${fname}?  I'd not have either of us spend these next weeks lonely."
              *set xspouse "lover"
              *goto account2
            #"Yes.  I'm sorry.  It is."
              *label wherewestand
              "Then I think we know where we stand, ${fname}."  Breden stares at you, regret achingly plain on ${xhis} face. Then ${xhe} pulls you to ${xhim} for a savage kiss; ${xhis} tears are hot against your cheeks. "And I'll let you go when you find the ${xgirl} who'll give you those children.  But Xthonos, I'd not have either of us spend these next weeks lonely."
              *set xspouse "lover"
              *goto account2
        *if aristo
          #"I'm the last of the ${lname} name, Breden.  I need an heir."
            For your House to be extinguished with your death…it would be an intolerable victory for the Hegemony, and a betrayal of all the ${orig_lname} forebears who passed down their name and blood to you. No matter what you feel for Breden, that's too high a price to pay.  "There must be an heir.  Natural or adopted…but I need a child to bear my name."
            
            "You couldn't adopt in a young noble just to carry on the name?"  There's an edge of desperation in ${xhis} voice.  "It needs to be a child?"  
            
            "It does."  It doesn't, strictly speaking.  But you'd always assumed you would raise your own heir, and you're not ready to let go of that idea.  What alternatives are possible now that you're a rebel, anyway?  Your thoughts are too scattered and emotion-laden to sift them seriously.
            
            *goto wherewestand
      *label weddingcer
      *page_break
      *achieve wedding
      *if helot
        The camps around
      Rim Square saw a few weddings every spring:
      *if aristo
        the older brothers and sisters of your noble peers, the scions of the main merchant families.  The agora would be strewn with silk ribbons and willow blossom, with a great feast for the whole town.  Servants of the Pelematou or Keriatou would come out with their viols and flutes and play themselves into exhaustion, pausing only for the actual rite of union at moonrise.  The nobles and free townsfolk would dance until the fires burned low and the horizon began to hint at dawn.
      *if helot
        the cautious youth who just turned twenty, the less cautious two or three years older, a few haggard widows and widowers still of childbearing age.  The elders would go with a Diakon to beg a bit extra food from the masters, and the yeasters would drag out their great ale jars.  Celebrations usually began in the late afternoon and built steadily as helots from more distant estates arrived.  By sunset the riotous singing could be heard from the furthest farm in Acron.
      
      At your own wilderness wedding the fires have to be kept low and the music restrained.  You can barely manage clean clothes, let alone 
      *if aristo
        the typical gold-trimmed robes.
      *if helot
        a new kyrtle.
      There's little out of the ordinary you can manage for food, and the ale is doled out sparingly, keeping in mind the possible necessity of an early morning flight. But the pipes and muffled drums play as joyous a reel as ever you've heard, and there's an intensity to the merrymaking that 
      *if helot
        you've only seen after particularly grim Harrowings.
      *if aristo
        you've never seen at any noble marriage.
      
      When your followers carry you both up the starlit hill to the improvised altar-block, their faces are solemn and eyes bright. Everyone tall enough presses in close, trying to keep their hand among the ones holding you up.  Despite the rugged terrain, you're borne up as smoothly and securely as if you were in a
      *if helot
        noble's
      litter, and lowered to the ground at last with great care.  The usual babble around a wedding rite is completely absent tonight; every eye is on you, every tongue stilled.
      
      "${fname} ${lname},
      *if eclect
        Eclect of the Merciful Angels:
      will you bind yourself to Breden Reaper as ${xhis} ${spouse}, and ${xhim} to you 
      *if xspouse = spouse
        in the same wise?"
      *if xspouse != spouse
        as your ${xspouse}?"
      *if rescuer = 0
        Joana Orchard's warm, familiar voice resonates through you as if you're the one speaking.
      *if (rescuer > 0) and zv_here
        Zvad's deep voice resonates through you as if you're the one speaking.
      *if (rescuer > 0) and not(zv_here)
        *if deputy != "Breden"
          ${deputy}'s 
        *if deputy = "Breden"
          Alira's 
        voice carries strong and clear across the dark meadow.
      
      "I do so bind me, and 
      *if religion < 20
        call all Angels 
      *if religion > 19
        in our shared kenon I call all these ${addressc}
      as my witness."  You don't realize you're holding your breath until Breden has echoed the vow.  The wedding knot is wrapped around your wrists, gauzy but firm.
      
      "Then in 
      *if religion < 20
        the name of Xthonos and all Angels, 
      *if religion > 19
        kenon's truth,
      I declare you wed."
      *if rescuer = 0
        Joana
      *if (rescuer > 0) and zv_here
        Zvad
      *if (rescuer > 0) and not(zv_here)
        *if deputy != "Breden"
          ${deputy} 
        *if deputy = "Breden"
          Alira
      *if sacrament = 0
        pours dust over your joined hands.
      *if sacrament = 1
        spills sacramental water over your joined hands.
      *if sacrament = 2
        beckons to the other outlaws, and the susurration of sacramental breath rises from all around you.
      *if sacrament = 3
        hands you two lamps, whose sacramental flames you unite over the knot.
      "Walk in Order together from this day until you
      *if religion < 20
        return to Xthonos's earth.   
      *if religion > 19
        are parted by death.
      Be chaste in unity, 
      *if religion > 19
        resisting Xaos, 
      faithful ever to the vows of marriage.  Let your joy be a sign for the foolish, for the weak, and for us all who stand witness to your union."
      
      The silence after the litany is broken by a whoop from
      *if followers < 100
        several dozen
      *if followers > 99
        *if followers > 200
          over
        a hundred
      *if morale < (followers/2)
        elated
      witnesses.
      *if morale < (followers/2)
        Despite all the grumbling against your leadership, something about the rite has clearly caught your outlaws' hearts.
      *set morale +15
      "Now kiss me, ${bfname}," Breden murmurs—and you do.
      *set bredwed true
      *page_break
      The celebrations around the altar last an hour or so. Then the other outlaws begin heading downhill to continue the revelry in the main camp.  The older ones wink and clap you on the shoulder first, offering oblique comments about their own wedding nights.
      *if simz_here and (s_lover = 2)
        ${simon} de Firiac gives you a quick, unsmiling nod before vanishing.
      *if (ciels > 9) and (c_rel > 0)
        You'd been wondering if you would see Ciels, but ${he} appears and tersely wishes you both well with
        *if c_rel > 5
          a genuine 
        *if c_rel < 10
          an only slightly forced
        smile.
        
      *if el_here
        "Blessings on you both!"
        *if e_rel > 8
          Elery emerges from the night to throw her arms around you, laughing giddily.  "Though, ${oath}, it took you bloody long enough to ask, ${addressu}.  Glad you had the sense to get it sorted before the Archon arrives."
          *set e_rel +1
        *if e_rel < 9
          Elery manages a smile and a cursory embrace of you before she throws her arms around Breden. You can barely hear her growl, "Hope it all goes as well as you think it will.  Better, even.  Bless you."
      
      One person doesn't appear as the crowd thins out.  You've not seen your father at any point since you asked Breden to marry you.  He clearly heard the news from someone else. Since then he has never appeared at common mealtimes nor slept near you; only the occasional glimpse of him hurrying in the opposite direction gives you any reason to think that he's still alive and with the band.
      *fake_choice
        #I can only feel relieved.  The less I see of him, the better.
        #He ought to be here—and it angers me every time I remember that he's not.
        #I try not to think about it.  A new ${spouse} shouldn't weep on ${his} wedding day.
      *label fakefix
      When there are only a handful of others left on the hilltop, Breden twines ${xhis} fingers through yours. "So.  Shall we see what…that waterfall up there looks like by moonlight, love?"  The two of you slip away to one last raucous burst of cheers, shouted advice, and laughter.
      
      The glen you end up in is nowhere near the waterfall, but both of you immediately recognize it as what you've been looking for: moonlit, dry, carpeted in soft grass and meadowflowers.  In the summer night, you shed your kyrtles swiftly without shivering.  The smell of crushed birdsfoot and clover spills into your nostrils when you first stretch out on the ground.  
      
      Then Breden's warm skin fills all your senses.
      *if ((bred_lover < 10) and (bred_lover >= 4)) and not(acepref)
        *page_break $!{oath}. This was worth waiting for.
        *goto honeymoon
      *else
        *page_break
        *goto honeymoon
    *if (not(choice_randomtest)) #I'd marry Breden, but not now.  Not when either of us could be dead within weeks.
      *goto account
    *if (not(choice_randomtest)) #I'd marry Breden, but only if I could be sure ${xhe} weren't the traitor.
      *goto account
    *if (not(choice_randomtest)) #The odd feeling dissipates completely.  I've no intention of marrying Breden.
      *goto account
    #In fact, it's past time that I ended my relations with ${xhim}.
      *if bred_lover >= 4
        *set bred_lover 3
      *if bred_heart = 3
        *set bred_heart 7
      It takes you the better part of an hour to find ${xhim}, trudging back from a day of drills in a distant clearing.  $!{xhe} sees at once from your face that something's amiss.  "What is it, love?"
      
      "Breden…" Staring into those dark, intent eyes, you almost change your mind. "We've hardly seen each other for weeks…and I'm sorry, but it's cleared my thoughts.  I can't afford to have my mind pulled away from the battle.  Not this one to come, and we can expect another one to follow soon after."
      
      $!{xhe} looks stricken for a moment before the wall comes up, implacable and angry.  "Is there someone else?"
      
      *if k_rel = 4
        You do your best to lie with a straight face.
      "No.  I just said…"
      
      "I heard you, ${bfname}. 
      *if aristo
        You're done playing your games with the helotry.
      Have it your way, then." 
      
      You stare at ${xhim}, taken aback.  "That's all you have to say?"
      
      "Neither of us have time for more of this." $!{xhe} pushes past you and keeps walking toward camp with a brittle-looking gait.
      *goto set_troops
*label account
*if (((bred_lover >= 4) or (bred_heart = 3)) and (bred_trust >= 10)) and bred_here
  Breden catches you gazing wistfully at ${xhim} one afternoon, grimaces, and walks over to confront you. "Wondering what treachery I'm working into our preparations, ${bfname}?"
  
  After a moment of shock, you glower back at ${xhim}. "Should I be?"
  
  "Don't know why you'd stop now." $!{xhe} pushes past you and keeps walking toward camp with a brittle-looking gait.
  *goto set_troops
*if (((bred_lover >= 4) or (bred_heart = 3)) and (bred_trust < 10)) and bred_here
  As it turns out, you're not the only one who's been affected by the separation.  Around sunset, Breden comes looking for you, eyes bright and intent. "You've barely stopped to eat or sleep these last weeks, ${fname}.  When was the last time we properly saw each other?"
  
  "I've asked myself the same question."  You can feel the pulse speed up in your throat.
  
  "Well…ready or not, they'll be coming after us soon.  And I thought tonight might be the last chance we have to be together."
  *if acepref and (bred_lover < 10)
    $!{xhe} clears ${xhis} throat.  "There are many ways we could enjoy each other's company.  I wanted to just ask, if you'll forgive me…"
    *choice
      #I shake my head at once.  "I've not changed, Breden."
        $!{xhe}
        *if ciels < 10
          looks as if ${xhe}'s about to say something for a moment—then sighs and inclines ${xhis} head in acceptance.
        *if ciels > 9
          grins ruefully.  
        "Can't blame a ${xgirl} for one last try.  Come with me then, love.  Let's spend the night with each other."
        
        *goto account3
      #I take ${xhis} hand. "Nothing's changed, love.  But if it would make you happy…"
        *set bred_lover 11
        *set aceprop true
        Breden looks up sharply at you. "Truly?"
        
        "Aye, truly."  You laugh at the bemused, half-guilty look on ${xhis} face. "It's a small thing to me, love.  I don't think it's quite as small to you.  Let's try."
        
        After a moment's silence, ${xhe} leans forward and slowly brings ${xhis} lips to yours.  It's as odd a sensation as you'd always suspected; there's clearly some trick to avoiding ${xhis} nose that you'll have to work out.  But you don't mind it, and quite enjoy the stupefying impact it seems to have on Breden.  
        
        "Angels," ${xhe} says hoarsely, pressing ${xhis} fingers into your back. "Now that's something I've been dreaming of for a long time."
        
        *goto nosmallthing
      #"$!{oath}, yes." All these months of closeness have kindled a new kind of desire in me.
        Breden looks up sharply at you. "Truly, ${fname}?  I mean…you said you'd never…"
        
        "I never have, for anyone else."  You reach out to cradle ${xhis} face, then lean in and press your lips against ${xhers}.  It's as odd a sensation as you'd always suspected, and there's clearly some trick to avoiding each other's noses that you'll have to work out.  "But I've never twined as much of my soul with anyone else as I have with you."
        *set bred_lover 12
        *set aceprop true
        
        *goto nosmallthing
  $!{xhe} leans in close, filling your nose with heady scents: woodsmoke, crushed grass and wildflowers, ${xhis} skin warmed by sunlight.  "There's a quiet glen upslope.
  *set glention true
  *if bred_lover = 5
    If you've had any second thoughts about the state of your reputation, noble ${milady},
  *if bred_lover = 6
    Unless you still think it will bring down Xaos,
  *if (bred_lover = 7) or (bred_heart = 3)
    If you'll forgive my boldness,
  *if bred_lover = 8
    With as secluded and comfortable a meadow as anyone could ask.  Forgive my boldness, ${fname}, but
  *if bred_lover = 9
    If you've finally decided you trust me enough,
  I know a use we could put it to."
  *label account2
  *choice
    *if bred_lover >= 10
      #I pull ${xhim} after me into the woods.
        *if not(glention)
          *gosub theresaglen
        *if not(proposal)
          *if acepref
            Thanks to Breden's eagerness, you
          *if not(acepref)
            You 
          don't make it as far as the glen.
        *if proposal
          Within minutes, you find what you're both looking for: a moonlit glen carpeted in soft grass and meadowflowers.  In the summer night, you shed your kyrtles swiftly without shivering.  The smell of crushed birdsfoot and clover spills into your nostrils when you first stretch out on the ground.
          
          Then Breden's warm skin fills all your senses.
        
        *goto honeymoon
    *if bred_lover < 10
      #It's time.  I give myself to ${xhim} completely—no more holding back.
        *if not(glention)
          *gosub theresaglen
        It takes an hour for you to reach Breden's glen, slowed as you are by kisses and clutching at each other.
        *if (bred_lover > 4) and (bred_lover < 8)
          Shame flickers at the edge of your consciousness, but you shut it out ruthlessly.
        By the time you finally step out into the moonlit meadow, your whole body feels afire under ${xhis} touch.  Your kyrtles slip to the ground, and all you can see is ${xhim}: dark, lithe, perfect.
        *label nosmallthing
        *if bred_lover > 10
          Slowed as you are by clumsy kisses and clutching at each other, it takes you some time to find what you're both looking for: a moonlit glen carpeted in soft grass and meadowflowers.  In the summer night, you shed your kyrtles swiftly without shivering.
        
        $!{xhe} pauses then, no longer touching but close enough for you to feel the heat of ${xhis} skin.  $!{xhis} eyes fill with uncertainty and desire. "I don't want…Angels, ${fname}, I know this is no small thing.  But if you'll have me…"   
        
        You answer ${xhim} without words.
        *if bred_lover > 10
          *page_break
          *goto honeymoon
        
        *label honeymoon
        *if bred_lover < 10
          *set bred_lover +10
        *label account3
        *if acepref and (bred_lover < 10)
          You hold each other and talk through the night's darkest hours, sharing your plans and fears for the battle ahead.
        Much later, you're staring drowsily up at the stars when Breden whispers, "${fname}?"
        
        "Yes?" you say, taking ${xhis} hand.
        *if (bred_lover = 11) and aceprop
          You're trying to think how best to explain that it wasn't unpleasant, though you doubt you'll ever really acquire the taste for it.
        *if (bred_lover = 12) and aceprop
          You're trying to think how best to tell ${xhim} that it felt wonderfully natural—a sharing you'd only make (or want to make) with this one extraordinary soul.
        
        "Any day now…it's going to happen." $!{xhis} voice is level, determined.
        *goto honeymoon2
    *if bred_lover < 10
      #I won't abandon chastity—but I still spend the evening kissing ${xhim}.
        At one point, ${xhe} pulls back, gasping, fingers tangled in your hair. "I hate to ask it, ${fname}, but…wouldn't 
        *if helot
          the priests 
        *if aristo
          your noble friends
        also consider this Xaotic and unchaste?"
        
        "Anything done with lips alone?"  You give a sharply dismissive head shake. "Some might.  I don't care."
        
        *goto honeymoon
    *if proposal and (xspouse = "lover")
      #My feelings are still too raw after ${xhis} response to my offer of marriage.
        "I'm sorry, Breden.  I'll need to be alone for a time."  You pull away, not trying to hide your disappointment.
        
        *if bredupset
          *label furytwist
          $!{xhis} face twists furiously, and ${xhis} voice is choked.  "Angels!  I should have had the sense…"  Then ${xhe} stalks away, pausing only to shout over ${xhis} shoulder, "Don't come looking for me when you change your Xthon'damned mind,
          *if aristo
            ${kuria}
          ${lname}."
          *if bred_lover > 10
            *set bred_lover 13
          *if bred_lover < 10
            *set bred_lover 3
          *goto set_troops
        "I'm sorry, ${fname}."  For a moment, Breden looks as wretched as you've ever seen ${xhim}.  "I wish…I wish I were the right one for you.  Truly I do."
        *goto set_troops
    #A tumble in the woods with ${xhim} is the last thing I want just now.
      You give a helpless, bitter laugh.  "I'm sorry, love.  The battle's coming, it's all I can think about, and…I just can't, now.  I'd not truly be there with you."
      
      *if bredupset
        *goto furytwist
      Breden looks like ${xhe}'s keen to say something, but after a moment ${xhe} exhales slowly instead and offers a rueful smile.  "Well.  Then let's sit here together awhile, love.  Talk to me.  Give yourself an hour's respite.  We can at least enjoy that much time in the same place."
      *goto set_troops
  *label honeymoon2
  *if bredwed
    *set bred_lover +10
  "They'll come.  And we might not win.  We might have to run.  
  
  "If worst comes to worst, and they're about to kill you…there's a last resort worth trying.  Put up your hands and say, [i]I wish to make an accounting[/i].  Supposedly they can't kill you then and there.  They'll try to take you to a commander.  And that might just give you enough extra time to escape."
  
  You sit up and stare at ${xhim}.  "Where did you hear that?"
  
  "A story from my old masters.  Back in the Souther Coast."  $!{xhe} rolls over to look at you.  "They loved puffing themselves up as if they would fight the Karagonds one day.  Probably half the things they said were inventions.  But if this one were true…"  $!{xhis} tone is level. "For the Phalangites to believe it, only one of us can try saying it.  Otherwise they'll wisen to the game and kill us all.  And it should be you.  You should have that chance."
  
  "That's…a Kryptast code.  Surely."
  
  Breden holds your stare, unblinking.  "I've always assumed so."
  *set needfood 9000
  *comment tracking acctg
  *choice
    #"How could your masters have learned something like that?"
      *set accounting 2
      "They fancied themselves rebels, ${fname}.  I took all kinds of ideas from them.  I don't know where they got them all."  Breden swallows hard, looking suddenly miserable. "This one…well, I wasn't going to share it with anyone.  Because of what they'd think.  But just now I thought I wanted to share it with you."
      
      "Well.  Thank you."  You look away uncomfortably, and a silence settles between the two of you. "It's…almost certainly an invention.  Kryptasts wouldn't let that kind of thing get about."
      
      "I reckon not." $!{xhe} rolls into a crouch, then stands.  There's a wistful note in ${xhis} voice.  "But…maybe someone overheard it once, ${fname}.  At the end of some fight or raid where they'd have expected the Alastors to just kill everyone.  The story might have started that way.  It might be true."
      
      "I'm not going to count on it."  You also stand, swallowing against the sudden dryness in your throat. "In any case,
      *if strategy = 1
        we're going to beat them.  They'll be the ones asking to make an accounting to us."
      *if strategy = 2
        they're not going to find us, let alone catch us."
      *if strategy = 3
        *if helcamp < (followers/2)
          there's still a slim chance that
        we're all going to be hiding in the Rim by the time they come for us."
      
      "I hope so, ${fname}." Going by ${xhis} forlorn tone, it's not much of a hope.
      *goto set_troops
    #"What am I supposed to do with that, Breden?"  My breath is coming more rapidly in my nostrils.
      *set accounting 3
      "Save your own life, if it comes to it," Breden says, eyes suddenly glistening in the moonlight.  "And you're supposed to trust me."
      
      "I have trusted you. Bloody ${oath}, I've put my life in your hands. You don't make it easy, though, do you?"
      
      "Damn it, ${fname}." $!{xhe} stands swiftly and turns away from you. When ${xhe} speaks again, ${xhis} voice is strained and shaking. "It isn't easy.  It can't be easy.  Not in the world we live in.  If you don't want to trust me, there'll always be reason enough not to."
      
      "If I didn't want it, we'd not be out here."  You stand as well, feeling dazed and lost. "But when does wanting to trust you just become blindness, Breden?  How much am I supposed to explain away?"
      
      "If you don't know I love you, and that that means you can trust me…" Breden's words trail away.
      *if bred_lover > 19
        "Angels.  Then I just made the mistake of my life."
        *set bred_lover 23
      *if bred_lover < 20
        "We'd best stop pretending to be lovers, ${addressu}.  It was a good pretense, though. I was fooled."
        *if bred_lover > 10
          *set bred_lover 13
        *if bred_lover < 10
          *set bred_lover 3
      $!{xhe} 
      *if bred_lover > 9
        shrugs on ${xhis} kyrtle and 
      starts for camp at a near-run.  For the next few days, ${xhe} finds ways to avoid you.
      *goto set_troops
    #"$!{oath}. You're a bloody Kryptast." I force out the words, fighting the urge to scream or vomit.
      *set accounting 4
      Breden rolls to ${xhis} feet, tears spilling down ${xhis} suddenly contorted face. "I knew it.  Knew I shouldn't tell 
      *if bred_lover < 20
        you."
        *if bred_lover > 10
          *set bred_lover 13
        *if bred_lover < 10
          *set bred_lover 3
      *if bred_lover > 19
        you, even now."
        *set bred_lover 23
      
      "What?  That you know something that no one but one of Them would know?"  Your voice sounds shrill and angry in your ears, and you feel on the verge of weeping as well. "How much am I supposed to overlook or explain away, Breden?  How long do I ignore what's staring me in the face?"
      
      "There are a hundred ways that my old masters could have heard a Kryptast code," Breden nearly screams, flinging ${xhis} arms wide. "A hundred explanations. Or it could be made up.
      *if bred_lover > 19
        You're my ${spouse}, ${fname}.
      Why would you choose the explanation that makes a traitor of me?"
      
      "How did your old masters die, Breden?" you demand.  When ${xhe} flinches, you press on fiercely, "How did things end for them, and their seditious talk, and their plans of rebellion?  You've never told us.  Was that for a reason?"
      
      Breden sags into ${xhim}self, ${xhis} fury collapsing into mere misery.  "They were killed, of course."  You've never seen so transparent a look of loss as the one wringing ${xhis} face now. Despite yourself, it reduces you to silence.  "They all died.  But I thought I'd keep their ideas alive.  I thought it might not always have to end that way."  After a few moments, ${xhe}
      *if bred_lover > 9
        shrugs on ${xhis} kyrtle and 
      stumbles off in the direction of your camp.
      
      In the morning, ${xhe}'s gone, without so much as a farewell.
      *fake_choice
        #$!{oath}…what have I done?
          If you'd had the least suspicion that your doubts would actually drive your 
          *if bred_lover < 4
            beloved
          *if (bred_lover < 20) and (bred_lover >= 4)
            lover
          *if bred_lover > 19
            ${xspouse}
          to flee the band, you'd never have spoken them aloud.  Grief-stricken and guilty, you try to track Breden down,
        #I'm wracked by doubt.
          An innocent driven away, or a traitor fleeing to share your plans with ${xhis} masters before ${xhe}'s finally caught?  You try to have ${xhim} followed,
        #Damn it all.  $!{xhe} is a traitor, ${xhe}'s made a fool of me, and all I regret is that I didn't kill ${xhim} last night.
          *set bred_trust +10
          You try to have ${xhim} hunted down, 
      but ${xhe}'s moving fast enough to escape your rangers.
      *set bred_here false
      *set followers -1
      *set nonkids -1
      *set breden 16
      *if deputy = "Breden"
        
        Appointing a new second-in-command is your most urgent task; the desertion of your deputy
        *if zvad > 10
          so soon after Zvad's abrupt departure
          *set morale -5
        has hurt your morale at the worst possible time.  You choose:
        *set morale -10
        *gosub pickadeputy
      *goto set_troops
    *if (acepref) #I stare at ${xhim} for a long time before clasping ${xhis} hand and murmuring, "Dangerous thing to admit to knowing.  Thank you."
      *goto goodaccount
    *if (not(acepref)) #I stare at ${xhim} for a long time before kissing ${xhim} and murmuring, "Dangerous thing to admit to knowing.  Thank you."
      *label goodaccount
      *set accounting 1
      $!{xhis} calm facade shatters as soon as your 
      *if not(acepref)
        lips 
      *if acepref
        fingers
      touch ${xhers}. "Oh, my love."  $!{xhe} beams through ${xhis} tears, ${xhis} whole body trembling, and 
      *if acepref
        presses your hand against ${xhis} heart.
      *if not(acepref)
        fervidly kisses you back. 
      "My love."
      *goto set_troops

*label set_troops
*if needfood = 9000
  *set needfood +accounting
  *comment tracking acct code
*set aristroops (292-cred_a)
*if aristroops < 0
  *set aristroops 0
*set merchtroops round(260-cred_m)
*if merchtroops < 0
  *set merchtroops 0
*set priestroops round(200-cred_p)
*if priestroops < 0
  *set priestroops 0
*set yeotroops (200-cred_y)
*if yeotroops < 0
  *set yeotroops 0
*set phalangites +notoriety
*if anarchy > 30
  *set phalangites -(anarchy*2)
*set phal2 60
*set phal3 60
*if phalangites < 180
  *set phal2 round(phalangites/3)
  *set phal3 round(phalangites/3)
*if phalangites > 300
  *set phal4 60
  *set theurges +1
*if phalangites > 360
  *set phal5 60
  *set theurges +1
*set phal1 ((((phalangites-phal2)-phal3)-phal4)-phal5)
*if (theuknown >= 10)
  *set theurges +3
*if anarchy <= 0
  *set alastroops 60
  *goto forcesize
*elseif anarchy < 5
  *set alastroops 110
  *goto forcesize
*elseif anarchy < 10
  *set alastroops 100
  *goto forcesize
*elseif anarchy < 20
  *set alastroops 80
  *goto forcesize
*elseif anarchy < 30
  *set alastroops 60
  *goto forcesize
*else
  *set alastroops 50
  *goto forcesize
*label forcesize
*gosub alltcheck
*set theirmorale alltroops
*set theirtotal alltroops
*set alastroops_orig alastroops
*set phal_orig phalangites
*if merchtroops < 60
  *set allmain -(60-merchtroops)
*set mainmules round(((allmain*0.47)*(6/7))/4.5)
*page_break
*if (strategy < 3) or (popular = 10)
  *set inwoods followers
  *set inadults nonkids
  *set inkids kids
*if (strategy = 3) and (popular != 10)
  *if helcamp < 0
    *set helcamp 8
  *if nonkids <= 21
    *if kids <= 2
      *set helcamp 0
      *set inwoods followers
      *set inadults nonkids
      *set inkids kids
      *goto debuglabel
    *else
      *if helcamp >= kids
        *set outkids kids
        *set helcamp kids
      *if kids > helcamp
        *set outkids helcamp
      Over the weeks, the few surviving adults in your band have managed to sneak
      *if outkids = kids
        all
      *set d2n_num outkids
      *gosub d2n
      of the band's children back into the Rim for fostering.
      *set inkids (kids-outkids)
      *set inadults nonkids
      *set inwoods (followers-helcamp)
      *goto debuglabel
  *if helcamp >= (followers-21)
    *achieve tothecamps
    *set helcamp (followers-21)
  *set inwoods (followers-helcamp)
  *if kids > 2
    *if (helcamp-8) >= kids
      *set outkids kids
    *if kids > (helcamp-8)
      *set outkids (helcamp-8)
  *if (helcamp-outkids) > nonkids
    *set helcamp (outkids+2)
  *set inkids (kids-outkids)
  *set inadults (nonkids-(helcamp-outkids))
  Over your weeks of preparation, you've managed to sneak 
  *set d2n_num helcamp
  *gosub d2n
  of your followers
  *if outkids > 0
    (including
    *if outkids = kids
      all of the band's remaining
    *set d2n_num outkids
    *gosub d2n
    children)
  back into the helot camps of the Rim, leaving 
  *if inwoods < 30
    only
  *set d2n_num inwoods
  *gosub d2n  
  with you in the woods.
*if choice_randomtest
  *choice
    #Just pre-intel, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.  ${inwoods} inwoods, ${inadults} inadults, ${inkids} inkids.  Snuck out ${helcamp} to helot camps, including ${outkids} kids.  Morale is ${morale}.
      *goto debuglabel
*label debuglabel
*if (inadults > 0)
  *set armshare (arms/inadults)
*if armshare > 1
  *set armshare 1
*if armshare < 0.66
  *set armshare 0.66
*if followers <=0
  *set followers 1
*set morshare (morale/followers)
*if morshare > 1
  *set morshare 1
*if morshare < 0.66
  *set morshare 0.66
You're pulling
*if strategy = 3
  your remaining outlaws
*if strategy = 1
  most of your outlaws
back into the deep wild, so it takes a while for news to reach you.
*if strategy = 3
  
  *comment endif
But just before sunset one day, your deputy strides up to you and mutters under ${dephis} breath, "The Phalangites are in Rim Square now.  Or were a week ago, when our scouts heard the news.  By this time, they'll likely be ready to move into the woods."

A few minutes later, you're both in the Leader's Tent with Young Earnn and three other exhausted, tense-looking rangers.  "What word?" you demand.

"They're moving."  There are rivulets of sweat on Earnn's brow, and his voice is taut.  "Got patrols up for three miles around the town, and they've been questioning everyone they see, especially in or near the forest.  Anyone without a good reason to be there and someone to vouch for them goes straight to the Harrower.  So all we know is what we've heard by dropping in on friends who do have good reason to be there."

"And our 
*if intelsale > 0
  informants and other
friends tell us…"

*if calea > 9
  "Start with the strangest one."  The bemused-looking young tracker hands you a leather tube with a paper scroll inside. "On our way back, we came across a lone traveler.  Well dressed, like a merchant or maybe even noble.  I was ready to put an arrow in her, but she said she'd been hired to pass on a message to the Whendward bandits.
  
  "When she'd given it us, she went straight back to the Rim.  Definitely didn't try following us." Earnn peers over your shoulder as you unroll it. "I learned a few letters, ${addressu}, and everything written here seems to fit what we heard from others." 
  *page_break
  Calea's hand is unmistakable, even if she doesn't sign her name. You're stunned at the risk she's taken to get this to you. 
  
  [b][i]Phalangites: [/i][/b]
  *set d2n_num phalangites
  *gosub d2n_np
  [i]${display_numb} all told.[/i]
  *if anarchy > 30
    [i]Not including the [/i]
    *set d2n_num anarchy
    *gosub d2n_np
    [i]${display_numb} or so who had to stay behind to help the Alasts. put out some of the fires you've started in the Rim.[/i]
  *if phalangites > 360
    [i](They're [b]very[/b] annoyed with you, ${fname}.)[/i]
  *set d2n_num phal1
  *gosub d2n_np
  [i]$!{display_numb} in the main host, commanded by a Tagmatarch with a Theurge-forged sword.  Another[/i]
  *if phalangites > 360
    [i]four[/i]
  *if (phalangites <= 360) and (phalangites > 300)
    [i]three[/i]
  *if (phalangites <= 300)
    [i]two[/i]
  [i]groups of sixty coming from other directions.[/i]  (A sketched map shows roughly where you can expect the flanking forces to enter the wilderness.)
  *line_break
  [i][b]Nobles[/b]: committed [/i]
  *set d2n_num aristroops
  *gosub d2n_np
  [i]${display_numb} to hunting you down.[/i]
  *if aristroops < 90
    [i](Just to keep up appearances, most of them; you've done remarkably little to upset our lot, in truth.)[/i]
  *if aristroops > 189
    [i](And be warned, they all want your head.  Rather badly.)[/i]
  *line_break
  [i][b]Alastors: [/b][/i]
  *set d2n_num alastroops
  *gosub d2n_np
  [i]${display_numb} coming, mostly with the main Phal. force.[/i]
  *if alastroops < 80
    [i](There would be more, but [/i]
    *if anarchy = 0
      [i]you've been so gentle, they don't take you seriously.)[/i]
    *if anarchy > 0
      [i]you've spread enough Xaos in the Rim that they're finding it hard to step away from it all.)[/i]
  *line_break
  *if (priestroops > 0) or ((merchtroops > 0) or (yeotroops > 0))
    [i]Also, I hear you've angered enough
    *if (priestroops > 0) 
      [i]priests that they've mustered a mob to join the hunt,[/i]
      *if ((merchtroops > 0) or (yeotroops > 0))
        [i]and enough[/i]
    *if (merchtroops > 0)
      [i]merchants that they've sent hirelings to guard the baggage trains,[/i]
      *if (yeotroops > 0)
        [i]and enough[/i]
    *if (yeotroops > 0)
      [i]yeomen that several villages have sent archers to join the hunt,[/i]
    [i]though I don't have numbers for those.[/i]
    *line_break
  *line_break
  [i]Three Theurges, at least—perhaps more.[/i]
  *line_break
  [i]Do try not to die.  Yet.[/i]
  *set intel +20
  
  You slide the scroll back into its sleeve, feeling:
  *fake_choice
    *if (alltroops > 600) #Nothing but terror at the scale of the forces it describes.
      You do your best to keep your dread from showing.
    #A surprising surge of gratitude, tinged perhaps with even a little fondness.
      Trust Calea to find a way.
    #Irritation.  I can hear Calea's voice reading the letter—and it's insufferably smug.
      Her House's future hangs on your success—but you're sure that if you do survive, she'll see it as [i]her[/i] success, not yours.
    #A burst of rage at that final word and all it portends.
      You'll never forget that she intends your defeat in the end.
    #A calculated determination to win this game, with both the Hegemony and the Keriatou.
      There's no room for more personal sentiments in a contest like this.
  "And you say these numbers fit with what you've heard from others?"
  
  Earnn gives a brisk nod. "Aye.  For the forces mustered in Rim Square, certainly.
*if calea < 10
  "That
  *if phal1 > 280
    some three hundred
  *if (phal1 < 281) and (phal1 > 190)
    some two hundred
  *if (phal1 < 190)
    a hundred or a hundred-fifty
  Phalangites are about to leave Rim Square to hunt for us—with more on the march elsewhere.
*if (cred_y > 230)
  We stopped off in some friendly yeoman villages, and they
  *if calea > 9
    also
  told us about at least two other flanking forces who will be entering the Whendward,
  *if calea < 10
    in areas where they go hunting.  So we know where to look for them, at any rate."
  *if calea > 9
    here and here." Earnn points to two points on Calea's map.
  *set intel +5
*if (cred_y < 231)
  No one we know has been able to confirm where the other Phalangites might be…but we know there's more than just the ones in Rim Square."
*if (calea < 10) and (intelsale > 0)
  
  A scraggly-bearded scout of seventeen or so leans forward, his face tight with fear. "Our informers say the Tagmatarch who's leading the host has a Theurge-forged sword.  A gift from the Archon herself."

*if (calea > 9) or (intelsale > 0)
  *if calea > 9
  
    "Angels, ${addressu}," a scraggly-bearded scout whispers, his face tight with fear.  "Are you not going to talk about the fact that they've got a bloody Theurge-forged sword?"
    
  *if plekspear
    *if pleksecret
      Your mind leaps immediately to your secret spears.  "We'll just make sure everyone knows to save an arrow for the fellow with the fancy sword."
    *if not(pleksecret)
      You manage to keep your voice smooth as you shrug.  "Well, if it comes to a duel with Theurgic weapons…I'd rather be the one with the spear."
  *if not(plekspear)
    You try not to let your own
    *if theurgy < 2
      terror
    *if theurgy > 1
      nervousness
    show.  Theurge-wrought arms can supposedly cut through anything.  Because of the vast amount of blood required in their forging, they're also extremely rare—almost never seen away from the Halassur frontline.
    *if aristo
      You remember hearing Hector talk in awe about seeing the Archon's personal guard split a boulder in two with a single blow.
    *if theurgy > 1
      
      As a ${wisard}, you could easily deal with this Tagmatarch one-on-one—but enemy Theurges will be in the air, 
      *if theuknown < 10
        and may be able to sense your powers.
      *if theuknown >= 10
        hunting for you. 
      Anything that allows the Phalangites to rapidly slaughter your outlaws while leaving the Theurges undistracted is disastrous.
    "We'll make sure everyone knows to save an arrow for the fellow with the fancy sword."
*page_break
"What about Theurges?" ${deputy} asks sharply.

*if (cred_p >= 215)
  One of the other scouts clears her throat.  "I heard something from a friendly Diakon.  Said a Theurge paid a visit to the Naos and told the Ecclesiast to expect
  *set d2n_num theurges
  *gosub d2n
  magi."
  *if theuknown >= 10
    Her cheeks twitches as she stares at you.  "At least two of them are veterans of the Halassur wars, ${addressu}.  They know they're dealing with a ${wisard} here."
  *set intel +10
*if (cred_p < 215)
  "Folk have seen at least three, with rumors of more," one of the other scouts responds.
  *if theuknown >= 10
    "Hard to imagine they'd only send three when they know they're up against a ${wisard}."

It's hard to tell whether the pounding of your heart is exhilaration or half-conscious terror. "Anything out of the helot camps?"

*if (cred_h > 250)
  Earnn nods intently.  "They've been doing everything they can to help, ${addressu}.  Some of them say they're going to foul the food for the fighters their masters have hired to hunt us, to keep them sick in the Rim.
  *set aristroops -46
  *set alltroops -46
  *set allmain -46
  *if priestroops > 0
    They also warned us to look out for 
    *set d2n_num priestroops
    *gosub d2n
    peasants from the Rimhart who have been stirred up by the Ecclesiasts to come fight us in the name of the Angels.
  *set intel +5
  Much of what we know, we heard first from them."
*if (cred_h < 251) and (cred_h > 159)
  Earnn gives a quick shrug.  "The helots like us, and they've shared what they know.  Said to look out for a mob of peasants from the Rimhart who have been stirred up by the priests to come fight us."
  *set intel +2
*if (cred_h < 160)
  Earnn looks embarrassed. "Well…not that many helots were willing to talk to us, ${addressu}.  Reckon they don't see us as their rebellion."

"And…anything from anyone else?"

*if (intronat and (intro_bad = 0)) and (natl > 74)
  "Well, bless that jongler Carles of yours, ${addressu}…he's got word to us that we can expect
  *set d2n_num alastroops
  *gosub d2n
  Alastors to join the Phalangites.
  *if alastroops < 80
    I'd have expected more, but it seems
    *if anarchy = 0
      we've been so quiet, they're confident in the Phalangites sorting us out.
    *if anarchy > 0
      too many of them are putting out fires in the Rim from the anarchy we've sown.
      *if anarchy > 30
        That also seems to be tying down about ${anarchy} Phalangites who left Rimmersford but never made it to Rim Square.
  He's also spied out some things about the tactics they're planning to use.  We'll tell you the details later."
  *set intel +10
*if (cred_a < 216) and (cred_m < 216)
  *if not(intronat) or (intro_bad > 0)
    "Nothing to speak of, ${addressu}.  The merchants and aristos aren't talking to us just now, as you can imagine."
  
  *goto stormbreak
Earnn chews his lips pensively.
*if (cred_m > 215)
  "Oh, and our friendly merchant contacts have shared what they know.  They also tell us that they've done their part to slow down the baggage trains, which will likely keep three dozen or so troops stuck back in the Rim trying to sort things out."
  *set phalangites -28
  *set phal1 -28
  *set aristroops -11
  *set alltroops -39
  *set allmain -39
  *set intel +10
  
*if (cred_a > 215)
  Another scout volunteers, "Mikal de Rose led a band of Phalangites and a Theurge off into the Great Brecks.  Said he'd heard you would be leading a sheep raid there.  As far as we can make out from talking to his retainers, ${addressu}, that was something kurios de Rose made up out of whole cloth, just to lead them away where they'll do no damage."
  
  "Mikal de Rose?"  Breden's old masters had been kindly enough,
  *if aristo
    and they had long-standing ties to the ${orig_lname},
  but you're still astonished to hear that they'd stick their necks out for your rebellion.
  
  "Aye, ${addressu}." Earnn shrugs with a small grin. "Seems there are some nobles out there who are more angry at the Hegemony than they're frightened of us."
  *set phalangites -21
  *set phal1 -21
  *set alltroops -21
  *set allmain -21
  *set theurges -1
  *set intel +10
  
*label stormbreak
*if intel > 30
  When you put together all the scouts' reports and informed speculations, you conclude that you're about to face some 
  *set d2n_num alltroops
  *gosub d2n
  soldiers, Alastors, and other armed enemies, to say nothing of the Theurges.
  *if skepreal <= 50
    [i]Angels defend us.[/i]
  *if skepreal > 50
    If you had any confidence that the Angels were listening, you'd be praying hard now.

Looking around your little group of spies, you force a grim smile onto your face. "Thank you all—this knowledge will save all our lives.  Time to let the band know that the storm is about to break."
*page_break
*if (int = 2) or (com = 2)
  "Don't tell me the Phalangites are unbeatable," Radmar growls at the dinner circle that evening. "$!{addressu} ${lname}, be honest.  In all the stories you've 
  *if int = 2
    read and 
  heard, there must be some times when they've lost—and to folk like us, not just Halassurq magi!"
  
  You give a curt nod, trying to muster enough appetite to finish your venison.  "I 
  *if int = 2
    read 
  *if com = 2
    heard tell
  of a revolt a hundred years ago, further up the ${whend}ish border.  The Phalangites lost badly.  They brought long pikes into the forest, tried to keep their usual tight formations, played drums as they marched…it all made them easy to ambush, over and over again.  Only a handful left the wilderness alive.
  
  *if int = 2
    "That history was written by  
  *if com = 2
    "The person who told 
    *if aristo
      me 
    *if helot
      my old masters
    that story said she'd heard it from   
  a Phalangite commander.  They won't make those mistakes again."  You glance around the suddenly subdued circle. 
  *if strategy = 1
    "We will beat them, but I won't pretend it's going to be easy."
  *if strategy = 2
    "That's why we're not going to try beating them.  Avoiding them is far easier."
  *if strategy = 3
    "Good thing that so many of us will be out in the Rim by the time they get here.  The rest will hide."
  
*if cha = 2
  "Gather round," you call to your followers just before dinner. "Some of you will already have heard the news: they're coming.  The Archon's troops reached Rim Square a week ago, and will be entering the Whendward soon."
  
  Over the tense, subdued chatter, you raise both your voice and your hands. "Hear me!  This is the hour we've been preparing for.  
  *if strategy = 1
    They've come to our wilderness.  Here, we know every ridge, cave, and trail; they know none of it.  And we will hunt them, harry them, and in the end slaughter them like so many deer.
  *if strategy = 2
    They'll not find us.  We will evade them until they're so hungry, weary, and sick of our arrows that they run back to Rimmersford.  
  *if strategy = 3
    *if helcamp < 40
      Many
    *if (helcamp > 39) and (helcamp < 65)
      Some fifty or so
    *if (helcamp > 65) and (helcamp < 90)
      Seventy or eighty
    *if (helcamp > 89) and (helcamp < 120)
      Around a hundred
    *if (helcamp > 119) and (helcamp < 190)
      Well over a hundred
    *if (helcamp > 189) and (helcamp < 230)
      Some two hundred
    *if (helcamp > 229) and (helcamp < 270)
      Some two hundred fifty
    *if (helcamp > 269) and (helcamp < 310)
      Some three hundred
    *if (helcamp > 309)
      More than three hundred
    of us have already crept out to the Rim, under the very noses of the Alastors and Phalangites.  Those of us who remain will hide, and they'll never find us.
  The only thing that could defeat us is our own fear.  Only be of good courage, and we will win!"
  
*if morale >= followers
  The band greets the news with stolid determination.  You've kept their mettle high through the grinding winter and spring. Now every outlaw in Whendward is ready to stand beside you and face whatever the Archon sends your way.
  *page_break
*if inadults < 23
  *goto simznight
*if morale < followers
  *if morale > ((followers*2)/3)
    *set morcheck 5
    *goto desset
  *elseif morale > (followers/2)
    *set morcheck 4
    *goto desset
  *elseif morale > (followers/3)
    *set morcheck 3
    *goto desset
  *else
    *set morcheck 2
    *goto desset
  *label desset
  *set deserters round(inadults/morcheck)
  *if (inadults-deserters) < 22
    *set deserters (inadults-22)
  *if inkids > (deserters*2)
    *set desertkids round(deserters*2)
    *goto desset2
  *if inkids > (deserters+2)
    *set desertkids round(deserters+2)
    *goto desset2
  *if inkids > (deserters/2)
    *set desertkids round(deserters/2)
    *goto desset2
  *if inkids > (deserters/3)
    *set desertkids round(deserters/3)
  *label desset2
  *if cha < 2
    The 
  *if cha > 1
    Despite your charismatic appeal, the
  band greets the news with stark silence.  In the morning, 
  *set d2n_num deserters
  *gosub d2n
  outlaws have
  *if desertkids <= 0
    vanished.
  *if desertkids > 0
    vanished, along with
    *set d2n_num desertkids
    *gosub d2n
    of their children.
  *set followers -deserters
  *set nonkids -deserters
  *set inwoods -deserters
  *set inadults -deserters
  *set inkids -desertkids
  *set kids -desertkids
  *set inwoods -desertkids
  *set followers -desertkids
  
  "We can't have deserters bringing word of our plans and movements to the enemy, ${addressu},"
  *if rad_here
    Radmar says hoarsely.
  *if not(rad_here) and kal_here
    ${kalt} growls.
  *if not(rad_here) and not(kal_here)
    a grizzled Whendward bandit says, wild-eyed.
  "Phalangites will catch them—some of them, anyhow—and force everything they know out of them."
  *choice
    #I let them go.  I'll not force anyone to stay unwillingly.
      *set ruth %-10
      *set theirintel +4
      *goto simznight
    #I have them tracked down and given the choice to return or die.
      *set ruth %+10
      Alira gathers up all her remaining rangers and goes hunting runaways.  
      *label alirahunt2
      Within two days, she's brought back
      *if deserters < 5
        all of them.  "When you put the choice to them that way, ${addressu}…there were few enough that none of them tried to fight."
        *set followers +deserters
        *set nonkids +deserters
        *set inwoods +deserters
        *set inadults +deserters
        *set inkids +desertkids
        *set kids +desertkids
        *set inwoods +desertkids
        *set followers +desertkids
        *goto simznight
      *if morcheck >= 4
        *set followers +round((deserters*3)/4)
        *set nonkids +round((deserters*3)/4)
        *set inwoods +round((deserters*3)/4)
        *set inadults +round((deserters*3)/4)
        *set inkids +desertkids
        *set kids +desertkids
        *set inwoods +desertkids
        *set followers +desertkids
        most of them in tow.  "There won't be any reaching the Phalangites, ${addressu}," she reassures you, grim-faced.  "Some tried to fight when we caught up to them.  These are the ones who saw reason."
      *if morcheck < 4
        *set followers +round(deserters/2)
        *set nonkids +round(deserters/2)
        *set inwoods +round(deserters/2)
        *set inadults +round(deserters/2)
        *set inkids +desertkids
        *set inwoods +desertkids
        *set kids +desertkids
        *set followers +desertkids
        half of them.  "There were too many for us to find them all, ${addressu}."
        
        "Only this many?" You'd thought Alira a better tracker than that.
        
        "No.  No, we found a good few more."  It's not just frustration putting an edge to Alira's voice.  "Some fought back.  Some just told us to make it cleaner than the Phalangites would."
        *set theirintel +2
      
      The mutters of "murderer"
      *if desertkids > 0
        and the empty stares of the
        *if desertkids = 1
          child
        *if desertkids > 1
          children 
        brought back
        *set morale -round(desertkids/3)
      haunt your band for the next week.
      *goto huntconseq
    *if (desertkids > 0) 
      #They made their choice already.  I send Alira to hunt them down and bring back the children.
        *set ruth %+20
        *goto alirahunt
    *if (desertkids > 0) 
      #We can't afford to spare the deserters' children—they'd only lower morale.
        *set ruth %+30
        Alira just stares at you when you give the order. "Taratur, ${addressu}.  No.  I'd sooner die on a Phalangite sword than kill a child."
        
        *if desertkids = 1
          You shake your head bleakly.  "The deserters are
          *goto theones
        "You'd let the Phalangites take all the ones still with us?"  Many of your
        *set d2n_num kids
        *gosub d2n
        remaining children are hanging around the breakfast circle. You take them all in with a bleak gesture. "There's no other way, Alira.
        *if eclect
          The Angels' will is not always easy.
        The deserters who chose to take their children—they're 
        *label theones
        the ones who made the choice here.  They forced our hand."
        
        *if (cha = 2) or eclect
          You don't think Alira would have obeyed your order if you hadn't 
          *if cha = 2
            put all your conviction behind it. "Damn us all, ${addressu}," she rasps at last, beckoning her silent, queasy-looking rangers after her.
          *if cha < 2
            invoked the Angels.  "As you say, Eclect," she finally says, thin-voiced.
          
          When she returns four days later, she stares at you without speaking, then gives a brief nod.
          *set morale -(desertkids*3)
          *if (s_rel > 6)
            *set s_rel 5
          *if (s_rel < 5)
            *set s_rel 6
          *page_break
          *goto simznight
        "No, ${addressu}," Alira snaps again. "We can yet bring them back.  And we will."
        *set morale -round(desertkids/2)
        *if morcheck >= 4
          *goto alirahunt3
        *if morcheck < 4
          *goto alirahunt4
    *if (desertkids <= 0) #They already made their choice.  They need to pay for it.
      *set ruth %+15
      *label alirahunt
      Alira 
      *if morcheck >= 4
        nods sharply when you give the order.  
        *label alirahunt3
        Within two days, she's back to confirm that all 
        *set d2n_num deserters
        *gosub d2n
        *if desertkids > 0
          adult deserters 
        are dead.
        *if desertkids > 0
          *gosub deskidsback
        No one else dares to flee, and any unhappy murmurs you overhear are cut off quickly when people see you.
      *if morcheck < 4
        greets your order with incredulity.  "You think those of us who are left will be able to track down that many fleeing bandits, ${addressu}?"
        
        "If you don't, the Phalangites will," you tell her coldly. "This is our one chance, Alira."
        
        *label alirahunt4
        *set deserters -round((deserters*2)/3)
        Within three days, she returns to confirm that her trackers managed to find and dispose of 
        *set d2n_num deserters
        *gosub d2n
        deserters.
        *if desertkids > 0
          *gosub deskidsback
        The remaining outlaws mutter unhappily to each other about your ruthlessness—while still fearing what the Phalangites may learn from the runaways who escaped your hunt.
        *set theirintel +2
      *label huntconseq
      *if (s_rel > 6)
        *set s_rel 5
      *if (s_rel < 5)
        *set s_rel 6
      *set morale -round(deserters/2)
      *page_break
      *goto simznight
*label simznight
*if simz_here and (s_rel < 9)
  That evening, you notice ${simon} is barely speaking or eating.  If others notice ${zhis} low spirits, it could erode morale at just the wrong time.
  *choice
    #I sit beside ${zhim} and ask quietly, "What's ailing you, ${zmilady} de Firiac?"
      *if (s_rel =  6) or (s_rel = 5)
        $!{zhe} raises unfriendly eyes to you. "I am about to lay down my life for the noblest of causes…led by a brute who doesn't merit the place fate has thrown to ${him}.  Is that not cause for some measure of gloom, ${addressu} ${lname}?"
        
        You stand again, swallowing back anger.
        *if (deserters > 0) and (theirintel < 4)
          Of course ${zhe}'s angry about your merciless response to the deserters.
          *if s_lover > 4
            "Is that truly all it takes to move me from love of your life to monster?"
          
            "I knew some of those folk, ${addressu}." ${simon} shakes ${zhis} head grimly.  "They were weak, but they didn't deserve to be murdered.  No matter what the Phalangites might be able to wring from them."
            
            "Then it's a good thing for us all that you weren't the one who had to deal with them."  $!{zhis} naivety makes you want to howl, but there's plainly no point in arguing further now.
        "If 
        *label ybitc
        you truly believe in our cause, de Firiac, then pin a smile back to your
        *if helot
          smug aristo
        cheeks before you steal the mettle of the others.  Whatever quarrels you have with me must wait until we've survived this army."
        
        ${simon}'s glare lasts only for one scalding moment.  Then ${zhe} bends ${zhis} face into some sickly version of a smile. "I shall keep my seditious unhappiness in check, glorious ${addressu}."
        
        "Good enough," you mutter before stalking away.
        *page_break
        *goto egynpike
      *if (s_rel > 6) and (s_sword != 1)
        $!{zhe} looks up warily. "Nothing that would concern you, ${addressu} ${lname}."
        
        "If you infect the rest with your misery, it concerns me."  You fold your arms.
        
        "Honor." ${simon}'s lips are thin, ${zhis} eyes suddenly hot.  "I came here for honor's sake, ${addressu}.  To make a stand against the Karagond beast that has stripped it from us all.  From what I'd heard, I thought I'd find a ${woman} who understood it.  Now I find myself about to sacrifice myself along a gang scarcely more honorable than the Hegemony we fight.  It makes a mockery of my life."
        
        "You came because you thought we would welcome any
        *if aristo
          fellow
        aristo with open arms," you retort, unmoved. "Even though you knew most nobles have been stripped of honor, or sold it outright.  Do you truly think most of them deserve any better treatment than what you've enjoyed from us?"
        
        ${simon} wavers, but only for a moment.  "To be a kidnapper, ${addressu}, a seller of bodies?  I wouldn't lower myself to that, were my enemy the worst fiend on earth.  We need to be better than the Karagonds are, ${addressu} ${lname}.  That's the only rebellion worth the name."
        
        "What you call rebellion, I call offering our throats for the knife."  You stand brusquely. "Now if
        *goto ybitc
      *if s_lover < 3
        "Just a bad turn of the stomach, ${addressu}.  I expect it to be better on the morrow."  $!{zhis} dismissive tone is belied by the desolation on ${zhis} face.
        
        "Well, I'm glad it's nothing more serious."  You clap ${zhim} on the shoulder, then lean in closer. 
        *if aristo
          "I don't suppose you would care for another 
        *if helot
          "Last
        chance to tell me the truth?"
        
        *if s_lover = 2
          "The truth?"  At the note of distaste in ${zhis} voice, you suddenly regret asking the question. "$!{kuria} ${lname}, the truth is that I am trying to shed myself of an attachment to a dishonorable and disloyal ${woman}.  If I'm to die on these Phalangites' swords, I wish to die with a clear mind and conscience."
          
          You stand as quickly as if 
          *if bred_here
            stung, glancing over at Breden. 
          *if not(bred_here)
            stung.
          "I'll leave you to it, then.  $!{oath}.  The sooner you stop brooding about it, the better for the band."
          *page_break
          *goto egynpike
        *if bredwed
          "Forgive me, ${addressu} ${lname}." ${simon} stands, plainly unwilling to meet your eyes.  "I should not be grieving my comrades in arms when we may so soon need to make a bold defense.  I will withdraw myself." $!{zhe} pushes through a nearby cluster of outlaws and out into the night.
          *page_break
          *goto egynpike          
        A small chuckle convulses ${zhis} body at once, but it's a long minute before ${zhe} speaks again. "We're fighting to change many things, ${addressu}.  Things the Thaumatarchy tells us are immutable.  I was mourning the things I cannot change, cannot have, and never will."  
        *if ((bred_lover < 4) and (bred_heart != 3)) or not(bred_here)
          When ${zhe} turns ${zhis} gaze on you, the ache is unmistakable.
        *if ((bred_lover >= 4) or (bred_heart = 3)) and bred_here
          $!{zhe} doesn't look at you, but the ache in ${zhis} voice is unmistakable.
          
          You glance over to Breden, on the far side of the clearing, caught up in laughing conversation with
          *if el_here
            Elery and
          ten friends.
        *choice
          *if (bred_lover >= 4) and (simzpref and bred_here)
            #"I'm sorry, ${zmilady} de Firiac.  Sometimes…we come to things too late."
              "Such is the will of Xthonos."  The young noble shrugs, manages a brief glance in your direction. "If it were easy, there would be no virtue in following it."
              
              *if religion > 19
                In kenon you're not sure what to think about Xthonos and Its will, but you decide this is no time to raise that.
              "It takes us strange places, ${zkuria}, 
              *if aristo
                not all of them difficult.  
                *if (xspouse != "lover")
                  Could I have imagined I would one day be wed to a former helot rebel?  
                The end to our loneliness may come when we least expect it."
              *if helot
                and that's the truth."  The idea that you'd have a good-looking aristo hanging on you—and be in any place to refuse ${zhim}—continues to seem unreal. "You'll find your other half one day."
              
              "A most helpful insight, ${addressu}."  ${simon} stands quickly and makes a bow, still avoiding your eyes. "But now I must beg your leave."
              *page_break
              *goto egynpike
          *if xspouse != "lover"
            #I stand up, stern-faced. "It's dishonorable to let yourself want some things, ${zkuria}."
              "Of this, ${addressu} ${lname}, I am abundantly aware."  ${simon} also stands, makes a fumbling, bitter-faced bow. "But you pressed me for the reasons for my unhappiness.  Perhaps now that you understand them to be unspeakable, you will have the grace to leave me alone." $!{zhe} pushes through a nearby cluster of outlaws and out into the night.
              *page_break
              *goto egynpike
          *if simzpref 
            #My throat goes dry.  "You could have more than you think, ${zmilady} ${simon}."
              *if (bredrel and bred_here) and ((bred_lover = 3) or ((bred_heart = 6) or (bred_heart = 7)))
                *gosub bredbroke
                "Oh, ${milady} ${lname}. How I wish it were possible. Under
                *goto thereisdishonor
              *if (bred_lover >= 4) and bred_here
                *label simzrebuke
                *set s_lover 2
                The shock in ${zhis} eyes turns swiftly to profound disappointment.  "You shame yourself, ${addressu}.  And you shame 
                *if xspouse != "lover"
                  your ${xspouse},
                  *set s_lover 1
                Breden Reaper."
                
                Your face feels blisteringly hot.
                *if acepref and (bred_heart = 3)
                  Somehow you'd hoped that ${zhe} wouldn't have noticed the endearments you've shared with Breden.
                "If you insist on telling me the unspeakable, ${simon}…what did you hope I was going to say?"
                
                "The honorable thing."  ${simon} stands, makes a fumbling bow.  There are tears on ${zhis} cheeks, and ${zhis} voice is so choked it's hard to make out the words.  "But be assured I'll not speak of it again."
                *page_break
                *goto egynpike
              $!{zhis} eyes widen, and for a moment there's a new light in them.  Then ${zhe} glances around at the other rebels, who seem for the most part to be ignoring you. "But not with honor, ${addressu} ${fname}. Under 
              *label thereisdishonor
              *if helot
                other circumstances…an honorable courtship…"
                
                You can't help smiling, but there's a bitterness to it.  "I don't know what you imagine an honorable courtship between noble and helot might look like, ${zmilady}. Or its outcome."
                          
                ${simon} shakes ${zhis} head slowly, ${zhis} voice hot with embarrassment.  "For all the imagining I have indeed done, Captain…you'd think I'd have some better idea by now of how to proceed with virtue.  But I don't."
                
                It takes all your willpower not to kiss ${zhim} at that moment.
                *choice
                  #A second later, willpower be damned, I do kiss ${zhim}.
                    *label skissno
                    *set s_lover 2.5
                    ${simon} gasps when your lips touch ${zhis}, and a shudder runs through ${zhis} whole body.  A moment later ${zhe} breaks away with such force that ${zhe} almost topples over backward.  Laughter and a few cheers break out across the circle, but others are staring at the furious noble with concern.  "$!{addressu}…I am not to be treated so." Anger and shame are harsh in ${zhis} voice.
                    
                    "You'll tell me you didn't want me to kiss you?"
                    
                    "I had already told you," ${simon} says unsteadily. "Damn you for not caring.  Damn you for dishonoring us both."  $!{zhis} arm hovers on the verge of striking you.  Then ${zhe} whirls and runs out into the woods.
                    *page_break
                    *goto egynpike
                  #"I'd honor you in love, ${simon}," I persist.  "What more need 'honor' mean than that?"
                    *set s_lover 4
                    "Restraint," ${simon} replies at once, soft-voiced and unyielding.  "A barrier against one's animal urges—against the pull of Xaos. The most important thing there is."
                    
                    You stare at ${zhim} in acute frustration for several moments. "Then we'd best spend no more of our time testing our capacity for it, ${zmilady} de Firiac."
                    
                    "I'm afraid I agree, ${kuria} ${lname}." ${simon} sighs, stands, and walks away.
                    *page_break
                    *goto egynpike
                  #"And now—when we've no more time to think on it?  When either of us could fall to the Phalangites?"
                    *set s_lover 4
                    ${simon} stands abruptly.  $!{zhis} throat works for a moment before ${zhe} manages: "Now, ${addressu}, above all times, I hold to honor and chastity."
                    
                    You also rise, shame and anger blending into a sour heat in your gut.  "Perhaps you shouldn't talk of desires you know you don't mean to follow, then."
                    
                    "Had you not pressed me, I wouldn't have spoken of them." ${simon} struggles to meet your eyes and finally turns away. "I shall assuredly not do so in future."
                    *page_break
                    *goto egynpike
                  #I sigh.  "Well, you know my heart. Tell me when you've decided how we can go ahead with honor."
                    *set s_lover 5
                    An uneasy, incredulous joy breaks across ${simon}'s face, and ${zhe} clasps your hands in ${zhis} own.  "I…aye, my dear ${addressu} ${fname}.  Thank you.  I shall think of little else."
                    
                    You shake your head as you rise, pulling away from ${zhim}.  "I hope that's not true, de Firiac.  Think about surviving the summer.  Maybe when we've done that, the rest will be of some use."
                    
                    ${simon} nods, beaming, and walks away with a light step.  At least ${zhe}'s no longer likely to infect others with ${zhis} bad mood.
                    *page_break
                    *goto egynpike
              *else
                *comment if aristo
                other, more proper circumstances, duly chaperoned by a person of honor…I think you know I should welcome your court."
                
                It takes all your willpower not to kiss ${zhim} at that moment.
                *choice
                  #A second later, willpower be damned, I do kiss ${zhim}.
                    *goto skissno
                  #"Then I eagerly await the hour when we find ourselves in better circumstances."  I touch my lips to ${zhis} hand.
                    $!{zhe} beams and inclines ${zhis} head with the careless grace of a young
                    *if zhe = "she"
                      lady
                    *if zhe = "he"
                      lord
                    at a ball.  Your fingers interlock and, for an instant, neither of you feel yourselves in this world of soot, undercooked venison, and lice in your matted 
                    *if (zhe = "he") and male
                      beards.
                    *if (zhe = "she") or female
                      hair. 
                    "As do I, my dearest ${fname}."
                    *set s_lover 5
                    *page_break
                    *goto egynpike
                  #"A chaperon?"  The incongruity makes you laugh aloud. "${simon}…in the world's eyes, we're dishonored already."
                    *set s_lover 4
                    "The stories they'll be telling…" It pains you to think of it, and you can see it cuts ${simon} even deeper. "You can't think that either of us has a reputation to return to.  All we have left is each other."
                    
                    "It isn't a matter of reputation alone, ${milady}."  The young de Firiac faces you, visibly distraught. "I thought you would understand.  
                    *if arrog > 0
                      You of all people."
                    *if arrog < 1
                      I thought…"
                      
                    "Understand what?"
                              
                    "That which sets us apart from the lower orders.  Our capacity to resist the Xaos within.  To follow the will of Xthonos of our own volition, without being cuffed or constrained into it." ${simon}'s pained expression only grows as ${zhe} stares at you. "Let that go…and what does our honor even mean?"  After a moment, ${zhe} strides away from you.
                    *page_break
                    *goto egynpike
          *if simzpref and (not(bred_here) or (bred_lover < 4))
            #"I'm sorry, ${zkuria} ${simon}.  You do me an honor I wish I could return."
              "Please, ${addressu}.  Say no more."  ${simon} exhales raggedly, then stands.  
              
              If only your heart were in it.  
              *if helot
                The idea that you'd have a good-looking aristo hanging on you—and be in any place to refuse ${zhim}—continues to seem unreal. "You must think me mad, ${zkuria} ${simon}."
              *if aristo
                It still seems mad to reject the only other noble to rebel alongside you. "Many would think it a terrible discourtesy."
              
              "Not at all."  
              *label holdasmile
              ${simon} holds a smile for a few seconds.  "To rebel against your nature would be a mad thing to ask of you.  We're straining at the edge of Xaos enough as it is.  Forgive me, ${addressu}."  $!{zhe} bows and takes ${zhis} leave.
              *page_break
              *goto egynpike
          *if not(simzpref)
            #I sigh.  "I'm sorry, ${zmilady} ${simon}.  As you say, some things cannot change."
              You've simply never found yourself drawn to
              *if (zhe = "she") and not(acepref)
                women,
              *if (zhe = "he") and not(acepref)
                men,
              *if acepref
                anyone that way,
              and the fact that it's
              *if helot
                a good-looking aristo hanging on you—a fact that you still struggle to believe!—doesn't
              *if aristo
                the only other noble to rebel alongside you doesn't
              change that fact.
              
              "Believe me, I understand."
              *goto holdasmile
          *if not(simzpref)
            #"Without sufficient will…some things are too big to change."
              Though you've never found yourself drawn to
              *if (zhe = "she") and not(acepref)
                women,
              *if (zhe = "he") and not(acepref)
                men,
              *if acepref
                anyone that way,
              you could almost imagine that for a sufficiently extraordinary person, someone you wanted to spend your life with…you could get past the oddness of lying with them.  But it would be no small act of will, and you've yet to meet anyone even close to compelling enough.
              
              "And how can the will be kindled, if there weren't already something present to kindle it?"
              *goto holdasmile
          *if acepref and ((bred_lover < 4) and (bred_heart != 3))
            #[i]$!{oath}, not again[/i]. "Don't try to sway my affections, de Firiac.  It's unseemly and unwelcome."
              ${simon} jerks away as if slapped. "You misundersta—"
              
              "Do I?"  Your glare silences ${zhim}.  "I've had enough ${zgirl}s and ${xgirl}s like you try to convince me that I was their 'other half' from the old myth.  That the only reason I'd never felt anything was that I'd been made to be theirs and theirs alone.  Some 
              *if aristo
                plied me 
              *if helot
                said it
              with jokes, some with sighs and tears.
              
              "But I'm no one's other half, de Firiac.  I don't regret it…and whatever you're mourning, 
              *if aristo
                I'll thank you not to 
              *if helot
                don't bloody try to
              wield it against me."
              
              After a moment's stunned silence, ${simon} finds ${zhis} feet and sketches a bow.  "Forgive me, ${addressu}."  Without saying anything else, ${zhe} vanishes into the dusk.
              *goto egynpike
          *if acepref
            #"Why so mournful when you have my friendship, de Firiac?"  Surely that's the important thing.
              At the genuine curiosity in your voice, and perhaps the edge of impatience, ${simon} gives a low laugh. "Angels, ${addressu}…I've had occasion to ask others the same thing in the past.  Friendship was always enough for me.  It should be enough now."  $!{zhis} lips twist slightly. "It'll certainly have to be."
              
              "And is my friendship so poor a substitute for…"  How to vent your ire without being too indelicate with the young noble? "For whatever you've in mind with my flesh?"
              
              "Of course not, ${addressu}.  Friendship is the purest and highest form of love.  To be called your friend is honor and joy." ${simon} gestures helplessly at the sky. "But is fine wine a substitute for a sunset?  When your heart yearns for both?"
              
              You can't hold back an amused snort.  "To one of us, a sunset.  To the other, more like paring my nails.  I don't mean to belittle what you're feeling, ${zmilady} de Firiac, but I simply don't understand it."
              
              "Nor should I have expected you to." 
              *goto holdasmile
          *if not(simzpref) and not(aropref)
            #My heart goes out to ${zhim}; I find myself reaching out to take ${zhis} hand.  "${simon}…for your sake, I would try."
              Though you've never found yourself drawn to
              *if (zhe = "she") and not(acepref)
                women,
              *if (zhe = "he") and not(acepref)
                men,
              *if acepref
                anyone that way,
              you always imagined that for a sufficiently extraordinary person, someone you wanted to spend your life with…you could get past the oddness of their body conjoined with yours.  "Maybe more can be changed than you think."
              
              *if (bredrel and bred_here) and ((bred_lover = 3) or ((bred_heart = 6) or (bred_heart = 7)))
                *gosub bredbroke
                *goto notunmindful
              *if (bred_lover >= 4) and bred_here
                *goto simzrebuke
              $!{zhis} eyes widen, and for a moment there's a new light in them.  Then ${zhe} glances around at the other rebels, who seem for the most part to be ignoring you, and ${zhis} face falls again. 
              *label notunmindful
              "Don't think me unmindful of the honor you do me, ${addressu} ${fname}.  But I cannot see how we can try anything within the bounds of propriety.  Under 
              *if helot
                other circumstances…an honorable courtship…"
                
                You can't help laughing, moved by relief as much as incongruity.  "$!{oath}, ${simon}.  I don't know what you imagine an honorable courtship between noble and helot might look like. Or its outcome."
                
                ${simon} shakes ${zhis} head slowly, ${zhis} voice hot with embarrassment.  "For all the imagining I have indeed done, Captain…you'd think I'd have some better idea by now of how to proceed with virtue.  But I don't."
                
                "Give it some thought, then."  You squeeze ${zhis} hand before standing up. "And tell me when you've got any idea."
              *if aristo
                other circumstances, duly chaperoned by a person of honor…I think you know I should welcome your court."
                
                You find yourself close to laughter, moved by relief as much as by the incongruity of a chaperon in the Whendward.  "Perhaps we will find the opportunity after this summer, my dear ${zkuria}."
                
                "If I weren't already determined to survive it, ${addressu} ${lname}…" ${simon} springs to ${zhis} feet. "Thank you, ${milady}.  Thank you for giving me hope again."
              *set s_lover 5
              *page_break
              *goto egynpike
          *if (acepref) and not(aropref)
            #"I can give you my heart, ${zmilady} de Firiac, though not my body."
              *if (bredrel and bred_here) and ((bred_lover = 3) or ((bred_heart = 6) or (bred_heart = 7)))
                *gosub bredbroke
                *goto isitposs
              *if (bred_heart = 3) and bred_here
                *goto simzrebuke
              You've seen enough of ${simon}'s goodness to love ${zhim} as much as you've loved anyone—and you think ${zhe} sees the truth of it in your smile now. 
              *label isitposs
              "$!{addressu}?" ${zhe} murmurs, wide-eyed. "Is it possible?"
              
              *if aristo
                "You may be aware that I've never had the desire for carnal intimacy with anyone, ${zkuria} ${simon}.  
              *if helot
                "Maybe you know that I've never wanted to share a bed with anyone, ${simon}.  
              But that doesn't mean I can't want to share my every waking hour with them—to know them and be known by them as deeply as two people can.  It doesn't mean that I can't fall in love."  You take ${zhis} hand and bring it to your chest, just over your heart.
              
              In all your life, you don't think you've seen such pure joy as that radiating from ${simon}'s face.  $!{zhe} drops to ${zhis} knees before you. "My love, my
              *if male
                lord,
              *if female
                lady,
              my sweet ${fname}.  For however long remains to us…you have my soul's devotion.  I swear I'll speak to you no untrue word, nor do aught to harm you, nor ever betray you.  You'll have no truer friend than me, nor any who loves you more deeply."
              
              *if helot
                There's something ridiculous, not to say scandalous, about ${zhis} lavishing such courtly language on a helot.  But of course that's why you're clasping ${zhis} hand in the first place.
              Tears prickle behind your eyes, and your voice is thick. "And you have my heart's love, ${simon} de Firiac."
              *set s_lover 10
              *page_break
              *goto egynpike
          #I pretend not to have understood ${zhim}. "Well, whatever is plaguing you…best to think on it after we've survived the summer."
            There's a note of relief in ${simon}'s voice, just distinguishable through the sorrow.  "Wise advice, ${addressu} ${lname}."  $!{zhe} rises and makes a cursory bow. "I fear in my weariness I may say foolish things.  I'd best find my bedroll."
            *page_break
            *goto egynpike
      *else
        $!{zhe} raises desolate eyes to you.  "Do you not find yourself taking stock of your life, ${addressu} ${fname}, now that we can see the enemy closing in?"
        
        "$!{oath}, ${zmilady} de Firiac.  When would I have time for that, with everything else that's needed doing?"  You keep your tone light. "And I hope that if I did, it wouldn't make me look quite as gloomish."
        
        $!{zhe} doesn't smile, and ${zhis} voice is barely audible.  
        *if s_lover = 6
          "Our one kiss, out there on the Brecks.  It's all I'll have of you, for the rest of my days."
        *if s_lover = 5
          "There will never be that chance we spoke of on the Brecks—that chance at an honorable courtship."
        *if (s_lover = 6) or (s_lover = 5)
          *choice
            #"We don't know that.  After we survive this summer…"
              "The Phalangites will very likely kill one or both of us within weeks, ${addressu}.  You, as the Theurges' topmost target.  Me, as I try to keep them from killing you." ${simon} says it with matter-of-fact, empty-eyed confidence. "Tomorrow I'll put a brave face back on for the band.  But tonight I'm sitting with the truth."
              
              "You can't know that."  It's surprisingly hard not to get pulled into the young noble's despair. "$!{oath}, ${simon}.  If anyone is going to survive, it's our blademaster.  And the Theurges have tried to kill me already."
              
              "Hold on to that hope, then, ${fname}."  The young de Firiac shifts, looking as if ${zhe} can no longer bear to be in your company. "But what might have been between us, ${addressu}…it deserves a little grief. If things come to pass as I fear, there'll be no time for grieving then."
              *choice
                #"Then damn it all—[i]be[/i] with me now."  I keep my voice barely above a breath, but I know ${zhe}'ll hear it.
                  *goto whatagoodboy
                #"You mustn't soak yourself in despair like this."
                  "Do you truly think you'll be able to shrug it off tomorrow, after steeping yourself in it tonight?"  You catch at ${zhis} arm as ${zhe} tries to stand.  "You think you'll be able to fight, when you've already convinced yourself we're doomed?"
                  
                  ${simon} pulls away from you, face twisting bitterly. "My sister Loane won every battle she ever fought against the Halassurqs.  Part of her secret was immersing herself in the brutal truths, not just in hope."
                  
                  "And how did that end for her?" you demand. "${simon}…this is unlike you.  $!{oath}, you're always the hopeful one, the idealist."
                  
                  "No, ${addressu}.  This has always been part of me.  If it displeases you, forgive me.  I'll be my old self on the morrow."  $!{zhe} makes the briefest of bows, and then leaves at a pace just short of a run.
                  *page_break
                  *goto egynpike          
                #I shake my head and let ${zhim} go.
                  *goto egynpike
            *if (s_lover = 6) 
              #I bring my face close to ${zhis}.  "${simon}…you know it needn't be."
                *label whatagoodboy
                "If you think we're about to die?"  You make a minute nod out into the woods. "Don't die without knowing me."
                
                The young noble closes ${zhis} eyes; you can see ${zhis} pulse ripple uncertainly in ${zhis} throat.  For a minute you think ${zhe}'s actually going to accept.  "I'll join you in rebelling against many things, ${addressu}.  But not this."
                
                You let the air burst in frustration from your lungs. "Against what?  Against a chastity code 
                *if skepreal > 50
                  written by priests to give them sanction over every last bit of our lives?"
                *if skepreal <=50
                  that takes no notice of situations like ours?"
                
                "Against honor, ${addressu}.  Against restraint.  Against 
                *if aristo
                  our nature as nobles."
                *if helot
                  my nature as a noble."  
                ${simon} stands, trembling.  "That 
                *if aristo
                  which sets us apart from the lower orders.  Our 
                capacity to resist the Xaos within—to follow the will of Xthonos of our own volition, without being cuffed or constrained into it.  Let that go…and what does our honor even mean?"  
                
                $!{zhe} doesn't wait to hear your answer, heading into the darkness at a pace just short of a run.
                *set s_lover 4
                *page_break
                *goto egynpike
            *if (s_lover = 5)
              #I bring my face close to ${zhis}.  "Then let's find honor enough in the chance we do have."
                *goto whatagoodboy
            #I give a slow nod.  "You're likely right."
              ${simon} exhales sharply. "So you see it too, ${addressu}."
              
              "I can't gainsay it.  You and I, one or both of us…we'll be in the thick of whatever comes this summer.  That's a dangerous place to be.  But that's what it means to lead a rebellion.  I reckon I'm ready to take what comes."  You stare out across the moonlit clearing for a moment before glancing back to ${zhim}. "You're finding the regrets hard to bear?"
              
              "Ah, Angels,
              *if helot
                ${addressu}
              ${fname}.  I'd…I'd wanted so much more." $!{zhe} is trembling now, body and voice.
              *choice
                #"If we survive, ${simon}…we'll find a way."  I clasp ${zhis} hand in mine.
                  After a few moments, ${simon} grows calmer again.  $!{zhe} keeps a grip on your hand, seemingly oblivious to the curious looks coming from the rest of the band. "My sister Loane won every battle she ever fought against the Halassurqs.  Part of her secret was taking time to immerse herself in the brutal truth, not just in hope.  Taking the bad truth as her lover, she called it."
                  
                  "Well, as competition goes…"  You offer a shrug, smiling wryly.  "I'm not afraid of the bad truth, ${simon}.  But I don't see a need to steep myself in it.  Things may yet go better than you fear."
                  
                  "In the morning, I might be able to believe that."  ${simon} gives a ragged sigh. "For now, ${addressu}…thank you for being here with me."
                  *page_break
                  *goto egynpike
                #"Well.  If you truly want more, you know where I'll be."  I get up and walk into the woods.
                  You find a moonlit glen not too far off, and wait.
                  *if s_lover = 5
                    After about half an hour, you ruefully conclude that ${zhe}'s not coming.
                    
                    In the morning, ${simon} curtly informs you that your dishonorable proposition was unwelcome. "The path of honor is clear, ${addressu}, even when facing death."
                    
                    "You seemed uncertain of the path last night, ${zmilady} de Firiac," you reply, level-voiced. "Nothing we might have done last night is dishonorable in my eyes.  If you seem to be drifting into agreement with me…"
                    
                    "Drifting into Xaos," ${simon} retorts bleakly. "It won't happen again, ${addressu}."
                    *set s_lover 4
                    *page_break
                    *goto egynpike
                  *if s_lover = 6
                    Several minutes later, you see ${zhim} approaching through the trees; ${zhis} reeling pace looks drunken, though you know none of you have had much in the way of ale.
                    
                    At last ${zhe} comes to a halt in front of you, a haunted, hungry look in ${zhis} eyes. "Damn you, ${addressu}."  $!{zhe} clasps your head in ${zhis} hands, pulling you to ${zhis} lips, trapping hot tears between ${zhis} cheek and yours. "Ah, damn you for that kiss."
                    *choice
                      #This may be our only chance.  I enjoy ${zhim} to the full.
                        When dawn begins to touch the glen the next morning, you drowsily reach out an arm in search of ${simon}'s nakedness—and find your hand closing on nothing but grass.  At some point while you slept, ${zhe} evidently dressed and slipped away.  
                        
                        You look for ${zhim} on the walk back to camp and at the fastbreaking…then all over the camp, with increasing dismay.  No one has seen ${zhim} since ${zhe} left the dinner circle to join you.
                        
                        Ciels clears ${his} throat delicately when you inform ${him} that ${simon}'s vanished. $!{he} will certainly have noticed your intent conversation the night before. "Is there any reason to think ${zhe} might have…"
                        
                        "Go hunting for ${zhim} as if ${zhe}'s running back to the Rim," you order, pushing back a sense of rising panic.  "If you find ${zhim}, do all you can to convince ${zhim} to return."
                        
                        Ciels scours the woods but returns empty-handed a day later, looking rueful and impressed.  "Well, that's confirmed the young ${zkuria} has woodcraft equal to mine.  Whichever way ${zhe} passed, ${zhe}'s hidden ${zhis} tracks like a master."
                        
                        There's no more time to spend in hunting ${zhim} down.  The desertion of the band's sole blademaster on the eve of your great confrontation is of course terrible for morale.
                        *set morale -20
                        *fake_choice
                          #Including mine.  I'm wracked with guilt over driving ${simon} away.
                            But you don't have the luxury of letting your guilt consume you.  There's an army on its way to destroy you, and you're going to have to face it without ${simon}'s help.
                            *page_break
                          #I'm just terrified ${zhe} might have left no tracks because ${zhe} did away with ${zhim}self.
                            [i]My honor is my life[/i]—how many times had you heard it from ${zhim}?  What might ${zhe} have done when ${zhe} woke up feeling dishonored?
                            
                            You do your best to push back the dread and shame.  Whatever ${simon} chose, it's ${zhis} business now.  Yours is facing the army sent to destroy you.
                            *page_break
                          #It infuriates me.  How could ${zhe} put ${zhis} scruples above the needs of the rebellion?
                          #Good riddance.  $!{zhis} so-called honor was a growing obstacle to our fight anyway.
                        *set s_lover -50
                        *set simz_here false
                        *goto egynpike
                      #I hold back.  For tonight, I'll just explore all the ways I can kiss ${zhim}.
                        When ${zhe} begins tugging at your kyrtle, you grip ${zhis} wrist and give a firm shake of your head.  "Not tonight."
                        
                        "There will be no other night, ${addressu}." ${simon} is shivering despite the warmth of the summer air.  "This…this is…"
                        
                        "This is yet honorable.  As are you."  You lower ${zhis} hand to your waist, pull ${zhim} in closer. "And trust me, de Firiac: I mean to keep you that way."
                        
                        You're both back in your tents two hours later, flustered and happy.  In the morning, ${simon} looks a bit abashed but can't keep the smile from ${zhis} face.  "Thank you, ${addressu}," ${zhe} whispers. "For your restraint.  And, ah, for its limits."
                        *set s_lover 9
                        *page_break
                        *goto egynpike
                      #I break off almost at once. "You don't truly want this, ${zmilady}."
                        "Do you think I don't know that?" ${simon} clutches at you, ${zhis} face silver-streaked under the moon. "I want to be chaste, ${addressu}.  To be honorable.  And I want nothing more than your flesh on mine."
                        
                        $!{zhis} throaty voice and kiss leave you breathless, but after a moment you pull back again.  "I don't want it, ${simon}.  Not if it means you driving yourself mad over your so-called dishonor.  We both know that's what you'd feel by dawn."
                        
                        The young noble throws up ${zhis} hands in consternation; there's a growing hint of anger in ${zhis} voice. "Angels, ${addressu}.  If you didn't want me to dishonor myself…then why by bloody Xthonos did you beckon me back here?  Do you want me to plead?  Did you just want to know you could reduce me to this?"
                        
                        "I thought you might shake off your bad conscience, ${zmilady}.  But you've not.  And we both know it."  You step away. "I'm sorry I can't be with you."
                        
                        $!{zhe} gives a wordless, frustrated cry and stalks away.  In the morning, you go for several hours without seeing ${zhim}; when ${zhe} finally joins the ${zhe} main band, ${zhe} doesn't meet your eyes.  But you do get a muttered, "Thank you."
                        *set s_lover 9
                        *page_break
                        *goto egynpike
        "If I held my honor as lightly as some others, it would be easier."
        
        It takes you a moment to catch ${zhis} meaning, and even then you find it hard to credit.  "You're still thinking of the Brecks?"
        
        "I've one great regret in my life, ${addressu}."  $!{zhe} stands up, keeping ${zhis} voice low. "That I could not be one with you with honor and chastity.  But as those seem to mean quite different things to us both…it is a loss I cannot escape." Before you can reply, ${simon} pushes through a nearby cluster of outlaws and hurries out into the night.
      *page_break
      *goto egynpike
    #"Cheer up, de Firiac," I say loudly.
      The rest of the outlaws look round at your voice; most notice ${simon}'s gloom for the first time.  The young noble blinks, then stands and makes a cursory bow. "Forgive my solemnity, ${addressu} ${lname}.  I did not think I would offend."
      
      "You haven't offended.  But nor is there cause to be so solemn."  You stride over to ${zhim}, place a hand jovially on ${zhis} shoulder. "Have some food, join in the singing.  We'll be on the move from tomorrow."
      
      ${simon} de Firiac opens ${zhis} mouth as if to argue, then looks around the outlaws and shuts it again.  "No doubt you are right, ${addressu}.  I must plead a sensitive stomach today, however. I'll remove myself to rest up for the weeks ahead."
      *if cha > 1
        
        Without ${simon}'s scowl casting a shadow over the evening, you quickly set the other outlaws at ease.  By the time you all retire to bed, you think at least a few more of them believe you'll survive the summer.
        *set morale +5
      *if cha < 2
        
        There's an uneasiness that doesn't quickly settle after ${simon}'s departure. "What's the blademaster so glum for?" you hear one bandit mutter. "$!{zhe} think they'll wipe us out that quick?"
        *set morale -5
      *page_break
      *goto egynpike
    #I ignore ${zhim}.
      *goto egynpike
*if ((kal_here) and not(bredwed)) and ((((bred_lover < 4) or (bred_lover = 13)) or ((bred_lover = 23) or not(bred_here))) and ((k_rel < 6) and (k_rel != 4)))
  When you're alone after dinner, ${kalt} saunters up to you, bright-eyed and bleak.  "Coming to it at last, ${addressu} ${fname}.  The great hunt, the last battle."
  
  You offer a fragmentary nod.  "We'll leave in the morning to go have a look at these Phalangites." 
  
  *if strategy = 1
    "And start finding ways to pick them off."  The lean young fighter rubs ${zhis} hands together,
  *if strategy > 1
    "And then begin the running away."  The lean young fighter snorts,
  but ${zhis} heart doesn't seem to be in it.  There's an uneasiness in ${zhis} face and stance, a nervous energy you've never seen in ${zhim} before.  $!{zhe} opens and closes ${zhis} mouth repeatedly, as if starting to speak and then thinking better of it.
  
  "Worried about it?" you ask at last.
  
  "About a pack of over-trained, over-armed Alastors?" ${kalt} immediately shrugs, seeming if anything a bit relieved at this topic.  "What's the worst that can happen?"
  
  "They send you to Elysia."
  *if skepreal > 50
    The sarcasm in your voice should be too light to offend any of your more devout followers who might be listening.
  *if skepreal <= 50
    It's partly a joke, but you suspect you're not the only one in the band who takes genuine comfort from the idea on some level.
  
  $!{zhe} blurts out a laugh.  "Sure I gave up my Elysian reward when I came to join your rebellion, ${addressu} ${fname}.  Or when I killed my old master's son."  $!{zhe} pauses, lips curving in a pained smile. "From time to time I find that sitting heavier on me.  Gives me a greater appetite for, ah, earthly rewards."
  *page_break
  Judging by ${zhis} fleeting wince, the strangeness in ${kalt}'s tone wasn't lost on ${zhim}.  You sigh and beckon ${zhim} to sit down across from you.  "Best to just say outright whatever you're trying to tell me, ${kalt}."
  
  "Ah, damn it all for a drachem."  $!{zhe} looks around to confirm you're 
  *if kalpref
    alone; ${zhis} voice when ${zhe} speaks is throaty and low. "You know what I feel, 
    *if aristo
      ${kuria}
    ${fname}. 
    *if k_rel != 3
      Surely you've got the eyes to see it. 
    And we might find soon enough whether either of us gets an Elysian reward. I'd not spend these next few nights alone."
    *choice
      *if ((bred_heart = 3) and bred_here) and (bred_lover < 10)
        #"It may not be obvious, ${kalt}…but Breden already has my heart."
          *goto bredhasheart
      *if k_rel = 3
        #I eye ${zhim} for a moment before smiling. "Nor would I."
          The heat in ${kalt}'s eyes flares.  "For more than just a kiss or two, then,
          *if aristo
            ${kuria}
          ${fname}?"
          
          You walk over to ${zhim}, press your lips to ${zhers}, and send your hands wandering south of ${zhis} waist. "A good deal more."
          
          *goto kissmekalt
      *if k_rel != 3
        #"It's taken you this long to ask? $!{oath}, ${kalt}." I clasp ${zhim} to me and press my lips to ${zhers}.
          *label kissmekalt
          *set k_rel 4
          "Angels, ${fname}." ${kalt} can barely speak through your kiss, but ${zhis} voice is as hungry as your own. "Take me back to the tent."
          
          Most of the Whendward outlaws are reasonably discreet in their coupling, at least when sharing a bedroll in the common tents. Those who can't contain themselves, who gasp or cry out, can expect to face general raillery in the morning. You'd never thought you would join their number. But you'd never felt anything like what ${kalt} does to you; by the time you realize you've given voice, you're well past caring.
          
          When at last you collapse atop ${zhim}, ${kalt} adds ${zhis} breathless chuckle to the ripple of stifled laughter from the rest of the big tent. "I take it…we're not making…a secret of it, then."
          
          You wordlessly pull ${zhim} closer, as if to shut out everything beyond the knot of your bodies.
          *page_break
          *goto egynpike
      *if k_rel != 3
        #"I'd enjoy a kiss, ${kalt}…but sharing a bedroll? That's more than I want."
          The words have barely left your mouth before ${kalt} pulls you close and brings ${zhis} mouth to yours. When ${zhe} parts, your lips feel almost as hot as if ${zhe} were still kissing you. "That's truly all you want from me,
          *if aristo
            ${kuria}
          ${fname}?"
          
          Part of you wants a good deal more. "For now, yes."
          
          For a moment, ${kalt} looks as if ${zhe}'s gauging your resolve; then ${zhe} pulls away with a shaky sigh. "I don't do half-measures, ${kuria}.  Until you trust me enough to put yourself in my hands, let's keep things as they were."
          *set k_rel 3
          *page_break
          *goto egynpike
      *if k_rel != 3
        #"Not unless I wed you honestly."
          *if bred_lover > 9
            *set k_rel 7
            "So Breden Reaper gets to have you in the middle of the camp, but I don't until we're wed?"  ${kalt}'s lips twist furiously.  "Don't swiving toy with me, ${lname}.  There's no reason it should matter with me when it didn't with ${xhim}."  Before you can make any response, ${zhe}'s gone.
            *page_break
            *goto egynpike
          *set k_rel 2.5
          *if aristo
            ${kalt} stares at you, incredulous.  "And what chance is there of that, 
            *if female
              milady
            *if male
              milord 
            ${lname}?"
          
            "If I find I can trust you?  If I come to believe you're my lost half?" You offer ${zhim} a grin.  "I don't see who's going to stop me.  It's not as if they still consider me a true noble, in any case."
            
            "They'll look differently on a noble who wed an animal, and you know it." ${kalt} doesn't return the smile.  "It's one thing to rebel against the Karagonds, ${kuria}.  It's another to break every noble's idea of what's clean and unclean."
            
            "Which I'm doing already," you point out.
            
            "Then why bloody wait?" ${kalt} protests. "If it's not to protect a reputation you'd kill anyway by wedding me?"
          *if helot
            ${kalt} blinks at you. "That's not stopping anyone else in the band, ${fname}.  Why not take what joy we can, while we can?"
          *choice
            #I've heard my whole life that un-Ordered sexual union invites jealousy, madness, and chaos.
              *if bred_lover != 6 
                It's not just the sacred Canon; the popular
                *if helot
                  fireside tales
                *if aristo
                   storybooks
                you grew up with were full of examples.  Most famously, there's the epic tragedy of Kevin and Leir, two young nobles who became illicit lovers when their parents refused them permission to marry.  Uncurbed by matrimony, their passion led to a spiral of worsening distrust and jealousy, with each one increasingly convinced that the other had betrayed him.  Finally Kevin took revenge by accepting the advances of the pirate king Redegard, leading in the end to the Battle of Six Storms in which all three were drowned.
              
              *if bred_lover = 6 
                As you'd said to Breden, when ${xhe} asked.
              "We need to fend off Xaos any way we can, ${kalt}.  All the more so as rebels.  I don't want to start down the slope to madness."
              *label comecourtme
              
              ${kalt} sighs and stands.  "Well, we'd best wait on the kisses, then, too.  I don't do half-measures, ${kuria}.  Come court me like I'm some virtuous
              *if zhe = "she"
                noble maiden, 
              *if zhe = "he"
                aristo lad,
              if you will, and we'll see what you decide."
              *page_break
              *goto egynpike
            *selectable_if (skepreal < 51) #The Angels bless the intimate union of bodies—but only within the sacred covenant of matrimony.
              *set skepreal %-10
              You ruefully trace a helix in the air. "I can't afford to lose their blessing."
              *goto comecourtme
            #A reputation for chastity may win us allies who would otherwise dismiss us as Xaotic.
              *if aristo
                ${kalt}'s not wrong when ${zhe} says that you'd lose reputation by marrying ${zhim}.  But you know all too well 
              *if helot
                You've heard
              how important chastity is to devout or traditional noble families; it's the most widely respected evidence of loyalty and orderliness.  "There are nobles all over Shayard who will look to this to see if we're slaves to our passions.  To Xaos.  And not just the nobles, either: merchants, priests, and those who listen to them.  I can't keep the band from their habits, but I can set an example that others will speak of."
            
              "You truly care what They think?" ${kalt}'s voice is growing thin with anger. "Damn it all, ${kuria}, they'll never see us
              *if aristo
                helots
              as more than animals."
              
              "Some will, if we act the part.  Enough to make a difference."
                
              ${kalt} scowls and pulls away.  "Best wait on kisses, then, too.  I don't do half-measures, ${kuria}."
              *page_break
              *goto egynpike
      #"I'm sorry, ${kalt}.  That's not…I don't want that." I try to put a note of finality into my voice.
        *if k_rel = 3
          ${kalt} tries to smile. "I know you'd said it before, ${kuria}. Just wondered whether being on the verge of death had changed matters.  Should have known you wouldn't shift for anything as small as that." $!{zhe} stands, nods blindly in your direction, and hurries away.
          *page_break
          *goto egynpike
        *if aristo
          ${kalt}'s attempt at a smile dies almost too quickly to be visible. "Only so much contamination you'll risk from us helots then, ${kuria}?"
          
          "Only so much pain." You work to keep your voice level. "Hear yourself, ${kalt}.  Hear the part of you that hates me, that comes out so quickly when you don't get what you want.  $!{oath}, I get enough of that from my father.  You think I would take a lover who sounds like him?"
          
          "I'm not your bloody father, ${milady} ${fname}." ${kalt} rises, averting ${zhis} eyes from yours. "And you think a few bitter words mean I hate you?  Angels."  
        *if helot
          ${kalt}'s face sags as ${zhe} takes in your unequivocal response. "Well, then. Sorry I asked it, Captain."
        $!{zhe} rises and strides off, straight-necked and alone.
        *page_break
        *goto egynpike
  *comment if not kalpref
  alone, ${zhis} throat working anxiously. "$!{addressu}, I'll be honest…it all comes of being inspired by you.  The Thaumatarchy says things can't change.  You've been showing us that they can.  That it's not really in our nature to only serve and suffer and sacrifice ourselves.  
  
  "I see you look at the world, and when you see some bit of it you don't like, you don't just accept it.  Even if someone says, oh, it's the nature of things, that doesn't stop you from trying to change it.  And you're making those changes happen, ${addressu}.
  *if theuknown >= 5
    You've been doing it through ${wisardry}, and you've been doing it with us.
  It's like…like there's a wall there that everyone else stays away from, but you just walk up to it, and through it, and suddenly we all realize that it wasn't ever really a wall at all.
  
  "Now…any of us could die in these coming weeks."  ${kalt} pauses for a moment, bringing ${zhis} hands up to nervously knead ${zhis} face.  "And I can accept that.  But if I die, I'd rather die as happy as I can.  With as few regrets.  And right now, there's one Xthon'damned big regret that…that I don't think I can walk away from without at least trying…."
  
  You take a deep breath. "I think I know what you're talking about, ${kalt}.  And…"
  
  $!{zhe} raises ${zhis} hands pleadingly. "Wait,
  *if aristo
    please, ${kuria}
  ${fname}.  I know.
  *if (bred_lover = 3) or (bred_lover = 13)
    You and that Reaper ${xgirl} were with each other.
  I know you usually…that as far as anyone knows, you've 
  *if acepref
    never gone looking
  *if not(acepref)
    only ever gone looking among
    *if xhe = "he"
      men
    *if xhe = "she"
      women
  for your other half.  Maybe that seems natural to you.  But…"  $!{zhe} lets ${zhis} arms fall again. "I don't think it's much of a secret that I would do anything for you, ${addressu}.  Anything at all.  My life's yours if you want it, in any way and for all time.  
  
  "Of all the things you've looked at and decided to change, because the world would be a better place if it changed…how much of a change would this one need?  And can you do it?  Will you?" ${kalt} falls silent at last, ${zhis} face taut with an expression that's not quite hopeful and not quite a smile.
  *choice
    *if ((bred_heart = 3) and bred_here) and (bred_lover < 10)
      #"It may not be obvious, ${kalt}…but Breden already has my heart."
        *label bredhasheart
        $!{zhis} eyes widen, and ${zhe} glances around to see where
        *if deputy = "Breden"
          your deputy
        *if deputy != "Breden"
          the other 
          *if aristo
            young helot
          *if helot
            youth
        is laughing with some of the other outlaws. "Xthon'damn it all, ${addressu}…if I'd known I wouldn't have said a thing. I knew the two of you were close, but…"
        
        "But we're not sharing a bedroll," you say wryly, "so it doesn't count."
        
        "Never even kissed ${xhim}, that I saw or heard of." ${kalt} stares at you for a moment, then waves it away. "Forget I said anything, ${addressu}.  I don't want any trouble with Reaper or ${xhis} friends.  And I'd not be the one to split you two."  $!{zhe} hurries off into the night.
        *set k_rel 1
        *page_break
        *goto egynpike
    #"That's not something I can change, ${kalt}.  It just is my nature."
      You've simply never found yourself drawn to
      *if not(acepref) and (zhe = "she")
        women.
      *if not(acepref) and (zhe = "he")
        men.
      *if acepref
        anyone in that way.
      ${kalt} is no exception, however winsomely ${zhe} may try to make ${zhis} case.
      
      $!{zhe} closes ${zhis} eyes and nods as your answer sinks in.  "And…you don't want to try to change that nature."
      
      You give a helpless laugh.  "$!{oath}, ${kalt}.  I don't even know where I'd begin.  Something I was born with, something that's always been part of me…how do you think that's going to change?"
      
      "Every helot here was born with a nature that was supposedly half-animal, and was told all their lives that they couldn't lead, couldn't fight.  You helped us start looking for the place to change that.  And once we started looking…we found it, ${addressu}.  We found it."
      
      *if arrog < 1
        "That was a lie of the Hegemony.  It was never truly 
        *if aristo
          your nature; you changed what you thought, 
        *if helot
          our nature; we changed what we thought,
        not the truth of 
      *if arrog <= 0
        things.
      *if arrog > 0
        things." It's no time to argue about the extent to which helots do indeed have a lower nature.  "That half-animal business is something you were told by someone else.
      It's not the same thing as a nature one recognizes in oneself."
      *label butwellsorry
      
      "But…well. I'm sorry for bringing up such folly, ${addressu}."  ${kalt} manages an anguished smile, which disintegrates after only a couple of seconds. As ${zhe} stands to leave, ${zhe} mutters, "Seems we're still going to be slaves to some things after all."
      *set k_rel 1
      *fake_choice
        #"It's not slavery to follow one's true nature," I retort testily.
          "Nor, I'd thought, an offense in ${addressu} ${lname}'s rebellion to ask why it has to be that way." $!{zhe} 
        #It's all I can do not to strike ${zhim}. "Get out!"
          "No fear, ${addressu}. I'm going."  $!{zhe} 
        #"So much a slave to your own desire that you don't give a damn for anyone else's."
          For a moment, it seems ${kalt} is going to answer.  But in the face of your anger, ${zhe} falters and
        #I let it go. $!{zhe}'s disappointed, ${zhe} doesn't know what ${zhe}'s saying.
          $!{zhe} 
      hurries away into the night.
      *page_break
      *goto egynpike
    #"It would take a lot of will to change something that big, ${kalt}.  And…I'm sorry.  I just don't have it."
      Though you've never found yourself drawn to
      *if not(acepref) and (zhe = "she")
        women,
      *if not(acepref) and (zhe = "he")
        men,
      *if acepref
        anyone in that way,
      you could almost imagine that for a sufficiently extraordinary person, someone you wanted to spend your life with…you could get past the oddness of lying with them.  But it would take no small act of will, and you've yet to meet anyone even close to compelling enough.
      
      ${kalt} moistens ${zhis} lips, clearly struggling to find the right words. "You think it could change.  But you just don't want to change it?"
      
      "Ah, ${oath}, ${kalt}. What does it mean to say that my 'nature' could change when I can barely imagine it?"  You shake your head. "I can't make myself want to change it, and without the wanting, it won't change.  So yes…even if it could change, I surely can't change it."
      *goto butwellsorry
    #"So you'd do anything for me—as long as I change who I am for you."
      ${kalt} winces at your cutting tone. 
      *label itakeit
      "Very well, ${fname}. So it's a no."
      
      "Of course the answer is no.  You're asking me to change who I am for you?"  The very idea makes you feel…
      *fake_choice
        *if helot and (acepref or ((male and malepref) or (female and femalepref)))
          #Alarmed.
            You grew up knowing that you'd either breed or face an early Harrowing.  After turning rebel, you'd never thought you'd feel again that awful tightness in your chest at the prospect of acting against your nature.
        #Outraged.
          *if helot and (acepref or ((male and malepref) or (female and femalepref)))
            The demand faced by every helot to breed or face an early Harrowing is one of the worst evils of the Hegemony.
          How dare ${zhe} ask you to act against your very nature?
        #Offended.
          Who does ${zhe} think ${zhe} is?  To treat your lifelong desires as something you could just change because ${zhe} asks you to?
        #Bemused.
          It's such a bizarre request, so much against the grain of nature, that you hardly know what to think of it.
      *comment endif
      
      ${kalt} looks pained but stubborn. "Every helot here was born with a nature that was supposedly half-animal, and was told all their lives that they couldn't lead, couldn't fight.  You helped us start looking for the place to change that.  And once we started looking…we found it, ${addressu}.  We found it."
      
      "So you're saying that my nature—the things I've always recognized about myself, the ways I've always felt—is the same as the lies of the Hegemony?"
      *goto butwellsorry
    #"How can you ask me that?"
      ${kalt} raises ${zhis} hands defensively.
      *goto itakeit
    *if (not(aropref)) #"I can't promise anything.  But…for you, I'll try."
      Though you've never found yourself particularly drawn to
      *if not(acepref) and (zhe = "she")
        women,
      *if not(acepref) and (zhe = "he")
        men,
      *if acepref
        anyone
        *if bred_lover >= 10
          but Breden
        in that way,
      you 
      *if acepref and (bred_lover >= 10)
        now know
      *if not(acepref) or (bred_lover < 10)
        always imagined 
      that for a sufficiently extraordinary person, 
      *if not(acepref) or (bred_lover < 10)
        someone you wanted to spend your life with…you could 
      *if acepref and (bred_lover >= 10)
        you can
      get past the oddness of their body conjoined with yours.  And something about ${kalt} has powerfully appealed to you:
      *fake_choice
        #$!{zhis} passion and courage.
        #$!{zhis} fearless candor in whatever ${zhe} says.
        #$!{zhis} decisiveness.
        *if kaltale
          #$!{zhis} unexpected gentleness.
            For someone who keeps up such a facade of savagery, ${kalt} can be astonishingly tender; you've glimpsed enough of that side of ${zhim} to crave more.
            
            *comment endif
        #It's hard to give it a name, really.
      *label strangekiss
      *set k_rel 3
      *if acepref and (bred_lover >= 10)
        You'd wondered how different ${kalt} would be from Breden.
      Kissing ${zhim}, it turns out, is strange but not unpleasant.
      *if (zhim = "him") and (not(acepref) or (acepref and (bred_lover >= 10)))
        The rasp of
        *if male
          someone else's
        stubble across your mouth 
      *if (zhim = "her") and (not(acepref) or (acepref and (bred_lover >= 10)))
        There's a smoothness to her face, an absence of beard and stubble, that
      *if (acepref) and (bred_lover < 10)
        Having someone's face bumping up against yours
      will take some getting used to.  But there's a warm, unfamiliar scent to ${zhim} that you find addicting—and the expression on ${zhis} face, the still-incredulous joy, is rich enough to keep you coming back to ${zhis} lips again and again.
      
      "Angels, ${fname}," ${kalt} whispers at last, when you part for the day.  "I didn't…${oath}, to be honest, I still don't really believe it.  Never thought I could truly have you, whatever I'd dreamed."
      
      "It's a good wall to walk through," you whisper back, head a-spin. 
      *page_break
      *goto egynpike
*label egynpike
*if choice_randomtest
  *choice
    #At Egyn's Pike, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.  ${inwoods} inwoods, ${inadults} inadults, ${inkids} inkids.
      *goto postchoice2
*label postchoice2
[b]Six days later, you're crouched[/b] between boulders on Egyn's Pike, scanning the cloudless sky for Theurges.  Two of the 
*if (cred_p >= 215)
  *set d2n_num theurges
  *gosub d2n
enemy magi have flown over you in the past few days; to all appearances, they're still bearing messages between the multiple Phalangite forces in the Whendward, not yet joining the hunt themselves.  Still, neither you nor your outlaws have managed to keep your eyes on the ground for long.

When you uneasily convince yourself that your little
*if strategy = 3
  warband
*if strategy < 3
  scouting party
is indeed alone, your eyes dart back to the valleys to the east.  Egyn's Pike is the highest hill between Rim Square and the snow-capped Whendish Range, overlooking vast tracts of wilderness and (barely visible some sixty miles off) the pastures, fields, and orchards of the Rim.  Today, as you'd hoped, it also provides a perfect vantage on the main enemy force.

"Bleeding Angels," you hear Young Earnn whisper nervously from just behind you.  You'd estimate there are
*if allmain < 190
  *set d2n_num allmain
  *gosub d2n
  *set housenum round(allmain/25)
  *goto howmfight
*if allmain < 240
  roughly two hundred
  *set housenum 8
  *goto howmfight
*if allmain < 290
  around two hundred and fifty
  *set housenum 10
  *goto howmfight
*if allmain < 370
  roughly three hundred
  *set housenum 12
  *goto howmfight
*if allmain < 470
  *set housenum 14
  roughly four hundred
  *goto howmfight
five hundred or more
*set housenum 20
*label howmfight
fighters marching toward you, and this is only one of the armies mustered against you (albeit the largest).  They're almost two miles away. You could be missing scores of tiny figures amongst the trees, and most details are simply invisible.
*page_break
While your other outlaws fan out down the hill
*if kal_here
  with ${kalt}
to intercept any enemy scouts, you
*if el_here
  and Elery
watch the steady advance of the enemy army.  At this distance, the Phalangites are distinguished by their meticulous order more than their red armor; their small columns hold together and keep a constant distance from each other, even while fording streams and cutting through thickets.  They maintain a good pace and are consistently leading the advance.

By contrast, the aristocrats of the Rim frequently fall behind, charge on ahead, or scatter off to the sides.  You imagine that by the end of the day, the Phalangites will be at least an hour ahead of most of them, preparing camp while the nobles catch up.  Though nearly all are afoot, their retinues still bring something of the pomp of the hunt: horns sounding, pennons flapping, hounds baying. 
*if helot
  The only House emblem you think you recognize is the crimson ram of the Keriatou, but
*if aristo
  You think you recognize the Keriatou ram and the Pelematou sparrowhawk; all told,
counting the banners, there are some 
*set d2n_num housenum
*gosub d2n
Houses pursuing you.

The Alastors 
*if com > 0
  are clearly trying to move like Phalangites, but they keep being broken up by the terrain,
*if com = 0
  are moving in a somewhat looser array than the Phalangites,
and lag well behind.   They start and jostle whenever they hear a yell from the noble parties—unlike the implacable infantry, who march on undistracted.
*if korszata > 0
  (Korszata clicks his tongue disdainfully when it happens for the fourth time.)
*if priestroops > 9
  There is also a motley cluster of
  *if priestroops > 46
    a few dozen
  commoners bringing up the rear, led by two figures in bright Ecclesiastical surplices. Squinting hard, you can just make out that everyone not in armor seems to be wearing a broad white sash, emblazoned (you imagine) with either the omphalos or the Archon's golden kennet.

Further back to the east, you can see two of the enemy's previous camps: great clearings where the Phalangites' [i]architectoi[/i] toppled trees and set up a paling of stakes around their tents.  Crossing the previous night's camp, looking almost like ants from this distance, are three dozen or so mules with another large escort.  By this evening, the week's supply train should have reached the main force.

Your heart is drumming madly against your ribs.
*fake_choice
  #But with excitement, not fear.  We're going to win, despite everything arrayed against us.
  #Yet I feel no emotion as my mind races, trying to come up with our next move.
  #Staring out at the Phalangite host, I don't believe we're going to survive this.
    You force down your despair, 
    *if skepreal <=50
      praying
    *if skepreal > 50
      hoping 
    it's neither visible nor contagious.
    
"They've got scent of us, ${addressu} ${lname}," Earnn points out tautly.  "They're following the course of our last mule train."

*if (strategy = 1) and (inadults > 15)
  "Then it's just as well we've come out to meet them," you breathe.  Most of your
  *if inkids > 2
    adult
  outlaws are in one raiding party or another, ready to begin harrying the invaders.
  *if inadults < 35
    You don't have enough outlaws to deal with the flanking forces, so you've focused all your efforts here, on the main Phalangite command.  Weaken and stall this army, and the others will falter.
    *goto harry
  Some have set off to intercept the flanking forces that are reported to be entering the Whendward through other valleys.  
  *if ((korszata = 0) and not(el_here)) and not(kal_here)
    
    You had to choose which of the band's leaders might be most useful facing the main force with you, and which you would send to face the other Phalangites. You decided that you'd send:
  *if (korszata > 0) or (el_here or kal_here)
    
    You've kept
    *if (korszata > 0)
      *if kal_here and el_here
        Korszata,
      *if not(kal_here) or not(el_here)
        Korszata
        *if kal_here or el_here
          and
    *if el_here
      Elery
      *if kal_here
        and
    *if kal_here
      ${kalt}
    with you to help deal with the main body.  Which if any of your band's leaders did you send away to lead a raid against one of the flanking forces?
  *set flanktick 2
  *if ((intel > 10) and (phalangites > 300)) and (inadults > 60)
    *set flanktick +1
  *if ((intel > 19) and (phalangites > 360)) and (inadults > 100)
    *set flanktick +1
  *set flanktotal flanktick
  *set rangers inadults
  *label flankleadch
  *choice
    *if zv_flank = 0
      *if (zv_here) #Zvad.
        *set zv_lead +2
        *set zv_flank +round(inadults/(flanktotal*2))
        *set rangers -zv_flank
        *set flanktick -1
        The craggy ${whend} had still been visibly unsure of whether he was going to stay with the band.  You sent him as much to keep him from changing his mind as to hurt the Phalangites.
        
        *if flanktick > 0
          Another party is led by:
          *goto flankleadch
        *goto kidscour
    *if rad_flank = 0
      *selectable_if (rad_here) #Radmar.
        *set rad_lead +2
        *set rad_flank +round(inadults/(flanktotal*2))
        *set rangers -rad_flank
        *set flanktick -1
        Radmar has taken 
        *if poric > 0
          Poric and
        *set d2n_num rad_flank
        *gosub d2n
        raiders north and east, hunting for the flanking force that is reportedly coming up the main track from the Norther Rim to the Whendward Pass.
        
        *if flanktick > 0
          Another party is led by:
          *goto flankleadch
        *goto kidscour
    *if bj_flank = 0
      *if (korszata > 0) #Bjel.
        *set bj_flank +round(inadults/(flanktotal*2))
        *set rangers -bj_flank
        *set flanktick -1
        The big former Phalangite has taken a squad of his ${whend}ish companions to harry their former comrades-in-arms.  "Memory guide and keep you, Oath-holder," he called before he left.
        
        *if flanktick > 0
          Another party is led by:
          *goto flankleadch
        *goto kidscour
    *if bj_flank = 0
      *if (bethune > 0) #Bethune.
        *set bj_flank +round(inadults/(flanktotal*2))
        *set rangers -bj_flank
        *set flanktick -1
        The Westriding rebel has taken a squad of her companions to harry the despised Phalangites.  "Ester's Spine and Bloody Jac!" she shouted as they set off, and the yeoman roared it back to her.
        
        *if flanktick > 0
          Another party is led by:
          *goto flankleadch
        *goto kidscour
    *if (simz_flank = 0) and (simz_here)
      *selectable_if ((simz_here) and (s_rel < 9)) #${simon}.
        *set simz_lead +2
        *set simz_flank +round(inadults/(flanktotal*2))
        *set rangers -simz_flank
        *set flanktick -1
        ${simon} de Firiac had been solemn on the day ${zhe} set out with ${zhis} band of yeoman archers. "It's no pleasure to battle fellow Shayardenes, ${addressu} ${lname}, even those who wear the omphalos.  But it needs doing…and we'll see it done." 
        *set simz_lead +2
        
        *if flanktick > 0
          Another party is led by:
          *goto flankleadch
        *goto kidscour
    *if (br_flank = 0) and (bred_trust < 9)
      *selectable_if (bred_here) #Breden.
        *set br_flank +round(inadults/(flanktotal*2))
        *set rangers -br_flank
        *set bred_lead +1
        *set flanktick -1
        "Right then.  Time to do or die.  Or both." Breden's mood had been bleak as ${xhe} set out.
        *if ((bred_lover >= 4) or (bred_heart = 3)) and (bred_trust < 10)
          $!{xhe} 
          *if (bred_lover = 3) or (bred_lover = 13)
            walked up to you as if ${xhe} were going to kiss you—but then thought better of it, and left you with nothing more than a reproachful look.
            *goto postbredbye
          *if bred_heart = 3
            held
          *if bred_heart != 3
            kissed 
          you for a long time—neither of you saying aloud that it might well be the last.
        *label postbredbye
        
        *if flanktick > 0
          Another party is led by:
          *goto flankleadch
        *goto kidscour      
    *if al_flank = 0
      #Alira.
        *set al_flank +round(inadults/(flanktotal*2))
        *set rangers -al_flank
        *set flanktick -1
        Your chief tracker has taken a band of her fellow hunters to strike down as many of the Phalangite scouts as possible.
        
        *if flanktick > 0
          Another party is led by:
          *goto flankleadch
        *goto kidscour
    #No one of particular note.
      *set meh_flank +round(((((((inadults/2)-al_flank)-br_flank)-simz_flank)-rad_flank)-bj_flank)-zv_flank)
      *set rangers -meh_flank
      *goto kidscour
  *label kidscour
  *set flanktroops ((((((meh_flank+al_flank)+br_flank)+simz_flank)+rad_flank)+bj_flank)+zv_flank)
  *set theirintel +6
  With your band divided, you find yourself once again acutely envying the Phalangites their magi.  Setting aside Theurgy's destructive power, the ability to fly between groups bearing messages would be invaluable.  Your couriers take far longer and are more vulnerable to capture or attack.
  *if inkids < 5
    
    But 
    *if int > 1
      with yourself as the rebellion's only ${wisard},
    *if int < 2
      although you might dream of the day that a Theurge joins your rebellion, for now
    you have no other recourse.
  *if inkids > 4
    *choice
      #I've got most of the children above five years old running messages.  They know the terrain well enough and can hide better than most adults.
        *set kidmess true
        Pin Thatcher is with your group, dispatching the young couriers who will keep you informed of how your other outlaws are faring.
        
        *goto harry
      #I could never put the band's children at risk like that.  They're all lying low in the deep wild.
        *set ruth %-10
        *set rangers -(flanktotal*5)
        Your couriers are young, but not below the age of innocence. 
        
        *goto harry
  *goto harry
*if strategy > 1
  *if inadults <= 15
    Part of the tension in his voice, you're sure, stems from the fact that only 
    *set d2n_num inadults
    *gosub d2n
    *if kids > 2
      adult
    rebels remain in your band.  You don't have many options in responding to the Phalangites.
  "Then it's time to…" 
  *choice
    *selectable_if (inadults > 15) #"…start slowing them down."  We're going to harry them from the woods.
      *goto harryplan
    *selectable_if (inadults > 6) #"…throw them off course."  I've brought several scouting parties to lay false trails.
      You spend a tense, dangerous week trying to stay just ahead of the army, close enough for the nobles' hounds to smell you.  Two or three times, the baying in the woods grows close enough that you think you're about to be caught.  But you manage to outrun them each time—and more importantly to distract the army from the point where your last supply train actually left the valley floor.
      
      Toward the end of the week, frustrated by your constant near escapes, the Theurges abandon their communication missions and swarm around the main army in search of you.  Perhaps inevitably, one of your scouting parties is caught in poor cover at the wrong moment.  The roar of vitriol igniting the trees is utterly terrifying, despite being a good mile away. You creep closer with one or two others, looking for survivors—but all you see is a horde of noble troops under the Pelematou banner, combing the brush in every direction around a still-smoking copse.
      
      You look to Earnn, wondering if your face mirrors the raw horror on his.  "Time to pull back," you say thickly, trying to keep a steady voice, "and save whatever luck's left to us."
      *set cas +6
      *gosub armscheck
      *gosub cascheck
      *page_break
      *set theirmorale -60
      For another week or two, your luck seems to hold.  But your scouts keep warning that multiple Phalangite forces are converging on the area where you're based, and the Theurges seem to have definitively shifted to hunting for you.
      *goto threadneedle
    #"…divide their loyalties as best we can."  I'll litter the wild with messages to sap their morale.
      *set theirmorale -10
      *if aristo
        *set theirmorale -10
      Every Phalangite is taught the alphabeta, the better to receive orders and plans.
      *if aristo or (int > 1)
        You've
        *goto barkwrote
      *elseif diakon > 13
        Edwer and his fellow Diakons have
        *goto barkwrote
      *elseif diakon > 9
        The Diakons who joined your band have
        *goto barkwrote
      *elseif etthena > 0
        Etthena and her literate Disbelievers have
        *goto barkwrote
      *elseif korszata > 0
        Korszata and Bjel have
        *goto barkwrote
      *elseif simz_here and (s_rel < 9)
        ${simon} has
        *goto barkwrote
      *else
        Your handful of lettered rebels have
        *goto barkwrote
      *label barkwrote
      spent much of the past week writing to them on scraps of parchment, bark sheets, leather, canvas—anything that will hold ink long enough for an enemy to see it.  This week, you scatter these little tracts everywhere in the path of the advancing army.
      *if (literate > 2) and (helcamp < (literate/2))
        Your
        *set d2n_num literate
        *gosub d2n
        literate outlaws (most of whom learned their letters from you during the past year) scrawl additional messages on every tree and slate outcrop they pass.
        *set theirmorale -(literate*2)
      
      The soldiers hunting you are Shayardene, generally from the Coast and Westriding.  Many of your messages appeal to the "true daughters and sons of Shayard" to join you against the common Karagond oppressor, noting the Hegemony's sundry abuses and cruelties against your nation.
      *if natl <=50
        (Just as you'd be appealing to the Wiends if you were facing a Wiendish army.)
      *if natl > 60
        You believe your passion for your homeland is by now well-known enough to attract the true patriots in the Archon's army.
        *set theirmorale -20
        *if bethune > 0
          
          When you asked Bethune if she had any advice, she tersely replied, "Veder's Brake."  Apparently that was where Karagond Theurges exterminated an army of Westriding nobles, including many Phalangites, toward the end of Cabel's Revolt some forty years ago.  The force had actually mustered against the rebels, but too slowly for the Karagonds' liking. "Make mention of that, and you'll pull up some bitter memories from the Westriding folk."
          *set theirmorale -15
      *if eclect
        
        In other tracts, you make public your claim to be the Angels' Eclect, warning the Phalangites that they attack you at peril of their souls.  You make reference to all the stories in the Codex and Traditions where the Eclectoi crushed their enemies despite overwhelming odds.
        *if diakon > 9
          The Diakons in the band enthusiastically endorse your claim.
          *set theirmorale -10
        *set theirmorale -10
      *if not(eclect) and (diakon > 9)
        
        In other tracts, the Diakons in your band call on the army to disperse or face the wrath of the Angels.  The soldiers likely know you to be devout, and having the endorsement of these priests—even lowly ones—will surely give some of them pause.
        *set theirmorale -10
      
      It's hard to tell how much consternation your messages leave before the Phalangites use them as kindling.  The army's Theurges certainly seem to redouble their efforts to catch you.  By the time your raiders finally slip away to rejoin the main band, you're seeing enemy magi overhead at least five times a day.
      *goto threadneedle        
    *if (inwoods < 44) #"…move the band without leaving a trail."  We're few enough to slip away without leaving any signs the army can follow.
      *set lostem true
      Your scouting party returns fleetly to camp, where you give the order.  Your 
      *if helcamp = 0
        small 
      *if helcamp > 0
        much-reduced 
      band follows
      *if c_rel > 0
        Ciels and
      Alira for five days up stream and over stone, taking care to leave as little scent and sign as possible.  Meanwhile, Young Earnn takes one of the mules and lays a strong false trail doubling back toward the Rim.  
      
      When he rejoins you at the end of the week, the boyish tracker is grinning triumphantly.  "Reckon they might just follow that mule all the way back to the stable she came from, ${addressu}.  But they'll not find us without the Angels' own luck."
      
      For weeks, it seems as if he's right.  Besides Theurges flying over the horizon every few days, you see no sign of the Archon's forces.  The vastness of the Whendward can swallow up even a good-sized army without a trace; it hides your little band like a pebble in a landslide.
      *set consc 4
      
      *label campblurb
      Keeping to cover, you cautiously withdraw toward the best and safest vantage point you know: the campsite you
      *if campsite > 0
        explored 
      *if campsite < 1
        were about to explore
      on the day that Alira reported the strangers heading up to the Whendward Pass.
      *set theirmorale -100
      *goto campsite
  *label harryplan
  *if strategy = 2
    *if el_here
      Elery wears a bleak smile as she stares down at the enemy.
    "Aye, then, ${addressu}.  Let's bait this bear…and hope we bleed it enough to chase it back to its den before it chews our heads off."
    
    *comment endif
  You've kept many of your
  *if helcamp > 0
    remaining
  outlaws as far back as you can while 
  *if strategy = 2
    sending:
    *choice
      #One or two small parties of rangers to harass the enemy.
        *set rangers round(inadults/4)
        *goto harry
      #Fully half my rebels to harass the enemy.
        *set rangers round(inadults/2)        
        *goto harry
      #A specific number of rebels, namely…
        *if (strategy = 1) and (inkids >= 5)
          You'll need to keep at least 
          *set babysitters round(inkids/8)
          *if babysitters > (inadults/3)
            *set babysitters round(inadults/3)
          *set d2n_num babysitters
          *gosub d2n
          of your fighters back to look after the band's
          *if outkids > 0
            remaining
          children.
        Of the
        *set d2n_num inadults
        *gosub d2n
        *if kids > 2
          adult
        rebels
        *if deserters > 0
          remaining
        in your band, you 
        *if (strategy = 1) 
          choose to bring:
          *if (inkids >= 5)
            *set rangermax (inadults-babysitters)
          *if (inkids < 5)
            *set rangermax inadults
        *if (strategy > 1)
          can bring up to two-thirds, or as many as
          *set rangermax round((inadults*2)/3)    
          *set d2n_num rangermax
          *gosub d2n
          rangers.  You bring:
        *input_number rangers 5 rangermax
        *goto harry
  *if (strategy = 3)
    sending
    *if inadults < 30
      a handful of rangers
      *set rangers 6
    *if inadults > 29
      small ranger parties
      *set rangers round(inadults/4)
    to watch and (if possible) harass the enemy.
    *if (inwoods > 25)
      You only hope it buys you time to sneak some more of your remaining outlaws right around the Phalangite scouts and into the Rim.
    *goto harry  
*label harry
*set violence +1
*if (strategy > 1) or (inkids < 5)
  *page_break
The fight of your life begins in oddly impersonal and scattered fashion.  You're all too aware that Captain Tychon of the Rim Square Alastors, 
*if aristo
  cousin 
Hector Keriatou, and some nameless Phalangite Tagmatarch 
*if (calea > 9) or (intelsale > 0)
  with a magic sword 
are leading the hunt for you—but you don't get close enough to the heart of the army to glimpse any of them.

*if (intel < 10) and (strategy = 3)
  Having such limited previous intelligence on the Phalangites, you keep a careful distance rather than actively trying to harry them.  You foul a few wells in their path, but with so many spring-swollen streams to drink from, this doesn't seem to have any effect. Twice you run into Alastors or nobles where you'd not expected them, and while your outlaws 
  *if com < 2
    (barely) 
  prevail in those clashes, it drives home the importance of caution.
  *set aristroops -8
  *set alastroops -6
  *set cas +round(rangers/10)
  *goto traptime
Instead, during the next week in the woods, your outlaws
*if strategy = 3
  find a handful of opportunities to
strike at the margins of the enemy host.  You pick off scouts and stragglers, foul the wells in their path, occasionally bait a small group into an ambush.
*if priestroops > 0
  The devout commoners mobilized by the Ecclesiasts are particularly easy marks, lagging behind the better warriors and readily drawn after "${lname}'s Xaos-lovers."
*gosub harrycas
*label traptime
*if traps > 0
  
  Many of the Archon's troops are moving through areas where you spent the winter laying traps.  By and large you find it's the less disciplined
  *if priestroops > 0
    commoners,
  nobles and Alastors
  *if com > 1
    *set traps (traps*2)
  *if (aristroops+alastroops) > traps
    *set aristroops -round(traps/2)
    *set alastroops -round(traps/2)
  *if (aristroops+alastroops) <= traps
    (along with some Phalangite scouts)
    *set aristroops -round(traps/3)
    *set alastroops -round(traps/3)
    *set phal1 -round(traps/6)
    *set phalangites -round(traps/6)
    *set phal2 -round(traps/6)
    *set phalangites -round(traps/6)
  who break away from the main force to pursue your raiders—and who can be lured into your deadfalls, stake pits, and landslides.
  *if com > 1
    Thanks to your skill as a tactician, you make the most of every trap, leaving a trail of bodies around each one.
  Over the following week, the Archon loses 
  *set d2n_num traps
  *gosub d2n
  fighters to your snares.
  *if com < 2
    *set cas +round(traps/20)
  *set cas +round(traps/20)
  *set morale +round(traps/4)
*if (intel < 10) and (strategy < 3)

  Time and again, however, you're surprised by Alastors or Phalangites appearing in a corner of the wilderness where you'd not expected them yet.  
  *set cas +round(rangers/8)
  *set morale -round(rangers/6)
  *if kidmess and (inkids > 6)
    *if inkids > 14
      Eleven
      *set inkids -11
      *set inwoods -11
      *set followers -11
      *set kidsdead +11
      *set dead +11
      *set morale -25
    *if inkids < 15
      Four
      *set inkids -4
      *set inwoods -4
      *set followers -4
      *set kidsdead +4
      *set dead +4
      *set morale -14
    child couriers are among your casualties, disappearing in areas which turned out to be under enemy watch.
  Perhaps if you'd been able to gather more information on your enemy before they arrived, you wouldn't be so often (or so disastrously) caught off guard.
*if (intel > 29) and (strategy < 3)
  
  Your attacks are all the more effective for having gathered as much intelligence as you have on the enemy.  With a fairly good idea of how many they are and where they'll be coming from, your greater familiarity with the terrain gives you a decided edge.
  
  "We're doing it!"
  *if el_here
    Elery crows
  *if not(el_here)
    Earnn exclaims in disbelief
  one day after returning unscathed from a raid that felled seven Alastors and two Phalangites. 
  *if el_here
    "Maybe we're not wolves to them, but we're big swiving wasps, at least."
  *set phal1 -round(rangers/10)
  *set phalangites -round(rangers/10)
  *set aristroops -round(rangers/10)
  *set alastroops -round(rangers/10)
  *set morale +20
*if (strategy = 1) and (popular != 10)

  *if intel < 10
    Despite all this, you
  *if intel > 9
    You
    *if intel > 29
      also
  begin to see the rewards of the time you put into drilling your 
  *if sybla > 0
    bandits, both with Sybla and 
  *if sybla = 0
    bandits
  over the past month.  They fight more effectively than you'd have believed possible back in the winter—waiting to strike until the enemy is close enough to be significantly hurt, and then retreating quickly and in good order.
  *if kal_here
    "Good to see that it's all adding up to something," ${kalt} grins proudly when you mention it.
  *set phal1 -round(rangers/10)
  *set phalangites -round(rangers/10)
  *set aristroops -round(rangers/10)
  *set alastroops -round(rangers/10)
  *set morale +20
  *page_break
*if (popular = 10) and (strategy = 1)

  Unfortunately, you
  *if (intel < 10) or (traps > 0)
    also
  have reason to regret the divisions in the band that kept you from making the most of the past month.  Too few of your outlaws have the skills to strike at the enemy and retreat in good order, or confidence with the weapons they've been half-trained to use.  You're taking more casualties than you can afford to, and hurting fewer of the Phalangites (compared to the relatively easier targets among the
  *if priestroops > 0
    common volunteers,
  nobles and Alastors).
  *set cas +round(rangers/8)
  *set morale -round(rangers/6)
  *page_break

As 
*if (intel < 10) and (strategy = 3)
  reports of your presence filter back to the army, you 
*if (intel > 9) or (strategy < 3)
  your attacks begin to sting the army, you inevitably 
draw the attention of its 
*set d2n_num theurges
*gosub d2n
Theurges. 
*if theurges <= 3
  You usually spy them flying off over the horizon with a message, but increasingly they also spend an hour or two a day circling the hills where you and your raiders are hidden.  
*if theurges > 3
  Three of them remain devoted to communication missions, but the 
  *if theurges > 4
    others focus 
  *if theurges = 4
    other one focuses
  on hunting your raiders.  The first time you hear the roar of vitriol igniting the trees, it's utterly terrifying despite being a good mile away.  By the end of the week, you're beginning to grow numbly accustomed to it, and to the outlaws who don't find their way back to camp at the end of the day.

On Bronday afternoon, 
*if rangers <= 11
  two
  *set cas +2
*if rangers > 11
  six
  *set cas +6
of your rebel scouts break cover on a lightly forested slope above you—and disappear in a vast fireball, too quickly for screams.  You and your fellow raiders dive into the bushes and lie unmoving while a Theurge soars overhead.  An empty blood phial falls from the sky and skitters down the stony slope mere yards from your face.    
*if yeotroops > 10
  
  There also prove to be 
  *set d2n_num yeotroops
  *gosub d2n
  stony-faced yeomen hunting you in the wilderness.  Some were raided by your outlaws, others are just hostile to your vision for Shayard, or hoping for the nobles' favor.  The contest between your archers and theirs is both deadly and bitter.
  *if yeotroops < 21
    *set cas +round(yeotroops/3)
  *if yeotroops >= 21
    *set cas +round(yeotroops/4)  
  *set yeotroops -round(rangers/5)
  *if yeotroops < 0
    *set yeotroops 0
*page_break
*gosub troopscheck
but the Phalangites march relentlessly onward.
*if cas > (rangers-7)
  *set cas (rangers-7)
  *if cas < 3
    *set cas 3
  *set harryloss true
As for you, 
*set d2n_num cas
*gosub d2n
of your outlaws have fallen in the woods.
*gosub armscheck
*gosub cascheck
*if harryloss or (rangers < 13)
  *if cas > 3
    Even
    *if kal_here
      ${kalt} has
    *if not(kal_here) and rad_here
      Radmar has
    *if not(kal_here) and not(rad_here)
      you have
    to admit
  *if cas <= 3
    With your tiny numbers,
  that's too many to sustain.  The survivors limp back to the deep wilderness as quickly as possible.
  *set morale -20
  *goto pullback
*if rangers < 24
  
  *goto week2harry
*page_break
It's clear
*if com = 0
  from your conversations with 
  *if korszata > 0
    Korszata and Bjel
  *if (korszata = 0) and el_here
    Elery and other
  *if (korszata = 0) and (not(el_here) and rad_here)
    Radmar and other
  *if (korszata = 0)
    more experienced bandits
that you could massively hamper the Archon's forces by successfully striking either their supply train or their Theurges.  A hundred miles into the wilderness, cutting off either their provisions or communications would slow them to a crawl.  Hitting both would paralyze them.

And of course the Phalangites need the Theurges for attack, not just communication.  Within two weeks, as the various flanking forces converge toward you, the magi will shift their priorities to hunting you down.  If you could strike now, before they've fully committed to the hunt, you could turn the course of the battle.

But with 
*set d2n_num rangers
*gosub d2n
raiders left in your party, both raids are tremendously risky.  The supply trains are reportedly guarded by 
*if merchtroops > 0
  *set d2n_num merchtroops
  *gosub d2n
  hired swords sent by the traders' Syntechnia, as well as
forty crack Phalangites and at least one Theurge.  The madness of attacking experienced Theurges hardly needs emphasizing.
*if ((theirintel > 3) and (theirintel != 6)) and (theuknown = 5)
  Especially as you fear that by now they've heard rumors of your own ${wisardry} from captured deserters; if they believe them, you'll have lost any element of surprise.
  *set theuknown 7
*choice
  #Attack the next supply train.
    *label supplytrain
    *set supply 80
    *if merchtroops < 40
      *set supply (merchtroops*2)+(40-merchtroops)
    *if (intel > 29) or (korszata > 0)
      "We have a window now, ${kuria},"
      *if el_here
        Elery
      *if not(el_here) and kal_here
        ${kalt}
      *if (not(el_here) and not(kal_here)) and (simz_here and (simz_flank < 1))
        ${simon}
      *if (not(el_here) and not(kal_here)) and (not(simz_here) or (simz_flank > 1))
        Young Earnn
      says intently.  "According to
      *if intel > 29
        our spies in the Rim, they're
      *if intel < 30
        Korszata, they'll be
      sending 
      *set d2n_num mainmules
      *gosub d2n
      mules every two days from Rim Square with grain enough for a week.  Because a Phalangite host and mules move at different speeds, every six days a train reaches the army. Our scouts tell us they're going to get one today.
      
      "The toughest guards will be the forty Phalangites who came in with the first mule train.  Since then, they've been doubling back, meeting each new supply train, sending its guards back to the Rim, and escorting the mules for five days until they catch up to the army again."
      
      You nod with sudden understanding.  "So tomorrow morning, we should have a few hours' window when the next supply train will be near enough to strike…and we'll be able to carry off the ambush against only the 
      *if merchtroops > 0
        Syntechnia
      hired guards, not the 
      *if theurges > 0
        Phalangites. But what
      *if theurges = 0
        Phalangites."  And your successful attack on the Theurges means you'll not need to face them, either.
        *goto currbivouac
    *if (intel < 30) and (korszata < 1)
      *if theurges = 0
        *goto currbivouac
      "What
      *set supply 160
    about the Theurge?"
    
    "We'll need to draw them away.  Give them a campfire a mile or two off, and some bandits to chase down into the woods."
    *if el_here
      Elery
    *if not(el_here)
      Young Earnn
    exhales sharply. "I'll find a place for it, ${kuria}.
    *if (theuknown > 4)
      Save your ${wisardry} for when we need it most.
    Just lend me four
    *if not(el_here)
      other 
    good hunters."
    *label currbivouac
    *page_break
    You leave your current bivouac around dusk, at an hour when you hope your
    *set d2n_num rangers
    *gosub d2n
    raiders will be able to sneak past the enemy scouts 
    *if theurges > 0
      and Theurges 
    unnoticed.  The next morning, you
    *if el_here and (theurges > 0)
      do your best in Elery's absence to
    identify the best ambush point along the broad track cleared by the marching army.
    
    By the time the first armored guards march into view, mules ambling contentedly behind them, you're all concealed in the woods.  
    *if theurges > 0
      When a minute passes with no Theurge appearing overhead, you glance around at the other outlaws; you'll have to proceed as if
      *if el_here
        Elery's
      *if not(el_here)
        Earnn's
      gambit has succeeded.  
    Heart pounding, you give the signal to strike.
    *if (int = 2) and (not(wipecut) or (blood > 0))
      *if wipecut
        Even the thought of spilling your own blood for Theurgy makes spots dance before your eyes.
      *choice
        *if (not(wipecut)) #At the same time, I cut my hand and use ${wisardry}.
          *set consc -1
          *label theuch
          *if (theuknown < 10)
            Did you want to hamper the guards through dozens of small changes—or is it time to stop being discreet with your ${wisardry}?  You've been studying the steep slope on the far side of the valley, and think that by increasing the natural flow of water in the scree, you could start a landslide that would bury half the supply train.
            
            Of course, if you managed to kill the other half, the secret of your ${wisardry} would still be safe.
            *if theurgy != 3
              Only your followers would know.
            *choice
              #Stay discreet.
                *set discreet true
                *set supply -20
                *goto supplynum
              #Bury them.
                *set landslide true
                *goto landslider
          *label landslider
          *set supply -40
          *if (intel > 29) or (korszata > 0)
            *set supply -40
          You stare out across the valley, focusing on what you can see and sense in the far slope.  It [i]wants[/i] to fall; the angle is so deliciously steep and the scree loose. But there are key stretches where boulders have toppled against each other and forced a pause in the mountain's long, slow collapse.  You focus on a few of those great stones and imagine the earth and scree beneath them beginning to flow like water—the water you can sense pent up all along the slope, in the soil and roots and moss.
          
          The thunder is shattering.  When the dust clears, you can see that half the
          *if (intel < 30) and (korszata < 1)
            Phalangite
          guards and more than half the mules are buried under the stones.
          
          *goto supplynum
        *if (not(wipecut)) 
          *selectable_if (blood > 0) #At the same time, I pull out a blood phial.
            *set blood -1
            *set usedblood +1
            *goto theuch
        *if wipecut
          #But I pull out a phial of aetherial blood and spill it into my palm.
            *set blood -1
            *set usedblood +1
            *goto theuch
        *if (theurges > 0) 
          #I'm not going to risk using ${wisardry} so close to a Theurge. What if they sense it and fly back?
            *goto supplynum
        *if (theurges = 0) and (not(wipecut))
          #I want to conserve my strength.  We can beat them without ${wisardry}.
            *goto supplynum
        *if (theurges = 0) and (wipecut)
          #I want to conserve my blood.  We can beat them without ${wisardry}.
            *goto supplynum

    *label supplynum
    Your archers 
    *if not(landslide)
      launch the ambush 
    *if (landslide)
      follow up
    with three volleys of arrows into the 
    *if not(landslide)
      mule train.  
    *if (landslide)
      stunned survivors.
    The surviving guards raise their shields and charge for you, bellowing with
    *if (landslide)
      terrified
    fury. Your raiders swap their bows for
    *if arms < inadults
      *set supply +10
      *set cas +5
      clubs, axes,
    swords and maces, and the real battle begins.
    
    *if discreet
      That's when you go to work.  Snapped armor straps, swords that twist in their masters' grips, suddenly rigid joints…you stay back from the fray and do everything you can think of to hamper the enemy.
    *if morale < followers
      *set supply +10
      *set cas +5
    *if wipecut and (blood <= 0)
      Even the thought of using Theurgy makes spots dance before your eyes.  You sway in place, hoping you won't pass out again.
    *if com > 1
      You throw yourself into the fray, wielding your ${weapon} with all the skill you have.
      *if ((intel < 30) and (korszata < 1)) and (not(plekspear) or pleksecret)
        Against a crack Phalangite squad, though, it's all you can do to stay alive.
      *set supply -15
    *if plekspear and (not(pleksecret) and not(wipecut))
      *set supply -30
      *if com = 0
        *set supply +10
        Normally, you'd hold back from the fray, but today you hurl yourself in with a ragged howl.
      Your Theurge-forged weapon cleaves armor as if it were parchment.
    From all sides comes the din of steel on steel, the howls of humans trying to kill each other.
    *if korszata > 0
      Korszata fights with supreme efficiency, shoulder to shoulder with two other former Phalangites.
      *set supply -15
    *if kal_here
      You catch a glimpse of ${kalt} bringing down a guard with a spiked bola.
      *set supply -10
    *if el_here and (theurges = 0)
      Elery is hurling sling-stones into the fray.
    *if rad_here and (rad_flank < 1)
      To your left, Radmar's axe smashes through an enemy's helm.
      *set supply -10
    *if zv_here and (zv_flank < 1)
      Zvad bellows a ${whend}ish war cry and rallies your right wing.
      *set supply -10
    *if simz_here and ((simz_flank < 1) and (s_rel < 9))
      ${simon} moves swiftly from enemy to enemy, ${zhis}
      *if s_sword != 1
        plundered
      sword felling one after another.
      *set supply -20
    *set supply -rangers
    *if supply < 1
      
      And while
      *set theirmorale -100
      *set morale +10
      *if (intel < 30) and (korszata = 0)
        the Phalangites die hard, taking many of your raiders with them…in the end, they all die.
        *set phal1 -40
      *if (intel > 29) or (korszata > 0)
        the fight grinds on for what seems an eternity, in the end the Syntechnia's hired guards have all fallen.
        *set merchtroops -40
        *if merchtroops < 0
          *set alastroops +merchtroops
          *set merchtroops 0
          *if alastroops < 0
            *set aristroops +alastroops
            *set alastroops 0
      *set arms +20
      *if not(landslide)
        *set arms +20
      *set cas +round(rangers/9)
      *label muleslau
      *set morale +15
      *set supplycut 5
      "Slaughter the mules and burn the grain," you bark to your bloodied, wide-eyed bandits, who seem paralyzed by their own
      *if (intel > 29) or (korszata > 0)
        unlikely
      victory.
      *if theurges = 0
        "Let nothing be left for the enemy.  Let them feed themselves on scraps, as we did in the winter!"
        
        Like a dam bursting, your surviving followers shake off their stupor and charge down to embrace you from all sides.  Their voices calling your name have a tone of near-frantic devotion.  Against seemingly hopeless odds, you've led them to a moment when the enemy Theurges are dead and the Phalangites about to go hungry.
        
        They believe you're going to win.
        *set notoriety +20
        *achieve supply
        *fake_choice
          #And for a moment, I do too.
          #For my part, I never doubted it for an instant.
          #I hide my fear of whatever the Hegemony still has in store for us.
        *set morale +30
        *goto pullback
      "Swiftly!  If any laggards have heard the fight, we could have a Theurge down on us at any minute."
      
      A Theurge does eventually soar from the horizon, followed shortly by two more—but far too late, drawn by the pillar of smoke rising from the great pyre you've made of their supply train.  The survivors of your raiding party are half a mile away and under heavy tree cover. "We've done it, ${addressu},"
      *if kal_here
        ${kalt} gasps,
      *if not(kal_here) and (korszata > 0)
        Korszata rumbles,
      *if not(kal_here) and (korszata < 1)
        an outlaw gasps,
      staring back at the magi swooping like angry wasps around the smoke.
      *gosub landsplain
      *if supply > 0
        *if theuknown < 10
          *set cred_p -50
        *set theuknown 10
      *set morale +20
      *achieve supply
      *set supplycut 5
      *goto nextfight
    *elseif supply < 20
      
      *set theirmorale -70
      *if (intel < 30) and (korszata = 0)
        If you'd only been fighting hired guards and not hardened Phalangites, you'd surely have crushed them.  As it is,
        *set phal1 -34
      *if (intel > 29) or (korszata > 0)
        In the end,
        *set merchtroops -34
        *if merchtroops < 0
          *set alastroops +merchtroops
          *set merchtroops 0
          *if alastroops < 0
            *set aristroops +alastroops
            *set alastroops 0
      a handful of muleteers escape with a few pack animals—but most of it is in your hands.
      *set arms +16
      *if not(landslide)
        *set arms +16
      *set supplycut 3
      *set cas +round(rangers/6)
      
      *goto muleslau
    *elseif (supply < 40) or (landslide)

      Though you manage to kill more than half the convoy's guards, the rest of them consolidate and push you back.  You've lost half your own ambushers by the time you call the retreat.  "Disengage, and run," you shout, fighting disappointment and panic.
      *if theurges = 0
        
        The supply train guards stick with their mules, wary of being drawn into an ambush.  When you finally muster your survivors an hour later, you're fairly sure you've lost any pursuit.
        *goto thankangels
      "Before they can signal the Theurge."
      
      The supply train guards stick with their mules, wary of being drawn into an ambush.  When the magi arrive, nearly an hour later, you're far off and under good cover. 
      *label thankangels
      "Thank Angels.  Still, we lost too swiving many for an attack that didn't even cost them their food,"
      *if kal_here
        ${kalt} growls.
      *if not(kal_here)
        one of your outlaws mutters.
      *set supply 39
      *set theirmorale -35
      *if (intel < 30) and (korszata = 0)
        *set phal1 -21
      *if (intel > 29) or (korszata > 0)
        *set merchtroops -21
        *if merchtroops < 0
          *set alastroops +merchtroops
          *set merchtroops 0
          *if alastroops < 0
            *set aristroops +alastroops
            *set alastroops 0
      *set cas +round(rangers/2)
      *set arms -cas
      *if arms < 0
        *set arms 2
      *set morale -10
      *gosub landsplain
      *if landslide and (theuknown < 10)
        *set cred_p -50
        *set theuknown 10
      *goto nextfight
    *else

      In the end, your attack hurts them—but not nearly enough.  They protect the mules, rally, and devastate your raiding party before you flee. 
      *if (intel > 29) or (korszata > 0)
        *set phal1 -12
      *if (intel < 30) or (korszata = 0)
        *set merchtroops -12
        *if merchtroops < 0
          *set alastroops +merchtroops
          *set merchtroops 0
          *if alastroops < 0
            *set aristroops +alastroops
            *set alastroops 0
      *set cas +round((rangers*2)/3)
      *set arms -cas
      *if arms < 0
        *set arms 2
      *set morale -20
      *goto nextfight
    *label nextfight
    *if theurges = 0
      *goto pullback
    
    You cautiously rendezvous with
    *if el_here
      Elery
    *if not(el_here)
      Young Earnn
    the next day.
    *if not(el_here)
      *set cas +3
      *set morale -6
      Only one other of the rangers who went with him returns, and they are both shaking. "The bastard caught us," is all Earnn can say for a long time.  "Hope we kept him off you long enough."
    *if el_here
      *set el_lead +2
      She hasn't lost a single one of the outlaws who went with her. "Luck, ${kuria}," Elery says with a shaky grin. "Could have gone a lot differently if our Theurge had circled right at one point instead of left, and caught us before we'd properly gone to ground."
    *if cas > (rangers-5)
      *set cas (rangers-5)
      *set morale -10
      *if el_here
        
        But her good luck doesn't compensate for the losses you had on the main raid.
      Your handful of survivors flee back to the deep wilderness in disarray.
      *goto pullback
    *if atkboth
      *page_break
      Having attacked their supply train, you turn your mind to any possible way of beating their magi.
      *if (el_here)
        "It's not going to be swiving easy, ${kuria} ${lname}, I can tell you that." Elery is plainly trying to keep her voice level. "I had a corner of my mind on it when we were baiting our Theurge…and anything I came up with could kill us as easily as them."
        
      *if not(el_here)
        Earnn's terror is a sobering reminder of how close to impossible it is.
        
      *goto theurgeatk
    *goto pullback
  #Attack the Theurges.
    *label theurgeatk
    In the past few days you've seen one or two outlaws attempt to fend off Theurges with arrows—even in one brave fool's case a flaming arrow, with a rag soaked in oil of dittany.  The mage doused the flame with a thought, and set the archer on fire by igniting the remaining oil in his quiver. 
    *if com = 2
      
      Plenty of your 
      *if aristo
        helot 
      outlaws could wrap a bola around their necks from forty yards, but you expect the Theurges' high collars would protect as well against that as their coats and cowls do against arrows. You've spent many an hour mentally running through other things that might work in theory.  
      *if helot
        Things you've only heard of from listening to conversations in the agora, and can barely imagine:
      ${erretsin} wind-spitters, or a ballista, or a catapult loaded with hot sand.  None of them things you could use here.
    Anything you try now has a good chance of ending much the same way as the dittany arrows.
    *label theurgeatk2
    *choice
      *if (theuknown < 10) and (theurgy > 1)
        *hide_reuse #Because they don't know I'm a ${wisard}, I have a chance to destroy them all with a single dramatic blow.
          This is the moment you've been waiting for.  If they'd known your powers, they would be on full alert for any possible ${wisardric} attack, day or night. As it is, you have one chance to strike them from a direction they couldn't possibly anticipate.
          
          *if theurgy != 3
            It begins as a mystery to your outlaws, too.  "What I'm going to ask you to do is strange," you flatly admit. "But trust me.  
          *if theurgy = 3
            You don't tell the full plan to anyone in the band. "What I'll ask you is strange," you acknowledge, "but trust me.
          It's based on something I've read…a way of turning their own powers against them."  They somewhat dubiously accept your word, even when you bring them up to a clifftop and set them to a night of hard labor, felling four large pines.  By dawn, you've lashed them together into a great round platform along with every dittany bush you can find.
          
          During the day you station a few outlaws under the tree raft, sharpening as many branches as possible into great spikes.  Your pulse skips every time a Theurge flies nearby. Will they spot the prematurely fallen pines, or the concentration of elemental fire in the dittany oil?  
          *if theuknown = 7
            *set cas +8
            *set morale -8
            
            To your horror, one of the enemy magi veers off course and hovers for several minutes above the clifftop.  You almost weep when you see her body stiffen and head snap up in realization.  Raising one hand with a shout of warning, she ignites the mass of dittany.  The fire-raft that you'd hoped to levitate and drop onto their camp by night is now burning your followers alive.
            
            All
            *set d2n_num theurges
            *gosub d2n
            of the enemy Theurges fly out on the hunt for you, vengefully combing every inch of the woods.  It's clear that they understand the precise intention of your trap, which means they know they're hunting for a magician.  If you'd chosen to ambush them in terrain less rugged with cover less dense, you'd surely all have been caught and slain.  As it is, four more of your rebels fall before you escape.
            
            Perhaps the enemy hadn't wanted to believe what your captured deserters must have been telling them—hadn't credited that in so remote a corner of the Hegemony they might truly be facing a self-taught Theurge.  But now that you've come so close to striking them, there will be no second chances.  They know of your ${wisardry} now, and they'll be on their guard.
            *set theuknown 10
            *if atkboth2
              *page_break
              Having failed to wipe out the Theurges, it's all the more vital that you successfully cut off the Phalangites' supplies.
              
              *goto supplytrain
            *goto pullback
          You watch as the first Phalangite engineers appear below you and begin felling their own trees.  The Theurges circle the camp, ready to pursue bandit archers who never appear. By evening, you've seen all
          *set d2n_num theurges
          *gosub d2n
          of them land and retire to their well-guarded tent in the center of the encampment.
          
          You sit up for hours, seething with anticipation.  By contrast, the handful of outlaws you've asked to stay awake with you grow increasingly drowsy and impatient.  "How are we going to get them to…do whatever it is you're thinking of, ${addressu}?"
          *if el_here
            Elery
          *if not(el_here) and kal_here
            ${kalt}
          *if (not(el_here) and not(kal_here))
            Young Earnn
          groans at last.
          
          "We aren't waiting for them to do anything.  We're waiting to see if we can get a friendly wind."  Every muscle and nerve is afire as you stand.  "Feel it? The wind just shifted.  Now: keep silence, trust me…and be ready to run if this fails."
          *if blood > 0
            *choice
              #I cut my palm.
                *goto cutpalm
              *selectable_if (blood > 1) #I use two blood phials.
                *set blood -2
                *set usedblood +2
                *goto nocutp
          *label cutpalm
          *set wipecut true
          *set consc -2
          *label nocutp
          You've never tried to shift anything so heavy before.  Even with the fire in the dittany complementing that in the tree trunks, levitating the whole platform makes your eyes bulge against your skull.  The thrumming of blood in your ears is so strong that it nearly drowns out the stifled yelps of shock from your followers.
          
          The wind catches the raft, with your encouragement.  You try to keep it steady as it floats out over the camp, to slow it when it reaches the center.  The heart of the camp is brightly lit, to catch anyone who might be desperate enough to make an assault on the Theurges' tent.  With the firelight flooding the guards' eyes, there's no real chance of them noticing a few stars obscured, even if they'd thought to look up. 
          
          Flickers of blackness begin to obscure your vision, but you grit your teeth and concentrate until you can actually see the path along which the pines want to fall. You nudge the wind against the raft until it's exactly where you need it.  Then, 
          *if not(wipecut)
            as the last blood evaporates from your palm,
          *if wipecut
            with the last of your consciousness
          you reach out and ignite it. A crown of flames
          *if wipecut
            bursts across the blackness…and you topple backward into oblivion.
          *if not(wipecut)
            roars into existence high above the Phalangite camp, then falls as fast and hot as a star.
          *if theuknown < 10
            *set cred_p -50
          *set theuknown 10
          *achieve theurgebane
          *set notoriety +60
          *page_break
          *if wipecut
            You wake up on the stretcher you'd had some of your bandits make, being carried back toward your camp.  Mustering all your energy, you manage to tap the shoulder of the outlaw dragging you along and rasp, "Did any survive?"
            
            He jumps and all but drops the stretcher. "Bleeding Angels, ${addressu}.  What could 
            *if theurgy = 3
              survive that?  If you had to show them all we've got a ${wisard} in the band, you picked the right swiving time for it."
              *set theurgy 4
              *if atkboth2
                
                The effort of smiling is almost too much for you.  It'll be many days before you could use ${wisardry} again without
                *if blood > 0
                  either using a blood phial or
                falling unconscious.  Do you still want to attack a supply train?
                *choice
                  #Absolutely.  When better than after we've just killed their magi?
                    *goto supplytrain
                  #No.  This is victory enough.
                    *goto pullback
              *goto pullback
            survive…whatever you just did?"
            
            The rest of the raiders gather around you, eyes wide and terrified.
          *if not(wipecut)
            For several minutes, you and your astounded followers gaze down at the great pyre that had been the Theurges' tent.  You're ready to scramble back to shelter should any survivors fly out of the wreckage, or be pulled out by the yelling swarm of Phalangites.  But no magi appear, conscious or injured.
            
            At last, 
            *if theurgy = 3
              one of your rebels glances over at you, a grin trembling on his face. "Angels, ${addressu}. If you had to show them all we've got a ${wisard} in the band, you picked the right swiving time for it."
              *set theurgy 4
              *set theirmorale -(theurges*50)
              *set theurges 0
              *if atkboth2
                *page_break
                While the Phalangites are still reeling from the loss of their Theurges, you move swiftly to wipe out their supply train.
                
                *goto supplytrain
              *goto pullback
          "What in the name of Almighty Xthonos was that?"
          *if kal_here
            ${kalt}
          *if not(kal_here) and el_here
            Elery
          *if (not(el_here) and not(kal_here))
            Young Earnn
          demands, throat so dry that the words barely escape.
          
          *gosub wisexplain
          *set theirmorale -(theurges*50)
          *set theurges 0
          
          They stare at you with more questions and fears than anyone is ready to put into words.  At last
          *if el_here
            Elery shakes her head and says, 
          *if not(el_here) and kal_here
            ${kalt} snorts, 
          *if (not(el_here) and not(kal_here))
            an awestruck Earnn mumbles,
          "Well, ${addressu},
          *if (el_here) or (kal_here)
            I have to say…that was a Xthon'damned 
          good time to pull [i]that[/i] secret out of the air."
          *set theurgy 4
          *if atkboth2
            *page_break
            While the Phalangites are still reeling from the loss of their Theurges, you move swiftly to wipe out their supply train.
            
            *goto supplytrain
          *goto pullback
      *if (int > 1) and (theuknown < 10)
        *hide_reuse #Try to ambush them using ${wisardry}.
          *if plekspear and (consc > 0)
            *label theuspear
            "$!{addressu},"
            *if kal_here
              ${kalt}
            *if not(kal_here)
              Young Earnn
            says dubiously, "these are seasoned Theurges.  
            *if theuknown >= 5
              Whatever you've managed to teach yourself…do 
            *if theuknown < 5
              Do
            you really think you can beat them before they burn us all?"
            
            "There's one thing we have that not even a seasoned Theurge would expect," you reply as you and your small party press out to the north.
            *if pleksecret
              To your party's confusion, you
            *if not(pleksecret)
              You
            glance at the whorl-bladed spear, on whose shaft you've impaled five rings of pinewood.  "Just trust me,
            *if theuknown < 5
              keep an arrow on them,
            and stay quick on your feet."
            
            *gosub theuthing
            Then you lift the Plektoi spear, hurl it forward with all your might, and sharply levitate the wood rings on its shaft.
            *page_break
            *if ((theirintel > 2) and (theirintel != 6)) and not(pleksecret)
              To your horror, however, the Theurge whirls and halts the spear in mid-air with a gesture. "So.  The famous Halassur-forged spear," he says in a loud voice, grinning. "I've been wanting to see how well it works."
              
              Drawing on more blood than you possess, he wrenches the spear from your ${wisardric} control and flings it back at you.  Your last, furious question is how they knew…and then the blade passes through your brain, taking all thought with it.
              *goto_scene death
            The Theurge seems to sense something, and spins in the air with a savage curse to face you.  He spares an instant's glance for the spear soaring toward him, but immediately returns his attention to you while drawing a terrifyingly large blood phial.  Does he assume it's a distraction, like the pine—or a strategic misstep by a self-taught Goete who doesn't understand that even steel blades can't pierce magecloth?  For just an instant, you feel the air around you grow thick, unbreathable, crushing.
            
            Then the pressure on you vanishes with the Theurge's shriek.  You pour all your ${wisardric} energy into maintaining the momentum of your throw, but trying to force the spear through your enemy's coat is like pushing a normal spear into an old oak.  The effort brings flecks to your vision and blood bursting from your nostrils.  
            
            Barely half an inch of the spearhead has pierced that black woolen coat.  Of course, that's enough to have him thrashing in agony, and he's cut his hands badly on the crescent blades trying to push the weapon back. [i]This was never made just for boar, or Plektoi hounds[/i], you think in a moment of icy clarity.
            
            Then the Theurge's head snaps forward, and your spear slides without further resistance through his suddenly plummeting body.  When you sprint up to the corpse, 
            *if theuknown < 5
              you see Earnn's arrow in the man's skull—but Earnn himself is staring at you, looking as if he's about to be sick. "Sweet
              *if religion < 20
                Angels,
              *if religion > 19
                kenon,
              ${addressu}…what was that?"
              
              *gosub wisexplain
              
              "Xthonos's Eyes. So that's why we've been doing so well."  The young ranger shakily retrieves his arrow. "Reckon he
              *set theuknown 5
              *goto penetrable
            Earnn is retrieving his arrow from its skull. "Thank
            *if religion < 20
              Angels
            *if religion > 19
              kenon
            you were right, ${addressu}," the young hunter says shakily. "He 
            *label penetrable
            couldn't keep his cowl impenetrable when all his attention was on his coat."
            
            You pull back the Plektos spear—and recoil as a tangle of viscera follow the blade out of the Theurge's riven body.  Choking back bile, you search for the bandolier of aetherial blood.  Many of the phials were shattered in the fall, but eight are still intact.              
            
            "Hide the body, quickly," you say, trying to swallow your terror.
            *set theurges -1
            *set theirmorale -50
            *set morale +10
            *set notoriety +10
            *if usedblood > 0
              *goto back_to_pos
            *if cut2
              After your brief but intense struggle, you're close to passing out from blood loss.  A second Theurge will likely be here shortly in response to the first one's signal. Your only chance of standing against them is to use these looted phials.
              *choice
                #I'll use them without the least qualm.
                  *set blood +8
                  *set ruthreal %+10
                  *goto back_to_pos
                #It pains me to use Harrowed blood, but I've got no other choice.
                  *set blood +8
                  *goto back_to_pos
                *if blood > 0
                  #I've never actually used the ones I picked up in Rim Square.  I don't intend to start now.
                    *goto smashphials
                #I could never use the blood of murdered helots.  We'll smash the phials and flee.
                  *label smashphials 
                  *set ruthreal %-20
                  *set cred_h +20
                  Bringing down one Theurge is enough work for one day.  
                  *if atkboth2
                    Better to shift your attention swiftly to their supply train, while they're still hunting for you over on this side of their camp.
                    
                    *goto supplytrain
                  
                  *goto pullback
            *label back_to_pos
            "Then back to positions.  We might have only a few minutes before we have to do this again." [i]And if they send two…[/i]
            
            *if not(cut2)
              *page_break
            The second mage flies in alone, and after failing to locate her comrade, she's even warier than the first.  But she makes the same mistake in the end: when your Theurge-forged spear flies toward her, she's too ready to dismiss it as another weapon.  Even through the shock of being stabbed, though, this one manages to preserve her focus.  Arrows bounce off her cowl and coat alike, even as she shrieks curses at you and tries to force the speartip from her abdomen.
            
            This time, with a duel that lasts more than a few seconds, you're more aware of what you're both doing—and how quickly she would best you under other circumstances.  Each of you burns through phial after phial, struggling to overcome the other's Changes.  But she's trying to maintain her altitude as well as her armor…while also, you somehow sense, fighting hard to undo your nonexistent Change on the spear's edge.  She hasn't realized (or, perhaps, believed) that its supernatural keenness has nothing to do with you.
            
            The Theurge releases her levitation, in the end, which leaves 
            *if kal_here
              ${kalt}
            *if not(kal_here)
              Earnn
            able to catch her and put a dagger in her eye.  You barely keep the spear from lurching straight through your enemy to disembowel her attacker.  
            *if kal_here
              By the time you reach ${kalt}, ${zhe}'s retrieved the spear and
              *if deputy != kalt
                is looking at it yearningly…but after a moment ${zhe}
              offers it back to you. "Well, ${addressu}, whoever sent these to us should be happy with how we're using them."
            
            The clash emptied six of your blood phials, and you retrieve only four unused ones from the second Theurge.  "Positions," you manage to croak despite your blinding headache.  As you sink back into cover with the spear trembling in your hand, squinting at the painfully bright noon sky, you wonder if the energy you have left is enough to bring you through a third Theurgic clash.
            *set blood -2
            *set usedblood +6
            *set theirmorale -50
            *set theurges -1
            *set morale +10
            *set notoriety +10
            *page_break
            An hour passes before (to your vast relief) you conclude that no one else is going to respond; none of the rest must have been in eyeshot of the signal.  
            
            *if kal_here
              ${kalt}'s
            *if not(kal_here) and el_here
              Elery's
            *if not(kal_here) and not(el_here)
              Earnn's
            elation soon fades to a troubled frown.  "After losing two of 
            *set d2n_num theurges
            *gosub d2n
            Theurges, ${addressu}, to some unknown cause…don't expect to see any of them flying alone again.  They'll be out in twos or threes from here on out, and watchful."
            
            The thought of trying to fight two at once sends a chill down your spine.   Even though ${deputy} has a second Theurgic spear, you've no way to deploy both at the same time against airborne magi.
            *choice
              #But I still want to try bringing down a pair of them.
                Your fellow rebels glance at each other, but none feels confident in questioning your decision.  You're the only one who could have recognized the decision for what it is: hubris.
                
                Alas, by the time you learn the lesson it's of no more use to you.  The next Theurge you face is a grizzled veteran of the Halassur wars.  Though you're successful in separating her from her companion, it's at the cost of raising her suspicions; she's fully alert and catches the spear you hurl at her just before it pierces her coat.  
                
                Then, staring at the weapon, she ignites the pine rings on the shaft, reducing them to ash.  You flail mentally to levitate the steel rather than the wood…but the spear plummets from your grasp.
                
                "$!{lname}!" the enemy mage cries as you turn to flee. "This is for Arabelle!"  Your last sensation is of a roar and a blinding light; the heat is great enough that you barely feel anything at all.
                *goto_scene death
              #I don't dare.  Better to leave them slowed and watchful.
                Causing two of them to vanish without explanation is as much victory as you can expect for now.
                *if atkboth2
                  Instead, you'll see whether you can also bring down a supply train before withdrawing into the wild.
                    
                  *goto supplytrain
                *goto pullback
          "$!{addressu} ${fname},"
          *if kal_here
            ${kalt}
          *if not(kal_here) and el_here
            Elery
          *if not(kal_here) and not(el_here)
            Young Earnn
          says dubiously, "these are seasoned Theurges.  Whatever 
          *if theuknown < 5
            weaknesses of theirs you think you've reasoned out,
          *if theuknown >= 5
            you've managed to teach yourself,
          do you really think you can beat them before they burn us all?"
          
          You're by no means sure, but you still lead out a band to the north. "Just trust me, and stay quick on your feet."
            
          *gosub theuthing
          Then you focus your ${wisardry} on making
          *if aristo
            an arrow impossibly sharp, and loose
          *if helot
            a wooden spear both impossibly sharp and light as a dart, and hurl
          it at him.
          
          He starts turning before your weapon is in the air, as if he can hear or smell Theurgy at work.  And you feel something pressing back against your Change, dulling the
          *if aristo
            arrow
          *if helot
            spear
          and slowing its flight.  Even with you throwing all your ${wisardry} into increasing its momentum, it taps against the Theurge's coat without piercing it. Your
          *if aristo
            arrow
          *if helot
            spear
          spirals down to the forest floor, your enemy draws out a huge blood phial…and you tumble into the field of boulders and thorny bushes behind you, all other thoughts displaced by raw terror.
          *if kal_here and (k_rel < 5)
            *gosub martyr1
            "Aye, 
            *if k_rel = 4
              love."
            *if k_rel != 4
              ${kalt}."
            *gosub martyr2
            *set kal_here false
            *set followers -1
            *set nonkids -1
            *set dead +1
            *gosub martyrtheu
            *if atkboth2
              *gosub postmartyr
              *goto supplytrain
            *goto pullback
          *elseif simz_here
            *gosub martyr1
            "Aye, ${zmilady} de Firiac."
            *gosub martyr2
            *set simz_here false
            *set followers -1
            *set nonkids -1
            *set dead +1
            *set s_rel -30
            *gosub martyrtheu
            *if atkboth2
              *gosub postmartyr
              *goto supplytrain
            *goto pullback
          *elseif el_here and (e_rel > 9)
            *set martyr "Elery"
            *set mhe "she"
            *set mhis "her"
            *gosub martyr1
            "Aye, Skinner. I'm alive."
            *gosub martyr2
            *set el_here false
            *set followers -1
            *set nonkids -1
            *set dead +1
            *set elery -50
            *gosub martyrtheu
            *if atkboth2
              *gosub postmartyr
              *goto supplytrain
            *goto pullback
          *else
            
            Unfortunately, all the other outlaws flee as soon as they witness your failure.  There's no one to attack or even distract the Theurge when he burns away the undergrowth and flies down to hunt you.  You slither down into the crevices between boulders, desperate to evade his sight.  At first, you think you've succeeded.  Then you hear the rumble of the great stones around you—grinding together, thrown off balance, beginning to roll.  
            
            In the horrific moment that they crush you, you shriek and [i]push[/i] outward with all your might, burning all the blood that pours from your shattered body.  The boulder field becomes a great eruption of shrapnel, shredding every tree within a hundred yards.  The Theurge drops from the sky, coat still intact but a reddish mess spilling out of the gap in his cowl where his eyes had been.
            
            It's the last thing you see as your consciousness and life slip away.
            *goto_scene death
      *if plekspear
        *hide_reuse #Lure them close enough to use my Theurge-forged spear against them, one on one.
          *if pleksecret
            This is the time to reveal your and ${deputy}'s secret weapons to your band.
          *if int > 1
            You're no great warrior. The obvious way to use the spear is through 
            *if theurgy > 1
              your own 
            ${wisardry}.
            *if theurgy = 0
              *choice
                #It's time to see if Ganelon's scroll is indeed what I'd feared.
                  For all these months, you've run through the mental exercises in Ganelon's scroll until they come without effort.  Now you try to keep your breathing measured as you cut your
                  *if blood <= 0
                    palm and
                  *if blood > 0
                    palm—it would be madness to waste one of your precious phials on a venture like this—and
                  focus on the cryptic words. "I look beyond the ephemeral. I see the nature of things, their reasons for being, the final causes of all their motion…."
                  
                  You feel light-headed and intensely nauseated. Time seems to slow, and the world shimmers as if you're falling away from it; the rocks and trees around you start to look smudged and hazy. Cursing the unnaturally rapid blood loss, you try to concentrate on the clearest thing around you: the keen, wet knife with which you just cut yourself.
                  
                  The words of the litany fly through your mind: "I see that nothing comes into the world without purpose.  Fear does not cloud my vision.  I see the world without its masks.  I see myself without a mirror.  I see the ends of all things…"
                  
                  Swaying on the very edge of unconsciousness, your perceptions shift.  Your disorientation isn't you falling away from the world. Rather, you are directly sensing the world falling all around you, the stones and water striving downward and the air and fire upward, each element seeking its natural resting place in the cosmos.
                  
                  And the detachment you feel from your own body and brain is not just an impending blackout.  You can sense yourself as a maze of conflicting causes and purposes—a formidable knot to be contemplated, untangled, and retied in any way you choose.
                  
                  "And I know," you whisper, completing the litany.  "I am the nature behind nature.  I am the cause beyond the final cause.  I am a Maker of Change."  Through the dizziness and nausea, you are flooded with such delirious confidence that you almost laugh aloud.  Even though you don't understand more than a fraction of what you're experiencing, you reach out to a fallen tree, sensing the elemental fire in its boughs.
                  
                  Somehow, you encourage it in its natural tendency to rise—and the tree lifts itself from the ground.  [i]$!{oath}[/i], you think in a daze, [i]it's true.  I am a ${wisard}. I can face them[/i].
                  *set consc -1
                  *page_break
                  *goto theuexpl
                #I refuse to have anything to do with blood magic.
                  Even in so dire a circumstance as this, you're not going to start down that road.
                  *goto theunope
            *if theuknown >= 5
              *goto theuspear
            *if (theuknown < 5)
              *choice
                #But I want to keep my ${wisardry} secret from everyone.
                  *label theunope
                  Instead, you do your best to think of a way to lure them down, close enough to target them with the spears. 
                  
                  Perhaps if you had a better head for combat tactics, you'd be able to figure something out.  As it is, you conclude that you'll need to try something else—holding onto your spear for the last resort.
                  *goto theurgeatk2
                #It's time to let my powers be known to my band.
                  *if (theuknown < 5)
                    *label theuexpl
                    You do your best to explain your ${wisardry} to your outlaws the next morning.  After some initial
                    *if wisard = "Goete"
                      horror and
                    confusion, they seem ready to accept it—as they would anything that gives you some chance of success.
                    *set theurgy 3
                    *set theuknown 5
                  *goto theuspear
          *if com = 2
            The challenge, of course, is that they're usually high in the air even when swooping to make a kill.  You can see why–virtually the only weakness of a Theurge in flight is their eyes, which aren't covered by the magically impenetrable coat and cowl.  The magi wouldn't want to be anywhere low enough to be blinded by sand or brought down by a skilled archer.
            
            For your part, you've no way of hurling so heavy a spear up to a Theurge's usual height. With so long and heavy a shaft, the javelin throwing straps you've used before would lose their accuracy.  But after much thought and scouring nearby valleys for a likely ambush site, another idea comes to you.  You and ${deputy} spend the afternoon practicing and preparing, advised by a bandit who used to cut and haul timber.
            
            The next morning a Theurge flies past, bearing messages to the north—and spots smoke from a campfire, smothered just a minute too late to evade his notice.  As he swoops down, your terrified-looking outlaws flee into a stand of towering cypress, dispersing along the courses you've set for them.  The Theurge hesitates only a moment before diving under the dense upper layer of foliage in pursuit, still high enough above the ground to be safe.
            
            While he's deciding which of your scattered rebels to burn first, six arrows bounce off his coat.  As you'd hoped, that sends him hurtling vengefully toward the small, steadfast band of archers. [i]Only one chance to get this right…[/i]. You swing the Plektoi spear once, twice, with all your might. The two strokes cut through four feet of trunk, in a tree from which yesterday you chopped a deep wedge.  A few dozen yards beyond you, ${deputy} is doing the same.
            
            And just as the Hegemonic mage is willing his vitriol phial into a fireball, two mighty cypresses topple directly into his path.  Their branches clear a swathe of forest at least fifty yards wide—and though he dodges frantically, a bough smashes into him too, snagging him in a tangle of branches.  The fireburst winks out as the Theurge is slammed into the ground.  Seconds later, you reach his twitching, gasping form and plunge your spear through the eye-gap in his cowl.
            *page_break
            You manage the same ambush one more time, the next day, in a different valley.  This time, your cypress misses, but ${deputy}'s narrowly catches the Theurge, and ${dephis} spear delivers the final blow.
            *label trapnomore
            
            But after allowing your band a few minutes of full-throated rejoicing, you return them to reality. "That's two out of 
            *set d2n_num theurges
            *gosub d2n
            down…and that's as much as we can expect to get out of this trick for now, I fear.
            *if theurges = 3
              Their last one
            *if theurges > 3
              The others 
            won't know how we did it…but they'll be more cautious about anything that looks like an ambush.  Plus, they just might find the fallen trees and guess our game.  While they're still grounded and frightened, it'll slow the whole army down.  Now's the time for us to 
            *set theirmorale -100
            *set theurges -2
            *set morale +20    
            *set notoriety +10
            *if atkboth2
              hit their supplies."
              *page_break
              *goto supplytrain
            pull back and join the others."
            *goto pullback
          *else
            You spend hours trying to come up with some way to ambush a flying Theurge from the trees, before reluctantly accepting that it's unlikely to succeed.
            *goto theunope
      *hide_reuse #I've got a mad idea for a trap that just might work.
        The challenge of attacking a Theurge, of course, is that they're usually high in the air even when swooping to make a kill.  You can see why–virtually their only weakness in flight is their eyes, which aren't covered by the magically impenetrable coat and cowl.
        
        That's the main weakness you intend to exploit.
        *if com = 0
          You may not have much combat skill, but 
          *if (int = 2) or aristo
            you read something similar in a book once.
          *if (int < 2) and helot
            a trapper described something to you once that you think you can turn to your advantage.
        On the night before your ambush, you work with your raiders to prepare a stretch of pine forest, pulling a handful of springy conifers back and staking them to the ground.
        
        The next morning a Theurge flies past, bearing messages to the north—and spots smoke from a campfire, smothered just a minute too late to evade his notice.  As he swoops down, a second figure appears in the air just behind him.  "Two of them,"
        *if el_here
          Elery
        *if not(el_here)
          Earnn
        breathes at your side. "Oh, Angels."
        
        Your terrified looking outlaws
        *if com = 0
          flee back through the pines toward a ravine.  Even though you ordered them to scatter, some of them end up haplessly following the terrain back into each other. Two bursts of vitriolic fire leave many of them dead or dying, despite the damp woolen clothes you're all wearing.
          *set cas +8
        *if com > 0
          scatter as you'd practiced, and the Theurges' fireblasts claim only a few casualties (thanks in part to the damp woolen clothes you're all wearing).  The survivors make for dense forest at the foot of a cliff, or toward a brush-choked ravine in the face of the cliff.
          *set cas +2
        You stay crouched in the undergrowth, and when the magi speed toward you, you howl defiance and cut the rope binding a conifer down.  
        
        It's no catapult—you couldn't get it to fling a load of any size with accuracy.  But you've tied long ropes with spiked weights at the end to the topmost branches.  They snap up like whips, a blur of lethal motion.  And perhaps more importantly, the pine hoists a cloak-full of fine river sand into the air, making a cloud that doesn't need to be accurate to be blinding.
        
        The two magi howl and veer off course; 
        *set snapsand true
        *if el_here
          Elery
        *if not(el_here)
          Earnn
        cuts the rope on a second conifer, and the spiked rope lashes directly into one Theurge.  Though the spikes don't penetrate her coat, the force of the blow is bone-shattering.  While the mage shrieks, your archers emerge at the top of the bluff and loose arrows at her.  As you'd hoped, her concentration has suffered enough that her cowl is no longer invulnerable.  She plummets to earth, an arrowshaft in her skull.
        
        The second Theurge has recovered himself, however, and is squinting down with bloodshot eyes as if to see every remaining trap.  A flurry of fireballs confirms that he has—and the ropes and cloaks burn fast, so that even when the blackened trees still spring up, they hurl nothing but sparks.
        
        By this time, you're sprinting for the ravine yourself…but glancing back, you see the mage soaring vengefully after you.
        *if int > 1
          *choice
            #Run!
              *goto gtfu
            #Use ${wisardry}!
              *if theurgy < 2
                It's too late—never having practiced ${wisardry}, you're still trying in vain to focus your thoughts when the mage's fire consumes you.
                *goto_scene death
              *elseif (theuknown < 7)
                The surprise is all that saves you.  When he pulls out a vitriol phial to cast at you, the last thing on the Theurge's mind is that you might also be able to see and unlock its pulsing elemental fire.  
                
                Even as you ignite it, you see his eyes widen, feel the first push of mental resistance to your Change…but he's too late.  He vanishes in a bluish-white fireball from his own hand.
                *goto trapnomore
              *else
                *set blood 0
                *set consc 1
                You're brutally outmatched in a Theurgic duel—far less experience, far less blood.  For several seconds, you hold your own, snuffing out his vitriolic fireballs as he hurls them at you.  But you don't ever quite manage to take the offensive; once or twice you try to ignite the vitriol in his hand, but he mentally bats your Change away without apparent effort. 
                
                *if (cha > 0) and (morale >= inwoods)
                  *goto clifftop
                The only mercy is that you're nearly unconscious from blood loss when his bluish-white flames finally consume you.
                *goto_scene death
        *label gtfu
        You're lucky that the woolen cloak you're wearing is naturally resistant to fire. The fireball that bursts behind you is strong enough to fling you into the ravine on a wave of hot air, but it doesn't kill you, and scorches only your exposed hands and feet.
        
        Your breath comes in great, gulping sobs from terror and pain.  You scramble down into the brush, trying to find enough cover that he won't be able to see you.  But you can still see him, hovering ever nearer, coming into the gorge itself to hunt you.
        *if (cha > 0) and (morale >= inwoods)
          *page_break
          *label clifftop
          Thank ${oath}, your surviving followers on the clifftop have enough courage and loyalty to hold their positions even in the face of an enraged Theurge.  Two great felled pines with thorn-brush woven through their boughs come crashing down the ravine. You dive into a crevice just before the trees slam onto the rocks next to you.
          
          When you crawl out, covered in dust and pine-sap, you locate the Theurge by following the faint gasps of breath.  The falling trees brought him down between two great boulders; his blood phials are smashed, his neck bent at an improbable angle.  When he sees you, his face contorts with fear and grief, but his body remains inert.
          *choice
            #I put him out of his misery as painlessly as possible.
              He doesn't seem to feel your knife against the great vein in his leg.  You sit with him, aching and exhausted, for the seconds it takes his life to spill away.
              
              *goto costenow
            #I leave him to die slow.
              *set ruth %+10
              Even if they found him in time, you doubt any Theurgy exists that could save his life or restore his spine.  You turn your back on him and limp away.
              
              *goto costenow
            #I beckon my followers around to stone him to death.
              *if ruth < 60
                The cruelty of it leaves a bitter taste in your mouth, but that doesn't stop you.
              *set ruth %+20
              It's vital that your rebels lose their fear of Theurges; you want as many as possible to take part in the death of this one, to see him utterly helpless and broken.  At first a few hesitate, but soon all of them
              *if (simz_here and (simz_flank = 0))
                bar a thin-lipped ${simon} de Firiac
              are whooping and cheering as they hurl rocks down on him.
              
              He doesn't last long, of course.  The stones continue to fly nevertheless until his remains are covered by a small, blood-spattered cairn.
              
              *set morale +20
              *goto costenow
        *if (cha = 0) or (morale < inwoods)
          The silence from the clifftop suggests that your followers there have fled rather than trying to drop anything onto an enraged Theurge.
        *if kal_here and (k_rel < 5)
          
          Then you hear a howl—unmistakably ${kalt}, flinging ${zhim}self 
          *goto flingself
        *if (simz_here and (simz_flank = 0)) and (s_rel < 5)
          
          Then you see the silhouette of ${simon} flying
          *label flingself
          off the lip of the ravine to hit the Theurge in midair.  The Hegemonic mage shrieks, clearly not dreaming that he'd be attacked so recklessly from above, and flings
          *if kal_here and (k_rel < 5)
            ${kalt}
          *if (simz_here and (simz_flank = 0)) and (s_rel < 5)
            ${simon}
          away with a burst of flame.  But when you can see again, you see your enemy sinking slowly, head lolling to one side, a dagger in his eye.
          
          When you crawl out of the rocks and brush, you find
          *if kal_here and (k_rel < 5)
            your fierce young rebel
            *set kal_here false
            *set k_rel -50
          *if (simz_here and (simz_flank = 0)) and (s_rel < 5)
            your earnest young noble
            *set simz_here false
            *set s_rel -50
          unmoving on the ravine floor—body seared, neck snapped.
          *fake_choice
            *if ((k_rel+50) = 4) 
              #I clutch at ${kalt}, weeping, unwilling to accept that ${zhis} passion could be so easily snuffed out.
            #Ah, ${sweetoath}.  We needed ${zhim} for more than this.
            #I pull myself to my feet and give a shaky salute. $!{zhe} cared enough to save my life when no one else would.
            *if (((k_rel+50) != 4) and (deputy = kalt)) or (deputy = simon)
              #To lose another deputy just before the great battle will shake the band's morale.
            #There's no time for sentimentality, even with such a sacrifice as this.
            *if ((k_rel+50) != 4) 
              #I didn't like ${zhim}, and I'm not going to pretend I did, even though ${zhe} saved my life.
          *label costenow
          *if ((deputy = kalt) and (k_rel < 0)) or ((deputy = simon) and (s_rel < 0))
            All the other survivors of the attack are gathering around you.  The band needs to know quickly who your second in command will be, now that ${deputy} is gone.
            *choice
              *if (zv_here)
                #Zvad.
                  *set deputy "Zvad"
                  *set dephis "his"
                  *set dephe "he"
                  *set zv_lead +1
                  *if (zv_flank < 1)
                    "Aye, ${addressu}," Zvad rumbles when you ask him. "I'll be your right hand."
                  
                    *goto costenow2
                  *else
                    You'll tell Zvad once you're back in the same place—always assuming he survives his own mission.
                    
                    *goto costenow2
              *if (el_here)
                #Elery.
                  She grimaces when you ask her, gazing at ${deputy}'s broken form.  But after a few moments, she nods mutely.
                  *set deputy "Elery"
                  *set dephis "her"
                  *set dephe "she"
                  *set el_lead +1
                  
                  *goto costenow2                  
              *if (rad_here)
                #Radmar.
                  *set dephis "his"
                  *set dephe "he"
                  *set rad_lead +1
                  *if (rad_flank < 1)
                    "I'll do it," Radmar growls when you ask, and gives a curt nod at ${deputy}'s broken form. "But don't expect that from me, eh, ${addressu}?"
                    *set deputy "Radmar"
                    
                    *goto costenow2
                  *else
                    You'll tell Radmar once you're back in the same place—always assuming he survives his own mission.
                    *set deputy "Radmar"
                    
                    *goto costenow2
              #Alira.
                *set deputy "Alira"
                *set dephis "her"
                *set dephe "she"
                *if (al_flank < 1)
                  Alira gives a brisk, unsmiling nod. "Aye, ${addressu}.  I'll serve as your second."
                  
                  *goto costenow2
                *else
                  You'll tell Alira once you're back in the same place—always assuming she survives her own mission.
                  
                  *goto costenow2
          *label costenow2
          "That's cost enough for the gain we've seen," you rasp to the other surviving bandits. "With two of 
          *set d2n_num theurges
          *gosub d2n
          Theurges fallen, the rest will be slowed down—but they won't so easily be trapped.  Let's be 
          *set theurges -2
          *set notoriety +10
          *set theirmorale -100
          *if atkboth2
            off after the supply train while they're still looking for us here."
            *page_break
            *goto supplytrain
          off and rejoin the rest."
          
          You get no argument from anyone else in the terrified raiding party.
          *goto pullback
        With no one daring to come help you, it is only a few minutes before a vitriol phial clinks to the ground at your feet—and the world disappears in bluish-white light.
        *goto_scene death
      *hide_reuse #The only thing I can think of is trying to get a few good fighters into the Theurges' tent by night—and they almost certainly wouldn't be coming back.
        When you raise the possibility, no one volunteers.  Even the most desperate rebel needs some prospect of success if they're going to throw their life away.
        
        You could easily put a few rebels into the sashes and clothes of a fallen noble retainer…but you've all seen that the Phalangites' guard on the camp perimeter is meticulous, especially after dark.  Any attempt to join the main force during the day would greatly increase the odds of being challenged by a fellow fighter.  
        
        Even assuming someone got inside without raising an alarm, the camp is well lit, with a robust internal watch round the center where the Theurges, Tagmatarch, and top nobles sleep.  An assassin would need to reach the Theurges' tent without waking a single mage—so there could be no distractions, no feints to draw away the guards, and the killings would need to be both swift and silent.
        
        In other words, there's every likelihood that an infiltrator would die long before they had the chance to strike at a mage, let alone all of them. "They know that an attack on their Theurges would cripple them, ${addressu},"
        *if el_here
          Elery
        *if not(el_here) and (korszata > 0)
          Korszata
        *if not(el_here) and (korszata = 0)
          Young Earnn
        points out bleakly. "Every mile they press into the wilderness, they need their magi more.  And when they've pinned us down and want to blast us or chase us into the Phalangites' arms, they'll need them most of all.  They'll put everything they have into guarding them."
        
        "I know what we're asking.  I know how unlikely it is."  You let some of your growing despair leak into your voice.  "But if no one is willing to make the sacrifice…then we'll all likely die."
        *if religion > 0
          As soon as the words leave your mouth, you feel a giddy disorientation.  How many times had you heard that message from the Naos or at a Harrowing?  All of you were raised to believe it; all of you are vulnerable to it.
          *choice
            *if (eclect) #I appeal to them as the Angels' Eclect, setting their minds on their Elysian reward.
              "You've recognized the truth that the Angels have Chosen me," you say to your raiders with quiet authority. "And I tell you in Their name that if none of us makes the attempt, this rebellion will fail.  
              
              "Even if the Theurges spare us, a rebellion in which no one is willing to sacrifice themselves for the Angels' cause cannot hope for Their blessing.  We may call ourselves servants of Xthonos. We may say that we count our earthly lives cheap in comparison with the eternal joys of Elysia.  But what is that worth unless our actions confirm our words?"
              
              After a long silence, 
              *if (simz_here and (simz_flank = 0)) and (s_rel < 5)
                ${simon} de Firiac steps forward, chin raised and trembling only slightly. "You speak the truth, ${addressu} ${lname}.  I accept this charge from the Angels, and offer my life to Their glory and to whatever fate Almighty Xthonos has decreed."
                *choice
                  #No.  I forbid it.
                    "The Angels will reward you for your selflessness, 
                    *if zhim = "him"
                      ${addressm}
                    *if zhim = "her"
                      ${addressf}
                    de Firiac."  You beam at ${zhim} for a few moments, then add gently, "But They do not yet accept your sacrifice.  Your skills are needed to serve the rebellion in greater battles to come.  Another will have been called to this task—not you."
                    
                    ${simon} looks inclined to protest, but swallows it. "By your authority, Eclect of the Angels."  For a moment, you fear no one else will volunteer.  Then
                    *goto civsfail
                  #"Glory to the Angels for inspiring such selflessness."
                    *label simzicide
                    You embrace ${simon} and trace an Angelic spiral on ${zhis} bowed head…
                    *fake_choice
                      #…wishing someone else had been inspired to make the sacrifice.  The de Firiac's skills will be no small loss to the band.
                      #…choking back a grief that goes deeper than I'd expected. Losing ${simon} will be a lasting hurt—and it's one I've inflicted on myself by inspiring ${zhim} to die.
                      #…elated that someone has volunteered who has the skills to actually succeed.
                      #…uneasy at the power of life and death I've claimed over my followers.
                    *label simzicide2
                    *set martyr simon
                    That night, ${zhe} makes it past the palings.  It's no challenge for ${simon} to sound like ${zhe} belongs with the other Rimmer nobles.  With ${zhis} scavenged omphalos sash, you can readily imagine ${zhim} passing off ${zhis} injuries from the past week as the result of a bandit ambush, and limping in to search for healing.
                    *gosub martyrdin
                    de Firiac, martyr of the Angels, whose sacrifice was accepted in order to save us.  Weep, and never forget ${zhim}, or the 
                    *set d2n_num theurges
                    *gosub d2n
                    Theurges ${zhe} slew."
                    *achieve martyrmaker
                    *set notoriety +30
                    *set s_rel -50
                    *set simz_here false
                    *set theirmorale -(theurges*50)
                    *set theurges 0
                    *if atkboth2
                      *page_break
                      Despite your eulogy, you know there's no time for the band to grieve ${martyr}.  Now is the best chance you'll get to win—by cutting off supplies to the suddenly isolated Phalangites.
                      
                      *goto supplytrain
                    *goto pullback
              *label civsfail
              two of the outlaws step forward at the same moment. You embrace them, proclaim them blessed of the Angels, and prepare them as best you can for their mission.
              *gosub martyrfail
              "Angels reward them," you say hoarsely, as several of your outlaws begin to weep. "They gave themselves for us and the rebellion.  They are heroes and martyrs of Xthonos."  Then as the first Theurges begin to circle outward from the camp like enraged hornets, you cut off your eulogy and flee for the trees.
              *if (simz_here and (simz_flank = 0)) and (s_rel < 5)
                
                "I could have done it, ${addressu}." ${simon} says it only once, after the pursuit has died down. "If it had been me in that camp, those Theurges would have been the ones to die."
                
                "The Angels are saving you for greater things," you reply, thick-voiced, hoping it's true. "Have faith that this will serve Their plan."
              *if atkboth2
                *page_break
                Having failed to wipe out the Theurges, it's all the more vital that you successfully cut off the Phalangites' supplies.
                
                *goto supplytrain
              *goto pullback
            *if ((religion < 20) and (religion > 10)) #I ask them to listen to the voice of the Angels in their hearts.  Is anyone being called to sacrifice themselves for an Elysian reward?
              *if religion = 11
                "I've heard the Angels, ${addressc}…telling me that They're going to call someone in this band to make the greatest sacrifice," you declare with pious certainty.
              *if religion > 11
                "Surely the Angels will have inspired someone in this group to save us," you say desperately.
              "Still your hearts, and listen.  Set your minds on the things above, not those of earth.  Remember the joys of Elysia, which so vastly outweigh any earthly suffering.  And tell me: is no one truly called to make this sacrifice?"
              
              After a long silence, 
              *if (simz_here and (simz_flank = 0)) and (s_rel < 5)
                ${simon} de Firiac draws a quavering breath and turns to you, ${zhis} eyes haunted but certain. "$!{addressu}…I hear Them calling me."
                *choice
                  #No.  I forbid it.
                    ${simon} stares at you for a long moment, then shakes ${zhis} head, a sad smile piquing ${zhis} lips. "Who are you to question what the Angels have told me, ${addressu}?  Listen again, but I know what I hear."
                    
                    *goto simzicide2
                  #"Glory to the Angels for inspiring such selflessness."
                    *goto simzicide
              *goto civsfail
            *if (religion > 19) #I appeal to them to empty themselves and reflect on our plight in the cool of kenon.
              "There's a destructive selfishness in every human mind, ${addressc}—that voice that screams, [i]Damn the whole world, as long as I draw one more breath[/i]."  You cast your eyes again around the circle, holding your followers' troubled stares. "Let it go.  Recognize it, set it aside…and in the emptiness of kenon, weigh the truth of the matter.  What does one person's life matter, when by their sacrifice they might save hundreds—might indeed save the rebellion that will set
              *if natl > 49
                all Shayard
              *if natl < 50
                the whole world
              free?  How would you judge the matter if the one life weren't your own?"
              
              After a long silence,
              *if (el_here)
                Elery steps forward.  It takes her two tries before her throat is moist enough to speak.  "You're right, ${addressu}.  If we don't look at it selfishly, one of us has to do it.  Someone who has a decent enough chance of getting them all."
                *choice
                  #No.  I forbid it.
                    Elery raises an eyebrow, her 
                    *if e_rel <= 9
                      lips trembling. 
                    *if e_rel > 9
                      glare still ferocious despite her trembling lips. 
                    "On what grounds?"
                    
                    "We'll have more need of your skills in the great battle to come…."
                    
                    She cuts you off with a sharp shake of the head.  "Ah, ${kuria}.  Get yourself back to kenon.  If there are still 
                    *set d2n_num theurges
                    *gosub d2n
                    Theurges with the Phalangites when they reach us, it won't make a jongler's damn of difference whether I'm with you or not.  Seen in the light of reason, this is our chance—our one chance.  And I'm the one to take it."
                    
                    *goto elicide
                  #"If it's what you feel in the cool of kenon…."
                    An awed murmur goes around the raiding party in honor of Elery's selflessness.  You bow to her…
                    *fake_choice
                      #…wishing someone else had been inspired to make the sacrifice.  Elery's skills will be no small loss to the band.
                      #…choking back a grief that goes deeper than I'd expected. Losing Elery Skinner will be a lasting hurt—and it's one I've inflicted on myself by inspiring her to die.
                      #…elated that someone has volunteered who has the skills to actually succeed.
                      #…uneasy at the power of life and death I've claimed over my followers.
                    *label elicide
                    *if ((zv_here and (zv_flank = 0)) and (elezvad > 6))
                      Zvad leaps forward, eyes wide in dismay.  "$!{addressu}—send me instead.  My experience…"
                      
                      "Hush, you great ox," Elery snaps, pain stark on her face. "You think there's a Wiend anywhere in that camp?  You could wear Phalangite armor and carry a letter from the Archon herself, and they'd still never let you past the palings."  Her hand whips out to cover Zvad's lips, interrupting whatever he might have said next. "[i]You[/i] are going to [i]live[/i]."
                      
                      *if korszata > 0
                        Zvad clutches at her fingers, turns desperately to Korszata.  "Phalangite armor!  We have some, and it wouldn't fit you, Skinner.  I could…"
                        
                        The former soldier shakes his head, looking mournful. "A poor disguise, clan-cousin.  The Archon's Phalangites disdain the rabble who march at their heels, but they will know each other, and where each one should be.  Few if any would be Wiendish.  And a Phalangite out of place would raise an immediate alarm."
                        
                      After a moment, Zvad's shoulders slump with acceptance and he returns to a crouch, not meeting anyone's gaze. Elery's lips vanish into a thin line; tears glint unshed in her eyes.
                      *page_break
                    *set martyr "Elery"
                    As the Phalangites make camp that night, Elery is intently watching their every move. "Well, I've got a path in mind, ${kuria}," she tells you with forced briskness as she dons the omphalos sash and cloak of a fallen noble hireling. "One that should get me seen by as few guards as possible.  Fewer questions to answer.  And I reckon they've left just enough trees up in the middle of camp that someone quick enough has a chance at keeping to the shadows.  Most of the time, anyway."
                    
                    Staring down at the brightly firelit encampment, you find it hard to imagine what she's talking about…but whether she's right or wrong, you don't want to sow any doubts now.  "Good fortune to you, Elery Skinner."
                    
                    "And almighty kenon bless you too, ${kuria} ${fname}."  Elery's smile is wry, with terror barely contained underneath.  "Or good swiving luck, anyway.  Wherever it comes from."
                    *gosub martyrdin
                    Skinner, first martyr of kenon.  Who slew 
                    *set d2n_num theurges
                    *gosub d2n
                    Theurges because she had purged her fear into emptiness.  Weep, and never forget her."
                    *achieve martyrmaker
                    *set theirmorale -(theurges*50)
                    *set theurges 0
                    *set notoriety +30
                    *set elery -50
                    *set el_here false
                    *if atkboth2
                      *page_break
                      Despite your eulogy, you know there's no time for the band to grieve ${martyr}.  Now is the best chance you'll get to win—by cutting off supplies to the suddenly isolated Phalangites.
                      
                      *goto supplytrain 
                    *goto pullback
              two of your outlaws step forward at the same time.  One says in a resigned, trembling voice, "I'd want someone to say yes. Reckon that someone might as well be me."
              *gosub martyrfail
              "We will remember them," you say hoarsely, as several of your outlaws begin to weep. "They gave themselves for us and the rebellion.  Our fallen heroes, who showed the enemy they are not safe even in their tents."  Then as the first Theurges begin to circle outward from the camp like enraged hornets, you cut off your eulogy and flee for the trees.
              *if atkboth2
                *page_break
                Having failed to wipe out the magi, it's all the more vital that you successfully cut off the Phalangites' supplies.
                
                *goto supplytrain
              *goto pullback
            #No.  I'm not going to be like the Ecclesiasts, calling for self-sacrifice in the Angels' name.
              Without an appeal to 
              *if religion > 19
                kenon,
              *if religion < 20
                the Angels,
              your desperate suggestion fails to convince anyone.
              *goto nosuicide
        Though no one would argue, your appeal rouses only pained shrugs.  
        *label nosuicide
        No one is willing to kill themselves for a near-certainty of failure.
        *page_break
        *if not(atkboth2) and not(atkboth)
          *goto week2harry
        *if atkboth2
          *page_break
          Having failed to wipe out the Theurges, it's all the more vital that you successfully cut off the Phalangites' supplies.
                
          *goto supplytrain
        *goto pullback
  #Attack the supply train, then the Theurges.
    *set atkboth true
    *goto supplytrain
  #Attack the Theurges, then the supply train.
    *set atkboth2 true
    *goto theurgeatk
  *if (strategy > 1) 
    #Attacking either would be too risky.  I'm not trying to defeat the Phalangites.
      You just want to evade them and inflict enough pain that they eventually decide to leave.
      *goto week2harry
  *if (strategy = 1) 
    #Attacking either would be a catastrophe. I'll stick to harrying the main Phalangite force.
      *goto week2harry

*label week2harry
*set harrytick true
In your second week of ambushes, you continue to whittle down the enemy.
*gosub harrycas
But the Theurges are getting better at intercepting your strikes before they start.
*if theuknown >= 10
  They're flying in pairs, and you think they're keen to catch the rebels' ${wisard} leader.
*set cas +(10+((theurges-3)*8))
*if cas > (rangers-5)
  *set cas (rangers-5)
  *if cas < 3
    *set cas 3
  *set harryloss true

*gosub troopscheck
but the 
*if (phal3 > 0) and (phal4 = 0)
  three
*if (phal4 > 0) and (phal5 = 0)
  four
*if (phal5 > 0)
  five
Phalangite factions are closing the net around you.

*if (strategy = 2) or ((strategy = 3) and (theirintel < 1))
  In an encouraging note, your scouts report that several of the non-Phalangite squadrons appear on the verge of breaking.  The Hegemonic infantry have refused to slow their pace, forcing the others to keep up or fall behind and risk being picked off by a bandit ambush.  The unrelenting march through the wilderness has reduced everyone who isn't a soldier to exhaustion.
  
  "They know they're only being attacked by a few of us, ${addressu}," Earnn says. "So they're bent on finding the rest of us."  
  *set theirmorale -50
  *if (strategy = 3) and (inwoods < 30)
  
    You manage a strained laugh. "When they learn that most of us are already in the Rim, I think our
    *if alastroops > 0
      Alastor
      *if aristroops > 0
        and
    *if aristroops > 0
      noble
    *if (aristroops < 1) and (alastroops < 1)
      commoner
    friends will have some hard words for the Phalangites."
  
  *goto w2cas
*else
  The Phalangites have slowed their pace of their advance to respond to your ambushes.
  *goto w2cas
*label w2cas
You lose 
*set d2n_num cas
*gosub d2n
rebels in the second week.  It's time
*if harryloss
  for your battered handful of survivors
to pull back to rejoin the rest of your band.
*label pullback
*gosub armscheck
*gosub cascheck
*page_break
*if (strategy > 1) or (flanktroops = 0)
  *goto pullback2
On your way back to the deep wilderness, you meet up with the other retreating raiders.
*if zv_flank > 0
  *set cas +round(zv_flank/9)
  *set cas +round(zv_flank*(1-armshare))
  *set cas +round(zv_flank*(1-morshare))
  *set phalcas round(zv_flank*2)
  Zvad is being half-carried back by the survivors of his band, blood streaking his face and chest.
  *if (elezvad > 4) and el_here
    Elery runs to his side, her face twisted with alarm until he manages a reassuring grin.
  "Well, ${addressu}," he says thickly to you, "I've been wrong so far, but not by much.  Don't think I'll be of much use here on out.  There's 
  *set d2n_num phalcas
  *gosub d2n
  fewer Phalangites coming our way, at least."
  *if (elezvad > 4) and ((elery+300) < 0)
    His face lightens to the color of old ash when he hears of Elery's death. "For swiving kenon?" he rasps, barely audible. "She did it for…"
    
    "For us, Zvad," you cut in sternly.  You'd known Zvad wasn't a particularly passionate kenonist, but there's something in his tone you don't like the sound of. "For you. Don't make less of it."
  *gosub phallocate
*if rad_flank > 0
  *set phalcas round(rad_flank*1.5)
  *if phalcas > 55
    *set phalcas 55
  *set cas +round(rad_flank/7) 
  *set cas +round(rad_flank*(1-armshare))
  *set cas +round(rad_flank*(1-morshare))
  Radmar grimly insists that he
  *if poric > 0
    and Poric
  *if poric < 1
    and his bandits
  won a great victory, with
  *set d2n_num phalcas
  *gosub d2n
  Phalangites dead.  He doesn't speak at first about how many he lost along the way.
  *gosub phallocate
*if bj_flank > 0
  *set phalcas round(bj_flank*5)
  *if phalcas > 55
    *set phalcas 55
  *set cas +round(bj_flank/13)
  *set cas +round(bj_flank*(1-armshare))
  *if korszata > 0
    Bjel and his 
  *if bethune > 0
    Bethune and her 
  haggard-looking band say little when they rejoin you—save to expect no more than a handful of Phalangites approaching from their direction.  Their tired eyes gleam with satisfaction.
  *gosub phallocate
*if simz_flank > 0
  *set phalcas round(simz_flank*7)
  *if phalcas > 55
    *set phalcas 55
  *set cas +round(simz_flank/7) 
  *set cas +round(simz_flank*(1-armshare))
  *set cas +round(simz_flank*(1-morshare))
  ${simon} and ${zhis} yeoman archers report back with tales of ambush after ambush, luring 
  *set d2n_num phalcas
  *gosub d2n
  Phalangites to their doom. 
  *gosub phallocate
*if br_flank > 0
  *set phalcas round(br_flank*1.3)
  *if phalcas > 55
    *set phalcas 55
  *set cas +round(br_flank/5) 
  *set cas +round(br_flank*(1-armshare))
  *set cas +round(br_flank*(1-morshare))
  Breden returns with a battered but enthusiastic raiding party, boasting that they felled 
  *set d2n_num phalcas
  *gosub d2n
  of the enemy.
  *gosub phallocate
*if al_flank > 0
  *set phalcas round(al_flank*1.8)
  *if phalcas > 55
    *set phalcas 55
  *set cas +round(al_flank/7) 
  *set cas +round(al_flank*(1-armshare))
  *set cas +round(al_flank*(1-morshare))
  Alira and her hunters return with wearily determined faces. "We've whittled them down a bit, ${addressu}.  Hope you did the same with the main force."
  *gosub phallocate
*if meh_flank > 0
  *set phalcas round((meh_flank*1.1)/(flanktotal-phaltick))
  *if phalcas > 55
    *set phalcas 55
  *label mehflank
  *if flanktotal > phaltick
    *gosub phallocate
    *goto mehflank
  *set cas +round(meh_flank/5)
  *set cas +round(meh_flank*(1-armshare))
  *set cas +round(meh_flank*(1-morshare))
  *if (((al_flank+br_flank)+(simz_flank+rad_flank))+(bj_flank+zv_flank)) > 0
    The other raid leaders you sent report back from their attempts.
*if armshare < 0.9
  All have similar complaints about trying to face Phalangites without enough steel arms.
*if morshare < 0.9
  The band's struggling morale seems 
  *if armshare < 0.9
    also to have contributed to their 
  *if armshare >= 0.9
    to have contributed to widespread
  losses.
*if theirintel > 5
  *set cas +(flanktotal*4)
*if cas > (flanktroops-6)
  *set cas (flanktroops-6)
All told, you have lost 
*set d2n_num cas
*gosub d2n
rebels in your attacks against the flanking forces.
*gosub armscheck
*gosub cascheck
*if theirintel > 5

  "They know too much about us," ${deputy} says bleakly after listening to all the stories.  "They knew names of a few bandits, and were too well prepared for the tactics we'd be using to fight 
  *if bj_flank = 0
    them."
  *if bj_flank > 0
    them.  All except 
    *if korszata > 0
      Bjel and his ex-Phalangites.  
    *if bethune > 0
      Bethune and the Westriding rebels.
    That, they don't seem to have expected."
  
  "What do you make of it?" you ask, knowing the answer.
  
  "Word got out to them, somehow.
  *if bj_flank > 0
    From before 
    *if korszata > 0
      Korszata and Bjel arrived.
    *if bethune > 0
      the Cabel yeomen joined us.
  A traitor, ${kuria}."
  *if (deputy = "Zvad") or (deputy = "Breden")
    ${deputy}'s face is starkly furious. "All our work to catch them out…and we've not been able to stop them."
  *if ((deputy = "Radmar") or (deputy = kalt)) and (breden = 16)
    $!{dephis} face is starkly furious. "And we know who that was, don't we, ${addressu}?"
*label pullback2
*set phalangites ((((phal1+phal2)+phal3)+phal4)+phal5)
*gosub alltcheck
*if (strategy = 3) and (inwoods > 42)
  When you return to your camp, you find that all in all, another twenty-two of your followers have crept out toward the Norther Rim to try their luck infiltrating the helot camps.  You hope your intelligence on the location of the Phalangites was good enough that they won't be caught.
  *set inwoods -22
  *if intel >= 25
    *set helcamp +22
    *set inadults -22
    *if inkids > 13
      *set inkids -12
      *set outkids +12
      *set inadults +12
  *if intel < 25
    *set followers -22
    *set nonkids -22
    *set inadults -22
    *if inkids > 13
      *set inkids -12
      *set outkids +12
      *set inadults +12
      *set nonkids +12
      *set kidsdead +12
    *set dead +22
    
  
*if (theirmorale >= (alltroops/3)) and (supplycut = 0)
  You don't have much time.  The Phalangites march nearly as fast as you do. Soon they'll be on you.  Your outlaws press as hard as they can from dawn to dusk, and slowly widen the gap between you and the enemy soldiers.  
*if (theirmorale < (alltroops/3)) or (supplycut > 0)
  *set morale +20
  The Phalangite forces are paralyzed 
  *if supplycut = 0
    after your attacks, 
  *if supplycut > 0
    by the loss of supplies, 
  giving you two weeks to
  *if strategy = 1
    regroup and consider your next move.
  *if strategy > 1
    recover and hide yourselves.
  *set consc 4
  *if theurges < 2
    With all
    *if theurges = 1
      but one of
    their magi dead, you 
  *if theurges >= 2
    You
  ask Alira what she thinks of starting a forest fire upwind of their camp.  
  *if theurges < 2
    They would struggle to extinguish it without Theurgy.
  *if theurges >= 2
    The Theurges would extinguish it, but it would force them to spend more blood and pull them away from hunting you.
    
  Your chief tracker nods warily.  "It could 
  *if theurges < 2
    break 
  *if theurges >= 2
    distract
  them, ${addressu} ${lname}, no doubt of that.  But it could easily run out of all control.  There's more brush this summer than usual, thanks to the good rains and the deer-pest last year.  
    
  "So we could end up caught in a great blaze…and even if we kept ahead of it, it could clear out a good swathe of cover between us and the Rim.  Leave a lot of stumps and leafless trees.  Make it harder if we needed to slip round them in a week or two without being seen."
  *choice
    #I order my rangers to set the forest ablaze.
      *if sacrament = 3
        "We ascend, ${addressu}," they murmur at once, in the words of your new sacrament. "We are fire."
        
      *set fire true
      *set cas +round(inadults/22)
      *if inkids > 11
        *set cas +round(inkids/22)
      *if cas < 2
        *set cas 2
      Two days later, you see a broad smudge darkening the eastern horizon.  At first, your outlaws cheer fiercely.  But the great smoke cloud moves closer and closer to you, and by the third day you can see the flames consuming.  All your efforts go into keeping a few miles ahead of the conflagration.  
        
      The summer winds can be strong and unpredictable, and the flames frequently jump from ridge to ridge, catching scouts and hunters off guard and nipping at the heels of your fleeing outlaws.  
      *if theurges >= 2
        The enemy Theurges constantly appear in the sky, trying to break the fire's momentum with landslides, pulling streams from their beds to spray the blaze.  One mage hovers in the air for hours, a barely visible speck, before clouds appear on the horizon from all sides and come swirling around her.
      By the time the great fire finally subsides in a downpour, 
      *set d2n_num cas
      *gosub d2n
      of your followers
      *if inkids > 11
        *if (inkids > 76)
          (including several children)
        *if (inkids > 54) and (inkids < 77)
          (including three children)
        *if (inkids < 55) and (inkids > 32)
          (including two children)
        *if inkids < 33
          (including a child)
      are dead.
      *gosub cascheck
      *if inkids > 11
        *set nonkids +round(inkids/22)
        *set kidsdead +round(inkids/22)
        *set inkids -round(inkids/22)
        *set morale -round(inkids/11)
        
      Within a few days, your surviving scouts return to report that the Archon's forces
      *if theurges > 0
        would have
      lost a quarter of their number to the fire,
      *set aristroops -round(aristroops/4)
      *set alastroops -round(alastroops/4)
      *set priestroops -round(priestroops/4)
      *set yeotroops -round(yeotroops/4)
      *set phal1 -round(phal1/4)
      *set phal2 -round(phal2/3)
      *set phal3 -round(phal3/4)
      *set phal4 -round(phal4/5)
      *set phal5 -round(phal5/6)
      *set theirmorale -round(alltroops/4)
      *if theurges > 0
        if it hadn't been for the remaining 
        *if theurges = 1
          mage, who was 
        *if theurges > 1
          magi, who were
        able to keep half of the camp intact.  They still lost many fighters,
        *set aristroops +round(aristroops/8)
        *set alastroops +round(alastroops/8)
        *set priestroops +round(priestroops/8)
        *set yeotroops +round(yeotroops/8)
        *set phal1 +round(phal1/8)
        *set theirmorale +round(alltroops/8)
      and the survivors are vengeful but clearly shaken.
      *gosub their0check
      *gosub alltcheck
        
      According to your scouts, there are 
      *set d2n_num allmain
      *gosub d2n
      fighters left in the main force, 
      *if allmain = phal1
        all
      of whom 
      *if allmain != phal1
        *set d2n_num phal1
        *gosub d2n
      are Phalangites.  How many survived in the flanking forces, you have no way of knowing.
      *if supplycut = 3
        *set supplycut 5
      *goto toheal
    *if (strategy = 1) #No.  I won't take the risk of it spreading.  I'll just send bands to harry them some more instead.
      Two-thirds of your surviving bandits take to the woods with you around the stationary Phalangite army.  Though many of the disheartened enemy keep behind the palisade, they need to hunt to feed themselves in the wild, and their hunting parties are vulnerable to your arrows and sling stones.
      *set rangers round(inadults*2)/3
      *set aristroops -round(rangers/10)
      *set alastroops -round(rangers/10)
      *set priestroops -round(rangers/8)
      *set phal1 -round(rangers/12)
      *set theirmorale -round(rangers/10)
      *if (strategy = 1) and (popular != 10)
        *set aristroops -round(rangers/10)
        *set alastroops -round(rangers/10)
        *set priestroops -round(rangers/8)
        *set phal1 -round(rangers/12)
        *set theirmorale -round(rangers/10)
      *if com > 1
        *set aristroops -10
        *set alastroops -10
        *set phal1 -10
        *set theirmorale -10
      *if korszata > 0
        *set aristroops -8
        *set alastroops -8
        *set phal2 -8
      *if el_here
        *set aristroops -8
        *set alastroops -4
        *set yeotroops -4
        *set phal3 -7
      *if rad_here
        *set aristroops -5
        *set phal4 -5
      *if zv_here
        *set alastroops -3
        *set aristroops -3
        *set phal5 -3
      *if kal_here
        *set aristroops -4
        *set phal1 -4
      *if simz_here and (s_rel < 9)
        *set alastroops -7
        *set yeotroops -7
        *set phal1 -7
      *gosub their0check
      *gosub alltcheck
      *set cas +round(rangers/10)
      *if theurges > 0
        *set cas +(12*theurges)
      *if cas > (inadults-20)
        *set cas (inadults-20)
      You lose
      *set d2n_num cas
      *gosub d2n
      outlaws in fierce clashes with the enemy
      *if theurges > 0
        Theurge and
      troops, but kill enough that by the end of the week, the main force is down to 
      *set d2n_num allmain
      *gosub d2n
      troops.  You don't know how many remain in the flanking forces.
      *gosub armscheck
      *gosub cascheck
      *goto toheal
    *if (strategy > 1) #No.  I won't take the risk of it spreading.  I'll withdraw deeper into the woods instead.
      Best to put as much distance between you and the disheartened Phalangites as you can, while you can.
      *goto toheal
  *label toheal
  
  *if (supplycut < 5) and (theurges > 1)
    *goto doggedly
  *if (limb > 0)
    As you travel through the woods, 
    *gosub healingem
  *set lostem true
  *goto campblurb
*label doggedly
*if limb > 0
  
  Despite your exhaustion,
  *gosub healingem
But 
*if allmain > 25
  the main army is still doggedly on your heels, while
*if allmain <= 25
  even though you've all but destroyed their main force,
*if (phal5 > 0)
  four
*if (phal4 > 0) and (phal5 = 0)
  three
*if (phal3 > 0) and (phal4 = 0)
  two
other flanking forces are converging on the ever-smaller set of valleys where you can be hiding.
*if alltroops > (inadults+50)

  Having seen the scale of the forces hunting for you affects the whole band's morale. "There's still too many of them, ${addressu}," 
  *if c_rel > 0
    Ciels 
  *if c_rel = 0
    Young Earnn
  says hoarsely, "and they're right on top of us."
  *set morale -round(alltroops/10)
*label threadneedle

*if choice_randomtest
  *choice
    #At threadneedle, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.  ${inwoods} inwoods, ${inadults} inadults, ${inkids} inkids, ${morale} morale.
      *goto postchoice7
*label postchoice7
*set kidcas 0
*if consc < 4
  *set consc +1
After several days' retreat, ${deputy} once again pulls you aside with news from the scouts. $!{dephis} face is strained, ${dephis} eyes unblinking.  "Now's the time, ${addressu} ${fname}. Their flanking forces have closed in enough that we know where they all are." 

$!{dephe} sketches a quick map in the dust. "We're as sure as we can be that we won't run into enough Phalangites to block us.  This is the only chance we'll have to thread the needle—to slip between their forces and run free in the deep woods again, before they trap us against the Ward."

You consider the lines ${deputy}'s scraped on the ground and what they mean for you.  If you succeed, the Phalangites will either lose your trail entirely or be left tracking your nimbler band from increasingly far behind, with no flanking forces to pin you down.  Either way, it would only be a matter of time before they had to give up and return to the Rim.  

If you fail…best not to think about failing.
*choice
  #We'll march through the night.  There's just enough moonlight, and their Theurges and scouts will be abed.
    You set off at dusk, bearing to the northeast.  At the head of the band, Earnn and Alira guide you up onto the exposed ridge which—if all goes well—should bring you between the 
    *if allmain <= 25
      flanking forces,
      *goto flankleaving
    main army and 
    *if phal4 = 0
      the 
    *if phal4 > 0
      a
    northern flanking force, 
    *label flankleaving
    leaving you with a free run all the way to the Owlscap and beyond.
    *if (strategy = 2) and (popular != 10)
      And your preparations pay off.
      
      For an hour, your 
      *set d2n_num inwoods
      *gosub d2n
      bandits creep through woods faintly illumined by the firelight of the main Phalangite host far below.  You flinch every time you hear a stick snap underfoot, and stay braced for the scream or bray that will bring the Theurges out to hunt you.  But your mules stay calm, because your outlaws stay calm. You've been on midnight runs with far rougher terrain and worse visibility.
      *if ((int > 1) or (el_here)) or (inwoods < 44)
        *set lostem true
        
        *if inwoods < 44
          You're few enough to keep
        *if ((int > 1) or (el_here)) and (inwoods > 43)
          Moreover, thanks to
        *if int > 1
          your
        *if int < 2
          Elery's
          *set el_lead +1
        finger-to-palm signals and agreed marching order, your band keeps relatively close together through the long night.  
        *label bydawn
        By dawn, you regroup for a silent fastbreaking. It takes less than half an hour for everyone to eat, and then you press on again (save a few scouts who hold back to see if you're being followed).  Only by mid-afternoon, with no Theurges having appeared overhead all day, do you wearily make camp.
        
        "They're scouring the area they thought they had us trapped in, ${addressu}," Alira reports when she arrives later that day, eyes heavy-lidded but satisfied. "We've got clean away from them.  Our safest camp isn't far from here.  Tomorrow we'll climb up there; there are caves where we can rest properly."
        *goto campsite
      *else
        
        By dawn, you're miles from the Phalangites.  You break your fast while waiting for everyone in the band to catch up to you. When the last few have eaten, you press on to the north.  Only a few scouts hang back to see if you're being followed.
        
        Your heart sinks a little further with each Theurge you spot flying overhead during the rest of the day, even though you think you manage to evade their notice.  
        *label exhaulira
        An exhausted Alira confirms your fears that evening.  "A few of their early scouts spotted a few of our last stragglers.  They know which way we're headed, and all their force is coming after us."  
        *label howclose
        
        "How close?"
        
        "Too close."  She points up the slope ahead of you, her finger shaking and eyes bleak.  "Tomorrow we'll reach our safest camp—the most defensible we've got.  Might be some of us have to make a stand there, ${addressu}.  Give the rest time to put more distance between us and the Phalangites."
        *if (deputy = "Zvad") and not(zv_here)
          
          With Zvad fallen, you'll need to choose a new deputy.
          *gosub pickadeputy
        *goto campsite
    *if inwoods < 44
      *set cas +round(inadults/13)
      *if cas < 1
        *set cas 1
      
      You slip, scrape, and tumble your way through the seemingly never-ending night, lit by the moon and (for one terrifying hour) the campfires of the Phalangite host far below you.  
      *if cas = 1
        One of your followers breaks her neck in a fall while fording a steep watercourse in the dark.
      *if cas > 1
        *set d2n_num cas
        *gosub d2n_np
        $!{display_numb} of your followers are severely injured as you hurriedly ford a stream in the dark; one breaks her neck slipping from a boulder.
      But there's few enough of you that you manage to stick together and keep your profile low.
      
      *gosub cascheck
      *goto bydawn
    But all does not go well.
    
    Your outlaws slip, scrape, and tumble their way through the lightless woods.  By the time the campfires of the Phalangite host appear below you, half your band is terrified and in pain. "We'll never make it, ${addressu}," one young Shayardene whimpers, staring down at the watchful camp guards.  They're too far away to make out their faces, but you feel as if their eyes are on you in the darkness.
    
    "No turning back," you whisper, desperately trying to will your bandits to stay calm.  Minutes later, however, a balky mule skids down the slope and brays in protest, infected by its driver's fear.  The Phalangite guards all turn to face your direction. A moment later, one strides off to the center of the camp.
    *if theurges = 0
      
      "They'll be on the hunt for us." You beckon your rebels into full-on flight, desperately hoping that no new Theurges have arrived since your attack. "Run, run for the crag!"
      *page_break
      The next few hours are a nightmare.  All of you batter yourselves on rocks and boughs to the point of bone-deep exhaustion…but you all hear the screams of those who tire, fall behind, and are caught by the vengeful Phalangites on your heels.  Dawn brings no respite, only the terrifying sight of one of the flanking forces on a hard march to intercept you.
      
      *if (com = 2) and (arms >= inadults)
        *gosub fightback
      It isn't until the afternoon that you come to a 
      *if campsite > 0
        familiar-looking
      stream and call a few moments' halt. "We've outpaced them," ${deputy} gasps, wiping water from ${dephis} lips. "Haven't heard or seen sign of them in an hour."
      
      "Some of us outpaced them," Alira says hollowly. "But only because they were slowed down by hunting those of us who were too slow.  They're still on our trail."
      *if kids > 2
        *set kidcas round(inkids/5)
      *if inadults > 10
        *set cas +2
        *if inadults > 19
          *set cas +round(inadults/8) 
      *if inkids > 15
        A heartbreaking number of the missing are children.  One outlaw mutters that some might only be scattered too widely to find you.
      
      *set inkids -kidcas
      *set kids -kidcas
      *set inwoods -kidcas      
      *set kidsdead +kidcas
      *set followers -kidcas
      *set dead +kidcas
      *set morale -(kidcas*2)
      *set morale -10
    *if theurges > 0
      Dozens of rebels gasp or curse as 
      *if theurges = 1
        a Theurge emerges from his tent and rises into the darkness.
        *goto movemovemove
      *set d2n_num theurges
      *gosub d2n
      Theurges emerge from their tent and rise into the darkness.
      *label movemovemove
      
      "Move, move, move!" Your voice has grown shrill in your own ears.  "For your lives…over the ridge and down!"
      *page_break
      The next few hours are a waking nightmare.  Fleeing into pitch darkness, you batter yourself on rocks and boughs, only able to see when the landscape lights up in a sulfurous blue fire-burst.  Four times, bandits near you are snatched up shrieking into the air and plummet to their deaths. You never see the Theurges in the blackness overhead.  Dawn brings no respite—only a Phalangite force pressing hard up the slope to intercept your band's long tail of injured stragglers.
      
      *if (com = 2) and (arms >= inadults)
        *gosub fightback
      The survivors who finally gather in the woods the next afternoon are a third fewer than the ones who set out at dusk. 
      *set morale -30
      *if kids > 2
        *set kidcas round(inkids/3)
      *if inadults > 10
        *set cas +2
        *if inadults > 19
          *set cas +round(inadults/3) 
      *if inkids > 15
        A heartbreaking number of the missing are children.  One outlaw mutters that some might only be scattered too widely to find you.
      
      *set inkids -kidcas
      *set kids -kidcas
      *set kidsdead +kidcas
      *set inwoods -kidcas      
      *set followers -kidcas
      *set dead +kidcas
      *set morale -(kidcas*2)
      *label nonelse
      "No one else behind me, ${addressu}," Alira says hollowly when she limps into the rhododendron where you're hiding. "None of ours, anyway."
    *gosub cascheck
    *goto howclose
  *if (not(choice_randomtest)) #Bringing the band through a forest in the dark would be madness.  We'll try it at dawn.
    *if inwoods < 44
      A larger band would surely have been caught.  By the time you reach the ridge overlooking the main Phalangite force, the enemy camp is stirring for the day's march.  But your 
      *set d2n_num inwoods
      *gosub d2n
      rebels slip along the hilltop, sticking to morning shadows and the patches of dense forest.  You evade the first scouts on the slope below, and make it back to proper forest cover before the Theurges take to the air.
      
      *if (strategy = 2) and (popular != 10)  
        Throughout the day, your practiced band moves swiftly and leaves little trace.  Alira hangs behind to make sure no one's on your trail, and by nightfall returns to you looking exultant.  "We've got clean away from them, ${addressu}.  They're all searching the area they thought they'd trapped us in."
        *set lostem true
        
        "Well, let's be sure we're well away before they realize it."
        *goto campblurb
      However, your heart sinks as throughout the day, you continue to have to hide from Theurges flying overhead.  Had everything gone according to plan, they'd surely all be searching the area you just escaped.
      *goto exhaulira
    By the time you reach the hills overlooking the main Phalangite force, the enemy camp is stirring for the day's march.  You and Alira lead your 
    *set d2n_num inwoods
    *gosub d2n
    rebels close to the ridgeline, doing your best to keep to morning shadows and the patches of dense forest.  
    
    But there are simply too many of you to go unnoticed.
    
    There's no warning of the attack before the fireball erupts a hundred yards behind you.  With the screaming still barely begun, all 
    *set d2n_num theurges
    *gosub d2n
    of the Archon's Theurges swoop out of the sun and begin to harry your outlaws.  The band fragments at once, scattering into threes and fours.  
    
    Minutes later, you sprint out into a clearing to see a great Phalangite force below, half of them carrying nets and shackles.  However many of you they don't kill, they clearly intend to carry back for a triumphal procession and Harrowing.  A howl of denial tears itself from your throat.  "Keep to the ridge!" you scream back into the woods. "Harrowers below!"  Then the arrows begin to fall around you, and you dive back into cover.
    
    For hours you flee through the woods, with the shrieks and explosions growing fainter.
    *if zv_here
      Just when you were numbly daring to hope that you'd escaped, you see one of the flanking forces pressing up the slope to intercept you.  "Damn them." Zvad's exhausted face crumples into a savage snarl.  "Run, ${addressu}!" He pushes you onward and beckons ten outlaws down the hill after him.
      *if korszata > 1
        
        The former soldier Bjel charges past you to join them, ululating with a noise you've never heard any human throat make.  The noise seems to put steel into the doomed ${whend}ish bandits.
        *set korszata 1
      They charge directly into a thicket of Phalangite swords—but they don't fall quickly, and the delay saves you.
      *set zvad -50
      
      *set zv_here false
    *if  (com = 2) and (arms >= inadults)
      *gosub fightback
    By nightfall, it becomes apparent that some two-thirds of your followers are not about to find their way back to you.  Either they died in the woods, fell into the enemy's hands, or were scattered beyond returning.
    *if (inadults > 12) and (inadults < 33)
      *set cas +3
    *if inadults >= 33
      *set cas +round((inadults*2)/3)
    *if kids > 3
      *set kidcas round((inkids*2)/3)
    *if inkids > 15
      The number of missing children is… unthinkable.
        
    *set inkids -kidcas
    *set kids -kidcas
    *set inwoods -kidcas      
    *set kidsdead +kidcas
    *set followers -kidcas
    *set dead +kidcas
    *set morale -(kidcas*2)
    *set morale -60
    *goto nonelse
*label campsite
*page_break
*if choice_randomtest
  *choice
    #At High Crag Camp, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.  ${inwoods} inwoods, ${inadults} inadults, ${inkids} inkids, ${morale} morale.
      *goto postchoice6
*label postchoice6
After a long, weary day's ascent, you scramble over a final rise and see what your scouts
*if campsite > 0
  now
refer to as the High Crag campsite.
*if campsite > 0
  It looks just as it did when you visited all those weeks ago. You drink from the broad pool with no less intense a thirst.
  
  ${deputy} nods to the fissures in the mountain above you. "You remember those caves, ${addressu}, and the streams that run out of them on the far side.
*if campsite = 0
  It's a dimple in the mountain's broad shoulder, just below its shattered crown of crags and ravines.  Tall dark evergreens blanket the area, threaded with the bright greens and whites of birch.  The tiny stream whose cascades you have to climb to reach the site turns out to be fed from a broad, flat pool with enough water to sustain your band for a month.

  "The caves you can see there, ${addressu}…" ${deputy} points up to the mountain's fissured crown. "There are a lot more tunnels and cracks behind them.  Some will take us to the ledges away up there, others drop down into streams going out the other side, into thick forest.  
That's how we'd run, if we need to leave in a hurry."

*if lostem
  "Let's hope we won't need them," you say, casting an eye back to the vastness of the wild behind you. "Come with me—I want to see what we can see from the top."
  
  It takes you half an hour to clamber up most of the way to the peak. You don't want to go beyond the last scrubby bushes and onto exposed rock.  From a high shelf, you try to spy your outlaws below, but the caves and forest provide invisibility from the air.  You'll also be able to see any enemy coming from many miles away. 
  
  "Might be best to hole up here for a while," ${deputy} offers, a note of hope in ${dephis} voice. "Send scouts out to keep an eye on them…set a few false campfires 
  *if theurges > 0
    to keep the magi busy far away. 
  *if theurges = 0
    just in case they've managed to fly in another Theurge.
  Meanwhile we can be safe."
  
  [i]Safe.[/i]  It feels impossible; you're not ready to let yourself believe in it yet.
  *page_break
  *goto joana
*if not(lostem)
  "Make ready," you order hoarsely.
  *if inwoods < 45
    If there were more of you, you might have split your followers here—have some flee while others do whatever they can to delay the enemy.  But the band is so small that you'll need to choose one course or the other.
  *if inwoods > 44
    You could split the band now…hold some back to fight and delay the Phalangites, while the rest slip away.  But only if you were willing to stay with the fighters.  A few of your toughest rebels would be willing to face certain death, outnumbered and beset by Theurges; the rest would only stand if there were a chance to retreat and survive.  If they thought their leader believed in that chance.
  *choice
    #"This is where we'll make our stand."
      "We won't find a better place for it," ${deputy} says, a fatalistic note in ${dephis} voice.
      
      *goto korszword
    *if (inwoods > 45) #"Send most of the band out through the caves.  The rest of us will draw their attention and hold them here as long as we can."
      The enemy probably won't be distracted by fewer than forty.  You look back over your 
      *set d2n_num inwoods
      *gosub d2n
      *if inkids > 2
        *set d2n_num inadults
        *gosub d2n_np
        outlaws—${display_numb} adults and
        *set d2n_num inkids
        *gosub d2n
        children—and
      *if inkids <= 2
        outlaws and
      decide how many you want to flee.
      *input_number flee 0 (inwoods-40)
      *if flee = 0
        On second thought, you'll all:
        *choice
          #Make a stand here.
            *goto korszword
          #Flee together.
            *goto joana
      *if inkids > 2
        You send
        *if flee >= inkids
          all
        *if flee < inkids
          many
        of the band's remaining children out into the woods with the escape party.
      *if pin > 0
        *set pin 5
        *if alless > 0
          *set alless 5
        Pin Thatcher protests, as you knew she would. "I want to fight at your side, ${addressu} ${fname}.  Don't send me away with the 
        *if inkids > 2
          little ones."
        *if inkids <= 2
          rest."
          
        "No time for that now, Pilyin," you say firmly, crouching beside the fierce young girl.  "You need to be a damned sight older and taller to go toe to toe with a Phalangite.  I order you
        *if alless > 0
          and Alless
        to survive until then.  Until you can be a leader in the 
        *if inkids > 2
          rebellion.  And for now, to protect the children."
        *if inkids <= 2
          rebellion."
        
        "Are you…"  Pin's mouth twists as if she's just bitten limebark, and her eyes shine wetly. "$!{addressu}, will I see you again?"
        *fake_choice
          #"Of course you will," I insist. "We'll tie them down here, then vanish before they know where to look for us."
            Pin looks uncertain, but your confident tone seems to have dispelled her fears for now. "Then we'll see you soon, ${addressu}."
          #"If I'm lucky.  And I've been lucky so far."  I try to keep my voice light.
            "Luck of
            *if religion < 20
              the Angels
            *if religion > 19
              kenon
            to you, then, ${addressu}," Pin says shakily. 
              
            "To all of us."  You clap her on the shoulder, forcing a smile. "Look for me in the woods."
          #"I don't know," I say starkly. "But we'll do our damnedest."
            "Oh, ${addressu}." The tears spill down Pin's cheeks. "Let me stay."
              
            "No, Pin.  This isn't your day."  You grip her small shoulders for a moment, then let go of her and stand.  "Don't try to face it before you're full grown.  And when your day comes, if we're not there…remember us."
          #She deserves the truth.  I glance around, then grip her shoulder and murmur, "Goodbye, Pin," at a level only she can hear.
            "Oh, ${addressu}." The tears spill down Pin's cheeks, but she reaches out a trembling hand and grips your arm back. "Let me stay, ${addressu}."
              
            "No, Pin.  This isn't your day."  Your voice is thick and raspy.  "Don't try to face it before you're full grown.  And when your day comes…remember us."
      
      *set inwoods -flee
      *set inadults -1
      *set inkids -(flee-1)
      *if inkids < 0
        *set inadults +inkids
        *set inkids 0
      You beckon to the outlaw you want to lead your 
      *set d2n_num flee
      *gosub d2n
      escaping rebels:
      *choice
        *if (zv_here) #Zvad.
          *set fleelead "Zvad"
          *set zv_here false
          The big ${whend} gives a curt nod. "Strength to your arm, ${addressu}."
          
          *goto korszword
        *if (bred_here) #Breden.
          *set fleelead "Breden"
          *if ((bred_lover < 4) or (bred_lover = 13)) and (bred_heart != 3)
            Breden nods grimly. "Scapewell, ${bfname}. Now of all times, scapewell."  Then ${xhe} turns and heads for the caves.
            
          *if ((bred_lover >= 4) and (bred_lover != 13)) or (bred_heart = 3)
            As you'd expected, Breden's instant and anguished response is, "No.  No, love.  Someone else."
            
            "You know it has to be you."  You pull ${xhim} close to you, feeling the pulse hammering in ${xhis} throat. "If we die here, the rebellion dies with us.  That's how the Hegemony will tell it, and they'll be believed.  Unless there's someone to tell the story a different way and keep the idea alive."
            
            "And you get the easy road.  You'll be the martyr."  $!{xhis} voice is low in your ear; pressed so close to ${xhim}, you can't tell whose tears are soaking your face.
            
            "We might yet live," you say, barely able to get the words out. "But you must live.  The rebellion needs you, love.  Scapewell."
            
            "[i]Ah Angels![/i]"  Breden tears away from your embrace with a howl. "Xthonos damn you, ${fname}.  Damn you if you don't come back to me."  $!{xhe} stalks off toward the caves.
            *page_break
          *set bred_here false
          *goto korszword
        *if (el_here) #Elery.
          *set fleelead "Elery"
          *set el_here false
          "Time for our survivors to go to ground, Skinner—and I've always heard there's no one like you for finding the right place."
          *if e_rel > 9
          
            Elery's face is a picture of misery, but she gives a short nod. "Scapewell, ${addressu}. Now of all times, scapewell."
          *if e_rel < 10
            Elery nods curtly.  "We'll use whatever time you can buy us, ${addressu}."
          Then she turns and heads for the caves.
          
          *goto korszword
        *if (rad_here) #Radmar.
          *set fleelead "Radmar"
          *set rad_here false
          "What?" Radmar snaps, taken aback.  "Not a chance, ${lname}.  Send me away just before the real fight?"
          
          You keep your own voice low.  "There'll be no less real a fight out there in the woods if we fail.  We need at least one of our strongest with the group that runs. They'll need you."
          
          After a pause, Radmar
          *if poric > 0
            glances at Poric, who's ushering several other outlaws toward the caves.  Then he
          scowls at you. "Don't die
          *if r_rel < 10
            too quickly
          up here, ${addressu}.  We'll need 
          *if r_rel > 9
            you when the Phalangites run back to the Rim."
          *if r_rel < 10
            all the time you can buy us."
          
          "I'll do my best," you growl back at him.
          
          *goto korszword
        *if (kal_here) #${kalt}.
          *set fleelead kalt
          *set kal_here false
          "What are you thinking, ${addressu}?" ${kalt} demands when you ask ${zhim}. "I'd make my stand up here with you."
          
          "No.  They'll need you more than we do."  You nod to the milling outlaws. "If we fall here, they'll be afraid, miserable.  They'll need someone who can turn that to anger.  Someone who can get them fighting again."
          
          *if k_rel != 4
            ${kalt}'s scowl fades as you speak, and by the end ${zhe}'s nodding.  "Aye then, ${addressu}.  I'll lead them.  Scapewell."
          *if k_rel = 4
            To your surprise, ${kalt}'s scowl only deepens as you speak.  $!{zhe} looks down at the ground as if searching for some other argument; then ${zhe} stalks toward you and plants ${zhis} lips against yours.  "Scapewell, you beautiful bastard," ${zhe} says huskily a few moments later. "Break the swivers.  And come back to me."
          
          *goto korszword
        *if ((simz_here) and (s_rel < 9)) #${simon} de Firiac.
          *set fleelead simon
          *set simz_here false
          "I'd make my stand with you, ${addressu} ${fname}, if you let me," ${simon} 
          *if (s_rel = 6) or (s_rel = 5)
            says grimly, but you can tell ${zhis} heart isn't in it.
            
            "No, de Firiac.  Go be a noble protector of the defenseless.  That should suit you well."  You bow stiffly to ${zhim}. $!{zhe} returns the gesture before turning to the caves.
            
            *goto korszword
          pleads. "With this terrain on our side, I could bring down a dozen Phalangites."
          
          "You might have the chance with the escape party as well."  You lean in close. "And I want someone leading them who won't stop fighting.  Someone to boost their mettle if things go ill with us here.  You're the leader they'll need, ${simon} de Firiac."
          
          The young noble looks anguished, but straightens and offers a salute with ${zhis}
          *if s_sword = 1
            family
          *if s_sword != 1
            captured
          sword. "By my life and honor, ${addressu}…I'll be their leader.  In your stead, or—Xthonos forbid—in your memory."  Dashing tears from ${zhis} eyes, ${zhe} turns to the caves.
          
          *goto korszword
        #Someone else.
          *set fleelead "Rand"
          *goto korszword
    #"At dawn, we'll all be leaving."
      *goto joana
*label korszword
*if fleelead = deputy
  With your deputy ${deputy} gone, you choose a new second-in-command:
  *gosub pickadeputy
*set cragprep true
All afternoon, your
*set d2n_num inwoods
*gosub d2n
*if flee > 0
  remaining
*gosub cragpreps
You watch the preparations with a sense of…
*fake_choice
  #Dread.
    It all feels terrifyingly futile.  How can you possibly stand against so powerful and resourceful an enemy?  You've never regretted the path that led you to rebellion more than you do at this moment. 
  #Determination.
    Tomorrow, you'll make your stand.  Until it's done, you'll think of nothing but how to fight as hard and as well as possible.
  #Eagerness.
    This is it—the first time when you'll make a stand against the Hegemony.  Seeing your rebels preparing so overtly for battle fills you with a joy so keen and intense it almost brings tears to your eyes.

*label joana

*if rescuer > 0
  *goto morningsickness
In the evening, Old Joana Orchard brings you a bowl of pottage. "Your father's not eating, ${fname}."  There's a note of concern in the 
*if aristo
  old helot's 
*if helot
  elder's
voice—faint, but more than you'd have thought to hear on the topic of your father.
*fake_choice
  #I cast a pained glance at her.  "Since he stopped speaking to me, there's not much I can do to help."
    Joana 
  *if aristo
    #"I've no time to indulge his theatrics, Joana."
      "I know, I know. More important things." Joana
  *if helot
    #"I don't have time to play games with him, Aunt Joana."
      "I know, I know. More important things." Joana
  #"Good."
    Joana raises a chiding eyebrow.  "That's not a thing to say of your father, ${fname}."
    
    "He's made it clear he doesn't consider me his child."  Your voice sounds sullen in your own ears.
    
    The old helot 
*if helot
  sighs and settles herself next to you. "So.  The two of you had a fight.  Over that business with Aryn Weller."
  *fake_choice
    #"He raved about another child.  His real son."
      "Ah."  Joana's face darkens. "Used to be something he shouted at your mother about every week or two.  Till you were maybe two years old.  Now it's been so long since I heard about it…I didn't know if he'd quenched those memories.  Sorry he hasn't, 
      *if he = "he"
        lad."
      *if he = "she"
        lass."
      
      "$!{oath}, Joana."  You can hear the cracking strain in your own voice. "What was he on about?"
      
      "Your mother…"  The old woman looks like she's weighing her words carefully.  "Well, both she and your father had been wed before.  Your mother's first husband got himself Harrowed before any children came along.  Around the same time, your father's wife and son both died, when that barn she was working in caught fire.  Ugly, grievous thing, no question.  He was half mad after that.
      
      "Some of us warned your mother not to hurry into anything new.  But she wasn't in the best mind herself.  Some of the elders had complained about her not bearing a child in time to save her husband, and that had got under her skin.  She knew your father hadn't the heart to love her.  She took him as a safe-mate anyway."
      
      The ache between your ribs is threatening to double you over.  "He loved [i]them[/i], then.  His first wife and son."
      
      "Well, Angels know he loved that babe."  Joana stays silent for a long time, then scowls and exhales sharply through her nostrils. "Other than that…the one time I reckon your father truly loved someone was when we were about your age.  A beautiful young fellow named Jaq from the Pelematou estate.  Never concerned about looking for a safe-mate, our Jaq, open about everything he did."  Her face looks unutterably weary.  "Got Harrowed about as quick as you'd expect.  Within a week or two, your father had stopped crying and arranged things with his first wife."
      *fake_choice
        #Tears are streaming down my face, and for several minutes I'm unable to speak. 
          Old Joana stands gingerly, clears her throat. "None of it makes a right of how he treated your mother.  Or you.  But I thought you should know."  She sets the bowl of pottage next to you and walks away.
        #"Damn him a coward then," I grate, resisting any hint of sympathy.
          "Not much point in damning him, ${fname}—that's what I've been trying to say." Old Joana rises, looking pained.  "And there's many who decided it was better to stay alive than hold out for a better half."
          
          "There's something he's done that's worth staying alive for?" 
          
          "You want me to defend him, ${fname}?"  Her eyes widen through the web of wrinkles, and she snorts softly.  "The man's a walking bile stain.  But he stopped shouting at your mother about his 'real son' when he thought his new ${daughter} was old enough to understand."

          You shake your head in violent negation. "And now he starts again."
          
          Joana sighs.  "Aye.  Aye, he couldn't even get that right, in the end.  But it's still no light thing to damn your own father, ${girl}."  She sets the bowl of pottage next to you and walks away.
        #I begin to pace, head in my hands.  "Ah, Xaos, Xaos.  Damn them for this.  Damn them for what they've done to us."
          "Just because we're cattle to Them doesn't mean we treat each other the same," Joana says after a moment, an edge returning to her voice. "Your father's made his own choices, ${fname}.  How he treated your mother.  How he's treated you."
          
          "$!{oath}, I know.  But…"  You feel like you're being gnawed out from within.  "Blow on blow, Joana.  They destroy us so [i]bloody[/i] long before they Harrow us.  From so many sides at once."
          
          "You knew that already."  The old woman gives a rattling sigh and stands. "And now you know more of what made your father into the walking bile stain he is.  Don't know if it'll make any difference, but you're old enough to be open about it."
      *goto morningsickness
    #"He betrayed Aryn to the Alastors."
      "Probably so," she says gruffly. "Probably so.  But there was never proof, ${fname}."
      
      "I don't give a damn for proof.  My father's a traitor, and I'm trying to lead a rebellion."
      
      "Your father's weak.  And a walking bile stain."  The elder grimaces and shakes her head.  "But there's more share his weakness than you'd like to think.  If you'd come of age in the Rim Square camps, you'd have come to know that…and you'd have had to decide whether to forgive them, or to turn into someone as sour as your father."
      
      You stare at her, trying to contain the roil of emotion in your throat.  "We're not in the helot camps any more, Joana."
      
      "No.  And maybe rebels don't forgive."  Joana Orchard gives a rattling sigh. "I'm only saying, ${girl}…your father blamed some of the other t'Keriatou for losing folk he loved when he was your age.  Xthonos, he hated them hard.  But that hate had nowhere to go. Specially when he found himself making the same choices."
      
      "We're out here so none of us will have to make those choices.  Never again."
      
      "May it be so, ${fname}."  Old Joana looks as if she's about to say more, but in the end just nods at the pottage. "Eat well."
    #"I don't want to speak about it."
      "Well then."  Joana clucks her tongue at your rudeness, sets the pottage down next to you, and walks off.
  *goto morningsickness
*if aristo
  sighs. "If we were all back in Rim Square, it'd be no place of mine to talk to you on this, young ${milady}."
  *fake_choice
    #"You were my mother's friend, Joana.  You could always speak your mind."
      "Maybe it seemed that way to you, ${kuria}," the old helot says wryly. "But…aye, I was a friend to her.  And she never hated your father, however much he deserved it.  That compassion that let her treat a helot like a sister?  It meant she'd never have given up on saving him."
      
      "It killed her."
      *label thinears
      Your voice is thin in your own ears.  "He wore her down until she died.  And was he saved?  How many of us have to die before we stop smiling under the blows, hit the old bastard back, and let him be the one to wither away?"
      
      Joana is silent for a long time.  "I hated the master, too, ${milady} ${fname}," she says at last. "When my boys were Harrowed, and all he could say was that he wanted me back pulling fruit the next day?  I'd have killed him then."  Her throat works for several seconds before she's able to continue. "I told your mother that.  Said, let me kill him for you, and die.  Wasn't in my right mind. Thought she'd have me off to the Harrower, too."
      
      You blink at her, trying dazedly to imagine the different course your life might have taken.  "She didn't."
      
      Old Joana exhales sharply through her nostrils. "She owned that he'd have deserved it.  Said he'd been so shamed and scorned by his own family and the other Houses that there wasn't much left in him that was worth keeping alive.  But the way she talked about it, the bits of his story she told…she pitied him, ${kuria}, and some bit of that pity got stuck to me.  She said he'd lost most of his soul to the same things that cost us ours.  Just from the other side.  And she'd keep trying to pull him away from it—to save what was worth saving."
      *fake_choice
        #"She failed, Joana.  She failed."  My stomach turns.  "If there was ever anything in him to save, it died a long time ago."
          "Could be, ${milady}.  Could be."  Joana shrugs, sets down the pottage, and walks away.  Over her shoulder, she adds, "But she didn't give up, even so."
        #"The same things?" I say incredulously. "What did he ever face that comes within a mile of your sufferings?"
          "Believe me, ${girl}, I had the same thought when first she said it."  Joana's weathered face goes flinty for a moment. "Nothing that happened to him matched what had happened to me.  But in time I saw she wasn't talking about that.  She said 'the same things.'  She meant the same things."
          
          You shake your head, impatient.  "I don't see what you mean."
          
          "Your mother, ${fname}…she had more life in her than any ten other nobles.  She treated us like humans, not cattle.  And I saw it make her more human." The old woman's mouth twists wryly. "While others turned more jackal with every year that went by.  Not by what was done to them, by what they did."
          
          *if arrog > 0
            For her sake, you're just about willing to ignore the demeaning metaphor.
          "And you pitied them?  The jackals?  Instead of hating them?"
          
          Old Joana stares at you for a moment, then offers a small shrug.  "Well, I wanted to be human myself, didn't I?"  She sets down your pottage. "Not saying it's your job to save him, ${fname}.  Maybe he can't be saved.  Just wanted you to think on it before you damn him any further."
        #I lapse into a pained, uneasy silence.
          Eventually, Joana sets down your pottage.  "Not saying it's your job to save him, ${fname}.  And maybe he can't be saved.  Just wanted you to think on it before you damn him any further."
      *goto morningsickness
    #"We aren't in Rim Square, though, are we."
      "No.  No, that we aren't, ${fname}."  Joana settles herself next to you with a muffled groan. "So I'll tell you my mind.  Because your mother was the best soul I ever knew, and she'd be grieved to see things come to this pass."
      
      "You think she'd say it was my place to mend it?" you ask incredulously. "$!{oath}, Joana, I know he's my father, but he's the one…"
      
      "He's a walking bile stain," the old helot cuts you off. "But your mother never gave up on trying to save him."
      
      "That's what bloody killed her, Joana, and you know it."
      *goto thinears
    #"And it's no place here, either."  I don't want to hear any more.
      "Well then."  Joana clucks her tongue, sets the pottage down next to you, and walks off.
  *goto morningsickness
*label morningsickness
*page_break
*if not(bred_here)
  *goto nosleep
*if bred_here
  *set bredvom round(inadults/3)
  *set inadults -bredvom
  *set inwoods -bredvom
  You sleep uneasily in the caves that night, haunted by dreams of Theurges overhead.  Around the second watch, you drowse awake to a nightmarishly pervasive noise and smell of vomit.  You scramble blearily to your feet, taking in the contorted silhouettes around you.  Then you run in a sudden panic to investigate the same sounds outside the cave.
  
  There's not been a single week when someone hasn't been ill with the flux, but tonight a good third of the outlaws in your camp are doubled over, barely able to move save to retch out their guts.  You stare in disbelief and growing horror.  Then you glance at the bowl of pottage 
  *if rescuer = 0
    Joana brought you.  It sits untouched at your side. Your conversation stole your appetite, and you'd thought you might want it more if you woke in the night.
  *if rescuer > 0
    at your side—one you didn't have the appetite for when it was first brought to you.
  
  You sniff the food, warily dab a bit on your tongue. There's an acrid note mostly but not entirely disguised by the smokiness;
  *if int < 2
    some manner of poison?
  *if int > 1
    hellebore, you think with a jolt of shock.
  Turning to find
  *if zv_here
    Zvad
    *goto whocook
  *elseif kal_here
    ${kalt}
    *goto whocook
  *elseif (simz_here and (s_rel < 10))
    ${simon}
    *goto whocook
  *else
    Alira
    *goto whocook
  *label whocook
  at your arm, you wave the bowl in fury.  "Who cooked this?  Whose turn was it on cooking duty tonight?"
  
  "Young Earnn.  
  *if rescuer = 0
    Gaved from the Pelematou estate.
  *if rescuer > 0
    Old Vorne.
  And Breden."
  *choice
    #I confront and question Breden.
      Breden's face shines with sweat in the moonlight, but ${xhe} doesn't look ill—just terrified.
      *gosub puke
      "Angels, ${bfname}."
      
      You stop a few feet from ${xhim}, your knuckles white around
      *if weapon = "sword"
        your sword.
      *if weapon != "sword"
        the haft of an axe.
      "Give me your best explanation, Breden. Give it fast."
      
      $!{xhe} blinks at you, a growing horror on ${xhis} face.  "If I'd done it,
      *if ((bred_lover < 4) or (bred_lover = 13)) and (bred_heart != 3)
        ${bfname},
      *if ((bred_lover >= 4) and (bred_lover != 13)) or (bred_heart = 3)
        love,
      you think I'd still be here?  You think I'd stay with the band I'd just poisoned?"
      
      "I think you'd better give me a better explanation than that of what's just happened."
      *goto dunno
    *selectable_if (not(bredwed)) #I find Breden and kill ${xhim}.
      "$!{bfname}—wait," Breden protests when you find ${xhim} in the moonlight. 
      *gosub puke
      "Wait,
      *if ((bred_lover >= 4) and (bred_lover != 13)) or (bred_heart = 3)
        love,
      I know…"
      
      No more excuses; no more honey-tongued explanations.
      *if (bred_lover >= 4) or ((bred_heart = 3)  or (bred_heart = 2))
        If you hesitate for even an instant, you'll be swayed by your
        *if bred_lover = 13
          one-time
        love for ${xhim} again, so you cling to the bitter clarity of what you know now.
      *label bredkilled
      *set bred_trust 20
      *set bredconsent true
      *set violence +1
      You raise 
      *if weapon = "sword"
        your sword
      *if weapon != "sword"
        the axe you seized
      and lunge for ${xhim}.  
      
      $!{xhe} tumbles backward with a wail of, "Oh Xthonos!" that rises into something high and frantic when your weapon lodges in ${xhis} shoulder.
      
      *if (bred_lover >= 4) or ((bred_heart = 3)  or (bred_heart = 2))
        You scream yourself.  This should have been quick, but your trembling and ${xhis} dodging have turned it into something too grim for nightmare.
      "Traitor!" you howl, trying to wrench the 
      *if weapon = "sword"
        blade 
      *if weapon != "sword"
        axehead
      out from bone.
      *if (bred_lover >= 4) or ((bred_heart = 3)  or (bred_heart = 2))
        *if bredwed
          [i]$!{xspouse}.[/i]
        The tears on your face feel scalding, acidic.
      "Poisoner!"
      
      "[i]${fname}![/i]" Breden shrieks, clawing vainly at you with one blood-slick hand. "[i]No! No![/i]"  $!{xhis} screams becomes garbled but even louder as you rip your weapon free.  After two more blows, ${xhe} falls abruptly and utterly silent.
      *if (bred_lover >= 4) or ((bred_heart = 3)  or (bred_heart = 2))
        *fake_choice
          #I fling the filthy ${weapon} away from me, sobbing and retching.
          #For a moment, I want to open my own veins with the weapon.
          #I'm nothing but anger, a spark of consciousness lost in a blaze.
          #I feel numb.  $!{oath}, I hope that stays.
      *page_break
      *if bred_pris
        *set bred_pris false
        Half the outlaws around you look shocked and horrified, but the other half are firmly supportive of your and
        *if (zv_here and (zvad > 2))
          Zvad's
          *goto ujudge
        *elseif rad_here
          Radmar's
          *goto ujudge
        *elseif kal_here
          ${kalt}'s
          *goto ujudge
        *else
          Alira's
          *goto ujudge
        *label ujudge
        judgment.
        *if (bred_lover >= 4) or ((bred_heart = 3)  or (bred_heart = 2))
          
          Forcing yourself back into some semblance of stability is the hardest thing you've ever done.
        "We'll bury ${xhim} later," you say hoarsely. "First we need to save as many of ${xhis} victims as we can."
        *gosub breddead
        *goto healingvom
      The other outlaws stare at you in
      *if bred_lead > 10
        unmitigated
      *if bred_lead > 5
        horror.  Many look as sick as their doubled-over comrades.  "What have you done, ${addressu}?" one whispers.
        
        "Passed judgment on the
      *if bred_lead < 6
        shock, many looking as sick as their doubled-over comrades. "Why…why did you…" one gasps.
        
        "Because ${xhe} was a
      Karagond spy who just poisoned us all," you snarl, thick-voiced as you try to wipe Breden's blood from your face. "After betraying us in Rim Square. $!{xhe} was the one.  It was always ${xhim}."
      *if bred_lead > 10
        
        But too many of the band have followed Breden, learned to trust ${xhim}, and are appalled at your summary execution.
        *if el_here
          Elery
        *if not(el_here) and (c_rel > 0)
          Ciels
        *if (el_here) or (c_rel > 0)
          has begun weeping on the ground, and manages to croak, 
        "Kill ${him}!  $!{he}'s gone mad!"  It's the last thing you hear. You never see the knife that takes you from behind.
        *page_break
        *goto_scene death
      *if bred_lead > 5
        
        "Angels, ${addressu}.  You don't know that."
        *if el_here
          Elery
          *set e_rel -10
        *if not(el_here) and (c_rel > 0)
          Ciels
        *if (el_here) or (c_rel > 0)
          has begun weeping on the ground. 
        *if not(el_here) and (c_rel < 1)
          Alira stares queasily at you.
        Between the sickness and your summary response, you can practically feel the band's morale collapsing all around you.
        
        "We all know it," you insist desperately.  
        *if (bred_lover >= 4) or ((bred_heart = 3)  or (bred_heart = 2))
          [i]They have to.  They have to know there was no other way.[/i]
        "$!{sweetoath}, will anyone pretend otherwise?"  When no one meets your eyes, 
        *if (bred_lover < 4) and ((bred_heart != 3)  and (bred_heart != 2))
          your throat constricts almost shut with fury.  "Damn it all.  
        *if (bred_lover >= 4) or ((bred_heart = 3)  or (bred_heart = 2))
          you sway in place, wishing you had eaten Breden's poison and vomited yourself into insensibility. "$!{oath}.
        Help the sick, then."
        *set morale -30
      *if bred_lead < 6
      
        While your followers are stunned at your summary execution, few enough of them were influenced by Breden that on the whole they believe you.  The ripple of dismay through the band is quickly stifled, and at your insistence they turn back to helping the sick.
      *gosub breddead
      *goto healingvom
    #I don't believe ${xhe} did anything wrong.  This is all just a terrible accident.
      You hurry out in search of Breden. Minutes later, you find ${xhim} crouched over 
      *if el_here
        Elery, 
        *set elsick true
      *if not(el_here) and (c_rel > 0)
        Ciels,
      *if not(el_here) and (c_rel < 1)
        young Pereth,
      who looks barely conscious and is covered in half-digested pottage.
      
      *if (zv_here and (zvad > 2)) or rad_here
        You also see
        *if (zv_here and (zvad > 2)) 
          Zvad stalking grimly
        *if ((zvad < 3) or not(zv_here)) and rad_here
          Radmar stalking murderously
        toward ${xhim}, weapon in hand.
        
        "No!" you shout—and a startled Breden rolls aside just in time to avoid the killing blow.  "Damn it all,
        *if (zv_here and (zvad > 2)) 
          Zvad,
        *if ((zvad < 3) or not(zv_here)) and rad_here
          Radmar,
        stop!  $!{xhe}'s no traitor!"
        
        *if (zv_here and (zvad > 2)) 
          Zvad doesn't strike again with his maul, but he lunges at Breden and kicks ${xhim}, hard, to keep ${xhim} from regaining ${xhis} feet. "Don't tell me you know that, ${addressu}."
          
          "I'm sure of it!" you yell.  "Stay your hand, Zvad."
          
          "Stop where you are, Reaper," Zvad growls, kicking Breden to the ground again. "Flat on your back…and we'll hear what you and the ${kuria} have to say."
          
          Breden blinks up at you both in shame and terror.
        *if ((zvad < 3) or not(zv_here)) and rad_here
          Teeth bared, Radmar ignores you and lashes out again at Breden with his axe. "Traitor! Poisoner!" he bellows.
          *if poric > 0
            "Ah, Poric!"  Tears are streaking his face.
          *choice
            #I charge at him.  If the only way to save Breden is to kill Radmar, I will.
              *if com = 0
                *label radchop
                Radmar bats aside your ${weapon} with barely any effort.  "Defend a traitor?" he spits at you.  "No more, ${lname}!"
                
                In a sudden panic, you try to block his axe.  All you manage is to deflect it enough that it takes three agonizing blows to kill you, rather than just one.
                *goto_scene death
              *if com = 1
                Unfortunately, you're not as good with your ${weapon} as Radmar is with his axe, and he bats you back without much effort.  But it gives Breden a chance to scramble away, and both you and Radmar see it. 
                
                "Traitors, all of you!" he snarls desperately. "Be damned to you, then!" He hurls himself at Breden, no longer trying to defend himself against you.  Hard on his heels, you
                *if weapon = "sword"
                  cut him down—but 
                *if weapon != "sword"
                  crack his skull—but 
                as Radmar topples forward, you see to your horror that his axe is buried in Breden's head.
                *set rad_here false
                *set radmar -60
                *set bred_here false
                *set breden -60
                *set followers -2
                *set nonkids -2
                *set dead +2
                *set inadults -2
                *set inwoods -2
                *if (deputy = "Breden") or (deputy = "Radmar")
                  *set deputy ""
                *fake_choice
                  #I'm so furious, it's all I can do to keep from stabbing Radmar's corpse.
                     But you whirl away instead and look for ${abler}.
                  #"No!" I howl, dropping my ${weapon} and catching up Breden's body.
                    *if (bred_lover >= 4) or ((bred_heart = 3)  or (bred_heart = 2))
                      *gosub failbred
                      But it's still several minutes before you can let ${xhim} go.
                    *if (bred_lover <= 3) or ((bred_heart = 3)  or (bred_heart = 2))
                      Tears scald your face, and you can't stop shaking.
                  #I stagger back, struck mute by horror.
                    At a stroke, you've lost two of your rebellion's natural leaders.  It's all you can do to fight off despair and go looking for ${abler}.
                  #All I can think of is the need to keep anyone else from dying.
                    There's nothing more anyone can do for Radmar and Breden.
                *goto healingvom
              *if com = 2
                You strike Radmar's axe with your own weapon, deflecting rather than blocking. The axe hits the ground next to Breden, while the big man's own strength carries him off balance.  He only staggers slightly, and rights himself quickly, but the opportunity is just enough for you to whip your ${weapon} up to
                *if weapon = "sword"
                  open his throat.
                *if weapon != "sword"
                  crack his skull.
              Nothing less would keep both you and Breden alive.
              
              Breden stares up at you with a mix of gratitude and raw terror.
              *set radmar -60
              *set rad_here false
              *if (deputy = "Radmar")
                *set deputy ""
              *goto bredgasp
            #I try to disarm Radmar with my ${weapon}.
              *if com < 2
                Unfortunately, disarming him proves to be beyond your skill, and
                *goto radchop
              *if com = 2
                You hurl yourself at the big fighter, howling as your ${weapon} meets his axe.  The two of you have sparred before, but warily rather than seriously, never fully testing what the other could do.  At some level, one or both of you always knew that you'd end up fighting in earnest one day.
                
                Just as you're beginning to think that you'll need to kill him to survive, he swings too hard and leaves himself exposed.  You crack your weapon against Radmar's left hand, then slam it hard into his axe, which goes flying from his grip.  
                *label yieldradmar
                "Yield, Radmar," you grate.  "By ${oath}, yield or you're a dead man."
                
                "And let this traitor live, ${lname}?"  Radmar's breath hisses through bared teeth.  He doesn't make a move toward his weapon, but he shoots a furious glare around the other bandits in the moonlight.
                *if (bred_lover > 9) and (bred_lover != 13)
                  "Just because ${xhe}'s 
                  *if bred_lover < 20
                    sharing your bedroll, 
                  *if bred_lover > 19
                    your few weeks' ${xspouse},
                  you'll ignore us all falling sick because of ${xhim}?"
                *label unlessproven
                
                "Unless ${xhe}'s proven traitor, aye.  Otherwise, who will you murder next time there's a flux in the camp?"  Before the doubtful murmur around you has time to resolve itself, you look to Breden. "What do you say happened tonight?"
                *goto dunno
            *if (theurgy > 1) #I cut my hand and use Theurgy to stop him.
              *set consc -1
              *if consc < 1
                It's not been nearly long enough since you last used Theurgy.  Unconsciousness sweeps over you before you can do more than yank the axe out of Radmar's hand.
                *label bredconsc
                *set radmar +10
                *gosub breddead
                
                When you wake up in ${abler}'s sick tent just before dawn, your first, thick-tongued question is: "Breden?"
                
                "Radmar caught ${xhim} by the throat, ${addressu}."  It's Alira's hard voice in the darkness. As your eyes adjust, you see ${abler} sprawled nearby in one of his own pallets. "And if ${xhe}'s in truth the one who put hellebore into the food, then ${xhe} deserved what ${xhe} got."
                *fake_choice
                  *if (bred_lover >= 4) or ((bred_heart = 3) or (bred_heart = 2)) 
                    #Oh, Breden.  Oh, my love.
                      *gosub failbred
                      But it takes you three tries before you master your voice enough to croak,
                  #I close my eyes, despairing at how quickly and violently my followers are turning on each other.
                    How can you possibly stand against the Thaumatarchy if you can't keep from murdering each other?
                  *if (bred_lover < 4) and ((bred_heart != 3) and (bred_heart != 2))
                    #I feel a sharp pang of grief for Breden. 
                      You still can't believe ${xhe} was the one responsible—not after all ${xhe}'d done to bring you through the hard winter.
                  #I'm overcome with rage at Radmar.  How dare he take "justice" into his own hands?
                    If you all survive the next week or two, you'll need to deal with him.
                  #I feel nothing but numbness, and a growing dread for what will come next.
                    You close your eyes and shake your head, as if to dispel a nightmare.
                "Hellebore?"
                
                "Aye, ${addressu}. Fairly sure of it."  ${abler}'s voice rises feebly in response. "Enough to purge, not kill…"
                
                "But if they can't run or fight, it might kill them anyway," Alira says grimly when your healer's words are cut off by another spasm of vomiting.
                
                Staggering up from your pallet, you look to your poisoned outlaws.
                *goto healingvom
              *label disarmrad
              Radmar's wood-hafted axe flies out of his grip.
              *if theuknown < 5
                A chorus of yells rises from your terrified outlaws, and Radmar whirls on you, eyes wide with dismay.
                
                "Aye, I'm a ${wisard}.
                *if (skep <= 50) and (wisard != "Goete")
                  By the Angels' grace.
                Though I'd never imagined I'd first have to use my ${wisardry} to save one band member from another."  You look round the
                *if wisard = "Goete"
                  horror-struck
                  *set morale -30
                band, then sharply back to the big fighter.
              *goto yieldradmar
            *if ((theurgy > 1) and (blood > 0)) #I break a blood phial and use Theurgy to stop him.
              *set blood -1
              *set usedblood +1
              *goto disarmrad
            #I order the other outlaws to stop Radmar.
              *if cha < 2
                "What—defending this traitor, ${addressu}?" Radmar snarls. "To Taratur with that!"
                
                Two of Breden's friends take heart from your cry, and grapple with the big fighter. One manages to pull his axe away.  But the majority of your outlaws are unconvinced, and swarm in to relieve Radmar and keep Breden from escaping.  
                
                Just as you're about to shout another order, you're knocked to the ground in the scrum.  Your head hits hard, and the world goes white before your eyes.
                *goto bredconsc
              *else
                Your tone of authority cuts through their doubt and anger, and they swarm over the big fighter before he can strike at Breden again.
                
                "What are you doing, ${lname}?" Radmar howls from beneath six other outlaws. "You'd truly let this traitor live?  This poisoning piece of filth?"
                *goto unlessproven
      Breden glances up at you, ${xhis} face contorted with frustration and terror.
      *label bredgasp
      "$!{bfname}!" ${xhe} gasps. "It's…there's something in what we ate…"
      
      "What happened?" you ask urgently.  "I know you were one of the cooks."
      *label dunno
      
      "I don't know!" ${xhe} cries. "Nothing we did.  Something epidemic, some foul humor in the caves.  Or something finding its way into the pot."
      
      "Finding its way?"
      *if (zv_here and (zvad > 2))
        Zvad blinks incredulously, then turns to you with a set expression. "No more, ${addressu}.  If you choose to believe ${xhim}, I'll not kill ${xhim} against your will.  But you'll not see me staying until ${xhe} tries again."
        *choice
          #I shake my head.  "I think ${xhe}'s innocent, Zvad.  I can't let you kill ${xhim}."
            *label zvaddep
            *set ruth %-10
            "Then memory keep you, ${addressu}."  Zvad stalks off. You later find out that nine others left the band with him.
            *set zv_here false
            *set morale -20
            *set followers -10
            *set nonkids -10
            *if deputy = "Zvad"
              You'll need to immediately appoint a deputy to replace him.
              *if rad_here or kal_here
                The intensity with which
                *if rad_here
                  Radmar
                  *if kal_here
                    and
                *if kal_here
                  ${kalt}
                *if kal_here and rad_here
                  are
                *if not(kal_here) or not(rad_here)
                  is
                glowering at you tells you that
                *if not(kal_here)
                  he
                *if not(rad_here)
                  ${zhe}
                *if kal_here and rad_here
                  they
                wouldn't accept it even if offered.  So you choose:
              *label zvadrepchoice
              *choice
                *if (bred_here) #Breden.
                  There's a stunned silence when you make the announcement.  
                  *if (rad_here or kal_here) and (cha < 2)
                  
                    As you turn your attention to the sick, it's 
                    *label probstab
                    probably 
                    *if rad_here
                      Radmar
                      *if kal_here
                        or
                    *if kal_here
                      ${kalt}
                    who stabs you in the back.  The cry of "Traitor!" is going up from too many throats for you to distinguish one from another.  
                    
                    You try to keep your feet and call for help, but your strength is flowing out fast as water, and your voice is inaudible.  The last thing you feel is three more blades driven into your torso.
                    *goto_scene death
                  *if (rad_here or kal_here) and (cha > 1)
                    If you were any less charismatic, you'd probably be killed right now.
                  Breden ${xhim}self blinks increduously at you and says nothing.  "Now to the sick," you declare, desperate to get people moving before your strained authority collapses entirely. "We need to heal them if we can."
                  *set deputy "Breden"
                  *set dephis xhis
                  *set dephe xhe
                  *goto healingvom
                *if (el_here) #Elery.
                  "She's sick, ${addressu}," another outlaw points out flatly. "You need a second who can lead us
                  *if lostem
                    if the Theurges find us
                  tomorrow."
                  
                  That's true, damn it all.  You choose:
                  *goto zvadrepchoice
                *if (simz_here and (s_rel < 9)) #${simon}.
                  "I'll do all I can, ${addressu} ${fname}," ${simon} says soberly. "Angels stand witness."
                  *set deputy simon
                  *set dephis zhis
                  *set dephe zhe
                  *set simz_lead +1
                  *goto healingvom
                #Alira.
                  Your chief ranger looks disapproving, but accepts after only a moment's hesitation. "Now to the sick," she barks. "There must be something we can do to get them back on their feet."
                  *set deputy "Alira"
                  *set dephis "her"
                  *set dephe "she"
                  *goto healingvom
            *goto healingvom
          *if (bred_lover > 19) #"$!{xhe}'s my ${xspouse}, Zvad.  I can't let you kill ${xhim}."
            *goto zvaddep
          #We need Zvad if we're going to survive.  I give a curt nod. "You're right.  Finish ${xhim}."
            *set ruth %+10
            *set bredconsent true
            *set violence +1
            Breden gives a
            *if (bred_lover >= 4) or ((bred_heart = 3) or (bred_heart = 2))
              heart-rending,
            wordless scream as Zvad's maul comes down.
            *if ruthreal <=50
              You can't keep yourself from flinching at the sight.
              
            "That's what traitors and spies have coming," the big ${whend} barks, stepping away from Breden's crumpled form. "Don't anyone else make ${xhis} mistake.  If all signs point to you…don't think we'll wait for proof."
            *gosub breddead
            *goto healingvom
          #"Tie ${xhim} up for now."
            *goto bredtied
      *elseif rad_here
        Radmar's nostrils are flared wide. "$!{addressu}, you're not going to credit this, are you?"
        *goto credbred
      *elseif kal_here
        ${kalt}'s eyes glint like knives. "That's the sorriest excuse for treachery I've ever heard."
        *goto credbred
      *else
        Alira blinks at Breden incredulously, then turns to you. "Even if it's true, ${addressu}, I'd say its their bad luck and you should kill them anyway."
        *goto credbred
      *label credbred
      
      "This…it's some mistake, 
      *if bredwed or ((bred_lover >= 4) and (bred_lover != 13))
        love.
      *if not(bredwed) and ((bred_lover < 4) or (bred_lover = 13))
        ${bfname}.  
      Or worse, it's someone trying to make you think we poisoned you all." Breden steps away from
      *if el_here
        Elery, 
      *if not(el_here) and (c_rel > 0)
        Ciels,
      *if not(el_here) and (c_rel < 1)
        Pereth,
      trembling in every limb but clearly trying to keep panic out of ${xhis} voice. "It wasn't me.  I'm sure it wasn't
      *if rescuer > 0
        Vorne
      *if rescuer = 0
        Gaved
      or Earnn.  What about those who handed it out?  Only half of the band took ill…"
      *if rescuer = 0
        
        Joana Orchard pushes past you, eyes ablaze.  "$!{xgirl}," she snarls, "are you daring to call me a traitor?"
      *choice
        #I don't believe Breden's excuses.  I grit my teeth and turn to ${xhim}, weapon in hand.
          "Angels, Breden.  What kind of fools do you take us for?"
          *set bred_pris true
          *goto bredkilled
        #It is an almost impossibly bad coincidence. I order Breden tied up until we can question ${xhim} further.
          *label bredtied
          *set bred_pris true
          *if deputy = "Breden"
            *set deputy ""
          "Bind ${xhim} and drop ${xhim}
          *if ((horion > 3) and (horion < 10)) or (s_rel > 9)
            in with the other prisoners,"
            *goto bprnext
          into one of the caves under guard,"
          *label bprnext
          you order.  "We'll ask ${xhim} more later.  For now, we've lives to save in the band, if we still can."
          
          Breden doesn't protest, just stares at you with
          *if (bred_lover >= 4) or (bred_heart = 3)
            an expression of betrayal.
            *goto healingvom
          *elseif (bred_heart >= 10) or (bred_trust > 9)
            grim resignation.
            *goto healingvom
          *else
            a hopeless expression.
            *goto healingvom
        #I don't know what to believe…and I'm not going to see anyone killed until I know more.
          "Let ${xhim} be."  You cut off the rising chorus of protest with a sharp, "We'll have more questions for ${xhim} later.  For now, we've lives to save in the band, if we still can."
          *goto dotheyaccept
        #I trust Breden.  If ${xhe} says ${xhe} didn't do this, I believe ${xhim}.
          "Enough," you shout. "I'll not see anyone killed, Earnn or Breden, when we don't even know it was the food that has everyone sick—let alone whether either of them meant it.  We have lives to save in the band.  I'll hear no more accusations until they're saved."
          *label dotheyaccept
          
          *if (morale < followers) and (bred_lead < 16)
            "Damn you, ${addressu}," one of the outlaws snarls back at you. "There's no chance this was anything other than treachery.  Deal with it now, or by all Angels, we will!"
            
            When you hesitate, something seems to snap in the group of bandits.  
            *if inadults > 43
              A half dozen reach Breden at the same time, with ten more just behind them.  $!{xhe} disappears beneath the mob
            *if inadults < 44
              Breden sees their intent and whirls to run…but ${xhe} can't outpace the knives that fly at ${xhis} back.  $!{xhe} topples forward 
            with a scream.
            *gosub breddead
            *fake_choice
              *if (bred_lover >= 4) or ((bred_heart = 3) or (bred_heart = 2))
                #My scream echoes ${xhis} own as I dash to ${xhis} side.
                  All you feel is the longing to sprint fast enough to carry ${xhim} away safe…but even as you start, ${xhe}'s falling, face turned away from you, and you feel as if you're running through chest-deep water.  When you finally
                  *if inadults > 43
                    shove through the vengeful crowd, what's left of
                  *if inadults < 44
                    reach ${xhim},
                  Breden is inert, face-down in the stones.  You spin to face ${xhis} murderers, sucking breath through your nostrils in furious, tearless sobs.
                
                  They stare back at you, implacable. "Walk away,
              *if (bred_lover < 4) and ((bred_heart != 3) and (bred_heart != 2))
                #I shout a vain protest.
                  "What are you doing?" I roar, running to Breden's side.  It's too late—you know that well before you arrive and stand over ${xhis} inert form. "What kind of Xaos is this?"
                
                  "Let it go, 
              #I stare in horror, knowing there's nothing I can do to save ${xhim}.
                There are no more screams, and within seconds your followers have walked away from Breden's inert form. "It's done,
              #I back away, wide-eyed, wondering if they'll come for me next.
                But Breden's death seems to sate their fury. Everyone stares wordlessly at ${xhis} body for a few moments, and then the 
                *if inadults > 43
                  mob 
                *if inadults < 44
                  group
                begins to disperse.  "Enough,
              #My main emotion is relief that ${xhe}'s dead…and that I wasn't the one to give the order.
                "It's done,
            ${addressu} ${fname},"
            *if rad_here
              Radmar growls.
            *if not(rad_here) and kal_here
              ${kalt} says flatly.
            *if not(rad_here) and not(kal_here)
              Alira says thinly.
            "Now there are lives to save if we can, before the Phalangites catch us gutless."
            *if (bred_lover >= 4) or ((bred_heart = 3) or (bred_heart = 2))
              *choice
                #I howl, raise my ${weapon} and hurl myself at the murderous bastards.
                  *label atkmurd
                  *if com > 1
                    A lesser warrior would have died a dozen times against the determined mob.  "For Breden!" you bellow with every outlaw you fell…and after a few minutes the survivors break, shrieking, rather than stand against the fury of ${addressu} ${fname}. 
                    *label plekalone
                    
                    You're left alone in the woods. Even the others who loved Breden are too dismayed to stand beside you.  
                    *label underdespair
                    The undertow of despair quickly saps whatever is left of your fury. 
                    
                    When the deep, throaty howls rise around you later that morning, part of you welcomes them.
                    *if plekspear
                      The magically keen spear fells two Plektoi hounds, but their shocked Theurge handlers pursue you from the air and set you afire.
                    *if not(plekspear)
                      Dying beneath the steely talons of a Plektos hound is terrifying, agonizing—but only for an instant.
                    *goto_scene death
                  Of course, there's no way you could survive against a terrified, furious bandit mob.  You know it, and in your despair and fury you welcome it.
                  
                  *if com > 0
                    You manage to fell a few of them, at least.
                    *if rad_here or kal_here
                      You just wish one had been 
                      *if rad_here
                        Radmar.
                      *if not(rad_here) and kal_here
                        ${kalt}.
                      
                  The last thing you see, beyond the knives plunging into you, is Breden's crumpled form.
                  *if skepreal > 50
                    You've never really believed in an afterlife…but if there is one, you hope
                  *if skepreal <=50
                    If the Angels are merciful,
                  you'll be with ${xhim} soon.
                  *goto_scene death
                *if (theurgy > 0) #I unleash the full fury of my ${wisardry} on them.
                  *label atktheu
                  When you toss
                  *if rad_here
                    Radmar
                  *if not(rad_here) and kal_here
                    ${kalt}
                  *if not(rad_here) and not(kal_here)
                    Alira 
                  and six other outlaws up into the air, then slam them back down again and again as if threshing the rocks with their bodies…it takes only seconds for all the rest to flee, madly shrieking, "Goety!"
                  *goto plekalone
                *if (bred_lover = 13)
                  #I can barely keep my loss and fury in check. "You just killed my… $!{xhe} was one of our best, damn you."
                    *goto onebest
                *if (bred_lover != 13)
                  #I can barely keep my loss and fury in check. "You just killed my ${xspouse}, damn you."
                    *label onebest
                    *if rad_here
                      "We killed a traitor."  Radmar stares at you, lips trembling. "And we don't have to stop there."
                      *choice
                        #I do my best to kill him.
                          *if (theurgy > 0)
                            *goto atktheu
                          *goto atkmurd
                        #"May the Phalangites gut you all." I spit at his feet and stalk off toward the wilderness.
                          Why would you stay a minute longer with the thugs that just murdered your ${xspouse}?
                        
                          *if (int = 2) and ((theuknown < 10) and (theurgy != 3))
                            It's
                            *goto probstab
                          *if cha = 2
                            A less charismatic leader would have been killed while walking away.
                          *if (int = 2) and ((theuknown >= 10) or (theurgy = 3))
                            Only their fear of your ${wisardry} keeps them in check.
                          *if com = 2
                            Only their fear of your ${weapon} keeps them in check.
                          But no one calls for you to come back; even the others who loved Breden are too dismayed to speak up or join you.
                          *goto underdespair
                        #I manage to swallow my rage.  The enemy are [i]outside[/i] this camp…however little I believe that at the moment.
                          "We do have to stop here.  Or throw ourselves on a Phalangite sword."  You turn your back on Radmar to keep yourself from tearing his throat out. "Let's see if there are still any lives we can save."
                          *goto healingvom
                        #I try to hide the terror that runs through me.  One false step now, and I'll be dead too.
                          You shake your head curtly and turn your back on him.  "Time to save lives.  If we can."
                          *goto healingvom
                    *if not(rad_here)
                      "We know how hard it must be for you—learning that your 
                      *if (bred_lover != 13)
                        ${xspouse} 
                      *if (bred_lover = 13)
                        ex-lover
                      was a traitor to the
                      *if kal_here
                        rebellion." ${kalt}'s voice holds
                        *if k_rel > 5
                          nothing resembling
                        *if k_rel < 6
                          genuine 
                        sympathy.
                      *if not(kal_here)
                        band." Alira's voice is steady, implacable.
                    "But we need to do whatever we can to heal the sick, or we'll be helpless before the Theurges."
                    *goto healingvom
                #I nod curtly.
                  *set bredconsent true
                  "Time to save lives, if we still can," you say, hoarse-voiced.
                  *goto healingvom
            *goto healingvom
          *if (morale >= followers) or (bred_lead > 15)
            For a moment, you don't think they're going to accept it.  But enough of them
            *if bred_lead > 15
              still admire Breden,
            *if bred_lead <= 15
              believe in your leadership,
            and they're willing to defer judgment on ${xhim} if you are.
            *goto healingvom
*label healingvom

It takes a few minutes to confirm that 
*set d2n_num bredvom
*gosub d2n
of your outlaws are incapacitated.
*if limb > 0
  *choice
    #And I think I can use ${wisardry} to heal them.  I cut my hand.
      *set consc -1
      In your ${wisardric} trance, you still can't tell what's caused the vomiting—but you can now recognize how your followers' bodies strive to restore the balance of humors.
      *if consc < 1
        By assisting that restoration, you manage to heal around a third of the ones who have been gathered in ${abler}'s tent. Then you find the floor rising up toward you.
        
        When you wake up, your trembling muscles and throbbing head suggest that any further attempt to use ${wisardry} will return you immediately to unconsciousness.  The other sick outlaws
        *if elsick
          (including Elery)
        will have to recover naturally.
        *set inadults +round(bredvom/3)
        *set inwoods +round(bredvom/3)
        *set bredvom -round(bredvom/3)
        *goto plektattack
      *goto healem
    *if (blood > 0) #I pull out a blood phial.
      *set blood -1
      *set usedblood +1
      In your ${wisardric} trance, you still can't tell what's caused the vomiting—but you can now recognize how your followers' bodies strive to restore the balance of humors.
      *label healem
      When you reach out mentally to assist that restoration, the sick outlaws sigh with visible relief.
      
      After the last blood is gone, you hold your breath, waiting to see whether they slip back into illness…but the balance holds.
      *set morale +15
      *if wisardry != "Goety"
        "Thank 
        *if religion < 20
          the Angels 
        *if religion > 19
          sweet swiving kenon
        for your ${wisardry}, ${addressu},"
      *if wisardry = "Goety"
        "Never thought I'd thank the Angels for Goety, ${addressu}," 
      one bandit croaks, standing on shaky legs. "It's a miracle, no doubt."
      *set inadults +bredvom
      *set inwoods +bredvom
      *set bredvom 0
      *set elsick false
      *goto plektattack
    #I'll use what I know of herbs to save them. I want to save my ${wisardry} in case there's a battle ahead.
      *goto herbkn
*if (limb < 1) and (int > 1)
  *if theurgy > 1
    Human bodies are still mostly a blur to you when you go into your ${wisardric} trance; 
  *if theurgy <= 1
    Even if you were willing to experiment with blood magic now,
  you've no idea how you could use ${wisardry} to heal your followers.  But you do remember everything you've ever heard about herbs.
  
  *label herbkn
  Horseroot to restore balance to the humors—fennel and dried barberry to settle the stomach.  It takes an hour or so to get it into everyone, but by the time you've finished, around half of the affected bandits
  *if elsick
    (including Elery)
    *set elsick false
  seem to be recovering.
  *set inadults +round(bredvom/2)
  *set inwoods +round(bredvom/2)
  *set bredvom -round(bredvom/2)
  *goto plektattack
*if (int < 2)
  You all do your best to heal 
  *if bleys >= 10
    them—and thank 
    *if skep <= 50
      Angels,
    *if skep > 50
      whatever powers there be,
    even though ${abler} is barely conscious, Huette Meriwether ate rather less of the pottage. "Herbs," she rasps. "There are herbs that should purge us of this."
    *goto herbkn
  them, but with ${abler} fading in and out of consciousness and barely able to talk you through the contents of his herbiary, there's little you can do.
*goto plektattack

*label plektattack

*if (deputy = "")
  *if bred_pris
    As long Breden is imprisoned and under suspicion, you'll need another deputy.  With Theurges still hunting
    *if lostem
      you,
    *if not(lostem)
      you and an army on your heels,
    this is no time to spend even a single night without a clear second-in-command.
    *goto replbre
  *if ((bred_lover >= 4) or ((bred_heart = 3) or (bred_heart = 2))) and (breden < 1)
    While you can barely force your mind to it…somewhere beneath the pain, you know you'll need 
  *if ((bred_lover < 4) and ((bred_heart != 3) and (bred_heart != 2))) or (breden > 0)
    There's one last thing to attend to before you can return to sleep: choosing
  a new deputy.
  *label replbre
  *choice
    *if (zv_here) #I ${ask} Zvad.
      "Aye, ${addressu}," Zvad rumbles. "I'll be your right hand.  Now get some sleep, if you can."
      
      *set deputy "Zvad"
      *set dephis "his"
      *set dephe "he"
      *set zv_lead +1
      *goto nosleep
    *if ((el_here) and not(elrefuse)) #I ${ask} Elery.
      *if bred_pris and (elsick)
        *goto elrefusing
      *if bred_pris and not(elsick)
        Though Elery's face is still wobbly from illness, the stare she turns on you is sharp and unwavering.  "You think I'd make it easy for you to replace Breden, ${addressu} ${lname}?  Fill ${xhis} place as quickly as possible, so you can just make ${xhim} disappear?"
        
        You give a brief, 
        *if (bred_lover >= 4) or (bred_heart = 3)
          mournful
        *if (bred_lover < 4) and (bred_heart != 3)
          irritable
        shake of your head.  "I've kept Breden alive to explain ${xhim}self when tempers have died down, Skinner.  If I'd meant ${xhim} to disappear, you think I'd be choosing ${xhis} friend as deputy?"
        
        She hesitates only an instant.  "Very well then.  Until ${xhe}'s back."
        *page_break
        *goto elset
      *if (breden > 0) and not(elsick)
        "Aye, ${addressu}," Elery replies, still looking unwell.  "Sorry to see Radmar die, but…aye, I'll take his place."
        *label elset
        
        *set deputy "Elery"
        *set dephis "her"
        *set dephe "she"
        *set el_lead +1
        *goto nosleep
      *label elrefusing
      *set elrefuse true
      *if elsick
        Her voice is feeble, but she manages to rasp,
        *if (breden > 0) or not(bredconsent)
          "You'll need someone who can stand for you
          *if lostem
            if the Theurges find us
          tomorrow, ${addressu}.  Not me."
          *goto replbre
      *if not(bredconsent) and (e_rel > 0)
        Grief and fury are stark in her eyes. "Lead these bastards, ${kuria} ${lname}?  Help you lead the swivers who just murdered ${xhim}?"
        
        "You think I should take one of them as deputy instead?"  You fight to keep your voice low. "You think I could, now?"
        
        Elery stares at you without speaking for a long time.  "Very well, ${kuria}.  I'll be your second."
        *set e_rel +2
        *page_break
        *goto elset
      "No, ${addressu}."  Grief and fury are stark in her eyes. "Breden was just killed, and 
      *if elsick
        you…?"  She doubles over again, retching. "Damn you all."
      *if not(elsick)
        you want me to take ${xhis} place?  Damn you all."
      *goto replbre
    *if (simz_here and (s_rel < 9)) #I ${ask} ${simon}.
      It takes a moment to find ${simon}, who's been helping at the far end of the camp.  But once ${zhe}'s found and the situation's explained, ${zhe} makes a shaky bow to you. "As you need, ${addressu} ${fname}." $!{zhis} voice is troubled but determined.
      
      *set deputy simon
      *set dephis zhis
      *set dephe zhe
      *set simz_lead +1
      *goto nosleep
    *if (kal_here) #I ${ask} ${kalt}.
      "Aye, ${addressu}," ${kalt} says at once. "You know you can count on me."
      
      *set deputy kalt
      *set dephis zhis
      *set dephe zhe
      *set kal_lead +1
      *goto nosleep
    *if ((rad_here) and not(radrefuse)) #I ${ask} Radmar.
      *if bred_pris
        "You can swive yourself, ${addressu}," the big man snarls. "Be your second, when you've kept a traitor alive in our midst?  Not bloody likely."
        *set radrefuse true
        *goto replbre
      "Now you ask?" Radmar says incredulously.  "After giving that bastard a free hand to betray us?  Well, better late than swiving never."
      
      *set deputy "Radmar"
      *set dephis "his"
      *set dephe "he"
      *set rad_lead +1
      *goto nosleep
    #I ${ask} Alira.
      Alira nods at once. "Now get some sleep, ${addressu}," she says, not unkindly.  "We'll need all our strength to deal with this."
      
      *set deputy "Alira"
      *set dephis "her"
      *set dephe "she"
      *goto nosleep
"Get some sleep, ${addressu}," 
*if (deputy != "Elery") or not(elsick)
  ${deputy} 
*if (deputy = "Elery") and (elsick)
  Alira
suggests at last.
*page_break
*label nosleep
You can't sleep.
*if lostem and (violence > 0)
  However exhausted you feel, however far away you know the enemy to be, some part of you is on alert and can't be calmed.
  *set plektoi 3
*if not(lostem) or (violence < 1)
  Your ears and mind are constantly alert for a Theurge attack.
*if ((bred_lover >= 4) or ((bred_heart = 3) or (bred_heart = 2))) and (breden < 0)
  Every time you drift off, visions of a screaming Breden jolt you awake.
More than once, when you're just on the verge of sleep you hear (or imagine?) a distant howl.  Each time you lie utterly still, trying not to tremble or breathe as you strain your ears for confirmation.  Each time, the night is silent for another hour or so.

When a hint of dawn brightens the eastern sky, you finally give up, rise from your bedroll, and take the steep path up toward the top of the mountain.  Alira is with your watch at the first shelf, dark circles under her eyes. "So I'm not the only one, ${addressu}." 
*if breden > 0
  She offers you a haggard, not very mirthful grin. "But there's
*if breden < 0
  She pauses, looking you over. "How are you taking ${xhis} death?"
  *fake_choice
    *if (bred_lover >= 4) or (bred_heart = 3)
      #"What [i]bloody[/i] kind of question…"  It's all I can do not to lash out at her.
        "I'm sorry, ${addressu}."  After several minutes' uncomfortable silence,
    #I stare at her emptily for a few moments, then look away.
      After several minutes' silent commiseration,
    *if (bred_heart = 1) 
      #"$!{xhe} was my friend."  I can't say any more.
        "I know, ${addressu}. I'm sorry."  After several minutes' silence,
    #"I still don't know if it was right."
      "Sometimes you can't know.  But you have to act anyway."
    *if (bred_lover < 4) and ((bred_heart < 1) or (bred_heart > 3))
      #"It was about damned time."
        "Reckon it was."
    #"Had to be done."
      "That it did."  
  Alira turns, stares down into the forest again. "There's 
no Phalangites to see down there.  If they're 
*if not(lostem)
  moving, it's 
*if lostem
  anywhere near us, they'd have had to sneak up
without light.  And we've had no signals from the scouts posted above us."

*if ((bred_lover >= 4) or ((bred_heart > 0) and (bred_heart < 4))) and (breden < 0)
  You do your best to banish Breden from your mind and focus on survival.
*if not(lostem)
  Where are your pursuers?  Surely it's too much to hope that they've lost you.
*if lostem
  Perhaps you really have lost them, and they're turning back to the Rim.  But you can't quite bring yourself to believe it. 
"You hear howls in the night?"  You keep your voice low enough that only she can hear.

"Not sure.  Could have been."  Alira moistens her lips.  "A wolf, maybe.  A good ways off."

"Or…something else they've set 
*if not(lostem)
  on 
*if lostem
  to find
us."  You aren't ready to use the word [i]Plektoi[/i] where anyone else can hear it.  Turning, you stare higher up the crag. "Let's get a better vantage and check with the upper scouts."
*page_break
*if choice_randomtest
  *choice
    #At plekfight, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.  ${inwoods} inwoods, ${inadults} inadults, ${inkids} inkids. ${bredvom} bredvom, ${helcamp} helcamp, ${flee} flee with ${fleelead}.  ${morale} morale.
      *goto postchoice3
*label postchoice3
The route up the mountain grows narrower and much steeper. In places, you have to push yourselves up a nearly sheer ravine or cut through a cave.  You keep to the sparse, scrubby bushes on the slopes as much as you can, mindful of how visible you must be from below, or from the air.  It's deliberately slow going, with one of you always scanning the sky and forest while the other presses onward.

You're approaching the upper crags when Alira breathes tautly from behind you. "$!{addressu}…"  At once you crouch, then very carefully turn to see where she's looking.  

In the woods just below your camp, a figure floats up through the trees—far lower than Theurges usually fly, as if trying to stay close to someone on the ground.  You hear a ripple of whistles and calls as your lower scouts spot the incoming danger, and the first few arrows bounce off the figure's robes.

Then something huge and shadowy slips over the edge of the slope into your camp.
*fake_choice
  #Angels.  Oh, sweet Angels.
  #I share a white-eyed glance with Alira.
  *if (introhlt) 
    #I'm a child in the woods again, and the terror is suffocating.
      It takes all your will to keep from fleeing in the opposite direction, even if it took you over a cliff.
  #My dry tongue can't quite shape the whisper.
*if lostem and (violence > 0)
  Two more enormous shadows follow in the wake of the first. Two more cowled Theurges rise out of the foliage.
Over the shrill cries of your followers, a howl rends the air.
*if not(introhlt)
  It's like nothing else you've heard in your life.
  *if helot
    You've been in the woods when the aristocrats' packs go after a stag, and no dog's throat could make this
  *if aristo
    No dog you ever hunted with could make this kind of
  deep-throated, gravelly roar, as much lion as wolf.  Even
  *if not(lostem) or (violence < 1)
    in the minutes
  before it reappears on the lower slopes of the mountain, you know it can only be a Plektos hound.
  
  The Theurgy-twisted dog is the size of a horse.  Its snout is unnaturally stretched, its hairless neck and shoulders thick with added muscle.  A row of bone spikes emerges between its eyes and runs down its spine to the root of its poised, 
*if introhlt
  Through all those years of nightmares, you knew that one day you'd face the Plektoi again.  Now you stare for
  *if lostem and (violence > 0)
    moments 
  *if not(lostem) or (violence < 1)
    minutes
  of paralysis until
  *if lostem and (violence > 0)
    the first
  one reappears on the lower slopes of the mountain, lashing the air with its spiked,
prehensile tail.

The scouts on the first ledge shriek and sprint for the nearest cave.  You groan, helpless to keep your followers from being savaged…but the Plektos ignores them, snout close to the ground, and continues bounding up the mountain.  It lands on a rocky crag which dissolves into scree under its iron-boned weight.  As the hound scrabbles for purchase, sending a shower of small boulders into the air, you remember climbing up that outcrop just a few minutes ago.

"$!{oath}, ${addressu}.  It's got your scent." Alira's nostrils are flared; her whole body trembles with the urge to flee.

*if plekspear  
  It's strangely calming to find all choice stripped from you—when only one, obvious course of action will keep you alive.  "Get to cover." You fumble for the spear strapped to your back, the one you've been carrying everywhere since you came to High Crag. "Keep the Theurge in your sights.  And when I spear the 
  *if violence < 1
    hound…"
    *choice
      #"Put an arrow into the Theurge."
        *set violence +1
        "They'll be distracted, 
        *if skep > 50
          with any luck."
        *if skep <= 50
          Angels willing."
        
        *goto staystoargue
      #I've managed so far to avoid killing anyone.  "Just…just run. I'll be right behind you."
        *set nonvio true
        *goto staystoargue
  hound…put an arrow into them. They'll be distracted, 
  *if skep > 50
    with any luck."
  *if skep <= 50
    Angels willing."
  *label staystoargue
  
  *if pleksecret
    Amazingly, she stays to argue. "Spears can't hurt a Plektos, ${addressu}…"
    
    "This one will.  Go!"
  As your 
  *if deputy != "Alira"
    chief ranger 
  *if deputy = "Alira"
    deputy
  hurries off up the slope, you run back to a relatively flat stretch.  The ground begins to thrum and tremble beneath your feet.  Your mind goes completely blank. The only things of any substance are the heavy, whorled metal in your hands and the rocks under your feet.  Everything else is intangible, untethered.
  
  A Theurge soars high into the sky, fingers dark with blood.  The Plektos crests the ridge, baying triumphantly, and thunders toward you.
  *choice
    #I set my spear.
      *if com = 0
        Battle a Plektos?  Only the greatest of heroes could do that.  But even someone with no natural combat skill can set a spear to receive a charge.
        
      The giant hound-beast doesn't shy away or slow.  There's a web of white lines on its leathery chest. Perhaps it's been forced to run onto spears until it learned not to fear them, learned that human weapons always splinter before doing any real harm.  It closes the gap between you in heartbeats, jaws agape.
      
      The impact of the Plektos sends you skidding backward, knocks you off your feet.  You hit the ground so hard that the whole world goes white for a few instants.  A roar nearly bursts your ears, a spray of rocks batters your face and body.  Hardly knowing which way you're crawling, you drag yourself blindly away, feeling your own blood slick on your lacerated hands.  The smell of dust and iron fills your nostrils.
      
      When your eyes can focus again, you see the hound thrashing on its back, pawing at the bent spear shaft.  A viscous liquid gouts from its mouth and the gash in its chest, so dark a red that it approaches black.  The spear slips partway out of the wound as if pulled by invisible hands—but the spearhead and crescent blade which split rock so effortlessly have warped on contact with the Plektos's bones, and grate to a halt in its ribcage. The monster vomits more blood, then gives a bubbling howl with a shrill, frightened note you'd never have imagined from its maw.
      
      *if nonvio
        You find your limbs and scramble away through the dust, toward the nearest spill of boulders.  The hovering Theurge remains preoccupied with trying to remove the spear and save his beast.  
        *label boulderspill
        Every instant you expect mage-fire to erupt around you…but it comes only when you reach the first great rock, scorching you and flinging you into a crevice.
        
        The pain is like nothing you've ever felt before, shouting from every inch of exposed skin.  Eyes blindly stinging, you crawl down the steepening slope.  You tumble down one drop, then another; another fireball roars somewhere behind you and overhead.  Then there's nothing under your hands, and you plummet through tree branches and air.
        *page_break
        The first thing you become conscious of is the agony of your skin—still burn-wet, with dirt and forest litter ground into it, scraped on all sides by sticks and thorns.  The second thing is the clamor of Phalangites in battle nearby.
          
        Forcing your sticky eyelids open, you think for a dully horrifying second that you've gone blind.  Then one pattern of shadows against the darkness resolves itself into a thornbush.  You realize that the mass of deadwood and brush into which you've fallen is in one of many dark cavities on the sheer mountainside.  When you manage to crane your neck around, you can see sunlight through trees above you, occluded momentarily by a Theurge in flight.

        Below is a tunnel from which you can faintly hear the cries of fleeing rebels.  Suppressing screams with every movement, you wrestle yourself free of the brush and crawl down into the caves to join the retreat.
        *page_break
        *goto sprintdark
      A far thinner shriek draws your eyes upward.  An arrow protrudes from the Theurge's side, just below the ribs; he clutches at it before folding over and plummeting headfirst from the sky.  Grappling with the spear and keeping his coat armor-hard were too much Theurgy to manage at one time.  You look back to see the Plektos's death throes carry it over the lip of the slope.  By the time it slams onto the lower ledge, it's no longer howling, just twitching and clawing feebly at the stone.
      
      Tears sting your eyes as you struggle dizzily to your feet.  [i]$!{oath}. $!{sweetoath}.  I'm alive.[/i] 
      *goto plektwar
*if cha < 2
  Staring down at your approaching death, you feel clarity descend, and with it a moment of inexplicable calm. "We'll have one chance, Alira.  Get to cover, but keep us in your sights.  And when I knock the Plektos off the 
  *if violence < 1
    mountain…"
    *choice
      #"Put an arrow into the Theurge."
        *set violence +1
        "They'll be distracted, 
        *if skep > 50
          with any luck.
        *if skep <= 50
          Angels willing.
        One chance.  Don't waste it."
        
        *goto alirahurry
      #I've managed so far to avoid killing anyone.  "Just…just run. I'll be right behind you."
        *set nonvio true
        *goto alirahurry
  mountain, put an arrow in the Theurge.  One chance.  Understand?"
  *page_break
  *label alirahurry
  As your 
  *if deputy != "Alira"
    chief ranger 
  *if deputy = "Alira"
    deputy
  hurries off up the slope, you scramble down—down and away, to a narrow ledge that curves around the side of the mountain.  A scattering of stones rolls ahead of you. You stop just before the point where the stones plummet into air.
  
  [i]$!{oath}, this is such a terrible plan.[/i]  For an instant, swaying on the edge of the cliff, you see your followers in the grove far below.
  *if lostem and (violence > 0)
    The two other Plektoi run amongst them, noses to the ground. They gut a few with snaps of their tails, but mainly bound through the fleeing crowd, hunting for something or someone.
  *if not(lostem) or (violence < 1)
    Most are fleeing into the caves, while a handful point shakily up at you, and at things just beyond the field of your vision.
  *if int > 1
    Then you hear a rumbling from the ridge behind you.  In seconds, the beast will be here.
    *choice
      #I cut my hand and prepare to use ${wisardry} to levitate it.
        *set consc -1
        *if consc < 1
          *label ohnoplek
          To your horror, as soon as you try to focus you feel your consciousness bleeding inexorably away.  If
          *if blood = 0
            you'd had any phials of aetherial blood, or if
          you'd not been forced to use your own blood so often for ${wisardry}, perhaps you'd be able to keep your feet through the levitation.  
          
          As it is, you try to lift the giant hound-beast when it thunders, baying, over the ridge…and the world goes dark before your eyes.  Your only remaining choice is whether to let yourself topple backward over the cliff, or fall supine and be savaged by the beast.
          *fake_choice
            #I'll not give them the satisfaction of killing me.
              The giddy acceleration and wind whistling past your ears are the last sensations you feel.  Many of your followers will, alas, have far worse ones.  But you'll not be there to share their fate.
            #Let the Plektos have me.  I won't kill myself.
              Perhaps it will inspire your followers to fight rather than flee to their deaths.  Perhaps the horror of seeing your body gnawed by the Theurge-hound will break their mettle.  You'll never know.
            #I refuse the choice and lash out with all the strength I have left.
              You shriek and [i]pull[/i] outward with all your might—consuming all the blood in your hand, your arm, your body.  And the slope peels away toward you in a great eruption of stone, carrying the yelping Plektos with it.  
              
              With every ${wisardric} sense heightened, you sense other lives snuffed out in the rock storm above you: Alira, the Theurge, your scouts on the broken mountain peak. Then what's left of you flies backwards off the cliff with what's left of the ledge.
              
              The thunder of the mountainside coming down around you is the last thing you hear.
          *goto_scene death
        *label plektheurgy
        *if theurgy < 2
          *achieve theurge
          You've resisted the temptation to make use of blood magic for months, but it's all you have to fall back on now.  Long ago,
          *if theurgy = 0
            despite your qualms,
          you memorized the mental exercises from your contraband scroll.  Now you begin to run through the litany, pushing back your terror.  "I look beyond the ephemeral. I see the nature of things, their reasons for being, the final causes of all their motion…."
          
          Time seems to slow, and the world shimmers as if you're falling away from it.  Struggling with the sensation of your mind floating away from your body, you try to concentrate on the clearest thing around you: the stones of the mountain, solid and anchored to the earth.
          
          The words of the scroll fly through your mind: "I see that nothing comes into the world without purpose.  Fear does not cloud my vision.  I see the world without its masks.  I see myself without a mirror.  I see the ends of all things…."
          
          At that moment, your perceptions shift.  Your disorientation isn't you falling away from the world.  Rather, you are directly sensing the world falling all around you, the stones and water striving downward and the air and fire upward, each element seeking its natural resting place in the cosmos.  
          
          And the detachment you feel from your own body and brain is not an impending blackout.  You can sense yourself as a blur, a maze of conflicting causes and purposes—a formidable knot to be contemplated, untangled, and retied in any way you choose.
          
          "And I know," you whisper.  "I am the nature behind nature.  I am the cause beyond the final cause."  A great slavering beast appears on the ridge above you, baying triumphantly.  You raise one bloody hand toward it as you complete the litany:
          *page_break "I am a Maker of Change."
          *goto levplek
        *elseif theuknown < 10
          You've kept your gifts a secret for so long.  Today, at last, the day comes when you'll be able to hide them no longer.
          
          Above you, a Theurge soars high into the sky, fingers dark with blood.  The great hound crests the ridge, baying triumphantly.  You stretch out one hand toward it.
          
          *goto levplek
        *else
          The giant, baying beast appears on the ridge above you. Mingled with the unusually hard earth of its flesh, you can sense the fire that warms and gives suppleness to every living creature.  You coax that fire into rising—and find yourself opposed.  
          
          An implacable will contends with your own, keeping the Plektos unChanged.  As the hound charges down the slope towards you, you see its keeper floating behind it, one bloodied hand outstretched toward you.
          *choice
            *selectable_if (blood > 1) #I break two blood phials and strive harder to lift the beast.
              *set blood -2
              *set usedblood +2
              *goto levplek2
            #I fight back against the Theurge with all my will.
              *set consc 0
              You can sense the blood draining from your hands, your arms, your chest.  For just a moment, head brutally athrob, you feel what it would be like to hurl yourself into one grand eruption of power—to die like one of the hero Theurges of the ancient legends, bringing the mountain down around you.
              
              *label levplek2
              The Theurge dips in the sky, pulling out more phials.  He's trying to handle far more than you—levitation, armoring himself, protecting the Plektos—and when you suddenly pour all of your power into levitating only the front paws of the hound, he can't shift his own focus quickly enough.
              
              Instants before reaching you, the beast finds its forelegs yanked steeply into the air.  It bellows in shock, scrabbles furiously at the mountainside with hind claws that suddenly bear its whole weight.  You dive away from the blindly skidding hound and the cascade of rocks behind it.  Its spiked tail whistles past your ear, a mere finger's breadth away.
              
              Then your mental grasp is pushed away.  The Plektos slams back to earth just as the mountainside vanishes beneath it.
              *goto levplek3
            #I jump off the cliff just before the Plektos reaches me, using my remaining power to levitate.
              You wait until you can almost feel the spray of the great hound's spittle…then hurl yourself backward with all your might.  The wind whips around you as you fall. The Plektos digs in its claws at the edge of the cliff and roars furiously down at you.
              
              While it's still struggling to get a firm grip on the ledge, you reverse your fall and levitate yourself slowly, terrifyingly, into range of that great spiked tail.  As you'd hoped, it can't resist.  When you see its muscles bunch, you hurl yourself upward as fast as you can.  
              
              The Plektos lashes out, barely misses you, and plummets from the cliff.  It jerks to a halt—caught by Theurgy in midair—then drops again.  Its final howl ends abruptly at the foot of the crag.
              *if lostem
                
                Alira must have put an arrow in its handler, 
                *if not(nonvio)
                  as you'd planned.  
                *if nonvio
                  despite your orders.
                If this had been the only Plektos, the only Theurge attacking your camp, you might have survived.  But you've made yourself far too conspicuous to the other hounds' keepers…and your moment of glory ends in a burst of Theurgic flame.
                *goto_scene death
              *if not(lostem)
                *goto scramb
        *label levplek
        As the Plektos springs for you, you can sense the elemental mix in its flesh; mingled with unusually hard earth is the fire that warms and gives life and suppleness to every creature. For the first time
        *if theuknown < 10
          in public,
        you coax that fire, encouraging its tendency to rise.
        
        And the great beast flies upward, howling in surprise.  Its flinty claws clash less than a yard overhead; the spiked tail whips down a second too late, grazing your scalp rather than splitting your skull.
        
        The cascade of rocks almost knocks you from the ledge.  As you dodge, you let go of your mental grasp on the Plektos.  From far above, you hear an incredulous shriek of, "Goety!"
        *label levplek3
        *if consc = 0
          *if nonvio
            And your consciousness slips away, never to return.
            *goto_scene death
          Sinking weakly to your knees, you see the beast stopping, caught by Theurgy in midair…and then you can't keep your head up or eyes open any longer.
          *page_break
          When you realize that you're being dragged over stones, for a moment you have a terrified image of a hound pulling you away in its teeth.  But your flailing hands strike arms, not jaws.
          
          "Xthonos!  It's me, ${addressu}." 
          
          You've never been half so glad to hear Alira's voice. "How…"
          
          "Shot the Theurge.  Must have been trying so hard to keep the beast from falling, he couldn't keep his armor up.  The Plektos hit the rocks hard enough to kill it."
          *goto plektwar
        The hound plummets from the cliff, jerks to a halt—caught by Theurgy in midair—and then drops again.  Its final howl ends abruptly at the foot of the crag.
        *label scramb
        
        *if nonvio
          The Theurge has been distracted by arrows flying around him, despite your orders.  But they don't seem to be finding any weakness in his armor, and he's raining fire down on a stretch of slope above you.
          *page_break
          You flee desperately toward the nearest spill of boulders.
          *goto boulderspill
        Scrambling up the hill, you find Alira looking shaken but triumphant.  "You were right, ${addressu}."  She points over the edge of the cliff. "Fell down there when my arrow took him.  Must have been trying so hard to keep the beast from falling, he couldn't keep his armor up.  
        *if religion < 20
          Thank Angels."
        *if religion > 19
          Thank Ang…thank swiving bloody kenon."
        *goto plektwar
      *selectable_if (blood > 0) #I use a blood phial.
        *set blood -1
        *set usedblood +1
        *goto plektheurgy
      #I don't want to use Theurgy.
        Instead, you'll…
        *label alternativeless
        *disable_reuse
        *choice
          #Try to dodge and let it fall off the cliff.
            You're clever enough to know that won't work.  Just possibly if you were a skilled fighter…but you know the Plektos is too fast for you, and would gut you easily with its spiked tail.
            *goto alternativeless
          #Fight the beast.
            A joke, surely.  Even if you were an extraordinary warrior, you couldn't best a Plektos hand to hand.
            *goto alternativeless
          #Run away.
            Where to?  It's far too fast, and even if you found a mountainside cranny too small for it, its keeper would burn you out.
            *goto alternativeless
          *if (not(choice_randomtest)) #Throw myself from the cliff.
            You sway on the edge.  Some part of you is desperate to live.  Another is ready to die.
            *choice
              #I've no choice.  No blood magic, not ever.
                The giddy acceleration and wind whistling past your ears are the last sensations you feel.  Many of your followers will, alas, have far worse ones.  But you'll not be there to share their fate.
                *goto_scene death
              #No.  I'll use ${wisardry}.
                *goto alternativepick
          #Use Theurgy after all.
            *label alternativepick
            *if blood > 0
              I want to…
              *choice
                #Use a blood phial.
                  *set blood -1
                  *set usedblood +1
                  *goto plektheurgy
                #Use my own blood.
                  *goto cutplek
            *label cutplek
            You prick your hand, drawing blood.
            *set consc -1
            *if consc < 1
              *goto ohnoplek
            *goto plektheurgy
  Then you hear the triumphant baying from behind you, and turn to face the hound-beast.  
  
  It springs down the slope toward you, skidding on a wave of scree.  Behind the Plektos, a Theurge rises into the air, fingers dark with blood.
  *fake_choice
    *if aristo and (natl >= 50)
      #"For the ${lname} and Shayard!"
    *if aristo and (natl < 50)
      #"For the glory of the ${lname}!"
    #"Come get me then, you bastard!"
    #I breathe a prayer.
    #I'm poised and silent.
  *if weapon = "sword"
    Sword
  *if weapon != "sword"
    Knife
  in hand, you balance lightly on the balls of your feet.  Your senses are heightened to such a degree that you almost lose yourself—you're the least vivid object in a world of tumbling stones, crushed pines, and the roaring, black-eyed monster.  Yet when the hound is almost upon you, you fling yourself to one side as smoothly as any dodge you ever made
  *if helot
    in a crowded scrum.
  *if aristo
    in the Keriatou practice yard.
  You duck out of the way of its whiplike tail, which grazes your shoulder rather than splitting your skull.
  
  You'd half-hoped that the Plektos's momentum would be unstoppable, that it would carry itself over the edge in a landslide, but its claws bite into the stone of the mountainside, and it halts itself with one hindleg clinging to the cliff wall.  When its baleful gaze meets yours, the animal urge to flee nearly overwhelms you.  
  
  Instead, before it fully regains its balance, you 
  *if weapon = "sword"
    lunge for it and just manage to bury your blade in 
  *if weapon != "sword"
    whip your blade into
  one deep-set eye.

  *if weapon = "sword"
    The sword rams against bone.  The creature's designers would have left no such easy pathway to the brain.  But the
  *if weapon != "sword"
    The 
  half-blinded Plektos snaps its head back with a bellow, loses its grip on the stone, and topples from the edge.  It jerks to a halt—caught by Theurgy in midair—but a moment later drops again.  Its final howl ends abruptly at the foot of the crag.
  *goto scramb
*if cha = 2
  "Run."  Maybe if you better understood ${wisardry} or combat, you'd have some idea of how to stop the beast.  As it is, you can think of nothing but the animal urge to flee in the opposite direction from your hunter and find some cranny to hide in.
  
  Alira vanishes into the scrub brush while you run up the trail.  It ends in a ravine with great boulders providing a sort of cave roof. At the end, there's a sheer rock face with a gap overhead.  Your three mountaintop scouts peer down at you from the gap, eyes wide.  
  
  Given a minute, you could find a way to climb the rock face.  But all any of you hear is the howl of the Plektos outside, the thunder of its charge toward your hiding place.  You know the ravine isn't narrow enough to keep its wedge-shaped head from reaching you.
  *fake_choice
    *selectable_if (cha < 2) #"[i]Help![/i]" I shriek, hands outstretched and flailing.
    #"Pull me up!" I bellow, managing to keep control of my voice.
    *if (religion > 0) 
      #"Pull me up, ${addressc}," I shout, trusting that they won't let their religious leader die.
  Though they plainly want nothing more than to flee, at your command they stretch their arms downward.  You leap as high as you can, and just manage to catch their hands.  Seconds after they haul you up, the Plektos's jaws snap beneath you, flecks of its saliva spraying your legs.
  
  You catch up a stone the size of your head and hurl it onto the hound's skull with a near-scream.  It bounces off with as little damage as if you'd thrown a pillow.  The Plektos snorts and slithers back out of the crevice.  "How could it get up here?" you gasp.
  
  "There's…there's a slope," one of your scouts whimpers, hand trembling almost too much to tell which way he's pointing.
  
  "Follow me."  At the note of confidence you somehow manage to keep in your voice, they fall in behind you.  The slope is steep and crumbling, and ends in a cliff. You wouldn't set foot on it if you had any other choice.  But you fear the Plektos's great claws will get it up to you.
  
  Then you notice that one of the crags next to you has weathered to a stone pillar with a base eroded enough that you could topple it.  "$!{oath}. Help me get that down."  
  
  Shoulder to shoulder against the crag, all you can see and feel is the rough rock. But you hear a snuffling and rattle of scree below, smell piss from one or more of the groaning outlaws next to you.  Then the pillar topples…revealing both the Plektos beginning to clamber up the slope and its keeper flying just overhead, fingers limned with fire.
  *page_break "Push it down."
  Had you been any whit less charismatic, you're sure the vision of death above and below would have paralyzed your outlaws.  But they crouch alongside you to send the pillar rolling over the lip of the slope, toward the scrambling Plektos.
  
  The flames vanish from the cowled Theurge's hand as he extends it toward the great stone.  
  *if violence > 0
    But even as the pillar slows, an arrow sprouts in the mage's side.  He drops with a shriek.  
  *if violence < 1
    But though the pillar slows, it has destabilized the fragile slope too much for any mage to halt.
  The Plektos is hit by a rockslide that carries it down and over the cliff. Its howl is drowned by the roar of cascading stones.
  
  *if violence < 1
    And then you're ducking back down to the ravine, flinging yourself down the drop and scrambling for the nearest spill of boulders.
    *goto boulderspill
  When you run back to the ravine, you see Alira crouched there, another arrow nocked in her bow.  The relief in her face is too deep for a smile. "$!{addressu}. Thank
  *if religion < 20
    Angels.
  *if religion > 19
    Ang…thank bloody kenon.
  I'd hoped you'd think of something that would distract the Theurge enough to drop his armor."
*label plektwar
*set plektoi -1
*page_break
*if not(lostem)
  You think numbly, [i]This is why the army hasn't come yet.[/i]  A Theurge's control over Plektoi famously grows tenuous with the presence of more prey; 
  *set d2n_num alltroops
  *gosub d2n
  of the Archon's forces would be nearly irresistible.
  
"That hound had you in its nostrils, ${addressu}," Alira says again, her usually steady voice quavering. "Coming for you.  Ignored half the band."

*if not(lostem)
  What better way to break our confidence before the final battle than sending in a Plektos to cut off the rebellion's head?
*if rescuer = 0
  "$!{oath}…I'm not the only one," you say, bile rising in your throat.
"If it has my scent…"
*if lostem
  Then you hear more howls from below, and the rising shrieks of a band about to dissolve in utter panic.
*if hosthem != "them"
  *set hostages "hostage"
*choice
  #Father!
    *gosub seebelow
    
    It takes you long minutes to run down the mountain to the last ledge.  None of your guards are left there. You can hear the boldest ones calling to you from the caves, imploring you to join them while you can.  But you linger at the edge under a sheltering pine, staring down into the woods.
    *gosub daddead
    
    Then
    *if not(lostem)
      *label slopesbelow
      on the slopes below your camp you spy the first Phalangites breaking cover—confident that they'll find your positions undefended, with the Plektos having killed you and descended the far side of the mountain.
      *choice
        #I try to bring my outlaws back out to resist them.
          *if flee > 0
            "We need to stand here," you implore your panicking followers. "At least slow them down long enough to give ${fleelead} and the rest a chance to escape."
            
            *if inadults < 40              
              But it's in vain.
          *if inadults < 40
            With only 
            *set d2n_num inadults
            *gosub d2n
            healthy adults left in the band, no one but you believes that it's still possible to stand against the enemy.
            *if kal_here
              Even ${kalt} shakes ${zhis} head and says curtly, "Fight another day, ${addressu}.  We've not got the numbers left to make any kind of a stand here."
            *if not(kal_here) and rad_here
              Radmar exhales angrily through his nostrils and says, "Another day, ${addressu}. When we've more healthy rebels left to us."
              
            *goto retreating
          *if (com+cha) < 3
            If you were more charismatic or a better general, you might have persuaded them.  As it is, they're too terrified; four or five break for the caves, with the rest following within seconds.  Behind you, you can hear the triumphant cries of the oncoming Phalangites.
            
            *goto retreating
          *if not(cragprep)
            If you'd not told everyone you'd be retreating in the morning—if you'd put the time into readying defenses—they might have listened to you.  But no one's prepared to make a stand now.
            *goto retreating
          *if ((com+cha) > 2) and cragprep
            Only a
            *if cha = 1
              moderately
            charismatic leader with
            *if com = 1
              at least some
            combat skill could have persuaded them back to the defense.  Thankfully, you are that leader, and within minutes the smudgefires are kindled.
            
          *goto armyfight
        #I order the retreat.
          *if flee > 0
            Your bold plan to delay the enemy advance has dissolved in the face of reality.
            *if inadults < 40
              You know you don't have enough healthy rebels left to make any real stand.  The only hope you have left is to flee and save as many as possible.
          *goto retreating
        *if (dadfeel > 0) #I'm paralyzed with despair.  Let them take me.
          Alira tries to pull you away. "$!{addressu} ${fname}…we can't stay here.  Live, and avenge him."  Her voice is thick and terrified in your ear.
          *choice
            #I stumble after her to the caves.
              *goto retreating
            *if (not(choice_randomtest)) #"Go, Alira.  Go and live."
              She turns and runs.  You can hear her brusquely rallying the survivors of your band to retreat.  Perhaps some of them will survive. Even through your anguish, you can find it in you to hope so.
              
              Minutes later, a Phalangite arrow takes you in the chest.  The pain is startling, dropping you to your knees, and your life ends in gasping horror as your lungs fill with blood.  
              
              But at least it's spared you from interrogation and Slow-Harrowing.  Your world goes black before any enemy has the chance to identify you.
              *goto_scene death
    *if lostem
      *label shatterhowl
      a throaty howl shatters the silence.  A second Plektos is bounding up the rocks.
      *if (dadfeel > 6) or (dadfeel = 0)
        You and Alira flee as one for the caves.
        
        *goto plekcave
      *if (dadfeel > 0) and (dadfeel < 7)
        Alira dashes for the caves.
        *choice
          #Acting on instinct alone, I flee alongside her.
            *label plekcave
            The mage-hound thunders after you.  Its howl brings a shower of sharp fragments from the ceiling.  You do your best to ignore it, running like mad for the stream that carved out the cavern—and in particular, the point where it drops away into a series of waterfalls.
            
            You're a step behind Alira in sliding down the first chute.  As you land on her, the shadow of the Plektos blots out any light above you.  You and Alira tumble bruisingly down the next five-foot cascade while the hound's snout snaps and slavers through the crevice above you.  As you'd hoped, the watercourse is narrow enough that the Plektos can't fit its shoulders in.
            *if int > 1
              *choice
                #I use Theurgy to pull the cave roof down onto the beast.
                  *if blood < 1
                    *goto cavetheuplek
                  *else
                    Using your own blood, or a phial?
                    *choice
                      #My own blood.
                        *label cavetheuplek
                        *if consc < 1
                          You feel your head begin to spin, and realize you won't have the strength to wobble a rock—not so soon after you last drove yourself into unconsciousness.
                          *if blood > 0
                            Before you collapse, you fumble for a blood phial.
                            *goto bloodph1
                          Giving up the plan, you roll away.
                          *goto notheupl
                        *set consc -1
                        *gosub theucavepl
                        *if consc < 1
                          *page_break
                          *set plekfight +1
                          When you regain consciousness, Alira has dragged you down into a dim-lit cavern filled with other terrified outlaws. "You killed the Plektos, ${addressu}," one says quietly.  "Just one left.  Heard it howling out there."
                          
                          *goto fight
                        *goto darkplek
                      #A phial of aetherial blood.
                        *label bloodph1
                        *set blood -1
                        *set usedblood +1
                        *gosub theucavepl
                        *label darkplek
                        
                        You're braced for falling rocks, but all that hits you is a shower of iron-smelling blood.  No sound of movement or breath comes from the great beast above you. "Swive me if you didn't kill it, ${addressu}," Alira's faint voice sounds in your ear.
                        
                        The two of you clamber down through the darkness until you come to a dim-lit cavern where a
                        *if inadults > 100
                          few
                        dozen outlaws are waiting, wide-eyed.  "There's one left out there, ${addressu},"  one of them whispers.  "Heard it howling right awful."
                        *set plekfight +1
                        *goto fight
                #I slide further down before it can bring its spiked tail to bear.
                  It's not easy to disentangle yourself from Alira when you don't dare to raise yourself more than a few inches.  But you manage somehow, and slide down the next waterfall in the crevice.
                  *goto notheupl
            *label notheupl
            
            The Plektos begins to tear at the rock with its steely claws, like a hound going after a rabbit in sandy soil.  You and Alira keep scrambling bloodily downward and forward while ever-larger chunks of stone shower down behind you.
            
            At last you reach a dim-lit cavern where a
            *if inadults > 100
              few
            dozen outlaws are waiting, wide-eyed.  One whispers, "They're at either end, ${addressu}. Heard another just outside, howling right awful."
            *goto fight
          *if (not(choice_randomtest)) #I let it take me.
            As the hound thunders closer, you shut your eyes and cling to the little pine.  A relief rises in you, bigger than the terror.  [i]No more pain.  The fight is someone else's, now.[/i]
            
            It's all over in a moment.  You barely have time to feel the crushing weight of the beast before you're gone.
            *goto_scene death
  *if (lostem) #Get myself to cover.  They can find me!
    *gosub seebelow
    
    *if campsite > 0
      There's a cave you remember from your earlier explorations—a way out, too narrow for the Plektoi to follow you.  If you get to it quickly enough, you might be able to get out into the woods, far enough away that they'll find it hard to pick up your scent.  For a few days, at any rate.  [i]How long can they keep Plektoi unleashed in a place like this?[/i]
      
      You beckon Alira down into a ravine, then a broad cave, heart pounding.  Long before you get to the exit you were hoping for, you hear a howl carry up the tunnel.
      
      Alira's lips press together for a moment, trembling.  "The air flow, ${addressu}.  I think it can smell you."
      
      From what you've seen of the Plektoi, you'd bet they can writhe or claw their way past any obstacles in this section of the cave system.  Your mind races to come up with any other option.  "Follow me."
      
      Minutes later, you emerge from a different tunnel onto a precipice.
      *gosub codingefficiency
      
      Alira tests the narrow, crumbling ledge, then looks up the not-quite sheer slope above you.  It takes the two of you only seconds to agree on a desperate plan.  Then you run back into the tunnel, hearing the sound of human feet.  Young Earnn and another ranger sprint into view.  "It's coming, ${addressu}," Earnn says shrilly. "A minute back, at most!"
      *label thinveneer
      
      "I'm waiting here for it," you say, hoping your voice conveys your thin veneer of calm rather than the panic just underneath.  "When you reach the cliff, climb up to join Alira. Go!"  Their footsteps fade behind you, replaced by a growing rumble in the darkness.
      *goto beedrop
    Surely in all the caves that dot this mountain, there must be at least one too narrow for Plektoi to pass through—one which can lead you out into the woods, far enough away that they'll find it hard to pick up your scent.
    
    Perhaps if you'd had any more time to explore High Crag, you'd know where it was. But when you descend and begin hunting for it, it's only a few minutes before
    *goto shatterhowl
  *if not(lostem) and (not(choice_randomtest)) 
    #The army will surely follow this attack, perhaps with more Plektoi. I need to call a retreat, now.
      It takes precious time to descend the crag and muster your terrified troops. By the time you finally pull back into the caves, the first rank of Phalangites are breaking cover on the slope behind you.  They're moving swiftly, confident that they'll find your positions undefended after the Plektos assault.
      
      *goto retreating
  #Rally the outlaws before they break.
    You dash down the mountain, Alira two steps behind. 
    *if not(lostem)
      As you descend,
      *goto slopesbelow
    *set plekfight +2
    *gosub seebelow
    
    *label cavefight
    Hurrying into one of the larger caverns, you find your followers on the verge of a rout.
    *if simz_here and (s_rel < 9)
      The shrill shout of, "Get out of my way, you yaudswiving aristo!" that you hear as you arrive tells you both that ${simon} is doing ${zhis} best to rally them, and that ${zhe}'s failing.
      
      *comment endif
    *if not(kal_here)
      "I've killed one of them," you call.
      *if cha > 1
        The crowd of bandits turns at once and floods toward you, desperately reassuring themselves that you truly are alive.
      *if cha = 1
        *set morale -round(inadults/16)
        Every eye turns in your direction, but while they're clearly glad to see you, you don't know how long you can keep them from breaking.
      *if cha < 1
        *set morale -round(inadults/8)
        Barely anyone listens. That leaves at least two more, after all.
      "Don't flee!  Out in the open woods, we'd have no chance.  We're in terrain we can use against them.  That's the only reason I'm still alive."
      
      "Plektoi, ${addressu}!" one of them wails. "How by Xaos are we supposed to stand up to Plektoi?"
      
      *if plekspear and ((deputy = "Alira") or (deputy = simon))
        "This spear," you say quietly, pointing to the whorled steel weapon in ${deputy}'s hands. "I've killed one of them with mine."
        *goto plekin
      *if int > 1
        "$!{wisardry}," you say with quiet confidence,
        *if consc < 1
          even though the very thought makes your head throb,
        "and strength of will."
      *if com > 1
        "Go for the eyes," you shout. "Put spears into their gullets.  Drop boulders on them.  Run them off cliffs.  They're tough, but they do die."
      *if cha > 1
        *if (religion > 0) and (religion < 20)
          "The grace of the Blessed Angels and the power of Almighty Xthonos."  The utter conviction in your voice sets your followers' faces alight. "Stand against these unnatural beasts in Xthonos's name, and we will fell them."
          *goto plekin
        You gesture at the handful of scouts next to you.  "We did it.  Together, we kept our courage, and a Plektos hound and its Theurge are both dead.  Keep courage with me now, and we'll kill these others."
    *if kal_here
      Only ${kalt} seems to be keeping them from scattering to the winds.  $!{zhe} grips the shoulder of one wavering bandit and speaks in a voice loud and cutting enough to be heard over the babble.  "Run, and you die.  They'll pick you off one by one.
      *if (kids > 2) and (flee = 0)
        And then they'll take the elders and children.
      Your only hope is to stand with me—here, together, now!"
      *if plekspear and (deputy = "kalt")
        $!{zhe} brandishes ${zhis} whorled mage-spear.
        *if pleksecret
          "And with this—with this Theurgy-forged spear—we'll kill them."
          
          There's an awed, disbelieving murmur.
        "The ${kuria}'s already killed one with ${his} spear," Alira calls. Every eye turns to you.
        *goto plekin
      
      "Against Plektoi?" someone cries disbelievingly.

      ${kalt} bares ${zhis} teeth wolfishly.  "There's no escaping the Thaumatarch's hound-pack.  The fools have left us no choice."  $!{zhis} voice rises with joyous, feverish conviction.  "So stand and fight as they charge!  Fight even as you feel their damned teeth in you!  Keep fighting those monsters until the last breath leaves your body!  
      
      "Because I swear—the last thing you'll see will be your brothers and sisters killing it, cutting down a Plektos.  And you'll go proud and laughing to the Angels, and say: When they came for us, I saw the impossible.  I saw the Plektoi lose.  I saw them die.  [i]I beat them.[/i]"
      *set kal_lead +2
    *label plekin
    
    *if kal_here
      ${kalt} is
    *if not(kal_here)
      You are
    cut off by a roar and a shower of stones from the ceiling.  A Plektos bounds into the cavern, jaws agape and tail poised to strike.
    *if plekspear and ((deputy = kalt) or ((deputy = "Alira") or (deputy = simon)))
      *set plektoi -1
      *set plekspear false
      When ${deputy} runs for it with a yell, it pounces onto this importunate prey—and rolls away, clawing at the bent spear and shrieking.  
      *if (deputy != "Alira")
        Alira 
      *if (deputy = "Alira")
        A scout
      is at the ready with her bow and puts an arrow into the shocked Theurge who hovers at the cave mouth.
      *set plekkeepers +1
      
      The third beast sniffs warily at its dying packmate before padding into the cave.  Even if you'd had a third spear, you don't think this Plektos would be charging onto it.
    *label plekrallych
    *choice
      *hide_reuse *if (int > 1) #I use ${wisardry} to bring down part of the cavern ceiling onto the hound.
        *if blood < 1
          *goto cavethplek
        *else
          Using your own blood, or a phial?
          *choice
            #My own blood.
              *label cavethplek
              *if consc < 1
                You feel your head begin to spin, and realize you won't have the strength to wobble a rock—not so soon after you last drove yourself into unconsciousness.
                *if blood > 0
                  Before you collapse, you fumble for a blood phial.
                  *goto bloodph2
                *goto plekrallych
              *set consc -1
              *goto darkplek2
            #A phial of aetherial blood.
              *label bloodph2
              *set blood -1
              *set usedblood +1
              *label darkplek2
              *gosub theucavepl2
              The next sensation you have—besides dull, pervasive pain—is the sticky mix of dust and blood that grits against your skin when you roll over.  Forcing open your eyes, you can just make out the shadows in faint light that's somehow made it through a narrow crevice and the haze of the collapse.  You become aware that around you are the bodies of
              *if inadults < 31
                a quarter of your 
                *set cas +round(inadults/4)
                *gosub cascheck
              *if inadults > 30
                *set cas +12
                *gosub cascheck
                twelve
              remaining followers, pulled out of the cave-in by the dazed survivors. 
              
              "$!{he}'s alive!" comes a shocked voice. "Angels, you were right—${he}'s alive."
              
              *label clusterround
              The remaining outlaws cluster around you, speaking in low tones.
              *if plektoi = 0
                "That's the Plektoi dead, ${addressu}…all three of them.  The last Theurge flew off.  Probably back soon with Phalangites in tow." A haggard smile doesn't leave ${deputy}'s blood-streaked face.  "But…${oath}, ${addressu}.  We did it.  They sent three Plektoi after us, and we
                *if deputy != simon
                  swiving
                killed them all."
                *goto slipaway
              *else
                "There's one of them left, ${addressu}.  Heard it sniffing round what was left of the entrance, then howled and ran off. Probably looking for another way in right now."
                *goto fight
      *selectable_if (com < 2) #I lead an attack on the beast.
        *if kal_here
          ${kalt} is at your shoulder, along with a swarm of your followers.
        *if simz_here and (s_rel < 9)
          ${simon} is at your shoulder, ${zhis} teeth bared and
          *if s_sword != 1
            crude
          sword in hand.
        *if not(kal_here) and ((cha > 1) and (morale >= inadults))
          The rest of the outlaws in the cave are hard on your heels. Terrified you may all be, but they'd sooner die at your side than be picked off a few at a time.
        *if not(kal_here) and ((cha < 2) or (morale < inadults))
          No one
          *if simz_here and (s_rel < 9)
            else
          follows you.
          
          The Plektos's great jaws loom open above 
          *if yebben > 9
            you.
            *gosub yebsacrifice
            *goto fight
          you, then snap down with crushing force.
          *goto_scene death
        *if (kal_here) or ((cha > 1) and (morale >= inadults))
          A dozen of you reach the Plektos at the same time.  Poised on the cave floor, it meets you with tail lashing, jaws snapping.
          *if (inadults > 39)
            You're knocked to one side almost at once by a back-swipe of the beast's tail.  For an instant of stunned terror, you wait to be eaten, but the monster is distracted by
            *if kal_here
              ${kalt} and the rest of
            the human swarm.
            
        *goto mobplekswarm
      *hide_reuse #I bellow, "Bring it down!" to my followers.
        *if not(kal_here) and ((cha < 2) or (morale < inadults))
          Your terrified outlaws pay you no attention at all.  You have an instant to try something different before the beast snaps you up.
          *goto plekrallych
        *if kal_here
          Already moved by ${kalt}'s speech, 
        *if not(kal_here) and ((cha > 1) and (morale >= inadults))
          Loyal to the last,
        your rebels hurl themselves with a thin battle-cry against the terrible beast.
        *label mobplekswarm
        *if (inadults < 40)
          *set cas +round(inadults/3)
          *gosub cascheck
          But there are too few outlaws to distract the hound from its prey.  The gape-jawed Plektos tears through them without once taking its eyes from you.
          
          *if yebben > 9
            *gosub yebsacrifice
            *goto fight
          Its hot breath and crushing teeth are the last things you feel. 
          *goto_scene death
        *set cas +31
        Can a hound be brought down by enough rabbits?  The Plektos shrugs off the screaming helots and yeomanry with ease, trampling some into the cave floor, crushing others in its jaws.  And yet you watch with awe and horror as your followers spend their dying strength stabbing at it, clinging to it, refusing to let it win.  
        
        A weathered Shayardene bandit, Vorne, is the first to do real damage.  When the hound closes its teeth around his legs, he rams one dagger-wielding arm into a nostril and holds wailing onto the beast's snout as it tries to shake him loose.  Then as its jaws gape open to cough him out, he ducks into the maw, ramming his short-spear deep into its pink throat.  Within seconds, he's dead…but the Plektos's breath comes in wet, gargling bursts, and it keeps its mouth clenched shut.
        
        *if simz_here and (s_rel < 9)
          ${simon} de Firiac disappeared in the first frenzied moments of the attack; you'd feared ${zhim} dead.  But now ${zhe} reappears, leaping onto the creature's back and broad shoulders.  When it snaps its head back toward ${zhim}, ${zhe} lunges and plants ${zhis} sword in one eye socket.  Then ${zhe}'s diving off, rolling free as 
        *if not(simz_here) or (s_rel > 8)
          *if kal_here
            ${kalt} launches ${zhim}self grimly at the creature's face while it's clawing at two other outlaws.  $!{zhe}'s flung back almost at once, skidding bloodily across the cavern floor—but ${zhis} knife stays in one eye, and
            *set cas +2
          *if not(kal_here)
            *set cas +6
            Another ten howling outlaws hurl themselves onto the creature's head.  Six of them die within seconds, and the rest are flung bloodily across the cavern floor…but one of the dead leaves her knife in an eye socket, and
        the half-blind Plektos lashes out with an ear-splitting shriek.
        
        Then it turns and bounds back into the woods. "Get down!" bellows
        *if kal_here
          ${kalt},
        *if simz_here and (s_rel < 9)
          ${simon},
        *if not(kal_here) and (not(simz_here) or (s_rel > 8))
          Alira,
        suiting action to word.  You duck behind a rock yourself mere moments before a vitriolic fireball steals all the air from the cave.
        
        When you can see again, and the breath returns to your scorched lungs, you spy the beast's Theurgic keeper flying after it.  
        *set d2n_num cas
        *gosub d2n_np
        $!{display_numb} of your followers lie dead around the cave…but you've injured and driven off a Plektos hound.
        *set plektoi -1
        *if plektoi > 0
          Just one more to go, somehow.
        *gosub cascheck
        *goto fight
      #I run in search of a narrower passage.
        You spy a crack in the wall of the cave and sprint for it.
        *if com > 1
          Fighting here would be madness—you would all be devoured.  
        *if kal_here
          ${kalt} sees you run and screams, "Fall back," ${zhis} voice taut with anger and fear.
          
          *comment endif
        Moments later you hear the Plektos thunder after you, the crunch of stone, the screams of your followers.  
        
        Hurling yourself into the crevice, you feel the whuff of its breath on your back—and hear the impact of its shoulders stopped short by the narrow gap.  Its teeth snap together a few 
        *if skepreal <= 50
          Angel-blessed 
        inches behind you.
        *choice
          *if (int > 1) #[i]Now[/i] I use ${wisardry} to bring the roof down.
            *if blood < 1
              *goto cavethplek2
            *else
              Using your own blood, or a phial?
              *choice
                #My own blood.
                  *label cavethplek2
                  *if consc < 1
                    You feel your head begin to spin almost at once, and can't bring your scattered thoughts to a focus.  Pressing desperately toward the roof with your mind, you succeed only in driving yourself into unconsciousness.  
                    
                    The last thing you feel is your body toppling forward, striking the floor hard…and teeth closing around your heel.
                    *goto_scene death
                  *set consc -1
                  *goto darkplek3
                #A phial of aetherial blood.
                  *set blood -1
                  *set usedblood +1
                  *label darkplek3
                  *gosub theucavepl2
                  The next sensation you have—besides dull, pervasive pain—is the sticky mix of dust and blood that grits against your skin when you roll over.  You can't see anything, but you can hear voices faintly from the far side of what must be a ton of rock and a dead Plektos.
              
                  You croak something, not sure of what you're saying, just trying to be audible.  
                  *if (inadults < 43) and (plektoi > 0)
                    The voices fall silent.  Then a triumphant howl sets the rocks shuddering around you, and steals the last of your hope. 
                    
                    Those aren't your followers out there—of course not.  You had too few left at the end to stand against a third Plektos.  With your body sealed in a crevice behind a rockslide, they must have all fled.
                    
                    You try to crawl backwards, but find the way thoroughly blocked.
                    *if blood > 0
                      The 
                      *set d2n_num blood
                      *gosub d2n
                      blood phials left in your bandolier have been shattered by the rockfall.
                   
                    There's only one final thing to do.
                    *page_break
                    Tears leak from your eyes as you listen to the beast claw its way through the wreckage.  When the Plektos scrabbles past the last fallen stones and lets light into your refuge, you howl wordlessly and pour all your ${wisardric} power into bringing down the entire cave roof.  
                    
                    You feel resistance, strongly, from more than one Theurge out there in the cave; shouts of alarm echo in your ears.  But you push on, with all the energy you have—with all the blood in your body, far more than your enemies are prepared to spend.  The last thing you feel is half the mountain coming down atop you, and them.  
                    
                    Like one of the heroes of old, you've drained yourself in one final, devastating feat of ${wisardry}.  Like them, you won't survive it.  But at least the Hegemony won't be able to display your body…or find it at all.  And with whatever damage you've done to the army (and the Plektos and Theurges), you hope your sacrifice will buy the survivors of your rebellion at least a little more time to escape.
                    *goto_scene death 
                  
                  "$!{he}'s alive!" comes a shocked, muffled voice.  "$!{oath}, the ${addressu}'s alive in there!"
                  
                  It takes the rest of your band's survivors half an hour to dig you out.
                  *if plektoi = 0
                    Finally, ${deputy} pulls you from the rubble.  "Nothing broken bar a rib or two, ${addressu}," ${dephe} says after a quick check of your limbs and skull.  You sway on ${dephis} shoulder, barely able to speak for the pain in your chest.
                  *if plektoi > 0
                    *set plektoi 0
                    "The third Plektos?" you demand, hoarse-voiced, when they pull you out over the battered corpse of the second.
                    
                    "Came sniffing for you almost as soon as the rocks fell, ${kuria}," ${deputy} says bleakly. "We reckoned we'd only have one chance, while it was distracted…so we all went for it.  Lost thirty-six people before we managed to get a spear down its gullet and a dagger in one of its eyes.  It ran off after that, and its Theurge went with it."
                    
                    "You chased it off?"  The air is heavy with the smell of blood and viscera; as you blink the dust from your eyes, you begin to see the bodies littering the floor.
                    
                    *if deputy != simon
                      "Damned well 
                    *if deputy = simon
                      "That we
                    did, ${addressu}." ${deputy} breaks into a shaky smile.
                    *set cas +36
                    *gosub cascheck
                  "Won't be long before that last Plektos's Theurge keeper leads at least some of the Phalangites up to us, though.  We need to get moving—now."
                  *goto fight
          #I turn and try to put its eyes out.
            Getting a blade past those madly probing jaws and into one small eye is no easy matter, especially when barely any light is reaching you.
            *if com < 2
              Your first strike glances harmlessly off the beast's snout.  It's ready for your second blow; you howl in shock as
              *label teethclose
              its teeth close on your forearm.
              
              Then you're being dragged out of the crevice like a rat, pinned deftly beneath a paw, and—with a quick snap and upward jerk of its head—dismembered at the elbow.  
              
              The claw that pierces your skull is a mercy, cutting off the sight of a Plektos gnawing on your severed limb.
              *goto_scene death
            *if com > 1
              *label eyesout
              But you wait for the opportunity as it inches its way toward you…and when the moment comes, you lunge and plant your
              *if weapon = "sword"
                sword
              *if weapon != "sword"
                knife
              in the eye socket.  
              
              The Plektos's howl deafens you, showering you in pungent saliva.  Maddened, it claws its way ever more frantically toward you, while you scramble back as far as you can.  Your hands close on a large, loose stone, which you slam vainly and repeatedly against its questing snout.  Only when the hound has stretched its neck forward as far as it can go do you drop the rock and try to plunge your
              *if weapon != "sword"
                second
              knife into its other eye.
              
              To your own lasting amazement, you succeed.
              
              The blind beast wails and snaps its head upward, slamming into the roof of the crevice.  A shower of rocks falls, grazing you and battering its skull and shoulders.  When it lurches back, leaving a trail of blood on the stones, you know you've won.
            *label blindretreat
            
            Its Theurge keeper hovers into view in the cave mouth, and you duck behind the rubble pile just as an eruption of blue flame roars through the cavern.  Then both Plektos and mage are gone.  You can hear the crashes and howls as the huge, unseeing hound tumbles down the mountainside.
            *set plektoi -1
            *if inadults > 27
              *set cas +9
            *if inadults < 28
              *set cas +round(inadults/3)
            *gosub cascheck
            *goto fight
          #I flee back as far as I can.
            It's not far before the crevice ends.  The hound is clawing its way toward you, slavering madly. Behind it, you can hear more screams from the cave as your followers all scatter.
            *if cha < 2
              *if com > 1
                There's nothing for it but to try to strike it where it's most vulnerable.
                
                Hitting a small, moving target is no easy task. Heavy brows protect the Plektos's eyes, and its jaws are madly probing the crevice for you.
                *goto eyesout
              You bat vainly at its impervious snout until at last
              *goto teethclose
            *else
            
              Or…are they scattering?
              
              The Plektos is twisting and jerking in place, no longer pressing toward you.  You glimpse the flicker of its tail behind it, hear the terrified but savage yells of outlaws: "Save the ${addressu}!"  Then the great hound shrieks and bucks upward hard enough to bring down a shower of large stones on its own head.  It pulls itself out of the rockfall and lurches back, leaving a trail of blood on the crevice floor.
              
              Crouching dazed in your safe corner, you catch a glimpse of two or three determined forms clinging to the Plektos's hindquarters, sawing and stabbing at its tail.  Much of the tail seems to be held down by others—some alive, some impaled on the spikes.  When the increasingly frantic hound backs out enough to bring its jaws to bear, four of your followers die screaming.
              
              But
              *if kal_here
                ${kalt} and
              *if simz_here and (s_rel < 9)
                ${simon} and 
              four other outlaws are ready on a ledge overhead.  They drop onto the Plektos's skull and stab for the eyes with whatever blades they have.  It rears up, sending them flying, but keeps shaking its head afterward. A handle protrudes from one eye socket.  With a bellowing moan, the creature breaks for the woods.
              *goto blindretreat
  *if (lostem and (hdead = 1)) #That sounds as if it's going after my noble ${hostages}.  I run to see.
    You and Alira dash down the mountain and into one of the narrow ravines that splits its west face.  
    *gosub seebelow
    
    At the ledge where the steep descent turns into a waterfall, you find 
    *if inadults > 60
      several dozen 
      *goto plekwarn
    *elseif inadults > 40
      over a dozen
      *goto plekwarn
    *else
      a handful
      *goto plekwarn
    *label plekwarn
    of your followers, huddled in terror before a tunnel mouth.  "Plektoi, ${kuria}!" one gasps, and flinches as a howl echoes from somewhere deep in the caverns. "Ah, Xthonos. One's down there, and there's another running about in the woods."
    
    You can see why they're paralyzed here.  Retreating into the open wilderness would be lunacy, but nor would anyone want to venture back into the darkness with a hound.  "Take heart—we've already killed one, and its Theurge.  What about
    *if bred_pris
      Breden and
    our ${hostages}?"
    
    "Still tied up down there, by the far entrance," admits one of the outlaws.  "When the Plektos started burrowing its way in, we left ${hosthem}
    *if bred_pris
      and Breden
    and ran."
    *choice
      #Damn it.  Well, I'm not about to try to rescue ${hosthem}.
        *goto ledgefight
      *if bred_pris
        #Ah, ${sweetoath}.  I can't let the hound have Breden.
          *goto caverescue
      #I beckon my bravest followers after me.  We'll need the ransom when we survive this.
        *goto caverescue
      #I beckon my bravest followers after me.  I won't let the Hegemony paint me as a hostage-murderer.
        *goto caverescue
      #I beckon my bravest followers after me.  No one deserves to die between a Plektos's teeth.
        *goto caverescue
    *label caverescue
    *set hdead 2
    *gosub tunnelnarr
    
    Just before you lose all visibility, a watery light appears around the corner.  You find yourself creeping toward a hall illuminated by a crack in the ceiling.  This tunnel is one of four or five that converge here, the largest of which leads to the woods outside.  A second one was narrower yesterday. Now the claw marks, rubble, and noise tell you where the Plektos has gone.
    
    *if horhostage
      In front of this, you see Horion
      *if linhostage
        and Linos
      lying prone in a darker pool.  Your noble hostage still has his hands bound behind his back.  His round head has been shattered almost beyond recognition.
      *if linhostage
        His priest has been bitten in two.
      *fake_choice
        #I can hardly stop shaking.
          *if introhlt
            Seeing someone actually die the death of your childhood nightmares, bodies shredded by Plektoi teeth….
            
            You have to turn your face to the wall and hold on until the hall stops spinning.  Then you force yourself to open your eyes again and speak in some semblance of a normal voice.
        *selectable_if (not(introhlt)) #I feel a deeper pang of regret than I'd expected.  I'd had a fondness for Horion.
        *selectable_if (not(introhlt)) #I curse the loss of the ransom under my breath.
        *selectable_if (not(introhlt)) #I spare them only a glance before staring down the clawed-open tunnel.
          All that matters is the beast in the darkness there.    
    *if s_rel < 9
      "We're too late.  For ${hosthem}…and probably for whoever it's chasing down that warren."
      *if bred_pris
        Breden, surely?  Even if ${xhe} did betray you, it would be hard to wish such an end on anyone.
      *label tunnelfight
      
      Alira clears her throat. "$!{addressu} ${lname}.  If the Plektoi have been given your scent…whoever they're burrowing after is likely someone
      *if dadfeel > 0
        else
      close to you."  She doesn't need to name any names.
      *if (deputy != "Alira") or ((deputy != kalt) and (k_rel = 4))
        Your deputy ${deputy} might well share some of your scent by now.
      *if rescuer = 0
        Joana Orchard.
        *if helot
          Terret Abler, or another friend from the Keriatou camp.
      *if kal_here and (k_rel = 4)
        Your lover ${kalt}.
      *if (deputy != "Breden") and (bred_here and not(bred_pris))
        Breden.
      *if (dadfeel = 0)
        Your father.
      *choice
        #"If we make enough noise, we may draw the Plektos back to us and save them."
          You exchange glances with the other two hunters, who nod back at you.  "We're here to fight the damned thing,"
          *if c_rel > 0
            Ciels
          *if c_rel < 1
            Young Earnn 
          mutters. "Best get it over with."
          
          Your four voices crack as you whoop and yell incoherently, loud enough to drown out all thought.  For several moments afterward, nothing stirs in the shadowy cave network.  Then an answering howl comes up the ragged, rubble-strewn tunnel.
          *goto plekarrive
        #"However long we have before the beast comes back, we'll need to make ready for fighting it."
          *if rescuer = 0
            *set joana 0
          You quickly scan the other tunnels leading from the hall, and find one which emerges onto a precipice.  
          *gosub codingefficiency
          
          Alira tests the narrow, crumbling ledge, then looks up the not-quite sheer slope above you.  Within seconds, the two of you have agreed a plan—a risky one, but the best you're likely to have under the circumstances.  
          
          As you're returning, you hear a change in the tenor of the distant Plektos's howls. Your heart begins to hammer in earnest when you meet the other two running down the tunnel. "It's coming, ${addressu}," Earnn says shrilly. "Got your scent."
          *goto thinveneer
    *else
      *if horhostage
        There's no sign of ${simon} de 
        *if bred_pris
          Firiac or Breden—you 
        *if not(bred_pris)
          Firiac—you 
        can only assume that 
        *if bred_pris
          they're
        *if not(bred_pris)
          ${zhe}'s 
        the object of the Plektos's pursuit.
      "Where's that tunnel go?" you breathe to 
      *if c_rel > 0
        Ciels.
      *if c_rel < 1
        Earnn.
      
      "Out to the west slope.  Or…"
      
      "Or back to this hall." ${simon}'s voice is barely audible from the shadows to your right.
      *if s_rel = 19
        Before you can leap back, you're knocked to the floor and agony bursts between your ribs.  Your fingers clutch at an feathered shaft.  "For Horion—monster."
        
        Alira is leaping past you, grimly determined to spear de Firiac before the young noble can nock another arrow.  But you'll never see how that fight ends.  In your final moments, your eyes go dark. The world shrivels away to the pain in your chest and the choking flood in your lungs.
        *goto_scene death
      $!{zhe} steps into view, holding a bow. "$!{kuria}, I could name five dozen nobles who'd have put an arrow in you just now for less shame than you've given me."
      
      *if helot
        "But you'd rather live?"  You glance meaningfully at your three armed followers.
      
        $!{zhis} lips twist. "And still you find ways to pile insult on insult.  No, Captain.
      *if aristo
        You study ${zhim} expressionlessly, poised to spring away or strike with your own ${weapon}. "Why didn't you?  Surely not out of any fear for your life."
        
        ${simon} gives a sharp, disdainful exhalation.  "Indeed.
      Life is cheaper than honor, all the more so on a day that will probably see us all dead by noon.  I spared you because [i]I am a member of this rebellion[/i], by Xthonos and all Angels.  And as cheaply as you've held my allegiance thus far, the path of greatest honor for me still lies in fighting at your side."  $!{zhe} moves up to you, close enough now that you can hear the breath coming fast and frightened in ${zhis} nostrils. "But know this: if you tried to chain me for ransom again after this, I'd die first, and kill you if I could."
      *if bred_pris
        
        You stare back into the darkness from which ${zhe} emerged, struggling with relief and anger.  "Is Breden going to jump out as well and make threats?"
        
        The young de Firiac shakes ${zhis} head.
        *if (ciels > 9) and (c_rel > 0)
          (You hear Ciels murmur something that sounds like a prayer of thanks behind your shoulder.)
        "$!{xhe} fled just ahead of me.  Kept going into the woods when I doubled back.  I can't blame ${xhim}, ${kuria}, given how you reward loyalty.  Not all will have the gentility to bear with it."
        *set breden 17
        *set followers -1
        *set nonkids -1
        *set bred_pris false
        *set bred_here false
      
      Whatever you might have answered is lost when Alira grabs your shoulder.  You can feel the terror in her fingers before you hear it in her voice. "$!{addressu}—hist! The beast's coming back.  Reckon it's caught wind of you."
      
      *label plekarrive
      The strike of claw on stone has a different tenor now, the echo of running rather than digging.  
      *label clawstone
      *choice
        *if (int = 2) #When it arrives, I'll use ${wisardry} to bring the ceiling down.
          *if blood < 1
            *goto cavetheuplek2
          *else
            As the Plektos thunders ever closer…do you draw out a phial of blood, or jab your hand with a
            *if helot
              bone
            needle?
            *choice
              *hide_reuse #I'll use my own blood.
                *label cavetheuplek2
                *if consc < 1
                  You feel your head begin to spin, and realize you won't have the strength to wobble a rock—not so soon after you last drove yourself into unconsciousness.  
                  *if blood > 0
                    Before you collapse, you fumble for a blood phial.
                    *goto bloodph3
                  You'll have to come up with some other plan.
                  *goto clawstone
                *set consc -1
                *goto darkplek4
              #I use a phial of aetherial blood.
                *label bloodph3
                *set blood -1
                *set usedblood +1
                *label darkplek4
                *gosub theucavepl2
                When you regain consciousness, Alira is
                *if cavein = 2
                  swabbing the blood from your head with a damp rag. 
                *if cavein > 2
                  crouched beside you.
                "Well, that did the job, ${addressu}," she says drily. 
                *if cavein = 2
                  "You're bleeding like a butchered calf, but your skull still feels solid enough.  Can you 
                *if cavein > 2
                  "Can't find any new wounds on you.  You still able to
                climb back up the tunnel, or do we need to carry you?"
                
                Gingerly running your hand along your scalp, you find the jagged gash from the cave-in.  Your fingers come back sticky and red, and your head is swimming, but you know the others need to see you upright. "I'll walk," you croak, and sway to your feet.
                *goto fight
        #Pull back up the tunnel and find a narrow spot where I can fight it.
          In a broad space like the hall, the Plektos would tear through your little band in moments.  You need to find a point that it will struggle to pass, where you have some chance of surviving a stand.
          
          You've run only for a minute or two when you hear the timbre of the howl grow louder, more reverberant.  The hound has arrived in the hall.  Then comes the echo of its panting and snuffling in the tunnel immediately behind you, its talons ringing on the stone.
          
          *if com = 2
            The first pinch point you reach would only hamper the beast for seconds as it wriggled its great shoulders past a protruding boulder.  You almost run onward…but then slow instinctively, some part of your mind sensing the possibilities.  Young Earnn pauses with you, wide-eyed and breathing fast. You extend a trembling hand to him.  "Your spear, Earnn. Then run on."
            
            The young tracker obeys at once, with only a slight tremor in his own hand betraying how hard it is to disarm himself.  Heart hammering, you clamber up to the narrow ledge above the pinch.  The din of the approaching hound becomes near-deafening; you find yourself barely able to breathe.  [i]If I'm wrong, at least it should be a quick death.[/i]
            
            Then the massive form appears in the dimly lit gap below you. It slams into the protruding cavern wall with a snarl, claws at the floor, and begins writhing past the boulder.  Its head rises as it pushes through the gap.  
            
            You slide down and ram Earnn's spear toward the Plektos's eye socket.  
            
            The blade jolts against bone, and for a dreadful instant you're sure you've missed—until the hound's agonized shriek brings down a shower of stone.  It tries to bound upward, but only wedges itself between the boulder and wall.  Jerked off balance by the spear in your hand, you can't keep from tumbling onto its snout.
            
            *if helot
              But you keep your head and your footing—as you did in countless scrum-ball matches when you fell in with a bigger helot—and
            *if aristo
              When the Keriatou blademaster had you practice on uneven footing, he couldn't have imagined how you'd use your training.  But you keep your balance, cry, "$!{lname}!" and
            bring the spear down into the other eye.
            *page_break
            *set plektoi -1
            The blinded hound whips its head up and screams again, flinging you off its head.  Your own head smacks the tunnel roof, hard enough to turn the whole world white around you. Then the rocky floor knocks the breath from your lungs.  Only half-conscious, feeling blood pour hotly down your forehead, you scrambled backward on your elbows like a crab.
            
            But though close enough to feel the whuff of breath from its nostrils, you've landed just too far from the Plektos for it to snap you up.  "Head down, ${addressu}!" comes Earnn's cry from behind you—and a good-sized stone flies over your head and crunches against the monster's nose.  It does no damage that you can see…but the hound keens and begins scrabbling away.
            
            Within seconds it's gone, with its injured wail receding down the cave.  Alira grabs you under the armpits and begins hauling you back toward your followers. "The beast's Theurge should have enough to do," she says levelly, "but let's not tempt him by hanging about."
            *goto fight
          *else
            The cave begins to ascend steeply. You haul yourself up, toward the light far above where your followers are waiting.  There's a point halfway up where the ceiling and floor nearly touch.  If the hound follows you up the slope, you think you can stop it there.
            
            But your fingers and feet keep slipping on the water-slick surface, and you've not yet reached the pinch point when the Plektos bursts into view below you.  Its triumphant howl brings a cascade of rocks down around you; you barely suppress a scream as you scrabble to keep your grip.  Then its claws grate against the stone, with a rasp you feel as much as hear, and it starts climbing after you.
            *if cha = 2
              *page_break
              Just as you are sure that you'll feel the Plektos's teeth in your heel, you hear a cry of "$!{addressu} ${fname}!" from
              *if (kal_here and (k_rel < 6)) and (not(plekspear) or (deputy != kalt)) 
                ${kalt}, taken up seconds later by
              a dozen throats.  Your followers are sliding down the slick tunnel to rescue you; their passion for you is greater than their terror.
              *if (kal_here and (k_rel < 6)) and (not(plekspear) or (deputy != kalt)) 
                "Kill the dog!" ${kalt} goads them on. "Don't stop!"
              *set plektoi -1
              
              Some hurl stones down at the beast to knock its claws loose and send it skidding downward.  Three lose their footing themselves and careen down the slope toward it—but their screams hold fury as well as terror, and they tumble down with weapons out-thrust.  Even as the Plektos's teeth close around him, one weathered bandit rams his dagger-wielding arm into a nostril.  He holds wailing onto the the hound's snout as it tries to shake him loose.  Then as its jaws gape open to cough him out, he ducks into the maw, ramming his short-spear deep into its pink throat.
              
              For a moment afterward, the wounded Plektos is invisible in the shadows. You can just hear its wet, ragged panting, with the edge of a whimper.  Then it gives a burbling howl and launches itself up the slope toward you.  But you've been hauled up past the pinch point, and when it tries to squeeze through the narrows after you, ten spears press in to find its eyes.  Half-blind, it falls again, scraping its way down the wet slope. 
              
              This time it runs, and doesn't come back.
              *if inadults > 10
                *set cas +3
              *if inadults < 11
                *set cas +round(inadults/3)
              *gosub cascheck
              *goto fight
            *else
              You hear screams high above, as your outlaws flee the tunnel mouth.  Perhaps if you were more charismatic, they might have come to help you. Perhaps the rangers fleeing with you would have found the courage to turn and face the beast.
              *if (s_rel > 9)
                
                Only one person stands against it, in the end.  ${simon} seizes your wrist and pulls you up to ${zhis} side. You can see in ${zhis} face how close the hound must be.  For a moment, ${zhis} bitter eyes hold yours. "Always remember you owe your life to a
                *if aristo
                  hostage, 
                *if helot
                  noble,  
                ${kuria} ${lname}." Then ${zhe} launches ${zhim}self down the slope with a final cry of, "De Firiac!"  
                *set simz_here false
                *set s_rel -50
                *set martyr "de Firiac"
                *set mhe zhe
                *goto plekmartyr
              *elseif kal_here and (k_rel < 5)
                As it is, only one person is both brave and loyal enough to seize the moment. "To Taratur with you!" comes the yell from a lean figure that skids past you down the slope.
                
                *set kal_here false
                *set k_rel -50
                *set martyr kalt
                *set mhe zhe
                *goto plekmartyr
              *elseif (el_here and (e_rel > 5)) and not(elsick)
                Just as you think you're about to die, Elery Skinner skids past you with a curse.
                
                *set el_here false
                *set e_rel -50
                *set martyr "Elery"
                *set mhe "she"
                *goto plekmartyr
              *elseif korszata > 0
                Only Korszata 
                *if korszata > 1
                  and Bjel are
                *if korszata = 1
                  is
                uncowed. With a roar of "Zabarejn!"
                *if korszata > 1
                  they skid
                *if korszata = 1
                  he skids
                past you, swords at the ready.
                
                *set korszata 0
                *set martyr "Korszata"
                *set mhe "he"
                *if korszata > 1
                  *set martyr "Korszata and Bjel"
                  *set mhe "they"
                *goto plekmartyr
              *else
                But no one does.  The last thing you feel is the Plektos's teeth closing on your heel, yanking you from the slippery rocks and slamming your body against the tunnel roof.  Then all goes mercifully black.
                *goto_scene death
            *label plekmartyr
            You scramble with grim determination to the pinch point, not looking back despite the deafening howls and a thundering noise which can only be ${martyr} and the Plektos going back down the slope together.  Earnn pulls you up the last few yards, his face drawn with shock. You can barely hear him over the shrieks from below. 
            
            "$!{mhe}…${mhe} bloody blinded the thing, ${addressu}.  Put a blade in at least one eye.  And I think the hound broke its back in the fall."
                
            You stare down at the writhing, spasming shadow at the foot of the slope. "And…${martyr}?"
                
            Alira shakes her head.  "Underneath it, last I saw."
                
            "$!{sweetoath}."  It's several moments before you reluctantly look away. "We have to go.  The beast's Theurge could be anywhere."
            *set plektoi -1
            *set plekreinforce +1
            *goto fight
        *if ((s_rel < 9) and (campsite > 0)) 
          #Retreat down another tunnel I explored long ago—I'm sure there's an opportunity there to trap the beast.
            This is one of the caves you walked when you first visited the High Crag, and you remember rightly that it leads out onto a precipice.
            *gosub codingefficiency
            The ledge you're standing on soon dwindles into nothing.
          
            "Up the cliff!" you order the others.  There are just handholds enough for them to clamber up, with help from the dense vines.  Behind you, you can hear a change in the timbre of the howling as the hound reaches the hall.  With all the calm you can muster, you walk back to the cave mouth and wait.
            *goto beedrop
        *if (s_rel > 9) 
          #Retreat down the tunnel ${simon} used to get here—${zhe} thinks we can trap the beast there.
            "Follow me," ${simon} says urgently, leading you down a side passage. "This leads to a drop that should kill anything, even a Plektos—and an unpleasant surprise for any Theurge on its heels.  All we have to do is lure them out."
          
            A minute later, you all emerge onto a precipice.  
            *gosub codingefficiency
          
            Alira tests the narrow, crumbling ledge, then glances up the not-quite sheer slope above you.  "You're thinking…?"
          
            The hint of a smile hovers grimly on the de Firiac's face.  "There's only one of us who'll do for bait.  $!{kuria}?"
          
            Minutes later, you're hovering alone at the mouth of the tunnel, clinging to whatever calm you can muster.  The others have clambered up to a safer perch in the vines above.
            *label beedrop
            *set campsite +5
            *gosub bees
            another Plektos and its Theurge.
            *goto fight
*label ledgefight
*set plekfight +4
*if com > 1
  "Spears won't be much use against a Plektos, unless we're close enough and lucky enough to find an eye." You scan the area rapidly and point to a crag a little ways up the slope.  "You two—wedge yours under that boulder there, and stand ready to dislodge it on my signal.  You others, guard the ledge and set spears."  The outlaws hurry to obey, trusting in your combat instincts.
  
The howl from the far side of the mountain shoulder gives you only a few moments' warning.  Then a Plektos thunders into view along the path, lithe and sure-footed despite the sheer drop to its left.
*choice
  *if (com > 1) #I signal frantically to the outlaws upslope.
    The boulder teeters, then crashes down onto a steep scree slope.  Intent on overrunning the spear-wielding outlaws on the path, the Plektos doesn't take notice of the rumble until too late.  Then it howls and crouches close to the ledge, digging in with its steely claws—but it can't withstand a rockslide.
    
    The battered hound plummets from the ledge, then stops in midair, caught by Theurgy.  You hear Alira shout, "Find the mage!  All archers!" and see her lead her hunters up to the ridge.  The Plektos snarls and writhes, lashing out with its tail as it begins to rise.  Just before it regains the path, it drops again with a shriek.  One of Alira's arrows must have found its distracted target.
    
    You can't see it in the mist of the waterfall, but you don't think even a Twisted One could survive a fall like that.
    *set plektoi -1
    *set plekkeepers +1
    *goto fight
  *if (int > 1) #I use ${wisardry} to sweep it from the path.
    *if blood < 1
      *goto ledgeplek
    *else
      As the Plektos thunders ever closer…do you draw out a phial of blood, or jab your hand with a
      *if helot
        bone
      needle?
      *choice
        #I'll use my own blood.
          *label ledgeplek
          *if consc < 1
            You feel your head begin to spin, and realize you won't have the strength to wobble a rock—not so soon after you last drove yourself into unconsciousness.
            *if blood > 0
              Before you collapse, you fumble for a blood phial.
              *goto bloodph4
            You shout to your followers, "Throw it off the mountain!"
            *goto ledgetoss
          *set consc -1
          *goto ledgeplek2
        #I use a phial of aetherial blood.
          *label bloodph4
          *set blood -1
          *set usedblood +1
          *label ledgeplek2
          Once again, you focus on levitating the beast, lifting the elemental fire in its flesh.  As you'd feared, a black-coated Theurge soars into view over the ravine, stretches out one bloody hand, and forces the hound back down to the trail.
          
          You know you're not strong enough to fight a seasoned Theurge—so instead, at the last second before the hound reaches your outlaws, you join your will to its keeper's.  The beast suddenly becomes even heavier than usual, slamming to the ledge and skidding to a halt just in front of your terrified followers.  
          
          Trusting in your ${wisardry}, one bold outlaw leaps forward and buries her spear in the hound's eye.  It howls and tries with all its might to lift its suddenly mountain-heavy frame.  At that moment, you and the Theurge both reverse your wills.  The hound thrashes, off-balance, and topples into the mist of the waterfall.
          
          You're poised for the mage to either levitate the hound or attack you directly—but instead, an arrow appears in the narrow gap in her cowl, and she flips over in the air before plummeting to the rocks.  Alira shrugs at your relieved, admiring glance.  "When you're vying with a Theurge, ${addressu}, maybe they'll stay still long enough for a woman to take proper aim."
          *set plektoi -1
          *set plekkeepers +1
          *goto fight
  *selectable_if (com < 2) #I lead a charge against it.
    It's bravery, but madness.  The Plektos doesn't slow or pause when it reaches you; your followers' spears and your ${weapon} barely scratch its thick leathery skin.  It lowers its snout and slams its head into you, even as its talons tear through your outlaws.
    
    In your last moments, you're plunging through the mist of the waterfall.  The world fades to a soft, cool gray around you, just before it abruptly goes black.
    *goto_scene death
  #I shout, "Throw it off the mountain!" to my followers.
    *label ledgetoss
    *if (cha > 1) or (bred_here and not(bred_pris))
      *if (bred_here and not(bred_pris)) and (cha < 2)
        Breden adds ${xhis} voice to yours, and ${xhis} magnetism has an effect you could never have created.
      Despite their terror, every one of your followers charges for the Plektos.
      *if eclect
        "For the Angels' Eclect!" one cries shrilly.
      *label plekleg
      The Plektos tears into them—but 
      *if cha > 1
        they 
      *if cha < 2
        a handful manage to
      cling to its legs, dragging their broken bodies behind them.  It stumbles, veering side to side as it tries to shake or stomp off its unwanted passengers.
      
      One dying bandit pushes against the cliff face with all her might, and sends the beast careening off the edge.  
      *label plekhover
      For an instant, it hovers in midair, caught by its dismayed Theurge. Then Alira finds the mage with an arrow.  Both hound and keeper plummet to the rocks, along with
      *set plektoi -1
      *set plekkeepers +1
      *if inadults > 60
        *set cas +12
        *goto ledgecas
      *elseif inadults > 40
        *set cas +8
        *goto ledgecas
      *else
        *set cas +round(inadults/5)
        *goto ledgecas
    *if inadults < 41
      "We're too few, ${addressu}!" one shrieks, and leads the rest in fleeing into the caves.
      *goto tunnrun
    They're terrified, and scatter despite your orders.
    *if inadults < 61
      Six of them try to charge the Plektos, clinging to its legs even after it's trampled them, but all they manage to do is slow it slightly.
      *set cas +6
      *if korszata > 0
        That's just enough for
        *if korszata = 2
          Bjel and
        Korszata, though.  The 
        *if korszata = 2
          two former Phalangites hurl themselves 
        *if korszata = 1
          former Phalangite hurls himself
        against the flanks of the beast, and (ignoring the claws and tail spikes piercing them) manage to heave it off the edge of the path.
        *set korszata 0
        *goto plekhover
      The rest of you retreat into the tunnel mouth.
      
      *goto tunnrun
    But there are enough outlaws there that those who do charge are enough.
    *set cas +9
    *goto plekleg
    *label ledgecas
    *set d2n_num cas
    *gosub d2n
    of your 
    *if cha > 1
      devoted 
    followers.
    *gosub cascheck
    *goto fight
  #I order a retreat into the tunnels.
    *label tunnrun
    *set plekfight 11
    This cavern system was formed by streams running down the mountain; the caves are slick with water and frequently near-vertical.  As you slip and slither downward,
    *if inadults > 60
      several of your outlaws lose their footing and fall screaming into the blackness.  For the rest of you,
      *set cas +5
    it's all you can do to keep from breaking your necks.
    
    The Plektos charges into the cave, baying, and pursues you.  There's only one gap too narrow for its lithe body to easily pass through—a pinch point where the ceiling and floor nearly touch.  It 
    *if inadults > 40
      snaps up your two hindmost followers, then
      *set cas +2
    begins tearing at the walls, burrowing like a hound after a badger.  You stare up at the flurry of claws and splintered rock and despair of being able to confront it there.
    
    "Our only chance is to hit it when it comes through," Alira says hoarsely. "Try to blind it and knock it off its feet.  The fall to the bottom might be enough to break its back."
    
    *if yebben > 9
      *if el_here and not(elsick)
        You hear Elery clearing her throat to speak, but she's suddenly cut off.
      "No.  There's another way."  The voice is unfamiliar with grief. "You taught me enough, ${addressu}.  Time to use it."
      
      Before you can say anything, you feel a rumble through the cavern walls—and the tunnel crashes down onto the Plektos's head, fast and decisive as a slamming door.  When the dust clears and a few shafts of light make it through, you can see the beast's mangled paws and snout pinned between boulders.
      
      *if el_here and not(elsick)
        Elery screams in frantic denial.
      You crawl over to where the voice came from.  Yebben Skinner's body is almost as pallid as a ${nere}, drained of all its blood.  Whatever he managed to do saved you, but at a fearsome cost.
      *set yebsac true
      *set yebben 0
      *set cas +1
      *set plektoi -1
      *set plekreinforce +1
      *gosub tunnruncas
      *goto fight
    *if korszata > 0
      "It will be me."  Korszata's voice holds no doubt, and only a tinge of fear.  "Clear the way below!"  And when the Plektos does break through in a cascade of falling rocks, the big ${whend} dives out to meet it with a bellow of, "Zabarejn!"
      
      Even as its claws pierce his armor, he puts a blade in one eye and yanks the hound off-balance.  They fall together, hit the base of the cave hard, and lie unmoving.
      *set korszata 0
      *set cas +1
      *set plektoi -1
      *set plekreinforce +1
      *gosub tunnruncas
      *goto fight
    *if el_here and not(elsick)
      Elery Skinner clears her throat three times before managing to speak.  "Sounds like just another swiving game of scrum-ball." You can hear her breath coming fast and frantic. When the Plektos does break through in a cascade of falling rocks, she dives out to meet it.
      
      She puts a blade in one eye and—even as its tail spikes lodge in her side—yanks the hound off-balance.  They fall together, hit the floor of the cave hard, and lie unmoving.
      *set el_here false
      *set cas +1
      *set elery -50
      *set plektoi -1
      *set plekreinforce +1
      *gosub tunnruncas
      *goto fight
    No one responds. You and Alira share a grim nod in the faint light of the tunnel.  When the hound finally breaks through, the two of you dive to meet it, coming from both sides at once.  You feel its claws pierce your ribs, and, gasping in agony, try to pull its leg off balance.  
    
    With a shriek, the Plektos slips and tumbles head over heels into the depths of the cave.  You fall with it. Your head strikes a rock, and you know no more.
    *goto_scene death
    *label tunnruncas
    *if cas > (inadults-19)
      *set cas (inadults-19)
    *gosub cascheck
    *return
*label fight
*page_break
*if plektoi > 0
  There's no time to catch your breath or celebrate your survival, with
  *if plektoi > 1
    two Plektoi
  *if plektoi < 2
    the final Plektos
  still at large.
  *if plekspear
    *set plektoi -1
    *set plekreinforce +1
    *set plekspear false
    Or so you think until ${deputy} finds you. "$!{addressu} ${fname}!  Thank 
    *if religion < 20
      Angels 
    *if religion < 19
      the kindly fates that
    you're alive."
    
    You glance at ${dephis} empty hands, then worriedly meet ${dephis} eyes. "The spear?"
    
    "Stuck in a
    *if deputy != simon
      swiving
    Plektos, ${addressu}.  Split apart and bent when it went through the ribs, as far as we can tell.  Had three of us on it trying to pull it out—but no luck."  ${deputy} wipes ${dephis} brow.  "Still,
    *if religion < 20
      Angels know 
    *if religion > 19
      kenon's truth,
    it was worth the loss.  It would have chewed through us all if we hadn't had the spear."    
    
    *if s_rel > 9
      *if s_rel != 19
        *set s_rel 18
      Suddenly you notice ${simon} de Firiac standing beside ${deputy}—unbound, defiantly wielding a sword.  You pour all your anger and incredulity into your voice.  "Who by ${oath} [i]armed[/i] our hostage?"
      
      "I armed myself, ${kuria}," ${simon} retorts coolly. "After freeing myself when my guards fled.
      *if horhostage
        Moments before the beast slaughtered
        *if linhostage
          hieros Linos and
        Horion." $!{zhis} voice quavers before ${zhe} regains control. "So.
      You need not blame your followers for doing anything to prevent my being eaten by the hound."
      
      "$!{zhe} managed to bring down the Theurge after we killed the Plektos," ${deputy} offers, looking only slightly abashed. "$!{zhe} saved our lives. And we thought we'd best have a blademaster to hand in case we came across the third one."
      *set plekreinforce -1
      *set plekkeepers +1
      *fake_choice
        #"They're all dead now…so get ${zhim} back in ${zhis} bonds."
          *if cha > 1
            Despite your charisma,
          ${deputy} and the rest don't make any move to follow your orders. "Angels, ${kuria}, enough!" ${simon} yells in exasperation. "Even now, do you think my loyalty suspect?  Even now, do you think I'm more use to this rebellion for some measly drachems from my father?" $!{zhe} whirls to address the band. "You're alive because a noble in the Southriding believed in this rebellion enough to arm you with treasures.  Weapons that no one else could possibly have got you. Do you still deem it wise to make yourselves the enemy of every noble in Shayard?"
          
          "$!{addressu}…" says ${deputy}, in a tone of voice that tells you you've lost the argument.  No one is going to take the young noble hostage now.
        #"Well, I reckon we'll accept a dead Theurge in lieu of a ransom."
          "You are as gracious as you are wise, ${addressu} ${lname}." ${simon}'s tone remains icy.
        #"Enough.  We'll make a final decision later."  But I know that if I let ${zhim} fight at our side now, only one decision will be acceptable.
          "If we all survive, ${addressu} ${lname}," ${simon} says bleakly.
      
      You turn away from the de Firiac.
    *if plektoi > 0
      "There's one hound left yet."
      *goto survplek
    *if plektoi < 1
      *goto postplek
  *label survplek
  *if (campsite < 5) and (campsite > 0)
    *set plekfight +7
    Beckoning Alira and a few others after you, you head back into the caves. "I know where we can trap 
    *if plektoi = 1
      it."
    *if plektoi > 1
      one of them."
    
    It's no easy thing to find your way through passages you barely remember from your long-ago exploration—especially once you can clearly hear howling from the tunnels behind you. [i]It's got my scent again.[/i] At last you emerge on the precipice you were hoping to find.  
    
    *gosub codingefficiency
    Alira tests the narrow, crumbling ledge, then glances up the not-quite sheer slope above you. "Are you…?"
    
    "The only bait it will follow." Minutes later, you're hovering alone at the mouth of the tunnel, clinging to whatever calm you can muster as the clamor of the hound grows louder.
    *gosub bees
    *if plektoi > 0
      another
    *if plektoi = 0
      the last 
    Plektos and its Theurge.
    *page_break
    *if plektoi > 0
      *goto ledgeprep
    *if plektoi = 0
      *goto postplek
  On what ground do you want to meet
  *if plektoi > 1
    them?
  *if plektoi < 2
    it?
  *choice
    *if (((plekfight != 2) and (plekfight != 3)) and ((plekfight != 6) and (plekfight != 9))) #I want to find a big enough cave that many of my followers can accompany me.
      You beckon Alira after you toward the main tunnel complex.
      *goto cavefight
    *if (plekfight < 7) #I want to find a narrow tunnel that could be defended by just a few followers.
      *gosub tunnelnarr
      
      Then you come to a junction, illuminated from a crack in the ceiling, where the channel you've been following intersects with a larger crevice.  A tunnel across the way clearly used to be narrower yesterday. The claw marks, rubble, and noise tell you where you could look for a Plektos.
      *goto tunnelfight
    *if (((plekfight != 4) and (plekfight != 5)) and ((plekfight != 6) and (plekfight != 11))) #I want to find an outside ledge where we could make use of the sheer mountain cliffs.
      *label ledgeprep
      You hurriedly make your way out to one of the narrow ravines that splits the mountain's west face.  At the ledge where the steep descent turns into a waterfall, you find 
      *if inadults > 60
        several dozen 
        *goto plekwarn2
      *elseif inadults > 40
        over a dozen
        *goto plekwarn2
      *else
        a handful
        *goto plekwarn2
      *label plekwarn2
      of your followers hovering in terror at the mouth of a tunnel, uncertain where to go. 
      *if (bred_here and not(bred_pris))
        Breden has been working hard to rally them, and at your appearance they seem at last to shake off despair.
      "$!{addressu}—you're alive!  You've seen the Plektoi?"
      
      "Seen, and killed.  Take heart!"  You point down into the mist where the waterfall breaks on the rocks. "You'll see another one die on these rocks today.  They should never have brought their hounds after us into this terrain."
      
      *if (bred_here and not(bred_pris)) and ((bred_lover >= 4) or (bred_heart = 3))
        Then you're interrupted by Breden's desperate embrace, as tears spill down into ${xhis} wide, shaky grin. "${fname}. ${fname}, thank Angels."  $!{xhe} pulls away almost at 
        *if bred_lover != 13
          once—you all have work to do if you're to survive—but 
        *if bred_lover = 13
          once—you doubt ${xhis} estrangement from you will disappear that easily—but 
        the tears and the smile remain on ${xhis} face.
        
      Alira takes a few moments to advise the archers on bringing down Theurges, while you muster those with short spears.
      *goto ledgefight
*if plektoi = 0
  You listen for long minutes before you're convinced that you'll hear no more howls—that they've sent no more Plektoi after you.  
  
*label postplek
*if lostem
  "Three Plektoi.  Three."  Alira looks and sounds dazed, as if truly struggling to believe you're alive. "If they expected us to survive at all, they'll expect us to be fleeing in disarray, right into their arms."
  
  "They'll also be able to follow the hounds' trail straight to us." Pain and weariness almost overwhelm you, but you force yourself to keep moving.
"Let's rally the band. 
*if not(lostem)
  Forgive me, ${addressu}—but the Phalangites will be upon us as soon as they realize we've killed the hound."
*if lostem
  We need to be 
  *if strategy = 1
    ready to receive them."
  *if strategy > 1
    gone before they arrive."
*label postroundone

*if ((deputy = "Elery") and (elery < 1)) or (((deputy = simon) and not(simz_here)) or ((deputy = kalt) and not(kal_here)))
  With ${deputy} fallen, you beckon over a new second-in-command:
  *gosub pickadeputy
  "If I fall today, you take the lead," you order.  ${deputy} says nothing, just gives a bleak nod.
  
*if (rescuer = 0) and (joana < 1)  
  You clamber back through the tunnels and find Gillian Adze emerging from the rubble-strewn Plektos burrow you ignored earlier.  The t'Keriatou elder is covered in blood—too much to possibly be her own, with her still walking.
  
  "There was a hound went after Joana Orchard, ${addressu} ${lname}.  She ran down there, but it kept after her, and…"  Gillian swallows with difficulty. "Xthonos damn it all.  I'm sorry."
  *fake_choice
    #Ah, ${oath}, no. I bury my face in my hands.
      The old woman's affection and her memories of your mother are lost now.  It's several long moments before you can bring yourself to keep moving.
    #I'll mourn Joana—but I can't be distracted by grief now.
    #The guilt hits me like a rockslide.  We might have saved her.
      Alira lays a hand on your shoulder. "You made the choice you needed to, ${addressu}.  It helped us bring down the thing that killed her."

*if dadfeel = 0
  As you limp out onto the broad ledge overlooking the lake, a scattering of outlaws turn to face you.  You'd been expecting the still-raw terror on their faces; you weren't prepared for the pity. "$!{addressu}," one of them rasps, gesturing out past the last pine tree on the ledge, down toward the woods.
  *gosub daddead
  
  *if dadfeel > 6
    Shaking off the stomach-churning shock as best you can, you
  *if dadfeel < 7
    It's all you can do to finally pick yourself up and
  keep moving.
*if hdead = 1
  *if s_rel > 9
    *if s_rel != 19
      *set s_rel 18
    ${simon} de Firiac is standing beside ${deputy}—unbound, defiantly wielding a sword.  You look around the assembled outlaws. "Who by ${oath} [i]armed[/i] our hostage?"
    
    "I armed myself, ${kuria}," ${simon} retorts. "After freeing myself when my guards fled.
    *if horhostage
      Moments before the beast slaughtered
      *if linhostage
        hieros Linos and
      Horion." $!{zhis} voice quavers before ${zhe} regains control. "So.
    You need not blame your followers for doing anything to prevent my being eaten by the hound."
    *if horhostage
      *fake_choice
        #I feel a deeper pang of regret than I'd expected.  I'd had a fondness for Horion.
        #I silently curse the loss of the ransom.
        #All I feel is irritation that the weeks of feeding ${hosthem} and dragging ${hosthem} behind us have come to naught.
        *if (int > 0) 
          #Seems I wasn't the only Plektoi target. Interesting.
            Whoever sent the Plektos made sure it had Horion's scent in its nose as well as yours.  The moon-faced noble had brutal enemies indeed.
      But there's nothing to be done about it now.
    *if not(lostem)
    
      "The Archon's army will be here at any moment."  You look ${zhim} up and down. 
    *if (lostem)
    
      You eye ${simon} levelly, considering the wisdom of trying to return an armed blademaster to ${zhis} bonds.
    "Do you still consider yourself a rebel, then, ${zmilady} de Firiac?"
    
    The young noble gives a caustic laugh.  "There's a Phalangite host out there that would most certainly deem me so, ${kuria} ${lname}.  Ask me again once we've survived them."
    
    *goto bgone
  You stumble down toward the cavern where you'd kept your ${hostages}. "Did it get ${hosthem}?" you demand when you see the outlaw you'd left guarding ${hosthem}.
  
  *if horhostage
    "The damned hound went straight for
    *if linhostage
      Linos and
    kurios Horion, ${addressu}."  The guard looks haggard and guilty. "Nothing I could do.  If I'd not run, I'd just be one more chewed up body."
    *fake_choice
      #I feel a deeper pang of regret than I'd expected.  I'd had a fondness for Horion.
        *if helot
          You could almost imagine him treating you like a free ${woman}—someone fit for more than just service and sacrifice.  Almost, you could have been friends.
        *if aristo
          You appreciated his avuncular charm and keen mind—to say nothing of his rebellious streak. Under other circumstances, he could have been a friend or mentor.
      #I silently curse the loss of the ransom.
        If you survive this attack, you'll draw even more mouths to feed and hands to arm.  A noble ransom could have gone a long way toward supplying your rebellion.
      #All I feel is irritation that the weeks of feeding ${hosthem} and dragging ${hosthem} behind us have come to naught.
        You could have killed them yourself long ago and spared yourself a world of trouble.
      *if (int > 0) 
        #Seems I wasn't the only Plektoi target. Interesting.
          Whoever sent the Plektos made sure it had Horion's scent in its nose as well as yours.  The moon-faced noble had brutal enemies indeed.
          *comment This needs to be on a separate line because it's a fake_choice.  AHSM
    *goto bgone
*label bgone
*if bred_pris
  *if (s_rel < 9) and not(horhostage)
    You stumble down toward the cavern where you'd left Breden tied up and under guard.
  "Where's Breden?"
  
  *if (s_rel > 9)
    The guard who had been watching ${xhim} shakes his head.
  "Gone.  Cut ${xhis} bonds and run off.  Seems to have made it into the woods.  No body to be found, anyhow—nor any tracks."
  *set breden 17
  *set bred_here false
  *set bred_pris false
  *set followers -1
  *set nonkids -1
  *fake_choice
    *if (bred_lover >= 4) or ((bred_heart > 1) and (bred_heart < 4))
      #It takes a moment for the loss to hit me.  Then it's all I can do to keep from weeping.
        *gosub t-or-no-t
    #[i]$!{oath}.[/i]  I've driven ${xhim} away.
      *gosub drivenaway
    #Running off before questioning? It's as much a confession as we'd ever have got from ${xhim}.
      "$!{xhe} poisoned us," you say starkly. "An innocent would have taken the chance to defend ${xhis} name."
    #I grind my teeth, wishing we had time to hunt ${xhim} down and put an end to ${xhis} treachery.
      "If anyone sees ${xhim}, put an arrow in ${xhim}," you bark. "$!{xhe}'s a traitor and poisoner, an enemy to
      *if skep <= 50
        Almighty Xthonos."
      *if skep > 50
        the rebellion."

*if roundone
  *goto roundtwo
*if choice_randomtest
  *choice
    #After plekfight, we have ${inwoods} inwoods, with ${inadults} inadults and ${inkids} inkids.  Arms ${arms}, wealth ${wealth}.
      *goto postchoice4
*label postchoice4
*if lostem
  *if el_here and not(elsick)
    Elery
  *if not(el_here) or elsick
    Alira
  runs up to your best watch point while you rally the band's survivors.  A few minutes later she rejoins you, brisk and unflappable despite her still-bleeding injuries. "There's clear movement up the valley, ${addressu}.  They're following the Plektoi's trail toward us.  Altogether I'd guess there's
  *if alltroops > 400
    more than four hundred of them
    *goto buttotal
  *elseif alltroops > 300
    more than three hundred of them
    *goto buttotal
  *elseif alltroops > 200
    more than two hundred of them
    *goto buttotal
  *elseif alltroops > 100
    more than a hundred of them
    *goto buttotal
  *else
    less than a hundred
    *goto buttotal
  *label buttotal
  left.
  *if alltroops > 450
    Could be even more over the brow of the hill.
  *if theurges > 0
    And of course they've still got 
    *set d2n_num theurges
    *gosub d2n
    *if theurges > 1
      Theurges
    *if theurges = 1
      Theurge
    left.
  But
  *if strategy = 1
    we've time enough to make ready and meet them, if you want to."
    *set d2n_num inadults
    *gosub d2n_np
    *choice
      *if (inadults < alltroops) #With only ${display_numb} battered rebels left, it's clearly time to run while we can.
        "We've killed their Plektoi.  That, and survival, is victory enough."  You nod to ${deputy}.  "Let's get moving."
        *goto slipaway
      #We've damaged them enough.  I'll not see more of us die today.
        *goto slipaway
      #I don't have the mettle left to fight them.
        *goto slipaway
      #"Today, we destroy them!"  I order my ${display_numb} surviving followers to prepare for battle.
        *if (morale < inadults)
          For several moments, no one does anything but shuffle their feet.  "We can run, ${addressu}," one bandit says at last. "They're far enough behind us now.  They'll never catch us if we do."
          
          "We swore to draw them out and destroy them,"
          *if kal_here
            ${kalt} cuts in, hot-eyed.
          *if not(kal_here) and rad_here
            Radmar interrupts angrily.
          *if not(kal_here) and not(rad_here)
            you plead.
          "Are we going to give up now, on the brink of victory?"
          
          "Don't know what we're on the brink of, save falling apart," the former yeoman mumbles. "We've been swiving lucky enough today. I'll not wait for a Phalangite to finish what the Plektoi started."
          
          When it becomes clear that almost none of the other survivors have the morale to fight, you accept the inevitable. "Let's get moving, then.  If we're going to run, let's run while we're still far enough ahead to lose them."
          *page_break
          *goto slipaway
        With the hours you have left, your surviving
        *gosub cragpreps
        *if (int > 1) and (usedblood > 0)
          
          You spend the better part of an hour trying to find the 
          *if plekkeepers = 1
            place where the first Theurge fell, to retrieve blood from his bandolier.
          *if plekkeepers > 1
            bodies of the
            *if plekkeepers = 2
              two
            *if plekkeepers = 3
              three
            fallen Theurges and their bandoliers of blood.
          *set plekkeepers (plekkeepers*3)
          Though many of the phials were shattered, you return with 
          *set d2n_num plekkeepers
          *gosub d2n
          in your tattered coat.
          *set blood +plekkeepers
          *set plekkeepers (plekkeepers/3)
        *if (int > 1) and (usedblood = 0)
          
          You could go looking for
          *if plekkeepers > 1
            fallen Theurges and see if any of their 
          *if plekkeepers = 1
            that first Plektos's keeper, to see if any of his
          blood phials survived the drop.
          *set bloodcheck true
          *choice
            *if (blood > 0) and (not(choice_randomtest)) 
              #I've never used the other phials I picked up.  Why get more of the filthy stuff?
                *goto allready
            *if (blood = 0) and (not(choice_randomtest))
              #No.  I'd die before using blood from a Harrower.
                How could you foul yourself with the blood of some murdered helot?  You focus on preparing the defenses alongside your followers.
                *goto allready
            #Deeply torn, I ask ${deputy} what ${dephe} thinks.
              "Find them and use them, ${addressu}," ${deputy} says 
              *if (deputy != simon)
                without the least 
              *if (deputy = simon)
                after a moment's
              hesitation. "Wherever you think they came from." 
              
              *goto foundphials
            #There's no room for scruples at this point.  I go hunting for them.
              *label foundphials
              It takes an hour's hard scrambling to find the 
              *if plekkeepers > 1
                 corpses of the Plektoi keepers.
              *if plekkeepers = 1
                the fallen Theurge's body.
              *set plekkeepers (plekkeepers*3)
              Though many blood phials were shattered, you return with 
              *set d2n_num plekkeepers
              *gosub d2n
              more in your tattered coat.
              *set blood +plekkeepers
              *set plekkeepers (plekkeepers/3)
              *goto allready
        *label allready
        All is ready by the time the first Phalangites break cover on the slope below.

        *if (korszata = 0) and not(bloodcheck)
          *page_break
        *goto armyfight
  *if strategy > 1
    we've got enough of a head start on them that if we leave now, they'll never catch us.  No army can outpace us in the deep wild."
    *fake_choice
      #"Hurry, then.  Let's move while we can."
      #"Do we have time to tend to our dead?"  I know the answer, but ask anyway.
        "I'm sorry, ${addressu}.  By the time we did anything, the army would be upon us."  She waits for a moment. When you don't speak, she calls to the others, "Haste to be gone, then.  We don't want to lose our lead."
      #"Run?" I feel a wash of hatred overpower everything else. "From the bastards who set Plektoi on us?  We should stand and fight.  We should destroy them."
        She blinks at you, then leans in close.  "This is no time for a change of strategy, ${addressu}.  Look around you.  The band's on the verge of breaking.  We had the Angels' own luck this morning, but we can't expect it to last against Phalangites.  We can run.  We should run."

        You look around at your haggard survivors, and have to admit she's right.
      #I stare dazedly at her, unable to speak.
        She exhales raggedly through her nostrils, then shouts over your shoulder to the rest.  "Haste to be gone, then.  We don't want to lose our lead."
    *goto slipaway
*label armyfight

The Phalangites who arrive at the brow of the hill are clearly expecting to find you in disarray, broken by the Plektos attack.  It's an unpleasant surprise for them to instead find a line of spears at the top of the steep climb, and arrows falling from unseen archers into the narrow watercourse.  At least a dozen of them die before they pull back.

*set phalangites -16
*set theirmorale -20
*set theurges +plekreinforce
*if theurges > 0
  The enemy
  *if theurges = 1
    Theurge flies
  *if theurges > 1
    Theurges fly
  warily around the columns of smoke and begin hurling vitriol phials down onto your defenders.
  *if plekreinforce > 0
    *if plekreinforce = theurges
      The 
      *if theurges = 1
        Theurge whose Plektos 
      *if theurges = 2
        Theurges whose Plektoi
      you killed are now the only ones with the army.
    *if plekreinforce != theurges
      There are 
      *set d2n_num theurges
      *gosub d2n
      of them now, joined by
      *if plekreinforce = 1
        the Plektos keeper whose beast 
      *if plekreinforce = 2
        two Plektos keepers whose beasts
      you killed.
  *set cas +(theurges*5)
  *if (com > 1)
    But you'd set the smudgefires—and the targets—in such a way that it would guide the
    *if theurges = 1
      mage
    *if theurges > 1
      magi
    along a specific course,
    *if snapsand
      hoping that
      *if theurges = 1
        he
      *if theurges > 1
        they
      wouldn't have worked out the role of sand in bringing down
      *if theurges = 1
        his
      *if theurges > 1
        their
      comrades.
      
      The trap springs with the snap of a conifer and another cloakful of sand flying into the air.
    *if not(snapsand)
      and
      *if theurges > 2
        two of them have
      *if theurges = 2
        they've
      *if theurges = 1
        he's
      taken the bait.
      
      You hear the snap of a conifer whipping upward as your bandits cut the rope holding it down. It's no catapult—you couldn't get it to fling a load of any size with accuracy.  But it hoists a cloak-full of fine river sand into the air, making a cloud that doesn't need to be accurate to be blinding.
      
      *comment endif
    The
    *if theurges = 1
      Theurge shrieks and claws his eyes
    *if theurges > 1
      Theurges shriek and claw their eyes
    before dipping, veering into the smoke.  Your bandits shower 
    *if theurges = 1
      him
    *if theurges > 1
      them
    with arrows and bolas.
    *if theurges = 1
      And he 
    *if theurges > 1
      And one of them
    goes down, choking and clutching at the arrowshaft in his stomach.
    *set morale +30
    *if theurges > 1
      The second one spirals off into the woods, cursing blindly at you.
    *if theurges > 2
      The remaining
      *if theurges > 3
        Theurges
      *if theurges = 3
        Theurge
      who circled round the outside of High Crag
      *if theurges > 3
        yell
      *if theurges = 3
        yells
      in shock and outrage, then 
      *if theurges > 3
        redouble their 
      *if theurges = 3
        redoubles his
      assault.
    *set theurges -1
    
    *set notoriety +10
    *set theirmorale -50
  *if int > 1
    *if (blood = 0) and (consc < 1)
      *gosub swaymis
    *if (blood != 0) and (consc >= 1)
      You know that the Theurges have a chance at sensing anything you do with your blood.  But this could be the moment that breaks you, unless you take action.
      *choice
        #I cut my hand and strike back with my own ${wisardry}.
          *set consc -1
          *if theuknown >= 7
            *label theuduel
            The Theurge nearest you seems to sense something as soon as you try to make a Change, and spins in the air with a savage curse.  "The Goete!" he yells at the top of his lungs. "The Goete is here!"
            
            You find yourself brutally outmatched in a Theurgic duel—far less experience, far less blood.  For several seconds, you hold your own, snuffing out his vitriolic fireballs as he hurls them at you.  But you don't ever quite manage to take the offensive; once or twice you try to ignite the vitriol in his hand, but he mentally bats your Change away without apparent effort.
            
            The only consolation of losing the duel is that by the time you do, you're losing consciousness so rapidly that you don't feel the flames that kill you.
            *goto_scene death
          *gosub theustrike
          *goto theublastcas
        *if (blood > 0) #I use a blood phial.
          *set blood -1
          *set usedblood +1
          *if theuknown >= 7
            *goto theuduel
          *gosub theustrike
          *goto theublastcas
        #I hold back.  I don't stand much chance against a seasoned Theurge.
          *goto theublastcas          
  *label theublastcas
  *set cas +(theurges*4)
  *if (com > 1) and (theurges > 1)
    *set cas -4
  *if cas > (inadults-10)
    *label theufirerun
    *set cas (inadults-21)
    The rain of Theurgic fire is too much for your beleaguered outlaws.  The score or so who survive the attack flee from the smoking bodies of their comrades.  
    *gosub armscheck
    *gosub cascheck
    *label soundretreat
    You scramble after them, defeat bitter in your throat.
    *page_break
    *goto retreating
  *if cas > 0
    You can barely see for the bursts of flame and thick sulfurous smoke on every side.  All you know, from the shrieks, is that your outlaws are dying by the score.
  *gosub cascheck
  *set morale -(theurges*10)

Then you hear yelling from the northeast shoulder of the crag, where a handful of your outlaws are watching for Phalangites scaling the steep slope.  Apparently
*if theurges > 0
  under cover of Theurgic fire
some of the Archon's troops found 
*if theurges = 0
  a cliff route your scouts overlooked,
*if theurges > 0
  their way up,
and are now tearing into your defenders.
*if theurges > 0
  The vitriolic fireballs stop; the Theurges have some compunction about blasting their own troops.
*if int > 1
  *if (blood = 0) and (consc < 1)
    *gosub swaymis
  *if (blood > 0) or (consc > 0)
    *set d2n_num theurges
    *gosub d2n_np  
    *choice
      #I cut my hand and hurl the Phalangites back with ${wisardry}.
        *set consc -1
        *label hurlphal
        *rand theucatch 1 100
        *if theucatch < (theurges*15)
          Somehow, despite all the chaos and smoke of the battlefield, 
          *if theurges > 1
            a
          *if theurges = 1
            the
          Theurge detects your attempt at a Change.  
          *label suddendeath
          Sudden, agonizing heat and the pungent smell of vitriol overwhelm all your other senses, and you topple dying to the dirt.
          *goto_scene death
        Keeping low to the ground, you run toward the clash and begin to levitate the Phalangites' booted feet.  One by one, they fly head-over-heels, howling in shock and terror.  Your rebel fighters cheer and hack at them while they're prone.  When you get close enough to see the soldiers scaling the steep slope, your brief bursts of levitation throw them off-balance and send them hurtling off a fifty-yard drop.
        
        By the time the blood evaporates from your hand, the assault has been decisively thrown back, and almost two dozen Phalangites are dead.
        *set phalangites -22
        *set alltroops -22
        *if theurges > 0
          Despite the screams of, "Goety!" no fireball erupts around you.  You must have been lucky enough to avoid detection this time, with all the smoke still in the air from your smudgefires and the first round of Theurgic attack.
        *if theuknown < 10
          *set cred_p -50
        *set theuknown 10
        *set theirmorale -42
        *set morale +10
        *if inadults > 25
          *set cas +6
        *if inadults < 26
          *set cas +round(inadults/4)
        *gosub armscheck
        *gosub cascheck
        *goto nextwar
      *if (blood > 0) #I open a blood phial and hurl the Phalangites back with ${wisardry}.
        *set blood -1
        *set usedblood +1
        *goto hurlphal
      *if (theurges > 1) 
        #It's too risky, with ${display_numb} Theurges in the air, any of whom might sense what I'm doing.
          They'd find you in a heartbeat if you started throwing Phalangites off the crag.  Instead…
          *goto cliffchoice
      *if (theurges = 1) 
        #It's too risky, with a Theurge still hunting for me.
          He'd find you in a heartbeat if you started throwing Phalangites off the crag.  Instead…
          *goto cliffchoice
      #I want to reserve my blood for when it's needed most.
        Every dram of
        *if blood > 0
          aetherial
        blood is precious in a battle like this.  Instead…
        *goto cliffchoice
*label cliffchoice
*choice
  #I lead the charge against them.
    *if com = 0
      It's a valiant attempt—but your combat skills aren't up to the task of facing the Thaumatarchy's elite soldiers.  Your charge ends almost as soon as you reach the enemy, with a sword through your skull.
      *goto_scene death
    *if com > 0
      Your rebels need to see you fighting shoulder to shoulder with them.  It's that knowledge that sends you hurtling toward the red-armored formation that's taking shape at the top of the cliff…you along with
    *if inadults < 40
      virtually every other rebel on the crag,
      *goto cliffoutcome
    *elseif inadults < 60
      two dozen other rebels,
      *goto cliffoutcome
    *else
      dozens of other rebels,
      *goto cliffoutcome
    *label cliffoutcome
    raising a cacophony of battle-cries.

    *if com = 1
      *if inadults < 38
        *label notenuf
        But there simply aren't enough of you left to push them back.  When a third of your rebels have fallen and the Phalangites are still claiming an ever-broader foothold atop the cliff, your survivors turn and flee for the caves.
        *set cas +round(inadults/3)
        *gosub armscheck
        *gosub cascheck
        *goto soundretreat
      And you survive—barely.  It's sheer good fortune that of the three rebels attacking a single soldier, it's the man on your left who falls with a split skull, rather than you.  Through force of numbers, you push the Phalangite avant-garde backwards and keep them from establishing a foothold atop the cliff.  Just when you're sure your line is about to give way, another gang of bandits
      *if rad_here
        led by Radmar
      arrives to reinforce you, roaring defiance to the Thaumatarch. 

      At last, with fifty dead or dying atop the cliff—most of them yours—the enemy retreats.
      *set cas +30
    *if com = 2
      And you hit them at just the right moment, before they quite manage to close off their right flank.  The Phalangites fight with courage and brutal skill, but their foothold atop the cliff is still tenuous enough that even the Hegemony's best troops can't defend it.  Not against a captain of your skill, at any rate.  You lose thirteen rebels in the clash, but at the end of it they scramble back, having lost even more.
      *set cas +13
      *set theirmorale -10
    *label postcliff
    *gosub cascheck
    *set phalangites -22
    *set alltroops -22
    *set theirmorale -30
    *goto nextwar
  #I try to inspire my followers—at the risk of drawing attention to myself.
    *rand theucatch 1 100
    *if theucatch < (theurges*5)
      Somehow, despite all the chaos and smoke of the battlefield, 
      *if theurges > 1
        a
      *if theurges = 1
        the
      Theurge overhears your orders.  
      *goto suddendeath
    *if cha < 2
      *goto holdback
    Your followers take heart at your sharp, fearless orders, and hit the red-armored formation atop the cliff before it has time to protect its right flank.
    *if inadults < 30
      *goto notenuf
    The fight is brutal, but you keep shouting out encouragement from the smoke, and in the end your rebels prevail through force of numbers and sheer determination. 
    *set cas +22
    *goto postcliff
  #I hold back and direct others to shore up the defenses.
    *label holdback
    Your followers charge toward the cliff and the red-armored formation that's taking shape there.
    *if inadults < 46
      *goto notenuf
    Thankfully, you have the numbers to prevail—but even defending a tenuous foothold on a clifftop, the Phalangites kill two of your rebels for every one of them who falls.  More than sixty bodies litter the slope by the time they fall back.
    *set cas +41
    *goto postcliff
*label nextwar
*page_break
*if theirmorale < (alltroops/7)
  *goto youwon
*if (inadults < 27) or (morale < inadults)
  *label toofew
  Your survivors look at each other, then down at what can be seen of the remaining enemy force.  "We've not got enough," Earnn says, voice cracking. "Not even close."  He's not the first to break for the caves, but nor is he the last.
  *goto soundretreat
Another, much larger assault force has started up the watercourse and the slopes around it while you've been focused on the northeastern clifftop.  The soldiers' shields bristle with arrows from your surviving archers, but
*if theurges = 0
  they'll soon have to lower those shields when they reach your barricades.
  *set phalangites -18
  *set alltroops -18
  *set theirmorale -20  
*if theurges > 0
  with most of your lower barricades blasted by Theurges, there's nothing to make them lower their defenses before they reach you. 
"Make ready!" you bellow, waving wildly down toward the Phalangite advance.
*if kal_here

  ${kalt} charges
*if simz_here

  ${simon} leaps
*if (simz_here) or (kal_here)
  down to
  *if theurges = 0
    join the shakiest-looking defenders on the first ditch.
  *if theurges > 0
    defend a barricade, beckoning a few rebels after ${zhim}.
*if kal_here
  "They'll not get past us," ${zhe} barks, raising a spear high. "Give the bastards some extra red on their damned armor!"  When the first Phalangites arrive and try to hack past your
  *if theurges > 0
    burning
  *if theurges = 0
    improvised
  wall of thorns and wooden spikes, ${kalt} leads a push that sends them back down the slope.
  *set phalangites -16
  *set alltroops -16
  *set theirmorale -20  
*if simz_here
  The de Firiac meets the Phalangites as they try to force their way through your improvised defenses—and ${zhis}
  *if s_sword != 1
    captured
  sword slips swift and smooth as a bird in flight, round their weapons, through their armor, sending one after another tumbling back down the hill with a grave wound.  $!{zhe} turns the thorns and wooden spikes into an impenetrable wall, the small band of fighters around ${zhim} into an invincible force.
  *set phalangites -28
  *set alltroops -28
  *set theirmorale -38
*if (alltroops < inadults) or (theirmorale < (alltroops/4))
  *page_break
  *goto youwon
*if korszata = 2
  
  The former Phalangite Bjel beckons a small band of his fellow ${whend}s out along a side trail.  Arrows fly up at them from enemy archers below, but a few minutes later, you hear a rumble and see a large boulder thundering down the mountainside, into the lower reaches of the watercourse.  Screams rise faintly from the dust.
  *set phalangites -32
  *set alltroops -32
  *set theirmorale -40
*if diakon > 9
  
  *if diakon > 13
    Diakon Edwer and some of his
  *if diakon <= 13
    The diakons and some of their
  mace-wielding helots hurry down to
*if etthena > 0

  The heresiarch Etthena leads a gang of Disbelievers down to
*if (diakon > 9) or (etthena > 0)
  *if theurges > 0
    take the place of Theurgy-burned defenders.
  *if theurges = 0
    reinforce a defensible ditch.
  A cry goes up:
  *set phalangites -32
  *set alltroops -32
  *set theirmorale -40
*if (diakon > 9)
  "Fight for the Angels and the True Codex!"
*if (etthena > 0)
  "For
  *if religion > 19
    the truth of kenon, and for
  ${addressu} ${fname}!"
*if bethune > 0
  
  The Westriding yeomen stand in reserve at first, but charge down as soon as they see a barricade about to fail, bellowing, "Cabel's Bones!"  They hammer into the Phalangites, heedless of blades and armor.
  *set phalangites -22
  *set alltroops -22
  *set theirmorale -25  
*if uthwen = 2
  Treth and the Brecklanders range along the clifftop, picking off vulnerable enemies with arrows.
  *set phalangites -12
  *set alltroops -12
  *set theirmorale -12  

A mighty blare of Phalangite horns rises from the woods below, along with a hammering of swords on shields.  The attackers on the slopes bellow, "Hegemony!" and press on relentlessly into your defenses.
*if arms < ((inadults*5)/6)
  Only 
  *set d2n_num arms
  *gosub d2n
  of your rebel fighters are armed with steel.  While their pikes and bows take their toll on the enemy, when it comes to hand-to-hand, many outlaws die on Phalangite swords.
  *set cas +round((inadults-arms)/4)
  *gosub cascheck
*if arms >= inadults
  All your rebels are armed with steel, as well as long wooden pikes to push the Phalangites back.
*if com > 1
  You crouch under cover of
  *if theurges > 0
    smoldering
  brush atop the slope and direct reinforcements to positions that look about to be overrun.
  *set cas -round(inadults/9)
The fighting goes on for what feels like hours thick with smoke, dust, and blood, but is in reality a half hour at most.
*if int > 1
  *if (blood = 0) and (consc < 1)
    *gosub swaymis
  *if (blood > 0) or (consc > 0)
    *choice
      #I cut my hand and wield ${wisardry} against them.
        *set consc -1
        *label hurlphal2
        *rand theucatch 1 100
        *if theucatch < (theurges*15)
          Somehow, despite all the chaos and smoke of the battlefield, 
          *if theurges > 1
            a
          *if theurges = 1
            the
          Theurge detects your attempt at a Change.  
          *goto suddendeath
        Focusing your mind on a great overhang of stone, you try to make it heavier, encouraging it to fall.
        *if theurges > 0
          Just as you feel it begin to give way, you also feel resistance—a Change opposing yours, a mind seeking yours out.  But it's too late.
        With a deafening crack, the outcrop plummets downslope and rolls into the woods, wiping out a squad of soldiers along the way.
        *if theurges > 0
          You crouch in the undergrowth, unmoving, for a long time until you're sure that the Theurges aren't going to find you.
          *if theuknown < 10
            *set cred_p -50
          *set theuknown 10
        *if korszata = 2

          When you lift your head, you can see that the Phalangites are all moving far more slowly now.  After Bjel's boulder and your attack, they're clearly afraid that at any moment a bit of the mountain will come thundering down on their heads.
          *set theirmorale -10
        *set phalangites -25
        *set alltroops -25
        *set theirmorale -45
        *set morale +10
        *goto firstroundres
      *if (blood > 0) #I use a phial of aetherial blood.
        *set blood -1
        *set usedblood +1
        *goto hurlphal2
      #No—this isn't the hour of greatest need, and I don't want to risk detection by a Theurge.
        Every dram of
        *if blood > 0
          aetherial
        blood is precious in a clash like this.  You hold back while the battle rages below you.
        *goto firstroundres
*label firstroundres
*set cas +round(inadults/6)
*set phalangites -round(inadults/2)
*set alltroops -round(inadults/2)
*set theirmorale -round(inadults/2)
*gosub armscheck
*gosub cascheck
*page_break
At long last, there's a single horn blast, then silence.  The first, least organized wave of Phalangite attack has been pushed back. You can see the survivors withdrawing in good order down a slope strewn with dead.  

*if (inadults < 27) or (morale < inadults)
  *goto toofew
"They thought they could break us that quick and easy,"
*if (el_here and not(elsick)) and (yebben > 0)
  Elery
*if ((not(el_here) or elsick) or (yebben < 1)) and (rad_here)
  Radmar
*if ((not(el_here) or elsick) or (yebben < 1)) and not(rad_here)
  Alira
says, coughing but bright-eyed.  "They thought 
*if theurges > 0
  a few fireballs,
*if lostem
  some Plektoi
*if not(lostem)
  a Plektos
and the sight of red armor would be enough to send us running from a defended position on high ground.  Reckon they'll know us better this time."

*if theurges > 0
  "Why did they attack up the slope in the first place?" Young Earnn asks, trembling. "They know where we are.  Why not just have the Theurges keep blasting us until there were none of us left?"
  
  "Maybe they're lower on blood than they'd like to be."  You grasp at the most comforting explanation, for your own morale as much as your followers'.  [i]Or maybe they just believed we would run, and they would capture more of us.  A burned rebel's less use than a Harrowed one.[/i] "Still, be ready for more fire when they decide how they're going to try again."
  *page_break
You limp from position to position, doing a quick headcount and receiving reports from elsewhere on the crag.  
*if kal_here
  ${kalt} is still alive, clapping ${zhis} similarly blood-spattered comrades on their shoulders and congratulating them on seeing off the Phalangites.
*if simz_here
  ${simon}'s face is unspeakably weary, but ${zhis} movements are still smooth and quick as ${zhe} tends to the wounded.
*if diakon > 13
  You hear reports that Diakon Edwer was stabbed in the guts by a Phalangite but only fell back a yard or two and kept enjoining his followers to fight.  By the time you reach him, he's bled to death.
  *set diakon -2
*if etthena > 0
  Etthena is dead on one of the lower barricades along with many of her Disbelievers, having turned back a Phalangite squad half again their number.
  *set etthena 0
*if bethune > 0
  The Westriding rebels report that their leader Bethune fell in combat.
  *set bethune 0
*if korszata = 2

  When you see a figure in Phalangite armor trudging through the dust, you raise your ${weapon} on instinct before realizing it's Korszata.  The towering ${whend} looks stricken. "Bjel is fallen, ${addressu}.  An arrow took him as he came from his trap."
  
  "He died well," you say hoarsely.  You hardly knew the man; it's impossible to muster grief for him amongst all the other dead. But when Korszata only stands, glassy-eyed and swaying slightly, you add, "He will not be forgotten.  Not by our enemy.  Not by us."
  
  The former Phalangite shakes off his grief and bows.  "Honor to serve, Oath-Holder."
  
  *set korszata 1
Overall, it seems that
*set d2n_num inadults
*gosub d2n
of your defenders are still alive and braced for the next wave.
*if (dadfeel = 0) or (hdead = 1)
  *set roundone true
  But you can't find your father—either in the casualties or the defense. Heart pounding, you climb back toward the sites of the Plektos attacks.
  *page_break
  *goto postroundone
A few minutes pass, quiet and tense.  You drink from the pool and send waterskins down to the barricades; the stream below is too fouled to sate your followers' desperate thirst.
*page_break
*label roundtwo
Then a cry pulls you back to the edge of the slope.  
*if theurges > 0
  "Theurges!  Theurges coming!"
  
  The enemy
  *if theurges = 1
    Theurge soars
    *set theuthey "he"
  *if theurges > 1
    Theurges soar
  in to uproot your smoking wooden barricades and drop the remnants on your rebels.  Your bandits' arrows bounce off
  *if theurges = 1
    his cowl
  *if theurges > 1
    their cowls
  without effect. Several unfortunate archers are plucked howling into the air and flung down the steep mountainside.  Only then does the vitriol bombardment begin again.
  *if (com > 1) and (theurges > 1)
    The Theurge you blinded but couldn't kill in your initial attack is particularly vengeful.
  *if int > 1
    *if (blood = 0) and (consc < 1)
      *gosub swaymis
    *if (blood > 0) or (consc > 0)
      *choice
        #I cut my hand and strike back with ${wisardry}.
          *set consc -1
          *if theuknown >= 7
            *goto theuduel
          *gosub theustrike
          *goto theublastcas2
        #I open a blood phial.
          *set blood -1
          *set usedblood +1
          *if theuknown >= 7
            *goto theuduel
          *gosub theustrike
          *goto theublastcas2
        *if (theuknown >= 10) 
          #That would be madness.  Knowing I'm a ${wisard}, ${theuthey}'ll be alert to any Change I make.
            *goto theublastcas2
        *if (theuknown = 7) 
          #Far too risky.  If our deserters have told the wrong tales, ${theuthey}'ll be alert to any Change I make.
            *goto theublastcas2
        *if (theuknown < 10) 
          #No.  Even now, I don't want to reveal my powers to the army.
            *goto theublastcas2

  *label theublastcas2
  The watercourse looks like a flaming river, and the forest around the pool is ablaze. 
  *set cas +(theurges*11)
  *set morale -(theurges*15)
  *if cas > (inadults-10)
    *goto theufirerun
  You huddle in the space between two boulders, gasping in the sulfur-smelling air.  Even through your dampened wool cloak the heat is blistering.
  *fake_choice
    #$!{oath}, we're going to die.  We'll all be ashes before they stop.
    #We're going to live.  Somehow we'll survive this.
    #We're going to break them. I swear I'll break them for this.
  At long last, the rain of fire stops.  After a few minutes of silence, the boldest rebels steal out to the edge.  You hear
  *if el_here and not(elsick)
    Elery's
  *if (not(el_here) or elsick) and rad_here
    Radmar's
  *if ((not(el_here) or elsick) and not(rad_here)) and kal_here
    ${kalt}'s
  *if ((not(el_here) or elsick) and not(rad_here)) and simz_here
    ${simon}'s
  *if ((not(el_here) or elsick) and not(rad_here)) and (not(simz_here) and not(kal_here))
    Alira's
  ragged shout:
"Phalangites—coming straight up the hill!"
*if (inadults < 27) or (morale < inadults)
  *goto toofew

This time, they're climbing up slowly, keeping to whatever cover they can find.  You gesture to a small gang who have rolled the
*if theurges > 0
  now-smoldering
corpse of the
*if lostem
  first
Plektos to the cliffside.  They push it over the edge.  It cartwheels down, hitting only a few Phalangites—but from the shocked oaths and moans, you think many more are dismayed to see that your band could kill one of the hounds of Karagon.
*set phalangites -6
*set alltroops -6
*set theirmorale -30

*if theurges > 0
  That draws the 
  *if theurges = 1
    Theurge 
  *if theurges > 1
    Theurges
  back, though. Any of your archers who loose arrows at the Phalangites get blasted from the air.
  *set cas +4
  *gosub cascheck
*if theurges = 0
  As they recover themselves and resume the climb, your surviving yeoman archers
  *if uthwen = 2
    and Brecklanders
  rain arrows down on them.  The great clumps of thorn-brush that you've rolled down the watercourse slow their advance further, exposing them to arrows.
  *set phalangites -22
  *set alltroops -22
  *set theirmorale -22

At last, when the enemy troops are nearly upon you, 
*if plekspear
  ${deputy} salutes you with ${dephis} whorled boar-spear. "Seems they aren't about to set another Plektos on us, ${addressu}…so I'd best put this to use while we live."
  
  In the haze of your smudgefires and the dust stirred up by the combat, it takes the Archon's forces several minutes to realize what kind of disaster they're facing.  Two assaults fail, and fail with astonishing speed. None of the Phalangites survive, and you can imagine that from below it's hard to see that their armor has been riven as if it were cloth.  
  
  Then a handful advance more cautiously, and out of the dust you hear the scream: "Mage-spear! The bastards have a ma—"
  *if theurges > 0
    Seconds later, the 
    *if theurges = 1
      Theurge flies
    *if theurges > 1
      Theurges fly
    in and shower the battlefield with vitriol.  
  *if theurges = 0
    Several more minutes pass.  Then another Phalangite squad marches into the battle-haze, and this time the fight isn't over quickly.  Instead, there's a shattering clang, and rising shrieks from your rebels.
    
    *if (calea > 9) or (intelsale > 0)
      "The Theurge-forged sword." Earnn's face is suddenly drawn with realization. 
    *if (calea < 10) and (intelsale < 1)
      You don't know what's happening until the first survivor runs shrieking up to fall at your feet.
    "The Tagmatarch came for
    *if deputy = simon
      ${zkuria}
    ${deputy}."
    *if (calea < 10) and (intelsale < 1)
      His eyes are wide, and he holds out what's left of his steel blade. "She's got a bloody Theurge-forged sword.  Can cut anything."
    
  *if (deputy != "Elery") and (deputy != "Alira")
    The handful of survivors who flee back to the woods confirm what you'd feared—${deputy}'s body lies with the other fallen, the spear is lost to you, and the Phalangites are rallying for another push up the hill.
  *if theurges = 0
  
    "Before dying, ${deputy} threw the spear off a cliff rather than lose it to the Phalangites," one rebel says hoarsely. "The Tagmatarch's gone after it.  The rest will be here any moment."
  *if deputy = "Zvad"
    *set zv_here false
    *set zvad -50
  *if deputy = "Breden"
    *set bred_here false
    *if theurges = 0
      *set breden 5
    *if theurges > 0
      *set breden 6
  *if deputy = "Radmar"
    *set rad_here false
    *set radmar -50
  *if deputy = simon
    *set simz_here false
    *set s_rel -50
  *if (deputy = "Elery") or (deputy = "Alira")
    *set cas +5
    *gosub armscheck
    *gosub cascheck
    You were sure ${deputy} would be dead—but minutes later she reappears at the top of the slope,
    *if theurges > 0
      drenched, scorched, and
    *if theurges = 0
      injured and
    trembling. "I lost the spear, ${addressu} ${lname}.
    *if theurges > 0
      Blasted Theurges found it while I was hiding in the stream, trying not to burn to death.  Now they're on their way up to us."
    *if theurges = 0
      Their captain blocked me, almost put her sword in my guts.  The only way I could live was to drop it, jump right back.  Everyone else started grabbing for it, and the Tagmatarch chopped up five of us before the last one held on to the spear long enough to toss it off a cliff."
      
      "It's gone?" you say incredulously.
      
      ${deputy} nods, shame-faced, one hand clenched on her heavily bleeding shoulder.  "The Tagmatarch's gone after it.  The rest will be here any moment."
  *set phalangites -65
  *set alltroops -65
  *set theirmorale -95
  *set plekspear false
  *page_break
*if korszata > 0
  Korszata gives you a grim salute and leads his surviving ${whend}s charging down
  *if theurges > 0
    the flame-scoured slope
    *set phalangites -20
    *set alltroops -20
    *set theirmorale -25
  *if theurges = 0
    to the barricades 
    *set phalangites -40
    *set alltroops -40
    *set theirmorale -50
  to meet them.  They vanish into the smoke and dust.
*if rad_here
  Radmar roars, "Throw them down to Taratur!" and leads
  *if korszata > 0
    another gang of cursing bandits into the fray.
  *if korszata = 0
    *if theurges > 0
      a charge down the slope.
    *if theurges = 0
      a party to the lower barricades.
*if (korszata = 0) and not(rad_here)
  your rebels
  *if theurges > 0
    dash out to the edge and pelt them with large stones.  With a thin cry of, "For the ${sigil}!" they draw their weapons and charge down the flame-scoured slope.
  *if theurges = 0
    give a great cry of, "For the ${sigil}!" and meet them at your battered barricades.
*if kal_here or simz_here
  For a moment, through the smoke you spy
  *if kal_here
    ${kalt}
  *if simz_here
    ${simon}
  desperately holding off a red-armored foe.
*set cas +round(inadults/4)
*if arms >= (inadults/2)
  *set phalangites -round(inadults/2)
  *set alltroops -round(inadults/2)
  *set theirmorale -round(inadults/2)
*if (arms < (inadults/2)) and (arms >= (inadults/5))
  *set phalangites -arms
  *set alltroops -arms
  *set theirmorale -arms  
*if arms < (inadults/5)
  *set cas +round(inadults/5)
  *set phalangites -round(inadults/5)
  *set alltroops -round(inadults/5)
  *set theirmorale -round(inadults/5)
*if int > 1
  *if (blood = 0) and (consc < 1)
    *gosub swaymis
  *if (blood > 0) or (consc > 0)
    *choice
      #I cut my hand and wield ${wisardry} against the Phalangites.
        *set consc -1
        *label hurlphal3
        *rand theucatch 1 100
        *if theucatch < (theurges*15)
          Somehow, despite all the chaos and smoke of the battlefield, 
          *if theurges > 1
            a
          *if theurges = 1
            the
          Theurge detects your attempt at a Change.  
          *goto suddendeath
        A grand old pine tree, felled by some winter storm, lies
        *if theurges > 0
          burning
        at the edge of the slope.  You levitate the root end out of the soil, giving it some spin, before releasing it to crash end-over-end down the mountain.
        *if theurges > 0
          *if theurges > 1
            The Theurges see
          *if theurges = 1
            The Theurge sees
          what you're doing, and try to lift the tree before it hits a Phalangite troop—but you spend the last of your blood fighting them, and the tree is moving too fast to stop. 
          *if theuknown < 10
            *set cred_p -50
          *set theuknown 10
        It plows through a red-armored formation, leaving bodies strewn in its wake.
        *set phalangites -18
        *set alltroops -18
        *set theirmorale -36
        *set morale +10
        *goto 2roundres
      *if (blood > 0) #I use a phial of aetherial blood.
        *set blood -1
        *set usedblood +1
        *goto hurlphal3
      #No—this isn't the hour of greatest need, and I don't want to risk detection by a Theurge.
        Every dram of
        *if blood > 0
          aetherial
        blood is precious in a clash like this.  You hold back while the battle rages below you.
        *goto 2roundres
*label 2roundres
*gosub armscheck
*gosub cascheck
*if (el_here and not(elsick))

  Then Elery's with you, gripping your shoulder, eyes wide and white in her soot-covered face. "There's no chance, ${addressu}.  No way they're making the same mistake again.  Marching straight up at us?"
  
  *if theurges > 0
    You stare at her in disbelief.  "$!{oath}, Skinner, they probably think we're all ashes."
    
    "No."  She points down at the troops.  "It's a force just big enough to pin us down here while they move up behind.  Coming up the cliff through the trees.  If they get enough soldiers up while we're distracted here…"
    
    Chewing on one cracked lip, you weigh her words for a few moments before nodding.
  *if theurges = 0
    You blink at her for a moment, then nod.
  "Take a band back into the woods.  See if they've found another way up."
*if (com > 1) and (not(el_here) or elsick)
  "They're making the same mistake again," Young Earnn says from your shoulder,
  *if theurges = 0
    nocking another arrow.
  *if theurges > 0
    keeping his bow lowered until the smoke blows your way to hide you from the 
    *if theurges = 1
      Theurge.
    *if theurges > 1
      Theurges.
  "Coming straight up at us."
  
  You share his satisfaction only for a moment—then step back, suddenly aghast.  "No.  No, they can't be.  No Phalangite captain would waste lives like this without cause."  Gripping his shoulder, you pull the young scout away from the edge of the crag. "Take a band back into the woods.  See if they've found another way up."
*page_break
*if (el_here and not(elsick)) or (com < 2)
  Ten minutes later, you hear cries and the clash of steel from behind you.
  *if not(el_here)
    Earnn clearly found something. 
    
    *comment endif
  You run back and find a battle underway in the woods.  Your outlier guards lie dead, killed noiselessly by Alastor trackers.  Two dozen Phalangites have made their way up a barely visible track on the bluff to a broad ledge beneath the crag. Many more are climbing up behind them.
  *if (not(el_here) or elsick)
    *set cas +2
    Earnn is holding them back for the moment, blocking the only route up from the ledge.  But his handful of rangers are struggling to contain the Phalangites, and two have already fallen.
    
    You shout for a few sturdy fighters and charge down to relieve Earnn's archers. "Get to a vantage where you can use bows against them!" you roar, batting back a Phalangite with your ${weapon}.
    
    For the next ten minutes, you fight as hard as you have in your life.  The Hegemony's infantry are skilled and relentless, if slightly slowed by a strenuous climb in full armor. It's all you can do to keep them from beheading you, let alone land a blow on them.  But the terrain is on your side, keeping them from engaging more than one-on-one.  
    
    And from above, former helots pelt them with sling shot and yeomen with arrows.  Over your shoulder, you can hear Young Earnn yelling orders as his archers rake the cliffs, felling other Phalangites who were edging their way up the track.  You keep all your focus on the man you're fighting—until the moment that he crumples, an arrow in his back, freeing you up to kill the soldier next to him.  Behind them, not a single red-armored figure remains standing.
    
    All around you, your rebels break into weary but elated cheers.  You've turned what could have been a battle-ending ambush into a catastrophe for the Archon's forces.
    *set morale +10
    *page_break
  *if el_here and not(elsick)
  
    But Elery has a handful of sturdy fighters blocking the only route up from the ledge, and archers in place to rain arrows onto it.  As you arrive, she's found a vantage from which a few more archers can rake the cliffs, felling dozens more who are edging their way up.  If the Phalangite ambush had succeeded, it would have been the end of the battle for you. Instead, it's turned into a catastrophe for the Archon's forces.
    
    The dying Phalangites on the ledge draw bows themselves.  You can see one of them casting around until he spies who's giving the orders.  Your yell of, "Elery! Get down!" comes only seconds before the arrow takes her in the back.  She topples forward into a pine thicket.
    
    By the time you reach her, nearly all the Phalangites are dead—and so is Elery Skinner.  You kneel at her side, listening in vain for breath.
    *fake_choice
      #[i]Oh, ${oath}, no.[/i]  Hot tears spill down my face.
        You only allow yourself a few moments to mourn.  When you stand, you can see similar grief on others' faces. "She died saving us."
        
      #"Vengeance!" I roar hoarsely. "Vengeance for every martyr!"
        The shaken rebels around you add their shouts to yours.
        
      #There's no time to do anything but run back to the battle.
    *set elery -50
    *set el_here false
    *set morale +10
  *set phalangites -55
  *set alltroops -55
  *set theirmorale -75
  You hurry back to the top of the watercourse, where the Phalangite advance has
  *if theurges = 0
    faltered.
    *set phalangites -70
    *set alltroops -70
    *set theirmorale -85
    *if (alltroops < inadults) or (theirmorale < (alltroops/2))
      When the cry goes out that their ambush has failed, they stumble back, some of the will visibly going out of them.
      *goto youwon
    The hill slope is strewn with red-armored bodies. Attacking uphill into a force well supplied with archers has been brutally costly, and the failure of their ambush will be even more disheartening when the news reaches them.  But they've kept up their morale and have now
  nearly pushed your forces back into the
  *if theurges > 0
    blazing
  woods.
  *if theurges > 0
    As you arrive, a vitriolic fireball explodes a dozen yards from you, scorching your face and leaving you momentarily blinded.  
    
    When the world around you becomes hazily visible again, you can see that the combination of bombardment from the air and the implacable ground assault has your rebels on the verge of a rout. None
    *set cas+(theurges*12)
    *set morale -10
  *if zv_here
    *gosub zvfall
  *if theurges = 0
    Few 
  of your blockades remain standing, and without the protection of thorns and spiked boughs, your followers are dying rapidly.
  *choice
    #"Fall back to the caves!"
      *if zv_here
        *gosub zvfall
      *goto cavewar
    #"Fight them in the woods!"
      *if zv_here
        *gosub zvfall
      *goto woodswar
    #"Stand and throw them back!"
      *if (cha < 1) or (morale < inadults)
        They ignore your call.
        *if zv_here
          *gosub zvfall
        All around you, your followers are fleeing for the caves—and you can see in their terrified eyes that they don't mean to resume the fight once they're there.
        *goto soundretreat
      You rally your rebels for one last stand at the edge of the slope.
      *if int > 1
        *if (blood = 0) and (consc < 1)
          *gosub swaymis
        *if (blood > 0) or (consc > 0)
          *choice
            #I cut my hand and wield ${wisardry} against the Phalangites.
              *set consc -1
              *label hurlphal4
              *rand theucatch 1 100
              *if theucatch < (theurges*15)
                Somehow, despite all the chaos and smoke of the battlefield, 
                *if theurges > 1
                  a
                *if theurges = 1
                  the
                Theurge detects your attempt at a Change.  
                *goto suddendeath
              *if theurges > 0
                All the grass underfoot is smoldering, kindled by the Theurges' vitriol.  The elemental flame is only barely subdued. You can sense its affinity toward the unburned roots and shrubs, its seeking to set aflame everything that has so far resisted it.
              *if theurges = 0
                You sense the elemental fire in the grass on the dry, sun-warmed slope.  
              Reaching out with your mind, you forcefully ignite a wide swathe just downhill of the advancing soldiers.  A great sheet of fire leaps up for just a moment, catches in the surviving grass, and crackles swiftly up the hill toward you.
              *if theurges > 0
                The remaining
                *if theurges = 1
                  Theurge veers 
                *if theurges > 1
                  Theurges veer
                up into the sky with cries of fury.
              "Back!" you shout, and your rebels scramble away.
              
              You're followed by terrible shrieks from the mountainside.  A dozen Phalangites burst out of the flames and smoke, coughing and scorched by their armor.  They soon fall to your followers' weapons.  From the sounds of it, many more are skidding back down the slope or taking shelter in the bloodstained water of the stream.
              *if rad_here
                Radmar 
              *if not(rad_here)
                Young Earnn
              leads a gang of rebels up to the edge of the inferno and rolls the few remaining large stones into the watercourse.
              *if theuknown < 10
                *set cred_p -50
              *set theuknown 10
              *set phalangites -46
              *set alltroops -46
              *set theirmorale -66
              *set morale +10
              
              "To the caves, ${addressu}," Alira mutters, rough-voiced, as the flames lick closer. "Best to fight where your fire won't catch us."  You nod and give the order.
              *goto 2rdoutcome
            *if (blood > 0) #I use a phial of aetherial blood.
              *set blood -1
              *set usedblood +1
              *goto hurlphal4
            #No—this isn't the hour of greatest need, and I don't want to risk detection by a Theurge.
              Every dram of
              *if blood > 0
                aetherial
              blood is precious in a clash like this.  You hold back.
              
              *goto laststand  
      *label laststand
      *if com > 1
        The Phalangites are advancing up the slope from all sides that aren't sheer. You grow hoarse directing your archers and small bands against them.
      *if cha > 1
        Only your extraordinary charisma keeps them at your side.
      
      *if zv_here
        *gosub zvfall
      Step by step, the Phalangites push your rebels back through the smoke.  But you make them pay for every yard of steep slope.  By the time you can resist no longer, and pull your survivors back to keep up the fight in the caves, the slope is hidden beneath a blanket of dead Shayardenes—many unarmored, but even more in Phalangite red.
      *set cas +round(inadults/4)
      *set phalangites -round(inadults/3)
      *set alltroops -round(inadults/3)
      *set theirmorale -round(inadults/3)
      *gosub armscheck
      *gosub cascheck
      *goto cavewar
  *label zvfall
  Below you, Zvad is trying to protect the retreat of a beleaguered, ever-shrinking gang of rebels.  There are Phalangites on every side with smashed-in helms and broken limbs, but the big ${whend}'s leather armor is cracked and slick with his own blood.  
  
  Even as you open your mouth to shout encouragement, a blade half-severs his maul arm.  You stand open-mouthed with horrified denial as his great weapon drops to the ground.  Before his strength spills out with his life, Zvad hurls himself onto the soldier who killed him, sending both of them tumbling down-slope and over a precipice.
  
  *set phalangites -35
  *set alltroops -35
  *set theirmorale -40
  *set zvad -50
  *set zv_here false
  *return
*if (not(el_here) or elsick) and (com < 2)
  *if zv_here
    *gosub zvfall
  Then the screams start from behind you.  To your horror, looking back you see the woods thick with red-armored figures.  The Phalangites must have found another way up the forested cliff face, past the handful of guards you posted there.
  *set cas +round(inadults/4)
  *set morale -20
  *choice
    #Fight them in the woods.
      *gosub armscheck
      *gosub cascheck
      *if (inadults < 60)
        "There's too few of us!"
        *goto yebretreat
      *if (morale < inadults)
        "We can't beat them!"
        *goto yebretreat
      *label woodswar
      You order all your surviving rebels back under the cover of the woods, to either side of the broad swathe of
      *if theurges > 0
        burning,
      Plektos-shattered trees.
      *if com > 1
        Your skills as a combat leader save many lives and bring down at least a dozen more Phalangites, as you lead the archers to cover the retreat.
        
        *set phalangites -15
        *set alltroops -15
        *set theirmorale -30
      *if com < 2
        *set cas +round(inadults/7)
      Your followers battle valiantly against soldiers on two fronts, but the terrain isn't as friendly to you as it was on the steep slope, and you find yourself pushed back to the cave system.  By the time you get there, the woods behind you are carpeted with bodies; many are armored in Phalangite red, but far too many are unarmored.
      *set phalangites -35
      *set alltroops -35
      *set theirmorale -40
      *goto 2rdoutcome
    #Fall back to the caves and fight there.
      *gosub armscheck
      *gosub cascheck
      *if (inadults < 45)
        "There's too few of us!"
        *goto yebretreat
      *if (morale < inadults)
        "We can't beat them!"
        *goto yebretreat
      "Fall back!" you bellow. "Back to the caves!"
      
      *label cavewar
      As you pull back, the Phalangites spill over the rim of the hill behind you, pursuing with savage determination. "Gut the rebel bastards!" you hear their commanders snarl. "Take their heads!"
      *goto 2rdoutcome
    #Retreat!
      "Flee!  Flee for your lives," you bellow.
      *label yebretreat
      *gosub armscheck
      *gosub cascheck
      All across High Crag, your rebels wail in despair and break for the caves.
      *if yebben > 9
        As the Phalangites charge triumphantly up from the watercourse, there's a deep rumble from the slope around them.  For a moment, you wonder dazedly
        *if theurges <= 0
          whether there's another Theurge on their side after all,
        *if theurges > 0
          what devilry their Theurges are up to,
        or whether there's about to be an earthquake.
        
        Then the mountainside erupts in a great storm of dust and flying stones, taking more than a hundred of the Archon's finest soldiers with it.  Only a dozen or so are left in your woods, and they rout almost at once, screaming as they go. Your archers are too shaken to kill them.
        
        For a moment, you stare down at the rapidly emptying basin where there used to be a hilltop pool.  Then you stagger back and go hunting for the only person who could conceivably be responsible.  You find Yebben Skinner atop a ledge, arms frozen in an outstretched gesture. His hand has a pink gash across the palm and his body is almost as pallid as a ${nere}'s, drained of all its blood.
        
        Tears burn your eyes as you sink down to his side.  "$!{oath}, boy.  $!{sweetoath}.  How by Taratur did you know… what did you teach yourself?"
        
        All around you, your outlaws continue to flee into the caves.  Whatever time Yebben's sacrifice has gained you, they don't intend to spend it on anything but putting as much distance as possible between themselves and the rest of the Archon's army.
        *set phalangites -102
        *set alltroops -102
        *set theirmorale -400
        *goto soundretreat
      *goto retreating
*label 2rdoutcome
*set onslope false
*gosub armscheck
*gosub cascheck

*if theurges > 0
  The 
  *if theurges > 1
    Theurges fly 
  *if theurges = 1
    Theurge flies 
  after you, but the flames you're braced for never come.  Daring a glance upward, you see with a jolt of hope that while the 
  *if theurges > 1
    nearest 
  mage still has plenty of yellow vitriol phials, 
  *if theurges = 1
    his
  *if theurges > 1
    their 
  blood bandoliers are hanging very light.
  *fake_choice
    #We have a chance.  $!{sweetoath}, we have a chance.
    #They're just holding back for now, hoping we're breaking.  If we stand, they'll blast us again.
    #There are enough swords here to kill us four times over, even if the Theurges do nothing.
You turn and clash with your pursuers at the mouth of the cave system, in narrow gaps where the Phalangites can only engage you a few at a time.
*if rad_here
  Radmar hews at them with berserk energy, spitting curses.  You see him pressed back into a side tunnel by the crush of battle, alone
  *if poric > 0
    save for Poric, at his side to the end.
    *set poric -10
  *if poric > 0
    and bleeding from dozens of wounds.
  You numbly expect to hear his death-cry within moments—but Phalangite after Phalangite streams in after him, and none emerges.  Long minutes later, there's an abruptly cut-off howl.
  *set phalangites -29
  *set alltroops -29
  *set theirmorale -36
  *set radmar -50
  *set rad_here false
*set cas +round(inadults/6)
*set phalangites -round(inadults/4)
*set alltroops -round(inadults/4)
*set theirmorale -round(inadults/4)
*gosub cascheck
*if (alltroops < inadults) or (theirmorale < (alltroops/2))
  *goto youwon

*if int > 1
  *if (blood = 0) and (consc < 1)
    *gosub swaymis
    *goto ksdeath
  *else
    *choice
      #I cut my hand and wield ${wisardry} against the Phalangites.
        *set consc -1
        *label hurlphal5
        *rand theucatch 1 100
        *if theucatch < (theurges*15)
          Somehow, despite all the chaos and smoke of the battlefield, 
          *if theurges > 1
            a
          *if theurges = 1
            the
          Theurge detects your attempt at a Change.  
          *goto suddendeath
        You shout to your rebels to fall back through a large cavern, into a narrow tunnel.  As the Archon's troops charge after you, you reach out to the weathered stone overhead and [i]pull[/i] with all your might, strengthening the tendency of the rock to fall.  
        *if theurges = 0
          
          There's 
        *if theurges > 0
          The remaining
          *if theurges = 1
            Theurge soars
          *if theurges > 1
            *set d2n_num theurges
            *gosub d2n
            Theurges soar
          in after them. For an instant, you feel your Change opposed, and the rock above your own head trembling.
          
          Then there's
        a deafening crack, a blast of dust-choked air, and everything goes dark before you.  
        *if theurges > 0
          The mind grappling with yours is snuffed out with the light.
          *set morale -(theurges*50)
          *set theurges 0
        The screams of your terrified followers are all that confirm you're alive—that, and the pain of the rock shards that flew your way during the cave-in.  There's a stinging wetness in your eye which you hope is just blood and not a blinding injury.
        
        "Keep moving!" Your voice is strangled in your own ears. "Back to the fight!"  The tunnel you're in wends its way round to another, higher cavern from which you hope you can bring down some more of the enemy.
        *if theuknown < 10
          *set cred_p -50
        *set theuknown 10
        *set phalangites -28
        *set alltroops -28
        *set theirmorale -66
        *set morale +10
        *goto ksdeath
      *if (blood > 0) #I use a phial of aetherial blood.
        *set blood -1
        *set usedblood +1
        *goto hurlphal5
      #No—I don't want to risk detection by a Theurge.
        *goto ksdeath
*label ksdeath
*if (alltroops < inadults) or (theirmorale < (alltroops/2))
  *goto youwon
*if kal_here
  You see ${kalt} fighting with desperate ferocity, surrounded by similarly fierce helots.  After the long and draining battle, the stream of curses and insults from ${zhis} mouth seems to be the only thing keeping ${zhim} upright.
  
  But at last, ${zhe} stumbles at the wrong time, and a Phalangite sword goes through ${zhis} chest.  $!{zhe} shrieks and buries a knife in the throat of the solider who killed ${zhim}…then topples forward, all the fight finally gone out of ${zhim}.
  
  *set phalangites -50
  *set alltroops -50
  *set theirmorale -50
  *set k_rel -50
  *set kal_here false
*if simz_here
  $!{simon} de Firiac's face contorts with fury as the last outlaws beside ${zhim} fall and ${zhe}'s surrounded by Phalangites. "For Loane!" ${zhe} cries—lashing out one last time with ${zhis} blade, sending one last over-confident soldier lurching back with a grievous wound.  Then ${zhe}'s overrun, vanishing beneath a vengeful swarm of red-armored troops.
  *set phalangites -50
  *set alltroops -50
  *set theirmorale -50
  *set s_rel -50
  *set simz_here false
*set phalangites -(inadults-16)
*set alltroops -(inadults-16)
*set theirmorale -(inadults-16)
*set cas +(inadults-16)
*gosub armscheck
*gosub cascheck
*if phalangites < 0
  *set cas +phalangites
*if (alltroops < inadults) or (theirmorale < (alltroops/2))
  *label youwon
  You brace yourselves for the next round of attack…and slowly, incredulously realize that none is coming.  All the movement you can see 
  *if onslope
    through the trees 
  *if not(onslope)
    beyond the cave entrance
  is withdrawal.
  *if (theurges = 0) and onslope
    Without Theurgic support, the Phalangites aren't foolish enough to keep assaulting an uphill position against a force well supplied with archers.
  *if not(onslope)
    Somehow you've managed to hit them hard enough that they can't or won't keep coming.
  
  You've won.
  *set arms +(inadults*3)
  *set morale +(inadults*20)
  *set inadults +bredvom
  *set inwoods +bredvom
  *goto won

And then you're fleeing back down a tunnel—you and a handful of survivors, escaping the slaughter in the caves behind you.  

There were simply too many.  You threw everything you had at the Archon's forces, used
*if int > 1
  ${wisardry} and
the terrain against them as best you could.  It wasn't enough.  It could never have been enough.
*page_break
*label retreating
*if bredvom > 0
  You force yourself not to dwell on the fate of the 
  *set d2n_num bredvom
  *gosub d2n
  poisoned outlaws
  *if elsick
    (including Elery Skinner)
  who were still too sick to fight or flee.  
  *if bredvom > 6
    The
  *if bredvom <= 6
    If any of them survived the
  *if lostem
    Plektoi
  *if not(lostem)
    Plektos
  *if bredvom > 6
    will have taken some of them; the rest are sure to be Harrowed.  But there's nothing you could do now 
  *if bredvom <= 6
    they'll surely be taken for Harrowing; there's nothing you can do
  to get them away from the cheering horde of red-armored soldiers.

*label sprintdark
*set followers -bredvom
*set nonkids -bredvom
*set dead +bredvom
*set morale -bredvom
*if elsick
  *set elery -50
  *set el_here false
At first, you and the other injured outlaws just sprint into the darkness, with the clamor of your armored pursuers spurring you onward.  You force yourself to a more deliberate pace as the tunnels drop away steeply, worn by streams that turn into long waterfalls.  As you're clawing your way down a wide, near-vertical shaft with few handholds, an overzealous Phalangite drops screaming past you. His arm clouts your shoulder, almost sending you after him.

Lower down the mountain, the caves open into ravines choked with thick brush and thorn-vines.  You press into the dense undergrowth, while shouts and horns echo from the ridges above.  [i]$!{oath}, the Archon's forces are everywhere[/i].
*if ((aristroops + priestroops)+(alastroops+yeotroops)) > 40
  While the Phalangites attacked the crag top, the
  *if aristroops > 0
    nobles
    *goto cragmorale
  *elseif alastroops > 0
    Alastors
    *goto cragmorale
  *elseif yeotroops > 0
    hostile yeomen
    *goto cragmorale
  *else
    Ecclesiasts' rabble
    *goto cragmorale
*else
  Those Phalangites who didn't assault the crag top 
  *goto cragmorale
*label cragmorale
have done their best to completely ring the mountain and cut off your retreat.  

Arrows rattle through the brush,
*if inadults > 50
  raising shrieks from every side.
  *set cas +round(inadults/10)
*if inadults <=50
  bringing down a handful of your survivors.
  *if inadults > 9
    *set cas +5
But the soldiers who pursue you down the slope are mostly carrying nets, not bows.  Having broken you, they mean to carry off as many as possible.
*if theurges > 1
  Theurges streak triumphantly across the sky, calling faint instructions down to your hunters.
*gosub armscheck
*gosub cascheck
*if theirmorale < (alltroops/3)

  If morale were stronger among the Archon's force, you think they'd have captured you all.  But
  *if theuknown >= 7
    *if theuknown < 10
      rumors of
    your ${wisardry} and
  the damage you've inflicted on them has made even the Phalangites wary.  Even in your own terror, you recognize the shakenness, the faint reluctance, when they descend and follow you into the undergrowth.  They're expecting a trap at every step…and their hesitancy is your salvation.
  *gosub kidsharrow
  *goto survived
*if theirmorale >= alltroops
  *gosub kidsharrow
  *goto breaklost
*label breaklost

*if (alltroops < 201) and (theurges < 3)
  For hours, you drag yourself onward—sometimes as fast as you can push your weary, battered limbs, sometimes frozen in place while the enemy combs the forest around you.  But at last, the shouts fade away behind you, and you limp through a silence so absolute it's eerie.  
  
  The army had too few troops to cover all of the rugged terrain around High Crag, and 
  *if theurges = 0
    no Theurges left to hunt you down from the air.
  *if theurges > 0
    too few Theurges to 
    *if inwoods > 50
      catch all of you. 
    *if inwoods <=50
      find a band as 
      *if dead > 30
        diminished 
      *if dead < 31
        small
      as yours. 
  *label tearssting
  Tears sting your eyes as you finally dare to believe that they're not going to catch you.
  
  [i]At least, not until they can fly in another Plektos.  This time with more Theurges.[/i]  Despair hits you hard…but beneath the numbness, your mind is already searching desperately for some way out.
  *goto flee
*else
  Behind and above you, the sound of pursuit grows louder and more triumphant.  They have enough 
  *if alltroops > 200
    troops to cover the rugged terrain, and they know they're closing the net around
  *if alltroops < 201
    Theurges to keep an eye on all the ravines and direct the soldiers to 
  your fleeing rebels.  You force your flagging limbs to move faster, ignoring the pain from branches lashing your skin.
  
  Then you round a rock spire and find yourself mere yards away from a dozen red-armored soldiers who have six of your followers bound or netted.  The Phalangite squad captain shouts, "Another one!" and beckons nine of his men up the valley toward you.  There's no way you could run past them, and the slopes to either side are steep enough that they'd catch you easily if you tried to climb.
  *choice
    #I try to fight my way through them.
      *set violence +1
      *if (com > 1)
        *if rescuer > 0
          The
        *if rescuer = 0
          Even more than when you faced the Alastors in Rim Square, the
        only hope you have is that they'll underestimate a ragged, bleeding helot rebel.  You give a hoarse yelp, turn, and flee.
        
        When the first of them rounds the corner after you, he's unprepared to find you crouched, armed, and waiting.  You
        *if weapon = "staff"
          plant the butt end of your staff in his throat,
        *if weapon != "staff"
          open his throat with your blade,
        then kick his body back to encumber the Phalangite behind him.  That gives you a few more precious seconds to scramble up and around to a ledge on the rock spire.  The soldiers still expect you to be fleeing back up the valley, and their helmets keep them from immediately spying you overhead.  You hurl and kick down three large, jagged-edged stones in rapid succession, aiming not for their protected heads but the shoulders of their sword arms.
        
        "Up the rock!  Net ${him}!" the captain roars, as three of his men howl and let their nets and weapons fall from suddenly nerveless fingers.  He dodges the stone you throw at him. "For Rovan! See the little bastard Harrowed!"
        *page_break
        Two of them draw out ropes woven with scores of fishhooks and hurl them up at you, trying to snag enough clothes, skin, or hair to tug you down off the rock.  Another swordsman warily advances up toward your ledge, blade at the ready, while the captain and two other battered Phalangites keep to the valley floor to cut off your escape.
        
        It takes all your dexterity to dodge the ropes; you know you won't be able to fend off an attacker at the same time.  The Phalangite closes with you, looking for a chance to disarm you so you can be easily netted.  The next time a rope lashes up at you, you catch its hooked length in your off-hand even as you hurl yourself at the approaching soldier.  He brings his sword up to block your blow with ease.  But before he can shove you back or knock the ${weapon} from your hand, you've lurched close enough to press the hooked rope against his scale mail.
        
        Below, a soldier shouts, "Caught ${him}!" and zealously hauls the rope tight.  It slices through your open palm and hooks your enemy's armor in at least four places.  He yowls as his comrade pulls him off-balance. While he struggles to regain his footing, you step back and slam one foot into his overextended knee.  There's a grinding snap, and the Phalangite swordsman topples from the ledge with a shriek.
        
        It gives you just enough time to scramble even higher, kicking down more stones after you to deter the three who follow.  And then you're high enough to leap across the gap between the spire and the valley wall, catching onto a tree and scrambling into a full retreat.
        *label givechase
        They give chase for another hour, but in the end you outrun them.  By nightfall, you're miles away from High Crag—and utterly alone.
        *goto flee
      *if (com < 2)
        *label ughdie
        Leaping for their throats at least earns you a quick end.  You're already so much in pain that the Phalangite blades entering your body barely register.  
        
        The last thing you hear is the captain's irate, "I don't give a damn if ${he} attacked you, you're meant to save them for the Harrower…." and then all is silence.
        *goto_scene death
    *if (theurgy > 1) #I use ${wisardry} against them.
      Your hands are bleeding already from a dozen times when you've batted aside a rose-vine or caught yourself on a thorny bough.
      *if (consc > 0)
        Now you 
        *label theugest
        gesture straight at the Phalangites.
        
        They roar in dismayed confusion as the light is cut off from their eyes—one of the only Changes you're confident you could make against so many people at once.  
        *if violence < 1
          It's also one that won't do any lasting violence to them.  To the end, you don't want to injure anyone if at all possible.
          
          *comment endif
        *if theuknown >= 7
          "Goety!  ${lname}!"  
        *if theuknown < 7
          "Goety? Angels!"
        All of them draw weapons, and a few bold ones move toward you despite their blindness, ready to strike at the least sound. "Shut your mouths!" the captain barks. "Kill the ${slur} bastard and we'll have the light back.  Hark for ${him}!"
        
        A different, thin cry rises from behind them.  "$!{addressu} ${fname}!" Your captive rebels strain against their bonds, a trace of hope returning to their eyes.
        *choice
          #I try to wend a path to them through the blinded Phalangites.  I can't leave my followers for the Harrower.
            You move at once, half-crouched and quiet as you can be.  The soldiers have drifted away from their prisoners, intent on finding you.  If you can only keep to the rocks, staying low so their out-thrust blades don't find you….
            
            You're nearly there when one of the Phalangites turns—he must have heard something, some brush of your foot hinting at attempted stealth—and lunges for you with his sword.
            *if (consc > 0) or (blood > 0)
              Your breath hisses through your teeth as you 
              *if consc > 0
                draw on more blood
              *if consc < 1
                *set blood -1
                *set usedblood +1
                break another blood phial
              and levitate him as fast as thought.  His sword parts the air above your head, and his shrieks cover the sound of your running.  Within seconds, you're at your followers' side, cutting them free.
              
              And then all of you are running, scrambling up the steep valley walls on either side of the stream.  The Phalangites regain some hazy vision as the blood fades in your palm…but not enough to be sure which fleeing, ragged figure is the rebel Goete.
              *goto givechase
            *else
              Without blood phials and a strong grip on consciousness, there's no ${wisardry} you can use against him…and your desperate lurch away from his sword just sends you toppling into another enemy.  
              
              "I've got ${him} here!"  You writhe away from the snarling Phalangite, but a boot slams into your back, pinning you to the ground. And then there's only pain and horror as their swords find you.  With their vision impaired, it takes them six blows to finally split your skull.
              *goto_scene death
          #Saving them is all but impossible. I vanish up the slope before the soldiers regain their sight.
            *label bracecry
            You're braced for some cry of condemnation as you turn and scramble up into the woods…but it never comes.  Whatever hope your followers had in you, it can't have been very much at this point.
            
            The Phalangites hear enough of your flight to know which side of the valley you're on, but with their vision impaired, navigating a steep slope of brush and scree proves all but impossible.  You're almost to the top, well out of view, when the last blood evaporates from your palm and their vision recovers.
            *goto givechase
          #I throw my knife to them.  If they can cut themselves free in time, they might have a chance.
            *if com = 0
              Unfortunately, the knife lands in the middle of the Phalangites, neither harming your enemies nor helping your allies.
              *goto bracecry
            *else
              You manage to toss the knife accurately enough that it lands next to a trussed bandit.  The last thing you see before you scramble out of view up the steep slope is him sawing at his bonds.
              
              Adding more escapees is enough to distract the Phalangites, further delaying their pursuit of you.
              *goto givechase
      *else
        But you're too close to unconsciousness to use your own 
        *if (blood > 0)
          *set blood -1
          *set usedblood +1
          blood.  Instead, you break a blood phial and
          *goto theugest
        *else
          blood, and you don't have any phials.
          *choice
            #I use ${wisardry} against them anyway.  Let it be the last thing I do.
              But what can you do against so many, without also killing your captive followers?
              *choice
                #This is the end.  Best for us all to die quickly here, rather than any of us feed their damned Harrower.
                  You reach out with your mind to the rocks along the ravine slopes: the barely contained scree, the great craggy overhangs striving downward.  You beckon them toward you with all your strength, all your consciousness, all the blood in your body.  A net falls around you, hooked ropes dig painfully into your already-lacerated skin, the Phalangites shout victoriously.  The world goes white around your eyes.  And there's a deafening crack overhead.

                  The last thing you see is the horrified realization in the eyes of the Phalangite captain.  Then you pass out, moments before the vast rockslide arrives at the bottom of the valley.
                  *goto_scene death
                #I cut off the light to their eyes, blinding them.
                  The Phalangites roar in dismayed confusion as their vision fails them—one of the only Changes you're confident you could make against so many people at once.  "Goety!  ${lname} ${slur}!"  All of them draw weapons, and a few bold ones move toward you despite their blindness, teeth bared, ready to lash out at the least sound.

                  You try to run, but your own vision goes blurry, fading out from the edges.
                  *goto savedby
                #I try to cripple them with pain.
                  Swaying in your ${wisardric} trance, with what feels like every inch of your own skin ablaze with pain, for an instant you can see your own agony—your body's yammering drive to force you to stop, to do nothing else until you've dealt with whatever's causing the pain.  You also see it mirrored to a much lesser degree in the Phalangites who are charging you: their own small cuts, the chafed skin and blistered feet.  Reaching out with your mind, you try to boost it throughout their flesh.
                  
                  And all twelve soldiers falter, eyes going wide and mouths wider, screaming with shock as they drop to their knees. "Goety!  Ah, aaagh!  Goe—aagh!"  You only get a moment of vengeful satisfaction, however, before blood loss sends a wash of gray across your vision.
                  *label savedby
                  As you topple into the stream, your last thought is despair. They'll be on you in a moment when you lose consciousness.
                  *if kal_here and (k_rel < 5)
                    *goto regainc
                  *elseif simz_here and (s_rel < 19)
                    *set savior simon
                    *goto regainc
                  *elseif rad_here and (r_rel > 10)
                    *set savior "Radmar"
                    *set savior_he "he"
                    *set savior_his "his"
                    *goto regainc
                  *elseif (el_here and not(elsick)) and (e_rel > 9)
                    *set savior "Elery"
                    *set savior_he "she"
                    *set savior_his "her"
                    *goto regainc                    
                  *elseif zv_here
                    *set savior "Zvad"
                    *set savior_he "he"
                    *set savior_his "his"
                    *goto regainc
                  *else
                    *goto_scene death 
                  *label regainc
                  *page_break
                  To your horror, you realize you're still alive, and being carried off in a net.  [i]$!{oath}.  They've spared me for the Harrower.[/i]  But when you writhe and groan a protest, ${savior}'s voice comes low in your ear. "$!{addressu}—thank Xthonos.  Can you walk?"

                  You force your eyes open and feel an intense burst of relief to see no red armor on any of the figures carrying you. "How…how?"

                  "Five of us were hiding upslope.  Didn't think we had a chance at them till you showed up. Then we hit them hard—brought them down before they recovered." $!{savior_he} shares a taut glance with the other tattered rebels. "All bar two, who got away, screaming about ${lname} the Goete.  The quicker we can move, the less likely they are to catch us again."

                  For a moment, you're not sure whether you will be able to walk, even with all your lives plainly at stake.  But you tell them to put you down, and with help from ${savior}'s shoulder, you keep your feet. "Let's go."

                  The moon is high in the sky before you can no longer hear or see any sign of pursuit from the Archon's troops.
                  *goto tearssting
            #I raise my ${weapon} and charge for them.
              *goto ughdie
            #I thrust my hands toward the sky and cry out, "Angels—aid your servant!"
              *goto angels_aid
            *if accounting > 0
              #"I wish to make an accounting!"
                *goto accountmake
            *if (accounting = 0) and (not(choice_randomtest))
              #I surrender.
                *goto surrender
    #I thrust my hands toward the earth and cry out, "Angels—aid your servant!"
      *label angels_aid
      *if (religion > 0) and (religion < 20)
        *if cha < 2
          The unimpressed Phalangites don't even slow down.
        *if cha = 2
          The Phalangites hesitate for just an instant—but despite the conviction in your voice, they're well accustomed to ignoring curses and pleas.
        You brace yourself to receive them and die.

        And then there's a cry from the slopes just above you: 
        *if eclect
          "Eclect!"
        *if not(eclect)
          "Angels!"
        Five ragged figures burst out of hiding, hurling stones as they charge your attackers.
        
        The red-armored soldiers duck for cover, startled and wary of an ambush from high ground.  But from your vantage, you can immediately tell that there are no archers in the handful of rebels.  They're just former helots, terrified, perhaps clinging to the slim hope that the Angels will save them if they save the 
        *if eclect
          Angels' mouthpiece on earth.
        *if not(eclect)
          ${woman} who taught them to hear Angels.
        Even if you joined them, you'd never beat the Phalangites.
        
        "Run, ${addressu}!" one of them howls.  At least she didn't use your name. Still, within moments the Phalangites are likely to realize who you are.  Then they'll cut down your hapless followers, and come for you.
        *choice
          *selectable_if (((religion != 12) and (religion != 11)) and ((religion != 2) and (religion != 1))) #"Angels!" I cry again, desperately steadfast in my faith. "Come to our aid!"
            You stand with arms outstretched while your followers hurl themselves onto the Phalangites…and die one after another in rapid succession.  There is no miracle.  No burst of fire, no parting of the earth to swallow your enemies.  And as the red-armored soldiers turn to you, 
            *label numbcert
            you realize with 
            *if (religion = 5) or (religion = 15)
              sudden, 
            *if (religion != 5) and (religion != 15)
              bitter, 
            numbing certainty that no miracle will come.
            
            [i]Sacrifice.[/i] Words you've heard dozens of times at Harrowings suddenly leap to mind, as vivid and strong as if they'd just been spoken into your ear. [i]Only through sacrifice can the world be preserved.[/i]
            
            You're still trembling from the impact of those words when the Phalangites reach you. "Who by Taratur are you?" the captain demands.
            
            "A sacrifice."  Your voice is harsh and shaky in your own ears. "Not the first, nor the last.  But for the Angels, and the true Order of Xthonos.  Let not those who kill me expect Their mercy."
            
            Something in your words affects the soldiers more than you'd expected—some resonant scrap of the authority you just heard in your mind.  The captain glances around as three or four Phalangites shuffle backward. Then he turns back to you, grim-faced.  "We're meant to capture you, not kill you." When his sword opens your belly from side to side, it feels like a dozen fires were just kindled in your guts. "But I've no mercy for a heretic who tries to frighten us."
            
            It takes you an hour of agony to die—an hour of stench, horror, and increasing delirium on the forest floor, abandoned by your killers and your followers alike.  Yet through it all, the sense of a steadying presence beside you not only persists but increases.  An attention in which you are held.  A witness in your final extremity.
            *goto_scene death
          #I turn and run.  This is the only chance I'll get.
            The wary Phalangites don't immediately pursue you.  It's almost two minutes before your followers' last death cry echoes up the ravine, and by that time you're already halfway up the steep, wooded slope.  The soldiers scramble after you, cursing as the weight of their armor send them sliding down scree slopes that bore your weight.  
            *if addressc != "sisters and brothers"
              They must not have guessed what the cry of "${addressu}" meant, because
            *if addressc = "sisters and brothers"
              Your followers' yell of ${addressu} didn't give the soldiers any hint of your identity, and
            they give up before too long.

            Even so, the wilderness around High Crag is full of hunters, and the moon is high in the sky before you can no longer hear or see any sign of them.
            *goto tearssting
      *else
        *if skepreal < 40
          Nothing happens.  No burst of fire, no parting of the earth to swallow your enemies.  Their swords flash in the sun, and
          *goto numbcert
        *else
          *if cha < 2
            The unimpressed Phalangites don't even slow down.  
          *if cha = 2
            The Phalangites hesitate for just an instant—but despite the conviction in your voice, they're well accustomed to ignoring curses and pleas.
          It takes them only seconds to get a net over you and drag you away to join your despairing fellow captives.
          *goto surrender
    *if (religion > 19) #I thrust my hands toward the sky and cry out, "May kenon consume you!"
      The Phalangites don't know what that curse means, of course.  To a large extent, neither do you.
      
      But the five terrified rebels hiding on the slopes above you do…and something in your final, passionate appeal brings them charging out with a cry of "Kenon!"
      
      The red-armored soldiers immediately duck for cover, afraid that your obscure curse was the signal for an ambush from high ground.  From your vantage, though, you can tell that there are no archers in the handful of former helots, nor any fighters who have a feather's chance against a Phalangite.  Within a minute or two, they're going to be slaughtered.  
      
      And they know it.  "Run, ${addressu}!" one of them howls, waving an axe in the air.
      
      You sprint back around the corner and launch yourself up the steep wooded slope.  [i]I'll give meaning to their sacrifice[/i], you vow as the last death cry echoes behind you.  [i]Martyrs of the rebellion.  Martyrs of kenon.  They will be remembered.[/i]
      
      Then the Phalangites round the rock spire and begin scrambling after you.  They curse loudly as the weight of their armor sends them sliding down scree slopes that bore your weight.  All thought vanishes from your mind—beyond the urgency of keeping ahead of them, fast and silent.  You run for hours, tumbling through the wilderness in any direction that takes you away from the sounds of pursuit.  The moon is high in the sky before you finally know you're alone.
      *goto flee
    *if accounting > 0
      #"I wish to make an accounting!"
        *label accountmake
        The Phalangites take mere seconds to reach you and net you.  Their red-armored captain gives you a boot in the spine as you're dragged off to be bound. "Shut your damned mouth, Xaos-licker.  You'll make account to the Harrower and the Angels for every last swiving thing you've done."
        
        [i]So it was a lie.  By Breden, or whoever told it to ${xhim}.[/i] Did [i]${xhe} betray me, then?[/i] Overwhelmed by pain and sick horror at your coming torture and death, you can barely sustain a moment's curiosity.
        
        *gosub captured
        
        Then a soldier undoes the rope linking you to the other captives and prods you off in a different direction.  When your shock fades, all you can feel is:
        *fake_choice
          #The sick certainty that I've been recognized.
            *if helot
              [i]The young master?  Some Keriatou retainer?[/i]
            *if aristo
              [i]Cousin Hector?[/i] 
            You glance all around you with mingled terror and humiliation.
          #The furious conviction that some captive found a way to reveal my identity.
            [i]Traitors.  I'm surrounded by traitors, to the bloody end.[/i]  Your mind is seething.
          #The mad hope that Breden's gambit will somehow work after all.
            You try to compose yourself as best you can.
        *if com > 1
          But as you try to shrug a bit more life into your shoulders, you also realize that the bonds on your wrists aren't biting into your skin quite so fiercely.  The soldier must have loosened the knots just a bit to tug the long rope through.  You doubt that anyone with less strength and dexterity than you would be able to make any use of it….
        
        The Phalangite captain leads you up to a campfire surrounded by silken tents, lightweight furnishings, and gilded tableware.  In the midst of a small group of soldiers wearing
        *if helot
          what you imagine to be
        commanders' insignia, a sturdy-looking noblewoman in red and gold armor is
        *if (alastroops < (alastroops_orig-25))
          sharply
        addressing a tall, white-bearded Alastor. "Your enforcers
        *if alastroops >= (alastroops_orig-10)
          served well, Tychon.  I'll not forget you when I make my report in Grand Shayard."
          
          "Honor to serve you, kuria Tagmatarch."  The Alastor captain looks absurdly proud.
        *if (alastroops < (alastroops_orig-10)) and (alastroops >= (alastroops_orig-25))
          fought hard, Tychon, and paid a price.  I'll recommend them for the martyrdom allowance."

          "You're a gracious commander, kuria."  The Alastor captain beams, as well he might–he'll surely skim off an ample share of any allowance paid for his fallen fighters.
        *if (alastroops < (alastroops_orig-25))
          were gutted in combat with this flock of rebels, Tychon.  What do you expect from me?  A commendation?"
          
          The Alastor bristles defensively. "Begging your tolerance, Tagmatarch,
          *if phalangites >= (phal_orig-60)
            but if you'd only sent a Plektos after them earlier, we'd have none of us lost so many…."
          *if phalangites < (phal_orig-60)
            but your troops fared no better.
          *if phalangites < (phal_orig-300)
            Far worse, in truth.  Hundreds slain, to take a barely fortified hilltop?
          *if phalangites < (phal_orig-60)
            And if 'flock' is the right word for a bunch of Xaos-reivers who managed to kill 
            *if not(lostem)
              a Plektos
            *if (lostem)
              three bloody Plektoi
            before taking on a Phalangite charge…well, you'd best find a new word for those Halassurqs you like to fight so much."
          
          "Enough."  The woman's face is flintlike. "This is a time for rejoicing.  Further reproach can wait." [i]Until its proper time[/i], say her eyes.  Captain Tychon draws himself up as if to hurl some insult, then thinks better of it and storms off.
        *comment end_if
        
        [i]Their Tagmatarch.[/i]  You can't keep your eyes away from the golden hilt of her sword.  The two visible inches of blade also look like pure gold, with an odd whorled pattern.  [i]Theurge-forged.  $!{oath}.[/i]
        
        The Phalangite leader turns to look appraisingly at you, then to the officer who brought you. "Ah, Galix. Have you brought me a ${girl} who might shed light on the demise of 
        *if not(lostem)
          that Plektos?"
        *if (lostem)
          those Plektoi?"
        
        "I believe so, Tagmatarch."  He leans in to murmur something.
        
        Her eyes flicker to you, twice, before she gives a brisk nod. "I'll hear ${him} alone, then, for now.  If this rabble devised some original way to fell the Twisted, best for it not to be known too widely."  You're dragged into a large tent. The guards salute and step outside, leaving you alone with the armored noble. "So.  Do you know who I am, ${girl}?"
        
        "The Tagmatarch leading this force against the rebellion."  You keep as cool a voice as you can manage, despite the hammering of your heart, and do your best to keep your eyes from her sword.
        
        "Do you know why you're here?"
        *page_break "Because I wish to make an accounting."
        There's nothing else that officer could have whispered that would have got you brought in here.

        "Ah."  The Tagmatarch looks you up and down, unsmiling.  "So you say.  And whence came your fantasy that I might wish to hear your account?"
        
        *if violence < 1
          You've tried at every step to avoid doing violence to your enemies.  But you can see that the only way you'll leave this tent alive is over the Phalangite commander's dead body—and that only with a good deal of luck.
          *choice
            #I'll die as I've lived.
              You draw yourself up with the shreds of dignity that remain to you.  "It's true, I'm no Kryptast.  But I thought you might wish to accept the surrender of ${fname} ${lname}."
              
              The Tagmatarch stares at you
              *if theuknown >= 7
                for only a moment before that golden, impossibly sharp sword is out and through your throat. "Goete!"
                
                *if theuknown >= 10
                  Of course she'll take no chances with a known mage, 
                *if theuknown < 10
                  Too many deserters spread word of my secret,
                you manage to think—before a huge gout of blood takes all your thoughts with it.
                *goto_scene death
              for an astonished moment. "Surrender?"
              *if aristo
                There's a hint of respect in her eyes.  "You know your blood will earn you no mercy, ${lname}."
              
              "With no other course left me?"  It takes iron self-control not to give way to the yammering terror in your guts. "Aye.  Let all Shayard see the end of this rebellion."
              
              *goto braveheart
            #It's the plainest self-defense.  No one could blame me for resorting to violence now.
              *goto whatwouldaksay
            #I abhor violence…but in the final, guilty extremity I won't let myself be killed.
              *set nonvio true
              *goto whatwouldaksay
        *label whatwouldaksay
        What would a Kryptast say?
        *if helot
          Now, more than ever, you can show no trace of the deference you were raised with—the terror of the nobility that was ground into you, year after year.
        "Play no games with me, woman.  I had it from my training, as you had it from yours."  As she exhales with sharp, angry surprise, you let your jaw jut insolently outward.  "Both of us succeeded in our work this day, at no small risk to our lives.  And like you, I hope to live to fight again."
        
        *if cha < 1
          You've never been a convincing liar, and she seems only fractionally convinced.
        *if cha > 0
          Her eyes narrow.
        "A fine hope indeed, for a rebel in bonds.  Perhaps you hope merely to escape the Harrower by provoking an early death."  You meet her hostile stare, doing your best to look unmoved…and she is the first one to blink. "I was not told to expect any Accounting here, ${girl}."
        
        *if com > 1
          In the moment that her eyes are averted, your wrists strain against the knot.  Nearly loose….
        "Nor are you ever told. For my part, I hadn't been told that you'd be sending Plektoi against the rebels, or I'd have taken measures to ensure they couldn't kill
        *if not(lostem)
          it.  
        *if (lostem)
          them.
        I wasn't told so much as your name."  
        
        The Tagmatarch's face is tense with fury.  "Would it have made a difference if you had been?  I am Aletheia de Arquin. And your impudent self?"
        *choice
          #"${fname} ${lname}."
            *set myownname true
            She blinks at you
            *if theuknown >= 7
              for only a moment before that golden, impossibly sharp sword is out and through your throat. "Goete!"

              It 
              *if theuknown >= 10
                should have been obvious that she'd take no chances with a known mage. 
              *if theuknown < 10
                was always likely that your deserters had been captured and told your secrets.
              [i]Foolish…[/i]you manage to think, before a huge gout of blood takes all your thoughts with it.
              *goto_scene death
            in shock, before glancing around the empty tent despite herself to see if anyone else has heard. "And you walk into my tent speaking of an Accounting?  You, whom above all others the Archon and Theurges long to see on a gibbet?"
            
            "No doubt they said so.  Yet here I am."  You smile thinly.  "Not all were ignorant of my true role."
            *if com > 1
              *goto tagma
            *if int > 1
              Even as you speak, you can see that she's on the verge of disbelief.  If you're going to survive, you've no choice but to use ${wisardry}.
              
              *goto alethwis
            
            Tagmatarch Aletheia's breath hisses through her teeth, and she draws her golden sword.  "Then tell me, Kryptast—if such you are—what your coterie hopes to gain by instigating such monstrous rebellions.  Persuade me that this truly is in service of the Hegemony and of Xthonos, and not just a whim of Xaos.  Or a lie by a
            *if aristo
              petty noble,
            *if helot
              Xaos-loving helot,
            feigning knowledge of things beyond ${his} ken."
            
            Your heart hammers in your chest as you stare at her, gauging what she'll believe.  "[i]Rebellions[/i]," you say.  "So this isn't the first time you've led the…response to our work."
            
            "$!{woman}, I have put down three uprisings in nearly as many years.  And while this is the first Accounting I've heard, I've seen the signs elsewhere."  She extends her arm until the point of her sword rests on your forehead.  A trickle of blood runs down at once, from skin cut so cleanly you feel nothing but an itch. "I believe the whispers I've heard in Grand Shayard.  I believe the Kryptasts are sowing hundreds of rebellions across the realm.  And now you'll tell me the true reason why, ${lname}…or you'll die here, just another martyr of the Mystikon who tried and failed to make an Accounting."
            *if int < 1
              
              If only your wits were a bit quicker, you might have come up with something she'd credit.  As it is, your mind stays empty…and when she sees it in your eyes, she lunges forward with a snarl.  You feel nothing as the mage-sword cleaves your brain.
              *goto_scene death
            *fake_choice
              #"Only through sacrifice can the world be preserved."
                You speak the words as sonorously as ever Ecclesiast Zebed managed, and are rewarded by a look of profound unease from Aletheia. "What does that bloody mean?"
                
                "The Ennearchs tell us that the Wards grow hungrier," you say huskily. "The sacrifice of the Harrowing is no longer sufficient.  To keep Xaos at bay, more of those who harbor Xaos in their hearts must die.  Thousands more."
                
                It's hard to tell the horror on her face from the suspicion.  "How…without a Harrower, how does the blood…"
                
                "This is a mystery which few know, kuria Aletheia.  Do you truly wish me to share it with you?"  
                
                She moistens her lips, trying to gauge the consequences from your unblinking stare.
              #"We are hunting, woman.  Trying to bring a far greater threat out of hiding."
                Aletheia sneers in disbelief.  "What could be a greater threat than rebellion across the realm?"
                
                You think back to your childhood fright-tales, and to long-ago conversations with Breden in Rim Square. "Sarcifer the Goete.  The traitor, the forsaken one, who used to be one of the Nine."
                
                Raw fear flickers through her eyes, overriding the suspicion.  "I…you think I'll credit such…"
                
                "He bides his time in the shadows, woman.  We know he longs for an army, such that he need not risk himself directly.  And so we seek to bait him with one."  After a moment's stunned silence, you shake your head.  "He did not come to this rebellion's aid, even though it was deep in the wilderness.  Perhaps he will succumb to the next one, though.  Perhaps you will have the honor of fighting under his fire-blasts, as I have beneath your Theurges'.  And you will be witness when at last we destroy him."
                
                *comment endif
              #"You're mistaken, Tagmatarch.  There is another force at work here, and we are vying against it."
                "The damned Halassurqs used the last peace to spread their agents into every corner of the realm, kuria Aletheia."  You keep your voice rapid and grim.  "Their plan, not ours, is to incite so great an uproar that the Hegemony can no longer sustain the war against them.  And so we infiltrate the rebellions they create, to destroy them from within."
                
                "You started this revolt, ${lname}," Aletheia insists incredulously.  "Am I truly to think that some Halassurq was involved?  In the Outer Bloody Rim?"
                
                "Blind fool!" you snap, and have the satisfaction of seeing her flinch in shock. "A supposed helot named Reaper—Breden Reaper—was the true instigator of this rebellion.  A tool of Halassur, trained in the east for years before being brought here, where none would expect ${xhim}.  Had ${xhe} remained in control, you might never have found the rebels here waiting for you.  But I took over from ${xhim} and delivered them into your hands."
                
                *comment endif
            The utter conviction in your voice reduces her to silence. At length, she withdraws her swordpoint from between your brows.
            *page_break
            *goto tagma
          #"Breden Reaper."
            *label saidhelot
            Tagmatarch Aletheia 
            *if aristo
              snorts skeptically.  "Don't give me some helot name, ${girl}, speaking as you do.  You're 
              *label yourenob
              noble, or your family was within the last two generations.  And no doubt that's where you heard about Accounting."
              *goto tagma
            *if helot
              shakes her head impatiently. To all appearances, the name means nothing to her.  
              *label answkr
              "And you expect me to believe that you're an Angel-swiving Kryptast, ${girl}?  Not the helot scum you smell like?"
            *goto tagma
          #"Radmar Millstone."
            *goto saidhelot
          *if (alias != "") #"They call me ${alias}."
            *label tagmalias
            "$!{alias}.  Am I supposed to credit that?"  Tagmatarch Aletheia gives a curt, skeptical laugh.
            *if aristo
              "From what House?  Speaking as you do, you're
              *goto yourenob
            *goto answkr
          *if (alias = "") #I quickly come up with an alias.
            You tell Tagmatarch Aletheia that you're
            *if not(choice_randomtest)
              named:
              *input_text alias
              *set alias "$!{alias}"
            *if (choice_randomtest)
              *set alias "Alias"
              named Murgyn.
              
              *comment endif
            *goto tagmalias
          *if (int > 1) #My ${wisardry} will be answer enough.
            *label alethwis
            You're bleeding from cuts all over your body, and have been on the verge of slipping into trance for the past hour.  Now you let go, swaying, and struggle to make sense of the blurry world around you.  There are a dozen ways you could kill Tagmatarch Aletheia…but few that are quick and silent enough to keep the whole army from descending on you.
            
            That Theurge-forged blade is vivid in your mind, even from the periphery of your vision. Its unnatural sharpness is so stark you can sense it through the sheath.  You reach out to it mentally, caressing bright elemental fire and earth, and know what to do.
            
            Just as the Phalangite leader is about to lose patience, you croak, "My master will answer for me."  Raising your bound wrists, you point just over the Phalangite's shoulder, toward the shadows around her bed.
            
            Few nobles of the Hegemony live free from the fear that a Kryptast is lurking unseen in their room.  Aletheia's eyes widen as she turns—and you beckon the fire in her sword swiftly upward.  As the sheath comes to rest fully on the edge, it parts smoothly, exposing the levitating golden blade.  The Tagmatarch feels the tug at her belt and gasps, scrabbling for a hilt that is now hanging inches above where she expects to find it.
            
            She whirls back toward you, drawing breath to cry out…and bringing her head close to the now nearly-vertical blade.  You kick out desperately at the floating hilt, and the sword wobbles against her skull.  Not hard, just enough to sink in two or three inches, like a knife tapped against butter.
            *if (consc > 0)  
              
              Then you pull back, just before you lose consciousness, and release the sword.  The Tagmatarch's corpse pulls it to the ground, but the blood-slick blade still points to the ceiling while the effect of your Change fades.  You wait until the trembling in your limbs is under control before cutting your bonds.
            *if (consc < 1)
              Then both of you collapse to the floor at the same time.  
              *page_break
              You fight your way back to consciousness, open bleary eyes to take in the shadowy corpse beside you.  It can't have been long.  You're still alone, still alive.
              
              The Theurge-forged blade has regained its weight and sunk into the ground, with only the broad hilt keeping it from disappearing entirely.  Reaching out with trembling hands, you retrieve it and sever your bonds, losing only a bit of flesh from the ball of your thumb.
              *set tagmatick false
            *achieve accountmade
            *goto tagmascape
        *label tagma
        
        *if cha < 2
          You can't imagine that she'll continue to believe you for long.  
          *if int > 1
            If you're going to survive, you've no choice but to use ${wisardry}.
             
            *goto alethwis
          With deliberate rudeness, you turn your back to her, saying, "I'll wait for my master to arrive and confirm the Archon's orders to you."  And you pull one chafed and bleeding wrist free from your bonds.
          
          The Phalangite's hand falls heavily on your shoulder.  "Damn your eyes, ${girl}, that isn't how it…"
          
          You take one small step back toward her and bring your sword hand down to grab that golden hilt.  She falters, begins to pull away as she realizes you're free…but by then you've drawn her blade and slammed it back in one swift motion, higher and to the side. "I will wait," you say emphatically for anyone listening, covering the gurgling sigh behind you. "I've shown you proof enough, woman.  I am who I say I am, and my master will confirm it to you."
          
          When you turn, the Theurge-forged blade in her chest carves effortlessly through her armor and ribs.  The Tagmatarch drops to the tent floor in a cascade of blood, cut nearly in half.  You're alone, and free.  At least for a moment.
          *achieve accountmade
          *page_break
          *goto tagmascape
        *else
          Recognition hits you suddenly, at a twitch of her lip.  Beneath the mask of scorn and growing disbelief, despite the fact that she has you utterly at her mercy, Aletheia de Arquin is terrified of you.
          
          There's a likely explanation for that degree of dread.  "De Arquin." You incline your head and look at her through narrowed eyes. "My master claimed a de Arquin, once.  I remember the tale now.  So proud a family, to have so great a treason nesting in its midst."
          
          The Theurge-forged sword 
          *if not(myownname)
            flies from its sheath to hover in front of your nose.  
          *if myownname
            rises once more.
          You can hear her fear plainly now, along with fury, as her words tumble out through clenched teeth.  "Say one more word against my House, varlet…"
          
          "And you will do nothing," you grate. "When my master arrives with the Theurges, what do you think he will presume if he finds me dead by a de Arquin's hand?  Trust me, woman, his vengeance will surpass all that he has already inflicted upon your House."  You begin walking toward her at a deliberate pace—and, wide-eyed and quivering, she lowers her blade just before you step into it.  Forcing your dry lips into a knowing grin, you raise your hands toward her.  "My wrists grow sore, Tagmatarch.  Kindly free me."
          
          "When, when your master…"
          
          "Now, woman!"  At your brusque order, the commander of the Archon's army jumps and raises her golden blade.  It severs the ropes as soon as it brushes against them, and the blood rushes painfully back into your hands.  You gingerly stretch your fingers, suck breath sharply through your teeth at the pain—and extend one stiff, shaking hand.  "So.  They sent you with so great a treasure?  Show it to me."
          
          You can see the outraged refusal flicker across her face; it almost reaches her tongue.  But the sheer audacity of the request—the insanity of a captured rebel demanding to be given the Tagmatarch's mage-sword!—and the unflinching confidence with which you utter it lead her to one conclusion.  And if it's true, then you already have the power of life and death over her.
          
          The golden hilt is cold and heavy in your hand.
          *page_break
          You could kill her now, even with hands still numb and tremorous.  But she's braced for that, expecting it. She'd likely get a scream out, and even with a Theurge-forged sword you wouldn't survive the whole army coming down on you.  Instead, you walk over to her bed and use the point of the blade to etch a small ${sigil} into its frame. "Fascinating," you murmur, then hand it back to her. "Aren't these usually kept for the Halassur front?  What on earth did they think you'd need it for against my rabble?"
          
          Tagmatarch Aletheia is badly off-balance now, but tries to reclaim some degree of initiative.  "Your rabble brought down
          *if lostem
            three bloody Plektoi,
          *if not(lostem)
            a Plektos,
          *if he = "he"
            kurios.
          *if he = "she"
            kuria.
          I'd still be keen to hear how that was accomplished.  But however it was done, I think the Archon judged the risks wisely."
          
          You ignore her implicit 
          *if helot
            request—and the sweet shock of having a noble address you as
            *if he = "he"
              kurios—pressing on instead
            *if he = "she"
              kuria—pressing on instead
          *if aristo
            request, pressing on
          with a question of more interest to you.  "And you truly weren't told to expect…one of my sort here?  No hint that this had been started by our hand?"  When she curtly shakes her head, you look away, lip curled.  "I suppose a de Arquin might not be told."
          
          "And I suppose that trust is given sparingly if at all in the Mystikon."  Though you're not facing her, you can hear the barely containable hatred in her voice.  "But among the Phalangites, the wrongdoings of a cousin do not disqualify one from command."
          
          Is she testing you?  Was her Kryptast-slain relative closer than a cousin?  It's impossible to know from her tense tone.
          *fake_choice
            #"Xaos spreads swiftly in families."
              Before Aletheia can react,
            #"A cousin?"  I turn back, raising a scornful eyebrow.  "Perhaps Xaos has corrupted more than one branch of the de Arquins, but that's not the death I had in mind."
              You'll wager that at least one other de Arquin has died under circumstances that could have been a subtle assassination.  And while Aletheia's eyes burn suspiciously into yours, she doesn't accuse or attack you.
              
              After a moment's silence,
            #"Then you chose your vocation wisely." I shrug neutrally.
              After a moment's uncomfortable silence, 
          you curse and pluck one of the ever-present lice from your matted hair. "Well, there's one use to which that sword will be well suited, assuming you can keep a steady hand with it.  My hair's become a ${nere}ish carpet, with the vermin to boot."  You pull a chair over from one corner of the tent and seat yourself expectantly in front of her.
          
          For an instant, you wonder if you've pushed too far, if the humiliation will be enough for this proud noble to kill you and face the consequences. Then you feel the cold flat of the sword on your skin as the Tagmatarch begins to run it over your scalp, her two hands holding the blade (with immense caution) rather than the hilt.  You do your best to relax as snarls of hair fall over your shoulders.  After a half-minute, you sit up with a start.
          
          "Damn it, woman, you've cut me."  You wave off her apologies with visible ire. "I'll take the rest off myself. Surely you've a mirror here?" When she finds it, you lean to stare at your hacked-off hair, and beckon impatiently for the sword. "There.  No, higher—I can't see where you've left off."
          
          This time, with Tagmatarch Aletheia working to keep the silver mirror at the right angle, she doesn't see your intent in time to cry out.  The blade slips through armor, bone, lungs, heart with as little resistance as if you were dragging it through water.
          *achieve accountmade
          *goto tagmascape
        *label tagmascape
        *set violence +1

        You sway in place, 
        *if nonvio
          wracked by guilt at your bloodshed,
        golden sword clenched in your fist.  All around the tent, you can hear the clamor of a camp in celebration, with
        *if alltroops < 90
          *set d2n_num alltroops
          *gosub d2n
        *if (alltroops >= 90) and (alltroops < 190)
          one
        *if (alltroops >= 190) and (alltroops < 290)
          two
        *if (alltroops >= 290) and (alltroops < 390)
          three
        *if (alltroops >= 390) and (alltroops < 490)
          four
        *if (alltroops >= 490) and (alltroops < 590)
          five
        *if (alltroops >= 590) and (alltroops < 690)
          six
        *if (alltroops >= 690) and (alltroops < 790)
          seven
        *if (alltroops >= 790) and (alltroops < 890)
          eight
        *if alltroops >= 890
          nine
        *if alltroops >= 100
          hundred
        *if alltroops >= 990
          or more
        enemy fighters between you and freedom.  
        *set tagmasword true
        *choice
          #My rebellion is over—but I'll kill as many of the bastards as I can before I die.
            *gosub commslaughter
            None survive, and only the second wave of soldiers running up to defend them see enough of what's happening to pull back and take up the cry of, "Mage-sword!  $!{he} has the bloody mage-sword!"
            
            *if com < 2
              You're no great fighter, 
              *if phalangites < 40
                but there are so few surviving Phalangites that your bloody assault is enough to break them.  
                *label phalrout
                The sight of a rebel wielding their commander's Theurge-forged blade sends the battered camp into full rout.  A few arrows whistle past you, but the archers are too busy running to find you in the dark.
                
                Despite your fierce hopes, you see neither Captain Tychon nor Hector Keriatou.  They must be leading the retreat.  You howl that they're accursed cowards, then charge down to scatter the remaining guards on your captured outlaws.
                
                *if el_here and not(elsick)
                  Elery hobbles up to you, ankle swollen, and breaks down in tears of sheer relief. "$!{oath}, ${addressu}. $!{sweetoath}.  How by all that's
                  *if skep > 50
                    unhallowed
                  *if skep <= 50
                    holy
                  did you manage this one?"
                  *set e_rel +5
                *if (not(el_here) or elsick) and (kal_here)
                  ${kalt} is barely recognizable for bruises. The Phalangites clearly had to beat ${zhim} within an inch of ${zhis} life to take ${zhim} prisoner. "Knew you'd…not…"  $!{zhis} voice trails away, and ${zhe}
                  *if k_rel = 4
                    sags into your arms.  "Knew you'd win."
                  *if k_rel > 4
                    staggers off on a fellow rebel's arm.
                    *set k_rel -2
                  *if k_rel < 4
                    manages a twist of the lips that you can just identify as a smile. "Knew I…was right.  Knew you'd win."
                *if (not(el_here) or elsick) and (simz_here)
                  ${simon} de Firiac stares at you through ${zhis} one good eye. The other is swollen nearly shut, with clotted blood all round from a gash across ${zhis} brow.  Tears are leaking from both. "I'd not hoped to see you again, ${addressu}.  Indeed, I'd hoped I wouldn't, this side of Elysia.  Not in my wildest imaginings…."
                *if ((not(el_here) or elsick) and (not(kal_here) and not(simz_here))) and (rad_here)
                  Radmar just stares at you, with an awe
                  *set r_rel +5
                  *if r_rel > 6
                    that approaches worship.
                  *if r_rel < 7
                    no less real for its reluctance.
                  "Damnation, ${addressu}.  
                  *if radmar < 10
                    Are we dreaming?"
                  *if radmar > 9
                    What now?"
                    *choice
                      #"Ask Breden."  I cut him in half with the mage-sword.
                        *set radmar -100
                        *set rad_here false
                        *if (bred_lover >= 4) or (bred_heart = 3)
                          Your 
                          *if (bred_lover = 13)
                            ex-lover
                          *if (bred_lover != 13)
                            love 
                          is avenged.
                        "Now follow me," you bark to the others.
                        *gosub priscas
                        *goto survived2
                      #My bleak stare sends him shrinking back.  But there's no use killing him yet.
                        *gosub priscas
                        *goto survived2
                      #"We run," I say curtly.  The rebellion needs Radmar.
                        *gosub priscas
                        *goto survived2
                *if ((not(el_here) or elsick) and (not(kal_here) and not(simz_here))) and not(rad_here)
                  Young Earnn looks like he doesn't know whether to prostrate himself before you or clap you on the shoulder.  "$!{sweetoath}, ${addressu}.  Thank…thank ${oath}.  I'd not thought to see you again this side of
                  *if skep > 50
                    the void."
                  *if skep <= 50
                    Elysia."
                
                "No time for talk," you breathe.  "Before they've any chance to regroup, let's be gone."
                *gosub priscas
                *goto survived
              alas, and your slaughter of the Archon's commanders will be all the revenge you enjoy this night.  As you charge down to face the second wave, they pull back and begin to pelt you with javelins.  
              
              You feel a moment's sharp agony as one takes you between the ribs.  Then another hits your skull, and you know nothing more.
              *goto_scene death
            You duck into the shadowy undergrowth before they can bring javelins or arrows to bear on you.
            *choice
              #Enough vengeance.  I can flee, and live.
                *label tagmaflee
                You've long since grown accustomed to navigating the woods by starlight.  Dozens of soldiers pursue you…but slowly, terrified of meeting a Theurge-forged sword in the dark.  A short ways north of the camp, you find a gorge with water roaring in its lightless depths. You follow it until you find a place where you can cross on a fallen pine, which you cut away behind you with a single blow of your sword.  
                
                The sounds of pursuit fade behind you, until you can hear nothing but your own ragged breath.  You've escaped them.  
                
                At least until they send another Plektos with your scent in its nostrils, accompanied by six forewarned Theurges to blast you from the air.  Your mind races as you flee, desperately seeking any possible way out.
                *goto flee
              #I'm going to rescue my captive rebels.
                *goto captiverescue
              #I'll kill them to my last breath.
                You keep to the undergrowth, killing the over-bold Phalangites who come in after you, and circle the camp.  Four times, you burst into a cluster of terrified soldiers, slaughter them all, and flee before the archers elsewhere can bring their missiles to bear on you.
                
                *if theurges > 0
                  Unfortunately, black-coated figures are not easily seen in the woods at night.  You only realize the
                  *if theurges = 1
                    Theurge has
                  *if theurges > 1
                    Theurges have
                  found you when the air around you ignites in blue flame.
                  *goto_scene death
                *set alltroops -90
                *if alltroops < 100
                  It's too much for the Archon's depleted army.
                  *goto phalrout
                But on the fifth run, a javelin takes you in the back.  You topple into the bushes, your legs suddenly nerveless and unresponsive.  Even then, you bring down two more Phalangite swordsmen who don't expect to find you still alive and fighting.  
                
                The last one shrieks, "$!{he}'s here!  The demon's here!" before you behead him. A dozen of his friends follow with torches ablaze, spot you, and fill you with arrows.
                *goto_scene death
          #I'll do my best to cut my way free and flee back into the woods.
            From your approach, you remember that there are campfires all around this area.  The nearest dense undergrowth that might cover your escape is on the far side of the commanders' fire, beside the trail that you climbed to get here.
            
            *gosub commslaughter
            When nearly all have fallen, you break through the horrified survivors and run for the shadows.
            
            *goto tagmaflee
          #I want to try to rescue my captive rebels.
            *gosub commslaughter
            When nearly all have fallen, you break through them and dart into the nearest shadowy undergrowth.
            
            *label captiverescue
            Your pursuers are dutiful but slow, terrified of meeting a Theurge-forged sword in the dark; they also expect you to be fleeing for the hills, not doubling back into the camp.  Still, by the time you reach the enclosure where your captive comrades are being held, the guards there are on high alert.  They're circling the prisoners with torches and javelins, ready to let fly at anything moving in the bushes.
            
            *if com < 2
              You don't have the skill to overcome so many.
              *if not(simz_here)
                That's just the stark truth.
                *choice
                  #I flee alone into the night.
                    *goto tagmaflee
                  #I free as many rebels as I can before the guards bring me down.
                    You're lucky.  The first guards you attack only manage to wound you with their javelins, slicing open your arm and side, rather than bringing you down.  When they're fallen, dead or limbless and shrieking, you're able to reach a group of 
                    *if inwoods > 40
                      several 
                    *if inwoods <= 40
                      a
                    dozen captive rebels.  The sword cuts their bonds.
                    
                    Then several of them scream and fall around you, just as an arrow slams into your own back.  Jolted to your knees, you try and fail to stand again.  "${addressu} ${lname}!" shouts a voice you can't quite recognize.  One of your rebels.
                    
                    You press the gold-hilted sword into their hands, whoever they are, and try to speak…but the ground is rising up to meet you, and the world becomes a haze of pain and encroaching gray.  Your last thought is a desperate hope that at least some of them escape.
                    *goto_scene death
              *else
                But on the edge of one group of captives, you see someone who just might.
                *page_break
                You wait until the rotation leaves only four guards between you.  Then you break from cover. There's no way to avoid being seen, but you dodge one javelin, take a gash in your arm from another.  The soldiers fall before you like barley to the scythe.  And while the others begin charging toward you, you cut ${simon} de Firiac's bonds and press the golden hilt into ${zhis} hands.
                
                $!{zhe} is magnificent and lethal, moving swift as a spark and fluidly as a shadow.  Another, larger cluster of soldiers tries to bring ${zhim} down, but the young blademaster tumbles unscathed into their midst and fells all ten in as many seconds.  
                
                You can't spend much time admiring ${zhis} handiwork, as you work to cut free more of your rebels with the late Tagmatarch's belt knife. When ${simon} manages
                *goto captiveflee
            *else
              *comment if com = 2
              You wait for the right opening, and when you see it, move without hesitation.  A torch is blown low by a strong gust of wind. The guards look at it, take their eyes off the suddenly dim undergrowth.  When it blazes up again, you're among them, and six Phalangites die in as many seconds.
              
              You pluck the torch from the hand of the last man to fall, and hurl it at the next closest group of guards.  They return a volley of javelins, but you've already rolled through the darkness to the captives at the edge of the enclosure.  "Hands," you whisper, freeing those who understand enough to offer you their bonds.  
              
              And then you run in a low crouch to meet another band of guards—who expect you to still be on the far side of the prison enclosure.  They fall almost before they manage to scream. Again, a shower of arrows and javelins falls behind you, too late.  When you burst from the shadows 
              *label captiveflee
              to kill a third group of guards, you bellow, "After me!" and lead an exodus into the forest.
              
              Perhaps half of the captives survive; the others fall to missiles, swords, or the river you ford just above the enemy camp.  But at least those who die won't face the Harrower.
              *achieve captiverescue
              *if (com < 2) and simz_here
                
                When the last sounds of pursuit fade behind you, ${simon} hands you back the Theurge-forged sword.  $!{zhe} stares at you in awe through ${zhis} one good eye. The other is swollen nearly shut, with clotted blood all round from a gash across ${zhis} brow.  Tears are leaking from both. "I'd not hoped to see you again, ${addressu}.  Indeed, I'd hoped I wouldn't, this side of Elysia.  Not in my wildest imaginings…."
                
                You swallow hard.  "If it hadn't been for your skill, ${zmilady} de Firiac, we would all be in Elysia soon.  Let's keep up a good pace."
            *set cas +round(inadults/2)
            *gosub cascheck
            *set arms +inadults
            *goto survived
    *if (accounting = 0) #I surrender.
      *label surrender
      *gosub captured
      
      As you're led into the prisoner enclosure, each rebel has their face brought close to a lantern and scanned from all sides.  You almost hope that with all the blood and battering, you'll go unrecognized.  Then: "This is the one," Hector Keriatou's cool, hateful voice echoes from the shadows. "My 
      *if helot
        erstwhile chattel."
      *if aristo
        beloved cousin."
      *if int > 1
      
        Even as you start to go into a ${wisardric} trance, a clout to your skull drops you into unconsciousness.
      *gosub fleecas
      *page_break
      *label braveheart
      Your parade through the Rim
      *if int > 1
        (under constant Theurgic guard)
      takes six months.  They bring you through part of the Westriding, too, and finally to Grand Shayard, the sprawling seat of the Archon.  You'd had no idea the Rim was so big, let alone the world.
      
      At each stop you're tormented, allowed no words but a scream; you leave covered in blood and refuse.  And yet you find in each crowd there are those whose faces betray something other than scorn or hate.  Some onlookers in every part of the realm study your humiliation with bitter sympathy, anger, or determination.
      
      As you approach the capital, for the first time in your life you see other machines that look as elaborate as Harrowers, but turned to the spinning of wool, the grinding of flour, or the weaving of cloth.  Your captors tell you before you arrive that twenty-two hundred Rim Squares would fit comfortably into Grand Shayard…but that's a reality beyond imagining until you see the smudge in the sky from a hundred thousand house-fires, and finally look down onto a vertiginously huge city, ramshackle houses spreading out to the horizon on all sides.
      *if aristo
        [i]My Season has come at last, cousins.[/i]
      
      Your Slow-Harrowing on the steps of the Naos takes six days.  On the last day, when your limbs have all been flayed and severed, you can feel death catching up with you despite the expert work of the attendant Theurge.  She forces the fog of agony from your mind for a moment while the account of your crimes is re-read. In what you know will be your last lucid moment, your eyes scan the crowd.
      
      You don't spy the face of the person waving it, but your eye is caught by a flash of black on white.  A familiar sigil traced on a scrap of cloth, crude but unmistakable: a ${sigil}.
      
      [i]It is not over[/i],  you try to cry, but you long ago lost your tongue.  A wordless, throaty rasp is the last thing your executioner hears from you.
      *goto_scene death
*label won
*achieve winfight
*set wonfight 10
*set notoriety +100
*page_break
*if choice_randomtest
  *choice
    #At victory, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.  ${inwoods} inwoods, ${inadults} inadults, ${inkids} inkids.
      *goto postchoice8
*label postchoice8
That night your survivors
*if theurges = 0
  build an enormous bonfire
*if theurges > 0
  gather under the moon 
and dance until dawn.  Their exuberance is wild and unearthly—like something out of a jongler's tale where the fey folk of the forest swallow villages in their mad reels.  Tomorrow there will be time for worries and plans, for reimmersion into reality.  Tonight, you've broken the Thaumatarch's army, and anything is possible.

*if kal_here
  "Didn't I tell you?" ${kalt} yells, laughing almost uncontrollably. "$!{oath}, 
  *if aristo
    ${addressu}
  ${fname}, didn't I tell them all we had it in us?  And you believed it, bless you.  And we've sent the yaudswivers bolting for home."

*if zv_here
  Zvad is barely moving for his bandages, but there's a light in his eyes and his voice is still strong. "You were right, ${addressu}.  
  *if (religion > 9) and (religion < 20)
    The Angels did speak to you, and 
  I should have trusted you.  Forgive me.  You'll hear no more doubt from me."
  
  *comment endif
*if simz_here and (s_rel < 9)
  ${simon} de Firiac
  *if s_rel < 5
    catches your hands, laughing almost uncontrollably. "You saw it, ${fname}!  You knew we could prevail!  And we did—sweet Angels, we did."
  *if s_rel >= 5
    bows to you with reluctant respect. "Amazing work, ${addressu} ${lname}.  A victory for the history books."
  
  *comment endif
*if el_here
  Elery
  *if elsick
    is still sick, but lucid enough to grip your hand.
  *if e_rel >= 10
    *if not(elsick)
      hurls herself at you, beaming. 
    "You did it!  $!{addressu} ${fname}, you bloody well beat them!"
  *if e_rel < 10
    *if not(elsick)
      can't hold back a grin. 
    "Well, damned if you didn't bring it off, ${addressu}.  Well done."
  
  *comment endif
*if bred_here and not(bred_pris)
  You find Breden leaning against a tree, wearing a look of incredulous relief.  "Angels.  Great bleeding Angels.  I truly didn't think we'd live to see the night."
  *if helcamp > 0
    $!{xhe} glances back at you, breaking into an enormous, fierce smile. "And we've got another
    *set d2n_num helcamp
    *gosub d2n
    rebels stirring up the camps.  The bastards will get back to find ten times more commotion in Shayard than they faced out here."
  *if bred_lover >= 4
    *if bred_lover != 13
      Standing up, ${xhe} pulls you into 
    *if bred_lover = 13
      For all ${xhis} anger with you, you can sense it's taking all ${xhis} will not to pull you in for 
    a kiss. "You've started it, 
    *if bred_lover != 13
      love.  
    *if bred_lover = 13
      ${bfname}.
    It's going to happen.  We're going to bring down the Thaumatarch."
  *if bred_heart = 3
    The love in ${xhis} eyes goes even deeper than the joy. "And it's down to you, love.  Your vision.  Your lead."
    
  *comment endif
The thought of the humiliation Hector Keriatou must be going through is particularly glorious.

*if (dadfeel > 0) and bred_pris
  At the same time, Breden's disappearance
*if dadfeel = 0
  Despite the general joy, some outlaws seem unsure of how much they're allowed to celebrate when their leader has just undergone a tragedy.
  *if (breden < 0) and ((bred_lover >= 4) or (bred_heart = 3))
    It's not just Breden's death.
  Only moments after the great victory, you'd learned
  *gosub daddead2  
  
  Ever since, the rest of the band have been tiptoeing around you, uncomfortable and uncertain.
  *if bred_pris
    Breden's disappearance also 
*if bred_pris
  has you on edge.  $!{xhe} managed to cut ${xhis} bonds and flee during the Plektos attack.  $!{xhe} never returned to the band afterward, and none of your rangers have spotted ${xhis} body or ${xhis} tracks.
  *set breden 17
  *set bred_here false
  *set bred_pris false
  *set followers -1
  *set nonkids -1
  *fake_choice
    *if (bred_lover >= 4) or ((bred_heart > 1) and (bred_heart < 4))
      #I can barely keep from weeping whenever I think of it.
        *gosub t-or-no-t
    #[i]$!{oath}.[/i]  I've driven ${xhim} away.
      *gosub drivenaway
    #Running off before questioning? It's as much a confession as we'd ever have got from ${xhim}.
      "$!{xhe} poisoned us," you growl to ${deputy}. "An innocent would have taken the chance to defend ${xhis} name."
    #I grind my teeth, wishing we had time to hunt ${xhim} down and put an end to ${xhis} treachery.
      "If anyone sees ${xhim}, put an arrow in ${xhim}," you tell ${deputy}. "$!{xhe}'s a traitor and poisoner, an enemy to
      *if skep <= 50
        Almighty Xthonos."
      *if skep > 50
        the rebellion."
*if (breden = 14)
  *if (hdead = 1) and horhostage
  
    Your noble ${hostages} also died at some point in the withdrawal.  "Phalangite archers," Young Earnn reports hoarsely.  "Don't think they can have known who they were killing."
    *set hdead 2

All in all, as you look around the celebration, you can't help feeling:
*fake_choice
  #Elated.  $!{oath}, we broke a Hegemonic army!
  #Deep satisfaction.  Their commander was no match for me.
  *if dadfeel < 8
    #Shattered.  My father is gone.
  *if dadfeel >= 8
    #Shattered.  I can't forget how many we've lost.
  #Nothing.  I'm completely numb.
  #Frightened.  This isn't the end.  It's never the end.
*if (radmar > 9) and rad_here
  With your authority newly strengthened and the rebellion triumphant, you…
  *gosub radexecute
*gosub bredtrial
The spirit of celebration lasts four nights—a short time for such a monumental and unlikely triumph.  

*gosub willtheyscour
By the fourth night, the revelry is more muted and comes to an early end.  By now, everyone has remembered the cost of the victory, and how much it relied on good fortune and surprises that you won't be able to repeat.  You doubt there's a single soul in the rebellion free from nightmares about Plektos howls and the smell of vitriol.

"We won't beat them like this a second time, ${addressu}," ${deputy} says flatly, as the last song comes to an end and your followers disperse.

"No.  We won't."  
*if (deputy = kalt) or (deputy = "Radmar")
  You glance ${dephis} way with some surprise. "But I hadn't thought to hear you say so."
  
  $!{dephe} shrugs.  "I knew we could do it.  Once.  And so we did.  But they'll have a better judgment of us now."
  
  *comment endif
It takes you three tries before you overcome a dry throat to say,
*goto havescent

*label survived
*page_break
*label survived2
*if inkids > 2
  *set kidsdead +round(inkids/3)
  *set dead +round(inkids/3)
  *set kids -round(inkids/3)
  *set followers -round(inkids/3)
  *set inwoods -round(inkids/3)
  *set morale -inkids
  *set inkids -round(inkids/3)
*if choice_randomtest
  *choice
    #At bare survival, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.  ${inwoods} inwoods, ${inadults} inadults, ${inkids} inkids.
      *goto postchoice9
*label postchoice9
*set wonfight 5
That night, deep in the wilderness, you sit with a handful of other survivors who can't sleep despite all your injuries and exhaustion.
*if dadfeel = 0
  An hour ago, ${deputy} told you the news you'd been braced to hear:
  *gosub daddead2  
  
  Now you're crouched in the moonlight with a small circle of survivors.
*if bred_pris
  Breden is not one of them.  $!{xhe} managed to cut ${xhis} bonds and flee during the Plektos attack.  $!{xhe} never returned to the band afterward, and you don't expect ${xhim} to.
  *set breden 17
  *set bred_here false
  *set bred_pris false
  *set followers -1
  *set nonkids -1
  *fake_choice
    *if (bred_lover >= 4) or ((bred_heart > 1) and (bred_heart < 4))
      #I can barely keep from weeping when I think of it.
        *gosub t-or-no-t
    #[i]$!{oath}.[/i]  I've driven ${xhim} away.
      *gosub drivenaway
    #Running off before questioning? It's as much a confession as we'd ever have got from ${xhim}.
      "$!{xhe} poisoned us," you growl to ${deputy}. "An innocent would have taken the chance to defend ${xhis} name."
    #I grind my teeth, wishing we had time to hunt ${xhim} down and put an end to ${xhis} treachery.
      "If anyone sees ${xhim}, put an arrow in ${xhim}," you tell ${deputy}. "$!{xhe}'s a traitor and poisoner, an enemy to
      *if skep <= 50
        Almighty Xthonos."
      *if skep > 50
        the rebellion."
  
  *comment endif
Your situation scarcely bears thinking about.  You've many gravely injured rebels, with no food, and you don't dare make a fire of any size.
*if (hdead = 1) and horhostage
  You learn that your noble ${hostages} also died at some point in the withdrawal.  "Phalangite archers," Young Earnn reports hoarsely.  "I'm sorry, ${addressu}.  Don't think they can have known they were killing Horion ${delelle}."
  *set hdead 2

*if helcamp > 0
  "Whatever happens to us, there's still the
  *if flee > 0
    *set d2n_num flee
    *gosub d2n
    who fled and the
  *set d2n_num helcamp
  *gosub d2n
  who made it out to the Rim," one outlaw rasps at last.  "We knew that was where the rebellion had a real chance.  They'll remember us, sisters and brothers."
  
"The Phalangites hopefully won't keep after us," ${deputy} says thinly. "Takes a lot to keep an army like that in the field.  And they well and truly broke us.
*if tagmasword
  Even with their Tagmatarch gutted and her sword stolen, they
*if not(tagmasword)
  They 
can call this a victory and go home.
*if (radmar > 9) and rad_here
  But…" $!{dephis} voice trails away.
  
  [i]Theurges won't give up.[/i] "We escaped them, ${deputy}," you rasp. "That's what matters, for now." 
  *page_break
  For days afterward you all stagger westward through the forest, up into the hills and away from High Crag.  The misery of your survivors is intense and unrelievable; none of you carried away any shelter or food from the camp.  All you have is your lives.
  
  And, in your case, the fury you've held inside ever since Radmar slaughtered Breden.  You know your demoralized survivors won't resist any vengeance you take on him now.  After several days, you…
  *gosub radexecute
  "We need to speak on something, ${addressu}." ${deputy} rubs at ${dephis} eyes, which are bloody from sleeplessness. "I don't expect the Phalangites to catch us now.
But the Theurges, and the bloody Plektoi…"

You swallow hard before agreeing,
*goto havescent

*label slipaway
*set wonfight 7
*set notoriety +20
*set inadults +bredvom
*set inwoods +bredvom

*if choice_randomtest
  *choice
    #At slipaway, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.  ${inwoods} inwoods, ${inadults} inadults, ${inkids} inkids.
      *goto postchoice10
*label postchoice10
You and your 
*set d2n_num inwoods
*gosub d2n
remaining rebels spend the rest of the day pressing deep into the woods, 
*if bredvom = 0
  as quick and stealthy as deer.
*if bredvom > 0
  bearing along the
  *set d2n_num bredvom
  *gosub d2n
  casualties of poisoning as swiftly as you can.
*if dadfeel = 0
  Your mind keeps circling back to the tragic news that reached you as you were descending High Crag:
  *gosub daddead2
  
  Now
Alira and her scouts fall away one by one to watch your backtrail and bring warning if the Archon's forces are at your heels.  

"$!{oath} send they don't have another Plektos," Alira mutters to you when you part. "But if they do, ${addressu}, I'll do what I can to make it howl before it takes me.  Give you some warning."  She manages a thin, terrified smile.

Knowing that this is your chance to truly escape puts a fire into your limbs—as does the memory of the 
*if lostem
  Plektoi.
*if not(lostem)
  Plektos.
Throughout the day, you barely feel the exhaustion of a sleepless night or the pain of your struggle with the 
*if lostem
  hound.
*if not(lostem)
  hounds.
Then with the twilight it all floods back in a great, erosive surge, leaving you swaying and barely able to move.  While the band makes camp around you, you stumble into a sheltered combe and pass out.
*page_break
*achieve evaded
Though the pre-dawn stirring wakes you, you give your battered, leaden body a few more motionless minutes before opening your eyes.  When you drag yourself upright to begin the day's flight, you find Alira crouched nearby.  The smile she gives you now is shaky with fatigue. "They're breaking up, ${kuria}.  No hounds to be seen, and 
*if theurges > 1
  the Theurges are staying close to camp.
*if theurges = 1
  the last Theurge is sticking close to camp.
*if theurges = 0
  no new Theurges.
We've escaped."

"You're sure?"  Your heart drums frantically. "$!{oath}, Alira.  Can it be true?  They can't afford to fail."

"Doesn't matter.  They did fail.  Failed to catch us, by army, by Theurge, and by hound.  They won't get ahead of us now, and they can't keep chasing us forever."  Alira's laugh has a sob-like catch in it, but her eyes are bright.  "The only choice they've got is to keep pouring blood and silver into the chase until the late autumn storms hit, or to pull back and take whatever consequence the Archon metes out."

No one dares a cheer, but the ripple of joy that goes round your camp is all the more intense for being half-pent.
*if el_here
  Elery
  *if elsick
    is still sick, but lucid enough to grip your hand.
  *if e_rel >= 10
    *if not(elsick)
      hurls herself at you, beaming. 
    "You did it!  $!{addressu} ${fname}, you bloody well beat them!"
  *if e_rel < 10
    *if not(elsick)
      can't hold back a grin. 
    "Damned if you didn't bring it off, ${addressu}.  Well done."
  
  *comment endif
*if bred_here and not(bred_pris)
  Breden sinks to the ground with a look of incredulous relief.  "Angels.  Great bleeding Angels.  We escaped them."
  *if helcamp > 0
    $!{xhe} glances back at you, breaking into an enormous, fierce smile. "And we've got another
    *set d2n_num helcamp
    *gosub d2n
    rebels stirring up the camps.  The bastards will get back to find ten times more commotion in Shayard than they faced out here."
  
  *comment endif
*if kal_here and (k_rel < 7)
  ${kalt} grins wearily at you. "Still wish we'd fought the yaudswivers, ${addressu}.  We could have kicked them straight back to Grand Shayard.  But I have to say…this is more satisfying than I'd expected."
  
  *comment endif
The thought of the humiliation Hector Keriatou must be going through is particularly glorious.

*if bred_pris
  Still, Breden's disappearance 
  *if (bred_lover >= 4) or ((bred_heart > 1) and (bred_heart < 4))
    makes it hard to feel much 
  *if (bred_lover < 4) and ((bred_heart <= 1) or (bred_heart >= 4))
    steals something of your
  satisfaction.  $!{xhe} managed to cut ${xhis} bonds and flee during the Plektos attack.  $!{xhe} never returned to the band afterward, and none of your rangers have spotted ${xhis} body or ${xhis} tracks.
  *set breden 17
  *set bred_here false
  *set bred_pris false
  *set followers -1
  *set nonkids -1
  *fake_choice
    *if (bred_lover >= 4) or ((bred_heart > 1) and (bred_heart < 4))
      #I can barely keep from weeping whenever I think of it.
        *gosub t-or-no-t
    #[i]$!{oath}.[/i]  I've driven ${xhim} away.
      *gosub drivenaway
    #Running off before questioning? It's as much a confession as we'd ever have got from ${xhim}.
      "$!{xhe} poisoned us," you growl to ${deputy}. "An innocent would have taken the chance to defend ${xhis} name."
    #I grind my teeth, wishing we had time to hunt ${xhim} down and put an end to ${xhis} treachery.
      "If anyone sees ${xhim}, put an arrow in ${xhim}," you tell ${deputy}. "$!{xhe}'s a traitor and poisoner, an enemy to
      *if skep <= 50
        Almighty Xthonos."
      *if skep > 50
        the rebellion."
  
  *comment endif
*if (radmar > 9) and rad_here
  Or it would be satisfying, if Breden's murder weren't still 
  *if (bred_lover >= 4) or (bred_heart = 3)
    haunting your memories.
  *if (bred_lover < 4) and (bred_heart != 3)
    souring your stomach whenever you saw Radmar.
  With your authority newly strengthened by your successful escape, you…
  *gosub radexecute
*if (hdead = 1) and horhostage
  *set hdead 2
  *if breden = 14
    Another
  *if breden != 14
    One 
  piece of bitter news is that your noble ${hostages} died in the withdrawal.  "Phalangite archers," Young Earnn reports hoarsely.  "I'm sorry, ${addressu}.  Don't think they can have known they were killing Horion ${delelle}."

All in all, you can't help feeling:
*fake_choice
  #Elated.  We've survived, against all odds.
  #Deeply satisfied.  We evaded everything they had to throw at us.
  *if dadfeel < 8
    #Shattered.  My father is gone.
  *if dadfeel >= 8
    #Shattered.  I can't forget the cost of victory.
  #Nothing.  I'm completely numb.
  #Frightened.  This isn't the end.  It's never the end.
*gosub bredtrial
*gosub willtheyscour
Only after two more days' retreat in the direction of the Ward does ${deputy} beckon you aside for the conversation you knew was coming.  Perhaps ${dephe} had been sparing you because of your father's death.  "$!{addressu} ${fname}…we need to talk about the Plektoi."

You try to speak, but at first your throat is too dry.
*goto havescent

*label havescent
"They'll still have my scent.  They won't send another army, but it's only a matter of time before they send more hounds."

${deputy} nods, bleak-faced.  "With a host of Theurges.  And they'll cut a swathe through anyone who's nearby when they catch you."

*if szth > 0
  There is one thing you know of that can counter Plektoi and protect those around you.
  *choice
    #Go to Szeric as quickly as possible to see if you can find Horion's secret Theurge.
      *goto szeric
    #I'm not going to chase phantoms.  There's a more obvious if terrifying solution.
      Your deputy furrows ${dephis} brow.
      *goto splitup
"The solution is clear, I'm afraid."

${deputy} furrows ${dephis} brow at you; ${dephe} evidently doesn't find it clear.
*label splitup
*if bred_pris
  *set bred_here false
  *set bred_pris false
  *set followers -1
  *set nonkids -1
  *set breden 17
"Time to split up?"

"Time to think the unthinkable."  There's one line that no Plektos can cross—nor anyone else who may come hunting.

You muster all the survivors of your band and choose who's going to lead them in your absence:
*gosub xaosprep
*goto intoxaos

*label szeric
*text_image 4_1.png center One Month Later

*if zv_here
  "Zvad's
*if not(zv_here)
  *if korszata > 0
    "Korszata's
  *if korszata < 1
    "Pitrj's
coming back, ${addressu}." Your scout gestures over her shoulder toward the lip of the cliff. "Not alone."

You crouch in the shadows at the edge, hidden by scraggly pines and frost-spangled boulders, and watch the
*if zv_here
  craggy ${whend}
*if not(zv_here)
  *if korszata > 0
    solemn former Phalangite
  *if korszata < 1
    ${whend}ish bandit
and his companion clamber along a stony stream bed far below.  It's taken days longer than you'd expected to reconnoiter these mountain villages. Most folk speak Szert here, not Wiendzna, and are suspicious of even ${whend}ish outsiders.  You try to make out the face of the fur-clad informant when the two turn and begin scrambling up the steep slope toward your camp.

"This is Andrejna, Eye of Clan Lesk," 
*if zv_here
  Zvad
*if not(zv_here)
  *if korszata > 0
    Korszata
  *if korszata < 1
    Pitrj
explains when they finally arrive and catch their breath.  His guest is a tall, lean woman. Her silver hair is shorn almost to the skull in what you've been told is the
*if natl > 60
  bizarre
fashion of the high-country ${whend}s.  Through the part in her heavy fur cloak, you can see the glint of gold and ivory from her clan chief regalia.  "Leader of half the villages on this end of Szeric.  An old friend of
*if zv_here
  mine,
*if not(zv_here)
  Zvad's,
and the Pan. And she's got some advice I thought you'd want to hear."

The Eye of the Lesk cuts in urgently, in accented but fluent koine. "Run back into Szjard, ${kuria}. Rumors have flown of a force in the woods asking after Pan Szeric.  This morning we saw the first Theurges on the horizon, and heard that an army is marching up our valley."

You feel your pulse race again.  "The Pan is coming after us?"

"The Pan is dead," Andrejna grates. "Szeric is hosting two hundred Phalangites and twice as many Alastors.  Or was.  Now, I think, I will be hosting them."
*label szerchoice
*choice
  *hide_reuse #"$!{oath}.  A Kryptast?  Or did they kill him outright?"
    The chief grimaces.  "For so great a blow as this, no Kryptast would be enough.  He was named traitor by his Alastor captain, who had brought in many 'reinforcements' in the name of hunting the rebel ${lname} across the Divljna Pass—what you call 'Whendward.'  
    
    "When instead they turned on the Pan, the Hegemonics had to kill his personal guard and all his clan-kin in the fortress.  The Archon in Wiendwic will choose a new Pan Szeric, and it will need to be from a rival clan.  None other would accept so great a feud as will follow from this."
    
    "Did they say why they thought he was a traitor?"
    
    "Speaking sedition and helping traitors to the Hegemony."  Andrejna stares at you coolly.  "None named.  But with you here asking after him, all will think they know the reason."
    
    "And they'll be wrong," you retort, to her raised eyebrow.  [i]Surely, it was the Theurge.  We're too late.[/i]
    *goto szerchoice
  *if ((horion > 15) and (horion < 27)) 
    *hide_reuse #"Had anyone from Shayard come across the pass to meet him recently?"
      Your speculation about Horion is cut off by her brisk head-shake. "No one that we saw.  And we would likely have seen them when they came down the valley."
      *goto szerchoice
  *hide_reuse #"What if these Alastors learn you've helped us?"
    "It will make no matter.  I am known as a close ally of the late Pan, and Lesk is no great clan to make them wary.  The only thing to save me would be to surrender you to them."  After a pause, she shrugs, offers a thin smile. "You are fortunate to have come across into the high country.  The lowland clans would trip over each other in their haste to dishonor themselves."
    *goto szerchoice
  #There's only one more question I want to ask.
    *set cerlota 1
    "Did the Pan have a guest?
    *if ((horion > 15) and (horion < 27))
      Not from Shayard.
    An ${erretsin} visitor?"
    
    Andrejna lowers her silvery eyebrows and regards you impassively for several moments. "The segnura Cerlota Viore.  She is the one who first brought us the news of the slaughter, the day after the attacks."
    
    Your eyes widen.  "She's with you still?"
    
    "Kuria Cerlota stayed with us only a few hours.  She said she would be pursued to all places save one, and did not wish to draw down doom on us. Then she went off there.  To the West."
    
    Your eyes follow her finger to the craggy horizon, where the sky darkens to the color of a bruise and strange lights flash on the ice of the peaks.  Terror and elation swirl up inside you to heights that neither could have achieved alone.
    
    "We'll run, then," you say, your tongue dry and stumbling.  "Some back to Shayard.  Some out into ${whendery}."  But for you, there's only one direction left.  Glancing over to mutilated Yed Gaverne, you see from his wide, unblinking eyes that he's realized it too.  "Those who go to carry on the fight in Shayard will be led by…"
    *gosub xaosprep
    *goto intoxaos
*label flee
*if choice_randomtest
  *choice
    #At preflee, we have ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  Arms ${arms}, wealth ${wealth}.  ${inwoods} inwoods, ${inadults} inadults, ${inkids} inkids.
      *goto postchoice11
*label postchoice11
*gosub fleecas
*page_break
Two hungry, feverish days later, you run past Yed Gaverne.

He sees you long before you see him, and hails you softly from a thicket across the valley. "$!{addressu}. $!{addressu} ${lname}."  When you see his smooth stump of an arm waving at you, an overwhelming surge of relief and terror passes through your body.  

His slow pace as he breaks cover and crosses to you gives you time to reflect on that intense emotion. It's not just that you've found another survivor of the catastrophe, you realize.  Rather, seeing the man who survived the Xaos-lands has brought your sole remaining choice into stark relief.  [i]I knew it, I think…but I couldn't bring myself to think it without him.[/i]

"Yed," you say hoarsely, swaying on your feet. "You lived."

A small smile quirks his ruined face.  "I've survived worse than Plektoi, ${addressu}, and a damn sight worse than Phalangites."
*if dadfeel > 0
  
  *goto postpostyed
*if dadfeel = 0
  Then his hint of good cheer vanishes.  "I'm sorry, ${addressu}.  Shouldn't be talking so blithe about it, when…"
  
  "When what?"  There's something in his eyes that steals the moisture from your throat.
  
  "You didn't have time to see, did you?"  Yed clucks his tongue. "Ah, ${addressu}, I'm sorry.  But…the Plektos got your father.  Out in the woods, before it came up the mountain for you."
  *choice
    #I sink to my knees, feeling numb and unmoored from reality.
      Even hearing the truth in Yed's voice, it seems impossible that he's gone.  His cruelty, his fleeting affection, his judgment…who can you be, with all of those fixed points gone from the world?
      *set dadfeel 5
      *goto postyed
    #"At least it was quick." I turn away, head spinning…feeling more sadness than I'd expected, and more compassion.
      Can you really mourn someone who brought so much misery to your life?  A little, perhaps.  For the misery he sank himself in, too deep to find any way out but one.
      *set dadfeel 8
      *goto postyed
    #"Serves the old bastard right," I whisper hoarsely to myself.
      The sense of release that sweeps over you is terrible but sweet.  The cruelty you've lived with your whole life is gone.  The last person who could hurt you without consequence is dead.  You stagger back, almost weeping at the sudden weight of freedom.
      *set dadfeel 10
      *goto postyed
    #[i]Oh, Angels, no. No.[/i]
      You double over, gasping with a pain too deep and dry for tears.
      *choice
        #I'd always hoped, one day…
          *set dadfeel 2
          So many years bearing with his cruelties for the scraps of genuine affection.  Treasuring each one when it came.  Trying to believe that in time they'd burgeon into something deeper, more consistent. 
          *goto postyed
        #I wanted so much to prove him wrong about me.
          *set dadfeel 3
          He was wrong about so Xthon'damned many things.  Who will know, now?  Who will tell you when you've won?
          *goto postyed
        #I knew things would never change—but he was my father.
          *set dadfeel 1
          A terrible father.  But losing him still feels like losing yourself.
          *goto postyed
*label postyed  
"Thank you for telling me."  Your voice is a faint rasp.  

Suddenly you find your mind filled with horrid imaginings of your father's corpse—all the many ways that a Plektos could have torn him. [i]How did it kill him?  How quickly?  Ah, ${sweetoath}.[/i]  You grip your head in your hands, trying to force the images away.

Yed inclines his head sadly.
*if (hdead != 1) or not(horhostage)
  "Wish I weren't the one who had to do it."
*if (hdead = 1) and horhostage
  "Your noble ${hostages}, too, ${addressu}.  I'm sorry to say it.  That Horion seemed a pleasant enough sort for an aristo."
  *set hdead 2

It's a struggle to refocus on your present danger.
*label postpostyed
"They'll send more hounds after me now, with more Theurges."  You keep your voice level, despite the terror pulsing just below the surface.  "They have my scent."

The former ostler goes absolutely still, staring at you with one wide, bright eye. "And you've got an idea."

"The same one you had, Yed.  Nothing Theurgic can pass through the Ward."
*fake_choice
  #"I'll travel just far enough to throw them off my trail, and then get back onto this side."
  #"I want to meet some of the survivors there.  See whether they'd support a rebellion."
  #I don't say anything more, just wait to see his response.
"Ah, ${addressu}."  Yed whirls away from you, begins pacing back and forth.  "Don't you go asking what I think you're asking me."

"I can't ask you anything more than to help me find the way there."  How could you ask more of anyone, when you've led so many to their deaths?  "And while we walk, to tell me whatever you think will keep me alive."

"Swiving Xthonos.  You think I can put what you need in words?  A year's worth, in however many days it takes us to reach the storms?"  

"No.  But I'll take whatever you can."

The lean, broken man stops and stares at you. "You took me in when I was dying, and saved me from the Plektos, ${addressu}.  Reckon I owe you a life.  I'll see you across the Ward, at least, and point you where you need to go."

It's hard not to weep, especially in your exhausted state. "There's…no thanks I can give that would…"

"Then don't try.  But let's keep moving."
*if tagmasword
  He looks sharply at your whorled golden sword.  "That looks a finer blade than I've seen you carry, ${addressu}.  But you know it can't come with us."
  
  "On more than one count."  You walk over to a boulder and sheathe it, then pull it out again. 
  
  Yed breaks into a sudden cackle of delight. "Well, damn me if that's not a nice trick.  But I'll wager you it won't put a scratch on the Ward-wall, ${addressu}, nor cross it for all the ${wisardry} in Karagon."
  
  "I'll find a crag near the Ward—something recognizable—and leave it stuck in there."  You start walking. "Someplace we'll recognize when we come back again."
  
  "When we come back."

As you scramble up the valley with Yed, the thought of your father's broken body returns to you with shattering clarity.  He would have had plenty to say about your desperate state right now.  You can almost hear his caustic voice in your mind.
*goto the_end

*label intoxaos
*if bandlead != "Yebben"
  ${bandlead} stares at you with dawning, horrified 
*if bandlead = "Yebben"
  ${bandlead}'s face slowly twists in 
realization. "What about you, ${addressu} ${lname}?" another outlaw demands, still not understanding.

You jab a finger at the western horizon, forcefully enough to hide any tremor in your hand.  "There's only one place I can go where no Plektos or Theurge can follow.  And thanks to Yed, we know now that it's possible to pass through and survive, soul intact."
*fake_choice
  #"I'll travel just far enough to throw them off my trail, and then get back onto this side of the Ward."
  #"I want to meet some of the survivors there.  See whether they'd support a rebellion."
  *if (cerlota > 0) 
    #"If this segnura Cerlota is still alive, I'll find her.  There are things she knows that the Hegemony fears, and our rebellion needs."
*if (cerlota > 0)
  Clan chief Andrejna nods her wordless approval.
A mutter of horror runs round 
*if (cerlota > 0)
  the rest of
your outlaws.  "$!{addressu}…the risk…"

"Is less than waiting until they send the next lot of Plektoi after us," you declare flatly.

"You can't carry a weapon in, ${addressu}," Yed Gaverne rasps, looking as if he's about to vomit. "Not even a paring blade."

*if tagmasword
  It's agonizing to give up the Tagmatarch's sword—the one prize you've brought out of this catastrophe.  But Yed is clearly right.  There's no way it's crossing a Ward.
  *choice
    #I hand it at once to ${bandlead}.
      *if bandlead = simon
        *goto givetosimz
      *label givetoblead
      *set sworddonor 2
      "Keep this until I return."  You yield the golden blade to the stunned-looking ${bandlead}.  
      *if (bandlead != simon) and (bandlead != "Zvad")
        "Find someone who can fight with it.
      *if (bandlead = simon) or (bandlead = "Zvad")
        "Wield it against them.
      Go after whoever in the Rim dares to speak of the Archon's 'victory' in these woods.  Remind them what it cost."
      *goto bloodcross
    *if (simz_here) and (bandlead != simon)
      #I'll give it to ${simon} de Firiac.  $!{zhe} won't be coming into Xaos with me.
        *label givetosimz
        *set sworddonor 3
        "Our blademaster should have this blade," you say quietly, unclasping the sheathed sword from your belt.
        *if s_rel >= 5
          "You and I may not have dreamed the same rebellion, de Firiac.  But you stayed loyal through the great fight.  And I reckon you'll do more damage to the Thaumatarchy with this than any of the rest of us could."
        
        ${simon} accepts the 
        *if s_rel >= 5
          sword with trembling hands, reverence and distaste warring across ${zhis} face. "I'll bear it with honor, ${addressu} ${lname}."
          
          You exhale sharply.  "That's what I thought you'd say.  But I'm giving it to you anyway."
        *if s_rel < 5
          sword, ${zhis} hands trembling, and raises it in reverent salute. "$!{addressu}.
          *if s_sword = 1
            You know I'd not set aside the sword of the de Firiac for any lesser blade.  But this…well,
          I'll bear it in your name and for your honor."  The tears in ${zhis} eyes wordlessly add, [i]In your memory.[/i]
        *goto bloodcross
    #I almost decide to hide it…but there's scant chance I'll ever return to claim it.  I give it to ${bandlead}.
      *goto givetoblead
    #No.  I'm not letting anyone else have it.
      You'll bear it with you to the Ward, then sheathe it deep into some crag that only you will be able to find again.  You know you'll come back for it.
      *set sworddonor 1
      *goto bloodcross
*if weapon = "staff"
  Is your staff a walking stick or a weapon?  There's at least a chance you'll get it through, but you hand your knife 
*if weapon != "staff"
  "Look after these for me."  You hand your knife and ${weapon} 
  *if (s_sword = 2) and (weapon != "sword")
    as well as ${simon}'s sword
to the stunned-looking ${bandlead}.
*label bloodcross
*if blood > 0

  Of course, aetherial blood won't cross the Wards either, and the
  *set d2n_num blood
  *gosub d2n
  *if blood > 1
    phials 
  *if blood = 1
    phial
    *set bloodthem "it"
  you still possess 
  *if blood > 1
    are 
  *if blood = 1
    is
  *if tagmasword
    (with the obvious exception of 
    *if sworddonor = 1
      your blade)
    *if sworddonor > 1
      the blade you just gave away)
  the most valuable 
  *if blood > 1
    items
  *if blood = 1
    item
  in your rebellion.
  *set blooddonor blood
  *choice
    #So I give ${bloodthem} to ${bandlead} to keep for me.
      *if (bandlead = "Yebben")
        *goto giveyeb
      *set blooddonor +100
      "Look after ${bloodthem} well," you tell ${bandlead}, handing over the pouch where you've kept your phials. "I'll be asking for ${bloodthem} back before you know it."
      
      "Not as if I could do aught else with ${bloodthem}, ${addressu}." ${bandlead} tucks the cloth away quickly. "Or would want to."
      *goto askgamgee
    *if (yebben > 7) and (bandlead != "Yebben")
      #I give ${bloodthem} to Yebben Skinner.
        *label giveyeb
        Yebben's careful hands fold around the pouch you hand him; the only tremor is in his voice. 
        *if yebben = 8
          "Are these…"
          
          "What I wouldn't show you before."
          
          The blind youth nods slowly.
        *if yebben < 10
          "I'll keep ${bloodthem} safe for you, ${addressu}."
        
          "If enough time passes and I haven't returned…"  You cough, your throat gone suddenly dry and taut. "Well, see if there's anything you can work out with ${bloodthem}.  Anything to help the rebellion.  I'm sorry I won't have the time to teach you."
          
          "As am I, ${kuria} ${lname}."  A wry smile creases Yebben's lips.  "But when you return, I'll ask again."
        *if yebben >= 10
          "I can feel ${bloodthem}, ${addressu}.  The potential."
          
          You glance down at the bag, feeling nothing, and wonder what you might have to learn from Yebben when next you see him.  "I haven't used them lightly, Skinner."
          
          Yebben raises a hand lined with half-healed cuts and smiles wryly.  "Nor will I, ${kuria} ${lname}."
        *set blooddonor +200
        *goto askgamgee
    #I can't give ${bloodthem} away.  I'll cache ${bloodthem} near the Ward.
      You secure the 
      *if blood > 1
        phials in their
      *if blood = 1
        phial in its
      pouch and set your face west, toward Xaos.
      *goto askgamgee
    #I'll use all my aetherial blood now, to heal such wounds as I can.
      *set blooddonor 0
      *if limb > 0
        *set morale +(blood*13)
        You pour all your skill and desperation into helping your survivors—knitting up bones, closing wounds, soothing swollen limbs and faces.  The blood probably lasts only for seconds, but your mind moves fleetly, touching some
        *set blood (blood*5)
        *if blood > inwoods
          *set blood (inwoods-3)
        *set d2n_num blood
        *gosub d2n
        injured rebels.
      *if limb <= 0
        You've still got almost no idea how to use ${wisardry} to help the body heal itself, but your clumsy attempts at least make your survivors feel better while your mind is on them.  For a lucky few, their wounds actually do close.
        *set morale +(blood*4)
      At last the dark stain evaporates from your hand, and you let the last phial clatter to the ground.
      *set blood 0
      *goto askgamgee
*label askgamgee

Then you pause, looking round the circle of outlaws.  "Obviously, I can't order anyone to come with me."  But your eyes rest imploringly on:
*label gamgeechoice
*choice
  *if (bandlead != "Zvad") and (zv_here)
    *hide_reuse #Zvad.
      The big ${whend} steps back from you, eyes wide. "$!{addressu}…I'd sooner have my body eaten by Plektoi than my soul by Xaos.  Don't ask me this."
      
      You shift your gaze to:
      *goto gamgeechoice
  *if (bandlead != "Breden") and (bred_here)
    *hide_reuse #Breden.
      $!{xhe} 
      *if (bred_trust > 9) or (bred_heart >= 10)
        shakes ${xhis} head 
        *if bred_heart >= 10
          curtly. 
        *if bred_heart < 10
          sadly. 
        "You'll need someone you trust out there, ${bfname}.  Not me."
        
        In that case, you'll ask:
        *goto gamgeechoice
      *if (bred_lover < 4) and (bred_heart != 3)
        hesitates for a long time and has to clear ${xhis} throat twice before managing, "Angels defend us.  I'll come with you."
      *if (bred_lover >  3) or ((bred_heart = 3) or (bred_heart = 1))
        *if ((bred_heart != 6) and (bred_heart != 7)) and (bred_lover != 13)
          strides at once to your side. "Always."  There's only the slightest tremor in ${xhis} voice, and only you are close enough to see the terror in ${xhis} rapidly blinking eyes. 
        *if ((bred_heart = 6) or (bred_heart = 7)) or (bred_lover = 13)
          stares at you for a long time without speaking. The grief in ${xhis} eyes is stark, stronger even than the fear. But at length ${xhe} nods and says hoarsely,
        "To Taratur itself."
      *set gamgee "Breden"
      *goto goodbyes
  *if (bandlead != "Elery") and (el_here and not(elsick))
    *hide_reuse #Elery.
      Elery
      *if ((elezvad > 4) and zv_here) and (e_rel > 7)
        glances once at Zvad before she
      *if ((elezvad <= 4) or not(zv_here)) or (e_rel < 8)
        immediately
      *if e_rel < 8
        snaps, "Bloody Taratur, ${addressu}, are you looking at me? I wouldn't follow you into a Barningday dance, let alone into Xaos."
      *if e_rel > 7
        replies, "I'm sorry, ${addressu}.  My place is here."
      
      You look to:
      *goto gamgeechoice
  *if (bandlead != "Radmar") and (rad_here)
    *hide_reuse #Radmar.
      *if radmar > 9
        He blinks suspiciously at you—perhaps wondering if you only want to punish him for his murder of Breden.
      "No,
      *if aristo
        ${kuria}
      ${lname}.
      *if r_rel < 10
        Not a chance in bloody Taratur.
      *if r_rel > 9
        I like you well enough, but not that swiving much.
      I'll fight here."  Radmar folds his arms.
      
      You look to:
      *goto gamgeechoice
  *if (bandlead != kalt) and (kal_here)
    *hide_reuse #${kalt}.
      *if k_rel > 5
        "When I first joined the band, ${addressu}, I thought I'd follow you anywhere." The wryness of ${kalt}'s grin doesn't come close to matching the bitterness in his voice. "You should have asked me then."
        
        When ${zhe} says nothing more, you turn to:
        *goto gamgeechoice
      The lean ex-helot hesitates only an instant before stepping to your side. "As you will, 
      *if k_rel != 4
        ${addressu} 
      ${fname}.  If Yed can live through it, so can we."
      *set gamgee kalt
      *goto goodbyes
  *if (((bandlead != simon) and (sworddonor != 3)) and (simz_here and (s_rel < 9)))
    *hide_reuse #${simon}.
      "When I joined the band, ${addressu}, I vowed I would follow you anywhere." ${simon} de Firiac unbuckles ${zhis} sheathed
      *if s_sword = 1
        family
      sword without hesitation and strides to your side.
      *if (s_rel >= 5) or ((s_lover < 5) and (s_lover > 0))
        There's no great enthusiasm in ${zhis} voice, just resignation to an unwelcome duty.
      *if (s_rel < 5)
        $!{zhis} eyes are 
        *if s_lover > 4
          bright—and though you see fear in them, somehow you think it has more to do with you than with where you're going.
        *if s_lover < 5
          bright and implacable.
      "Xaos is no exception."
      *set gamgee simon
      *goto goodbyes
  *if (bandlead != "Ciels") and (c_rel > 0)
    *hide_reuse #Ciels.
      The young tracker
      *if (ciels > 9) and bred_here
        looks at Breden, then shakes ${his} head. "I can't, ${addressu}.  Choose someone else."
        
        You look to:
        *goto gamgeechoice
      *if (c_rel < 6)
        looks at you expressionlessly. "No, ${addressu}.  Choose someone else." $!{his} dislike is clear in ${his} voice, if not ${his} face.
        
        You look to:
        *goto gamgeechoice        
      blinks at you.  "Me, ${addressu}?"
      
      "Aye, Ciels.  Whatever beasts stalk the Xaos-lands, I'll need a companion who can catch wind of them a mile off and keep us out of their way.  As well as someone who can improvise a weapon from whatever we find there."
      
      "Angels."  Ciels stares away from you for a few moments, then smiles shakily while lowering ${his} bow to the ground.  "Always wondered what those Storms looked like from the far side."
      *set gamgee "Ciels"
      *goto goodbyes
  #No one.  This is a path I'll walk alone.
    From Yed's stories, most of the threats in the Xaos-lands are best avoided rather than confronted.  Hard as it is to imagine facing it alone, you'll probably be more likely to survive that way.
    *goto goodbyes

*label goodbyes

Yed licks his lips, then hands off his own dagger to ${bandlead}.  "You took me in when I was dying, and saved me from the Plektos, ${addressu}.  Reckon I owe you a life.  I'll see you across the Ward, at least, and point you where you need to go."

You nod in silent gratitude.
*if ((s_lover >= 5) and (s_rel < 5)) and ((gamgee != simon) and simz_here)
  When you don't look to anyone else, ${simon} de Firiac steps forward, ${zhis} face a mask of anguish. "$!{addressu} ${fname}, you mean to take
  *if (gamgee != "") and (gamgee != "four")
    ${gamgee} and 
  Yed… 
  *if bandlead = simon
    are you sure my place is here with the band, rather…"
  *if bandlead != simon
    what about…"
  *page_break
  *if bandlead = simon
    "$!{zmilady} de Firiac, the rebellion needs a leader in my absence—a role I trust only you to take."  You keep your voice gentle. "Your duty to the cause is clear."
    
    "Not yet so clear to me."
    *goto vergetears
  "You are blademaster to the rebellion, ${zmilady} de Firiac.  
  *if aristo
    It would ill befit me to bring you to a place where no sword can pass."
  *if helot
    Does it make sense for me to take you somewhere you can't bring a sword?"
  You keep your voice gentle.
  *if sworddonor = 3
    "Especially the one I've just left you."
  
  "Swords be damned, ${addressu}," ${zhe} snaps, as wild-eyed as you've ever seen ${zhim}.  "I am sworn to you.  How can you ask me to stand by as you hurl yourself into the very maw of Xaos?"
  
  "I don't ask you to stand by, ${simon}, love."  You walk up to ${zhim} and clasp ${zhis} hand, swallowing against a dry throat.  "I ask you to go where the rebellion most needs you.  We both know that isn't with me."
  
  "I know no such thing." 
  *label vergetears
  ${simon} is plainly on the verge of tears. "${fname}…this rebellion would never have come about without you, without your leadership.  You are the rebellion.  To protect you is to protect it, and to abandon you is…"
  
  "What I am asking you."  Your interruption is as tender as you can make it. "For the loyalty you owe me, ${simon} de Firiac, as much as the love you bear…I ask you to trust me, and to go where I send you."  You lean in close, murmur, "And trust that I will come back to you.  This is not the end."  Then you pull away from ${zhim} before you're drawn to change your mind.
  
  $!{zhe} looks so lost that for a moment you wonder whether ${zhe}'ll actually refuse you.  But in the end ${zhe} rasps out, "As you command, ${milady} ${lname}," and walks away.
  
  You turn to Yed.
  *goto onourway
*if ((k_rel = 4) or (k_rel = 3)) and ((gamgee != kalt) and kal_here)
  But before you can say anything else, ${kalt} has grabbed your shoulder and is pulling you behind ${zhim} into the woods. "A word with you, ${addressu} ${fname}," ${zhe} grates.  None of your shaken bandits raise a hand to stop ${zhim}, nor move to follow.
  
  When ${kalt} finally stops in a sufficiently private copse, ${zhis} breath is rapid and ${zhis} eyes dark with rage. "So. You'll run off to swiving Xaos with
  *if (gamgee != "") and (gamgee != "four")
    ${gamgee} and 
  Yed, and just leave me here?"
  *fake_choice
    #"You're the spine of this rebellion, love.  They'll need that more than ever now."
      "And you?  You won't need me, fleeing across a Xthon'damned Ward?" ${kalt} shakes ${zhis} head, and something in that ragged movement betrays the anguish just below ${zhis} fury.
      
      "I won't need you as much as the rebellion does."  You grasp ${zhim} by the shoulders, hold on when ${zhe} tries to twist away.  "You know it's true, ${kalt}.  Whenever we've been soft and full of doubt, you've been there.  Everything's going to be uncertain for them now.  They need someone to keep them from falling apart.  They need you 
      *if bandlead = kalt
        leading them."
      *if bandlead != kalt
        with them."
        
        "But not leading them, of course."  How much of ${zhis} ire is the bruised pride you hear in ${zhis} voice now?
        
        "No.  They'll need ${bandlead} for that.  They'll need you to keep ${bandlead} honest.  Just like I've needed you."
      
      "Damn, damn, damn it all." ${kalt} puts ${zhis} face in ${zhis} hands.  "I can't…I wish I could say you're wrong, damn you.  But I
    *if bandlead != kalt
      #"$!{bandlead} will need your strength and support."
        "[i]${bandlead}[/i] will need me?  Xthon'damn it all, ${fname}, you're about to flee across a Ward."  ${kalt} shakes ${zhis} head, and something in that ragged movement betrays the anguish just below ${zhis} fury.
        
        "Can any of us keep me alive if a Xaos-storm hits me?" You grasp ${zhim} by the shoulders, hold on when ${zhe} tries to twist away.  "I know you have the strength to keep the band in fighting spirits.  That's something ${bandlead} is going to need a lot of in the hard days ahead."
        
        "I don't care." $!{zhis} face is desolate. "Here's the heart of it.  I
    #"Don't ask me to bring you along and watch you die."
      "You didn't even ask."  ${kalt} throws ${zhis} arms wide, and something in that ragged movement betrays the anguish just below ${zhis} fury.
      
      You almost manage a gasping laugh.  "As if asking you to face a Xaos-storm would have been a sign of love?"
      
      "I reckon asking what I want would have been." $!{zhis} face is desolate. "Swive Xaos, swive whatever else is across that Ward. I
    #"What's swiving wrong with you?"  My own anger flares up in the face of ${zhers}.
      $!{zhe} barks out an incredulous laugh. "What's wrong?  What's wrong is I 
  don't want to live without you, ${fname} bloody ${lname}, and 
  *if k_rel = 4
    it's barely been any time we've had together.  
  *if k_rel = 3
    all I've had of you are a few kisses.
  And now you're running away from me."
      
  "I'm not running from you, love.  I'm running from the Xthon'damned Hegemony.  And I need you to stay 
  *if bandlead != kalt
    here 
  *if bandlead = kalt
    here, take the lead,
  and fight them when I can't."  You swallow against a dry throat. "I'm going to live.  I'm coming back.  This won't be the end for you and me."
  
  ${kalt} stares at you as if desperate to lock every detail in memory… or perhaps ${zhe}'s just contemplating breaking your legs.  Then ${zhe}'s pulling you to ${zhim}, ${zhis} lips fierce against your own. "See that it's not, ${addressu}.  I'm not finished with you yet."
  
  Several minutes later, you rejoin the group alone and look to Yed.
  *goto onourway
*if (((bred_lover >= 4) and (bred_lover != 13)) or (bred_heart = 3)) and ((gamgee != "Breden") and bred_here)
  When you don't look to anyone else, Breden takes a hesitant step toward you, 
  *if (bandlead != "Breden")
    brow furrowed in confusion. "${fname}, you mean to take
    *if (gamgee != "") and (gamgee != "four")
      ${gamgee} and 
    Yed…what about…"
  
    "I want you here, love. Making people believe in the rebellion.  Supporting ${bandlead} as you've supported me."  
  *if (bandlead = "Breden")
    ${xhis} face pained.  "${fname}…
    *if bred_lover > 19
      I'm your ${xspouse}.
    Why have me here, while
    *if (gamgee != "") and (gamgee != "four")
      they go
    *if (gamgee = "") or (gamgee = "four")
      Yed goes
    with you?"
    
    "I want you at the head while I'm gone.  I want a leader who believes in the rebellion and can make others believe in it too."
  You stride forward to ${xhis} side, whisper into ${xhis} ear: "I want to know you're alive."
  
  "Blast it, ${fname}." Tears spill down Breden's 
  *if (bred_heart = 6) or (bred_heart = 7)
    cheeks, and ${xhe} stumbles back. "You don't want me with you. We know that. Don't dress it with sweet words." Still weeping, ${xhe} hurries down the hill away from you.
    
    When you speak again to Yed, your voice sounds hoarse and strange in your own ears.
    *goto onourway
  cheeks. "You think I can just watch you run off to your death?"
  
  "No.  I'll live.  I promise you.  Xaos itself won't keep me from finding you again."  And nothing exists but ${xhis} shaking body in your arms, ${xhis} face 
  *if bred_heart != 3
    and lips and tongue 
  against your own.
  
  Finally, Breden pulls away and wordlessly rejoins the others, ${xhis} face anguished but resigned.  You turn to Yed before you have a chance to change your mind.  
*label onourway
"Let's be on our way."

Just before you pass out of eyeshot, you find yourself pausing. Something is absent, something wrong.  It takes you several moments to realize that you're braced for a final, caustic word from your father.  Xthonos knows he'd have had plenty to say about this mad plan.
*goto the_end

*label kidsharrow
*if (kids > 0)
  *page_break
  You're nearly caught at the confluence of two streams.  Just as you're about to swing your legs over a precipice and slide down tree roots to a pool below, a faint rattle of pebbles sends you scrambling back into the bushes instead. A wide-eyed, bleeding
  *if (el_here and not(elsick))
    Elery
  *if (not(el_here) or elsick) and rad_here
    Radmar
  *if (not(el_here) or elsick) and not(rad_here)
    Earnn
  appears just behind you; you signal frantically to
  *if el_here and not(elsick)
    her
  *if (not(el_here) or elsick)
    him
  to freeze.
  
  Seconds later, nine figures appear on the far side of the gorge, searching for a way down to the valley floor.
  *if theurges > 0
    One of them wears a long black coat and diadem.
  *if theurges = 0
    While most are carrying nets, two of them also have bows and look unlikely to miss at this range.
  At least three are Phalangites.  If they see any movement from the narrow gap, you're surely dead.
  
  Their curt speech carries faintly across the ravine.  "Have a care to catch every child. Alive."
  *if theurges > 0
    Is that a tremor in the Theurge's voice? "They're
  *if theurges = 0
    The captain sounds grim. "The Theurges said they're
  the most important ones to bring back for punishment."
  
  "Harrowing children, kurios?" The flatness of the Phalangite's tone perfectly conveys his disgust. "Was that not why we fought the Halassurqs?"
  
  "These are traitors and criminals, corrupted beyond repair by the devil ${lname}.  Not true children.  Find them all."  
  *if inkids < 50
    
    "There don't seem to be many of them, kurios."
    
    "Maybe the bastards ate them over the winter.  I hear it was a hungry one.  Keep hunting, still."
  He beckons the soldiers on up the stream.
  *fake_choice
    *if (inkids > 2)
      #I'm blind with tears.  I've delivered our children into their hands.  Into the Harrower.
        For a moment, overcome with guilt and nausea, you nearly leap out of hiding, shrieking, [i]Take me instead, damn you.[/i]  But of course they wouldn't, and some part of you remembers that.  
        *if el_here or (radmar < 10)
          You'd just doom
          *if el_here and not(elsick)
            Elery
          *if (not(el_here) or elsick) and rad_here
            Radmar
          *if (not(el_here) or elsick) and not(rad_here)
            Earnn
          to death as well as yourself.
      
        And some part of you still wants badly to live.
    *if (pin > 0) and (inkids > 0)
      #[i]Stay ahead of them, Pin,[/i] I plead mentally.
        You don't think you could live with yourself if
        *if alless > 0
          Alless and
        Pin fell into their hands.
        *if skepreal <=50
          With every second you stay frozen, you pour out your prayers to the Merciful Angels to protect your rebellion's children.
    #Hatred pulses through me.  [i]Children? They won't even hold back from murdering children?[/i]
      *if pin < 0
        Before Chirex, you'd
      *if pin >= 0
        You've 
      only once seen a child Harrowed—a runaway
      *if aristo
        helot
      who cut an Alastor's face trying to escape.  Although Ecclesiast Zebed preached for weeks afterward on reprobation, on the utter corruption that may earn a Harrowing at any age, it still sat ill with everyone in Rim Square.  Everyone knows that killing children is something the murderous Halassurqs do, not the Angelfearing folk of the Hegemony.
      
      It's no surprise that they've declared you all reprobate, that they'd see every man, woman, girl, and boy bled for rebellion.  But the vileness of it still takes your breath away.
    #The numbness is splintering; my hands shake, my heart races, I fight the urge to scream.
      Panic doubles you over.  You stuff your hands into your mouth, as if to keep your sobbing breath from giving you away.  All thoughts scatter save the horrible, inescapable certainty that you've lost. [i]$!{oath}. $!{sweetoath}.[/i]
    #My mind stays empty—as if I fear my thoughts will be as audible as my ragged breath.
      You do your best to calm yourself, to keep your mind focused on survival.
*comment endif

The Phalangite party disappear from view, seeking another way down into the valley. At length
*if el_here and not(elsick)
  Elery
*if (not(el_here) or elsick) and rad_here
  Radmar
*if (not(el_here) or elsick) and not(rad_here)
  Earnn
crawls past you, drops into the open, and keeps fleeing with barely a second's pause.  When no shouts rise or arrows fall, you do the same, though more slowly.
*return

*label t-or-no-t
Traitor or no traitor, ${xhe}'s lost to you now.  You'll never
*if bred_lover = 13
  have the chance to reconcile, never
feel ${xhis} arms around 
*if (bred_lover >= 4) or (bred_heart = 3)
  you again.
*if (bred_lover < 4) and (bred_heart < 3)
  you or truly know ${xhim}.
*return

*label drivenaway
If ${xhe} wasn't a traitor, you've needlessly lost
*if bred_heart = 1
  a good friend and
one of the band's natural leaders.  If only you'd tried harder to get to the bottom of things that last night, rather than just taking ${xhim} prisoner…
*return

*label zvadcounsel
*set votetick +1
*set zvote true
*set runvote +1
*set runeld +1
*if democ > 2
  *set runvote +1
"The Whendward Band has always lived by a simple rule. When they come for you, you run.  You keep three steps ahead of them, and you wait for them to get hungry and uncomfortable enough to declare victory and go home. It would be madness to do anything else."
*return

*label bredcounsel
*set votetick +1
*set bvote true
*set govote +1
*if democ > 2
  *set govote +1
*set goeld +1
"This is a dead end," Breden says, quietly but intently. "That's the first thing we need to understand.  As long as we stay hidden in the wilderness, however many of us survive the summer, our rebellion goes nowhere else.

*if svote
  "$!{zmilady} de Firiac has told us what we need to do if we're going to win.  We need to go back to the helot camps of the Rim—not to convince them to come join us in the woods, but to begin spreading the rebellion to where they are."
*if not(svote)
  "All our lives, runaway helots have flowed in ones and twos from camp to camp, until finally they reached this place.  We need to reverse that stream.  We need to leave here in twos and threes, groups small enough to go to ground and escape when the Alastors get wind of us.  And we need to take the message of this rebellion back out to the helot camps!"
*return

*label kalcounsel
*set votetick +1
*set warvote +1
*if democ > 2
  *set warvote +1
*set wareld +1
*set kvote true
"Well, I reckon everyone knows what I'd say anyway." ${kalt} smiles broadly for a disarming moment; then the humor fades while the teeth remain. 
*if rvote and (followers >= 45)
  "I'm with Radmar.  This is no time to swiving run.  This is our chance to break them, and win."
*if not(rvote) or (followers < 45)
  "But here it is.  If we can't break them here, on our own ground?  If we can't crush these genteel Southriding Phalangites and send the Theurges flying off home like so many scared pigeons…well, then, let's stop pretending this is a rebellion.  
  
  "If we're bandits, we should run.  But I say we're rebels,
  *if followers < 45
    however many or few of us there are,
  and we should live or die as rebels.  Let's choose a place where we can make a stand, and prepare to destroy them there!"
*return

*label simzcounsel
*set votetick +1
*set govote +1
*if democ > 2
  *set govote +1
*set goeld +1
*set svote true
The young noble looks 
*if bvote
  gratefully at Breden.
*if not(bvote)
  around, face drawn. 
"I fear that if we try to stand, we'll be crushed. And if we try to flee, we'll be hunted and scattered beyond recovery.
*if bvote
  I support what Breden Reaper has proposed.  Let us go back to the Rim, before they come to us—and let us fight them not with blades, but with words."
*if not(bvote)
  But if we choose to scatter ourselves, we may both live and grow.
  
  "This band was formed by desperate yeomen, but also by runaway helots flowing in ones and twos from camp to camp until finally they reached this place.  Now is the hour when we can and must reverse that stream—leaving here in twos and threes, in groups small enough to go to ground and escape when the Alastors get wind of us.  And we need to take the message of this rebellion back out to the helot camps!"
*return

*label elcounsel
*set votetick +1
*set runvote +1
*if democ > 2
  *set runvote +1
*set runeld +1
*set evote true
Elery Skinner 
*if (elezvad < 8) or (zv_here)
  leans forward with her customary no-nonsense confidence.  "This 
*if (elezvad > 7) and not(zv_here)
  stares around the circle, unsmiling and harsh-voiced. "If Zvad were still with us, he'd tell you that this
wilderness is good for one damn thing: running and hiding.  We can sting them with arrows, we can wear them down with ambushes…but we can't beat them by standing and fighting.  We know how to run and hide.  We do that until they tire of hunting us and hand the job back to Hector bloody Keriatou."
*return

*label radcounsel
*set votetick +1
*set rvote true
*set warvote +1
*if democ > 2  
  *set warvote +1
*set wareld +1
*if deputy != "Radmar"
  *if rad_mutiny
    Since he returned from his winter mutiny, the hot-tempered youth's stature in the band has only grown.
  *if not(rad_mutiny)
    The hot-tempered youth has a small but devoted following among former helots impressed by his size and battle skill.  
*if nonkids < 45
  It's surprising to see Radmar fall silent, looking visibly torn. "You all know I'd dearly love to make a stand and crush the bastards.  With a few more of us, I believe we could do it, too.  But with only 
  *set d2n_num nonkids
  *gosub d2n
  fighters in the band… well.  Truth is, I don't know which way I'd choose."
  *set warvote -1
  *return
You're not surprised to hear Radmar growl, "The only way to win is to win.  
*if not(kvote)
  If we can't break them here, on our own ground?  If we can't crush these genteel Southriding Phalangites and send the Theurges flying off home like so many scared pigeons…well, then, let's stop pretending this is a rebellion.  
  
  "If we're bandits, we should run.  But I say we're rebels, and we should live or die as rebels.  Let's choose a place where we can make a stand, and prepare to destroy them there!"
*if kvote
  I'm with ${kalt}.  Face them and crush them when they come for us."
*return

*label eclectspoken
*if democ > 1
  A cry rises from several places around the grove: "The Eclect has spoken!"
*return

*label popcalc
*if (govote >= warvote) and (govote >= runvote)
  *set popular 3
*if (warvote >= govote) and (warvote >= runvote)
  *set popular 1
*if (runvote >= govote) and (runvote >= warvote)
  *set popular 2
*if (goeld >= wareld) and (goeld >= runeld)
  *set eldchoice 3
*if (wareld >= goeld) and (wareld >= runeld)
  *set eldchoice 1
*if (runeld >= goeld) and (runeld >= wareld)
  *set eldchoice 2
*return

*label nowyou
Now, with 
*if democ > 1
  the ${moot}
*if democ < 2
  your fellow outlaws
looking to you, you
*return

*label depbetray

In the midst of the hubbub, ${deputy} abruptly stands and—before you can catch ${dephis} arm or ask what ${dephe} thinks ${dephe}'s doing—stalks out of the 
*if democ < 2
  tent.
*if democ > 1
  grove.
$!{dephe} returns a moment later, and your heart drums against your ribs when you see a Theurge-forged spear in ${dephis} hand. "Forgive me, ${milady}," your deputy
*set warvote +5
*set pleksecret false
*return

*label wrongstrat
*if democ < 2
  When you head out and announce the decision to the rest of the band, it becomes even clearer that
  *if eclect
    (notwithstanding your word as Eclect)
  it's not a popular option.
*return

*label nextyou

Next, you
*return

*label bandpref
They recognize that a clear majority of your outlaws would prefer to
*if popular = 1
  stand and fight,
*if popular = 2
  evade the Archon's forces,
*if popular = 3
  flee back to the Rim,
*return

*label followband
however, and conclude that the wisest course is to adopt that strategy rather than an unpopular and divisive one that might paralyze the band.
*set strategy popular
*return

*label whocares
but they're confident that the band can be swayed by a clear decision from the circle of elders.
*set strategy eldchoice
*return

*label okmindch
*if democ = 0
  Because the band is accustomed to looking to you as sole leader (rather than to a moot or circle of elders), they grudgingly accept your last-minute change of mind.
*if eclect
  It does somewhat undermine your standing as Eclect, confirming that the Angels don't always guide you on important matters.  Many devout band members find this unsettling. 
  *set morale -5

*return

*label protests
The band greets your abrupt change of heart with a chorus of protest.  Despite your best efforts to
*if eclect
  invoke Angelic authority and
calm the situation, a mob is soon chanting
*if popular = 1
  "Stand and fight!"
*if popular = 2
  "Keep to the woods!"
*if popular = 3
  "Back to the Rim!"
in furious unison.

Far from resolving the divisions within the band, you have worsened them while weakening your own authority.  
*set morale -10
*return

*label radmurder
"You'll choose this coward's course even when 
*if plekspear
  we know we could break the Plektoi? 
*if not(plekspear)
  the band is ready to stand and fight?
[i]$!{xhe}'s a traitor[/i], damn it all—taking the only way ${xhe} knows to steal our victory!"

"Rad," Breden begins, ${xhis} voice unruffled and soothing.
          
Only eight yards or so separate the two of them.  When Radmar roars and launches himself at Breden, there's no time for the latter to flee—only to stumble ineffectually away. But 
*if el_here
  Elery is between them, knife in hand, 
  *set el_here false
  *set spcas "Elery"
  *set elery -50
  *if hor_guard = "Elery"
    *set hor_guard "Alira"
  *goto deadlunge
*elseif simz_here and (s_rel < 9)
  ${simon} de Firiac is between them, sword already drawn,
  *set simz_here false
  *set spcas simon
  *set s_rel -50
  *if hor_guard = simon
    *set hor_guard "Alira"
  *goto deadlunge
*else
  Ciels is between them, knife in hand,
  *set spcas "Ciels"
  *goto deadlunge
*label deadlunge
lunging toward Radmar just when everyone else is scrambling 
*if not(plekspear)
  away.
*if plekspear
  away from that terrible spear.

When the crowd clears, Breden is on ${xhis} back, wide-eyed but unharmed, Radmar is on his knees, clutching at the gash in his throat with blood-soaked fingers, and ${spcas} is unmoving in the dust, laid open from shoulder 
*if plekspear
  to hip by the Plektoi spear.
*if not(plekspear)
  to heart by Radmar's axe.
*if poric > 0
  Poric gives a long, wordless shriek and drops to his knees beside Radmar just as the big man topples, face down, next to ${spcas}.
*set rad_here false
*set radmar -30
*set morale -50
*if hor_guard = "Radmar"
  *set hor_guard "Alira"
*page_break
You're not sure the band will ever recover from watching Radmar and ${spcas} kill each other.  For days afterwards, the meal circles are silent. On your gloomy traverses through the woods, people speak only when they must.
*if kids > 2
  The band's children, by contrast, burst into frantic tears at the least provocation.
Many of the bandits disappear on long deer hunts until it feels as if the band is
*if winterfail > 0
  again
dissolving.  The fraught debate over how to survive the summer was straining the ties between you even before it descended to murder.
          
Breden in particular is 
*if (spcas = "Elery") or ((spcas = "Ciels") and (ciels > 9))
  devastated
  *goto bydeath
*else
  shaken
  *goto bydeath
*label bydeath
by ${spcas}'s sacrifice.  You repeatedly find ${xhim} lagging behind the rest of the band, tears streaming down ${xhis} face, and ${xhe}'s even more reticent than the others.
*if spcas = "Ciels"
  *set c_rel -50
*if ((bred_lover >= 4) and (bred_lover != 13)) or (bred_heart = 3)
  Every effort to comfort ${xhim} when the two of you are alone only seems to drive ${xhim} further behind ${xhis} shell.

*return

*label simonflee
*set s_rel +20
*set simz_here false
When it becomes clear what you've done, ${simon} de Firiac vanishes.  No farewells, none of the recriminations or hard choices you'd been braced for; ${zhe} simply flees the band.

As soon you realize ${zhe}'s gone, you send Ciels after ${zhim}. $!{he} returns empty-handed a day later, looking rueful and impressed.  "Well, that's confirmed the young ${zkuria} has woodcraft equal to mine.  Whichever way ${zhe} passed, ${zhe}'s hidden ${zhis} tracks like a master."
        
You shake your head in frustration.  "Put the word about, then.  If anyone comes across ${zhim}…"
*choice
  #"…tell ${zhim} to come back to us.  $!{zhe} was always welcome here."
    *return
  #"…find out what ${zhe} intends to do, and make sure ${zhe} isn't causing us any trouble."
    *return
  #"…kill ${zhim} on sight."
    *return

*label simzfree
When you release ${zhim} from ${zhis} bonds, ${simon} turns to confront you. 
*if s_rel = 19
  $!{zhis} voice is shaking with anger and contempt.  "When I came here, ${lname}…I thought you were the hope of Shayard.  I thought you would unite us against the Thaumatarch."
  
  "I don't care about 'uniting,' ${zkuria}," you retort. "I'm here to break the power of the Hegemony.  Those who don't have the stomach for what's necessary can go their own way when they're of no further use.  I'm not going to hold back in the name of unity."
  
  "You'll destroy Shayard, and the Thaumatarch will still rule over the wreckage." ${simon} folds ${zhis} arms. "I'll show you another way is possible, ${kuria} ${lname}.  One day, if you live long enough, you'll see."
  *set simz_here false
  *page_break
  *return
"One last time, ${kuria} ${lname}: don't cast me away.  I came to fight, not to hide."  $!{zhe} is shaking with barely contained anger. "If you don't want my father's ransom,
*if s_rel = 11
  or to kill me as you'd threatened,
then why would you send me away now?"
*choice
  *if (helot) #"Because this rebellion is against you and your kind, no less than the Thaumatarchy."
    *goto rebelnoble
  *if (aristo) #"Because this rebellion is against the aristocracy, no less than the Thaumatarchy."
    *label rebelnoble
    *set cred_a -10
    *set cred_h +20
    *set cred_y +20
    A mostly-approving rumble rises from the small crowd of outlaws who have gathered to watch the release.  "You'll fail," ${simon} pleads, hoarse and incredulous.  "And you don't have to.  Not all nobles are 
    *label theenemy
    the enemy!  
    *if aristo
      You of all people know that.
    Together, our strength…"
    
    *if rad_here
      Radmar interrupts loudly, "Our?  We've got plenty of stout arms already, ${zmilady}. And there's more out there in the world—a lot more of us than you, begging your noble pardon.  What does your strength add to ours?"
    
      To ${zhis} credit, ${simon} doesn't pretend that ${zhis} blademastery is indispensable.  "I'm just one more pair of arms, true.  But back beyond the Rim, there are others like me who could be convinced to bring so much more.  Soldierly experience, gold, land, learning, relations…"
    
      Radmar spits onto the forest floor.  "Oh, that strength.  We know all about that, ${zmilady}. That's what's kept us quiet through the whipping, the hunger months, the come-with-me-behind-the-stable-now, the children sold off after harvest."  He stalks up to ${simon}, eyes dark and violent. "We're not quiet, now.  We know our own strength, now.  Maybe we'll kill the Karagonds, maybe they'll kill us.  But either way, it'll be us that does it—and us deciding what comes after."
      
    "On your way, ${zmilady}," you say brusquely.  
    *label simwhirl
    ${simon} stares at you for a moment longer, then whirls and runs away.
    *set s_rel 9
    *set simz_here false
    *page_break
    *return
  #"Because I can't trust you."
    "This is how the Kryptasts come, ${zkuria}. Smiling, swearing vows, full of fire and promise."  You keep talking over ${zhis} rising protest.  "No one here knows you.  No one can vouch for you." 
    
    "But…so, wh…you, you won't take help from anyone who wasn't raised within ten miles of Rim Bloody Square?"  ${simon}'s voice cracks despite ${zhis} audible attempt to retain control.
    
    "Someone who arrives like you did?  I'd think twice. Someone who then tries to convince me to keep ${zhim} on after I've threatened ${zhim}, held ${zhim} hostage, took ${zhis} precious sword, and treated ${zhis} honor like dirt?"  You shake your head slowly.  "You fail the test, de Firiac."
    
    *goto simwhirl
  #"I told you: I won't ask my band to fight alongside their oppressor."
    *set cred_a -5
    *set cred_h +10
    *set cred_y +10
    ${simon}'s face darkens with outrage.  "Damn it all, ${lname}—I'm not
    *goto theenemy
  #"Because you're a reckless child."
    ${simon} staggers as if stabbed.  "You?
    *if helot
      You truly think…."
    *if aristo
      You, of all people?"
    
    "The band doesn't need impulsive dreamers," you say coldly.  "What did you think we'd make of you—arriving with two helots, a horse, and the clothes on your back? That we'd admire your bravery?  Our chevalier arrived to the rescue?  Here's my thought: [i]That's the last person I want at my shoulder.[/i]  Who knows what nonsense you'll think of when the Karagonds are actually on us?  Come back when you've learned the difference between courage and foolery, ${zkuria}."
    
    ${simon} turns with brittle self-control and strides out into the brush without looking back.
    *set s_rel 9
    *set simz_here false
    *page_break
    *return
  #"That's a fair question, ${zmilady} de Firiac."  Perhaps you should reconsider.
    The ${zgirl}'s been through enough
    *if helot
      to demonstrate ${zhis} loyalty, 
    *if aristo
      to satisfy any helot, 
    surely.  Sensing the direction of your thought, ${simon} flings ${zhim}self to ${zhis} knees before you. "$!{kuria}—I understand it all.  Your concern about Kryptasts, your desire to not just bring
    *if aristo
      another
    *if helot
      a
    noble so quickly into the band.  Even the ransom—Angels know that feeding the band is challenge enough to call for desperate measures.  But accept me now!  I'm a blade, and I belong with the band."

    ${deputy} speaks up dubiously.  "You're not just another pair of hands to swing a weapon.  You'd be a target for every Kryptast and Theurge in the archonty.  And if they kill you, they'll say it was us rebels who did it, and win more noble support in your name."  

    "Let them hunt me."  ${simon}'s eyes blaze up at you.  "They'll find me no easy quarry.  But in life or death, this is where I'd serve."
    *choice
      #$!{zhe} can stay.
        *set s_rel -3
        "You pass the test, 
        *if helot or (kuria != "Captain")
          ${zkuria}
        de Firiac," you declare.  "If all this hasn't caused you to lose heart, or to take the chance of freedom when it's offered,
        *if (aristo) and (kuria = "Captain")
          who here could force you to leave, so much against your will?"

          "Captain…"  Despite ${zhim}self, the young blademaster looks as if ${zhe} can hardly believe your words.

          *set cred_h +10
          You cut ${zhim} off.  "Which reminds me.  We don't do noble titles here.  I don't want to hear anyone calling you ${zkuria}, or ${zmilady}, or any title you haven't earned by fighting the Thaumatarch.  Understood?"  ${simon} gives a fervent nod; you hope ${zhis} humility will mollify those outlaws not satisfied by ${zhis} humiliation. "Then 
        welcome to the band."

        The murmur that ripples through the other outlaws is hard to read—not obviously disapproving, nor pleased.  ${simon} leaps to ${zhis} feet, beaming fiercely.  "Oh, ${kuria}—thank you.  Thanks upon thanks.  I vow to you, on my life and honor, you won't regret this!"
        *if s_sword = 2
          *choice
            #I give ${simon} back ${zhis} family sword.
              "You'll make better use of this than I."  You unbelt the fine scabbard and offer it back to ${zhim}—not without a tinge of reluctance.

              The last of ${simon}'s anger seems to melt away.  "$!{milady}…my liege."  $!{zhe} reverently accepts the blade from you, draws it, and raises it in salute.  "I wield it at your command, in service to you and to our cause, until my life's end."
              *set s_sword 1
              *page_break
              *return
            #I'll keep the sword until such time as we need ${zhim} to fight for us.
              *goto swordmine
            #$!{zhis} sword?  It's mine.
              *label swordmine
              You note approvingly that ${simon}'s eyes don't even flicker once toward the blade scabbarded at your waist.  If ${zhe} has any expectation of regaining his family heirloom, ${zhe} doesn't let it show.
              
              *return
        *return
      #No, ${deputy}'s right.  We don't need another target.
        "If you'd serve, make your way back to the Rim and try to kindle rebellion among
        *if aristo
          the other Houses.  There's as much danger to you there…but less to the rest of us."
        *if helot
          your own kind, ${zmilady}.  You'll put us less at risk that way."
        
        *goto simwhirl
*label horbody
*choice
  #I bury ${hosthem} discreetly in the deep woods and tell the band to keep it a secret.
    *if hosthem = "them"
      Your hostages soon share 
    *if hosthem != "them"
      You leave your former hostage in
    a deep and anonymous grave.  Not in a thousand years would anyone find ${hosthem}—not this far out in the wilderness.
          
    *set horhostage false
    *return
  #I want the whole Rim to know about it.
    You have
    *if hosthem = "them"
      your noble hostages' bodies
    *if ((s_rel > 9) and (hosthem = zhim))
      ${simon} de Firiac's body
    *if (hosthem = "him") and (s_rel <= 9)
      Horion ${delelle}'s body
    dumped at the crossroads outside Rim Square, with a scrap of paper identifying ${hosthem}.
    *if horhostage and (delelle = "de Lelle")
          
      A week later, ${deputy} finds you in the woods during a traverse between camps.  $!{dephe} is wide-eyed and 
      *if deputy != kalt
        sweating profusely. 
      *if deputy = kalt
        beaming.
      "$!{kuria}… word just came back from the Rim.  That Horion gave us a false family name.  He was a bloody Leilatou—cousin to the bloody Archon!"
            
      You blink at deputy, trying to take in the astonishing claim.  "Is this a joke?"
            
      "Far from it.  The whole Rim is in an uproar, and they say the Archon and the Keriatou have both sworn to avenge Horion before the summer is out.  Conte Phrygia is having more Phalangites flown in by Theurges." Your deputy
      *if deputy != kalt
        looks around anxiously.
      *if deputy = kalt
        laughs and claps ${zhis} hands. 
      "We've well and truly done it now, ${kuria} ${lname}."
            
      "Let them come," you retort, with a bravado you only half feel.  "A few more won't make a difference this summer.  But striking at the Archon's cousin…that will spread word of our rebellion throughout the whole Hegemony."
      *page_break
      *set delelle "Leilatou"
    *set anarchy +7
    *set cred_a -30
    *set cred_p -20
    *if aristo
      *set cred_h +20
      *set cred_y +20
    *set notoriety +40
    *set horhostage false
    *return

*label howelsespend
*if wealth > 0

  How else do you want to spend your 
  *set d2n_num wealth
  *gosub d2n
  remaining drachems?
*return

*label robinhood
*if robin = 1
  "Aye, ${addressu},"  ${deputy} agrees.  "They'll think better of our rebellion for it, however things fare when the Phalangites arrive."
*if robin = 0
  "Depending on how the battle goes, we may not need drachems," ${deputy} notes cheerily. "May as well leave them with those who need them most."
  *set robin 1

*return

*label troopscheck
*if not(harrytick)
  By the end of the week,
*if harrytick
  After a fortnight of harrying the Archon's force,
*if (((aristroops > 0) or aristofail) and ((alastroops > 0) or alastfail)) and ((((priestroops > 0) or (cred_p >= 200)) or priestfail) and (((yeotroops > 0) or (cred_y >= 170)) or yeofail))
  *if slowedthem
    a line of graves and injured troops mark their backtrail;
    *return
  you've slowed your enemy's advance and inflicted some damage,
  *set slowedthem true
  *return
*if (aristroops < 1) and not(aristofail)
  the noble Houses who came hunting you have been broken, and all save a handful of young nobles have returned to the Rim in disarray;
  *set theirmorale -80
  *set aristofail true
  *set aristroops 0
*if (alastroops < 1) and not(alastfail)
  the Alastors have been shattered;
  *set theirmorale -60
  *set alastfail true  
  *set alastroops 0
*if ((priestroops < 1) and (cred_p < 200)) and not(priestfail)
  the devout commoners who followed the Ecclesiasts have fled back to their towns;
  *set theirmorale -20
  *set priestfail true
  *set priestroops 0
*if ((yeotroops < 1) and (cred_y < 170)) and not(yeofail)
  the yeomen stalking the woods have all fallen to your arrows;
  *set theirmorale -(170-cred_y)
  *set yeofail true
  *set yeotroops 0
*return

*label phallocate
*set phaltick +1
*if phaltick = 1
  *set phal2 -phalcas
*if phaltick = 2
  *set phal3 -phalcas
*if phaltick = 3
  *set phal4 -phalcas
*if phaltick = 4
  *set phal5 -phalcas
*set theirmorale -phalcas
*set phalcas 0

*return

*label cascheck
*set followers -cas
*set nonkids -cas
*set dead +cas
*if inwoods > 0
  *set inwoods -cas
  *set inadults -cas
*set rangers -cas
*set morale -cas
*set cas 0
*if followers <= 0
  *set followers 1 
*if nonkids <= 0
  *set followers 1 
*if inwoods < 0
  *set inwoods 1 
*if inadults < 0
  *set inadults 1 
*if inkids < 0
  *set inkids 1 
*return

*label their0check
*if (aristroops < 1)
  *set aristroops 0
*if (alastroops < 1)
  *set alastroops 0
*if (priestroops < 1)
  *set priestroops 0
*if (yeotroops < 1)
  *set yeotroops 0
*if (merchtroops < 1)
  *set merchtroops 0
*if (phal1 < 1)
  *set phal1 0
*if (phal2 < 1)
  *set phal2 0
*if (phal3 < 1)
  *set phal3 0
*if (phal4 < 1)
  *set phal4 0
*if (phal5 < 1)
  *set phal5 0
*return

*label consc0
You grit your teeth but feel the world slipping away from you.  Within moments you will be unconscious.
*return

*label theuthing
Around midmorning the next day, as you'd expected, a Theurge flies past to exchange the day's news with the northern flanking force.
*if blood > 0
  *choice
    #I cut my hand.
      *goto cuthand2
    #I pull out a blood phial.
      *set blood -1
      *set usedblood +1
      *goto blph
You take a deep breath and cut your hand.
*label cuthand2
*set cut2 true
*set consc -1
*if consc < 1
  *gosub consc0

*label blph
Reaching out with your mind, you ignite a dry pine on the ridgetop.  From your hiding place in the underbrush, you can see the enemy mage immediately veer toward you.  He tosses a black speck upward as he changes course. A minute later, far above you, it expands into a blood-red fireball, a signal likely visible from forty miles away.

Just uphill from you, your bandits scramble conspicuously into denser forest.  The Theurge flies cautiously in their direction—clearly wary of a trap but not wanting to lose them.  You wait, blood thundering in your ears, until he's thirty yards or so past you.
*return

*label martyr1
*page_break
As you half-dive, half-scramble down a deep crevice, a vitriolic fireball fills the air above you with white-blue, sulfurous light.  Even behind some shelter it leaves your hood and kyrtle smoldering and all your exposed skin scorched.  When the light recedes, most of the concealing undergrowth has been blasted away and the rest is afire.  You slither into the gap under a boulder as best you can and freeze, trying to stop yourself from whimpering with agony and dread.
            
When you hear another fireburst a moment later and two long, terrible shrieks, all you can feel is the numb conviction that the Theurge has disposed of your outlaws before coming for you.  But after several minutes' silence, you hear Earnn's shrill voice: "$!{addressu}? $!{addressu} ${fname}?  Are…are you alive?"  Sobs of desperate hope begin to shake you as you claw your way out of hiding.  

${martyr}'s lean body is burned red from head to toe; at such close range, even the woolen clothes you were all wearing provided little protection.  But ${mhis} dagger is buried in the eye of the Theurge at ${mhis} feet. "$!{addressu}?" ${mhe} rasps blindly as you limp closer.

*return           

*label martyr2
You want to take ${mhis} hand, offer some measure of comfort, but the thought of touching that charred, raw skin is unbearable.

"Thank…Angels."  A moment later, ${mhe} says, faint-voiced, "Water?"  But by the time you bring a skin to ${mhis} lips, ${mhe}'s unresponsive, unbreathing.
            
"$!{mhe}… ${mhe} saw that the Theurge was flying low to find you, and took ${mhis} chance."  Earnn trembles all over as he explains. "And even when the Theurge hit, ${mhe} didn't stop."
            
"We need to get to cover," you say, voice cracking.  You can't think about ${martyr} now. "There'll be a second one coming.  And…we know now I can't beat them."
*set theurges -1
*set theirmorale -90
*set morale -10
*return

*label martyrtheu
*if theuknown < 5
  
  "Sweet
  *if religion < 20
    Angels,
  *if religion > 19
    kenon,
  ${addressu}…what were you even trying to do?  What did you do?"  Earnn sounds on the verge of panic.
  
  *gosub wisexplain
  
  "Xthonos's Blood. You're
  *if wisard = "wisard"
    a,
  a ${wisard}."  The young ranger glances at the dead mage, then back at ${martyr}, and shudders. "Learn how it works, then, ${addressu}.  Learn faster."
  *set theuknown 5
*return

*label postmartyr
*page_break
Though still shaken by ${martyr}'s sacrifice and your own near-death, you force yourself to stick to the plan.  Taking down a supply train will stall the Phalangites' advance and shake their morale far more than a single Theurge's death.

*return

*label martyrfail

Watching from a bluff above the Phalangite camp that night, you see no disturbance of any kind along the perimeter, long after the attempt must have started. Almost, you dare to hope that your martyrs will succeed.  

Then the first alarmed voices rise from the center of the camp, and you see first a few guards, then many more running near the leaders' tents. Only moments later, two Theurges emerge from their shelter…and at least eight of the running forms become torches in the darkness.

*set phal1 -6
*set theirmorale -10
*set morale -5
*set cas +2
*gosub cascheck
*return

*label martyrdin

Two hours later, a din suddenly erupts in the middle of the camp.  Guards run everywhere, torches blaze to life.  You keep waiting for a Theurge to fly out—but none emerges from the central cluster of tents.  The din has become hysterical.  Your followers glance at each other, hardly daring to believe that ${martyr} might have succeeded.

Then three pikes rise above the growing Phalangite crowd, who shriek their hatred louder than ever.  The limbs and head at the top of the poles look to be battered beyond recognition, even had you been closer; but it can only be one person.  Several of your fellow outlaws groan and begin to cry.
                    
"Weep, ${addressc}."  Tears are streaming down your own cheeks.  "Weep for ${martyr}
*set theirmorale -(theurges*90)
*set morale +45
*set cas 1
*gosub cascheck
*return

*label theresaglen
As Breden presses close against you, ${xhe} fills your nose with heady scents: woodsmoke, crushed grass and wildflowers.  "There's a quiet glen upslope," ${xhe} whispers. "No one will disturb us there."

*return

*label failbred
[i]I failed you.[/i] Your fingernails dig into your face as you rock back and forth; it doesn't feel like your skin, your nails, your anguish.  You can't collapse now, not with the Phalangites
*if lostem
  still haunting the woods.
*if not(lostem)
  on your heels.
*return

*label harrycas
*set aristroops -13
*set aristroops -round(rangers/15)
*set alastroops -11
*set alastroops -round(rangers/20)
*set priestroops -24
*set priestroops -round(rangers/10)
*if (strategy = 1) and (popular != 10)
  *set aristroops -13
  *set aristroops -round(rangers/15)
  *set alastroops -11
  *set alastroops -round(rangers/20)
  *set priestroops -24
  *set priestroops -round(rangers/10)
*if korszata > 0
  *set aristroops -8
  *set alastroops -8
*if el_here
  *set aristroops -8
  *set alastroops -4
  *set yeotroops -4
*if rad_here and (rad_flank < 1)
  *set aristroops -5
*if zv_here and (zv_flank < 1)
  *set alastroops -3
  *set aristroops -3
*if kal_here
  *set aristroops -4
*if simz_here and ((simz_flank < 1) and (s_rel < 9))
  *set alastroops -7
*gosub their0check
*if ((priestroops < 1) and (cred_p < 200)) and not(priestfail)
  *if harrytick
    The Ecclesiasts and their commoners prove particularly vulnerable to your snares.
  By the end of the week, their few survivors have crept off back to the Rim in shame.
  *set theirmorale -20
  *set priestfail true
*set cas +round(rangers/13)
*return

*label alltcheck
*set alltroops ((phalangites+aristroops)+((merchtroops+priestroops)+(yeotroops+alastroops)))
*set allmain (((phal1+aristroops)+(priestroops+alastroops))+round(yeotroops/3))
*return

*label armscheck
*set arms -cas
*if arms < 0
  *set arms 4
*return

*label bredbroke  
$!{zhis} eyes widen, and ${zhe} glances toward Breden.  "Please, ${addressu}, do not shame…"

"Breden and I parted ways some time ago, ${zmilady}.  There's no dishonor here."

${simon}'s face is an extraordinary blend of joy and guilt.
*return                  

*label bredtrial
*if bred_here
  *if wonfight = 10
    With the rebellion triumphant and your pursuers scattered, in 
  *if wonfight != 10
    In
  the morning you
  *if democ > 1
    call ${a_moot}
  *if democ = 1
    sit with
    *if (deputy != "Breden") and (deputy != "Earnn")
      ${deputy} and
    the surviving rebel "elders"
  *if democ = 0
    *if (deputy != "Breden") and (deputy != "Earnn")
      and ${deputy}
    sit down with Breden, 
    *if rescuer > 0
      Old Vorne,
    *if rescuer = 0
      Gaved,
    and Earnn 
  to investigate the poisoning of the band.  
  *if democ > 0
    An anxious-looking Breden, 
    *if rescuer > 0
      Old Vorne,
    *if rescuer = 0
      Gaved,
    and Earnn share their accounts of that wretched night.
  They'd built the fire in a small cave and one of them had always been tending it, so none but them could have had access to the cookpot.  They also all swear that none of the three of them could have poisoned the pot without the others seeing it.
  
  "But the food we cooked, ${addressu}?" Earnn ventures, blinking rapidly. "Well…we'd cut up a heap of herbs and grasses on a stone outside, and then Breden and I went in to start the fire and 
  *if rescuer > 0
    Vorne
  *if rescuer = 0
    Gaved
  went down to the lake for water. I reckon there was a good five minutes before we had the fire going, when Breden and I wouldn't have seen anyone passing by.  Anyone could have added to the herbs without us seeing.  I'm sorry.  We…we'd thought there was no enemy in the camp with us."
  
  "That's a carelessness we won't repeat," you say, biting back a harsher response.  
  
  "As you say, ${bfname}." Breden gives a fervent nod.  "We've learned our lesson, and I'm sure the rest of the band as well.  All of us will be hunting for any sign of whoever tried to kill us.  But for now…I can't see that we've any good sign to follow."
  
  You 
  *if (bred_lover >= 4) or (bred_heart = 3)
    try to 
  ignore the pleading note in ${xhis} voice as you weigh the likelihood of treachery.  Earnn
  *if rescuer > 0
    and Vorne had both
  turned bandit well before you arrived; if 
  *if rescuer > 0
    they were traitors, they
  *if rescuer = 0
    he were a traitor, he
  would have been sent to the Whendward Band with no way of knowing that a rebellion was in the offing.
  *if rescuer = 0
    Gaved has been simple-minded since a bad beating when he was six; it's beyond belief that he could have been knowingly induced to betray you.
  Of them all, only Breden could possibly have been the traitor in Rim Square. 
  
  In this case, it seems clear, there's no way to attribute blame to just one of them.
  *choice
    #So they'll share it.  All three need to die for letting us be poisoned.
      *set ruth %+20
      Anything less, and you'd only be inviting another traitor to take advantage of the same weakness.
      *if (bred_lover >= 4) or (bred_heart = 3)
        You can't spare Breden just because ${xhe}'s your 
        *if bred_lover < 20
          *if bred_lover = 13
            former
          lover.
        *if bred_lover >= 20
          ${xspouse}.
      One of them almost certainly betrayed you; perhaps two or three working in concert.  Even though you can't really bring yourself to believe in
      *if rescuer = 0
        Gaved's or
        *set ruth %+10
      Earnn's guilt, the only responsible act you can take is to burn out any risk to your rebellion.
      
      *if (democ = 0) or (bred_lead < 10)
        *set earnndead true
        You don't give Breden any chance to talk you (or the rest of the band) out of it.  A quick word in
        *if rad_here
          Radmar's
        *if not(rad_here)
          Alira's
        ear, and all three of the suspects are beaten down, bound, and gagged before they can utter another word.  No one else dares to gainsay you.  
        Your authority 
        *if democ = 0
          as sole leader of the rebellion 
        is at its strongest in the wake of your 
        *if wonfight = 10
          unexpected victory.
        *if wonfight != 10
          leading the band to survival.
        *if bred_lead < 10
          Whatever influence Breden has built up over the other rebels isn't enough to save ${xhim}, with the memories of the poisoning still so vivid.
        
        The sight of Breden's thrashing as ${xhe}'s dragged away, and the muffled screams through ${xhis} gag…
        *gosub breddead
        *set bred_trust 21
        *if el_here
          *set e_rel -10
        *fake_choice
          *if (bred_lover >= 4) or (bred_heart = 3)
            #Almost kill me.
              A haze obscures your vision and the blood pounds in your ears—but not loudly enough to keep the screams out.  When they finally, blessedly stop, it's several minutes before you realize you're on your knees, clutching your head in your hands.  The rebels around you eye you with a mix of sympathy and concern.
              
              "It needed doing," you rasp, struggling to stand.  Your eyes burn with unshed tears. "The price of treachery.  Let everyone know it.  And know that no one—no one—is exempt."
              *page_break
          #Haunt me for weeks.
            Most of the other rebels quickly shake off any gloom after the executions of the supposed poisoners.  You can't escape the memories, though, however hard and often you try.  Unless you're focused specifically on some pressing task, images of Breden and the others seep back into your mind.  And with the Archon's troops no longer at your heels, the tasks have become less pressing, the diversions fewer.
          #Don't affect me at all.
          #Are remarkably satisfying.
            At last—at long bloody last—you've sent ${xhim} to the traitor's grave where ${xhe} belongs.  Now you can truly glory in your victory over the Hegemony.  [i]We've rooted out everything they had to throw at us.[/i]
        *goto investigover
      *if (democ > 0) and (bred_lead >= 10)
        But when you announce your intent, the
        *if democ = 1
          council of elders
        *if democ > 1
          ${moot}
        loudly objects.  Breden has won enough loyalty and affection that they won't see ${xhim} killed without proof of wrongdoing.  "$!{xhe} has Earnn vouching for ${xhis} every move, ${addressu}, which is more than any of the rest of us can say," one older bandit growls.  "There's not enough cause to kill someone who's spoken so fair against the Hegemony.  
        
        You argue, but not for long.  "Just let it be known that from now on, whoever's cooking is responsible for any poison that finds its way into the food."
        
        Breden finds you on the trail later that day, as you press on into the woods. $!{xhis} voice is flat, ${xhis} eyes expressionless.  "You would have had me killed."
        
        "Aye."
        *if (bred_lover >= 4) or (bred_heart = 3)
          It's hard to get the words out; you try to make them as sharp as possible.
        *if (bred_lover < 4) and (bred_heart != 3)
          You shoot back a wary gaze.
        "The band was poisoned, and you're responsible.  Whether or not you were the one who put the leaves in the food."
        
        $!{xhe} says nothing more, just gives one brief nod and falls back.
        *if (bred_lover >= 4)
          But that night, and through all the nights that follow, ${xhe} comes nowhere near your bed.
        *if (bred_heart = 3)
          But ${xhe} doesn't sit with you at dinner, or find you afterwards for talk.
        *page_break
        *set bred_heart 20
      *goto investigover
    #We'll spare them this once.  If anything like this happens again, the cooks will pay with their lives.
      *label sparethecooks
      *if rad_here
        Only Radmar greets your verdict with furious denial.
      *if kal_here
        ${kalt}'s lips narrow when ${zhe} hears the news, but ${zhe} says nothing against it.
      The rest of the band are willing to be swayed by you; 
      *if bred_lead >= 10
        Breden is well-loved in the band, and
      everyone is still flush with the joy of victory.
      *goto investigover
    #We'll spare them, and leave any future problems to our future judgment.
      *goto sparethecooks
*label investigover
*if deputy = ""
  With Breden slain, you'll need to choose another deputy.
  *gosub pickadeputy
  As you trek onward, you try to make ${deputy} aware of all the strategic choices that led up to your victory in the woods.  Some of them were known to everyone in the band, some only to you and your previous deputies.
  
*return

*label xaosprep
*choice
  *if (deputy != "") and (fleelead != deputy)
    #My deputy ${deputy}, of course.
      *set bandlead deputy
      *return
  *if (deputy != "Zvad") and (zv_here)
    #Zvad.
      *set bandlead "Zvad"
      *return
  *if (deputy != "Breden") and (bred_here)
    #Breden.
      *set bandlead "Breden"
      *return
  *if (deputy != "Elery") and (el_here)
    #Elery.
      *set bandlead "Elery"
      *return
  *if (deputy != "Radmar") and (rad_here)
    #Radmar.
      *if radmar > 9
        The bastard may have murdered Breden…but the rebellion may need all his brutality in the months to come.
      *set bandlead "Radmar"
      *return
  *if (deputy != kalt) and (kal_here)
    #${kalt}.
      *set bandlead kalt
      *return
  *if ((deputy != simon) and (simz_here))
    #${simon} de Firiac.
      *set bandlead simon
      *return
  *if (korszata > 0)
    #Korszata.
      *set bandlead "Korszata"
      *return
  *if (deputy != "Alira")
    #Alira.
      *set bandlead "Alira"
      *return
  *if (diakon > 13)
    #Diakon Edwer.
      *set bandlead "Diakon Edwer"
      *return
  *if etthena > 0
    #Etthena the Disbeliever.
      *set bandlead "Etthena"
      *return
  *if bethune > 0
    #Bethune.
      *set bandlead "Bethune"
      *return
  *if c_rel > 0
    #Ciels.
      *set bandlead "Ciels"
      *return
  *if yebben > 0
    #Yebben.
      *set bandlead "Yebben"
      *return
  *if not(earnndead)
    #Young Earnn.
      *set bandlead "Earnn"
      *if deputy = ""
        *set deputy "Earnn"
      *return
  *if (earnndead)
    #Whoever they choose for themselves.
      You don't want to be responsible for choosing from the survivors, none of whom are without their flaws.  Let the band choose for themselves, in your absence.
      
      *return

*label puke
$!{xhe}'s crouched over 
*if el_here
  Elery,
  *set elsick true
*if not(el_here) and (c_rel > 0)
  Ciels,
*if not(el_here) and (c_rel < 1)
  young Pereth,
who looks barely conscious and is covered in half-digested pottage.  
*return

*label healingem
you use your developing skills as a Theurgic healer keeping several band members alive and further boosting morale. "Angels bless you, ${addressu}," a young outlaw weeps feebly after you've closed his wound.  His eyes had been clouded with pain and shock. Now they shine up at you. "My life is yours, now and always."
*set morale +20
*set followers +6
*set nonkids +6
*set inadults +6
*set inwoods +6
    
*return

*label theucavepl
*set plektoi -1
*set cavein +1
Somehow you manage to focus beyond the adamantine claws and teeth clashing just above you—up toward the cavern ceiling, the mountain stone eroded and split by water.  You can feel how much it wants to fall, striving downward less violently but no less implacably than the Plektos.  Spreading your arms, you welcome it down.

There's a crack like thunder, drowning out even the hound's snarls.  You feel an instant of resistance, another mind trying to undo your work…and then it's snuffed out, along with all the light around you.  The roar of the collapse is deafening, the blast of air strong as a punch to the chest. 
*return

*label theucavepl2
*set plektoi -1
*if cavein > 0
  Once again, when the beast charges into sight, you reach up to the ceiling and welcome it down.
  *if cavein = 1
    Again, you feel a moment's mental resistance against your Change; again, it's too late.  You couldn't control the collapse if you tried, and nor can the Theurge outside the cave entrance.  The Plektos vanishes in a hail of stone, just before a blow to your own head drops you into blackness.
    *set plekreinforce +1
    *return
  You burst into uncontrollable laughter, and not just from relief at seeing the last Plektos buried.  It feels as if you're somehow sharing in the release of the stone, its pure delight in falling.  But the strain on your mind is too much—though nothing hits you this time, you still collapse into darkness.
  *return
*set cavein +2
Somehow you manage to focus beyond the taloned, sinewy beast with your scent in its nostrils.  You cast your thoughts up toward the cavern ceiling, to the mountain stone eroded and split by water.  You can feel how much wants to fall…and spreading your arms, you welcome it down.

There's a crack like thunder, drowning out even the hound's snarls.  You feel an instant of resistance, another mind trying to undo your work.  But it's too late.  You couldn't control the collapse if you tried, and nor can the Theurge outside the cave entrance.  The Plektos vanishes in a hail of stone, just before a blow to your own head drops you into blackness.
*set plekreinforce +1
*page_break
*return

*label yebsacrifice
*set plektoi -1
Then—just as you brace yourself for death—something flies past your shoulder, so fast that you barely see it before it slams into the hound's maw.  It's a stone, a good-sized boulder, striking sparks from the Plektos's teeth and lodging in its throat.  

You fling yourself to one side as the beast goes mad, rearing upward, trying to cough out the obstruction.  Then there's a deafening crack; pain blazes along your shoulder and side as you're covered with splinters of rock and hot blood.  The Plektos topples forward.  Its skull is still largely intact but the jaw lolls brokenly, with blood pouring from the space where the boulder was a few moments earlier.

Its keeper
*if plektoi = 0
  hovers for a horrified instant outside the cave, then vanishes arrow-fast into the sky.
  *set plekreinforce +1
*if plektoi = 1
  flies into the cave mouth, hand outstretched toward the twitching corpse.  Alira's arrow takes him in the head.
  *set plekkeepers +1
Gasping from the agony in your side, you drag yourself to your feet and stare back wildly. "$!{sweetoath}…what…"

Yebben Skinner's body is almost as pallid as a ${nere}, drained of all its blood.  Whatever he managed to do saved you, but at a fearsome cost.
*set yebsac true
*set yebben 0
*return

*label helcampcheck
*if helcamp > (followers-21)
  *set helcamp (followers-21)
*return

*label disorientation
It's disorienting to realize that after all these months of acting a part, you can no longer distinguish it from your true feelings.  You've
*if hypocrite = 1
  become the sum of your actions.
  *set ruthreal ruth
  *set skepreal skep
  *set natlreal natl
*if hypocrite = 2
  lost the softness that used to torment you.
  *set ruthreal ruth
*if hypocrite = 3
  lost your edge—that willingness to do anything, no matter who it hurt.
  *set ruthreal ruth
*if hypocrite = 4
  come to a point where the ${nere}ish skepticism feels truer than the litanies you once loved.
  *set skepreal skep
*if hypocrite = 5
  truly come to fear Xthonos and revere the Angels; the idea that the ${nere}s might be right about them now feels like a genuinely alarming blasphemy.
  *set skepreal skep
*if hypocrite = 6
  lost that devotion to Shayard-above-all that used to drive you.
  *set natlreal natl
*if hypocrite = 7
  realized that the only road to triumph is indeed to put Shayard first.
  *set natlreal natl
*set hypocrite +10
*return

*label bees
*page_break
Then the Plektos surges into view with an exultant howl and the sound of breaking rock. Spinning away, you flee along the narrow path, eyes desperately searching the mass of vines.  One vine jumps and twitches: a rope, lowered by the outlaws overhead.  You catch it with both hands, push yourself into a sprint and feel the line grow taut. When the ledge narrows to a tiny lip, you try to run along the cliff wall…until your feet slip away at last, sending you careening out over the void.  
 
Clinging to the rope, you spin round helplessly to see the Plektos's spiked tail whip toward you—and fall short by inches as the ledge disintegrates under its weight.  It scrabbles for purchase, steely claws digging into the rock face as it draws back its tail for another strike.  And a thousand furious bees ascend from the space where their hive had been.

The white-bees of the Whendward are famously aggressive, protecting their miserly amount of honey with stings long and venomous enough to make a bear think twice.  While they can't pierce the Plektos's skin, they swarm vengefully around its eyes and snout.  The monstrous hound bellows and bats at them with one paw and its tail while jerking its head wildly from side to side.

The hound's Theurge keeper flies out of the tunnel before grasping what ails the beast.  He screams as the bees envelop him too, flying up his coat sleeves and the gap in his cowl.  Alira's first arrow bounces off his coat, but by the time the second one hits him, he's lost all concentration.  As its Theurge topples, the Plektos loses its grip on the cliff and plunges downward with a final wail.

The other outlaws quickly haul you up until you can once again get your footing.  A blaze of pain in your leg tells you that one of the white-bees has found you. You crush it and drag yourself away from the thrumming cloud below. Even when you rejoin your little party, none of you speaks for several minutes until you're sure you've climbed out of earshot of the destroyed hive.

The swelling on your leg feels on fire.  But you've killed
*set plektoi -1
*set plekkeepers +1
*return

*label seebelow
Below you are great swathes of flattened 
*if inadults > 65
  trees, littered with bodies.  The 
  *if lostem
    Plektoi 
  *if not(lostem)
    Plektos
  clearly hit your resting band like an avalanche; the survivors must have fled into the caves.
*if inadults < 66
  trees where the 
  *if lostem
    remaining Plektoi have 
  *if not(lostem)
    Plektos
  hunted for you and your small group of outlaws.  Only one or two bodies are visible; the rest must have been in the caves, or fled quickly into them.
*set cas +round(inadults/10)
*gosub cascheck
*return

*label tunnelnarr
*set plekfight +7
Alira, Young Earnn, and 
*if c_rel > 0
  Ciels
*if c_rel < 1
  another loyal hunter 
join you, white-eyed but determined.  "If we can't bring the bastards down in close quarters, we'll not do it anywhere,"
*if c_rel > 0
  Ciels
*if c_rel < 1
  Earnn 
ventures hoarsely, hefting a short spear. "Follow me.  We won't need a torch."
    
The cavern system was formed by streams running down the mountain. The caves are slick with water and frequently become near-vertical.  As you slip and slither further into the network, the light fades behind you.  From the darkness ahead, you hear a near-constant snarling and the grate of claws on rock.
    
*if introhlt
  The descent is a constant battle against your memories—as if you're forcing yourself to climb down that tree from your ${girl}hood.
More than once, you halt despite yourself, your muscles freezing at a guttural growl out of the black.  But each time you force yourself to start moving again, because the young hunter was right: a Plektos has the advantage over you anywhere, but all the more in open terrain.  Your best chance of survival comes from facing them here.
*return

*label willtheyscour
During the days, you're pressing relentlessly into the wilderness, desperate to escape the range of any Theurges they send after you.  Having 
*if wonfight = 10
  broken 
*if wonfight < 10
  evaded
their army, you can no longer be certain that the Thaumatarchy won't scour the whole Whendward with fire.  "They destroyed the Westriding after Cabel's revolt, ${addressu}," ${deputy} reminds you grimly, "and that was 
*if deputy = simon
  the finest farmland in the realm."
*if deputy != simon
  a damned sight more valuable to them than this wasteland."

*return

*label wisexplain
"$!{wisardry}," you reply.
*if wisard = "Theurge"
  "The power to set things right."
*if wisard = "Goete"
  *set morale -10
  *set cred_p -50
  Seeing the seeds of terror and rejection in your followers' eyes, you hastily add, "Not from any dark power. But let the Hegemony think so, and fear."
*if wisard = "Wisard"
  *set natl %+5
  "The old Shayardene art.  Stolen by Karagonds and called Theurgy."          
*return

*label landsplain
*if landslide and (theuknown < 5)

  "How…${addressu}, how by Xthonos did that landslide start?"  The rebel who asks is plainly afraid of the answer.
        
  *gosub wisexplain
  
  They all stare at you 
  *if (kal_here)
    for minutes longer until ${kalt} gives a low whistle of disbelief. "Swiving Angels, ${addressu}.  Glad you decided it was time to pull [i]that[/i] secret out of the air."
    *goto landsplainover
  *elseif (simz_here and ((simz_flank < 1) and (s_rel < 9)))
    until ${simon} 
    *if s_rel < 5
      drops to one knee. "$!{addressu} ${lname}—glory to the Merciful Angels!  The gift They've given you will save us all!"
    *if s_rel > 4
      clears ${zhis} throat uncomfortably. "A mighty gift indeed, ${addressu}.  Angels be with us all."
    *goto landsplainover
  *else
    until your questioner finally manages, "P-praise the Angels."
  *label landsplainover
  *set theuknown 5
*return

*label radexecute
*choice
  #Execute Radmar for Breden's murder.
    The survivors who loved Breden have been seething against Radmar for days. Those who'd supported the killing have been increasingly shamefaced and silent.  When you come for Radmar one evening, it's with a dozen others at your side, and no one stands up for him.
    *if poric > 0
      *gosub gladporic
      kill both of them would be bad for morale.
    
    "It's a good swiving day to die!"  Even pinned to the ground and struggling, the big 
    *if helot
      fighter 
    *if aristo
      helot
    can reach every ear with his roar. "Before this ${lname} fool finds another traitor to coddle and gets even mo…"
      
    You swing 
    *if weapon = "sword"
      your sword
    *if weapon != "sword"
      an axe
    down on his neck twice, then bury it in his shuddering back and step away. "Next time…"  Your voice is thick to the point of unintelligibility.  Clearing your throat, you manage, "Next time any of you thinks to kill a fellow rebel without trial, remember Radmar Millstone."
    *set radmar -100
    *label radgone
    *set rad_here false
    *page_break
    *if (deputy != "Radmar") or (radmar > 0)
      *label radgone2
      As you hurry onward through the wilderness, the mood of the band grows tenser. Every distant wolf or jackal howl has you all startling like colts.  Could the Hegemony possibly be ready to send fresh pursuit after you already?  It seems impossible, but it's hard for you genuinely to believe you've escaped them.
        
      *return
    *else
      With Radmar killed, you'll need to choose another deputy.
      *gosub pickadeputy
      As you trek onward, you try to make ${deputy} aware of all the strategic choices that led up to your victory in the woods.  Some of them were known to everyone in the band, some only to you and your previous deputies.
    
      *return
  #Banish him into the wilderness.
    The survivors who loved Breden have been seething against Radmar for days. Those who'd supported the killing have been increasingly shamefaced and silent.  When you stride up to Radmar one evening, it's with a dozen others at your side, and no one stands up for him.
    *if poric > 0
      *gosub gladporic
      banish both of them would be bad for morale.
      
    The big fighter crouches at your approach, eyes wide and furious.  A few silent moments later, when he realizes you're not about to swarm him, he straightens to his full height.  "Time for you to try punishing me, ${lname}?"
      
    "Time for you to try your luck alone in the wild," you say bleakly.  "There's no place in this rebellion for folk who murder their comrades."
      
    "What do you think Breden was, damn you?" Radmar spits. 
    *if pin <= 0
      "Every soul Harrowed in Rim Square that day was ${xhis} victim.
    *if pin > 0
      "$!{xhe} murdered everyone who was too sick last week to escape the Plektos or the Phalangites.
    $!{xhe} was a traitor—and you bloody well are too, for pining after ${xhim}."
      
    You struggle to retain control of your voice. "You murdered
    *if (bred_lover >= 4) and (bred_lover != 13)
      my ${xspouse},
    *if (bred_lover < 4) or (bred_lover = 13)
      Breden Reaper,
    Radmar.  This one time, I mean to let you live.  You fought the Hegemony hard as any of us, and I'd not tarnish our victory with your blood.  But, ${oath}…if I hear another swiving word from you, I'll gut you where you stand.  Same if I see you here by morning."
      
    When no one else speaks up, Radmar shrugs and stalks off to his tent.  By dawn, he's gone.
    *set radmar 0
    *goto radgone
  #Choose to let him live and remain with the band.
    Punishing Radmar won't bring Breden back, and the rebellion needs every competent fighter you can find.
    *if (bred_lover >= 4) or ((bred_heart = 2) or (bred_heart = 3))
      To see him every day
      *if deputy = "Radmar"
        and be forced to discuss strategy with him
      feels like packing your throat with burning coals…but that doesn't matter.  You can't let it matter.
    It's some small consolation that many other band members also consider him a murderer and are visibly furious with him.
    *if poric > 0
      Also, with Poric among the casualties of your
      *if wonfight < 10
        flight,
      *if wonfight >= 10
        battle,
      Radmar's suffering is in any case worse than anything you could have devised.
      *set poric 0    
    *goto radgone2

*label codingefficiency
Bees careen around your face, dipping into the orbflower vines that blanket the cliff face. You can hear the thrum of hundreds nearby; there must be an overhang under your feet, with a huge hive beneath. 
*return

*label gladporic
You're silently grateful that Poric didn't survive your 
*if wonfight < 10
  flight; 
*if wonfight >= 10
  battle;
having to 
*set poric 0
*return

*label cragpreps
bandits throw themselves into preparing for the coming battle: spiked wooden blockades and rockfalls for the Phalangites, piles of wood and wet moss, ready to fill the air with smoke against
*if theurges = 0
  any newly arrived
Theurges.
*if korszata > 0
  *if korszata > 1
    While Bjel drills the fighters one last time, 
  Korszata stalks back and forth from the caves to the cascades, overseeing all the preparations.

  "Couldn't the Theurges make those flare up and burn whoever's near them?" you ask the former Phalangite uneasily, pointing to the firewood piles.
  
  Korszata nods, unsmiling. "But they say it takes much blood.  Wet wood makes smoke, not fire.  We use this on Halassur.  Also makes it hard for them to see their soldiers' weapons and make them death-sharp."
  
  *if theurgy > 2
    Unfortunately, the same will be true for you.
  "Could they blow the smoke away?"
  
  "This too, yes.  But it also takes much blood to harness the wind.  Or so I understand."  
  *if int < 2
    
    A moving dot in the sky catches your eye.  It's several heart-pounding moments before you conclude it's a bird rather than a distant Theurge.
  *if int > 1
    He glances at you, one eyebrow raised.
    
    You nod as you think of your own experiments.  Moving air is simple, but keeping it to one direction rather than just feeding its natural turbulence, is beyond you.
  "So the things we're doing…it's to run them out of blood?"
  
  "The only way to win against Theurges.  They will have brought much blood, of course.  But they have been using it now for weeks." Korszata shrugs fatalistically. "Perhaps by now their supplies are low.  Memory guide you, ${addressu}."
  *if (skepreal <= 50) and (int > 1)
  
    His parting words make you a bit uneasy; is all this talk of "memory" the ${whend}s invoking the blessing of their Forgotten Gods?  For now, you just offer up a quick prayer for guidance to the Angels.  Later, there will be time to worry about whether the cosmopolitanism that drew Bjel and Korszata to you might be leading you into error.
  *page_break
  Korszata returns to a gang who are piling up boulders to roll down the slope.
*return

*label fightback

You manage to rally some of your best archers and fiercest fighters to slow the enemy's pursuit.  For all your gifts as a captain, however, there's little you can do to stem this disaster.  One by one, your rebels die around you—by Theurgic fire, by mace-blows, by spears and arrows.  

All your resistance manages is to raise the cost of victory for the Archon's forces.
*set phalcas 0
*set phalcas -round((inadults*3)/5)
*set alltroops +phalcas
*set theirmorale +round(phalcas*1.5)
*if aristroops > 0  
  The
  *if aristo
    other
  nobles of the Rim won't soon forget the moment when you lure their guard into a box valley and rain arrows down on them.
  *set aristroops +phalcas
  *if aristroops <= 0
    Most are slaughtered, and the rest flee, broken.
    *set phalcas aristroops
  *if aristroops > 0
    *set phalcas 0
*if alastroops > 0  
  An Alastor force is similarly gutted by your counter-ambush.
  *set alastroops +phalcas
  *if alastroops <= 0
    *set phalcas alastroops
  *if alastroops > 0
    *set phalcas 0
*if phalcas != 0
  *set phalangites +phalcas
  And the Phalangites will not have expected to lose so many red-armored warriors in the rout.
Still, in the end all you can do is flee for your life with a handful of survivors.

*return

*label deskidsback
The children she brings back huddle together miserably, unspeaking.
*set inkids +desertkids
*set kids +desertkids
*set inwoods +desertkids
*set followers +desertkids
*set morale -desertkids
*return

*label priscas
*set cas +round(inadults/4)
*gosub cascheck
*set arms +inadults
*return

*label fleecas
*set cas round((inadults*5)/6)
*set kidcas round((inkids*8)/9)
*set kids -kidcas
*set inkids -kidcas
*set inwoods -kidcas
*set kidsdead +kidcas
*set followers -kidcas
*set dead +kidcas
*set morale -(kidcas*2)
*if (kids < 2) and ((pin > 0) or (alless > 0))
  *set pin 0
  *set alless 0
*if (kids >= 2) and ((pin > 0) and (pin != 5))
  *set pin +10
*if (kids >= 2) and ((alless > 0) and (alless != 5))
  *set alless +10
*if followers < 30
  *set morale 9
*if followers < 20
  *set morale 5
*if followers < 10
  *set morale 1
*gosub armscheck
*gosub cascheck
*return

*label breddead
*set breden -60
*set bred_here false
*set followers -1
*set nonkids -1
*set inadults -1
*set inwoods -1
*set dead +1
*if deputy = "Breden"
  *set deputy ""
*return

*label daddead

The dawn sunlight picks out your father's unmoving form in the mud.  He'd clearly tried to run into the thickest undergrowth he could reach; now he lies at the end of an avenue of splintered trees and bushes.  The angle of his neck and the blood from his savaged belly tell you everything you need to know.
*choice
  #I cling to the pine, feeling numb and unmoored from reality.
    Even staring down at his body, it seems impossible that he's gone.  His cruelty, his fleeting affection, his judgment…who can you be, with all of those fixed points gone from the world?
    *set dadfeel 5
    *return
  #"At least it was quick." I turn away, head spinning…feeling more sadness than I'd expected, and more compassion.
    Can you really mourn someone who brought so much misery to your life?  A little, perhaps.  For the misery he sank himself in, too deep to find any way out but one.
    *set dadfeel 8
    *return
  #"Serves the old bastard right," I whisper hoarsely to myself.
    The sense of release that sweeps over you is terrible but sweet.  The cruelty you've lived with your whole life is gone.  The last person who could hurt you without consequence is dead.  You stagger back, almost weeping at the sudden weight of freedom.
    *set dadfeel 10
    *return
  #[i]Oh, Angels, no. No.[/i]
    You double over, gasping with a pain too deep and dry for tears.
    *choice
      #I'd always hoped, one day…
        *set dadfeel 2
        So many years bearing with his cruelties for the scraps of genuine affection.  Treasuring each one when it came.  Trying to believe that in time they'd burgeon into something deeper, more consistent. 
        *return
      #I wanted so much to prove him wrong about me.
        *set dadfeel 3
        He was wrong about so Xthon'damned many things.  Who will know, now?  Who will tell you when you've won?
        *return
      #I knew things would never change—but he was my father.
        *set dadfeel 1
        A terrible father.  But losing him still feels like losing yourself. You lurch back, unable to look at his corpse any more.
        *return
  *if (lostem and (plektoi > 0)) #Whatever else I'm feeling, it's drowned out by terror that I'll die the same way.
    You can't take your eyes off his broken body, or stop imagining what his last moments must have been like—the jaws catching him up, the feeling of the teeth in his stomach and back, the violent shaking that snapped his neck.
    *set dadfeel 7
    *return

*label daddead2
*if (hdead = 1) and horhostage
  both that the 
  *if lostem
    Plektoi 
  *if not(lostem)
    Plektos
  had killed your noble ${hostages} and
  *set hdead 2
that your father was the first one to die beneath a hound's claws. "However they got your scent, ${addressu}," Alira explained hoarsely, "they must have got his as well."
  
In that shattering moment, your response was:
*choice
  #Silence and utter numbness. For a moment, I felt unmoored from reality.
    It still seems impossible that he's gone.  His cruelty, his fleeting affection, his judgment…who can you be, with all of those fixed points gone from the world?
    *set dadfeel 5
    *return
  #"At least it was quick." I felt more sadness than I'd expected, and more compassion.
    Can you really mourn someone who brought so much misery to your life?  A little, perhaps.  For the misery he sank himself in, too deep to find any way out but one.
    *set dadfeel 8
    *return
  #"Served the old bastard right."
    The sense of release that swept over you was terrible but sweet.  The cruelty you've lived with your whole life is gone.  The last person who could hurt you without consequence is dead.  You nearly wept at the sudden weight of freedom.
    *set dadfeel 10
    *return
  #A wordless wail of, [i]Oh, Angels, no. No.[/i]
    You doubled over, gasping with a pain too deep and dry for tears.
    *choice
      #I'd always hoped, one day…
        *set dadfeel 2
        So many years bearing with his cruelties for the scraps of genuine affection.  Treasuring each one when it came.  Trying to believe that in time they'd burgeon into something deeper, more consistent. 
        *return
      #I wanted so much to prove him wrong about me.
        *set dadfeel 3
        He was wrong about so Xthon'damned many things.  Who will know, now?  Who will tell you when you've won?
        *return
      #I knew things would never change—but he was my father.
        *set dadfeel 1
        A terrible father.  But losing him still feels like losing yourself.
        *return
    
*label swaymis
*if not(swaymtick)
  You sway miserably on the sidelines, acutely aware that your own ${wisardry} is spent.  If you tried to do anything at this point, you'd immediately fall unconscious.
  *set swaymtick true
*return

*label theustrike 
The
*if theurges > 1
  Theurges are
*if theurges = 1
  Theurge is
visibly laden with vitriol phials.  The last thing on 
*if theurges = 1
  his mind
*if theurges > 1
  their minds
is that any of the rebels below might be able to see and unlock that pulsing elemental fire.  
          
As you reach out to ignite the 
*if theurges > 1
  nearest 
Theurge's vitriol, you see his eyes widen, feel the first push of mental resistance to your Change…but he's too late.  He vanishes in a bluish-white fireball from his own hand. 
*set morale +30
*set theirmorale -50
*set theurges -1

*if theurges > 1              
  In the confusion, you manage to ignite a second Theurge's vitriol bandolier.  She also erupts in light, like some vast star in the daytime sky.
  *set morale +20
  *set theurges -1
  *set theirmorale -50
The surviving
*if theurges > 1
  Theurges realize
*if theurges = 1
  Theurge realizes
what must be going on, and staunchly resist your last attempt before the blood evaporates from your palm.  "Ware Goety!" goes up the disbelieving cry. "A Goete among the rebels!"

*set cas -24
*set cred_p -50
*set theuknown 10
*return

*label pickadeputy
*choice
  *if ((bred_here) and not(bred_pris)) #Breden.
    *set deputy "Breden"
    *set dephis xhis
    *set dephe xhe
    *set bred_lead +1
    *return
  *if (zv_here) #Zvad
    *set deputy "Zvad"
    *set dephis "his"
    *set dephe "he"
    *set zv_lead +1
    *return
  *if (el_here and not(elsick)) 
    #Elery
      *set deputy "Elery"
      *set dephis "her"
      *set dephe "she"
      *set el_lead +1
      *return
  *if (simz_here and (s_rel < 9)) #${simon}.
    *set deputy simon
    *set dephis zhis
    *set dephe zhe
    *set simz_lead +1
    *return
  *if (kal_here) #${kalt}.
    *set deputy kalt
    *set dephis zhis
    *set dephe zhe
    *set kal_lead +1
    *return
  *if (rad_here) #Radmar.
    *set deputy "Radmar"
    *set dephis "his"
    *set dephe "he"
    *set rad_lead +1
    *return
  #Alira.
    *set deputy "Alira"
    *set dephis "her"
    *set dephe "she"
    *return
  *if (wonfight > 4) and not(earnndead)
    #Young Earnn.
      *set deputy "Earnn"
      *set dephis "his"
      *set dephe "he"
      *return

*label captured
The other captives look round dully at you as you're added to their number.  Besides a few despairing groans, there's no response that might identify you to the enemy; no one has any illusion that it would buy a moment's mercy.  The Phalangites thread a long rope through the bonds on your wrists, then force you all to your feet. "Walk, you filth.  Back to the cages."

The tree shadows are growing long and dark by the time you reach the Hegemonic camp.  Great bonfires are being kindled and a hearty supper cooked. Precious casks of Southriding wine have been broached to celebrate the end of the campaign.  All around, hymns are rising from young jonglers welcoming back the returning troops.

[i]Victory, victory! Thank Angels for victory,[/i]
*line_break
[i]Every rebel is fallen[/i]

[i]What fools thought to challenge the army of Xthonos?[/i]
*line_break
[i]That Which Is stands unshaken[/i]
        
*if theirtotal >= (alltroops+100)
  Your sole trace of consolation is that you enter past their healers' tents, which are full of casualties from your fierce resistance.
*if theirtotal > (alltroops+250)
  There's no celebration here, where they know better than any how many hundreds have died or been injured in hunting you.
*if theirtotal < (alltroops+100)
  You enter past their healers' tents, where the injuries your followers managed to inflict are being treated.
*if priestroops > 8
  The shiftless or pious peasants who followed their Ecclesiasts into the wild spit in your direction. "Demons! Die and be damned!"
*if aristroops > 16
  Some of the noble retainers
  *if alastroops > 20
    and Alastors
  hurl mud and refuse at you.
The Phalangites just stare implacably as you're dragged past; your Harrowing will be 
*if theirtotal <= alltroops
  satisfaction
*if theirtotal > alltroops
  vengeance 
enough for them.
*return
    
*label commslaughter
When you burst back through the tent door, the guards barely have time to glance at you before your sword passes through them.  You barely spare them a glance yourself, sprinting relentlessly toward the commanders' campfire.  A touch from this blade will cripple or kill; all you need care about is touching as many as possible.
            
Several of the elite Phalangites and nobility have their swords out by the time you arrive.  It does them as little good as their armor. You hew
*if com = 0
  clumsily
through both alike, and their shouts turn to screams.  
*return

*label the_end
*fake_choice
  #But I'm free of him at last.
  #"Be damned, old man," I snarl under my breath. "Damn you for dying before I could prove you wrong."
  #Why should I feel so lost, so empty?
  #Tears scald my eyes as I turn back toward the Ward.
*set rollover4 earnndead
Five days later, you reach the watershed atop a pass and see the
*if cerlota > 0
  snow-blanketed
trees thin out ahead of you.  You've been keeping under cover, cautious of the Theurges flitting overhead. Gazing across the waste ahead, it's clear that you'll no longer have to worry about them.

The forest gives way abruptly to a landscape of twisted stone spires, rubble, and small patches of scabby, spiky grass.  A thick steam rises from vents in the ground, blighting every plant close enough to touch.  A scattering of trees have grown from seeds blown or borne across the boundary, but all have been visibly changed: stretched high or wide, leaves and trunk luminous or bubbling with tarry red sap.  Some have prehensile, hooked branches that move against the breeze.

Great black clouds swirl in the distance, flickering with viridian light.  From far off you can hear deep stone-grinding rumbles and a high-pitched, variable keening that might just thinkably be the wind.

Between you and this nightmare landscape is a mossy wall, three stones high.

"That's it, ${addressu}," Yed rasps, his ragged body tensed for flight.  "That's the Ward."

*if (gamgee != "") and (gamgee != "four")
  *if gamgee != simon
    "Hold on to your soul," murmurs ${gamgee} bleakly.
  *if gamgee = simon
    ${simon} moistens ${zhis} lips. "Merciful Angels defend us."

You take a deep breath, 
*if skepreal > 50
  force your mind to calm itself,
*if skepreal <=50
  cast a final prayer to the silent Angels,
and stride forward into Xaos.

*text_image 4_2.png center Here ends Part One of Choice of Rebels.

*text_image 4_3.png center The rebellion will continue in Choice of Rebels: Stormwright.

*if choice_randomtest
  *choice
    #At the end, we have we have ${inwoods} inwoods, with ${inadults} inadults and ${inkids} inkids; ${followers} followers, with ${nonkids} nonkids and ${kids} kids.  ${helcamp} in camps and ${flee} fled.  Arms ${arms}, wealth ${wealth}.
      *goto postchoice5
*label postchoice5
*check_achievements
*if not(choice_achieved_intoxaos)
  *achieve intoxaos
*if violence < 1
  *achieve nonviolent
*if literate > followers
  *set literate (followers-1)
*goto_scene ending

*label d2n_np
*set np true
*label d2n
*set display_numb ""
*set thousands 0
*set hundreds 0
*set tens 0
*set single 0
*if d2n_num = 0
    *set display_numb "zero"
    *goto finish_d2n
*if d2n_num < 0
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if d2n_num > 999
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if (d2n_num modulo 1) > 0
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if d2n_num < 10
    *set single d2n_num
    *goto single_digit
*label thousands_digit_addition_repeat
*comment leaving this here in case we want to switch the thousands back on
*if d2n_num > 999
    *set d2n_num -1000
    *set thousands +1
    *goto thousands_digit_addition_repeat
*label hundreds_digit_addition_repeat
*if d2n_num > 99
    *set d2n_num -100
    *set hundreds +1
    *goto hundreds_digit_addition_repeat
*if (d2n_num > 9) and (d2n_num < 20)
    *goto skip_tens_and_singles
*label tens_digit_addition_repeat
*if d2n_num > 9
    *set d2n_num - 10
    *set tens + 1
    *goto tens_digit_addition_repeat
*set single d2n_num
*label skip_tens_and_singles
*if thousands = 1
    *set display_numb "one thousand"
*if thousands = 2
    *set display_numb "two thousand"
*if thousands = 3
    *set display_numb "three thousand"
*if thousands = 4
    *set display_numb "four thousand"
*if thousands = 5
    *set display_numb "five thousand"
*if thousands = 6
    *set display_numb "six thousand"
*if thousands = 7
    *set display_numb "seven thousand"
*if thousands = 8
    *set display_numb "eight thousand"
*if thousands = 9
    *set display_numb "nine thousand"
*if ((thousands > 0) and ((tens > 0) or (single > 0))) and ((hundreds < 1) and (d2n_num < 10))
    *set display_numb &" and"
    *goto tens_digit
*if ((thousands > 0) and (d2n_num > 9)) and (((hundreds < 1) and (tens < 1)) and (single < 1))
    *set display_numb &" and"
    *goto tens_digit
*if ((thousands > 0) and ((tens > 1) and (single > 0))) and (hundreds < 1)
    *set display_numb &" and"
    *goto tens_digit
*if (thousands > 0) and ((hundreds > 0) and ((tens > 0) or ((single > 0) or (d2n_num > 9))))
    *set display_numb &","
*if (thousands > 0) 
  *set display_numb &" "
*if hundreds = 1
    *set display_numb &"one hundred"
*if hundreds = 2
    *set display_numb &"two hundred"
*if hundreds = 3
    *set display_numb &"three hundred"
*if hundreds = 4
    *set display_numb &"four hundred"
*if hundreds = 5
    *set display_numb &"five hundred"
*if hundreds = 6
    *set display_numb &"six hundred"
*if hundreds = 7
    *set display_numb &"seven hundred"
*if hundreds = 8
    *set display_numb &"eight hundred"
*if hundreds = 9
    *set display_numb &"nine hundred"
*if ((hundreds > 0) and (tens < 1)) and ((single > 0) or (d2n_num > 9))
    *set display_numb &" and"
*label tens_digit
*if (hundreds > 0) 
  *set display_numb &" "    
*label teens
*if d2n_num = 10
    *set display_numb &"ten"
    *goto finish_d2n
*if d2n_num = 11
    *set display_numb &"eleven"
    *goto finish_d2n
*if d2n_num = 12
    *set display_numb &"twelve"
    *goto finish_d2n
*if d2n_num = 13
    *set display_numb &"thirteen"
    *goto finish_d2n
*if d2n_num = 14
    *set display_numb &"fourteen"
    *goto finish_d2n
*if d2n_num = 15
    *set display_numb &"fifteen"
    *goto finish_d2n
*if d2n_num = 16
    *set display_numb &"sixteen"
    *goto finish_d2n
*if d2n_num = 17
    *set display_numb &"seventeen"
    *goto finish_d2n
*if d2n_num = 18
    *set display_numb &"eighteen"
    *goto finish_d2n
*if d2n_num = 19
    *set display_numb &"nineteen"
    *goto finish_d2n
*if tens = 1
    *bug Should not be reachable
*if tens = 2
    *set display_numb &"twenty"
*if tens = 3
    *set display_numb &"thirty"
*if tens = 4
    *set display_numb &"forty"
*if tens = 5
    *set display_numb &"fifty"
*if tens = 6
    *set display_numb &"sixty"
*if tens = 7
    *set display_numb &"seventy"
*if tens = 8
    *set display_numb &"eighty"
*if tens = 9
    *set display_numb &"ninety"
*if (single > 0) and (tens > 0)
    *set display_numb &"-"
*label single_digit
*if single = 1
    *set display_numb &"one"
*if single = 2
    *set display_numb &"two"
*if single = 3
    *set display_numb &"three"
*if single = 4
    *set display_numb &"four"
*if single = 5
    *set display_numb &"five"
*if single = 6
    *set display_numb &"six"
*if single = 7
    *set display_numb &"seven"
*if single = 8
    *set display_numb &"eight"
*if single = 9
    *set display_numb &"nine"
*label finish_d2n
*if not(np)
    ${display_numb}
*set np false
*return
