*text_image chap_6.png center Six: The Wolflings

[i]The young Bear initiate lowered the water bucket at the top of the hill, careful not to spill a single drop. His mentor smiled.[/i]

[i]"How long do I have to do this?" the initiate asked.[/i]

[i]"A few days. Weeks. It depends."[/i]

[i]"On what?"[/i]

[i]"On how long you intend to have clean water to drink," the mentor answered patiently.[/i]
*line_break
- an oft told anecdote.
*page_break 

Lyall takes you through the woods and follows paths that 
*if survival > 15
	you recognize as being hidden or otherwise obscured. You memorize every turn so you could come back this way on your own if you had to. 
	*goto onward
*else
	wind and meander so frequently that you are hopelessly lost in under the space of an hour.
	*goto onward
*label onward

$!{lyall_he} is not much of a talker and seems content with keeping ${lyall_his} silence, which is why you are surprised when ${lyall_he} speaks. 

*if ((action > deliberation) and (selfishness >= equity))
	"It must be difficult being the fist of our living god. Each choice, each moment, a test of sorts. I cannot imagine the weight of it."

	$!{lyall_he} shakes ${lyall_his} head. 

	"I worry that I will lose perspective. Wander from the Wolf's path and into some safer life, but we are not allowed to waver, are we?"

	*choice
		#"No. We must not."
			*set action %+10
			*set lyall_affinity %+30
			Lyall smiles. It is the first time you have seen the expression on ${lyall_his} face. It illuminates ${lyall_his} rough features. 

			"It feels good to be in the presence of someone who understands the burden of the path we travel."
			*goto post_convo
		#"If it serves us."
			*set selfishness %+10
			*set lyall_affinity %+20
			*set ara_affinity %+15
			"I think it should be the other way, ${prenom}. We serve Wolf in all we do. His desires should be ours. No?"

			But ${lyall_he} is not asking you a question. $!{lyall_he} continues walking and talking as if you had not disagreed with ${lyall_him}.
			*goto post_convo
		#"If our path is well-considered, then it is right."
			*set deliberation %+10
			*set lyall_affinity %-5
			*set hawk_affinity %+15
			"Well-considered?" Lyall says the words as if they are foreign to ${lyall_him}. 

			"You disagree?" you ask. 

			"Any follower of Wolf would," ${lyall_he} says, and leaves it at that.
			*goto post_convo
		#"As long as our actions are just."
			*set equity %+10
			*set lyall_affinity %-10
			*set bear_affinity %+15
			"Justice?" Lyall asks. "What do vengeance and action have to do with justice?"

			$!{lyall_he} continues walking as if you had not spoken at all.
			*goto post_convo
*else
	"I have often wondered about the vessel of our god and how perfect such a creature must be to harbor his living soul. Do you think you deserved the honor of his presence, ${prenom}?"

	It could be your imagination, but there's something in ${lyall_his} tone that sounds like judgment.
	*if sensitivity >= 20
		The way ${lyall_his} gaze flits away from yours all but confirms it.
	*comment endif

	*choice
		*comment the affinity gains are less here, because as a non-Wolf path Lyall
		*comment automatically trusts you less. The player has to work to earn his/her 
		*comment trust. 
		#"I was a child when I was invested. I do not know that any child could deserve such a thing."
			*set deliberation %+5
			*set lyall_affinity %-10
			"Must children be without purpose? I think the savagery of our world proves that sentiment is watery, ${prenom}. Children are made to struggle. It is the only way to grow."
			*goto post_convo
		#"My actions speak for themselves."
			*set action %+5
			*set lyall_affinity %+15
			"That they do, ${prenom}. Perhaps our actions are the only thing that can recommend us in this world," ${lyall_he} says.
			*goto post_convo
		#"No. I think it could have been anyone."
			*set equity %+5
			*set lyall_affinity %-15
			"Yet it was you who he passed into. You who dreamed the Wolf-dream and survived his fever. Yet you think this means nothing. Curious."
			*goto post_convo
		#"I was chosen. It could not have been otherwise. Why question it?"
			*set selfishness %+5
			*set lyall_affinity %+15
			"You are right. Asking questions about what is inevitable only distracts us from the realities. I appreciate the clarity of your thinking."
			*goto post_convo

*label post_convo

The two of you continue through the woods as the ground begins to slant upward and the terrain grows rougher. Lyall offers you pieces of ${lyall_his} story through casual conversation punctuated by long stretches of silence. $!{lyall_he} is extraordinarily sensitive to Wolf's will, like you,
*if tribe = "Quiet"
	and like you, ${lyall_he} hails from the Quietly Swimming clan.
	*goto chat_cont
*else 
	but unlike you, hails from the Quietly Swimming clan.
	*goto chat_cont
*label chat_cont
$!{lyall_his} home clan explains the elaborate braids in ${lyall_his} hair and the light and patient drawl of ${lyall_his} speech. $!{lyall_he} led this Wolf enclave before its untimely end. 

"After Wolf went silent, we did not know what to do or where to go. I used rituals to consult my dreams and find a direction, but my dreams were always the same. I dreamed of bloodied paw prints in the snow and a mindless hunger. I was never good at interpretation," Lyall jokes grimly.

"It was never my strong suit, either," you agree. 

Lyall makes a noise that could be interpreted as a laugh and continues ahead. 

*page_break 

You travel for two nights and three days before you reach where Lyall leads you. The two of you adopt a steady, companionable flow of traveling and communicating together without the need for much negotiation. You take the first watch on the first night and ${lyall_he} takes it on the second. It is comforting, if strange, to share the duty of your security with someone else. You still remember how the Wolf kept a vigilant watch through your eyes while you slept, but those days are gone. 

One day Lyall brings up the topic of restraint. "I wonder, sometimes, if we are really ourselves, or just an extension of Wolf's will."

Lyall shakes ${lyall_his} head. "Though I am not the avatar of Wolf, my faith in him and obedience to his cause strengthens me. But the cost…I think that I exist, that my choices are mine, but I cannot be sure, can I? It is only the thin strand of my will, my restraint, that keeps me from becoming a creature of pure violence. I think, perhaps, that would be easier."

Lyall's words do not necessarily beg a response, but you have also felt that pull. Will you commiserate with ${lyall_him}?

*fake_choice
	#"We must do what Wolf wills. That is why we exist. It is what keeps us alive."
		*set survival +5
		*set action %+5
		*set deliberation %-5
		*set lyall_affinity %+15
		Lyall accepts this answer. 

		"That is true. I try to remind myself of that every day," ${lyall_he} says. "It is good that you agree. It is…comforting."
	#"It is a fine line, but walking it carefully is how we stay ourselves."
		*set restraint %+10
		*set deliberation %+5
		*set action %-5
		*set lyall_affinity %+25
		Lyall seems somewhat surprised by what you have to say. 

		"I would not have thought you would agree, ${prenom}. That Wolf's avatar shares these concerns is unexpected. I suppose we all struggle with our nature."
	#Say nothing. You would not want to influence ${lyall_his} choices, but you listen intently.
		*set sensitivity +5
		*set equity %+10
		*set selfishness %-10
		*set lyall_affinity %+10
		Eventually Lyall shakes ${lyall_his} head. 

		"Maybe these ideas are useless. Thank you, nonetheless, for listening to my foolishness."

Lyall is quiet for what is left of the trip.

The site where the remainder of the Wolf enclave has taken root is under the eaves of a dilapidated Bear temple. The ursine god was not exactly an ally to Wolf when the latter god walked beside you, but neither was he hostile. If there was a god who would give shelter to the rowdy children of Wolf, it would be Bear.

As you approach you can see a few of the Wolf worshipers hauling stones out of the temple. You look at Lyall and ${lyall_he} answers without needing the question. The two of you have developed a sort of shorthand during your brief time together. 

"We are restoring Bear's sacred space while we rest in its shade. It honors him and for now it gives us a purpose."

You quietly approve, but Lyall is their leader and you are merely a visitor, so you keep your opinion to yourself. You are only about thirty paces from the temple when Lyall stops you. 

*if ((action > deliberation) and (selfishness >= equity))
	"You follow the Wolf's path, ${prenom}. I can tell that even in your stride. That is how deeply these things run. Wolf is dead or he has abandoned us, but all we have left is the path that we walk. I have been trying to convince the others to walk the Wolf's path, to live with purpose and vitality, whether Wolf stalks our dreams or not. I need you to help me convince them."
	*goto pre_rally
*else
	"I barely know you, but I know you have diverged from Wolf's path. I can smell it on you. You are not the leader we deserve, but perhaps you can still lead. Convince them that they need to follow Wolf's impulses to their last breath. Tell them their fealty is not wasted on a dead god. That is what they need to hear and it will mean everything if it comes from you, despite how far you have fallen."
	*goto pre_rally

*label pre_rally
*page_break
You can see the zeal in Lyall's eyes and you have no doubt that ${lyall_he} is absolutely committed to the ideals of the Wolf god. Perhaps more so than you. Still, ${lyall_he} manages to turn on a smile and greet the first of the curious Wolf followers. 

$!{lyall_he} quickly introduces you to the enclave: There is the lean, bald, and impossibly fit Suba who gives you a fleeting grin while she looks you over; Fillin, whose round face makes him seem young, though the size of his biceps dwarf yours several times over; Zev and his twin-sister, Roan, who stares impassively behind a curtain of white-blond hair; and Hemming, the eldest, whose grizzled facial hair and sunburned skin belie a strong, wiry frame.

"So now that we have kissed and said hello…who are you, and why should we care?" Suba asks, leaning on a long wooden staff and exposing her sharp white teeth. 

"A little respect for our honored guest," Hemming chides lightly. "Can you not recognize the skin of your god when you see ${him}?"

Suba reorients herself and stares hard as if trying to peer through your skin. Eventually she shrugs. "Could be, or ${he} could be another fool with a lie to peddle."

*if gender != "none"
	"$!{he} is
*if gender = "none"
	"$!{he} are
the living vessel of the Wolf," Lyall says, ${lyall_his} voice cutting above the din. 

Fillin is the first to approach. His expression is unreadable. He comes within an arm span of you and falls to one knee. Zev does the same and Roan follows. Hemming saunters over and gives an exaggerated bow before taking a knee and even Suba, last to come forward, eventually kneels. 

"We have waited for some sign of what to do next, ${prenom}. I have humbly counseled for retribution against those who drew blood from our enclave, but the final decision should rightfully rest with the one closest to Wolf's spirit," Lyall explains, and then slowly kneels. 

Six people do not make much of a group, but you can sense the fierceness of their collective spirit as if it were a tangible thing. This group is the closest you have felt to Wolf's living presence since the day he went quiet. 

What will you suggest they do now? 

*choice
	#"Follow Wolf's example. Seek out others and grow stronger."
		*set action %+5
		*set lyall_affinity %+35
		*set survival +5
		Lyall stands and pats you hard on the back. 

		"The soul of Wolf has spoken! 
		*if gender != "none"
			$!{he} means
		*if gender = "none"
			$!{he} mean
		to lead us into battle."

		$!{lyall_he} continues. "The Rising Sun has spread like a blight and no one has risen to tamp them down. We are small in number, but I believe ${prenom} will agree that we can hunt them down to whatever rock they hide under, and we can do them harm. Is that not the will of the Wolf?"

		*choice
			#Refuse Lyall's influence: "No. You overstep your bounds by speaking for me and for Wolf."
				*set action %+5
				*set enclave_purpose "join"
				Lyall's eyes open wide and ${lyall_his} jaw lies slack until anger screws it tight again.

				"You…you embarrass us with your cowardice! You will answer this insult. I challenge you, ${prenom}, for the leadership of this enclave."

				A hush falls on the group. 

				"Are you sure this is—" Zev begins, but is quickly silenced by his sister's hand on his shoulder. He allows her to pull him back and let the scene before them play out. 
				*goto lyall_challenge
			#Further inflame the Wolf followers: "Yes. The Rising Sun should be hunted wherever they are, and their swift end is the will of Wolf."
				*set enclave_leader "you"
				*set lyall_fate "live"
				*set chaos_score +1
				*set action %+10
				*set lyall_affinity %+25
				*set enclave_purpose "fight"
				A cheer goes up from the enclave members. Their eyes are narrowed in anger and, perhaps, in anticipation of sweet vengeance. 

				Your siblings in Wolf talk among themselves, and Lyall comes up to your side. 

				"You have made a good decision. The only decision. We would follow Wolf's decree into the afterlife and follow it still. We are his sword and will ever be."

				The rest of the evening devolves into the drinking and cavorting that sometimes comes with a declaration of war.
				*label fireside_chat
				A roaring fire is made, and the members of the enclave drink, and laugh, and taunt each other until the early hours of the morning. One by one, they retire to their sleep. Lyall remains, stoking the flame and staring into its depths as if it holds some inscrutable secret.

				"I was raised up in a small community of Highwalk shamans and Wolf faithful. They told me I was claimed as one of Wolf's own from the moment of my birth. On the day of my birth, mine was the lustiest cry for life they had heard in an age. I heard the stories about Wolf coming to just one ${lyall_gender} and inhabiting them. I thought it would be me. I knew it."

				Lyall never takes ${lyall_his} eyes off of the fire.

				"Tonight it does not feel so bad that I was wrong. The burden is less heavy. Does that make me weak, ${prenom}?"

				*fake_choice
					#"It is for Wolf to say, not I."
						Lyall purses ${lyall_his} lips and nods sharply. 

						"We will all be judged according to our faith and strength once Wolf returns. So, you are right. These discussions will not change that truth."
					#"Shouldering unnecessary burdens is not strength."
						Lyall smiles.

						"You are something else, avatar of Wolf," ${lyall_he} says.
					#"No. I do not think so."
						Lyall turns away from the fire. 

						"Maybe. Maybe not," ${lyall_he} says. 
					#"Perhaps it does."
						Lyall laughs. 

						"If Wolf devours me for my weakness, then I will accept that fate gladly. It would mean he…well, it would be fitting, at least."

				$!{lyall_he} stands.

				*if (((action > deliberation) and (selfishness >= equity)) or (lyall_affinity >= 70))
					"${prenom}. I have always thought of myself as more of a wolf than a ${lyall_gender}. It has always seemed easier than the alternative. But these days, I am not sure." $!{lyall_he} looks over. "Would you share a bed with me? Let us be humans, as tender and rough as we want, for a night."

					How do you respond to Lyall's invitation? 

					*choice
						#Accept.
							*set eel_affinity %+30
							*set lyall_romance "sleptwith"
							Lyall reaches over and pulls you in for a kiss. $!{lyall_his} mouth tastes sweet from the wine you have all been drinking. $!{lyall_his} kiss is as ferocious as you might expect. 

							The night grows wilder from there. 

							*goto aftermath 
						#Refuse.
							*set lyall_romance "refused"
							You try to give your reasons, but Lyall is not terribly interested in hearing them.

							"You confuse me with some other kind of ${lyall_gender}, ${prenom}. Your refusal does not offend. There is no reason for apology."

							$!{lyall_he} pats your knee and kicks dirt onto the fire. "You should sleep. The sun always arrives too soon when you curl up with a drink."

							Lyall salutes you with ${lyall_his} cracked mug and ambles off. You follow ${lyall_his} advice and catch some sleep yourself. 
							*goto aftermath
						#Delay.
							*set lyall_romance "delayed"
							"Perhaps some other time," you offer. 

							Lyall's grin is subtle and dangerous. 

							"You and I know better, beloved of Wolf. There is no time beside this moment. But I will play your game. If there is a tomorrow, then we will consider it."

							$!{lyall_he} raises ${lyall_his} cracked mug. "If."

							You return the gesture, and repeat, "if."

							"Good night, ${prenom}," Lyall says. 

							"Good night."

							Lyall heads off, presumably to sleep, otherwise to find the diversion that you denied ${lyall_him}. You seek out sleep shortly after, and the morning comes in what feels like moments.
							*goto aftermath
				*else
					"I will do whatever it takes to protect this enclave. If I cannot be Wolf's avatar, then I will be his paragon. You can rely on me for that."

					$!{lyall_he} drains the cracked mug ${lyall_he} drinks from and tosses the dregs into the fire.

					"Find some sleep if you can," ${lyall_he} says, and walks away from the flame. 

					You stare into it for a long time before realizing that you will not find within it what Lyall sought. You head out to rest shortly after.
					*goto aftermath
			#Suggest a peaceful resolution to Lyall: "We should consider the future of this enclave carefully. The focus should be on survival."
				*if ((((sensitivity > 20) or (influence >= 3)) or (ritual > 15)) and (riser_affinity < 50))
					*set enclave_leader "both"
					*set lyall_fate "live"
					*set bear_affinity %+20
					*set hawk_affinity %+20
					*set ara_affinity %-15
					*check_achievements
					*if not(choice_achieved_coleader)
						*achieve coleader
					*set enclave_purpose "survive"
					"A peaceful resolution with these animals? Better we should chain ourselves to mountain lions and make friends with them," Lyall offers grimly. 

					"This enclave has already suffered deaths. To weaken it further would be irresponsible," you explain. 

					"We are prepared to die."

					"But you do not have to."

					"What do you know about our deaths, outsider. You were not—"

					"Lyall." The call comes from Roan, perhaps the quietest member of the enclave. The thin blonde nods in your direction. "What ${prenom} says has the ring of truth. What war could we bring against the Rising Sun in our current state? Wolf is vicious and cunning, but not reckless. Not unless there is no other way. ${prenom} is suggesting another way. We should listen."

					Lyall seems prepared to argue, but ultimately backs off. $!{lyall_he} spreads ${lyall_his} hands open, as if to giving a blessing for you to continue.

					"This enclave should survive. Bolster its numbers with other worshipers and grow in strength. If vengeance remains your goal, then execute it when doing so will not mean all of your deaths."

					"It does make a kind of sense, does it not, Lyall?" Fillin asks. 

					Hemming makes a noise of agreement and nods his head. Lyall can see that the group is deciding without ${lyall_him}, but you will never know if ${lyall_he} is rankled by it. $!{lyall_his} face remains impassive. 

					"Then we follow ${prenom}'s advice," Lyall says, and the matter is abruptly settled. In this way, the group comes to a silent consensus that both you and Lyall will speak for the enclave's well-being. Neither Lyall nor yourself agrees to it outright, but the matter is settled all the same. 

					Afterward, each person finds their way to sleep and you attempt to do the same. However, much of the night is spent sleepless, wondering about the fate of the enclave. You shut your eyes for a moment to think and open them to sunlight. 
					*goto aftermath
				*elseif riser_affinity > 60
					"We will never submit to the Rising Sun. Nor to their puppets," Lyall spits.

					"Puppets? Are you accusing me of something, Lyall?" you ask. Your tone is low and sharp. 

					"Yes, I am. I can smell their stink on you. We will not bend to their will. Ever." 

					*goto lyall_challenge
				*else
					Lyall looks at you as if you have sprouted wings and a forked tongue. 

					"You are mad, or a coward, or severely disillusioned, if you think we will allow ourselves to kiss cheeks with the Rising Sun and make up. Their influence drew blood from our enclave, and we will not soon forget it."

					Lyall stiffens and straightens, like an animal preparing to pounce. 

					*goto lyall_challenge
	#"Make your own decisions. You do not need to seek my approval, or anyone's for that matter."
		*set selfishness %+5
		*set eel_affinity %+15
		*set sensitivity +5
		"Are you certain of that, fearless leader?" Hemming asks. "I have hobbled through many enclaves and I cannot say I have ever heard such rhetoric from one in Wolf's confidence."

		"It sounds like blasphemy," Roan says, her voice light but not soft. 

		Lyall stands. $!{lyall_his} fists are balled at ${lyall_his} sides. 

		*if ((action > deliberation) and (selfishness >= equity))
			"I cannot understand what would make you go against Wolf's desires. You, of all people, should understand that his will alone gives us purpose."

			Lyall narrows ${lyall_his} eyes.
			*goto lyall_challenge
		*else
			"I knew. I knew that you were not what this enclave needed. It was foolish of me to think that wisdom to save this enclave could come from without."

			Lyall straightens ${lyall_his} shoulders.
			*goto lyall_challenge

		*label lyall_challenge 
		*page_break
		"You have no idea what we have endured since Wolf went quiet. Now you are here speaking as though this decision is arbitrary. Purposeless." $!{lyall_he} continues, "If you will not give us the direction we need, then I will remain the head of this enclave. I know what is best. I formally challenge you for leadership of this enclave."

		There are mixed responses from the group. Suba whistles and Fillin swears. Roan and Zev stare at each other and then at you. A leadership challenge is not something to be undertaken lightly. The look on Lyall's face suggests ${lyall_he} means it. 

		Hemming clears his throat and attracts everyone's attention for a moment. "A leadership challenge recognizes strength alone and means that the winner has final say about the direction of this enclave. It can be brutal. There are so few of us now that potentially losing two leaders to a challenge would be harmful. Is there another way—"

		"Old coward," says Suba, laughing.

		"Older wolves are to be venerated. They don't survive long in the wild without learning. He might be speaking wisdom," Fillin snaps.

		"Negotiate. Defer. Avoid harm." Lyall manages to make each word sound more vitriolic than the last. "The Wolf's path is unconcerned with these scruples. The challenge remains."

		*choice
			#Accept the challenge and fight Lyall for control of the enclave.
				*label challenge_accepted

				It is agreed that shedding blood in Bear's house would be disrespectful of the patient god, so the enclave sets up a makeshift fighting circle demarcated by bundles of sticks. Suba tears strips from her own shirt and binds Lyall's knuckles with them. Zev and Roan come over to offer you the same service.

				"The tearing is an acknowledgment that the enclave takes no sides. We give of ourselves to both combatants. Whatever the outcome, we stand with the victor and recognize strength alone," Roan explains, while wrapping your knuckles and wrists. 

				"Lyall is strong," Zev says, and scratches his unkempt hair. "$!{lyall_he} has ritual skills and physical prowess, but like any flame, can only burn hot for so long."

				He gives you a lopsided grin. "Try not to die."

				Inside the circle, you stand across from Lyall and prepare to fight for the good of the enclave. But what tactics will you use against ${lyall_him}?

				*choice
					#Tire ${lyall_him} out by surviving ${lyall_his} attacks, then bring ${lyall_him} down with a decisive strike.
						*if survival >= 15
							Lyall moves quickly, but you track ${lyall_his} movements while steeling yourself for the inevitable onslaught. It comes like a bracing cold.

							$!{lyall_his} fists strike against you repeatedly and the blows only seem to multiply when you counter. There is no doubt that ${lyall_he} is quicker than you are, but ${lyall_he} is not fighting smart. As Lyall throws ${lyall_him}self into punch after punch, so obviously trying to end the fight quickly, you can feel the diminished edge of those strikes. Not that they ever stop hurting.

							You wait until the hits start to slack and then, all at once, you launch your counterattack. It takes a truly skilled fighter to recover when backed into a corner, but Lyall almost manages it. $!{lyall_he} holds ${lyall_his} own even as you rain attacks down on ${lyall_him}. But you can see the end in the way ${lyall_his} shoulders sag and ${lyall_his} footwork goes limp.

							A single kick drives Lyall to ${lyall_his} knees and you wait, loaming over ${lyall_him} to see if ${lyall_he} will stand again. $!{lyall_he} does not.
							*goto lyall_defeated
						*else
							*set lyall_fight_modifier "survival"
							Lyall is faster than you would have expected, but your stamina is nothing to be trifled with. You find yourself taking hits: a bone-rattling punch to the sternum; a scratch across your forearm leaving hot lines of pain on your skin; and a blow to your left knee that slows you down considerably, but you stay on your feet, and you can see Lyall slowing down after a while. 

							Unfortunately, you cannot find an opening. 

							The fight goes on and you find yourself worn down by ${lyall_his} aggressive fighting style and relentless pace. Every opening you find is a snare that Lyall intends for you to fall into and be trapped. $!{lyall_he} is cunning as well as vicious. 
							*goto fight_fail_1
					#Match my ritual skills against ${lyall_his}.
						*if ritual >= 20
							There is not enough time to prepare for some ritual that will amaze, but you have faith in your skills. You reach for the echoes of this place and find there is much that assist you. There is a pervasive cold buried deep in the land that transcends seasons, which you slowly draw upon.

							Lyall moves quickly and you take more than a few hits while waiting for the right time to strike. The ice is a holdover from the terrible winters that have ravaged these hills. It heeds your call, but does so at its own pace. It will not be hurried. Even when Lyall puts you in a choke hold and squeezes the air from your lungs.

							As you begin to slip out of consciousness, you suddenly find it. The ice and cold is at your fingertips and you merely have to reach up and touch Lyall's arm. The touch is a momentary discomfort and ${lyall_he} shakes it off. But the cold spreads and soon ${lyall_he} does not have enough strength in either arm to choke you. $!{lyall_he} falls backward and you can see, from the intensity of ${lyall_his} expression and the ritual words on ${lyall_his} lips, that ${lyall_he} is trying to dispel your rites with power of ${lyall_his} own. 

							There is no use. You have Lyall in the grips of your ritual, and ${lyall_he} will only find release if that is your intent.
							*goto lyall_defeated
						*else
							*set lyall_fight_modifier "ritual"
							You reach down into the living will of the earth and draw up the embrace of winter that lies dormant in the soil. The memory of ice and snow is enough to conjure the paralyzing sense of being frozen in place. You attempt to direct it at Lyall, so as to slow ${lyall_him} down and make ${lyall_him} careless. 

							But Lyall's own skills in the realm of ritual are as formidable as Zev warned. $!{lyall_he} not only shrugs off the chill that rises up around ${lyall_him} in a heavy white haze, but also manages to twist and redirect the icy smoke back on you. 

							You can feel the cold rising up from the ground and stretching about you. Lyall comes at you fist first and you dodge furious punches and kicks while trying to snap out of the exhausting malaise that your manipulated rite has affected you with.

							*label fight_fail_1

							Things are going badly. What do you think will help to turn the tide in your favor?

							*choice
								#Analyze ${lyall_his} attack patterns and identify some weakness that I can exploit. 
									*if sensitivity >= 25
										Lyall is strong, but ultimately reckless. You tell yourself it is not impossible to bring ${lyall_him} down, but you have to focus. Your swollen left eye and bloody lip make that difficult, though. 

										You take a few hard blows while you analyze ${lyall_his} patterns of attack. You can hear the voices of the enclave members turning against you, accusing you of cowardice for flinching from Lyall's fists.

										But eventually you piece together a strategy. Lyall is favoring ${lyall_his} left side and moving lightly on ${lyall_his} right foot. It might be enough. 

										You try to stay on Lyall's right side, though ${lyall_he} makes it difficult. You hammer ${lyall_his} lower body with strikes that drive ${lyall_him} back a few steps and then you sweep in for a definitive blow. 

										The bone crunches where you drive your knee into ${lyall_his} side.

										Lyall sinks down to the dusty ground. $!{lyall_he} tries to stand and fails and you take your first relaxed breath since you entered the circle. 
										*goto lyall_defeated
									*else
										You trade blows with Lyall and try to outpace ${lyall_him} while keeping a safe distance between you. Your plan is to stay fighting until you can find something to use against ${lyall_him}. 

										It would be a sound plan if you could ever find ${lyall_his} weaknesses. Instead you go around and take hits. You strategize and take hits. You catch your breath, and you take more hits. 

										Before long you barely have energy to stand, much less fight. You nearly collapse, while Lyall approaches again for a follow-up.
										*goto lyall_victor
								*if (lyall_fight_modifier != "ritual") #Try a last-ditch ritual.
									*if ritual >= 20
										Lyall's quickness makes it hard to focus long enough to manage a ritual, which are by nature complex and fickle. And it does not help that you are already beaten and tired. You try to clear a space in your mind where you can focus on the particulars of the rite you're thinking of. 

										Lyall throws a vicious punch in your direction and you grab ${lyall_his} forearm and use ${lyall_his} momentum to flip ${lyall_him} over. $!{lyall_he} is surprised, but even as ${lyall_he} hits the ground, you can see on ${lyall_his} face that he expects to spring back up immediately. 

										You have other plans. 

										The ground opens up underneath ${lyall_him} and swallows ${lyall_his} arms and legs. $!{lyall_he} struggles and tries to wrench ${lyall_him}self free, but the ground has closed completely around ${lyall_his} limbs. 

										"Do you yield?" you ask. 

										"Never!" ${lyall_he} shouts.

										You will the earth closer and it presses hard against Lyall's enclosed body. $!{lyall_he} screams. 

										"Yield."

										Lyall screams again and ${lyall_his} eyes are wild with anger and frustration, but ${lyall_he} cannot climb out. A few moments later ${lyall_he} yields and you release ${lyall_him}. 
										*goto lyall_defeated
									*else
										You attempt to turn the elements themselves against Lyall by reaching into the memory of the ground and the wind, then drawing out something that is willing to be called.

										The air is the first to answer the call of your ritual. The light breeze becomes a gale that buffets Lyall. $!{lyall_he} struggles to stand and then is forced down to ${lyall_his} knees. You then rally the memory of winter that lies deep in the ground of these hills and turn it against ${lyall_him}. 

										Lyall slows and does not stand. You have won. 

										Or, perhaps not. You do not see Lyall's mouth moving until it is too late. You have no ritual defenses ready when ${lyall_his} own rites come to fruition. The ground beneath you turns watery and you sink quickly. Your arms flail and you shout arcane defenses that do not work fast enough to protect you. 

										You sink up to your neck before the ground solidifies. You cannot move in Lyall's earthen snare. $!{lyall_he} walks over to you as casually as an old friend. 

										"Yield," ${lyall_he} says simply. 

										You would not yield if there were something left to do, but the elements are overdrawn and you are bone weary. You concede and Lyall pulls you out of the ground. 
										*goto lyall_victor
								*if (lyall_fight_modifier != "survival") #Block ${lyall_his} attacks and counterattack.
									*if survival >= 15
										You force yourself to be still inside your mind even while weathering a punch to the side of your head that rattles your brain and a kick to hipbone that you anticipate will bloom into a fabulous purple bruise.

										You stay calm and take the hits until you are ready. 

										Lyall launches into a series of attacks and slightly overextends ${lyall_his} left arm. You take the opportunity to break it for ${lyall_him}. To be fair, you cannot be sure if the arm is truly broken, but there is an audible crack and ${lyall_he} pulls away viper-quick. Still not quick enough. 

										You are on ${lyall_him} now and ${lyall_he} is partially disabled, though still attempting to use ${lyall_his} damaged arm fluently. Lyall's counterattacks and blocks become sloppy and you have no problem putting ${lyall_him} down. 
										*goto lyall_defeated
									*else
										It is not obvious at first that Lyall is going to overpower you. You have a decent strategy and just enough resilience left in you to execute it. $!{lyall_he} comes on fast again and you defend yourself, though you move a little slower after the first round of beatings. 

										You have to wait until ${lyall_he} starts to slow down and then turn the tables. So you wait. 

										But the tables never turn. Lyall is not only quicker than you thought, but hardier. $!{lyall_he} matches you blow for blow and in the end launches a spinning kick aimed at your head that you block as best as you can, but still rattles you so badly that you sink down to one knee. 

										$!{lyall_he} stands over you and waits. $!{lyall_he} seems to know before you do that you will not get back up again. 
										*goto lyall_victor
								*if (lyall_fight_modifier != "combat") #Fight harder.
									*if combat >= 20
										You cannot be sure how much vigor you have left in your battered bones, but you roar aloud and charge nonetheless. Your left eye is almost swollen shut, but you find a way to ignore it.

										Lyall is surprised at the eleventh-hour comeback. $!{lyall_he} puts on a spirited show, but you are channeling the fullness of your rage and strength into every bone-crunching hit. Lyall's defense stutters and you tear into the gap, laying into ${lyall_him} with your fists, which ache horribly but still bash just fine.

										$!{lyall_he} drops to one knee in the dirt and spits blood to one side. You wait for ${lyall_him} to stand, but ${lyall_he} does not.
										*goto lyall_defeated 
									*else
										There is something invigorating about going blow for blow with Lyall. You have taken a fair amount of abuse since the challenge began, but you still have a few more blows to trade.

										After a few hits, you notices Lyall is slowing and you redouble your efforts.

										It seems that any minute ${lyall_he} will break and you will overwhelm ${lyall_him}. And yet somehow it is the opposite that comes to pass. Lyall seems to draw on some hidden reserve of strength and speed and turns your relentless assault into a hasty, sloppy defense. It becomes clear to you that ${lyall_he} was baiting you, drawing you out, and weakening your position by forcing you to expend more energy than you could afford. 

										Your defense falls apart, and Lyall methodically dismantles all hope you had of victory. You sink down to the dirt and cannot find the energy to stand again.
										*goto lyall_victor
					#Tactics? I am going to fight ${lyall_him} until ${lyall_he} collapses.
						*if combat >= 20
							You set out to do just that. You unleash a scream that would rattle the very foundations of the earth, then you charge at Lyall with enough force to break ${lyall_his} spine if ${lyall_he} was not prepared for it. 

							The two of you tumble into the dirt and you bash ${lyall_his} head repeatedly with your fists and elbows. But you are bound to be disappointed if you were seeking an easy fight. Lyall fights like a cornered creature. $!{lyall_he} claws at your eyes and drives ${lyall_his} fists into any soft place on your body. The pain is immense and grows steadily. 

							As you both struggle back to your feet, Lyall leaps toward you in an attempt to drive ${lyall_his} knee into your head. It is only by a fraction of second that you are able to raise an arm in defense. The blow lands so hard that you feel the bone in your arm rattle. You are pushed back several steps, so Lyall takes advantage of the stumble to come in harder. 

							But Lyall has underestimated both your strength and your quickness. You pummel ${lyall_him} with a flurry of strikes so sudden that you can see the expression on ${lyall_his} face change from certainty to fear. You land a blow to the side of ${lyall_his} head after which ${lyall_he} wobbles unsteadily on ${lyall_his} feet, stumbles, and then collapses outright. $!{lyall_he} lays there for a moment before trying to climb to ${lyall_his} feet. 
							*goto lyall_defeated
						*else
							*set lyall_fight_modifier "combat"
							You intend to match Lyall blow for blow. $!{lyall_he} comes on like pure rage itself and you find yourself in the position of defending yourself before long. You grind your teeth and fight harder, intending to take ${lyall_him} down no matter what.

							The harder you fight the more clear it becomes that you are overmatched. $!{lyall_he} is not exactly stronger than you are, but ${lyall_he} seems driven by distilled rage and crashes against you without hesitation.

							You are backed up against the edge of the circle before long. A single step over, and the challenge will be called in Lyall's favor. You have just a few moments to figure out how to respond. 
							*goto fight_fail_1
			#Cede your claim over the enclave. Allow Lyall to take control.
				*if (((equity > selfishness) and (sensitivity >= 20)) or ((influence >= 3) and ((sensitivity >= 15) or (survival >= 15))))
					*set lyall_affinity %-5
					*set bear_affinity %+10
					"You want to cede your claim?" Fillin asks, clearly confused. He asks the group, "Is that possible?"

					Hemming raises his hands, as if to disavow the responsibility of answering.

					"The challenge is to recognize a leader. I suppose the challenged does not have to accept, but you understand that you cannot take this back," Roan asks. 

					You reiterate that you have no intention of leading while Lyall is capable of doing so. For ${lyall_his} part, ${lyall_he} seems to find the idea distasteful. 

					"It is cowardly and weak-minded. But if you truly wish to avoid the fight, then I will not force you. And you have my word that you will be treated as one of us for as long as you remain here."

					*goto no_challenge
				*else
					*set lyall_affinity %-15
					Lyall actually laughs when you make the suggestion. "Do you think that is how it works, Wolf-bearer? Have you spent so long away from the rites of our god?"

					$!{lyall_he} shakes ${lyall_his} head. 

					"No. You will accept the challenge and the stronger of us will take control. There is no other way. There is no negotiating this point. Now, go and prepare yourself for what comes next."

					Roan, unexpectedly, speaks on your behalf. "Lyall. We have already lost many of our own. It is not right that more of us should die, and least of all at each other's hands."

					Lyall looks at Roan, aghast. $!{lyall_he} struggles for a moment to find a rebuttal. 
					*goto control_ceded
			#Suggest a co-leadership.
				*if (((sensitivity + quickthinking) >= 35) or (influence >= 3))
					*set enclave_leader "both"
					*set lyall_fate "live"
					*check_achievements
					*if not(choice_achieved_coleader)
						*achieve coleader
					"There is another path we might take, beside shedding each other's blood," you say, and then explain your idea: a leadership shared between Lyall and yourself. 

					"There has never been such an alliance," Lyall counters. 

					"We have never lived in a time without the guidance of Wolf. Our world has changed, and we need not be afraid to change alongside it. I do not mean to put us down a path without the wisdom of the Wolf path, and I think with you as a partner this enclave would greatly benefit."

					*if gender != "none"
						"$!{he} speaks
					*if gender = "none"
						"$!{he} speak
					wisely," Suba says, unexpectedly. "I have never seen a wolf with two jaws, but I would know to fear it."

					Zev offers agreement as well. "We have suffered loss and it is wise to rally our strengths rather than divide them."

					Lyall looks at the others. There does not seem to be disagreement among them. ${lyall_he} looks back at you. 

					"I accept."

					The release of tension is immediate and the enclave goes about preparing for the quickly darkening evening.

					*goto fireside_chat
				*else
					"We can disagree without enacting violence upon each other. I would suggest a shared leadership. Between us we can look after the best interest of this enclave."

					"No," Lyall says. 

					"At least consider it," you counter. 

					"It might work. We could share the responsibilities of leadership or it could fail and we will be here again, except with more time between us to grow softer. I refuse to weaken this enclave. I will not share this leadership." Lyall grins, and says, "but you are free to take it from me."

					There is no talking after that. Lyall refuses to be negotiated with, and you have your answer. 
					*goto challenge_accepted
			*selectable_if ((action >= deliberation) and (equity > selfishness)) #[i]Hawk Path[/i]: Allow the group to decide whether or not I should accept the challenge.
				*set deliberation %+5
				You turn the decision over to the enclave itself. It is, after all, their future under discussion. 

				"The ruled becomes the rulers, then?" Suba says, sardonically. "Perhaps I should be leader. It would fun."

				"And we would be dead in a week," Fillin replies.

				Suba laughs. She shakes her head, and says, "that is true. But for a week, it would be fun."

				"A challenge should play out. The victor leads. It is the way things are done," Roan says, then adds, "but we have lost lives. The challenge could claim both your lives and then what happens next?"

				"My sister has a point. If there is a way to do this without bloodshed, then I think we should do it." Zev works his jaw and sucks at his teeth. "I think Lyall should remain in control."

				"$!{lyall_he} has led us so far and has seen us at our worst. I agree," Hemming says, while stroking his scraggly goat's beard. 

				The others come around and elect Lyall as their chosen leader. You can tell the decision makes ${lyall_him} uncomfortable, but ${lyall_he} seems to accept it. 

				"And you would go along with this? You would allow me to lead without challenge?" Lyall asks. 

				*choice
					#"If that is the will of the group. Yes."
						*set equity %+5
						*label no_challenge
						*set enclave_leader "lyall"
						Lyall accepts, and the matter is effectively settled. It is possible that you have just made history as the first person to ever bloodlessly transfer leadership in a Wolf enclave. It is a sign of change, and there are many things yet to change.

						Since the sun is beginning to set, the enclave members start a fire and roast a number of meat and vegetable provisions. They talk and laugh as if they have no cares, and you find their infectious brand of camaraderie draws you in. By the time the fire gutters out, your belly is full and you feel tired, but safe. The feeling of having others around you with a common purpose is one that you have not experienced for some time. You try not to get used to it. 
						*goto aftermath
					#"No. I have the best interest of this enclave in mind. I cannot allow it."
						*set action %+5
						*label pre_challenge
						Lyall seems almost heartened by this turn of events.

						"Maybe you are still something of a wolf after all," Lyall says. 
						*goto challenge_accepted 
					#"Only if you promise to swear you will not seek further retribution for the Wolf worshipers who have been killed. Bloodshed only begets further bloodshed."
						*set deliberation %+5
						*goto no_challenge
					#"And let you turn this enclave against me? I do not think so."
						*set selfishness %+5
						*goto pre_challenge
	#"Whatever you do, do not lose faith in the gods or be seduced by apathy toward them."
		*set equity %+5
		*set combat +5
		Lyall seethes as you speak, but to ${lyall_his} credit waits until you are finished before laying into you. 

		"And what were the gods doing to aid us while we fought for our lives these past few weeks? Did Hawk descend from her heavenly perch and claw the eyes of those who came for us in the night like cowards? Did Eel cover us with his grace and hide us from them? No. There is but one god worth our praise and we follow, even if he is gone. We follow."

		The others attempt to speak, but Lyall drowns them out.
		*goto lyall_challenge
	#"Be patient. Wait until the way forward is clear and then make a decision about your future."
		*set deliberation %+5
		*set quickthinking +5
		Lyall looks confused at first, then undeniably angry. "Wait and see? That is what you intend to offer us? Are we daisies waiting patiently to be plucked? No. I cannot accept that. We cannot accept that."

		Suba scowls at ${lyall_him}.

		"Do you have a choice, Lyall? 
		*if gender != "none"
			$!{he} is
		*if gender = "none"
			$!{he} are 
		the Wolf avatar. We are obligated to follow."

		Lyall ignores Suba and rounds on you. 
		*goto lyall_challenge

*label lyall_defeated
*set influence +1
*set enclave_leader "you"
*if enclave_purpose = "none"
	*set enclave_purpose "survive"
*page_break
It is clear Lyall does not have the force of will to keep fighting, but defiance is writ plainly across ${lyall_his} features. 

"I submit," ${lyall_he} says. "My fate is yours to decide."

Suba, who until now has seemed firmly in Lyall's corner, is the first to speak. "Lyall challenged and failed. If you let ${lyall_him} live, you will regret it. Wolf's path could not be clearer in this case."

"I have to agree," says Roan. In her quiet voice, she adds, "could you rest easy knowing that someone who would have seen you dead is leading a group of accomplished warriors? Killing ${lyall_him} makes the most sense."

Hemming scowls, but says nothing. Fillin however does not hesitate to disagree. 

"If the reason for this disagreement was to show that there are other ways to deal with our disagreements than through violence, then killing Lyall accomplishes nothing."

"Enough with your clucking!" Lyall shouts. "${prenom} leads this enclave now. The decision rests with ${him}."

That it does. And how do you decide to deal with Lyall?

*choice
	#Banish ${lyall_him}.
		*set equity %+5
		*set lyall_fate "banished"
		"I will not kill another of Wolf's faithful, but your place among this enclave is forfeit. Find others who will take you in or live according to your own desires. Whatever you decide it will not be here."

		Lyall stares at you for a long time. "You are gracious, Wolf-bearer. Too kind for your own good. I hope it does not become your undoing."

		It does not take long for Lyall to gather ${lyall_his} things and head out into the hills, but ${lyall_his} words hang over you like a portent. You hear those words even when night falls and the enclave makes a fire for the evening to cook their simple fare. However, eventually the fire goes out and sleep claims you. You try to leave Lyall's warning behind when you wake the next morning.

		*goto aftermath
	#End ${lyall_his} life.
		*set action %+5
		*set death_toll +1
		*set lyall_fate "dead"
		*if pacifism
			*set pacifism_broken true
		You do not relish the decision, but you are not sure that Lyall can be trusted. If you were in ${lyall_his} place—kneeling in the dirt—you would like to think you would encourage mercy, but you know better. 

		"Do you have final words for your enclave?" you ask. 

		Lyall shrugs and smiles with the levity of a dead ${lyall_gender}. 

		"Have no fear of following this one. 
		*if gender != "none"
			$!{he} is
		*if gender = "none"
			$!{he} are 
		as much Wolf as any of us and more. This proves it," ${lyall_he} says, then, "do it."

		It is not easy to take Lyall's life, but you do not hesitate and it is done quickly. None of the members of the enclave look away. 

		Afterward they burn the body in silence and drink to Lyall's memory. They invite you, but the thought of drinking to the memory of someone you have so recently slain strikes you as perverse. Instead you try to sleep. It takes a long time before it comes and when it does your dreams are full of howling. You strain your ears in the dark for a note of judgment or anger, but the howling is not miserable. It is joyful. Ecstatic. 

		You wake with a sickly taste in your mouth. 
		*goto aftermath
	#Demand Lyall submit to me and support my decisions.
		*set lyall_fate "live"
		*set deliberation %+5
		*check_achievements
		*if not(choice_achieved_fallinline)
			*achieve fallinline

		"You have a place here, Lyall. That does not have to change, but you will fall in line as long as I am the recognized leader of this enclave," you explain.

		Lyall is silent for a while and then eventually gives you a terse nod.

		"I would hear you say it aloud."

		"I recognize you as leader. I will do as you say," Lyall says, begrudgingly. 

		Afterward ${lyall_he} stands, and the matter is closed.

		The enclave busies itself with the preparations for the evening. A fire is started and a meal shared between potential rivals-turned-allies. Lyall does not seem to hold a grudge, which makes sense for a true believer in Wolf's methods. The order has been established, and there is nothing left to fight. Still, it takes you a moment longer to fall asleep knowing that ${lyall_he} rests nearby, and you find yourself waking early for the same reason. 
		*goto aftermath

*label lyall_victor
*set enclave_leader "lyall"
*set enclave_purpose "fight"
*page_break
As much as you want to keep fighting, there is nothing left for you to do. Lyall has defeated you, though your bones are slow to recognize the fact. You kneel in the dirt and ${lyall_he} stands over you like an executioner. 

*label control_ceded

"I should kill ${him}," Lyall says to ${lyall_him}self. "One way to be sure…"

"You are going to kill the Wolf avatar?" Hemming asks incredulously. "With Wolf gone, ${prenom} is our closest connection to whatever is left of our god. Kill ${him} and what do we have but memories?"

"Did I ask for your counsel, old wolf?" Lyall says. $!{lyall_he} does not take ${lyall_his} eyes off of you. 

"No, but I think you might need it," Hemming says.

"Swear that you will not attempt to usurp this enclave. On the blood of all the gods, you swear," Lyall says. There is no mistaking it: This is a command.

You are tired and beaten, so you swear. Even if you do not mean it. 

Lyall allows you to stand. $!{lyall_he} looks you over once more and then leaves the fighting circle. The others disperse. All except for Fillin. He stays behind until all of the others have gone, and then he approaches. 

"Lyall was never soft, but Wolf's absence has made ${lyall_him} unyielding. It means little, but I'm glad you survived."

"Thank you," you reply. 

Fillin helps you over to a spot at the mouth of Bear's temple where you can rest, before leaving to find his own rest. In the morning, you tell yourself, you will figure out the next move, but your head aches along with the rest of you, and you can barely keep your eyes open. You fall asleep quickly and the morning comes too soon.
*goto aftermath

*label aftermath
*page_break
You find the group and Suba eagerly waves you over to share a meal of fragrant boiled roots and potatoes while Zev skins a freshly caught rabbit.

*if lyall_romance = "sleptwith"
	Lyall sits across from you on a log and eyes you occasionally. $!{lyall_he} has a bruise on ${lyall_his} chin from your night together. You have a few bruises of your own. 

	$!{lyall_he} almost seems to be waiting for you to say something. 

	*fake_choice
		#[Point to the bruise on your throat] "We match each other."
			"If I knew we were going to compare battle scars, I would have inflicted more of them," Lyall says casually. 

			"You think you would have had the chance?" you ask. 

			Lyall smirks. "Maybe."
		#"It was a good night. Do you agree?"
			Lyall smiles. It is a wolf's smile, if you have ever seen one. Wily as any predator.

			"If it were not, I might have killed you in your sleep," ${lyall_he} says. 

			You are not entirely sure it is a joke. 
		#"You are something else, Lyall. Full of surprises."
			Lyall shifts on ${lyall_his} log. "I could say the same of you, ${prenom}. That thing you did with your—"

			You cough loudly into your sleeve and Lyall just grins. 
		#Wink at Lyall. 
			You wink at Lyall from across the fire and Lyall catches the gesture. So does Suba, who blows you a theatrical kiss in return. Lyall's glare causes the tall warrior to break into stifled laughter.
		#Say nothing. I would rather savor the moment. 
			You enjoy the companionable silence between the two of you. There is a kind of warmth there that you can feel even from a distance. Still, whenever you catch Lyall's gaze drifting across yours, you smile and ${lyall_he} does the same. 
		#Say nothing. Last night was last night, I want to keep it that way. 
			You enjoy breakfast and Lyall does not approach you or try to instigate conversation, but ${lyall_his} gaze follows you until it is absolutely clear you have no intention of engaging ${lyall_him}. 
	*comment endif

	The gazes of the other members of the enclave surreptitiously watch your interaction with Lyall, but they say nothing of it. Wisely.

	Gradually the fireside conversation drifts to other matters.

"We are all surprised that
*if ((enclave_leader = "you") and (lyall_fate = "banished"))
	you let Lyall live. But you are our fearless leader and questioning you means death,"
	*goto aftermath_2
*elseif enclave_leader = "lyall"
	Lyall let you live, ${prenom}. But all is forgiven as far as we are concerned,"
	*goto aftermath_2
*elseif enclave_leader = "both"
	you did not end up tearing each other apart. But around here we find grudges to be tedious,"
	*goto aftermath_2
*elseif (lyall_fate = "dead")
	you tore Lyall apart. But these things happen,"
	*goto aftermath_2
*else
	things ended up as peacefully as they did,"
	*goto aftermath_2
*label aftermath_2
Suba says cheerily.

"Let ${him} eat in peace, Suba," Hemming says. 

The dark-skinned woman shrugs and continues demolishing the potatoes before her. Breakfast continues in that vein, nestled somewhere in between awkwardness and camaraderie. 

*if enclave_leader = "lyall"
	Lyall looks over the group. $!{lyall_his} eyebrows are knitted in concentration or perhaps with the gravity of what ${lyall_he} is about to say. 

	"Enclave. We have spent weeks just surviving from one moment to another without guidance from Wolf. I believe it is time to directly address our future. First we will deal with the animals that attacked us and killed our sisters and brothers. Once that blood debt has been settled, we will search out the Rising Sun wherever they hide, and we will kill them."

	Lyall turns to you. 

	"${prenom}, you were nearby the village when we came across each other. You likely know best the current state of the village. What say you about their fates? Are you with us?"

	*label village_choice

	*choice
		*selectable_if (village_state > 1) #Tell the truth: "I have already exacted vengeance on this enclave's behalf."
			*if ((enclave_leader = "lyall") or (enclave_leader = "both"))
				*label vengeance_taken
				Lyall's eyes go wide. "You sought vengeance on Wolf's behalf on your own?"

				"I am his avatar. Would you expect less of me?" you ask. 

				Lyall takes a while to answer. 

				"No. I suppose not."

				*if enclave_leader = "lyall"
					$!{lyall_he} addresses the enclave once more. 

					"We continue onto our hunt, then. Prepare your things, and we leave at noon."
					*goto end_chapter
				*else
					The news gets around that the Clearwaters have been taken care of, and it does not take long for the enclave to start moving. The next part of their journey lies ahead.   
					*goto end_chapter
			*elseif ((enclave_leader = "you") and ((lyall_fate = "dead") or (lyall_fate = "banished")))
				Zev looks amazed. 

				"I see. Well, then forget I brought this up."

				He returns to the rest of enclave to spread the news. Since the matter of the Clearwaters is now settled, there is no real reason to stay holed up in the hills above their village. The enclave prepares for what comes next without needing to be commanded to do so. Their autonomy is impressive. 
				*goto end_chapter
			*elseif ((enclave_leader = "you") and (lyall_fate = "live"))
				*goto vengeance_taken
			*else
				*goto vengeance_taken
		#Lie: "The Clearwater village was already destroyed when I arrived. There is no reason to return there."
			*set ara_affinity %+20
			"Destroyed? By whose hand?" Zev asks. 

			"Perhaps their love affair with the Risers went sour. It would not be the first time a sweet romance ended in bloodshed," Suba answers.

			*if lyall_fate = "live"
				"And you are certain of this? You saw the place destroyed with your own eyes?"

				"Of course," you reply, without even flinching.

				You are not certain Lyall believes the lie, but ${lyall_he} does not press the issue.
				*goto after_lie
			*else
				"Then our business in these hills is done. We might travel south and gather what followers of Wolf we can," Fillin says. 
				*goto after_lie

			*label after_lie

			The enclave discusses this news for a while longer and then goes about the business of preparing for its next step, which previously had been the destruction of the Clearwater village. 
			*if village_state != 4
				*set equity %+10
				*set selfishness %-10
				You cannot be sure how much time you have bought the villagers, because eventually they will realize they have been lied to. Hopefully, by then the villagers will have found protection or the wolves will have caught a juicier scent. Either way, you have done what you could.
			*if village_state = 4
				*set selfishness %+10
				*set equity %-10
				You do not tell the Wolf enclave that you yourself slaughtered the Clearwaters and robbed them of their "justice." You encourage the wolves to move on from their myopic insistence on righting past wrongs and to look forward to the future.
			*goto end_chapter
		*selectable_if (village_state != 4) #"The village is safe, and I intend for it to remain so."
			*if ((enclave_leader = "lyall") or (enclave_leader = "both"))
				Lyall regards you for a moment and then asks you to repeat your statement. When you do, ${lyall_he} shakes ${lyall_his} head. 
				*goto village_decision
			*elseif ((lyall_fate = "live") and (enclave_leader != "lyall"))
				Lyall narrows ${lyall_his} eyes, but waits for someone else to speak up. $!{lyall_he} does not have to wait long, because Fillin eventually steps in.
				*goto village_decision
			*else
				Fillin shakes his head and looks at you with frank confusion. 
				*goto village_decision

			*label village_decision
			"You want to protect them? From us?"

			"I do. If necessary," you reply. "There has been enough bloodshed."

			"The bloodshed has barely started. Our brothers and sisters are dead, and you defend their killers?"

			The enclave members grumble among themselves and you can hear their growing discontent. What will you do? 

			*choice
				*if ((enclave_leader = "you") or (enclave_leader = "both")) #Exert my authority as leader: Forbid action against the village.
					You quietly let the group know you will not brook dissent on the subject. 

					*if lyall_fate = "live"
						Lyall is quick to begin pointing out the atrocities committed against the enclave, which you respond to with a roar that quiets the chatter. 

						"I will not repeat myself. The Clearwater discussion is closed," you shout.
					*comment endif

					*label village_decision_2
					There is a little more noise from the group, but it is just the sound of people swallowing an unpopular opinion. You have no doubt they will obey, and that is what matters. They will not forget their dead, but they will not seek revenge, either. At least not from the villagers. 

					The group needs something else to focus on, and so they busy themselves with preparing to leave the hills. There is no reason to stay longer, since retribution has been pulled off the table. 
					*goto end_chapter
				#Back down: Allow the enclave to hunt the Clearwaters.
					*if village_state = 0
						It is not ideal, but you understand the desire of the Wolf enclave to hunt down those who have done violence to them.

						*goto decision_made
					*elseif village_state = 2
						You would have preferred to keep your promise to the Clearwaters that they would remain safe if their leader paid the price for their actions in blood, but you will not force the enclave to abide by that decision: Their minds, and their desire for vengeance, are their own.

						*goto decision_made
					*else
						You will let them go. They will soon find on their own that you have already exacted the vengeance they seek, and they will have to satisfied with it. 

						*goto decision_made
				#Threaten the enclave and keep them in line.
					*if ((action > deliberation) and (selfishness >= equity))
						*if ((enclave_leader = "both") or (enclave_leader = "you"))
							"I am the Wolf-bearer, and it is my decision.
							*label sticking_to_your_guns
							I am making the Clearwater village my responsibility and I will see them left alone, unless you all intend to go through me."
							*goto village_decision_2
						*else
							"I cannot let you attack these people."
							*goto village_decision_2
					*else
						You start to edge forward in a threatening manner, but Hemming gives you a sad grimace and shakes his head. 

						*goto decision_made
				#Reason with them.
					*if sensitivity >= 25
						"We do not have to kill them. This enclave has had its blood spilled, yes, but vengeance is not our only solution. Besides, they are filthy and starving. It is hardly an appropriate hunt."

						There is disagreement, but a few of the enclave members are quick to hear your argument. They are sick of these hills and are not particularly keen on returning to the site where their compatriots died. 

						*goto village_decision_2
					*else
						You start to make your case, but you catch Suba's eyes and she gently shakes her head. 

						*label decision_made
						You realize the group has made up its mind. Whatever you are about to say will fall upon deaf ears. You decide to keep your silence instead.

						The enclave members prepare for their mission of retribution.
						*if ((village_state = 3) or (village_state = 4))
							You do not tell them they will find a village full of the dead.
							*goto end_chapter  
						*else
							If the villagers are smart, they will find a way to protect themselves and if not, then perhaps the world is too savage now to live in safely.
							*goto end_chapter
		*selectable_if (village_state <= 1) #"The village is safe, for now, but I do not care what happens to it."
			*set selfishness %+5
			*set survival +5
			*if ((enclave_leader = "lyall") or (enclave_leader = "both"))
				Lyall acknowledges your findings and immediately begins making plans to destroy the Clearwater village and take the vengeance that has been thus far denied the enclave.

				"We will wait until nightfall and then strike. They will not be prepared," Lyall explains to the group.

				With a clear task before them, the enclave organizes quickly and prepares for its mission.

				*if clearwater_aid
					*set deviousness true
					*set chaos_score +2
					*set quickthinking +10
					*set selfishness %+10
					*set equity %-10
					*set ara_affinity %+15
					Despite helping the Clearwaters survive, you still allow the Wolf enclave to attack them. Spider herself would approve of such deviousness.
				*goto end_chapter
			*elseif (((enclave_leader = "you") and (lyall_fate = "dead")) or (lyall_fate = "banished"))
				*goto village_killing
			*elseif ((enclave_leader = "you") and (lyall_fate = "live"))
				*label village_killing
				"If the Clearwaters are still alive then our next step is obvious. Is it not? We kill them," 
				*if ((lyall_fate = "dead") or (lyall_fate = "banished"))
					Zev says.
					*goto village_killing_2
				*else
					Lyall says.
					*goto village_killing_2

				*label village_killing_2
				There seems to be a general consensus, and you have no intention of standing in their way. The enclave sets about preparing to take the village and you make your own preparations.

				*if clearwater_aid
					*check_achievements
					*if not(choice_achieved_bastard)
						*achieve bastard
					*set deviousness true
					*set quickthinking +10
					*set selfishness %+10
					*set ara_affinity %+15
					Despite helping the Clearwaters survive, you still allow the Wolf enclave to attack them. Spider herself would approve of such deviousness.
				*goto end_chapter
			*else
				*goto village_killing
*elseif enclave_leader = "both"
	*label revenge_talk 
	Lyall speaks while cutting into an apple with a short, thin knife. 

	*if lyall_talkback
		"There is one more thing to discuss, I think. The Clearwater village. What are your intentions, ${prenom}? They drew blood. I would think some retribution is in order. No?"
		*goto revenge_talk_2
	*else
		"We have a matter to discuss. The fate of the Clearwater village. They wronged us and drew blood. It is unfortunate, but we must retaliate."
		*goto revenge_talk_2

	*label revenge_talk_2

	"I agree," Roan adds.

	"It seems a petty thing, especially knowing that they were driven to it by Riser lies, but I will not argue with the group's decision," Hemming says. 

	The others weigh in, but Lyall is not looking at them. $!{lyall_he} stares straight at you. 

	*if lyall_talkback
		"What will we do, ${prenom}?" Lyall asks.
		*goto village_choice
	*else
		"And your counsel, ${prenom}?" Lyall asks.
		*goto village_choice 
*elseif ((enclave_leader = "you") and (lyall_fate = "live"))
	*set lyall_talkback true
	*goto revenge_talk
*else
	*comment the only case in which not covered by enclave-both, enclave-lyall, or 
	*comment enclave-you/lyall survives, would be if Lyall is dead/banished.
	As breakfast winds down, Zev approaches you. 

	"We have an outstanding matter, ${prenom}. We have to decide what to do about the Clearwaters who attacked us. Even if we put the Rising Sun's involvement aside, we still lost people. There is still a price for that blood. What do you suggest we do?"
	*goto village_choice

*label end_chapter 
*page_break
You look at the members of the enclave. Even for a short time it was good to be in the company of others like yourself, despite any friction caused by the clash of ideals. You have further business with the Quiet in the south.
*if prophecy_received
	If you intend to learn the details of Ghazal's prophecy, then you cannot stop here.
	*goto post_prophecy
*else
	If Spider's many-seeing eyes are to be believed, then there is something you must seek there.
	*goto post_prophecy

*label post_prophecy
You explain you will not be continuing on beside them.

"We have kept the enclave intact thus far. May it remain so until our next meeting," Roan says. 

"Unless we are all killed," Suba chimes in. 

The others shoot judgmental looks her way and she shakes her head, conceding, "It may not be likely, but it could happen."

"Safe travels, ${prenom}," Zev tells you, and claps you on the back.
*if enclave_purpose = "join"
	"Hopefully, by the next time you see us we will be stronger in number."
*if enclave_purpose = "fight"
	"The next time you see us, there will be a trail of Riser bodies between us."
*if enclave_purpose = "survive"
	"We will survive until the next time you see us. Do the same yourself."
*comment endif

"Careful in the south, friend. The Quiet are an odd bunch," Hemming says.
*if tribe = "Quiet"
	He adds, "Well, not all of them. Just, well…you know."
*comment endif 

*if lyall_fate = "live"
	And last, Lyall approaches you and gives you a tight nod. "I suppose I cannot convince you to join the enclave permanently?"

	"I seek answers. Unfortunately, I will not find them here. After, perhaps," you explain.

	"Fair enough. I have the feeling we will see each other soon enough."
*comment endif

After the last farewell, you pack what few things you have and a few provisions given to you by the enclave, and head out. There are only a few days to the border of the Quiet lands that you were directed to, but leaving the enclave makes the first few steps feel interminable.

*finish
