*text_image chap_1.png center One: Profaned

[i]…and the great white Wolf—who is gracious unless hungry—gave the girl a ride across the river on the soft fur of his back. The girl was careful to cling hard to his fur, because Clearwaters know that the Wolf is always hungry.[/i]
*line_break
-excerpt from an old Clearwater fable.

*page_break Begin

There is green then flashes of hot white. Drums in your ears and thunder in your feet. Then you catch snatches of a conversation; serious talk, accusations, then howling, howling, howling. 

The air is thick and close; are there fire ants in your chest or is that the pain of drawing breath? Are you breathing or is that someone else? Someone close by? You only know for sure that you are running and you are afraid. 

You remember a white field and snow, but you do not recall the cold. In the memory, you know you are not alone, but it is not until you see the enormous shape slinking toward you that you begin to feel afraid. His teeth are as sharp as daggers, and his eyes…

You shake your head and the memory—a very old one indeed—slips away. 

The pain in your chest settles, your breathing calms by degrees, and you start to look around. You are standing on two feet and the deep greenery of a forest floor is all around you. The white flashes from earlier were just the sunlight struggling through the canopy overhead. Your senses return to you after having briefly gone wild. You feel almost silly for the panic, but there is a feeling of wrongness that is persistent. 

You cannot immediately recall what you were running from, but you know yourself and that is a good sign; you are the avatar of the Wolf God. Others have to content themselves with worship, but you are connected directly to the divine presence. At least, you were. At the moment, there is some disconnect; you look at your hands and they are just hands, you cannot feel the feral power running through them. It is confusing and disorienting, but you know better than to dwell. Just because you have managed to calm yourself down does not mean there is nothing in the forest to fear. It makes sense to keep going.

There are several ways you can think of to move forward: 

*choice
	#Use superior ritual knowledge to scan the sky through the canopy and divine my location. 
		*set ritual +15
		The sun is high in the sky and the leaves and branches overhead make your task difficult, but you are skilled in the arcane rites that trace the motions of the heavens. You are able to pick up directional cues where others would only see the glare of the sun and the idle passing of clouds. 

		It is enough to find a path. 
		*goto pre_query_transition
	#Deftly follow animal tracks and water trails through the forest.
		*set survival +15
		Where less practiced eyes would see only the trails of dirt lurking beneath the rotting leaves and upturned logs across the forest floor, you see a map of natural activity. Here there are the skittish steps of deer on the move and elsewhere the deft prints of wolves following quickly behind. You read the living memory of the forest and have little trouble making your way. 
		*goto pre_query_transition
	#Climb one of the nearby trees: From a vantage point closer to the sky, perhaps I can better understand the layout of the ground.  
		*set ritual +5
		*set survival +5
		You scramble up a nearby tree, moving slowly but carefully, swinging higher until you can see clearly around you. Something about being high up relaxes you, even as you survey the land. From this high up, you can also see better through the dense canopy at the sky above, which gives you a sense, real or imagined, of being closer to the gods above.

		Relying on both senses—the high, deep language of the slow heavens, and the frantic, busy tongue of the land—you find your way. 
		*goto pre_query_transition
	#Rely on my natural perceptiveness and intuition in order to find my way.
		*set influence +1
		*set restraint %+10
		You have learned to trust your instincts through long practice, cunning reversals, and bitter disappointments. You follow your whims and trust in the subtle pull of fortune to set you on the right direction. You find this makes you a more charismatic leader and helps to strengthen your resolve in moments where you might otherwise succumb to the pull of baser impulses. 
		*goto pre_query_transition
*label pre_query_transition
*page_break
This deep in the woodland, there are scant signs of human presence beside your own, but you move carefully, regardless. Not every threat has a human face.

The path you forge begins to trigger thoughts, memories maybe, or just associations. The wide trunks and heavily striated bark of the trees around you suggests you are in the north, even though you do not remember exactly how you got here. The last few days and weeks are a haze in your memory and you find it difficult to pluck anything definitive from them, but you can remember the long howling and a searing pain. 

A little way down, you catch sight of a living blur almost too fast for the common eye to track. But you are far from common. 

The stag flees downwind, perhaps after scenting you, or more precisely scenting the part of the Wolf God that lives in your skin. The smell of the animal, rich and woody, makes you realize just how hungry you are. 

Will you give chase? 

*choice 
	#Yes. I am a hunter and the stag is prey; simple.
		*set action %+15
		*set deliberation%-15
		*set stag_kill true
		*check_achievements
		*if not(choice_achieved_firstblood)
			*achieve firstblood
		The stag flees from you in obvious terror. Your heart seems to want to escape your chest, and the feeling goes to your head. 

		You catch up with the stag and it is as if the animal is moving in slow motion. You know you have to be careful, animals that are cornered are the deadliest. But when you throw yourself at the stag and it collapses under you, you work quickly to ensure that it never rises again. 

		Afterward, in the glow of the kill, you take what meat you can get quickly from the stag and leave the rest to the other animals lurking in your periphery, brought by the smell of the freshly dead. You leave the stag's remains for them. A kind of charity.

		You move on.
		*goto post_animal_hunt 
	#Perhaps. If it amuses me.
		*set selfishness %+15
		*set equity %-15
		*check_achievements
		*if not(choice_achieved_firstblood)
			*achieve firstblood
		*set stag_kill true
		You trail the animal with ease, flushing it out further and further. The hunt is the most amusing part, but the kill is satisfying in its own right. It takes strength to kill an animal without a weapon, but only a bit of cleverness to drive it down a precipitous drop. You stand over the stag and finish it decisively once it becomes clear that the chase can go no further.

		You cannot fully dress it down without a blade, but the meal was never the goal. 

		You take what you can and move on.
		*goto post_animal_hunt
	#Perhaps not. I should stay on task and find my way out of this forest as quickly as possible.
		*set deliberation %+15
		*set action %-15
		Though it might be wise to do some hunting and come away with some provisions, there could still be danger lurking around you. The forest provides other means anyway. You watch the stag flee out of the corner of your eye and instead grab a handful of berries and edible leaves, even the grass can be harvested if you get hungry enough. 

		You move on. 
		*goto post_animal_hunt
	#No. The animal deserves free rein and peace as much as I do.
		*set equity %+15
		*set selfishness %-15
		Even though you can claim familiarity with the trees and easily track the motion of the fleeing stag, this forest is not your home and sometimes respecting your surroundings means resisting the urge to interrupt the life cycle of the less powerful. The stag stops running for a long moment and stares at you before some other sound sends it skittering into a thick copse. 

		Instead of stag meat you harvest a few berries and leaves that are safe to eat and then you move on.
		*goto post_animal_hunt

*label post_animal_hunt
*page_break
The temperature wanes along with the sunlight, but even with diminished visibility, you can still navigate via the potent smells where animals have marked their territory and the ever-changing feel of the forest beneath your bare feet. Above you, through the profusion of branches and leaves, is the night sky and its constellations for guidance. 
*if ritual < 6
	Though some of the nuances of the cosmic arrangement may be lost on you, you can still mark out the basics. 
*comment endif

The sky is the gods' playground, where their incorporeal forms revolve around the world either in loving stewardship or jealous watch, depending on the viewer's opinion. But the gods are not always so distant, as you well know. Your first experience of them left a hot brand on your memories, marking you in some subtle way from that moment forward. What were the circumstances of that experience? 

*fake_choice
	#It was when I was taken by Wolf: the god who prefers savagery and action.
		*set action %+10
		*set deliberation %-10
		You were visited before your tenth year by the great white Wolf who walked through your dreams. You needed no further proof of gods or their influence in the mortal world. Nothing more about gods needed to be proved to you, who lived alongside one. 
	#I saw a woman inhabited by Hawk: the goddess who enforces equity and justice. 
		*set equity %+10
		*set selfishness %-10
		Where you grew up, there were two men with a terrible grudge against each other. They argued daily over a number of escalating transgressions. The wife of one man prayed almost daily to Hawk, who ensures impartiality, for an end to their squabbling. In the middle of another one of the men's quarrels at the height of summer, the pious wife was invested with Hawk's presence. A light seemed to infuse her hair and shine forth from her eyes. Though usually soft-spoken, this woman became as chilly as marble and drew a golden, shimmering sword from the air beside her. She sliced down between the two men and declared in a voice like steel before all present that the quarreling would end, or blood would follow. The men never argued publicly again. 

		You still remember that sword. 
	#I was told a story about the children of Spider: the goddess who most loves selfishness and want. 
		*set selfishness %+10
		*set equity %-10
		In a village far from where you were born, it was said that each year a child was born who was marked for Spider's care. One year, the child, born like all years with a weblike caul around the eyes and nose, was refused to Spider by his mother. Sometime later, a host of seventeen children of various ages came to the village. Each of them spoke a single word of a prophesied fate for the village and its inhabitants if the child was not relinquished. A terrible fate.

		In the end, the mother gave over the child. What choice did she have?
	#I learned about the strength of Bear: the god who is deliberate and ponderous. 
		*set deliberation %+10
		*set action %-10
		You were once told by another child, before Wolf came into your life, of his uncle who awoke in the night to his home burning around him. He was choked by the smoke and unable to see. He coughed and drifted close to losing consciousness, but he heard the roar of a bear and realized suddenly that the noise had come from himself. He charged out of the burning structure and safely into the night. He swore that Bear had given him the strength at that last moment when he was near death. 

		The story could have easily been embellished, but it stayed with you for years. 

So you learned about the capricious nature of gods and the lives they touch.
*page_break
The night grows cooler, but even still, sweat slicks your skin. It is high summer, and the longer you walk the more you begin to feel something other than the heat gnawing at you. An emptiness in your head and heart. An echo where your sharpest senses used to reside. You come across a clearing and stop again to rest and find your bearings.  

*page_break
You look up at the sky. 

It is a riot of lights, much clearer in this open space than before when you were snatching glances through the trees. The stars are all bullying and jockeying for position among the long blanket of dark sky. In those celestial bodies are the answers to your heart's questions. You need only look up and find the constellations that represent the gods who hold all mortal knowledge in their mouths. 

*label query_transition_2
*if query_counter >= 5
	*goto wolf_choice
You will have to consult all five constellations before you have your answer, but the vast sky is open to whichever order you choose. 

*if query_counter = 0
	Which will you read first?
*if query_counter >= 1
	Which will you read next?

*label god_query

*comment This section uses a variable to ensure that the player goes through
*comment each option before being able to move on, but allows them to go through
*comment said options in their preferred order. 

*choice
	*disable_reuse #The Hawk Star.
		*set query_counter +1
		The Hawk Star is a bright glimmer in the near-black sky. The single brightest object making its way across the heavens aside from the luminous moon. 

		The star, named after Hawk, the shrewd mother with wings outstretched in glorious flight. The goddess whose eyes are sharp and mind sharper still. This is her star.

		The mother of equity, Hawk judiciously minds the space between the myriad genders. For the benefit of her wisdom and nuance, you need only whisper the gender you prefer to be recognized as into the wind.

		*choice
			#I consider myself female.
				*set gender "female"
				*set he "she"
				*set his "her"
				*set him "her"
				*set man_woman "woman"
				*goto male_female_choice
			#I consider myself male.
				*set gender "male"
				*set man_woman "man"
				*goto male_female_choice
			#I am neither female nor male.
				*set gender "none"
				*set he "they"
				*set his "their"
				*set him "them"
				*set man_woman "person"
				*goto male_female_choice

		*label male_female_choice
		The Hawk star shines indifferently in the distance, but you can feel something is different in your blood. You feel recognized.
		*if (query_counter = 5)
			*goto wolf_choice
		*else
			*goto query_transition_2
	*disable_reuse #The Great Wandering Bear.
		*set query_counter +1
		The Bear constellation is a massive network of embers in the firmament. It feels closer than the other stars, as if you could reach out and touch it. Or as if it could reach down and touch you.

		Bear, the ursine god whose method is patience in all things, is the steadying force whose long memory encompasses all of creation. Bear alone remembers how the profusion of peoples grew out of just a handful of families.

		You will need his long sight to answer your questions. In return, you need only offer him the memory that is in your blood, the memory of your clan. There are the Clearwater, whose hands turned the soil and made bread, the Highwalk who first learned to ride horses and hunt, and the Quietly Swimming, or the Quiet, who never strayed far from the waters they rose from. 

		It is simply a matter of ancestry and blood, but Bear prizes such things. Which clan do you hail from? 

		*choice
			#"I am Clearwater; the first builders to make homes from the bounty of the earth. I am of those who entwine their hair with wooden loops in deference to the trees that made their first homes."
				*set tribe "Clearwater"
				*goto bear_continue
			#"I am Highwalk; the travelers who circumnavigate the placid steppes. Descended from those who first felt the urge to wander further than the limits of their own imaginations."
				*set tribe "Highwalk"
				*goto bear_continue
			#"I am Quietly Swimming; scholars of the southern waterways who hunt both day and night. I am bred from those born to move gracefully, as fluid as the marsh waters that nourish them."
				*set tribe "Quiet"
				*goto bear_continue
		*label bear_continue
		Despite all its massive strength, the great Bear seems calm, ponderous, and protective tonight. It is hard not to feel a bit safer with the Bear looming overhead. 
		*if (query_counter = 5)
			*goto wolf_choice
		*else
			*goto query_transition_2
	*disable_reuse #Writhing Eel.
		*set query_counter +1
		The twisted shape of the Writhing Eel constellation is like a band across the waist of the night, suggesting to the lurid eye the divide between upper and lower, decency and delight. 

		Like its namesake, the constellation is provocative. Eel is the god for whom all roads lead to pleasure and the satisfaction of physical, oft carnal needs. He resides in the heart and the loins, the high places and the low. 

		In order to invoke his aid, you must surrender your wants to him.

		What are your attractions?

		*choice
			#"I am attracted to men," I tell the sky.
				*set attraction "male" 
				*goto sexual_preference
			#"I am attracted to women," I explain to the open air.
				*set attraction "female"
				*goto sexual_preference
			#"It matters not. My blood runs hot," I declare under the heavens.
				*set attraction "bi"
				*goto sexual_preference
			#I have no interest in romance. I am interested in survival.
				You shout to the sky that you will not play Eel's games and in reply you can perceive a quirk of the long, winding constellation.
				*goto post_sex_pref
			#I say nothing. Eel can read into my silence whatever he pleases. 
				*set attraction "bi"
				Silence is an answer as well, and the constellation offers some movement in reply. At least, you think it moves. You think its slight gyration might be a twist of irony or whimsy.
				*goto post_sex_pref
		*label sexual_preference 
		Having told Eel your interests, you see motion in the constellation, a certain tightening of the long band.
		*label post_sex_pref
		Perhaps it is just in your imagination.
		*if (query_counter = 5)
			*goto wolf_choice
		*else
			*goto query_transition_2
	*disable_reuse #The Spider's Skein.
		*set query_counter +1
		The Spider's Skein knits the southwest edges of the night, keeping all within it tied tightly. You find your gaze drawn to its complexities. 

		Named for the Spider, the goddess who revels in the self above all things. Selfish and cruelly cunning, one cannot open a dialogue with the goddess whose favorite toy is secrets without offering one's true name. 

		What is your name? 

		*choice
			#Volk.
				*set prenom "Volk"
				*set name_set true
				*goto name_decided
			#Onai.
				*set prenom "Onai"
				*set name_set true
				*goto name_decided
			#Bvaso.
				*set prenom "Bvaso"
				*set name_set true
				*goto name_decided
			#Ōkami.
				*set prenom "Ōkami"
				*set name_set true
				*goto name_decided
			#Tala.
				*set prenom "Tala"
				*set name_set true
				*goto name_decided
			#Nekra.
				*set prenom "Nekra"
				*set name_set true
				*goto name_decided
			#Bhangi.
				*set prenom "Bhangi"
				*set name_set true
				*goto name_decided
			#None of these.
				*label NameMaking
				What are you called? 
				*input_text prenom
				Ah, then $!{prenom} is your name, yes?
				*choice
					#Yes, exactly as I said.
						*set prenom "$!{prenom}"
						*set name_set true
						*goto name_decided
					#No, you have misheard. It is just a little different.
						*goto NameMaking

		*label name_decided

		"${prenom}," you whisper to the sky.

		In the distance, just between the call of wolves and the nightbirds' songs, you can hear the chirrup of insects. There is something fearful in their calls tonight.
		*if (query_counter = 5)
			*goto wolf_choice
		*else
			*goto query_transition_2
	*disable_reuse #Distant Gazelle.
		*set query_counter +1
		Two sleek, slender shapes leap through the far shores of the eastern edges of the sky. The racing, dodging shapes are Gazelle's aspects. They tend to warm you every time you see them. 

		Gazelle, the tender-hearted goddess whose intentions are generous, is also the goddess whose subtlety and evasiveness makes her the most unapproachable of the celestial figures. She offers kindness, yet takes no sides. Both features represent her; the clever, crafty Gazelle running to the west, and the kind, empathetic one sprinting to the east.

		To which does your eye move? East or West?

		*choice
			#West. To the Quick-Thinking aspect of Gazelle.
				*set quickthinking +10
				*goto gazelle_choice
			#East. To the Sensitive aspect of Gazelle.
				*set sensitivity +10
				*goto gazelle_choice

		*label gazelle_choice

		The longer you stare, the further away the two aspects of Gazelle seem to run from each other. But once you blink, they seem closer again. You get the sense they will never truly converge, but that they are not so far away from each other as you think. 

		You blink again and when the twin constellations reset, you look away. 
		*if (query_counter = 5)
			*goto wolf_choice
		*else
			*goto query_transition_2
	*if (query_counter >= 5) #Only the Wolf remains.
		*goto wolf_choice

*label wolf_choice
*set chara_generation_done true
*page_break
*if ritual > 5
	Having opened yourself up to the wisdom of gods circling the upper skies in their star-bound forms, you feel stronger in your esoteric power. You draw the sigils of each: the Bear's steely claw, the Hawk's far-seeing eye, the Eel's long form, the Spider's complex web, and the gentle arc of the Gazelle's leap. There remains only one god whose aid you have not conjured, whose touch you have yet to feel.
	*page_break
	*goto wolf_choice_2
*else
	You have felt the touch of all five gods on your senses and you feel stronger for it. Their knowledge thrums in your blood and leads to a kind of intuitive wisdom. You need only concentrate on your question long enough in the clear space of meditation. There is only one god left to query. The god whose touch is most familiar.
	*page_break
	*goto wolf_choice_2

*label wolf_choice_2

The moon is the left eye of Wolf, the god who hunts. The moon governs impulse and conflict, weighing both before deciding to bare its teeth or slink away. 

Wolf's animal strength runs through you as surely as your own pulse. Or it did before this night. You are alone in the forest, draped in shadows, and never has the presence of Wolf felt more distant. 

The phase of the moon is the last piece of the sky you need to complete your query.

*choice
	#Prone. The Wolf Moon is at its lowest point, weakening its overall strength, but also greatly lessening its more savage impulses.
		*set sensitivity +10
		*set wolf_moon "prone"
		*set restraint %+20
		*goto wolf_choice_3
	#Rising. The Wolf Moon is partway along its ascendancy, strengthened from its prone state, but also more feral.
		*set combat +10
		*set restraint %+15
		*set wolf_moon "rising"
		*goto wolf_choice_3
	#Hunting. The Wolf Moon is at its highest point, resulting in unrivaled strength, but barely contained ferocity. 
		*set combat +15
		*set restraint %-5
		*set wolf_moon "hunting"
		*goto wolf_choice_3

*label wolf_choice_3
*set wolf_moon_selected true

You arrive at the same truth, regardless of how many times or ways you scry the heavens. The truth remains the same in your gut. 

Wolf is nowhere.

The god who once consumed a part of your heart and bound you forever to himself has defied your covenant. His moon has not fallen out of the sky, and the violent tension in your limbs is proof that he once inhabited you. But Wolf is gone, and without a word to his most trusted disciple. 

*page_break

"The gods live high above us. But they also walk beside us," your
*if tribe = "Highwalk"
	auntie—one of the many women you called auntie as a Highwalk child regardless of blood relation—once explained, as she drew diagrams and pictures in the steppe dirt.
*if tribe = "Quiet"
	tutor in the Quietly Swimming enclave once explained, while keeping one eye on you and another on a pot full of seaweed, boiling with pungent herbs and spices. 
*if tribe = "Clearwater"
	Clearwater grandfather once explained, as the two of you sat peeling the tough root vegetables that grew near the edge of the town. 
"Sometimes the gods choose to take us into their confidence. They see something in an individual that they prize highly, and they might choose to become one with us, to share themselves with us and walk beside us for a moment, a season, or a lifetime. Those who receive this attention and bear this weight we call avatars—sometimes manifestations, or incarnations. All just words. The experience is something else entirely."

This was a lesson from your childhood. You remember hearing it when you were still only just you. What did you feel in that moment, knowing that a god could one day slip into your skin and share it with you? 

*fake_choice
	#Terror.
		Would it be like the stuff of nightmares, you must have wondered a thousand times, to give up control and be ridden by a force beyond your comprehension? Would you feel anything at all? The question would have been like a burning coal in your gut. A terrible possibility lurking at the edge of your thoughts.
	#Exhilaration.
		It could be me, you might have thought, and found yourself up late at night thinking about it. You might have wondered how it would feel to have a god in your flesh and to have been chosen for the honor among a countless number of others. You might have anticipated it. Longed for it.
	#Confusion.
		It is a lot for a child to handle, being told that one day your body, your mind, and everything about you could be altered by an alien presence. It is not surprising that you were confused.
	#Peace.
		Perhaps a part of you always knew that it would be you. That you would be chosen to play host to a god. And if you had accepted it so long ago then all the better. After all, what choice did you have?
	#Indignation.
		You might have been furious. You might have wondered how a spirit without form itself could make demands on your body, could presume authority over your flesh and mind without consent. Even if the words never left your lips, you were angry, and perhaps that anger, that indignation is what made you a target. A fact that might have made you angrier still.

And then you became Wolf's avatar. One night, you awoke in an unfamiliar field laden with snow and saw the white wolf, twice your size or more, stalking across the white earth. He left no prints where his paws fell.

As he drew closer, you could see his right eye, a menacing ochre that made you shiver. In his luminous left eye, like the moon itself, you could see your reflection. You were both hunter and prey. 

You woke up from the dream, if it truly was a dream, sweating and feverish. 
*if tribe = "Quiet"
	The medicine-man
*if tribe = "Clearwater"
	Your grandfather
*if tribe = "Highwalk"
	The caravan healer
could not tell whether you would live or die. When you rose from the fever, you were no longer alone in your mind. Wolf walked beside you. Until today. 

The enormity of Wolf's absence begins to dawn on you. 

Some gods, like Hawk, possess their avatars fully, leaving no room for personality, burning away all that is human in their hosts while making room for their own divine presence. Some gods, like Spider, slip into their avatars like clothes and wear them for a season before leaping to another, preferring to keep their meddling in human affairs as clandestine as possible. One thing is clear—the avatars of the gods are elevated above mundane humans in ways both overt and subtle—some are preternaturally strong, others can draw from the twisting, living spirits inherent within all things through arcane rites, which would take a mere mortal a lifetime to learn, yet others have wits so quick that they can whisper, cajole, force, and manipulate others into doing their bidding. However, despite these gifts, the gods' living emissaries can be felled. 

In the end, Wolf chose you and you alone. The covenant that was made in that cold field was a kind of partnership: Wolf trusted in your judgment and intellect while making his desires and instincts known. The two of you walked in one skin and spoke with one voice.

You do not know, and never thought to ask, whether your skills came from being chosen by Wolf or were the reason he chose you, but you cannot remember a time that you were not capable and powerful in one way or another. 

Wolf chose you, and you were strong. Now he appears to be gone and you can feel the absence in every breath as his living avatar. 

It must terrify you. 

*choice
	#Of course. To be alone after all this time?
		*set restraint %+10
		*set deliberation %+5
		*set action %-5

		Wolf was closer to you than a sibling and more than just a voice in the back of your head. Your skin feels hollow without him, and you vow to find out what happened to him. 
		*goto wolf_question
	#No. There is no room for terror. I must only act.
		*set survival +5
		*set action %+5
		*set deliberation %-5

		Wolf would not waste time mourning you or fretting if you had disappeared. He would act, seeking answers surely and meting out justice deftly. If you and he are as one, it is obvious what you must do. 
		*goto wolf_question
	#Terrified? I am elated. I have my body and mind to myself again.
		*set quickthinking +5
		*set selfishness %+5
		*set equity %-5

		Wolf entered your body without permission and took your inability to fight him off as complicity. Though he is gone, his strength still resides in your limbs. Perhaps you will avenge him with that borrowed strength. Perhaps. 
		*goto wolf_question
	#Wolf's absence may invite others to target me. If that is the case then let them come.
		*set combat +5
		*set action %+5
		*set deliberation %-5

		When there is a vacuum in the hierarchy of dominance, others will seek to enter it. This is a law of the natural world. You will have to prove yourself capable of defending the spot that you and Wolf have carved out on the food chain. You feel more than up to the challenge. 
		*goto wolf_question
	#I worry that without Wolf I will not have the strength to do the good I wish to.
		*set sensitivity +5
		*set equity %+5
		*set selfishness %-5

		Wolf gave you a great many gifts when he came into you. You can still access some of them, but you worry that his ancient wisdom is lost to you. Your path forward may be harder to walk, and that is worth worrying over. 
		*goto wolf_question
	#I am concerned that my connection to the divine has been severed.
		*set ritual +5
		*set deliberation %+5
		*set action %-5

		Wolf helped you to access the deeper mysteries of the world. Without his aid, it's possible that this connection will be damaged. You will have to work harder to ensure you remain connected to the power that once came so easily to you. 
		*goto wolf_question

*label wolf_question
*page_break

You know that many more questions will follow later: What has happened to Wolf? What will it mean for you? But for now, you are alive, and perhaps you ought to stay that way.

You continue on, out of the clearing and back into the woods, but with a renewed sense of direction and some small inkling of your situation: You are no longer under the Wolf's direct protection, but his instincts still live within you and your own human skills are formidable. From the day of your visitation on that snowy field, you have been training your body and mind to be the keenest edge for Wolf to share. Your days were filled with challenges that taught you to embrace the feral side of yourself, while honoring your human intelligence. Unlike other gods, Wolf keeps no priests. His acolytes seek to embody his violent whims but they have no direct guidance; you are the closest thing to worship in his name. At least you were. 

Another hour into your travels and the spacing of the trees begins to loosen, growing further apart and allowing easier traffic. A little later, you spy evidence of human habitation. There are long-downed trees with the best, driest part hacked off and sectioned up, presumably for firewood. You encounter rudimentary paved pathways. You advance with caution.

Sniffing the air, you can tell there are other people nearby, probably three or more, and they have started a fire. Before long, you see a glow that strikes you as foreign to these parts.

*if survival > 5 
	You have no trouble keeping quiet as you approach the fire before you.
	*goto first_encounter
*else
	You watch your feet and try not to draw attention.
	*goto first_encounter 

*label first_encounter
*page_break 

Eventually, you close in and hear what sounds like voices raised in argument. 

"—no right to be here!" you overhear, then, "—will not warn you again."

The voices lead you to a natural drop above a dilapidated stone structure, a squat and fairly garish temple.
*if sensitivity > 5 
	You notice the dark whorls painted on the outside of the temple. They suggest a temple consecrated to the god Eel. Perhaps you ought to be careful, knowing that there might be a god closely watching the outcome of this conflict. 
*comment endif

Below, you see the people to whom the voices belong. There are four people in tattered leathers, three men and a woman. Two of them are armed and the others bare-handed, but there is a crossbow leaning against a fallen log. The four of them are sitting or standing around a modest flame, and the woman stands on the other side of the fire. She is wrapped in a dark cloak, and because she is facing slightly away from you, you cannot make out her features. 
*if (tribe = "Quiet") and (sensitivity > 5)
	However, you glean that she is Quiet, like you, from her stature, the peculiar weave of her cloak, and the particular lilt of her speaking.
*comment endif

One of the leather-wearing crew holds out a hand, palm facing outward, to the cloaked woman in a placating gesture. 

"We would rather not have any trouble with you, but do not push us," he says. 

The cloaked woman hisses
*if tribe = "Quiet"
	a curse in the guttural tones of the language that the Quiet call "Old Yarish." The exact meaning of the curse is lost on you, but it has something to do with bearing bastard sons.
	*goto first_encounter_2
*else 
	something.
	*goto first_encounter_2

*label first_encounter_2
The still-sitting members of the group by the fire get to their feet at this new provocation. Their fingers reach tentatively for their weapons, but the man holding out his hand, clearly a leader in some capacity, asks for caution.

The situation is growing more serious. You feel you should get involved somehow, and since you still have the element of surprise, there are several options open to you. 
*choice
	#Climb down the rise and get involved directly.
		You move down the rise carefully and quietly, but it is not long before you are noticed. The armed group fans out without being commanded to do so, forming a defensive position around their leader. Clearly, they have had martial training. 

		The cloaked woman glances at you, but does not say anything. If anything, your arrival has made everyone more anxious. 

		The leader of the armed group looks you up and down, but does not say anything, either. 

		There are three weapons between the four of them, but if you are confident in your combat skills, you might be able to dispatch them. However, perhaps diplomacy might serve equally well. The choice is ultimately yours, force or discourse?

		*choice
			#Force. The only talking I need to do is with my fists.
				You decide to attack. Perhaps the remainder of Wolf's instincts within you recognize that strength is the most universal language. But how will you attack?
				*label when_diplomacy_fails
				*if diplomatic_failure 
					But attacking outright is only one of the methods available to you. How will you settle this?
				*choice
					#An all-out assault. No tricks, no hesitation.
						*if combat >= 15
							*set quickthinking +10
							Four opponents with weapons, expecting to fight an ordinary ${man_woman}. How unfortunate for them. 

							One of them uses a crossbow to get off a shot at you that misses, but it is the only one she manages. There is someone with an axe, another with a sword. None of them can keep up with you. Their arms move as if submerged in molasses, their strikes are as bloodless as their faces as they realize how outmatched they are. 

							It is only a few moments before you have disarmed and subdued them.
							*goto combat_success
						*elseif combat > 9
							*set quickthinking +5
							You have the advantage of surprise, already moving by the time the group can properly prepare for you. Fighting four enemies simultaneously is challenging, but greater numbers make the battle muddled; as long as you keep moving, keep shifting positions, and weaving around your opponents, you know the crossbow will be too risky to use. 

							*label mid_combat_scene
							Someone swings an axe at you and by the time you dance away from it, there is a short sword coming at your side. Annoying. 

							It takes a redoubled effort to disarm the axe-wielder and twist the wrist of the sword-user. A few sweaty minutes later, you have put down all four opponents.
							*goto combat_success
						*else
							You fly into the midst of your opponents, dodging an axe, slipping under an overhead sword strike, and smashing limbs as you go. But as you fight, the tide begins to slowly turn against you. 

							*label wolf_combat_1
							*set restraint %-5
							You grit your teeth and dig deep. You cede a little restraint, a little control over the wild, feral power inside of you and newfound strength rises up. Suddenly, the sword coming at you does not seem so fast nor the axe quite as heavy when you grab its wielder's arm and twist it away from you. 

							It does not take much longer before you manage to remove the company's weapons and leave them groaning in the dirt.
							*goto combat_success
					#Invoke a ritual to borrow strength from the presiding gods, then strike.
						*if ritual >= 10
							*set survival +10
							When you reach for the power, it arrives slithering and cool on your skin. Eel grants you his curious strength. 

							*label eel_powered
							When the armed company attempts to attack you, you slip past their strikes, able to move with oily grace among their ranks. You strike and are gone before retaliation can touch you. 

							*if eel_and_combat
								Before the last of Eel's power has faded from your limbs, all four of your opponents are lying on the ground.
								*goto combat_success
							*else
								The effort of fighting and sustaining a connection with the realm of gods leaves you winded and exhausted, but all four of your opponents are lying on the ground. 
								*goto combat_success
						*elseif (((ritual = 5) and (combat >= 10)) or ((ritual = 5) and (survival >= 10)))
							*set eel_and_combat true
							*set survival +5
							You invoke the ritual, expecting the power of gods to flow freely into you, but what you receive is only a fragment, a muddled reminder that you and your grasp in the realm of ritual is tenuous. Still, you receive some semblance of power from Eel's bounty. 

							The rest is all you. 

							*goto eel_powered
						*else
							The gods are quiet when you reach for their assistance. A long moment passes before you give up on their aid. But do you need their help when you have the aptitude of a god living in your gut?

							*goto wolf_combat_1
					#Intimidate them into submission using trickery to disarm them before I strike.
						*if quickthinking > 5
							*set survival +5
							There are four of them and only one of you, but you have the benefit of being cunning and not entirely honest. You notice the symbol branded on their leathers and, while you are not familiar with it, clearly it marks them as a part of a group. 

							"Ward sent me to meet with you," you explain to the leader of the group.

							You proceed to spin a yarn of half-truths and outright lies so quickly that it causes the group to pause and look at each other. You approach them cautiously, talking all the time. When you are close enough, you attack without warning and take them by surprise.

							*goto mid_combat_scene
						*else
							"Ward sent me to meet with you," you say, beginning to explain a false situation to the leader of the group.

							But he is not swayed by your double-speak. He gestures to his companions, and they come after you before you can get close.

							Having to fight opponents on their terms puts you immediately at a disadvantage. They manage to keep you at a distance with their weapons—a sword and an axe—and any advantage you might have bought yourself with your trickery quickly evaporates. You can sense the tide of the battle turning against you. 

							*goto wolf_combat_1
			#Diplomacy. Why fight until I have exhausted all other choices?
				You decide to talk rather than fight. Blood need not always be spilled, despite what Wolf might have done. But how will you defuse the mounting tension of the situation? 
				*choice
					#Ask that all involved parties sheathe their weapons and use common sense instead of killing each other.
						*if (survival >= 15) or (quickthinking >= 15)
							*set sensitivity +5
							Neither the armed group, nor the cloaked woman seem totally inclined to relax their suspicions, but you point out that there has not been any reason yet to draw blood, nothing worth killing over, and that gets closer to putting them at ease. 
							*goto diplomatic_success
						*else
							*set diplomatic_failure true
							"And who are you to command us, stranger?" the leader of the armed group asks. "If you have any sense at all, you will leave the way you came before we decide to take offense at your tone."

							The cloaked woman says nothing, but her hard gaze flicks between you and the others.

							Perhaps you would have left without incident, but the threat stirs a part of you that Wolf left behind. The challenge rises up in your blood and makes you angry enough to vibrate. 

							There is only way to answer the insult.
							*goto when_diplomacy_fails
					#Present myself as a humble, unarmed mediator and attempt to find common ground through discussion. 
						*if combat > 14
							*set diplomatic_failure true
							You put up your hands and approach the armed group in an attempt to make peace. You tell them you are unarmed and harmless, but the armed group is leery. It is possible that they see the way you edge toward them and grow skittish, or maybe it is your martial bearing that puts them off their ease, but either way, they seem unlikely to make peace. 

							"We will not be lured into your trap," one of them shouts. Then, in another instant, the woman in their group is aiming a crossbow at you. 

							Diplomacy suddenly seems out of the question. Blood it is then.

							*goto when_diplomacy_fails
						*elseif sensitivity >= 10
							*set quickthinking +5
							You calmly explain you are not a threat and despite a few derisive comments, the armed company and the cloaked woman seem to believe you. 

							For the moment it appears you have their ears. 
							*page_break
							*goto diplomatic_success
						*else 
							*set diplomatic_failure true
							"We have no interest in talking with you, stranger," says the leader of the armed group. "Leave. Now. Before we decide to take offense at your tone."

							The cloaked woman says nothing, but her hard gaze flicks between you and the others.

							Perhaps you would have left without incident, but the threat stirs a part of you that Wolf left behind. The challenge rises up in your blood and makes you angry enough to vibrate. 

							There is only one way to answer the insult.
							*goto when_diplomacy_fails
					*selectable_if (wolf_moon = "hunting") #[i]Hunting Moon[/i]: Announce myself as Wolf's avatar and demand obedience.
						*set restraint %-5
						*set influence +1
						*set eel_affinity %-10
						*set riser_affinity %-10
						*set gellas_reoccurs true
						The growl starts low in the back of your throat and is barely audible. You flash your teeth for an instant; your canines are longer than most and have a cruel edge. You are governed by the hunting moon, which is when the Wolf is at its most animalistic. You draw on that wild power now. 

						You step forward and everyone steps back. That means they are cautious. That means they are afraid. Good. 

						"I am the one who walks with Wolf. I am his claw." You give them a smile. "I am his teeth."

						The cloaked woman mutters something, but a look in her direction silences her. The armed group lower their weapons, just a fraction. 

						"You will disarm yourselves before me. Obey or I will take you apart."

						The armed group is slow to comply, but they put their weapons away in your presence. The authority feels good, perhaps a bit too good. Your blood is beating and you want to go further, but you have already decided not to fight. You push back the urge to kill, and it costs some small amount of already tenuous restraint to do so.

						"Leave this place," you tell them. "All of you. Disappear."

						The leader of the armed group looks ready to disagree, but another long look in your direction and he reconsiders. 

						"We ought to go," he tells his people. They pack their things, shouldering weapons and bedrolls before trudging east into the night. As they leave, you notice a recurring sigil branded on their leathers.
						*if sensitivity > 5
							*set recognize_rising_sun true
							You recall it as the sigil of the Rising Sun. A group vowed never to serve under any gods. Their numbers have swelled in recent years. 
							*goto dismissed
						*else
							But it means nothing to you. 
							*goto dismissed

						*label dismissed

						The cloaked woman remains after the four armed men and woman have gone. She gives you a curious look—as if wondering exactly what to do with you—then turns to leave.

						Once everyone is gone, the blood stops beating in your ears and your canines begin to resemble normal human teeth once again. You move on.

						You know that the edge of the forest must be nearing, so you will continue east until you find it. From there you should be able to figure out exactly where you are and then where to go next.
						*goto end_of_chapter
			#I am going to break this fight up, even if it requires breaking a few limbs.
				You are prepared to keep the armed group from causing any more trouble, but what course will your actions take?

				*goto when_diplomacy_fails
	#Frighten all five people below and drive them away from each other.
		*if quickthinking >= ritual
			If you leave these people alone for much longer, they will likely kill each other. You decide to take action to prevent that, at least for the moment. 

			A look around the area reveals there is not much to work with. You are unarmed and there are at least three weapons that you can see on the ground. Your best bet is—

			Then you see it. Settled high up in a twist of branches belonging to one of the sky-scaling oaks is a bulging nest. Ah!

			If there is one thing that can clear an area, it is a hornet's sting. You scout the ground for a rock and throw it with aim informed by your preternatural senses. The rock dislodges the nest, but the noise rattles the armed group into action. They hardly have time to investigate before the nest falls to the forest floor and cracks open. 

			The hornets are incensed! The pained cries of everyone caught in their path is evidence of your genius plan. 

			*label fleeing_groups
			Both sides flee into the relative safety of the forest, giving you enough time to consider your response. Since you have not been seen by either side, you could reasonably pursue either of them and meet them on your own terms, perhaps offering aid and getting into their good graces. 

			Which side is more attractive? 
			*choice
				#The armed group.
					*set riser_affinity %+25
					*set recognize_rising_sun true
					You follow the armed group into the forest where they are recovering from the trick you have just played on them. 

					*if quickthinking >= ritual
						Two of the group are rubbing at the welts running up their arms and legs, while another is rubbing her cheek where she was gouged several times. 
						*goto riser_pacify
					*else
						The four of them are on full alert. Their weapons are drawn and their expressions tight. They seem to be expecting the wolf to leap out of the very trees.
						*goto riser_pacify

					*label riser_pacify
					When you arrive, they turn their weapons on you, but that is no surprise. You feign innocence, raising your hands and allowing them to acclimate to your presence.

					"Who are you? What do you want?" their leader asks. 

					You make up a story about being: 

					*choice
						#"A wandering healer."
							*if quickthinking >= ritual
								*goto hornet_explanation
							*else
								You explain there is a local plant that can help to ward away wolves because they cannot abide the stench of it. 

								The story is rubbish, but it is worth the telling just to watch them furiously rubbing some random herbs on their faces, chests, and arms. 
								*goto riser_pacify_2
						#"A hunter from a nearby village."
							*if quickthinking >= ritual 
								*goto hornet_explanation
							*else
								*goto wolf_explanation
						#"A Wolf priest communing with nature."
							*if quickthinking >=ritual 
								*label hornet_explanation
								You explain that you have been stung by hornets in this forest before and suggest a local plant with curative properties.
								*goto riser_pacify_2
							*else
								The group gets skittish at mention of a wolf. 
								*label wolf_explanation
								You calmly, quickly explain that you have driven the great white wolf away. It will not be harming them. 

								*goto riser_pacify_2
					*label riser_pacify_2

					The armed group begins to relax around you. At least enough that they start to converse. 

					"You have fortuitous timing, stranger. That business with the
					*if quickthinking >= ritual
						hornets
						*goto continue_riser
					*else 
						wolf
						*goto continue_riser
					*label continue_riser
					*set recognize_rising_sun true
					*set encampment_directions "risers"
					*set gellas_reoccurs true
					could have been much worse. We thank you," says their leader, or at least the man they allow to speak for them. "We are members of the Rising Sun, aiming to meet with another contingent of our brothers and sisters at Ishko, a Clearwater settlement about a day east of here."

					Perhaps responding to some confusion in your expression, the leader explains. 

					"The Rising Sun is a group of independent-minded souls. We exist, or try to exist, outside the reach of gods and spirits. Incidents like this, sadly, are pretty common for us."

					What this man is saying is heresy, and Wolf would have slaughtered them for merely suggesting it, but you remind yourself that you are not Wolf. Not entirely. Not anymore.

					"Anyway, stranger—"

					"My name is ${prenom}."

					"${prenom}, then. My name is Gellas, and these are my brothers and sister in the Sun: Joven, Cathelyn, and Serk. We appreciate your aid, but we must continue on. Perhaps we shall see each other in Ishko."

					"That is a possibility," you agree. You have reason enough to travel in that direction, after all it stands to reason you could find food and shelter there. After that, your hunt for answers could begin.

					The Rising Sun followers trudge off to the east. You do not follow them, but head in the same general direction. Ishko is sounding like a better plan by the moment.
					*goto end_of_chapter
				#The cloaked woman. 
					*set eel_affinity %+25
					You follow the cloaked woman into the forest where she is recovering from the trick you have just played on her. 

					*if quickthinking < ritual
						The woman is rubbing at the welts running up her arm. In her other hand, she clutches a bone-handle knife. She has a few welts on her face as well, but seems to be ignoring them.
						*goto shaman_pacify 

					*label shaman_pacify
					When you arrive, she turns her weapon on you, but that is no surprise. You feign innocence, raising your hands and allowing her to acclimate to your presence.

					"And you are?" she asks. 

					You make up a story about being: 

					*choice
						#"A wandering healer."
							*if quickthinking >= ritual
								You offer to help.

								*label hornet_explanation_2
								She thanks you, but ultimately refuses your aid. She explains that she has her own methods of dealing with the hornet stings. Sure enough, as you converse, you see the welts slowly fading on her skin.
								*goto shaman_pacify_2
							*else
								You start to tell her about a local plant that can help to ward away wolves, but she stops you.

								"You needn't waste your breath on me, Wolf-kin. I know what you are."
								*goto shaman_pacify_2
						#"A hunter from a nearby village."
							*if quickthinking >= ritual
								You explain that you have been stung by hornets in this forest before and suggest a local plant with curative properties.

								*goto hornet_explanation_2
							*else
								*goto wolf_explanation_2
						#"A Wolf priest communing with nature."
							*if quickthinking >=ritual 
								You explain that you have been stung by hornets in this forest before and suggest a local plant with curative properties.

								*goto hornet_explanation_2
							*else
								The woman raises an eyebrow at the mention of Wolf. 
								*label wolf_explanation_2
								You calmly explain that you have driven the great white wolf away. It will not be harming her. 

								She laughs.
								*goto shaman_pacify_2

					*label shaman_pacify_2

					*if quickthinking >=ritual
						"I thank you for your offer of aid," she says. "But I am a shaman and we have our own methods."

						She smiles.

						*label shaman_farewell
						*set encampment_directions "shaman"
						"I appreciate you intervening when you did. Things could have gotten much worse. And for your assistance, Eel, my patron, owes you a debt that I cannot hope to pay alone. I will tell you, however, that if you are looking for shelter, you can find it in Ishko. A Clearwater settlement just a day or so east of here. That is if you tire of sleeping under the stars."

						She turns to leave. 

						"Thank you," you tell her. 

						"We both serve the gods, Wolf-kin. I am obliged to help, am I not? After all, what is family for?"

						She disappears into the trees and you wait until she is gone before you head east. Shelter and food sound like a good start. Then you can continue finding out more about Wolf and where he is gone.
						*goto end_of_chapter
					*else
						"I am a shaman, stranger," she says. "I know more than you give me credit for."

						*goto shaman_farewell
		*else
			If you leave these people alone for much longer, they will likely kill each other. You decide to take action to prevent that, at least for the moment. 

			You dig deep into your memories and find a trick that seems appropriate in this situation. When you first became an avatar of Wolf, the god graced you with a simple way to ward off enemies. At least those who did not pose much in the way of a genuine threat, that kind of knowledge would come later. 

			All it takes is for you to reach into the pit of your stomach where the Wolf's instincts live. You grasp the shape of the white wolf and bring it out into your hands and eyes and teeth. You growl and yell at the moon, but it comes out in a howl. The ritual is taking hold. 

			You descend the rise as quickly as possible, and when the first of the armed group sees you, he shouts in alarm. He is seeing a huge white wolf coming toward him even though you have not changed form, merely suggested a transformation to his eyes, which are eager to believe the deception. His fear helps to convince the others that they are also seeing a wolf coming toward them. 

			You howl again and go running.

			They all disperse, even the cloaked woman who narrows her eyes at you, almost as if she could see through the deception, but in the end she runs away as surely and as quickly as the rest of them. 

			*goto fleeing_groups
	#Hunt down and kill the armed group from the shadows.
		*set pantheon_regard -1
		*set death_toll +5
		*set action %+20
		*set combat +5
		You decide to remove the threat entirely. 

		These strangers are clearly organized and seem to be held back by a thin leash. Better to be rid of them definitively, conclusively. 

		There is no way to descend the rise and come out behind them, but you are able to go the long way around and come up to the west of the group where the firelight is most likely to blind them to your approach. You climb down the rise quietly, and the escalating argument between the four armed individuals and the cloaked woman makes for good cover. When you are on the ground, you stalk your prey like any hunter would. 

		By the time the first one of them notices your presence and attempts to alert the others, he is already down. A quick, merciless strike to his throat ensures he stays down. 

		The woman among them nearly clips you with her crossbow, but her inaccuracy seals her fate. The other two join forces and try to come at you together, but you are stronger than they are. And faster. 

		When you are finished, there are four corpses by the fire. The cloaked woman looks on with her hand floating over her mouth. She looks horrified, but she has not fled yet. 

		What do you say to her, if anything? 
		*choice
			#"You are safe. They will not hurt you now."
				*set encampment_directions "shaman"
				She nods slowly. 

				"I would have been content with merely driving them out," she says. "Killing them all…it seems excessive."

				"It was necessary."

				"Was it? I suppose you would know better than I. Either way, as his shaman, I can tell you that my patron god owes you debt, stranger. He will see that it is paid."

				*if selfishness > equity
					"Make sure that he does, shaman," you tell her.

					"You will get everything you have earned and more. Trust me," the shaman says.
					*goto selfish_check 
				*else
					"I did not do it for a reward," you explain.

					The shaman's mouth turns up in wry amusement. "Precisely why you are worthy of it."
					*goto selfish_check 

				*label selfish_check

				She turns away from you, then back. "I should mention: if you are looking for civilization again, there is a settlement no more than a day to the east of here. Small place, but enough for food and water. Maybe even a bath."

				She makes a meaningful sweeping gesture with two fingers of her left hand toward the dilapidated temple and then turns back to the forest. You watch her go before you make your own way as well.
				*goto end_of_chapter
			#"I think you should leave here."
				*set encampment_directions "shaman"
				"Yes, I suppose so. Assuming you will not strike me dead once I turn around."

				You shrug and she laughs. It is a sudden burst of dry, grim amusement. 

				"Thank you, stranger. Your methods are brutal, but I cannot deny that you might well have saved my life and protected Eel's temple from further desecration. 

				"As his shaman, I can tell that Eel owes you a debt. He will see it paid. I cannot do much for you personally, but if you are looking for civilization again, there is a settlement about a day east of here."

				You take her directions into consideration, but as for Eel's supposed debt to you, that is a different matter. The ways gods choose to pay their debts are as varied as their temperaments. Being owed a boon can be a help or a hindrance. It remains to be seen which Eel will offer you. 

				You part from the shaman without much more talk. Both of you walk separate ways back into the dark of the forest.
				*goto end_of_chapter
			#Say nothing. Leave her to gawk at the bodies.
				As you turn to leave, she calls out.

				*if (tribe = "Quiet") and (sensitivity > 5)
					"Thank you, you have done us a service," she says.

					"Us? You mean Eel, then. You are one of his shamans," you say.
					*goto shaman_thanks
				*else
					"This is one of Eel's places. You have done us a service by protecting it."

					"Us?" you ask.
					*goto shaman_thanks

				*label shaman_thanks

				"Yes. I am a shaman of Eel. He does not walk with me, as Wolf walks with you, but…well, I manage. Thank you, stranger."

				You grunt. She can take that as a farewell or not, but you have done enough here.
				*goto end_of_chapter
*label diplomatic_success
*set recognize_rising_sun true
*set gellas_reoccurs true
Both sides are hesitant to meet each others' eyes, but gradually they explain the situation. The leader of the armed group is the first to drop his weapon, and the first to speak. 

"My name is Gellas. I am a member of the Rising Sun, but we have been called Risers as well by those less friendly toward us. Have you heard of our group?" he asks you.

"A group of faithless brutes—" the cloaked woman hisses. 

"We prefer self-determined," Gellas counters. "We do not follow the old ways. The gods or whatever the spirits are that claim authority over us: We do not accept their yoke."

The cloaked woman narrows her eyes. 

"And you believe in trampling sacred spaces, apparently. This is a temple to the god Eel. Your presence is bad enough." She points an accusing finger. "But eating and drinking and burning your stinking fire beneath the eaves of his home? It is an affront. You have not been anointed with his oils or sworn to his service. Your faithlessness offends."

"We are far from home and tired. We stopped here because this clearing is easy to defend from forest predators. Besides, if your god is so protective of this space then why does not he strike us down himself? Why send a frail, whining fruit fly to buzz around our ears and annoy us?"

"I offered to show you another place to camp, away from Eel's sacred grounds!" the cloaked woman shouts. 

"Why does your pleasure-god claim a space in the middle of nowhere? Or do the gods demand all land to be consecrated in their name?"

"Eel is god of the low places as well as the high. This is a place for journeymen of his faith to ponder their deepest selves, and you are not welcome."

The situation is getting tense. If you intend to intervene, now would be the time. 

*choice
	#To the Rising Sun group, peaceably: "This is a space sacred to Eel's worshipers; can we not find you some other place to rest your heads?"
		*set riser_affinity %-25
		*set eel_affinity %+25

		The Risers look abashed and Gellas seems…disappointed, perhaps. 
 
		"You are probably right," Gellas says. "We will find somewhere else to camp, though it means we will get less sleep before dawn."

		"We will likely see each other again, stranger," he tells you. 

		*label risers_leave
		The Risers collect their gear and disappear into the forest. You watch them go, and when they are gone the Eel worshiper approaches you. 

		"You have protected the faith today, Wolf-kin."

		It is difficult to hide your surprise. She laughs. 

		"I can smell him on you. The wet beast stink of the wild dog god. It is distinctive. Especially to a shaman. Anyway, thank you for intruding. It shames me that a follower of Wolf was calmer than I, but the gods teach us strange lessons.

		"I will stay here and undo whatever damage those animals did here, but if you are looking for shelter and a place to sleep that is not the forest floor, there is a settlement a day or so east of here called Ishko. Clearwater mostly, good people."

		You thank her for the advice and leave her to her task. Perhaps it is best for you to go find the settlement and from there, seek answers elsewhere to the questions you have about Wolf and where he is gone.
		*goto end_of_chapter
	#To the Rising Sun group, forcefully: "You have clearly intruded on something above your ken. Begone, quickly, before we have a real problem."
		*set riser_affinity %-30
		*set eel_affinity %+30

		One of the Risers steps forward with a blade, but Gellas juts an arm out in front of him, stopping him. The Riser leader stares at you, as if trying to make a decision. 

		"You do not want us as an enemy, stranger. Think on that for the next time you see me."

		He turns back to his companions, and says, "Let us leave this place."

		*goto risers_leave
	#To the Eel worshiper, peaceably: "They only intend to rest for a while and then be on their way; can you not allow them their brief sojourn?"
		*set riser_affinity %+25
		*set eel_affinity %-25
		The woman looks surprised to hear you supporting the Risers, but ultimately she bows her head and accepts. 

		"Disappointing, to be sure, to have this place defiled, but once you have all moved on, I will restore it and all will be as it was. Be careful sleeping under Eel's gaze. Trespassers tend to find little comfort here."

		*label eel_shaman_leaves
		She shakes her head one final time and then walks away, out into the forest. 

		When she is gone, Gellas and his companions relax a bit. 

		"Thank you for siding with us, friend. We could have handled it ourselves, but…well, you may have saved that woman's life. And it cost her only her pride."

		Gellas smiles. 

		"We will get some rest here then we will be heading on to Ishko, a Clearwater settlement maybe a day east of here. You should consider it if you could use a bath and a decent meal."

		It is not a bad idea. Going east and getting some sleep under an actual roof, then moving on and finding some answers to your questions. The prospect of Ishko sounds better by the moment. 
		*goto end_of_chapter
	#To the Eel worshiper, forcefully: "Does Eel demand you sow chaos in his house? Leave this place safely right now. I cannot guarantee the offer will last another breath."
		*set riser_affinity %+30
		*set eel_affinity %-30

		The woman's mouth hangs open for a moment before she bites her lip and points at you. 

		"That…is a serious mistake, stranger, and you may find that gods are not so forgiving. Sleep well."

		*goto eel_shaman_leaves
	#To both sides: "None of you have acquitted yourselves well here, and all of you should leave. Now."
		*set equity %+20
		Both sides are quiet for a moment. Then the Eel worshiper speaks. 

		"You would try to command me in the seat of Eel's power and favor? You are brave, stranger. Brave and reckless. But you are not wrong. I will agree to walk away, if they will."

		"We will. I do not know who you think you are, newcomer, but you should know that you have not made any friends today. Should I see you again, I promise you it will be on different terms," Gellas says, then to the Eel worshiper, "as for you. Hope we do not cross paths again ever or I may squash you, fruit fly."

		"Some insects sting," she says. 

		Gellas and his people smirk at that and both sides lob insults, veiled and otherwise, while preparing to leave. Eventually, the Risers and the Eel worshiper leave in opposite directions and you are left alone in the forest clearing with just Eel's broken down temple for company. 

		Once you are sure that everyone has cleared out, you leave as well, heading toward what you are sure is the edge of the forest. It should be just a little more than a day before you are there.
		*goto end_of_chapter

*label combat_success
*set recognize_rising_sun true
The formerly armed group stares at you with simmering rage, those of them that are still sensible. 

"Congratulations, you managed to take us while we were off our guard," their leader says, and spits blood into the dirt. "But trust me, this is not going to go well for you. We are the Rising Sun, friend."

The cloaked woman interjects. 

"You Risers are just the faithless in new colors, preaching an end to the old ways: No more worship of gods, no more faith. But what rises up in its place? Chaos, disorder."

"We have faith in ourselves. We have faith in our brothers and sisters. What we reject is the notion that man should kneel while their so-called gods stand proud," the leader shouts. 

"I have served as Eel's shaman for many years and I have seen what faith without direction can do. Like the desecration of other people's sacred spaces." The shaman points at the broken down temple. 

The leader already has a rejoinder prepared, but you cut him off:

"Enough."

*label riser_kill_choice
The Risers are on their knees, their eyes narrowed in your direction. You have defeated them in battle, but will you allow them to survive or end their lives here? 

*comment originally I made it so that if the player's restraint was too
*comment low then they would be unable to choose the mercy option here.
*comment however I realized that it was a little early to be robbing players
*comment of their agency. 
*choice
	#Allow the Risers to walk away.
		*set sensitivity +5
		*set influence +1
		*set restraint %-5
		*set pantheon_regard +1
		*set riser_affinity %-25
		*set bear_affinity %+25
		*label risers_live
		*set encampment_directions "shaman"
		It takes a while for the Risers to come to their feet after you tell them that they can take their injured and go. Wary of a trick, they slowly help each other get up and get moving. 

		They limp into the forest like wounded beasts.

		"The dangers of the forest might kill them, but it is unlikely. You should be prepared for reprisal, Wolf-kin," says the shaman.

		You look at her with some surprise.

		"Did you know all along what I am?" you ask. 

		"Of course," she says. "Eel's favor elevates me slightly. Not so much as you, an avatar of the gods, a living font of their power, but…I can at least recognize one of my own."

		The shaman points to the temple. 

		"My work will keep me here a few more days, but if you are looking for cooked food and shelter beyond the canopy overhead there is a settlement called Ishko at the edge of the forest, just another half day to the east."

		You thank her and she nods. Then she turns toward Eel's temple and you head off to the east. Civilization sounds like a good start.
		*goto end_of_chapter
	#Make peace before letting the Risers go.
		*if influence > 1
			*set riser_affinity %-10
			"Not one more drop of blood needs to be shed here. Go safely and put reprisal out of your mind. Remember that I could have killed you, but I did not hurt you—any of you—more than necessary to stop the fighting," you tell them.

			"As if we need your charity, dog!" one of them shouts. 

			Their leader turns on the man angrily. 

			"Would you rather die than accept a peaceful solution? Your life is not yours to throw away as long as I lead this group," the Riser leader shouts. He shakes his head and swears, then looks back at you. "We will leave. I cannot promise things will be peaceful if we meet again, but I will remember what you did here, stranger. All of it."

			*goto risers_live
		*else
			*set riser_affinity %-35
			Before you can say much of anything, their leader spits at you. 

			"We are not interested in anything you have to say. You will wish you'd have killed us here, stranger. That I can promise," he says.

			*goto risers_live
	#Kill the Risers. 
		*set death_toll +5
		*set action %+15
		*set deliberation %-15
		All but the sickest animal will struggle when the end comes upon them. These are no different. When it's done, their eyes still reflect the firelight. You look away. 

		*label riser_murder
		*set encampment_directions "shaman"
		The shaman meets your eye
		*if savage_riser_death
			and shakes her head. 

			"That was…" 

			She does not finish the statement.
			*goto riser_murder_2
		*else
			and nods once. There is conspiracy and grim acknowledgment in the gesture, the curve of her mouth, and the way she holds herself. 
			*goto riser_murder_2

		*label riser_murder_2
		
		"I have work to do here." She waves a hand in the direction of the 
		*if savage_riser_death
			mangled
		corpses. "If you are looking for food and shelter beyond the canopy overhead, there is a settlement called Ishko at the edge of the forest, just another half day to the east."

		You thank her for the information. 

		*if savage_riser_death
			"We are bound to help each other, are we not, Wolf-kin?" She smiles at the expression on your face when she mentions Wolf. "I can smell him on you. The wet fur and blood and steel. Something is different though, something beyond my ken. I cannot help, but I hope you find whatever you are looking for."
		
		She turns away to tend the bodies, signaling an end to the conversation, and you walk away, to the east and to Ishko; civilization sounds good after tonight's work.
		*goto end_of_chapter
	*if (((ritual > 5) and (sensitivity > 5)) and (shaman_advice)) 
		#Take the shaman's advice: implore the nearby gods to obscure their memories.
			*set eel_affinity %+10
			*set ritual +5
			*set risers_spelled true
			*set encampment_directions "shaman"
			You have to be absolutely silent to hear the whisper slithering through the grass. The sound of a presence that is neither entirely real nor totally imagined. Your skill at cultivating the quiet—some might say holy—space of ritual allows you to hear the wet, slippery visitor that is invisible in the tall grass. 

			"Eel, who is brother to Wolf," you say without words. "Take their memories of me, of this woman, of what has happened here. Please."

			You never see what coils and uncoils around your feet because you know it can be dangerous to look, but it grows fatter and the air thicker. Breathing the hot, oily air grows impossible and you force yourself not to gag. And then it's over. All is as it was before you reached out for aid. Except…

			All four of the bruised Risers stagger to their feet and look at you with uncertain expressions. 

			"What happened here?" one of them asks. 

			You explain that they were attacked by wolves, but that the creatures were driven away. They accept this explanation passively and thank you before wandering away in the forest. 

			When they are gone, the shaman whistles. 

			"You are quite a surprise, Wolf-kin," she says. 

			You raise an eyebrow. She knows what you are. 

			"I did not expect someone as talented in the ways of ritual understanding to walk with Wolf. But, I suppose stranger things have happened."

			She watches until the Risers are gone and then goes to tend Eel's dilapidated temple. She calls out to you without turning from her work. 

			"If you want food and shelter, seek out Ishko. Only a half-day or so to the East."

			You thank her and she waves you off, but not before saying. "I hope you find what you are missing, Wolf-kin."

			You leave her to her work. 
			*goto end_of_chapter
	*if (restraint < 30) #Sate my Wolf's instincts. Attack and tear them apart.
		*set death_toll +5
		*set chaos_score +1
		*set restraint %+25
		*set pantheon_regard -1
		*set eel_affinity %-10
		*set savage_riser_death true
		The metallic taste in your mouth becomes all you can think of. Your fingers twitch despite you. It takes the first scream to snap you to awareness, one of the Risers is already dead by then. When you take the rest, the strongest thing you feel is relief. 

		*goto riser_murder
	*disable_reuse #Ask Eel's shaman what she would do with them.
		*set shaman_advice true
		The woman is clearly surprised to be asked her opinion on the situation, but she recovers admirably. 

		"Eel does not require blood to sate his appetites as some other gods do, but there is occasional wisdom in violence. They have marked your face and mine, and if they live it exposes us both to potential vengeance not only from them, but from their brethren.

		"But I am loathe to tell you to kill men and women. Perhaps if there was some way to render them insensible." She pauses. "Ultimately, the decision is yours, stranger."

		She draws her cloak closer as if the night has taken on a sudden chill.
		*page_break
		*goto riser_kill_choice 

*label end_of_chapter
*page_break
Your journey east to the edge of the forest takes you about a half day as
*if encampment_directions = "shaman"
	the shaman said it would.
	*goto end_continue
*elseif encampment_directions = "risers"
	the Risers said it would.
	*goto end_continue
*else
	the crow flies.
	*goto end_continue
*label end_continue

You wander out in the transitional zone where the densely packed trees begin to space out and the tall grass thins. Before you in the dazzling fullness of midday sunlight is a world that you feel you are seeing for the first time. The place in your chest where Wolf once sat and made his wishes known is now hollow, and you feel the coming days will dictate whether that emptiness is a blessing or a curse. 
*finish
