*set you "you"
*set your "your"
You awaken with a jolt. It takes a moment for it to sink in: you are yourself; you are safe; you are whole. You managed to confront Wolf and wake away without becoming his meal.

You struggle to stand. 
*if meeting_sen
	Sen is there to offer you his hand. He pulls you onto your feet and pats you on the shoulder.
	*if wolf_fight_combat
		"We did it. I can barely believe it."
	*comment endif
*if meeting_lyall
	"Welcome back," Lyall says, and helps you climb to your feet. 
*comment endif

Tumelo's meeting house is still the same as it was before you were abruptly thrown into Wolf's dream, but it feels different. Perhaps you are different.

*if (((meeting_ara) or (meeting_sen)) or meeting_lyall)
	You quickly explain, as much as you can anyway, what transpired in the Wolf dream. 

*if meeting_ara
	"There are not many who encounter Wolf on his terms and leave with their bodies and minds intact. You are in rarefied company, my friend," ${ara_name} says, managing to sound only moderately disdainful. 
*comment endif

*if meeting_lyall
	You half expect Lyall to be apoplectic, after all you just confronted and refused to relent to your god, ${lyall_his} god. However, ${lyall_he} has a more nuanced view: "I was not called, ${prenom}. For all my faith and ferocity, Wolf did not choose me to inhabit. If he had, I cannot say for certain what I would or would not have done. I do know that if Wolf could not defeat you, then by every law we follow he did not deserve to take your consciousness for his own."

	Lyall puts a hand on your shoulder. 

	"You survived, ${prenom}. You survived. That is enough for now," ${lyall_he} says. 
*comment endif

As details of your conflict with Wolf cross your mind, it occurs to you that you are free, or at least as free as any living being could claim to be. 

*if meeting_lyall
	"This place symbolizes nothing good. We should leave," Lyall says, while looking around the large space and shivering. 
	*goto leaving_siltstone
*elseif meeting_sen
	"If it is all the same to you, ${prenom}. I think it is past time we left this place," Sen says suddenly. "It has the reek of misspent power about it, and such things tend to draw conflict as surely as anything."
	*goto leaving_siltstone
*elseif (meeting_ara and ((meeting_sen = false) and (meeting_lyall = false)))
	"Should we leave, ${prenom}? Before the fell spirits come to eat up whatever remains of your former patron god?" ${ara_name} asks. 

	You could take umbrage with ${ara_his} tone, but ${ara_he} is not wrong. Incorporeal beings flock to places of great spiritual disturbance, and you can think of few more disturbed places that the funeral ground of a powerful god. 
	*goto leaving_siltstone
*else
	You are compelled to leave the meeting house where so much occurred to change your world, to begin to put Wolf's destruction behind you.  
	*goto leaving_siltstone

*label leaving_siltstone

You walk out into the sunlight of Siltstone
*if meeting_sen
	and Sen calls after you. 

	"${prenom}. We have done a great deal already for the Rising Sun cause by allying in the first place, but I fear I must ask you yet another favor. I would have your word that the growing coalition of the Rising Sun is safe from…well, safe from you. I have placed my faith in you, ${prenom}, but the people who trust in me need some reassurance that this is not a one-off. That this thing we have done is a symbol of how things can be in the future."

	Sen's youthful face is set in a grimace. 

	"I am asking you to promise me that there will be no retribution against us from you and whatever Wolf worshipers remain."

	*choice
		#I can promise you that. Unequivocally. 
			*set riser_safe_stub true
			*set action %+20
			*set deliberation %-20
			Sen tries not to let his relief show, but it is plain on his face. 

			"This means everything to me and my people. Thank you, ${prenom}," Sen says. He grins and without the burden of leadership for a moment, he looks considerably younger. But before long he arms himself again with an air of chilly formality. "I should see after my people. This detour has taken us far from where we expected to be. But should you ever have need of our aid, my aid, send word to anyone of mine and they will get me the message."

			Sen pulls you into an embrace before you can refuse or demure. Afterward he turns and leaves to find his soldiers and start their journey. 

			*page_break
			*goto picking_your_ending
		#I will make no such promises.
			*set riser_affinity %-50
			*set deliberation %+25
			*set action %-25
			*set riser_hunted_stub true
			Sen's face grows distant as soon as you speak. He shakes his head. 

			*goto sen_threat
		#I will not come after the Rising Sun, if I am left alone. However, I cannot speak for the others. They follow their own paths.
			*if enclave_leader = "you"
				*set riser_affinity %-50
				*set equity %+25
				*set selfishness %-25
				*set riser_hunted_stub true
				Sen's expression hardly changes. "You are their leader, are you not? At least one contingent of them. Issue a decree, dammit! Call them off!"

				"They are not mine to command, especially now that Wolf is gone," you reply. 

				The Riser commander gives you a withering glare. 

				*label sen_threat
				"You are making a mistake, ${prenom}, and I promise you that it will cost many lives. But I can no more force you into rational behavior than I can command your people on your behalf. The Rising Sun will protect itself. You can be assured of that."

				Sen stalks away from you, and the smattering of Rising Sun soldiers you saw loitering around Siltstone join him. You very much doubt you have seen the last of the commander. You wonder if the next time you encounter him it will be on opposite ends of the battlefield.

				*page_break
				*goto picking_your_ending
			*else
				*set riser_affinity %-35
				*set riser_hunted_stub true
				"You must have some power over them, ${prenom}! You just met their god!"

				"They are not mine to command, Sen. I was never their leader," you reply.

				Sen gives you a pleading look. He searches your face for some sign that you will reconsider, but when it becomes clear that you will not or cannot, his expression hardens. 

				*goto sen_threat
*elseif meeting_lyall
	and Lyall calls out. 

	"${prenom}.
	*if enclave_leader = "lyall"
		I intend to lead the Wolf enclave on a campaign against the Rising Sun.
	*if ((enclave_leader = "you") or (enclave_leader = "both"))
		I do not know what you intend for the Wolf enclave, but I think we should strike against the Rising Sun. 
	*comment endif
	They will eventually receive word, even rumors, that Wolf is gone for good. They have shamans and ritualists, as well. The secret will not last. We need to show force now. If we band together with the other enclaves, if we rally the faithful, then we can demonstrate how powerful we still are. Will you support this?" 

	*choice
		*if (enclave_leader != "lyall") #No. I forbid it.
			*set lyall_affinity %-35
			*set equity %+25
			*set selfishness %-25
			Lyall looks taken aback. 

			"You forbid it?" Lyall asks acidly. 

			*label lyall_disappointed
			$!{lyall_he} recoils, pauses. "You will regret this, ${prenom}. Trust me on that. When the Rising Sun is burning homes and we are burying ours in ditches, you will recall when we had the chance to change our fate and chose the fool's path."

			Lyall does not spend another breath on you. $!{lyall_he} leaves Siltstone immediately, probably to seek out the Wolf enclave and give them the news: ${prenom} has failed us. 

			You do not think Lyall is right, that blood is the only option and outcome, but time will solve this disagreement. You can only hope that what you have chosen is the best option for the people who believe in you. 

			*page_break
			*goto picking_your_ending
		#It makes sense. We should strike them while we can.
			*set lyall_affinity %+20
			*set action %+20
			*set deliberation %-20
			*set riser_hunted_stub true 

			*goto lyall_pleased
		#No. We should wait and see how they react to the news.
			*set lyall_affinity %-25
			*set deliberation %+25
			*set action %-25
			*set riser_safe_stub true

			*goto lyall_disappointed
		#You hardly need my blessing. I imagine that the Wolf enclaves are already prepared to attack.
			*set lyall_affinity %+20
			*set equity %+10
			*set selfishness %-10
			*set action %+20
			*set deliberation %-20
			*set riser_hunted_stub true
			*label lyall_pleased
			Lyall grins like a child at your bloody gift. 

			"We will start immediately, ${prenom}. You have made the right choice and your word will go far in convincing our enclave, all the remaining enclaves, to fight."

			$!{lyall_he} leaves Siltstone immediately in order to spread the gospel of war. You know your choice will have consequences, but there is hope it will save at least as many lives as will be taken. It is some comfort.

			*page_break 
			*goto picking_your_ending 
		#Yes. And I will join the attacks myself. 
			*set enclave_joiner true
			*set lyall_affinity %+35
			*set action %+30
			*set deliberation %-30
			Lyall gives you a wicked smile. "I was hoping you would say that."

			*page_break
			*gosub_scene consumed_end hunting_risers

			*if lyall_romance != "refused"
				*gosub romancing_lyall

			*page_break
			*goto picking_your_ending_2
		#We should seek a peaceful resolution. 
			*if ((lyall_affinity >= 60) and ((enclave_leader != "lyall") or (sensitivity >= 35)))
				*set riser_curbed_stub true
				*set lyall_affinity %+15
				*set deliberation %+20
				*set action %-20
				*set equity %+15
				*set selfishness %-15
				*set quickthinking +5
				*check_achievements
				*if not(choice_achieved_givepeaceachance)
					*achieve givepeaceachance
				Lyall considers your words for a long time. You are nearly certain ${lyall_he} will refuse, fighting even the notion that there could be peace between the Rising Sun and the remaining Wolf enclaves. But when ${lyall_he} opens ${lyall_his} mouth, it is not incredulity and rancor that comes out. 

				"I have been fighting since I was a child, ${prenom}. It galls me to think there is another way. Imagine how much time was wasted on fighting, killing for every inch of respect, power, even the right to exist." Lyall's jaw tenses, but ${lyall_he} fights through the tension and releases it. "Maybe the next generation will not have to fight like I did. It worries me, because they will need to be strong if this peace you want fails. But if we do not try, we will know. I will try to convince the enclave to attempt this, but I cannot promise they will abide it."

				"A chance is all I ask for," you explain. 

				Lyall nods and walks away. You trust ${lyall_he} will do ${lyall_his} best to convince the enclave to seek a peaceful outcome with the Rising Sun. You hope that will be enough. 

				*page_break
				*goto picking_your_ending
			*else
				*set riser_hunted_stub true
				Lyall laughs thinking your statement a bleak joke. $!{lyall_he} does not laugh for long.

				"You mean to make peace with them? Wolf only just moments dead and you forget what you are, what we are? The others have the luxury of questioning and plotting and playing with their thumbs, but we are made of fire and steel, ${prenom}. We cannot relent. Not while they target our people."

				Lyall makes it clear there is no room for debate. $!{lyall_he} bids you farewell and promptly leaves Siltstone, presumably to return to the enclave and begin waging war on the Rising Sun. 

				*page_break
				*goto picking_your_ending
*else
	and find yourself dazzled by the light of the day.
	*goto picking_your_ending

*label picking_your_ending

The world is different now than it was at the beginning of your journey. You have helped to shape it and now the road before you is open, and Wolf is not snapping at your heels. So what will you do with this newfound possibility? 

*choice
	*if (van_return) #Return to Mara's Caravan and see if Ghazal is still awaiting me.
		*gosub_scene consumed_end romancing_ghazal

		*page_break
		*goto picking_your_ending_2
	#Stay in Siltstone until a more interesting adventure arises.
		Now that your concerns with Wolf have been resolved, you do not have anywhere to go immediately. You decide to stay in Siltstone for the time being. 

		You are offered employ by
		*if combat >= ritual
			Kasigo, a hard woman who runs the town's only drinking hall, which doubles as a venue for the sharing of information.

			You have to occasionally turn out a drunk or rough up someone with bad intentions, but the work is not strenuous and you pick up little things, like how to ferment a delicious honey wine or how best to keep wheat dry in a damp environment. 

			*if quickthinking >= 45
				Kasigo even tasks you with handling the money that comes into the Shanty after she realizes how quick you are with numbers and deems you trustworthy enough.
			*comment endif
		*if ritual > combat
			Adika, a permanently scruffy and temperamental shaman whose loyalty tips toward whichever god he has not fallen out of favor with recently.

			You are supposed to be his assistant, but your ritual knowledge is more impressive by far, so you become something like a partner in a short amount of time.

			*if sensitivity >= 45
				Adika comes to you whenever he has trouble interpreting his own dreams and eventually asks if you would like to be formally trained to become a shaman. You mull over the offer, but you do not know that professing faith in another god is in the cards for you just yet. 
			*comment endif 
		*comment endif

		*label generic_ending_stuff
		Life is pleasant, if a little boring at times, but you begin to notice that you can sleep through the night without worrying about vicious Wolf dreams, and your shoulders are not constantly tense from the threat of violence. 

		Still, you know when adventure comes and you are required to fight or think your way out of dangerous situations, you will be ready. 

		*goto picking_your_ending_2
	#Find the Wolf enclave and join them.
		*set enclave_joiner true
		The Wolf enclave welcomes you back without fanfare, which is almost disappointing considering how long it takes you to find them in the back country of Clearwater lands.

		"It took you long enough," Roan, usually quiet to a fault, says. "We heard you making your way through the trees since day broke. You should be more cautious."

		She points to a small roasted bird on a makeshift spit and offers it up. "Squab?"

		As easy as that, you are integrated into the enclave. The duties are judiciously split and
		*if ((enclave_leader = "you") or (enclave_leader = "both"))
			*if enclave_leader = "both"
				as one of their chosen leaders
			*if enclave_leader = "you"
				as their chosen leader 
			you are often given the first choice on the duties that sustain the enclave, but not always. Your relationship with the group is mutually respectful, but not over-zealous. 
			*goto enclave_end
		*else
			you are given tasks oriented toward your skill set, and you quickly realize how egalitarian the structure of the enclave is by design. 
			*goto enclave_end

		*label enclave_end

		*if riser_hunted_stub
			The enclave spends a great amount of time over the next few months planning and carrying out attacks on the Rising Sun. Sometimes you are directly involved and other times the effort is more individualized, but the pressure never relents.
		*if riser_safe_stub
			The enclave more or less avoids conflict with the Rising Sun, though occasional skirmishes cannot be entirely avoided between two such proud and martially minded groups. Luckily, you do not see much besides the occasional broken bone or busted lip.
		*if riser_curbed_stub
			The enclave is reluctant to fully agree to peace with the Rising Sun, but over time things get easier gradually. It begins with an exchange of goods, and a few months in, Fillin begins courting a Rising Sun soldier who is so fit, strong, and skilled with a blade that when they spar, they almost seem like brothers. 
		*comment endif
		*if (((riser_hunted_stub = false) and (riser_safe_stub = false)) and (riser_curbed_stub = false))
			Eventually the question of the Rising Sun comes up. The group naturally grows in power as Wolf's demise becomes common knowledge. 

			You are asked for your opinion on the matter one morning as you wander into an argument between Suba and Hemming. 

			"We should have already hunted them to extinction! Enough Equivocating!" Suba shouts, rubbing a hand over her bald head in frustration.
			*if enclave_purpose = "fight"
				"We already decided to fight. It should be a closed matter."

			*if wolves_harsh_fate
				"Zev died because we fought when talking might have helped," Hemming shouts back. 

				Suba's fists lock at the mention of their former ally's name.
			*comment endif

			Hemming sighs. "Suba. We cannot win. They are growing stronger and we are godless. What chance do we have?"

			"What chance do we need? If we die, we die. There is no shame in it."

			When Hemming sees you, he waves you over. "${prenom}! Please explain to Suba that fighting the Rising Sun is going to get us killed."

			Suba crosses her arms over her chest and rolls her eyes. "Yes, ${prenom}. Tell me how violently irrational I am."

			*choice
				#I think we should fight. Suba's right.
					*set riser_hunted_stub true
					*set action %+25
					*set deliberation %-25
					Suba claps excitedly and Hemming makes a disgusted noise.

					"See? Now here is a real wolf!" Suba exclaims. "Come, ${prenom}. Let us convince the rest of our less-bloodthirsty friends to wake up and fight."

					The muscled warrior puts her arm around your neck and leads you off to find the rest of the enclave.

					*goto fighting_wolves
				#Hemming makes sense. We should be careful. Talk to them, if they will listen.
					*set deliberation %+25
					*set action %+25
					"We should make peace with them if at all possible," you say, explaining your position. 

					Hemming looks surprised, but then loudly offers his agreement. Suba shakes her head. 

					*if (((influence >= 5) and (enclave_leader = "you")) or (enclave_leader = "both"))
						*set riser_curbed_stub true
						*set sensitivity +5
						*set equity %+20
						*set selfishness %-20
						*check_achievements
						*if not(choice_achieved_givepeaceachance)
							*achieve givepeaceachance
						"Fine. We will make peace, if we can, but when we fail." Suba grins. "We will do it my way."

						You soon find that the matter of peace with the Rising Sun if larger than just convincing Suba, or even the rest of the Wolf enclave. You are soon asked for your opinion by other groups: Eel shamans, caravan leaders, trading towns, even unaffiliated groups representing strange new gods. You counsel peace and cooperation each time, and you hope the message will spread. 

						*goto enclave_fate_4
					*else 
						*set riser_hunted_stub true
						"Are you even still wolves under all that timidness, I wonder," Suba says aloud.

						She walks away, leaving you and Hemming to your shared ideologies. 

						*label fighting_wolves
						In a few days it is announced that the Wolf enclave will begin coordinated attacks on the Riser camps.

						*goto enclave_fate_4
				#We should mind our business and stay out of theirs, unless they make problems for us.
					*set equity %+25
					*set selfishness %-25
					*set riser_hunted_stub true
					Neither party seems to be content with that answer and they keep arguing well into the night.

					*goto enclave_fate_4

		*label enclave_fate_4

		*if (((lyall_dies = false) and (lyall_romance != "refused")) and (lyall_fate != "banished"))
			*page_break
			*gosub romancing_lyall 

		*goto picking_your_ending_2
	#Roam the land. I am sure there is someone who could use my help.
		Once you leave Siltstone, you travel until you reach the ocean. You spend time in a village off the coast where people are being assaulted at night by a so-called monster. You find that this beast is no more than a overgrown lynx harassing the local populace. 
		*if deliberation >= action
			You manage to scare it off without killing it.
		*if action > deliberation
			You manage to trap it and the villager's hunters kill it and use its pelt as a trophy. 
		*comment endif

		You travel briefly alongside a caravan and are led to a boisterous old man named Papa Finch. He delights in telling elaborate, untruthful stories which always end with his aggrandizement, but he and his followers are pleasant enough company. You help them with a few chores and fighting off occasional bandits and they pay you in food and help you mend your threadbare clothes. 

		*goto generic_ending_stuff

*label picking_your_ending_2

*if riser_hunted_stub
	*gosub riser_hunted_stub

*if riser_safe_stub
	*gosub riser_safe_stub

*if riser_curbed_stub
	*gosub riser_curbed_stub

*if (meeting_lyall = false) or (enclave_joiner = false)
	*gosub enclave_fate
	*goto proper_ending
*if (((ara_affinity >= 65) and ((chaos_score >= 2) or (selfishness > equity))) and ((van_return = false) and (ara_dies = false)))
	*gosub romancing_ara

	*goto proper_ending
*elseif ara_dies = false
	*gosub ara_fate
	*goto proper_ending 
*else
	*goto proper_ending

*label proper_ending

There are rumors, gossip, about your role in the fall of Wolf and how you helped shape the world. And though more than half of those tales are untrue, they are fated to become the stuff of legends. They will tell how a ${tribe} ${man_woman} rose to challenge gods, but they will elide the difficulties and complications. The wonder of your tale will amaze and dazzle, while the details fall into obscurity. Even still, your legend grows. 

*gosub_scene consumed_end final_ending


*comment HERE ARE THE ENDING SUBROUTINES.
*comment The stubs are little vignettes that help wrap up various parts of the narrative.

*label riser_hunted_stub
You do not need to seek out news of the Rising Sun. You see their homesteads burning and their defensive structures toppling wherever you go. You find a crude representation of a wolf's head painted in places where the Risers have been struck. The divide between those faithful to the old pantheon is thrown into sharp relief as the attacks grow more severe. There are whispers of reprisals staged in the night, temples and villages razed. You begin to wonder if all-out war will follow, and if so, who will win.

*return 

*label riser_safe_stub 
The Rising Sun flourishes without the direct threat of attacks staged by the worshipers of the dead Wolf. Though the faithful of other gods might dislike the methods of the upstart group, they are unlikely to attack without direct provocation.
*if meeting_sen
	You even hear that Sen has stepped down from commanding the Rising Sun troops and has taken a leadership role within the coalition as it moves to legitimacy. 
*comment endif

There are rumors though that the Rising Sun is merely bidding time, growing stronger until they are prepared to dominate and subjugate those still loyal to the old faith and convert them at the edge of a sword. 

*return

*label riser_curbed_stub
It is a long road toward peace between the Rising Sun and the loyalists of the old faith. It is a journey marked by many first steps, like the village destroyed in a dispute between the Quiet and the Rising Sun, which the latter group then helped rebuild. Or a cease-fire negotiated between one of Hawk's holiest temples and the Risers who had been leading incursions against it. 

No one expects the hostilities will end immediately, but any progress in that direction is welcome by most. 

*return 

*label ara_fate
${ara_name}'s name comes up every so often in the weeks after Siltstone. You hear of a beautiful ${ara_gender} convincing a Rising Sun initiate to burn down one of Gazelle's temples; it is an act the young, confused soldier is executed for. ${ara_name} also seems to be at the heart of a plot to rally believers of the old gods and members of the Rising Sun alike to hunt down and kill members of a budding clan who worship gods of metal and are capable of amazing feats of engineering. But in your travels you do not encounter ${ara_him} directly. Perhaps ${ara_he} knows better than to cross your path again.

*return 

*label enclave_fate
The Wolf enclave seeks you out before long. They have survived after Wolf's destruction and found purpose
*if riser_hunted_stub
	hunting the Rising Sun. 
	*goto enclave_fate_2
*else	
	seeking a new way to live in the world without the guidance of their god. 
	*goto enclave_fate_2

*label enclave_fate_2
They are cordial toward you, but it becomes clear that in choosing not to return to the enclave, your relationship with them will not be as it was. Suba tells you not to lose the ferocity that made you Wolf's heir. Fillin gives you a knife made from the bones of a great hunting beast that he felled himself. Hemming whispers a blessing over you that he hopes will keep you fighting fit for years to come, while 
*if wolves_harsh_fate
	Roan give you a bloody stag.
	*goto enclave_fate_3
*else
	Zev and Roan give you a bloody stag.
	*goto enclave_fate_3
*label enclave_fate_3
*if ((lyall_fate != "dead") and (lyall_dies = false))
	Lyall comes later and promises only that ${lyall_he} will look after the enclave, come what may.
	*if lyall_fate = "banished"
		You stop short of ending Lyall's banishment, but ${lyall_he} seems to understand that and respect it.
	*comment endif
*comment endif

*return 

*label romancing_ara

You wake in the middle of a vicious rain storm one night to find ${ara_name} sitting beside you. $!{ara_he} is dressed in a wolf's pelt and little else. 

"Hello, ${prenom}. I thought it was time we had a conversation."

Thunder underscores ${ara_his} words dramatically. "You are no stranger to rabble-rousing and causing chaos. I appreciate that. I think it is time we joined forces, so to speak. There are still things in this world that threaten the supremacy of gods, more specifically, my supremacy. I do not want to be the biggest fish, ${prenom}, but no one is going to take away my pond."

${ara_name} comes closer and you can smell rose and sage on ${ara_his} skin, but also the iron tang of blood. "Join me, ${prenom}. Help me hunt my enemies and humble them. It will be glorious. And I am willing to offer you a considerable reward. Though maybe I can reward you even if you refuse."

${ara_name}'s suggestion is less than subtle. 

*choice
	#Join ${ara_name}'s scheme, and accept ${ara_his} carnal offer.
		*gosub ara_intimacy 

		"Now, shall we go shape the world in my image?" ${ara_name} asks. "Break some things?"

		*gosub ara_havoc

		*goto ara_romance_end
	#Refuse both.
		"I thought you would be more fun, ${prenom}. But I am not surprised exactly." ${ara_name} smiles smugly, as if ${ara_he} knew what the outcome of ${ara_his} offer would be before ${ara_he} asked. "Enjoy yourself, ${prenom}. As long as you can, enjoy yourself."

		*goto ara_leaves
	#Accept the offer, but refuse the scheme.
		"Ah, I see. Well then let us see if the wolf can be spun in the spider's web," ${ara_name} says, and sheds the wolf pelt. 

		*gosub ara_intimacy

		*label ara_leaves
		${ara_name} leaves as quietly as ${ara_he} came. You wonder if ${ara_he} will make ${ara_his} offer to someone else, someone who will accept and help Spider turn the world into her playground. But that is not your concern, at least not until they try to make you bow to their whims as well. 

		*goto ara_romance_end
	#Sign on for the fight, but not for the erotic proposal. 
		${ara_name} laughs when you tell ${ara_him} you want to join ${ara_him}, but not to sleep with ${ara_him}. 

		"You are a perfect surprise, ${prenom}. And I am very, very hard to surprise," ${ara_name} says. $!{ara_he} stands, and the wolf pelt draped over ${ara_his} shoulder slithers down ${ara_his} body, obscuring ${ara_his} body. 

		"We should get started, should we not?" ${ara_name} asks. 

		You agree. 
		*gosub ara_havoc

		*goto ara_romance_end

*label ara_romance_end 
*return

*label ara_havoc
You feel it is long past time you caused a little havoc. 

${ara_name} proves ${ara_him}self a cunning tactician and a brutal taskmaster. Together you put down revolts that would threaten Spider, spin long plots that benefit the manipulative goddess, and all the time ${ara_name} reveres your bloody instincts. 

Against all odds, as the belief in the other gods slowly fade, faith in Spider expands. The Spider goddess grows stronger and ${ara_name}, one of many of the goddess's avatars, rises in prestige. There are rumors about the goddess's pet wolf, but such gossip is usually rewarded by a long, painful death. 

You wonder what will happen if ${ara_name} ever begins to see you as a risk to ${ara_his} power, but that is a concern for some other time. The work you do is rewarding and you are feared. It is enough.

*return

*label ara_intimacy 
${ara_name}'s body is soft and pliable, but ${ara_he} is a brutal taskmaster. $!{ara_he} drives you on with pleasure and pain in equal measures, the carrot and the stick. 

You end the evening soaked in sweat and sore, while ${ara_name} just gives you a typically sardonic grin.

*return

*label romancing_lyall

Lyall approaches you at the cook fire, where Hemming is regaling a half-asleep Roan with a tale that so far as you can tell is about nothing.

"Old man, find somewhere else to be," Lyall says. 

Hemming grunts and snaps back, but it is all posture. Roan wakes long enough to see the expression on Lyall's face, then quickly finds someplace else to be. 

Lyall sits across the fire from you and stares. 

*if lyall_romance = "delayed"
	"We once sat at a fire like this and I offered you companionship. You delayed, demurred, and now we are here. Is now the time, I wonder. Or is there such a time at all?"
	*goto romance_cont
*elseif lyall_romance = "sleptwith"
	"I am fond of you, ${prenom}. You should know that by now that I do not—"
	*goto romance_cont
*else
	"I have never been good at this sort of thing, ${prenom}. I would like to be with you."
	*goto romance_cont

*label romance_cont

Lyall shifts. It is a nervous gesture and not one you would ever expect from the warrior.

"I want to be clear. I do not want to keep my warm bed. I want to fight…and live…beside you. Is that acceptable?"

Lyall frowns in your direction. $!{lyall_he} shuffles ${lyall_his} feet back and forth through the dirt. 

*choice
	#Refuse Lyall's offer. 
		"I understand, ${prenom}. I felt it necessary to ask in order to be true to myself and my feelings. I have always attempted to be transparent in that way."

		You attempt to explain yourself, but Lyall refuses. 

		"It does not matter why. I am not heartbroken, merely disappointed. No hunter likes be denied ${lyall_his} quarry."

		It takes a moment for you to realize it was a joke. By the time you do, Lyall is already walking away. 

		"Get some sleep, ${prenom}."

		*goto lyall_refusal
	#Accept Lyall's suggestion of greater intimacy.
		*check_achievements
		*if not(choice_achieved_twowolves)
			*achieve twowolves

		Lyall stares at you for a while, as if not quite daring to believe your answer. You have to get up and walk around the fire before ${lyall_he} snaps out of ${lyall_his} reverie. 

		"I did not really think you would agree to this," Lyall says frankly.

		You spend the night together and Lyall warms up to the idea soon enough. $!{lyall_he} shows you a tenderness and urgency that is unexpected. 

		The next morning, when ${lyall_he} awakes beside you, ${lyall_he} squints against the sunlight and laughs. The laugh is free of the bloody-minded determination that marks ${lyall_his} personality; it is warm and genuine. 

		"I thought you would be gone when I woke, like an Eel dream," ${lyall_he} says. 

		"I am still here," you reply.

		"That you are." 

		The next few days are an adjustment. Lyall comes to depend on you in small ways and you do the same. It is a true partnership that continues to offer small, strange delights for a long time to come. 

		*return
	*if (lyall_romance = "delayed") #Delay. Again.
		*label delayed
		Lyall smiles. "We are quickly running out of tomorrows, ${prenom}. I appreciate that you are trying to protect my feelings, but you need not bother. Get sleep, if you can."

		*label lyall_refusal
		You do get sleep eventually. The next day Lyall behaves as if ${lyall_his} suggestion never happened. It is probably the best path forward and ${lyall_he} is no more or less friendly toward you. 

		*return
	*if (lyall_romance != "delayed") #Delay
		*goto delayed
