*comment Choice of Rebels: Uprising written by Joel Havenstone, copyright 2017.
*comment Using ChoiceScript (copyright 2010 by Dan Fabulich) under the terms of the ChoiceScript license:
*comment  http://www.choiceofgames.com/LICENSE-1.0.txt
*page_break
*text_image XoR_title.png center Choice of Rebels
This is the state of your leadership and the rebellion:

$!{addressu} ${fname} ${lname}
*if aristo
  *line_break
  Born a noble of 
  *if orig_lname != lname
    House ${orig_lname}
  *if orig_lname = lname
    the Shayard Rim
*if helot
  *line_break
  Born a helot to House Keriatou
*if (int = 2)
  *line_break
  Self-taught ${wisard}
*if religion >= 20
  *line_break
  Revealer of kenon
*if (religion < 20) and (religion >= 10)
  *line_break
  Prophet of the common Angelic voice
*if addressu = "the greatly mourned"
  *line_break
  A martyr of the rebellion
*if (epithet != "") or (slur !="")

  [b]Epithets[/b]
*if epithet != ""
  *line_break
  Called by your followers:
  *if eclect
    *line_break
    Eclect of the Angels
  *if liebreaker
    *line_break
    Lie-Breaker
  *if openhanded
    *line_break
    Open-Handed
*if slur != ""
  *line_break
  Called by the Thaumatarchy:
  *if childkiller
    *line_break
    Child-Killer
  *if shameveined
    *line_break
    Shame-Veined
  *if filthborn
    *line_break
    Filthborn
*if alias != ""
  *line_break
  Sometimes known by the alias ${alias}.

*text_image traits.png center Traits
[b]Charisma:[/b]
*if cha = 0
  You're plain-spoken and struggle to win others over.
*if cha = 1
  You are reasonably persuasive and charming.
*if cha = 2
  You are inspiring, eloquent, and naturally charming.
*line_break
[b]Combat:[/b]
*if com = 0
  You're unlikely to win a fight or lead others to victory.
*if com = 1
  You've practiced the ${weapon} and figured out some basic small-group tactics.
*if com = 2
  You have an excellent grasp of tactics and fight very well with the ${weapon}.
*line_break
[b]Intellect:[/b]
*if int = 0
  You're 
  *if helot
    illiterate, 
  uninformed about most 
  *if helot
    topics, 
  *if aristo
    topics
  and not very strong at reasoning.
*if int = 1
  *if aristo
    You have decent reasoning skills and basic knowledge on a range of topics.
  *if helot
    Though you can't read, your reason and good memory have helped you acquire basic knowledge on a range of topics.
*if int = 2
  You're
  *if helot
    not only literate but
  widely read on many topics, with an excellent memory and strong reasoning skills.

You are popularly seen to be:
*stat_chart
  opposed_pair ruth 
    Ruthless
    Compassionate
  opposed_pair skep
    Skeptical
    Devout
  opposed_pair natl
    Homelander
    Cosmopolitan

*text_image followers.png center Followers
Your rebellion has ${followers} surviving
*if (kids > 0)
  followers, including ${nonkids} adults and ${kids} 
  *if kids > 1
    children.
  *if kids = 1
    child.
*if (kids <= 0)
  followers.
*if literate > 0
  *line_break
  Of these, ${literate} are literate.
*if helcamp > 0
  ${helcamp} are currently infiltrating the Rim; the rest remain in the Whendward Hills.
*if dead > 0
  *line_break
  Since the rebellion began, ${dead} of your followers have 
  *if kidsdead > 0
    died, including ${kidsdead}
    *if kidsdead != 1
      children.
    *if kidsdead = 1
      child.
  *if kidsdead <= 0
    died.
*line_break
Morale
*if dead > 100
  among the survivors
is
*if morale >= (followers+20)
  exceptionally strong.
*if (morale < (followers+20)) and (morale > followers)
  strong.
*if (morale > ((followers*2)/3)) and (morale <= followers)
  generally positive.
*if (morale > (followers/2)) and (morale <= ((followers*2)/3))
  struggling.
*if (morale <= (followers/2)) and (morale > (followers/3))
  poor.
*if morale <= (followers/3)
  utterly dismal.

*text_image resources.png center Resources
*stat_chart
  text Wealth
  text Arms
  text Mules
*if blood > 0
  *stat_chart
    text Blood

*stat_chart
  text Anarchy


Your story might have played out differently had you made different choices as a rebel leader…
*if (choice_randomtest)
  *ending
*set restart 1
*choice
  #…after you left Rim Square.  (Replay from Chapter Two.)
    *goto_scene savescene
  #…after you survived the winter. (Replay from Chapter Three.)
    *goto_scene savescene2
  #…as you prepared for the Hegemony to strike. (Replay from Chapter Four.)
    *goto_scene savescene3
  #Finish the game.
    Make sure to save your game below! You'll need your saved game to continue where you left off in the next episode.
    *save_game uprisingsave

    We hope you've enjoyed playing [i]Choice of Rebels: Uprising.[/i]

    *feedback

    Thanks for playing!

    *ending
