*comment Choice of Rebels: Uprising written by Joel Havenstone, copyright 2017.
*comment Using ChoiceScript (copyright 2010 by Dan Fabulich) under the terms of the ChoiceScript license:
*comment  http://www.choiceofgames.com/LICENSE-1.0.txt
*temp sick rollover1
*temp fundraise rollover2
*temp tick 2
*temp ale 0
*temp romance 0
*temp dance false
*temp trusttick true
*temp bulwark false
*temp donation 0
*temp yeodonate 0
*temp mulesale 0
*temp doctor 0
*temp armsale 0
*temp armsalelimit 0
*temp armsfoll arms
*temp topdog ""
*temp t_his ""
*temp mutiny "mutiny"
*if rad_mutiny
  *set mutiny "another mutiny"
*temp rad_council false
*temp el_council false
*temp ter_council false
*temp youngun "Breden"
*temp y_his xhis
*temp elder "Joana"
*temp elder2 "Joana"
*temp bredalien false
*temp bredsuspnow false
*temp nobred false
*if not(bred_here)
  *set nobred true
*temp lname_length length(lname)
*temp lname_last lname#lname_length
*if lname_length > 3
  *temp lname_lastz lname#(lname_length-1)
  *temp lname_lasty lname#(lname_length-2)
  *temp lname_lastx lname#(lname_length-3)
*temp lname_a lname#1
*if lname_length > 1
  *temp lname_b lname#2
*if lname_length > 2
  *temp lname_c lname#3
*if lname_length > 3
  *temp lname_d lname#4
*if lname_length > 4
  *temp lname_e lname#5
*if lname_length > 5
  *temp lname_f lname#6
*if lname_length > 6
  *temp lname_g lname#7
*if lname_length > 3
  *temp lname_start ((lname_a&lname_b)&lname_c)
*if lname_length > 6
  *temp lname_mid ((lname_d&lname_e)&(lname_f&lname_g))
*if lname_length = 6
  *temp lname_mid ((lname_d&lname_e)&(lname_f))
*if lname_length = 5
  *temp lname_mid ((lname_d&lname_e))
*if lname_length = 4
  *temp lname_mid ((lname_d))
*if lname_length > 3
  *temp lname_end ((lname_lastx&lname_lasty)&(lname_lastz&lname_last))
*temp altname ""
*temp i 0
*set cerlota 0
*set tagmasword false
*page_break
*if (wealth < 13)
  *if wealth < 0
    *set wealth 0
  *goto spring
*else
  As you emerge from the long winter, you take another look at the silver and loot you've accumulated. With food no longer critical, you could spend some of that wealth to win allies, raise morale, or make your band more effective.
  
  *if ((mules-freemules) > 0)
    You could also consider selling 
    *if mules = 1
      your sole mule for a few more gold staters.
    *if mules > 1
      one or more of your
      *set d2n_num mules
      *gosub d2n
      mules.  
    The band is in better health now, and less dependent on barley from the Rim; ${deputy} 
    *if mules > 15
      reckons you could get by with fifteen mules.
    *if mules = 15
      has said the current number of mules is just about right,
    *if mules < 15
      has wished aloud that you had at least fifteen mules, 
    *if mules <= 15
      but perhaps that's more than you truly need.
    *if freemules > 0
      (Alas, the 
      *set d2n_num freemules
      *gosub d2n
      mules from the Architelone remain impossible to sell.)
  
  *if winterfail > 0
    Your failure to keep the band together through the winter has plainly affected how the survivors see you.
  *label banditwealth
  *if arms > nonkids
    *set armsfoll nonkids
  *if tick = 3
    *page_break
  *gosub morale_check
  Your current wealth amounts to
  *set d2n_num wealth
  *gosub d2n
  silver drachems.
  *set tick 3
  *choice
    *if (ale = 0)
      *selectable_if (wealth >= followers) #Buy ale, beef, and cheese for a grand feast to celebrate our survival. (${followers} silver.)
        *set ale 1
        *set wealth -followers
        *if (followers/4) > 15
          *set morale +round(followers/4)
        *if (followers/4) <= 15
          *set morale +15
        *label partytime
        *if ale = 1
          After a whole winter living on scratchings and tightly rationed barley bread, your band erupts in incredulous laughter and cheers when you unveil the food and ale and declare a feast to celebrate the coming of spring. You've also got
        *if ale = 2
          Though there's not enough food for anything you'd call a feast, there are 
        two small casks of 
        *if rescuer = 0
          Hetten Halt-Hand's sour barley and aconite beer,
        *if rescuer != 0
          something your bandits tried to brew from barley and aconite,
        which probably won't kill you once you've skimmed the barm off.  
          
        With a thunderstorm just having passed, you're also willing to risk a good blaze.  You build two small mountains of dried wood and set them alight to purge the cold from your bones and the damp from your clothes and bedrolls.  
        *if winterfail = 0
          The outlaws gather around the bonfires, broach the casks, and begin raising their drinking horns:

          "To ${kuria} ${lname}, who brought us through the hard winter!"

          *if liebreaker
            "To $!{kuria} ${fname} Lie-Breaker, and all the Ecclesiasts who paid the tithe to the poor of Whendward!"

          *if demerre = 3
            "To the unwilling generosity of House de Merre!"

          *if (demerre != 3) or not(liebreaker)
            "To all the merchants who shared their drachems with us!"

          *if (fundraise > 0) and (cha> 0)
            "To the helots who gave up their barley to keep us alive—Angels remember them!"

          "To us!  Who's like us?  Damn few—and all dead!"
        *if winterfail > 0
        
          Even after broaching the casks, it takes a while before the bleak-faced outlaws begin raising their drinking horns, and the toasts are wry or grim at first.  "To a dry kyrtle and a full belly.  To that one pheasant six weeks ago—the only fat one we found all swiving winter.  To the fallen."  
          
          But as three youths begin drumming and the ale settles into your outlaws' bellies, the mood lightens. "To all of us who are still here!  To that first deer, Angels bless its soul.  To the battle to come."

        Then
        *if bred_here
          Breden
        *if not(bred_here)
          a young, fiery man who has caught your vision
        lifts a horn and shouts, "This is only the beginning.  [i]To the breaking of every Harrower, and the death of the Thaumatarch![/i]"

        Over deafening cheers, another young outlaw bellows, "And the liberation of Shayard!"

        The clamor becomes slightly but noticeably quieter.  Zvad has barely lifted his horn, and throws a glance of tolerant amusement in your direction.  Most of your outlaws are Shayardene helots, but there are a few like Zvad who come from the neighboring archonty of Whendery—or "Wiendrj," as they unpronounceably call it.  Obviously you want to keep them inspired too, but your promises must be credible.  If you're going to talk about Whendish liberation, you'd better mean it.
        *choice
          #My first priority is to liberate my homeland of Shayard—though obviously I'd be happy if the Whends also liberated Whendery.
            You raise your drinking horn.  "To Shayard, free and safe from outsiders!"  Bowing to Zvad, you continue, "And may our Whendish cousins free their own beloved conty one day as well."

            "One war at a time, ${kuria}," Zvad growls amiably, lifting his horn back at you.
            *set natl %+20
            *set cred_y +10
            *goto dancedance
          #My vision is to free all four provinces, including Wiendrj, from the Thaumatarch's tyranny.
            You raise your drinking horn.  "To the liberation of every archonty—of Wiendrj, of Erezza, of Nyryal!"  You're sure you garbled those names, but the Wiends in the band raucously cheer your efforts anyway.  "I swear, I will not rest until every land is free of the Thaumatarch's yoke."
            *set natl %-20
            *set cred_y -5
            *set whend "Wiend"
            *set whendery "Wiendrj"
            *set erretsin "Erezziano"
            *set errets "Erezza"
            *set nere "Nyr"
            *set nereal "Nyryal"
            *goto dancedance
          #I don't want to alienate any of my band by expressing a goal.  Instead, I raise my horn and shout, "To the rebellion!"
            Perhaps it's only you imagining your own feelings into others…but you think the cheer rising from your outlaws holds a note of relief.  There's no need to say anything that would set some of the Shayardenes against the Whends, or the other way round.
            *goto dancedance
        *label dancedance
        
        Once you've 
        *if ale = 1
          devoured the meal and feel warm and round-bellied for the first time in months,
        *if (ale = 2) and (rescuer = 0)
          swilled the last of Hetten's brew, 
        *if (ale = 2) and (rescuer != 0)
          finished your toasts, 
        two of the band produce pipes and a drum and strike up "The Primrose Reel."  Half of the outlaws
        *if kids > 2
          and most of the children
        immediately leap up and start dancing around the bonfire.  You spy your father seated across the ring, arms folded forlornly around his legs.  He's hollow-cheeked from an ague that has plagued him these last two weeks, but you can't imagine him trying a reel anyway.  

        A hazy but startling image of him dancing with your mother bubbles into your mind.  You find it hard to believe that it's an actual memory—but maybe you're just reading the misery of later years back into your earliest childhood.  Maybe your father did dance, once.
        *if breden >= 2

          It feels suddenly intolerable to just sit on the grass.  You stand up (to loud cheers from your followers) and join the reel, spiraling toward and away from the bonfire for song after song until your legs are about to buckle from exhaustion.
          *if bred_here
            Breden is spinning lithely around the fire with Ciels,
            *if ciels >= 1
              who's evidently as good a dancer as ${he} is a tracker.
            *if ciels < 1
              one of the band's best trackers, who turned outlaw shortly before you arrived.  
            *set ciels 15
            They bow to you as you whirl past them, but plainly have little interest in anyone but each other.
          
          You aren't sure when your father leaves the bonfire, but at some point you realize he's no longer hunched at the edge of your awareness.  When the dancing is finally done, you reclaim your bedroll, roll it out on the dry ground around the bonfire, and sleep as soundly as you ever have in the glow of the embers.
          *goto alenext
        *else
          Disquieted, you look away. 

          Almost at once, you find your eyes drawn to Breden.  $!{xhe} is spinning lithely around the fire with Ciels, 
          *if ciels > 0
            who's evidently as good a dancer as ${he} is a tracker.
          *if ciels < 1
            one of the band's best trackers, who turned outlaw shortly before you arrived.  
            *set ciels 1
          It's the first time you've seen Breden dance, and (you think) the only time you've seen ${xhim} laugh since the day you left your village.  
          *if (acepref)
            $!{xhis} whole body speaks of grace and joy; it's an extraordinary moment of beauty.
          *if not(acepref)
            As ${xhis} hand brushes Ciels's waist, you're taken aback by a sudden pang, no less insistent than the worst hunger you felt in the winter.

          *if (bred_trust > 9) and not(acepref)
            As you'd half-feared, when 
          *if (bred_trust < 10) or (acepref)
            When 
          the drum rumbles to an end Breden strides up to you, eyes intent.  "Agile ${kuria}, care to join me in the ring?"
          *if bred_trust > 9
            Under the facade of cheer, there's a strange note in ${xhis} voice, half challenge and half plea.  When you don't immediately reply, ${xhe} murmurs, "You can trust me.  Really," and pauses for the length of a breath before continuing, "I haven't drunk enough to trample your toes."
          *choice
            #"All right.  Let's see how well you dance."
              *if bred_trust > 9
                A relieved smile flashes across ${xhis} face.
              "Surely you've already seen how well I dance?"  Breden pulls you out into the ring as the drums start to pulse again.  "When you were watching me and Ciels so very closely?"

              "I saw enough," you say lightly, "but I'll give you a chance to make a second impression."  
              *label ok_dance
              *achieve dance
              *set dance true
              
              The piper plays the first notes to "My Love O' the Greenwood."  Your outlaws standing at the sidelines cheer, whistle, and clap along as you join the dance.  Several start singing:
              
              [i]Follow the breeze down, soft and bonny[/i]
              *line_break
              [i]To gather bloom and sweet bracken and honey[/i]
              *line_break
              [i]And weave us a bower of branch and fern[/i]
              *line_break
              [i]To shelter love 'til winter return[/i]
              *line_break
              [i]My love o' the greenwood is strong of heart[/i]
              *line_break
              [i]My greenwood love is strong[/i]
              
              You and Breden whirl into each other's arms and away again, circling around the bonfires.
              *if (bred_lover >= 4) and (bred_trust > 9)
                It's the first time you've been this physically close to ${xhim} in months.
              When the dance sends you to other partners, ${xhis} hands always linger for a reluctant instant on your shoulder and hip, and ${xhis} eyes rarely leave your face.

              As first the singing, then the piping stops and you whirl to a halt, 
              *if aropref
                *set bred_lover -50
                *set bred_heart 8
                Breden speaks in a slightly shaky voice. "Sometimes I can work it out without any need to ask, ${bfname}. Wanted to be sure with you, though. Are you chaste because you lack the desire, or because you're just stronger-willed than most?"
                *page_break
                *if helot
                  With life returning to normal, of course your followers will flock back to fireside gossip about other helots' liaisons and appetites.
                *if aristo
                  A half-scandalized laugh bursts out of you.  More than one young aristo had tied themselves in knots trying to find an appropriately indirect way to ask the same question.   You still find the helots' candor on carnal matters somewhere between refreshing and outrageous.
                "$!{oath}.  Couldn't it just have been that I've been pouring all my hours into trying to bring us through the winter alive?"  
                
                "Could be."  $!{xhe} glances in the direction of the tents. "But the strain of the winter didn't have that effect on most others."
                
                "True enough."  There's scant privacy in an outlaw camp; 
                *if helot
                  you've heard as much coupling in the past ten weeks as in the previous ten years.  
                *if aristo
                  your ears had been ablaze for weeks before you finally grew accustomed to the discreet nightly commotion.
                You study ${xhim} for a moment before shaking your head. "It doesn't need any strength of will.  I've never wanted to lie with anyone."
                
                Breden exhales ruefully, removes ${xhis} hands from your shoulders.  "Aye, I'd thought so.  And I reckon it's obvious by now that I can't say the same." $!{xhe} manages a grin. "But it's good to know it's a matter of nature, not just my own shortcomings."
                *label arochoice
                *choice
                  #I cautiously return ${xhis} smile.  "Friends, then?"
                    Breden
                    *if aristo
                      laughs and offers a quick bow. "Angels.  Never imagined I'd have an aristo asking that.  But, aye, I'd be glad of it, ${kuria} ${fname}."
                    *if helot
                      swiftly clasps your hand. "I'd be glad of that, ${fname}."
                    *set bred_heart 1
                    *goto alenext
                  #"And I'm glad we understand each other." I keep my tone as neutral as possible as I step away.
                    Breden's smile turns melancholy, and ${xhe} bows to you. "Indeed, ${kuria}.  I'm glad of it too."  After a moment's pause, ${xhe} strides away from you and catches Ciels out of the crowd.
                    *goto alenext
                  #I just give ${xhim} a curt nod, hoping this means no future requests to dance.
                    Sensing your obvious displeasure, Breden swallows whatever ${xhe} had been about to say and retreats across the meadow.  You see ${xhim} a few minutes later, dancing with Ciels again.
                    *goto alenext
              *if (bred_lover >= 4) and (bred_trust < 10)
                Breden folds ${xhis} arms possessively around the small of your back.  "Why by all Angels have we never danced before?" ${xhe} murmurs.  "Don't tell me it was because we had to keep things a secret 
                *if aristo
                  from your aristo cousins 
                back home.  The rest of the band have kept themselves warm with dancing through the winter."

                Your laugh sounds short and uneasy in your own ears. "Love—every moment you and I have had together, I've stolen from other people who wanted to hear where we would find tomorrow's food.  There's been no time for dancing."

                "No."  Breden drops ${xhis} voice to a whisper.  "Nor time to hunt for whoever sold us to Chirex.  
                *if (deputy != "Breden") or (demerre = 0)
                  At least, you haven't spoken of it to me again since the day it happened."  
                *if (deputy = "Breden") and (demerre > 0)
                  You've spoken of the traitor to me only once in all our time here."
                $!{xhe} holds your eyes with a pained smile, and you feel a shiver go through ${xhis} body.  "${fname}—if you don't trust me, I can't force you to.  I'm only saying…we may not get many springs."
                *choice
                  #I trust and love Breden, and I'll tell ${xhim} so.
                    "Sssshh."  You put your fingers over ${xhis} mouth.  "A lot of things were put off in the winter.  But now it's time for hunting as well as dancing.  And I'll need you with me for all of it.  More than I've ever needed anything.  Not one of our springs will go to waste, I promise you."

                    You feel Breden raggedly exhale past your fingers; you hadn't realized ${xhe}'d been holding ${xhis} breath.  "I've been afraid, ${fname}. You said nothing for so long—I was sure you had decided I was the tr…to blame.  I've not known how to talk about it, let alone how to win you back."

                    You pull ${xhim} in to you, close enough that none of the raucous bandits nearby can hear.  "I know you're no traitor.  And you won me a long time ago."  $!{xhe}'s caught off guard by the ferocity of your kiss and lurches giddily backward, nearly sending you both into the fire.
                    *set bred_trust 2
                    *label kissfall
                    The other outlaws close ranks around you, laughing and threatening to clear your heads with a dousing in the stream.  
                    
                    Some of the other revelers are starting to steal away, two by two.  Like everyone raised under the Angels' Canon, the helots of your town 
                    *if rescuer = 0
                      understand 
                    *if rescuer = 1
                      understood
                    that matrimony is one of life's most crucial bulwarks against Xaos—taming the unruliest of passions, quenching the uncontrollable violence of jealousy.  But it's also widely accepted that helot youth will often discreetly "range" a little before settling down with a spouse.
                    *set bulwark true
                    *if aristo
                      (There's nothing like the aristocratic rigidity you were raised with, where a whisper of unchastity can ruin a girl or boy's reputation and result in exclusion from devout society).

                    The Whendward bandits tend to be even more pragmatic and far less discreet.  As one of them wryly explained to you, "When life's this hard and short, ${kuria}, you don't ask, 'Am I letting more chaos into the world?'  You just ask, 'Would it make him happy—and will anyone else knife me for him?'"
                    *if aristo
                      *set bfname fname
                    *choice
                      *if romance > 17
                        #I invite Breden back to my tent.
                          *goto whoopie
                      *if romance < 18
                        #I take Breden back to the bedroll we've been sharing.
                          *label whoopie
                          *if elezvad = 9
                            Nearby, Elery snorts, "Angels forbid we should get a reputation for immorality."  You ignore her, though you can feel your ears growing hot.  A few moments later she stalks off toward Zvad, intent clear on her face.
                            
                            *set e_rel -5
                            *set morale -3
                            *set elezvad 10
                          *if bred_lover = 11
                            Then you remember something you can whole-heartedly look forward to.  You
                          *if bred_lover < 10
                            *set bred_lover 14
                          *if bred_lover > 11
                            Trying not to walk with indecent haste, you 
                          stride past the dancers to reclaim your tattered bedcloth from the trees where it's been hanging.  The feel of the canvas—fire-warmed and fully dry for the first time in many clammy, miserable weeks—is more exhilarating than the ale in your belly.  You extend it to Breden and watch ${xhis} whole face brighten as ${xhis} hand touches the cloth.  Leaning down to ${xhis} ear, you say, "Imagine how that's going to feel draped around your shoulders and back in a few minutes."

                          There's little privacy among outlaws, of course.  You just manage to avoid stepping on a couple who retired to the tent even before you, as you pick your way to your rush-strewn corner.  As you pull Breden down with you and envelop ${xhim} in that blissfully warm blanket, you shut out everything else.  
                          *if (romance < 18) and not(acepref)
                            It's second nature by now, 
                          *if (romance > 17) or acepref
                            It's strange,
                          this discreet coupling—feeling, more than hearing, the accelerating rhythm of ${xhis} breath against your cheek and ${xhis} stifled gasps against your shoulder.

                          *if bred_lover = 11
                            To your relief, it's not unpleasant, though you doubt you'll ever really acquire the taste for it.
                          *if bred_lover = 12
                            But to your relief, it feels natural, a sharing you'd only make (or want to make) with this one extraordinary soul.
                          When 
                          *if bred_lover != 11
                            you're both 
                          *if bred_lover = 11
                            ${xhe}'s
                          spent, Breden slides ${xhis} mouth up to your ear.  You can feel that ${xhe}'s smiling, and also the cold wetness of tears pressed between ${xhis} cheek and yours.  "I'm with you, ${fname}.  Whatever happens."
                          *goto alenext
                      *if romance > 17
                        #Ah, ${oath}—it's going to be hard to part for the night.
                          *goto nowhoopie
                      *if romance < 18
                        #Ah, ${oath}—it's never been harder to part for the night.
                          *label nowhoopie
                          When the dancing's finally done, you walk back toward the tents with Breden.  As you turn to say goodnight, ${xhe} fixes you with a
                          *if romance < 20
                            long-suffering 
                          *if romance > 19
                            quizzical
                          stare.  "You do know, ${kuria}, we're the only ones in this camp who'll be alone in our bedrolls tonight."

                          That's an exaggeration, but ${xhis} point is fair enough.  
                          *if romance < 20
                            You've not yet slept 
                          *if romance > 19
                            You're not about to sleep
                          with Breden because…
                          *choice
                            *if aristo
                              #As a young noble, I maintained a chaste reputation, and that's an asset I won't relinquish lightly.
                                *label nobleasset
                                *set bred_lover 5
                                Only noble families which are already very rich and powerful—like your cousins of House Keriatou—allow their sons or daughters to flout the rules of chastity.  Most of the devout and traditional Houses still value it highly, including Shayard's ruling family, the Leilatou.  (It's said that their extraordinary commitment to Canon is one of the reasons why the Thaumatarch has appointed three successive Leilatou Archons to govern Shayard).  Chastity is not the only way for youths to prove themselves capable of lifelong loyalty and orderliness, of course—but it's an important one.

                                Breden sees the answer in your face and gapes at you.  "Honestly?  You're still holding out hope for a noble
                                *if femalepref or (acepref and male)
                                  wife?"
                                *if malepref or (acepref and female)
                                  husband?"

                                "Of course not."  It's unthinkable that any other House would accept a marriage alliance with the ${lname} at this point.  But if you ever hope to win round other nobles to your rebellion, you'll need to muster all possible evidence to convince them you're not a Xaos-loving anarchist.  "A reputation isn't just about marriageability.  It's the clearest sign that you care about Order—about all the rules that separate us from the animals."

                                Breden steps away from you, rubbing ${xhis} forehead; ${xhis} tone is less warm than it was.  "${fname}…have a care with that 'animal' talk.  I know you grew up hearing it all the time.  I know you're thinking of dogs and horses when you say it.  But we've heard enough of nobles telling us we're animals because we don't follow their rules."

                                You manage to swallow your first angry, defensive retort.  "I'm sorry.  Really—I am.  But it's important to show that we're not breaking all the rules.  The right reputation might actually bring more of the right people onto our side.  A few more people like me."

                                "Let's hope so,
                                *if female
                                  kuria."  
                                *if male
                                  kurios."
                                *if romance = 25
                                  Breden is stiff and silent for a moment.  Then ${xhis} face relents into a half-grin.  "I'm sorry, ${fname}.  I don't mean to act the dolt.  When dreams you've held for months start coming true, it's easy to get greedy and want them all at once."

                                  You lean in for a final kiss.  "Thank you for…well, for getting me to dance.  And for being bold enough to say what we were both feeling."
                                  *goto alenext
                                Breden attempts a smile, gives you a stiff nod, and walks away.
                                *goto alenext
                            #I've heard my whole life that un-Ordered sexual union invites jealousy, madness, and chaos.
                              *label kevinandleir
                              *set bred_lover 6
                              It's not just the sacred Canon; the popular
                              *if helot
                                fireside tales
                              *if aristo
                                storybooks
                              you grew up with were full of examples.  Most famously, there's the epic tragedy of Kevin and Leir, two young nobles who became illicit lovers when their parents refused them permission to marry.  Uncurbed by matrimony, their passion led to a spiral of worsening distrust and jealousy, with each one increasingly convinced that the other had betrayed him.  Finally Kevin took revenge by accepting the advances of the pirate king Redegard, leading in the end to the Battle of Six Storms in which all three were drowned.

                              As if reading your mind, Breden says, "We're not Kevin and Leir, ${fname}.  None of us.  Do you see the other outlaws here going mad and killing each other?"

                              "Not yet," you say, half-seriously.  "But Breden—this isn't the way the world works.  Up here, we all have to stick together, because we're facing a greater enemy.  Down in normal life, rules and vows are all that keep Xaos at bay.  And we won't stay up here in the woods forever.  We've got to set the example here that we'll live by after we've won."

                              Breden looks away with a helpless laugh.  "Well, if I had any doubts before, I don't now.  You truly, truly believe we're going to win."

                              "Of course I do. And one way it'll happen is by convincing everyone that we're not Xaos-lovers."
                              *if aristo
                                You know all too well how important chastity is to devout or traditional noble families; it's the most widely respected evidence of loyalty and orderliness.  "Chastity is the clearest sign that we care about Order—about all the rules that separate us from the animals."

                                Breden steps away from you, rubbing ${xhis} forehead; ${xhis} tone is less warm than it was.  "${fname}…have a care with that 'animal' talk.  I know you grew up hearing it all the time.  I know you're thinking of dogs and horses when you say it.  But we've heard enough of nobles telling us we're animals because we don't follow their rules."

                                You manage to swallow your first angry, defensive retort.  "I'm sorry.  Really—I am.  But it's important to show that we're not breaking all the rules.  The right reputation might actually bring more of the right people onto our side.  A few more people like me."

                                "Let's hope so,
                                *if female
                                  kuria."  
                                *if male
                                  kurios."
                                *if romance = 25
                                  Breden is stiff and silent for a moment.  Then ${xhis} face relents into a rueful grin.  "I'm sorry, ${fname}.  I don't mean to act the dolt.  When dreams you've held for months start coming true, it's easy to get greedy and want them all at once."

                                  You lean in for a final kiss.  "Thank you for…well, for getting me to dance.  And for being bold enough to say what we were both feeling."
                                  *goto alenext
                                Breden attempts a smile, gives you a stiff nod, and walks away.
                                *goto alenext
                              You scowl as you remember the nobles in your town and their many condescending references to helots' inability to govern their impulses.  "Breden…everybody will assume that because we're helots, we're animals who don't care about Order.  We've got to prove otherwise."

                              "Do you ever think you might be too worried about what the nobles, priests, and merchants think of us?" Breden asks irritably.

                              "Do you?" you ask sharply, stung and uncertain.  "Can we win alone?"

                              Breden rubs ${xhis} forehead and pauses before finally saying, "No.  But I don't know who you think you're actually going to impress with your self-control."  
                              *if romance = 25
                                $!{xhe} stays stiff and silent for a moment.  Then ${xhis} face relents into a rueful grin.  "I'm sorry, ${fname}.  I don't mean to act the dolt.  When dreams you've held for months start coming true, it's easy to get greedy and want them all at once."

                                You lean in for a final kiss.  "Thank you for…well, for getting me to dance.  And for being bold enough to say what we were both feeling."
                                *goto alenext
                              $!{xhe} attempts a smile, then walks away.
                              *goto alenext
                            *selectable_if (skepreal < 51) #The Angels bless the intimate union of bodies—but only within the sacred covenant of matrimony.
                              *label sacredmatrimony
                              *set bred_lover 7
                              *set skepreal %-15
                              *set skep %-15
                              "Breden, 
                              *if romance < 20
                                you know 
                              I'm not ready to marry."  You try to keep your voice light.  
                              *if romance < 20
                                "I told you before.  It's
                              *if romance > 19
                                "It's 
                              the Angelic way.  We're called to be loyal to just one other person, for life.  It's a way to show our dedication to Order—the union of bodies is a symbol of the Oneness that the world is founded on."

                              Breden sighs. "I know 
                              *if romance < 20
                                you've said so, 
                              *if romance > 19
                                that's the doctrine, 
                              ${fname}.
                              *if helot
                                The Diakon in our camp preached it too."
                              *if aristo
                                Maybe we don't think enough about Canon in the helot camps."
                              $!{xhe} pauses for a moment, then adds, "Just seems to me that it wouldn't break the unity of the world if we shared a bed."

                              "I know it wouldn't."  You reach out for ${xhis} shoulder, wondering how to make ${xhim} understand.  "But yes, this matters to me.  Everyone knows that carnal passion is one of the most common doorways for Xaos in the world.  The Karagonds are going to say we're Xaos-lovers because we don't follow their
                              *if skepreal <= 50
                                bits of the
                              Codex of Liturgy, and they'll dredge up any evidence they can find.  I don't want to give them the least satisfaction."

                              Breden bursts out laughing, and you feel your cheeks heat up as you realize why ${xhe}'s amused.  "Or me either, apparently?  Fine, fine."  $!{xhe} leans in for a goodnight kiss, most of ${xhis} former irritation now transferred to you.  "Sleep the sleep of the saintly.  I'll try again tomorrow."
                              *goto alenext
                            *if romance < 20
                              #I'd not known ${xhim} long enough before we fled to the woods—and I'd prefer our first lovemaking to take place where we can have a little privacy.
                                "Yes.  I'll be reminded of that, all night long."  
                                *label alittleprivacy
                                *set bred_lover 8
                                You cast a wry eye up to the main tent, imagining how much less discreet people are going to be tonight than usual.  "I've told you all winter that I want our first time, at least, to be without an audience.  The ale hasn't changed that.  Sorry."

                                "The woods have privacy."

                                "And mud, and sharp rocks, and pine cones.  I'd like a bit of comfort, too, thanks."

                                *if aristo
                                  "Are all aristocrats as soft as you?"
                                *if helot
                                  "Are you sure you're actually a helot?"
                                Breden's exasperation sounds about half amused.  "You know, we might be living this merry woodland life for years.  Are you really going to hold out for linen sheets?"

                                You confirm that ${xhis} complaints are no match for your lips.  "Look.  When we finally take each other, I want to see you.  I want to be able to see every inch of you,"  you interrupt yourself with another kiss,  "every curve of you, every muscle that moves in your face.  So, no.  No sneaking off into the woods by night.  No grappling in a muddy bedroll while the rest of the band lie there listening.  Nothing in darkness and cold, nothing hurried.  All right?"

                                Breden flings up ${xhis} hands.  "Just promise me, when spring has properly arrived and the air is warm…we'll go on a long hunt together.  Halfway to Whendery, miles from anyone.  Camp in a nice dry clearing.  With a waterfall.  And no bloody pine cones."

                                "Done."  Your last kiss takes up a good few minutes; you finally have to break it off before it resurrects Breden's hopes for the night.
                                *goto alenext
                            #I only sleep with someone I trust completely.
                              *label moretrust
                              *set bred_lover 9
                              *if romance = 20
                                You look ${xhim} over for a moment before replying.  "Breden…some day soon, you'll probably joke with me that we would have been a lot warmer all winter if we'd been sharing a bedroll.  And I'll agree with you, and beg your forgiveness.  And we'll make up for lost time.  But…not yet."

                                "Well.  At least you'll stoop to a dance with me."  Breden sighs, a little unsteadily, and murmurs as ${xhe} walks past you, "An honest fool—but a fool."
                                *goto alenext
                              It's hard to explain to Breden why 
                              *if romance < 20
                                you've held 
                              *if romance > 19
                                you would hold
                              back from taking ${xhim} into your bed.  The truth is, however beautiful ${xhe} is, you don't yet feel you know ${xhim} well enough for that level of trust.
                              *if romance = 18
                                You just haven't been able to ignore the possibility that ${xhe} betrayed the other young helots to Chirex.

                              "I'm sorry, Breden," you say.
                              *if romance = 25
                                "Let's not try to run before we're comfortable walking."

                                "As you say, ${kuria}."  Breden is silent for a moment; then ${xhis} face relents into a rueful grin.  "I'm sorry, ${fname}.  I don't mean to act the dolt.  When dreams you've held for months start coming true, it's easy to get greedy and want them all at once."

                                You lean in for a final kiss.  "Thank you for…well, for getting me to dance.  And for being bold enough to say what we were both feeling."
                                *goto alenext
                              "You've been very patient—and my answer is still no, for now."  Then, perhaps with a certain ale-fueled bitterness, you add, "Maybe you should find Ciels.  $!{he} might not be spoken for yet."
                              
                              "Don't be an idiot," Breden says with some heat.  "I don't want just anyone, ${fname}.  And I don't appreciate the loyalty tests."  $!{xhe} stalks off into the night before you have a chance to reply.
                              *goto alenext
                  *selectable_if (bred_trust != 2) #I think I love Breden, but I'm nagged by the fear that ${xhe} might be the traitor in our midst.  I change the subject.
                    *set romance 18
                    "Every life has too few springs," you say.  "And you're wasting this one on too much thinking and talking."  Before Breden can say anything, you pull ${xhim} toward you and give ${xhim} a deep, hungry kiss that leaves ${xhim} short of breath.  "Dance with me."
                    *goto kissfall
                  *selectable_if (bred_trust != 2) #My old love for Breden hasn't survived a winter of constantly wondering whether ${xhe} betrayed us.  It's time to end things with ${xhim}.
                    *set bred_lover 3
                    *label downgently
                    You place one hand on Breden's shoulder and step away from ${xhim}.  "Breden…it's not fair for me to keep tormenting you like this."

                    "What is that supposed to mean?" ${xhe} says colorlessly, hands falling to ${xhis} sides.

                    "When you don't see signs of love from me, you think it means I don't trust you.  But it doesn't.  It just means I don't love you."

                    Breden gives a nod so slow as to be almost imperceptible. "I see.  And when did that change?"

                    "I don't know.  Sometime over the last few months.  We're…all different people than we were back in the village."  You hold out your hands helplessly.  "I'm sorry, Breden.  I truly am."

                    *if cha < 2
                      *set bredsuspnow true
                      Breden leans back toward you; there's something in ${xhis} eyes that makes you nervously aware of the knife at ${xhis} belt.  "You're useless as a liar, ${lname}."  $!{xhis} words hiss through your apologies.  "So you think I'm a traitor after all."

                      Sometimes you wish that—like Breden ${xhim}self—you had the gift of sounding credible no matter what you're saying.  "I don't know what to think, Breden."

                      "What's wrong with you, ${lname}?"  Breden's voice is thick as ${xhe} gazes around the ring of noisily celebrating outlaws.  "All these people you don't know…and you decide to distrust the one who's closest to you."
                      *if zvad > 2
                        *label bredzvad_1
                        You and ${xhe} notice at the same moment that Zvad is watching you steadily from across the circle.  Breden meets the Whend's cool gaze for a moment, then turns back to you.  "${fname}—why has Zvad been following me everywhere?"  When you hesitate, ${xhis} eyes widen with abrupt horror.  "Tell me you didn't. Please, please, tell me you didn't share your…crazy suspicions with Zvad."
                  
                        "Breden…"  You try to hush ${xhim} as heads begin to turn in your direction.

                        "Oh, Xthonos damn you," Breden half-laughs, half-sobs.  "He's going to kill me."  $!{xhe} pushes a finger savagely into your collarbone.  "You forced this on me.  Remember that when the real traitor sells you to the Theurges."  Before you can say anything else, ${xhe} stalks away.
                        *set breden +10
                        *set bred_trust 11
                        *set bred_here false
                        *goto alenext
                      $!{xhe} stalks away into the night, leaving you standing alone.
                      *set bred_trust 11
                      *goto alenext
                    Your charisma makes you an effective liar; Breden takes you at your word when you say that you don't suspect ${xhim} of treachery.  $!{xhe} merely lurches away from you, shaking ${xhis} head as if to clear it.  "Well…then Xthonos damn you for that dance."

                    You half-expect ${xhim} to head back to Ciels, but ${xhe} simply stalks away into the night.
                    *goto alenext

              *elseif (bred_lover >= 4) and (bred_trust > 9)
                Breden takes a few steps back from you, lips twisted in a regretful smile.  "You know, ${fname}, the rest of the band have been keeping themselves warm with dancing this whole winter."  $!{xhis} eyes search for yours.  "Seems to me that you and I have been colder than we needed to be."

                You've missed being held by ${xhim}, and you're sure ${xhe} knows it.  You say:
                *choice
                  #"You're right, love.  We should have been dancing all winter long."
                    Breden steps in closer to you again and speaks almost inaudibly.  "Even though you still think I might be the traitor?"
                    *set romance 20
                    *label honestfool
                    *choice
                      *if (not(choice_randomtest)) #"I don't think that, Breden."
                        *label honfool2
                        Breden gives a sharp, angry shake of ${xhis} head.  "Please, ${fname}.  If you're going to be a suspicious fool, at least be an honest fool."  Before you have a chance to reply, ${xhe} has stalked away
                        *goto backtociels
                      *if (not(choice_randomtest)) #"I've still no idea who the traitor is."
                        "Or isn't," Breden growls.  "No one's come off your list, yet."
                        
                        "Should anyone have?"  It's hard not to be irked by the resentment in ${xhis} tone. "I've barely had the time to look into it, what with keeping us alive through winter."
                        
                        *label andthose
                        "And those who risked their lives to bring us through that winter…that doesn't prove their loyalty?"
                        
                        "Goes a long way toward it."  You fold your arms. "You want me to say it means everything.  It doesn't, and you should see that as clearly as I do.  But that doesn't mean it means nothing, either."
                        
                        Breden steps back with a rueful, reluctant, and still half-angry smile.  "Well. Thank you for the honesty.  Look forward to when you decide you've enough proof to trust me fully."
                        *set bredalien true
                        *goto alenext
                      #"Yes.  Even so."
                        Breden draws ${xhim}self up, 
                        *if (bred_lover < 4) and (romance != 25)
                          glowering.
                          *goto andthose
                        glowering; as ${xhe} opens ${xhis} mouth, you brace for a withering retort.  Instead ${xhe} leans in and closes ${xhis} lips fiercely against yours.  "You're a suspicious fool, ${lname}," ${xhe} informs you through the kiss.  "But at least you're an honest fool."
                        *if romance = 25
                          *choice
                            #I pull away in dismay.
                              *set bred_lover 2
                              As you recoil Breden hastily raises ${xhis} hands, saying, "I'm sorry, ${fname}.  I was carried away…"
                              
                              "Don't ever do that again," you interrupt ${xhim} sharply.  "I said I didn't know how I felt.  I didn't ask you to try to make up my mind for me."

                              Breden's face crumples.  "I'm sorry," ${xhe} repeats, voice thick with shame and unhappiness.  $!{xhe} turns and stumbles away from the bonfire.
                              *goto alenext
                            #I return ${xhis} kiss with passion.
                              *goto kissfall
                            #When the kiss ends, I step away, unsure of how I feel.
                              You and Breden stand silently for what feels like a long time.  Eventually, ${xhis} expectant face collapses into a small, broken smile.  "I'm sorry, ${fname}.  Try to forget all this—it's just the ale.  Let things go back to normal in the morning."

                              "I'm not going to forget it," you say quietly, stepping up to ${xhim} again.  "Breden…I'd be lying if I said I felt nothing for you.  I'm not sure what it all adds up to, but…give me time to sort out what I think, and we'll talk again."  

                              A bit of hope re-enters ${xhis} eyes. "Until the next time I convince you to dance with me, then?"

                              "Until our next dance."  You brush your lips very quickly against ${xhis} again—and feel the same physical jolt as when ${xhe} kissed you the first time.  Before the kiss turns serious, you bid Breden good night and quickly walk off.
                              *goto alenext
                        *goto kissfall
                  *if (not(choice_randomtest)) #"We'll have to bear the cold for a little while yet."
                    *label chilly
                    Breden presses ${xhis} lips tightly together.  "I'm sorry you feel that way, ${fname}.  Truly sorry."  
                    *label bredstride
                    $!{xhe} turns and strides back  
                    *label backtociels
                    *set bredalien true
                    *set ciels 14
                    to ${xhis} previous dancing partner.  Ciels looks surprised and glances nervously in your direction, but Breden just laughs and pulls ${him} back into the dance.

                    You sit by the singers for a long time, 
                    *if not(acepref)
                      trying to enjoy the revelry and jokes.  But the evening has lost any savor for you, and you retire early, reclaiming 
                    *if acepref
                      enjoying the revelry and jokes, before reclaiming
                    your bedroll from where it's been hanging near the bonfire.  
                    *if not(acepref)
                      At least you'll sleep 
                    *if acepref
                      You can't imagine any physical bliss greater than sleeping
                    in a dry blanket tonight for the first time in many clammy, miserable weeks.
                    *goto alenext
              *elseif (bred_heart = 3)
                Breden takes a step or two away from you, eyes bright and uncertain. "The things you said to me in Rim Square, ${kuria}…do they still hold true?"
                *choice
                  *if (not(acepref)) #I pull ${xhim} back to me, close enough to feel ${xhis} breath on my lips. "Now's your chance to find out."
                    $!{xhe} breaks into a smile…then 
                    *if bred_trust > 9
                      says almost inaudibly, "Even though you still think I might be the traitor?"
                      *goto honestfool
                    leans forward to close the minute distance between your lips.
                    *goto kissfall
                  #"Love—of course they do."  After all ${xhe} contributed to the band's survival, you feel closer to Breden than ever.
                    "All the winter's done is give me more signs of how extraordinary you are."  You've certainly seen more than ample evidence of ${xhis} courage and passion for the cause.  "I'm sorry I was so consumed by…well, ${oath}, by making sure we all lived.  I know we've not had the time together I would have wanted."
                    
                    Breden glances around the jubilant outlaws, then walks you out to the edge of the crowd. "Some in the band have asked if I'm your lover, ${kuria}."  $!{xhis} lips quirk wryly. "I don't quite know what to tell 
                    *if bred_trust < 10
                      them."
                    *if bred_trust > 9
                      them.  Angels—I don't even know if you trust me."
                    *label labelchoice
                    *choice
                      *if ((bred_trust > 9) and (trusttick)) #"Of course I trust you."  And I do.
                        *set trusttick false
                        You lean forward, looking straight into ${xhis} eyes. "Breden, I saw enough during the winter to realize that I should never have suspected you.  I may not have known you long, but I've known you long enough
                        *if (bred_lover >= 4) or (bred_heart = 3)
                          and well enough
                        to know you're no traitor.  I lost sight of that, and I'm sorry."
                          
                        Breden searches your face for at length before saying, with lingering incredulity, "I think I believe you." $!{xhis} hands close around yours, trembling. "That doesn't answer my question about…what we tell the band."
                        *set bred_trust 2
                        *goto labelchoice
                      *if ((bred_trust > 9) and (trusttick)) #"Of course I trust you."  I wish I did.
                        *set trusttick false
                        *if cha < 2
                          *goto honfool2
                        "After all we went through in the winter, 
                        *if deputy = "Breden"
                          with you as my strong right hand…how
                        *if deputy != "Breden"
                          and all I saw of you…how
                        could I not trust you?"
                        
                        Breden studies your face for some time before saying, "I'm glad to hear it, ${bfname}."  You can hear the lingering doubt in ${xhis} voice. "That doesn't answer my question about…what we tell the band."
                        *goto labelchoice
                      *if (bred_trust < 10) and not(acepref)
                        #"We can tell them we're lovers."  I lean forward and kiss ${xhim}.
                          *goto kissfall
                      #"Tell them we're courting.  Chastely."
                        *set bulwark true
                        Like everyone raised under the Angels' Canon, your outlaws were taught that chastity and matrimony are a crucial bulwark against Xaos—taming the unruliest of passions, quenching the uncontrollable violence of jealousy.  But you know it's also widely accepted that helot youth will often discreetly "range" a little before settling down with a spouse.
                        *if aristo
                          (There's nothing like the aristocratic rigidity you were raised with, where a whisper of unchastity can ruin a girl or boy's reputation and result in exclusion from devout society).

                        The Whendward bandits tend to be even more pragmatic and far less discreet.  As one of them wryly explained to you, "When life's this hard and short, ${kuria}, you don't ask, 'Am I letting more chaos into the world?'  You just ask, 'Would it make him happy—and will anyone else knife me for him?'"
                          
                        *if aristo
                          "I suppose they'll believe it from you,
                          *if male
                            kurios.
                          *if female
                            kuria
                          ${lname}." 
                        *if helot
                          "As if we're aristos?  Angels, ${fname}, don't let being captain go to your head."
                        Breden pauses, exhaling through ${xhis} teeth. "And will we ever be other than chaste in our courting?"
                        *label otherthanchaste
                        *if acepref
                          *choice
                            *hide_reuse #"Isn't it enough for you to have my time, my thoughts, my heart?"
                              You struggle to imagine how anything the two of you did with your bodies would add to the long nights you've spent talking with each other.  When you've never shared yourself so deeply with anyone else, it's hard not to bristle at the idea that it's somehow inadequate.
                                
                              *label notenuf
                              Breden sees the hurt in your face and looks away with a despairing laugh. "Angels, ${fname}, it means the world to me.  And yes, it's been enough."  $!{xhe} fixes ${xhis} eyes on yours. "But it won't be enough forever, my love.
                              *if acepref
                                I'm not made that way.
                              And we may not have another spring.  Is there no chance?"
                              *goto otherthanchaste
                            #I shake my head.  "Breden…that's just not who I am."
                              For a long time, ${xhe} stares back toward the fire without speaking.  "And if I seek that elsewhere?  
                              *label freeroaming
                              What would it mean for you and me?"
                              *choice
                                #It would be a relief, to be honest.
                                  *set ciels 11
                                  "As long as you and I can stay as close as we are…why would it matter to me if you're twining bodies with someone else?"
                                  *if aristo
                                    You can't say it without a tremor; it's no light thing to so flagrantly rebel against the chastity code ground into you from childhood.  But it's unquestionably what your heart feels.
                                  *if helot
                                    You've known plenty of helots who had to make some similar accommodation between their heart's love and their safe-mate.
                                  "Satisfy yourself as you please, love.  Only come back to me."
                                  *label btociels
                                    
                                  Breden looks up sharply at you. "Can you truly mean that, ${fname}?"
                                    
                                  "Breden…"  You almost have to laugh at the mix of hope and guilty hunger on ${xhis} face.  What an odd thing it must be to have such a small thing matter so much. "I truly don't care.  Go.  Enjoy yourself, and come back when your head is clearer."
                                    
                                  When ${xhe} embraces you, you can feel the unusual heat in ${xhis} cheeks and neck, and ${xhis} voice is thick. "I'll still wish it were you.  But thank you, ${fname}."  $!{xhe} strides back and pulls Ciels out of the crowd.  The young ranger looks surprised and glances nervously in your direction, but Breden just nods to you and draws ${him} back into the dance.
                                  *goto alenext
                                #"As long as it stays just a matter of bodies, not of hearts."
                                  *set ciels 12
                                  You couldn't bear for Breden to fall in love with anyone else—but it seems obvious to you that twining souls and twining bodies are two very different things. "As long as it doesn't end up with you giving more of your heart to someone else than you do to me…satisfy your body as you please."
                                  *goto btociels
                                #I can't face the idea of Breden being intimate with anyone else, body or heart.
                                  *set ciels 2
                                  "It would mean the end, Breden."  You swallow against a suddenly dust-dry throat. "I can't share you like that.  I understand if that means you need to…"
                                    
                                  "No." Breden puts a finger to your lips, ${xhis} face frightened and fierce. "I shouldn't have said it, love.  I'm sorry.  To find someone I can be as close to as I can with you, and as honest…there's nothing I could find elsewhere that outweighs that.  We don't need to change.  I'm so sorry."
                                    
                                  After a moment, you reach out to ${xhim}, arms shaking slightly. "Another dance?"
                                    
                                  "Aye, love." $!{xhe} accepts your hands and draws you back into the circle. "Always."
                                  *goto alenext
                            #After a long pause, I say: "If it's so important to you, love…we can try."
                              *set bred_lover 11
                              Breden looks up sharply at you. "Truly, ${fname}?  I mean…you said you'd never wanted…"
                                
                              You offer ${xhim} a smile.  "I don't.  But I can see how much you do, and I love you, and I don't want to leave you wretched."
                                
                              Breden tries and fails to return the smile.  "Well, I can't say I was ever happy with the idea of mating with someone
                              *if ((xhe = "he") and (he = "she")) or ((xhe = "she") and (he = "he"))
                                who didn't want it, just for the sake of their
                              *if xhe = he
                                when I didn't want it, just for the sake of 
                              surviving a Harrowing.  I'd like to be…truly wanted, ${fname}."
                                
                              "I truly want to make you happy.  Can that be good enough?"
                              
                              After a moment's silence, ${xhe} leans forward and slowly brings ${xhis} lips to yours.  It's as odd a sensation as you'd always suspected; there's clearly some trick to avoiding ${xhis} nose that you'll have to work out.  But you don't mind it, and quite enjoy the stupefying impact it seems to have on Breden.  
                                
                              "Angels," ${xhe} says hoarsely, closing ${xhis} fingers around your arm. "Take me back to the tent."
                              *page_break
                              *goto whoopie
                            #I feel close enough to ${xhim} to kindle something I've not felt before. "Take me back to the tent and we'll see."
                              Breden looks up sharply at you. "Truly, ${fname}?  I mean…you said you'd never wanted…"
                              
                              "I never have for anyone else."  You reach out to cradle ${xhis} face, then lean in and press your lips against ${xhers}.  It's as odd a sensation as you'd always suspected, and there's clearly some trick to avoiding each other's noses that you'll have to work out.  "But I've never twined as much of my soul with anyone else as I have with you."
                              *set bred_lover 12
                              
                              *goto whoopie
                        *else
                          *comment if not acepref
                          *choice
                            *hide_reuse #"Isn't it enough for you to have my time, my thoughts, my heart?"
                              Surely that's the important thing.  Over the long nights you've spent talking, you've shared more of yourself with Breden than you have with anyone else on earth.  How much would a conjunction of bodies add to that?
                                
                              *goto notenuf
                            #"If we marry."  I've heard my whole life that un-Ordered sexual union invites jealousy, madness, and chaos.
                              *goto kevinandleir
                            *selectable_if (skepreal < 51) #"If we marry." The Angels bless the intimate union of bodies—but only within a state of matrimony.
                              *goto sacredmatrimony
                            *if (aristo) #As a young noble, I maintained a chaste reputation, and that's an asset I won't relinquish lightly.
                              *goto nobleasset
                            #"Not until we can be a bit more discreet about it."  There's no privacy to be had in a bandit camp.
                              *goto alittleprivacy
                            #"Perhaps in time."  When I trust ${xhim} more.
                              *if bred_trust > 9
                                *set romance 20
                              *if bred_trust < 10
                                *set romance 24
                              *goto moretrust
                      #"'Lover' would be the wrong word."
                        You love Breden, but you don't 
                        *if not(acepref)
                          yet
                        want others to assume that you're courting, let alone sharing a bedroll.
                        
                        Breden's eyes are intent.  "Will it ever be the right one? 
                        *if aristo
                          Or—forgiving my boldness, ${kuria}—will
                        *if helot
                          Or will
                        we remain the only two in the Whendward Band who say they love each other but sleep apart at night?"
                        *goto otherthanchaste
                      *hide_reuse #"Why care what they think?"
                        Breden shakes ${xhis} head, grinning despite ${xhim}self.  "I don't, ${bfname}, as you might have guessed.  [i]I[/i] want to know what you'd say of 
                        *if (bred_trust < 10) or not(trusttick)
                          us."                          
                        *if (bred_trust > 9) and (trusttick)
                          us.  And whether you still think me a traitor." $!{xhis} face darkens slightly as ${xhe} utters the last word.
                        *goto labelchoice
                  *if (not(choice_randomtest))
                    *selectable_if (bred_trust != 2) #The love I felt for Breden hasn't survived a winter of constantly wondering whether ${xhe} betrayed us.  I'll try to let ${xhim} down gently.
                      *set bred_heart 7
                      *goto downgently
                  *if (bred_trust > 9) #"How can they, until I know whether you betrayed us?"
                    *set bred_heart 7
                    *goto damnidiot
              *else
                *comment if bred_lover < 4
                Breden keeps ${xhis} light grip on your waist. "I have to confess something to you, ${kuria}," ${xhe} says gravely.  
                *if bred_trust > 9
                  "Your stupid, stubborn refusal to trust me isn't entirely groundless.  I had a
                *if bred_trust < 10
                  "A
                hidden motive for inviting you to our seditious meetings back in the village."
                *if acepref
                  $!{xhis} eyes are shining with unmistakable intent.
                  *choice
                    #A dance is all very well, but this can go nowhere good.  "Breden…I'm sorry, but it can't be."
                      *label acesplain2
                      *if aristo
                        Disappointment and anger mingle in ${xhis} eyes. "Presuming above my station,
                        *if male
                          kurios?"
                        *if female
                          kuria?"
                          
                        "Presuming to know my mind?" you retort, irked by ${xhis} bitter tone.
                      *label acesplain
                      *set bred_heart 8
                      "I've never wanted a lover, man nor woman.  I don't expect I ever will."
                      
                      The firelight casts stark shadows across Breden's suddenly blank face. "Never?"
                      
                      "Not with anyone, Breden."  You shake your head emphatically. "If there was ever a chance that I'd 
                      *if aristo
                        be forced into some marriage to perpetuate the ${lname} name,
                      *if helot
                        have to share my life with a safe-mate,
                      I'm free of it now.  And with a rebellion to lead, I can't imagine spending my energies on anything else."  [i]As unimportant as mating,[/i] you almost, but don't quite, add.
                      
                      "Well."  Breden runs ${xhis} hands through ${xhis} hair and manages a smile. "Thanks for the honesty, then, ${kuria}. And for a lovely dance."
                      *goto arochoice
                    *if bred_heart = 2
                      #$!{oath}. No more hiding what I feel for ${xhim}, then…
                        "A hidden motive?"  Your pulse is racing, and not just from the dance.
                        *goto didyou
                    *if bred_heart != 2
                      #Ah, ${oath}…I want to be closer to ${xhim} than I've ever been with anyone else.
                        "A hidden motive?"  Your pulse is racing, and not just from the dance.
                        *set bred_heart 2
                        *goto didyou
                    #I hear ${xhim} out.
                      "Did you?"
                      *goto didyou
                
                "Did you?"
                *if not(acepref)
                  Your pulse is still racing from the dance, you tell yourself.                  
                *label didyou
                  
                "Yes."  $!{xhe} studies your face, ${xhis} eyes intent and uncertain.  
                *if aristo
                  "At first, of course, I assumed it was unthinkable.  You were open-minded enough, for a noble…but how could you really understand a helot?  And then you stood up to Chirex.  I had never dreamt…"
                *if helot
                  "And when I asked you to stand with me that day, for Olen's wake?  It wasn't just because I'd heard you were a free-talker."  

                $!{xhe} falls silent, and you say:
                *set romance 25
                *choice
                  *if bred_lover = 0.5
                    #"You already know my secret motives," and kiss ${xhim}.
                      $!{xhe} expects your kiss, this time—but not its ferocity.  Caught off guard, ${xhe} lurches giddily backward, nearly sending you both into the fire.
                      *goto kissfall
                  *if not(acepref) and (bred_lover = 0)
                    #"I had my own secret motives," and kiss ${xhim}.
                      $!{xhe}'s caught off guard by the ferocity of your kiss and lurches giddily backward, nearly sending you both into the fire.
                      *goto kissfall
                  *if bred_heart = 2
                    #"I've had my own secret motives."  But how to explain them when ${xhe}'s so clearly hoping for a kiss?
                      *if aristo
                        "Please understand, Breden.  I've never felt…never had any desire to be carnally intimate with anyone.  Not a noble, not a helot.  And I don't want that now."  You're suddenly terrified that ${xhe}'ll take insult—that ${xhe}'ll think this is about the warnings of blood contamination in the Karagond Canon.  A
                      *if helot
                        "I've never felt…never wanted to share a bed with anyone, Breden.  And I don't want that now."  You're suddenly terrified that ${xhe}'ll take insult, and a
                      torrent of words tumbles out of your mouth.  "But…I've never met another soul like you.  No one half so dear.  I want to be with you, to hear everything you have to say.  To truly know you.  To love you."
                      
                      The firelight casts stark shadows across Breden's suddenly blank face. "Ah.  That…well.  That's lovely, ${bfname}."  Putting a hand to ${xhis} forehead, ${xhe} breaks into rueful laughter. "Angels, I'm sorry.  I don't think I've ever had such good news and such, ah, unexpected news in the same breath before.  No sharing a bed?  Never?"
                      *fake_choice
                        #"I've never had the desire."  I don't want to raise any expectations I can't fulfill.
                          After a moment's pause to see if you add anything else,
                        #"Even if I never feel the desire…that doesn't mean it will never happen."
                          Breden tries and fails to smile.  "Well, I can't say I was ever happy with the idea of mating with someone
                          *if ((xhe = "he") and (he = "she")) or ((xhe = "she") and (he = "he"))
                            who didn't want it, just for the sake of their
                          *if xhe = he
                            when I didn't want it, just for the sake of 
                          surviving a Harrowing.  I'd like to be wanted, ${fname}."
                          
                          "I want you—your time, your thoughts, your heart."  [i]Just not your body.  Not the way you want me to.[/i]
                          
                          "And that's no small thing."
                        #"I always wondered if, for the right person, I might find myself wanting it."
                          With your heart so twined with Breden's, you feel the spark of something—a warmth in your body, a desire for ${xhers}, in a way you've never felt before and wouldn't expect to feel for anyone else. "I can't promise anything, Breden.  But can we wait, and see?"
                          
                      Breden exhales gustily and reaches out to take your hand.  "I've never met another soul quite like you either, ${fname} ${lname}.  I'd hoped you'd feel the same thing for me that I do…"  A smile begins in one corner of ${xhis} mouth, small but genuine. "And maybe it's the same in the ways that matter most.  Do two people ever truly love each other the same way?"
                      
                      "What does that mean?" You can hardly dare to hope that it's ${xhis} final word.
                      
                      "It means I'd like to dance again, my love."  $!{xhe} reaches out to accept your hands. "And to truly know you, as you said."
                      *set bred_heart 3
                      *if aristo
                        *set bfname fname
                      *goto alenext
                  #"Breden…I don't know what to say."
                    *if (bred_trust > 9) and not(acepref)
                      Breden steps in closer to you again and speaks almost inaudibly.  "Because you still think I might be the traitor?"
                      *goto honestfool
                    Breden spreads ${xhis} hands in a helpless gesture.  "Does it really come as a surprise?  I thought I was being obvious."  

                    "I didn't want to assume anything."  All you had seen in ${xhim} was enthusiastic friendship and a shared passion for a freer world.  The idea that you misread ${xhis} passion is more disconcerting than you would have expected.  "You weren't obvious."

                    "I thought…ah, Xaos."  Breden looks suddenly very uncomfortable, but forges stubbornly ahead.  
                    *if deputy = "Breden"
                      "I thought with all the time we'd been spending together…since you decided to make me your second in command, even though Zvad had so much experience…."
                    *if deputy = "Zvad"
                      "I thought that was part of the reason you hadn't been including me in any decisions, since we came out here to the woods.  That you were keeping your distance because you were afraid of what I felt.  Or what you felt."  
                    The dance begins again, the other outlaws circle around you, but neither of you speaks or moves away.  Eventually, ${xhis} expectant face collapses into a small, broken smile.  "I'm sorry, ${bfname}.  Try to forget all this—it's just the ale.  Let things go back to normal in the morning."
                    *if acepref
                      *choice
                        *if (not(choice_randomtest)) #That's what I'm most comfortable doing.
                          "Until the morning, then," you say, a bit stiffly. 
                          *goto bredstride
                        #I want ${xhim} to understand why I can't return ${xhis} passion.
                          "Another ${woman} might have seen the signs more clearly, Breden," you offer sympathetically.
                          *goto acesplain
                        #I feel something for Breden.  Not what ${xhe} wants…but not nothing, and I want ${xhim} to know it.
                          *goto notgoing
                    
                    *label notgoing
                    "I'm not going to forget it," you insist, stepping back to ${xhim}.  "Breden…I'd be lying if I said I felt nothing for you.
                    *if acepref
                      You should know that I've never wanted a lover, and I still don't.  Not 
                      *if aristo
                        for carnal intimacy.
                      *if helot
                        in the swiving way.
                      But there's more to love than that, and…"  You see the bemusement on ${xhis} face and cut yourself off with a groan.  "Ah, ${oath}.
                    I'm not sure what it all adds up to, but…give me time to sort out what I think, and we'll talk again."  

                    *if not(acepref)
                      A glint of hope reappears in ${xhis} eyes.
                    *if acepref
                      $!{xhe} stares at you for a moment before breaking into a ragged smile.
                    "All right, ${bfname}.  Let me know when you've thought it over."
                    *goto alenext
                  #"Breden…this can never be between us."
                    $!{xhis} expectant face collapses into disappointment.  "I'll probably regret asking this, ${fname}," ${xhe} says in a small voice.  "But…why?"
                    
                    *if acepref
                      *goto acesplain
                    To yourself, you can admit the truth:
                    *fake_choice
                      #$!{xhe}'s undeniably attractive, but I'm just not drawn to ${xhim} in that way.
                      #The immaturity and poor judgment I've seen from ${xhim} has put me off.
                      #I don't trust ${xhim}.
                    "You're beautiful and strong, Breden.  Anyone would be honored to have you at their side.  But…"  You try to think of what you can say.  "You know the old story about finding your other half."  

                    Breden gives a leaden nod.  Everyone knows the myth, which is even older than the Angels' Codex where most of you first heard it.  Before birth, each person was joined to someone else in a single, perfect body with two faces and eight limbs.  Then we were all split in half, and each half sent incomplete and lonely into the world.  "You recognize your missing half when you finally find ${xhim}.  And I'm not ${xhim}."

                    "I'm sorry, Breden."

                    $!{xhe} steps close to you, ${xhis} face drawn and desperate.  "What happens when one person recognizes it and the other doesn't?"

                    "One of them has made a mistake."

                    Breden slowly nods again, ${xhis} desperation hardening into something colder and less vulnerable.  "Clearly.
                    *if aristo
                      After all, having a helot as your 'missing half' would be bloody humiliating."
                    *if helot
                      Well…then Xthonos damn you for that dance."
                    $!{xhe} stalks away into the night before you can say another word.
                    *set bred_lover -10
                    *if aristo and (bfname = fname)
                      *set bfname (kuria&" ")&fname
                    *goto alenext

            #"I'll step on your toes.  But if that doesn't put you off…aye, one dance."
              "Delighted."  Breden bows with a grin.  "Need to get some feeling back into my toes, anyway."
              
              *goto ok_dance
            *if (not(aropref)) #"Oh, I wouldn't want to steal you from Ciels."
              Breden glances back to Ciels, who's watching the two of you with scarcely veiled curiosity.  "I think ${he} could live with the disappointment."

              "You shouldn't play with ${his} heart that way," you say chidingly.  "The way you were dancing with ${him}, it was practically a promise."

              *if bred_lover > 0
                "Why are you being a jealous ass?" Breden whispers, stepping in close to you.  "So I danced with Ciels before I danced with you.
                *if bred_trust > 9
                  You pushed me away and called me a traitor, remember?
                  *if rollover4
                    And you shut me out of the most important raids of the winter.
                  I don't owe you a damned thing.  But
                I'm asking you for a dance now."
              *if bred_lover <= 0
                Breden's eyes flare angrily and remain smoldering.  "If you thought that, jealous ${kuria}, you need to learn the language of dancing better.  Let me teach you what a real promise-in-dance is like."
              *choice
                #Dance with ${xhim}.
                  *goto ok_dance
                *if (not(choice_randomtest)) #Decline again.
                  *goto chilly
                *if (acepref and ((bred_heart != 2) and (bred_heart != 3))) #"Breden…it's not the kind of promise I'd ever be interested in."
                  *goto acesplain2
            #"I've never been much of a dancer.  You'll find better partners, I think."
              Breden looks appraisingly at your feet, then grins up at you. "No.  No, I don't think I will."
              *choice
                *if aropref
                  #Time to be clear with ${xhim}. "Breden…I think you're looking for something I'll never be interested in."
                    *goto acesplain2
                *if (bred_heart = 3) and acepref
                  #"Dancing isn't something I'd much enjoy, love."  I've never seen the point in it.
                    "It's something I would."  Breden's grin doesn't falter.  "Unless you truly couldn't bear it…would you humor me?"
                    *choice
                      #"If you were in any doubt of how much you mean to me…" Grinning resignedly back, I let ${xhim} pull me into the dance.
                        *goto ok_dance
                      #It's an uneasy feeling, letting ${xhim} draw you out like this.  "Let's try, then."
                        *goto ok_dance
                      *if (not(choice_randomtest)) #"I'm sorry, love. It would just feel too strange.  Not like myself."
                        Breden nods slowly, trying to swallow ${xhis} disappointment. "As you wish, then, ${bfname}.  I hope you'll understand if I dance with others."  $!{xhe} starts to walk away—then turns back, ${xhis} eyes strange in the firelight. "If things ever went beyond dancing, ${fname}, with someone else?
                        *goto freeroaming
                #"Well…don't say you weren't warned."
                  *goto ok_dance
                *if (not(choice_randomtest)) #"I'm sorry.  After all we've been through, I don't feel like dancing."
                  *if bred_trust > 9
                    *goto chilly
                  Disappointment and sympathy war across Breden's face. "Well.  Sorry to hear it, ${bfname}.  Perhaps another time, then."
                  *goto bredstride
                *if (not(choice_randomtest)) #I say flatly, "I don't want to dance with you, Breden."
                  *if bred_trust > 9
                    *goto damnidiot
                  *goto chilly
            *if bred_trust > 9
              #"No.  Not interested."
                *label damnidiot
                *set bredsuspnow true
                *set bredalien true 
                Breden's smile drops off ${xhis} face.  "Walk with me, ${kuria}," ${xhe} says in a tight, angry voice, beckoning you away from the other outlaws.

                You find ${xhis} demanding tone of voice insufferable and without moving, reply, "Say what you have to say." 

                $!{xhis} eyebrows leap up ${xhis} forehead, and ${xhe} leans in to you, making little effort to keep ${xhis} own voice down.  "Fine.  You're a damned idiot, ${lname}.  Not just because you've decided not to trust me—with no good reason—but because you're so clearly determined to insult me.
                *if rollover4
                  Tonight, or on the Alastor raid.
                *if deputy = "Breden"
                  You think you can treat me like a suspect and your strong right hand at the same time?
                What happens when you find that someone else was your culprit after all?  You think you'll just apologize and everything will be fine again?"

                "Breden, 
                *if not(dance)
                  all I said was that I didn't want to dance with you.  
                *if dance
                  I said nothing I haven't said to you before.
                Calm down and stop making a fool of yourself."

                Breden shakes ${xhis} head in a sharp, savage negation.  "You're wasting my loyalty, throwing it away for nothing, and you won't even hear it.  Who's next?  What happens when you decide to suspect Zvad?"
                *if zvad > 2
                  *goto bredzvad_1

                "You're embarrassing yourself," you bark, aware that heads are starting to turn your way all around the bonfire.  You're sure Zvad has been watching you silently since your altercation began.  "I won't talk with you while you're like this.  Go sober up and go to sleep."  Breden snaps ${xhis} mouth shut and storms away from the bonfire.
                *goto alenext
            *if (bred_lover < 4) or (bred_trust > 9)
              #"With you?  I'd sooner throw myself into the fire." I can't keep my dislike for ${xhim} in check any longer.
                *set bredalien true 
                *if not(acepref)
                  That momentary, treacherous flicker of attraction only fuels your fury. 
                *if bred_trust > 9
                  "You think you can throw insults at me, call me brainsick to cover up your own cowardice, and still expect a dance?"
                *if bred_trust <= 9
                  At the moment, all you want is to put a hole in ${xhis} insufferable confidence. "With so many others worshiping the ground you walk on, you think you'll add me to the list?"
                Your sharp, humorless laugh is probably audible from the Rim. "Go to Taratur, ${xgirl}. You'll never have me."
                
                The outlaws all around you fall silent, shocked at your public shaming of
                *if deputy = "Breden"
                  your deputy.
                *if deputy != "Breden"
                  such an influential band member.
                All Breden's muscles are tensed as if to run, or strike you. "Angels, ${lname}. Where…? All I asked was a bloody dance, and you…"
                
                "Wanted to be plain." You hadn't realized before how much you'd resented holding your tongue for the peace of the band. "We're not friends, Reaper, and certainly nothing more than friendly.
                *if bred_lover >= 4
                  Not any longer.
                Don't act as if we were."
                
                "No damned fear of that, ${kuria}." As ${xhis} shock recedes, Breden's face comes to mirror your own contempt. "I know where I stand now."

                Within minutes, Breden is in Ciels's arms again, circling the bonfire, pointedly ignoring you.  Perhaps unsurprisingly, no one else dares ask you to dance.  $!{xhis} many friends in the band cast hard glances at you; Radmar, on the other hand, bares his teeth in evident approval.
                *set bred_heart 10
                *set r_rel +5
                *set morale -(bred_lead*2)
                *goto alenext
        *label alenext
        
        The next morning, you break camp at sunrise to evade any Theurges who might have spied the fires.  Several outlaws complain of having to rise at dawn with their heads still thick from ale, but they chuckle as they grumble.
        *if ((breden > 10) and not(nobred)) and (zvad > 1)
          *page_break
          *set followers -1
          *set nonkids -1
          *set deputy "Zvad"
          The cheery mood dissipates as the news spreads that Breden is gone.  $!{xhe} never returned to ${xhis} tent, and although the perimeter guards didn't see ${xhim} pass, ${xhe} is clearly nowhere to be found.  

          "Do we hunt for ${xhim}, ${kuria}?" 
          *if rescuer = 0
            Hetten the brewer 
          *if rescuer != 0
            Pitrj
          asks.  Like most of the band, he saw the end of your confrontation with Breden last night.  He's clearly unsure whether the popular young helot's disappearance is due to a personal quarrel or something more serious.

          "No time," you say curtly.  "$!{xhe}'s made ${xhis} decision.  We don't force anyone to stay with the band."  

          As the rest of the band begins to move out, you beckon Zvad to one side.  "Our best scouts will be combing our backtrail, ${kuria}," the Whendish bandit rumbles before you've said anything.  "If ${xhe}'s trying to follow us, or lead any trouble to us, we'll know."  You nod your gratitude.

          But there's no sign of Breden.  Not that day, not in the following days, as you lead the band deeper into the wilderness.  $!{xhe} really is gone.
          *if (bred_lover > 0) or ((bred_heart = 2) or (bred_heart = 3))
            You're surprised by how strong the ache of abandonment is, and how long it takes to subside.
        *if (wealth > 0) and (ale < 2)
          *goto banditwealth
        *else
          *goto spring
    *selectable_if (wealth > 99) #Buy forged weapons—swords, steel maces, spears—for the band. (At least 100 silver.)
      At present, your
      *set d2n_num nonkids
      *gosub d2n
      *if kids > 2
        adult 
      followers 
      *if arms = 0
        are armed with nothing more than staves, bows, and a few wood-axes.
        *goto cacfence
      share
      *set d2n_num arms
      *gosub d2n
      forged
      *if arms = 1
        weapon.
      *if arms > 1
        arms.
      *label cacfence
      
      Cacelon the fence has finally confirmed that he's found a supplier who would be willing to sell you more weapons—for a gold stater each.  His message makes clear that any haggling would be a waste of time.
      
      "It's daylight robbery.  But then, that's our line of work."  Zvad shrugs resignedly.  "We're not going to find them cheaper from anyone else, ${kuria}."
      *choice
        #I'm not going to buy weapons at that rate.  That's nearly twice what they're worth!
          "We don't need them badly enough to pay Cacelon that much," you growl.
          
          *goto banditwealth
        #We need all the arms we can get, however much it costs.
          *set armsalelimit round(wealth/100)
          *if armsalelimit > (wealth/100)
            *set armsalelimit -1
          You send to Cacelon, agreeing to his price.  With your 
          *set d2n_num wealth
          *gosub d2n
          silver, you could buy up to 
          *set d2n_num armsalelimit
          *gosub d2n
          weapons, adding to the 
          *set d2n_num arms
          *gosub d2n
          arms you already have for your 
          *set d2n_num nonkids
          *gosub d2n
          *if kids > 0
            adult 
          bandits.  How many weapons do you want to buy?
          *if (choice_randomtest)
            *set armsalelimit (nonkids-arms)
            *if armsalelimit <= 0
              *set armsalelimit 1
            *if armsalelimit > (wealth/100)
              *set armsalelimit round(wealth/100)
            *if armsalelimit > (wealth/100)
              *set armsalelimit -1
          *input_number armsale 0 armsalelimit
          *if armsale = 0
            *goto banditwealth
          The 
          *set d2n_num armsale
          *gosub d2n
          *if armsale = 1
            short sword you can afford soon arrives
          *if armsale > 1
            weapons soon arrive 
          in your camp.
          *set wealth -(armsale*100)
          *if wealth < 0
            *choice
              #Wealth is ${wealth}.
                *bug neg wealth
          *set arms +armsale
          *set armsfoll arms
          *if arms > nonkids
            *set armsfoll nonkids
          *set tick 2
          
          *goto banditwealth   
    *if diakon = 0
      #Pay a Diakon of the Angels to come perform religious services.
        *set diakon 1
        Your more devout followers have clearly been longing for the Sacraments of Compassion, the monthly ceremony in which they receive assurance of the Angels' mercy if they repent of their disorderly or uncompassionate behavior. 

        They're not the only ones with unmet religious yearnings.  Even those outlaws who hate Ecclesiasts seem to miss the Diakons, the low-level priests who administered the Sacraments in helot camps.  (The Karagond priesthood have a prudent division of labor, in which Ecclesiasts preside over Harrowings and Diakons handle everything else related to the helotry: birth-naming, marrying, burying, and all the ceremonies in between).

        You're not sure if you could find a Diakon who would offer your followers any absolution, rather than just condemning you all as rebels.
        *if skepreal > 50
          And personally, you don't think there's much to choose from between one pack of lie-peddlers and another.  But you recognize that the band is missing 
          *gosub hurtmorale
        *if skepreal = 50
          You're neither particularly devout nor skeptical, and don't miss the rituals you grew up with.  But you recognize that the band is missing 
          *gosub hurtmorale
          *if wealth > 99
            *page_break
            *goto diakon_1
          *else

            At the same time, you're
            *goto diakon_2
        *if skepreal < 50
          Also, like many devout Shayardenes, you believe that the Karagond Ecclesiasts distorted the original word of the Angels to justify the bloody rule of the Thaumatarch.  You've hoped that your outlaw band could be free of their lies, and you're worried that a Diakon will just reintroduce Karagond dogma.  On the other hand, you recognize that the band is missing
          *gosub hurtmorale
        *choice
          #Find a Diakon who will perform the Sacrament in exchange for money.
            *if wealth < 100
              You're 
              *label diakon_2
              quite sure a Diakon won't give you the time of day for less than a hundred silver—and you only have
              *set d2n_num wealth
              *gosub d2n
              to your name.
              *choice
                #Offer the priest more money than I actually possess.
                  *goto diakon_1
                #Never mind, we can't afford a Sacrament.
                  *set tick 2
                  *goto banditwealth
            *label diakon_1
            It isn't all that hard to ambush a Diakon leaving a helot camp.  After three days' hunting, you catch a jowly, gray-haired man wearing the traditional dust-colored coat and narrow dark brown stole.  Distracted with the jammed stopper of his water flask, he doesn't notice your party emerging from the woods until he is already surrounded.

            "Good day, Uncle," you say lightly.  "We've come late for the Sacrament.  Any mercy left for us?"

            Sweat breaks across the Diakon's brow as he takes in your bows and axes, but his voice remains cool as he retorts, "There's no forgiveness for rebellion."

            You shake your head in a quick, firm negative.  "And you'll never hear us ask forgiveness for fighting the atrocities of the Thaumatarch.  
            *if nothief < 2
              Nor for stealing to survive.  
            But there are other small acts of chaos that weigh on my people's consciences.  So we thought we might invite you to come to our camp and perform a Sacrament—to cover only those areas where you and we all agree that we need mercy."

            "That isn't how…"

            "And of course, we'd be willing to make an offering for your service," you interrupt.  "A hundred drachems, for a day's blessings."

            That gives him pause.  Diakons are fed and housed by the nobles whose estates they serve, but only rarely are they actually paid.  "You're ${fname} ${lname}?" he asks.  When you nod, he rubs his face pensively.  "I've heard your name in the camps.  Generally in the conversations that come to a sudden stop when I appear."
            *page_break
            *if cred_p < 171
              *set diakon 2
              The Diakon swallows hard, then continues.  "I've also heard you damned by a half-dozen Ecclesiasts.  It's not just that you're a rebel—you're 
              *if temple > 0
                a rebel who directly attacks the sacred servants and temples of Xthonos!
                *if (theuknown >= 10)
                  And above all, you're 
              *if (theuknown >= 10)
                a known Goete, who uses the dark arts of Xaos against the blessed Theurges.
              If any of my brethren heard that I'd helped you, I'd be Harrowed as a traitor.  You think I hold my life worth no more than a stater?"

              "No one would hear…" you start, but this time he cuts you off.

              "No.  My word is no.  So kill me or let me pass, ${lname}.  You'll have no words of mercy 
              *if (theuknown >= 10)
                for your Goety
              from me."

              You sigh, annoyed.  "Don't be so dramatic, Uncle.  Your life's in no danger."  Murdering a Diakon in cold blood would hardly improve morale among your devout followers, or make it any easier for you to find another priest to carry out the Sacrament.  "If you won't serve our need, go your way."

              Over the following few days, unfortunately, all your attempts to bring back a Diakon end with similar refusals.  You seem to have burned your bridges rather thoroughly with the local priesthood of Xthonos.  The devout Whendward outlaws sink into miserable silence, convinced that their choice to follow
              *if (theuknown >= 10) 
                a sorcerer like
              you has put them beyond the Angels' mercy.

              You'll have to think of some other way to 
              *if morale < followers
                restore morale.
              *if morale >= followers
                meet your followers' religious needs.
              *set morale -5
              *goto banditwealth
            *else
              "And have you managed to hear anything else in these conversations?" you query.

              The Diakon snorts sourly.
              *if cred_h > 249
                "What do you think?  They adore you."
              *if (cred_h < 250) and (cred_h > 180)
                "They don't seem to hate you too much."
              *if (cred_h < 181) and (cred_h > 100)
                "Can't say they sound all that happy with you and your bandits.  Did you run out of nobles to steal from?"
              *if cred_h < 101
                "Sounds to me like they're ready to bottle your blood themselves and spare the Theurges a Harrowing.  How did you get them to hate you so much?"
              He finally manages to unstop his flask and takes a thirsty swig.  "But never mind what my flock thinks.  If I come to your camp and say the words, how can I be sure that it won't get back to the Hegemony?  I don't think they'd be interested in splitting hairs about whether my Sacrament covered your rebellion."

              "If we weren't good at keeping secrets from the Hegemony, we wouldn't be here."

              The priest groans.  "Angels forgive this sophistry.  Let's go, before I change my mind."

              The sun has set by the time you reach the field of tumbled boulders that marks the final approach to your camp.  One of your night scouts appears atop an outcrop and welcomes you back with a mimicked nightjar call.  As you reach the first tents, you remove the Diakon's blindfold and encourage him to dismount from the mule.  Your devout followers crowd around to greet him with mingled joy and nervousness.  "Welcome, Uncle!   Blessings on you for coming here to us…we don't have much, but all we have is yours."

              You really don't have much, of course.
              *if ale > 0
                The ale you bought to celebrate your survival was gone within three nights.
              While you're no longer on the verge of freezing or starvation, your rations are still sparse and the nights still chilly.
              *set diakon 3
              *choice
                #Give the Diakon extra food and blankets to make sure he's as comfortable as possible.
                  *if skepreal != 50
                    You may not have much respect for the priesthood of Xthonos, but a
                  *if skepreal = 50
                    A 
                  guest is a guest, and you don't want anyone to malign the hospitality of the Whendward Band.  The Diakon notes that he's being treated with special honor, and seems much mollified.  Though their stomachs are slightly emptier than usual, your devout followers are relieved to see him so pleased—and to your surprise, even the less devout outlaws don't seem to begrudge him the special treatment.
                  *set cred_p +3
                  *goto diakonpreach
                #Give the Diakon exactly the same sparse food ration and shelter that my followers live with.
                  Your more devout followers might be willing to part with their rations for the Diakon, but you can't let them weaken themselves—and you can just imagine what the less devout outlaws would think of watching your guest stuff himself while they go to bed hungry.  

                  "I know it's poor fare we have to offer, Uncle," you say, as you all gnaw on the evening jerky and barley flatbread.  "We've not been long out of the winter."

                  The cleric glances down at your plate, then at your father's, and seems mollified to see that neither of you have a larger portion.  "That's all right.  You're giving me excellent material for my homilies against banditry."
                  *set cred_h +3
                  *goto diakonpreach
              *label diakonpreach

              *achieve diakon
              In the morning, you invite your band to receive the Sacrament of Compassion from the Diakon in the field of stones.  A few of them scoff at the invitation.
              *if skep > 50
                "I thought you were some kind of Nereish skeptic, ${kuria}," one of them calls in mock-surprise.
              Most of the band, however, choose to take part—even those who aren't particularly pious.  Forgoing any initial sermon, the Diakon spreads his arms wide and begins intoning the sacred words.

              "All praise to the Angels of Xthonos—Mighty Angels, show us mercy.
              *line_break
              To the disorderly, the Angels bring the vengeance of righteousness.  
              *line_break
              But to the penitent, They show mercy and compassion."

              Usually at this point, the Diakon would say, "To the rebel?" and the crowd would respond, "Vengeance!"  But today, he gives you all a pointed glance and skips over rebellion and loyalty to the next crime in the list.

              "To the murderer—vengeance.
              *line_break
              But to the life-giver—mercy.
              *line_break
              To the thief—vengeance.
              *line_break
              But to the generous—mercy."

              The litany goes on at some length, covering all the main forms of chaotic and orderly behavior, while the Diakon walks up and down among the kneeling helots, releasing fistfuls of dust over their heads.  When it's done, you can see the relief on your followers' dirt-smudged faces.  They're clean again.
              *set morale +40
              *page_break
              Several hours later, you drop the Diakon off on the fringes of the noble estate where he lives.  His blindfold removed, the ruddy-faced priest blinks wearily up at you.  "Now that we're done…I believe you were willing to part with some silver for the Sacrament?"
              *choice
                #Pay him as promised.
                  *if wealth < 100
                    Unfortunately, you don't have a hundred drachems to pay him.  You produce 
                    *set d2n_num wealth
                    *gosub d2n
                    drachems, mumbling apologetically that it's all you have.
                    *set wealth 0
                    
                    *goto diakonliar
                  *else
                    *set diakon 4
                    *set wealth -100
                    It pains you to part with your hard-won silver when the band is still recovering from the winter—but you believe you've boosted morale more with this priest's visit than you would have by buying them a few extra meals.  "As promised, Uncle," you say, counting out ten decadrachms into his palm.  The coins instantly vanish into the man's dust-colored coat.

                    As you watch the beaming Diakon trudge away, you wonder if this really is the best way to meet your followers' religious yearnings.  Perhaps you'll be able to think of another way over the coming weeks.
                    *if wealth > 0
                      *goto banditwealth
                    *else
                      *goto spring
                #Don't pay him.  What's he going to do?
                  *label diakonliar
                  The Diakon fixes you with a frosty gaze.  "So.  I should have known better than to trust a Xaos-loving bandit's word, I suppose.  Be sure that in future, my fellow Diakons will know how exactly far they can trust you.  Don't expect any more false Sacraments to ease your followers' consciences!"  Spluttering curses under his breath, he stalks away.

                  You're guessing that your reputation with the priesthood of Xthonos will sink to new lows after this episode.  If you do want to meet your followers' religious yearnings, you'll need to think of another way to do it.
                  *set cred_p -20
                  *if wealth > 0
                    *goto banditwealth
                  *else
                    *goto spring
          #No, on second thought, I don't want anything to do with any priests of Xthonos.
            You start considering whether there's anything else you can do to satisfy your followers' religious yearnings.  There's an inkling lurking somewhere in your mind, but you think you'll need to give it another week or two before it turns into a conscious vision.
            
            *set tick 2
            *goto banditwealth

    *if (sybla = 0) and ((armsfoll > 0) and (wealth > 2))
      *if (wealth < armsfoll) #Pay someone to come train the band in using their captured swords and spears.  (One silver per armed outlaw.)
        *set morale +round(wealth/3)
        *set wealth 0
        *goto syblatrain
    *if (sybla = 0) and (armsfoll > 0)
      *if (wealth >= armsfoll) #Pay someone to come train the band in using their captured swords and spears.  (${armsfoll} silver.)
        *set wealth -round(armsfoll)
        *set morale +round(armsfoll/3)
        *label syblatrain
        *set sybla 1
        When you raise the idea with Zvad, he breaks into a rare grin.  "I know the woman for the job, ${kuria}.  She guards caravans between here and Wiendrj.  Got a message from her two days back through a merchant contact—saying she'd be coming over the Ojlskaf Pass this week, and to make sure our folk kept well out of her way.  When she's done with that job, she'd come train us for the right coin."

        You look at him quizzically.  "Did she pay us not to attack her caravan—or just ask us sweetly?"

        The craggy ${whend} shakes his head solemnly, eyes twinkling.  "Nothing sweet about Sybla, ${kuria}.  She was kind to warn us."

        Sybla of Eliczka turns out to be a wiry, mid-height ${whend}ish mercenary whose wispy, dark-dyed hair is bound up in a severe topknot.  She travels unarmored, with a ${whend}ish shortspear and sword strapped to her back.  "A drachem per trainee, and only because Zvad is the one asking," she greets you on your first meeting.  When you agree, she bows crisply to you and "asks" if you would accompany her during the entirety of the training.
        *if com = 0
          
          "I am not much of a fighter," you say, doubtful.

          "And I will not make you one," Sybla replies at once.  "But your band already accept your authority, ${kuria}.  I wish to waste no time if any of them are inclined to question mine."
        Her voice is soft but penetrating, and you soon learn that almost everything she says is in essence a command.
        *page_break
        On the first morning of training, Sybla orders anyone who has captured a long Alastor spear to cut it down to the size of hers.  "You're woodsfolk.  No use learning a weapon that you can only use out in a town or in the plains.  Sooner or later, the Hegemony will follow you back here—so we must make you ready to defeat them here, in these very woods."  

        For a week, the mercenary captain drills your bandits relentlessly in the use of their captured weapons.  
        *if com > 0
          You are awed by how much her combat knowledge and skills exceed your own.
        *if com = 0
          You stand alongside her, rarely more aware of how hopeless you would be in hand-to-hand combat, but trying to absorb some of her advice.
        When the sun sinks below the distant mountains, Sybla frees the exhausted outlaws and takes her supper with Zvad.  The two taciturn ${whend}s talk intently long into the night, ignoring all those around them.
        *fake_choice
          #I let them alone.
          #I watch them curiously, trying to guess what they're talking about.
            It's all but impossible to guess what Zvad and Sybla are discussing, given their barely expressive faces and low voices.  You feel that Zvad often looks mournful, but then, ${whend}s often do.
            
          #I try to listen in on their conversation.
            You edge round the fire one evening, in time to hear Zvad rumble, "You're wrong, old friend."  He sounds troubled.
            
            "It ends only one way," Sybla says flatly.  "Don't let this…"  Then her head swivels round.  "$!{kuria}.  Memory find you."
            
            You stumblingly return the odd ${whend}ish greeting.  "Today went well, I thought."
            
            "They are learning." Sybla's tone leaves it somehow unclear whether she is agreeing with you.  "You will have your silver's worth."
            
            After a few moments, Zvad clears his throat.  "Well, I'm off to sleep, ${kuria}. Sybla."  He bows, looking mournful, and walks off.  You catch some snatches of their conversation on subsequent nights, but as far as you can tell, they're reminiscing about old jobs as paid guards.
            *page_break
        By the end of the training, all your followers using iron or steel weapons are visibly more confident, and at least somewhat more competent.  

        "They'll be no match for a Phalangite force, of course," Sybla informs you with a strategist's detachment on the evening before she departs. "But they're less likely to be routed by a smaller force now.  And the longer they continue the drills I've taught them, the more likely they are to win."

        "Kuria Sybla, I'm more grateful than I can say.  Obviously, we need more help than you could give in one week."  You try desperately to think of anything that will keep her here for long enough to turn the band into real soldiers.  Even if you couldn't afford to pay her, perhaps you could convince her to join your rebellion.
        *achieve sybla
        *choice
          *selectable_if (wealth >= armsfoll) #Offer to hire her for another week.
            "They do not need me here next week," Sybla replies, not unkindly.  "They need to practice what I've taught them.  It will be some time before they're ready to learn more."
            
            "Very well.  I'll pay you, now, to come back when you think they'll be ready."  From talking with Zvad, you're confident that Sybla never breaks a contract—and you won't let her get away without something binding her to return.
            
            The ${whend}ish mercenary stares at you with an expression you can't quite read.  "I can not take your money, ${kuria} ${lname}."
            
            "I don't understand you."
            
            *goto syblapity
          #Ask if she'll join your band—for the sake of her friendship with Zvad.
            Sybla looks at you coolly.  "What do you know about my friendship with Zvad, ${kuria} ${lname}?"

            "Nothing," you admit.  "The only thing he said is that you worked together, long ago.  But any friendship between sellswords that survives one of them turning bandit has some power to it."
            *goto zvadstory
          #Appeal to the cause of overthrowing the Thaumatarch.
            Sybla furrows her brow coolly.  "Why do you think I wish to see the Thaumatarch fall, ${kuria} ${lname}?"

            "I don't believe you're only here for our silver, kuria.  Or even out of loyalty to an old friend and fellow sellsword."  You see no sign that you're on the right track, but press on regardless.  "Will you tell me that you love the laws that force men like Zvad out here into the wilderness?  Is that no part of why you came to help us?"
            *goto zvadstory
        *label zvadstory
        
        The ${whend}ish mercenary smiles for the first time since you met her, moved by an emotion you can't quite read. "Our company chose the wrong employer, once.  A man who flouted the Thaumatarch's law and died for it.  When the Alastors came hunting, loyal Zvad took the blame on himself and escaped to the woods, so the rest of us could remain free."

        "I'd have expected no less from him."  Fascinated and hopeful, you press forward: "And now, all these years on—would you consider joining him?"
        *page_break
        *label syblapity
        Sybla glances around to make sure you are alone.  As she returns her eyes to yours, you recognize her emotion: pity.  "I have seen why Zvad chooses to follow you, ${kuria}.
        *if cha > 1
          You have extraordinary charm and conviction.
        *if com > 1
          You fight as I did when I was your age.
        *if int > 1
          Your mind is keen as a new-honed spear.
        But ${kuria}: you do not have the time you need."  

        "What do you mean?"

        "The woods give you some protection against Theurge spying and Phalangites' favored tactics.  So they have not yet poured down upon you.  But they will be preparing, and 
        *if rescuer = 0
          they will not have forgotten your sacrilege at their Harrowing.
        I do not believe they will let you survive the spring."

        You feel as if she just drove her spear stock into your gut.  "You don't think we have any hope?"

        Sybla of Eliczka tilts her head to one side with a contemplative gaze.  You imagine that you can see her strategist's mind sifting through all the likely alternatives.  "Not enough for me to join you, ${kuria}.  I am truly sorry."

        After she has been blindfolded and departed for the lowlands on mule-back, you lean back and try to take comfort from the newly cheery swagger of your followers around the camp.  The arms training has boosted their morale.  As long as you can keep your own flickering confidence alight, surely you still have a chance.
        *if wealth > 0
          *goto banditwealth
        *else
          *goto spring
    *hide_reuse #Distribute silver to the poor yeomanry of the nearby farm country.
      "Aye, ${kuria},"  ${deputy} agrees.  "They'll think better of our rebellion for it."
      
      How many of your band's
      *set d2n_num wealth
      *gosub d2n
      drachems do you want to send discreetly to the yeomanry?
      *input_number yeodonate 0 wealth
      *if yeodonate <= 1200
        *set cred_y +round(yeodonate/12)
      *if yeodonate > 1200
        *set cred_y +round(100+((yeodonate-1200)/50))
      You hear that your
      *if yeodonate < 49
        petty donations have changed few minds
      *if yeodonate >= 49
        generosity is reasonably well received 
      among the yeomanry.
      *set wealth -yeodonate
      *if (yeodonate > 599) and not(openhanded)
        *goto setepithet
      *if wealth > 0
        *if tick = 2
          
          *comment endif
        *goto banditwealth
      *else
        *goto spring

    *hide_reuse #Distribute silver to the helots in the noble estates of the Rim.
      How many of your band's
      *set d2n_num wealth
      *gosub d2n
      drachems do you want to send discreetly to win over the helotry to your cause?
      *input_number donation 0 wealth
      *set wealth -donation
      *set tick 2
      *if donation <= 800
        *set cred_h +round(donation/8)
      *if donation > 800
        *set cred_h +round(100+((donation-800)/50))
      *if donation = 0
        All right—never mind.
        *goto banditwealth
      *if donation < 20
        Your tiny donation wins you a friend or two.
      *if donation > 19
        You've made 
        *if donation < 90
          a few
        *if (donation > 89) and (donation < 250)
          some
        *if donation > 249
          a great many
        helots very happy with you.
        *if (donation > 399) and not(openhanded)
          *label setepithet
          *set openhanded true
          *if not(liebreaker)
            *set epithet "the Open-Handed"
          Indeed, after a few well-placed large gifts, the legend of your generosity begins to spread across the region.  By the time spring arrives, your scouts in the Rim report hearing ballads about "${fname} the Open-Handed, who robs the wealthy to feed the lowly."  

          You get a few gibes from your outlaws about paying to feed the 
          *if donation > 0
            helots
            *if yeodonate > 0
              and
          *if yeodonate > 0
            yeomen
          rather than feeding them.  But 
          *if winterfail = 0
            the gibes aren't serious—you did bring them alive through the winter, after all—and 
          *if winterfail > 0
            notwithstanding the bitter edge to their jokes,
          they clearly feel proud of the new reputation of the Whendward Band.
          *achieve robinhood
          *set morale +30
          *set tick 3
      *if wealth > 0
        *if tick = 2
          
          *comment endif
        *goto banditwealth
      *else
        *goto spring
    *if mules > 1
      *selectable_if ((mules-freemules)> 0) #Sell at least one mule.
        *if freemules = 0
          Any of your 
          *set d2n_num mules
          *gosub d2n
          mules 
        *if freemules > 0
          Sixteen of your 
          *set d2n_num mules
          *gosub d2n
          mules wear the Architelone Xedia's brand, and cannot be sold. 
          *if ((mules-freemules)> 1)
            Any of the others
          *if ((mules-freemules) = 1)
            The last one
        could be fenced for around seven gold staters, or seven hundred drachems.  
        *if freemules < 15
          Zvad 
          *if deputy = "Breden"
            apparently has advised Breden
          *if deputy != "Breden"
            advises you
          *if mules > 15
            to hold onto no fewer than fifteen mules.
          *if mules <= 15
            not to sell.  "Reckon we'll want all of them in the days ahead, ${kuria}."
        
        You'll sell:
        *input_number mulesale 0 (mules-freemules)
        *set wealth +(mulesale*700)
        *set mules -mulesale
        *set mulesale 0
        *goto banditwealth
    #Save my remaining silver.
      *goto spring

*label morale_check
At the moment,
*if morale < (followers/2)
  you sense that morale is bad among your followers—more than half of them are miserable.
*if (morale >= (followers/2)) and (morale < followers)
  morale could definitely be better in the band; a significant minority of your followers are disheartened and would run away if the going got tough.
*if (morale >= followers) and (morale < (followers+20))
  the band's morale is good, though you don't know how well it will hold up under a serious challenge.
*if morale >= (followers+20)
  morale is outstanding among your band;
  *if wealth > 9 
    you shouldn't need to spend any more on boosting their mettle.
  *if wealth < 10 
    they're confident in your leadership and in their future.
*return

*label spring
*page_break
*if ale = 0
  *if (winterfail > 0)
    To restore some of the bonds that the winter strained to snapping, you propose a proper celebration of the coming of spring.
    *set ale 2
    *goto partytime
  The band's morale
  *if morale < (followers/2)
    may be poor, but
  *if (morale >= (followers/2)) and (morale < followers)
    could be better, but
  *if (morale >= followers) and (morale < (followers+20))
    has increased under your able leadership, and
  *if morale >= (followers+20)
    is very strong, and
  you survived until the spring; that's worth celebrating.
  *set ale 2
  *goto partytime
*if (((deputy = "Zvad") and ((bred_lead > 0) and bred_here)) or ((deputy = "Breden") and (zv_lead > 0))) or ((el_lead > 0) or (rad_lead > 0))
  With the coming of spring, you can't help noticing how many outlaws are still deferring to the folk who led them on winter missions.  Not only to your deputy ${deputy}—the Band also increasingly looks for leadership to
  *if (deputy = "Zvad") and ((bred_lead > 0) and bred_here)
    Breden,
  *if (deputy = "Breden") and (zv_lead > 0)
    Zvad,
  *if (el_lead > 0) 
    Elery,
  *if (rad_lead > 0) 
    Radmar,
  your head scout Alira, and perhaps one or two others.
  *if rescuer = 0
    The helot elders are visibly struggling to maintain their traditional authority; they aren't seen as the ones who brought you safe through the winter.
    *if winterfail > 0
      Nor, it must be said, are you.
  *if ((zv_lead > bred_lead) and (zv_lead > rad_lead)) and (zv_lead > el_lead)
    *set topdog "Zvad"
    *set t_his "his"
    *goto judgeby
  *elseif ((rad_lead > bred_lead) and (rad_lead> el_lead)) or (not(el_here) and not(bred_here))
    *set topdog "Radmar"
    *set t_his "his"
    *goto judgeby
  *elseif (el_lead > bred_lead) or not(bred_here)
    *set topdog "Elery"
    *set t_his "her"
    *goto judgeby
  *else
    *set topdog "Breden"
    *set t_his xhis
    *goto judgeby
  *label judgeby
  
  To judge by appearances,
  *if topdog = deputy
    ${deputy} is still the most influential leader besides yourself.  
  *if topdog != deputy
    the most influential of the new leaders is ${topdog}. Thanks to ${t_his}
    *if topdog = "Zvad"
      long history with the Band and
    *if (topdog = "Radmar") and rad_mutiny
      leadership of the mutiny and
    visibility through the winter, ${t_his} authority has outstripped ${deputy}'s.
  But any of the others could also sway the course of the Band's decisions.
  *fake_choice
    #Or challenge me outright for the leadership.  I'll need to look for ways to weaken their clout.
      At the very least, you can give their rivals more opportunities to lead.  And if you sense anyone preparing an attack on your authority, you'll need to make sure the confrontation happens on your terms, not theirs.
    #I'm not going to undercut any of them, but I'm worried that this sows the seeds of ${mutiny}.
      You'll keep a wary eye on ${topdog} and the others.  If it looks like one of them is preparing a challenge to your authority, you'll need to cut it off as early as possible.
    #It's dangerous but unavoidable.  We need all the capable leaders we can get.
      How could you have brought the Band through the winter without relying heavily on others?  If you rely on the best-skilled outlaws, it's inevitable that the rest will admire them.
    #And I'm more than ready to share authority with them.
      *if democ > 0
        That is, after all,
        *if democ > 1
          what ${a_moot} means.
        *if democ = 1
          what a council of elders means.  You'll be sure to include the most influential outlaws in your deliberations.
      *if democ <= 0
        You've had to rethink your determination to keep all authority in your own hands.  A council of "elders" (whatever their actual age) will be better able to bring the rest of the Whendward Band along with you on a controversial decision. And you're likely to face plenty of those in the days ahead.
        *set democ 1
*if rescuer = 0

  With your band's survival no longer in question, 
  *if not(bred_here)
    you can turn your mind to other things—like the question of your betrayal in Rim Square.  Are you confident that Breden Reaper was the sole traitor?
    *choice
      #Of course ${xhe} was.  Let's not start jumping at shadows.
        *set nohunt true
        *goto newbie
      #No, and I want to discreetly scour the band for other spies.
        *goto idealadvice
      #No, but my nagging doubts aren't strong enough to justify a hunt.
        *set nohunt true
        *goto newbie
  the time has come at last to hunt for the traitor or traitors who betrayed you to Chirex.
  *if bred_here and (bred_trust = 1)
    Do you want to find a way to test Breden's loyalty as well?  If
    *gosub bred_offense
    *choice
      #No—I trust Breden.
        *set bred_trust 2
        *goto traitorplan
      #No.  I don't know if I trust Breden, but I don't want to risk driving ${xhim} away.
        *set bred_trust 4
        *goto traitorplan
      #Yes—I can only truly trust ${xhim} if I've tried to prove ${xhis} loyalty.
        Though you've tried not to make it obvious to Breden ${xhim}self, you have harbored some 
        *if (bred_lover > 0) or ((bred_heart = 2) or (bred_heart = 3))
          painful
        questions about ${xhis} loyalty since the day Chirex pulled those seditious young helots out of the crowd.  You can't exempt ${xhim} from this test.  After conferring with Zvad, you agree on a plan.
        *goto traitorplan
  *elseif bred_here and (bred_trust > 9)
    Breden's detailed knowledge of the younger helots that ${xhe} invited to the meetings will be essential.  You can't see the hunt being successful without ${xhis} help.  
    
    *if bred_lover = 3
      But you'll need to test ${xhis} loyalty as well, in a way that won't be immediately obvious to ${xhim}.  After conferring with Zvad, you agree on a plan.
      *goto traitorplan
    But you need to decide whether you suspect ${xhim} and want to try to test ${xhim} as well—knowing that if
    *gosub bred_offense
    *choice
      #I've decided not to suspect Breden unless ${xhe} gives me further reason.
        Anyone would have felt suspicious of Breden when it first became clear that there was a traitor.  But on further consideration, you just don't believe treachery on that scale is consistent with ${xhis} character and actions.
        *if (bred_lover >= 4) or ((bred_heart = 2) or (bred_heart = 3))
          You don't think your instincts are so unreliable that you would fall in love with someone capable of sending ${xhis} friends to the Harrower.
        *if rollover5 = "Breden"
          *if (bred_lover >= 4) or ((bred_heart = 2) or (bred_heart = 3))
            Also,
          *if (bred_lover < 4) and ((bred_heart != 2) and (bred_heart != 3))
            For one thing, 
          ${xhe} had a prime chance to betray you to the Alastors on your raid, and didn't take it.
        *set bred_trust 3
        *goto traitorplan
      #I consider Breden a suspect and want to find a discreet way to test ${xhim} as well.
        You haven't changed your mind since the day Chirex pulled those seditious young helots out of the crowd.  Everyone's a suspect, no matter how close to you.  After conferring with Zvad, you agree on a plan.
        *goto traitorplan
    *label bred_offense
    ${xhe} realizes ${xhe}'s been included in the test and takes offense, it might cost you
    *if (bred_lover >= 4) or ((bred_heart = 2) or (bred_heart = 3))
      *if (bred_trust > 10) and bredalien
        any chance of regaining
      ${xhis} love and
    one of your rebellion's few natural leaders.  That's a high price, especially if you think ${xhe}'s probably innocent at the end of the day.
    *return
  *else
    *if not(bred_here)
      *label idealadvice
      Ideally you'd want someone to advise you on the younger helots—someone who knows them all and is well trusted as a leader.  With Breden gone, you could include 
      *if el_here
        either Elery or 
      Radmar in planning for your traitor hunt.  Or there's Terret Abler, who's no less respected than the battle-leaders, but wasn't part of the illicit meetings in Rim Square.  That makes him less a suspect, and also likely less useful in narrowing down targets.
      *choice
        #I want Radmar's counsel.  I don't believe he's a traitor.
          *set radmar 2
          *if rad_mutiny
            A mutineer, yes.  
          You wouldn't trust him to follow you.  But you're confident that he's not in the pay of the Karagonds.
          *set rad_council true
          *goto traitorplan
        #Radmar may well be a traitor, but I can include him in the planning and still test his loyalty.
          However fiercely he rails against the Hegemony, his absence on the day of the Fourth Harrowing remains suspicious.  But you think you can put him to the test without his realizing it.
          *set rad_council true
          *goto traitorplan
        *if el_here 
          #I definitely want Elery's help.
            There's little doubt that Elery would have gone into the Harrower had you not intervened; she's no tool of the Karagonds.  She knows the young helots, and they'd follow her anywhere.
            *if e_rel < 10
              And while your relationship may be
              *if e_rel > 2
                cold,
              *if e_rel < 3
                hostile,
              you trust her to do and say what's right for the band.
            *set el_council true
            *goto traitorplan
        #I'll bring Terret Abler into my confidence.
          The band's healer tended to just about everyone at some point over the course of the winter.  He'll have as good a sense as anyone of who's the most suspicious, and how best to test them.
          *set ter_council true
          *goto traitorplan
        #Actually, on reflection I'm sure that Breden was the traitor.  There's no reason to keep up the hunt.
          It's hard to let go of your fear of another betrayal—but if you keep hunting for phantoms, it will distract you from everything else a rebellion needs from its leader.
          *set nohunt true
          
          *goto newbie
    *label traitorplan
    
    You call a secret council with Zvad, 
    *if bred_here
      Breden, 
    *if (rad_council)
      Radmar,
      *set youngun "Radmar"
      *set y_his "his"
    *if (el_council)
      Elery,
      *set youngun "Elery"
      *set y_his "her"
    *if (ter_council)
      Terret,
      *set youngun "Terret"
      *set y_his "his"
    and
    *if aristo
      Joana Orchard, the no-nonsense helot elder who used to work your father's lands.  
    *if helot
      the helot elder who you think is least likely to be a traitor:
      *choice
        #Old Joana Orchard.
          *goto askedyouhere
        #Gillian Adze from the Keriatou estate.
          Gillian knows the greatest number of helots; she'll be vital to your plan.
          
          *set elder "Gillian"
          *set elder2 "Gillian"
          *goto askedyouhere
        #My father.
          Your father is many things, but you genuinely don't think he'd betray you to the Karagonds.
          
          *set elder "Father"
          *set elder2 "your father"
          *goto askedyouhere
    *label askedyouhere
    "I've asked you here because I trust the three of you, and because between you, you're familiar with everyone else," you begin.  "Zvad, you know the old Whendward Band; ${youngun}, you know the young helots of Rim 
    *if not(ter_council)
      Square, especially the seditious ones; 
    *if (ter_council)
      Square;
    and ${elder}, you know the older ones."

    "I don't know everyone from the old pack well," Zvad says doubtfully.  "Some were there before me.  Many who came since aren't too talkative."

    *if demerre > 3
      "Don't forget the new ones from the de Merre estate," ${youngun} points out.  "None of us knows them."
      
    "They aren't the problem," you persist.  "The problem is that during the last Harrowing in our town, the Theurges and Ecclesiast were able to single out the young helots who had been part of Breden's seditious little debates."
    
    *if bred_here or rad_council
      "The Alastors arrested thirteen of them," ${youngun} 
      *if bred_here
        explains immediately to Zvad.  "They accused them of avoiding the Harrowing; it made a good excuse to Harrow the whole lot of us, many more than they'd normally choose.  I think they were also hoping that one would snap and start accusing the others in public.  If ${bfname} hadn't saved us, we'd all be dead."
      *if rad_council
        says grimly to Zvad. "I'd have been the fourteenth, but for luck.  They knew just where to find us, and just when to strike."
    *if el_council
      *if elezvad > 2
        "It's as I told you," Elery says to Zvad,
      *if elezvad < 3
        "They caught us up in the woods—too many of them to fight," Elery informs Zvad,
      her voice taut with remembered horror.  "We were a hair's breadth away from being fed to the machine.  They knew just where to find us, and just when to 
      *if e_rel < 8
        strike."
      *if e_rel > 7
        strike.  If ${kuria} ${fname} hadn't saved us, we'd all be dead."
    *if ter_council
      Your young Abler nods uneasily. "Aye, Radmar talked on that when he was in the sick tents.  Said the only reason he wasn't caught with the rest was luck."
    
    "The point is," you conclude, "someone betrayed us to the Hegemony.
    *if followers < 200
      That person might be dead by now, but we can't count on it.
    We need to catch him or her before it happens again."
    *if rad_council
      
      "It was Breden bloody Reaper." Radmar's brows lower ominously. "Why are you still casting about when you've already done what needed doing, ${kuria}?"
      
      "Because if the traitor wasn't Breden, now's the time to catch them.  Now, when they think we've stopped hunting."  You're undeterred by the young fighter's snort. "If we catch nothing, no harm done."
    *page_break
    "So why am I here?" ${elder2} asks brusquely.
    *if aristo
      Her bluntness always infuriated your father, but greatly endeared her to your late mother and to you.
    "As you said, I know the old folk.  You want to be looking at the young ones."
    
    *if elder = "Father"
      He
    *if elder != "Father"
      She
    casts a meaningful glance at ${youngun}, who 
    *if ter_council
      spreads his hands in a gesture of acceptance. "It's a fair point, ${kuria}.  Why look to anyone not in Breden's old group?"
      
      "Because the traitor could well be someone who heard of the meetings without ever attending.  An uncle or a mother, as easily as a young friend.  So ${elder}, that's why you,
      *goto youngunandme
    bristles.  "Something you want to say,
    *if elder = "Father"
      uncle ${lname}?"
    *if elder = "Joana"
      Orchard?"  
    *if elder = "Gillian"
      Adze?"  
    $!{y_his} tone is barely civil, with none of the respect that you were raised to give your elders.
    *fake_choice
      #"Aye, ${elder}.  What are you saying?"
        "Nothing welcome, clearly." $!{elder2} glares defensively at you both. "Don't see why I should stay a moment longer if this is how you're going about things."
        
        "I want you here because the young ones aren't the only ones who could have known what was going on in those woods."  You raise your hands to fend off the inevitable objections. "Older folk get wind of things all the time.  The girls and boys at those meetings could have let things slip to a mother or uncle as easily as a young friend."
        
        *if elder = "Father"
          Your father
        *if elder != "Father"
          The helot elder
        snorts, still visibly unconvinced.  "Angelspit, ${girl}, if any of us had caught wind of that foolishness, we'd have stopped it in its tracks."
        
        "Even so.  We need to suspect everyone, young or old.  You,
      #Let them fight it out.
        "Shouldn't need saying—at least, not to anyone with the sense the Angels gave a partridge," ${elder2} barks.  "I'd not heard about your little meetings until after the Harrowing—and I'd warrant no one else with any gray in their hair had either, or we'd have stopped your foolishness before it cost lives!  Whatever fool 
        *if bred_here
          [i]organized[/i] 
        *if not(bred_here)
          organized
        them did a good job of keeping them secret."  
        *if elder = "Father"
          He clears his 
        *if elder != "Father"
          She clears her
        throat pointedly. "From helots, anyway."
        
        *if not(rad_council)
          ${youngun}'s face tautens with a furious smile.  "All so clear, isn't it?  None of our excited boys or girls could have let slip to a mother or uncle about the meetings—because if they had, surely any elder would have done the good thing.  Gray in the hair puts them beyond suspicion."

        *if (rad_council)
          The breath blasts scornfully from Radmar's nostrils. "Well, you all know my mind.  The fool who organized them was the traitor.  But if we're to doubt that?  Any of the pups at our meetings might have let slip to a mother or uncle, as easily as to a young friend.  Don't tell me to shut my eyes to anyone with a scrap of gray."

        $!{elder2} recoils from ${youngun}'s insolence.  "I ought to beat some respect back into…"        
        
        You step in, raising your hands to placate them. "For the time being, everyone's a suspect—young or old.  You, 
      #Cut in, explaining why I'll test both old and young helots.
        "What if one of the young ones talked to a mother, or uncle?" you ask ${elder2} before either of them can speak again.  "Out of excitement, or guilt, or curiosity.  No, everyone's a suspect, young or old—but you, 
    *label youngunandme
    ${youngun}, and I are going to start by ranking them in order of who's most likely.  And I think we can agree that the first names on the list will be youth who attended some of those 
    *if not(rad_council)
      discussions—Radmar, first of all."
    *if (rad_council)
      discussions with you, Millstone."
    
    "I've seen no reason to suspect anyone from your town," Zvad cuts in gently.  "We've 
    *if nothief < 2
      raided and 
    starved together all through this winter.  You don't think a traitor would have tried to sell us out by now?  To earn a warm bed and a meal, if for no other reason?"

    You shake your head. "We've 
    *if nothief < 2
      kept our major raids a secret, and we've 
    made sure that at least one of the old Whendward Band was always with our people on hunts and patrols. They might have had no good chance to betray us.  Now we need to start giving them that chance, one or two at a time."

    You explain your plan to start creating openings for betrayal—to allow solo hunting again, and then start working down the list of suspects, ensuring that they find out details of a juicy upcoming raid.  "We'll keep a discreet eye on the ones we're testing, to see if they vanish on a 'hunt.'  And we'll also be the ones who go on ahead of the raid to confirm whether Alastors have been tipped off to our plans."
    *if rad_council and (radmar != 2)
      
      As Radmar and ${elder2} fall again to arguing over the list, you step back and consider the big young fighter.  [i]Is he bright enough to see the snare we're baiting for him as well?[/i]  
      
      The most valuable knowledge for the Hegemony isn't where we're going to raid, but where we're planning to camp in a week's time.  You and Zvad will make sure that Radmar finds out where you're supposedly heading, with the opportunity to communicate it during a raid. [i]And Angels help him if we find anyone there after changing course….[/i]
      *set radmar 3
    *page_break
    *if bred_here and ((bred_trust != 2) and (bred_trust != 4))
      It takes the rest of the afternoon to thrash out your suspect list and agree the details of the first test raid.  Then you break up the meeting.

      *if (bred_trust > 9) or (bred_trust = 3)
        All evening, you can see that Breden is impatient to get you alone.  On the way back from your evening ablutions in the woods, you are unsurprised to find ${xhim} waiting for you outside the camp.  "Sorry to trouble you, ${lname}, but I have to know.  
        *if not(bredsuspnow)
          When exactly did I stop being 
        *if (bredsuspnow)
          Am I supposed to believe I'm no longer 
        your first suspect?  
        *if (bredsuspnow)
          After you just told me so at the feast?"
          
          *goto sighsuspect
        I'm still clearly ${elder2}'s."
        *if deputy = "Breden"

          "You've been my right hand throughout the winter.  How many plans could you have ruined if you'd been a traitor?"

          "Not all that many, really," Breden replies, unsmiling.  "You've been happy to have me at your side, persuading the band to follow your lead—but you've been careful about what you tell me, and when, during any raid planning.  Did you think I hadn't noticed?"
          *if rollover5 = "Breden"

            "You didn't sell us out to the Alastors," you point out.  "You could have ruined that ambush with a sneeze."

            "It must have occurred to your suspicious soul that I was biding my time—trying to lull you into trusting me again.  You're no fool."
        *if deputy != "Breden"
          *if rollover5 = "Breden"

            "You didn't sell us out to the Alastors," you point out.  "You could have ruined that ambush with a sneeze."

            Breden doesn't smile.  "It must have occurred to your suspicious soul that I was biding my time—trying to lull you into trusting me again.  You're no fool."
        
        "You're too useful not to trust," you shrug.  "No one else could have helped me put that list of suspects together today. It'll be another thing if we test everyone on the list and don't catch anyone.  But I don't think that's going to happen."

        "And that's it?"  $!{xhe} sounds intensely skeptical.  
        *if (bred_lover < 4)
          "That's
        *if (bred_lover >= 4)
          "That—plus a
          *if bred_lover > 9
            shared bedroll—is
          *if bred_lover < 10
            night of dancing—is
        all it takes to get me back in the inner circle?"
        *if bred_lover >= 4
          Seeing your sudden scowl, ${xhe} raises ${xhis} hands in defense.  "${fname}, 
          *if bred_lover > 9
            I've
          *if bred_lover < 10
            I
          loved every
          *if bred_lover > 9
            kiss,
          *if bred_lover < 10
            dance,
          but…I'd hate to think it was a bluff, to convince me that you trust me again."
        
        *if bred_trust = 3
          You lean forward, looking straight into ${xhis} eyes. "Breden, it was always wrong for me to suspect you.  I may not have known you long, but I've known you long enough
          *if (bred_lover >= 4) or (bred_heart = 3)
            and well enough
          to know you're no traitor.  I lost sight of that, and I'm sorry."

          Breden stares stormily back at you, searching your face for any sign of duplicity.  At length, ${xhe} says, "I think I believe you."

          "And forgive me?"

          The ghost of a smile hovers around ${xhis} lips.  "Soon."
          *set bred_trust 2
          *page_break
          *goto newbie
        *label sighsuspect
        You sigh.  "You never were my first suspect, Breden.  You were always somewhere on the list, and you still are.  Yes, you're in my inner circle.  But…if you feel the need to go hunting this spring, ask Zvad to go with you."
        *if cha< 2
          *page_break
          Breden stares stormily back at you, searching your face for any sign of duplicity.  "You're useless as a liar, ${fname}," ${xhe} says at length. "You're trying to test me, too, somehow."

          Sometimes you wish you had the charisma to sound credible no matter what you're saying.  "I just told you, Breden—until we've found the traitor, I'll be watching you like anyone else."

          "That's not all, is it?" Breden persists.  "There's some other game you've cooked up.  You and Zvad?"
          *if zvad > 2
            $!{xhe} sees something in your expression that make ${xhis} eyes widen with horror.  "Tell me you didn't. Please, please, tell me you didn't share your…crazy suspicions with Zvad."
            
            "Breden…"

            "Oh, Xthonos damn you," Breden half-laughs, half-sobs.  "That's why he's been following me around everywhere.  He's going to kill me."  

            "Don't be ridic…"

            "Don't you say another damned thing."  $!{xhe} pushes a finger savagely into your collarbone.  "You forced this on me, ${lname}.  Remember that when the real traitor sells you to the Theurges."
            *set breden +10
            *set bred_here false
          *if zvad < 3
            $!{xhe} leans in, ${xhis} expression abruptly urgent and frightened.  "Please tell me you didn't share your crazy suspicions with Zvad."

            "Calm down, for Angels' sake.  All Zvad knows about the betrayal is what he just heard at our meeting.  I've certainly not singled you out as any sort of main suspect."

            Breden steps away from you, still scowling.  "Well…I suppose I should take that as a comforting indication that you haven't already decided to drive me out of the band."
          Before you can say anything else, ${xhe} stalks away. 
          *if not(bred_here) and not(nobred)
            *page_break
            *set deputy "Zvad"
            The next morning, you discover that Breden is gone.  $!{xhe} never returned to ${xhis} tent, and although the perimeter guards didn't see ${xhim} pass, ${xhe} is clearly nowhere in the camp.  

            "Do we hunt for ${xhim}, ${kuria}?" 
            *if rescuer = 0
              elder Hetten 
            *if rescuer != 0
              Pitrj
            asks.  He's clearly unsure whether the popular young helot's disappearance is due to a personal quarrel or something more serious.

            "No time," you say curtly.  "$!{xhe}'s made ${xhis} decision.  We don't force anyone to stay with the band."  

            As the rest of the band begins to move out, you beckon Zvad to one side.  "Our best scouts will be combing our backtrail, ${kuria}," he rumbles before you've said anything.  "If ${xhe}'s trying to follow us, or lead any trouble to us, we'll know."  You nod your gratitude.

            But there's no sign of Breden.  Not that day; not in the following days, as you lead the band deeper into the wilderness.  $!{xhe} really is gone.
            *if (bred_lover >= 4) or ((bred_heart = 2) or (bred_heart = 3))
              You're surprised by how strong the ache of abandonment is, and how long it takes to subside.            
            *if zvad > 2
              "Did I make a mistake, Zvad?" you finally ask a week later.

              "$!{xhe} was the traitor, ${kuria}."  The big ${whend} spits out of the tent.  "When ${xhe} knew we suspected ${xhim}, ${xhe} ran.  It's that simple.  No mistake."

              You wish you could be as sure as Zvad.  "Well, don't assume ${xhe} was the only traitor," you reply, trying to set aside your disquiet.  "We'll still check through everyone else."
              *set zvad 3
              *page_break
            *goto newbie
          *page_break
          *goto zvadscheme

        Affront and satisfaction struggle across Breden's face.  "That's more what I'd expected, Xthon'damn you."  $!{xhe} stalks away.
        *page_break
      *label zvadscheme
      That night, you meet Zvad again.  "That seemed to go well," he rumbles.

      *if (bred_trust > 9) and (cha < 2)
        "Well enough," you say distractedly, thinking of Breden's perceptiveness and barely contained fury.  "We'll need to be very careful in the coming weeks, though."
        *goto zvadscheme_2
      *else
        You nod and say in a low voice, "I don't think they saw through us."
        *goto zvadscheme_2
      *label zvadscheme_2
      
      "You're sure you need to test 
      *if zvad < 3
        Breden and
      ${elder2} as well?" Zvad asks, forehead furrowed.
      *if deputy = "Breden"
        "You don't trust your own deputy?"

      "It would be reckless to exempt any helot from my town, Zvad."  You don't actually suspect ${elder2}, and you are sure the big ${whend} knows it.  But 
      *if zvad > 2
        you don't want Zvad to lose sight of the fact that Breden might be innocent.
      *if zvad < 3
        if at all possible, you don't want Zvad to start singling out Breden as a prime suspect.  
      If you satisfy yourself that Breden is no traitor, ${xhe}'d
      *if deputy = "Breden"
        continue to
      be a natural leader in the band, and you don't want lingering suspicions to keep Zvad from working well with ${xhim}.

      Zvad shrugs.  "So we'll start baiting a snare for them, too."

      "As we discussed.  The most valuable knowledge for the Hegemony isn't where we're going to raid, but where we're going to camp in a week's time.  We'll make sure that Breden and ${elder} find out where we're heading, and give them the opportunity to communicate it during a raid."

      Much as he did when you first suggested the idea, Zvad shakes his head tolerantly.  "It's your hunt, ${kuria}, and I'll help as I can.  But there's a saying: the more traps you lay, the fewer places you have to set your 
      *if zvad > 2
        feet.  And if you think you know where the wolf sleeps, don't waste your time trapping the entire forest."
      *if zvad < 3
        feet."  
      He quickly changes the subject as you hear another outlaw approaching the tent.
      *page_break
    *goto newbie
*label newbie
*if rollover3 > 0
  *set nothief +rollover3
  *comment belatedly tracking whether you checked the Harrower
*if (rescuer = 0) and not(nohunt)
  Over the next week, you begin the slow process of giving your followers a chance to betray you, a few at a time.  
Meanwhile,
*if (morale >= followers) and (cred_h > 50)
  *set followers +7
  *set nonkids +7
  *if (rescuer = 0) and not(nohunt)
    as if sifting existing traitors from your band is not hard enough, 
  the spring brings a trickle of new outlaws.  One of these new arrivals is particularly noteworthy.
  *goto newbie_2
*else
  though 
  *if morale < followers
    your disheartened band hasn't attracted many new followers,
    *if cred_h < 50
      and
  *if cred_h < 50
    the helotry don't think enough of you to flock to your banner,
  you do get one noteworthy new arrival.
  *goto newbie_2
*label newbie_2

*if ((anarchy < 21) and (demerre < 4)) and (temple < 3)
  *if zhe = "she"
    *set simon "Suzane"
  *if zhe = "he"
    *set simon "Simon"
  *set simz_here true
  ${simon} de Firiac arrives in the company of two helots from ${zhis} family's estate.  $!{zhis} finely woven wool cloak covers brightly dyed silks and linens, and the sleek bay horse walking beside ${zhim} was not bred for the plow.  "$!{zhe} refused to disarm, ${kuria}," your patrol leader reports bemusedly.  "Said ${zhis} sword was ${zhis} honor, and ${zhe} was only going to surrender it to you."

  "Hilt-first, of course," the young noble says, carefully suiting action to word.  $!{zhis} hair is a glossy black, not dusty or wiry like so many others in your band. "$!{milady} ${lname}, the life and honor of ${simon} de Firiac is in your hands."

  "Well, ${zkuria}," you say as you accept ${zhis} blade, "you're the first of your sort we've seen passing through Whendward."  The sword is keen and finely balanced; it's clearly no mere heirloom, notwithstanding the elaborate family crest at the pommel.
  
  "We aren't 'passing through,' ${milady}," ${zhe} counters, bowing deeply.  $!{zhis} eyes are aglow with admiration as ${zhe} looks up at you. "We're here to join you."
  *page_break
  "For years, I've dreamed in secret of chasing the thieving Karagonds from Shayard.  My father beat me when I spoke of it, and my helot friends begged me to be cautious, lest we all be sent to the Harrower.  But your rebellion has set tongues wagging and hearts afire from here to Shayard City—and not just among the helotry."

  *if aristo
    You notice that as ${zhe} bows, the deliberate inclination of ${zhis} wrists and neck takes just the right angle to indicate genuine respect, not mocking hyperbole.  The young noble seems to have learned courtly etiquette from the same sort of detail-obsessed teacher who instructed you and your Keriatou cousins. 
  *if temple = 2
    *page_break
    "I've seen you before, haven't I?" you say, trying to place ${zhim}.

    ${simon} swallows.  "Yes.  You raided the Temple of Xthonos in my town."

    "Ah, that's right."  Now you remember the admiring glances the young noble threw you. 
  "You'd be the only aristo
  *if aristo
    besides myself and my father 
  in the Whendward Band.  Not to put too fine a point on it, ${zmilady} de Firiac: what makes you think you're welcome here?"
  *if helot
    It's still no easy thing for you to speak to a noble this way…but you need to make sure both ${zhe} and your fellow rebels are under no illusion that you'll give ${zhim} any deference.  [i]We've not started this rebellion just to hand it over to some aristo with a bow and a smile.[/i]
   
  *if aristo
    "Well, you made your place here, ${milady} 
    *if (lname_length > 3)
      ${lname}.  And
      *if ((lname_end = "atou") and aristo) and (natl > 50)
        whatever your House's name, I've heard you bear a passion for Shayard."
      *if ((lname_end = "atou") and aristo) and (natl < 51)
        whatever name your ancestors chose for your House, you're no pawn of the Karagonds."
      *if ((lname_start = "de ") and aristo)
        your House's name tells me you're not the first in your line to resist the Karagonds."
    *if lname_length <= 3
      ${lname}."
    When you don't respond to ${zhis} smile,
  ${simon} shrugs.  "I hoped any rebellion would welcome a blademaster, even one of only the first Kyklos.  More importantly, ${milady}, I think you know we'll never beat the Thaumatarch unless helots and aristocrats can come together, rather than waste our energies fighting each other!
  
  "Yours is the first helot rebellion I've heard of that has not simply ravaged the local nobility or dissolved into anarchy.  I'm wagering my life that you've made that choice deliberately—that you want to keep the door open for an uprising of all Shayardenes, even the nobles."
  *page_break
  "Well, that's very fine of you." You don't try to hide your skepticism.  "What about me wagering the lives of my band?  How can I know you're not a Kryptast?"
  
  ${simon} looks surprised for a moment, then breaks out laughing.  "Well, I imagine a Kryptast would be less obvious.  Surely they know how to impersonate helots as well as nobles?  But I also don't imagine you'll trust me right away.  I'll serve wherever you'll allow me, whether it be fighting Alastors or…or cleaning your boots!"
  
  "The young ${zkuria} is honest," one of ${zhis} helot companions adds fervently.  "$!{zhis} father will have disowned ${zhim} after ${zhe} ran off with us. If you send us away, we'll have nowhere to go."
  
  You glance over to your companions.  
  *if bred_here
    Breden looks intrigued;
  Zvad looks dubious.  Most of the other outlaws, including
  *if el_here
    Elery and
  Radmar, are visibly hostile to the idea of admitting a noble.
  *if aristo
  
    Your willingness to confront Theurge Chirex won you their allegiance, and they've accepted your father on sufferance.  But this is different.
  Allowing ${simon} to join the band would be a clear sign that you are (as ${zhe} said) ready to welcome not just helots but the
  *if arrog <= 0
    old
  ruling class into your rebellion.
  *if helot
    And you've got scarce confidence that ${zhe} wouldn't try to take over from you.
  *choice
    #Accept ${zhim} into the band.
      *set s_rel 1
      *set followers +3
      *set nonkids +3
      *set cred_h -10
      *set cred_y -10
      *set cred_a +10
      *if (arrog < 1) or helot
        "All right, ${simon}.  But you dress like the rest of us, live like the rest of us, and travel like the rest of us. Those fine clothes, that horse, and whatever wealth you came with—it all belongs to the band now." 

        "If you'd come during the winter, those would have saved some lives," Zvad adds brusquely.

        ${simon} reddens.  "If we'd come a month ago, we would have needed to hide away more winter supplies, and the chance of being caught before we even left would have been greater…."

        You wave a hand at the two of them.  "It doesn't matter.  Are you happy for us to sell your horse and all your noble trappings?"
        
      *if (arrog > 0) and aristo
        You bow with (you hope) the same nuance and precision as your new comrade. "Then welcome to the rebellion, ${zmilady} de Firiac."  It's hard to restrain your enthusiasm at finally having someone else of your own social caliber in the band, but you want to be sure you have the measure of this ${simon} before letting your guard down. "It grieves me that we cannot treat you according to your deserts.  You'll share a tent—and we'll need to sell your horse."
        
        Clearly ${simon} had already reconciled ${zhim}self to that loss; ${zhe} only smiles.
      "Of course, ${milady}.  Anything for the cause."

      "And this sword?"  You hand the weapon casually to ${deputy}.

      $!{zhis} eyes dart after it as ${zhis} shoulders stiffen.  "$!{milady}—as I've said, that sword is my honor."

      *if skep > 50
        "Drivel," you say, quietly but sharply.  "Honor is not something that can be bound up in a bit of metal.  That's just another mystical fiction the Karagonds have taught us, and I don't have any patience for it.  Honor is something you earn by standing up for the truth.  Can you do that without this sword?"

      *if skep < 51
        "What's more important—your honor, or bringing down the Thaumatarch?"

        The young noble sets ${zhis} chin stubbornly.  "I don't believe the two come into conflict."

        "Very nice—until you insist that your honor depends on you holding a particular bit of metal.  Let's be clear: to defeat the Thaumatarch, would you be willing to part with this sword?"

      "Yes, ${milady}."

      "This fine family heirloom, which could likely be sold to buy a dozen axes for your comrades?"

      "Yes, ${milady}."  There are tears standing in ${zhis} eyes, but ${zhe} grates out the answer without pause.
      *choice
        #Good.  We'll need as many of the band armed as possible.
          Zvad should be able to exchange this with your fence Cacelon.  You nod to the big Whend, then turn back to the resolute young noble.  "Your sacrifice does you credit.
          *set s_sword 0
          *set arms +12
          *gosub simonhaze
          Understood?"
          
          ${simon} nods fervently. "Understood, ${kuria}.
          *goto noregretit
        #If ${simon} really is a low-ranking blademaster, I'm not about to trade away the best sword in the band.
          *goto enoughblade
        *if aristo
          #Having made my point…of course I'm not going to deprive a fellow noble of ${zhis} family blade.
            *goto enoughblade
        #That sword would look good on me.
          *set s_sword 2
          *if helot
            You've been wanting to learn how to use a blade.
          *if aristo
            Your own 
            *if weapon != "sword"
              long-lost
            blade 
            *if weapon = "sword"
              is 
            *if weapon != "sword"
              was 
            nowhere near the quality of ${simon}'s heirloom.
          *set weapon "sword"
          And a leader always looks better with a fine sword at ${his} side.  
          *if helot or (com < 1)
            Perhaps you can prevail upon ${simon} for some lessons.
          "Well, I'll keep it for now.
          *gosub simonhaze
          Understood?"
          
          ${simon} nods fervently. "Understood, ${kuria}.
          *goto noregretit
      *label enoughblade
      You wait for a moment, then say, "As it happens, we've got enough maces at the moment."  You press on before anyone in the band can protest.  "But that doesn't change what I said about honor, so keep it in mind.
      *gosub simonhaze
      And your sword back."

      A huge, elated smile breaks across ${zhis} face.  "Thank you, ${kuria}!  
      *label noregretit
      *achieve simon
      You won't regret it, on my life!"  
      *if not(bred_here)
        $!{zhis} infatuation is as clear as if ${zhe} had dropped to one knee to confess it.  It seems you'll need to deal with…
        *choice
          *if zhe = "he"
            *selectable_if (not(acepref)) #Simon's disappointment when he realizes I'm not attracted to men.
              It's a shame, but you simply couldn't be attracted to Simon if you tried.  Hopefully his passion for your cause will survive a little heartbreak.
              *goto namechange
          *if zhe = "he"
            *selectable_if (not(acepref)) #The temptation of an attractive young nobleman who plainly admires me.
              *set malepref true
              *set simzpref true
              *goto seduction
          *if zhe = "she"
            *selectable_if (not(acepref)) #Suzane's disappointment when she realizes I'm not attracted to women.
              It's a shame, but you simply couldn't be attracted to Suzane if you tried.  Hopefully her passion for your cause will survive a little heartbreak.
              *goto namechange
          *if zhe = "she"
            *selectable_if (not(acepref)) #The temptation of an attractive young noblewoman who plainly admires me.
              *set femalepref true
              *set simzpref true
              *label seduction
              You doubt that ${simon} would simply tumble into a bedroll with you, even given the opportunity.  
              *if not(bulwark)
                *if aristo
                  Like you and every other young noble, for years ${zhe}'ll have been taught that erotic self-control is one of the key things that separates humans from beasts.  ${simon}'s clearly the honorable type; you don't think ${zhe}'ll see ${zhis} rebellion against Karagon as a rebellion against the Canon's code of chastity.
                *if helot
                  Young nobles are raised with a rigid code of chastity, and ${simon}'s clearly the honorable type.

                The helots of your town are somewhat less strict.  Like everyone raised under the Angels' Canon, they understand that matrimony is one of life's most crucial bulwarks against Xaos—taming the unruliest of passions, quenching the uncontrollable violence of jealousy.  But it's widely accepted that helot youth will often discreetly "range" a little before settling down with a spouse.

                The Whendward bandits tend to be even more pragmatic and far less discreet.  As one of them wryly explained to you, "When life's this hard and short, ${kuria}, you don't ask, 'Am I letting more chaos into the world?'  You just ask, 'Would it make him happy—and will anyone else knife me for him?'"

              For your part, you intend to…
              *choice
                #Keep ${simon} at arm's length.
                  You don't need any more chaos in your life than there is already.  Hopefully ${simon}'s passion for your cause will survive a little heartbreak.
                  *goto namechange
                #Befriend ${zhim}.
                  *set s_rel 2
                  *if aristo
                    It would be nice to have someone else in the band who was raised enjoying the same things as you—you would have far more topics for conversation than with the other outlaws.
                  *if helot
                    Having a friendship with an aristocrat is hard to imagine, given the much-emphasized distance between your stations.  But ${simon} seems genuinely eager to reach out across that gulf.
                  You'll just take care not to give ${zhim} the impression that you intend anything other than friendship.
                  *goto namechange
                #Seduce ${zhim}—if I'm convinced ${zhe}'s trustworthy.
                  *set s_rel 3
                  *if helot
                    Having this kind of power over a noble is an intoxicating inversion of all the rules you grew up with.
                  It shouldn't be hard to stoke the flames of ${simon}'s attraction to you as you get to know ${zhim} better.  By the time you're satisfied that ${zhe}'s sincere, you should have ${zhim} wrapped around your finger.
                  *goto namechange
          *if (acepref) #Another admirer who'll need to learn that I'm not interested in anyone that way.
            *if helot
              Gratifying to your pride as it might be to have an aristo lover, it's 
              *if aropref
                just not going 
              *if not(aropref)
                vanishingly unlikely
              to happen.
            Hopefully ${zhis} passion for your cause will survive a little heartbreak.
            *if aristo
              And at least you'll get to enjoy the benefits of having someone else in the band who was raised with the art of civilized conversation.
            *goto namechange
        *label simonhaze
        *if (aristo) and (kuria = "Captain")
          *set cred_h +10
          Another thing: we don't do noble titles here.  I don't want to hear anyone calling you ${zkuria}, or ${zmilady}, or any title you haven't earned by fighting the Thaumatarch.  If your two companions earn leadership before you do, you'll obey them.  Understood?"  ${simon} nods fervently; you hope ${zhis} humility mollifies at least some of the other outlaws.  "Very well.
        *if arrog < 1
          You'll start on gathering duty—roots, herbs, brush and firewood.  If we decide to trust you, then we'll see about giving you a more active role in the rebellion. 
        *if arrog > 0
          Once you've proven yourself, we'll give you the role you merit.
        *return
      *else
        
        As ${simon} is led away, Breden drifts over and murmurs in your ear, "You do realize ${zhe}'s in love with you, O great and
        *if aristo
          noble 
        *if helot
          glorious
        ${kuria}."
        *if aristo
          There's something in the way ${xhe} emphasizes the word "noble" that makes you uncomfortable.
        
        "$!{zhe}'s in love with the rebellion," you reply shortly.  "We'll see how long that lasts."  Breden's probably right, though.  You'll need to deal with…
        *choice
          *if zhe = "he"
            *selectable_if (not(acepref)) #Simon's disappointment when he realizes I'm not attracted to men.
              *goto notemptation
          *if zhe = "he"
            *selectable_if (not(acepref)) #The temptation of an attractive young nobleman who plainly admires me.
              *set malepref true
              *set simzpref true
              *goto temptation
          *if zhe = "she"
            *selectable_if (not(acepref)) #Suzane's disappointment when she realizes I'm not attracted to women.
              *goto notemptation
          *if zhe = "she"
            *selectable_if (not(acepref)) #The temptation of an attractive young noblewoman who plainly admires me.
              *set femalepref true
              *set simzpref true
              *goto temptation
          *if (acepref) #Another admirer who'll need to learn that I'm not interested in anyone that way.
            *if helot
              Gratifying to your pride as it might be to have an aristo lover, it's 
              *if aropref
                just not going 
              *if not(aropref)
                vanishingly unlikely
              to happen.
            Hopefully ${zhis} passion for your cause will survive a little heartbreak.
            *if aristo
              And at least you'll get to enjoy the benefits of having someone else in the band who was raised with the art of civilized conversation.
            *goto notemptation

        *label notemptation
        Breden shrugs.  "I'd wager ${zhis} love for our rebellion will end one week from the moment that ${zhe} loses the hope of winning your heart."

        "Indeed?"  You look quizzically at Breden—is ${xhe} really jealous of this noble, even though you 
        *if (aropref or not(acepref)) or ((bred_lover != 11) and (bred_lover != 12))
          couldn't 
        *if (acepref and not(aropref)) and ((bred_lover = 11) or (bred_lover = 12))
          doubt you could
        be attracted to ${simon} if you tried?  "Well, you'll need to keep a close eye on ${zhim} to win that wager. Care to choose a small group
        *if sybla > 0
          of those who already had some sword training from Sybla
        and start daily blade training with ${zhim}, from tomorrow?"

        After an instant of surprise, ${xhe} grins and inclines ${xhis} head in assent.  "All right, ${kuria}.  Start with sticks, move on to steel?"

        "Yes.  Tell me what our new blademaster is made of."
        *goto namechange
        *label temptation
        Breden raises an eyebrow at you.
        *if (bred_lover != 0) or ((bred_heart = 3) or (bred_heart = 7))
          You're sure you hear a jealous note in ${xhis} voice.
        "And we'll see how long you're able to resist temptation?"
        
        *if (bred_lover = 0) and ((bred_heart != 3) and (bred_heart != 7))
        
          "A long damned time," you retort sharply.  "At the very least, until I'm sure ${zhe}'s no Kryptast."
          *goto nokrypt
        *if (bred_lover != 0) or ((bred_heart = 3) or (bred_heart = 7))
          *choice
            #"Longer than you can resist jealousy," I tease.
              It's rare enough that you see Breden flustered.  
              *if (bred_heart != 7) and (bred_lover > 3)
                You enjoy the moment while it lasts.
              *if (bred_heart = 7) or (bred_lover <= 3)
                But the flare of pain on ${xhis} face is too naked for you to enjoy it.
              *goto bladetrain
            *if (bred_lover > 3) or (bred_heart = 3)
              #I just laugh. "Do you honestly think you've anything to worry about?"
                It's rare enough that you see Breden flustered, and you enjoy the moment while it lasts.
                *goto bladetrain
            #"$!{oath}, Breden, ${zhe}'s not [i]that[/i] tempting."  I barely know ${zhim}, after all.
              You wave off the idea with some annoyance.
              *goto bladetrain
            #"A long damned time," I retort sharply.  "At the very least, until I'm sure ${zhe}'s no Kryptast."
              *label nokrypt
              *if ((bred_lover > 0) or (bred_heart = 3)) and (bred_trust > 9)
                You swallow your next thoughts unspoken, but Breden looks as pained as if you'd said them aloud: the last thing you need is to fall in love with someone else who might be a traitor.
                *goto bladetrain
              *else
                As soon as the words leave your mouth, you wonder whether Breden will hear an unintended accusation in them—but ${xhe} seems unfazed.
                *goto bladetrain
        *label bladetrain
        "Enough of 
        *if not(el_here)
          that. I
        *if el_here
          that." You turn to Elery. "I
        need you to select a small group
        *if sybla > 0
          of those who already learned the first thing about a sword from Sybla
        and start daily blade training with de Firiac, from tomorrow."

        *if not(el_here)
          $!{xhe} 
        *if el_here
          She
        looks surprised for a moment, but quickly recovers.  "All right, ${kuria}.  Start with sticks, move on to steel?"

        "Yes.  Tell me what our new blademaster is made of."
        *goto namechange
    #Reject ${zhim} and try to ransom ${zhim} back to ${zhis} family.
      *set followers +2
      *set nonkids +2
      *set cred_a -10
      *set cred_h +10
      *set cred_y +5
      *set s_rel 10
      *achieve kidnap
      *set notoriety +5
      *set anarchy +1
      *set violence +1
      "I'm sorry, ${zkuria}," you say quietly.  "You're right, we're not a bunch of Xaos-loving brigands, burning down estates for the joy of it.  But I won't ask my followers to fight alongside the families that have oppressed them for generations.  You're useful to us for whatever ransom your father will pay, nothing more."

      ${simon} looks as stunned as if you'd physically struck ${zhim}.
      *if aristo
        "But…but damn it, ${lname}, you're noble yourself!"
        
        *if arrog <= 0
          "I was, to my shame."
        *if arrog > 0
          "And thus well-equipped to make the hard decisions that a rebellion needs."
      *if helot
        "Then…I have been a very great fool."

        You shrug.  "If you thought it would be easy to get a band of rebel helots to ignore what the nobles of Shayard have done to them…then yes."
      You look away from ${simon} to the two helots who accompanied ${zhim}.  "You'll be free to stay or leave.  Though I fear it won't be much of a choice, with the de Firiacs thinking you conspired with us to kidnap their young ${zkuria}.  But make the choice in a few days' time.  Take the time to think about where your loyalties lie."  They exchange shamefaced glances with each other and their former master, but say nothing.

      "And when my father doesn't ransom me?" ${simon} demands.  "He won't, you know.  He'd rather you killed me—removed his shame."
      *choice
        #"Then he'll get his wish."
          *set ruth %+5
          *set s_rel 11
          ${simon}'s cheeks darken, and ${zhe} seems close to tears.  "You're a brutal, short-sighted thug, ${lname}.  You couldn't be less like the ${woman} I'd hoped to find."

          "Your hopes aren't really that important, ${zkuria}," you reply.  "But we can all hope that your father chooses to ransom you.  Take ${zhim} away."

          *goto orientchoice
        #"Then we'll see if we can find another customer."
          "We might offer you to Conte Leilatou, for example.  Isn't the Archon supposed to protect all the nobles under her authority?"

          *label simztears
          ${simon} shakes ${zhis} head, sounding close to tears.  "You really mean to discard my allegiance so lightly, ${kuria} ${lname}?"

          "I don't do it lightly, ${zkuria} de Firiac.  I do it in the expectation of a large ransom.  Until we receive it, please enjoy the hospitality of the greenwood."

          *goto orientchoice
        #"We'll cross that bridge if we need to."
          *goto simztears
      *label orientchoice
      *if not(bred_here)
        ${simon} gives you one last stricken, incredulous look before ${zhe} is led away—and you realize that you've rejected not only a noble blademaster, but an attractive young
        *if femalepref or (acepref and (zgirl = "boy"))
          man
        *if malepref or (acepref and (zgirl = "girl"))
          woman
        who is wholly infatuated with you.
        *choice
          *if zhe = "he"
            *selectable_if (not(acepref)) #That's fine—I'm not attracted to men anyway.
              Dealing with Simon's eventual disappointment when he realized his dreams could never be fulfilled would only have been a headache.
              *goto zvadnap
          *if zhe = "he"
            *selectable_if (not(acepref)) #That's fine—I could have resisted the temptation.
              *set malepref true
              *set simzpref true
              It certainly doesn't change your calculation that he's more useful to you for his ransom than as a follower.
              *goto zvadnap
          *if zhe = "she"
            *selectable_if (not(acepref)) #That's fine—I'm not attracted to women anyway.
              Dealing with Suzane's eventual disappointment when she realized her dreams could never be fulfilled would only have been a headache.
              *goto zvadnap
          *if zhe = "she"
            *selectable_if (not(acepref)) #That's fine—I could have resisted the temptation.
              *set femalepref true
              *set simzpref true
              It certainly doesn't change your calculation that she's more useful to you for her ransom than as a follower.
              *goto zvadnap
          *if (acepref) #At least I won't need to explain to this one that I'm not interested in anyone that way.
            Dealing with ${simon}'s eventual disappointment when ${zhe} realized ${zhis} dreams could never be fulfilled would only have been a headache.
            *goto zvadnap
            
      *else
        As ${simon} is led off under guard, Breden drifts over and murmurs in your ear, "You do realize our prisoner is in love with you, O great and
        *if aristo
          noble 
        *if helot
          glorious
        ${kuria}."
        *if aristo
          There's something in the way ${xhe} emphasizes the word "noble" that makes you uncomfortable.

        "$!{zhe} was in love with the rebellion, not me," you reply shortly.  And even if Breden were right…
        *choice
          *if zhe = "he"
            *selectable_if (not(acepref)) #Simon would simply have been disappointed when he realized I'm not attracted to men.
              *goto notemptation_2
          *if zhe = "he"
            *selectable_if (not(acepref)) #I could resist the temptation of an attractive young nobleman.
              *set malepref true
              *set simzpref true
              *goto temptation_2
          *if zhe = "she"
            *selectable_if (not(acepref)) #Suzane would simply have been disappointed when she realized I'm not attracted to women.
              *goto notemptation_2
          *if zhe = "she"
            *selectable_if (not(acepref)) #I could resist the temptation of an attractive young noblewoman.
              *set femalepref true
              *set simzpref true
              *goto temptation_2
          *if (acepref) #At least I won't need to explain to this one that I'm not interested in anyone that way.
            Dealing with ${simon}'s eventual disappointment when ${zhe} realized ${zhis} dreams could never be fulfilled would only have been a headache.
            *goto notemptation_2
        *label notemptation_2
        Breden shrugs.  "If you say so, ${kuria}.  How do you intend to let ${zhis} father know we have ${zhim}?"

        "We'll pass the word through one of our merchant friends."  
        *goto zvadnap
        *label temptation_2
        Breden raises an eyebrow at you.
        *if (bred_lover > 0) or ((bred_heart = 3) or (bred_heart = 7))
          You're sure you hear a note of jealousy in ${xhis} voice.
        "If you say so, ${kuria}.  How do you intend to let ${zhis} father know we have ${zhim}?"

        "We'll pass the word through one of our merchant friends."
        *label zvadnap
        You glance over to Zvad.  "Has the band ever dealt in ransoms in the past?"

        The ${whend}ish outlaw shakes his head.  "Not as I know, ${kuria}.  Didn't want to provoke the nobility and Theurges too far."  He rubs his craggy chin resignedly.  "But you provoked them even farther before you joined us…so we may as well wring all the silver we can out of them."

        "Silver?  I was thinking of '${zhis} weight in gold.'  Isn't that what the pirates and bandits always ask for in the stories?"

        Zvad gives an amused grunt.  "Don't try to swap a sheep for a horse, ${kuria}.  If the father coughs up enough silver to outweigh the young ${zkuria}'s boots, I'd be surprised.  But we'll see."
        
        You nod, and conclude with:
        *choice
          #"Meanwhile, sell ${zhis} sword.  That could buy a dozen axes for the band."
            *set s_sword 0
            *set arms +12
            "Done, ${kuria}," Zvad says approvingly.  "Some of my old friends should be able to move a sword like that for us."
            *goto namechange
          #"Regardless, I'll keep ${zhis} sword."
            *set s_sword 2
            *if helot or (com = 0)
              "You can use a sword, ${kuria}?" Zvad queries, looking dubious.
              
              *if helot
                *set cred_a -5
                *set cred_h +10
                *set cred_y +5
                There's a delightful tang of the forbidden to it—wielding not only a sword, but a noble's own family heirloom.  "No, but 
              *if aristo
                "Not well," you admit.  "But
              I've been meaning to learn."
            *if aristo
              You have a sword, but it's no heirloom like this one.
            *if com = 2
              ${simon}'s blade is of extraordinary quality, far better than any you've 
              *if aristo
                sparred with.
              *if helot
                seen in Rim Square.
            *if helot
              You reckon
            *if aristo
              And 
            a leader always looks better with a fine sword at ${his} side.
            *goto namechange
*else
  *achieve kalt
  *set kal_here true
  *set followers +1
  *set nonkids +1
  *if zhe = "she"
    *set kalt "Kala"
  *if zhe = "he"
    *set kalt "Kalt"

  ${kalt} is small and gaunt even for a helot, with narrow hips, a markedly concave stomach, and ribs distinctly visible through the rips in ${zhis} kyrtle.  By contrast,  ${zhis} face is broad-featured, with wide lips, flat cheekbones, and a crooked nose that looks as if it has been repeatedly broken.  $!{zhe} doesn't have a helot's customary self-effacing slouch; of all the helots you've known, only 
  *if helot
    you and Breden come
  *if aristo
    Breden comes 
  close to ${zhis} proud posture and tone.

  "You're Captain ${fname} ${lname} of Whendward," ${zhe} declares loudly. "I'm $!{kalt} Swineherd. I came looking for you."
 
  "Why me?"

  "We've heard a lot about you down on the great farm estates, captain."  $!{zhis} words spill out with youthful fervor and only a trace of audible nervousness. 
  *if demerre > 3
    "They say that you break Harrowers, fight Theurges…and slaughter nobles in their homes."

    "All that's true."

    "Well, that's enough for me."  ${kalt} casts ${zhis} eyes around the other outlaws.
    *goto kaltmurd
  *elseif cred_h < 100
    "They say that you're a callous brute who claims to fight in the name of the helots, but doesn't care about us at all."

    You sigh.  "So why are you here?" 

    "Because I don't think it's true.  I think you're just clumsy, maybe a little foolish, and poorly advised."  Before you have time to react, ${kalt} presses on.
    *goto kaltmurd
  *elseif (gandhi > 0)
    "They say that you're trying to topple the Thaumatarchy—and that you'd like do it without killing people."

    *if violence <= 8
      "With as little chaos and violence as possible," you affirm, remembering your appeal 
      *if aristo
        to the helots 
      back in the agora of Rim Square.
      *if violence > 0
        You've not been completely peaceable, but you've done what you can to limit the damage of your revolt.
      "Is that why you're here?" 
      
      "I'm here because you've managed to stir up plenty of anarchy, which gave me reason to hope
    *if violence > 8
      It takes a moment for you to remember how your rebellion began: with a desperate appeal to the mob in Rim Square to spare their oppressors. "Ah.  That didn't survive the winter, I'm afraid."

      "Good.  I was hoping
    you're not as naive as you sound."  Before you have time to react, ${kalt} presses on.
    *goto kaltmurd
  *elseif (cred_h > 299) and (cred_a < 150)
    "They say that the helots love you and the nobles hate you."

    "And that's why you're here?" 

    "Sounds to me like you're doing something right."  ${kalt} grins and casts ${zhis} eyes around the other outlaws.
    *goto kaltmurd
  *elseif (cred_h > 299) and (cred_a >= 150)
    "They say that the helots love you…and the nobles don't hate you nearly as much as you'd expect."

    "And that's why you're here?" 

    "I'm here because it's time the aristos got scared of you. I can help you with that."  Before you have time to react, ${kalt} presses on.
    *goto kaltmurd
  *else
    "They say that you're trying to fight the Thaumatarchy, but haven't yet got the helots to love you."

    "So why are you here?" 

    "To teach you what we really want from your rebellion."  Before you have time to react, ${kalt} presses on.
    *goto kaltmurd
  *label kaltmurd 
  "Will you take a fleeing murderer into your band?"
 
  You raise an eyebrow. "That depends on who you killed, and why."
  
  "My master's son."  ${kalt}'s face tightens, but ${zhis} voice stays level. "His father tried for years to beat some proper deference into me.  The boy got to the age where he was interested in more than just beating helots, and one morning he thought he'd try it with me.  I broke his skull with an iron firedog and went out the window."
  *page_break
  "With that kind of story, you'll fit in well here." You keep your eyes on ${zhis} face as you suggest, "It's also the sort of story a Kryptast spy would tell to ensure a sympathetic welcome, don't you think?"
  
  *if lname_length > 3
    *if aristo and (lname_start = "de ")
      "In a band led by young
      *if male
        lord
      *if female
        lady
      Lofty de Shayarin?  I reckon they'd be safer to make up some tale about the local Alastor."  After a moment's wry silence,
  ${kalt} breaks into an unexpected smile and spreads ${zhis} hands. "It's good you're not 
  *if gandhi > 0
    completely
  a soft heart, captain.  But put me in front of an Alastor, or an Ecclesiast, or a
  *if lname_length > 3
    *if aristo and (lname_start = "de ")
      less well-meaning
  noble, and I'll kill them.  And I'll keep killing them even after you believe I'm who I say I am."
  
  *if lname_length > 3
    *if aristo and (lname_start != "de ")
      "I'm a noble," you point out drily.
    
      "You are,
      *if (lname_end = "atou")
        and with a Karagond name
      at that," ${kalt} shrugs.  "But you seem to mean well, so I'll make an exception."
  *if (lname_length < 4) and aristo
    "I'm a noble," you point out drily.
    
    "You are, at that," ${kalt} shrugs.  "But you seem to mean well, so I'll make an exception."
  
  You consider ${zhim} in silence for a moment.  Only a handful of your band genuinely take relish in violence; your intuition tells you that if ${kalt} had the skill to match ${zhis} ferocity, ${zhe} could become your rebellion's most formidable killer.  $!{zhe} could also, needless to say, be a great deal of trouble.  At length you tell ${zhim}:
  *choice
    #"Then start killing them.  Kill enough, and one day you'll be a general."
      *set ruth %+10
      *set cred_a -5
      *if gandhi > 0
        Perhaps ${kalt} is right; perhaps you were naive to think that you could transform the Hegemony with little anarchy.  Your months of banditry have confirmed that you can't keep a rebellion alive without bloodshed.  Now you'll let ${kalt} try it ${zhis} way.
        
        *set gandhi 0
      ${kalt} beams at you, eyes ablaze.  "Aye, captain.
      *if cred_h < 299
        That's what the helots want to hear from you: that you're willing to avenge every Harrowing, every beating, every violation we've suffered from the nobles and the Hegemony.  That's what will make them love you."
      *if cred_h > 298
        That's what I was expecting from you.  That's what has won you the love of the helots."
      *goto kaltcrush
    #"Just so long as you're killing the right people, at the right times."
      "Not much use in killing the wrong people." ${kalt}
      *if demerre = 3
        folds ${zhis} arms, scowling slightly. "But I'll tell you true, ${kuria}, I was sad to hear you
        *goto kmercydm
      *if demerre > 3
        grins at you. "And from what I've heard of the fate of House de Merre, we seem to have the same ideas about that."
      *if demerre < 3
        shrugs lightly. "Your rebellion's killed enough so far. I reckon we'll find some we would both agree are the right ones."
      *goto kaltcrush
    #"We don't measure victory by how many people we kill, ${kalt}."
      *set ruth %-5
      *set cred_a +5
      ${kalt} is clearly struggling to keep scorn out of ${zhis} voice.  "Yes, I'd heard you 
      *if demerre != 3
        were a compassionate ${woman}, with
      *if demerre = 3
        *label kmercydm
        had mercy on House de Merre because of 
      some idea that we could win 
      *if demerre > 3
        without ruthlessness.  
      *if demerre < 4
        over the nobility.  
      It shook my confidence in you."

      "And yet you're here?"

      ${kalt} steps up to you, eyes ablaze. "You're the only rebel leader
      *if cha = 2
        in a generation with the charisma to tie us together.  Let's be honest, you've done nothing of real note—but already your legend is igniting across Shayard.
        *if morale >= followers
          Your followers talk about you like you're an Angel of Xthonos.
      *if com = 2
        in a generation who could possibly lead us to victory against the Thaumatarch's armies.  The helots talk in awe about how you fight.
      *if (int = 2) and (theuknown > 0)
        in history to wield the power of Theurgy.
      *if (int = 2) and (theuknown < 5)
        with the intellect to guide us to victory.  If the helots agree on one thing, it's that no one else understands the way our enemy thinks like you do.
      So where else could I go, captain?"  $!{zhe} shakes ${zhis} head.  "Either I win you over, you stop holding back, and we tear down the Hegemony together…or the Hegemony kills us all.  I'll take my chances with you."
      *goto kaltcrush
  *label kaltcrush

  Looking at ${zhis} bright gaze and the way ${zhis} lips remain slightly parted even as ${zhe} stops speaking, you realize that you're going to have to deal with…
  *choice
    *if zhe = "he"
      *selectable_if (not(acepref)) #Kalt's eventual disappointment when he realizes I'm not attracted to men.
        It's a shame, but you simply couldn't be attracted to Kalt if you tried.  Still, you're fairly sure that his passion for the cause will survive a little heartbreak.
        *goto kaltwelcome
    *if zhe = "he"
      *selectable_if (not(acepref)) #The temptation of a follower who is infatuated with me.
        *set malepref true
        *set kalpref true
        *goto kaltseduce
    *if zhe = "she"
      *selectable_if (not(acepref)) #Kala's eventual disappointment when she realizes I'm not attracted to women.
        It's a shame, but you simply couldn't be attracted to Kala if you tried.  Still, you're fairly sure that her passion for your cause will survive a little heartbreak.
        *goto kaltwelcome
    *if zhe = "she"
      *selectable_if (not(acepref)) #The temptation of a follower who is infatuated with me.
        *set femalepref true
        *set kalpref true
        *goto kaltseduce
    *if acepref
      #Explaining to yet another admirer that you're not interested in anyone that way.
        You hope that ${zhis} passion for the cause will survive a little heartbreak.
        *goto kaltwelcome
  *label kaltseduce    
  *if bred_here
    *if (breden = 1) and (bred_heart < 10)
      You cast a fleeting glance at Breden.  From the taut expression on ${xhis} face, half-amused and half-angry, you are fairly sure that ${xhe} has picked up on the same signals.
    *goto kaltwelcome
  *else
    For a moment, you wonder how ${kalt} would react if you set out to seduce ${zhim}.  
    *if bulwark
      You can't imagine ${zhim} being that concerned about sowing chaos—${zhe} seems the type who would revel in unruly passion for its own sake.
    *if not(bulwark)
      In your part of the world, everyone is raised to understand that matrimony is one of life's most crucial bulwarks against Xaos—taming the unruliest of passions, quenching the uncontrollable violence of jealousy.  
      *if aristo
        Young nobles like yourself are expected to abide by a particularly rigid code of chastity.
      But among the helotry, it's widely accepted that young helots will discreetly "range" a little before settling down with a spouse.

      The Whendward bandits tend to be even more pragmatic and far less discreet.  As one of them wryly explained to you, "When life's this hard and short, ${kuria}, you don't ask, 'Am I letting more chaos into the world?'  You just ask, 'Would it make him happy—and will anyone else knife me for him?'"
      
    For your part, you intend to…
    *choice
      #Keep ${kalt} at arm's length.
        You don't need any more chaos in your life than there is already—and ${kalt}'s blazing eyes practically promise chaos.  You're fairly sure that ${zhis} passion for your cause will survive a little heartbreak.

        "Then welcome to the band, ${kalt}," you say pleasantly, bowing to ${zhim}.  "Zvad will find you some less ragged clothes and show you where to sleep."
        *goto namechange
      #Befriend ${zhim}.
        You don't need any more chaos in your life than there is already—and ${kalt}'s blazing eyes practically promise chaos.  You're fairly sure that ${zhis} passion for your cause will survive a little heartbreak.
        *goto namechange
      #Seduce ${zhim}—if I'm convinced ${zhe}'s trustworthy.
        *set k_rel 2
        It shouldn't be hard to stoke the flames of ${kalt}'s attraction to you as you watch ${zhim} and see what ${zhe}'s made of.  By the time you're satisfied that ${zhe} can be trusted, you're sure ${zhe}'ll accept your advances.

        "Well, you're one of us now, ${kalt}," you say warmly, gripping ${zhis} hand in yours.  "And we'll put your passion to good use.  Follow me—we'll find you some less ragged clothes, and I'll show you where you can sleep for now."
        *goto namechange
  *label kaltwelcome
  "Then welcome to the band, ${kalt}," you say evenly.  "You're among friends.  You and I can talk more later—but for now, Zvad will find you some less ragged clothes and show you where to sleep."
  *if bred_here
    
    As ${kalt} follows Zvad into the camp, Breden leans over to you with a low, impressed whistle.  "You've brought the wolf inside the walls with that one, ${fname}."
    *if (bred_lover > 0) or ((bred_heart = 3) or (bred_heart = 7))
      You think you hear a jealous note in ${xhis} voice.
    *if (bred_lover = 0) and ((bred_heart != 3) and (bred_heart != 7))
      
      "You think I should start closing our doors to helots who want to join?" you ask, a little testily.
      
      *goto notatall
    *if (bred_lover > 0) or ((bred_heart = 3) or (bred_heart = 7))
      *choice
        #I throw ${xhim} a wry glance.  "Jealousy's a mind-clouder, you know."
          It's rare enough that you see Breden flustered.
          *if (bred_heart != 7) and (bred_lover > 3)
            You enjoy the moment while it lasts.  Then you
          *if (bred_heart = 7) or (bred_lover <= 3)
            But the flare of pain on ${xhis} face is too naked for you to enjoy it.  You
          *goto whateverhis
        *if (bred_lover > 3) or (bred_heart = 3)
          #I just laugh. "Do you honestly think you've anything to worry about?"
            It's rare enough that you see Breden flustered, and you enjoy the moment while it lasts.  Then you
            *label whateverhis
            turn your gaze back to ${kalt}.  "Whatever ${zhis} reasons, 
            *if (bred_lover > 3) or (bred_heart = 3)
              love,
            we'll need all the wolves we can get."
            
            "Aye, that's true enough."  Breden regains ${xhis} composure and shakes ${xhis} head.  "But
            *goto watchout
        #"$!{oath}, Breden, ${zhe}'s not [i]that[/i] tempting."  I barely know ${zhim}, after all.
          You wave off the idea with some annoyance. 
          
          "I'm not saying it's the wrong idea, ${bfname}." Breden looks apologetic.
          *goto everywolf
        #"You think I should start closing our doors to helots who want to join?" I ask, a little testily.
          *label notatall
          "Not at all."  Breden shakes ${xhis} head.  
          *label everywolf
          "We'll need every wolf we can get.  But 
          *label watchout
          if you try to lead this rebellion in a way ${zhe} doesn't like…watch out."
          *goto namechange
  *goto namechange
*label namechange
*if lname_length < 4
  *goto anarchy_check
*page_break
*if (aristo and (lname_start = "de "))
  *set altname (lname_mid&"atou")
  *if simz_here
    ${simon}'s
  *if kal_here
    ${kalt}'s
  offhand comment about your House's name lingers in your mind.
  *if kal_here
    ("Lofty de Shayarin," indeed!)
  As a ${lname}, you were raised to be proud that every generation of your ancestors refused to adopt a more Karagond-sounding name.
  *if kal_here
    For all ${kalt}'s
    *if arrog > 0
      wretched
    irreverence, you think you heard an approving note in ${zhis} voice.
  *if simz_here
    It's no surprise that a noble with a similar heritage, like de Firiac, would approve.
  Most of the yeomanry will likely share that approval.
  
  At the same time, you're aware that out there in the wider world, others will judge your name rather differently.  In all four archonties, there are nobles whose ancestors chose more advantageous surnames—not just grand aristarchs like the Keriatou, but the petty gentry that provide most of the Ecclesiasts and top administrators for the Hegemony.  
  
  And just below them are a host of Diakons, Telones, and other clerks drawn from the mercantile classes; they may not have changed their names but share a nation-spanning, Koine-language culture with the majority of the gentry.  All of them will assume that you're their enemy twice over, not just hostile to the Thaumatarchy but disdainful of anyone assimilated to its cosmopolitan culture.
  
  Changing your name now, at the height of your uprising, would be a particularly striking gesture of openness to the Koine-speaking class that keeps the multi-national Hegemony running.
  *choice
    *if (natl >= 30) #What an unworthy thought.  I'd never change my name to some awful cod-Karagond nonsense like ${altname}.
      *goto anarchy_check
    #No.  I'd rather our rebellion set an example of no one having their family name held against them.
      *goto anarchy_check
    #Abandoning the ${lname} name would do far more to alienate the nobles in every nation who have steadfastly held to their ancestral names.
      *goto anarchy_check
    #I've no interest in winning over the Hegemony's administrative class, in any case.  Nor do I think I'd succeed if I tried.
      *goto anarchy_check
    #And yet… 
      It's hard to imagine what the future will look like with the Thaumatarchy toppled…but you have the nagging feeling that its cosmopolitan classes might be very useful in restoring order.  Especially if you had any aspirations to hold together a continent-spanning empire, rather than just restore Shayard's long-lost independence.
      *if lingo = "shayarin"
        
        Of course, if you didn't also change the band's common language from Shayarin to Koine, changing your name would be an incomprehensible gesture.  But if you did both together, it might startle a number of petty gentry and merchants into reconsidering your rebellion.
      *choice
        #I change my name to ${altname}.
          *set lname altname
          *label newatou
          *set cred_a +10
          *set cred_m +10
          *set cred_y -20
          *set morale -5
          You stand up at the next morning meal and beckon your followers to hear you.  "The seeds of our rebellion were sown in Shayard.  And as the ${orig_lname} name testifies, my own roots are deep in Shayardene soil.  But we must remain open to anyone who seeks a just Order.  Our enemy is the Thaumatarch: not Koine-speakers, nor those whose ancestors chose a Karagond name. 
          
          "Accordingly,
          *if lingo = "shayarin"
            I ask all of you who can to speak to each other in Koine.  And
            *set natl %-15
            *set lingo "koine"
          *set natl %-30
          I wish to be called ${kuria} ${fname} ${lname} henceforth.  Let my name not be a barrier to anyone who might seek to join us—whatever their nation, their language, or their family's history."
          
          Most of your followers murmur uneasily at this, even the ${whend}s, and
          *if kal_here 
            ${kalt} wrinkles ${zhis} nose as if catching scent of a corpse.  For his part,
          *if simz_here and (s_rel < 9)
            ${simon} seems torn between finding it admirable and unseemly.  For his part,
          your father looks apoplectic.  He catches you later, just before camp-breaking.  "What…what shame and madness…what crime against your House…"
          
          You cut in forcefully, before he hits on any of the harsh words that have been gnawing at your own mind. "Calm yourself, Father.  Our ${orig_lname} ancestors chose to stand up to the Thaumatarchy in a small way.  It's no crime to trade the small for the great."
          
          At vast effort, he brings himself under control.  "When other Houses sold their names for the Karagonds' favor, we remained true. If there were one area where I'd never have expected you to dishonor us…"
          
          "Other Houses were following strategies of personal advantage, or perhaps survival.  Mine aims at far greater honor."
          *page_break
          A strained, mocking bark bursts from his throat.
          *goto fatherchat
        #I adopt a different Karagond-sounding name.
          Henceforth, you and any heirs you may
          *if female and malepref
            bear or 
          *if male and femalepref
            sire or
          adopt into the House will be known as:
          *if choice_randomtest
            *set lname "Metanatou"
            Metanatou.
            *page_break
            *goto newatou
          *label nameatouchoice
          *input_text lname
          *set lname_length length(lname)
          *set lname_last lname#lname_length
          *if lname_length > 1
            *set lname_lastz lname#(lname_length-1)
          *if lname_length >= 3
            *set lname_lasty lname#(lname_length-2)
          *if lname_length >= 4
            *set lname_lastx lname#(lname_length-3)
          *set lname_end ((lname_lastx&lname_lasty)&(lname_lastz&lname_last))
          *if lname_end != "atou"
            Not much point in changing your name to something that doesn't end in "-atou."  Nothing else would win over the folk you hope to sway.
            
            You consider changing it to:
            *goto nameatouchoice
          *set lname "$!{lname}"
          "${fname} ${lname}."  You say the name cautiously to yourself…feeling giddy at yet another area of unexpected freedom.
          *choice
            #Yes, ${lname} is the name I want to adopt.
              *goto newatou
            #Not quite right.  I'll choose something different.
              You consider changing it to:
              *goto nameatouchoice
            #No, it sounds all wrong.  I'll stick with ${orig_lname} after all.
              *set lname orig_lname
              *goto anarchy_check
        #No, it simply wouldn't be right.
          *goto anarchy_check         
*if lname_length < 5
  *goto anarchy_check
*if (aristo and (lname_end = "atou"))
  *set lname_length -4
  *label nameset
  *set i +1
  *if i < lname_length
    *set altname &"${lname#i}"
    *goto nameset
  *if i = lname_length
    *set altname &"${lname#i}"
    *if (((lname#i) = "n") or ((lname#i) = "m")) or (((lname#i) = "r") or ((lname#i) = "l"))
      *set altname &"${lname#i}"
    *set altname &"e"
  *set altname ("de "&altname)
  *if simz_here
    ${simon}'s
  *if kal_here
    ${kalt}'s
  offhand comment about your House's name lingers in your mind.  It would have been centuries ago, during or after the Conquest, that the ${lname} abandoned their ancestral Shayarin name.  No one in your family remembers what it might have been.  $!{altname}, possibly?
  
  In any case, you've been reminded that others across Shayard will be judging you for the Karagond tenor of ${lname}.  You might gain some credibility—with your Shayardene followers, anyway—by revoking your ancestors' change and adopting a less foreign-sounding name.
  *choice
    #$!{oath}…I'm not going to change the name my House has held for three hundred years!
      The thought no sooner enters your mind than you reject it.  You are ${fname} ${lname}.  Anyone who would judge you for your ancestors' deeds rather than your own deserves nothing but disdain.
      
      *goto anarchy_check
    #I'm not changing it.  When my rebellion extends beyond Shayard, ${lname} will sound less "foreign" than ${altname}.
      Noble Houses across the Hegemony have adopted the Karagond "-atou" in their names—and many would no doubt take your change of name as a personal slight.  Best to keep the name you were born with.
      
      *goto anarchy_check
    #I change my name to ${altname}.
      *set lname altname
      *label newname
      *set natl %+20
      You make the announcement at the next morning meal.  "The names the Hegemony has given us may be a petty thing to rebel against…but I no longer wish to be called by the remnants of 
      *if lname = altname
        a good
      *if lname != altname
        some long-forgotten 
      Shayarin name chopped and stretched on a Karagond rack.  Let it be known henceforth: I am ${fname} ${lname}."
      
      While most of your followers
      *if simz_here and (s_rel < 9)
        join ${simon} de Firiac in a resounding
      cheer—the ${whend}s no less than the Shayardenes—your father looks apoplectic.  He catches you later, just before camp-breaking.  "What…what shame and madness…what crime against your House…"
      
      "Calm yourself, Father.  The House didn't die when our ancestors chose to call themselves ${orig_lname}."
      
      At vast effort, he brings himself under control.  "Nor did they change it on some honorless whim!"
      
      "We don't know why they chose a Karagond name, Father.  I'd not lightly call them dishonorable."  You fold your arms and try to keep your own voice level.  "Perhaps it was a necessity at the time.  But my own strategy aims at a far greater honor than bare survival—one which I believe our ancestors would be proud to see."
      *page_break
      His bitter scowl twists up at one corner.
      *goto fatherchat
    #I change my name to de Uttrim—for the Outer Rim where I grew up.
      It's a Rim-sounding name, like Breden or Yebben…older even than the conquest of the Rim and Westriding by the Shayardene queens and kings of old.  
      
      *set lname "de Uttrim"
      *goto newname
    #I want to adopt a different Shayarin-sounding House name.
      *label namechangechoice
      Henceforth, you and any heirs you may
      *if female and malepref
        bear or 
      *if male and femalepref
        sire or
      adopt into the House will be known as 
      *if choice_randomtest
        *set lname "de Change"
        de Change.
        *page_break
        *goto newname
      "de ______."
      *input_text lname
      *set lname "$!{lname}"
      *set lname ("de "&lname)
      "${fname} ${lname}."  You say the name cautiously to yourself…feeling giddy at yet another area of unexpected freedom.
      *choice
        #Yes, ${lname} is the name I want to adopt.
          *goto newname
        #Not quite right.  I'll choose something different.
          *goto namechangechoice
        #No, it sounds all wrong.  I'll stick with ${orig_lname} after all.
          *set lname orig_lname
          *goto anarchy_check
*label anarchy_check
Throughout the winter and spring, your father remains resolutely unimpressed by your leadership.  You hadn't expected anything else, but it grates on you that he can't seem to acknowledge the least achievement on your part.  One evening, when you mention that you've been discussing the band's strategy with ${deputy}, he snorts with contempt—and you round on him. "What's so funny, father?"

He blinks at you warily but without surprise; he's accustomed to your outbursts by now, and was probably hoping to provoke you.  
*label fatherchat
"You have a 'strategy,' ${fname}?  
*if aristo
  Doesn't that overstate things just a bit?"
*if helot
  Sounds a fancy name for 'making it up as we go.'"

"You think we've survived this far by accident?"

Your father 
*if orig_lname = lname
  shakes his head.  
*if orig_lname != lname
  gives a wild laugh.  
"From the sounds of it,
*if anarchy < 10
  you've created hardly any anarchy down in the lowlands.  They barely feel your rebellion.  That's part of your strategy?"

  You rub your forehead wearily.  "Father…we aren't just trying to tear everything down.  We want to leave a land that can still be governed after the Thaumatarch falls, and people who don't hate us as Xaos-lovers."
  
  "You can't do anything whole-heartedly, can you?" your father demands.  "All this means, you young fool, is that when they send the Theurges and Alastors after us, they'll be able to send all of them—none of them will be distracted by putting out fires in the lowlands."
  
  You wonder how many other outlaws are thinking the same thing.  "Then 
*if (anarchy > 9) and (anarchy < 31)
  you've created enough anarchy down in the lowlands to annoy everyone but not enough to hurt anyone.  That's a strategy?"

  You rub your forehead wearily.  "Father…we aren't just trying to tear everything down.  We're trying to find a balance—create enough anarchy to break the Hegemony's hold, but not so much that we turn Shayard into another of the Xaos-lands."

  "You can't do anything whole-heartedly, can you?" he demands.  "All this means, you young fool, is that when they send the Theurges and Alastors after us, they'll be able to send a horde—hardly any will have to be putting out fires in the lowlands."

  You wonder how many other outlaws are thinking the same thing.  "Then 
*if anarchy > 30
  you've thrown all the areas that border the Whendward Hills into anarchy.  That was a strategy?  To me, it looks like you only know how to break things."

  You rub your forehead wearily.  "The more anarchy there is, Father, the more troops the Hegemony will have to use to put out fires in the lowlands—and the fewer troops they'll have to send against us.  So yes, we mean to set all of Shayard ablaze."

  "But what's going to be left when you're done?" he demands.  "Will there be a Shayard worth having?  How much damage are you going to do before they finally pour Theurges and Alastors into these hills and crush us?"

  You wonder how many other outlaws are thinking the same thing.  "If they do manage to find us, 
we'll throw them back, Father."

"No, ${fname}.  No, you won't."  Your father shakes his head fervidly.  
*if orig_lname != lname
  "Just as you've killed the ${orig_lname} name, you'll kill me—the last of the true name.  And yourself,
*if orig_lname = lname
  "You'll die, and I with you,
and all these hapless fools who believed in you."
*finish

*label hurtmorale
*if morale < followers
  something, and it's hurting morale.
*if morale >= followers
  something.
*return
  
*label d2n
*set display_numb ""
*set thousands 0
*set hundreds 0
*set tens 0
*set single 0
*if d2n_num = 0
    *set display_numb "zero"
    *goto finish_d2n
*if d2n_num < 0
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if d2n_num > 999
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if (d2n_num modulo 1) > 0
    *set display_numb "${d2n_num}"
    *goto finish_d2n
*if d2n_num < 10
    *set single d2n_num
    *goto single_digit
*label thousands_digit_addition_repeat
*comment leaving this here in case we want to switch the thousands back on
*if d2n_num > 999
    *set d2n_num -1000
    *set thousands +1
    *goto thousands_digit_addition_repeat
*label hundreds_digit_addition_repeat
*if d2n_num > 99
    *set d2n_num -100
    *set hundreds +1
    *goto hundreds_digit_addition_repeat
*if (d2n_num > 9) and (d2n_num < 20)
    *goto skip_tens_and_singles
*label tens_digit_addition_repeat
*if d2n_num > 9
    *set d2n_num - 10
    *set tens + 1
    *goto tens_digit_addition_repeat
*set single d2n_num
*label skip_tens_and_singles
*if thousands = 1
    *set display_numb "one thousand"
*if thousands = 2
    *set display_numb "two thousand"
*if thousands = 3
    *set display_numb "three thousand"
*if thousands = 4
    *set display_numb "four thousand"
*if thousands = 5
    *set display_numb "five thousand"
*if thousands = 6
    *set display_numb "six thousand"
*if thousands = 7
    *set display_numb "seven thousand"
*if thousands = 8
    *set display_numb "eight thousand"
*if thousands = 9
    *set display_numb "nine thousand"
*if ((thousands > 0) and ((tens > 0) or (single > 0))) and ((hundreds < 1) and (d2n_num < 10))
    *set display_numb &" and"
    *goto tens_digit
*if ((thousands > 0) and (d2n_num > 9)) and (((hundreds < 1) and (tens < 1)) and (single < 1))
    *set display_numb &" and"
    *goto tens_digit
*if ((thousands > 0) and ((tens > 1) and (single > 0))) and (hundreds < 1)
    *set display_numb &" and"
    *goto tens_digit
*if (thousands > 0) and ((hundreds > 0) and ((tens > 0) or ((single > 0) or (d2n_num > 9))))
    *set display_numb &","
*if (thousands > 0) 
  *set display_numb &" "
*if hundreds = 1
    *set display_numb &"one hundred"
*if hundreds = 2
    *set display_numb &"two hundred"
*if hundreds = 3
    *set display_numb &"three hundred"
*if hundreds = 4
    *set display_numb &"four hundred"
*if hundreds = 5
    *set display_numb &"five hundred"
*if hundreds = 6
    *set display_numb &"six hundred"
*if hundreds = 7
    *set display_numb &"seven hundred"
*if hundreds = 8
    *set display_numb &"eight hundred"
*if hundreds = 9
    *set display_numb &"nine hundred"
*if ((hundreds > 0) and (tens < 1)) and ((single > 0) or (d2n_num > 9))
    *set display_numb &" and"
*label tens_digit
*if (hundreds > 0) 
  *set display_numb &" "    
*label teens
*if d2n_num = 10
    *set display_numb &"ten"
    *goto finish_d2n
*if d2n_num = 11
    *set display_numb &"eleven"
    *goto finish_d2n
*if d2n_num = 12
    *set display_numb &"twelve"
    *goto finish_d2n
*if d2n_num = 13
    *set display_numb &"thirteen"
    *goto finish_d2n
*if d2n_num = 14
    *set display_numb &"fourteen"
    *goto finish_d2n
*if d2n_num = 15
    *set display_numb &"fifteen"
    *goto finish_d2n
*if d2n_num = 16
    *set display_numb &"sixteen"
    *goto finish_d2n
*if d2n_num = 17
    *set display_numb &"seventeen"
    *goto finish_d2n
*if d2n_num = 18
    *set display_numb &"eighteen"
    *goto finish_d2n
*if d2n_num = 19
    *set display_numb &"nineteen"
    *goto finish_d2n
*if tens = 1
    *bug Should not be reachable
*if tens = 2
    *set display_numb &"twenty"
*if tens = 3
    *set display_numb &"thirty"
*if tens = 4
    *set display_numb &"forty"
*if tens = 5
    *set display_numb &"fifty"
*if tens = 6
    *set display_numb &"sixty"
*if tens = 7
    *set display_numb &"seventy"
*if tens = 8
    *set display_numb &"eighty"
*if tens = 9
    *set display_numb &"ninety"
*if (single > 0) and (tens > 0)
    *set display_numb &"-"
*label single_digit
*if single = 1
    *set display_numb &"one"
*if single = 2
    *set display_numb &"two"
*if single = 3
    *set display_numb &"three"
*if single = 4
    *set display_numb &"four"
*if single = 5
    *set display_numb &"five"
*if single = 6
    *set display_numb &"six"
*if single = 7
    *set display_numb &"seven"
*if single = 8
    *set display_numb &"eight"
*if single = 9
    *set display_numb &"nine"
*label finish_d2n
*if not(np)
    ${display_numb}
*set np false
*return
