*text_image final.png center Final: Wolves

[i]"You are mine," Wolf said, and bared his awful teeth.[/i]

[i]"Whether I offer mercy or the glory of being torn apart limb by limb, you are mine—every delicious bit of you."[/i]
*line_break
- excerpted from the testimony of the supposed first-ever avatar of Wolf.
*page_break

You are surrounded by trees, as ever in these dreams, but the feeling is more keen than it has ever been. You can feel the chill of the air and can clearly make out the individual snowflakes drifting from the low-hanging branches. They fall so slowly that it is almost as if they are suspended.

Snow crunches beneath your feet as you walk a path that winds through the woods. You know, in the inexplicable surety of dreams, that the only way out of the woods is through, so you follow the path, though the world darkens around you by degrees. 

It does not take long for you to come upon him. 

Wolf sits on his back paws, recumbent and almost still enough to suggest relaxation. You doubt the lupine god has relaxed for even a moment since his inception. He regards you with something resembling 
*if action < 70
	general disdain.
*if action >= 70
	cautious anticipation.
*comment endif

He is larger than any wolf you have ever seen. You expected that, but you could not have anticipated the way his gray fur reveals hints of red whenever he moves even slightly, or the incongruous patch of bone-white that circles his right eye. His features are expressive, but whatever his half-animal mind is thinking lies beyond your ken. 

You expect some kind of reaction from him, but for a long time nothing happens. Wolf just sits in the snow and stares at you as the snow drifts at its glacial, lazy pace. So naturally, his sudden attack jolts you. The god whose domain is hunger leaps at you, moving his impressive bulk with swift and sleek power. You are forced to react immediately:

*choice
	#I rouse the snow to wakefulness and urge it to rise against my attacker.
		*if ritual >= 20
			The ice and snow are slow to respond, so indolent have they become in this cold, slow place, but in the last instant—as Wolf's jaw widens and the arc of his leap threatens to crush you underneath him—the stillness of this dream-space is upended. A vicious whirl of ice and gentle snowflakes turned jagged by force erupts between you and Wolf.

			Wolf howls as the relentless swirl of ice throws him backward through the air and onto the ground. By the time he stands again, he seems uncharacteristically hesitant to attack. 
			*goto wolf_fight_success
		*else
			*goto wolf_fight_fail
	#I rely on my instincts and quick reflexes to evade Wolf and keep him at a distance.
		*if quickthinking >= 15
			Wolf cannot hurt you if he cannot catch you, so you dash toward Wolf as he comes down at you and then slide underneath him in a flurry of ice and kicked up snow. 
			*goto wolf_fight_success
		*else
			*goto wolf_fight_fail
	#I meet him head on. I will not be his easy snack.
		*if combat >= 20
			You wait until Wolf is nearly crashing down on you and reach up, digging both hands into the scruff of his neck and jerk hard enough to send him careening away from you. He makes a noise full of indignation as he crashes into the ground. You prepare for his counter-attack, but Wolf makes no immediate move toward you.
			*goto wolf_fight_success
		*else
			*goto wolf_fight_fail
	#I can take whatever Wolf intends to throw at me.
		*if survival >= 20
			In your imagination, or perhaps your worst fears, Wolf's body has a weight that could crush you instantly, but his form—though strong and fierce—is not immovable. The impact of him against you pushes you both into the snow, but you are able to keep his snapping, ferocious jaws from closing around your throat by pressing against him with your hands. You eventually work up enough strength and leverage to throw him overhead.

			The wolf god makes a frustrated noise as he sails over you. He lands gracefully enough, but he does not come after you again. Instead he waits, watches. 
			*goto wolf_fight_success
		*else
			*goto wolf_fight_fail
	#I use the twisting logic of dreams to my benefit and bend the world around Wolf to incapacitate him.
		*if sensitivity >= 25
			The world around Wolf starts to shimmer and then it bends. He is suspended in the air for an instant, then he is slammed down by a force considerably more brutal than gravity alone. Wolf rises, unsteadily, but does not come at you again.
			*goto wolf_fight_success
		*else
			*goto wolf_fight_fail

*label wolf_fight_fail
The token resistance that you offer is nothing to Wolf. He tears through your attempts at combating him and comes at you with more determination than you expected. All of the conflicts you have survived until now have not adequately prepared you for what Wolf represents: fearsome, awful power. 

His paws pin your arms at both sides of your head and he leers at you.

"Anything to say before I consume you, ${prenom}?"

*fake_choice
	#"I will never be fully yours. I will fight you always."
		*set action %+10
		*set deliberation %-10
		Wolf moves his head closer to yours and briefly he looks more terrible than anything you have ever seen. His full godly powers are etched into his animal face in thrumming lines of power that are darker than ink, and depthless. In each one of his gleaming teeth you see a dozen ways that you could die. 

		"Fight then, child, for all the good it will do. Go ahead and fight."
	#"You are not my god, Wolf."
		*set action %+10
		*set deliberation %-10
		"You wound me, ${prenom}. I had taken you for one of my finest. But in the end your faith is inconsequential. You have already brought me everything I need."
	#"Is this how it was always meant to be?"
		*set deliberation %+10
		*set action %-10
		"Since your first breath. There was never any other way this could go," Wolf says, then adds quietly. "Unless there was…but now you will never know."
	#"Do not do this, Wolf. I have been faithful…"
		*set selfishness %+10
		*set equity %-10
		"And your faith will be rewarded, ${prenom}." He is already salivating. "You will live forever now. Your name will be joined to mine for eternity. Is that not reward enough?"
	#"Why bother? Do whatever you have to."
		*set selfishness %+10
		*set equity %-10
		"Why?" Wolf repeats. "Because hawks are proud, because spiders are sly, because the gazelle races toward the horizon, and wolves are hungry. Always hungry."
	#Say nothing.
		*set action %+5
		*set deliberation %-5

		"Yes. Oh yes," Wolf says. "Strong and quiet and proud. I hope your noble silence brings you solace when the pain begins."
*comment endif

Wolf laughs, and then he feasts.
*page_break 

*label wolf_lunch
The pain is terrible, yes, but it is not the pain that drives you to the edge of sanity and perhaps somewhat beyond it. No, it is the way Wolf's jaws consume more than flesh: He tears at the deepest parts of yourself. You feel memories slipping away, whole parts of your mind and your person-hood. True to his word, he is consuming you body and soul. 

Honestly, once the pain is gone, you miss it because it means that Wolf has burrowed his way into your senses. What follows is a perfect darkness and beyond that? Nothing good.

*page_break
*goto_scene consumed_end

*label wolf_fight_success

Wolf reorients himself after his failed attack and shakes the snow from his fur. His expression is not one of defeat, but of wry amusement. 

"You are capable, ${prenom}. I will give you that. To be expected of my flesh," Wolf says. 
*if ((pantheon_lead = "you") or (three_god_powerup = true))
	*set self_score %+10
	"Better still, I can smell the power on you. The authority. You have humbled my mighty siblings. For that I must offer you my respect and I assure you, ${prenom}, few have ever heard those words from me."
	*goto continue_convo_1
*elseif ((hawk_dies) or (bear_dies))
	*set self_score %+5
	"And you come before me with the blood of my killers on your hands. You have done well by me, ${prenom}. Very well indeed."
	*goto continue_convo_1
*else
	*goto continue_convo_1
*label continue_convo_1

It occurs to you that you have never heard his voice before, only felt him stirring in your mind and his impulses filling up your veins. It is more melodious than you would expect, softer too. 

He continues, "But the hour grows late and you only now arrive. You have kept me waiting for my body, for my resurrection."

Perhaps reading something in your face, or your stance, Wolf laughs. 

"You did not expect to leave here intact, did you? 
*if ((action > deliberation) and (selfishness >= equity))
	*set self_score %+10
	Even though you are indisputably one of my followers in temperament, still
	*goto continue_convo_2
*else
	You are barely a wolf and
	*goto continue_convo_2
*label continue_convo_2
you exist to glorify me, avatar. My mark elevates you to the highest high, but the cost is great. My siblings tore my flesh and spread my physical being along the firmament, but they did not devour me. If they meant to wipe me from existence, then they should have swallowed up every mote of me." He grins, and it is terrible. "I will not make their mistake when I swallow you whole."

He smiles when you recoil from his suggestion. 

"Oh, do not worry, child. Your mortal frame will crack open and I will pour myself inside. Every drop of my essence will fill you up and burn away the self that you know, the mind that you treasure, the impulses that drive you, until only I remain. If you are strong, very strong, then something of you will remain. But the body cannot serve two masters. "

He takes another step toward you across the snowy field. His right eye catches the moon and takes on a sinister shine. 
*page_break 
Wolf looks almost rapturous as he advances on you. 

"The hour of my rebirth arrives, ${prenom}. I have waited here since the mutinous attack hamstrung me, sent me twisting through the darkest depths. It was humbling, being so reduced. But you came. And now you will die so that I may suck the marrow of your soul and be reborn.

"So, ${prenom} are you prepared to give yourself to me, body, blood, and soul?" Wolf asks, his maw fairly salivating. 

*choice
	#No, I have made it this far as myself. I refuse to be anyone's meal.
		*goto directing_to_last_fight
	*if ((three_god_powerup) or (intention = "demolish")) #I am not interested in whatever deal Wolf is willing to suggest. He is part of the old way, an enemy. I will destroy Wolf utterly and remove him from existence forever.
		*set self_strength %+10
		*label directing_to_last_fight
		*gosub final_fight
		*page_break

		*if self_strength > wolf_strength
			*goto wolf_defeated_combat
		*else
			*label bitter_defeat
			In the end, Wolf still stands. Despite your best efforts. You threw everything you could his way, but he is a god after all.  

			"You fought well, ${prenom}. No one could have expected more from you. I am almost proud of your efforts." Wolf comes closer, so close you can feel the heat of his breath cutting through the cold. "But you were not meant to be more than my shadow. You are mine. Always and forever, you are mine."

			*goto wolf_lunch
	#It is my duty to revive Wolf. It has ever been so.
		Wolf grins. 

		"I knew you would see reason, child. Now come here and let me taste my new form."

		*goto wolf_lunch
	#Fight back. Show Wolf that you are formidable in your own right.
		*goto directing_to_last_fight
	#Use my will to subdue Wolf. 
		*gosub final_fight_intellect

		*if self_strength > wolf_strength
			*set wolf_peace_victory true
			*page_break
			You rally for one final push into Wolf's mind. He resists it, of course, but there is a crack. You push into the breach and his resistance buckles. 

			Suddenly he stops advancing. He shakes as if trying to rid himself of you, but you have a hold on his mind and refuse to let go.

			He is incensed. You can feel the anger boiling up within him, but it has nowhere to go—you keep his leash painfully short lest he break your control. Like any trapped wild animal, he snaps, gnaws, and fights for any inch of relief. But the god whose domain is action and cunning cannot free himself, and before long he realizes this. He stops struggling, gives into the knowledge that he is well and truly caught. 

			Wolf leans back onto his haunches and lets out a plaintive howl, and the snow, as if in sympathy, stops falling. The world begins to flicker at its edges. The trees all around you are solid, but you can also see through them. The artifice of the dream is fraying.

			"It will not last long now," he says.

			You wonder what he means. He does not explain himself. Instead, Wolf cocks his head at an angle and regards you. 

			*goto wolf_defeated_intellect
		*else
			*goto bitter_defeat

*label wolf_defeated_combat
Wolf's chest heaves. He stares at you out of one half-shut eye.

*label wolf_defeated_intellect
*set deliberation %+15
*set action %-15
"When you were born, ${prenom}, Gazelle read your future in your first cry. She claimed she could not see further than a few days. You defied her sight, and that is why I wanted you. I wanted the child that would dare to shrug off our influence. So this…this is delicious irony," Wolf says.

"It did not have to come to this, Wolf," you say. 

"Oh, but it did. We can only be what we are, ${prenom}. The lion cannot unmake herself, the sparrow cannot forsake his wings for gills. The story we write is the only story. I tried to defy the end to my story by consuming and investing myself within you. I failed. Such is the way of things."

Wolf takes a shaky step toward you, but something causes him to topple forward. You see what it is right away: His left paw is transparent. You can see through it to the white snow underneath. It has faded like a half-remembered thread from a dream. 

"Already the pieces of me are fading into the nothing from which my kind was born. Take what remains, ${prenom}. Consume me like I would have done to you."

It is a gruesome suggestion perhaps, but Wolf is right. He would have consumed you without a second thought. Will you not do the same to him?

*choice
	#Consume the Wolf god.
		*gosub eating_wolf

		*goto chapter_close_wolf_eaten
	#Refuse the savage command.
		*if restraint <= 27
			*gosub gobbling_wolf_up

		*if wolf_eaten_trigger
			*goto chapter_close_wolf_eaten
		*else
			*set sensitivity +5
			*set deliberation %+15
			*set action %-15
			*set equity %+15
			*set selfishness %-15
			You will not do to Wolf what he would have done to you.

			Wolf snorts. His white breath streams out in the cool air, curling into impossible shapes before fading altogether.

			"You would rather this power of mine goes to waste?" Wolf asks. "Your loss."

			*goto chapter_close
	#Help keep Wolf intact.
		*set deliberation %+15
		*set action %-15
		*set equity %+10
		*set selfishness %-10
		*set sensitivity +5
		Wolf snorts.

		*if (selfishness > equity)
			"Do not pretend to be concerned with the plight of others, ${prenom}. It does not suit you."
		*if (equity >= selfishness)
			"Your heart bleeds for me, does it, ${prenom}? Save your pity. I have earned this fate and worse."
		*comment endif

		*if restraint <= 27
			*gosub gobbling_wolf_up

		*if wolf_eaten_trigger
			*goto chapter_close_wolf_eaten
		*else
			*goto chapter_close
	*if (wolf_peace_victory) #Make peace with Wolf in his final moments.
		*set equity %+20
		*set selfishness %-20
		*set selfishness %-20
		*set ritual +5
		*check_achievements
		*if not(choice_achieved_gentlenight)
			*achieve gentlenight
		The suggestion seems to stun him. Wolf is uncharacteristically quiet.

		"I do not deserve an heir. I should fade into the dark and be rid of all attachment to this world of blood and fire," Wolf says. His voice is thin and reedy. His body is fading faster now. "I should have eaten you whole."

		He looks at you. Whatever he sees makes him smile.

		"I do not deserve an heir, but fate has decided I should have one. I suppose that is something." Wolf closes his eyes. "Here. It is not much, but this is a piece of me. It should make you stronger, somewhat."

		You feel a warmth in your chest that fades gradually. 

		"Take care of my world, ${prenom}. If not…"
		*goto chapter_close

*label chapter_close
*set wolf_dead true
Wolf takes a final belabored breath. More than half of him has faded now, but he stares at you until the very last moment. Until nothing of him remains.

*label chapter_close_wolf_eaten 

You are left alone in the quiet that remains, but you faintly hear the stirrings of life around you, and then a bright light forces you to shut your eyes.

*page_break
*goto_scene survived_end

*comment THE FINAL WOLF FIGHT SUBROUTINE

*label final_fight
*set wolf_fight_combat true
"Oh?" Wolf says, his eyes twinkling in amusement. "You are prepared to fight me, seriously? Your petty victories have given you ideas above your station, child."

Wolf paces around you and bares his teeth to frighten you.
*if ((pacifism) and (pacifism_broken = false))
	*set wolf_strength %+20
	"You think you can take me on? As fragile and unbloodied as you are? You would have done better to submit to me, ${prenom}. At least I would have spared you some of the pain."
	*goto after_first_wolf_enc
*elseif pantheon_regard >= 8
	*set self_strength %+10
	"You served the other gods. Playing their messenger when you should have been serving me. Pathetic, infuriating human."
	*goto after_first_wolf_enc
*comment endif

*label after_first_wolf_enc
*if restraint <= 30
	*set wolf_strength %+15
	Wolf's taunts are infuriating. You can feel the anger rising off of you in waves, and it only seems to make him stronger, more confident.
	*goto continue_fighting
*else
	*set self_strength %+10
	You ignore his taunts. Your mind forms a bulwark against him, refusing to strengthen Wolf's resolve by feeding into the anger and impatience that drives him.
	*goto continue_fighting

*label continue_fighting

*if (((meeting_sen) and (influence >= 3)) or ((meeting_sen) and (ritual >= 20)))
	*set self_strength %+20

	You focus and reach across the chasm between dreams and waking life. You are surprised by how easy it is. You tug the chord and it yields. Just like that, Sen is standing before you. 

	He looks around, surprised and disoriented, but not for long. He draws his blade when he sees Wolf.

	"Wolf. Pleased to make your acquaintance. I am commander Sen of the Rising Sun coalition. I am honored. I hope you will not mind if I make a blanket out of your pelt when we are finished here, it looks comfortable."

	The fierce god laughs. It is a strange snorting noise. 

	"I like this one, ${prenom}. He has a sense of humor. It will not save him, but maybe I will tear out just his throat."
*comment endif

Wolf comes at you in a blur of gray and white fur. You almost lose his shape against the white expanse of snow between you. 
*if (((meeting_sen) and (influence >= 3)) or ((meeting_sen) and (ritual >= 20)))
	Sen comes in from beside you and lunges toward Wolf. His sword slices horizontally and would have struck a grievous blow if Wolf had not been moving faster than Sen could track. The blow catches Wolf's side and causes the god to roar in pain and anger, but it hardly slows him. 
*comment endif 

As Wolf bears down on you, you react instinctively,
*if (((ritual + sensitivity) >= 50) or ((ritual + survival) >= 50))
	*set self_strength %+30
	twisting and cajoling the gently falling snow to riot and revolt, to grow uncontrollably. The snow explodes around Wolf, spreading from minuscule dots in the air to intricate, bladed constellations that catch his fur and tear into the flesh beneath. Wolf, bloodied and enraged, struggles through the maze of growing ice.
	*goto you_react
*elseif (((combat + survival) >= 50) or ((combat + quickthinking) >= 50))
	*set self_strength %+30
	wrestling him down to the snow-covered ground. Wolf yelps in surprise as you pin him underneath you, pulling on a reserve of strength and ferocity that might be a product of the dream and the force of your will. You do not have time to question it. You drive your fist into Wolf's enormous body over and over again as your lupine foe wails. 
	*goto you_react
*elseif ((quickthinking + survival) >= 40)
	*set self_strength %+30
	dodging out of the way and waiting until Wolf tries to circle back and come at you again. Instead, you take aim at one of his hind legs and deliver a vicious kick that causes him to buckle momentarily, long enough for you leap toward him and pummel him.
	*goto you_react
*else
	*set wolf_strength %+30
	throwing up your hands in defense, but Wolf is violently tenacious. His jaws close around your upper arm and lock. Pain lances your entire arm as you try to get him to disengage before he tears your entire arm out of its socket. When the pressure abates slightly, you are able to pull away. Blood flows freely from the wound and drips from Wolf's red-slicked maw. 

	*if ((meeting_sen) and (influence >= 3))
		"${prenom}!" Sen shouts. "Are you alright?"

		You nod gravely, but you are not sure.
	*goto you_react

*label you_react

*if wolf_strength >= self_strength
	*label hail_mary_pass
	Wolf cocks his head to one side.

	"This is enough now, is it not, ${prenom}?" Wolf says. "Yield."

	You are not sure you can win against Wolf, but you have decided not to yield and you will not betray your convictions.

	*if eel_affinity >= 60
		*check_achievements
		*if not(choice_achieved_eelhelper)
			*achieve eelhelper
		*set self_strength %+15
		The air tightens. It is hard to explain, but it is as if the space between things narrows and draws everything painfully close. The already cold air becomes frigid and you can feel each hair on your body. 

		"Elder Brother. You overstep." 

		The voice seeps in from the darkness around the edges of the woods. "${prenom} is not yours alone to take. And though our siblings are silent in your demesne, I have never been denied entry to any world I choose to slither into."

		"Eel," Wolf says, annoyed. "Little one, you should not put yourself in my way. You will regret it. Deeply."

		"I might," Eel says, his voice coming from the air itself. "But the uncertainty is half the fun."

		Cold air suddenly assaults you. You gasp from the brutal chill, and the cold, practically liquid now, rushes into your mouth and fills you with a terrible strength. Wolf watches in undisguised rage. 

		"You will not change a thing, Little Brother. I will wear ${his} fucking skin!"

		Wolf dashes toward you. 

		Your hands respond without thought and form gestures of prayer so complex that you can barely understand them. Whereas even the most practiced ritualist merely suggests, convinces, and begs for the sufferance of the elements, Eel drives you now, and he does not ask. The ground beneath Wolf's feet drops away and swirling dark waters take their place. Wolf tries to leap, but there is nothing beneath him and instead he sinks into the sudden whirlpool. Wolf roars with the full force of his breath, and the world shakes. Trees are ripped away from their roots and all the fallen snow is blasted outward from the epicenter of Wolf's scream. 

		Eventually, Wolf climbs out of the tide pool, his fur matted and his eyes are bloodshot. The woods around you are cleared, and you no longer feel Eel's presence. 

		"Always my siblings interfere. But no more interruptions, ${prenom}," Wolf says.
		*if self_strength >= wolf_strength
			He seems far worse for the wear. 
		*if wolf_strength > self_strength
			He gives you an unnerving smile.
		*comment endif
		*goto fight_scene_end
	*else
		Wolf moves to attack again and you rally one final, exhausted attempt to overpower him. He presses in on you and you raise an arm in defense, but Wolf stops in the last moment before his teeth sink in.
		*goto fight_scene_end
*else
	You look at Wolf, who in this moment does not seem quite so huge and ominous as he did a moment before. You could almost be convinced that this is not the same god who stalked your dreams and took hold of your being when you were a child.

	Wolf is defeated, you know it and you assume he knows it as well. He can growl and threaten, but he is not strong enough to consume you, and you no longer fear his wrath.
	*goto fight_scene_end

*label fight_scene_end
*return

*label final_fight_intellect
*comment I created this fight in case players had prioritized non-violent methods, so they would not feel trapped or cheated
*comment by a forced fisticuffs scenario. 

You barely look at Wolf before he is raising his lupine head and chuckling in your direction. 

"Is that your approach, little one. You are going to try to force me to behave? Best of luck."

*if ((pacifism) and (pacifism_broken = false))
	*set self_strength %+35
	Despite what Wolf says, you have faced challenge after challenge without resorting to violence. You do not have to be afraid of what he represents.
*comment endif

He takes a step forward. 
*if restraint >= 50
	*set self_strength %+15
	And you stay firmly rooted. 

	"Ah. You are resolved, I see. I wonder if it will help you do this impossible, ridiculous thing you have set out to do,"
	*goto intellect_fight_1
*else
	*set wolf_strength %+10
	And you take a step back. 

	"Do you mistrust yourself, ${prenom}? Fear that your non-violent plan will end in blood and tears like everything else in your life?"
	*goto intellect_fight_1

*label intellect_fight_1
Wolf says, and takes another step. 

"Stop," you command. 
*if ((influence >= 3) or (sensitivity >= 25))
	*set self_strength %+25
	It is only a moment, but Wolf does stop. 

	When he manages to push past the command and move forward, his motions are sluggish and jerky. He is no longer fully in control.
	*goto intellect_fight_2
*elseif influence >= 2
	*set self_strength %+15
	Wolf's front paw falters for a moment before it lands in the snow. The god's face changes as some thought or impulse flickers behind those sharp eyes. 
	*goto intellect_fight_2	
*else
	*set wolf_strength %+25
	But Wolf does not seem to be bothered or slowed by your imperative. He takes a deliberate step toward you. 
	*goto intellect_fight_2		

*label intellect_fight_2

"You are not my equal, ${prenom}. Stop this farce," he says, half-growling. 

If you are to prove him wrong, you will need to force the issue. This being a dream, your dream as much as Wolf's, you have power here that you might not in the corporeal world. You focus on Wolf and attempt to force his will to bend. You quickly find it is not that simple. When you reach out and try to impress your desires on him, you briefly touch the swirling chaos that is Wolf's mind and his intentions. It is abrasive, resolute, and it is angry.

*if pantheon_regard >= 7
	*set wolf_strength %-10
	The roil almost sends you tumbling into anguish and potentially madness, but a reassuring force adds their power to yours. 

	Wolf's mind lets out something like a scream. 

	"Sister! You would interfere in this?" Wolf snaps. 

	The force forms words which are soft, but you have no trouble hearing them. 

	"Brother, your chaos threatens to swallow up your chosen one. $!{he} should not be destroyed for ${his} loyalty," Gazelle says to Wolf, then to you, "I have distracted him. Now, ${prenom}. Fight with everything within you."

Your attempt to penetrate that writhing mass
*if sensitivity >= 30
	*set self_strength %+30
	threatens to break the solidity of your own mind. Memories rise unbidden: your first taste of the spiced ${tribe} wine, the smell of fire, the tenderness of your very first friendship. But in the end, those memories anchor you and keep you from spiraling when Wolf's consciousness pushes back against yours. 

	*label mind_win

	You push back twice as hard, and Wolf flinches. His mind still resists your attempt at domination, but there is a new note in the frantic song that is his thinking: uncertainty. He stands and regards you. 

	"You think this solves things, ${prenom}? Victory is not assured for you. Not with these tricks of yours."

	*return
*elseif ((sensitivity + quickthinking) >= 40)
	*set self_strength %+30
	causes you to recoil in an attempt to protect yourself, but you cannot win this fight through restraint alone. You push back and navigate the straits of Wolf's feral thoughts with as much care as you can muster.

	*goto mind_win
*else
	*set wolf_strength %+25
	is rebuffed immediately and thoroughly. You feel a sense of whiplash as Wolf sends you reeling from the ferocity of his psychic defense. 

	"Child. You think you are the first to try to cow me? In the countless years that I have stalked this world and the world beyond?"

	*return

*label gobbling_wolf_up
*comment this is the scenario that happens if you try to do something besides eating wolf, but you don't have 
*comment the proper level of restraint.

You intend to leave Wolf as he is, but your mouth salivates and you are suddenly so hungry.

*label eating_wolf
*set action %+30
*set deliberation %-30
*check_achievements
*if not(choice_achieved_godeater)
	*achieve godeater
*if pacifism
	*set pacifism_broken true
*set wolf_eaten_trigger true

Wolf's weakened state kindles something in you, something less than human, and you do not have the restraint to disobey. You attack the weakened god and begin to bite and tear at his flesh with your teeth. What fills your mouth and warms your gut is not blood, but power. Raw. Undiluted. 

You feel what little agency Wolf has left stirring in your belly, in your soul, but it is soon snuffed out. A powerful thrill races up your spine. 

*return
