*if (attraction = "male")
	*set lyall_gender "man"
	*set lyall_he "he"
	*set lyall_his "his"
	*set lyall_him "him"
	*set lyall_possess "his"

*text_image chap_5.png center Five: Burning

[i]"What is war?" asked Brother Eel, who was the youngest of the sibling-gods, as they sat by the fire.[/i]

[i]"War is terror," said Sister Gazelle, while sipping honeyed water.[/i]

[i]"War is opportunity," said Sister Spider with a smile as she combed her long, dark hair with a fine, white comb.[/i]

[i]Sister Hawk stared into the flames, and said, "War is discourse."[/i]

[i]"War is collapse," said Brother Bear, after a lengthy period of consideration.[/i]

[i]"And you, Brother Wolf? What is war to you?" Eel asked.[/i]

[i]Brother Wolf picked his teeth with fresh animal bone, and simply said, "Kindling."[/i]
*line_break
-from a tale originating in the Clearwater lands.
*page_break

The sweat beads up on your pelt and runs down between your eyes. The salt stings, and your vision blurs as you search for a way out. You try to press the animal panic down in your gut, but everywhere you turn it is there, staring into your face and scratching at you. You whine, then you shout, and you do not stop shouting until the thick, black smoke cuts off your breath. 
*if sensitivity >= 20 
	You know, instinctively, that you are not this trapped animal, but the fear is real. The pain coursing through your lungs is a message. 
*comment endif

The flames rise around you until all is ash. You wake up abruptly, sweating and scanning for danger, and it takes a moment for the flames to register. You search, again, locked in the same scenario for an exit while the flames rise around you. You cough and try to shout, but the smoke again is too much. 

You experience this same terror a half-dozen more times before you truly wake, in your own skin and not a wolf's. 

*if wake_at = 1
	You must have tossed and turned in your sleep because when you roll over, Ghazal is beside you, propped up on one elbow, ${ghazal_his} incisive gaze leveled at you. 

	"A dream?" ${ghazal_he} asks. 

	*if sensitivity >= 15 
		"An omen. A message," you reply. 

		$!{ghazal_he} nods.
		*goto continue_dream
	*else
		"Yes," you reply.
		*goto continue_dream
	*label continue_dream

	"Tell me," Ghazal says. 

	You explain the dream in as much detail as your mind, still reeling slightly, can offer. Ghazal listens and then takes a deep breath before replying. 

	"The fire was real. I can feel the heat rising off of you still. As for the wolves…"

	*if sensitivity >= 15 
		"They are not wolves," you answer, finishing ${ghazal_his} thought. 

		The seer seems impressed. "Exactly. I think you have received a warning. Your wolves are in danger."
		*goto worship_explanation
	*else
		Ghazal shakes ${ghazal_his} head. "Sometimes these things are symbols. The wolves, I believe, are something else. People connected to you. Do you understand?"

		You do understand.
		*goto worship_explanation

	*label worship_explanation	

	Some gods have elaborate places of worship: Hawk commands sprawling temples built high into the sky, and Eel has sites of power in low, abandoned places. Hawk's Featherlight Circle, for example, once little more than a gathering of oddly shaped rocks, has become a dedicated site of worship with an intricate, swirling mosaic at its center, created from tiny stones brought from pilgrims who brave long journeys to see it. 

	Others, like Spider, like Wolf, exalt themselves through the flesh. 

	Wolf has no temples and disdains the cheap adoration of the masses; his is a small but devoted body of worshipers. As his avatar or once-avatar, they are as close to a cohort as you could claim. 

	If they are in danger, then it is your responsibility to help them. As much as Wolf takes pride in independence and self-sufficiency, there is a time for protecting your own.
	*page_break

	You prepare to leave and 
	*if wake_at = 1 
		Ghazal stops you. 

		"I wish your wolves the safety of passage beneath Gazelle's long stride,
		*if van_v_risers
			but do not return to this caravan, ${prenom}, or whatever sway you hold with our gods will not protect you from me. I promise that."

			$!{ghazal_his} expression is unreadable. 
			*if ritual > 15
				Yet you get the sense of enormous ritual power gathering in the tent around you, closing in on you like a noose.
				*goto post_ghazal
			*else
				You shiver without knowing why.
				*goto post_ghazal

			*label post_ghazal

			You climb out of Ghazal's bed and get dressed. The morning is chilly, but perhaps not as cold as your lover of a single night has become. Luckily you have somewhere else to be. 
			*goto post_dream_continue
		*else
			and you have my personal wish for safety and success, ${prenom}. And…"

			You wait for ${ghazal_him} to continue. 

			"It is not every day that you meet someone who understands what it means to live alongside the direct will of the gods. It is heartening to not feel alone for a moment, is it not?"

			*fake_choice
				#"I would not know; I always feel alone."
					Ghazal makes a face. "That is sad to hear, but not surprising, I suppose. Those faithful to Wolf walk a hard path, but that is not all you are."

					$!{ghazal_he} puts a hand on your chest. "${prenom}."

					"${prenom}," ${ghazal_he} repeats. "Do not forget that you are capable of warmth and softness, though the world may try to convince you otherwise."

					"And what would you convince me of?" you ask. 

					Ghazal scoffs. "Come back after all this is done and perhaps I will show you."
					*goto post_ghazal_goodbye
				#"It is. I feel at peace here, with you, and that feeling has been elusive."
					*label van_nostalgia
					"I try to remind myself what this place can be like for those viewing it with fresh eyes. I have spent my entire life here, and it sometimes feels like a prison," Ghazal says, while sweeping hair out of ${ghazal_his} eyes. "But I have responsibility, and people respect me. It is only my father and I, but with the people of the 'Van my family is bigger and more loving than most."

					Ghazal pauses, looks at you as if searching for something in your face. 

					"There is a place for you, ${prenom}. Even if you cannot see it yet. There is a place for you."

					Ghazal's earnestness makes it hard to disagree with ${ghazal_him}. Instead, you squeeze ${ghazal_his} hand and prepare to go.
					*goto post_ghazal_goodbye 
				*if (tribe = "Highwalk") #"This reminds me of where I grew up. It is a bittersweet feeling. But being with you makes it better."
					*goto van_nostalgia
				#"I think you have mistaken what this is. Was."
					Ghazal does not seem rattled by the statement. $!{ghazal_he} gives you a smile and raises an eyebrow. 

					"I am not asking for marriage, ${prenom}. You are an avatar to the gods. You understand what that means. You understand the weight. It is reassuring," ${ghazal_he} says, then adds, "Was."

					Ghazal wraps ${ghazal_him}self in a blanket and gestures toward the exit of the tent. 

					"Onward to adventure, no?" ${ghazal_he} asks. You take the cue and prepare to leave.
				#"You still have the voice of your god to keep you company, Ghazal. You should treasure it."
					Ghazal gives you a look that borders on pity, but changes at the last moment into something else. 

					"The gods are not our friends, ${prenom}. We are their tools, and if we are lucky they treat us as finely as a master of craft treats her hammer and her anvil. But we should not think that the love and admiration of the gods is the only love and admiration we are worth."

					$!{ghazal_he} takes your hand and kisses it. 

					"Be safe, ${prenom}, and above all: Be yourself."

					You soon realize that the sun is rising and it is time to go. 
					*goto post_ghazal_goodbye

			*label post_ghazal_goodbye

			You say goodbye to Ghazal and thank ${ghazal_him} again for ${ghazal_his} blessing. You leave the tent and head out into the morning. Shortly, you will leave for the south. 

			*goto post_dream_continue
			
	*else
		thank the dream-reader and her young companion before heading toward the edge of the 'Van.
		*goto post_dream_continue
		
*elseif wake_at = 2
	You find yourself again among the horses who stamp their feet and move away from you. You cannot blame them, considering that there is heat rising off of your ${skin_choice} skin in waves, and you smell like singed animal hair. 
	*if sensitivity < 20 
		So it seems your dream was something more than a dream. 
	*comment endif

	You spend the next hour wandering the caravan in the chilly morning asking after a shaman, or a dream-reader, someone who might be able to pull the meaning from your troubling dream. Unfortunately, with access to the seer cut off, it takes longer than you would like, but eventually you are directed to someone with some little shamanic gift.

	*label dream_reader
	The toothless old woman barely looks at you before barking out a few short sentences in some gnarled steppe language. 
	*if tribe = "Highwalk"
		Despite growing up on the steppe, you can hardly understand a word.
	She gestures to the child with ritual markings on his forearms who sits beside her.
	*if tribe = "Highwalk"
		He's a future shaman preparing to walk the long road to ritual power.
	*if tribe != "Highwalk"
		He appraises with frank curiosity, but then shyly averts his gaze when you look back. 
	*comment endif

	"She asks about your fire dream. She can smell the ashes," the child translates. 

	You explain your dream to the child, who patiently and carefully relays the experience to the woman. She shakes her head and makes a sign in the dirt with a bronze-tipped stick that she pulls out of her coat. 
	*if ritual > 15
		The sign is a ritual glyph that is rich with many possible interpretations: It can suggest, depending on the context, an elegy for the dead, a warning to the living, or both.
	*comment endif

	The old woman explains something to the child. He nods gravely, the serious expression is too onerous for his features, still pudgy with a child's fat. 

	"The wolves are in danger. The smoke gathers around them," he says, then adds, "she says that you will understand."

	And you do.
	*page_break
	*goto worship_explanation
*else
	You are in the tent of the
	*if caravan_helped = 1
		water-bearer
	*if caravan_helped = 2
		healer
	you assisted. After your disturbing dream, you find that your ${skin_choice} skin smells like cinders and singed hair. Your host, who was sleeping nearby, wakes along with you and is quick to ask after your health. You explain that you were dreaming, and he must notice the smell because he shakes his head and says, "a dream and something else beside. I will find a shaman to parse this dream of yours. Wait here."

	True to his word, he brings an old woman and a child, both bundled up against the chill of the morning, to the tent. You thank your host, and he gives you a warm nod and a smile before leaving you to the privacy of his tent. 

	*goto dream_reader
*label post_dream_continue
There will be a long journey across the southern reaches of the steppe before you find the area suggested to you by your dream. You set out while the sun is still grumbling awake. 

The shrub-land stretches endlessly in every direction, and it is hours before it offers any deviation.
*if selfishness > equity
	You should have stolen a horse in Mara's 'Van. The thought comes from nowhere to kick you while you travel.
*comment endif

The first of the trees appears on the horizon, but it still takes half a day to reach them. By then the sun is starting to set, and there are still whole days of travel in between you and the place the Wolf-dream has marked in your mind, hot and vibrant like a brand.
*page_break 

The place you find to the south of the steppe, the place you remember as the site of your own burning over and over again, is little more than rubble when you arrive. The campsite lies at the bottom of a gully you climb down into. The smell that greets you is not so different from the one in your dream; burned hair, singed flesh. 

The camp was little more than a handful of tents, which are now burned-out husks.
*if ((sensitivity >= 20) or (quickthinking >= 20))
	You notice there are no bones, no corpses.
*comment endif

You circle the camp three or four times before forcing yourself to decide what to do next. You have to make sense of the scene, discover who was responsible for burning this Wolf worshiper camp to the ground. You have several ways to go about it:

*fake_choice
	#I cut my flesh and mix my blood into the dirt where the lives of Wolf's own children were taken. If the land is sympathetic, I will have an answer.
		Your blood is more directly connected to Wolf than anyone's, and you can use that to your advantage. You bite down on the side of one wrist and elicit a few droplets of blood that you smear into the charred dirt. The feeling that follows is like being nudged by the wind.

		The forces you have roused from the dust urge you eastward, and you follow.
	#I look for the tracks around the camp and follow where they lead.
		You comb the campgrounds for nearly an hour before you find the tracks you are looking for. Here a print of a boot in soft earth, and there a trail of snapped twigs leading east. You carefully follow the trail and trust in your instincts and experience to lead you onward.
	#Check the ruins of the village. If the fires are just recently guttered out, whoever burned this camp down must be nearby.
		Your search method relies more heavily on conjecture than you are comfortable with, but ultimately, it is the best option available to you. Sure enough, the fires were burning hot until somewhat recently. You search the perimeter of the campsite and eventually come to a hard-packed path you would barely call a road. You follow it with increasing surety that you are moving in the right direction. If nothing else, a wolf trusts ${his} gut.

The search leads you just over a mile to the east and over hilly, rocky terrain. A village awaits you, if such a small collection of log cabins could be called a village. You hear a whistle as you approach the cabins, and look up to find a lookout atop one of the structures aiming a bow at you. The sentry cannot have more than thirteen years on his skinny body, but he holds the weapon with steady confidence. You get the sense he has had cause to use it before now. 

The boy's whistle calls others from their homes, and before long there's nearly a dozen people standing in a loose arrangement in front of you. 
*if sensitivity >= 20
	Their clothes are threadbare and much mended.
*comment endif

One of the villagers, a blocky woman with a tight scowl, muscles through the gathering and addresses you.

"Stranger," she says, packing the single word with suspicion. 

"A group nearby was killed. The trail ends here," you tell her, skipping pleasantries. 

Her eyebrows furrow in confusion. 
*if ((sensitivity >= 25) or (quickthinking >= 25))
	The gesture is almost innocent enough for you to believe that what she says next is the truth. Almost. 
	*goto convo_cont
*else
	It is a natural gesture you suspect means this is the first time she is hearing these charges, but the worried glances the villagers are trading gives you reason to suspect she is not being entirely forthcoming with what she says next. 
	*goto convo_cont
*label convo_cont
"My people go out to hunt on occasion, but they never engage others. It is dangerous enough without coming to blows over the occasional deer or boar. Would you agree, stranger?"

*fake_choice
	#"Are you sure you want to lie to the Wolf avatar?"
	#"The trail ends here, and I think you want to come clean before we have to have a disagreement."
	#"What, exactly, did you do to the Wolf worshipers at that camp?"

You demand an explanation and step forward, causing the young sentry to loose a warning arrow, which lands at your feet.

*if ishko_aid
	The woman-leader raises a hand, and the sentry does not fire again. 

	"One of our brothers-in-arms came from a trip to the west in the last few weeks. He told us many things, including a rumor that Ishko was saved by a ${man_woman} who arrived from the wild. I don't think it's a coincidence that you arrive here asking questions about the Wolf worshipers. Are you the Wolf avatar?"

	You give her a long stare before nodding. 

	She swears and bites her bottom lip. The villagers behind her look amongst themselves and pointedly avoid your gaze. 

	"It was not supposed to happen how it did," their leader says. "This far south, things are different from how they are in Ishko. Different, but not so different, you understand. The soldiers from the Rising Sun came at the end of winter, promised cooperation, and told us the wolves in the forest were keeping great stores of food while we starved. We survived the winter, but…"

	You look around at the gaunt faces and tattered rags the villagers are wearing. You can already tell how the story played out. 

	"The planting is slow-going and the harvest is still a long way off. We were starving and the wolves—" the leader sees your expression go dark at the slur. "—Excuse me, the Wolf worshipers. They were fewer than we are and they had so much food stored. We only meant to trade, but they were fierce. I couldn't hold my people back, and the Wolf worshipers didn't even try to…" She pauses. Stands straighter. "The food was a lie. They barely had any more than we did, but we didn't know until after. We burned the bodies."

	The body is Wolf's temple and burning it after death is a small token of respect to the savage god. But the fact remains that these villagers murdered Wolf's worshipers on the basis of a rumor. Your fist is curled so tightly when you hear this news that when you unfurl your fingers, there's a bright red line where your nails met your flesh. Your anger is righteous, but you are not all Wolf, and in the relative calm of reflection, where do you think the blame for this attack lies? 

	*label clearwater_judgement
	*choice
		#With the Clearwaters themselves: They slaughtered people who had faith in Wolf. There is no need to look further to find blame.
			*set action %+10
			Of course these Clearwaters are responsible for the deaths. It was with their own hands that they slew your brothers and sisters. Whatever comes next, you can go forward with the certainty that they deserve to pay a blood price for their actions and anything less would be a mercy.
			*goto village_fate
		#With the Rising Sun: They manipulated these villagers into killing their enemies through falsehoods.
			*set equity %+10
			The Rising Sun came to these people and prodded their weaknesses, forced them to make a terrible choice like an animal with a limb stuck in a snare. You try to keep in mind that in this situation, these people were not the hand that struck your Wolf siblings down. They were the knife.
			*goto village_fate 
		#It does not matter who was responsible. All involved must pay. 
			*set action %+5
			*set equity %+5
			Whoever wielded the knife or drew the bow is as culpable as the voice that whispered in their ear. The Clearwaters and the Rising Sun and anyone else whose fingers are in this mess are responsible, and it falls to you to mete out fit punishment.
			*goto village_fate
		#No decision can be made about the intent of the attack without further investigation.
			*set deliberation %+10
			No one will benefit from hasty decisions here. The worshipers of Wolf are dead and neither hand-wringing nor immediate violence will put breath back into their charred bodies. You try to remind yourself of that every few moments and hope that the thought will bring with it some much-needed calm.
			*goto village_fate
		*selectable_if (tribe = "Clearwater") #[i]Clearwater Clan[/i]: Clearwaters would not have attacked except for under extreme pressure. I know people like this, communities like this, they would not have killed without reason.
			*set deliberation %+5
			*set equity %+5
			You are more than familiar with the Clearwater attitudes toward outsiders, but you find it hard, verging on impossible, to believe the Clearwaters would have killed Wolf worshipers, or anyone, without being pushed to it. You do not necessarily think that excuses the matter, but it helps you uncurl your fists. 
			*goto village_fate

	*label village_fate 

	So you are left standing before a handful of starving villagers implicated in an act of great violence against the god you once served. You press down the unthinking rage that is a part of Wolf's legacy. At least for long enough to make a decision. What do you decide to do with them?

	*choice
		*selectable_if ((van_attacked = false) and (van_v_risers = false)) #Counsel the Clearwaters to connect with Mara's Caravan, thus ensuring their survival through the next rough winter.
			*set equity %+10
			*if (((quickthinking >= 25) or (influence >= 3)) or (survival >= 25))
				*set sensitivity +5
				*set village_state 1
				*set pantheon_regard +1
				*set clearwater_aid true
				*set suggest_village_aid "Ishko"
				*label village_aid_decision
				You point out their thin faces and torn clothing. 

				"You will not last another winter on your own," you tell them.

				"We will. We always have," the leader replies, her voice is tired though her shoulders are square. 

				You shake your head. 
				*if suggest_village_aid = "Ishko"
					"Mara's Caravan is three days' travel to the north, at the edge of the steppe. Send a rider and make arrangements with them to trade through the cold months. Otherwise, I advise you to make for Ishko and beg shelter, because your life here is untenable."
				*if suggest_village_aid = "Risers"
					"From the moment you accepted their words as truth, you became a part of the Rising Sun's group. Seek them out for your shelter. You have proven to yourselves to be their creatures. They will accept you. Otherwise, you will not survive the next hard winter. I promise you that."

					"We have no love for the Sun Soldiers," the village-leader says. 

					"Fine. But love won't keep you alive," you reply. 
				*comment endif
				
				The mood of the town is somber, but you can see they are carefully considering your words. Their leader can catch the scent of a growing consensus as easily as you can. She's shrewd, and it is not difficult to see how she came to be in charge of these people. 

				"And the worshipers? You expect us to believe that the avatar of Wolf will let us walk away from their deaths unharmed?" the town's leader asks. 

				"Wolf is gone," you reply. 

				There are a few gasps. The Wolf god is not well-loved: Who could truly love a force of violence and hunger? But your suggestion that a god could disappear is still a kind of blasphemy.

				"The choice of how to move forward is yours, but you have my recommendation," you tell them.

				The villagers are still on edge as you turn away. The sentry still holds his bow at the ready and their leader never takes her eye off of you, but once you turn your back to the Clearwaters, in your mind, your business with them is over. If you think about them and nurse the anger seething just under your calm demeanor, it would end with their bodies strewn on the ground. 

				You place one foot in front of the other and walk away without doing harm to a single person. 
				*goto leave_village
			*else
				*goto village_aid_fail
		#Tell the Clearwaters to join with the Risers, because without the aid of a larger group, they will remain a hungry, desperate people open to the manipulation of others.
			*set equity %+10
			*set suggest_village_aid "Risers"
			*if (((influence >= 2) and (riser_affinity > 50)) or ((sensitivity + quickthinking) >= 30))
				*set chaos_score +1
				*set survival +5
				*set village_state 1
				*goto village_aid_decision
			*else
				*set restraint %-5
				*label village_aid_fail
				You explain to the villagers it will be difficult for them to survive without the aid of a larger group to provide goods and services they do not have enough hands to do themselves. You try to explain this as gently as you can, considering that these villagers are responsible for the death of Wolf's worshipers, your brothers and sisters in faith. 

				Perhaps it is in the tone of your voice, the natural ferocity of your stance, or the mere suggestion of danger, but the villagers refuse to consider your words. 

				"We will survive on our own, stranger, as we have for years," their leader explains. 

				"This is survival? Attacking other groups as if you were half-starved dogs?" you reply, snarling without exactly meaning to. 

				"We were lied to and we regret what happened, but we will be vigilant going forward," she says.

				"You will be, because it will not go well for you if I have to return."

				The village-leader's posture stiffens, but to her credit, she does not rise to the provocation. The villagers take her lead and mostly remain calm, though you can see that a few of them are biting back the urge to fight.

				It takes some amount of restraint to turn away from the Clearwater village, especially knowing that there is a sentry with a bow trained on your back. But the villagers have made their choice, and you have other concerns beside their folly to attend.
				*goto leave_village
		#Finding any survivors among the wrongly attacked and displaced Wolf worshipers is your main priority. Tell the Clearwaters they will aid in the search or face your wrath.
			*set deliberation %+10
			*if (((influence >= 3) or (equity >= 70)) or ((sensitivity + combat) >= 35))
				*set clearwaters_search true
				*set village_state 1
				*set pantheon_regard +1
				You speak and the villagers stare at each other in surprise, as if waiting for you to reveal some trick. They probably wonder if it could really be so simple earn the forgiveness of the vengeful Wolf god. 

				You repeat yourself: "You will comb the woods and search for any survivors. Preferably before nightfall?"

				They will not move on your authority, but eventually their leader gives her consent with a tight nod, and they scatter. A few of them stay behind to stand beside their leader, presumably to protect her from the dangerous stranger. 

				"Do you think they will find anyone out there?" the woman-leader asks. 

				"It is possible, but there are no certainties," you reply.

				"You have no faith?"

				"I will answer that once they find survivors."

				You set off to the forest yourself and no one stops you or questions your aims. The Clearwaters might well find surviving Wolf worshipers, but they do not have your nose, and they do not have your senses. You have to join in the search yourself. 
				*goto leave_village
			*else
				"We would help you if we could, but our priority is to fend for ourselves. To survive. We cannot spare the hands," the village-leader explains. 

				You stare at her in something like shock. 

				"You refuse to give so little of yourselves to repay what you owe? You should be begging clemency," you growl. 

				A handful of the villagers step back, though you pose no immediate danger to them. To her credit, their leader does not move. 

				"This is about survival," she says. 

				"And you will not survive, if you do not right the wrong you have done."

				"I am sorry."

				"Not yet," you say, and step toward her. 

				The armed villagers move forward at the perceived threat and their leader allows it. It is not long before they are crowding forward and brandishing their weapons. 
				*goto clearwaters_fight
		#Leave the villagers alive, but burn down their village. When they are forced to scrape by without a home or basic safety considerations, then they will understand the gravity of what they have done.
			*set action %+5
			*set deliberation %-5
			*set selfishness %+5 
			*set equity %-5
			*if (((combat + ritual) >= 30) or ((influence >= 3) and (survival >= 20)))
				*set ara_affinity %+10
				*set quickthinking +5
				*set village_state 3
				"You can survive without this place you call home. It is a bloodless price for your crimes against Wolf. Any other god would demand more than this pittance," you tell them. 

				Their leader, so sure of herself until now, falters. 

				"We cannot. It is too much to ask," she says. 

				"The other option is death. Would you prefer it? Would you condemn your people?"

				She seems like she is about to challenge you, but an old shaman approaches and puts a hand on her shoulder. The shaman regards you with one white iris, then turns back to the village leader. 

				*if gender = "none"
					"$!{he} are
				*if gender != "none"
					"$!{he} is
				serious. If we fight here, we risk losing many. If we accept this judgment, then we have a chance to start over." The shaman tugs at her sleeve. 

				She blinks back tears and is sober-eyed when she next meets your gaze.

				"Will you give us time to collect our belongings?" she asks.

				"I can do that much."

				The villagers collect what little they own before you set fire to their town. 

				The buildings in the town are modestly constructed with the goal of keeping the cold out rather than standing up to arson. 
				*if ritual > combat
					You hardly need to do more than imagine the town burning and you can already hear the excited whisper of the flames sleeping within the dry wood of the buildings in town, ready to ignite. You ask the flames to wake and they do slowly, raising fire and smoke high above the town. The ritual is exhausting, doubly so considering you have to keep an eye out from an attack from the villagers, but they keep their distance. Their fear keeps them docile. 
					*goto burnt_town
				*else
					A few of the villagers shout abuse and one or two approach you before their family and friends drag them away. Ignoring them, you gather enough wood to set the first building aflame. The fire spreads, and you help it along by taking a torch from home to home. It is grim and grueling work, yes, but you do it without flinching. 
					*goto burnt_town 

				*label burnt_town

				The burning does not calm you and the wailing of the more emotional villagers does not bring you peace, but there is a sense of balance about what you have done that feels right in your gut. You cannot help but feel that even Wolf, as bloodthirsty and unthinking as he could be, would have approved of this resolution. 

				The villagers wander away from the flames and to whatever future lies before them. You wait until the fires rise to their highest point and ensure that the blaze poses no danger to the surrounding woods before you leave the burning village behind. 
				*goto leave_village
			*else 
				You tell the Clearwaters gathered before you that you intend to burn down their village, and their looks are incredulous. 

				The woman-speaker cocks a head to the side. "Do you think we will allow this? Are you mad?"

				You bare your teeth. As unnaturally long and sharp as they are, it gives an effect of terror. 

				"Do you think I am offering you a choice?" you ask.

				The village leader has iron in her spine. She replies, "No. I suppose you are not." She gestures to her people and they surge forward.

				*goto clearwaters_fight
		#Demand reparations be paid to the Wolf avatar. They will give me whatever they have that is of value.
			*set selfishness %+10
			*if (((influence >= 3) or (combat >= 25)) or (ritual >= 25))
				"You will repay the offense you have offered Wolf," you tell the villagers. 

				"We have nothing of value to you here, unless you mean to starve us and our children," their leader replies. 

				"I can extract my payment in blood and bone, if you prefer."

				Some of the villagers are visibly rattled by your threat, but the village-leader raises a hand and calls for calm. "We have one thing of consequence. A set of rituals handed down to us from Mother Hawk. Both are sacred to us; one of them is used to keep our hunters safe on their long hunts and the other to foster a deeper connection with the goddess. We can offer you knowledge of one, but not both. And Hawk will not be pleased to have her secrets pilfered."

				Which ritual will you take from the Clearwaters?
				*choice
					#The hunting ritual, which will increase my ability to survive dangerous situations.
						*set survival +5
						*set clearwater_gift "survival"
						*label ritual_gains
						*set hawk_affinity %-5
						*set bear_affinity %-10
						*set village_state 1
						The village shaman comes up through the group and looks you over with one milky eye. 

						"Thought you'd be bigger," the shaman, of indeterminate gender, says.

						"Well you'll have to close your eyes, obviously," the shaman chides, and you do. 

						The experience that follows is a strange combination of wonder and frustration. You try to grasp at the feeling, which fills your head like a consistent buzz, but is not exactly noise. It is as if there are words of some dream-language filling up your head. You struggle and strain to understand it, but the more you reach for it, the further understanding flees.

						"Well, open your eyes, or do you want to finish your daydream first?" The sardonic voice of the shaman cuts into your thoughts.

						"You are an impertinent wizened thing," you say, then open your eyes. 

						The shaman shrugs. "I have been called worse. The ritual is yours. I hope you choke on it."

						The leader of the village makes herself known again and gestures ruefully toward the woods from which you emerged. "We have nothing else for you, Wolf-faithful."

						You feel different. Changed. 
						*if clearwater_gift = "ritual"
							The sky above you seems to be whispering, and the colors around you are more vibrant than they have ever been.
						*if clearwater_gift = "survival"
							Your lungs feel fuller and your legs sturdier. It feels as though you could run for ten miles or more without tiring.
						*comment endif

						"This is enough," you tell them. You are not entirely sure it is. Does it make up for the dead worshipers? Perhaps not, but this ritual will help you, and that will have to be enough for now. 

						You turn to leave the village, and you can feel them watching you go. Waiting, maybe, for you to change your mind and attack. You have more important things to do. 

						*goto leave_village
					#The communication ritual, which will make me more capable of getting the attention of the gods.
						*set pantheon_regard +1
						*set clearwater_gift "ritual"
						*goto ritual_gains
					#I want both. Naturally. 
						*set selfishness %+5
						*set equity %-5
						*label avarice
						The village-leader smirks, but the expression seems sad on her broad face. Or perhaps just resigned. 

						"Your avarice is disappointing, Wolf avatar. We were fools to consider making any deal with your like."

						She drops a hand and an arrow flies. You dodge it, but there can be no doubt. The villagers mean to fight. 

						*goto clearwaters_fight
			*else 
				*goto avarice
		#Slaughter the Clearwaters for their actions.
			*set action %+10
			*set deliberation %-10
			*if ((combat >= 20) or (ritual >= 20))
				*if (combat > ritual)
					*goto combat_slaughter
				*else
					*goto ritual_slaughter
			*else
				*if (combat > ritual)
					*goto combat_defeat
				*else
					*goto ritual_defeat
		#Kill only their leader, allowing the others to survive with the death of their leader as a warning.
			*set action %+5
			*set equity %+5
			*if (((influence >= 2) and (combat >= 15)) or ((influence >= 2) and (survival > 15)))
				*if pacifism 
					*set pacifism_broken true
				*set death_toll +1
				*set sensitivity +5
				*set village_state 2

				A few of the villagers object loudly and raise their weapons with every intention to fight, but their leader settles them down with one clear shout.

				"A fair deal," she says. 

				The incredulous noises that come from the villagers she leads suggests she is well-liked or at least that these people have enough pride in themselves to stand up for their own. Either way, it does not change the circumstances. The exchange of one Clearwater life for all of those they have killed is more than fair. 

				She comes forward with the confident gait of a soldier. 

				"Do not seek vengeance for this," she tells her people. "It ends here."

				She looks into your eyes as if searching for some confirmation that you will keep your word. There is nothing there for her to find. She cannot know your mind, so it is doubly noble for her to offer herself as a sacrifice. 

				"It ends here," you agree. 

				You have no reason to make her suffer, so you do not. When it is over you turn the body over to the villagers to bury or burn. None of them will meet your gaze, and you could not expect anything different. As you watch them swaddle her body in white cloth and prepare it for burning—the Clearwater's preferred method for disposing of the dead, commending them to the sky—you learn something of their small mercies and take that knowledge with you. 

				You return to the woods from which you came and half-expect the villagers to follow, incensed and bloodthirsty, but by the time the log cabins disappear from view, you cannot see one person behind you. 

				*goto leave_village
			*else
				The woman-leader looks at you, blinks, and actually laughs out loud. 

				"You have been in the wild too long."

				She gestures to the villagers behind her and they slowly move toward you. 

				*goto clearwaters_fight
*elseif riser_affinity >= 58
	"The Sun soldiers told us about Ishko and their ally there. Now that I consider it, you fit that description quite well. Have you come to tell more of their tales?" their leader asks, her tone full of spite. 

	The woman drops a hand, and another arrow comes sailing. This time it is not intended to miss. You dodge out of the way, but the villagers are spreading out and wielding actual weapons, not the improvised farming implements of their Ishkoan brethren. 

	"Did you think you could come into our home and finish what your friends started?" she asks. 

	You try to respond, but she hisses over you. "Enough talking, stranger."

	*label clearwaters_fight

	Do you reply with violence of your own, or do you attempt to force a diplomatic solution? 

	*choice
		#Protect myself without killing the attacking Clearwaters.
			*set deliberation %+5
			*set action %-5
			*if pacifism
				*set pacifism_broken true
			The villagers come streaming toward you as soon as they realize you aren't going to give up peacefully. They are largely untrained, but there are a few fighters among them. You take them on in ones or twos and hold your own. You doubt the child-sentry will fire arrows into the group, which is a relief, but stray too far from the group, and he won't hesitate to put an arrow into you.

			*if (((combat >= 20) and (restraint >= 33)) or ((ritual >= 20) and (restraint >= 33)))
				*if (combat >= ritual)
					*set village_state 1
					The villagers who have not been thoroughly trained to fight are not much of a challenge. They tire easily and telegraph their moves with every swing of the ax or slice of the sword. You wear them out by dancing around their clumsy strikes, instead of parrying their blows and leaving yourself open to follow-ups by their better-trained peers. Once the weaker ones start to slow, you sweep their legs or drive your elbows and knees hard into their ribs or break their noses. 

					The blows hurt enough to incapacitate without killing and leaves you more time to deal with the actual fighters among them. 

					There are only a few, but they are fierce. The three of them try to corral you and press the advantage of their superior numbers. But they have not faced your like before. Your speed is greatly enhanced by your time spent harboring the divine, and their blows land on open air. You can almost tell the moment when the balance tips from predator to prey in your favor. 

					One of the fighters breaks from the group and tries to escape. It is enough of a distraction for you to take down another and engage the last in a fistfight that ends with him splayed out in the dirt. You keep moving, though, already anticipating the sentry's arrows, and they begin raining down before long. 

					You need only move out of the range of his shots to frustrate the young archer and eventually he lowers his weapon, defeated by practicality. 

					*label fight_end_nonlethal
					"The fact that you are alive to groan into the dirt is a gift," you tell the defeated villagers. "Get up. Lick your wounds, but do not forget that it was by my kindness that you lived. Harm another who belongs to Wolf and the next price will be steeper."

					You turn and walk away without another word. What else is there to say? You let them live. You trust they are grateful enough. 

					*goto leave_village
				*else
					For most shamans, a ritual requires careful planning and days of preparation to execute even the simplest of feats. Your relationship with the divine is different. Was it because of Wolf's influence on your body and soul, or did your natural aptitude make you attractive to the erstwhile god? You do not know, but when you call to whatever forces lie dormant in this village, they reply in force.

					The roots of the great trees of the surrounding woods reach up through the earth like fingers to grab at those who come against you. The villagers cry out at the supernatural assault and try to hack at the roots while they coil around ankles and legs. The child archer on the roof fires arrows, but the wind blowing through the village is allied against him, and he consistently misses his mark. 

					One of the villagers, an ancient shaman, chants his ritual words in an attempt to thwart or invert your own rites, but the shaman is unable to stop or slow your workings. You almost feel sorry when the ground trembles beneath him, and a root slaps the fragile ritualist aside.

					Before long, all of the villagers who raised weapons against you have been taken care of, but still live. 

					*goto fight_end_nonlethal 
			*elseif ((combat >= 25) or (ritual >= 25))
				*set restraint %+10
				*set death_toll +15
				*if (combat >= ritual)
					*set action %+10
					*set village_state 4
					Some of the villagers are not strong fighters. You can tell by the way they tire after just a few strikes and how easily you can dispatch them. The ease of their defeat stokes something in you, and you find yourself wanting to push them harder, to see what they are really capable of. You bring down a kick on a villager's already twisted leg and delight in the crunching of broken bone.

					You did not mean to hurt the man, at least not entirely. It was just easy to do and so you do it. You find yourself growing hungry for the hunt, so you are pleased when the other villagers keep coming. 

					You do not kill all of them. Some are truly worthy adversaries and you try to leave them alive, but the others are inconsequential. They do not even offer a challenge, and so their lives are made meaningless. 

					Eventually, you get your fill of destruction and you realize how far you have gone when you only meant to defend yourself. You survey the wrecked bodies before you and feel a contentment of sorts. It is a deep satisfaction that is on one hand relaxing and on the other truly terrifying. 

					You leave the village quickly and no one follows you. They would not dare. 
					*goto leave_village
					*comment combat success & restraint failure
				*else
					*set action %+10
					*set village_state 4
					You were cautioned once by the ${tribe} shaman who served as your informal instructor in the arcane rites, that beseeching the gods or calling to the land while in the grips of turbulent emotion was an unparalleled danger. Still, you reach out to the land, and the wind, and the heat of the sun that the earth remembers, and call them up in your defense. 

					The forces of the land respond, and everything afterward is chaos. One of the villagers erupts into flames while another is strangled to the ground by a huge root that suddenly emerges. You try to pull the freakish piece of nature away from the man with the force of your intent, but by the time you do, he has gone limp.

					A terribly old shaman mutters sacred words in an attempt to settle the forces you have brought to bear on this village, but the situation has gone beyond his capabilities. He collapses into an exhausted heap, and the madness around him rages on. 

					Eventually you manage to quiet the raging forces, but the damage is already done. Several villagers lie dead and others wander aimlessly in the wake of the strange and sudden attack.

					There is no apology that can make up for the lost lives, so you do not even try. It would be only be an insult at this point and, if you are honest, there is a part of you that enjoys the kill. There is a thrill to it that leaves you feeling more satisfied and clearheaded afterward. You leave the broken village behind without a second glance.
					*comment ritual success & restraint failure
					*goto leave_village 
			*else 
				*if (combat >= ritual)
					*label combat_defeat
					*set restraint %-5
					*set defeat_by_clearwaters true
					*set village_state 1
					Your best option is to take on the villagers one at a time and split them up so that they don't overwhelm you.

					The first few villagers are clearly not trained for combat. They overreach and work themselves too hard while trying to land blows. It is easy to evade them, and you let them tire themselves out before you deliver incapacitating blows.

					But then the genuine fighters move in. They are slow and methodical. They employ exploratory feints and counter-moves in order to take the measure of your speed and strength. They surround you and draw you into making strikes that weaken your position. One of them dives in, deft as a snake, while another comes up on your side and sweeps your leg from under you with the butt of a spear. 

					*label save_before_death
					It's only at the last instant, when the spear point is coming down toward your throat, that you call on your reserves of strength and power, which gives you enough speed to roll away. You leap to your feet. The villagers, so sure that they had you pinned, are unprepared when you sprint toward the woods. 

					You can hear the experienced fighters giving chase, but the voice of their leader shouts out. 

					"Leave ${him}. Let ${him} crawl back to where ${he} came from," she says, and your pursuers break off behind you. 

					It is humbling to be defeated, and you can almost hear Wolf's mocking snarl in your ears. But it is just your sense of chafed pride that follows you into the woods. 
					*goto leave_village
					*comment combat failure
				*else
					*label ritual_defeat
					*set restraint %-5
					*set defeat_by_clearwaters true
					You call out to the land, and the wind, and all of the elements therein for their support, and they respond instantly. It is not so easy for most who practice the deep mysteries. It takes a strong will to be so cavalier with the rites of power. 

					You draw up the power of the earth, and the enormous roots of the great trees of the woods around the village start to emerge from the ground. They whip about frantically and send the armed villagers scattering. The young archer on the roof lets his arrows fly, but the air, it seems, is on your side. The sentry's arrows miss their marks.

					You have the shape of the ritual in your mind, and it is strong until it is not. The feeling of another ritualist twisting the shape of your rite is like having fingers digging through your skin in an attempt to extract your soul. The pain is excruciating, and when you fall to one knee you catch sight of the shaman, an ancient thing supported by a wooden cane and ashen with the strain of forcing your workings awry.

					The shaman's interference gives his allies a chance to regroup. They come for you, and in your weakened state you hardly have the strength to fight them off. One of the villagers sweeps your leg with a spear and you tumble to the ground. 

					*goto save_before_death
					*comment ritual defeat 
		#Seek a diplomatic outcome.
			*if (((sensitivity >= 20) or (quickthinking >= 20)) or (influence >= 3))
				*set village_state 1
				*set bear_affinity %+15
				"If this comes to blows, I promise you will lose friends, brothers, sisters in this fight. Even if you manage to defeat me, I will make the cost great enough for you to regret this day for the rest of your lives."

				The armed villagers hesitate. 

				"And we should just let you go, then?" the leader asks. "Even knowing that you could return to kill us in our beds?"

				"You can live in fear of an unknown tomorrow or you can die right now for certain. Your choice," you reply.

				The woman looks at you with a mix of resignation and disgust. "Let ${him} go."

				You incline your head in acknowledgment of her choice, but she is already walking away. You can understand why she might be eager to put this day behind her. 

				As for yourself, you head off toward the woods you came out of. If there is any sign of survivors from the Wolf worshiper massacre, then they should be your next goal.
				*goto leave_village
			*else 
				*set restraint %-5
				You attempt to negotiate with the villagers, but instead of listening they use the opportunity to rush you. You are forced into a defensive mode, and things quickly turn ugly. 

				Though not all of the villagers are capable fighters, a few of them are and they come against you in a fury. You hold them off for a while, but they press their advantage and it is not long before you find yourself in a bad position. 

				One of the better fighters manages to use his spear to sweep you off your feet and you fall badly. 

				*goto save_before_death
		#Sate my Wolf's urge: Kill them all.
			*if ((combat >= 20) or (ritual >= 20))
				*if (combat >= ritual)
					*label combat_slaughter
					*if pacifism
						*set pacifism_broken true
					*set restraint %+20
					*set death_toll +30
					*set village_state 4
					There's no reason for you to hold back. The boundaries that keep you civilized are erased when your life is threatened. If the villagers want to fight, then you are happy to oblige them. 

					You charge the first set and their terror is obvious as you leap into their midst. Your body falls into a calm rhythm of violence as you bash and claw through the soft, untrained bodies of the villagers before you. Toward the back of their ranks are real fighters who present a challenge and make you sweat with their feints and quick parries. The blood beats high in your ears and you sweat with the effort of taking them down, but they inevitably fall, too. 

					When it is over, there is no one left to stand against you. The child archer cowers on his rooftop perch and you don't bother to go after him. How much fight would he offer, anyway? 

					You feel sore but satisfied afterward. The martial trial allowed your instincts to run rampant, and you appreciate the exertion. As for the lives you've claimed, you are sure that Wolf would have done worse, which makes it easy to put the dead behind you and walk purposefully back to the woods.
					*goto leave_village
				*else
					*label ritual_slaughter
					*if pacifism
						*set pacifism_broken true
					*set restraint %+20
					*set death_toll +30
					*set village_state 4
					As a child, when you were first learning about your gift for ritual, the ${tribe} shaman who was your instructor cautioned you against calling out to the land, spirits, and gods, while in the grips of strong emotion. The results could be dire. 

					But you have the wrath of a god to visit upon these people, and you refuse to stem the tide. You reach out to the land, and the wind, and the very heat of the sun cradled in the ground's memory, then you unleash them all. The log cabins quake and lose structure, toppling in on themselves while several of the villagers burst into flames where they stand. The wind buffets those who try to escape the chaos and keeps the villagers corralled in the center of the fray.

					You spy a shaman, old as time itself, attempting to shout his ritual words over the din, but the wind cuts off his words and a vortex surrounds him, choking the air from his lungs. 

					Eventually the righteous anger of the earth subsides, and what's left is a shambles. Many of the villagers lay unmoving while a few crawl about and attempt to rouse their fallen allies or see to their own wounds. You cannot help but feel vindicated in this. The Clearwaters brought this fury down upon themselves, and you were merely the vessel. 

					Unburdened by conscience, you turn away and head back to the woods from which you came.
					*goto leave_village
			*else
				*if (combat >= ritual)
					*goto combat_defeat
				*else
					*goto ritual_defeat
*else
	"I cannot allow you to go any further. Please understand that we live in difficult times," the leader explains.

	"Did you kill the Wolf worshipers?" you ask at last.

	The village-speaker goes silent. When she speaks again, her voice is barely above a whisper. "It was not our intention to harm anyone. We wanted to do it a different way.

	"We were told they were hoarding food. Poaching off of our lands and disappearing before we could respond. After a difficult hunting season, there was little enough to go around as it was. We had to do something. The confrontation…they were wolves in men's and women's skins. We would not have chosen to do what we did. No one would have chosen that. But it was a lie. They had no more food than we did. Our conflict. Their deaths. It solved nothing."

	You take a moment to process this tale. Your brothers and sisters murdered for food that never existed. With calm that you do not feel, you ask, "And who told you these lies?"

	"The Sun soldiers who came through here."

	The Wolf worshipers are dead and your only consolation is that their bodies were burned, thus setting their souls free of the skin. There will be action next, and you will have to come to a decision about how to move forward with this knowledge. But for the moment you consider where the blame for this travesty falls. Who bears the greatest share of guilt? 

	*goto clearwater_judgement 

*label leave_village 
*page_break
You leave 
*if village_state = 1
	the bewildered, starving villagers behind
	*goto leave_village_2
*elseif village_state = 2
	the newly leaderless village behind 
	*goto leave_village_2 
*elseif village_state = 3
	the smoking remains of the village behind
	*goto leave_village_2
*else
	the village behind
	*goto leave_village_2
*label leave_village_2
and head back to the ruined camp where the Wolf worshipers were killed. If any of them survived, then you might be able to track them from there. Merely being in the space where Wolf's followers died is disturbing, but without Wolf's direct intercession, there is no other way to find survivors. 
*page_break
You spend some time among the ashes looking for footsteps or waiting for some spark of divine knowledge, but nothing comes. Night is coming quickly, and you know that it is best to use the last of the failing light to find shelter. 

You are climbing up out of the gully when you see a shape moving among the trees.

"Come out and face me!" you shout. 

The person, a ${lyall_gender}, emerges from the trees and you recognize something in ${lyall_his} bearing. $!{lyall_he} has the same fierceness in ${lyall_his} glare as you do. It is like looking into a mirror that reflects the deepest self. $!{lyall_his} hair is short and hastily cropped, ${lyall_his} fingers slide up and down the point of a throwing knife held light in ${lyall_his} right hand.

"You smell like a friend," ${lyall_he} says. "But we will see the truth of that. What is your name?"

"${prenom}."

$!{lyall_he} does not visibly react to hearing your name, but after a moment slides ${lyall_his} knife into ${lyall_his} belt. "The Wolf avatar arrives, then. Too late to save their lives. You know that, right?"

"I had the dream and I came to do what I could."

"What you could," ${lyall_he} repeats.

"And who are you?"

"Lyall. The so-called leader of this Wolf-enclave. What remains of it, anyway," ${lyall_he} says. "We looked through what was left behind by whoever killed our brothers and sisters, but I felt I had left something behind, something undiscovered. I suppose it might have been you."

You understand something of ${lyall_his} impulse. Whatever causes ${lyall_his} gaze to linger on you, causes yours to do the same. An unspoken kinship, or something else. You do not have time to consider the feeling further. Lyall turns toward what might generously be called a path, and starts down it. 

"I suppose you should follow me," ${lyall_he} says. 

*finish
