*if ((attraction = "male") or (attraction = "bi"))
	*set ghazal_gender "man"
	*set ghazal_he "he"
	*set ghazal_his "his"
	*set ghazal_him "him"
	*set ghazal_possess "his"

*text_image chap_4.png center Four: Other People's Problems

[i]The seeress of Gazelle spread her skirts about her—which were as bright as the day, as warm as the hour of noon, and tranquil as the night.[/i]

[i]Her guest, bowing low, asked, "Great Seeress! How can you walk in such voluminous skirts?"[/i]

[i]The seeress laughed. "Where would I go when all the world humbles itself to seek me out?"[/i]
*line_break
-From an oral myth of the Highwalk people.
*page_break 
*if risers_live 
	*set van_attacked true

Grass stretches out in every direction for mile after unbroken mile.
*if tribe = "Highwalk"
	The Highwalk call this place the doubled-sky because the hard grassland is as endless as the firmament above it.
*if tribe != "Highwalk"
	The feeling is vertiginous, seeing how long the land can go without stopping. You wonder how anything can live here or find their way. 
You travel the grasslands for days searching for some sign of the caravan you seek. There are hardy plants and some small animals to be found, and they sustain you through the hot days and cool, windy nights. The howling wind that blows across the steppe at night nearly sounds like a voice attempting to speak to you. 
*if tribe = "Highwalk"
	Among your people, that screaming wind is the Sister Gale who is cursed to tell the hour of one's death in a voice that only the dying can hear.
*comment endif 

You find the caravan's trail eventually. This roving community leaves behind wide swaths that are hard to miss. 

*if ((riser_affinity > 55) and (riser_conflict = false))
	However, instead of finding the Mara's 'Van waiting for you, you encounter two members of the Rising Sun on horseback. You can tell them by the bold standard sewn into their jackets. You half-expect hostility. They spot you and spend a moment conferring before approaching. 

	Neither of the two are familiar to you. One is a woman with a high forehead and an imperious look, while the other is a man with close-set eyes and a crooked smile. Both are armed: She has a short-bow, string taut between her fingers, and he has a wicked-looking axe hanging from the side of his saddle. 

	"Hail, traveler," the woman says. 

	You nod a greeting. 

	"You were at Ishko, were you not?"

	*fake_choice
		#"Yes."
		#"No."
		#"What business is it of yours?"
		#Say nothing.
	*comment endif

	The man giggles, as if you have made some terribly funny joke. He stops when the woman shoots him a dangerous look. She turns her attention back to you. 

	"We have heard quite a bit about what happened at Ishko. The report mentions a ${man_woman} with ${hair_choice}, ${skin_choice} skin, and feral eyes." She lets the tension go out of the bowstring. 
	*if ishko_occupied
		"You were the one who helped us take Ishko. We owe you our gratitude for your actions."
	*if not(ishko_occupied)
		"We owe you our gratitude for your actions there."

	"My name is Hiwa, and this sorry sack of a man is called Grin, for obvious reasons."

	Grin smiles beatifically. 

	"We are keeping an eye on communities that may cause problems for the Rising Sun. We have had minor clashes with Mara's Caravan before, but our superiors are concerned that news of the unpleasantness in Ishko will spark further aggressiveness from the 'Van. The report we make will likely have a serious impact on future interactions with the Caravan."

	*choice
		#Encourage preemptively curbing the aggression from Mara's Caravan.
			*set action %+15
			*set deliberation %-15
			*set riser_affinity %+35
			*set combat +5
			*set delayed_van_attack true
			You point out that Ishko's resistance was not only to viewing the Rising Sun encampment nearby as an equal, but also that the Ishkoans questioned the right of the Rising Sun to exist at all. If Mara's 'Van is at all similar, they will never negotiate with those they consider infidels and heretics.

			As you walk through the rationale, you begin to gain a better sense of battle tactics on a larger scale. It will likely help you in future violent conflict.

			Hiwa listens intently to your reasoning. She is silent for a long while before replying. 

			"I was raised in a Highwalk community not so different from Mara's 'Van. Even casually questioning the beneficence of the gods…" Her face hardens. "I was thrown out of my 'Van. For a Highwalker to be removed from her caravan forcefully is a terrible, scarring shame.
			*if tribe = "Highwalk"
				But I do not need to tell you that; I can see we share some common ancestry."
			*if tribe != "Highwalk"
				It is difficult to explain to someone outside of our circles."

			Hiwa sighs and runs her fingers through her coarse hair. "I will take your counsel seriously. It will likely result in an attack on Mara's 'Van, but what other option do we have but to wait for them to come against us?"
			*goto scouting_party_choice			
		#Strongly discourage any potential attacks.
			*set deliberation %+15
			*set action %-15
			*set riser_affinity %-5
			*set hawk_affinity %+15
			*set quickthinking +5
			*set risers_warned_off true
			You point out that attacking the caravan could very well incite a larger conflict with its trading partners along the edge of the steppe. Furthermore, the caravan is not resource-rich, so any such conflict would result in minimal gains.

			The rationale for discouraging the attack comes to you at the last minute. Thinking on your toes is becoming easier. 

			Hiwa listens to you without reacting and then finally nods. 

			"It is sound reasoning, yes, but I can't help but feel you are directing me. Regardless, I will pass on your thoughts." 
			*goto scouting_party_choice
		#Outright forbid any attacks.
			*set equity %+15
			*set selfishness %-15
			*set riser_affinity %-20
			*set hawk_affinity %+10
			*set sensitivity +5
			*set risers_warned_off true
			You forbid the scouts from relaying any intelligence that might increase tensions between the Rising Sun and Mara's Caravan. 

			Your sudden feelings for the people of the Caravan, whom you do not even know, may be a sign that you are growing increasingly invested in the well-being of others.

			Hiwa seems taken aback by the intensity of your censure.

			"You have no rank among us. You would do well to remember that before you next speak to two armed soldiers."

			*goto scouting_party_choice
		#Ask the scouts to stop wasting your time; whatever they do is their business and their petty grudges are none of your concern. 
			*set selfishness %+15
			*set equity %-15
			*set survival +5
			*set delayed_van_attack true
			The business of the Rising Sun and their grudges is insignificant to your larger goals. You tell the scouts as much. You are more concerned with your own survival than that of others. Such pragmatism about your own protection may aid you in the future. 

			Hiwa bristles at your tone at first, but ultimately does not find fault with your reasoning. 

			"I appreciate your candor, and you are right: This is our decision and too much depends on it to allow an outsider to make it for us."
			*goto scouting_party_choice
		#Encourage cooperation between the Rising Sun and Mara's Caravan.
			*set deliberation %+15
			*set action %-15
			*set bear_affinity %+20
			*set influence +1
			*set risers_warned_off true
			You suggest that working with the Caravan might be the best option for the Rising Sun, especially on the steppe where life can be brutal and unforgiving. 

			Hiwa is clearly amused by your suggestion. You watch as it slowly occurs to her that you are serious. 

			"Work with them?" She looks up at the sky, then back at you. "If anyone else had said that, I would have laughed, but you may be mad enough to believe it possible. Trust me, ${prenom}. It would not work. Still, we thank you for your counsel. It has given us much to consider."
			*goto scouting_party_choice

	*label scouting_party_choice
	*if delayed_van_attack = true
		*set van_attacked false

	Hiwa spurs her horse to action. 

	"It's quite the ride to the next Rising Sun outpost. We should get going."

	Grin merely shows you his white teeth and tips his head in your direction. The two of them set off afterward, and you continue on toward the caravan.
	*page_break 

	*label caravan_description
	Mara's Caravan is one of the larger Highwalk settlements. Its namesake was the first primary surveyor, and the roving town took her name in gratitude. The caravan travels the steppe with the seasons, living off of the hard-won nourishment of the land and trading with other settlements at the edges of the enormous territory. 
	*if tribe="Highwalk"
		Many Highwalk people consider the nomadic life to be an anachronism that owes more to a romantic sense of the past than a feasible plan for the future.

	*if van_attacked = false
		You approach the nomadic community and find it abuzz with cook fires, hardy grazing animals, and quietly working people. Large hide tents are set up within the described perimeter of the caravan. 

		The first few people you encounter 
		*if tribe = "Highwalk"
			greet you warmly, welcome you home though you have never met them, and encourage you to see the primary surveyor. 
		*if tribe != "Highwalk"
			look you over and suggest that you should take your business to Rasul, before returning to the tasks in which they were engaged.
		*comment endif

		It takes some wandering through the large community before you find the man in question. Rasul, the primary surveyor, squats over a low, collapsible table staring intently at a map. The man has arms like the trunks of trees, and his greasy, gold-and-silver hair is bound in a knot behind his head. You recognize him from the 
		*if tribe = "Highwalk" 
			careful
		*if tribe != "Highwalk" 
			hasty
		descriptions of the caravan members you encountered earlier, but you would have noticed him even without their directions. He has the bearing of leadership about him.

		He straightens when he sees you. 

		"It is early yet in the season for trading, so I doubt you are here for our goods. If I am honest, you look a dangerous sort. So tell me, stranger, who are you and what brings you to our caravan?" 

		*label rasul_choice
		*choice
			#Give my name and explain why I am here.
				You introduce yourself and give Rasul a summary of your travels thus far and explain your intentions in Mara's 'Van: You need the seer's guidance on a critical matter involving the gods themselves. 

				Rasul scratches his beard and stares at you for a long moment. 

				"I respect your candor, ${prenom}," he says, "but the seer's wisdom is not for sale. Wiser men and women than I decided that well before I was the primary surveyor. Even if the seer was not my child, I could not help you. 
				*if tribe = "Highwalk"
					You are one of us, maybe not from this 'Van, but one of us still. It does not please me to turn you away."
				*if tribe != "Highwalk"
					There is nothing I can do for you."
				*comment endif

				*label rasul_denies_entry
				Despite Rasul's judgment, there must be something you can do to persuade or to circumvent him. The promise of the seer's aid has brought you too far to give up now. 

				What will you do?
				*choice
					#Reach out to one of the deities that watch over Mara's 'Van and beseech their aid.  
						If Rasul refuses to grant you access to the seer, you intend to quite literally go over his head. Two gods claim domain over the steppe: Hawk and Gazelle. The former circles the skies above, watching patiently. The latter runs endlessly across it with her eyes fixed on the horizon. Gazelle is reclusive and not known to answer summonses. That leaves Hawk. 

						You relax your mind and scan the sky with reverence. You settle into a trance before long, and the shadow of an enormous bird of prey passes over you.

						*if ((((ritual >= 10) and (tribe = "Highwalk")) or ((ritual >= 10) and (hawk_affinity > 50))) or (ritual >= 20))
							*set sensitivity +5
							The Hawk replies in an amused whisper that sounds like an echo coming across an impossible distance. 

							"You must be needy to reach out for my aid, Wolfling. I hope that what you seek is worth your time."

							When you return to yourself, your right fist is closed and when you open it there is a rainbow-hued feather. Light dances across its surface. Even holding it makes you feel as though you have deeper connection with the land around you. 

							Rasul sees it and his eyes grow wide. 

							"Beloved of the wing'd-lady," he says. "I am sorry that…I mean to say, I did not know you were favored by Hawk herself. I will bring you to the seer immediately."

							True to his word, Rasul takes you to a large tent protected by a single guard. The guard steps aside once he sees Rasul and holds the flap of the tent open. The primary surveyor gestures toward the open portal and you step through.
							*goto seer
						*else
							But Hawk's voice eludes you. She speaks in dismissive whispers and you leave the trance unfulfilled and without her aid. 

							Rasul has long since returned to more pressing matters.

							*goto horse_sleeper
					#Challenge Rasul to physical combat.
						"If I defeat you in single combat, will you allow me access to the seer?" you ask. 

						Rasul laughs. 

						"Single combat? It is has been a very long time since I found my equal in combat. I have trained since childhood to be the primary surveyor and I have survived many trials." He flicks his earlobe and sets swinging the feathered earring hanging from it. "It is not through skill alone I hold this post. You do not want to fight me."

						You repeat your question. He stares at you. 

						"Fine," he says. He strips off his vest and exposes his barrel-chest and the extent of his lean, hard musculature. "No weapons, but if you win, you may see Ghazal. If you lose. Well, it would be cruel to put conditions on the inevitable."

						He comes at you before his sentence ends. 
						*if ((combat >= 20) or (survival >= 20))
							*set hawk_affinity %+15
							Rasul is fast and strong. You almost have trouble keeping up with him. His shoulders are hunched, and he never leaves himself open. The two of you circle each other, feinting, teasing, while searching for openings. 

							You pivot on your left leg and he comes in furiously. He might be thinking he will be too fast for you to recover before he comes down on you, but you are faster than he thinks, and smarter. The footwork is just another feint. He comes in to deliver a crushing punch and you slide out of the way at the last moment, delivering an upward knee into his lower chest. 

							The blow takes him by surprise and you take advantage of that by following it up with a series of lightning-quick punches that put Rasul on his back. As he lies in the dirt, you hear a sharp birdcall from a hawk wheeling above. It feels like congratulation.

							You stand over Rasul, and he chuckles.

							"You have done the impossible. You have made me feel old," he says.

							You help him up and he tells you where to find the seer's tent.

							*goto hater_guard
						*else
							If you expected Rasul to move like an older man, you are greatly disappointed. He is almost faster than he is strong, and he is very strong. You block his first kick, but he hammers you over and over with the same leg, maintaining exquisite balance while weakening your left side. 

							You push back and gain a little distance only to find him coming back again with a right cross punch that takes advantage of his long arm span.

							You are panting in the dust before long. Rasul barely sweats. He stands over you with a look of pity before he helps you up. 

							"I have work to do," he says, and leaves you standing there, defeated and dismissed.
							*goto horse_sleeper 
					#Work around him. There must be a way to find and consult the seer without his knowledge.
						You tell Rasul you understand his decision and that you will respect it. He thanks you, but something in his look tells you he does not entirely believe you. He graciously offers you shelter for the night, and you accept. 

						You spend the next hour or so scouting the caravan, and eventually you find the one tent that has a guard posted outside. What, you wonder, would the caravan desire to protect more than anything else? 

						*if quickthinking >= 15 
							To avoid being caught, you wait until the dead of night and then find your way back to the guarded tent. There is a new guard there who circles the tent every few minutes. You watch him until you are sure of his movements, and then you act. 

							Gaining entrance into the tent is the work of less than a minute.

							*label seer
							Once you are inside, you find the seer watching you, not alarmed as you might expect, but bemused. 

							"Welcome, stranger," ${ghazal_he} says. "I am Ghazal. You have come quite a long way to see me. I am honored. Truly."

							You start to explain, but Ghazal stops you. $!{ghazal_he} stands from the pillows on which ${ghazal_he} was seated and approaches you. $!{ghazal_he} is slender and soft, dressed in bright, clashing colors. $!{ghazal_his} eyes are bright and expressive.
							*if ((action > deliberation) and (selfishness >= equity))
								The smell of ${ghazal_him} makes you salivate slightly. Your wolf's senses tell you that this creature, dressed in Gazelle's musk, is prey.
							*comment endif

							"Do you think I would be any kind of seer if I did not know why you came?"

							"I suppose not," you reply. 

							Ghazal smirks at you. "I had a dream that a dog wandered into my tent. It had kind eyes. But you are not a dog, are you? Tame and pleasant?"

							*choice
								#"If you want me to be."
									*goto yes_dog
								#"Do I look like a dog?"
									*label yes_dog
									Ghazal steps in, almost close enough to touch you. $!{ghazal_he} reaches out and traces the curves of your face with the tips of ${ghazal_his} fingers without ever laying them on your skin. 

									"I can see a bit of that dog in your countenance. But that does not mean that you will not bite, now does it? I think we may be the same in that respect."
									*goto ghazal_backstory
								#"Depends on who is asking."
									*goto no_dog
								#"No. I am certainly not a dog."
									*label no_dog
									"No. I can see you are not a tame animal. You are something else entirely. I can respect that. I myself seem to be tame and pleasant, but I am not always tame, nor pleasant."
									*goto ghazal_backstory

							*label ghazal_backstory

							Ghazal brushes ${ghazal_his} hair behind ${ghazal_his} shoulder and puts a hand to ${ghazal_his} chin. "I became the seer of Mara's Caravan at eight summers-old. The previous seer, my mother, walked into the steppe and never returned. They say she ascended, that she climbed into the sky to become one with Mother Gazelle. But it is just as likely she was torn apart by the foxes and wolves that hunt the steppe.

							"And that is how it is for those touched by the gods. At the knife's edge of madness. But the reward? Such dreams I have seen, of worlds beyond ours, and the wonders of tides lapping from spectral shores." Ghazal shrugs, and winks at you. "And occasionally someone attractive wanders into my tent."

							Will you continue the conversation with Ghazal, or steer ${ghazal_him} toward your purpose?

							*fake_choice
								#Ask how Ghazal became Mara's Caravan's seer.
									*set deliberation %+5
									*set action %-5
									"Life out here can be difficult. There are many dangers. The primary surveyor works hard to ensure that we are safe, but there are dangers even they cannot anticipate. Our caravan has survived while others have not, because we have a seer. After my mother vanished, I began to have nightmares. Terrible dreams of fire in the sky and gods screaming from a void. Then the predictions…"

									Ghazal shakes ${ghazal_his} head. "After that it was obvious. I began training immediately."

									"But that is in the past," Ghazal explains. "And the future is something else entirely."
								#Flirt with ${ghazal_him}.
									*set eel_affinity %+5
									You tell Ghazal you do not always find someone so attractive in every tent that you wander into. $!{ghazal_he} laughs at that. You notice ${ghazal_his} smile is a mite crooked, but it is an endearing imperfection. 

									"I did not expect the great and terrible Wolf's protégé would have a sense of humor."

									"I did not expect Gazelle's emissary would be capable of much besides drinking tea and making vague comments," you reply. 

									That sets Ghazal off once more. $!{ghazal_his} eyes grow wide and ${ghazal_he} shakes ${ghazal_his} head in mirth. 

									Ghazal gives you a warm look, appraising your ${skin_choice} skin and ${hair_choice}. "It is good to have a moment to not think about hard things. Thank you for the distraction."
								#Refocus the conversation to the prophecy you came for.
									*set action %+5
									*set deliberation %-5
									"Of course, Wolf-bearer. I did not mean to distract you."
								#Ask about life on the steppe.
									*set deliberation %+5
									*set action %-5
									"It can be hard, but also rhythmic. There are a handful of permanent settlements scattered along the steppe, but for the most part, the caravans are our way of life.
									*if tribe = "Highwalk"
										I am sure I do not have to tell you, being Highwalk yourself, but there is always uncertainty. 
									*if tribe != "Highwalk"
										There is always uncertainty. 
									We prioritize trade and mobility over some of the comforts other clans enjoy. Sometimes I dream of other ways to live, but history and tradition mean something to us. Our way of life is our way of life." 

									Ghazal spreads ${ghazal_his} hands wide. "It is what we know, so it is what we do. And that is all."

							Ghazal gestures to the ground where a small pile of wood has been prepared for a fire. 

							"All right. If there is nothing else, then let us see what the wind whispers for you, shall we?"
							*page_break

							$!{ghazal_he} builds the fire and throws scraps of paper, cracked animal bones, and handfuls of dust into it. $!{ghazal_his} ritual builds upon these castoffs and grows stronger and brighter as ${ghazal_he} adds to it.
							*if ((sensitivity >= 15) or (ritual >= 15))
								You can tell the exact moment Gazelle's spirit comes into the room. Ghazal's back goes straighter and ${ghazal_his} brown eyes turn as reflective as glass.
							*comment endif

							Ghazal cocks ${ghazal_his} head.

							"Compatriot of brother Wolf," Ghazal says, but in a voice that is gnarled with age and boundlessly compassionate. "Welcome."

							"Sister Gazelle." You instantly recognize the shift as a sort of possession. Ghazal is elsewhere and ${ghazal_his} patron god has, for the moment, taken ${ghazal_his} place.

							"I must not stay long, but it is good to see you well. Wolf's leaving has made your existence more difficult, I assume," Gazelle says.

							The goddess closes Ghazal's eyes for a span of ten breaths or more and then opens them again with some difficulty. 

							"Transit grows harder by the day. We once took for granted how easy it was to inhabit your kind. You were so in awe of us. Just a touch and we could dress in your skin, dominate you. The power is intoxicating. Now things are different. Change comes for us all."

							Ghazal, or perhaps the goddess inside ${ghazal_him} looks at you with shiny, distant eyes.

							*set prophecy_received true
							"I will disappoint you, ${prenom}. The prophecy you seek is not the one that I am of a mind to give. Wherever he has gone, the truth remains that Wolf was cunning and beautiful, but he was terrible. I too can be terrible. Go south, ${prenom}. At the border of the lands belonging to the Quiet there is turmoil that greatly concerns me: The Rising Sun continues to show its might. You may find something of use to you there. Do as I ask and I will help you. Otherwise, well…" 
							
							Ghazal blinks a few times and returns to ${ghazal_him}self. 

							"I wish I could do more for you," Ghazal says. "But Gazelle has said all she will say. Though…"

							Ghazal reaches into ${ghazal_his} voluminous robes and pulls out a long needle.

							"Give me your hand," Ghazal commands. 

							*set ritual +5
							$!{ghazal_he} snatches it before you can properly decide. Ghazal pricks a finger with the needle and when the blood wells up, ${ghazal_he} spits into the tiny wound and rubs it in. In a moment, you feel strangely invigorated, as if the world has become slightly brighter.

							"A gift from Gazelle in the hope you will assist her in whatever she wishes. It will help you to complete rituals, if you wish to walk that path. Either way, the faithful need your help. The Rising Sun's continual interference in our way of life has become untenable. Something needs to be done, no?"

							*choice
								#"The Rising Sun is just another group trying to survive."
									*set equity %+5
									*set selfishness %-5

									"I think most of us would prefer them to define the terms of their survival without bloodshed and wanton destruction, but I understand your point, ${prenom}."
									*goto pre_romance
								#"They are bloodthirsty children more than worthy of our scorn."
									*set action %+5
									*set deliberation %-5
									*goto pre_romance
								#"They are heralds of a new age in history. One outside of the tyranny of our gods. They will upend everything, and that is what we need."
									*set chaos_score +1
									*goto pre_romance
								#"The Rising Sun is beneath my interest. Far beneath it."
									*set selfishness %+5
									*set equity %-5
									*goto pre_romance
								#"They have not yet shown who they truly are underneath their provocative methods."
									*set deliberation %+5
									*set action %-5
									*goto pre_romance

							*label pre_romance

							"You should sleep now. If you intend to follow Gazelle's instructions, you will need the rest. It will be days before you see the Quiet border, even if we lend you a horse. Though there is no mandate that you have to sleep alone."

							The suggestion is clandestine, but not made with embarrassment. Ghazal looks at you with frank appraisal.

							Will you accept the offer to spend the rest of the night together?
							*choice
								#Accept Ghazal's offer of a night of indulgence. 
									*set eel_affinity %+30
									*set ghazal_romance true
									On the pillows and blankets of Ghazal's tent ${ghazal_he} shows you that ${ghazal_he} is not all softness and brightly colored things. There is an edge to ${ghazal_his} voracious play and a self-confidence that at first surprises, then delights you. 

									Better still, once it is over, the two of you come to a silent agreement to start it up again. 
									*goto post_romance
								#Refuse Ghazal's offer. $!{ghazal_he} can keep ${ghazal_his} mystery and romance.
									Ghazal accepts your refusal with aplomb. 

									"Ah. I see," ${ghazal_he} says. "I wish you well then, Wolf-bearer. Travel safely, if you can."

									"What do you mean?" you ask.

									$!{ghazal_he} smiles, but does not elaborate. The benefit of seeing the future you suppose. 
									*goto no_romance
								#Perhaps some other time, but now is not the right time for intimate interludes. 
									"I respect your politeness, ${prenom}, but a refusal will not shatter my fragile ego. Still, if you find yourself near the caravan in the future, stop in. I'm sure we will find much to discuss or to do," Ghazal says.

									You give ${ghazal_him} a respectful bow. 
									*goto no_romance

							*label post_romance 
							*set wake_at 1
							Ghazal stretches out beside you in the profusion of pillows and blankets. $!{ghazal_his} expression is guarded, but bemused. 

							*if van_v_risers = false
								"You are not what I expected, ${prenom}."

								$!{ghazal_he} never tells you exactly what ${ghazal_he} expected. Instead ${ghazal_he} asks, "${prenom}, do you think you will return here after you find whatever you are seeking? Will we see each other again?"

								*choice
									#"I will, if you are still here."
										*set van_return true
										"I did not take you for a romantic, ${prenom}," Ghazal says with a smile. "Perhaps there are depths to you yet to be revealed."

										*goto post_romance_choice
									#"There is nothing here for me."
										Ghazal nods, but does not comment. 
										*goto post_romance_choice
									#"You are the seer. You tell me."
										*set van_return true
										Ghazal grins. "You will return here, but we will be different people then. We will see whether anything is possible between us."
										*goto post_romance_choice

								*label post_romance_choice
								$!{ghazal_he} falls asleep with one arm thrown across your chest. Eventually, you drift off as well.

								*goto spider_dream
							*else
								"You are a better lover than you are an ally," ${ghazal_he} says. 

								"What do you mean?" 

								"It is different for everyone I assume, but I see the future as a vast, incomprehensible image painted with colored oil. Each streak, each burst of brilliance is someone's influence on that mad mosaic. I see your colors. I know how this ends for us."

								"I do not understand," you reply.

								"Oh? Well, then tell your friends in the Rising Sun that we will be prepared for them when they come. As for us, you and I, this is the end of it."

								You suppose there is no arguing with someone who sees the future and can clearly see how you have manipulated both the Rising Sun and Mara's 'Van. You would expect Ghazal to be more upset about it, but ${ghazal_he} falls asleep beside you in just a few moments. It doesn't take long for you to follow suit. 
								*goto spider_dream

							*label no_romance

							You leave Ghazal's tent and search for somewhere else to sleep. 

							*if caravan_helped > 0
								*set wake_at 3
								By chance you encounter 
								*if caravan_helped = 1
									the scarred man you helped out the fires around the caravan. 
								*if caravan_helped = 2
									the healer you helped with the wounded. 
								He is enthusiastic about helping to return the favor. He offers you a sleeping pallet.
								*goto spider_dream
							*else
								*goto horse_sleeper_less_text
						*else
							You wait until it is late enough that the casual passersby are no longer a concern before you try to sneak into the seer's tent. You wait until the guard starts to pace around the tent and it is clear. As you sneak toward the entry flap, you see Rasul approaching with a dozen or two armed men at his back.

							"Now, why did I think you would try to do something as underhanded as sneaking around our caravan at night?" he asks. "Do yourself a favor and go back to your lodgings and go to sleep. We will all forget this happened, and you will leave in the morning."

							*if ((combat >= 20) or (action >= 55))
								The odds are not in your favor, but when you clench your fists and step forward, you can see a few of the guards flinch. 

								"Let ${him} in."

								The voice comes from inside the tent, and everyone stops, including Rasul. 

								"That is not a good idea, Ghazal. We can't trust ${him}."

								"Let ${him} in, father. I have already seen how this ends. It does not go well for you and yours."

								It clearly galls Rasul to follow the command, but he relents and steps aside so you can enter the seer's tent. 

								*goto seer
							*else
								You know it is unlikely that you can fight off more than a dozen people, so you accept the threat masquerading as advice. 

								*label horse_sleeper
								With no other immediate options for seeking out the seer, you look for lodgings. In the morning you can continue your search. 

								*label horse_sleeper_less_text
								*set wake_at 2
								You find a passable sleeping area among the horses, and the Highwalk girl who tends them takes pity on you and gives you two blankets. It feels at first as if you will pass the chilly night stubbornly refusing sleep, but sooner or later it comes for you.

								*goto spider_dream 
			#Demand an audience with the seer.
				*if ((influence >= 3) or ((influence >= 2) and (sensitivity >= 20)))
					Rasul narrows his eyes at you and briefly looks like he intends to exchange more than just words with you, but ultimately he backs down. 

					"Your reputation precedes you, ${prenom}," he says. 

					You raise an eyebrow and Rasul sniffs at you.

					"You could not have imagined that you could traipse into the most well-connected caravan in this part of the world and expect to remain anonymous. I don't want to start any trouble that I can avoid, so I will not stand in the way of you speaking to Ghazal, if ${ghazal_he} wishes it. But if you offer ${ghazal_him} insult, I will personally rend your limbs from your body."

					The primary surveyor turns away from you, effectively concluding the conversation. 

					*page_break

					You spend some time wandering the caravan before you find someone willing to direct you to the seer's tent.
					*label hater_guard
					The guard outside the tent responsible for safeguarding the seer is skeptical of your authority, but ultimately allows you past. 

					*goto seer
				*else
					Rasul listens patiently to your demand and responds curtly. 

					"No."

					You repeat your demand: You have every intention of speaking with the seer. 

					"No," he repeats. "The seer is our most treasured resource after water. Any one of us would die for ${ghazal_him}. Your demands mean nothing to me."

					You are stunned by the primary surveyor's flat refusal.
					*goto rasul_denies_entry
			*if (delayed_van_attack = true) #Warn Rasul about the imminent Riser attack.
				*set van_v_risers true
				*label riser_troubles
				You explain that you encountered a Rising Sun scouting party not very far from the site of the caravan. 
				*if delayed_van_attack
					You tell Rasul it seemed they were assessing the vulnerabilities of the caravan. You obviously neglect to mention that you did not necessarily discourage the attack.
				*if risers_warned_off 
					You inform Rasul you convinced the scouting party that attacking the 'van was a bad idea. You also mention that it would be prudent to shore up defenses around the caravan anyway.
				*comment endif

				Rasul considers this and calls out to a lanky youth nearby. The boy approaches and Rasul gives him detailed instructions to gather several influential members of the community with all haste. He turns back to you once the youth runs off. 

				"Thank you for your assistance. We will be on guard. The Rising Sun have feinted toward attacking us before, but if they are serious this time, then you might have just saved many lives. Is there something I can do to thank you? A place to sleep, provisions perhaps?"

				"I need to see the seer," you explain. 

				He sucks air between his teeth.

				"Technically, I cannot grant you access to the seer without a vote from the 'Van Collective. However, given the situation and your aid, I can look the other way. I'm sorry I do not have more time to guide you to Ghazal myself, but I have to make preparations. Please excuse me."

				*goto finding_seer
			*if (risers_warned_off = true) #Explain how you stopped the Rising Sun from attacking.
				*goto riser_troubles
			*if ((van_attacked = true) and (caravan_helped >= 1)) #Explain that you worked among the laborers; request access to the seer as a fair trade.
				You explain you came to the caravan's assistance although it took time away from your search for the seer. When he hears that you have assisted the caravan, Rasul's demeanor changes. 

				"Ah, I had heard word of a stranger helping out
				*if caravan_helped = 1
					with the fires.
				*if caravan_helped = 2
					with the wounded.
				Thank you for your assistance. Though you have done us a great service, I cannot give you permission to visit our seer. That honor belongs to the caravan as a collective, and the matter would have to be put to a vote. However, if you were to find Ghazal's guarded tent on your own and somehow convince the guard that you had my blessing to speak to ${ghazal_him}, I would not be inclined to stop you."

				Rasul winks at you conspiratorially. 

				"Thank you again. Truly. Perilous times show us who our true allies are, but rarely are we pleasantly surprised."

				Rasul returns to the business of running the caravan, and you seek out Ghazal's tent. It is not difficult to find: It is the only tent with a guard posted outside it. You explain to the androgynous guard that Rasul has authorized your presence and you are begrudgingly allowed entrance. 

				*goto seer
			#Misdirect Rasul about my intentions.
				*if (((quickthinking >= 20) or ((quickthinking >= 15) and (selfishness >= 60))) or ((quickthinking >= 15) and (influence >= 3)))
					You present yourself as a humble shaman of Wolf concerned about the flux in the hitherto dependable rhythms of the moon's transit. You mention, in no uncertain terms, that disturbances among the celestial bodies means disturbances among the gods. 

					You are not lying, exactly. Wolf's absence has had some effect on the celestial bodies, but finding the exact nature of that effect would take days and months of study that you can ill afford. Instead, you cite ancient law and cryptic research. Rasul's eyes glaze over as you ramble. 

					"Enough, mystic. I do not have the time for whatever madness you are spewing. Speak to Ghazal. $!{ghazal_he} has a stronger constitution for this sort of thing, and I must return to the business of the caravan."

					*label finding_seer 
					Rasul tells you where you can find the seer, and you go looking for ${ghazal_him}. You find the tent Rasul described, but the scowling guard seems to have no intention of letting you past. 

					It is not until a voice from within speaks, saying, "let ${him} in," that the guard finally relents. 

					*goto seer
				*else 
					You intend to spin a tale about coming to pay homage to the shaman, and Rasul stops you almost before you begin. 

					"The seer does not accept gifts. Nor does the seer need your homage. Is that all? I have pressing business to return to."

					*goto rasul_denies_entry
	*else
		But the caravan you arrive at is in dire shape. There are children screaming and blood splashed intermittently on the grass. Many of the colorful tents have been collapsed, and there are dozens of wounded upon which a handful of harried-looking healers are performing basic triage. As you enter the caravan grounds, you stop someone and ask what has happened. She quickly explains that a group of armed soldiers wearing a sunburst standard came through and attacked. 

		You are making your way through the caravan, assessing the situation. It is possible the seer you have been seeking is no longer in the caravan: Communities with valuable resources tend to see to their protection first. 
		*if tribe = "Highwalk"
			If you were the primary surveyor of this caravan, responsible for its safety and plotting its course through the seasons, you would have gotten your seer far from the danger. 
		*if tribe != "Highwalk"
			Though it is possible the seer was the focus of the attack to begin with.
		*comment endif

		As you make your way around, a man with scars crisscrossing both arms calls out to you. 

		"You there! Do you not see the state of things? Help us."

		There are sites of burning all around where cook-fires were upturned in the attack. This man is coordinating efforts to scoop buckets of water out of huge drums that the caravan uses as its supplementary water supply. 

		Nearby you see one of the healers laying a poultice on an elderly person. However, two to three more wounded lie moaning beside him.

		Will you help the caravanners? 
		*choice
			#Yes. I will help put out the fires.
				*set combat +5
				*set caravan_helped 1
				For the next few hours, you haul heavy buckets of water and help put out fires all over the caravan. The work is exhausting, but you consistently push past your desire to stop. You have to watch your step and control your movements carefully in order to save your strength. The work stretches your muscles to a place of extreme tension, but afterward, when the fires are all outed, you feel stronger and slightly more balanced on your feet. 

				*goto caravan_thanks
			#Yes. I will help the healer.
				*set survival +5
				*set caravan_helped 2

				The healer seems beyond relieved when you come to his side and offer to help. He instructs you in how to treat minor cuts and bruises and walks you through administering a mild sedative made out of a pulped long grass found at the farthest northern edge of the steppe. 

				Over the course of several hours, you learn a lot about treating wounds. Your ability to survive in a variety of situations has been positively impacted. 

				Eventually, the sun sets and nearly all of the most urgent wounds have been seen to. The healer claps you on the shoulder and gives you a tired smile. 

				*label caravan_thanks 
				"Thank you, friend. Without your help, I would have been overwhelmed hours ago. You have done the caravan a great service."

				You accept his praise and stretch your cramped fingers. You excuse yourself and head off to continue searching for the seer. 
				*goto van_attack_cont
			#No. Finding the seer is more important. The existence of a god is at stake. 
				*set restraint %+10
				The impulse to aid these people is there, but you cannot justify interceding when you are so close to your goal. If the seer can truly help you find out what has happened to Wolf, then you are on the cusp of influencing divine events. You need no further encouragement to continue on. 

				*label van_attack_cont

				Your search through the caravan eventually leads you to the primary surveyor, the de facto head of the caravan, Rasul. He's a large man with gold-and-silver hair tied into a knot atop his head. He has arms twice the size of yours and a waist like a pillar. He is talking to three others. You overhear a bit of their conversation: 

				"We should send riders after them immediately." "No. We should see to our wounded first." "…dare think they can get away with this offense."

				Rasul remains silent throughout, but eventually takes the side of prudence.

				"If we find the contingent that attacked us, then what? A third of our fighting force is wounded and a number of them dead. Those that remain are worried about leaving their families in case of another attack. I agree with them. We stay until we have recovered. We can discuss retribution, if that is truly what the caravan wants, once we are on our feet," he says.

				Rasul dismisses the people surrounding him, and you wait until they are gone to approach. The primary surveyor is massaging his brow when you walk up. He looks you up and down. 

				"I will be honest, stranger: I have had a long day."

				He offers a tired smile, a joke then.  

				"I am Rasul. The first primary surveyor in two generations to see the 'Van attacked. As you might imagine, I am very busy. What do you need, stranger?"
				*goto rasul_choice
*else
	*goto caravan_description

*label spider_dream
*page_break

You awake in the dark. Your senses tell you this is no ordinary dream, and perhaps it is not a dream at all. There is real danger here. Your breath curls in front of you, and your hands are bitterly numb from cold. You can feel something lingering above you, a monstrous shape. You flee instinctively. 

Trees whip by as you run, but you can feel the thing close behind. You know that it means to capture you. How will you save yourself? 

*fake_choice 
	#Use survival skills to hide in the dark.
		You evade it long enough to find a place to hide. Beneath a fallen tree you find a wet, cold burrow you can just fit inside. You roll in and try to still your breath.

		When enough time passes that you might be safe, you start to inch out of the burrow. Something grabs your arm and snatches you out of the burrow and into the air. 
	#Stand and fight.
		You spin around and confront the thing stalking you, hoping to take it by surprise. But there is nothing there. The huge shape you felt looming over you is nothing at all.

		You start to wonder what you were imagining when something loops around your waist. You look down, but before you can even register what you are seeing, you are pulled hard into the air. 
	#Find the best paths through the dark using my senses.
		Your senses are keen, and you know you can outrun whatever is chasing you. The pathways before you are knotted, but you navigate them quickly, gaining precious seconds with every hazard you avoid. 

		You feel you have nearly gotten clear when you run into something delicate but strangely firm. You try to extricate yourself from it, and then in the next instant, you are yanked off of your feet and hauled into the air. 
*comment endif

The legs work quickly to spin you into a cocoon of silk as the massive shape of the spider becomes clear. The creature's profusion of eyes consider you. 

"It seems wolves are not so deft in the air. Who knew?" The voice comes not from the spider directly, but from around it. The words warble with a tangible weight. 

*if (action > deliberation) and (selfishness >= equity)
	*goto after_capture 
*else
	"Then again, you are more
	*if (deliberation >= action) and (selfishness > equity)
		spider than wolf, aren't you?"
		*goto after_capture
	*if (action >= deliberation) and (equity > selfishness)
		bird than wolf, aren't you?"
		*goto after_capture
	*if (deliberation > action) and (equity >= selfishness)
		bear than wolf, aren't you?"
		*goto after_capture

*label after_capture

The enormous spider tightens your silken cell until your body aches.

"Now let us see, ${prenom}.
*if (death_toll >= 5)
	*set spider_observation +1
	You have shed blood. A lot of blood. 
	*goto spider_next_1
*label spider_next_1
*if (riser_affinity > 50)
	*set spider_observation +1
	You have made unlikely, and quite frankly, untrustworthy allies.
	*goto spider_next_2
*label spider_next_2
*if (riser_ishko_cooperation = true)
	*set spider_observation +1
	You have created bridges between enemies, which I would have preferred to burn.
	*goto spider_next_3
*label spider_next_3
*if (chaos_score >= 1)
	*set spider_observation +1
	You have begun to question how central godhood really is to humanity's prosperity.
	*goto spider_next_4
*label spider_next_4 
*if (pacifism = true)
	*set spider_observation +1
	You have sworn never to shed blood, which is madness, of course. 
	*goto spider_next_5
*label spider_next_5 
*if (ishko_occupied = true)
	*set spider_observation +1
	You have proven strong enough to take Ishko from its people, which I truly appreciated, by the way.
	*goto spider_next_6
*label spider_next_6
*if spider_observation >= 2 
	So you have been quite busy, my lupine friend."
*if spider_observation = 1
	And I am sure you will further impress me."
*if spider_observation = 0 
	Let us peer deeply into your soul and see what treats we will find."

The spider shifts, which sends vibrations through the massive web. 
	
*if (((selfishness >= 75) or (influence >= 3)) or (quickthinking >= 20))
	*set spider_gift_1 true
	*set sensitivity +5
	"I have watched many mortals navigate the perils of their short, simple lives, but you are something special. You are truly yourself under Wolf's musk and bluster. I reward individuality, and I think you are deserving of a reward.

	"Your senses are keen, but let's make them keener," the spider says.

	You feel the darkness recede a little. You can feel in greater detail the silk pressing tight against your skin. You can see the fine hairs across the great spider's skin. Even with heightened senses however, you are still incapable of wriggling free. 
	*goto spider_next_7
*else
	"I must say, I find it odd that you are not…more. You could have so much for yourself if you would but take it. Command it. Outthink anyone who covets what you have. But you lack the skills. Unfortunate, but there is still time for you to show us what you really are."
	*goto spider_next_7

*label spider_next_7
*if ((van_v_risers = true) and (spider_gift_1 = true))
	*set ritual +5
	"And I have one more gift for you. 
	*label spider_gifts
	I watched you play the people of the traveling caravan against the gods-hating militants. You pulled their strings with as much cunning as any of my disciples and for that, you deserve this: I hope you use it selfishly and often."

	You can feel wheels turning in your mind. You feel more able to stand up to the spider's intrusion into your mind. The force of your ritual knowledge has become sharper.  
	*goto after_spider_comment 
*elseif (van_v_risers = true)
	"
	*goto spider_gifts
*else 
	*goto after_spider_comment 
	
*label after_spider_comment
*page_break

The spider makes a noise like laughter, but horrible. 

*if prophecy_received = false
	"I almost forgot. Your prophecy. You went searching for it and came away with empty hands. I myself have no appetite for prestidigitation or hoary oracular stunts, but I can tell you that there are interesting developments brewing in the south. Near the border of the veritable sludge pits that the Quiet call their home. Go there, and I doubt you will be disappointed.

"We have had some fun, have we not? But it is time for you to wake, ${prenom}."

The spider edges closer, until you can see its glistening fangs. You wake with that image fresh in mind.

The specifics are hazy, but what feeling are you left with?
*choice
	#Fear. Spider was able to easily subdue me in the dream. 
		*set ara_affinity %-5 
		It's true the gods have their methods of contact and control, but being pursued through your dreams like a frightened rabbit leaves you shaken and resentful. You imagine there are easier ways to send a message, but perhaps Spider meant to rattle you.  
		*goto last_part
	#Exhilaration. Spider is a powerful god and a potential ally.
		*set ara_affinity %+20
		Though the dream itself was unsettling, you imagine that Spider visited you because she saw something useful in you. A goddess as powerful and cunning as she is could make for a strong ally. 
		*goto last_part
	#Anger. How dare Spider insert herself into my dreams.
		*set ara_affinity %-10
		You vow that next time you won't make it so easy. If Spider intends to invade your dreams again, she will find you harder quarry to catch next time.  
		*goto last_part

*label last_part

Eventually, you manage to put the bizarre dream behind you and go back to sleep, but your rest is fitful and short. Instead of the prophecy you came so far to find, you are given another thread to follow back to its source and are beset with strange dreams. You delay returning to sleep but when you do, you dream of Wolf's cries and spiderwebs. 

*finish
