*text_image chap_7.png center Seven: Unfailing Light

[i]The worshipers of Wolf come to a lakeside town and demand succor. The people there make them welcome, boil them tea with fresh roots and fragrant leaves. They force obeisance from these people, who listen to their growling demands.[/i]

[i]Later, the followers of a rival clan, lead by a hoary-headed Bear shaman, come to the lakeside town and espouse a hatred of the law-breaking wolves. The people of the town shape their mouths to speak words of placation. They brew tea with fresh roots and fragrant leaves. They make these newcomers welcome.[/i]

[i]Later, the followers of Spider, dressed in silk and steel, come to the lakeside town. The people find yet more fresh leaves to boil into calming tea and fresh cups in which to serve them.[/i]
*line_break
-From an oral history of the south-central lands.
*page_break
*if tribe = "Quiet"
	*set quiet_nickname "[i]kingcu[/i]"
	*goto chapter_start
*else
	*set quiet_nickname "stranger"
	*goto chapter_start
*label chapter_start 
The air is thick and wet in the marshlands the Quiet call home. 
*if survival >= 25 
	Your shoulders and calves ache from the long travel, but you manage to remain upright, knowing that succumbing to bad posture out of exhaustion will only cause more pain later on.
	*goto continue_1 
*else
	Your shoulders are slumped in exhaustion, and you have stumbled more than once on the long, sleep-starved journey into the heart of Quiet land.
	*goto continue_1

*label continue_1

There are enormous mosquitoes that buzz around your head, but they never come close enough to bite. The insects can taste Wolf's tang in your blood and even the hungriest pest will not consume the blood of a god. It is a small, but welcome relief. One of few to be found in the marshes of the south. 

*if tribe = "Quiet"
	You grew up in these lands, but find yourself questioning the shifting reeds that grow alongside the hard-packed paths. Are they the same as those you saw an hour before?
*comment endif

The land twists and turns deceptively and brings you deeper into its hot, humid embrace. You give up on wiping the sweat across your brow because it springs up just as fast. You only intervene when it drips into your eyes.

You wander until you start to encounter the faintest signs of civilization. It is hours more before you see a single soul. 

The first person who you happen across is a hoary man who is wading in the marsh water with an intent look on his face. He glances up at you, and then back down at the water he is carefully moving through. 

*if tribe = "Quiet"
	"You should know better than to step so heavily around these waters, ${quiet_nickname}," he says. The term refers to a marsh-flower, and is affectionate, if gently patronizing.
	*goto continue_2
*else
	"There are giant snapping turtles in these waters, ${quiet_nickname}. Your plodding feet could wake them. And then? Snap!" he says, then goes purposefully silent.
	*goto continue_2

*label continue_2

The Quiet-man continues to make slow circles in the water, clearly searching for something, and seems to ignore you, but you catch him glancing up at you every once in a while. He seems open to interaction, or at least, not outwardly hostile. What questions do you have for him?

*choice
	#Ask what he is searching for.
		He laughs. 

		*if tribe = "Quiet"
			"You have forgotten much, I see." He shakes his head.

		"I am hunting. As for the prey, that will reveal itself in time. Today, a fish. Tomorrow, a frog. The next day, perhaps I will be the prey. I can only trust that Eel will provide his slippery wisdom. And that it will be enough."

		The old man suddenly becomes a blur of motion as his hand shoots into the water and rises with a large, black-scaled fish in its grasp. 
		*if tribe = "Quiet"
			[i]Bispiriti[/i], it is called in the local parlance. "Water Flesh" for its slimy texture—until cooked, after which it becomes firm, flaky, and supposedly delicious.
		*comment endif

		"Today, I am blessed. As for tomorrow. Who can say?" the old man says, as he climbs out of the water, and throws the thrashing fish into a sack. Clearly pleased, he climbs back into the marsh. 
		*goto continue_3
	#Ask where I might find the nearest town.
		"Town?" he asks. "Dozens of hours back in the direction you came, ${quiet_nickname}.
		We have families here, communities. Nothing like a town."

		He scans the water carefully. He barely seems to be paying any attention at all to you or your query. "But sometimes we find what we seek despite ourselves." 
		*goto continue_3
	#Ask about the current situation in the marshland.
		The old man is silent awhile, then answers:

		"The better question is what remains of these waterways. The Sons of the Sunburst build their temple to themselves and grin to our faces, call us neighbor, as though their hands would never turn against us. But day-by-day, the water brings less into our nets and into our hands."

		He snorts and rakes a hand across his sunburned neck.

		"Eel has a plan. He must," the old man says. You are not sure whether he is trying to convince you, or himself.
		*goto continue_3
	#Ask about who leads the Quiet.
		"I was ten summers old when my mother left me in this marsh with a bone knife and a net. If I came home, it would be with enough to feed my family for a day. I did it. And do you know what she said, ${quiet_nickname}?"

		The old man smiles, but mirth does not lift his cheeks.

		"'Good, now tomorrow you will know where to hunt.' Does that sound like a people who have a leader? There are no emperors in the mud. Everyone hunts."
		*goto continue_3

*label continue_3

You attempt to ask another question, but the old man ignores you. When it becomes clear that he has nothing else to share, you head out and leave him searching the waters intently.
*page_break 

You walk as the sun travels on its westward course and wonder if you will find shelter before long. The freshwater that flows through the marsh nourishes all kinds of plant and animal life, but you do not find much evidence of human habitats.

You make a stop under a matchstick-thin but flowering tree. The twisting landscape of the marsh rises and dips under tall reeds, and the waters coil like the arteries of a living thing.
*if tribe = "Quiet"
	The complexity of the marshland feels familiar to you, and that familiarity brings with it both comfort and longing. You try not to dwell on the feeling.
	*goto continue_4 
*else
	The busy interconnectedness of the marshland feels isolating and alien. The patterns seem designed to trap and corner. You cannot help but feel like the snare is meant for you.
	*goto continue_4

*label continue_4 
*page_break
The sense that you are being watched creeps up on you, and you force yourself to move. One sorry excuse for a path seems as good as any other, so you follow it deeper in the marshland. You pass through a thick copse of waterborne plants and on the other side you find a familiar face. 

She looks more austere without holy indignation burned into her features, and she has exchanged her dark cloak for a bright emerald shawl that sits on her shoulders and glitters in the late afternoon sunlight like the waters that surround her. There is no doubt this is the same woman you encountered in the forests outside of Ishko on the day that Wolf's presence fled from you.

The shaman gives you a wry grin. 

*if eel_affinity >= 62
	*set ritual +5
	*set sensitivity +5
	"Friend of Eel, welcome to his waters," she says. And indeed you do feel welcome. The warm, damp air feels suddenly less oppressive and you are more comfortable in your clothes. Perhaps the shaman or Eel himself has passed some blessing over you. 

	After you have expressed your gratitude for the warm welcome, you inquire about how she found you. It is doubtful her presence here is a coincidence. She shrugs her delicate shoulders. 

	"You make noise, Wolf-kin. More than any marsh-thing would. It is not hard to follow, to track."

	"And what do you want?" you ask. 

	"A great many things, but I think you are the one with the most pressing need. The visions have lead you here, no?"

	You nod slowly. If she knows about
	*if prophecy_received
		Ghazal's prophecy
		*goto after_proph
	*else
		Spider's predictions
		*goto after_proph
	*label after_proph
	then there is no use trying to hide your purpose from her.

	"Well then, Wolf-kin. My name is Mizah. I think I can help you find out what you are doing chasing visions in the back-end of nowhere."

	*label shaman_explanation
	*page_break

	Mizah offers you a seat on the gnarled trunk of what must have once been a grand tree. She spreads her shawl beneath her and lowers herself to the ground. 

	"The Rising Sun has not been content to just trample sacred ground. They have grown formidable over the months and years that the gods have seen fit to let them multiply. Uninvited and unwanted, they have cultivated a great horror in the dark safety of our marshes. They have built a fortress, and its presence offends."

	*if riser_affinity >= 50
		You point out that the Risers and their affairs are not directly within the purview of the gods.
		*goto shaman_cont_1
	*else
		You are no ally to the Rising Sun, and you wonder aloud why their fortress has attracted the gaze of the gods who until now have seen fit to let them spread like weeds.
		*goto shaman_cont_1

	*label shaman_cont_1

	"You would be right if they had not taken the Bear avatar hostage," Mizah says. 

	That gets your attention. 

	"His name is Enyeto and he is currently within their brick and stone monstrosity. Even the true servants of the faith will not risk death or worse in an attempt to release the ursine god's chosen. Now, I cannot claim to know the methods of the gods, but someone must seek out the Bear, and your arrival is quite suggestive, you must admit."

	The fact that
	*if prophecy_received
		Ghazal's foresight
		*goto keep_on
	*else
		Spider's sticky wisdom
		*goto keep_on
	*label keep_on
	has led here must mean something. 

	It makes sense to seek out Enyeto, the Bear avatar, and hear what he has to say. The patient Bear god has been the stalwart of the pantheon since its genesis. Even if your goals were purely selfish, a meeting with him may be well worth your time. The remaining question is about the Risers and their fortress.
	*page_break
	*if ((pantheon_regard < 5) and (encampment_directions != "shaman"))
		"And that is all that I can offer you. Though you are well-known to Eel, the rest of the pantheon does not regard you quite so highly. You will have to do the rest on your own. I will neither aid nor hinder you," Mizah says. 

		The shaman seems resolute on this point. However, as a shaman of Eel who rules the waters of the marsh, she would likely know the best approach to the Rising Sun fortress. You could try, at the risk of provoking Eel's ire, to pressure Mizah into assisting you, or you could attempt to appease her. 

		You could also entreat the god directly, using your ritual skills. Eel is notoriously temperamental, though, and your efforts may be in vain. 

		Finally, you could decide to deal with the situation on your own. 

		*choice
			#Force Mizah into helping me.
				"I am not in the habit of being denied what I seek, shaman. I expected that a follower of Wolf's own brother would want to be of assistance."

				Your voice is stone cold and you expect Mizah to flinch from it.
				*if ((influence >= 3) or (combat >= 20))
					She has considerably more self-control than that, but she shakes her head in the end. "You have a point. There are times where letting old grudges play out is much the same as personally securing the victory of your enemies."

					She straightens. "I will take you to the fortress. I know the waterways better than anyone. I can get you close, but you will have to find a way in. I hope you are this persuasive when your life is at stake, Wolf-kin."

					*page_break
					*goto mizah_aid 
				*else
					She laughs instead. 

					"You expect me to fear you, Wolf-kin? Or should I revere you? At the center of Eel's power, you have the audacity to threaten and cajole? You are mad. I wish you safe travels, Wolf-kin."

					*goto no_help
			#Appease Mizah, and through her, Eel.
				"Set aside whatever feelings you may hold about me. Do you imagine that you have a better chance at dealing with the Rising Sun alone? With only Eel as an ally?"

				Mizah's resolute expression softens a fraction. You press on.

				"Or is preserving the sanctity of the Quiet lands a lesser priority than keeping your grudge?"

				*if ((quickthinking >= 25) or (sensitivity >= 25))
					She raises a hand. "Enough. I would sooner be flayed than let those jackals dig their claws deeper into the marsh. You have made your point. I will take you to the fortress, or as near as I can. I hope you are prepared to do what needs to be done after that."

					*page_break
					*goto mizah_aid
				*else 
					"Do you imagine you are the only one with resources, Wolf-kin? If you will not rid the marsh of the Rising Sun, then Eel will find someone who can and will. We do not fear the consequences of your negligence." She taps the soft mud with her foot. "Something here always grows anew. Safe travels to you."

					*goto no_help
			#Contact Eel directly.
				You decide to contact Eel yourself. The shaman is not the only one who can delve in the mysteries of the gods. 

				Your focus wanders through the marsh and down into the rich mud beneath your feet. The marsh is teeming with life and you allow those living things to float in and out of your attention at will. You are not a part of the marsh, so at first they do not recognize or acknowledge you. 

				*if ((ritual + sensitivity) >= 40)
					The rite itself is difficult. It requires tapping into the system of life that orders everything around you, but silence and clarity of purpose help you to get into the necessary space. 

					The silence spreads around you and your senses dim as your attention drifts into the dark, dank place where the Eel god lives. 

					You can see him out of the corners of your eyes, circling, his body is sleek and oily and endless. It coils around and around you, almost daring you to seek escape, but you force yourself to stay calm. 

					"Weapon of my Brother-Wolf," Eel says, his words are heavily sibilant and wet-sounding. "Are you welcome here, I wonder? In the dark?"

					"I seek safe passage to the fortress."

					"Oh?" The word is stretched out until it fades back into silence. "And I can help? Oh, maybe, maybe. I can." 

					It goes quiet again, then, "Maybe."

					Before you can say anything, Eel speaks again. 

					"Brother-Wolf was my favorite Brother. Indulgent, cruel, but not so mannered and chilly as our Sister-Spider. But you…are not he. Not exactly. Not anymore."

					The voice comes closer, something wet and smooth, but somehow sharp, brushes your leg. You feel wetness welling up at the spot. Blood.

					"Still."

					The word echoes. 

					"I would not swallow his progeny without cause. Go. The shaman will take you. Go. And…" There is a long stretch of quiet in which the air snuggles so close that you can barely breathe. "If you should see him: Tell him that the dark is lonelier these days."

					You awake on your back, gasping, and choking on the water coming up from your lungs. Mizah is crouched nearby, watching you eject swamp water. Once it becomes clear you will survive, she stands with a groan. 

					"Get up, Wolf-kin. Apparently we have some rowing to do."
					*page_break
					*goto mizah_aid
				*else
					And then they turn against you. You can feel them closing the door to your senses all at once and you can no longer feel the living presence of the marsh. Only your mundane senses remain. Delving further would be disrespectful to the god who reigns here and therefore dangerous.

					Mizah gives you a smug look. 

					"Eel is not kind to trespassers. It is time to go, Wolf-kin."

					*label no_help
					It is clear that you will receive no further aid from the Eel or his followers, which means you will have to find your way to the fortress alone. 

					It is a good thing then that you have a variety of useful skills.

					*label finding_fortress_alone
					You are able to see, smell, feel, and hear what others cannot. You wander through the muck until you become relatively certain you have found the way to the Rising Sun fortress. 

					The ground becomes steadier and the wildlife more skittish. You go where the insects are quietest and the small signs of civilization become more apparent. The Rising Sun do not live in concert with nature so much as in direct defiance of it, and their trace is not hard to follow. 
					*goto foot_approach
			#Strike out on my own.
				*set survival +5
				Mizah's help would have been useful, but there are other ways you can find a fortress in the middle of a marsh. Either through the power of self-determination, or sheer stubbornness, you feel that going it alone has somehow better prepared you to survive whatever comes next. 

				*goto finding_fortress_alone
	*else
		Mizah offers thoughts on that as well. 
		*if encampment_directions = "shaman"
			"Because you aided me in the defense of Eel's temple, I can tell you that there is an approach from the water.
		*if encampment_directions != "shaman"
			"There is an approach from the water. 
		I can row you there under the cover of night—it would evade the sentries they have posted in the marsh, but scaling the fortress will be no easy task. You will need uncommon hardiness to climb its jagged face. Unless you can find another way in.

		"You could also move through the wetlands on foot. It is more direct and requires much stealth. Arcane wisdom would also help.

		"Or, if you are confident in your skills on the battlefield, you could assault the keep directly. This will no doubt bring you into a direct clash with the marsh sentries. I would not counsel this path, but you are Wolf-kin
		*if death_toll >= 5 
			and your blood thirst is legend."
			*goto shaman_cont_2
		*else
			and you will do as you will."
			*goto shaman_cont_2

		*label shaman_cont_2

		"So which do you think is your best option, Wolf-kin?"

		*choice
			#Accept Mizah's help and take the waterways.
				*label mizah_aid
				Eel's shaman leads you into the thick marsh waters, and hidden within a profusion of reeds is a long, slim boat. She climbs into the boat without disturbing the water beneath it; your attempt to do the same is laughable in comparison.

				*if tribe = "Quiet"
					"You have been too long out of the water, Wolf-kin."
				*if tribe != "Quiet"
					"Your feet will never be wet enough for the marshland, Wolf-kin."
				*comment endif

				Mizah waits for you to climb into the thin shell, then she sheds her shawl and reveals her sinewy, suntanned arms. She dips an oar into the water and slowly, but steadily starts to row.

				Her patient, consistent rowing is so quiet that you suspect there is more at work than simple craft. Mizah navigates the waterways and moves with confidence from larger waterways into smaller, oft hidden tributaries. As you watch her, you notice the patterns she rows seem to linger in the water long after she has passed. 
				*if sensitivity < 20
					*set restraint %+5
					You do not wholly understand the shapes, but they calm and center you unexpectedly.
				*if sensitivity >= 20
					*set ritual +5
					The shapes reveal something of the rites through which she worships Eel. You grow in your understanding of Eel's power as you watch her row and learn, in small part, how to make that power yours. 

				"I have paddled these paths since I could hold an oar," she explains. "As you might imagine, I am fairly adept."

				She points out various forms of marsh life as you travel. It helps the time pass and between her soothing voice and the gentle propulsion of the boat, you hardly realize how much time you have spent in transit. The sun is close to setting before your target comes into view. It is not what you would have expected from Mizah's description. 

				The fortress is a thick stone building with smooth walls that curve outward as it gains height; likely to discourage easy scaling. Though it is early evening, the premises are bright with torchlight, and guards prowl the area. 

				You are lucky to be in Mizah's company, because her near-silent rowing and skills at concealment mean that you pass unnoticed through a thin waterway that is little more than a stream.

				"We part ways here, Wolf-kin. You have a plan to get into the fortress I suspect?"

				*choice
					#"I am going to climb out of this boat and walk into the fortress. If anyone tries to stop me, they will regret it."
						Mizah's lip curls sardonically. 

						"I have no doubt there will be more than enough regret to go around once this hunt of yours is over. Go with many blessings, Wolf-kin."

						You bid the shaman farewell and head up toward the fortress through the muck of swamp.
						
						*goto foot_approach 
					#"I think I can scale their wall. They have made it difficult, but not difficult enough."
						"I see," Mizah says. "Well, what is a construction before the will of gods? Go safely, Wolf-kin."

						You thank the shaman then climb out of the boat. It is a short way to the base of the fortress, but the swamp water makes the trip as uncomfortable as possible.

						*page_break
						*goto scale_approach
					#"I can extend Eel's concealments and use them to hide my entrance."
						Mizah shrugs. "It will take significant ritual ability to do what you suggest. I hope, for your sake, you are capable of it. If they catch you…"

						She grins. 

						"I will pray for your safety. For whatever my prayers are worth."

						You are unclear whether or not the shaman is mocking you, but her prayers will not make the difference here. Your will is more than enough.

						*page_break
						*goto ritual_choice
					#"I can sneak past them. They are slow and their over-reliance on fires will blind them to my passage."
						*goto sneaking_choice
					#"I am fast enough and strong enough. I will hunt them, one-by-one."
						Mizah seems skeptical, but she does not voice her concerns, so you do not know whether she doubts your chances of success or scorns your violent methods. Either way, you have decided on a course of action and you intend to carry it out. 

						You climb out of Mizah's boat and into the cool marsh water. It mutes your step and when you climb onto the soggy earth, a copse of high reeds keeps you hidden. You can see the sentries prowling the area around the fortress. 

						There are quite a few of them, but a challenge is a challenge.

						*page_break
						*goto hunting_choice
					*if (riser_affinity >= 60) #"I have a…working relationship with the Rising Sun. I think I can enter the fortress without bloodshed."
						Mizah's expression sours upon the mention of the Rising Sun, but she keeps her opinions to herself. 

						"I will say a prayer for your safety, Wolf-kin," she offers. 

						You acknowledge the help she has given you thus far and then climb out of the boat. The rapidly cooling night has sapped some of the warmth from the marsh water, but the air is still thick and humid. 

						Your first step on dry land draws the attention of a duo of Rising Sun soldiers who approach with their weapons at the ready: a halberd and a long, curved knife, respectively. 

						*label riser_escort
						"Who goes there?" they ask. 

						You declare yourself. You need no introduction beyond: "I am Wolf's avatar."

						The guards are quick to follow up with further questions, but you ignore them. It is only worth your time to speak to whoever leads them. They agree to deliver you to their leader.
						*goto fort_allyentry
					*if (eel_affinity >= 55) #[i]Eel Favor[/i]: Use ritual power to turn the marshland against the Rising Sun occupiers.
						Mizah's face slides into a conspiratorial smile.

						"I think we have a similar perspective, you and I."

						She flexes her fingers and then closes her fist tight. Light escapes from between her fingers, but when she opens them again, there is nothing there. She grins at your confused look. 

						"I too have wished to flex my otherworldly might…but Eel has forbidden me to come into direct conflict with the Rising Sun, but you are outside of such restrictions. I hope you are able to give them exactly what they deserve, Wolf-kin."

						Mizah waits for you to climb out of the shell and into the swamp before she begins to softly paddle the boat away. 

						*page_break
						*goto ritual_violence_choice
			#Challenge the Risers directly.
				"I am not really one for subtle confrontation," you explain.

				The Eel shaman does not seem to think the direct approach is best, but she does not try to stop you. It seems she knows better than to put herself between the Wolf avatar and the Rising Sun.

				The marsh water is cool and sloshes underneath you as you climb onto the moist ground. You make no effort to conceal yourself and it will not be long before you encounter the Rising Sun's sentries.

				You almost feel sorry for them.

				*page_break
				*goto prior_to_assault
			#Slink through the marsh, hidden through the use of arcane rites and subterfuge.
				*set eel_affinity %+15
				Mizah seems to agree with use of ritual to confound your enemies. 

				"Eel himself prefers to stay in the dark and damp. Such methods have his implicit blessing. I also wish you luck, Wolf-kin."

				You make your way through the muck of the marsh and, as you approach the fortress, you begin to implore the spirits and elements of the marsh to hide you. 

				*goto ritual_choice
*elseif eel_affinity < 50
	"I had not expected to find a wolf swimming these waters, but we do live in curious times. I am Mizah, shaman to the swimming god."

	The smug half-smile melts from her face. 

	"You are not one of Eel's favored people. The benefit of his wisdom should be closed to you. But—"

	The shaman stares at you with eyes as clear as marsh sludge. You cannot even imagine what goes on behind them. 

	"You are still family, Wolf-kin, of a sort. I will tell you what I know."

	*goto shaman_explanation
*else
	"Wolf-kin, you have not earned the scorn of my patron god,
	*if encampment_directions = "shaman"
		and he remembers the aid you offered when I faced down the Rising Sun." She smiles warmly.
	*if encampment_directions != "shaman" 
		but neither have proven yourself to be worthy of his gaze. It is rare to find a soul who Eel has not marked with his regard. But I am sure you have more than enough time to disappoint him." Her smile is not kind. 

	"I am Mizah, and I will tell you what I know about what you seek."

	*goto shaman_explanation 

*label scale_approach
*page_break 
Night falls slowly onto the swamp and by the time you approach the backside of the fortress, patrolled by a handful of sentries bearing burning torches, there is just enough light left for you to plan a path up the side of the fortress. 

The climbing will take considerable endurance and attention to detail. Are you prepared? 

*choice
	#I can get up there. Easily.
		You realize as you dig your fingers into the fortress wall that you did not take into account the ever-present moisture in the air. When you start to climb, you find yourself struggling to maintain a solid grip on the rounded stones that make up the fortress's outer wall. Worse still, the dark makes each handhold—minor places where wind and rain has chipped away from the perfect smoothness of the stonework—harder to find than the last.

		*if ((survival + sensitivity) >= 40)
			But you have made your way through harder trials than this, and you refuse to let yourself be daunted by a wall. 

			*if enclave_purpose = "fight"
				Below and a ways off, you can hear the unexpected sounds of conflict. The patrol you managed to avoid is rallying against some new threat. 

				You continue to climb, but the smell drifts up from the ground: wolves. You can smell that the enclave has come and they are sowing the destruction you would expect from a group of half-feral warriors sworn to bringing down the Rising Sun. You smile and shake your head; they are incorrigible. 

				You continue to climb.
				*goto fort_climbentry
			*else
				You take it slow. Breathing is almost as important as climbing. You're careful and diligent. Breathe in and out, steady as an ox cart. You keep your sharp gaze on the next handhold and the next until you near the mid-point of the fortress wall, and then it is time to look for a way in. 
				*goto fort_climbentry
		*else
			It is not difficult at first, in fact the handholds seem obvious, and you make decent progress. But the slickness of the wall works against you and before long you are struggling to maintain a grip. The going is slow, and you lose almost as much space as you gain. A noise below distracts you and your fingers just miss the next crevice. 

			*if enclave_purpose = "fight"
				You tumble, but not far, you manage to recover before you hit the ground. Climbing is not going to work, you need to find another way in. 

				It is luck or maybe fate, or both that you catch the scent of wolves in the air. The members of the Wolf enclave are living up to their promise to hunt the Rising Sun, and they are attacking the fortress.

				It is challenging, but you can parse their smells: Zev, Roan, Suba, Hemming, Fillin. They are all there. 
				*if lyall_fate = "live"
					Even Lyall is among them, yelping and snarling in the night air. 
				*comment endif 

				You use their perfectly timed insurrection to probe the fortress for vulnerabilities. You find an abandoned gate, which you assume until very recently was manned. It is locked, but the lock does not require much coaxing.
				*goto fort_wolfsupported 
			*else
				You fall, not a long way, but enough to briefly send you reeling while several members of the riser patrol surround you. They hoist you to your feet and when you seem inclined to struggle, they crack your ribs to head off further trouble. 

				Afterward you are somewhat more docile.
				*goto fort_prisonentry
	#There has to be an easier way in.
		There might be an easier way in. What do you have in mind? 

		*choice
			#Wrap myself in ritual and find a way inside.
				Using ritual to get into the fortress is a better use of your talents than climbing, hand over fist into the fortress. You make up your mind that climbing is not the right move.
				*page_break 
				*goto ritual_choice
			#Hunt the sentries individually until there is no one between me and the entrance.
				It will be easier to hunt the patrol, thin the herd, and then penetrate the fortress. It is more your style, as well. 
				*page_break
				*goto hunting_choice
			#Find a vulnerability and sneak in.
				You change your mind. Your skills are more suited to subterfuge than the rigors of climbing the side of a structure built to deter entry. 
				*page_break
				*goto sneaking_choice
	#Subtlety is a waste of my time. I will storm the fortress.
		You have no fear of the Rising Sun. Sneaking and hiding holds no interest for you at the moment. 

		*goto prior_to_assault

*label foot_approach 
*page_break 
The soupy heat abates only slightly as evening presses in. You walk over the uneven and spare landscape and follow the incongruous scents of leather, steel, and smoke through the marshland. 

You see the first Rising Sun sentries from a distance. They do nothing to mask their presence, such is their
*if riser_affinity > 50 
	confidence.
*if riser_affinity <= 50
	arrogance.
*comment endif 

You have time to plan your approach.

*choice
	#I will attack them outright. Save the subterfuge for the cowardly.
		*label prior_to_assault
		*set riser_affinity %-20
		*set action %+10
		*set deliberation %-10
		The soldiers see you emerge from the dark and it makes you smile to imagine their growing terror as they reach for their weapons. The Rising Sun has grown accustomed to taking what they feel is theirs. You have other ideas.

		The first two soldiers go down almost immediately. 

		*if combat >= 20
			*if ((enclave_purpose = "fight") and (combat >= 15))
				*comment SUCCESS W/ WOLF worshipers AID 

				The next one tries to keep his distance, but you quickly realize he is playing for time, hoping to give his allies time to surround you. You do not give him the satisfaction. 

				You rush toward him and his defense falls apart. He falls easily and you turn your attention to the next soldier. And the next. 

				In the thick of battle you almost miss the familiar scent on the breeze, but once you are paying attention, it is unmistakable. 

				"Leave some for us!" someone shouts. 

				*label wolf_aid
				You catch a blur of motion as Zev and Roan, from the Wolf enclave, run past you and crash into the nearest group of soldiers. Roan leaps onto a man twice her size and claws at his face while Zev wrests a spear out of someone's hands and uses it to impale him. The other Wolf worshipers are not far behind: Fillin, Suba, and Hemming all wade into the fray.
				*if lyall_fate = "live"
					Lyall in particular gives you a sly grin before beating a terrified Sun soldier half to death.
				*comment endif

				You fight alongside the enclave, but soldiers keep pouring out of the fortress.

				"We will keep them busy, ${prenom},"
				*if lyall_fate = "live"
					Lyall says.
				*if lyall_fate != "live"
					Hemming says.
				"You go on and finish what you started."

				*label wolf_aid_cont
				It is hard to leave them to the fight, but you still have business within the fortress. You thank the other sibling-wolves for their assistance and head toward the fortress. They begin dropping the portcullis as you approach. As if that would keep you out. 
				*goto fort_wolfsupported
			*else
				*comment SUCCESS ALONE
				The rest present something of a challenge. They are highly trained after all, and they seem to be prepared for an interruption. 

				You are not exactly a simple combatant, however. Even as the number of guards multiplies, you fight on tirelessly, ignoring the bruises and cuts you acquire as the fight drags on.

				One of the soldiers comes after you with a hatchet in a series of wide swings. When you go to block his hand, another targets you with a cudgel to the wrist that snaps something. You fight through the intense pain and make both soldiers regret their attack.

				Eventually, the last of the soldiers before you falls. You give yourself time for a few deep breaths before you head to the entrance of the fortress. You might survive another all-out assault, but it is wise to avoid staying in one place and inviting another Rising Sun attack.
				*goto fort_fightentry
		*else
			*if enclave_purpose = "fight"
				*set restraint %-5
				*comment FAILURE, SWITCHED TO SUCESS B/C worshiper AID

				But the others start to prod at your defenses and join together in order to keep you at bay. Your frustration rises as you try to go on the offensive, only to be pushed back time and time again. 

				Exhaustion threatens to set in as the soldiers' numbers grow.

				"Is there anything sadder than watching an old wolf past ${his} prime?" someone says, laughing. 

				*goto wolf_aid
			*else
				*set fortress_fight_fail true
				*comment FAILURE, NO AID

				You manage to hold your own for some time before the sheer numbers start to catch up to you. They just keep coming from the direction of the fortress, and it seems that they have a near-infinite number to spare. 

				You take a hard blow to your side from the butt end of a spear and nearly collapse to your knees. The Rising Sun soldiers take the opening to press their advantage and pile on you while you growl, claw, and attempt to fight your way free.

				It does not work. Before long they have managed to get chains on you. As inconceivable as it seems, you have lost. 

				The Risers hoist you to your feet and march you into the fortress. 

				*goto fort_prisonentry
	#Pick them off one-by-one, and savor the hunt.
		*label hunting_choice
		*set action %+5
		*set deliberation %-5
		*set selfishness %+5
		*set equity %-5
		*set restraint %+5
		You stick to the shadows, to the damp patches where your footfalls are muted, and the corona cast by the torches of the sentries do not quite penetrate. The first sentry comes too close and before he can register your presence, he is down. The next is wary and assumes a fighting stance, but the scream dies in her throat as you put her down.

		*if ((combat >= 25) or ((quickthinking + survival) >= 40))
			*if ((enclave_purpose = "fight") and ((combat >= 15) or (survival >= 15)))
				*comment SUCCESS W/ WOLFIES
				It takes a few moments before you realize you are not the only shadow crisscrossing the impromptu battlefield. The smell, though, registers fast. 

				"We do not like being left out of the fun," whispers Roan, who is suddenly crouched beside you. You catch a glimpse of her eyes, which are hidden as usual behind her near-white hair, but through the curtain you can see a reflection of the sentries' flames. It makes her seem eerie, otherworldly.

				The others from the Wolf enclave are nearby as well. They are hidden from the increasingly agitated group of diminishing guards. You cannot imagine they will be ignorant for long. 

				"The Rising Sun know something is wrong. They will send more swords. We will hold them off while you enter the fortress."

				You attempt to reply, but Roan is already gone, back into the growing fray.

				*goto wolf_aid_cont
			*else
				*comment SUCCESS ALONE
				*set death_toll +10
				*if pacifism
					*set pacifism_broken true
				It is a matter of moving outside of the limited peripheral vision of your prey. You stay outside of what they can see, like a nightmare whose details dissipate with the dawn, but you are very real. 

				One of the soldiers catches you as you emerge from the dark like some living horror and he takes a step backward. His body moves sluggishly compared to your superior speed. You grin when he goes down. The feeling is a visceral satisfaction of a successful hunt, but you slip back into the shadows before anyone else can spot you. 

				As the number of Rising Sun soldiers dwindles, they begin to band together, hoping to use superior numbers to fight off whatever is stalking them on their own doorstep. But their fear makes them weak and when you attack in earnest, trading subterfuge for force, they break ranks. 

				This makes them easier to kill.
				*goto fort_fightentry
		*else
			*if enclave_purpose = "fight"
				*comment FAILURE TURNED WOLFIE SUCCESS
				The first few soldiers go down easily, but they are missed. Too many more answer their disappearance, and you are placed in an awkward spot. 

				You fight off the first few, but their supply of bodies is greater than your endurance. Things begin to look dire. 

				*goto wolf_aid
			*else
				*set fortress_fight_fail true
				*comment FAILURE
				You are strong enough and fast enough to dispatch many of the soldiers before they can cause too much trouble, but the increasing body count draws the wrong sort of attention. The soldiers you take down are quickly replaced. 

				You fight valiantly. Harder than anyone else could have, but their superior numbers overwhelm you before long.

				*goto fort_prisonentry
	#Sneak past the sentries without arousing their suspicion. Their slow, mundane vision will never catch me.
		*label sneaking_choice
		*set action %-5
		*set deliberation %+5
		*set selfishness %-5
		*set equity %+5
		The wetness of the marsh is both excellent cover for the noise of your footsteps and an irritating encumbrance, slowing you down with each dragging step.

		However, you move quietly and know to avoid the wide sweeps of light coming from the sentries' torches. 

		*if ((quickthinking + sensitivity) >= 35)
			*if ((enclave_purpose = "fight") and (quickthinking >= 15))
				*comment SUCCESS W/ HELP
				The watching, though, is the longest part. As you wait for some pattern, some flaw in the rigid order of the Rising Sun patrol to reveal itself, you discover something else: You are not the only wolf in this marsh. 

				A whooping cry catches your attention, and you see a flash as Zev and Roan throw themselves in tandem into a very surprised patrolwoman. 

				Suba knocks a man senseless and then rests his lolling head on her bosom as she dances in circles, laughing brightly as if she's suddenly become unhinged. She shouts, "This one is courting me. How sweet!"

				You catch the scents of Hemming and Fillin, too.
				*if lyall_fate = "live"
					Even Lyall is fighting out there in the dark.
				*comment endif 

				Their commotion makes for the perfect distraction. You will not have a better moment to infiltrate the fortress, so you take it. 

				*goto fort_wolfsupported
			*else
				*comment SUCCESS ALONE
				It takes a great deal of patience as you wait for the right moment, but you also need the wisdom to notice the moment when it comes. You stay crouched in the muck of the marsh until your thighs ache with the strain of your stooped position, but little by little the rhythm of the Rising Sun patrol reveals itself to you. At the changing of the guard you have a chance, maybe the space of four long breaths, if you are moving quickly, to cross the threshold and disappear into the fortress.

				The guards should not be able to see you from where they are standing, as you are practically flush against the fortress wall and they are more likely to be expecting an attack from a group of angry locals than a lone ${man_woman}.

				You wait for your moment and then you move.
				*goto fort_sneakentry
		*else
			*comment FAILURE, TURNED GROUP SUCCESS
			You wait for the right moment, knowing it could be hours before you can slip inside the fortress unnoticed. Finally the opportunity presents itself; the changing of the guard. 

			You move, fast, maybe too fast. A single wrong step into a deeper-than-it-looks mud puddle makes a wet squelch that draws the attention of a nearby soldier. She looks over at you with huge brown eyes, and then she cries out before you can silence her. 

			The rest of her patrol converge on your location and you crack your knuckles. A fight is inevitable. 

			*if enclave_purpose = "fight"
				*goto wolf_aid
			*else
				But with superior numbers they easily overwhelm you and they drag you, half-conscious, into their fortress. 

				*goto fort_prisonentry
	#Wrap myself in an arcane guise through the use of complex ritual and stroll past them.
		*label ritual_choice
		*set action %-5
		*set deliberation %+5
		You begin to wrap the protections of the marshland around you in layers that press nearly into your skin. The marsh is slow to recognize you.
		*if tribe = "Quiet"
			The marsh sludge runs true through your veins, despite how long it's been since you have wet your feet in it.
		*comment endif

		*if ritual >= 20
			You adorn yourself until you are nearly suffocating in the thick, moist air. Only then do you step out where you might be seen. 

			*if enclave_purpose = "fight"
				*comment SUCCESS W/ WOLFIES
				You walk past a sentry who waves her torch in your direction and, despite a momentary pause, just continues on her rounds. 

				You have nearly reached the heavy double doors through which you need to pass, but as you are about to enter the fortress, someone nearby looks in your direction and squints hard into the night. You wonder if you are about to be discovered, but there is a commotion elsewhere which draws the sentry's attention.

				You hardly even need to look over in the direction the noise is coming from. Their smells are easy to differentiate now that you have met them all: Hemming, Suba, Fillin, Roan. 
				*if lyall_fate = "live"
					Even Lyall has come to join the attack. 
				*comment endif

				You wonder if their sensitivity allows them to pierce the veil of your rite and see through it, but you don't spend too much time considering it. You take the opportunity afforded by their intervention and slip into the fortress while the sentries are distracted.

				*goto fort_sneakentry
			*else
				*comment SUCCESS ALONE
				The sentries are paying keen attention to the dark where dangers lurk, but even the sharpest eyes among them see nothing as you pass. You suspect a practiced ritualist might pierce the veil of your rite, but none exist among these soldiers. 

				You are able to move past the bulk of the Rising Sun's guards, which puts you in front of the massive double doors at the entrance of the fortress. You have to wait for quite some time before a changing of the guard when the doors open. You slip inside.

				*goto fort_sneakentry
		*else
			You take the first step out into direct light, where you might be seen; it is a moment where you have to trust absolutely in your abilities.

			The first of the sentry spots you from a dozen or so paces off and squints hard into the dimness. He cannot see you, exactly, but is clearly suspicious about something…moving, shifting perhaps, in the dark. Your ritual is not iron-clad. There are holes in your disguise. 

			*if enclave_purpose = "fight"
				*comment FAILURE SWITCHED TO SUCCESS B/C WOLFIES
				The sentry who spots you does not wait to confirm what he's seeing and quickly calls others to his side. They form what seems to be a considerable fighting force, which you are unprepared to engage. 

				Lucky then that before the Rising Sun soldiers attack, there is a whoop that distracts them and draws your attention as well. 	

				*goto wolf_aid
			*else
				*set fortress_fight_fail true
				*comment FAILURE ALONE
				Before you can decide to double-down on your ritual, shore up the broken places, or fight, the sentries are upon you. They cautiously form a semi-circle around you and attempt to hem you in. Once your ritual is exposed and you let it drop to ease the strain on your mind and spirit, the sentries drop the pretense of maintaining a polite distance. They close in and you are somewhat sardonically grateful that they do not club you to death.

				*goto fort_prisonentry
	*if (riser_affinity >= 60) #[i]Rising Sun ally[/i]: Announce myself and demand to be taken to their commanding officer.
		You walk into the wide corona of light cast by the torches scattered before the Rising Sun fortress, and the nearest soldiers snap to attention.

		*goto riser_escort
	*if (eel_affinity >= 60) #[i]Eel Favor[/i]: I can viciously turn the entire marshland against the Rising Sun patrol using ritual.
		*label ritual_violence_choice
		With the marsh firmly beneath you—the muck of it pressed under your feet and the heavy wetness of it settling onto your ${hair_choice}—you feel powerfully connected to the living world. 

		You can feel the Riser soldiers, too. It is a bit less immediate, but their essence is certainly present. All you need to do is let the marsh recognize them as enemies. Simple enough.

		It starts with a few mosquitoes. Hardly more than an annoyance. At first.

		*if ritual >= 20
			*if ((enclave_purpose = "fight") and (ritual >= 15))
				*comment SUCCESS W/ WOLVES
				But then a cloud of them descend on the Rising Sun patrol, a horrible stinging swarm. But the mosquitoes, as terrible as they are, are the least of the Rising Sun's problems. 

				You hear a low, deep keening. Not more than five breaths later, the members of the Wolf enclave are running out of the brush directly at the distracted, besieged Risers.

				The wolves are all there: Zev, Roan, Hemming, Suba.
				*if lyall_fate = "live"
					Even Lyall arrives alongside them.
				*comment endif 

				The mosquitoes largely ignore the Wolf enclave, instead focusing their malice on the Risers, which makes it hard for them to fight back. Suba, fresh from half-eviscerating a man, makes eye-contact with you and laughs. 

				"Still here, ${prenom}! You have business elsewhere, no?" She throws a thumb toward the fortress, then re-enters the fray. 

				*goto wolf_aid_cont
			*else
				*comment SUCCESS ALONE
				When dozens, then hundreds, then thousands of mosquitoes descend on the Rising Sun patrol, the situation becomes considerably more serious. The guards scream as the mosquitoes feast on them, driven by some horrible menace. It does not help that the very ground beneath their feet is shifting and sliding, as if a sudden, unseen rainstorm has soaked the ground and turned it into mud. The Rising Sun soldiers cannot flee the cloud of bloodsucking insects, and the condition of the area makes it impossible for their compatriots inside the fortress to rescue them.

				That does not stop others from trying. 

				*goto fort_fightentry
		*else
			*if enclave_purpose = "fight"
				*comment FAILURE TO SUCCESS, WOLFIES
				The insects are vicious: they bite their way through the Rising Sun sentries, sending them into a state of absolute chaos, but when the soldiers notice you as well, they manage to rally themselves and close ranks against you. 

				It is an unexpected turn of events and you are unsure if you can fight your way through them, especially after marshaling so much of your will for the ritual. 

				You take a deep breath, preparing yourself for what comes next…

				*goto wolf_aid
			*else
				*comment FAILURE ALONE
				*set fortress_fight_fail true
				The dozens, then hundreds, then many thousands of mosquitoes attack the unsuspecting Risers. They swat futilely at the sudden insect horde, but their ineffective counter-assault against the aggressive mosquitoes proves largely ineffective. 

				The discomfort and irritation of the Rising Sun gives you a certain level of confidence when you approach the fortress, but the soldiers prove themselves better trained and sturdier than you suspect. They spot you through the cloud of insects and quickly close ranks against the threat. 

				You hardly expect such a quick recovery. Three members of the patrol lie on the ground, struggling to stand, but the others attack you outright. You are forced to defend yourself, but you are unprepared and exhausted from your ritual. It is not long before they overwhelm you. 
			
				*goto fort_prisonentry

*label fort_climbentry
*set infiltrate_type "stealth"
*page_break
You climb into the fortress through a cracked arrowslit high on the western wall. The maneuver requires a great amount of contortion and you scrape the skin off of one shoulder, but you manage to pull your body through.

You take a deep breath once your feet are firmly under you again.
*if enclave_purpose = "fight"
	Naturally, you worry about the enclave and how they are doing against whatever resistance the Rising Sun is throwing at them, but you have to trust in their abilities now. 
*comment endif 

The inside of the fortress is lackluster: thin hallways and sconces burning stinking oil. You follow the vague, distant animal-scent that you assume belongs to Bear's avatar, but the scent leads you to a locked room, which you break into, only to find an armed man awaiting you. His bearing and the glittering sword at his waist suggest he is more than just a soldier. 

*goto sen_intro

*label fort_sneakentry
*set infiltrate_type "stealth"
*page_break
The halls of the fortress are thin. You imagine a small group of defenders could claim an advantage and hold out against a larger force. It is a sensible design, but it does not help now that you are already inside. There is no one to guide you, so you are forced to move slowly and carefully through the halls of the fortress and create a map in your mind of the places you have already searched.

You move higher and higher through the structure until near the very top of the fortress you find a locked door. The lock was designed to keep someone out, but not you.

Behind the door is an armed man who wears the regalia of the Rising Sun, but his bearing and the glittering sword at his waist suggest he is no mere foot soldier. 

*goto sen_intro

*label fort_prisonentry
*set infiltrate_type "disgraced"
*set restraint %-15
*page_break 
The Rising Sun soldiers half march and half drag you through the close halls of their fortress. They have beaten you badly, but you can already feel your cracked bones and split skin knitting back together. It would take something altogether more decisive to kill a vessel of the gods. The pain however is still fresh and sharp; a clear reminder of your failure.

They drag you up into the higher reaches of the fortress, then throw you into a room where a well-armored man awaits you. 

You look around while struggling to your feet. The offices are spacious, but without luxury. The man, you gather, is the leader of this fortress. 

*goto sen_intro

*label fort_allyentry
*set infiltrate_type "friendly"
*page_break
The Rising Sun soldiers on either side of you walk with their backs straight, but their fingers clench too tightly around their weapons. Whatever trust they place in your alliance with their cause is tenuous and threatens to spill over into reactionary violence. 
*if selfishness > deliberation 
	You cannot help but smile at their discomfort. Let them fear you then. Perhaps it will keep them in line. 
	*goto ascend_fort
*else
	It is disappointing that despite your proven regard for the Rising Sun there is still so much tension between you. But in a world so marked by strife, what could be different?
	*goto ascend_fort

*label fort_fightentry
*set infiltrate_type "fight"
*page_break
The soldiers of the Rising Sun lie broken or dead at your feet. The lucky ones have scattered, tripping and stumbling into the dark where any number of predators await them. None worse than you. 

All that is left is entering the fortress itself. 
*goto ascend_fort

*label fort_wolfsupported
*set infiltrate_type "wolfhelped"
*page_break
The sounds of conflict between the Rising Sun and the members of the Wolf enclave grow distant as you near the entrance of the fortress. Perhaps you should have stayed and fought alongside them, but you have the feeling that the extremely self-sufficient members of the cohort would have resented such an obvious lack of faith. 

In truth, your goal lies before you. 

The interior of the fortress is all awkward angles. You can imagine a group of defenders with their backs pressed into the walls defending against a hundred invaders. Unfortunately for them, the invader has already penetrated their stronghold, and the winding nature of the fortress will make you, a sole person, all the harder to find. 
*goto ascend_fort 

*label ascend_fort

You ascend tight, winding stairwells and pass through dim hallways where sconces burn stinking smoke into the stifled air. It is a relief when you reach the spacious, cool offices of the fortress's commanding officer. 

*label sen_intro
You would have expected a stouter man, or older at the least, to be a commanding officer. It brings to mind the fact that the Rising Sun is a young organization without the deep roots of the old faith. Young, but not without teeth.

Though this young leader of men holds himself casually, there is something brutal in his demeanor. 

"Welcome to the fortress we call Unfailing Light, ${prenom}. 
*if riser_affinity < 60
	Though I wish it were under better circumstances.
	*goto cpt_convo
*else
	I thank you for being civil with my men thus far.
	*goto cpt_convo
*label cpt_convo
I am Commander Sen of the Brilliant Spear contingent, but just Sen is fine. I am the leader of this rabble, I suppose. For now anyway. I have received many reports about you: your intercessions in Ishko, Mara's Caravan, even the business with our Clearwater neighbors to the north.
*if enclave_purpose = "fight"
	We see your influence everywhere and we wonder what it is—"

	The muffled sounds of shouts rise up to the windows of the office and Sen turns to look. You do not have to. You can hear the howls, snarls, and war whoops of Wolf worshipers storming the fortress. They were committed to bringing the fight to the Rising Sun and there was never any doubt they would be true to their word.

	Sen is less impressed. 

	"Zealots. They imagine themselves animals and act as such. I hesitate to command soldiers to slaughter them, but it seems the only language they will heed. But you could call them off. I would consider it a gesture of goodwill."

	*choice
		#Try to call off the Wolf enclave.
			*set deliberation %+10
			*set action %-10
			*set restraint %-5
			The guttered embers of whatever spirit Wolf left inside you are sparked to a low flame when you offer to call off the enclave. Compromise is not in Wolf's language. You struggle to get the words out through gritted teeth. 

			"I can try to call them off. I cannot guarantee they will listen."

			Sen opens a broad and heavily reinforced portal almost big enough to climb through. It looks out on the half-lit marshland evening. Far below you can see the enclave members fighting Rising Sun soldiers. They are outnumbered, but still holding their own. 

			You call the retreat.

			*if enclave_leader = "you"
				*set riser_affinity %+25
				The Wolf worshipers are clearly confused, but they hear your voice and they heed it. They retreat slowly, suspiciously, at first, but after Sen calls for his own men to retreat, the Wolf enclave quickly scatters into the trees and are gone.

				You step out of the window. Sen looks relieved. 

				"Thank you, ${prenom}. You have saved lives today. Lives of people who are important to both of us. I will not soon forget that. But now we should talk about why you are here."
				*goto cpt_convo_2
			*else
				*set riser_affinity %-15
				*set wolves_harsh_fate true
				The Wolf worshipers stop when they hear your voice, but then one of them-Suba, perhaps-screams something that you cannot glean from your height and the enclave continues fighting. If anything, your call for retreat seems to have further inflamed them, and the Rising Sun soldiers are losing ground more quickly. 

				Sen is, unsurprisingly, angered by this turn of events. 

				"I suppose wolves are not easily corralled. Luckily I have more men than your allies have sense. As for you and I, my preference would be to have this business between us resolved as soon as possible. So why are you in my fortress, ${prenom}?"
				*goto cpt_convo_2
		#Stay out of their conflict.
			*set riser_affinity %-15
			"Your conflicts with the worshipers of Wolf are your own and perhaps not without merit," you counter. "I will not intercede."

			The Riser leader draws himself up. "Spoken like a true adherent of the old gods. Unyielding. Unconcerned about the damage your inaction will cause. Never mind then. My soldiers will make quick work of them.

			"But as I was asking, before the temporary interruption: What do you want?"
			*goto cpt_convo_2
		#Refuse to call them off.
			*set riser_affinity %-30
			*set restraint %+10
			*set action %+10
			*set deliberation %-10
			*set wolves_harsh_fate true
			"They will tear your soldiers apart and if they die in the process then they will have died for a worthy cause, but they will not go without taking many of your people with them. So perhaps you should give up instead?"

			Sen looks at you for a long time before laughing bitterly.

			"You are just as much of a beast as I had heard, ${prenom}. So we talk while our respective followers kill each other? I have to wonder: What is it that you actually want?"
			*goto cpt_convo_2
*else
	Everywhere we see your influence and wonder what it is you actually want?"
	*goto cpt_convo_2

*label cpt_convo_2
*page_break 
*if fortress_fight_fail
	Sen crosses his arms tightly in front of him.

	"I assume from the fact that you came here uninvited and caused trouble with my men, that your intentions are less than benevolent."
*comment endif

Your most pressing goal is Enyeto and you tell him as much. Sen shakes his head and makes a noise of disgust. 

"I wish we had never encountered the damnable Bear. His presence has brought nothing but conflict. Even as quiet and unassuming as he is, merely keeping him in our dungeons has rallied the locals against us. But what other choice did I have? He killed one of our own. Keeping my soldiers in line, in tune with the purpose of the Rising Sun, means telling them that every one of our lives is as important as the lives of the gods and their messengers. Allowing Enyeto to kill even one of our own without punishment goes against that message."

He strokes his close-cropped beard. 

"We cannot keep him here indefinitely without charge. But the charge can only be death, and sentencing the Bear avatar to die? It would mean open war with the old guard. Who would that serve? No. The Rising Sun's goal is to prepare our people for a world without gods, not necessarily to hasten that conflict."

He shakes his head, says to himself, "Each option is worse than the last."

*choice
	#Request that Sen free the Bear avatar.
		"Free him?" Sen asks, laughing. "Just like that?"

		The mirth fades quickly. "You are serious?"

		"If you cannot kill him and you cannot keep him, what other choice do you have?" you ask. 

		"My men will cry bloody murder." He rubs the crease between his brow. "But it makes sense, I suppose. As much as any of this makes sense."

		*if riser_affinity <= 50
			"Yet I am not inclined to do you any favors, ${prenom}. You have made things very difficult for me and my people. So I am unsure why I should do as you say."
		*comment endif

		He considers your proposal for a while longer before sniffing and spitting into a corner. 

		*if riser_affinity < 50
			"I will take your suggestion under advisement, but this will not happen overnight. The question weighs upon me and I will give it the consideration that it is due. For now, you may speak with him."

			*goto enyeto_meeting
		*else
			"Consider it done. You may go speak with him. One of my men will show you the way."

			*goto enyeto_meeting
	#Have Enyeto sentenced to death.
		*set sen_death_request true
		Sen does not attempt to hide his surprise at your recommendation. 

		"I admit that I did not expect you to counsel execution for the Bear god's representative. I have been considering his fate for a long time. Perhaps longer than I should have." 

		Sen shakes his head. 

		"I will take your suggestion under advisement, and perhaps you should think over your request as well. Killing the gods' own avatars sets a precedent that will be difficult to undo. It is a decision which, for better or worse, will bind us to each other. You should speak with him before you make any rash decisions. I insist." 

		You are not thrilled to be counseled to caution by a member of the Rising Sun, but Sen will not budge from his position. 

		"Then take me to him," you say. 

		"Of course. Follow me," the commander says. 
		*goto enyeto_meeting
	#Ask to speak with Enyeto before any decision is made.
		*set sen_accompany true

		"Not an unreasonable request. I can take you to him myself and then we can discuss what to do. Is that fair?" Sen asks. 

		You agree that it is. 

		"Good, then follow me, Wolf avatar."
		*goto enyeto_meeting
	#Assassinate Sen. If I remove the Rising Sun's regional leader, it may help destabilize their forces and weaken them, simplifying my business with the Bear avatar. 
		It makes sense for the Riser leader to die. His elimination will strike a blow against the Rising Sun in the region, and while they regroup, their enemies will have time to rally against them. But it will not be easy.

		How will you go about it? 

		*choice
			#Catch him unaware and overwhelm him.
				Perhaps it is meaningful that Sen's hands lay by his side, just a hand-span too far from his weapon to seem menacing. But you are resolved and whatever the outcome, you will strike. 

				You move like a loosed arrow. It is the only way to get to Sen without an inevitable counterattack.

				*if quickthinking >= 15
					You vault the desk between you and watch as the Rising Sun commander comes to the too-slow realization of your intentions to kill him. 

					His hand goes for his sword. It is close, but for his sake, it is not close enough. 

					You make it clean, which is the least you can do for a worthy adversary. 
					*goto kill_success 
				*else
					But the counterattack that you fear comes swiftly and the lash of his blade uses your momentum against you and slices a wicked wound down the left side of your body as you move inexorably along its edge. You crash into the ground and Sen stands over you with his sword at your neck. You can heal from the bloody gash in your side and you can heal quickly, but not if he kills you. Especially not without Wolf living inside your skin.

					*goto kill_fail
			#Turn the elements within the room against him.
				You expect the commander of the southern Rising Sun forces will be formidable, so you are prepared to take some extraordinary measures to make sure he does not survive your attempt on his life. You conceive of a ritual that might work.

				It is difficult to reach out to the elements of the room, so far up from the earth, and closed off to the wind and open air by stone. Yet there are burning lanterns, there is dust, there is water in the air. It is not impossible. 

				*if ritual >= 20
					Sen stands at his desk and you coax the flames, cajoling their inchoate heat to violent purpose. Sen looks over at the flickering fire in his lantern, perhaps suspecting some invisible tampering. He goes to take a step back, but you have seized the fire's imagination and it bursts outward with longing.

					The commander is caught in the fire, which swirls around him. He screams, but even the sound dies in the face of this enchanted flame.

					*goto kill_success
				*else
					Sen is standing so close to the flame at his desk that when you beg the flames to reach out, to explode into violence, he is caught in the blast. The fire licks his upper torso, but he dodges out of the way instinctively and avoids the worst of it. 

					He comes toward you, sword drawn, and nearly before you can react, he drives the point of his sword into your shoulder. The pain is considerable, but the wound will heal as long as you stay alive. As for your assassination attempt, it is obvious that is over now. 

					*goto kill_fail
			#Attack him outright. Anything else would be cowardly.
				You don't bother with pretense. 

				If Sen does not see you coming, he will be easier to kill and you will feel cheated. So you come directly at him. He draws his sword with surprising speed and slices in your direction. 

				*if combat >= 20
					You get in close and Sen's sword is suddenly considerably less useful. He is unable to draw it to full length in close quarters and you easily disarm him. 

					You can see the spark of fear in his expression, but he is proud enough to meet his end on both feet. He never gives in to his terror, never grovels. It is enough for you to make it quick. Clean. 

					*goto kill_success
				*else
					The first cut misses, as does the second and third. You get close enough to land a hard blow, and there's a crunch under your fist that suggests a broken nose at the very least. 

					But afterward Sen proves himself adept at keeping you at a distance. When he finally gets serious, his sword moves like a flash of light and scores a cut across your midsection. You do not bother checking the wound, it will knit as long as you draw breath, but Sen is still moving: He comes in from your left and pierces your side. The blade runs all the way through. He twists it and you fall to your knees. 

					*goto kill_fail
		*label kill_success
		*check_achievements
		*if not(choice_achieved_commanderdead)
			*achieve commanderdead
		*set sen_killed true
		*set pantheon_regard +1
		*set death_toll +1
		*set chaos_score +1
		Sen lies dead. Someone will rise to replace him, but your efforts cannot be understated. You have killed a leader of the Rising Sun militia and directly challenged the group in their own battlements.

		You can imagine the look on the faces of the Wolf enclave members when they learn what you have done. You can also imagine the fury that will rain down upon them as the Rising Sun seeks retribution for the murder of another one of their own. 

		But you cannot consider consequences while your own life is still in danger. You have to find Enyeto before the entire fortress erupts into chaos.

		You leave Sen's office and seek out the cells of the fortress. They are not at the lowest point of the structure but the highest.
		*goto enyeto_meeting

		*label kill_fail
		*set defeat_by_risers true
		Sen breathes hard and scowls at you, but after a while a crazed smile crosses his bloodied face. 

		"It has been a while since someone took a shot at me, ${prenom}. Even longer since it was a good shot. So here's what I will do. I will not order your immediate execution, like I should. Instead, I invite you to be our guest."

		Sen whistles loudly, and within moments a number of soldiers pour in from the door behind you. 

		"Take ${him} to the cells. I am sure 
		*if gender = "none"
			${he} have
		*if gender != "none"
			${he} has
		a lot to discuss with the Bear avatar," Sen says. His voice is cold. 
		*goto enyeto_meeting

*label enyeto_meeting 
*page_break
Enyeto's cell is not the light-starved menagerie of horrors that you expect. It is a well-appointed room that features a reinforced iron gate, but also two large windows and a modest bed.

The Bear avatar sits on the floor with legs folded underneath him. His craggy face and long, greasy hair—studded with colored beads—are not flattering, but his gray-blue eyes are immediately striking. He takes a look at you and draws a deep breath.

"It was suggested that I should expect you," he says. "What a very long way you have come to be disappointed, Wolf-kin."

"My name is ${prenom}."

"That it is. But names are not so important to us, are they? Titans in the skin of lambs."

Enyeto laughs, dry and hoarse.

"Excuse my lazy philosophies. I have had too much time to think. But I imagine you are not here to think, ${prenom}. I think you are here to do something rash. So let us talk for a moment about unpleasant things. About murder and consequence."
*page_break 

Enyeto shifts on the floor and clears his throat.

"My knees ache in this wet hell. I cannot imagine how Eel slithers around in this muck," he says, then smiles. It fades quickly. "The man I killed aimed to provoke me. I knew that patience was the higher path. Yet it took only a little of my anger, a flash, and he was dead. Such is the burden of our horrible strength, ${prenom}, that the lives of others are reduced to blood and bone in moments."

"So I am here. It is penance, of a sort. Do the Rising Sun deserve their anger and outrage for their dead colleague? Perhaps. But it is not their outrage that keeps me here when the full weight of Bear's fury could break this fortress like a pile of twigs. It is the fact of my strength, and theirs. Either of which could tear our world apart. And, if set against each other, most certainly will."

*if sen_killed
	"You come before me smelling like the blood of our enemies and it tells me that I must be right. Slaughter is the destiny that we have made for ourselves."
	*goto next_sen_convo
*elseif defeat_by_risers
	"You are beaten and humbled. Well, perhaps not humbled. Never that. Chastened, though, for the moment. It is an important thing to learn humility at the hands of your enemies."
	*goto next_sen_convo
*else
	*goto next_sen_convo

*label next_sen_convo

Enyeto sighs. 

"I will let you speak for yourself, once-bearer of the Wolf soul. Kin. What will be done about the Rising Sun? Let your will be known, and know that all your sister and brother gods will hear your answer."

*choice 
	#"Violence. Conflict. These will not heal the wounds we have inflicted on each other."
		*set deliberation %+10
		Enyeto is quiet for a long moment, then replies. 

		*if (((action >= 75) or (sen_killed)) or (death_toll >= 5))
			*set pantheon_regard -1
			*set bear_affinity %-30
			"You pay lip service to an end to violence, while tearing the throats out of your enemies. A Wolf and a snake as well. It is either that you do not know yourself or that you think your siblings do not know you, Wolf-kin. Either way, the result is the same and it is unfortunate."

			*goto enyeto_cont
		*elseif pacifism
			*set bear_affinity %+30
			*set hawk_affinity %+25
			*set eel_affinity %+15
			*set ara_affinity %-15
			"You are a truer adherent to the path of non-violence than I am, Wolf-kin. I am ashamed to come before you with blood on my hands like an animal while yours remain clean."

			*label enyeto_apology
			"I am humbled to admit that I did not think you could be more than Wolf's jaw. A snapping, snarling thing without discrimination, devoid of empathy. I was wrong. I misjudged you, and I will try not to make the same mistake again."

			"I agree that we should take a measured approach to the Rising Sun and seek diplomacy when it is available to us. My greatest hope is that there is still a way to resolve these tensions without further bloodshed."
			*goto enyeto_cont
		*else
			*set bear_affinity %+15
			*set hawk_affinity %+5
			*goto enyeto_apology
	#"Only force will dissuade further…misunderstandings with the Rising Sun."
		*set action %+10
		*set hawk_affinity %-10
		*set ara_affinity %+15
		*set eel_affinity %+15
		Enyeto shrugs. His massive frame heaves upward and crashes down like the tide. 

		"Blood is your language, Wolf-kin. It was ever so. But I had hoped distance from Wolf's long shadow would have given you nuance. Perspective. It is possible that it could not have been otherwise, that Wolf settled into your skin because you were the perfect vessel; you were a creature without the flaw of empathy. I cannot agree, but that should not surprise you. We stand on opposing shores. I hope one day you will come to see my wisdom."
		*goto enyeto_cont

	#"The gods and their avatars have little place in the discussion. Let individuals make their own decisions."
		*set equity %+10
		*set eel_affinity %-10
		*set hawk_affinity %+10
		*set ara_affinity %+20
		*set bear_affinity %-5
		Enyeto listens carefully, then takes a long pause to consider your words before shaking his head sadly. 

		"We must be deliberate. Careful. This is true. We must not act in haste, but eventually we must act. It is the nature of gods to decide, if necessary, to compel. Otherwise we are no more empowered than the tree or the rain to change and shape the world."

		"And we should decide what the world looks like?" you ask.

		"If not us, then…" He spreads his hands, as if the gesture alone was an answer. "We cannot become inert. There is no strength in standing by forever."
		*goto enyeto_cont
	#"Each of us must make our own decisions. Our own desires and goals are the only compasses."
		*set selfishness %+10
		*set ara_affinity %+25
		*set bear_affinity %-15
		Enyeto stares at you for some time before replying.

		"Myopic self-regard is the shortest road to tyranny. If we cannot be relied upon to hold ourselves to a benevolent standard, then chaos is the only future we deserve. Whatever primordial force wrought us into being, Wolf-kin, gave us the benefit of strong-willed siblings to keep us true. Our pantheon has no guardian than dissent, then eventual consensus. It is disappointing, though perhaps not unexpected, to hear that you think otherwise."
		*goto enyeto_cont

*label enyeto_cont

The Bear avatar climbs to his feet slowly.

"I am glad to have met you, ${prenom}.
*if bear_affinity > 50
	I am comforted to know that you are out there, helping to keep the world from slipping into disarray. 
*if bear_affinity <= 50
	Even if we are not exactly of the same mind.
*comment endif

"But it is past time you left, and I need to decide what to do with myself."

*if ((sen_death_request) or (sen_accompany))
	Sen leans against a wall, just out of Enyeto's sight, but neither of you are foolish enough to assume that the Bear avatar does not know about his presence. 

	Sen's frown deepens the lines around his mouth and you wonder if he is older than he seems. 

	*if sen_death_request
		"Do you still think he should die? Or is it different now, having spoken to him and heard his side? Or is it important enough to secure this victory for the common man?"

		*choice
			#"Yes. Enyeto dies."
				*label enyeto_dies
				"I see. It will be done, Wolf avatar, but, if I may ask, why call for the death of one of your own?" 

				*choice
					#"If we mean to stand up to the gods, we will have to shed blood sooner or later."
						*set action %+10
						*set deliberation %-10
						"You are not wrong, ${prenom}, but I suppose I had hoped it would be later," Sen replies.

						*goto enyeto_death_scene
					#"Enyeto is weak-willed. He let himself be taken and remains here still. He deserves to die."
						*set selfishness %+5
						*set equity %-5
						"Remind me to never prove myself any less than a stout warrior," Sen says. It is a joke or something like it, but it comes out with a touch of apprehension and bitterness. 

						It does not bother you if Sen finds you capricious. He will be careful not to cross you then. It works to your favor. 

						*goto enyeto_death_scene
					#"Why? It is my will, my authority, and I am strong enough to enforce it."
						*set action %+15
						*set selfishness %+15
						*set deliberation %-15
						*set equity %-15
						"And just like that, you condemn a man-in fact more than just a man-to his death? I wonder if it is strength of will you enforce or mindless slaughter? For now though, it matters little. His death serves the same end."

						Whether Sen finds you brutal or kind, as long as he does as you ask, then he proves his usefulness. 

						*goto enyeto_death_scene
					*if (sensitivity >= 20) #"I do not trust him. He is not telling the whole story."
						*set equity %+10
						*set selfishness %-10
						*set action %+10
						*set deliberation %-10
						"That is very likely. The gods do like their games. But what is it that you suspect?" Sen asks.

						You cannot be sure, but you do know that lying to the Wolf avatar is not a wise course of action. Executing Enyeto will not harm Bear himself, but it sends a strong message to the ursine god that you are not to be trifled with.

						*goto enyeto_death_scene
			#Ask Sen to set Enyeto free.
				*label enyeto_freed
				*set bear_fate "free"
				Both Sen and Enyeto seem surprised that you are asking for the Bear avatar's release, but ultimately the Riser commander just shakes his head and points at the nearest guard. 

				"You heard our guest. Release the prisoner."

				The guard unlocks the cell and Enyeto stares for a while at the open door before climbing to his feet. 

				"This changes nothing, or at least, very little. Our conflict with the Rising Sun will not end here, despite this small mercy," Enyeto says. His expression is grave. He continues, "Yet, it is a start perhaps. A gesture that will not be soon forgotten."

				Enyeto gathers what few things he has and leaves. Sen shakes his head. 

				"Not the wisest thing I have done today," he says. "But perhaps you can make it worth my while and pay the debt that you just incurred."

				*goto joining_rising_sun
			#"No. Let him live, but keep him here."
				*label enyeto_in_chains
				*set bear_fate "imprisoned"
				"I see," Sen says. "If I am honest, I think that is the wisest course of action. If the Bear avatar lives, we can keep an eye on him and potentially use him as leverage later on. It makes sense."

				"I have one request, ${prenom}."

				The commander makes eye contact with you and his gaze is steady and sober.

				*goto joining_rising_sun
			*if (riser_affinity >= 55) #"It is your decision to make, Commander Sen."
				*label enyeto_sen_decides
				*if riser_affinity >= bear_affinity

					"His life is not worth the trouble," Sen says. 
					*label enyeto_death_scene 
					*set chaos_score +1
					*set ara_affinity %+20
					*set bear_affinity %-20
					*set hawk_affinity %-20
					*set bear_fate "dead"
					It is as simple as a nod of the head, and Rising Sun soldiers, in their immaculate sunburst armor, are rushing into Enyeto's cell. The Bear avatar does not struggle, which somehow makes the exchange harder to watch. Their weapons rise and fall in sync and the whole thing is over in moments.

					You are left standing beside the executioners of a god. Their blades drip onto the stone floor. 

					"We are bound up in this together now. It may not be clear to you, but our purposes may not be so dissimilar."

					Sen's eyes glitter like dark gems. 

					*label joining_rising_sun
					"Help us remove the gods from their perch. We must look past this conflict to the future of humanity, a future without the chains of divine rule. We will not succeed without allies, and who better than the Wolf itself? They will not go easily, but we will never relent. Join our cause, ${prenom}. We need you."
					*choice
						#Join the Rising Sun.
							*check_achievements
							*if not(choice_achieved_riserjoiner)
								*achieve riserjoiner
							*set riser_affinity %+55
							*set hawk_affinity %-10
							*set bear_affinity %-10
							*set ara_affinity %-10
							*set combat +5
							*set riser_joiner true
							*label rising_sun_joiner
							*set riser_supplies true
							Sen slaps you hard on the shoulder. "I promise you,
							*if gender = "male"
								brother,
								*goto joiner_cont
							*elseif gender = "female"
								sister,
								*goto joiner_cont
							*else
								friend,
								*goto joiner_cont
							*label joiner_cont
							your aid will change the tide of our conflict with the old guard. Thank you. Likewise, if you should ever need my aid, I will be there."

							Sen gestures to one of his soldiers and they come to his side immediately. Sen rips the sunburst patch, the symbol of the Rising Sun, off of the soldier's jacket and hands it to you with a serious nod. He then turns back to the soldier.

							"Make sure our guest leaves with whatever provisions 
							*if gender = "none"
								${he} require.
							*if gender != "none"
								${he} requires. 
							I hope you will excuse me, ${prenom}. The concerns associated with running a fortress are myriad."
							*goto friendly_escape
						#Help them unseat the gods, but on my own terms. 
							*set riser_affinity %+25
							*set hawk_affinity %-20
							*set bear_affinity %-5

							"I could have foreseen a more promising outcome, but it is not in my nature to turn down an offer of aid. Thank you. Our cause will benefit greatly from the aid of such a powerful ally, whatever your reasons are."
							*goto friendly_escape
						#Refuse.
							*set riser_affinity %-10
							*set hawk_affinity %+5
							You make it clear that you have no interest in joining the ranks of the Rising Sun and Sen is quiet for a long time, before he eventually shrugs. 

							"There might come a time that you will regret this decision, but it is not my place to force you into it.
							*if riser_affinity >= 75
								Regardless, our door remains open, should you ever change your mind."
								*goto friendly_escape
							*else
								That said, I think it is past time you were on your way."
								*goto friendly_escape
						#[Lie] Promise him my help.
							*set riser_affinity %+5
							*set ara_affinity %+10
							*goto rising_sun_joiner
				*else
					"If I call for the Bear avatar's death, it could tip whatever equilibrium we have managed to cobble together thus far. We will never be allies with those from old faith, but we need not purposefully antagonize them." Sen bites his lip, then nods. "Enyeto lives."

					The Bear avatar does not seem particularly pleased or interested in this turn of events. He simply sits in his cell and passively takes in the new information.

					"But there is one other thing we should discuss, ${prenom}."

					Sen's expression grows dire.
					*goto joining_rising_sun
	*else
		"So what do we do, Wolf avatar? You've spoken to the Bear, and you know that he is not going to change his mind. So what do we do?"

		*choice
			#"Set him free. Keeping him here accomplishes nothing."
				*goto enyeto_freed
			#"Kill him. If he will not leave and he cannot stay, what else can be done?"
				*goto enyeto_dies
			#"Keep him alive, but imprisoned. It seems to be what he wants."
				*goto enyeto_in_chains
			#"Whatever you decide, I can live with."
				*goto enyeto_sen_decides
*else
	It seems the Bear avatar is on the cusp of deciding whether or not to martyr himself for his actions against the Rising Sun. Will you attempt to dissuade him or leave him to his fate?

	*choice
		*if (bear_fate != "free") #Persuade Enyeto to escape.
			*set action %+5
			*set deliberation %-5
			*if ((influence >= 3) or ((sensitivity + quickthinking) >= 45))
				*set bear_affinity %+5
				*set bear_fate "free"
				"What good are you doing here if you stay? You say it is up to us to change things about this world, if that is so, then what changes do you hope to make from within these walls?" you ask pointedly.

				The Bear avatar looks at you and in that moment, you can feel the weight of his sins pressing down on you as if they were your own. He shakes his head, and the spell of guilt and contrition is broken.

				"You are right," he says. "Though I never expected such wisdom from the mouth of a Wolf. I will leave this place, as you say."

				Enyeto stands and smoothes his wrinkled garments. He leaves his cell and the Rising Sun guards standing nearby give him a wide berth, perhaps recalling the circumstances that led him to his imprisonment in the first place.

				The Bear avatar gives you a final, curious glance and then he is gone.
				*goto fortress_pre_leaving
			*else
				"If you stay, who benefits? Everything we know is changing and you have to help make sense of it," you say.  

				He gives a ponderously slow shake of his head. "No. I will watch and wait. A measured decision, a rational one is what will help make sense of the world. I was rash before, which was harmful. I will not repeat my mistake."

				You could rage and fight and struggle, but the Bear avatar is decided and will not reconsider. It is a disappointing outcome, but you are left with no option but to leave him to his fate. You turn to leave and he says: "Be careful that you do not make mistakes of your own, ${prenom}, mistakes that you cannot undo."

				*goto enyeto_before_leaving
		#Tell him to stay, but promise to return for him.
			*set equity %+5
			*set selfishness %-5
			"You are safer here than you would be if you were being hunted through this swamp and beyond in retribution for your actions. Stay here and I will return for you after I have found what I seek. I swear. Stay alive until then."

			Enyeto seems to consider your words for a long time before he finally nods. 

			"Time will tell if you are an ally or something else altogether, Wolf-kin. But we can do nothing without faith. I will anticipate your return."

			*label enyeto_before_leaving
			You take one last look at the avatar of the mighty Bear, legs folded underneath him and behind bars that could not hope to hold him if he had a mind to tear them apart. 

			You leave the cell. Enyeto can take care of himself for now, and you have pressing concerns elsewhere.

			*label fortress_pre_leaving
			*if infiltrate_type = "stealth"
				*goto stealth_escape
			*elseif infiltrate_type = "friendly"
				*goto friendly_escape
			*else
				*goto post_combat_escape 
		#Tell him to stay. He deserves his punishment.
			*set deliberation %+5
			*set action %-5
			"You performed an act of murder. If your conscience forces you to stay here, then there is no higher law to obey," you say.

			Enyeto looks grave as he replies. "Trust me, Wolf-kin, I have long considered my fate and I have come to the same conclusion. I will stay here until there is a need for me elsewhere greater than the sum of my sins. I only hope your own conscience will lead you into such solemn reflection one day."

			You doubt that sitting in a prison cell is how you will pay penance for your actions thus far, but you keep that to yourself. 

			*goto enyeto_before_leaving
		#Tell him how ridiculous it is for him to stay imprisoned.
			*set selfishness %+5
			*set equity %-5
			"A war is brewing on our doorstep and you are sitting cross-legged on the ground. It seems to me that you are running from your responsibility to do anything at all. It would be comical, if it ceased being ridiculous," you explain.  

			"You sound more Spider than Wolf, my friend. And what do you imagine I should do? Eat the soldiers here, spit their bones from the battlements, and prove myself the awful Old God of myth?" Enyeto laughs to himself. "Wolf represents our terrible optimism better than any of us. He would act, I know, without concern for outcomes, but I am old, ${prenom}. Reaction, impulse, they will not save us. The day has grown too late for such things."

			It rattles your sense of pride to be lectured by a man who refuses to save himself, but you have bigger concerns than Enyeto's ramblings. 
			*goto enyeto_before_leaving

*label stealth_escape
*page_break
*goto leaving_fortress

*label post_combat_escape
*page_break
*goto leaving_fortress

*label friendly_escape
*page_break
*if defeat_by_risers
	*comment If you fail killing Sen
	Considering your failed attempt at murdering their commander, the Rising Sun is probably not inclined to let you back out the way they let you in, so you do not bother asking. 

	*if bear_fate = "free"
		You simply follow Enyeto's lead and leave through the bent bars and climb down the slick outer wall of the fortress. It requires a level of focus that is almost overwhelming, but your feet land on solid ground again safely enough.
		*goto leaving_fortress
	*else
		The bars on the window high up on the wall of the cell seem promising. You step back as far as you can then get a running start and bound up the wall until you can grasp the bars of the window. You test them and find them pitifully pliable. It does take a concerted effort, but you manage to bend them enough to pull yourself through.

		You have to climb down the slick outer wall of the fortress. It takes care and patience, and more than once you nearly fall. Eventually you work your way down to the ground. 
		*goto leaving_fortress 
*else
	*comment Regular friendly escape.
	It feels strange leaving the fortress without fighting your way out, but you have no illusions about what it means to be trusted by the Rising Sun. A guard flanks you on both sides and you can hardly fault them for their caution: If a wolf is in your midst, you keep an eye on it, even if it is housebroken.
	*goto leaving_fortress

*label leaving_fortress

You leave the fortress called Unfailing Light and head back into the muck and humidity of the marsh.
*if enclave_purpose = "fight"
	Less than a mile away from the fortress, you catch the scent of the enclave again. They reveal themselves before you. Some, however, are missing.

	Hemming explains.
	*if wolves_harsh_fate
		"It was a good fight. A glorious one, even. But Zev was struck down. It was…we did what we could."

		The old wolf does not say anything further, so Suba continues.

		"Roan
		*if lyall_fate = "lives"
			is with him, and Lyall is preparing to perform the necessary rites.
		*if lyall_fate != "lives"
			is with him. She will see to what needs to be seen to.
		Zev's body…" She shakes with anger, but forces herself to say the words. "His body will be consecrated for his honorable death. And you, ${prenom}. Find our god. Otherwise, Zev's essence will never be swallowed by the Great Wolf and he will never know rest. Find our god, ${prenom}."
		*goto wolf_chat
	*else
		"Roan took a bad blow. Zev
		*if lyall_fate = "live"
			and Lyall are seeing to her.
		*if lyall_fate != "live"
			is seeing to her.
		She will live, but perhaps it will be some time before she is tearing out throats on the battlefield again."

		Suba throws her head back and cackles. 

		"She-wolves do not let flesh wounds keep them docile, old dog. Your mouth spews piss." She turns to you. "And you, ${prenom}. If Roan had been killed, her essence would have wandered the tapestry of the sky forever without knowing rest in the belly of the Great Wolf. We have never feared death, but this uncertainty…"

		She looks upset, which is disturbing considering her usual bloodthirsty jocularity. "Just find him, ${prenom}. Find Wolf."

		*goto wolf_chat

	*label wolf_chat

	The enclave members wander off to whatever meeting ground they previously established. A part of you wishes you could follow them, such is the pack instinct instilled in you by Wolf. However, you know where your road leads.

	*goto post_enclave_split
*else
	You were meant to meet Enyeto here and you did that and more, but Wolf's fate is hardly any clearer.
	*goto post_enclave_split

*label post_enclave_split
You intend to 
*if prophecy_received
	return to Mara's Caravan and extract the truth from Ghazal and ${ghazal_his} god.
	*goto next_break
*else
	find ${ara_name} and get ${ara_him} to give you the truth behind Spider's prophecy.
	*goto next_break
*label next_break
*if tribe != "Quiet"
	You will be glad to get out of the sticky, bug-infested marsh.
	*goto end_scene
*else
	It will be hard to leave the familiar murky waters of the Quiet lands behind, but you have much to do.
	*goto end_scene 

*label end_scene

The paths leading out of the marsh are easier to follow than those leading in. It is almost as if the waters themselves are anxious to be rid of you. It is hard to blame them. Wolves so often make poor house guests. 

*finish
