*text_image chap_8.png center Eight: Thirst and Drowning Both

[i]"Who are you?" the gods asked.[/i]

[i]"I am Be Reham. Warrior. Unbloodied."[/i]

[i]Children's laughter tinkled throughout the dark space. Be Reham was unnerved. It was a strange feeling for the warlord.[/i]

[i]"That is who you were. Now. Let us tell you who you are."[/i]
*line_break
-excerpt from "Tales of the Old Gods"
*page_break

The roads north out of the marshes are neglected. The caravans provide the major trade between the north and south, but the growing uncertainty of tensions with the Rising Sun have kept the caravans revolving closer to home and the Quiet are not well-known for their engineering skills—even if they did have the desire to maintain the roads. The Quiet are more particular to the waterways that crisscross the great landmass that the three great clans begrudgingly share. There are rumors that they sail even further out into the calamitous sea, but as far as you know those are only just rumors. 

You are grateful there are roads at all. 

*if riser_supplies
	The first day is made easier by the supplies you took from the Rising Sun. You would not like to imagine how difficult it would be without them.
	*goto supplies_o_no
*else
	The first day suggests your travels will be a struggle. You spend hours foraging for food. Although you try to conserve your meager supply, your stomach seems to have other plans.
	*goto supplies_o_no

*label supplies_o_no
You catch sight of signs of storm on the second day: the heavy air; the stillness of the wind; and clouds beaten into wisps. You estimate a few hours before the weather changes. You could try to make some headway before the storm reaches you. You could stop and find a secure location before the weather turns. Or you could try to change your course and attempt to avoid the storm entirely. 

*fake_choice
	#Forge ahead. Make camp later.
		You are confident there is enough time to make it a bit further before the storm hits. The cracked, overgrown roads hamper your momentum, but the further you get away from the Quiet, the better, and presumably more well-traveled, the roads get. 

		You spend a few more hours on the road before finding a relatively safe space to pass the rest of the evening and wait out the storm. 
	#Take extra time to secure my location.
		It makes more sense to stop and find shelter immediately. You would prefer to find high ground, in case of flooding, but even though you are a day out from the thick of the marsh, the land is still low. You find a clearing instead where the risk of being struck by downed trees is minimal. It is the best you can do at the moment. 
	#Take a detour. Try to avoid the storm.
		You have a general sense of the direction the storm is advancing from, which is enough to attempt to avoid it. You take a detour off the road, which takes you into the wildlife, but you have no fear of common predators. After a few hours moving east, you subtly change your bearings and begin to head north again. Hopefully, you have moved out of the direct course of the storm and have avoided the worst of it. You find a space to ride out the storm and wait. 

*page_break
The first flash of lightning wakes you. You cannot really recall falling asleep, but you are certainly awake now. The sky turns white again and then the rain, hard and relentless, begins. Another flash of lightning and this time, thunder accompanies it. The massive boom shakes you to your toes and makes you feel small in comparison.

Your senses are a mess. You can hardly smell through the rain, and all you can see is the dark until the lightning intermittently burns the sky. 

The thunder cracks again, but this time you hear something inside of it. A shout. You see lightning, and then in the fading light, you see shadows leftover.

There is deep ritual at work here. Something beyond the mortal ken.

A burst of lightning touches down near your camp, and a white fire blooms in defiance of the rain. You can see shapes moving in the roaring flame and hear voices:

*if prophecy_received
	"…did as I was asked. I put the Wolf avatar on the path…" The voice is gentle, but firm. It conjures memories of fields and wind that are not your own. Gazelle herself, you assume.
	*goto post_prophecy
*else
	"…spun my web for the Wolf avatar, set ${him} running toward them, as promised…" The voice is confident and cool. The Spider, undoubtedly.
	*goto post_prophecy

*label post_prophecy

The other voices are less familiar. They fade in and out as the fire shifts and the rain beats down. Another flash of lightning splits the sky, and you can finally see them clearly.

*page_break
Each of the five gods, save Wolf, is emblazoned on the sky: They sit around a massive table but themselves are no bigger than children. Hawk sits at the head of the table, her feet protruding from her over-sized seat and her hair is all feathers; Bear has his hairy arms folded and scowls; Spider is slender and beautiful, but when she opens her mouth, it is full of horrors; Gazelle's head has the sleek shape of an antelope; Eel is slumped in his enormous chair, kicking his legs gleefully as water streams down his dark body.

"Wolf's avatar is the element for which there is no accounting. Yet we have done what we can. We have endeavored to place ${him} in circumstances where ${his} judgment would be keenly tested," Hawk says. 

"The results have been interesting," Spider replies. Something slithers beneath her skin. 

The lightning flashes again and the gods disappear from the sky. You wait for the next flash, knowing instinctively that it will come. When the sky brightens again, the gods are no longer children in this vignette, but animal versions of themselves. Between them is a fresh kill. 

Gazelle begins to speak, but Spider turns and her many eyes see in your direction. Her face, such that it is, erupts into a grotesque mimicry of a smile. 

"We have a guest."
*page_break 
This is not the first time you have sat at the Court of the Gods. The occasions were always rare and unexpected, but at least when Wolf rode your skin, these divine meetings were less disjointed and disorienting. Even the gods themselves express a measure of surprise that you can see them through the flashes of lightning and the roar of thunder.

The others face you after Spider's comment. Their expressions are unreadable for the most part, set in their animal faces, but none of them seems to have expected you. 

"Well-met, ${prenom}, avatar of our Brother-Wolf," Bear says. 

The others follow with some greeting of their own, but your mind circles around something that
*if prophecy_received
	Gazelle
	*goto post_prophecy_2
*else
	Spider
	*goto post_prophecy_2
*label post_prophecy_2
said earlier, and then Hawk seemed to confirm. It was the machinations of these gods that led you—directly, indirectly, or more likely, some combination of both—to this point. The idea of being led on a merry chase by the gods while you searched for news of one of their own has a deep impact on you.

You feel:

*fake_choice
	#Empathetic: Without Wolf at my side, there was no way for the gods to know how I would react. As a holder of divine power, even now, I represented a potential threat. I would have done the same.
		*set godly_attitude "empathetic"
		You can understand why the gods would watch you so closely, though you do not necessarily approve of the lengths they have gone to in order to do so. You do not intend to exacerbate their fear, but your best intentions might not be enough.
	#Indignant: They have monitored and directed, but they have not been forthcoming. Their meddling has no end and serves no end besides their own.
		*set godly_attitude "indignant"
		You are understandably frustrated by the way the gods have interfered in your mission and your life. They have been involved since the start it seems, with little or no intention of transparency. This is enough to make them suspect. 
	#Wrathful: I am one of their own, even without Wolf's direct guidance. I represent his interests, his instincts. Their actions represent a betrayal, and I deserve satisfaction.
		*set godly_attitude "wrathful"
		You are Wolf's living totem. No other can claim that honor. Since childhood you have made his priorities your own, his hungers your own, and you are now indistinguishable from his will. The gods have trespassed against you, and they have therefore trespassed against Wolf. Their meddling will be paid for, you decide in the driving rain. 
	#Amused: The gods have gone to such comical lengths to move me around like a piece in some grand game. They know I am dangerous, and so why not? They are not wrong.
		*set godly_attitude "amused"
		The snares that the gods have set out have tangled you up and thrown you in their path, but you doubt they fully understand what they have caught. You are unconcerned about their games, and why should you be when they have proven themselves so sheepish by playing them to begin with? 

You put your feelings aside and allow the gods to continue their meeting. As they speak, their voices grow clearer and you are more able to parse their shapes through the flashes of light, though the images before you change, seemingly at random. Now they are clouds in the shape of men, then they are wisps of smoke formed into hulking shapes. 

"${prenom}." Gazelle's voice is light and mothering. "You are in an unenviable position to be without your god. We also know this pain, as we were once taken from the cool embrace of our forebears in the endless waters and thrown into the height of the sky. We regret that you have come unmoored from our love.
*if death_toll >= 10
	However, I am saddened by the blood you have spilled.
	*if village_state = 4
		Entire families have fallen to your appetite.
	*if bear_fate = "dead"
		Even the blood of one our brother Bear's avatar is on your hands.
	*label violence_query
	Do you feel no tug of conscience? Have we failed so badly to impart some sense of the worth of living things?"

	*choice
		#"It weighs on me, mother Gazelle, but I cannot go and retrieve the lives I have taken."
			*set deliberation %+5
			*set action %-5
			Gazelle bows her head respectfully. 

			"You are correct about that. Perhaps you will be more cautious to avoid further bloodying your hands in the future?"
			*goto qna_2
		#"My choices, though sometimes violent, were in service of a greater good."
			*set equity %+5
			*set selfishness %-5
			Gazelle exchanges a look with Hawk, then graces you with a small, sad smile. 

			"You sound like one of our sister's zealots. Always assured of the righteousness of their actions through the safekeeping of the larger whole. But what future does blood bring but more blood?"

			She never answers her own question.
			*goto qna_2
		#"Why lament old blood already spilled? Wolves don't cry over the bones of prey."
			*set action %+5
			*set deliberation %-5
			"I see, Wolf-kin. Thank you for your honesty."

			Gazelle turns away from you, and a small part of you aches despite yourself.
			*goto qna_2
		#"Cry for me, mother Gazelle, for I shed blood, not tears."
			*set selfishness %+5
			*set equity %-5

			"I cry for all children who are lost, Wolf-kin."

			Her voice is still soft, but there's a new hardness in the way she looks at you. 
			*goto qna_2
*else
	*set survival +5
	*set restraint %+15
	*set pantheon_regard +1
	Yet you managed to avoid most senseless bloodshed. You are one of our sacred children, ${prenom}. Do not forget."

	Gazelle's gentle voice fills you with warmth and purpose. You feel more hale and hardy than you have in all your days. 

	*goto qna_2
	
*label qna_2

Gazelle gives you a last, lingering look. "Be cautious, ${prenom}. The closer you lie to the bloodied ground, the harder it will be to stand again. Restrain yourself, or you will become lost to the thrill you seek."

As Gazelle grows silent, Eel comes to the fore. His eyes are as dark as the grave.

"Beloved Sibling-Wolf. Fellow child of appetite, of life's perpetual lust, we understand each other, do we not?
*if ((lyall_romance = "sleptwith") or (ghazal_romance = true))
	*set eel_affinity %+25
	*set ritual +5
	You have spent time savoring the warmth of another and you radiate that warmth, even now. We things of the depths appreciate such warmth more than others, I think. This is true, I think. Is it not so, Wolf-kin? Is it not?"

	"Such things must be rewarded. I have a boon for you, a small thing, but from one higher being to another, a gift should never be taken lightly."

	Your mouth fills with the taste of seawater. Your instinct is to spit it out, but you drink it down instead. The fire of it fills your belly and you suddenly understand something of Eel's nature, something sweet and ritualistically powerful, but half-rotten. 
	*goto qna_3
*else
	*set eel_affinity %-15
	Yet you have refrained from the delectation of flesh, smooth or rough, and your chastity offends. Can you understand the worth of man if you remove yourself from its rewards? I doubt it. I doubt it very much. How do you plead, beast-of-gods?" 

	*choice
		#"My romantic life is none of your concern, Eel."
			*set eel_affinity %-5
			"No?" Eel asks, his dark eyes bore into you. 

			"Yes. Maybe. Maybe not." It feels like the equivalent of a shoulder shrug. "There are connections invisible even to the keen eye. A platter of fruit and the wolf chooses the sword. Meaningful."
			*goto qna_3
		#"Companionship is not the only inherent pleasure."
			*set eel_affinity %+10
			"Wisdom from the wolf-child. Seek comfort, indulgence, pleasure—where and when you find them. All other terrestrial mysteries are bound to disappoint."
			*goto qna_3
		#"Do I misread you or are you offering your own flesh for sampling?"
			*set eel_affinity %+15
			Eel's laugh is like seaweed being dragged over sand.

			"I wonder if you would survive my affections. Hmmm…" Eel's voice takes on the quality of glass being ground. "I could show you wondrous things, Wolf-kin. Horrible things, too."

			"Eel, you forget yourself," Hawk interjects. 

			"Oh? Oh."
			*goto qna_3
		#"I fail to see how this bears on my actions as the avatar of Wolf."
			*set eel_affinity %-10
			"It probably does not. Forgive the question. But you should know, Wolf-kin, that your actions paint a tapestry for all to see, those that can see, anyway."
			*goto qna_3

*label qna_3

The final voice to rise above the din of lightning, rain, and storm is Hawk's own. She is calm and judicious, if there is passion behind her deep, thoughtful voice. Then it is hidden from you. 

"You have come far to search for word of our brother, Wolf. Do you intend to return him to this pantheon if and when you find him?"

The other gods go silent. Even the rain and wind settle. Eel's dark eyes slide in his large, broad face and one of them watches you while the other watches Hawk. Spider is reclined in a luxurious bed of webs, but you can see the perfect tension she keeps ready in all of her many limbs. Bear closes his eyes and leans slightly forward. Gazelle is perfectly still. It is as if she has become a living statue in perfect likeness. 

What are your intentions regarding Wolf?

*choice
	#"Yes. I intend to find him and return him to his rightful place in the pantheon."
		*set action %+5
		*set deliberation %-5
		*set equity %+15
		*set selfishness %-15
		*set hawk_affinity %-10
		*set bear_affinity %+5
		*set ara_affinity %-10
		"I find this talk about rightful places distasteful. What we deserve is what we earn, through our own cleverness and guile. Anything else is someone else's to take," Spider says. 

		"The world is all but on fire and you still find time to serve yourself. Your flights of fancy are wearying, sister." Bear's massive frame and quiet demeanor barely mask the sudden potential violence in him.

		"Turmoil makes us all selfish," Spider says, in reply.
		*goto qna_over
	#"Whether or not Wolf returns to the pantheon is not my concern. I merely wish to find him, and if necessary, avenge him."
		*set equity %+10
		*set selfishness %-10
		*set action %+10
		*set deliberation %-10
		*set hawk_affinity %-10
		*set bear_affinity %-10
		*set ara_affinity %-5
		"Vengeance. Ever a noble goal," Bear says, his tone fairly dripping with scorn.

		"But not without merit. One of our own has gone silent, Brother-Bear. Should we go on forever without answers? Without satisfaction?" Eel asks. He sounds merry, but his body is coiled tightly.

		"Why concern ourselves with revenge? If someone indeed has found the way to slaughter gods, then we have bigger problems. As for myself, I welcome the chance to fight for my life. If I win, I have triumphed against death itself. And if I lose? Then I get to try on oblivion. Is there eternal penance for us, I wonder?" Spider shrugs her many legs one at a time.
		*goto qna_over
	#"I have no interest in returning Wolf to his previous status. I want my own freedom, and in order to gain that, I must know if I am truly free of him."
		*set action %+10
		*set deliberation %-10
		*set selfishness %+5
		*set equity %-5
		*set hawk_affinity %+20
		*set bear_affinity %+20
		*set ara_affinity %-10
		Spider is the first to speak up. "It's an illusion, freedom. As high as you rise, there are always strings moving us from one moment to the next. Circumstance or predestination, does the title matter when the result is the same? I applaud your desire for control, but you will be disappointed in the end, ${prenom}. I promise you that."

		"You are too jaded, sister," Eel says, then turns to you. "I understand the impulse-well, all impulses really, but this one specifically. You want to be outside of the influence of the god that governs you, that whips your skin into a frenzy. I think the real question is what you would do with this new autonomy. Would you be merciful or terrible? If for nothing else but satisfying my curiosity, I hope you stay free of Wolf, ${prenom}."

		"You have a rare chance to be both elevated by our brother's influence and free of it. I hope in the end that you do not squander this unique opportunity," Gazelle says tenderly. 
		*goto qna_over
	#"I am faithful to Wolf. He is my god and whatever he desires, once I find him, I will honor."
		*set deliberation %+10
		*set action %-10
		*set equity %+5
		*set selfishness %-10
		*set hawk_affinity %+10
		*set bear_affinity %+10
		*set ara_affinity %-15
		"It is good to see such loyalty in our brother's subject, but I wonder if your humanity has no stake in your decisions. Are you merely an extension of our brother's will?" Hawk asks. 

		"$!{he} could hardly be more. But neither would any animal chained to another for so long. The fact that 
		*if gender != "none"
			${he} has
		*if gender = "none"
			${he} have
		gotten so far without direct guidance is a wonder," Spider says, insulting you offhand. 

		"${prenom} only wishes to be useful. There are worse impulses," Bear replies.
		*goto qna_over
	#"Wolf and I have always been one. Without him I am not whole, and I want to be whole once more."
		*set selfishness %+5
		*set action %+5
		*set deliberation %-5
		*set equity %-5
		*set ara_affinity %+5
		*set eel_affinity %-5
		*set bear_affinity %+5
		*set hawk_affinity %-5
		"I recognize that you are in an unfortunate position, Wolf-kin, to be without your god. I have much empathy for you. But there are considerations that we must make as a collective, which cannot be understood by your limited perspective. We must consider more than repairing your connection to Wolf. We must protect the whole."

		"Our sister means to say that you are not a priority, ${prenom}. She cares not for your troubles, only that you have the potential to cause chaos," Spider says.

		"A predictably narrow view from the selfish Spider," Bear says, his tone admonishing.

		"And how would you put it, O loyal, O faithful, Brother-Bear?" Eel says. He can hardly keep from chuckling.
		*goto qna_over
	#"The world is more interesting with Wolf in it, so restoring him is worthwhile. That is all."
		*set selfishness %+15
		*set action %+15
		*set deliberation %-15
		*set equity %-15
		*set ara_affinity %+15
		*set hawk_affinity %-15
		*set bear_affinity %-15
		"Poorly considered, Wolf-kin," Hawk says quietly. 

		Spider, on the other hand, overflows with laughter. Her many eyes are bright with amusement. "I heartily disagree, sister. Our brother has chosen a most delicious apprentice in this one. Who else could so embody disruption and whimsy? Oh, how I wish you were one of mine. Perhaps, it is not too late, eh? Would you proudly wear my silk chain, ${prenom}? Would you let me enter your mind and dominate you?"

		"Sister. The very insinuation is obscene," Gazelle says sharply. It is the closest you have heard her come to anger. 

		Spider settles back into her web, still tittering. "Of course you are right, sister. I meant no harm."

		"Sometimes I think all you mean is harm, sister," Eel says, but you can tell by his tone that he approves of her ribaldry. 

		*goto qna_over
	#"Why would I return Wolf to a broken pantheon? I wish to end the sway you all hold over the mortal world, not extend it."
		*set chaos_score +1
		*check_achievements
		*if not(choice_achieved_chaosagent)
			*achieve chaosagent
		*set action %+10
		*set deliberation %-10
		*set selfishness %+10
		*set equity %-10
		*set hawk_affinity %-15
		*set bear_affinity %-15
		*set ara_affinity %-5
		*set eel_affinity %-5
		"Your wish, human…" Hawk says the word with a strange wistfulness. "…is beyond impossible. We did not shape the stars and paint the heavens only to abandon the world."

		"And what independence could humanity assert without eventually falling to war and strife?" Gazelle asks. 

		"To be fair," Spider begins. "We have not exactly prevented war among them."

		Bear grunts, which you suppose is meant to serve as a reply. 

		"But we taught them pleasure, intellect, and we have so much more yet to teach. Would you gamble on man's survival without the lessons taught by our perfect minds?"
		*goto qna_over 
		
*label qna_over 
*if (((enclave_leader = "lyall") or (enclave_leader = "both")) and (riser_affinity < 60))
	*set meeting_lyall true
*if ((riser_affinity >= 60) and (sen_killed = false))
	*set meeting_sen true
*if (((selfishness > equity) and (action > deliberation)) and (ara_affinity >= 65))
	*set meeting_ara true

"Settle down," Hawk insists. The other gods come to heel, mostly. "You must understand, ${prenom}, that we have spent many centuries guiding our charges, and your situation is unique. There is no consensus about you, and that is worrisome.
*if chaos_score >= 2
	*set gods_hinder true
	But some of us see in you a potential for great harm, which we cannot allow. If it makes things easier, we are sorry that it comes to this."
	*goto the_storm
*else
	However, we cannot expect the world to always stay the same. We will try not to stand in your way, ${prenom}. Safe travels."
	*goto the_storm

*label the_storm

The great gleaming image of the gods looming above you slowly fades, and you are left in the dark of night. The storm worsens. 
*page_break 
Wind whips at you at dizzying speed and the rain drives hard enough to push you to your knees. It is only through force of will and sheer luck that you manage not to be thrown clear. You could scream, but the storm screams louder and its cries are deafening. 

Time ceases to mean much as the storm pummels you and the world around you.
*if gods_hinder
	The wind has a plaintive, keening note that sounds nearly familiar. The feeling of recognition stays with you as the noise grows louder and seems to surround you. It seizes you with a terror that brings your childhood to mind: huddled
	*if tribe="Highwalk"
		in the corner as the furious wind beat a dusty, tuneless legato against the hide-bound tent.
	*if tribe="Quiet"
		and tied to a tall, sturdy tree as the waters surged and surged again, threatening to wash away all the safety you had ever known.
	*if tribe="Clearwater"
		in a simple shack as snow and ice bore endlessly down from a pitiless, blank sky.
	*comment endif

	You are reminded of what it was like before Wolf was in your skin and you knew his protection would see you through such calamity. In another instant, you recognize the moans in the wind for a howling. The hair on your body, though plastered to your skin in the cold rain, stands up defiantly. Wolf.

	The sense of your god is overwhelming at first, and then it is suddenly gone, and along with it, the worst of the storm. The rain still beats, but the winds have settled and the sky lightens fractionally.
	*goto siltstone_intro
*else
	You cannot see more than a hand's span in front of your face and you are exhausted by the effort it takes to stay upright. You are nearly prepared to give in to the whims of the storm and let it blow you where it will. However, in this last moment when the wind strikes you, you can feel its strength waning. The storm, perhaps, is breaking. Sure enough, the winds settle and the rain soon does the same.
	*goto siltstone_intro

*label siltstone_intro

You look around and find you do not recognize your surroundings. The dense copse of tall trees that you took shelter near is gone. You wonder if the storm really did blow you so far off track, but even the smell of this place is different. The mud beneath your feet is richer in color than the ignoble browns that characterize the northern borders of the Quiet land. You suspect the work of gods and their incomprehensible rituals.
*if gods_hinder
	One god, in particular. 
*comment endif

You wander this new area, taking note of the hardscrabble vegetation and the smell of clay in the soil. It is not long before the telltale signs of living people start to emerge: The road, for one, is a fairly good sign. You follow the road a few miles and you encounter a few people, none of whom seem particularly interested in speaking with a stranger who seems to have been living in wilderness for a little too long.

*if meeting_sen
	You also encounter a handful of the Rising Sun faithful. These men and women do not seem especially inclined to cause trouble, but their presence is surprising nonetheless.
*comment endif

The road leads to a modest town, but in comparison to the places you have spent the last few weeks, it is palatial.
*if sensitivity >= 25
	There are the smells you expect: cook fires and fertilizer, the mineral wetness of several deep-dug wells, but there is something like decay underneath it all, and an electric wrongness that sets your jaw tight. It is only through a deep self-mastery that you are able to encourage your anxious body to loosen.
	*goto enter_siltstone
*else
	But there is something setting you on edge as you near the town, which proclaims itself to be 'Siltstone' on a colorful hand-painted sign standing a mile out. You feel irritated, cornered, and impatient. You hope it will pass.
	*goto enter_siltstone

*label enter_siltstone 
*page_break
There are two patrolwomen standing outside of the town's western facing gate. As you near, they look you over with some suspicion.

"Hail, traveler. What business do you have in Siltstone?" one asks.

She seems friendly enough, but despite her casual tone you notice she does not loosen her grip around her weapon.

*choice
	#"I am a humble mystic, come to ply my trade for a few coins."
		*if ritual >= 20
			"Ah," the patrolwoman says. "Well, I would advise you keep your expectations modest. We are a town of few true believers. The gods do not appreciate meddling."

			You make a note of that.
			*goto entrance_granted
		*elseif combat >= 20
			"You look more apt to knife someone in face than read their palm, stranger. It is not my place to deny you entrance, 
			*label bullshit_detect
			but have a care: We will not brook much trouble in Siltstone."

			*label entrance_granted
			The patrolwomen both stand aside and allow you to enter the town.

			*goto siltstone_proper
		*else
			"Is that right?" the patrolwoman asks. "Well, enter then,
			*goto bullshit_detect
	#"I merely seek a few days' rest off the road."
		"And by the look of you, a rest is well-earned. Welcome to Siltstone, stranger. You can trade an afternoon's honest labor for a bed at Kasigo's shanty. She will also take coin, if you have it, though most do not."

		*goto entrance_granted
	#"You would be wise to stand aside."
		*if combat >= 20
			"You seem capable, stranger, I will give you that. We are also capable, and you know nothing of our skills. It would be wise of you to change your tone. Enter, if you like,
			*goto bullshit_detect
		*elseif ritual > 20
			The patrolwoman looks ready to say something cutting, but hesitates as the wind around you picks up. She has the expression of a dog sensing a coming storm. 

			"Go ahead, stranger,
			*goto bullshit_detect
		*else
			"And you would be wise to keep your threats to yourself. You may enter,
			*goto bullshit_detect
	#"I am here to ply my services as a mercenary."
		*if combat >= 20
			"There usually is not much trouble around here until late in the summer when the caravans come. I cannot say you have come at a good time for work."

			"There is always some work to be done," you reply.

			"That there is, stranger. Please enter. Welcome to Siltstone."

			*goto entrance_granted
		*elseif ritual >= 20
			"I'd sooner believe you were a sorcerer come to whip lightning from your robe. Either way, stranger, it is not within my power to deny you entry based on your appearance alone,
			*goto bullshit_detect
		*else
			"We usually look for a bit more grit in our mercenaries, stranger. No offense. You may enter Siltstone,
			*goto bullshit_detect
	*if (sensitivity >= 25) #"Something smells wrong in your city."
		The two patrolwomen exchange a look. 

		"All right? That is…unusual," one says. 

		The other one scratches her head. "I admit, we have never heard that one before. Are you all right, friend?"

		You remind yourself that they are without senses as keen as your own. But you do not feel particularly compelled to explain things to them either. "Am I free to enter?"

		"Yes,
		*goto bullshit_detect

*label siltstone_proper

Siltstone is a great deal more developed than any of the places you have passed through recently. It dwarfs Ishko several times over and boasts actual architecture where Mara's Caravan had only temporary housing, ready to be folded and stowed for travel at a moment's notice.
*if meeting_sen
	You also notice there are strangers moving about the denizens of Siltstone. They blend well, but there is no denying that they are also members of the Rising Sun. You grow increasingly curious about their presence, but discovering their aims in Siltstone is secondary to your own goals, so you let it pass for the moment.
*comment endif

Whatever the circumstances, you are standing in the center of a town that feels wrong to you and you doubt this is an accident. You should find out what led you here and why. 

You assume Siltstone operates like most towns: Someone who lives here knows where to find its secrets.
*if sensitivity < 25
	Even if you have to beat it out of them.
*comment endif 

You could seek out the local toughs and make an example out of them. Perhaps they have information to spill. Or considering Siltstone seems like a town with some trade, you could locate an information broker and coax them to reveal something about their town. You could also rely on ritual, perhaps stir up the shadows and see what shakes loose.

*choice
	#Seek out the town's ruffians. Force them to give me information.
		It is the same anywhere. Where there is commerce and success, there is discontent. You seek out that discontent and find it in a group of gamblers throwing dice in the dirt behind an ancient-looking drinking establishment. 

		One of the gamblers, squatting to loudly inspect and dispute the outcome of a throw, sees you and levers herself up out of the dirt.

		"You are in the wrong place, outsider," she says with finality. "One chance to turn around. If we are feeling generous that is."

		The other gamblers gather behind her. They let their weapons show to intimidate you. The sunlight glints from broad machetes and long, crooked knives.

		They do not seem inclined to listen, but you can try to talk them down anyway. 

		*fake_choice
			#"I am not here to fight with you. I only have a few questions."
				"Oh, good. We were just discussing how badly we wanted to answer a few questions. It that not so, boys?" the head gambler says.

				They reply in low, guttural tones. It looks like it will be a brawl then. 
			#Talk? Yes, they will talk. Afterward.
				You crack your knuckles. This is not a terrible outcome. 
			#"All right, I will go."
				"Wait a moment. I think I have changed my mind. We have been gambling all day, for several days. I think we could use some fun. Do we agree, boys?"

				They seem content to let their weapons do the talking.
		*comment endif

		The gamblers are practiced fighters, though their methods are rough. It shows in the way they advance on you, swinging their blades with a deftness made even more dangerous by their ability to work together.
		*if combat < 25
			The head gambler directs them with subtle cues and they follow her lead without question. You wonder what the story is behind their teamwork, but you are too busy avoiding the sharp edges of their knives to ask. 

			The gamblers come after you with a bloodthirsty glee. You narrowly dodge a hard horizontal chop that would have otherwise taken off a finger or three. Sweat stings your eyes, and you realize how serious this fight has become. 

			You bare your teeth and prepare to draw on some modicum of Wolf's leftover essence, but a hand on your shoulder yanks you backward and a woman muscles her way in front of you.

			"Hey!" she shouts. "No fighting near my place. I have told you too many times, Keeya."

			The head gambler, Keeya, whistles and the others drop out of their fighting stances and into lazy, casual postures. "Just a little fun, Kasigo. No disrespect intended."

			Kasigo—your unlikely savior, though considering what you were about to unleash on the gamblers, their savior—points a broomstick at you. 

			"Get out of here, stranger, before I let them take you apart. If you want to find trouble, go bother Tumelo up on the hill. He is the principal trader of Siltstone and he seems to like dealing with feral outsiders like you."

			You nod to Kasigo in thanks for the information and then look over at Keeya, who blows you a kiss as you turn to leave. 

			*goto tumelo_more_info
		*else
			But ultimately they have no practice fighting a vessel infused with godly power. You break them down almost without thinking. 

			The head gambler proves the toughest of the bunch and even she gets flung around with ease. By the end, they are all groaning in the dirt and you can ask your questions. 

			"I want to know where I would go in this town if I needed to do something in secret. Disappear a god, perhaps."

			The head gambler, clutching her side, squints at you through direct sunlight. She smiles wide, showing her blood-stained teeth. "Tumelo usually deals with people who come through Siltstone looking for trouble. He is the principal trader of this town. Whatever you need to find, you will probably find with him. Be careful though, he is a snake."

			*goto tumelo_more_info

	#Divine the information myself, using rituals.
		You seek out the center of town and find that it is fairly bustling. Apparently this is where a large portion of the town's people spend their time when they are not working whatever tasks keep them fed. The concentration of people, and the way they stare at you, makes your work harder but it needs to be done.

		You focus on the lines of intention in the earth. There is a flow of feeling and intention that connects people with their world, whether they are aware of it or not. You try to focus on that. 

		*if ritual < 20
			It is difficult, but the size and severity of the discrepancy that you encounter makes it easier to locate.
			*goto ask_the_locals
		*else
			Almost immediately you notice what is wrong with Siltstone. There is a brokenness, a vacuum of intention, and the void swirls around one place in particular.
			*goto ask_the_locals

		*label ask_the_locals
		It's a squat, ugly thing, the building in question. It is surrounded by both people performing menial tasks and others clearly armed and prepared for trouble.

		You ask a passerby about the structure and who it belongs to. 

		"You are certainly new here, friend. The principal trader of Siltstone resides there. Tumelo. He deals with the caravans who come through this area, provides them with safe routes and maps updated each season."

		"A good man?" you ask. 

		She wrinkles her nose. "A good citizen."

		You thank her for her time and she leaves you.
		*goto tumelo_more_info

	#Find someone with information and connections. Encourage them to help me.
		After quietly asking around for someone who might be able to trade you for useful information, you find your way to Kasigo's Shanty. It is a rough-hewn structure that looks apt to collapse under at the first signs of a strong breeze, but you can tell from the vines that grow alongside it and the lived- in, earthy smell within that it has stood for some time.

		Kasigo herself is a wiry woman whose braided hair falls wild down her back and into her face as she scrubs a table—which is little more than a few pieces of oft-repaired wood banged together. 

		She takes a look at you, and says, "I doubt we have anything strong enough for you. You have the look of someone with things to forget."

		*fake_choice
			#"Actually, remembering is my problem at the moment."
				"Well, then we certainly do not have what you are looking for."
			#"There are many things I would like to forget, but that is not why I am here."
				"Oh? Then enlighten me. What can Siltstone's greatest and only vintner do for you?"
			#"I come seeking a god."
				"And you think you will find one in Siltstone? We are short on gods today. Maybe we will get some in the next trade with the caravans."
			#"A drink would be a good start, actually."
				Kasigo gives you a knowing smile and pours something from an earthen jug. She passes you a little clay cup and you sip from it. The drink is deceptively sweet and nearly too strong. You cough. 

				"A special blend. It comes on strong, but it can be a good companion at the end of the night. Now, I doubt you came from…wherever to sample my drinks." She gestures at your disheveled state. "What do you really need?"
		*comment endif

		You explain that you are looking for someone who might have had recent dealings with the gods, or perhaps were party to strange events in Siltstone. 

		*if quickthinking < 20
			Kasigo raises an eyebrow. "Strange events? Lesedi claims her goat's calf was born with a man's face, but that was only after she stumbled out of here just before sunrise, half-blind on drink."

			"To be fair, the goat was hideous, but not as strange as she seemed to think it was." Kasigo shakes her head, laughing at her own joke.

			When she sees you do not share her mirth, the shanty owner waves her hand dismissively at you. "Go ask your questions to Tumelo, the principal trader. His place is up on the eastern hill. Big and lavish. You can hardly miss it."

			You thank her for her time and leave Kasigo to her work.
			*goto tumelo_more_info
		*else
			Kasigo looks at you, then looks toward the door. There is no one else around, but she still double-checks before she speaks again. 

			"I play host to all sorts of travelers who come through Siltstone. But not all of them. Some travelers, people with the means, stay with Tumelo. He is the principal trader."

			Kasigo hesitates. "His compound is on the eastern hill. You will know it when you see it."
			*goto tumelo_more_info

		*label tumelo_more_info

		You head toward the place where this principal trader lives and as you lay eyes on it, you feel a coldness wash down your back. It is something like recognition, though you have never seen this place before. You have no doubt that someone here knows something about Wolf's disappearance. 
		*goto tumelo_audience

*label tumelo_audience
*page_break
You are rebuffed the first time you attempt to get an audience with Tumelo, and the second. His secretary, Kgosi, a fussy man with tight braids and a quick tongue, implores you to come back in three days. You are loathe to wait that long, but are wary of shedding blood before you know what to expect. You try to tell yourself that viewed in comparison with the rest of your travels, three days is more than bearable. 

You arrive early on the appointed day and half expect to be met with more demurrals,
*if sensitivity < 15
	for which you would surely have to punch this lying man in his face.
	*goto tumelo_audience_2
*else
	but Kgosi surprises you.
	*goto tumelo_audience_2

*label tumelo_audience_2
"Thank you for your patience, ${prenom}." You regret somewhat that you had to give the man your name, but it was an unavoidable part of arranging the meeting. "Master Tumelo will see you at once."

You are led into the compound and the sense of wrongness persists and worsens. It is nearly like being surrounded by buzzing, invisible flies. You try to put the feeling out of your mind. 

Tumelo sits before you on a small lake of pillows and beaded carpets. There are also close to a dozen armed guards standing with their backs to the walls of the room. 

*if ((meeting_ara) and (meeting_sen))
	There are also two faces you did not expect to see: Sen, the Rising Sun commander and ${ara_name}, the Spider avatar. Neither of them seem particularly enthusiastic to share space with one another.

	"You are awfully late, ${prenom}. Poor weather on the journey up?" ${ara_name} asks.

	Sen pretends ${ara_name} has not spoken. "It is good that you have arrived, ${prenom}. Now we can begin negotiations with Master Tumelo in earnest."

	*gosub tumelo_bullshit

	"If you traded as well you lied, I think Siltstone would be twice the size by now," ${ara_name} says.

	"I want information on Wolf," you say. 

	"I am sorry you have come so far for so little, but I know nothing of the affairs of the gods. As I said, I am a trader. That is all."

	Sen folds his arms. "I think the principal trader has said all he is willing to say. Another form of coercion might be in order."

	*choice
		#Ask ${ara_name} to "convince" Tumelo to speak to me.
			*label ara_challenge
			${ara_name} seems delighted to be asked to do what ${ara_he} is best at: namely, manipulation.

			$!{ara_his} eyes go dark and you can feel something walking up your spine, but when you try to slap it away there is nothing there. Sen seems equally disturbed and scratches restlessly at his forearms.

			*if ((ara_affinity >= 65) and (influence >= 3))
				*set ara_affinity %+15
				*set deliberation %+10
				*set action %-10
				"Master Tumelo," ${ara_name}'s voice isn't ${ara_his} voice anymore. Spider herself is present. "I would rather not waste any more time. Not when there are so much more interesting things I could be doing."

				The principal trader contorts unnaturally on his pillows. His fingers claw at his face and he makes a bloody groan. 

				"Tell us what we wish to know. Give us all of your secrets. What do you know about Wolf?"

				The mention of the lupine god causes Tumelo to scream out, but his eyes roll back into his head before he can speak. 

				"Hmm…" ${ara_name} says. $!{ara_he} raps ${ara_his} knuckles against ${ara_his} cheek. No longer channeling ${ara_his} god then. "That was not supposed to happen."

				*if meeting_sen
					"So you killed him, then. Excellent work, spider," Sen says. 

					${ara_name} turns on him. "Do you imagine that you would be harder to kill?"
				*if meeting_lyall
					"Untrustworthy and ineffectual. How useful you have been, spider," Lyall points out.

					${ara_name}'s usually calm demeanor threatens to erupt into violence. "One bite, little wolf, and I could end your world."
				*goto bear_hawk_appear
			*else
				*label ara_berserk
				${ara_name} speaks, but it is the voice of mellifluous of Spider that emerges. Beautiful, measured, and terrible. "When we drew the differences between man and beast into the sand, I argued that all lesser creatures should occupy a single category. I did not see why man should be separate from animals when both were made to serve. It feels good to serve, does it not?"

				Tumelo falls back on his pillows, a huge grin plastered across his face. But it is his guards that you watch. They are advancing from the walls where they were stationed with weapons in hand. 

				${ara_name} laughs. $!{ara_his} voice is ${ara_his} again.

				"You are cute, ${prenom}. However, I am the mouthpiece of the god of deceptions, and you have overplayed your hand."

				*if meeting_sen
					Sen draws his sword and backs toward you. "Funny, I never feared spiders before today. If we survive this though, I think I keep my distance in the future."

					There is no more time for quips. The guards attack.
					*goto ara_attack
				*elseif meeting_lyall
					"Damned spiders." Lyall spits on the ground. "Ah, well. Let us get this done."

					$!{lyall_he} cracks ${lyall_his} neck and prepares to wade into the fray.
					*goto ara_attack
				*else
					It was never out of the question for ${ara_name} to turn on you, but that does not soothe betrayal's sting.

					The guards attack.
					*goto ara_attack

				*label ara_attack

				You are aware that Tumelo's guards are being manipulated by ${ara_name}, but you may not be able to keep them out of harm's way. 

				*choice
					#Fight the guards, but incapacitate them instead of killing them.
						*set deliberation %+15
						*set action %-15
						*set equity %+20
						*set selfishness %-20
						You would prefer not to have to take lives in order to survive ${ara_name}'s little coup, but ${ara_he} does not make it easy for you.

						The guards come at you with a zeal that is unnatural. Their eyes are shiny and bright, their jaws slack, and they are seemingly tireless. 

						*if meeting_lyall
							Lyall does not quite agree with your reserved approach, but restrains ${lyall_him}self from killing the guards all the same. When ${lyall_he} shatters a man's ankle, you can almost hear ${lyall_his} equivocation: He's still alive, is he not?
						*if meeting_sen
							Sen keeps his sword sheathed for the most part and you are impressed by his virtuosic combat performance. Even more so because of all the blood he manages not to spill. 
						*comment endif 

						You take down the first two guards without too much trouble, but ${ara_name}'s hold on them causes them to get back up afterward. You have had easier fights. 

						*if combat >= 25
							*set survival +5
							The work is tiring. 

							${ara_name}'s newly made slaves are relentless, and it takes a lot out of you to put them down and keep them down. You focus on delivering injuries that hamper their ability to come after you: a twisted wrist; a dislocated knee; a shoulder wrenched violently out of its socket. 

							You can see the realization dawning in ${ara_name}'s eyes that ${ara_he} is losing ground.

							"Oh, fine." ${ara_name} makes a noise between a sigh and a growl. The guards come to their senses all at once and collapse where they stand. "I thought that would be more enjoyable. Oh well. So what now, ${prenom}. Vengeance? Blood?"

							*goto ara_fate
						*else
							The guards grow increasingly vicious as ${ara_name} seeks to end the fight decisively in ${ara_his} favor. Your conscientious attempt to keep the guards alive works against you as they throw themselves mindlessly into harm's way.

							You lose ground, slowly at first, then altogether as the guards still standing rush you. 

							Many hands are pining you down as ${ara_name} looms over you.

							"That was underwhelming. I really thought you would take them down easily. Ah, well. Sorry it comes to this, but you know how well weakness goes over in the wild." 

							${ara_name} sweeps ${ara_his} hand casually and one of the guards raises a nasty looking cudgel over your head. 

							And then brings it down. 
							*goto bear_hawk_appear
					#Kill them.
						*set restraint %+10
						*set action %+20
						*set deliberation %-20
						*if pacifism
							*set pacifism_broken true 
						You do not need to keep the guards alive, only Tumelo holds any real value to you. 

						*if meeting_sen
							"Should we spare them?" Sen asks, unsheathing his sword.

							"Why bother?" you ask. 

							His expression is blank. "To work then."
						*if meeting_lyall
							"We are not going to go easy on them, are we?" Lyall asks. 

							"No. We are not," you reply.

							"The best news I have heard in days."
						*comment endif

						The first of the guards is a disappointing opponent. He takes a sloppy swing at you and you easily turn his momentum against him and impale him on his own sword. You hope the others will prove more of a challenge. 

						*if ((combat >= 25) and ((survival >= 20) or ((action > deliberation) and (selfishness > equity))))
							*set combat +5
							*set death_toll +10
							*if death_toll >= 35
								*check_achievements
								*if not(choice_achieved_bloodrain)
									*achieve bloodrain
							You tear through the guards. You are not explicitly trying to kill them all, but you are long past caring who lives and who does not. One guard, barely even a man yet, survives with only a few broken limbs while you nearly tear the head off of another. Your penchant for violence is boundless and capricious.

							${ara_name} slowly loses ${ara_his} smug smile as the body count grows higher. You guess this was not the scene ${ara_he} had imagined.

							*goto ara_fate
						*else
							The blood-scent fills the close air of Tumelo's meeting room and you work through the grind of killing each guard who comes before you. Your shoulders ache and you accumulate a host of scratches, bruises, and cuts. Before long you can barely differentiate your blood from the blood of others. 

							The ${ara_name}-controlled guards fight like feral, cornered dogs. They take as much punishment as the mete out, and you are exhausted. 

							"You can give up, you know. I could spare you" ${ara_name} says. "I cannot think why I would, though."

							You are moving too slowly to stop the guard who slips around your side and comes in hard with a sword stroke that you can tell will be a killing blow. Not the end you expected, but a good death nonetheless. A clean death on your feet in the thick of battle. You could have done worse.

							The killing blow never comes. The arms of the guards go slack with their weapons in hand as if gravity has become too much for them to bear. 
							*goto bear_hawk_appear
					#Quickly go after ${ara_name} and force ${ara_him} to free the guards.
						You have to move fast enough to get to ${ara_name} before ${ara_he} can rally the guards around ${ara_him}, thus forcibly removing your opportunity.

						*if meeting_sen
							Sen seems to understand your plan intuitively. He moves to put himself between you and the nearest guards. In doing so he takes a hard blow to the side, but keeps fighting despite what must be considerable pain.
						*if meeting_lyall
							Lyall uses ${lyall_his} agility to give you a better shot at ${ara_name}. $!{lyall_he} takes out one of guards with perhaps a bit too much force, but you appreciate the assistance regardless.
						*comment endif

						You dodge two guards trying to put themselves between you and ${ara_name}. They are starting to see through your plan and your windows is quickly closing. 

						*if ((quickthinking + combat) >= 40)
							*set equity %+20
							*set selfishness %-20
							*set sensitivity +5
							You manage to break through a cluster of four guards and come face-to-face with ${ara_name}. $!{ara_his} eyes grow wide as ${ara_he} realizes that you have broken through ${ara_his} defense. You do not waste time savoring ${ara_his} fear. A well-placed and much deserved punch to solar plexus brings ${ara_name} to ${ara_his} knees. 

							The physical assault breaks ${ara_name}'s concentration, and the guards collapse simultaneously. 

							The Spider avatar struggles to catch ${ara_his} breath.
							*goto ara_fate
						*else
							You nearly break through, but the guards form a tight wall around ${ara_name} at the last moment and you are rebuffed, hard, for your efforts. 

							"Good thinking, ${prenom}. You almost had me. I hope that comforts you in the afterlife. If there is one for creatures like us."

							A guard standing to the left of you pulls her arm back and goes to run you through with her spear.
							*goto bear_hawk_appear
					#Interrupt the ritual ${ara_name} is using to control the guards.
						You think it might be possible to break the hold ${ara_name} has on the guards, but it might take focus that you can ill afford while fighting for your life. 

						The first of the guards comes after you and you manage to dive under his hooked blade. Another nearly brains you with an oversized cudgel.

						*if meeting_sen
							"${prenom}!" Sen shouts, and kicks away a guard about to run you through.
						*if meeting_lyall
							Lyall bites a woman's shoulder then punches another guard in the face so hard that a crack resounds. The man goes down instantly. 

							"Idiot," Lyall hisses. "Do you have a plan or not?"
						*comment endif

						You have to duck and dodge, but a part of your mind opens up despite the stress and you can nearly see the lines in the air hanging over the guards under ${ara_name}'s control. It is hard, migraine-inducing work, but you reach out to the dust lying in the corners, the slight breeze entering through a cracked window, any force willing to lend even a drop of might to your cause. You do not know if it will be enough, but you send the collected power out in an unfelt, radial blast. 

						*if ((ritual + sensitivity) >= 40)
							*set sensitivity +5
							*set equity %+10
							*set selfishness %-10
							It does not break the connections that ${ara_name} has built, but it rattles them badly, and because ${ara_he} has spread his power so thin between the many guards, those connections falter and break on their own.

							The guards crumple to ground like puppets with cut strings, and for once the Spider avatar is speechless. 

							*label ara_fate
							It is time for you to decide what to do with ${ara_name}.

							*fake_choice
								#Is there any question? Kill ${ara_him}.
								#Listen to ${ara_his} reasoning for the betrayal.
								#$!{ara_he} shouldn't die, but must pay. A half-dozen broken bones and limbs should do. 
								#${ara_name} is a distraction. There are important matters to address with Tumelo.

							*goto bear_hawk_appear
						*else
							You can see the connections twisting and shaking under your ritual assault, but the guards do not go down. ${ara_name}'s power is stronger than you anticipated. 

							"A good trick, really. As last-ditch efforts go, that was one of the more inspiring. Alas—" ${ara_name} says.

							One of the guards raises a sword over your head.
							*goto bear_hawk_appear
		#Convince Sen to use his Riser troops to intimidate Tumelo.
			*label sen_challenge
			*set chaos_score +1
			*set action %+15
			*set deliberation %-15
			Sen seems surprised by the request. You point out you know he has Risers stationed both within and immediately outside of Siltstone. 

			"True," Sen says, confirming it. "I have three dozen soldiers at the ready. They can do significant damage to your holdings and this town in general if we wish. Perhaps it is time to bargain, merchant."

			Tumelo levels a withering look in Sen's direction, but his shoulders slump in defeat.

			*if meeting_ara
				Before he can speak however, ${ara_name} does. "This is a truly touching moment of friendship and solidarity, but I confess that I find myself less than impressed. The Rising Sun is a group of children with pitchforks chasing invisible monsters in the dark. They are not worth calling subjects, much less allies."

				*if ((influence >= 3) and (selfishness >= 60))
					*label ara_success_deal
					$!{ara_his} eyes narrow and the edges of ${ara_his} mouth curl into a feral grimace, but eventually ${ara_his} features soften again. 

					"This accord is a mistake, but you have survived bigger missteps. At the very least, I think whatever happens next should be interesting."
					*goto end_sen_choice
				*elseif chaos_score > 2
					*goto ara_success_deal 
				*else
					*goto ara_berserk

			*label end_sen_choice

			"Alright," Tumelo says. "I will tell you what business brought Wolf to Siltstone."
			*goto bear_hawk_appear
		#Disarm the guards, then deal with Tumelo.
			*label disarm_choice
			You prefer not to play word games with Tumelo, but his guards are a considerable factor. You cannot make an effective threat without provoking them into conflict. So they need to be removed from the situation.

			You start moving before you can fully consider your actions. The element of surprise will be important if you are going to take down a superior number of opponents with the added difficulty of not killing them.

			*if meeting_sen
				Sen jumps into the fray after you, then shouts, "Some warning next time?"
			*if meeting_ara
				${ara_name} seems as though ${ara_he} will wait out the fight, but at the last moment pulls a dagger from ${ara_his} belt. 
			*if meeting_lyall
				Lyall is moving almost before you are. You had no doubt ${lyall_he} would.
			*comment endif

			As you collide with the first of Tumelo's personal guard, your method is:

			*choice
				#Forceful. Unambiguous. I am going to beat them until they drop their weapons.
					You hardly need to employ trickery in order to beat these men and women into submission. They are surprisingly hardy, but they will fall eventually. 
					*if ((combat + survival) >= 40)
						*goto disarm_success
					*else
						*goto disarm_fail
				#Fast and clever. I will finish this quickly and decisively.
					Nearly every time someone reaches for you, you are somewhere else. You utilize every ounce of speed your body and the feral spirit inside you can muster. You take a few, regrettable blows, but you manage to respond just as fiercely. 
					*if (((combat + quickthinking) >= 40) or ((quickthinking + survival) >= 40))
						*goto disarm_success
					*else
						*goto disarm_fail
				#Mystical. I intend to use my ritual advantage to its full potential.
					The elements here are not as active as they are elsewhere. The town and this building are too new for the kind of deep history and rhythms your rituals draw from. Instead you reach up for the wood beneath your feet and warp it unnaturally. You encourage upheaval and the wood obliges.

					Your enemies can hardly even stand. It is a good start, but you still have to incapacitate them.
					*if ((ritual + quickthinking) >= 40)
						*goto disarm_success
					*else
						*goto disarm_fail 

			*label disarm_fail

			Your efforts are valiant, but at the end, you are too tired and too outnumbered to continue. You underestimated the efficiency of Tumelo's honor guard and their ability to work together to counter your tactics.

			You are pushed to one knee and Tumelo, finally standing from his many cushions, looks down at you.
			*if lyall_takeover
				Lyall lies nearby. $!{lyall_he} looks like ${lyall_he} has seen better days.
			*comment endif

			"I expected better. I am not sure why, but I did." He makes a motion and one of his guards draws a hooked blade. You expected better from yourself as well.
			*goto bear_hawk_appear

			*label disarm_success
			*set action %+15
			*set deliberation %-15
			*if meeting_lyall
				*set lyall_affinity %+20
			*if meeting_ara
				*set ara_affinity %+20
			*if meeting_sen
				*set riser_affinity %+20

			You do not have to take down every guard before they eventually stop coming at you. Only a little more than half. Those lying on the ground nurse sprained wrists or twisted knees, but you have managed to leave them mostly intact. 

			When all is said and done, you turn to Tumelo.
			*if lyall_takeover
				Lyall is standing with ${lyall_his} foot on the principal trader's chest. $!{lyall_he} beams as if ${lyall_he} has just caught a prize deer. "And I left him alive, too."
			*comment endif

			"Can we talk now or do I have to leave you half-broken, too?" you ask.

			Tumelo raises his hands in acquiescence. 

			"I will tell you what you wish, ${prenom}. I ask only that you spare my guards, they are faultless."

			"Done."

			*if meeting_lyall
				With ${lyall_his} bloodlust thus curtailed, Lyall makes a face.
			*comment endif

			"I was here when Wolf was dealt with. I will tell you what happened." 

			Tumelo opens his mouth, presumably to start explaining, but a voice rings out.		
			*goto bear_hawk_appear
		#Peaceably influence Tumelo into talking.
			*label diplomacy_choice
			You guess there are just a few minutes before the principal trader, who clearly has secrets worth hiding, begins to get nervous, and nervous people with the ability to cause violence tend to reach for that tool early. 

			*if (((meeting_ara) or ((meeting_ara) and (meeting_lyall))) or ((meeting_sen) and (meeting_ara)))
				"There are two of the gods' avatars in this room," you explain. "Is the information you are holding worth invoking our direct ire? Tell us what we want to know and we will leave. We have no quarrel with Siltstone and we have no quarrel with you. Tell us about Wolf."

				${ara_name} examines ${ara_his} nails as if disinterested in the proceedings.
				*if meeting_lyall
					Lyall, on the other hand, looks furious. Likely ${lyall_his} plan involved a good deal more murder. 
				*if meeting_sen
					On the other hand, Sen seems to approve of your methods, though he remains quiet, preferring to cede the negotiations to you.
				*goto tumelo_peace
			*elseif meeting_sen
				"We have not come all of this way to terrorize you, Tumelo. Sen and I, and whatever forces he brought will leave you and this town in peace. We only want to know about Wolf."
				*goto tumelo_peace
			*elseif meeting_lyall
				"Lyall and I represent some of the last worshipers of Wolf. Our interest in this matter could not be purer. We do not want to fight with you. We only want to know about Wolf."
				*goto tumelo_peace
			*else
				"I want to know about what happened to Wolf, Tumelo. I do not want to fight with you or to harm anyone in this town. Tell me what I want to know and I will have no further business here. Please."
				*goto tumelo_peace

			*label tumelo_peace

			Tumelo eyes you for a long time.

			*if ((influence >= 3) or (sensitivity >= 35))
				*set influence +1
				*set quickthinking +5
				*set deliberation %+15
				*set action %-15
				*set equity %+15
				*set selfishness %-15
				"I did not know what to make of you, Wolf avatar. In honesty, you are not the first chosen of the gods that I have hosted in these halls. You may, however, be the most genuine. We have much to discuss, ${prenom}. Please, take a seat. I will tell you what you want to know. About Wolf and what transpired here."

				*goto bear_hawk_appear
			*else
				*label tumelo_speech
				"This is the way of things, ${prenom}: the gods make promises, they make deals, and beneficial or not, we mere lowly servants, are expected to oblige. This is old thinking. Seemingly overnight we have ourselves in a new world. In this world? The gods are as lost as we are. I will tell you nothing, Wolf avatar, but you are more than welcome to all of the hospitality of the many blades in my command."

				*label tumelo_guard_fight

				Tumelo's guards move from the wall and start approaching you.

				*if meeting_sen
					"I assume you expected a slightly friendlier resolution?" Sen asks, drawing his sword.
				*if meeting_ara
					${ara_name} shakes ${ara_his} head. "This is why I never bother bargaining. Better to go straight from threats to murder."
				*if meeting_lyall
					Lyall says nothing at all, but smiles like someone gone mad.
				*comment endif

				The fighting starts quickly after that. The guards attempt to quickly subdue the threat, but you are hardier than they think and you have not survived this long without employing a few tricks. 

				*if ((combat >= 25) or (combat > ritual))
					You rush at the first set of guards, erasing whatever jump they might have gotten on you. They are well-trained, which is inconvenient, but it only makes victory that much sweeter. Your entire body burns with the effort of holding off the guards, but you are encouraged by how many of them are lying on the ground. You, on the other hand, are still standing. 

					The mood is changing. You can smell their fear. They should be afraid. 

					Another cluster of them come at you, and you rush to meet them. 
					*goto bear_hawk_appear
				*elseif ((ritual >= 25) or (ritual > (combat)))
					There is not much to work with in the building from a ritual standpoint. You find yourself wishing you were outside in between dodging punches, kicks, spear-thrusts, and swipes of all manner of bladed weapon. But even a slim chance is still a chance. 

					The motes of dust floating in the air respond to your impromptu summons and turn against the attacking force. Their vision is immediately impaired, and they sneeze and cough as the air violates their senses. Considerably softened, they are not quite so tough. 

					You can feel your victory at hand. 
					*goto bear_hawk_appear			
				*elseif survival >= 25
					Some people can take physical punishment, but you have all but made it an art. You wear your attackers to the bones and then they make sloppy mistakes. You turn the space against them by forcing them to fight in awkward clusters. They have to take turns coming at you, and that breaks up their momentum. They are easier to dismantle when they are breathing heavily and dripping sweat into their bulky armor. 

					You turn the tide against them gradually until you can see their hesitance. But for you, the excitement is just starting. 
					*goto bear_hawk_appear
				*else
					However, you are facing an overwhelming number and there is not much room to maneuver. You find yourself bogged down by Tumelo's personal guard and their persistence. Before long, you catch a blow to your lower back that puts you on your knees. The blood beating in your throat and the hot spark of the Wolf spirit burning inside you make it impossible to tell the severity of the wound, but when you attempt to stand you find it difficult. 

					"Stay down," someone grunts. "Make it easy on yourself."

					Four guards surround you and they look prepared to put you in the ground. It is not the ending you would have chosen, but you fought hard. There is something to be said for that. 
					*goto bear_hawk_appear
		#Invoke a ritual to terrify Tumelo into assisting me.
			*label ritual_choice
			You have little interest in negotiating with Tumelo if you can get quicker results with a simpler tool: fear. 

			You cast your senses about the room and see what you can use to your advantage. The history within the building and around it is dull and only echoes of a vibrant natural history remain. Thousands of years of rushing water, wild growing trees, and rich dense earth have been compressed into deadened building materials. But even there, some life remains. 

			*if meeting_sen 
				Sen whispers from nearby so that only you can hear him. "${prenom}, I think this situation requires a more active solution than stunning these people with your dreamy silence."
			*if meeting_ara
				As your senses roam the room, you can feel ${ara_name}'s presence deep in your stomach. $!{ara_his} deep reserves of ritual power intermingle with your own. $!{ara_he} knows what you are up to.
			*if meeting_lyall
				"If you just intend to stand there, I am more than happy to do this thing in your stead," Lyall snaps. 
			*comment endif 

			You reach out to the wood beneath your feet. It has perhaps the strongest remaining connection to the life it once lived. You urge it to rise up and imprison those you deem enemies. 

			*if ritual >= 25
				*label ritual_completion
				*set sensitivity +5
				*set action %+15
				*set deliberation %-15
				The wood warps and snaps beneath their feet and shoots up at impossible angles, catching arms and crossing through legs. The guards are trapped fast within the tight embrace of the ensorcelled wood.
				*goto ritual_success
			*elseif meeting_ara
				The wood does not immediately react. You can see the shape of what you want to happen, but there is a disconnect between the power you wield and the ability to force those shapes onto the world. 

				"Is it really so hard to ask for help?" ${ara_name} asks aloud. 

				You can feel ${ara_him} pulling on your connection, strengthening it. 

				*goto ritual_completion
			*else 
				However, the wood does not respond as enthusiastically as you hope. Even as you reach deeper and press harder, there is only the slightest quaver in the ground.
				*goto ritual_fail

			*label ritual_fail 

			The last remnants of the failed ritual scatters. and your attention comes back to the guards surrounding you. Your aggression has stirred them into direct action against you. 

			Tumelo sucks air against his tongue and makes a chiding noise.

			"Entertaining, ${prenom}, but ineffective," he says, and gestures for his guards to attack. 

			The ritual took more out of you than you expected. You can hardly fight back when they come at you with their weapons.
			*if lyall_takeover
				Lyall looks nearly as bad as you feel.
			*goto bear_hawk_appear

			*label ritual_success 

			They are trapped in their intricate wooden cages. You cannot say you envy their awkward positions, but considering how easily the ritual could have killed them, it is probably preferable on their parts.

			"We were discussing a trade of information," you say to Tumelo.
			*if lyall_takeover
				Lyall breaks a splinter off of a nearby rod of wood jutting up from the floor. $!{lyall_he} offers it to Tumelo, who is collapsed into a pile beneath ${lyall_him}. The principal trader groans in response, so Lyall shrugs and picks ${lyall_his} teeth with it.
			*comment endif

			The fight seems to have abandoned Tumelo. He spills his mind to you.

			"I will tell you what happened to Wolf. I was compelled to keep the secret, but you should know. I will tell you everything."
			*goto bear_hawk_appear
		#Start killing Tumelo's guards and go from there.
			*label murder_choice
			*if pacifism
				*set pacifism_broken true
			*set restraint %+10
			You have no interest in playing games of diplomacy with Tumelo. If the trader does not intend to give you the information you seek, then you can tear it out of him. 

			"I will kill every one of your guards and then I will remove parts of your body until you tell me what I want to know," you explain dispassionately. "Do you understand that?"

			Tumelo ignores you, and with a gesture his personal guard begins to move toward you.

			*if meeting_sen
				"That could have done with a [i]little[/i] more finesse, ${prenom}," Sen complains, but he readies his sword anyway.

			*if meeting_ara
				"What is it with wolves and tearing people limb from limb?" ${ara_name} asks. 

			*if meeting_lyall
				Lyall nods respectfully in your direction. "Glad to see we speak the same language."
			*comment endif

			You have a scant few moments before the bloodbath begins, and because of the direct nature of your threat, there are only a few ways to handle it.

			*choice
				#Hard and direct. The only way to fight. 
					You can take these pet soldiers down without trickery or fear. 

					One of them comes at you with a hatchet, wielding it too loosely and too close to his own face. He learns his mistake when you turn the weapon on him and it ends up lodged, wetly, in his nose.
					*if ((combat + survival) >= 40)
						*goto kill_success
					*else
						*goto kill_fail
				#Emphasizing quickness and guile. Kill them before they can kill you.
					They cannot move as fast as you can or think as quickly. 

					Their sluggishness costs them as you slip past one of the guards and grab him under an obvious and ridiculous decorative plate in his armor. You swing him in front of you, and another oncoming guard, moving too fast to stop herself, impales her comrade on the point of her spear. 
					*if (((combat + quickthinking) >= 40) or ((quickthinking + survival) >= 40))
						*goto kill_success
					*else
						*goto kill_fail
				#Employ ritual tricks. Keep them completely baffled.
					You intend to use every advantage available to you, especially considering their greater numbers. The elements are quiet, though: The building, even the town itself, is too new and its living history is buried under layers of development. But even here, there are echoes. You reach out to the wood beneath your feet and encourage upheaval. The guards topple against each other, suddenly imbalanced and easy to kill. You take out two before they can even stand.
					*if ((ritual + quickthinking) >= 40)
						*goto kill_success
					*else
						*goto kill_fail 

			*label kill_fail

			The first few deaths are expectedly satisfying. But their numbers are larger than your own. The guards press on you with a focus perhaps sharpened by their proximity to death. You have given them little option besides fighting for their lives. 

			You get pressed in from all sides and little wounds start to stack as your vitality wanes. You move slower than you would like and before long, you are panting and exhausted.
			*if lyall_takeover
				Lyall has already fallen. Still breathing, though.
			*comment endif

			This is not how you would have thought it would end, but when one of Tumelo's guards raises a spear and tries to drive it down into your chest, you hardly have the energy to stop him. 

			*goto bear_hawk_appear

			*label kill_success
			*set death_toll +10
			*set equity %-25
			*set selfishness %+25
			*if death_toll > 50
				*check_achievements
				*if not(choice_achieved_bloodrain)
					*achieve bloodrain

			Nearly all the guards are dead by the time you start to tire, but it is no matter, you have more than enough energy left to pick off the last of them. You take a few steps forward, and those remaining fall back. Cowardice in the face of death. Typical. 

			*if lyall_takeover
				Lyall is laughing. $!{lyall_his} hands are fairly dripping with gore, which you doubt is ${lyall_his} own. 
			*comment endif

			You intend to eviscerate them anyway. The price of challenging a god. 

			*goto bear_hawk_appear
		*if (selfishness >= 60) #Offer ${ara_name} as a bargaining chip.
			*label ara_trade_deal
			*set selfishness %+30
			*set equity %-30
			"Would you consider a compromise, Tumelo? Information on Wolf's whereabouts for one of the rarest things in the world. Something that wealth alone cannot acquire."

			Tumelo leans forward, avarice plain on his otherwise handsome features.

			"An avatar of the gods. ${ara_name}."

			*if meeting_sen
				"I am no lover of the gods, ${prenom}, but trading a life for information. Are you sure you know what you are doing here?"

				You ignore him. His opinions will not bring you the results you need.
			*if meeting_lyall
				"Selling a spider to a rat. You are sullying your hands with this deal, ${prenom}."
			*comment endif

			Tumelo laughs and claps his hands twice. His guards ready their weapons.

			"An avatar in my retinue. I like the sound of that, ${prenom}. It is a worthy trade."

			${ara_name}, quiet until now, just shakes ${ara_his} head. "You are untrustworthy, deceptive, and low, ${prenom}." $!{ara_he} slowly breaks into a smile. "I could not be happier. Of all the living totems of all the gods, I managed to find one who is like me. I will never trust you again, that much is clear, but I appreciate the way you play the game."

			*if ((influence >= 3) and (selfishness > equity))
				*set quickthinking +5
				${ara_name} turns to Tumelo and puts out ${ara_his} hands, as if asking to be bound. "I am yours, principal trader."

				The guards move quickly to wrap ${ara_his} wrists with strong ropes. Tumelo looks happy enough to burst into song.

				"This could not have gone better. I will tell you what you want to know, ${prenom}. Yes. Wolf was here, briefly. What I think you will find interesting is who else was in attendance."
				*goto bear_hawk_appear
			*else
				*goto ara_berserk
		#Dismiss Sen and ${ara_name} first, then deal with Tumelo on my own.
			*set meeting_sen false
			*set meeting_ara false
			"I appreciate you both being here, but this is something I need to do alone," you explain. 

			${ara_name} seems almost insulted, while Sen struggles to comprehend. 

			"I marched soldiers here to support your efforts, as I said I would." Sen half-snarls, but masters himself. "I hope you know what you are doing here."

			"I do," you say, reassuring him. 

			"I very much doubt that, Wolf-kin, but this was never my fight to begin with. Enjoy whatever comes next," ${ara_name} says, and bows with an exaggerated flourish. 

			Both of your would-be allies leave, and Tumelo's guards part to let them past. 

			Now you are alone, but still no closer to the information you seek. By which method will you attempt to find the truth?
			*goto wraparound_1
*elseif ((meeting_lyall) and (meeting_ara))
	Also in the meeting room are ${ara_name}, the Spider avatar, and Lyall, from the Wolf enclave. Needless to say, they are not exactly the faces you expected to see. 

	"It is good you have arrived, ${prenom}. Your lateness could be excused, but leaving me in the company of a spider for this long is harder to rectify," Lyall says. $!{lyall_his} tone is serious, but there is a vague lightness in ${lyall_his} expression that suggests it is a joke. 

	"It seems everyone in this room has been waiting patiently for your arrival. Myself? I just wanted to be around when the killing started." ${ara_name} smiles slickly. 

	"The arachnid and I agree on something, then," Lyall adds.

	*gosub tumelo_bullshit

	"I will not waste your time, principal trader. I am interested in information about Wolf. I know he was here. Please tell me what you know." You try to be diplomatic.

	*gosub tumelo_blowoff

	${ara_name} inspects ${ara_his} nails and Lyall looks around the room, calculating. You are left with a choice. What will you do to insure that Tumelo tells you what you want to know? 

	*choice
		#Have ${ara_name} "convince" Tumelo to speak to me.
			*goto ara_challenge
		#Have Lyall keep the guards busy while I go after Tumelo.
			*label lyall_challenge
			It is remarkable how easily you can communicate with Lyall. Barely a glance, a movement of the eye that some might call a twitch and ${lyall_he} already knows the general shape of the plan. But will ${lyall_he} follow it? 

			You want to go after Tumelo directly, but the fact that he is surrounded by his personal guard makes that a difficult proposition. If Lyall keeps them busy, you can move with impunity.

			*if (((lyall_affinity >= 65) or (influence >= 3)) or (enclave_leader = "you"))
				*set survival +5
				*set action %+20
				*set deliberation %-20
				You can tell Lyall would prefer to be the one putting ${lyall_his} fists in Tumelo's face, but ${lyall_he} follows your instructions nonetheless.

				The guards move to intercept, but Lyall is more than enough to keep them occupied. $!{lyall_he} moves like a lynx, all limber animal muscle. You watch only the beginning of ${lyall_his} assault: An acrobat leap from one guard's chest—throwing her to the ground—carries Lyall over another and then behind him. Lyall parlays the move into a wicked blow to the side that brings the second guard down. 

				You turn your attention to Tumelo after that. He is understandably terrified, but he does not yield immediately. It takes a bit of "coaxing."

				"All right, wolfling. All right. What do you want?" Tumelo says. It only takes a few brutal blows to sensitive areas. 

				"Call off your guards."

				He does. Lyall looks like a child whose play has been thwarted. 

				"Now, tell me about Wolf."

				Tumelo hesitates, licks his lips, but the threat of more "coaxing" makes him give up any hope of resistance. "Fine. I know what happened to Wolf. I was here when it happened."

				*goto bear_hawk_appear 
			*else
				*set lyall_takeover true
				But, maybe predictably, Lyall has other plans:

				"Fuck that," ${lyall_he} says. $!{lyall_he} charges for Tumelo, leaving you to deal with the angry guards approaching from all sides.

				*if meeting_ara
					${ara_name} pulls a dagger as thin as a needle from one of the many hidden compartments on ${ara_his} person. "Well, that could have gone better."
				*comment endif

				You have a few moments before things get really ugly.

				*choice
					#Kill the guards.
						*goto murder_choice
					#Take them down with ritual invocations.
						*goto ritual_choice
					#Disarm the guards without hurting them. Badly. 
						*goto disarm_choice
		#Negotiate with Tumelo. Hopefully violence will not be necessary. 
			*goto diplomacy_choice
		#Invoke a ritual that will terrorize Tumelo and make him more open to my request.
			*goto ritual_choice
		#Disarm the guards and have a frank conversation with the principal trader.
			*goto disarm_choice
		#Kill the guards, then ask my question again. 
			*goto murder_choice
		*if (selfishness > 55) #Offer ${ara_name} to Tumelo as an incentive. 
			*goto ara_trade_deal
		#Dismiss ${ara_name} and Lyall, then deal with Tumelo myself.
			*set meeting_ara false
			*set meeting_lyall false
			"I understand you both have reasons for being here, but this is something better done alone," you explain. 

			${ara_name} narrows ${ara_his} eyes and Lyall's nostrils flare.

			"If you fail, ${prenom}, there will be no apologies. Only reckoning," Lyall says coolly. 

			"Then I will not fail." 

			"It takes a strong person to turn away the aid of powerful allies, ${prenom}. Or a incredibly foolish one. Either way, good luck," ${ara_name} adds.

			Both of your would-be allies leave reluctantly, and Tumelo's guards part to let them past. 

			Now you are alone, but how will you attempt to find the truth?
			*goto wraparound_1
*elseif meeting_sen
	Sen, the commander of the Rising Sun forces in the South, stands before you. He is dressed in modest leather protective wear that is stained and beaten from travel. He smiles in your direction. 

	"${prenom}. Good to see you got here safely."

	Naturally, you inquire about his presence. 

	"The Rising Sun has access to a few ritualists of our own. They draw on the power of the natural world, and eschew the connection to the gods. I had them search for signs of Wolf and they suggested here. It was difficult and it took their full attention and several days, but I came as soon as I could. It is fortuitous that we arrive at the same time. At least our gracious host will not have to repeat himself."

	*gosub tumelo_bullshit

	Honeyed words will not tell you what you need to know, so you do not quibble or mince words. 

	"What do you know about Wolf?" you ask.

	*gosub tumelo_blowoff 

	Sen snorts, then says to you, "I have a heard better lies told by children. I wonder if his tune would change if we struck him."

	Tumelo's guards start forward at Sen's statement, but Tumelo raises a hand and they go back to their positions. 

	"I am sure our guest merely misspoke. I do not think I am in any real danger of harm, am I?" Tumelo asks. 

	Sen is silent, perhaps deferring to you. There are multiple ways you can imagine dealing with Tumelo and the fact that he has information that you need. 

	*choice
		#Ask Sen to use his Riser troops to intimidate Tumelo. 
			*goto sen_challenge
		#Kill his guards and Tumelo will talk.
			*goto murder_choice
		#Disarm Tumelo's guards and then see if he will tell me what I want to know.
			*goto disarm_choice
		#Negotiate with Tumelo without violence. 
			*goto diplomacy_choice
		#A well-placed ritual invocation could scare Tumelo, convince him that confessing is his best options.
			*goto ritual_choice
		#Dismiss Sen. I can deal with Tumelo on my own.
			*set meeting_sen false
			Sen stares at you for a while without blinking. "You want me to leave you here? Alone?"

			*if restraint < 50
				"Do you think I am incapable of this?" you snap, despite yourself.
				*goto sen_chat
			*else
				"I can do this," you insist.
				*goto sen_chat

			*label sen_chat

			"I think it is unwise to turn away proffered aid, but this is your great work, ${prenom}, not mine."

			Sen takes a final glance at Tumelo, who watches these events unfold with passive disinterest. Then the Riser commander leaves. You are left alone with Tumelo and his guards. How will you press for the information you need?
			*goto wraparound_1
*elseif meeting_ara
	${ara_name} is also, suspiciously, in attendance. $!{ara_he} gives you a bright smile.

	"I know, I know. A face you did not quite expect? Let us agree, wolfling, that something is [i]wrong[/i] with Siltstone and that alone makes it interesting to me. The fact that you were sent here or brought here, perhaps, gave me even more reason to look into it."

	You ask ${ara_him} outright if ${ara_he} intends to interfere. $!{ara_he} taps ${ara_his} bottom lip with a slender finger. "No. But you should know that I am notoriously untrustworthy."

	You shake your head. ${ara_name} has aims that you will never fully understand, but you will have to deal with those issues as they arise. 

	You turn your attention to the question at hand. 

	*gosub tumelo_bullshit

	"Wolf. He was here. What do you know about his disappearance or his visit here?" you ask. 

	${ara_name} acts aloof, but ${ara_his} posture and the expression on ${ara_his} face betrays ${ara_him}. 

	*gosub tumelo_blowoff

	You do not intend to be brushed aside; Tumelo knows something about Wolf, you can feel it, and you intend to find out. The only question is how you will go about it. 

	*choice
		#Ask ${ara_name} to "soften" Tumelo and make him a bit more compliant.
			*goto ara_challenge 
		#Negotiate with Tumelo. It need not come to violence. 
			*goto diplomacy_choice
		#Use a ritual to terrify Tumelo and his guards into submission. 
			*goto ritual_choice
		#Kill Tumelo's guards in front of him and see if he changes his mind about speaking to you. 
			*goto murder_choice
		#Disarm the guards first, then press Tumelo for information. 
			*goto disarm_choice
		*if (selfishness > 55) #Offer ${ara_name} to Tumelo as a bribe.
			*goto ara_trade_deal
		#Dismiss ${ara_name}. You can deal with Tumelo yourself.
			*set meeting_ara false
			"You want me to leave?" ${ara_name} asks. "You mistrust me?"

			Before you can answer, ${ara_name} waves ${ara_his} own question off with a laugh. "A joke, Wolf-kin. I hardly care about what you think of my trustworthiness. But it is bad form to look a gifted spider in the mouth. Is that the phrase?"

			"I am closer to an answer than ever. I have to do the rest on my own," you explain. 

			"I understand, ${prenom}. But some advice before I go: You might think this is fairy tale, and you are nearing the happy ending, but it really is a game. There are winners and losers. Decide which you will be before it is decided for you." ${ara_name} smiles and then takes ${ara_his} leave.

			When ${ara_he} is gone, Tumelo clears his throat. You have unfinished business. How will you go about extracting the information that Siltstone's principal trader seems so reluctant to yield?
			*goto wraparound_1 
*elseif meeting_lyall
	You would not have expected Lyall, your would-be rival from the Wolf enclave, to be standing in front of you with ${lyall_his} arms crossed, but you are starting to learn that fate—if there is such a thing—is fickle.

	"So much work to arrange this meeting and you are the last to arrive," Lyall says, half-mocking, half-irritated. 

	You express your surprise, but Lyall brushes it off. "Of course I am here. The outcome of this meeting has relevance to the search for Wolf. Now, might we begin?"

	*gosub tumelo_bullshit

	"I would like you to tell me what dealings you and your town had with Wolf?"

	"Wolves? We hunt them when they get too close to the walls, otherwise…" He spreads his hands genially.

	"Wolf. The god, merchant. No more evasions," Lyall hisses. 

	*gosub tumelo_blowoff

	Weeks and months of searching have led you here, to a town that feels terribly wrong. You are loathe to simply take Tumelo's word. But how will you extract the information you seek?

	*choice
		#Tell Lyall to keep the guards occupied while I go after Tumelo.
			*goto lyall_challenge
		#Negotiate with Tumelo, convince him that violence is off the table.
			*goto diplomacy_choice
		#Kill his guards. Force him to talk. Simple.
			*goto murder_choice
		#Invoke a terrifying ritual and use it convince Tumelo that his secret is not worth dying over.
			*goto ritual_choice
		#Disarm Tumelo's guards and he might grow eager to confess.
			*goto disarm_choice
		#Dismiss Lyall. I can handle Tumelo on my own.
			*set meeting_lyall false
			"You want to do this on your own?" Lyall repeats, incredulous. 

			"I do, and I will."

			Lyall's eyes grow wide. "I think you have lost your wits, ${prenom}. But we are wolves and we know when to band and when to go on our own. Travel safely and succeed, because if you do not. Do not expect me, or any of us, to be forgiving."

			Lyall leaves and you are left with Tumelo and his guards. He has information you need. How will you get it from him?

			*goto wraparound_1
*else
	*gosub tumelo_bullshit

	There is something in the man's genial smile that you plainly do not trust. 

	"I would like information on Wolf. I know he was here. I can feel it, somehow. What do you know about him?"

	*gosub tumelo_blowoff

	You can continue trying to make him talk, or resort to less-savory means. 

	*label wraparound_1
	*choice
		#Diplomacy might succeed if I can keep him talking.
			*goto diplomacy_choice
		#Disarm the guards, then deal with Tumelo.
			*goto disarm_choice
		#Why waste time? If I start killing his guards, Tumelo will talk.
			*goto murder_choice
		#Use a ritual invocation to terrify Tumelo into doing what I ask.
			*goto ritual_choice

*comment THIS SECTION CONTAINS THE TUMELO MEETING SUBROUTINES.

*label tumelo_bullshit
Tumelo, whose face is unlined and beard neatly trimmed, has a huge smile and a devious glint in his eyes.
*if (((meeting_lyall = true) or (meeting_ara = true)) or (meeting_sen = true))
	"Honored guests,
	*goto tumelo_bullshit_2
*else
	"Honored guest,
	*goto tumelo_bullshit_2
*label tumelo_bullshit_2
I have no idea why I am of interest to you. I only do a little trading. Still, I bid you welcome all the same."
*return

*label tumelo_blowoff
"I know Wolf is a god, great and terrible. I know that like all gods he is unknowable. Thus ends our theological lesson," Tumelo says, mockery and impatience in his voice. 
*return

*comment THIS ENDS THE SUBROUTINE SECTION.

*label bear_hawk_appear

"Enough."

The voice dominates the space and inspires obedience, or at the very least, absolute attention. A blinding light suffuses the room and out of it steps two forms. The first you remember from the ravine. She looks younger now, though that might be her lack of scars and the fact that she is not wearing the heavy raiments of war. Her dark hair, twined with brightly hued feathers, falls around her heart-shaped face and her expression is dire. The second shape could pass for Enyeto's twin, though this man is more slender and his brows are knitted together in a look of permanent concern. The glow surrounding them is proof enough of their divinity.

Hawk and Bear in their full godly forms.

"${prenom}," Hawk says. "It is long past time we spoke."

*finish
