*text_image chap_9.png center Nine: Feather and Claw

[i]"Hush, wolfling. No tears now. Your childhood is over and done, and there will be time ahead for weeping. I promise you that."[/i]
*line_break
-the first words spoken to you after Wolf inhabited your body.
*page_break 

That the trail has led here, to an out-of-the-way town, a cramped room among two seemingly displeased gods, is beyond whatever you would have expected when you awoke in the woods—terrified and alone. 

Hawk's feet hover just a hand-span above the ground and Her cool gaze—yellow melting into silver—tracks you from across the room; a safe distance, for now anyway.

"${prenom}. Bearer of Wolf…" Hawk says, then hesitates, reconsiders. "No. 'Bearer' is no longer accurate, I think. Inheritor of Wolf. Do you know me?"

*if restraint >= 40
	You nod.
	*goto continue_1
*else
	You snarl, and the goddess must take it as acknowledgment, because she continues without introduction.
	*goto continue_1

*label continue_1

"We have come a far way to seek you out, our Brother Bear and I. Never in the long history of mortals have we extended ourselves so. I want to impress upon you the unorthodox nature of this visit, so that you will understand the gravity."

*if ((pacifism) and (pacifism_broken = false))
	*set deliberation %+10
	*set action %-10
	*set equity %+5
	*set selfishness %-5
	*set hawk_affinity %+25
	*set bear_affinity %+25
	*set influence +1
	*set restraint %+5
	Hawk smiles at you. "You promised once that you could navigate our savage world without bloodshed and I was skeptical, but you have proven good as your word, so I have faith that you will be able to hear us out."
	*goto pre_reaction
*elseif pacifism_broken
	*set hawk_affinity %+5
	Hawk frowns. "You once thought you could walk this world without getting blood on your hands, and you were wrong, ${prenom}. So I think you will understand what we have to say."
	*goto pre_reaction
*else
	*goto pre_reaction

*label pre_reaction
*choice
	#Cut Hawk off.
		*set action %+15
		*set deliberation %-15
		"Your words are flowery, Sister Hawk, but wasted on me. Why are you here?" you say with as much civility as you can muster. 

		Hawk seems taken aback, but her recovery is speedy. 

		"I should have expected such a welcome from a disciple of Wolf. 
		*if chaos_score >= 2
			Especially one whose reckless actions have damaged the autonomy and power of this pantheon.
		Very well."

		Hawk reaches into the empty space before her and drags something from the open air. Your eyes do not want to focus on the space, it feels wrong, but you force yourself to watch. Hawk pulls, with minimal effort, a large gray shape from the tear she has rent into the air. She drops it unceremoniously to her feet. 

		The furry body makes a muffled thump as it lands on the carpeted ground of Tumelo's abode. You merely need a glance before your pulse quickens in your throat. 

		Wolf. Your god lies motionless before you.

		*goto convo_converge
	#Remain silent and let her finish.
		*set deliberation %+15
		*set action %-15
		Hawk upturns her palms; a gesture that promises honesty and transparency. If you have doubts, you do not voice them just now. 

		"We have watched you, ${prenom}. All of the gods have observed your progress these last months. You were an anomaly that we could not account for in all of our machinations. You were one of us, but freed from our impulses and our will."

		*if chaos_score >= 2
			The goddess frowns. "And what you have done with that freedom has left a deepening gash in the authority and power of our pantheon."
			*goto pre_convo_converge
		*else
			The goddess gives you a nod, if not of approval, then begrudging respect. "And you have conducted yourself better than many would have in your situation."
			*goto pre_convo_converge

		*label pre_convo_converge

		Hawk sweeps her hand gently and the air before her tears open. The blackness she conjures is hard to look at, but you watch as an even blacker shape emerges from the thin slice of broken space. It drifts to the ground, this mass, and suddenly you can hear your own blood pumping hard in your ears as recognition dawns on you. 

		The body is Wolf's. 

		Hawk has produced your god and he is completely still.

		*label convo_converge

		*if meeting_lyall
			Lyall's eyes go wide and ${lyall_he} hisses.
		*if meeting_ara
			${ara_name} glances at the still black shape and sighs softly.
		*if meeting_sen
			Sen moves to draw his weapon, but seeing that Wolf does not move, he refrains.
		*comment endif

		Bear gives you an impossibly weary, unfathomably sad smile. "It is past time we explained, ${prenom}. The discussion about how to deal with Wolf lasted a hundred years and for all that time Sister-Hawk and I argued. Our positions shifted and changed, evolved. It was no easy thing to argue for killing him; Wolf was, and still is, one of our own. But he was so impulsive, so hungry. 

		"Worse still, where the Rising Sun has gained strength, it has leeched away our own. Surely you must have felt as much? The faith could not survive as it was with Wolf inside of it. It would have come to war with the Rising Sun and led to scores of our supplicants dead. Even if we could demolish the Rising Sun, could we survive the conflict against whatever faith sprang from its ashes? We needed another way."

		"You killed my god," you say. They are finally confessing it.

		*if meeting_sen
			"This is what you can expect from a set of scheming, selfish beings who put themselves above their charges. For what it is worth, ${prenom}, I am sorry that this is the answer you have found," Sen offers.
		*comment endif

		*if meeting_lyall 
			"Do not hear another word of this, ${prenom}. We will tear their throats out and glut ourselves on their divine blood or we will die trying. How else can we repay their falseness?" Lyall snarls. $!{lyall_he} does not take ${lyall_his} gaze from the still form on the ground.
		*comment endif

		*if meeting_ara
			${ara_name} folds ${ara_his} arms across ${ara_his} chest. "You should know, ${prenom}. I had nothing to do with this madness. Though I am impressed that Hawk and Bear managed to agree long enough to commit both fratricide and deicide."
		*comment endif

		Hawk straightens. She looks every bit what you would expect from the de facto leader of the old gods. Her tone, when she next speaks, is elegiac:

		"We have no more prevarications, ${prenom}. Here is the full truth, simple and clean: We killed our brother because we feared he would lead to the end of everything. We decided that it was necessary, even if it could never be entirely just. We offer you his body to do with what you will. Bury it in some forsaken corner of the world, devour it and gain his full power for your own, or leave it here to rot. It is yours to decide, but know that we cannot allow another terrible being to take his place. Seek peace, ${prenom}, that is my advice, but what becomes of all this is yours to decide."

		Her gaze is unapologetic and you can hardly believe what she is telling you. 

		"You killed Wolf," you repeat. The enormity of the confession fully settles. 

		*page_break
		*goto decisions
	#Question why the gods choose this moment to appear.
		*set equity %+15
		*set selfishness %-15
		"I have struggled to get to this point. I have been misled, threatened, attacked, and only now when I approach the truth do you manifest before me. Your timing is impeccable." You can only just keep the note of suspicion from your tone.

		Hawk opens her mouth, but it is Bear who answers. 

		"We have been over-cautious. We did not know what to expect from you. An anomalous being. A ${man_woman} invested with the strength of a god, then cut loose from the restraints of a direct divine influence. It was unprecedented, and so we had to be careful with how we approached you. 
		*if chaos_score >= 2
			It seems there was fair rationale behind our decision, since you have proved yourself to be disdainful of our rule, seeking to damage our authority and undermine the tenuous peace we have tried to hold.
		Regardless, we left the decision too long. There is no more room for caution. It is time to be frank."

		Bear gives a significant look to Hawk, who nods.
		*goto pre_convo_converge

*label decisions

You have no doubt that Hawk and Bear are telling the truth. It would not benefit them to lie, especially when it could mean invoking your wrath. You look again at Wolf's shape, huge and black and dead; a primordial power laid low.

*if meeting_ara
	"Sister Hawk counsels peace, but can you trust her to uphold it when she has proven so apt at using deadly force to solve her problems?" ${ara_name} asks.

	*if meeting_sen
		"I hate to agree with the Spider, but ${ara_he} has a point. If she would eliminate one threat in such a fashion, then what keeps her from doing the same to you?" Sen asks.
	*comment endif

	*if meeting_lyall
		"Peace? The penalties for taking up arms against our god are beyond clear, ${prenom}. Tell me you will not consider making peace with these faithless curs." Lyall searches your face for some sign of appropriate indignation.
	*goto pre_confrontation_loop
*if meeting_sen
	"Gods will always present ultimatums, ${prenom}, because they seek to control, even as they confess their guilt. Careful what you take when it is offered from a closed fist rather than an open palm," Sen cautions.
	*goto pre_confrontation_loop
*if meeting_lyall
	"We are so close to our vengeance, ${prenom}. We merely need to reach out and take it. You will avenge Wolf, will you not? For our enclave, for all those who believe?" Lyall whispers fiercely. There is a wounded vulnerability in ${lyall_his} voice.
*label pre_confrontation_loop

There is no question that you will act, that you must act, but is there anything you are inclined to say to Wolf's killers before you do?

*fake_choice
	#"How did you do it? How did you kill him?"
		Bear gives you a profoundly sad look. You would call it shame, if you thought that your god's murderers were capable of shame. 

		"We have ways of calling to our own. We did it while you slept, so Wolf would come himself across a great distance. He could not refuse the call. We lay in wait and fought him with celestial fire and purified steel. He was not easily felled."

		Hawk shakes her head. "It was slaughter, but there was no choice. The existence of the divine presence is at stake. Godhood has always required sacrifice. Wolf understood that. Every one of us understands."
	#"Why are you confessing now?"
		"We did not know what to expect from Wolf's remaining weapon. There was disagreement between Bear and me about how to handle your existence. He suggested watching you and waiting to see what kind of ${man_woman} you would reveal yourself to be. Neither of us expected your strength, nor the tenacity you have shown," Hawk says. "We feared that you might tear the world apart searching for him."
	#"Are you not afraid of what happens now that I have learned a god can die?"
		Hawk's sword—half incorporeal, half solid steel—slides into her palm reflexively.

		"A calculated risk," Bear says, perhaps not trusting Hawk to be civil in the face of your statement. "Leaving you to hunt for an answer to Wolf's fate any longer seemed like the more dangerous option. We hoped that by coming to you…"

		Bear does not finish his sentence. Maybe it is better that he does not. 
	#"Can I bring him back?"
		Hawk's eyes grow wide. "I will not let that happen, ${prenom}. Wolf is my brother and to strike him down tore my soul asunder, but I would strike him down a thousand times before allowing the faith to fall to ruin. There is no space for his savagery in the new world. I am sorry, but I cannot yield."

		Bear says nothing, but his position is clear even in the way he folds his arms across his chest. 
	#They killed Wolf, what else is there to know? 
		Your god's killers stand in front of you. You can hardly be expected to engage his murderers in casual conversation. No, you have no words for them until you decide what is to be done. 

*page_break
*label confrontation_loop

It is not an easy burden to shoulder, but you know your actions here and now could change the world: Will you seek revenge for Wolf and fight his killers to the death—either theirs or your own? Will you attempt to understand and make peace with the motivations of the elder gods who slew your patron; will you take Hawk's offer and leave with Wolf's body as a token of understanding, if not forgiveness, for their actions? Will you attempt to usurp the natural order and assert yourself as the head of the pantheon? Or will you seek to destroy the pantheon itself, ending the old faith, and leading to a future without the stewardship of gods?

*choice
	#Seek Revenge. There is no other worthwhile option.
		It has come to this moment. Vengeance is within reach and you will not just ignore it. But are you prepared to kill the gods themselves? It will be no simple thing and if you fight, are you willing to kill or die for your cause?
		*set restraint %+20
		*label gods_brawl
		*if chaos_score >= 2
		
			*set self_score %+10
			The gods have already shown their hand. Your actions have helped to destabilize their rule, weaken them. If there was a time to strike, it would be now. 

		You prepare yourself for what must certainly come next. Hawk, seeing something in your demeanor to indicate your plans, moves to attack. Bear simply watches.

		Hawk glides toward you, her feet never quite touching the ground, and brandishes her feathered-hilt sword.
		*if pantheon_regard <= 4
			*set enemy_score %+5
			Her eyes are narrowed in anger, or hatred. 

		*if meeting_ara
			*set enemy_score %-5
			${ara_name} throws a line of…something at Hawk. It is twisted so deeply with ${ara_his} power that you can feel it humming as it flies by. The bolt strikes Hawk and washes over her, slowing, but not stopping her assault.
		*comment endif

		*if meeting_sen
			*set enemy_score %-5
			Sen leaps in front of you and lashes at Hawk with his blade. She seems genuinely surprised by the speed and strength of his swing, but it only delays her a moment. She deflects the attack with a flick of the wrist and slams Sen in the side with an acrobatic kick that would have been impossible if the goddess were not already airborne. 
		*comment endif

		*if meeting_lyall
			*set enemy_score %-5
			Lyall rushes to meet Hawk's attack before you can caution ${lyall_him} against it. $!{lyall_he} leaps toward Hawk and swipes with both hands, curled into vicious claws, aimed at eyes and nose and anything soft enough to break. Hawk struggles with her feral opponent, but ultimately throws Lyall off and continues toward you. 
		*comment endif 

		Hawk crashes directly into you,
		*if survival >= 20
			*set self_score %+10
			but you manage to stay on your feet. Her expression registers surprise, which gives you a bit of leverage. You drive your elbow into the side of her head and she drifts away from you, momentarily reeling. Unfortunately, she is made of hardier stuff and she quickly recovers.
			*goto post_survival 
		*else
			*if meeting_sen
				*set self_score %+5
				which sends you both to the ground in a mess of tangled limbs. 

				"${prenom}!" Sen shouts.

				Hawk is reaching for her sword, which fell from her hand during her impact with you. Sen kicks it out of the way and Hawk grunts her displeasure. You manage to throw her off, but she is airborne again in a moment. Ruffled, but uninjured, and unfortunately for you, she is armed once more. There must be some preternatural link between her and the blade.
				*goto post_survival
			*else
				*set enemy_score %+10
				which knocks you off your feet. She looms above you like a conquering hero from myth and raises the sword above her head. You roll out of the way before she can push it down into your chest.
				*goto post_survival

		*label post_survival

		"You could not have thought this would be easy, wolfling," Hawk spits.
		*if ((meeting_ara) or ((meeting_sen) or (meeting_lyall)))
			"Even with the sorry excuse for aid that you managed to dredge up."
		*comment endif 

		Bear finally moves, and he comes with unnatural speed. 
		*if ara_turn
			*set enemy_score %+5
			${ara_name} stands behind him, whispering the words of a ritual that seems to further enhance his speed.
		*comment endif

		You only have a moment to anticipate his approach. 

		*if quickthinking >= 20
			*set self_score %+10
			You wait until the last possible moment to sidestep, and Bear's momentum takes him past you like a rampaging bull. He turns, quick to remedy his mistake.
			*goto end_fight_scene_1
		*else
			*if meeting_lyall
				*set self_score %+5
				But Lyall throws ${lyall_him}self into the god's way. $!{lyall_he} launches into a flurry of punches and kicks which drive Bear back a few steps and gives you a moment to think. 
				*goto end_fight_scene_1
			*else
				*set enemy_score %+10
				You do not have time to dodge, so you meet Bear's rush full force. It is a very bad idea. He punches so hard that even though you block it with your fists up, you feel the impact in your teeth.
				*goto end_fight_scene_1

		*label end_fight_scene_1

		*if self_score > enemy_score
			*set fight_points +2
			Hawk and Bear glance at each other. It is only a moment, but you detect something unexpected passing between them: fear.
			*goto fight_scene_2
		*elseif self_score = enemy_score
			*set fight_points +1
			You breathe hard, contemplating your next move. Hawk and Bear seem to be re-evaluating you.
			*goto fight_scene_2
		*else
			You will have to do better than this in order to defeat them.
			*goto fight_scene_2

		*label fight_scene_2
		*page_break
		*set enemy_score 50
		*set self_score 50

		You have to go on the offensive, otherwise Hawk and Bear will tire you out and overwhelm you. What form of resistance do you think is wisest? 

		*choice
			#Ritual. I'll throw every ounce of power I have against them.
				Hawk and Bear have avoided arcane combat so far and you wonder if there might be a vulnerability there. 

				Tumelo's rooms are not the best staging ground for a battle of ritual strengths. It would be better by far to have the naked ground beneath your feet and the air running across your ${skin_choice} skin. Alas, there is little space for wishful thinking: You have gods to fell.

				The elements, such as they are, are slow to rouse and you have a flash of fear that they will wake too late to serve you in this fight. Hawk is already holding her blade at her side and Bear is cracking the knuckles on his massive fist.

				*if (((meeting_sen) or (meeting_ara)) or (meeting_lyall))
					"I need more time," you call out. 

					*if meeting_sen
						*set self_score %+5
						Sen nods. It is inspiring to watch him—mortal, finite—throwing himself in the path of gods who mean him ill. You do not have much time to ponder his bravery, however.
					*comment endif 

					*if meeting_ara
						*set self_score %+5
						${ara_name} throws ${ara_his} hands into the air and forms complex shapes that seem to buzz and thrum with energy. $!{ara_he} thrusts ${ara_his} hands out toward Hawk and Bear. The action forms a tight barrier between them and you: It is a start.

						*if meeting_sen
							"We will see if Lord Riser can do better," ${ara_name} says. It is characteristically cocky, but ${ara_he} is breathing heavily as ${ara_he} says it.
						*comment endif

					*if meeting_lyall
						*set self_score %+5
						Lyall, who started moving the moment you raised the call, takes a few swipes at Bear, utilizing ${lyall_his} superior agility to keep Bear off-balance and unprepared for the next move. Hawk hesitates, her gaze flickering between you and Lyall. The distraction does not last long, but any time that Lyall can buy you is precious.
				*comment endif

				There is rancor and death in this room, resting within Wolf's still form, and you are sure you can bend it to your will. But the forces of death and destruction are slippery: They warp and suggest, even as you cajole them into a useful shape. 

				*if (((ritual >= 25) and (sensitivity >= 25)) or ((ritual >= 25) and (survival >= 25)))
					*label ritual_focus_success
					*set self_score %+10
					You ignore the careless taunts of the chaotic forces swirling around the room. Instead you focus, push through the mad suggestions of destructive power and bend it to your purpose. Your ritual causes a bolt of raw power to lash out from the center of the room and you recoil with the force of it pushing back against you as it leaps in Hawk's direction. The goddess accurately predicts an attack, but even her preternatural sight cannot track it. The avian goddess is lashed hard and cries out. Bear tries to use a working of his own to counter or protect, but he is struck hard and staggers away from the solid blow. 
					*goto end_fight_scene_2 
				*elseif ((ritual >= 20) and (influence >= 3))
					*goto ritual_focus_success
				*else
					*set self_score %-10
					*set enemy_score %-5
					Your mind is strong, but the violent impulses you are attempting to cultivate are stronger. The power, raw, and untamed, whips from the confines of your ritual and lashes around the room with preternatural fury. You are struck by a weighted, but invisible force, and thrown to the ground. You hear Hawk cry out as well, her voice high and momentarily panicked. You look up from the ground and see her careening through the air, only just stopping short of crashing into a wall.

					Bear makes a motion with his hand, and the ritual seems to evaporate. Whatever he has done makes his face flush and his shoulders sag. You stand clutching your side where the errant working struck out at you. 
					*goto end_fight_scene_2

				*label end_fight_scene_2

				*if self_score > enemy_score
					*set fight_points +2
					Hawk crouches beside Bear, who stands slightly in front of her, as if protecting her from further harm. They both seem winded, but you expect they have more tricks up their sleeves.
					*goto fight_scene_3
				*if self_score = enemy_score
					*set fight_points +1
					Both gods seem prepared to continue fighting. 
					*goto fight_scene_3
				*else
					Hawk hovers above the ground and stares down her nose at you. Bear's arms are folded over his massive chest. They seem unlikely to give any quarter.
					*goto fight_scene_3
			#Combat. Even together, they cannot match me in a direct fight.
				You know now what to do, how to answer might. There is only one true way: You prepare yourself mentally and then you rush forward.

				You direct your efforts toward Hawk. Overpower her and leave Bear, the bigger of the two, without the promise of aid. But the avian goddess is prepared for your attack. She has her blade in hand and uses its length to keep you at a distance.

				You know that you do not have much time until Bear joins the fray once again. 

				*if (((meeting_ara) or (meeting_sen)) or (meeting_lyall))
					*gosub physical_conflict_help
				
				Hawk comes at you with her sword brandished and her face set in a mask of calm that sits ill over her barely restrained fury. 

				She is naturally strong and a fierce fighter, but she is straightforward, hamstrung by the rules of engagement and her own need to be seen as honorable and righteous. It should not be hard to turn those high morals against her, which is fitting considering it is her unscrupulous judgment that brings you both to this moment. 

				*if (((combat + quickthinking) >= 45) or ((quickthinking + survival) >= 45))
					*label combat_focus_success
					*set self_score %+15
					The goddess tries to skewer you with her sword, but she telegraphs the move by drawing her arm too far back. You have enough time because of the close quarters of the fight to block the attack and knock the blade from her hand. It is a momentary victory. She can call the weapon back to her hand, but she cannot move both space and time. You are moving fast enough to plant a half dozen blows that you know she can feel through her light armor.

					Hawk reels for a moment and swears. Her calm demeanor has utterly cracked, and she shoots you a seething glare. 

					"Filthy mongrel. You are less than a beast," she spits. 

					You merely crack your knuckles. 

					*goto free_bear
				*elseif ((combat >= 25) and (action >= 55))
					*goto combat_focus_success
				*else
					*label combat_focus_failure
					*set enemy_score %+10
					Hawk comes in on your right and tries to drive her sword into your side, but you knock her blade away without much effort. However, the move was a feint and the goddess does a gravity-defying pirouette and comes in hard with her sword thrusting toward you. You manage to miss the point of the blade driving into your abdomen, but it slices into your side, leaving a hot line of pain as you push away from the cut.

					Hawk grins at you and her eyes flick down at the blood dripping from her sword. 

					"I am thinking of renaming my sword. [i]Wolfsbane[/i] sounds fetching, does it not?" she taunts.
					*goto free_bear

				*label free_bear

				*if meeting_ara
					Eventually, Bear growls deeply within his watery prison and bursts free of it. He wipes the water out of his face and gives ${ara_name} a wry look. 

					"Impressive, ${ara_name}. It seems you have been practicing something besides cutting remarks."

					${ara_name} bows elaborately. "I aim to please."
				*comment endif

				*goto end_fight_scene_2
			*if (meeting_ara) #Sensitivity. I can amplify ${ara_name}'s rituals. Together we can break through their defenses.
				"${ara_name}," you call. 

				"${prenom}. Why do I have the feeling you are about to ask me to do something?" ${ara_name} replies. 

				"Take out the goddess. I will support you," you answer.

				${ara_name} takes a deeply performative sigh, but focuses on Hawk nonetheless. ${ara_name} forms a diamond with the forefinger and thumb of each hand and puts the shape up to ${ara_his} eye.

				*if meeting_lyall
					*set self_score %+10
					Without needing to be directed, Lyall races at Bear, presumably to keep him from interrupting the ritual you and ${ara_name} are building. Bear is less than pleased, but meets Lyall in combat just the same.
				*comment endif 

				*if meeting_sen
					*set self_score %+10
					"I can buy you a little time, ${prenom}," Sen announces. He draws his sword and walks casually in Bear's direction. 

					"Here we are again, Bear god. Shall we pick up where we left off in the marshlands?" Sen asks, then rushes forward. 
				*comment endif

				As ${ara_name} constructs ${ara_his} ritual, Hawk, sensing the change in the air, starts to slide out of the Spider's path.
				*if ((sensitivity + ritual) >= 50)
					*set self_score %+10
					At least she attempts to move, but you reach into the dust floating around the room and force it into a swirling storm around Hawk. The goddess fights through it, but the dust blinds her and disrupts her ability to fly. 

					The delay is enough for ${ara_name} to finish ${ara_his} ritual. The localized dust storm around Hawk starts to smolder, then suddenly ignites. She lets out an otherworldly scream and launches herself forward, through the flames and onto the safety of Tumelo's carpet. She is singed, but alive.

					"That…" Hawk starts to say as she extinguishes the last of flames dancing upon her clothes and skin. "…was uncalled for."

					The goddess straightens and glares in your direction. She seems hurt, but you doubt it is enough to ground her permanently.

					*goto end_fight_scene_2
				*else
					*set enemy_score %+15
					You try to stop her from dodging ${ara_name}'s attack by inspiring the dust in the air to tighten around her, strangling the goddess's ability to dodge, but Hawk is more fleet than you expect and she manages to tuck her body into a roll at the last moment, and the snare you have set closes around empty air. 

					${ara_name}'s ritual finishes at nearly the same time, but Hawk is long gone and ${ara_name} ends up burning a circular space on the ground where Hawk should have been standing. 

					"Are you even trying, ${prenom}?" ${ara_name} asks in frustration. 

					Hawk, nonplussed, gives you a slick smile. "I am inclined to ask the same question, wolfling."

					*goto end_fight_scene_2
			#Speed. I can move faster, think faster, than they can. 
				*if (((meeting_ara) or (meeting_lyall)) or (meeting_sen))
					*gosub physical_conflict_help
				*if (((quickthinking >= 20) and (survival >= 20)) or (survival >= 25))
					*goto combat_focus_success
				*elseif (((survival >= 20) and (combat >= 20)) or (combat >= 25))
					*goto combat_focus_success
				*else
					*goto combat_focus_failure
			*if (meeting_lyall) #Determination. Lyall and I can wear them down.
				"Lyall," you say, and within a moment ${lyall_he} is at your side. "Should we be subtle?"

				$!{lyall_he} gives a lupine smile. "Subtle? I am not familiar with the word."

				You nod and Lyall breaks off to the right, and you go left. You communicate the strategy without words precisely, but some combination of gestures and shared intention. You converge on Hawk and she raises her blade, prepared for a fight. 

				*if meeting_ara
					*set self_score %+5
					"I suppose I will take on the Bear then," ${ara_name} calls after you. 

					${ara_name} takes a deep breath and flings a hand in Bear's direction. At first nothing happens, but eventually moisture coalesces in the air and forms a sort of watery barrier around Bear. He struggles, but it only seems to ensnare him deeper. 

					"Huh…" ${ara_name} says to ${ara_him}self. "Not bad."

					With the Bear god dealt with, for now, you turn your attention completely to Lyall and your joint attack on Hawk. 
				*comment endif

				The goddess is a natural predator and prepares well for the assault. She moves with awesome speed and grace as you and Lyall rain down blows upon her. She dodges punches from two directions at once and deflects lightning fast kicks.

				*if (((quickthinking >= 20) or (survival >= 20)) and (lyall_affinity >= 55))
					*set self_score %+10
					Yet as strong and skilled as Hawk is, she falters against two equally talented and motivated opponents. Her blocks begin to come a little too slow and a punch slips through her iron defense, then two. Lyall swings at the goddess, an attack she is able to fend off, but then Lyall dodges to the right and you leap over ${lyall_his} shoulder and deliver a kick to Hawk's neck, which knocks the goddess to the ground. 

					She manages to stand afterward, but she spits a mouthful of blood to the ground. 

					"All right," she says, more to herself than to you or Lyall. "All right."

					When she next looks over at you, she seems prepared to take you apart.
					*goto post_lyall_aid
				*else
					*set enemy_score %+10
					Her guard you find is nearly impervious to attack, even with Lyall throwing ${lyall_his} full might behind every blow and you doing the same. You manage to get a few hits in, but it seems to do little more than make Hawk angrier. 

					Lyall leaps in the goddess's direction, attempting to drive ${lyall_his} knee downward into Hawk's chest, but Hawk reaches up and grabs Lyall's leg, yanking ${lyall_him} from the air and throwing ${lyall_him} to the ground. You follow up, hoping to take advantage of the distraction and nearly get your stomach cut open for your trouble.

					Hawk is a little winded, but you and Lyall seem to have taken more hits between you than she has. 

					"Is that it?" Hawk says. She laughs—hearty and deep. "Well. I think you will find that you need more than whatever that was to put me in an early grave."
					*goto post_lyall_aid
				*label post_lyall_aid
				*if meeting_ara
					*goto free_bear
				*else 
					*goto if_escape_1
				
				*label if_escape_1
				*goto end_fight_scene_2
			*if (meeting_sen) #Endurance. I can combine my strength with Sen and we can outlast them.
				"Sen! To my side," you call. 

				The Riser commander throws himself beside you and holds his sword at the ready. He does not wait for instructions, does not need them: He's fought in enough situations against the odds to know exactly what to do.

				Hawk and Bear do not wait, they come for you like avenging angels. 

				*if meeting_ara
					*set self_score %+5
					Lucky for you, ${ara_name} is in a helpful mood. $!{ara_he} throws ${ara_his} hands up and a shield of dust raises around you and Sen. Hawk and Bear fight through it, but it slows them and blinds them in turn.
					*goto fight_goes_on
				*elseif ara_turn
					*set enemy_score %+5
					${ara_name} throws up ${ara_his} hands and a cloud of dust rises, blinding you and Sen at the worst possible moment. 
					*goto fight_goes_on
				*else
					*goto fight_goes_on

				*label fight_goes_on

				You and Sen fight with collective strength and singular purpose. It is impressive to hold off one god for any amount of time, but to keep two at bay is beyond human.
				*if (((survival + combat) >= 40) or ((survival + quickthinking) >= 40))
					*set self_score %+10
					But you do not just hold off Hawk and Bear, you eventually start to gain ground. You and Sen fight in such close synchronization that the gods are driven back and you start to fight, not just to persevere, but to win. Sen slashes a hot wet line across Bear's arm and you drive a heel so hard into Hawk's leg that you can hear the boom of bone snapping. 

					Both gods back away to nurse their wounds. 

					You give Sen
					*if meeting_ara
						and ${ara_name}
					*comment endif
					an approving nod, but the fight is not over yet. You prepare for whatever comes next.
					*goto end_fight_scene_2
				*else
					*set enemy_score %+10
					Eventually the strain shows through and the battering blows of Bear and the sharp, incisive assault of Hawk start to weaken your defense. Sen blocks a viper-quick cut from Hawk's sword and underestimates its strength. You hear a terrible wrenching sound and Sen is flung backward. The momentary distraction is enough for Bear to sucker punch you hard enough to make the room spin for moment. 

					"Good, but not good enough, ${prenom}," Bear says. "If you want to win, I would suggest you get serious. Soon."

					Sheer bloody-minded stubbornness keeps you on your feet. You ask after Sen's health, and he lies convincingly about being alright. And so the fight continues. 
					*goto end_fight_scene_2

		*label fight_scene_3
		*page_break
		*set enemy_score 50
		*set self_score 50
		*if fight_points = 4
			*label hawk_bear_concession
			Hawk puts out a hand, urging you to halt. 

			"You are clearly formidable, ${prenom}. But are you prepared to risk death to get the vengeance you desire? Can there be no compromise?"

			Bear, massive and visibly tired, adds, "we would be willing to accept fault and fair punishment: As long as Wolf is not allowed back into the world. That is our precondition."

			"Is that not a worthwhile outcome? Bear and I will cede our direct influence over the mortal world for a hundred years. Our avatars will be freed from our thrall. You need only leave here with the promise that Wolf will not be revived by your hand. Is that a fair outcome, ${prenom}?"

			*if meeting_lyall
				Lyall replies before you can. "You are not our maker, feathered witch. We serve at the mercy of the lupine god and him alone. Let us finish what we have started, ${prenom}. They are weak and desperate. Only a little more and they will break, then die like cowards."

				$!{lyall_his} face is contorted into a tight snarl, and you have no doubt Lyall means what ${lyall_he} says. $!{lyall_he} would be happy to murder these gods, who have shown their falseness.
			*comment endif

			The decision lies before you: Accept their surrender, press the attack, or perhaps, use their weakened position to demand further concessions. 

			*choice
				#"I accept your terms. Leave the mortal world and I will not revive the Wolf god."
					*set intention "peaceful"
					*if ((meeting_lyall) and (lyall_affinity >= 60))
						Lyall growls as you speak the words. 

						"${prenom}, we cannot make peace with these traitors."

						"We can and we will. What other choice do you have? Fight forever? Kill everyone in our path until the world looks exactly how we expect it? Think, Lyall."

						The Wolf adherent is reluctant to let ${lyall_his} prey loose. $!{lyall_he} eyes Bear and Hawk, ${lyall_his} hands are still curled into tight fists.

						"This is a mistake, ${prenom}." Lyall makes a dismissive noise and turns ${lyall_his} head. "But it is your mistake to make, and you fought well today. I will not stand in your way."
						*goto toward_peace
					*elseif meeting_lyall
						*gosub lyall_betrayal
						*page_break
						*goto toward_peace
					*else
						*goto toward_peace

					*label toward_peace
					The gods share a long look at each other before addressing you.

					Hawk asks, "You will honor this arrangement?"

					You say nothing of your reluctance to let them leave this room, this town, with their lives intact. "Yes."

					"Then you are not what we feared, ${prenom}. An acolyte of Wolf with even a fraction of his terrifying strength could have been monstrous, but it seems you have some pit of mercy still," Bear comments. 

					"Leave this place before I change my mind!" you yell. 

					The gods flinch, but quickly regain their composure. 

					"We will not return to this plane for some time, but mark this, ${prenom}. We will not stand idle if you choose to become the beast that Wolf ordained you to be. We cannot," Hawk warns. 

					Hawk and Bear do not take much more time to consider their exit. Light wraps around them both and in an instant, they are gone. 

					*page_break
					*goto gods_defeated_end
				#"The only terms I will accept begin and end with your corpses lying beside Wolf's."
					*set intention "revenge"
					Both Hawk and Bear accept the news with resignation, as if they already knew what their offer would yield.

					"Then we fight, I suppose," Hawk says sadly.

					*goto sensitive_fight_start
				#"Leave here, but before you do: Invest me with your power. I wish to be inheritor to three gods, instead of one."
					*set selfishness %+25
					*set equity %-25
					*if ((influence + chaos_score) >= 4)
						Both gods are seemingly taken aback by this offer. Hawk seems prepared to protest, but Bear puts a large hand on her shoulder. She looks over and he shakes his head: "We cannot fight forever."

						Bear looks at you as if trying to peer into your soul. 

						"You will honor this deal?"

						You reply, with some exasperation, that you would not have offered what you did not intend to honor. The fact that Bear is considering accepting seems to put Hawk on edge, but eventually her shoulders slump and she relents. 

						*label three_god_powers
						*set ritual +5
						*set sensitivity +5
						*set combat +5
						*set survival +5
						*set three_god_powerup true
						*check_achievements
						*if not(choice_achieved_threegodpower)
							*achieve threegodpower
						The warrior goddess closes her eyes and exhales. When she opens her eyes again, they are lit with a sickeningly blue light that you are unable to look into for more than a few seconds.

						"This is the power of a god, ${prenom}. See if you can hold it," Hawk says.  

						The light lances through you without warning. It is both cold and burning hot at once, and your veins feel full of the searing brightness. You open your mouth to scream, but the light just pours out as if your mortal vessel was insufficient to contain it.

						"A lesser ${man_woman} would already be dead," Bear notes. 

						*if meeting_ara
							*if gender != "none"
								$!{he} does
							*if gender = "none"
								$!{he} do
							seem to be in a bit of pain," ${ara_name} adds.
						*comment endif 

						Though the pain is incredible, you manage not to crumple to the ground…until Bear adds his own strength. Bear's energy presses down on you like a weight. You collapse to the rugs that cover the floor and struggle to catch your breath. Hawk's cruel light and Bear's overwhelming presence both suffuse your body, and the pain is worse than any you could imagine. And then it is over.

						"$!{he} survived," Hawk says. You note what sounds like vague disappointment. 

						You feel different. The change is imperceptible at first, but it is there. You do not feel stronger as such, but your motions feel sharpened and your sense of detail drastically heightened. You can see the motes of dust in the air, could snatch them from it if you wanted.

						"We will go now. Please do not follow. We have given you much of our strength, but I doubt your ability to master it quickly enough to challenge us now. Worse still, you have been weakened in the taking. I do not think much of your chances against us now," Bear explains patiently. 

						You find he is right. Your body is sore and your mind is reeling with the sudden changes to your perception. A fight against two gods in this state would be disastrous.

						"I hope you make good choices with the power you have been entrusted with, but I know better than to have faith in what I cannot control," Hawk says. 

						*if meeting_lyall
							"It is exactly that lack of faith that led you to this outcome, bird-woman," Lyall points out harshly. 

							The goddess seems like she is going to lash out against Lyall, but reconsiders. "You may be right, wolfling. May you never learn the burden of godhood."

							She gives you a pointed look. 
						*comment endif

						"It is time, Sister. Past time," Bear says. The two gods close their eyes and another flash of that cold, strange light washes over them, and then they are gone. 

						*if meeting_sen
							Once they have gone, Sen looks at you. He releases a breath that you are not even sure he knew he was holding. 

							"So what does it feel like? To host the power of three gods instead of just one?" he asks. 

							You flex your hand. The skin is the same, but you feel a queer might just beneath it. 

							"Good," you reply. 
						*page_break
						*goto gods_defeated_end 
					*else
						*set going_once true
						*set enemy_score %+10
						Hawk blinks in surprise. "You are worse than Wolf. He was a butcher, but you would make yourself a tyrant."

						The goddess flicks her wrist and her sword moves so fast it looks a blur. 

						"No. We end this here and now," she says. 
						*goto sensitive_fight_start
		*elseif fight_points <= 1 
			"You should have reconsidered, ${prenom}. You cannot win against us. Once we defeat you, we will tear your body apart and make an example of those who refuse to accept a more peaceful world. I am sorry it has come to this," Bear says. 

			His hands are curled like claws and he seems ready to strike. 

			*goto sensitive_fight_start
		*else
			There is no clear winner yet. There is time to decide the fight in your favor, but Bear and Hawk will not make things simple for you.

			*goto sensitive_fight_start
		*label sensitive_fight_start

		Hawk raises a fist high above her head and suddenly the air feels closer in the previously spacious hall.
		*if ara_turn
			*set enemy_score %+5
			The Spider also holds ${ara_his} hand aloft, contributing to, and multiplying the effect of Hawk's ritual.
		*comment endif

		*if sensitivity >= 25
			*set self_score %+15
			You can taste the excess power in the air, raising every hair on your body, and tickling your sinuses like an oncoming thunder storm. Whatever is coming your way is terrible, and you move to avoid it.

			The bolt is white-hot and sears the space between where you are and where you had been a moment before. Hawk's aim is impeccable, but underestimates your foresight. You take just a moment to savor the look of surprise on her face when she realizes her ritual missed.

			*goto post_sensitivity
		*elseif ((sensitivity + quickthinking) >= 45)
			*set self_score %+15
			The goddess telegraphs her ritual in the way she snaps her wrist and juts her hand, palm forward, in your direction. It is a bit of flair; she could just as easily summon forth the requisite power necessary to blast you into myth without blinking an eyelash, but luckily for you, Hawk has a sense of the dramatic.

			You dodge, well, scramble mostly, out of the way as a burning flash of heat and light chars the space immediately beside you.

			"Dammit," Hawk swears under her breath.

			*goto post_sensitivity
		*else
			*set enemy_score %+10

			The animal part of your mind suddenly wants to move, to get out of the way, to flee, but your body moves too sluggishly. Hawk thrusts a hand in your direction and a blast of something hot and bright careens toward you. Naturally, you try to dodge, but the burning sphere catches your forearm and the pain is enough to throw you off your feet. The smell of singed hair and skin radiate from the site of the wound, which you hesitate to look at, but is not as bad as you would have assumed. 

			"This is not a game, ${prenom}. The stakes are too high to let you walk away from this," Hawk says. 
			*goto post_sensitivity 

		*label post_sensitivity

		You do not have long to prepare for Bear's attack. His fingers are interlaced in a complex arrangement that changes rapidly. Beneath you, the weave of the carpets is warping, snapping like the jaws of a thousand snakes. The suddenly iron-like threads climb your legs and lock you in place. You cannot move. Your only hope is to disrupt the intricacies of Bear's ritual with one of your own making. 

		*if ritual >= 25
			*set self_score %+15
			Your fingers move as fast as your thoughts. The motions and rhythms are merely to focus your intentions into useful forms, what emerges from this deep concentration is purely a product of your unshakable will. The fibers of the carpet are firmly under Bear's control and you cannot sway them to your side and encourage them to release you, but within each fibers is a spark of rebellion, the heart of flame. You kindle that spark to greater and greater fury, and within moments the carpet underfoot bursts into flames. 

			The heat is intense, but you remain unburnt. The fire recognizes you as a liberator, a temporary ally. The fire rises around you and Bear's concentration snaps. His mouth is agape, unbelieving. His incredulity is an opening. 

			*goto post_ritual
		*elseif ((ritual >= 20) and ((sensitivity >= 20) or (survival >= 20)))
			*set self_score %+15
			Yet you cannot hope to directly counter Bear's casting: he is deep in concentration and the strength of his ritual seems absolute. Instead you approach the problem sideways. Your ritual strength is not as powerful as Bear's but it is enough to undermine the integrity of a piece of wood, which is all you need. You encourage the beams of wood crisscrossed in the ceiling above Bear's head to shrug off their incredible burden and the wood is quick to consent to a well-earned rest. The wood slackens and it is enough to cause a section of the roof above the ursine god to cave in. 

			Bear howls as the roof collapses beside him. He manages to dodge, avoiding being crushed, but he cannot keep the ritual together. His casting falters and you are free to counterattack. 
			*goto post_ritual
		*else
			*if meeting_ara
				*set enemy_score %-10
				However, your ritual strength cannot match Bear's and the fibers of the carpet grow tight around your ankles, reaching up as high as your thighs. You look over and ${ara_name} is laughing. $!{ara_he} shakes ${ara_his} head. 

				"I've seen tighter traps, ${prenom}."

				$!{ara_he} moves through a series of motions with ${ara_his} hands, and the reaching tendrils seem to age and wither under ${ara_his} attentions. 

				"Move. Now," ${ara_he} commands.

				You waste no time arguing: You need to put as much space between yourself and Bear as possible, in case he has a counterattack already brewing.
				*goto post_ritual
			*else
				*set enemy_score %+10
				You try to rally whatever ritual power is at your discretion, but the fibers wrapped around your ankles and lower leg are squeezing so tightly that you can hardly concentrate. Bear makes a gesture and you are dragged to your knees.

				*if meeting_sen
					Sen tries to come to your side, but Hawk is suddenly between you. She lashes out with the speed of a serpent and drives the pommel of her sword into his throat. He falls to the ground, hacking and wheezing, but he is alive when Hawk could have killed him, which is something.
				*comment endif

				*if meeting_lyall
					Lyall tries to come to your aid, but ${lyall_he} falls into nearly the same trap. The plush carpeting that covers nearly every surface of the ground in Tumelo's hall betrays ${lyall_him}. $!{lyall_he} sinks into the floor, while screaming bloody murder.
				*comment endif

				Eventually Bear's ritual hold on you loosens and you crawl out to safety. Even standing makes your head swim a little, but you try not to show weakness. 
				*goto post_ritual

		*label post_ritual

		*if self_score > enemy_score
			*set fight_points +2
			You feel stronger than you have any right to considering what you have weathered so far, but you are still standing and Hawk and Bear seem worse for the wear.
			*goto fight_outcome
		*elseif self_score = enemy_score
			*set fight_points +1
			You idly wonder if the world has ever seen such a fight. You have fought as hard and as long as you could have and so have your rival gods. It is with great effort that you call forth the dregs of your energy and force yourself to stand tall. 

			"Let us end this," you say, hating the note of exhaustion in your voice.
			*goto fight_outcome
		*else
			You are exhausted and hurting, but you hope you have fought hard enough.
			*goto fight_outcome

		*label fight_outcome
		*page_break
		*if fight_points >= 5
			Hawk's sword lies on the ground between you, but she seems to be unable to call the blade to her hand. Her expression is fierce and undaunted, though her body shakes with the effort of trying to stand. She eventually relents and lets the blade lie. Bear, by her side until the last, looks equally defeated. 

			*label to_kill_or_not
			You have fought hard for this moment, but now that it is here, can you truly strike the killing blow?

			*choice
				#No. Let the traitors leave this world in disgrace.
					"Leave this world. If we encounter each other again, I will hunt you down and make you regret returning," you threaten. 

					Bear goes to Hawk's side to support the wounded goddess, but she stands on her own and locks eyes with you. 

					"You will find this world is difficult to carry on your back, ${prenom}. But if you are so desperate to try, you will not find resistance from me."

					Bear says nothing, but he puts a gentle hand on Hawk's shoulder. The gesture says much that the gods themselves do not.

					"Yes, Brother. It is past time." Hawk says. She straightens, still proud and haughty as ever despite her recent defeat. 

					*if ara_turn
						${ara_name} holds ${ara_him}self apart. $!{ara_he} shakes ${ara_his} head. "I chose poorly, ${prenom}. But I have to admit, it was fun."
					*comment endif

					They begin a ritual that causes a sterile blue light to wash over them. Their figures become indistinct in the light, and their edges blur as you look at them. As they fade from sight, Bear speaks. His voice comes as if from a great distance. 

					"When you realize that being the savior of the world is not what you had hoped, we will be waiting, ${prenom}."

					After that, they are gone. 

					*page_break
					*goto gods_defeated_end
				#Of course. It is no less than they deserve.
					*goto pre_deicide
				#I will allow them one final chance for Bear and Hawk to cede their power to me. That will be their payment for their crimes.
					*if ara_turn
						You intend to take the power of Hawk and Bear, but you instinctively mistrust ${ara_name}'s deceptive, twisting sorcery. 

						You turn your attention toward the other two traitor gods.
					*comment endif 

					*if ((hawk_affinity >= 60) or (bear_affinity >= 60))
						*if going_once
							Hawk blinks at you. Once. Twice. 

							"Of course it comes back to this…" she says, half-groaning.

							*label bear_gives_in
							"Give ${him} what 
							*if gender = "none"
								${he} want,
							*if gender != "none"
								${he} wants,
							Hawk," Bear says.

							"Are you mad, Brother?"

							"If this world will only respect strength, then maybe we should give our support to the strongest of us. For better or worse." Bear gives his sister a tired smile. "We have tried everything else we could think of, and we have been at this for too long now."

							Hawk shakes her head in disbelief. "So we give it all away? Our power? Our ability to protect—"

							"How many lives have we saved recently, Hawk?" Bear snaps. "No. We have watched our charges fight, starve, die, and our contribution has been to grieve for them. What has our power truly wrought?"

							Hawk goes silent for a long time, then looks at you. Something like fury burns in her eyes, but she says, "All right."

							*goto three_god_powers
						*else
							"You want us to give you our power?" Hawk says in disbelief. "I would rather die a hundred deaths. Do your worst, ${prenom}."

							*goto bear_gives_in
					*else
						*if going_once
							Hawk shakes her head. 

							"You offer this impossibility again? As if we would be mad enough to accept this time? You are as mad as your sire. Hurry and do your worst, ${prenom}."
							*goto pre_execution
						*else
							Hawk laughs. It is gentle at first, then devolves into a snorting, calamitous ruckus. "You waste your time and our last moments with jokes. Make good on your lineage, Wolf-scion. Do what is in your blood." The way she says the final word chills you. You feel you will hear her voice saying it in your mind for months and years to come. 
							*goto pre_execution

						*label pre_execution
						
						Bear does not speak a word, but his look is pure defiance. The choice is practically made for you.

						*goto pre_deicide

			*label pre_deicide
			You stand and stare down your nose at them. They brought Wolf low and you are now on the cusp of returning the favor. A thrill of excitement rushes through you, but do you feel another emotion as well? 

			*fake_choice
				#I am disappointed. I thought they would make better adversaries.
					*set action %+10
					*set deliberation %-10
					You wanted a fight worthy of your growing legend, but even these gods had trouble standing before you. It is understandably disappointing, however it will not stop you from taking their lives.
				#I am sad. The death of Hawk and Bear will signal the end of an era.
					*set deliberation %+10
					*set action %-10
					Bear and Hawk have to die: There is no argument that could change your mind at this point, but you have empathy enough to regret what you have to do. If you had expected joy at this outcome, you do not find it here now. 
				#I am angry. Even now, so close to death, and they still refuse to grovel before me.
					*set selfishness %+10
					*set equity %-10
					Some part of you wanted them to beg. If they threw their hands before them in worship and begged for their lives, then you might have considered sparing them. One of them, perhaps. However, they will not give you even that satisfaction. You remind yourself that it does not matter; their fates are sealed regardless. 
				#I am content. I set out to avenge Wolf and the moment is finally here.
					*set equity %+10
					*set selfishness %-10
					You expected this. You knew it would end in blood and now the moment has come. You are calm and prepared to do what you must.
			*comment endif

			*if meeting_sen
				Sen gives the fallen gods a mirthless smile.

				"You fought well. But the future belongs to us."
			*comment endif

			*if meeting_ara
				${ara_name} blows Bear and Hawk each a kiss. "Tell our Brother Wolf hello from me when you see him."
			*comment endif

			*if meeting_lyall
				Lyall says nothing, but the corners of ${lyall_his} mouth are turned up in a tight, vicious smile.
			*comment endif

			*label dead_gods
			*set hawk_dies true
			*set bear_dies true
			*if ara_turn
				*set ara_dies true
				*set friend_kill_count +1
			*if pacifism
				*set pacifism_broken true
			They struggle, as any living thing would, but the fight has gone out of them. When it is over, Hawk and Bear lie on the ground and the divine light that radiated from their physical manifestations first dulls, then gutters out completely. They are as dead as Wolf, and having killed their divine forms, you very much doubt that they are going to come back.

			It takes some time for the reality to hit you: The cause you have pursued is now finished. Those responsible for Wolf's destruction have met the same end.
			*page_break
			*goto gods_killed_end
		*elseif fight_points >= 4
			Bear tries to reach for some power, tries to fill himself with it, but whatever reserves he anticipates must already be spent because the air around him remains still. Hawk sees this and is the first to name it. 

			"Enough, Brother. It is enough now," she says, and turns to you. "We concede. The fight is yours, ${prenom}. As are our lives."

			*if ara_turn
				"This is not exactly what I had expected. I should have kept faith this once," ${ara_name} jokes.
			*comment endif

			*goto to_kill_or_not
		*else
			*comment this needs to be more of a question answered, instead of a continuation of an earlier narrative.
			*comment maybe start with what/how Hawk/Bear are doing. 

			You have all taken blows and dealt them, but in the end you are battered and bruised, your reserves of power and strength near empty. The fight has gone out of you, and you have a sense of what comes next. 

			In the end you expect Hawk to be standing before you, haughty and imperious, ready to deal the final blow, but to your surprise it is Bear. He seems…hesitant. 

			"Neither of us expected this, ${prenom}. We did not intend for you to suffer the same fate as our Brother Wolf. It could have been different."

			*if ara_turn
				"Or maybe nothing could have ever been different. Maybe this is how it was written when the stars were young. Or maybe this is the wage you have earned for your choices." ${ara_name} shrugs. "Either way."
			*comment endif

			*if meeting_ara
				Bear looks toward ${ara_name}, who stands beside you, proud and wry-mouthed even at this late hour. The Spider avatar shrugs. "Get on with it, Bear. I would vastly prefer death to the tedium of whatever speech you have planned."
			*comment endif

			*if meeting_sen
				Sen bows his head. You can imagine what he is thinking; his glorious coup against the gods has failed in its infancy.
			*comment endif 

			*if meeting_lyall 
				Lyall is shaking with anger, but ${lyall_he} remains calm.
				*if lyall_romance = "sleptwith"
					"It was an honor fighting beside you, ${prenom}. You were…are a worthy partner. A true wolf until the last."
				*comment endif 

			Bear is still for a while, as if awaiting some sign or marshaling some inner reserve of his will. He gives you one final, penitent look.

			"May we meet again, ${prenom}, and may next time end differently."

			The blow is heavy, but there is little pain. Before the end you think you hear a keening in the distance. A wolf's song. It fades slowly and then there is nothing else.
			*page_break
			*goto_scene death
	#Try to understand Bear and Hawk's motivations. 
		You want to understand why Wolf was murdered, even if you have no desire to forgive the transgression.
		*if restraint <= 50
			But speaking to Bear and Hawk, who stand before you with clean hands having killed their own brother, brings the taste of bile up from the back of your throat. 
		*comment endif

		"You murdered my god," you say. It feels ridiculous to say this again, but what else is there to say? 

		"You will never know how difficult it was, ${prenom}. Wolf was ours. We smelled his burning fur and heard his howl in our ears when we fell from darkness into awareness at the beginning of time. We would not have done what we did except for out of desperation," Bear says. 

		Desperation. The word triggers something in you, makes you think of the panic and raw disorientation that Wolf's absence left within you during those first moments. Can you make peace with gods who could have done this horrible thing? And what of Wolf's instincts inside you? Can you satisfy yourself with this outcome?

		*choice
			#Whether I want to or not is immaterial. I must make peace or be ready to do what they have done and worse. I will not allow them to make me a monster, too.
				*set intention "peaceful"
				*if ((pantheon_regard >= 7) or ((influence >= 4) and (chaos_score < 2)))
					"We could fight. Tear each other limb from limb, but that will not improve things for anyone. The Rising Sun and members of the Old Faith will still be at each other's throats. Wolf will still be dead."

					You look at Hawk, then Bear. Gods both saddled with an impossible decision. Whether or not you would have made the same choice is no longer important. Bleeding each other dry is not a solution.

					"It must be peace," you say.

					*if meeting_lyall
						*gosub lyall_betrayal

					*if ((hawk_affinity >= 60) or (bear_affinity >= 60))
						*set deliberation %+15
						*set action %-15
						*set equity %+15
						*set selfishness %-15
						Hawk and Bear share a long look, one of them slowly nods, and then the other.

						"You are different than Wolf, ${prenom}. Our fears about you have turned out to be unfounded. Whatever you have done to get to this point, what is most important is that you desire to rise above Wolf's bottomless appetites," Hawk says. 

						Bear chimes in. "For our part, we intend to leave this plane for a time. Humans have been under our protection for a long time, but we have not grown at their pace. Much still surprises us. It might be time for us to take a step back from the direct stewardship of man's affairs. It is past time that there was further autonomy in the human world."

						*goto peaceful_end
					*else
						Bear gives you a pitiful look. 

						"If we could trust you, we would. But we have fought too hard to protect this world to allow it to suffer again because we trusted the wrong ${man_woman}. I am sorry, ${prenom}, but we cannot make peace with Wolf's heir."

						Hawk puts a hand on Bear's shoulder. "Enough, brother. It is time to finish what we started."

						Bear nods. 

						"Apologies, ${prenom}."

						The two gods prepare for combat, and you should do the same.

						*page_break
						*goto gods_brawl
				*else
					*if restraint >= 50
						You can feel the pull of Wolf's wishes pulling you inexorably toward blood and conflict, but you are not the same ${man_woman} that you were at the outset of you journey. You are no longer merely a worshiper, but a free ${man_woman} with your own set of desired outcomes. 

						"I cannot remedy this with blood. Not this time," you say, as much to yourself as the others. "I do not want to fight."

						*if meeting_lyall
							*gosub lyall_betrayal

						*label pre_peace
						*page_break

						After everything you should hate the ursine and avian gods, but you no longer have it in you. 

						"Leave this place in peace and I will do the same. One day you will pay for your mistakes, but not today, not at my hand," you tell them. 

						*if meeting_ara
							*set ara_peace_refusal true
							*gosub ara_betrayal

						When all is said and done, Hawk and Bear are prepared to leave and you still intend to let them. It is not an easy decision to make, but you make it with the best interests of more than just yourself in mind.

						*label gods_leaving
						"You are a worthy inheritor of Wolf's mantle, ${prenom}," Hawk says, right before the end.

						The two gods wrap themselves in a brilliant light that blinds at first, then fades as quickly as it came on. 

						*goto peaceful_end
					*else
						*set wolf_control true
						You try to say the words that will release the gods from the burden of Wolf's murder, but inside your mouth fills with the taste of blood. You try to shake it off, regroup your thoughts, but your fingers curl into a fist involuntarily. 

						You hear Wolf's low growl in your mind and you are surprised to find it emanating from your own throat.

						"I…" you start, but it ends in something less than language. A primal jumble of sounds that causes Hawk to grip her sword tighter and Bear to take a step back. 

						You try again to speak the peaceful words that are so clear in your mind, but your body is in rebellion. You regret, for an instant, the self-indulgent and impolitic choices that led you here. Maybe another ${man_woman} could have risen above ${his} baser instincts, but right now, in this place, you are not that ${man_woman}. Peace is off the table, so it will be blood instead. 

						You take a lumbering step toward the other gods. 

						*if meeting_sen 
							*gosub sen_betrayal

						*goto gods_brawl
			#Hawk and Bear have shown poor judgment and are hardly worthy to lead. I will take the pantheon under my control.
				*goto coup
			#No. Never. I have heard them out and their reasons are weak. They must be punished, brought low.  
				You finally decide and the decision fills you with purpose. 

				*goto gods_brawl
	#Attempt to peacefully take Wolf's body, though you know Wolf's instincts will push against the decision.
		*set intention "peaceful"
		*set restraint %-5
		*if restraint > 30
			*label peaceful_resolution
			*if meeting_lyall
				*gosub lyall_betrayal

			*page_break
			You would not have imagined that after all this time and all the trials you have survived that the end of your journey would be this: A solution with spilled blood or even the slightest vengeance, but you can feel the weight of your choices settling over you. More blood will not bring Wolf back, nor will it feed and clothe his followers. 

			"This is the right thing, ${prenom}," Hawk says, but you barely hear her over the sound of your own pulse in your ear. 

			You do not trust yourself to speak. Instead you crouch down and begin to lift Wolf's body up off the ground and over your shoulder. It is heavier than you expect, but light enough to carry.

			*if meeting_lyall
				Lyall averts ${lyall_his} eyes from the corpse in deference.
			*if meeting_sen
				Sen eyes Wolf's still form warily as if at any moment it could leap to life and tear him apart.
			*comment endif

			*if meeting_ara
				${ara_name} whispers something that sounds reverent, but is too low to discern.
			*comment endif

			As you turn and walk away from the gods who killed Wolf, you find your voice: "I do not wish violence upon you two, but I cannot promise it will be so in the future. We should give each other a wide berth in the future."

			Bear solemnly agrees. Hawk says nothing.

			*goto gods_leaving
		*else
			Even saying the words seems to burn your throat. You try, again and again, to make peace with the gods who openly claim to have murdered your kin, your god, but you cannot. You are full of rage, low on restraint, and there is a rising feeling in your gut that foretells rash decisions.

			Every instinct inside you that Wolf has placed there since you were a child rears up against this decision. 

			*if (((pacifism) and (chaos_score <= 2)) or (pantheon_regard >= 7))
				*set restraint %+15
				You bare your teeth as the anger crowds the other thoughts in your mind, but then you feel a soft touch on your shoulder. The contact immediately brings to mind a scene from your childhood: A woman running a comb through your 
				*if hair_choice = "bald"
					hair before styling it.
					*goto hair_var_disp
				*elseif hair_choice = "braided hair"
					hair before styling it.
					*goto hair_var_disp
				*else
					${hair_choice}.
					*goto hair_var_disp
				*label hair_var_disp
				She is telling you a ${tribe} story of the stars and how they were plucked out of the sea and placed in the sky to dry. You recall the tenderness of the woman more than anything. Your mother. 

				The feeling subsides, and a voice fills the room. 

				"You desire to rise above Wolf's relentless anguish, ${prenom}, so I will do what I can to help. To soothe the rage that he has cultivated. You have done well by your gods, and it is time for us to offer you more than just our words."

				You feel some of your anger leeching away. You again see another path before you; a path that is not littered with broken bodies.

				*goto peaceful_resolution
			*else
				*goto intervention_fail

			*label intervention_fail
			*if restraint < 35
				*set wolf_control true
				*set action %+10
				*set deliberation %-10
				You growl, spittle dripping from your mouth as you set eyes on them. The murderers.

				It becomes impossible to distinguish between your impulses and Wolf's old directives buried deep within your skin. 

				You want to kill them. Need to kill them.

				*if meeting_ara
					"We can only ever be what we are, ${prenom}," ${ara_name} says. There is a note of regret in ${ara_his} voice.
				*comment endif

				*if meeting_sen
					*gosub sen_betrayal
				*comment endif 

				*label inevitable_bloodshed
				Neither Hawk nor Bear seem particularly surprised by your sudden blood-thirst. If anything, they seem resigned. 

				"All right, ${prenom}," Bear says, and cracks the knuckles of his massive hands. "Let us dance if we must."
				*goto gods_brawl
			*else
				*goto inevitable_bloodshed
	#Rearrange the natural order of the pantheon. Bend them under my leadership.
		*label coup
		*set intention "control"
		"Abdicate." You say the word with every ounce of disdain that Hawk and Bear, sitting at the top of the pecking order, secretly controlling how events play out from on high, deserve.

		"You have tried and failed to lead us. It is time for you to step down. Hawk, your judgment is clouded. You do not see as clearly as you pretend. Bear, your ponderousness has made you slow to react and leads you to false conclusions."

		Hawk raises an eyebrow. "And you would do better? Doubtful, little wolf. For all the ability that brought you here, you are still human at your core. There is more to all this than bravado and venom."

		*if meeting_ara
			"Is there?" ${ara_name} asks acidly.
		*comment endif

		*if meeting_lyall
			"If there is, you would not know it by your conduct. Bird woman," Lyall hisses. 

			Hawk looks mildly amused by this outburst, but she does not reply.
		*comment endif

		Bear shakes his head slowly. 

		"We cannot allow just anyone to take over our sacred task," he says. 

		It becomes clear Hawk and Bear will not concede their positions easily. Yet they must be convinced, or perhaps destroyed. Either way might easily end in bloodshed. 

		*choice
			#Turn Hawk against Bear. Convince her that you are her best shot at keeping order.
				You decide to make your case to Hawk. She considers herself a goddess of ordered things and, you presume, most likely to hear an appeal to reason. 

				"Killing Wolf has kept him from starting a war with the Rising Sun, or worse, but you still have problems, Hawk. The gods are not fierce enough to keep from being overrun by members of opposing faiths, or falling into irrelevancy. You need Wolf's strength. My strength."

				"I do not deny there is some truth to what you say. But the path of the Wolf is what brought us here. The solution that Bear and I agreed on was borne of the understanding that unchecked violence could not solve our problems," Hawk says. 

				Bear grunts. "${prenom} is misguided. 
				*if gender != "none"
					$!{he} brings
				*if gender = "none"
					$!{he} bring
				nothing new to the table. No angle that we have not already considered."

				*if (((influence >= 3) or (pantheon_regard >= 7)) or (sensitivity >= 30))
					"Let ${him} speak, Bear. We killed ${his} patron god. We owe ${him} this much," Hawk says. 

					"Hawk…" Bear starts, but the goddess shuts him down with a severe look.

					"We would make better allies, you and I," you explain to Hawk.
					*if ((equity > selfishness) and ((quickthinking >= 20) or (sensitivity >= 20)))
						*set god_ally "Hawk"
						*set god_his "her"
						*set god_him "her"
						*set god_he "she"
						*set god_foe "Bear"
						*set foe_him "him"
						*set foe_his "his"
						*set foe_he "he"
						"We are both fair and thoughtful. We could protect everyone, Hawk, but we cannot do it unless we deal with Bear."

						Bear starts to object, but Hawk has already made her decision. She brandishes her sword and only some preternatural instinct on Bear's part takes him out of the path of her blade. He leaps back and narrows his eyes in her direction. 

						"Betrayal at last," he barks, half-snarling. 

						"Our alliance was not meant to last, Bear. You know as well as I do that it was borne of necessity. I have to protect this world and I need strong allies to do it. May we settle our differences in our next life." Hawk's weapon is primed and she seems ready to do whatever she has to.

						*label hawk_vs_bear
						${god_ally} stands tall and stares down your now mutual foe. $!{god_his} flesh and blood form is imposing, but ${god_foe} for one seems unimpressed. ${god_ally} rolls ${god_his} shoulders back and dashes toward ${god_foe}.

						Light streams between ${god_foe}'s closed fist, and ${foe_he} fires a punch in ${god_ally}'s direction that sears the air, even from where you are standing several paces away. $!{god_ally} defends just as the punch impacts. The explosion of heat is near unbearable and the brightness is blinding. When you can see again, ${god_ally} seems winded but is still standing. You should help ${god_him}…or perhaps you would prefer to see how this plays out.

						*choice
							#Use a ritual to slow ${god_foe} down.
								You craft a ritual you are sure will slow ${god_foe} to a crawl. The close air of Tumelo's meeting room begins to swirl around ${foe_him}.
								*if ((((ritual + sensitivity) >= 50) or ((ritual + survival) >= 50)) or (ritual >= 40))
									${god_foe} fights against the unnatural burst of wind and pressure, but it slows ${foe_him} enough for ${god_ally} to turn the tide of battle, delivering increasingly brutal attacks until ${god_foe} is driven to near defeat.

									The ${god_foe} unleashes a terrifying wail. 

									*label hawk_bear_defeat
									*if god_ally = "Hawk"
										*set bear_dies true
									*if god_ally = "Bear"
										*set hawk_dies true
									${god_foe} makes you the sole focus of ${foe_his} attention. It is an attempt to change the tenor of the fight and put you down for good. $!{foe_he} flings ${foe_him}self in your direction. But ${god_ally}, at the last possible moment, steps into ${foe_his} way and thrusts hard with
									*if god_ally = "Hawk"
										her feathered sword.
									*if god_ally = "Bear"
										his clawed hand.
									*comment endif 

									The strike is true and ${god_foe} looks down at the grievous wound, as if disbelieving its existence or questioning that the blow could have come from someone so close. 

									"This is what you chose?" ${god_foe} asks ${god_ally}, before crumpling to the ground.

									*if meeting_ara
										"Brutal, but efficient. A clean death. A worthy one," ${ara_name} says, after the blood is spilled. 
									*if meeting_sen
										Sen turns his head out of respect for the fallen.
									*if meeting_lyall
										Lyall touches ${lyall_his} hand to his forehead, then ${lyall_his} lips. However, ${lyall_he} says nothing.
									*comment endif

									*goto hawk_bear_ally
								*else
									However, ${foe_he} is enraged and past the point where such simple tricks could be effective. $!{foe_he} barrels through and grabs ${god_ally}.

									*label ally_is_killed
									Their embrace is almost tender, then all at once it becomes vicious. ${god_ally}'s body goes limp and ${god_foe} lets it fall to the ground.

									${god_foe} stands there for a while, considering the act. 

									"More divine blood spilled. And make no mistake, we deserve every drop for what we did, ${prenom}." ${god_foe} says.
									*goto bloodied_foe
							*if (meeting_sen) #Send Sen to engage ${god_foe}.
								Sen eagerly joins the fray. He throws himself into it and fights all but back-to-back with ${god_ally}. It is strange to see the two fighting together, but these are strange times. 

								*if ((riser_affinity < 60) or (chaos_score < 2))
									*set sen_dies true
									*set friend_kill_count +1
									Both Sen and ${god_ally} are exceptional combatants, but ${god_foe} begins fighting like a cornered animal, fierce and hungry for survival. Sen tries to go for a deciding thrust, but misses by a hair and ends up taking a lash across his shoulder from 
									*if god_foe = "Hawk"
										Hawk's feathered sword.
									*if god_foe = "Bear"
										Bear's great clawed hand.
									*comment endif

									The wound seems to jolt the Riser commander. It is not until he turns that you see how deep and ragged the cut is. You call out to him, but Sen is stunned by the wound. He looks at you, surprised, and then he collapses.

									You see the blood spreading beneath him. It is quickly absorbed by the lush carpets of Tumelo's meeting room.

									*goto bloodied_foe
								*else
									They fight well together and even before you get involved, ${god_foe} begins struggling. $!{foe_he} is consistently driven back until eventually ${foe_he} takes a cut to the gut that distracts ${foe_him} long enough for you to intervene. 

									*label group_fight_chain 
									*if ((combat + survival) >= 45)
										*label hawk_bear_success
										You throw yourself into the fight. When you join your strength with the others, the outcome starts to become clear. 

										${god_foe} is breathing heavily. $!{foe_he} looks up at you from under sweat-soaked locks pasted across ${foe_his} face: "We should have ended you along with your sire, dog."

										*goto hawk_bear_defeat 
									*elseif ((survival + quickthinking) >= 45)
										*goto hawk_bear_success
									*elseif ((ritual + sensitivity) >= 45)
										*goto hawk_bear_success
									*else
										*goto losing_to_hawk_bear
							#Keep ${god_foe} occupied while ${god_ally} recovers.
								You move in and engage ${god_foe} in order to give ${god_ally} time to recover from the blow ${god_he} has been dealt.

								You quickly realize the caliber of opponent you are dealing with when ${god_foe} nearly decapitates you with ${foe_his}
								*if god_foe = "Hawk"
									gleaming sword.
								*if god_foe = "Bear"
									vicious clawed hand.
								*comment endif
								Still, you manage to keep ${god_foe} at a distance. You land a few blows and stay ahead of ${foe_his} reprisals. $!{foe_he} begins to grow irritated at ${foe_his} inability to put you down. 

								*if ((combat >= 25) or ((combat + survival) >= 45))
									*goto hawk_bear_defeat
								*else
									*goto ally_is_killed
							*if (meeting_ara) #Ask ${ara_name} to ensnare ${god_foe} in a mystic web.
								${ara_name} is characteristically reluctant to directly involve ${ara_him}self, but the fact that ${god_foe} seems prepared to murder ${ara_him} and everyone else in the room is incentive enough. 

								${ara_name} reaches out with ritualistic might and draws lines of power in the air. $!{ara_he} calls out to ${ara_his} namesake and creates a translucent web by drawing strength from the neglected corners; the cobwebs and the dust. ${god_foe} evades it at first, but the growing web catches ${foe_him} eventually.

								${ara_name} gives a smug grin. 
								*if selfishness >= 66
									*set ara_dies true
									*set friend_kill_count +1
									But ${god_foe} rallies ${foe_his} own power and begins to break through the web. ${ara_name}, the closest to ${foe_him} is overconfident that the ritual will hold and does not dodge as ${god_foe} lurches toward ${ara_him}. 

									${god_foe}'s
									*if god_foe = "Hawk"
										sword slices
									*if god_foe = "Bear"
										clawed hand rakes
									across ${ara_name}'s midsection. The Spider avatar opens ${ara_his} mouth in surprise, but nothing comes out. $!{ara_he} collapses, still clutching the surprising wound. 

									*goto bloodied_foe
								*else
									The web holds for longer than it has any right to. By the time ${god_foe} breaks through, ${foe_he} is visibly exhausted and frustrated with this new turn of events. 

									*goto group_fight_chain
							#Watch what happens without intervening.
								*if god_ally = "hawk"
									*set hawk_dies true
								*if god_ally = "bear"
									*set bear_dies true
								${god_ally} is vicious and angry. $!{god_he} keeps coming, throwing ${god_him}self against ${god_foe}, trying to break through ${foe_his} defenses.

								Finally, ${god_he} manages to catch ${god_foe} off-guard. ${god_ally} folds ${god_his} left hand in a series of intricate gestures, and at the end there is the smell of ozone and fresh-turned soil: A spike of hardened earth shoots up from the ground and impales ${god_foe} in the side. $!{god_foe} cries out, but is not staggered; ${foe_he} lashes out with
								*if god_foe = "Hawk"
									her blade, shining like moonlight
								*if god_foe = "Bear"
									his hand, transformed into a grizzled claw
								and swipes across ${god_ally}'s throat.

								${god_ally}'s eyes go wide with the surprise of the injury. $!{god_he} holds ${god_his} hand up to the wound and then looks at the blood spilling fast. $!{god_he} looks at you, quizzically, as if to ask what this means, and then ${god_he} falls to the ground. 
								
								*comment if anyone dies, we funnel to this case. 
								*label bloodied_foe
								*page_break
								${god_foe} stands before you, hands bloodied. 

								"So it comes to this. You and I, as if this was some cosmic joke." $!{foe_he} smiles. "Let us dance, ${prenom}. Just you and I."

								${god_foe} comes at you with eyes narrowed. There is no time for cleverness or craft, only raw power will save you, so you gather what you can. You lash out with all your strength and ${god_foe} does the same. The sum of so much concentrated strength knocks the both of you backward and sends you tumbling to the ground.

								*if ((ritual >= 25) or (combat >= 25))
									*label god_foe_dies
									*if god_foe = "Hawk"
										*set hawk_dies true
									*if god_foe = "Bear"
										*set bear_dies true
									*if pacifism
										*set pacifism_broken true
									There is a moment when you are sure you have reached the end of your travels. The pain you feel seems endless and you cannot bring yourself to stand for some time. Eventually, you begin to test your limbs—one by one. You stand when you are fairly sure that you will not collapse. 

									You are alive, though ${god_foe} is not. $!{foe_he} is still and you can no longer feel ${foe_his} divine presence. $!{foe_his} human shell has been hollowed out. 

									*if ((bear_dies) and (hawk_dies))
										*goto gods_killed_end
									*else
										*goto hawk_bear_ally
								*else
									*label losing_to_hawk_bear
									You lie there for a time, trying to take in labored breaths. There's pain webbing through your chest and you are afraid to look down. When you do, the wound is worse than you expected. Your breaths are shallower now. 
									
									${god_foe} stands above you. $!{foe_he} is wounded, too, but ${foe_he} will live. You will not. 

									"It was a close thing, ${prenom}. You fought well. You should be proud of that, at least."

									It is not what you want to hear, but the validation relieves some of the terrible pressure in your chest. It encourages you to let go. 

									Eventually you give in to the overwhelming exhaustion, but not before you hear the terrible keening of wolf song through the slowly encroaching darkness. 
									*page_break
									*goto_scene death
							*if (meeting_lyall) #Let Lyall enter the fray.
								*set helper "lyall"
								Lyall throws ${lyall_him}self into the fight and comes into it like a ${lyall_gender} possessed. $!{lyall_he} alternates low and high attacks, keeping ${god_foe} consistently off balance. You offer support, distracting ${god_foe} with the potential of another strong enemy wading into the fight.

								It starts to look like the combined power of two gods and a fierce wolf might overwhelm ${god_foe},
								*if ((lyall_affinity <= 55) and (influence < 3))
									*set lyall_dies true
									*set meeting_lyall false
									*set friend_kill_count +1
									but Lyall makes a misstep and ${god_foe} launches straight into the opening. $!{foe_he} slams so hard against Lyall that it rattles the warrior's entire frame. There is nothing natural about the blow and before ${lyall_he} even hits the ground, you can tell that it is over. 

									The fight does not even leave a moment to mourn before you are forced to reenter the fight or risk losing your own life. 

									*goto bloodied_foe
								*else
									so you keep up the pressure—Lyall hurling ${lyall_him}self at ${god_foe} relentlessly, you keeping ${foe_him} distracted, and ${god_ally} battering ${foe_him} with divinity-infused strikes. 

									*goto group_fight_chain
					*else

						The goddess sighs. 

						"No." She looks genuinely remorseful. "I have tried to hold the world together by any means. That was hubris. My course is set, ${prenom}, and there can be no deviation until all my children are safe, or they are all dead."

						*goto denied
				*else
					Hawk shakes her head. 

					"Our brother is right, ${prenom}. And I am sorry about that." Hawk's hand tightens around the pommel of her sword.

					*label denied
					You prepare yourself. It seems the discussion is officially over.

					*goto gods_brawl
			#Get Bear to betray Hawk. Tell him her quickness to judgment endangers everything.
				"Brother Bear," you begin. "You could not have known how things would unfold in the wake of Wolf's death. But they are more desperate now than they ever were before. Hawk has made this mess, but you and I will fix it."

				Hawk's nostrils flare with indignation. 

				"Spare no thought to ${his} idiocy, brother. We should slit ${his} throat," she says. 

				Bear gives Hawk a withering look. 

				"You would spill more blood, sister? Without even hearing ${him} out?"

				"And give ${him} a chance to spill more of this bile?" Hawk replies. "I do not think so. $!{his} motive is obvious: split us up, prey on the weaker."


				"Think about it, Bear. Hawk considers herself righteous. She desires an uncontested rule. That is why she wants me dead," you explain.

				Hawk takes a step toward you, her foot sliding noiselessly on the air. "Careful, human. You are playing a very dangerous game."

				*if (((influence >= 3) or (pantheon_regard >= 7)) or (sensitivity >= 30))
					*set god_ally "Bear"
					*set god_his "his"
					*set god_he "he"
					*set god_him "him"
					*set god_foe "Hawk"
					*set foe_he "she"
					*set foe_him "her"
					*set foe_his "her"
					Bear puts a hand on Hawk's shoulder, which stops her in her tracks. "No."

					Hawk's head whips around and she glares at Bear, who returns her gaze steadily. 

					"No more blood will be shed for this unless it is ours," Bear says. 

					"Brother…" Hawk says, and closes her eyes. When she opens them again, she seems to have made a decision. She pulls her sword free. "I cannot allow Wolf's pet to diminish this pantheon. If you are with ${him}, brother, then you are my enemy."

					Bear's lips curl back into a snarl. 

					"Then let us be enemies, sister."

					*goto hawk_vs_bear
				*else
					Naturally, you expect Bear to support you, but he rounds on you as surely as Hawk does.

					"It was a clever gambit, I admit. Turn us against each other, but your argument lacks…" Bear smiles wide. "…teeth."

					The sibling gods seem to be preparing for battle. Continuing your conversation with them seems unlikely.

					*page_break
					*goto gods_brawl
			#Get them both to abdicate peacefully by convincing them that I am best suited to lead the pantheon.
				"You intend to lead us?" Hawk asks. Clearly the idea had never even occurred to her. "Ludicrous."

				*if meeting_lyall
					Hawk smiles sardonically. "And I think your friend agrees with me."

					*gosub lyall_betrayal

				*if lyall_speaks_out
					*page_break
					After Lyall is dealt with, Hawk raises a sardonic eyebrow. "Even your own turn against you, yet you would lead us?"

					*if meeting_lyall
						"Temporarily," Lyall adds, somewhat abashed.
				*comment endif

				Bear shakes his hoary head. "You cannot lead us, ${prenom}. You are far from qualified."

				*if ((bear_affinity >= 60) or (hawk_affinity >= 60))
					You put your hands together, fingers splayed open in a sign of openness and transparency, then you begin to plead your case: "You cannot return to head of this pantheon. Not after what you both have done. And who else would lead? Gazelle, in all her tenderness? Eel, with his self-indulgent nature? Or Spider, in her infinite machinations?"

					*if meeting_ara
						"I resent that characterization," ${ara_name} says. "True though it may be."
					*comment endif 

					"And you think that is enough to secure a place for yourself at the head of our pantheon?" Hawk asks incredulously.

					*if (((influence + chaos_score) >= 4) or ((pantheon_regard + influence) >= 8))
						*set pantheon_lead "you"
						*check_achievements
						*if not(choice_achieved_alpha)
							*achieve alpha
						"This conflict raging with the Rising Sun will be the end of the faith as we know it. We can adapt, or we can die out," you explain. 

						*if meeting_sen
							Hawk looks over to Sen. "And you? Do you think this is true? That our abdication will help ensure a peace between our respective believers?"

							"I think we have tried other means. We have few bloodless options remaining to us," Sen replies.
						*comment endif

						The elder gods take some time to digest this. Bear is naturally the first to see reason. 

						"We cannot fight our way out of this, Sister Hawk. All over, there is discord and strife. As much as we have fought against it, we have also contributed to it. I think it is past time we did something selfless," Bear says. 

						*if meeting_lyall
							"Pity you decide on magnanimity after you slew our god," Lyall says viciously.

							The other gods spare ${lyall_him} only a look before returning their attention to you.
						*comment endif

						"I do not have faith that you will do better than we did, ${prenom}, but a lack of faith did not save us before. I would be foolish to expect a different result now. And let us be clear: You will be neither a god, nor our leader. However, we will respect your wishes, if they do not directly contravene our own. I trust that is fair."

						Even if you wanted absolute power, it would come at the cost of slaying every god in the pantheon. This is more than you could have hoped for in the early days without Wolf, and it is a generous offer even now. You accept. 

						"Then there is nothing further to say. We will leave this world to your stewardship, ${prenom}. I trust you will leave this world better than you found it," Bear says. 

						Both Hawk and Bear begin a ritual that wraps them in a brutal, wondrous light. When it clears, they are gone as quickly and quietly as they had come. 

						*page_break
						*goto peaceful_end
					*else
						*goto abdicate_fail
				*else
					*label abdicate_fail
					"I am sorry," Bear adds. "We cannot allow you to take control of this world and risk continuing down Wolf's reckless path. We have been the protectors of the world for longer than you have been alive. We cannot abandon that post because you have dreams of grandeur."

					Hawk draws her sword and whatever ideas you had about a peaceful abdication evaporate.

					"Enough talk," Hawk says. "Will you fight for your beliefs, ${prenom}, or would you prefer die on your knees?"

					*goto gods_brawl
			#Kill them both if they will not relent.
				"Brother Bear, Sister Hawk," you begin. "The world is no longer yours. It has moved on."

				Bear shakes his head slowly. "Perhaps that is the case, ${prenom}, but I can promise you that it will never be yours."

				Hawk grunts her assent and prepares for battle. 

				You smile. It was always going to end this way, was it not?

				*goto gods_brawl
	#Eliminate the pantheon, by any means.
		*comment the ara_turn variable shows whether or not Ara/n is your ally or foe during the fight sequence.
		*set intention "demolish"
		You tell the gods flatly that you believe their time to be over. You tell them to stay out of human affairs, even going so far as to provoke their ire. 

		The gods are quiet for a moment. 

		"And without our stewardship?" Bear asks. 

		You reply that all will finally be well. 

		Hawk gives a braying, unselfconscious laugh. "Unacceptable. It is a burdensome task, but it is given unto us by forces that we do not dare disobey. The fabric of man's fragile existence is predicated on guidance by beings with more wisdom, more—"

		You raise a hand. "You cannot lead. Not any longer. Give them a chance to find their own way."

		Hawk gapes at you as if you have suggested the end of the world, and in some ways you have.

		"If you will not leave this world in peace of your own volition, I will help you along," you explain. 

		*if meeting_lyall
			*gosub lyall_betrayal
	
		*if meeting_ara
			*gosub ara_betrayal

		*label pantheon_destruction 
		*page_break

		Hawk gives you a long, sad look. "I never intended to reign forever. It has always left a foul taste in my mouth, but you…your way is reckless, ${prenom}, and we cannot allow it. I am sorry."

		"Either you will fall or we will, ${prenom}. I see no other way," Bear says. 

		*goto gods_brawl

*label gods_killed_end
*comment both gods are defeated and killed. 
You stand in the center of the room having committed the highest form of blasphemy and
*if hair_choice != "bald head"
	rake your hand through your ${hair_choice}.
	*goto killer_1
*else
	run your hand over your ${hair_choice}. 
	*goto killer_1
*label killer_1
You half-expect a bolt of lightning to split you in two, calling divine retribution down from some other world above, but nothing happens. There is just the silence that stretches. You look around you and the room is not as you know it. The world is not as you know it. Something has dragged you from the comfort of your own mind like a waking dream, and you have no doubt who or what it is. 

*goto summoning

*label gods_defeated_end 
*comment the ending of the fight where the gods are defeated, but survive, having returned to the skies. 
Bear and Hawk are gone, absconded to whatever rabbit hole they have made for themselves in their vast heavens. 
*if intention = "revenge"
	It is no matter to you, ultimately: You have meted out the vengeance you came for in other ways, and they now know you are not a meal they can easily digest.
*if intention = "control"
	They have retreated out of fear and you have wrested control of the natural order from them. You have remade the pantheon in your image, and you doubt that any of the gods will attempt to take that power from you in the near future.
You take a breath, deep and clarifying, and you wonder how long it has been since you could breathe so easily. It is steadying. You take another breath and upon the exhale, it is all frost.

*label summoning
You are no longer standing in the cloying heat of the south. You are nowhere that exists in reality. You have been summoned, and there is only one force remaining that would have the audacity to summon you. 

Wolf.
*finish 

*label peaceful_end
*comment any end that manages to go through without conflict funnels here.

Hawk and Bear have disappeared into the golden light and you are left standing in the middle of the room. You managed to survive the conflict without drawing blood from Hawk or
*if friend_kill_count > 0 
	Bear, but blood stains your hands nonetheless.
	*goto peaceful_end_2
*else
	Bear, and your hands are mercifully clean.
	*goto peaceful_end_2

*label peaceful_end_2

You turn to leave Tumelo's compound but a familiar scent stops you in your tracks: the clean white blankness of ice, and the rank wet fur smell of a predator. It is truly unmistakable. The smell triggers something between a memory and a physical jolt. 

*goto summoning

*label hawk_bear_ally
*comment in the case you fought one or the other god, this is an ending in which whichever one survives and you do as well.

When all is said and done, you stand over ${god_foe}'s still form. You feel something of a sense of things having been set right, though the cost was high.

${god_ally} bends down and puts two fingers to ${god_foe}'s forehead. 

"We were allies, friends even. Closer than any others in this pantheon. This is not how I thought things would end," ${god_ally} says.

You have no comforting words.
*if friend_kill_count >= 1
	You have experienced loss as well.
*comment endif 

Instead, you ask, "What will you do now?"

${god_ally} stands. "I will send ${foe_his} body to the fires under the world to be purified and returned to us in whatever form the great plan dictates. It will be a demanding journey, and it will be some time before ${foe_he} or I see this world again. Keep it safe until then, ${prenom}."

${god_ally} lifts the corpse and slings it over one shoulder.

"I hope I was right to side with you. The stakes are too high to be wrong," ${god_ally} says, and then disappears into a shaft of golden light. 

You think about what you will do as well.

*goto peaceful_end_2


*comment THIS SECTION CONTAINS THE SUBROUTINES FOR "BETRAYAL" SCENES FROM ARA/LYALL/SEN

*label ara_betrayal
${ara_name} taps you lightly on the shoulder. 

*if intention = "demolish"
	"I am terribly sorry to interrupt, but you know that thing about demolishing the entire pantheon? Well, there is just one small problem: That includes me, so I clearly have no intention of seeing that happen."
	*goto ara_betrayal_2
*else
	"This is not exactly how I wanted this all to play out. I thought this would be fun, that you were fun. But I have too much planned for this world to let it crumble in your hands."
	*goto ara_betrayal_2
*label ara_betrayal_2

${ara_name} makes a flourish with ${ara_his} hands. "So we arrive at an impasse."

*if meeting_sen 
	"So the Spider readies ${ara_his} poisonous bite. You are as trustworthy as your namesake," Sen spits. 

	${ara_name} pretends to be visibly abashed by the Riser's statement, but gives up the ruse as soon as ${ara_he} has adopted it. 

	"I am a god and you are a gnat. Less than, actually. Speak to me again in that tone and I will encourage your brain leak out of your ears, Commander."
*comment endif

${ara_name} could be a terrible enemy, especially if ${ara_he} manages to get Hawk and Bear on ${ara_his} side. $!{ara_he} is clearly waiting for some kind of reaction from you, how do you reply?

*choice
	#Appeal to ${ara_name}'s selfish nature and get ${ara_him} to change ${ara_his} mind.
		"No one is going to deliver you a more interesting world than I can," you explain. "Join me, and we will make that world together."

		${ara_name} taps ${ara_his} fingers on the sleeve of ${ara_his} fine shirt. 
		*if ((selfishness > equity) and (ara_affinity >= 65))
			$!{ara_he} sighs loudly. 

			"I should not be so easy to manipulate, you know. But you are right, ${prenom}. Just…do me this one courtesy? When you retell this story, pretend that I put up a better fight?"

			You agree to ${ara_name}'s condition. It seems a small concession for such a powerful ally. So it is that as easily as ${ara_name} has betrayed you, ${ara_he} has returned to your good graces. You would be wise to distrust ${ara_him} and better still to keep a close eye on ${ara_him} going forward.

			${ara_name} turns to Hawk and Bear. "Well? Shall we begin changing the world?"
			*goto post_ara_betrayal
		*else
			Eventually ${ara_he} shakes ${ara_his} head.

			*goto failed_appeal
	#Kill ${ara_name} for betraying me.
		*label ara_fight
		${ara_name}'s eyes light up as you settle into an easy, martial stance. 

		"That is what I love to see, ${prenom}—prepared to fight and die for any offense at any time. You are a monster, surely, but my very favorite kind." ${ara_name} spreads ${ara_his} hands. "Come for me."

		*if ara_peace_refusal
			Reasoning with ${ara_name} is no longer an option, so you attack instead
			*goto ara_fight_2
		*else
			The longer you delay, the more likely it is that Hawk and Bear will interfere, so you do not disappoint: You attack the Spider avatar
			*goto ara_fight_2
		*label ara_fight_2
		*if ((combat >= 20) and ((survival >= 20) or (quickthinking >= 20)))
			in a headlong rush. You throw yourself at ${ara_him} as fast you can. You imagine the less time you give ${ara_him} to prepare ${ara_his} twisted rituals, the better it will go for you. ${ara_name} tries to respond by putting up a barrier of strange, unearthly fire between you, but as the fire sparks and begins to form a shield, you reach through it—ignoring the pain that sears your arm—and put your hand, flat and viper-quick, through the Spider avatar's chest.
			*goto ara_bites_it
		*elseif ((ritual >= 20) and ((sensitivity >= 20) or (survival >= 20)))
			with a hastily prepared ritual that raises the ground toward ${ara_him} in jagged spears. $!{ara_he} dances between the sudden protrusions with grace, but is slow to respond to the lightning-fast assault. ${ara_name} claps ${ara_his} hands, and a wreath of strange blue flame begins to surround ${ara_him}. The flame closes in quickly, but you are quicker. A lance of earth twined brutally with the luxurious rugs lining Tumelo's floor bursts through the Spider avatar's chest. 

			*label ara_bites_it
			*check_achievements
			*if not(choice_achieved_araslain)
				*achieve araslain
			*set friend_kill_count +1
			*set meeting_ara false
			*set ara_dies true
			*set hawk_affinity %-10
			*set bear_affinity %-10
			${ara_name} stares down at the wound dumbly, as if it were an elaborate prank or a minor inconvenience instead of a killing blow. 

			$!{ara_he} looks at you. "This was my favorite body, ${prenom}. I…I have never been killed by one of us before. I wonder what will…"

			${ara_name} goes still, mouth open as if about to speak. 

			*if meeting_sen
				"Gods…" Sen swears incredulously. 
			*comment endif

			*if meeting_lyall
				Lyall spits at the ground, then whispers. "I pray that the fires below the bottom of the world char your bones and turn them into purified smoke, ${ara_name}."
			*comment endif

			*if ara_peace_refusal
				Hawk and Bear nod their heads gravely in honor of their fallen sibling. You cannot imagine that either of them expected this outcome, but neither are they surprised by it. 

				"You did what had to be done, ${prenom}. There is no shame in it," Bear says. Hawk echoes the sentiment.
				*goto end_scene
			*else
				*set hawk_affinity %-5
				*set bear_affinity %-5
				Hawk and Bear exchange a look, perhaps reconsidering what kind of opponent they are dealing with. Hawk is predictably the first to react. 

				"It took Bear and me many years to decide on Wolf's fate, yet you can decide ${ara_name}'s in an instant. We are really and truly different, ${prenom}." Whatever softness and understanding was evident in her features is now gone.
				*goto end_scene
			*label end_scene
			*page_break
			*goto post_ara_betrayal
		*else
			with a burst of speed that you hope ${ara_he} does not see coming. You manage to catch ${ara_him} off-guard, but that does not last long. ${ara_name} begins a ritual that spreads a barrier of pure, blue flame between you. You are already so close to ${ara_him} that even as you turn away, try to escape the sudden fire, it catches you and pulls you in. You catch fire and the pain is exquisite. You drop to your knees and ${ara_name} stands above you with ${ara_his} hands stretched toward you like an icon of some gentler god.

			You see through the haze of heat and the greasy smoke coming off of your own body, and ${ara_name}'s face seems warped and inhuman. "Fitting," you think. 

			It is one of the last things you ever think before the darkness closes in and you hear what sounds like a wolf's chuffing laughter in your ear. 
			*page_break
			*goto_scene death
	#Express my disappointment in this turn of events, but accept ${ara_his} choice. 
		"I thought you were made of better stuff," you say. "But I cannot blame you for being true to your nature."

		${ara_name} shrugs. 

		*label failed_appeal
		*set ara_turn true
		*set meeting_ara false
		"Sorry? What else should I say? As you say, you know what I am, ${prenom}. Sentiment and misguided loyalty are not enough to sway me. I follow…if not my conscience, then my whims, and they do not lead me toward your desired end. Maybe in the next life?"

		You square your shoulders and reevaluate ${ara_name}, as a potential enemy this time. 

		"Maybe in the next life," you echo.

		*if ara_peace_refusal
			${ara_name} turns to Hawk and Bear. "And you? You will accept a fragile peace with ${man_woman} who could tear everything apart at a moment's notice? You are as foolish as always."

			${ara_name}'s words do not seem to stir the other gods to action, which infuriates the spider. 

			"Fine. If no one will join me, then I will do it myself. Come, ${prenom}, I came here to be entertained and I will not be disappointed."

			*goto ara_fight
		*else
			*goto post_ara_betrayal

*label post_ara_betrayal
*return

*label lyall_betrayal
*set lyall_speaks_out true
Lyall steps in front of you, ${lyall_his} face twisted into a snarl. Lyall does not give off a friendly, warm aura at the best of times, but now ${lyall_he} is completely incensed. 

*if intention = "peaceful"
	"This is the reason you came here? To equivocate and grovel for scraps? These so-called gods are not worthy of their throne. It is our duty to rip them from it," ${lyall_he} says, ${lyall_his} voice rising steadily.
*comment endif
*if intention = "demolish"
	"You think you can just tear the faith apart? Are you mad, ${prenom}?"
*comment endif

*if meeting_ara
	"And so the dog shows ${lyall_his} mangy paws," ${ara_name} says, laughing. "Typical."

	Lyall replies without looking over at ${ara_him}. "Careful, Spider, or you could easily be next."
	*goto handling_lyall
*elseif ((meeting_ara) and (intention = "demolish"))
	"$!{lyall_he} is probably flea-ridden, but ${lyall_he} is not wrong, ${prenom}. Bringing about the end of our pantheon was not high on my list of things to accomplish today."
	*goto handling_lyall
*else
	*goto handling_lyall

*label handling_lyall

It seems unlikely Lyall will back down. Will you relent or attempt to bring the other wolf to heel?

*choice
	#Reason with Lyall. Get ${lyall_him} to understand my position.
		*if ((influence >= 3) or ((sensitivity >= 25) and (quickthinking >= 25))) 
			"I have as much of a stake in this as you do, Lyall. My god has been butchered as well. But who leads the remaining worshipers if we both die here? What does their future look like? Hunted mercilessly to extinction? No. We owe them better than that."

			Lyall sneers. 

			"Better to die than to do nothing. Do you think this is Wolf's will? To make peace and hold hands over His corpse?" Lyall shouts. 

			*if meeting_ara
				"I am not saying I agree with our feral friend, but peace? It seems an overly cautious road to walk," ${ara_name} says. 
			*comment endif

			"Wolf is dead," you answer. "His will need not be ours."

			Lyall looks at Wolf's corpse. A magnificent beast once, now lying still. 

			"We will do it your way, ${prenom}. For the others. But I do not like this plan. I do not agree with it."

			You think about the Wolf clan: Suba, Hemming, and the rest. What would they have done? You do not consider it long. They are not here and you are; your will is what matters now.

			You turn to Hawk and Bear. There is much still to do.

			*goto post_lyall_betrayal
		*elseif lyall_affinity >= 60
			"No," you say. 

			Lyall looks at you askance. "What?"

			"No."

			"${prenom}…" Lyall begins. You cut ${lyall_him} off. 

			"You do not have a vote. I am not asking your forbearance," you say sternly, viciously. 

			Lyall seems desperate to challenge you, but ultimately, ${lyall_he} bites down on ${lyall_his} objections, which leaves you to your remaining qualms with Hawk and Bear.

			*goto post_lyall_betrayal
		*else
			*goto lyall_pre_fight
	#If Lyall will not see reason, then ${lyall_he} must be removed. Permanently.
		*set lyall_intent "kill"
		You crack your knuckles.
		*goto lyall_fight
	#Hurt ${lyall_him} enough to get ${lyall_him} out of the way.
		*label lyall_pre_fight
		*set lyall_intent "disable"
		Before you can utter a word, 
		*label lyall_fight
		Lyall comes at you; ${lyall_he} is all animal strength and rage. You meet ${lyall_his} first blow—an overhand punch aimed at your eyes—and ${lyall_his} second, which comes as a lightning-fast kick to your side. If it was not clear before, then it is clear now that Lyall has been touched by Wolf: ${lyall_he} fights with the strength of ten warriors. But you are not so easily cowed.

		You push back.

		*if (((combat + quickthinking) >= 45) or ((combat + survival) >= 45))
			You target Lyall's weaknesses without mercy. $!{lyall_he} has a tell before ${lyall_he} pivots off ${lyall_his} left foot; ${lyall_his} block is weaker on ${lyall_his} right side. $!{lyall_he} has a blind spot right around ${lyall_his} left shoulder. 

			You use the sum of this information to hammer Lyall over and over, push ${lyall_him} back into unfavorable positions, and ultimately deliver a crushing blow that momentarily stops Lyall's breath and knocks ${lyall_him} to the ground. 

			*label after_lyall_defeat
			You stand over ${lyall_him} and ${lyall_he} does not get up.

			Lyall spits in your direction. It does not reach you, but it sends a message just the same.

			"At least you finally prove yourself capable of holy violence. A shame you directed it at the wrong person. Still, you are formidable, ${prenom}," ${lyall_he} says. "Go on. Do it."

			*if lyall_intent = "kill"
				*set meeting_lyall false
				*set lyall_dies true
				In the last moment, ${lyall_he} turns ${lyall_his} head. You try to make it quick.

				*if meeting_ara
					"As brutal and glorious as I expected of you, ${prenom}," ${ara_name} says, reverence in ${ara_his} voice.
				*comment endif

				*set hawk_affinity %-10
				*set bear_affinity %-10
				Hawk and Bear watch this without comment, but when you turn back toward them, their eyes are somewhat harder than they had been before.
				*goto post_lyall_betrayal
			*else
				*set meeting_lyall false
				*set lyall_fallback true
				You look at Lyall, heavily injured, and prepared to die. 

				"I am not going to kill you. Whatever else you may be, you are like me. No one else understands what we understand. I will not have your blood on my hands."

				Lyall looks up at you, surprised. "A poor choice."

				"I know, but it is mine to make," you reply. 

				*if meeting_ara
					"I would have ended ${lyall_him}," ${ara_name} says. 

					"I know that, too," you say. 
				*comment endif

				*set hawk_affinity %+5
				*set bear_affinity %+5
				Hawk and Bear watch you with open curiosity, but neither says a word.
				*goto post_lyall_betrayal
		*elseif ((ritual + sensitivity) >= 45)
			You turn your intention at Lyall and unleash your frustration. $!{lyall_he} has obstructed you, challenged you, for the last time. You reach into your own reserves of strength and compel the very air to turn against ${lyall_him}. The pressure in the room grows awful, and Lyall is knocked sideways off of ${lyall_his} feet. $!{lyall_he} crashes to the ground and lands badly, lying like a broken thing. 

			*goto after_lyall_defeat
		*else 
			Your counterattack is brutal and quick, but Lyall is fast and brutal, too. The fight starts to turn in Lyall's favor and as hard as you fight, you find yourself losing ground. $!{lyall_he} sweeps your feet out from under you and before you can get up, ${lyall_he} has ${lyall_his} foot pressing into your throat. 

			"I expected more of you, ${prenom}. But even those of us who are blessed with so much sometimes need to be taken down. But do not worry: I will right the wrongs done to Wolf—in his name and in yours."

			You try to roll away, but Lyall's heel comes down on your throat again and again. The pain is blessedly fleeting, and as you struggle to draw increasingly labored breaths, you can hear the cry of a wolf—panicked and desperate. The sound comes from far away, but you follow it, and as you do the world before you goes gray and distant. 
			*page_break
			*goto_scene death
	#Listen to Lyall. After all, Wolf's killers are right in front of me.
		*set restraint %+10
		*set action %+10
		*set deliberation %-10
		Lyall gives you a slow, satisfied smile. $!{lyall_he} turns to Hawk and Bear. "You have proven that gods can die. Let us know how it feels."
		*goto post_lyall_betrayal
*label post_lyall_betrayal
*return

*label sen_betrayal
*set riser_affinity %-15
You hear the clean vibration of a sword clearing a scabbard and in your peripheral vision you catch Sen sliding around your left side. He steps in front of you and holds his weapon out. He stands between you and Hawk and Bear. It is an uncomfortable place for him to be.

*label pre_sen_sort
*if meeting_ara
	"The little zealot shows his stripes," ${ara_name} says. 
*comment endif

Sen doesn't seem interested in what you have to say, but perhaps you should say something. 

*fake_choice
	#"I tried to fight it, but this…is how it was meant to be."
		"I thought it could be different, a new world. As it stands, you will die with the old one," Sen replies.
	#"Wolf demands retribution. I cannot deny him."
		"Fair enough," Sen says. 
	#Say nothing.
		Sen's mouth quirks. 

		"Good. It is better if we do this without words, ${prenom}."
*comment endif

Sen comes at you like a whirlwind of steel. His sword lashes out, draws at least one stinging line across your forearm before you can even think to answer it. 

*if meeting_ara
	You take a step away from Sen to regroup and ${ara_name} steps forward. $!{ara_his} hands curl and form strange shapes. 
	*if ritual >= 20
		It is only because of your ritual training and skill that you can see the faint lines of power forming a web between ${ara_name}'s fingers and Sen.
	${ara_name} has somehow ensnared the soldier, because he stops coming toward you. 

	"Feeble-minded humans," $!{ara_he} says. "Should I kill him? Devour his mind with my working. It would make a good snack."

	*choice
		#Kill him. Eat his mind.
			*goto sen_eaten
		#Incapacitate him. We have a bigger fight on our hands. 
			*set meeting_sen false
			*set sen_fallback true
			${ara_name} frowns. 

			"I thought wolves had harder hearts than that," ${ara_name} says, clearly disappointed. 

			$!{ara_name} yanks ${ara_his} hand back hard and snaps whatever mystical tether keeps Sen bound to ${ara_his} will. The soldier falls to the ground, unconscious.

			*goto post_sen
		#I could not care less.
			*label sen_eaten 
			*set meeting_sen false
			*set sen_dies true
			${ara_name} grins, but Hawk and Bear look on in revulsion as ${ara_name}'s fingers twist unnaturally into a gnarled fist and Sen's eyes roll back into his head. He falls to the ground and his beautiful sword clatters to the ground. 

			You spare his corpse a pitying look. He could have been a great ally. 

			*label post_sen
			Before long, you turn your gaze to Hawk and Bear. 

			"Now it is our time together," you say calmly.

			*page_break
			*goto gods_brawl
*else
	*if (((combat + quickthinking) >= 45) or ((ritual + sensitivity) >= 45))
		*if ritual > combat
			When you gather your wits about you, a subtle anger starts to rise up in your chest. The Riser commander came to you looking for aid and now he has turned against you. 

			You turn that anger into power and feed off of it. You reach out to the quiet, nearly inert-but-not-quite thrum of life in the steel of Sen's weapon. You grab hold of it and pull. 

			Sen goes to thrust his blade, but the weapon pushes back with impossible force. The sudden lurch twists Sen's wrist hard and he shouts in agony. But you do not stop there: You soften the ground underneath him and he falls into it like wet sand. You tighten the floor around him again, trapping him up to his neck. 

			"Let the human be," Hawk says. "You have made your point. And there has already been enough death."

			And will you leave him alive? 

			*choice
				#"I will. He was a comrade, for a time."
					*set meeting_sen false
					*set sen_fallback true
					*set deliberation %+15
					*set action %-15
					*set selfishness %-25
					*set equity %+25
					*if meeting_ara
						The Spider avatar snorts. "I would have sucked the very marrow from his soul. But who am I to counsel the wise wolf?"
					*comment endif 

					*label pre_gods_fight
					You turn your attention to the duo of traitorous gods. You are not even close to being finished with them. 
					*goto gods_brawl
				#"Why bother? He opposed me, betrayed me. He should die."
					*set meeting_sen false
					*set sen_dies true
					*set action %+25
					*set deliberation %-25
					*set selfishness %+10
					*set equity %-10
					*label dead_sen
					You make a fist in your mind and the ground mirrors your will. Sen only releases a sigh as the air is crushed from his chest. His once handsome face goes still, settling into a mask of suffering. 

					*if meeting_ara
						"No mercy. No quarter," ${ara_name} says to you, then looks up at Hawk and Bear. "Worried yet?"
					*comment endif

					*goto pre_gods_fight
				#"I have a fight to win. Killing him ensures he will not hinder my plans further. It makes sense."
					*set meeting_sen false
					*set sen_dies true
					*set action %-10
					*set deliberation %+10
					*set selfishness %+15
					*set equity %-15
					*goto dead_sen
		*else
			You leap back, seeking a moment to think up a counter-attack, but Sen is a practiced soldier and shows no intention of letting up his assault. He cuts to your left and his blade finds air, but it is a close thing. His next slice comes even closer to taking a chunk out of your mid-section.

			Sen is a good swordsman, but it becomes clear before long that he is used to a different class of foe. Once you begin to tap into the unrestrained, savage power in your chest and fight back, Sen starts to stumble. He loses ground, stepping back, his bold attacks turned to defensive, exploratory cuts. 

			You can see the terror growing in his eyes. It thrills a part of you that is very close to the surface now. He tries to run you through and you knock his sword away. The weapon's clatter is muffled by the piled-high pillows and carpets on Tumelo's floor. 

			All but defenseless, Sen's hand moves to his waist, tries to pull a knife from a belt there. 

			You can stop him, but how? 

			*choice
				#Grab him before he gets to the knife and break his arm.
					*set sen_fallback true
					You are already moving as Sen reaches for his knife. You catch his sword-arm as he is in the process of yanking the short steel weapon from its scabbard, and you wrench his arm hard enough that you can feel when his arm dislocates from his shoulder. He screams, naturally, but he is still a soldier. He tries to punch you with his left hand, but you kick in him the stomach and he collapses. 

					As he tries to recover, you take his knife and throw it away.

					*goto ara_reaction
				#Snap his traitor neck. 
					*set meeting_sen false
					*set sen_dies true
					It does not take much to end someone's life. Not as much as is claimed in the valorous old stories. You reach out and grab Sen, hug him close so that his sword arm is trapped between you and he cannot pull free his knife. The embrace is strangely intimate, but perhaps that is fitting for what comes next. 

					You twist. The cords of his neck stand out, he tries to fight, but you are very strong. The crunch sends a vicious thrill through you.

					You allow his body to slump and fall to the ground. 

					"Is this more of what you would bring into this world, ${prenom}?" Hawk asks, looking at Sen's lifeless body. She closes her eyes for a moment, a prayer perhaps. When she opens them again, she seems resolute. "You may be as much of plague as your patron god."

					*if meeting_ara
						"If 
						*if gender != "none"
							${he} bathes
						*if gender = "none"
							${he} bathe
						the world in blood, then it will be the more interesting for it," ${ara_name} says.

						"You have become monstrous, Spider," Bear opines. 

						"More than any of us, I have been true to my nature, Brother Bear," the Spider avatar says with a grin. 
					*comment endif

					You do not answer Hawk's accusation. It is past time that your business with Hawk and Bear was settled.

					*goto post_sen_fight
				#Break his leg. That should be enough to keep him down awhile. 
					*set sen_fallback true
					Sen goes for his knife. He's skilled, so he keeps an eye on you, but he is not prepared for the burst of overwhelming speed that carries you inside his guard. You deliver a solid kick to his left knee and he howls when the joint shifts to an unnatural angle. He collapses backward, slashing with his newly freed weapon, but you have already stepped back and out of the knife's arc.

					*label ara_reaction

					"Stay down," you suggest. 

					It seems for a moment that he intends to keep fighting, but he must see something in your expression, and the fire in his eyes gutters somewhat. 

					*if meeting_ara
						${ara_name} laughs down at Sen. "I have seen more glorious fights. That is certain."

						Sen looses a torrent of curses, which just delights ${ara_name} further.

						"${prenom} is right: Stay down, little mouse, if you know what is best. There are gods among you." ${ara_name} turns toward the other gods, watching you closely. 
					*comment endif 

					You leave Sen to swear and promise retribution, or whatever he intends to do while he nurses his wounds.

					*goto post_sen_fight
				#Punch him hard enough to put him down for a bit.
					*set sen_fallback true
					He reaches for the knife, but his motions are slow enough for you to intervene. He is only just human, after all. 

					You land a hard, vicious strike to his face and feel Sen's head snap back with the force of it. He goes down so quickly that you have a split second concern that you might have killed him, but if you listen closely, your preternatural senses can pick up the slow and steady beat of his heart.

					*if meeting_ara
						"That was underwhelming," ${ara_name} says. $!{ara_he} shakes ${ara_his} head. "I would have at least broken a bone or two."
					*comment endif

					*label post_sen_fight
					With Sen out of the way, you can focus on the other gods. You crack your knuckles and take a step toward Hawk and Bear. 

					*goto post_sen_betrayal
	*else
		You fight back like an animal backed into a corner. You lash out with punches, kicks, and brutal swipes of your hand curled into a desperate claw. 

		You slowly gain ground, pushing Sen back and further back until he seems to be tiring. You catch it too late: the slow-growing smile. Sen is playing with you, drawing you into a false sense of confidence. You try to back away, but he has no intention of letting you go. He rushes forward, his footwork deft and practiced. His blade is colder than you would think as it slides into you. 

		The pain is exquisite, but the surprise of it is more off-putting.

		"I wanted you to be a savior," he whispers, as he pushes the sword in further and twists it. "Forgive me, ${prenom}. The world needs fewer monsters, not more."

		You are vaguely aware that you are losing blood quickly. You are dying and it feels like it is happening to someone else. 

		Sen pulls his blade back and out. You slump forward, holding the wound and looking around the room. 

		*if meeting_ara
			"${prenom}…this is not the end I dreamed of." ${ara_name} looks perplexed. $!{ara_his} voice seems to come from far away.
		*comment endif

		"All things considered, this is a better conclusion for this story," Hawk says. She remains imperious and chilly until your last shaking breath. 

		Somewhere in the dark, as oblivion rushes over you like ice water, you hear a wolf's howling, and it is like the words of a song you almost remember.
		*page_break
		*goto_scene death

*label post_sen_betrayal
*return

*label physical_conflict_help
"Deal with him," you shout. 

*if meeting_lyall
	*set self_score %+5
	"Easy enough, ${prenom}. I only need to know how much of his face I should leave intact," Lyall replies. 

	True to ${lyall_his} word, ${lyall_he} attacks with unrestrained ferocity. $!{lyall_he} throws ${lyall_him}self at Bear, and the ursine god is immediately consumed with the effort of keeping Lyall's fingers out of the fleshy bits of his face and throat. 
*comment endif

*if meeting_ara
	*set self_score %+5
	"Please, as if you have to tell me," says the Spider avatar. $!{ara_he} raises both hands and locks ${ara_his} fingers in a pattern.
	*if meeting_lyall
		$!{ara_he} issues a clipped warning to Lyall, who backs off quickly.
	*comment endif

	Soon Bear is surrounded by a widening net of moisture that expands and slows down his every step.

	*if meeting_sen
		*set self_score %+5
		"Impressive, though I prefer the honesty of steel to sorcery," Sen says. He leaves Bear to ${ara_name} and joins you to fight off Hawk. 
*comment endif
*return

*comment END THE SUBROUTINE SECTION!
