*text_image chap_3.png center Three: Roads

[i]"The Hawk who wheels above[/i]

[i]in skies whose ends are stitched[/i]

[i]with feathers and blue silk[/i]

[i]has eyes in the dust, in the heart, in the mist."[/i]
*line_break
-a translation of a famous Highwalk poem. 
*page_break

It takes nearly two days before you spy the lowest part of the trail leading into the ravine. The rocky, uneven walkway is almost manageable compared to the steep, jagged paths you could expect if you had tried to cross on either side. Whatever stream cut through these rocks has long dried up, which makes the going that much easier.

When you descend further, you see a figure reclining on a rock. They are resting or waiting for something. Your eyesight is sharp enough to reveal a few facts: The person has long hair, tied back and away from their face, leather armor that has seen better days, and a sword with a feathered-hilt. 
*if sensitivity >= 10 
	The long, white-gold feathers twined into the hilt of the sword strongly remind you of a hawk's tail. 
*comment endif 

You might speak to them and see what news they might share. It is common for travelers to keep each other abreast of the goings-on of surrounding areas. Of course, you are also free to walk by without a word. 

*choice
	#Ask what news the stranger brings. 
		You hail the stranger, and ask, "What news?"

		The traveler responds, in a deep, mellifluous voice. Her face is as weather-beaten as her armaments.

		"News? The sun spins in the sky, man kills, and we crawl toward oblivion. I have also heard tell of unrest in Ishko. Oh, and there is rumor of the men bearing the sun standard gathering at some sort of compound in the south."

		She shrugs. 

		"All hearsay," she says. "And you? Any tidbits to share?"

		You tell her as much as you can without placing yourself too close to any events. She nods as you finish and then points toward the ravine. 

		*goto stranger_chat
	#Casually chat with the stranger. 
		You decide to stop and pass words with the stranger, who you can tell from up close, is a woman. She is handsome though her weather-worn face is as lined and deeply colored as the dark leathers she wears. She sits with a hand on the pommel of her sword, but makes no move to draw it as you come closer. 

		"Hail, stranger," she says. 

		You reply with the same. 

		*label stranger_chat 
		"The way ahead is through broken land. Forsaken by all gods." She spits to make her point. "I have been sitting here wondering if my business is urgent enough to make me attempt the crossing."

		"Go around then?" you offer. 

		She shakes her head. 

		"This ravine is the most direct crossing. Climbing the rise might take weeks. Too much time."

		"It sounds like the only way is through," you tell her. 

		"I have come to the same point myself." She raps a finger on her sword's pommel thoughtfully, then says, "greater numbers might help matters. You would not be trudging through this rocky mess if you did not intend to cross. We need not be companions, but crossing together is our safest option."

		*label accompany_choice
		It seems that the traveler intends to cross alongside you whether you require her presence or not. How do you respond to that decision?
		*choice
			#"I do not know you. I have no obligation to assist you."
				*set action %+5
				*set deliberation %-5

				"That is true. You do not know me," the stranger says. "But I am still not inclined to leave you to your whatever dark things prowl this place."
				*goto without_hawk
			#"Why not? As you say, I was crossing anyway."
				*set equity %+5
				*set selfishness %-5

				"That is very kind of you. Thank you," the stranger says.
				*goto with_hawk
			#"I cannot reliably watch your back and mine. I am sorry."
				*set deliberation %+5
				*set action %-5

				"You make a fair point. I don't expect you to go out of your way to assist me. But should we encounter trouble, I will look out for you to the best of my ability," the stranger says. 
				*goto without_hawk
			#"Assuming you will offer compensation for my protection."
				*set selfishness %+5
				*set equity %-5 

				The stranger laughs. The sound is mellow and deep. 

				"I have little to offer you besides the benefit of the wisdom gained from many years on the road. Even then I would not boast of my coffers to anyone. I will try to think of something more useful to you."

				"Please do," you reply. 

				The stranger laughs again.
				*goto with_hawk
	#Ignore the stranger.
		As you start to walk by the stranger, they call out to you. 

		"You intend to pass through the ravine?" 

		You keep walking and only a few steps later find an unwelcome presence keeping pace alongside you. You glance and find the stranger staring back at you. She has a muscular build and the kind of scarring to her face and throat that you would expect from someone who swings a sword for her supper. 

		"I would not go alone, friend," she says. 

		"Is that what we are?" you ask. 

		"Friend or foe, it remains the same. This place is forsaken by the gods. Going through alone is not wise. I can attest to that through personal experience. If you do not mind, I would accompany you."

		*goto accompany_choice
*label with_hawk 

She climbs to her feet, adjusts her leather vest and tightens the straps of the guards crisscrossing her arms. When she's ready, the two of you head forward.
*goto enter_ravine

*label without_hawk

You move ahead without waiting for the traveler, but she arranges herself and follows quickly. You enter the ravine alongside your uninvited escort.  
*goto enter_ravine 

*label enter_ravine

The ravine floor is not especially difficult to traverse. Years of hard rushing water have carved a path through the rock and smoothed the stones underneath. You can imagine it would be treacherous going if the water was still present, but all that surrounds you are the high stone walls of the ravine and a silence that grows deeper as you walk further. 

The traveler walks beside you at a companionable distance. Her gaze scans the rock walls and the path ahead as if anticipating something. 

"This was a holy place once. A long time ago, before my father's and mother's time, when the gods were strong and faith was unquestioned. Their intercession kept it safe. Now there are rumors of fell spirits walking this path. The influence of the gods is waning, I think. Their time is drawing to a close."

The quiet lengthens, and it becomes clear that the traveler intends for you to reply. Do you think that the time of gods is over? 
*choice
	#"Yes. The gods, if they were once powerful and beneficent, are no longer either."
		*set pantheon_regard +1
		*set hawk_affinity %+20
		*set deliberation %+10
		*set action %-10

		The traveler gives you an appraising look before responding. The long shadows of the ravine fall over half her face. It looks, briefly, like a mask. 

		"The gods have much to account for. I too suspect that the common man is better without their constant interference. Who could say though when places like this exist? Places that have withered without their stewardship?"

		"There may be worse prices to pay," you say. 

		"That is truth if ever I've heard it." 

		You and the traveler are quiet after that. 

		*goto god_question_after
	#"Yes. The yoke of the gods has been cast off. If they refuse to cede us our independence, then they should be destroyed."
		*set pantheon_regard -1
		*set riser_affinity %+10
		*set hawk_affinity %-5
		*set action %+10
		*set deliberation %-10

		"Destroyed? Who could accomplish such a thing as killing a god?" the traveler asks.

		"That is a very good question," you reply. 

		The traveler gives you a sidelong look, but does not push the issue further. 

		*goto god_question_after
	#"No. I think the gods still have a role to play in all this."
		*set hawk_scrutiny true
		*set pantheon_regard +2
		*set restraint %+5
		*set deliberation %+5
		*set action %-5
		*set ara_affinity %+10

		The traveler seems surprised. 

		"I wonder what the gods have done to earn your support, stranger. Still maybe you are right. It is possible that the gods could yet climb out of their own selfishness and lust for power and surprise us." 

		She does not seem convinced, but you don't push the issue. Her views are her own. 

		Instead, the two of you continue forward in companionable silence.

		*goto god_question_after  
	#"No. We are lower than gods, and without them we are crawling through the dark. If we want their guidance, their mercy, then we have to submit to them."
		*set hawk_affinity %-15 
		*set action %+10
		*set deliberation %-10

		The traveler visibly sneers at you. 

		"The shepherd is separate from the wolf who hunts the sheep, is that not true? You would reduce our place in the world to give them higher praise?"

		"And you would falsely hold yourself in a better light than the gods who gave you breath?" you reply. 

		"If it meant finally having a place in the world. I would."

		The disagreement never becomes heated, despite your radically different views. It could be the way your words echo from the towering walls of rock that make you hesitant to raise your voice. 

		*goto god_question_after
	#"The whims of the gods, for good or ill, have nothing to do with me or getting out of this ravine."
		*set selfishness %+15
		*set equity %-10
		*set hawk_affinity %-10
		*set eel_affinity %+15

		"I imagine there are a great deal of people who feel much the same as you do. I imagine that apathy is what allows their endless lives and boundless influence in our lives to continue unchecked."

		"Maybe," you say, without looking at the traveler, or slowing down. 

		She gets your point and continues on beside you in silence. 

		*goto god_question_after
	#"I'd prefer to keep my opinions to myself. Watch the path, those rocks ahead look dangerous."
		*set restraint %+5
		*set hawk_affinity %-10
		*set deliberation %+10
		*set action %-10

		The traveler does not reply. She keeps her silence, though something in her posture shifts. It seems she has grown colder toward you, but at least she is no longer prying into your affairs. 
		*goto god_question_after

*label god_question_after 

The shadows of the ravine deepen the further you travel into it. The sun penetrates the craggy rock formation overhead, but offers little of its warmth. The going gets rougher underfoot, and it grows colder. 

You and the traveler beside you take turns pointing out particularly perilous sections of the ground where twisting an ankle would be a matter of a single step. To your surprise, her senses are nearly as sharp as your own.

The path widens into a kind of clearing at the heart of the ravine. This is the deepest part of the natural formation, and the light is all but extinguished here.

The traveler grimaces beside you. Her fingers twitch beside the pommel of her sword. 

The dread creeps up on you slowly. Your gut is at war with the urge to flee and to fight, but the dark space is absent of a tangible threat. 
*if sensitivity >= 25
	You see something flit by almost too fast to see. It happens again and again. You can taste decay at the tip of your tongue. The dead abound.
*page_break 

*if death_toll >= 10
	*check_achievements
	*if not(choice_achieved_deadmen)
		*achieve deadmen
	It takes some time before you realize: the ground you are walking on is not the ground. Hands reach up from the blackness beneath you and attempt to drag you down into it. 

	It is a seething mass of foul, negative emotions trying to push itself up and into your body. You narrowly avoid its grasp, but the amount of arms coming from the ground are multiplying by the moment. 

	*if (ritual + sensitivity) > 15 
		You can sense bits and pieces of humanity in it. It could be an echo of human emotions, magnified in death and dragged into this awful place. 
	*comment endif 

	The traveler leaps to avoid the touch of the horrible thing's arms. She looks at it with disgust and seems intent to brandish her sword against it for whatever good that would do. 

	What will you do?

	*choice
		#Fight off the attacking spirits.
			There is no way to the other side of the clearing and away from this terrible mass of spirits except through them. You decide to fight. 

			*if combat >= 25
				It is difficult to find purchase when the arms are of little to no substance, but you are steeled by purpose and the fury of Wolf's own avatar. You fight your way through the maze of spirit-arms that chill you to the bone wherever they touch. They sap your will to continue, but your combat prowess keeps the worst of them off of you. You clench your jaw until your teeth ache to deal with the pain and stay on your feet whenever one touches you.

				The traveler fights just as hard beside you. Her sword is a blur around her and her feet are light as she moves steadily through the terrible sea of limbs. More than once you find her sword where one of those fingers would have grabbed you. 

				Eventually you make your way to the other side, tired and battered, but alive. You suppress a bitter laugh when you remember coming through the ravine was meant to be the easy road. 
				*goto post_spirit_fight
			*else
				The nature of the enemy poses a problem, however. You try to swipe at the attacking spirits, but your hands pass through their weightless bodies. 
				*goto after_fight_fail

			*label after_fight_fail

			The malicious spirits surround you. Everywhere they touch on your body goes cold, and you don't have the will to fight them for long. You sink to your knees, and the darkness fills the space around you.  

			*goto pre_stat_drop
		#Subvert the spirit-attackers with ritual force.
				The gods of Wolf's pantheon are powerful, but their reach is limited to the living. They could no more manipulate the dead than they could the flow of time itself. 

				Yet there are tremors of the living in the spirit mass. It could be enough. 

				You reach down into the earth and grasp at the shifting ground beneath you where the bloated, corrupted spirit-mass has embedded itself and its tendrils. You attempt to pull the ground apart, to destabilize what the spirit-body has insinuated itself into. 

				*if ritual >= 15
					At first the reply of the ground is faint. The spirit-mass has siphoned off so much of its resilience and strength, but you find that the earth is ready to enact its vengeance. The ground breaks apart in huge chunks. The hard-packed earth of the clearing turns into chaos around you and the spirit hands desperately try to pull it together. Yet for the all tumult, a straight and relatively stable path remains before you. 

					You offer the earth your thanks before racing across the clearing. 
					
					There isn't enough room for the traveler to run beside you, so she follows close behind. You can hear her breathing and swearing quietly as the ground wars with the spirit dominating it.  

					Even when you have crossed to the other side, the earth still rages. You hope the fury of the earth does not bring down the walls of the ravine around you. The thought makes you quickly move toward the end of the ravine and leave the clearing behind you.
					*goto post_spirit_fight 
				*else
					Yet the earth's voice is far away. You imagine the spirit-mass has been here for a long time, growing stronger off of the strength of the recent dead.

					The strain of trying to reach the land around you makes it hard to avoid the hands that reach for you. Each touch weakens your resolve, and it's not long before the dark leaps up around you.
					*goto pre_stat_drop
		#Revoke their power over you and dismiss the spirits.
			The spirit arms reach for you and you refuse to run. You stand with both feet planted. 

			You are no stranger to operating in the space where fear equals death, but you refuse to be intimidated by the spirit-mass roiling beneath you. 

			You take a breath and address the thing directly.

			*if ((sensitivity > 15) or (influence >= 3))
				"You have no power over me," you shout. "Nor my companion."

				Your words echo from the high walls of the ravine. The hands cease reaching for you. At least for the space of a few seconds. 

				"I will pass unmolested. I do not fear you, dead thing."

				You walk as though you were strolling through a grassy field rather than through the heart of a horror. 
				
				And the traveler walks beside you in subtle awe of your composure. 

				You never turn back to see if the spirit-mass is reaching after you. Not after you have crossed safely. Not after you have spotted the end of the ravine. Never. 
				*goto post_spirit_fight
			*else
				But its hands do not slow long enough for you to make your point. The spirits' many hands and its very many fingers reach into your ${skin_choice} skin and bring you to your knees. You struggle, but you cannot find your footing as the darkness creeps over you. 

				*goto pre_stat_drop
		#Push through the vengeful spirits.
			You are certain you can face whatever this spirit-horror can do to you, and there is only one way across the clearing.

			When the first spirit-hand touches you, you feel a shock and instant numbness where the spirits' fingers grasp, but you continue, moving forward despite the discomfort. 

			You are dedicated to making it through to the other side. 
			*if survival >= 15
				The hands of the spirit-mass claw at your arms and legs, they scratch at your face and attempt to drag you down into the uncertain ground beneath you. In your mind, you hear a whisper that suggests it would be easier to relent. To give in. 

				You keep moving forward. 

				There isn't much time to linger on her, but you see the traveler struggling forward as well, and her perseverance gives you a little more hope. 
				
				The other side of the clearing seems as if it's miles away and you can barely feel your limbs. The whisper in your head is now louder than your own thoughts, but something keeps you moving. 

				The other side gets closer. You are surprised to still be upright. What was once a whisper has become a roar in your head, and the last few feet are indescribable in their torment. Your feet touch something hard, and just like that, you have crossed through the spirit-horror and survived. 

				The traveler comes through a minute or so later and nearly retches beside you. The both of you take a few moments to orient yourself before continuing on.
				*goto post_spirit_fight
			*else
				But the hands of the spirit-mass are countless and your will is limited. Ultimately, you find yourself falling to your knees and struggling fruitlessly to stand. The darkness is not long in overcoming you. 
				*goto pre_stat_drop
*elseif ((death_toll > 0) and (death_toll <= 10))
	As you search for an end to the clearing, you sense that you are being watched. You wheel around, hoping to find whoever or whatever is stalking you, but it moves just a moment too quickly, managing to stay out of your vision. 

	It comes upon you all at once. 

	The thing feels like regret and anger, it refuses to be ignored. Before you it seems less like a living thing than a shroud. Your eyes burn if you try to trace the edges of it. 
	*if (ritual + sensitivity) > 15 
		It is not something god-made and thus outside of your direct influence, but you can sense the vestiges of humanity about it. The once-living thing is likely an echo of human emotion somehow dragged to this dank place.
	*comment endif 
	
	The traveler hisses at the horrible thing, but makes no move against it. She's calculating, perhaps. 

	What do you do? 
	*choice 
		#Weather the assault of the spirit-mass.
			*if survival >= 15
				Their presence alone sets you on edge and makes your jaw tighten instinctively, but you refuse to let the spirits intimidate you. You take a deep, centering breath as the spirits converge on you. Before everything turns black. 

				Inside of the roiling, screaming darkness, the spirits buffet against you and attempt to rip into your ${skin_choice} skin, but you remind yourself that the incorporeal forces can't harm you unless they overpower you. 

				You let them scream and roll, howl their bloody cry, but throughout you remain standing. You notice after what could be minutes or hours that there is a shaft of light penetrating the darkness. You move toward it. Your arms and legs are sore and your mind is tired, but you push yourself to lift one leg then the other. One step turns into a second then a third and suddenly, you have moved beyond the surging mass.  
				
				A few paces away, you find the traveler struggling through a similar mass. Before you can decide to help her or leave her to her fate, she breaks loose on her own. She emerges looking as harried and exhausted as you feel. 

				"Gods burn and salt this cursed place," she swears. 

				You can't help but feel similarly.

				You move on as quickly as you can, putting space between yourself and the grasping hands that still reach for you. You hope never to have to travel through this place again.

				*label post_spirit_fight
				*page_break
				As you walk away from your confrontation with the mad echoes of the dead, you consider the
				*if death_toll = 1
					death
				*if death_toll != 1
					deaths
				you have caused. It is not impossible to imagine that the dead you create help to strengthen that unthinking body of malice. Is murder justified in your quest for answers, justice, and purpose?
				*choice
					#"Strength is justification enough."
						*set action %+5
						*set deliberation %-5
						You have lived alongside Wolf for many years and you have seen what horrors the world is capable of. You are not afraid of using your strength to reshape your surroundings. If others are intimidated by your power, forced into lesser positions, or destroyed altogether, then theirs is a necessary sacrifice. Whoever is responsible for Wolf's destruction should fear your resolve.
						*goto walk_on
					#"If the good of many relies on the death of a few, then so be it."
						*set equity %+5
						*set selfishness %-5
						You are loath to reduce the worth of individuals, but you understand that good intentions alone will not do the greatest good. You are not afraid of killing if it can save the lives of countless more. The consequences are yours to live with, but Wolf would not have chosen someone with shoulders that could not carry such weight. It is only with resolve this strong that you discover those responsible for Wolf's recent absence from the world.
						*goto walk_on
					#"Each life is sacred, all must be done to preserve their dignity and safety."
						*set deliberation %+5
						*set action %-5
						Especially during dark times, common humanity provides the best way forward. The gods themselves inhabit human bodies, presumably to learn something of the lives of their sacred wards. You carefully consider the value of each life and while this may be what separates you from the god that once lived in your skin, you also believe that is what ultimately made you so valuable to him. It could be that your humanity and concern will lead to Wolf's killer. 
						*goto walk_on  
					#"The sum of a life is its utility, and some lives are only made useful by their destruction."
						*set selfishness %+5
						*set equity %-5
						Your views are as cynical as the times that shaped them, but who will be more committed to continuing Wolf's legacy or finding those responsible for his end than you?
						*goto walk_on

				*label walk_on

				With these thoughts in mind, you continue plodding through the dark ravine and leave the knotted, angry spirits behind.
				*page_break

				After leaving the spirit-plagued clearing, the path before you narrows once again. You can also once more see the light of day ahead of you.  

				The traveler keeps pace with you and insists she is fine despite her labored breathing. 

				"I have passed through this place before. This is the worst it has ever been. I wonder if they grow bolder or I more frail." She chuckles to herself. "Either option is terrifying."

				As you approach the end of the ravine, the traveler stops you. 

				"We part here, fellow traveler. My business from here forward is my own. I wish you safe travels, though, and it might be that we will encounter each other again. I might even ask your name."

				She strides out in the light, her lean form strikes quite the silhouette. In the shadow that trails behind her, there are glorious wings sprouting from her back, but those wings are nowhere to be seen on the dusty robe draped across her shoulders. 

				The bizarre shadow suggests the arcane is at work, and the shape of it implies the presence of Hawk. You cannot help but think that you were meant to see it, that this was an announcement of sorts. The gods do love their chicanery.  

				After a moment of consideration, you follow the Hawk avatar out into the bright day, but she is gone. Only your travels remain ahead of you.  

				*label just_before_steppe 
				The sun is warm on your ${skin_choice} skin at the mouth of the ravine and before you is the wide, endless land-sea of the steppe. The open vista inspires
				*if tribe = "Highwalk"
					nostalgic pride
				*if tribe != "Highwalk"
					a vague, disorienting terror. 
				*goto on_to_van
			*else
				The attacking spirits are terrifying, but you believe you are strong enough to stand up to them. As they surround you, you plant your feet and close your eyes as they rush forth. 

				You are able to fight the cold, shrieking void that they create. Your will is stronger than they are. 

				For a while anyway. 

				*label pre_stat_drop
				*if sensitivity < 15
					*set restraint %-10
					*goto after_stat_drop
				*else 
					*set survival -5
					*goto after_stat_drop
				*label after_stat_drop

				Your thoughts grow desperate and you lash out futilely to keep the bodiless spirits away from you. As hard as you fight, they keep encroaching until every last sliver of light is obscured. You are wrapped entirely in their darkness.

				You can feel
				*if sensitivity < 15 
					your restraint being pushed to the limit. You sense that you will have a harder time reigning in your instincts from now on.
					*goto post_stat_drop_descrip
				*else
					your body and mind growing numb in the cold darkness. You suspect that going forward your survival instinct will be somewhat less keen.
					*goto post_stat_drop_descrip
				*label post_stat_drop_descrip
				After a few desperate, awful moments, you feel somehow calmer. What runs through your mind as the spirits strangle you?

				*choice
					#Even if I die here, the other gods will continue to search for answers about their brother Wolf.
						*set deliberation %+5
						*set action %-5
						*goto post_choice
					#I can't die. I will fight my way out no matter what.
						*set action %+5
						*set deliberation %-5
						*goto post_choice
					#I don't think this is the end. How could my story end with spirits?
						*set selfishness %+5
						*set equity %-5
						*goto post_choice
					#There is so much left to do. I can't let myself go.
						*set equity %+5
						*set selfishness %-5
						*goto post_choice

				*label post_choice

				You are trying to draw breath and failing when you feel the hand around your wrist. At first it feels like the darkness around you is trying to draw you deeper, but ultimately the hand tugging at you does the opposite. You are pulled, inch by unyielding inch, out of the consuming grasp of the spirits as they shriek in your ears.

				You are pulled until you emerge entirely from the dark mass.  

				The traveler helps you to stand. She seems to have gone through some difficulties herself, but between the two of you, you escape past the reach of the wailing spirits. 
				
				"I have had cause to travel through this place before and I can tell you that we were lucky. Others have suffered far worse fates than ours in that clearing," the traveler says, and is quiet after. 

				You walk together in a companionable silence as you search for an exit to this damned ravine. 

				*goto after_violence_query
		#Dash past the thing and out of the cursed clearing.
			The arms emerging from the flailing, shifting mass are slow-moving, and you are sure that you are fast enough to outrun them. You do not give yourself time to consider the alternative. You break into a run. 

			As you approach on the left of the mass, it seems to understand your intentions and three arms simultaneously shoot from the center, if it could be said to have a center, of the thing.

			*if ((survival >= 20) or (quickthinking >= 20))
				But you are too quick to be ensnared. Your body responds almost without delay, and you are able to dodge as two of the three arms pass harmlessly overhead. The third only briefly brushes your side. The contact chills you to the bone, but it is not enough to stop you. 

				The traveler runs nearly as fast as you do. Her sword clangs awkwardly at her side, but she keeps up and dodges like a woman who has been forced to resort to nimbleness before now.

				You do not turn around until you are sure you have cleared the reach of the spirit mass.
				*goto post_spirit_fight
			*else
				You dodge two of the three arms, but the third reaches into your side. Your skin offers as much resistance as water might, and your blood is chilled. You trip. Your momentum throws you forward, but the long darkness of the mass wraps itself around you before you even hit the ground. 
				*goto pre_stat_drop
		#Use my ritual knowledge to put the spirit to rest.
			All of the gods of the sky, Wolf and his ilk, are gods of life and thus have no direct language to speak for or to the dead. Yet you are not powerless, even in this dark and foreboding place. 

			You can still hear the wind and smell the earth, tainted though it is with the tasteless reek of the soul-wounded dead. You reach for the land, the wind, and the memory of water rushing through this ravine. 

			*if ritual >= 15
				And in turn they reach back into you and rush through your ears louder than your own pulse. The spirit mass reaches for you, tries to wrap its profusion of hands around you, but the once-water and the wind and the earth are inside you. They are wrapped around you. The hands of the wailing, suffering spirits cannot find you. 

				It is nothing to ask the generous earth to extend its protection to the traveler as well. She walks untroubled as the arms of the mass grab at her. She seems perplexed, but ultimately seems to accept that the intercession must be your doing. You cannot tell her yourself, as the sound of rushing water, hard-blowing wind, and crushing earth are filling your ears and mouth. She likely couldn't hear you anyway.

				As you reach a safe distance from the dark mass, the pulse of the earth slowly leaves your ears and mouth. Your senses are yours once again, and you are safe. For the moment. 
				*goto post_spirit_fight
			*else
				But they do not reach back. The water that once rushed through this place has been gone for so long that it would take someone more skilled in the deep mysteries to bring them out again. What little of the wind and earth responds to your summons can hardly fend off the persistent grasping of the many-handed spirit mass. 

				Its hands chill everywhere they touch, and the darkness doesn't take long to envelop you.
				*goto pre_stat_drop
		#Reason with the spirits.
			You stand your ground as the spirits, bound in horrifying unity, approach. You shout in their direction, imploring them to stop, to turn away. Your tone is steely, your stance firm, and you invest your voice with as much gravitas and more as anyone could produce in your situation.

			*if ((sensitivity >= 15) or (influence >= 3))
				And somehow it is enough. At least enough to slow the spirits' onward charge. Traveling with Wolf, you have stared down danger countless times and you don't consider this any different. 

				"This will not ease your pain," you say. 

				The spirit mass wavers. The dense darkness that forms its core shifts and rolls over itself like a living nightmare, but you do not look away.

				"You will not have me, spirit," you declare. "Nor my companion."

				Carefully you start to walk toward the other side of the clearing. The spirit mass does not move stop you. A handful of tense moments pass before you are out of the range of the spirits' reach. 
				*goto post_spirit_fight
			*else 
				But the thing does not respond to your posturing. It comes forward faster than before, and you do not have time to flee. It reaches its cold fingers into you and fills the space around you before you can even scream. 

				*goto pre_stat_drop
*else
	You wander through the dark, your hackles raised and your stomach churning with the irrational fear that seems to have settled into your skin. You can neither find the way you entered the clearing nor the other side of it, though you could see the exit clearly as you entered.

	You would suspect the use of ritualistic power obscuring your senses, but the air lacks the deep, mossy tang of arcane workings. Whatever has ensnared you is subtle magic indeed or something else altogether.

	The traveler spits at the ground and shakes her head.  

	"This place…" She grasps for the right words to describe this foreboding place. "It is broken. Hard to navigate. The spirits of the dead congregate here without guidance to set them on a proper path."

	*if sensitivity > 15
		*set hawk_affinity %+10
		"I know. I could taste them," you say. 

		The traveler seems impressed.
	"Thankfully, the way out is not far from here."

	"How do you know the way?" you ask. 

	"I have, unfortunately, had cause to travel through this place. I try to avoid it, but my travels sometimes lead me through places like this and worse, too, if you can believe such places exist."

	*label pre_violence_query

	True to her word, the traveler leads you to the other side of the clearing, and slowly the awful feeling inside you recedes. 

	Up ahead light floods through the ravine, much brighter than the late afternoon sun you expected.

	"The clearing we passed through. It can be truly awful for those with blood on their hands. I have more than once been assailed by the spirits of those who have fallen under my blade. Yet when I found you, you were more peaceful than I imagine any killer would be on their first time through. 

	"Do you imagine that you can keep your hands clean on your travels, stranger? Can you stay unbloodied in this brutal world?"
	*choice
		#"For a greater good, I would shed blood."
			*set hawk_affinity %+15
			*set equity %+15
			*set selfishness %-15

			"Then I think we understand each other."

			*goto after_violence_query 
		#"I will not kill, nor do unnecessary harm. I swear it."
			*set pacifism true
			*set bear_affinity %+25

			"I hope that you can stand on those morals, stranger. These lands of ours are riddled with the bones of those who thought it prudent to stay removed from violence and turmoil. They forgot that it takes strength to enforce peace. Still, I hope you can find whatever balance you seek."

			*goto after_violence_query 
		#"You think these are clean? I am just getting started."
			*set restraint %-5
			*set hawk_affinity %-10
			*set action %+15
			*set deliberation %-15

			"Are you so hungry for blood, stranger? To what end? Do you even know?

			"Well, ultimately it doesn't matter. We all live under the threat of the sword, whether we wield one or not. One day you may find that there's a bigger one aimed at your throat."

			*goto after_violence_query
		#"I am a creature of whim. If I have to rupture and kill to get what I want, so be it."
			*set hawk_affinity %-20
			*set ara_affinity %+20
			*set selfishness %+15
			*set equity %-15
			*set chaos_score +1

			"Disruption and chaos: Is that what spurns you on, stranger? What excites your blood? I can't imagine what thoughts churn inside that mind of yours and I am truly glad of that."

			*goto after_violence_query

	*label after_violence_query
	*page_break

	The both of you walk until you emerge from the ravine. It is late in the day, suggesting that many hours have passed instead of the handful you had estimated. You wonder aloud how long you were in the ravine. 

	"A few days, I would say. Time bends differently in the places once touched by the gods," the traveler says, and shrugs. 

	You find it hard to believe that you were walking the length of the ravine for days, but your stomach, suddenly aching with hunger, and your feet, abruptly pained and swollen, suggest a stranger truth. 

	You look out to the great, flat expanse of grass before you and get dizzy with
	*if tribe = "Highwalk"
		a swelling sense of homesickness.
		*goto hawk_farewell
	*else
		a sense of vertigo at the endlessness of it.
		*goto hawk_farewell

	*label hawk_farewell

	"One encounters many interesting people on the road, but few with the mettle to survive such a twisted place. I have encountered countless humans and many other bearers of our will, but few such people as yourself."

	You notice the distinct avian cant of the stranger's face. Hawk herself stares back at you from behind the traveler's eyes. Whatever arcane concealments that kept you from seeing her until now are abruptly dismissed. 

	"Until we meet again," the traveler-god says.

	She wanders off to her own journey, no doubt leaving you with questions, but your own travels await. You continue forward.

	*goto on_to_van 

*label on_to_van 
*page_break

Before reaching the steppe proper you find a small, clear stream where you find water and have a chance to catch small game—which you roast over an open flame—and collect edible plants. You spend a night recovering from your strange ordeals before continuing forward.

*comment this section is a dream of the past, which happened before the game begins.
You lie down beneath the stars and see Gazelle's twin constellations sparkling in the distant sky. You hope she will grant you pleasant dreams, but when they come, they are far from pleasant. It hardly even feels like a dream. 

You are almost sure you are standing where you once stood, and you can even feel the rough cloth against your skin and the breeze blowing
*if hair_choice != "bald head"
	through your ${hair_choice}.
*if hair_choice = "bald head"
	over your smooth, shaved head.
It is years ago, when you were younger and just growing accustomed to living in Wolf's long shadow. 

You are standing over a man whose hand is pressed at the wound in his side. He looks up at you with a mix of revulsion and terror. The wound you have inflicted upon him is deep, but he will survive. Maybe. 

"Finish it," Wolf whispers in the back of your mind. "He tried to kill you. Kill us. He failed. End him."

Your mouth waters at the command. The part of your heart that rests under Wolf's lupine paw aches to do it. The thrill is nearly erotic. 

"He is my enemy, ${prenom}," Wolf says, his voice echoing.

This man tried to kill you. He is a member of some nameless, seething insurgency with ideas of bringing the gods to their knees. You noticed him and his allies tracking you near a hamlet called Holmgrum. They followed you all the way out into rough country, far from the safety of the burgeoning settlements on the outskirts of civilized land. Now his friends lie dead around him. 

He tried to kill you. 

You should kill him. Wolf wants you to. So do you?

*choice
	#I snap his neck. Dragging him along will only drain my resources. 
		*set action %+15
		*set deliberation %-15
		*set survival +5
		You break the man's neck. It is clean and quick and he barely has a moment to resist before the life goes out of him. 
		*goto murderous_wolf
	#I take his water and other supplies, but leave him alive. If he recovers, he can tell others of my prowess. 
		*set selfishness %+15
		*set equity %-15
		*set influence +1
		You turn one eye to the bright morning sky and see the silhouette of a bird circling. Hawk, who can see out of the eyes of all birds of prey, may offer your attacker succor and send him aid. Or she might not. 
		*goto charitable_wolf
	#I leave him to bleed out. If his allies find me, that might drag things out unnecessarily.
		*set selfishness %+10
		*set equity %-10
		*set quickthinking +5
		You find it hard to be particularly concerned with the life of a single man, especially one who would take up arms against you. 
		*goto murderous_wolf
	#I tear my sleeve and tell him to press it against his wound, then help him back to town.
		*set equity %+15
		*set selfishness %-15
		*set sensitivity +5
		He moves slowly, understandable considering the blood that seeps through the cloth he keeps pressed to his side. He is wise enough to keep quiet as the two of you hobble toward town. 

		You leave him at the gates of Holmgrum and signal to the lone watchman that someone is in need of help. The wounded man thanks you as you walk away, but you do not stop to acknowledge the gesture.
		*goto charitable_wolf
	#I tear out his heart. As his life drips between my fingers, I will feel my rituals grow stronger.
		*set action %+20
		*set deliberation %-20
		*set ritual +5
		He does not beg, which irks Wolf, but the god is satisfied when you tear out the enemy's heart. 
		*goto murderous_wolf

*label murderous_wolf

"You had to do it, ${prenom}. It is our fierceness that gives us strength, that makes us whole. We are adrift without it, and gods cannot afford indecision,"
*goto wolf_muses

*label charitable_wolf

"It is a mistake to offer mercy, ${prenom}. But you are lucky that I am here to protect you when you make foolish decisions,"
*goto wolf_muses

*label wolf_muses
Wolf huffs. "It is time to turn our attention to other matters. I smell blood and conflict in the east. Your fleshy mortal kin are playing at war-making. We will go among them and sow violence like they have never seen. As their cries rise up in terror, I will eat their fear, and we will grow stronger."

The suggestion is not an uncommon one: Wolf has ridden you across unfathomable tracts of lands and made you perform unspeakable acts against those he considers his enemies or even just those he deems are worthy of dying at his hand. He is an exacting, brutal master, but you have grown stronger in his service. 

Do you find it to be a fair trade? Spilling blood for power?

*fake_choice
	#Yes. I am his weapon and he keeps me sharp.
		*set chaos_score +1
		You are Wolf's blade and you are content with the job. He asks you to kill and you do, he asks to intimidate and you do. It is not difficult or complex. 
	#Perhaps. Whatever he asks is worth doing, as long as Wolf gives me something for my trouble.
		*set ara_affinity %+15
		The relationship is essentially transactional: Wolf gives you power and you give him slaughter if and when he requires it. There are worse lots in life, and you have side-stepped them by being attached to a god. Things could be so much worse. 
	#No. I am enslaved to the hunger of a rabid god.
		*set hawk_affinity %+15
		*set bear_affinity %+10
		Wolf consumes. It seems to be all he does. He may calculate and scheme like the other gods, but his primary drive seems to be the acquisition of power and using that power to keep others in line. 
	#I try not to dwell on what I am forced to do. I am alive, for now. That is enough.
		*set restraint %+15
		You are resigned to your fate. You know what Wolf is and you understand your role as his tool. Survival is your greatest priority. Anything beyond that is a luxury you cannot afford to consider. 
	#I am patient. I will wait until the right moment, gather my power, then assert my independence from Wolf. Until then, I do as I am told.
		*set pantheon_regard +1
		It is a slim chance. You cannot imagine that there are many avatars of the gods who have managed to escape their fate. But the idea of escaping keeps you alive, even if it does not help to make the work you do for Wolf more palatable. 
	#It is bloody work, but it is a challenge and I deeply enjoy a good challenge.
		*set eel_affinity %+15
		You are hardly concerned about the lives you take, and though you do not necessarily relish in the bloodshed, you know it provides a greater challenge and a more exciting life than whatever you would have experienced in the ${tribe} town you were born in.
*comment endif

And so, eager or not, you head off to the next conflict Wolf embroils you in, a territorial squabble about access to a minor quarry. A Highwalk Caravan, back from a years-long sojourn to the furthest end of the steppe, claims ancestral rights to the quarry, while the local river-Quiet objects with the argument that they are protecting the area and are putting back-breaking days and months of service into developing the pit. The Quiet argue that they need the sturdy stones to build fishing implements and shore up their homes against the whims of the oft-flooding river.

Wolf has no opinion about the politics, but both groups have made the mistake of shedding enough blood to call to the Wolf god. So you are forced to march into this powder keg and expected to wreak havoc, bring the bloodshed, and instill in them the terror of their most ferocious god. Which you must have done, no?

*choice
	#I fight the command tooth and nail.
		*gosub trial_end
		*label wolf_force
		You try to fight, and your resistance, rather than frustrating Wolf, seems to amuse him. He forces you to lift your hands and go to his bloody work. 

		*label wolf_killing
		Neither the Highwalk nor the Quiet fighters are prepared when you come into their midst, attacking indiscriminately. Wolf savors the taste of their fear as you strike them down. The wise ones escape, and Wolf does not instruct you to give chase. He wants you to fight the strong ones, the ones who think they stand a chance against the avatar of a living god. Some of them manage not to disgrace themselves, and one or two show such promise that Wolf is even momentarily impressed. 

		But they all die. Each and every one of them that lifts a weapon against you. Some slower than others. In the dream you cannot recall their faces, so it seems like the same person dying over and over. 

		When you are done, the quarry is littered with bodies.

		"Some of those who escaped are already spreading tales of what happened here to their allies." You cannot see them beyond the high walls of the quarry, but Wolf has never given you a reason to doubt his hearing.

		"Can you feel yourself growing stronger?" Wolf asks. 

		You can: Your lungs seem to take in more air, and you stand somewhat straighter. The blood pooled around your feet is not your own, and even that gives you a rush of power, deepening the well of power from which Wolf draws. 

		"The weak long to play a role, ${prenom}. This is how we honor them. We eat their weakness and grow stronger by it. Stronger and stronger until the entire world kneels. That is the natural order, and that is what ensures that the sun will never set on my brothers and my sisters and myself."

		You turn away from the bodies. and Wolf is already urging you forward. 

		"Stronger and stronger," he whispers.
		*goto end_dream
	#I do as Wolf bids me. Reluctantly.
		*gosub trial_end
		*goto wolf_force
	#I make them fear me.
		*gosub trial_end
		*goto wolf_killing

*label end_dream 
*page_break 
You wake in a cold sweat. It takes time to orient yourself and untangle yourself from the threads of your memories.

You do not spend another moment rehashing a dead time. 

According to your directions, Mara's Caravan, where you might find a prophet of Gazelle, is not more than twelve hours away by foot, but you have already lost days to the twisted space at the center of the ravine and hours to a poor sleep full of old dreams. You wonder what awaits you at the 'Van as you again set off toward it. 
*finish

*label trial_end
*check_purchase adfree
*if choice_purchased_adfree or not(choice_purchase_supported)
	*label purchased
	*return
Remember earlier how we told you that the first three chapters are available for free? This is the end of the free content.

*if choice_prerelease and choice_is_web
	*subscribe {"allowContinue": false}

[i]To find out what happens next, please purchase the remaining chapters.[/i]

*purchase_discount adfree 2019-07-09 $4.99 $2.99 purchased
*abort
*return