*set you "Wolf"
*set your "Wolf's"
*set wolf_control true
*if equity >= 60
	*set wolf_humanity %+30
	*goto further_wolf_vars
*else
	*set wolf_humanity %-15
	*goto further_wolf_vars
*label further_wolf_vars
*if ((intention = "revenge") or (intention = "control"))
	*set wolf_humanity %-25
	*goto further_wolf_vars_2
*elseif intention = "peaceful"
	*set wolf_humanity %+20
	*goto further_wolf_vars_2
*else
	*goto further_wolf_vars_2
*label further_wolf_vars_2
*if ((influence >= 3) and ((action > deliberation) and (equity < selfishness)))
	*set wolf_humanity %-30
	*goto proper_start
*elseif ((influence >= 3) and (deliberation > selfishness))
	*set wolf_humanity %+30
	*goto proper_start
*else
	*set wolf_humanity %-10
	*goto proper_start

*label proper_start

${prenom} awakens with a jolt. The room around ${him}, within the depths of Tumelo's meeting house, is largely the same as it was before ${he} collapsed. But ${he} ${him}self
*if gender = "none"
	are
*if gender != "none" 
	is
different. 

*if meeting_lyall
	Lyall gives ${him} a strange look. "Are you all right, ${prenom}?" ${lyall_he} asks. "Can you stand?"

	${prenom} nods, then tests this hypothesis by putting weight on ${his} legs and standing. "I suppose so."

	"Good. It was embarrassing to see you sprawled out like you had just had your first sip of beer," Lyall says. It might be the closest ${lyall_he} has come to a joke.

	Lyall starts to say something else, but ${lyall_he} stops ${lyall_him}self. $!{lyall_he} narrows ${lyall_his} eyes at you. "Who are you?"

	*if meeting_ara
		${ara_name} makes an amused noise. "I was wondering how long it would take you to realize. Faster than expected, wolfling. I am almost impressed."
	*comment endif

	Not long after that, Lyall's eyes go wide as the realization comes to ${lyall_him}. $!{lyall_he} goes to one knee immediately. $!{lyall_he} says one word: "Wolf."
	*goto words_with_friends
*elseif ((meeting_ara) and (meeting_lyall = false))
	
	*goto words_with_friends
*elseif meeting_sen
	Sen gives ${prenom} a concerned look. 

	"You seemed fine one moment and then the next you collapsed. What—"

	Once ${prenom} gets to ${his} feet and starts to look around, Sen bristles like an animal scenting a predator on the breeze. He does not say whether it is a gesture or something else entirely that gives ${him} away, but it quickly becomes clear to the Rising Sun commander that ${prenom} is no longer what ${he} was. 

	Sen's hand goes to his weapon instinctively, smoothly. 

	"I would not bother," ${prenom} says, nodding to Sen's sword. "If I wanted you dead, I could have done it in an instant."

	*if meeting_ara
		"$!{he} is right, little soldier. I doubt you would last more than a few blows with our friend here," ${ara_name} adds.
	*comment endif

	Sen looks reluctant to relinquish his hold on his weapon. "You are Wolf now, are you not?"
	*goto words_with_friends
*else
	${prenom} looks around. $!{his} eyes are unfocused, wild. It takes some time before ${he} is able to open ${his} mouth and speak, and even then ${he} talks as if addressing some unseen other. 
	*goto words_with_friends

*label words_with_friends

"I can still feel ${him} inside me,"
*if (((meeting_ara = false) and (meeting_sen = false)) and (meeting_lyall = false))
	The Wolf god—who is slowly inhabiting ${prenom}'s—skin says quietly to ${him}self.
	*goto words_with_friends_2
*else
	The Wolf god—who is slowly inhabiting ${prenom}'s—skin says.
	*goto words_with_friends_2
*label words_with_friends_2
"Still struggling to assert ${him}self. It is useless, but I would expect nothing less. Regardless, ${his} body is mine now."

*if meeting_ara
	"What will you do with it, Brother Wolf? This brand new form of yours? Rain blood and judgment on your enemies, I assume," ${ara_name} says. $!{ara_his} tone is as coy as always, though limned now with uncharacteristic seriousness.

	"And you think I would tell you, Spider? No. Better to keep you in suspense, I think," Wolf answers. 

	${ara_name} grins and gives a deep, wholly insincere bow. "As you will, fiercest of the gods."
*comment endif

*if meeting_lyall
	Lyall shifts uncomfortably. Clearly there is no protocol among Wolf worshipers about meeting your god in the flesh.
	*if lyall_romance != "none"
		*set lyall_romance "none"
		It takes some time, but eventually ${lyall_he} works up the courage to address Wolf. "Great Wolf. Is…does ${prenom} hear us? $!{he} fought fiercely, I would have ${him} know the worth of such things. Even in death."

		Wolf turns to look at Lyall.

		"$!{he} knows your feelings, Lyall. If it helps you to know," Wolf says, then ${his} face hardens marginally. "But you are my subject first. It will not be between us as it was."

		Lyall, hardened to a fault, does not express the emotion that is plain on ${lyall_his} face. Instead, ${lyall_he} nods stiffly.
	*comment endif

	Lyall clears ${lyall_his} throat, and says, "Whatever you plan to do next, there are those who are still loyal to you. We walk with you until the last."
	*goto post_script
*elseif	meeting_sen
	"Commander Sen," Wolf says suddenly. 

	"Yes," Sen answers. His voice is calm, but anyone with ears could hear the steel underneath. 

	"Go and tell your brethren in the Rising Sun 
	*if riser_affinity >= 50
		that they have nothing to fear from me as long as they do not seek me out. You came in ${prenom}'s moment of need and helped to fight. You have earned the protection of your people," Wolf explains, then drops ${his} voice. "But I do not forget that you and yours are dangerous. So I will not have you by my side. I am a god now. Your sworn enemy. This alliance will not benefit either of us."
	*if riser_affinity < 50
		that Wolf is coming for them. They can prepare themselves—sharpen their blades and bolster their ranks—but I am coming, and nothing will stop me." 
	*comment endif

	Sen listens to this with his hand still on his blade, clearly considering Wolf's words carefully. His fingers loosen on the grip of his blade by degrees. He leaves the meeting house without another word. 
	*goto post_script
*else
	"I am Wolf," 
	*if gender != "none"
		${he} says
	*if gender = "none"
		${he} say
	to ${him}self. "I am Wolf."
	*goto post_script

*label post_script 

Eventually Wolf's posture straightens and 
*if gender != "none"
	${he} begins
*if gender = "none"
	${he} begin
to seem more comfortable in ${his} new form. 

"I think I can get used to this," 
*if gender = "none"
	${he} say, and make ${his} way
*if gender != "none"
	${he} says, and makes ${his} way
out of Tumelo's meeting house and into the bright sunshine of Siltstone. 

When 
*if gender != "none"
	${he} first feels
*if gender = "none"
	${he} first feel
the heat on ${his} skin, ${he} cannot help but smile, like a child first experiencing the world. "Oh yes, I think I am going to like this body a great deal."

*page_break
Later…
*comment Here the narrative splits according to who Wolf's largest remaining "threat" is.

Wolf takes the first steps into the town and no one takes particular notice, despite the fact that it is a small town that harbors the usual suspicion of travelers and strangers. $!{his} hair has grown out somewhat and the skin around ${his} eyes is drawn tight, otherwise, 
*if gender != "none"
	${he} is
*if gender = "none"
	${he} are
no more worse for the wear of the past few weeks traveling in this new body.

*if gender != "none"
	$!{he} looks around, and subtly sniffs
*if gender = "none"
	$!{he} look around, and subtly sniff
the area to track ${his} quarry. 
*if gender != "none"
	$!{he} finds who ${he} is
*if gender = "none"
	$!{he} find who ${he} are
looking for in a quiet corner of town, sitting under a shady tree. 

*if ((hawk_dies = false) and (bear_dies = false))
	The man and woman look up as ${he} approaches. 
	*if three_god_powerup
		They look more tired and frail, but that is to be expected since more than half of their power sits in ${his} belly.
	*comment endif

	"So, it comes to this," the man says. He is tall and thin. His braided hair is shot through with gray and decorated with five white feathers and one red. "You are reborn, Wolf. How does it feel?"

	The woman, densely muscled with a scarred face, whittles a piece of wood with a long, dangerous looking knife; she does not look up from her work. 

	"For a long time in the darkness, howling in anger, being invisible: I wanted you both dead, siblings. I could almost taste your blood in my mouth, even though I had no body with which to seek vengeance. Now, I have the perfect weapon. Did you think that new forms would throw me off your scents? You have grown pitiful in your attempts at evasion, and I have everything I need to destroy you."

	Hawk's new male-bodied avatar tenses. Bear's female avatar attempts to project calm, but her grip tightens around her knife. 

	*if wolf_humanity >= 60
		"But I have found that killing you is not my chief concern," Wolf says. 

		"What?" Hawk's avatar says. The incredulous look on his face suggests the goddess who directs him is far from prepared to accept Wolf's change of heart. "You think we will believe that you, Wolf—the devourer—intend to let us leave here alive. Without retribution."

		The way he says the word "retribution" hangs in the air. But Wolf, for ${his} part just shakes ${his} head.

		"Believe whatever you want, Hawk. I have ever been a creature of forward motion. This is consistent with who I have always been. I could kill you both and chew your bones until not even the salt remains, or we can leave the blood spilled behind us." Wolf bares ${his} white teeth at that. "Would you prefer that?"

		Hawk's avatar steps back and the Bear avatar stands. The self-possessed woman, with all the patience of Bear, puts a hand on her ally's shoulder and addresses Wolf. 

		"No. We will accept the peaceful resolution you offer, Wolf. The uncertainty of these times have changed us all. I have no doubt that even your wild heart can change."

		"Well," Wolf says, cracking ${his} knuckles. "I never said I had changed completely."

		The punch that Wolf throws in Bear avatar's direction is unexpected and lightning quick. It packs enough force to lay the large woman out flat on her back. 

		Hawk goes to Bear's side, fire in his eyes, but Bear lifts a hand. "I think I deserved that much at least."

		"That and more," Wolf growls, but relaxes ${his} fists. "But I have other matters yet to attend. Goodbye, Siblings. Until next time."

		*goto post_script_2
	*else
		The Bear avatar never gets a chance to use it. By the time she realizes that the attack is coming, Wolf has already driven ${his} elbow into Bear's nose and crushed it to a pulp. The knife slips out of her hand and Wolf is already moving on Hawk. 

		The goddess's avatar pulls the ever-present sword from the air at his side. He proves himself more than capable with the blade, cutting a bloody ribbon into Wolf's side before ${he} wrests the blade away.

		"You will never–"

		Wolf does not hear the end of Hawk's statement, because ${he} forcefully ends her avatar's life. 

		Bear however is still in control of his. The woman leaps in Wolf's direction and attempts to use her bulk to pin him, but Wolf incites the air around Bear to chaos, and suddenly tumultuous gusts of wind rock her and throw her off course. She crashes to the ground and Wolf jumps on top of her.

		"Do it," Bear's avatar spits. 

		Wolf does. 
		
		*goto post_script_2
*elseif (((hawk_dies = false) and (bear_dies = true)) or ((bear_dies = false) and (hawk_dies = true)))
	*comment Either Bear or Hawk dies, but one remains. I used the god_ally variable b/c that's the only case in which
	*comment one of those two gods would be dead and not both. 

	${god_ally} is waiting for ${him}. $!{god_his} new avatar is significantly younger than ${god_his} earlier form, but the avatar's eyes are old and keen. $!{god_he} looks up as Wolf approaches and puts down the long bone needles ${god_he} has been using to knit. 

	"I have been trying to learn more mortal tasks. Mundane things. It helps me to feel closer to them," ${god_ally} says, then adds pointedly, "our charges."

	"You told me you would stay away from this world," Wolf says. 

	"No. I made that deal with ${prenom}. I have yet to decide exactly what to do with you, Brother. Sacrifices were made to see this thing through. I want to ensure they were not made in vain," ${god_ally} replies.

	*if wolf_humanity >= 60
		"It would be satisfying to tear you limb from limb and leave what remains for the crows. However, swallowing ${prenom} has given me some perspective. It may not be in my best interest to destroy you," Wolf explains. 

		${god_ally} looks at Wolf as if ${he} has just told ${god_him} that the sun rises at midnight.

		"You and your traitorous sibling brought me low, but vengeance will not fill my belly. So as long as you stay out of my way, I have no reason to retaliate," Wolf continues. 

		"I had reservations that ${prenom} could change your mind on anything of substance, but it seems I was wrong," ${god_ally} says. 

		"Give me some credit,
		*if god_ally = "Hawk"
			Sister.
		*if god_ally = "Bear"
			Brother.
		I am not the bloodthirsty monster you would paint me as. Well, not always."

		${god_ally} scoffs. "I see. So what will you do now, Wolf, the Kind Hearted?"

		Wolf raises a finger in warning. "Do not push me. This is still a tentative peace between us."

		${god_ally} assents to that with a nod of ${god_his} head. 

		With the threat of violence passed, there is nothing left to say between the two gods. Wolf gives a begrudging nod to ${god_ally} and leaves. 

		*goto post_script_2
	*else
		Wolf snarls at ${god_ally}. "You should have stayed in your hiding hole. I might not have hunted you if I could not smell your stink in this world."

		${god_ally} stands. $!{god_he} squares ${god_his} shoulders and stares Wolf down. $!{god_his} incredibly young face feels discordant with ${god_his} martial stance. 
		*if god_ally = "Hawk"
			$!{god_he} flicks ${god_his} wrist and ${god_his} feather-hilted sword appears in ${god_his} hand.
		*comment endif

		"Shall we, Brother Wolf?" ${god_he} asks. 

		The gods circle each other for a few moments, then Wolf attacks. The two clash again and again, seemingly evenly matched for a time, but ultimately Wolf takes a superior position and forces ${god_ally} into defending ${god_him}self. 

		${god_ally} slips, a tiny mistake, and Wolf
		*if god_ally = "Hawk"
			knocks ${god_his} sword away. 
		*if god_ally = "Bear"
			knocks ${god_him} off his feet.
		*comment endif

		${god_ally} gives Wolf a glare. "Do not waste either of our time, Wolf."

		Wolf gives ${god_him} a stiff nod, a recognition of a battle well fought, and brings ${his} heel down hard on ${god_ally}'s throat. 

		*goto post_script_2
*else
	*comment Both Hawk and Bear are dead.
	*set ara_threat true
	*if ara_dies
		*set ara_name "Aranea"
		*if ara_gender = "man"
			*set ara_he "she"
			*set ara_his "her"
			*set ara_him "her"
			*set ara_gender "woman"
		Spider's new avatar wears a crimson gown that is completely impractical in the dusty streets of this farming town, but whether or not the woman is even visible to the people who live there is not immediately clear.

		"I know we have had our differences, ${prenom}, but do you mind not killing me before we have a chance to talk? I am running out of attractive avatars to inhabit. This one's name is ${ara_name}. I had her raised primarily for beauty and grace, but she can kill you violently at least a few dozen ways. So shall we try to keep this civil?"

		*label continuing_spider_convo

		*if meeting_ara = false
			"I am not ${prenom} any longer," Wolf explains.

			${ara_name} raises a manicured eyebrow. "I see. So ${prenom} lost then. Pity, I liked ${him} more than I like you."

			"Your preference is noted, Sister."
			*goto ara_convo_cont
		*else
			"So, Wolf, you have had some time to yourself. Time to experience the world and come to your own conclusions. So what shall it be? Fisticuffs or words?"

			"I think you know very well why I am here," Wolf says. 
			*goto ara_convo_cont

		*label ara_convo_cont

		Spider's avatar rolls ${ara_his} eyes toward the clear blue sky then downward again. "Hawk and Bear have been dealt with and I am now your most immediate concern: Gazelle is too wrapped up in her prophecies to act against you, and Eel is busy being mysterious, or whatever he does with his time. I am your biggest living competitor, for now anyway. 

		"So I suppose that makes this the part where I tell you that I am going to fall in line. But you would hardly believe that, would you?"

		*if wolf_humanity >= 60
			"I do not have to kill you. If you can be trusted, this once, to be less than completely treacherous," Wolf says.

			${ara_name} looks surprised, briefly. $!{ara_his} naturally bemused expression returns before long.

			"And what assurances do I have that you will not renege? I think you and I are beyond blind trust," ${ara_name} replies.
		*if wolf_humanity < 65
			"No. Likely not."
		*comment endif

		${ara_name}'s laugh is light and whimsical. $!{ara_he} stands. 

		"I was on the fence when Hawk and Bear sketched their plan. I did not believe that any one of us could be so dangerous as to warrant what they did to you, but I am no longer sure. Now that they have failed, and you have swallowed up your avatar, I do not know what remains to keep you in check. As loath as I am to dirty my hands, I suppose it must be me."

		*if ara_affinity >= 75
			"I think that ${prenom} deserves that much from our alliance, unconventional though it was," ${ara_name} adds.
		*comment endif

		${ara_name} moves to leave and Wolf goes to stop ${ara_him}, but the Spider avatar just smiles beatifically and points. Wolf's gaze follows and 
		*if gender != "none"
			${he} sees
		*if gender = "none"
			${he} see
		dozens of people armed with farming implements and other makeshift weapons pouring out of their houses and advancing. 

		"I will see you later, I am sure," ${ara_name} says, as ${ara_he} walks into the ever-growing crowd. 

		Wolf edges backward, gauging the mob and wondering if ${he} should fight or flee. $!{he} 
		*if gender != "none"
			cracks ${his} knuckles and makes
		*if gender = "none"
			crack ${his} knuckles and make
		${his} choice.
		*goto post_script_2
	*else
		${ara_name} looks as radiant as ever. $!{ara_he} is sitting on the ground with ${ara_his} back against the tall wooden fence surrounding the perimeter of the town. $!{ara_he} is cutting into an apple with a knife just a hair longer than ${ara_his} thumb. 

		"Welcome to—well, whatever the hell this town is called," ${ara_name} says. 
		*goto continuing_spider_convo

*label post_script_2
*page_break 
*if riser_affinity < 50
	*gosub hunting_risers

*if van_return
	*gosub romancing_ghazal

There are tales of where Wolf went and what ${he} did in the months and years after inhabiting ${prenom}'s form, but the best indication is in the 
*if wolf_humanity >= 60
	surprising lack of violence and death ${he} left in ${his} wake. 
*if wolf_humanity < 60
	broken bodies of ${his} enemies left scattered in ${his} wake.
*comment endif

Wolf's legend continues to grow, even if 
*if gender != "none"
	${he} is
*if gender = "none"
	${he} are
spoken of in whispers by enemies and allies alike. 

*gosub final_ending

*comment THE SUBROUTINES that tie up individual parts of the narrative.

*label final_ending
*page_break 
*text_image epilogue.png center Epilogue: Tide and Shore
*if ((pacifism) and (pacifism_broken = false))
	*check_achievements
	*if not(choice_achieved_pacifist)
		*achieve pacifist

[i]After the Wolf had brought the girl across the river safely, she bowed and thanked him. The Wolf accepted her reverence as fair payment, but could not help his curiosity. He asked, "Why did you show no fear, girl-child? Have you not heard tales of the terrible, hungry Wolf?"[/i]

[i]The girl smiled meekly, and said, "All the clans know that there are worse things than wolves. Especially in the dark of the water."[/i]
*line_break
-The ending to an old Clearwater fable.

*page_break

At the far edge of the world where the dark sea crashes against the shore, two children sit in the surf with the roiling water swirling around their toes. One of the children is small, his wet and incandescent hair is plastered across his face and his skin is black as oil and smooth. The other child seems older and self-assured, her brown hair is cropped short and her long legs reach further than her friend's into the chaotic waters. 

"The world did not end, Gazelle," says the short boy. He turns his gaze, as sly as any god, on his friend. "Your foresight is flawed."

Gazelle shrugs her slender shoulders.

"You are right, Eel," she says.

She continues watching the water come and go. Eel crosses his arms.

"Nothing else to say for yourself? Your prophecies came to nothing. You said that if Wolf died then the world would follow. But Wolf died
*if wolf_dead
	and we are still here."
	*goto final_ending_2
*else
	and returned, and we are still here."
	*goto final_ending_2

*label final_ending_2

Gazelle digs her toes into the sand and waits for the oncoming rush of water to fill the trench that her toes have made. The water comes and goes, and the sand is made smooth again before long. 

"We can die, Brother. We have only known fear for the well-being of our charges, but now there are those of us who fear an eternal quietude. Things will change now. The tide creeps up the shore."

The two gods are quiet for a while. 

"And that means the end of the world?" Eel asks.

"No. Not necessarily, but…" Gazelle says, gaze drifting along the horizon.

"But?"

"The weather is turning, Brother. We should go. Find shelter."

Eel sees it too. There are dark clouds gathering, and occasional lightning. The thunder announces itself soon after. Even as far away as the beach, the wind begins to pick up. 

"Yes," Eel says. "I think you are right. It is time to go."

*goto_scene ending 

*label hunting_risers
*if pacifism
	*set pacifism_broken true
Two men and three women wearing the sunburst standard on their beaten leathers stand around a half-guttered flame and attempt to warm their hands. Theirs is a fairly remote appointment, proof that the Rising Sun is working hard to extend its foothold into untamed lands.

"I would give my right arm for something other than these terrible preserves," one of the men complain. 

"That would be cheap compared to what it took to secure that terrible food you are eating. If it offends you, it might be good to give it to someone else," a woman responds, and puts out her hand in jest. 

The group laughs. It is the kind of laugh that expresses something besides humor, a necessary exhalation of discomfort and doubt. They have all heard the stories of entire Rising Sun outposts disappearing in the night.

One of the women says something crude and there is more laughter, but the laughing is cut short. Someone thinks they hear something. Howling. 

*if wolf_control
	Wolf does not waste time. 
	*if gender != "none"
		$!{he} is 
	*if gender = "none"
		$!{he} are
	among them before the first cry of alarm. $!{his} hands are a dervish and ${his} eyes seem rimmed with blood.
	*goto hunting_risers_2
*else
	You are among them before the first cry of alarm.
	*if ritual > combat
		The ground quakes and the Risers are unable to find their feet. You slide through their ranks like water while they founder.
		*goto hunting_risers_2
	*else
		You rush into their midst and proceed to cause as much havoc as you physically can. 
		*goto hunting_risers_2

*label hunting_risers_2
One of the men goes down and the woman closest to him tries to help, and loses a limb for her efforts. There are screams and shouts, but not for long.

*if enclave_purpose = "fight"
	Suba walks up from the bank of a nearby creek and stretches her lean body. "I caught two down by the water. I thought they would be more interesting, but they died disappointingly quickly."

	*if meeting_lyall
		Lyall and Fillin eventually come into view from far down a makeshift road. They are carrying supplies that are no doubt pilfered from Rising Sun soldiers. The blood splattered on their clothes says as much. 

		Fillin gestures to the packs they are hauling and shouts, "a worthwhile endeavor!"

		Lyall reminds Fillin to speak with some deference, but the thrill of the fight makes it hard even for Lyall to keep a grin from cracking at the corner of ${lyall_his} mouth.
	*comment endif

	*if wolf_control
		Wolf takes stock of the body count and nods. 

		"We have dealt them a blow, but we cannot stop now. Not until the Sun worshipers are broken and cowed," ${he} says. 

		"We identified another outpost to the south. Close enough that you smell their stink on the breeze," Suba says. 

		Wolf grunts assent. 

		"Why wait? We leave immediately," Wolf says. 

		The order filters through the group, and they begin to make their winding way south.
		*page_break
		*return
	*else
		As the last of the bodies fall, Hemming seeks you out. He looks older than he did the last time you saw him, and you wonder briefly if killing is truly in his nature. Perhaps he fell under the sway of the wrong god all those years ago. 

		"There is another outpost out west. It is close enough that we could be there within a day or two." He pauses. "Unless there is something else you think we could be doing…"

		You give him a look and put a hand on his shoulder. 

		"What we are doing is worthwhile," you explain. 

		"Ah. I have no doubt. We are watering the world in blood and something has to grow in it, right?" Hemming says ruefully, then walks away. 

		You turn to the west and to work still ahead of you. 
		*page_break
		*return
*elseif ((meeting_lyall) and (enclave_purpose != "fight"))
	Lyall comes in fast and hard beside
	*if wolf_control
		Wolf.
	*if not(wolf_control)
		you. 
	$!{lyall_he} is all fists, and claws, and teeth. $!{lyall_he} fights as viciously as any beast of the wilds. 

	Before long, the main force of the soldiers are quieted and Lyall hunts the few who escape, trying to flee into the riverbank. When ${lyall_he} returns, it is clear from ${lyall_his} hands that ${lyall_he} has washed some blood from them into the river, but not all. 

	"There is another outpost. It is not far," Lyall suggests. $!{lyall_he} points west. It has been this way for weeks. Hunting for retribution, for catharsis.

	*if wolf_control 
		"Then lead the way," Wolf says. 

		Lyall produces a smile, or some approximation of one, and sets off to the west with Wolf walking at ${lyall_his} side.
	*if not(wolf_control)
		You turn in the direction that Lyall indicates. You have lost count of the lives you have taken, and though you have inflicted great harm to the Rising Sun, it is far from defeated. 

		More bloodshed, then. 

		"Let us see what the next group is made of," you say. 

		You and Lyall collect supplies from the dead Risers before continuing on: It is unlikely they will need them any time soon. 

	*page_break
	*return
*else
	It is exhausting work, but not so exhausting that purpose is lost to bloodthirstiness. 

	*if wolf_control
		Wolf is reckless and joyous, moving through the soldiers like a force of nature.

		When they are all dead, Wolf scratches ${his} head. "Disappointing. I expected more of a challenge this time."

		*if gender != "none"
			$!{he} collects whatever supplies ${he} needs
		*if gender = "none"
			$!{he} collect whatever supplies ${he} need
		before continuing on. There is another outpost only just a few days away. $!{he} can take their supplies if ${he} needs to. They will not need them once they are dead. 
		*page_break
		*return
	*else
		You are methodical and careful, knowing that despite your prowess, a group of skilled fighters could take you down. You do not give them the chance.

		When the soldiers are all still, you go through their supplies and take only what you need to sustain you until you reach the next outpost. You have no doubt you will be able to find more supplies when you take them unawares and kill them. 

		You know there has to be an end to the killing, but you cannot see it from where you are standing, looking out west at the direction you need to travel. 

		"Eventually," you say to yourself, and then beginning walking.
		
		*page_break
		*return
		
*label romancing_ghazal
It is much later when ${you} arrive at Mara's Caravan.

*if riser_affinity <= 50
	*comment acknowledges if you/Wolf have gone on a murderous rampage
	${you} tried to wash the dried blood of Rising Sun soldiers from beneath ${your} fingernails, even knowing such efforts will not likely disguise the truth from a seer equipped with Gazelle's far sight. 

	Sure enough, Ghazal holds ${ghazal_him}self back, regards ${you} from a distance.

	"You are bloodier than when you left us," ${ghazal_he} says.

	"Sometimes blood needs to be spilled," ${you} reply. 

	"Does it?" Ghazal replies. $!{ghazal_he} seems to think differently, but lets the subject drop.

	Ghazal steps aside and allows ${you} into ${ghazal_his} tent. 
	*goto ghazal_romance
*else
	*goto ghazal_romance 

*label ghazal_romance 

Over the next few days, Ghazal and the people of Mara's 'Van begin to show ${you} a life beyond warfare: the most skilled cooks of the caravan patiently go over how to pack and roast oats into a misshapen, but delicious cake.
*if wolf_control = false
	You passively learn
*if wolf_control
	Wolf passively learns
the games and rhymes of the children by watching them run around the grounds of the caravan, and
*if wolf_control
	*if gender = "none"
		${he} teach
	*if gender != "none"
		${he} teaches
*if wolf_control = false
	You teach
*if ritual > survival
	the elders a set of rituals that might help calm the vicious storms that sometimes tear through the area late in the autumn.
	*goto ghazal_romance_2
*else
	the foragers of the caravan about fruits and vegetables that grow far from the steppes, but can be safely traded for with outsiders.
	*goto ghazal_romance_2

*label ghazal_romance_2

One day Ghazal takes ${you} aside, and says, "This could be your life. It is simple and slow, and yes, you know that it is sometimes violent, but your hands
*if ((pacifism) and (pacifism_broken = false))
	can stay clean."
	*goto ghazal_romance_3
*else
	can be cleaner than they are."
	*goto ghazal_romance_3	

*label ghazal_romance_3

*if wolf_control = false
	You could stay in Mara's Caravan and live alongside the seer and ${ghazal_his} people. Or does the world beyond the steppe still call to you?

	*choice
		#"Yes, I will stay."
			*check_achievements
			*if not(choice_achieved_settlingdown)
				*achieve settlingdown
			You can scarcely imagine a life among these nomadic people, but that is a part of the excitement of it. 

			"Yes," you tell Ghazal. "I will stay."

			You barely know what that means at the time, but the in next few weeks, months, and years, you learn. The elders teach you their songs, which greet the sun
			*if tribe = "Highwalk"
				which you nearly remember from your youth.
			*if tribe != "Highwalk"
				which begin as harsh and strange to you and sound clumsy on your tongue, but become a part of the tapestry your ears expect upon waking.
			*comment endif

			You are eventually asked to become the second of the primary surveyor. Rasul takes you under his wing and teaches you how to direct the Caravan in ways direct and indirect. By the time he becomes sick and can no longer lead, Rasul is more than confident that you will take care of the Mara's Caravan, its people, and its seer. 

			Every once in a while you leave the Caravan to trade, or hunt, or simply to enjoy the vastness of the steppe and you encounter a gazelle incongruous to the rest of the landscape, standing in the tall grass. The animal never approaches and neither do you. It just watches, but for some reason that puts you a little more at peace.

			*if (((selfishness >= 50) and (ara_affinity >= 70)) and (ara_dies = false))
				*page_break
				One day, late in summer, you are returning from a successful negotiation with another Highwalk caravan. A potential conflict averted, you feel proud of your accomplishment. 

				"${prenom}!" someone calls from a distance. 

				You turn to see an unfamiliar face. It is not until ${ara_he} walks closer, just a few paces away from you, that you recognize the compound irises which disappear almost as soon as you notice them. 

				"${ara_name}."

				$!{ara_he} bows. "In the flesh."

				Spider has enlisted a new avatar it seems. $!{ara_he} looks similar to last: sly smile, slender frame. But this avatar has shorter hair, a blunt cut that emphasizes the amber-colored eyes underneath. 

				"I never took you for the pastoral type, ${prenom}. This is not where I thought you would land."

				"Oh? And where did you think I would end up?" you ask. 

				"At my side." ${ara_name} says frankly. "And it is not too late. Any idiot can breed chicken, but you are different. Exceptional. You know that your destiny is bigger than this place, ${prenom}. Why waste it? Come with me. Be with me. If nothing else, it will be an adventure."

				You look over your shoulder and you can see the cook fires of Mara's 'Van burning. You can almost smell them. But ${ara_name} is standing in front of you, all casual sensuality and danger. Can you really turn ${ara_him} down?

				*choice
					#Yes. I have a responsibility to the caravan.
						*label ara_rejection
						${ara_name} gives you a pitying look. 

						"You are free of Wolf's influence, I should have expected you to think like a mortal. But you are more than your flesh, ${prenom}, and small dreams will no longer suit you. When you tire of this life, seek me out. And we shall find a suitable game for you to play."

						${ara_name} bows to you. It is not the mocking salute that ${ara_he} did when you first met in Ishko. $!{ara_he} stays bent for long enough that when ${ara_he} rises again, you have no doubt that the gesture was genuine. 

						"Safe travels," you tell ${ara_him}. 

						"Safe?" ${ara_name} shakes ${ara_his} head. "I hope not."

						$!{ara_he} leaves and you watch ${ara_him} until ${ara_he} goes so far along the grassy steppe that even your preternaturally gifted eyes cannot track. Then you turn and walk back toward the caravan. 

						*goto post_ghazal_romance
					#No. I never belonged here to begin with, I will not delude myself any longer. I will go with ${ara_name}.
						*check_achievements
						*if not(choice_achieved_spidersteal)
							*achieve spidersteal
						${ara_name} smiles and holds out a piece of canvas wrapped tightly around a long object. You have to come close to take it from ${ara_him} and when you do you smell the scent of ${ara_him}—like nearly over ripened fruit and cinnamon. $!{ara_he} takes your face in ${ara_his} hand and kisses you. The kiss is brief, but fierce. 

						Afterward, ${ara_he} lets you take the canvas. You unfurl it and inside is a long tooth.

						"One of my worshipers found that in Quiet lands. I have never seen its like, so I am mightily curious." 

						"So you want me to help you hunt some unknown beast?" you ask. 

						"I thought it was time you slaughtered something larger than a duck," ${ara_name} taunts. 

						*if ((pacifism) and (pacifism_broken = false))
							"I have tried very hard not to kill, ${ara_name}," you reply. 

							"Well, there is always time to learn new skills."
						*comment endif 

						${ara_name} leads the way while whistling a strange, haunting tune. You wonder if ${ara_he} has secured supplies, or has any idea of how treacherous the journey from the highlands to the marshes of the Quiet can be. But you do not consider these things for long. After all, did ${ara_he} not say it would be an adventure? 

						*goto post_ghazal_romance
					#Maybe someday, but not today.
						*goto ara_rejection
			*goto post_ghazal_romance
		#"No. I cannot settle with the Caravan. I do not think my story ends here."
			*goto no_ghazal_romance
		#"Give me time to consider the offer."
			*label no_ghazal_romance
			"I understand," Ghazal says. "Will you at least stay until the celebration of the First Frost? We could use your help."

			You agree to help out until at least that long. It is not that you belong to Mara's Caravan and its people, but with the matter of Wolf resolved, there is more room in your life for improvisation.

			*goto ghazal_romance_opt_out
*else
	Wolf regards Ghazal for a long moment before ${he} 
	*if gender = "none"
		shake ${his} head.
	*if gender != "none"
		shakes ${his} head.

	"I am not meant for this life. Not forever. Surely you can see that."

	"I have seen a great many things and I know that the ${prenom} who left this Caravan months ago is not the same ${prenom} who returned to it. I have been in the presence of the divine long enough to recognize the signs." Ghazal pulls ${ghazal_his} robe closer. Perhaps it is the chill in the air. Perhaps it is Wolf that makes ${ghazal_him} want to instinctively protect ${ghazal_him}self. "I also know there is not one path open to you. One day you may return to us. In one form or another."

	Wolf arches an eyebrow. "And you would wait for me to return? On some slim chance? Some half-foretold thing?"

	"You are beginning to sound like one of the supplicants who journey far and wide to hear my oracles, just to greet them with doubt and suspicion. There is a chance you will return: in this life, or another. Believe, or doubt, either way we will see," Ghazal says with more steel in ${ghazal_his} voice than expected. 

	Wolf says nothing, only inclines ${his} head in deference. 

	*label ghazal_romance_opt_out
	Over the next weeks,
	*if wolf_control
		Wolf helps
	*if wolf_control = false
		you help
	to prepare the Caravan for the cold weather that will soon come. The members of the caravan show their gratitude in an elaborate feast they throw on the eve of ${your} leaving. Ten of the large flightless birds that stalk the steppe are hunted and roasted, preserved fruits are stuffed with fiery peppers, and the alcoholic fermented milk from the heaving animals that the caravaners raise is passed around in hide-bound gourds. 

	*if wolf_control
		Wolf is
	*if wolf_control = false
		You are
	presented with a ceremonial bow that is lovingly, painstakingly engraved with a hundred years of Caravan lore. 

	It is a joyous occasion though farewells are exchanged. Afterward
	*if wolf_control
		Wolf leaves
	*if wolf_control = false
		You leave
	the steppe and move on to another place, another adventure. 
	*goto post_ghazal_romance

*label post_ghazal_romance
*return
