*text_image chap_2.png center Two: Other Gods

[i]"Brother Wolf," said Eel. "I have heard you are the closest of us to your original animal state and therefore the wisest. So tell me: what is luck?"[/i]

[i]"Well, Brother Eel. I think that for an eel like you, luck is in your kin," said Wolf.[/i]

[i]"Is that because families help each other?" asked Eel.[/i]

[i]Wolf smiled and bared his awful teeth. "Not exactly. You are lucky because wolves do not eat their kin."[/i]
*line_break
—from an old Quiet fable.
*page_break

You smell Ishko before you see it. The wind carries the scents of cooked food and manure across the hilly landscape. You find the Clearwater settlement, almost big enough to be called a town, carved into the side of a pleasantly sloping hill.

The Clearwaters have been expanding their territories for ten years or more. They have branched out all across the northern hills and tested their luck at the edge of the vast steppe to the south, which the Highwalk call home. 
*if tribe = "Clearwater"
	It has meant unexpected prosperity for the still-growing clan. You cannot help but think of these gains with some pride.
*if tribe = "Highwalk"
	This has caused occasional tension between the clans. You cannot imagine the awkwardly lumbering, wooden structures of the Clearwaters cluttering the vast austerity of the steppe. You shake your head at the ridiculous image as you continue on.
*if tribe = "Quiet"
	The ceaseless squabbling for land between Clearwater and Highwalk has long been a source of bleak humor for the comparatively reclusive Quiet. You recall the phrase: what use does the magpie have with a hammer?
*comment endif

You find your way to Ishko proper and notice the unfinished touches of the young settlement; low stone walls, pitched tents between wooden homes. You also notice the eyes on you. It is understandable: You are a stranger and these are strange times. 
*if tribe = "Clearwater"
	But though you attract wary glances, there is nothing outwardly hostile in their gazes. They are merely curious.
*if tribe = "Highwalk"
	A woman snatches a child out of your path as you walk by, an old man forms a claw with his fingers and makes a sign to Hawk against mischief. A youth with a puffed out chest grips the handle of a spade with white knuckles.
*if tribe = "Quiet"
	"Something reeks of fish," you overhear, but it is hard to tell who has said it. There are sneering men and women nearby, but no one says anything else that you can hear.
*comment endif

*if (attraction = "male") or (attraction = "bi")
	*set ara_name "Aran"
	*set ara_he "he"
	*set ara_gender "man"
	*set ara_him "him"
	*set ara_his "his"
	*set ara_possess "his"
	*goto meet_ara
*label meet_ara
You continue on toward the center of the settlement and someone steps into your path, presumably to greet you. But you can quickly tell that ${ara_he} is not a local. The cut of ${ara_his} tunic seems scandalous by local standards and ${ara_his} hair is neatly cut and clean, if fairly long.

"${prenom}," ${ara_he} says warmly. "Welcome to Ishko! Home of no one you ever need know, famous for not burning down. Not yet anyway."

$!{ara_his} sudden candor and conspiratorial tone is bracing. You do not know who ${ara_he} is, but ${ara_he} is speaking to you directly. 

How do you reply?

*choice
	#With suspicion: I do not know ${ara_him} and cannot trust ${ara_him}.
		*set influence +1
		*set selfishness %+10
		*set equity %-10
		*set ara_affinity %+25
		"Mistrust, discomfort." $!{ara_he} puts a hand on ${ara_his} jaw and drums ${ara_his} fingers against it. "You are right to put as little faith as possible in me. I am impressed. Perhaps there is hope for you yet, little wolf."
		*goto ara_reaction
	#With warmth: $!{ara_he} seems friendly, and that can be an advantage.
		*set equity %+10
		*set sensitivity +5
		*set selfishness %-10
		*set ara_affinity %-10
		$!{ara_he} raises an eyebrow when you respond pleasantly. $!{ara_he} laughs outright a moment later. 

		"Our Wolf really has evaporated," ${ara_he} says. "Speaking to a stranger without baring teeth? Unusual to say the least, my lupine friend."
		*goto ara_reaction
	#With hostility: $!{ara_he} presumes familiarity without cause. That is reason enough to anger me.
		*set action %+10
		*set deliberation %-10
		*set quickthinking +5
		*set ara_affinity %+15
		When you growl your reply, ${ara_his} eyes narrow and ${ara_his} grin widens. 

		"There it is. The raw edge. The animal instincts, still there. What a beautiful sight," ${ara_he} says. "If you give in to those impulses, you will surely become a beautiful whirlwind of death. You will be lost in the sensation of it. I cannot wait."
		*goto ara_reaction
	#With humor: Whoever ${ara_he} is, ${ara_he} does not seem to be very serious. May as well match ${ara_his} tone with mine.
		*set ritual +5
		*set selfishness %+5
		*set deliberation %-5
		*set ara_affinity %+10
		You crack a joke about your proclivity toward strangling strangers. It is not much of a joke, but being Wolf's avatar has not left much time for comedy. 

		Still, the stranger laughs raucously as if a joke was the last thing ${ara_he} expected.

		"Wolf's own weapon is funny. I would not have imagined. Not ever," ${ara_he} responds.
		*goto ara_reaction 

*label ara_reaction

"Who are you?" you ask. "And how do you know my name?"

$!{ara_he} genuflects sarcastically.

"I am ${ara_name}. I know a great many things. And I believe you know me."

Around the periphery of ${ara_his} dark irises, there are suddenly a half-dozen or more tiny eyes staring back at you. You blink, and the effect is gone: ${ara_his} eyes are normal once again, but you cannot shake the sensation of being watched. 

"Spider," you say. 

"Yes. The living embodiment of the clever, cunning, gracious goddess. At your service. Possibly," ${ara_name} says. "But look at you, you are filthy and tired. There is a place nearby where you can find a little food and shelter, if sleeping under the stars has lost some of its charm. Come find me in the morning if you have questions that need answering."

You cannot recall ever meeting an avatar of Spider, but there is little doubt that ${ara_he} is what ${ara_he} claims to be. You shake your head and make your way deeper into the settlement.
*page_break

You find the closest thing to an inn near the heart of the settlement, and its Clearwater proprietress looks at you with 
*if tribe != "Clearwater"
	open disdain. She offers you a place to sleep, a hot meal and a bath if you choose in return for hours of work chopping and hauling wood for her hearth. She does not seem to trust you with an axe in hand and so she floats nearby until you finish and return the instrument to her.
	*goto at_the_inn_2
*else
	pity.

	"One of our own looking like a wild-${man_woman}. Hawk must have had an eye out to bring you to my doorstep," she says, ushering you into the warm establishment. "You need a meal in you and a bath, I would wager."

	The woman will not hear anything about repayment, so you only bring the subject up once.
	*goto at_the_inn_2

*label at_the_inn_2

The meal she offers is simple fare: vegetables boiled beyond recognition and a simple fish broth, but it is hot and therefore welcome. After you've eaten in a companionable enough silence, you ask her to tell you a bit about Ishko. She bristles at the question initially, but eventually answers.

She tells you
*if tribe = "Clearwater" 
	about her partner whose idea it was to help establish the new settlement at the edge of Clearwater territory. It was a romantic notion but had its difficulties; wild animal attacks at the fringes of the village, long bouts of drought in the high summer, and starvation during the winters.
*if tribe != "Clearwater"
	in clipped sentences about goods stolen by Highwalk and Quiet strangers in the dead of night. She points out that any attempt to weaken Ishko from within its borders carries the price of death, but stops short of making specific accusations.

*page_break
After finishing your modest dinner you are offered a bath. The water is lukewarm at best and there is no soap to speak of, but there is a warped piece of glass in which you catch your reflection. Your hair is: 

*choice
	#Twisted in dark, intricate braids that trail down my back.
		*set hair_choice "braided hair"
		*goto skin_choice
	#Copper-red and shaved short with whatever sharp implement is within reach.
		*set hair_choice "short hair"
		*goto skin_choice
	#Light blond and curly, when it is not laden with oil and sweat. 
		*set hair_choice "curly hair"
		*goto skin_choice
	#Black and straight, usually tied back with some bit of leather or twine.
		*set hair_choice "long black hair"
		*goto skin_choice
	#Brown and wavy, of average length, but thick. 
		*set hair_choice "wavy hair"
		*goto skin_choice
	#Black and kinky with soft, oft-tangled whorls.
		*set hair_choice "kinky hair"
		*goto skin_choice
	#Non-existent. I shave it completely clean every chance I get. 
		*set hair_choice "bald head"
		*goto skin_choice

*label skin_choice

You have to grudgingly admit that your head looks better when clean. As does your skin, which is: 

*choice
	#Clear and unblemished, free of major scarring.
		*set skin_choice "smooth"
		*goto sleepy_time
	#Crisscrossed with scars at various stages of healing. 
		*set skin_choice "scarred"
		*goto sleepy_time
	#Freckled across my face, chest, and arms. 
		*set skin_choice "freckled"
		*goto sleepy_time
	#Unscarred, but tattoos proudly declaring my clan all but cover my back and upper arms.
		*set skin_choice "tattooed"
		*goto sleepy_time

*label sleepy_time

You leave the bath and feel somewhat restored. But sleep is your ultimate goal. You find your designated sleeping area:
*if tribe != "Clearwater"
	a stained pallet thrown down in a corner of a communal space packed with other sleepers. You briefly wonder if the Clearwater woman would have treated one of her own so poorly, but do not dwell on the thought long. 
*if tribe = "Clearwater"
	a pallet and feather-stuffed pillow in a relatively secluded area of the inn.
You fall asleep quickly. 

You dream. 
*page_break 

You hear the pad of his preternaturally quiet steps on the softened ground, but Wolf can no more hide from you than you from him. You cannot see his shape in the driving rain, but you catch his scent through the wet. He 
*if ((action > deliberation) and (selfishness >= equity))
	circles you for a few long moments, but in the end pads into your view.
	*goto continue
*else
	growls at you from somewhere out in the rain and appears before you gradually.
	*goto continue

*label continue
You wonder how it is possible for a fallen god to skulk around you in your sleep, but that concern is made distant in the gnarled logic of dreams. 

*if pantheon_regard < 5
	There is a body lying before Wolf. Someone that you tore apart in the forest. There is blood on Wolf's maw. You cannot tell whether if it belongs to the dead person, the Wolf, or yourself.
	*goto sleepy_time_2 

*if pantheon_regard >= 5
	The Wolf carries a broken rabbit in his teeth and drops it at his feet. He licks blood from his maw and stares at you. You can feel his hunger inside you so keenly that your stomach knots with it. 
	*if restraint > 30
		Somehow you find the strength to stay upright. You restrain yourself, when you otherwise might lapse into bestial urges. 
		*goto sleepy_time_2
	*else
		You get on your knees and feast on the animal, tearing at it with your teeth and savoring the hot, fresh meat. There is no need to restrain yourself. You are an animal, too.
		*goto sleepy_time_2

*label sleepy_time_2

*comment This is Wolf path.
*if ((action > deliberation) and (selfishness >= equity))
	"You are me." 

	The voice is yours, or some animal approximation of your voice. "We will be avenged."
	*goto post_dream
*else
	"A wolf is always a wolf, teeth bared or smiling."

	The voice you hear is your own. But you are not speaking the words. Wolf watches you carefully.

	"I am you and you are me. And we will be avenged."
	*goto post_dream

*label post_dream 
*page_break 

In the morning, the strange mood of your dream burns off under the sun like dew, but leaves a tacky feeling in the back of your throat. Most gods reach out to their servants through dreams and signs, but Wolf was always more direct with you, preferring to lead you through instinct and feeling than distant, jumbled augury. There are others though, avatars and priests of far-seeing gods who are known to unravel meaning from dreams and delve into unknown futures. Perhaps it would be worth your time to seek one out. 

Once you are fully awake, you begin to ready yourself for the day. 

The innkeeper offers you breakfast—such as it is—and you accept gratefully. As you work through the lentils you were given, you see ${ara_name} doing the same, seated at one of the long tables that forms the half-cocked dining room. You approach ${ara_him}, and ${ara_he} smiles. 

"Not the finest food in the wide world, but one does what one must, no?"

"That is true," you remark, and sit across from ${ara_him}. "You offered to answer my questions."

"Did I?" ${ara_name} says. "Ask them and we will see, I suppose."

*label ara_reaction_2
What questions, if any, do you have for the Spider host?

*choice
	*disable_reuse #"Why approach me?"
		*set no_question true
		${ara_name} shrugs. 

		"I waited here for you." $!{ara_he} reaches out to touch your cheek, but draws back ${ara_his} hand at the last moment. "I wanted to see for myself if it was true what the goddess saw."

		"What did she see?" you ask. 

		"That is a different question, little wolf," ${ara_he} says. 
		*page_break
		*goto ara_reaction_2
	*disable_reuse #"You are the same as I am, an avatar."
		*set no_question true
		"Not quite a question, is it? And, are we the same?" ${ara_name} tests the last word out on ${ara_his} tongue. $!{ara_he} considers the question for a moment. "No. I do not think so. We are both hosts, avatars, whatever you would like to call those of us whose bodies are living altars to the gods. But I do not think we are the same, Wolf-kin. Especially not with your newfound freedom."

		"Freedom? What do you mean?" you ask.  

		"Ah. Yet another question," ${ara_he} says. 
		*page_break
		*goto ara_reaction_2
	*disable_reuse #"Do you know what has happened to Wolf?"
		*set no_question true
		*set wolf_question true
		"There it is: The question worth asking. Would you believe me, ${prenom}, if I said that Wolf was gone? Murdered perhaps or dead from his own foolish nature. Would you take me at my word?"

		Before you can answer, ${ara_he} waves off your reply. 

		"Wolf is dead. That is all I know. You and whatever of him you carry are all that remains of our brother-god. So I suppose you ought to step carefully, a false move and all that remains of a proud force of nature becomes extinct. Quite the burden if you ask me," ${ara_he} says. "But if it were me, I would go looking for someone who could look into the sky and the stars and fetch me some answers. Maybe someone with far enough sight that they see my fate before them and my past behind them."

		"I was thinking the same," you say, and look at ${ara_him} pointedly.

		${ara_name} laughs. "Are you thinking about me? No, Wolf-kin. Spider has many eyes but none, so far as I know, that peer into the future or the past. Our lady watches the world and weaves her impenetrable web, but what fun would it be if she already knew the outcome? Why play a game whose result is already set? How would one prove one's mastery of all things?"

		And you reply: 
		*fake_choice
			#"Then you are useless to me."
				*set ara_affinity %+15
				${ara_name} smiles broadly. "Just so, Wolf-kin.
			#"Do you really think you can hold me in your web?"
				*set action %+10
				*set deliberation %-10
				"I do not know, Wolf-kin, but it is a very big web.
			#"Spider is fond of her games. Is she not?"
				*set deliberation %+10
				*set action %-10
				"As much as you enjoy the taste of blood, Wolf-kin.
			#"That is fine. I could not trust your prophecy anyway."
				*set hawk_affinity %+15
				"So true, Wolf-kin. So very true.
			#"For the joy of the game itself. Is Spider above such pleasures?"
				*set eel_affinity %+15
				"You are not wrong, ${prenom}. You are certainly not wrong. 
		Anyway, you are better off finding a prophet or prophetess. Someone beloved of Gazelle, who scans the horizon. Or Hawk, maybe, if you can stand humbling yourself before her."
		*page_break
		*goto ara_reaction_2
	*disable_reuse #Ask about the dream.
		*set no_question true
		You tell ${ara_name} about your Wolf-dream. You stress the unusual nature of a being contacted through a dream. $!{ara_he} listens, for the first time with something resembling seriousness, but in the end ${ara_he} shrugs. 

		"The dreams are usually a communication with our gods, but yours—you say that Wolf usually contacts you through instinct and feeling?" ${ara_he} asks.

		"Exactly."

		"The dream could just be a dream. Or maybe there is some deeper game. I am no priest to go throwing bones in the fire for you, ${prenom}. The best I can do is tell you to seek someone more experienced in the arcane."
		*page_break
		*goto ara_reaction_2
	*if (no_question = false) #"I have no interest in what an agent of the deceiving Spider has to say."
		*goto post_question
	*if (no_question = true) #I have no other questions. 
		*goto post_question

*label post_question
*if ((no_question = false) or ((no_question = true) and (wolf_question = false)))
	As you walk away, ${ara_name} calls after you. 

	"You should know, Wolf-kin, that your patron-god is dead and gone. I know you can feel it and see it in the stars, just like I can. I cannot tell you who or what is responsible, but I am curious. What will you do next? No one has ever been released from the grasp of the gods. At least not without significant bloodshed. What will you make of yourself now, ${prenom}?

	"If it were me, I think I would find a prophet, someone whose business it is to pry into the celestial mysteries. One much beloved by Gazelle whose gaze is fixed firmly on the horizon. Maybe someone like that could help you? But, who knows…"

	You turn around and ${ara_name} is gone. 
	*goto after_spider
*else
	You part with ${ara_name} having learned what you wanted to know, but can you entirely trust the source of your information?
	*goto after_spider

*label after_spider

The goddess Spider is known for playing games of calculation, manipulation, and deception, but whether you trust her or not, what her flesh and blood emissary is saying has an element of truth. You can feel the difference for yourself: Wolf is dead. If not dead, then gone somewhere you cannot follow, nor perhaps would you want to. 

Your next goal must be the steppe. ${ara_name}'s less-than-subtle insinuation that you need a prophet's aid is not incorrect. Though it is said that all the gods can glean snatches of likely futures, Gazelle and Hawk are particularly gifted with presentiment. Hawk keeps such revelations to herself, but kind-hearted Gazelle could be persuaded to share them. So you leave the inn with the intention of moving south, toward the boundless steppe 
*if tribe = "Highwalk"
	that you call home.
*if tribe != "Highwalk"
	which is vast and unlike any other place in the world. 
*page_break

Ishko, which was relatively sedate the day before, is now vibrating with activity. There are men and women running every which way and some commotion near the settlement's front gate. You consider whether to go investigate, but before you can make a decision, someone casually slips their arm under yours. ${ara_name}'s slick grin greets your inspection.  

"A storm brewing in this sleepy little hovel? We should find what is the matter."

There are pockets of Ishkoans gathered around the central square watching the approach of a large group of armed and leather-armored newcomers.  

*if recognize_rising_sun
	You recognize them as belonging to the Rising Sun group before you even see them. Their smell—beaten leather, traces of blood, and sweat—discloses their identities readily enough. The stylized sunburst branded on their tunics merely proves the point. 
*if recognize_rising_sun = false
	"The Rising Sun or Risers, more colloquially," ${ara_name} whispers. "A group outside of the magnanimous tutelage of the gods, which subtly and correctly guide all our lives. Risers are heathens of the worst sort, but that does not mean they are exactly powerless, does it?"
*comment endif

The Risers, some of them riding horses and others on foot, march down the center of town and stop just paces away from where you are standing. 

One of them calls the halt and climbs down from his horse.
*if gellas_reoccurs
	*set r_captain "Gellas"
	You recognize him from the forest; his name is Gellas. He sees you and 
	*if riser_affinity < 50
		scowls.
		*goto riser_meeting
	*elseif riser_affinity = 50
		nods his acknowledgement.
		*goto riser_meeting
	*else
		waves you over.
		*goto riser_meeting
*elseif risers_spelled
	*set r_captain "Gellas"
	You recognize him as Gellas, the leader of the Risers you encountered in the forest, but he does not recognize you. The ritual you worked with Eel's assistance has apparently held.
	*goto riser_meeting
*else
	*set r_captain "Vesul"
	He is tall and his expression grim. One of his coterie asks, "Vesul, should we scout a place to camp beyond the walls?"

	"No," their leader replies. "We will not be here long."
	*goto riser_meeting

*label riser_meeting

*if riser_affinity > 60 
	"I see you came to Ishko. I hope they have treated you kindly," ${r_captain} shouts in your direction.

	*if tribe = "Clearwater"
		"They have," you reply. 
	*if tribe != "Clearwater"
		"More or less," you reply.
	*comment endif

	"Good. Good," he says. "I would prefer we were meeting under better circumstances, but the order has come, and Ishko may no longer be the safest place for you to be. I am sorry you have walked into turmoil."

	"What is the trouble?" ${ara_name} asks, still standing at your side. 

	${r_captain} looks at ${ara_him} for the first time. He hesitates, but eventually explains the situation. 

	"The Rising Sun has been attempting to negotiate with Ishko for some time about the rivers and fertile land between this settlement and a number of nearby Rising Sun encampments. We have only just begun to settle in this far north, but—" ${r_captain} spits, "—the Ishkoans have resisted sharing even one parcel of their land with us. They cite ancient and spiritual dominance, using potential retribution from angry gods to scare us away. Our encampments will not survive through the coming winter without securing additional provisions. They have set the stage for a serious disagreement between us.
	
	"Though…you are
	*if tribe = "Clearwater"
		Clearwater, too, are you not? 
	*if tribe != "Clearwater"
		an outsider. 
	If you could speak to them, try to make them see reason and avoid potential bloodshed. We would be indebted to you."

	*label diplomacy_options
	*choice
		#"I will speak to them on your behalf."
			*goto diplomacy_continue
		#"Perhaps you should reconsider your position and leave this town alone."
			${r_captain} rakes a hand through his hair. "I would love nothing more than to leave this stinking place far behind me, but the Ishkoans overplay their hand. They claim rights to land they cannot reasonably defend or possibly need. My people need this land as well, and we are not afraid to fight for it.

			"So will you help us reason with the Ishkoans or not?"
			*choice
				#"I cannot. This is your mess to clean up. Not mine."
					*set riser_affinity %-10
					*set restraint %-5
					*set riser_difficulty ((influence * 2) + (combat + survival))
					${r_captain} lets out a long sigh, as if the weight of your words have pressed it out of him. 

					You feel a bit of difficulty yourself. As much as the wolf in you would have loved to tear the Risers apart, you have refrained, and the unspilled blood extracts a toll from your restraint. 

					*if riser_difficulty >= 28
						*label risers_intimidated
						*set riser_conflict true
						${r_captain} squeezes the bridge of his nose and closes his eyes for a moment before returning his gaze to you. 

						"My people will suffer needlessly because of your decision here today. I hope you understand that."

						He hesitates. 

						"But I will not fight you. Not without a more suitable force behind me."
						*page_break

						*label ishko_thanks
						*set ishko_aid true
						As ${r_captain} and his soldiers leave Ishko, the members of the settlement watch hopefully. When it is clear they have gone, the Ishkoans are visibly relieved, but your presence does not entirely set them at ease. 

						One of them approaches you. 

						"Thank you, stranger. We appreciate you interceding on our behalf. Who knows if they will be back, but each battle we do not fight helps make our community that much safer."

						You accept his thanks, but refuse further considerations. You have spent long enough in Ishko.
						*page_break
						As you go to leave the settlement, you are stopped by ${ara_name}. 

						"Savior of the downtrodden! What a soft-touch you are, ${prenom}," ${ara_he} says. 

						*if restraint < 35
							"Go spin your damned web elsewhere, ${ara_name}," you tell ${ara_him} with a growl.

							The sudden flash of irritation seems to come out of nowhere. It is not necessarily a cause for concern yet, but you make a note to keep an eye on your temper.

							"At last we see some of that fire. Where was that when you were dealing with the Rising Sun?"

							${ara_name} shrugs.
							*goto post_restraint_check
						*else
							You do not rise to ${ara_his} bait, and ${ara_he} pouts sarcastically.
							*goto post_restraint_check

						*label post_restraint_check 

						"Well, there will always be more chaos to incite. Not to mention livelier places to do it. I assume you are headed to the steppe?" ${ara_he} asks. $!{ara_he} gives you an inscrutable smile. "Of course you are, and I hope that all kinds of opportunities for trouble await you, ${prenom}."

						Before you can consider whether or not to do violence against ${ara_him} or ask what ${ara_he} means, ${ara_he} laughs and walks away. 

						You do not follow. You have your own places to go. 
						*goto continue_1
					*else 
						*label risers_unintimidated
						"We will not be leaving. Farming and fishing rights are the difference between death and survival this far north. If it means anything, though, I am sorry about what comes next."

						*goto pre_riser_fight_with_text
				#"I will, because otherwise it will mean more death."
					*set sensitivity +5
					*set bear_affinity %+15
					"Good," ${r_captain} says. "I am glad you have seen reason."

					*goto diplomacy_continue
				#"If it will benefit me."
					*goto bribery
		#"Would it not be wiser to just take the town unawares?"
			${r_captain} squints at you, as if to gauge your seriousness.

			"That would be beneficial to the Rising Sun cause, but given the size of the town and the number of able-bodied persons, difficult. Unless we had help." He looks at you, and asks, "are you serious about this?"
			*choice
				#"Yes. We will take Ishko by force."
					You address the gathered Ishkoans. 

					"This settlement is no longer yours," you tell them. "This is simple. Do not make it difficult."

					*goto ishko_force
				#"Maybe attacking outright is not the wisest course of action. We should reconsider."
					An expression crosses ${r_captain}'s face that takes time for you to place. Something like relief. 

					"Yes," he says. "A different way. So will you talk to them then?"

					*choice
						#"Yes, of course."
							*set riser_affinity %+25
							*if tribe = "Clearwater"
								*set tribe_multiplier 2
							*label diplomacy_continue
							*set ishko_diplomacy (influence * tribe_multiplier)*2
							You approach the gathered Ishkoans with ${r_captain} and the other Rising Sun faithful following at a measured distance.

							"Who will speak for Ishko?" you ask.

							Some of the Ishkoans tighten their fingers around makeshift weapons. 

							The man who pushes his way to the front of the crowd does not offer his name or much in the way of greeting. Instead he points a finger at ${r_captain}.

							"So the conquerors approach. You eye our land with greed and covet what the gods themselves have given us. We have seen in the eyes of the Hawk who wheels above us what will become of those who fall under your sway. We reject your offer before it slips out of your snake's tongue.

							"But you, outsider, we do not know what to make of you. Will you throw in with these monsters, or will you find your sense and leave their side?"

							*if ishko_diplomacy >= 5
								He grunts, nods, and waits for you to speak.
								*label immediate_diplomacy
								And just like that, you have been given an opportunity to influence the future of relations between the Rising Sun and the Clearwater settlement of Ishko. Will you encourage harmony or incite chaos?
								*choice
									#[To the Rising Sun] "The Ishkoans have staked out this territory. By the laws of gods and men, it is theirs. You should leave. Now."
										*set riser_difficulty ((influence * 5) + combat)
										*if riser_difficulty >= 19
											*goto risers_intimidated
										*else
											"Unfortunately, I do not think that is how this is going to go," ${r_captain} says.

											*goto pre_riser_fight_with_text
									#"[To both groups] "There is no reason, aside from ignorance, why both Rising Sun and Ishkoans cannot share fishing and farming rights in this area." [Encourage cooperation]
										*if ((((sensitivity + ritual) >= 24) and (influence > 1)) or (((quickthinking + survival) >= 24) and (influence > 1)))
											*check_achievements
											*if not(choice_achieved_ishkopeace)
												*achieve ishkopeace
											*set riser_ishko_cooperation true
											*set pantheon_regard +1
											*set ishko_aid true
											The Ishkoans are slow to hear your words and almost too wary to heed them, but something in your tone or bearing brings them around. 

											The Rising Sun soldiers shift awkwardly as the negotiations commence, but ${r_captain} is the very picture of a diplomat. He argues firmly, but never forcefully for the sharing of land rights among Ishkoans and their neighbors, the burgeoning Rising Sun encampment.

											The negotiations remain tense for some time, but they proceed without outright animosity, which is a good sign. 

											You realize after an hour or so that you are no longer needed. The threat of violence has passed. You prepare yourself to move on, but first ${r_captain} catches your eye, and mouths, "thank you," before returning to the negotiations.

											You have managed a difficult negotiation, which required a quick mind, a deep understanding of people, and an authoritative air. Going forward, which of those skills would you like to cultivate? 
											*choice
												#Wit and Mental Clarity.
													*set quickthinking +15
													*set sensitivity +5
													*goto upgrade_choice
												#Understanding and Sensitivity.
													*set sensitivity +15
													*set influence +1
													*goto upgrade_choice
												#Influence and Authoritative Presence.
													*set influence +2
													*set sensitivity +5
													*goto upgrade_choice
											*label upgrade_choice

											Satisfied with your work in Ishko, you start to move on. 
											*label ara_interrupt_flow
											*page_break
											On your way to the edge of town, you find ${ara_name} waiting for you. $!{ara_he} is casually watching two children struggling at fetching water from a well, but ${ara_he} does nothing to help. 

											*if riser_ishko_cooperation 
												"They are like those children, are they not? Struggling with things bigger than their little hands can wrap around," ${ara_he} says, watching the children awhile, before continuing, "but it is not our job to shepherd them. Only to observe, to occasionally dispense some cryptic wisdom. To amuse ourselves. Hopefully you learn that lesson before the steppe. But I have never had much use for hope."
												*goto ara_text_continue
											*else
												"Have you learned a lesson? They cannot be tamed, nor can they be helped. We can only trust them to amuse us with their foibles and occasionally devise new and interesting ways to slay each other. That is what they exist for. Like those children, they struggle, but there is nothing in the end but waste and ache.

												"But you know that deep down and this life of ours will find plenty of opportunities to reteach that lesson," ${ara_name} says. 

												"Head to the steppe, I promise it will be worth your time," ${ara_he} adds.
												*goto ara_text_continue
											*label ara_text_continue

											You leave ${ara_name}, watching the children struggle with the bucket between them. And as much water as they slosh onto the ground, they end up with more than enough in their bucket. And perhaps that is something. 
											*goto continue_1
										*else 
											The negotiations begin earnestly, but it quickly becomes apparent that the frustrations and tensions between the Rising Sun and the Ishkoans go deeper than you anticipated. 

											The situation teeters on open fighting, but it never turns into the bloodshed you are anticipating. 

											The Ishkoans demand that you and the Rising Sun both leave their settlement. It does not look like the Rising Sun soldiers have any intention of doing so, but eventually ${r_captain} relents and calls his soldiers off. 

											"I knew they would not accept. Now we have to do this another way," he says, somewhere in between confiding in you and talking to himself.

											You part with the Risers and head out on your own. 
											*goto ara_interrupt_flow
									#(To the Ishkoans) "You have no true rights to this land besides the supposed favor of gods, which in the world of men is less than nothing."
										*label ishko_force
										*set ishko_diplomacy ((influence * 5) + (combat + riser_affinity))
										${r_captain} edges in behind you to emphasize to the Ishkoans exactly how grave their situation is. His armed soldiers help punctuate the threat. 
										*if ishko_diplomacy >= 85
											*set riser_affinity %+15
											*set ishko_occupied true
											The Ishkoans are surly and understandably frustrated by having a new order imposed on them against their will, but the transition is bloodless. 

											${r_captain} and his men spread out to quickly quash any spark of dissent before it ignites, leaving you free to go. 
											*page_break
											*goto ara_sun_mockery
										*else 
											*set restraint %-5

											The Rising Sun soldiers are well-trained, you can see it in their bearing and the way they subtly shift into combat readiness. 

											But when it becomes apparent that the Ishkoans will not relent and that it will come to blows, you perhaps overestimate the efficacy of ten fighting men and yourself against an entire settlement full of zealous civilians with something to fight for.

											The Ishkoans might be untrained, but they are crafty. Living on the fringes of civilizations has taught them a few tricks to protect themselves. They come in waves, forming a pincer so that you and the Rising Sun are fighting on multiple fronts. And you are steadily losing ground. 

											${r_captain} calls for a retreat, and the Ishkoans slowly push back against you, pushing you through the streets until the walls are in sight. A few of the Risers break for the walls while others hold off the Ishkoans. Through a haze of exhaustion, you reach into your reserve of animal strength and fight harder for the minutes it takes to secure your own exit. 

											Eventually you make it out of Ishko. 

											The power struggle having failed, you see no reason to further work alongside the Rising Sun. They gather outside of Ishko's walls and lick their wounds and you look forward. You have other concerns, and so you move on. 
											*page_break
											*goto ara_rock_mockery
									#"The strong must claim the land and water, if only to protect the weak who cannot do it themselves. Perhaps we should find out who is stronger here." [Purposefully sow discord & chaos using your wits and commanding presence]
										*set riser_difficulty ((influence * 9) + (quickthinking))
										*set ishko_diplomacy ((influence * 9) + (quickthinking))
										*if ((riser_difficulty + ishko_diplomacy) >= 65)
											*set chaos_score +1
											*set selfishness %+10
											*set equity %-10
											*set restraint %+10
											${r_captain} and his Rising Sun soldiers move into formation so gradually that even you barely notice, but the Ishkoans are also readying themselves for a confrontation. When the violence erupts, it comes all at once. 

											*label riser_ishko_brawl
											Both sides rush at each other, leaving barely any room to consider you or your involvement in their struggle. 

											At the end of the fight, the Rising Sun soldiers are as bruised and battered as the Ishkoans who fought hard to repel them. Neither side is truly victorious, and the Rising Sun eventually limp away from the center of Ishko as the few Ishkoans who can still stand upright follow at a cautious distance. 

											While the two groups continue their standoff, you quietly leave them to their conflict. 

											*page_break

											As you sneak out of the settlement, you encounter ${ara_name} sitting atop the fence you are about to jump over. 

											*if ((riser_difficulty + ishko_diplomacy) >= 65)
												"This is how I know we were always meant to be close, ${prenom}. Because you are just as much trouble as I am. A mad wolf in the chicken coop.

												"Bring that keen sense of chaos with you when you go to the steppe, and maybe we will rewrite all the rules together some day," ${ara_he} says.
												*goto end_ara_talk
											*else
												"Not the most elegant plot I have ever seen, but you are not exactly a dull blade, are you? You entertain me, and that is not easy to do.

												"I hope you continue to entertain me. Go to the steppe for now. Someday, we will continue to spread our unique brand of mischief. Surely you want to," ${ara_he} says.
												*goto end_ara_talk

											*label end_ara_talk

											$!{ara_he} lets ${ara_him}self fall backward off of the wall. When you hop atop the wall yourself to scan the other side, ${ara_he}'s gone. 

											You follow ${ara_his} example and head over the wall, and out of Ishko.
											*goto continue_1
										*elseif ((riser_difficulty + ishko_diplomacy) >= 50)
											*set selfishness %+5
											*set equity %+5
											*set riser_affinity %-10
											Maybe if you were a little more clever as a schemer your plan could have gone off without a hitch, but the Rising Sun quickly catches on to what you intend to do. Nevertheless, they cannot stop you because the Ishkoans are already riled up. 

											*goto riser_ishko_brawl
										*else
											*label vs_risers_ishkoans
											*set riser_affinity %-15
											*set restraint %-5
											After a moment of tension, the Ishkoans and the Rising Sun soldiers seem to come to a near simultaneous conclusion. They turn on you, instead of each other. 

											Perhaps you could take the Rising Sun, well-trained though they are, or perhaps you could take the Ishkoans, though they outnumber you ten times over or more. But you certainly cannot take both. 

											Your ruse having failed, you manage to just hold off both groups as you dodge, leap, and crawl toward the edge of the settlement. 

											"Block ${his} escape!" ${r_captain} shouts. 

											An Ishkoan dives for you, but you tap into Wolf's instincts and somersault backward out of his reach. A Rising Sun soldier tries to skewer you as you land, but another bit of Wolf keeps you ahead of the blade. 

											At the edge of town, you spring up onto the low roof of a nearby shack and from there vault over the wall at the edge of Ishko, flying free of the settlement all at once.
											*page_break
											Your landing could be smoother. You bruise both your shins, and the pain vibrates up into your teeth, but you manage to keep moving. Thankfully, neither the Rising Sun nor the Ishkoans follow you past the edge of town. 

											You hope it is because they are busy killing each other.

											*label ara_rock_mockery
											Nearly a mile out you find ${ara_name} stretched out serenely on a large rock. Sunning ${ara_him}self presumably. $!{ara_his} eyes flicker open as you approach. 

											"So that did not go well, eh? Do not worry, some of us are born schemers and some…" ${ara_he} trails off intentionally.

											You keep walking. 

											"Go to the steppe. Maybe you will learn something about making the world bend to you," ${ara_he} shouts after you. 
											*goto continue_1
									#Signal to the Rising Sun to attack while the Ishkoans are still expecting to parley.
										*if riser_affinity < 55
											*set action %+10
											*set deliberation %-10
											*set riser_affinity %+15
											The Ishkoans do not expect a full-on attack in the middle of a parley so they are easy to take. 

											The element of surprise exposes their already lackluster combat training. If feels almost wrong to subdue the town with so little effort, but even the paltry fight the Ishkoans put up is enough to get your blood racing. 

											Between you and the Rising Sun soldiers, the Ishkoans fall without significant difficulty. 

											After the last of them have been secured, ${r_captain} turns to you and extends a hand, which you take in a friendly embrace. 

											"Thank you for helping us. You kept anyone from getting seriously hurt by acting so quickly. And trust me, we will not mistreat the Ishkoans. Though perhaps now they will take our entreaties a little more seriously going forward."

											${r_captain} passes a few more words with you before one of his soldiers requires his attention. Following that, you begin leaving the settlement, your business in Ishko is finished. 

											As you leave, you note the angry, hopeless, impotent glares of the Ishkoans who kneel in the dust. 
											*page_break 
											On your way to the edge of the settlement, ${ara_name} walks up beside you and matches your pace. 

											"Fast friends with the Rising Sun? Who knew such beauty could grow from such thorny ground," ${ara_name} says. 

											"And by that you mean?" you ask. 

											"The avatar of a slain god befriends members of a group openly hostile to the rule of gods. Strange. I would say to be careful. But what good has ever come of listening to a spider?" ${ara_name} says, adding, "but that is what I like about you, ${prenom}. I see a lot of surprises coming from you down the line. Whatever happens, I think your actions on the steppe will continue to make things interesting."

											${ara_name}'s next footfall never lands. You turn and ${ara_he}'s gone. You shake your head and continue on.
											*goto continue_1
										*else
											*goto vs_risers_ishkoans
							*else
								*set ishko_difficulty (riser_affinity + combat) - 40 
								He regards you and the band gathered behind you, then he turns away and the Ishkoans attack.

								*if ishko_difficulty >= 20 
									*set death_toll +1
									*set singular_death "ishkoan"

									The Ishkoans are angry, but disorganized. They lack the discipline of a trained militia and as they come at you and the Rising Sun band, you can easily see the weaknesses in their attack. The vanguard is practically tripping over itself, slowing those behind them and allowing you and the Rising Sun, united for the moment, to easily adopt a defensive position and corral them. 

									It is a short fight. 

									When it is all over, the Rising Sun soldiers detain those among the settlement members who are still spoiling for a fight, while ${r_captain} stands next to you and surveys the scene. One Ishkoan was killed and one militia member injured. 

									"It need not have come to this," ${r_captain} says. "Still, there is no question we will take the fishing and farming rights now that blood has been drawn. Thank you, by the way, for supporting our efforts." 

									Whether you intended it or not, your actions have helped change the course of Ishko's future. With ${r_captain}'s gratitude, you start to leave Ishko. 
									*page_break

									On the outskirts of the settlement, you encounter ${ara_name} whispering into the ear of an Ishkoan who stares blankly at the sky until ${ara_name} pulls away. The Ishokan shakes his head and walks away dazed. ${ara_name} smiles in your direction. 

									"Hail the conqueror! Subduer of country yokels and victor against the insignificant," ${ara_he} says. 

									You do not bother mentioning that the Ishkoans attacked first. You keep walking. 

									"I hope you intend to take that sense of chaos and turmoil to the steppe. If ever there were a people in need of a little shaking up."

									${ara_name} smiles brightly and watches you walk away.
									*goto continue_1
								*else
									*goto continue_1
						#"Perhaps. If you make it worth my time."
							*label bribery
							*set riser_affinity %+5
							*set selfishness %+10
							*set equity %-10
							"I would have been surprised if this did not come down to bribery. It is something of a relief to know that we think the same," ${r_captain} says. "We can offer you a scroll that is my keeping. It describes hidden lore of your gods who live in the stars, I had thought to destroy it, but it can be yours. Or I can give you combat training. You are formidable, I am sure, but who does it hurt to learn a little more?

							"So what will you choose?"
							*choice
								#The ritual scroll: I want to improve my understanding of the lore of my gods.
									*set scroll_possession true
									${r_captain} hands you the scroll, and the weight of it alone in your hands feels significant. You remind yourself to find time later to devour the information therein. 

									*label pre_diplomacy 
									But for now you have a peace to broker.

									*goto diplomacy_continue
								#The combat training: I want to strike harder.
									*set combat_training true
									${r_captain} purses his lips and shrugs out of his heavy armor. He walks you through a few combat drills. You can imagine him showing them to Rising Sun trainees. But you are no one's trainee. 

									You pick up the moves quickly. They lack the fluid grace and animal fury of your own fighting style. However, you can see how they would be effective, especially when used as a group. 

									You promise to make time later to fully deconstruct the movements. 
									*goto pre_diplomacy
								#"None of these options are adequate. Offer me something more."
									${r_captain} frowns. 

									"I was so hoping you would not give in to greed."

									*goto pre_riser_fight_with_text

						#"If you cannot take the town alone, then leave with your tails between your legs."
							*set riser_affinity %-15
							${r_captain} is momentarily taken aback by your bluntness. Anger quickly follows. 

							"You have a high opinion of yourself, ${prenom}, to speak to me with so little respect. However, you are not wrong." He straightens his already erect posture. "Will you stand aside and let us take Ishko?"
							*choice
								#"It is yours…if you can take it."
									*set riser_affinity %+10
									*set action %+10
									*set deliberation %-10
									${r_captain}'s mouth twists wryly, he says, "I said it would be difficult. But you will find I am not easily daunted."

									${r_captain} and his militia, with the sun-burst of their cause emblazoned on their chests, step out to meet the Ishkoans head-on. 

									The fighting turns ugly quickly. The Ishkoans are untrained but have the benefit of numbers, while the Rising Sun boast superior weaponry and fight with an impressive single-mindedness.

									In the end, the Rising Sun claw out a victory, leaving broken and cowed those Ishkoans who chose to fight. 

									"From this moment forward," barks ${r_captain}, whose blood runs freely from a gash in arm. "This settlement is under our protection and guidance. Piss into the wrong pot, and I swear you will regret it."

									The Rising Sun busy themselves subduing the Ishkoans who opposed them, and you are already moving on.

									*page_break
									*label ara_sun_mockery
									At the gate of Ishko, ${ara_name} sits on the dusty ground, braiding and unbraiding thin strands of colored silk into ${ara_his} hair. $!{ara_he} looks up at you and squints against the sun. 

									"The sun can be so annoying. Always in one's eyes. Making things uncomfortable. So presumptuous. Ah, well, what is to be done?" ${ara_he} says.

									$!{ara_he} stands and brushes ${ara_him}self off. 

									"If I were you, I would head to the steppe. I always prefer the climate there. Hopefully, you will have a little fun there. Without your new friends."

									Before you can return the barb, ${ara_name} is gone. You wonder as you walk out of Ishko why you do not have the power to appear or disappear at will. 

									*goto continue_1
								#"I have my own plans for this town. Their worship is worth more to me than your sword."
									*label worship_option
									*set riser_affinity %-10
									*set selfishness %+10
									*set equity %-10
									*set ishko_aid true
									*if (((combat * 3) >=riser_affinity) or ((influence * 30) >=riser_affinity))
										${r_captain} grimaces. His soldiers edge forward at your comment, but he waves them back. 

										"This is not worth drawing weapons over," he tells them, then to you, says, "you may live to regret standing in our way, ${prenom}. But for now, Ishko is yours to do with what you will. If you can claim it, of course."

										${r_captain} shouts orders to his soldiers, and they begin to march out of Ishko. 

										That leaves you an entire settlement to bring under your thumb.
										
										With roughly half of Ishko standing before you, you make the pronouncement that for protecting them from the Rising Sun threat, they are now both under the protection of Wolf's living form and beholden to ${him}.

										*if influence >= 2
											*set sensitivity +5
											*set restraint %+10
											*set ishkoans_worship_you true
											The Ishkoans do not get down on their knees. They are too proud and independent for that, but slowly you can feel their quiet gratitude building up inside you. You feel more sensitive to the world now, and you know that they have given you a part of their faith. 

											You carry that faith with you as you leave Ishko, and it makes you stronger.

											*page_break
											*set ara_affinity %+5
											At Ishko's gate you find ${ara_name} waiting for you, grinning brightly. 

											"So you have taken the town's praise for yourself. The valiant, powerful wolf prowling the borders of the settlement and keeping the monsters at bay. I like the idea, but I wonder if you truly mean to protect them or is their worship just another bloody piece of meat for you to chew?

											"You could not possibly mean to be their protector. This is some deeper game."

											*choice
												#"I mean it."
													*set equity %+10
													*set selfishness %-10
													*set ara_affinity %-5
													${ara_name} frowns.

													"How boring. Hopefully, you will be more entertaining on the steppe. The world is in such dire need of entertainment."
													*goto post_worship_question
												#"Faith is power, and I want more of it."
													*set pantheon_regard -1
													*set ara_affinity %+5
													*set action %+10
													*set deliberation %-10
													${ara_name} cocks ${ara_his} head and stares at you. 

													"I applaud your avarice, but be careful not to take too much more than your share. There are other hunters too, and they do not like going hungry."

													Then smiling, ${ara_he} adds, "either way, you keep things interesting. I hope you bring that acquisitive nature to the steppe. I do like watching you work." 
													*goto post_worship_question
												#"I did not mean a word of it."
													*set selfishness %+10
													*set equity %-10
													*set ara_affinity %+10
													${ara_name} laughs and claps. 

													"There is the wolf I want. Merciless and insincere," ${ara_he} says. 

													$!{ara_he} folds ${ara_his} arms, still grinning. 

													"We are going to have a lot of fun together, Wolf-kin."
													*goto post_worship_question
											*label post_worship_question 

											${ara_name} bids you farewell and makes ${ara_his} way out of Ishko. You follow shortly thereafter.

											*goto continue_1
										*else
											*set restraint %-5
											The Ishkoans do not bend their knees for you, despite hard looks and veiled threats. Whatever they might owe you for turning away the Rising Sun, it does not add up to their fealty. 

											It becomes clear they do not even particularly want you among them. You bite your tongue to keep from exploding in anger. After all, the other gods would likely frown on you slaughtering all of Ishko in retaliation. 

											Instead you take a deep breath, draw from your pool of restraint, and leave the settlement. 
											*page_break 
											${ara_name} waits for you outside of Ishko. $!{ara_he} balances a stiletto horizontally between both palms without cutting ${ara_him}self. 

											"Hard to capture hearts and minds, is it not? At least not without adequate force. Well, next time, maybe. And there are always more worshipers to be had. The independent-minded people of the steppe for example, just waiting to be dominated. Are you not excited by the thought?"

											But ${ara_name} and ${ara_his} stiletto are gone before you can reply. Predictably. 

											You walk on. 
											*goto continue_1			
									*else
										${r_captain} laughs.

										"You think these people are going to follow you? Look around."

										The Ishkoans are now staring at you as hard as they are at the Rising Sun. It seems that ${r_captain}'s warm reception has somewhat turned their opinions against you. 

										"But since you are so set on opposing us, let us see what you can do."

										${r_captain} draws his sword and his soldiers follow suit. 

										*goto pre_riser_fight

								#"I am not sure you are worthy enough, so in fact I do intend to stand in your way."
									*set action %+10
									*set deliberation %-10
									${r_captain} draws his sword. 

									"I would have preferred to do this another way, ${prenom}. But I cannot say I am terribly surprised it turned out like this."

									He gestures to his soldiers, and they fan out around him. 

									"We take the town."

									*goto pre_riser_fight
				#"If you are frightened, then perhaps I should take the town for myself. Their worship is more useful than your cowardice."
					*goto worship_option
				*selectable_if ((action > deliberation) and (selfishness >= equity)) #[i]Wolf Path[/i]: "Do you intend for me to repeat myself, Captain?"
					*set riser_affinity %-10
					*set action %+10
					*set deliberation %-10
					*set influence +1
					${r_captain} looks momentarily taken aback, but quickly recovers in order to save face before his soldiers. "The Rising Sun stands ready to do what must be done." 

					"Good. We have a town to take."

					You approach the Ishkoans and calmly explain to them their options. Fight against the Rising Sun with you bolstering their ranks, or submit. 

					*goto ishko_force
*elseif riser_affinity > 45	
	"You," ${r_captain} shouts. 

	You realize he is talking to you. 

	"Can you speak for this settlement? We intend to negotiate, but if no terms can be reached, we are not above taking what we came for."

	*if tribe = "Clearwater"
		Despite the fact that you are Clearwater,
		*goto speaking_for_ishko
	*else
		Considering that you are not even Clearwater,
		*goto speaking_for_ishko

	*label speaking_for_ishko
	you do not actually have the authority to speak on Ishko's behalf, but that need not stop you. 

	*choice
		#Attempt to negotiate with the Rising Sun on behalf of Ishko. 
			You are not Ishkoan, but you are the living embodiment of Wolf, or what remains of him at least. Your impulses are the other thing that rules you. You step forward.

			*goto immediate_diplomacy
		#Refuse to let ${r_captain} intimidate Ishko. 
			"You mean to stand in our way?" ${r_captain} asks. "Really?"

			${r_captain} seems surprised by the notion that you might want to stand against him and his soldiers.

			"Ishkoan or no, you will submit just the same eventually."

			*goto pre_riser_fight_with_text
		#Help the Rising Sun take Ishko. 
			"I somehow doubt this settlement is yours to give away," ${r_captain} says. 

			"No one is going to put up as much of a fight as I would," you reply. "And I am not fighting you."

			"So that just leaves an entire town to take."

			"Exactly," you say. 

			"Then shall we begin?"

			You face the assembled Ishkoans. 

			"This settlement has just changed hands. I would suggest that you allow this to occur peaceably. There is no real need to shed blood here, because if you fight back, you will lose."

			*goto ishko_force
*elseif (riser_affinity < 45) and (riser_affinity > 35) 
	${r_captain} looks in your direction and sneers.

	"You are not among our favorites, I can you tell you that. So tell me, why are you here? Do you intend to stand in our way?"
	*choice
		#"I am going to stop you right here."
			"Oh, good. Let us get truly acquainted then,"

			*goto pre_riser_fight_with_text
		#"Let me help you take the town."
			You politely inform the Ishkoans that, strictly speaking, their settlement is no longer their own.

			*goto ishko_force
		#"Actually, this town, and its worship, is mine."
			*goto worship_option
		#"Ishko is protected by forces beyond your understanding. You will not take it easily." [Use Ritual to intimidate ${r_captain}]
			*set riser_difficulty ((ritual) + (sensitivity + pantheon_regard))
			${r_captain} scoffs at that. 

			"I am not afraid of your mystical nonsense. Protecting spirits that never reveal themselves. Soft-headed tripe."

			*if riser_difficulty  >= 30
				*set ritual +10
				So instead of more talk, you put your threat into action. There are hawks circling above Ishko and it takes a mild adjustment in the bounce of light to create the illusion. Even the small stretch of ritual power makes you gnash your teeth, but you ignore it. Somewhere in the effort of it you feel yourself growing stronger, more comfortable in the realm of mysteries.

				When the Risers and Ishkoans both look up, they see monstrous hawks with enormous wingspans. Their huge bodies blot the distant sun, and their shadows fall wild over the buildings and people of Ishko. 

				The Risers draw their weapons and prepare for an attack, whereas the Ishkoans drop to their knees in prayer. 

				"They delay only because it pleases me. Should I tell them there is a feast of flesh to be had between you and your soldiers?" you ask. 

				${r_captain} manages his fear well, much more deftly than his soldiers, but in the end he breaks. 

				"Swear that those monsters will keep their distance if we leave the village untouched."

				"I swear it."

				And the Risers carefully, watching each other's backs, leave Ishko in tight formation with their eyes fixed on the sky. 
				*page_break
				*goto ishko_thanks
			*else
				You attempt to put fear into ${r_captain}'s smug expression, but when you reach into land, skies, and your own reserves of arcane power, there is not enough to establish a connection. 

				${r_captain} laughs. 

				"Was that it? Now let me show you what I am capable of," he says. 

				*goto pre_riser_fight_with_text
*else
	${r_captain} draws his blade and points it your direction. 

	"So we cross paths once again," he says. "Your gods must be cruel to put you in my way."

	Your reply? 
	*fake_choice
		#"Cruel? To you, certainly."
			${r_captain} laughs abruptly. 

			"Amusing. I wonder if your tongue will be as clever once I remove it from your mouth."
		#"You have one opportunity to put that sword down."
			"Oh?" says ${r_captain}. "How kind of you. I am not offering you any such courtesy."
		#"This does not have to end with you dead, but it will if you do not sheathe that sword."
			${r_captain} blinks at you. "Is that all you have to say? Then here's my answer:"
		#"We should discuss this." 
			"No, I think we have spoken quite enough," ${r_captain} replies.
		#"Pick a fight with me if you must, but leave these villagers out of this."
			"Killing you is just the preface. Afterward, we are going to have a long, fruitful discussion with the inhabitants of this settlement," ${r_captain} says. 
	*comment endif 

	*label pre_riser_fight_with_text
	${r_captain} raises a hand above his head and swings down a closed fist. The soldiers surrounding him prepare their weapons. ${ara_name} folds ${ara_his} arms and watches, while roughly two dozen of the Ishkoan Clearwaters watch the situation unfold from the relative safety of doorframes and behind fenceposts. 

	*label pre_riser_fight
	*set riser_affinity %-15
	*set riser_conflict true
	You have just moments before the Risers strike. How will you defend yourself? 

	*choice
		#Alone and honorably.
			*set riser_difficulty ((combat) + (combat * aran_aid))

			The decision is no decision at all. Even without the savage impulse stirring in your blood, there is more honor and satisfaction in fighting fairly and emerging victorious. You crack your knuckles and step into the brewing fray. 

			*if riser_difficulty >= 20
				*set restraint %+10
				*set influence +1
				Though you have decided to fight fairly, the Risers are beholden to no such promises. They come at you two or three at a time, swinging bladed weapons in tight arcs. They fight in concert and try to corral you, push you into inferior positions, but you dance in and out of their range, frustrating their attempts. 

				Combat is won and lost with patience and so even when your muscles weary of dodging and you take numerous flesh wounds from the Risers's weapons, you still take care with each move and countermove. One at a time, you dispatch the combatants who come against you as the Risers become increasingly frustrated, impatient, and prone to error. 

				${r_captain} looks at you when only you and he remain. All the others lie broken at your feet. 

				"I doubted you," he says. "That was a mistake."

				"Yes. It was," you reply. 

				He lasts longer than the others. He fights more ferociously and with more cunning, but he falls like the others do. Sooner or later, he lies at your feet. The Ishkoans look on in hushed, reverent silence. 

				*label risers_death_choice
				You have fought ten men and women and defeated each of them. You look down at the defeated. If you kill them now, you can ensure they'll never stand up against you again. But the Ishkoans are watching closely, and you cannot tell how they'll react to wholesale slaughter. The decision rests heavy on your shoulders. 
				*choice
					#Kill the Risers. Their continued existence is a threat to the Clearwaters. If they understand that, then there is only one outcome.
						*label clean_riser_deaths
						*set death_toll +10
						*set action %+10
						*set deliberation %-10
						*set restraint %+5
						What follows is clean. Methodical. You end their lives without relish or cruelty. 

						Some of the Ishkoans watch with guarded faces while the others choose to look away. 

						When it is done, ${ara_name} looks over the scene with amusement.

						"I wonder if you will make corpses everywhere you go?" ${ara_he} asks. "Now that you have reddened the soil of Ishko, will you water the steppe with blood as well? I look forward to finding out, ${prenom}."

						${ara_name} walks off and disappears into the encampment, and you turn away from the corpses. You leave them to the discretion of the Ishkoans and head out toward the road.
						*goto continue_1
					#Let the Risers live. Their survival is a concession, but there has to be another way to live beside complete brutality. 
						*label let_risers_live
						*set deliberation %+10
						*set action %-10
						*set sensitivity +5
						*set bear_affinity %+15
						*set risers_live true
						${r_captain} glares. 

						"You would leave us alive, after this embarrassment. After this—" His face twists as he spits the next word. "Defeat."

						"You are no longer my problem. Do not make this worse," you caution.

						"I have the feeling your problems are just beginning," ${r_captain} says. 

						The Risers collect themselves slowly and leave Ishko. You doubt they'll make an attempt on the encampment again and you tell the Ishkoans as much. They do not seem inclined to believe you and after seeing you fight, they do not seem to want you around any more than they wanted the Risers. You decide to leave ahead of any more violence. 

						As you head out of Ishko, you see ${ara_name} sitting on the low wall that surrounds the encampment. 

						"I would have thought you would have killed them," ${ara_he} says, and points out the injured group descending the hills surrounding the encampment. "I wonder if it was wise, leaving them alive. I wonder if their blood was not worth spilling."

						${ara_name}'s voice is ruminative and ponderous, and then suddenly it is not. "Not my decision. But will you be headed to the steppe next, ${prenom}? It is lovely this time of year."

						You go to answer, but ${ara_name} is gone. You shake your head and find the road. 
						*goto continue_1
					#Let the Ishkoans decide whether or not to butcher the Risers.
						*label ishkoans_kill_risers
						You offer the Ishkoans the decision, and they glance about uncertainly as if the choice were too much for them to bear. Ultimately though, they choose. 

						Allowing the Rising Sun to live and continue to terrorize them in the future is a heavier fate than ending the lives of their enemies.

						You spare them the difficulty of having to do the bloody work themselves.

						*goto clean_riser_deaths
			*else
				*set combat +10
				You manage to take down the first handful of challengers, but the fighters are more skilled than you would have thought. Fighting against them gives you a solid challenge and you learn to anticipate their moves and adapt, but as the fight wears on it becomes clear that growing wise to their moves is not enough.
				*label fight_loss_scenario 
				*if riser_difficulty <= 14 
					*set ishkoans_hurt "many"
					*goto continue_fight_loss
				*else
					*set ishkoans_hurt "few"
					*goto continue_fight_loss
				*label continue_fight_loss

				The situation quickly becomes frantic. ${r_captain} calls orders above the shouts, and even though you fight like an animal backed into a corner, you lose ground by the minute. The risers fight in tight order with spears, keeping you at a distance. 

				As it begins to appear hopeless, you hear a shout. 

				*if tribe = "Clearwater" 
					"Protect ${him}! 
					*if gender = "none"
						$!{he} are one of ours!
					*if gender != "none"
						$!{he}'s one of our own!"
					*goto ishkoans_fight
				*else
					"For Ishko!"
					*goto ishkoans_fight

				*label ishkoans_fight
				*if ishkoans_aid
					Your edict echoes through the small encampment, and you do not need to wait until they have joined your side to know that they'll come. The awe and fear of the gods is strong enough to evoke a tangible feeling of power that vibrates in your teeth. You charge forward and set an example of the kind of battle-worthiness you expect from your temporary vassals.

				The Ishkoans pour into the space beside you, flailing with improvised arms: machetes, butcher knives, and only a handful of legitimate swords and spears. They fight admirably considering and manage to slowly, but consistently, push the Risers back to the edge of town.

				${r_captain} orders the retreat, and his soldiers limp toward him, protecting themselves as best as possible against the unexpected assault.

				You can tell the bloodlust is starting to fade from the Ishkoans, but a casual word could still ignite real violence. If the Risers are dead then their threats end here. Do you intend to push the Ishkoans to murder? 

				*choice
					#Yes. As long as the Rising Sun soldiers survive, they are a threat. Killing them all is the only option that makes sense.
						*set death_toll +10
						The Ishkoans hesitate for a moment, and then the bloodshed starts. 

						When it's over, the mob stumbles away from the scene, shedding individuals until only a few dazed Ishkoans remain, breathing hard and regarding the bodies of their enemies. 

						And then even they walk away. 

						${ara_name} plucks a coin purse from one of the recent dead and checks the heft of it. $!{ara_he} smiles, and the purse disappears into a fold of ${ara_his} tunic. $!{ara_he} turns to you. 

						"Now that you have dispensed with that little mess, I will be seeing you later. Hopefully you will take your distinct brand of chaos to the steppe. I do so love to profit from the deceased. They never ask for their coin back," ${ara_he} says.

						${ara_name} walks away and you do not follow. Whatever ${ara_name}'s game, there is little to be gained from playing along. Especially when you have your own imperatives. 

						The Ishkoans 
						*if ishkoans_hurt = "many"
							watch you warily as they tend their wounded and dead. There are people openly weeping on their knees in the dusty lane. They glare at you as you walk by. It is the least you can do to meet their furious stares. 

							None of them makes a move despite the tension so neither do you. You leave Ishko to its fate and take to the road while the sun is still high in the sky.
							*page_break
							*goto continue_1
						*else
							tend to their wounded, who have sustained mostly surface injuries. The mood is not triumphant exactly, especially not with the bodies of the Risers still cooling in the center of town, but the Ishkoans have a grim determination about them. They have successfully defended their young territory. Retaliations might come their way later, but that is a concern for another day. 

							More than one Ishkoan nods in your direction as you leave the encampment and head to the road. No words are exchanged.
							*page_break
							*goto continue_1
					#No. If we slaughter all of the Risers present, the bloodshed will hardly stop there. 
						*goto let_risers_live
					#Let the Ishkoans decide whether or not to slaughter the Rising Sun soldiers.
						*if ishkoans_hurt = "few"
							The Ishkoans grapple with the question and cast looks upon the defeated Risers that range from pitying to withering. Ultimately, the settlement decides that further bloodshed is neither wise nor necessary. 

							*goto let_risers_live
						*else
							*goto ishkoans_kill_risers
		#Alone, employing every dirty trick I know.
			*set riser_difficulty ((aran_aid * 3) + (combat + quickthinking))
			*if riser_difficulty >= 25
				*set survival +5
				Taking the offensive is your best chance, and you take it without hesitation. Whereas others hold tight to their scruples, you have no such issues. You throw a fistful of dust into the eyes of the first Riser you come across and quickly take him off his feet. The next comes at you with a sloppily telegraphed thrust of her short blade, and ends up impaling her own ally. You take advantage of her momentary horror and take her down as easily as the first. 

				The next few are expecting your tricks, so they are a little harder to fight. Luckily you have a few they have not seen yet. 

				From the unnatural way you twist and turn as the Risers come at you, to the animal roar you unleash in their faces; there is no way they can touch you. 

				Afterward, when they are lying in the dust, panting and decimated, you look on, tired but triumphant. 

				Now that they are on their backs, their lives are yours. Kill them or let them go?
				*choice
					#Kill them. 
						*set death_toll +10
						It is not a matter of honor. As bloodthirsty as the wolf inside you can be, it is not about pleasure either. You kill them because once they are dead they are not your problem anymore.

						${r_captain} is the last to go and defiant to the final moment.

						You leave the bodies for the Ishkoans. It is the least they can do considering that you have eliminated their greatest threat. 

						When it is over, you catch ${ara_name} watching you from the doorway of an Ishkoan residence. $!{ara_he} points at the recent dead. 

						"Seems your friends had a hard time," ${ara_he} says. 

						"We were not close," you reply. 

						${ara_name} grins. "Humor. Bloodshed. You keep things interesting, wolf. Hopefully you will take your interesting perspective to the steppe."

						You start to respond, but ${ara_he}'s already gone. You shake your head and then continue on out of Ishko. 

						*goto continue_1
					#Let them walk away.
						You have to content yourself with knowing that there is no blood on your hands, because gratitude is not forthcoming on the faces of the defeated. 

						${r_captain} eyes you warily when you tell him and his soldiers to leave Ishko immediately. They do so quietly, picking up their broken comrades and limping toward the edge of town. Something in ${r_captain}'s furious gaze tells you that he is not going to take his defeat lying down. But for right now, Ishko is safe, and you are a hero of sorts. But it does not particularly feel that way. 

						The Ishkoans keep their distance, perhaps having seen the extent of the your martial skill, and are now thinking better of close contact. 

						You shake your head and set out, away from the Ishkoans and their quiet gawking. 

						*label ara_mercy_speech
						On the way out of town you see ${ara_name} cleaning ${ara_his} nails with a thin-bladed knife. $!{ara_he} seems to barely notice you, but starts talking once you near ${ara_him}. 

						*label aran_banter
						"Mercy from a wolf? What a wonder the world is," ${ara_he} says.

						"My mercy is all used up now," you reply, and flash a smile. 

						Whether or not your comment was intended as a joke or a threat, ${ara_name} grins and slides the knife's blade against ${ara_his} thumb.

						"You should head to the steppe. A good sense of humor is so rare these days, and those people could always use a laugh."

						${ara_name} waves the knife in a careless hand and walks away whistling. You watch ${ara_him} go and then head out yourself. 
						*goto continue_1
					#Let the Ishkoans decide. 
						*goto ishkoans_kill_risers
			*else
				*set quickthinking +10
				The first few Risers go down easily, but it does not take long for ${r_captain} to begin turning the tide. You get a better sense of the Rising Sun combat tactics, but you are exhausted and battered. 

				*goto continue_fight_loss
		#Use an unpredictable ritual to turn the forces of the earth against the Risers.
			*set riser_difficulty ((aran_aid * 3) + (ritual + sensitivity))
			As the Risers begin to advance on you, you reach into the depths of your experience for a suitable ritual. It would be easier if the stars were out to chart the relationships among the roving celestial bodies, but instead you are forced to rely on your innate knowledge.

			*if riser_difficulty >= 25
				*set survival +5
				The power of ritual is not only in the effects, but in the clear space of its conjuring. You feel a moment of something resembling peace as the power accumulates around you, but only for a moment. That peace tightens into a coil around you and robs you of breath. You keep the tightness, cultivate it, and then the earth leaps forward. 

				The Risers, and anyone unfortunate enough to be standing nearby, are thrown off their feet as the ground trembles and cracks beneath them. The soldiers tumble like straw dolls on the earth turned suddenly temperamental. 

				You catch ${r_captain}'s terror as he slides into a diagonal fissure, clawing for purchase as he falls. 

				A choice emerges as the Risers struggle. You can make a spectacle of your power, revel in the fear and awe that you produce, or perhaps satisfy yourself with merely with rattling them to defeat. Or you can expend less of yourself, destabilizing the ground long enough to let the Ishkoans defend their home. 

				*choice
					#Content yourself with knocking them down.
						*set ishkoans_hurt "few"
						*set equity %+10
						*set selfishness %-10
						You allow the tightness in your chest, like a held breath, to loosen, and the earth's anger subsides. The monstrous tremors cease, and the center of Ishko looks like it has been rent in dozens of places. Any damage to the actual structures that surround the town seems minimal. Luckily for the residents of the encampment. 

						The Risers struggle to their feet, though some of them clearly need assistance to do so. 

						*goto let_risers_live
					#Unleash your full ritual potential.  
						*set death_toll +10
						*set selfishness %+10
						*set equity %-10
						*set ishkoans_hurt "many"
						You press the earth closer. 

						The tightness in your chest flares into actual pain and the force of it nearly doubles you over. The ground ripples beneath one of the soldiers and he sinks, screaming into it like quicksand, but the ground hardens again once he has been swallowed completely. Another woman attempts to vault over a growing chasm beneath her only to find another hole appear at her landing point. 

						${r_captain} curses you and the gods as he tumbles beyond the reach of his allies. 

						When it is done, there is little remaining of the Risers and the ground has become wretched. More than a few homes and other structures have sustained damage, and the Ishkoans eye you with equal parts fear, anger, and suspicion. 

						"The wolf has more than just teeth to recommend ${him}, I see," you hear. 

						${ara_name} stands beside a tall, jagged piece of earth that rose up and impaled one of the Risers, who now stares with blank eyes. ${ara_name} strokes the dead man's cheek and turns to you.

						"You should go to the steppe next," ${ara_name} says. "You do seem to make things interesting, and those people are in such need of a change."

						The Spider avatar walks toward the edge of town merrily, as if the carnage that has just occurred has left no mark whatsoever on ${ara_him}. 

						When you leave as well, you can feel the hard stares of the Ishkoans following you for a long time. 
						*goto continue_1
					#Target the Risers; give the Ishkoans time to fight back.
						*set deliberation %+10
						*set action %-10
						The earth responds to your call, the force you hold in your chest, and the ground trembles with it. 

						You can barely breathe, much less call the Ishkoans to action, but they need little prompting.

						You watch as natural laws are violated: the Risers struggle to stay on their feet, but the Ishkoans charge unaffected by your controlled ritual. The fight ends quickly with the Risers unable to capably defend themselves. 

						When it is over, you attempt to catch your breath, and the Ishkoans promptly remove the Risers from their settlement. 

						As for you, you do not wait around for their thanks. As soon as you can breathe regularly again, you make for the edge of the little village. Grand acts of ritual are rare enough to make people uncomfortable, and discomfort sometimes produces ugliness in people. It is wise to leave before that ugliness is directed at you.
						*page_break
						*goto ara_mercy_speech
			*else
				*set ritual +10
				There is a mechanical sort of knowledge that allows for these rituals—the positions of stars, the moon, the revolution of the burning sun—but there is also a space within yourself that facilitates the exchange of energies, terrestrial and otherwise. When you reach into that space, the power that you need is slippery. Elusive. 

				The Risers surround you, but the earth, which you expected to leap up at your command, is still.

				You fight off the first of the soldiers, but the botched ritual has left you exhausted and stunned. Things look grim until you hear the first shout. 

				*goto ishkoans_fight
		#Command the Clearwaters to fight alongside me in the name of the gods. 
			*set riser_difficulty ((influence * 2) + aran_aid)
			*if riser_difficulty >= 5
				*set sensitivity +5
				*set ishkoans_aid true
				*set ishkoans_hurt "few"
				*goto ishkoans_fight
			*else
				*set influence +1
				*set ishkoans_hurt "many"
				With no less than the authority of the gods behind you, you order the Ishkoans to fight. It does not require much more than a clear, loud voice and a purposefulness that stirs their faith and mobilizes them. 

				The Ishkoans rush to your side and fight, but even given their collective strength, the Risers are still powerful and well-trained. The Risers hold out for longer than you would have imagined. 

				You watch Risers and Ishkoans alike topple in battle while you fight alongside ditch-diggers, butchers, and housewives. 

				${r_captain} falls to a pitchfork in his side, and the Risers are all but defeated, but the price is high. Many of the inhabitants of Ishko suffer serious injuries, though it does not seem that any of them have perished outright. Likewise, the Risers have survived despite their wounds. 

				${r_captain} stares at you while holding his bleeding wound. "So this is what it comes to. I ask only that you make it quick for my soldiers." 

				And you reply: 
				*choice
					#"I am not going to kill you, ${r_captain}."
						*set equity %+5
						*set selfishness %-5
						*set risers_live true
						${r_captain} raises an eyebrow.

						"A poor attempt at humor," he says. 

						"Leave Ishko alone. I would not attempt retribution if I were you," you say. 

						It takes a few moments for him to accept that you are not going to kill him and his soldiers. The ten of them struggle to their feet, propping each other up and alternating glares in your direction. 

						They leave Ishko without another word. 

						The members of the settlement watch the soldiers leave with barely restrained violence in their postures.

						Afterward, you begin to leave as well when ${ara_name} stops you. 

						*goto aran_banter
					#"I can do that. After all, you and your soldiers fought honorably."
						*set deliberation %+5
						*set action %-5
						*label some_dead_risers
						*set death_toll +10
						*goto clean_riser_deaths
					#Say nothing. Slaughter them all. 
						*set action %+5
						*set deliberation %-5
						*goto some_dead_risers

		*disable_reuse #Ask for ${ara_name}'s help.
			${ara_name} raises an eyebrow when you ask for ${ara_his} aid against the Risers. 
 
			"I am not really the type to get my hands dirty," ${ara_he} replies.
			*if ara_affinity >= 55
				*set aran_aid 2

				"But neither I nor my patron-god are exactly known for consistency of character. I will help you."

				$!{ara_he} blinks ${ara_his} long lashes, and you catch those disconcerting other eyes peeking out beneath ${ara_his} sleepy lids.

				"It is done," ${ara_he} declares. "The inhabitants of Ishko have been gently coerced into helping you, and I have sown uncertainty amongst the Rising Sun ranks. You would be surprised how many battles are won or lost on certainty." 

				${ara_name} folds ${ara_his} arms. 

				"The rest is up to you, Wolf-kin."

				*goto pre_riser_fight
			*else
				*set ara_affinity %-10
				"So you will have to figure something else out. You have my utmost confidence."

				*goto pre_riser_fight

*label continue_1
*page_break
It is a long walk before the rolling green hills that characterizes the north begin to flatten out. You stop occasionally to gather water from clear streams and to rest, but then you walk again. You travel south and east, hunting small game in order to supplement your meager rations and living off of the land. 

*if scroll_possession
	*set sensitivity +5
	*set ritual +10
	You find time in the quiet austerity to read through the scroll you obtained from the Riser captain. It contains many notes on the course of the stars and what their positions mean. The text is illuminating and possessively impacts your more esoteric skills, but unfortunately it does not provide any deeper knowledge on the situation with Wolf. You roll it up and keep it in the leather container in which it was given to you before continuing on your way.
*if combat_training
	*set combat +10
	*set survival +5
	You find some time to go through the combat drills that ${r_captain} showed you. The more you practice them, the more you come to a begrudging respect for the Rising Sun battle movements. You learn more than you would think, though you are hardly ready to become a Riser convert. You do learn quite a few useful tricks.

Over the course of several days, then weeks, your path leads you to lower elevation into rocky, broken terrain. Though it raises your hackles and fills your mouth with a bad taste, you are certain that you are going in the right direction. Before you is a fissure in the earth and a slim pass through which you are meant to travel. You look up at the overcast sky and shake your head. 

The gods, unsurprisingly, are silent. 
*finish 
